Ada95/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 2010-2015,2016 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.112 2016/06/25 20:30:41 tom Exp $
  32 dnl Macros used in NCURSES Ada95 auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
  43 dnl ------------------
  44 dnl Conditionally generate script according to whether we're using a given autoconf.
  45 dnl
  46 dnl $1 = version to compare against
  47 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  48 dnl $3 = code to use if AC_ACVERSION is older than $1.
  49 define([CF_ACVERSION_CHECK],
  50 [
  51 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
  52 ifdef([m4_version_compare],
  53 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  54 [CF_ACVERSION_COMPARE(
  55 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  56 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  57 dnl ---------------------------------------------------------------------------
  58 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  59 dnl --------------------
  60 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  61 dnl                      MAJOR2, MINOR2, TERNARY2,
  62 dnl                      PRINTABLE2, not FOUND, FOUND)
  63 define([CF_ACVERSION_COMPARE],
  64 [ifelse(builtin([eval], [$2 < $5]), 1,
  65 [ifelse([$8], , ,[$8])],
  66 [ifelse([$9], , ,[$9])])])dnl
  67 dnl ---------------------------------------------------------------------------
  68 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
  69 dnl -------------------
  70 dnl Construct the list of include-options for the C programs in the Ada95
  71 dnl binding.
  72 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  73 [
  74 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  75 if test "$srcdir" != "."; then
  76         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  77 fi
  78 if test "$GCC" != yes; then
  79         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  80 elif test "$includedir" != "/usr/include"; then
  81         if test "$includedir" = '${prefix}/include' ; then
  82                 if test x$prefix != x/usr ; then
  83                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  84                 fi
  85         else
  86                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  87         fi
  88 fi
  89 AC_SUBST(ACPPFLAGS)
  90 ])dnl
  91 dnl ---------------------------------------------------------------------------
  92 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
  93 dnl ---------------
  94 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
  95 AC_DEFUN([CF_ADD_ADAFLAGS],[
  96         ADAFLAGS="$ADAFLAGS $1"
  97         AC_SUBST(ADAFLAGS)
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ADD_CFLAGS version: 12 updated: 2015/04/12 15:39:00
 101 dnl -------------
 102 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 103 dnl The second parameter if given makes this macro verbose.
 104 dnl
 105 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 106 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 107 dnl confused by the quotes (which require backslashes to keep them usable).
 108 AC_DEFUN([CF_ADD_CFLAGS],
 109 [
 110 cf_fix_cppflags=no
 111 cf_new_cflags=
 112 cf_new_cppflags=
 113 cf_new_extra_cppflags=
 114
 115 for cf_add_cflags in $1
 116 do
 117 case $cf_fix_cppflags in
 118 (no)
 119         case $cf_add_cflags in
 120         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 121                 case $cf_add_cflags in
 122                 (-D*)
 123                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 124
 125                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 126                                 && test -z "${cf_tst_cflags}" \
 127                                 && cf_fix_cppflags=yes
 128
 129                         if test $cf_fix_cppflags = yes ; then
 130                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 131                                 continue
 132                         elif test "${cf_tst_cflags}" = "\"'" ; then
 133                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 134                                 continue
 135                         fi
 136                         ;;
 137                 esac
 138                 case "$CPPFLAGS" in
 139                 (*$cf_add_cflags)
 140                         ;;
 141                 (*)
 142                         case $cf_add_cflags in
 143                         (-D*)
 144                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 145                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 146                                 ;;
 147                         esac
 148                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 149                         ;;
 150                 esac
 151                 ;;
 152         (*)
 153                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 154                 ;;
 155         esac
 156         ;;
 157 (yes)
 158         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 159
 160         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 161
 162         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 163                 && test -z "${cf_tst_cflags}" \
 164                 && cf_fix_cppflags=no
 165         ;;
 166 esac
 167 done
 168
 169 if test -n "$cf_new_cflags" ; then
 170         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 171         CFLAGS="$CFLAGS $cf_new_cflags"
 172 fi
 173
 174 if test -n "$cf_new_cppflags" ; then
 175         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 176         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 177 fi
 178
 179 if test -n "$cf_new_extra_cppflags" ; then
 180         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 181         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 182 fi
 183
 184 AC_SUBST(EXTRA_CPPFLAGS)
 185
 186 ])dnl
 187 dnl ---------------------------------------------------------------------------
 188 dnl CF_ADD_INCDIR version: 14 updated: 2015/05/25 20:53:04
 189 dnl -------------
 190 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 191 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 192 dnl but old versions (and some misinstalled ones) need that.  To make things
 193 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 194 dnl the include-path).
 195 AC_DEFUN([CF_ADD_INCDIR],
 196 [
 197 if test -n "$1" ; then
 198   for cf_add_incdir in $1
 199   do
 200         while test $cf_add_incdir != /usr/include
 201         do
 202           if test -d $cf_add_incdir
 203           then
 204                 cf_have_incdir=no
 205                 if test -n "$CFLAGS$CPPFLAGS" ; then
 206                   # a loop is needed to ensure we can add subdirs of existing dirs
 207                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 208                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 209                           cf_have_incdir=yes; break
 210                         fi
 211                   done
 212                 fi
 213
 214                 if test "$cf_have_incdir" = no ; then
 215                   if test "$cf_add_incdir" = /usr/local/include ; then
 216                         if test "$GCC" = yes
 217                         then
 218                           cf_save_CPPFLAGS=$CPPFLAGS
 219                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 220                           AC_TRY_COMPILE([#include <stdio.h>],
 221                                   [printf("Hello")],
 222                                   [],
 223                                   [cf_have_incdir=yes])
 224                           CPPFLAGS=$cf_save_CPPFLAGS
 225                         fi
 226                   fi
 227                 fi
 228
 229                 if test "$cf_have_incdir" = no ; then
 230                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 231                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 232
 233                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 234                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 235                   cf_add_incdir="$cf_top_incdir"
 236                 else
 237                   break
 238                 fi
 239           else
 240                 break
 241           fi
 242         done
 243   done
 244 fi
 245 ])dnl
 246 dnl ---------------------------------------------------------------------------
 247 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 248 dnl ----------
 249 dnl Add a library, used to enforce consistency.
 250 dnl
 251 dnl $1 = library to add, without the "-l"
 252 dnl $2 = variable to update (default $LIBS)
 253 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 254 dnl ---------------------------------------------------------------------------
 255 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 256 dnl -------------
 257 dnl     Adds to the library-path
 258 dnl
 259 dnl     Some machines have trouble with multiple -L options.
 260 dnl
 261 dnl $1 is the (list of) directory(s) to add
 262 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 263 dnl
 264 AC_DEFUN([CF_ADD_LIBDIR],
 265 [
 266 if test -n "$1" ; then
 267         for cf_add_libdir in $1
 268         do
 269                 if test $cf_add_libdir = /usr/lib ; then
 270                         :
 271                 elif test -d $cf_add_libdir
 272                 then
 273                         cf_have_libdir=no
 274                         if test -n "$LDFLAGS$LIBS" ; then
 275                                 # a loop is needed to ensure we can add subdirs of existing dirs
 276                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 277                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 278                                                 cf_have_libdir=yes; break
 279                                         fi
 280                                 done
 281                         fi
 282                         if test "$cf_have_libdir" = no ; then
 283                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 284                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 285                         fi
 286                 fi
 287         done
 288 fi
 289 ])dnl
 290 dnl ---------------------------------------------------------------------------
 291 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 292 dnl -----------
 293 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 294 dnl prepended to an existing list, since their dependencies are assumed to
 295 dnl already exist in the list.
 296 dnl
 297 dnl $1 = libraries to add, with the "-l", etc.
 298 dnl $2 = variable to update (default $LIBS)
 299 AC_DEFUN([CF_ADD_LIBS],[
 300 cf_add_libs="$1"
 301 # Filter out duplicates - this happens with badly-designed ".pc" files...
 302 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 303 do
 304         for cf_add_2lib in $cf_add_libs
 305         do
 306                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 307                 then
 308                         cf_add_1lib=
 309                         break
 310                 fi
 311         done
 312         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 313 done
 314 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 315 ])dnl
 316 dnl ---------------------------------------------------------------------------
 317 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 318 dnl ------------------
 319 dnl Append to a search-list for a nonstandard header/lib-file
 320 dnl     $1 = the variable to return as result
 321 dnl     $2 = the package name
 322 dnl     $3 = the subdirectory, e.g., bin, include or lib
 323 dnl $4 = the directory under which we will test for subdirectories
 324 dnl $5 = a directory that we do not want $4 to match
 325 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 326 [
 327 test "x$4" != "x$5" && \
 328 test -d "$4" && \
 329 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 330         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 331         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 332         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 333         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 334         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 335         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 336 }
 337 ])dnl
 338 dnl ---------------------------------------------------------------------------
 339 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 340 dnl --------------
 341 dnl Allow user to disable a normally-on option.
 342 AC_DEFUN([CF_ARG_DISABLE],
 343 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 344 dnl ---------------------------------------------------------------------------
 345 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 346 dnl -------------
 347 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 348 dnl values.
 349 dnl
 350 dnl Parameters:
 351 dnl $1 = option name
 352 dnl $2 = help-string
 353 dnl $3 = action to perform if option is not default
 354 dnl $4 = action if perform if option is default
 355 dnl $5 = default option value (either 'yes' or 'no')
 356 AC_DEFUN([CF_ARG_OPTION],
 357 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 358         if test "$enableval" != "$5" ; then
 359 ifelse([$3],,[    :]dnl
 360 ,[    $3]) ifelse([$4],,,[
 361         else
 362                 $4])
 363         fi],[enableval=$5 ifelse([$4],,,[
 364         $4
 365 ])dnl
 366 ])])dnl
 367 dnl ---------------------------------------------------------------------------
 368 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 369 dnl -----------
 370 dnl Check for suitable "ar" (archiver) options for updating an archive.
 371 dnl
 372 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 373 dnl as well as a workaround for breakage of make's archive rules by the GNU
 374 dnl binutils "ar" program.
 375 AC_DEFUN([CF_AR_FLAGS],[
 376 AC_REQUIRE([CF_PROG_AR])
 377
 378 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 379         cf_cv_ar_flags=unknown
 380         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 381         do
 382
 383                 # check if $ARFLAGS already contains this choice
 384                 if test "x$ARFLAGS" != "x" ; then
 385                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 386                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 387                                 cf_cv_ar_flags=
 388                                 break
 389                         fi
 390                 fi
 391
 392                 rm -f conftest.$ac_cv_objext
 393                 rm -f conftest.a
 394
 395                 cat >conftest.$ac_ext <<EOF
 396 #line __oline__ "configure"
 397 int     testdata[[3]] = { 123, 456, 789 };
 398 EOF
 399                 if AC_TRY_EVAL(ac_compile) ; then
 400                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 401                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 402                         if test -f conftest.a ; then
 403                                 cf_cv_ar_flags=$cf_ar_flags
 404                                 break
 405                         fi
 406                 else
 407                         CF_VERBOSE(cannot compile test-program)
 408                         break
 409                 fi
 410         done
 411         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 412 ])
 413
 414 if test -n "$ARFLAGS" ; then
 415         if test -n "$cf_cv_ar_flags" ; then
 416                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 417         fi
 418 else
 419         ARFLAGS=$cf_cv_ar_flags
 420 fi
 421
 422 AC_SUBST(ARFLAGS)
 423 ])
 424 dnl ---------------------------------------------------------------------------
 425 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 426 dnl -----------
 427 dnl If we're cross-compiling, allow the user to override the tools and their
 428 dnl options.  The configure script is oriented toward identifying the host
 429 dnl compiler, etc., but we need a build compiler to generate parts of the
 430 dnl source.
 431 dnl
 432 dnl $1 = default for $CPPFLAGS
 433 dnl $2 = default for $LIBS
 434 AC_DEFUN([CF_BUILD_CC],[
 435 CF_ACVERSION_CHECK(2.52,,
 436         [AC_REQUIRE([CF_PROG_EXT])])
 437 if test "$cross_compiling" = yes ; then
 438
 439         # defaults that we might want to override
 440         : ${BUILD_CFLAGS:=''}
 441         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 442         : ${BUILD_LDFLAGS:=''}
 443         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 444         : ${BUILD_EXEEXT:='$x'}
 445         : ${BUILD_OBJEXT:='o'}
 446
 447         AC_ARG_WITH(build-cc,
 448                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 449                 [BUILD_CC="$withval"],
 450                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 451         AC_MSG_CHECKING(for native build C compiler)
 452         AC_MSG_RESULT($BUILD_CC)
 453
 454         AC_MSG_CHECKING(for native build C preprocessor)
 455         AC_ARG_WITH(build-cpp,
 456                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 457                 [BUILD_CPP="$withval"],
 458                 [BUILD_CPP='${BUILD_CC} -E'])
 459         AC_MSG_RESULT($BUILD_CPP)
 460
 461         AC_MSG_CHECKING(for native build C flags)
 462         AC_ARG_WITH(build-cflags,
 463                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 464                 [BUILD_CFLAGS="$withval"])
 465         AC_MSG_RESULT($BUILD_CFLAGS)
 466
 467         AC_MSG_CHECKING(for native build C preprocessor-flags)
 468         AC_ARG_WITH(build-cppflags,
 469                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 470                 [BUILD_CPPFLAGS="$withval"])
 471         AC_MSG_RESULT($BUILD_CPPFLAGS)
 472
 473         AC_MSG_CHECKING(for native build linker-flags)
 474         AC_ARG_WITH(build-ldflags,
 475                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 476                 [BUILD_LDFLAGS="$withval"])
 477         AC_MSG_RESULT($BUILD_LDFLAGS)
 478
 479         AC_MSG_CHECKING(for native build linker-libraries)
 480         AC_ARG_WITH(build-libs,
 481                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 482                 [BUILD_LIBS="$withval"])
 483         AC_MSG_RESULT($BUILD_LIBS)
 484
 485         # this assumes we're on Unix.
 486         BUILD_EXEEXT=
 487         BUILD_OBJEXT=o
 488
 489         : ${BUILD_CC:='${CC}'}
 490
 491         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 492                 AC_MSG_ERROR([Cross-build requires two compilers.
 493 Use --with-build-cc to specify the native compiler.])
 494         fi
 495
 496 else
 497         : ${BUILD_CC:='${CC}'}
 498         : ${BUILD_CPP:='${CPP}'}
 499         : ${BUILD_CFLAGS:='${CFLAGS}'}
 500         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 501         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 502         : ${BUILD_LIBS:='${LIBS}'}
 503         : ${BUILD_EXEEXT:='$x'}
 504         : ${BUILD_OBJEXT:='o'}
 505 fi
 506
 507 AC_SUBST(BUILD_CC)
 508 AC_SUBST(BUILD_CPP)
 509 AC_SUBST(BUILD_CFLAGS)
 510 AC_SUBST(BUILD_CPPFLAGS)
 511 AC_SUBST(BUILD_LDFLAGS)
 512 AC_SUBST(BUILD_LIBS)
 513 AC_SUBST(BUILD_EXEEXT)
 514 AC_SUBST(BUILD_OBJEXT)
 515 ])dnl
 516 dnl ---------------------------------------------------------------------------
 517 dnl CF_CC_ENV_FLAGS version: 4 updated: 2016/06/25 16:23:40
 518 dnl ---------------
 519 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 520 dnl into CC.  This will not help with broken scripts that wrap the compiler with
 521 dnl options, but eliminates a more common category of user confusion.
 522 dnl
 523 dnl In particular, it addresses the problem of being able to run the C
 524 dnl preprocessor in a consistent manner.
 525 dnl
 526 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 527 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 528 dnl outweighs that limitation.
 529 AC_DEFUN([CF_CC_ENV_FLAGS],
 530 [
 531 # This should have been defined by AC_PROG_CC
 532 : ${CC:=cc}
 533
 534 AC_MSG_CHECKING(\$CC variable)
 535 case "$CC" in
 536 (*[[\ \ ]]-*)
 537         AC_MSG_RESULT(broken)
 538         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 539         # humor him...
 540         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]][[    ]]*//'`
 541         CC=`echo "$CC " | sed -e 's/[[  ]]-[[IUD]][[^   ]][[^   ]]*//g' -e 's/[[        ]]*$//'`
 542         CF_ADD_CFLAGS($cf_flags)
 543         CF_VERBOSE(resulting CC: '$CC')
 544         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 545         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 546         ;;
 547 (*)
 548         AC_MSG_RESULT(ok)
 549         ;;
 550 esac
 551 ])dnl
 552 dnl ---------------------------------------------------------------------------
 553 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 554 dnl ---------------
 555 dnl Determine the default configuration into which we'll install ncurses.  This
 556 dnl can be overridden by the user's command-line options.  There's two items to
 557 dnl look for:
 558 dnl     1. the prefix (e.g., /usr)
 559 dnl     2. the header files (e.g., /usr/include/ncurses)
 560 dnl We'll look for a previous installation of ncurses and use the same defaults.
 561 dnl
 562 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 563 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 564 dnl programs from a vendor's.
 565 AC_DEFUN([CF_CFG_DEFAULTS],
 566 [
 567 AC_MSG_CHECKING(for prefix)
 568 if test "x$prefix" = "xNONE" ; then
 569         case "$cf_cv_system_name" in
 570                 # non-vendor systems don't have a conflict
 571         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 572                 prefix=/usr
 573                 ;;
 574         (*)     prefix=$ac_default_prefix
 575                 ;;
 576         esac
 577 fi
 578 AC_MSG_RESULT($prefix)
 579
 580 if test "x$prefix" = "xNONE" ; then
 581 AC_MSG_CHECKING(for default include-directory)
 582 test -n "$verbose" && echo 1>&AC_FD_MSG
 583 for cf_symbol in \
 584         $includedir \
 585         $includedir/ncurses \
 586         $prefix/include \
 587         $prefix/include/ncurses \
 588         /usr/local/include \
 589         /usr/local/include/ncurses \
 590         /usr/include \
 591         /usr/include/ncurses
 592 do
 593         cf_dir=`eval echo $cf_symbol`
 594         if test -f $cf_dir/curses.h ; then
 595         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 596                 includedir="$cf_symbol"
 597                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 598                 break
 599         fi
 600         fi
 601         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 602 done
 603 AC_MSG_RESULT($includedir)
 604 fi
 605 ])dnl
 606 dnl ---------------------------------------------------------------------------
 607 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 608 dnl --------------
 609 dnl Check if we're accidentally using a cache from a different machine.
 610 dnl Derive the system name, as a check for reusing the autoconf cache.
 611 dnl
 612 dnl If we've packaged config.guess and config.sub, run that (since it does a
 613 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 614 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 615 dnl which is useful in cross-compiles.
 616 dnl
 617 dnl Note: we would use $ac_config_sub, but that is one of the places where
 618 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 619 AC_DEFUN([CF_CHECK_CACHE],
 620 [
 621 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 622         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 623         system_name="$host_os"
 624 else
 625         system_name="`(uname -s -r) 2>/dev/null`"
 626         if test -z "$system_name" ; then
 627                 system_name="`(hostname) 2>/dev/null`"
 628         fi
 629 fi
 630 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 631 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 632
 633 test -z "$system_name" && system_name="$cf_cv_system_name"
 634 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 635
 636 if test ".$system_name" != ".$cf_cv_system_name" ; then
 637         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 638         AC_MSG_ERROR("Please remove config.cache and try again.")
 639 fi
 640 ])dnl
 641 dnl ---------------------------------------------------------------------------
 642 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
 643 dnl -----------------
 644 dnl Check if the given compiler is really clang.  clang's C driver defines
 645 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 646 dnl not ignore some gcc options.
 647 dnl
 648 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 649 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 650 dnl the wrappers for gcc and g++ warnings.
 651 dnl
 652 dnl $1 = GCC (default) or GXX
 653 dnl $2 = CLANG_COMPILER (default)
 654 dnl $3 = CFLAGS (default) or CXXFLAGS
 655 AC_DEFUN([CF_CLANG_COMPILER],[
 656 ifelse([$2],,CLANG_COMPILER,[$2])=no
 657
 658 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 659         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 660         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 661         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 662         AC_TRY_COMPILE([],[
 663 #ifdef __clang__
 664 #else
 665 make an error
 666 #endif
 667 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 668 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
 669 ],[])
 670         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 671         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 672 fi
 673 ])
 674 dnl ---------------------------------------------------------------------------
 675 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
 676 dnl ----------------
 677 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 678 dnl variations of ncurses' installs.
 679 dnl
 680 dnl $1 = ncurses when looking for ncurses, or is empty
 681 AC_DEFUN([CF_CURSES_HEADER],[
 682 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 683 cf_cv_ncurses_header=none
 684 for cf_header in \
 685         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
 686         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 687 do
 688 AC_TRY_COMPILE([#include <${cf_header}>],
 689         [initscr(); tgoto("?", 0,0)],
 690         [cf_cv_ncurses_header=$cf_header; break],[])
 691 done
 692 ])
 693
 694 if test "$cf_cv_ncurses_header" = none ; then
 695         AC_MSG_ERROR(No curses header-files found)
 696 fi
 697
 698 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 699 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 700 ])dnl
 701 dnl ---------------------------------------------------------------------------
 702 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
 703 dnl ----------
 704 dnl "dirname" is not portable, so we fake it with a shell script.
 705 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
 706 dnl ---------------------------------------------------------------------------
 707 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
 708 dnl ---------------
 709 dnl You can always use "make -n" to see the actual options, but it's hard to
 710 dnl pick out/analyze warning messages when the compile-line is long.
 711 dnl
 712 dnl Sets:
 713 dnl     ECHO_LT - symbol to control if libtool is verbose
 714 dnl     ECHO_LD - symbol to prefix "cc -o" lines
 715 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
 716 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
 717 dnl     ECHO_CC - symbol to put before any "cc" line
 718 dnl
 719 AC_DEFUN([CF_DISABLE_ECHO],[
 720 AC_MSG_CHECKING(if you want to see long compiling messages)
 721 CF_ARG_DISABLE(echo,
 722         [  --disable-echo          do not display "compiling" commands],
 723         [
 724         ECHO_LT='--silent'
 725         ECHO_LD='@echo linking [$]@;'
 726         RULE_CC='@echo compiling [$]<'
 727         SHOW_CC='@echo compiling [$]@'
 728         ECHO_CC='@'
 729 ],[
 730         ECHO_LT=''
 731         ECHO_LD=''
 732         RULE_CC=''
 733         SHOW_CC=''
 734         ECHO_CC=''
 735 ])
 736 AC_MSG_RESULT($enableval)
 737 AC_SUBST(ECHO_LT)
 738 AC_SUBST(ECHO_LD)
 739 AC_SUBST(RULE_CC)
 740 AC_SUBST(SHOW_CC)
 741 AC_SUBST(ECHO_CC)
 742 ])dnl
 743 dnl ---------------------------------------------------------------------------
 744 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
 745 dnl ------------------------
 746 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
 747 AC_MSG_CHECKING(if we want to use GNAT projects)
 748 CF_ARG_DISABLE(gnat-projects,
 749         [  --disable-gnat-projects test: disable GNAT projects even if usable],
 750         [enable_gnat_projects=no],
 751         [enable_gnat_projects=yes])
 752 AC_MSG_RESULT($enable_gnat_projects)
 753 ])dnl
 754 dnl ---------------------------------------------------------------------------
 755 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
 756 dnl ---------------
 757 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
 758 dnl prefer a standard location, and use -L options only if we do not find the
 759 dnl library in the standard library location(s).
 760 dnl     $1 = library name
 761 dnl     $2 = library class, usually the same as library name
 762 dnl     $3 = includes
 763 dnl     $4 = code fragment to compile/link
 764 dnl     $5 = corresponding function-name
 765 dnl     $6 = flag, nonnull if failure should not cause an error-exit
 766 dnl
 767 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
 768 dnl to use a -L option.
 769 AC_DEFUN([CF_FIND_LIBRARY],
 770 [
 771         eval 'cf_cv_have_lib_'$1'=no'
 772         cf_libdir=""
 773         AC_CHECK_FUNC($5,
 774                 eval 'cf_cv_have_lib_'$1'=yes',[
 775                 cf_save_LIBS="$LIBS"
 776                 AC_MSG_CHECKING(for $5 in -l$1)
 777                 LIBS="-l$1 $LIBS"
 778                 AC_TRY_LINK([$3],[$4],
 779                         [AC_MSG_RESULT(yes)
 780                          eval 'cf_cv_have_lib_'$1'=yes'
 781                         ],
 782                         [AC_MSG_RESULT(no)
 783                         CF_LIBRARY_PATH(cf_search,$2)
 784                         for cf_libdir in $cf_search
 785                         do
 786                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
 787                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
 788                                 AC_TRY_LINK([$3],[$4],
 789                                         [AC_MSG_RESULT(yes)
 790                                          eval 'cf_cv_have_lib_'$1'=yes'
 791                                          break],
 792                                         [AC_MSG_RESULT(no)
 793                                          LIBS="$cf_save_LIBS"])
 794                         done
 795                         ])
 796                 ])
 797 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
 798 ifelse($6,,[
 799 if test $cf_found_library = no ; then
 800         AC_MSG_ERROR(Cannot link $1 library)
 801 fi
 802 ])
 803 ])dnl
 804 dnl ---------------------------------------------------------------------------
 805 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
 806 dnl ---------------
 807 dnl Find a library (specifically the linkage used in the code fragment),
 808 dnl searching for it if it is not already in the library path.
 809 dnl See also CF_ADD_SEARCHPATH.
 810 dnl
 811 dnl Parameters (4-on are optional):
 812 dnl     $1 = headers for library entrypoint
 813 dnl     $2 = code fragment for library entrypoint
 814 dnl     $3 = the library name without the "-l" option or ".so" suffix.
 815 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
 816 dnl     $5 = action to perform if not successful
 817 dnl     $6 = module name, if not the same as the library name
 818 dnl     $7 = extra libraries
 819 dnl
 820 dnl Sets these variables:
 821 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
 822 dnl     $cf_cv_header_path_$3 - include-directory if needed
 823 dnl     $cf_cv_library_path_$3 - library-directory if needed
 824 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
 825 AC_DEFUN([CF_FIND_LINKAGE],[
 826
 827 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
 828 # will be set on completion of the AC_TRY_LINK below.
 829 cf_cv_header_path_$3=
 830 cf_cv_library_path_$3=
 831
 832 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
 833
 834 cf_save_LIBS="$LIBS"
 835
 836 AC_TRY_LINK([$1],[$2],[
 837         cf_cv_find_linkage_$3=yes
 838         cf_cv_header_path_$3=/usr/include
 839         cf_cv_library_path_$3=/usr/lib
 840 ],[
 841
 842 LIBS="-l$3 $7 $cf_save_LIBS"
 843
 844 AC_TRY_LINK([$1],[$2],[
 845         cf_cv_find_linkage_$3=yes
 846         cf_cv_header_path_$3=/usr/include
 847         cf_cv_library_path_$3=/usr/lib
 848         cf_cv_library_file_$3="-l$3"
 849 ],[
 850         cf_cv_find_linkage_$3=no
 851         LIBS="$cf_save_LIBS"
 852
 853         CF_VERBOSE(find linkage for $3 library)
 854         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
 855
 856         cf_save_CPPFLAGS="$CPPFLAGS"
 857         cf_test_CPPFLAGS="$CPPFLAGS"
 858
 859         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
 860         for cf_cv_header_path_$3 in $cf_search
 861         do
 862                 if test -d $cf_cv_header_path_$3 ; then
 863                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
 864                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
 865                         AC_TRY_COMPILE([$1],[$2],[
 866                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
 867                                 cf_cv_find_linkage_$3=maybe
 868                                 cf_test_CPPFLAGS="$CPPFLAGS"
 869                                 break],[
 870                                 CPPFLAGS="$cf_save_CPPFLAGS"
 871                                 ])
 872                 fi
 873         done
 874
 875         if test "$cf_cv_find_linkage_$3" = maybe ; then
 876
 877                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
 878
 879                 cf_save_LIBS="$LIBS"
 880                 cf_save_LDFLAGS="$LDFLAGS"
 881
 882                 ifelse([$6],,,[
 883                 CPPFLAGS="$cf_test_CPPFLAGS"
 884                 LIBS="-l$3 $7 $cf_save_LIBS"
 885                 AC_TRY_LINK([$1],[$2],[
 886                         CF_VERBOSE(... found $3 library in system)
 887                         cf_cv_find_linkage_$3=yes])
 888                         CPPFLAGS="$cf_save_CPPFLAGS"
 889                         LIBS="$cf_save_LIBS"
 890                         ])
 891
 892                 if test "$cf_cv_find_linkage_$3" != yes ; then
 893                         CF_LIBRARY_PATH(cf_search,$3)
 894                         for cf_cv_library_path_$3 in $cf_search
 895                         do
 896                                 if test -d $cf_cv_library_path_$3 ; then
 897                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
 898                                         CPPFLAGS="$cf_test_CPPFLAGS"
 899                                         LIBS="-l$3 $7 $cf_save_LIBS"
 900                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
 901                                         AC_TRY_LINK([$1],[$2],[
 902                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
 903                                         cf_cv_find_linkage_$3=yes
 904                                         cf_cv_library_file_$3="-l$3"
 905                                         break],[
 906                                         CPPFLAGS="$cf_save_CPPFLAGS"
 907                                         LIBS="$cf_save_LIBS"
 908                                         LDFLAGS="$cf_save_LDFLAGS"
 909                                         ])
 910                                 fi
 911                         done
 912                         CPPFLAGS="$cf_save_CPPFLAGS"
 913                         LDFLAGS="$cf_save_LDFLAGS"
 914                 fi
 915
 916         else
 917                 cf_cv_find_linkage_$3=no
 918         fi
 919         ],$7)
 920 ])
 921
 922 LIBS="$cf_save_LIBS"
 923
 924 if test "$cf_cv_find_linkage_$3" = yes ; then
 925 ifelse([$4],,[
 926         CF_ADD_INCDIR($cf_cv_header_path_$3)
 927         CF_ADD_LIBDIR($cf_cv_library_path_$3)
 928         CF_ADD_LIB($3)
 929 ],[$4])
 930 else
 931 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
 932 fi
 933 ])dnl
 934 dnl ---------------------------------------------------------------------------
 935 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
 936 dnl -----------------
 937 dnl make ADAFLAGS consistent with CFLAGS
 938 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
 939         AC_MSG_CHECKING(optimization options for ADAFLAGS)
 940         case "$CFLAGS" in
 941         (*-g*)
 942                 CF_ADD_ADAFLAGS(-g)
 943                 ;;
 944         esac
 945         case "$CFLAGS" in
 946         (*-O*)
 947                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
 948                 CF_ADD_ADAFLAGS($cf_O_flag)
 949                 ;;
 950         esac
 951         AC_MSG_RESULT($ADAFLAGS)
 952 ])dnl
 953 dnl ---------------------------------------------------------------------------
 954 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
 955 dnl -----------------
 956 dnl Test for availability of useful gcc __attribute__ directives to quiet
 957 dnl compiler warnings.  Though useful, not all are supported -- and contrary
 958 dnl to documentation, unrecognized directives cause older compilers to barf.
 959 AC_DEFUN([CF_GCC_ATTRIBUTES],
 960 [
 961 if test "$GCC" = yes
 962 then
 963 cat > conftest.i <<EOF
 964 #ifndef GCC_PRINTF
 965 #define GCC_PRINTF 0
 966 #endif
 967 #ifndef GCC_SCANF
 968 #define GCC_SCANF 0
 969 #endif
 970 #ifndef GCC_NORETURN
 971 #define GCC_NORETURN /* nothing */
 972 #endif
 973 #ifndef GCC_UNUSED
 974 #define GCC_UNUSED /* nothing */
 975 #endif
 976 EOF
 977 if test "$GCC" = yes
 978 then
 979         AC_CHECKING([for $CC __attribute__ directives])
 980 cat > conftest.$ac_ext <<EOF
 981 #line __oline__ "${as_me:-configure}"
 982 #include "confdefs.h"
 983 #include "conftest.h"
 984 #include "conftest.i"
 985 #if     GCC_PRINTF
 986 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
 987 #else
 988 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
 989 #endif
 990 #if     GCC_SCANF
 991 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
 992 #else
 993 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
 994 #endif
 995 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
 996 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
 997 extern void foo(void) GCC_NORETURN;
 998 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
 999 EOF
1000         cf_printf_attribute=no
1001         cf_scanf_attribute=no
1002         for cf_attribute in scanf printf unused noreturn
1003         do
1004                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1005                 cf_directive="__attribute__(($cf_attribute))"
1006                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1007
1008                 case $cf_attribute in
1009                 (printf)
1010                         cf_printf_attribute=yes
1011                         cat >conftest.h <<EOF
1012 #define GCC_$cf_ATTRIBUTE 1
1013 EOF
1014                         ;;
1015                 (scanf)
1016                         cf_scanf_attribute=yes
1017                         cat >conftest.h <<EOF
1018 #define GCC_$cf_ATTRIBUTE 1
1019 EOF
1020                         ;;
1021                 (*)
1022                         cat >conftest.h <<EOF
1023 #define GCC_$cf_ATTRIBUTE $cf_directive
1024 EOF
1025                         ;;
1026                 esac
1027
1028                 if AC_TRY_EVAL(ac_compile); then
1029                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1030                         cat conftest.h >>confdefs.h
1031                         case $cf_attribute in
1032                         (noreturn)
1033                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1034                                 ;;
1035                         (printf)
1036                                 cf_value='/* nothing */'
1037                                 if test "$cf_printf_attribute" != no ; then
1038                                         cf_value='__attribute__((format(printf,fmt,var)))'
1039                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1040                                 fi
1041                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1042                                 ;;
1043                         (scanf)
1044                                 cf_value='/* nothing */'
1045                                 if test "$cf_scanf_attribute" != no ; then
1046                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1047                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1048                                 fi
1049                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1050                                 ;;
1051                         (unused)
1052                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1053                                 ;;
1054                         esac
1055                 fi
1056         done
1057 else
1058         fgrep define conftest.i >>confdefs.h
1059 fi
1060 rm -rf conftest*
1061 fi
1062 ])dnl
1063 dnl ---------------------------------------------------------------------------
1064 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1065 dnl --------------
1066 dnl Find version of gcc
1067 AC_DEFUN([CF_GCC_VERSION],[
1068 AC_REQUIRE([AC_PROG_CC])
1069 GCC_VERSION=none
1070 if test "$GCC" = yes ; then
1071         AC_MSG_CHECKING(version of $CC)
1072         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1073         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1074         AC_MSG_RESULT($GCC_VERSION)
1075 fi
1076 ])dnl
1077 dnl ---------------------------------------------------------------------------
1078 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
1079 dnl ---------------
1080 dnl Check if the compiler supports useful warning options.  There's a few that
1081 dnl we don't use, simply because they're too noisy:
1082 dnl
1083 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1084 dnl     -Wredundant-decls (system headers make this too noisy)
1085 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1086 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1087 dnl             is enabled for ncurses using "--enable-const".
1088 dnl     -pedantic
1089 dnl
1090 dnl Parameter:
1091 dnl     $1 is an optional list of gcc warning flags that a particular
1092 dnl             application might want to use, e.g., "no-unused" for
1093 dnl             -Wno-unused
1094 dnl Special:
1095 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1096 dnl
1097 AC_DEFUN([CF_GCC_WARNINGS],
1098 [
1099 AC_REQUIRE([CF_GCC_VERSION])
1100 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1101 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1102
1103 cat > conftest.$ac_ext <<EOF
1104 #line __oline__ "${as_me:-configure}"
1105 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1106 EOF
1107
1108 if test "$INTEL_COMPILER" = yes
1109 then
1110 # The "-wdXXX" options suppress warnings:
1111 # remark #1419: external declaration in primary source file
1112 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1113 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1114 # remark #193: zero used for undefined preprocessing identifier
1115 # remark #593: variable "curs_sb_left_arrow" was set but never used
1116 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1117 # remark #869: parameter "tw" was never referenced
1118 # remark #981: operands are evaluated in unspecified order
1119 # warning #279: controlling expression is constant
1120
1121         AC_CHECKING([for $CC warning options])
1122         cf_save_CFLAGS="$CFLAGS"
1123         EXTRA_CFLAGS="-Wall"
1124         for cf_opt in \
1125                 wd1419 \
1126                 wd1683 \
1127                 wd1684 \
1128                 wd193 \
1129                 wd593 \
1130                 wd279 \
1131                 wd810 \
1132                 wd869 \
1133                 wd981
1134         do
1135                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1136                 if AC_TRY_EVAL(ac_compile); then
1137                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1138                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1139                 fi
1140         done
1141         CFLAGS="$cf_save_CFLAGS"
1142
1143 elif test "$GCC" = yes
1144 then
1145         AC_CHECKING([for $CC warning options])
1146         cf_save_CFLAGS="$CFLAGS"
1147         EXTRA_CFLAGS=
1148         cf_warn_CONST=""
1149         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1150         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1151         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1152         for cf_opt in W Wall \
1153                 Wbad-function-cast \
1154                 Wcast-align \
1155                 Wcast-qual \
1156                 Wdeclaration-after-statement \
1157                 Wextra \
1158                 Winline \
1159                 Wmissing-declarations \
1160                 Wmissing-prototypes \
1161                 Wnested-externs \
1162                 Wpointer-arith \
1163                 Wshadow \
1164                 Wstrict-prototypes \
1165                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
1166         do
1167                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1168                 if AC_TRY_EVAL(ac_compile); then
1169                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1170                         case $cf_opt in
1171                         (Wcast-qual)
1172                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1173                                 ;;
1174                         (Winline)
1175                                 case $GCC_VERSION in
1176                                 ([[34]].*)
1177                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1178                                         continue;;
1179                                 esac
1180                                 ;;
1181                         (Wpointer-arith)
1182                                 case $GCC_VERSION in
1183                                 ([[12]].*)
1184                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1185                                         continue;;
1186                                 esac
1187                                 ;;
1188                         esac
1189                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1190                 fi
1191         done
1192         CFLAGS="$cf_save_CFLAGS"
1193 fi
1194 rm -rf conftest*
1195
1196 AC_SUBST(EXTRA_CFLAGS)
1197 ])dnl
1198 dnl ---------------------------------------------------------------------------
1199 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
1200 dnl -----------------
1201 AC_DEFUN([CF_GNATPREP_OPT_T],[
1202 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
1203 cf_cv_gnatprep_opt_t=no
1204 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
1205 ])
1206 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
1207 AC_SUBST(GNATPREP_OPTS)
1208 ])dnl
1209 dnl ---------------------------------------------------------------------------
1210 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
1211 dnl ----------------
1212 AC_DEFUN([CF_GNAT_GENERICS],
1213 [
1214 AC_REQUIRE([CF_GNAT_VERSION])
1215
1216 AC_MSG_CHECKING(if GNAT supports generics)
1217 case $cf_gnat_version in
1218 (3.[[1-9]]*|[[4-9]].*)
1219         cf_gnat_generics=yes
1220         ;;
1221 (*)
1222         cf_gnat_generics=no
1223         ;;
1224 esac
1225 AC_MSG_RESULT($cf_gnat_generics)
1226
1227 if test "$cf_gnat_generics" = yes
1228 then
1229         cf_compile_generics=generics
1230         cf_generic_objects="\${GENOBJS}"
1231 else
1232         cf_compile_generics=
1233         cf_generic_objects=
1234 fi
1235
1236 AC_SUBST(cf_compile_generics)
1237 AC_SUBST(cf_generic_objects)
1238 ])dnl
1239 dnl ---------------------------------------------------------------------------
1240 dnl CF_GNAT_PROJECTS version: 8 updated: 2015/04/17 21:13:04
1241 dnl ----------------
1242 dnl GNAT projects are configured with ".gpr" project files.
1243 dnl GNAT libraries are a further development, using the project feature.
1244 AC_DEFUN([CF_GNAT_PROJECTS],
1245 [
1246 AC_REQUIRE([CF_GNAT_VERSION])
1247 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
1248
1249 cf_gnat_libraries=no
1250 cf_gnat_projects=no
1251
1252 if test "$enable_gnat_projects" != no ; then
1253 AC_MSG_CHECKING(if GNAT supports project files)
1254 case $cf_gnat_version in
1255 (3.[[0-9]]*)
1256         ;;
1257 (*)
1258         case $cf_cv_system_name in
1259         (cygwin*|msys*)
1260                 ;;
1261         (*)
1262                 mkdir conftest.src conftest.bin conftest.lib
1263                 cd conftest.src
1264                 rm -rf conftest* *~conftest*
1265                 cat >>library.gpr <<CF_EOF
1266 project Library is
1267   Kind := External ("LIB_KIND");
1268   for Library_Name use "ConfTest";
1269   for Object_Dir use ".";
1270   for Library_ALI_Dir use External("LIBRARY_DIR");
1271   for Library_Version use External ("SONAME");
1272   for Library_Kind use Kind;
1273   for Library_Dir use External("BUILD_DIR");
1274   Source_Dir := External ("SOURCE_DIR");
1275   for Source_Dirs use (Source_Dir);
1276 end Library;
1277 CF_EOF
1278                 cat >>confpackage.ads <<CF_EOF
1279 package ConfPackage is
1280    procedure conftest;
1281 end ConfPackage;
1282 CF_EOF
1283                 cat >>confpackage.adb <<CF_EOF
1284 with Text_IO;
1285 package body ConfPackage is
1286    procedure conftest is
1287    begin
1288       Text_IO.Put ("Hello World");
1289       Text_IO.New_Line;
1290    end conftest;
1291 end ConfPackage;
1292 CF_EOF
1293                 if ( $cf_ada_make $ADAFLAGS \
1294                                 -Plibrary.gpr \
1295                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
1296                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
1297                                 -XSOURCE_DIR=`pwd` \
1298                                 -XSONAME=libConfTest.so.1 \
1299                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1300                         cf_gnat_projects=yes
1301                 fi
1302                 cd ..
1303                 if test -f conftest.lib/confpackage.ali
1304                 then
1305                         cf_gnat_libraries=yes
1306                 fi
1307                 rm -rf conftest* *~conftest*
1308                 ;;
1309         esac
1310         ;;
1311 esac
1312 AC_MSG_RESULT($cf_gnat_projects)
1313 fi # enable_gnat_projects
1314
1315 if test $cf_gnat_projects = yes
1316 then
1317         AC_MSG_CHECKING(if GNAT supports libraries)
1318         AC_MSG_RESULT($cf_gnat_libraries)
1319 fi
1320
1321 if test "$cf_gnat_projects" = yes
1322 then
1323         USE_OLD_MAKERULES="#"
1324         USE_GNAT_PROJECTS=""
1325 else
1326         USE_OLD_MAKERULES=""
1327         USE_GNAT_PROJECTS="#"
1328 fi
1329
1330 if test "$cf_gnat_libraries" = yes
1331 then
1332         USE_GNAT_LIBRARIES=""
1333 else
1334         USE_GNAT_LIBRARIES="#"
1335 fi
1336
1337 AC_SUBST(USE_OLD_MAKERULES)
1338 AC_SUBST(USE_GNAT_PROJECTS)
1339 AC_SUBST(USE_GNAT_LIBRARIES)
1340 ])dnl
1341 dnl ---------------------------------------------------------------------------
1342 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
1343 dnl --------------
1344 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1345 dnl is noted that gnat may compile a tasking unit even for configurations which
1346 dnl fail at runtime.
1347 AC_DEFUN([CF_GNAT_SIGINT],[
1348 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1349 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1350
1351 package ConfTest is
1352
1353    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1354    pragma Unreserve_All_Interrupts;
1355    pragma Warnings (On);
1356
1357    protected Process is
1358       procedure Stop;
1359       function Continue return Boolean;
1360       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1361    private
1362       Done : Boolean := False;
1363    end Process;
1364
1365 end ConfTest;],
1366 [package body ConfTest is
1367    protected body Process is
1368       procedure Stop is
1369       begin
1370          Done := True;
1371       end Stop;
1372       function Continue return Boolean is
1373       begin
1374          return not Done;
1375       end Continue;
1376    end Process;
1377 end ConfTest;],
1378         [cf_cv_gnat_sigint=yes],
1379         [cf_cv_gnat_sigint=no])])
1380
1381 if test $cf_cv_gnat_sigint = yes ; then
1382         USE_GNAT_SIGINT=""
1383 else
1384         USE_GNAT_SIGINT="#"
1385 fi
1386 AC_SUBST(USE_GNAT_SIGINT)
1387 ])dnl
1388 dnl ---------------------------------------------------------------------------
1389 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
1390 dnl ----------------
1391 dnl Verify that a test program compiles/links with GNAT.
1392 dnl $cf_ada_make is set to the program that compiles/links
1393 dnl $ADAFLAGS may be set to the GNAT flags.
1394 dnl
1395 dnl $1 is the text of the spec
1396 dnl $2 is the text of the body
1397 dnl $3 is the shell command to execute if successful
1398 dnl $4 is the shell command to execute if not successful
1399 AC_DEFUN([CF_GNAT_TRY_LINK],
1400 [
1401 rm -rf conftest* *~conftest*
1402 cat >>conftest.ads <<CF_EOF
1403 $1
1404 CF_EOF
1405 cat >>conftest.adb <<CF_EOF
1406 $2
1407 CF_EOF
1408 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1409 ifelse($3,,      :,[      $3])
1410 ifelse($4,,,[else
1411    $4])
1412 fi
1413 rm -rf conftest* *~conftest*
1414 ])dnl
1415 dnl ---------------------------------------------------------------------------
1416 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
1417 dnl ---------------
1418 dnl Verify that a test program compiles and runs with GNAT
1419 dnl $cf_ada_make is set to the program that compiles/links
1420 dnl $ADAFLAGS may be set to the GNAT flags.
1421 dnl
1422 dnl $1 is the text of the spec
1423 dnl $2 is the text of the body
1424 dnl $3 is the shell command to execute if successful
1425 dnl $4 is the shell command to execute if not successful
1426 AC_DEFUN([CF_GNAT_TRY_RUN],
1427 [
1428 rm -rf conftest* *~conftest*
1429 cat >>conftest.ads <<CF_EOF
1430 $1
1431 CF_EOF
1432 cat >>conftest.adb <<CF_EOF
1433 $2
1434 CF_EOF
1435 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1436    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1437 ifelse($3,,      :,[      $3])
1438 ifelse($4,,,[   else
1439       $4])
1440    fi
1441 ifelse($4,,,[else
1442    $4])
1443 fi
1444 rm -rf conftest* *~conftest*
1445 ])dnl
1446 dnl ---------------------------------------------------------------------------
1447 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
1448 dnl ---------------
1449 dnl Verify version of GNAT.
1450 AC_DEFUN([CF_GNAT_VERSION],
1451 [
1452 AC_MSG_CHECKING(for gnat version)
1453 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
1454         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1455         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1456 AC_MSG_RESULT($cf_gnat_version)
1457
1458 case $cf_gnat_version in
1459 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
1460         cf_cv_prog_gnat_correct=yes
1461         ;;
1462 (*)
1463         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1464         cf_cv_prog_gnat_correct=no
1465         ;;
1466 esac
1467 ])
1468 dnl ---------------------------------------------------------------------------
1469 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
1470 dnl -------------
1471 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1472 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1473 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1474 dnl since it is interwoven with GNU extensions.
1475 dnl
1476 dnl Well, yes we could work around it...
1477 AC_DEFUN([CF_GNU_SOURCE],
1478 [
1479 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1480 AC_TRY_COMPILE([#include <sys/types.h>],[
1481 #ifndef _XOPEN_SOURCE
1482 make an error
1483 #endif],
1484         [cf_cv_gnu_source=no],
1485         [cf_save="$CPPFLAGS"
1486          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1487          AC_TRY_COMPILE([#include <sys/types.h>],[
1488 #ifdef _XOPEN_SOURCE
1489 make an error
1490 #endif],
1491         [cf_cv_gnu_source=no],
1492         [cf_cv_gnu_source=yes])
1493         CPPFLAGS="$cf_save"
1494         ])
1495 ])
1496 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1497 ])dnl
1498 dnl ---------------------------------------------------------------------------
1499 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
1500 dnl --------------
1501 dnl Construct a search-list of directories for a nonstandard header-file
1502 dnl
1503 dnl Parameters
1504 dnl     $1 = the variable to return as result
1505 dnl     $2 = the package name
1506 AC_DEFUN([CF_HEADER_PATH],
1507 [
1508 $1=
1509
1510 # collect the current set of include-directories from compiler flags
1511 cf_header_path_list=""
1512 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1513         for cf_header_path in $CPPFLAGS $CFLAGS
1514         do
1515                 case $cf_header_path in
1516                 (-I*)
1517                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1518                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1519                         cf_header_path_list="$cf_header_path_list [$]$1"
1520                         ;;
1521                 esac
1522         done
1523 fi
1524
1525 # add the variations for the package we are looking for
1526 CF_SUBDIR_PATH($1,$2,include)
1527
1528 test "$includedir" != NONE && \
1529 test "$includedir" != "/usr/include" && \
1530 test -d "$includedir" && {
1531         test -d $includedir &&    $1="[$]$1 $includedir"
1532         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1533 }
1534
1535 test "$oldincludedir" != NONE && \
1536 test "$oldincludedir" != "/usr/include" && \
1537 test -d "$oldincludedir" && {
1538         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1539         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1540 }
1541
1542 $1="[$]$1 $cf_header_path_list"
1543 ])dnl
1544 dnl ---------------------------------------------------------------------------
1545 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1546 dnl ---------------
1547 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1548 AC_DEFUN([CF_HELP_MESSAGE],
1549 [AC_DIVERT_HELP([$1])dnl
1550 ])dnl
1551 dnl ---------------------------------------------------------------------------
1552 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
1553 dnl ---------------
1554 dnl Construct the list of include-options according to whether we're building
1555 dnl in the source directory or using '--srcdir=DIR' option.
1556 AC_DEFUN([CF_INCLUDE_DIRS],
1557 [
1558 if test "$srcdir" != "."; then
1559         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
1560 fi
1561 CPPFLAGS="-I../include $CPPFLAGS"
1562 if test "$srcdir" != "."; then
1563         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
1564 fi
1565 CPPFLAGS="-I. $CPPFLAGS"
1566 AC_SUBST(CPPFLAGS)
1567 ])dnl
1568 dnl ---------------------------------------------------------------------------
1569 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
1570 dnl -----------------
1571 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1572 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1573 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1574 dnl
1575 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1576 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1577 dnl the wrappers for gcc and g++ warnings.
1578 dnl
1579 dnl $1 = GCC (default) or GXX
1580 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1581 dnl $3 = CFLAGS (default) or CXXFLAGS
1582 AC_DEFUN([CF_INTEL_COMPILER],[
1583 AC_REQUIRE([AC_CANONICAL_HOST])
1584 ifelse([$2],,INTEL_COMPILER,[$2])=no
1585
1586 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1587         case $host_os in
1588         (linux*|gnu*)
1589                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1590                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1591                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1592                 AC_TRY_COMPILE([],[
1593 #ifdef __INTEL_COMPILER
1594 #else
1595 make an error
1596 #endif
1597 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1598 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
1599 ],[])
1600                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1601                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1602                 ;;
1603         esac
1604 fi
1605 ])dnl
1606 dnl ---------------------------------------------------------------------------
1607 dnl CF_LARGEFILE version: 9 updated: 2015/04/18 08:56:57
1608 dnl ------------
1609 dnl Add checks for large file support.
1610 AC_DEFUN([CF_LARGEFILE],[
1611 ifdef([AC_FUNC_FSEEKO],[
1612         AC_SYS_LARGEFILE
1613         if test "$enable_largefile" != no ; then
1614         AC_FUNC_FSEEKO
1615
1616         # Normally we would collect these definitions in the config.h,
1617         # but (like _XOPEN_SOURCE), some environments rely on having these
1618         # defined before any of the system headers are included.  Another
1619         # case comes up with C++, e.g., on AIX the compiler compiles the
1620         # header files by themselves before looking at the body files it is
1621         # told to compile.  For ncurses, those header files do not include
1622         # the config.h
1623         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
1624         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
1625         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
1626
1627         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
1628                 AC_TRY_COMPILE([
1629 #include <sys/types.h>
1630 #include <dirent.h>
1631                 ],[
1632                 /* if transitional largefile support is setup, this is true */
1633                 extern struct dirent64 * readdir(DIR *);
1634                 struct dirent64 *x = readdir((DIR *)0);
1635                 struct dirent *y = readdir((DIR *)0);
1636                 int z = x - y;
1637                 ],
1638                 [cf_cv_struct_dirent64=yes],
1639                 [cf_cv_struct_dirent64=no])
1640         ])
1641         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
1642         fi
1643 ])
1644 ])
1645 dnl ---------------------------------------------------------------------------
1646 dnl CF_LD_RPATH_OPT version: 7 updated: 2016/02/20 18:01:19
1647 dnl ---------------
1648 dnl For the given system and compiler, find the compiler flags to pass to the
1649 dnl loader to use the "rpath" feature.
1650 AC_DEFUN([CF_LD_RPATH_OPT],
1651 [
1652 AC_REQUIRE([CF_CHECK_CACHE])
1653
1654 LD_RPATH_OPT=
1655 AC_MSG_CHECKING(for an rpath option)
1656 case $cf_cv_system_name in
1657 (irix*)
1658         if test "$GCC" = yes; then
1659                 LD_RPATH_OPT="-Wl,-rpath,"
1660         else
1661                 LD_RPATH_OPT="-rpath "
1662         fi
1663         ;;
1664 (linux*|gnu*|k*bsd*-gnu|freebsd*)
1665         LD_RPATH_OPT="-Wl,-rpath,"
1666         ;;
1667 (openbsd[[2-9]].*|mirbsd*)
1668         LD_RPATH_OPT="-Wl,-rpath,"
1669         ;;
1670 (dragonfly*)
1671         LD_RPATH_OPT="-rpath "
1672         ;;
1673 (netbsd*)
1674         LD_RPATH_OPT="-Wl,-rpath,"
1675         ;;
1676 (osf*|mls+*)
1677         LD_RPATH_OPT="-rpath "
1678         ;;
1679 (solaris2*)
1680         LD_RPATH_OPT="-R"
1681         ;;
1682 (*)
1683         ;;
1684 esac
1685 AC_MSG_RESULT($LD_RPATH_OPT)
1686
1687 case "x$LD_RPATH_OPT" in
1688 (x-R*)
1689         AC_MSG_CHECKING(if we need a space after rpath option)
1690         cf_save_LIBS="$LIBS"
1691         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1692         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1693         LIBS="$cf_save_LIBS"
1694         AC_MSG_RESULT($cf_rpath_space)
1695         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1696         ;;
1697 esac
1698 ])dnl
1699 dnl ---------------------------------------------------------------------------
1700 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
1701 dnl ---------------
1702 dnl Construct a search-list of directories for a nonstandard library-file
1703 dnl
1704 dnl Parameters
1705 dnl     $1 = the variable to return as result
1706 dnl     $2 = the package name
1707 AC_DEFUN([CF_LIBRARY_PATH],
1708 [
1709 $1=
1710 cf_library_path_list=""
1711 if test -n "${LDFLAGS}${LIBS}" ; then
1712         for cf_library_path in $LDFLAGS $LIBS
1713         do
1714                 case $cf_library_path in
1715                 (-L*)
1716                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1717                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1718                         cf_library_path_list="$cf_library_path_list [$]$1"
1719                         ;;
1720                 esac
1721         done
1722 fi
1723
1724 CF_SUBDIR_PATH($1,$2,lib)
1725
1726 $1="$cf_library_path_list [$]$1"
1727 ])dnl
1728 dnl ---------------------------------------------------------------------------
1729 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
1730 dnl -------------
1731 dnl Compute the library-prefix for the given host system
1732 dnl $1 = variable to set
1733 define([CF_LIB_PREFIX],
1734 [
1735         case $cf_cv_system_name in
1736         (OS/2*|os2*)
1737                 if test "$DFT_LWR_MODEL" = libtool; then
1738                         LIB_PREFIX='lib'
1739                 else
1740                         LIB_PREFIX=''
1741                 fi
1742                 ;;
1743         (*)     LIB_PREFIX='lib'
1744                 ;;
1745         esac
1746 ifelse($1,,,[$1=$LIB_PREFIX])
1747         AC_SUBST(LIB_PREFIX)
1748 ])dnl
1749 dnl ---------------------------------------------------------------------------
1750 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
1751 dnl -------------
1752 dnl Compute the library file-suffix from the given model name
1753 dnl $1 = model name
1754 dnl $2 = variable to set (the nominal library suffix)
1755 dnl $3 = dependency variable to set (actual filename)
1756 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1757 AC_DEFUN([CF_LIB_SUFFIX],
1758 [
1759         case X$1 in
1760         (Xlibtool)
1761                 $2='.la'
1762                 $3=[$]$2
1763                 ;;
1764         (Xdebug)
1765                 $2='_g.a'
1766                 $3=[$]$2
1767                 ;;
1768         (Xprofile)
1769                 $2='_p.a'
1770                 $3=[$]$2
1771                 ;;
1772         (Xshared)
1773                 case $cf_cv_system_name in
1774                 (aix[[5-7]]*)
1775                         $2='.so'
1776                         $3=[$]$2
1777                         ;;
1778                 (cygwin*|msys*|mingw*)
1779                         $2='.dll'
1780                         $3='.dll.a'
1781                         ;;
1782                 (darwin*)
1783                         $2='.dylib'
1784                         $3=[$]$2
1785                         ;;
1786                 (hpux*)
1787                         case $target in
1788                         (ia64*)
1789                                 $2='.so'
1790                                 $3=[$]$2
1791                                 ;;
1792                         (*)
1793                                 $2='.sl'
1794                                 $3=[$]$2
1795                                 ;;
1796                         esac
1797                         ;;
1798                 (*)
1799                         $2='.so'
1800                         $3=[$]$2
1801                         ;;
1802                 esac
1803                 ;;
1804         (*)
1805                 $2='.a'
1806                 $3=[$]$2
1807                 ;;
1808         esac
1809         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
1810         then
1811                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
1812                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
1813         fi
1814 ])dnl
1815 dnl ---------------------------------------------------------------------------
1816 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
1817 dnl -----------
1818 dnl Compute the string to append to -library from the given model name
1819 dnl $1 = model name
1820 dnl $2 = variable to set
1821 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1822 AC_DEFUN([CF_LIB_TYPE],
1823 [
1824         case $1 in
1825         (libtool) $2=''   ;;
1826         (normal)  $2=''   ;;
1827         (debug)   $2='_g' ;;
1828         (profile) $2='_p' ;;
1829         (shared)  $2=''   ;;
1830         esac
1831         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1832 ])dnl
1833 dnl ---------------------------------------------------------------------------
1834 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
1835 dnl ----------------
1836 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
1837 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
1838 dnl have to provide wrappers for global tables to ensure they're linked
1839 dnl properly.
1840 AC_DEFUN([CF_LINK_DATAONLY],
1841 [
1842 AC_MSG_CHECKING([if data-only library module links])
1843 AC_CACHE_VAL(cf_cv_link_dataonly,[
1844         rm -f conftest.a
1845         cat >conftest.$ac_ext <<EOF
1846 #line __oline__ "configure"
1847 int     testdata[[3]] = { 123, 456, 789 };
1848 EOF
1849         if AC_TRY_EVAL(ac_compile) ; then
1850                 mv conftest.o data.o && \
1851                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
1852         fi
1853         rm -f conftest.$ac_ext data.o
1854         cat >conftest.$ac_ext <<EOF
1855 #line __oline__ "configure"
1856 int     testfunc()
1857 {
1858 #if defined(NeXT)
1859         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
1860 #else
1861         extern int testdata[[3]];
1862         return testdata[[0]] == 123
1863            &&  testdata[[1]] == 456
1864            &&  testdata[[2]] == 789;
1865 #endif
1866 }
1867 EOF
1868         if AC_TRY_EVAL(ac_compile); then
1869                 mv conftest.o func.o && \
1870                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
1871         fi
1872         rm -f conftest.$ac_ext func.o
1873         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
1874         cf_saveLIBS="$LIBS"
1875         LIBS="conftest.a $LIBS"
1876         AC_TRY_RUN([
1877         int main()
1878         {
1879                 extern int testfunc();
1880                 ${cf_cv_main_return:-return} (!testfunc());
1881         }
1882         ],
1883         [cf_cv_link_dataonly=yes],
1884         [cf_cv_link_dataonly=no],
1885         [cf_cv_link_dataonly=unknown])
1886         LIBS="$cf_saveLIBS"
1887         ])
1888 AC_MSG_RESULT($cf_cv_link_dataonly)
1889
1890 if test "$cf_cv_link_dataonly" = no ; then
1891         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
1892         BROKEN_LINKER=1
1893 fi
1894
1895 ])dnl
1896 dnl ---------------------------------------------------------------------------
1897 dnl CF_MAKEFLAGS version: 17 updated: 2015/08/05 20:44:28
1898 dnl ------------
1899 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
1900 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
1901 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
1902 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
1903 AC_DEFUN([CF_MAKEFLAGS],
1904 [
1905 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
1906         cf_cv_makeflags=''
1907         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
1908         do
1909                 cat >cf_makeflags.tmp <<CF_EOF
1910 SHELL = $SHELL
1911 all :
1912         @ echo '.$cf_option'
1913 CF_EOF
1914                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
1915                 case "$cf_result" in
1916                 (.*k|.*kw)
1917                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
1918                         case "$cf_result" in
1919                         (.*CC=*)        cf_cv_makeflags=
1920                                 ;;
1921                         (*)     cf_cv_makeflags=$cf_option
1922                                 ;;
1923                         esac
1924                         break
1925                         ;;
1926                 (.-)    ;;
1927                 (*)     echo "given option \"$cf_option\", no match \"$cf_result\""
1928                         ;;
1929                 esac
1930         done
1931         rm -f cf_makeflags.tmp
1932 ])
1933
1934 AC_SUBST(cf_cv_makeflags)
1935 ])dnl
1936 dnl ---------------------------------------------------------------------------
1937 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1938 dnl ------------
1939 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1940 dnl a monocase filesystem.
1941 AC_DEFUN([CF_MAKE_TAGS],[
1942 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1943
1944 AC_CHECK_PROGS(CTAGS, exctags ctags)
1945 AC_CHECK_PROGS(ETAGS, exetags etags)
1946
1947 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1948
1949 if test "$cf_cv_mixedcase" = yes ; then
1950         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1951 else
1952         MAKE_UPPER_TAGS=no
1953 fi
1954
1955 if test "$MAKE_UPPER_TAGS" = yes ; then
1956         MAKE_UPPER_TAGS=
1957 else
1958         MAKE_UPPER_TAGS="#"
1959 fi
1960
1961 if test "$MAKE_LOWER_TAGS" = yes ; then
1962         MAKE_LOWER_TAGS=
1963 else
1964         MAKE_LOWER_TAGS="#"
1965 fi
1966
1967 AC_SUBST(CTAGS)
1968 AC_SUBST(ETAGS)
1969
1970 AC_SUBST(MAKE_UPPER_TAGS)
1971 AC_SUBST(MAKE_LOWER_TAGS)
1972 ])dnl
1973 dnl ---------------------------------------------------------------------------
1974 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
1975 dnl ----------------------
1976 dnl Check if the file-system supports mixed-case filenames.  If we're able to
1977 dnl create a lowercase name and see it as uppercase, it doesn't support that.
1978 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
1979 [
1980 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
1981 if test "$cross_compiling" = yes ; then
1982         case $target_alias in
1983         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
1984                 cf_cv_mixedcase=no
1985                 ;;
1986         (*)
1987                 cf_cv_mixedcase=yes
1988                 ;;
1989         esac
1990 else
1991         rm -f conftest CONFTEST
1992         echo test >conftest
1993         if test -f CONFTEST ; then
1994                 cf_cv_mixedcase=no
1995         else
1996                 cf_cv_mixedcase=yes
1997         fi
1998         rm -f conftest CONFTEST
1999 fi
2000 ])
2001 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2002 ])dnl
2003 dnl ---------------------------------------------------------------------------
2004 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
2005 dnl ----------
2006 dnl Check for a working mkstemp.  This creates two files, checks that they are
2007 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2008 AC_DEFUN([CF_MKSTEMP],[
2009 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2010 rm -rf conftest*
2011 AC_TRY_RUN([
2012 #include <sys/types.h>
2013 #include <stdlib.h>
2014 #include <stdio.h>
2015 #include <string.h>
2016 #include <sys/stat.h>
2017 int main()
2018 {
2019         char *tmpl = "conftestXXXXXX";
2020         char name[2][80];
2021         int n;
2022         int result = 0;
2023         int fd;
2024         struct stat sb;
2025
2026         umask(077);
2027         for (n = 0; n < 2; ++n) {
2028                 strcpy(name[n], tmpl);
2029                 if ((fd = mkstemp(name[n])) >= 0) {
2030                         if (!strcmp(name[n], tmpl)
2031                          || stat(name[n], &sb) != 0
2032                          || (sb.st_mode & S_IFMT) != S_IFREG
2033                          || (sb.st_mode & 077) != 0) {
2034                                 result = 1;
2035                         }
2036                         close(fd);
2037                 }
2038         }
2039         if (result == 0
2040          && !strcmp(name[0], name[1]))
2041                 result = 1;
2042         ${cf_cv_main_return:-return}(result);
2043 }
2044 ],[cf_cv_func_mkstemp=yes
2045 ],[cf_cv_func_mkstemp=no
2046 ],[cf_cv_func_mkstemp=maybe])
2047 ])
2048 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2049         AC_CHECK_FUNC(mkstemp)
2050 fi
2051 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2052         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2053 fi
2054 ])dnl
2055 dnl ---------------------------------------------------------------------------
2056 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2057 dnl ----------
2058 dnl Write a debug message to config.log, along with the line number in the
2059 dnl configure script.
2060 AC_DEFUN([CF_MSG_LOG],[
2061 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2062 ])dnl
2063 dnl ---------------------------------------------------------------------------
2064 dnl CF_NCURSES_ADDON version: 5 updated: 2015/04/26 18:06:58
2065 dnl ----------------
2066 dnl Configure an ncurses add-on, built outside the ncurses tree.
2067 AC_DEFUN([CF_NCURSES_ADDON],[
2068 AC_REQUIRE([CF_NCURSES_CONFIG])
2069
2070 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2071
2072 AC_MSG_CHECKING(if you want wide-character code)
2073 AC_ARG_ENABLE(widec,
2074         [  --enable-widec          compile with wide-char/UTF-8 code],
2075         [with_widec=$enableval],
2076         [with_widec=no])
2077 AC_MSG_RESULT($with_widec)
2078 if test "$with_widec" = yes ; then
2079         CF_UTF8_LIB
2080         CF_NCURSES_CONFIG(ncursesw)
2081 else
2082         CF_NCURSES_CONFIG(ncurses)
2083 fi
2084
2085 if test "$NCURSES_CONFIG_PKG" != none ; then
2086         cf_version=`$PKG_CONFIG --modversion $NCURSES_CONFIG_PKG 2>/dev/null`
2087
2088         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2089         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2090         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2091
2092         cf_cv_abi_version=`$PKG_CONFIG --variable=abi_version $NCURSES_CONFIG_PKG 2>/dev/null`
2093         if test -z "$cf_cv_abi_version"
2094         then
2095                 cf_cv_abi_version=`$PKG_CONFIG --variable=major_version $NCURSES_CONFIG_PKG 2>/dev/null`
2096         fi
2097
2098 elif test "$NCURSES_CONFIG" != none ; then
2099
2100         cf_version=`$NCURSES_CONFIG --version 2>/dev/null`
2101
2102         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2103         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2104         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2105
2106         # ABI version is not available from headers
2107         cf_cv_abi_version=`$NCURSES_CONFIG --abi-version 2>/dev/null`
2108
2109 else
2110
2111         for cf_name in MAJOR MINOR PATCH
2112         do
2113         cat >conftest.$ac_ext <<CF_EOF
2114         #include <${cf_cv_ncurses_header:-curses.h}>
2115         AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2116 CF_EOF
2117                 cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2118                 AC_TRY_EVAL(cf_try)
2119                 if test -f conftest.out ; then
2120                         cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]][[    ]]*//"`
2121                         eval NCURSES_$cf_name=\"$cf_result\"
2122                         # cat conftest.$ac_ext
2123                         # cat conftest.out
2124                 fi
2125         done
2126
2127         cf_cv_abi_version=${NCURSES_MAJOR}
2128
2129 fi
2130
2131 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2132
2133 dnl Show the computed version, for logging
2134 cf_cv_timestamp=`date`
2135
2136 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2137
2138 dnl We need these values in the generated headers
2139 AC_SUBST(NCURSES_MAJOR)
2140 AC_SUBST(NCURSES_MINOR)
2141 AC_SUBST(NCURSES_PATCH)
2142
2143 dnl We need these values in the generated makefiles
2144 AC_SUBST(cf_cv_rel_version)
2145 AC_SUBST(cf_cv_abi_version)
2146
2147 dnl FIXME - not needed for Ada95
2148 AC_SUBST(cf_cv_builtin_bool)
2149 AC_SUBST(cf_cv_header_stdbool_h)
2150 AC_SUBST(cf_cv_type_of_bool)dnl
2151
2152 ])
2153 dnl ---------------------------------------------------------------------------
2154 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2155 dnl -------------------
2156 dnl Check if we can compile with ncurses' header file
2157 dnl $1 is the cache variable to set
2158 dnl $2 is the header-file to include
2159 dnl $3 is the root name (ncurses or ncursesw)
2160 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2161         AC_TRY_COMPILE([
2162 ]ifelse($3,ncursesw,[
2163 #define _XOPEN_SOURCE_EXTENDED
2164 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2165 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2166 ])[
2167 #include <$2>],[
2168 #ifdef NCURSES_VERSION
2169 ]ifelse($3,ncursesw,[
2170 #ifndef WACS_BSSB
2171         make an error
2172 #endif
2173 ])[
2174 printf("%s\n", NCURSES_VERSION);
2175 #else
2176 #ifdef __NCURSES_H
2177 printf("old\n");
2178 #else
2179         make an error
2180 #endif
2181 #endif
2182         ]
2183         ,[$1=$2]
2184         ,[$1=no])
2185 ])dnl
2186 dnl ---------------------------------------------------------------------------
2187 dnl CF_NCURSES_CONFIG version: 17 updated: 2015/07/07 04:22:07
2188 dnl -----------------
2189 dnl Tie together the configure-script macros for ncurses, preferring these in
2190 dnl order:
2191 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2192 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2193 dnl c) just plain libraries
2194 dnl
2195 dnl $1 is the root library name (default: "ncurses")
2196 AC_DEFUN([CF_NCURSES_CONFIG],[
2197 AC_REQUIRE([CF_PKG_CONFIG])
2198 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2199 cf_have_ncuconfig=no
2200
2201 if test "x${PKG_CONFIG:=none}" != xnone; then
2202         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2203         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2204                 AC_MSG_RESULT(yes)
2205
2206                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2207                 cf_have_ncuconfig=unknown
2208
2209                 cf_save_CPPFLAGS="$CPPFLAGS"
2210                 cf_save_LIBS="$LIBS"
2211
2212                 CPPFLAGS="$CPPFLAGS `$PKG_CONFIG --cflags $cf_ncuconfig_root`"
2213                 CF_ADD_LIBS(`$PKG_CONFIG --libs $cf_ncuconfig_root`)
2214
2215                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2216                         [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2217                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2218                                 int main(void)
2219                                 { char *xx = curses_version(); return (xx == 0); }],
2220                                 [cf_have_ncuconfig=yes],
2221                                 [cf_have_ncuconfig=no],
2222                                 [cf_have_ncuconfig=maybe])],
2223                         [cf_have_ncuconfig=no])
2224                 AC_MSG_RESULT($cf_have_ncuconfig)
2225                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2226                 if test "$cf_have_ncuconfig" != "yes"
2227                 then
2228                         CPPFLAGS="$cf_save_CPPFLAGS"
2229                         LIBS="$cf_save_LIBS"
2230                         NCURSES_CONFIG_PKG=none
2231                 else
2232                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2233                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2234                 fi
2235
2236         else
2237                 AC_MSG_RESULT(no)
2238                 NCURSES_CONFIG_PKG=none
2239         fi
2240 else
2241         NCURSES_CONFIG_PKG=none
2242 fi
2243
2244 if test "x$cf_have_ncuconfig" = "xno"; then
2245         echo "Looking for ${cf_ncuconfig_root}-config"
2246
2247         CF_ACVERSION_CHECK(2.52,
2248                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncuconfig_root}-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2249                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncuconfig_root}-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2250
2251         if test "$NCURSES_CONFIG" != none ; then
2252
2253                 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
2254                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2255
2256                 # even with config script, some packages use no-override for curses.h
2257                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2258
2259                 dnl like CF_NCURSES_CPPFLAGS
2260                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2261
2262                 dnl like CF_NCURSES_LIBS
2263                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2264                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2265
2266                 dnl like CF_NCURSES_VERSION
2267                 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2268
2269         else
2270
2271                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2272                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2273
2274         fi
2275 else
2276         NCURSES_CONFIG=none
2277 fi
2278 ])dnl
2279 dnl ---------------------------------------------------------------------------
2280 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2281 dnl -------------------
2282 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2283 dnl the CPPFLAGS variable so we can include its header.
2284 dnl
2285 dnl The header files may be installed as either curses.h, or ncurses.h (would
2286 dnl be obsolete, except that some packagers prefer this name to distinguish it
2287 dnl from a "native" curses implementation).  If not installed for overwrite,
2288 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2289 dnl /usr/include/ncurses), but someone may have installed overwriting the
2290 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2291 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2292 dnl the header.
2293 dnl
2294 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2295 dnl is already in the include-path, don't even bother with this, since we cannot
2296 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2297 dnl
2298 dnl The optional parameter gives the root name of the library, in case it is
2299 dnl not installed as the default curses library.  That is how the
2300 dnl wide-character version of ncurses is installed.
2301 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2302 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2303
2304 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2305 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2306
2307 test -n "$cf_cv_curses_dir" && \
2308 test "$cf_cv_curses_dir" != "no" && { \
2309   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2310 }
2311
2312 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2313         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2314         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2315         for cf_header in $cf_header_list
2316         do
2317                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2318                 test "$cf_cv_ncurses_h" != no && break
2319         done
2320 ])
2321
2322 CF_NCURSES_HEADER
2323 CF_TERM_HEADER
2324
2325 # some applications need this, but should check for NCURSES_VERSION
2326 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2327
2328 CF_NCURSES_VERSION
2329 ])dnl
2330 dnl ---------------------------------------------------------------------------
2331 dnl CF_NCURSES_HEADER version: 4 updated: 2015/04/15 19:08:48
2332 dnl -----------------
2333 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2334 dnl variations of ncurses' installs.
2335 dnl
2336 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2337 AC_DEFUN([CF_NCURSES_HEADER],[
2338
2339 if test "$cf_cv_ncurses_h" != no ; then
2340         cf_cv_ncurses_header=$cf_cv_ncurses_h
2341 else
2342
2343 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2344         test -n "$verbose" && echo
2345         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2346         test -n "$verbose" && echo search path $cf_search
2347         cf_save2_CPPFLAGS="$CPPFLAGS"
2348         for cf_incdir in $cf_search
2349         do
2350                 CF_ADD_INCDIR($cf_incdir)
2351                 for cf_header in \
2352                         ncurses.h \
2353                         curses.h
2354                 do
2355                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2356                         if test "$cf_cv_ncurses_h2" != no ; then
2357                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2358                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2359                                 break
2360                         fi
2361                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2362                 done
2363                 CPPFLAGS="$cf_save2_CPPFLAGS"
2364                 test "$cf_cv_ncurses_h2" != no && break
2365         done
2366         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2367         ])
2368
2369         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2370         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2371         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2372                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2373         fi
2374         CF_ADD_INCDIR($cf_1st_incdir)
2375
2376 fi
2377
2378 # Set definitions to allow ifdef'ing for ncurses.h
2379
2380 case $cf_cv_ncurses_header in
2381 (*ncurses.h)
2382         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2383         ;;
2384 esac
2385
2386 case $cf_cv_ncurses_header in
2387 (ncurses/curses.h|ncurses/ncurses.h)
2388         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2389         ;;
2390 (ncursesw/curses.h|ncursesw/ncurses.h)
2391         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2392         ;;
2393 esac
2394
2395 ])dnl
2396 dnl ---------------------------------------------------------------------------
2397 dnl CF_NCURSES_LIBS version: 17 updated: 2015/04/15 19:08:48
2398 dnl ---------------
2399 dnl Look for the ncurses library.  This is a little complicated on Linux,
2400 dnl because it may be linked with the gpm (general purpose mouse) library.
2401 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2402 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2403 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2404 dnl and the linker will record a dependency.
2405 dnl
2406 dnl The optional parameter gives the root name of the library, in case it is
2407 dnl not installed as the default curses library.  That is how the
2408 dnl wide-character version of ncurses is installed.
2409 AC_DEFUN([CF_NCURSES_LIBS],
2410 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2411
2412 cf_nculib_root=ifelse($1,,ncurses,$1)
2413         # This works, except for the special case where we find gpm, but
2414         # ncurses is in a nonstandard location via $LIBS, and we really want
2415         # to link gpm.
2416 cf_ncurses_LIBS=""
2417 cf_ncurses_SAVE="$LIBS"
2418 AC_CHECK_LIB(gpm,Gpm_Open,
2419         [AC_CHECK_LIB(gpm,initscr,
2420                 [LIBS="$cf_ncurses_SAVE"],
2421                 [cf_ncurses_LIBS="-lgpm"])])
2422
2423 case $host_os in
2424 (freebsd*)
2425         # This is only necessary if you are linking against an obsolete
2426         # version of ncurses (but it should do no harm, since it's static).
2427         if test "$cf_nculib_root" = ncurses ; then
2428                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2429         fi
2430         ;;
2431 esac
2432
2433 CF_ADD_LIBS($cf_ncurses_LIBS)
2434
2435 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2436 then
2437         CF_ADD_LIBS(-l$cf_nculib_root)
2438 else
2439         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2440                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2441                 [initscr()],
2442                 initscr)
2443 fi
2444
2445 if test -n "$cf_ncurses_LIBS" ; then
2446         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2447         cf_ncurses_SAVE="$LIBS"
2448         for p in $cf_ncurses_LIBS ; do
2449                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2450                 if test "$q" != "$LIBS" ; then
2451                         LIBS="$q"
2452                 fi
2453         done
2454         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2455                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2456                 [AC_MSG_RESULT(yes)],
2457                 [AC_MSG_RESULT(no)
2458                  LIBS="$cf_ncurses_SAVE"])
2459 fi
2460
2461 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2462 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2463 ])dnl
2464 dnl ---------------------------------------------------------------------------
2465 dnl CF_NCURSES_VERSION version: 14 updated: 2012/10/06 08:57:51
2466 dnl ------------------
2467 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2468 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2469 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2470 AC_DEFUN([CF_NCURSES_VERSION],
2471 [
2472 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2473 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2474         cf_cv_ncurses_version=no
2475         cf_tempfile=out$$
2476         rm -f $cf_tempfile
2477         AC_TRY_RUN([
2478 #include <${cf_cv_ncurses_header:-curses.h}>
2479 #include <stdio.h>
2480 int main()
2481 {
2482         FILE *fp = fopen("$cf_tempfile", "w");
2483 #ifdef NCURSES_VERSION
2484 # ifdef NCURSES_VERSION_PATCH
2485         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2486 # else
2487         fprintf(fp, "%s\n", NCURSES_VERSION);
2488 # endif
2489 #else
2490 # ifdef __NCURSES_H
2491         fprintf(fp, "old\n");
2492 # else
2493         make an error
2494 # endif
2495 #endif
2496         ${cf_cv_main_return:-return}(0);
2497 }],[
2498         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2499
2500         # This will not work if the preprocessor splits the line after the
2501         # Autoconf token.  The 'unproto' program does that.
2502         cat > conftest.$ac_ext <<EOF
2503 #include <${cf_cv_ncurses_header:-curses.h}>
2504 #undef Autoconf
2505 #ifdef NCURSES_VERSION
2506 Autoconf NCURSES_VERSION
2507 #else
2508 #ifdef __NCURSES_H
2509 Autoconf "old"
2510 #endif
2511 ;
2512 #endif
2513 EOF
2514         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2515         AC_TRY_EVAL(cf_try)
2516         if test -f conftest.out ; then
2517                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2518                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2519                 rm -f conftest.out
2520         fi
2521 ])
2522         rm -f $cf_tempfile
2523 ])
2524 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2525 ])dnl
2526 dnl ---------------------------------------------------------------------------
2527 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
2528 dnl -------------
2529 dnl Compute the object-directory name from the given model name
2530 AC_DEFUN([CF_OBJ_SUBDIR],
2531 [
2532         case $1 in
2533         (libtool) $2='obj_lo'  ;;
2534         (normal)  $2='objects' ;;
2535         (debug)   $2='obj_g' ;;
2536         (profile) $2='obj_p' ;;
2537         (shared)
2538                 case $cf_cv_system_name in
2539                 (cygwin|msys)
2540                         $2='objects' ;;
2541                 (*)
2542                         $2='obj_s' ;;
2543                 esac
2544         esac
2545 ])dnl
2546 dnl ---------------------------------------------------------------------------
2547 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
2548 dnl ----------
2549 dnl Provide a value for the $PATH and similar separator (or amend the value
2550 dnl as provided in autoconf 2.5x).
2551 AC_DEFUN([CF_PATHSEP],
2552 [
2553         AC_MSG_CHECKING(for PATH separator)
2554         case $cf_cv_system_name in
2555         (os2*)  PATH_SEPARATOR=';'  ;;
2556         (*)     ${PATH_SEPARATOR:=':'}  ;;
2557         esac
2558 ifelse([$1],,,[$1=$PATH_SEPARATOR])
2559         AC_SUBST(PATH_SEPARATOR)
2560         AC_MSG_RESULT($PATH_SEPARATOR)
2561 ])dnl
2562 dnl ---------------------------------------------------------------------------
2563 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
2564 dnl --------------
2565 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2566 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2567 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2568 dnl delayed evaluation of those symbols.
2569 AC_DEFUN([CF_PATH_SYNTAX],[
2570 if test "x$prefix" != xNONE; then
2571         cf_path_syntax="$prefix"
2572 else
2573         cf_path_syntax="$ac_default_prefix"
2574 fi
2575
2576 case ".[$]$1" in
2577 (.\[$]\(*\)*|.\'*\'*)
2578         ;;
2579 (..|./*|.\\*)
2580         ;;
2581 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
2582         ;;
2583 (.\[$]{*prefix}*|.\[$]{*dir}*)
2584         eval $1="[$]$1"
2585         case ".[$]$1" in
2586         (.NONE/*)
2587                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2588                 ;;
2589         esac
2590         ;;
2591 (.no|.NONE/*)
2592         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2593         ;;
2594 (*)
2595         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2596         ;;
2597 esac
2598 ])dnl
2599 dnl ---------------------------------------------------------------------------
2600 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
2601 dnl -------------
2602 dnl Check for the package-config program, unless disabled by command-line.
2603 AC_DEFUN([CF_PKG_CONFIG],
2604 [
2605 AC_MSG_CHECKING(if you want to use pkg-config)
2606 AC_ARG_WITH(pkg-config,
2607         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2608         [cf_pkg_config=$withval],
2609         [cf_pkg_config=yes])
2610 AC_MSG_RESULT($cf_pkg_config)
2611
2612 case $cf_pkg_config in
2613 (no)
2614         PKG_CONFIG=none
2615         ;;
2616 (yes)
2617         CF_ACVERSION_CHECK(2.52,
2618                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2619                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2620         ;;
2621 (*)
2622         PKG_CONFIG=$withval
2623         ;;
2624 esac
2625
2626 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2627 if test "$PKG_CONFIG" != none ; then
2628         CF_PATH_SYNTAX(PKG_CONFIG)
2629 elif test "x$cf_pkg_config" != xno ; then
2630         AC_MSG_WARN(pkg-config is not installed)
2631 fi
2632
2633 AC_SUBST(PKG_CONFIG)
2634 ])dnl
2635 dnl ---------------------------------------------------------------------------
2636 dnl CF_POSIX_C_SOURCE version: 9 updated: 2015/04/12 15:39:00
2637 dnl -----------------
2638 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2639 dnl
2640 dnl     POSIX.1-1990                            _POSIX_SOURCE
2641 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2642 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2643 dnl             Bindings Option
2644 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2645 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2646 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2647 dnl
2648 dnl Parameters:
2649 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2650 AC_DEFUN([CF_POSIX_C_SOURCE],
2651 [
2652 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2653
2654 cf_save_CFLAGS="$CFLAGS"
2655 cf_save_CPPFLAGS="$CPPFLAGS"
2656
2657 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2658 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2659
2660 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2661         CF_MSG_LOG(if the symbol is already defined go no further)
2662         AC_TRY_COMPILE([#include <sys/types.h>],[
2663 #ifndef _POSIX_C_SOURCE
2664 make an error
2665 #endif],
2666         [cf_cv_posix_c_source=no],
2667         [cf_want_posix_source=no
2668          case .$cf_POSIX_C_SOURCE in
2669          (.[[12]]??*)
2670                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2671                 ;;
2672          (.2)
2673                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2674                 cf_want_posix_source=yes
2675                 ;;
2676          (.*)
2677                 cf_want_posix_source=yes
2678                 ;;
2679          esac
2680          if test "$cf_want_posix_source" = yes ; then
2681                 AC_TRY_COMPILE([#include <sys/types.h>],[
2682 #ifdef _POSIX_SOURCE
2683 make an error
2684 #endif],[],
2685                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2686          fi
2687          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2688          CFLAGS="$cf_trim_CFLAGS"
2689          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2690          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2691          AC_TRY_COMPILE([#include <sys/types.h>],[
2692 #ifndef _POSIX_C_SOURCE
2693 make an error
2694 #endif],,
2695          [cf_cv_posix_c_source=no])
2696          CFLAGS="$cf_save_CFLAGS"
2697          CPPFLAGS="$cf_save_CPPFLAGS"
2698         ])
2699 ])
2700
2701 if test "$cf_cv_posix_c_source" != no ; then
2702         CFLAGS="$cf_trim_CFLAGS"
2703         CPPFLAGS="$cf_trim_CPPFLAGS"
2704         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2705 fi
2706
2707 ])dnl
2708 dnl ---------------------------------------------------------------------------
2709 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
2710 dnl ----------
2711 dnl Check for archiver "ar".
2712 AC_DEFUN([CF_PROG_AR],[
2713 AC_CHECK_TOOL(AR, ar, ar)
2714 ])
2715 dnl ---------------------------------------------------------------------------
2716 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
2717 dnl -----------
2718 dnl Check for awk, ensure that the check found something.
2719 AC_DEFUN([CF_PROG_AWK],
2720 [
2721 AC_PROG_AWK
2722 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
2723 ])dnl
2724 dnl ---------------------------------------------------------------------------
2725 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
2726 dnl ----------
2727 dnl standard check for CC, plus followup sanity checks
2728 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
2729 AC_DEFUN([CF_PROG_CC],[
2730 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
2731 CF_GCC_VERSION
2732 CF_ACVERSION_CHECK(2.52,
2733         [AC_PROG_CC_STDC],
2734         [CF_ANSI_CC_REQD])
2735 CF_CC_ENV_FLAGS
2736 ])dnl
2737 dnl ---------------------------------------------------------------------------
2738 dnl CF_PROG_CC_C_O version: 4 updated: 2016/05/21 18:08:09
2739 dnl --------------
2740 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
2741 dnl the output file can be renamed, and allows for a shell variable that can
2742 dnl be used later.  The parameter is either CC or CXX.  The result is the
2743 dnl cache variable:
2744 dnl     $cf_cv_prog_CC_c_o
2745 dnl     $cf_cv_prog_CXX_c_o
2746 dnl
2747 dnl $1 = compiler
2748 dnl $2 = compiler options, if any
2749 AC_DEFUN([CF_PROG_CC_C_O],
2750 [AC_REQUIRE([AC_PROG_CC])dnl
2751 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
2752 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
2753 [
2754 cat > conftest.$ac_ext <<CF_EOF
2755 int main()
2756 {
2757         ${cf_cv_main_return:-return}(0);
2758 }
2759 CF_EOF
2760 # We do the test twice because some compilers refuse to overwrite an
2761 # existing .o file with -o, though they will create one.
2762 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
2763 if AC_TRY_EVAL(ac_try) &&
2764   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
2765 then
2766   eval cf_cv_prog_$1_c_o=yes
2767 else
2768   eval cf_cv_prog_$1_c_o=no
2769 fi
2770 rm -rf conftest*
2771 ])dnl
2772 if test $cf_cv_prog_$1_c_o = yes; then
2773   AC_MSG_RESULT([yes])
2774 else
2775   AC_MSG_RESULT([no])
2776 fi
2777 ])dnl
2778 dnl ---------------------------------------------------------------------------
2779 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
2780 dnl -------------
2781 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
2782 dnl This macro adds a check to ensure the script found something.
2783 AC_DEFUN([CF_PROG_EGREP],
2784 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
2785         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
2786                 then ac_cv_prog_egrep='grep -E'
2787                 else ac_cv_prog_egrep='egrep'
2788         fi])
2789         EGREP=$ac_cv_prog_egrep
2790         AC_SUBST([EGREP])
2791         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
2792 ])dnl
2793 dnl ---------------------------------------------------------------------------
2794 dnl CF_PROG_EXT version: 13 updated: 2015/04/18 09:03:58
2795 dnl -----------
2796 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
2797 AC_DEFUN([CF_PROG_EXT],
2798 [
2799 AC_REQUIRE([CF_CHECK_CACHE])
2800 case $cf_cv_system_name in
2801 (os2*)
2802         CFLAGS="$CFLAGS -Zmt"
2803         CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
2804         CXXFLAGS="$CXXFLAGS -Zmt"
2805         # autoconf's macro sets -Zexe and suffix both, which conflict:w
2806         LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
2807         ac_cv_exeext=.exe
2808         ;;
2809 esac
2810
2811 AC_EXEEXT
2812 AC_OBJEXT
2813
2814 PROG_EXT="$EXEEXT"
2815 AC_SUBST(PROG_EXT)
2816 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
2817 ])dnl
2818 dnl ---------------------------------------------------------------------------
2819 dnl CF_PROG_GNAT version: 3 updated: 2015/04/18 08:56:57
2820 dnl ------------
2821 dnl Check for gnatmake, ensure that it is complete.
2822 AC_DEFUN([CF_PROG_GNAT],[
2823 cf_ada_make=gnatmake
2824 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
2825 if test "$ac_cv_prog_gnat_exists" = no; then
2826         cf_ada_make=
2827         cf_cv_prog_gnat_correct=no
2828 else
2829         CF_GNAT_VERSION
2830         AC_CHECK_PROG(M4_exists, m4, yes, no)
2831         if test "$ac_cv_prog_M4_exists" = no; then
2832                 cf_cv_prog_gnat_correct=no
2833                 echo Ada95 binding required program m4 not found. Ada95 binding disabled.
2834         fi
2835         if test "$cf_cv_prog_gnat_correct" = yes; then
2836                 AC_MSG_CHECKING(if GNAT works)
2837                 CF_GNAT_TRY_RUN([procedure conftest;],
2838 [with Text_IO;
2839 with GNAT.OS_Lib;
2840 procedure conftest is
2841 begin
2842    Text_IO.Put ("Hello World");
2843    Text_IO.New_Line;
2844    GNAT.OS_Lib.OS_Exit (0);
2845 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
2846                 AC_MSG_RESULT($cf_cv_prog_gnat_correct)
2847         fi
2848 fi
2849
2850 AC_SUBST(cf_ada_make)
2851 ])dnl
2852 dnl ---------------------------------------------------------------------------
2853 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
2854 dnl ------------
2855 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
2856 dnl option if it is supported.
2857 AC_DEFUN([CF_PROG_LN_S],[
2858 AC_PROG_LN_S
2859 AC_MSG_CHECKING(if $LN_S -f options work)
2860
2861 rm -f conf$$.src conf$$dst
2862 echo >conf$$.dst
2863 echo first >conf$$.src
2864 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
2865         cf_prog_ln_sf=yes
2866 else
2867         cf_prog_ln_sf=no
2868 fi
2869 rm -f conf$$.dst conf$$src
2870 AC_MSG_RESULT($cf_prog_ln_sf)
2871
2872 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
2873 ])dnl
2874 dnl ---------------------------------------------------------------------------
2875 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2876 dnl ----------------
2877 dnl Remove all -U and -D options that refer to the given symbol from a list
2878 dnl of C compiler options.  This works around the problem that not all
2879 dnl compilers process -U and -D options from left-to-right, so a -U option
2880 dnl cannot be used to cancel the effect of a preceding -D option.
2881 dnl
2882 dnl $1 = target (which could be the same as the source variable)
2883 dnl $2 = source (including '$')
2884 dnl $3 = symbol to remove
2885 define([CF_REMOVE_DEFINE],
2886 [
2887 $1=`echo "$2" | \
2888         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2889                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2890 ])dnl
2891 dnl ---------------------------------------------------------------------------
2892 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
2893 dnl -------------
2894 dnl Remove the given library from the symbol
2895 dnl
2896 dnl $1 = target (which could be the same as the source variable)
2897 dnl $2 = source (including '$')
2898 dnl $3 = library to remove
2899 define([CF_REMOVE_LIB],
2900 [
2901 # remove $3 library from $2
2902 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
2903 ])dnl
2904 dnl ---------------------------------------------------------------------------
2905 dnl CF_SHARED_OPTS version: 89 updated: 2015/08/15 18:38:59
2906 dnl --------------
2907 dnl --------------
2908 dnl Attempt to determine the appropriate CC/LD options for creating a shared
2909 dnl library.
2910 dnl
2911 dnl Notes:
2912 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
2913 dnl the build-tree, i.e., by making use of the libraries that are compiled in
2914 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
2915 dnl shared library since that can lead to unexpected results at runtime.
2916 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
2917 dnl libraries are compiled in ../../lib
2918 dnl
2919 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
2920 dnl to install symbolic links to the rel/abi versions of shared libraries.
2921 dnl
2922 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
2923 dnl version when making symbolic links.
2924 dnl
2925 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
2926 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
2927 dnl (ex: libncurses.so.<ver>).
2928 dnl
2929 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
2930 AC_DEFUN([CF_SHARED_OPTS],
2931 [
2932         AC_REQUIRE([CF_LD_RPATH_OPT])
2933         RM_SHARED_OPTS=
2934         LOCAL_LDFLAGS=
2935         LOCAL_LDFLAGS2=
2936         LD_SHARED_OPTS=
2937         INSTALL_LIB="-m 644"
2938         : ${rel_builddir:=.}
2939
2940         shlibdir=$libdir
2941         AC_SUBST(shlibdir)
2942
2943         MAKE_DLLS="#"
2944         AC_SUBST(MAKE_DLLS)
2945
2946         cf_cv_do_symlinks=no
2947         cf_ld_rpath_opt=
2948         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
2949
2950         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
2951         AC_ARG_WITH(shlib-version,
2952         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
2953         [test -z "$withval" && withval=auto
2954         case $withval in
2955         (yes)
2956                 cf_cv_shlib_version=auto
2957                 ;;
2958         (rel|abi|auto)
2959                 cf_cv_shlib_version=$withval
2960                 ;;
2961         (*)
2962                 AC_MSG_RESULT($withval)
2963                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
2964                 ;;
2965         esac
2966         ],[cf_cv_shlib_version=auto])
2967         AC_MSG_RESULT($cf_cv_shlib_version)
2968
2969         cf_cv_rm_so_locs=no
2970         cf_try_cflags=
2971
2972         # Some less-capable ports of gcc support only -fpic
2973         CC_SHARED_OPTS=
2974         if test "$GCC" = yes
2975         then
2976                 AC_MSG_CHECKING(which $CC option to use)
2977                 cf_save_CFLAGS="$CFLAGS"
2978                 for CC_SHARED_OPTS in -fPIC -fpic ''
2979                 do
2980                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
2981                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
2982                 done
2983                 AC_MSG_RESULT($CC_SHARED_OPTS)
2984                 CFLAGS="$cf_save_CFLAGS"
2985         fi
2986
2987         cf_cv_shlib_version_infix=no
2988
2989         case $cf_cv_system_name in
2990         (aix4.[3-9]*|aix[[5-7]]*)
2991                 if test "$GCC" = yes; then
2992                         CC_SHARED_OPTS='-Wl,-brtl'
2993                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
2994                 else
2995                         CC_SHARED_OPTS='-brtl'
2996                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
2997                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
2998                 fi
2999                 ;;
3000         (beos*)
3001                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
3002                 ;;
3003         (cygwin*)
3004                 CC_SHARED_OPTS=
3005                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3006                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3007                 cf_cv_shlib_version=cygdll
3008                 cf_cv_shlib_version_infix=cygdll
3009                 shlibdir=$bindir
3010                 MAKE_DLLS=
3011                 cat >mk_shared_lib.sh <<-CF_EOF
3012                 #!$SHELL
3013                 SHARED_LIB=\[$]1
3014                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3015                 shift
3016                 cat <<-EOF
3017                 Linking shared library
3018                 ** SHARED_LIB \[$]SHARED_LIB
3019                 ** IMPORT_LIB \[$]IMPORT_LIB
3020 EOF
3021                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3022 CF_EOF
3023                 chmod +x mk_shared_lib.sh
3024                 ;;
3025         (msys*)
3026                 CC_SHARED_OPTS=
3027                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3028                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3029                 cf_cv_shlib_version=msysdll
3030                 cf_cv_shlib_version_infix=msysdll
3031                 shlibdir=$bindir
3032                 MAKE_DLLS=
3033                 cat >mk_shared_lib.sh <<-CF_EOF
3034                 #!$SHELL
3035                 SHARED_LIB=\[$]1
3036                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3037                 shift
3038                 cat <<-EOF
3039                 Linking shared library
3040                 ** SHARED_LIB \[$]SHARED_LIB
3041                 ** IMPORT_LIB \[$]IMPORT_LIB
3042 EOF
3043                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3044 CF_EOF
3045                 chmod +x mk_shared_lib.sh
3046                 ;;
3047         (darwin*)
3048                 cf_try_cflags="no-cpp-precomp"
3049                 CC_SHARED_OPTS="-dynamic"
3050                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
3051                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
3052                 cf_cv_shlib_version_infix=yes
3053                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
3054                         cf_save_LDFLAGS=$LDFLAGS
3055                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3056                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
3057                                 LDFLAGS=$cf_save_LDFLAGS])
3058                 if test $cf_cv_ldflags_search_paths_first = yes; then
3059                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3060                 fi
3061                 ;;
3062         (hpux[[7-8]]*)
3063                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
3064                 if test "$GCC" != yes; then
3065                         CC_SHARED_OPTS='+Z'
3066                 fi
3067                 MK_SHARED_LIB='${LD} -b -o $[@]'
3068                 INSTALL_LIB="-m 555"
3069                 ;;
3070         (hpux*)
3071                 # (tested with gcc 2.7.2 -- I don't have c89)
3072                 if test "$GCC" = yes; then
3073                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
3074                 else
3075                         CC_SHARED_OPTS='+Z'
3076                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
3077                 fi
3078                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
3079                 # HP-UX shared libraries must be executable, and should be
3080                 # readonly to exploit a quirk in the memory manager.
3081                 INSTALL_LIB="-m 555"
3082                 ;;
3083         (interix*)
3084                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3085                 if test "$cf_cv_shlib_version" = rel; then
3086                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
3087                 else
3088                         cf_shared_soname='`basename $@`'
3089                 fi
3090                 CC_SHARED_OPTS=
3091                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
3092                 ;;
3093         (irix*)
3094                 if test "$cf_cv_enable_rpath" = yes ; then
3095                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3096                 fi
3097                 # tested with IRIX 5.2 and 'cc'.
3098                 if test "$GCC" != yes; then
3099                         CC_SHARED_OPTS='-KPIC'
3100                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
3101                 else
3102                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
3103                 fi
3104                 cf_cv_rm_so_locs=yes
3105                 ;;
3106         (linux*|gnu*|k*bsd*-gnu)
3107                 if test "$DFT_LWR_MODEL" = "shared" ; then
3108                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3109                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3110                 fi
3111                 if test "$cf_cv_enable_rpath" = yes ; then
3112                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3113                 fi
3114                 CF_SHARED_SONAME
3115                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3116                 ;;
3117         (mingw*)
3118                 cf_cv_shlib_version=mingw
3119                 cf_cv_shlib_version_infix=mingw
3120                 shlibdir=$bindir
3121                 MAKE_DLLS=
3122                 if test "$DFT_LWR_MODEL" = "shared" ; then
3123                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
3124                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3125                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
3126                 fi
3127                 CC_SHARED_OPTS=
3128                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3129                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3130                 cat >mk_shared_lib.sh <<-CF_EOF
3131                 #!$SHELL
3132                 SHARED_LIB=\[$]1
3133                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3134                 shift
3135                 cat <<-EOF
3136                 Linking shared library
3137                 ** SHARED_LIB \[$]SHARED_LIB
3138                 ** IMPORT_LIB \[$]IMPORT_LIB
3139 EOF
3140                 exec \[$]* -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3141 CF_EOF
3142                 chmod +x mk_shared_lib.sh
3143                 ;;
3144         (openbsd[[2-9]].*|mirbsd*)
3145                 if test "$DFT_LWR_MODEL" = "shared" ; then
3146                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3147                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3148                 fi
3149                 if test "$cf_cv_enable_rpath" = yes ; then
3150                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3151                 fi
3152                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3153                 CF_SHARED_SONAME
3154                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3155                 ;;
3156         (nto-qnx*|openbsd*|freebsd[[12]].*)
3157                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3158                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
3159                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3160                 ;;
3161         (dragonfly*|freebsd*)
3162                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3163                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3164                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3165                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
3166                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3167                 fi
3168                 CF_SHARED_SONAME
3169                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3170                 ;;
3171         (netbsd*)
3172                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3173                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3174                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3175                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3176                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3177                         if test "$cf_cv_shlib_version" = auto; then
3178                         if test -f /usr/libexec/ld.elf_so; then
3179                                 cf_cv_shlib_version=abi
3180                         else
3181                                 cf_cv_shlib_version=rel
3182                         fi
3183                         fi
3184                         CF_SHARED_SONAME
3185                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
3186                 else
3187                         MK_SHARED_LIB='${CC} -Wl,-shared -Wl,-Bshareable -o $[@]'
3188                 fi
3189                 ;;
3190         (osf*|mls+*)
3191                 # tested with OSF/1 V3.2 and 'cc'
3192                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
3193                 # link with shared libs).
3194                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
3195                 case $host_os in
3196                 (osf4*)
3197                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
3198                         ;;
3199                 esac
3200                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
3201                 if test "$DFT_LWR_MODEL" = "shared" ; then
3202                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3203                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3204                 fi
3205                 cf_cv_rm_so_locs=yes
3206                 ;;
3207         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
3208                 # tested with osr5.0.5
3209                 if test "$GCC" != yes; then
3210                         CC_SHARED_OPTS='-belf -KPIC'
3211                 fi
3212                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
3213                 if test "$cf_cv_enable_rpath" = yes ; then
3214                         # only way is to set LD_RUN_PATH but no switch for it
3215                         RUN_PATH=$libdir
3216                 fi
3217                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3218                 LINK_PROGS='LD_RUN_PATH=${libdir}'
3219                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
3220                 ;;
3221         (sunos4*)
3222                 # tested with SunOS 4.1.1 and gcc 2.7.0
3223                 if test "$GCC" != yes; then
3224                         CC_SHARED_OPTS='-KPIC'
3225                 fi
3226                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
3227                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3228                 ;;
3229         (solaris2*)
3230                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
3231                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
3232                 if test "$DFT_LWR_MODEL" = "shared" ; then
3233                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
3234                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3235                 fi
3236                 if test "$cf_cv_enable_rpath" = yes ; then
3237                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
3238                 fi
3239                 CF_SHARED_SONAME
3240                 if test "$GCC" != yes; then
3241                         cf_save_CFLAGS="$CFLAGS"
3242                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
3243                         do
3244                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
3245                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
3246                         done
3247                         CFLAGS="$cf_save_CFLAGS"
3248                         CC_SHARED_OPTS=$cf_shared_opts
3249                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3250                 else
3251                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3252                 fi
3253                 ;;
3254         (sysv5uw7*|unix_sv*)
3255                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
3256                 if test "$GCC" != yes; then
3257                         CC_SHARED_OPTS='-KPIC'
3258                 fi
3259                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
3260                 ;;
3261         (*)
3262                 CC_SHARED_OPTS='unknown'
3263                 MK_SHARED_LIB='echo unknown'
3264                 ;;
3265         esac
3266
3267         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
3268         case "$cf_cv_shlib_version" in
3269         (rel|abi)
3270                 case "$MK_SHARED_LIB" in
3271                 (*'-o $[@]')
3272                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
3273                         ;;
3274                 (*)
3275                         AC_MSG_WARN(ignored --with-shlib-version)
3276                         ;;
3277                 esac
3278                 ;;
3279         esac
3280
3281         if test -n "$cf_try_cflags"
3282         then
3283 cat > conftest.$ac_ext <<EOF
3284 #line __oline__ "${as_me:-configure}"
3285 #include <stdio.h>
3286 int main(int argc, char *argv[[]])
3287 {
3288         printf("hello\n");
3289         return (argv[[argc-1]] == 0) ;
3290 }
3291 EOF
3292                 cf_save_CFLAGS="$CFLAGS"
3293                 for cf_opt in $cf_try_cflags
3294                 do
3295                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
3296                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
3297                         if AC_TRY_EVAL(ac_compile); then
3298                                 AC_MSG_RESULT(yes)
3299                                 cf_save_CFLAGS="$CFLAGS"
3300                         else
3301                                 AC_MSG_RESULT(no)
3302                         fi
3303                 done
3304                 CFLAGS="$cf_save_CFLAGS"
3305         fi
3306
3307
3308         # RPATH_LIST is a colon-separated list of directories
3309         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
3310         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
3311
3312         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
3313
3314         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
3315         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
3316
3317         AC_SUBST(CC_SHARED_OPTS)
3318         AC_SUBST(LD_RPATH_OPT)
3319         AC_SUBST(LD_SHARED_OPTS)
3320         AC_SUBST(MK_SHARED_LIB)
3321         AC_SUBST(RM_SHARED_OPTS)
3322
3323         AC_SUBST(LINK_PROGS)
3324         AC_SUBST(LINK_TESTS)
3325
3326         AC_SUBST(EXTRA_LDFLAGS)
3327         AC_SUBST(LOCAL_LDFLAGS)
3328         AC_SUBST(LOCAL_LDFLAGS2)
3329
3330         AC_SUBST(INSTALL_LIB)
3331         AC_SUBST(RPATH_LIST)
3332 ])dnl
3333 dnl ---------------------------------------------------------------------------
3334 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
3335 dnl ----------------
3336 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
3337 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
3338 dnl option.
3339 dnl
3340 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
3341 dnl If missing, use "rel".
3342 define([CF_SHARED_SONAME],
3343 [
3344         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
3345         if test "$cf_cv_shlib_version" = rel; then
3346                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3347         else
3348                 cf_cv_shared_soname='`basename $[@]`'
3349         fi
3350 ])
3351 dnl ---------------------------------------------------------------------------
3352 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
3353 dnl --------------
3354 dnl     Remove "-g" option from the compiler options
3355 AC_DEFUN([CF_STRIP_G_OPT],
3356 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
3357 dnl ---------------------------------------------------------------------------
3358 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
3359 dnl --------------
3360 dnl Construct a search-list for a nonstandard header/lib-file
3361 dnl     $1 = the variable to return as result
3362 dnl     $2 = the package name
3363 dnl     $3 = the subdirectory, e.g., bin, include or lib
3364 AC_DEFUN([CF_SUBDIR_PATH],
3365 [
3366 $1=
3367
3368 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3369
3370 for cf_subdir_prefix in \
3371         /usr \
3372         /usr/local \
3373         /usr/pkg \
3374         /opt \
3375         /opt/local \
3376         [$]HOME
3377 do
3378         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
3379 done
3380 ])dnl
3381 dnl ---------------------------------------------------------------------------
3382 dnl CF_TERM_HEADER version: 4 updated: 2015/04/15 19:08:48
3383 dnl --------------
3384 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3385 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3386 dnl but some packagers change this, breaking various applications.
3387 AC_DEFUN([CF_TERM_HEADER],[
3388 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3389 case ${cf_cv_ncurses_header} in
3390 (*/ncurses.h|*/ncursesw.h)
3391         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3392         ;;
3393 (*)
3394         cf_term_header=term.h
3395         ;;
3396 esac
3397
3398 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3399 do
3400 AC_TRY_COMPILE([#include <stdio.h>
3401 #include <${cf_cv_ncurses_header:-curses.h}>
3402 #include <$cf_test>
3403 ],[int x = auto_left_margin],[
3404         cf_cv_term_header="$cf_test"],[
3405         cf_cv_term_header=unknown
3406         ])
3407         test "$cf_cv_term_header" != unknown && break
3408 done
3409 ])
3410
3411 # Set definitions to allow ifdef'ing to accommodate subdirectories
3412
3413 case $cf_cv_term_header in
3414 (*term.h)
3415         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
3416         ;;
3417 esac
3418
3419 case $cf_cv_term_header in
3420 (ncurses/term.h)
3421         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
3422         ;;
3423 (ncursesw/term.h)
3424         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
3425         ;;
3426 esac
3427 ])dnl
3428 dnl ---------------------------------------------------------------------------
3429 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
3430 dnl ---------------
3431 dnl Define a top_builddir symbol, for applications that need an absolute path.
3432 AC_DEFUN([CF_TOP_BUILDDIR],
3433 [
3434 top_builddir=ifelse($1,,`pwd`,$1)
3435 AC_SUBST(top_builddir)
3436 ])dnl
3437 dnl ---------------------------------------------------------------------------
3438 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
3439 dnl -------------------
3440 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
3441 dnl can define it successfully.
3442 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
3443 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3444         AC_TRY_COMPILE([
3445 #include <stdlib.h>
3446 #include <string.h>
3447 #include <sys/types.h>
3448 ],[
3449 #ifndef _XOPEN_SOURCE
3450 make an error
3451 #endif],
3452         [cf_cv_xopen_source=no],
3453         [cf_save="$CPPFLAGS"
3454          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3455          AC_TRY_COMPILE([
3456 #include <stdlib.h>
3457 #include <string.h>
3458 #include <sys/types.h>
3459 ],[
3460 #ifdef _XOPEN_SOURCE
3461 make an error
3462 #endif],
3463         [cf_cv_xopen_source=no],
3464         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3465         CPPFLAGS="$cf_save"
3466         ])
3467 ])
3468
3469 if test "$cf_cv_xopen_source" != no ; then
3470         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3471         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3472         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3473         CF_ADD_CFLAGS($cf_temp_xopen_source)
3474 fi
3475 ])
3476 dnl ---------------------------------------------------------------------------
3477 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3478 dnl --------
3479 dnl Make an uppercase version of a variable
3480 dnl $1=uppercase($2)
3481 AC_DEFUN([CF_UPPER],
3482 [
3483 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3484 ])dnl
3485 dnl ---------------------------------------------------------------------------
3486 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
3487 dnl -----------
3488 dnl Check for multibyte support, and if not found, utf8 compatibility library
3489 AC_DEFUN([CF_UTF8_LIB],
3490 [
3491 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3492         cf_save_LIBS="$LIBS"
3493         AC_TRY_LINK([
3494 #include <stdlib.h>],[putwc(0,0);],
3495         [cf_cv_utf8_lib=yes],
3496         [CF_FIND_LINKAGE([
3497 #include <libutf8.h>],[putwc(0,0);],utf8,
3498                 [cf_cv_utf8_lib=add-on],
3499                 [cf_cv_utf8_lib=no])
3500 ])])
3501
3502 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3503 # ncurses/ncursesw:
3504 if test "$cf_cv_utf8_lib" = "add-on" ; then
3505         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
3506         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3507         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3508         CF_ADD_LIBS($cf_cv_library_file_utf8)
3509 fi
3510 ])dnl
3511 dnl ---------------------------------------------------------------------------
3512 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3513 dnl ----------
3514 dnl Use AC_VERBOSE w/o the warnings
3515 AC_DEFUN([CF_VERBOSE],
3516 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3517 CF_MSG_LOG([$1])
3518 ])dnl
3519 dnl ---------------------------------------------------------------------------
3520 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
3521 dnl ---------------
3522 dnl Check for compiler-support for weak symbols.
3523 dnl This works with "recent" gcc.
3524 AC_DEFUN([CF_WEAK_SYMBOLS],[
3525 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
3526
3527 AC_TRY_COMPILE([
3528 #include <stdio.h>],
3529 [
3530 #if defined(__GNUC__)
3531 #  if defined __USE_ISOC99
3532 #    define _cat_pragma(exp)    _Pragma(#exp)
3533 #    define _weak_pragma(exp)   _cat_pragma(weak name)
3534 #  else
3535 #    define _weak_pragma(exp)
3536 #  endif
3537 #  define _declare(name)        __extension__ extern __typeof__(name) name
3538 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
3539 #endif
3540
3541 weak_symbol(fopen);
3542 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
3543 ])
3544 ])dnl
3545 dnl ---------------------------------------------------------------------------
3546 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
3547 dnl --------------------
3548 dnl Command-line option to specify the Ada95 compiler.
3549 AC_DEFUN([CF_WITH_ADA_COMPILER],[
3550 AC_MSG_CHECKING(for ada-compiler)
3551 AC_ARG_WITH(ada-compiler,
3552         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
3553         [cf_ada_compiler=$withval],
3554         [cf_ada_compiler=gnatmake])
3555 AC_SUBST(cf_ada_compiler)
3556 AC_MSG_RESULT($cf_ada_compiler)
3557 ])dnl
3558 dnl ---------------------------------------------------------------------------
3559 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
3560 dnl -------------------
3561 dnl Command-line option to specify where Ada includes will install.
3562 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
3563 AC_MSG_CHECKING(for ada-include)
3564 CF_WITH_PATH(ada-include,
3565    [  --with-ada-include=DIR  Ada includes are in DIR],
3566    ADA_INCLUDE,
3567    PREFIX/share/ada/adainclude,
3568    [$]prefix/share/ada/adainclude)
3569 AC_SUBST(ADA_INCLUDE)
3570 AC_MSG_RESULT($ADA_INCLUDE)
3571 ])dnl
3572 dnl ---------------------------------------------------------------------------
3573 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
3574 dnl -------------------
3575 dnl Command-line option to specify where Ada objects will install.
3576 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
3577 AC_MSG_CHECKING(for ada-objects)
3578 CF_WITH_PATH(ada-objects,
3579    [  --with-ada-objects=DIR  Ada objects are in DIR],
3580    ADA_OBJECTS,
3581    PREFIX/lib/ada/adalib,
3582    [$]prefix/lib/ada/adalib)
3583 AC_SUBST(ADA_OBJECTS)
3584 AC_MSG_RESULT($ADA_OBJECTS)
3585 ])dnl
3586 dnl ---------------------------------------------------------------------------
3587 dnl CF_WITH_ADA_SHAREDLIB version: 4 updated: 2014/05/31 21:08:37
3588 dnl ---------------------
3589 dnl Command-line option to specify if an Ada95 shared-library should be built,
3590 dnl and optionally what its soname should be.
3591 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
3592 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
3593 AC_ARG_WITH(ada-sharedlib,
3594         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
3595         [with_ada_sharedlib=$withval],
3596         [with_ada_sharedlib=no])
3597 AC_MSG_RESULT($with_ada_sharedlib)
3598
3599 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
3600 MAKE_ADA_SHAREDLIB="#"
3601
3602 if test "x$with_ada_sharedlib" != xno
3603 then
3604         MAKE_ADA_SHAREDLIB=
3605         if test "x$with_ada_sharedlib" != xyes
3606         then
3607                 ADA_SHAREDLIB="$with_ada_sharedlib"
3608         fi
3609 fi
3610
3611 AC_SUBST(ADA_SHAREDLIB)
3612 AC_SUBST(MAKE_ADA_SHAREDLIB)
3613 ])dnl
3614 dnl ---------------------------------------------------------------------------
3615 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3616 dnl ------------------
3617 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3618 dnl libraries.
3619 AC_DEFUN([CF_WITH_CURSES_DIR],[
3620
3621 AC_MSG_CHECKING(for specific curses-directory)
3622 AC_ARG_WITH(curses-dir,
3623         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3624         [cf_cv_curses_dir=$withval],
3625         [cf_cv_curses_dir=no])
3626 AC_MSG_RESULT($cf_cv_curses_dir)
3627
3628 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3629 then
3630         CF_PATH_SYNTAX(withval)
3631         if test -d "$cf_cv_curses_dir"
3632         then
3633                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3634                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3635         fi
3636 fi
3637 ])dnl
3638 dnl ---------------------------------------------------------------------------
3639 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
3640 dnl ------------------
3641 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
3642 dnl "lib" prefix, e.g., because it used the dll naming convention.
3643 dnl
3644 dnl $1 = variable to set
3645 AC_DEFUN([CF_WITH_LIB_PREFIX],
3646 [
3647 AC_MSG_CHECKING(if you want to have a library-prefix)
3648 AC_ARG_WITH(lib-prefix,
3649         [  --with-lib-prefix       override library-prefix],
3650         [with_lib_prefix=$withval],
3651         [with_lib_prefix=auto])
3652 AC_MSG_RESULT($with_lib_prefix)
3653
3654 if test $with_lib_prefix = auto
3655 then
3656         CF_LIB_PREFIX($1)
3657 elif test $with_lib_prefix = no
3658 then
3659         LIB_PREFIX=
3660 else
3661         LIB_PREFIX=$with_lib_prefix
3662 fi
3663 ])dnl
3664 dnl ---------------------------------------------------------------------------
3665 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
3666 dnl ------------
3667 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
3668 dnl defaulting to yes/no.
3669 dnl
3670 dnl $1 = option name
3671 dnl $2 = help-text
3672 dnl $3 = environment variable to set
3673 dnl $4 = default value, shown in the help-message, must be a constant
3674 dnl $5 = default value, if it's an expression & cannot be in the help-message
3675 dnl
3676 AC_DEFUN([CF_WITH_PATH],
3677 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
3678 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
3679 if ifelse([$5],,true,[test -n "$5"]) ; then
3680 CF_PATH_SYNTAX(withval)
3681 fi
3682 eval $3="$withval"
3683 AC_SUBST($3)dnl
3684 ])dnl
3685 dnl ---------------------------------------------------------------------------
3686 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
3687 dnl -------------------------
3688 dnl Allow the choice of the pkg-config library directory to be overridden.
3689 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
3690
3691 case $PKG_CONFIG in
3692 (no|none|yes)
3693         AC_MSG_CHECKING(for pkg-config library directory)
3694         ;;
3695 (*)
3696         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
3697         ;;
3698 esac
3699
3700 PKG_CONFIG_LIBDIR=no
3701 AC_ARG_WITH(pkg-config-libdir,
3702         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
3703         [PKG_CONFIG_LIBDIR=$withval],
3704         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
3705
3706 case x$PKG_CONFIG_LIBDIR in
3707 (x/*)
3708         ;;
3709 (xyes)
3710         # Look for the library directory using the same prefix as the executable
3711         if test "x$PKG_CONFIG" = xnone
3712         then
3713                 cf_path=$prefix
3714         else
3715                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
3716         fi
3717
3718         # If you don't like using the default architecture, you have to specify the
3719         # intended library directory and corresponding compiler/linker options.
3720         #
3721         # This case allows for Debian's 2014-flavor of multiarch, along with the
3722         # most common variations before that point.  Some other variants spell the
3723         # directory differently, e.g., "pkg-config", and put it in unusual places.
3724         # pkg-config has always been poorly standardized, which is ironic...
3725         case x`(arch) 2>/dev/null` in
3726         (*64)
3727                 cf_search_path="\
3728                         $cf_path/lib/*64-linux-gnu \
3729                         $cf_path/share \
3730                         $cf_path/lib64 \
3731                         $cf_path/lib32 \
3732                         $cf_path/lib"
3733                 ;;
3734         (*)
3735                 cf_search_path="\
3736                         $cf_path/lib/*-linux-gnu \
3737                         $cf_path/share \
3738                         $cf_path/lib32 \
3739                         $cf_path/lib \
3740                         $cf_path/libdata"
3741                 ;;
3742         esac
3743
3744         CF_VERBOSE(list...)
3745         for cf_config in $cf_search_path
3746         do
3747                 CF_VERBOSE(checking $cf_config/pkgconfig)
3748                 if test -d $cf_config/pkgconfig
3749                 then
3750                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
3751                         AC_MSG_CHECKING(done)
3752                         break
3753                 fi
3754         done
3755         ;;
3756 (*)
3757         ;;
3758 esac
3759
3760 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
3761         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
3762 fi
3763
3764 AC_SUBST(PKG_CONFIG_LIBDIR)
3765 ])dnl
3766 dnl ---------------------------------------------------------------------------
3767 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
3768 dnl ---------------
3769 dnl Check for POSIX thread library.
3770 AC_DEFUN([CF_WITH_PTHREAD],
3771 [
3772 AC_MSG_CHECKING(if you want to link with the pthread library)
3773 AC_ARG_WITH(pthread,
3774         [  --with-pthread          use POSIX thread library],
3775         [with_pthread=$withval],
3776         [with_pthread=no])
3777 AC_MSG_RESULT($with_pthread)
3778
3779 if test "$with_pthread" != no ; then
3780         AC_CHECK_HEADER(pthread.h,[
3781         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
3782
3783         for cf_lib_pthread in pthread c_r
3784         do
3785             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
3786             cf_save_LIBS="$LIBS"
3787             CF_ADD_LIB($cf_lib_pthread)
3788             AC_TRY_LINK([
3789 #include <pthread.h>
3790 ],[
3791                 int rc = pthread_create(0,0,0,0);
3792                 int r2 = pthread_mutexattr_settype(0, 0);
3793 ],[with_pthread=yes],[with_pthread=no])
3794             LIBS="$cf_save_LIBS"
3795             AC_MSG_RESULT($with_pthread)
3796             test "$with_pthread" = yes && break
3797         done
3798
3799         if test "$with_pthread" = yes ; then
3800             CF_ADD_LIB($cf_lib_pthread)
3801             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
3802         else
3803             AC_MSG_ERROR(Cannot link with pthread library)
3804         fi
3805         ])
3806 fi
3807 ])
3808 dnl ---------------------------------------------------------------------------
3809 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
3810 dnl ---------------
3811 dnl For testing, override the derived host system-type which is used to decide
3812 dnl things such as the linker commands used to build shared libraries.  This is
3813 dnl normally chosen automatically based on the type of system which you are
3814 dnl building on.  We use it for testing the configure script.
3815 dnl
3816 dnl This is different from the --host option: it is used only for testing parts
3817 dnl of the configure script which would not be reachable with --host since that
3818 dnl relies on the build environment being real, rather than mocked up.
3819 AC_DEFUN([CF_WITH_SYSTYPE],[
3820 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
3821 AC_ARG_WITH(system-type,
3822         [  --with-system-type=XXX  test: override derived host system-type],
3823 [AC_MSG_WARN(overriding system type to $withval)
3824         cf_cv_system_name=$withval
3825         host_os=$withval
3826 ])
3827 ])dnl
3828 dnl ---------------------------------------------------------------------------
3829 dnl CF_XOPEN_SOURCE version: 50 updated: 2015/10/17 19:03:33
3830 dnl ---------------
3831 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
3832 dnl or adapt to the vendor's definitions to get equivalent functionality,
3833 dnl without losing the common non-POSIX features.
3834 dnl
3835 dnl Parameters:
3836 dnl     $1 is the nominal value for _XOPEN_SOURCE
3837 dnl     $2 is the nominal value for _POSIX_C_SOURCE
3838 AC_DEFUN([CF_XOPEN_SOURCE],[
3839 AC_REQUIRE([AC_CANONICAL_HOST])
3840
3841 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
3842 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
3843 cf_xopen_source=
3844
3845 case $host_os in
3846 (aix[[4-7]]*)
3847         cf_xopen_source="-D_ALL_SOURCE"
3848         ;;
3849 (cygwin|msys)
3850         cf_XOPEN_SOURCE=600
3851         ;;
3852 (darwin[[0-8]].*)
3853         cf_xopen_source="-D_APPLE_C_SOURCE"
3854         ;;
3855 (darwin*)
3856         cf_xopen_source="-D_DARWIN_C_SOURCE"
3857         cf_XOPEN_SOURCE=
3858         ;;
3859 (freebsd*|dragonfly*)
3860         # 5.x headers associate
3861         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
3862         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
3863         cf_POSIX_C_SOURCE=200112L
3864         cf_XOPEN_SOURCE=600
3865         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3866         ;;
3867 (hpux11*)
3868         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
3869         ;;
3870 (hpux*)
3871         cf_xopen_source="-D_HPUX_SOURCE"
3872         ;;
3873 (irix[[56]].*)
3874         cf_xopen_source="-D_SGI_SOURCE"
3875         cf_XOPEN_SOURCE=
3876         ;;
3877 (linux*|gnu*|mint*|k*bsd*-gnu)
3878         CF_GNU_SOURCE
3879         ;;
3880 (minix*)
3881         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
3882         ;;
3883 (mirbsd*)
3884         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
3885         cf_XOPEN_SOURCE=
3886         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3887         ;;
3888 (netbsd*)
3889         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
3890         ;;
3891 (openbsd[[4-9]]*)
3892         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
3893         cf_xopen_source="-D_BSD_SOURCE"
3894         cf_XOPEN_SOURCE=600
3895         ;;
3896 (openbsd*)
3897         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
3898         ;;
3899 (os2*)
3900         cf_XOPEN_SOURCE=
3901         ;;
3902 (osf[[45]]*)
3903         cf_xopen_source="-D_OSF_SOURCE"
3904         ;;
3905 (nto-qnx*)
3906         cf_xopen_source="-D_QNX_SOURCE"
3907         ;;
3908 (sco*)
3909         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
3910         ;;
3911 (solaris2.*)
3912         cf_xopen_source="-D__EXTENSIONS__"
3913         cf_cv_xopen_source=broken
3914         ;;
3915 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
3916         cf_XOPEN_SOURCE=
3917         cf_POSIX_C_SOURCE=
3918         ;;
3919 (*)
3920         CF_TRY_XOPEN_SOURCE
3921         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3922         ;;
3923 esac
3924
3925 if test -n "$cf_xopen_source" ; then
3926         CF_ADD_CFLAGS($cf_xopen_source,true)
3927 fi
3928
3929 dnl In anything but the default case, we may have system-specific setting
3930 dnl which is still not guaranteed to provide all of the entrypoints that
3931 dnl _XOPEN_SOURCE would yield.
3932 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
3933         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
3934         AC_TRY_COMPILE([#include <stdlib.h>],[
3935 #ifndef _XOPEN_SOURCE
3936 make an error
3937 #endif],
3938         [cf_XOPEN_SOURCE_set=yes],
3939         [cf_XOPEN_SOURCE_set=no])
3940         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
3941         if test $cf_XOPEN_SOURCE_set = yes
3942         then
3943                 AC_TRY_COMPILE([#include <stdlib.h>],[
3944 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
3945 make an error
3946 #endif],
3947                 [cf_XOPEN_SOURCE_set_ok=yes],
3948                 [cf_XOPEN_SOURCE_set_ok=no])
3949                 if test $cf_XOPEN_SOURCE_set_ok = no
3950                 then
3951                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
3952                 fi
3953         else
3954                 CF_TRY_XOPEN_SOURCE
3955         fi
3956 fi
3957 ])