3019a073c8800a57824499822625240742cb16c8
[ncurses.git] / Ada95 / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright (c) 2010,2011 Free Software Foundation, Inc.                   *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey
30 dnl
31 dnl $Id: aclocal.m4,v 1.30 2011/07/02 19:51:20 tom Exp $
32 dnl Macros used in NCURSES Ada95 auto-configuration script.
33 dnl
34 dnl These macros are maintained separately from NCURSES.  The copyright on
35 dnl this file applies to the aggregation of macros and does not affect use of
36 dnl these macros in other applications.
37 dnl
38 dnl See http://invisible-island.net/autoconf/ for additional information.
39 dnl
40 dnl ---------------------------------------------------------------------------
41 dnl ---------------------------------------------------------------------------
42 dnl CF_ACVERSION_CHECK version: 2 updated: 2011/05/08 11:22:03
43 dnl ------------------
44 dnl Conditionally generate script according to whether we're using a given autoconf.
45 dnl
46 dnl $1 = version to compare against
47 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
48 dnl $3 = code to use if AC_ACVERSION is older than $1.
49 define(CF_ACVERSION_CHECK,
50 [
51 ifdef([m4_version_compare],
52 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
53 [CF_ACVERSION_COMPARE(
54 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
55 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
56 dnl ---------------------------------------------------------------------------
57 dnl CF_ACVERSION_COMPARE version: 2 updated: 2011/04/14 20:56:50
58 dnl --------------------
59 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
60 dnl                      MAJOR2, MINOR2, TERNARY2,
61 dnl                      PRINTABLE2, not FOUND, FOUND)
62 define(CF_ACVERSION_COMPARE,
63 [ifelse(builtin([eval], [$2 < $5]), 1,
64 [ifelse([$8], , ,[$8])],
65 [ifelse([$9], , ,[$9])])])dnl
66 dnl ---------------------------------------------------------------------------
67 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
68 dnl -------------------
69 dnl Construct the list of include-options for the C programs in the Ada95
70 dnl binding.
71 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
72 [
73 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
74 if test "$srcdir" != "."; then
75         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
76 fi
77 if test "$GCC" != yes; then
78         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
79 elif test "$includedir" != "/usr/include"; then
80         if test "$includedir" = '${prefix}/include' ; then
81                 if test $prefix != /usr ; then
82                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
83                 fi
84         else
85                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
86         fi
87 fi
88 AC_SUBST(ACPPFLAGS)
89 ])dnl
90 dnl ---------------------------------------------------------------------------
91 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
92 dnl ---------------
93 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
94 AC_DEFUN([CF_ADD_ADAFLAGS],[
95         ADAFLAGS="$ADAFLAGS $1"
96         AC_SUBST(ADAFLAGS)
97 ])dnl
98 dnl ---------------------------------------------------------------------------
99 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
100 dnl -------------
101 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
102 dnl The second parameter if given makes this macro verbose.
103 dnl
104 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
105 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
106 dnl confused by the quotes (which require backslashes to keep them usable).
107 AC_DEFUN([CF_ADD_CFLAGS],
108 [
109 cf_fix_cppflags=no
110 cf_new_cflags=
111 cf_new_cppflags=
112 cf_new_extra_cppflags=
113
114 for cf_add_cflags in $1
115 do
116 case $cf_fix_cppflags in
117 no)
118         case $cf_add_cflags in #(vi
119         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
120                 case $cf_add_cflags in
121                 -D*)
122                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
123
124                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
125                                 && test -z "${cf_tst_cflags}" \
126                                 && cf_fix_cppflags=yes
127
128                         if test $cf_fix_cppflags = yes ; then
129                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
130                                 continue
131                         elif test "${cf_tst_cflags}" = "\"'" ; then
132                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
133                                 continue
134                         fi
135                         ;;
136                 esac
137                 case "$CPPFLAGS" in
138                 *$cf_add_cflags) #(vi
139                         ;;
140                 *) #(vi
141                         case $cf_add_cflags in #(vi
142                         -D*)
143                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
144                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
145                                 ;;
146                         esac
147                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
148                         ;;
149                 esac
150                 ;;
151         *)
152                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
153                 ;;
154         esac
155         ;;
156 yes)
157         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
158
159         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
160
161         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
162                 && test -z "${cf_tst_cflags}" \
163                 && cf_fix_cppflags=no
164         ;;
165 esac
166 done
167
168 if test -n "$cf_new_cflags" ; then
169         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
170         CFLAGS="$CFLAGS $cf_new_cflags"
171 fi
172
173 if test -n "$cf_new_cppflags" ; then
174         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
175         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
176 fi
177
178 if test -n "$cf_new_extra_cppflags" ; then
179         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
180         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
181 fi
182
183 AC_SUBST(EXTRA_CPPFLAGS)
184
185 ])dnl
186 dnl ---------------------------------------------------------------------------
187 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
188 dnl -------------
189 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
190 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
191 dnl but old versions (and some misinstalled ones) need that.  To make things
192 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
193 dnl the include-path).
194 AC_DEFUN([CF_ADD_INCDIR],
195 [
196 if test -n "$1" ; then
197   for cf_add_incdir in $1
198   do
199         while test $cf_add_incdir != /usr/include
200         do
201           if test -d $cf_add_incdir
202           then
203                 cf_have_incdir=no
204                 if test -n "$CFLAGS$CPPFLAGS" ; then
205                   # a loop is needed to ensure we can add subdirs of existing dirs
206                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
207                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
208                           cf_have_incdir=yes; break
209                         fi
210                   done
211                 fi
212
213                 if test "$cf_have_incdir" = no ; then
214                   if test "$cf_add_incdir" = /usr/local/include ; then
215                         if test "$GCC" = yes
216                         then
217                           cf_save_CPPFLAGS=$CPPFLAGS
218                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
219                           AC_TRY_COMPILE([#include <stdio.h>],
220                                   [printf("Hello")],
221                                   [],
222                                   [cf_have_incdir=yes])
223                           CPPFLAGS=$cf_save_CPPFLAGS
224                         fi
225                   fi
226                 fi
227
228                 if test "$cf_have_incdir" = no ; then
229                   CF_VERBOSE(adding $cf_add_incdir to include-path)
230                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
231
232                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
233                   test "$cf_top_incdir" = "$cf_add_incdir" && break
234                   cf_add_incdir="$cf_top_incdir"
235                 else
236                   break
237                 fi
238           fi
239         done
240   done
241 fi
242 ])dnl
243 dnl ---------------------------------------------------------------------------
244 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
245 dnl ----------
246 dnl Add a library, used to enforce consistency.
247 dnl
248 dnl $1 = library to add, without the "-l"
249 dnl $2 = variable to update (default $LIBS)
250 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
251 dnl ---------------------------------------------------------------------------
252 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
253 dnl -------------
254 dnl     Adds to the library-path
255 dnl
256 dnl     Some machines have trouble with multiple -L options.
257 dnl
258 dnl $1 is the (list of) directory(s) to add
259 dnl $2 is the optional name of the variable to update (default LDFLAGS)
260 dnl
261 AC_DEFUN([CF_ADD_LIBDIR],
262 [
263 if test -n "$1" ; then
264   for cf_add_libdir in $1
265   do
266     if test $cf_add_libdir = /usr/lib ; then
267       :
268     elif test -d $cf_add_libdir
269     then
270       cf_have_libdir=no
271       if test -n "$LDFLAGS$LIBS" ; then
272         # a loop is needed to ensure we can add subdirs of existing dirs
273         for cf_test_libdir in $LDFLAGS $LIBS ; do
274           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
275             cf_have_libdir=yes; break
276           fi
277         done
278       fi
279       if test "$cf_have_libdir" = no ; then
280         CF_VERBOSE(adding $cf_add_libdir to library-path)
281         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
282       fi
283     fi
284   done
285 fi
286 ])dnl
287 dnl ---------------------------------------------------------------------------
288 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
289 dnl -----------
290 dnl Add one or more libraries, used to enforce consistency.
291 dnl
292 dnl $1 = libraries to add, with the "-l", etc.
293 dnl $2 = variable to update (default $LIBS)
294 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
295 dnl ---------------------------------------------------------------------------
296 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
297 dnl ------------------
298 dnl Append to a search-list for a nonstandard header/lib-file
299 dnl     $1 = the variable to return as result
300 dnl     $2 = the package name
301 dnl     $3 = the subdirectory, e.g., bin, include or lib
302 dnl $4 = the directory under which we will test for subdirectories
303 dnl $5 = a directory that we do not want $4 to match
304 AC_DEFUN([CF_ADD_SUBDIR_PATH],
305 [
306 test "$4" != "$5" && \
307 test -d "$4" && \
308 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
309         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
310         test -d $4/$3 &&          $1="[$]$1 $4/$3"
311         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
312         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
313         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
314         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
315 }
316 ])dnl
317 dnl ---------------------------------------------------------------------------
318 dnl CF_ANSI_CC_CHECK version: 11 updated: 2011/07/01 19:47:45
319 dnl ----------------
320 dnl This was originally adapted from the macros 'fp_PROG_CC_STDC' and
321 dnl 'fp_C_PROTOTYPES' in the sharutils 4.2 distribution.
322 AC_DEFUN([CF_ANSI_CC_CHECK],
323 [
324 # This should have been defined by AC_PROG_CC
325 : ${CC:=cc}
326
327 # Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
328 # into CC.  This will not help with broken scripts that wrap the compiler with
329 # options, but eliminates a more common category of user confusion.
330 AC_MSG_CHECKING(\$CC variable)
331 case "$CC" in #(vi
332 *[[\ \  ]]-[[IUD]]*)
333         AC_MSG_RESULT(broken)
334         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
335         # humor him...
336         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
337         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
338         CF_ADD_CFLAGS($cf_flags)
339         ;;
340 *)
341         AC_MSG_RESULT(ok)
342         ;;
343 esac
344
345 AC_CACHE_CHECK(for ${CC:-cc} option to accept ANSI C, cf_cv_ansi_cc,[
346 cf_cv_ansi_cc=no
347 cf_save_CFLAGS="$CFLAGS"
348 cf_save_CPPFLAGS="$CPPFLAGS"
349 # Don't try gcc -ansi; that turns off useful extensions and
350 # breaks some systems' header files.
351 # AIX                   -qlanglvl=ansi
352 # Ultrix and OSF/1      -std1
353 # HP-UX                 -Aa -D_HPUX_SOURCE
354 # SVR4                  -Xc
355 # UnixWare 1.2          (cannot use -Xc, since ANSI/POSIX clashes)
356 for cf_arg in "-DCC_HAS_PROTOS" \
357         "" \
358         -qlanglvl=ansi \
359         -std1 \
360         -Ae \
361         "-Aa -D_HPUX_SOURCE" \
362         -Xc
363 do
364         CF_ADD_CFLAGS($cf_arg)
365         AC_TRY_COMPILE(
366 [
367 #ifndef CC_HAS_PROTOS
368 #if !defined(__STDC__) || (__STDC__ != 1)
369 choke me
370 #endif
371 #endif
372 ],[
373         int test (int i, double x);
374         struct s1 {int (*f) (int a);};
375         struct s2 {int (*f) (double a);};],
376         [cf_cv_ansi_cc="$cf_arg"; break])
377 done
378 CFLAGS="$cf_save_CFLAGS"
379 CPPFLAGS="$cf_save_CPPFLAGS"
380 ])
381
382 if test "$cf_cv_ansi_cc" != "no"; then
383 if test ".$cf_cv_ansi_cc" != ".-DCC_HAS_PROTOS"; then
384         CF_ADD_CFLAGS($cf_cv_ansi_cc)
385 else
386         AC_DEFINE(CC_HAS_PROTOS)
387 fi
388 fi
389 ])dnl
390 dnl ---------------------------------------------------------------------------
391 dnl CF_ANSI_CC_REQD version: 4 updated: 2008/03/23 14:48:54
392 dnl ---------------
393 dnl For programs that must use an ANSI compiler, obtain compiler options that
394 dnl will make it recognize prototypes.  We'll do preprocessor checks in other
395 dnl macros, since tools such as unproto can fake prototypes, but only part of
396 dnl the preprocessor.
397 AC_DEFUN([CF_ANSI_CC_REQD],
398 [AC_REQUIRE([CF_ANSI_CC_CHECK])
399 if test "$cf_cv_ansi_cc" = "no"; then
400         AC_MSG_ERROR(
401 [Your compiler does not appear to recognize prototypes.
402 You have the following choices:
403         a. adjust your compiler options
404         b. get an up-to-date compiler
405         c. use a wrapper such as unproto])
406 fi
407 ])dnl
408 dnl ---------------------------------------------------------------------------
409 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
410 dnl -----------
411 dnl Check for suitable "ar" (archiver) options for updating an archive.
412 AC_DEFUN([CF_AR_FLAGS],[
413 AC_REQUIRE([CF_PROG_AR])
414
415 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
416         cf_cv_ar_flags=unknown
417         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
418         do
419
420                 # check if $ARFLAGS already contains this choice
421                 if test "x$ARFLAGS" != "x" ; then
422                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
423                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
424                                 cf_cv_ar_flags=
425                                 break
426                         fi
427                 fi
428
429                 rm -f conftest.$ac_cv_objext
430                 rm -f conftest.a
431
432                 cat >conftest.$ac_ext <<EOF
433 #line __oline__ "configure"
434 int     testdata[[3]] = { 123, 456, 789 };
435 EOF
436                 if AC_TRY_EVAL(ac_compile) ; then
437                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
438                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
439                         if test -f conftest.a ; then
440                                 cf_cv_ar_flags=$cf_ar_flags
441                                 break
442                         fi
443                 else
444                         CF_VERBOSE(cannot compile test-program)
445                         break
446                 fi
447         done
448         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
449 ])
450
451 if test -n "$ARFLAGS" ; then
452         if test -n "$cf_cv_ar_flags" ; then
453                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
454         fi
455 else
456         ARFLAGS=$cf_cv_ar_flags
457 fi
458
459 AC_SUBST(ARFLAGS)
460 ])
461 dnl ---------------------------------------------------------------------------
462 dnl CF_BUILD_CC version: 6 updated: 2006/10/14 15:23:15
463 dnl -----------
464 dnl If we're cross-compiling, allow the user to override the tools and their
465 dnl options.  The configure script is oriented toward identifying the host
466 dnl compiler, etc., but we need a build compiler to generate parts of the
467 dnl source.
468 dnl
469 dnl $1 = default for $CPPFLAGS
470 dnl $2 = default for $LIBS
471 AC_DEFUN([CF_BUILD_CC],[
472 AC_REQUIRE([CF_PROG_EXT])
473 if test "$cross_compiling" = yes ; then
474
475         # defaults that we might want to override
476         : ${BUILD_CFLAGS:=''}
477         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
478         : ${BUILD_LDFLAGS:=''}
479         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
480         : ${BUILD_EXEEXT:='$x'}
481         : ${BUILD_OBJEXT:='o'}
482
483         AC_ARG_WITH(build-cc,
484                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
485                 [BUILD_CC="$withval"],
486                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
487         AC_MSG_CHECKING(for native build C compiler)
488         AC_MSG_RESULT($BUILD_CC)
489
490         AC_MSG_CHECKING(for native build C preprocessor)
491         AC_ARG_WITH(build-cpp,
492                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
493                 [BUILD_CPP="$withval"],
494                 [BUILD_CPP='${BUILD_CC} -E'])
495         AC_MSG_RESULT($BUILD_CPP)
496
497         AC_MSG_CHECKING(for native build C flags)
498         AC_ARG_WITH(build-cflags,
499                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
500                 [BUILD_CFLAGS="$withval"])
501         AC_MSG_RESULT($BUILD_CFLAGS)
502
503         AC_MSG_CHECKING(for native build C preprocessor-flags)
504         AC_ARG_WITH(build-cppflags,
505                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
506                 [BUILD_CPPFLAGS="$withval"])
507         AC_MSG_RESULT($BUILD_CPPFLAGS)
508
509         AC_MSG_CHECKING(for native build linker-flags)
510         AC_ARG_WITH(build-ldflags,
511                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
512                 [BUILD_LDFLAGS="$withval"])
513         AC_MSG_RESULT($BUILD_LDFLAGS)
514
515         AC_MSG_CHECKING(for native build linker-libraries)
516         AC_ARG_WITH(build-libs,
517                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
518                 [BUILD_LIBS="$withval"])
519         AC_MSG_RESULT($BUILD_LIBS)
520
521         # this assumes we're on Unix.
522         BUILD_EXEEXT=
523         BUILD_OBJEXT=o
524
525         : ${BUILD_CC:='${CC}'}
526
527         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
528                 AC_MSG_ERROR([Cross-build requires two compilers.
529 Use --with-build-cc to specify the native compiler.])
530         fi
531
532 else
533         : ${BUILD_CC:='${CC}'}
534         : ${BUILD_CPP:='${CPP}'}
535         : ${BUILD_CFLAGS:='${CFLAGS}'}
536         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
537         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
538         : ${BUILD_LIBS:='${LIBS}'}
539         : ${BUILD_EXEEXT:='$x'}
540         : ${BUILD_OBJEXT:='o'}
541 fi
542
543 AC_SUBST(BUILD_CC)
544 AC_SUBST(BUILD_CPP)
545 AC_SUBST(BUILD_CFLAGS)
546 AC_SUBST(BUILD_CPPFLAGS)
547 AC_SUBST(BUILD_LDFLAGS)
548 AC_SUBST(BUILD_LIBS)
549 AC_SUBST(BUILD_EXEEXT)
550 AC_SUBST(BUILD_OBJEXT)
551 ])dnl
552 dnl ---------------------------------------------------------------------------
553 dnl CF_CFG_DEFAULTS version: 8 updated: 2011/06/04 20:09:13
554 dnl ---------------
555 dnl Determine the default configuration into which we'll install ncurses.  This
556 dnl can be overridden by the user's command-line options.  There's two items to
557 dnl look for:
558 dnl     1. the prefix (e.g., /usr)
559 dnl     2. the header files (e.g., /usr/include/ncurses)
560 dnl We'll look for a previous installation of ncurses and use the same defaults.
561 dnl
562 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
563 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
564 dnl programs from a vendor's.
565 AC_DEFUN([CF_CFG_DEFAULTS],
566 [
567 AC_MSG_CHECKING(for prefix)
568 if test "x$prefix" = "xNONE" ; then
569         case "$cf_cv_system_name" in
570                 # non-vendor systems don't have a conflict
571         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|k*bsd*-gnu)
572                 prefix=/usr
573                 ;;
574         *)      prefix=$ac_default_prefix
575                 ;;
576         esac
577 fi
578 AC_MSG_RESULT($prefix)
579
580 if test "x$prefix" = "xNONE" ; then
581 AC_MSG_CHECKING(for default include-directory)
582 test -n "$verbose" && echo 1>&AC_FD_MSG
583 for cf_symbol in \
584         $includedir \
585         $includedir/ncurses \
586         $prefix/include \
587         $prefix/include/ncurses \
588         /usr/local/include \
589         /usr/local/include/ncurses \
590         /usr/include \
591         /usr/include/ncurses
592 do
593         cf_dir=`eval echo $cf_symbol`
594         if test -f $cf_dir/curses.h ; then
595         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
596                 includedir="$cf_symbol"
597                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
598                 break
599         fi
600         fi
601         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
602 done
603 AC_MSG_RESULT($includedir)
604 fi
605 ])dnl
606 dnl ---------------------------------------------------------------------------
607 dnl CF_CHECK_CACHE version: 11 updated: 2008/03/23 14:45:59
608 dnl --------------
609 dnl Check if we're accidentally using a cache from a different machine.
610 dnl Derive the system name, as a check for reusing the autoconf cache.
611 dnl
612 dnl If we've packaged config.guess and config.sub, run that (since it does a
613 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
614 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
615 dnl which is useful in cross-compiles.
616 dnl
617 dnl Note: we would use $ac_config_sub, but that is one of the places where
618 dnl autoconf 2.5x broke compatibility with autoconf 2.13
619 AC_DEFUN([CF_CHECK_CACHE],
620 [
621 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
622         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
623         system_name="$host_os"
624 else
625         system_name="`(uname -s -r) 2>/dev/null`"
626         if test -z "$system_name" ; then
627                 system_name="`(hostname) 2>/dev/null`"
628         fi
629 fi
630 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name")
631 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
632
633 test -z "$system_name" && system_name="$cf_cv_system_name"
634 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
635
636 if test ".$system_name" != ".$cf_cv_system_name" ; then
637         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
638         AC_MSG_ERROR("Please remove config.cache and try again.")
639 fi
640 ])dnl
641 dnl ---------------------------------------------------------------------------
642 dnl CF_CURSES_HEADER version: 3 updated: 2011/05/01 19:47:45
643 dnl ----------------
644 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
645 dnl variations of ncurses' installs.
646 dnl
647 dnl $1 = ncurses when looking for ncurses, or is empty
648 AC_DEFUN([CF_CURSES_HEADER],[
649 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
650 cf_cv_ncurses_header=none
651 for cf_header in ifelse($1,,,[ \
652     $1/ncurses.h \
653         $1/curses.h]) \
654         ncurses.h \
655         curses.h ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
656 do
657 AC_TRY_COMPILE([#include <${cf_header}>],
658         [initscr(); tgoto("?", 0,0)],
659         [cf_cv_ncurses_header=$cf_header; break],[])
660 done
661 ])
662
663 if test "$cf_cv_ncurses_header" = none ; then
664         AC_MSG_ERROR(No curses header-files found)
665 fi
666
667 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
668 AC_CHECK_HEADERS($cf_cv_ncurses_header)
669 ])dnl
670 dnl ---------------------------------------------------------------------------
671 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
672 dnl ----------
673 dnl "dirname" is not portable, so we fake it with a shell script.
674 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
675 dnl ---------------------------------------------------------------------------
676 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
677 dnl ---------------
678 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
679 dnl prefer a standard location, and use -L options only if we do not find the
680 dnl library in the standard library location(s).
681 dnl     $1 = library name
682 dnl     $2 = library class, usually the same as library name
683 dnl     $3 = includes
684 dnl     $4 = code fragment to compile/link
685 dnl     $5 = corresponding function-name
686 dnl     $6 = flag, nonnull if failure should not cause an error-exit
687 dnl
688 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
689 dnl to use a -L option.
690 AC_DEFUN([CF_FIND_LIBRARY],
691 [
692         eval 'cf_cv_have_lib_'$1'=no'
693         cf_libdir=""
694         AC_CHECK_FUNC($5,
695                 eval 'cf_cv_have_lib_'$1'=yes',[
696                 cf_save_LIBS="$LIBS"
697                 AC_MSG_CHECKING(for $5 in -l$1)
698                 LIBS="-l$1 $LIBS"
699                 AC_TRY_LINK([$3],[$4],
700                         [AC_MSG_RESULT(yes)
701                          eval 'cf_cv_have_lib_'$1'=yes'
702                         ],
703                         [AC_MSG_RESULT(no)
704                         CF_LIBRARY_PATH(cf_search,$2)
705                         for cf_libdir in $cf_search
706                         do
707                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
708                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
709                                 AC_TRY_LINK([$3],[$4],
710                                         [AC_MSG_RESULT(yes)
711                                          eval 'cf_cv_have_lib_'$1'=yes'
712                                          break],
713                                         [AC_MSG_RESULT(no)
714                                          LIBS="$cf_save_LIBS"])
715                         done
716                         ])
717                 ])
718 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
719 ifelse($6,,[
720 if test $cf_found_library = no ; then
721         AC_MSG_ERROR(Cannot link $1 library)
722 fi
723 ])
724 ])dnl
725 dnl ---------------------------------------------------------------------------
726 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
727 dnl ---------------
728 dnl Find a library (specifically the linkage used in the code fragment),
729 dnl searching for it if it is not already in the library path.
730 dnl See also CF_ADD_SEARCHPATH.
731 dnl
732 dnl Parameters (4-on are optional):
733 dnl     $1 = headers for library entrypoint
734 dnl     $2 = code fragment for library entrypoint
735 dnl     $3 = the library name without the "-l" option or ".so" suffix.
736 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
737 dnl     $5 = action to perform if not successful
738 dnl     $6 = module name, if not the same as the library name
739 dnl     $7 = extra libraries
740 dnl
741 dnl Sets these variables:
742 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
743 dnl     $cf_cv_header_path_$3 - include-directory if needed
744 dnl     $cf_cv_library_path_$3 - library-directory if needed
745 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
746 AC_DEFUN([CF_FIND_LINKAGE],[
747
748 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
749 # will be set on completion of the AC_TRY_LINK below.
750 cf_cv_header_path_$3=
751 cf_cv_library_path_$3=
752
753 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
754
755 cf_save_LIBS="$LIBS"
756
757 AC_TRY_LINK([$1],[$2],[
758         cf_cv_find_linkage_$3=yes
759         cf_cv_header_path_$3=/usr/include
760         cf_cv_library_path_$3=/usr/lib
761 ],[
762
763 LIBS="-l$3 $7 $cf_save_LIBS"
764
765 AC_TRY_LINK([$1],[$2],[
766         cf_cv_find_linkage_$3=yes
767         cf_cv_header_path_$3=/usr/include
768         cf_cv_library_path_$3=/usr/lib
769         cf_cv_library_file_$3="-l$3"
770 ],[
771         cf_cv_find_linkage_$3=no
772         LIBS="$cf_save_LIBS"
773
774     CF_VERBOSE(find linkage for $3 library)
775     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
776
777     cf_save_CPPFLAGS="$CPPFLAGS"
778     cf_test_CPPFLAGS="$CPPFLAGS"
779
780     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
781     for cf_cv_header_path_$3 in $cf_search
782     do
783       if test -d $cf_cv_header_path_$3 ; then
784         CF_VERBOSE(... testing $cf_cv_header_path_$3)
785         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
786         AC_TRY_COMPILE([$1],[$2],[
787             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
788             cf_cv_find_linkage_$3=maybe
789             cf_test_CPPFLAGS="$CPPFLAGS"
790             break],[
791             CPPFLAGS="$cf_save_CPPFLAGS"
792             ])
793       fi
794     done
795
796     if test "$cf_cv_find_linkage_$3" = maybe ; then
797
798       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
799
800       cf_save_LIBS="$LIBS"
801       cf_save_LDFLAGS="$LDFLAGS"
802
803       ifelse([$6],,,[
804         CPPFLAGS="$cf_test_CPPFLAGS"
805         LIBS="-l$3 $7 $cf_save_LIBS"
806         AC_TRY_LINK([$1],[$2],[
807             CF_VERBOSE(... found $3 library in system)
808             cf_cv_find_linkage_$3=yes])
809             CPPFLAGS="$cf_save_CPPFLAGS"
810             LIBS="$cf_save_LIBS"
811             ])
812
813       if test "$cf_cv_find_linkage_$3" != yes ; then
814         CF_LIBRARY_PATH(cf_search,$3)
815         for cf_cv_library_path_$3 in $cf_search
816         do
817           if test -d $cf_cv_library_path_$3 ; then
818             CF_VERBOSE(... testing $cf_cv_library_path_$3)
819             CPPFLAGS="$cf_test_CPPFLAGS"
820             LIBS="-l$3 $7 $cf_save_LIBS"
821             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
822             AC_TRY_LINK([$1],[$2],[
823                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
824                 cf_cv_find_linkage_$3=yes
825                 cf_cv_library_file_$3="-l$3"
826                 break],[
827                 CPPFLAGS="$cf_save_CPPFLAGS"
828                 LIBS="$cf_save_LIBS"
829                 LDFLAGS="$cf_save_LDFLAGS"
830                 ])
831           fi
832         done
833         CPPFLAGS="$cf_save_CPPFLAGS"
834         LDFLAGS="$cf_save_LDFLAGS"
835       fi
836
837     else
838       cf_cv_find_linkage_$3=no
839     fi
840     ],$7)
841 ])
842
843 LIBS="$cf_save_LIBS"
844
845 if test "$cf_cv_find_linkage_$3" = yes ; then
846 ifelse([$4],,[
847         CF_ADD_INCDIR($cf_cv_header_path_$3)
848         CF_ADD_LIBDIR($cf_cv_library_path_$3)
849         CF_ADD_LIB($3)
850 ],[$4])
851 else
852 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
853 fi
854 ])dnl
855 dnl ---------------------------------------------------------------------------
856 dnl CF_GCC_ATTRIBUTES version: 14 updated: 2010/10/23 15:52:32
857 dnl -----------------
858 dnl Test for availability of useful gcc __attribute__ directives to quiet
859 dnl compiler warnings.  Though useful, not all are supported -- and contrary
860 dnl to documentation, unrecognized directives cause older compilers to barf.
861 AC_DEFUN([CF_GCC_ATTRIBUTES],
862 [
863 if test "$GCC" = yes
864 then
865 cat > conftest.i <<EOF
866 #ifndef GCC_PRINTF
867 #define GCC_PRINTF 0
868 #endif
869 #ifndef GCC_SCANF
870 #define GCC_SCANF 0
871 #endif
872 #ifndef GCC_NORETURN
873 #define GCC_NORETURN /* nothing */
874 #endif
875 #ifndef GCC_UNUSED
876 #define GCC_UNUSED /* nothing */
877 #endif
878 EOF
879 if test "$GCC" = yes
880 then
881         AC_CHECKING([for $CC __attribute__ directives])
882 cat > conftest.$ac_ext <<EOF
883 #line __oline__ "${as_me:-configure}"
884 #include "confdefs.h"
885 #include "conftest.h"
886 #include "conftest.i"
887 #if     GCC_PRINTF
888 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
889 #else
890 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
891 #endif
892 #if     GCC_SCANF
893 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
894 #else
895 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
896 #endif
897 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
898 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
899 extern void foo(void) GCC_NORETURN;
900 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
901 EOF
902         cf_printf_attribute=no
903         cf_scanf_attribute=no
904         for cf_attribute in scanf printf unused noreturn
905         do
906                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
907                 cf_directive="__attribute__(($cf_attribute))"
908                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
909
910                 case $cf_attribute in #(vi
911                 printf) #(vi
912                         cf_printf_attribute=yes
913                         cat >conftest.h <<EOF
914 #define GCC_$cf_ATTRIBUTE 1
915 EOF
916                         ;;
917                 scanf) #(vi
918                         cf_scanf_attribute=yes
919                         cat >conftest.h <<EOF
920 #define GCC_$cf_ATTRIBUTE 1
921 EOF
922                         ;;
923                 *) #(vi
924                         cat >conftest.h <<EOF
925 #define GCC_$cf_ATTRIBUTE $cf_directive
926 EOF
927                         ;;
928                 esac
929
930                 if AC_TRY_EVAL(ac_compile); then
931                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
932                         cat conftest.h >>confdefs.h
933                         case $cf_attribute in #(vi
934                         printf) #(vi
935                                 if test "$cf_printf_attribute" = no ; then
936                                         cat >>confdefs.h <<EOF
937 #define GCC_PRINTFLIKE(fmt,var) /* nothing */
938 EOF
939                                 else
940                                         cat >>confdefs.h <<EOF
941 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
942 EOF
943                                 fi
944                                 ;;
945                         scanf) #(vi
946                                 if test "$cf_scanf_attribute" = no ; then
947                                         cat >>confdefs.h <<EOF
948 #define GCC_SCANFLIKE(fmt,var) /* nothing */
949 EOF
950                                 else
951                                         cat >>confdefs.h <<EOF
952 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
953 EOF
954                                 fi
955                                 ;;
956                         esac
957                 fi
958         done
959 else
960         fgrep define conftest.i >>confdefs.h
961 fi
962 rm -rf conftest*
963 fi
964 ])dnl
965 dnl ---------------------------------------------------------------------------
966 dnl CF_GCC_VERSION version: 5 updated: 2010/04/24 11:02:31
967 dnl --------------
968 dnl Find version of gcc
969 AC_DEFUN([CF_GCC_VERSION],[
970 AC_REQUIRE([AC_PROG_CC])
971 GCC_VERSION=none
972 if test "$GCC" = yes ; then
973         AC_MSG_CHECKING(version of $CC)
974         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
975         test -z "$GCC_VERSION" && GCC_VERSION=unknown
976         AC_MSG_RESULT($GCC_VERSION)
977 fi
978 ])dnl
979 dnl ---------------------------------------------------------------------------
980 dnl CF_GCC_WARNINGS version: 27 updated: 2010/10/23 15:52:32
981 dnl ---------------
982 dnl Check if the compiler supports useful warning options.  There's a few that
983 dnl we don't use, simply because they're too noisy:
984 dnl
985 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
986 dnl     -Wredundant-decls (system headers make this too noisy)
987 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
988 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
989 dnl             is enabled for ncurses using "--enable-const".
990 dnl     -pedantic
991 dnl
992 dnl Parameter:
993 dnl     $1 is an optional list of gcc warning flags that a particular
994 dnl             application might want to use, e.g., "no-unused" for
995 dnl             -Wno-unused
996 dnl Special:
997 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
998 dnl
999 AC_DEFUN([CF_GCC_WARNINGS],
1000 [
1001 AC_REQUIRE([CF_GCC_VERSION])
1002 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1003
1004 cat > conftest.$ac_ext <<EOF
1005 #line __oline__ "${as_me:-configure}"
1006 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1007 EOF
1008
1009 if test "$INTEL_COMPILER" = yes
1010 then
1011 # The "-wdXXX" options suppress warnings:
1012 # remark #1419: external declaration in primary source file
1013 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1014 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1015 # remark #193: zero used for undefined preprocessing identifier
1016 # remark #593: variable "curs_sb_left_arrow" was set but never used
1017 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1018 # remark #869: parameter "tw" was never referenced
1019 # remark #981: operands are evaluated in unspecified order
1020 # warning #279: controlling expression is constant
1021
1022         AC_CHECKING([for $CC warning options])
1023         cf_save_CFLAGS="$CFLAGS"
1024         EXTRA_CFLAGS="-Wall"
1025         for cf_opt in \
1026                 wd1419 \
1027                 wd1683 \
1028                 wd1684 \
1029                 wd193 \
1030                 wd593 \
1031                 wd279 \
1032                 wd810 \
1033                 wd869 \
1034                 wd981
1035         do
1036                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1037                 if AC_TRY_EVAL(ac_compile); then
1038                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1039                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1040                 fi
1041         done
1042         CFLAGS="$cf_save_CFLAGS"
1043
1044 elif test "$GCC" = yes
1045 then
1046         AC_CHECKING([for $CC warning options])
1047         cf_save_CFLAGS="$CFLAGS"
1048         EXTRA_CFLAGS=
1049         cf_warn_CONST=""
1050         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1051         for cf_opt in W Wall \
1052                 Wbad-function-cast \
1053                 Wcast-align \
1054                 Wcast-qual \
1055                 Winline \
1056                 Wmissing-declarations \
1057                 Wmissing-prototypes \
1058                 Wnested-externs \
1059                 Wpointer-arith \
1060                 Wshadow \
1061                 Wstrict-prototypes \
1062                 Wundef $cf_warn_CONST $1
1063         do
1064                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1065                 if AC_TRY_EVAL(ac_compile); then
1066                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1067                         case $cf_opt in #(vi
1068                         Wcast-qual) #(vi
1069                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1070                                 ;;
1071                         Winline) #(vi
1072                                 case $GCC_VERSION in
1073                                 [[34]].*)
1074                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1075                                         continue;;
1076                                 esac
1077                                 ;;
1078                         esac
1079                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1080                 fi
1081         done
1082         CFLAGS="$cf_save_CFLAGS"
1083 fi
1084 rm -rf conftest*
1085
1086 AC_SUBST(EXTRA_CFLAGS)
1087 ])dnl
1088 dnl ---------------------------------------------------------------------------
1089 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
1090 dnl ----------------
1091 AC_DEFUN([CF_GNAT_GENERICS],
1092 [
1093 AC_REQUIRE([CF_GNAT_VERSION])
1094
1095 AC_MSG_CHECKING(if GNAT supports generics)
1096 case $cf_gnat_version in #(vi
1097 3.[[1-9]]*|[[4-9]].*) #(vi
1098         cf_gnat_generics=yes
1099         ;;
1100 *)
1101         cf_gnat_generics=no
1102         ;;
1103 esac
1104 AC_MSG_RESULT($cf_gnat_generics)
1105
1106 if test "$cf_gnat_generics" = yes
1107 then
1108         cf_compile_generics=generics
1109         cf_generic_objects="\${GENOBJS}"
1110 else
1111         cf_compile_generics=
1112         cf_generic_objects=
1113 fi
1114
1115 AC_SUBST(cf_compile_generics)
1116 AC_SUBST(cf_generic_objects)
1117 ])dnl
1118 dnl ---------------------------------------------------------------------------
1119 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
1120 dnl --------------------
1121 dnl Check if the gnat pragma "Unreferenced" works.
1122 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
1123 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
1124 CF_GNAT_TRY_LINK([procedure conftest;],
1125 [with Text_IO;
1126 with GNAT.OS_Lib;
1127 procedure conftest is
1128    test : Integer;
1129    pragma Unreferenced (test);
1130 begin
1131    test := 1;
1132    Text_IO.Put ("Hello World");
1133    Text_IO.New_Line;
1134    GNAT.OS_Lib.OS_Exit (0);
1135 end conftest;],
1136         [cf_cv_pragma_unreferenced=yes],
1137         [cf_cv_pragma_unreferenced=no])])
1138
1139 # if the pragma is supported, use it (needed in the Trace code).
1140 if test $cf_cv_pragma_unreferenced = yes ; then
1141         PRAGMA_UNREF=TRUE
1142 else
1143         PRAGMA_UNREF=FALSE
1144 fi
1145 AC_SUBST(PRAGMA_UNREF)
1146 ])dnl
1147 dnl ---------------------------------------------------------------------------
1148 dnl CF_GNAT_PROJECTS version: 2 updated: 2011/03/23 20:24:41
1149 dnl ----------------
1150 dnl GNAT projects are configured with ".gpr" project files.
1151 dnl GNAT libraries are a further development, using the project feature.
1152 AC_DEFUN([CF_GNAT_PROJECTS],
1153 [
1154 AC_REQUIRE([CF_GNAT_VERSION])
1155
1156 cf_gnat_libraries=no
1157 cf_gnat_projects=no
1158
1159 AC_MSG_CHECKING(if GNAT supports project files)
1160 case $cf_gnat_version in #(vi
1161 3.[[0-9]]*) #(vi
1162         ;;
1163 *)
1164         case $cf_cv_system_name in #(vi
1165         cygwin*) #(vi
1166                 ;;
1167         *)
1168                 mkdir conftest.src conftest.bin conftest.lib
1169                 cd conftest.src
1170                 rm -rf conftest* *~conftest*
1171                 cat >>library.gpr <<CF_EOF
1172 project Library is
1173   Kind := External ("LIB_KIND");
1174   for Library_Name use "ConfTest";
1175   for Object_Dir use ".";
1176   for Library_ALI_Dir use External("LIBRARY_DIR");
1177   for Library_Version use External ("SONAME");
1178   for Library_Kind use Kind;
1179   for Library_Dir use External("BUILD_DIR");
1180   Source_Dir := External ("SOURCE_DIR");
1181   for Source_Dirs use (Source_Dir);
1182   package Compiler is
1183      for Default_Switches ("Ada") use
1184        ("-g",
1185         "-O2",
1186         "-gnatafno",
1187         "-gnatVa",   -- All validity checks
1188         "-gnatwa");  -- Activate all optional errors
1189   end Compiler;
1190 end Library;
1191 CF_EOF
1192                 cat >>confpackage.ads <<CF_EOF
1193 package ConfPackage is
1194    procedure conftest;
1195 end ConfPackage;
1196 CF_EOF
1197                 cat >>confpackage.adb <<CF_EOF
1198 with Text_IO;
1199 package body ConfPackage is
1200    procedure conftest is
1201    begin
1202       Text_IO.Put ("Hello World");
1203       Text_IO.New_Line;
1204    end conftest;
1205 end ConfPackage;
1206 CF_EOF
1207                 if ( $cf_ada_make $ADAFLAGS \
1208                                 -Plibrary.gpr \
1209                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
1210                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
1211                                 -XSOURCE_DIR=`pwd` \
1212                                 -XSONAME=libConfTest.so.1 \
1213                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1214                         cf_gnat_projects=yes
1215                 fi
1216                 cd ..
1217                 if test -f conftest.lib/confpackage.ali
1218                 then
1219                         cf_gnat_libraries=yes
1220                 fi
1221                 rm -rf conftest* *~conftest*
1222                 ;;
1223         esac
1224         ;;
1225 esac
1226 AC_MSG_RESULT($cf_gnat_projects)
1227
1228 if test $cf_gnat_projects = yes
1229 then
1230         AC_MSG_CHECKING(if GNAT supports libraries)
1231         AC_MSG_RESULT($cf_gnat_libraries)
1232 fi
1233
1234 if test "$cf_gnat_projects" = yes
1235 then
1236         USE_OLD_MAKERULES="#"
1237         USE_GNAT_PROJECTS=""
1238 else
1239         USE_OLD_MAKERULES=""
1240         USE_GNAT_PROJECTS="#"
1241 fi
1242
1243 if test "$cf_gnat_libraries" = yes
1244 then
1245         USE_GNAT_LIBRARIES=""
1246 else
1247         USE_GNAT_LIBRARIES="#"
1248 fi
1249
1250 AC_SUBST(USE_OLD_MAKERULES)
1251 AC_SUBST(USE_GNAT_PROJECTS)
1252 AC_SUBST(USE_GNAT_LIBRARIES)
1253 ])dnl
1254 dnl ---------------------------------------------------------------------------
1255 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
1256 dnl --------------
1257 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1258 dnl is noted that gnat may compile a tasking unit even for configurations which
1259 dnl fail at runtime.
1260 AC_DEFUN([CF_GNAT_SIGINT],[
1261 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1262 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1263
1264 package ConfTest is
1265
1266    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1267    pragma Unreserve_All_Interrupts;
1268    pragma Warnings (On);
1269
1270    protected Process is
1271       procedure Stop;
1272       function Continue return Boolean;
1273       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1274    private
1275       Done : Boolean := False;
1276    end Process;
1277
1278 end ConfTest;],
1279 [package body ConfTest is
1280    protected body Process is
1281       procedure Stop is
1282       begin
1283          Done := True;
1284       end Stop;
1285       function Continue return Boolean is
1286       begin
1287          return not Done;
1288       end Continue;
1289    end Process;
1290 end ConfTest;],
1291         [cf_cv_gnat_sigint=yes],
1292         [cf_cv_gnat_sigint=no])])
1293
1294 if test $cf_cv_gnat_sigint = yes ; then
1295         USE_GNAT_SIGINT=""
1296 else
1297         USE_GNAT_SIGINT="#"
1298 fi
1299 AC_SUBST(USE_GNAT_SIGINT)
1300 ])dnl
1301 dnl ---------------------------------------------------------------------------
1302 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
1303 dnl ----------------
1304 dnl Verify that a test program compiles/links with GNAT.
1305 dnl $cf_ada_make is set to the program that compiles/links
1306 dnl $ADAFLAGS may be set to the GNAT flags.
1307 dnl
1308 dnl $1 is the text of the spec
1309 dnl $2 is the text of the body
1310 dnl $3 is the shell command to execute if successful
1311 dnl $4 is the shell command to execute if not successful
1312 AC_DEFUN([CF_GNAT_TRY_LINK],
1313 [
1314 rm -rf conftest* *~conftest*
1315 cat >>conftest.ads <<CF_EOF
1316 $1
1317 CF_EOF
1318 cat >>conftest.adb <<CF_EOF
1319 $2
1320 CF_EOF
1321 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1322 ifelse($3,,      :,[      $3])
1323 ifelse($4,,,[else
1324    $4])
1325 fi
1326 rm -rf conftest* *~conftest*
1327 ])dnl
1328 dnl ---------------------------------------------------------------------------
1329 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
1330 dnl ---------------
1331 dnl Verify that a test program compiles and runs with GNAT
1332 dnl $cf_ada_make is set to the program that compiles/links
1333 dnl $ADAFLAGS may be set to the GNAT flags.
1334 dnl
1335 dnl $1 is the text of the spec
1336 dnl $2 is the text of the body
1337 dnl $3 is the shell command to execute if successful
1338 dnl $4 is the shell command to execute if not successful
1339 AC_DEFUN([CF_GNAT_TRY_RUN],
1340 [
1341 rm -rf conftest* *~conftest*
1342 cat >>conftest.ads <<CF_EOF
1343 $1
1344 CF_EOF
1345 cat >>conftest.adb <<CF_EOF
1346 $2
1347 CF_EOF
1348 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1349    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1350 ifelse($3,,      :,[      $3])
1351 ifelse($4,,,[   else
1352       $4])
1353    fi
1354 ifelse($4,,,[else
1355    $4])
1356 fi
1357 rm -rf conftest* *~conftest*
1358 ])dnl
1359 dnl ---------------------------------------------------------------------------
1360 dnl CF_GNAT_VERSION version: 17 updated: 2011/03/23 20:24:41
1361 dnl ---------------
1362 dnl Verify version of GNAT.
1363 AC_DEFUN([CF_GNAT_VERSION],
1364 [
1365 AC_MSG_CHECKING(for gnat version)
1366 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
1367         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1368     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1369 AC_MSG_RESULT($cf_gnat_version)
1370
1371 case $cf_gnat_version in #(vi
1372 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*) #(vi
1373         cf_cv_prog_gnat_correct=yes
1374         ;;
1375 *)
1376         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1377         cf_cv_prog_gnat_correct=no
1378         ;;
1379 esac
1380 ])
1381 dnl ---------------------------------------------------------------------------
1382 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
1383 dnl -------------
1384 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1385 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1386 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1387 dnl since it is interwoven with GNU extensions.
1388 dnl
1389 dnl Well, yes we could work around it...
1390 AC_DEFUN([CF_GNU_SOURCE],
1391 [
1392 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1393 AC_TRY_COMPILE([#include <sys/types.h>],[
1394 #ifndef _XOPEN_SOURCE
1395 make an error
1396 #endif],
1397         [cf_cv_gnu_source=no],
1398         [cf_save="$CPPFLAGS"
1399          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1400          AC_TRY_COMPILE([#include <sys/types.h>],[
1401 #ifdef _XOPEN_SOURCE
1402 make an error
1403 #endif],
1404         [cf_cv_gnu_source=no],
1405         [cf_cv_gnu_source=yes])
1406         CPPFLAGS="$cf_save"
1407         ])
1408 ])
1409 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1410 ])dnl
1411 dnl ---------------------------------------------------------------------------
1412 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
1413 dnl --------------
1414 dnl Construct a search-list of directories for a nonstandard header-file
1415 dnl
1416 dnl Parameters
1417 dnl     $1 = the variable to return as result
1418 dnl     $2 = the package name
1419 AC_DEFUN([CF_HEADER_PATH],
1420 [
1421 $1=
1422
1423 # collect the current set of include-directories from compiler flags
1424 cf_header_path_list=""
1425 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1426         for cf_header_path in $CPPFLAGS $CFLAGS
1427         do
1428                 case $cf_header_path in #(vi
1429                 -I*)
1430                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1431                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1432                         cf_header_path_list="$cf_header_path_list [$]$1"
1433                         ;;
1434                 esac
1435         done
1436 fi
1437
1438 # add the variations for the package we are looking for
1439 CF_SUBDIR_PATH($1,$2,include)
1440
1441 test "$includedir" != NONE && \
1442 test "$includedir" != "/usr/include" && \
1443 test -d "$includedir" && {
1444         test -d $includedir &&    $1="[$]$1 $includedir"
1445         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1446 }
1447
1448 test "$oldincludedir" != NONE && \
1449 test "$oldincludedir" != "/usr/include" && \
1450 test -d "$oldincludedir" && {
1451         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1452         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1453 }
1454
1455 $1="[$]$1 $cf_header_path_list"
1456 ])dnl
1457 dnl ---------------------------------------------------------------------------
1458 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1459 dnl ---------------
1460 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1461 AC_DEFUN([CF_HELP_MESSAGE],
1462 [AC_DIVERT_HELP([$1])dnl
1463 ])dnl
1464 dnl ---------------------------------------------------------------------------
1465 dnl CF_INCLUDE_DIRS version: 6 updated: 2009/01/06 19:37:40
1466 dnl ---------------
1467 dnl Construct the list of include-options according to whether we're building
1468 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
1469 dnl with gcc, don't append the includedir if it happens to be /usr/include,
1470 dnl since that usually breaks gcc's shadow-includes.
1471 AC_DEFUN([CF_INCLUDE_DIRS],
1472 [
1473 CPPFLAGS="$CPPFLAGS -I. -I../include"
1474 if test "$srcdir" != "."; then
1475         CPPFLAGS="$CPPFLAGS -I\${srcdir}/../include"
1476 fi
1477 if test "$GCC" != yes; then
1478         CPPFLAGS="$CPPFLAGS -I\${includedir}"
1479 elif test "$includedir" != "/usr/include"; then
1480         if test "$includedir" = '${prefix}/include' ; then
1481                 if test $prefix != /usr ; then
1482                         CPPFLAGS="$CPPFLAGS -I\${includedir}"
1483                 fi
1484         else
1485                 CPPFLAGS="$CPPFLAGS -I\${includedir}"
1486         fi
1487 fi
1488 AC_SUBST(CPPFLAGS)
1489 ])dnl
1490 dnl ---------------------------------------------------------------------------
1491 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
1492 dnl -----------------
1493 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1494 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1495 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1496 dnl
1497 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1498 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1499 dnl the wrappers for gcc and g++ warnings.
1500 dnl
1501 dnl $1 = GCC (default) or GXX
1502 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1503 dnl $3 = CFLAGS (default) or CXXFLAGS
1504 AC_DEFUN([CF_INTEL_COMPILER],[
1505 ifelse([$2],,INTEL_COMPILER,[$2])=no
1506
1507 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1508         case $host_os in
1509         linux*|gnu*)
1510                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1511                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1512                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1513                 AC_TRY_COMPILE([],[
1514 #ifdef __INTEL_COMPILER
1515 #else
1516 make an error
1517 #endif
1518 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1519 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
1520 ],[])
1521                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1522                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1523                 ;;
1524         esac
1525 fi
1526 ])dnl
1527 dnl ---------------------------------------------------------------------------
1528 dnl CF_LARGEFILE version: 7 updated: 2007/06/02 11:58:50
1529 dnl ------------
1530 dnl Add checks for large file support.
1531 AC_DEFUN([CF_LARGEFILE],[
1532 ifdef([AC_FUNC_FSEEKO],[
1533     AC_SYS_LARGEFILE
1534     if test "$enable_largefile" != no ; then
1535         AC_FUNC_FSEEKO
1536
1537         # Normally we would collect these definitions in the config.h,
1538         # but (like _XOPEN_SOURCE), some environments rely on having these
1539         # defined before any of the system headers are included.  Another
1540         # case comes up with C++, e.g., on AIX the compiler compiles the
1541         # header files by themselves before looking at the body files it is
1542         # told to compile.  For ncurses, those header files do not include
1543         # the config.h
1544         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
1545         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
1546         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
1547
1548         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
1549                 AC_TRY_COMPILE([
1550 #include <sys/types.h>
1551 #include <dirent.h>
1552                 ],[
1553                 /* if transitional largefile support is setup, this is true */
1554                 extern struct dirent64 * readdir(DIR *);
1555                 struct dirent64 *x = readdir((DIR *)0);
1556                 struct dirent *y = readdir((DIR *)0);
1557                 int z = x - y;
1558                 ],
1559                 [cf_cv_struct_dirent64=yes],
1560                 [cf_cv_struct_dirent64=no])
1561         ])
1562         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64)
1563     fi
1564 ])
1565 ])
1566 dnl ---------------------------------------------------------------------------
1567 dnl CF_LD_RPATH_OPT version: 4 updated: 2011/06/04 20:09:13
1568 dnl ---------------
1569 dnl For the given system and compiler, find the compiler flags to pass to the
1570 dnl loader to use the "rpath" feature.
1571 AC_DEFUN([CF_LD_RPATH_OPT],
1572 [
1573 AC_REQUIRE([CF_CHECK_CACHE])
1574
1575 LD_RPATH_OPT=
1576 AC_MSG_CHECKING(for an rpath option)
1577 case $cf_cv_system_name in #(vi
1578 irix*) #(vi
1579         if test "$GCC" = yes; then
1580                 LD_RPATH_OPT="-Wl,-rpath,"
1581         else
1582                 LD_RPATH_OPT="-rpath "
1583         fi
1584         ;;
1585 linux*|gnu*|k*bsd*-gnu) #(vi
1586         LD_RPATH_OPT="-Wl,-rpath,"
1587         ;;
1588 openbsd[[2-9]].*|mirbsd*) #(vi
1589         LD_RPATH_OPT="-Wl,-rpath,"
1590         ;;
1591 freebsd*) #(vi
1592         LD_RPATH_OPT="-rpath "
1593         ;;
1594 netbsd*) #(vi
1595         LD_RPATH_OPT="-Wl,-rpath,"
1596         ;;
1597 osf*|mls+*) #(vi
1598         LD_RPATH_OPT="-rpath "
1599         ;;
1600 solaris2*) #(vi
1601         LD_RPATH_OPT="-R"
1602         ;;
1603 *)
1604         ;;
1605 esac
1606 AC_MSG_RESULT($LD_RPATH_OPT)
1607
1608 case "x$LD_RPATH_OPT" in #(vi
1609 x-R*)
1610         AC_MSG_CHECKING(if we need a space after rpath option)
1611         cf_save_LIBS="$LIBS"
1612         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1613         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1614         LIBS="$cf_save_LIBS"
1615         AC_MSG_RESULT($cf_rpath_space)
1616         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1617         ;;
1618 esac
1619 ])dnl
1620 dnl ---------------------------------------------------------------------------
1621 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
1622 dnl ---------------
1623 dnl Construct a search-list of directories for a nonstandard library-file
1624 dnl
1625 dnl Parameters
1626 dnl     $1 = the variable to return as result
1627 dnl     $2 = the package name
1628 AC_DEFUN([CF_LIBRARY_PATH],
1629 [
1630 $1=
1631 cf_library_path_list=""
1632 if test -n "${LDFLAGS}${LIBS}" ; then
1633         for cf_library_path in $LDFLAGS $LIBS
1634         do
1635                 case $cf_library_path in #(vi
1636                 -L*)
1637                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1638                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1639                         cf_library_path_list="$cf_library_path_list [$]$1"
1640                         ;;
1641                 esac
1642         done
1643 fi
1644
1645 CF_SUBDIR_PATH($1,$2,lib)
1646
1647 $1="$cf_library_path_list [$]$1"
1648 ])dnl
1649 dnl ---------------------------------------------------------------------------
1650 dnl CF_LIB_PREFIX version: 8 updated: 2008/09/13 11:34:16
1651 dnl -------------
1652 dnl Compute the library-prefix for the given host system
1653 dnl $1 = variable to set
1654 AC_DEFUN([CF_LIB_PREFIX],
1655 [
1656         case $cf_cv_system_name in #(vi
1657         OS/2*|os2*) #(vi
1658         LIB_PREFIX=''
1659         ;;
1660         *)      LIB_PREFIX='lib'
1661         ;;
1662         esac
1663 ifelse($1,,,[$1=$LIB_PREFIX])
1664         AC_SUBST(LIB_PREFIX)
1665 ])dnl
1666 dnl ---------------------------------------------------------------------------
1667 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
1668 dnl -------------
1669 dnl Find the and soname for the given shared library.  Set the cache variable
1670 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
1671 dnl variable to "unknown".
1672 dnl
1673 dnl $1 = headers
1674 dnl $2 = code
1675 dnl $3 = library name
1676 AC_DEFUN([CF_LIB_SONAME],
1677 [
1678 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
1679
1680 cf_cv_$3_soname=unknown
1681 if test "$cross_compiling" != yes ; then
1682 cat >conftest.$ac_ext <<CF_EOF
1683 $1
1684 int main()
1685 {
1686 $2
1687         ${cf_cv_main_return:-return}(0);
1688 }
1689 CF_EOF
1690 cf_save_LIBS="$LIBS"
1691         CF_ADD_LIB($3)
1692         if AC_TRY_EVAL(ac_compile) ; then
1693                 if AC_TRY_EVAL(ac_link) ; then
1694                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
1695                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
1696                 fi
1697         fi
1698 rm -rf conftest*
1699 LIBS="$cf_save_LIBS"
1700 fi
1701 ])
1702 ])
1703 dnl ---------------------------------------------------------------------------
1704 dnl CF_LIB_SUFFIX version: 17 updated: 2011/07/02 15:36:04
1705 dnl -------------
1706 dnl Compute the library file-suffix from the given model name
1707 dnl $1 = model name
1708 dnl $2 = variable to set (the nominal library suffix)
1709 dnl $3 = dependency variable to set (actual filename)
1710 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1711 AC_DEFUN([CF_LIB_SUFFIX],
1712 [
1713         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
1714         case $1 in #(vi
1715         libtool) #(vi
1716                 $2='.la'
1717                 $3=[$]$2
1718                 ;;
1719         normal) #(vi
1720                 $2='.a'
1721                 $3=[$]$2
1722                 ;;
1723         debug) #(vi
1724                 $2='_g.a'
1725                 $3=[$]$2
1726                 ;;
1727         profile) #(vi
1728                 $2='_p.a'
1729                 $3=[$]$2
1730                 ;;
1731         shared) #(vi
1732                 case $cf_cv_system_name in
1733                 aix[[5-7]]*) #(vi
1734                         $2='.a'
1735                         $3=[$]$2
1736                         ;;
1737                 cygwin*) #(vi
1738                         $2='.dll'
1739                         $3='.dll.a'
1740                         ;;
1741                 darwin*) #(vi
1742                         $2='.dylib'
1743                         $3=[$]$2
1744                         ;;
1745                 hpux*) #(vi
1746                         case $target in
1747                         ia64*) #(vi
1748                                 $2='.so'
1749                                 $3=[$]$2
1750                                 ;;
1751                         *) #(vi
1752                                 $2='.sl'
1753                                 $3=[$]$2
1754                                 ;;
1755                         esac
1756                         ;;
1757                 *)      $2='.so'
1758                         $3=[$]$2
1759                         ;;
1760                 esac
1761         esac
1762         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1763         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
1764 ])dnl
1765 dnl ---------------------------------------------------------------------------
1766 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
1767 dnl -----------
1768 dnl Compute the string to append to -library from the given model name
1769 dnl $1 = model name
1770 dnl $2 = variable to set
1771 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1772 AC_DEFUN([CF_LIB_TYPE],
1773 [
1774         case $1 in
1775         libtool) $2=''   ;;
1776         normal)  $2=''   ;;
1777         debug)   $2='_g' ;;
1778         profile) $2='_p' ;;
1779         shared)  $2=''   ;;
1780         esac
1781         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1782 ])dnl
1783 dnl ---------------------------------------------------------------------------
1784 dnl CF_LINK_DATAONLY version: 9 updated: 2009/01/01 20:21:38
1785 dnl ----------------
1786 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
1787 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
1788 dnl have to provide wrappers for global tables to ensure they're linked
1789 dnl properly.
1790 AC_DEFUN([CF_LINK_DATAONLY],
1791 [
1792 AC_MSG_CHECKING([if data-only library module links])
1793 AC_CACHE_VAL(cf_cv_link_dataonly,[
1794         rm -f conftest.a
1795         cat >conftest.$ac_ext <<EOF
1796 #line __oline__ "configure"
1797 int     testdata[[3]] = { 123, 456, 789 };
1798 EOF
1799         if AC_TRY_EVAL(ac_compile) ; then
1800                 mv conftest.o data.o && \
1801                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
1802         fi
1803         rm -f conftest.$ac_ext data.o
1804         cat >conftest.$ac_ext <<EOF
1805 #line __oline__ "configure"
1806 int     testfunc()
1807 {
1808 #if defined(NeXT)
1809         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
1810 #else
1811         extern int testdata[[3]];
1812         return testdata[[0]] == 123
1813            &&  testdata[[1]] == 456
1814            &&  testdata[[2]] == 789;
1815 #endif
1816 }
1817 EOF
1818         if AC_TRY_EVAL(ac_compile); then
1819                 mv conftest.o func.o && \
1820                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
1821         fi
1822         rm -f conftest.$ac_ext func.o
1823         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
1824         cf_saveLIBS="$LIBS"
1825         LIBS="conftest.a $LIBS"
1826         AC_TRY_RUN([
1827         int main()
1828         {
1829                 extern int testfunc();
1830                 ${cf_cv_main_return:-return} (!testfunc());
1831         }
1832         ],
1833         [cf_cv_link_dataonly=yes],
1834         [cf_cv_link_dataonly=no],
1835         [cf_cv_link_dataonly=unknown])
1836         LIBS="$cf_saveLIBS"
1837         ])
1838 AC_MSG_RESULT($cf_cv_link_dataonly)
1839
1840 if test "$cf_cv_link_dataonly" = no ; then
1841         AC_DEFINE(BROKEN_LINKER)
1842         BROKEN_LINKER=1
1843 fi
1844
1845 ])dnl
1846 dnl ---------------------------------------------------------------------------
1847 dnl CF_LINK_FUNCS version: 7 updated: 2006/12/16 12:33:30
1848 dnl -------------
1849 dnl Most Unix systems have both link and symlink, a few don't have symlink.
1850 dnl A few non-Unix systems implement symlink, but not link.
1851 dnl A few non-systems implement neither (or have nonfunctional versions).
1852 AC_DEFUN([CF_LINK_FUNCS],
1853 [
1854 AC_CHECK_FUNCS( \
1855         remove \
1856         unlink )
1857
1858 if test "$cross_compiling" = yes ; then
1859         AC_CHECK_FUNCS( \
1860                 link \
1861                 symlink )
1862 else
1863         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
1864                 cf_cv_link_funcs=
1865                 for cf_func in link symlink ; do
1866                         AC_TRY_RUN([
1867 #include <sys/types.h>
1868 #include <sys/stat.h>
1869 #ifdef HAVE_UNISTD_H
1870 #include <unistd.h>
1871 #endif
1872 int main()
1873 {
1874         int fail = 0;
1875         char *src = "config.log";
1876         char *dst = "conftest.chk";
1877         struct stat src_sb;
1878         struct stat dst_sb;
1879
1880         stat(src, &src_sb);
1881         fail = ($cf_func("config.log", "conftest.chk") < 0)
1882             || (stat(dst, &dst_sb) < 0)
1883             || (dst_sb.st_mtime != src_sb.st_mtime);
1884 #ifdef HAVE_UNLINK
1885         unlink(dst);
1886 #else
1887         remove(dst);
1888 #endif
1889         ${cf_cv_main_return:-return} (fail);
1890 }
1891                         ],[
1892                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
1893                         eval 'ac_cv_func_'$cf_func'=yes'],[
1894                         eval 'ac_cv_func_'$cf_func'=no'],[
1895                         eval 'ac_cv_func_'$cf_func'=error'])
1896                 done
1897                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
1898         ])
1899         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK)
1900         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK)
1901 fi
1902 ])dnl
1903 dnl ---------------------------------------------------------------------------
1904 dnl CF_MAIN_RETURN version: 1 updated: 2006/12/10 09:51:54
1905 dnl --------------
1906 dnl Check if a return from main to the shell actually returns the same exit
1907 dnl code.  This is true for almost any POSIX environment.
1908 dnl
1909 dnl Some very old environments did not flush stdout, etc., on an exit.  That
1910 dnl would be a useful case to test for also.
1911 AC_DEFUN([CF_MAIN_RETURN],
1912 [
1913 cf_cv_main_return=return
1914 ])dnl
1915 dnl ---------------------------------------------------------------------------
1916 dnl CF_MAKEFLAGS version: 14 updated: 2011/03/31 19:29:46
1917 dnl ------------
1918 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
1919 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
1920 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
1921 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
1922 AC_DEFUN([CF_MAKEFLAGS],
1923 [
1924 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
1925         cf_cv_makeflags=''
1926         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
1927         do
1928                 cat >cf_makeflags.tmp <<CF_EOF
1929 SHELL = /bin/sh
1930 all :
1931         @ echo '.$cf_option'
1932 CF_EOF
1933                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
1934                 case "$cf_result" in
1935                 .*k)
1936                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
1937                         case "$cf_result" in
1938                         .*CC=*) cf_cv_makeflags=
1939                                 ;;
1940                         *)      cf_cv_makeflags=$cf_option
1941                                 ;;
1942                         esac
1943                         break
1944                         ;;
1945                 .-)     ;;
1946                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
1947                         ;;
1948                 esac
1949         done
1950         rm -f cf_makeflags.tmp
1951 ])
1952
1953 AC_SUBST(cf_cv_makeflags)
1954 ])dnl
1955 dnl ---------------------------------------------------------------------------
1956 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1957 dnl ------------
1958 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1959 dnl a monocase filesystem.
1960 AC_DEFUN([CF_MAKE_TAGS],[
1961 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1962
1963 AC_CHECK_PROGS(CTAGS, exctags ctags)
1964 AC_CHECK_PROGS(ETAGS, exetags etags)
1965
1966 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1967
1968 if test "$cf_cv_mixedcase" = yes ; then
1969         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1970 else
1971         MAKE_UPPER_TAGS=no
1972 fi
1973
1974 if test "$MAKE_UPPER_TAGS" = yes ; then
1975         MAKE_UPPER_TAGS=
1976 else
1977         MAKE_UPPER_TAGS="#"
1978 fi
1979
1980 if test "$MAKE_LOWER_TAGS" = yes ; then
1981         MAKE_LOWER_TAGS=
1982 else
1983         MAKE_LOWER_TAGS="#"
1984 fi
1985
1986 AC_SUBST(CTAGS)
1987 AC_SUBST(ETAGS)
1988
1989 AC_SUBST(MAKE_UPPER_TAGS)
1990 AC_SUBST(MAKE_LOWER_TAGS)
1991 ])dnl
1992 dnl ---------------------------------------------------------------------------
1993 dnl CF_MIXEDCASE_FILENAMES version: 3 updated: 2003/09/20 17:07:55
1994 dnl ----------------------
1995 dnl Check if the file-system supports mixed-case filenames.  If we're able to
1996 dnl create a lowercase name and see it as uppercase, it doesn't support that.
1997 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
1998 [
1999 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2000 if test "$cross_compiling" = yes ; then
2001         case $target_alias in #(vi
2002         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-mingw32*|*-uwin*) #(vi
2003                 cf_cv_mixedcase=no
2004                 ;;
2005         *)
2006                 cf_cv_mixedcase=yes
2007                 ;;
2008         esac
2009 else
2010         rm -f conftest CONFTEST
2011         echo test >conftest
2012         if test -f CONFTEST ; then
2013                 cf_cv_mixedcase=no
2014         else
2015                 cf_cv_mixedcase=yes
2016         fi
2017         rm -f conftest CONFTEST
2018 fi
2019 ])
2020 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES)
2021 ])dnl
2022 dnl ---------------------------------------------------------------------------
2023 dnl CF_MKSTEMP version: 7 updated: 2010/08/14 18:25:37
2024 dnl ----------
2025 dnl Check for a working mkstemp.  This creates two files, checks that they are
2026 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2027 AC_DEFUN([CF_MKSTEMP],[
2028 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2029 rm -rf conftest*
2030 AC_TRY_RUN([
2031 #include <sys/types.h>
2032 #include <stdlib.h>
2033 #include <stdio.h>
2034 #include <string.h>
2035 #include <sys/stat.h>
2036 int main()
2037 {
2038         char *tmpl = "conftestXXXXXX";
2039         char name[2][80];
2040         int n;
2041         int result = 0;
2042         int fd;
2043         struct stat sb;
2044
2045         umask(077);
2046         for (n = 0; n < 2; ++n) {
2047                 strcpy(name[n], tmpl);
2048                 if ((fd = mkstemp(name[n])) >= 0) {
2049                         if (!strcmp(name[n], tmpl)
2050                          || stat(name[n], &sb) != 0
2051                          || (sb.st_mode & S_IFMT) != S_IFREG
2052                          || (sb.st_mode & 077) != 0) {
2053                                 result = 1;
2054                         }
2055                         close(fd);
2056                 }
2057         }
2058         if (result == 0
2059          && !strcmp(name[0], name[1]))
2060                 result = 1;
2061         ${cf_cv_main_return:-return}(result);
2062 }
2063 ],[cf_cv_func_mkstemp=yes
2064 ],[cf_cv_func_mkstemp=no
2065 ],[AC_CHECK_FUNC(mkstemp)
2066 ])
2067 ])
2068 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2069         AC_DEFINE(HAVE_MKSTEMP)
2070 fi
2071 ])dnl
2072 dnl ---------------------------------------------------------------------------
2073 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2074 dnl ----------
2075 dnl Write a debug message to config.log, along with the line number in the
2076 dnl configure script.
2077 AC_DEFUN([CF_MSG_LOG],[
2078 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2079 ])dnl
2080 dnl ---------------------------------------------------------------------------
2081 dnl CF_NCURSES_ADDON version: 4 updated: 2011/03/27 17:10:13
2082 dnl ----------------
2083 dnl Configure an ncurses add-on, built outside the ncurses tree.
2084 AC_DEFUN([CF_NCURSES_ADDON],[
2085
2086 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2087
2088 AC_MSG_CHECKING(if you want wide-character code)
2089 AC_ARG_ENABLE(widec,
2090         [  --enable-widec          compile with wide-char/UTF-8 code],
2091         [with_widec=$enableval],
2092         [with_widec=no])
2093 AC_MSG_RESULT($with_widec)
2094 if test "$with_widec" = yes ; then
2095         CF_UTF8_LIB 
2096         CF_NCURSES_CONFIG(ncursesw)
2097 else
2098         CF_NCURSES_CONFIG(ncurses)
2099 fi
2100
2101 if test "$NCURSES_CONFIG" != none ; then
2102
2103 cf_version=`$NCURSES_CONFIG --version`
2104
2105 NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2106 NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2107 NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2108
2109 # ABI version is not available from headers
2110 cf_cv_abi_version=`$NCURSES_CONFIG --abi-version`
2111
2112 else
2113
2114 for cf_name in MAJOR MINOR PATCH
2115 do
2116 cat >conftest.$ac_ext <<CF_EOF
2117 #include <${cf_cv_ncurses_header:-curses.h}>
2118 AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2119 CF_EOF
2120         cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2121         AC_TRY_EVAL(cf_try)
2122         if test -f conftest.out ; then
2123                 cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]][[    ]]*//"`
2124                 eval NCURSES_$cf_name=\"$cf_result\"
2125                 # cat conftest.$ac_ext
2126                 # cat conftest.out
2127         fi
2128 done
2129
2130 cf_cv_abi_version=${NCURSES_MAJOR}
2131
2132 fi
2133
2134 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2135
2136 dnl Show the computed version, for logging
2137 cf_cv_timestamp=`date`
2138
2139 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2140
2141 dnl We need these values in the generated headers
2142 AC_SUBST(NCURSES_MAJOR)
2143 AC_SUBST(NCURSES_MINOR)
2144 AC_SUBST(NCURSES_PATCH)
2145
2146 dnl We need these values in the generated makefiles
2147 AC_SUBST(cf_cv_rel_version)
2148 AC_SUBST(cf_cv_abi_version)
2149
2150 dnl FIXME - not needed for Ada95
2151 AC_SUBST(cf_cv_builtin_bool)
2152 AC_SUBST(cf_cv_header_stdbool_h)
2153 AC_SUBST(cf_cv_type_of_bool)dnl
2154
2155 ])
2156 dnl ---------------------------------------------------------------------------
2157 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2158 dnl -------------------
2159 dnl Check if we can compile with ncurses' header file
2160 dnl $1 is the cache variable to set
2161 dnl $2 is the header-file to include
2162 dnl $3 is the root name (ncurses or ncursesw)
2163 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2164         AC_TRY_COMPILE([
2165 ]ifelse($3,ncursesw,[
2166 #define _XOPEN_SOURCE_EXTENDED
2167 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2168 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2169 ])[
2170 #include <$2>],[
2171 #ifdef NCURSES_VERSION
2172 ]ifelse($3,ncursesw,[
2173 #ifndef WACS_BSSB
2174         make an error
2175 #endif
2176 ])[
2177 printf("%s\n", NCURSES_VERSION);
2178 #else
2179 #ifdef __NCURSES_H
2180 printf("old\n");
2181 #else
2182         make an error
2183 #endif
2184 #endif
2185         ]
2186         ,[$1=$2]
2187         ,[$1=no])
2188 ])dnl
2189 dnl ---------------------------------------------------------------------------
2190 dnl CF_NCURSES_CONFIG version: 8 updated: 2010/07/08 05:17:30
2191 dnl -----------------
2192 dnl Tie together the configure-script macros for ncurses.
2193 dnl Prefer the "-config" script from ncurses 6.x, to simplify analysis.
2194 dnl Allow that to be overridden using the $NCURSES_CONFIG environment variable.
2195 dnl
2196 dnl $1 is the root library name (default: "ncurses")
2197 AC_DEFUN([CF_NCURSES_CONFIG],
2198 [
2199 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2200
2201 echo "Looking for ${cf_ncuconfig_root}-config"
2202 AC_PATH_PROGS(NCURSES_CONFIG,${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config,none)
2203
2204 if test "$NCURSES_CONFIG" != none ; then
2205
2206 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
2207 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2208
2209 # even with config script, some packages use no-override for curses.h
2210 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2211
2212 dnl like CF_NCURSES_CPPFLAGS
2213 AC_DEFINE(NCURSES)
2214
2215 dnl like CF_NCURSES_LIBS
2216 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2217 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2218
2219 dnl like CF_NCURSES_VERSION
2220 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2221
2222 else
2223
2224 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2225 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2226
2227 fi
2228 ])dnl
2229 dnl ---------------------------------------------------------------------------
2230 dnl CF_NCURSES_CPPFLAGS version: 20 updated: 2010/11/20 17:02:38
2231 dnl -------------------
2232 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2233 dnl the CPPFLAGS variable so we can include its header.
2234 dnl
2235 dnl The header files may be installed as either curses.h, or ncurses.h (would
2236 dnl be obsolete, except that some packagers prefer this name to distinguish it
2237 dnl from a "native" curses implementation).  If not installed for overwrite,
2238 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2239 dnl /usr/include/ncurses), but someone may have installed overwriting the
2240 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2241 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2242 dnl the header.
2243 dnl
2244 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2245 dnl is already in the include-path, don't even bother with this, since we cannot
2246 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2247 dnl
2248 dnl The optional parameter gives the root name of the library, in case it is
2249 dnl not installed as the default curses library.  That is how the
2250 dnl wide-character version of ncurses is installed.
2251 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2252 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2253
2254 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2255 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2256
2257 test -n "$cf_cv_curses_dir" && \
2258 test "$cf_cv_curses_dir" != "no" && { \
2259   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2260 }
2261
2262 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2263         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2264         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2265         for cf_header in $cf_header_list
2266         do
2267                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2268                 test "$cf_cv_ncurses_h" != no && break
2269         done
2270 ])
2271
2272 CF_NCURSES_HEADER
2273 CF_TERM_HEADER
2274
2275 # some applications need this, but should check for NCURSES_VERSION
2276 AC_DEFINE(NCURSES)
2277
2278 CF_NCURSES_VERSION
2279 ])dnl
2280 dnl ---------------------------------------------------------------------------
2281 dnl CF_NCURSES_HEADER version: 2 updated: 2008/03/23 14:48:54
2282 dnl -----------------
2283 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2284 dnl variations of ncurses' installs.
2285 dnl
2286 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2287 AC_DEFUN([CF_NCURSES_HEADER],[
2288
2289 if test "$cf_cv_ncurses_h" != no ; then
2290         cf_cv_ncurses_header=$cf_cv_ncurses_h
2291 else
2292
2293 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2294         test -n "$verbose" && echo
2295         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2296         test -n "$verbose" && echo search path $cf_search
2297         cf_save2_CPPFLAGS="$CPPFLAGS"
2298         for cf_incdir in $cf_search
2299         do
2300                 CF_ADD_INCDIR($cf_incdir)
2301                 for cf_header in \
2302                         ncurses.h \
2303                         curses.h
2304                 do
2305                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2306                         if test "$cf_cv_ncurses_h2" != no ; then
2307                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2308                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2309                                 break
2310                         fi
2311                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2312                 done
2313                 CPPFLAGS="$cf_save2_CPPFLAGS"
2314                 test "$cf_cv_ncurses_h2" != no && break
2315         done
2316         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2317         ])
2318
2319         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2320         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2321         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2322                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2323         fi
2324         CF_ADD_INCDIR($cf_1st_incdir)
2325
2326 fi
2327
2328 # Set definitions to allow ifdef'ing for ncurses.h
2329
2330 case $cf_cv_ncurses_header in # (vi
2331 *ncurses.h)
2332         AC_DEFINE(HAVE_NCURSES_H)
2333         ;;
2334 esac
2335
2336 case $cf_cv_ncurses_header in # (vi
2337 ncurses/curses.h|ncurses/ncurses.h)
2338         AC_DEFINE(HAVE_NCURSES_NCURSES_H)
2339         ;;
2340 ncursesw/curses.h|ncursesw/ncurses.h)
2341         AC_DEFINE(HAVE_NCURSESW_NCURSES_H)
2342         ;;
2343 esac
2344
2345 ])dnl
2346 dnl ---------------------------------------------------------------------------
2347 dnl CF_NCURSES_LIBS version: 16 updated: 2010/11/20 17:02:38
2348 dnl ---------------
2349 dnl Look for the ncurses library.  This is a little complicated on Linux,
2350 dnl because it may be linked with the gpm (general purpose mouse) library.
2351 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2352 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2353 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2354 dnl and the linker will record a dependency.
2355 dnl
2356 dnl The optional parameter gives the root name of the library, in case it is
2357 dnl not installed as the default curses library.  That is how the
2358 dnl wide-character version of ncurses is installed.
2359 AC_DEFUN([CF_NCURSES_LIBS],
2360 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2361
2362 cf_nculib_root=ifelse($1,,ncurses,$1)
2363         # This works, except for the special case where we find gpm, but
2364         # ncurses is in a nonstandard location via $LIBS, and we really want
2365         # to link gpm.
2366 cf_ncurses_LIBS=""
2367 cf_ncurses_SAVE="$LIBS"
2368 AC_CHECK_LIB(gpm,Gpm_Open,
2369         [AC_CHECK_LIB(gpm,initscr,
2370                 [LIBS="$cf_ncurses_SAVE"],
2371                 [cf_ncurses_LIBS="-lgpm"])])
2372
2373 case $host_os in #(vi
2374 freebsd*)
2375         # This is only necessary if you are linking against an obsolete
2376         # version of ncurses (but it should do no harm, since it's static).
2377         if test "$cf_nculib_root" = ncurses ; then
2378                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2379         fi
2380         ;;
2381 esac
2382
2383 CF_ADD_LIBS($cf_ncurses_LIBS)
2384
2385 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2386 then
2387         CF_ADD_LIBS(-l$cf_nculib_root)
2388 else
2389         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2390                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2391                 [initscr()],
2392                 initscr)
2393 fi
2394
2395 if test -n "$cf_ncurses_LIBS" ; then
2396         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2397         cf_ncurses_SAVE="$LIBS"
2398         for p in $cf_ncurses_LIBS ; do
2399                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2400                 if test "$q" != "$LIBS" ; then
2401                         LIBS="$q"
2402                 fi
2403         done
2404         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2405                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2406                 [AC_MSG_RESULT(yes)],
2407                 [AC_MSG_RESULT(no)
2408                  LIBS="$cf_ncurses_SAVE"])
2409 fi
2410
2411 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2412 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2413 ])dnl
2414 dnl ---------------------------------------------------------------------------
2415 dnl CF_NCURSES_VERSION version: 13 updated: 2010/10/23 15:54:49
2416 dnl ------------------
2417 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2418 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2419 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2420 AC_DEFUN([CF_NCURSES_VERSION],
2421 [
2422 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2423 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2424         cf_cv_ncurses_version=no
2425         cf_tempfile=out$$
2426         rm -f $cf_tempfile
2427         AC_TRY_RUN([
2428 #include <${cf_cv_ncurses_header:-curses.h}>
2429 #include <stdio.h>
2430 int main()
2431 {
2432         FILE *fp = fopen("$cf_tempfile", "w");
2433 #ifdef NCURSES_VERSION
2434 # ifdef NCURSES_VERSION_PATCH
2435         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2436 # else
2437         fprintf(fp, "%s\n", NCURSES_VERSION);
2438 # endif
2439 #else
2440 # ifdef __NCURSES_H
2441         fprintf(fp, "old\n");
2442 # else
2443         make an error
2444 # endif
2445 #endif
2446         ${cf_cv_main_return:-return}(0);
2447 }],[
2448         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2449
2450         # This will not work if the preprocessor splits the line after the
2451         # Autoconf token.  The 'unproto' program does that.
2452         cat > conftest.$ac_ext <<EOF
2453 #include <${cf_cv_ncurses_header:-curses.h}>
2454 #undef Autoconf
2455 #ifdef NCURSES_VERSION
2456 Autoconf NCURSES_VERSION
2457 #else
2458 #ifdef __NCURSES_H
2459 Autoconf "old"
2460 #endif
2461 ;
2462 #endif
2463 EOF
2464         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2465         AC_TRY_EVAL(cf_try)
2466         if test -f conftest.out ; then
2467                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2468                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2469                 rm -f conftest.out
2470         fi
2471 ])
2472         rm -f $cf_tempfile
2473 ])
2474 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES)
2475 ])dnl
2476 dnl ---------------------------------------------------------------------------
2477 dnl CF_NO_LEAKS_OPTION version: 4 updated: 2006/12/16 14:24:05
2478 dnl ------------------
2479 dnl see CF_WITH_NO_LEAKS
2480 AC_DEFUN([CF_NO_LEAKS_OPTION],[
2481 AC_MSG_CHECKING(if you want to use $1 for testing)
2482 AC_ARG_WITH($1,
2483         [$2],
2484         [AC_DEFINE($3)ifelse([$4],,[
2485          $4
2486 ])
2487         : ${with_cflags:=-g}
2488         : ${with_no_leaks:=yes}
2489          with_$1=yes],
2490         [with_$1=])
2491 AC_MSG_RESULT(${with_$1:-no})
2492
2493 case .$with_cflags in #(vi
2494 .*-g*)
2495         case .$CFLAGS in #(vi
2496         .*-g*) #(vi
2497                 ;;
2498         *)
2499                 CF_ADD_CFLAGS([-g])
2500                 ;;
2501         esac
2502         ;;
2503 esac
2504 ])dnl
2505 dnl ---------------------------------------------------------------------------
2506 dnl CF_NUMBER_SYNTAX version: 1 updated: 2003/09/20 18:12:49
2507 dnl ----------------
2508 dnl Check if the given variable is a number.  If not, report an error.
2509 dnl $1 is the variable
2510 dnl $2 is the message
2511 AC_DEFUN([CF_NUMBER_SYNTAX],[
2512 if test -n "$1" ; then
2513   case $1 in #(vi
2514   [[0-9]]*) #(vi
2515         ;;
2516   *)
2517         AC_MSG_ERROR($2 is not a number: $1)
2518         ;;
2519   esac
2520 else
2521   AC_MSG_ERROR($2 value is empty)
2522 fi
2523 ])dnl
2524 dnl ---------------------------------------------------------------------------
2525 dnl CF_OBJ_SUBDIR version: 4 updated: 2002/02/23 20:38:31
2526 dnl -------------
2527 dnl Compute the object-directory name from the given model name
2528 AC_DEFUN([CF_OBJ_SUBDIR],
2529 [
2530         case $1 in
2531         libtool) $2='obj_lo'  ;;
2532         normal)  $2='objects' ;;
2533         debug)   $2='obj_g' ;;
2534         profile) $2='obj_p' ;;
2535         shared)
2536                 case $cf_cv_system_name in #(vi
2537                 cygwin) #(vi
2538                         $2='objects' ;;
2539                 *)
2540                         $2='obj_s' ;;
2541                 esac
2542         esac
2543 ])dnl
2544 dnl ---------------------------------------------------------------------------
2545 dnl CF_PATHSEP version: 5 updated: 2010/05/26 05:38:42
2546 dnl ----------
2547 dnl Provide a value for the $PATH and similar separator
2548 AC_DEFUN([CF_PATHSEP],
2549 [
2550         case $cf_cv_system_name in
2551         os2*)   PATH_SEPARATOR=';'  ;;
2552         *)      PATH_SEPARATOR=':'  ;;
2553         esac
2554 ifelse([$1],,,[$1=$PATH_SEPARATOR])
2555         AC_SUBST(PATH_SEPARATOR)
2556 ])dnl
2557 dnl ---------------------------------------------------------------------------
2558 dnl CF_PATH_SYNTAX version: 13 updated: 2010/05/26 05:38:42
2559 dnl --------------
2560 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2561 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2562 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2563 dnl delayed evaluation of those symbols.
2564 AC_DEFUN([CF_PATH_SYNTAX],[
2565 if test "x$prefix" != xNONE; then
2566   cf_path_syntax="$prefix"
2567 else
2568   cf_path_syntax="$ac_default_prefix"
2569 fi
2570
2571 case ".[$]$1" in #(vi
2572 .\[$]\(*\)*|.\'*\'*) #(vi
2573   ;;
2574 ..|./*|.\\*) #(vi
2575   ;;
2576 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
2577   ;;
2578 .\[$]{*prefix}*) #(vi
2579   eval $1="[$]$1"
2580   case ".[$]$1" in #(vi
2581   .NONE/*)
2582     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2583     ;;
2584   esac
2585   ;; #(vi
2586 .no|.NONE/*)
2587   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2588   ;;
2589 *)
2590   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2591   ;;
2592 esac
2593 ])dnl
2594 dnl ---------------------------------------------------------------------------
2595 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
2596 dnl -------------
2597 dnl Check for the package-config program, unless disabled by command-line.
2598 AC_DEFUN([CF_PKG_CONFIG],
2599 [
2600 AC_MSG_CHECKING(if you want to use pkg-config)
2601 AC_ARG_WITH(pkg-config,
2602         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2603         [cf_pkg_config=$withval],
2604         [cf_pkg_config=yes])
2605 AC_MSG_RESULT($cf_pkg_config)
2606
2607 case $cf_pkg_config in #(vi
2608 no) #(vi
2609         PKG_CONFIG=none
2610         ;;
2611 yes) #(vi
2612         CF_ACVERSION_CHECK(2.52,
2613                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2614                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2615         ;;
2616 *)
2617         PKG_CONFIG=$withval
2618         ;;
2619 esac
2620
2621 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2622 if test "$PKG_CONFIG" != none ; then
2623         CF_PATH_SYNTAX(PKG_CONFIG)
2624 fi
2625
2626 AC_SUBST(PKG_CONFIG)
2627 ])dnl
2628 dnl ---------------------------------------------------------------------------
2629 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
2630 dnl -----------------
2631 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2632 dnl
2633 dnl     POSIX.1-1990                            _POSIX_SOURCE
2634 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2635 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2636 dnl             Bindings Option
2637 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2638 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2639 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2640 dnl
2641 dnl Parameters:
2642 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2643 AC_DEFUN([CF_POSIX_C_SOURCE],
2644 [
2645 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2646
2647 cf_save_CFLAGS="$CFLAGS"
2648 cf_save_CPPFLAGS="$CPPFLAGS"
2649
2650 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2651 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2652
2653 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2654         CF_MSG_LOG(if the symbol is already defined go no further)
2655         AC_TRY_COMPILE([#include <sys/types.h>],[
2656 #ifndef _POSIX_C_SOURCE
2657 make an error
2658 #endif],
2659         [cf_cv_posix_c_source=no],
2660         [cf_want_posix_source=no
2661          case .$cf_POSIX_C_SOURCE in #(vi
2662          .[[12]]??*) #(vi
2663                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2664                 ;;
2665          .2) #(vi
2666                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2667                 cf_want_posix_source=yes
2668                 ;;
2669          .*)
2670                 cf_want_posix_source=yes
2671                 ;;
2672          esac
2673          if test "$cf_want_posix_source" = yes ; then
2674                 AC_TRY_COMPILE([#include <sys/types.h>],[
2675 #ifdef _POSIX_SOURCE
2676 make an error
2677 #endif],[],
2678                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2679          fi
2680          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2681          CFLAGS="$cf_trim_CFLAGS"
2682          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2683          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2684          AC_TRY_COMPILE([#include <sys/types.h>],[
2685 #ifndef _POSIX_C_SOURCE
2686 make an error
2687 #endif],,
2688          [cf_cv_posix_c_source=no])
2689          CFLAGS="$cf_save_CFLAGS"
2690          CPPFLAGS="$cf_save_CPPFLAGS"
2691         ])
2692 ])
2693
2694 if test "$cf_cv_posix_c_source" != no ; then
2695         CFLAGS="$cf_trim_CFLAGS"
2696         CPPFLAGS="$cf_trim_CPPFLAGS"
2697         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2698 fi
2699
2700 ])dnl
2701 dnl ---------------------------------------------------------------------------
2702 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
2703 dnl ----------
2704 dnl Check for archiver "ar".
2705 AC_DEFUN([CF_PROG_AR],[
2706 AC_CHECK_TOOL(AR, ar, ar)
2707 ])
2708 dnl ---------------------------------------------------------------------------
2709 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
2710 dnl -----------
2711 dnl Check for awk, ensure that the check found something.
2712 AC_DEFUN([CF_PROG_AWK],
2713 [
2714 AC_PROG_AWK
2715 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
2716 ])dnl
2717 dnl ---------------------------------------------------------------------------
2718 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
2719 dnl --------------
2720 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
2721 dnl the output file can be renamed, and allows for a shell variable that can
2722 dnl be used later.  The parameter is either CC or CXX.  The result is the
2723 dnl cache variable:
2724 dnl     $cf_cv_prog_CC_c_o
2725 dnl     $cf_cv_prog_CXX_c_o
2726 AC_DEFUN([CF_PROG_CC_C_O],
2727 [AC_REQUIRE([AC_PROG_CC])dnl
2728 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
2729 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
2730 [
2731 cat > conftest.$ac_ext <<CF_EOF
2732 #include <stdio.h>
2733 int main()
2734 {
2735         ${cf_cv_main_return:-return}(0);
2736 }
2737 CF_EOF
2738 # We do the test twice because some compilers refuse to overwrite an
2739 # existing .o file with -o, though they will create one.
2740 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
2741 if AC_TRY_EVAL(ac_try) &&
2742   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
2743 then
2744   eval cf_cv_prog_$1_c_o=yes
2745 else
2746   eval cf_cv_prog_$1_c_o=no
2747 fi
2748 rm -rf conftest*
2749 ])dnl
2750 if test $cf_cv_prog_$1_c_o = yes; then
2751   AC_MSG_RESULT([yes])
2752 else
2753   AC_MSG_RESULT([no])
2754 fi
2755 ])dnl
2756 dnl ---------------------------------------------------------------------------
2757 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
2758 dnl -------------
2759 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
2760 dnl This macro adds a check to ensure the script found something.
2761 AC_DEFUN([CF_PROG_EGREP],
2762 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
2763    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
2764     then ac_cv_prog_egrep='grep -E'
2765     else ac_cv_prog_egrep='egrep'
2766     fi])
2767  EGREP=$ac_cv_prog_egrep
2768  AC_SUBST([EGREP])
2769 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
2770 ])dnl
2771 dnl ---------------------------------------------------------------------------
2772 dnl CF_PROG_EXT version: 10 updated: 2004/01/03 19:28:18
2773 dnl -----------
2774 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
2775 AC_DEFUN([CF_PROG_EXT],
2776 [
2777 AC_REQUIRE([CF_CHECK_CACHE])
2778 case $cf_cv_system_name in
2779 os2*)
2780     CFLAGS="$CFLAGS -Zmt"
2781     CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
2782     CXXFLAGS="$CXXFLAGS -Zmt"
2783     # autoconf's macro sets -Zexe and suffix both, which conflict:w
2784     LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
2785     ac_cv_exeext=.exe
2786     ;;
2787 esac
2788
2789 AC_EXEEXT
2790 AC_OBJEXT
2791
2792 PROG_EXT="$EXEEXT"
2793 AC_SUBST(PROG_EXT)
2794 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT")
2795 ])dnl
2796 dnl ---------------------------------------------------------------------------
2797 dnl CF_PROG_GNAT version: 1 updated: 2010/06/19 15:22:18
2798 dnl ------------
2799 dnl Check for gnatmake, ensure that it is complete.
2800 AC_DEFUN([CF_PROG_GNAT],[
2801 cf_ada_make=gnatmake
2802 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
2803 if test "$ac_cv_prog_gnat_exists" = no; then
2804    cf_ada_make=
2805 else
2806    CF_GNAT_VERSION
2807    AC_CHECK_PROG(M4_exists, m4, yes, no)
2808    if test "$ac_cv_prog_M4_exists" = no; then
2809       cf_cv_prog_gnat_correct=no
2810       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
2811    fi
2812    if test "$cf_cv_prog_gnat_correct" = yes; then
2813       AC_MSG_CHECKING(if GNAT works)
2814       CF_GNAT_TRY_RUN([procedure conftest;],
2815 [with Text_IO;
2816 with GNAT.OS_Lib;
2817 procedure conftest is
2818 begin
2819    Text_IO.Put ("Hello World");
2820    Text_IO.New_Line;
2821    GNAT.OS_Lib.OS_Exit (0);
2822 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
2823       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
2824    fi
2825 fi
2826
2827 AC_SUBST(cf_ada_make)
2828 ])dnl
2829 dnl ---------------------------------------------------------------------------
2830 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
2831 dnl ------------
2832 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
2833 dnl option if it is supported.
2834 AC_DEFUN([CF_PROG_LN_S],[
2835 AC_PROG_LN_S
2836 AC_MSG_CHECKING(if $LN_S -f options work)
2837
2838 rm -f conf$$.src conf$$dst
2839 echo >conf$$.dst
2840 echo first >conf$$.src
2841 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
2842         cf_prog_ln_sf=yes
2843 else
2844         cf_prog_ln_sf=no
2845 fi
2846 rm -f conf$$.dst conf$$src
2847 AC_MSG_RESULT($cf_prog_ln_sf)
2848
2849 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
2850 ])dnl
2851 dnl ---------------------------------------------------------------------------
2852 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2853 dnl ----------------
2854 dnl Remove all -U and -D options that refer to the given symbol from a list
2855 dnl of C compiler options.  This works around the problem that not all
2856 dnl compilers process -U and -D options from left-to-right, so a -U option
2857 dnl cannot be used to cancel the effect of a preceding -D option.
2858 dnl
2859 dnl $1 = target (which could be the same as the source variable)
2860 dnl $2 = source (including '$')
2861 dnl $3 = symbol to remove
2862 define([CF_REMOVE_DEFINE],
2863 [
2864 $1=`echo "$2" | \
2865         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2866                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2867 ])dnl
2868 dnl ---------------------------------------------------------------------------
2869 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
2870 dnl -------------
2871 dnl Remove the given library from the symbol
2872 dnl
2873 dnl $1 = target (which could be the same as the source variable)
2874 dnl $2 = source (including '$')
2875 dnl $3 = library to remove
2876 define([CF_REMOVE_LIB],
2877 [
2878 # remove $3 library from $2
2879 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
2880 ])dnl
2881 dnl ---------------------------------------------------------------------------
2882 dnl CF_SHARED_OPTS version: 67 updated: 2011/07/02 15:36:04
2883 dnl --------------
2884 dnl --------------
2885 dnl Attempt to determine the appropriate CC/LD options for creating a shared
2886 dnl library.
2887 dnl
2888 dnl Note: ${LOCAL_LDFLAGS} is used to link executables that will run within the
2889 dnl build-tree, i.e., by making use of the libraries that are compiled in ../lib
2890 dnl We avoid compiling-in a ../lib path for the shared library since that can
2891 dnl lead to unexpected results at runtime.
2892 dnl ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared libraries
2893 dnl are compiled in ../../lib
2894 dnl
2895 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
2896 dnl to install symbolic links to the rel/abi versions of shared libraries.
2897 dnl
2898 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
2899 dnl version when making symbolic links.
2900 dnl
2901 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
2902 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
2903 dnl (ex: libncurses.so.<ver>).
2904 dnl
2905 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
2906 AC_DEFUN([CF_SHARED_OPTS],
2907 [
2908         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
2909         AC_REQUIRE([CF_LD_RPATH_OPT])
2910         LOCAL_LDFLAGS=
2911         LOCAL_LDFLAGS2=
2912         LD_SHARED_OPTS=
2913         INSTALL_LIB="-m 644"
2914
2915         cf_cv_do_symlinks=no
2916         cf_ld_rpath_opt=
2917         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
2918
2919         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
2920         AC_ARG_WITH(shlib-version,
2921         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
2922         [test -z "$withval" && withval=auto
2923         case $withval in #(vi
2924         yes) #(vi
2925                 cf_cv_shlib_version=auto
2926                 ;;
2927         rel|abi|auto|no) #(vi
2928                 cf_cv_shlib_version=$withval
2929                 ;;
2930         *)
2931                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
2932                 ;;
2933         esac
2934         ],[cf_cv_shlib_version=auto])
2935         AC_MSG_RESULT($cf_cv_shlib_version)
2936
2937         cf_cv_rm_so_locs=no
2938
2939         # Some less-capable ports of gcc support only -fpic
2940         CC_SHARED_OPTS=
2941         if test "$GCC" = yes
2942         then
2943                 AC_MSG_CHECKING(which $CC option to use)
2944                 cf_save_CFLAGS="$CFLAGS"
2945                 for CC_SHARED_OPTS in -fPIC -fpic ''
2946                 do
2947                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
2948                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
2949                 done
2950                 AC_MSG_RESULT($CC_SHARED_OPTS)
2951                 CFLAGS="$cf_save_CFLAGS"
2952         fi
2953
2954         cf_cv_shlib_version_infix=no
2955
2956         case $cf_cv_system_name in #(vi
2957         aix4.[3-9]*|aix[[5-7]]*) #(vi
2958                 if test "$GCC" = yes; then
2959                         CC_SHARED_OPTS=
2960                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${libdir}:/usr/lib -o [$]@'
2961                 else
2962                         # CC_SHARED_OPTS='-qpic=large -G'
2963                         # perhaps "-bM:SRE -bnoentry -bexpall"
2964                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${libdir}:/usr/lib -o [$]@'
2965                 fi
2966                 ;;
2967         beos*) #(vi
2968                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
2969                 ;;
2970         cygwin*) #(vi
2971                 CC_SHARED_OPTS=
2972                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
2973                 cf_cv_shlib_version=cygdll
2974                 cf_cv_shlib_version_infix=cygdll
2975                 cat >mk_shared_lib.sh <<-CF_EOF
2976                 #!/bin/sh
2977                 SHARED_LIB=\[$]1
2978                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
2979                 shift
2980                 cat <<-EOF
2981                 Linking shared library
2982                 ** SHARED_LIB \[$]SHARED_LIB
2983                 ** IMPORT_LIB \[$]IMPORT_LIB
2984 EOF
2985                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
2986 CF_EOF
2987                 chmod +x mk_shared_lib.sh
2988                 ;;
2989         darwin*) #(vi
2990                 EXTRA_CFLAGS="-no-cpp-precomp"
2991                 CC_SHARED_OPTS="-dynamic"
2992                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
2993                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
2994                 cf_cv_shlib_version_infix=yes
2995                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
2996                         cf_save_LDFLAGS=$LDFLAGS
2997                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
2998                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
2999                                 LDFLAGS=$cf_save_LDFLAGS])
3000                 if test $cf_cv_ldflags_search_paths_first = yes; then
3001                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3002                 fi
3003                 ;;
3004         hpux*) #(vi
3005                 # (tested with gcc 2.7.2 -- I don't have c89)
3006                 if test "$GCC" = yes; then
3007                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
3008                 else
3009                         CC_SHARED_OPTS='+Z'
3010                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
3011                 fi
3012                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
3013                 # HP-UX shared libraries must be executable, and should be
3014                 # readonly to exploit a quirk in the memory manager.
3015                 INSTALL_LIB="-m 555"
3016                 ;;
3017         interix*)
3018                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3019                 if test "$cf_cv_shlib_version" = rel; then
3020                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
3021                 else
3022                         cf_shared_soname='`basename $@`'
3023                 fi
3024                 CC_SHARED_OPTS=
3025                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${libdir} -Wl,-h,'$cf_shared_soname' -o $@'
3026                 ;;
3027         irix*) #(vi
3028                 if test "$cf_cv_enable_rpath" = yes ; then
3029                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${libdir} $EXTRA_LDFLAGS"
3030                 fi
3031                 # tested with IRIX 5.2 and 'cc'.
3032                 if test "$GCC" != yes; then
3033                         CC_SHARED_OPTS='-KPIC'
3034                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
3035                 else
3036                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
3037                 fi
3038                 cf_cv_rm_so_locs=yes
3039                 ;;
3040         linux*|gnu*|k*bsd*-gnu) #(vi
3041                 if test "$DFT_LWR_MODEL" = "shared" ; then
3042                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3043                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3044                 fi
3045                 if test "$cf_cv_enable_rpath" = yes ; then
3046                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${libdir} $EXTRA_LDFLAGS"
3047                 fi
3048                 CF_SHARED_SONAME
3049                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3050                 ;;
3051         openbsd[[2-9]].*|mirbsd*) #(vi
3052                 if test "$DFT_LWR_MODEL" = "shared" ; then
3053                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3054                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3055                 fi
3056                 if test "$cf_cv_enable_rpath" = yes ; then
3057                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${libdir} $EXTRA_LDFLAGS"
3058                 fi
3059                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3060                 CF_SHARED_SONAME
3061                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3062                 ;;
3063         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
3064                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3065                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
3066                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3067                 ;;
3068         freebsd*) #(vi
3069                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3070                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3071                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3072                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${libdir} $LOCAL_LDFLAGS"
3073                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${libdir} $EXTRA_LDFLAGS"
3074                 fi
3075                 CF_SHARED_SONAME
3076                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
3077                 ;;
3078         netbsd*) #(vi
3079                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3080                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3081                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3082                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3083                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${libdir} $EXTRA_LDFLAGS"
3084                         if test "$cf_cv_shlib_version" = auto; then
3085                         if test -f /usr/libexec/ld.elf_so; then
3086                                 cf_cv_shlib_version=abi
3087                         else
3088                                 cf_cv_shlib_version=rel
3089                         fi
3090                         fi
3091                         CF_SHARED_SONAME
3092                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
3093                 else
3094                         MK_SHARED_LIB='${LD} -shared -Bshareable -o $[@]'
3095                 fi
3096                 ;;
3097         osf*|mls+*) #(vi
3098                 # tested with OSF/1 V3.2 and 'cc'
3099                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
3100                 # link with shared libs).
3101                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
3102                 case $host_os in #(vi
3103                 osf4*)
3104                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
3105                         ;;
3106                 esac
3107                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
3108                 if test "$DFT_LWR_MODEL" = "shared" ; then
3109                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3110                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3111                 fi
3112                 cf_cv_rm_so_locs=yes
3113                 ;;
3114         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
3115                 # tested with osr5.0.5
3116                 if test "$GCC" != yes; then
3117                         CC_SHARED_OPTS='-belf -KPIC'
3118                 fi
3119                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
3120                 if test "$cf_cv_enable_rpath" = yes ; then
3121                         # only way is to set LD_RUN_PATH but no switch for it
3122                         RUN_PATH=$libdir
3123                 fi
3124                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3125                 LINK_PROGS='LD_RUN_PATH=${libdir}'
3126                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
3127                 ;;
3128         sunos4*) #(vi
3129                 # tested with SunOS 4.1.1 and gcc 2.7.0
3130                 if test "$GCC" != yes; then
3131                         CC_SHARED_OPTS='-KPIC'
3132                 fi
3133                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
3134                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3135                 ;;
3136         solaris2*) #(vi
3137                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
3138                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
3139                 if test "$DFT_LWR_MODEL" = "shared" ; then
3140                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
3141                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3142                 fi
3143                 if test "$cf_cv_enable_rpath" = yes ; then
3144                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
3145                 fi
3146                 CF_SHARED_SONAME
3147                 if test "$GCC" != yes; then
3148                         cf_save_CFLAGS="$CFLAGS"
3149                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
3150                         do
3151                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
3152                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
3153                         done
3154                         CFLAGS="$cf_save_CFLAGS"
3155                         CC_SHARED_OPTS=$cf_shared_opts
3156                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3157                 else
3158                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3159                 fi
3160                 ;;
3161         sysv5uw7*|unix_sv*) #(vi
3162                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
3163                 if test "$GCC" != yes; then
3164                         CC_SHARED_OPTS='-KPIC'
3165                 fi
3166                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
3167                 ;;
3168         *)
3169                 CC_SHARED_OPTS='unknown'
3170                 MK_SHARED_LIB='echo unknown'
3171                 ;;
3172         esac
3173
3174         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
3175         case "$cf_cv_shlib_version" in #(vi
3176         rel|abi)
3177                 case "$MK_SHARED_LIB" in #(vi
3178                 *'-o $[@]') #(vi
3179                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
3180                         ;;
3181                 *)
3182                         AC_MSG_WARN(ignored --with-shlib-version)
3183                         ;;
3184                 esac
3185                 ;;
3186         esac
3187
3188         if test -n "$cf_ld_rpath_opt" ; then
3189                 MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${libdir}"
3190         fi
3191
3192         AC_SUBST(CC_SHARED_OPTS)
3193         AC_SUBST(LD_RPATH_OPT)
3194         AC_SUBST(LD_SHARED_OPTS)
3195         AC_SUBST(MK_SHARED_LIB)
3196         AC_SUBST(LINK_PROGS)
3197         AC_SUBST(LINK_TESTS)
3198         AC_SUBST(EXTRA_LDFLAGS)
3199         AC_SUBST(LOCAL_LDFLAGS)
3200         AC_SUBST(LOCAL_LDFLAGS2)
3201         AC_SUBST(INSTALL_LIB)
3202 ])dnl
3203 dnl ---------------------------------------------------------------------------
3204 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
3205 dnl ----------------
3206 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
3207 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
3208 dnl option.
3209 dnl
3210 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
3211 dnl If missing, use "rel".
3212 define([CF_SHARED_SONAME],
3213 [
3214         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
3215         if test "$cf_cv_shlib_version" = rel; then
3216                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3217         else
3218                 cf_cv_shared_soname='`basename $[@]`'
3219         fi
3220 ])
3221 dnl ---------------------------------------------------------------------------
3222 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
3223 dnl --------------
3224 dnl     Remove "-g" option from the compiler options
3225 AC_DEFUN([CF_STRIP_G_OPT],
3226 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
3227 dnl ---------------------------------------------------------------------------
3228 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
3229 dnl --------------
3230 dnl Construct a search-list for a nonstandard header/lib-file
3231 dnl     $1 = the variable to return as result
3232 dnl     $2 = the package name
3233 dnl     $3 = the subdirectory, e.g., bin, include or lib
3234 AC_DEFUN([CF_SUBDIR_PATH],
3235 [
3236 $1=
3237
3238 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
3239 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3240 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
3241 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
3242 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
3243 ])dnl
3244 dnl ---------------------------------------------------------------------------
3245 dnl CF_SUBST version: 4 updated: 2006/06/17 12:33:03
3246 dnl --------
3247 dnl     Shorthand macro for substituting things that the user may override
3248 dnl     with an environment variable.
3249 dnl
3250 dnl     $1 = long/descriptive name
3251 dnl     $2 = environment variable
3252 dnl     $3 = default value
3253 AC_DEFUN([CF_SUBST],
3254 [AC_CACHE_VAL(cf_cv_subst_$2,[
3255 AC_MSG_CHECKING(for $1 (symbol $2))
3256 CF_SUBST_IF([-z "[$]$2"], [$2], [$3])
3257 cf_cv_subst_$2=[$]$2
3258 AC_MSG_RESULT([$]$2)
3259 ])
3260 ])dnl
3261 dnl ---------------------------------------------------------------------------
3262 dnl CF_TERM_HEADER version: 2 updated: 2010/10/23 15:54:49
3263 dnl --------------
3264 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3265 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3266 dnl but some packagers change this, breaking various applications.
3267 AC_DEFUN([CF_TERM_HEADER],[
3268 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3269 case ${cf_cv_ncurses_header} in #(vi
3270 */ncurses.h|*/ncursesw.h) #(vi
3271         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3272         ;;
3273 *)
3274         cf_term_header=term.h
3275         ;;
3276 esac
3277
3278 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3279 do
3280 AC_TRY_COMPILE([#include <stdio.h>
3281 #include <${cf_cv_ncurses_header:-curses.h}>
3282 #include <$cf_test>
3283 ],[int x = auto_left_margin],[
3284         cf_cv_term_header="$cf_test"],[
3285         cf_cv_term_header=unknown
3286         ])
3287         test "$cf_cv_term_header" != unknown && break
3288 done
3289 ])
3290
3291 # Set definitions to allow ifdef'ing to accommodate subdirectories
3292
3293 case $cf_cv_term_header in # (vi
3294 *term.h)
3295         AC_DEFINE(HAVE_TERM_H)
3296         ;;
3297 esac
3298
3299 case $cf_cv_term_header in # (vi
3300 ncurses/term.h) #(vi
3301         AC_DEFINE(HAVE_NCURSES_TERM_H)
3302         ;;
3303 ncursesw/term.h)
3304         AC_DEFINE(HAVE_NCURSESW_TERM_H)
3305         ;;
3306 esac
3307 ])dnl
3308 dnl ---------------------------------------------------------------------------
3309 dnl CF_TOP_BUILDDIR version: 1 updated: 2006/10/15 16:33:23
3310 dnl ---------------
3311 dnl Define a top_builddir symbol, for applications that need an absolute path.
3312 AC_DEFUN([CF_TOP_BUILDDIR],
3313 [
3314 top_builddir=`pwd`
3315 AC_SUBST(top_builddir)
3316 ])dnl
3317 dnl ---------------------------------------------------------------------------
3318 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3319 dnl --------
3320 dnl Make an uppercase version of a variable
3321 dnl $1=uppercase($2)
3322 AC_DEFUN([CF_UPPER],
3323 [
3324 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3325 ])dnl
3326 dnl ---------------------------------------------------------------------------
3327 dnl CF_UTF8_LIB version: 7 updated: 2010/06/20 09:24:28
3328 dnl -----------
3329 dnl Check for multibyte support, and if not found, utf8 compatibility library
3330 AC_DEFUN([CF_UTF8_LIB],
3331 [
3332 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3333         cf_save_LIBS="$LIBS"
3334         AC_TRY_LINK([
3335 #include <stdlib.h>],[putwc(0,0);],
3336         [cf_cv_utf8_lib=yes],
3337         [CF_FIND_LINKAGE([
3338 #include <libutf8.h>],[putwc(0,0);],utf8,
3339                 [cf_cv_utf8_lib=add-on],
3340                 [cf_cv_utf8_lib=no])
3341 ])])
3342
3343 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3344 # ncurses/ncursesw:
3345 if test "$cf_cv_utf8_lib" = "add-on" ; then
3346         AC_DEFINE(HAVE_LIBUTF8_H)
3347         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3348         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3349         CF_ADD_LIBS($cf_cv_library_file_utf8)
3350 fi
3351 ])dnl
3352 dnl ---------------------------------------------------------------------------
3353 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3354 dnl ----------
3355 dnl Use AC_VERBOSE w/o the warnings
3356 AC_DEFUN([CF_VERBOSE],
3357 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3358 CF_MSG_LOG([$1])
3359 ])dnl
3360 dnl ---------------------------------------------------------------------------
3361 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
3362 dnl ---------------
3363 dnl Check for compiler-support for weak symbols.
3364 dnl This works with "recent" gcc.
3365 AC_DEFUN([CF_WEAK_SYMBOLS],[
3366 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
3367
3368 AC_TRY_COMPILE([
3369 #include <stdio.h>],
3370 [
3371 #if defined(__GNUC__)
3372 #  if defined __USE_ISOC99
3373 #    define _cat_pragma(exp)    _Pragma(#exp)
3374 #    define _weak_pragma(exp)   _cat_pragma(weak name)
3375 #  else
3376 #    define _weak_pragma(exp)
3377 #  endif
3378 #  define _declare(name)        __extension__ extern __typeof__(name) name
3379 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
3380 #endif
3381
3382 weak_symbol(fopen);
3383 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
3384 ])
3385 ])dnl
3386 dnl ---------------------------------------------------------------------------
3387 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
3388 dnl --------------------
3389 dnl Command-line option to specify the Ada95 compiler.
3390 AC_DEFUN([CF_WITH_ADA_COMPILER],[
3391 AC_MSG_CHECKING(for ada-compiler)
3392 AC_ARG_WITH(ada-compiler,
3393         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
3394         [cf_ada_compiler=$withval],
3395         [cf_ada_compiler=gnatmake])
3396 AC_SUBST(cf_ada_compiler)
3397 AC_MSG_RESULT($cf_ada_compiler)
3398 ])dnl
3399 dnl ---------------------------------------------------------------------------
3400 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
3401 dnl -------------------
3402 dnl Command-line option to specify where Ada includes will install.
3403 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
3404 AC_MSG_CHECKING(for ada-include)
3405 CF_WITH_PATH(ada-include,
3406    [  --with-ada-include=DIR  Ada includes are in DIR],
3407    ADA_INCLUDE,
3408    PREFIX/share/ada/adainclude,
3409    [$]prefix/share/ada/adainclude)
3410 AC_SUBST(ADA_INCLUDE)
3411 AC_MSG_RESULT($ADA_INCLUDE)
3412 ])dnl
3413 dnl ---------------------------------------------------------------------------
3414 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
3415 dnl -------------------
3416 dnl Command-line option to specify where Ada objects will install.
3417 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
3418 AC_MSG_CHECKING(for ada-objects)
3419 CF_WITH_PATH(ada-objects,
3420    [  --with-ada-objects=DIR  Ada objects are in DIR],
3421    ADA_OBJECTS,
3422    PREFIX/lib/ada/adalib,
3423    [$]prefix/lib/ada/adalib)
3424 AC_SUBST(ADA_OBJECTS)
3425 AC_MSG_RESULT($ADA_OBJECTS)
3426 ])dnl
3427 dnl ---------------------------------------------------------------------------
3428 dnl CF_WITH_ADA_SHAREDLIB version: 2 updated: 2010/06/26 17:35:58
3429 dnl ---------------------
3430 dnl Command-line option to specify if an Ada95 shared-library should be built,
3431 dnl and optionally what its soname should be.
3432 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
3433 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
3434 AC_ARG_WITH(ada-sharedlib,
3435         [  --with-ada-sharedlib=XX build Ada95 shared-library],
3436         [with_ada_sharedlib=$withval],
3437         [with_ada_sharedlib=no])
3438 AC_MSG_RESULT($with_ada_sharedlib)
3439
3440 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
3441 MAKE_ADA_SHAREDLIB="#"
3442
3443 if test "x$with_ada_sharedlib" != xno
3444 then
3445         MAKE_ADA_SHAREDLIB=
3446         if test "x$with_ada_sharedlib" != xyes
3447         then
3448                 ADA_SHAREDLIB="$with_ada_sharedlib"
3449         fi
3450 fi
3451
3452 AC_SUBST(ADA_SHAREDLIB)
3453 AC_SUBST(MAKE_ADA_SHAREDLIB)
3454 ])dnl
3455 dnl ---------------------------------------------------------------------------
3456 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3457 dnl ------------------
3458 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3459 dnl libraries.
3460 AC_DEFUN([CF_WITH_CURSES_DIR],[
3461
3462 AC_MSG_CHECKING(for specific curses-directory)
3463 AC_ARG_WITH(curses-dir,
3464         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3465         [cf_cv_curses_dir=$withval],
3466         [cf_cv_curses_dir=no])
3467 AC_MSG_RESULT($cf_cv_curses_dir)
3468
3469 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3470 then
3471         CF_PATH_SYNTAX(withval)
3472         if test -d "$cf_cv_curses_dir"
3473         then
3474                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3475                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3476         fi
3477 fi
3478 ])dnl
3479 dnl ---------------------------------------------------------------------------
3480 dnl CF_WITH_PATH version: 10 updated: 2010/10/23 15:44:18
3481 dnl ------------
3482 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
3483 dnl defaulting to yes/no.
3484 dnl
3485 dnl $1 = option name
3486 dnl $2 = help-text
3487 dnl $3 = environment variable to set
3488 dnl $4 = default value, shown in the help-message, must be a constant
3489 dnl $5 = default value, if it's an expression & cannot be in the help-message
3490 dnl
3491 AC_DEFUN([CF_WITH_PATH],
3492 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
3493 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
3494 if ifelse([$5],,true,[test -n "$5"]) ; then
3495 CF_PATH_SYNTAX(withval)
3496 fi
3497 $3="$withval"
3498 AC_SUBST($3)dnl
3499 ])dnl
3500 dnl ---------------------------------------------------------------------------
3501 dnl CF_WITH_PTHREAD version: 3 updated: 2010/05/29 16:31:02
3502 dnl ---------------
3503 dnl Check for POSIX thread library.
3504 AC_DEFUN([CF_WITH_PTHREAD],
3505 [
3506 AC_MSG_CHECKING(if you want to link with the pthread library)
3507 AC_ARG_WITH(pthread,
3508     [  --with-pthread          use POSIX thread library],
3509     [with_pthread=$withval],
3510     [with_pthread=no])
3511 AC_MSG_RESULT($with_pthread)
3512
3513 if test "$with_pthread" != no ; then
3514     AC_CHECK_HEADER(pthread.h,[
3515         AC_DEFINE(HAVE_PTHREADS_H)
3516
3517         AC_MSG_CHECKING(if we can link with the pthread library)
3518         cf_save_LIBS="$LIBS"
3519         CF_ADD_LIB(pthread)
3520         AC_TRY_LINK([
3521 #include <pthread.h>
3522 ],[
3523         int rc = pthread_create(0,0,0,0);
3524 ],[with_pthread=yes],[with_pthread=no])
3525         LIBS="$cf_save_LIBS"
3526         AC_MSG_RESULT($with_pthread)
3527
3528         if test "$with_pthread" = yes ; then
3529             CF_ADD_LIB(pthread)
3530             AC_DEFINE(HAVE_LIBPTHREADS)
3531         else
3532             AC_MSG_ERROR(Cannot link with pthread library)
3533         fi
3534     ])
3535 fi
3536 ])
3537 dnl ---------------------------------------------------------------------------
3538 dnl CF_XOPEN_SOURCE version: 36 updated: 2011/07/02 15:36:04
3539 dnl ---------------
3540 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
3541 dnl or adapt to the vendor's definitions to get equivalent functionality,
3542 dnl without losing the common non-POSIX features.
3543 dnl
3544 dnl Parameters:
3545 dnl     $1 is the nominal value for _XOPEN_SOURCE
3546 dnl     $2 is the nominal value for _POSIX_C_SOURCE
3547 AC_DEFUN([CF_XOPEN_SOURCE],[
3548
3549 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
3550 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
3551 cf_xopen_source=
3552
3553 case $host_os in #(vi
3554 aix[[4-7]]*) #(vi
3555         cf_xopen_source="-D_ALL_SOURCE"
3556         ;;
3557 cygwin) #(vi
3558         cf_XOPEN_SOURCE=600
3559         ;;
3560 darwin[[0-8]].*) #(vi
3561         cf_xopen_source="-D_APPLE_C_SOURCE"
3562         ;;
3563 darwin*) #(vi
3564         cf_xopen_source="-D_DARWIN_C_SOURCE"
3565         ;;
3566 freebsd*|dragonfly*) #(vi
3567         # 5.x headers associate
3568         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
3569         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
3570         cf_POSIX_C_SOURCE=200112L
3571         cf_XOPEN_SOURCE=600
3572         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3573         ;;
3574 hpux11*) #(vi
3575         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
3576         ;;
3577 hpux*) #(vi
3578         cf_xopen_source="-D_HPUX_SOURCE"
3579         ;;
3580 irix[[56]].*) #(vi
3581         cf_xopen_source="-D_SGI_SOURCE"
3582         ;;
3583 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
3584         CF_GNU_SOURCE
3585         ;;
3586 mirbsd*) #(vi
3587         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <arpa/inet.h>
3588         ;;
3589 netbsd*) #(vi
3590         # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
3591         ;;
3592 openbsd*) #(vi
3593         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
3594         ;;
3595 osf[[45]]*) #(vi
3596         cf_xopen_source="-D_OSF_SOURCE"
3597         ;;
3598 nto-qnx*) #(vi
3599         cf_xopen_source="-D_QNX_SOURCE"
3600         ;;
3601 sco*) #(vi
3602         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
3603         ;;
3604 solaris2.1[[0-9]]) #(vi
3605         cf_xopen_source="-D__EXTENSIONS__ -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3606         ;;
3607 solaris2.[[1-9]]) #(vi
3608         cf_xopen_source="-D__EXTENSIONS__"
3609         ;;
3610 *)
3611         AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3612         AC_TRY_COMPILE([#include <sys/types.h>],[
3613 #ifndef _XOPEN_SOURCE
3614 make an error
3615 #endif],
3616         [cf_cv_xopen_source=no],
3617         [cf_save="$CPPFLAGS"
3618          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3619          AC_TRY_COMPILE([#include <sys/types.h>],[
3620 #ifdef _XOPEN_SOURCE
3621 make an error
3622 #endif],
3623         [cf_cv_xopen_source=no],
3624         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3625         CPPFLAGS="$cf_save"
3626         ])
3627 ])
3628         if test "$cf_cv_xopen_source" != no ; then
3629                 CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3630                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3631                 cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3632                 CF_ADD_CFLAGS($cf_temp_xopen_source)
3633         fi
3634         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3635         ;;
3636 esac
3637
3638 if test -n "$cf_xopen_source" ; then
3639         CF_ADD_CFLAGS($cf_xopen_source)
3640 fi
3641 ])