Ada95/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 2010-2012,2013 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.67 2013/06/15 21:13:50 tom Exp $
  32 dnl Macros used in NCURSES Ada95 auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl CF_ACVERSION_CHECK version: 4 updated: 2013/03/04 19:52:56
  43 dnl ------------------
  44 dnl Conditionally generate script according to whether we're using a given autoconf.
  45 dnl
  46 dnl $1 = version to compare against
  47 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  48 dnl $3 = code to use if AC_ACVERSION is older than $1.
  49 define([CF_ACVERSION_CHECK],
  50 [
  51 ifdef([AC_ACVERSION], ,[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])dnl
  52 ifdef([m4_version_compare],
  53 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  54 [CF_ACVERSION_COMPARE(
  55 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  56 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  57 dnl ---------------------------------------------------------------------------
  58 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  59 dnl --------------------
  60 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  61 dnl                      MAJOR2, MINOR2, TERNARY2,
  62 dnl                      PRINTABLE2, not FOUND, FOUND)
  63 define([CF_ACVERSION_COMPARE],
  64 [ifelse(builtin([eval], [$2 < $5]), 1,
  65 [ifelse([$8], , ,[$8])],
  66 [ifelse([$9], , ,[$9])])])dnl
  67 dnl ---------------------------------------------------------------------------
  68 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
  69 dnl -------------------
  70 dnl Construct the list of include-options for the C programs in the Ada95
  71 dnl binding.
  72 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  73 [
  74 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  75 if test "$srcdir" != "."; then
  76         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  77 fi
  78 if test "$GCC" != yes; then
  79         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  80 elif test "$includedir" != "/usr/include"; then
  81         if test "$includedir" = '${prefix}/include' ; then
  82                 if test $prefix != /usr ; then
  83                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  84                 fi
  85         else
  86                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  87         fi
  88 fi
  89 AC_SUBST(ACPPFLAGS)
  90 ])dnl
  91 dnl ---------------------------------------------------------------------------
  92 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
  93 dnl ---------------
  94 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
  95 AC_DEFUN([CF_ADD_ADAFLAGS],[
  96         ADAFLAGS="$ADAFLAGS $1"
  97         AC_SUBST(ADAFLAGS)
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
 101 dnl -------------
 102 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 103 dnl The second parameter if given makes this macro verbose.
 104 dnl
 105 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 106 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 107 dnl confused by the quotes (which require backslashes to keep them usable).
 108 AC_DEFUN([CF_ADD_CFLAGS],
 109 [
 110 cf_fix_cppflags=no
 111 cf_new_cflags=
 112 cf_new_cppflags=
 113 cf_new_extra_cppflags=
 114
 115 for cf_add_cflags in $1
 116 do
 117 case $cf_fix_cppflags in
 118 no)
 119         case $cf_add_cflags in #(vi
 120         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 121                 case $cf_add_cflags in
 122                 -D*)
 123                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 124
 125                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 126                                 && test -z "${cf_tst_cflags}" \
 127                                 && cf_fix_cppflags=yes
 128
 129                         if test $cf_fix_cppflags = yes ; then
 130                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 131                                 continue
 132                         elif test "${cf_tst_cflags}" = "\"'" ; then
 133                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 134                                 continue
 135                         fi
 136                         ;;
 137                 esac
 138                 case "$CPPFLAGS" in
 139                 *$cf_add_cflags) #(vi
 140                         ;;
 141                 *) #(vi
 142                         case $cf_add_cflags in #(vi
 143                         -D*)
 144                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 145                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 146                                 ;;
 147                         esac
 148                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 149                         ;;
 150                 esac
 151                 ;;
 152         *)
 153                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 154                 ;;
 155         esac
 156         ;;
 157 yes)
 158         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 159
 160         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 161
 162         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 163                 && test -z "${cf_tst_cflags}" \
 164                 && cf_fix_cppflags=no
 165         ;;
 166 esac
 167 done
 168
 169 if test -n "$cf_new_cflags" ; then
 170         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 171         CFLAGS="$CFLAGS $cf_new_cflags"
 172 fi
 173
 174 if test -n "$cf_new_cppflags" ; then
 175         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 176         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 177 fi
 178
 179 if test -n "$cf_new_extra_cppflags" ; then
 180         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 181         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 182 fi
 183
 184 AC_SUBST(EXTRA_CPPFLAGS)
 185
 186 ])dnl
 187 dnl ---------------------------------------------------------------------------
 188 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 189 dnl -------------
 190 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 191 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 192 dnl but old versions (and some misinstalled ones) need that.  To make things
 193 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 194 dnl the include-path).
 195 AC_DEFUN([CF_ADD_INCDIR],
 196 [
 197 if test -n "$1" ; then
 198   for cf_add_incdir in $1
 199   do
 200         while test $cf_add_incdir != /usr/include
 201         do
 202           if test -d $cf_add_incdir
 203           then
 204                 cf_have_incdir=no
 205                 if test -n "$CFLAGS$CPPFLAGS" ; then
 206                   # a loop is needed to ensure we can add subdirs of existing dirs
 207                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 208                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 209                           cf_have_incdir=yes; break
 210                         fi
 211                   done
 212                 fi
 213
 214                 if test "$cf_have_incdir" = no ; then
 215                   if test "$cf_add_incdir" = /usr/local/include ; then
 216                         if test "$GCC" = yes
 217                         then
 218                           cf_save_CPPFLAGS=$CPPFLAGS
 219                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 220                           AC_TRY_COMPILE([#include <stdio.h>],
 221                                   [printf("Hello")],
 222                                   [],
 223                                   [cf_have_incdir=yes])
 224                           CPPFLAGS=$cf_save_CPPFLAGS
 225                         fi
 226                   fi
 227                 fi
 228
 229                 if test "$cf_have_incdir" = no ; then
 230                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 231                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 232
 233                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 234                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 235                   cf_add_incdir="$cf_top_incdir"
 236                 else
 237                   break
 238                 fi
 239           fi
 240         done
 241   done
 242 fi
 243 ])dnl
 244 dnl ---------------------------------------------------------------------------
 245 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 246 dnl ----------
 247 dnl Add a library, used to enforce consistency.
 248 dnl
 249 dnl $1 = library to add, without the "-l"
 250 dnl $2 = variable to update (default $LIBS)
 251 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 252 dnl ---------------------------------------------------------------------------
 253 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 254 dnl -------------
 255 dnl     Adds to the library-path
 256 dnl
 257 dnl     Some machines have trouble with multiple -L options.
 258 dnl
 259 dnl $1 is the (list of) directory(s) to add
 260 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 261 dnl
 262 AC_DEFUN([CF_ADD_LIBDIR],
 263 [
 264 if test -n "$1" ; then
 265   for cf_add_libdir in $1
 266   do
 267     if test $cf_add_libdir = /usr/lib ; then
 268       :
 269     elif test -d $cf_add_libdir
 270     then
 271       cf_have_libdir=no
 272       if test -n "$LDFLAGS$LIBS" ; then
 273         # a loop is needed to ensure we can add subdirs of existing dirs
 274         for cf_test_libdir in $LDFLAGS $LIBS ; do
 275           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 276             cf_have_libdir=yes; break
 277           fi
 278         done
 279       fi
 280       if test "$cf_have_libdir" = no ; then
 281         CF_VERBOSE(adding $cf_add_libdir to library-path)
 282         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 283       fi
 284     fi
 285   done
 286 fi
 287 ])dnl
 288 dnl ---------------------------------------------------------------------------
 289 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 290 dnl -----------
 291 dnl Add one or more libraries, used to enforce consistency.
 292 dnl
 293 dnl $1 = libraries to add, with the "-l", etc.
 294 dnl $2 = variable to update (default $LIBS)
 295 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 296 dnl ---------------------------------------------------------------------------
 297 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 298 dnl ------------------
 299 dnl Append to a search-list for a nonstandard header/lib-file
 300 dnl     $1 = the variable to return as result
 301 dnl     $2 = the package name
 302 dnl     $3 = the subdirectory, e.g., bin, include or lib
 303 dnl $4 = the directory under which we will test for subdirectories
 304 dnl $5 = a directory that we do not want $4 to match
 305 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 306 [
 307 test "$4" != "$5" && \
 308 test -d "$4" && \
 309 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 310         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 311         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 312         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 313         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 314         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 315         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 316 }
 317 ])dnl
 318 dnl ---------------------------------------------------------------------------
 319 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 320 dnl --------------
 321 dnl Allow user to disable a normally-on option.
 322 AC_DEFUN([CF_ARG_DISABLE],
 323 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 324 dnl ---------------------------------------------------------------------------
 325 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 326 dnl -------------
 327 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 328 dnl values.
 329 dnl
 330 dnl Parameters:
 331 dnl $1 = option name
 332 dnl $2 = help-string
 333 dnl $3 = action to perform if option is not default
 334 dnl $4 = action if perform if option is default
 335 dnl $5 = default option value (either 'yes' or 'no')
 336 AC_DEFUN([CF_ARG_OPTION],
 337 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 338   if test "$enableval" != "$5" ; then
 339 ifelse([$3],,[    :]dnl
 340 ,[    $3]) ifelse([$4],,,[
 341   else
 342     $4])
 343   fi],[enableval=$5 ifelse([$4],,,[
 344   $4
 345 ])dnl
 346   ])])dnl
 347 dnl ---------------------------------------------------------------------------
 348 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 349 dnl -----------
 350 dnl Check for suitable "ar" (archiver) options for updating an archive.
 351 AC_DEFUN([CF_AR_FLAGS],[
 352 AC_REQUIRE([CF_PROG_AR])
 353
 354 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 355         cf_cv_ar_flags=unknown
 356         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 357         do
 358
 359                 # check if $ARFLAGS already contains this choice
 360                 if test "x$ARFLAGS" != "x" ; then
 361                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 362                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 363                                 cf_cv_ar_flags=
 364                                 break
 365                         fi
 366                 fi
 367
 368                 rm -f conftest.$ac_cv_objext
 369                 rm -f conftest.a
 370
 371                 cat >conftest.$ac_ext <<EOF
 372 #line __oline__ "configure"
 373 int     testdata[[3]] = { 123, 456, 789 };
 374 EOF
 375                 if AC_TRY_EVAL(ac_compile) ; then
 376                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 377                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 378                         if test -f conftest.a ; then
 379                                 cf_cv_ar_flags=$cf_ar_flags
 380                                 break
 381                         fi
 382                 else
 383                         CF_VERBOSE(cannot compile test-program)
 384                         break
 385                 fi
 386         done
 387         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 388 ])
 389
 390 if test -n "$ARFLAGS" ; then
 391         if test -n "$cf_cv_ar_flags" ; then
 392                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 393         fi
 394 else
 395         ARFLAGS=$cf_cv_ar_flags
 396 fi
 397
 398 AC_SUBST(ARFLAGS)
 399 ])
 400 dnl ---------------------------------------------------------------------------
 401 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 402 dnl -----------
 403 dnl If we're cross-compiling, allow the user to override the tools and their
 404 dnl options.  The configure script is oriented toward identifying the host
 405 dnl compiler, etc., but we need a build compiler to generate parts of the
 406 dnl source.
 407 dnl
 408 dnl $1 = default for $CPPFLAGS
 409 dnl $2 = default for $LIBS
 410 AC_DEFUN([CF_BUILD_CC],[
 411 CF_ACVERSION_CHECK(2.52,,
 412         [AC_REQUIRE([CF_PROG_EXT])])
 413 if test "$cross_compiling" = yes ; then
 414
 415         # defaults that we might want to override
 416         : ${BUILD_CFLAGS:=''}
 417         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 418         : ${BUILD_LDFLAGS:=''}
 419         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 420         : ${BUILD_EXEEXT:='$x'}
 421         : ${BUILD_OBJEXT:='o'}
 422
 423         AC_ARG_WITH(build-cc,
 424                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 425                 [BUILD_CC="$withval"],
 426                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 427         AC_MSG_CHECKING(for native build C compiler)
 428         AC_MSG_RESULT($BUILD_CC)
 429
 430         AC_MSG_CHECKING(for native build C preprocessor)
 431         AC_ARG_WITH(build-cpp,
 432                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 433                 [BUILD_CPP="$withval"],
 434                 [BUILD_CPP='${BUILD_CC} -E'])
 435         AC_MSG_RESULT($BUILD_CPP)
 436
 437         AC_MSG_CHECKING(for native build C flags)
 438         AC_ARG_WITH(build-cflags,
 439                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 440                 [BUILD_CFLAGS="$withval"])
 441         AC_MSG_RESULT($BUILD_CFLAGS)
 442
 443         AC_MSG_CHECKING(for native build C preprocessor-flags)
 444         AC_ARG_WITH(build-cppflags,
 445                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 446                 [BUILD_CPPFLAGS="$withval"])
 447         AC_MSG_RESULT($BUILD_CPPFLAGS)
 448
 449         AC_MSG_CHECKING(for native build linker-flags)
 450         AC_ARG_WITH(build-ldflags,
 451                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 452                 [BUILD_LDFLAGS="$withval"])
 453         AC_MSG_RESULT($BUILD_LDFLAGS)
 454
 455         AC_MSG_CHECKING(for native build linker-libraries)
 456         AC_ARG_WITH(build-libs,
 457                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 458                 [BUILD_LIBS="$withval"])
 459         AC_MSG_RESULT($BUILD_LIBS)
 460
 461         # this assumes we're on Unix.
 462         BUILD_EXEEXT=
 463         BUILD_OBJEXT=o
 464
 465         : ${BUILD_CC:='${CC}'}
 466
 467         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 468                 AC_MSG_ERROR([Cross-build requires two compilers.
 469 Use --with-build-cc to specify the native compiler.])
 470         fi
 471
 472 else
 473         : ${BUILD_CC:='${CC}'}
 474         : ${BUILD_CPP:='${CPP}'}
 475         : ${BUILD_CFLAGS:='${CFLAGS}'}
 476         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 477         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 478         : ${BUILD_LIBS:='${LIBS}'}
 479         : ${BUILD_EXEEXT:='$x'}
 480         : ${BUILD_OBJEXT:='o'}
 481 fi
 482
 483 AC_SUBST(BUILD_CC)
 484 AC_SUBST(BUILD_CPP)
 485 AC_SUBST(BUILD_CFLAGS)
 486 AC_SUBST(BUILD_CPPFLAGS)
 487 AC_SUBST(BUILD_LDFLAGS)
 488 AC_SUBST(BUILD_LIBS)
 489 AC_SUBST(BUILD_EXEEXT)
 490 AC_SUBST(BUILD_OBJEXT)
 491 ])dnl
 492 dnl ---------------------------------------------------------------------------
 493 dnl CF_CC_ENV_FLAGS version: 1 updated: 2012/10/03 05:25:49
 494 dnl ---------------
 495 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 496 dnl into CC.  This will not help with broken scripts that wrap the compiler with
 497 dnl options, but eliminates a more common category of user confusion.
 498 AC_DEFUN([CF_CC_ENV_FLAGS],
 499 [
 500 # This should have been defined by AC_PROG_CC
 501 : ${CC:=cc}
 502
 503 AC_MSG_CHECKING(\$CC variable)
 504 case "$CC" in #(vi
 505 *[[\ \  ]]-[[IUD]]*)
 506         AC_MSG_RESULT(broken)
 507         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 508         # humor him...
 509         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 510         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 511         CF_ADD_CFLAGS($cf_flags)
 512         ;;
 513 *)
 514         AC_MSG_RESULT(ok)
 515         ;;
 516 esac
 517 ])dnl
 518 dnl ---------------------------------------------------------------------------
 519 dnl CF_CFG_DEFAULTS version: 9 updated: 2013/04/13 18:58:32
 520 dnl ---------------
 521 dnl Determine the default configuration into which we'll install ncurses.  This
 522 dnl can be overridden by the user's command-line options.  There's two items to
 523 dnl look for:
 524 dnl     1. the prefix (e.g., /usr)
 525 dnl     2. the header files (e.g., /usr/include/ncurses)
 526 dnl We'll look for a previous installation of ncurses and use the same defaults.
 527 dnl
 528 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 529 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 530 dnl programs from a vendor's.
 531 AC_DEFUN([CF_CFG_DEFAULTS],
 532 [
 533 AC_MSG_CHECKING(for prefix)
 534 if test "x$prefix" = "xNONE" ; then
 535         case "$cf_cv_system_name" in
 536                 # non-vendor systems don't have a conflict
 537         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|k*bsd*-gnu|mingw*)
 538                 prefix=/usr
 539                 ;;
 540         *)      prefix=$ac_default_prefix
 541                 ;;
 542         esac
 543 fi
 544 AC_MSG_RESULT($prefix)
 545
 546 if test "x$prefix" = "xNONE" ; then
 547 AC_MSG_CHECKING(for default include-directory)
 548 test -n "$verbose" && echo 1>&AC_FD_MSG
 549 for cf_symbol in \
 550         $includedir \
 551         $includedir/ncurses \
 552         $prefix/include \
 553         $prefix/include/ncurses \
 554         /usr/local/include \
 555         /usr/local/include/ncurses \
 556         /usr/include \
 557         /usr/include/ncurses
 558 do
 559         cf_dir=`eval echo $cf_symbol`
 560         if test -f $cf_dir/curses.h ; then
 561         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 562                 includedir="$cf_symbol"
 563                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 564                 break
 565         fi
 566         fi
 567         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 568 done
 569 AC_MSG_RESULT($includedir)
 570 fi
 571 ])dnl
 572 dnl ---------------------------------------------------------------------------
 573 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 574 dnl --------------
 575 dnl Check if we're accidentally using a cache from a different machine.
 576 dnl Derive the system name, as a check for reusing the autoconf cache.
 577 dnl
 578 dnl If we've packaged config.guess and config.sub, run that (since it does a
 579 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 580 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 581 dnl which is useful in cross-compiles.
 582 dnl
 583 dnl Note: we would use $ac_config_sub, but that is one of the places where
 584 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 585 AC_DEFUN([CF_CHECK_CACHE],
 586 [
 587 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 588         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 589         system_name="$host_os"
 590 else
 591         system_name="`(uname -s -r) 2>/dev/null`"
 592         if test -z "$system_name" ; then
 593                 system_name="`(hostname) 2>/dev/null`"
 594         fi
 595 fi
 596 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 597 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 598
 599 test -z "$system_name" && system_name="$cf_cv_system_name"
 600 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 601
 602 if test ".$system_name" != ".$cf_cv_system_name" ; then
 603         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 604         AC_MSG_ERROR("Please remove config.cache and try again.")
 605 fi
 606 ])dnl
 607 dnl ---------------------------------------------------------------------------
 608 dnl CF_CLANG_COMPILER version: 1 updated: 2012/06/16 14:55:39
 609 dnl -----------------
 610 dnl Check if the given compiler is really clang.  clang's C driver defines
 611 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 612 dnl not ignore some gcc options.
 613 dnl
 614 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 615 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 616 dnl the wrappers for gcc and g++ warnings.
 617 dnl
 618 dnl $1 = GCC (default) or GXX
 619 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
 620 dnl $3 = CFLAGS (default) or CXXFLAGS
 621 AC_DEFUN([CF_CLANG_COMPILER],[
 622 ifelse([$2],,CLANG_COMPILER,[$2])=no
 623
 624 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 625         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 626         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 627         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 628         AC_TRY_COMPILE([],[
 629 #ifdef __clang__
 630 #else
 631 make an error
 632 #endif
 633 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 634 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
 635 ],[])
 636         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 637         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 638 fi
 639 ])
 640 dnl ---------------------------------------------------------------------------
 641 dnl CF_CURSES_HEADER version: 3 updated: 2011/05/01 19:47:45
 642 dnl ----------------
 643 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 644 dnl variations of ncurses' installs.
 645 dnl
 646 dnl $1 = ncurses when looking for ncurses, or is empty
 647 AC_DEFUN([CF_CURSES_HEADER],[
 648 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 649 cf_cv_ncurses_header=none
 650 for cf_header in ifelse($1,,,[ \
 651     $1/ncurses.h \
 652         $1/curses.h]) \
 653         ncurses.h \
 654         curses.h ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 655 do
 656 AC_TRY_COMPILE([#include <${cf_header}>],
 657         [initscr(); tgoto("?", 0,0)],
 658         [cf_cv_ncurses_header=$cf_header; break],[])
 659 done
 660 ])
 661
 662 if test "$cf_cv_ncurses_header" = none ; then
 663         AC_MSG_ERROR(No curses header-files found)
 664 fi
 665
 666 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 667 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 668 ])dnl
 669 dnl ---------------------------------------------------------------------------
 670 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
 671 dnl ----------
 672 dnl "dirname" is not portable, so we fake it with a shell script.
 673 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
 674 dnl ---------------------------------------------------------------------------
 675 dnl CF_DISABLE_ECHO version: 12 updated: 2012/10/06 16:30:28
 676 dnl ---------------
 677 dnl You can always use "make -n" to see the actual options, but it's hard to
 678 dnl pick out/analyze warning messages when the compile-line is long.
 679 dnl
 680 dnl Sets:
 681 dnl     ECHO_LT - symbol to control if libtool is verbose
 682 dnl     ECHO_LD - symbol to prefix "cc -o" lines
 683 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
 684 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
 685 dnl     ECHO_CC - symbol to put before any "cc" line
 686 dnl
 687 AC_DEFUN([CF_DISABLE_ECHO],[
 688 AC_MSG_CHECKING(if you want to see long compiling messages)
 689 CF_ARG_DISABLE(echo,
 690         [  --disable-echo          do not display "compiling" commands],
 691         [
 692     ECHO_LT='--silent'
 693     ECHO_LD='@echo linking [$]@;'
 694     RULE_CC='@echo compiling [$]<'
 695     SHOW_CC='@echo compiling [$]@'
 696     ECHO_CC='@'
 697 ],[
 698     ECHO_LT=''
 699     ECHO_LD=''
 700     RULE_CC=''
 701     SHOW_CC=''
 702     ECHO_CC=''
 703 ])
 704 AC_MSG_RESULT($enableval)
 705 AC_SUBST(ECHO_LT)
 706 AC_SUBST(ECHO_LD)
 707 AC_SUBST(RULE_CC)
 708 AC_SUBST(SHOW_CC)
 709 AC_SUBST(ECHO_CC)
 710 ])dnl
 711 dnl ---------------------------------------------------------------------------
 712 dnl CF_ENABLE_PC_FILES version: 9 updated: 2012/08/04 13:59:54
 713 dnl ------------------
 714 dnl This is the "--enable-pc-files" option, which is available if there is a
 715 dnl pkg-config configuration on the local machine.
 716 AC_DEFUN([CF_ENABLE_PC_FILES],[
 717 AC_REQUIRE([CF_PKG_CONFIG])
 718 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
 719
 720 if test "$PKG_CONFIG" != none ; then
 721         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
 722         AC_ARG_ENABLE(pc-files,
 723                 [  --enable-pc-files       generate and install .pc files for pkg-config],
 724                 [enable_pc_files=$enableval],
 725                 [enable_pc_files=no])
 726         AC_MSG_RESULT($enable_pc_files)
 727         if test "$enable_pc_files" != no
 728         then
 729                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
 730         fi
 731 else
 732         enable_pc_files=no
 733 fi
 734 ])dnl
 735 dnl ---------------------------------------------------------------------------
 736 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
 737 dnl ---------------
 738 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
 739 dnl prefer a standard location, and use -L options only if we do not find the
 740 dnl library in the standard library location(s).
 741 dnl     $1 = library name
 742 dnl     $2 = library class, usually the same as library name
 743 dnl     $3 = includes
 744 dnl     $4 = code fragment to compile/link
 745 dnl     $5 = corresponding function-name
 746 dnl     $6 = flag, nonnull if failure should not cause an error-exit
 747 dnl
 748 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
 749 dnl to use a -L option.
 750 AC_DEFUN([CF_FIND_LIBRARY],
 751 [
 752         eval 'cf_cv_have_lib_'$1'=no'
 753         cf_libdir=""
 754         AC_CHECK_FUNC($5,
 755                 eval 'cf_cv_have_lib_'$1'=yes',[
 756                 cf_save_LIBS="$LIBS"
 757                 AC_MSG_CHECKING(for $5 in -l$1)
 758                 LIBS="-l$1 $LIBS"
 759                 AC_TRY_LINK([$3],[$4],
 760                         [AC_MSG_RESULT(yes)
 761                          eval 'cf_cv_have_lib_'$1'=yes'
 762                         ],
 763                         [AC_MSG_RESULT(no)
 764                         CF_LIBRARY_PATH(cf_search,$2)
 765                         for cf_libdir in $cf_search
 766                         do
 767                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
 768                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
 769                                 AC_TRY_LINK([$3],[$4],
 770                                         [AC_MSG_RESULT(yes)
 771                                          eval 'cf_cv_have_lib_'$1'=yes'
 772                                          break],
 773                                         [AC_MSG_RESULT(no)
 774                                          LIBS="$cf_save_LIBS"])
 775                         done
 776                         ])
 777                 ])
 778 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
 779 ifelse($6,,[
 780 if test $cf_found_library = no ; then
 781         AC_MSG_ERROR(Cannot link $1 library)
 782 fi
 783 ])
 784 ])dnl
 785 dnl ---------------------------------------------------------------------------
 786 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
 787 dnl ---------------
 788 dnl Find a library (specifically the linkage used in the code fragment),
 789 dnl searching for it if it is not already in the library path.
 790 dnl See also CF_ADD_SEARCHPATH.
 791 dnl
 792 dnl Parameters (4-on are optional):
 793 dnl     $1 = headers for library entrypoint
 794 dnl     $2 = code fragment for library entrypoint
 795 dnl     $3 = the library name without the "-l" option or ".so" suffix.
 796 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
 797 dnl     $5 = action to perform if not successful
 798 dnl     $6 = module name, if not the same as the library name
 799 dnl     $7 = extra libraries
 800 dnl
 801 dnl Sets these variables:
 802 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
 803 dnl     $cf_cv_header_path_$3 - include-directory if needed
 804 dnl     $cf_cv_library_path_$3 - library-directory if needed
 805 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
 806 AC_DEFUN([CF_FIND_LINKAGE],[
 807
 808 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
 809 # will be set on completion of the AC_TRY_LINK below.
 810 cf_cv_header_path_$3=
 811 cf_cv_library_path_$3=
 812
 813 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
 814
 815 cf_save_LIBS="$LIBS"
 816
 817 AC_TRY_LINK([$1],[$2],[
 818         cf_cv_find_linkage_$3=yes
 819         cf_cv_header_path_$3=/usr/include
 820         cf_cv_library_path_$3=/usr/lib
 821 ],[
 822
 823 LIBS="-l$3 $7 $cf_save_LIBS"
 824
 825 AC_TRY_LINK([$1],[$2],[
 826         cf_cv_find_linkage_$3=yes
 827         cf_cv_header_path_$3=/usr/include
 828         cf_cv_library_path_$3=/usr/lib
 829         cf_cv_library_file_$3="-l$3"
 830 ],[
 831         cf_cv_find_linkage_$3=no
 832         LIBS="$cf_save_LIBS"
 833
 834     CF_VERBOSE(find linkage for $3 library)
 835     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
 836
 837     cf_save_CPPFLAGS="$CPPFLAGS"
 838     cf_test_CPPFLAGS="$CPPFLAGS"
 839
 840     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
 841     for cf_cv_header_path_$3 in $cf_search
 842     do
 843       if test -d $cf_cv_header_path_$3 ; then
 844         CF_VERBOSE(... testing $cf_cv_header_path_$3)
 845         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
 846         AC_TRY_COMPILE([$1],[$2],[
 847             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
 848             cf_cv_find_linkage_$3=maybe
 849             cf_test_CPPFLAGS="$CPPFLAGS"
 850             break],[
 851             CPPFLAGS="$cf_save_CPPFLAGS"
 852             ])
 853       fi
 854     done
 855
 856     if test "$cf_cv_find_linkage_$3" = maybe ; then
 857
 858       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
 859
 860       cf_save_LIBS="$LIBS"
 861       cf_save_LDFLAGS="$LDFLAGS"
 862
 863       ifelse([$6],,,[
 864         CPPFLAGS="$cf_test_CPPFLAGS"
 865         LIBS="-l$3 $7 $cf_save_LIBS"
 866         AC_TRY_LINK([$1],[$2],[
 867             CF_VERBOSE(... found $3 library in system)
 868             cf_cv_find_linkage_$3=yes])
 869             CPPFLAGS="$cf_save_CPPFLAGS"
 870             LIBS="$cf_save_LIBS"
 871             ])
 872
 873       if test "$cf_cv_find_linkage_$3" != yes ; then
 874         CF_LIBRARY_PATH(cf_search,$3)
 875         for cf_cv_library_path_$3 in $cf_search
 876         do
 877           if test -d $cf_cv_library_path_$3 ; then
 878             CF_VERBOSE(... testing $cf_cv_library_path_$3)
 879             CPPFLAGS="$cf_test_CPPFLAGS"
 880             LIBS="-l$3 $7 $cf_save_LIBS"
 881             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
 882             AC_TRY_LINK([$1],[$2],[
 883                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
 884                 cf_cv_find_linkage_$3=yes
 885                 cf_cv_library_file_$3="-l$3"
 886                 break],[
 887                 CPPFLAGS="$cf_save_CPPFLAGS"
 888                 LIBS="$cf_save_LIBS"
 889                 LDFLAGS="$cf_save_LDFLAGS"
 890                 ])
 891           fi
 892         done
 893         CPPFLAGS="$cf_save_CPPFLAGS"
 894         LDFLAGS="$cf_save_LDFLAGS"
 895       fi
 896
 897     else
 898       cf_cv_find_linkage_$3=no
 899     fi
 900     ],$7)
 901 ])
 902
 903 LIBS="$cf_save_LIBS"
 904
 905 if test "$cf_cv_find_linkage_$3" = yes ; then
 906 ifelse([$4],,[
 907         CF_ADD_INCDIR($cf_cv_header_path_$3)
 908         CF_ADD_LIBDIR($cf_cv_library_path_$3)
 909         CF_ADD_LIB($3)
 910 ],[$4])
 911 else
 912 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
 913 fi
 914 ])dnl
 915 dnl ---------------------------------------------------------------------------
 916 dnl CF_FIXUP_ADAFLAGS version: 1 updated: 2012/03/31 18:48:10
 917 dnl -----------------
 918 dnl make ADAFLAGS consistent with CFLAGS
 919 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
 920         AC_MSG_CHECKING(optimization options for ADAFLAGS)
 921         case "$CFLAGS" in
 922         *-g*)
 923                 CF_ADD_ADAFLAGS(-g)
 924                 ;;
 925         esac
 926         case "$CFLAGS" in
 927         *-O*)
 928                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
 929                 CF_ADD_ADAFLAGS($cf_O_flag)
 930                 ;;
 931         esac
 932         AC_MSG_RESULT($ADAFLAGS)
 933 ])dnl
 934 dnl ---------------------------------------------------------------------------
 935 dnl CF_GCC_ATTRIBUTES version: 16 updated: 2012/10/02 20:55:03
 936 dnl -----------------
 937 dnl Test for availability of useful gcc __attribute__ directives to quiet
 938 dnl compiler warnings.  Though useful, not all are supported -- and contrary
 939 dnl to documentation, unrecognized directives cause older compilers to barf.
 940 AC_DEFUN([CF_GCC_ATTRIBUTES],
 941 [
 942 if test "$GCC" = yes
 943 then
 944 cat > conftest.i <<EOF
 945 #ifndef GCC_PRINTF
 946 #define GCC_PRINTF 0
 947 #endif
 948 #ifndef GCC_SCANF
 949 #define GCC_SCANF 0
 950 #endif
 951 #ifndef GCC_NORETURN
 952 #define GCC_NORETURN /* nothing */
 953 #endif
 954 #ifndef GCC_UNUSED
 955 #define GCC_UNUSED /* nothing */
 956 #endif
 957 EOF
 958 if test "$GCC" = yes
 959 then
 960         AC_CHECKING([for $CC __attribute__ directives])
 961 cat > conftest.$ac_ext <<EOF
 962 #line __oline__ "${as_me:-configure}"
 963 #include "confdefs.h"
 964 #include "conftest.h"
 965 #include "conftest.i"
 966 #if     GCC_PRINTF
 967 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
 968 #else
 969 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
 970 #endif
 971 #if     GCC_SCANF
 972 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
 973 #else
 974 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
 975 #endif
 976 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
 977 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
 978 extern void foo(void) GCC_NORETURN;
 979 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
 980 EOF
 981         cf_printf_attribute=no
 982         cf_scanf_attribute=no
 983         for cf_attribute in scanf printf unused noreturn
 984         do
 985                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
 986                 cf_directive="__attribute__(($cf_attribute))"
 987                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
 988
 989                 case $cf_attribute in #(vi
 990                 printf) #(vi
 991                         cf_printf_attribute=yes
 992                         cat >conftest.h <<EOF
 993 #define GCC_$cf_ATTRIBUTE 1
 994 EOF
 995                         ;;
 996                 scanf) #(vi
 997                         cf_scanf_attribute=yes
 998                         cat >conftest.h <<EOF
 999 #define GCC_$cf_ATTRIBUTE 1
