Ada95/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2019,2020 Thomas E. Dickey                                *
   3 dnl Copyright 2010-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey
  31 dnl
  32 dnl $Id: aclocal.m4,v 1.157 2020/05/31 20:52:36 tom Exp $
  33 dnl Macros used in NCURSES Ada95 auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See these pages for additional information:
  40 dnl             https://invisible-island.net/autoconf/
  41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  42 dnl
  43 dnl ---------------------------------------------------------------------------
  44 dnl ---------------------------------------------------------------------------
  45 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
  46 dnl ------------------
  47 dnl Conditionally generate script according to whether we're using a given autoconf.
  48 dnl
  49 dnl $1 = version to compare against
  50 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  51 dnl $3 = code to use if AC_ACVERSION is older than $1.
  52 define([CF_ACVERSION_CHECK],
  53 [
  54 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
  55 ifdef([m4_version_compare],
  56 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  57 [CF_ACVERSION_COMPARE(
  58 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  59 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  60 dnl ---------------------------------------------------------------------------
  61 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  62 dnl --------------------
  63 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  64 dnl                      MAJOR2, MINOR2, TERNARY2,
  65 dnl                      PRINTABLE2, not FOUND, FOUND)
  66 define([CF_ACVERSION_COMPARE],
  67 [ifelse(builtin([eval], [$2 < $5]), 1,
  68 [ifelse([$8], , ,[$8])],
  69 [ifelse([$9], , ,[$9])])])dnl
  70 dnl ---------------------------------------------------------------------------
  71 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
  72 dnl -------------------
  73 dnl Construct the list of include-options for the C programs in the Ada95
  74 dnl binding.
  75 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  76 [
  77 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  78 if test "$srcdir" != "."; then
  79         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  80 fi
  81 if test "$GCC" != yes; then
  82         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  83 elif test "$includedir" != "/usr/include"; then
  84         if test "$includedir" = '${prefix}/include' ; then
  85                 if test x$prefix != x/usr ; then
  86                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  87                 fi
  88         else
  89                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  90         fi
  91 fi
  92 AC_SUBST(ACPPFLAGS)
  93 ])dnl
  94 dnl ---------------------------------------------------------------------------
  95 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
  96 dnl ---------------
  97 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
  98 AC_DEFUN([CF_ADD_ADAFLAGS],[
  99         ADAFLAGS="$ADAFLAGS $1"
 100         AC_SUBST(ADAFLAGS)
 101 ])dnl
 102 dnl ---------------------------------------------------------------------------
 103 dnl CF_ADD_CFLAGS version: 14 updated: 2020/04/04 16:16:13
 104 dnl -------------
 105 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 106 dnl $1 = flags to add
 107 dnl $2 = if given makes this macro verbose.
 108 dnl
 109 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 110 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 111 dnl confused by the quotes (which require backslashes to keep them usable).
 112 AC_DEFUN([CF_ADD_CFLAGS],
 113 [
 114 cf_fix_cppflags=no
 115 cf_new_cflags=
 116 cf_new_cppflags=
 117 cf_new_extra_cppflags=
 118
 119 for cf_add_cflags in $1
 120 do
 121 case $cf_fix_cppflags in
 122 (no)
 123         case $cf_add_cflags in
 124         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 125                 case $cf_add_cflags in
 126                 (-D*)
 127                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 128
 129                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 130                                 && test -z "${cf_tst_cflags}" \
 131                                 && cf_fix_cppflags=yes
 132
 133                         if test $cf_fix_cppflags = yes ; then
 134                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 135                                 continue
 136                         elif test "${cf_tst_cflags}" = "\"'" ; then
 137                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 138                                 continue
 139                         fi
 140                         ;;
 141                 esac
 142                 case "$CPPFLAGS" in
 143                 (*$cf_add_cflags)
 144                         ;;
 145                 (*)
 146                         case $cf_add_cflags in
 147                         (-D*)
 148                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 149                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 150                                 ;;
 151                         esac
 152                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 153                         ;;
 154                 esac
 155                 ;;
 156         (*)
 157                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 158                 ;;
 159         esac
 160         ;;
 161 (yes)
 162         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 163
 164         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 165
 166         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 167                 && test -z "${cf_tst_cflags}" \
 168                 && cf_fix_cppflags=no
 169         ;;
 170 esac
 171 done
 172
 173 if test -n "$cf_new_cflags" ; then
 174         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 175         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 176 fi
 177
 178 if test -n "$cf_new_cppflags" ; then
 179         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 180         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 181 fi
 182
 183 if test -n "$cf_new_extra_cppflags" ; then
 184         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 185         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 186 fi
 187
 188 AC_SUBST(EXTRA_CPPFLAGS)
 189
 190 ])dnl
 191 dnl ---------------------------------------------------------------------------
 192 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
 193 dnl -------------
 194 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 195 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 196 dnl but old versions (and some misinstalled ones) need that.  To make things
 197 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 198 dnl the include-path).
 199 AC_DEFUN([CF_ADD_INCDIR],
 200 [
 201 if test -n "$1" ; then
 202   for cf_add_incdir in $1
 203   do
 204         while test $cf_add_incdir != /usr/include
 205         do
 206           if test -d $cf_add_incdir
 207           then
 208                 cf_have_incdir=no
 209                 if test -n "$CFLAGS$CPPFLAGS" ; then
 210                   # a loop is needed to ensure we can add subdirs of existing dirs
 211                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 212                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 213                           cf_have_incdir=yes; break
 214                         fi
 215                   done
 216                 fi
 217
 218                 if test "$cf_have_incdir" = no ; then
 219                   if test "$cf_add_incdir" = /usr/local/include ; then
 220                         if test "$GCC" = yes
 221                         then
 222                           cf_save_CPPFLAGS=$CPPFLAGS
 223                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 224                           AC_TRY_COMPILE([#include <stdio.h>],
 225                                   [printf("Hello")],
 226                                   [],
 227                                   [cf_have_incdir=yes])
 228                           CPPFLAGS=$cf_save_CPPFLAGS
 229                         fi
 230                   fi
 231                 fi
 232
 233                 if test "$cf_have_incdir" = no ; then
 234                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 235                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 236
 237                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 238                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 239                   cf_add_incdir="$cf_top_incdir"
 240                 else
 241                   break
 242                 fi
 243           else
 244                 break
 245           fi
 246         done
 247   done
 248 fi
 249 ])dnl
 250 dnl ---------------------------------------------------------------------------
 251 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 252 dnl ----------
 253 dnl Add a library, used to enforce consistency.
 254 dnl
 255 dnl $1 = library to add, without the "-l"
 256 dnl $2 = variable to update (default $LIBS)
 257 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 258 dnl ---------------------------------------------------------------------------
 259 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 260 dnl -------------
 261 dnl     Adds to the library-path
 262 dnl
 263 dnl     Some machines have trouble with multiple -L options.
 264 dnl
 265 dnl $1 is the (list of) directory(s) to add
 266 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 267 dnl
 268 AC_DEFUN([CF_ADD_LIBDIR],
 269 [
 270 if test -n "$1" ; then
 271         for cf_add_libdir in $1
 272         do
 273                 if test $cf_add_libdir = /usr/lib ; then
 274                         :
 275                 elif test -d $cf_add_libdir
 276                 then
 277                         cf_have_libdir=no
 278                         if test -n "$LDFLAGS$LIBS" ; then
 279                                 # a loop is needed to ensure we can add subdirs of existing dirs
 280                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 281                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 282                                                 cf_have_libdir=yes; break
 283                                         fi
 284                                 done
 285                         fi
 286                         if test "$cf_have_libdir" = no ; then
 287                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 288                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 289                         fi
 290                 fi
 291         done
 292 fi
 293 ])dnl
 294 dnl ---------------------------------------------------------------------------
 295 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 296 dnl -----------
 297 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 298 dnl prepended to an existing list, since their dependencies are assumed to
 299 dnl already exist in the list.
 300 dnl
 301 dnl $1 = libraries to add, with the "-l", etc.
 302 dnl $2 = variable to update (default $LIBS)
 303 AC_DEFUN([CF_ADD_LIBS],[
 304 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 305 # reverse order
 306 cf_add_0lib=
 307 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 308 # filter duplicates
 309 for cf_add_1lib in $cf_add_0lib; do
 310         for cf_add_2lib in $cf_add_libs; do
 311                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 312                         cf_add_1lib=
 313                         break
 314                 fi
 315         done
 316         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 317 done
 318 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 319 ])dnl
 320 dnl ---------------------------------------------------------------------------
 321 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 322 dnl ------------------
 323 dnl Append to a search-list for a nonstandard header/lib-file
 324 dnl     $1 = the variable to return as result
 325 dnl     $2 = the package name
 326 dnl     $3 = the subdirectory, e.g., bin, include or lib
 327 dnl $4 = the directory under which we will test for subdirectories
 328 dnl $5 = a directory that we do not want $4 to match
 329 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 330 [
 331 test "x$4" != "x$5" && \
 332 test -d "$4" && \
 333 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 334         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 335         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 336         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 337         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 338         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 339         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 340 }
 341 ])dnl
 342 dnl ---------------------------------------------------------------------------
 343 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 344 dnl --------------
 345 dnl use this macro for appending text without introducing an extra blank at
 346 dnl the beginning
 347 define([CF_APPEND_TEXT],
 348 [
 349         test -n "[$]$1" && $1="[$]$1 "
 350         $1="[$]{$1}$2"
 351 ])dnl
 352 dnl ---------------------------------------------------------------------------
 353 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 354 dnl --------------
 355 dnl Allow user to disable a normally-on option.
 356 AC_DEFUN([CF_ARG_DISABLE],
 357 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 358 dnl ---------------------------------------------------------------------------
 359 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 360 dnl -------------
 361 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 362 dnl values.
 363 dnl
 364 dnl Parameters:
 365 dnl $1 = option name
 366 dnl $2 = help-string
 367 dnl $3 = action to perform if option is not default
 368 dnl $4 = action if perform if option is default
 369 dnl $5 = default option value (either 'yes' or 'no')
 370 AC_DEFUN([CF_ARG_OPTION],
 371 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 372         if test "$enableval" != "$5" ; then
 373 ifelse([$3],,[    :]dnl
 374 ,[    $3]) ifelse([$4],,,[
 375         else
 376                 $4])
 377         fi],[enableval=$5 ifelse([$4],,,[
 378         $4
 379 ])dnl
 380 ])])dnl
 381 dnl ---------------------------------------------------------------------------
 382 dnl CF_AR_FLAGS version: 7 updated: 2020/04/04 11:37:29
 383 dnl -----------
 384 dnl Check for suitable "ar" (archiver) options for updating an archive.
 385 dnl
 386 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 387 dnl as well as a workaround for breakage of make's archive rules by the GNU
 388 dnl binutils "ar" program.
 389 AC_DEFUN([CF_AR_FLAGS],[
 390 AC_REQUIRE([CF_PROG_AR])
 391
 392 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 393         case $cf_cv_system_name in
 394         (*-msvc*)
 395                 cf_cv_ar_flags=''
 396                 cat >mk_static_lib.sh <<-EOF
 397                 #!$SHELL
 398                 MSVC_BIN="[$]AR"
 399                 out="\[$]1"
 400                 shift
 401                 exec \[$]MSVC_BIN -out:"\[$]out" \[$]@
 402                 EOF
 403                 chmod +x mk_static_lib.sh
 404                 AR=`pwd`/mk_static_lib.sh
 405                 ;;
 406         (*)
 407                 cf_cv_ar_flags=unknown
 408                 for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 409                 do
 410
 411                         # check if $ARFLAGS already contains this choice
 412                         if test "x$ARFLAGS" != "x" ; then
 413                                 cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 414                                 if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 415                                         cf_cv_ar_flags=
 416                                         break
 417                                 fi
 418                         fi
 419
 420                         rm -f conftest.$ac_cv_objext
 421                         rm -f conftest.a
 422
 423                         cat >conftest.$ac_ext <<EOF
 424 #line __oline__ "configure"
 425 int     testdata[[3]] = { 123, 456, 789 };
 426 EOF
 427                         if AC_TRY_EVAL(ac_compile) ; then
 428                                 echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 429                                 $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 430                                 if test -f conftest.a ; then
 431                                         cf_cv_ar_flags=$cf_ar_flags
 432                                         break
 433                                 fi
 434                         else
 435                                 CF_VERBOSE(cannot compile test-program)
 436                                 break
 437                         fi
 438                 done
 439                 rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 440                 ;;
 441         esac
 442 ])
 443
 444 if test -n "$ARFLAGS" ; then
 445         if test -n "$cf_cv_ar_flags" ; then
 446                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 447         fi
 448 else
 449         ARFLAGS=$cf_cv_ar_flags
 450 fi
 451
 452 AC_SUBST(ARFLAGS)
 453 ])
 454 dnl ---------------------------------------------------------------------------
 455 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
 456 dnl -----------
 457 dnl If we're cross-compiling, allow the user to override the tools and their
 458 dnl options.  The configure script is oriented toward identifying the host
 459 dnl compiler, etc., but we need a build compiler to generate parts of the
 460 dnl source.
 461 dnl
 462 dnl $1 = default for $CPPFLAGS
 463 dnl $2 = default for $LIBS
 464 AC_DEFUN([CF_BUILD_CC],[
 465 CF_ACVERSION_CHECK(2.52,,
 466         [AC_REQUIRE([CF_PROG_EXT])])
 467 if test "$cross_compiling" = yes ; then
 468
 469         # defaults that we might want to override
 470         : ${BUILD_CFLAGS:=''}
 471         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 472         : ${BUILD_LDFLAGS:=''}
 473         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 474         : ${BUILD_EXEEXT:='$x'}
 475         : ${BUILD_OBJEXT:='o'}
 476
 477         AC_ARG_WITH(build-cc,
 478                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 479                 [BUILD_CC="$withval"],
 480                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 481         AC_MSG_CHECKING(for native build C compiler)
 482         AC_MSG_RESULT($BUILD_CC)
 483
 484         AC_MSG_CHECKING(for native build C preprocessor)
 485         AC_ARG_WITH(build-cpp,
 486                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 487                 [BUILD_CPP="$withval"],
 488                 [BUILD_CPP='${BUILD_CC} -E'])
 489         AC_MSG_RESULT($BUILD_CPP)
 490
 491         AC_MSG_CHECKING(for native build C flags)
 492         AC_ARG_WITH(build-cflags,
 493                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 494                 [BUILD_CFLAGS="$withval"])
 495         AC_MSG_RESULT($BUILD_CFLAGS)
 496
 497         AC_MSG_CHECKING(for native build C preprocessor-flags)
 498         AC_ARG_WITH(build-cppflags,
 499                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 500                 [BUILD_CPPFLAGS="$withval"])
 501         AC_MSG_RESULT($BUILD_CPPFLAGS)
 502
 503         AC_MSG_CHECKING(for native build linker-flags)
 504         AC_ARG_WITH(build-ldflags,
 505                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 506                 [BUILD_LDFLAGS="$withval"])
 507         AC_MSG_RESULT($BUILD_LDFLAGS)
 508
 509         AC_MSG_CHECKING(for native build linker-libraries)
 510         AC_ARG_WITH(build-libs,
 511                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 512                 [BUILD_LIBS="$withval"])
 513         AC_MSG_RESULT($BUILD_LIBS)
 514
 515         # this assumes we're on Unix.
 516         BUILD_EXEEXT=
 517         BUILD_OBJEXT=o
 518
 519         : ${BUILD_CC:='${CC}'}
 520
 521         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 522                 AC_MSG_ERROR([Cross-build requires two compilers.
 523 Use --with-build-cc to specify the native compiler.])
 524         fi
 525
 526 else
 527         : ${BUILD_CC:='${CC}'}
 528         : ${BUILD_CPP:='${CPP}'}
 529         : ${BUILD_CFLAGS:='${CFLAGS}'}
 530         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 531         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 532         : ${BUILD_LIBS:='${LIBS}'}
 533         : ${BUILD_EXEEXT:='$x'}
 534         : ${BUILD_OBJEXT:='o'}
 535 fi
 536
 537 AC_SUBST(BUILD_CC)
 538 AC_SUBST(BUILD_CPP)
 539 AC_SUBST(BUILD_CFLAGS)
 540 AC_SUBST(BUILD_CPPFLAGS)
 541 AC_SUBST(BUILD_LDFLAGS)
 542 AC_SUBST(BUILD_LIBS)
 543 AC_SUBST(BUILD_EXEEXT)
 544 AC_SUBST(BUILD_OBJEXT)
 545 ])dnl
 546 dnl ---------------------------------------------------------------------------
 547 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
 548 dnl ---------------
 549 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 550 dnl into CC.  This will not help with broken scripts that wrap the compiler
 551 dnl with options, but eliminates a more common category of user confusion.
 552 dnl
 553 dnl In particular, it addresses the problem of being able to run the C
 554 dnl preprocessor in a consistent manner.
 555 dnl
 556 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 557 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 558 dnl outweighs that limitation.
 559 AC_DEFUN([CF_CC_ENV_FLAGS],
 560 [
 561 # This should have been defined by AC_PROG_CC
 562 : ${CC:=cc}
 563
 564 AC_MSG_CHECKING(\$CFLAGS variable)
 565 case "x$CFLAGS" in
 566 (*-[[IUD]]*)
 567         AC_MSG_RESULT(broken)
 568         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 569         cf_flags="$CFLAGS"
 570         CFLAGS=
 571         for cf_arg in $cf_flags
 572         do
 573                 CF_ADD_CFLAGS($cf_arg)
 574         done
 575         ;;
 576 (*)
 577         AC_MSG_RESULT(ok)
 578         ;;
 579 esac
 580
 581 AC_MSG_CHECKING(\$CC variable)
 582 case "$CC" in
 583 (*[[\ \ ]]-*)
 584         AC_MSG_RESULT(broken)
 585         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 586         # humor him...
 587         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 588         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 589         CC="$cf_prog"
 590         for cf_arg in $cf_flags
 591         do
 592                 case "x$cf_arg" in
 593                 (x-[[IUDfgOW]]*)
 594                         CF_ADD_CFLAGS($cf_arg)
 595                         ;;
 596                 (*)
 597                         CC="$CC $cf_arg"
 598                         ;;
 599                 esac
 600         done
 601         CF_VERBOSE(resulting CC: '$CC')
 602         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 603         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 604         ;;
 605 (*)
 606         AC_MSG_RESULT(ok)
 607         ;;
 608 esac
 609 ])dnl
 610 dnl ---------------------------------------------------------------------------
 611 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 612 dnl ---------------
 613 dnl Determine the default configuration into which we'll install ncurses.  This
 614 dnl can be overridden by the user's command-line options.  There's two items to
 615 dnl look for:
 616 dnl     1. the prefix (e.g., /usr)
 617 dnl     2. the header files (e.g., /usr/include/ncurses)
 618 dnl We'll look for a previous installation of ncurses and use the same defaults.
 619 dnl
 620 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 621 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 622 dnl programs from a vendor's.
 623 AC_DEFUN([CF_CFG_DEFAULTS],
 624 [
 625 AC_MSG_CHECKING(for prefix)
 626 if test "x$prefix" = "xNONE" ; then
 627         case "$cf_cv_system_name" in
 628                 # non-vendor systems don't have a conflict
 629         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 630                 prefix=/usr
 631                 ;;
 632         (*)     prefix=$ac_default_prefix
 633                 ;;
 634         esac
 635 fi
 636 AC_MSG_RESULT($prefix)
 637
 638 if test "x$prefix" = "xNONE" ; then
 639 AC_MSG_CHECKING(for default include-directory)
 640 test -n "$verbose" && echo 1>&AC_FD_MSG
 641 for cf_symbol in \
 642         $includedir \
 643         $includedir/ncurses \
 644         $prefix/include \
 645         $prefix/include/ncurses \
 646         /usr/local/include \
 647         /usr/local/include/ncurses \
 648         /usr/include \
 649         /usr/include/ncurses
 650 do
 651         cf_dir=`eval echo $cf_symbol`
 652         if test -f $cf_dir/curses.h ; then
 653         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 654                 includedir="$cf_symbol"
 655                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 656                 break
 657         fi
 658         fi
 659         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 660 done
 661 AC_MSG_RESULT($includedir)
 662 fi
 663 ])dnl
 664 dnl ---------------------------------------------------------------------------
 665 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 666 dnl --------------
 667 dnl Check if we're accidentally using a cache from a different machine.
 668 dnl Derive the system name, as a check for reusing the autoconf cache.
 669 dnl
 670 dnl If we've packaged config.guess and config.sub, run that (since it does a
 671 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 672 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 673 dnl which is useful in cross-compiles.
 674 dnl
 675 dnl Note: we would use $ac_config_sub, but that is one of the places where
 676 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 677 AC_DEFUN([CF_CHECK_CACHE],
 678 [
 679 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 680         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 681         system_name="$host_os"
 682 else
 683         system_name="`(uname -s -r) 2>/dev/null`"
 684         if test -z "$system_name" ; then
 685                 system_name="`(hostname) 2>/dev/null`"
 686         fi
 687 fi
 688 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 689 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 690
 691 test -z "$system_name" && system_name="$cf_cv_system_name"
 692 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 693
 694 if test ".$system_name" != ".$cf_cv_system_name" ; then
 695         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 696         AC_MSG_ERROR("Please remove config.cache and try again.")
 697 fi
 698 ])dnl
 699 dnl ---------------------------------------------------------------------------
 700 dnl CF_CHECK_GNAT_VERSION version: 3 updated: 2020/05/23 19:39:36
 701 dnl ---------------------
 702 AC_DEFUN([CF_CHECK_GNAT_VERSION],
 703 [
 704 AC_REQUIRE([CF_GNAT_VERSION])
 705 case $cf_cv_gnat_version in
 706 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
 707         cf_cv_prog_gnat_correct=yes
 708         ;;
 709 (*)
 710         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
 711         cf_cv_prog_gnat_correct=no
 712         ;;
 713 esac
 714 ])
 715 dnl ---------------------------------------------------------------------------
 716 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
 717 dnl -----------------
 718 dnl Check if the given compiler is really clang.  clang's C driver defines
 719 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 720 dnl not ignore some gcc options.
 721 dnl
 722 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 723 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 724 dnl the wrappers for gcc and g++ warnings.
 725 dnl
 726 dnl $1 = GCC (default) or GXX
 727 dnl $2 = CLANG_COMPILER (default)
 728 dnl $3 = CFLAGS (default) or CXXFLAGS
 729 AC_DEFUN([CF_CLANG_COMPILER],[
 730 ifelse([$2],,CLANG_COMPILER,[$2])=no
 731
 732 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 733         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 734         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 735         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 736         AC_TRY_COMPILE([],[
 737 #ifdef __clang__
 738 #else
 739 make an error
 740 #endif
 741 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 742 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
 743 ],[])
 744         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 745         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 746 fi
 747 ])
 748 dnl ---------------------------------------------------------------------------
 749 dnl CF_CONST_X_STRING version: 4 updated: 2020/03/10 18:53:47
 750 dnl -----------------
 751 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
 752 dnl character-strings.
 753 dnl
 754 dnl It is ambiguous because the specification accommodated the pre-ANSI
 755 dnl compilers bundled by more than one vendor in lieu of providing a standard C
 756 dnl compiler other than by costly add-ons.  Because of this, the specification
 757 dnl did not take into account the use of const for telling the compiler that
 758 dnl string literals would be in readonly memory.
 759 dnl
 760 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
 761 dnl let the compiler decide how to represent Xt's strings which were #define'd.
 762 dnl That does not solve the problem of using the block of Xt's strings which
 763 dnl are compiled into the library (and is less efficient than one might want).
 764 dnl
 765 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
 766 dnl when compiling the library and compiling using the library, to tell the
 767 dnl compiler that String is const.
 768 AC_DEFUN([CF_CONST_X_STRING],
 769 [
 770 AC_REQUIRE([AC_PATH_XTRA])
 771
 772 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
 773
 774 AC_TRY_COMPILE(
 775 [
 776 #include <stdlib.h>
 777 #include <X11/Intrinsic.h>
 778 ],
 779 [String foo = malloc(1); (void)foo],[
 780
 781 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
 782         AC_TRY_COMPILE(
 783                 [
 784 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
 785 #undef  XTSTRINGDEFINES /* X11R5 and later */
 786 #include <stdlib.h>
 787 #include <X11/Intrinsic.h>
 788                 ],[String foo = malloc(1); *foo = 0],[
 789                         cf_cv_const_x_string=no
 790                 ],[
 791                         cf_cv_const_x_string=yes
 792                 ])
 793 ])
 794
 795 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
 796
 797 case $cf_cv_const_x_string in
 798 (no)
 799         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
 800         ;;
 801 (*)
 802         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
 803         ;;
 804 esac
 805
 806 ])
 807 ])dnl
 808 dnl ---------------------------------------------------------------------------
 809 dnl CF_CONST_X_STRING version: 4 updated: 2020/03/10 18:53:47
 810 dnl -----------------
 811 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
 812 dnl character-strings.
 813 dnl
 814 dnl It is ambiguous because the specification accommodated the pre-ANSI
 815 dnl compilers bundled by more than one vendor in lieu of providing a standard C
 816 dnl compiler other than by costly add-ons.  Because of this, the specification
 817 dnl did not take into account the use of const for telling the compiler that
 818 dnl string literals would be in readonly memory.
 819 dnl
 820 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
 821 dnl let the compiler decide how to represent Xt's strings which were #define'd.
 822 dnl That does not solve the problem of using the block of Xt's strings which
 823 dnl are compiled into the library (and is less efficient than one might want).
 824 dnl
 825 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
 826 dnl when compiling the library and compiling using the library, to tell the
 827 dnl compiler that String is const.
 828 AC_DEFUN([CF_CONST_X_STRING],
 829 [
 830 AC_REQUIRE([AC_PATH_XTRA])
 831
 832 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
 833
 834 AC_TRY_COMPILE(
 835 [
 836 #include <stdlib.h>
 837 #include <X11/Intrinsic.h>
 838 ],
 839 [String foo = malloc(1); (void)foo],[
 840
 841 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
 842         AC_TRY_COMPILE(
 843                 [
 844 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
 845 #undef  XTSTRINGDEFINES /* X11R5 and later */
 846 #include <stdlib.h>
 847 #include <X11/Intrinsic.h>
 848                 ],[String foo = malloc(1); *foo = 0],[
 849                         cf_cv_const_x_string=no
 850                 ],[
 851                         cf_cv_const_x_string=yes
 852                 ])
 853 ])
 854
 855 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
 856
 857 case $cf_cv_const_x_string in
 858 (no)
 859         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
 860         ;;
 861 (*)
 862         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
 863         ;;
 864 esac
 865
 866 ])
 867 ])dnl
 868 dnl ---------------------------------------------------------------------------
 869 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
 870 dnl ----------------
 871 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 872 dnl variations of ncurses' installs.
 873 dnl
 874 dnl $1 = ncurses when looking for ncurses, or is empty
 875 AC_DEFUN([CF_CURSES_HEADER],[
 876 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 877 cf_cv_ncurses_header=none
 878 for cf_header in \
 879         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
 880         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 881 do
 882 AC_TRY_COMPILE([#include <${cf_header}>],
 883         [initscr(); tgoto("?", 0,0)],
 884         [cf_cv_ncurses_header=$cf_header; break],[])
 885 done
 886 ])
 887
 888 if test "$cf_cv_ncurses_header" = none ; then
 889         AC_MSG_ERROR(No curses header-files found)
 890 fi
 891
 892 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 893 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 894 ])dnl
 895 dnl ---------------------------------------------------------------------------
 896 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
 897 dnl ----------
 898 dnl "dirname" is not portable, so we fake it with a shell script.
 899 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
 900 dnl ---------------------------------------------------------------------------
 901 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
 902 dnl ---------------
 903 dnl You can always use "make -n" to see the actual options, but it's hard to
 904 dnl pick out/analyze warning messages when the compile-line is long.
 905 dnl
 906 dnl Sets:
 907 dnl     ECHO_LT - symbol to control if libtool is verbose
 908 dnl     ECHO_LD - symbol to prefix "cc -o" lines
 909 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
 910 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
 911 dnl     ECHO_CC - symbol to put before any "cc" line
 912 dnl
 913 AC_DEFUN([CF_DISABLE_ECHO],[
 914 AC_MSG_CHECKING(if you want to see long compiling messages)
 915 CF_ARG_DISABLE(echo,
 916         [  --disable-echo          do not display "compiling" commands],
 917         [
 918         ECHO_LT='--silent'
 919         ECHO_LD='@echo linking [$]@;'
 920         RULE_CC='@echo compiling [$]<'
 921         SHOW_CC='@echo compiling [$]@'
 922         ECHO_CC='@'
 923 ],[
 924         ECHO_LT=''
 925         ECHO_LD=''
 926         RULE_CC=''
 927         SHOW_CC=''
 928         ECHO_CC=''
 929 ])
 930 AC_MSG_RESULT($enableval)
 931 AC_SUBST(ECHO_LT)
 932 AC_SUBST(ECHO_LD)
 933 AC_SUBST(RULE_CC)
 934 AC_SUBST(SHOW_CC)
 935 AC_SUBST(ECHO_CC)
 936 ])dnl
 937 dnl ---------------------------------------------------------------------------
 938 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
 939 dnl ------------------------
 940 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
 941 AC_MSG_CHECKING(if we want to use GNAT projects)
 942 CF_ARG_DISABLE(gnat-projects,
 943         [  --disable-gnat-projects test: disable GNAT projects even if usable],
 944         [enable_gnat_projects=no],
 945         [enable_gnat_projects=yes])
 946 AC_MSG_RESULT($enable_gnat_projects)
 947 ])dnl
 948 dnl ---------------------------------------------------------------------------
 949 dnl CF_ENABLE_BROKEN_LINKER version: 1 updated: 2020/02/08 15:59:30
 950 dnl -----------------------
 951 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
 952 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
 953 dnl an unconditional feature.
 954 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
 955
 956 AC_MSG_CHECKING(if you want broken-linker support code)
 957 AC_ARG_ENABLE(broken_linker,
 958         [  --enable-broken_linker  compile with broken-linker support code],
 959         [with_broken_linker=$enableval],
 960         [with_broken_linker=no])
 961 AC_MSG_RESULT($with_broken_linker)
 962
 963 : ${BROKEN_LINKER:=0}
 964 if test "x$with_broken_linker" = xyes ; then
 965         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
 966         BROKEN_LINKER=1
 967 fi
 968 AC_SUBST(BROKEN_LINKER)
 969 ])dnl
 970 dnl ---------------------------------------------------------------------------
 971 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
 972 dnl ---------------
 973 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
 974 dnl prefer a standard location, and use -L options only if we do not find the
 975 dnl library in the standard library location(s).
 976 dnl     $1 = library name
 977 dnl     $2 = library class, usually the same as library name
 978 dnl     $3 = includes
 979 dnl     $4 = code fragment to compile/link
 980 dnl     $5 = corresponding function-name
 981 dnl     $6 = flag, nonnull if failure should not cause an error-exit
 982 dnl
 983 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
 984 dnl to use a -L option.
 985 AC_DEFUN([CF_FIND_LIBRARY],
 986 [
 987         eval 'cf_cv_have_lib_'$1'=no'
 988         cf_libdir=""
 989         AC_CHECK_FUNC($5,
 990                 eval 'cf_cv_have_lib_'$1'=yes',[
 991                 cf_save_LIBS="$LIBS"
 992                 AC_MSG_CHECKING(for $5 in -l$1)
 993                 LIBS="-l$1 $LIBS"
 994                 AC_TRY_LINK([$3],[$4],
 995                         [AC_MSG_RESULT(yes)
 996                          eval 'cf_cv_have_lib_'$1'=yes'
 997                         ],
 998                         [AC_MSG_RESULT(no)
 999                         CF_LIBRARY_PATH(cf_search,$2)
1000                         for cf_libdir in $cf_search
1001                         do
1002                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1003                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1004                                 AC_TRY_LINK([$3],[$4],
1005                                         [AC_MSG_RESULT(yes)
1006                                          eval 'cf_cv_have_lib_'$1'=yes'
1007                                          break],
1008                                         [AC_MSG_RESULT(no)
1009                                          LIBS="$cf_save_LIBS"])
1010                         done
1011                         ])
1012                 ])
1013 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
1014 ifelse($6,,[
1015 if test $cf_found_library = no ; then
1016         AC_MSG_ERROR(Cannot link $1 library)
1017 fi
1018 ])
1019 ])dnl
1020 dnl ---------------------------------------------------------------------------
1021 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
1022 dnl ---------------
1023 dnl Find a library (specifically the linkage used in the code fragment),
1024 dnl searching for it if it is not already in the library path.
1025 dnl See also CF_ADD_SEARCHPATH.
1026 dnl
1027 dnl Parameters (4-on are optional):
1028 dnl     $1 = headers for library entrypoint
1029 dnl     $2 = code fragment for library entrypoint
1030 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1031 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1032 dnl     $5 = action to perform if not successful
1033 dnl     $6 = module name, if not the same as the library name
1034 dnl     $7 = extra libraries
1035 dnl
1036 dnl Sets these variables:
1037 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1038 dnl     $cf_cv_header_path_$3 - include-directory if needed
1039 dnl     $cf_cv_library_path_$3 - library-directory if needed
1040 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1041 AC_DEFUN([CF_FIND_LINKAGE],[
1042
1043 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1044 # will be set on completion of the AC_TRY_LINK below.
1045 cf_cv_header_path_$3=
1046 cf_cv_library_path_$3=
1047
1048 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1049
1050 cf_save_LIBS="$LIBS"
1051
1052 AC_TRY_LINK([$1],[$2],[
1053         cf_cv_find_linkage_$3=yes
1054         cf_cv_header_path_$3=/usr/include
1055         cf_cv_library_path_$3=/usr/lib
1056 ],[
1057
1058 LIBS="-l$3 $7 $cf_save_LIBS"
1059
1060 AC_TRY_LINK([$1],[$2],[
1061         cf_cv_find_linkage_$3=yes
1062         cf_cv_header_path_$3=/usr/include
1063         cf_cv_library_path_$3=/usr/lib
1064         cf_cv_library_file_$3="-l$3"
1065 ],[
1066         cf_cv_find_linkage_$3=no
1067         LIBS="$cf_save_LIBS"
1068
1069         CF_VERBOSE(find linkage for $3 library)
1070         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1071
1072         cf_save_CPPFLAGS="$CPPFLAGS"
1073         cf_test_CPPFLAGS="$CPPFLAGS"
1074
1075         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1076         for cf_cv_header_path_$3 in $cf_search
1077         do
1078                 if test -d $cf_cv_header_path_$3 ; then
1079                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1080                         CPPFLAGS="$cf_save_CPPFLAGS"
1081                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1082                         AC_TRY_COMPILE([$1],[$2],[
1083                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1084                                 cf_cv_find_linkage_$3=maybe
1085                                 cf_test_CPPFLAGS="$CPPFLAGS"
1086                                 break],[
1087                                 CPPFLAGS="$cf_save_CPPFLAGS"
1088                                 ])
1089                 fi
1090         done
1091
1092         if test "$cf_cv_find_linkage_$3" = maybe ; then
1093
1094                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1095
1096                 cf_save_LIBS="$LIBS"
1097                 cf_save_LDFLAGS="$LDFLAGS"
1098
1099                 ifelse([$6],,,[
1100                 CPPFLAGS="$cf_test_CPPFLAGS"
1101                 LIBS="-l$3 $7 $cf_save_LIBS"
1102                 AC_TRY_LINK([$1],[$2],[
1103                         CF_VERBOSE(... found $3 library in system)
1104                         cf_cv_find_linkage_$3=yes])
1105                         CPPFLAGS="$cf_save_CPPFLAGS"
1106                         LIBS="$cf_save_LIBS"
1107                         ])
1108
1109                 if test "$cf_cv_find_linkage_$3" != yes ; then
1110                         CF_LIBRARY_PATH(cf_search,$3)
1111                         for cf_cv_library_path_$3 in $cf_search
1112                         do
1113                                 if test -d $cf_cv_library_path_$3 ; then
1114                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1115                                         CPPFLAGS="$cf_test_CPPFLAGS"
1116                                         LIBS="-l$3 $7 $cf_save_LIBS"
1117                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1118                                         AC_TRY_LINK([$1],[$2],[
1119                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1120                                         cf_cv_find_linkage_$3=yes
1121                                         cf_cv_library_file_$3="-l$3"
1122                                         break],[
1123                                         CPPFLAGS="$cf_save_CPPFLAGS"
1124                                         LIBS="$cf_save_LIBS"
1125                                         LDFLAGS="$cf_save_LDFLAGS"
1126                                         ])
1127                                 fi
1128                         done
1129                         CPPFLAGS="$cf_save_CPPFLAGS"
1130                         LDFLAGS="$cf_save_LDFLAGS"
1131                 fi
1132
1133         else
1134                 cf_cv_find_linkage_$3=no
1135         fi
1136         ],$7)
1137 ])
1138
1139 LIBS="$cf_save_LIBS"
1140
1141 if test "$cf_cv_find_linkage_$3" = yes ; then
1142 ifelse([$4],,[
1143         CF_ADD_INCDIR($cf_cv_header_path_$3)
1144         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1145         CF_ADD_LIB($3)
1146 ],[$4])
1147 else
1148 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1149 fi
1150 ])dnl
1151 dnl ---------------------------------------------------------------------------
1152 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1153 dnl -----------------
1154 dnl make ADAFLAGS consistent with CFLAGS
1155 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1156         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1157         case "$CFLAGS" in
1158         (*-g*)
1159                 CF_ADD_ADAFLAGS(-g)
1160                 ;;
1161         esac
1162         case "$CFLAGS" in
1163         (*-O*)
1164                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1165                 CF_ADD_ADAFLAGS($cf_O_flag)
1166                 ;;
1167         esac
1168         AC_MSG_RESULT($ADAFLAGS)
1169 ])dnl
1170 dnl ---------------------------------------------------------------------------
1171 dnl CF_GCC_ATTRIBUTES version: 18 updated: 2020/03/10 18:53:47
1172 dnl -----------------
1173 dnl Test for availability of useful gcc __attribute__ directives to quiet
1174 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1175 dnl to documentation, unrecognized directives cause older compilers to barf.
1176 AC_DEFUN([CF_GCC_ATTRIBUTES],
1177 [
1178 if test "$GCC" = yes
1179 then
1180 cat > conftest.i <<EOF
1181 #ifndef GCC_PRINTF
1182 #define GCC_PRINTF 0
1183 #endif
1184 #ifndef GCC_SCANF
1185 #define GCC_SCANF 0
1186 #endif
1187 #ifndef GCC_NORETURN
1188 #define GCC_NORETURN /* nothing */
1189 #endif
1190 #ifndef GCC_UNUSED
1191 #define GCC_UNUSED /* nothing */
1192 #endif
1193 EOF
1194 if test "$GCC" = yes
1195 then
1196         AC_CHECKING([for $CC __attribute__ directives])
1197 cat > conftest.$ac_ext <<EOF
1198 #line __oline__ "${as_me:-configure}"
1199 #include "confdefs.h"
1200 #include "conftest.h"
1201 #include "conftest.i"
1202 #if     GCC_PRINTF
1203 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1204 #else
1205 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1206 #endif
1207 #if     GCC_SCANF
1208 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1209 #else
1210 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1211 #endif
1212 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1213 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1214 extern void foo(void) GCC_NORETURN;
1215 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
1216 EOF
1217         cf_printf_attribute=no
1218         cf_scanf_attribute=no
1219         for cf_attribute in scanf printf unused noreturn
1220         do
1221                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1222                 cf_directive="__attribute__(($cf_attribute))"
1223                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1224
1225                 case $cf_attribute in
1226                 (printf)
1227                         cf_printf_attribute=yes
1228                         cat >conftest.h <<EOF
1229 #define GCC_$cf_ATTRIBUTE 1
1230 EOF
1231                         ;;
1232                 (scanf)
1233                         cf_scanf_attribute=yes
1234                         cat >conftest.h <<EOF
1235 #define GCC_$cf_ATTRIBUTE 1
1236 EOF
1237                         ;;
1238                 (*)
1239                         cat >conftest.h <<EOF
1240 #define GCC_$cf_ATTRIBUTE $cf_directive
1241 EOF
1242                         ;;
1243                 esac
1244
1245                 if AC_TRY_EVAL(ac_compile); then
1246                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1247                         cat conftest.h >>confdefs.h
1248                         case $cf_attribute in
1249                         (noreturn)
1250                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1251                                 ;;
1252                         (printf)
1253                                 cf_value='/* nothing */'
1254                                 if test "$cf_printf_attribute" != no ; then
1255                                         cf_value='__attribute__((format(printf,fmt,var)))'
1256                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1257                                 fi
1258                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1259                                 ;;
1260                         (scanf)
1261                                 cf_value='/* nothing */'
1262                                 if test "$cf_scanf_attribute" != no ; then
1263                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1264                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1265                                 fi
1266                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1267                                 ;;
1268                         (unused)
1269                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1270                                 ;;
1271                         esac
1272                 fi
1273         done
1274 else
1275         fgrep define conftest.i >>confdefs.h
1276 fi
1277 rm -rf conftest*
1278 fi
1279 ])dnl
1280 dnl ---------------------------------------------------------------------------
1281 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
1282 dnl --------------
1283 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
1284 dnl compatible), attempt to determine if icc/clang is actually used.
1285 AC_DEFUN([CF_GCC_VERSION],[
1286 AC_REQUIRE([AC_PROG_CC])
1287 GCC_VERSION=none
1288 if test "$GCC" = yes ; then
1289         AC_MSG_CHECKING(version of $CC)
1290         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1291         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1292         AC_MSG_RESULT($GCC_VERSION)
1293 fi
1294 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1295 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1296 ])dnl
1297 dnl ---------------------------------------------------------------------------
1298 dnl CF_GCC_WARNINGS version: 37 updated: 2020/01/05 20:04:12
1299 dnl ---------------
1300 dnl Check if the compiler supports useful warning options.  There's a few that
1301 dnl we don't use, simply because they're too noisy:
1302 dnl
1303 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1304 dnl     -Winline (usually not worthwhile)
1305 dnl     -Wredundant-decls (system headers make this too noisy)
1306 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1307 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1308 dnl             is enabled for ncurses using "--enable-const".
1309 dnl     -pedantic
1310 dnl
1311 dnl Parameter:
1312 dnl     $1 is an optional list of gcc warning flags that a particular
1313 dnl             application might want to use, e.g., "no-unused" for
1314 dnl             -Wno-unused
1315 dnl Special:
1316 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1317 dnl
1318 AC_DEFUN([CF_GCC_WARNINGS],
1319 [
1320 AC_REQUIRE([CF_GCC_VERSION])
1321 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
1322 cat > conftest.$ac_ext <<EOF
1323 #line __oline__ "${as_me:-configure}"
1324 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1325 EOF
1326 if test "$INTEL_COMPILER" = yes
1327 then
1328 # The "-wdXXX" options suppress warnings:
1329 # remark #1419: external declaration in primary source file
1330 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1331 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1332 # remark #193: zero used for undefined preprocessing identifier
1333 # remark #593: variable "curs_sb_left_arrow" was set but never used
1334 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1335 # remark #869: parameter "tw" was never referenced
1336 # remark #981: operands are evaluated in unspecified order
1337 # warning #279: controlling expression is constant
1338
1339         AC_CHECKING([for $CC warning options])
1340         cf_save_CFLAGS="$CFLAGS"
1341         EXTRA_CFLAGS="-Wall"
1342         for cf_opt in \
1343                 wd1419 \
1344                 wd1683 \
1345                 wd1684 \
1346                 wd193 \
1347                 wd593 \
1348                 wd279 \
1349                 wd810 \
1350                 wd869 \
1351                 wd981
1352         do
1353                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1354                 if AC_TRY_EVAL(ac_compile); then
1355                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1356                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1357                 fi
1358         done
1359         CFLAGS="$cf_save_CFLAGS"
1360 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
1361 then
1362         AC_CHECKING([for $CC warning options])
1363         cf_save_CFLAGS="$CFLAGS"
1364         EXTRA_CFLAGS=
1365         cf_warn_CONST=""
1366         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1367         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1368         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1369         for cf_opt in W Wall \
1370                 Wbad-function-cast \
1371                 Wcast-align \
1372                 Wcast-qual \
1373                 Wdeclaration-after-statement \
1374                 Wextra \
1375                 Winline \
1376                 Wmissing-declarations \
1377                 Wmissing-prototypes \
1378                 Wnested-externs \
1379                 Wpointer-arith \
1380                 Wshadow \
1381                 Wstrict-prototypes \
1382                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
1383         do
1384                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1385                 if AC_TRY_EVAL(ac_compile); then
1386                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1387                         case $cf_opt in
1388                         (Winline)
1389                                 case $GCC_VERSION in
1390                                 ([[34]].*)
1391                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1392                                         continue;;
1393                                 esac
1394                                 ;;
1395                         (Wpointer-arith)
1396                                 case $GCC_VERSION in
1397                                 ([[12]].*)
1398                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1399                                         continue;;
1400                                 esac
1401                                 ;;
1402                         esac
1403                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1404                 fi
1405         done
1406         CFLAGS="$cf_save_CFLAGS"
1407 fi
1408 rm -rf conftest*
1409
1410 AC_SUBST(EXTRA_CFLAGS)
1411 ])dnl
1412 dnl ---------------------------------------------------------------------------
1413 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
1414 dnl -----------------
1415 AC_DEFUN([CF_GNATPREP_OPT_T],[
1416 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
1417 cf_cv_gnatprep_opt_t=no
1418 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
1419 ])
1420 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
1421 AC_SUBST(GNATPREP_OPTS)
1422 ])dnl
1423 dnl ---------------------------------------------------------------------------
1424 dnl CF_GNAT_GENERICS version: 5 updated: 2020/05/31 16:49:35
1425 dnl ----------------
1426 AC_DEFUN([CF_GNAT_GENERICS],
1427 [
1428 AC_REQUIRE([CF_GNAT_VERSION])
1429
1430 AC_MSG_CHECKING(if GNAT supports generics)
1431 case $cf_cv_gnat_version in
1432 (3.[[1-9]]*|[[4-9]].*|[[1-9]][[0-9]].*)
1433         cf_gnat_generics=yes
1434         ;;
1435 (*)
1436         cf_gnat_generics=no
1437         ;;
1438 esac
1439 AC_MSG_RESULT($cf_gnat_generics)
1440
1441 if test "$cf_gnat_generics" = yes
1442 then
1443         cf_compile_generics=generics
1444         cf_generic_objects="\${GENOBJS}"
1445 else
1446         cf_compile_generics=
1447         cf_generic_objects=
1448 fi
1449
1450 AC_SUBST(cf_compile_generics)
1451 AC_SUBST(cf_generic_objects)
1452 ])dnl
1453 dnl ---------------------------------------------------------------------------
1454 dnl CF_GNAT_PROJECTS version: 10 updated: 2019/12/31 08:53:54
1455 dnl ----------------
1456 dnl GNAT projects are configured with ".gpr" project files.
1457 dnl GNAT libraries are a further development, using the project feature.
1458 AC_DEFUN([CF_GNAT_PROJECTS],
1459 [
1460 AC_REQUIRE([CF_GNAT_VERSION])
1461 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
1462
1463 cf_gnat_libraries=no
1464 cf_gnat_projects=no
1465
1466 if test "$enable_gnat_projects" != no ; then
1467 AC_MSG_CHECKING(if GNAT supports project files)
1468 case $cf_cv_gnat_version in
1469 (3.[[0-9]]*)
1470         ;;
1471 (*)
1472         case $cf_cv_system_name in
1473         (cygwin*|msys*)
1474                 ;;
1475         (*)
1476                 rm -rf conftest* *~conftest*
1477                 if mkdir conftest.src conftest.bin conftest.lib
1478                 then
1479                         cd conftest.src
1480                         rm -rf conftest* *~conftest*
1481                         cat >>library.gpr <<CF_EOF
1482 project Library is
1483   Kind := External ("LIB_KIND");
1484   for Library_Name use "ConfTest";
1485   for Object_Dir use ".";
1486   for Library_ALI_Dir use External("LIBRARY_DIR");
1487   for Library_Version use External ("SONAME");
1488   for Library_Kind use Kind;
1489   for Library_Dir use External("BUILD_DIR");
1490   Source_Dir := External ("SOURCE_DIR");
1491   for Source_Dirs use (Source_Dir);
1492 end Library;
1493 CF_EOF
1494                         cat >>confpackage.ads <<CF_EOF
1495 package ConfPackage is
1496    procedure conftest;
1497 end ConfPackage;
1498 CF_EOF
1499                         cat >>confpackage.adb <<CF_EOF
1500 with Text_IO;
1501 package body ConfPackage is
1502    procedure conftest is
1503    begin
1504       Text_IO.Put ("Hello World");
1505       Text_IO.New_Line;
1506    end conftest;
1507 end ConfPackage;
1508 CF_EOF
1509                         if ( $cf_ada_make $ADAFLAGS \
1510                                         -Plibrary.gpr \
1511                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
1512                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
1513                                         -XSOURCE_DIR=`pwd` \
1514                                         -XSONAME=libConfTest.so.1 \
1515                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1516                                 cf_gnat_projects=yes
1517                         fi
1518                         cd ..
1519                 fi
1520                 if test -f conftest.lib/confpackage.ali
1521                 then
1522                         cf_gnat_libraries=yes
1523                 fi
1524                 rm -rf conftest* *~conftest*
1525                 ;;
1526         esac
1527         ;;
1528 esac
1529 AC_MSG_RESULT($cf_gnat_projects)
1530 fi # enable_gnat_projects
1531
1532 if test $cf_gnat_projects = yes
1533 then
1534         AC_MSG_CHECKING(if GNAT supports libraries)
1535         AC_MSG_RESULT($cf_gnat_libraries)
1536 fi
1537
1538 if test "$cf_gnat_projects" = yes
1539 then
1540         USE_OLD_MAKERULES="#"
1541         USE_GNAT_PROJECTS=""
1542 else
1543         USE_OLD_MAKERULES=""
1544         USE_GNAT_PROJECTS="#"
1545 fi
1546
1547 if test "$cf_gnat_libraries" = yes
1548 then
1549         USE_GNAT_LIBRARIES=""
1550 else
1551         USE_GNAT_LIBRARIES="#"
1552 fi
1553
1554 AC_SUBST(USE_OLD_MAKERULES)
1555 AC_SUBST(USE_GNAT_PROJECTS)
1556 AC_SUBST(USE_GNAT_LIBRARIES)
1557 ])dnl
1558 dnl ---------------------------------------------------------------------------
1559 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
1560 dnl --------------
1561 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1562 dnl is noted that gnat may compile a tasking unit even for configurations which
1563 dnl fail at runtime.
1564 AC_DEFUN([CF_GNAT_SIGINT],[
1565 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1566 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1567
1568 package ConfTest is
1569
1570    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1571    pragma Unreserve_All_Interrupts;
1572    pragma Warnings (On);
1573
1574    protected Process is
1575       procedure Stop;
1576       function Continue return Boolean;
1577       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1578    private
1579       Done : Boolean := False;
1580    end Process;
1581
1582 end ConfTest;],
1583 [package body ConfTest is
1584    protected body Process is
1585       procedure Stop is
1586       begin
1587          Done := True;
1588       end Stop;
1589       function Continue return Boolean is
1590       begin
1591          return not Done;
1592       end Continue;
1593    end Process;
1594 end ConfTest;],
1595         [cf_cv_gnat_sigint=yes],
1596         [cf_cv_gnat_sigint=no])])
1597
1598 if test $cf_cv_gnat_sigint = yes ; then
1599         USE_GNAT_SIGINT=""
1600 else
1601         USE_GNAT_SIGINT="#"
1602 fi
1603 AC_SUBST(USE_GNAT_SIGINT)
1604 ])dnl
1605 dnl ---------------------------------------------------------------------------
1606 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
1607 dnl ----------------
1608 dnl Verify that a test program compiles/links with GNAT.
1609 dnl $cf_ada_make is set to the program that compiles/links
1610 dnl $ADAFLAGS may be set to the GNAT flags.
1611 dnl
1612 dnl $1 is the text of the spec
1613 dnl $2 is the text of the body
1614 dnl $3 is the shell command to execute if successful
1615 dnl $4 is the shell command to execute if not successful
1616 AC_DEFUN([CF_GNAT_TRY_LINK],
1617 [
1618 rm -rf conftest* *~conftest*
1619 cat >>conftest.ads <<CF_EOF
1620 $1
1621 CF_EOF
1622 cat >>conftest.adb <<CF_EOF
1623 $2
1624 CF_EOF
1625 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1626 ifelse($3,,      :,[      $3])
1627 ifelse($4,,,[else
1628    $4])
1629 fi
1630 rm -rf conftest* *~conftest*
1631 ])dnl
1632 dnl ---------------------------------------------------------------------------
1633 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
1634 dnl ---------------
1635 dnl Verify that a test program compiles and runs with GNAT
1636 dnl $cf_ada_make is set to the program that compiles/links
1637 dnl $ADAFLAGS may be set to the GNAT flags.
1638 dnl
1639 dnl $1 is the text of the spec
1640 dnl $2 is the text of the body
1641 dnl $3 is the shell command to execute if successful
1642 dnl $4 is the shell command to execute if not successful
1643 AC_DEFUN([CF_GNAT_TRY_RUN],
1644 [
1645 rm -rf conftest* *~conftest*
1646 cat >>conftest.ads <<CF_EOF
1647 $1
1648 CF_EOF
1649 cat >>conftest.adb <<CF_EOF
1650 $2
1651 CF_EOF
1652 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1653    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1654 ifelse($3,,      :,[      $3])
1655 ifelse($4,,,[   else
1656       $4])
1657    fi
1658 ifelse($4,,,[else
1659    $4])
1660 fi
1661 rm -rf conftest* *~conftest*
1662 ])dnl
1663 dnl ---------------------------------------------------------------------------
1664 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
1665 dnl ---------------
1666 dnl $1 = cache variable to update
1667 dnl $2 = program name
1668 dnl Verify version of GNAT or related tool
1669 AC_DEFUN([CF_GNAT_VERSION],
1670 [
1671 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
1672 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
1673         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1674         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1675 ])
1676 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
1677 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
1678 ])dnl
1679 dnl ---------------------------------------------------------------------------
1680 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
1681 dnl -------------
1682 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1683 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1684 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1685 dnl since it is interwoven with GNU extensions.
1686 dnl
1687 dnl Well, yes we could work around it...
1688 dnl
1689 dnl Parameters:
1690 dnl     $1 is the nominal value for _XOPEN_SOURCE
1691 AC_DEFUN([CF_GNU_SOURCE],
1692 [
1693 cf_gnu_xopen_source=ifelse($1,,500,$1)
1694
1695 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
1696 AC_TRY_COMPILE([#include <sys/types.h>],[
1697         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
1698                 return 0;
1699         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
1700                 return 0;
1701         #else
1702         #       error not GNU C library
1703         #endif],
1704         [cf_cv_gnu_library=yes],
1705         [cf_cv_gnu_library=no])
1706 ])
1707
1708 if test x$cf_cv_gnu_library = xyes; then
1709
1710         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
1711         # was changed to help a little.  newlib incorporated the change about 4
1712         # years later.
1713         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
1714                 cf_save="$CPPFLAGS"
1715                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1716                 AC_TRY_COMPILE([#include <sys/types.h>],[
1717                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
1718                                 return 0;
1719                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
1720                                 return 0;
1721                         #else
1722                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
1723                         #endif],
1724                         [cf_cv_gnu_library_219=yes],
1725                         [cf_cv_gnu_library_219=no])
1726                 CPPFLAGS="$cf_save"
1727         ])
1728
1729         if test "x$cf_cv_gnu_library_219" = xyes; then
1730                 cf_save="$CPPFLAGS"
1731                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
1732                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
1733                         AC_TRY_COMPILE([
1734                                 #include <limits.h>
1735                                 #include <sys/types.h>
1736                                 ],[
1737                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
1738                                         return 0;
1739                                 #else
1740                                 #       error GNU C library is too old
1741                                 #endif],
1742                                 [cf_cv_gnu_dftsrc_219=yes],
1743                                 [cf_cv_gnu_dftsrc_219=no])
1744                         ])
1745                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
1746         else
1747                 cf_cv_gnu_dftsrc_219=maybe
1748         fi
1749
1750         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
1751
1752                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1753                 AC_TRY_COMPILE([#include <sys/types.h>],[
1754                         #ifndef _XOPEN_SOURCE
1755                         #error  expected _XOPEN_SOURCE to be defined
1756                         #endif],
1757                         [cf_cv_gnu_source=no],
1758                         [cf_save="$CPPFLAGS"
1759                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
1760                          AC_TRY_COMPILE([#include <sys/types.h>],[
1761                                 #ifdef _XOPEN_SOURCE
1762                                 #error  expected _XOPEN_SOURCE to be undefined
1763                                 #endif],
1764                                 [cf_cv_gnu_source=no],
1765                                 [cf_cv_gnu_source=yes])
1766                         CPPFLAGS="$cf_save"
1767                         ])
1768                 ])
1769
1770                 if test "$cf_cv_gnu_source" = yes
1771                 then
1772                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
1773                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
1774                         AC_TRY_COMPILE([#include <sys/types.h>],[
1775                                 #ifdef _DEFAULT_SOURCE
1776                                 #error  expected _DEFAULT_SOURCE to be undefined
1777                                 #endif],
1778                                 [cf_cv_default_source=no],
1779                                 [cf_cv_default_source=yes])
1780                         ])
1781                         if test "$cf_cv_default_source" = yes
1782                         then
1783                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1784                         fi
1785                 fi
1786         fi
1787
1788 fi
1789 ])dnl
1790 dnl ---------------------------------------------------------------------------
1791 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
1792 dnl --------------
1793 dnl Construct a search-list of directories for a nonstandard header-file
1794 dnl
1795 dnl Parameters
1796 dnl     $1 = the variable to return as result
1797 dnl     $2 = the package name
1798 AC_DEFUN([CF_HEADER_PATH],
1799 [
1800 $1=
1801
1802 # collect the current set of include-directories from compiler flags
1803 cf_header_path_list=""
1804 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1805         for cf_header_path in $CPPFLAGS $CFLAGS
1806         do
1807                 case $cf_header_path in
1808                 (-I*)
1809                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1810                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1811                         cf_header_path_list="$cf_header_path_list [$]$1"
1812                         ;;
1813                 esac
1814         done
1815 fi
1816
1817 # add the variations for the package we are looking for
1818 CF_SUBDIR_PATH($1,$2,include)
1819
1820 test "$includedir" != NONE && \
1821 test "$includedir" != "/usr/include" && \
1822 test -d "$includedir" && {
1823         test -d $includedir &&    $1="[$]$1 $includedir"
1824         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1825 }
1826
1827 test "$oldincludedir" != NONE && \
1828 test "$oldincludedir" != "/usr/include" && \
1829 test -d "$oldincludedir" && {
1830         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1831         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1832 }
1833
1834 $1="[$]$1 $cf_header_path_list"
1835 ])dnl
1836 dnl ---------------------------------------------------------------------------
1837 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
1838 dnl ---------------
1839 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1840 AC_DEFUN([CF_HELP_MESSAGE],
1841 [CF_ACVERSION_CHECK(2.53,[],[
1842 AC_DIVERT_HELP($1)])dnl
1843 ])dnl
1844 dnl ---------------------------------------------------------------------------
1845 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
1846 dnl ---------------
1847 dnl Construct the list of include-options according to whether we're building
1848 dnl in the source directory or using '--srcdir=DIR' option.
1849 AC_DEFUN([CF_INCLUDE_DIRS],
1850 [
1851 if test "$srcdir" != "."; then
1852         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
1853 fi
1854 CPPFLAGS="-I../include $CPPFLAGS"
1855 if test "$srcdir" != "."; then
1856         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
1857 fi
1858 CPPFLAGS="-I. $CPPFLAGS"
1859 AC_SUBST(CPPFLAGS)
1860 ])dnl
1861 dnl ---------------------------------------------------------------------------
1862 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
1863 dnl ---------------
1864 dnl prompt for/fill-in useful install-program options
1865 AC_DEFUN([CF_INSTALL_OPTS],
1866 [
1867 CF_INSTALL_OPT_S
1868 CF_INSTALL_OPT_P
1869 CF_INSTALL_OPT_O
1870 ])dnl
1871 dnl ---------------------------------------------------------------------------
1872 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
1873 dnl ----------------
1874 dnl Almost all "install" programs default to the current user's ownership.
1875 dnl Almost - MINIX is an exception.
1876 AC_DEFUN([CF_INSTALL_OPT_O],
1877 [
1878 AC_MSG_CHECKING(if install needs to be told about ownership)
1879 case `$ac_config_guess` in
1880 (*minix)
1881         with_install_o=yes
1882         ;;
1883 (*)
1884         with_install_o=no
1885         ;;
1886 esac
1887
1888 AC_MSG_RESULT($with_install_o)
1889 if test "x$with_install_o" = xyes
1890 then
1891         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
1892 else
1893         INSTALL_OPT_O=
1894 fi
1895
1896 AC_SUBST(INSTALL_OPT_O)
1897 ])dnl
1898 dnl ---------------------------------------------------------------------------
1899 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
1900 dnl ----------------
1901 dnl Some install-programs accept a "-p" option to preserve file modification
1902 dnl timestamps.  That can be useful as an install option, as well as a way to
1903 dnl avoid the need for ranlib after copying a static archive.
1904 AC_DEFUN([CF_INSTALL_OPT_P],
1905 [
1906 : ${INSTALL:=install}
1907 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
1908         rm -rf conftest*
1909         date >conftest.in
1910         mkdir conftest.out
1911         sleep 3
1912         if $INSTALL -p conftest.in conftest.out 2>/dev/null
1913         then
1914                 if test -f conftest.out/conftest.in
1915                 then
1916                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
1917                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
1918                         if test -s conftest.err
1919                         then
1920                                 cf_cv_install_p=no
1921                         else
1922                                 cf_cv_install_p=yes
1923                         fi
1924                 else
1925                         cf_cv_install_p=no
1926                 fi
1927         else
1928                 cf_cv_install_p=no
1929         fi
1930         rm -rf conftest*
1931 ])
1932 ])dnl
1933 dnl ---------------------------------------------------------------------------
1934 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
1935 dnl ----------------
1936 dnl By default, we should strip executables which are installed, but leave the
1937 dnl ability to suppress that for unit-testing.
1938 AC_DEFUN([CF_INSTALL_OPT_S],
1939 [
1940 AC_MSG_CHECKING(if you want to install stripped executables)
1941 CF_ARG_DISABLE(stripping,
1942         [  --disable-stripping     do not strip (debug info) installed executables],
1943         [with_stripping=no],
1944         [with_stripping=yes])
1945 AC_MSG_RESULT($with_stripping)
1946
1947 if test "$with_stripping" = yes
1948 then
1949         INSTALL_OPT_S="-s"
1950 else
1951         INSTALL_OPT_S=
1952 fi
1953 AC_SUBST(INSTALL_OPT_S)
1954 ])dnl
1955 dnl ---------------------------------------------------------------------------
1956 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
1957 dnl -----------------
1958 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1959 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1960 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1961 dnl
1962 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1963 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1964 dnl the wrappers for gcc and g++ warnings.
1965 dnl
1966 dnl $1 = GCC (default) or GXX
1967 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1968 dnl $3 = CFLAGS (default) or CXXFLAGS
1969 AC_DEFUN([CF_INTEL_COMPILER],[
1970 AC_REQUIRE([AC_CANONICAL_HOST])
1971 ifelse([$2],,INTEL_COMPILER,[$2])=no
1972
1973 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1974         case $host_os in
1975         (linux*|gnu*)
1976                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1977                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1978                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1979                 AC_TRY_COMPILE([],[
1980 #ifdef __INTEL_COMPILER
1981 #else
1982 make an error
1983 #endif
1984 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1985 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
1986 ],[])
1987                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1988                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1989                 ;;
1990         esac
1991 fi
1992 ])dnl
1993 dnl ---------------------------------------------------------------------------
1994 dnl CF_LARGEFILE version: 12 updated: 2020/03/19 20:23:48
1995 dnl ------------
1996 dnl Add checks for large file support.
1997 AC_DEFUN([CF_LARGEFILE],[
1998 ifdef([AC_FUNC_FSEEKO],[
1999         AC_SYS_LARGEFILE
2000         if test "$enable_largefile" != no ; then
2001         AC_FUNC_FSEEKO
2002
2003         # Normally we would collect these definitions in the config.h,
2004         # but (like _XOPEN_SOURCE), some environments rely on having these
2005         # defined before any of the system headers are included.  Another
2006         # case comes up with C++, e.g., on AIX the compiler compiles the
2007         # header files by themselves before looking at the body files it is
2008         # told to compile.  For ncurses, those header files do not include
2009         # the config.h
2010         if test "$ac_cv_sys_large_files" != no
2011         then
2012                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
2013         fi
2014         if test "$ac_cv_sys_largefile_source" != no
2015         then
2016                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
2017         fi
2018         if test "$ac_cv_sys_file_offset_bits" != no
2019         then
2020                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
2021         fi
2022
2023         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2024                 AC_TRY_COMPILE([
2025 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
2026 #include <sys/types.h>
2027 #include <dirent.h>
2028                 ],[
2029                 /* if transitional largefile support is setup, this is true */
2030                 extern struct dirent64 * readdir(DIR *);
2031                 struct dirent64 *x = readdir((DIR *)0);
2032                 struct dirent *y = readdir((DIR *)0);
2033                 int z = x - y;
2034                 (void)z;
2035                 ],
2036                 [cf_cv_struct_dirent64=yes],
2037                 [cf_cv_struct_dirent64=no])
2038         ])
2039         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
2040         fi
2041 ])
2042 ])
2043 dnl ---------------------------------------------------------------------------
2044 dnl CF_LD_RPATH_OPT version: 8 updated: 2018/08/18 16:36:35
2045 dnl ---------------
2046 dnl For the given system and compiler, find the compiler flags to pass to the
2047 dnl loader to use the "rpath" feature.
2048 AC_DEFUN([CF_LD_RPATH_OPT],
2049 [
2050 AC_REQUIRE([CF_CHECK_CACHE])
2051
2052 LD_RPATH_OPT=
2053 if test "x$cf_cv_enable_rpath" != xno
2054 then
2055         AC_MSG_CHECKING(for an rpath option)
2056         case $cf_cv_system_name in
2057         (irix*)
2058                 if test "$GCC" = yes; then
2059                         LD_RPATH_OPT="-Wl,-rpath,"
2060                 else
2061                         LD_RPATH_OPT="-rpath "
2062                 fi
2063                 ;;
2064         (linux*|gnu*|k*bsd*-gnu|freebsd*)
2065                 LD_RPATH_OPT="-Wl,-rpath,"
2066                 ;;
2067         (openbsd[[2-9]].*|mirbsd*)
2068                 LD_RPATH_OPT="-Wl,-rpath,"
2069                 ;;
2070         (dragonfly*)
2071                 LD_RPATH_OPT="-rpath "
2072                 ;;
2073         (netbsd*)
2074                 LD_RPATH_OPT="-Wl,-rpath,"
2075                 ;;
2076         (osf*|mls+*)
2077                 LD_RPATH_OPT="-rpath "
2078                 ;;
2079         (solaris2*)
2080                 LD_RPATH_OPT="-R"
2081                 ;;
2082         (*)
2083                 ;;
2084         esac
2085         AC_MSG_RESULT($LD_RPATH_OPT)
2086
2087         case "x$LD_RPATH_OPT" in
2088         (x-R*)
2089                 AC_MSG_CHECKING(if we need a space after rpath option)
2090                 cf_save_LIBS="$LIBS"
2091                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2092                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2093                 LIBS="$cf_save_LIBS"
2094                 AC_MSG_RESULT($cf_rpath_space)
2095                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2096                 ;;
2097         esac
2098 fi
2099 ])dnl
2100 dnl ---------------------------------------------------------------------------
2101 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
2102 dnl ---------------
2103 dnl Construct a search-list of directories for a nonstandard library-file
2104 dnl
2105 dnl Parameters
2106 dnl     $1 = the variable to return as result
2107 dnl     $2 = the package name
2108 AC_DEFUN([CF_LIBRARY_PATH],
2109 [
2110 $1=
2111 cf_library_path_list=""
2112 if test -n "${LDFLAGS}${LIBS}" ; then
2113         for cf_library_path in $LDFLAGS $LIBS
2114         do
2115                 case $cf_library_path in
2116                 (-L*)
2117                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2118                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2119                         cf_library_path_list="$cf_library_path_list [$]$1"
2120                         ;;
2121                 esac
2122         done
2123 fi
2124
2125 CF_SUBDIR_PATH($1,$2,lib)
2126
2127 $1="$cf_library_path_list [$]$1"
2128 ])dnl
2129 dnl ---------------------------------------------------------------------------
2130 dnl CF_LIB_PREFIX version: 13 updated: 2020/04/04 10:11:47
2131 dnl -------------
2132 dnl Compute the library-prefix for the given host system
2133 dnl $1 = variable to set
2134 define([CF_LIB_PREFIX],
2135 [
2136         case $cf_cv_system_name in
2137         (OS/2*|os2*)
2138                 if test "$DFT_LWR_MODEL" = libtool; then
2139                         LIB_PREFIX='lib'
2140                 else
2141                         LIB_PREFIX=''
2142                 fi
2143                 ;;
2144         (*-msvc*)
2145                 LIB_PREFIX=''
2146                 ;;
2147         (*)     LIB_PREFIX='lib'
2148                 ;;
2149         esac
2150 ifelse($1,,,[$1=$LIB_PREFIX])
2151         AC_SUBST(LIB_PREFIX)
2152 ])dnl
2153 dnl ---------------------------------------------------------------------------
2154 dnl CF_LIB_SUFFIX version: 26 updated: 2020/04/04 10:11:47
2155 dnl -------------
2156 dnl Compute the library file-suffix from the given model name
2157 dnl $1 = model name
2158 dnl $2 = variable to set (the nominal library suffix)
2159 dnl $3 = dependency variable to set (actual filename)
2160 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
2161 AC_DEFUN([CF_LIB_SUFFIX],
2162 [
2163         case X$1 in
2164         (Xlibtool)
2165                 $2='.la'
2166                 $3=[$]$2
2167                 ;;
2168         (Xdebug)
2169                 case $cf_cv_system_name in
2170                 (*-msvc*)
2171                         $2='_g.lib'
2172                         ;;
2173                 (*)
2174                         $2='_g.a'
2175                         ;;
2176                 esac
2177                 $3=[$]$2
2178                 ;;
2179         (Xprofile)
2180                 case $cf_cv_system_name in
2181                 (*-msvc*)
2182                         $2='_p.lib'
2183                         ;;
2184                 (*)
2185                         $2='_p.a'
2186                         ;;
2187                 esac
2188                 $3=[$]$2
2189                 ;;
2190         (Xshared)
2191                 case $cf_cv_system_name in
2192                 (aix[[5-7]]*)
2193                         $2='.so'
2194                         $3=[$]$2
2195                         ;;
2196                 (*-msvc*)
2197                         $2='.dll'
2198                         $3='.dll.lib'
2199                         ;;
2200                 (cygwin*|msys*|mingw*)
2201                         $2='.dll'
2202                         $3='.dll.a'
2203                         ;;
2204                 (darwin*)
2205                         $2='.dylib'
2206                         $3=[$]$2
2207                         ;;
2208                 (hpux*)
2209                         case $target in
2210                         (ia64*)
2211                                 $2='.so'
2212                                 $3=[$]$2
2213                                 ;;
2214                         (*)
2215                                 $2='.sl'
2216                                 $3=[$]$2
2217                                 ;;
2218                         esac
2219                         ;;
2220                 (*)
2221                         $2='.so'
2222                         $3=[$]$2
2223                         ;;
2224                 esac
2225                 ;;
2226         (*)
2227                 case $target in
2228                 (*-msvc*)
2229                         $2='.lib'
2230                         ;;
2231                 (*)
2232                         $2='.a'
2233                         ;;
2234                 esac
2235                 $3=[$]$2
2236                 ;;
2237         esac
2238         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
2239         then
2240                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
2241                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
2242         fi
2243 ])dnl
2244 dnl ---------------------------------------------------------------------------
2245 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
2246 dnl -----------
2247 dnl Compute the string to append to -library from the given model name
2248 dnl $1 = model name
2249 dnl $2 = variable to set
2250 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
2251 AC_DEFUN([CF_LIB_TYPE],
2252 [
2253         case $1 in
2254         (libtool) $2=''   ;;
2255         (normal)  $2=''   ;;
2256         (debug)   $2='_g' ;;
2257         (profile) $2='_p' ;;
2258         (shared)  $2=''   ;;
2259         esac
2260         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
2261 ])dnl
2262 dnl ---------------------------------------------------------------------------
2263 dnl CF_LINK_DATAONLY version: 13 updated: 2020/02/08 15:59:30
2264 dnl ----------------
2265 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
2266 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
2267 dnl have to provide wrappers for global tables to ensure they're linked
2268 dnl properly.
2269 AC_DEFUN([CF_LINK_DATAONLY],
2270 [
2271 AC_MSG_CHECKING([if data-only library module links])
2272 AC_CACHE_VAL(cf_cv_link_dataonly,[
2273         rm -f conftest.a
2274         cat >conftest.$ac_ext <<EOF
2275 #line __oline__ "configure"
2276 int     testdata[[3]] = { 123, 456, 789 };
2277 EOF
2278         if AC_TRY_EVAL(ac_compile) ; then
2279                 mv conftest.o data.o && \
2280                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
2281         fi
2282         rm -f conftest.$ac_ext data.o
2283         cat >conftest.$ac_ext <<EOF
2284 #line __oline__ "configure"
2285 int     testfunc(void)
2286 {
2287 #if defined(NeXT)
2288         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
2289 #else
2290         extern int testdata[[3]];
2291         return testdata[[0]] == 123
2292            &&  testdata[[1]] == 456
2293            &&  testdata[[2]] == 789;
2294 #endif
2295 }
2296 EOF
2297         if AC_TRY_EVAL(ac_compile); then
2298                 mv conftest.o func.o && \
2299                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
2300         fi
2301         rm -f conftest.$ac_ext func.o
2302         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
2303         cf_saveLIBS="$LIBS"
2304         LIBS="conftest.a $LIBS"
2305         AC_TRY_RUN([
2306         int main(void)
2307         {
2308                 extern int testfunc();
2309                 ${cf_cv_main_return:-return} (!testfunc());
2310         }
2311         ],
2312         [cf_cv_link_dataonly=yes],
2313         [cf_cv_link_dataonly=no],
2314         [cf_cv_link_dataonly=unknown])
2315         LIBS="$cf_saveLIBS"
2316         ])
2317 AC_MSG_RESULT($cf_cv_link_dataonly)
2318
2319 if test "$cf_cv_link_dataonly" = no ; then
2320         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
2321         BROKEN_LINKER=1
2322 fi
2323 AC_SUBST(BROKEN_LINKER)
2324
2325 ])dnl
2326 dnl ---------------------------------------------------------------------------
2327 dnl CF_MAKEFLAGS version: 18 updated: 2018/02/21 21:26:03
2328 dnl ------------
2329 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
2330 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
2331 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
2332 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
2333 AC_DEFUN([CF_MAKEFLAGS],
2334 [
2335 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
2336         cf_cv_makeflags=''
2337         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
2338         do
2339                 cat >cf_makeflags.tmp <<CF_EOF
2340 SHELL = $SHELL
2341 all :
2342         @ echo '.$cf_option'
2343 CF_EOF
2344                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
2345                 case "$cf_result" in
2346                 (.*k|.*kw)
2347                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
2348                         case "$cf_result" in
2349                         (.*CC=*)        cf_cv_makeflags=
2350                                 ;;
2351                         (*)     cf_cv_makeflags=$cf_option
2352                                 ;;
2353                         esac
2354                         break
2355                         ;;
2356                 (.-)
2357                         ;;
2358                 (*)
2359                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
2360                         ;;
2361                 esac
2362         done
2363         rm -f cf_makeflags.tmp
2364 ])
2365
2366 AC_SUBST(cf_cv_makeflags)
2367 ])dnl
2368 dnl ---------------------------------------------------------------------------
2369 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
2370 dnl ------------
2371 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
2372 dnl a monocase filesystem.
2373 AC_DEFUN([CF_MAKE_TAGS],[
2374 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
2375
2376 AC_CHECK_PROGS(CTAGS, exctags ctags)
2377 AC_CHECK_PROGS(ETAGS, exetags etags)
2378
2379 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
2380
2381 if test "$cf_cv_mixedcase" = yes ; then
2382         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
2383 else
2384         MAKE_UPPER_TAGS=no
2385 fi
2386
2387 if test "$MAKE_UPPER_TAGS" = yes ; then
2388         MAKE_UPPER_TAGS=
2389 else
2390         MAKE_UPPER_TAGS="#"
2391 fi
2392
2393 if test "$MAKE_LOWER_TAGS" = yes ; then
2394         MAKE_LOWER_TAGS=
2395 else
2396         MAKE_LOWER_TAGS="#"
2397 fi
2398
2399 AC_SUBST(CTAGS)
2400 AC_SUBST(ETAGS)
2401
2402 AC_SUBST(MAKE_UPPER_TAGS)
2403 AC_SUBST(MAKE_LOWER_TAGS)
2404 ])dnl
2405 dnl ---------------------------------------------------------------------------
2406 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
2407 dnl ----------------------
2408 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2409 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2410 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2411 [
2412 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2413 if test "$cross_compiling" = yes ; then
2414         case $target_alias in
2415         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
2416                 cf_cv_mixedcase=no
2417                 ;;
2418         (*)
2419                 cf_cv_mixedcase=yes
2420                 ;;
2421         esac
2422 else
2423         rm -f conftest CONFTEST
2424         echo test >conftest
2425         if test -f CONFTEST ; then
2426                 cf_cv_mixedcase=no
2427         else
2428                 cf_cv_mixedcase=yes
2429         fi
2430         rm -f conftest CONFTEST
2431 fi
2432 ])
2433 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2434 ])dnl
2435 dnl ---------------------------------------------------------------------------
2436 dnl CF_MKSTEMP version: 10 updated: 2017/01/21 11:12:16
2437 dnl ----------
2438 dnl Check for a working mkstemp.  This creates two files, checks that they are
2439 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2440 AC_DEFUN([CF_MKSTEMP],[
2441 AC_CHECK_HEADERS( \
2442 unistd.h \
2443 )
2444 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2445 rm -rf conftest*
2446 AC_TRY_RUN([
2447 #include <sys/types.h>
2448 #ifdef HAVE_UNISTD_H
2449 #include <unistd.h>
2450 #endif
2451 #include <stdlib.h>
2452 #include <stdio.h>
2453 #include <string.h>
2454 #include <sys/stat.h>
2455 int main(void)
2456 {
2457         char *tmpl = "conftestXXXXXX";
2458         char name[2][80];
2459         int n;
2460         int result = 0;
2461         int fd;
2462         struct stat sb;
2463
2464         umask(077);
2465         for (n = 0; n < 2; ++n) {
2466                 strcpy(name[n], tmpl);
2467                 if ((fd = mkstemp(name[n])) >= 0) {
2468                         if (!strcmp(name[n], tmpl)
2469                          || stat(name[n], &sb) != 0
2470                          || (sb.st_mode & S_IFMT) != S_IFREG
2471                          || (sb.st_mode & 077) != 0) {
2472                                 result = 1;
2473                         }
2474                         close(fd);
2475                 }
2476         }
2477         if (result == 0
2478          && !strcmp(name[0], name[1]))
2479                 result = 1;
2480         ${cf_cv_main_return:-return}(result);
2481 }
2482 ],[cf_cv_func_mkstemp=yes
2483 ],[cf_cv_func_mkstemp=no
2484 ],[cf_cv_func_mkstemp=maybe])
2485 ])
2486 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2487         AC_CHECK_FUNC(mkstemp)
2488 fi
2489 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2490         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2491 fi
2492 ])dnl
2493 dnl ---------------------------------------------------------------------------
2494 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2495 dnl ----------
2496 dnl Write a debug message to config.log, along with the line number in the
2497 dnl configure script.
2498 AC_DEFUN([CF_MSG_LOG],[
2499 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2500 ])dnl
2501 dnl ---------------------------------------------------------------------------
2502 dnl CF_NCURSES_ADDON version: 5 updated: 2015/04/26 18:06:58
2503 dnl ----------------
2504 dnl Configure an ncurses add-on, built outside the ncurses tree.
2505 AC_DEFUN([CF_NCURSES_ADDON],[
2506 AC_REQUIRE([CF_NCURSES_CONFIG])
2507
2508 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2509
2510 AC_MSG_CHECKING(if you want wide-character code)
2511 AC_ARG_ENABLE(widec,
2512         [  --enable-widec          compile with wide-char/UTF-8 code],
2513         [with_widec=$enableval],
2514         [with_widec=no])
2515 AC_MSG_RESULT($with_widec)
2516 if test "$with_widec" = yes ; then
2517         CF_UTF8_LIB
2518         CF_NCURSES_CONFIG(ncursesw)
2519 else
2520         CF_NCURSES_CONFIG(ncurses)
2521 fi
2522
2523 if test "$NCURSES_CONFIG_PKG" != none ; then
2524         cf_version=`$PKG_CONFIG --modversion $NCURSES_CONFIG_PKG 2>/dev/null`
2525
2526         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2527         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2528         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2529
2530         cf_cv_abi_version=`$PKG_CONFIG --variable=abi_version $NCURSES_CONFIG_PKG 2>/dev/null`
2531         if test -z "$cf_cv_abi_version"
2532         then
2533                 cf_cv_abi_version=`$PKG_CONFIG --variable=major_version $NCURSES_CONFIG_PKG 2>/dev/null`
2534         fi
2535
2536 elif test "$NCURSES_CONFIG" != none ; then
2537
2538         cf_version=`$NCURSES_CONFIG --version 2>/dev/null`
2539
2540         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2541         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2542         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2543
2544         # ABI version is not available from headers
2545         cf_cv_abi_version=`$NCURSES_CONFIG --abi-version 2>/dev/null`
2546
2547 else
2548
2549         for cf_name in MAJOR MINOR PATCH
2550         do
2551         cat >conftest.$ac_ext <<CF_EOF
2552         #include <${cf_cv_ncurses_header:-curses.h}>
2553         AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2554 CF_EOF
2555                 cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2556                 AC_TRY_EVAL(cf_try)
2557                 if test -f conftest.out ; then
2558                         cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]][[    ]]*//"`
2559                         eval NCURSES_$cf_name=\"$cf_result\"
2560                         # cat conftest.$ac_ext
2561                         # cat conftest.out
2562                 fi
2563         done
2564
2565         cf_cv_abi_version=${NCURSES_MAJOR}
2566
2567 fi
2568
2569 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2570
2571 dnl Show the computed version, for logging
2572 cf_cv_timestamp=`date`
2573
2574 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2575
2576 dnl We need these values in the generated headers
2577 AC_SUBST(NCURSES_MAJOR)
2578 AC_SUBST(NCURSES_MINOR)
2579 AC_SUBST(NCURSES_PATCH)
2580
2581 dnl We need these values in the generated makefiles
2582 AC_SUBST(cf_cv_rel_version)
2583 AC_SUBST(cf_cv_abi_version)
2584
2585 dnl FIXME - not needed for Ada95
2586 AC_SUBST(cf_cv_builtin_bool)
2587 AC_SUBST(cf_cv_header_stdbool_h)
2588 AC_SUBST(cf_cv_type_of_bool)dnl
2589
2590 ])
2591 dnl ---------------------------------------------------------------------------
2592 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2593 dnl -------------------
2594 dnl Check if we can compile with ncurses' header file
2595 dnl $1 is the cache variable to set
2596 dnl $2 is the header-file to include
2597 dnl $3 is the root name (ncurses or ncursesw)
2598 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2599         AC_TRY_COMPILE([
2600 ]ifelse($3,ncursesw,[
2601 #define _XOPEN_SOURCE_EXTENDED
2602 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2603 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2604 ])[
2605 #include <$2>],[
2606 #ifdef NCURSES_VERSION
2607 ]ifelse($3,ncursesw,[
2608 #ifndef WACS_BSSB
2609         make an error
2610 #endif
2611 ])[
2612 printf("%s\n", NCURSES_VERSION);
2613 #else
2614 #ifdef __NCURSES_H
2615 printf("old\n");
2616 #else
2617         make an error
2618 #endif
2619 #endif
2620         ]
2621         ,[$1=$2]
2622         ,[$1=no])
2623 ])dnl
2624 dnl ---------------------------------------------------------------------------
2625 dnl CF_NCURSES_CONFIG version: 23 updated: 2020/02/27 05:21:59
2626 dnl -----------------
2627 dnl Tie together the configure-script macros for ncurses, preferring these in
2628 dnl order:
2629 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2630 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2631 dnl c) just plain libraries
2632 dnl
2633 dnl $1 is the root library name (default: "ncurses")
2634 AC_DEFUN([CF_NCURSES_CONFIG],[
2635 AC_REQUIRE([CF_PKG_CONFIG])
2636 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2637 cf_have_ncuconfig=no
2638
2639 if test "x${PKG_CONFIG:=none}" != xnone; then
2640         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2641         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2642                 AC_MSG_RESULT(yes)
2643
2644                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2645                 cf_have_ncuconfig=unknown
2646
2647                 cf_save_CFLAGS="$CFLAGS"
2648                 cf_save_CPPFLAGS="$CPPFLAGS"
2649                 cf_save_LIBS="$LIBS"
2650
2651                 cf_pkg_cflags=`$PKG_CONFIG --cflags $cf_ncuconfig_root`
2652                 cf_pkg_libs=`$PKG_CONFIG --libs $cf_ncuconfig_root`
2653
2654                 # while -W for passing linker flags is prevalent, it is not "standard".
2655                 # At least one wrapper for c89/c99 (in Apple's xcode) has its own
2656                 # incompatible _and_ non-standard -W option which gives an error.  Work
2657                 # around that pitfall.
2658                 case "x${CC}@@${cf_pkg_libs}@${cf_pkg_cflags}" in
2659                 (x*c[[89]]9@@*-W*)
2660                         CF_ADD_CFLAGS($cf_pkg_cflags)
2661                         CF_ADD_LIBS($cf_pkg_libs)
2662
2663                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2664                                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2665                                 [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2666                                         int main(void)
2667                                         { char *xx = curses_version(); return (xx == 0); }],
2668                                         [cf_test_ncuconfig=yes],
2669                                         [cf_test_ncuconfig=no],
2670                                         [cf_test_ncuconfig=maybe])],
2671                                 [cf_test_ncuconfig=no])
2672
2673                         CFLAGS="$cf_save_CFLAGS"
2674                         CPPFLAGS="$cf_save_CPPFLAGS"
2675                         LIBS="$cf_save_LIBS"
2676
2677                         if test "x$cf_test_ncuconfig" != xyes; then
2678                                 cf_temp=`echo "x$cf_pkg_cflags" | sed -e s/^x// -e 's/-W[[^     ]]*//g'`
2679                                 cf_pkg_cflags="$cf_temp"
2680                                 cf_temp=`echo "x$cf_pkg_libs" | sed -e s/^x// -e 's/-W[[^       ]]*//g'`
2681                                 cf_pkg_libs="$cf_temp"
2682                         fi
2683                         ;;
2684                 esac
2685
2686                 CF_ADD_CFLAGS($cf_pkg_cflags)
2687                 CF_ADD_LIBS($cf_pkg_libs)
2688
2689                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2690                         [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2691                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2692                                 int main(void)
2693                                 { char *xx = curses_version(); return (xx == 0); }],
2694                                 [cf_have_ncuconfig=yes],
2695                                 [cf_have_ncuconfig=no],
2696                                 [cf_have_ncuconfig=maybe])],
2697                         [cf_have_ncuconfig=no])
2698                 AC_MSG_RESULT($cf_have_ncuconfig)
2699                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2700                 if test "$cf_have_ncuconfig" != "yes"
2701                 then
2702                         CPPFLAGS="$cf_save_CPPFLAGS"
2703                         LIBS="$cf_save_LIBS"
2704                         NCURSES_CONFIG_PKG=none
2705                 else
2706                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2707                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2708                         CF_TERM_HEADER
2709                 fi
2710
2711         else
2712                 AC_MSG_RESULT(no)
2713                 NCURSES_CONFIG_PKG=none
2714         fi
2715 else
2716         NCURSES_CONFIG_PKG=none
2717 fi
2718
2719 if test "x$cf_have_ncuconfig" = "xno"; then
2720         cf_ncurses_config="${cf_ncuconfig_root}${NCURSES_CONFIG_SUFFIX}-config"; echo "Looking for ${cf_ncurses_config}"
2721
2722         CF_ACVERSION_CHECK(2.52,
2723                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2724                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2725
2726         if test "$NCURSES_CONFIG" != none ; then
2727
2728                 CF_ADD_CFLAGS(`$NCURSES_CONFIG --cflags`)
2729                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2730
2731                 # even with config script, some packages use no-override for curses.h
2732                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2733
2734                 dnl like CF_NCURSES_CPPFLAGS
2735                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2736
2737                 dnl like CF_NCURSES_LIBS
2738                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2739                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2740
2741                 dnl like CF_NCURSES_VERSION
2742                 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2743
2744         else
2745
2746                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2747                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2748
2749         fi
2750 else
2751         NCURSES_CONFIG=none
2752 fi
2753 ])dnl
2754 dnl ---------------------------------------------------------------------------
2755 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2756 dnl -------------------
2757 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2758 dnl the CPPFLAGS variable so we can include its header.
2759 dnl
2760 dnl The header files may be installed as either curses.h, or ncurses.h (would
2761 dnl be obsolete, except that some packagers prefer this name to distinguish it
2762 dnl from a "native" curses implementation).  If not installed for overwrite,
2763 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2764 dnl /usr/include/ncurses), but someone may have installed overwriting the
2765 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2766 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2767 dnl the header.
2768 dnl
2769 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2770 dnl is already in the include-path, don't even bother with this, since we cannot
2771 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2772 dnl
2773 dnl The optional parameter gives the root name of the library, in case it is
2774 dnl not installed as the default curses library.  That is how the
2775 dnl wide-character version of ncurses is installed.
2776 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2777 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2778
2779 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2780 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2781
2782 test -n "$cf_cv_curses_dir" && \
2783 test "$cf_cv_curses_dir" != "no" && { \
2784   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2785 }
2786
2787 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2788         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2789         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2790         for cf_header in $cf_header_list
2791         do
2792                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2793                 test "$cf_cv_ncurses_h" != no && break
2794         done
2795 ])
2796
2797 CF_NCURSES_HEADER
2798 CF_TERM_HEADER
2799
2800 # some applications need this, but should check for NCURSES_VERSION
2801 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2802
2803 CF_NCURSES_VERSION
2804 ])dnl
2805 dnl ---------------------------------------------------------------------------
2806 dnl CF_NCURSES_HEADER version: 4 updated: 2015/04/15 19:08:48
2807 dnl -----------------
2808 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2809 dnl variations of ncurses' installs.
2810 dnl
2811 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2812 AC_DEFUN([CF_NCURSES_HEADER],[
2813
2814 if test "$cf_cv_ncurses_h" != no ; then
2815         cf_cv_ncurses_header=$cf_cv_ncurses_h
2816 else
2817
2818 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2819         test -n "$verbose" && echo
2820         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2821         test -n "$verbose" && echo search path $cf_search
2822         cf_save2_CPPFLAGS="$CPPFLAGS"
2823         for cf_incdir in $cf_search
2824         do
2825                 CF_ADD_INCDIR($cf_incdir)
2826                 for cf_header in \
2827                         ncurses.h \
2828                         curses.h
2829                 do
2830                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2831                         if test "$cf_cv_ncurses_h2" != no ; then
2832                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2833                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2834                                 break
2835                         fi
2836                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2837                 done
2838                 CPPFLAGS="$cf_save2_CPPFLAGS"
2839                 test "$cf_cv_ncurses_h2" != no && break
2840         done
2841         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2842         ])
2843
2844         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2845         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2846         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2847                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2848         fi
2849         CF_ADD_INCDIR($cf_1st_incdir)
2850
2851 fi
2852
2853 # Set definitions to allow ifdef'ing for ncurses.h
2854
2855 case $cf_cv_ncurses_header in
2856 (*ncurses.h)
2857         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2858         ;;
2859 esac
2860
2861 case $cf_cv_ncurses_header in
2862 (ncurses/curses.h|ncurses/ncurses.h)
2863         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2864         ;;
2865 (ncursesw/curses.h|ncursesw/ncurses.h)
2866         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2867         ;;
2868 esac
2869
2870 ])dnl
2871 dnl ---------------------------------------------------------------------------
2872 dnl CF_NCURSES_LIBS version: 17 updated: 2015/04/15 19:08:48
2873 dnl ---------------
2874 dnl Look for the ncurses library.  This is a little complicated on Linux,
2875 dnl because it may be linked with the gpm (general purpose mouse) library.
2876 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2877 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2878 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2879 dnl and the linker will record a dependency.
2880 dnl
2881 dnl The optional parameter gives the root name of the library, in case it is
2882 dnl not installed as the default curses library.  That is how the
2883 dnl wide-character version of ncurses is installed.
2884 AC_DEFUN([CF_NCURSES_LIBS],
2885 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2886
2887 cf_nculib_root=ifelse($1,,ncurses,$1)
2888         # This works, except for the special case where we find gpm, but
2889         # ncurses is in a nonstandard location via $LIBS, and we really want
2890         # to link gpm.
2891 cf_ncurses_LIBS=""
2892 cf_ncurses_SAVE="$LIBS"
2893 AC_CHECK_LIB(gpm,Gpm_Open,
2894         [AC_CHECK_LIB(gpm,initscr,
2895                 [LIBS="$cf_ncurses_SAVE"],
2896                 [cf_ncurses_LIBS="-lgpm"])])
2897
2898 case $host_os in
2899 (freebsd*)
2900         # This is only necessary if you are linking against an obsolete
2901         # version of ncurses (but it should do no harm, since it's static).
2902         if test "$cf_nculib_root" = ncurses ; then
2903                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2904         fi
2905         ;;
2906 esac
2907
2908 CF_ADD_LIBS($cf_ncurses_LIBS)
2909
2910 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2911 then
2912         CF_ADD_LIBS(-l$cf_nculib_root)
2913 else
2914         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2915                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2916                 [initscr()],
2917                 initscr)
2918 fi
2919
2920 if test -n "$cf_ncurses_LIBS" ; then
2921         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2922         cf_ncurses_SAVE="$LIBS"
2923         for p in $cf_ncurses_LIBS ; do
2924                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2925                 if test "$q" != "$LIBS" ; then
2926                         LIBS="$q"
2927                 fi
2928         done
2929         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2930                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2931                 [AC_MSG_RESULT(yes)],
2932                 [AC_MSG_RESULT(no)
2933                  LIBS="$cf_ncurses_SAVE"])
2934 fi
2935
2936 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2937 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2938 ])dnl
2939 dnl ---------------------------------------------------------------------------
2940 dnl CF_NCURSES_VERSION version: 15 updated: 2017/05/09 19:26:10
2941 dnl ------------------
2942 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2943 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2944 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2945 AC_DEFUN([CF_NCURSES_VERSION],
2946 [
2947 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2948 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2949         cf_cv_ncurses_version=no
2950         cf_tempfile=out$$
2951         rm -f $cf_tempfile
2952         AC_TRY_RUN([
2953 #include <${cf_cv_ncurses_header:-curses.h}>
2954 #include <stdio.h>
2955 int main(void)
2956 {
2957         FILE *fp = fopen("$cf_tempfile", "w");
2958 #ifdef NCURSES_VERSION
2959 # ifdef NCURSES_VERSION_PATCH
2960         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2961 # else
2962         fprintf(fp, "%s\n", NCURSES_VERSION);
2963 # endif
2964 #else
2965 # ifdef __NCURSES_H
2966         fprintf(fp, "old\n");
2967 # else
2968         make an error
2969 # endif
2970 #endif
2971         ${cf_cv_main_return:-return}(0);
2972 }],[
2973         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2974
2975         # This will not work if the preprocessor splits the line after the
2976         # Autoconf token.  The 'unproto' program does that.
2977         cat > conftest.$ac_ext <<EOF
2978 #include <${cf_cv_ncurses_header:-curses.h}>
2979 #undef Autoconf
2980 #ifdef NCURSES_VERSION
2981 Autoconf NCURSES_VERSION
2982 #else
2983 #ifdef __NCURSES_H
2984 Autoconf "old"
2985 #endif
2986 ;
2987 #endif
2988 EOF
2989         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2990         AC_TRY_EVAL(cf_try)
2991         if test -f conftest.out ; then
2992                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2993                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2994                 rm -f conftest.out
2995         fi
2996 ])
2997         rm -f $cf_tempfile
2998 ])
2999 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
3000 ])dnl
3001 dnl ---------------------------------------------------------------------------
3002 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
3003 dnl -------------
3004 dnl Compute the object-directory name from the given model name
3005 AC_DEFUN([CF_OBJ_SUBDIR],
3006 [
3007         case $1 in
3008         (libtool) $2='obj_lo'  ;;
3009         (normal)  $2='objects' ;;
3010         (debug)   $2='obj_g' ;;
3011         (profile) $2='obj_p' ;;
3012         (shared)
3013                 case $cf_cv_system_name in
3014                 (cygwin|msys)
3015                         $2='objects' ;;
3016                 (*)
3017                         $2='obj_s' ;;
3018                 esac
3019         esac
3020 ])dnl
3021 dnl ---------------------------------------------------------------------------
3022 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
3023 dnl ----------
3024 dnl Provide a value for the $PATH and similar separator (or amend the value
3025 dnl as provided in autoconf 2.5x).
3026 AC_DEFUN([CF_PATHSEP],
3027 [
3028         AC_MSG_CHECKING(for PATH separator)
3029         case $cf_cv_system_name in
3030         (os2*)  PATH_SEPARATOR=';'  ;;
3031         (*)     ${PATH_SEPARATOR:=':'}  ;;
3032         esac
3033 ifelse([$1],,,[$1=$PATH_SEPARATOR])
3034         AC_SUBST(PATH_SEPARATOR)
3035         AC_MSG_RESULT($PATH_SEPARATOR)
3036 ])dnl
3037 dnl ---------------------------------------------------------------------------
3038 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
3039 dnl --------------
3040 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
3041 dnl begins with one of the prefix/exec_prefix variables, and then again if the
3042 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
3043 dnl delayed evaluation of those symbols.
3044 AC_DEFUN([CF_PATH_SYNTAX],[
3045 if test "x$prefix" != xNONE; then
3046         cf_path_syntax="$prefix"
3047 else
3048         cf_path_syntax="$ac_default_prefix"
3049 fi
3050
3051 case ".[$]$1" in
3052 (.\[$]\(*\)*|.\'*\'*)
3053         ;;
3054 (..|./*|.\\*)
3055         ;;
3056 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
3057         ;;
3058 (.\[$]{*prefix}*|.\[$]{*dir}*)
3059         eval $1="[$]$1"
3060         case ".[$]$1" in
3061         (.NONE/*)
3062                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
3063                 ;;
3064         esac
3065         ;;
3066 (.no|.NONE/*)
3067         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
3068         ;;
3069 (*)
3070         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
3071         ;;
3072 esac
3073 ])dnl
3074 dnl ---------------------------------------------------------------------------
3075 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
3076 dnl -------------
3077 dnl Check for the package-config program, unless disabled by command-line.
3078 AC_DEFUN([CF_PKG_CONFIG],
3079 [
3080 AC_MSG_CHECKING(if you want to use pkg-config)
3081 AC_ARG_WITH(pkg-config,
3082         [  --with-pkg-config{=path} enable/disable use of pkg-config],
3083         [cf_pkg_config=$withval],
3084         [cf_pkg_config=yes])
3085 AC_MSG_RESULT($cf_pkg_config)
3086
3087 case $cf_pkg_config in
3088 (no)
3089         PKG_CONFIG=none
3090         ;;
3091 (yes)
3092         CF_ACVERSION_CHECK(2.52,
3093                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
3094                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
3095         ;;
3096 (*)
3097         PKG_CONFIG=$withval
3098         ;;
3099 esac
3100
3101 test -z "$PKG_CONFIG" && PKG_CONFIG=none
3102 if test "$PKG_CONFIG" != none ; then
3103         CF_PATH_SYNTAX(PKG_CONFIG)
3104 elif test "x$cf_pkg_config" != xno ; then
3105         AC_MSG_WARN(pkg-config is not installed)
3106 fi
3107
3108 AC_SUBST(PKG_CONFIG)
3109 ])dnl
3110 dnl ---------------------------------------------------------------------------
3111 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
3112 dnl -----------------
3113 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
3114 dnl
3115 dnl     POSIX.1-1990                            _POSIX_SOURCE
3116 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
3117 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
3118 dnl             Bindings Option
3119 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
3120 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
3121 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
3122 dnl
3123 dnl Parameters:
3124 dnl     $1 is the nominal value for _POSIX_C_SOURCE
3125 AC_DEFUN([CF_POSIX_C_SOURCE],
3126 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
3127
3128 if test "$cf_cv_posix_visible" = no; then
3129
3130 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
3131
3132 cf_save_CFLAGS="$CFLAGS"
3133 cf_save_CPPFLAGS="$CPPFLAGS"
3134
3135 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
3136 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
3137
3138 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
3139         CF_MSG_LOG(if the symbol is already defined go no further)
3140         AC_TRY_COMPILE([#include <sys/types.h>],[
3141 #ifndef _POSIX_C_SOURCE
3142 make an error
3143 #endif],
3144         [cf_cv_posix_c_source=no],
3145         [cf_want_posix_source=no
3146          case .$cf_POSIX_C_SOURCE in
3147          (.[[12]]??*)
3148                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3149                 ;;
3150          (.2)
3151                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3152                 cf_want_posix_source=yes
3153                 ;;
3154          (.*)
3155                 cf_want_posix_source=yes
3156                 ;;
3157          esac
3158          if test "$cf_want_posix_source" = yes ; then
3159                 AC_TRY_COMPILE([#include <sys/types.h>],[
3160 #ifdef _POSIX_SOURCE
3161 make an error
3162 #endif],[],
3163                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
3164          fi
3165          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
3166          CFLAGS="$cf_trim_CFLAGS"
3167          CPPFLAGS="$cf_trim_CPPFLAGS"
3168          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
3169          CF_MSG_LOG(if the second compile does not leave our definition intact error)
3170          AC_TRY_COMPILE([#include <sys/types.h>],[
3171 #ifndef _POSIX_C_SOURCE
3172 make an error
3173 #endif],,
3174          [cf_cv_posix_c_source=no])
3175          CFLAGS="$cf_save_CFLAGS"
3176          CPPFLAGS="$cf_save_CPPFLAGS"
3177         ])
3178 ])
3179
3180 if test "$cf_cv_posix_c_source" != no ; then
3181         CFLAGS="$cf_trim_CFLAGS"
3182         CPPFLAGS="$cf_trim_CPPFLAGS"
3183         CF_ADD_CFLAGS($cf_cv_posix_c_source)
3184 fi
3185
3186 fi # cf_cv_posix_visible
3187
3188 ])dnl
3189 dnl ---------------------------------------------------------------------------
3190 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
3191 dnl ----------------
3192 dnl POSIX documents test-macros which an application may set before any system
3193 dnl headers are included to make features available.
3194 dnl
3195 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
3196 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
3197 dnl recent features visible in the system header files unless the application
3198 dnl overrides the corresponding test-macros.  Doing that introduces portability
3199 dnl problems.
3200 dnl
3201 dnl This macro makes a special check for the symbols used for this, to avoid a
3202 dnl conflicting definition.
3203 AC_DEFUN([CF_POSIX_VISIBLE],
3204 [
3205 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
3206 AC_TRY_COMPILE([#include <stdio.h>],[
3207 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
3208         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
3209         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
3210         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
3211 #error conflicting symbols found
3212 #endif
3213 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
3214 ])
3215 ])dnl
3216 dnl ---------------------------------------------------------------------------
3217 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
3218 dnl ----------
3219 dnl Check for archiver "ar".
3220 AC_DEFUN([CF_PROG_AR],[
3221 AC_CHECK_TOOL(AR, ar, ar)
3222 ])
3223 dnl ---------------------------------------------------------------------------
3224 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
3225 dnl -----------
3226 dnl Check for awk, ensure that the check found something.
3227 AC_DEFUN([CF_PROG_AWK],
3228 [
3229 AC_PROG_AWK
3230 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
3231 ])dnl
3232 dnl ---------------------------------------------------------------------------
3233 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
3234 dnl ----------
3235 dnl standard check for CC, plus followup sanity checks
3236 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
3237 AC_DEFUN([CF_PROG_CC],[
3238 CF_ACVERSION_CHECK(2.53,
3239         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
3240          AC_REQUIRE([AC_PROG_CC])],
3241         [])
3242 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
3243 CF_GCC_VERSION
3244 CF_ACVERSION_CHECK(2.52,
3245         [AC_PROG_CC_STDC],
3246         [CF_ANSI_CC_REQD])
3247 CF_CC_ENV_FLAGS
3248 ])dnl
3249 dnl ---------------------------------------------------------------------------
3250 dnl CF_PROG_CC_C_O version: 5 updated: 2017/01/21 11:06:25
3251 dnl --------------
3252 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
3253 dnl the output file can be renamed, and allows for a shell variable that can
3254 dnl be used later.  The parameter is either CC or CXX.  The result is the
3255 dnl cache variable:
3256 dnl     $cf_cv_prog_CC_c_o
3257 dnl     $cf_cv_prog_CXX_c_o
3258 dnl
3259 dnl $1 = compiler
3260 dnl $2 = compiler options, if any
3261 AC_DEFUN([CF_PROG_CC_C_O],
3262 [AC_REQUIRE([AC_PROG_CC])dnl
3263 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
3264 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
3265 [
3266 cat > conftest.$ac_ext <<CF_EOF
3267 int main(void)
3268 {
3269         ${cf_cv_main_return:-return}(0);
3270 }
3271 CF_EOF
3272 # We do the test twice because some compilers refuse to overwrite an
3273 # existing .o file with -o, though they will create one.
3274 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
3275 if AC_TRY_EVAL(ac_try) &&
3276   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
3277 then
3278   eval cf_cv_prog_$1_c_o=yes
3279 else
3280   eval cf_cv_prog_$1_c_o=no
3281 fi
3282 rm -rf conftest*
3283 ])dnl
3284 if test $cf_cv_prog_$1_c_o = yes; then
3285   AC_MSG_RESULT([yes])
3286 else
3287   AC_MSG_RESULT([no])
3288 fi
3289 ])dnl
3290 dnl ---------------------------------------------------------------------------
3291 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
3292 dnl -------------
3293 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
3294 dnl This macro adds a check to ensure the script found something.
3295 AC_DEFUN([CF_PROG_EGREP],
3296 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
3297         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
3298                 then ac_cv_prog_egrep='grep -E'
3299                 else ac_cv_prog_egrep='egrep'
3300         fi])
3301         EGREP=$ac_cv_prog_egrep
3302         AC_SUBST([EGREP])
3303         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
3304 ])dnl
3305 dnl ---------------------------------------------------------------------------
3306 dnl CF_PROG_EXT version: 14 updated: 2018/06/20 20:23:13
3307 dnl -----------
3308 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
3309 AC_DEFUN([CF_PROG_EXT],
3310 [
3311 AC_REQUIRE([CF_CHECK_CACHE])
3312 case $cf_cv_system_name in
3313 (os2*)
3314         CFLAGS="$CFLAGS -Zmt"
3315         CF_APPEND_TEXT(CPPFLAGS,-D__ST_MT_ERRNO__)
3316         CXXFLAGS="$CXXFLAGS -Zmt"
3317         # autoconf's macro sets -Zexe and suffix both, which conflict:w
3318         LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
3319         ac_cv_exeext=.exe
3320         ;;
3321 esac
3322
3323 AC_EXEEXT
3324 AC_OBJEXT
3325
3326 PROG_EXT="$EXEEXT"
3327 AC_SUBST(PROG_EXT)
3328 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
3329 ])dnl
3330 dnl ---------------------------------------------------------------------------
3331 dnl CF_PROG_GNAT version: 10 updated: 2019/12/31 08:53:54
3332 dnl ------------
3333 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
3334 AC_DEFUN([CF_PROG_GNAT],[
3335 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
3336 do
3337         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
3338
3339         unset ac_cv_path_cf_TEMP_gnat
3340         unset cf_TEMP_gnat
3341         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
3342         eval cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat
3343
3344         if test "x$cf_TEMP_gnat" != xno; then
3345                 unset cf_cv_gnat_version
3346                 unset cf_TEMP_gnat
3347                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
3348         fi
3349         eval cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat
3350
3351         unset cf_TEMP_gnat
3352         unset cf_cv_gnat_version
3353         unset ac_cv_path_cf_TEMP_gnat
3354 done
3355
3356 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
3357         cf_ada_make=
3358         cf_cv_prog_gnat_correct=no
3359 else
3360         cf_ada_make=gnatmake
3361         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
3362                 # gprconfig is newer than gnatmake; we can continue...
3363                 cf_ada_config="##"
3364         else
3365                 rm -rf conftest* *~conftest*
3366                 if mkdir conftest.src
3367                 then
3368                         cf_ada_config=""
3369                         cd conftest.src
3370                         for cf_gprconfig in Ada C
3371                         do
3372                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
3373                                 if test $cf_gprconfig = C
3374                                 then
3375                                         for cf_gprconfig_param in \
3376                                                 $cf_gprconfig,,,,GNATGCC \
3377                                                 $cf_gprconfig,,,,GCC \
3378                                                 $cf_gprconfig
3379                                         do
3380                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
3381                                                 test -n "$cf_gprconfig_value" && break
3382                                         done
3383                                 else
3384                                         cf_gprconfig_param=$cf_gprconfig
3385                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
3386                                 fi
3387                                 if test -n "$cf_gprconfig_value"
3388                                 then
3389                                         eval cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value
3390                                         AC_MSG_RESULT($cf_gprconfig_value)
3391                                 else
3392                                         AC_MSG_RESULT(missing)
3393                                         cf_ada_config="#"
3394                                         break
3395                                 fi
3396                         done
3397                         cd ..
3398                         rm -rf conftest* *~conftest*
3399                 fi
3400         fi
3401         if test "x$cf_ada_config" != "x#"
3402         then
3403                 CF_GNAT_VERSION
3404                 CF_CHECK_GNAT_VERSION
3405                 AC_CHECK_PROG(M4_exists, m4, yes, no)
3406                 if test "$ac_cv_prog_M4_exists" = no; then
3407                         cf_cv_prog_gnat_correct=no
3408                         AC_MSG_WARN(Ada95 binding required program m4 not found. Ada95 binding disabled)
3409                 fi
3410                 if test "$cf_cv_prog_gnat_correct" = yes; then
3411                         AC_MSG_CHECKING(if GNAT works)
3412                         CF_GNAT_TRY_RUN([procedure conftest;],
3413 [with Text_IO;
3414 with GNAT.OS_Lib;
3415 procedure conftest is
3416 begin
3417    Text_IO.Put ("Hello World");
3418    Text_IO.New_Line;
3419    GNAT.OS_Lib.OS_Exit (0);
3420 end conftest;],
3421 [cf_cv_prog_gnat_correct=yes],
3422 [cf_cv_prog_gnat_correct=no])
3423                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
3424                 fi
3425         else
3426                 cf_cv_prog_gnat_correct=no
3427         fi
3428 fi
3429
3430 AC_SUBST(cf_ada_make)
3431 AC_SUBST(cf_ada_config)
3432 AC_SUBST(cf_ada_config_Ada)
3433 AC_SUBST(cf_ada_config_C)
3434 ])dnl
3435 dnl ---------------------------------------------------------------------------
3436 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
3437 dnl ---------------
3438 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
3439 dnl misc/tabset install won't work properly.  Usually this happens only when
3440 dnl using the fallback mkinstalldirs script
3441 AC_DEFUN([CF_PROG_INSTALL],
3442 [AC_PROG_INSTALL
3443 case $INSTALL in
3444 (/*)
3445         ;;
3446 (*)
3447         CF_DIRNAME(cf_dir,$INSTALL)
3448         test -z "$cf_dir" && cf_dir=.
3449         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
3450         ;;
3451 esac
3452 ])dnl
3453 dnl ---------------------------------------------------------------------------
3454 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
3455 dnl ------------
3456 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
3457 dnl option if it is supported.
3458 AC_DEFUN([CF_PROG_LN_S],[
3459 AC_PROG_LN_S
3460 AC_MSG_CHECKING(if $LN_S -f options work)
3461
3462 rm -f conf$$.src conf$$dst
3463 echo >conf$$.dst
3464 echo first >conf$$.src
3465 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
3466         cf_prog_ln_sf=yes
3467 else
3468         cf_prog_ln_sf=no
3469 fi
3470 rm -f conf$$.dst conf$$src
3471 AC_MSG_RESULT($cf_prog_ln_sf)
3472
3473 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
3474 ])dnl
3475 dnl ---------------------------------------------------------------------------
3476 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
3477 dnl ----------------
3478 dnl Remove all -U and -D options that refer to the given symbol from a list
3479 dnl of C compiler options.  This works around the problem that not all
3480 dnl compilers process -U and -D options from left-to-right, so a -U option
3481 dnl cannot be used to cancel the effect of a preceding -D option.
3482 dnl
3483 dnl $1 = target (which could be the same as the source variable)
3484 dnl $2 = source (including '$')
3485 dnl $3 = symbol to remove
3486 define([CF_REMOVE_DEFINE],
3487 [
3488 $1=`echo "$2" | \
3489         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
3490                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
3491 ])dnl
3492 dnl ---------------------------------------------------------------------------
3493 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
3494 dnl -------------
3495 dnl Remove the given library from the symbol
3496 dnl
3497 dnl $1 = target (which could be the same as the source variable)
3498 dnl $2 = source (including '$')
3499 dnl $3 = library to remove
3500 define([CF_REMOVE_LIB],
3501 [
3502 # remove $3 library from $2
3503 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
3504 ])dnl
3505 dnl ---------------------------------------------------------------------------
3506 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
3507 dnl ---------------------
3508 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
3509 dnl $1 = name of current macro
3510 define([CF_RESTORE_XTRA_FLAGS],
3511 [
3512 LIBS="$cf_save_LIBS_$1"
3513 CFLAGS="$cf_save_CFLAGS_$1"
3514 CPPFLAGS="$cf_save_CPPFLAGS_$1"
3515 ])dnl
3516 dnl ---------------------------------------------------------------------------
3517 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
3518 dnl ------------------
3519 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
3520 dnl and libraries which do not update those variables.
3521 dnl
3522 dnl $1 = name of current macro
3523 define([CF_SAVE_XTRA_FLAGS],
3524 [
3525 cf_save_LIBS_$1="$LIBS"
3526 cf_save_CFLAGS_$1="$CFLAGS"
3527 cf_save_CPPFLAGS_$1="$CPPFLAGS"
3528 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
3529 for cf_X_CFLAGS in $X_CFLAGS
3530 do
3531         case "x$cf_X_CFLAGS" in
3532         x-[[IUD]]*)
3533                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
3534                 ;;
3535         *)
3536                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
3537                 ;;
3538         esac
3539 done
3540 ])dnl
3541 dnl ---------------------------------------------------------------------------
3542 dnl CF_SHARED_OPTS version: 96 updated: 2020/05/23 19:39:36
3543 dnl --------------
3544 dnl --------------
3545 dnl Attempt to determine the appropriate CC/LD options for creating a shared
3546 dnl library.
3547 dnl
3548 dnl Notes:
3549 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
3550 dnl the build-tree, i.e., by making use of the libraries that are compiled in
3551 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
3552 dnl shared library since that can lead to unexpected results at runtime.
3553 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
3554 dnl libraries are compiled in ../../lib
3555 dnl
3556 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
3557 dnl to install symbolic links to the rel/abi versions of shared libraries.
3558 dnl
3559 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
3560 dnl version when making symbolic links.
3561 dnl
3562 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
3563 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
3564 dnl (ex: libncurses.so.<ver>).
3565 dnl
3566 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
3567 AC_DEFUN([CF_SHARED_OPTS],
3568 [
3569         AC_REQUIRE([CF_LD_RPATH_OPT])
3570
3571         RM_SHARED_OPTS=
3572         LOCAL_LDFLAGS=
3573         LOCAL_LDFLAGS2=
3574         LD_SHARED_OPTS=
3575         INSTALL_LIB="-m 644"
3576         : ${rel_builddir:=.}
3577
3578         shlibdir=$libdir
3579         AC_SUBST(shlibdir)
3580
3581         MAKE_DLLS="#"
3582         AC_SUBST(MAKE_DLLS)
3583
3584         cf_cv_do_symlinks=no
3585         cf_ld_rpath_opt=
3586         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
3587
3588         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
3589         AC_ARG_WITH(shlib-version,
3590         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
3591         [test -z "$withval" && withval=auto
3592         case $withval in
3593         (yes)
3594                 cf_cv_shlib_version=auto
3595                 ;;
3596         (rel|abi|auto)
3597                 cf_cv_shlib_version=$withval
3598                 ;;
3599         (*)
3600                 AC_MSG_RESULT($withval)
3601                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
3602                 ;;
3603         esac
3604         ],[cf_cv_shlib_version=auto])
3605         AC_MSG_RESULT($cf_cv_shlib_version)
3606
3607         cf_cv_rm_so_locs=no
3608         cf_try_cflags=
3609
3610         # Some less-capable ports of gcc support only -fpic
3611         CC_SHARED_OPTS=
3612
3613         cf_try_fPIC=no
3614         if test "$GCC" = yes
3615         then
3616                 cf_try_fPIC=yes
3617         else
3618                 case $cf_cv_system_name in
3619                 (*linux*)       # e.g., PGI compiler
3620                         cf_try_fPIC=yes
3621                         ;;
3622                 esac
3623         fi
3624
3625         if test "$cf_try_fPIC" = yes
3626         then
3627                 AC_MSG_CHECKING(which $CC option to use)
3628                 cf_save_CFLAGS="$CFLAGS"
3629                 for CC_SHARED_OPTS in -fPIC -fpic ''
3630                 do
3631                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
3632                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
3633                 done
3634                 AC_MSG_RESULT($CC_SHARED_OPTS)
3635                 CFLAGS="$cf_save_CFLAGS"
3636         fi
3637
3638         cf_cv_shlib_version_infix=no
3639
3640         case $cf_cv_system_name in
3641         (aix4.[3-9]*|aix[[5-7]]*)
3642                 if test "$GCC" = yes; then
3643                         CC_SHARED_OPTS='-Wl,-brtl'
3644                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3645                 else
3646                         CC_SHARED_OPTS='-brtl'
3647                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
3648                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3649                 fi
3650                 ;;
3651         (beos*)
3652                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
3653                 ;;
3654         (cygwin*)
3655                 CC_SHARED_OPTS=
3656                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3657                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3658                 cf_cv_shlib_version=cygdll
3659                 cf_cv_shlib_version_infix=cygdll
3660                 shlibdir=$bindir
3661                 MAKE_DLLS=
3662                 cat >mk_shared_lib.sh <<-CF_EOF
3663                 #!$SHELL
3664                 SHARED_LIB=\[$]1
3665                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3666                 shift
3667                 cat <<-EOF
3668                 Linking shared library
3669                 ** SHARED_LIB \[$]SHARED_LIB
3670                 ** IMPORT_LIB \[$]IMPORT_LIB
3671 EOF
3672                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3673 CF_EOF
3674                 chmod +x mk_shared_lib.sh
3675                 ;;
3676         (msys*)
3677                 CC_SHARED_OPTS=
3678                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3679                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3680                 cf_cv_shlib_version=msysdll
3681                 cf_cv_shlib_version_infix=msysdll
3682                 shlibdir=$bindir
3683                 MAKE_DLLS=
3684                 cat >mk_shared_lib.sh <<-CF_EOF
3685                 #!$SHELL
3686                 SHARED_LIB=\[$]1
3687                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3688                 shift
3689                 cat <<-EOF
3690                 Linking shared library
3691                 ** SHARED_LIB \[$]SHARED_LIB
3692                 ** IMPORT_LIB \[$]IMPORT_LIB
3693 EOF
3694                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3695 CF_EOF
3696                 chmod +x mk_shared_lib.sh
3697                 ;;
3698         (darwin*)
3699                 cf_try_cflags="no-cpp-precomp"
3700                 CC_SHARED_OPTS="-dynamic"
3701                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
3702                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
3703                 cf_cv_shlib_version_infix=yes
3704                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
3705                         cf_save_LDFLAGS=$LDFLAGS
3706                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3707                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
3708                                 LDFLAGS=$cf_save_LDFLAGS])
3709                 if test $cf_cv_ldflags_search_paths_first = yes; then
3710                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3711                 fi
3712                 ;;
3713         (hpux[[7-8]]*)
3714                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
3715                 if test "$GCC" != yes; then
3716                         CC_SHARED_OPTS='+Z'
3717                 fi
3718                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
3719                 INSTALL_LIB="-m 555"
3720                 ;;
3721         (hpux*)
3722                 # (tested with gcc 2.7.2 -- I don't have c89)
3723                 if test "$GCC" = yes; then
3724                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
3725                 else
3726                         CC_SHARED_OPTS='+Z'
3727                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
3728                 fi
3729                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
3730                 # HP-UX shared libraries must be executable, and should be
3731                 # readonly to exploit a quirk in the memory manager.
3732                 INSTALL_LIB="-m 555"
3733                 ;;
3734         (interix*)
3735                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3736                 if test "$cf_cv_shlib_version" = rel; then
3737                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3738                 else
3739                         cf_shared_soname='`basename $[@]`'
3740                 fi
3741                 CC_SHARED_OPTS=
3742                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
3743                 ;;
3744         (irix*)
3745                 if test "$cf_cv_enable_rpath" = yes ; then
3746                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3747                 fi
3748                 # tested with IRIX 5.2 and 'cc'.
3749                 if test "$GCC" != yes; then
3750                         CC_SHARED_OPTS='-KPIC'
3751                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
3752                 else
3753                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
3754                 fi
3755                 cf_cv_rm_so_locs=yes
3756                 ;;
3757         (linux*|gnu*|k*bsd*-gnu)
3758                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
3759                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3760                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3761                 fi
3762                 if test "$cf_cv_enable_rpath" = yes ; then
3763                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3764                 fi
3765                 CF_SHARED_SONAME
3766                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3767                 ;;
3768         (mingw*msvc*)
3769                 cf_cv_shlib_version=msvcdll
3770                 cf_cv_shlib_version_infix=msvcdll
3771                 shlibdir=$bindir
3772                 MAKE_DLLS=
3773                 if test "$DFT_LWR_MODEL" = "shared" ; then
3774                         LOCAL_LDFLAGS="-link -dll"
3775                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3776                         EXTRA_LDFLAGS="-link -dll $EXTRA_LDFLAGS"
3777                 fi
3778                 CC_SHARED_OPTS=
3779                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ ${LD} [$]{CFLAGS}'
3780                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.lib"
3781                 cat >mk_shared_lib.sh <<-CF_EOF
3782                 #!$SHELL
3783                 SHARED_LIB=\[$]1
3784                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.lib/'\`
3785                 shift
3786                 my_ld=\[$]1
3787                 shift
3788                 cat <<-EOF
3789                 Linking shared library
3790                 ** SHARED LIB \$SHARED_LIB
3791                 ** IMPORT_LIB \$IMPORT_LIB
3792 EOF
3793                 args=\$(echo \[$]* | sed -E "s#-l(\w*)#\1.dll.lib#g" | sed -E "s#-L(\w*)#-LIBPATH:\1#g")
3794                 exec \$my_ld -DLL -IMPLIB:"\${IMPORT_LIB}" -OUT:"\${SHARED_LIB}" ${LDFLAGS} \$args
3795                 mv "\${IMPORT_LIB}" "\${IMPORT_LIB}"
3796 CF_EOF
3797                 chmod +x mk_shared_lib.sh
3798                 cat >mk_prog.sh <<-CF_EOF
3799                 #!$SHELL
3800                 shift
3801                 # Ignore first argument (compiler) and use LD (link.exe) unconditionally
3802                 LD="[$]LD"
3803                 clopts=()
3804                 ldopts=()
3805                 libs=()
3806                 isdll=0
3807                 while test \[$]# -gt 0; do
3808                         case "\[$]1" in
3809                                 -link)
3810                                         # ignore -link argument
3811                                         ;;
3812                                 -dll)
3813                                         isdll=1
3814                                         ;;
3815                                 -W* | -w*)
3816                                         # ignore warnings
3817                                         ;;
3818                                 -D*)
3819                                         clopts+=("\[$]1")
3820                                         ;;
3821                                 -I*)
3822                                         clopts+=("\[$]1")
3823                                         ;;
3824                                 -l*)
3825                                         libs+=("\`echo \"\[$]1\" | sed \"s/^-l//\"\`")
3826                                         ;;
3827                                 -L*)
3828                                         ldopts+=("\`echo \"\[$]1\" | sed \"s/^-L/-LIBPATH:/\"\`")
3829                                         ;;
3830                                 *.obj | *.o)
3831                                         ldopts+=("\[$]1")
3832                                         ;;
3833                                 -Wl,*)
3834                                         for linkarg in \`echo '\[$]1' | sed -e 's/-Wl,//' -e 's/,/ /'\`; do
3835                                                 ldopts+=("\[$]{linkarg}")
3836                                         done
3837                                         ;;
3838                                 *.lib)
3839                                         ldopts+=("\[$]1")
3840                                         ;;
3841                                 -o)
3842                                         shift
3843                                         ldopts+=("-out:\[$]1")
3844                                         ;;
3845                                 *)
3846                                         clopts+=("\[$]1")
3847                                         ldopts+=("\[$]1")
3848                                         ;;
3849                         esac
3850                         shift
3851                 done
3852                 if [[ "\$isdll" -ne 0 ]]; then
3853                         for lib in \[$]{libs[[*]]}; do
3854                                 ldopts+=("\[$]lib.dll.lib")
3855                         done
3856                 else
3857                         for lib in \[$]{libs[[*]]}; do
3858                                 ldopts+=("\[$]lib.lib")
3859                         done
3860                 fi
3861                 cat <<-EOF
3862                 Creating program
3863                 ** ld options:   "\[$]{ldopts[[@]]}"
3864 EOF
3865                 exec \[$]LD \[$]{ldopts[[@]]}
3866 CF_EOF
3867                 chmod +x mk_prog.sh
3868                 LINK_PROGS="$SHELL ${rel_builddir}/mk_prog.sh"
3869                 ;;
3870         (mingw*)
3871                 cf_cv_shlib_version=mingw
3872                 cf_cv_shlib_version_infix=mingw
3873                 shlibdir=$bindir
3874                 MAKE_DLLS=
3875                 if test "$DFT_LWR_MODEL" = "shared" ; then
3876                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
3877                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3878                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
3879                 fi
3880                 CC_SHARED_OPTS=
3881                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3882                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3883                 cat >mk_shared_lib.sh <<-CF_EOF
3884                 #!$SHELL
3885                 SHARED_LIB=\[$]1
3886                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3887                 shift
3888                 cat <<-EOF
3889                 Linking shared library
3890                 ** SHARED_LIB \[$]SHARED_LIB
3891                 ** IMPORT_LIB \[$]IMPORT_LIB
3892 EOF
3893                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3894 CF_EOF
3895                 chmod +x mk_shared_lib.sh
3896                 ;;
3897         (openbsd[[2-9]].*|mirbsd*)
3898                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
3899                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3900                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3901                 fi
3902                 if test "$cf_cv_enable_rpath" = yes ; then
3903                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3904                 fi
3905                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3906                 CF_SHARED_SONAME
3907                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3908                 ;;
3909         (nto-qnx*|openbsd*|freebsd[[12]].*)
3910                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3911                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
3912                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3913                 ;;
3914         (dragonfly*|freebsd*)
3915                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3916                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3917                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3918                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
3919                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3920                 fi
3921                 CF_SHARED_SONAME
3922                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3923                 ;;
3924         (netbsd*)
3925                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3926                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3927                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3928                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3929                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3930                         if test "$cf_cv_shlib_version" = auto; then
3931                         if test -f /usr/libexec/ld.elf_so; then
3932                                 cf_cv_shlib_version=abi
3933                         else
3934                                 cf_cv_shlib_version=rel
3935                         fi
3936                         fi
3937                         CF_SHARED_SONAME
3938                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
3939                 else
3940                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -Wl,-shared -Wl,-Bshareable -o $[@]'
3941                 fi
3942                 ;;
3943         (osf*|mls+*)
3944                 # tested with OSF/1 V3.2 and 'cc'
3945                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
3946                 # link with shared libs).
3947                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
3948                 case $host_os in
3949                 (osf4*)
3950                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
3951                         ;;
3952                 esac
3953                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
3954                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
3955                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3956                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3957                 fi
3958                 cf_cv_rm_so_locs=yes
3959                 ;;
3960         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
3961                 # tested with osr5.0.5
3962                 if test "$GCC" != yes; then
3963                         CC_SHARED_OPTS='-belf -KPIC'
3964                 fi
3965                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
3966                 if test "$cf_cv_enable_rpath" = yes ; then
3967                         # only way is to set LD_RUN_PATH but no switch for it
3968                         RUN_PATH=$libdir
3969                 fi
3970                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3971                 LINK_PROGS='LD_RUN_PATH=${libdir}'
3972                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
3973                 ;;
3974         (sunos4*)
3975                 # tested with SunOS 4.1.1 and gcc 2.7.0
3976                 if test "$GCC" != yes; then
3977                         CC_SHARED_OPTS='-KPIC'
3978                 fi
3979                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
3980                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3981                 ;;
3982         (solaris2*)
3983                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
3984                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
3985                 if test "$DFT_LWR_MODEL" = "shared" ; then
3986                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
3987                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3988                 fi
3989                 if test "$cf_cv_enable_rpath" = yes ; then
3990                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
3991                 fi
3992                 CF_SHARED_SONAME
3993                 if test "$GCC" != yes; then
3994                         cf_save_CFLAGS="$CFLAGS"
3995                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
3996                         do
3997                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
3998                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
3999                         done
4000                         CFLAGS="$cf_save_CFLAGS"
4001                         CC_SHARED_OPTS=$cf_shared_opts
4002                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
4003                 else
4004                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
4005                 fi
4006                 ;;
4007         (sysv5uw7*|unix_sv*)
4008                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
4009                 if test "$GCC" != yes; then
4010                         CC_SHARED_OPTS='-KPIC'
4011                 fi
4012                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
4013                 ;;
4014         (*)
4015                 CC_SHARED_OPTS='unknown'
4016                 MK_SHARED_LIB='echo unknown'
4017                 ;;
4018         esac
4019
4020         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
4021         case "$cf_cv_shlib_version" in
4022         (rel|abi)
4023                 case "$MK_SHARED_LIB" in
4024                 (*'-o $[@]')
4025                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
4026                         ;;
4027                 (*)
4028                         AC_MSG_WARN(ignored --with-shlib-version)
4029                         ;;
4030                 esac
4031                 ;;
4032         esac
4033
4034         if test -n "$cf_try_cflags"
4035         then
4036 cat > conftest.$ac_ext <<EOF
4037 #line __oline__ "${as_me:-configure}"
4038 #include <stdio.h>
4039 int main(int argc, char *argv[[]])
4040 {
4041         printf("hello\n");
4042         return (argv[[argc-1]] == 0) ;
4043 }
4044 EOF
4045                 cf_save_CFLAGS="$CFLAGS"
4046                 for cf_opt in $cf_try_cflags
4047                 do
4048                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
4049                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
4050                         if AC_TRY_EVAL(ac_compile); then
4051                                 AC_MSG_RESULT(yes)
4052                                 cf_save_CFLAGS="$CFLAGS"
4053                         else
4054                                 AC_MSG_RESULT(no)
4055                         fi
4056                 done
4057                 CFLAGS="$cf_save_CFLAGS"
4058         fi
4059
4060
4061         # RPATH_LIST is a colon-separated list of directories
4062         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
4063         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
4064
4065         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
4066
4067         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
4068         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
4069
4070         AC_SUBST(CC_SHARED_OPTS)
4071         AC_SUBST(LD_RPATH_OPT)
4072         AC_SUBST(LD_SHARED_OPTS)
4073         AC_SUBST(MK_SHARED_LIB)
4074         AC_SUBST(RM_SHARED_OPTS)
4075
4076         AC_SUBST(LINK_PROGS)
4077         AC_SUBST(LINK_TESTS)
4078
4079         AC_SUBST(EXTRA_LDFLAGS)
4080         AC_SUBST(LOCAL_LDFLAGS)
4081         AC_SUBST(LOCAL_LDFLAGS2)
4082
4083         AC_SUBST(INSTALL_LIB)
4084         AC_SUBST(RPATH_LIST)
4085 ])dnl
4086 dnl ---------------------------------------------------------------------------
4087 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
4088 dnl ----------------
4089 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
4090 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
4091 dnl option.
4092 dnl
4093 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
4094 dnl If missing, use "rel".
4095 define([CF_SHARED_SONAME],
4096 [
4097         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
4098         if test "$cf_cv_shlib_version" = rel; then
4099                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
4100         else
4101                 cf_cv_shared_soname='`basename $[@]`'
4102         fi
4103 ])
4104 dnl ---------------------------------------------------------------------------
4105 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
4106 dnl --------------
4107 dnl     Remove "-g" option from the compiler options
4108 AC_DEFUN([CF_STRIP_G_OPT],
4109 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
4110 dnl ---------------------------------------------------------------------------
4111 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
4112 dnl --------------
4113 dnl Construct a search-list for a nonstandard header/lib-file
4114 dnl     $1 = the variable to return as result
4115 dnl     $2 = the package name
4116 dnl     $3 = the subdirectory, e.g., bin, include or lib
4117 AC_DEFUN([CF_SUBDIR_PATH],
4118 [
4119 $1=
4120
4121 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
4122
4123 for cf_subdir_prefix in \
4124         /usr \
4125         /usr/local \
4126         /usr/pkg \
4127         /opt \
4128         /opt/local \
4129         [$]HOME
4130 do
4131         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
4132 done
4133 ])dnl
4134 dnl ---------------------------------------------------------------------------
4135 dnl CF_TERM_HEADER version: 5 updated: 2020/03/19 20:23:48
4136 dnl --------------
4137 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
4138 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
4139 dnl but some packagers change this, breaking various applications.
4140 AC_DEFUN([CF_TERM_HEADER],[
4141 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
4142 case ${cf_cv_ncurses_header} in
4143 (*/ncurses.h|*/ncursesw.h)
4144         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
4145         ;;
4146 (*)
4147         cf_term_header=term.h
4148         ;;
4149 esac
4150
4151 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
4152 do
4153 AC_TRY_COMPILE([#include <stdio.h>
4154 #include <${cf_cv_ncurses_header:-curses.h}>
4155 #include <$cf_test>
4156 ],[int x = auto_left_margin; (void)x],[
4157         cf_cv_term_header="$cf_test"],[
4158         cf_cv_term_header=unknown
4159         ])
4160         test "$cf_cv_term_header" != unknown && break
4161 done
4162 ])
4163
4164 # Set definitions to allow ifdef'ing to accommodate subdirectories
4165
4166 case $cf_cv_term_header in
4167 (*term.h)
4168         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
4169         ;;
4170 esac
4171
4172 case $cf_cv_term_header in
4173 (ncurses/term.h)
4174         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
4175         ;;
4176 (ncursesw/term.h)
4177         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
4178         ;;
4179 esac
4180 ])dnl
4181 dnl ---------------------------------------------------------------------------
4182 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
4183 dnl ---------------
4184 dnl Define a top_builddir symbol, for applications that need an absolute path.
4185 AC_DEFUN([CF_TOP_BUILDDIR],
4186 [
4187 top_builddir=ifelse($1,,`pwd`,$1)
4188 AC_SUBST(top_builddir)
4189 ])dnl
4190 dnl ---------------------------------------------------------------------------
4191 dnl CF_TRY_XOPEN_SOURCE version: 2 updated: 2018/06/20 20:23:13
4192 dnl -------------------
4193 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
4194 dnl can define it successfully.
4195 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
4196 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
4197         AC_TRY_COMPILE([
4198 #include <stdlib.h>
4199 #include <string.h>
4200 #include <sys/types.h>
4201 ],[
4202 #ifndef _XOPEN_SOURCE
4203 make an error
4204 #endif],
4205         [cf_cv_xopen_source=no],
4206         [cf_save="$CPPFLAGS"
4207          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
4208          AC_TRY_COMPILE([
4209 #include <stdlib.h>
4210 #include <string.h>
4211 #include <sys/types.h>
4212 ],[
4213 #ifdef _XOPEN_SOURCE
4214 make an error
4215 #endif],
4216         [cf_cv_xopen_source=no],
4217         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
4218         CPPFLAGS="$cf_save"
4219         ])
4220 ])
4221
4222 if test "$cf_cv_xopen_source" != no ; then
4223         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
4224         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
4225         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
4226         CF_ADD_CFLAGS($cf_temp_xopen_source)
4227 fi
4228 ])
4229 dnl ---------------------------------------------------------------------------
4230 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
4231 dnl --------
4232 dnl Make an uppercase version of a variable
4233 dnl $1=uppercase($2)
4234 AC_DEFUN([CF_UPPER],
4235 [
4236 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4237 ])dnl
4238 dnl ---------------------------------------------------------------------------
4239 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
4240 dnl -----------
4241 dnl Check for multibyte support, and if not found, utf8 compatibility library
4242 AC_DEFUN([CF_UTF8_LIB],
4243 [
4244 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
4245         cf_save_LIBS="$LIBS"
4246         AC_TRY_LINK([
4247 #include <stdlib.h>],[putwc(0,0);],
4248         [cf_cv_utf8_lib=yes],
4249         [CF_FIND_LINKAGE([
4250 #include <libutf8.h>],[putwc(0,0);],utf8,
4251                 [cf_cv_utf8_lib=add-on],
4252                 [cf_cv_utf8_lib=no])
4253 ])])
4254
4255 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
4256 # ncurses/ncursesw:
4257 if test "$cf_cv_utf8_lib" = "add-on" ; then
4258         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
4259         CF_ADD_INCDIR($cf_cv_header_path_utf8)
4260         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
4261         CF_ADD_LIBS($cf_cv_library_file_utf8)
4262 fi
4263 ])dnl
4264 dnl ---------------------------------------------------------------------------
4265 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
4266 dnl ----------
4267 dnl Use AC_VERBOSE w/o the warnings
4268 AC_DEFUN([CF_VERBOSE],
4269 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
4270 CF_MSG_LOG([$1])
4271 ])dnl
4272 dnl ---------------------------------------------------------------------------
4273 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
4274 dnl ---------------
4275 dnl Check for compiler-support for weak symbols.
4276 dnl This works with "recent" gcc.
4277 AC_DEFUN([CF_WEAK_SYMBOLS],[
4278 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
4279
4280 AC_TRY_COMPILE([
4281 #include <stdio.h>],
4282 [
4283 #if defined(__GNUC__)
4284 #  if defined __USE_ISOC99
4285 #    define _cat_pragma(exp)    _Pragma(#exp)
4286 #    define _weak_pragma(exp)   _cat_pragma(weak name)
4287 #  else
4288 #    define _weak_pragma(exp)
4289 #  endif
4290 #  define _declare(name)        __extension__ extern __typeof__(name) name
4291 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
4292 #endif
4293
4294 weak_symbol(fopen);
4295 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
4296 ])
4297 ])dnl
4298 dnl ---------------------------------------------------------------------------
4299 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
4300 dnl --------------------
4301 dnl Command-line option to specify the Ada95 compiler.
4302 AC_DEFUN([CF_WITH_ADA_COMPILER],[
4303 AC_MSG_CHECKING(for ada-compiler)
4304 AC_ARG_WITH(ada-compiler,
4305         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
4306         [cf_ada_compiler=$withval],
4307         [cf_ada_compiler=gnatmake])
4308 AC_SUBST(cf_ada_compiler)
4309 AC_MSG_RESULT($cf_ada_compiler)
4310 ])dnl
4311 dnl ---------------------------------------------------------------------------
4312 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
4313 dnl -------------------
4314 dnl Command-line option to specify where Ada includes will install.
4315 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
4316 AC_MSG_CHECKING(for ada-include)
4317 CF_WITH_PATH(ada-include,
4318    [  --with-ada-include=DIR  Ada includes are in DIR],
4319    ADA_INCLUDE,
4320    PREFIX/share/ada/adainclude,
4321    [$]prefix/share/ada/adainclude)
4322 AC_SUBST(ADA_INCLUDE)
4323 AC_MSG_RESULT($ADA_INCLUDE)
4324 ])dnl
4325 dnl ---------------------------------------------------------------------------
4326 dnl CF_WITH_ADA_LIBNAME version: 1 updated: 2019/09/07 18:59:41
4327 dnl -------------------
4328 dnl CF_WITH_ADA_LIBNAME
4329 dnl -------------------
4330 dnl Command-line option to specify how to name the resulting Ada library.
4331 dnl $1 = default value
4332 AC_DEFUN([CF_WITH_ADA_LIBNAME],[
4333 AC_MSG_CHECKING(for ada-libname)
4334 AC_ARG_WITH(ada-libname,
4335    [  --with-ada-libname=XXX  override default Ada library-name],
4336    ADA_LIBNAME=[$]withval,
4337    ADA_LIBNAME=$1)
4338 case "x$ADA_LIBNAME" in
4339 (x|xyes|xno)
4340         ADA_LIBNAME=$1
4341         ;;
4342 esac
4343 AC_SUBST(ADA_LIBNAME)
4344 AC_MSG_RESULT($ADA_LIBNAME)
4345 ])dnl
4346 dnl ---------------------------------------------------------------------------
4347 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
4348 dnl -------------------
4349 dnl Command-line option to specify where Ada objects will install.
4350 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
4351 AC_MSG_CHECKING(for ada-objects)
4352 CF_WITH_PATH(ada-objects,
4353    [  --with-ada-objects=DIR  Ada objects are in DIR],
4354    ADA_OBJECTS,
4355    PREFIX/lib/ada/adalib,
4356    [$]prefix/lib/ada/adalib)
4357 AC_SUBST(ADA_OBJECTS)
4358 AC_MSG_RESULT($ADA_OBJECTS)
4359 ])dnl
4360 dnl ---------------------------------------------------------------------------
4361 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
4362 dnl ---------------------
4363 dnl Command-line option to specify if an Ada95 shared-library should be built,
4364 dnl and optionally what its soname should be.
4365 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
4366 AC_REQUIRE([CF_GNAT_PROJECTS])
4367 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
4368 AC_ARG_WITH(ada-sharedlib,
4369         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
4370         [with_ada_sharedlib=$withval],
4371         [with_ada_sharedlib=no])
4372 AC_MSG_RESULT($with_ada_sharedlib)
4373
4374 if test "x$with_ada_sharedlib" != xno
4375 then
4376         if test "x$cf_gnat_projects" != xyes
4377         then
4378                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
4379                 with_ada_sharedlib=no
4380         fi
4381 fi
4382
4383 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
4384 MAKE_ADA_SHAREDLIB="#"
4385
4386 if test "x$with_ada_sharedlib" != xno
4387 then
4388         MAKE_ADA_SHAREDLIB=
4389         if test "x$with_ada_sharedlib" != xyes
4390         then
4391                 ADA_SHAREDLIB="$with_ada_sharedlib"
4392         fi
4393 fi
4394
4395 AC_SUBST(ADA_SHAREDLIB)
4396 AC_SUBST(MAKE_ADA_SHAREDLIB)
4397 ])dnl
4398 dnl ---------------------------------------------------------------------------
4399 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
4400 dnl ------------------
4401 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
4402 dnl libraries.
4403 AC_DEFUN([CF_WITH_CURSES_DIR],[
4404
4405 AC_MSG_CHECKING(for specific curses-directory)
4406 AC_ARG_WITH(curses-dir,
4407         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
4408         [cf_cv_curses_dir=$withval],
4409         [cf_cv_curses_dir=no])
4410 AC_MSG_RESULT($cf_cv_curses_dir)
4411
4412 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
4413 then
4414         CF_PATH_SYNTAX(withval)
4415         if test -d "$cf_cv_curses_dir"
4416         then
4417                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
4418                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
4419         fi
4420 fi
4421 ])dnl
4422 dnl ---------------------------------------------------------------------------
4423 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
4424 dnl ------------------
4425 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
4426 dnl "lib" prefix, e.g., because it used the dll naming convention.
4427 dnl
4428 dnl $1 = variable to set
4429 AC_DEFUN([CF_WITH_LIB_PREFIX],
4430 [
4431 AC_MSG_CHECKING(if you want to have a library-prefix)
4432 AC_ARG_WITH(lib-prefix,
4433         [  --with-lib-prefix       override library-prefix],
4434         [with_lib_prefix=$withval],
4435         [with_lib_prefix=auto])
4436 AC_MSG_RESULT($with_lib_prefix)
4437
4438 if test $with_lib_prefix = auto
4439 then
4440         CF_LIB_PREFIX($1)
4441 elif test $with_lib_prefix = no
4442 then
4443         LIB_PREFIX=
4444 else
4445         LIB_PREFIX=$with_lib_prefix
4446 fi
4447 ])dnl
4448 dnl ---------------------------------------------------------------------------
4449 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
4450 dnl ------------
4451 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
4452 dnl defaulting to yes/no.
4453 dnl
4454 dnl $1 = option name
4455 dnl $2 = help-text
4456 dnl $3 = environment variable to set
4457 dnl $4 = default value, shown in the help-message, must be a constant
4458 dnl $5 = default value, if it's an expression & cannot be in the help-message
4459 dnl
4460 AC_DEFUN([CF_WITH_PATH],
4461 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
4462 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
4463 if ifelse([$5],,true,[test -n "$5"]) ; then
4464 CF_PATH_SYNTAX(withval)
4465 fi
4466 eval $3="$withval"
4467 AC_SUBST($3)dnl
4468 ])dnl
4469 dnl ---------------------------------------------------------------------------
4470 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
4471 dnl -------------------------
4472 dnl Allow the choice of the pkg-config library directory to be overridden.
4473 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
4474
4475 case $PKG_CONFIG in
4476 (no|none|yes)
4477         AC_MSG_CHECKING(for pkg-config library directory)
4478         ;;
4479 (*)
4480         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
4481         ;;
4482 esac
4483
4484 PKG_CONFIG_LIBDIR=no
4485 AC_ARG_WITH(pkg-config-libdir,
4486         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
4487         [PKG_CONFIG_LIBDIR=$withval],
4488         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
4489
4490 case x$PKG_CONFIG_LIBDIR in
4491 (x/*)
4492         ;;
4493 (xyes)
4494         # Look for the library directory using the same prefix as the executable
4495         if test "x$PKG_CONFIG" = xnone
4496         then
4497                 cf_path=$prefix
4498         else
4499                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
4500         fi
4501
4502         # If you don't like using the default architecture, you have to specify the
4503         # intended library directory and corresponding compiler/linker options.
4504         #
4505         # This case allows for Debian's 2014-flavor of multiarch, along with the
4506         # most common variations before that point.  Some other variants spell the
4507         # directory differently, e.g., "pkg-config", and put it in unusual places.
4508         # pkg-config has always been poorly standardized, which is ironic...
4509         case x`(arch) 2>/dev/null` in
4510         (*64)
4511                 cf_search_path="\
4512                         $cf_path/lib/*64-linux-gnu \
4513                         $cf_path/share \
4514                         $cf_path/lib64 \
4515                         $cf_path/lib32 \
4516                         $cf_path/lib"
4517                 ;;
4518         (*)
4519                 cf_search_path="\
4520                         $cf_path/lib/*-linux-gnu \
4521                         $cf_path/share \
4522                         $cf_path/lib32 \
4523                         $cf_path/lib \
4524                         $cf_path/libdata"
4525                 ;;
4526         esac
4527
4528         CF_VERBOSE(list...)
4529         for cf_config in $cf_search_path
4530         do
4531                 CF_VERBOSE(checking $cf_config/pkgconfig)
4532                 if test -d $cf_config/pkgconfig
4533                 then
4534                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
4535                         AC_MSG_CHECKING(done)
4536                         break
4537                 fi
4538         done
4539         ;;
4540 (*)
4541         ;;
4542 esac
4543
4544 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
4545         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
4546 fi
4547
4548 AC_SUBST(PKG_CONFIG_LIBDIR)
4549 ])dnl
4550 dnl ---------------------------------------------------------------------------
4551 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
4552 dnl ---------------
4553 dnl Check for POSIX thread library.
4554 AC_DEFUN([CF_WITH_PTHREAD],
4555 [
4556 AC_MSG_CHECKING(if you want to link with the pthread library)
4557 AC_ARG_WITH(pthread,
4558         [  --with-pthread          use POSIX thread library],
4559         [with_pthread=$withval],
4560         [with_pthread=no])
4561 AC_MSG_RESULT($with_pthread)
4562
4563 if test "$with_pthread" != no ; then
4564         AC_CHECK_HEADER(pthread.h,[
4565         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
4566
4567         for cf_lib_pthread in pthread c_r
4568         do
4569             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
4570             cf_save_LIBS="$LIBS"
4571             CF_ADD_LIB($cf_lib_pthread)
4572             AC_TRY_LINK([
4573 #include <pthread.h>
4574 ],[
4575                 int rc = pthread_create(0,0,0,0);
4576                 int r2 = pthread_mutexattr_settype(0, 0);
4577 ],[with_pthread=yes],[with_pthread=no])
4578             LIBS="$cf_save_LIBS"
4579             AC_MSG_RESULT($with_pthread)
4580             test "$with_pthread" = yes && break
4581         done
4582
4583         if test "$with_pthread" = yes ; then
4584             CF_ADD_LIB($cf_lib_pthread)
4585             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
4586         else
4587             AC_MSG_ERROR(Cannot link with pthread library)
4588         fi
4589         ])
4590 fi
4591 ])
4592 dnl ---------------------------------------------------------------------------
4593 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
4594 dnl ---------------
4595 dnl For testing, override the derived host system-type which is used to decide
4596 dnl things such as the linker commands used to build shared libraries.  This is
4597 dnl normally chosen automatically based on the type of system which you are
4598 dnl building on.  We use it for testing the configure script.
4599 dnl
4600 dnl This is different from the --host option: it is used only for testing parts
4601 dnl of the configure script which would not be reachable with --host since that
4602 dnl relies on the build environment being real, rather than mocked up.
4603 AC_DEFUN([CF_WITH_SYSTYPE],[
4604 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
4605 AC_ARG_WITH(system-type,
4606         [  --with-system-type=XXX  test: override derived host system-type],
4607 [AC_MSG_WARN(overriding system type to $withval)
4608         cf_cv_system_name=$withval
4609         host_os=$withval
4610 ])
4611 ])dnl
4612 dnl ---------------------------------------------------------------------------
4613 dnl CF_XOPEN_SOURCE version: 55 updated: 2018/12/31 20:46:17
4614 dnl ---------------
4615 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
4616 dnl or adapt to the vendor's definitions to get equivalent functionality,
4617 dnl without losing the common non-POSIX features.
4618 dnl
4619 dnl Parameters:
4620 dnl     $1 is the nominal value for _XOPEN_SOURCE
4621 dnl     $2 is the nominal value for _POSIX_C_SOURCE
4622 AC_DEFUN([CF_XOPEN_SOURCE],[
4623 AC_REQUIRE([AC_CANONICAL_HOST])
4624 AC_REQUIRE([CF_POSIX_VISIBLE])
4625
4626 if test "$cf_cv_posix_visible" = no; then
4627
4628 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
4629 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
4630 cf_xopen_source=
4631
4632 case $host_os in
4633 (aix[[4-7]]*)
4634         cf_xopen_source="-D_ALL_SOURCE"
4635         ;;
4636 (msys)
4637         cf_XOPEN_SOURCE=600
4638         ;;
4639 (darwin[[0-8]].*)
4640         cf_xopen_source="-D_APPLE_C_SOURCE"
4641         ;;
4642 (darwin*)
4643         cf_xopen_source="-D_DARWIN_C_SOURCE"
4644         cf_XOPEN_SOURCE=
4645         ;;
4646 (freebsd*|dragonfly*|midnightbsd*)
4647         # 5.x headers associate
4648         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
4649         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
4650         cf_POSIX_C_SOURCE=200112L
4651         cf_XOPEN_SOURCE=600
4652         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
4653         ;;
4654 (hpux11*)
4655         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
4656         ;;
4657 (hpux*)
4658         cf_xopen_source="-D_HPUX_SOURCE"
4659         ;;
4660 (irix[[56]].*)
4661         cf_xopen_source="-D_SGI_SOURCE"
4662         cf_XOPEN_SOURCE=
4663         ;;
4664 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
4665         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
4666         ;;
4667 (minix*)
4668         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
4669         ;;
4670 (mirbsd*)
4671         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
4672         cf_XOPEN_SOURCE=
4673         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4674         ;;
4675 (netbsd*)
4676         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
4677         ;;
4678 (openbsd[[4-9]]*)
4679         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
4680         cf_xopen_source="-D_BSD_SOURCE"
4681         cf_XOPEN_SOURCE=600
4682         ;;
4683 (openbsd*)
4684         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
4685         ;;
4686 (osf[[45]]*)
4687         cf_xopen_source="-D_OSF_SOURCE"
4688         ;;
4689 (nto-qnx*)
4690         cf_xopen_source="-D_QNX_SOURCE"
4691         ;;
4692 (sco*)
4693         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
4694         ;;
4695 (solaris2.*)
4696         cf_xopen_source="-D__EXTENSIONS__"
4697         cf_cv_xopen_source=broken
4698         ;;
4699 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
4700         cf_XOPEN_SOURCE=
4701         cf_POSIX_C_SOURCE=
4702         ;;
4703 (*)
4704         CF_TRY_XOPEN_SOURCE
4705         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4706         ;;
4707 esac
4708
4709 if test -n "$cf_xopen_source" ; then
4710         CF_ADD_CFLAGS($cf_xopen_source,true)
4711 fi
4712
4713 dnl In anything but the default case, we may have system-specific setting
4714 dnl which is still not guaranteed to provide all of the entrypoints that
4715 dnl _XOPEN_SOURCE would yield.
4716 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
4717         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
4718         AC_TRY_COMPILE([#include <stdlib.h>],[
4719 #ifndef _XOPEN_SOURCE
4720 make an error
4721 #endif],
4722         [cf_XOPEN_SOURCE_set=yes],
4723         [cf_XOPEN_SOURCE_set=no])
4724         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
4725         if test $cf_XOPEN_SOURCE_set = yes
4726         then
4727                 AC_TRY_COMPILE([#include <stdlib.h>],[
4728 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
4729 make an error
4730 #endif],
4731                 [cf_XOPEN_SOURCE_set_ok=yes],
4732                 [cf_XOPEN_SOURCE_set_ok=no])
4733                 if test $cf_XOPEN_SOURCE_set_ok = no
4734                 then
4735                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
4736                 fi
4737         else
4738                 CF_TRY_XOPEN_SOURCE
4739         fi
4740 fi
4741 fi # cf_cv_posix_visible
4742 ])