Ada95/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2019,2020 Thomas E. Dickey                                *
   3 dnl Copyright 2010-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey
  31 dnl
  32 dnl $Id: aclocal.m4,v 1.162 2020/09/26 23:08:42 tom Exp $
  33 dnl Macros used in NCURSES Ada95 auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See these pages for additional information:
  40 dnl             https://invisible-island.net/autoconf/
  41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  42 dnl
  43 dnl ---------------------------------------------------------------------------
  44 dnl ---------------------------------------------------------------------------
  45 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
  46 dnl ------------------
  47 dnl Conditionally generate script according to whether we're using a given autoconf.
  48 dnl
  49 dnl $1 = version to compare against
  50 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  51 dnl $3 = code to use if AC_ACVERSION is older than $1.
  52 define([CF_ACVERSION_CHECK],
  53 [
  54 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
  55 ifdef([m4_version_compare],
  56 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  57 [CF_ACVERSION_COMPARE(
  58 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  59 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  60 dnl ---------------------------------------------------------------------------
  61 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  62 dnl --------------------
  63 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  64 dnl                      MAJOR2, MINOR2, TERNARY2,
  65 dnl                      PRINTABLE2, not FOUND, FOUND)
  66 define([CF_ACVERSION_COMPARE],
  67 [ifelse(builtin([eval], [$2 < $5]), 1,
  68 [ifelse([$8], , ,[$8])],
  69 [ifelse([$9], , ,[$9])])])dnl
  70 dnl ---------------------------------------------------------------------------
  71 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
  72 dnl -------------------
  73 dnl Construct the list of include-options for the C programs in the Ada95
  74 dnl binding.
  75 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  76 [
  77 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  78 if test "$srcdir" != "."; then
  79         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  80 fi
  81 if test "$GCC" != yes; then
  82         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  83 elif test "$includedir" != "/usr/include"; then
  84         if test "$includedir" = '${prefix}/include' ; then
  85                 if test x$prefix != x/usr ; then
  86                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  87                 fi
  88         else
  89                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  90         fi
  91 fi
  92 AC_SUBST(ACPPFLAGS)
  93 ])dnl
  94 dnl ---------------------------------------------------------------------------
  95 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
  96 dnl ---------------
  97 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
  98 AC_DEFUN([CF_ADD_ADAFLAGS],[
  99         ADAFLAGS="$ADAFLAGS $1"
 100         AC_SUBST(ADAFLAGS)
 101 ])dnl
 102 dnl ---------------------------------------------------------------------------
 103 dnl CF_ADD_CFLAGS version: 14 updated: 2020/04/04 16:16:13
 104 dnl -------------
 105 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 106 dnl $1 = flags to add
 107 dnl $2 = if given makes this macro verbose.
 108 dnl
 109 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 110 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 111 dnl confused by the quotes (which require backslashes to keep them usable).
 112 AC_DEFUN([CF_ADD_CFLAGS],
 113 [
 114 cf_fix_cppflags=no
 115 cf_new_cflags=
 116 cf_new_cppflags=
 117 cf_new_extra_cppflags=
 118
 119 for cf_add_cflags in $1
 120 do
 121 case $cf_fix_cppflags in
 122 (no)
 123         case $cf_add_cflags in
 124         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 125                 case $cf_add_cflags in
 126                 (-D*)
 127                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 128
 129                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 130                                 && test -z "${cf_tst_cflags}" \
 131                                 && cf_fix_cppflags=yes
 132
 133                         if test $cf_fix_cppflags = yes ; then
 134                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 135                                 continue
 136                         elif test "${cf_tst_cflags}" = "\"'" ; then
 137                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 138                                 continue
 139                         fi
 140                         ;;
 141                 esac
 142                 case "$CPPFLAGS" in
 143                 (*$cf_add_cflags)
 144                         ;;
 145                 (*)
 146                         case $cf_add_cflags in
 147                         (-D*)
 148                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 149                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 150                                 ;;
 151                         esac
 152                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 153                         ;;
 154                 esac
 155                 ;;
 156         (*)
 157                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 158                 ;;
 159         esac
 160         ;;
 161 (yes)
 162         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 163
 164         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 165
 166         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 167                 && test -z "${cf_tst_cflags}" \
 168                 && cf_fix_cppflags=no
 169         ;;
 170 esac
 171 done
 172
 173 if test -n "$cf_new_cflags" ; then
 174         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 175         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 176 fi
 177
 178 if test -n "$cf_new_cppflags" ; then
 179         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 180         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 181 fi
 182
 183 if test -n "$cf_new_extra_cppflags" ; then
 184         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 185         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 186 fi
 187
 188 AC_SUBST(EXTRA_CPPFLAGS)
 189
 190 ])dnl
 191 dnl ---------------------------------------------------------------------------
 192 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
 193 dnl -------------
 194 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 195 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 196 dnl but old versions (and some misinstalled ones) need that.  To make things
 197 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 198 dnl the include-path).
 199 AC_DEFUN([CF_ADD_INCDIR],
 200 [
 201 if test -n "$1" ; then
 202   for cf_add_incdir in $1
 203   do
 204         while test $cf_add_incdir != /usr/include
 205         do
 206           if test -d $cf_add_incdir
 207           then
 208                 cf_have_incdir=no
 209                 if test -n "$CFLAGS$CPPFLAGS" ; then
 210                   # a loop is needed to ensure we can add subdirs of existing dirs
 211                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 212                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 213                           cf_have_incdir=yes; break
 214                         fi
 215                   done
 216                 fi
 217
 218                 if test "$cf_have_incdir" = no ; then
 219                   if test "$cf_add_incdir" = /usr/local/include ; then
 220                         if test "$GCC" = yes
 221                         then
 222                           cf_save_CPPFLAGS=$CPPFLAGS
 223                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 224                           AC_TRY_COMPILE([#include <stdio.h>],
 225                                   [printf("Hello")],
 226                                   [],
 227                                   [cf_have_incdir=yes])
 228                           CPPFLAGS=$cf_save_CPPFLAGS
 229                         fi
 230                   fi
 231                 fi
 232
 233                 if test "$cf_have_incdir" = no ; then
 234                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 235                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 236
 237                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 238                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 239                   cf_add_incdir="$cf_top_incdir"
 240                 else
 241                   break
 242                 fi
 243           else
 244                 break
 245           fi
 246         done
 247   done
 248 fi
 249 ])dnl
 250 dnl ---------------------------------------------------------------------------
 251 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 252 dnl ----------
 253 dnl Add a library, used to enforce consistency.
 254 dnl
 255 dnl $1 = library to add, without the "-l"
 256 dnl $2 = variable to update (default $LIBS)
 257 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 258 dnl ---------------------------------------------------------------------------
 259 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 260 dnl -------------
 261 dnl     Adds to the library-path
 262 dnl
 263 dnl     Some machines have trouble with multiple -L options.
 264 dnl
 265 dnl $1 is the (list of) directory(s) to add
 266 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 267 dnl
 268 AC_DEFUN([CF_ADD_LIBDIR],
 269 [
 270 if test -n "$1" ; then
 271         for cf_add_libdir in $1
 272         do
 273                 if test $cf_add_libdir = /usr/lib ; then
 274                         :
 275                 elif test -d $cf_add_libdir
 276                 then
 277                         cf_have_libdir=no
 278                         if test -n "$LDFLAGS$LIBS" ; then
 279                                 # a loop is needed to ensure we can add subdirs of existing dirs
 280                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 281                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 282                                                 cf_have_libdir=yes; break
 283                                         fi
 284                                 done
 285                         fi
 286                         if test "$cf_have_libdir" = no ; then
 287                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 288                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 289                         fi
 290                 fi
 291         done
 292 fi
 293 ])dnl
 294 dnl ---------------------------------------------------------------------------
 295 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 296 dnl -----------
 297 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 298 dnl prepended to an existing list, since their dependencies are assumed to
 299 dnl already exist in the list.
 300 dnl
 301 dnl $1 = libraries to add, with the "-l", etc.
 302 dnl $2 = variable to update (default $LIBS)
 303 AC_DEFUN([CF_ADD_LIBS],[
 304 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 305 # reverse order
 306 cf_add_0lib=
 307 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 308 # filter duplicates
 309 for cf_add_1lib in $cf_add_0lib; do
 310         for cf_add_2lib in $cf_add_libs; do
 311                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 312                         cf_add_1lib=
 313                         break
 314                 fi
 315         done
 316         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 317 done
 318 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 319 ])dnl
 320 dnl ---------------------------------------------------------------------------
 321 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 322 dnl ------------------
 323 dnl Append to a search-list for a nonstandard header/lib-file
 324 dnl     $1 = the variable to return as result
 325 dnl     $2 = the package name
 326 dnl     $3 = the subdirectory, e.g., bin, include or lib
 327 dnl $4 = the directory under which we will test for subdirectories
 328 dnl $5 = a directory that we do not want $4 to match
 329 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 330 [
 331 test "x$4" != "x$5" && \
 332 test -d "$4" && \
 333 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 334         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 335         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 336         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 337         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 338         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 339         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 340 }
 341 ])dnl
 342 dnl ---------------------------------------------------------------------------
 343 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 344 dnl --------------
 345 dnl use this macro for appending text without introducing an extra blank at
 346 dnl the beginning
 347 define([CF_APPEND_TEXT],
 348 [
 349         test -n "[$]$1" && $1="[$]$1 "
 350         $1="[$]{$1}$2"
 351 ])dnl
 352 dnl ---------------------------------------------------------------------------
 353 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 354 dnl --------------
 355 dnl Allow user to disable a normally-on option.
 356 AC_DEFUN([CF_ARG_DISABLE],
 357 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 358 dnl ---------------------------------------------------------------------------
 359 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 360 dnl -------------
 361 dnl Allow user to enable a normally-off option.
 362 AC_DEFUN([CF_ARG_ENABLE],
 363 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 364 dnl ---------------------------------------------------------------------------
 365 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 366 dnl -------------
 367 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 368 dnl values.
 369 dnl
 370 dnl Parameters:
 371 dnl $1 = option name
 372 dnl $2 = help-string
 373 dnl $3 = action to perform if option is not default
 374 dnl $4 = action if perform if option is default
 375 dnl $5 = default option value (either 'yes' or 'no')
 376 AC_DEFUN([CF_ARG_OPTION],
 377 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 378         if test "$enableval" != "$5" ; then
 379 ifelse([$3],,[    :]dnl
 380 ,[    $3]) ifelse([$4],,,[
 381         else
 382                 $4])
 383         fi],[enableval=$5 ifelse([$4],,,[
 384         $4
 385 ])dnl
 386 ])])dnl
 387 dnl ---------------------------------------------------------------------------
 388 dnl CF_AR_FLAGS version: 7 updated: 2020/04/04 11:37:29
 389 dnl -----------
 390 dnl Check for suitable "ar" (archiver) options for updating an archive.
 391 dnl
 392 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 393 dnl as well as a workaround for breakage of make's archive rules by the GNU
 394 dnl binutils "ar" program.
 395 AC_DEFUN([CF_AR_FLAGS],[
 396 AC_REQUIRE([CF_PROG_AR])
 397
 398 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 399         case $cf_cv_system_name in
 400         (*-msvc*)
 401                 cf_cv_ar_flags=''
 402                 cat >mk_static_lib.sh <<-EOF
 403                 #!$SHELL
 404                 MSVC_BIN="[$]AR"
 405                 out="\[$]1"
 406                 shift
 407                 exec \[$]MSVC_BIN -out:"\[$]out" \[$]@
 408                 EOF
 409                 chmod +x mk_static_lib.sh
 410                 AR=`pwd`/mk_static_lib.sh
 411                 ;;
 412         (*)
 413                 cf_cv_ar_flags=unknown
 414                 for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 415                 do
 416
 417                         # check if $ARFLAGS already contains this choice
 418                         if test "x$ARFLAGS" != "x" ; then
 419                                 cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 420                                 if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 421                                         cf_cv_ar_flags=
 422                                         break
 423                                 fi
 424                         fi
 425
 426                         rm -f conftest.$ac_cv_objext
 427                         rm -f conftest.a
 428
 429                         cat >conftest.$ac_ext <<EOF
 430 #line __oline__ "configure"
 431 int     testdata[[3]] = { 123, 456, 789 };
 432 EOF
 433                         if AC_TRY_EVAL(ac_compile) ; then
 434                                 echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 435                                 $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 436                                 if test -f conftest.a ; then
 437                                         cf_cv_ar_flags=$cf_ar_flags
 438                                         break
 439                                 fi
 440                         else
 441                                 CF_VERBOSE(cannot compile test-program)
 442                                 break
 443                         fi
 444                 done
 445                 rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 446                 ;;
 447         esac
 448 ])
 449
 450 if test -n "$ARFLAGS" ; then
 451         if test -n "$cf_cv_ar_flags" ; then
 452                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 453         fi
 454 else
 455         ARFLAGS=$cf_cv_ar_flags
 456 fi
 457
 458 AC_SUBST(ARFLAGS)
 459 ])
 460 dnl ---------------------------------------------------------------------------
 461 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
 462 dnl -----------
 463 dnl If we're cross-compiling, allow the user to override the tools and their
 464 dnl options.  The configure script is oriented toward identifying the host
 465 dnl compiler, etc., but we need a build compiler to generate parts of the
 466 dnl source.
 467 dnl
 468 dnl $1 = default for $CPPFLAGS
 469 dnl $2 = default for $LIBS
 470 AC_DEFUN([CF_BUILD_CC],[
 471 CF_ACVERSION_CHECK(2.52,,
 472         [AC_REQUIRE([CF_PROG_EXT])])
 473 if test "$cross_compiling" = yes ; then
 474
 475         # defaults that we might want to override
 476         : ${BUILD_CFLAGS:=''}
 477         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 478         : ${BUILD_LDFLAGS:=''}
 479         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 480         : ${BUILD_EXEEXT:='$x'}
 481         : ${BUILD_OBJEXT:='o'}
 482
 483         AC_ARG_WITH(build-cc,
 484                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 485                 [BUILD_CC="$withval"],
 486                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 487         AC_MSG_CHECKING(for native build C compiler)
 488         AC_MSG_RESULT($BUILD_CC)
 489
 490         AC_MSG_CHECKING(for native build C preprocessor)
 491         AC_ARG_WITH(build-cpp,
 492                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 493                 [BUILD_CPP="$withval"],
 494                 [BUILD_CPP='${BUILD_CC} -E'])
 495         AC_MSG_RESULT($BUILD_CPP)
 496
 497         AC_MSG_CHECKING(for native build C flags)
 498         AC_ARG_WITH(build-cflags,
 499                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 500                 [BUILD_CFLAGS="$withval"])
 501         AC_MSG_RESULT($BUILD_CFLAGS)
 502
 503         AC_MSG_CHECKING(for native build C preprocessor-flags)
 504         AC_ARG_WITH(build-cppflags,
 505                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 506                 [BUILD_CPPFLAGS="$withval"])
 507         AC_MSG_RESULT($BUILD_CPPFLAGS)
 508
 509         AC_MSG_CHECKING(for native build linker-flags)
 510         AC_ARG_WITH(build-ldflags,
 511                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 512                 [BUILD_LDFLAGS="$withval"])
 513         AC_MSG_RESULT($BUILD_LDFLAGS)
 514
 515         AC_MSG_CHECKING(for native build linker-libraries)
 516         AC_ARG_WITH(build-libs,
 517                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 518                 [BUILD_LIBS="$withval"])
 519         AC_MSG_RESULT($BUILD_LIBS)
 520
 521         # this assumes we're on Unix.
 522         BUILD_EXEEXT=
 523         BUILD_OBJEXT=o
 524
 525         : ${BUILD_CC:='${CC}'}
 526
 527         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 528                 AC_MSG_ERROR([Cross-build requires two compilers.
 529 Use --with-build-cc to specify the native compiler.])
 530         fi
 531
 532 else
 533         : ${BUILD_CC:='${CC}'}
 534         : ${BUILD_CPP:='${CPP}'}
 535         : ${BUILD_CFLAGS:='${CFLAGS}'}
 536         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 537         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 538         : ${BUILD_LIBS:='${LIBS}'}
 539         : ${BUILD_EXEEXT:='$x'}
 540         : ${BUILD_OBJEXT:='o'}
 541 fi
 542
 543 AC_SUBST(BUILD_CC)
 544 AC_SUBST(BUILD_CPP)
 545 AC_SUBST(BUILD_CFLAGS)
 546 AC_SUBST(BUILD_CPPFLAGS)
 547 AC_SUBST(BUILD_LDFLAGS)
 548 AC_SUBST(BUILD_LIBS)
 549 AC_SUBST(BUILD_EXEEXT)
 550 AC_SUBST(BUILD_OBJEXT)
 551 ])dnl
 552 dnl ---------------------------------------------------------------------------
 553 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
 554 dnl ---------------
 555 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 556 dnl into CC.  This will not help with broken scripts that wrap the compiler
 557 dnl with options, but eliminates a more common category of user confusion.
 558 dnl
 559 dnl In particular, it addresses the problem of being able to run the C
 560 dnl preprocessor in a consistent manner.
 561 dnl
 562 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 563 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 564 dnl outweighs that limitation.
 565 AC_DEFUN([CF_CC_ENV_FLAGS],
 566 [
 567 # This should have been defined by AC_PROG_CC
 568 : ${CC:=cc}
 569
 570 AC_MSG_CHECKING(\$CFLAGS variable)
 571 case "x$CFLAGS" in
 572 (*-[[IUD]]*)
 573         AC_MSG_RESULT(broken)
 574         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 575         cf_flags="$CFLAGS"
 576         CFLAGS=
 577         for cf_arg in $cf_flags
 578         do
 579                 CF_ADD_CFLAGS($cf_arg)
 580         done
 581         ;;
 582 (*)
 583         AC_MSG_RESULT(ok)
 584         ;;
 585 esac
 586
 587 AC_MSG_CHECKING(\$CC variable)
 588 case "$CC" in
 589 (*[[\ \ ]]-*)
 590         AC_MSG_RESULT(broken)
 591         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 592         # humor him...
 593         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 594         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 595         CC="$cf_prog"
 596         for cf_arg in $cf_flags
 597         do
 598                 case "x$cf_arg" in
 599                 (x-[[IUDfgOW]]*)
 600                         CF_ADD_CFLAGS($cf_arg)
 601                         ;;
 602                 (*)
 603                         CC="$CC $cf_arg"
 604                         ;;
 605                 esac
 606         done
 607         CF_VERBOSE(resulting CC: '$CC')
 608         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 609         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 610         ;;
 611 (*)
 612         AC_MSG_RESULT(ok)
 613         ;;
 614 esac
 615 ])dnl
 616 dnl ---------------------------------------------------------------------------
 617 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 618 dnl ---------------
 619 dnl Determine the default configuration into which we'll install ncurses.  This
 620 dnl can be overridden by the user's command-line options.  There's two items to
 621 dnl look for:
 622 dnl     1. the prefix (e.g., /usr)
 623 dnl     2. the header files (e.g., /usr/include/ncurses)
 624 dnl We'll look for a previous installation of ncurses and use the same defaults.
 625 dnl
 626 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 627 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 628 dnl programs from a vendor's.
 629 AC_DEFUN([CF_CFG_DEFAULTS],
 630 [
 631 AC_MSG_CHECKING(for prefix)
 632 if test "x$prefix" = "xNONE" ; then
 633         case "$cf_cv_system_name" in
 634                 # non-vendor systems don't have a conflict
 635         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 636                 prefix=/usr
 637                 ;;
 638         (*)     prefix=$ac_default_prefix
 639                 ;;
 640         esac
 641 fi
 642 AC_MSG_RESULT($prefix)
 643
 644 if test "x$prefix" = "xNONE" ; then
 645 AC_MSG_CHECKING(for default include-directory)
 646 test -n "$verbose" && echo 1>&AC_FD_MSG
 647 for cf_symbol in \
 648         $includedir \
 649         $includedir/ncurses \
 650         $prefix/include \
 651         $prefix/include/ncurses \
 652         /usr/local/include \
 653         /usr/local/include/ncurses \
 654         /usr/include \
 655         /usr/include/ncurses
 656 do
 657         cf_dir=`eval echo $cf_symbol`
 658         if test -f $cf_dir/curses.h ; then
 659         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 660                 includedir="$cf_symbol"
 661                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 662                 break
 663         fi
 664         fi
 665         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 666 done
 667 AC_MSG_RESULT($includedir)
 668 fi
 669 ])dnl
 670 dnl ---------------------------------------------------------------------------
 671 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 672 dnl --------------
 673 dnl Check if we're accidentally using a cache from a different machine.
 674 dnl Derive the system name, as a check for reusing the autoconf cache.
 675 dnl
 676 dnl If we've packaged config.guess and config.sub, run that (since it does a
 677 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 678 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 679 dnl which is useful in cross-compiles.
 680 dnl
 681 dnl Note: we would use $ac_config_sub, but that is one of the places where
 682 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 683 AC_DEFUN([CF_CHECK_CACHE],
 684 [
 685 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 686         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 687         system_name="$host_os"
 688 else
 689         system_name="`(uname -s -r) 2>/dev/null`"
 690         if test -z "$system_name" ; then
 691                 system_name="`(hostname) 2>/dev/null`"
 692         fi
 693 fi
 694 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 695 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 696
 697 test -z "$system_name" && system_name="$cf_cv_system_name"
 698 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 699
 700 if test ".$system_name" != ".$cf_cv_system_name" ; then
 701         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 702         AC_MSG_ERROR("Please remove config.cache and try again.")
 703 fi
 704 ])dnl
 705 dnl ---------------------------------------------------------------------------
 706 dnl CF_CHECK_GNAT_VERSION version: 3 updated: 2020/05/23 19:39:36
 707 dnl ---------------------
 708 AC_DEFUN([CF_CHECK_GNAT_VERSION],
 709 [
 710 AC_REQUIRE([CF_GNAT_VERSION])
 711 case $cf_cv_gnat_version in
 712 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
 713         cf_cv_prog_gnat_correct=yes
 714         ;;
 715 (*)
 716         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
 717         cf_cv_prog_gnat_correct=no
 718         ;;
 719 esac
 720 ])
 721 dnl ---------------------------------------------------------------------------
 722 dnl CF_CLANG_COMPILER version: 3 updated: 2020/08/28 04:10:22
 723 dnl -----------------
 724 dnl Check if the given compiler is really clang.  clang's C driver defines
 725 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 726 dnl not ignore some gcc options.
 727 dnl
 728 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 729 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 730 dnl the wrappers for gcc and g++ warnings.
 731 dnl
 732 dnl $1 = GCC (default) or GXX
 733 dnl $2 = CLANG_COMPILER (default)
 734 dnl $3 = CFLAGS (default) or CXXFLAGS
 735 AC_DEFUN([CF_CLANG_COMPILER],[
 736 ifelse([$2],,CLANG_COMPILER,[$2])=no
 737
 738 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 739         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 740         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 741         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 742         AC_TRY_COMPILE([],[
 743 #ifdef __clang__
 744 #else
 745 make an error
 746 #endif
 747 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 748 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
 749 ],[])
 750         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 751         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 752 fi
 753
 754 if test "x$CLANG_COMPILER" = "xyes" ; then
 755         CF_APPEND_TEXT(CFLAGS,-Wno-error=implicit-function-declaration)
 756 fi
 757 ])
 758 dnl ---------------------------------------------------------------------------
 759 dnl CF_CONST_X_STRING version: 4 updated: 2020/03/10 18:53:47
 760 dnl -----------------
 761 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
 762 dnl character-strings.
 763 dnl
 764 dnl It is ambiguous because the specification accommodated the pre-ANSI
 765 dnl compilers bundled by more than one vendor in lieu of providing a standard C
 766 dnl compiler other than by costly add-ons.  Because of this, the specification
 767 dnl did not take into account the use of const for telling the compiler that
 768 dnl string literals would be in readonly memory.
 769 dnl
 770 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
 771 dnl let the compiler decide how to represent Xt's strings which were #define'd.
 772 dnl That does not solve the problem of using the block of Xt's strings which
 773 dnl are compiled into the library (and is less efficient than one might want).
 774 dnl
 775 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
 776 dnl when compiling the library and compiling using the library, to tell the
 777 dnl compiler that String is const.
 778 AC_DEFUN([CF_CONST_X_STRING],
 779 [
 780 AC_REQUIRE([AC_PATH_XTRA])
 781
 782 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
 783
 784 AC_TRY_COMPILE(
 785 [
 786 #include <stdlib.h>
 787 #include <X11/Intrinsic.h>
 788 ],
 789 [String foo = malloc(1); (void)foo],[
 790
 791 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
 792         AC_TRY_COMPILE(
 793                 [
 794 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
 795 #undef  XTSTRINGDEFINES /* X11R5 and later */
 796 #include <stdlib.h>
 797 #include <X11/Intrinsic.h>
 798                 ],[String foo = malloc(1); *foo = 0],[
 799                         cf_cv_const_x_string=no
 800                 ],[
 801                         cf_cv_const_x_string=yes
 802                 ])
 803 ])
 804
 805 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
 806
 807 case $cf_cv_const_x_string in
 808 (no)
 809         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
 810         ;;
 811 (*)
 812         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
 813         ;;
 814 esac
 815
 816 ])
 817 ])dnl
 818 dnl ---------------------------------------------------------------------------
 819 dnl CF_CONST_X_STRING version: 4 updated: 2020/03/10 18:53:47
 820 dnl -----------------
 821 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
 822 dnl character-strings.
 823 dnl
 824 dnl It is ambiguous because the specification accommodated the pre-ANSI
 825 dnl compilers bundled by more than one vendor in lieu of providing a standard C
 826 dnl compiler other than by costly add-ons.  Because of this, the specification
 827 dnl did not take into account the use of const for telling the compiler that
 828 dnl string literals would be in readonly memory.
 829 dnl
 830 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
 831 dnl let the compiler decide how to represent Xt's strings which were #define'd.
 832 dnl That does not solve the problem of using the block of Xt's strings which
 833 dnl are compiled into the library (and is less efficient than one might want).
 834 dnl
 835 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
 836 dnl when compiling the library and compiling using the library, to tell the
 837 dnl compiler that String is const.
 838 AC_DEFUN([CF_CONST_X_STRING],
 839 [
 840 AC_REQUIRE([AC_PATH_XTRA])
 841
 842 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
 843
 844 AC_TRY_COMPILE(
 845 [
 846 #include <stdlib.h>
 847 #include <X11/Intrinsic.h>
 848 ],
 849 [String foo = malloc(1); (void)foo],[
 850
 851 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
 852         AC_TRY_COMPILE(
 853                 [
 854 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
 855 #undef  XTSTRINGDEFINES /* X11R5 and later */
 856 #include <stdlib.h>
 857 #include <X11/Intrinsic.h>
 858                 ],[String foo = malloc(1); *foo = 0],[
 859                         cf_cv_const_x_string=no
 860                 ],[
 861                         cf_cv_const_x_string=yes
 862                 ])
 863 ])
 864
 865 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
 866
 867 case $cf_cv_const_x_string in
 868 (no)
 869         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
 870         ;;
 871 (*)
 872         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
 873         ;;
 874 esac
 875
 876 ])
 877 ])dnl
 878 dnl ---------------------------------------------------------------------------
 879 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
 880 dnl ----------------
 881 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 882 dnl variations of ncurses' installs.
 883 dnl
 884 dnl $1 = ncurses when looking for ncurses, or is empty
 885 AC_DEFUN([CF_CURSES_HEADER],[
 886 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 887 cf_cv_ncurses_header=none
 888 for cf_header in \
 889         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
 890         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 891 do
 892 AC_TRY_COMPILE([#include <${cf_header}>],
 893         [initscr(); tgoto("?", 0,0)],
 894         [cf_cv_ncurses_header=$cf_header; break],[])
 895 done
 896 ])
 897
 898 if test "$cf_cv_ncurses_header" = none ; then
 899         AC_MSG_ERROR(No curses header-files found)
 900 fi
 901
 902 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 903 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 904 ])dnl
 905 dnl ---------------------------------------------------------------------------
 906 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
 907 dnl ----------
 908 dnl "dirname" is not portable, so we fake it with a shell script.
 909 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
 910 dnl ---------------------------------------------------------------------------
 911 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
 912 dnl ---------------
 913 dnl You can always use "make -n" to see the actual options, but it's hard to
 914 dnl pick out/analyze warning messages when the compile-line is long.
 915 dnl
 916 dnl Sets:
 917 dnl     ECHO_LT - symbol to control if libtool is verbose
 918 dnl     ECHO_LD - symbol to prefix "cc -o" lines
 919 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
 920 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
 921 dnl     ECHO_CC - symbol to put before any "cc" line
 922 dnl
 923 AC_DEFUN([CF_DISABLE_ECHO],[
 924 AC_MSG_CHECKING(if you want to see long compiling messages)
 925 CF_ARG_DISABLE(echo,
 926         [  --disable-echo          do not display "compiling" commands],
 927         [
 928         ECHO_LT='--silent'
 929         ECHO_LD='@echo linking [$]@;'
 930         RULE_CC='@echo compiling [$]<'
 931         SHOW_CC='@echo compiling [$]@'
 932         ECHO_CC='@'
 933 ],[
 934         ECHO_LT=''
 935         ECHO_LD=''
 936         RULE_CC=''
 937         SHOW_CC=''
 938         ECHO_CC=''
 939 ])
 940 AC_MSG_RESULT($enableval)
 941 AC_SUBST(ECHO_LT)
 942 AC_SUBST(ECHO_LD)
 943 AC_SUBST(RULE_CC)
 944 AC_SUBST(SHOW_CC)
 945 AC_SUBST(ECHO_CC)
 946 ])dnl
 947 dnl ---------------------------------------------------------------------------
 948 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
 949 dnl ------------------------
 950 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
 951 AC_MSG_CHECKING(if we want to use GNAT projects)
 952 CF_ARG_DISABLE(gnat-projects,
 953         [  --disable-gnat-projects test: disable GNAT projects even if usable],
 954         [enable_gnat_projects=no],
 955         [enable_gnat_projects=yes])
 956 AC_MSG_RESULT($enable_gnat_projects)
 957 ])dnl
 958 dnl ---------------------------------------------------------------------------
 959 dnl CF_ENABLE_BROKEN_LINKER version: 1 updated: 2020/02/08 15:59:30
 960 dnl -----------------------
 961 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
 962 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
 963 dnl an unconditional feature.
 964 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
 965
 966 AC_MSG_CHECKING(if you want broken-linker support code)
 967 AC_ARG_ENABLE(broken_linker,
 968         [  --enable-broken_linker  compile with broken-linker support code],
 969         [with_broken_linker=$enableval],
 970         [with_broken_linker=no])
 971 AC_MSG_RESULT($with_broken_linker)
 972
 973 : ${BROKEN_LINKER:=0}
 974 if test "x$with_broken_linker" = xyes ; then
 975         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
 976         BROKEN_LINKER=1
 977 fi
 978 AC_SUBST(BROKEN_LINKER)
 979 ])dnl
 980 dnl ---------------------------------------------------------------------------
 981 dnl CF_ENABLE_WARNINGS version: 7 updated: 2020/08/29 09:05:21
 982 dnl ------------------
 983 dnl Configure-option to enable gcc warnings
 984 dnl
 985 dnl $1 = extra options to add, if supported
 986 dnl $2 = option for checking attributes.  By default, this is done when
 987 dnl      warnings are enabled.  For other values:
 988 dnl      yes: always do this, e.g., to use in generated library-headers
 989 dnl      no: never do this
 990 AC_DEFUN([CF_ENABLE_WARNINGS],[
 991 if ( test "$GCC" = yes || test "$GXX" = yes )
 992 then
 993 CF_FIX_WARNINGS(CFLAGS)
 994 CF_FIX_WARNINGS(CPPFLAGS)
 995 CF_FIX_WARNINGS(LDFLAGS)
 996 AC_MSG_CHECKING(if you want to turn on gcc warnings)
 997 CF_ARG_ENABLE(warnings,
 998         [  --enable-warnings       test: turn on gcc compiler warnings],
 999         [with_warnings=yes],
1000         [with_warnings=no])
1001 AC_MSG_RESULT($with_warnings)
1002 if test "$with_warnings" = "yes"
1003 then
1004         ifelse($2,,[CF_GCC_ATTRIBUTES])
1005         CF_GCC_WARNINGS($1)
1006 fi
1007 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
1008 fi
1009 ])dnl
1010 dnl ---------------------------------------------------------------------------
1011 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
1012 dnl ---------------
1013 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
1014 dnl prefer a standard location, and use -L options only if we do not find the
1015 dnl library in the standard library location(s).
1016 dnl     $1 = library name
1017 dnl     $2 = library class, usually the same as library name
1018 dnl     $3 = includes
1019 dnl     $4 = code fragment to compile/link
1020 dnl     $5 = corresponding function-name
1021 dnl     $6 = flag, nonnull if failure should not cause an error-exit
1022 dnl
1023 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
1024 dnl to use a -L option.
1025 AC_DEFUN([CF_FIND_LIBRARY],
1026 [
1027         eval 'cf_cv_have_lib_'$1'=no'
1028         cf_libdir=""
1029         AC_CHECK_FUNC($5,
1030                 eval 'cf_cv_have_lib_'$1'=yes',[
1031                 cf_save_LIBS="$LIBS"
1032                 AC_MSG_CHECKING(for $5 in -l$1)
1033                 LIBS="-l$1 $LIBS"
1034                 AC_TRY_LINK([$3],[$4],
1035                         [AC_MSG_RESULT(yes)
1036                          eval 'cf_cv_have_lib_'$1'=yes'
1037                         ],
1038                         [AC_MSG_RESULT(no)
1039                         CF_LIBRARY_PATH(cf_search,$2)
1040                         for cf_libdir in $cf_search
1041                         do
1042                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1043                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1044                                 AC_TRY_LINK([$3],[$4],
1045                                         [AC_MSG_RESULT(yes)
1046                                          eval 'cf_cv_have_lib_'$1'=yes'
1047                                          break],
1048                                         [AC_MSG_RESULT(no)
1049                                          LIBS="$cf_save_LIBS"])
1050                         done
1051                         ])
1052                 ])
1053 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
1054 ifelse($6,,[
1055 if test $cf_found_library = no ; then
1056         AC_MSG_ERROR(Cannot link $1 library)
1057 fi
1058 ])
1059 ])dnl
1060 dnl ---------------------------------------------------------------------------
1061 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
1062 dnl ---------------
1063 dnl Find a library (specifically the linkage used in the code fragment),
1064 dnl searching for it if it is not already in the library path.
1065 dnl See also CF_ADD_SEARCHPATH.
1066 dnl
1067 dnl Parameters (4-on are optional):
1068 dnl     $1 = headers for library entrypoint
1069 dnl     $2 = code fragment for library entrypoint
1070 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1071 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1072 dnl     $5 = action to perform if not successful
1073 dnl     $6 = module name, if not the same as the library name
1074 dnl     $7 = extra libraries
1075 dnl
1076 dnl Sets these variables:
1077 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1078 dnl     $cf_cv_header_path_$3 - include-directory if needed
1079 dnl     $cf_cv_library_path_$3 - library-directory if needed
1080 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1081 AC_DEFUN([CF_FIND_LINKAGE],[
1082
1083 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1084 # will be set on completion of the AC_TRY_LINK below.
1085 cf_cv_header_path_$3=
1086 cf_cv_library_path_$3=
1087
1088 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1089
1090 cf_save_LIBS="$LIBS"
1091
1092 AC_TRY_LINK([$1],[$2],[
1093         cf_cv_find_linkage_$3=yes
1094         cf_cv_header_path_$3=/usr/include
1095         cf_cv_library_path_$3=/usr/lib
1096 ],[
1097
1098 LIBS="-l$3 $7 $cf_save_LIBS"
1099
1100 AC_TRY_LINK([$1],[$2],[
1101         cf_cv_find_linkage_$3=yes
1102         cf_cv_header_path_$3=/usr/include
1103         cf_cv_library_path_$3=/usr/lib
1104         cf_cv_library_file_$3="-l$3"
1105 ],[
1106         cf_cv_find_linkage_$3=no
1107         LIBS="$cf_save_LIBS"
1108
1109         CF_VERBOSE(find linkage for $3 library)
1110         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1111
1112         cf_save_CPPFLAGS="$CPPFLAGS"
1113         cf_test_CPPFLAGS="$CPPFLAGS"
1114
1115         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1116         for cf_cv_header_path_$3 in $cf_search
1117         do
1118                 if test -d $cf_cv_header_path_$3 ; then
1119                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1120                         CPPFLAGS="$cf_save_CPPFLAGS"
1121                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1122                         AC_TRY_COMPILE([$1],[$2],[
1123                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1124                                 cf_cv_find_linkage_$3=maybe
1125                                 cf_test_CPPFLAGS="$CPPFLAGS"
1126                                 break],[
1127                                 CPPFLAGS="$cf_save_CPPFLAGS"
1128                                 ])
1129                 fi
1130         done
1131
1132         if test "$cf_cv_find_linkage_$3" = maybe ; then
1133
1134                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1135
1136                 cf_save_LIBS="$LIBS"
1137                 cf_save_LDFLAGS="$LDFLAGS"
1138
1139                 ifelse([$6],,,[
1140                 CPPFLAGS="$cf_test_CPPFLAGS"
1141                 LIBS="-l$3 $7 $cf_save_LIBS"
1142                 AC_TRY_LINK([$1],[$2],[
1143                         CF_VERBOSE(... found $3 library in system)
1144                         cf_cv_find_linkage_$3=yes])
1145                         CPPFLAGS="$cf_save_CPPFLAGS"
1146                         LIBS="$cf_save_LIBS"
1147                         ])
1148
1149                 if test "$cf_cv_find_linkage_$3" != yes ; then
1150                         CF_LIBRARY_PATH(cf_search,$3)
1151                         for cf_cv_library_path_$3 in $cf_search
1152                         do
1153                                 if test -d $cf_cv_library_path_$3 ; then
1154                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1155                                         CPPFLAGS="$cf_test_CPPFLAGS"
1156                                         LIBS="-l$3 $7 $cf_save_LIBS"
1157                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1158                                         AC_TRY_LINK([$1],[$2],[
1159                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1160                                         cf_cv_find_linkage_$3=yes
1161                                         cf_cv_library_file_$3="-l$3"
1162                                         break],[
1163                                         CPPFLAGS="$cf_save_CPPFLAGS"
1164                                         LIBS="$cf_save_LIBS"
1165                                         LDFLAGS="$cf_save_LDFLAGS"
1166                                         ])
1167                                 fi
1168                         done
1169                         CPPFLAGS="$cf_save_CPPFLAGS"
1170                         LDFLAGS="$cf_save_LDFLAGS"
1171                 fi
1172
1173         else
1174                 cf_cv_find_linkage_$3=no
1175         fi
1176         ],$7)
1177 ])
1178
1179 LIBS="$cf_save_LIBS"
1180
1181 if test "$cf_cv_find_linkage_$3" = yes ; then
1182 ifelse([$4],,[
1183         CF_ADD_INCDIR($cf_cv_header_path_$3)
1184         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1185         CF_ADD_LIB($3)
1186 ],[$4])
1187 else
1188 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1189 fi
1190 ])dnl
1191 dnl ---------------------------------------------------------------------------
1192 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1193 dnl -----------------
1194 dnl make ADAFLAGS consistent with CFLAGS
1195 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1196         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1197         case "$CFLAGS" in
1198         (*-g*)
1199                 CF_ADD_ADAFLAGS(-g)
1200                 ;;
1201         esac
1202         case "$CFLAGS" in
1203         (*-O*)
1204                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1205                 CF_ADD_ADAFLAGS($cf_O_flag)
1206                 ;;
1207         esac
1208         AC_MSG_RESULT($ADAFLAGS)
1209 ])dnl
1210 dnl ---------------------------------------------------------------------------
1211 dnl CF_FIX_WARNINGS version: 2 updated: 2020/08/28 15:08:28
1212 dnl ---------------
1213 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
1214 dnl "-Werror" flags can interfere with configure-checks.  Those go into
1215 dnl EXTRA_CFLAGS.
1216 dnl
1217 dnl $1 = variable name to repair
1218 define([CF_FIX_WARNINGS],[
1219 if ( test "$GCC" = yes || test "$GXX" = yes )
1220 then
1221         case [$]$1 in
1222         (*-Werror=*)
1223                 CF_VERBOSE(repairing $1: [$]$1)
1224                 cf_temp_flags=
1225                 for cf_temp_scan in [$]$1
1226                 do
1227                         case "x$cf_temp_scan" in
1228                         (x-Werror=*)
1229                                 CF_APPEND_TEXT(EXTRA_CFLAGS,"$cf_temp_scan")
1230                                 ;;
1231                         (*)
1232                                 CF_APPEND_TEXT(cf_temp_flags,"$cf_temp_scan")
1233                                 ;;
1234                         esac
1235                 done
1236                 $1="$cf_temp_flags"
1237                 CF_VERBOSE(... fixed [$]$1)
1238                 CF_VERBOSE(... extra $EXTRA_CFLAGS)
1239                 ;;
1240         esac
1241 fi
1242 AC_SUBST(EXTRA_CFLAGS)
1243 ])dnl
1244 dnl ---------------------------------------------------------------------------
1245 dnl CF_GCC_ATTRIBUTES version: 19 updated: 2020/08/29 09:05:21
1246 dnl -----------------
1247 dnl Test for availability of useful gcc __attribute__ directives to quiet
1248 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1249 dnl to documentation, unrecognized directives cause older compilers to barf.
1250 AC_DEFUN([CF_GCC_ATTRIBUTES],
1251 [
1252 if ( test "$GCC" = yes || test "$GXX" = yes )
1253 then
1254 cat > conftest.i <<EOF
1255 #ifndef GCC_PRINTF
1256 #define GCC_PRINTF 0
1257 #endif
1258 #ifndef GCC_SCANF
1259 #define GCC_SCANF 0
1260 #endif
1261 #ifndef GCC_NORETURN
1262 #define GCC_NORETURN /* nothing */
1263 #endif
1264 #ifndef GCC_UNUSED
1265 #define GCC_UNUSED /* nothing */
1266 #endif
1267 EOF
1268 if test "$GCC" = yes
1269 then
1270         AC_CHECKING([for $CC __attribute__ directives])
1271 cat > conftest.$ac_ext <<EOF
1272 #line __oline__ "${as_me:-configure}"
1273 #include "confdefs.h"
1274 #include "conftest.h"
1275 #include "conftest.i"
1276 #if     GCC_PRINTF
1277 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1278 #else
1279 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1280 #endif
1281 #if     GCC_SCANF
1282 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1283 #else
1284 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1285 #endif
1286 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1287 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1288 extern void foo(void) GCC_NORETURN;
1289 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
1290 EOF
1291         cf_printf_attribute=no
1292         cf_scanf_attribute=no
1293         for cf_attribute in scanf printf unused noreturn
1294         do
1295                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1296                 cf_directive="__attribute__(($cf_attribute))"
1297                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1298
1299                 case $cf_attribute in
1300                 (printf)
1301                         cf_printf_attribute=yes
1302                         cat >conftest.h <<EOF
1303 #define GCC_$cf_ATTRIBUTE 1
1304 EOF
1305                         ;;
1306                 (scanf)
1307                         cf_scanf_attribute=yes
1308                         cat >conftest.h <<EOF
1309 #define GCC_$cf_ATTRIBUTE 1
1310 EOF
1311                         ;;
1312                 (*)
1313                         cat >conftest.h <<EOF
1314 #define GCC_$cf_ATTRIBUTE $cf_directive
1315 EOF
1316                         ;;
1317                 esac
1318
1319                 if AC_TRY_EVAL(ac_compile); then
1320                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1321                         cat conftest.h >>confdefs.h
1322                         case $cf_attribute in
1323                         (noreturn)
1324                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1325                                 ;;
1326                         (printf)
1327                                 cf_value='/* nothing */'
1328                                 if test "$cf_printf_attribute" != no ; then
1329                                         cf_value='__attribute__((format(printf,fmt,var)))'
1330                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1331                                 fi
1332                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1333                                 ;;
1334                         (scanf)
1335                                 cf_value='/* nothing */'
1336                                 if test "$cf_scanf_attribute" != no ; then
1337                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1338                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1339                                 fi
1340                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1341                                 ;;
1342                         (unused)
1343                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1344                                 ;;
1345                         esac
1346                 fi
1347         done
1348 else
1349         fgrep define conftest.i >>confdefs.h
1350 fi
1351 rm -rf conftest*
1352 fi
1353 ])dnl
1354 dnl ---------------------------------------------------------------------------
1355 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
1356 dnl --------------
1357 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
1358 dnl compatible), attempt to determine if icc/clang is actually used.
1359 AC_DEFUN([CF_GCC_VERSION],[
1360 AC_REQUIRE([AC_PROG_CC])
1361 GCC_VERSION=none
1362 if test "$GCC" = yes ; then
1363         AC_MSG_CHECKING(version of $CC)
1364         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1365         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1366         AC_MSG_RESULT($GCC_VERSION)
1367 fi
1368 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1369 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1370 ])dnl
1371 dnl ---------------------------------------------------------------------------
1372 dnl CF_GCC_WARNINGS version: 38 updated: 2020/08/28 15:08:28
1373 dnl ---------------
1374 dnl Check if the compiler supports useful warning options.  There's a few that
1375 dnl we don't use, simply because they're too noisy:
1376 dnl
1377 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1378 dnl     -Winline (usually not worthwhile)
1379 dnl     -Wredundant-decls (system headers make this too noisy)
1380 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1381 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1382 dnl             is enabled for ncurses using "--enable-const".
1383 dnl     -pedantic
1384 dnl
1385 dnl Parameter:
1386 dnl     $1 is an optional list of gcc warning flags that a particular
1387 dnl             application might want to use, e.g., "no-unused" for
1388 dnl             -Wno-unused
1389 dnl Special:
1390 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1391 dnl
1392 AC_DEFUN([CF_GCC_WARNINGS],
1393 [
1394 AC_REQUIRE([CF_GCC_VERSION])
1395 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
1396 cat > conftest.$ac_ext <<EOF
1397 #line __oline__ "${as_me:-configure}"
1398 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1399 EOF
1400 if test "$INTEL_COMPILER" = yes
1401 then
1402 # The "-wdXXX" options suppress warnings:
1403 # remark #1419: external declaration in primary source file
1404 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1405 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1406 # remark #193: zero used for undefined preprocessing identifier
1407 # remark #593: variable "curs_sb_left_arrow" was set but never used
1408 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1409 # remark #869: parameter "tw" was never referenced
1410 # remark #981: operands are evaluated in unspecified order
1411 # warning #279: controlling expression is constant
1412
1413         AC_CHECKING([for $CC warning options])
1414         cf_save_CFLAGS="$CFLAGS"
1415         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
1416         for cf_opt in \
1417                 wd1419 \
1418                 wd1683 \
1419                 wd1684 \
1420                 wd193 \
1421                 wd593 \
1422                 wd279 \
1423                 wd810 \
1424                 wd869 \
1425                 wd981
1426         do
1427                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1428                 if AC_TRY_EVAL(ac_compile); then
1429                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1430                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1431                 fi
1432         done
1433         CFLAGS="$cf_save_CFLAGS"
1434 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
1435 then
1436         AC_CHECKING([for $CC warning options])
1437         cf_save_CFLAGS="$CFLAGS"
1438         cf_warn_CONST=""
1439         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1440         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1441         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1442         for cf_opt in W Wall \
1443                 Wbad-function-cast \
1444                 Wcast-align \
1445                 Wcast-qual \
1446                 Wdeclaration-after-statement \
1447                 Wextra \
1448                 Winline \
1449                 Wmissing-declarations \
1450                 Wmissing-prototypes \
1451                 Wnested-externs \
1452                 Wpointer-arith \
1453                 Wshadow \
1454                 Wstrict-prototypes \
1455                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
1456         do
1457                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1458                 if AC_TRY_EVAL(ac_compile); then
1459                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1460                         case $cf_opt in
1461                         (Winline)
1462                                 case $GCC_VERSION in
1463                                 ([[34]].*)
1464                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1465                                         continue;;
1466                                 esac
1467                                 ;;
1468                         (Wpointer-arith)
1469                                 case $GCC_VERSION in
1470                                 ([[12]].*)
1471                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1472                                         continue;;
1473                                 esac
1474                                 ;;
1475                         esac
1476                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1477                 fi
1478         done
1479         CFLAGS="$cf_save_CFLAGS"
1480 fi
1481 rm -rf conftest*
1482
1483 AC_SUBST(EXTRA_CFLAGS)
1484 ])dnl
1485 dnl ---------------------------------------------------------------------------
1486 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
1487 dnl -----------------
1488 AC_DEFUN([CF_GNATPREP_OPT_T],[
1489 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
1490 cf_cv_gnatprep_opt_t=no
1491 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
1492 ])
1493 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
1494 AC_SUBST(GNATPREP_OPTS)
1495 ])dnl
1496 dnl ---------------------------------------------------------------------------
1497 dnl CF_GNAT_GENERICS version: 6 updated: 2020/07/04 19:30:27
1498 dnl ----------------
1499 AC_DEFUN([CF_GNAT_GENERICS],
1500 [
1501 AC_REQUIRE([CF_GNAT_VERSION])
1502
1503 AC_MSG_CHECKING(if GNAT supports generics)
1504 case $cf_cv_gnat_version in
1505 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
1506         cf_gnat_generics=yes
1507         ;;
1508 (*)
1509         cf_gnat_generics=no
1510         ;;
1511 esac
1512 AC_MSG_RESULT($cf_gnat_generics)
1513
1514 if test "$cf_gnat_generics" = yes
1515 then
1516         cf_compile_generics=generics
1517         cf_generic_objects="\${GENOBJS}"
1518 else
1519         cf_compile_generics=
1520         cf_generic_objects=
1521 fi
1522
1523 AC_SUBST(cf_compile_generics)
1524 AC_SUBST(cf_generic_objects)
1525 ])dnl
1526 dnl ---------------------------------------------------------------------------
1527 dnl CF_GNAT_PROJECTS version: 10 updated: 2019/12/31 08:53:54
1528 dnl ----------------
1529 dnl GNAT projects are configured with ".gpr" project files.
1530 dnl GNAT libraries are a further development, using the project feature.
1531 AC_DEFUN([CF_GNAT_PROJECTS],
1532 [
1533 AC_REQUIRE([CF_GNAT_VERSION])
1534 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
1535
1536 cf_gnat_libraries=no
1537 cf_gnat_projects=no
1538
1539 if test "$enable_gnat_projects" != no ; then
1540 AC_MSG_CHECKING(if GNAT supports project files)
1541 case $cf_cv_gnat_version in
1542 (3.[[0-9]]*)
1543         ;;
1544 (*)
1545         case $cf_cv_system_name in
1546         (cygwin*|msys*)
1547                 ;;
1548         (*)
1549                 rm -rf conftest* *~conftest*
1550                 if mkdir conftest.src conftest.bin conftest.lib
1551                 then
1552                         cd conftest.src
1553                         rm -rf conftest* *~conftest*
1554                         cat >>library.gpr <<CF_EOF
1555 project Library is
1556   Kind := External ("LIB_KIND");
1557   for Library_Name use "ConfTest";
1558   for Object_Dir use ".";
1559   for Library_ALI_Dir use External("LIBRARY_DIR");
1560   for Library_Version use External ("SONAME");
1561   for Library_Kind use Kind;
1562   for Library_Dir use External("BUILD_DIR");
1563   Source_Dir := External ("SOURCE_DIR");
1564   for Source_Dirs use (Source_Dir);
1565 end Library;
1566 CF_EOF
1567                         cat >>confpackage.ads <<CF_EOF
1568 package ConfPackage is
1569    procedure conftest;
1570 end ConfPackage;
1571 CF_EOF
1572                         cat >>confpackage.adb <<CF_EOF
1573 with Text_IO;
1574 package body ConfPackage is
1575    procedure conftest is
1576    begin
1577       Text_IO.Put ("Hello World");
1578       Text_IO.New_Line;
1579    end conftest;
1580 end ConfPackage;
1581 CF_EOF
1582                         if ( $cf_ada_make $ADAFLAGS \
1583                                         -Plibrary.gpr \
1584                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
1585                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
1586                                         -XSOURCE_DIR=`pwd` \
1587                                         -XSONAME=libConfTest.so.1 \
1588                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1589                                 cf_gnat_projects=yes
1590                         fi
1591                         cd ..
1592                 fi
1593                 if test -f conftest.lib/confpackage.ali
1594                 then
1595                         cf_gnat_libraries=yes
1596                 fi
1597                 rm -rf conftest* *~conftest*
1598                 ;;
1599         esac
1600         ;;
1601 esac
1602 AC_MSG_RESULT($cf_gnat_projects)
1603 fi # enable_gnat_projects
1604
1605 if test $cf_gnat_projects = yes
1606 then
1607         AC_MSG_CHECKING(if GNAT supports libraries)
1608         AC_MSG_RESULT($cf_gnat_libraries)
1609 fi
1610
1611 if test "$cf_gnat_projects" = yes
1612 then
1613         USE_OLD_MAKERULES="#"
1614         USE_GNAT_PROJECTS=""
1615 else
1616         USE_OLD_MAKERULES=""
1617         USE_GNAT_PROJECTS="#"
1618 fi
1619
1620 if test "$cf_gnat_libraries" = yes
1621 then
1622         USE_GNAT_LIBRARIES=""
1623 else
1624         USE_GNAT_LIBRARIES="#"
1625 fi
1626
1627 AC_SUBST(USE_OLD_MAKERULES)
1628 AC_SUBST(USE_GNAT_PROJECTS)
1629 AC_SUBST(USE_GNAT_LIBRARIES)
1630 ])dnl
1631 dnl ---------------------------------------------------------------------------
1632 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
1633 dnl --------------
1634 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1635 dnl is noted that gnat may compile a tasking unit even for configurations which
1636 dnl fail at runtime.
1637 AC_DEFUN([CF_GNAT_SIGINT],[
1638 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1639 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1640
1641 package ConfTest is
1642
1643    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1644    pragma Unreserve_All_Interrupts;
1645    pragma Warnings (On);
1646
1647    protected Process is
1648       procedure Stop;
1649       function Continue return Boolean;
1650       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1651    private
1652       Done : Boolean := False;
1653    end Process;
1654
1655 end ConfTest;],
1656 [package body ConfTest is
1657    protected body Process is
1658       procedure Stop is
1659       begin
1660          Done := True;
1661       end Stop;
1662       function Continue return Boolean is
1663       begin
1664          return not Done;
1665       end Continue;
1666    end Process;
1667 end ConfTest;],
1668         [cf_cv_gnat_sigint=yes],
1669         [cf_cv_gnat_sigint=no])])
1670
1671 if test $cf_cv_gnat_sigint = yes ; then
1672         USE_GNAT_SIGINT=""
1673 else
1674         USE_GNAT_SIGINT="#"
1675 fi
1676 AC_SUBST(USE_GNAT_SIGINT)
1677 ])dnl
1678 dnl ---------------------------------------------------------------------------
1679 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
1680 dnl ----------------
1681 dnl Verify that a test program compiles/links with GNAT.
1682 dnl $cf_ada_make is set to the program that compiles/links
1683 dnl $ADAFLAGS may be set to the GNAT flags.
1684 dnl
1685 dnl $1 is the text of the spec
1686 dnl $2 is the text of the body
1687 dnl $3 is the shell command to execute if successful
1688 dnl $4 is the shell command to execute if not successful
1689 AC_DEFUN([CF_GNAT_TRY_LINK],
1690 [
1691 rm -rf conftest* *~conftest*
1692 cat >>conftest.ads <<CF_EOF
1693 $1
1694 CF_EOF
1695 cat >>conftest.adb <<CF_EOF
1696 $2
1697 CF_EOF
1698 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1699 ifelse($3,,      :,[      $3])
1700 ifelse($4,,,[else
1701    $4])
1702 fi
1703 rm -rf conftest* *~conftest*
1704 ])dnl
1705 dnl ---------------------------------------------------------------------------
1706 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
1707 dnl ---------------
1708 dnl Verify that a test program compiles and runs with GNAT
1709 dnl $cf_ada_make is set to the program that compiles/links
1710 dnl $ADAFLAGS may be set to the GNAT flags.
1711 dnl
1712 dnl $1 is the text of the spec
1713 dnl $2 is the text of the body
1714 dnl $3 is the shell command to execute if successful
1715 dnl $4 is the shell command to execute if not successful
1716 AC_DEFUN([CF_GNAT_TRY_RUN],
1717 [
1718 rm -rf conftest* *~conftest*
1719 cat >>conftest.ads <<CF_EOF
1720 $1
1721 CF_EOF
1722 cat >>conftest.adb <<CF_EOF
1723 $2
1724 CF_EOF
1725 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1726    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1727 ifelse($3,,      :,[      $3])
1728 ifelse($4,,,[   else
1729       $4])
1730    fi
1731 ifelse($4,,,[else
1732    $4])
1733 fi
1734 rm -rf conftest* *~conftest*
1735 ])dnl
1736 dnl ---------------------------------------------------------------------------
1737 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
1738 dnl ---------------
1739 dnl $1 = cache variable to update
1740 dnl $2 = program name
1741 dnl Verify version of GNAT or related tool
1742 AC_DEFUN([CF_GNAT_VERSION],
1743 [
1744 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
1745 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
1746         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1747         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1748 ])
1749 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
1750 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
1751 ])dnl
1752 dnl ---------------------------------------------------------------------------
1753 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
1754 dnl -------------
1755 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1756 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1757 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1758 dnl since it is interwoven with GNU extensions.
1759 dnl
1760 dnl Well, yes we could work around it...
1761 dnl
1762 dnl Parameters:
1763 dnl     $1 is the nominal value for _XOPEN_SOURCE
1764 AC_DEFUN([CF_GNU_SOURCE],
1765 [
1766 cf_gnu_xopen_source=ifelse($1,,500,$1)
1767
1768 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
1769 AC_TRY_COMPILE([#include <sys/types.h>],[
1770         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
1771                 return 0;
1772         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
1773                 return 0;
1774         #else
1775         #       error not GNU C library
1776         #endif],
1777         [cf_cv_gnu_library=yes],
1778         [cf_cv_gnu_library=no])
1779 ])
1780
1781 if test x$cf_cv_gnu_library = xyes; then
1782
1783         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
1784         # was changed to help a little.  newlib incorporated the change about 4
1785         # years later.
1786         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
1787                 cf_save="$CPPFLAGS"
1788                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1789                 AC_TRY_COMPILE([#include <sys/types.h>],[
1790                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
1791                                 return 0;
1792                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
1793                                 return 0;
1794                         #else
1795                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
1796                         #endif],
1797                         [cf_cv_gnu_library_219=yes],
1798                         [cf_cv_gnu_library_219=no])
1799                 CPPFLAGS="$cf_save"
1800         ])
1801
1802         if test "x$cf_cv_gnu_library_219" = xyes; then
1803                 cf_save="$CPPFLAGS"
1804                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
1805                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
1806                         AC_TRY_COMPILE([
1807                                 #include <limits.h>
1808                                 #include <sys/types.h>
1809                                 ],[
1810                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
1811                                         return 0;
1812                                 #else
1813                                 #       error GNU C library is too old
1814                                 #endif],
1815                                 [cf_cv_gnu_dftsrc_219=yes],
1816                                 [cf_cv_gnu_dftsrc_219=no])
1817                         ])
1818                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
1819         else
1820                 cf_cv_gnu_dftsrc_219=maybe
1821         fi
1822
1823         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
1824
1825                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1826                 AC_TRY_COMPILE([#include <sys/types.h>],[
1827                         #ifndef _XOPEN_SOURCE
1828                         #error  expected _XOPEN_SOURCE to be defined
1829                         #endif],
1830                         [cf_cv_gnu_source=no],
1831                         [cf_save="$CPPFLAGS"
1832                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
1833                          AC_TRY_COMPILE([#include <sys/types.h>],[
1834                                 #ifdef _XOPEN_SOURCE
1835                                 #error  expected _XOPEN_SOURCE to be undefined
1836                                 #endif],
1837                                 [cf_cv_gnu_source=no],
1838                                 [cf_cv_gnu_source=yes])
1839                         CPPFLAGS="$cf_save"
1840                         ])
1841                 ])
1842
1843                 if test "$cf_cv_gnu_source" = yes
1844                 then
1845                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
1846                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
1847                         AC_TRY_COMPILE([#include <sys/types.h>],[
1848                                 #ifdef _DEFAULT_SOURCE
1849                                 #error  expected _DEFAULT_SOURCE to be undefined
1850                                 #endif],
1851                                 [cf_cv_default_source=no],
1852                                 [cf_cv_default_source=yes])
1853                         ])
1854                         if test "$cf_cv_default_source" = yes
1855                         then
1856                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1857                         fi
1858                 fi
1859         fi
1860
1861 fi
1862 ])dnl
1863 dnl ---------------------------------------------------------------------------
1864 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
1865 dnl --------------
1866 dnl Construct a search-list of directories for a nonstandard header-file
1867 dnl
1868 dnl Parameters
1869 dnl     $1 = the variable to return as result
1870 dnl     $2 = the package name
1871 AC_DEFUN([CF_HEADER_PATH],
1872 [
1873 $1=
1874
1875 # collect the current set of include-directories from compiler flags
1876 cf_header_path_list=""
1877 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1878         for cf_header_path in $CPPFLAGS $CFLAGS
1879         do
1880                 case $cf_header_path in
1881                 (-I*)
1882                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1883                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1884                         cf_header_path_list="$cf_header_path_list [$]$1"
1885                         ;;
1886                 esac
1887         done
1888 fi
1889
1890 # add the variations for the package we are looking for
1891 CF_SUBDIR_PATH($1,$2,include)
1892
1893 test "$includedir" != NONE && \
1894 test "$includedir" != "/usr/include" && \
1895 test -d "$includedir" && {
1896         test -d $includedir &&    $1="[$]$1 $includedir"
1897         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1898 }
1899
1900 test "$oldincludedir" != NONE && \
1901 test "$oldincludedir" != "/usr/include" && \
1902 test -d "$oldincludedir" && {
1903         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1904         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1905 }
1906
1907 $1="[$]$1 $cf_header_path_list"
1908 ])dnl
1909 dnl ---------------------------------------------------------------------------
1910 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
1911 dnl ---------------
1912 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1913 AC_DEFUN([CF_HELP_MESSAGE],
1914 [CF_ACVERSION_CHECK(2.53,[],[
1915 AC_DIVERT_HELP($1)])dnl
1916 ])dnl
1917 dnl ---------------------------------------------------------------------------
1918 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
1919 dnl ---------------
1920 dnl Construct the list of include-options according to whether we're building
1921 dnl in the source directory or using '--srcdir=DIR' option.
1922 AC_DEFUN([CF_INCLUDE_DIRS],
1923 [
1924 if test "$srcdir" != "."; then
1925         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
1926 fi
1927 CPPFLAGS="-I../include $CPPFLAGS"
1928 if test "$srcdir" != "."; then
1929         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
1930 fi
1931 CPPFLAGS="-I. $CPPFLAGS"
1932 AC_SUBST(CPPFLAGS)
1933 ])dnl
1934 dnl ---------------------------------------------------------------------------
1935 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
1936 dnl ---------------
1937 dnl prompt for/fill-in useful install-program options
1938 AC_DEFUN([CF_INSTALL_OPTS],
1939 [
1940 CF_INSTALL_OPT_S
1941 CF_INSTALL_OPT_P
1942 CF_INSTALL_OPT_O
1943 ])dnl
1944 dnl ---------------------------------------------------------------------------
1945 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
1946 dnl ----------------
1947 dnl Almost all "install" programs default to the current user's ownership.
1948 dnl Almost - MINIX is an exception.
1949 AC_DEFUN([CF_INSTALL_OPT_O],
1950 [
1951 AC_MSG_CHECKING(if install needs to be told about ownership)
1952 case `$ac_config_guess` in
1953 (*minix)
1954         with_install_o=yes
1955         ;;
1956 (*)
1957         with_install_o=no
1958         ;;
1959 esac
1960
1961 AC_MSG_RESULT($with_install_o)
1962 if test "x$with_install_o" = xyes
1963 then
1964         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
1965 else
1966         INSTALL_OPT_O=
1967 fi
1968
1969 AC_SUBST(INSTALL_OPT_O)
1970 ])dnl
1971 dnl ---------------------------------------------------------------------------
1972 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
1973 dnl ----------------
1974 dnl Some install-programs accept a "-p" option to preserve file modification
1975 dnl timestamps.  That can be useful as an install option, as well as a way to
1976 dnl avoid the need for ranlib after copying a static archive.
1977 AC_DEFUN([CF_INSTALL_OPT_P],
1978 [
1979 : ${INSTALL:=install}
1980 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
1981         rm -rf conftest*
1982         date >conftest.in
1983         mkdir conftest.out
1984         sleep 3
1985         if $INSTALL -p conftest.in conftest.out 2>/dev/null
1986         then
1987                 if test -f conftest.out/conftest.in
1988                 then
1989                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
1990                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
1991                         if test -s conftest.err
1992                         then
1993                                 cf_cv_install_p=no
1994                         else
1995                                 cf_cv_install_p=yes
1996                         fi
1997                 else
1998                         cf_cv_install_p=no
1999                 fi
2000         else
2001                 cf_cv_install_p=no
2002         fi
2003         rm -rf conftest*
2004 ])
2005 ])dnl
2006 dnl ---------------------------------------------------------------------------
2007 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
2008 dnl ----------------
2009 dnl By default, we should strip executables which are installed, but leave the
2010 dnl ability to suppress that for unit-testing.
2011 AC_DEFUN([CF_INSTALL_OPT_S],
2012 [
2013 AC_MSG_CHECKING(if you want to install stripped executables)
2014 CF_ARG_DISABLE(stripping,
2015         [  --disable-stripping     do not strip (debug info) installed executables],
2016         [with_stripping=no],
2017         [with_stripping=yes])
2018 AC_MSG_RESULT($with_stripping)
2019
2020 if test "$with_stripping" = yes
2021 then
2022         INSTALL_OPT_S="-s"
2023 else
2024         INSTALL_OPT_S=
2025 fi
2026 AC_SUBST(INSTALL_OPT_S)
2027 ])dnl
2028 dnl ---------------------------------------------------------------------------
2029 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
2030 dnl -----------------
2031 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2032 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2033 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2034 dnl
2035 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2036 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2037 dnl the wrappers for gcc and g++ warnings.
2038 dnl
2039 dnl $1 = GCC (default) or GXX
2040 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2041 dnl $3 = CFLAGS (default) or CXXFLAGS
2042 AC_DEFUN([CF_INTEL_COMPILER],[
2043 AC_REQUIRE([AC_CANONICAL_HOST])
2044 ifelse([$2],,INTEL_COMPILER,[$2])=no
2045
2046 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2047         case $host_os in
2048         (linux*|gnu*)
2049                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2050                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2051                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2052                 AC_TRY_COMPILE([],[
2053 #ifdef __INTEL_COMPILER
2054 #else
2055 make an error
2056 #endif
2057 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2058 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2059 ],[])
2060                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2061                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2062                 ;;
2063         esac
2064 fi
2065 ])dnl
2066 dnl ---------------------------------------------------------------------------
2067 dnl CF_LARGEFILE version: 12 updated: 2020/03/19 20:23:48
2068 dnl ------------
2069 dnl Add checks for large file support.
2070 AC_DEFUN([CF_LARGEFILE],[
2071 ifdef([AC_FUNC_FSEEKO],[
2072         AC_SYS_LARGEFILE
2073         if test "$enable_largefile" != no ; then
2074         AC_FUNC_FSEEKO
2075
2076         # Normally we would collect these definitions in the config.h,
2077         # but (like _XOPEN_SOURCE), some environments rely on having these
2078         # defined before any of the system headers are included.  Another
2079         # case comes up with C++, e.g., on AIX the compiler compiles the
2080         # header files by themselves before looking at the body files it is
2081         # told to compile.  For ncurses, those header files do not include
2082         # the config.h
2083         if test "$ac_cv_sys_large_files" != no
2084         then
2085                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
2086         fi
2087         if test "$ac_cv_sys_largefile_source" != no
2088         then
2089                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
2090         fi
2091         if test "$ac_cv_sys_file_offset_bits" != no
2092         then
2093                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
2094         fi
2095
2096         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2097                 AC_TRY_COMPILE([
2098 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
2099 #include <sys/types.h>
2100 #include <dirent.h>
2101                 ],[
2102                 /* if transitional largefile support is setup, this is true */
2103                 extern struct dirent64 * readdir(DIR *);
2104                 struct dirent64 *x = readdir((DIR *)0);
2105                 struct dirent *y = readdir((DIR *)0);
2106                 int z = x - y;
2107                 (void)z;
2108                 ],
2109                 [cf_cv_struct_dirent64=yes],
2110                 [cf_cv_struct_dirent64=no])
2111         ])
2112         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
2113         fi
2114 ])
2115 ])
2116 dnl ---------------------------------------------------------------------------
2117 dnl CF_LD_RPATH_OPT version: 8 updated: 2018/08/18 16:36:35
2118 dnl ---------------
2119 dnl For the given system and compiler, find the compiler flags to pass to the
2120 dnl loader to use the "rpath" feature.
2121 AC_DEFUN([CF_LD_RPATH_OPT],
2122 [
2123 AC_REQUIRE([CF_CHECK_CACHE])
2124
2125 LD_RPATH_OPT=
2126 if test "x$cf_cv_enable_rpath" != xno
2127 then
2128         AC_MSG_CHECKING(for an rpath option)
2129         case $cf_cv_system_name in
2130         (irix*)
2131                 if test "$GCC" = yes; then
2132                         LD_RPATH_OPT="-Wl,-rpath,"
2133                 else
2134                         LD_RPATH_OPT="-rpath "
2135                 fi
2136                 ;;
2137         (linux*|gnu*|k*bsd*-gnu|freebsd*)
2138                 LD_RPATH_OPT="-Wl,-rpath,"
2139                 ;;
2140         (openbsd[[2-9]].*|mirbsd*)
2141                 LD_RPATH_OPT="-Wl,-rpath,"
2142                 ;;
2143         (dragonfly*)
2144                 LD_RPATH_OPT="-rpath "
2145                 ;;
2146         (netbsd*)
2147                 LD_RPATH_OPT="-Wl,-rpath,"
2148                 ;;
2149         (osf*|mls+*)
2150                 LD_RPATH_OPT="-rpath "
2151                 ;;
2152         (solaris2*)
2153                 LD_RPATH_OPT="-R"
2154                 ;;
2155         (*)
2156                 ;;
2157         esac
2158         AC_MSG_RESULT($LD_RPATH_OPT)
2159
2160         case "x$LD_RPATH_OPT" in
2161         (x-R*)
2162                 AC_MSG_CHECKING(if we need a space after rpath option)
2163                 cf_save_LIBS="$LIBS"
2164                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2165                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2166                 LIBS="$cf_save_LIBS"
2167                 AC_MSG_RESULT($cf_rpath_space)
2168                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2169                 ;;
2170         esac
2171 fi
2172 ])dnl
2173 dnl ---------------------------------------------------------------------------
2174 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
2175 dnl ---------------
2176 dnl Construct a search-list of directories for a nonstandard library-file
2177 dnl
2178 dnl Parameters
2179 dnl     $1 = the variable to return as result
2180 dnl     $2 = the package name
2181 AC_DEFUN([CF_LIBRARY_PATH],
2182 [
2183 $1=
2184 cf_library_path_list=""
2185 if test -n "${LDFLAGS}${LIBS}" ; then
2186         for cf_library_path in $LDFLAGS $LIBS
2187         do
2188                 case $cf_library_path in
2189                 (-L*)
2190                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2191                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2192                         cf_library_path_list="$cf_library_path_list [$]$1"
2193                         ;;
2194                 esac
2195         done
2196 fi
2197
2198 CF_SUBDIR_PATH($1,$2,lib)
2199
2200 $1="$cf_library_path_list [$]$1"
2201 ])dnl
2202 dnl ---------------------------------------------------------------------------
2203 dnl CF_LIB_PREFIX version: 13 updated: 2020/04/04 10:11:47
2204 dnl -------------
2205 dnl Compute the library-prefix for the given host system
2206 dnl $1 = variable to set
2207 define([CF_LIB_PREFIX],
2208 [
2209         case $cf_cv_system_name in
2210         (OS/2*|os2*)
2211                 if test "$DFT_LWR_MODEL" = libtool; then
2212                         LIB_PREFIX='lib'
2213                 else
2214                         LIB_PREFIX=''
2215                 fi
2216                 ;;
2217         (*-msvc*)
2218                 LIB_PREFIX=''
2219                 ;;
2220         (*)     LIB_PREFIX='lib'
2221                 ;;
2222         esac
2223 ifelse($1,,,[$1=$LIB_PREFIX])
2224         AC_SUBST(LIB_PREFIX)
2225 ])dnl
2226 dnl ---------------------------------------------------------------------------
2227 dnl CF_LIB_SUFFIX version: 26 updated: 2020/04/04 10:11:47
2228 dnl -------------
2229 dnl Compute the library file-suffix from the given model name
2230 dnl $1 = model name
2231 dnl $2 = variable to set (the nominal library suffix)
2232 dnl $3 = dependency variable to set (actual filename)
2233 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
2234 AC_DEFUN([CF_LIB_SUFFIX],
2235 [
2236         case X$1 in
2237         (Xlibtool)
2238                 $2='.la'
2239                 $3=[$]$2
2240                 ;;
2241         (Xdebug)
2242                 case $cf_cv_system_name in
2243                 (*-msvc*)
2244                         $2='_g.lib'
2245                         ;;
2246                 (*)
2247                         $2='_g.a'
2248                         ;;
2249                 esac
2250                 $3=[$]$2
2251                 ;;
2252         (Xprofile)
2253                 case $cf_cv_system_name in
2254                 (*-msvc*)
2255                         $2='_p.lib'
2256                         ;;
2257                 (*)
2258                         $2='_p.a'
2259                         ;;
2260                 esac
2261                 $3=[$]$2
2262                 ;;
2263         (Xshared)
2264                 case $cf_cv_system_name in
2265                 (aix[[5-7]]*)
2266                         $2='.so'
2267                         $3=[$]$2
2268                         ;;
2269                 (*-msvc*)
2270                         $2='.dll'
2271                         $3='.dll.lib'
2272                         ;;
2273                 (cygwin*|msys*|mingw*)
2274                         $2='.dll'
2275                         $3='.dll.a'
2276                         ;;
2277                 (darwin*)
2278                         $2='.dylib'
2279                         $3=[$]$2
2280                         ;;
2281                 (hpux*)
2282                         case $target in
2283                         (ia64*)
2284                                 $2='.so'
2285                                 $3=[$]$2
2286                                 ;;
2287                         (*)
2288                                 $2='.sl'
2289                                 $3=[$]$2
2290                                 ;;
2291                         esac
2292                         ;;
2293                 (*)
2294                         $2='.so'
2295                         $3=[$]$2
2296                         ;;
2297                 esac
2298                 ;;
2299         (*)
2300                 case $target in
2301                 (*-msvc*)
2302                         $2='.lib'
2303                         ;;
2304                 (*)
2305                         $2='.a'
2306                         ;;
2307                 esac
2308                 $3=[$]$2
2309                 ;;
2310         esac
2311         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
2312         then
2313                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
2314                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
2315         fi
2316 ])dnl
2317 dnl ---------------------------------------------------------------------------
2318 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
2319 dnl -----------
2320 dnl Compute the string to append to -library from the given model name
2321 dnl $1 = model name
2322 dnl $2 = variable to set
2323 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
2324 AC_DEFUN([CF_LIB_TYPE],
2325 [
2326         case $1 in
2327         (libtool) $2=''   ;;
2328         (normal)  $2=''   ;;
2329         (debug)   $2='_g' ;;
2330         (profile) $2='_p' ;;
2331         (shared)  $2=''   ;;
2332         esac
2333         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
2334 ])dnl
2335 dnl ---------------------------------------------------------------------------
2336 dnl CF_LINK_DATAONLY version: 13 updated: 2020/02/08 15:59:30
2337 dnl ----------------
2338 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
2339 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
2340 dnl have to provide wrappers for global tables to ensure they're linked
2341 dnl properly.
2342 AC_DEFUN([CF_LINK_DATAONLY],
2343 [
2344 AC_MSG_CHECKING([if data-only library module links])
2345 AC_CACHE_VAL(cf_cv_link_dataonly,[
2346         rm -f conftest.a
2347         cat >conftest.$ac_ext <<EOF
2348 #line __oline__ "configure"
2349 int     testdata[[3]] = { 123, 456, 789 };
2350 EOF
2351         if AC_TRY_EVAL(ac_compile) ; then
2352                 mv conftest.o data.o && \
2353                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
2354         fi
2355         rm -f conftest.$ac_ext data.o
2356         cat >conftest.$ac_ext <<EOF
2357 #line __oline__ "configure"
2358 int     testfunc(void)
2359 {
2360 #if defined(NeXT)
2361         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
2362 #else
2363         extern int testdata[[3]];
2364         return testdata[[0]] == 123
2365            &&  testdata[[1]] == 456
2366            &&  testdata[[2]] == 789;
2367 #endif
2368 }
2369 EOF
2370         if AC_TRY_EVAL(ac_compile); then
2371                 mv conftest.o func.o && \
2372                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
2373         fi
2374         rm -f conftest.$ac_ext func.o
2375         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
2376         cf_saveLIBS="$LIBS"
2377         LIBS="conftest.a $LIBS"
2378         AC_TRY_RUN([
2379         int main(void)
2380         {
2381                 extern int testfunc();
2382                 ${cf_cv_main_return:-return} (!testfunc());
2383         }
2384         ],
2385         [cf_cv_link_dataonly=yes],
2386         [cf_cv_link_dataonly=no],
2387         [cf_cv_link_dataonly=unknown])
2388         LIBS="$cf_saveLIBS"
2389         ])
2390 AC_MSG_RESULT($cf_cv_link_dataonly)
2391
2392 if test "$cf_cv_link_dataonly" = no ; then
2393         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
2394         BROKEN_LINKER=1
2395 fi
2396 AC_SUBST(BROKEN_LINKER)
2397
2398 ])dnl
2399 dnl ---------------------------------------------------------------------------
2400 dnl CF_MAKEFLAGS version: 18 updated: 2018/02/21 21:26:03
2401 dnl ------------
2402 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
2403 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
2404 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
2405 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
2406 AC_DEFUN([CF_MAKEFLAGS],
2407 [
2408 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
2409         cf_cv_makeflags=''
2410         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
2411         do
2412                 cat >cf_makeflags.tmp <<CF_EOF
2413 SHELL = $SHELL
2414 all :
2415         @ echo '.$cf_option'
2416 CF_EOF
2417                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
2418                 case "$cf_result" in
2419                 (.*k|.*kw)
2420                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
2421                         case "$cf_result" in
2422                         (.*CC=*)        cf_cv_makeflags=
2423                                 ;;
2424                         (*)     cf_cv_makeflags=$cf_option
2425                                 ;;
2426                         esac
2427                         break
2428                         ;;
2429                 (.-)
2430                         ;;
2431                 (*)
2432                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
2433                         ;;
2434                 esac
2435         done
2436         rm -f cf_makeflags.tmp
2437 ])
2438
2439 AC_SUBST(cf_cv_makeflags)
2440 ])dnl
2441 dnl ---------------------------------------------------------------------------
2442 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
2443 dnl ------------
2444 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
2445 dnl a monocase filesystem.
2446 AC_DEFUN([CF_MAKE_TAGS],[
2447 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
2448
2449 AC_CHECK_PROGS(CTAGS, exctags ctags)
2450 AC_CHECK_PROGS(ETAGS, exetags etags)
2451
2452 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
2453
2454 if test "$cf_cv_mixedcase" = yes ; then
2455         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
2456 else
2457         MAKE_UPPER_TAGS=no
2458 fi
2459
2460 if test "$MAKE_UPPER_TAGS" = yes ; then
2461         MAKE_UPPER_TAGS=
2462 else
2463         MAKE_UPPER_TAGS="#"
2464 fi
2465
2466 if test "$MAKE_LOWER_TAGS" = yes ; then
2467         MAKE_LOWER_TAGS=
2468 else
2469         MAKE_LOWER_TAGS="#"
2470 fi
2471
2472 AC_SUBST(CTAGS)
2473 AC_SUBST(ETAGS)
2474
2475 AC_SUBST(MAKE_UPPER_TAGS)
2476 AC_SUBST(MAKE_LOWER_TAGS)
2477 ])dnl
2478 dnl ---------------------------------------------------------------------------
2479 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
2480 dnl ----------------------
2481 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2482 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2483 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2484 [
2485 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2486 if test "$cross_compiling" = yes ; then
2487         case $target_alias in
2488         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
2489                 cf_cv_mixedcase=no
2490                 ;;
2491         (*)
2492                 cf_cv_mixedcase=yes
2493                 ;;
2494         esac
2495 else
2496         rm -f conftest CONFTEST
2497         echo test >conftest
2498         if test -f CONFTEST ; then
2499                 cf_cv_mixedcase=no
2500         else
2501                 cf_cv_mixedcase=yes
2502         fi
2503         rm -f conftest CONFTEST
2504 fi
2505 ])
2506 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2507 ])dnl
2508 dnl ---------------------------------------------------------------------------
2509 dnl CF_MKSTEMP version: 10 updated: 2017/01/21 11:12:16
2510 dnl ----------
2511 dnl Check for a working mkstemp.  This creates two files, checks that they are
2512 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2513 AC_DEFUN([CF_MKSTEMP],[
2514 AC_CHECK_HEADERS( \
2515 unistd.h \
2516 )
2517 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2518 rm -rf conftest*
2519 AC_TRY_RUN([
2520 #include <sys/types.h>
2521 #ifdef HAVE_UNISTD_H
2522 #include <unistd.h>
2523 #endif
2524 #include <stdlib.h>
2525 #include <stdio.h>
2526 #include <string.h>
2527 #include <sys/stat.h>
2528 int main(void)
2529 {
2530         char *tmpl = "conftestXXXXXX";
2531         char name[2][80];
2532         int n;
2533         int result = 0;
2534         int fd;
2535         struct stat sb;
2536
2537         umask(077);
2538         for (n = 0; n < 2; ++n) {
2539                 strcpy(name[n], tmpl);
2540                 if ((fd = mkstemp(name[n])) >= 0) {
2541                         if (!strcmp(name[n], tmpl)
2542                          || stat(name[n], &sb) != 0
2543                          || (sb.st_mode & S_IFMT) != S_IFREG
2544                          || (sb.st_mode & 077) != 0) {
2545                                 result = 1;
2546                         }
2547                         close(fd);
2548                 }
2549         }
2550         if (result == 0
2551          && !strcmp(name[0], name[1]))
2552                 result = 1;
2553         ${cf_cv_main_return:-return}(result);
2554 }
2555 ],[cf_cv_func_mkstemp=yes
2556 ],[cf_cv_func_mkstemp=no
2557 ],[cf_cv_func_mkstemp=maybe])
2558 ])
2559 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2560         AC_CHECK_FUNC(mkstemp)
2561 fi
2562 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2563         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2564 fi
2565 ])dnl
2566 dnl ---------------------------------------------------------------------------
2567 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2568 dnl ----------
2569 dnl Write a debug message to config.log, along with the line number in the
2570 dnl configure script.
2571 AC_DEFUN([CF_MSG_LOG],[
2572 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2573 ])dnl
2574 dnl ---------------------------------------------------------------------------
2575 dnl CF_NCURSES_ADDON version: 5 updated: 2015/04/26 18:06:58
2576 dnl ----------------
2577 dnl Configure an ncurses add-on, built outside the ncurses tree.
2578 AC_DEFUN([CF_NCURSES_ADDON],[
2579 AC_REQUIRE([CF_NCURSES_CONFIG])
2580
2581 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2582
2583 AC_MSG_CHECKING(if you want wide-character code)
2584 AC_ARG_ENABLE(widec,
2585         [  --enable-widec          compile with wide-char/UTF-8 code],
2586         [with_widec=$enableval],
2587         [with_widec=no])
2588 AC_MSG_RESULT($with_widec)
2589 if test "$with_widec" = yes ; then
2590         CF_UTF8_LIB
2591         CF_NCURSES_CONFIG(ncursesw)
2592 else
2593         CF_NCURSES_CONFIG(ncurses)
2594 fi
2595
2596 if test "$NCURSES_CONFIG_PKG" != none ; then
2597         cf_version=`$PKG_CONFIG --modversion $NCURSES_CONFIG_PKG 2>/dev/null`
2598
2599         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2600         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2601         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2602
2603         cf_cv_abi_version=`$PKG_CONFIG --variable=abi_version $NCURSES_CONFIG_PKG 2>/dev/null`
2604         if test -z "$cf_cv_abi_version"
2605         then
2606                 cf_cv_abi_version=`$PKG_CONFIG --variable=major_version $NCURSES_CONFIG_PKG 2>/dev/null`
2607         fi
2608
2609 elif test "$NCURSES_CONFIG" != none ; then
2610
2611         cf_version=`$NCURSES_CONFIG --version 2>/dev/null`
2612
2613         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2614         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2615         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2616
2617         # ABI version is not available from headers
2618         cf_cv_abi_version=`$NCURSES_CONFIG --abi-version 2>/dev/null`
2619
2620 else
2621
2622         for cf_name in MAJOR MINOR PATCH
2623         do
2624         cat >conftest.$ac_ext <<CF_EOF
2625         #include <${cf_cv_ncurses_header:-curses.h}>
2626         AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2627 CF_EOF
2628                 cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2629                 AC_TRY_EVAL(cf_try)
2630                 if test -f conftest.out ; then
2631                         cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]][[    ]]*//"`
2632                         eval NCURSES_$cf_name=\"$cf_result\"
2633                         # cat conftest.$ac_ext
2634                         # cat conftest.out
2635                 fi
2636         done
2637
2638         cf_cv_abi_version=${NCURSES_MAJOR}
2639
2640 fi
2641
2642 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2643
2644 dnl Show the computed version, for logging
2645 cf_cv_timestamp=`date`
2646
2647 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2648
2649 dnl We need these values in the generated headers
2650 AC_SUBST(NCURSES_MAJOR)
2651 AC_SUBST(NCURSES_MINOR)
2652 AC_SUBST(NCURSES_PATCH)
2653
2654 dnl We need these values in the generated makefiles
2655 AC_SUBST(cf_cv_rel_version)
2656 AC_SUBST(cf_cv_abi_version)
2657
2658 dnl FIXME - not needed for Ada95
2659 AC_SUBST(cf_cv_builtin_bool)
2660 AC_SUBST(cf_cv_header_stdbool_h)
2661 AC_SUBST(cf_cv_type_of_bool)dnl
2662
2663 ])
2664 dnl ---------------------------------------------------------------------------
2665 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2666 dnl -------------------
2667 dnl Check if we can compile with ncurses' header file
2668 dnl $1 is the cache variable to set
2669 dnl $2 is the header-file to include
2670 dnl $3 is the root name (ncurses or ncursesw)
2671 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2672         AC_TRY_COMPILE([
2673 ]ifelse($3,ncursesw,[
2674 #define _XOPEN_SOURCE_EXTENDED
2675 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2676 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2677 ])[
2678 #include <$2>],[
2679 #ifdef NCURSES_VERSION
2680 ]ifelse($3,ncursesw,[
2681 #ifndef WACS_BSSB
2682         make an error
2683 #endif
2684 ])[
2685 printf("%s\n", NCURSES_VERSION);
2686 #else
2687 #ifdef __NCURSES_H
2688 printf("old\n");
2689 #else
2690         make an error
2691 #endif
2692 #endif
2693         ]
2694         ,[$1=$2]
2695         ,[$1=no])
2696 ])dnl
2697 dnl ---------------------------------------------------------------------------
2698 dnl CF_NCURSES_CONFIG version: 23 updated: 2020/02/27 05:21:59
2699 dnl -----------------
2700 dnl Tie together the configure-script macros for ncurses, preferring these in
2701 dnl order:
2702 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2703 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2704 dnl c) just plain libraries
2705 dnl
2706 dnl $1 is the root library name (default: "ncurses")
2707 AC_DEFUN([CF_NCURSES_CONFIG],[
2708 AC_REQUIRE([CF_PKG_CONFIG])
2709 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2710 cf_have_ncuconfig=no
2711
2712 if test "x${PKG_CONFIG:=none}" != xnone; then
2713         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2714         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2715                 AC_MSG_RESULT(yes)
2716
2717                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2718                 cf_have_ncuconfig=unknown
2719
2720                 cf_save_CFLAGS="$CFLAGS"
2721                 cf_save_CPPFLAGS="$CPPFLAGS"
2722                 cf_save_LIBS="$LIBS"
2723
2724                 cf_pkg_cflags=`$PKG_CONFIG --cflags $cf_ncuconfig_root`
2725                 cf_pkg_libs=`$PKG_CONFIG --libs $cf_ncuconfig_root`
2726
2727                 # while -W for passing linker flags is prevalent, it is not "standard".
2728                 # At least one wrapper for c89/c99 (in Apple's xcode) has its own
2729                 # incompatible _and_ non-standard -W option which gives an error.  Work
2730                 # around that pitfall.
2731                 case "x${CC}@@${cf_pkg_libs}@${cf_pkg_cflags}" in
2732                 (x*c[[89]]9@@*-W*)
2733                         CF_ADD_CFLAGS($cf_pkg_cflags)
2734                         CF_ADD_LIBS($cf_pkg_libs)
2735
2736                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2737                                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2738                                 [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2739                                         int main(void)
2740                                         { char *xx = curses_version(); return (xx == 0); }],
2741                                         [cf_test_ncuconfig=yes],
2742                                         [cf_test_ncuconfig=no],
2743                                         [cf_test_ncuconfig=maybe])],
2744                                 [cf_test_ncuconfig=no])
2745
2746                         CFLAGS="$cf_save_CFLAGS"
2747                         CPPFLAGS="$cf_save_CPPFLAGS"
2748                         LIBS="$cf_save_LIBS"
2749
2750                         if test "x$cf_test_ncuconfig" != xyes; then
2751                                 cf_temp=`echo "x$cf_pkg_cflags" | sed -e s/^x// -e 's/-W[[^     ]]*//g'`
2752                                 cf_pkg_cflags="$cf_temp"
2753                                 cf_temp=`echo "x$cf_pkg_libs" | sed -e s/^x// -e 's/-W[[^       ]]*//g'`
2754                                 cf_pkg_libs="$cf_temp"
2755                         fi
2756                         ;;
2757                 esac
2758
2759                 CF_ADD_CFLAGS($cf_pkg_cflags)
2760                 CF_ADD_LIBS($cf_pkg_libs)
2761
2762                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2763                         [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2764                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2765                                 int main(void)
2766                                 { char *xx = curses_version(); return (xx == 0); }],
2767                                 [cf_have_ncuconfig=yes],
2768                                 [cf_have_ncuconfig=no],
2769                                 [cf_have_ncuconfig=maybe])],
2770                         [cf_have_ncuconfig=no])
2771                 AC_MSG_RESULT($cf_have_ncuconfig)
2772                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2773                 if test "$cf_have_ncuconfig" != "yes"
2774                 then
2775                         CPPFLAGS="$cf_save_CPPFLAGS"
2776                         LIBS="$cf_save_LIBS"
2777                         NCURSES_CONFIG_PKG=none
2778                 else
2779                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2780                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2781                         CF_TERM_HEADER
2782                 fi
2783
2784         else
2785                 AC_MSG_RESULT(no)
2786                 NCURSES_CONFIG_PKG=none
2787         fi
2788 else
2789         NCURSES_CONFIG_PKG=none
2790 fi
2791
2792 if test "x$cf_have_ncuconfig" = "xno"; then
2793         cf_ncurses_config="${cf_ncuconfig_root}${NCURSES_CONFIG_SUFFIX}-config"; echo "Looking for ${cf_ncurses_config}"
2794
2795         CF_ACVERSION_CHECK(2.52,
2796                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2797                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2798
2799         if test "$NCURSES_CONFIG" != none ; then
2800
2801                 CF_ADD_CFLAGS(`$NCURSES_CONFIG --cflags`)
2802                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2803
2804                 # even with config script, some packages use no-override for curses.h
2805                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2806
2807                 dnl like CF_NCURSES_CPPFLAGS
2808                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2809
2810                 dnl like CF_NCURSES_LIBS
2811                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2812                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2813
2814                 dnl like CF_NCURSES_VERSION
2815                 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2816
2817         else
2818
2819                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2820                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2821
2822         fi
2823 else
2824         NCURSES_CONFIG=none
2825 fi
2826 ])dnl
2827 dnl ---------------------------------------------------------------------------
2828 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2829 dnl -------------------
2830 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2831 dnl the CPPFLAGS variable so we can include its header.
2832 dnl
2833 dnl The header files may be installed as either curses.h, or ncurses.h (would
2834 dnl be obsolete, except that some packagers prefer this name to distinguish it
2835 dnl from a "native" curses implementation).  If not installed for overwrite,
2836 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2837 dnl /usr/include/ncurses), but someone may have installed overwriting the
2838 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2839 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2840 dnl the header.
2841 dnl
2842 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2843 dnl is already in the include-path, don't even bother with this, since we cannot
2844 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2845 dnl
2846 dnl The optional parameter gives the root name of the library, in case it is
2847 dnl not installed as the default curses library.  That is how the
2848 dnl wide-character version of ncurses is installed.
2849 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2850 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2851
2852 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2853 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2854
2855 test -n "$cf_cv_curses_dir" && \
2856 test "$cf_cv_curses_dir" != "no" && { \
2857   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2858 }
2859
2860 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2861         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2862         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2863         for cf_header in $cf_header_list
2864         do
2865                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2866                 test "$cf_cv_ncurses_h" != no && break
2867         done
2868 ])
2869
2870 CF_NCURSES_HEADER
2871 CF_TERM_HEADER
2872
2873 # some applications need this, but should check for NCURSES_VERSION
2874 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2875
2876 CF_NCURSES_VERSION
2877 ])dnl
2878 dnl ---------------------------------------------------------------------------
2879 dnl CF_NCURSES_HEADER version: 4 updated: 2015/04/15 19:08:48
2880 dnl -----------------
2881 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2882 dnl variations of ncurses' installs.
2883 dnl
2884 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2885 AC_DEFUN([CF_NCURSES_HEADER],[
2886
2887 if test "$cf_cv_ncurses_h" != no ; then
2888         cf_cv_ncurses_header=$cf_cv_ncurses_h
2889 else
2890
2891 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2892         test -n "$verbose" && echo
2893         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2894         test -n "$verbose" && echo search path $cf_search
2895         cf_save2_CPPFLAGS="$CPPFLAGS"
2896         for cf_incdir in $cf_search
2897         do
2898                 CF_ADD_INCDIR($cf_incdir)
2899                 for cf_header in \
2900                         ncurses.h \
2901                         curses.h
2902                 do
2903                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2904                         if test "$cf_cv_ncurses_h2" != no ; then
2905                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2906                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2907                                 break
2908                         fi
2909                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2910                 done
2911                 CPPFLAGS="$cf_save2_CPPFLAGS"
2912                 test "$cf_cv_ncurses_h2" != no && break
2913         done
2914         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2915         ])
2916
2917         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2918         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2919         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2920                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2921         fi
2922         CF_ADD_INCDIR($cf_1st_incdir)
2923
2924 fi
2925
2926 # Set definitions to allow ifdef'ing for ncurses.h
2927
2928 case $cf_cv_ncurses_header in
2929 (*ncurses.h)
2930         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2931         ;;
2932 esac
2933
2934 case $cf_cv_ncurses_header in
2935 (ncurses/curses.h|ncurses/ncurses.h)
2936         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2937         ;;
2938 (ncursesw/curses.h|ncursesw/ncurses.h)
2939         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2940         ;;
2941 esac
2942
2943 ])dnl
2944 dnl ---------------------------------------------------------------------------
2945 dnl CF_NCURSES_LIBS version: 17 updated: 2015/04/15 19:08:48
2946 dnl ---------------
2947 dnl Look for the ncurses library.  This is a little complicated on Linux,
2948 dnl because it may be linked with the gpm (general purpose mouse) library.
2949 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2950 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2951 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2952 dnl and the linker will record a dependency.
2953 dnl
2954 dnl The optional parameter gives the root name of the library, in case it is
2955 dnl not installed as the default curses library.  That is how the
2956 dnl wide-character version of ncurses is installed.
2957 AC_DEFUN([CF_NCURSES_LIBS],
2958 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2959
2960 cf_nculib_root=ifelse($1,,ncurses,$1)
2961         # This works, except for the special case where we find gpm, but
2962         # ncurses is in a nonstandard location via $LIBS, and we really want
2963         # to link gpm.
2964 cf_ncurses_LIBS=""
2965 cf_ncurses_SAVE="$LIBS"
2966 AC_CHECK_LIB(gpm,Gpm_Open,
2967         [AC_CHECK_LIB(gpm,initscr,
2968                 [LIBS="$cf_ncurses_SAVE"],
2969                 [cf_ncurses_LIBS="-lgpm"])])
2970
2971 case $host_os in
2972 (freebsd*)
2973         # This is only necessary if you are linking against an obsolete
2974         # version of ncurses (but it should do no harm, since it's static).
2975         if test "$cf_nculib_root" = ncurses ; then
2976                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2977         fi
2978         ;;
2979 esac
2980
2981 CF_ADD_LIBS($cf_ncurses_LIBS)
2982
2983 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2984 then
2985         CF_ADD_LIBS(-l$cf_nculib_root)
2986 else
2987         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2988                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2989                 [initscr()],
2990                 initscr)
2991 fi
2992
2993 if test -n "$cf_ncurses_LIBS" ; then
2994         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2995         cf_ncurses_SAVE="$LIBS"
2996         for p in $cf_ncurses_LIBS ; do
2997                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2998                 if test "$q" != "$LIBS" ; then
2999                         LIBS="$q"
3000                 fi
3001         done
3002         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
3003                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
3004                 [AC_MSG_RESULT(yes)],
3005                 [AC_MSG_RESULT(no)
3006                  LIBS="$cf_ncurses_SAVE"])
3007 fi
3008
3009 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
3010 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
3011 ])dnl
3012 dnl ---------------------------------------------------------------------------
3013 dnl CF_NCURSES_VERSION version: 15 updated: 2017/05/09 19:26:10
3014 dnl ------------------
3015 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
3016 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
3017 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
3018 AC_DEFUN([CF_NCURSES_VERSION],
3019 [
3020 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
3021 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
3022         cf_cv_ncurses_version=no
3023         cf_tempfile=out$$
3024         rm -f $cf_tempfile
3025         AC_TRY_RUN([
3026 #include <${cf_cv_ncurses_header:-curses.h}>
3027 #include <stdio.h>
3028 int main(void)
3029 {
3030         FILE *fp = fopen("$cf_tempfile", "w");
3031 #ifdef NCURSES_VERSION
3032 # ifdef NCURSES_VERSION_PATCH
3033         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
3034 # else
3035         fprintf(fp, "%s\n", NCURSES_VERSION);
3036 # endif
3037 #else
3038 # ifdef __NCURSES_H
3039         fprintf(fp, "old\n");
3040 # else
3041         make an error
3042 # endif
3043 #endif
3044         ${cf_cv_main_return:-return}(0);
3045 }],[
3046         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
3047
3048         # This will not work if the preprocessor splits the line after the
3049         # Autoconf token.  The 'unproto' program does that.
3050         cat > conftest.$ac_ext <<EOF
3051 #include <${cf_cv_ncurses_header:-curses.h}>
3052 #undef Autoconf
3053 #ifdef NCURSES_VERSION
3054 Autoconf NCURSES_VERSION
3055 #else
3056 #ifdef __NCURSES_H
3057 Autoconf "old"
3058 #endif
3059 ;
3060 #endif
3061 EOF
3062         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
3063         AC_TRY_EVAL(cf_try)
3064         if test -f conftest.out ; then
3065                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
3066                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
3067                 rm -f conftest.out
3068         fi
3069 ])
3070         rm -f $cf_tempfile
3071 ])
3072 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
3073 ])dnl
3074 dnl ---------------------------------------------------------------------------
3075 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
3076 dnl -------------
3077 dnl Compute the object-directory name from the given model name
3078 AC_DEFUN([CF_OBJ_SUBDIR],
3079 [
3080         case $1 in
3081         (libtool) $2='obj_lo'  ;;
3082         (normal)  $2='objects' ;;
3083         (debug)   $2='obj_g' ;;
3084         (profile) $2='obj_p' ;;
3085         (shared)
3086                 case $cf_cv_system_name in
3087                 (cygwin|msys)
3088                         $2='objects' ;;
3089                 (*)
3090                         $2='obj_s' ;;
3091                 esac
3092         esac
3093 ])dnl
3094 dnl ---------------------------------------------------------------------------
3095 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
3096 dnl ----------
3097 dnl Provide a value for the $PATH and similar separator (or amend the value
3098 dnl as provided in autoconf 2.5x).
3099 AC_DEFUN([CF_PATHSEP],
3100 [
3101         AC_MSG_CHECKING(for PATH separator)
3102         case $cf_cv_system_name in
3103         (os2*)  PATH_SEPARATOR=';'  ;;
3104         (*)     ${PATH_SEPARATOR:=':'}  ;;
3105         esac
3106 ifelse([$1],,,[$1=$PATH_SEPARATOR])
3107         AC_SUBST(PATH_SEPARATOR)
3108         AC_MSG_RESULT($PATH_SEPARATOR)
3109 ])dnl
3110 dnl ---------------------------------------------------------------------------
3111 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
3112 dnl --------------
3113 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
3114 dnl begins with one of the prefix/exec_prefix variables, and then again if the
3115 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
3116 dnl delayed evaluation of those symbols.
3117 AC_DEFUN([CF_PATH_SYNTAX],[
3118 if test "x$prefix" != xNONE; then
3119         cf_path_syntax="$prefix"
3120 else
3121         cf_path_syntax="$ac_default_prefix"
3122 fi
3123
3124 case ".[$]$1" in
3125 (.\[$]\(*\)*|.\'*\'*)
3126         ;;
3127 (..|./*|.\\*)
3128         ;;
3129 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
3130         ;;
3131 (.\[$]{*prefix}*|.\[$]{*dir}*)
3132         eval $1="[$]$1"
3133         case ".[$]$1" in
3134         (.NONE/*)
3135                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
3136                 ;;
3137         esac
3138         ;;
3139 (.no|.NONE/*)
3140         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
3141         ;;
3142 (*)
3143         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
3144         ;;
3145 esac
3146 ])dnl
3147 dnl ---------------------------------------------------------------------------
3148 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
3149 dnl -------------
3150 dnl Check for the package-config program, unless disabled by command-line.
3151 AC_DEFUN([CF_PKG_CONFIG],
3152 [
3153 AC_MSG_CHECKING(if you want to use pkg-config)
3154 AC_ARG_WITH(pkg-config,
3155         [  --with-pkg-config{=path} enable/disable use of pkg-config],
3156         [cf_pkg_config=$withval],
3157         [cf_pkg_config=yes])
3158 AC_MSG_RESULT($cf_pkg_config)
3159
3160 case $cf_pkg_config in
3161 (no)
3162         PKG_CONFIG=none
3163         ;;
3164 (yes)
3165         CF_ACVERSION_CHECK(2.52,
3166                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
3167                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
3168         ;;
3169 (*)
3170         PKG_CONFIG=$withval
3171         ;;
3172 esac
3173
3174 test -z "$PKG_CONFIG" && PKG_CONFIG=none
3175 if test "$PKG_CONFIG" != none ; then
3176         CF_PATH_SYNTAX(PKG_CONFIG)
3177 elif test "x$cf_pkg_config" != xno ; then
3178         AC_MSG_WARN(pkg-config is not installed)
3179 fi
3180
3181 AC_SUBST(PKG_CONFIG)
3182 ])dnl
3183 dnl ---------------------------------------------------------------------------
3184 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
3185 dnl -----------------
3186 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
3187 dnl
3188 dnl     POSIX.1-1990                            _POSIX_SOURCE
3189 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
3190 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
3191 dnl             Bindings Option
3192 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
3193 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
3194 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
3195 dnl
3196 dnl Parameters:
3197 dnl     $1 is the nominal value for _POSIX_C_SOURCE
3198 AC_DEFUN([CF_POSIX_C_SOURCE],
3199 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
3200
3201 if test "$cf_cv_posix_visible" = no; then
3202
3203 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
3204
3205 cf_save_CFLAGS="$CFLAGS"
3206 cf_save_CPPFLAGS="$CPPFLAGS"
3207
3208 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
3209 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
3210
3211 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
3212         CF_MSG_LOG(if the symbol is already defined go no further)
3213         AC_TRY_COMPILE([#include <sys/types.h>],[
3214 #ifndef _POSIX_C_SOURCE
3215 make an error
3216 #endif],
3217         [cf_cv_posix_c_source=no],
3218         [cf_want_posix_source=no
3219          case .$cf_POSIX_C_SOURCE in
3220          (.[[12]]??*)
3221                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3222                 ;;
3223          (.2)
3224                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3225                 cf_want_posix_source=yes
3226                 ;;
3227          (.*)
3228                 cf_want_posix_source=yes
3229                 ;;
3230          esac
3231          if test "$cf_want_posix_source" = yes ; then
3232                 AC_TRY_COMPILE([#include <sys/types.h>],[
3233 #ifdef _POSIX_SOURCE
3234 make an error
3235 #endif],[],
3236                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
3237          fi
3238          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
3239          CFLAGS="$cf_trim_CFLAGS"
3240          CPPFLAGS="$cf_trim_CPPFLAGS"
3241          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
3242          CF_MSG_LOG(if the second compile does not leave our definition intact error)
3243          AC_TRY_COMPILE([#include <sys/types.h>],[
3244 #ifndef _POSIX_C_SOURCE
3245 make an error
3246 #endif],,
3247          [cf_cv_posix_c_source=no])
3248          CFLAGS="$cf_save_CFLAGS"
3249          CPPFLAGS="$cf_save_CPPFLAGS"
3250         ])
3251 ])
3252
3253 if test "$cf_cv_posix_c_source" != no ; then
3254         CFLAGS="$cf_trim_CFLAGS"
3255         CPPFLAGS="$cf_trim_CPPFLAGS"
3256         CF_ADD_CFLAGS($cf_cv_posix_c_source)
3257 fi
3258
3259 fi # cf_cv_posix_visible
3260
3261 ])dnl
3262 dnl ---------------------------------------------------------------------------
3263 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
3264 dnl ----------------
3265 dnl POSIX documents test-macros which an application may set before any system
3266 dnl headers are included to make features available.
3267 dnl
3268 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
3269 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
3270 dnl recent features visible in the system header files unless the application
3271 dnl overrides the corresponding test-macros.  Doing that introduces portability
3272 dnl problems.
3273 dnl
3274 dnl This macro makes a special check for the symbols used for this, to avoid a
3275 dnl conflicting definition.
3276 AC_DEFUN([CF_POSIX_VISIBLE],
3277 [
3278 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
3279 AC_TRY_COMPILE([#include <stdio.h>],[
3280 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
3281         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
3282         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
3283         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
3284 #error conflicting symbols found
3285 #endif
3286 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
3287 ])
3288 ])dnl
3289 dnl ---------------------------------------------------------------------------
3290 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
3291 dnl ----------
3292 dnl Check for archiver "ar".
3293 AC_DEFUN([CF_PROG_AR],[
3294 AC_CHECK_TOOL(AR, ar, ar)
3295 ])
3296 dnl ---------------------------------------------------------------------------
3297 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
3298 dnl -----------
3299 dnl Check for awk, ensure that the check found something.
3300 AC_DEFUN([CF_PROG_AWK],
3301 [
3302 AC_PROG_AWK
3303 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
3304 ])dnl
3305 dnl ---------------------------------------------------------------------------
3306 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
3307 dnl ----------
3308 dnl standard check for CC, plus followup sanity checks
3309 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
3310 AC_DEFUN([CF_PROG_CC],[
3311 CF_ACVERSION_CHECK(2.53,
3312         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
3313          AC_REQUIRE([AC_PROG_CC])],
3314         [])
3315 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
3316 CF_GCC_VERSION
3317 CF_ACVERSION_CHECK(2.52,
3318         [AC_PROG_CC_STDC],
3319         [CF_ANSI_CC_REQD])
3320 CF_CC_ENV_FLAGS
3321 ])dnl
3322 dnl ---------------------------------------------------------------------------
3323 dnl CF_PROG_CC_C_O version: 5 updated: 2017/01/21 11:06:25
3324 dnl --------------
3325 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
3326 dnl the output file can be renamed, and allows for a shell variable that can
3327 dnl be used later.  The parameter is either CC or CXX.  The result is the
3328 dnl cache variable:
3329 dnl     $cf_cv_prog_CC_c_o
3330 dnl     $cf_cv_prog_CXX_c_o
3331 dnl
3332 dnl $1 = compiler
3333 dnl $2 = compiler options, if any
3334 AC_DEFUN([CF_PROG_CC_C_O],
3335 [AC_REQUIRE([AC_PROG_CC])dnl
3336 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
3337 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
3338 [
3339 cat > conftest.$ac_ext <<CF_EOF
3340 int main(void)
3341 {
3342         ${cf_cv_main_return:-return}(0);
3343 }
3344 CF_EOF
3345 # We do the test twice because some compilers refuse to overwrite an
3346 # existing .o file with -o, though they will create one.
3347 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
3348 if AC_TRY_EVAL(ac_try) &&
3349   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
3350 then
3351   eval cf_cv_prog_$1_c_o=yes
3352 else
3353   eval cf_cv_prog_$1_c_o=no
3354 fi
3355 rm -rf conftest*
3356 ])dnl
3357 if test $cf_cv_prog_$1_c_o = yes; then
3358   AC_MSG_RESULT([yes])
3359 else
3360   AC_MSG_RESULT([no])
3361 fi
3362 ])dnl
3363 dnl ---------------------------------------------------------------------------
3364 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
3365 dnl -------------
3366 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
3367 dnl This macro adds a check to ensure the script found something.
3368 AC_DEFUN([CF_PROG_EGREP],
3369 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
3370         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
3371                 then ac_cv_prog_egrep='grep -E'
3372                 else ac_cv_prog_egrep='egrep'
3373         fi])
3374         EGREP=$ac_cv_prog_egrep
3375         AC_SUBST([EGREP])
3376         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
3377 ])dnl
3378 dnl ---------------------------------------------------------------------------
3379 dnl CF_PROG_EXT version: 14 updated: 2018/06/20 20:23:13
3380 dnl -----------
3381 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
3382 AC_DEFUN([CF_PROG_EXT],
3383 [
3384 AC_REQUIRE([CF_CHECK_CACHE])
3385 case $cf_cv_system_name in
3386 (os2*)
3387         CFLAGS="$CFLAGS -Zmt"
3388         CF_APPEND_TEXT(CPPFLAGS,-D__ST_MT_ERRNO__)
3389         CXXFLAGS="$CXXFLAGS -Zmt"
3390         # autoconf's macro sets -Zexe and suffix both, which conflict:w
3391         LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
3392         ac_cv_exeext=.exe
3393         ;;
3394 esac
3395
3396 AC_EXEEXT
3397 AC_OBJEXT
3398
3399 PROG_EXT="$EXEEXT"
3400 AC_SUBST(PROG_EXT)
3401 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
3402 ])dnl
3403 dnl ---------------------------------------------------------------------------
3404 dnl CF_PROG_GNAT version: 10 updated: 2019/12/31 08:53:54
3405 dnl ------------
3406 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
3407 AC_DEFUN([CF_PROG_GNAT],[
3408 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
3409 do
3410         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
3411
3412         unset ac_cv_path_cf_TEMP_gnat
3413         unset cf_TEMP_gnat
3414         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
3415         eval cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat
3416
3417         if test "x$cf_TEMP_gnat" != xno; then
3418                 unset cf_cv_gnat_version
3419                 unset cf_TEMP_gnat
3420                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
3421         fi
3422         eval cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat
3423
3424         unset cf_TEMP_gnat
3425         unset cf_cv_gnat_version
3426         unset ac_cv_path_cf_TEMP_gnat
3427 done
3428
3429 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
3430         cf_ada_make=
3431         cf_cv_prog_gnat_correct=no
3432 else
3433         cf_ada_make=gnatmake
3434         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
3435                 # gprconfig is newer than gnatmake; we can continue...
3436                 cf_ada_config="##"
3437         else
3438                 rm -rf conftest* *~conftest*
3439                 if mkdir conftest.src
3440                 then
3441                         cf_ada_config=""
3442                         cd conftest.src
3443                         for cf_gprconfig in Ada C
3444                         do
3445                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
3446                                 if test $cf_gprconfig = C
3447                                 then
3448                                         for cf_gprconfig_param in \
3449                                                 $cf_gprconfig,,,,GNATGCC \
3450                                                 $cf_gprconfig,,,,GCC \
3451                                                 $cf_gprconfig
3452                                         do
3453                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
3454                                                 test -n "$cf_gprconfig_value" && break
3455                                         done
3456                                 else
3457                                         cf_gprconfig_param=$cf_gprconfig
3458                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
3459                                 fi
3460                                 if test -n "$cf_gprconfig_value"
3461                                 then
3462                                         eval cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value
3463                                         AC_MSG_RESULT($cf_gprconfig_value)
3464                                 else
3465                                         AC_MSG_RESULT(missing)
3466                                         cf_ada_config="#"
3467                                         break
3468                                 fi
3469                         done
3470                         cd ..
3471                         rm -rf conftest* *~conftest*
3472                 fi
3473         fi
3474         if test "x$cf_ada_config" != "x#"
3475         then
3476                 CF_GNAT_VERSION
3477                 CF_CHECK_GNAT_VERSION
3478                 AC_CHECK_PROG(M4_exists, m4, yes, no)
3479                 if test "$ac_cv_prog_M4_exists" = no; then
3480                         cf_cv_prog_gnat_correct=no
3481                         AC_MSG_WARN(Ada95 binding required program m4 not found. Ada95 binding disabled)
3482                 fi
3483                 if test "$cf_cv_prog_gnat_correct" = yes; then
3484                         AC_MSG_CHECKING(if GNAT works)
3485                         CF_GNAT_TRY_RUN([procedure conftest;],
3486 [with Text_IO;
3487 with GNAT.OS_Lib;
3488 procedure conftest is
3489 begin
3490    Text_IO.Put ("Hello World");
3491    Text_IO.New_Line;
3492    GNAT.OS_Lib.OS_Exit (0);
3493 end conftest;],
3494 [cf_cv_prog_gnat_correct=yes],
3495 [cf_cv_prog_gnat_correct=no])
3496                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
3497                 fi
3498         else
3499                 cf_cv_prog_gnat_correct=no
3500         fi
3501 fi
3502
3503 AC_SUBST(cf_ada_make)
3504 AC_SUBST(cf_ada_config)
3505 AC_SUBST(cf_ada_config_Ada)
3506 AC_SUBST(cf_ada_config_C)
3507 ])dnl
3508 dnl ---------------------------------------------------------------------------
3509 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
3510 dnl ---------------
3511 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
3512 dnl misc/tabset install won't work properly.  Usually this happens only when
3513 dnl using the fallback mkinstalldirs script
3514 AC_DEFUN([CF_PROG_INSTALL],
3515 [AC_PROG_INSTALL
3516 case $INSTALL in
3517 (/*)
3518         ;;
3519 (*)
3520         CF_DIRNAME(cf_dir,$INSTALL)
3521         test -z "$cf_dir" && cf_dir=.
3522         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
3523         ;;
3524 esac
3525 ])dnl
3526 dnl ---------------------------------------------------------------------------
3527 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
3528 dnl ------------
3529 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
3530 dnl option if it is supported.
3531 AC_DEFUN([CF_PROG_LN_S],[
3532 AC_PROG_LN_S
3533 AC_MSG_CHECKING(if $LN_S -f options work)
3534
3535 rm -f conf$$.src conf$$dst
3536 echo >conf$$.dst
3537 echo first >conf$$.src
3538 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
3539         cf_prog_ln_sf=yes
3540 else
3541         cf_prog_ln_sf=no
3542 fi
3543 rm -f conf$$.dst conf$$src
3544 AC_MSG_RESULT($cf_prog_ln_sf)
3545
3546 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
3547 ])dnl
3548 dnl ---------------------------------------------------------------------------
3549 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
3550 dnl ----------------
3551 dnl Remove all -U and -D options that refer to the given symbol from a list
3552 dnl of C compiler options.  This works around the problem that not all
3553 dnl compilers process -U and -D options from left-to-right, so a -U option
3554 dnl cannot be used to cancel the effect of a preceding -D option.
3555 dnl
3556 dnl $1 = target (which could be the same as the source variable)
3557 dnl $2 = source (including '$')
3558 dnl $3 = symbol to remove
3559 define([CF_REMOVE_DEFINE],
3560 [
3561 $1=`echo "$2" | \
3562         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
3563                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
3564 ])dnl
3565 dnl ---------------------------------------------------------------------------
3566 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
3567 dnl -------------
3568 dnl Remove the given library from the symbol
3569 dnl
3570 dnl $1 = target (which could be the same as the source variable)
3571 dnl $2 = source (including '$')
3572 dnl $3 = library to remove
3573 define([CF_REMOVE_LIB],
3574 [
3575 # remove $3 library from $2
3576 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
3577 ])dnl
3578 dnl ---------------------------------------------------------------------------
3579 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
3580 dnl ---------------------
3581 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
3582 dnl $1 = name of current macro
3583 define([CF_RESTORE_XTRA_FLAGS],
3584 [
3585 LIBS="$cf_save_LIBS_$1"
3586 CFLAGS="$cf_save_CFLAGS_$1"
3587 CPPFLAGS="$cf_save_CPPFLAGS_$1"
3588 ])dnl
3589 dnl ---------------------------------------------------------------------------
3590 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
3591 dnl ------------------
3592 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
3593 dnl and libraries which do not update those variables.
3594 dnl
3595 dnl $1 = name of current macro
3596 define([CF_SAVE_XTRA_FLAGS],
3597 [
3598 cf_save_LIBS_$1="$LIBS"
3599 cf_save_CFLAGS_$1="$CFLAGS"
3600 cf_save_CPPFLAGS_$1="$CPPFLAGS"
3601 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
3602 for cf_X_CFLAGS in $X_CFLAGS
3603 do
3604         case "x$cf_X_CFLAGS" in
3605         x-[[IUD]]*)
3606                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
3607                 ;;
3608         *)
3609                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
3610                 ;;
3611         esac
3612 done
3613 ])dnl
3614 dnl ---------------------------------------------------------------------------
3615 dnl CF_SHARED_OPTS version: 102 updated: 2020/08/22 18:17:19
3616 dnl --------------
3617 dnl --------------
3618 dnl Attempt to determine the appropriate CC/LD options for creating a shared
3619 dnl library.
3620 dnl
3621 dnl Notes:
3622 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
3623 dnl the build-tree, i.e., by making use of the libraries that are compiled in
3624 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
3625 dnl shared library since that can lead to unexpected results at runtime.
3626 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
3627 dnl libraries are compiled in ../../lib
3628 dnl
3629 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
3630 dnl to install symbolic links to the rel/abi versions of shared libraries.
3631 dnl
3632 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
3633 dnl version when making symbolic links.
3634 dnl
3635 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
3636 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
3637 dnl (ex: libncurses.so.<ver>).
3638 dnl
3639 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
3640 AC_DEFUN([CF_SHARED_OPTS],
3641 [
3642         AC_REQUIRE([CF_LD_RPATH_OPT])
3643
3644         RM_SHARED_OPTS=
3645         LOCAL_LDFLAGS=
3646         LOCAL_LDFLAGS2=
3647         LD_SHARED_OPTS=
3648         INSTALL_LIB="-m 644"
3649         : ${rel_builddir:=.}
3650
3651         shlibdir=$libdir
3652         AC_SUBST(shlibdir)
3653
3654         MAKE_DLLS="#"
3655         AC_SUBST(MAKE_DLLS)
3656
3657         cf_cv_do_symlinks=no
3658         cf_ld_rpath_opt=
3659         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
3660
3661         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
3662         AC_ARG_WITH(shlib-version,
3663         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
3664         [test -z "$withval" && withval=auto
3665         case $withval in
3666         (yes)
3667                 cf_cv_shlib_version=auto
3668                 ;;
3669         (rel|abi|auto)
3670                 cf_cv_shlib_version=$withval
3671                 ;;
3672         (*)
3673                 AC_MSG_RESULT($withval)
3674                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
3675                 ;;
3676         esac
3677         ],[cf_cv_shlib_version=auto])
3678         AC_MSG_RESULT($cf_cv_shlib_version)
3679
3680         cf_cv_rm_so_locs=no
3681         cf_try_cflags=
3682
3683         # Some less-capable ports of gcc support only -fpic
3684         CC_SHARED_OPTS=
3685
3686         cf_try_fPIC=no
3687         if test "$GCC" = yes
3688         then
3689                 cf_try_fPIC=yes
3690         else
3691                 case $cf_cv_system_name in
3692                 (*linux*)       # e.g., PGI compiler
3693                         cf_try_fPIC=yes
3694                         ;;
3695                 esac
3696         fi
3697
3698         if test "$cf_try_fPIC" = yes
3699         then
3700                 AC_MSG_CHECKING(which $CC option to use)
3701                 cf_save_CFLAGS="$CFLAGS"
3702                 for CC_SHARED_OPTS in -fPIC -fpic ''
3703                 do
3704                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
3705                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
3706                 done
3707                 AC_MSG_RESULT($CC_SHARED_OPTS)
3708                 CFLAGS="$cf_save_CFLAGS"
3709         fi
3710
3711         cf_cv_shlib_version_infix=no
3712
3713         case $cf_cv_system_name in
3714         (aix4.[3-9]*|aix[[5-7]]*)
3715                 if test "$GCC" = yes; then
3716                         CC_SHARED_OPTS='-Wl,-brtl'
3717                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3718                 else
3719                         CC_SHARED_OPTS='-brtl'
3720                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
3721                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3722                 fi
3723                 ;;
3724         (beos*)
3725                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
3726                 ;;
3727         (cygwin*)
3728                 CC_SHARED_OPTS=
3729                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3730                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3731                 cf_cv_shlib_version=cygdll
3732                 cf_cv_shlib_version_infix=cygdll
3733                 shlibdir=$bindir
3734                 MAKE_DLLS=
3735                 cat >mk_shared_lib.sh <<-CF_EOF
3736                 #!$SHELL
3737                 SHARED_LIB=\[$]1
3738                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3739                 shift
3740                 cat <<-EOF
3741                 Linking shared library
3742                 ** SHARED_LIB \[$]SHARED_LIB
3743                 ** IMPORT_LIB \[$]IMPORT_LIB
3744 EOF
3745                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3746 CF_EOF
3747                 chmod +x mk_shared_lib.sh
3748                 ;;
3749         (msys*)
3750                 CC_SHARED_OPTS=
3751                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3752                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3753                 cf_cv_shlib_version=msysdll
3754                 cf_cv_shlib_version_infix=msysdll
3755                 shlibdir=$bindir
3756                 MAKE_DLLS=
3757                 cat >mk_shared_lib.sh <<-CF_EOF
3758                 #!$SHELL
3759                 SHARED_LIB=\[$]1
3760                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3761                 shift
3762                 cat <<-EOF
3763                 Linking shared library
3764                 ** SHARED_LIB \[$]SHARED_LIB
3765                 ** IMPORT_LIB \[$]IMPORT_LIB
3766 EOF
3767                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3768 CF_EOF
3769                 chmod +x mk_shared_lib.sh
3770                 ;;
3771         (darwin*)
3772                 cf_try_cflags="no-cpp-precomp"
3773                 CC_SHARED_OPTS="-dynamic"
3774                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
3775                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
3776                 cf_cv_shlib_version_infix=yes
3777                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
3778                         cf_save_LDFLAGS=$LDFLAGS
3779                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3780                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
3781                                 LDFLAGS=$cf_save_LDFLAGS])
3782                 if test $cf_cv_ldflags_search_paths_first = yes; then
3783                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3784                 fi
3785                 ;;
3786         (hpux[[7-8]]*)
3787                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
3788                 if test "$GCC" != yes; then
3789                         CC_SHARED_OPTS='+Z'
3790                 fi
3791                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
3792                 INSTALL_LIB="-m 555"
3793                 ;;
3794         (hpux*)
3795                 # (tested with gcc 2.7.2 -- I don't have c89)
3796                 if test "$GCC" = yes; then
3797                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
3798                 else
3799                         CC_SHARED_OPTS='+Z'
3800                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
3801                 fi
3802                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
3803                 # HP-UX shared libraries must be executable, and should be
3804                 # readonly to exploit a quirk in the memory manager.
3805                 INSTALL_LIB="-m 555"
3806                 ;;
3807         (interix*)
3808                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3809                 if test "$cf_cv_shlib_version" = rel; then
3810                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3811                 else
3812                         cf_shared_soname='`basename $[@]`'
3813                 fi
3814                 CC_SHARED_OPTS=
3815                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
3816                 ;;
3817         (irix*)
3818                 if test "$cf_cv_enable_rpath" = yes ; then
3819                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3820                 fi
3821                 # tested with IRIX 5.2 and 'cc'.
3822                 if test "$GCC" != yes; then
3823                         CC_SHARED_OPTS='-KPIC'
3824                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
3825                 else
3826                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
3827                 fi
3828                 cf_cv_rm_so_locs=yes
3829                 ;;
3830         (linux*|gnu*|k*bsd*-gnu)
3831                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
3832                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3833                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3834                 fi
3835                 if test "$cf_cv_enable_rpath" = yes ; then
3836                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3837                 fi
3838                 CF_SHARED_SONAME
3839                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3840                 ;;
3841         (mingw*msvc*)
3842                 cf_cv_shlib_version=msvcdll
3843                 cf_cv_shlib_version_infix=msvcdll
3844                 shlibdir=$bindir
3845                 MAKE_DLLS=
3846                 if test "$DFT_LWR_MODEL" = "shared" ; then
3847                         LOCAL_LDFLAGS="-link -dll"
3848                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3849                         EXTRA_LDFLAGS="-link -dll $EXTRA_LDFLAGS"
3850                 fi
3851                 CC_SHARED_OPTS=
3852                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ ${LD} [$]{CFLAGS}'
3853                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.lib"
3854                 cat >mk_shared_lib.sh <<-CF_EOF
3855                 #!$SHELL
3856                 SHARED_LIB=\[$]1
3857                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.lib/'\`
3858                 shift
3859                 my_ld=\[$]1
3860                 shift
3861                 cat <<-EOF
3862                 Linking shared library
3863                 ** SHARED LIB \$SHARED_LIB
3864                 ** IMPORT_LIB \$IMPORT_LIB
3865 EOF
3866                 args=\$(echo \[$]* | sed -E "s#-l(\w*)#\1.dll.lib#g" | sed -E "s#-L(\w*)#-LIBPATH:\1#g")
3867                 exec \$my_ld -DLL -IMPLIB:"\${IMPORT_LIB}" -OUT:"\${SHARED_LIB}" ${LDFLAGS} \$args
3868                 mv "\${IMPORT_LIB}" "\${IMPORT_LIB}"
3869 CF_EOF
3870                 chmod +x mk_shared_lib.sh
3871                 cat >mk_prog.sh <<-CF_EOF
3872                 #!$SHELL
3873                 shift
3874                 # Ignore first argument (compiler) and use LD (link.exe) unconditionally
3875                 LD="[$]LD"
3876                 clopts=()
3877                 ldopts=("/subsystem:console")
3878                 libs=()
3879                 isdll=0
3880                 while test \[$]# -gt 0; do
3881                         case "\[$]1" in
3882                                 -link)
3883                                         # ignore -link argument
3884                                         ;;
3885                                 -M[[TD]] | -M[[TD]]d)
3886                                         # ignore runtime-library option
3887                                         ;;
3888                                 -dll)
3889                                         isdll=1
3890                                         ;;
3891                                 -W* | -w*)
3892                                         # ignore warnings
3893                                         ;;
3894                                 -D*)
3895                                         clopts+=("\[$]1")
3896                                         ;;
3897                                 -I*)
3898                                         clopts+=("\[$]1")
3899                                         ;;
3900                                 -l*)
3901                                         libs+=("\`echo \"\[$]1\" | sed \"s/^-l//\"\`")
3902                                         ;;
3903                                 -L*)
3904                                         ldopts+=("\`echo \"\[$]1\" | sed \"s/^-L/-LIBPATH:/\"\`")
3905                                         ;;
3906                                 *.obj | *.o)
3907                                         ldopts+=("\[$]1")
3908                                         ;;
3909                                 -Wl,*)
3910                                         for linkarg in \`echo '\[$]1' | sed -e 's/-Wl,//' -e 's/,/ /'\`; do
3911                                                 ldopts+=("\[$]{linkarg}")
3912                                         done
3913                                         ;;
3914                                 *.lib)
3915                                         ldopts+=("\[$]1")
3916                                         ;;
3917                                 -o)
3918                                         shift
3919                                         ldopts+=("-out:\[$]1")
3920                                         ;;
3921                                 *)
3922                                         clopts+=("\[$]1")
3923                                         ldopts+=("\[$]1")
3924                                         ;;
3925                         esac
3926                         shift
3927                 done
3928                 if [[ "\$isdll" -ne 0 ]]; then
3929                         for lib in \[$]{libs[[*]]}; do
3930                                 ldopts+=("\[$]lib.dll.lib")
3931                         done
3932                 else
3933                         for lib in \[$]{libs[[*]]}; do
3934                                 ldopts+=("\[$]lib.lib")
3935                         done
3936                 fi
3937                 cat <<-EOF
3938                 Creating program
3939                 ** ld options:   "\[$]{ldopts[[@]]}"
3940 EOF
3941                 exec \[$]LD \[$]{ldopts[[@]]}
3942 CF_EOF
3943                 chmod +x mk_prog.sh
3944                 LINK_PROGS="$SHELL ${rel_builddir}/mk_prog.sh"
3945                 LINK_TESTS="$SHELL ${rel_builddir}/mk_prog.sh"
3946                 ;;
3947         (mingw*)
3948                 cf_cv_shlib_version=mingw
3949                 cf_cv_shlib_version_infix=mingw
3950                 shlibdir=$bindir
3951                 MAKE_DLLS=
3952                 if test "$DFT_LWR_MODEL" = "shared" ; then
3953                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
3954                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3955                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
3956                 fi
3957                 CC_SHARED_OPTS=
3958                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3959                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3960                 cat >mk_shared_lib.sh <<-CF_EOF
3961                 #!$SHELL
3962                 SHARED_LIB=\[$]1
3963                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3964                 shift
3965                 cat <<-EOF
3966                 Linking shared library
3967                 ** SHARED_LIB \[$]SHARED_LIB
3968                 ** IMPORT_LIB \[$]IMPORT_LIB
3969 EOF
3970                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3971 CF_EOF
3972                 chmod +x mk_shared_lib.sh
3973                 ;;
3974         (openbsd[[2-9]].*|mirbsd*)
3975                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
3976                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3977                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3978                 fi
3979                 if test "$cf_cv_enable_rpath" = yes ; then
3980                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3981                 fi
3982                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3983                 CF_SHARED_SONAME
3984                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3985                 ;;
3986         (nskJ*)
3987                 CC_SHARED_OPTS=
3988                 MK_SHARED_LIB='${LD} -Wshared -Weld=-export_all -o $[@]'
3989                 ;;
3990         (nskL*)
3991                 CC_SHARED_OPTS=
3992                 MK_SHARED_LIB='${LD} -Wshared -Wxld=-export_all -o $[@]'
3993                 ;;
3994         (nto-qnx*|openbsd*|freebsd[[12]].*)
3995                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3996                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
3997                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3998                 ;;
3999         (dragonfly*|freebsd*)
4000                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
4001                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
4002                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
4003                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
4004                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
4005                 fi
4006                 CF_SHARED_SONAME
4007                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
4008                 ;;
4009         (netbsd*)
4010                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
4011                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
4012                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
4013                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
4014                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
4015                         if test "$cf_cv_shlib_version" = auto; then
4016                         if test -f /usr/libexec/ld.elf_so; then
4017                                 cf_cv_shlib_version=abi
4018                         else
4019                                 cf_cv_shlib_version=rel
4020                         fi
4021                         fi
4022                         CF_SHARED_SONAME
4023                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
4024                 else
4025                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -o $[@]'
4026                 fi
4027                 ;;
4028         (osf*|mls+*)
4029                 # tested with OSF/1 V3.2 and 'cc'
4030                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
4031                 # link with shared libs).
4032                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
4033                 case $host_os in
4034                 (osf4*)
4035                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
4036                         ;;
4037                 esac
4038                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
4039                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
4040                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
4041                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
4042                 fi
4043                 cf_cv_rm_so_locs=yes
4044                 ;;
4045         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
4046                 # tested with osr5.0.5
4047                 if test "$GCC" != yes; then
4048                         CC_SHARED_OPTS='-belf -KPIC'
4049                 fi
4050                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
4051                 if test "$cf_cv_enable_rpath" = yes ; then
4052                         # only way is to set LD_RUN_PATH but no switch for it
4053                         RUN_PATH=$libdir
4054                 fi
4055                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
4056                 LINK_PROGS='LD_RUN_PATH=${libdir}'
4057                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
4058                 ;;
4059         (sunos4*)
4060                 # tested with SunOS 4.1.1 and gcc 2.7.0
4061                 if test "$GCC" != yes; then
4062                         CC_SHARED_OPTS='-KPIC'
4063                 fi
4064                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
4065                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
4066                 ;;
4067         (solaris2*)
4068                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
4069                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
4070                 if test "$DFT_LWR_MODEL" = "shared" ; then
4071                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
4072                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
4073                 fi
4074                 if test "$cf_cv_enable_rpath" = yes ; then
4075                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
4076                 fi
4077                 CF_SHARED_SONAME
4078                 if test "$GCC" != yes; then
4079                         cf_save_CFLAGS="$CFLAGS"
4080                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
4081                         do
4082                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
4083                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
4084                         done
4085                         CFLAGS="$cf_save_CFLAGS"
4086                         CC_SHARED_OPTS=$cf_shared_opts
4087                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
4088                 else
4089                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
4090                 fi
4091                 ;;
4092         (sysv5uw7*|unix_sv*)
4093                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
4094                 if test "$GCC" != yes; then
4095                         CC_SHARED_OPTS='-KPIC'
4096                 fi
4097                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
4098                 ;;
4099         (*)
4100                 CC_SHARED_OPTS='unknown'
4101                 MK_SHARED_LIB='echo unknown'
4102                 ;;
4103         esac
4104
4105         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
4106         case "$cf_cv_shlib_version" in
4107         (rel|abi)
4108                 case "$MK_SHARED_LIB" in
4109                 (*'-o $[@]')
4110                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
4111                         ;;
4112                 (*)
4113                         AC_MSG_WARN(ignored --with-shlib-version)
4114                         ;;
4115                 esac
4116                 ;;
4117         esac
4118
4119         if test -n "$cf_try_cflags"
4120         then
4121 cat > conftest.$ac_ext <<EOF
4122 #line __oline__ "${as_me:-configure}"
4123 #include <stdio.h>
4124 int main(int argc, char *argv[[]])
4125 {
4126         printf("hello\n");
4127         return (argv[[argc-1]] == 0) ;
4128 }
4129 EOF
4130                 cf_save_CFLAGS="$CFLAGS"
4131                 for cf_opt in $cf_try_cflags
4132                 do
4133                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
4134                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
4135                         if AC_TRY_EVAL(ac_compile); then
4136                                 AC_MSG_RESULT(yes)
4137                                 cf_save_CFLAGS="$CFLAGS"
4138                         else
4139                                 AC_MSG_RESULT(no)
4140                         fi
4141                 done
4142                 CFLAGS="$cf_save_CFLAGS"
4143         fi
4144
4145
4146         # RPATH_LIST is a colon-separated list of directories
4147         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
4148         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
4149
4150         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
4151
4152         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
4153         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
4154
4155         AC_SUBST(CC_SHARED_OPTS)
4156         AC_SUBST(LD_RPATH_OPT)
4157         AC_SUBST(LD_SHARED_OPTS)
4158         AC_SUBST(MK_SHARED_LIB)
4159         AC_SUBST(RM_SHARED_OPTS)
4160
4161         AC_SUBST(LINK_PROGS)
4162         AC_SUBST(LINK_TESTS)
4163
4164         AC_SUBST(EXTRA_LDFLAGS)
4165         AC_SUBST(LOCAL_LDFLAGS)
4166         AC_SUBST(LOCAL_LDFLAGS2)
4167
4168         AC_SUBST(INSTALL_LIB)
4169         AC_SUBST(RPATH_LIST)
4170 ])dnl
4171 dnl ---------------------------------------------------------------------------
4172 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
4173 dnl ----------------
4174 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
4175 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
4176 dnl option.
4177 dnl
4178 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
4179 dnl If missing, use "rel".
4180 define([CF_SHARED_SONAME],
4181 [
4182         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
4183         if test "$cf_cv_shlib_version" = rel; then
4184                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
4185         else
4186                 cf_cv_shared_soname='`basename $[@]`'
4187         fi
4188 ])
4189 dnl ---------------------------------------------------------------------------
4190 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
4191 dnl --------------
4192 dnl     Remove "-g" option from the compiler options
4193 AC_DEFUN([CF_STRIP_G_OPT],
4194 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
4195 dnl ---------------------------------------------------------------------------
4196 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
4197 dnl --------------
4198 dnl Construct a search-list for a nonstandard header/lib-file
4199 dnl     $1 = the variable to return as result
4200 dnl     $2 = the package name
4201 dnl     $3 = the subdirectory, e.g., bin, include or lib
4202 AC_DEFUN([CF_SUBDIR_PATH],
4203 [
4204 $1=
4205
4206 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
4207
4208 for cf_subdir_prefix in \
4209         /usr \
4210         /usr/local \
4211         /usr/pkg \
4212         /opt \
4213         /opt/local \
4214         [$]HOME
4215 do
4216         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
4217 done
4218 ])dnl
4219 dnl ---------------------------------------------------------------------------
4220 dnl CF_TERM_HEADER version: 5 updated: 2020/03/19 20:23:48
4221 dnl --------------
4222 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
4223 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
4224 dnl but some packagers change this, breaking various applications.
4225 AC_DEFUN([CF_TERM_HEADER],[
4226 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
4227 case ${cf_cv_ncurses_header} in
4228 (*/ncurses.h|*/ncursesw.h)
4229         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
4230         ;;
4231 (*)
4232         cf_term_header=term.h
4233         ;;
4234 esac
4235
4236 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
4237 do
4238 AC_TRY_COMPILE([#include <stdio.h>
4239 #include <${cf_cv_ncurses_header:-curses.h}>
4240 #include <$cf_test>
4241 ],[int x = auto_left_margin; (void)x],[
4242         cf_cv_term_header="$cf_test"],[
4243         cf_cv_term_header=unknown
4244         ])
4245         test "$cf_cv_term_header" != unknown && break
4246 done
4247 ])
4248
4249 # Set definitions to allow ifdef'ing to accommodate subdirectories
4250
4251 case $cf_cv_term_header in
4252 (*term.h)
4253         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
4254         ;;
4255 esac
4256
4257 case $cf_cv_term_header in
4258 (ncurses/term.h)
4259         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
4260         ;;
4261 (ncursesw/term.h)
4262         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
4263         ;;
4264 esac
4265 ])dnl
4266 dnl ---------------------------------------------------------------------------
4267 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
4268 dnl ---------------
4269 dnl Define a top_builddir symbol, for applications that need an absolute path.
4270 AC_DEFUN([CF_TOP_BUILDDIR],
4271 [
4272 top_builddir=ifelse($1,,`pwd`,$1)
4273 AC_SUBST(top_builddir)
4274 ])dnl
4275 dnl ---------------------------------------------------------------------------
4276 dnl CF_TRY_XOPEN_SOURCE version: 2 updated: 2018/06/20 20:23:13
4277 dnl -------------------
4278 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
4279 dnl can define it successfully.
4280 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
4281 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
4282         AC_TRY_COMPILE([
4283 #include <stdlib.h>
4284 #include <string.h>
4285 #include <sys/types.h>
4286 ],[
4287 #ifndef _XOPEN_SOURCE
4288 make an error
4289 #endif],
4290         [cf_cv_xopen_source=no],
4291         [cf_save="$CPPFLAGS"
4292          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
4293          AC_TRY_COMPILE([
4294 #include <stdlib.h>
4295 #include <string.h>
4296 #include <sys/types.h>
4297 ],[
4298 #ifdef _XOPEN_SOURCE
4299 make an error
4300 #endif],
4301         [cf_cv_xopen_source=no],
4302         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
4303         CPPFLAGS="$cf_save"
4304         ])
4305 ])
4306
4307 if test "$cf_cv_xopen_source" != no ; then
4308         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
4309         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
4310         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
4311         CF_ADD_CFLAGS($cf_temp_xopen_source)
4312 fi
4313 ])
4314 dnl ---------------------------------------------------------------------------
4315 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
4316 dnl --------
4317 dnl Make an uppercase version of a variable
4318 dnl $1=uppercase($2)
4319 AC_DEFUN([CF_UPPER],
4320 [
4321 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4322 ])dnl
4323 dnl ---------------------------------------------------------------------------
4324 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
4325 dnl -----------
4326 dnl Check for multibyte support, and if not found, utf8 compatibility library
4327 AC_DEFUN([CF_UTF8_LIB],
4328 [
4329 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
4330         cf_save_LIBS="$LIBS"
4331         AC_TRY_LINK([
4332 #include <stdlib.h>],[putwc(0,0);],
4333         [cf_cv_utf8_lib=yes],
4334         [CF_FIND_LINKAGE([
4335 #include <libutf8.h>],[putwc(0,0);],utf8,
4336                 [cf_cv_utf8_lib=add-on],
4337                 [cf_cv_utf8_lib=no])
4338 ])])
4339
4340 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
4341 # ncurses/ncursesw:
4342 if test "$cf_cv_utf8_lib" = "add-on" ; then
4343         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
4344         CF_ADD_INCDIR($cf_cv_header_path_utf8)
4345         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
4346         CF_ADD_LIBS($cf_cv_library_file_utf8)
4347 fi
4348 ])dnl
4349 dnl ---------------------------------------------------------------------------
4350 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
4351 dnl ----------
4352 dnl Use AC_VERBOSE w/o the warnings
4353 AC_DEFUN([CF_VERBOSE],
4354 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
4355 CF_MSG_LOG([$1])
4356 ])dnl
4357 dnl ---------------------------------------------------------------------------
4358 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
4359 dnl ---------------
4360 dnl Check for compiler-support for weak symbols.
4361 dnl This works with "recent" gcc.
4362 AC_DEFUN([CF_WEAK_SYMBOLS],[
4363 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
4364
4365 AC_TRY_COMPILE([
4366 #include <stdio.h>],
4367 [
4368 #if defined(__GNUC__)
4369 #  if defined __USE_ISOC99
4370 #    define _cat_pragma(exp)    _Pragma(#exp)
4371 #    define _weak_pragma(exp)   _cat_pragma(weak name)
4372 #  else
4373 #    define _weak_pragma(exp)
4374 #  endif
4375 #  define _declare(name)        __extension__ extern __typeof__(name) name
4376 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
4377 #endif
4378
4379 weak_symbol(fopen);
4380 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
4381 ])
4382 ])dnl
4383 dnl ---------------------------------------------------------------------------
4384 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
4385 dnl --------------------
4386 dnl Command-line option to specify the Ada95 compiler.
4387 AC_DEFUN([CF_WITH_ADA_COMPILER],[
4388 AC_MSG_CHECKING(for ada-compiler)
4389 AC_ARG_WITH(ada-compiler,
4390         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
4391         [cf_ada_compiler=$withval],
4392         [cf_ada_compiler=gnatmake])
4393 AC_SUBST(cf_ada_compiler)
4394 AC_MSG_RESULT($cf_ada_compiler)
4395 ])dnl
4396 dnl ---------------------------------------------------------------------------
4397 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
4398 dnl -------------------
4399 dnl Command-line option to specify where Ada includes will install.
4400 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
4401 AC_MSG_CHECKING(for ada-include)
4402 CF_WITH_PATH(ada-include,
4403    [  --with-ada-include=DIR  Ada includes are in DIR],
4404    ADA_INCLUDE,
4405    PREFIX/share/ada/adainclude,
4406    [$]prefix/share/ada/adainclude)
4407 AC_SUBST(ADA_INCLUDE)
4408 AC_MSG_RESULT($ADA_INCLUDE)
4409 ])dnl
4410 dnl ---------------------------------------------------------------------------
4411 dnl CF_WITH_ADA_LIBNAME version: 1 updated: 2019/09/07 18:59:41
4412 dnl -------------------
4413 dnl CF_WITH_ADA_LIBNAME
4414 dnl -------------------
4415 dnl Command-line option to specify how to name the resulting Ada library.
4416 dnl $1 = default value
4417 AC_DEFUN([CF_WITH_ADA_LIBNAME],[
4418 AC_MSG_CHECKING(for ada-libname)
4419 AC_ARG_WITH(ada-libname,
4420    [  --with-ada-libname=XXX  override default Ada library-name],
4421    ADA_LIBNAME=[$]withval,
4422    ADA_LIBNAME=$1)
4423 case "x$ADA_LIBNAME" in
4424 (x|xyes|xno)
4425         ADA_LIBNAME=$1
4426         ;;
4427 esac
4428 AC_SUBST(ADA_LIBNAME)
4429 AC_MSG_RESULT($ADA_LIBNAME)
4430 ])dnl
4431 dnl ---------------------------------------------------------------------------
4432 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
4433 dnl -------------------
4434 dnl Command-line option to specify where Ada objects will install.
4435 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
4436 AC_MSG_CHECKING(for ada-objects)
4437 CF_WITH_PATH(ada-objects,
4438    [  --with-ada-objects=DIR  Ada objects are in DIR],
4439    ADA_OBJECTS,
4440    PREFIX/lib/ada/adalib,
4441    [$]prefix/lib/ada/adalib)
4442 AC_SUBST(ADA_OBJECTS)
4443 AC_MSG_RESULT($ADA_OBJECTS)
4444 ])dnl
4445 dnl ---------------------------------------------------------------------------
4446 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
4447 dnl ---------------------
4448 dnl Command-line option to specify if an Ada95 shared-library should be built,
4449 dnl and optionally what its soname should be.
4450 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
4451 AC_REQUIRE([CF_GNAT_PROJECTS])
4452 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
4453 AC_ARG_WITH(ada-sharedlib,
4454         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
4455         [with_ada_sharedlib=$withval],
4456         [with_ada_sharedlib=no])
4457 AC_MSG_RESULT($with_ada_sharedlib)
4458
4459 if test "x$with_ada_sharedlib" != xno
4460 then
4461         if test "x$cf_gnat_projects" != xyes
4462         then
4463                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
4464                 with_ada_sharedlib=no
4465         fi
4466 fi
4467
4468 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
4469 MAKE_ADA_SHAREDLIB="#"
4470
4471 if test "x$with_ada_sharedlib" != xno
4472 then
4473         MAKE_ADA_SHAREDLIB=
4474         if test "x$with_ada_sharedlib" != xyes
4475         then
4476                 ADA_SHAREDLIB="$with_ada_sharedlib"
4477         fi
4478 fi
4479
4480 AC_SUBST(ADA_SHAREDLIB)
4481 AC_SUBST(MAKE_ADA_SHAREDLIB)
4482 ])dnl
4483 dnl ---------------------------------------------------------------------------
4484 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
4485 dnl ------------------
4486 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
4487 dnl libraries.
4488 AC_DEFUN([CF_WITH_CURSES_DIR],[
4489
4490 AC_MSG_CHECKING(for specific curses-directory)
4491 AC_ARG_WITH(curses-dir,
4492         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
4493         [cf_cv_curses_dir=$withval],
4494         [cf_cv_curses_dir=no])
4495 AC_MSG_RESULT($cf_cv_curses_dir)
4496
4497 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
4498 then
4499         CF_PATH_SYNTAX(withval)
4500         if test -d "$cf_cv_curses_dir"
4501         then
4502                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
4503                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
4504         fi
4505 fi
4506 ])dnl
4507 dnl ---------------------------------------------------------------------------
4508 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
4509 dnl ------------------
4510 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
4511 dnl "lib" prefix, e.g., because it used the dll naming convention.
4512 dnl
4513 dnl $1 = variable to set
4514 AC_DEFUN([CF_WITH_LIB_PREFIX],
4515 [
4516 AC_MSG_CHECKING(if you want to have a library-prefix)
4517 AC_ARG_WITH(lib-prefix,
4518         [  --with-lib-prefix       override library-prefix],
4519         [with_lib_prefix=$withval],
4520         [with_lib_prefix=auto])
4521 AC_MSG_RESULT($with_lib_prefix)
4522
4523 if test $with_lib_prefix = auto
4524 then
4525         CF_LIB_PREFIX($1)
4526 elif test $with_lib_prefix = no
4527 then
4528         LIB_PREFIX=
4529 else
4530         LIB_PREFIX=$with_lib_prefix
4531 fi
4532 ])dnl
4533 dnl ---------------------------------------------------------------------------
4534 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
4535 dnl ------------
4536 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
4537 dnl defaulting to yes/no.
4538 dnl
4539 dnl $1 = option name
4540 dnl $2 = help-text
4541 dnl $3 = environment variable to set
4542 dnl $4 = default value, shown in the help-message, must be a constant
4543 dnl $5 = default value, if it's an expression & cannot be in the help-message
4544 dnl
4545 AC_DEFUN([CF_WITH_PATH],
4546 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
4547 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
4548 if ifelse([$5],,true,[test -n "$5"]) ; then
4549 CF_PATH_SYNTAX(withval)
4550 fi
4551 eval $3="$withval"
4552 AC_SUBST($3)dnl
4553 ])dnl
4554 dnl ---------------------------------------------------------------------------
4555 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
4556 dnl -------------------------
4557 dnl Allow the choice of the pkg-config library directory to be overridden.
4558 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
4559
4560 case $PKG_CONFIG in
4561 (no|none|yes)
4562         AC_MSG_CHECKING(for pkg-config library directory)
4563         ;;
4564 (*)
4565         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
4566         ;;
4567 esac
4568
4569 PKG_CONFIG_LIBDIR=no
4570 AC_ARG_WITH(pkg-config-libdir,
4571         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
4572         [PKG_CONFIG_LIBDIR=$withval],
4573         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
4574
4575 case x$PKG_CONFIG_LIBDIR in
4576 (x/*)
4577         ;;
4578 (xyes)
4579         # Look for the library directory using the same prefix as the executable
4580         if test "x$PKG_CONFIG" = xnone
4581         then
4582                 cf_path=$prefix
4583         else
4584                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
4585         fi
4586
4587         # If you don't like using the default architecture, you have to specify the
4588         # intended library directory and corresponding compiler/linker options.
4589         #
4590         # This case allows for Debian's 2014-flavor of multiarch, along with the
4591         # most common variations before that point.  Some other variants spell the
4592         # directory differently, e.g., "pkg-config", and put it in unusual places.
4593         # pkg-config has always been poorly standardized, which is ironic...
4594         case x`(arch) 2>/dev/null` in
4595         (*64)
4596                 cf_search_path="\
4597                         $cf_path/lib/*64-linux-gnu \
4598                         $cf_path/share \
4599                         $cf_path/lib64 \
4600                         $cf_path/lib32 \
4601                         $cf_path/lib"
4602                 ;;
4603         (*)
4604                 cf_search_path="\
4605                         $cf_path/lib/*-linux-gnu \
4606                         $cf_path/share \
4607                         $cf_path/lib32 \
4608                         $cf_path/lib \
4609                         $cf_path/libdata"
4610                 ;;
4611         esac
4612
4613         CF_VERBOSE(list...)
4614         for cf_config in $cf_search_path
4615         do
4616                 CF_VERBOSE(checking $cf_config/pkgconfig)
4617                 if test -d $cf_config/pkgconfig
4618                 then
4619                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
4620                         AC_MSG_CHECKING(done)
4621                         break
4622                 fi
4623         done
4624         ;;
4625 (*)
4626         ;;
4627 esac
4628
4629 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
4630         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
4631 fi
4632
4633 AC_SUBST(PKG_CONFIG_LIBDIR)
4634 ])dnl
4635 dnl ---------------------------------------------------------------------------
4636 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
4637 dnl ---------------
4638 dnl Check for POSIX thread library.
4639 AC_DEFUN([CF_WITH_PTHREAD],
4640 [
4641 AC_MSG_CHECKING(if you want to link with the pthread library)
4642 AC_ARG_WITH(pthread,
4643         [  --with-pthread          use POSIX thread library],
4644         [with_pthread=$withval],
4645         [with_pthread=no])
4646 AC_MSG_RESULT($with_pthread)
4647
4648 if test "$with_pthread" != no ; then
4649         AC_CHECK_HEADER(pthread.h,[
4650         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
4651
4652         for cf_lib_pthread in pthread c_r
4653         do
4654             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
4655             cf_save_LIBS="$LIBS"
4656             CF_ADD_LIB($cf_lib_pthread)
4657             AC_TRY_LINK([
4658 #include <pthread.h>
4659 ],[
4660                 int rc = pthread_create(0,0,0,0);
4661                 int r2 = pthread_mutexattr_settype(0, 0);
4662 ],[with_pthread=yes],[with_pthread=no])
4663             LIBS="$cf_save_LIBS"
4664             AC_MSG_RESULT($with_pthread)
4665             test "$with_pthread" = yes && break
4666         done
4667
4668         if test "$with_pthread" = yes ; then
4669             CF_ADD_LIB($cf_lib_pthread)
4670             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
4671         else
4672             AC_MSG_ERROR(Cannot link with pthread library)
4673         fi
4674         ])
4675 fi
4676 ])
4677 dnl ---------------------------------------------------------------------------
4678 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
4679 dnl ---------------
4680 dnl For testing, override the derived host system-type which is used to decide
4681 dnl things such as the linker commands used to build shared libraries.  This is
4682 dnl normally chosen automatically based on the type of system which you are
4683 dnl building on.  We use it for testing the configure script.
4684 dnl
4685 dnl This is different from the --host option: it is used only for testing parts
4686 dnl of the configure script which would not be reachable with --host since that
4687 dnl relies on the build environment being real, rather than mocked up.
4688 AC_DEFUN([CF_WITH_SYSTYPE],[
4689 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
4690 AC_ARG_WITH(system-type,
4691         [  --with-system-type=XXX  test: override derived host system-type],
4692 [AC_MSG_WARN(overriding system type to $withval)
4693         cf_cv_system_name=$withval
4694         host_os=$withval
4695 ])
4696 ])dnl
4697 dnl ---------------------------------------------------------------------------
4698 dnl CF_XOPEN_SOURCE version: 55 updated: 2018/12/31 20:46:17
4699 dnl ---------------
4700 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
4701 dnl or adapt to the vendor's definitions to get equivalent functionality,
4702 dnl without losing the common non-POSIX features.
4703 dnl
4704 dnl Parameters:
4705 dnl     $1 is the nominal value for _XOPEN_SOURCE
4706 dnl     $2 is the nominal value for _POSIX_C_SOURCE
4707 AC_DEFUN([CF_XOPEN_SOURCE],[
4708 AC_REQUIRE([AC_CANONICAL_HOST])
4709 AC_REQUIRE([CF_POSIX_VISIBLE])
4710
4711 if test "$cf_cv_posix_visible" = no; then
4712
4713 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
4714 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
4715 cf_xopen_source=
4716
4717 case $host_os in
4718 (aix[[4-7]]*)
4719         cf_xopen_source="-D_ALL_SOURCE"
4720         ;;
4721 (msys)
4722         cf_XOPEN_SOURCE=600
4723         ;;
4724 (darwin[[0-8]].*)
4725         cf_xopen_source="-D_APPLE_C_SOURCE"
4726         ;;
4727 (darwin*)
4728         cf_xopen_source="-D_DARWIN_C_SOURCE"
4729         cf_XOPEN_SOURCE=
4730         ;;
4731 (freebsd*|dragonfly*|midnightbsd*)
4732         # 5.x headers associate
4733         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
4734         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
4735         cf_POSIX_C_SOURCE=200112L
4736         cf_XOPEN_SOURCE=600
4737         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
4738         ;;
4739 (hpux11*)
4740         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
4741         ;;
4742 (hpux*)
4743         cf_xopen_source="-D_HPUX_SOURCE"
4744         ;;
4745 (irix[[56]].*)
4746         cf_xopen_source="-D_SGI_SOURCE"
4747         cf_XOPEN_SOURCE=
4748         ;;
4749 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
4750         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
4751         ;;
4752 (minix*)
4753         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
4754         ;;
4755 (mirbsd*)
4756         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
4757         cf_XOPEN_SOURCE=
4758         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4759         ;;
4760 (netbsd*)
4761         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
4762         ;;
4763 (openbsd[[4-9]]*)
4764         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
4765         cf_xopen_source="-D_BSD_SOURCE"
4766         cf_XOPEN_SOURCE=600
4767         ;;
4768 (openbsd*)
4769         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
4770         ;;
4771 (osf[[45]]*)
4772         cf_xopen_source="-D_OSF_SOURCE"
4773         ;;
4774 (nto-qnx*)
4775         cf_xopen_source="-D_QNX_SOURCE"
4776         ;;
4777 (sco*)
4778         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
4779         ;;
4780 (solaris2.*)
4781         cf_xopen_source="-D__EXTENSIONS__"
4782         cf_cv_xopen_source=broken
4783         ;;
4784 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
4785         cf_XOPEN_SOURCE=
4786         cf_POSIX_C_SOURCE=
4787         ;;
4788 (*)
4789         CF_TRY_XOPEN_SOURCE
4790         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4791         ;;
4792 esac
4793
4794 if test -n "$cf_xopen_source" ; then
4795         CF_ADD_CFLAGS($cf_xopen_source,true)
4796 fi
4797
4798 dnl In anything but the default case, we may have system-specific setting
4799 dnl which is still not guaranteed to provide all of the entrypoints that
4800 dnl _XOPEN_SOURCE would yield.
4801 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
4802         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
4803         AC_TRY_COMPILE([#include <stdlib.h>],[
4804 #ifndef _XOPEN_SOURCE
4805 make an error
4806 #endif],
4807         [cf_XOPEN_SOURCE_set=yes],
4808         [cf_XOPEN_SOURCE_set=no])
4809         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
4810         if test $cf_XOPEN_SOURCE_set = yes
4811         then
4812                 AC_TRY_COMPILE([#include <stdlib.h>],[
4813 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
4814 make an error
4815 #endif],
4816                 [cf_XOPEN_SOURCE_set_ok=yes],
4817                 [cf_XOPEN_SOURCE_set_ok=no])
4818                 if test $cf_XOPEN_SOURCE_set_ok = no
4819                 then
4820                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
4821                 fi
4822         else
4823                 CF_TRY_XOPEN_SOURCE
4824         fi
4825 fi
4826 fi # cf_cv_posix_visible
4827 ])