ncurses 6.1 - patch 20180616
[ncurses.git] / Ada95 / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright (c) 2010-2017,2018 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey
30 dnl
31 dnl $Id: aclocal.m4,v 1.132 2018/06/16 23:08:19 tom Exp $
32 dnl Macros used in NCURSES Ada95 auto-configuration script.
33 dnl
34 dnl These macros are maintained separately from NCURSES.  The copyright on
35 dnl this file applies to the aggregation of macros and does not affect use of
36 dnl these macros in other applications.
37 dnl
38 dnl See https://invisible-island.net/autoconf/ for additional information.
39 dnl
40 dnl ---------------------------------------------------------------------------
41 dnl ---------------------------------------------------------------------------
42 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
43 dnl ------------------
44 dnl Conditionally generate script according to whether we're using a given autoconf.
45 dnl
46 dnl $1 = version to compare against
47 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
48 dnl $3 = code to use if AC_ACVERSION is older than $1.
49 define([CF_ACVERSION_CHECK],
50 [
51 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
52 ifdef([m4_version_compare],
53 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
54 [CF_ACVERSION_COMPARE(
55 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
56 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
57 dnl ---------------------------------------------------------------------------
58 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
59 dnl --------------------
60 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
61 dnl                      MAJOR2, MINOR2, TERNARY2,
62 dnl                      PRINTABLE2, not FOUND, FOUND)
63 define([CF_ACVERSION_COMPARE],
64 [ifelse(builtin([eval], [$2 < $5]), 1,
65 [ifelse([$8], , ,[$8])],
66 [ifelse([$9], , ,[$9])])])dnl
67 dnl ---------------------------------------------------------------------------
68 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
69 dnl -------------------
70 dnl Construct the list of include-options for the C programs in the Ada95
71 dnl binding.
72 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
73 [
74 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
75 if test "$srcdir" != "."; then
76         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
77 fi
78 if test "$GCC" != yes; then
79         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
80 elif test "$includedir" != "/usr/include"; then
81         if test "$includedir" = '${prefix}/include' ; then
82                 if test x$prefix != x/usr ; then
83                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
84                 fi
85         else
86                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
87         fi
88 fi
89 AC_SUBST(ACPPFLAGS)
90 ])dnl
91 dnl ---------------------------------------------------------------------------
92 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
93 dnl ---------------
94 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
95 AC_DEFUN([CF_ADD_ADAFLAGS],[
96         ADAFLAGS="$ADAFLAGS $1"
97         AC_SUBST(ADAFLAGS)
98 ])dnl
99 dnl ---------------------------------------------------------------------------
100 dnl CF_ADD_CFLAGS version: 13 updated: 2017/02/25 18:57:40
101 dnl -------------
102 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
103 dnl The second parameter if given makes this macro verbose.
104 dnl
105 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
106 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
107 dnl confused by the quotes (which require backslashes to keep them usable).
108 AC_DEFUN([CF_ADD_CFLAGS],
109 [
110 cf_fix_cppflags=no
111 cf_new_cflags=
112 cf_new_cppflags=
113 cf_new_extra_cppflags=
114
115 for cf_add_cflags in $1
116 do
117 case $cf_fix_cppflags in
118 (no)
119         case $cf_add_cflags in
120         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
121                 case $cf_add_cflags in
122                 (-D*)
123                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
124
125                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
126                                 && test -z "${cf_tst_cflags}" \
127                                 && cf_fix_cppflags=yes
128
129                         if test $cf_fix_cppflags = yes ; then
130                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
131                                 continue
132                         elif test "${cf_tst_cflags}" = "\"'" ; then
133                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
134                                 continue
135                         fi
136                         ;;
137                 esac
138                 case "$CPPFLAGS" in
139                 (*$cf_add_cflags)
140                         ;;
141                 (*)
142                         case $cf_add_cflags in
143                         (-D*)
144                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
145                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
146                                 ;;
147                         esac
148                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
149                         ;;
150                 esac
151                 ;;
152         (*)
153                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
154                 ;;
155         esac
156         ;;
157 (yes)
158         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
159
160         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
161
162         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
163                 && test -z "${cf_tst_cflags}" \
164                 && cf_fix_cppflags=no
165         ;;
166 esac
167 done
168
169 if test -n "$cf_new_cflags" ; then
170         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
171         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
172 fi
173
174 if test -n "$cf_new_cppflags" ; then
175         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
176         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
177 fi
178
179 if test -n "$cf_new_extra_cppflags" ; then
180         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
181         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
182 fi
183
184 AC_SUBST(EXTRA_CPPFLAGS)
185
186 ])dnl
187 dnl ---------------------------------------------------------------------------
188 dnl CF_ADD_INCDIR version: 14 updated: 2015/05/25 20:53:04
189 dnl -------------
190 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
191 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
192 dnl but old versions (and some misinstalled ones) need that.  To make things
193 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
194 dnl the include-path).
195 AC_DEFUN([CF_ADD_INCDIR],
196 [
197 if test -n "$1" ; then
198   for cf_add_incdir in $1
199   do
200         while test $cf_add_incdir != /usr/include
201         do
202           if test -d $cf_add_incdir
203           then
204                 cf_have_incdir=no
205                 if test -n "$CFLAGS$CPPFLAGS" ; then
206                   # a loop is needed to ensure we can add subdirs of existing dirs
207                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
208                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
209                           cf_have_incdir=yes; break
210                         fi
211                   done
212                 fi
213
214                 if test "$cf_have_incdir" = no ; then
215                   if test "$cf_add_incdir" = /usr/local/include ; then
216                         if test "$GCC" = yes
217                         then
218                           cf_save_CPPFLAGS=$CPPFLAGS
219                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
220                           AC_TRY_COMPILE([#include <stdio.h>],
221                                   [printf("Hello")],
222                                   [],
223                                   [cf_have_incdir=yes])
224                           CPPFLAGS=$cf_save_CPPFLAGS
225                         fi
226                   fi
227                 fi
228
229                 if test "$cf_have_incdir" = no ; then
230                   CF_VERBOSE(adding $cf_add_incdir to include-path)
231                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
232
233                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
234                   test "$cf_top_incdir" = "$cf_add_incdir" && break
235                   cf_add_incdir="$cf_top_incdir"
236                 else
237                   break
238                 fi
239           else
240                 break
241           fi
242         done
243   done
244 fi
245 ])dnl
246 dnl ---------------------------------------------------------------------------
247 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
248 dnl ----------
249 dnl Add a library, used to enforce consistency.
250 dnl
251 dnl $1 = library to add, without the "-l"
252 dnl $2 = variable to update (default $LIBS)
253 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
254 dnl ---------------------------------------------------------------------------
255 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
256 dnl -------------
257 dnl     Adds to the library-path
258 dnl
259 dnl     Some machines have trouble with multiple -L options.
260 dnl
261 dnl $1 is the (list of) directory(s) to add
262 dnl $2 is the optional name of the variable to update (default LDFLAGS)
263 dnl
264 AC_DEFUN([CF_ADD_LIBDIR],
265 [
266 if test -n "$1" ; then
267         for cf_add_libdir in $1
268         do
269                 if test $cf_add_libdir = /usr/lib ; then
270                         :
271                 elif test -d $cf_add_libdir
272                 then
273                         cf_have_libdir=no
274                         if test -n "$LDFLAGS$LIBS" ; then
275                                 # a loop is needed to ensure we can add subdirs of existing dirs
276                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
277                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
278                                                 cf_have_libdir=yes; break
279                                         fi
280                                 done
281                         fi
282                         if test "$cf_have_libdir" = no ; then
283                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
284                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
285                         fi
286                 fi
287         done
288 fi
289 ])dnl
290 dnl ---------------------------------------------------------------------------
291 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
292 dnl -----------
293 dnl Add one or more libraries, used to enforce consistency.  Libraries are
294 dnl prepended to an existing list, since their dependencies are assumed to
295 dnl already exist in the list.
296 dnl
297 dnl $1 = libraries to add, with the "-l", etc.
298 dnl $2 = variable to update (default $LIBS)
299 AC_DEFUN([CF_ADD_LIBS],[
300 cf_add_libs="$1"
301 # Filter out duplicates - this happens with badly-designed ".pc" files...
302 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
303 do
304         for cf_add_2lib in $cf_add_libs
305         do
306                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
307                 then
308                         cf_add_1lib=
309                         break
310                 fi
311         done
312         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
313 done
314 ifelse($2,,LIBS,[$2])="$cf_add_libs"
315 ])dnl
316 dnl ---------------------------------------------------------------------------
317 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
318 dnl ------------------
319 dnl Append to a search-list for a nonstandard header/lib-file
320 dnl     $1 = the variable to return as result
321 dnl     $2 = the package name
322 dnl     $3 = the subdirectory, e.g., bin, include or lib
323 dnl $4 = the directory under which we will test for subdirectories
324 dnl $5 = a directory that we do not want $4 to match
325 AC_DEFUN([CF_ADD_SUBDIR_PATH],
326 [
327 test "x$4" != "x$5" && \
328 test -d "$4" && \
329 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
330         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
331         test -d $4/$3 &&          $1="[$]$1 $4/$3"
332         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
333         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
334         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
335         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
336 }
337 ])dnl
338 dnl ---------------------------------------------------------------------------
339 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
340 dnl --------------
341 dnl use this macro for appending text without introducing an extra blank at
342 dnl the beginning
343 define([CF_APPEND_TEXT],
344 [
345         test -n "[$]$1" && $1="[$]$1 "
346         $1="[$]{$1}$2"
347 ])dnl
348 dnl ---------------------------------------------------------------------------
349 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
350 dnl --------------
351 dnl Allow user to disable a normally-on option.
352 AC_DEFUN([CF_ARG_DISABLE],
353 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
354 dnl ---------------------------------------------------------------------------
355 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
356 dnl -------------
357 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
358 dnl values.
359 dnl
360 dnl Parameters:
361 dnl $1 = option name
362 dnl $2 = help-string
363 dnl $3 = action to perform if option is not default
364 dnl $4 = action if perform if option is default
365 dnl $5 = default option value (either 'yes' or 'no')
366 AC_DEFUN([CF_ARG_OPTION],
367 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
368         if test "$enableval" != "$5" ; then
369 ifelse([$3],,[    :]dnl
370 ,[    $3]) ifelse([$4],,,[
371         else
372                 $4])
373         fi],[enableval=$5 ifelse([$4],,,[
374         $4
375 ])dnl
376 ])])dnl
377 dnl ---------------------------------------------------------------------------
378 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
379 dnl -----------
380 dnl Check for suitable "ar" (archiver) options for updating an archive.
381 dnl
382 dnl In particular, handle some obsolete cases where the "-" might be omitted,
383 dnl as well as a workaround for breakage of make's archive rules by the GNU
384 dnl binutils "ar" program.
385 AC_DEFUN([CF_AR_FLAGS],[
386 AC_REQUIRE([CF_PROG_AR])
387
388 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
389         cf_cv_ar_flags=unknown
390         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
391         do
392
393                 # check if $ARFLAGS already contains this choice
394                 if test "x$ARFLAGS" != "x" ; then
395                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
396                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
397                                 cf_cv_ar_flags=
398                                 break
399                         fi
400                 fi
401
402                 rm -f conftest.$ac_cv_objext
403                 rm -f conftest.a
404
405                 cat >conftest.$ac_ext <<EOF
406 #line __oline__ "configure"
407 int     testdata[[3]] = { 123, 456, 789 };
408 EOF
409                 if AC_TRY_EVAL(ac_compile) ; then
410                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
411                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
412                         if test -f conftest.a ; then
413                                 cf_cv_ar_flags=$cf_ar_flags
414                                 break
415                         fi
416                 else
417                         CF_VERBOSE(cannot compile test-program)
418                         break
419                 fi
420         done
421         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
422 ])
423
424 if test -n "$ARFLAGS" ; then
425         if test -n "$cf_cv_ar_flags" ; then
426                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
427         fi
428 else
429         ARFLAGS=$cf_cv_ar_flags
430 fi
431
432 AC_SUBST(ARFLAGS)
433 ])
434 dnl ---------------------------------------------------------------------------
435 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
436 dnl -----------
437 dnl If we're cross-compiling, allow the user to override the tools and their
438 dnl options.  The configure script is oriented toward identifying the host
439 dnl compiler, etc., but we need a build compiler to generate parts of the
440 dnl source.
441 dnl
442 dnl $1 = default for $CPPFLAGS
443 dnl $2 = default for $LIBS
444 AC_DEFUN([CF_BUILD_CC],[
445 CF_ACVERSION_CHECK(2.52,,
446         [AC_REQUIRE([CF_PROG_EXT])])
447 if test "$cross_compiling" = yes ; then
448
449         # defaults that we might want to override
450         : ${BUILD_CFLAGS:=''}
451         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
452         : ${BUILD_LDFLAGS:=''}
453         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
454         : ${BUILD_EXEEXT:='$x'}
455         : ${BUILD_OBJEXT:='o'}
456
457         AC_ARG_WITH(build-cc,
458                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
459                 [BUILD_CC="$withval"],
460                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
461         AC_MSG_CHECKING(for native build C compiler)
462         AC_MSG_RESULT($BUILD_CC)
463
464         AC_MSG_CHECKING(for native build C preprocessor)
465         AC_ARG_WITH(build-cpp,
466                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
467                 [BUILD_CPP="$withval"],
468                 [BUILD_CPP='${BUILD_CC} -E'])
469         AC_MSG_RESULT($BUILD_CPP)
470
471         AC_MSG_CHECKING(for native build C flags)
472         AC_ARG_WITH(build-cflags,
473                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
474                 [BUILD_CFLAGS="$withval"])
475         AC_MSG_RESULT($BUILD_CFLAGS)
476
477         AC_MSG_CHECKING(for native build C preprocessor-flags)
478         AC_ARG_WITH(build-cppflags,
479                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
480                 [BUILD_CPPFLAGS="$withval"])
481         AC_MSG_RESULT($BUILD_CPPFLAGS)
482
483         AC_MSG_CHECKING(for native build linker-flags)
484         AC_ARG_WITH(build-ldflags,
485                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
486                 [BUILD_LDFLAGS="$withval"])
487         AC_MSG_RESULT($BUILD_LDFLAGS)
488
489         AC_MSG_CHECKING(for native build linker-libraries)
490         AC_ARG_WITH(build-libs,
491                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
492                 [BUILD_LIBS="$withval"])
493         AC_MSG_RESULT($BUILD_LIBS)
494
495         # this assumes we're on Unix.
496         BUILD_EXEEXT=
497         BUILD_OBJEXT=o
498
499         : ${BUILD_CC:='${CC}'}
500
501         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
502                 AC_MSG_ERROR([Cross-build requires two compilers.
503 Use --with-build-cc to specify the native compiler.])
504         fi
505
506 else
507         : ${BUILD_CC:='${CC}'}
508         : ${BUILD_CPP:='${CPP}'}
509         : ${BUILD_CFLAGS:='${CFLAGS}'}
510         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
511         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
512         : ${BUILD_LIBS:='${LIBS}'}
513         : ${BUILD_EXEEXT:='$x'}
514         : ${BUILD_OBJEXT:='o'}
515 fi
516
517 AC_SUBST(BUILD_CC)
518 AC_SUBST(BUILD_CPP)
519 AC_SUBST(BUILD_CFLAGS)
520 AC_SUBST(BUILD_CPPFLAGS)
521 AC_SUBST(BUILD_LDFLAGS)
522 AC_SUBST(BUILD_LIBS)
523 AC_SUBST(BUILD_EXEEXT)
524 AC_SUBST(BUILD_OBJEXT)
525 ])dnl
526 dnl ---------------------------------------------------------------------------
527 dnl CF_CC_ENV_FLAGS version: 8 updated: 2017/09/23 08:50:24
528 dnl ---------------
529 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
530 dnl into CC.  This will not help with broken scripts that wrap the compiler
531 dnl with options, but eliminates a more common category of user confusion.
532 dnl
533 dnl In particular, it addresses the problem of being able to run the C
534 dnl preprocessor in a consistent manner.
535 dnl
536 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
537 dnl the nuisance of having inconsistent settings for compiler and preprocessor
538 dnl outweighs that limitation.
539 AC_DEFUN([CF_CC_ENV_FLAGS],
540 [
541 # This should have been defined by AC_PROG_CC
542 : ${CC:=cc}
543
544 AC_MSG_CHECKING(\$CC variable)
545 case "$CC" in
546 (*[[\ \ ]]-*)
547         AC_MSG_RESULT(broken)
548         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
549         # humor him...
550         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
551         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
552         CC="$cf_prog"
553         for cf_arg in $cf_flags
554         do
555                 case "x$cf_arg" in
556                 (x-[[IUDfgOW]]*)
557                         CF_ADD_CFLAGS($cf_arg)
558                         ;;
559                 (*)
560                         CC="$CC $cf_arg"
561                         ;;
562                 esac
563         done
564         CF_VERBOSE(resulting CC: '$CC')
565         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
566         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
567         ;;
568 (*)
569         AC_MSG_RESULT(ok)
570         ;;
571 esac
572 ])dnl
573 dnl ---------------------------------------------------------------------------
574 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
575 dnl ---------------
576 dnl Determine the default configuration into which we'll install ncurses.  This
577 dnl can be overridden by the user's command-line options.  There's two items to
578 dnl look for:
579 dnl     1. the prefix (e.g., /usr)
580 dnl     2. the header files (e.g., /usr/include/ncurses)
581 dnl We'll look for a previous installation of ncurses and use the same defaults.
582 dnl
583 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
584 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
585 dnl programs from a vendor's.
586 AC_DEFUN([CF_CFG_DEFAULTS],
587 [
588 AC_MSG_CHECKING(for prefix)
589 if test "x$prefix" = "xNONE" ; then
590         case "$cf_cv_system_name" in
591                 # non-vendor systems don't have a conflict
592         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
593                 prefix=/usr
594                 ;;
595         (*)     prefix=$ac_default_prefix
596                 ;;
597         esac
598 fi
599 AC_MSG_RESULT($prefix)
600
601 if test "x$prefix" = "xNONE" ; then
602 AC_MSG_CHECKING(for default include-directory)
603 test -n "$verbose" && echo 1>&AC_FD_MSG
604 for cf_symbol in \
605         $includedir \
606         $includedir/ncurses \
607         $prefix/include \
608         $prefix/include/ncurses \
609         /usr/local/include \
610         /usr/local/include/ncurses \
611         /usr/include \
612         /usr/include/ncurses
613 do
614         cf_dir=`eval echo $cf_symbol`
615         if test -f $cf_dir/curses.h ; then
616         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
617                 includedir="$cf_symbol"
618                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
619                 break
620         fi
621         fi
622         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
623 done
624 AC_MSG_RESULT($includedir)
625 fi
626 ])dnl
627 dnl ---------------------------------------------------------------------------
628 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
629 dnl --------------
630 dnl Check if we're accidentally using a cache from a different machine.
631 dnl Derive the system name, as a check for reusing the autoconf cache.
632 dnl
633 dnl If we've packaged config.guess and config.sub, run that (since it does a
634 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
635 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
636 dnl which is useful in cross-compiles.
637 dnl
638 dnl Note: we would use $ac_config_sub, but that is one of the places where
639 dnl autoconf 2.5x broke compatibility with autoconf 2.13
640 AC_DEFUN([CF_CHECK_CACHE],
641 [
642 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
643         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
644         system_name="$host_os"
645 else
646         system_name="`(uname -s -r) 2>/dev/null`"
647         if test -z "$system_name" ; then
648                 system_name="`(hostname) 2>/dev/null`"
649         fi
650 fi
651 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
652 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
653
654 test -z "$system_name" && system_name="$cf_cv_system_name"
655 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
656
657 if test ".$system_name" != ".$cf_cv_system_name" ; then
658         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
659         AC_MSG_ERROR("Please remove config.cache and try again.")
660 fi
661 ])dnl
662 dnl ---------------------------------------------------------------------------
663 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
664 dnl -----------------
665 dnl Check if the given compiler is really clang.  clang's C driver defines
666 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
667 dnl not ignore some gcc options.
668 dnl
669 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
670 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
671 dnl the wrappers for gcc and g++ warnings.
672 dnl
673 dnl $1 = GCC (default) or GXX
674 dnl $2 = CLANG_COMPILER (default)
675 dnl $3 = CFLAGS (default) or CXXFLAGS
676 AC_DEFUN([CF_CLANG_COMPILER],[
677 ifelse([$2],,CLANG_COMPILER,[$2])=no
678
679 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
680         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
681         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
682         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
683         AC_TRY_COMPILE([],[
684 #ifdef __clang__
685 #else
686 make an error
687 #endif
688 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
689 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
690 ],[])
691         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
692         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
693 fi
694 ])
695 dnl ---------------------------------------------------------------------------
696 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
697 dnl ----------------
698 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
699 dnl variations of ncurses' installs.
700 dnl
701 dnl $1 = ncurses when looking for ncurses, or is empty
702 AC_DEFUN([CF_CURSES_HEADER],[
703 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
704 cf_cv_ncurses_header=none
705 for cf_header in \
706         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
707         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
708 do
709 AC_TRY_COMPILE([#include <${cf_header}>],
710         [initscr(); tgoto("?", 0,0)],
711         [cf_cv_ncurses_header=$cf_header; break],[])
712 done
713 ])
714
715 if test "$cf_cv_ncurses_header" = none ; then
716         AC_MSG_ERROR(No curses header-files found)
717 fi
718
719 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
720 AC_CHECK_HEADERS($cf_cv_ncurses_header)
721 ])dnl
722 dnl ---------------------------------------------------------------------------
723 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
724 dnl ----------
725 dnl "dirname" is not portable, so we fake it with a shell script.
726 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
727 dnl ---------------------------------------------------------------------------
728 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
729 dnl ---------------
730 dnl You can always use "make -n" to see the actual options, but it's hard to
731 dnl pick out/analyze warning messages when the compile-line is long.
732 dnl
733 dnl Sets:
734 dnl     ECHO_LT - symbol to control if libtool is verbose
735 dnl     ECHO_LD - symbol to prefix "cc -o" lines
736 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
737 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
738 dnl     ECHO_CC - symbol to put before any "cc" line
739 dnl
740 AC_DEFUN([CF_DISABLE_ECHO],[
741 AC_MSG_CHECKING(if you want to see long compiling messages)
742 CF_ARG_DISABLE(echo,
743         [  --disable-echo          do not display "compiling" commands],
744         [
745         ECHO_LT='--silent'
746         ECHO_LD='@echo linking [$]@;'
747         RULE_CC='@echo compiling [$]<'
748         SHOW_CC='@echo compiling [$]@'
749         ECHO_CC='@'
750 ],[
751         ECHO_LT=''
752         ECHO_LD=''
753         RULE_CC=''
754         SHOW_CC=''
755         ECHO_CC=''
756 ])
757 AC_MSG_RESULT($enableval)
758 AC_SUBST(ECHO_LT)
759 AC_SUBST(ECHO_LD)
760 AC_SUBST(RULE_CC)
761 AC_SUBST(SHOW_CC)
762 AC_SUBST(ECHO_CC)
763 ])dnl
764 dnl ---------------------------------------------------------------------------
765 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
766 dnl ------------------------
767 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
768 AC_MSG_CHECKING(if we want to use GNAT projects)
769 CF_ARG_DISABLE(gnat-projects,
770         [  --disable-gnat-projects test: disable GNAT projects even if usable],
771         [enable_gnat_projects=no],
772         [enable_gnat_projects=yes])
773 AC_MSG_RESULT($enable_gnat_projects)
774 ])dnl
775 dnl ---------------------------------------------------------------------------
776 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
777 dnl ---------------
778 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
779 dnl prefer a standard location, and use -L options only if we do not find the
780 dnl library in the standard library location(s).
781 dnl     $1 = library name
782 dnl     $2 = library class, usually the same as library name
783 dnl     $3 = includes
784 dnl     $4 = code fragment to compile/link
785 dnl     $5 = corresponding function-name
786 dnl     $6 = flag, nonnull if failure should not cause an error-exit
787 dnl
788 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
789 dnl to use a -L option.
790 AC_DEFUN([CF_FIND_LIBRARY],
791 [
792         eval 'cf_cv_have_lib_'$1'=no'
793         cf_libdir=""
794         AC_CHECK_FUNC($5,
795                 eval 'cf_cv_have_lib_'$1'=yes',[
796                 cf_save_LIBS="$LIBS"
797                 AC_MSG_CHECKING(for $5 in -l$1)
798                 LIBS="-l$1 $LIBS"
799                 AC_TRY_LINK([$3],[$4],
800                         [AC_MSG_RESULT(yes)
801                          eval 'cf_cv_have_lib_'$1'=yes'
802                         ],
803                         [AC_MSG_RESULT(no)
804                         CF_LIBRARY_PATH(cf_search,$2)
805                         for cf_libdir in $cf_search
806                         do
807                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
808                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
809                                 AC_TRY_LINK([$3],[$4],
810                                         [AC_MSG_RESULT(yes)
811                                          eval 'cf_cv_have_lib_'$1'=yes'
812                                          break],
813                                         [AC_MSG_RESULT(no)
814                                          LIBS="$cf_save_LIBS"])
815                         done
816                         ])
817                 ])
818 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
819 ifelse($6,,[
820 if test $cf_found_library = no ; then
821         AC_MSG_ERROR(Cannot link $1 library)
822 fi
823 ])
824 ])dnl
825 dnl ---------------------------------------------------------------------------
826 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
827 dnl ---------------
828 dnl Find a library (specifically the linkage used in the code fragment),
829 dnl searching for it if it is not already in the library path.
830 dnl See also CF_ADD_SEARCHPATH.
831 dnl
832 dnl Parameters (4-on are optional):
833 dnl     $1 = headers for library entrypoint
834 dnl     $2 = code fragment for library entrypoint
835 dnl     $3 = the library name without the "-l" option or ".so" suffix.
836 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
837 dnl     $5 = action to perform if not successful
838 dnl     $6 = module name, if not the same as the library name
839 dnl     $7 = extra libraries
840 dnl
841 dnl Sets these variables:
842 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
843 dnl     $cf_cv_header_path_$3 - include-directory if needed
844 dnl     $cf_cv_library_path_$3 - library-directory if needed
845 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
846 AC_DEFUN([CF_FIND_LINKAGE],[
847
848 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
849 # will be set on completion of the AC_TRY_LINK below.
850 cf_cv_header_path_$3=
851 cf_cv_library_path_$3=
852
853 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
854
855 cf_save_LIBS="$LIBS"
856
857 AC_TRY_LINK([$1],[$2],[
858         cf_cv_find_linkage_$3=yes
859         cf_cv_header_path_$3=/usr/include
860         cf_cv_library_path_$3=/usr/lib
861 ],[
862
863 LIBS="-l$3 $7 $cf_save_LIBS"
864
865 AC_TRY_LINK([$1],[$2],[
866         cf_cv_find_linkage_$3=yes
867         cf_cv_header_path_$3=/usr/include
868         cf_cv_library_path_$3=/usr/lib
869         cf_cv_library_file_$3="-l$3"
870 ],[
871         cf_cv_find_linkage_$3=no
872         LIBS="$cf_save_LIBS"
873
874         CF_VERBOSE(find linkage for $3 library)
875         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
876
877         cf_save_CPPFLAGS="$CPPFLAGS"
878         cf_test_CPPFLAGS="$CPPFLAGS"
879
880         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
881         for cf_cv_header_path_$3 in $cf_search
882         do
883                 if test -d $cf_cv_header_path_$3 ; then
884                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
885                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
886                         AC_TRY_COMPILE([$1],[$2],[
887                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
888                                 cf_cv_find_linkage_$3=maybe
889                                 cf_test_CPPFLAGS="$CPPFLAGS"
890                                 break],[
891                                 CPPFLAGS="$cf_save_CPPFLAGS"
892                                 ])
893                 fi
894         done
895
896         if test "$cf_cv_find_linkage_$3" = maybe ; then
897
898                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
899
900                 cf_save_LIBS="$LIBS"
901                 cf_save_LDFLAGS="$LDFLAGS"
902
903                 ifelse([$6],,,[
904                 CPPFLAGS="$cf_test_CPPFLAGS"
905                 LIBS="-l$3 $7 $cf_save_LIBS"
906                 AC_TRY_LINK([$1],[$2],[
907                         CF_VERBOSE(... found $3 library in system)
908                         cf_cv_find_linkage_$3=yes])
909                         CPPFLAGS="$cf_save_CPPFLAGS"
910                         LIBS="$cf_save_LIBS"
911                         ])
912
913                 if test "$cf_cv_find_linkage_$3" != yes ; then
914                         CF_LIBRARY_PATH(cf_search,$3)
915                         for cf_cv_library_path_$3 in $cf_search
916                         do
917                                 if test -d $cf_cv_library_path_$3 ; then
918                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
919                                         CPPFLAGS="$cf_test_CPPFLAGS"
920                                         LIBS="-l$3 $7 $cf_save_LIBS"
921                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
922                                         AC_TRY_LINK([$1],[$2],[
923                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
924                                         cf_cv_find_linkage_$3=yes
925                                         cf_cv_library_file_$3="-l$3"
926                                         break],[
927                                         CPPFLAGS="$cf_save_CPPFLAGS"
928                                         LIBS="$cf_save_LIBS"
929                                         LDFLAGS="$cf_save_LDFLAGS"
930                                         ])
931                                 fi
932                         done
933                         CPPFLAGS="$cf_save_CPPFLAGS"
934                         LDFLAGS="$cf_save_LDFLAGS"
935                 fi
936
937         else
938                 cf_cv_find_linkage_$3=no
939         fi
940         ],$7)
941 ])
942
943 LIBS="$cf_save_LIBS"
944
945 if test "$cf_cv_find_linkage_$3" = yes ; then
946 ifelse([$4],,[
947         CF_ADD_INCDIR($cf_cv_header_path_$3)
948         CF_ADD_LIBDIR($cf_cv_library_path_$3)
949         CF_ADD_LIB($3)
950 ],[$4])
951 else
952 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
953 fi
954 ])dnl
955 dnl ---------------------------------------------------------------------------
956 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
957 dnl -----------------
958 dnl make ADAFLAGS consistent with CFLAGS
959 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
960         AC_MSG_CHECKING(optimization options for ADAFLAGS)
961         case "$CFLAGS" in
962         (*-g*)
963                 CF_ADD_ADAFLAGS(-g)
964                 ;;
965         esac
966         case "$CFLAGS" in
967         (*-O*)
968                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
969                 CF_ADD_ADAFLAGS($cf_O_flag)
970                 ;;
971         esac
972         AC_MSG_RESULT($ADAFLAGS)
973 ])dnl
974 dnl ---------------------------------------------------------------------------
975 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
976 dnl -----------------
977 dnl Test for availability of useful gcc __attribute__ directives to quiet
978 dnl compiler warnings.  Though useful, not all are supported -- and contrary
979 dnl to documentation, unrecognized directives cause older compilers to barf.
980 AC_DEFUN([CF_GCC_ATTRIBUTES],
981 [
982 if test "$GCC" = yes
983 then
984 cat > conftest.i <<EOF
985 #ifndef GCC_PRINTF
986 #define GCC_PRINTF 0
987 #endif
988 #ifndef GCC_SCANF
989 #define GCC_SCANF 0
990 #endif
991 #ifndef GCC_NORETURN
992 #define GCC_NORETURN /* nothing */
993 #endif
994 #ifndef GCC_UNUSED
995 #define GCC_UNUSED /* nothing */
996 #endif
997 EOF
998 if test "$GCC" = yes
999 then
1000         AC_CHECKING([for $CC __attribute__ directives])
1001 cat > conftest.$ac_ext <<EOF
1002 #line __oline__ "${as_me:-configure}"
1003 #include "confdefs.h"
1004 #include "conftest.h"
1005 #include "conftest.i"
1006 #if     GCC_PRINTF
1007 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1008 #else
1009 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1010 #endif
1011 #if     GCC_SCANF
1012 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1013 #else
1014 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1015 #endif
1016 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1017 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1018 extern void foo(void) GCC_NORETURN;
1019 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1020 EOF
1021         cf_printf_attribute=no
1022         cf_scanf_attribute=no
1023         for cf_attribute in scanf printf unused noreturn
1024         do
1025                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1026                 cf_directive="__attribute__(($cf_attribute))"
1027                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1028
1029                 case $cf_attribute in
1030                 (printf)
1031                         cf_printf_attribute=yes
1032                         cat >conftest.h <<EOF
1033 #define GCC_$cf_ATTRIBUTE 1
1034 EOF
1035                         ;;
1036                 (scanf)
1037                         cf_scanf_attribute=yes
1038                         cat >conftest.h <<EOF
1039 #define GCC_$cf_ATTRIBUTE 1
1040 EOF
1041                         ;;
1042                 (*)
1043                         cat >conftest.h <<EOF
1044 #define GCC_$cf_ATTRIBUTE $cf_directive
1045 EOF
1046                         ;;
1047                 esac
1048
1049                 if AC_TRY_EVAL(ac_compile); then
1050                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1051                         cat conftest.h >>confdefs.h
1052                         case $cf_attribute in
1053                         (noreturn)
1054                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1055                                 ;;
1056                         (printf)
1057                                 cf_value='/* nothing */'
1058                                 if test "$cf_printf_attribute" != no ; then
1059                                         cf_value='__attribute__((format(printf,fmt,var)))'
1060                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1061                                 fi
1062                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1063                                 ;;
1064                         (scanf)
1065                                 cf_value='/* nothing */'
1066                                 if test "$cf_scanf_attribute" != no ; then
1067                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1068                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1069                                 fi
1070                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1071                                 ;;
1072                         (unused)
1073                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1074                                 ;;
1075                         esac
1076                 fi
1077         done
1078 else
1079         fgrep define conftest.i >>confdefs.h
1080 fi
1081 rm -rf conftest*
1082 fi
1083 ])dnl
1084 dnl ---------------------------------------------------------------------------
1085 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1086 dnl --------------
1087 dnl Find version of gcc
1088 AC_DEFUN([CF_GCC_VERSION],[
1089 AC_REQUIRE([AC_PROG_CC])
1090 GCC_VERSION=none
1091 if test "$GCC" = yes ; then
1092         AC_MSG_CHECKING(version of $CC)
1093         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1094         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1095         AC_MSG_RESULT($GCC_VERSION)
1096 fi
1097 ])dnl
1098 dnl ---------------------------------------------------------------------------
1099 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
1100 dnl ---------------
1101 dnl Check if the compiler supports useful warning options.  There's a few that
1102 dnl we don't use, simply because they're too noisy:
1103 dnl
1104 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1105 dnl     -Wredundant-decls (system headers make this too noisy)
1106 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1107 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1108 dnl             is enabled for ncurses using "--enable-const".
1109 dnl     -pedantic
1110 dnl
1111 dnl Parameter:
1112 dnl     $1 is an optional list of gcc warning flags that a particular
1113 dnl             application might want to use, e.g., "no-unused" for
1114 dnl             -Wno-unused
1115 dnl Special:
1116 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1117 dnl
1118 AC_DEFUN([CF_GCC_WARNINGS],
1119 [
1120 AC_REQUIRE([CF_GCC_VERSION])
1121 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1122 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1123
1124 cat > conftest.$ac_ext <<EOF
1125 #line __oline__ "${as_me:-configure}"
1126 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1127 EOF
1128
1129 if test "$INTEL_COMPILER" = yes
1130 then
1131 # The "-wdXXX" options suppress warnings:
1132 # remark #1419: external declaration in primary source file
1133 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1134 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1135 # remark #193: zero used for undefined preprocessing identifier
1136 # remark #593: variable "curs_sb_left_arrow" was set but never used
1137 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1138 # remark #869: parameter "tw" was never referenced
1139 # remark #981: operands are evaluated in unspecified order
1140 # warning #279: controlling expression is constant
1141
1142         AC_CHECKING([for $CC warning options])
1143         cf_save_CFLAGS="$CFLAGS"
1144         EXTRA_CFLAGS="-Wall"
1145         for cf_opt in \
1146                 wd1419 \
1147                 wd1683 \
1148                 wd1684 \
1149                 wd193 \
1150                 wd593 \
1151                 wd279 \
1152                 wd810 \
1153                 wd869 \
1154                 wd981
1155         do
1156                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1157                 if AC_TRY_EVAL(ac_compile); then
1158                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1159                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1160                 fi
1161         done
1162         CFLAGS="$cf_save_CFLAGS"
1163
1164 elif test "$GCC" = yes
1165 then
1166         AC_CHECKING([for $CC warning options])
1167         cf_save_CFLAGS="$CFLAGS"
1168         EXTRA_CFLAGS=
1169         cf_warn_CONST=""
1170         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1171         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1172         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1173         for cf_opt in W Wall \
1174                 Wbad-function-cast \
1175                 Wcast-align \
1176                 Wcast-qual \
1177                 Wdeclaration-after-statement \
1178                 Wextra \
1179                 Winline \
1180                 Wmissing-declarations \
1181                 Wmissing-prototypes \
1182                 Wnested-externs \
1183                 Wpointer-arith \
1184                 Wshadow \
1185                 Wstrict-prototypes \
1186                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
1187         do
1188                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1189                 if AC_TRY_EVAL(ac_compile); then
1190                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1191                         case $cf_opt in
1192                         (Wcast-qual)
1193                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1194                                 ;;
1195                         (Winline)
1196                                 case $GCC_VERSION in
1197                                 ([[34]].*)
1198                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1199                                         continue;;
1200                                 esac
1201                                 ;;
1202                         (Wpointer-arith)
1203                                 case $GCC_VERSION in
1204                                 ([[12]].*)
1205                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1206                                         continue;;
1207                                 esac
1208                                 ;;
1209                         esac
1210                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1211                 fi
1212         done
1213         CFLAGS="$cf_save_CFLAGS"
1214 fi
1215 rm -rf conftest*
1216
1217 AC_SUBST(EXTRA_CFLAGS)
1218 ])dnl
1219 dnl ---------------------------------------------------------------------------
1220 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
1221 dnl -----------------
1222 AC_DEFUN([CF_GNATPREP_OPT_T],[
1223 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
1224 cf_cv_gnatprep_opt_t=no
1225 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
1226 ])
1227 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
1228 AC_SUBST(GNATPREP_OPTS)
1229 ])dnl
1230 dnl ---------------------------------------------------------------------------
1231 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
1232 dnl ----------------
1233 AC_DEFUN([CF_GNAT_GENERICS],
1234 [
1235 AC_REQUIRE([CF_GNAT_VERSION])
1236
1237 AC_MSG_CHECKING(if GNAT supports generics)
1238 case $cf_gnat_version in
1239 (3.[[1-9]]*|[[4-9]].*)
1240         cf_gnat_generics=yes
1241         ;;
1242 (*)
1243         cf_gnat_generics=no
1244         ;;
1245 esac
1246 AC_MSG_RESULT($cf_gnat_generics)
1247
1248 if test "$cf_gnat_generics" = yes
1249 then
1250         cf_compile_generics=generics
1251         cf_generic_objects="\${GENOBJS}"
1252 else
1253         cf_compile_generics=
1254         cf_generic_objects=
1255 fi
1256
1257 AC_SUBST(cf_compile_generics)
1258 AC_SUBST(cf_generic_objects)
1259 ])dnl
1260 dnl ---------------------------------------------------------------------------
1261 dnl CF_GNAT_PROJECTS version: 9 updated: 2018/01/14 15:46:09
1262 dnl ----------------
1263 dnl GNAT projects are configured with ".gpr" project files.
1264 dnl GNAT libraries are a further development, using the project feature.
1265 AC_DEFUN([CF_GNAT_PROJECTS],
1266 [
1267 AC_REQUIRE([CF_GNAT_VERSION])
1268 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
1269
1270 cf_gnat_libraries=no
1271 cf_gnat_projects=no
1272
1273 if test "$enable_gnat_projects" != no ; then
1274 AC_MSG_CHECKING(if GNAT supports project files)
1275 case $cf_gnat_version in
1276 (3.[[0-9]]*)
1277         ;;
1278 (*)
1279         case $cf_cv_system_name in
1280         (cygwin*|msys*)
1281                 ;;
1282         (*)
1283                 rm -rf conftest* *~conftest*
1284                 if mkdir conftest.src conftest.bin conftest.lib
1285                 then
1286                         cd conftest.src
1287                         rm -rf conftest* *~conftest*
1288                         cat >>library.gpr <<CF_EOF
1289 project Library is
1290   Kind := External ("LIB_KIND");
1291   for Library_Name use "ConfTest";
1292   for Object_Dir use ".";
1293   for Library_ALI_Dir use External("LIBRARY_DIR");
1294   for Library_Version use External ("SONAME");
1295   for Library_Kind use Kind;
1296   for Library_Dir use External("BUILD_DIR");
1297   Source_Dir := External ("SOURCE_DIR");
1298   for Source_Dirs use (Source_Dir);
1299 end Library;
1300 CF_EOF
1301                         cat >>confpackage.ads <<CF_EOF
1302 package ConfPackage is
1303    procedure conftest;
1304 end ConfPackage;
1305 CF_EOF
1306                         cat >>confpackage.adb <<CF_EOF
1307 with Text_IO;
1308 package body ConfPackage is
1309    procedure conftest is
1310    begin
1311       Text_IO.Put ("Hello World");
1312       Text_IO.New_Line;
1313    end conftest;
1314 end ConfPackage;
1315 CF_EOF
1316                         if ( $cf_ada_make $ADAFLAGS \
1317                                         -Plibrary.gpr \
1318                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
1319                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
1320                                         -XSOURCE_DIR=`pwd` \
1321                                         -XSONAME=libConfTest.so.1 \
1322                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1323                                 cf_gnat_projects=yes
1324                         fi
1325                         cd ..
1326                 fi
1327                 if test -f conftest.lib/confpackage.ali
1328                 then
1329                         cf_gnat_libraries=yes
1330                 fi
1331                 rm -rf conftest* *~conftest*
1332                 ;;
1333         esac
1334         ;;
1335 esac
1336 AC_MSG_RESULT($cf_gnat_projects)
1337 fi # enable_gnat_projects
1338
1339 if test $cf_gnat_projects = yes
1340 then
1341         AC_MSG_CHECKING(if GNAT supports libraries)
1342         AC_MSG_RESULT($cf_gnat_libraries)
1343 fi
1344
1345 if test "$cf_gnat_projects" = yes
1346 then
1347         USE_OLD_MAKERULES="#"
1348         USE_GNAT_PROJECTS=""
1349 else
1350         USE_OLD_MAKERULES=""
1351         USE_GNAT_PROJECTS="#"
1352 fi
1353
1354 if test "$cf_gnat_libraries" = yes
1355 then
1356         USE_GNAT_LIBRARIES=""
1357 else
1358         USE_GNAT_LIBRARIES="#"
1359 fi
1360
1361 AC_SUBST(USE_OLD_MAKERULES)
1362 AC_SUBST(USE_GNAT_PROJECTS)
1363 AC_SUBST(USE_GNAT_LIBRARIES)
1364 ])dnl
1365 dnl ---------------------------------------------------------------------------
1366 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
1367 dnl --------------
1368 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1369 dnl is noted that gnat may compile a tasking unit even for configurations which
1370 dnl fail at runtime.
1371 AC_DEFUN([CF_GNAT_SIGINT],[
1372 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1373 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1374
1375 package ConfTest is
1376
1377    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1378    pragma Unreserve_All_Interrupts;
1379    pragma Warnings (On);
1380
1381    protected Process is
1382       procedure Stop;
1383       function Continue return Boolean;
1384       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1385    private
1386       Done : Boolean := False;
1387    end Process;
1388
1389 end ConfTest;],
1390 [package body ConfTest is
1391    protected body Process is
1392       procedure Stop is
1393       begin
1394          Done := True;
1395       end Stop;
1396       function Continue return Boolean is
1397       begin
1398          return not Done;
1399       end Continue;
1400    end Process;
1401 end ConfTest;],
1402         [cf_cv_gnat_sigint=yes],
1403         [cf_cv_gnat_sigint=no])])
1404
1405 if test $cf_cv_gnat_sigint = yes ; then
1406         USE_GNAT_SIGINT=""
1407 else
1408         USE_GNAT_SIGINT="#"
1409 fi
1410 AC_SUBST(USE_GNAT_SIGINT)
1411 ])dnl
1412 dnl ---------------------------------------------------------------------------
1413 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
1414 dnl ----------------
1415 dnl Verify that a test program compiles/links with GNAT.
1416 dnl $cf_ada_make is set to the program that compiles/links
1417 dnl $ADAFLAGS may be set to the GNAT flags.
1418 dnl
1419 dnl $1 is the text of the spec
1420 dnl $2 is the text of the body
1421 dnl $3 is the shell command to execute if successful
1422 dnl $4 is the shell command to execute if not successful
1423 AC_DEFUN([CF_GNAT_TRY_LINK],
1424 [
1425 rm -rf conftest* *~conftest*
1426 cat >>conftest.ads <<CF_EOF
1427 $1
1428 CF_EOF
1429 cat >>conftest.adb <<CF_EOF
1430 $2
1431 CF_EOF
1432 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1433 ifelse($3,,      :,[      $3])
1434 ifelse($4,,,[else
1435    $4])
1436 fi
1437 rm -rf conftest* *~conftest*
1438 ])dnl
1439 dnl ---------------------------------------------------------------------------
1440 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
1441 dnl ---------------
1442 dnl Verify that a test program compiles and runs with GNAT
1443 dnl $cf_ada_make is set to the program that compiles/links
1444 dnl $ADAFLAGS may be set to the GNAT flags.
1445 dnl
1446 dnl $1 is the text of the spec
1447 dnl $2 is the text of the body
1448 dnl $3 is the shell command to execute if successful
1449 dnl $4 is the shell command to execute if not successful
1450 AC_DEFUN([CF_GNAT_TRY_RUN],
1451 [
1452 rm -rf conftest* *~conftest*
1453 cat >>conftest.ads <<CF_EOF
1454 $1
1455 CF_EOF
1456 cat >>conftest.adb <<CF_EOF
1457 $2
1458 CF_EOF
1459 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1460    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1461 ifelse($3,,      :,[      $3])
1462 ifelse($4,,,[   else
1463       $4])
1464    fi
1465 ifelse($4,,,[else
1466    $4])
1467 fi
1468 rm -rf conftest* *~conftest*
1469 ])dnl
1470 dnl ---------------------------------------------------------------------------
1471 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
1472 dnl ---------------
1473 dnl Verify version of GNAT.
1474 AC_DEFUN([CF_GNAT_VERSION],
1475 [
1476 AC_MSG_CHECKING(for gnat version)
1477 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
1478         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1479         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1480 AC_MSG_RESULT($cf_gnat_version)
1481
1482 case $cf_gnat_version in
1483 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
1484         cf_cv_prog_gnat_correct=yes
1485         ;;
1486 (*)
1487         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1488         cf_cv_prog_gnat_correct=no
1489         ;;
1490 esac
1491 ])
1492 dnl ---------------------------------------------------------------------------
1493 dnl CF_GNU_SOURCE version: 8 updated: 2018/06/16 19:05:13
1494 dnl -------------
1495 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1496 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1497 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1498 dnl since it is interwoven with GNU extensions.
1499 dnl
1500 dnl Well, yes we could work around it...
1501 dnl
1502 dnl Parameters:
1503 dnl     $1 is the nominal value for _XOPEN_SOURCE
1504 AC_DEFUN([CF_GNU_SOURCE],
1505 [
1506 cf_gnu_xopen_source=ifelse($1,,500,$1)
1507
1508 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
1509 AC_TRY_COMPILE([#include <sys/types.h>],[
1510         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
1511                 return 0;
1512         #else
1513         #       error not GNU C library
1514         #endif],
1515         [cf_cv_gnu_library=yes],
1516         [cf_cv_gnu_library=no])
1517 ])
1518
1519 if test x$cf_cv_gnu_library = xyes; then
1520
1521         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
1522         # was changed to help a little...
1523         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
1524                 cf_save="$CPPFLAGS"
1525                 CPPFLAGS="$CPPFLAGS -D_DEFAULT_SOURCE"
1526                 AC_TRY_COMPILE([#include <sys/types.h>],[
1527                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
1528                                 return 0;
1529                         #else
1530                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
1531                         #endif],
1532                         [cf_cv_gnu_library_219=yes],
1533                         [cf_cv_gnu_library_219=no])
1534                 CPPFLAGS="$cf_save"
1535         ])
1536
1537         if test "x$cf_cv_gnu_library_219" = xyes; then
1538                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
1539                         cf_save="$CPPFLAGS"
1540                         CPPFLAGS="$CPPFLAGS -D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source"
1541                         AC_TRY_COMPILE([
1542                                 #include <limits.h>
1543                                 #include <sys/types.h>
1544                                 ],[
1545                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
1546                                         return 0;
1547                                 #else
1548                                 #       error GNU C library is too old
1549                                 #endif],
1550                                 [cf_cv_gnu_dftsrc_219=yes],
1551                                 [cf_cv_gnu_dftsrc_219=no])
1552                         ])
1553                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
1554         else
1555                 cf_cv_gnu_dftsrc_219=maybe
1556         fi
1557
1558         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
1559
1560                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1561                 AC_TRY_COMPILE([#include <sys/types.h>],[
1562                         #ifndef _XOPEN_SOURCE
1563                         #error  expected _XOPEN_SOURCE to be defined
1564                         #endif],
1565                         [cf_cv_gnu_source=no],
1566                         [cf_save="$CPPFLAGS"
1567                          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1568                          AC_TRY_COMPILE([#include <sys/types.h>],[
1569                                 #ifdef _XOPEN_SOURCE
1570                                 #error  expected _XOPEN_SOURCE to be undefined
1571                                 #endif],
1572                                 [cf_cv_gnu_source=no],
1573                                 [cf_cv_gnu_source=yes])
1574                         CPPFLAGS="$cf_save"
1575                         ])
1576                 ])
1577
1578                 if test "$cf_cv_gnu_source" = yes
1579                 then
1580                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
1581                         CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1582                         AC_TRY_COMPILE([#include <sys/types.h>],[
1583                                 #ifdef _DEFAULT_SOURCE
1584                                 #error  expected _DEFAULT_SOURCE to be undefined
1585                                 #endif],
1586                                 [cf_cv_default_source=no],
1587                                 [cf_cv_default_source=yes])
1588                         ])
1589                         test "$cf_cv_default_source" = yes && CPPFLAGS="$CPPFLAGS -D_DEFAULT_SOURCE"
1590                 fi
1591         fi
1592
1593 fi
1594 ])dnl
1595 dnl ---------------------------------------------------------------------------
1596 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
1597 dnl --------------
1598 dnl Construct a search-list of directories for a nonstandard header-file
1599 dnl
1600 dnl Parameters
1601 dnl     $1 = the variable to return as result
1602 dnl     $2 = the package name
1603 AC_DEFUN([CF_HEADER_PATH],
1604 [
1605 $1=
1606
1607 # collect the current set of include-directories from compiler flags
1608 cf_header_path_list=""
1609 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1610         for cf_header_path in $CPPFLAGS $CFLAGS
1611         do
1612                 case $cf_header_path in
1613                 (-I*)
1614                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1615                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1616                         cf_header_path_list="$cf_header_path_list [$]$1"
1617                         ;;
1618                 esac
1619         done
1620 fi
1621
1622 # add the variations for the package we are looking for
1623 CF_SUBDIR_PATH($1,$2,include)
1624
1625 test "$includedir" != NONE && \
1626 test "$includedir" != "/usr/include" && \
1627 test -d "$includedir" && {
1628         test -d $includedir &&    $1="[$]$1 $includedir"
1629         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1630 }
1631
1632 test "$oldincludedir" != NONE && \
1633 test "$oldincludedir" != "/usr/include" && \
1634 test -d "$oldincludedir" && {
1635         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1636         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1637 }
1638
1639 $1="[$]$1 $cf_header_path_list"
1640 ])dnl
1641 dnl ---------------------------------------------------------------------------
1642 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1643 dnl ---------------
1644 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1645 AC_DEFUN([CF_HELP_MESSAGE],
1646 [AC_DIVERT_HELP([$1])dnl
1647 ])dnl
1648 dnl ---------------------------------------------------------------------------
1649 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
1650 dnl ---------------
1651 dnl Construct the list of include-options according to whether we're building
1652 dnl in the source directory or using '--srcdir=DIR' option.
1653 AC_DEFUN([CF_INCLUDE_DIRS],
1654 [
1655 if test "$srcdir" != "."; then
1656         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
1657 fi
1658 CPPFLAGS="-I../include $CPPFLAGS"
1659 if test "$srcdir" != "."; then
1660         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
1661 fi
1662 CPPFLAGS="-I. $CPPFLAGS"
1663 AC_SUBST(CPPFLAGS)
1664 ])dnl
1665 dnl ---------------------------------------------------------------------------
1666 dnl CF_INSTALL_OPTS version: 1 updated: 2014/07/21 18:19:51
1667 dnl ---------------
1668 dnl prompt for/fill-in useful install-program options
1669 AC_DEFUN([CF_INSTALL_OPTS],
1670 [
1671 CF_INSTALL_OPT_S
1672 CF_INSTALL_OPT_O
1673 ])dnl
1674 dnl ---------------------------------------------------------------------------
1675 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
1676 dnl ----------------
1677 dnl Almost all "install" programs default to the current user's ownership.
1678 dnl Almost - MINIX is an exception.
1679 AC_DEFUN([CF_INSTALL_OPT_O],
1680 [
1681 AC_MSG_CHECKING(if install needs to be told about ownership)
1682 case `$ac_config_guess` in
1683 (*minix)
1684         with_install_o=yes
1685         ;;
1686 (*)
1687         with_install_o=no
1688         ;;
1689 esac
1690
1691 AC_MSG_RESULT($with_install_o)
1692 if test "x$with_install_o" = xyes
1693 then
1694         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
1695 else
1696         INSTALL_OPT_O=
1697 fi
1698
1699 AC_SUBST(INSTALL_OPT_O)
1700 ])dnl
1701 dnl ---------------------------------------------------------------------------
1702 dnl CF_INSTALL_OPT_S version: 1 updated: 2014/07/21 18:19:51
1703 dnl ----------------
1704 dnl By default, we should strip executables which are installed, but leave the
1705 dnl ability to suppress that for unit-testing.
1706 AC_DEFUN([CF_INSTALL_OPT_S],
1707 [
1708 AC_MSG_CHECKING(if you want to install stripped executables)
1709 CF_ARG_DISABLE(stripping,
1710         [  --disable-stripping     do not strip installed executables],
1711         [with_stripping=no],
1712         [with_stripping=yes])
1713 AC_MSG_RESULT($with_stripping)
1714
1715 if test "$with_stripping" = yes
1716 then
1717         INSTALL_OPT_S="-s"
1718 else
1719         INSTALL_OPT_S=
1720 fi
1721 AC_SUBST(INSTALL_OPT_S)
1722 ])dnl
1723 dnl ---------------------------------------------------------------------------
1724 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
1725 dnl -----------------
1726 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1727 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1728 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1729 dnl
1730 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1731 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1732 dnl the wrappers for gcc and g++ warnings.
1733 dnl
1734 dnl $1 = GCC (default) or GXX
1735 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1736 dnl $3 = CFLAGS (default) or CXXFLAGS
1737 AC_DEFUN([CF_INTEL_COMPILER],[
1738 AC_REQUIRE([AC_CANONICAL_HOST])
1739 ifelse([$2],,INTEL_COMPILER,[$2])=no
1740
1741 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1742         case $host_os in
1743         (linux*|gnu*)
1744                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1745                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1746                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1747                 AC_TRY_COMPILE([],[
1748 #ifdef __INTEL_COMPILER
1749 #else
1750 make an error
1751 #endif
1752 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1753 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
1754 ],[])
1755                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1756                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1757                 ;;
1758         esac
1759 fi
1760 ])dnl
1761 dnl ---------------------------------------------------------------------------
1762 dnl CF_LARGEFILE version: 10 updated: 2017/01/21 11:06:25
1763 dnl ------------
1764 dnl Add checks for large file support.
1765 AC_DEFUN([CF_LARGEFILE],[
1766 ifdef([AC_FUNC_FSEEKO],[
1767         AC_SYS_LARGEFILE
1768         if test "$enable_largefile" != no ; then
1769         AC_FUNC_FSEEKO
1770
1771         # Normally we would collect these definitions in the config.h,
1772         # but (like _XOPEN_SOURCE), some environments rely on having these
1773         # defined before any of the system headers are included.  Another
1774         # case comes up with C++, e.g., on AIX the compiler compiles the
1775         # header files by themselves before looking at the body files it is
1776         # told to compile.  For ncurses, those header files do not include
1777         # the config.h
1778         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
1779         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
1780         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
1781
1782         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
1783                 AC_TRY_COMPILE([
1784 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
1785 #include <sys/types.h>
1786 #include <dirent.h>
1787                 ],[
1788                 /* if transitional largefile support is setup, this is true */
1789                 extern struct dirent64 * readdir(DIR *);
1790                 struct dirent64 *x = readdir((DIR *)0);
1791                 struct dirent *y = readdir((DIR *)0);
1792                 int z = x - y;
1793                 ],
1794                 [cf_cv_struct_dirent64=yes],
1795                 [cf_cv_struct_dirent64=no])
1796         ])
1797         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
1798         fi
1799 ])
1800 ])
1801 dnl ---------------------------------------------------------------------------
1802 dnl CF_LD_RPATH_OPT version: 7 updated: 2016/02/20 18:01:19
1803 dnl ---------------
1804 dnl For the given system and compiler, find the compiler flags to pass to the
1805 dnl loader to use the "rpath" feature.
1806 AC_DEFUN([CF_LD_RPATH_OPT],
1807 [
1808 AC_REQUIRE([CF_CHECK_CACHE])
1809
1810 LD_RPATH_OPT=
1811 AC_MSG_CHECKING(for an rpath option)
1812 case $cf_cv_system_name in
1813 (irix*)
1814         if test "$GCC" = yes; then
1815                 LD_RPATH_OPT="-Wl,-rpath,"
1816         else
1817                 LD_RPATH_OPT="-rpath "
1818         fi
1819         ;;
1820 (linux*|gnu*|k*bsd*-gnu|freebsd*)
1821         LD_RPATH_OPT="-Wl,-rpath,"
1822         ;;
1823 (openbsd[[2-9]].*|mirbsd*)
1824         LD_RPATH_OPT="-Wl,-rpath,"
1825         ;;
1826 (dragonfly*)
1827         LD_RPATH_OPT="-rpath "
1828         ;;
1829 (netbsd*)
1830         LD_RPATH_OPT="-Wl,-rpath,"
1831         ;;
1832 (osf*|mls+*)
1833         LD_RPATH_OPT="-rpath "
1834         ;;
1835 (solaris2*)
1836         LD_RPATH_OPT="-R"
1837         ;;
1838 (*)
1839         ;;
1840 esac
1841 AC_MSG_RESULT($LD_RPATH_OPT)
1842
1843 case "x$LD_RPATH_OPT" in
1844 (x-R*)
1845         AC_MSG_CHECKING(if we need a space after rpath option)
1846         cf_save_LIBS="$LIBS"
1847         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1848         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1849         LIBS="$cf_save_LIBS"
1850         AC_MSG_RESULT($cf_rpath_space)
1851         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1852         ;;
1853 esac
1854 ])dnl
1855 dnl ---------------------------------------------------------------------------
1856 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
1857 dnl ---------------
1858 dnl Construct a search-list of directories for a nonstandard library-file
1859 dnl
1860 dnl Parameters
1861 dnl     $1 = the variable to return as result
1862 dnl     $2 = the package name
1863 AC_DEFUN([CF_LIBRARY_PATH],
1864 [
1865 $1=
1866 cf_library_path_list=""
1867 if test -n "${LDFLAGS}${LIBS}" ; then
1868         for cf_library_path in $LDFLAGS $LIBS
1869         do
1870                 case $cf_library_path in
1871                 (-L*)
1872                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1873                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1874                         cf_library_path_list="$cf_library_path_list [$]$1"
1875                         ;;
1876                 esac
1877         done
1878 fi
1879
1880 CF_SUBDIR_PATH($1,$2,lib)
1881
1882 $1="$cf_library_path_list [$]$1"
1883 ])dnl
1884 dnl ---------------------------------------------------------------------------
1885 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
1886 dnl -------------
1887 dnl Compute the library-prefix for the given host system
1888 dnl $1 = variable to set
1889 define([CF_LIB_PREFIX],
1890 [
1891         case $cf_cv_system_name in
1892         (OS/2*|os2*)
1893                 if test "$DFT_LWR_MODEL" = libtool; then
1894                         LIB_PREFIX='lib'
1895                 else
1896                         LIB_PREFIX=''
1897                 fi
1898                 ;;
1899         (*)     LIB_PREFIX='lib'
1900                 ;;
1901         esac
1902 ifelse($1,,,[$1=$LIB_PREFIX])
1903         AC_SUBST(LIB_PREFIX)
1904 ])dnl
1905 dnl ---------------------------------------------------------------------------
1906 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
1907 dnl -------------
1908 dnl Compute the library file-suffix from the given model name
1909 dnl $1 = model name
1910 dnl $2 = variable to set (the nominal library suffix)
1911 dnl $3 = dependency variable to set (actual filename)
1912 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1913 AC_DEFUN([CF_LIB_SUFFIX],
1914 [
1915         case X$1 in
1916         (Xlibtool)
1917                 $2='.la'
1918                 $3=[$]$2
1919                 ;;
1920         (Xdebug)
1921                 $2='_g.a'
1922                 $3=[$]$2
1923                 ;;
1924         (Xprofile)
1925                 $2='_p.a'
1926                 $3=[$]$2
1927                 ;;
1928         (Xshared)
1929                 case $cf_cv_system_name in
1930                 (aix[[5-7]]*)
1931                         $2='.so'
1932                         $3=[$]$2
1933                         ;;
1934                 (cygwin*|msys*|mingw*)
1935                         $2='.dll'
1936                         $3='.dll.a'
1937                         ;;
1938                 (darwin*)
1939                         $2='.dylib'
1940                         $3=[$]$2
1941                         ;;
1942                 (hpux*)
1943                         case $target in
1944                         (ia64*)
1945                                 $2='.so'
1946                                 $3=[$]$2
1947                                 ;;
1948                         (*)
1949                                 $2='.sl'
1950                                 $3=[$]$2
1951                                 ;;
1952                         esac
1953                         ;;
1954                 (*)
1955                         $2='.so'
1956                         $3=[$]$2
1957                         ;;
1958                 esac
1959                 ;;
1960         (*)
1961                 $2='.a'
1962                 $3=[$]$2
1963                 ;;
1964         esac
1965         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
1966         then
1967                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
1968                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
1969         fi
1970 ])dnl
1971 dnl ---------------------------------------------------------------------------
1972 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
1973 dnl -----------
1974 dnl Compute the string to append to -library from the given model name
1975 dnl $1 = model name
1976 dnl $2 = variable to set
1977 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1978 AC_DEFUN([CF_LIB_TYPE],
1979 [
1980         case $1 in
1981         (libtool) $2=''   ;;
1982         (normal)  $2=''   ;;
1983         (debug)   $2='_g' ;;
1984         (profile) $2='_p' ;;
1985         (shared)  $2=''   ;;
1986         esac
1987         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1988 ])dnl
1989 dnl ---------------------------------------------------------------------------
1990 dnl CF_LINK_DATAONLY version: 12 updated: 2017/07/23 17:46:07
1991 dnl ----------------
1992 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
1993 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
1994 dnl have to provide wrappers for global tables to ensure they're linked
1995 dnl properly.
1996 AC_DEFUN([CF_LINK_DATAONLY],
1997 [
1998 AC_MSG_CHECKING([if data-only library module links])
1999 AC_CACHE_VAL(cf_cv_link_dataonly,[
2000         rm -f conftest.a
2001         cat >conftest.$ac_ext <<EOF
2002 #line __oline__ "configure"
2003 int     testdata[[3]] = { 123, 456, 789 };
2004 EOF
2005         if AC_TRY_EVAL(ac_compile) ; then
2006                 mv conftest.o data.o && \
2007                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
2008         fi
2009         rm -f conftest.$ac_ext data.o
2010         cat >conftest.$ac_ext <<EOF
2011 #line __oline__ "configure"
2012 int     testfunc(void)
2013 {
2014 #if defined(NeXT)
2015         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
2016 #else
2017         extern int testdata[[3]];
2018         return testdata[[0]] == 123
2019            &&  testdata[[1]] == 456
2020            &&  testdata[[2]] == 789;
2021 #endif
2022 }
2023 EOF
2024         if AC_TRY_EVAL(ac_compile); then
2025                 mv conftest.o func.o && \
2026                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
2027         fi
2028         rm -f conftest.$ac_ext func.o
2029         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
2030         cf_saveLIBS="$LIBS"
2031         LIBS="conftest.a $LIBS"
2032         AC_TRY_RUN([
2033         int main(void)
2034         {
2035                 extern int testfunc();
2036                 ${cf_cv_main_return:-return} (!testfunc());
2037         }
2038         ],
2039         [cf_cv_link_dataonly=yes],
2040         [cf_cv_link_dataonly=no],
2041         [cf_cv_link_dataonly=unknown])
2042         LIBS="$cf_saveLIBS"
2043         ])
2044 AC_MSG_RESULT($cf_cv_link_dataonly)
2045
2046 if test "$cf_cv_link_dataonly" = no ; then
2047         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
2048         BROKEN_LINKER=1
2049 fi
2050
2051 ])dnl
2052 dnl ---------------------------------------------------------------------------
2053 dnl CF_MAKEFLAGS version: 18 updated: 2018/02/21 21:26:03
2054 dnl ------------
2055 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
2056 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
2057 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
2058 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
2059 AC_DEFUN([CF_MAKEFLAGS],
2060 [
2061 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
2062         cf_cv_makeflags=''
2063         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
2064         do
2065                 cat >cf_makeflags.tmp <<CF_EOF
2066 SHELL = $SHELL
2067 all :
2068         @ echo '.$cf_option'
2069 CF_EOF
2070                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
2071                 case "$cf_result" in
2072                 (.*k|.*kw)
2073                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
2074                         case "$cf_result" in
2075                         (.*CC=*)        cf_cv_makeflags=
2076                                 ;;
2077                         (*)     cf_cv_makeflags=$cf_option
2078                                 ;;
2079                         esac
2080                         break
2081                         ;;
2082                 (.-)
2083                         ;;
2084                 (*)
2085                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
2086                         ;;
2087                 esac
2088         done
2089         rm -f cf_makeflags.tmp
2090 ])
2091
2092 AC_SUBST(cf_cv_makeflags)
2093 ])dnl
2094 dnl ---------------------------------------------------------------------------
2095 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
2096 dnl ------------
2097 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
2098 dnl a monocase filesystem.
2099 AC_DEFUN([CF_MAKE_TAGS],[
2100 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
2101
2102 AC_CHECK_PROGS(CTAGS, exctags ctags)
2103 AC_CHECK_PROGS(ETAGS, exetags etags)
2104
2105 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
2106
2107 if test "$cf_cv_mixedcase" = yes ; then
2108         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
2109 else
2110         MAKE_UPPER_TAGS=no
2111 fi
2112
2113 if test "$MAKE_UPPER_TAGS" = yes ; then
2114         MAKE_UPPER_TAGS=
2115 else
2116         MAKE_UPPER_TAGS="#"
2117 fi
2118
2119 if test "$MAKE_LOWER_TAGS" = yes ; then
2120         MAKE_LOWER_TAGS=
2121 else
2122         MAKE_LOWER_TAGS="#"
2123 fi
2124
2125 AC_SUBST(CTAGS)
2126 AC_SUBST(ETAGS)
2127
2128 AC_SUBST(MAKE_UPPER_TAGS)
2129 AC_SUBST(MAKE_LOWER_TAGS)
2130 ])dnl
2131 dnl ---------------------------------------------------------------------------
2132 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
2133 dnl ----------------------
2134 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2135 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2136 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2137 [
2138 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2139 if test "$cross_compiling" = yes ; then
2140         case $target_alias in
2141         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
2142                 cf_cv_mixedcase=no
2143                 ;;
2144         (*)
2145                 cf_cv_mixedcase=yes
2146                 ;;
2147         esac
2148 else
2149         rm -f conftest CONFTEST
2150         echo test >conftest
2151         if test -f CONFTEST ; then
2152                 cf_cv_mixedcase=no
2153         else
2154                 cf_cv_mixedcase=yes
2155         fi
2156         rm -f conftest CONFTEST
2157 fi
2158 ])
2159 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2160 ])dnl
2161 dnl ---------------------------------------------------------------------------
2162 dnl CF_MKSTEMP version: 10 updated: 2017/01/21 11:12:16
2163 dnl ----------
2164 dnl Check for a working mkstemp.  This creates two files, checks that they are
2165 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2166 AC_DEFUN([CF_MKSTEMP],[
2167 AC_CHECK_HEADERS( \
2168 unistd.h \
2169 )
2170 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2171 rm -rf conftest*
2172 AC_TRY_RUN([
2173 #include <sys/types.h>
2174 #ifdef HAVE_UNISTD_H
2175 #include <unistd.h>
2176 #endif
2177 #include <stdlib.h>
2178 #include <stdio.h>
2179 #include <string.h>
2180 #include <sys/stat.h>
2181 int main(void)
2182 {
2183         char *tmpl = "conftestXXXXXX";
2184         char name[2][80];
2185         int n;
2186         int result = 0;
2187         int fd;
2188         struct stat sb;
2189
2190         umask(077);
2191         for (n = 0; n < 2; ++n) {
2192                 strcpy(name[n], tmpl);
2193                 if ((fd = mkstemp(name[n])) >= 0) {
2194                         if (!strcmp(name[n], tmpl)
2195                          || stat(name[n], &sb) != 0
2196                          || (sb.st_mode & S_IFMT) != S_IFREG
2197                          || (sb.st_mode & 077) != 0) {
2198                                 result = 1;
2199                         }
2200                         close(fd);
2201                 }
2202         }
2203         if (result == 0
2204          && !strcmp(name[0], name[1]))
2205                 result = 1;
2206         ${cf_cv_main_return:-return}(result);
2207 }
2208 ],[cf_cv_func_mkstemp=yes
2209 ],[cf_cv_func_mkstemp=no
2210 ],[cf_cv_func_mkstemp=maybe])
2211 ])
2212 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2213         AC_CHECK_FUNC(mkstemp)
2214 fi
2215 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2216         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2217 fi
2218 ])dnl
2219 dnl ---------------------------------------------------------------------------
2220 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2221 dnl ----------
2222 dnl Write a debug message to config.log, along with the line number in the
2223 dnl configure script.
2224 AC_DEFUN([CF_MSG_LOG],[
2225 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2226 ])dnl
2227 dnl ---------------------------------------------------------------------------
2228 dnl CF_NCURSES_ADDON version: 5 updated: 2015/04/26 18:06:58
2229 dnl ----------------
2230 dnl Configure an ncurses add-on, built outside the ncurses tree.
2231 AC_DEFUN([CF_NCURSES_ADDON],[
2232 AC_REQUIRE([CF_NCURSES_CONFIG])
2233
2234 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2235
2236 AC_MSG_CHECKING(if you want wide-character code)
2237 AC_ARG_ENABLE(widec,
2238         [  --enable-widec          compile with wide-char/UTF-8 code],
2239         [with_widec=$enableval],
2240         [with_widec=no])
2241 AC_MSG_RESULT($with_widec)
2242 if test "$with_widec" = yes ; then
2243         CF_UTF8_LIB
2244         CF_NCURSES_CONFIG(ncursesw)
2245 else
2246         CF_NCURSES_CONFIG(ncurses)
2247 fi
2248
2249 if test "$NCURSES_CONFIG_PKG" != none ; then
2250         cf_version=`$PKG_CONFIG --modversion $NCURSES_CONFIG_PKG 2>/dev/null`
2251
2252         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2253         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2254         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2255
2256         cf_cv_abi_version=`$PKG_CONFIG --variable=abi_version $NCURSES_CONFIG_PKG 2>/dev/null`
2257         if test -z "$cf_cv_abi_version"
2258         then
2259                 cf_cv_abi_version=`$PKG_CONFIG --variable=major_version $NCURSES_CONFIG_PKG 2>/dev/null`
2260         fi
2261
2262 elif test "$NCURSES_CONFIG" != none ; then
2263
2264         cf_version=`$NCURSES_CONFIG --version 2>/dev/null`
2265
2266         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2267         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2268         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2269
2270         # ABI version is not available from headers
2271         cf_cv_abi_version=`$NCURSES_CONFIG --abi-version 2>/dev/null`
2272
2273 else
2274
2275         for cf_name in MAJOR MINOR PATCH
2276         do
2277         cat >conftest.$ac_ext <<CF_EOF
2278         #include <${cf_cv_ncurses_header:-curses.h}>
2279         AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2280 CF_EOF
2281                 cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2282                 AC_TRY_EVAL(cf_try)
2283                 if test -f conftest.out ; then
2284                         cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]][[    ]]*//"`
2285                         eval NCURSES_$cf_name=\"$cf_result\"
2286                         # cat conftest.$ac_ext
2287                         # cat conftest.out
2288                 fi
2289         done
2290
2291         cf_cv_abi_version=${NCURSES_MAJOR}
2292
2293 fi
2294
2295 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2296
2297 dnl Show the computed version, for logging
2298 cf_cv_timestamp=`date`
2299
2300 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2301
2302 dnl We need these values in the generated headers
2303 AC_SUBST(NCURSES_MAJOR)
2304 AC_SUBST(NCURSES_MINOR)
2305 AC_SUBST(NCURSES_PATCH)
2306
2307 dnl We need these values in the generated makefiles
2308 AC_SUBST(cf_cv_rel_version)
2309 AC_SUBST(cf_cv_abi_version)
2310
2311 dnl FIXME - not needed for Ada95
2312 AC_SUBST(cf_cv_builtin_bool)
2313 AC_SUBST(cf_cv_header_stdbool_h)
2314 AC_SUBST(cf_cv_type_of_bool)dnl
2315
2316 ])
2317 dnl ---------------------------------------------------------------------------
2318 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2319 dnl -------------------
2320 dnl Check if we can compile with ncurses' header file
2321 dnl $1 is the cache variable to set
2322 dnl $2 is the header-file to include
2323 dnl $3 is the root name (ncurses or ncursesw)
2324 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2325         AC_TRY_COMPILE([
2326 ]ifelse($3,ncursesw,[
2327 #define _XOPEN_SOURCE_EXTENDED
2328 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2329 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2330 ])[
2331 #include <$2>],[
2332 #ifdef NCURSES_VERSION
2333 ]ifelse($3,ncursesw,[
2334 #ifndef WACS_BSSB
2335         make an error
2336 #endif
2337 ])[
2338 printf("%s\n", NCURSES_VERSION);
2339 #else
2340 #ifdef __NCURSES_H
2341 printf("old\n");
2342 #else
2343         make an error
2344 #endif
2345 #endif
2346         ]
2347         ,[$1=$2]
2348         ,[$1=no])
2349 ])dnl
2350 dnl ---------------------------------------------------------------------------
2351 dnl CF_NCURSES_CONFIG version: 20 updated: 2018/01/03 04:47:33
2352 dnl -----------------
2353 dnl Tie together the configure-script macros for ncurses, preferring these in
2354 dnl order:
2355 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2356 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2357 dnl c) just plain libraries
2358 dnl
2359 dnl $1 is the root library name (default: "ncurses")
2360 AC_DEFUN([CF_NCURSES_CONFIG],[
2361 AC_REQUIRE([CF_PKG_CONFIG])
2362 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2363 cf_have_ncuconfig=no
2364
2365 if test "x${PKG_CONFIG:=none}" != xnone; then
2366         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2367         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2368                 AC_MSG_RESULT(yes)
2369
2370                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2371                 cf_have_ncuconfig=unknown
2372
2373                 cf_save_CPPFLAGS="$CPPFLAGS"
2374                 cf_save_LIBS="$LIBS"
2375
2376                 CPPFLAGS="$CPPFLAGS `$PKG_CONFIG --cflags $cf_ncuconfig_root`"
2377                 CF_ADD_LIBS(`$PKG_CONFIG --libs $cf_ncuconfig_root`)
2378
2379                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2380                         [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2381                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2382                                 int main(void)
2383                                 { char *xx = curses_version(); return (xx == 0); }],
2384                                 [cf_have_ncuconfig=yes],
2385                                 [cf_have_ncuconfig=no],
2386                                 [cf_have_ncuconfig=maybe])],
2387                         [cf_have_ncuconfig=no])
2388                 AC_MSG_RESULT($cf_have_ncuconfig)
2389                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2390                 if test "$cf_have_ncuconfig" != "yes"
2391                 then
2392                         CPPFLAGS="$cf_save_CPPFLAGS"
2393                         LIBS="$cf_save_LIBS"
2394                         NCURSES_CONFIG_PKG=none
2395                 else
2396                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2397                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2398                         CF_TERM_HEADER
2399                 fi
2400
2401         else
2402                 AC_MSG_RESULT(no)
2403                 NCURSES_CONFIG_PKG=none
2404         fi
2405 else
2406         NCURSES_CONFIG_PKG=none
2407 fi
2408
2409 if test "x$cf_have_ncuconfig" = "xno"; then
2410         cf_ncurses_config="${cf_ncuconfig_root}${NCURSES_CONFIG_SUFFIX}-config"; echo "Looking for ${cf_ncurses_config}"
2411
2412         CF_ACVERSION_CHECK(2.52,
2413                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2414                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2415
2416         if test "$NCURSES_CONFIG" != none ; then
2417
2418                 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
2419                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2420
2421                 # even with config script, some packages use no-override for curses.h
2422                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2423
2424                 dnl like CF_NCURSES_CPPFLAGS
2425                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2426
2427                 dnl like CF_NCURSES_LIBS
2428                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2429                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2430
2431                 dnl like CF_NCURSES_VERSION
2432                 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2433
2434         else
2435
2436                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2437                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2438
2439         fi
2440 else
2441         NCURSES_CONFIG=none
2442 fi
2443 ])dnl
2444 dnl ---------------------------------------------------------------------------
2445 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2446 dnl -------------------
2447 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2448 dnl the CPPFLAGS variable so we can include its header.
2449 dnl
2450 dnl The header files may be installed as either curses.h, or ncurses.h (would
2451 dnl be obsolete, except that some packagers prefer this name to distinguish it
2452 dnl from a "native" curses implementation).  If not installed for overwrite,
2453 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2454 dnl /usr/include/ncurses), but someone may have installed overwriting the
2455 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2456 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2457 dnl the header.
2458 dnl
2459 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2460 dnl is already in the include-path, don't even bother with this, since we cannot
2461 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2462 dnl
2463 dnl The optional parameter gives the root name of the library, in case it is
2464 dnl not installed as the default curses library.  That is how the
2465 dnl wide-character version of ncurses is installed.
2466 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2467 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2468
2469 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2470 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2471
2472 test -n "$cf_cv_curses_dir" && \
2473 test "$cf_cv_curses_dir" != "no" && { \
2474   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2475 }
2476
2477 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2478         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2479         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2480         for cf_header in $cf_header_list
2481         do
2482                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2483                 test "$cf_cv_ncurses_h" != no && break
2484         done
2485 ])
2486
2487 CF_NCURSES_HEADER
2488 CF_TERM_HEADER
2489
2490 # some applications need this, but should check for NCURSES_VERSION
2491 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2492
2493 CF_NCURSES_VERSION
2494 ])dnl
2495 dnl ---------------------------------------------------------------------------
2496 dnl CF_NCURSES_HEADER version: 4 updated: 2015/04/15 19:08:48
2497 dnl -----------------
2498 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2499 dnl variations of ncurses' installs.
2500 dnl
2501 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2502 AC_DEFUN([CF_NCURSES_HEADER],[
2503
2504 if test "$cf_cv_ncurses_h" != no ; then
2505         cf_cv_ncurses_header=$cf_cv_ncurses_h
2506 else
2507
2508 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2509         test -n "$verbose" && echo
2510         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2511         test -n "$verbose" && echo search path $cf_search
2512         cf_save2_CPPFLAGS="$CPPFLAGS"
2513         for cf_incdir in $cf_search
2514         do
2515                 CF_ADD_INCDIR($cf_incdir)
2516                 for cf_header in \
2517                         ncurses.h \
2518                         curses.h
2519                 do
2520                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2521                         if test "$cf_cv_ncurses_h2" != no ; then
2522                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2523                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2524                                 break
2525                         fi
2526                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2527                 done
2528                 CPPFLAGS="$cf_save2_CPPFLAGS"
2529                 test "$cf_cv_ncurses_h2" != no && break
2530         done
2531         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2532         ])
2533
2534         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2535         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2536         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2537                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2538         fi
2539         CF_ADD_INCDIR($cf_1st_incdir)
2540
2541 fi
2542
2543 # Set definitions to allow ifdef'ing for ncurses.h
2544
2545 case $cf_cv_ncurses_header in
2546 (*ncurses.h)
2547         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2548         ;;
2549 esac
2550
2551 case $cf_cv_ncurses_header in
2552 (ncurses/curses.h|ncurses/ncurses.h)
2553         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2554         ;;
2555 (ncursesw/curses.h|ncursesw/ncurses.h)
2556         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2557         ;;
2558 esac
2559
2560 ])dnl
2561 dnl ---------------------------------------------------------------------------
2562 dnl CF_NCURSES_LIBS version: 17 updated: 2015/04/15 19:08:48
2563 dnl ---------------
2564 dnl Look for the ncurses library.  This is a little complicated on Linux,
2565 dnl because it may be linked with the gpm (general purpose mouse) library.
2566 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2567 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2568 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2569 dnl and the linker will record a dependency.
2570 dnl
2571 dnl The optional parameter gives the root name of the library, in case it is
2572 dnl not installed as the default curses library.  That is how the
2573 dnl wide-character version of ncurses is installed.
2574 AC_DEFUN([CF_NCURSES_LIBS],
2575 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2576
2577 cf_nculib_root=ifelse($1,,ncurses,$1)
2578         # This works, except for the special case where we find gpm, but
2579         # ncurses is in a nonstandard location via $LIBS, and we really want
2580         # to link gpm.
2581 cf_ncurses_LIBS=""
2582 cf_ncurses_SAVE="$LIBS"
2583 AC_CHECK_LIB(gpm,Gpm_Open,
2584         [AC_CHECK_LIB(gpm,initscr,
2585                 [LIBS="$cf_ncurses_SAVE"],
2586                 [cf_ncurses_LIBS="-lgpm"])])
2587
2588 case $host_os in
2589 (freebsd*)
2590         # This is only necessary if you are linking against an obsolete
2591         # version of ncurses (but it should do no harm, since it's static).
2592         if test "$cf_nculib_root" = ncurses ; then
2593                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2594         fi
2595         ;;
2596 esac
2597
2598 CF_ADD_LIBS($cf_ncurses_LIBS)
2599
2600 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2601 then
2602         CF_ADD_LIBS(-l$cf_nculib_root)
2603 else
2604         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2605                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2606                 [initscr()],
2607                 initscr)
2608 fi
2609
2610 if test -n "$cf_ncurses_LIBS" ; then
2611         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2612         cf_ncurses_SAVE="$LIBS"
2613         for p in $cf_ncurses_LIBS ; do
2614                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2615                 if test "$q" != "$LIBS" ; then
2616                         LIBS="$q"
2617                 fi
2618         done
2619         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2620                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2621                 [AC_MSG_RESULT(yes)],
2622                 [AC_MSG_RESULT(no)
2623                  LIBS="$cf_ncurses_SAVE"])
2624 fi
2625
2626 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2627 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2628 ])dnl
2629 dnl ---------------------------------------------------------------------------
2630 dnl CF_NCURSES_VERSION version: 15 updated: 2017/05/09 19:26:10
2631 dnl ------------------
2632 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2633 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2634 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2635 AC_DEFUN([CF_NCURSES_VERSION],
2636 [
2637 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2638 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2639         cf_cv_ncurses_version=no
2640         cf_tempfile=out$$
2641         rm -f $cf_tempfile
2642         AC_TRY_RUN([
2643 #include <${cf_cv_ncurses_header:-curses.h}>
2644 #include <stdio.h>
2645 int main(void)
2646 {
2647         FILE *fp = fopen("$cf_tempfile", "w");
2648 #ifdef NCURSES_VERSION
2649 # ifdef NCURSES_VERSION_PATCH
2650         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2651 # else
2652         fprintf(fp, "%s\n", NCURSES_VERSION);
2653 # endif
2654 #else
2655 # ifdef __NCURSES_H
2656         fprintf(fp, "old\n");
2657 # else
2658         make an error
2659 # endif
2660 #endif
2661         ${cf_cv_main_return:-return}(0);
2662 }],[
2663         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2664
2665         # This will not work if the preprocessor splits the line after the
2666         # Autoconf token.  The 'unproto' program does that.
2667         cat > conftest.$ac_ext <<EOF
2668 #include <${cf_cv_ncurses_header:-curses.h}>
2669 #undef Autoconf
2670 #ifdef NCURSES_VERSION
2671 Autoconf NCURSES_VERSION
2672 #else
2673 #ifdef __NCURSES_H
2674 Autoconf "old"
2675 #endif
2676 ;
2677 #endif
2678 EOF
2679         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2680         AC_TRY_EVAL(cf_try)
2681         if test -f conftest.out ; then
2682                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2683                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2684                 rm -f conftest.out
2685         fi
2686 ])
2687         rm -f $cf_tempfile
2688 ])
2689 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2690 ])dnl
2691 dnl ---------------------------------------------------------------------------
2692 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
2693 dnl -------------
2694 dnl Compute the object-directory name from the given model name
2695 AC_DEFUN([CF_OBJ_SUBDIR],
2696 [
2697         case $1 in
2698         (libtool) $2='obj_lo'  ;;
2699         (normal)  $2='objects' ;;
2700         (debug)   $2='obj_g' ;;
2701         (profile) $2='obj_p' ;;
2702         (shared)
2703                 case $cf_cv_system_name in
2704                 (cygwin|msys)
2705                         $2='objects' ;;
2706                 (*)
2707                         $2='obj_s' ;;
2708                 esac
2709         esac
2710 ])dnl
2711 dnl ---------------------------------------------------------------------------
2712 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
2713 dnl ----------
2714 dnl Provide a value for the $PATH and similar separator (or amend the value
2715 dnl as provided in autoconf 2.5x).
2716 AC_DEFUN([CF_PATHSEP],
2717 [
2718         AC_MSG_CHECKING(for PATH separator)
2719         case $cf_cv_system_name in
2720         (os2*)  PATH_SEPARATOR=';'  ;;
2721         (*)     ${PATH_SEPARATOR:=':'}  ;;
2722         esac
2723 ifelse([$1],,,[$1=$PATH_SEPARATOR])
2724         AC_SUBST(PATH_SEPARATOR)
2725         AC_MSG_RESULT($PATH_SEPARATOR)
2726 ])dnl
2727 dnl ---------------------------------------------------------------------------
2728 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
2729 dnl --------------
2730 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2731 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2732 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2733 dnl delayed evaluation of those symbols.
2734 AC_DEFUN([CF_PATH_SYNTAX],[
2735 if test "x$prefix" != xNONE; then
2736         cf_path_syntax="$prefix"
2737 else
2738         cf_path_syntax="$ac_default_prefix"
2739 fi
2740
2741 case ".[$]$1" in
2742 (.\[$]\(*\)*|.\'*\'*)
2743         ;;
2744 (..|./*|.\\*)
2745         ;;
2746 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
2747         ;;
2748 (.\[$]{*prefix}*|.\[$]{*dir}*)
2749         eval $1="[$]$1"
2750         case ".[$]$1" in
2751         (.NONE/*)
2752                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2753                 ;;
2754         esac
2755         ;;
2756 (.no|.NONE/*)
2757         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2758         ;;
2759 (*)
2760         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2761         ;;
2762 esac
2763 ])dnl
2764 dnl ---------------------------------------------------------------------------
2765 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
2766 dnl -------------
2767 dnl Check for the package-config program, unless disabled by command-line.
2768 AC_DEFUN([CF_PKG_CONFIG],
2769 [
2770 AC_MSG_CHECKING(if you want to use pkg-config)
2771 AC_ARG_WITH(pkg-config,
2772         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2773         [cf_pkg_config=$withval],
2774         [cf_pkg_config=yes])
2775 AC_MSG_RESULT($cf_pkg_config)
2776
2777 case $cf_pkg_config in
2778 (no)
2779         PKG_CONFIG=none
2780         ;;
2781 (yes)
2782         CF_ACVERSION_CHECK(2.52,
2783                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2784                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2785         ;;
2786 (*)
2787         PKG_CONFIG=$withval
2788         ;;
2789 esac
2790
2791 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2792 if test "$PKG_CONFIG" != none ; then
2793         CF_PATH_SYNTAX(PKG_CONFIG)
2794 elif test "x$cf_pkg_config" != xno ; then
2795         AC_MSG_WARN(pkg-config is not installed)
2796 fi
2797
2798 AC_SUBST(PKG_CONFIG)
2799 ])dnl
2800 dnl ---------------------------------------------------------------------------
2801 dnl CF_POSIX_C_SOURCE version: 9 updated: 2015/04/12 15:39:00
2802 dnl -----------------
2803 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2804 dnl
2805 dnl     POSIX.1-1990                            _POSIX_SOURCE
2806 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2807 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2808 dnl             Bindings Option
2809 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2810 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2811 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2812 dnl
2813 dnl Parameters:
2814 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2815 AC_DEFUN([CF_POSIX_C_SOURCE],
2816 [
2817 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2818
2819 cf_save_CFLAGS="$CFLAGS"
2820 cf_save_CPPFLAGS="$CPPFLAGS"
2821
2822 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2823 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2824
2825 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2826         CF_MSG_LOG(if the symbol is already defined go no further)
2827         AC_TRY_COMPILE([#include <sys/types.h>],[
2828 #ifndef _POSIX_C_SOURCE
2829 make an error
2830 #endif],
2831         [cf_cv_posix_c_source=no],
2832         [cf_want_posix_source=no
2833          case .$cf_POSIX_C_SOURCE in
2834          (.[[12]]??*)
2835                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2836                 ;;
2837          (.2)
2838                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2839                 cf_want_posix_source=yes
2840                 ;;
2841          (.*)
2842                 cf_want_posix_source=yes
2843                 ;;
2844          esac
2845          if test "$cf_want_posix_source" = yes ; then
2846                 AC_TRY_COMPILE([#include <sys/types.h>],[
2847 #ifdef _POSIX_SOURCE
2848 make an error
2849 #endif],[],
2850                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2851          fi
2852          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2853          CFLAGS="$cf_trim_CFLAGS"
2854          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2855          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2856          AC_TRY_COMPILE([#include <sys/types.h>],[
2857 #ifndef _POSIX_C_SOURCE
2858 make an error
2859 #endif],,
2860          [cf_cv_posix_c_source=no])
2861          CFLAGS="$cf_save_CFLAGS"
2862          CPPFLAGS="$cf_save_CPPFLAGS"
2863         ])
2864 ])
2865
2866 if test "$cf_cv_posix_c_source" != no ; then
2867         CFLAGS="$cf_trim_CFLAGS"
2868         CPPFLAGS="$cf_trim_CPPFLAGS"
2869         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2870 fi
2871
2872 ])dnl
2873 dnl ---------------------------------------------------------------------------
2874 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
2875 dnl ----------
2876 dnl Check for archiver "ar".
2877 AC_DEFUN([CF_PROG_AR],[
2878 AC_CHECK_TOOL(AR, ar, ar)
2879 ])
2880 dnl ---------------------------------------------------------------------------
2881 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
2882 dnl -----------
2883 dnl Check for awk, ensure that the check found something.
2884 AC_DEFUN([CF_PROG_AWK],
2885 [
2886 AC_PROG_AWK
2887 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
2888 ])dnl
2889 dnl ---------------------------------------------------------------------------
2890 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
2891 dnl ----------
2892 dnl standard check for CC, plus followup sanity checks
2893 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
2894 AC_DEFUN([CF_PROG_CC],[
2895 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
2896 CF_GCC_VERSION
2897 CF_ACVERSION_CHECK(2.52,
2898         [AC_PROG_CC_STDC],
2899         [CF_ANSI_CC_REQD])
2900 CF_CC_ENV_FLAGS
2901 ])dnl
2902 dnl ---------------------------------------------------------------------------
2903 dnl CF_PROG_CC_C_O version: 5 updated: 2017/01/21 11:06:25
2904 dnl --------------
2905 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
2906 dnl the output file can be renamed, and allows for a shell variable that can
2907 dnl be used later.  The parameter is either CC or CXX.  The result is the
2908 dnl cache variable:
2909 dnl     $cf_cv_prog_CC_c_o
2910 dnl     $cf_cv_prog_CXX_c_o
2911 dnl
2912 dnl $1 = compiler
2913 dnl $2 = compiler options, if any
2914 AC_DEFUN([CF_PROG_CC_C_O],
2915 [AC_REQUIRE([AC_PROG_CC])dnl
2916 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
2917 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
2918 [
2919 cat > conftest.$ac_ext <<CF_EOF
2920 int main(void)
2921 {
2922         ${cf_cv_main_return:-return}(0);
2923 }
2924 CF_EOF
2925 # We do the test twice because some compilers refuse to overwrite an
2926 # existing .o file with -o, though they will create one.
2927 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
2928 if AC_TRY_EVAL(ac_try) &&
2929   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
2930 then
2931   eval cf_cv_prog_$1_c_o=yes
2932 else
2933   eval cf_cv_prog_$1_c_o=no
2934 fi
2935 rm -rf conftest*
2936 ])dnl
2937 if test $cf_cv_prog_$1_c_o = yes; then
2938   AC_MSG_RESULT([yes])
2939 else
2940   AC_MSG_RESULT([no])
2941 fi
2942 ])dnl
2943 dnl ---------------------------------------------------------------------------
2944 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
2945 dnl -------------
2946 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
2947 dnl This macro adds a check to ensure the script found something.
2948 AC_DEFUN([CF_PROG_EGREP],
2949 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
2950         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
2951                 then ac_cv_prog_egrep='grep -E'
2952                 else ac_cv_prog_egrep='egrep'
2953         fi])
2954         EGREP=$ac_cv_prog_egrep
2955         AC_SUBST([EGREP])
2956         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
2957 ])dnl
2958 dnl ---------------------------------------------------------------------------
2959 dnl CF_PROG_EXT version: 13 updated: 2015/04/18 09:03:58
2960 dnl -----------
2961 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
2962 AC_DEFUN([CF_PROG_EXT],
2963 [
2964 AC_REQUIRE([CF_CHECK_CACHE])
2965 case $cf_cv_system_name in
2966 (os2*)
2967         CFLAGS="$CFLAGS -Zmt"
2968         CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
2969         CXXFLAGS="$CXXFLAGS -Zmt"
2970         # autoconf's macro sets -Zexe and suffix both, which conflict:w
2971         LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
2972         ac_cv_exeext=.exe
2973         ;;
2974 esac
2975
2976 AC_EXEEXT
2977 AC_OBJEXT
2978
2979 PROG_EXT="$EXEEXT"
2980 AC_SUBST(PROG_EXT)
2981 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
2982 ])dnl
2983 dnl ---------------------------------------------------------------------------
2984 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
2985 dnl ---------------
2986 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
2987 dnl misc/tabset install won't work properly.  Usually this happens only when
2988 dnl using the fallback mkinstalldirs script
2989 AC_DEFUN([CF_PROG_INSTALL],
2990 [AC_PROG_INSTALL
2991 case $INSTALL in
2992 (/*)
2993         ;;
2994 (*)
2995         CF_DIRNAME(cf_dir,$INSTALL)
2996         test -z "$cf_dir" && cf_dir=.
2997         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
2998         ;;
2999 esac
3000 ])dnl
3001 dnl ---------------------------------------------------------------------------
3002 dnl CF_PROG_GNAT version: 6 updated: 2018/01/16 16:45:49
3003 dnl ------------
3004 dnl Check for gnatmake, ensure that it is complete.
3005 AC_DEFUN([CF_PROG_GNAT],[
3006 cf_ada_make=gnatmake
3007 cf_ada_config="#"
3008 AC_CHECK_PROG(gnatmake_exists, $cf_ada_make, yes, no)
3009 if test "$ac_cv_prog_gnatmake_exists" = no; then
3010         cf_ada_make=
3011         cf_cv_prog_gnat_correct=no
3012 else
3013         AC_CHECK_PROG(gprconfig_exists, gprconfig, yes, no)
3014         if test "$ac_cv_prog_gprconfig_exists" = yes
3015         then
3016                 rm -rf conftest* *~conftest*
3017                 if mkdir conftest.src
3018                 then
3019                         cf_ada_config=""
3020                         cd conftest.src
3021                         for cf_gprconfig in Ada C
3022                         do
3023                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
3024                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
3025                                 if test -n "$cf_gprconfig_value"
3026                                 then
3027                                         eval cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value
3028                                         AC_MSG_RESULT($cf_gprconfig_value)
3029                                 else
3030                                         AC_MSG_RESULT(missing)
3031                                         cf_ada_config="#"
3032                                         break
3033                                 fi
3034                         done
3035                         cd ..
3036                         rm -rf conftest* *~conftest*
3037                 fi
3038         else
3039                 # gprconfig is newer than gnatmake; we can continue...
3040                 cf_ada_config="##"
3041         fi
3042         if test "x$cf_ada_config" != "x#"
3043         then
3044                 CF_GNAT_VERSION
3045                 AC_CHECK_PROG(M4_exists, m4, yes, no)
3046                 if test "$ac_cv_prog_M4_exists" = no; then
3047                         cf_cv_prog_gnat_correct=no
3048                         echo Ada95 binding required program m4 not found. Ada95 binding disabled.
3049                 fi
3050                 if test "$cf_cv_prog_gnat_correct" = yes; then
3051                         AC_MSG_CHECKING(if GNAT works)
3052                         CF_GNAT_TRY_RUN([procedure conftest;],
3053 [with Text_IO;
3054 with GNAT.OS_Lib;
3055 procedure conftest is
3056 begin
3057    Text_IO.Put ("Hello World");
3058    Text_IO.New_Line;
3059    GNAT.OS_Lib.OS_Exit (0);
3060 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
3061                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
3062                 fi
3063         else
3064                 cf_cv_prog_gnat_correct=no
3065         fi
3066 fi
3067
3068 AC_SUBST(cf_ada_make)
3069 AC_SUBST(cf_ada_config)
3070 AC_SUBST(cf_ada_config_Ada)
3071 AC_SUBST(cf_ada_config_C)
3072 ])dnl
3073 dnl ---------------------------------------------------------------------------
3074 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
3075 dnl ------------
3076 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
3077 dnl option if it is supported.
3078 AC_DEFUN([CF_PROG_LN_S],[
3079 AC_PROG_LN_S
3080 AC_MSG_CHECKING(if $LN_S -f options work)
3081
3082 rm -f conf$$.src conf$$dst
3083 echo >conf$$.dst
3084 echo first >conf$$.src
3085 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
3086         cf_prog_ln_sf=yes
3087 else
3088         cf_prog_ln_sf=no
3089 fi
3090 rm -f conf$$.dst conf$$src
3091 AC_MSG_RESULT($cf_prog_ln_sf)
3092
3093 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
3094 ])dnl
3095 dnl ---------------------------------------------------------------------------
3096 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
3097 dnl ----------------
3098 dnl Remove all -U and -D options that refer to the given symbol from a list
3099 dnl of C compiler options.  This works around the problem that not all
3100 dnl compilers process -U and -D options from left-to-right, so a -U option
3101 dnl cannot be used to cancel the effect of a preceding -D option.
3102 dnl
3103 dnl $1 = target (which could be the same as the source variable)
3104 dnl $2 = source (including '$')
3105 dnl $3 = symbol to remove
3106 define([CF_REMOVE_DEFINE],
3107 [
3108 $1=`echo "$2" | \
3109         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
3110                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
3111 ])dnl
3112 dnl ---------------------------------------------------------------------------
3113 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
3114 dnl -------------
3115 dnl Remove the given library from the symbol
3116 dnl
3117 dnl $1 = target (which could be the same as the source variable)
3118 dnl $2 = source (including '$')
3119 dnl $3 = library to remove
3120 define([CF_REMOVE_LIB],
3121 [
3122 # remove $3 library from $2
3123 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
3124 ])dnl
3125 dnl ---------------------------------------------------------------------------
3126 dnl CF_SHARED_OPTS version: 92 updated: 2017/12/30 17:26:05
3127 dnl --------------
3128 dnl --------------
3129 dnl Attempt to determine the appropriate CC/LD options for creating a shared
3130 dnl library.
3131 dnl
3132 dnl Notes:
3133 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
3134 dnl the build-tree, i.e., by making use of the libraries that are compiled in
3135 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
3136 dnl shared library since that can lead to unexpected results at runtime.
3137 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
3138 dnl libraries are compiled in ../../lib
3139 dnl
3140 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
3141 dnl to install symbolic links to the rel/abi versions of shared libraries.
3142 dnl
3143 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
3144 dnl version when making symbolic links.
3145 dnl
3146 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
3147 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
3148 dnl (ex: libncurses.so.<ver>).
3149 dnl
3150 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
3151 AC_DEFUN([CF_SHARED_OPTS],
3152 [
3153         AC_REQUIRE([CF_LD_RPATH_OPT])
3154         RM_SHARED_OPTS=
3155         LOCAL_LDFLAGS=
3156         LOCAL_LDFLAGS2=
3157         LD_SHARED_OPTS=
3158         INSTALL_LIB="-m 644"
3159         : ${rel_builddir:=.}
3160
3161         shlibdir=$libdir
3162         AC_SUBST(shlibdir)
3163
3164         MAKE_DLLS="#"
3165         AC_SUBST(MAKE_DLLS)
3166
3167         cf_cv_do_symlinks=no
3168         cf_ld_rpath_opt=
3169         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
3170
3171         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
3172         AC_ARG_WITH(shlib-version,
3173         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
3174         [test -z "$withval" && withval=auto
3175         case $withval in
3176         (yes)
3177                 cf_cv_shlib_version=auto
3178                 ;;
3179         (rel|abi|auto)
3180                 cf_cv_shlib_version=$withval
3181                 ;;
3182         (*)
3183                 AC_MSG_RESULT($withval)
3184                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
3185                 ;;
3186         esac
3187         ],[cf_cv_shlib_version=auto])
3188         AC_MSG_RESULT($cf_cv_shlib_version)
3189
3190         cf_cv_rm_so_locs=no
3191         cf_try_cflags=
3192
3193         # Some less-capable ports of gcc support only -fpic
3194         CC_SHARED_OPTS=
3195
3196         cf_try_fPIC=no
3197         if test "$GCC" = yes
3198         then
3199                 cf_try_fPIC=yes
3200         else
3201                 case $cf_cv_system_name in
3202                 (*linux*)       # e.g., PGI compiler
3203                         cf_try_fPIC=yes
3204                         ;;
3205                 esac
3206         fi
3207
3208         if test "$cf_try_fPIC" = yes
3209         then
3210                 AC_MSG_CHECKING(which $CC option to use)
3211                 cf_save_CFLAGS="$CFLAGS"
3212                 for CC_SHARED_OPTS in -fPIC -fpic ''
3213                 do
3214                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
3215                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
3216                 done
3217                 AC_MSG_RESULT($CC_SHARED_OPTS)
3218                 CFLAGS="$cf_save_CFLAGS"
3219         fi
3220
3221         cf_cv_shlib_version_infix=no
3222
3223         case $cf_cv_system_name in
3224         (aix4.[3-9]*|aix[[5-7]]*)
3225                 if test "$GCC" = yes; then
3226                         CC_SHARED_OPTS='-Wl,-brtl'
3227                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3228                 else
3229                         CC_SHARED_OPTS='-brtl'
3230                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
3231                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3232                 fi
3233                 ;;
3234         (beos*)
3235                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
3236                 ;;
3237         (cygwin*)
3238                 CC_SHARED_OPTS=
3239                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3240                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3241                 cf_cv_shlib_version=cygdll
3242                 cf_cv_shlib_version_infix=cygdll
3243                 shlibdir=$bindir
3244                 MAKE_DLLS=
3245                 cat >mk_shared_lib.sh <<-CF_EOF
3246                 #!$SHELL
3247                 SHARED_LIB=\[$]1
3248                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3249                 shift
3250                 cat <<-EOF
3251                 Linking shared library
3252                 ** SHARED_LIB \[$]SHARED_LIB
3253                 ** IMPORT_LIB \[$]IMPORT_LIB
3254 EOF
3255                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3256 CF_EOF
3257                 chmod +x mk_shared_lib.sh
3258                 ;;
3259         (msys*)
3260                 CC_SHARED_OPTS=
3261                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3262                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3263                 cf_cv_shlib_version=msysdll
3264                 cf_cv_shlib_version_infix=msysdll
3265                 shlibdir=$bindir
3266                 MAKE_DLLS=
3267                 cat >mk_shared_lib.sh <<-CF_EOF
3268                 #!$SHELL
3269                 SHARED_LIB=\[$]1
3270                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3271                 shift
3272                 cat <<-EOF
3273                 Linking shared library
3274                 ** SHARED_LIB \[$]SHARED_LIB
3275                 ** IMPORT_LIB \[$]IMPORT_LIB
3276 EOF
3277                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3278 CF_EOF
3279                 chmod +x mk_shared_lib.sh
3280                 ;;
3281         (darwin*)
3282                 cf_try_cflags="no-cpp-precomp"
3283                 CC_SHARED_OPTS="-dynamic"
3284                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
3285                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
3286                 cf_cv_shlib_version_infix=yes
3287                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
3288                         cf_save_LDFLAGS=$LDFLAGS
3289                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3290                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
3291                                 LDFLAGS=$cf_save_LDFLAGS])
3292                 if test $cf_cv_ldflags_search_paths_first = yes; then
3293                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3294                 fi
3295                 ;;
3296         (hpux[[7-8]]*)
3297                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
3298                 if test "$GCC" != yes; then
3299                         CC_SHARED_OPTS='+Z'
3300                 fi
3301                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
3302                 INSTALL_LIB="-m 555"
3303                 ;;
3304         (hpux*)
3305                 # (tested with gcc 2.7.2 -- I don't have c89)
3306                 if test "$GCC" = yes; then
3307                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
3308                 else
3309                         CC_SHARED_OPTS='+Z'
3310                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
3311                 fi
3312                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
3313                 # HP-UX shared libraries must be executable, and should be
3314                 # readonly to exploit a quirk in the memory manager.
3315                 INSTALL_LIB="-m 555"
3316                 ;;
3317         (interix*)
3318                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3319                 if test "$cf_cv_shlib_version" = rel; then
3320                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3321                 else
3322                         cf_shared_soname='`basename $[@]`'
3323                 fi
3324                 CC_SHARED_OPTS=
3325                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
3326                 ;;
3327         (irix*)
3328                 if test "$cf_cv_enable_rpath" = yes ; then
3329                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3330                 fi
3331                 # tested with IRIX 5.2 and 'cc'.
3332                 if test "$GCC" != yes; then
3333                         CC_SHARED_OPTS='-KPIC'
3334                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
3335                 else
3336                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
3337                 fi
3338                 cf_cv_rm_so_locs=yes
3339                 ;;
3340         (linux*|gnu*|k*bsd*-gnu)
3341                 if test "$DFT_LWR_MODEL" = "shared" ; then
3342                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3343                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3344                 fi
3345                 if test "$cf_cv_enable_rpath" = yes ; then
3346                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3347                 fi
3348                 CF_SHARED_SONAME
3349                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3350                 ;;
3351         (mingw*)
3352                 cf_cv_shlib_version=mingw
3353                 cf_cv_shlib_version_infix=mingw
3354                 shlibdir=$bindir
3355                 MAKE_DLLS=
3356                 if test "$DFT_LWR_MODEL" = "shared" ; then
3357                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
3358                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3359                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
3360                 fi
3361                 CC_SHARED_OPTS=
3362                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3363                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3364                 cat >mk_shared_lib.sh <<-CF_EOF
3365                 #!$SHELL
3366                 SHARED_LIB=\[$]1
3367                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3368                 shift
3369                 cat <<-EOF
3370                 Linking shared library
3371                 ** SHARED_LIB \[$]SHARED_LIB
3372                 ** IMPORT_LIB \[$]IMPORT_LIB
3373 EOF
3374                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3375 CF_EOF
3376                 chmod +x mk_shared_lib.sh
3377                 ;;
3378         (openbsd[[2-9]].*|mirbsd*)
3379                 if test "$DFT_LWR_MODEL" = "shared" ; then
3380                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3381                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3382                 fi
3383                 if test "$cf_cv_enable_rpath" = yes ; then
3384                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3385                 fi
3386                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3387                 CF_SHARED_SONAME
3388                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3389                 ;;
3390         (nto-qnx*|openbsd*|freebsd[[12]].*)
3391                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3392                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
3393                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3394                 ;;
3395         (dragonfly*|freebsd*)
3396                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3397                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3398                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3399                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
3400                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3401                 fi
3402                 CF_SHARED_SONAME
3403                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3404                 ;;
3405         (netbsd*)
3406                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3407                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3408                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3409                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3410                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3411                         if test "$cf_cv_shlib_version" = auto; then
3412                         if test -f /usr/libexec/ld.elf_so; then
3413                                 cf_cv_shlib_version=abi
3414                         else
3415                                 cf_cv_shlib_version=rel
3416                         fi
3417                         fi
3418                         CF_SHARED_SONAME
3419                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
3420                 else
3421                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -Wl,-shared -Wl,-Bshareable -o $[@]'
3422                 fi
3423                 ;;
3424         (osf*|mls+*)
3425                 # tested with OSF/1 V3.2 and 'cc'
3426                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
3427                 # link with shared libs).
3428                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
3429                 case $host_os in
3430                 (osf4*)
3431                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
3432                         ;;
3433                 esac
3434                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
3435                 if test "$DFT_LWR_MODEL" = "shared" ; then
3436                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3437                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3438                 fi
3439                 cf_cv_rm_so_locs=yes
3440                 ;;
3441         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
3442                 # tested with osr5.0.5
3443                 if test "$GCC" != yes; then
3444                         CC_SHARED_OPTS='-belf -KPIC'
3445                 fi
3446                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
3447                 if test "$cf_cv_enable_rpath" = yes ; then
3448                         # only way is to set LD_RUN_PATH but no switch for it
3449                         RUN_PATH=$libdir
3450                 fi
3451                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3452                 LINK_PROGS='LD_RUN_PATH=${libdir}'
3453                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
3454                 ;;
3455         (sunos4*)
3456                 # tested with SunOS 4.1.1 and gcc 2.7.0
3457                 if test "$GCC" != yes; then
3458                         CC_SHARED_OPTS='-KPIC'
3459                 fi
3460                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
3461                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3462                 ;;
3463         (solaris2*)
3464                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
3465                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
3466                 if test "$DFT_LWR_MODEL" = "shared" ; then
3467                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
3468                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3469                 fi
3470                 if test "$cf_cv_enable_rpath" = yes ; then
3471                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
3472                 fi
3473                 CF_SHARED_SONAME
3474                 if test "$GCC" != yes; then
3475                         cf_save_CFLAGS="$CFLAGS"
3476                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
3477                         do
3478                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
3479                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
3480                         done
3481                         CFLAGS="$cf_save_CFLAGS"
3482                         CC_SHARED_OPTS=$cf_shared_opts
3483                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3484                 else
3485                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3486                 fi
3487                 ;;
3488         (sysv5uw7*|unix_sv*)
3489                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
3490                 if test "$GCC" != yes; then
3491                         CC_SHARED_OPTS='-KPIC'
3492                 fi
3493                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
3494                 ;;
3495         (*)
3496                 CC_SHARED_OPTS='unknown'
3497                 MK_SHARED_LIB='echo unknown'
3498                 ;;
3499         esac
3500
3501         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
3502         case "$cf_cv_shlib_version" in
3503         (rel|abi)
3504                 case "$MK_SHARED_LIB" in
3505                 (*'-o $[@]')
3506                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
3507                         ;;
3508                 (*)
3509                         AC_MSG_WARN(ignored --with-shlib-version)
3510                         ;;
3511                 esac
3512                 ;;
3513         esac
3514
3515         if test -n "$cf_try_cflags"
3516         then
3517 cat > conftest.$ac_ext <<EOF
3518 #line __oline__ "${as_me:-configure}"
3519 #include <stdio.h>
3520 int main(int argc, char *argv[[]])
3521 {
3522         printf("hello\n");
3523         return (argv[[argc-1]] == 0) ;
3524 }
3525 EOF
3526                 cf_save_CFLAGS="$CFLAGS"
3527                 for cf_opt in $cf_try_cflags
3528                 do
3529                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
3530                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
3531                         if AC_TRY_EVAL(ac_compile); then
3532                                 AC_MSG_RESULT(yes)
3533                                 cf_save_CFLAGS="$CFLAGS"
3534                         else
3535                                 AC_MSG_RESULT(no)
3536                         fi
3537                 done
3538                 CFLAGS="$cf_save_CFLAGS"
3539         fi
3540
3541
3542         # RPATH_LIST is a colon-separated list of directories
3543         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
3544         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
3545
3546         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
3547
3548         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
3549         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
3550
3551         AC_SUBST(CC_SHARED_OPTS)
3552         AC_SUBST(LD_RPATH_OPT)
3553         AC_SUBST(LD_SHARED_OPTS)
3554         AC_SUBST(MK_SHARED_LIB)
3555         AC_SUBST(RM_SHARED_OPTS)
3556
3557         AC_SUBST(LINK_PROGS)
3558         AC_SUBST(LINK_TESTS)
3559
3560         AC_SUBST(EXTRA_LDFLAGS)
3561         AC_SUBST(LOCAL_LDFLAGS)
3562         AC_SUBST(LOCAL_LDFLAGS2)
3563
3564         AC_SUBST(INSTALL_LIB)
3565         AC_SUBST(RPATH_LIST)
3566 ])dnl
3567 dnl ---------------------------------------------------------------------------
3568 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
3569 dnl ----------------
3570 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
3571 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
3572 dnl option.
3573 dnl
3574 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
3575 dnl If missing, use "rel".
3576 define([CF_SHARED_SONAME],
3577 [
3578         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1