1000 EOF
1001                         ;;
1002                 *) #(vi
1003                         cat >conftest.h <<EOF
1004 #define GCC_$cf_ATTRIBUTE $cf_directive
1005 EOF
1006                         ;;
1007                 esac
1008
1009                 if AC_TRY_EVAL(ac_compile); then
1010                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1011                         cat conftest.h >>confdefs.h
1012                         case $cf_attribute in #(vi
1013                         noreturn) #(vi
1014                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1015                                 ;;
1016                         printf) #(vi
1017                                 cf_value='/* nothing */'
1018                                 if test "$cf_printf_attribute" != no ; then
1019                                         cf_value='__attribute__((format(printf,fmt,var)))'
1020                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1021                                 fi
1022                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1023                                 ;;
1024                         scanf) #(vi
1025                                 cf_value='/* nothing */'
1026                                 if test "$cf_scanf_attribute" != no ; then
1027                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1028                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1029                                 fi
1030                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1031                                 ;;
1032                         unused) #(vi
1033                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1034                                 ;;
1035                         esac
1036                 fi
1037         done
1038 else
1039         fgrep define conftest.i >>confdefs.h
1040 fi
1041 rm -rf conftest*
1042 fi
1043 ])dnl
1044 dnl ---------------------------------------------------------------------------
1045 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1046 dnl --------------
1047 dnl Find version of gcc
1048 AC_DEFUN([CF_GCC_VERSION],[
1049 AC_REQUIRE([AC_PROG_CC])
1050 GCC_VERSION=none
1051 if test "$GCC" = yes ; then
1052         AC_MSG_CHECKING(version of $CC)
1053         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1054         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1055         AC_MSG_RESULT($GCC_VERSION)
1056 fi
1057 ])dnl
1058 dnl ---------------------------------------------------------------------------
1059 dnl CF_GCC_WARNINGS version: 29 updated: 2012/06/16 14:55:39
1060 dnl ---------------
1061 dnl Check if the compiler supports useful warning options.  There's a few that
1062 dnl we don't use, simply because they're too noisy:
1063 dnl
1064 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1065 dnl     -Wredundant-decls (system headers make this too noisy)
1066 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1067 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1068 dnl             is enabled for ncurses using "--enable-const".
1069 dnl     -pedantic
1070 dnl
1071 dnl Parameter:
1072 dnl     $1 is an optional list of gcc warning flags that a particular
1073 dnl             application might want to use, e.g., "no-unused" for
1074 dnl             -Wno-unused
1075 dnl Special:
1076 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1077 dnl
1078 AC_DEFUN([CF_GCC_WARNINGS],
1079 [
1080 AC_REQUIRE([CF_GCC_VERSION])
1081 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1082 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1083
1084 cat > conftest.$ac_ext <<EOF
1085 #line __oline__ "${as_me:-configure}"
1086 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1087 EOF
1088
1089 if test "$INTEL_COMPILER" = yes
1090 then
1091 # The "-wdXXX" options suppress warnings:
1092 # remark #1419: external declaration in primary source file
1093 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1094 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1095 # remark #193: zero used for undefined preprocessing identifier
1096 # remark #593: variable "curs_sb_left_arrow" was set but never used
1097 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1098 # remark #869: parameter "tw" was never referenced
1099 # remark #981: operands are evaluated in unspecified order
1100 # warning #279: controlling expression is constant
1101
1102         AC_CHECKING([for $CC warning options])
1103         cf_save_CFLAGS="$CFLAGS"
1104         EXTRA_CFLAGS="-Wall"
1105         for cf_opt in \
1106                 wd1419 \
1107                 wd1683 \
1108                 wd1684 \
1109                 wd193 \
1110                 wd593 \
1111                 wd279 \
1112                 wd810 \
1113                 wd869 \
1114                 wd981
1115         do
1116                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1117                 if AC_TRY_EVAL(ac_compile); then
1118                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1119                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1120                 fi
1121         done
1122         CFLAGS="$cf_save_CFLAGS"
1123
1124 elif test "$GCC" = yes
1125 then
1126         AC_CHECKING([for $CC warning options])
1127         cf_save_CFLAGS="$CFLAGS"
1128         EXTRA_CFLAGS=
1129         cf_warn_CONST=""
1130         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1131         for cf_opt in W Wall \
1132                 Wbad-function-cast \
1133                 Wcast-align \
1134                 Wcast-qual \
1135                 Winline \
1136                 Wmissing-declarations \
1137                 Wmissing-prototypes \
1138                 Wnested-externs \
1139                 Wpointer-arith \
1140                 Wshadow \
1141                 Wstrict-prototypes \
1142                 Wundef $cf_warn_CONST $1
1143         do
1144                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1145                 if AC_TRY_EVAL(ac_compile); then
1146                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1147                         case $cf_opt in #(vi
1148                         Wcast-qual) #(vi
1149                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1150                                 ;;
1151                         Winline) #(vi
1152                                 case $GCC_VERSION in
1153                                 [[34]].*)
1154                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1155                                         continue;;
1156                                 esac
1157                                 ;;
1158                         Wpointer-arith) #(vi
1159                                 case $GCC_VERSION in
1160                                 [[12]].*)
1161                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1162                                         continue;;
1163                                 esac
1164                                 ;;
1165                         esac
1166                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1167                 fi
1168         done
1169         CFLAGS="$cf_save_CFLAGS"
1170 fi
1171 rm -rf conftest*
1172
1173 AC_SUBST(EXTRA_CFLAGS)
1174 ])dnl
1175 dnl ---------------------------------------------------------------------------
1176 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
1177 dnl ----------------
1178 AC_DEFUN([CF_GNAT_GENERICS],
1179 [
1180 AC_REQUIRE([CF_GNAT_VERSION])
1181
1182 AC_MSG_CHECKING(if GNAT supports generics)
1183 case $cf_gnat_version in #(vi
1184 3.[[1-9]]*|[[4-9]].*) #(vi
1185         cf_gnat_generics=yes
1186         ;;
1187 *)
1188         cf_gnat_generics=no
1189         ;;
1190 esac
1191 AC_MSG_RESULT($cf_gnat_generics)
1192
1193 if test "$cf_gnat_generics" = yes
1194 then
1195         cf_compile_generics=generics
1196         cf_generic_objects="\${GENOBJS}"
1197 else
1198         cf_compile_generics=
1199         cf_generic_objects=
1200 fi
1201
1202 AC_SUBST(cf_compile_generics)
1203 AC_SUBST(cf_generic_objects)
1204 ])dnl
1205 dnl ---------------------------------------------------------------------------
1206 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
1207 dnl --------------------
1208 dnl Check if the gnat pragma "Unreferenced" works.
1209 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
1210 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
1211 CF_GNAT_TRY_LINK([procedure conftest;],
1212 [with Text_IO;
1213 with GNAT.OS_Lib;
1214 procedure conftest is
1215    test : Integer;
1216    pragma Unreferenced (test);
1217 begin
1218    test := 1;
1219    Text_IO.Put ("Hello World");
1220    Text_IO.New_Line;
1221    GNAT.OS_Lib.OS_Exit (0);
1222 end conftest;],
1223         [cf_cv_pragma_unreferenced=yes],
1224         [cf_cv_pragma_unreferenced=no])])
1225
1226 # if the pragma is supported, use it (needed in the Trace code).
1227 if test $cf_cv_pragma_unreferenced = yes ; then
1228         PRAGMA_UNREF=TRUE
1229 else
1230         PRAGMA_UNREF=FALSE
1231 fi
1232 AC_SUBST(PRAGMA_UNREF)
1233 ])dnl
1234 dnl ---------------------------------------------------------------------------
1235 dnl CF_GNAT_PROJECTS version: 2 updated: 2011/03/23 20:24:41
1236 dnl ----------------
1237 dnl GNAT projects are configured with ".gpr" project files.
1238 dnl GNAT libraries are a further development, using the project feature.
1239 AC_DEFUN([CF_GNAT_PROJECTS],
1240 [
1241 AC_REQUIRE([CF_GNAT_VERSION])
1242
1243 cf_gnat_libraries=no
1244 cf_gnat_projects=no
1245
1246 AC_MSG_CHECKING(if GNAT supports project files)
1247 case $cf_gnat_version in #(vi
1248 3.[[0-9]]*) #(vi
1249         ;;
1250 *)
1251         case $cf_cv_system_name in #(vi
1252         cygwin*) #(vi
1253                 ;;
1254         *)
1255                 mkdir conftest.src conftest.bin conftest.lib
1256                 cd conftest.src
1257                 rm -rf conftest* *~conftest*
1258                 cat >>library.gpr <<CF_EOF
1259 project Library is
1260   Kind := External ("LIB_KIND");
1261   for Library_Name use "ConfTest";
1262   for Object_Dir use ".";
1263   for Library_ALI_Dir use External("LIBRARY_DIR");
1264   for Library_Version use External ("SONAME");
1265   for Library_Kind use Kind;
1266   for Library_Dir use External("BUILD_DIR");
1267   Source_Dir := External ("SOURCE_DIR");
1268   for Source_Dirs use (Source_Dir);
1269   package Compiler is
1270      for Default_Switches ("Ada") use
1271        ("-g",
1272         "-O2",
1273         "-gnatafno",
1274         "-gnatVa",   -- All validity checks
1275         "-gnatwa");  -- Activate all optional errors
1276   end Compiler;
1277 end Library;
1278 CF_EOF
1279                 cat >>confpackage.ads <<CF_EOF
1280 package ConfPackage is
1281    procedure conftest;
1282 end ConfPackage;
1283 CF_EOF
1284                 cat >>confpackage.adb <<CF_EOF
1285 with Text_IO;
1286 package body ConfPackage is
1287    procedure conftest is
1288    begin
1289       Text_IO.Put ("Hello World");
1290       Text_IO.New_Line;
1291    end conftest;
1292 end ConfPackage;
1293 CF_EOF
1294                 if ( $cf_ada_make $ADAFLAGS \
1295                                 -Plibrary.gpr \
1296                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
1297                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
1298                                 -XSOURCE_DIR=`pwd` \
1299                                 -XSONAME=libConfTest.so.1 \
1300                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1301                         cf_gnat_projects=yes
1302                 fi
1303                 cd ..
1304                 if test -f conftest.lib/confpackage.ali
1305                 then
1306                         cf_gnat_libraries=yes
1307                 fi
1308                 rm -rf conftest* *~conftest*
1309                 ;;
1310         esac
1311         ;;
1312 esac
1313 AC_MSG_RESULT($cf_gnat_projects)
1314
1315 if test $cf_gnat_projects = yes
1316 then
1317         AC_MSG_CHECKING(if GNAT supports libraries)
1318         AC_MSG_RESULT($cf_gnat_libraries)
1319 fi
1320
1321 if test "$cf_gnat_projects" = yes
1322 then
1323         USE_OLD_MAKERULES="#"
1324         USE_GNAT_PROJECTS=""
1325 else
1326         USE_OLD_MAKERULES=""
1327         USE_GNAT_PROJECTS="#"
1328 fi
1329
1330 if test "$cf_gnat_libraries" = yes
1331 then
1332         USE_GNAT_LIBRARIES=""
1333 else
1334         USE_GNAT_LIBRARIES="#"
1335 fi
1336
1337 AC_SUBST(USE_OLD_MAKERULES)
1338 AC_SUBST(USE_GNAT_PROJECTS)
1339 AC_SUBST(USE_GNAT_LIBRARIES)
1340 ])dnl
1341 dnl ---------------------------------------------------------------------------
1342 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
1343 dnl --------------
1344 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1345 dnl is noted that gnat may compile a tasking unit even for configurations which
1346 dnl fail at runtime.
1347 AC_DEFUN([CF_GNAT_SIGINT],[
1348 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1349 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1350
1351 package ConfTest is
1352
1353    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1354    pragma Unreserve_All_Interrupts;
1355    pragma Warnings (On);
1356
1357    protected Process is
1358       procedure Stop;
1359       function Continue return Boolean;
1360       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1361    private
1362       Done : Boolean := False;
1363    end Process;
1364
1365 end ConfTest;],
1366 [package body ConfTest is
1367    protected body Process is
1368       procedure Stop is
1369       begin
1370          Done := True;
1371       end Stop;
1372       function Continue return Boolean is
1373       begin
1374          return not Done;
1375       end Continue;
1376    end Process;
1377 end ConfTest;],
1378         [cf_cv_gnat_sigint=yes],
1379         [cf_cv_gnat_sigint=no])])
1380
1381 if test $cf_cv_gnat_sigint = yes ; then
1382         USE_GNAT_SIGINT=""
1383 else
1384         USE_GNAT_SIGINT="#"
1385 fi
1386 AC_SUBST(USE_GNAT_SIGINT)
1387 ])dnl
1388 dnl ---------------------------------------------------------------------------
1389 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
1390 dnl ----------------
1391 dnl Verify that a test program compiles/links with GNAT.
1392 dnl $cf_ada_make is set to the program that compiles/links
1393 dnl $ADAFLAGS may be set to the GNAT flags.
1394 dnl
1395 dnl $1 is the text of the spec
1396 dnl $2 is the text of the body
1397 dnl $3 is the shell command to execute if successful
1398 dnl $4 is the shell command to execute if not successful
1399 AC_DEFUN([CF_GNAT_TRY_LINK],
1400 [
1401 rm -rf conftest* *~conftest*
1402 cat >>conftest.ads <<CF_EOF
1403 $1
1404 CF_EOF
1405 cat >>conftest.adb <<CF_EOF
1406 $2
1407 CF_EOF
1408 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1409 ifelse($3,,      :,[      $3])
1410 ifelse($4,,,[else
1411    $4])
1412 fi
1413 rm -rf conftest* *~conftest*
1414 ])dnl
1415 dnl ---------------------------------------------------------------------------
1416 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
1417 dnl ---------------
1418 dnl Verify that a test program compiles and runs with GNAT
1419 dnl $cf_ada_make is set to the program that compiles/links
1420 dnl $ADAFLAGS may be set to the GNAT flags.
1421 dnl
1422 dnl $1 is the text of the spec
1423 dnl $2 is the text of the body
1424 dnl $3 is the shell command to execute if successful
1425 dnl $4 is the shell command to execute if not successful
1426 AC_DEFUN([CF_GNAT_TRY_RUN],
1427 [
1428 rm -rf conftest* *~conftest*
1429 cat >>conftest.ads <<CF_EOF
1430 $1
1431 CF_EOF
1432 cat >>conftest.adb <<CF_EOF
1433 $2
1434 CF_EOF
1435 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1436    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1437 ifelse($3,,      :,[      $3])
1438 ifelse($4,,,[   else
1439       $4])
1440    fi
1441 ifelse($4,,,[else
1442    $4])
1443 fi
1444 rm -rf conftest* *~conftest*
1445 ])dnl
1446 dnl ---------------------------------------------------------------------------
1447 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
1448 dnl ---------------
1449 dnl Verify version of GNAT.
1450 AC_DEFUN([CF_GNAT_VERSION],
1451 [
1452 AC_MSG_CHECKING(for gnat version)
1453 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
1454         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1455     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1456 AC_MSG_RESULT($cf_gnat_version)
1457
1458 case $cf_gnat_version in #(vi
1459 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
1460         cf_cv_prog_gnat_correct=yes
1461         ;;
1462 *)
1463         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1464         cf_cv_prog_gnat_correct=no
1465         ;;
1466 esac
1467 ])
1468 dnl ---------------------------------------------------------------------------
1469 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
1470 dnl -------------
1471 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1472 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1473 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1474 dnl since it is interwoven with GNU extensions.
1475 dnl
1476 dnl Well, yes we could work around it...
1477 AC_DEFUN([CF_GNU_SOURCE],
1478 [
1479 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1480 AC_TRY_COMPILE([#include <sys/types.h>],[
1481 #ifndef _XOPEN_SOURCE
1482 make an error
1483 #endif],
1484         [cf_cv_gnu_source=no],
1485         [cf_save="$CPPFLAGS"
1486          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1487          AC_TRY_COMPILE([#include <sys/types.h>],[
1488 #ifdef _XOPEN_SOURCE
1489 make an error
1490 #endif],
1491         [cf_cv_gnu_source=no],
1492         [cf_cv_gnu_source=yes])
1493         CPPFLAGS="$cf_save"
1494         ])
1495 ])
1496 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1497 ])dnl
1498 dnl ---------------------------------------------------------------------------
1499 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
1500 dnl --------------
1501 dnl Construct a search-list of directories for a nonstandard header-file
1502 dnl
1503 dnl Parameters
1504 dnl     $1 = the variable to return as result
1505 dnl     $2 = the package name
1506 AC_DEFUN([CF_HEADER_PATH],
1507 [
1508 $1=
1509
1510 # collect the current set of include-directories from compiler flags
1511 cf_header_path_list=""
1512 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1513         for cf_header_path in $CPPFLAGS $CFLAGS
1514         do
1515                 case $cf_header_path in #(vi
1516                 -I*)
1517                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1518                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1519                         cf_header_path_list="$cf_header_path_list [$]$1"
1520                         ;;
1521                 esac
1522         done
1523 fi
1524
1525 # add the variations for the package we are looking for
1526 CF_SUBDIR_PATH($1,$2,include)
1527
1528 test "$includedir" != NONE && \
1529 test "$includedir" != "/usr/include" && \
1530 test -d "$includedir" && {
1531         test -d $includedir &&    $1="[$]$1 $includedir"
1532         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1533 }
1534
1535 test "$oldincludedir" != NONE && \
1536 test "$oldincludedir" != "/usr/include" && \
1537 test -d "$oldincludedir" && {
1538         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1539         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1540 }
1541
1542 $1="[$]$1 $cf_header_path_list"
1543 ])dnl
1544 dnl ---------------------------------------------------------------------------
1545 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1546 dnl ---------------
1547 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1548 AC_DEFUN([CF_HELP_MESSAGE],
1549 [AC_DIVERT_HELP([$1])dnl
1550 ])dnl
1551 dnl ---------------------------------------------------------------------------
1552 dnl CF_INCLUDE_DIRS version: 7 updated: 2012/11/10 19:15:05
1553 dnl ---------------
1554 dnl Construct the list of include-options according to whether we're building
1555 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
1556 dnl with gcc, don't append the includedir if it happens to be /usr/include,
1557 dnl since that usually breaks gcc's shadow-includes.
1558 AC_DEFUN([CF_INCLUDE_DIRS],
1559 [
1560 if test "$GCC" != yes; then
1561         CPPFLAGS="-I\${includedir} $CPPFLAGS"
1562 elif test "$includedir" != "/usr/include"; then
1563         if test "$includedir" = '${prefix}/include' ; then
1564                 if test $prefix != /usr ; then
1565                         CPPFLAGS="-I\${includedir} $CPPFLAGS"
1566                 fi
1567         else
1568                 CPPFLAGS="-I\${includedir} $CPPFLAGS"
1569         fi
1570 fi
1571 if test "$srcdir" != "."; then
1572         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
1573 fi
1574 CPPFLAGS="-I. -I../include $CPPFLAGS"
1575 AC_SUBST(CPPFLAGS)
1576 ])dnl
1577 dnl ---------------------------------------------------------------------------
1578 dnl CF_INTEL_COMPILER version: 5 updated: 2013/02/10 10:41:05
1579 dnl -----------------
1580 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1581 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1582 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1583 dnl
1584 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1585 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1586 dnl the wrappers for gcc and g++ warnings.
1587 dnl
1588 dnl $1 = GCC (default) or GXX
1589 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1590 dnl $3 = CFLAGS (default) or CXXFLAGS
1591 AC_DEFUN([CF_INTEL_COMPILER],[
1592 AC_REQUIRE([AC_CANONICAL_HOST])
1593 ifelse([$2],,INTEL_COMPILER,[$2])=no
1594
1595 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1596         case $host_os in
1597         linux*|gnu*)
1598                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1599                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1600                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1601                 AC_TRY_COMPILE([],[
1602 #ifdef __INTEL_COMPILER
1603 #else
1604 make an error
1605 #endif
1606 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1607 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
1608 ],[])
1609                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1610                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1611                 ;;
1612         esac
1613 fi
1614 ])dnl
1615 dnl ---------------------------------------------------------------------------
1616 dnl CF_LARGEFILE version: 8 updated: 2012/10/06 08:57:51
1617 dnl ------------
1618 dnl Add checks for large file support.
1619 AC_DEFUN([CF_LARGEFILE],[
1620 ifdef([AC_FUNC_FSEEKO],[
1621     AC_SYS_LARGEFILE
1622     if test "$enable_largefile" != no ; then
1623         AC_FUNC_FSEEKO
1624
1625         # Normally we would collect these definitions in the config.h,
1626         # but (like _XOPEN_SOURCE), some environments rely on having these
1627         # defined before any of the system headers are included.  Another
1628         # case comes up with C++, e.g., on AIX the compiler compiles the
1629         # header files by themselves before looking at the body files it is
1630         # told to compile.  For ncurses, those header files do not include
1631         # the config.h
1632         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
1633         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
1634         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
1635
1636         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
1637                 AC_TRY_COMPILE([
1638 #include <sys/types.h>
1639 #include <dirent.h>
1640                 ],[
1641                 /* if transitional largefile support is setup, this is true */
1642                 extern struct dirent64 * readdir(DIR *);
1643                 struct dirent64 *x = readdir((DIR *)0);
1644                 struct dirent *y = readdir((DIR *)0);
1645                 int z = x - y;
1646                 ],
1647                 [cf_cv_struct_dirent64=yes],
1648                 [cf_cv_struct_dirent64=no])
1649         ])
1650         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
1651     fi
1652 ])
1653 ])
1654 dnl ---------------------------------------------------------------------------
1655 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
1656 dnl ---------------
1657 dnl For the given system and compiler, find the compiler flags to pass to the
1658 dnl loader to use the "rpath" feature.
1659 AC_DEFUN([CF_LD_RPATH_OPT],
1660 [
1661 AC_REQUIRE([CF_CHECK_CACHE])
1662
1663 LD_RPATH_OPT=
1664 AC_MSG_CHECKING(for an rpath option)
1665 case $cf_cv_system_name in #(vi
1666 irix*) #(vi
1667         if test "$GCC" = yes; then
1668                 LD_RPATH_OPT="-Wl,-rpath,"
1669         else
1670                 LD_RPATH_OPT="-rpath "
1671         fi
1672         ;;
1673 linux*|gnu*|k*bsd*-gnu) #(vi
1674         LD_RPATH_OPT="-Wl,-rpath,"
1675         ;;
1676 openbsd[[2-9]].*|mirbsd*) #(vi
1677         LD_RPATH_OPT="-Wl,-rpath,"
1678         ;;
1679 dragonfly*|freebsd*) #(vi
1680         LD_RPATH_OPT="-rpath "
1681         ;;
1682 netbsd*) #(vi
1683         LD_RPATH_OPT="-Wl,-rpath,"
1684         ;;
1685 osf*|mls+*) #(vi
1686         LD_RPATH_OPT="-rpath "
1687         ;;
1688 solaris2*) #(vi
1689         LD_RPATH_OPT="-R"
1690         ;;
1691 *)
1692         ;;
1693 esac
1694 AC_MSG_RESULT($LD_RPATH_OPT)
1695
1696 case "x$LD_RPATH_OPT" in #(vi
1697 x-R*)
1698         AC_MSG_CHECKING(if we need a space after rpath option)
1699         cf_save_LIBS="$LIBS"
1700         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1701         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1702         LIBS="$cf_save_LIBS"
1703         AC_MSG_RESULT($cf_rpath_space)
1704         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1705         ;;
1706 esac
1707 ])dnl
1708 dnl ---------------------------------------------------------------------------
1709 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
1710 dnl ---------------
1711 dnl Construct a search-list of directories for a nonstandard library-file
1712 dnl
1713 dnl Parameters
1714 dnl     $1 = the variable to return as result
1715 dnl     $2 = the package name
1716 AC_DEFUN([CF_LIBRARY_PATH],
1717 [
1718 $1=
1719 cf_library_path_list=""
1720 if test -n "${LDFLAGS}${LIBS}" ; then
1721         for cf_library_path in $LDFLAGS $LIBS
1722         do
1723                 case $cf_library_path in #(vi
1724                 -L*)
1725                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1726                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1727                         cf_library_path_list="$cf_library_path_list [$]$1"
1728                         ;;
1729                 esac
1730         done
1731 fi
1732
1733 CF_SUBDIR_PATH($1,$2,lib)
1734
1735 $1="$cf_library_path_list [$]$1"
1736 ])dnl
1737 dnl ---------------------------------------------------------------------------
1738 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
1739 dnl -------------
1740 dnl Compute the library-prefix for the given host system
1741 dnl $1 = variable to set
1742 define([CF_LIB_PREFIX],
1743 [
1744         case $cf_cv_system_name in #(vi
1745         OS/2*|os2*) #(vi
1746         LIB_PREFIX=''
1747         ;;
1748         *)      LIB_PREFIX='lib'
1749         ;;
1750         esac
1751 ifelse($1,,,[$1=$LIB_PREFIX])
1752         AC_SUBST(LIB_PREFIX)
1753 ])dnl
1754 dnl ---------------------------------------------------------------------------
1755 dnl CF_LIB_SUFFIX version: 19 updated: 2013/06/15 11:58:48
1756 dnl -------------
1757 dnl Compute the library file-suffix from the given model name
1758 dnl $1 = model name
1759 dnl $2 = variable to set (the nominal library suffix)
1760 dnl $3 = dependency variable to set (actual filename)
1761 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1762 AC_DEFUN([CF_LIB_SUFFIX],
1763 [
1764         case $1 in #(vi
1765         libtool) #(vi
1766                 $2='.la'
1767                 $3=[$]$2
1768                 ;;
1769         normal) #(vi
1770                 $2='.a'
1771                 $3=[$]$2
1772                 ;;
1773         debug) #(vi
1774                 $2='_g.a'
1775                 $3=[$]$2
1776                 ;;
1777         profile) #(vi
1778                 $2='_p.a'
1779                 $3=[$]$2
1780                 ;;
1781         shared) #(vi
1782                 case $cf_cv_system_name in
1783                 aix[[5-7]]*) #(vi
1784                         $2='.a'
1785                         $3=[$]$2
1786                         ;;
1787                 cygwin*|mingw*) #(vi
1788                         $2='.dll'
1789                         $3='.dll.a'
1790                         ;;
1791                 darwin*) #(vi
1792                         $2='.dylib'
1793                         $3=[$]$2
1794                         ;;
1795                 hpux*) #(vi
1796                         case $target in
1797                         ia64*) #(vi
1798                                 $2='.so'
1799                                 $3=[$]$2
1800                                 ;;
1801                         *) #(vi
1802                                 $2='.sl'
1803                                 $3=[$]$2
1804                                 ;;
1805                         esac
1806                         ;;
1807                 *)      $2='.so'
1808                         $3=[$]$2
1809                         ;;
1810                 esac
1811         esac
1812         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1813         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
1814 ])dnl
1815 dnl ---------------------------------------------------------------------------
1816 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
1817 dnl -----------
1818 dnl Compute the string to append to -library from the given model name
1819 dnl $1 = model name
1820 dnl $2 = variable to set
1821 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1822 AC_DEFUN([CF_LIB_TYPE],
1823 [
1824         case $1 in
1825         libtool) $2=''   ;;
1826         normal)  $2=''   ;;
1827         debug)   $2='_g' ;;
1828         profile) $2='_p' ;;
1829         shared)  $2=''   ;;
1830         esac
1831         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1832 ])dnl
1833 dnl ---------------------------------------------------------------------------
1834 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
1835 dnl ----------------
1836 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
1837 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
1838 dnl have to provide wrappers for global tables to ensure they're linked
1839 dnl properly.
1840 AC_DEFUN([CF_LINK_DATAONLY],
1841 [
1842 AC_MSG_CHECKING([if data-only library module links])
1843 AC_CACHE_VAL(cf_cv_link_dataonly,[
1844         rm -f conftest.a
1845         cat >conftest.$ac_ext <<EOF
1846 #line __oline__ "configure"
1847 int     testdata[[3]] = { 123, 456, 789 };
1848 EOF
1849         if AC_TRY_EVAL(ac_compile) ; then
1850                 mv conftest.o data.o && \
1851                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
1852         fi
1853         rm -f conftest.$ac_ext data.o
1854         cat >conftest.$ac_ext <<EOF
1855 #line __oline__ "configure"
1856 int     testfunc()
1857 {
1858 #if defined(NeXT)
1859         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
1860 #else
1861         extern int testdata[[3]];
1862         return testdata[[0]] == 123
1863            &&  testdata[[1]] == 456
1864            &&  testdata[[2]] == 789;
1865 #endif
1866 }
1867 EOF
1868         if AC_TRY_EVAL(ac_compile); then
1869                 mv conftest.o func.o && \
1870                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
1871         fi
1872         rm -f conftest.$ac_ext func.o
1873         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
1874         cf_saveLIBS="$LIBS"
1875         LIBS="conftest.a $LIBS"
1876         AC_TRY_RUN([
1877         int main()
1878         {
1879                 extern int testfunc();
1880                 ${cf_cv_main_return:-return} (!testfunc());
1881         }
1882         ],
1883         [cf_cv_link_dataonly=yes],
1884         [cf_cv_link_dataonly=no],
1885         [cf_cv_link_dataonly=unknown])
1886         LIBS="$cf_saveLIBS"
1887         ])
1888 AC_MSG_RESULT($cf_cv_link_dataonly)
1889
1890 if test "$cf_cv_link_dataonly" = no ; then
1891         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
1892         BROKEN_LINKER=1
1893 fi
1894
1895 ])dnl
1896 dnl ---------------------------------------------------------------------------
1897 dnl CF_MAKEFLAGS version: 14 updated: 2011/03/31 19:29:46
1898 dnl ------------
1899 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
1900 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
1901 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
1902 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
1903 AC_DEFUN([CF_MAKEFLAGS],
1904 [
1905 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
1906         cf_cv_makeflags=''
1907         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
1908         do
1909                 cat >cf_makeflags.tmp <<CF_EOF
1910 SHELL = /bin/sh
1911 all :
1912         @ echo '.$cf_option'
1913 CF_EOF
1914                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
1915                 case "$cf_result" in
1916                 .*k)
1917                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
1918                         case "$cf_result" in
1919                         .*CC=*) cf_cv_makeflags=
1920                                 ;;
1921                         *)      cf_cv_makeflags=$cf_option
1922                                 ;;
1923                         esac
1924                         break
1925                         ;;
1926                 .-)     ;;
1927                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
1928                         ;;
1929                 esac
1930         done
1931         rm -f cf_makeflags.tmp
1932 ])
1933
1934 AC_SUBST(cf_cv_makeflags)
1935 ])dnl
1936 dnl ---------------------------------------------------------------------------
1937 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1938 dnl ------------
1939 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1940 dnl a monocase filesystem.
1941 AC_DEFUN([CF_MAKE_TAGS],[
1942 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1943
1944 AC_CHECK_PROGS(CTAGS, exctags ctags)
1945 AC_CHECK_PROGS(ETAGS, exetags etags)
1946
1947 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1948
1949 if test "$cf_cv_mixedcase" = yes ; then
1950         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1951 else
1952         MAKE_UPPER_TAGS=no
1953 fi
1954
1955 if test "$MAKE_UPPER_TAGS" = yes ; then
1956         MAKE_UPPER_TAGS=
1957 else
1958         MAKE_UPPER_TAGS="#"
1959 fi
1960
1961 if test "$MAKE_LOWER_TAGS" = yes ; then
1962         MAKE_LOWER_TAGS=
1963 else
1964         MAKE_LOWER_TAGS="#"
1965 fi
1966
1967 AC_SUBST(CTAGS)
1968 AC_SUBST(ETAGS)
1969
1970 AC_SUBST(MAKE_UPPER_TAGS)
1971 AC_SUBST(MAKE_LOWER_TAGS)
1972 ])dnl
1973 dnl ---------------------------------------------------------------------------
1974 dnl CF_MIXEDCASE_FILENAMES version: 4 updated: 2012/10/02 20:55:03
1975 dnl ----------------------
1976 dnl Check if the file-system supports mixed-case filenames.  If we're able to
1977 dnl create a lowercase name and see it as uppercase, it doesn't support that.
1978 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
1979 [
1980 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
1981 if test "$cross_compiling" = yes ; then
1982         case $target_alias in #(vi
1983         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-mingw32*|*-uwin*) #(vi
1984                 cf_cv_mixedcase=no
1985                 ;;
1986         *)
1987                 cf_cv_mixedcase=yes
1988                 ;;
1989         esac
1990 else
1991         rm -f conftest CONFTEST
1992         echo test >conftest
1993         if test -f CONFTEST ; then
1994                 cf_cv_mixedcase=no
1995         else
1996                 cf_cv_mixedcase=yes
1997         fi
1998         rm -f conftest CONFTEST
1999 fi
2000 ])
2001 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2002 ])dnl
2003 dnl ---------------------------------------------------------------------------
2004 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
2005 dnl ----------
2006 dnl Check for a working mkstemp.  This creates two files, checks that they are
2007 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2008 AC_DEFUN([CF_MKSTEMP],[
2009 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2010 rm -rf conftest*
2011 AC_TRY_RUN([
2012 #include <sys/types.h>
2013 #include <stdlib.h>
2014 #include <stdio.h>
2015 #include <string.h>
2016 #include <sys/stat.h>
2017 int main()
2018 {
2019         char *tmpl = "conftestXXXXXX";
2020         char name[2][80];
2021         int n;
2022         int result = 0;
2023         int fd;
2024         struct stat sb;
2025
2026         umask(077);
2027         for (n = 0; n < 2; ++n) {
2028                 strcpy(name[n], tmpl);
2029                 if ((fd = mkstemp(name[n])) >= 0) {
2030                         if (!strcmp(name[n], tmpl)
2031                          || stat(name[n], &sb) != 0
2032                          || (sb.st_mode & S_IFMT) != S_IFREG
2033                          || (sb.st_mode & 077) != 0) {
2034                                 result = 1;
2035                         }
2036                         close(fd);
2037                 }
2038         }
2039         if (result == 0
2040          && !strcmp(name[0], name[1]))
2041                 result = 1;
2042         ${cf_cv_main_return:-return}(result);
2043 }
2044 ],[cf_cv_func_mkstemp=yes
2045 ],[cf_cv_func_mkstemp=no
2046 ],[cf_cv_func_mkstemp=maybe])
2047 ])
2048 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2049         AC_CHECK_FUNC(mkstemp)
2050 fi
2051 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2052         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2053 fi
2054 ])dnl
2055 dnl ---------------------------------------------------------------------------
2056 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2057 dnl ----------
2058 dnl Write a debug message to config.log, along with the line number in the
2059 dnl configure script.
2060 AC_DEFUN([CF_MSG_LOG],[
2061 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2062 ])dnl
2063 dnl ---------------------------------------------------------------------------
2064 dnl CF_NCURSES_ADDON version: 4 updated: 2011/03/27 17:10:13
2065 dnl ----------------
2066 dnl Configure an ncurses add-on, built outside the ncurses tree.
2067 AC_DEFUN([CF_NCURSES_ADDON],[
2068
2069 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2070
2071 AC_MSG_CHECKING(if you want wide-character code)
2072 AC_ARG_ENABLE(widec,
2073         [  --enable-widec          compile with wide-char/UTF-8 code],
2074         [with_widec=$enableval],
2075         [with_widec=no])
2076 AC_MSG_RESULT($with_widec)
2077 if test "$with_widec" = yes ; then
2078         CF_UTF8_LIB
2079         CF_NCURSES_CONFIG(ncursesw)
2080 else
2081         CF_NCURSES_CONFIG(ncurses)
2082 fi
2083
2084 if test "$NCURSES_CONFIG" != none ; then
2085
2086 cf_version=`$NCURSES_CONFIG --version`
2087
2088 NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2089 NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2090 NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2091
2092 # ABI version is not available from headers
2093 cf_cv_abi_version=`$NCURSES_CONFIG --abi-version`
2094
2095 else
2096
2097 for cf_name in MAJOR MINOR PATCH
2098 do
2099 cat >conftest.$ac_ext <<CF_EOF
2100 #include <${cf_cv_ncurses_header:-curses.h}>
2101 AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2102 CF_EOF
2103         cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2104         AC_TRY_EVAL(cf_try)
2105         if test -f conftest.out ; then
2106                 cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]][[    ]]*//"`
2107                 eval NCURSES_$cf_name=\"$cf_result\"
2108                 # cat conftest.$ac_ext
2109                 # cat conftest.out
2110         fi
2111 done
2112
2113 cf_cv_abi_version=${NCURSES_MAJOR}
2114
2115 fi
2116
2117 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2118
2119 dnl Show the computed version, for logging
2120 cf_cv_timestamp=`date`
2121
2122 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2123
2124 dnl We need these values in the generated headers
2125 AC_SUBST(NCURSES_MAJOR)
2126 AC_SUBST(NCURSES_MINOR)
2127 AC_SUBST(NCURSES_PATCH)
2128
2129 dnl We need these values in the generated makefiles
2130 AC_SUBST(cf_cv_rel_version)
2131 AC_SUBST(cf_cv_abi_version)
2132
2133 dnl FIXME - not needed for Ada95
2134 AC_SUBST(cf_cv_builtin_bool)
2135 AC_SUBST(cf_cv_header_stdbool_h)
2136 AC_SUBST(cf_cv_type_of_bool)dnl
2137
2138 ])
2139 dnl ---------------------------------------------------------------------------
2140 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2141 dnl -------------------
2142 dnl Check if we can compile with ncurses' header file
2143 dnl $1 is the cache variable to set
2144 dnl $2 is the header-file to include
2145 dnl $3 is the root name (ncurses or ncursesw)
2146 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2147         AC_TRY_COMPILE([
2148 ]ifelse($3,ncursesw,[
2149 #define _XOPEN_SOURCE_EXTENDED
2150 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2151 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2152 ])[
2153 #include <$2>],[
2154 #ifdef NCURSES_VERSION
2155 ]ifelse($3,ncursesw,[
2156 #ifndef WACS_BSSB
2157         make an error
2158 #endif
2159 ])[
2160 printf("%s\n", NCURSES_VERSION);
2161 #else
2162 #ifdef __NCURSES_H
2163 printf("old\n");
2164 #else
2165         make an error
2166 #endif
2167 #endif
2168         ]
2169         ,[$1=$2]
2170         ,[$1=no])
2171 ])dnl
2172 dnl ---------------------------------------------------------------------------
2173 dnl CF_NCURSES_CONFIG version: 10 updated: 2012/10/06 08:57:51
2174 dnl -----------------
2175 dnl Tie together the configure-script macros for ncurses.
2176 dnl Prefer the "-config" script from ncurses 6.x, to simplify analysis.
2177 dnl Allow that to be overridden using the $NCURSES_CONFIG environment variable.
2178 dnl
2179 dnl $1 is the root library name (default: "ncurses")
2180 AC_DEFUN([CF_NCURSES_CONFIG],
2181 [
2182 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2183
2184 echo "Looking for ${cf_ncuconfig_root}-config"
2185
2186 CF_ACVERSION_CHECK(2.52,
2187         [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2188         [AC_PATH_PROGS(NCURSES_CONFIG, ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2189
2190 if test "$NCURSES_CONFIG" != none ; then
2191
2192 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
2193 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2194
2195 # even with config script, some packages use no-override for curses.h
2196 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2197
2198 dnl like CF_NCURSES_CPPFLAGS
2199 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2200
2201 dnl like CF_NCURSES_LIBS
2202 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2203 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2204
2205 dnl like CF_NCURSES_VERSION
2206 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2207
2208 else
2209
2210 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2211 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2212
2213 fi
2214 ])dnl
2215 dnl ---------------------------------------------------------------------------
2216 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2217 dnl -------------------
2218 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2219 dnl the CPPFLAGS variable so we can include its header.
2220 dnl
2221 dnl The header files may be installed as either curses.h, or ncurses.h (would
2222 dnl be obsolete, except that some packagers prefer this name to distinguish it
2223 dnl from a "native" curses implementation).  If not installed for overwrite,
2224 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2225 dnl /usr/include/ncurses), but someone may have installed overwriting the
2226 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2227 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2228 dnl the header.
2229 dnl
2230 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2231 dnl is already in the include-path, don't even bother with this, since we cannot
2232 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2233 dnl
2234 dnl The optional parameter gives the root name of the library, in case it is
2235 dnl not installed as the default curses library.  That is how the
2236 dnl wide-character version of ncurses is installed.
2237 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2238 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2239
2240 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2241 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2242
2243 test -n "$cf_cv_curses_dir" && \
2244 test "$cf_cv_curses_dir" != "no" && { \
2245   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2246 }
2247
2248 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2249         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2250         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2251         for cf_header in $cf_header_list
2252         do
2253                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2254                 test "$cf_cv_ncurses_h" != no && break
2255         done
2256 ])
2257
2258 CF_NCURSES_HEADER
2259 CF_TERM_HEADER
2260
2261 # some applications need this, but should check for NCURSES_VERSION
2262 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2263
2264 CF_NCURSES_VERSION
2265 ])dnl
2266 dnl ---------------------------------------------------------------------------
2267 dnl CF_NCURSES_HEADER version: 3 updated: 2012/10/06 08:57:51
2268 dnl -----------------
2269 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2270 dnl variations of ncurses' installs.
2271 dnl
2272 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2273 AC_DEFUN([CF_NCURSES_HEADER],[
2274
2275 if test "$cf_cv_ncurses_h" != no ; then
2276         cf_cv_ncurses_header=$cf_cv_ncurses_h
2277 else
2278
2279 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2280         test -n "$verbose" && echo
2281         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2282         test -n "$verbose" && echo search path $cf_search
2283         cf_save2_CPPFLAGS="$CPPFLAGS"
2284         for cf_incdir in $cf_search
2285         do
2286                 CF_ADD_INCDIR($cf_incdir)
2287                 for cf_header in \
2288                         ncurses.h \
2289                         curses.h
2290                 do
2291                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2292                         if test "$cf_cv_ncurses_h2" != no ; then
2293                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2294                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2295                                 break
2296                         fi
2297                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2298                 done
2299                 CPPFLAGS="$cf_save2_CPPFLAGS"
2300                 test "$cf_cv_ncurses_h2" != no && break
2301         done
2302         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2303         ])
2304
2305         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2306         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2307         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2308                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2309         fi
2310         CF_ADD_INCDIR($cf_1st_incdir)
2311
2312 fi
2313
2314 # Set definitions to allow ifdef'ing for ncurses.h
2315
2316 case $cf_cv_ncurses_header in # (vi
2317 *ncurses.h)
2318         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2319         ;;
2320 esac
2321
2322 case $cf_cv_ncurses_header in # (vi
2323 ncurses/curses.h|ncurses/ncurses.h)
2324         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2325         ;;
2326 ncursesw/curses.h|ncursesw/ncurses.h)
2327         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2328         ;;
2329 esac
2330
2331 ])dnl
2332 dnl ---------------------------------------------------------------------------
2333 dnl CF_NCURSES_LIBS version: 16 updated: 2010/11/20 17:02:38
2334 dnl ---------------
2335 dnl Look for the ncurses library.  This is a little complicated on Linux,
2336 dnl because it may be linked with the gpm (general purpose mouse) library.
2337 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2338 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2339 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2340 dnl and the linker will record a dependency.
2341 dnl
2342 dnl The optional parameter gives the root name of the library, in case it is
2343 dnl not installed as the default curses library.  That is how the
2344 dnl wide-character version of ncurses is installed.
2345 AC_DEFUN([CF_NCURSES_LIBS],
2346 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2347
2348 cf_nculib_root=ifelse($1,,ncurses,$1)
2349         # This works, except for the special case where we find gpm, but
2350         # ncurses is in a nonstandard location via $LIBS, and we really want
2351         # to link gpm.
2352 cf_ncurses_LIBS=""
2353 cf_ncurses_SAVE="$LIBS"
2354 AC_CHECK_LIB(gpm,Gpm_Open,
2355         [AC_CHECK_LIB(gpm,initscr,
2356                 [LIBS="$cf_ncurses_SAVE"],
2357                 [cf_ncurses_LIBS="-lgpm"])])
2358
2359 case $host_os in #(vi
2360 freebsd*)
2361         # This is only necessary if you are linking against an obsolete
2362         # version of ncurses (but it should do no harm, since it's static).
2363         if test "$cf_nculib_root" = ncurses ; then
2364                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2365         fi
2366         ;;
2367 esac
2368
2369 CF_ADD_LIBS($cf_ncurses_LIBS)
2370
2371 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2372 then
2373         CF_ADD_LIBS(-l$cf_nculib_root)
2374 else
2375         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2376                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2377                 [initscr()],
2378                 initscr)
2379 fi
2380
2381 if test -n "$cf_ncurses_LIBS" ; then
2382         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2383         cf_ncurses_SAVE="$LIBS"
2384         for p in $cf_ncurses_LIBS ; do
2385                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2386                 if test "$q" != "$LIBS" ; then
2387                         LIBS="$q"
2388                 fi
2389         done
2390         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2391                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2392                 [AC_MSG_RESULT(yes)],
2393                 [AC_MSG_RESULT(no)
2394                  LIBS="$cf_ncurses_SAVE"])
2395 fi
2396
2397 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2398 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2399 ])dnl
2400 dnl ---------------------------------------------------------------------------
2401 dnl CF_NCURSES_VERSION version: 14 updated: 2012/10/06 08:57:51
2402 dnl ------------------
2403 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2404 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2405 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2406 AC_DEFUN([CF_NCURSES_VERSION],
2407 [
2408 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2409 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2410         cf_cv_ncurses_version=no
2411         cf_tempfile=out$$
2412         rm -f $cf_tempfile
2413         AC_TRY_RUN([
2414 #include <${cf_cv_ncurses_header:-curses.h}>
2415 #include <stdio.h>
2416 int main()
2417 {
2418         FILE *fp = fopen("$cf_tempfile", "w");
2419 #ifdef NCURSES_VERSION
2420 # ifdef NCURSES_VERSION_PATCH
2421         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2422 # else
2423         fprintf(fp, "%s\n", NCURSES_VERSION);
2424 # endif
2425 #else
2426 # ifdef __NCURSES_H
2427         fprintf(fp, "old\n");
2428 # else
2429         make an error
2430 # endif
2431 #endif
2432         ${cf_cv_main_return:-return}(0);
2433 }],[
2434         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2435
2436         # This will not work if the preprocessor splits the line after the
2437         # Autoconf token.  The 'unproto' program does that.
2438         cat > conftest.$ac_ext <<EOF
2439 #include <${cf_cv_ncurses_header:-curses.h}>
2440 #undef Autoconf
2441 #ifdef NCURSES_VERSION
2442 Autoconf NCURSES_VERSION
2443 #else
2444 #ifdef __NCURSES_H
2445 Autoconf "old"
2446 #endif
2447 ;
2448 #endif
2449 EOF
2450         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2451         AC_TRY_EVAL(cf_try)
2452         if test -f conftest.out ; then
2453                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2454                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2455                 rm -f conftest.out
2456         fi
2457 ])
2458         rm -f $cf_tempfile
2459 ])
2460 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2461 ])dnl
2462 dnl ---------------------------------------------------------------------------
2463 dnl CF_OBJ_SUBDIR version: 4 updated: 2002/02/23 20:38:31
2464 dnl -------------
2465 dnl Compute the object-directory name from the given model name
2466 AC_DEFUN([CF_OBJ_SUBDIR],
2467 [
2468         case $1 in
2469         libtool) $2='obj_lo'  ;;
2470         normal)  $2='objects' ;;
2471         debug)   $2='obj_g' ;;
2472         profile) $2='obj_p' ;;
2473         shared)
2474                 case $cf_cv_system_name in #(vi
2475                 cygwin) #(vi
2476                         $2='objects' ;;
2477                 *)
2478                         $2='obj_s' ;;
2479                 esac
2480         esac
2481 ])dnl
2482 dnl ---------------------------------------------------------------------------
2483 dnl CF_PATHSEP version: 6 updated: 2012/09/29 18:38:12
2484 dnl ----------
2485 dnl Provide a value for the $PATH and similar separator (or amend the value
2486 dnl as provided in autoconf 2.5x).
2487 AC_DEFUN([CF_PATHSEP],
2488 [
2489         AC_MSG_CHECKING(for PATH separator)
2490         case $cf_cv_system_name in
2491         os2*)   PATH_SEPARATOR=';'  ;;
2492         *)      ${PATH_SEPARATOR:=':'}  ;;
2493         esac
2494 ifelse([$1],,,[$1=$PATH_SEPARATOR])
2495         AC_SUBST(PATH_SEPARATOR)
2496         AC_MSG_RESULT($PATH_SEPARATOR)
2497 ])dnl
2498 dnl ---------------------------------------------------------------------------
2499 dnl CF_PATH_SYNTAX version: 14 updated: 2012/06/19 20:58:54
2500 dnl --------------
2501 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2502 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2503 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2504 dnl delayed evaluation of those symbols.
2505 AC_DEFUN([CF_PATH_SYNTAX],[
2506 if test "x$prefix" != xNONE; then
2507   cf_path_syntax="$prefix"
2508 else
2509   cf_path_syntax="$ac_default_prefix"
2510 fi
2511
2512 case ".[$]$1" in #(vi
2513 .\[$]\(*\)*|.\'*\'*) #(vi
2514   ;;
2515 ..|./*|.\\*) #(vi
2516   ;;
2517 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
2518   ;;
2519 .\[$]{*prefix}*|.\[$]{*dir}*) #(vi
2520   eval $1="[$]$1"
2521   case ".[$]$1" in #(vi
2522   .NONE/*)
2523     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2524     ;;
2525   esac
2526   ;; #(vi
2527 .no|.NONE/*)
2528   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2529   ;;
2530 *)
2531   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2532   ;;
2533 esac
2534 ])dnl
2535 dnl ---------------------------------------------------------------------------
2536 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
2537 dnl -------------
2538 dnl Check for the package-config program, unless disabled by command-line.
2539 AC_DEFUN([CF_PKG_CONFIG],
2540 [
2541 AC_MSG_CHECKING(if you want to use pkg-config)
2542 AC_ARG_WITH(pkg-config,
2543         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2544         [cf_pkg_config=$withval],
2545         [cf_pkg_config=yes])
2546 AC_MSG_RESULT($cf_pkg_config)
2547
2548 case $cf_pkg_config in #(vi
2549 no) #(vi
2550         PKG_CONFIG=none
2551         ;;
2552 yes) #(vi
2553         CF_ACVERSION_CHECK(2.52,
2554                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2555                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2556         ;;
2557 *)
2558         PKG_CONFIG=$withval
2559         ;;
2560 esac
2561
2562 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2563 if test "$PKG_CONFIG" != none ; then
2564         CF_PATH_SYNTAX(PKG_CONFIG)
2565 fi
2566
2567 AC_SUBST(PKG_CONFIG)
2568 ])dnl
2569 dnl ---------------------------------------------------------------------------
2570 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
2571 dnl -----------------
2572 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2573 dnl
2574 dnl     POSIX.1-1990                            _POSIX_SOURCE
2575 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2576 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2577 dnl             Bindings Option
2578 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2579 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2580 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2581 dnl
2582 dnl Parameters:
2583 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2584 AC_DEFUN([CF_POSIX_C_SOURCE],
2585 [
2586 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2587
2588 cf_save_CFLAGS="$CFLAGS"
2589 cf_save_CPPFLAGS="$CPPFLAGS"
2590
2591 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2592 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2593
2594 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2595         CF_MSG_LOG(if the symbol is already defined go no further)
2596         AC_TRY_COMPILE([#include <sys/types.h>],[
2597 #ifndef _POSIX_C_SOURCE
2598 make an error
2599 #endif],
2600         [cf_cv_posix_c_source=no],
2601         [cf_want_posix_source=no
2602          case .$cf_POSIX_C_SOURCE in #(vi
2603          .[[12]]??*) #(vi
2604                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2605                 ;;
2606          .2) #(vi
2607                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2608                 cf_want_posix_source=yes
2609                 ;;
2610          .*)
2611                 cf_want_posix_source=yes
2612                 ;;
2613          esac
2614          if test "$cf_want_posix_source" = yes ; then
2615                 AC_TRY_COMPILE([#include <sys/types.h>],[
2616 #ifdef _POSIX_SOURCE
2617 make an error
2618 #endif],[],
2619                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2620          fi
2621          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2622          CFLAGS="$cf_trim_CFLAGS"
2623          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2624          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2625          AC_TRY_COMPILE([#include <sys/types.h>],[
2626 #ifndef _POSIX_C_SOURCE
2627 make an error
2628 #endif],,
2629          [cf_cv_posix_c_source=no])
2630          CFLAGS="$cf_save_CFLAGS"
2631          CPPFLAGS="$cf_save_CPPFLAGS"
2632         ])
2633 ])
2634
2635 if test "$cf_cv_posix_c_source" != no ; then
2636         CFLAGS="$cf_trim_CFLAGS"
2637         CPPFLAGS="$cf_trim_CPPFLAGS"
2638         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2639 fi
2640
2641 ])dnl
2642 dnl ---------------------------------------------------------------------------
2643 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
2644 dnl ----------
2645 dnl Check for archiver "ar".
2646 AC_DEFUN([CF_PROG_AR],[
2647 AC_CHECK_TOOL(AR, ar, ar)
2648 ])
2649 dnl ---------------------------------------------------------------------------
2650 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
2651 dnl -----------
2652 dnl Check for awk, ensure that the check found something.
2653 AC_DEFUN([CF_PROG_AWK],
2654 [
2655 AC_PROG_AWK
2656 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
2657 ])dnl
2658 dnl ---------------------------------------------------------------------------
2659 dnl CF_PROG_CC version: 3 updated: 2012/10/06 15:31:55
2660 dnl ----------
2661 dnl standard check for CC, plus followup sanity checks
2662 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
2663 AC_DEFUN([CF_PROG_CC],[
2664 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
2665 CF_GCC_VERSION
2666 CF_ACVERSION_CHECK(2.52,
2667         [AC_PROG_CC_STDC],
2668         [CF_ANSI_CC_REQD])
2669 CF_CC_ENV_FLAGS
2670 ])dnl
2671 dnl ---------------------------------------------------------------------------
2672 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
2673 dnl --------------
2674 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
2675 dnl the output file can be renamed, and allows for a shell variable that can
2676 dnl be used later.  The parameter is either CC or CXX.  The result is the
2677 dnl cache variable:
2678 dnl     $cf_cv_prog_CC_c_o
2679 dnl     $cf_cv_prog_CXX_c_o
2680 AC_DEFUN([CF_PROG_CC_C_O],
2681 [AC_REQUIRE([AC_PROG_CC])dnl
2682 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
2683 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
2684 [
2685 cat > conftest.$ac_ext <<CF_EOF
2686 #include <stdio.h>
2687 int main()
2688 {
2689         ${cf_cv_main_return:-return}(0);
2690 }
2691 CF_EOF
2692 # We do the test twice because some compilers refuse to overwrite an
2693 # existing .o file with -o, though they will create one.
2694 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
2695 if AC_TRY_EVAL(ac_try) &&
2696   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
2697 then
2698   eval cf_cv_prog_$1_c_o=yes
2699 else
2700   eval cf_cv_prog_$1_c_o=no
2701 fi
2702 rm -rf conftest*
2703 ])dnl
2704 if test $cf_cv_prog_$1_c_o = yes; then
2705   AC_MSG_RESULT([yes])
2706 else
2707   AC_MSG_RESULT([no])
2708 fi
2709 ])dnl
2710 dnl ---------------------------------------------------------------------------
2711 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
2712 dnl -------------
2713 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
2714 dnl This macro adds a check to ensure the script found something.
2715 AC_DEFUN([CF_PROG_EGREP],
2716 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
2717    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
2718     then ac_cv_prog_egrep='grep -E'
2719     else ac_cv_prog_egrep='egrep'
2720     fi])
2721  EGREP=$ac_cv_prog_egrep
2722  AC_SUBST([EGREP])
2723 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
2724 ])dnl
2725 dnl ---------------------------------------------------------------------------
2726 dnl CF_PROG_EXT version: 11 updated: 2012/10/06 08:57:51
2727 dnl -----------
2728 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
2729 AC_DEFUN([CF_PROG_EXT],
2730 [
2731 AC_REQUIRE([CF_CHECK_CACHE])
2732 case $cf_cv_system_name in
2733 os2*)
2734     CFLAGS="$CFLAGS -Zmt"
2735     CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
2736     CXXFLAGS="$CXXFLAGS -Zmt"
2737     # autoconf's macro sets -Zexe and suffix both, which conflict:w
2738     LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
2739     ac_cv_exeext=.exe
2740     ;;
2741 esac
2742
2743 AC_EXEEXT
2744 AC_OBJEXT
2745
2746 PROG_EXT="$EXEEXT"
2747 AC_SUBST(PROG_EXT)
2748 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
2749 ])dnl
2750 dnl ---------------------------------------------------------------------------
2751 dnl CF_PROG_GNAT version: 2 updated: 2011/10/22 14:01:47
2752 dnl ------------
2753 dnl Check for gnatmake, ensure that it is complete.
2754 AC_DEFUN([CF_PROG_GNAT],[
2755 cf_ada_make=gnatmake
2756 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
2757 if test "$ac_cv_prog_gnat_exists" = no; then
2758    cf_ada_make=
2759    cf_cv_prog_gnat_correct=no
2760 else
2761    CF_GNAT_VERSION
2762    AC_CHECK_PROG(M4_exists, m4, yes, no)
2763    if test "$ac_cv_prog_M4_exists" = no; then
2764       cf_cv_prog_gnat_correct=no
2765       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
2766    fi
2767    if test "$cf_cv_prog_gnat_correct" = yes; then
2768       AC_MSG_CHECKING(if GNAT works)
2769       CF_GNAT_TRY_RUN([procedure conftest;],
2770 [with Text_IO;
2771 with GNAT.OS_Lib;
2772 procedure conftest is
2773 begin
2774    Text_IO.Put ("Hello World");
2775    Text_IO.New_Line;
2776    GNAT.OS_Lib.OS_Exit (0);
2777 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
2778       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
2779    fi
2780 fi
2781
2782 AC_SUBST(cf_ada_make)
2783 ])dnl
2784 dnl ---------------------------------------------------------------------------
2785 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
2786 dnl ------------
2787 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
2788 dnl option if it is supported.
2789 AC_DEFUN([CF_PROG_LN_S],[
2790 AC_PROG_LN_S
2791 AC_MSG_CHECKING(if $LN_S -f options work)
2792
2793 rm -f conf$$.src conf$$dst
2794 echo >conf$$.dst
2795 echo first >conf$$.src
2796 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
2797         cf_prog_ln_sf=yes
2798 else
2799         cf_prog_ln_sf=no
2800 fi
2801 rm -f conf$$.dst conf$$src
2802 AC_MSG_RESULT($cf_prog_ln_sf)
2803
2804 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
2805 ])dnl
2806 dnl ---------------------------------------------------------------------------
2807 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2808 dnl ----------------
2809 dnl Remove all -U and -D options that refer to the given symbol from a list
2810 dnl of C compiler options.  This works around the problem that not all
2811 dnl compilers process -U and -D options from left-to-right, so a -U option
2812 dnl cannot be used to cancel the effect of a preceding -D option.
2813 dnl
2814 dnl $1 = target (which could be the same as the source variable)
2815 dnl $2 = source (including '$')
2816 dnl $3 = symbol to remove
2817 define([CF_REMOVE_DEFINE],
2818 [
2819 $1=`echo "$2" | \
2820         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2821                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2822 ])dnl
2823 dnl ---------------------------------------------------------------------------
2824 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
2825 dnl -------------
2826 dnl Remove the given library from the symbol
2827 dnl
2828 dnl $1 = target (which could be the same as the source variable)
2829 dnl $2 = source (including '$')
2830 dnl $3 = library to remove
2831 define([CF_REMOVE_LIB],
2832 [
2833 # remove $3 library from $2
2834 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
2835 ])dnl
2836 dnl ---------------------------------------------------------------------------
2837 dnl CF_SHARED_OPTS version: 73 updated: 2013/06/15 12:17:19
2838 dnl --------------
2839 dnl --------------
2840 dnl Attempt to determine the appropriate CC/LD options for creating a shared
2841 dnl library.
2842 dnl
2843 dnl Note: ${LOCAL_LDFLAGS} is used to link executables that will run within the
2844 dnl build-tree, i.e., by making use of the libraries that are compiled in ../lib
2845 dnl We avoid compiling-in a ../lib path for the shared library since that can
2846 dnl lead to unexpected results at runtime.
2847 dnl ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared libraries
2848 dnl are compiled in ../../lib
2849 dnl
2850 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
2851 dnl to install symbolic links to the rel/abi versions of shared libraries.
2852 dnl
2853 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
2854 dnl version when making symbolic links.
2855 dnl
2856 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
2857 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
2858 dnl (ex: libncurses.so.<ver>).
2859 dnl
2860 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
2861 AC_DEFUN([CF_SHARED_OPTS],
2862 [
2863         AC_REQUIRE([CF_LD_RPATH_OPT])
2864         LOCAL_LDFLAGS=
2865         LOCAL_LDFLAGS2=
2866         LD_SHARED_OPTS=
2867         INSTALL_LIB="-m 644"
2868
2869         cf_cv_do_symlinks=no
2870         cf_ld_rpath_opt=
2871         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
2872
2873         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
2874         AC_ARG_WITH(shlib-version,
2875         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
2876         [test -z "$withval" && withval=auto
2877         case $withval in #(vi
2878         yes) #(vi
2879                 cf_cv_shlib_version=auto
2880                 ;;
2881         rel|abi|auto|no) #(vi
2882                 cf_cv_shlib_version=$withval
2883                 ;;
2884         *)
2885                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
2886                 ;;
2887         esac
2888         ],[cf_cv_shlib_version=auto])
2889         AC_MSG_RESULT($cf_cv_shlib_version)
2890
2891         cf_cv_rm_so_locs=no
2892         cf_try_cflags=
2893
2894         # Some less-capable ports of gcc support only -fpic
2895         CC_SHARED_OPTS=
2896         if test "$GCC" = yes
2897         then
2898                 AC_MSG_CHECKING(which $CC option to use)
2899                 cf_save_CFLAGS="$CFLAGS"
2900                 for CC_SHARED_OPTS in -fPIC -fpic ''
2901                 do
2902                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
2903                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
2904                 done
2905                 AC_MSG_RESULT($CC_SHARED_OPTS)
2906                 CFLAGS="$cf_save_CFLAGS"
2907         fi
2908
2909         cf_cv_shlib_version_infix=no
2910
2911         case $cf_cv_system_name in #(vi
2912         aix4.[3-9]*|aix[[5-7]]*) #(vi
2913                 if test "$GCC" = yes; then
2914                         CC_SHARED_OPTS=
2915                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
2916                 else
2917                         # CC_SHARED_OPTS='-qpic=large -G'
2918                         # perhaps "-bM:SRE -bnoentry -bexpall"
2919                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
2920                 fi
2921                 ;;
2922         beos*) #(vi
2923                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
2924                 ;;
2925         cygwin*) #(vi
2926                 CC_SHARED_OPTS=
2927                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
2928                 cf_cv_shlib_version=cygdll
2929                 cf_cv_shlib_version_infix=cygdll
2930                 cat >mk_shared_lib.sh <<-CF_EOF
2931                 #!/bin/sh
2932                 SHARED_LIB=\[$]1
2933                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
2934                 shift
2935                 cat <<-EOF
2936                 Linking shared library
2937                 ** SHARED_LIB \[$]SHARED_LIB
2938                 ** IMPORT_LIB \[$]IMPORT_LIB
2939 EOF
2940                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
2941 CF_EOF
2942                 chmod +x mk_shared_lib.sh
2943                 ;;
2944         darwin*) #(vi
2945                 cf_try_cflags="no-cpp-precomp"
2946                 CC_SHARED_OPTS="-dynamic"
2947                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
2948                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
2949                 cf_cv_shlib_version_infix=yes
2950                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
2951                         cf_save_LDFLAGS=$LDFLAGS
2952                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
2953                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
2954                                 LDFLAGS=$cf_save_LDFLAGS])
2955                 if test $cf_cv_ldflags_search_paths_first = yes; then
2956                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
2957                 fi
2958                 ;;
2959         hpux[[7-8]]*) #(vi
2960                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
2961                 if test "$GCC" != yes; then
2962                         CC_SHARED_OPTS='+Z'
2963                 fi
2964                 MK_SHARED_LIB='${LD} -b -o $[@]'
2965                 INSTALL_LIB="-m 555"
2966                 ;;
2967         hpux*) #(vi
2968                 # (tested with gcc 2.7.2 -- I don't have c89)
2969                 if test "$GCC" = yes; then
2970                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
2971                 else
2972                         CC_SHARED_OPTS='+Z'
2973                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
2974                 fi
2975                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
2976                 # HP-UX shared libraries must be executable, and should be
2977                 # readonly to exploit a quirk in the memory manager.
2978                 INSTALL_LIB="-m 555"
2979                 ;;
2980         interix*)
2981                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
2982                 if test "$cf_cv_shlib_version" = rel; then
2983                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
2984                 else
2985                         cf_shared_soname='`basename $@`'
2986                 fi
2987                 CC_SHARED_OPTS=
2988                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
2989                 ;;
2990         irix*) #(vi
2991                 if test "$cf_cv_enable_rpath" = yes ; then
2992                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
2993                 fi
2994                 # tested with IRIX 5.2 and 'cc'.
2995                 if test "$GCC" != yes; then
2996                         CC_SHARED_OPTS='-KPIC'
2997                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
2998                 else
2999                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
3000                 fi
3001                 cf_cv_rm_so_locs=yes
3002                 ;;
3003         linux*|gnu*|k*bsd*-gnu) #(vi
3004                 if test "$DFT_LWR_MODEL" = "shared" ; then
3005                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3006                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3007                 fi
3008                 if test "$cf_cv_enable_rpath" = yes ; then
3009                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3010                 fi
3011                 CF_SHARED_SONAME
3012                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3013                 ;;
3014         mingw*) #(vi
3015                 cf_cv_shlib_version=mingw
3016                 cf_cv_shlib_version_infix=mingw
3017                 CC_SHARED_OPTS=
3018                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3019                 #MK_SHARED_LIB='${CC} ${CFLAGS} -mdll -Wl,-soname,'$cf_cv_shared_soname',-stats -o $[@]'
3020                 #MK_SHARED_LIB='${DLLTOOL} --export-all-symbols --output-exp --output-lib $[@]'
3021                 cat >mk_shared_lib.sh <<-CF_EOF
3022                 #!/bin/sh
3023                 SHARED_LIB=\[$]1
3024                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3025                 shift
3026                 cat <<-EOF
3027                 Linking shared library
3028                 ** SHARED_LIB \[$]SHARED_LIB
3029                 ** IMPORT_LIB \[$]IMPORT_LIB
3030 EOF
3031                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
3032 CF_EOF
3033                 chmod +x mk_shared_lib.sh
3034                 ;;
3035         openbsd[[2-9]].*|mirbsd*) #(vi
3036                 if test "$DFT_LWR_MODEL" = "shared" ; then
3037                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3038                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3039                 fi
3040                 if test "$cf_cv_enable_rpath" = yes ; then
3041                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3042                 fi
3043                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3044                 CF_SHARED_SONAME
3045                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3046                 ;;
3047         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
3048                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3049                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
3050                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3051                 ;;
3052         dragonfly*|freebsd*) #(vi
3053                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3054                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3055                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3056                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
3057                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3058                 fi
3059                 CF_SHARED_SONAME
3060                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
3061                 ;;
3062         netbsd*) #(vi
3063                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3064                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3065                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3066                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3067                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3068                         if test "$cf_cv_shlib_version" = auto; then
3069                         if test -f /usr/libexec/ld.elf_so; then
3070                                 cf_cv_shlib_version=abi
3071                         else
3072                                 cf_cv_shlib_version=rel
3073                         fi
3074                         fi
3075                         CF_SHARED_SONAME
3076                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
3077                 else
3078                         MK_SHARED_LIB='${LD} -shared -Bshareable -o $[@]'
3079                 fi
3080                 ;;
3081         osf*|mls+*) #(vi
3082                 # tested with OSF/1 V3.2 and 'cc'
3083                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
3084                 # link with shared libs).
3085                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
3086                 case $host_os in #(vi
3087                 osf4*)
3088                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
3089                         ;;
3090                 esac
3091                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
3092                 if test "$DFT_LWR_MODEL" = "shared" ; then
3093                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3094                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3095                 fi
3096                 cf_cv_rm_so_locs=yes
3097                 ;;
3098         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
3099                 # tested with osr5.0.5
3100                 if test "$GCC" != yes; then
3101                         CC_SHARED_OPTS='-belf -KPIC'
3102                 fi
3103                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
3104                 if test "$cf_cv_enable_rpath" = yes ; then
3105                         # only way is to set LD_RUN_PATH but no switch for it
3106                         RUN_PATH=$libdir
3107                 fi
3108                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3109                 LINK_PROGS='LD_RUN_PATH=${libdir}'
3110                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
3111                 ;;
3112         sunos4*) #(vi
3113                 # tested with SunOS 4.1.1 and gcc 2.7.0
3114                 if test "$GCC" != yes; then
3115                         CC_SHARED_OPTS='-KPIC'
3116                 fi
3117                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
3118                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3119                 ;;
3120         solaris2*) #(vi
3121                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
3122                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
3123                 if test "$DFT_LWR_MODEL" = "shared" ; then
3124                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
3125                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3126                 fi
3127                 if test "$cf_cv_enable_rpath" = yes ; then
3128                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
3129                 fi
3130                 CF_SHARED_SONAME
3131                 if test "$GCC" != yes; then
3132                         cf_save_CFLAGS="$CFLAGS"
3133                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
3134                         do
3135                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
3136                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
3137                         done
3138                         CFLAGS="$cf_save_CFLAGS"
3139                         CC_SHARED_OPTS=$cf_shared_opts
3140                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3141                 else
3142                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3143                 fi
3144                 ;;
3145         sysv5uw7*|unix_sv*) #(vi
3146                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
3147                 if test "$GCC" != yes; then
3148                         CC_SHARED_OPTS='-KPIC'
3149                 fi
3150                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
3151                 ;;
3152         *)
3153                 CC_SHARED_OPTS='unknown'
3154                 MK_SHARED_LIB='echo unknown'
3155                 ;;
3156         esac
3157
3158         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
3159         case "$cf_cv_shlib_version" in #(vi
3160         rel|abi)
3161                 case "$MK_SHARED_LIB" in #(vi
3162                 *'-o $[@]') #(vi
3163                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
3164                         ;;
3165                 *)
3166                         AC_MSG_WARN(ignored --with-shlib-version)
3167                         ;;
3168                 esac
3169                 ;;
3170         esac
3171
3172         if test -n "$cf_try_cflags"
3173         then
3174 cat > conftest.$ac_ext <<EOF
3175 #line __oline__ "${as_me:-configure}"
3176 #include <stdio.h>
3177 int main(int argc, char *argv[[]])
3178 {
3179         printf("hello\n");
3180         return (argv[[argc-1]] == 0) ;
3181 }
3182 EOF
3183                 cf_save_CFLAGS="$CFLAGS"
3184                 for cf_opt in $cf_try_cflags
3185                 do
3186                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
3187                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
3188                         if AC_TRY_EVAL(ac_compile); then
3189                                 AC_MSG_RESULT(yes)
3190                                 cf_save_CFLAGS="$CFLAGS"
3191                         else
3192                                 AC_MSG_RESULT(no)
3193                         fi
3194                 done
3195                 CFLAGS="$cf_save_CFLAGS"
3196         fi
3197
3198
3199         # RPATH_LIST is a colon-separated list of directories
3200         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
3201         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
3202
3203         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
3204         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
3205
3206         AC_SUBST(CC_SHARED_OPTS)
3207         AC_SUBST(LD_RPATH_OPT)
3208         AC_SUBST(LD_SHARED_OPTS)
3209         AC_SUBST(MK_SHARED_LIB)
3210         AC_SUBST(LINK_PROGS)
3211         AC_SUBST(LINK_TESTS)
3212         AC_SUBST(EXTRA_LDFLAGS)
3213         AC_SUBST(LOCAL_LDFLAGS)
3214         AC_SUBST(LOCAL_LDFLAGS2)
3215         AC_SUBST(INSTALL_LIB)
3216         AC_SUBST(RPATH_LIST)
3217 ])dnl
3218 dnl ---------------------------------------------------------------------------
3219 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
3220 dnl ----------------
3221 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
3222 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
3223 dnl option.
3224 dnl
3225 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
3226 dnl If missing, use "rel".
3227 define([CF_SHARED_SONAME],
3228 [
3229         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
3230         if test "$cf_cv_shlib_version" = rel; then
3231                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3232         else
3233                 cf_cv_shared_soname='`basename $[@]`'
3234         fi
3235 ])
3236 dnl ---------------------------------------------------------------------------
3237 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
3238 dnl --------------
3239 dnl     Remove "-g" option from the compiler options
3240 AC_DEFUN([CF_STRIP_G_OPT],
3241 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
3242 dnl ---------------------------------------------------------------------------
3243 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
3244 dnl --------------
3245 dnl Construct a search-list for a nonstandard header/lib-file
3246 dnl     $1 = the variable to return as result
3247 dnl     $2 = the package name
3248 dnl     $3 = the subdirectory, e.g., bin, include or lib
3249 AC_DEFUN([CF_SUBDIR_PATH],
3250 [
3251 $1=
3252
3253 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
3254 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3255 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
3256 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
3257 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
3258 ])dnl
3259 dnl ---------------------------------------------------------------------------
3260 dnl CF_TERM_HEADER version: 3 updated: 2012/10/06 08:57:51
3261 dnl --------------
3262 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3263 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3264 dnl but some packagers change this, breaking various applications.
3265 AC_DEFUN([CF_TERM_HEADER],[
3266 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3267 case ${cf_cv_ncurses_header} in #(vi
3268 */ncurses.h|*/ncursesw.h) #(vi
3269         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3270         ;;
3271 *)
3272         cf_term_header=term.h
3273         ;;
3274 esac
3275
3276 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3277 do
3278 AC_TRY_COMPILE([#include <stdio.h>
3279 #include <${cf_cv_ncurses_header:-curses.h}>
3280 #include <$cf_test>
3281 ],[int x = auto_left_margin],[
3282         cf_cv_term_header="$cf_test"],[
3283         cf_cv_term_header=unknown
3284         ])
3285         test "$cf_cv_term_header" != unknown && break
3286 done
3287 ])
3288
3289 # Set definitions to allow ifdef'ing to accommodate subdirectories
3290
3291 case $cf_cv_term_header in # (vi
3292 *term.h)
3293         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
3294         ;;
3295 esac
3296
3297 case $cf_cv_term_header in # (vi
3298 ncurses/term.h) #(vi
3299         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
3300         ;;
3301 ncursesw/term.h)
3302         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
3303         ;;
3304 esac
3305 ])dnl
3306 dnl ---------------------------------------------------------------------------
3307 dnl CF_TOP_BUILDDIR version: 1 updated: 2006/10/15 16:33:23
3308 dnl ---------------
3309 dnl Define a top_builddir symbol, for applications that need an absolute path.
3310 AC_DEFUN([CF_TOP_BUILDDIR],
3311 [
3312 top_builddir=`pwd`
3313 AC_SUBST(top_builddir)
3314 ])dnl
3315 dnl ---------------------------------------------------------------------------
3316 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
3317 dnl -------------------
3318 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
3319 dnl can define it successfully.
3320 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
3321 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3322         AC_TRY_COMPILE([
3323 #include <stdlib.h>
3324 #include <string.h>
3325 #include <sys/types.h>
3326 ],[
3327 #ifndef _XOPEN_SOURCE
3328 make an error
3329 #endif],
3330         [cf_cv_xopen_source=no],
3331         [cf_save="$CPPFLAGS"
3332          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3333          AC_TRY_COMPILE([
3334 #include <stdlib.h>
3335 #include <string.h>
3336 #include <sys/types.h>
3337 ],[
3338 #ifdef _XOPEN_SOURCE
3339 make an error
3340 #endif],
3341         [cf_cv_xopen_source=no],
3342         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3343         CPPFLAGS="$cf_save"
3344         ])
3345 ])
3346
3347 if test "$cf_cv_xopen_source" != no ; then
3348         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3349         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3350         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3351         CF_ADD_CFLAGS($cf_temp_xopen_source)
3352 fi
3353 ])
3354 dnl ---------------------------------------------------------------------------
3355 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3356 dnl --------
3357 dnl Make an uppercase version of a variable
3358 dnl $1=uppercase($2)
3359 AC_DEFUN([CF_UPPER],
3360 [
3361 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3362 ])dnl
3363 dnl ---------------------------------------------------------------------------
3364 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
3365 dnl -----------
3366 dnl Check for multibyte support, and if not found, utf8 compatibility library
3367 AC_DEFUN([CF_UTF8_LIB],
3368 [
3369 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3370         cf_save_LIBS="$LIBS"
3371         AC_TRY_LINK([
3372 #include <stdlib.h>],[putwc(0,0);],
3373         [cf_cv_utf8_lib=yes],
3374         [CF_FIND_LINKAGE([
3375 #include <libutf8.h>],[putwc(0,0);],utf8,
3376                 [cf_cv_utf8_lib=add-on],
3377                 [cf_cv_utf8_lib=no])
3378 ])])
3379
3380 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3381 # ncurses/ncursesw:
3382 if test "$cf_cv_utf8_lib" = "add-on" ; then
3383         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
3384         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3385         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3386         CF_ADD_LIBS($cf_cv_library_file_utf8)
3387 fi
3388 ])dnl
3389 dnl ---------------------------------------------------------------------------
3390 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3391 dnl ----------
3392 dnl Use AC_VERBOSE w/o the warnings
3393 AC_DEFUN([CF_VERBOSE],
3394 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3395 CF_MSG_LOG([$1])
3396 ])dnl
3397 dnl ---------------------------------------------------------------------------
3398 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
3399 dnl ---------------
3400 dnl Check for compiler-support for weak symbols.
3401 dnl This works with "recent" gcc.
3402 AC_DEFUN([CF_WEAK_SYMBOLS],[
3403 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
3404
3405 AC_TRY_COMPILE([
3406 #include <stdio.h>],
3407 [
3408 #if defined(__GNUC__)
3409 #  if defined __USE_ISOC99
3410 #    define _cat_pragma(exp)    _Pragma(#exp)
3411 #    define _weak_pragma(exp)   _cat_pragma(weak name)
3412 #  else
3413 #    define _weak_pragma(exp)
3414 #  endif
3415 #  define _declare(name)        __extension__ extern __typeof__(name) name
3416 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
3417 #endif
3418
3419 weak_symbol(fopen);
3420 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
3421 ])
3422 ])dnl
3423 dnl ---------------------------------------------------------------------------
3424 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
3425 dnl --------------------
3426 dnl Command-line option to specify the Ada95 compiler.
3427 AC_DEFUN([CF_WITH_ADA_COMPILER],[
3428 AC_MSG_CHECKING(for ada-compiler)
3429 AC_ARG_WITH(ada-compiler,
3430         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
3431         [cf_ada_compiler=$withval],
3432         [cf_ada_compiler=gnatmake])
3433 AC_SUBST(cf_ada_compiler)
3434 AC_MSG_RESULT($cf_ada_compiler)
3435 ])dnl
3436 dnl ---------------------------------------------------------------------------
3437 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
3438 dnl -------------------
3439 dnl Command-line option to specify where Ada includes will install.
3440 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
3441 AC_MSG_CHECKING(for ada-include)
3442 CF_WITH_PATH(ada-include,
3443    [  --with-ada-include=DIR  Ada includes are in DIR],
3444    ADA_INCLUDE,
3445    PREFIX/share/ada/adainclude,
3446    [$]prefix/share/ada/adainclude)
3447 AC_SUBST(ADA_INCLUDE)
3448 AC_MSG_RESULT($ADA_INCLUDE)
3449 ])dnl
3450 dnl ---------------------------------------------------------------------------
3451 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
3452 dnl -------------------
3453 dnl Command-line option to specify where Ada objects will install.
3454 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
3455 AC_MSG_CHECKING(for ada-objects)
3456 CF_WITH_PATH(ada-objects,
3457    [  --with-ada-objects=DIR  Ada objects are in DIR],
3458    ADA_OBJECTS,
3459    PREFIX/lib/ada/adalib,
3460    [$]prefix/lib/ada/adalib)
3461 AC_SUBST(ADA_OBJECTS)
3462 AC_MSG_RESULT($ADA_OBJECTS)
3463 ])dnl
3464 dnl ---------------------------------------------------------------------------
3465 dnl CF_WITH_ADA_SHAREDLIB version: 2 updated: 2010/06/26 17:35:58
3466 dnl ---------------------
3467 dnl Command-line option to specify if an Ada95 shared-library should be built,
3468 dnl and optionally what its soname should be.
3469 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
3470 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
3471 AC_ARG_WITH(ada-sharedlib,
3472         [  --with-ada-sharedlib=XX build Ada95 shared-library],
3473         [with_ada_sharedlib=$withval],
3474         [with_ada_sharedlib=no])
3475 AC_MSG_RESULT($with_ada_sharedlib)
3476
3477 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
3478 MAKE_ADA_SHAREDLIB="#"
3479
3480 if test "x$with_ada_sharedlib" != xno
3481 then
3482         MAKE_ADA_SHAREDLIB=
3483         if test "x$with_ada_sharedlib" != xyes
3484         then
3485                 ADA_SHAREDLIB="$with_ada_sharedlib"
3486         fi
3487 fi
3488
3489 AC_SUBST(ADA_SHAREDLIB)
3490 AC_SUBST(MAKE_ADA_SHAREDLIB)
3491 ])dnl
3492 dnl ---------------------------------------------------------------------------
3493 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3494 dnl ------------------
3495 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3496 dnl libraries.
3497 AC_DEFUN([CF_WITH_CURSES_DIR],[
3498
3499 AC_MSG_CHECKING(for specific curses-directory)
3500 AC_ARG_WITH(curses-dir,
3501         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3502         [cf_cv_curses_dir=$withval],
3503         [cf_cv_curses_dir=no])
3504 AC_MSG_RESULT($cf_cv_curses_dir)
3505
3506 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3507 then
3508         CF_PATH_SYNTAX(withval)
3509         if test -d "$cf_cv_curses_dir"
3510         then
3511                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3512                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3513         fi
3514 fi
3515 ])dnl
3516 dnl ---------------------------------------------------------------------------
3517 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
3518 dnl ------------------
3519 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
3520 dnl "lib" prefix, e.g., because it used the dll naming convention.
3521 dnl
3522 dnl $1 = variable to set
3523 AC_DEFUN([CF_WITH_LIB_PREFIX],
3524 [
3525 AC_MSG_CHECKING(if you want to have a library-prefix)
3526 AC_ARG_WITH(lib-prefix,
3527         [  --with-lib-prefix       override library-prefix],
3528         [with_lib_prefix=$withval],
3529         [with_lib_prefix=auto])
3530 AC_MSG_RESULT($with_lib_prefix)
3531
3532 if test $with_lib_prefix = auto
3533 then
3534         CF_LIB_PREFIX($1)
3535 elif test $with_lib_prefix = no
3536 then
3537         LIB_PREFIX=
3538 else
3539         LIB_PREFIX=$with_lib_prefix
3540 fi
3541 ])dnl
3542 dnl ---------------------------------------------------------------------------
3543 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
3544 dnl ------------
3545 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
3546 dnl defaulting to yes/no.
3547 dnl
3548 dnl $1 = option name
3549 dnl $2 = help-text
3550 dnl $3 = environment variable to set
3551 dnl $4 = default value, shown in the help-message, must be a constant
3552 dnl $5 = default value, if it's an expression & cannot be in the help-message
3553 dnl
3554 AC_DEFUN([CF_WITH_PATH],
3555 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
3556 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
3557 if ifelse([$5],,true,[test -n "$5"]) ; then
3558 CF_PATH_SYNTAX(withval)
3559 fi
3560 eval $3="$withval"
3561 AC_SUBST($3)dnl
3562 ])dnl
3563 dnl ---------------------------------------------------------------------------
3564 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 2 updated: 2011/12/10 18:58:47
3565 dnl -------------------------
3566 dnl Allow the choice of the pkg-config library directory to be overridden.
3567 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
3568 if test "$PKG_CONFIG" != none ; then
3569         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
3570         AC_ARG_WITH(pkg-config-libdir,
3571                 [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
3572                 [PKG_CONFIG_LIBDIR=$withval],
3573                 [PKG_CONFIG_LIBDIR=yes])
3574
3575         case x$PKG_CONFIG_LIBDIR in #(vi
3576         x/*) #(vi
3577                 ;;
3578         xyes) #(vi
3579                 # look for the library directory using the same prefix as the executable
3580                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
3581                 case x`(arch) 2>/dev/null` in #(vi
3582                 *64) #(vi
3583                         for cf_config in $cf_path/share $cf_path/lib64 $cf_path/lib32 $cf_path/lib
3584                         do
3585                                 if test -d $cf_config/pkgconfig
3586                                 then
3587                                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
3588                                         break
3589                                 fi
3590                         done
3591                         ;;
3592                 *)
3593                         PKG_CONFIG_LIBDIR=$cf_path/lib/pkgconfig
3594                         ;;
3595                 esac
3596                 ;;
3597         *)
3598                 ;;
3599         esac
3600
3601         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
3602 fi
3603
3604 AC_SUBST(PKG_CONFIG_LIBDIR)
3605 ])dnl
3606 dnl ---------------------------------------------------------------------------
3607 dnl CF_WITH_PTHREAD version: 6 updated: 2012/10/06 17:41:51
3608 dnl ---------------
3609 dnl Check for POSIX thread library.
3610 AC_DEFUN([CF_WITH_PTHREAD],
3611 [
3612 AC_MSG_CHECKING(if you want to link with the pthread library)
3613 AC_ARG_WITH(pthread,
3614     [  --with-pthread          use POSIX thread library],
3615     [with_pthread=$withval],
3616     [with_pthread=no])
3617 AC_MSG_RESULT($with_pthread)
3618
3619 if test "$with_pthread" != no ; then
3620     AC_CHECK_HEADER(pthread.h,[
3621         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
3622
3623         for cf_lib_pthread in pthread c_r
3624         do
3625             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
3626             cf_save_LIBS="$LIBS"
3627             CF_ADD_LIB($cf_lib_pthread)
3628             AC_TRY_LINK([
3629 #include <pthread.h>
3630 ],[
3631                 int rc = pthread_create(0,0,0,0);
3632                 int r2 = pthread_mutexattr_settype(0, 0);
3633 ],[with_pthread=yes],[with_pthread=no])
3634             LIBS="$cf_save_LIBS"
3635             AC_MSG_RESULT($with_pthread)
3636             test "$with_pthread" = yes && break
3637         done
3638
3639         if test "$with_pthread" = yes ; then
3640             CF_ADD_LIB($cf_lib_pthread)
3641             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
3642         else
3643             AC_MSG_ERROR(Cannot link with pthread library)
3644         fi
3645     ])
3646 fi
3647 ])
3648 dnl ---------------------------------------------------------------------------
3649 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
3650 dnl ---------------
3651 dnl For testing, override the derived host system-type which is used to decide
3652 dnl things such as the linker commands used to build shared libraries.  This is
3653 dnl normally chosen automatically based on the type of system which you are
3654 dnl building on.  We use it for testing the configure script.
3655 dnl
3656 dnl This is different from the --host option: it is used only for testing parts
3657 dnl of the configure script which would not be reachable with --host since that
3658 dnl relies on the build environment being real, rather than mocked up.
3659 AC_DEFUN([CF_WITH_SYSTYPE],[
3660 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
3661 AC_ARG_WITH(system-type,
3662         [  --with-system-type=XXX  test: override derived host system-type],
3663 [AC_MSG_WARN(overriding system type to $withval)
3664         cf_cv_system_name=$withval
3665         host_os=$withval
3666 ])
3667 ])dnl
3668 dnl ---------------------------------------------------------------------------
3669 dnl CF_XOPEN_SOURCE version: 43 updated: 2013/02/10 10:41:05
3670 dnl ---------------
3671 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
3672 dnl or adapt to the vendor's definitions to get equivalent functionality,
3673 dnl without losing the common non-POSIX features.
3674 dnl
3675 dnl Parameters:
3676 dnl     $1 is the nominal value for _XOPEN_SOURCE
3677 dnl     $2 is the nominal value for _POSIX_C_SOURCE
3678 AC_DEFUN([CF_XOPEN_SOURCE],[
3679 AC_REQUIRE([AC_CANONICAL_HOST])
3680
3681 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
3682 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
3683 cf_xopen_source=
3684
3685 case $host_os in #(vi
3686 aix[[4-7]]*) #(vi
3687         cf_xopen_source="-D_ALL_SOURCE"
3688         ;;
3689 cygwin) #(vi
3690         cf_XOPEN_SOURCE=600
3691         ;;
3692 darwin[[0-8]].*) #(vi
3693         cf_xopen_source="-D_APPLE_C_SOURCE"
3694         ;;
3695 darwin*) #(vi
3696         cf_xopen_source="-D_DARWIN_C_SOURCE"
3697         cf_XOPEN_SOURCE=
3698         ;;
3699 freebsd*|dragonfly*) #(vi
3700         # 5.x headers associate
3701         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
3702         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
3703         cf_POSIX_C_SOURCE=200112L
3704         cf_XOPEN_SOURCE=600
3705         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3706         ;;
3707 hpux11*) #(vi
3708         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
3709         ;;
3710 hpux*) #(vi
3711         cf_xopen_source="-D_HPUX_SOURCE"
3712         ;;
3713 irix[[56]].*) #(vi
3714         cf_xopen_source="-D_SGI_SOURCE"
3715         cf_XOPEN_SOURCE=
3716         ;;
3717 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
3718         CF_GNU_SOURCE
3719         ;;
3720 mirbsd*) #(vi
3721         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
3722         cf_XOPEN_SOURCE=
3723         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3724         ;;
3725 netbsd*) #(vi
3726         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
3727         ;;
3728 openbsd[[4-9]]*) #(vi
3729         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
3730         cf_xopen_source="-D_BSD_SOURCE"
3731         cf_XOPEN_SOURCE=600
3732         ;;
3733 openbsd*) #(vi
3734         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
3735         ;;
3736 osf[[45]]*) #(vi
3737         cf_xopen_source="-D_OSF_SOURCE"
3738         ;;
3739 nto-qnx*) #(vi
3740         cf_xopen_source="-D_QNX_SOURCE"
3741         ;;
3742 sco*) #(vi
3743         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
3744         ;;
3745 solaris2.*) #(vi
3746         cf_xopen_source="-D__EXTENSIONS__"
3747         ;;
3748 *)
3749         CF_TRY_XOPEN_SOURCE
3750         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3751         ;;
3752 esac
3753
3754 if test -n "$cf_xopen_source" ; then
3755         CF_ADD_CFLAGS($cf_xopen_source)
3756 fi
3757
3758 dnl In anything but the default case, we may have system-specific setting
3759 dnl which is still not guaranteed to provide all of the entrypoints that
3760 dnl _XOPEN_SOURCE would yield.
3761 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
3762         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
3763         AC_TRY_COMPILE([#include <stdlib.h>],[
3764 #ifndef _XOPEN_SOURCE
3765 make an error
3766 #endif],
3767         [cf_XOPEN_SOURCE_set=yes],
3768         [cf_XOPEN_SOURCE_set=no])
3769         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
3770         if test $cf_XOPEN_SOURCE_set = yes
3771         then
3772                 AC_TRY_COMPILE([#include <stdlib.h>],[
3773 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
3774 make an error
3775 #endif],
3776                 [cf_XOPEN_SOURCE_set_ok=yes],
3777                 [cf_XOPEN_SOURCE_set_ok=no])
3778                 if test $cf_XOPEN_SOURCE_set_ok = no
3779                 then
3780                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
3781                 fi
3782         else
3783                 CF_TRY_XOPEN_SOURCE
3784         fi
3785 fi
3786 ])