Ada95/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 2010-2014,2015 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.109 2015/11/01 01:03:41 tom Exp $
  32 dnl Macros used in NCURSES Ada95 auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
  43 dnl ------------------
  44 dnl Conditionally generate script according to whether we're using a given autoconf.
  45 dnl
  46 dnl $1 = version to compare against
  47 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  48 dnl $3 = code to use if AC_ACVERSION is older than $1.
  49 define([CF_ACVERSION_CHECK],
  50 [
  51 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
  52 ifdef([m4_version_compare],
  53 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  54 [CF_ACVERSION_COMPARE(
  55 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  56 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  57 dnl ---------------------------------------------------------------------------
  58 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  59 dnl --------------------
  60 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  61 dnl                      MAJOR2, MINOR2, TERNARY2,
  62 dnl                      PRINTABLE2, not FOUND, FOUND)
  63 define([CF_ACVERSION_COMPARE],
  64 [ifelse(builtin([eval], [$2 < $5]), 1,
  65 [ifelse([$8], , ,[$8])],
  66 [ifelse([$9], , ,[$9])])])dnl
  67 dnl ---------------------------------------------------------------------------
  68 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
  69 dnl -------------------
  70 dnl Construct the list of include-options for the C programs in the Ada95
  71 dnl binding.
  72 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  73 [
  74 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  75 if test "$srcdir" != "."; then
  76         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  77 fi
  78 if test "$GCC" != yes; then
  79         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  80 elif test "$includedir" != "/usr/include"; then
  81         if test "$includedir" = '${prefix}/include' ; then
  82                 if test x$prefix != x/usr ; then
  83                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  84                 fi
  85         else
  86                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  87         fi
  88 fi
  89 AC_SUBST(ACPPFLAGS)
  90 ])dnl
  91 dnl ---------------------------------------------------------------------------
  92 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
  93 dnl ---------------
  94 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
  95 AC_DEFUN([CF_ADD_ADAFLAGS],[
  96         ADAFLAGS="$ADAFLAGS $1"
  97         AC_SUBST(ADAFLAGS)
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ADD_CFLAGS version: 12 updated: 2015/04/12 15:39:00
 101 dnl -------------
 102 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 103 dnl The second parameter if given makes this macro verbose.
 104 dnl
 105 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 106 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 107 dnl confused by the quotes (which require backslashes to keep them usable).
 108 AC_DEFUN([CF_ADD_CFLAGS],
 109 [
 110 cf_fix_cppflags=no
 111 cf_new_cflags=
 112 cf_new_cppflags=
 113 cf_new_extra_cppflags=
 114
 115 for cf_add_cflags in $1
 116 do
 117 case $cf_fix_cppflags in
 118 (no)
 119         case $cf_add_cflags in
 120         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 121                 case $cf_add_cflags in
 122                 (-D*)
 123                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 124
 125                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 126                                 && test -z "${cf_tst_cflags}" \
 127                                 && cf_fix_cppflags=yes
 128
 129                         if test $cf_fix_cppflags = yes ; then
 130                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 131                                 continue
 132                         elif test "${cf_tst_cflags}" = "\"'" ; then
 133                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 134                                 continue
 135                         fi
 136                         ;;
 137                 esac
 138                 case "$CPPFLAGS" in
 139                 (*$cf_add_cflags)
 140                         ;;
 141                 (*)
 142                         case $cf_add_cflags in
 143                         (-D*)
 144                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 145                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 146                                 ;;
 147                         esac
 148                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 149                         ;;
 150                 esac
 151                 ;;
 152         (*)
 153                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 154                 ;;
 155         esac
 156         ;;
 157 (yes)
 158         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 159
 160         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 161
 162         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 163                 && test -z "${cf_tst_cflags}" \
 164                 && cf_fix_cppflags=no
 165         ;;
 166 esac
 167 done
 168
 169 if test -n "$cf_new_cflags" ; then
 170         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 171         CFLAGS="$CFLAGS $cf_new_cflags"
 172 fi
 173
 174 if test -n "$cf_new_cppflags" ; then
 175         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 176         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 177 fi
 178
 179 if test -n "$cf_new_extra_cppflags" ; then
 180         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 181         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 182 fi
 183
 184 AC_SUBST(EXTRA_CPPFLAGS)
 185
 186 ])dnl
 187 dnl ---------------------------------------------------------------------------
 188 dnl CF_ADD_INCDIR version: 14 updated: 2015/05/25 20:53:04
 189 dnl -------------
 190 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 191 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 192 dnl but old versions (and some misinstalled ones) need that.  To make things
 193 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 194 dnl the include-path).
 195 AC_DEFUN([CF_ADD_INCDIR],
 196 [
 197 if test -n "$1" ; then
 198   for cf_add_incdir in $1
 199   do
 200         while test $cf_add_incdir != /usr/include
 201         do
 202           if test -d $cf_add_incdir
 203           then
 204                 cf_have_incdir=no
 205                 if test -n "$CFLAGS$CPPFLAGS" ; then
 206                   # a loop is needed to ensure we can add subdirs of existing dirs
 207                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 208                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 209                           cf_have_incdir=yes; break
 210                         fi
 211                   done
 212                 fi
 213
 214                 if test "$cf_have_incdir" = no ; then
 215                   if test "$cf_add_incdir" = /usr/local/include ; then
 216                         if test "$GCC" = yes
 217                         then
 218                           cf_save_CPPFLAGS=$CPPFLAGS
 219                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 220                           AC_TRY_COMPILE([#include <stdio.h>],
 221                                   [printf("Hello")],
 222                                   [],
 223                                   [cf_have_incdir=yes])
 224                           CPPFLAGS=$cf_save_CPPFLAGS
 225                         fi
 226                   fi
 227                 fi
 228
 229                 if test "$cf_have_incdir" = no ; then
 230                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 231                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 232
 233                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 234                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 235                   cf_add_incdir="$cf_top_incdir"
 236                 else
 237                   break
 238                 fi
 239           else
 240                 break
 241           fi
 242         done
 243   done
 244 fi
 245 ])dnl
 246 dnl ---------------------------------------------------------------------------
 247 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 248 dnl ----------
 249 dnl Add a library, used to enforce consistency.
 250 dnl
 251 dnl $1 = library to add, without the "-l"
 252 dnl $2 = variable to update (default $LIBS)
 253 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 254 dnl ---------------------------------------------------------------------------
 255 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 256 dnl -------------
 257 dnl     Adds to the library-path
 258 dnl
 259 dnl     Some machines have trouble with multiple -L options.
 260 dnl
 261 dnl $1 is the (list of) directory(s) to add
 262 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 263 dnl
 264 AC_DEFUN([CF_ADD_LIBDIR],
 265 [
 266 if test -n "$1" ; then
 267         for cf_add_libdir in $1
 268         do
 269                 if test $cf_add_libdir = /usr/lib ; then
 270                         :
 271                 elif test -d $cf_add_libdir
 272                 then
 273                         cf_have_libdir=no
 274                         if test -n "$LDFLAGS$LIBS" ; then
 275                                 # a loop is needed to ensure we can add subdirs of existing dirs
 276                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 277                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 278                                                 cf_have_libdir=yes; break
 279                                         fi
 280                                 done
 281                         fi
 282                         if test "$cf_have_libdir" = no ; then
 283                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 284                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 285                         fi
 286                 fi
 287         done
 288 fi
 289 ])dnl
 290 dnl ---------------------------------------------------------------------------
 291 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 292 dnl -----------
 293 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 294 dnl prepended to an existing list, since their dependencies are assumed to
 295 dnl already exist in the list.
 296 dnl
 297 dnl $1 = libraries to add, with the "-l", etc.
 298 dnl $2 = variable to update (default $LIBS)
 299 AC_DEFUN([CF_ADD_LIBS],[
 300 cf_add_libs="$1"
 301 # Filter out duplicates - this happens with badly-designed ".pc" files...
 302 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 303 do
 304         for cf_add_2lib in $cf_add_libs
 305         do
 306                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 307                 then
 308                         cf_add_1lib=
 309                         break
 310                 fi
 311         done
 312         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 313 done
 314 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 315 ])dnl
 316 dnl ---------------------------------------------------------------------------
 317 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 318 dnl ------------------
 319 dnl Append to a search-list for a nonstandard header/lib-file
 320 dnl     $1 = the variable to return as result
 321 dnl     $2 = the package name
 322 dnl     $3 = the subdirectory, e.g., bin, include or lib
 323 dnl $4 = the directory under which we will test for subdirectories
 324 dnl $5 = a directory that we do not want $4 to match
 325 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 326 [
 327 test "x$4" != "x$5" && \
 328 test -d "$4" && \
 329 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 330         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 331         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 332         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 333         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 334         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 335         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 336 }
 337 ])dnl
 338 dnl ---------------------------------------------------------------------------
 339 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 340 dnl --------------
 341 dnl Allow user to disable a normally-on option.
 342 AC_DEFUN([CF_ARG_DISABLE],
 343 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 344 dnl ---------------------------------------------------------------------------
 345 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 346 dnl -------------
 347 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 348 dnl values.
 349 dnl
 350 dnl Parameters:
 351 dnl $1 = option name
 352 dnl $2 = help-string
 353 dnl $3 = action to perform if option is not default
 354 dnl $4 = action if perform if option is default
 355 dnl $5 = default option value (either 'yes' or 'no')
 356 AC_DEFUN([CF_ARG_OPTION],
 357 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 358         if test "$enableval" != "$5" ; then
 359 ifelse([$3],,[    :]dnl
 360 ,[    $3]) ifelse([$4],,,[
 361         else
 362                 $4])
 363         fi],[enableval=$5 ifelse([$4],,,[
 364         $4
 365 ])dnl
 366 ])])dnl
 367 dnl ---------------------------------------------------------------------------
 368 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 369 dnl -----------
 370 dnl Check for suitable "ar" (archiver) options for updating an archive.
 371 dnl
 372 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 373 dnl as well as a workaround for breakage of make's archive rules by the GNU
 374 dnl binutils "ar" program.
 375 AC_DEFUN([CF_AR_FLAGS],[
 376 AC_REQUIRE([CF_PROG_AR])
 377
 378 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 379         cf_cv_ar_flags=unknown
 380         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 381         do
 382
 383                 # check if $ARFLAGS already contains this choice
 384                 if test "x$ARFLAGS" != "x" ; then
 385                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 386                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 387                                 cf_cv_ar_flags=
 388                                 break
 389                         fi
 390                 fi
 391
 392                 rm -f conftest.$ac_cv_objext
 393                 rm -f conftest.a
 394
 395                 cat >conftest.$ac_ext <<EOF
 396 #line __oline__ "configure"
 397 int     testdata[[3]] = { 123, 456, 789 };
 398 EOF
 399                 if AC_TRY_EVAL(ac_compile) ; then
 400                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 401                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 402                         if test -f conftest.a ; then
 403                                 cf_cv_ar_flags=$cf_ar_flags
 404                                 break
 405                         fi
 406                 else
 407                         CF_VERBOSE(cannot compile test-program)
 408                         break
 409                 fi
 410         done
 411         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 412 ])
 413
 414 if test -n "$ARFLAGS" ; then
 415         if test -n "$cf_cv_ar_flags" ; then
 416                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 417         fi
 418 else
 419         ARFLAGS=$cf_cv_ar_flags
 420 fi
 421
 422 AC_SUBST(ARFLAGS)
 423 ])
 424 dnl ---------------------------------------------------------------------------
 425 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 426 dnl -----------
 427 dnl If we're cross-compiling, allow the user to override the tools and their
 428 dnl options.  The configure script is oriented toward identifying the host
 429 dnl compiler, etc., but we need a build compiler to generate parts of the
 430 dnl source.
 431 dnl
 432 dnl $1 = default for $CPPFLAGS
 433 dnl $2 = default for $LIBS
 434 AC_DEFUN([CF_BUILD_CC],[
 435 CF_ACVERSION_CHECK(2.52,,
 436         [AC_REQUIRE([CF_PROG_EXT])])
 437 if test "$cross_compiling" = yes ; then
 438
 439         # defaults that we might want to override
 440         : ${BUILD_CFLAGS:=''}
 441         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 442         : ${BUILD_LDFLAGS:=''}
 443         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 444         : ${BUILD_EXEEXT:='$x'}
 445         : ${BUILD_OBJEXT:='o'}
 446
 447         AC_ARG_WITH(build-cc,
 448                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 449                 [BUILD_CC="$withval"],
 450                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 451         AC_MSG_CHECKING(for native build C compiler)
 452         AC_MSG_RESULT($BUILD_CC)
 453
 454         AC_MSG_CHECKING(for native build C preprocessor)
 455         AC_ARG_WITH(build-cpp,
 456                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 457                 [BUILD_CPP="$withval"],
 458                 [BUILD_CPP='${BUILD_CC} -E'])
 459         AC_MSG_RESULT($BUILD_CPP)
 460
 461         AC_MSG_CHECKING(for native build C flags)
 462         AC_ARG_WITH(build-cflags,
 463                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 464                 [BUILD_CFLAGS="$withval"])
 465         AC_MSG_RESULT($BUILD_CFLAGS)
 466
 467         AC_MSG_CHECKING(for native build C preprocessor-flags)
 468         AC_ARG_WITH(build-cppflags,
 469                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 470                 [BUILD_CPPFLAGS="$withval"])
 471         AC_MSG_RESULT($BUILD_CPPFLAGS)
 472
 473         AC_MSG_CHECKING(for native build linker-flags)
 474         AC_ARG_WITH(build-ldflags,
 475                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 476                 [BUILD_LDFLAGS="$withval"])
 477         AC_MSG_RESULT($BUILD_LDFLAGS)
 478
 479         AC_MSG_CHECKING(for native build linker-libraries)
 480         AC_ARG_WITH(build-libs,
 481                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 482                 [BUILD_LIBS="$withval"])
 483         AC_MSG_RESULT($BUILD_LIBS)
 484
 485         # this assumes we're on Unix.
 486         BUILD_EXEEXT=
 487         BUILD_OBJEXT=o
 488
 489         : ${BUILD_CC:='${CC}'}
 490
 491         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 492                 AC_MSG_ERROR([Cross-build requires two compilers.
 493 Use --with-build-cc to specify the native compiler.])
 494         fi
 495
 496 else
 497         : ${BUILD_CC:='${CC}'}
 498         : ${BUILD_CPP:='${CPP}'}
 499         : ${BUILD_CFLAGS:='${CFLAGS}'}
 500         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 501         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 502         : ${BUILD_LIBS:='${LIBS}'}
 503         : ${BUILD_EXEEXT:='$x'}
 504         : ${BUILD_OBJEXT:='o'}
 505 fi
 506
 507 AC_SUBST(BUILD_CC)
 508 AC_SUBST(BUILD_CPP)
 509 AC_SUBST(BUILD_CFLAGS)
 510 AC_SUBST(BUILD_CPPFLAGS)
 511 AC_SUBST(BUILD_LDFLAGS)
 512 AC_SUBST(BUILD_LIBS)
 513 AC_SUBST(BUILD_EXEEXT)
 514 AC_SUBST(BUILD_OBJEXT)
 515 ])dnl
 516 dnl ---------------------------------------------------------------------------
 517 dnl CF_CC_ENV_FLAGS version: 2 updated: 2015/04/12 15:39:00
 518 dnl ---------------
 519 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 520 dnl into CC.  This will not help with broken scripts that wrap the compiler with
 521 dnl options, but eliminates a more common category of user confusion.
 522 AC_DEFUN([CF_CC_ENV_FLAGS],
 523 [
 524 # This should have been defined by AC_PROG_CC
 525 : ${CC:=cc}
 526
 527 AC_MSG_CHECKING(\$CC variable)
 528 case "$CC" in
 529 (*[[\ \ ]]-[[IUD]]*)
 530         AC_MSG_RESULT(broken)
 531         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 532         # humor him...
 533         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 534         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 535         CF_ADD_CFLAGS($cf_flags)
 536         ;;
 537 (*)
 538         AC_MSG_RESULT(ok)
 539         ;;
 540 esac
 541 ])dnl
 542 dnl ---------------------------------------------------------------------------
 543 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 544 dnl ---------------
 545 dnl Determine the default configuration into which we'll install ncurses.  This
 546 dnl can be overridden by the user's command-line options.  There's two items to
 547 dnl look for:
 548 dnl     1. the prefix (e.g., /usr)
 549 dnl     2. the header files (e.g., /usr/include/ncurses)
 550 dnl We'll look for a previous installation of ncurses and use the same defaults.
 551 dnl
 552 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 553 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 554 dnl programs from a vendor's.
 555 AC_DEFUN([CF_CFG_DEFAULTS],
 556 [
 557 AC_MSG_CHECKING(for prefix)
 558 if test "x$prefix" = "xNONE" ; then
 559         case "$cf_cv_system_name" in
 560                 # non-vendor systems don't have a conflict
 561         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 562                 prefix=/usr
 563                 ;;
 564         (*)     prefix=$ac_default_prefix
 565                 ;;
 566         esac
 567 fi
 568 AC_MSG_RESULT($prefix)
 569
 570 if test "x$prefix" = "xNONE" ; then
 571 AC_MSG_CHECKING(for default include-directory)
 572 test -n "$verbose" && echo 1>&AC_FD_MSG
 573 for cf_symbol in \
 574         $includedir \
 575         $includedir/ncurses \
 576         $prefix/include \
 577         $prefix/include/ncurses \
 578         /usr/local/include \
 579         /usr/local/include/ncurses \
 580         /usr/include \
 581         /usr/include/ncurses
 582 do
 583         cf_dir=`eval echo $cf_symbol`
 584         if test -f $cf_dir/curses.h ; then
 585         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 586                 includedir="$cf_symbol"
 587                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 588                 break
 589         fi
 590         fi
 591         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 592 done
 593 AC_MSG_RESULT($includedir)
 594 fi
 595 ])dnl
 596 dnl ---------------------------------------------------------------------------
 597 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 598 dnl --------------
 599 dnl Check if we're accidentally using a cache from a different machine.
 600 dnl Derive the system name, as a check for reusing the autoconf cache.
 601 dnl
 602 dnl If we've packaged config.guess and config.sub, run that (since it does a
 603 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 604 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 605 dnl which is useful in cross-compiles.
 606 dnl
 607 dnl Note: we would use $ac_config_sub, but that is one of the places where
 608 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 609 AC_DEFUN([CF_CHECK_CACHE],
 610 [
 611 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 612         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 613         system_name="$host_os"
 614 else
 615         system_name="`(uname -s -r) 2>/dev/null`"
 616         if test -z "$system_name" ; then
 617                 system_name="`(hostname) 2>/dev/null`"
 618         fi
 619 fi
 620 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 621 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 622
 623 test -z "$system_name" && system_name="$cf_cv_system_name"
 624 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 625
 626 if test ".$system_name" != ".$cf_cv_system_name" ; then
 627         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 628         AC_MSG_ERROR("Please remove config.cache and try again.")
 629 fi
 630 ])dnl
 631 dnl ---------------------------------------------------------------------------
 632 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
 633 dnl -----------------
 634 dnl Check if the given compiler is really clang.  clang's C driver defines
 635 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 636 dnl not ignore some gcc options.
 637 dnl
 638 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 639 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 640 dnl the wrappers for gcc and g++ warnings.
 641 dnl
 642 dnl $1 = GCC (default) or GXX
 643 dnl $2 = CLANG_COMPILER (default)
 644 dnl $3 = CFLAGS (default) or CXXFLAGS
 645 AC_DEFUN([CF_CLANG_COMPILER],[
 646 ifelse([$2],,CLANG_COMPILER,[$2])=no
 647
 648 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 649         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 650         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 651         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 652         AC_TRY_COMPILE([],[
 653 #ifdef __clang__
 654 #else
 655 make an error
 656 #endif
 657 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 658 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
 659 ],[])
 660         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 661         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 662 fi
 663 ])
 664 dnl ---------------------------------------------------------------------------
 665 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
 666 dnl ----------------
 667 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 668 dnl variations of ncurses' installs.
 669 dnl
 670 dnl $1 = ncurses when looking for ncurses, or is empty
 671 AC_DEFUN([CF_CURSES_HEADER],[
 672 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 673 cf_cv_ncurses_header=none
 674 for cf_header in \
 675         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
 676         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 677 do
 678 AC_TRY_COMPILE([#include <${cf_header}>],
 679         [initscr(); tgoto("?", 0,0)],
 680         [cf_cv_ncurses_header=$cf_header; break],[])
 681 done
 682 ])
 683
 684 if test "$cf_cv_ncurses_header" = none ; then
 685         AC_MSG_ERROR(No curses header-files found)
 686 fi
 687
 688 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 689 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 690 ])dnl
 691 dnl ---------------------------------------------------------------------------
 692 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
 693 dnl ----------
 694 dnl "dirname" is not portable, so we fake it with a shell script.
 695 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
 696 dnl ---------------------------------------------------------------------------
 697 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
 698 dnl ---------------
 699 dnl You can always use "make -n" to see the actual options, but it's hard to
 700 dnl pick out/analyze warning messages when the compile-line is long.
 701 dnl
 702 dnl Sets:
 703 dnl     ECHO_LT - symbol to control if libtool is verbose
 704 dnl     ECHO_LD - symbol to prefix "cc -o" lines
 705 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
 706 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
 707 dnl     ECHO_CC - symbol to put before any "cc" line
 708 dnl
 709 AC_DEFUN([CF_DISABLE_ECHO],[
 710 AC_MSG_CHECKING(if you want to see long compiling messages)
 711 CF_ARG_DISABLE(echo,
 712         [  --disable-echo          do not display "compiling" commands],
 713         [
 714         ECHO_LT='--silent'
 715         ECHO_LD='@echo linking [$]@;'
 716         RULE_CC='@echo compiling [$]<'
 717         SHOW_CC='@echo compiling [$]@'
 718         ECHO_CC='@'
 719 ],[
 720         ECHO_LT=''
 721         ECHO_LD=''
 722         RULE_CC=''
 723         SHOW_CC=''
 724         ECHO_CC=''
 725 ])
 726 AC_MSG_RESULT($enableval)
 727 AC_SUBST(ECHO_LT)
 728 AC_SUBST(ECHO_LD)
 729 AC_SUBST(RULE_CC)
 730 AC_SUBST(SHOW_CC)
 731 AC_SUBST(ECHO_CC)
 732 ])dnl
 733 dnl ---------------------------------------------------------------------------
 734 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
 735 dnl ------------------------
 736 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
 737 AC_MSG_CHECKING(if we want to use GNAT projects)
 738 CF_ARG_DISABLE(gnat-projects,
 739         [  --disable-gnat-projects test: disable GNAT projects even if usable],
 740         [enable_gnat_projects=no],
 741         [enable_gnat_projects=yes])
 742 AC_MSG_RESULT($enable_gnat_projects)
 743 ])dnl
 744 dnl ---------------------------------------------------------------------------
 745 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
 746 dnl ---------------
 747 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
 748 dnl prefer a standard location, and use -L options only if we do not find the
 749 dnl library in the standard library location(s).
 750 dnl     $1 = library name
 751 dnl     $2 = library class, usually the same as library name
 752 dnl     $3 = includes
 753 dnl     $4 = code fragment to compile/link
 754 dnl     $5 = corresponding function-name
 755 dnl     $6 = flag, nonnull if failure should not cause an error-exit
 756 dnl
 757 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
 758 dnl to use a -L option.
 759 AC_DEFUN([CF_FIND_LIBRARY],
 760 [
 761         eval 'cf_cv_have_lib_'$1'=no'
 762         cf_libdir=""
 763         AC_CHECK_FUNC($5,
 764                 eval 'cf_cv_have_lib_'$1'=yes',[
 765                 cf_save_LIBS="$LIBS"
 766                 AC_MSG_CHECKING(for $5 in -l$1)
 767                 LIBS="-l$1 $LIBS"
 768                 AC_TRY_LINK([$3],[$4],
 769                         [AC_MSG_RESULT(yes)
 770                          eval 'cf_cv_have_lib_'$1'=yes'
 771                         ],
 772                         [AC_MSG_RESULT(no)
 773                         CF_LIBRARY_PATH(cf_search,$2)
 774                         for cf_libdir in $cf_search
 775                         do
 776                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
 777                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
 778                                 AC_TRY_LINK([$3],[$4],
 779                                         [AC_MSG_RESULT(yes)
 780                                          eval 'cf_cv_have_lib_'$1'=yes'
 781                                          break],
 782                                         [AC_MSG_RESULT(no)
 783                                          LIBS="$cf_save_LIBS"])
 784                         done
 785                         ])
 786                 ])
 787 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
 788 ifelse($6,,[
 789 if test $cf_found_library = no ; then
 790         AC_MSG_ERROR(Cannot link $1 library)
 791 fi
 792 ])
 793 ])dnl
 794 dnl ---------------------------------------------------------------------------
 795 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
 796 dnl ---------------
 797 dnl Find a library (specifically the linkage used in the code fragment),
 798 dnl searching for it if it is not already in the library path.
 799 dnl See also CF_ADD_SEARCHPATH.
 800 dnl
 801 dnl Parameters (4-on are optional):
 802 dnl     $1 = headers for library entrypoint
 803 dnl     $2 = code fragment for library entrypoint
 804 dnl     $3 = the library name without the "-l" option or ".so" suffix.
 805 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
 806 dnl     $5 = action to perform if not successful
 807 dnl     $6 = module name, if not the same as the library name
 808 dnl     $7 = extra libraries
 809 dnl
 810 dnl Sets these variables:
 811 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
 812 dnl     $cf_cv_header_path_$3 - include-directory if needed
 813 dnl     $cf_cv_library_path_$3 - library-directory if needed
 814 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
 815 AC_DEFUN([CF_FIND_LINKAGE],[
 816
 817 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
 818 # will be set on completion of the AC_TRY_LINK below.
 819 cf_cv_header_path_$3=
 820 cf_cv_library_path_$3=
 821
 822 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
 823
 824 cf_save_LIBS="$LIBS"
 825
 826 AC_TRY_LINK([$1],[$2],[
 827         cf_cv_find_linkage_$3=yes
 828         cf_cv_header_path_$3=/usr/include
 829         cf_cv_library_path_$3=/usr/lib
 830 ],[
 831
 832 LIBS="-l$3 $7 $cf_save_LIBS"
 833
 834 AC_TRY_LINK([$1],[$2],[
 835         cf_cv_find_linkage_$3=yes
 836         cf_cv_header_path_$3=/usr/include
 837         cf_cv_library_path_$3=/usr/lib
 838         cf_cv_library_file_$3="-l$3"
 839 ],[
 840         cf_cv_find_linkage_$3=no
 841         LIBS="$cf_save_LIBS"
 842
 843         CF_VERBOSE(find linkage for $3 library)
 844         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
 845
 846         cf_save_CPPFLAGS="$CPPFLAGS"
 847         cf_test_CPPFLAGS="$CPPFLAGS"
 848
 849         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
 850         for cf_cv_header_path_$3 in $cf_search
 851         do
 852                 if test -d $cf_cv_header_path_$3 ; then
 853                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
 854                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
 855                         AC_TRY_COMPILE([$1],[$2],[
 856                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
 857                                 cf_cv_find_linkage_$3=maybe
 858                                 cf_test_CPPFLAGS="$CPPFLAGS"
 859                                 break],[
 860                                 CPPFLAGS="$cf_save_CPPFLAGS"
 861                                 ])
 862                 fi
 863         done
 864
 865         if test "$cf_cv_find_linkage_$3" = maybe ; then
 866
 867                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
 868
 869                 cf_save_LIBS="$LIBS"
 870                 cf_save_LDFLAGS="$LDFLAGS"
 871
 872                 ifelse([$6],,,[
 873                 CPPFLAGS="$cf_test_CPPFLAGS"
 874                 LIBS="-l$3 $7 $cf_save_LIBS"
 875                 AC_TRY_LINK([$1],[$2],[
 876                         CF_VERBOSE(... found $3 library in system)
 877                         cf_cv_find_linkage_$3=yes])
 878                         CPPFLAGS="$cf_save_CPPFLAGS"
 879                         LIBS="$cf_save_LIBS"
 880                         ])
 881
 882                 if test "$cf_cv_find_linkage_$3" != yes ; then
 883                         CF_LIBRARY_PATH(cf_search,$3)
 884                         for cf_cv_library_path_$3 in $cf_search
 885                         do
 886                                 if test -d $cf_cv_library_path_$3 ; then
 887                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
 888                                         CPPFLAGS="$cf_test_CPPFLAGS"
 889                                         LIBS="-l$3 $7 $cf_save_LIBS"
 890                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
 891                                         AC_TRY_LINK([$1],[$2],[
 892                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
 893                                         cf_cv_find_linkage_$3=yes
 894                                         cf_cv_library_file_$3="-l$3"
 895                                         break],[
 896                                         CPPFLAGS="$cf_save_CPPFLAGS"
 897                                         LIBS="$cf_save_LIBS"
 898                                         LDFLAGS="$cf_save_LDFLAGS"
 899                                         ])
 900                                 fi
 901                         done
 902                         CPPFLAGS="$cf_save_CPPFLAGS"
 903                         LDFLAGS="$cf_save_LDFLAGS"
 904                 fi
 905
 906         else
 907                 cf_cv_find_linkage_$3=no
 908         fi
 909         ],$7)
 910 ])
 911
 912 LIBS="$cf_save_LIBS"
 913
 914 if test "$cf_cv_find_linkage_$3" = yes ; then
 915 ifelse([$4],,[
 916         CF_ADD_INCDIR($cf_cv_header_path_$3)
 917         CF_ADD_LIBDIR($cf_cv_library_path_$3)
 918         CF_ADD_LIB($3)
 919 ],[$4])
 920 else
 921 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
 922 fi
 923 ])dnl
 924 dnl ---------------------------------------------------------------------------
 925 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
 926 dnl -----------------
 927 dnl make ADAFLAGS consistent with CFLAGS
 928 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
 929         AC_MSG_CHECKING(optimization options for ADAFLAGS)
 930         case "$CFLAGS" in
 931         (*-g*)
 932                 CF_ADD_ADAFLAGS(-g)
 933                 ;;
 934         esac
 935         case "$CFLAGS" in
 936         (*-O*)
 937                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
 938                 CF_ADD_ADAFLAGS($cf_O_flag)
 939                 ;;
 940         esac
 941         AC_MSG_RESULT($ADAFLAGS)
 942 ])dnl
 943 dnl ---------------------------------------------------------------------------
 944 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
 945 dnl -----------------
 946 dnl Test for availability of useful gcc __attribute__ directives to quiet
 947 dnl compiler warnings.  Though useful, not all are supported -- and contrary
 948 dnl to documentation, unrecognized directives cause older compilers to barf.
 949 AC_DEFUN([CF_GCC_ATTRIBUTES],
 950 [
 951 if test "$GCC" = yes
 952 then
 953 cat > conftest.i <<EOF
 954 #ifndef GCC_PRINTF
 955 #define GCC_PRINTF 0
 956 #endif
 957 #ifndef GCC_SCANF
 958 #define GCC_SCANF 0
 959 #endif
 960 #ifndef GCC_NORETURN
 961 #define GCC_NORETURN /* nothing */
 962 #endif
 963 #ifndef GCC_UNUSED
 964 #define GCC_UNUSED /* nothing */
 965 #endif
 966 EOF
 967 if test "$GCC" = yes
 968 then
 969         AC_CHECKING([for $CC __attribute__ directives])
 970 cat > conftest.$ac_ext <<EOF
 971 #line __oline__ "${as_me:-configure}"
 972 #include "confdefs.h"
 973 #include "conftest.h"
 974 #include "conftest.i"
 975 #if     GCC_PRINTF
 976 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
 977 #else
 978 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
 979 #endif
 980 #if     GCC_SCANF
 981 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
 982 #else
 983 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
 984 #endif
 985 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
 986 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
 987 extern void foo(void) GCC_NORETURN;
 988 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
 989 EOF
 990         cf_printf_attribute=no
 991         cf_scanf_attribute=no
 992         for cf_attribute in scanf printf unused noreturn
 993         do
 994                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
 995                 cf_directive="__attribute__(($cf_attribute))"
 996                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
 997
 998                 case $cf_attribute in
 999                 (printf)
1000                         cf_printf_attribute=yes
1001                         cat >conftest.h <<EOF
1002 #define GCC_$cf_ATTRIBUTE 1
1003 EOF
1004                         ;;
1005                 (scanf)
1006                         cf_scanf_attribute=yes
1007                         cat >conftest.h <<EOF
1008 #define GCC_$cf_ATTRIBUTE 1
1009 EOF
1010                         ;;
1011                 (*)
1012                         cat >conftest.h <<EOF
1013 #define GCC_$cf_ATTRIBUTE $cf_directive
1014 EOF
1015                         ;;
1016                 esac
1017
1018                 if AC_TRY_EVAL(ac_compile); then
1019                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1020                         cat conftest.h >>confdefs.h
1021                         case $cf_attribute in
1022                         (noreturn)
1023                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1024                                 ;;
1025                         (printf)
1026                                 cf_value='/* nothing */'
1027                                 if test "$cf_printf_attribute" != no ; then
1028                                         cf_value='__attribute__((format(printf,fmt,var)))'
1029                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1030                                 fi
1031                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1032                                 ;;
1033                         (scanf)
1034                                 cf_value='/* nothing */'
1035                                 if test "$cf_scanf_attribute" != no ; then
1036                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1037                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1038                                 fi
1039                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1040                                 ;;
1041                         (unused)
1042                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1043                                 ;;
1044                         esac
1045                 fi
1046         done
1047 else
1048         fgrep define conftest.i >>confdefs.h
1049 fi
1050 rm -rf conftest*
1051 fi
1052 ])dnl
1053 dnl ---------------------------------------------------------------------------
1054 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1055 dnl --------------
1056 dnl Find version of gcc
1057 AC_DEFUN([CF_GCC_VERSION],[
1058 AC_REQUIRE([AC_PROG_CC])
1059 GCC_VERSION=none
1060 if test "$GCC" = yes ; then
1061         AC_MSG_CHECKING(version of $CC)
1062         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1063         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1064         AC_MSG_RESULT($GCC_VERSION)
1065 fi
1066 ])dnl
1067 dnl ---------------------------------------------------------------------------
1068 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
1069 dnl ---------------
1070 dnl Check if the compiler supports useful warning options.  There's a few that
1071 dnl we don't use, simply because they're too noisy:
1072 dnl
1073 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1074 dnl     -Wredundant-decls (system headers make this too noisy)
1075 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1076 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1077 dnl             is enabled for ncurses using "--enable-const".
1078 dnl     -pedantic
1079 dnl
1080 dnl Parameter:
1081 dnl     $1 is an optional list of gcc warning flags that a particular
1082 dnl             application might want to use, e.g., "no-unused" for
1083 dnl             -Wno-unused
1084 dnl Special:
1085 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1086 dnl
1087 AC_DEFUN([CF_GCC_WARNINGS],
1088 [
1089 AC_REQUIRE([CF_GCC_VERSION])
1090 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1091 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1092
1093 cat > conftest.$ac_ext <<EOF
1094 #line __oline__ "${as_me:-configure}"
1095 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1096 EOF
1097
1098 if test "$INTEL_COMPILER" = yes
1099 then
1100 # The "-wdXXX" options suppress warnings:
1101 # remark #1419: external declaration in primary source file
1102 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1103 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1104 # remark #193: zero used for undefined preprocessing identifier
1105 # remark #593: variable "curs_sb_left_arrow" was set but never used
1106 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1107 # remark #869: parameter "tw" was never referenced
1108 # remark #981: operands are evaluated in unspecified order
1109 # warning #279: controlling expression is constant
1110
1111         AC_CHECKING([for $CC warning options])
1112         cf_save_CFLAGS="$CFLAGS"
1113         EXTRA_CFLAGS="-Wall"
1114         for cf_opt in \
1115                 wd1419 \
1116                 wd1683 \
1117                 wd1684 \
1118                 wd193 \
1119                 wd593 \
1120                 wd279 \
1121                 wd810 \
1122                 wd869 \
1123                 wd981
1124         do
1125                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1126                 if AC_TRY_EVAL(ac_compile); then
1127                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1128                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1129                 fi
1130         done
1131         CFLAGS="$cf_save_CFLAGS"
1132
1133 elif test "$GCC" = yes
1134 then
1135         AC_CHECKING([for $CC warning options])
1136         cf_save_CFLAGS="$CFLAGS"
1137         EXTRA_CFLAGS=
1138         cf_warn_CONST=""
1139         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1140         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1141         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1142         for cf_opt in W Wall \
1143                 Wbad-function-cast \
1144                 Wcast-align \
1145                 Wcast-qual \
1146                 Wdeclaration-after-statement \
1147                 Wextra \
1148                 Winline \
1149                 Wmissing-declarations \
1150                 Wmissing-prototypes \
1151                 Wnested-externs \
1152                 Wpointer-arith \
1153                 Wshadow \
1154                 Wstrict-prototypes \
1155                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
1156         do
1157                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1158                 if AC_TRY_EVAL(ac_compile); then
1159                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1160                         case $cf_opt in
1161                         (Wcast-qual)
1162                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1163                                 ;;
1164                         (Winline)
1165                                 case $GCC_VERSION in
1166                                 ([[34]].*)
1167                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1168                                         continue;;
1169                                 esac
1170                                 ;;
1171                         (Wpointer-arith)
1172                                 case $GCC_VERSION in
1173                                 ([[12]].*)
1174                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1175                                         continue;;
1176                                 esac
1177                                 ;;
1178                         esac
1179                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1180                 fi
1181         done
1182         CFLAGS="$cf_save_CFLAGS"
1183 fi
1184 rm -rf conftest*
1185
1186 AC_SUBST(EXTRA_CFLAGS)
1187 ])dnl
1188 dnl ---------------------------------------------------------------------------
1189 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
1190 dnl -----------------
1191 AC_DEFUN([CF_GNATPREP_OPT_T],[
1192 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
1193 cf_cv_gnatprep_opt_t=no
1194 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
1195 ])
1196 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
1197 AC_SUBST(GNATPREP_OPTS)
1198 ])dnl
1199 dnl ---------------------------------------------------------------------------
1200 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
1201 dnl ----------------
1202 AC_DEFUN([CF_GNAT_GENERICS],
1203 [
1204 AC_REQUIRE([CF_GNAT_VERSION])
1205
1206 AC_MSG_CHECKING(if GNAT supports generics)
1207 case $cf_gnat_version in
1208 (3.[[1-9]]*|[[4-9]].*)
1209         cf_gnat_generics=yes
1210         ;;
1211 (*)
1212         cf_gnat_generics=no
1213         ;;
1214 esac
1215 AC_MSG_RESULT($cf_gnat_generics)
1216
1217 if test "$cf_gnat_generics" = yes
1218 then
1219         cf_compile_generics=generics
1220         cf_generic_objects="\${GENOBJS}"
1221 else
1222         cf_compile_generics=
1223         cf_generic_objects=
1224 fi
1225
1226 AC_SUBST(cf_compile_generics)
1227 AC_SUBST(cf_generic_objects)
1228 ])dnl
1229 dnl ---------------------------------------------------------------------------
1230 dnl CF_GNAT_PROJECTS version: 8 updated: 2015/04/17 21:13:04
1231 dnl ----------------
1232 dnl GNAT projects are configured with ".gpr" project files.
1233 dnl GNAT libraries are a further development, using the project feature.
1234 AC_DEFUN([CF_GNAT_PROJECTS],
1235 [
1236 AC_REQUIRE([CF_GNAT_VERSION])
1237 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
1238
1239 cf_gnat_libraries=no
1240 cf_gnat_projects=no
1241
1242 if test "$enable_gnat_projects" != no ; then
1243 AC_MSG_CHECKING(if GNAT supports project files)
1244 case $cf_gnat_version in
1245 (3.[[0-9]]*)
1246         ;;
1247 (*)
1248         case $cf_cv_system_name in
1249         (cygwin*|msys*)
1250                 ;;
1251         (*)
1252                 mkdir conftest.src conftest.bin conftest.lib
1253                 cd conftest.src
1254                 rm -rf conftest* *~conftest*
1255                 cat >>library.gpr <<CF_EOF
1256 project Library is
1257   Kind := External ("LIB_KIND");
1258   for Library_Name use "ConfTest";
1259   for Object_Dir use ".";
1260   for Library_ALI_Dir use External("LIBRARY_DIR");
1261   for Library_Version use External ("SONAME");
1262   for Library_Kind use Kind;
1263   for Library_Dir use External("BUILD_DIR");
1264   Source_Dir := External ("SOURCE_DIR");
1265   for Source_Dirs use (Source_Dir);
1266 end Library;
1267 CF_EOF
1268                 cat >>confpackage.ads <<CF_EOF
1269 package ConfPackage is
1270    procedure conftest;
1271 end ConfPackage;
1272 CF_EOF
1273                 cat >>confpackage.adb <<CF_EOF
1274 with Text_IO;
1275 package body ConfPackage is
1276    procedure conftest is
1277    begin
1278       Text_IO.Put ("Hello World");
1279       Text_IO.New_Line;
1280    end conftest;
1281 end ConfPackage;
1282 CF_EOF
1283                 if ( $cf_ada_make $ADAFLAGS \
1284                                 -Plibrary.gpr \
1285                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
1286                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
1287                                 -XSOURCE_DIR=`pwd` \
1288                                 -XSONAME=libConfTest.so.1 \
1289                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1290                         cf_gnat_projects=yes
1291                 fi
1292                 cd ..
1293                 if test -f conftest.lib/confpackage.ali
1294                 then
1295                         cf_gnat_libraries=yes
1296                 fi
1297                 rm -rf conftest* *~conftest*
1298                 ;;
1299         esac
1300         ;;
1301 esac
1302 AC_MSG_RESULT($cf_gnat_projects)
1303 fi # enable_gnat_projects
1304
1305 if test $cf_gnat_projects = yes
1306 then
1307         AC_MSG_CHECKING(if GNAT supports libraries)
1308         AC_MSG_RESULT($cf_gnat_libraries)
1309 fi
1310
1311 if test "$cf_gnat_projects" = yes
1312 then
1313         USE_OLD_MAKERULES="#"
1314         USE_GNAT_PROJECTS=""
1315 else
1316         USE_OLD_MAKERULES=""
1317         USE_GNAT_PROJECTS="#"
1318 fi
1319
1320 if test "$cf_gnat_libraries" = yes
1321 then
1322         USE_GNAT_LIBRARIES=""
1323 else
1324         USE_GNAT_LIBRARIES="#"
1325 fi
1326
1327 AC_SUBST(USE_OLD_MAKERULES)
1328 AC_SUBST(USE_GNAT_PROJECTS)
1329 AC_SUBST(USE_GNAT_LIBRARIES)
1330 ])dnl
1331 dnl ---------------------------------------------------------------------------
1332 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
1333 dnl --------------
1334 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1335 dnl is noted that gnat may compile a tasking unit even for configurations which
1336 dnl fail at runtime.
1337 AC_DEFUN([CF_GNAT_SIGINT],[
1338 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1339 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1340
1341 package ConfTest is
1342
1343    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1344    pragma Unreserve_All_Interrupts;
1345    pragma Warnings (On);
1346
1347    protected Process is
1348       procedure Stop;
1349       function Continue return Boolean;
1350       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1351    private
1352       Done : Boolean := False;
1353    end Process;
1354
1355 end ConfTest;],
1356 [package body ConfTest is
1357    protected body Process is
1358       procedure Stop is
1359       begin
1360          Done := True;
1361       end Stop;
1362       function Continue return Boolean is
1363       begin
1364          return not Done;
1365       end Continue;
1366    end Process;
1367 end ConfTest;],
1368         [cf_cv_gnat_sigint=yes],
1369         [cf_cv_gnat_sigint=no])])
1370
1371 if test $cf_cv_gnat_sigint = yes ; then
1372         USE_GNAT_SIGINT=""
1373 else
1374         USE_GNAT_SIGINT="#"
1375 fi
1376 AC_SUBST(USE_GNAT_SIGINT)
1377 ])dnl
1378 dnl ---------------------------------------------------------------------------
1379 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
1380 dnl ----------------
1381 dnl Verify that a test program compiles/links with GNAT.
1382 dnl $cf_ada_make is set to the program that compiles/links
1383 dnl $ADAFLAGS may be set to the GNAT flags.
1384 dnl
1385 dnl $1 is the text of the spec
1386 dnl $2 is the text of the body
1387 dnl $3 is the shell command to execute if successful
1388 dnl $4 is the shell command to execute if not successful
1389 AC_DEFUN([CF_GNAT_TRY_LINK],
1390 [
1391 rm -rf conftest* *~conftest*
1392 cat >>conftest.ads <<CF_EOF
1393 $1
1394 CF_EOF
1395 cat >>conftest.adb <<CF_EOF
1396 $2
1397 CF_EOF
1398 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1399 ifelse($3,,      :,[      $3])
1400 ifelse($4,,,[else
1401    $4])
1402 fi
1403 rm -rf conftest* *~conftest*
1404 ])dnl
1405 dnl ---------------------------------------------------------------------------
1406 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
1407 dnl ---------------
1408 dnl Verify that a test program compiles and runs with GNAT
1409 dnl $cf_ada_make is set to the program that compiles/links
1410 dnl $ADAFLAGS may be set to the GNAT flags.
1411 dnl
1412 dnl $1 is the text of the spec
1413 dnl $2 is the text of the body
1414 dnl $3 is the shell command to execute if successful
1415 dnl $4 is the shell command to execute if not successful
1416 AC_DEFUN([CF_GNAT_TRY_RUN],
1417 [
1418 rm -rf conftest* *~conftest*
1419 cat >>conftest.ads <<CF_EOF
1420 $1
1421 CF_EOF
1422 cat >>conftest.adb <<CF_EOF
1423 $2
1424 CF_EOF
1425 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1426    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1427 ifelse($3,,      :,[      $3])
1428 ifelse($4,,,[   else
1429       $4])
1430    fi
1431 ifelse($4,,,[else
1432    $4])
1433 fi
1434 rm -rf conftest* *~conftest*
1435 ])dnl
1436 dnl ---------------------------------------------------------------------------
1437 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
1438 dnl ---------------
1439 dnl Verify version of GNAT.
1440 AC_DEFUN([CF_GNAT_VERSION],
1441 [
1442 AC_MSG_CHECKING(for gnat version)
1443 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
1444         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1445         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1446 AC_MSG_RESULT($cf_gnat_version)
1447
1448 case $cf_gnat_version in
1449 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
1450         cf_cv_prog_gnat_correct=yes
1451         ;;
1452 (*)
1453         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1454         cf_cv_prog_gnat_correct=no
1455         ;;
1456 esac
1457 ])
1458 dnl ---------------------------------------------------------------------------
1459 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
1460 dnl -------------
1461 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1462 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1463 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1464 dnl since it is interwoven with GNU extensions.
1465 dnl
1466 dnl Well, yes we could work around it...
1467 AC_DEFUN([CF_GNU_SOURCE],
1468 [
1469 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1470 AC_TRY_COMPILE([#include <sys/types.h>],[
1471 #ifndef _XOPEN_SOURCE
1472 make an error
1473 #endif],
1474         [cf_cv_gnu_source=no],
1475         [cf_save="$CPPFLAGS"
1476          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1477          AC_TRY_COMPILE([#include <sys/types.h>],[
1478 #ifdef _XOPEN_SOURCE
1479 make an error
1480 #endif],
1481         [cf_cv_gnu_source=no],
1482         [cf_cv_gnu_source=yes])
1483         CPPFLAGS="$cf_save"
1484         ])
1485 ])
1486 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1487 ])dnl
1488 dnl ---------------------------------------------------------------------------
1489 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
1490 dnl --------------
1491 dnl Construct a search-list of directories for a nonstandard header-file
1492 dnl
1493 dnl Parameters
1494 dnl     $1 = the variable to return as result
1495 dnl     $2 = the package name
1496 AC_DEFUN([CF_HEADER_PATH],
1497 [
1498 $1=
1499
1500 # collect the current set of include-directories from compiler flags
1501 cf_header_path_list=""
1502 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1503         for cf_header_path in $CPPFLAGS $CFLAGS
1504         do
1505                 case $cf_header_path in
1506                 (-I*)
1507                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1508                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1509                         cf_header_path_list="$cf_header_path_list [$]$1"
1510                         ;;
1511                 esac
1512         done
1513 fi
1514
1515 # add the variations for the package we are looking for
1516 CF_SUBDIR_PATH($1,$2,include)
1517
1518 test "$includedir" != NONE && \
1519 test "$includedir" != "/usr/include" && \
1520 test -d "$includedir" && {
1521         test -d $includedir &&    $1="[$]$1 $includedir"
1522         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1523 }
1524
1525 test "$oldincludedir" != NONE && \
1526 test "$oldincludedir" != "/usr/include" && \
1527 test -d "$oldincludedir" && {
1528         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1529         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1530 }
1531
1532 $1="[$]$1 $cf_header_path_list"
1533 ])dnl
1534 dnl ---------------------------------------------------------------------------
1535 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1536 dnl ---------------
1537 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1538 AC_DEFUN([CF_HELP_MESSAGE],
1539 [AC_DIVERT_HELP([$1])dnl
1540 ])dnl
1541 dnl ---------------------------------------------------------------------------
1542 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
1543 dnl ---------------
1544 dnl Construct the list of include-options according to whether we're building
1545 dnl in the source directory or using '--srcdir=DIR' option.
1546 AC_DEFUN([CF_INCLUDE_DIRS],
1547 [
1548 if test "$srcdir" != "."; then
1549         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
1550 fi
1551 CPPFLAGS="-I../include $CPPFLAGS"
1552 if test "$srcdir" != "."; then
1553         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
1554 fi
1555 CPPFLAGS="-I. $CPPFLAGS"
1556 AC_SUBST(CPPFLAGS)
1557 ])dnl
1558 dnl ---------------------------------------------------------------------------
1559 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
1560 dnl -----------------
1561 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1562 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1563 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1564 dnl
1565 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1566 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1567 dnl the wrappers for gcc and g++ warnings.
1568 dnl
1569 dnl $1 = GCC (default) or GXX
1570 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1571 dnl $3 = CFLAGS (default) or CXXFLAGS
1572 AC_DEFUN([CF_INTEL_COMPILER],[
1573 AC_REQUIRE([AC_CANONICAL_HOST])
1574 ifelse([$2],,INTEL_COMPILER,[$2])=no
1575
1576 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1577         case $host_os in
1578         (linux*|gnu*)
1579                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1580                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1581                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1582                 AC_TRY_COMPILE([],[
1583 #ifdef __INTEL_COMPILER
1584 #else
1585 make an error
1586 #endif
1587 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1588 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
1589 ],[])
1590                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1591                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1592                 ;;
1593         esac
1594 fi
1595 ])dnl
1596 dnl ---------------------------------------------------------------------------
1597 dnl CF_LARGEFILE version: 9 updated: 2015/04/18 08:56:57
1598 dnl ------------
1599 dnl Add checks for large file support.
1600 AC_DEFUN([CF_LARGEFILE],[
1601 ifdef([AC_FUNC_FSEEKO],[
1602         AC_SYS_LARGEFILE
1603         if test "$enable_largefile" != no ; then
1604         AC_FUNC_FSEEKO
1605
1606         # Normally we would collect these definitions in the config.h,
1607         # but (like _XOPEN_SOURCE), some environments rely on having these
1608         # defined before any of the system headers are included.  Another
1609         # case comes up with C++, e.g., on AIX the compiler compiles the
1610         # header files by themselves before looking at the body files it is
1611         # told to compile.  For ncurses, those header files do not include
1612         # the config.h
1613         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
1614         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
1615         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
1616
1617         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
1618                 AC_TRY_COMPILE([
1619 #include <sys/types.h>
1620 #include <dirent.h>
1621                 ],[
1622                 /* if transitional largefile support is setup, this is true */
1623                 extern struct dirent64 * readdir(DIR *);
1624                 struct dirent64 *x = readdir((DIR *)0);
1625                 struct dirent *y = readdir((DIR *)0);
1626                 int z = x - y;
1627                 ],
1628                 [cf_cv_struct_dirent64=yes],
1629                 [cf_cv_struct_dirent64=no])
1630         ])
1631         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
1632         fi
1633 ])
1634 ])
1635 dnl ---------------------------------------------------------------------------
1636 dnl CF_LD_RPATH_OPT version: 6 updated: 2015/04/12 15:39:00
1637 dnl ---------------
1638 dnl For the given system and compiler, find the compiler flags to pass to the
1639 dnl loader to use the "rpath" feature.
1640 AC_DEFUN([CF_LD_RPATH_OPT],
1641 [
1642 AC_REQUIRE([CF_CHECK_CACHE])
1643
1644 LD_RPATH_OPT=
1645 AC_MSG_CHECKING(for an rpath option)
1646 case $cf_cv_system_name in
1647 (irix*)
1648         if test "$GCC" = yes; then
1649                 LD_RPATH_OPT="-Wl,-rpath,"
1650         else
1651                 LD_RPATH_OPT="-rpath "
1652         fi
1653         ;;
1654 (linux*|gnu*|k*bsd*-gnu)
1655         LD_RPATH_OPT="-Wl,-rpath,"
1656         ;;
1657 (openbsd[[2-9]].*|mirbsd*)
1658         LD_RPATH_OPT="-Wl,-rpath,"
1659         ;;
1660 (dragonfly*|freebsd*)
1661         LD_RPATH_OPT="-rpath "
1662         ;;
1663 (netbsd*)
1664         LD_RPATH_OPT="-Wl,-rpath,"
1665         ;;
1666 (osf*|mls+*)
1667         LD_RPATH_OPT="-rpath "
1668         ;;
1669 (solaris2*)
1670         LD_RPATH_OPT="-R"
1671         ;;
1672 (*)
1673         ;;
1674 esac
1675 AC_MSG_RESULT($LD_RPATH_OPT)
1676
1677 case "x$LD_RPATH_OPT" in
1678 (x-R*)
1679         AC_MSG_CHECKING(if we need a space after rpath option)
1680         cf_save_LIBS="$LIBS"
1681         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1682         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1683         LIBS="$cf_save_LIBS"
1684         AC_MSG_RESULT($cf_rpath_space)
1685         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1686         ;;
1687 esac
1688 ])dnl
1689 dnl ---------------------------------------------------------------------------
1690 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
1691 dnl ---------------
1692 dnl Construct a search-list of directories for a nonstandard library-file
1693 dnl
1694 dnl Parameters
1695 dnl     $1 = the variable to return as result
1696 dnl     $2 = the package name
1697 AC_DEFUN([CF_LIBRARY_PATH],
1698 [
1699 $1=
1700 cf_library_path_list=""
1701 if test -n "${LDFLAGS}${LIBS}" ; then
1702         for cf_library_path in $LDFLAGS $LIBS
1703         do
1704                 case $cf_library_path in
1705                 (-L*)
1706                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1707                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1708                         cf_library_path_list="$cf_library_path_list [$]$1"
1709                         ;;
1710                 esac
1711         done
1712 fi
1713
1714 CF_SUBDIR_PATH($1,$2,lib)
1715
1716 $1="$cf_library_path_list [$]$1"
1717 ])dnl
1718 dnl ---------------------------------------------------------------------------
1719 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
1720 dnl -------------
1721 dnl Compute the library-prefix for the given host system
1722 dnl $1 = variable to set
1723 define([CF_LIB_PREFIX],
1724 [
1725         case $cf_cv_system_name in
1726         (OS/2*|os2*)
1727                 if test "$DFT_LWR_MODEL" = libtool; then
1728                         LIB_PREFIX='lib'
1729                 else
1730                         LIB_PREFIX=''
1731                 fi
1732                 ;;
1733         (*)     LIB_PREFIX='lib'
1734                 ;;
1735         esac
1736 ifelse($1,,,[$1=$LIB_PREFIX])
1737         AC_SUBST(LIB_PREFIX)
1738 ])dnl
1739 dnl ---------------------------------------------------------------------------
1740 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
1741 dnl -------------
1742 dnl Compute the library file-suffix from the given model name
1743 dnl $1 = model name
1744 dnl $2 = variable to set (the nominal library suffix)
1745 dnl $3 = dependency variable to set (actual filename)
1746 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1747 AC_DEFUN([CF_LIB_SUFFIX],
1748 [
1749         case X$1 in
1750         (Xlibtool)
1751                 $2='.la'
1752                 $3=[$]$2
1753                 ;;
1754         (Xdebug)
1755                 $2='_g.a'
1756                 $3=[$]$2
1757                 ;;
1758         (Xprofile)
1759                 $2='_p.a'
1760                 $3=[$]$2
1761                 ;;
1762         (Xshared)
1763                 case $cf_cv_system_name in
1764                 (aix[[5-7]]*)
1765                         $2='.so'
1766                         $3=[$]$2
1767                         ;;
1768                 (cygwin*|msys*|mingw*)
1769                         $2='.dll'
1770                         $3='.dll.a'
1771                         ;;
1772                 (darwin*)
1773                         $2='.dylib'
1774                         $3=[$]$2
1775                         ;;
1776                 (hpux*)
1777                         case $target in
1778                         (ia64*)
1779                                 $2='.so'
1780                                 $3=[$]$2
1781                                 ;;
1782                         (*)
1783                                 $2='.sl'
1784                                 $3=[$]$2
1785                                 ;;
1786                         esac
1787                         ;;
1788                 (*)
1789                         $2='.so'
1790                         $3=[$]$2
1791                         ;;
1792                 esac
1793                 ;;
1794         (*)
1795                 $2='.a'
1796                 $3=[$]$2
1797                 ;;
1798         esac
1799         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
1800         then
1801                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
1802                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
1803         fi
1804 ])dnl
1805 dnl ---------------------------------------------------------------------------
1806 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
1807 dnl -----------
1808 dnl Compute the string to append to -library from the given model name
1809 dnl $1 = model name
1810 dnl $2 = variable to set
1811 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1812 AC_DEFUN([CF_LIB_TYPE],
1813 [
1814         case $1 in
1815         (libtool) $2=''   ;;
1816         (normal)  $2=''   ;;
1817         (debug)   $2='_g' ;;
1818         (profile) $2='_p' ;;
1819         (shared)  $2=''   ;;
1820         esac
1821         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1822 ])dnl
1823 dnl ---------------------------------------------------------------------------
1824 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
1825 dnl ----------------
1826 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
1827 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
1828 dnl have to provide wrappers for global tables to ensure they're linked
1829 dnl properly.
1830 AC_DEFUN([CF_LINK_DATAONLY],
1831 [
1832 AC_MSG_CHECKING([if data-only library module links])
1833 AC_CACHE_VAL(cf_cv_link_dataonly,[
1834         rm -f conftest.a
1835         cat >conftest.$ac_ext <<EOF
1836 #line __oline__ "configure"
1837 int     testdata[[3]] = { 123, 456, 789 };
1838 EOF
1839         if AC_TRY_EVAL(ac_compile) ; then
1840                 mv conftest.o data.o && \
1841                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
1842         fi
1843         rm -f conftest.$ac_ext data.o
1844         cat >conftest.$ac_ext <<EOF
1845 #line __oline__ "configure"
1846 int     testfunc()
1847 {
1848 #if defined(NeXT)
1849         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
1850 #else
1851         extern int testdata[[3]];
1852         return testdata[[0]] == 123
1853            &&  testdata[[1]] == 456
1854            &&  testdata[[2]] == 789;
1855 #endif
1856 }
1857 EOF
1858         if AC_TRY_EVAL(ac_compile); then
1859                 mv conftest.o func.o && \
1860                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
1861         fi
1862         rm -f conftest.$ac_ext func.o
1863         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
1864         cf_saveLIBS="$LIBS"
1865         LIBS="conftest.a $LIBS"
1866         AC_TRY_RUN([
1867         int main()
1868         {
1869                 extern int testfunc();
1870                 ${cf_cv_main_return:-return} (!testfunc());
1871         }
1872         ],
1873         [cf_cv_link_dataonly=yes],
1874         [cf_cv_link_dataonly=no],
1875         [cf_cv_link_dataonly=unknown])
1876         LIBS="$cf_saveLIBS"
1877         ])
1878 AC_MSG_RESULT($cf_cv_link_dataonly)
1879
1880 if test "$cf_cv_link_dataonly" = no ; then
1881         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
1882         BROKEN_LINKER=1
1883 fi
1884
1885 ])dnl
1886 dnl ---------------------------------------------------------------------------
1887 dnl CF_MAKEFLAGS version: 17 updated: 2015/08/05 20:44:28
1888 dnl ------------
1889 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
1890 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
1891 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
1892 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
1893 AC_DEFUN([CF_MAKEFLAGS],
1894 [
1895 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
1896         cf_cv_makeflags=''
1897         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
1898         do
1899                 cat >cf_makeflags.tmp <<CF_EOF
1900 SHELL = $SHELL
1901 all :
1902         @ echo '.$cf_option'
1903 CF_EOF
1904                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
1905                 case "$cf_result" in
1906                 (.*k|.*kw)
1907                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
1908                         case "$cf_result" in
1909                         (.*CC=*)        cf_cv_makeflags=
1910                                 ;;
1911                         (*)     cf_cv_makeflags=$cf_option
1912                                 ;;
1913                         esac
1914                         break
1915                         ;;
1916                 (.-)    ;;
1917                 (*)     echo "given option \"$cf_option\", no match \"$cf_result\""
1918                         ;;
1919                 esac
1920         done
1921         rm -f cf_makeflags.tmp
1922 ])
1923
1924 AC_SUBST(cf_cv_makeflags)
1925 ])dnl
1926 dnl ---------------------------------------------------------------------------
1927 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1928 dnl ------------
1929 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1930 dnl a monocase filesystem.
1931 AC_DEFUN([CF_MAKE_TAGS],[
1932 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1933
1934 AC_CHECK_PROGS(CTAGS, exctags ctags)
1935 AC_CHECK_PROGS(ETAGS, exetags etags)
1936
1937 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1938
1939 if test "$cf_cv_mixedcase" = yes ; then
1940         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1941 else
1942         MAKE_UPPER_TAGS=no
1943 fi
1944
1945 if test "$MAKE_UPPER_TAGS" = yes ; then
1946         MAKE_UPPER_TAGS=
1947 else
1948         MAKE_UPPER_TAGS="#"
1949 fi
1950
1951 if test "$MAKE_LOWER_TAGS" = yes ; then
1952         MAKE_LOWER_TAGS=
1953 else
1954         MAKE_LOWER_TAGS="#"
1955 fi
1956
1957 AC_SUBST(CTAGS)
1958 AC_SUBST(ETAGS)
1959
1960 AC_SUBST(MAKE_UPPER_TAGS)
1961 AC_SUBST(MAKE_LOWER_TAGS)
1962 ])dnl
1963 dnl ---------------------------------------------------------------------------
1964 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
1965 dnl ----------------------
1966 dnl Check if the file-system supports mixed-case filenames.  If we're able to
1967 dnl create a lowercase name and see it as uppercase, it doesn't support that.
1968 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
1969 [
1970 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
1971 if test "$cross_compiling" = yes ; then
1972         case $target_alias in
1973         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
1974                 cf_cv_mixedcase=no
1975                 ;;
1976         (*)
1977                 cf_cv_mixedcase=yes
1978                 ;;
1979         esac
1980 else
1981         rm -f conftest CONFTEST
1982         echo test >conftest
1983         if test -f CONFTEST ; then
1984                 cf_cv_mixedcase=no
1985         else
1986                 cf_cv_mixedcase=yes
1987         fi
1988         rm -f conftest CONFTEST
1989 fi
1990 ])
1991 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
1992 ])dnl
1993 dnl ---------------------------------------------------------------------------
1994 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
1995 dnl ----------
1996 dnl Check for a working mkstemp.  This creates two files, checks that they are
1997 dnl successfully created and distinct (AmigaOS apparently fails on the last).
1998 AC_DEFUN([CF_MKSTEMP],[
1999 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2000 rm -rf conftest*
2001 AC_TRY_RUN([
2002 #include <sys/types.h>
2003 #include <stdlib.h>
2004 #include <stdio.h>
2005 #include <string.h>
2006 #include <sys/stat.h>
2007 int main()
2008 {
2009         char *tmpl = "conftestXXXXXX";
2010         char name[2][80];
2011         int n;
2012         int result = 0;
2013         int fd;
2014         struct stat sb;
2015
2016         umask(077);
2017         for (n = 0; n < 2; ++n) {
2018                 strcpy(name[n], tmpl);
2019                 if ((fd = mkstemp(name[n])) >= 0) {
2020                         if (!strcmp(name[n], tmpl)
2021                          || stat(name[n], &sb) != 0
2022                          || (sb.st_mode & S_IFMT) != S_IFREG
2023                          || (sb.st_mode & 077) != 0) {
2024                                 result = 1;
2025                         }
2026                         close(fd);
2027                 }
2028         }
2029         if (result == 0
2030          && !strcmp(name[0], name[1]))
2031                 result = 1;
2032         ${cf_cv_main_return:-return}(result);
2033 }
2034 ],[cf_cv_func_mkstemp=yes
2035 ],[cf_cv_func_mkstemp=no
2036 ],[cf_cv_func_mkstemp=maybe])
2037 ])
2038 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2039         AC_CHECK_FUNC(mkstemp)
2040 fi
2041 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2042         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2043 fi
2044 ])dnl
2045 dnl ---------------------------------------------------------------------------
2046 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2047 dnl ----------
2048 dnl Write a debug message to config.log, along with the line number in the
2049 dnl configure script.
2050 AC_DEFUN([CF_MSG_LOG],[
2051 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2052 ])dnl
2053 dnl ---------------------------------------------------------------------------
2054 dnl CF_NCURSES_ADDON version: 5 updated: 2015/04/26 18:06:58
2055 dnl ----------------
2056 dnl Configure an ncurses add-on, built outside the ncurses tree.
2057 AC_DEFUN([CF_NCURSES_ADDON],[
2058 AC_REQUIRE([CF_NCURSES_CONFIG])
2059
2060 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2061
2062 AC_MSG_CHECKING(if you want wide-character code)
2063 AC_ARG_ENABLE(widec,
2064         [  --enable-widec          compile with wide-char/UTF-8 code],
2065         [with_widec=$enableval],
2066         [with_widec=no])
2067 AC_MSG_RESULT($with_widec)
2068 if test "$with_widec" = yes ; then
2069         CF_UTF8_LIB
2070         CF_NCURSES_CONFIG(ncursesw)
2071 else
2072         CF_NCURSES_CONFIG(ncurses)
2073 fi
2074
2075 if test "$NCURSES_CONFIG_PKG" != none ; then
2076         cf_version=`$PKG_CONFIG --modversion $NCURSES_CONFIG_PKG 2>/dev/null`
2077
2078         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2079         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2080         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2081
2082         cf_cv_abi_version=`$PKG_CONFIG --variable=abi_version $NCURSES_CONFIG_PKG 2>/dev/null`
2083         if test -z "$cf_cv_abi_version"
2084         then
2085                 cf_cv_abi_version=`$PKG_CONFIG --variable=major_version $NCURSES_CONFIG_PKG 2>/dev/null`
2086         fi
2087
2088 elif test "$NCURSES_CONFIG" != none ; then
2089
2090         cf_version=`$NCURSES_CONFIG --version 2>/dev/null`
2091
2092         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2093         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2094         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2095
2096         # ABI version is not available from headers
2097         cf_cv_abi_version=`$NCURSES_CONFIG --abi-version 2>/dev/null`
2098
2099 else
2100
2101         for cf_name in MAJOR MINOR PATCH
2102         do
2103         cat >conftest.$ac_ext <<CF_EOF
2104         #include <${cf_cv_ncurses_header:-curses.h}>
2105         AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2106 CF_EOF
2107                 cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2108                 AC_TRY_EVAL(cf_try)
2109                 if test -f conftest.out ; then
2110                         cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]][[    ]]*//"`
2111                         eval NCURSES_$cf_name=\"$cf_result\"
2112                         # cat conftest.$ac_ext
2113                         # cat conftest.out
2114                 fi
2115         done
2116
2117         cf_cv_abi_version=${NCURSES_MAJOR}
2118
2119 fi
2120
2121 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2122
2123 dnl Show the computed version, for logging
2124 cf_cv_timestamp=`date`
2125
2126 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2127
2128 dnl We need these values in the generated headers
2129 AC_SUBST(NCURSES_MAJOR)
2130 AC_SUBST(NCURSES_MINOR)
2131 AC_SUBST(NCURSES_PATCH)
2132
2133 dnl We need these values in the generated makefiles
2134 AC_SUBST(cf_cv_rel_version)
2135 AC_SUBST(cf_cv_abi_version)
2136
2137 dnl FIXME - not needed for Ada95
2138 AC_SUBST(cf_cv_builtin_bool)
2139 AC_SUBST(cf_cv_header_stdbool_h)
2140 AC_SUBST(cf_cv_type_of_bool)dnl
2141
2142 ])
2143 dnl ---------------------------------------------------------------------------
2144 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2145 dnl -------------------
2146 dnl Check if we can compile with ncurses' header file
2147 dnl $1 is the cache variable to set
2148 dnl $2 is the header-file to include
2149 dnl $3 is the root name (ncurses or ncursesw)
2150 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2151         AC_TRY_COMPILE([
2152 ]ifelse($3,ncursesw,[
2153 #define _XOPEN_SOURCE_EXTENDED
2154 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2155 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2156 ])[
2157 #include <$2>],[
2158 #ifdef NCURSES_VERSION
2159 ]ifelse($3,ncursesw,[
2160 #ifndef WACS_BSSB
2161         make an error
2162 #endif
2163 ])[
2164 printf("%s\n", NCURSES_VERSION);
2165 #else
2166 #ifdef __NCURSES_H
2167 printf("old\n");
2168 #else
2169         make an error
2170 #endif
2171 #endif
2172         ]
2173         ,[$1=$2]
2174         ,[$1=no])
2175 ])dnl
2176 dnl ---------------------------------------------------------------------------
2177 dnl CF_NCURSES_CONFIG version: 17 updated: 2015/07/07 04:22:07
2178 dnl -----------------
2179 dnl Tie together the configure-script macros for ncurses, preferring these in
2180 dnl order:
2181 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2182 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2183 dnl c) just plain libraries
2184 dnl
2185 dnl $1 is the root library name (default: "ncurses")
2186 AC_DEFUN([CF_NCURSES_CONFIG],[
2187 AC_REQUIRE([CF_PKG_CONFIG])
2188 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2189 cf_have_ncuconfig=no
2190
2191 if test "x${PKG_CONFIG:=none}" != xnone; then
2192         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2193         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2194                 AC_MSG_RESULT(yes)
2195
2196                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2197                 cf_have_ncuconfig=unknown
2198
2199                 cf_save_CPPFLAGS="$CPPFLAGS"
2200                 cf_save_LIBS="$LIBS"
2201
2202                 CPPFLAGS="$CPPFLAGS `$PKG_CONFIG --cflags $cf_ncuconfig_root`"
2203                 CF_ADD_LIBS(`$PKG_CONFIG --libs $cf_ncuconfig_root`)
2204
2205                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2206                         [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2207                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2208                                 int main(void)
2209                                 { char *xx = curses_version(); return (xx == 0); }],
2210                                 [cf_have_ncuconfig=yes],
2211                                 [cf_have_ncuconfig=no],
2212                                 [cf_have_ncuconfig=maybe])],
2213                         [cf_have_ncuconfig=no])
2214                 AC_MSG_RESULT($cf_have_ncuconfig)
2215                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2216                 if test "$cf_have_ncuconfig" != "yes"
2217                 then
2218                         CPPFLAGS="$cf_save_CPPFLAGS"
2219                         LIBS="$cf_save_LIBS"
2220                         NCURSES_CONFIG_PKG=none
2221                 else
2222                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2223                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2224                 fi
2225
2226         else
2227                 AC_MSG_RESULT(no)
2228                 NCURSES_CONFIG_PKG=none
2229         fi
2230 else
2231         NCURSES_CONFIG_PKG=none
2232 fi
2233
2234 if test "x$cf_have_ncuconfig" = "xno"; then
2235         echo "Looking for ${cf_ncuconfig_root}-config"
2236
2237         CF_ACVERSION_CHECK(2.52,
2238                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncuconfig_root}-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2239                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncuconfig_root}-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2240
2241         if test "$NCURSES_CONFIG" != none ; then
2242
2243                 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
2244                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2245
2246                 # even with config script, some packages use no-override for curses.h
2247                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2248
2249                 dnl like CF_NCURSES_CPPFLAGS
2250                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2251
2252                 dnl like CF_NCURSES_LIBS
2253                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2254                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2255
2256                 dnl like CF_NCURSES_VERSION
2257                 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2258
2259         else
2260
2261                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2262                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2263
2264         fi
2265 else
2266         NCURSES_CONFIG=none
2267 fi
2268 ])dnl
2269 dnl ---------------------------------------------------------------------------
2270 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2271 dnl -------------------
2272 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2273 dnl the CPPFLAGS variable so we can include its header.
2274 dnl
2275 dnl The header files may be installed as either curses.h, or ncurses.h (would
2276 dnl be obsolete, except that some packagers prefer this name to distinguish it
2277 dnl from a "native" curses implementation).  If not installed for overwrite,
2278 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2279 dnl /usr/include/ncurses), but someone may have installed overwriting the
2280 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2281 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2282 dnl the header.
2283 dnl
2284 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2285 dnl is already in the include-path, don't even bother with this, since we cannot
2286 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2287 dnl
2288 dnl The optional parameter gives the root name of the library, in case it is
2289 dnl not installed as the default curses library.  That is how the
2290 dnl wide-character version of ncurses is installed.
2291 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2292 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2293
2294 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2295 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2296
2297 test -n "$cf_cv_curses_dir" && \
2298 test "$cf_cv_curses_dir" != "no" && { \
2299   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2300 }
2301
2302 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2303         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2304         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2305         for cf_header in $cf_header_list
2306         do
2307                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2308                 test "$cf_cv_ncurses_h" != no && break
2309         done
2310 ])
2311
2312 CF_NCURSES_HEADER
2313 CF_TERM_HEADER
2314
2315 # some applications need this, but should check for NCURSES_VERSION
2316 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2317
2318 CF_NCURSES_VERSION
2319 ])dnl
2320 dnl ---------------------------------------------------------------------------
2321 dnl CF_NCURSES_HEADER version: 4 updated: 2015/04/15 19:08:48
2322 dnl -----------------
2323 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2324 dnl variations of ncurses' installs.
2325 dnl
2326 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2327 AC_DEFUN([CF_NCURSES_HEADER],[
2328
2329 if test "$cf_cv_ncurses_h" != no ; then
2330         cf_cv_ncurses_header=$cf_cv_ncurses_h
2331 else
2332
2333 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2334         test -n "$verbose" && echo
2335         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2336         test -n "$verbose" && echo search path $cf_search
2337         cf_save2_CPPFLAGS="$CPPFLAGS"
2338         for cf_incdir in $cf_search
2339         do
2340                 CF_ADD_INCDIR($cf_incdir)
2341                 for cf_header in \
2342                         ncurses.h \
2343                         curses.h
2344                 do
2345                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2346                         if test "$cf_cv_ncurses_h2" != no ; then
2347                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2348                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2349                                 break
2350                         fi
2351                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2352                 done
2353                 CPPFLAGS="$cf_save2_CPPFLAGS"
2354                 test "$cf_cv_ncurses_h2" != no && break
2355         done
2356         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2357         ])
2358
2359         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2360         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2361         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2362                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2363         fi
2364         CF_ADD_INCDIR($cf_1st_incdir)
2365
2366 fi
2367
2368 # Set definitions to allow ifdef'ing for ncurses.h
2369
2370 case $cf_cv_ncurses_header in
2371 (*ncurses.h)
2372         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2373         ;;
2374 esac
2375
2376 case $cf_cv_ncurses_header in
2377 (ncurses/curses.h|ncurses/ncurses.h)
2378         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2379         ;;
2380 (ncursesw/curses.h|ncursesw/ncurses.h)
2381         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2382         ;;
2383 esac
2384
2385 ])dnl
2386 dnl ---------------------------------------------------------------------------
2387 dnl CF_NCURSES_LIBS version: 17 updated: 2015/04/15 19:08:48
2388 dnl ---------------
2389 dnl Look for the ncurses library.  This is a little complicated on Linux,
2390 dnl because it may be linked with the gpm (general purpose mouse) library.
2391 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2392 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2393 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2394 dnl and the linker will record a dependency.
2395 dnl
2396 dnl The optional parameter gives the root name of the library, in case it is
2397 dnl not installed as the default curses library.  That is how the
2398 dnl wide-character version of ncurses is installed.
2399 AC_DEFUN([CF_NCURSES_LIBS],
2400 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2401
2402 cf_nculib_root=ifelse($1,,ncurses,$1)
2403         # This works, except for the special case where we find gpm, but
2404         # ncurses is in a nonstandard location via $LIBS, and we really want
2405         # to link gpm.
2406 cf_ncurses_LIBS=""
2407 cf_ncurses_SAVE="$LIBS"
2408 AC_CHECK_LIB(gpm,Gpm_Open,
2409         [AC_CHECK_LIB(gpm,initscr,
2410                 [LIBS="$cf_ncurses_SAVE"],
2411                 [cf_ncurses_LIBS="-lgpm"])])
2412
2413 case $host_os in
2414 (freebsd*)
2415         # This is only necessary if you are linking against an obsolete
2416         # version of ncurses (but it should do no harm, since it's static).
2417         if test "$cf_nculib_root" = ncurses ; then
2418                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2419         fi
2420         ;;
2421 esac
2422
2423 CF_ADD_LIBS($cf_ncurses_LIBS)
2424
2425 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2426 then
2427         CF_ADD_LIBS(-l$cf_nculib_root)
2428 else
2429         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2430                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2431                 [initscr()],
2432                 initscr)
2433 fi
2434
2435 if test -n "$cf_ncurses_LIBS" ; then
2436         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2437         cf_ncurses_SAVE="$LIBS"
2438         for p in $cf_ncurses_LIBS ; do
2439                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2440                 if test "$q" != "$LIBS" ; then
2441                         LIBS="$q"
2442                 fi
2443         done
2444         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2445                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2446                 [AC_MSG_RESULT(yes)],
2447                 [AC_MSG_RESULT(no)
2448                  LIBS="$cf_ncurses_SAVE"])
2449 fi
2450
2451 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2452 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2453 ])dnl
2454 dnl ---------------------------------------------------------------------------
2455 dnl CF_NCURSES_VERSION version: 14 updated: 2012/10/06 08:57:51
2456 dnl ------------------
2457 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2458 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2459 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2460 AC_DEFUN([CF_NCURSES_VERSION],
2461 [
2462 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2463 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2464         cf_cv_ncurses_version=no
2465         cf_tempfile=out$$
2466         rm -f $cf_tempfile
2467         AC_TRY_RUN([
2468 #include <${cf_cv_ncurses_header:-curses.h}>
2469 #include <stdio.h>
2470 int main()
2471 {
2472         FILE *fp = fopen("$cf_tempfile", "w");
2473 #ifdef NCURSES_VERSION
2474 # ifdef NCURSES_VERSION_PATCH
2475         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2476 # else
2477         fprintf(fp, "%s\n", NCURSES_VERSION);
2478 # endif
2479 #else
2480 # ifdef __NCURSES_H
2481         fprintf(fp, "old\n");
2482 # else
2483         make an error
2484 # endif
2485 #endif
2486         ${cf_cv_main_return:-return}(0);
2487 }],[
2488         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2489
2490         # This will not work if the preprocessor splits the line after the
2491         # Autoconf token.  The 'unproto' program does that.
2492         cat > conftest.$ac_ext <<EOF
2493 #include <${cf_cv_ncurses_header:-curses.h}>
2494 #undef Autoconf
2495 #ifdef NCURSES_VERSION
2496 Autoconf NCURSES_VERSION
2497 #else
2498 #ifdef __NCURSES_H
2499 Autoconf "old"
2500 #endif
2501 ;
2502 #endif
2503 EOF
2504         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2505         AC_TRY_EVAL(cf_try)
2506         if test -f conftest.out ; then
2507                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2508                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2509                 rm -f conftest.out
2510         fi
2511 ])
2512         rm -f $cf_tempfile
2513 ])
2514 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2515 ])dnl
2516 dnl ---------------------------------------------------------------------------
2517 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
2518 dnl -------------
2519 dnl Compute the object-directory name from the given model name
2520 AC_DEFUN([CF_OBJ_SUBDIR],
2521 [
2522         case $1 in
2523         (libtool) $2='obj_lo'  ;;
2524         (normal)  $2='objects' ;;
2525         (debug)   $2='obj_g' ;;
2526         (profile) $2='obj_p' ;;
2527         (shared)
2528                 case $cf_cv_system_name in
2529                 (cygwin|msys)
2530                         $2='objects' ;;
2531                 (*)
2532                         $2='obj_s' ;;
2533                 esac
2534         esac
2535 ])dnl
2536 dnl ---------------------------------------------------------------------------
2537 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
2538 dnl ----------
2539 dnl Provide a value for the $PATH and similar separator (or amend the value
2540 dnl as provided in autoconf 2.5x).
2541 AC_DEFUN([CF_PATHSEP],
2542 [
2543         AC_MSG_CHECKING(for PATH separator)
2544         case $cf_cv_system_name in
2545         (os2*)  PATH_SEPARATOR=';'  ;;
2546         (*)     ${PATH_SEPARATOR:=':'}  ;;
2547         esac
2548 ifelse([$1],,,[$1=$PATH_SEPARATOR])
2549         AC_SUBST(PATH_SEPARATOR)
2550         AC_MSG_RESULT($PATH_SEPARATOR)
2551 ])dnl
2552 dnl ---------------------------------------------------------------------------
2553 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
2554 dnl --------------
2555 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2556 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2557 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2558 dnl delayed evaluation of those symbols.
2559 AC_DEFUN([CF_PATH_SYNTAX],[
2560 if test "x$prefix" != xNONE; then
2561         cf_path_syntax="$prefix"
2562 else
2563         cf_path_syntax="$ac_default_prefix"
2564 fi
2565
2566 case ".[$]$1" in
2567 (.\[$]\(*\)*|.\'*\'*)
2568         ;;
2569 (..|./*|.\\*)
2570         ;;
2571 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
2572         ;;
2573 (.\[$]{*prefix}*|.\[$]{*dir}*)
2574         eval $1="[$]$1"
2575         case ".[$]$1" in
2576         (.NONE/*)
2577                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2578                 ;;
2579         esac
2580         ;;
2581 (.no|.NONE/*)
2582         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2583         ;;
2584 (*)
2585         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2586         ;;
2587 esac
2588 ])dnl
2589 dnl ---------------------------------------------------------------------------
2590 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
2591 dnl -------------
2592 dnl Check for the package-config program, unless disabled by command-line.
2593 AC_DEFUN([CF_PKG_CONFIG],
2594 [
2595 AC_MSG_CHECKING(if you want to use pkg-config)
2596 AC_ARG_WITH(pkg-config,
2597         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2598         [cf_pkg_config=$withval],
2599         [cf_pkg_config=yes])
2600 AC_MSG_RESULT($cf_pkg_config)
2601
2602 case $cf_pkg_config in
2603 (no)
2604         PKG_CONFIG=none
2605         ;;
2606 (yes)
2607         CF_ACVERSION_CHECK(2.52,
2608                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2609                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2610         ;;
2611 (*)
2612         PKG_CONFIG=$withval
2613         ;;
2614 esac
2615
2616 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2617 if test "$PKG_CONFIG" != none ; then
2618         CF_PATH_SYNTAX(PKG_CONFIG)
2619 elif test "x$cf_pkg_config" != xno ; then
2620         AC_MSG_WARN(pkg-config is not installed)
2621 fi
2622
2623 AC_SUBST(PKG_CONFIG)
2624 ])dnl
2625 dnl ---------------------------------------------------------------------------
2626 dnl CF_POSIX_C_SOURCE version: 9 updated: 2015/04/12 15:39:00
2627 dnl -----------------
2628 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2629 dnl
2630 dnl     POSIX.1-1990                            _POSIX_SOURCE
2631 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2632 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2633 dnl             Bindings Option
2634 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2635 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2636 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2637 dnl
2638 dnl Parameters:
2639 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2640 AC_DEFUN([CF_POSIX_C_SOURCE],
2641 [
2642 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2643
2644 cf_save_CFLAGS="$CFLAGS"
2645 cf_save_CPPFLAGS="$CPPFLAGS"
2646
2647 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2648 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2649
2650 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2651         CF_MSG_LOG(if the symbol is already defined go no further)
2652         AC_TRY_COMPILE([#include <sys/types.h>],[
2653 #ifndef _POSIX_C_SOURCE
2654 make an error
2655 #endif],
2656         [cf_cv_posix_c_source=no],
2657         [cf_want_posix_source=no
2658          case .$cf_POSIX_C_SOURCE in
2659          (.[[12]]??*)
2660                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2661                 ;;
2662          (.2)
2663                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2664                 cf_want_posix_source=yes
2665                 ;;
2666          (.*)
2667                 cf_want_posix_source=yes
2668                 ;;
2669          esac
2670          if test "$cf_want_posix_source" = yes ; then
2671                 AC_TRY_COMPILE([#include <sys/types.h>],[
2672 #ifdef _POSIX_SOURCE
2673 make an error
2674 #endif],[],
2675                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2676          fi
2677          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2678          CFLAGS="$cf_trim_CFLAGS"
2679          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2680          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2681          AC_TRY_COMPILE([#include <sys/types.h>],[
2682 #ifndef _POSIX_C_SOURCE
2683 make an error
2684 #endif],,
2685          [cf_cv_posix_c_source=no])
2686          CFLAGS="$cf_save_CFLAGS"
2687          CPPFLAGS="$cf_save_CPPFLAGS"
2688         ])
2689 ])
2690
2691 if test "$cf_cv_posix_c_source" != no ; then
2692         CFLAGS="$cf_trim_CFLAGS"
2693         CPPFLAGS="$cf_trim_CPPFLAGS"
2694         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2695 fi
2696
2697 ])dnl
2698 dnl ---------------------------------------------------------------------------
2699 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
2700 dnl ----------
2701 dnl Check for archiver "ar".
2702 AC_DEFUN([CF_PROG_AR],[
2703 AC_CHECK_TOOL(AR, ar, ar)
2704 ])
2705 dnl ---------------------------------------------------------------------------
2706 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
2707 dnl -----------
2708 dnl Check for awk, ensure that the check found something.
2709 AC_DEFUN([CF_PROG_AWK],
2710 [
2711 AC_PROG_AWK
2712 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
2713 ])dnl
2714 dnl ---------------------------------------------------------------------------
2715 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
2716 dnl ----------
2717 dnl standard check for CC, plus followup sanity checks
2718 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
2719 AC_DEFUN([CF_PROG_CC],[
2720 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
2721 CF_GCC_VERSION
2722 CF_ACVERSION_CHECK(2.52,
2723         [AC_PROG_CC_STDC],
2724         [CF_ANSI_CC_REQD])
2725 CF_CC_ENV_FLAGS
2726 ])dnl
2727 dnl ---------------------------------------------------------------------------
2728 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
2729 dnl --------------
2730 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
2731 dnl the output file can be renamed, and allows for a shell variable that can
2732 dnl be used later.  The parameter is either CC or CXX.  The result is the
2733 dnl cache variable:
2734 dnl     $cf_cv_prog_CC_c_o
2735 dnl     $cf_cv_prog_CXX_c_o
2736 AC_DEFUN([CF_PROG_CC_C_O],
2737 [AC_REQUIRE([AC_PROG_CC])dnl
2738 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
2739 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
2740 [
2741 cat > conftest.$ac_ext <<CF_EOF
2742 #include <stdio.h>
2743 int main()
2744 {
2745         ${cf_cv_main_return:-return}(0);
2746 }
2747 CF_EOF
2748 # We do the test twice because some compilers refuse to overwrite an
2749 # existing .o file with -o, though they will create one.
2750 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
2751 if AC_TRY_EVAL(ac_try) &&
2752   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
2753 then
2754   eval cf_cv_prog_$1_c_o=yes
2755 else
2756   eval cf_cv_prog_$1_c_o=no
2757 fi
2758 rm -rf conftest*
2759 ])dnl
2760 if test $cf_cv_prog_$1_c_o = yes; then
2761   AC_MSG_RESULT([yes])
2762 else
2763   AC_MSG_RESULT([no])
2764 fi
2765 ])dnl
2766 dnl ---------------------------------------------------------------------------
2767 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
2768 dnl -------------
2769 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
2770 dnl This macro adds a check to ensure the script found something.
2771 AC_DEFUN([CF_PROG_EGREP],
2772 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
2773         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
2774                 then ac_cv_prog_egrep='grep -E'
2775                 else ac_cv_prog_egrep='egrep'
2776         fi])
2777         EGREP=$ac_cv_prog_egrep
2778         AC_SUBST([EGREP])
2779         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
2780 ])dnl
2781 dnl ---------------------------------------------------------------------------
2782 dnl CF_PROG_EXT version: 13 updated: 2015/04/18 09:03:58
2783 dnl -----------
2784 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
2785 AC_DEFUN([CF_PROG_EXT],
2786 [
2787 AC_REQUIRE([CF_CHECK_CACHE])
2788 case $cf_cv_system_name in
2789 (os2*)
2790         CFLAGS="$CFLAGS -Zmt"
2791         CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
2792         CXXFLAGS="$CXXFLAGS -Zmt"
2793         # autoconf's macro sets -Zexe and suffix both, which conflict:w
2794         LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
2795         ac_cv_exeext=.exe
2796         ;;
2797 esac
2798
2799 AC_EXEEXT
2800 AC_OBJEXT
2801
2802 PROG_EXT="$EXEEXT"
2803 AC_SUBST(PROG_EXT)
2804 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
2805 ])dnl
2806 dnl ---------------------------------------------------------------------------
2807 dnl CF_PROG_GNAT version: 3 updated: 2015/04/18 08:56:57
2808 dnl ------------
2809 dnl Check for gnatmake, ensure that it is complete.
2810 AC_DEFUN([CF_PROG_GNAT],[
2811 cf_ada_make=gnatmake
2812 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
2813 if test "$ac_cv_prog_gnat_exists" = no; then
2814         cf_ada_make=
2815         cf_cv_prog_gnat_correct=no
2816 else
2817         CF_GNAT_VERSION
2818         AC_CHECK_PROG(M4_exists, m4, yes, no)
2819         if test "$ac_cv_prog_M4_exists" = no; then
2820                 cf_cv_prog_gnat_correct=no
2821                 echo Ada95 binding required program m4 not found. Ada95 binding disabled.
2822         fi
2823         if test "$cf_cv_prog_gnat_correct" = yes; then
2824                 AC_MSG_CHECKING(if GNAT works)
2825                 CF_GNAT_TRY_RUN([procedure conftest;],
2826 [with Text_IO;
2827 with GNAT.OS_Lib;
2828 procedure conftest is
2829 begin
2830    Text_IO.Put ("Hello World");
2831    Text_IO.New_Line;
2832    GNAT.OS_Lib.OS_Exit (0);
2833 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
2834                 AC_MSG_RESULT($cf_cv_prog_gnat_correct)
2835         fi
2836 fi
2837
2838 AC_SUBST(cf_ada_make)
2839 ])dnl
2840 dnl ---------------------------------------------------------------------------
2841 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
2842 dnl ------------
2843 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
2844 dnl option if it is supported.
2845 AC_DEFUN([CF_PROG_LN_S],[
2846 AC_PROG_LN_S
2847 AC_MSG_CHECKING(if $LN_S -f options work)
2848
2849 rm -f conf$$.src conf$$dst
2850 echo >conf$$.dst
2851 echo first >conf$$.src
2852 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
2853         cf_prog_ln_sf=yes
2854 else
2855         cf_prog_ln_sf=no
2856 fi
2857 rm -f conf$$.dst conf$$src
2858 AC_MSG_RESULT($cf_prog_ln_sf)
2859
2860 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
2861 ])dnl
2862 dnl ---------------------------------------------------------------------------
2863 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2864 dnl ----------------
2865 dnl Remove all -U and -D options that refer to the given symbol from a list
2866 dnl of C compiler options.  This works around the problem that not all
2867 dnl compilers process -U and -D options from left-to-right, so a -U option
2868 dnl cannot be used to cancel the effect of a preceding -D option.
2869 dnl
2870 dnl $1 = target (which could be the same as the source variable)
2871 dnl $2 = source (including '$')
2872 dnl $3 = symbol to remove
2873 define([CF_REMOVE_DEFINE],
2874 [
2875 $1=`echo "$2" | \
2876         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2877                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2878 ])dnl
2879 dnl ---------------------------------------------------------------------------
2880 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
2881 dnl -------------
2882 dnl Remove the given library from the symbol
2883 dnl
2884 dnl $1 = target (which could be the same as the source variable)
2885 dnl $2 = source (including '$')
2886 dnl $3 = library to remove
2887 define([CF_REMOVE_LIB],
2888 [
2889 # remove $3 library from $2
2890 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
2891 ])dnl
2892 dnl ---------------------------------------------------------------------------
2893 dnl CF_SHARED_OPTS version: 89 updated: 2015/08/15 18:38:59
2894 dnl --------------
2895 dnl --------------
2896 dnl Attempt to determine the appropriate CC/LD options for creating a shared
2897 dnl library.
2898 dnl
2899 dnl Notes:
2900 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
2901 dnl the build-tree, i.e., by making use of the libraries that are compiled in
2902 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
2903 dnl shared library since that can lead to unexpected results at runtime.
2904 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
2905 dnl libraries are compiled in ../../lib
2906 dnl
2907 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
2908 dnl to install symbolic links to the rel/abi versions of shared libraries.
2909 dnl
2910 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
2911 dnl version when making symbolic links.
2912 dnl
2913 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
2914 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
2915 dnl (ex: libncurses.so.<ver>).
2916 dnl
2917 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
2918 AC_DEFUN([CF_SHARED_OPTS],
2919 [
2920         AC_REQUIRE([CF_LD_RPATH_OPT])
2921         RM_SHARED_OPTS=
2922         LOCAL_LDFLAGS=
2923         LOCAL_LDFLAGS2=
2924         LD_SHARED_OPTS=
2925         INSTALL_LIB="-m 644"
2926         : ${rel_builddir:=.}
2927
2928         shlibdir=$libdir
2929         AC_SUBST(shlibdir)
2930
2931         MAKE_DLLS="#"
2932         AC_SUBST(MAKE_DLLS)
2933
2934         cf_cv_do_symlinks=no
2935         cf_ld_rpath_opt=
2936         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
2937
2938         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
2939         AC_ARG_WITH(shlib-version,
2940         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
2941         [test -z "$withval" && withval=auto
2942         case $withval in
2943         (yes)
2944                 cf_cv_shlib_version=auto
2945                 ;;
2946         (rel|abi|auto)
2947                 cf_cv_shlib_version=$withval
2948                 ;;
2949         (*)
2950                 AC_MSG_RESULT($withval)
2951                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
2952                 ;;
2953         esac
2954         ],[cf_cv_shlib_version=auto])
2955         AC_MSG_RESULT($cf_cv_shlib_version)
2956
2957         cf_cv_rm_so_locs=no
2958         cf_try_cflags=
2959
2960         # Some less-capable ports of gcc support only -fpic
2961         CC_SHARED_OPTS=
2962         if test "$GCC" = yes
2963         then
2964                 AC_MSG_CHECKING(which $CC option to use)
2965                 cf_save_CFLAGS="$CFLAGS"
2966                 for CC_SHARED_OPTS in -fPIC -fpic ''
2967                 do
2968                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
2969                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
2970                 done
2971                 AC_MSG_RESULT($CC_SHARED_OPTS)
2972                 CFLAGS="$cf_save_CFLAGS"
2973         fi
2974
2975         cf_cv_shlib_version_infix=no
2976
2977         case $cf_cv_system_name in
2978         (aix4.[3-9]*|aix[[5-7]]*)
2979                 if test "$GCC" = yes; then
2980                         CC_SHARED_OPTS='-Wl,-brtl'
2981                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
2982                 else
2983                         CC_SHARED_OPTS='-brtl'
2984                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
2985                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
2986                 fi
2987                 ;;
2988         (beos*)
2989                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
2990                 ;;
2991         (cygwin*)
2992                 CC_SHARED_OPTS=
2993                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
2994                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
2995                 cf_cv_shlib_version=cygdll
2996                 cf_cv_shlib_version_infix=cygdll
2997                 shlibdir=$bindir
2998                 MAKE_DLLS=
2999                 cat >mk_shared_lib.sh <<-CF_EOF
3000                 #!$SHELL
3001                 SHARED_LIB=\[$]1
3002                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3003                 shift
3004                 cat <<-EOF
3005                 Linking shared library
3006                 ** SHARED_LIB \[$]SHARED_LIB
3007                 ** IMPORT_LIB \[$]IMPORT_LIB
3008 EOF
3009                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3010 CF_EOF
3011                 chmod +x mk_shared_lib.sh
3012                 ;;
3013         (msys*)
3014                 CC_SHARED_OPTS=
3015                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3016                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3017                 cf_cv_shlib_version=msysdll
3018                 cf_cv_shlib_version_infix=msysdll
3019                 shlibdir=$bindir
3020                 MAKE_DLLS=
3021                 cat >mk_shared_lib.sh <<-CF_EOF
3022                 #!$SHELL
3023                 SHARED_LIB=\[$]1
3024                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3025                 shift
3026                 cat <<-EOF
3027                 Linking shared library
3028                 ** SHARED_LIB \[$]SHARED_LIB
3029                 ** IMPORT_LIB \[$]IMPORT_LIB
3030 EOF
3031                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3032 CF_EOF
3033                 chmod +x mk_shared_lib.sh
3034                 ;;
3035         (darwin*)
3036                 cf_try_cflags="no-cpp-precomp"
3037                 CC_SHARED_OPTS="-dynamic"
3038                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
3039                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
3040                 cf_cv_shlib_version_infix=yes
3041                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
3042                         cf_save_LDFLAGS=$LDFLAGS
3043                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3044                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
3045                                 LDFLAGS=$cf_save_LDFLAGS])
3046                 if test $cf_cv_ldflags_search_paths_first = yes; then
3047                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3048                 fi
3049                 ;;
3050         (hpux[[7-8]]*)
3051                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
3052                 if test "$GCC" != yes; then
3053                         CC_SHARED_OPTS='+Z'
3054                 fi
3055                 MK_SHARED_LIB='${LD} -b -o $[@]'
3056                 INSTALL_LIB="-m 555"
3057                 ;;
3058         (hpux*)
3059                 # (tested with gcc 2.7.2 -- I don't have c89)
3060                 if test "$GCC" = yes; then
3061                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
3062                 else
3063                         CC_SHARED_OPTS='+Z'
3064                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
3065                 fi
3066                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
3067                 # HP-UX shared libraries must be executable, and should be
3068                 # readonly to exploit a quirk in the memory manager.
3069                 INSTALL_LIB="-m 555"
3070                 ;;
3071         (interix*)
3072                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3073                 if test "$cf_cv_shlib_version" = rel; then
3074                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
3075                 else
3076                         cf_shared_soname='`basename $@`'
3077                 fi
3078                 CC_SHARED_OPTS=
3079                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
3080                 ;;
3081         (irix*)
3082                 if test "$cf_cv_enable_rpath" = yes ; then
3083                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3084                 fi
3085                 # tested with IRIX 5.2 and 'cc'.
3086                 if test "$GCC" != yes; then
3087                         CC_SHARED_OPTS='-KPIC'
3088                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
3089                 else
3090                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
3091                 fi
3092                 cf_cv_rm_so_locs=yes
3093                 ;;
3094         (linux*|gnu*|k*bsd*-gnu)
3095                 if test "$DFT_LWR_MODEL" = "shared" ; then
3096                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3097                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3098                 fi
3099                 if test "$cf_cv_enable_rpath" = yes ; then
3100                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3101                 fi
3102                 CF_SHARED_SONAME
3103                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3104                 ;;
3105         (mingw*)
3106                 cf_cv_shlib_version=mingw
3107                 cf_cv_shlib_version_infix=mingw
3108                 shlibdir=$bindir
3109                 MAKE_DLLS=
3110                 if test "$DFT_LWR_MODEL" = "shared" ; then
3111                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
3112                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3113                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
3114                 fi
3115                 CC_SHARED_OPTS=
3116                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3117                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3118                 cat >mk_shared_lib.sh <<-CF_EOF
3119                 #!$SHELL
3120                 SHARED_LIB=\[$]1
3121                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3122                 shift
3123                 cat <<-EOF
3124                 Linking shared library
3125                 ** SHARED_LIB \[$]SHARED_LIB
3126                 ** IMPORT_LIB \[$]IMPORT_LIB
3127 EOF
3128                 exec \[$]* -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3129 CF_EOF
3130                 chmod +x mk_shared_lib.sh
3131                 ;;
3132         (openbsd[[2-9]].*|mirbsd*)
3133                 if test "$DFT_LWR_MODEL" = "shared" ; then
3134                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3135                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3136                 fi
3137                 if test "$cf_cv_enable_rpath" = yes ; then
3138                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3139                 fi
3140                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3141                 CF_SHARED_SONAME
3142                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3143                 ;;
3144         (nto-qnx*|openbsd*|freebsd[[12]].*)
3145                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3146                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
3147                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3148                 ;;
3149         (dragonfly*|freebsd*)
3150                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3151                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3152                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3153                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
3154                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3155                 fi
3156                 CF_SHARED_SONAME
3157                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3158                 ;;
3159         (netbsd*)
3160                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3161                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3162                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3163                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3164                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3165                         if test "$cf_cv_shlib_version" = auto; then
3166                         if test -f /usr/libexec/ld.elf_so; then
3167                                 cf_cv_shlib_version=abi
3168                         else
3169                                 cf_cv_shlib_version=rel
3170                         fi
3171                         fi
3172                         CF_SHARED_SONAME
3173                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
3174                 else
3175                         MK_SHARED_LIB='${CC} -Wl,-shared -Wl,-Bshareable -o $[@]'
3176                 fi
3177                 ;;
3178         (osf*|mls+*)
3179                 # tested with OSF/1 V3.2 and 'cc'
3180                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
3181                 # link with shared libs).
3182                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
3183                 case $host_os in
3184                 (osf4*)
3185                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
3186                         ;;
3187                 esac
3188                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
3189                 if test "$DFT_LWR_MODEL" = "shared" ; then
3190                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3191                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3192                 fi
3193                 cf_cv_rm_so_locs=yes
3194                 ;;
3195         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
3196                 # tested with osr5.0.5
3197                 if test "$GCC" != yes; then
3198                         CC_SHARED_OPTS='-belf -KPIC'
3199                 fi
3200                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
3201                 if test "$cf_cv_enable_rpath" = yes ; then
3202                         # only way is to set LD_RUN_PATH but no switch for it
3203                         RUN_PATH=$libdir
3204                 fi
3205                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3206                 LINK_PROGS='LD_RUN_PATH=${libdir}'
3207                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
3208                 ;;
3209         (sunos4*)
3210                 # tested with SunOS 4.1.1 and gcc 2.7.0
3211                 if test "$GCC" != yes; then
3212                         CC_SHARED_OPTS='-KPIC'
3213                 fi
3214                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
3215                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3216                 ;;
3217         (solaris2*)
3218                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
3219                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
3220                 if test "$DFT_LWR_MODEL" = "shared" ; then
3221                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
3222                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3223                 fi
3224                 if test "$cf_cv_enable_rpath" = yes ; then
3225                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
3226                 fi
3227                 CF_SHARED_SONAME
3228                 if test "$GCC" != yes; then
3229                         cf_save_CFLAGS="$CFLAGS"
3230                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
3231                         do
3232                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
3233                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
3234                         done
3235                         CFLAGS="$cf_save_CFLAGS"
3236                         CC_SHARED_OPTS=$cf_shared_opts
3237                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3238                 else
3239                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3240                 fi
3241                 ;;
3242         (sysv5uw7*|unix_sv*)
3243                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
3244                 if test "$GCC" != yes; then
3245                         CC_SHARED_OPTS='-KPIC'
3246                 fi
3247                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
3248                 ;;
3249         (*)
3250                 CC_SHARED_OPTS='unknown'
3251                 MK_SHARED_LIB='echo unknown'
3252                 ;;
3253         esac
3254
3255         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
3256         case "$cf_cv_shlib_version" in
3257         (rel|abi)
3258                 case "$MK_SHARED_LIB" in
3259                 (*'-o $[@]')
3260                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
3261                         ;;
3262                 (*)
3263                         AC_MSG_WARN(ignored --with-shlib-version)
3264                         ;;
3265                 esac
3266                 ;;
3267         esac
3268
3269         if test -n "$cf_try_cflags"
3270         then
3271 cat > conftest.$ac_ext <<EOF
3272 #line __oline__ "${as_me:-configure}"
3273 #include <stdio.h>
3274 int main(int argc, char *argv[[]])
3275 {
3276         printf("hello\n");
3277         return (argv[[argc-1]] == 0) ;
3278 }
3279 EOF
3280                 cf_save_CFLAGS="$CFLAGS"
3281                 for cf_opt in $cf_try_cflags
3282                 do
3283                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
3284                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
3285                         if AC_TRY_EVAL(ac_compile); then
3286                                 AC_MSG_RESULT(yes)
3287                                 cf_save_CFLAGS="$CFLAGS"
3288                         else
3289                                 AC_MSG_RESULT(no)
3290                         fi
3291                 done
3292                 CFLAGS="$cf_save_CFLAGS"
3293         fi
3294
3295
3296         # RPATH_LIST is a colon-separated list of directories
3297         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
3298         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
3299
3300         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
3301
3302         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
3303         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
3304
3305         AC_SUBST(CC_SHARED_OPTS)
3306         AC_SUBST(LD_RPATH_OPT)
3307         AC_SUBST(LD_SHARED_OPTS)
3308         AC_SUBST(MK_SHARED_LIB)
3309         AC_SUBST(RM_SHARED_OPTS)
3310
3311         AC_SUBST(LINK_PROGS)
3312         AC_SUBST(LINK_TESTS)
3313
3314         AC_SUBST(EXTRA_LDFLAGS)
3315         AC_SUBST(LOCAL_LDFLAGS)
3316         AC_SUBST(LOCAL_LDFLAGS2)
3317
3318         AC_SUBST(INSTALL_LIB)
3319         AC_SUBST(RPATH_LIST)
3320 ])dnl
3321 dnl ---------------------------------------------------------------------------
3322 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
3323 dnl ----------------
3324 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
3325 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
3326 dnl option.
3327 dnl
3328 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
3329 dnl If missing, use "rel".
3330 define([CF_SHARED_SONAME],
3331 [
3332         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
3333         if test "$cf_cv_shlib_version" = rel; then
3334                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3335         else
3336                 cf_cv_shared_soname='`basename $[@]`'
3337         fi
3338 ])
3339 dnl ---------------------------------------------------------------------------
3340 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
3341 dnl --------------
3342 dnl     Remove "-g" option from the compiler options
3343 AC_DEFUN([CF_STRIP_G_OPT],
3344 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
3345 dnl ---------------------------------------------------------------------------
3346 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
3347 dnl --------------
3348 dnl Construct a search-list for a nonstandard header/lib-file
3349 dnl     $1 = the variable to return as result
3350 dnl     $2 = the package name
3351 dnl     $3 = the subdirectory, e.g., bin, include or lib
3352 AC_DEFUN([CF_SUBDIR_PATH],
3353 [
3354 $1=
3355
3356 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3357
3358 for cf_subdir_prefix in \
3359         /usr \
3360         /usr/local \
3361         /usr/pkg \
3362         /opt \
3363         /opt/local \
3364         [$]HOME
3365 do
3366         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
3367 done
3368 ])dnl
3369 dnl ---------------------------------------------------------------------------
3370 dnl CF_TERM_HEADER version: 4 updated: 2015/04/15 19:08:48
3371 dnl --------------
3372 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3373 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3374 dnl but some packagers change this, breaking various applications.
3375 AC_DEFUN([CF_TERM_HEADER],[
3376 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3377 case ${cf_cv_ncurses_header} in
3378 (*/ncurses.h|*/ncursesw.h)
3379         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3380         ;;
3381 (*)
3382         cf_term_header=term.h
3383         ;;
3384 esac
3385
3386 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3387 do
3388 AC_TRY_COMPILE([#include <stdio.h>
3389 #include <${cf_cv_ncurses_header:-curses.h}>
3390 #include <$cf_test>
3391 ],[int x = auto_left_margin],[
3392         cf_cv_term_header="$cf_test"],[
3393         cf_cv_term_header=unknown
3394         ])
3395         test "$cf_cv_term_header" != unknown && break
3396 done
3397 ])
3398
3399 # Set definitions to allow ifdef'ing to accommodate subdirectories
3400
3401 case $cf_cv_term_header in
3402 (*term.h)
3403         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
3404         ;;
3405 esac
3406
3407 case $cf_cv_term_header in
3408 (ncurses/term.h)
3409         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
3410         ;;
3411 (ncursesw/term.h)
3412         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
3413         ;;
3414 esac
3415 ])dnl
3416 dnl ---------------------------------------------------------------------------
3417 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
3418 dnl ---------------
3419 dnl Define a top_builddir symbol, for applications that need an absolute path.
3420 AC_DEFUN([CF_TOP_BUILDDIR],
3421 [
3422 top_builddir=ifelse($1,,`pwd`,$1)
3423 AC_SUBST(top_builddir)
3424 ])dnl
3425 dnl ---------------------------------------------------------------------------
3426 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
3427 dnl -------------------
3428 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
3429 dnl can define it successfully.
3430 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
3431 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3432         AC_TRY_COMPILE([
3433 #include <stdlib.h>
3434 #include <string.h>
3435 #include <sys/types.h>
3436 ],[
3437 #ifndef _XOPEN_SOURCE
3438 make an error
3439 #endif],
3440         [cf_cv_xopen_source=no],
3441         [cf_save="$CPPFLAGS"
3442          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3443          AC_TRY_COMPILE([
3444 #include <stdlib.h>
3445 #include <string.h>
3446 #include <sys/types.h>
3447 ],[
3448 #ifdef _XOPEN_SOURCE
3449 make an error
3450 #endif],
3451         [cf_cv_xopen_source=no],
3452         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3453         CPPFLAGS="$cf_save"
3454         ])
3455 ])
3456
3457 if test "$cf_cv_xopen_source" != no ; then
3458         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3459         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3460         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3461         CF_ADD_CFLAGS($cf_temp_xopen_source)
3462 fi
3463 ])
3464 dnl ---------------------------------------------------------------------------
3465 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3466 dnl --------
3467 dnl Make an uppercase version of a variable
3468 dnl $1=uppercase($2)
3469 AC_DEFUN([CF_UPPER],
3470 [
3471 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3472 ])dnl
3473 dnl ---------------------------------------------------------------------------
3474 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
3475 dnl -----------
3476 dnl Check for multibyte support, and if not found, utf8 compatibility library
3477 AC_DEFUN([CF_UTF8_LIB],
3478 [
3479 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3480         cf_save_LIBS="$LIBS"
3481         AC_TRY_LINK([
3482 #include <stdlib.h>],[putwc(0,0);],
3483         [cf_cv_utf8_lib=yes],
3484         [CF_FIND_LINKAGE([
3485 #include <libutf8.h>],[putwc(0,0);],utf8,
3486                 [cf_cv_utf8_lib=add-on],
3487                 [cf_cv_utf8_lib=no])
3488 ])])
3489
3490 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3491 # ncurses/ncursesw:
3492 if test "$cf_cv_utf8_lib" = "add-on" ; then
3493         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
3494         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3495         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3496         CF_ADD_LIBS($cf_cv_library_file_utf8)
3497 fi
3498 ])dnl
3499 dnl ---------------------------------------------------------------------------
3500 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3501 dnl ----------
3502 dnl Use AC_VERBOSE w/o the warnings
3503 AC_DEFUN([CF_VERBOSE],
3504 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3505 CF_MSG_LOG([$1])
3506 ])dnl
3507 dnl ---------------------------------------------------------------------------
3508 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
3509 dnl ---------------
3510 dnl Check for compiler-support for weak symbols.
3511 dnl This works with "recent" gcc.
3512 AC_DEFUN([CF_WEAK_SYMBOLS],[
3513 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
3514
3515 AC_TRY_COMPILE([
3516 #include <stdio.h>],
3517 [
3518 #if defined(__GNUC__)
3519 #  if defined __USE_ISOC99
3520 #    define _cat_pragma(exp)    _Pragma(#exp)
3521 #    define _weak_pragma(exp)   _cat_pragma(weak name)
3522 #  else
3523 #    define _weak_pragma(exp)
3524 #  endif
3525 #  define _declare(name)        __extension__ extern __typeof__(name) name
3526 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
3527 #endif
3528
3529 weak_symbol(fopen);
3530 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
3531 ])
3532 ])dnl
3533 dnl ---------------------------------------------------------------------------
3534 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
3535 dnl --------------------
3536 dnl Command-line option to specify the Ada95 compiler.
3537 AC_DEFUN([CF_WITH_ADA_COMPILER],[
3538 AC_MSG_CHECKING(for ada-compiler)
3539 AC_ARG_WITH(ada-compiler,
3540         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
3541         [cf_ada_compiler=$withval],
3542         [cf_ada_compiler=gnatmake])
3543 AC_SUBST(cf_ada_compiler)
3544 AC_MSG_RESULT($cf_ada_compiler)
3545 ])dnl
3546 dnl ---------------------------------------------------------------------------
3547 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
3548 dnl -------------------
3549 dnl Command-line option to specify where Ada includes will install.
3550 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
3551 AC_MSG_CHECKING(for ada-include)
3552 CF_WITH_PATH(ada-include,
3553    [  --with-ada-include=DIR  Ada includes are in DIR],
3554    ADA_INCLUDE,
3555    PREFIX/share/ada/adainclude,
3556    [$]prefix/share/ada/adainclude)
3557 AC_SUBST(ADA_INCLUDE)
3558 AC_MSG_RESULT($ADA_INCLUDE)
3559 ])dnl
3560 dnl ---------------------------------------------------------------------------
3561 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
3562 dnl -------------------
3563 dnl Command-line option to specify where Ada objects will install.
3564 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
3565 AC_MSG_CHECKING(for ada-objects)
3566 CF_WITH_PATH(ada-objects,
3567    [  --with-ada-objects=DIR  Ada objects are in DIR],
3568    ADA_OBJECTS,
3569    PREFIX/lib/ada/adalib,
3570    [$]prefix/lib/ada/adalib)
3571 AC_SUBST(ADA_OBJECTS)
3572 AC_MSG_RESULT($ADA_OBJECTS)
3573 ])dnl
3574 dnl ---------------------------------------------------------------------------
3575 dnl CF_WITH_ADA_SHAREDLIB version: 4 updated: 2014/05/31 21:08:37
3576 dnl ---------------------
3577 dnl Command-line option to specify if an Ada95 shared-library should be built,
3578 dnl and optionally what its soname should be.
3579 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
3580 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
3581 AC_ARG_WITH(ada-sharedlib,
3582         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
3583         [with_ada_sharedlib=$withval],
3584         [with_ada_sharedlib=no])
3585 AC_MSG_RESULT($with_ada_sharedlib)
3586
3587 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
3588 MAKE_ADA_SHAREDLIB="#"
3589
3590 if test "x$with_ada_sharedlib" != xno
3591 then
3592         MAKE_ADA_SHAREDLIB=
3593         if test "x$with_ada_sharedlib" != xyes
3594         then
3595                 ADA_SHAREDLIB="$with_ada_sharedlib"
3596         fi
3597 fi
3598
3599 AC_SUBST(ADA_SHAREDLIB)
3600 AC_SUBST(MAKE_ADA_SHAREDLIB)
3601 ])dnl
3602 dnl ---------------------------------------------------------------------------
3603 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3604 dnl ------------------
3605 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3606 dnl libraries.
3607 AC_DEFUN([CF_WITH_CURSES_DIR],[
3608
3609 AC_MSG_CHECKING(for specific curses-directory)
3610 AC_ARG_WITH(curses-dir,
3611         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3612         [cf_cv_curses_dir=$withval],
3613         [cf_cv_curses_dir=no])
3614 AC_MSG_RESULT($cf_cv_curses_dir)
3615
3616 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3617 then
3618         CF_PATH_SYNTAX(withval)
3619         if test -d "$cf_cv_curses_dir"
3620         then
3621                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3622                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3623         fi
3624 fi
3625 ])dnl
3626 dnl ---------------------------------------------------------------------------
3627 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
3628 dnl ------------------
3629 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
3630 dnl "lib" prefix, e.g., because it used the dll naming convention.
3631 dnl
3632 dnl $1 = variable to set
3633 AC_DEFUN([CF_WITH_LIB_PREFIX],
3634 [
3635 AC_MSG_CHECKING(if you want to have a library-prefix)