Ada95/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 2010-2013,2014 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.101 2015/04/26 22:09:06 tom Exp $
  32 dnl Macros used in NCURSES Ada95 auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
  43 dnl ------------------
  44 dnl Conditionally generate script according to whether we're using a given autoconf.
  45 dnl
  46 dnl $1 = version to compare against
  47 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  48 dnl $3 = code to use if AC_ACVERSION is older than $1.
  49 define([CF_ACVERSION_CHECK],
  50 [
  51 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
  52 ifdef([m4_version_compare],
  53 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  54 [CF_ACVERSION_COMPARE(
  55 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  56 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  57 dnl ---------------------------------------------------------------------------
  58 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  59 dnl --------------------
  60 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  61 dnl                      MAJOR2, MINOR2, TERNARY2,
  62 dnl                      PRINTABLE2, not FOUND, FOUND)
  63 define([CF_ACVERSION_COMPARE],
  64 [ifelse(builtin([eval], [$2 < $5]), 1,
  65 [ifelse([$8], , ,[$8])],
  66 [ifelse([$9], , ,[$9])])])dnl
  67 dnl ---------------------------------------------------------------------------
  68 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
  69 dnl -------------------
  70 dnl Construct the list of include-options for the C programs in the Ada95
  71 dnl binding.
  72 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  73 [
  74 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  75 if test "$srcdir" != "."; then
  76         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  77 fi
  78 if test "$GCC" != yes; then
  79         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  80 elif test "$includedir" != "/usr/include"; then
  81         if test "$includedir" = '${prefix}/include' ; then
  82                 if test x$prefix != x/usr ; then
  83                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  84                 fi
  85         else
  86                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  87         fi
  88 fi
  89 AC_SUBST(ACPPFLAGS)
  90 ])dnl
  91 dnl ---------------------------------------------------------------------------
  92 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
  93 dnl ---------------
  94 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
  95 AC_DEFUN([CF_ADD_ADAFLAGS],[
  96         ADAFLAGS="$ADAFLAGS $1"
  97         AC_SUBST(ADAFLAGS)
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ADD_CFLAGS version: 12 updated: 2015/04/12 15:39:00
 101 dnl -------------
 102 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 103 dnl The second parameter if given makes this macro verbose.
 104 dnl
 105 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 106 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 107 dnl confused by the quotes (which require backslashes to keep them usable).
 108 AC_DEFUN([CF_ADD_CFLAGS],
 109 [
 110 cf_fix_cppflags=no
 111 cf_new_cflags=
 112 cf_new_cppflags=
 113 cf_new_extra_cppflags=
 114
 115 for cf_add_cflags in $1
 116 do
 117 case $cf_fix_cppflags in
 118 (no)
 119         case $cf_add_cflags in
 120         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 121                 case $cf_add_cflags in
 122                 (-D*)
 123                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 124
 125                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 126                                 && test -z "${cf_tst_cflags}" \
 127                                 && cf_fix_cppflags=yes
 128
 129                         if test $cf_fix_cppflags = yes ; then
 130                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 131                                 continue
 132                         elif test "${cf_tst_cflags}" = "\"'" ; then
 133                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 134                                 continue
 135                         fi
 136                         ;;
 137                 esac
 138                 case "$CPPFLAGS" in
 139                 (*$cf_add_cflags)
 140                         ;;
 141                 (*)
 142                         case $cf_add_cflags in
 143                         (-D*)
 144                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 145                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 146                                 ;;
 147                         esac
 148                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 149                         ;;
 150                 esac
 151                 ;;
 152         (*)
 153                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 154                 ;;
 155         esac
 156         ;;
 157 (yes)
 158         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 159
 160         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 161
 162         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 163                 && test -z "${cf_tst_cflags}" \
 164                 && cf_fix_cppflags=no
 165         ;;
 166 esac
 167 done
 168
 169 if test -n "$cf_new_cflags" ; then
 170         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 171         CFLAGS="$CFLAGS $cf_new_cflags"
 172 fi
 173
 174 if test -n "$cf_new_cppflags" ; then
 175         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 176         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 177 fi
 178
 179 if test -n "$cf_new_extra_cppflags" ; then
 180         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 181         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 182 fi
 183
 184 AC_SUBST(EXTRA_CPPFLAGS)
 185
 186 ])dnl
 187 dnl ---------------------------------------------------------------------------
 188 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 189 dnl -------------
 190 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 191 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 192 dnl but old versions (and some misinstalled ones) need that.  To make things
 193 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 194 dnl the include-path).
 195 AC_DEFUN([CF_ADD_INCDIR],
 196 [
 197 if test -n "$1" ; then
 198   for cf_add_incdir in $1
 199   do
 200         while test $cf_add_incdir != /usr/include
 201         do
 202           if test -d $cf_add_incdir
 203           then
 204                 cf_have_incdir=no
 205                 if test -n "$CFLAGS$CPPFLAGS" ; then
 206                   # a loop is needed to ensure we can add subdirs of existing dirs
 207                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 208                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 209                           cf_have_incdir=yes; break
 210                         fi
 211                   done
 212                 fi
 213
 214                 if test "$cf_have_incdir" = no ; then
 215                   if test "$cf_add_incdir" = /usr/local/include ; then
 216                         if test "$GCC" = yes
 217                         then
 218                           cf_save_CPPFLAGS=$CPPFLAGS
 219                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 220                           AC_TRY_COMPILE([#include <stdio.h>],
 221                                   [printf("Hello")],
 222                                   [],
 223                                   [cf_have_incdir=yes])
 224                           CPPFLAGS=$cf_save_CPPFLAGS
 225                         fi
 226                   fi
 227                 fi
 228
 229                 if test "$cf_have_incdir" = no ; then
 230                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 231                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 232
 233                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 234                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 235                   cf_add_incdir="$cf_top_incdir"
 236                 else
 237                   break
 238                 fi
 239           fi
 240         done
 241   done
 242 fi
 243 ])dnl
 244 dnl ---------------------------------------------------------------------------
 245 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 246 dnl ----------
 247 dnl Add a library, used to enforce consistency.
 248 dnl
 249 dnl $1 = library to add, without the "-l"
 250 dnl $2 = variable to update (default $LIBS)
 251 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 252 dnl ---------------------------------------------------------------------------
 253 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 254 dnl -------------
 255 dnl     Adds to the library-path
 256 dnl
 257 dnl     Some machines have trouble with multiple -L options.
 258 dnl
 259 dnl $1 is the (list of) directory(s) to add
 260 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 261 dnl
 262 AC_DEFUN([CF_ADD_LIBDIR],
 263 [
 264 if test -n "$1" ; then
 265         for cf_add_libdir in $1
 266         do
 267                 if test $cf_add_libdir = /usr/lib ; then
 268                         :
 269                 elif test -d $cf_add_libdir
 270                 then
 271                         cf_have_libdir=no
 272                         if test -n "$LDFLAGS$LIBS" ; then
 273                                 # a loop is needed to ensure we can add subdirs of existing dirs
 274                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 275                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 276                                                 cf_have_libdir=yes; break
 277                                         fi
 278                                 done
 279                         fi
 280                         if test "$cf_have_libdir" = no ; then
 281                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 282                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 283                         fi
 284                 fi
 285         done
 286 fi
 287 ])dnl
 288 dnl ---------------------------------------------------------------------------
 289 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 290 dnl -----------
 291 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 292 dnl prepended to an existing list, since their dependencies are assumed to
 293 dnl already exist in the list.
 294 dnl
 295 dnl $1 = libraries to add, with the "-l", etc.
 296 dnl $2 = variable to update (default $LIBS)
 297 AC_DEFUN([CF_ADD_LIBS],[
 298 cf_add_libs="$1"
 299 # Filter out duplicates - this happens with badly-designed ".pc" files...
 300 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 301 do
 302         for cf_add_2lib in $cf_add_libs
 303         do
 304                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 305                 then
 306                         cf_add_1lib=
 307                         break
 308                 fi
 309         done
 310         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 311 done
 312 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 313 ])dnl
 314 dnl ---------------------------------------------------------------------------
 315 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 316 dnl ------------------
 317 dnl Append to a search-list for a nonstandard header/lib-file
 318 dnl     $1 = the variable to return as result
 319 dnl     $2 = the package name
 320 dnl     $3 = the subdirectory, e.g., bin, include or lib
 321 dnl $4 = the directory under which we will test for subdirectories
 322 dnl $5 = a directory that we do not want $4 to match
 323 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 324 [
 325 test "x$4" != "x$5" && \
 326 test -d "$4" && \
 327 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 328         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 329         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 330         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 331         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 332         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 333         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 334 }
 335 ])dnl
 336 dnl ---------------------------------------------------------------------------
 337 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 338 dnl --------------
 339 dnl Allow user to disable a normally-on option.
 340 AC_DEFUN([CF_ARG_DISABLE],
 341 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 342 dnl ---------------------------------------------------------------------------
 343 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 344 dnl -------------
 345 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 346 dnl values.
 347 dnl
 348 dnl Parameters:
 349 dnl $1 = option name
 350 dnl $2 = help-string
 351 dnl $3 = action to perform if option is not default
 352 dnl $4 = action if perform if option is default
 353 dnl $5 = default option value (either 'yes' or 'no')
 354 AC_DEFUN([CF_ARG_OPTION],
 355 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 356   if test "$enableval" != "$5" ; then
 357 ifelse([$3],,[    :]dnl
 358 ,[    $3]) ifelse([$4],,,[
 359   else
 360     $4])
 361   fi],[enableval=$5 ifelse([$4],,,[
 362   $4
 363 ])dnl
 364   ])])dnl
 365 dnl ---------------------------------------------------------------------------
 366 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 367 dnl -----------
 368 dnl Check for suitable "ar" (archiver) options for updating an archive.
 369 AC_DEFUN([CF_AR_FLAGS],[
 370 AC_REQUIRE([CF_PROG_AR])
 371
 372 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 373         cf_cv_ar_flags=unknown
 374         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 375         do
 376
 377                 # check if $ARFLAGS already contains this choice
 378                 if test "x$ARFLAGS" != "x" ; then
 379                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 380                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 381                                 cf_cv_ar_flags=
 382                                 break
 383                         fi
 384                 fi
 385
 386                 rm -f conftest.$ac_cv_objext
 387                 rm -f conftest.a
 388
 389                 cat >conftest.$ac_ext <<EOF
 390 #line __oline__ "configure"
 391 int     testdata[[3]] = { 123, 456, 789 };
 392 EOF
 393                 if AC_TRY_EVAL(ac_compile) ; then
 394                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 395                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 396                         if test -f conftest.a ; then
 397                                 cf_cv_ar_flags=$cf_ar_flags
 398                                 break
 399                         fi
 400                 else
 401                         CF_VERBOSE(cannot compile test-program)
 402                         break
 403                 fi
 404         done
 405         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 406 ])
 407
 408 if test -n "$ARFLAGS" ; then
 409         if test -n "$cf_cv_ar_flags" ; then
 410                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 411         fi
 412 else
 413         ARFLAGS=$cf_cv_ar_flags
 414 fi
 415
 416 AC_SUBST(ARFLAGS)
 417 ])
 418 dnl ---------------------------------------------------------------------------
 419 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 420 dnl -----------
 421 dnl If we're cross-compiling, allow the user to override the tools and their
 422 dnl options.  The configure script is oriented toward identifying the host
 423 dnl compiler, etc., but we need a build compiler to generate parts of the
 424 dnl source.
 425 dnl
 426 dnl $1 = default for $CPPFLAGS
 427 dnl $2 = default for $LIBS
 428 AC_DEFUN([CF_BUILD_CC],[
 429 CF_ACVERSION_CHECK(2.52,,
 430         [AC_REQUIRE([CF_PROG_EXT])])
 431 if test "$cross_compiling" = yes ; then
 432
 433         # defaults that we might want to override
 434         : ${BUILD_CFLAGS:=''}
 435         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 436         : ${BUILD_LDFLAGS:=''}
 437         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 438         : ${BUILD_EXEEXT:='$x'}
 439         : ${BUILD_OBJEXT:='o'}
 440
 441         AC_ARG_WITH(build-cc,
 442                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 443                 [BUILD_CC="$withval"],
 444                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 445         AC_MSG_CHECKING(for native build C compiler)
 446         AC_MSG_RESULT($BUILD_CC)
 447
 448         AC_MSG_CHECKING(for native build C preprocessor)
 449         AC_ARG_WITH(build-cpp,
 450                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 451                 [BUILD_CPP="$withval"],
 452                 [BUILD_CPP='${BUILD_CC} -E'])
 453         AC_MSG_RESULT($BUILD_CPP)
 454
 455         AC_MSG_CHECKING(for native build C flags)
 456         AC_ARG_WITH(build-cflags,
 457                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 458                 [BUILD_CFLAGS="$withval"])
 459         AC_MSG_RESULT($BUILD_CFLAGS)
 460
 461         AC_MSG_CHECKING(for native build C preprocessor-flags)
 462         AC_ARG_WITH(build-cppflags,
 463                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 464                 [BUILD_CPPFLAGS="$withval"])
 465         AC_MSG_RESULT($BUILD_CPPFLAGS)
 466
 467         AC_MSG_CHECKING(for native build linker-flags)
 468         AC_ARG_WITH(build-ldflags,
 469                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 470                 [BUILD_LDFLAGS="$withval"])
 471         AC_MSG_RESULT($BUILD_LDFLAGS)
 472
 473         AC_MSG_CHECKING(for native build linker-libraries)
 474         AC_ARG_WITH(build-libs,
 475                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 476                 [BUILD_LIBS="$withval"])
 477         AC_MSG_RESULT($BUILD_LIBS)
 478
 479         # this assumes we're on Unix.
 480         BUILD_EXEEXT=
 481         BUILD_OBJEXT=o
 482
 483         : ${BUILD_CC:='${CC}'}
 484
 485         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 486                 AC_MSG_ERROR([Cross-build requires two compilers.
 487 Use --with-build-cc to specify the native compiler.])
 488         fi
 489
 490 else
 491         : ${BUILD_CC:='${CC}'}
 492         : ${BUILD_CPP:='${CPP}'}
 493         : ${BUILD_CFLAGS:='${CFLAGS}'}
 494         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 495         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 496         : ${BUILD_LIBS:='${LIBS}'}
 497         : ${BUILD_EXEEXT:='$x'}
 498         : ${BUILD_OBJEXT:='o'}
 499 fi
 500
 501 AC_SUBST(BUILD_CC)
 502 AC_SUBST(BUILD_CPP)
 503 AC_SUBST(BUILD_CFLAGS)
 504 AC_SUBST(BUILD_CPPFLAGS)
 505 AC_SUBST(BUILD_LDFLAGS)
 506 AC_SUBST(BUILD_LIBS)
 507 AC_SUBST(BUILD_EXEEXT)
 508 AC_SUBST(BUILD_OBJEXT)
 509 ])dnl
 510 dnl ---------------------------------------------------------------------------
 511 dnl CF_CC_ENV_FLAGS version: 2 updated: 2015/04/12 15:39:00
 512 dnl ---------------
 513 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 514 dnl into CC.  This will not help with broken scripts that wrap the compiler with
 515 dnl options, but eliminates a more common category of user confusion.
 516 AC_DEFUN([CF_CC_ENV_FLAGS],
 517 [
 518 # This should have been defined by AC_PROG_CC
 519 : ${CC:=cc}
 520
 521 AC_MSG_CHECKING(\$CC variable)
 522 case "$CC" in
 523 (*[[\ \ ]]-[[IUD]]*)
 524         AC_MSG_RESULT(broken)
 525         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 526         # humor him...
 527         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 528         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 529         CF_ADD_CFLAGS($cf_flags)
 530         ;;
 531 (*)
 532         AC_MSG_RESULT(ok)
 533         ;;
 534 esac
 535 ])dnl
 536 dnl ---------------------------------------------------------------------------
 537 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 538 dnl ---------------
 539 dnl Determine the default configuration into which we'll install ncurses.  This
 540 dnl can be overridden by the user's command-line options.  There's two items to
 541 dnl look for:
 542 dnl     1. the prefix (e.g., /usr)
 543 dnl     2. the header files (e.g., /usr/include/ncurses)
 544 dnl We'll look for a previous installation of ncurses and use the same defaults.
 545 dnl
 546 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 547 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 548 dnl programs from a vendor's.
 549 AC_DEFUN([CF_CFG_DEFAULTS],
 550 [
 551 AC_MSG_CHECKING(for prefix)
 552 if test "x$prefix" = "xNONE" ; then
 553         case "$cf_cv_system_name" in
 554                 # non-vendor systems don't have a conflict
 555         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 556                 prefix=/usr
 557                 ;;
 558         (*)     prefix=$ac_default_prefix
 559                 ;;
 560         esac
 561 fi
 562 AC_MSG_RESULT($prefix)
 563
 564 if test "x$prefix" = "xNONE" ; then
 565 AC_MSG_CHECKING(for default include-directory)
 566 test -n "$verbose" && echo 1>&AC_FD_MSG
 567 for cf_symbol in \
 568         $includedir \
 569         $includedir/ncurses \
 570         $prefix/include \
 571         $prefix/include/ncurses \
 572         /usr/local/include \
 573         /usr/local/include/ncurses \
 574         /usr/include \
 575         /usr/include/ncurses
 576 do
 577         cf_dir=`eval echo $cf_symbol`
 578         if test -f $cf_dir/curses.h ; then
 579         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 580                 includedir="$cf_symbol"
 581                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 582                 break
 583         fi
 584         fi
 585         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 586 done
 587 AC_MSG_RESULT($includedir)
 588 fi
 589 ])dnl
 590 dnl ---------------------------------------------------------------------------
 591 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 592 dnl --------------
 593 dnl Check if we're accidentally using a cache from a different machine.
 594 dnl Derive the system name, as a check for reusing the autoconf cache.
 595 dnl
 596 dnl If we've packaged config.guess and config.sub, run that (since it does a
 597 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 598 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 599 dnl which is useful in cross-compiles.
 600 dnl
 601 dnl Note: we would use $ac_config_sub, but that is one of the places where
 602 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 603 AC_DEFUN([CF_CHECK_CACHE],
 604 [
 605 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 606         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 607         system_name="$host_os"
 608 else
 609         system_name="`(uname -s -r) 2>/dev/null`"
 610         if test -z "$system_name" ; then
 611                 system_name="`(hostname) 2>/dev/null`"
 612         fi
 613 fi
 614 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 615 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 616
 617 test -z "$system_name" && system_name="$cf_cv_system_name"
 618 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 619
 620 if test ".$system_name" != ".$cf_cv_system_name" ; then
 621         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 622         AC_MSG_ERROR("Please remove config.cache and try again.")
 623 fi
 624 ])dnl
 625 dnl ---------------------------------------------------------------------------
 626 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
 627 dnl -----------------
 628 dnl Check if the given compiler is really clang.  clang's C driver defines
 629 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 630 dnl not ignore some gcc options.
 631 dnl
 632 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 633 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 634 dnl the wrappers for gcc and g++ warnings.
 635 dnl
 636 dnl $1 = GCC (default) or GXX
 637 dnl $2 = CLANG_COMPILER (default)
 638 dnl $3 = CFLAGS (default) or CXXFLAGS
 639 AC_DEFUN([CF_CLANG_COMPILER],[
 640 ifelse([$2],,CLANG_COMPILER,[$2])=no
 641
 642 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 643         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 644         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 645         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 646         AC_TRY_COMPILE([],[
 647 #ifdef __clang__
 648 #else
 649 make an error
 650 #endif
 651 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 652 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
 653 ],[])
 654         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 655         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 656 fi
 657 ])
 658 dnl ---------------------------------------------------------------------------
 659 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
 660 dnl ----------------
 661 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 662 dnl variations of ncurses' installs.
 663 dnl
 664 dnl $1 = ncurses when looking for ncurses, or is empty
 665 AC_DEFUN([CF_CURSES_HEADER],[
 666 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 667 cf_cv_ncurses_header=none
 668 for cf_header in \
 669         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
 670         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 671 do
 672 AC_TRY_COMPILE([#include <${cf_header}>],
 673         [initscr(); tgoto("?", 0,0)],
 674         [cf_cv_ncurses_header=$cf_header; break],[])
 675 done
 676 ])
 677
 678 if test "$cf_cv_ncurses_header" = none ; then
 679         AC_MSG_ERROR(No curses header-files found)
 680 fi
 681
 682 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 683 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 684 ])dnl
 685 dnl ---------------------------------------------------------------------------
 686 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
 687 dnl ----------
 688 dnl "dirname" is not portable, so we fake it with a shell script.
 689 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
 690 dnl ---------------------------------------------------------------------------
 691 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
 692 dnl ---------------
 693 dnl You can always use "make -n" to see the actual options, but it's hard to
 694 dnl pick out/analyze warning messages when the compile-line is long.
 695 dnl
 696 dnl Sets:
 697 dnl     ECHO_LT - symbol to control if libtool is verbose
 698 dnl     ECHO_LD - symbol to prefix "cc -o" lines
 699 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
 700 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
 701 dnl     ECHO_CC - symbol to put before any "cc" line
 702 dnl
 703 AC_DEFUN([CF_DISABLE_ECHO],[
 704 AC_MSG_CHECKING(if you want to see long compiling messages)
 705 CF_ARG_DISABLE(echo,
 706         [  --disable-echo          do not display "compiling" commands],
 707         [
 708         ECHO_LT='--silent'
 709         ECHO_LD='@echo linking [$]@;'
 710         RULE_CC='@echo compiling [$]<'
 711         SHOW_CC='@echo compiling [$]@'
 712         ECHO_CC='@'
 713 ],[
 714         ECHO_LT=''
 715         ECHO_LD=''
 716         RULE_CC=''
 717         SHOW_CC=''
 718         ECHO_CC=''
 719 ])
 720 AC_MSG_RESULT($enableval)
 721 AC_SUBST(ECHO_LT)
 722 AC_SUBST(ECHO_LD)
 723 AC_SUBST(RULE_CC)
 724 AC_SUBST(SHOW_CC)
 725 AC_SUBST(ECHO_CC)
 726 ])dnl
 727 dnl ---------------------------------------------------------------------------
 728 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
 729 dnl ------------------------
 730 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
 731 AC_MSG_CHECKING(if we want to use GNAT projects)
 732 CF_ARG_DISABLE(gnat-projects,
 733         [  --disable-gnat-projects test: disable GNAT projects even if usable],
 734         [enable_gnat_projects=no],
 735         [enable_gnat_projects=yes])
 736 AC_MSG_RESULT($enable_gnat_projects)
 737 ])dnl
 738 dnl ---------------------------------------------------------------------------
 739 dnl CF_ENABLE_PC_FILES version: 12 updated: 2015/04/17 21:13:04
 740 dnl ------------------
 741 dnl This is the "--enable-pc-files" option, which is available if there is a
 742 dnl pkg-config configuration on the local machine.
 743 AC_DEFUN([CF_ENABLE_PC_FILES],[
 744 AC_REQUIRE([CF_PKG_CONFIG])
 745 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
 746
 747 if test "x$PKG_CONFIG" != xnone
 748 then
 749         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
 750 else
 751         AC_MSG_CHECKING(if we should install .pc files)
 752 fi
 753
 754 AC_ARG_ENABLE(pc-files,
 755         [  --enable-pc-files       generate and install .pc files for pkg-config],
 756         [enable_pc_files=$enableval],
 757         [enable_pc_files=no])
 758 AC_MSG_RESULT($enable_pc_files)
 759
 760 if test "x$enable_pc_files" != xno
 761 then
 762         case "x$PKG_CONFIG_LIBDIR" in
 763         (xno|xyes)
 764                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
 765                 MAKE_PC_FILES="#"
 766                 ;;
 767         (*)
 768                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
 769                 MAKE_PC_FILES=
 770                 ;;
 771         esac
 772 else
 773         MAKE_PC_FILES="#"
 774 fi
 775 AC_SUBST(MAKE_PC_FILES)
 776 ])dnl
 777 dnl ---------------------------------------------------------------------------
 778 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
 779 dnl ---------------
 780 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
 781 dnl prefer a standard location, and use -L options only if we do not find the
 782 dnl library in the standard library location(s).
 783 dnl     $1 = library name
 784 dnl     $2 = library class, usually the same as library name
 785 dnl     $3 = includes
 786 dnl     $4 = code fragment to compile/link
 787 dnl     $5 = corresponding function-name
 788 dnl     $6 = flag, nonnull if failure should not cause an error-exit
 789 dnl
 790 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
 791 dnl to use a -L option.
 792 AC_DEFUN([CF_FIND_LIBRARY],
 793 [
 794         eval 'cf_cv_have_lib_'$1'=no'
 795         cf_libdir=""
 796         AC_CHECK_FUNC($5,
 797                 eval 'cf_cv_have_lib_'$1'=yes',[
 798                 cf_save_LIBS="$LIBS"
 799                 AC_MSG_CHECKING(for $5 in -l$1)
 800                 LIBS="-l$1 $LIBS"
 801                 AC_TRY_LINK([$3],[$4],
 802                         [AC_MSG_RESULT(yes)
 803                          eval 'cf_cv_have_lib_'$1'=yes'
 804                         ],
 805                         [AC_MSG_RESULT(no)
 806                         CF_LIBRARY_PATH(cf_search,$2)
 807                         for cf_libdir in $cf_search
 808                         do
 809                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
 810                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
 811                                 AC_TRY_LINK([$3],[$4],
 812                                         [AC_MSG_RESULT(yes)
 813                                          eval 'cf_cv_have_lib_'$1'=yes'
 814                                          break],
 815                                         [AC_MSG_RESULT(no)
 816                                          LIBS="$cf_save_LIBS"])
 817                         done
 818                         ])
 819                 ])
 820 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
 821 ifelse($6,,[
 822 if test $cf_found_library = no ; then
 823         AC_MSG_ERROR(Cannot link $1 library)
 824 fi
 825 ])
 826 ])dnl
 827 dnl ---------------------------------------------------------------------------
 828 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
 829 dnl ---------------
 830 dnl Find a library (specifically the linkage used in the code fragment),
 831 dnl searching for it if it is not already in the library path.
 832 dnl See also CF_ADD_SEARCHPATH.
 833 dnl
 834 dnl Parameters (4-on are optional):
 835 dnl     $1 = headers for library entrypoint
 836 dnl     $2 = code fragment for library entrypoint
 837 dnl     $3 = the library name without the "-l" option or ".so" suffix.
 838 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
 839 dnl     $5 = action to perform if not successful
 840 dnl     $6 = module name, if not the same as the library name
 841 dnl     $7 = extra libraries
 842 dnl
 843 dnl Sets these variables:
 844 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
 845 dnl     $cf_cv_header_path_$3 - include-directory if needed
 846 dnl     $cf_cv_library_path_$3 - library-directory if needed
 847 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
 848 AC_DEFUN([CF_FIND_LINKAGE],[
 849
 850 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
 851 # will be set on completion of the AC_TRY_LINK below.
 852 cf_cv_header_path_$3=
 853 cf_cv_library_path_$3=
 854
 855 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
 856
 857 cf_save_LIBS="$LIBS"
 858
 859 AC_TRY_LINK([$1],[$2],[
 860         cf_cv_find_linkage_$3=yes
 861         cf_cv_header_path_$3=/usr/include
 862         cf_cv_library_path_$3=/usr/lib
 863 ],[
 864
 865 LIBS="-l$3 $7 $cf_save_LIBS"
 866
 867 AC_TRY_LINK([$1],[$2],[
 868         cf_cv_find_linkage_$3=yes
 869         cf_cv_header_path_$3=/usr/include
 870         cf_cv_library_path_$3=/usr/lib
 871         cf_cv_library_file_$3="-l$3"
 872 ],[
 873         cf_cv_find_linkage_$3=no
 874         LIBS="$cf_save_LIBS"
 875
 876         CF_VERBOSE(find linkage for $3 library)
 877         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
 878
 879         cf_save_CPPFLAGS="$CPPFLAGS"
 880         cf_test_CPPFLAGS="$CPPFLAGS"
 881
 882         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
 883         for cf_cv_header_path_$3 in $cf_search
 884         do
 885                 if test -d $cf_cv_header_path_$3 ; then
 886                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
 887                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
 888                         AC_TRY_COMPILE([$1],[$2],[
 889                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
 890                                 cf_cv_find_linkage_$3=maybe
 891                                 cf_test_CPPFLAGS="$CPPFLAGS"
 892                                 break],[
 893                                 CPPFLAGS="$cf_save_CPPFLAGS"
 894                                 ])
 895                 fi
 896         done
 897
 898         if test "$cf_cv_find_linkage_$3" = maybe ; then
 899
 900                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
 901
 902                 cf_save_LIBS="$LIBS"
 903                 cf_save_LDFLAGS="$LDFLAGS"
 904
 905                 ifelse([$6],,,[
 906                 CPPFLAGS="$cf_test_CPPFLAGS"
 907                 LIBS="-l$3 $7 $cf_save_LIBS"
 908                 AC_TRY_LINK([$1],[$2],[
 909                         CF_VERBOSE(... found $3 library in system)
 910                         cf_cv_find_linkage_$3=yes])
 911                         CPPFLAGS="$cf_save_CPPFLAGS"
 912                         LIBS="$cf_save_LIBS"
 913                         ])
 914
 915                 if test "$cf_cv_find_linkage_$3" != yes ; then
 916                         CF_LIBRARY_PATH(cf_search,$3)
 917                         for cf_cv_library_path_$3 in $cf_search
 918                         do
 919                                 if test -d $cf_cv_library_path_$3 ; then
 920                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
 921                                         CPPFLAGS="$cf_test_CPPFLAGS"
 922                                         LIBS="-l$3 $7 $cf_save_LIBS"
 923                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
 924                                         AC_TRY_LINK([$1],[$2],[
 925                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
 926                                         cf_cv_find_linkage_$3=yes
 927                                         cf_cv_library_file_$3="-l$3"
 928                                         break],[
 929                                         CPPFLAGS="$cf_save_CPPFLAGS"
 930                                         LIBS="$cf_save_LIBS"
 931                                         LDFLAGS="$cf_save_LDFLAGS"
 932                                         ])
 933                                 fi
 934                         done
 935                         CPPFLAGS="$cf_save_CPPFLAGS"
 936                         LDFLAGS="$cf_save_LDFLAGS"
 937                 fi
 938
 939         else
 940                 cf_cv_find_linkage_$3=no
 941         fi
 942         ],$7)
 943 ])
 944
 945 LIBS="$cf_save_LIBS"
 946
 947 if test "$cf_cv_find_linkage_$3" = yes ; then
 948 ifelse([$4],,[
 949         CF_ADD_INCDIR($cf_cv_header_path_$3)
 950         CF_ADD_LIBDIR($cf_cv_library_path_$3)
 951         CF_ADD_LIB($3)
 952 ],[$4])
 953 else
 954 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
 955 fi
 956 ])dnl
 957 dnl ---------------------------------------------------------------------------
 958 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
 959 dnl -----------------
 960 dnl make ADAFLAGS consistent with CFLAGS
 961 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
 962         AC_MSG_CHECKING(optimization options for ADAFLAGS)
 963         case "$CFLAGS" in
 964         (*-g*)
 965                 CF_ADD_ADAFLAGS(-g)
 966                 ;;
 967         esac
 968         case "$CFLAGS" in
 969         (*-O*)
 970                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
 971                 CF_ADD_ADAFLAGS($cf_O_flag)
 972                 ;;
 973         esac
 974         AC_MSG_RESULT($ADAFLAGS)
 975 ])dnl
 976 dnl ---------------------------------------------------------------------------
 977 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
 978 dnl -----------------
 979 dnl Test for availability of useful gcc __attribute__ directives to quiet
 980 dnl compiler warnings.  Though useful, not all are supported -- and contrary
 981 dnl to documentation, unrecognized directives cause older compilers to barf.
 982 AC_DEFUN([CF_GCC_ATTRIBUTES],
 983 [
 984 if test "$GCC" = yes
 985 then
 986 cat > conftest.i <<EOF
 987 #ifndef GCC_PRINTF
 988 #define GCC_PRINTF 0
 989 #endif
 990 #ifndef GCC_SCANF
 991 #define GCC_SCANF 0
 992 #endif
 993 #ifndef GCC_NORETURN
 994 #define GCC_NORETURN /* nothing */
 995 #endif
 996 #ifndef GCC_UNUSED
 997 #define GCC_UNUSED /* nothing */
 998 #endif
 999 EOF
1000 if test "$GCC" = yes
1001 then
1002         AC_CHECKING([for $CC __attribute__ directives])
1003 cat > conftest.$ac_ext <<EOF
1004 #line __oline__ "${as_me:-configure}"
1005 #include "confdefs.h"
1006 #include "conftest.h"
1007 #include "conftest.i"
1008 #if     GCC_PRINTF
1009 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1010 #else
1011 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1012 #endif
1013 #if     GCC_SCANF
1014 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1015 #else
1016 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1017 #endif
1018 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1019 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1020 extern void foo(void) GCC_NORETURN;
1021 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1022 EOF
1023         cf_printf_attribute=no
1024         cf_scanf_attribute=no
1025         for cf_attribute in scanf printf unused noreturn
1026         do
1027                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1028                 cf_directive="__attribute__(($cf_attribute))"
1029                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1030
1031                 case $cf_attribute in
1032                 (printf)
1033                         cf_printf_attribute=yes
1034                         cat >conftest.h <<EOF
1035 #define GCC_$cf_ATTRIBUTE 1
1036 EOF
1037                         ;;
1038                 (scanf)
1039                         cf_scanf_attribute=yes
1040                         cat >conftest.h <<EOF
1041 #define GCC_$cf_ATTRIBUTE 1
1042 EOF
1043                         ;;
1044                 (*)
1045                         cat >conftest.h <<EOF
1046 #define GCC_$cf_ATTRIBUTE $cf_directive
1047 EOF
1048                         ;;
1049                 esac
1050
1051                 if AC_TRY_EVAL(ac_compile); then
1052                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1053                         cat conftest.h >>confdefs.h
1054                         case $cf_attribute in
1055                         (noreturn)
1056                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1057                                 ;;
1058                         (printf)
1059                                 cf_value='/* nothing */'
1060                                 if test "$cf_printf_attribute" != no ; then
1061                                         cf_value='__attribute__((format(printf,fmt,var)))'
1062                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1063                                 fi
1064                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1065                                 ;;
1066                         (scanf)
1067                                 cf_value='/* nothing */'
1068                                 if test "$cf_scanf_attribute" != no ; then
1069                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1070                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1071                                 fi
1072                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1073                                 ;;
1074                         (unused)
1075                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1076                                 ;;
1077                         esac
1078                 fi
1079         done
1080 else
1081         fgrep define conftest.i >>confdefs.h
1082 fi
1083 rm -rf conftest*
1084 fi
1085 ])dnl
1086 dnl ---------------------------------------------------------------------------
1087 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1088 dnl --------------
1089 dnl Find version of gcc
1090 AC_DEFUN([CF_GCC_VERSION],[
1091 AC_REQUIRE([AC_PROG_CC])
1092 GCC_VERSION=none
1093 if test "$GCC" = yes ; then
1094         AC_MSG_CHECKING(version of $CC)
1095         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1096         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1097         AC_MSG_RESULT($GCC_VERSION)
1098 fi
1099 ])dnl
1100 dnl ---------------------------------------------------------------------------
1101 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
1102 dnl ---------------
1103 dnl Check if the compiler supports useful warning options.  There's a few that
1104 dnl we don't use, simply because they're too noisy:
1105 dnl
1106 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1107 dnl     -Wredundant-decls (system headers make this too noisy)
1108 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1109 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1110 dnl             is enabled for ncurses using "--enable-const".
1111 dnl     -pedantic
1112 dnl
1113 dnl Parameter:
1114 dnl     $1 is an optional list of gcc warning flags that a particular
1115 dnl             application might want to use, e.g., "no-unused" for
1116 dnl             -Wno-unused
1117 dnl Special:
1118 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1119 dnl
1120 AC_DEFUN([CF_GCC_WARNINGS],
1121 [
1122 AC_REQUIRE([CF_GCC_VERSION])
1123 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1124 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1125
1126 cat > conftest.$ac_ext <<EOF
1127 #line __oline__ "${as_me:-configure}"
1128 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1129 EOF
1130
1131 if test "$INTEL_COMPILER" = yes
1132 then
1133 # The "-wdXXX" options suppress warnings:
1134 # remark #1419: external declaration in primary source file
1135 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1136 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1137 # remark #193: zero used for undefined preprocessing identifier
1138 # remark #593: variable "curs_sb_left_arrow" was set but never used
1139 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1140 # remark #869: parameter "tw" was never referenced
1141 # remark #981: operands are evaluated in unspecified order
1142 # warning #279: controlling expression is constant
1143
1144         AC_CHECKING([for $CC warning options])
1145         cf_save_CFLAGS="$CFLAGS"
1146         EXTRA_CFLAGS="-Wall"
1147         for cf_opt in \
1148                 wd1419 \
1149                 wd1683 \
1150                 wd1684 \
1151                 wd193 \
1152                 wd593 \
1153                 wd279 \
1154                 wd810 \
1155                 wd869 \
1156                 wd981
1157         do
1158                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1159                 if AC_TRY_EVAL(ac_compile); then
1160                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1161                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1162                 fi
1163         done
1164         CFLAGS="$cf_save_CFLAGS"
1165
1166 elif test "$GCC" = yes
1167 then
1168         AC_CHECKING([for $CC warning options])
1169         cf_save_CFLAGS="$CFLAGS"
1170         EXTRA_CFLAGS=
1171         cf_warn_CONST=""
1172         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1173         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1174         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1175         for cf_opt in W Wall \
1176                 Wbad-function-cast \
1177                 Wcast-align \
1178                 Wcast-qual \
1179                 Wdeclaration-after-statement \
1180                 Wextra \
1181                 Winline \
1182                 Wmissing-declarations \
1183                 Wmissing-prototypes \
1184                 Wnested-externs \
1185                 Wpointer-arith \
1186                 Wshadow \
1187                 Wstrict-prototypes \
1188                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
1189         do
1190                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1191                 if AC_TRY_EVAL(ac_compile); then
1192                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1193                         case $cf_opt in
1194                         (Wcast-qual)
1195                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1196                                 ;;
1197                         (Winline)
1198                                 case $GCC_VERSION in
1199                                 ([[34]].*)
1200                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1201                                         continue;;
1202                                 esac
1203                                 ;;
1204                         (Wpointer-arith)
1205                                 case $GCC_VERSION in
1206                                 ([[12]].*)
1207                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1208                                         continue;;
1209                                 esac
1210                                 ;;
1211                         esac
1212                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1213                 fi
1214         done
1215         CFLAGS="$cf_save_CFLAGS"
1216 fi
1217 rm -rf conftest*
1218
1219 AC_SUBST(EXTRA_CFLAGS)
1220 ])dnl
1221 dnl ---------------------------------------------------------------------------
1222 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
1223 dnl -----------------
1224 AC_DEFUN([CF_GNATPREP_OPT_T],[
1225 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
1226 cf_cv_gnatprep_opt_t=no
1227 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
1228 ])
1229 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
1230 AC_SUBST(GNATPREP_OPTS)
1231 ])dnl
1232 dnl ---------------------------------------------------------------------------
1233 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
1234 dnl ----------------
1235 AC_DEFUN([CF_GNAT_GENERICS],
1236 [
1237 AC_REQUIRE([CF_GNAT_VERSION])
1238
1239 AC_MSG_CHECKING(if GNAT supports generics)
1240 case $cf_gnat_version in
1241 (3.[[1-9]]*|[[4-9]].*)
1242         cf_gnat_generics=yes
1243         ;;
1244 (*)
1245         cf_gnat_generics=no
1246         ;;
1247 esac
1248 AC_MSG_RESULT($cf_gnat_generics)
1249
1250 if test "$cf_gnat_generics" = yes
1251 then
1252         cf_compile_generics=generics
1253         cf_generic_objects="\${GENOBJS}"
1254 else
1255         cf_compile_generics=
1256         cf_generic_objects=
1257 fi
1258
1259 AC_SUBST(cf_compile_generics)
1260 AC_SUBST(cf_generic_objects)
1261 ])dnl
1262 dnl ---------------------------------------------------------------------------
1263 dnl CF_GNAT_PROJECTS version: 8 updated: 2015/04/17 21:13:04
1264 dnl ----------------
1265 dnl GNAT projects are configured with ".gpr" project files.
1266 dnl GNAT libraries are a further development, using the project feature.
1267 AC_DEFUN([CF_GNAT_PROJECTS],
1268 [
1269 AC_REQUIRE([CF_GNAT_VERSION])
1270 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
1271
1272 cf_gnat_libraries=no
1273 cf_gnat_projects=no
1274
1275 if test "$enable_gnat_projects" != no ; then
1276 AC_MSG_CHECKING(if GNAT supports project files)
1277 case $cf_gnat_version in
1278 (3.[[0-9]]*)
1279         ;;
1280 (*)
1281         case $cf_cv_system_name in
1282         (cygwin*|msys*)
1283                 ;;
1284         (*)
1285                 mkdir conftest.src conftest.bin conftest.lib
1286                 cd conftest.src
1287                 rm -rf conftest* *~conftest*
1288                 cat >>library.gpr <<CF_EOF
1289 project Library is
1290   Kind := External ("LIB_KIND");
1291   for Library_Name use "ConfTest";
1292   for Object_Dir use ".";
1293   for Library_ALI_Dir use External("LIBRARY_DIR");
1294   for Library_Version use External ("SONAME");
1295   for Library_Kind use Kind;
1296   for Library_Dir use External("BUILD_DIR");
1297   Source_Dir := External ("SOURCE_DIR");
1298   for Source_Dirs use (Source_Dir);
1299 end Library;
1300 CF_EOF
1301                 cat >>confpackage.ads <<CF_EOF
1302 package ConfPackage is
1303    procedure conftest;
1304 end ConfPackage;
1305 CF_EOF
1306                 cat >>confpackage.adb <<CF_EOF
1307 with Text_IO;
1308 package body ConfPackage is
1309    procedure conftest is
1310    begin
1311       Text_IO.Put ("Hello World");
1312       Text_IO.New_Line;
1313    end conftest;
1314 end ConfPackage;
1315 CF_EOF
1316                 if ( $cf_ada_make $ADAFLAGS \
1317                                 -Plibrary.gpr \
1318                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
1319                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
1320                                 -XSOURCE_DIR=`pwd` \
1321                                 -XSONAME=libConfTest.so.1 \
1322                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1323                         cf_gnat_projects=yes
1324                 fi
1325                 cd ..
1326                 if test -f conftest.lib/confpackage.ali
1327                 then
1328                         cf_gnat_libraries=yes
1329                 fi
1330                 rm -rf conftest* *~conftest*
1331                 ;;
1332         esac
1333         ;;
1334 esac
1335 AC_MSG_RESULT($cf_gnat_projects)
1336 fi # enable_gnat_projects
1337
1338 if test $cf_gnat_projects = yes
1339 then
1340         AC_MSG_CHECKING(if GNAT supports libraries)
1341         AC_MSG_RESULT($cf_gnat_libraries)
1342 fi
1343
1344 if test "$cf_gnat_projects" = yes
1345 then
1346         USE_OLD_MAKERULES="#"
1347         USE_GNAT_PROJECTS=""
1348 else
1349         USE_OLD_MAKERULES=""
1350         USE_GNAT_PROJECTS="#"
1351 fi
1352
1353 if test "$cf_gnat_libraries" = yes
1354 then
1355         USE_GNAT_LIBRARIES=""
1356 else
1357         USE_GNAT_LIBRARIES="#"
1358 fi
1359
1360 AC_SUBST(USE_OLD_MAKERULES)
1361 AC_SUBST(USE_GNAT_PROJECTS)
1362 AC_SUBST(USE_GNAT_LIBRARIES)
1363 ])dnl
1364 dnl ---------------------------------------------------------------------------
1365 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
1366 dnl --------------
1367 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1368 dnl is noted that gnat may compile a tasking unit even for configurations which
1369 dnl fail at runtime.
1370 AC_DEFUN([CF_GNAT_SIGINT],[
1371 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1372 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1373
1374 package ConfTest is
1375
1376    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1377    pragma Unreserve_All_Interrupts;
1378    pragma Warnings (On);
1379
1380    protected Process is
1381       procedure Stop;
1382       function Continue return Boolean;
1383       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1384    private
1385       Done : Boolean := False;
1386    end Process;
1387
1388 end ConfTest;],
1389 [package body ConfTest is
1390    protected body Process is
1391       procedure Stop is
1392       begin
1393          Done := True;
1394       end Stop;
1395       function Continue return Boolean is
1396       begin
1397          return not Done;
1398       end Continue;
1399    end Process;
1400 end ConfTest;],
1401         [cf_cv_gnat_sigint=yes],
1402         [cf_cv_gnat_sigint=no])])
1403
1404 if test $cf_cv_gnat_sigint = yes ; then
1405         USE_GNAT_SIGINT=""
1406 else
1407         USE_GNAT_SIGINT="#"
1408 fi
1409 AC_SUBST(USE_GNAT_SIGINT)
1410 ])dnl
1411 dnl ---------------------------------------------------------------------------
1412 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
1413 dnl ----------------
1414 dnl Verify that a test program compiles/links with GNAT.
1415 dnl $cf_ada_make is set to the program that compiles/links
1416 dnl $ADAFLAGS may be set to the GNAT flags.
1417 dnl
1418 dnl $1 is the text of the spec
1419 dnl $2 is the text of the body
1420 dnl $3 is the shell command to execute if successful
1421 dnl $4 is the shell command to execute if not successful
1422 AC_DEFUN([CF_GNAT_TRY_LINK],
1423 [
1424 rm -rf conftest* *~conftest*
1425 cat >>conftest.ads <<CF_EOF
1426 $1
1427 CF_EOF
1428 cat >>conftest.adb <<CF_EOF
1429 $2
1430 CF_EOF
1431 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1432 ifelse($3,,      :,[      $3])
1433 ifelse($4,,,[else
1434    $4])
1435 fi
1436 rm -rf conftest* *~conftest*
1437 ])dnl
1438 dnl ---------------------------------------------------------------------------
1439 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
1440 dnl ---------------
1441 dnl Verify that a test program compiles and runs with GNAT
1442 dnl $cf_ada_make is set to the program that compiles/links
1443 dnl $ADAFLAGS may be set to the GNAT flags.
1444 dnl
1445 dnl $1 is the text of the spec
1446 dnl $2 is the text of the body
1447 dnl $3 is the shell command to execute if successful
1448 dnl $4 is the shell command to execute if not successful
1449 AC_DEFUN([CF_GNAT_TRY_RUN],
1450 [
1451 rm -rf conftest* *~conftest*
1452 cat >>conftest.ads <<CF_EOF
1453 $1
1454 CF_EOF
1455 cat >>conftest.adb <<CF_EOF
1456 $2
1457 CF_EOF
1458 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1459    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1460 ifelse($3,,      :,[      $3])
1461 ifelse($4,,,[   else
1462       $4])
1463    fi
1464 ifelse($4,,,[else
1465    $4])
1466 fi
1467 rm -rf conftest* *~conftest*
1468 ])dnl
1469 dnl ---------------------------------------------------------------------------
1470 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
1471 dnl ---------------
1472 dnl Verify version of GNAT.
1473 AC_DEFUN([CF_GNAT_VERSION],
1474 [
1475 AC_MSG_CHECKING(for gnat version)
1476 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
1477         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1478         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1479 AC_MSG_RESULT($cf_gnat_version)
1480
1481 case $cf_gnat_version in
1482 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
1483         cf_cv_prog_gnat_correct=yes
1484         ;;
1485 (*)
1486         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1487         cf_cv_prog_gnat_correct=no
1488         ;;
1489 esac
1490 ])
1491 dnl ---------------------------------------------------------------------------
1492 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
1493 dnl -------------
1494 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1495 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1496 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1497 dnl since it is interwoven with GNU extensions.
1498 dnl
1499 dnl Well, yes we could work around it...
1500 AC_DEFUN([CF_GNU_SOURCE],
1501 [
1502 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1503 AC_TRY_COMPILE([#include <sys/types.h>],[
1504 #ifndef _XOPEN_SOURCE
1505 make an error
1506 #endif],
1507         [cf_cv_gnu_source=no],
1508         [cf_save="$CPPFLAGS"
1509          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1510          AC_TRY_COMPILE([#include <sys/types.h>],[
1511 #ifdef _XOPEN_SOURCE
1512 make an error
1513 #endif],
1514         [cf_cv_gnu_source=no],
1515         [cf_cv_gnu_source=yes])
1516         CPPFLAGS="$cf_save"
1517         ])
1518 ])
1519 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1520 ])dnl
1521 dnl ---------------------------------------------------------------------------
1522 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
1523 dnl --------------
1524 dnl Construct a search-list of directories for a nonstandard header-file
1525 dnl
1526 dnl Parameters
1527 dnl     $1 = the variable to return as result
1528 dnl     $2 = the package name
1529 AC_DEFUN([CF_HEADER_PATH],
1530 [
1531 $1=
1532
1533 # collect the current set of include-directories from compiler flags
1534 cf_header_path_list=""
1535 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1536         for cf_header_path in $CPPFLAGS $CFLAGS
1537         do
1538                 case $cf_header_path in
1539                 (-I*)
1540                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1541                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1542                         cf_header_path_list="$cf_header_path_list [$]$1"
1543                         ;;
1544                 esac
1545         done
1546 fi
1547
1548 # add the variations for the package we are looking for
1549 CF_SUBDIR_PATH($1,$2,include)
1550
1551 test "$includedir" != NONE && \
1552 test "$includedir" != "/usr/include" && \
1553 test -d "$includedir" && {
1554         test -d $includedir &&    $1="[$]$1 $includedir"
1555         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1556 }
1557
1558 test "$oldincludedir" != NONE && \
1559 test "$oldincludedir" != "/usr/include" && \
1560 test -d "$oldincludedir" && {
1561         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1562         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1563 }
1564
1565 $1="[$]$1 $cf_header_path_list"
1566 ])dnl
1567 dnl ---------------------------------------------------------------------------
1568 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1569 dnl ---------------
1570 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1571 AC_DEFUN([CF_HELP_MESSAGE],
1572 [AC_DIVERT_HELP([$1])dnl
1573 ])dnl
1574 dnl ---------------------------------------------------------------------------
1575 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
1576 dnl ---------------
1577 dnl Construct the list of include-options according to whether we're building
1578 dnl in the source directory or using '--srcdir=DIR' option.
1579 AC_DEFUN([CF_INCLUDE_DIRS],
1580 [
1581 if test "$srcdir" != "."; then
1582         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
1583 fi
1584 CPPFLAGS="-I../include $CPPFLAGS"
1585 if test "$srcdir" != "."; then
1586         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
1587 fi
1588 CPPFLAGS="-I. $CPPFLAGS"
1589 AC_SUBST(CPPFLAGS)
1590 ])dnl
1591 dnl ---------------------------------------------------------------------------
1592 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
1593 dnl -----------------
1594 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1595 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1596 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1597 dnl
1598 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1599 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1600 dnl the wrappers for gcc and g++ warnings.
1601 dnl
1602 dnl $1 = GCC (default) or GXX
1603 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1604 dnl $3 = CFLAGS (default) or CXXFLAGS
1605 AC_DEFUN([CF_INTEL_COMPILER],[
1606 AC_REQUIRE([AC_CANONICAL_HOST])
1607 ifelse([$2],,INTEL_COMPILER,[$2])=no
1608
1609 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1610         case $host_os in
1611         (linux*|gnu*)
1612                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1613                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1614                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1615                 AC_TRY_COMPILE([],[
1616 #ifdef __INTEL_COMPILER
1617 #else
1618 make an error
1619 #endif
1620 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1621 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
1622 ],[])
1623                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1624                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1625                 ;;
1626         esac
1627 fi
1628 ])dnl
1629 dnl ---------------------------------------------------------------------------
1630 dnl CF_LARGEFILE version: 9 updated: 2015/04/18 08:56:57
1631 dnl ------------
1632 dnl Add checks for large file support.
1633 AC_DEFUN([CF_LARGEFILE],[
1634 ifdef([AC_FUNC_FSEEKO],[
1635         AC_SYS_LARGEFILE
1636         if test "$enable_largefile" != no ; then
1637         AC_FUNC_FSEEKO
1638
1639         # Normally we would collect these definitions in the config.h,
1640         # but (like _XOPEN_SOURCE), some environments rely on having these
1641         # defined before any of the system headers are included.  Another
1642         # case comes up with C++, e.g., on AIX the compiler compiles the
1643         # header files by themselves before looking at the body files it is
1644         # told to compile.  For ncurses, those header files do not include
1645         # the config.h
1646         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
1647         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
1648         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
1649
1650         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
1651                 AC_TRY_COMPILE([
1652 #include <sys/types.h>
1653 #include <dirent.h>
1654                 ],[
1655                 /* if transitional largefile support is setup, this is true */
1656                 extern struct dirent64 * readdir(DIR *);
1657                 struct dirent64 *x = readdir((DIR *)0);
1658                 struct dirent *y = readdir((DIR *)0);
1659                 int z = x - y;
1660                 ],
1661                 [cf_cv_struct_dirent64=yes],
1662                 [cf_cv_struct_dirent64=no])
1663         ])
1664         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
1665         fi
1666 ])
1667 ])
1668 dnl ---------------------------------------------------------------------------
1669 dnl CF_LD_RPATH_OPT version: 6 updated: 2015/04/12 15:39:00
1670 dnl ---------------
1671 dnl For the given system and compiler, find the compiler flags to pass to the
1672 dnl loader to use the "rpath" feature.
1673 AC_DEFUN([CF_LD_RPATH_OPT],
1674 [
1675 AC_REQUIRE([CF_CHECK_CACHE])
1676
1677 LD_RPATH_OPT=
1678 AC_MSG_CHECKING(for an rpath option)
1679 case $cf_cv_system_name in
1680 (irix*)
1681         if test "$GCC" = yes; then
1682                 LD_RPATH_OPT="-Wl,-rpath,"
1683         else
1684                 LD_RPATH_OPT="-rpath "
1685         fi
1686         ;;
1687 (linux*|gnu*|k*bsd*-gnu)
1688         LD_RPATH_OPT="-Wl,-rpath,"
1689         ;;
1690 (openbsd[[2-9]].*|mirbsd*)
1691         LD_RPATH_OPT="-Wl,-rpath,"
1692         ;;
1693 (dragonfly*|freebsd*)
1694         LD_RPATH_OPT="-rpath "
1695         ;;
1696 (netbsd*)
1697         LD_RPATH_OPT="-Wl,-rpath,"
1698         ;;
1699 (osf*|mls+*)
1700         LD_RPATH_OPT="-rpath "
1701         ;;
1702 (solaris2*)
1703         LD_RPATH_OPT="-R"
1704         ;;
1705 (*)
1706         ;;
1707 esac
1708 AC_MSG_RESULT($LD_RPATH_OPT)
1709
1710 case "x$LD_RPATH_OPT" in
1711 (x-R*)
1712         AC_MSG_CHECKING(if we need a space after rpath option)
1713         cf_save_LIBS="$LIBS"
1714         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1715         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1716         LIBS="$cf_save_LIBS"
1717         AC_MSG_RESULT($cf_rpath_space)
1718         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1719         ;;
1720 esac
1721 ])dnl
1722 dnl ---------------------------------------------------------------------------
1723 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
1724 dnl ---------------
1725 dnl Construct a search-list of directories for a nonstandard library-file
1726 dnl
1727 dnl Parameters
1728 dnl     $1 = the variable to return as result
1729 dnl     $2 = the package name
1730 AC_DEFUN([CF_LIBRARY_PATH],
1731 [
1732 $1=
1733 cf_library_path_list=""
1734 if test -n "${LDFLAGS}${LIBS}" ; then
1735         for cf_library_path in $LDFLAGS $LIBS
1736         do
1737                 case $cf_library_path in
1738                 (-L*)
1739                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1740                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1741                         cf_library_path_list="$cf_library_path_list [$]$1"
1742                         ;;
1743                 esac
1744         done
1745 fi
1746
1747 CF_SUBDIR_PATH($1,$2,lib)
1748
1749 $1="$cf_library_path_list [$]$1"
1750 ])dnl
1751 dnl ---------------------------------------------------------------------------
1752 dnl CF_LIB_PREFIX version: 11 updated: 2015/04/18 08:56:57
1753 dnl -------------
1754 dnl Compute the library-prefix for the given host system
1755 dnl $1 = variable to set
1756 define([CF_LIB_PREFIX],
1757 [
1758         case $cf_cv_system_name in
1759         (OS/2*|os2*)
1760                 LIB_PREFIX=''
1761                 ;;
1762         (*)     LIB_PREFIX='lib'
1763                 ;;
1764         esac
1765 ifelse($1,,,[$1=$LIB_PREFIX])
1766         AC_SUBST(LIB_PREFIX)
1767 ])dnl
1768 dnl ---------------------------------------------------------------------------
1769 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
1770 dnl -------------
1771 dnl Compute the library file-suffix from the given model name
1772 dnl $1 = model name
1773 dnl $2 = variable to set (the nominal library suffix)
1774 dnl $3 = dependency variable to set (actual filename)
1775 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1776 AC_DEFUN([CF_LIB_SUFFIX],
1777 [
1778         case X$1 in
1779         (Xlibtool)
1780                 $2='.la'
1781                 $3=[$]$2
1782                 ;;
1783         (Xdebug)
1784                 $2='_g.a'
1785                 $3=[$]$2
1786                 ;;
1787         (Xprofile)
1788                 $2='_p.a'
1789                 $3=[$]$2
1790                 ;;
1791         (Xshared)
1792                 case $cf_cv_system_name in
1793                 (aix[[5-7]]*)
1794                         $2='.so'
1795                         $3=[$]$2
1796                         ;;
1797                 (cygwin*|msys*|mingw*)
1798                         $2='.dll'
1799                         $3='.dll.a'
1800                         ;;
1801                 (darwin*)
1802                         $2='.dylib'
1803                         $3=[$]$2
1804                         ;;
1805                 (hpux*)
1806                         case $target in
1807                         (ia64*)
1808                                 $2='.so'
1809                                 $3=[$]$2
1810                                 ;;
1811                         (*)
1812                                 $2='.sl'
1813                                 $3=[$]$2
1814                                 ;;
1815                         esac
1816                         ;;
1817                 (*)
1818                         $2='.so'
1819                         $3=[$]$2
1820                         ;;
1821                 esac
1822                 ;;
1823         (*)
1824                 $2='.a'
1825                 $3=[$]$2
1826                 ;;
1827         esac
1828         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
1829         then
1830                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
1831                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
1832         fi
1833 ])dnl
1834 dnl ---------------------------------------------------------------------------
1835 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
1836 dnl -----------
1837 dnl Compute the string to append to -library from the given model name
1838 dnl $1 = model name
1839 dnl $2 = variable to set
1840 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1841 AC_DEFUN([CF_LIB_TYPE],
1842 [
1843         case $1 in
1844         (libtool) $2=''   ;;
1845         (normal)  $2=''   ;;
1846         (debug)   $2='_g' ;;
1847         (profile) $2='_p' ;;
1848         (shared)  $2=''   ;;
1849         esac
1850         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1851 ])dnl
1852 dnl ---------------------------------------------------------------------------
1853 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
1854 dnl ----------------
1855 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
1856 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
1857 dnl have to provide wrappers for global tables to ensure they're linked
1858 dnl properly.
1859 AC_DEFUN([CF_LINK_DATAONLY],
1860 [
1861 AC_MSG_CHECKING([if data-only library module links])
1862 AC_CACHE_VAL(cf_cv_link_dataonly,[
1863         rm -f conftest.a
1864         cat >conftest.$ac_ext <<EOF
1865 #line __oline__ "configure"
1866 int     testdata[[3]] = { 123, 456, 789 };
1867 EOF
1868         if AC_TRY_EVAL(ac_compile) ; then
1869                 mv conftest.o data.o && \
1870                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
1871         fi
1872         rm -f conftest.$ac_ext data.o
1873         cat >conftest.$ac_ext <<EOF
1874 #line __oline__ "configure"
1875 int     testfunc()
1876 {
1877 #if defined(NeXT)
1878         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
1879 #else
1880         extern int testdata[[3]];
1881         return testdata[[0]] == 123
1882            &&  testdata[[1]] == 456
1883            &&  testdata[[2]] == 789;
1884 #endif
1885 }
1886 EOF
1887         if AC_TRY_EVAL(ac_compile); then
1888                 mv conftest.o func.o && \
1889                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
1890         fi
1891         rm -f conftest.$ac_ext func.o
1892         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
1893         cf_saveLIBS="$LIBS"
1894         LIBS="conftest.a $LIBS"
1895         AC_TRY_RUN([
1896         int main()
1897         {
1898                 extern int testfunc();
1899                 ${cf_cv_main_return:-return} (!testfunc());
1900         }
1901         ],
1902         [cf_cv_link_dataonly=yes],
1903         [cf_cv_link_dataonly=no],
1904         [cf_cv_link_dataonly=unknown])
1905         LIBS="$cf_saveLIBS"
1906         ])
1907 AC_MSG_RESULT($cf_cv_link_dataonly)
1908
1909 if test "$cf_cv_link_dataonly" = no ; then
1910         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
1911         BROKEN_LINKER=1
1912 fi
1913
1914 ])dnl
1915 dnl ---------------------------------------------------------------------------
1916 dnl CF_MAKEFLAGS version: 16 updated: 2015/04/15 19:08:48
1917 dnl ------------
1918 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
1919 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
1920 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
1921 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
1922 AC_DEFUN([CF_MAKEFLAGS],
1923 [
1924 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
1925         cf_cv_makeflags=''
1926         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
1927         do
1928                 cat >cf_makeflags.tmp <<CF_EOF
1929 SHELL = /bin/sh
1930 all :
1931         @ echo '.$cf_option'
1932 CF_EOF
1933                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
1934                 case "$cf_result" in
1935                 (.*k|.*kw)
1936                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
1937                         case "$cf_result" in
1938                         (.*CC=*)        cf_cv_makeflags=
1939                                 ;;
1940                         (*)     cf_cv_makeflags=$cf_option
1941                                 ;;
1942                         esac
1943                         break
1944                         ;;
1945                 (.-)    ;;
1946                 (*)     echo "given option \"$cf_option\", no match \"$cf_result\""
1947                         ;;
1948                 esac
1949         done
1950         rm -f cf_makeflags.tmp
1951 ])
1952
1953 AC_SUBST(cf_cv_makeflags)
1954 ])dnl
1955 dnl ---------------------------------------------------------------------------
1956 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1957 dnl ------------
1958 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1959 dnl a monocase filesystem.
1960 AC_DEFUN([CF_MAKE_TAGS],[
1961 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1962
1963 AC_CHECK_PROGS(CTAGS, exctags ctags)
1964 AC_CHECK_PROGS(ETAGS, exetags etags)
1965
1966 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1967
1968 if test "$cf_cv_mixedcase" = yes ; then
1969         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1970 else
1971         MAKE_UPPER_TAGS=no
1972 fi
1973
1974 if test "$MAKE_UPPER_TAGS" = yes ; then
1975         MAKE_UPPER_TAGS=
1976 else
1977         MAKE_UPPER_TAGS="#"
1978 fi
1979
1980 if test "$MAKE_LOWER_TAGS" = yes ; then
1981         MAKE_LOWER_TAGS=
1982 else
1983         MAKE_LOWER_TAGS="#"
1984 fi
1985
1986 AC_SUBST(CTAGS)
1987 AC_SUBST(ETAGS)
1988
1989 AC_SUBST(MAKE_UPPER_TAGS)
1990 AC_SUBST(MAKE_LOWER_TAGS)
1991 ])dnl
1992 dnl ---------------------------------------------------------------------------
1993 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
1994 dnl ----------------------
1995 dnl Check if the file-system supports mixed-case filenames.  If we're able to
1996 dnl create a lowercase name and see it as uppercase, it doesn't support that.
1997 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
1998 [
1999 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2000 if test "$cross_compiling" = yes ; then
2001         case $target_alias in
2002         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
2003                 cf_cv_mixedcase=no
2004                 ;;
2005         (*)
2006                 cf_cv_mixedcase=yes
2007                 ;;
2008         esac
2009 else
2010         rm -f conftest CONFTEST
2011         echo test >conftest
2012         if test -f CONFTEST ; then
2013                 cf_cv_mixedcase=no
2014         else
2015                 cf_cv_mixedcase=yes
2016         fi
2017         rm -f conftest CONFTEST
2018 fi
2019 ])
2020 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2021 ])dnl
2022 dnl ---------------------------------------------------------------------------
2023 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
2024 dnl ----------
2025 dnl Check for a working mkstemp.  This creates two files, checks that they are
2026 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2027 AC_DEFUN([CF_MKSTEMP],[
2028 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2029 rm -rf conftest*
2030 AC_TRY_RUN([
2031 #include <sys/types.h>
2032 #include <stdlib.h>
2033 #include <stdio.h>
2034 #include <string.h>
2035 #include <sys/stat.h>
2036 int main()
2037 {
2038         char *tmpl = "conftestXXXXXX";
2039         char name[2][80];
2040         int n;
2041         int result = 0;
2042         int fd;
2043         struct stat sb;
2044
2045         umask(077);
2046         for (n = 0; n < 2; ++n) {
2047                 strcpy(name[n], tmpl);
2048                 if ((fd = mkstemp(name[n])) >= 0) {
2049                         if (!strcmp(name[n], tmpl)
2050                          || stat(name[n], &sb) != 0
2051                          || (sb.st_mode & S_IFMT) != S_IFREG
2052                          || (sb.st_mode & 077) != 0) {
2053                                 result = 1;
2054                         }
2055                         close(fd);
2056                 }
2057         }
2058         if (result == 0
2059          && !strcmp(name[0], name[1]))
2060                 result = 1;
2061         ${cf_cv_main_return:-return}(result);
2062 }
2063 ],[cf_cv_func_mkstemp=yes
2064 ],[cf_cv_func_mkstemp=no
2065 ],[cf_cv_func_mkstemp=maybe])
2066 ])
2067 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2068         AC_CHECK_FUNC(mkstemp)
2069 fi
2070 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2071         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2072 fi
2073 ])dnl
2074 dnl ---------------------------------------------------------------------------
2075 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2076 dnl ----------
2077 dnl Write a debug message to config.log, along with the line number in the
2078 dnl configure script.
2079 AC_DEFUN([CF_MSG_LOG],[
2080 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2081 ])dnl
2082 dnl ---------------------------------------------------------------------------
2083 dnl CF_NCURSES_ADDON version: 5 updated: 2015/04/26 18:06:58
2084 dnl ----------------
2085 dnl Configure an ncurses add-on, built outside the ncurses tree.
2086 AC_DEFUN([CF_NCURSES_ADDON],[
2087 AC_REQUIRE([CF_NCURSES_CONFIG])
2088
2089 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2090
2091 AC_MSG_CHECKING(if you want wide-character code)
2092 AC_ARG_ENABLE(widec,
2093         [  --enable-widec          compile with wide-char/UTF-8 code],
2094         [with_widec=$enableval],
2095         [with_widec=no])
2096 AC_MSG_RESULT($with_widec)
2097 if test "$with_widec" = yes ; then
2098         CF_UTF8_LIB
2099         CF_NCURSES_CONFIG(ncursesw)
2100 else
2101         CF_NCURSES_CONFIG(ncurses)
2102 fi
2103
2104 if test "$NCURSES_CONFIG_PKG" != none ; then
2105         cf_version=`$PKG_CONFIG --modversion $NCURSES_CONFIG_PKG 2>/dev/null`
2106
2107         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2108         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2109         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2110
2111         cf_cv_abi_version=`$PKG_CONFIG --variable=abi_version $NCURSES_CONFIG_PKG 2>/dev/null`
2112         if test -z "$cf_cv_abi_version"
2113         then
2114                 cf_cv_abi_version=`$PKG_CONFIG --variable=major_version $NCURSES_CONFIG_PKG 2>/dev/null`
2115         fi
2116
2117 elif test "$NCURSES_CONFIG" != none ; then
2118
2119         cf_version=`$NCURSES_CONFIG --version 2>/dev/null`
2120
2121         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2122         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2123         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2124
2125         # ABI version is not available from headers
2126         cf_cv_abi_version=`$NCURSES_CONFIG --abi-version 2>/dev/null`
2127
2128 else
2129
2130         for cf_name in MAJOR MINOR PATCH
2131         do
2132         cat >conftest.$ac_ext <<CF_EOF
2133         #include <${cf_cv_ncurses_header:-curses.h}>
2134         AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2135 CF_EOF
2136                 cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2137                 AC_TRY_EVAL(cf_try)
2138                 if test -f conftest.out ; then
2139                         cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]][[    ]]*//"`
2140                         eval NCURSES_$cf_name=\"$cf_result\"
2141                         # cat conftest.$ac_ext
2142                         # cat conftest.out
2143                 fi
2144         done
2145
2146         cf_cv_abi_version=${NCURSES_MAJOR}
2147
2148 fi
2149
2150 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2151
2152 dnl Show the computed version, for logging
2153 cf_cv_timestamp=`date`
2154
2155 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2156
2157 dnl We need these values in the generated headers
2158 AC_SUBST(NCURSES_MAJOR)
2159 AC_SUBST(NCURSES_MINOR)
2160 AC_SUBST(NCURSES_PATCH)
2161
2162 dnl We need these values in the generated makefiles
2163 AC_SUBST(cf_cv_rel_version)
2164 AC_SUBST(cf_cv_abi_version)
2165
2166 dnl FIXME - not needed for Ada95
2167 AC_SUBST(cf_cv_builtin_bool)
2168 AC_SUBST(cf_cv_header_stdbool_h)
2169 AC_SUBST(cf_cv_type_of_bool)dnl
2170
2171 ])
2172 dnl ---------------------------------------------------------------------------
2173 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2174 dnl -------------------
2175 dnl Check if we can compile with ncurses' header file
2176 dnl $1 is the cache variable to set
2177 dnl $2 is the header-file to include
2178 dnl $3 is the root name (ncurses or ncursesw)
2179 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2180         AC_TRY_COMPILE([
2181 ]ifelse($3,ncursesw,[
2182 #define _XOPEN_SOURCE_EXTENDED
2183 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2184 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2185 ])[
2186 #include <$2>],[
2187 #ifdef NCURSES_VERSION
2188 ]ifelse($3,ncursesw,[
2189 #ifndef WACS_BSSB
2190         make an error
2191 #endif
2192 ])[
2193 printf("%s\n", NCURSES_VERSION);
2194 #else
2195 #ifdef __NCURSES_H
2196 printf("old\n");
2197 #else
2198         make an error
2199 #endif
2200 #endif
2201         ]
2202         ,[$1=$2]
2203         ,[$1=no])
2204 ])dnl
2205 dnl ---------------------------------------------------------------------------
2206 dnl CF_NCURSES_CONFIG version: 13 updated: 2015/04/26 18:06:58
2207 dnl -----------------
2208 dnl Tie together the configure-script macros for ncurses, preferring these in
2209 dnl order:
2210 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2211 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2212 dnl c) just plain libraries
2213 dnl
2214 dnl $1 is the root library name (default: "ncurses")
2215 AC_DEFUN([CF_NCURSES_CONFIG],[
2216 AC_REQUIRE([CF_PKG_CONFIG])
2217 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2218 cf_have_ncuconfig=no
2219
2220 if test "x$PKG_CONFIG" != xnone; then
2221         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2222         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2223                 AC_MSG_RESULT(yes)
2224
2225                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2226                 cf_have_ncuconfig=unknown
2227
2228                 cf_save_CPPFLAGS="$CPPFLAGS"
2229                 cf_save_LIBS="$LIBS"
2230
2231                 CPPFLAGS="$CPPFLAGS `$PKG_CONFIG --cflags $cf_ncuconfig_root`"
2232                 CF_ADD_LIBS(`$PKG_CONFIG --libs $cf_ncuconfig_root`)
2233
2234                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2235                         [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2236                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2237                                 int main(void)
2238                                 { char *xx = curses_version(); return (xx == 0); }],
2239                                 [cf_have_ncuconfig=yes],
2240                                 [cf_have_ncuconfig=no])],
2241                         [cf_have_ncuconfig=no])
2242
2243                 AC_MSG_RESULT($cf_have_ncuconfig)
2244                 if test "$cf_have_ncuconfig" != "yes"
2245                 then
2246                         CPPFLAGS="$cf_save_CPPFLAGS"
2247                         LIBS="$cf_save_LIBS"
2248                         NCURSES_CONFIG_PKG=none
2249                 else
2250                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2251                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2252                 fi
2253
2254         else
2255                 AC_MSG_RESULT(no)
2256                 NCURSES_CONFIG_PKG=none
2257         fi
2258 else
2259         NCURSES_CONFIG_PKG=none
2260 fi
2261
2262 if test "x$cf_have_ncuconfig" = "xno"; then
2263         echo "Looking for ${cf_ncuconfig_root}-config"
2264
2265         CF_ACVERSION_CHECK(2.52,
2266                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncuconfig_root}-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2267                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncuconfig_root}-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2268
2269         if test "$NCURSES_CONFIG" != none ; then
2270
2271                 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
2272                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2273
2274                 # even with config script, some packages use no-override for curses.h
2275                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2276
2277                 dnl like CF_NCURSES_CPPFLAGS
2278                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2279
2280                 dnl like CF_NCURSES_LIBS
2281                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2282                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2283
2284                 dnl like CF_NCURSES_VERSION
2285                 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2286
2287         else
2288
2289                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2290                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2291
2292         fi
2293 else
2294         NCURSES_CONFIG=none
2295 fi
2296 ])dnl
2297 dnl ---------------------------------------------------------------------------
2298 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2299 dnl -------------------
2300 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2301 dnl the CPPFLAGS variable so we can include its header.
2302 dnl
2303 dnl The header files may be installed as either curses.h, or ncurses.h (would
2304 dnl be obsolete, except that some packagers prefer this name to distinguish it
2305 dnl from a "native" curses implementation).  If not installed for overwrite,
2306 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2307 dnl /usr/include/ncurses), but someone may have installed overwriting the
2308 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2309 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2310 dnl the header.
2311 dnl
2312 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2313 dnl is already in the include-path, don't even bother with this, since we cannot
2314 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2315 dnl
2316 dnl The optional parameter gives the root name of the library, in case it is
2317 dnl not installed as the default curses library.  That is how the
2318 dnl wide-character version of ncurses is installed.
2319 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2320 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2321
2322 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2323 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2324
2325 test -n "$cf_cv_curses_dir" && \
2326 test "$cf_cv_curses_dir" != "no" && { \
2327   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2328 }
2329
2330 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2331         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2332         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2333         for cf_header in $cf_header_list
2334         do
2335                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2336                 test "$cf_cv_ncurses_h" != no && break
2337         done
2338 ])
2339
2340 CF_NCURSES_HEADER
2341 CF_TERM_HEADER
2342
2343 # some applications need this, but should check for NCURSES_VERSION
2344 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2345
2346 CF_NCURSES_VERSION
2347 ])dnl
2348 dnl ---------------------------------------------------------------------------
2349 dnl CF_NCURSES_HEADER version: 4 updated: 2015/04/15 19:08:48
2350 dnl -----------------
2351 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2352 dnl variations of ncurses' installs.
2353 dnl
2354 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2355 AC_DEFUN([CF_NCURSES_HEADER],[
2356
2357 if test "$cf_cv_ncurses_h" != no ; then
2358         cf_cv_ncurses_header=$cf_cv_ncurses_h
2359 else
2360
2361 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2362         test -n "$verbose" && echo
2363         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2364         test -n "$verbose" && echo search path $cf_search
2365         cf_save2_CPPFLAGS="$CPPFLAGS"
2366         for cf_incdir in $cf_search
2367         do
2368                 CF_ADD_INCDIR($cf_incdir)
2369                 for cf_header in \
2370                         ncurses.h \
2371                         curses.h
2372                 do
2373                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2374                         if test "$cf_cv_ncurses_h2" != no ; then
2375                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2376                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2377                                 break
2378                         fi
2379                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2380                 done
2381                 CPPFLAGS="$cf_save2_CPPFLAGS"
2382                 test "$cf_cv_ncurses_h2" != no && break
2383         done
2384         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2385         ])
2386
2387         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2388         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2389         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2390                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2391         fi
2392         CF_ADD_INCDIR($cf_1st_incdir)
2393
2394 fi
2395
2396 # Set definitions to allow ifdef'ing for ncurses.h
2397
2398 case $cf_cv_ncurses_header in
2399 (*ncurses.h)
2400         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2401         ;;
2402 esac
2403
2404 case $cf_cv_ncurses_header in
2405 (ncurses/curses.h|ncurses/ncurses.h)
2406         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2407         ;;
2408 (ncursesw/curses.h|ncursesw/ncurses.h)
2409         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2410         ;;
2411 esac
2412
2413 ])dnl
2414 dnl ---------------------------------------------------------------------------
2415 dnl CF_NCURSES_LIBS version: 17 updated: 2015/04/15 19:08:48
2416 dnl ---------------
2417 dnl Look for the ncurses library.  This is a little complicated on Linux,
2418 dnl because it may be linked with the gpm (general purpose mouse) library.
2419 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2420 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2421 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2422 dnl and the linker will record a dependency.
2423 dnl
2424 dnl The optional parameter gives the root name of the library, in case it is
2425 dnl not installed as the default curses library.  That is how the
2426 dnl wide-character version of ncurses is installed.
2427 AC_DEFUN([CF_NCURSES_LIBS],
2428 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2429
2430 cf_nculib_root=ifelse($1,,ncurses,$1)
2431         # This works, except for the special case where we find gpm, but
2432         # ncurses is in a nonstandard location via $LIBS, and we really want
2433         # to link gpm.
2434 cf_ncurses_LIBS=""
2435 cf_ncurses_SAVE="$LIBS"
2436 AC_CHECK_LIB(gpm,Gpm_Open,
2437         [AC_CHECK_LIB(gpm,initscr,
2438                 [LIBS="$cf_ncurses_SAVE"],
2439                 [cf_ncurses_LIBS="-lgpm"])])
2440
2441 case $host_os in
2442 (freebsd*)
2443         # This is only necessary if you are linking against an obsolete
2444         # version of ncurses (but it should do no harm, since it's static).
2445         if test "$cf_nculib_root" = ncurses ; then
2446                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2447         fi
2448         ;;
2449 esac
2450
2451 CF_ADD_LIBS($cf_ncurses_LIBS)
2452
2453 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2454 then
2455         CF_ADD_LIBS(-l$cf_nculib_root)
2456 else
2457         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2458                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2459                 [initscr()],
2460                 initscr)
2461 fi
2462
2463 if test -n "$cf_ncurses_LIBS" ; then
2464         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2465         cf_ncurses_SAVE="$LIBS"
2466         for p in $cf_ncurses_LIBS ; do
2467                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2468                 if test "$q" != "$LIBS" ; then
2469                         LIBS="$q"
2470                 fi
2471         done
2472         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2473                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2474                 [AC_MSG_RESULT(yes)],
2475                 [AC_MSG_RESULT(no)
2476                  LIBS="$cf_ncurses_SAVE"])
2477 fi
2478
2479 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2480 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2481 ])dnl
2482 dnl ---------------------------------------------------------------------------
2483 dnl CF_NCURSES_VERSION version: 14 updated: 2012/10/06 08:57:51
2484 dnl ------------------
2485 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2486 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2487 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2488 AC_DEFUN([CF_NCURSES_VERSION],
2489 [
2490 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2491 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2492         cf_cv_ncurses_version=no
2493         cf_tempfile=out$$
2494         rm -f $cf_tempfile
2495         AC_TRY_RUN([
2496 #include <${cf_cv_ncurses_header:-curses.h}>
2497 #include <stdio.h>
2498 int main()
2499 {
2500         FILE *fp = fopen("$cf_tempfile", "w");
2501 #ifdef NCURSES_VERSION
2502 # ifdef NCURSES_VERSION_PATCH
2503         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2504 # else
2505         fprintf(fp, "%s\n", NCURSES_VERSION);
2506 # endif
2507 #else
2508 # ifdef __NCURSES_H
2509         fprintf(fp, "old\n");
2510 # else
2511         make an error
2512 # endif
2513 #endif
2514         ${cf_cv_main_return:-return}(0);
2515 }],[
2516         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2517
2518         # This will not work if the preprocessor splits the line after the
2519         # Autoconf token.  The 'unproto' program does that.
2520         cat > conftest.$ac_ext <<EOF
2521 #include <${cf_cv_ncurses_header:-curses.h}>
2522 #undef Autoconf
2523 #ifdef NCURSES_VERSION
2524 Autoconf NCURSES_VERSION
2525 #else
2526 #ifdef __NCURSES_H
2527 Autoconf "old"
2528 #endif
2529 ;
2530 #endif
2531 EOF
2532         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2533         AC_TRY_EVAL(cf_try)
2534         if test -f conftest.out ; then
2535                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2536                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2537                 rm -f conftest.out
2538         fi
2539 ])
2540         rm -f $cf_tempfile
2541 ])
2542 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2543 ])dnl
2544 dnl ---------------------------------------------------------------------------
2545 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
2546 dnl -------------
2547 dnl Compute the object-directory name from the given model name
2548 AC_DEFUN([CF_OBJ_SUBDIR],
2549 [
2550         case $1 in
2551         (libtool) $2='obj_lo'  ;;
2552         (normal)  $2='objects' ;;
2553         (debug)   $2='obj_g' ;;
2554         (profile) $2='obj_p' ;;
2555         (shared)
2556                 case $cf_cv_system_name in
2557                 (cygwin|msys)
2558                         $2='objects' ;;
2559                 (*)
2560                         $2='obj_s' ;;
2561                 esac
2562         esac
2563 ])dnl
2564 dnl ---------------------------------------------------------------------------
2565 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
2566 dnl ----------
2567 dnl Provide a value for the $PATH and similar separator (or amend the value
2568 dnl as provided in autoconf 2.5x).
2569 AC_DEFUN([CF_PATHSEP],
2570 [
2571         AC_MSG_CHECKING(for PATH separator)
2572         case $cf_cv_system_name in
2573         (os2*)  PATH_SEPARATOR=';'  ;;
2574         (*)     ${PATH_SEPARATOR:=':'}  ;;
2575         esac
2576 ifelse([$1],,,[$1=$PATH_SEPARATOR])
2577         AC_SUBST(PATH_SEPARATOR)
2578         AC_MSG_RESULT($PATH_SEPARATOR)
2579 ])dnl
2580 dnl ---------------------------------------------------------------------------
2581 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
2582 dnl --------------
2583 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2584 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2585 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2586 dnl delayed evaluation of those symbols.
2587 AC_DEFUN([CF_PATH_SYNTAX],[
2588 if test "x$prefix" != xNONE; then
2589         cf_path_syntax="$prefix"
2590 else
2591         cf_path_syntax="$ac_default_prefix"
2592 fi
2593
2594 case ".[$]$1" in
2595 (.\[$]\(*\)*|.\'*\'*)
2596         ;;
2597 (..|./*|.\\*)
2598         ;;
2599 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
2600         ;;
2601 (.\[$]{*prefix}*|.\[$]{*dir}*)
2602         eval $1="[$]$1"
2603         case ".[$]$1" in
2604         (.NONE/*)
2605                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2606                 ;;
2607         esac
2608         ;;
2609 (.no|.NONE/*)
2610         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2611         ;;
2612 (*)
2613         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2614         ;;
2615 esac
2616 ])dnl
2617 dnl ---------------------------------------------------------------------------
2618 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
2619 dnl -------------
2620 dnl Check for the package-config program, unless disabled by command-line.
2621 AC_DEFUN([CF_PKG_CONFIG],
2622 [
2623 AC_MSG_CHECKING(if you want to use pkg-config)
2624 AC_ARG_WITH(pkg-config,
2625         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2626         [cf_pkg_config=$withval],
2627         [cf_pkg_config=yes])
2628 AC_MSG_RESULT($cf_pkg_config)
2629
2630 case $cf_pkg_config in
2631 (no)
2632         PKG_CONFIG=none
2633         ;;
2634 (yes)
2635         CF_ACVERSION_CHECK(2.52,
2636                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2637                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2638         ;;
2639 (*)
2640         PKG_CONFIG=$withval
2641         ;;
2642 esac
2643
2644 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2645 if test "$PKG_CONFIG" != none ; then
2646         CF_PATH_SYNTAX(PKG_CONFIG)
2647 elif test "x$cf_pkg_config" != xno ; then
2648         AC_MSG_WARN(pkg-config is not installed)
2649 fi
2650
2651 AC_SUBST(PKG_CONFIG)
2652 ])dnl
2653 dnl ---------------------------------------------------------------------------
2654 dnl CF_POSIX_C_SOURCE version: 9 updated: 2015/04/12 15:39:00
2655 dnl -----------------
2656 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2657 dnl
2658 dnl     POSIX.1-1990                            _POSIX_SOURCE
2659 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2660 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2661 dnl             Bindings Option
2662 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2663 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2664 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2665 dnl
2666 dnl Parameters:
2667 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2668 AC_DEFUN([CF_POSIX_C_SOURCE],
2669 [
2670 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2671
2672 cf_save_CFLAGS="$CFLAGS"
2673 cf_save_CPPFLAGS="$CPPFLAGS"
2674
2675 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2676 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2677
2678 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2679         CF_MSG_LOG(if the symbol is already defined go no further)
2680         AC_TRY_COMPILE([#include <sys/types.h>],[
2681 #ifndef _POSIX_C_SOURCE
2682 make an error
2683 #endif],
2684         [cf_cv_posix_c_source=no],
2685         [cf_want_posix_source=no
2686          case .$cf_POSIX_C_SOURCE in
2687          (.[[12]]??*)
2688                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2689                 ;;
2690          (.2)
2691                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2692                 cf_want_posix_source=yes
2693                 ;;
2694          (.*)
2695                 cf_want_posix_source=yes
2696                 ;;
2697          esac
2698          if test "$cf_want_posix_source" = yes ; then
2699                 AC_TRY_COMPILE([#include <sys/types.h>],[
2700 #ifdef _POSIX_SOURCE
2701 make an error
2702 #endif],[],
2703                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2704          fi
2705          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2706          CFLAGS="$cf_trim_CFLAGS"
2707          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2708          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2709          AC_TRY_COMPILE([#include <sys/types.h>],[
2710 #ifndef _POSIX_C_SOURCE
2711 make an error
2712 #endif],,
2713          [cf_cv_posix_c_source=no])
2714          CFLAGS="$cf_save_CFLAGS"
2715          CPPFLAGS="$cf_save_CPPFLAGS"
2716         ])
2717 ])
2718
2719 if test "$cf_cv_posix_c_source" != no ; then
2720         CFLAGS="$cf_trim_CFLAGS"
2721         CPPFLAGS="$cf_trim_CPPFLAGS"
2722         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2723 fi
2724
2725 ])dnl
2726 dnl ---------------------------------------------------------------------------
2727 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
2728 dnl ----------
2729 dnl Check for archiver "ar".
2730 AC_DEFUN([CF_PROG_AR],[
2731 AC_CHECK_TOOL(AR, ar, ar)
2732 ])
2733 dnl ---------------------------------------------------------------------------
2734 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
2735 dnl -----------
2736 dnl Check for awk, ensure that the check found something.
2737 AC_DEFUN([CF_PROG_AWK],
2738 [
2739 AC_PROG_AWK
2740 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
2741 ])dnl
2742 dnl ---------------------------------------------------------------------------
2743 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
2744 dnl ----------
2745 dnl standard check for CC, plus followup sanity checks
2746 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
2747 AC_DEFUN([CF_PROG_CC],[
2748 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
2749 CF_GCC_VERSION
2750 CF_ACVERSION_CHECK(2.52,
2751         [AC_PROG_CC_STDC],
2752         [CF_ANSI_CC_REQD])
2753 CF_CC_ENV_FLAGS
2754 ])dnl
2755 dnl ---------------------------------------------------------------------------
2756 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
2757 dnl --------------
2758 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
2759 dnl the output file can be renamed, and allows for a shell variable that can
2760 dnl be used later.  The parameter is either CC or CXX.  The result is the
2761 dnl cache variable:
2762 dnl     $cf_cv_prog_CC_c_o
2763 dnl     $cf_cv_prog_CXX_c_o
2764 AC_DEFUN([CF_PROG_CC_C_O],
2765 [AC_REQUIRE([AC_PROG_CC])dnl
2766 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
2767 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
2768 [
2769 cat > conftest.$ac_ext <<CF_EOF
2770 #include <stdio.h>
2771 int main()
2772 {
2773         ${cf_cv_main_return:-return}(0);
2774 }
2775 CF_EOF
2776 # We do the test twice because some compilers refuse to overwrite an
2777 # existing .o file with -o, though they will create one.
2778 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
2779 if AC_TRY_EVAL(ac_try) &&
2780   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
2781 then
2782   eval cf_cv_prog_$1_c_o=yes
2783 else
2784   eval cf_cv_prog_$1_c_o=no
2785 fi
2786 rm -rf conftest*
2787 ])dnl
2788 if test $cf_cv_prog_$1_c_o = yes; then
2789   AC_MSG_RESULT([yes])
2790 else
2791   AC_MSG_RESULT([no])
2792 fi
2793 ])dnl
2794 dnl ---------------------------------------------------------------------------
2795 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
2796 dnl -------------
2797 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
2798 dnl This macro adds a check to ensure the script found something.
2799 AC_DEFUN([CF_PROG_EGREP],
2800 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
2801         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
2802                 then ac_cv_prog_egrep='grep -E'
2803                 else ac_cv_prog_egrep='egrep'
2804         fi])
2805         EGREP=$ac_cv_prog_egrep
2806         AC_SUBST([EGREP])
2807         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
2808 ])dnl
2809 dnl ---------------------------------------------------------------------------
2810 dnl CF_PROG_EXT version: 13 updated: 2015/04/18 09:03:58
2811 dnl -----------
2812 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
2813 AC_DEFUN([CF_PROG_EXT],
2814 [
2815 AC_REQUIRE([CF_CHECK_CACHE])
2816 case $cf_cv_system_name in
2817 (os2*)
2818         CFLAGS="$CFLAGS -Zmt"
2819         CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
2820         CXXFLAGS="$CXXFLAGS -Zmt"
2821         # autoconf's macro sets -Zexe and suffix both, which conflict:w
2822         LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
2823         ac_cv_exeext=.exe
2824         ;;
2825 esac
2826
2827 AC_EXEEXT
2828 AC_OBJEXT
2829
2830 PROG_EXT="$EXEEXT"
2831 AC_SUBST(PROG_EXT)
2832 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
2833 ])dnl
2834 dnl ---------------------------------------------------------------------------
2835 dnl CF_PROG_GNAT version: 3 updated: 2015/04/18 08:56:57
2836 dnl ------------
2837 dnl Check for gnatmake, ensure that it is complete.
2838 AC_DEFUN([CF_PROG_GNAT],[
2839 cf_ada_make=gnatmake
2840 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
2841 if test "$ac_cv_prog_gnat_exists" = no; then
2842         cf_ada_make=
2843         cf_cv_prog_gnat_correct=no
2844 else
2845         CF_GNAT_VERSION
2846         AC_CHECK_PROG(M4_exists, m4, yes, no)
2847         if test "$ac_cv_prog_M4_exists" = no; then
2848                 cf_cv_prog_gnat_correct=no
2849                 echo Ada95 binding required program m4 not found. Ada95 binding disabled.
2850         fi
2851         if test "$cf_cv_prog_gnat_correct" = yes; then
2852                 AC_MSG_CHECKING(if GNAT works)
2853                 CF_GNAT_TRY_RUN([procedure conftest;],
2854 [with Text_IO;
2855 with GNAT.OS_Lib;
2856 procedure conftest is
2857 begin
2858    Text_IO.Put ("Hello World");
2859    Text_IO.New_Line;
2860    GNAT.OS_Lib.OS_Exit (0);
2861 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
2862                 AC_MSG_RESULT($cf_cv_prog_gnat_correct)
2863         fi
2864 fi
2865
2866 AC_SUBST(cf_ada_make)
2867 ])dnl
2868 dnl ---------------------------------------------------------------------------
2869 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
2870 dnl ------------
2871 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
2872 dnl option if it is supported.
2873 AC_DEFUN([CF_PROG_LN_S],[
2874 AC_PROG_LN_S
2875 AC_MSG_CHECKING(if $LN_S -f options work)
2876
2877 rm -f conf$$.src conf$$dst
2878 echo >conf$$.dst
2879 echo first >conf$$.src
2880 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
2881         cf_prog_ln_sf=yes
2882 else
2883         cf_prog_ln_sf=no
2884 fi
2885 rm -f conf$$.dst conf$$src
2886 AC_MSG_RESULT($cf_prog_ln_sf)
2887
2888 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
2889 ])dnl
2890 dnl ---------------------------------------------------------------------------
2891 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2892 dnl ----------------
2893 dnl Remove all -U and -D options that refer to the given symbol from a list
2894 dnl of C compiler options.  This works around the problem that not all
2895 dnl compilers process -U and -D options from left-to-right, so a -U option
2896 dnl cannot be used to cancel the effect of a preceding -D option.
2897 dnl
2898 dnl $1 = target (which could be the same as the source variable)
2899 dnl $2 = source (including '$')
2900 dnl $3 = symbol to remove
2901 define([CF_REMOVE_DEFINE],
2902 [
2903 $1=`echo "$2" | \
2904         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2905                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2906 ])dnl
2907 dnl ---------------------------------------------------------------------------
2908 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
2909 dnl -------------
2910 dnl Remove the given library from the symbol
2911 dnl
2912 dnl $1 = target (which could be the same as the source variable)
2913 dnl $2 = source (including '$')
2914 dnl $3 = library to remove
2915 define([CF_REMOVE_LIB],
2916 [
2917 # remove $3 library from $2
2918 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
2919 ])dnl
2920 dnl ---------------------------------------------------------------------------
2921 dnl CF_SHARED_OPTS version: 87 updated: 2015/04/17 21:13:04
2922 dnl --------------
2923 dnl --------------
2924 dnl Attempt to determine the appropriate CC/LD options for creating a shared
2925 dnl library.
2926 dnl
2927 dnl Notes:
2928 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
2929 dnl the build-tree, i.e., by making use of the libraries that are compiled in
2930 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
2931 dnl shared library since that can lead to unexpected results at runtime.
2932 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
2933 dnl libraries are compiled in ../../lib
2934 dnl
2935 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
2936 dnl to install symbolic links to the rel/abi versions of shared libraries.
2937 dnl
2938 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
2939 dnl version when making symbolic links.
2940 dnl
2941 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
2942 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
2943 dnl (ex: libncurses.so.<ver>).
2944 dnl
2945 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
2946 AC_DEFUN([CF_SHARED_OPTS],
2947 [
2948         AC_REQUIRE([CF_LD_RPATH_OPT])
2949         RM_SHARED_OPTS=
2950         LOCAL_LDFLAGS=
2951         LOCAL_LDFLAGS2=
2952         LD_SHARED_OPTS=
2953         INSTALL_LIB="-m 644"
2954         : ${rel_builddir:=.}
2955
2956         shlibdir=$libdir
2957         AC_SUBST(shlibdir)
2958
2959         MAKE_DLLS="#"
2960         AC_SUBST(MAKE_DLLS)
2961
2962         cf_cv_do_symlinks=no
2963         cf_ld_rpath_opt=
2964         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
2965
2966         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
2967         AC_ARG_WITH(shlib-version,
2968         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
2969         [test -z "$withval" && withval=auto
2970         case $withval in
2971         (yes)
2972                 cf_cv_shlib_version=auto
2973                 ;;
2974         (rel|abi|auto|no)
2975                 cf_cv_shlib_version=$withval
2976                 ;;
2977         (*)
2978                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
2979                 ;;
2980         esac
2981         ],[cf_cv_shlib_version=auto])
2982         AC_MSG_RESULT($cf_cv_shlib_version)
2983
2984         cf_cv_rm_so_locs=no
2985         cf_try_cflags=
2986
2987         # Some less-capable ports of gcc support only -fpic
2988         CC_SHARED_OPTS=
2989         if test "$GCC" = yes
2990         then
2991                 AC_MSG_CHECKING(which $CC option to use)
2992                 cf_save_CFLAGS="$CFLAGS"
2993                 for CC_SHARED_OPTS in -fPIC -fpic ''
2994                 do
2995                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
2996                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
2997                 done
2998                 AC_MSG_RESULT($CC_SHARED_OPTS)
2999                 CFLAGS="$cf_save_CFLAGS"
3000         fi
3001
3002         cf_cv_shlib_version_infix=no
3003
3004         case $cf_cv_system_name in
3005         (aix4.[3-9]*|aix[[5-7]]*)
3006                 if test "$GCC" = yes; then
3007                         CC_SHARED_OPTS='-Wl,-brtl'
3008                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3009                 else
3010                         CC_SHARED_OPTS='-brtl'
3011                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
3012                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3013                 fi
3014                 ;;
3015         (beos*)
3016                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
3017                 ;;
3018         (cygwin*)
3019                 CC_SHARED_OPTS=
3020                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3021                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3022                 cf_cv_shlib_version=cygdll
3023                 cf_cv_shlib_version_infix=cygdll
3024                 shlibdir=$bindir
3025                 MAKE_DLLS=
3026                 cat >mk_shared_lib.sh <<-CF_EOF
3027                 #!/bin/sh
3028                 SHARED_LIB=\[$]1
3029                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3030                 shift
3031                 cat <<-EOF
3032                 Linking shared library
3033                 ** SHARED_LIB \[$]SHARED_LIB
3034                 ** IMPORT_LIB \[$]IMPORT_LIB
3035 EOF
3036                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3037 CF_EOF
3038                 chmod +x mk_shared_lib.sh
3039                 ;;
3040         (msys*)
3041                 CC_SHARED_OPTS=
3042                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3043                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3044                 cf_cv_shlib_version=msysdll
3045                 cf_cv_shlib_version_infix=msysdll
3046                 shlibdir=$bindir
3047                 MAKE_DLLS=
3048                 cat >mk_shared_lib.sh <<-CF_EOF
3049                 #!/bin/sh
3050                 SHARED_LIB=\[$]1
3051                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3052                 shift
3053                 cat <<-EOF
3054                 Linking shared library
3055                 ** SHARED_LIB \[$]SHARED_LIB
3056                 ** IMPORT_LIB \[$]IMPORT_LIB
3057 EOF
3058                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3059 CF_EOF
3060                 chmod +x mk_shared_lib.sh
3061                 ;;
3062         (darwin*)
3063                 cf_try_cflags="no-cpp-precomp"
3064                 CC_SHARED_OPTS="-dynamic"
3065                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
3066                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
3067                 cf_cv_shlib_version_infix=yes
3068                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
3069                         cf_save_LDFLAGS=$LDFLAGS
3070                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3071                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
3072                                 LDFLAGS=$cf_save_LDFLAGS])
3073                 if test $cf_cv_ldflags_search_paths_first = yes; then
3074                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3075                 fi
3076                 ;;
3077         (hpux[[7-8]]*)
3078                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
3079                 if test "$GCC" != yes; then
3080                         CC_SHARED_OPTS='+Z'
3081                 fi
3082                 MK_SHARED_LIB='${LD} -b -o $[@]'
3083                 INSTALL_LIB="-m 555"
3084                 ;;
3085         (hpux*)
3086                 # (tested with gcc 2.7.2 -- I don't have c89)
3087                 if test "$GCC" = yes; then
3088                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
3089                 else
3090                         CC_SHARED_OPTS='+Z'
3091                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
3092                 fi
3093                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
3094                 # HP-UX shared libraries must be executable, and should be
3095                 # readonly to exploit a quirk in the memory manager.
3096                 INSTALL_LIB="-m 555"
3097                 ;;
3098         (interix*)
3099                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3100                 if test "$cf_cv_shlib_version" = rel; then
3101                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
3102                 else
3103                         cf_shared_soname='`basename $@`'
3104                 fi
3105                 CC_SHARED_OPTS=
3106                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
3107                 ;;
3108         (irix*)
3109                 if test "$cf_cv_enable_rpath" = yes ; then
3110                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3111                 fi
3112                 # tested with IRIX 5.2 and 'cc'.
3113                 if test "$GCC" != yes; then
3114                         CC_SHARED_OPTS='-KPIC'
3115                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
3116                 else
3117                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
3118                 fi
3119                 cf_cv_rm_so_locs=yes
3120                 ;;
3121         (linux*|gnu*|k*bsd*-gnu)
3122                 if test "$DFT_LWR_MODEL" = "shared" ; then
3123                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3124                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3125                 fi
3126                 if test "$cf_cv_enable_rpath" = yes ; then
3127                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3128                 fi
3129                 CF_SHARED_SONAME
3130                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3131                 ;;
3132         (mingw*)
3133                 cf_cv_shlib_version=mingw
3134                 cf_cv_shlib_version_infix=mingw
3135                 shlibdir=$bindir
3136                 MAKE_DLLS=
3137                 if test "$DFT_LWR_MODEL" = "shared" ; then
3138                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
3139                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3140                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
3141                 fi
3142                 CC_SHARED_OPTS=
3143                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3144                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3145                 cat >mk_shared_lib.sh <<-CF_EOF
3146                 #!/bin/sh
3147                 SHARED_LIB=\[$]1
3148                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3149                 shift
3150                 cat <<-EOF
3151                 Linking shared library
3152                 ** SHARED_LIB \[$]SHARED_LIB
3153                 ** IMPORT_LIB \[$]IMPORT_LIB
3154 EOF
3155                 exec \[$]* -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3156 CF_EOF
3157                 chmod +x mk_shared_lib.sh
3158                 ;;
3159         (openbsd[[2-9]].*|mirbsd*)
3160                 if test "$DFT_LWR_MODEL" = "shared" ; then
3161                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3162                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3163                 fi
3164                 if test "$cf_cv_enable_rpath" = yes ; then
3165                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3166                 fi
3167                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3168                 CF_SHARED_SONAME
3169                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3170                 ;;
3171         (nto-qnx*|openbsd*|freebsd[[12]].*)
3172                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3173                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
3174                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3175                 ;;
3176         (dragonfly*|freebsd*)
3177                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3178                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3179                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3180                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
3181                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3182                 fi
3183                 CF_SHARED_SONAME
3184                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3185                 ;;
3186         (netbsd*)
3187                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3188                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3189                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3190                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3191                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3192                         if test "$cf_cv_shlib_version" = auto; then
3193                         if test -f /usr/libexec/ld.elf_so; then
3194                                 cf_cv_shlib_version=abi
3195                         else
3196                                 cf_cv_shlib_version=rel
3197                         fi
3198                         fi
3199                         CF_SHARED_SONAME
3200                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
3201                 else
3202                         MK_SHARED_LIB='${CC} -Wl,-shared -Wl,-Bshareable -o $[@]'
3203                 fi
3204                 ;;
3205         (osf*|mls+*)
3206                 # tested with OSF/1 V3.2 and 'cc'
3207                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
3208                 # link with shared libs).
3209                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
3210                 case $host_os in
3211                 (osf4*)
3212                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
3213                         ;;
3214                 esac
3215                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
3216                 if test "$DFT_LWR_MODEL" = "shared" ; then
3217                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3218                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3219                 fi
3220                 cf_cv_rm_so_locs=yes
3221                 ;;
3222         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
3223                 # tested with osr5.0.5
3224                 if test "$GCC" != yes; then
3225                         CC_SHARED_OPTS='-belf -KPIC'
3226                 fi
3227                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
3228                 if test "$cf_cv_enable_rpath" = yes ; then
3229                         # only way is to set LD_RUN_PATH but no switch for it
3230                         RUN_PATH=$libdir
3231                 fi
3232                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3233                 LINK_PROGS='LD_RUN_PATH=${libdir}'
3234                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
3235                 ;;
3236         (sunos4*)
3237                 # tested with SunOS 4.1.1 and gcc 2.7.0
3238                 if test "$GCC" != yes; then
3239                         CC_SHARED_OPTS='-KPIC'
3240                 fi
3241                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
3242                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3243                 ;;
3244         (solaris2*)
3245                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
3246                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
3247                 if test "$DFT_LWR_MODEL" = "shared" ; then
3248                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
3249                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3250                 fi
3251                 if test "$cf_cv_enable_rpath" = yes ; then
3252                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
3253                 fi
3254                 CF_SHARED_SONAME
3255                 if test "$GCC" != yes; then
3256                         cf_save_CFLAGS="$CFLAGS"
3257                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
3258                         do
3259                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
3260                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
3261                         done
3262                         CFLAGS="$cf_save_CFLAGS"
3263                         CC_SHARED_OPTS=$cf_shared_opts
3264                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3265                 else
3266                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3267                 fi
3268                 ;;
3269         (sysv5uw7*|unix_sv*)
3270                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
3271                 if test "$GCC" != yes; then
3272                         CC_SHARED_OPTS='-KPIC'
3273                 fi
3274                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
3275                 ;;
3276         (*)
3277                 CC_SHARED_OPTS='unknown'
3278                 MK_SHARED_LIB='echo unknown'
3279                 ;;
3280         esac
3281
3282         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
3283         case "$cf_cv_shlib_version" in
3284         (rel|abi)
3285                 case "$MK_SHARED_LIB" in
3286                 (*'-o $[@]')
3287                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
3288                         ;;
3289                 (*)
3290                         AC_MSG_WARN(ignored --with-shlib-version)
3291                         ;;
3292                 esac
3293                 ;;
3294         esac
3295
3296         if test -n "$cf_try_cflags"
3297         then
3298 cat > conftest.$ac_ext <<EOF
3299 #line __oline__ "${as_me:-configure}"
3300 #include <stdio.h>
3301 int main(int argc, char *argv[[]])
3302 {
3303         printf("hello\n");
3304         return (argv[[argc-1]] == 0) ;
3305 }
3306 EOF
3307                 cf_save_CFLAGS="$CFLAGS"
3308                 for cf_opt in $cf_try_cflags
3309                 do
3310                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
3311                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
3312                         if AC_TRY_EVAL(ac_compile); then
3313                                 AC_MSG_RESULT(yes)
3314                                 cf_save_CFLAGS="$CFLAGS"
3315                         else
3316                                 AC_MSG_RESULT(no)
3317                         fi
3318                 done
3319                 CFLAGS="$cf_save_CFLAGS"
3320         fi
3321
3322
3323         # RPATH_LIST is a colon-separated list of directories
3324         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
3325         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
3326
3327         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
3328
3329         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
3330         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
3331
3332         AC_SUBST(CC_SHARED_OPTS)
3333         AC_SUBST(LD_RPATH_OPT)
3334         AC_SUBST(LD_SHARED_OPTS)
3335         AC_SUBST(MK_SHARED_LIB)
3336         AC_SUBST(RM_SHARED_OPTS)
3337
3338         AC_SUBST(LINK_PROGS)
3339         AC_SUBST(LINK_TESTS)
3340
3341         AC_SUBST(EXTRA_LDFLAGS)
3342         AC_SUBST(LOCAL_LDFLAGS)
3343         AC_SUBST(LOCAL_LDFLAGS2)
3344
3345         AC_SUBST(INSTALL_LIB)
3346         AC_SUBST(RPATH_LIST)
3347 ])dnl
3348 dnl ---------------------------------------------------------------------------
3349 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
3350 dnl ----------------
3351 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
3352 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
3353 dnl option.
3354 dnl
3355 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
3356 dnl If missing, use "rel".
3357 define([CF_SHARED_SONAME],
3358 [
3359         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
3360         if test "$cf_cv_shlib_version" = rel; then
3361                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3362         else
3363                 cf_cv_shared_soname='`basename $[@]`'
3364         fi
3365 ])
3366 dnl ---------------------------------------------------------------------------
3367 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
3368 dnl --------------
3369 dnl     Remove "-g" option from the compiler options
3370 AC_DEFUN([CF_STRIP_G_OPT],
3371 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
3372 dnl ---------------------------------------------------------------------------
3373 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
3374 dnl --------------
3375 dnl Construct a search-list for a nonstandard header/lib-file
3376 dnl     $1 = the variable to return as result
3377 dnl     $2 = the package name
3378 dnl     $3 = the subdirectory, e.g., bin, include or lib
3379 AC_DEFUN([CF_SUBDIR_PATH],
3380 [
3381 $1=
3382
3383 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3384
3385 for cf_subdir_prefix in \
3386         /usr \
3387         /usr/local \
3388         /usr/pkg \
3389         /opt \
3390         /opt/local \
3391         [$]HOME
3392 do
3393         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
3394 done
3395 ])dnl
3396 dnl ---------------------------------------------------------------------------
3397 dnl CF_TERM_HEADER version: 4 updated: 2015/04/15 19:08:48
3398 dnl --------------
3399 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3400 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3401 dnl but some packagers change this, breaking various applications.
3402 AC_DEFUN([CF_TERM_HEADER],[
3403 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3404 case ${cf_cv_ncurses_header} in
3405 (*/ncurses.h|*/ncursesw.h)
3406         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3407         ;;
3408 (*)
3409         cf_term_header=term.h
3410         ;;
3411 esac
3412
3413 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3414 do
3415 AC_TRY_COMPILE([#include <stdio.h>
3416 #include <${cf_cv_ncurses_header:-curses.h}>
3417 #include <$cf_test>
3418 ],[int x = auto_left_margin],[
3419         cf_cv_term_header="$cf_test"],[
3420         cf_cv_term_header=unknown
3421         ])
3422         test "$cf_cv_term_header" != unknown && break
3423 done
3424 ])
3425
3426 # Set definitions to allow ifdef'ing to accommodate subdirectories
3427
3428 case $cf_cv_term_header in
3429 (*term.h)
3430         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
3431         ;;
3432 esac
3433
3434 case $cf_cv_term_header in
3435 (ncurses/term.h)
3436         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
3437         ;;
3438 (ncursesw/term.h)
3439         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
3440         ;;
3441 esac
3442 ])dnl
3443 dnl ---------------------------------------------------------------------------
3444 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
3445 dnl ---------------
3446 dnl Define a top_builddir symbol, for applications that need an absolute path.
3447 AC_DEFUN([CF_TOP_BUILDDIR],
3448 [
3449 top_builddir=ifelse($1,,`pwd`,$1)
3450 AC_SUBST(top_builddir)
3451 ])dnl
3452 dnl ---------------------------------------------------------------------------
3453 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
3454 dnl -------------------
3455 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
3456 dnl can define it successfully.
3457 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
3458 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3459         AC_TRY_COMPILE([
3460 #include <stdlib.h>
3461 #include <string.h>
3462 #include <sys/types.h>
3463 ],[
3464 #ifndef _XOPEN_SOURCE
3465 make an error
3466 #endif],
3467         [cf_cv_xopen_source=no],
3468         [cf_save="$CPPFLAGS"
3469          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3470          AC_TRY_COMPILE([
3471 #include <stdlib.h>
3472 #include <string.h>
3473 #include <sys/types.h>
3474 ],[
3475 #ifdef _XOPEN_SOURCE
3476 make an error
3477 #endif],
3478         [cf_cv_xopen_source=no],
3479         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3480         CPPFLAGS="$cf_save"
3481         ])
3482 ])
3483
3484 if test "$cf_cv_xopen_source" != no ; then
3485         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3486         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3487         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3488         CF_ADD_CFLAGS($cf_temp_xopen_source)
3489 fi
3490 ])
3491 dnl ---------------------------------------------------------------------------
3492 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3493 dnl --------
3494 dnl Make an uppercase version of a variable
3495 dnl $1=uppercase($2)
3496 AC_DEFUN([CF_UPPER],
3497 [
3498 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3499 ])dnl
3500 dnl ---------------------------------------------------------------------------
3501 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
3502 dnl -----------
3503 dnl Check for multibyte support, and if not found, utf8 compatibility library
3504 AC_DEFUN([CF_UTF8_LIB],
3505 [
3506 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3507         cf_save_LIBS="$LIBS"
3508         AC_TRY_LINK([
3509 #include <stdlib.h>],[putwc(0,0);],
3510         [cf_cv_utf8_lib=yes],
3511         [CF_FIND_LINKAGE([
3512 #include <libutf8.h>],[putwc(0,0);],utf8,
3513                 [cf_cv_utf8_lib=add-on],
3514                 [cf_cv_utf8_lib=no])
3515 ])])
3516
3517 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3518 # ncurses/ncursesw:
3519 if test "$cf_cv_utf8_lib" = "add-on" ; then
3520         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
3521         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3522         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3523         CF_ADD_LIBS($cf_cv_library_file_utf8)
3524 fi
3525 ])dnl
3526 dnl ---------------------------------------------------------------------------
3527 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3528 dnl ----------
3529 dnl Use AC_VERBOSE w/o the warnings
3530 AC_DEFUN([CF_VERBOSE],
3531 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3532 CF_MSG_LOG([$1])
3533 ])dnl
3534 dnl ---------------------------------------------------------------------------
3535 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
3536 dnl ---------------
3537 dnl Check for compiler-support for weak symbols.
3538 dnl This works with "recent" gcc.
3539 AC_DEFUN([CF_WEAK_SYMBOLS],[
3540 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
3541
3542 AC_TRY_COMPILE([
3543 #include <stdio.h>],
3544 [
3545 #if defined(__GNUC__)
3546 #  if defined __USE_ISOC99
3547 #    define _cat_pragma(exp)    _Pragma(#exp)
3548 #    define _weak_pragma(exp)   _cat_pragma(weak name)
3549 #  else
3550 #    define _weak_pragma(exp)
3551 #  endif
3552 #  define _declare(name)        __extension__ extern __typeof__(name) name
3553 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
3554 #endif
3555
3556 weak_symbol(fopen);
3557 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
3558 ])
3559 ])dnl
3560 dnl ---------------------------------------------------------------------------
3561 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
3562 dnl --------------------
3563 dnl Command-line option to specify the Ada95 compiler.
3564 AC_DEFUN([CF_WITH_ADA_COMPILER],[
3565 AC_MSG_CHECKING(for ada-compiler)
3566 AC_ARG_WITH(ada-compiler,
3567         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
3568         [cf_ada_compiler=$withval],
3569         [cf_ada_compiler=gnatmake])
3570 AC_SUBST(cf_ada_compiler)
3571 AC_MSG_RESULT($cf_ada_compiler)
3572 ])dnl
3573 dnl ---------------------------------------------------------------------------
3574 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
3575 dnl -------------------
3576 dnl Command-line option to specify where Ada includes will install.
3577 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
3578 AC_MSG_CHECKING(for ada-include)
3579 CF_WITH_PATH(ada-include,
3580    [  --with-ada-include=DIR  Ada includes are in DIR],
3581    ADA_INCLUDE,
3582    PREFIX/share/ada/adainclude,
3583    [$]prefix/share/ada/adainclude)
3584 AC_SUBST(ADA_INCLUDE)
3585 AC_MSG_RESULT($ADA_INCLUDE)
3586 ])dnl
3587 dnl ---------------------------------------------------------------------------
3588 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
3589 dnl -------------------
3590 dnl Command-line option to specify where Ada objects will install.
3591 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
3592 AC_MSG_CHECKING(for ada-objects)
3593 CF_WITH_PATH(ada-objects,
3594    [  --with-ada-objects=DIR  Ada objects are in DIR],
3595    ADA_OBJECTS,
3596    PREFIX/lib/ada/adalib,
3597    [$]prefix/lib/ada/adalib)
3598 AC_SUBST(ADA_OBJECTS)
3599 AC_MSG_RESULT($ADA_OBJECTS)
3600 ])dnl
3601 dnl ---------------------------------------------------------------------------
3602 dnl CF_WITH_ADA_SHAREDLIB version: 4 updated: 2014/05/31 21:08:37
3603 dnl ---------------------
3604 dnl Command-line option to specify if an Ada95 shared-library should be built,
3605 dnl and optionally what its soname should be.
3606 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
3607 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
3608 AC_ARG_WITH(ada-sharedlib,
3609         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
3610         [with_ada_sharedlib=$withval],
3611         [with_ada_sharedlib=no])
3612 AC_MSG_RESULT($with_ada_sharedlib)
3613
3614 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
3615 MAKE_ADA_SHAREDLIB="#"
3616
3617 if test "x$with_ada_sharedlib" != xno
3618 then
3619         MAKE_ADA_SHAREDLIB=
3620         if test "x$with_ada_sharedlib" != xyes
3621         then
3622                 ADA_SHAREDLIB="$with_ada_sharedlib"
3623         fi
3624 fi
3625
3626 AC_SUBST(ADA_SHAREDLIB)
3627 AC_SUBST(MAKE_ADA_SHAREDLIB)
3628 ])dnl
3629 dnl ---------------------------------------------------------------------------
3630 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3631 dnl ------------------
3632 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3633 dnl libraries.
3634 AC_DEFUN([CF_WITH_CURSES_DIR],[
3635
3636 AC_MSG_CHECKING(for specific curses-directory)
3637 AC_ARG_WITH(curses-dir,
3638         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3639         [cf_cv_curses_dir=$withval],
3640         [cf_cv_curses_dir=no])
3641 AC_MSG_RESULT($cf_cv_curses_dir)
3642
3643 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3644 then
3645         CF_PATH_SYNTAX(withval)
3646         if test -d "$cf_cv_curses_dir"
3647         then
3648                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3649                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3650         fi
3651 fi
3652 ])dnl
3653 dnl ---------------------------------------------------------------------------
3654 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
3655 dnl ------------------
3656 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
3657 dnl "lib" prefix, e.g., because it used the dll naming convention.
3658 dnl
3659 dnl $1 = variable to set
3660 AC_DEFUN([CF_WITH_LIB_PREFIX],
3661 [
3662 AC_MSG_CHECKING(if you want to have a library-prefix)
3663 AC_ARG_WITH(lib-prefix,
3664         [  --with-lib-prefix       override library-prefix],
3665         [with_lib_prefix=$withval],
3666         [with_lib_prefix=auto])
3667 AC_MSG_RESULT($with_lib_prefix)
3668
3669 if test $with_lib_prefix = auto
3670 then
3671         CF_LIB_PREFIX($1)
3672 elif test $with_lib_prefix = no
3673 then
3674         LIB_PREFIX=
3675 else
3676         LIB_PREFIX=$with_lib_prefix
3677 fi
3678 ])dnl
3679 dnl ---------------------------------------------------------------------------
3680 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
3681 dnl ------------
3682 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
3683 dnl defaulting to yes/no.
3684 dnl
3685 dnl $1 = option name
3686 dnl $2 = help-text
3687 dnl $3 = environment variable to set
3688 dnl $4 = default value, shown in the help-message, must be a constant
3689 dnl $5 = default value, if it's an expression & cannot be in the help-message
3690 dnl
3691 AC_DEFUN([CF_WITH_PATH],
3692 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
3693 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
3694 if ifelse([$5],,true,[test -n "$5"]) ; then
3695 CF_PATH_SYNTAX(withval)
3696 fi
3697 eval $3="$withval"
3698 AC_SUBST($3)dnl
3699 ])dnl
3700 dnl ---------------------------------------------------------------------------
3701 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 7 updated: 2015/04/26 18:06:58
3702 dnl -------------------------
3703 dnl Allow the choice of the pkg-config library directory to be overridden.
3704 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
3705 AC_MSG_CHECKING(for $PKG_CONFIG library directory)
3706 if test "x$PKG_CONFIG" = xnone ; then
3707         PKG_CONFIG_LIBDIR=none
3708 else
3709         AC_ARG_WITH(pkg-config-libdir,
3710                 [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
3711                 [PKG_CONFIG_LIBDIR=$withval],
3712                 [PKG_CONFIG_LIBDIR=yes])
3713 fi
3714
3715 case x$PKG_CONFIG_LIBDIR in
3716 (x/*)
3717         ;;
3718 (xyes)
3719         # Look for the library directory using the same prefix as the executable
3720         if test "x$PKG_CONFIG" = xnone
3721         then
3722                 cf_path=$prefix
3723         else
3724                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
3725         fi
3726
3727         # If you don't like using the default architecture, you have to specify the
3728         # intended library directory and corresponding compiler/linker options.
3729         #
3730         # This case allows for Debian's 2014-flavor of multiarch, along with the
3731         # most common variations before that point.  Some other variants spell the
3732         # directory differently, e.g., "pkg-config", and put it in unusual places.
3733         # pkg-config has always been poorly standardized, which is ironic...
3734         case x`(arch) 2>/dev/null` in
3735         (*64)
3736                 cf_search_path="\
3737                         $cf_path/lib/*64-linux-gnu \
3738                         $cf_path/share \
3739                         $cf_path/lib64 \
3740                         $cf_path/lib32 \
3741                         $cf_path/lib"
3742                 ;;
3743         (*)
3744                 cf_search_path="\
3745                         $cf_path/lib/*-linux-gnu \
3746                         $cf_path/share \
3747                         $cf_path/lib32 \
3748                         $cf_path/lib \
3749                         $cf_path/libdata"
3750                 ;;
3751         esac
3752
3753         CF_VERBOSE(list...)
3754         for cf_config in $cf_search_path
3755         do
3756                 CF_VERBOSE(checking $cf_config/pkgconfig)
3757                 if test -d $cf_config/pkgconfig
3758                 then
3759                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
3760                         AC_MSG_CHECKING(done)
3761                         break
3762                 fi
3763         done
3764         ;;
3765 (*)
3766         ;;
3767 esac
3768
3769 if test "x$PKG_CONFIG" != xnone ; then
3770         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
3771 fi
3772
3773 AC_SUBST(PKG_CONFIG_LIBDIR)
3774 ])dnl
3775 dnl ---------------------------------------------------------------------------
3776 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
3777 dnl ---------------
3778 dnl Check for POSIX thread library.
3779 AC_DEFUN([CF_WITH_PTHREAD],
3780 [
3781 AC_MSG_CHECKING(if you want to link with the pthread library)
3782 AC_ARG_WITH(pthread,
3783         [  --with-pthread          use POSIX thread library],
3784         [with_pthread=$withval],
3785         [with_pthread=no])
3786 AC_MSG_RESULT($with_pthread)
3787
3788 if test "$with_pthread" != no ; then
3789         AC_CHECK_HEADER(pthread.h,[
3790         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
3791
3792         for cf_lib_pthread in pthread c_r
3793         do
3794             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
3795             cf_save_LIBS="$LIBS"
3796             CF_ADD_LIB($cf_lib_pthread)
3797             AC_TRY_LINK([
3798 #include <pthread.h>
3799 ],[
3800                 int rc = pthread_create(0,0,0,0);
3801                 int r2 = pthread_mutexattr_settype(0, 0);
3802 ],[with_pthread=yes],[with_pthread=no])
3803             LIBS="$cf_save_LIBS"
3804             AC_MSG_RESULT($with_pthread)
3805             test "$with_pthread" = yes && break
3806         done
3807
3808         if test "$with_pthread" = yes ; then
3809             CF_ADD_LIB($cf_lib_pthread)
3810             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
3811         else
3812             AC_MSG_ERROR(Cannot link with pthread library)
3813         fi
3814         ])
3815 fi
3816 ])
3817 dnl ---------------------------------------------------------------------------
3818 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
3819 dnl ---------------
3820 dnl For testing, override the derived host system-type which is used to decide
3821 dnl things such as the linker commands used to build shared libraries.  This is
3822 dnl normally chosen automatically based on the type of system which you are
3823 dnl building on.  We use it for testing the configure script.
3824 dnl
3825 dnl This is different from the --host option: it is used only for testing parts
3826 dnl of the configure script which would not be reachable with --host since that
3827 dnl relies on the build environment being real, rather than mocked up.
3828 AC_DEFUN([CF_WITH_SYSTYPE],[
3829 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
3830 AC_ARG_WITH(system-type,
3831         [  --with-system-type=XXX  test: override derived host system-type],
3832 [AC_MSG_WARN(overriding system type to $withval)
3833         cf_cv_system_name=$withval
3834         host_os=$withval
3835 ])
3836 ])dnl
3837 dnl ---------------------------------------------------------------------------
3838 dnl CF_XOPEN_SOURCE version: 49 updated: 2015/04/12 15:39:00
3839 dnl ---------------
3840 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
3841 dnl or adapt to the vendor's definitions to get equivalent functionality,
3842 dnl without losing the common non-POSIX features.
3843 dnl
3844 dnl Parameters:
3845 dnl     $1 is the nominal value for _XOPEN_SOURCE
3846 dnl     $2 is the nominal value for _POSIX_C_SOURCE
3847 AC_DEFUN([CF_XOPEN_SOURCE],[
3848 AC_REQUIRE([AC_CANONICAL_HOST])
3849
3850 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
3851 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
3852 cf_xopen_source=
3853
3854 case $host_os in
3855 (aix[[4-7]]*)
3856         cf_xopen_source="-D_ALL_SOURCE"
3857         ;;
3858 (cygwin|msys)
3859         cf_XOPEN_SOURCE=600
3860         ;;
3861 (darwin[[0-8]].*)
3862         cf_xopen_source="-D_APPLE_C_SOURCE"
3863         ;;
3864 (darwin*)
3865         cf_xopen_source="-D_DARWIN_C_SOURCE"
3866         cf_XOPEN_SOURCE=
3867         ;;
3868 (freebsd*|dragonfly*)
3869         # 5.x headers associate
3870         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
3871         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
3872         cf_POSIX_C_SOURCE=200112L
3873         cf_XOPEN_SOURCE=600
3874         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3875         ;;
3876 (hpux11*)
3877         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
3878         ;;
3879 (hpux*)
3880         cf_xopen_source="-D_HPUX_SOURCE"
3881         ;;
3882 (irix[[56]].*)
3883         cf_xopen_source="-D_SGI_SOURCE"
3884         cf_XOPEN_SOURCE=
3885         ;;
3886 (linux*|gnu*|mint*|k*bsd*-gnu)
3887         CF_GNU_SOURCE
3888         ;;
3889 (minix*)
3890         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
3891         ;;
3892 (mirbsd*)
3893         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
3894         cf_XOPEN_SOURCE=
3895         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3896         ;;
3897 (netbsd*)
3898         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
3899         ;;
3900 (openbsd[[4-9]]*)
3901         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
3902         cf_xopen_source="-D_BSD_SOURCE"
3903         cf_XOPEN_SOURCE=600
3904         ;;
3905 (openbsd*)
3906         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
3907         ;;
3908 (osf[[45]]*)
3909         cf_xopen_source="-D_OSF_SOURCE"
3910         ;;
3911 (nto-qnx*)
3912         cf_xopen_source="-D_QNX_SOURCE"
3913         ;;
3914 (sco*)
3915         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
3916         ;;
3917 (solaris2.*)
3918         cf_xopen_source="-D__EXTENSIONS__"
3919         cf_cv_xopen_source=broken
3920         ;;
3921 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
3922         cf_XOPEN_SOURCE=
3923         cf_POSIX_C_SOURCE=
3924         ;;
3925 (*)
3926         CF_TRY_XOPEN_SOURCE
3927         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3928         ;;
3929 esac
3930
3931 if test -n "$cf_xopen_source" ; then
3932         CF_ADD_CFLAGS($cf_xopen_source,true)
3933 fi
3934
3935 dnl In anything but the default case, we may have system-specific setting
3936 dnl which is still not guaranteed to provide all of the entrypoints that
3937 dnl _XOPEN_SOURCE would yield.
3938 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
3939         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
3940         AC_TRY_COMPILE([#include <stdlib.h>],[
3941 #ifndef _XOPEN_SOURCE
3942 make an error
3943 #endif],
3944         [cf_XOPEN_SOURCE_set=yes],
3945         [cf_XOPEN_SOURCE_set=no])
3946         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
3947         if test $cf_XOPEN_SOURCE_set = yes
3948         then
3949                 AC_TRY_COMPILE([#include <stdlib.h>],[
3950 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
3951 make an error
3952 #endif],
3953                 [cf_XOPEN_SOURCE_set_ok=yes],
3954                 [cf_XOPEN_SOURCE_set_ok=no])
3955                 if test $cf_XOPEN_SOURCE_set_ok = no
3956                 then
3957                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
3958                 fi
3959         else
3960                 CF_TRY_XOPEN_SOURCE
3961         fi
3962 fi
3963 ])