Ada95/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2020,2021 Thomas E. Dickey                                *
   3 dnl Copyright 2010-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey
  31 dnl
  32 dnl $Id: aclocal.m4,v 1.173 2021/03/23 00:37:21 tom Exp $
  33 dnl Macros used in NCURSES Ada95 auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See these pages for additional information:
  40 dnl             https://invisible-island.net/autoconf/
  41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  42 dnl
  43 dnl ---------------------------------------------------------------------------
  44 dnl ---------------------------------------------------------------------------
  45 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
  46 dnl ------------------
  47 dnl Conditionally generate script according to whether we're using a given autoconf.
  48 dnl
  49 dnl $1 = version to compare against
  50 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  51 dnl $3 = code to use if AC_ACVERSION is older than $1.
  52 define([CF_ACVERSION_CHECK],
  53 [
  54 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
  55 ifdef([m4_version_compare],
  56 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  57 [CF_ACVERSION_COMPARE(
  58 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  59 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  60 dnl ---------------------------------------------------------------------------
  61 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  62 dnl --------------------
  63 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  64 dnl                      MAJOR2, MINOR2, TERNARY2,
  65 dnl                      PRINTABLE2, not FOUND, FOUND)
  66 define([CF_ACVERSION_COMPARE],
  67 [ifelse(builtin([eval], [$2 < $5]), 1,
  68 [ifelse([$8], , ,[$8])],
  69 [ifelse([$9], , ,[$9])])])dnl
  70 dnl ---------------------------------------------------------------------------
  71 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
  72 dnl -------------------
  73 dnl Construct the list of include-options for the C programs in the Ada95
  74 dnl binding.
  75 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  76 [
  77 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  78 if test "$srcdir" != "."; then
  79         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  80 fi
  81 if test "$GCC" != yes; then
  82         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  83 elif test "$includedir" != "/usr/include"; then
  84         if test "$includedir" = '${prefix}/include' ; then
  85                 if test x$prefix != x/usr ; then
  86                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  87                 fi
  88         else
  89                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  90         fi
  91 fi
  92 AC_SUBST(ACPPFLAGS)
  93 ])dnl
  94 dnl ---------------------------------------------------------------------------
  95 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
  96 dnl ---------------
  97 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
  98 AC_DEFUN([CF_ADD_ADAFLAGS],[
  99         ADAFLAGS="$ADAFLAGS $1"
 100         AC_SUBST(ADAFLAGS)
 101 ])dnl
 102 dnl ---------------------------------------------------------------------------
 103 dnl CF_ADD_CFLAGS version: 15 updated: 2020/12/31 10:54:15
 104 dnl -------------
 105 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 106 dnl $1 = flags to add
 107 dnl $2 = if given makes this macro verbose.
 108 dnl
 109 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 110 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 111 dnl confused by the quotes (which require backslashes to keep them usable).
 112 AC_DEFUN([CF_ADD_CFLAGS],
 113 [
 114 cf_fix_cppflags=no
 115 cf_new_cflags=
 116 cf_new_cppflags=
 117 cf_new_extra_cppflags=
 118
 119 for cf_add_cflags in $1
 120 do
 121 case "$cf_fix_cppflags" in
 122 (no)
 123         case "$cf_add_cflags" in
 124         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 125                 case "$cf_add_cflags" in
 126                 (-D*)
 127                         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 128
 129                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 130                                 && test -z "${cf_tst_cflags}" \
 131                                 && cf_fix_cppflags=yes
 132
 133                         if test "$cf_fix_cppflags" = yes ; then
 134                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 135                                 continue
 136                         elif test "${cf_tst_cflags}" = "\"'" ; then
 137                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 138                                 continue
 139                         fi
 140                         ;;
 141                 esac
 142                 case "$CPPFLAGS" in
 143                 (*$cf_add_cflags)
 144                         ;;
 145                 (*)
 146                         case "$cf_add_cflags" in
 147                         (-D*)
 148                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 149                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 150                                 ;;
 151                         esac
 152                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 153                         ;;
 154                 esac
 155                 ;;
 156         (*)
 157                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 158                 ;;
 159         esac
 160         ;;
 161 (yes)
 162         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 163
 164         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^[[^"]]*"'\''//'`
 165
 166         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 167                 && test -z "${cf_tst_cflags}" \
 168                 && cf_fix_cppflags=no
 169         ;;
 170 esac
 171 done
 172
 173 if test -n "$cf_new_cflags" ; then
 174         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 175         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 176 fi
 177
 178 if test -n "$cf_new_cppflags" ; then
 179         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 180         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 181 fi
 182
 183 if test -n "$cf_new_extra_cppflags" ; then
 184         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 185         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 186 fi
 187
 188 AC_SUBST(EXTRA_CPPFLAGS)
 189
 190 ])dnl
 191 dnl ---------------------------------------------------------------------------
 192 dnl CF_ADD_INCDIR version: 16 updated: 2020/12/31 20:19:42
 193 dnl -------------
 194 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 195 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 196 dnl but old versions (and some misinstalled ones) need that.  To make things
 197 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 198 dnl the include-path).
 199 AC_DEFUN([CF_ADD_INCDIR],
 200 [
 201 if test -n "$1" ; then
 202   for cf_add_incdir in $1
 203   do
 204         while test "$cf_add_incdir" != /usr/include
 205         do
 206           if test -d "$cf_add_incdir"
 207           then
 208                 cf_have_incdir=no
 209                 if test -n "$CFLAGS$CPPFLAGS" ; then
 210                   # a loop is needed to ensure we can add subdirs of existing dirs
 211                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 212                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 213                           cf_have_incdir=yes; break
 214                         fi
 215                   done
 216                 fi
 217
 218                 if test "$cf_have_incdir" = no ; then
 219                   if test "$cf_add_incdir" = /usr/local/include ; then
 220                         if test "$GCC" = yes
 221                         then
 222                           cf_save_CPPFLAGS=$CPPFLAGS
 223                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 224                           AC_TRY_COMPILE([#include <stdio.h>],
 225                                   [printf("Hello")],
 226                                   [],
 227                                   [cf_have_incdir=yes])
 228                           CPPFLAGS=$cf_save_CPPFLAGS
 229                         fi
 230                   fi
 231                 fi
 232
 233                 if test "$cf_have_incdir" = no ; then
 234                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 235                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 236
 237                   cf_top_incdir=`echo "$cf_add_incdir" | sed -e 's%/include/.*$%/include%'`
 238                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 239                   cf_add_incdir="$cf_top_incdir"
 240                 else
 241                   break
 242                 fi
 243           else
 244                 break
 245           fi
 246         done
 247   done
 248 fi
 249 ])dnl
 250 dnl ---------------------------------------------------------------------------
 251 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 252 dnl ----------
 253 dnl Add a library, used to enforce consistency.
 254 dnl
 255 dnl $1 = library to add, without the "-l"
 256 dnl $2 = variable to update (default $LIBS)
 257 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 258 dnl ---------------------------------------------------------------------------
 259 dnl CF_ADD_LIBDIR version: 11 updated: 2020/12/31 20:19:42
 260 dnl -------------
 261 dnl     Adds to the library-path
 262 dnl
 263 dnl     Some machines have trouble with multiple -L options.
 264 dnl
 265 dnl $1 is the (list of) directory(s) to add
 266 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 267 dnl
 268 AC_DEFUN([CF_ADD_LIBDIR],
 269 [
 270 if test -n "$1" ; then
 271         for cf_add_libdir in $1
 272         do
 273                 if test "$cf_add_libdir" = /usr/lib ; then
 274                         :
 275                 elif test -d "$cf_add_libdir"
 276                 then
 277                         cf_have_libdir=no
 278                         if test -n "$LDFLAGS$LIBS" ; then
 279                                 # a loop is needed to ensure we can add subdirs of existing dirs
 280                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 281                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 282                                                 cf_have_libdir=yes; break
 283                                         fi
 284                                 done
 285                         fi
 286                         if test "$cf_have_libdir" = no ; then
 287                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 288                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 289                         fi
 290                 fi
 291         done
 292 fi
 293 ])dnl
 294 dnl ---------------------------------------------------------------------------
 295 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 296 dnl -----------
 297 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 298 dnl prepended to an existing list, since their dependencies are assumed to
 299 dnl already exist in the list.
 300 dnl
 301 dnl $1 = libraries to add, with the "-l", etc.
 302 dnl $2 = variable to update (default $LIBS)
 303 AC_DEFUN([CF_ADD_LIBS],[
 304 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 305 # reverse order
 306 cf_add_0lib=
 307 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 308 # filter duplicates
 309 for cf_add_1lib in $cf_add_0lib; do
 310         for cf_add_2lib in $cf_add_libs; do
 311                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 312                         cf_add_1lib=
 313                         break
 314                 fi
 315         done
 316         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 317 done
 318 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 319 ])dnl
 320 dnl ---------------------------------------------------------------------------
 321 dnl CF_ADD_SUBDIR_PATH version: 5 updated: 2020/12/31 20:19:42
 322 dnl ------------------
 323 dnl Append to a search-list for a nonstandard header/lib-file
 324 dnl     $1 = the variable to return as result
 325 dnl     $2 = the package name
 326 dnl     $3 = the subdirectory, e.g., bin, include or lib
 327 dnl $4 = the directory under which we will test for subdirectories
 328 dnl $5 = a directory that we do not want $4 to match
 329 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 330 [
 331 test "x$4" != "x$5" && \
 332 test -d "$4" && \
 333 ifelse([$5],NONE,,[{ test -z "$5" || test "x$5" = xNONE || test "x$4" != "x$5"; } &&]) {
 334         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 335         test -d "$4/$3" &&          $1="[$]$1 $4/$3"
 336         test -d "$4/$3/$2" &&       $1="[$]$1 $4/$3/$2"
 337         test -d "$4/$3/$2/$3" &&    $1="[$]$1 $4/$3/$2/$3"
 338         test -d "$4/$2/$3" &&       $1="[$]$1 $4/$2/$3"
 339         test -d "$4/$2/$3/$2" &&    $1="[$]$1 $4/$2/$3/$2"
 340 }
 341 ])dnl
 342 dnl ---------------------------------------------------------------------------
 343 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 344 dnl --------------
 345 dnl use this macro for appending text without introducing an extra blank at
 346 dnl the beginning
 347 define([CF_APPEND_TEXT],
 348 [
 349         test -n "[$]$1" && $1="[$]$1 "
 350         $1="[$]{$1}$2"
 351 ])dnl
 352 dnl ---------------------------------------------------------------------------
 353 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 354 dnl --------------
 355 dnl Allow user to disable a normally-on option.
 356 AC_DEFUN([CF_ARG_DISABLE],
 357 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 358 dnl ---------------------------------------------------------------------------
 359 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 360 dnl -------------
 361 dnl Allow user to enable a normally-off option.
 362 AC_DEFUN([CF_ARG_ENABLE],
 363 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 364 dnl ---------------------------------------------------------------------------
 365 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 366 dnl -------------
 367 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 368 dnl values.
 369 dnl
 370 dnl Parameters:
 371 dnl $1 = option name
 372 dnl $2 = help-string
 373 dnl $3 = action to perform if option is not default
 374 dnl $4 = action if perform if option is default
 375 dnl $5 = default option value (either 'yes' or 'no')
 376 AC_DEFUN([CF_ARG_OPTION],
 377 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 378         if test "$enableval" != "$5" ; then
 379 ifelse([$3],,[    :]dnl
 380 ,[    $3]) ifelse([$4],,,[
 381         else
 382                 $4])
 383         fi],[enableval=$5 ifelse([$4],,,[
 384         $4
 385 ])dnl
 386 ])])dnl
 387 dnl ---------------------------------------------------------------------------
 388 dnl CF_AR_FLAGS version: 9 updated: 2021/01/01 13:31:04
 389 dnl -----------
 390 dnl Check for suitable "ar" (archiver) options for updating an archive.
 391 dnl
 392 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 393 dnl as well as a workaround for breakage of make's archive rules by the GNU
 394 dnl binutils "ar" program.
 395 AC_DEFUN([CF_AR_FLAGS],[
 396 AC_REQUIRE([CF_PROG_AR])
 397
 398 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 399         case "$cf_cv_system_name" in
 400         (*-msvc*)
 401                 cf_cv_ar_flags=''
 402                 cat >mk_static_lib.sh <<-EOF
 403                 #!$SHELL
 404                 MSVC_BIN="[$]AR"
 405                 out="\[$]1"
 406                 shift
 407                 exec \[$]MSVC_BIN -out:"\[$]out" \[$]@
 408                 EOF
 409                 chmod +x mk_static_lib.sh
 410                 AR=`pwd`/mk_static_lib.sh
 411                 ;;
 412         (*)
 413                 cf_cv_ar_flags=unknown
 414                 for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 415                 do
 416
 417                         # check if $ARFLAGS already contains this choice
 418                         if test "x$ARFLAGS" != "x" ; then
 419                                 cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 420                                 if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 421                                         cf_cv_ar_flags=
 422                                         break
 423                                 fi
 424                         fi
 425
 426                         rm -f "conftest.$ac_cv_objext"
 427                         rm -f conftest.a
 428
 429                         cat >"conftest.$ac_ext" <<EOF
 430 #line __oline__ "configure"
 431 int     testdata[[3]] = { 123, 456, 789 };
 432 EOF
 433                         if AC_TRY_EVAL(ac_compile) ; then
 434                                 echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 435                                 $AR $ARFLAGS "$cf_ar_flags" conftest.a "conftest.$ac_cv_objext" 2>&AC_FD_CC 1>/dev/null
 436                                 if test -f conftest.a ; then
 437                                         cf_cv_ar_flags="$cf_ar_flags"
 438                                         break
 439                                 fi
 440                         else
 441                                 CF_VERBOSE(cannot compile test-program)
 442                                 break
 443                         fi
 444                 done
 445                 rm -f conftest.a "conftest.$ac_ext" "conftest.$ac_cv_objext"
 446                 ;;
 447         esac
 448 ])
 449
 450 if test -n "$ARFLAGS" ; then
 451         if test -n "$cf_cv_ar_flags" ; then
 452                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 453         fi
 454 else
 455         ARFLAGS=$cf_cv_ar_flags
 456 fi
 457
 458 AC_SUBST(ARFLAGS)
 459 ])
 460 dnl ---------------------------------------------------------------------------
 461 dnl CF_BUILD_CC version: 9 updated: 2021/01/02 09:31:20
 462 dnl -----------
 463 dnl If we're cross-compiling, allow the user to override the tools and their
 464 dnl options.  The configure script is oriented toward identifying the host
 465 dnl compiler, etc., but we need a build compiler to generate parts of the
 466 dnl source.
 467 dnl
 468 dnl $1 = default for $CPPFLAGS
 469 dnl $2 = default for $LIBS
 470 AC_DEFUN([CF_BUILD_CC],[
 471 CF_ACVERSION_CHECK(2.52,,
 472         [AC_REQUIRE([CF_PROG_EXT])])
 473 if test "$cross_compiling" = yes ; then
 474
 475         # defaults that we might want to override
 476         : ${BUILD_CFLAGS:=''}
 477         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 478         : ${BUILD_LDFLAGS:=''}
 479         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 480         : ${BUILD_EXEEXT:='$x'}
 481         : ${BUILD_OBJEXT:='o'}
 482
 483         AC_ARG_WITH(build-cc,
 484                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 485                 [BUILD_CC="$withval"],
 486                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 487         AC_MSG_CHECKING(for native build C compiler)
 488         AC_MSG_RESULT($BUILD_CC)
 489
 490         AC_MSG_CHECKING(for native build C preprocessor)
 491         AC_ARG_WITH(build-cpp,
 492                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 493                 [BUILD_CPP="$withval"],
 494                 [BUILD_CPP='${BUILD_CC} -E'])
 495         AC_MSG_RESULT($BUILD_CPP)
 496
 497         AC_MSG_CHECKING(for native build C flags)
 498         AC_ARG_WITH(build-cflags,
 499                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 500                 [BUILD_CFLAGS="$withval"])
 501         AC_MSG_RESULT($BUILD_CFLAGS)
 502
 503         AC_MSG_CHECKING(for native build C preprocessor-flags)
 504         AC_ARG_WITH(build-cppflags,
 505                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 506                 [BUILD_CPPFLAGS="$withval"])
 507         AC_MSG_RESULT($BUILD_CPPFLAGS)
 508
 509         AC_MSG_CHECKING(for native build linker-flags)
 510         AC_ARG_WITH(build-ldflags,
 511                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 512                 [BUILD_LDFLAGS="$withval"])
 513         AC_MSG_RESULT($BUILD_LDFLAGS)
 514
 515         AC_MSG_CHECKING(for native build linker-libraries)
 516         AC_ARG_WITH(build-libs,
 517                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 518                 [BUILD_LIBS="$withval"])
 519         AC_MSG_RESULT($BUILD_LIBS)
 520
 521         # this assumes we're on Unix.
 522         BUILD_EXEEXT=
 523         BUILD_OBJEXT=o
 524
 525         : ${BUILD_CC:='${CC}'}
 526
 527         if { test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}'; } ; then
 528                 AC_MSG_ERROR([Cross-build requires two compilers.
 529 Use --with-build-cc to specify the native compiler.])
 530         fi
 531
 532 else
 533         : ${BUILD_CC:='${CC}'}
 534         : ${BUILD_CPP:='${CPP}'}
 535         : ${BUILD_CFLAGS:='${CFLAGS}'}
 536         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 537         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 538         : ${BUILD_LIBS:='${LIBS}'}
 539         : ${BUILD_EXEEXT:='$x'}
 540         : ${BUILD_OBJEXT:='o'}
 541 fi
 542
 543 AC_SUBST(BUILD_CC)
 544 AC_SUBST(BUILD_CPP)
 545 AC_SUBST(BUILD_CFLAGS)
 546 AC_SUBST(BUILD_CPPFLAGS)
 547 AC_SUBST(BUILD_LDFLAGS)
 548 AC_SUBST(BUILD_LIBS)
 549 AC_SUBST(BUILD_EXEEXT)
 550 AC_SUBST(BUILD_OBJEXT)
 551 ])dnl
 552 dnl ---------------------------------------------------------------------------
 553 dnl CF_C11_NORETURN version: 2 updated: 2021/03/22 20:37:21
 554 dnl ---------------
 555 AC_DEFUN([CF_C11_NORETURN],
 556 [
 557 AC_MSG_CHECKING(if you want to use C11 _Noreturn feature)
 558 CF_ARG_ENABLE(stdnoreturn,
 559         [  --enable-stdnoreturn    enable C11 _Noreturn feature for diagnostics],
 560         [enable_stdnoreturn=yes],
 561         [enable_stdnoreturn=no])
 562 AC_MSG_RESULT($enable_stdnoreturn)
 563
 564 if test $enable_stdnoreturn = yes; then
 565 AC_CACHE_CHECK([for C11 _Noreturn feature], cf_cv_c11_noreturn,
 566         [AC_TRY_COMPILE([
 567 #include <stdio.h>
 568 #include <stdlib.h>
 569 #include <stdnoreturn.h>
 570 static void giveup(void) { exit(0); }
 571         ],
 572         [if (feof(stdin)) giveup()],
 573         cf_cv_c11_noreturn=yes,
 574         cf_cv_c11_noreturn=no)
 575         ])
 576 else
 577         cf_cv_c11_noreturn=no,
 578 fi
 579
 580 if test "$cf_cv_c11_noreturn" = yes; then
 581         AC_DEFINE(HAVE_STDNORETURN_H, 1)
 582         AC_DEFINE_UNQUOTED(STDC_NORETURN,_Noreturn,[Define if C11 _Noreturn keyword is supported])
 583         HAVE_STDNORETURN_H=1
 584 else
 585         HAVE_STDNORETURN_H=0
 586 fi
 587
 588 AC_SUBST(HAVE_STDNORETURN_H)
 589 ])dnl
 590 dnl ---------------------------------------------------------------------------
 591 dnl CF_CC_ENV_FLAGS version: 10 updated: 2020/12/31 18:40:20
 592 dnl ---------------
 593 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 594 dnl into CC.  This will not help with broken scripts that wrap the compiler
 595 dnl with options, but eliminates a more common category of user confusion.
 596 dnl
 597 dnl In particular, it addresses the problem of being able to run the C
 598 dnl preprocessor in a consistent manner.
 599 dnl
 600 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 601 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 602 dnl outweighs that limitation.
 603 AC_DEFUN([CF_CC_ENV_FLAGS],
 604 [
 605 # This should have been defined by AC_PROG_CC
 606 : "${CC:=cc}"
 607
 608 AC_MSG_CHECKING(\$CFLAGS variable)
 609 case "x$CFLAGS" in
 610 (*-[[IUD]]*)
 611         AC_MSG_RESULT(broken)
 612         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 613         cf_flags="$CFLAGS"
 614         CFLAGS=
 615         for cf_arg in $cf_flags
 616         do
 617                 CF_ADD_CFLAGS($cf_arg)
 618         done
 619         ;;
 620 (*)
 621         AC_MSG_RESULT(ok)
 622         ;;
 623 esac
 624
 625 AC_MSG_CHECKING(\$CC variable)
 626 case "$CC" in
 627 (*[[\ \ ]]-*)
 628         AC_MSG_RESULT(broken)
 629         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 630         # humor him...
 631         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 632         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 633         CC="$cf_prog"
 634         for cf_arg in $cf_flags
 635         do
 636                 case "x$cf_arg" in
 637                 (x-[[IUDfgOW]]*)
 638                         CF_ADD_CFLAGS($cf_arg)
 639                         ;;
 640                 (*)
 641                         CC="$CC $cf_arg"
 642                         ;;
 643                 esac
 644         done
 645         CF_VERBOSE(resulting CC: '$CC')
 646         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 647         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 648         ;;
 649 (*)
 650         AC_MSG_RESULT(ok)
 651         ;;
 652 esac
 653 ])dnl
 654 dnl ---------------------------------------------------------------------------
 655 dnl CF_CFG_DEFAULTS version: 16 updated: 2021/01/04 19:33:05
 656 dnl ---------------
 657 dnl Determine the default configuration into which we'll install ncurses.  This
 658 dnl can be overridden by the user's command-line options.  There's two items to
 659 dnl look for:
 660 dnl     1. the prefix (e.g., /usr)
 661 dnl     2. the header files (e.g., /usr/include/ncurses)
 662 dnl We'll look for a previous installation of ncurses and use the same defaults.
 663 dnl
 664 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 665 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 666 dnl programs from a vendor's.
 667 AC_DEFUN([CF_CFG_DEFAULTS],
 668 [AC_REQUIRE([AC_PROG_FGREP])dnl
 669
 670 AC_MSG_CHECKING(for prefix)
 671 if test "x$prefix" = "xNONE" ; then
 672         case "$cf_cv_system_name" in
 673                 # non-vendor systems don't have a conflict
 674         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 675                 prefix=/usr
 676                 ;;
 677         (*)     prefix=$ac_default_prefix
 678                 ;;
 679         esac
 680 fi
 681 AC_MSG_RESULT($prefix)
 682
 683 if test "x$prefix" = "xNONE" ; then
 684 AC_MSG_CHECKING(for default include-directory)
 685 test -n "$verbose" && echo 1>&AC_FD_MSG
 686 for cf_symbol in \
 687         "$includedir" \
 688         "$includedir/ncurses" \
 689         "$prefix/include" \
 690         "$prefix/include/ncurses" \
 691         /usr/local/include \
 692         /usr/local/include/ncurses \
 693         /usr/include \
 694         /usr/include/ncurses
 695 do
 696         cf_dir=`eval echo "$cf_symbol"`
 697         if test -f "$cf_dir/curses.h" ; then
 698         if ( ${FGREP-fgrep} NCURSES_VERSION "$cf_dir/curses.h" >/dev/null 2>&1 ) ; then
 699                 includedir="$cf_symbol"
 700                 test -n "$verbose"  && echo $ECHO_N "   found " 1>&AC_FD_MSG
 701                 break
 702         fi
 703         fi
 704         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 705 done
 706 AC_MSG_RESULT($includedir)
 707 fi
 708 ])dnl
 709 dnl ---------------------------------------------------------------------------
 710 dnl CF_CHECK_CACHE version: 13 updated: 2020/12/31 10:54:15
 711 dnl --------------
 712 dnl Check if we're accidentally using a cache from a different machine.
 713 dnl Derive the system name, as a check for reusing the autoconf cache.
 714 dnl
 715 dnl If we've packaged config.guess and config.sub, run that (since it does a
 716 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 717 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 718 dnl which is useful in cross-compiles.
 719 dnl
 720 dnl Note: we would use $ac_config_sub, but that is one of the places where
 721 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 722 AC_DEFUN([CF_CHECK_CACHE],
 723 [
 724 if test -f "$srcdir/config.guess" || test -f "$ac_aux_dir/config.guess" ; then
 725         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 726         system_name="$host_os"
 727 else
 728         system_name="`(uname -s -r) 2>/dev/null`"
 729         if test -z "$system_name" ; then
 730                 system_name="`(hostname) 2>/dev/null`"
 731         fi
 732 fi
 733 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 734 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 735
 736 test -z "$system_name" && system_name="$cf_cv_system_name"
 737 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 738
 739 if test ".$system_name" != ".$cf_cv_system_name" ; then
 740         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 741         AC_MSG_ERROR("Please remove config.cache and try again.")
 742 fi
 743 ])dnl
 744 dnl ---------------------------------------------------------------------------
 745 dnl CF_CHECK_GNAT_VERSION version: 4 updated: 2021/01/01 13:31:04
 746 dnl ---------------------
 747 AC_DEFUN([CF_CHECK_GNAT_VERSION],
 748 [
 749 AC_REQUIRE([CF_GNAT_VERSION])
 750 case "$cf_cv_gnat_version" in
 751 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
 752         cf_cv_prog_gnat_correct=yes
 753         ;;
 754 (*)
 755         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
 756         cf_cv_prog_gnat_correct=no
 757         ;;
 758 esac
 759 ])
 760 dnl ---------------------------------------------------------------------------
 761 dnl CF_CLANG_COMPILER version: 8 updated: 2021/01/01 13:31:04
 762 dnl -----------------
 763 dnl Check if the given compiler is really clang.  clang's C driver defines
 764 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 765 dnl not ignore some gcc options.
 766 dnl
 767 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 768 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 769 dnl the wrappers for gcc and g++ warnings.
 770 dnl
 771 dnl $1 = GCC (default) or GXX
 772 dnl $2 = CLANG_COMPILER (default)
 773 dnl $3 = CFLAGS (default) or CXXFLAGS
 774 AC_DEFUN([CF_CLANG_COMPILER],[
 775 ifelse([$2],,CLANG_COMPILER,[$2])=no
 776
 777 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 778         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 779         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 780         AC_TRY_COMPILE([],[
 781 #ifdef __clang__
 782 #else
 783 make an error
 784 #endif
 785 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 786 ],[])
 787         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 788         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 789 fi
 790
 791 CLANG_VERSION=none
 792
 793 if test "x$ifelse([$2],,CLANG_COMPILER,[$2])" = "xyes" ; then
 794         case "$CC" in
 795         (c[[1-9]][[0-9]]|*/c[[1-9]][[0-9]])
 796                 AC_MSG_WARN(replacing broken compiler alias $CC)
 797                 CFLAGS="$CFLAGS -std=`echo "$CC" | sed -e 's%.*/%%'`"
 798                 CC=clang
 799                 ;;
 800         esac
 801
 802         AC_MSG_CHECKING(version of $CC)
 803         CLANG_VERSION="`$CC --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(CLANG[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
 804         test -z "$CLANG_VERSION" && CLANG_VERSION=unknown
 805         AC_MSG_RESULT($CLANG_VERSION)
 806
 807         for cf_clang_opt in \
 808                 -Qunused-arguments \
 809                 -Wno-error=implicit-function-declaration
 810         do
 811                 AC_MSG_CHECKING(if option $cf_clang_opt works)
 812                 cf_save_CFLAGS="$CFLAGS"
 813                 CFLAGS="$CFLAGS $cf_clang_opt"
 814                 AC_TRY_LINK([
 815                         #include <stdio.h>],[
 816                         printf("hello!\\n");],[
 817                         cf_clang_optok=yes],[
 818                         cf_clang_optok=no])
 819                 AC_MSG_RESULT($cf_clang_optok)
 820                 CFLAGS="$cf_save_CFLAGS"
 821                 if test "$cf_clang_optok" = yes; then
 822                         CF_VERBOSE(adding option $cf_clang_opt)
 823                         CF_APPEND_TEXT(CFLAGS,$cf_clang_opt)
 824                 fi
 825         done
 826 fi
 827 ])
 828 dnl ---------------------------------------------------------------------------
 829 dnl CF_CONST_X_STRING version: 6 updated: 2021/01/01 13:31:04
 830 dnl -----------------
 831 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
 832 dnl character-strings.
 833 dnl
 834 dnl It is ambiguous because the specification accommodated the pre-ANSI
 835 dnl compilers bundled by more than one vendor in lieu of providing a standard C
 836 dnl compiler other than by costly add-ons.  Because of this, the specification
 837 dnl did not take into account the use of const for telling the compiler that
 838 dnl string literals would be in readonly memory.
 839 dnl
 840 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
 841 dnl let the compiler decide how to represent Xt's strings which were #define'd.
 842 dnl That does not solve the problem of using the block of Xt's strings which
 843 dnl are compiled into the library (and is less efficient than one might want).
 844 dnl
 845 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
 846 dnl when compiling the library and compiling using the library, to tell the
 847 dnl compiler that String is const.
 848 AC_DEFUN([CF_CONST_X_STRING],
 849 [
 850 AC_REQUIRE([AC_PATH_XTRA])
 851
 852 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
 853
 854 AC_TRY_COMPILE(
 855 [
 856 #include <stdlib.h>
 857 #include <X11/Intrinsic.h>
 858 ],
 859 [String foo = malloc(1); (void)foo],[
 860
 861 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
 862         AC_TRY_COMPILE(
 863                 [
 864 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
 865 #undef  XTSTRINGDEFINES /* X11R5 and later */
 866 #include <stdlib.h>
 867 #include <X11/Intrinsic.h>
 868                 ],[String foo = malloc(1); *foo = 0],[
 869                         cf_cv_const_x_string=no
 870                 ],[
 871                         cf_cv_const_x_string=yes
 872                 ])
 873 ])
 874
 875 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
 876
 877 case "$cf_cv_const_x_string" in
 878 (no)
 879         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
 880         ;;
 881 (*)
 882         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
 883         ;;
 884 esac
 885
 886 ])
 887 ])dnl
 888 dnl ---------------------------------------------------------------------------
 889 dnl CF_CONST_X_STRING version: 6 updated: 2021/01/01 13:31:04
 890 dnl -----------------
 891 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
 892 dnl character-strings.
 893 dnl
 894 dnl It is ambiguous because the specification accommodated the pre-ANSI
 895 dnl compilers bundled by more than one vendor in lieu of providing a standard C
 896 dnl compiler other than by costly add-ons.  Because of this, the specification
 897 dnl did not take into account the use of const for telling the compiler that
 898 dnl string literals would be in readonly memory.
 899 dnl
 900 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
 901 dnl let the compiler decide how to represent Xt's strings which were #define'd.
 902 dnl That does not solve the problem of using the block of Xt's strings which
 903 dnl are compiled into the library (and is less efficient than one might want).
 904 dnl
 905 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
 906 dnl when compiling the library and compiling using the library, to tell the
 907 dnl compiler that String is const.
 908 AC_DEFUN([CF_CONST_X_STRING],
 909 [
 910 AC_REQUIRE([AC_PATH_XTRA])
 911
 912 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
 913
 914 AC_TRY_COMPILE(
 915 [
 916 #include <stdlib.h>
 917 #include <X11/Intrinsic.h>
 918 ],
 919 [String foo = malloc(1); (void)foo],[
 920
 921 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
 922         AC_TRY_COMPILE(
 923                 [
 924 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
 925 #undef  XTSTRINGDEFINES /* X11R5 and later */
 926 #include <stdlib.h>
 927 #include <X11/Intrinsic.h>
 928                 ],[String foo = malloc(1); *foo = 0],[
 929                         cf_cv_const_x_string=no
 930                 ],[
 931                         cf_cv_const_x_string=yes
 932                 ])
 933 ])
 934
 935 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
 936
 937 case "$cf_cv_const_x_string" in
 938 (no)
 939         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
 940         ;;
 941 (*)
 942         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
 943         ;;
 944 esac
 945
 946 ])
 947 ])dnl
 948 dnl ---------------------------------------------------------------------------
 949 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
 950 dnl ----------------
 951 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 952 dnl variations of ncurses' installs.
 953 dnl
 954 dnl $1 = ncurses when looking for ncurses, or is empty
 955 AC_DEFUN([CF_CURSES_HEADER],[
 956 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 957 cf_cv_ncurses_header=none
 958 for cf_header in \
 959         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
 960         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 961 do
 962 AC_TRY_COMPILE([#include <${cf_header}>],
 963         [initscr(); tgoto("?", 0,0)],
 964         [cf_cv_ncurses_header=$cf_header; break],[])
 965 done
 966 ])
 967
 968 if test "$cf_cv_ncurses_header" = none ; then
 969         AC_MSG_ERROR(No curses header-files found)
 970 fi
 971
 972 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 973 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 974 ])dnl
 975 dnl ---------------------------------------------------------------------------
 976 dnl CF_DIRNAME version: 5 updated: 2020/12/31 20:19:42
 977 dnl ----------
 978 dnl "dirname" is not portable, so we fake it with a shell script.
 979 AC_DEFUN([CF_DIRNAME],[$1=`echo "$2" | sed -e 's%/[[^/]]*$%%'`])dnl
 980 dnl ---------------------------------------------------------------------------
 981 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
 982 dnl ---------------
 983 dnl You can always use "make -n" to see the actual options, but it's hard to
 984 dnl pick out/analyze warning messages when the compile-line is long.
 985 dnl
 986 dnl Sets:
 987 dnl     ECHO_LT - symbol to control if libtool is verbose
 988 dnl     ECHO_LD - symbol to prefix "cc -o" lines
 989 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
 990 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
 991 dnl     ECHO_CC - symbol to put before any "cc" line
 992 dnl
 993 AC_DEFUN([CF_DISABLE_ECHO],[
 994 AC_MSG_CHECKING(if you want to see long compiling messages)
 995 CF_ARG_DISABLE(echo,
 996         [  --disable-echo          do not display "compiling" commands],
 997         [
 998         ECHO_LT='--silent'
 999         ECHO_LD='@echo linking [$]@;'
1000         RULE_CC='@echo compiling [$]<'
1001         SHOW_CC='@echo compiling [$]@'
1002         ECHO_CC='@'
1003 ],[
1004         ECHO_LT=''
1005         ECHO_LD=''
1006         RULE_CC=''
1007         SHOW_CC=''
1008         ECHO_CC=''
1009 ])
1010 AC_MSG_RESULT($enableval)
1011 AC_SUBST(ECHO_LT)
1012 AC_SUBST(ECHO_LD)
1013 AC_SUBST(RULE_CC)
1014 AC_SUBST(SHOW_CC)
1015 AC_SUBST(ECHO_CC)
1016 ])dnl
1017 dnl ---------------------------------------------------------------------------
1018 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1019 dnl ------------------------
1020 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1021 AC_MSG_CHECKING(if we want to use GNAT projects)
1022 CF_ARG_DISABLE(gnat-projects,
1023         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1024         [enable_gnat_projects=no],
1025         [enable_gnat_projects=yes])
1026 AC_MSG_RESULT($enable_gnat_projects)
1027 ])dnl
1028 dnl ---------------------------------------------------------------------------
1029 dnl CF_ENABLE_BROKEN_LINKER version: 2 updated: 2021/01/02 17:09:14
1030 dnl -----------------------
1031 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
1032 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
1033 dnl an unconditional feature.
1034 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
1035
1036 AC_MSG_CHECKING(if you want broken-linker support code)
1037 AC_ARG_ENABLE(broken_linker,
1038         [  --enable-broken_linker  compile with broken-linker support code],
1039         [with_broken_linker=$enableval],
1040         [with_broken_linker=no])
1041 AC_MSG_RESULT($with_broken_linker)
1042
1043 : "${BROKEN_LINKER:=0}"
1044 if test "x$with_broken_linker" = xyes ; then
1045         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
1046         BROKEN_LINKER=1
1047 fi
1048 AC_SUBST(BROKEN_LINKER)
1049 ])dnl
1050 dnl ---------------------------------------------------------------------------
1051 dnl CF_ENABLE_WARNINGS version: 9 updated: 2021/01/05 19:40:50
1052 dnl ------------------
1053 dnl Configure-option to enable gcc warnings
1054 dnl
1055 dnl $1 = extra options to add, if supported
1056 dnl $2 = option for checking attributes.  By default, this is done when
1057 dnl      warnings are enabled.  For other values:
1058 dnl      yes: always do this, e.g., to use in generated library-headers
1059 dnl      no: never do this
1060 AC_DEFUN([CF_ENABLE_WARNINGS],[
1061 if test "$GCC" = yes || test "$GXX" = yes
1062 then
1063 CF_FIX_WARNINGS(CFLAGS)
1064 CF_FIX_WARNINGS(CPPFLAGS)
1065 CF_FIX_WARNINGS(LDFLAGS)
1066 AC_MSG_CHECKING(if you want to turn on gcc warnings)
1067 CF_ARG_ENABLE(warnings,
1068         [  --enable-warnings       test: turn on gcc compiler warnings],
1069         [enable_warnings=yes],
1070         [enable_warnings=no])
1071 AC_MSG_RESULT($enable_warnings)
1072 if test "$enable_warnings" = "yes"
1073 then
1074         ifelse($2,,[CF_GCC_ATTRIBUTES])
1075         CF_GCC_WARNINGS($1)
1076 fi
1077 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
1078 fi
1079 ])dnl
1080 dnl ---------------------------------------------------------------------------
1081 dnl CF_FIND_LIBRARY version: 11 updated: 2021/01/02 09:31:20
1082 dnl ---------------
1083 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
1084 dnl prefer a standard location, and use -L options only if we do not find the
1085 dnl library in the standard library location(s).
1086 dnl     $1 = library name
1087 dnl     $2 = library class, usually the same as library name
1088 dnl     $3 = includes
1089 dnl     $4 = code fragment to compile/link
1090 dnl     $5 = corresponding function-name
1091 dnl     $6 = flag, nonnull if failure should not cause an error-exit
1092 dnl
1093 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
1094 dnl to use a -L option.
1095 AC_DEFUN([CF_FIND_LIBRARY],
1096 [
1097         eval 'cf_cv_have_lib_'"$1"'=no'
1098         cf_libdir=""
1099         AC_CHECK_FUNC($5,
1100                 eval 'cf_cv_have_lib_'"$1"'=yes',[
1101                 cf_save_LIBS="$LIBS"
1102                 AC_MSG_CHECKING(for $5 in -l$1)
1103                 LIBS="-l$1 $LIBS"
1104                 AC_TRY_LINK([$3],[$4],
1105                         [AC_MSG_RESULT(yes)
1106                          eval 'cf_cv_have_lib_'"$1"'=yes'
1107                         ],
1108                         [AC_MSG_RESULT(no)
1109                         CF_LIBRARY_PATH(cf_search,$2)
1110                         for cf_libdir in $cf_search
1111                         do
1112                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1113                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1114                                 AC_TRY_LINK([$3],[$4],
1115                                         [AC_MSG_RESULT(yes)
1116                                          eval 'cf_cv_have_lib_'"$1"'=yes'
1117                                          break],
1118                                         [AC_MSG_RESULT(no)
1119                                          LIBS="$cf_save_LIBS"])
1120                         done
1121                         ])
1122                 ])
1123 eval 'cf_found_library="[$]cf_cv_have_lib_'"$1"\"
1124 ifelse($6,,[
1125 if test "$cf_found_library" = no ; then
1126         AC_MSG_ERROR(Cannot link $1 library)
1127 fi
1128 ])
1129 ])dnl
1130 dnl ---------------------------------------------------------------------------
1131 dnl CF_FIND_LINKAGE version: 22 updated: 2020/12/31 20:19:42
1132 dnl ---------------
1133 dnl Find a library (specifically the linkage used in the code fragment),
1134 dnl searching for it if it is not already in the library path.
1135 dnl See also CF_ADD_SEARCHPATH.
1136 dnl
1137 dnl Parameters (4-on are optional):
1138 dnl     $1 = headers for library entrypoint
1139 dnl     $2 = code fragment for library entrypoint
1140 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1141 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1142 dnl     $5 = action to perform if not successful
1143 dnl     $6 = module name, if not the same as the library name
1144 dnl     $7 = extra libraries
1145 dnl
1146 dnl Sets these variables:
1147 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1148 dnl     $cf_cv_header_path_$3 - include-directory if needed
1149 dnl     $cf_cv_library_path_$3 - library-directory if needed
1150 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1151 AC_DEFUN([CF_FIND_LINKAGE],[
1152
1153 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1154 # will be set on completion of the AC_TRY_LINK below.
1155 cf_cv_header_path_$3=
1156 cf_cv_library_path_$3=
1157
1158 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1159
1160 cf_save_LIBS="$LIBS"
1161
1162 AC_TRY_LINK([$1],[$2],[
1163         cf_cv_find_linkage_$3=yes
1164         cf_cv_header_path_$3=/usr/include
1165         cf_cv_library_path_$3=/usr/lib
1166 ],[
1167
1168 LIBS="-l$3 $7 $cf_save_LIBS"
1169
1170 AC_TRY_LINK([$1],[$2],[
1171         cf_cv_find_linkage_$3=yes
1172         cf_cv_header_path_$3=/usr/include
1173         cf_cv_library_path_$3=/usr/lib
1174         cf_cv_library_file_$3="-l$3"
1175 ],[
1176         cf_cv_find_linkage_$3=no
1177         LIBS="$cf_save_LIBS"
1178
1179         CF_VERBOSE(find linkage for $3 library)
1180         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1181
1182         cf_save_CPPFLAGS="$CPPFLAGS"
1183         cf_test_CPPFLAGS="$CPPFLAGS"
1184
1185         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1186         for cf_cv_header_path_$3 in $cf_search
1187         do
1188                 if test -d "$cf_cv_header_path_$3" ; then
1189                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1190                         CPPFLAGS="$cf_save_CPPFLAGS"
1191                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1192                         AC_TRY_COMPILE([$1],[$2],[
1193                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1194                                 cf_cv_find_linkage_$3=maybe
1195                                 cf_test_CPPFLAGS="$CPPFLAGS"
1196                                 break],[
1197                                 CPPFLAGS="$cf_save_CPPFLAGS"
1198                                 ])
1199                 fi
1200         done
1201
1202         if test "$cf_cv_find_linkage_$3" = maybe ; then
1203
1204                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1205
1206                 cf_save_LIBS="$LIBS"
1207                 cf_save_LDFLAGS="$LDFLAGS"
1208
1209                 ifelse([$6],,,[
1210                 CPPFLAGS="$cf_test_CPPFLAGS"
1211                 LIBS="-l$3 $7 $cf_save_LIBS"
1212                 AC_TRY_LINK([$1],[$2],[
1213                         CF_VERBOSE(... found $3 library in system)
1214                         cf_cv_find_linkage_$3=yes])
1215                         CPPFLAGS="$cf_save_CPPFLAGS"
1216                         LIBS="$cf_save_LIBS"
1217                         ])
1218
1219                 if test "$cf_cv_find_linkage_$3" != yes ; then
1220                         CF_LIBRARY_PATH(cf_search,$3)
1221                         for cf_cv_library_path_$3 in $cf_search
1222                         do
1223                                 if test -d "$cf_cv_library_path_$3" ; then
1224                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1225                                         CPPFLAGS="$cf_test_CPPFLAGS"
1226                                         LIBS="-l$3 $7 $cf_save_LIBS"
1227                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1228                                         AC_TRY_LINK([$1],[$2],[
1229                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1230                                         cf_cv_find_linkage_$3=yes
1231                                         cf_cv_library_file_$3="-l$3"
1232                                         break],[
1233                                         CPPFLAGS="$cf_save_CPPFLAGS"
1234                                         LIBS="$cf_save_LIBS"
1235                                         LDFLAGS="$cf_save_LDFLAGS"
1236                                         ])
1237                                 fi
1238                         done
1239                         CPPFLAGS="$cf_save_CPPFLAGS"
1240                         LDFLAGS="$cf_save_LDFLAGS"
1241                 fi
1242
1243         else
1244                 cf_cv_find_linkage_$3=no
1245         fi
1246         ],$7)
1247 ])
1248
1249 LIBS="$cf_save_LIBS"
1250
1251 if test "$cf_cv_find_linkage_$3" = yes ; then
1252 ifelse([$4],,[
1253         CF_ADD_INCDIR($cf_cv_header_path_$3)
1254         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1255         CF_ADD_LIB($3)
1256 ],[$4])
1257 else
1258 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1259 fi
1260 ])dnl
1261 dnl ---------------------------------------------------------------------------
1262 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1263 dnl -----------------
1264 dnl make ADAFLAGS consistent with CFLAGS
1265 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1266         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1267         case "$CFLAGS" in
1268         (*-g*)
1269                 CF_ADD_ADAFLAGS(-g)
1270                 ;;
1271         esac
1272         case "$CFLAGS" in
1273         (*-O*)
1274                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1275                 CF_ADD_ADAFLAGS($cf_O_flag)
1276                 ;;
1277         esac
1278         AC_MSG_RESULT($ADAFLAGS)
1279 ])dnl
1280 dnl ---------------------------------------------------------------------------
1281 dnl CF_FIX_WARNINGS version: 3 updated: 2020/12/31 18:40:20
1282 dnl ---------------
1283 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
1284 dnl "-Werror" flags can interfere with configure-checks.  Those go into
1285 dnl EXTRA_CFLAGS.
1286 dnl
1287 dnl $1 = variable name to repair
1288 define([CF_FIX_WARNINGS],[
1289 if test "$GCC" = yes || test "$GXX" = yes
1290 then
1291         case [$]$1 in
1292         (*-Werror=*)
1293                 CF_VERBOSE(repairing $1: [$]$1)
1294                 cf_temp_flags=
1295                 for cf_temp_scan in [$]$1
1296                 do
1297                         case "x$cf_temp_scan" in
1298                         (x-Werror=*)
1299                                 CF_APPEND_TEXT(EXTRA_CFLAGS,$cf_temp_scan)
1300                                 ;;
1301                         (*)
1302                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
1303                                 ;;
1304                         esac
1305                 done
1306                 $1="$cf_temp_flags"
1307                 CF_VERBOSE(... fixed [$]$1)
1308                 CF_VERBOSE(... extra $EXTRA_CFLAGS)
1309                 ;;
1310         esac
1311 fi
1312 AC_SUBST(EXTRA_CFLAGS)
1313 ])dnl
1314 dnl ---------------------------------------------------------------------------
1315 dnl CF_GCC_ATTRIBUTES version: 24 updated: 2021/03/20 12:00:25
1316 dnl -----------------
1317 dnl Test for availability of useful gcc __attribute__ directives to quiet
1318 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1319 dnl to documentation, unrecognized directives cause older compilers to barf.
1320 AC_DEFUN([CF_GCC_ATTRIBUTES],
1321 [AC_REQUIRE([AC_PROG_FGREP])dnl
1322 AC_REQUIRE([CF_C11_NORETURN])dnl
1323
1324 if test "$GCC" = yes || test "$GXX" = yes
1325 then
1326 cat > conftest.i <<EOF
1327 #ifndef GCC_PRINTF
1328 #define GCC_PRINTF 0
1329 #endif
1330 #ifndef GCC_SCANF
1331 #define GCC_SCANF 0
1332 #endif
1333 #ifndef GCC_NORETURN
1334 #define GCC_NORETURN /* nothing */
1335 #endif
1336 #ifndef GCC_UNUSED
1337 #define GCC_UNUSED /* nothing */
1338 #endif
1339 EOF
1340 if test "$GCC" = yes
1341 then
1342         AC_CHECKING([for $CC __attribute__ directives])
1343 cat > "conftest.$ac_ext" <<EOF
1344 #line __oline__ "${as_me:-configure}"
1345 #include "confdefs.h"
1346 #include "conftest.h"
1347 #include "conftest.i"
1348 #if     GCC_PRINTF
1349 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1350 #else
1351 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1352 #endif
1353 #if     GCC_SCANF
1354 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1355 #else
1356 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1357 #endif
1358 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1359 extern GCC_NORETURN void oops(char *,...) GCC_PRINTFLIKE(1,2);
1360 extern GCC_NORETURN void foo(void);
1361 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
1362 EOF
1363         cf_printf_attribute=no
1364         cf_scanf_attribute=no
1365         for cf_attribute in scanf printf unused noreturn
1366         do
1367                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1368                 cf_directive="__attribute__(($cf_attribute))"
1369                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1370
1371                 case "$cf_attribute" in
1372                 (printf)
1373                         cf_printf_attribute=yes
1374                         cat >conftest.h <<EOF
1375 #define GCC_$cf_ATTRIBUTE 1
1376 EOF
1377                         ;;
1378                 (scanf)
1379                         cf_scanf_attribute=yes
1380                         cat >conftest.h <<EOF
1381 #define GCC_$cf_ATTRIBUTE 1
1382 EOF
1383                         ;;
1384                 (*)
1385                         cat >conftest.h <<EOF
1386 #define GCC_$cf_ATTRIBUTE $cf_directive
1387 EOF
1388                         ;;
1389                 esac
1390
1391                 if AC_TRY_EVAL(ac_compile); then
1392                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1393                         cat conftest.h >>confdefs.h
1394                         case "$cf_attribute" in
1395                         (noreturn)
1396                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1397                                 ;;
1398                         (printf)
1399                                 cf_value='/* nothing */'
1400                                 if test "$cf_printf_attribute" != no ; then
1401                                         cf_value='__attribute__((format(printf,fmt,var)))'
1402                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1403                                 fi
1404                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1405                                 ;;
1406                         (scanf)
1407                                 cf_value='/* nothing */'
1408                                 if test "$cf_scanf_attribute" != no ; then
1409                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1410                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1411                                 fi
1412                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1413                                 ;;
1414                         (unused)
1415                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1416                                 ;;
1417                         esac
1418                 fi
1419         done
1420 else
1421         ${FGREP-fgrep} define conftest.i >>confdefs.h
1422 fi
1423 rm -rf ./conftest*
1424 fi
1425 ])dnl
1426 dnl ---------------------------------------------------------------------------
1427 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
1428 dnl --------------
1429 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
1430 dnl compatible), attempt to determine if icc/clang is actually used.
1431 AC_DEFUN([CF_GCC_VERSION],[
1432 AC_REQUIRE([AC_PROG_CC])
1433 GCC_VERSION=none
1434 if test "$GCC" = yes ; then
1435         AC_MSG_CHECKING(version of $CC)
1436         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1437         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1438         AC_MSG_RESULT($GCC_VERSION)
1439 fi
1440 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1441 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1442 ])dnl
1443 dnl ---------------------------------------------------------------------------
1444 dnl CF_GCC_WARNINGS version: 41 updated: 2021/01/01 16:53:59
1445 dnl ---------------
1446 dnl Check if the compiler supports useful warning options.  There's a few that
1447 dnl we don't use, simply because they're too noisy:
1448 dnl
1449 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1450 dnl     -Winline (usually not worthwhile)
1451 dnl     -Wredundant-decls (system headers make this too noisy)
1452 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1453 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1454 dnl             is enabled for ncurses using "--enable-const".
1455 dnl     -pedantic
1456 dnl
1457 dnl Parameter:
1458 dnl     $1 is an optional list of gcc warning flags that a particular
1459 dnl             application might want to use, e.g., "no-unused" for
1460 dnl             -Wno-unused
1461 dnl Special:
1462 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1463 dnl
1464 AC_DEFUN([CF_GCC_WARNINGS],
1465 [
1466 AC_REQUIRE([CF_GCC_VERSION])
1467 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
1468 cat > "conftest.$ac_ext" <<EOF
1469 #line __oline__ "${as_me:-configure}"
1470 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1471 EOF
1472 if test "$INTEL_COMPILER" = yes
1473 then
1474 # The "-wdXXX" options suppress warnings:
1475 # remark #1419: external declaration in primary source file
1476 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1477 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1478 # remark #193: zero used for undefined preprocessing identifier
1479 # remark #593: variable "curs_sb_left_arrow" was set but never used
1480 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1481 # remark #869: parameter "tw" was never referenced
1482 # remark #981: operands are evaluated in unspecified order
1483 # warning #279: controlling expression is constant
1484
1485         AC_CHECKING([for $CC warning options])
1486         cf_save_CFLAGS="$CFLAGS"
1487         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
1488         for cf_opt in \
1489                 wd1419 \
1490                 wd1683 \
1491                 wd1684 \
1492                 wd193 \
1493                 wd593 \
1494                 wd279 \
1495                 wd810 \
1496                 wd869 \
1497                 wd981
1498         do
1499                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1500                 if AC_TRY_EVAL(ac_compile); then
1501                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1502                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1503                 fi
1504         done
1505         CFLAGS="$cf_save_CFLAGS"
1506 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
1507 then
1508         AC_CHECKING([for $CC warning options])
1509         cf_save_CFLAGS="$CFLAGS"
1510         cf_warn_CONST=""
1511         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1512         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1513         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1514         for cf_opt in W Wall \
1515                 Wbad-function-cast \
1516                 Wcast-align \
1517                 Wcast-qual \
1518                 Wdeclaration-after-statement \
1519                 Wextra \
1520                 Winline \
1521                 Wmissing-declarations \
1522                 Wmissing-prototypes \
1523                 Wnested-externs \
1524                 Wpointer-arith \
1525                 Wshadow \
1526                 Wstrict-prototypes \
1527                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
1528         do
1529                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1530                 if AC_TRY_EVAL(ac_compile); then
1531                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1532                         case "$cf_opt" in
1533                         (Winline)
1534                                 case "$GCC_VERSION" in
1535                                 ([[34]].*)
1536                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1537                                         continue;;
1538                                 esac
1539                                 ;;
1540                         (Wpointer-arith)
1541                                 case "$GCC_VERSION" in
1542                                 ([[12]].*)
1543                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1544                                         continue;;
1545                                 esac
1546                                 ;;
1547                         esac
1548                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1549                 fi
1550         done
1551         CFLAGS="$cf_save_CFLAGS"
1552 fi
1553 rm -rf ./conftest*
1554
1555 AC_SUBST(EXTRA_CFLAGS)
1556 ])dnl
1557 dnl ---------------------------------------------------------------------------
1558 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
1559 dnl -----------------
1560 AC_DEFUN([CF_GNATPREP_OPT_T],[
1561 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
1562 cf_cv_gnatprep_opt_t=no
1563 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
1564 ])
1565 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
1566 AC_SUBST(GNATPREP_OPTS)
1567 ])dnl
1568 dnl ---------------------------------------------------------------------------
1569 dnl CF_GNAT_GENERICS version: 7 updated: 2021/01/01 13:31:04
1570 dnl ----------------
1571 AC_DEFUN([CF_GNAT_GENERICS],
1572 [
1573 AC_REQUIRE([CF_GNAT_VERSION])
1574
1575 AC_MSG_CHECKING(if GNAT supports generics)
1576 case "$cf_cv_gnat_version" in
1577 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
1578         cf_gnat_generics=yes
1579         ;;
1580 (*)
1581         cf_gnat_generics=no
1582         ;;
1583 esac
1584 AC_MSG_RESULT($cf_gnat_generics)
1585
1586 if test "$cf_gnat_generics" = yes
1587 then
1588         cf_compile_generics=generics
1589         cf_generic_objects="\${GENOBJS}"
1590 else
1591         cf_compile_generics=
1592         cf_generic_objects=
1593 fi
1594
1595 AC_SUBST(cf_compile_generics)
1596 AC_SUBST(cf_generic_objects)
1597 ])dnl
1598 dnl ---------------------------------------------------------------------------
1599 dnl CF_GNAT_PROJECTS version: 13 updated: 2021/01/02 17:09:14
1600 dnl ----------------
1601 dnl GNAT projects are configured with ".gpr" project files.
1602 dnl GNAT libraries are a further development, using the project feature.
1603 AC_DEFUN([CF_GNAT_PROJECTS],
1604 [
1605 AC_REQUIRE([CF_GNAT_VERSION])
1606 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
1607
1608 cf_gnat_libraries=no
1609 cf_gnat_projects=no
1610
1611 if test "$enable_gnat_projects" != no ; then
1612 AC_MSG_CHECKING(if GNAT supports project files)
1613 case "$cf_cv_gnat_version" in
1614 (3.[[0-9]]*)
1615         ;;
1616 (*)
1617         case "$cf_cv_system_name" in
1618         (cygwin*|msys*)
1619                 ;;
1620         (*)
1621                 rm -rf ./conftest* ./*~conftest*
1622                 if mkdir conftest.src conftest.bin conftest.lib
1623                 then
1624                         cd conftest.src
1625                         rm -rf ./conftest* ./*~conftest*
1626                         cat >>library.gpr <<CF_EOF
1627 project Library is
1628   Kind := External ("LIB_KIND");
1629   for Library_Name use "ConfTest";
1630   for Object_Dir use ".";
1631   for Library_ALI_Dir use External("LIBRARY_DIR");
1632   for Library_Version use External ("SONAME");
1633   for Library_Kind use Kind;
1634   for Library_Dir use External("BUILD_DIR");
1635   Source_Dir := External ("SOURCE_DIR");
1636   for Source_Dirs use (Source_Dir);
1637 end Library;
1638 CF_EOF
1639                         cat >>confpackage.ads <<CF_EOF
1640 package ConfPackage is
1641    procedure conftest;
1642 end ConfPackage;
1643 CF_EOF
1644                         cat >>confpackage.adb <<CF_EOF
1645 with Text_IO;
1646 package body ConfPackage is
1647    procedure conftest is
1648    begin
1649       Text_IO.Put ("Hello World");
1650       Text_IO.New_Line;
1651    end conftest;
1652 end ConfPackage;
1653 CF_EOF
1654                         if ( "$cf_ada_make" $ADAFLAGS \
1655                                         -Plibrary.gpr \
1656                                         -XBUILD_DIR="`cd ../conftest.bin;pwd`" \
1657                                         -XLIBRARY_DIR="`cd ../conftest.lib;pwd`" \
1658                                         -XSOURCE_DIR="`pwd`" \
1659                                         -XSONAME=libConfTest.so.1 \
1660                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1661                                 cf_gnat_projects=yes
1662                         fi
1663                         cd ..
1664                 fi
1665                 if test -f conftest.lib/confpackage.ali
1666                 then
1667                         cf_gnat_libraries=yes
1668                 fi
1669                 rm -rf ./conftest* ./*~conftest*
1670                 ;;
1671         esac
1672         ;;
1673 esac
1674 AC_MSG_RESULT($cf_gnat_projects)
1675 fi # enable_gnat_projects
1676
1677 if test "$cf_gnat_projects" = yes
1678 then
1679         AC_MSG_CHECKING(if GNAT supports libraries)
1680         AC_MSG_RESULT($cf_gnat_libraries)
1681 fi
1682
1683 USE_OLD_MAKERULES=""
1684 USE_GNAT_PROJECTS="#"
1685 USE_GNAT_MAKE_GPR="#"
1686 USE_GNAT_GPRBUILD="#"
1687
1688 if test "$cf_gnat_projects" = yes
1689 then
1690         USE_OLD_MAKERULES="#"
1691         USE_GNAT_PROJECTS=""
1692         if test "$cf_cv_VERSION_GPRBUILD" != no
1693         then
1694                 USE_GNAT_GPRBUILD=""
1695         elif test "$cf_cv_VERSION_GNATMAKE" != no
1696         then
1697                 USE_GNAT_MAKE_GPR=""
1698         else
1699                 AC_MSG_WARN(use old makefile rules since tools are missing)
1700         fi
1701 fi
1702
1703 if test "$cf_gnat_libraries" = yes
1704 then
1705         USE_GNAT_LIBRARIES=""
1706 else
1707         USE_GNAT_LIBRARIES="#"
1708 fi
1709
1710 AC_SUBST(USE_OLD_MAKERULES)
1711 AC_SUBST(USE_GNAT_PROJECTS)
1712 AC_SUBST(USE_GNAT_LIBRARIES)
1713 AC_SUBST(USE_GNAT_MAKE_GPR)
1714 AC_SUBST(USE_GNAT_GPRBUILD)
1715 ])dnl
1716 dnl ---------------------------------------------------------------------------
1717 dnl CF_GNAT_SIGINT version: 2 updated: 2021/01/01 13:31:04
1718 dnl --------------
1719 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1720 dnl is noted that gnat may compile a tasking unit even for configurations which
1721 dnl fail at runtime.
1722 AC_DEFUN([CF_GNAT_SIGINT],[
1723 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1724 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1725
1726 package ConfTest is
1727
1728    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1729    pragma Unreserve_All_Interrupts;
1730    pragma Warnings (On);
1731
1732    protected Process is
1733       procedure Stop;
1734       function Continue return Boolean;
1735       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1736    private
1737       Done : Boolean := False;
1738    end Process;
1739
1740 end ConfTest;],
1741 [package body ConfTest is
1742    protected body Process is
1743       procedure Stop is
1744       begin
1745          Done := True;
1746       end Stop;
1747       function Continue return Boolean is
1748       begin
1749          return not Done;
1750       end Continue;
1751    end Process;
1752 end ConfTest;],
1753         [cf_cv_gnat_sigint=yes],
1754         [cf_cv_gnat_sigint=no])])
1755
1756 if test "$cf_cv_gnat_sigint" = yes ; then
1757         USE_GNAT_SIGINT=""
1758 else
1759         USE_GNAT_SIGINT="#"
1760 fi
1761 AC_SUBST(USE_GNAT_SIGINT)
1762 ])dnl
1763 dnl ---------------------------------------------------------------------------
1764 dnl CF_GNAT_TRY_LINK version: 4 updated: 2021/01/01 13:31:04
1765 dnl ----------------
1766 dnl Verify that a test program compiles/links with GNAT.
1767 dnl $cf_ada_make is set to the program that compiles/links
1768 dnl $ADAFLAGS may be set to the GNAT flags.
1769 dnl
1770 dnl $1 is the text of the spec
1771 dnl $2 is the text of the body
1772 dnl $3 is the shell command to execute if successful
1773 dnl $4 is the shell command to execute if not successful
1774 AC_DEFUN([CF_GNAT_TRY_LINK],
1775 [
1776 rm -rf ./conftest* ./*~conftest*
1777 cat >>conftest.ads <<CF_EOF
1778 $1
1779 CF_EOF
1780 cat >>conftest.adb <<CF_EOF
1781 $2
1782 CF_EOF
1783 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1784 ifelse($3,,      :,[      $3])
1785 ifelse($4,,,[else
1786    $4])
1787 fi
1788 rm -rf ./conftest* ./*~conftest*
1789 ])dnl
1790 dnl ---------------------------------------------------------------------------
1791 dnl CF_GNAT_TRY_RUN version: 6 updated: 2021/01/01 13:31:04
1792 dnl ---------------
1793 dnl Verify that a test program compiles and runs with GNAT
1794 dnl $cf_ada_make is set to the program that compiles/links
1795 dnl $ADAFLAGS may be set to the GNAT flags.
1796 dnl
1797 dnl $1 is the text of the spec
1798 dnl $2 is the text of the body
1799 dnl $3 is the shell command to execute if successful
1800 dnl $4 is the shell command to execute if not successful
1801 AC_DEFUN([CF_GNAT_TRY_RUN],
1802 [
1803 rm -rf ./conftest* ./*~conftest*
1804 cat >>conftest.ads <<CF_EOF
1805 $1
1806 CF_EOF
1807 cat >>conftest.adb <<CF_EOF
1808 $2
1809 CF_EOF
1810 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1811    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1812 ifelse($3,,      :,[      $3])
1813 ifelse($4,,,[   else
1814       $4])
1815    fi
1816 ifelse($4,,,[else
1817    $4])
1818 fi
1819 rm -rf ./conftest* ./*~conftest*
1820 ])dnl
1821 dnl ---------------------------------------------------------------------------
1822 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
1823 dnl ---------------
1824 dnl $1 = cache variable to update
1825 dnl $2 = program name
1826 dnl Verify version of GNAT or related tool
1827 AC_DEFUN([CF_GNAT_VERSION],
1828 [
1829 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
1830 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
1831         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1832         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1833 ])
1834 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
1835 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
1836 ])dnl
1837 dnl ---------------------------------------------------------------------------
1838 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
1839 dnl -------------
1840 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1841 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1842 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1843 dnl since it is interwoven with GNU extensions.
1844 dnl
1845 dnl Well, yes we could work around it...
1846 dnl
1847 dnl Parameters:
1848 dnl     $1 is the nominal value for _XOPEN_SOURCE
1849 AC_DEFUN([CF_GNU_SOURCE],
1850 [
1851 cf_gnu_xopen_source=ifelse($1,,500,$1)
1852
1853 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
1854 AC_TRY_COMPILE([#include <sys/types.h>],[
1855         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
1856                 return 0;
1857         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
1858                 return 0;
1859         #else
1860         #       error not GNU C library
1861         #endif],
1862         [cf_cv_gnu_library=yes],
1863         [cf_cv_gnu_library=no])
1864 ])
1865
1866 if test x$cf_cv_gnu_library = xyes; then
1867
1868         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
1869         # was changed to help a little.  newlib incorporated the change about 4
1870         # years later.
1871         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
1872                 cf_save="$CPPFLAGS"
1873                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1874                 AC_TRY_COMPILE([#include <sys/types.h>],[
1875                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
1876                                 return 0;
1877                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
1878                                 return 0;
1879                         #else
1880                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
1881                         #endif],
1882                         [cf_cv_gnu_library_219=yes],
1883                         [cf_cv_gnu_library_219=no])
1884                 CPPFLAGS="$cf_save"
1885         ])
1886
1887         if test "x$cf_cv_gnu_library_219" = xyes; then
1888                 cf_save="$CPPFLAGS"
1889                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
1890                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
1891                         AC_TRY_COMPILE([
1892                                 #include <limits.h>
1893                                 #include <sys/types.h>
1894                                 ],[
1895                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
1896                                         return 0;
1897                                 #else
1898                                 #       error GNU C library is too old
1899                                 #endif],
1900                                 [cf_cv_gnu_dftsrc_219=yes],
1901                                 [cf_cv_gnu_dftsrc_219=no])
1902                         ])
1903                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
1904         else
1905                 cf_cv_gnu_dftsrc_219=maybe
1906         fi
1907
1908         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
1909
1910                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1911                 AC_TRY_COMPILE([#include <sys/types.h>],[
1912                         #ifndef _XOPEN_SOURCE
1913                         #error  expected _XOPEN_SOURCE to be defined
1914                         #endif],
1915                         [cf_cv_gnu_source=no],
1916                         [cf_save="$CPPFLAGS"
1917                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
1918                          AC_TRY_COMPILE([#include <sys/types.h>],[
1919                                 #ifdef _XOPEN_SOURCE
1920                                 #error  expected _XOPEN_SOURCE to be undefined
1921                                 #endif],
1922                                 [cf_cv_gnu_source=no],
1923                                 [cf_cv_gnu_source=yes])
1924                         CPPFLAGS="$cf_save"
1925                         ])
1926                 ])
1927
1928                 if test "$cf_cv_gnu_source" = yes
1929                 then
1930                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
1931                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
1932                         AC_TRY_COMPILE([#include <sys/types.h>],[
1933                                 #ifdef _DEFAULT_SOURCE
1934                                 #error  expected _DEFAULT_SOURCE to be undefined
1935                                 #endif],
1936                                 [cf_cv_default_source=no],
1937                                 [cf_cv_default_source=yes])
1938                         ])
1939                         if test "$cf_cv_default_source" = yes
1940                         then
1941                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1942                         fi
1943                 fi
1944         fi
1945
1946 fi
1947 ])dnl
1948 dnl ---------------------------------------------------------------------------
1949 dnl CF_HEADER_PATH version: 15 updated: 2021/01/01 13:31:04
1950 dnl --------------
1951 dnl Construct a search-list of directories for a nonstandard header-file
1952 dnl
1953 dnl Parameters
1954 dnl     $1 = the variable to return as result
1955 dnl     $2 = the package name
1956 AC_DEFUN([CF_HEADER_PATH],
1957 [
1958 $1=
1959
1960 # collect the current set of include-directories from compiler flags
1961 cf_header_path_list=""
1962 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1963         for cf_header_path in $CPPFLAGS $CFLAGS
1964         do
1965                 case "$cf_header_path" in
1966                 (-I*)
1967                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1968                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1969                         cf_header_path_list="$cf_header_path_list [$]$1"
1970                         ;;
1971                 esac
1972         done
1973 fi
1974
1975 # add the variations for the package we are looking for
1976 CF_SUBDIR_PATH($1,$2,include)
1977
1978 test "$includedir" != NONE && \
1979 test "$includedir" != "/usr/include" && \
1980 test -d "$includedir" && {
1981         test -d "$includedir" &&    $1="[$]$1 $includedir"
1982         test -d "$includedir/$2" && $1="[$]$1 $includedir/$2"
1983 }
1984
1985 test "$oldincludedir" != NONE && \
1986 test "$oldincludedir" != "/usr/include" && \
1987 test -d "$oldincludedir" && {
1988         test -d "$oldincludedir"    && $1="[$]$1 $oldincludedir"
1989         test -d "$oldincludedir/$2" && $1="[$]$1 $oldincludedir/$2"
1990 }
1991
1992 $1="[$]$1 $cf_header_path_list"
1993 ])dnl
1994 dnl ---------------------------------------------------------------------------
1995 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
1996 dnl ---------------
1997 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1998 AC_DEFUN([CF_HELP_MESSAGE],
1999 [CF_ACVERSION_CHECK(2.53,[],[
2000 AC_DIVERT_HELP($1)])dnl
2001 ])dnl
2002 dnl ---------------------------------------------------------------------------
2003 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
2004 dnl ---------------
2005 dnl Construct the list of include-options according to whether we're building
2006 dnl in the source directory or using '--srcdir=DIR' option.
2007 AC_DEFUN([CF_INCLUDE_DIRS],
2008 [
2009 if test "$srcdir" != "."; then
2010         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
2011 fi
2012 CPPFLAGS="-I../include $CPPFLAGS"
2013 if test "$srcdir" != "."; then
2014         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
2015 fi
2016 CPPFLAGS="-I. $CPPFLAGS"
2017 AC_SUBST(CPPFLAGS)
2018 ])dnl
2019 dnl ---------------------------------------------------------------------------
2020 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
2021 dnl ---------------
2022 dnl prompt for/fill-in useful install-program options
2023 AC_DEFUN([CF_INSTALL_OPTS],
2024 [
2025 CF_INSTALL_OPT_S
2026 CF_INSTALL_OPT_P
2027 CF_INSTALL_OPT_O
2028 ])dnl
2029 dnl ---------------------------------------------------------------------------
2030 dnl CF_INSTALL_OPT_O version: 3 updated: 2020/12/31 20:19:42
2031 dnl ----------------
2032 dnl Almost all "install" programs default to the current user's ownership.
2033 dnl Almost - MINIX is an exception.
2034 AC_DEFUN([CF_INSTALL_OPT_O],
2035 [
2036 AC_MSG_CHECKING(if install needs to be told about ownership)
2037 case `$ac_config_guess` in
2038 (*minix)
2039         with_install_o=yes
2040         ;;
2041 (*)
2042         with_install_o=no
2043         ;;
2044 esac
2045
2046 AC_MSG_RESULT($with_install_o)
2047 if test "x$with_install_o" = xyes
2048 then
2049         INSTALL_OPT_O="`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`"
2050 else
2051         INSTALL_OPT_O=
2052 fi
2053
2054 AC_SUBST(INSTALL_OPT_O)
2055 ])dnl
2056 dnl ---------------------------------------------------------------------------
2057 dnl CF_INSTALL_OPT_P version: 3 updated: 2021/01/01 13:31:04
2058 dnl ----------------
2059 dnl Some install-programs accept a "-p" option to preserve file modification
2060 dnl timestamps.  That can be useful as an install option, as well as a way to
2061 dnl avoid the need for ranlib after copying a static archive.
2062 AC_DEFUN([CF_INSTALL_OPT_P],
2063 [
2064 : "${INSTALL:=install}"
2065 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
2066         rm -rf ./conftest*
2067         date >conftest.in
2068         mkdir conftest.out
2069         sleep 3
2070         if $INSTALL -p conftest.in conftest.out 2>/dev/null
2071         then
2072                 if test -f conftest.out/conftest.in
2073                 then
2074                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
2075                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
2076                         if test -s conftest.err
2077                         then
2078                                 cf_cv_install_p=no
2079                         else
2080                                 cf_cv_install_p=yes
2081                         fi
2082                 else
2083                         cf_cv_install_p=no
2084                 fi
2085         else
2086                 cf_cv_install_p=no
2087         fi
2088         rm -rf ./conftest*
2089 ])
2090 ])dnl
2091 dnl ---------------------------------------------------------------------------
2092 dnl CF_INSTALL_OPT_S version: 3 updated: 2021/01/05 19:23:48
2093 dnl ----------------
2094 dnl By default, we should strip executables which are installed, but leave the
2095 dnl ability to suppress that for unit-testing.
2096 AC_DEFUN([CF_INSTALL_OPT_S],
2097 [
2098 AC_MSG_CHECKING(if you want to install stripped executables)
2099 CF_ARG_DISABLE(stripping,
2100         [  --disable-stripping     do not strip (debug info) installed executables],
2101         [enable_stripping=no],
2102         [enable_stripping=yes])
2103 AC_MSG_RESULT($enable_stripping)
2104
2105 if test "$enable_stripping" = yes
2106 then
2107         INSTALL_OPT_S="-s"
2108 else
2109         INSTALL_OPT_S=
2110 fi
2111 AC_SUBST(INSTALL_OPT_S)
2112 ])dnl
2113 dnl ---------------------------------------------------------------------------
2114 dnl CF_INTEL_COMPILER version: 8 updated: 2021/01/01 16:53:59
2115 dnl -----------------
2116 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2117 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2118 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2119 dnl
2120 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2121 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2122 dnl the wrappers for gcc and g++ warnings.
2123 dnl
2124 dnl $1 = GCC (default) or GXX
2125 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2126 dnl $3 = CFLAGS (default) or CXXFLAGS
2127 AC_DEFUN([CF_INTEL_COMPILER],[
2128 AC_REQUIRE([AC_CANONICAL_HOST])
2129 ifelse([$2],,INTEL_COMPILER,[$2])=no
2130
2131 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2132         case "$host_os" in
2133         (linux*|gnu*)
2134                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2135                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2136                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2137                 AC_TRY_COMPILE([],[
2138 #ifdef __INTEL_COMPILER
2139 #else
2140 make an error
2141 #endif
2142 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2143 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2144 ],[])
2145                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2146                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2147                 ;;
2148         esac
2149 fi
2150 ])dnl
2151 dnl ---------------------------------------------------------------------------
2152 dnl CF_LARGEFILE version: 12 updated: 2020/03/19 20:23:48
2153 dnl ------------
2154 dnl Add checks for large file support.
2155 AC_DEFUN([CF_LARGEFILE],[
2156 ifdef([AC_FUNC_FSEEKO],[
2157         AC_SYS_LARGEFILE
2158         if test "$enable_largefile" != no ; then
2159         AC_FUNC_FSEEKO
2160
2161         # Normally we would collect these definitions in the config.h,
2162         # but (like _XOPEN_SOURCE), some environments rely on having these
2163         # defined before any of the system headers are included.  Another
2164         # case comes up with C++, e.g., on AIX the compiler compiles the
2165         # header files by themselves before looking at the body files it is
2166         # told to compile.  For ncurses, those header files do not include
2167         # the config.h
2168         if test "$ac_cv_sys_large_files" != no
2169         then
2170                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
2171         fi
2172         if test "$ac_cv_sys_largefile_source" != no
2173         then
2174                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
2175         fi
2176         if test "$ac_cv_sys_file_offset_bits" != no
2177         then
2178                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
2179         fi
2180
2181         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2182                 AC_TRY_COMPILE([
2183 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
2184 #include <sys/types.h>
2185 #include <dirent.h>
2186                 ],[
2187                 /* if transitional largefile support is setup, this is true */
2188                 extern struct dirent64 * readdir(DIR *);
2189                 struct dirent64 *x = readdir((DIR *)0);
2190                 struct dirent *y = readdir((DIR *)0);
2191                 int z = x - y;
2192                 (void)z;
2193                 ],
2194                 [cf_cv_struct_dirent64=yes],
2195                 [cf_cv_struct_dirent64=no])
2196         ])
2197         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
2198         fi
2199 ])
2200 ])
2201 dnl ---------------------------------------------------------------------------
2202 dnl CF_LD_RPATH_OPT version: 9 updated: 2021/01/01 13:31:04
2203 dnl ---------------
2204 dnl For the given system and compiler, find the compiler flags to pass to the
2205 dnl loader to use the "rpath" feature.
2206 AC_DEFUN([CF_LD_RPATH_OPT],
2207 [
2208 AC_REQUIRE([CF_CHECK_CACHE])
2209
2210 LD_RPATH_OPT=
2211 if test "x$cf_cv_enable_rpath" != xno
2212 then
2213         AC_MSG_CHECKING(for an rpath option)
2214         case "$cf_cv_system_name" in
2215         (irix*)
2216                 if test "$GCC" = yes; then
2217                         LD_RPATH_OPT="-Wl,-rpath,"
2218                 else
2219                         LD_RPATH_OPT="-rpath "
2220                 fi
2221                 ;;
2222         (linux*|gnu*|k*bsd*-gnu|freebsd*)
2223                 LD_RPATH_OPT="-Wl,-rpath,"
2224                 ;;
2225         (openbsd[[2-9]].*|mirbsd*)
2226                 LD_RPATH_OPT="-Wl,-rpath,"
2227                 ;;
2228         (dragonfly*)
2229                 LD_RPATH_OPT="-rpath "
2230                 ;;
2231         (netbsd*)
2232                 LD_RPATH_OPT="-Wl,-rpath,"
2233                 ;;
2234         (osf*|mls+*)
2235                 LD_RPATH_OPT="-rpath "
2236                 ;;
2237         (solaris2*)
2238                 LD_RPATH_OPT="-R"
2239                 ;;
2240         (*)
2241                 ;;
2242         esac
2243         AC_MSG_RESULT($LD_RPATH_OPT)
2244
2245         case "x$LD_RPATH_OPT" in
2246         (x-R*)
2247                 AC_MSG_CHECKING(if we need a space after rpath option)
2248                 cf_save_LIBS="$LIBS"
2249                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2250                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2251                 LIBS="$cf_save_LIBS"
2252                 AC_MSG_RESULT($cf_rpath_space)
2253                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2254                 ;;
2255         esac
2256 fi
2257 ])dnl
2258 dnl ---------------------------------------------------------------------------
2259 dnl CF_LIBRARY_PATH version: 11 updated: 2021/01/01 13:31:04
2260 dnl ---------------
2261 dnl Construct a search-list of directories for a nonstandard library-file
2262 dnl
2263 dnl Parameters
2264 dnl     $1 = the variable to return as result
2265 dnl     $2 = the package name
2266 AC_DEFUN([CF_LIBRARY_PATH],
2267 [
2268 $1=
2269 cf_library_path_list=""
2270 if test -n "${LDFLAGS}${LIBS}" ; then
2271         for cf_library_path in $LDFLAGS $LIBS
2272         do
2273                 case "$cf_library_path" in
2274                 (-L*)
2275                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2276                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2277                         cf_library_path_list="$cf_library_path_list [$]$1"
2278                         ;;
2279                 esac
2280         done
2281 fi
2282
2283 CF_SUBDIR_PATH($1,$2,lib)
2284
2285 $1="$cf_library_path_list [$]$1"
2286 ])dnl
2287 dnl ---------------------------------------------------------------------------
2288 dnl CF_LIB_PREFIX version: 14 updated: 2021/01/01 13:31:04
2289 dnl -------------
2290 dnl Compute the library-prefix for the given host system
2291 dnl $1 = variable to set
2292 define([CF_LIB_PREFIX],
2293 [
2294         case "$cf_cv_system_name" in
2295         (OS/2*|os2*)
2296                 if test "$DFT_LWR_MODEL" = libtool; then
2297                         LIB_PREFIX='lib'
2298                 else
2299                         LIB_PREFIX=''
2300                 fi
2301                 ;;
2302         (*-msvc*)
2303                 LIB_PREFIX=''
2304                 ;;
2305         (*)     LIB_PREFIX='lib'
2306                 ;;
2307         esac
2308 ifelse($1,,,[$1=$LIB_PREFIX])
2309         AC_SUBST(LIB_PREFIX)
2310 ])dnl
2311 dnl ---------------------------------------------------------------------------
2312 dnl CF_LIB_SUFFIX version: 28 updated: 2021/01/01 16:53:59
2313 dnl -------------
2314 dnl Compute the library file-suffix from the given model name
2315 dnl $1 = model name
2316 dnl $2 = variable to set (the nominal library suffix)
2317 dnl $3 = dependency variable to set (actual filename)
2318 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
2319 AC_DEFUN([CF_LIB_SUFFIX],
2320 [
2321         case X$1 in
2322         (Xlibtool)
2323                 $2='.la'
2324                 $3=[$]$2
2325                 ;;
2326         (Xdebug)
2327                 case "$cf_cv_system_name" in
2328                 (*-msvc*)
2329                         $2='_g.lib'
2330                         ;;
2331                 (*)
2332                         $2='_g.a'
2333                         ;;
2334                 esac
2335                 $3=[$]$2
2336                 ;;
2337         (Xprofile)
2338                 case "$cf_cv_system_name" in
2339                 (*-msvc*)
2340                         $2='_p.lib'
2341                         ;;
2342                 (*)
2343                         $2='_p.a'
2344                         ;;
2345                 esac
2346                 $3=[$]$2
2347                 ;;
2348         (Xshared)
2349                 case "$cf_cv_system_name" in
2350                 (aix[[5-7]]*)
2351                         $2='.so'
2352                         $3=[$]$2
2353                         ;;
2354                 (*-msvc*)
2355                         $2='.dll'
2356                         $3='.dll.lib'
2357                         ;;
2358                 (cygwin*|msys*|mingw*)
2359                         $2='.dll'
2360                         $3='.dll.a'
2361                         ;;
2362                 (darwin*)
2363                         $2='.dylib'
2364                         $3=[$]$2
2365                         ;;
2366                 (hpux*)
2367                         case "$target" in
2368                         (ia64*)
2369                                 $2='.so'
2370                                 $3=[$]$2
2371                                 ;;
2372                         (*)
2373                                 $2='.sl'
2374                                 $3=[$]$2
2375                                 ;;
2376                         esac
2377                         ;;
2378                 (*)
2379                         $2='.so'
2380                         $3=[$]$2
2381                         ;;
2382                 esac
2383                 ;;
2384         (*)
2385                 case "$target" in
2386                 (*-msvc*)
2387                         $2='.lib'
2388                         ;;
2389                 (*)
2390                         $2='.a'
2391                         ;;
2392                 esac
2393                 $3=[$]$2
2394                 ;;
2395         esac
2396         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
2397         then
2398                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
2399                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
2400         fi
2401 ])dnl
2402 dnl ---------------------------------------------------------------------------
2403 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
2404 dnl -----------
2405 dnl Compute the string to append to -library from the given model name
2406 dnl $1 = model name
2407 dnl $2 = variable to set
2408 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
2409 AC_DEFUN([CF_LIB_TYPE],
2410 [
2411         case $1 in
2412         (libtool) $2=''   ;;
2413         (normal)  $2=''   ;;
2414         (debug)   $2='_g' ;;
2415         (profile) $2='_p' ;;
2416         (shared)  $2=''   ;;
2417         esac
2418         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
2419 ])dnl
2420 dnl ---------------------------------------------------------------------------
2421 dnl CF_LINK_DATAONLY version: 13 updated: 2020/02/08 15:59:30
2422 dnl ----------------
2423 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
2424 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
2425 dnl have to provide wrappers for global tables to ensure they're linked
2426 dnl properly.
2427 AC_DEFUN([CF_LINK_DATAONLY],
2428 [
2429 AC_MSG_CHECKING([if data-only library module links])
2430 AC_CACHE_VAL(cf_cv_link_dataonly,[
2431         rm -f conftest.a
2432         cat >conftest.$ac_ext <<EOF
2433 #line __oline__ "configure"
2434 int     testdata[[3]] = { 123, 456, 789 };
2435 EOF
2436         if AC_TRY_EVAL(ac_compile) ; then
2437                 mv conftest.o data.o && \
2438                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
2439         fi
2440         rm -f conftest.$ac_ext data.o
2441         cat >conftest.$ac_ext <<EOF
2442 #line __oline__ "configure"
2443 int     testfunc(void)
2444 {
2445 #if defined(NeXT)
2446         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
2447 #else
2448         extern int testdata[[3]];
2449         return testdata[[0]] == 123
2450            &&  testdata[[1]] == 456
2451            &&  testdata[[2]] == 789;
2452 #endif
2453 }
2454 EOF
2455         if AC_TRY_EVAL(ac_compile); then
2456                 mv conftest.o func.o && \
2457                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
2458         fi
2459         rm -f conftest.$ac_ext func.o
2460         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
2461         cf_saveLIBS="$LIBS"
2462         LIBS="conftest.a $LIBS"
2463         AC_TRY_RUN([
2464         int main(void)
2465         {
2466                 extern int testfunc();
2467                 ${cf_cv_main_return:-return} (!testfunc());
2468         }
2469         ],
2470         [cf_cv_link_dataonly=yes],
2471         [cf_cv_link_dataonly=no],
2472         [cf_cv_link_dataonly=unknown])
2473         LIBS="$cf_saveLIBS"
2474         ])
2475 AC_MSG_RESULT($cf_cv_link_dataonly)
2476
2477 if test "$cf_cv_link_dataonly" = no ; then
2478         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
2479         BROKEN_LINKER=1
2480 fi
2481 AC_SUBST(BROKEN_LINKER)
2482
2483 ])dnl
2484 dnl ---------------------------------------------------------------------------
2485 dnl CF_MAKEFLAGS version: 20 updated: 2021/01/03 19:29:49
2486 dnl ------------
2487 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
2488 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
2489 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
2490 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
2491 AC_DEFUN([CF_MAKEFLAGS],
2492 [AC_REQUIRE([AC_PROG_FGREP])dnl
2493
2494 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
2495         cf_cv_makeflags=''
2496         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
2497         do
2498                 cat >cf_makeflags.tmp <<CF_EOF
2499 SHELL = $SHELL
2500 all :
2501         @ echo '.$cf_option'
2502 CF_EOF
2503                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | ${FGREP-fgrep} -v "ing directory" | sed -e 's,[[  ]]*$,,'`
2504                 case "$cf_result" in
2505                 (.*k|.*kw)
2506                         cf_result="`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`"
2507                         case "$cf_result" in
2508                         (.*CC=*)        cf_cv_makeflags=
2509                                 ;;
2510                         (*)     cf_cv_makeflags=$cf_option
2511                                 ;;
2512                         esac
2513                         break
2514                         ;;
2515                 (.-)
2516                         ;;
2517                 (*)
2518                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
2519                         ;;
2520                 esac
2521         done
2522         rm -f cf_makeflags.tmp
2523 ])
2524
2525 AC_SUBST(cf_cv_makeflags)
2526 ])dnl
2527 dnl ---------------------------------------------------------------------------
2528 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
2529 dnl ------------
2530 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
2531 dnl a monocase filesystem.
2532 AC_DEFUN([CF_MAKE_TAGS],[
2533 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
2534
2535 AC_CHECK_PROGS(CTAGS, exctags ctags)
2536 AC_CHECK_PROGS(ETAGS, exetags etags)
2537
2538 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
2539
2540 if test "$cf_cv_mixedcase" = yes ; then
2541         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
2542 else
2543         MAKE_UPPER_TAGS=no
2544 fi
2545
2546 if test "$MAKE_UPPER_TAGS" = yes ; then
2547         MAKE_UPPER_TAGS=
2548 else
2549         MAKE_UPPER_TAGS="#"
2550 fi
2551
2552 if test "$MAKE_LOWER_TAGS" = yes ; then
2553         MAKE_LOWER_TAGS=
2554 else
2555         MAKE_LOWER_TAGS="#"
2556 fi
2557
2558 AC_SUBST(CTAGS)
2559 AC_SUBST(ETAGS)
2560
2561 AC_SUBST(MAKE_UPPER_TAGS)
2562 AC_SUBST(MAKE_LOWER_TAGS)
2563 ])dnl
2564 dnl ---------------------------------------------------------------------------
2565 dnl CF_MIXEDCASE_FILENAMES version: 9 updated: 2021/01/01 16:53:59
2566 dnl ----------------------
2567 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2568 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2569 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2570 [
2571 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2572 if test "$cross_compiling" = yes ; then
2573         case "$target_alias" in
2574         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*|darwin*)
2575                 cf_cv_mixedcase=no
2576                 ;;
2577         (*)
2578                 cf_cv_mixedcase=yes
2579                 ;;
2580         esac
2581 else
2582         rm -f conftest CONFTEST
2583         echo test >conftest
2584         if test -f CONFTEST ; then
2585                 cf_cv_mixedcase=no
2586         else
2587                 cf_cv_mixedcase=yes
2588         fi
2589         rm -f conftest CONFTEST
2590 fi
2591 ])
2592 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2593 ])dnl
2594 dnl ---------------------------------------------------------------------------
2595 dnl CF_MKSTEMP version: 11 updated: 2021/01/01 13:31:04
2596 dnl ----------
2597 dnl Check for a working mkstemp.  This creates two files, checks that they are
2598 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2599 AC_DEFUN([CF_MKSTEMP],[
2600 AC_CHECK_HEADERS( \
2601 unistd.h \
2602 )
2603 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2604 rm -rf ./conftest*
2605 AC_TRY_RUN([
2606 #include <sys/types.h>
2607 #ifdef HAVE_UNISTD_H
2608 #include <unistd.h>
2609 #endif
2610 #include <stdlib.h>
2611 #include <stdio.h>
2612 #include <string.h>
2613 #include <sys/stat.h>
2614 int main(void)
2615 {
2616         char *tmpl = "conftestXXXXXX";
2617         char name[2][80];
2618         int n;
2619         int result = 0;
2620         int fd;
2621         struct stat sb;
2622
2623         umask(077);
2624         for (n = 0; n < 2; ++n) {
2625                 strcpy(name[n], tmpl);
2626                 if ((fd = mkstemp(name[n])) >= 0) {
2627                         if (!strcmp(name[n], tmpl)
2628                          || stat(name[n], &sb) != 0
2629                          || (sb.st_mode & S_IFMT) != S_IFREG
2630                          || (sb.st_mode & 077) != 0) {
2631                                 result = 1;
2632                         }
2633                         close(fd);
2634                 }
2635         }
2636         if (result == 0
2637          && !strcmp(name[0], name[1]))
2638                 result = 1;
2639         ${cf_cv_main_return:-return}(result);
2640 }
2641 ],[cf_cv_func_mkstemp=yes
2642 ],[cf_cv_func_mkstemp=no
2643 ],[cf_cv_func_mkstemp=maybe])
2644 ])
2645 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2646         AC_CHECK_FUNC(mkstemp)
2647 fi
2648 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2649         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2650 fi
2651 ])dnl
2652 dnl ---------------------------------------------------------------------------
2653 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2654 dnl ----------
2655 dnl Write a debug message to config.log, along with the line number in the
2656 dnl configure script.
2657 AC_DEFUN([CF_MSG_LOG],[
2658 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2659 ])dnl
2660 dnl ---------------------------------------------------------------------------
2661 dnl CF_NCURSES_ADDON version: 6 updated: 2021/01/04 19:33:05
2662 dnl ----------------
2663 dnl Configure an ncurses add-on, built outside the ncurses tree.
2664 AC_DEFUN([CF_NCURSES_ADDON],[
2665 AC_REQUIRE([CF_NCURSES_CONFIG])
2666
2667 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2668
2669 AC_MSG_CHECKING(if you want wide-character code)
2670 AC_ARG_ENABLE(widec,
2671         [  --enable-widec          compile with wide-char/UTF-8 code],
2672         [with_widec=$enableval],
2673         [with_widec=no])
2674 AC_MSG_RESULT($with_widec)
2675 if test "$with_widec" = yes ; then
2676         CF_UTF8_LIB
2677         CF_NCURSES_CONFIG(ncursesw)
2678 else
2679         CF_NCURSES_CONFIG(ncurses)
2680 fi
2681
2682 if test "$NCURSES_CONFIG_PKG" != none ; then
2683         cf_version=`$PKG_CONFIG --modversion $NCURSES_CONFIG_PKG 2>/dev/null`
2684
2685         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2686         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2687         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2688
2689         cf_cv_abi_version=`$PKG_CONFIG --variable=abi_version $NCURSES_CONFIG_PKG 2>/dev/null`
2690         if test -z "$cf_cv_abi_version"
2691         then
2692                 cf_cv_abi_version=`$PKG_CONFIG --variable=major_version $NCURSES_CONFIG_PKG 2>/dev/null`
2693         fi
2694
2695 elif test "$NCURSES_CONFIG" != none ; then
2696
2697         cf_version=`$NCURSES_CONFIG --version 2>/dev/null`
2698
2699         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2700         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2701         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2702
2703         # ABI version is not available from headers
2704         cf_cv_abi_version=`$NCURSES_CONFIG --abi-version 2>/dev/null`
2705
2706 else
2707
2708         for cf_name in MAJOR MINOR PATCH
2709         do
2710         cat >conftest.$ac_ext <<CF_EOF
2711         #include <${cf_cv_ncurses_header:-curses.h}>
2712         AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2713 CF_EOF
2714                 cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2715                 AC_TRY_EVAL(cf_try)
2716                 if test -f conftest.out ; then
2717                         cf_result=`sed -e "s/^.*AUTOCONF_${cf_name}[[   ]][[    ]]*//" conftest.out`
2718                         eval NCURSES_$cf_name=\"$cf_result\"
2719                         # cat conftest.$ac_ext
2720                         # cat conftest.out
2721                 fi
2722         done
2723
2724         cf_cv_abi_version=${NCURSES_MAJOR}
2725
2726 fi
2727
2728 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2729
2730 dnl Show the computed version, for logging
2731 cf_cv_timestamp=`date`
2732
2733 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2734
2735 dnl We need these values in the generated headers
2736 AC_SUBST(NCURSES_MAJOR)
2737 AC_SUBST(NCURSES_MINOR)
2738 AC_SUBST(NCURSES_PATCH)
2739
2740 dnl We need these values in the generated makefiles
2741 AC_SUBST(cf_cv_rel_version)
2742 AC_SUBST(cf_cv_abi_version)
2743
2744 dnl FIXME - not needed for Ada95
2745 AC_SUBST(cf_cv_builtin_bool)
2746 AC_SUBST(cf_cv_header_stdbool_h)
2747 AC_SUBST(cf_cv_type_of_bool)dnl
2748
2749 ])
2750 dnl ---------------------------------------------------------------------------
2751 dnl CF_NCURSES_CC_CHECK version: 5 updated: 2020/12/31 20:19:42
2752 dnl -------------------
2753 dnl Check if we can compile with ncurses' header file
2754 dnl $1 is the cache variable to set
2755 dnl $2 is the header-file to include
2756 dnl $3 is the root name (ncurses or ncursesw)
2757 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2758         AC_TRY_COMPILE([
2759 ]ifelse($3,ncursesw,[
2760 #define _XOPEN_SOURCE_EXTENDED
2761 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2762 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2763 ])[
2764 #include <$2>],[
2765 #ifdef NCURSES_VERSION
2766 ]ifelse($3,ncursesw,[
2767 #ifndef WACS_BSSB
2768         make an error
2769 #endif
2770 ])[
2771 printf("%s\\n", NCURSES_VERSION);
2772 #else
2773 #ifdef __NCURSES_H
2774 printf("old\\n");
2775 #else
2776         make an error
2777 #endif
2778 #endif
2779         ]
2780         ,[$1=$2]
2781         ,[$1=no])
2782 ])dnl
2783 dnl ---------------------------------------------------------------------------
2784 dnl CF_NCURSES_CONFIG version: 26 updated: 2021/01/03 08:05:37
2785 dnl -----------------
2786 dnl Tie together the configure-script macros for ncurses, preferring these in
2787 dnl order:
2788 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2789 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2790 dnl c) just plain libraries
2791 dnl
2792 dnl $1 is the root library name (default: "ncurses")
2793 AC_DEFUN([CF_NCURSES_CONFIG],[
2794 AC_REQUIRE([CF_PKG_CONFIG])
2795 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2796 cf_have_ncuconfig=no
2797
2798 if test "x${PKG_CONFIG:=none}" != xnone; then
2799         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2800         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2801                 AC_MSG_RESULT(yes)
2802
2803                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2804                 cf_have_ncuconfig=unknown
2805
2806                 cf_save_CFLAGS="$CFLAGS"
2807                 cf_save_CPPFLAGS="$CPPFLAGS"
2808                 cf_save_LIBS="$LIBS"
2809
2810                 cf_pkg_cflags="`$PKG_CONFIG --cflags $cf_ncuconfig_root`"
2811                 cf_pkg_libs="`$PKG_CONFIG --libs $cf_ncuconfig_root`"
2812
2813                 # while -W for passing linker flags is prevalent, it is not "standard".
2814                 # At least one wrapper for c89/c99 (in Apple's xcode) has its own
2815                 # incompatible _and_ non-standard -W option which gives an error.  Work
2816                 # around that pitfall.
2817                 case "x${CC}@@${cf_pkg_libs}@${cf_pkg_cflags}" in
2818                 (x*c[[89]]9@@*-W*)
2819                         CF_ADD_CFLAGS($cf_pkg_cflags)
2820                         CF_ADD_LIBS($cf_pkg_libs)
2821
2822                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2823                                 [initscr(); mousemask(0,0); tigetstr((char *)0);],
2824                                 [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2825                                         int main(void)
2826                                         { char *xx = curses_version(); return (xx == 0); }],
2827                                         [cf_test_ncuconfig=yes],
2828                                         [cf_test_ncuconfig=no],
2829                                         [cf_test_ncuconfig=maybe])],
2830                                 [cf_test_ncuconfig=no])
2831
2832                         CFLAGS="$cf_save_CFLAGS"
2833                         CPPFLAGS="$cf_save_CPPFLAGS"
2834                         LIBS="$cf_save_LIBS"
2835
2836                         if test "x$cf_test_ncuconfig" != xyes; then
2837                                 cf_temp=`echo "x$cf_pkg_cflags" | sed -e s/^x// -e 's/-W[[^     ]]*//g'`
2838                                 cf_pkg_cflags="$cf_temp"
2839                                 cf_temp=`echo "x$cf_pkg_libs" | sed -e s/^x// -e 's/-W[[^       ]]*//g'`
2840                                 cf_pkg_libs="$cf_temp"
2841                         fi
2842                         ;;
2843                 esac
2844
2845                 CF_ADD_CFLAGS($cf_pkg_cflags)
2846                 CF_ADD_LIBS($cf_pkg_libs)
2847
2848                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2849                         [initscr(); mousemask(0,0); tigetstr((char *)0);],
2850                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2851                                 int main(void)
2852                                 { char *xx = curses_version(); return (xx == 0); }],
2853                                 [cf_have_ncuconfig=yes],
2854                                 [cf_have_ncuconfig=no],
2855                                 [cf_have_ncuconfig=maybe])],
2856                         [cf_have_ncuconfig=no])
2857                 AC_MSG_RESULT($cf_have_ncuconfig)
2858                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2859                 if test "$cf_have_ncuconfig" != "yes"
2860                 then
2861                         CPPFLAGS="$cf_save_CPPFLAGS"
2862                         LIBS="$cf_save_LIBS"
2863                         NCURSES_CONFIG_PKG=none
2864                 else
2865                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2866                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2867                         CF_TERM_HEADER
2868                 fi
2869
2870         else
2871                 AC_MSG_RESULT(no)
2872                 NCURSES_CONFIG_PKG=none
2873         fi
2874 else
2875         NCURSES_CONFIG_PKG=none
2876 fi
2877
2878 if test "x$cf_have_ncuconfig" = "xno"; then
2879         cf_ncurses_config="${cf_ncuconfig_root}${NCURSES_CONFIG_SUFFIX}-config"; echo "Looking for ${cf_ncurses_config}"
2880
2881         CF_ACVERSION_CHECK(2.52,
2882                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2883                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2884
2885         if test "$NCURSES_CONFIG" != none ; then
2886
2887                 CF_ADD_CFLAGS(`$NCURSES_CONFIG --cflags`)
2888                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2889
2890                 # even with config script, some packages use no-override for curses.h
2891                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2892
2893                 dnl like CF_NCURSES_CPPFLAGS
2894                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2895
2896                 dnl like CF_NCURSES_LIBS
2897                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2898                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2899
2900                 dnl like CF_NCURSES_VERSION
2901                 cf_cv_ncurses_version="`$NCURSES_CONFIG --version`"
2902
2903         else
2904
2905                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2906                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2907
2908         fi
2909 else
2910         NCURSES_CONFIG=none
2911 fi
2912 ])dnl
2913 dnl ---------------------------------------------------------------------------
2914 dnl CF_NCURSES_CPPFLAGS version: 22 updated: 2021/01/02 09:31:20
2915 dnl -------------------
2916 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2917 dnl the CPPFLAGS variable so we can include its header.
2918 dnl
2919 dnl The header files may be installed as either curses.h, or ncurses.h (would
2920 dnl be obsolete, except that some packagers prefer this name to distinguish it
2921 dnl from a "native" curses implementation).  If not installed for overwrite,
2922 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2923 dnl /usr/include/ncurses), but someone may have installed overwriting the
2924 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2925 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2926 dnl the header.
2927 dnl
2928 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2929 dnl is already in the include-path, don't even bother with this, since we cannot
2930 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2931 dnl
2932 dnl The optional parameter gives the root name of the library, in case it is
2933 dnl not installed as the default curses library.  That is how the
2934 dnl wide-character version of ncurses is installed.
2935 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2936 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2937
2938 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2939 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2940
2941 test -n "$cf_cv_curses_dir" && \
2942 test "$cf_cv_curses_dir" != "no" && { \
2943   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2944 }
2945
2946 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2947         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2948         { test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw; } && cf_header_list="$cf_header_list curses.h ncurses.h"
2949         for cf_header in $cf_header_list
2950         do
2951                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2952                 test "$cf_cv_ncurses_h" != no && break
2953         done
2954 ])
2955
2956 CF_NCURSES_HEADER
2957 CF_TERM_HEADER
2958
2959 # some applications need this, but should check for NCURSES_VERSION
2960 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2961
2962 CF_NCURSES_VERSION
2963 ])dnl
2964 dnl ---------------------------------------------------------------------------
2965 dnl CF_NCURSES_HEADER version: 7 updated: 2021/01/04 19:33:05
2966 dnl -----------------
2967 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2968 dnl variations of ncurses' installs.
2969 dnl
2970 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2971 AC_DEFUN([CF_NCURSES_HEADER],[
2972
2973 if test "$cf_cv_ncurses_h" != no ; then
2974         cf_cv_ncurses_header=$cf_cv_ncurses_h
2975 else
2976
2977 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2978         test -n "$verbose" && echo
2979         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2980         test -n "$verbose" && echo "search path $cf_search"
2981         cf_save2_CPPFLAGS="$CPPFLAGS"
2982         for cf_incdir in $cf_search
2983         do
2984                 CF_ADD_INCDIR($cf_incdir)
2985                 for cf_header in \
2986                         ncurses.h \
2987                         curses.h
2988                 do
2989                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2990                         if test "$cf_cv_ncurses_h2" != no ; then
2991                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2992                                 test -n "$verbose" && echo $ECHO_N "    ... found $ECHO_C" 1>&AC_FD_MSG
2993                                 break
2994                         fi
2995                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2996                 done
2997                 CPPFLAGS="$cf_save2_CPPFLAGS"
2998                 test "$cf_cv_ncurses_h2" != no && break
2999         done
3000         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
3001         ])
3002
3003         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
3004         cf_cv_ncurses_header="`basename "$cf_cv_ncurses_h2"`"
3005         if test "`basename "$cf_1st_incdir"`" = "$cf_ncuhdr_root" ; then
3006                 cf_cv_ncurses_header="$cf_ncuhdr_root/$cf_cv_ncurses_header"
3007         fi
3008         CF_ADD_INCDIR($cf_1st_incdir)
3009
3010 fi
3011
3012 # Set definitions to allow ifdef'ing for ncurses.h
3013
3014 case "$cf_cv_ncurses_header" in
3015 (*ncurses.h)
3016         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
3017         ;;
3018 esac
3019
3020 case "$cf_cv_ncurses_header" in
3021 (ncurses/curses.h|ncurses/ncurses.h)
3022         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
3023         ;;
3024 (ncursesw/curses.h|ncursesw/ncurses.h)
3025         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
3026         ;;
3027 esac
3028
3029 ])dnl
3030 dnl ---------------------------------------------------------------------------
3031 dnl CF_NCURSES_LIBS version: 20 updated: 2021/01/03 08:05:37
3032 dnl ---------------
3033 dnl Look for the ncurses library.  This is a little complicated on Linux,
3034 dnl because it may be linked with the gpm (general purpose mouse) library.
3035 dnl Some distributions have gpm linked with (bsd) curses, which makes it
3036 dnl unusable with ncurses.  However, we don't want to link with gpm unless
3037 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
3038 dnl and the linker will record a dependency.
3039 dnl
3040 dnl The optional parameter gives the root name of the library, in case it is
3041 dnl not installed as the default curses library.  That is how the
3042 dnl wide-character version of ncurses is installed.
3043 AC_DEFUN([CF_NCURSES_LIBS],
3044 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
3045
3046 cf_nculib_root=ifelse($1,,ncurses,$1)
3047         # This works, except for the special case where we find gpm, but
3048         # ncurses is in a nonstandard location via $LIBS, and we really want
3049         # to link gpm.
3050 cf_ncurses_LIBS=""
3051 cf_ncurses_SAVE="$LIBS"
3052 AC_CHECK_LIB(gpm,Gpm_Open,
3053         [AC_CHECK_LIB(gpm,initscr,
3054                 [LIBS="$cf_ncurses_SAVE"],
3055                 [cf_ncurses_LIBS="-lgpm"])])
3056
3057 case "$host_os" in
3058 (freebsd*)
3059         # This is only necessary if you are linking against an obsolete
3060         # version of ncurses (but it should do no harm, since it's static).
3061         if test "$cf_nculib_root" = ncurses ; then
3062                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
3063         fi
3064         ;;
3065 esac
3066
3067 CF_ADD_LIBS($cf_ncurses_LIBS)
3068
3069 if test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no"
3070 then
3071         CF_ADD_LIBS(-l$cf_nculib_root)
3072 else
3073         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
3074                 [#include <${cf_cv_ncurses_header:-curses.h}>],
3075                 [initscr()],
3076                 initscr)
3077 fi
3078
3079 if test -n "$cf_ncurses_LIBS" ; then
3080         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
3081         cf_ncurses_SAVE="$LIBS"
3082         for p in $cf_ncurses_LIBS ; do
3083                 q=`echo "$LIBS" | sed -e "s%$p %%" -e "s%$p$%%"`
3084                 if test "$q" != "$LIBS" ; then
3085                         LIBS="$q"
3086                 fi
3087         done
3088         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
3089                 [initscr(); mousemask(0,0); tigetstr((char *)0);],
3090                 [AC_MSG_RESULT(yes)],
3091                 [AC_MSG_RESULT(no)
3092                  LIBS="$cf_ncurses_SAVE"])
3093 fi
3094
3095 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
3096 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
3097 ])dnl
3098 dnl ---------------------------------------------------------------------------
3099 dnl CF_NCURSES_VERSION version: 16 updated: 2020/12/31 20:19:42
3100 dnl ------------------
3101 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
3102 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
3103 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
3104 AC_DEFUN([CF_NCURSES_VERSION],
3105 [
3106 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
3107 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
3108         cf_cv_ncurses_version=no
3109         cf_tempfile=out$$
3110         rm -f "$cf_tempfile"
3111         AC_TRY_RUN([
3112 #include <${cf_cv_ncurses_header:-curses.h}>
3113 #include <stdio.h>
3114 int main(void)
3115 {
3116         FILE *fp = fopen("$cf_tempfile", "w");
3117 #ifdef NCURSES_VERSION
3118 # ifdef NCURSES_VERSION_PATCH
3119         fprintf(fp, "%s.%d\\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
3120 # else
3121         fprintf(fp, "%s\\n", NCURSES_VERSION);
3122 # endif
3123 #else
3124 # ifdef __NCURSES_H
3125         fprintf(fp, "old\\n");
3126 # else
3127         make an error
3128 # endif
3129 #endif
3130         ${cf_cv_main_return:-return}(0);
3131 }],[
3132         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
3133
3134         # This will not work if the preprocessor splits the line after the
3135         # Autoconf token.  The 'unproto' program does that.
3136         cat > "conftest.$ac_ext" <<EOF
3137 #include <${cf_cv_ncurses_header:-curses.h}>
3138 #undef Autoconf
3139 #ifdef NCURSES_VERSION
3140 Autoconf NCURSES_VERSION
3141 #else
3142 #ifdef __NCURSES_H
3143 Autoconf "old"
3144 #endif
3145 ;
3146 #endif
3147 EOF
3148         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
3149         AC_TRY_EVAL(cf_try)
3150         if test -f conftest.out ; then
3151                 cf_out=`sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%' conftest.out`
3152                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
3153                 rm -f conftest.out
3154         fi
3155 ])
3156         rm -f "$cf_tempfile"
3157 ])
3158 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
3159 ])dnl
3160 dnl ---------------------------------------------------------------------------
3161 dnl CF_OBJ_SUBDIR version: 8 updated: 2021/01/01 13:31:04
3162 dnl -------------
3163 dnl Compute the object-directory name from the given model name
3164 AC_DEFUN([CF_OBJ_SUBDIR],
3165 [
3166         case $1 in
3167         (libtool) $2='obj_lo'  ;;
3168         (normal)  $2='objects' ;;
3169         (debug)   $2='obj_g' ;;
3170         (profile) $2='obj_p' ;;
3171         (shared)
3172                 case "$cf_cv_system_name" in
3173                 (cygwin|msys)
3174                         $2='objects' ;;
3175                 (*)
3176                         $2='obj_s' ;;
3177                 esac
3178         esac
3179 ])dnl
3180 dnl ---------------------------------------------------------------------------
3181 dnl CF_PATHSEP version: 8 updated: 2021/01/01 13:31:04
3182 dnl ----------
3183 dnl Provide a value for the $PATH and similar separator (or amend the value
3184 dnl as provided in autoconf 2.5x).
3185 AC_DEFUN([CF_PATHSEP],
3186 [
3187         AC_MSG_CHECKING(for PATH separator)
3188         case "$cf_cv_system_name" in
3189         (os2*)  PATH_SEPARATOR=';'  ;;
3190         (*)     ${PATH_SEPARATOR:=':'}  ;;
3191         esac
3192 ifelse([$1],,,[$1=$PATH_SEPARATOR])
3193         AC_SUBST(PATH_SEPARATOR)
3194         AC_MSG_RESULT($PATH_SEPARATOR)
3195 ])dnl
3196 dnl ---------------------------------------------------------------------------
3197 dnl CF_PATH_SYNTAX version: 18 updated: 2020/12/31 18:40:20
3198 dnl --------------
3199 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
3200 dnl begins with one of the prefix/exec_prefix variables, and then again if the
3201 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
3202 dnl delayed evaluation of those symbols.
3203 AC_DEFUN([CF_PATH_SYNTAX],[
3204 if test "x$prefix" != xNONE; then
3205         cf_path_syntax="$prefix"
3206 else
3207         cf_path_syntax="$ac_default_prefix"
3208 fi
3209
3210 case ".[$]$1" in
3211 (.\[$]\(*\)*|.\'*\'*)
3212         ;;
3213 (..|./*|.\\*)
3214         ;;
3215 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
3216         ;;
3217 (.\[$]\{*prefix\}*|.\[$]\{*dir\}*)
3218         eval $1="[$]$1"
3219         case ".[$]$1" in
3220         (.NONE/*)
3221                 $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
3222                 ;;
3223         esac
3224         ;;
3225 (.no|.NONE/*)
3226         $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
3227         ;;
3228 (*)
3229         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
3230         ;;
3231 esac
3232 ])dnl
3233 dnl ---------------------------------------------------------------------------
3234 dnl CF_PKG_CONFIG version: 11 updated: 2021/01/01 13:31:04
3235 dnl -------------
3236 dnl Check for the package-config program, unless disabled by command-line.
3237 AC_DEFUN([CF_PKG_CONFIG],
3238 [
3239 AC_MSG_CHECKING(if you want to use pkg-config)
3240 AC_ARG_WITH(pkg-config,
3241         [  --with-pkg-config{=path} enable/disable use of pkg-config],
3242         [cf_pkg_config=$withval],
3243         [cf_pkg_config=yes])
3244 AC_MSG_RESULT($cf_pkg_config)
3245
3246 case "$cf_pkg_config" in
3247 (no)
3248         PKG_CONFIG=none
3249         ;;
3250 (yes)
3251         CF_ACVERSION_CHECK(2.52,
3252                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
3253                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
3254         ;;
3255 (*)
3256         PKG_CONFIG=$withval
3257         ;;
3258 esac
3259
3260 test -z "$PKG_CONFIG" && PKG_CONFIG=none
3261 if test "$PKG_CONFIG" != none ; then
3262         CF_PATH_SYNTAX(PKG_CONFIG)
3263 elif test "x$cf_pkg_config" != xno ; then
3264         AC_MSG_WARN(pkg-config is not installed)
3265 fi
3266
3267 AC_SUBST(PKG_CONFIG)
3268 ])dnl
3269 dnl ---------------------------------------------------------------------------
3270 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
3271 dnl -----------------
3272 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
3273 dnl
3274 dnl     POSIX.1-1990                            _POSIX_SOURCE
3275 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
3276 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
3277 dnl             Bindings Option
3278 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
3279 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
3280 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
3281 dnl
3282 dnl Parameters:
3283 dnl     $1 is the nominal value for _POSIX_C_SOURCE
3284 AC_DEFUN([CF_POSIX_C_SOURCE],
3285 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
3286
3287 if test "$cf_cv_posix_visible" = no; then
3288
3289 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
3290
3291 cf_save_CFLAGS="$CFLAGS"
3292 cf_save_CPPFLAGS="$CPPFLAGS"
3293
3294 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
3295 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
3296
3297 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
3298         CF_MSG_LOG(if the symbol is already defined go no further)
3299         AC_TRY_COMPILE([#include <sys/types.h>],[
3300 #ifndef _POSIX_C_SOURCE
3301 make an error
3302 #endif],
3303         [cf_cv_posix_c_source=no],
3304         [cf_want_posix_source=no
3305          case .$cf_POSIX_C_SOURCE in
3306          (.[[12]]??*)
3307                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3308                 ;;
3309          (.2)
3310                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3311                 cf_want_posix_source=yes
3312                 ;;
3313          (.*)
3314                 cf_want_posix_source=yes
3315                 ;;
3316          esac
3317          if test "$cf_want_posix_source" = yes ; then
3318                 AC_TRY_COMPILE([#include <sys/types.h>],[
3319 #ifdef _POSIX_SOURCE
3320 make an error
3321 #endif],[],
3322                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
3323          fi
3324          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
3325          CFLAGS="$cf_trim_CFLAGS"
3326          CPPFLAGS="$cf_trim_CPPFLAGS"
3327          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
3328          CF_MSG_LOG(if the second compile does not leave our definition intact error)
3329          AC_TRY_COMPILE([#include <sys/types.h>],[
3330 #ifndef _POSIX_C_SOURCE
3331 make an error
3332 #endif],,
3333          [cf_cv_posix_c_source=no])
3334          CFLAGS="$cf_save_CFLAGS"
3335          CPPFLAGS="$cf_save_CPPFLAGS"
3336         ])
3337 ])
3338
3339 if test "$cf_cv_posix_c_source" != no ; then
3340         CFLAGS="$cf_trim_CFLAGS"
3341         CPPFLAGS="$cf_trim_CPPFLAGS"
3342         CF_ADD_CFLAGS($cf_cv_posix_c_source)
3343 fi
3344
3345 fi # cf_cv_posix_visible
3346
3347 ])dnl
3348 dnl ---------------------------------------------------------------------------
3349 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
3350 dnl ----------------
3351 dnl POSIX documents test-macros which an application may set before any system
3352 dnl headers are included to make features available.
3353 dnl
3354 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
3355 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
3356 dnl recent features visible in the system header files unless the application
3357 dnl overrides the corresponding test-macros.  Doing that introduces portability
3358 dnl problems.
3359 dnl
3360 dnl This macro makes a special check for the symbols used for this, to avoid a
3361 dnl conflicting definition.
3362 AC_DEFUN([CF_POSIX_VISIBLE],
3363 [
3364 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
3365 AC_TRY_COMPILE([#include <stdio.h>],[
3366 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
3367         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
3368         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
3369         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
3370 #error conflicting symbols found
3371 #endif
3372 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
3373 ])
3374 ])dnl
3375 dnl ---------------------------------------------------------------------------
3376 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
3377 dnl ----------
3378 dnl Check for archiver "ar".
3379 AC_DEFUN([CF_PROG_AR],[
3380 AC_CHECK_TOOL(AR, ar, ar)
3381 ])
3382 dnl ---------------------------------------------------------------------------
3383 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
3384 dnl -----------
3385 dnl Check for awk, ensure that the check found something.
3386 AC_DEFUN([CF_PROG_AWK],
3387 [
3388 AC_PROG_AWK
3389 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
3390 ])dnl
3391 dnl ---------------------------------------------------------------------------
3392 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
3393 dnl ----------
3394 dnl standard check for CC, plus followup sanity checks
3395 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
3396 AC_DEFUN([CF_PROG_CC],[
3397 CF_ACVERSION_CHECK(2.53,
3398         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
3399          AC_REQUIRE([AC_PROG_CC])],
3400         [])
3401 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
3402 CF_GCC_VERSION
3403 CF_ACVERSION_CHECK(2.52,
3404         [AC_PROG_CC_STDC],
3405         [CF_ANSI_CC_REQD])
3406 CF_CC_ENV_FLAGS
3407 ])dnl
3408 dnl ---------------------------------------------------------------------------
3409 dnl CF_PROG_CC_C_O version: 6 updated: 2021/01/01 13:31:04
3410 dnl --------------
3411 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
3412 dnl the output file can be renamed, and allows for a shell variable that can
3413 dnl be used later.  The parameter is either CC or CXX.  The result is the
3414 dnl cache variable:
3415 dnl     $cf_cv_prog_CC_c_o
3416 dnl     $cf_cv_prog_CXX_c_o
3417 dnl
3418 dnl $1 = compiler
3419 dnl $2 = compiler options, if any
3420 AC_DEFUN([CF_PROG_CC_C_O],
3421 [AC_REQUIRE([AC_PROG_CC])dnl
3422 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
3423 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
3424 [
3425 cat > conftest.$ac_ext <<CF_EOF
3426 int main(void)
3427 {
3428         ${cf_cv_main_return:-return}(0);
3429 }
3430 CF_EOF
3431 # We do the test twice because some compilers refuse to overwrite an
3432 # existing .o file with -o, though they will create one.
3433 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
3434 if AC_TRY_EVAL(ac_try) &&
3435   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
3436 then
3437   eval cf_cv_prog_$1_c_o=yes
3438 else
3439   eval cf_cv_prog_$1_c_o=no
3440 fi
3441 rm -rf ./conftest*
3442 ])dnl
3443 if test "$cf_cv_prog_$1_c_o" = yes; then
3444   AC_MSG_RESULT([yes])
3445 else
3446   AC_MSG_RESULT([no])
3447 fi
3448 ])dnl
3449 dnl ---------------------------------------------------------------------------
3450 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
3451 dnl -------------
3452 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
3453 dnl This macro adds a check to ensure the script found something.
3454 AC_DEFUN([CF_PROG_EGREP],
3455 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
3456         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
3457                 then ac_cv_prog_egrep='grep -E'
3458                 else ac_cv_prog_egrep='egrep'
3459         fi])
3460         EGREP=$ac_cv_prog_egrep
3461         AC_SUBST([EGREP])
3462         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
3463 ])dnl
3464 dnl ---------------------------------------------------------------------------
3465 dnl CF_PROG_EXT version: 15 updated: 2021/01/02 09:31:20
3466 dnl -----------
3467 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
3468 AC_DEFUN([CF_PROG_EXT],
3469 [
3470 AC_REQUIRE([CF_CHECK_CACHE])
3471 case "$cf_cv_system_name" in
3472 (os2*)
3473         CFLAGS="$CFLAGS -Zmt"
3474         CF_APPEND_TEXT(CPPFLAGS,-D__ST_MT_ERRNO__)
3475         CXXFLAGS="$CXXFLAGS -Zmt"
3476         # autoconf's macro sets -Zexe and suffix both, which conflict:w
3477         LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
3478         ac_cv_exeext=.exe
3479         ;;
3480 esac
3481
3482 AC_EXEEXT
3483 AC_OBJEXT
3484
3485 PROG_EXT="$EXEEXT"
3486 AC_SUBST(PROG_EXT)
3487 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
3488 ])dnl
3489 dnl ---------------------------------------------------------------------------
3490 dnl CF_PROG_GNAT version: 12 updated: 2021/01/02 17:09:14
3491 dnl ------------
3492 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
3493 AC_DEFUN([CF_PROG_GNAT],[
3494 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
3495 do
3496         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
3497
3498         unset ac_cv_path_cf_TEMP_gnat
3499         unset cf_TEMP_gnat
3500         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
3501         eval "cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat"
3502
3503         if test "x$cf_TEMP_gnat" != xno; then
3504                 unset cf_cv_gnat_version
3505                 unset cf_TEMP_gnat
3506                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
3507         fi
3508         eval "cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat"
3509
3510         unset cf_TEMP_gnat
3511         unset cf_cv_gnat_version
3512         unset ac_cv_path_cf_TEMP_gnat
3513 done
3514
3515 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
3516         cf_ada_make=
3517         cf_cv_prog_gnat_correct=no
3518 else
3519         cf_ada_make=gnatmake
3520         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
3521                 # gprconfig is newer than gnatmake; we can continue...
3522                 cf_ada_config="##"
3523         else
3524                 rm -rf ./conftest* ./*~conftest*
3525                 if mkdir conftest.src
3526                 then
3527                         cf_ada_config=""
3528                         cd conftest.src
3529                         for cf_gprconfig in Ada C
3530                         do
3531                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
3532                                 if test "$cf_gprconfig" = C
3533                                 then
3534                                         for cf_gprconfig_param in \
3535                                                 "$cf_gprconfig,,,,GNATGCC" \
3536                                                 "$cf_gprconfig,,,,GCC" \
3537                                                 "$cf_gprconfig"
3538                                         do
3539                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
3540                                                 test -n "$cf_gprconfig_value" && break
3541                                         done
3542                                 else
3543                                         cf_gprconfig_param=$cf_gprconfig
3544                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
3545                                 fi
3546                                 if test -n "$cf_gprconfig_value"
3547                                 then
3548                                         eval "cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value"
3549                                         AC_MSG_RESULT($cf_gprconfig_value)
3550                                 else
3551                                         AC_MSG_RESULT(missing)
3552                                         cf_ada_config="#"
3553                                         break
3554                                 fi
3555                         done
3556                         cd ..
3557                         rm -rf ./conftest* ./*~conftest*
3558                 fi
3559         fi
3560         if test "x$cf_ada_config" != "x#"
3561         then
3562                 CF_GNAT_VERSION
3563                 CF_CHECK_GNAT_VERSION
3564                 AC_CHECK_PROG(M4_exists, m4, yes, no)
3565                 if test "$ac_cv_prog_M4_exists" = no; then
3566                         cf_cv_prog_gnat_correct=no
3567                         AC_MSG_WARN(Ada95 binding required program m4 not found. Ada95 binding disabled)
3568                 fi
3569                 if test "$cf_cv_prog_gnat_correct" = yes; then
3570                         AC_MSG_CHECKING(if GNAT works)
3571                         CF_GNAT_TRY_RUN([procedure conftest;],
3572 [with Text_IO;
3573 with GNAT.OS_Lib;
3574 procedure conftest is
3575 begin
3576    Text_IO.Put ("Hello World");
3577    Text_IO.New_Line;
3578    GNAT.OS_Lib.OS_Exit (0);
3579 end conftest;],
3580 [cf_cv_prog_gnat_correct=yes],
3581 [cf_cv_prog_gnat_correct=no])
3582                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
3583                 fi
3584         else
3585                 cf_cv_prog_gnat_correct=no
3586         fi
3587 fi
3588
3589 AC_SUBST(cf_ada_make)
3590 AC_SUBST(cf_ada_config)
3591 AC_SUBST(cf_ada_config_Ada)
3592 AC_SUBST(cf_ada_config_C)
3593 ])dnl
3594 dnl ---------------------------------------------------------------------------
3595 dnl CF_PROG_INSTALL version: 10 updated: 2021/01/04 19:33:05
3596 dnl ---------------
3597 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
3598 dnl misc/tabset install won't work properly.  Usually this happens only when
3599 dnl using the fallback mkinstalldirs script
3600 AC_DEFUN([CF_PROG_INSTALL],
3601 [AC_PROG_INSTALL
3602 case $INSTALL in
3603 (/*)
3604         ;;
3605 (*)
3606         CF_DIRNAME(cf_dir,$INSTALL)
3607         test -z "$cf_dir" && cf_dir=.
3608         INSTALL="`cd \"$cf_dir\" && pwd`"/"`echo "$INSTALL" | sed -e 's%^.*/%%'`"
3609         ;;
3610 esac
3611 ])dnl
3612 dnl ---------------------------------------------------------------------------
3613 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
3614 dnl ------------
3615 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
3616 dnl option if it is supported.
3617 AC_DEFUN([CF_PROG_LN_S],[
3618 AC_PROG_LN_S
3619 AC_MSG_CHECKING(if $LN_S -f options work)
3620
3621 rm -f conf$$.src conf$$dst
3622 echo >conf$$.dst
3623 echo first >conf$$.src
3624 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
3625         cf_prog_ln_sf=yes
3626 else
3627         cf_prog_ln_sf=no
3628 fi
3629 rm -f conf$$.dst conf$$src
3630 AC_MSG_RESULT($cf_prog_ln_sf)
3631
3632 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
3633 ])dnl
3634 dnl ---------------------------------------------------------------------------
3635 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
3636 dnl ----------------
3637 dnl Remove all -U and -D options that refer to the given symbol from a list
3638 dnl of C compiler options.  This works around the problem that not all
3639 dnl compilers process -U and -D options from left-to-right, so a -U option
3640 dnl cannot be used to cancel the effect of a preceding -D option.
3641 dnl
3642 dnl $1 = target (which could be the same as the source variable)
3643 dnl $2 = source (including '$')
3644 dnl $3 = symbol to remove
3645 define([CF_REMOVE_DEFINE],
3646 [
3647 $1=`echo "$2" | \
3648         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
3649                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
3650 ])dnl
3651 dnl ---------------------------------------------------------------------------
3652 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
3653 dnl -------------
3654 dnl Remove the given library from the symbol
3655 dnl
3656 dnl $1 = target (which could be the same as the source variable)
3657 dnl $2 = source (including '$')
3658 dnl $3 = library to remove
3659 define([CF_REMOVE_LIB],
3660 [
3661 # remove $3 library from $2
3662 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
3663 ])dnl
3664 dnl ---------------------------------------------------------------------------
3665 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
3666 dnl ---------------------
3667 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
3668 dnl $1 = name of current macro
3669 define([CF_RESTORE_XTRA_FLAGS],
3670 [
3671 LIBS="$cf_save_LIBS_$1"
3672 CFLAGS="$cf_save_CFLAGS_$1"
3673 CPPFLAGS="$cf_save_CPPFLAGS_$1"
3674 ])dnl
3675 dnl ---------------------------------------------------------------------------
3676 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
3677 dnl ------------------
3678 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
3679 dnl and libraries which do not update those variables.
3680 dnl
3681 dnl $1 = name of current macro
3682 define([CF_SAVE_XTRA_FLAGS],
3683 [
3684 cf_save_LIBS_$1="$LIBS"
3685 cf_save_CFLAGS_$1="$CFLAGS"
3686 cf_save_CPPFLAGS_$1="$CPPFLAGS"
3687 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
3688 for cf_X_CFLAGS in $X_CFLAGS
3689 do
3690         case "x$cf_X_CFLAGS" in
3691         x-[[IUD]]*)
3692                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
3693                 ;;
3694         *)
3695                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
3696                 ;;
3697         esac
3698 done
3699 ])dnl
3700 dnl ---------------------------------------------------------------------------
3701 dnl CF_SHARED_OPTS version: 105 updated: 2021/01/02 17:09:14
3702 dnl --------------
3703 dnl --------------
3704 dnl Attempt to determine the appropriate CC/LD options for creating a shared
3705 dnl library.
3706 dnl
3707 dnl Notes:
3708 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
3709 dnl the build-tree, i.e., by making use of the libraries that are compiled in
3710 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
3711 dnl shared library since that can lead to unexpected results at runtime.
3712 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
3713 dnl libraries are compiled in ../../lib
3714 dnl
3715 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
3716 dnl to install symbolic links to the rel/abi versions of shared libraries.
3717 dnl
3718 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
3719 dnl version when making symbolic links.
3720 dnl
3721 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
3722 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
3723 dnl (ex: libncurses.so.<ver>).
3724 dnl
3725 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
3726 AC_DEFUN([CF_SHARED_OPTS],
3727 [
3728         AC_REQUIRE([CF_LD_RPATH_OPT])
3729
3730         RM_SHARED_OPTS=
3731         LOCAL_LDFLAGS=
3732         LOCAL_LDFLAGS2=
3733         LD_SHARED_OPTS=
3734         INSTALL_LIB="-m 644"
3735         : ${rel_builddir:=.}
3736
3737         shlibdir=$libdir
3738         AC_SUBST(shlibdir)
3739
3740         MAKE_DLLS="#"
3741         AC_SUBST(MAKE_DLLS)
3742
3743         cf_cv_do_symlinks=no
3744         cf_ld_rpath_opt=
3745         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
3746
3747         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
3748         AC_ARG_WITH(shlib-version,
3749         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
3750         [test -z "$withval" && withval=auto
3751         case "$withval" in
3752         (yes)
3753                 cf_cv_shlib_version=auto
3754                 ;;
3755         (rel|abi|auto)
3756                 cf_cv_shlib_version=$withval
3757                 ;;
3758         (*)
3759                 AC_MSG_RESULT($withval)
3760                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
3761                 ;;
3762         esac
3763         ],[cf_cv_shlib_version=auto])
3764         AC_MSG_RESULT($cf_cv_shlib_version)
3765
3766         cf_cv_rm_so_locs=no
3767         cf_try_cflags=
3768
3769         # Some less-capable ports of gcc support only -fpic
3770         CC_SHARED_OPTS=
3771
3772         cf_try_fPIC=no
3773         if test "$GCC" = yes
3774         then
3775                 cf_try_fPIC=yes
3776         else
3777                 case "$cf_cv_system_name" in
3778                 (*linux*)       # e.g., PGI compiler
3779                         cf_try_fPIC=yes
3780                         ;;
3781                 esac
3782         fi
3783
3784         if test "$cf_try_fPIC" = yes
3785         then
3786                 AC_MSG_CHECKING(which $CC option to use)
3787                 cf_save_CFLAGS="$CFLAGS"
3788                 for CC_SHARED_OPTS in -fPIC -fpic ''
3789                 do
3790                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
3791                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
3792                 done
3793                 AC_MSG_RESULT($CC_SHARED_OPTS)
3794                 CFLAGS="$cf_save_CFLAGS"
3795         fi
3796
3797         cf_cv_shlib_version_infix=no
3798
3799         case "$cf_cv_system_name" in
3800         (aix4.[3-9]*|aix[[5-7]]*)
3801                 if test "$GCC" = yes; then
3802                         CC_SHARED_OPTS='-Wl,-brtl'
3803                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3804                 else
3805                         CC_SHARED_OPTS='-brtl'
3806                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
3807                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3808                 fi
3809                 ;;
3810         (beos*)
3811                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
3812                 ;;
3813         (cygwin*)
3814                 CC_SHARED_OPTS=
3815                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3816                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3817                 cf_cv_shlib_version=cygdll
3818                 cf_cv_shlib_version_infix=cygdll
3819                 shlibdir=$bindir
3820                 MAKE_DLLS=
3821                 cat >mk_shared_lib.sh <<-CF_EOF
3822                 #!$SHELL
3823                 SHARED_LIB=\[$]1
3824                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3825                 shift
3826                 cat <<-EOF
3827                 Linking shared library
3828                 ** SHARED_LIB \[$]SHARED_LIB
3829                 ** IMPORT_LIB \[$]IMPORT_LIB
3830 EOF
3831                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3832 CF_EOF
3833                 chmod +x mk_shared_lib.sh
3834                 ;;
3835         (msys*)
3836                 CC_SHARED_OPTS=
3837                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3838                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3839                 cf_cv_shlib_version=msysdll
3840                 cf_cv_shlib_version_infix=msysdll
3841                 shlibdir=$bindir
3842                 MAKE_DLLS=
3843                 cat >mk_shared_lib.sh <<-CF_EOF
3844                 #!$SHELL
3845                 SHARED_LIB=\[$]1
3846                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3847                 shift
3848                 cat <<-EOF
3849                 Linking shared library
3850                 ** SHARED_LIB \[$]SHARED_LIB
3851                 ** IMPORT_LIB \[$]IMPORT_LIB
3852 EOF
3853                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3854 CF_EOF
3855                 chmod +x mk_shared_lib.sh
3856                 ;;
3857         (darwin*)
3858                 cf_try_cflags="no-cpp-precomp"
3859                 CC_SHARED_OPTS="-dynamic"
3860                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
3861                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
3862                 cf_cv_shlib_version_infix=yes
3863                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
3864                         cf_save_LDFLAGS=$LDFLAGS
3865                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3866                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
3867                                 LDFLAGS=$cf_save_LDFLAGS])
3868                 if test "$cf_cv_ldflags_search_paths_first" = yes; then
3869                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3870                 fi
3871                 ;;
3872         (hpux[[7-8]]*)
3873                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
3874                 if test "$GCC" != yes; then
3875                         CC_SHARED_OPTS='+Z'
3876                 fi
3877                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
3878                 INSTALL_LIB="-m 555"
3879                 ;;
3880         (hpux*)
3881                 # (tested with gcc 2.7.2 -- I don't have c89)
3882                 if test "$GCC" = yes; then
3883                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
3884                 else
3885                         CC_SHARED_OPTS='+Z'
3886                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
3887                 fi
3888                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
3889                 # HP-UX shared libraries must be executable, and should be
3890                 # readonly to exploit a quirk in the memory manager.
3891                 INSTALL_LIB="-m 555"
3892                 ;;
3893         (interix*)
3894                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3895                 if test "$cf_cv_shlib_version" = rel; then
3896                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3897                 else
3898                         cf_shared_soname='`basename $[@]`'
3899                 fi
3900                 CC_SHARED_OPTS=
3901                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
3902                 ;;
3903         (irix*)
3904                 if test "$cf_cv_enable_rpath" = yes ; then
3905                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3906                 fi
3907                 # tested with IRIX 5.2 and 'cc'.
3908                 if test "$GCC" != yes; then
3909                         CC_SHARED_OPTS='-KPIC'
3910                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
3911                 else
3912                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
3913                 fi
3914                 cf_cv_rm_so_locs=yes
3915                 ;;
3916         (linux*|gnu*|k*bsd*-gnu)
3917                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
3918                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3919                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3920                 fi
3921                 if test "$cf_cv_enable_rpath" = yes ; then
3922                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3923                 fi
3924                 CF_SHARED_SONAME
3925                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3926                 ;;
3927         (mingw*msvc*)
3928                 cf_cv_shlib_version=msvcdll
3929                 cf_cv_shlib_version_infix=msvcdll
3930                 shlibdir=$bindir
3931                 MAKE_DLLS=
3932                 if test "$DFT_LWR_MODEL" = "shared" ; then
3933                         LOCAL_LDFLAGS="-link -dll"
3934                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3935                         EXTRA_LDFLAGS="-link -dll $EXTRA_LDFLAGS"
3936                 fi
3937                 CC_SHARED_OPTS=
3938                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ ${LD} [$]{CFLAGS}'
3939                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.lib"
3940                 cat >mk_shared_lib.sh <<-CF_EOF
3941                 #!$SHELL
3942                 SHARED_LIB=\[$]1
3943                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.lib/'\`
3944                 shift
3945                 my_ld=\[$]1
3946                 shift
3947                 cat <<-EOF
3948                 Linking shared library
3949                 ** SHARED LIB \$SHARED_LIB
3950                 ** IMPORT_LIB \$IMPORT_LIB
3951 EOF
3952                 args=\$(echo \[$]* | sed -E "s#-l(\w*)#\1.dll.lib#g" | sed -E "s#-L(\w*)#-LIBPATH:\1#g")
3953                 exec \$my_ld -DLL -IMPLIB:"\${IMPORT_LIB}" -OUT:"\${SHARED_LIB}" ${LDFLAGS} \$args
3954                 mv "\${IMPORT_LIB}" "\${IMPORT_LIB}"
3955 CF_EOF
3956                 chmod +x mk_shared_lib.sh
3957                 cat >mk_prog.sh <<-CF_EOF
3958                 #!$SHELL
3959                 shift
3960                 # Ignore first argument (compiler) and use LD (link.exe) unconditionally
3961                 LD="[$]LD"
3962                 clopts=()
3963                 ldopts=("/subsystem:console")
3964                 libs=()
3965                 isdll=0
3966                 while test \[$]# -gt 0; do
3967                         case "\[$]1" in
3968                                 -link)
3969                                         # ignore -link argument
3970                                         ;;
3971                                 -M[[TD]] | -M[[TD]]d)
3972                                         # ignore runtime-library option
3973                                         ;;
3974                                 -dll)
3975                                         isdll=1
3976                                         ;;
3977                                 -W* | -w*)
3978                                         # ignore warnings
3979                                         ;;
3980                                 -D*)
3981                                         clopts+=("\[$]1")
3982                                         ;;
3983                                 -I*)
3984                                         clopts+=("\[$]1")
3985                                         ;;
3986                                 -l*)
3987                                         libs+=("\`echo \"\[$]1\" | sed \"s/^-l//\"\`")
3988                                         ;;
3989                                 -L*)
3990                                         ldopts+=("\`echo \"\[$]1\" | sed \"s/^-L/-LIBPATH:/\"\`")
3991                                         ;;
3992                                 *.obj | *.o)
3993                                         ldopts+=("\[$]1")
3994                                         ;;
3995                                 -Wl,*)
3996                                         for linkarg in \`echo '\[$]1' | sed -e 's/-Wl,//' -e 's/,/ /'\`; do
3997                                                 ldopts+=("\[$]{linkarg}")
3998                                         done
3999                                         ;;
4000                                 *.lib)
4001                                         ldopts+=("\[$]1")
4002                                         ;;
4003                                 -o)
4004                                         shift
4005                                         ldopts+=("-out:\[$]1")
4006                                         ;;
4007                                 *)
4008                                         clopts+=("\[$]1")
4009                                         ldopts+=("\[$]1")
4010                                         ;;
4011                         esac
4012                         shift
4013                 done
4014                 if [[ "\$isdll" -ne 0 ]]; then
4015                         for lib in \[$]{libs[[*]]}; do
4016                                 ldopts+=("\[$]lib.dll.lib")
4017                         done
4018                 else
4019                         for lib in \[$]{libs[[*]]}; do
4020                                 ldopts+=("\[$]lib.lib")
4021                         done
4022                 fi
4023                 cat <<-EOF
4024                 Creating program
4025                 ** ld options:   "\[$]{ldopts[[@]]}"
4026 EOF
4027                 exec \[$]LD \[$]{ldopts[[@]]}
4028 CF_EOF
4029                 chmod +x mk_prog.sh
4030                 LINK_PROGS="$SHELL ${rel_builddir}/mk_prog.sh"
4031                 LINK_TESTS="$SHELL ${rel_builddir}/mk_prog.sh"
4032                 ;;
4033         (mingw*)
4034                 cf_cv_shlib_version=mingw
4035                 cf_cv_shlib_version_infix=mingw
4036                 shlibdir=$bindir
4037                 MAKE_DLLS=
4038                 if test "$DFT_LWR_MODEL" = "shared" ; then
4039                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
4040                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
4041                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
4042                 fi
4043                 CC_SHARED_OPTS=
4044                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
4045                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
4046                 cat >mk_shared_lib.sh <<-CF_EOF
4047                 #!$SHELL
4048                 SHARED_LIB=\[$]1
4049                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
4050                 shift
4051                 cat <<-EOF
4052                 Linking shared library
4053                 ** SHARED_LIB \[$]SHARED_LIB
4054                 ** IMPORT_LIB \[$]IMPORT_LIB
4055 EOF
4056                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
4057 CF_EOF
4058                 chmod +x mk_shared_lib.sh
4059                 ;;
4060         (openbsd[[2-9]].*|mirbsd*)
4061                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
4062                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
4063                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
4064                 fi
4065                 if test "$cf_cv_enable_rpath" = yes ; then
4066                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
4067                 fi
4068                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
4069                 CF_SHARED_SONAME
4070                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
4071                 ;;
4072         (nskJ*)
4073                 CC_SHARED_OPTS=
4074                 MK_SHARED_LIB='${LD} -Wshared -Weld=-export_all -o $[@]'
4075                 ;;
4076         (nskL*)
4077                 CC_SHARED_OPTS=
4078                 MK_SHARED_LIB='${LD} -Wshared -Wxld=-export_all -o $[@]'
4079                 ;;
4080         (nto-qnx*|openbsd*|freebsd[[12]].*)
4081                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
4082                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
4083                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
4084                 ;;
4085         (dragonfly*|freebsd*)
4086                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
4087                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
4088                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
4089                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
4090                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
4091                 fi
4092                 CF_SHARED_SONAME
4093                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
4094                 ;;
4095         (netbsd*)
4096                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
4097                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
4098                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
4099                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
4100                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
4101                         if test "$cf_cv_shlib_version" = auto; then
4102                         if test -f /usr/libexec/ld.elf_so; then
4103                                 cf_cv_shlib_version=abi
4104                         else
4105                                 cf_cv_shlib_version=rel
4106                         fi
4107                         fi
4108                         CF_SHARED_SONAME
4109                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
4110                 else
4111                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -o $[@]'
4112                 fi
4113                 ;;
4114         (osf*|mls+*)
4115                 # tested with OSF/1 V3.2 and 'cc'
4116                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
4117                 # link with shared libs).
4118                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
4119                 case "$host_os" in
4120                 (osf4*)
4121                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
4122                         ;;
4123                 esac
4124                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
4125                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
4126                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
4127                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
4128                 fi
4129                 cf_cv_rm_so_locs=yes
4130                 ;;
4131         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
4132                 # tested with osr5.0.5
4133                 if test "$GCC" != yes; then
4134                         CC_SHARED_OPTS='-belf -KPIC'
4135                 fi
4136                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
4137                 if test "$cf_cv_enable_rpath" = yes ; then
4138                         # only way is to set LD_RUN_PATH but no switch for it
4139                         RUN_PATH=$libdir
4140                 fi
4141                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
4142                 LINK_PROGS='LD_RUN_PATH=${libdir}'
4143                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
4144                 ;;
4145         (sunos4*)
4146                 # tested with SunOS 4.1.1 and gcc 2.7.0
4147                 if test "$GCC" != yes; then
4148                         CC_SHARED_OPTS='-KPIC'
4149                 fi
4150                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
4151                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
4152                 ;;
4153         (solaris2*)
4154                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
4155                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
4156                 if test "$DFT_LWR_MODEL" = "shared" ; then
4157                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
4158                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
4159                 fi
4160                 if test "$cf_cv_enable_rpath" = yes ; then
4161                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
4162                 fi
4163                 CF_SHARED_SONAME
4164                 if test "$GCC" != yes; then
4165                         cf_save_CFLAGS="$CFLAGS"
4166                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
4167                         do
4168                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
4169                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\\n");],[break])
4170                         done
4171                         CFLAGS="$cf_save_CFLAGS"
4172                         CC_SHARED_OPTS=$cf_shared_opts
4173                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
4174                 else
4175                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
4176                 fi
4177                 ;;
4178         (sysv5uw7*|unix_sv*)
4179                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
4180                 if test "$GCC" != yes; then
4181                         CC_SHARED_OPTS='-KPIC'
4182                 fi
4183                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
4184                 ;;
4185         (*)
4186                 CC_SHARED_OPTS='unknown'
4187                 MK_SHARED_LIB='echo unknown'
4188                 ;;
4189         esac
4190
4191         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
4192         case "$cf_cv_shlib_version" in
4193         (rel|abi)
4194                 case "$MK_SHARED_LIB" in
4195                 (*'-o $[@]')
4196                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
4197                         ;;
4198                 (*)
4199                         AC_MSG_WARN(ignored --with-shlib-version)
4200                         ;;
4201                 esac
4202                 ;;
4203         esac
4204
4205         if test -n "$cf_try_cflags"
4206         then
4207 cat > conftest.$ac_ext <<EOF
4208 #line __oline__ "${as_me:-configure}"
4209 #include <stdio.h>
4210 int main(int argc, char *argv[[]])
4211 {
4212         printf("hello\\n");
4213         return (argv[[argc-1]] == 0) ;
4214 }
4215 EOF
4216                 cf_save_CFLAGS="$CFLAGS"
4217                 for cf_opt in $cf_try_cflags
4218                 do
4219                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
4220                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
4221                         if AC_TRY_EVAL(ac_compile); then
4222                                 AC_MSG_RESULT(yes)
4223                                 cf_save_CFLAGS="$CFLAGS"
4224                         else
4225                                 AC_MSG_RESULT(no)
4226                         fi
4227                 done
4228                 CFLAGS="$cf_save_CFLAGS"
4229         fi
4230
4231
4232         # RPATH_LIST is a colon-separated list of directories
4233         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
4234         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
4235
4236         test "$cf_cv_rm_so_locs" = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
4237
4238         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
4239         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
4240
4241         AC_SUBST(CC_SHARED_OPTS)
4242         AC_SUBST(LD_RPATH_OPT)
4243         AC_SUBST(LD_SHARED_OPTS)
4244         AC_SUBST(MK_SHARED_LIB)
4245         AC_SUBST(RM_SHARED_OPTS)
4246
4247         AC_SUBST(LINK_PROGS)
4248         AC_SUBST(LINK_TESTS)
4249
4250         AC_SUBST(EXTRA_LDFLAGS)
4251         AC_SUBST(LOCAL_LDFLAGS)
4252         AC_SUBST(LOCAL_LDFLAGS2)
4253
4254         AC_SUBST(INSTALL_LIB)
4255         AC_SUBST(RPATH_LIST)
4256 ])dnl
4257 dnl ---------------------------------------------------------------------------
4258 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
4259 dnl ----------------
4260 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
4261 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
4262 dnl option.
4263 dnl
4264 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
4265 dnl If missing, use "rel".
4266 define([CF_SHARED_SONAME],
4267 [
4268         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
4269         if test "$cf_cv_shlib_version" = rel; then
4270                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
4271         else
4272                 cf_cv_shared_soname='`basename $[@]`'
4273         fi
4274 ])
4275 dnl ---------------------------------------------------------------------------
4276 dnl CF_STRIP_G_OPT version: 4 updated: 2021/01/02 09:31:20
4277 dnl --------------
4278 dnl     Remove "-g" option from the compiler options
4279 AC_DEFUN([CF_STRIP_G_OPT],
4280 [$1=`echo "${$1}" | CF__SED_TRIMBLANKS(-e 's%-g %%' -e 's%-g$%%')`])dnl
4281 dnl ---------------------------------------------------------------------------
4282 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
4283 dnl --------------
4284 dnl Construct a search-list for a nonstandard header/lib-file
4285 dnl     $1 = the variable to return as result
4286 dnl     $2 = the package name
4287 dnl     $3 = the subdirectory, e.g., bin, include or lib
4288 AC_DEFUN([CF_SUBDIR_PATH],
4289 [
4290 $1=
4291
4292 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
4293
4294 for cf_subdir_prefix in \
4295         /usr \
4296         /usr/local \
4297         /usr/pkg \
4298         /opt \
4299         /opt/local \
4300         [$]HOME
4301 do
4302         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
4303 done
4304 ])dnl
4305 dnl ---------------------------------------------------------------------------
4306 dnl CF_TERM_HEADER version: 6 updated: 2021/01/02 09:31:20
4307 dnl --------------
4308 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
4309 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
4310 dnl but some packagers change this, breaking various applications.
4311 AC_DEFUN([CF_TERM_HEADER],[
4312 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
4313 case "${cf_cv_ncurses_header}" in
4314 (*/ncurses.h|*/ncursesw.h)
4315         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
4316         ;;
4317 (*)
4318         cf_term_header=term.h
4319         ;;
4320 esac
4321
4322 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
4323 do
4324 AC_TRY_COMPILE([#include <stdio.h>
4325 #include <${cf_cv_ncurses_header:-curses.h}>
4326 #include <$cf_test>
4327 ],[int x = auto_left_margin; (void)x],[
4328         cf_cv_term_header="$cf_test"],[
4329         cf_cv_term_header=unknown
4330         ])
4331         test "$cf_cv_term_header" != unknown && break
4332 done
4333 ])
4334
4335 # Set definitions to allow ifdef'ing to accommodate subdirectories
4336
4337 case "$cf_cv_term_header" in
4338 (*term.h)
4339         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
4340         ;;
4341 esac
4342
4343 case "$cf_cv_term_header" in
4344 (ncurses/term.h)
4345         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
4346         ;;
4347 (ncursesw/term.h)
4348         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
4349         ;;
4350 esac
4351 ])dnl
4352 dnl ---------------------------------------------------------------------------
4353 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
4354 dnl ---------------
4355 dnl Define a top_builddir symbol, for applications that need an absolute path.
4356 AC_DEFUN([CF_TOP_BUILDDIR],
4357 [
4358 top_builddir=ifelse($1,,`pwd`,$1)
4359 AC_SUBST(top_builddir)
4360 ])dnl
4361 dnl ---------------------------------------------------------------------------
4362 dnl CF_TRY_XOPEN_SOURCE version: 2 updated: 2018/06/20 20:23:13
4363 dnl -------------------
4364 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
4365 dnl can define it successfully.
4366 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
4367 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
4368         AC_TRY_COMPILE([
4369 #include <stdlib.h>
4370 #include <string.h>
4371 #include <sys/types.h>
4372 ],[
4373 #ifndef _XOPEN_SOURCE
4374 make an error
4375 #endif],
4376         [cf_cv_xopen_source=no],
4377         [cf_save="$CPPFLAGS"
4378          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
4379          AC_TRY_COMPILE([
4380 #include <stdlib.h>
4381 #include <string.h>
4382 #include <sys/types.h>
4383 ],[
4384 #ifdef _XOPEN_SOURCE
4385 make an error
4386 #endif],
4387         [cf_cv_xopen_source=no],
4388         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
4389         CPPFLAGS="$cf_save"
4390         ])
4391 ])
4392
4393 if test "$cf_cv_xopen_source" != no ; then
4394         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
4395         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
4396         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
4397         CF_ADD_CFLAGS($cf_temp_xopen_source)
4398 fi
4399 ])
4400 dnl ---------------------------------------------------------------------------
4401 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
4402 dnl --------
4403 dnl Make an uppercase version of a variable
4404 dnl $1=uppercase($2)
4405 AC_DEFUN([CF_UPPER],
4406 [
4407 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4408 ])dnl
4409 dnl ---------------------------------------------------------------------------
4410 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
4411 dnl -----------
4412 dnl Check for multibyte support, and if not found, utf8 compatibility library
4413 AC_DEFUN([CF_UTF8_LIB],
4414 [
4415 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
4416         cf_save_LIBS="$LIBS"
4417         AC_TRY_LINK([
4418 #include <stdlib.h>],[putwc(0,0);],
4419         [cf_cv_utf8_lib=yes],
4420         [CF_FIND_LINKAGE([
4421 #include <libutf8.h>],[putwc(0,0);],utf8,
4422                 [cf_cv_utf8_lib=add-on],
4423                 [cf_cv_utf8_lib=no])
4424 ])])
4425
4426 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
4427 # ncurses/ncursesw:
4428 if test "$cf_cv_utf8_lib" = "add-on" ; then
4429         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
4430         CF_ADD_INCDIR($cf_cv_header_path_utf8)
4431         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
4432         CF_ADD_LIBS($cf_cv_library_file_utf8)
4433 fi
4434 ])dnl
4435 dnl ---------------------------------------------------------------------------
4436 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
4437 dnl ----------
4438 dnl Use AC_VERBOSE w/o the warnings
4439 AC_DEFUN([CF_VERBOSE],
4440 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
4441 CF_MSG_LOG([$1])
4442 ])dnl
4443 dnl ---------------------------------------------------------------------------
4444 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
4445 dnl ---------------
4446 dnl Check for compiler-support for weak symbols.
4447 dnl This works with "recent" gcc.
4448 AC_DEFUN([CF_WEAK_SYMBOLS],[
4449 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
4450
4451 AC_TRY_COMPILE([
4452 #include <stdio.h>],
4453 [
4454 #if defined(__GNUC__)
4455 #  if defined __USE_ISOC99
4456 #    define _cat_pragma(exp)    _Pragma(#exp)
4457 #    define _weak_pragma(exp)   _cat_pragma(weak name)
4458 #  else
4459 #    define _weak_pragma(exp)
4460 #  endif
4461 #  define _declare(name)        __extension__ extern __typeof__(name) name
4462 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
4463 #endif
4464
4465 weak_symbol(fopen);
4466 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
4467 ])
4468 ])dnl
4469 dnl ---------------------------------------------------------------------------
4470 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
4471 dnl --------------------
4472 dnl Command-line option to specify the Ada95 compiler.
4473 AC_DEFUN([CF_WITH_ADA_COMPILER],[
4474 AC_MSG_CHECKING(for ada-compiler)
4475 AC_ARG_WITH(ada-compiler,
4476         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
4477         [cf_ada_compiler=$withval],
4478         [cf_ada_compiler=gnatmake])
4479 AC_SUBST(cf_ada_compiler)
4480 AC_MSG_RESULT($cf_ada_compiler)
4481 ])dnl
4482 dnl ---------------------------------------------------------------------------
4483 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
4484 dnl -------------------
4485 dnl Command-line option to specify where Ada includes will install.
4486 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
4487 AC_MSG_CHECKING(for ada-include)
4488 CF_WITH_PATH(ada-include,
4489    [  --with-ada-include=DIR  Ada includes are in DIR],
4490    ADA_INCLUDE,
4491    PREFIX/share/ada/adainclude,
4492    [$]prefix/share/ada/adainclude)
4493 AC_SUBST(ADA_INCLUDE)
4494 AC_MSG_RESULT($ADA_INCLUDE)
4495 ])dnl
4496 dnl ---------------------------------------------------------------------------
4497 dnl CF_WITH_ADA_LIBNAME version: 1 updated: 2019/09/07 18:59:41
4498 dnl -------------------
4499 dnl CF_WITH_ADA_LIBNAME
4500 dnl -------------------
4501 dnl Command-line option to specify how to name the resulting Ada library.
4502 dnl $1 = default value
4503 AC_DEFUN([CF_WITH_ADA_LIBNAME],[
4504 AC_MSG_CHECKING(for ada-libname)
4505 AC_ARG_WITH(ada-libname,
4506    [  --with-ada-libname=XXX  override default Ada library-name],
4507    ADA_LIBNAME=[$]withval,
4508    ADA_LIBNAME=$1)
4509 case "x$ADA_LIBNAME" in
4510 (x|xyes|xno)
4511         ADA_LIBNAME=$1
4512         ;;
4513 esac
4514 AC_SUBST(ADA_LIBNAME)
4515 AC_MSG_RESULT($ADA_LIBNAME)
4516 ])dnl
4517 dnl ---------------------------------------------------------------------------
4518 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
4519 dnl -------------------
4520 dnl Command-line option to specify where Ada objects will install.
4521 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
4522 AC_MSG_CHECKING(for ada-objects)
4523 CF_WITH_PATH(ada-objects,
4524    [  --with-ada-objects=DIR  Ada objects are in DIR],
4525    ADA_OBJECTS,
4526    PREFIX/lib/ada/adalib,
4527    [$]prefix/lib/ada/adalib)
4528 AC_SUBST(ADA_OBJECTS)
4529 AC_MSG_RESULT($ADA_OBJECTS)
4530 ])dnl
4531 dnl ---------------------------------------------------------------------------
4532 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
4533 dnl ---------------------
4534 dnl Command-line option to specify if an Ada95 shared-library should be built,
4535 dnl and optionally what its soname should be.
4536 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
4537 AC_REQUIRE([CF_GNAT_PROJECTS])
4538 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
4539 AC_ARG_WITH(ada-sharedlib,
4540         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
4541         [with_ada_sharedlib=$withval],
4542         [with_ada_sharedlib=no])
4543 AC_MSG_RESULT($with_ada_sharedlib)
4544
4545 if test "x$with_ada_sharedlib" != xno
4546 then
4547         if test "x$cf_gnat_projects" != xyes
4548         then
4549                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
4550                 with_ada_sharedlib=no
4551         fi
4552 fi
4553
4554 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
4555 MAKE_ADA_SHAREDLIB="#"
4556
4557 if test "x$with_ada_sharedlib" != xno
4558 then
4559         MAKE_ADA_SHAREDLIB=
4560         if test "x$with_ada_sharedlib" != xyes
4561         then
4562                 ADA_SHAREDLIB="$with_ada_sharedlib"
4563         fi
4564 fi
4565
4566 AC_SUBST(ADA_SHAREDLIB)
4567 AC_SUBST(MAKE_ADA_SHAREDLIB)
4568 ])dnl
4569 dnl ---------------------------------------------------------------------------
4570 dnl CF_WITH_CURSES_DIR version: 4 updated: 2021/01/02 19:22:58
4571 dnl ------------------
4572 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
4573 dnl libraries.
4574 AC_DEFUN([CF_WITH_CURSES_DIR],[
4575
4576 AC_MSG_CHECKING(for specific curses-directory)
4577 AC_ARG_WITH(curses-dir,
4578         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
4579         [cf_cv_curses_dir=$withval],
4580         [cf_cv_curses_dir=no])
4581 AC_MSG_RESULT($cf_cv_curses_dir)
4582
4583 if test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no"
4584 then
4585         CF_PATH_SYNTAX(withval)
4586         if test -d "$cf_cv_curses_dir"
4587         then
4588                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
4589                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
4590         fi
4591 fi
4592 ])dnl
4593 dnl ---------------------------------------------------------------------------
4594 dnl CF_WITH_LIB_PREFIX version: 2 updated: 2021/01/01 16:53:59
4595 dnl ------------------
4596 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
4597 dnl "lib" prefix, e.g., because it used the dll naming convention.
4598 dnl
4599 dnl $1 = variable to set
4600 AC_DEFUN([CF_WITH_LIB_PREFIX],
4601 [
4602 AC_MSG_CHECKING(if you want to have a library-prefix)
4603 AC_ARG_WITH(lib-prefix,
4604         [  --with-lib-prefix       override library-prefix],
4605         [with_lib_prefix=$withval],
4606         [with_lib_prefix=auto])
4607 AC_MSG_RESULT($with_lib_prefix)
4608
4609 if test "$with_lib_prefix" = auto
4610 then
4611         CF_LIB_PREFIX($1)
4612 elif test "$with_lib_prefix" = no
4613 then
4614         LIB_PREFIX=
4615 else
4616         LIB_PREFIX=$with_lib_prefix
4617 fi
4618 ])dnl
4619 dnl ---------------------------------------------------------------------------
4620 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
4621 dnl ------------
4622 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
4623 dnl defaulting to yes/no.
4624 dnl
4625 dnl $1 = option name
4626 dnl $2 = help-text
4627 dnl $3 = environment variable to set
4628 dnl $4 = default value, shown in the help-message, must be a constant
4629 dnl $5 = default value, if it's an expression & cannot be in the help-message
4630 dnl
4631 AC_DEFUN([CF_WITH_PATH],
4632 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
4633 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
4634 if ifelse([$5],,true,[test -n "$5"]) ; then
4635 CF_PATH_SYNTAX(withval)
4636 fi
4637 eval $3="$withval"
4638 AC_SUBST($3)dnl
4639 ])dnl
4640 dnl ---------------------------------------------------------------------------
4641 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 11 updated: 2021/01/01 16:16:30
4642 dnl -------------------------
4643 dnl Allow the choice of the pkg-config library directory to be overridden.
4644 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
4645
4646 case "$PKG_CONFIG" in
4647 (no|none|yes)
4648         AC_MSG_CHECKING(for pkg-config library directory)
4649         ;;
4650 (*)
4651         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
4652         ;;
4653 esac
4654
4655 PKG_CONFIG_LIBDIR=no
4656 AC_ARG_WITH(pkg-config-libdir,
4657         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
4658         [PKG_CONFIG_LIBDIR=$withval],
4659         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
4660
4661 case x$PKG_CONFIG_LIBDIR in
4662 (x/*)
4663         ;;
4664 (xyes)
4665         # Look for the library directory using the same prefix as the executable
4666         if test "x$PKG_CONFIG" = xnone
4667         then
4668                 cf_path=$prefix
4669         else
4670                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
4671         fi
4672
4673         # If you don't like using the default architecture, you have to specify the
4674         # intended library directory and corresponding compiler/linker options.
4675         #
4676         # This case allows for Debian's 2014-flavor of multiarch, along with the
4677         # most common variations before that point.  Some other variants spell the
4678         # directory differently, e.g., "pkg-config", and put it in unusual places.
4679         # pkg-config has always been poorly standardized, which is ironic...
4680         case x`(arch) 2>/dev/null` in
4681         (*64)
4682                 cf_search_path="\
4683                         $cf_path/lib/*64-linux-gnu \
4684                         $cf_path/share \
4685                         $cf_path/lib64 \
4686                         $cf_path/lib32 \
4687                         $cf_path/lib"
4688                 ;;
4689         (*)
4690                 cf_search_path="\
4691                         $cf_path/lib/*-linux-gnu \
4692                         $cf_path/share \
4693                         $cf_path/lib32 \
4694                         $cf_path/lib \
4695                         $cf_path/libdata"
4696                 ;;
4697         esac
4698
4699         CF_VERBOSE(list...)
4700         for cf_config in $cf_search_path
4701         do
4702                 CF_VERBOSE(checking $cf_config/pkgconfig)
4703                 if test -d "$cf_config/pkgconfig"
4704                 then
4705                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
4706                         AC_MSG_CHECKING(done)
4707                         break
4708                 fi
4709         done
4710         ;;
4711 (*)
4712         ;;
4713 esac
4714
4715 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
4716         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
4717 fi
4718
4719 AC_SUBST(PKG_CONFIG_LIBDIR)
4720 ])dnl
4721 dnl ---------------------------------------------------------------------------
4722 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
4723 dnl ---------------
4724 dnl Check for POSIX thread library.
4725 AC_DEFUN([CF_WITH_PTHREAD],
4726 [
4727 AC_MSG_CHECKING(if you want to link with the pthread library)
4728 AC_ARG_WITH(pthread,
4729         [  --with-pthread          use POSIX thread library],
4730         [with_pthread=$withval],
4731         [with_pthread=no])
4732 AC_MSG_RESULT($with_pthread)
4733
4734 if test "$with_pthread" != no ; then
4735         AC_CHECK_HEADER(pthread.h,[
4736         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
4737
4738         for cf_lib_pthread in pthread c_r
4739         do
4740             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
4741             cf_save_LIBS="$LIBS"
4742             CF_ADD_LIB($cf_lib_pthread)
4743             AC_TRY_LINK([
4744 #include <pthread.h>
4745 ],[
4746                 int rc = pthread_create(0,0,0,0);
4747                 int r2 = pthread_mutexattr_settype(0, 0);
4748 ],[with_pthread=yes],[with_pthread=no])
4749             LIBS="$cf_save_LIBS"
4750             AC_MSG_RESULT($with_pthread)
4751             test "$with_pthread" = yes && break
4752         done
4753
4754         if test "$with_pthread" = yes ; then
4755             CF_ADD_LIB($cf_lib_pthread)
4756             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
4757         else
4758             AC_MSG_ERROR(Cannot link with pthread library)
4759         fi
4760         ])
4761 fi
4762 ])
4763 dnl ---------------------------------------------------------------------------
4764 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
4765 dnl ---------------
4766 dnl For testing, override the derived host system-type which is used to decide
4767 dnl things such as the linker commands used to build shared libraries.  This is
4768 dnl normally chosen automatically based on the type of system which you are
4769 dnl building on.  We use it for testing the configure script.
4770 dnl
4771 dnl This is different from the --host option: it is used only for testing parts
4772 dnl of the configure script which would not be reachable with --host since that
4773 dnl relies on the build environment being real, rather than mocked up.
4774 AC_DEFUN([CF_WITH_SYSTYPE],[
4775 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
4776 AC_ARG_WITH(system-type,
4777         [  --with-system-type=XXX  test: override derived host system-type],
4778 [AC_MSG_WARN(overriding system type to $withval)
4779         cf_cv_system_name=$withval
4780         host_os=$withval
4781 ])
4782 ])dnl
4783 dnl ---------------------------------------------------------------------------
4784 dnl CF_XOPEN_SOURCE version: 57 updated: 2021/01/01 16:53:59
4785 dnl ---------------
4786 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
4787 dnl or adapt to the vendor's definitions to get equivalent functionality,
4788 dnl without losing the common non-POSIX features.
4789 dnl
4790 dnl Parameters:
4791 dnl     $1 is the nominal value for _XOPEN_SOURCE
4792 dnl     $2 is the nominal value for _POSIX_C_SOURCE
4793 AC_DEFUN([CF_XOPEN_SOURCE],[
4794 AC_REQUIRE([AC_CANONICAL_HOST])
4795 AC_REQUIRE([CF_POSIX_VISIBLE])
4796
4797 if test "$cf_cv_posix_visible" = no; then
4798
4799 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
4800 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
4801 cf_xopen_source=
4802
4803 case "$host_os" in
4804 (aix[[4-7]]*)
4805         cf_xopen_source="-D_ALL_SOURCE"
4806         ;;
4807 (msys)
4808         cf_XOPEN_SOURCE=600
4809         ;;
4810 (darwin[[0-8]].*)
4811         cf_xopen_source="-D_APPLE_C_SOURCE"
4812         ;;
4813 (darwin*)
4814         cf_xopen_source="-D_DARWIN_C_SOURCE"
4815         cf_XOPEN_SOURCE=
4816         ;;
4817 (freebsd*|dragonfly*|midnightbsd*)
4818         # 5.x headers associate
4819         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
4820         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
4821         cf_POSIX_C_SOURCE=200112L
4822         cf_XOPEN_SOURCE=600
4823         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
4824         ;;
4825 (hpux11*)
4826         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
4827         ;;
4828 (hpux*)
4829         cf_xopen_source="-D_HPUX_SOURCE"
4830         ;;
4831 (irix[[56]].*)
4832         cf_xopen_source="-D_SGI_SOURCE"
4833         cf_XOPEN_SOURCE=
4834         ;;
4835 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
4836         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
4837         ;;
4838 (minix*)
4839         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
4840         ;;
4841 (mirbsd*)
4842         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
4843         cf_XOPEN_SOURCE=
4844         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4845         ;;
4846 (netbsd*)
4847         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
4848         ;;
4849 (openbsd[[4-9]]*)
4850         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
4851         cf_xopen_source="-D_BSD_SOURCE"
4852         cf_XOPEN_SOURCE=600
4853         ;;
4854 (openbsd*)
4855         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
4856         ;;
4857 (osf[[45]]*)
4858         cf_xopen_source="-D_OSF_SOURCE"
4859         ;;
4860 (nto-qnx*)
4861         cf_xopen_source="-D_QNX_SOURCE"
4862         ;;
4863 (sco*)
4864         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
4865         ;;
4866 (solaris2.*)
4867         cf_xopen_source="-D__EXTENSIONS__"
4868         cf_cv_xopen_source=broken
4869         ;;
4870 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
4871         cf_XOPEN_SOURCE=
4872         cf_POSIX_C_SOURCE=
4873         ;;
4874 (*)
4875         CF_TRY_XOPEN_SOURCE
4876         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4877         ;;
4878 esac
4879
4880 if test -n "$cf_xopen_source" ; then
4881         CF_ADD_CFLAGS($cf_xopen_source,true)
4882 fi
4883
4884 dnl In anything but the default case, we may have system-specific setting
4885 dnl which is still not guaranteed to provide all of the entrypoints that
4886 dnl _XOPEN_SOURCE would yield.
4887 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
4888         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
4889         AC_TRY_COMPILE([#include <stdlib.h>],[
4890 #ifndef _XOPEN_SOURCE
4891 make an error
4892 #endif],
4893         [cf_XOPEN_SOURCE_set=yes],
4894         [cf_XOPEN_SOURCE_set=no])
4895         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
4896         if test "$cf_XOPEN_SOURCE_set" = yes
4897         then
4898                 AC_TRY_COMPILE([#include <stdlib.h>],[
4899 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
4900 make an error
4901 #endif],
4902                 [cf_XOPEN_SOURCE_set_ok=yes],
4903                 [cf_XOPEN_SOURCE_set_ok=no])
4904                 if test "$cf_XOPEN_SOURCE_set_ok" = no
4905                 then
4906                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
4907                 fi
4908         else
4909                 CF_TRY_XOPEN_SOURCE
4910         fi
4911 fi
4912 fi # cf_cv_posix_visible
4913 ])
4914 dnl ---------------------------------------------------------------------------
4915 dnl CF__SED_TRIMBLANKS version: 1 updated: 2021/01/02 09:31:20
4916 dnl ------------------
4917 dnl Trim something using sed, then trim extra whitespace
4918 dnl $1 = extra parameters, e.g., in CF_STRIP_G_OPT
4919 define([CF__SED_TRIMBLANKS],[sed ifelse($1,,,[$1] )-e 's%[[     ]]% %g' -e 's% [[ ]]*% %g' -e 's%^ %%' -e 's% [$]%%'])dnl