ncurses 6.0 - patch 20160903
[ncurses.git] / Ada95 / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright (c) 2010-2015,2016 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey
30 dnl
31 dnl $Id: aclocal.m4,v 1.116 2016/09/04 00:11:44 tom Exp $
32 dnl Macros used in NCURSES Ada95 auto-configuration script.
33 dnl
34 dnl These macros are maintained separately from NCURSES.  The copyright on
35 dnl this file applies to the aggregation of macros and does not affect use of
36 dnl these macros in other applications.
37 dnl
38 dnl See http://invisible-island.net/autoconf/ for additional information.
39 dnl
40 dnl ---------------------------------------------------------------------------
41 dnl ---------------------------------------------------------------------------
42 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
43 dnl ------------------
44 dnl Conditionally generate script according to whether we're using a given autoconf.
45 dnl
46 dnl $1 = version to compare against
47 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
48 dnl $3 = code to use if AC_ACVERSION is older than $1.
49 define([CF_ACVERSION_CHECK],
50 [
51 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
52 ifdef([m4_version_compare],
53 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
54 [CF_ACVERSION_COMPARE(
55 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
56 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
57 dnl ---------------------------------------------------------------------------
58 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
59 dnl --------------------
60 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
61 dnl                      MAJOR2, MINOR2, TERNARY2,
62 dnl                      PRINTABLE2, not FOUND, FOUND)
63 define([CF_ACVERSION_COMPARE],
64 [ifelse(builtin([eval], [$2 < $5]), 1,
65 [ifelse([$8], , ,[$8])],
66 [ifelse([$9], , ,[$9])])])dnl
67 dnl ---------------------------------------------------------------------------
68 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
69 dnl -------------------
70 dnl Construct the list of include-options for the C programs in the Ada95
71 dnl binding.
72 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
73 [
74 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
75 if test "$srcdir" != "."; then
76         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
77 fi
78 if test "$GCC" != yes; then
79         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
80 elif test "$includedir" != "/usr/include"; then
81         if test "$includedir" = '${prefix}/include' ; then
82                 if test x$prefix != x/usr ; then
83                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
84                 fi
85         else
86                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
87         fi
88 fi
89 AC_SUBST(ACPPFLAGS)
90 ])dnl
91 dnl ---------------------------------------------------------------------------
92 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
93 dnl ---------------
94 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
95 AC_DEFUN([CF_ADD_ADAFLAGS],[
96         ADAFLAGS="$ADAFLAGS $1"
97         AC_SUBST(ADAFLAGS)
98 ])dnl
99 dnl ---------------------------------------------------------------------------
100 dnl CF_ADD_CFLAGS version: 12 updated: 2015/04/12 15:39:00
101 dnl -------------
102 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
103 dnl The second parameter if given makes this macro verbose.
104 dnl
105 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
106 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
107 dnl confused by the quotes (which require backslashes to keep them usable).
108 AC_DEFUN([CF_ADD_CFLAGS],
109 [
110 cf_fix_cppflags=no
111 cf_new_cflags=
112 cf_new_cppflags=
113 cf_new_extra_cppflags=
114
115 for cf_add_cflags in $1
116 do
117 case $cf_fix_cppflags in
118 (no)
119         case $cf_add_cflags in
120         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
121                 case $cf_add_cflags in
122                 (-D*)
123                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
124
125                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
126                                 && test -z "${cf_tst_cflags}" \
127                                 && cf_fix_cppflags=yes
128
129                         if test $cf_fix_cppflags = yes ; then
130                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
131                                 continue
132                         elif test "${cf_tst_cflags}" = "\"'" ; then
133                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
134                                 continue
135                         fi
136                         ;;
137                 esac
138                 case "$CPPFLAGS" in
139                 (*$cf_add_cflags)
140                         ;;
141                 (*)
142                         case $cf_add_cflags in
143                         (-D*)
144                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
145                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
146                                 ;;
147                         esac
148                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
149                         ;;
150                 esac
151                 ;;
152         (*)
153                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
154                 ;;
155         esac
156         ;;
157 (yes)
158         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
159
160         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
161
162         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
163                 && test -z "${cf_tst_cflags}" \
164                 && cf_fix_cppflags=no
165         ;;
166 esac
167 done
168
169 if test -n "$cf_new_cflags" ; then
170         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
171         CFLAGS="$CFLAGS $cf_new_cflags"
172 fi
173
174 if test -n "$cf_new_cppflags" ; then
175         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
176         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
177 fi
178
179 if test -n "$cf_new_extra_cppflags" ; then
180         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
181         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
182 fi
183
184 AC_SUBST(EXTRA_CPPFLAGS)
185
186 ])dnl
187 dnl ---------------------------------------------------------------------------
188 dnl CF_ADD_INCDIR version: 14 updated: 2015/05/25 20:53:04
189 dnl -------------
190 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
191 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
192 dnl but old versions (and some misinstalled ones) need that.  To make things
193 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
194 dnl the include-path).
195 AC_DEFUN([CF_ADD_INCDIR],
196 [
197 if test -n "$1" ; then
198   for cf_add_incdir in $1
199   do
200         while test $cf_add_incdir != /usr/include
201         do
202           if test -d $cf_add_incdir
203           then
204                 cf_have_incdir=no
205                 if test -n "$CFLAGS$CPPFLAGS" ; then
206                   # a loop is needed to ensure we can add subdirs of existing dirs
207                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
208                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
209                           cf_have_incdir=yes; break
210                         fi
211                   done
212                 fi
213
214                 if test "$cf_have_incdir" = no ; then
215                   if test "$cf_add_incdir" = /usr/local/include ; then
216                         if test "$GCC" = yes
217                         then
218                           cf_save_CPPFLAGS=$CPPFLAGS
219                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
220                           AC_TRY_COMPILE([#include <stdio.h>],
221                                   [printf("Hello")],
222                                   [],
223                                   [cf_have_incdir=yes])
224                           CPPFLAGS=$cf_save_CPPFLAGS
225                         fi
226                   fi
227                 fi
228
229                 if test "$cf_have_incdir" = no ; then
230                   CF_VERBOSE(adding $cf_add_incdir to include-path)
231                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
232
233                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
234                   test "$cf_top_incdir" = "$cf_add_incdir" && break
235                   cf_add_incdir="$cf_top_incdir"
236                 else
237                   break
238                 fi
239           else
240                 break
241           fi
242         done
243   done
244 fi
245 ])dnl
246 dnl ---------------------------------------------------------------------------
247 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
248 dnl ----------
249 dnl Add a library, used to enforce consistency.
250 dnl
251 dnl $1 = library to add, without the "-l"
252 dnl $2 = variable to update (default $LIBS)
253 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
254 dnl ---------------------------------------------------------------------------
255 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
256 dnl -------------
257 dnl     Adds to the library-path
258 dnl
259 dnl     Some machines have trouble with multiple -L options.
260 dnl
261 dnl $1 is the (list of) directory(s) to add
262 dnl $2 is the optional name of the variable to update (default LDFLAGS)
263 dnl
264 AC_DEFUN([CF_ADD_LIBDIR],
265 [
266 if test -n "$1" ; then
267         for cf_add_libdir in $1
268         do
269                 if test $cf_add_libdir = /usr/lib ; then
270                         :
271                 elif test -d $cf_add_libdir
272                 then
273                         cf_have_libdir=no
274                         if test -n "$LDFLAGS$LIBS" ; then
275                                 # a loop is needed to ensure we can add subdirs of existing dirs
276                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
277                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
278                                                 cf_have_libdir=yes; break
279                                         fi
280                                 done
281                         fi
282                         if test "$cf_have_libdir" = no ; then
283                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
284                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
285                         fi
286                 fi
287         done
288 fi
289 ])dnl
290 dnl ---------------------------------------------------------------------------
291 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
292 dnl -----------
293 dnl Add one or more libraries, used to enforce consistency.  Libraries are
294 dnl prepended to an existing list, since their dependencies are assumed to
295 dnl already exist in the list.
296 dnl
297 dnl $1 = libraries to add, with the "-l", etc.
298 dnl $2 = variable to update (default $LIBS)
299 AC_DEFUN([CF_ADD_LIBS],[
300 cf_add_libs="$1"
301 # Filter out duplicates - this happens with badly-designed ".pc" files...
302 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
303 do
304         for cf_add_2lib in $cf_add_libs
305         do
306                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
307                 then
308                         cf_add_1lib=
309                         break
310                 fi
311         done
312         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
313 done
314 ifelse($2,,LIBS,[$2])="$cf_add_libs"
315 ])dnl
316 dnl ---------------------------------------------------------------------------
317 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
318 dnl ------------------
319 dnl Append to a search-list for a nonstandard header/lib-file
320 dnl     $1 = the variable to return as result
321 dnl     $2 = the package name
322 dnl     $3 = the subdirectory, e.g., bin, include or lib
323 dnl $4 = the directory under which we will test for subdirectories
324 dnl $5 = a directory that we do not want $4 to match
325 AC_DEFUN([CF_ADD_SUBDIR_PATH],
326 [
327 test "x$4" != "x$5" && \
328 test -d "$4" && \
329 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
330         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
331         test -d $4/$3 &&          $1="[$]$1 $4/$3"
332         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
333         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
334         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
335         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
336 }
337 ])dnl
338 dnl ---------------------------------------------------------------------------
339 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
340 dnl --------------
341 dnl Allow user to disable a normally-on option.
342 AC_DEFUN([CF_ARG_DISABLE],
343 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
344 dnl ---------------------------------------------------------------------------
345 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
346 dnl -------------
347 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
348 dnl values.
349 dnl
350 dnl Parameters:
351 dnl $1 = option name
352 dnl $2 = help-string
353 dnl $3 = action to perform if option is not default
354 dnl $4 = action if perform if option is default
355 dnl $5 = default option value (either 'yes' or 'no')
356 AC_DEFUN([CF_ARG_OPTION],
357 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
358         if test "$enableval" != "$5" ; then
359 ifelse([$3],,[    :]dnl
360 ,[    $3]) ifelse([$4],,,[
361         else
362                 $4])
363         fi],[enableval=$5 ifelse([$4],,,[
364         $4
365 ])dnl
366 ])])dnl
367 dnl ---------------------------------------------------------------------------
368 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
369 dnl -----------
370 dnl Check for suitable "ar" (archiver) options for updating an archive.
371 dnl
372 dnl In particular, handle some obsolete cases where the "-" might be omitted,
373 dnl as well as a workaround for breakage of make's archive rules by the GNU
374 dnl binutils "ar" program.
375 AC_DEFUN([CF_AR_FLAGS],[
376 AC_REQUIRE([CF_PROG_AR])
377
378 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
379         cf_cv_ar_flags=unknown
380         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
381         do
382
383                 # check if $ARFLAGS already contains this choice
384                 if test "x$ARFLAGS" != "x" ; then
385                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
386                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
387                                 cf_cv_ar_flags=
388                                 break
389                         fi
390                 fi
391
392                 rm -f conftest.$ac_cv_objext
393                 rm -f conftest.a
394
395                 cat >conftest.$ac_ext <<EOF
396 #line __oline__ "configure"
397 int     testdata[[3]] = { 123, 456, 789 };
398 EOF
399                 if AC_TRY_EVAL(ac_compile) ; then
400                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
401                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
402                         if test -f conftest.a ; then
403                                 cf_cv_ar_flags=$cf_ar_flags
404                                 break
405                         fi
406                 else
407                         CF_VERBOSE(cannot compile test-program)
408                         break
409                 fi
410         done
411         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
412 ])
413
414 if test -n "$ARFLAGS" ; then
415         if test -n "$cf_cv_ar_flags" ; then
416                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
417         fi
418 else
419         ARFLAGS=$cf_cv_ar_flags
420 fi
421
422 AC_SUBST(ARFLAGS)
423 ])
424 dnl ---------------------------------------------------------------------------
425 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
426 dnl -----------
427 dnl If we're cross-compiling, allow the user to override the tools and their
428 dnl options.  The configure script is oriented toward identifying the host
429 dnl compiler, etc., but we need a build compiler to generate parts of the
430 dnl source.
431 dnl
432 dnl $1 = default for $CPPFLAGS
433 dnl $2 = default for $LIBS
434 AC_DEFUN([CF_BUILD_CC],[
435 CF_ACVERSION_CHECK(2.52,,
436         [AC_REQUIRE([CF_PROG_EXT])])
437 if test "$cross_compiling" = yes ; then
438
439         # defaults that we might want to override
440         : ${BUILD_CFLAGS:=''}
441         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
442         : ${BUILD_LDFLAGS:=''}
443         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
444         : ${BUILD_EXEEXT:='$x'}
445         : ${BUILD_OBJEXT:='o'}
446
447         AC_ARG_WITH(build-cc,
448                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
449                 [BUILD_CC="$withval"],
450                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
451         AC_MSG_CHECKING(for native build C compiler)
452         AC_MSG_RESULT($BUILD_CC)
453
454         AC_MSG_CHECKING(for native build C preprocessor)
455         AC_ARG_WITH(build-cpp,
456                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
457                 [BUILD_CPP="$withval"],
458                 [BUILD_CPP='${BUILD_CC} -E'])
459         AC_MSG_RESULT($BUILD_CPP)
460
461         AC_MSG_CHECKING(for native build C flags)
462         AC_ARG_WITH(build-cflags,
463                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
464                 [BUILD_CFLAGS="$withval"])
465         AC_MSG_RESULT($BUILD_CFLAGS)
466
467         AC_MSG_CHECKING(for native build C preprocessor-flags)
468         AC_ARG_WITH(build-cppflags,
469                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
470                 [BUILD_CPPFLAGS="$withval"])
471         AC_MSG_RESULT($BUILD_CPPFLAGS)
472
473         AC_MSG_CHECKING(for native build linker-flags)
474         AC_ARG_WITH(build-ldflags,
475                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
476                 [BUILD_LDFLAGS="$withval"])
477         AC_MSG_RESULT($BUILD_LDFLAGS)
478
479         AC_MSG_CHECKING(for native build linker-libraries)
480         AC_ARG_WITH(build-libs,
481                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
482                 [BUILD_LIBS="$withval"])
483         AC_MSG_RESULT($BUILD_LIBS)
484
485         # this assumes we're on Unix.
486         BUILD_EXEEXT=
487         BUILD_OBJEXT=o
488
489         : ${BUILD_CC:='${CC}'}
490
491         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
492                 AC_MSG_ERROR([Cross-build requires two compilers.
493 Use --with-build-cc to specify the native compiler.])
494         fi
495
496 else
497         : ${BUILD_CC:='${CC}'}
498         : ${BUILD_CPP:='${CPP}'}
499         : ${BUILD_CFLAGS:='${CFLAGS}'}
500         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
501         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
502         : ${BUILD_LIBS:='${LIBS}'}
503         : ${BUILD_EXEEXT:='$x'}
504         : ${BUILD_OBJEXT:='o'}
505 fi
506
507 AC_SUBST(BUILD_CC)
508 AC_SUBST(BUILD_CPP)
509 AC_SUBST(BUILD_CFLAGS)
510 AC_SUBST(BUILD_CPPFLAGS)
511 AC_SUBST(BUILD_LDFLAGS)
512 AC_SUBST(BUILD_LIBS)
513 AC_SUBST(BUILD_EXEEXT)
514 AC_SUBST(BUILD_OBJEXT)
515 ])dnl
516 dnl ---------------------------------------------------------------------------
517 dnl CF_CC_ENV_FLAGS version: 6 updated: 2016/08/29 20:57:00
518 dnl ---------------
519 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
520 dnl into CC.  This will not help with broken scripts that wrap the compiler
521 dnl with options, but eliminates a more common category of user confusion.
522 dnl
523 dnl In particular, it addresses the problem of being able to run the C
524 dnl preprocessor in a consistent manner.
525 dnl
526 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
527 dnl the nuisance of having inconsistent settings for compiler and preprocessor
528 dnl outweighs that limitation.
529 AC_DEFUN([CF_CC_ENV_FLAGS],
530 [
531 # This should have been defined by AC_PROG_CC
532 : ${CC:=cc}
533
534 AC_MSG_CHECKING(\$CC variable)
535 case "$CC" in
536 (*[[\ \ ]]-*)
537         AC_MSG_RESULT(broken)
538         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
539         # humor him...
540         cf_flags=`echo "$CC" | sed -e 's/^.*[[  ]]\(-[[^        ]]\)/\1/'`
541         CC=`echo "$CC " | sed -e 's/[[  ]]-[[^  ]].*$//' -e 's/[[       ]]*$//'`
542         for cf_arg in $cf_flags
543         do
544                 case "x$cf_arg" in
545                 (x-[[IUDfgOW]]*)
546                         CF_ADD_CFLAGS($cf_flags)
547                         ;;
548                 (*)
549                         CC="$CC $cf_arg"
550                         ;;
551                 esac
552         done
553         CF_VERBOSE(resulting CC: '$CC')
554         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
555         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
556         ;;
557 (*)
558         AC_MSG_RESULT(ok)
559         ;;
560 esac
561 ])dnl
562 dnl ---------------------------------------------------------------------------
563 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
564 dnl ---------------
565 dnl Determine the default configuration into which we'll install ncurses.  This
566 dnl can be overridden by the user's command-line options.  There's two items to
567 dnl look for:
568 dnl     1. the prefix (e.g., /usr)
569 dnl     2. the header files (e.g., /usr/include/ncurses)
570 dnl We'll look for a previous installation of ncurses and use the same defaults.
571 dnl
572 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
573 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
574 dnl programs from a vendor's.
575 AC_DEFUN([CF_CFG_DEFAULTS],
576 [
577 AC_MSG_CHECKING(for prefix)
578 if test "x$prefix" = "xNONE" ; then
579         case "$cf_cv_system_name" in
580                 # non-vendor systems don't have a conflict
581         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
582                 prefix=/usr
583                 ;;
584         (*)     prefix=$ac_default_prefix
585                 ;;
586         esac
587 fi
588 AC_MSG_RESULT($prefix)
589
590 if test "x$prefix" = "xNONE" ; then
591 AC_MSG_CHECKING(for default include-directory)
592 test -n "$verbose" && echo 1>&AC_FD_MSG
593 for cf_symbol in \
594         $includedir \
595         $includedir/ncurses \
596         $prefix/include \
597         $prefix/include/ncurses \
598         /usr/local/include \
599         /usr/local/include/ncurses \
600         /usr/include \
601         /usr/include/ncurses
602 do
603         cf_dir=`eval echo $cf_symbol`
604         if test -f $cf_dir/curses.h ; then
605         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
606                 includedir="$cf_symbol"
607                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
608                 break
609         fi
610         fi
611         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
612 done
613 AC_MSG_RESULT($includedir)
614 fi
615 ])dnl
616 dnl ---------------------------------------------------------------------------
617 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
618 dnl --------------
619 dnl Check if we're accidentally using a cache from a different machine.
620 dnl Derive the system name, as a check for reusing the autoconf cache.
621 dnl
622 dnl If we've packaged config.guess and config.sub, run that (since it does a
623 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
624 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
625 dnl which is useful in cross-compiles.
626 dnl
627 dnl Note: we would use $ac_config_sub, but that is one of the places where
628 dnl autoconf 2.5x broke compatibility with autoconf 2.13
629 AC_DEFUN([CF_CHECK_CACHE],
630 [
631 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
632         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
633         system_name="$host_os"
634 else
635         system_name="`(uname -s -r) 2>/dev/null`"
636         if test -z "$system_name" ; then
637                 system_name="`(hostname) 2>/dev/null`"
638         fi
639 fi
640 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
641 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
642
643 test -z "$system_name" && system_name="$cf_cv_system_name"
644 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
645
646 if test ".$system_name" != ".$cf_cv_system_name" ; then
647         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
648         AC_MSG_ERROR("Please remove config.cache and try again.")
649 fi
650 ])dnl
651 dnl ---------------------------------------------------------------------------
652 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
653 dnl -----------------
654 dnl Check if the given compiler is really clang.  clang's C driver defines
655 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
656 dnl not ignore some gcc options.
657 dnl
658 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
659 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
660 dnl the wrappers for gcc and g++ warnings.
661 dnl
662 dnl $1 = GCC (default) or GXX
663 dnl $2 = CLANG_COMPILER (default)
664 dnl $3 = CFLAGS (default) or CXXFLAGS
665 AC_DEFUN([CF_CLANG_COMPILER],[
666 ifelse([$2],,CLANG_COMPILER,[$2])=no
667
668 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
669         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
670         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
671         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
672         AC_TRY_COMPILE([],[
673 #ifdef __clang__
674 #else
675 make an error
676 #endif
677 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
678 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
679 ],[])
680         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
681         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
682 fi
683 ])
684 dnl ---------------------------------------------------------------------------
685 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
686 dnl ----------------
687 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
688 dnl variations of ncurses' installs.
689 dnl
690 dnl $1 = ncurses when looking for ncurses, or is empty
691 AC_DEFUN([CF_CURSES_HEADER],[
692 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
693 cf_cv_ncurses_header=none
694 for cf_header in \
695         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
696         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
697 do
698 AC_TRY_COMPILE([#include <${cf_header}>],
699         [initscr(); tgoto("?", 0,0)],
700         [cf_cv_ncurses_header=$cf_header; break],[])
701 done
702 ])
703
704 if test "$cf_cv_ncurses_header" = none ; then
705         AC_MSG_ERROR(No curses header-files found)
706 fi
707
708 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
709 AC_CHECK_HEADERS($cf_cv_ncurses_header)
710 ])dnl
711 dnl ---------------------------------------------------------------------------
712 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
713 dnl ----------
714 dnl "dirname" is not portable, so we fake it with a shell script.
715 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
716 dnl ---------------------------------------------------------------------------
717 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
718 dnl ---------------
719 dnl You can always use "make -n" to see the actual options, but it's hard to
720 dnl pick out/analyze warning messages when the compile-line is long.
721 dnl
722 dnl Sets:
723 dnl     ECHO_LT - symbol to control if libtool is verbose
724 dnl     ECHO_LD - symbol to prefix "cc -o" lines
725 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
726 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
727 dnl     ECHO_CC - symbol to put before any "cc" line
728 dnl
729 AC_DEFUN([CF_DISABLE_ECHO],[
730 AC_MSG_CHECKING(if you want to see long compiling messages)
731 CF_ARG_DISABLE(echo,
732         [  --disable-echo          do not display "compiling" commands],
733         [
734         ECHO_LT='--silent'
735         ECHO_LD='@echo linking [$]@;'
736         RULE_CC='@echo compiling [$]<'
737         SHOW_CC='@echo compiling [$]@'
738         ECHO_CC='@'
739 ],[
740         ECHO_LT=''
741         ECHO_LD=''
742         RULE_CC=''
743         SHOW_CC=''
744         ECHO_CC=''
745 ])
746 AC_MSG_RESULT($enableval)
747 AC_SUBST(ECHO_LT)
748 AC_SUBST(ECHO_LD)
749 AC_SUBST(RULE_CC)
750 AC_SUBST(SHOW_CC)
751 AC_SUBST(ECHO_CC)
752 ])dnl
753 dnl ---------------------------------------------------------------------------
754 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
755 dnl ------------------------
756 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
757 AC_MSG_CHECKING(if we want to use GNAT projects)
758 CF_ARG_DISABLE(gnat-projects,
759         [  --disable-gnat-projects test: disable GNAT projects even if usable],
760         [enable_gnat_projects=no],
761         [enable_gnat_projects=yes])
762 AC_MSG_RESULT($enable_gnat_projects)
763 ])dnl
764 dnl ---------------------------------------------------------------------------
765 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
766 dnl ---------------
767 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
768 dnl prefer a standard location, and use -L options only if we do not find the
769 dnl library in the standard library location(s).
770 dnl     $1 = library name
771 dnl     $2 = library class, usually the same as library name
772 dnl     $3 = includes
773 dnl     $4 = code fragment to compile/link
774 dnl     $5 = corresponding function-name
775 dnl     $6 = flag, nonnull if failure should not cause an error-exit
776 dnl
777 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
778 dnl to use a -L option.
779 AC_DEFUN([CF_FIND_LIBRARY],
780 [
781         eval 'cf_cv_have_lib_'$1'=no'
782         cf_libdir=""
783         AC_CHECK_FUNC($5,
784                 eval 'cf_cv_have_lib_'$1'=yes',[
785                 cf_save_LIBS="$LIBS"
786                 AC_MSG_CHECKING(for $5 in -l$1)
787                 LIBS="-l$1 $LIBS"
788                 AC_TRY_LINK([$3],[$4],
789                         [AC_MSG_RESULT(yes)
790                          eval 'cf_cv_have_lib_'$1'=yes'
791                         ],
792                         [AC_MSG_RESULT(no)
793                         CF_LIBRARY_PATH(cf_search,$2)
794                         for cf_libdir in $cf_search
795                         do
796                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
797                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
798                                 AC_TRY_LINK([$3],[$4],
799                                         [AC_MSG_RESULT(yes)
800                                          eval 'cf_cv_have_lib_'$1'=yes'
801                                          break],
802                                         [AC_MSG_RESULT(no)
803                                          LIBS="$cf_save_LIBS"])
804                         done
805                         ])
806                 ])
807 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
808 ifelse($6,,[
809 if test $cf_found_library = no ; then
810         AC_MSG_ERROR(Cannot link $1 library)
811 fi
812 ])
813 ])dnl
814 dnl ---------------------------------------------------------------------------
815 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
816 dnl ---------------
817 dnl Find a library (specifically the linkage used in the code fragment),
818 dnl searching for it if it is not already in the library path.
819 dnl See also CF_ADD_SEARCHPATH.
820 dnl
821 dnl Parameters (4-on are optional):
822 dnl     $1 = headers for library entrypoint
823 dnl     $2 = code fragment for library entrypoint
824 dnl     $3 = the library name without the "-l" option or ".so" suffix.
825 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
826 dnl     $5 = action to perform if not successful
827 dnl     $6 = module name, if not the same as the library name
828 dnl     $7 = extra libraries
829 dnl
830 dnl Sets these variables:
831 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
832 dnl     $cf_cv_header_path_$3 - include-directory if needed
833 dnl     $cf_cv_library_path_$3 - library-directory if needed
834 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
835 AC_DEFUN([CF_FIND_LINKAGE],[
836
837 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
838 # will be set on completion of the AC_TRY_LINK below.
839 cf_cv_header_path_$3=
840 cf_cv_library_path_$3=
841
842 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
843
844 cf_save_LIBS="$LIBS"
845
846 AC_TRY_LINK([$1],[$2],[
847         cf_cv_find_linkage_$3=yes
848         cf_cv_header_path_$3=/usr/include
849         cf_cv_library_path_$3=/usr/lib
850 ],[
851
852 LIBS="-l$3 $7 $cf_save_LIBS"
853
854 AC_TRY_LINK([$1],[$2],[
855         cf_cv_find_linkage_$3=yes
856         cf_cv_header_path_$3=/usr/include
857         cf_cv_library_path_$3=/usr/lib
858         cf_cv_library_file_$3="-l$3"
859 ],[
860         cf_cv_find_linkage_$3=no
861         LIBS="$cf_save_LIBS"
862
863         CF_VERBOSE(find linkage for $3 library)
864         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
865
866         cf_save_CPPFLAGS="$CPPFLAGS"
867         cf_test_CPPFLAGS="$CPPFLAGS"
868
869         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
870         for cf_cv_header_path_$3 in $cf_search
871         do
872                 if test -d $cf_cv_header_path_$3 ; then
873                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
874                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
875                         AC_TRY_COMPILE([$1],[$2],[
876                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
877                                 cf_cv_find_linkage_$3=maybe
878                                 cf_test_CPPFLAGS="$CPPFLAGS"
879                                 break],[
880                                 CPPFLAGS="$cf_save_CPPFLAGS"
881                                 ])
882                 fi
883         done
884
885         if test "$cf_cv_find_linkage_$3" = maybe ; then
886
887                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
888
889                 cf_save_LIBS="$LIBS"
890                 cf_save_LDFLAGS="$LDFLAGS"
891
892                 ifelse([$6],,,[
893                 CPPFLAGS="$cf_test_CPPFLAGS"
894                 LIBS="-l$3 $7 $cf_save_LIBS"
895                 AC_TRY_LINK([$1],[$2],[
896                         CF_VERBOSE(... found $3 library in system)
897                         cf_cv_find_linkage_$3=yes])
898                         CPPFLAGS="$cf_save_CPPFLAGS"
899                         LIBS="$cf_save_LIBS"
900                         ])
901
902                 if test "$cf_cv_find_linkage_$3" != yes ; then
903                         CF_LIBRARY_PATH(cf_search,$3)
904                         for cf_cv_library_path_$3 in $cf_search
905                         do
906                                 if test -d $cf_cv_library_path_$3 ; then
907                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
908                                         CPPFLAGS="$cf_test_CPPFLAGS"
909                                         LIBS="-l$3 $7 $cf_save_LIBS"
910                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
911                                         AC_TRY_LINK([$1],[$2],[
912                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
913                                         cf_cv_find_linkage_$3=yes
914                                         cf_cv_library_file_$3="-l$3"
915                                         break],[
916                                         CPPFLAGS="$cf_save_CPPFLAGS"
917                                         LIBS="$cf_save_LIBS"
918                                         LDFLAGS="$cf_save_LDFLAGS"
919                                         ])
920                                 fi
921                         done
922                         CPPFLAGS="$cf_save_CPPFLAGS"
923                         LDFLAGS="$cf_save_LDFLAGS"
924                 fi
925
926         else
927                 cf_cv_find_linkage_$3=no
928         fi
929         ],$7)
930 ])
931
932 LIBS="$cf_save_LIBS"
933
934 if test "$cf_cv_find_linkage_$3" = yes ; then
935 ifelse([$4],,[
936         CF_ADD_INCDIR($cf_cv_header_path_$3)
937         CF_ADD_LIBDIR($cf_cv_library_path_$3)
938         CF_ADD_LIB($3)
939 ],[$4])
940 else
941 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
942 fi
943 ])dnl
944 dnl ---------------------------------------------------------------------------
945 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
946 dnl -----------------
947 dnl make ADAFLAGS consistent with CFLAGS
948 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
949         AC_MSG_CHECKING(optimization options for ADAFLAGS)
950         case "$CFLAGS" in
951         (*-g*)
952                 CF_ADD_ADAFLAGS(-g)
953                 ;;
954         esac
955         case "$CFLAGS" in
956         (*-O*)
957                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
958                 CF_ADD_ADAFLAGS($cf_O_flag)
959                 ;;
960         esac
961         AC_MSG_RESULT($ADAFLAGS)
962 ])dnl
963 dnl ---------------------------------------------------------------------------
964 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
965 dnl -----------------
966 dnl Test for availability of useful gcc __attribute__ directives to quiet
967 dnl compiler warnings.  Though useful, not all are supported -- and contrary
968 dnl to documentation, unrecognized directives cause older compilers to barf.
969 AC_DEFUN([CF_GCC_ATTRIBUTES],
970 [
971 if test "$GCC" = yes
972 then
973 cat > conftest.i <<EOF
974 #ifndef GCC_PRINTF
975 #define GCC_PRINTF 0
976 #endif
977 #ifndef GCC_SCANF
978 #define GCC_SCANF 0
979 #endif
980 #ifndef GCC_NORETURN
981 #define GCC_NORETURN /* nothing */
982 #endif
983 #ifndef GCC_UNUSED
984 #define GCC_UNUSED /* nothing */
985 #endif
986 EOF
987 if test "$GCC" = yes
988 then
989         AC_CHECKING([for $CC __attribute__ directives])
990 cat > conftest.$ac_ext <<EOF
991 #line __oline__ "${as_me:-configure}"
992 #include "confdefs.h"
993 #include "conftest.h"
994 #include "conftest.i"
995 #if     GCC_PRINTF
996 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
997 #else
998 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
999 #endif
1000 #if     GCC_SCANF
1001 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1002 #else
1003 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1004 #endif
1005 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1006 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1007 extern void foo(void) GCC_NORETURN;
1008 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1009 EOF
1010         cf_printf_attribute=no
1011         cf_scanf_attribute=no
1012         for cf_attribute in scanf printf unused noreturn
1013         do
1014                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1015                 cf_directive="__attribute__(($cf_attribute))"
1016                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1017
1018                 case $cf_attribute in
1019                 (printf)
1020                         cf_printf_attribute=yes
1021                         cat >conftest.h <<EOF
1022 #define GCC_$cf_ATTRIBUTE 1
1023 EOF
1024                         ;;
1025                 (scanf)
1026                         cf_scanf_attribute=yes
1027                         cat >conftest.h <<EOF
1028 #define GCC_$cf_ATTRIBUTE 1
1029 EOF
1030                         ;;
1031                 (*)
1032                         cat >conftest.h <<EOF
1033 #define GCC_$cf_ATTRIBUTE $cf_directive
1034 EOF
1035                         ;;
1036                 esac
1037
1038                 if AC_TRY_EVAL(ac_compile); then
1039                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1040                         cat conftest.h >>confdefs.h
1041                         case $cf_attribute in
1042                         (noreturn)
1043                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1044                                 ;;
1045                         (printf)
1046                                 cf_value='/* nothing */'
1047                                 if test "$cf_printf_attribute" != no ; then
1048                                         cf_value='__attribute__((format(printf,fmt,var)))'
1049                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1050                                 fi
1051                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1052                                 ;;
1053                         (scanf)
1054                                 cf_value='/* nothing */'
1055                                 if test "$cf_scanf_attribute" != no ; then
1056                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1057                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1058                                 fi
1059                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1060                                 ;;
1061                         (unused)
1062                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1063                                 ;;
1064                         esac
1065                 fi
1066         done
1067 else
1068         fgrep define conftest.i >>confdefs.h
1069 fi
1070 rm -rf conftest*
1071 fi
1072 ])dnl
1073 dnl ---------------------------------------------------------------------------
1074 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1075 dnl --------------
1076 dnl Find version of gcc
1077 AC_DEFUN([CF_GCC_VERSION],[
1078 AC_REQUIRE([AC_PROG_CC])
1079 GCC_VERSION=none
1080 if test "$GCC" = yes ; then
1081         AC_MSG_CHECKING(version of $CC)
1082         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1083         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1084         AC_MSG_RESULT($GCC_VERSION)
1085 fi
1086 ])dnl
1087 dnl ---------------------------------------------------------------------------
1088 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
1089 dnl ---------------
1090 dnl Check if the compiler supports useful warning options.  There's a few that
1091 dnl we don't use, simply because they're too noisy:
1092 dnl
1093 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1094 dnl     -Wredundant-decls (system headers make this too noisy)
1095 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1096 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1097 dnl             is enabled for ncurses using "--enable-const".
1098 dnl     -pedantic
1099 dnl
1100 dnl Parameter:
1101 dnl     $1 is an optional list of gcc warning flags that a particular
1102 dnl             application might want to use, e.g., "no-unused" for
1103 dnl             -Wno-unused
1104 dnl Special:
1105 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1106 dnl
1107 AC_DEFUN([CF_GCC_WARNINGS],
1108 [
1109 AC_REQUIRE([CF_GCC_VERSION])
1110 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1111 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1112
1113 cat > conftest.$ac_ext <<EOF
1114 #line __oline__ "${as_me:-configure}"
1115 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1116 EOF
1117
1118 if test "$INTEL_COMPILER" = yes
1119 then
1120 # The "-wdXXX" options suppress warnings:
1121 # remark #1419: external declaration in primary source file
1122 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1123 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1124 # remark #193: zero used for undefined preprocessing identifier
1125 # remark #593: variable "curs_sb_left_arrow" was set but never used
1126 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1127 # remark #869: parameter "tw" was never referenced
1128 # remark #981: operands are evaluated in unspecified order
1129 # warning #279: controlling expression is constant
1130
1131         AC_CHECKING([for $CC warning options])
1132         cf_save_CFLAGS="$CFLAGS"
1133         EXTRA_CFLAGS="-Wall"
1134         for cf_opt in \
1135                 wd1419 \
1136                 wd1683 \
1137                 wd1684 \
1138                 wd193 \
1139                 wd593 \
1140                 wd279 \
1141                 wd810 \
1142                 wd869 \
1143                 wd981
1144         do
1145                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1146                 if AC_TRY_EVAL(ac_compile); then
1147                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1148                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1149                 fi
1150         done
1151         CFLAGS="$cf_save_CFLAGS"
1152
1153 elif test "$GCC" = yes
1154 then
1155         AC_CHECKING([for $CC warning options])
1156         cf_save_CFLAGS="$CFLAGS"
1157         EXTRA_CFLAGS=
1158         cf_warn_CONST=""
1159         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1160         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1161         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1162         for cf_opt in W Wall \
1163                 Wbad-function-cast \
1164                 Wcast-align \
1165                 Wcast-qual \
1166                 Wdeclaration-after-statement \
1167                 Wextra \
1168                 Winline \
1169                 Wmissing-declarations \
1170                 Wmissing-prototypes \
1171                 Wnested-externs \
1172                 Wpointer-arith \
1173                 Wshadow \
1174                 Wstrict-prototypes \
1175                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
1176         do
1177                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1178                 if AC_TRY_EVAL(ac_compile); then
1179                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1180                         case $cf_opt in
1181                         (Wcast-qual)
1182                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1183                                 ;;
1184                         (Winline)
1185                                 case $GCC_VERSION in
1186                                 ([[34]].*)
1187                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1188                                         continue;;
1189                                 esac
1190                                 ;;
1191                         (Wpointer-arith)
1192                                 case $GCC_VERSION in
1193                                 ([[12]].*)
1194                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1195                                         continue;;
1196                                 esac
1197                                 ;;
1198                         esac
1199                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1200                 fi
1201         done
1202         CFLAGS="$cf_save_CFLAGS"
1203 fi
1204 rm -rf conftest*
1205
1206 AC_SUBST(EXTRA_CFLAGS)
1207 ])dnl
1208 dnl ---------------------------------------------------------------------------
1209 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
1210 dnl -----------------
1211 AC_DEFUN([CF_GNATPREP_OPT_T],[
1212 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
1213 cf_cv_gnatprep_opt_t=no
1214 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
1215 ])
1216 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
1217 AC_SUBST(GNATPREP_OPTS)
1218 ])dnl
1219 dnl ---------------------------------------------------------------------------
1220 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
1221 dnl ----------------
1222 AC_DEFUN([CF_GNAT_GENERICS],
1223 [
1224 AC_REQUIRE([CF_GNAT_VERSION])
1225
1226 AC_MSG_CHECKING(if GNAT supports generics)
1227 case $cf_gnat_version in
1228 (3.[[1-9]]*|[[4-9]].*)
1229         cf_gnat_generics=yes
1230         ;;
1231 (*)
1232         cf_gnat_generics=no
1233         ;;
1234 esac
1235 AC_MSG_RESULT($cf_gnat_generics)
1236
1237 if test "$cf_gnat_generics" = yes
1238 then
1239         cf_compile_generics=generics
1240         cf_generic_objects="\${GENOBJS}"
1241 else
1242         cf_compile_generics=
1243         cf_generic_objects=
1244 fi
1245
1246 AC_SUBST(cf_compile_generics)
1247 AC_SUBST(cf_generic_objects)
1248 ])dnl
1249 dnl ---------------------------------------------------------------------------
1250 dnl CF_GNAT_PROJECTS version: 8 updated: 2015/04/17 21:13:04
1251 dnl ----------------
1252 dnl GNAT projects are configured with ".gpr" project files.
1253 dnl GNAT libraries are a further development, using the project feature.
1254 AC_DEFUN([CF_GNAT_PROJECTS],
1255 [
1256 AC_REQUIRE([CF_GNAT_VERSION])
1257 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
1258
1259 cf_gnat_libraries=no
1260 cf_gnat_projects=no
1261
1262 if test "$enable_gnat_projects" != no ; then
1263 AC_MSG_CHECKING(if GNAT supports project files)
1264 case $cf_gnat_version in
1265 (3.[[0-9]]*)
1266         ;;
1267 (*)
1268         case $cf_cv_system_name in
1269         (cygwin*|msys*)
1270                 ;;
1271         (*)
1272                 mkdir conftest.src conftest.bin conftest.lib
1273                 cd conftest.src
1274                 rm -rf conftest* *~conftest*
1275                 cat >>library.gpr <<CF_EOF
1276 project Library is
1277   Kind := External ("LIB_KIND");
1278   for Library_Name use "ConfTest";
1279   for Object_Dir use ".";
1280   for Library_ALI_Dir use External("LIBRARY_DIR");
1281   for Library_Version use External ("SONAME");
1282   for Library_Kind use Kind;
1283   for Library_Dir use External("BUILD_DIR");
1284   Source_Dir := External ("SOURCE_DIR");
1285   for Source_Dirs use (Source_Dir);
1286 end Library;
1287 CF_EOF
1288                 cat >>confpackage.ads <<CF_EOF
1289 package ConfPackage is
1290    procedure conftest;
1291 end ConfPackage;
1292 CF_EOF
1293                 cat >>confpackage.adb <<CF_EOF
1294 with Text_IO;
1295 package body ConfPackage is
1296    procedure conftest is
1297    begin
1298       Text_IO.Put ("Hello World");
1299       Text_IO.New_Line;
1300    end conftest;
1301 end ConfPackage;
1302 CF_EOF
1303                 if ( $cf_ada_make $ADAFLAGS \
1304                                 -Plibrary.gpr \
1305                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
1306                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
1307                                 -XSOURCE_DIR=`pwd` \
1308                                 -XSONAME=libConfTest.so.1 \
1309                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1310                         cf_gnat_projects=yes
1311                 fi
1312                 cd ..
1313                 if test -f conftest.lib/confpackage.ali
1314                 then
1315                         cf_gnat_libraries=yes
1316                 fi
1317                 rm -rf conftest* *~conftest*
1318                 ;;
1319         esac
1320         ;;
1321 esac
1322 AC_MSG_RESULT($cf_gnat_projects)
1323 fi # enable_gnat_projects
1324
1325 if test $cf_gnat_projects = yes
1326 then
1327         AC_MSG_CHECKING(if GNAT supports libraries)
1328         AC_MSG_RESULT($cf_gnat_libraries)
1329 fi
1330
1331 if test "$cf_gnat_projects" = yes
1332 then
1333         USE_OLD_MAKERULES="#"
1334         USE_GNAT_PROJECTS=""
1335 else
1336         USE_OLD_MAKERULES=""
1337         USE_GNAT_PROJECTS="#"
1338 fi
1339
1340 if test "$cf_gnat_libraries" = yes
1341 then
1342         USE_GNAT_LIBRARIES=""
1343 else
1344         USE_GNAT_LIBRARIES="#"
1345 fi
1346
1347 AC_SUBST(USE_OLD_MAKERULES)
1348 AC_SUBST(USE_GNAT_PROJECTS)
1349 AC_SUBST(USE_GNAT_LIBRARIES)
1350 ])dnl
1351 dnl ---------------------------------------------------------------------------
1352 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
1353 dnl --------------
1354 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1355 dnl is noted that gnat may compile a tasking unit even for configurations which
1356 dnl fail at runtime.
1357 AC_DEFUN([CF_GNAT_SIGINT],[
1358 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1359 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1360
1361 package ConfTest is
1362
1363    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1364    pragma Unreserve_All_Interrupts;
1365    pragma Warnings (On);
1366
1367    protected Process is
1368       procedure Stop;
1369       function Continue return Boolean;
1370       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1371    private
1372       Done : Boolean := False;
1373    end Process;
1374
1375 end ConfTest;],
1376 [package body ConfTest is
1377    protected body Process is
1378       procedure Stop is
1379       begin
1380          Done := True;
1381       end Stop;
1382       function Continue return Boolean is
1383       begin
1384          return not Done;
1385       end Continue;
1386    end Process;
1387 end ConfTest;],
1388         [cf_cv_gnat_sigint=yes],
1389         [cf_cv_gnat_sigint=no])])
1390
1391 if test $cf_cv_gnat_sigint = yes ; then
1392         USE_GNAT_SIGINT=""
1393 else
1394         USE_GNAT_SIGINT="#"
1395 fi
1396 AC_SUBST(USE_GNAT_SIGINT)
1397 ])dnl
1398 dnl ---------------------------------------------------------------------------
1399 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
1400 dnl ----------------
1401 dnl Verify that a test program compiles/links with GNAT.
1402 dnl $cf_ada_make is set to the program that compiles/links
1403 dnl $ADAFLAGS may be set to the GNAT flags.
1404 dnl
1405 dnl $1 is the text of the spec
1406 dnl $2 is the text of the body
1407 dnl $3 is the shell command to execute if successful
1408 dnl $4 is the shell command to execute if not successful
1409 AC_DEFUN([CF_GNAT_TRY_LINK],
1410 [
1411 rm -rf conftest* *~conftest*
1412 cat >>conftest.ads <<CF_EOF
1413 $1
1414 CF_EOF
1415 cat >>conftest.adb <<CF_EOF
1416 $2
1417 CF_EOF
1418 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1419 ifelse($3,,      :,[      $3])
1420 ifelse($4,,,[else
1421    $4])
1422 fi
1423 rm -rf conftest* *~conftest*
1424 ])dnl
1425 dnl ---------------------------------------------------------------------------
1426 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
1427 dnl ---------------
1428 dnl Verify that a test program compiles and runs with GNAT
1429 dnl $cf_ada_make is set to the program that compiles/links
1430 dnl $ADAFLAGS may be set to the GNAT flags.
1431 dnl
1432 dnl $1 is the text of the spec
1433 dnl $2 is the text of the body
1434 dnl $3 is the shell command to execute if successful
1435 dnl $4 is the shell command to execute if not successful
1436 AC_DEFUN([CF_GNAT_TRY_RUN],
1437 [
1438 rm -rf conftest* *~conftest*
1439 cat >>conftest.ads <<CF_EOF
1440 $1
1441 CF_EOF
1442 cat >>conftest.adb <<CF_EOF
1443 $2
1444 CF_EOF
1445 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1446    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1447 ifelse($3,,      :,[      $3])
1448 ifelse($4,,,[   else
1449       $4])
1450    fi
1451 ifelse($4,,,[else
1452    $4])
1453 fi
1454 rm -rf conftest* *~conftest*
1455 ])dnl
1456 dnl ---------------------------------------------------------------------------
1457 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
1458 dnl ---------------
1459 dnl Verify version of GNAT.
1460 AC_DEFUN([CF_GNAT_VERSION],
1461 [
1462 AC_MSG_CHECKING(for gnat version)
1463 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
1464         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1465         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1466 AC_MSG_RESULT($cf_gnat_version)
1467
1468 case $cf_gnat_version in
1469 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
1470         cf_cv_prog_gnat_correct=yes
1471         ;;
1472 (*)
1473         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1474         cf_cv_prog_gnat_correct=no
1475         ;;
1476 esac
1477 ])
1478 dnl ---------------------------------------------------------------------------
1479 dnl CF_GNU_SOURCE version: 7 updated: 2016/08/05 05:15:37
1480 dnl -------------
1481 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1482 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1483 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1484 dnl since it is interwoven with GNU extensions.
1485 dnl
1486 dnl Well, yes we could work around it...
1487 AC_DEFUN([CF_GNU_SOURCE],
1488 [
1489 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1490 AC_TRY_COMPILE([#include <sys/types.h>],[
1491 #ifndef _XOPEN_SOURCE
1492 make an error
1493 #endif],
1494         [cf_cv_gnu_source=no],
1495         [cf_save="$CPPFLAGS"
1496          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1497          AC_TRY_COMPILE([#include <sys/types.h>],[
1498 #ifdef _XOPEN_SOURCE
1499 make an error
1500 #endif],
1501         [cf_cv_gnu_source=no],
1502         [cf_cv_gnu_source=yes])
1503         CPPFLAGS="$cf_save"
1504         ])
1505 ])
1506
1507 if test "$cf_cv_gnu_source" = yes
1508 then
1509 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
1510 CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1511         AC_TRY_COMPILE([#include <sys/types.h>],[
1512 #ifdef _DEFAULT_SOURCE
1513 make an error
1514 #endif],
1515                 [cf_cv_default_source=no],
1516                 [cf_cv_default_source=yes])
1517         ])
1518 test "$cf_cv_default_source" = yes && CPPFLAGS="$CPPFLAGS -D_DEFAULT_SOURCE"
1519 fi
1520 ])dnl
1521 dnl ---------------------------------------------------------------------------
1522 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
1523 dnl --------------
1524 dnl Construct a search-list of directories for a nonstandard header-file
1525 dnl
1526 dnl Parameters
1527 dnl     $1 = the variable to return as result
1528 dnl     $2 = the package name
1529 AC_DEFUN([CF_HEADER_PATH],
1530 [
1531 $1=
1532
1533 # collect the current set of include-directories from compiler flags
1534 cf_header_path_list=""
1535 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1536         for cf_header_path in $CPPFLAGS $CFLAGS
1537         do
1538                 case $cf_header_path in
1539                 (-I*)
1540                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1541                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1542                         cf_header_path_list="$cf_header_path_list [$]$1"
1543                         ;;
1544                 esac
1545         done
1546 fi
1547
1548 # add the variations for the package we are looking for
1549 CF_SUBDIR_PATH($1,$2,include)
1550
1551 test "$includedir" != NONE && \
1552 test "$includedir" != "/usr/include" && \
1553 test -d "$includedir" && {
1554         test -d $includedir &&    $1="[$]$1 $includedir"
1555         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1556 }
1557
1558 test "$oldincludedir" != NONE && \
1559 test "$oldincludedir" != "/usr/include" && \
1560 test -d "$oldincludedir" && {
1561         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1562         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1563 }
1564
1565 $1="[$]$1 $cf_header_path_list"
1566 ])dnl
1567 dnl ---------------------------------------------------------------------------
1568 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1569 dnl ---------------
1570 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1571 AC_DEFUN([CF_HELP_MESSAGE],
1572 [AC_DIVERT_HELP([$1])dnl
1573 ])dnl
1574 dnl ---------------------------------------------------------------------------
1575 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
1576 dnl ---------------
1577 dnl Construct the list of include-options according to whether we're building
1578 dnl in the source directory or using '--srcdir=DIR' option.
1579 AC_DEFUN([CF_INCLUDE_DIRS],
1580 [
1581 if test "$srcdir" != "."; then
1582         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
1583 fi
1584 CPPFLAGS="-I../include $CPPFLAGS"
1585 if test "$srcdir" != "."; then
1586         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
1587 fi
1588 CPPFLAGS="-I. $CPPFLAGS"
1589 AC_SUBST(CPPFLAGS)
1590 ])dnl
1591 dnl ---------------------------------------------------------------------------
1592 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
1593 dnl -----------------
1594 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1595 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1596 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1597 dnl
1598 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1599 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1600 dnl the wrappers for gcc and g++ warnings.
1601 dnl
1602 dnl $1 = GCC (default) or GXX
1603 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1604 dnl $3 = CFLAGS (default) or CXXFLAGS
1605 AC_DEFUN([CF_INTEL_COMPILER],[
1606 AC_REQUIRE([AC_CANONICAL_HOST])
1607 ifelse([$2],,INTEL_COMPILER,[$2])=no
1608
1609 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1610         case $host_os in
1611         (linux*|gnu*)
1612                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1613                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1614                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1615                 AC_TRY_COMPILE([],[
1616 #ifdef __INTEL_COMPILER
1617 #else
1618 make an error
1619 #endif
1620 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1621 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
1622 ],[])
1623                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1624                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1625                 ;;
1626         esac
1627 fi
1628 ])dnl
1629 dnl ---------------------------------------------------------------------------
1630 dnl CF_LARGEFILE version: 9 updated: 2015/04/18 08:56:57
1631 dnl ------------
1632 dnl Add checks for large file support.
1633 AC_DEFUN([CF_LARGEFILE],[
1634 ifdef([AC_FUNC_FSEEKO],[
1635         AC_SYS_LARGEFILE
1636         if test "$enable_largefile" != no ; then
1637         AC_FUNC_FSEEKO
1638
1639         # Normally we would collect these definitions in the config.h,
1640         # but (like _XOPEN_SOURCE), some environments rely on having these
1641         # defined before any of the system headers are included.  Another
1642         # case comes up with C++, e.g., on AIX the compiler compiles the
1643         # header files by themselves before looking at the body files it is
1644         # told to compile.  For ncurses, those header files do not include
1645         # the config.h
1646         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
1647         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
1648         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
1649
1650         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
1651                 AC_TRY_COMPILE([
1652 #include <sys/types.h>
1653 #include <dirent.h>
1654                 ],[
1655                 /* if transitional largefile support is setup, this is true */
1656                 extern struct dirent64 * readdir(DIR *);
1657                 struct dirent64 *x = readdir((DIR *)0);
1658                 struct dirent *y = readdir((DIR *)0);
1659                 int z = x - y;
1660                 ],
1661                 [cf_cv_struct_dirent64=yes],
1662                 [cf_cv_struct_dirent64=no])
1663         ])
1664         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
1665         fi
1666 ])
1667 ])
1668 dnl ---------------------------------------------------------------------------
1669 dnl CF_LD_RPATH_OPT version: 7 updated: 2016/02/20 18:01:19
1670 dnl ---------------
1671 dnl For the given system and compiler, find the compiler flags to pass to the
1672 dnl loader to use the "rpath" feature.
1673 AC_DEFUN([CF_LD_RPATH_OPT],
1674 [
1675 AC_REQUIRE([CF_CHECK_CACHE])
1676
1677 LD_RPATH_OPT=
1678 AC_MSG_CHECKING(for an rpath option)
1679 case $cf_cv_system_name in
1680 (irix*)
1681         if test "$GCC" = yes; then
1682                 LD_RPATH_OPT="-Wl,-rpath,"
1683         else
1684                 LD_RPATH_OPT="-rpath "
1685         fi
1686         ;;
1687 (linux*|gnu*|k*bsd*-gnu|freebsd*)
1688         LD_RPATH_OPT="-Wl,-rpath,"
1689         ;;
1690 (openbsd[[2-9]].*|mirbsd*)
1691         LD_RPATH_OPT="-Wl,-rpath,"
1692         ;;
1693 (dragonfly*)
1694         LD_RPATH_OPT="-rpath "
1695         ;;
1696 (netbsd*)
1697         LD_RPATH_OPT="-Wl,-rpath,"
1698         ;;
1699 (osf*|mls+*)
1700         LD_RPATH_OPT="-rpath "
1701         ;;
1702 (solaris2*)
1703         LD_RPATH_OPT="-R"
1704         ;;
1705 (*)
1706         ;;
1707 esac
1708 AC_MSG_RESULT($LD_RPATH_OPT)
1709
1710 case "x$LD_RPATH_OPT" in
1711 (x-R*)
1712         AC_MSG_CHECKING(if we need a space after rpath option)
1713         cf_save_LIBS="$LIBS"
1714         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1715         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1716         LIBS="$cf_save_LIBS"
1717         AC_MSG_RESULT($cf_rpath_space)
1718         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1719         ;;
1720 esac
1721 ])dnl
1722 dnl ---------------------------------------------------------------------------
1723 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
1724 dnl ---------------
1725 dnl Construct a search-list of directories for a nonstandard library-file
1726 dnl
1727 dnl Parameters
1728 dnl     $1 = the variable to return as result
1729 dnl     $2 = the package name
1730 AC_DEFUN([CF_LIBRARY_PATH],
1731 [
1732 $1=
1733 cf_library_path_list=""
1734 if test -n "${LDFLAGS}${LIBS}" ; then
1735         for cf_library_path in $LDFLAGS $LIBS
1736         do
1737                 case $cf_library_path in
1738                 (-L*)
1739                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1740                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1741                         cf_library_path_list="$cf_library_path_list [$]$1"
1742                         ;;
1743                 esac
1744         done
1745 fi
1746
1747 CF_SUBDIR_PATH($1,$2,lib)
1748
1749 $1="$cf_library_path_list [$]$1"
1750 ])dnl
1751 dnl ---------------------------------------------------------------------------
1752 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
1753 dnl -------------
1754 dnl Compute the library-prefix for the given host system
1755 dnl $1 = variable to set
1756 define([CF_LIB_PREFIX],
1757 [
1758         case $cf_cv_system_name in
1759         (OS/2*|os2*)
1760                 if test "$DFT_LWR_MODEL" = libtool; then
1761                         LIB_PREFIX='lib'
1762                 else
1763                         LIB_PREFIX=''
1764                 fi
1765                 ;;
1766         (*)     LIB_PREFIX='lib'
1767                 ;;
1768         esac
1769 ifelse($1,,,[$1=$LIB_PREFIX])
1770         AC_SUBST(LIB_PREFIX)
1771 ])dnl
1772 dnl ---------------------------------------------------------------------------
1773 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
1774 dnl -------------
1775 dnl Compute the library file-suffix from the given model name
1776 dnl $1 = model name
1777 dnl $2 = variable to set (the nominal library suffix)
1778 dnl $3 = dependency variable to set (actual filename)
1779 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1780 AC_DEFUN([CF_LIB_SUFFIX],
1781 [
1782         case X$1 in
1783         (Xlibtool)
1784                 $2='.la'
1785                 $3=[$]$2
1786                 ;;
1787         (Xdebug)
1788                 $2='_g.a'
1789                 $3=[$]$2
1790                 ;;
1791         (Xprofile)
1792                 $2='_p.a'
1793                 $3=[$]$2
1794                 ;;
1795         (Xshared)
1796                 case $cf_cv_system_name in
1797                 (aix[[5-7]]*)
1798                         $2='.so'
1799                         $3=[$]$2
1800                         ;;
1801                 (cygwin*|msys*|mingw*)
1802                         $2='.dll'
1803                         $3='.dll.a'
1804                         ;;
1805                 (darwin*)
1806                         $2='.dylib'
1807                         $3=[$]$2
1808                         ;;
1809                 (hpux*)
1810                         case $target in
1811                         (ia64*)
1812                                 $2='.so'
1813                                 $3=[$]$2
1814                                 ;;
1815                         (*)
1816                                 $2='.sl'
1817                                 $3=[$]$2
1818                                 ;;
1819                         esac
1820                         ;;
1821                 (*)
1822                         $2='.so'
1823                         $3=[$]$2
1824                         ;;
1825                 esac
1826                 ;;
1827         (*)
1828                 $2='.a'
1829                 $3=[$]$2
1830                 ;;
1831         esac
1832         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
1833         then
1834                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
1835                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
1836         fi
1837 ])dnl
1838 dnl ---------------------------------------------------------------------------
1839 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
1840 dnl -----------
1841 dnl Compute the string to append to -library from the given model name
1842 dnl $1 = model name
1843 dnl $2 = variable to set
1844 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1845 AC_DEFUN([CF_LIB_TYPE],
1846 [
1847         case $1 in
1848         (libtool) $2=''   ;;
1849         (normal)  $2=''   ;;
1850         (debug)   $2='_g' ;;
1851         (profile) $2='_p' ;;
1852         (shared)  $2=''   ;;
1853         esac
1854         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1855 ])dnl
1856 dnl ---------------------------------------------------------------------------
1857 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
1858 dnl ----------------
1859 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
1860 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
1861 dnl have to provide wrappers for global tables to ensure they're linked
1862 dnl properly.
1863 AC_DEFUN([CF_LINK_DATAONLY],
1864 [
1865 AC_MSG_CHECKING([if data-only library module links])
1866 AC_CACHE_VAL(cf_cv_link_dataonly,[
1867         rm -f conftest.a
1868         cat >conftest.$ac_ext <<EOF
1869 #line __oline__ "configure"
1870 int     testdata[[3]] = { 123, 456, 789 };
1871 EOF
1872         if AC_TRY_EVAL(ac_compile) ; then
1873                 mv conftest.o data.o && \
1874                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
1875         fi
1876         rm -f conftest.$ac_ext data.o
1877         cat >conftest.$ac_ext <<EOF
1878 #line __oline__ "configure"
1879 int     testfunc()
1880 {
1881 #if defined(NeXT)
1882         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
1883 #else
1884         extern int testdata[[3]];
1885         return testdata[[0]] == 123
1886            &&  testdata[[1]] == 456
1887            &&  testdata[[2]] == 789;
1888 #endif
1889 }
1890 EOF
1891         if AC_TRY_EVAL(ac_compile); then
1892                 mv conftest.o func.o && \
1893                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
1894         fi
1895         rm -f conftest.$ac_ext func.o
1896         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
1897         cf_saveLIBS="$LIBS"
1898         LIBS="conftest.a $LIBS"
1899         AC_TRY_RUN([
1900         int main()
1901         {
1902                 extern int testfunc();
1903                 ${cf_cv_main_return:-return} (!testfunc());
1904         }
1905         ],
1906         [cf_cv_link_dataonly=yes],
1907         [cf_cv_link_dataonly=no],
1908         [cf_cv_link_dataonly=unknown])
1909         LIBS="$cf_saveLIBS"
1910         ])
1911 AC_MSG_RESULT($cf_cv_link_dataonly)
1912
1913 if test "$cf_cv_link_dataonly" = no ; then
1914         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
1915         BROKEN_LINKER=1
1916 fi
1917
1918 ])dnl
1919 dnl ---------------------------------------------------------------------------
1920 dnl CF_MAKEFLAGS version: 17 updated: 2015/08/05 20:44:28
1921 dnl ------------
1922 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
1923 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
1924 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
1925 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
1926 AC_DEFUN([CF_MAKEFLAGS],
1927 [
1928 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
1929         cf_cv_makeflags=''
1930         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
1931         do
1932                 cat >cf_makeflags.tmp <<CF_EOF
1933 SHELL = $SHELL
1934 all :
1935         @ echo '.$cf_option'
1936 CF_EOF
1937                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
1938                 case "$cf_result" in
1939                 (.*k|.*kw)
1940                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
1941                         case "$cf_result" in
1942                         (.*CC=*)        cf_cv_makeflags=
1943                                 ;;
1944                         (*)     cf_cv_makeflags=$cf_option
1945                                 ;;
1946                         esac
1947                         break
1948                         ;;
1949                 (.-)    ;;
1950                 (*)     echo "given option \"$cf_option\", no match \"$cf_result\""
1951                         ;;
1952                 esac
1953         done
1954         rm -f cf_makeflags.tmp
1955 ])
1956
1957 AC_SUBST(cf_cv_makeflags)
1958 ])dnl
1959 dnl ---------------------------------------------------------------------------
1960 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1961 dnl ------------
1962 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1963 dnl a monocase filesystem.
1964 AC_DEFUN([CF_MAKE_TAGS],[
1965 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1966
1967 AC_CHECK_PROGS(CTAGS, exctags ctags)
1968 AC_CHECK_PROGS(ETAGS, exetags etags)
1969
1970 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1971
1972 if test "$cf_cv_mixedcase" = yes ; then
1973         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1974 else
1975         MAKE_UPPER_TAGS=no
1976 fi
1977
1978 if test "$MAKE_UPPER_TAGS" = yes ; then
1979         MAKE_UPPER_TAGS=
1980 else
1981         MAKE_UPPER_TAGS="#"
1982 fi
1983
1984 if test "$MAKE_LOWER_TAGS" = yes ; then
1985         MAKE_LOWER_TAGS=
1986 else
1987         MAKE_LOWER_TAGS="#"
1988 fi
1989
1990 AC_SUBST(CTAGS)
1991 AC_SUBST(ETAGS)
1992
1993 AC_SUBST(MAKE_UPPER_TAGS)
1994 AC_SUBST(MAKE_LOWER_TAGS)
1995 ])dnl
1996 dnl ---------------------------------------------------------------------------
1997 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
1998 dnl ----------------------
1999 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2000 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2001 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2002 [
2003 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2004 if test "$cross_compiling" = yes ; then
2005         case $target_alias in
2006         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
2007                 cf_cv_mixedcase=no
2008                 ;;
2009         (*)
2010                 cf_cv_mixedcase=yes
2011                 ;;
2012         esac
2013 else
2014         rm -f conftest CONFTEST
2015         echo test >conftest
2016         if test -f CONFTEST ; then
2017                 cf_cv_mixedcase=no
2018         else
2019                 cf_cv_mixedcase=yes
2020         fi
2021         rm -f conftest CONFTEST
2022 fi
2023 ])
2024 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2025 ])dnl
2026 dnl ---------------------------------------------------------------------------
2027 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
2028 dnl ----------
2029 dnl Check for a working mkstemp.  This creates two files, checks that they are
2030 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2031 AC_DEFUN([CF_MKSTEMP],[
2032 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2033 rm -rf conftest*
2034 AC_TRY_RUN([
2035 #include <sys/types.h>
2036 #include <stdlib.h>
2037 #include <stdio.h>
2038 #include <string.h>
2039 #include <sys/stat.h>
2040 int main()
2041 {
2042         char *tmpl = "conftestXXXXXX";
2043         char name[2][80];
2044         int n;
2045         int result = 0;
2046         int fd;
2047         struct stat sb;
2048
2049         umask(077);
2050         for (n = 0; n < 2; ++n) {
2051                 strcpy(name[n], tmpl);
2052                 if ((fd = mkstemp(name[n])) >= 0) {
2053                         if (!strcmp(name[n], tmpl)
2054                          || stat(name[n], &sb) != 0
2055                          || (sb.st_mode & S_IFMT) != S_IFREG
2056                          || (sb.st_mode & 077) != 0) {
2057                                 result = 1;
2058                         }
2059                         close(fd);
2060                 }
2061         }
2062         if (result == 0
2063          && !strcmp(name[0], name[1]))
2064                 result = 1;
2065         ${cf_cv_main_return:-return}(result);
2066 }
2067 ],[cf_cv_func_mkstemp=yes
2068 ],[cf_cv_func_mkstemp=no
2069 ],[cf_cv_func_mkstemp=maybe])
2070 ])
2071 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2072         AC_CHECK_FUNC(mkstemp)
2073 fi
2074 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2075         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2076 fi
2077 ])dnl
2078 dnl ---------------------------------------------------------------------------
2079 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2080 dnl ----------
2081 dnl Write a debug message to config.log, along with the line number in the
2082 dnl configure script.
2083 AC_DEFUN([CF_MSG_LOG],[
2084 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2085 ])dnl
2086 dnl ---------------------------------------------------------------------------
2087 dnl CF_NCURSES_ADDON version: 5 updated: 2015/04/26 18:06:58
2088 dnl ----------------
2089 dnl Configure an ncurses add-on, built outside the ncurses tree.
2090 AC_DEFUN([CF_NCURSES_ADDON],[
2091 AC_REQUIRE([CF_NCURSES_CONFIG])
2092
2093 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2094
2095 AC_MSG_CHECKING(if you want wide-character code)
2096 AC_ARG_ENABLE(widec,
2097         [  --enable-widec          compile with wide-char/UTF-8 code],
2098         [with_widec=$enableval],
2099         [with_widec=no])
2100 AC_MSG_RESULT($with_widec)
2101 if test "$with_widec" = yes ; then
2102         CF_UTF8_LIB
2103         CF_NCURSES_CONFIG(ncursesw)
2104 else
2105         CF_NCURSES_CONFIG(ncurses)
2106 fi
2107
2108 if test "$NCURSES_CONFIG_PKG" != none ; then
2109         cf_version=`$PKG_CONFIG --modversion $NCURSES_CONFIG_PKG 2>/dev/null`
2110
2111         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2112         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2113         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2114
2115         cf_cv_abi_version=`$PKG_CONFIG --variable=abi_version $NCURSES_CONFIG_PKG 2>/dev/null`
2116         if test -z "$cf_cv_abi_version"
2117         then
2118                 cf_cv_abi_version=`$PKG_CONFIG --variable=major_version $NCURSES_CONFIG_PKG 2>/dev/null`
2119         fi
2120
2121 elif test "$NCURSES_CONFIG" != none ; then
2122
2123         cf_version=`$NCURSES_CONFIG --version 2>/dev/null`
2124
2125         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2126         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2127         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2128
2129         # ABI version is not available from headers
2130         cf_cv_abi_version=`$NCURSES_CONFIG --abi-version 2>/dev/null`
2131
2132 else
2133
2134         for cf_name in MAJOR MINOR PATCH
2135         do
2136         cat >conftest.$ac_ext <<CF_EOF
2137         #include <${cf_cv_ncurses_header:-curses.h}>
2138         AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2139 CF_EOF
2140                 cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2141                 AC_TRY_EVAL(cf_try)
2142                 if test -f conftest.out ; then
2143                         cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]][[    ]]*//"`
2144                         eval NCURSES_$cf_name=\"$cf_result\"
2145                         # cat conftest.$ac_ext
2146                         # cat conftest.out
2147                 fi
2148         done
2149
2150         cf_cv_abi_version=${NCURSES_MAJOR}
2151
2152 fi
2153
2154 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2155
2156 dnl Show the computed version, for logging
2157 cf_cv_timestamp=`date`
2158
2159 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2160
2161 dnl We need these values in the generated headers
2162 AC_SUBST(NCURSES_MAJOR)
2163 AC_SUBST(NCURSES_MINOR)
2164 AC_SUBST(NCURSES_PATCH)
2165
2166 dnl We need these values in the generated makefiles
2167 AC_SUBST(cf_cv_rel_version)
2168 AC_SUBST(cf_cv_abi_version)
2169
2170 dnl FIXME - not needed for Ada95
2171 AC_SUBST(cf_cv_builtin_bool)
2172 AC_SUBST(cf_cv_header_stdbool_h)
2173 AC_SUBST(cf_cv_type_of_bool)dnl
2174
2175 ])
2176 dnl ---------------------------------------------------------------------------
2177 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2178 dnl -------------------
2179 dnl Check if we can compile with ncurses' header file
2180 dnl $1 is the cache variable to set
2181 dnl $2 is the header-file to include
2182 dnl $3 is the root name (ncurses or ncursesw)
2183 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2184         AC_TRY_COMPILE([
2185 ]ifelse($3,ncursesw,[
2186 #define _XOPEN_SOURCE_EXTENDED
2187 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2188 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2189 ])[
2190 #include <$2>],[
2191 #ifdef NCURSES_VERSION
2192 ]ifelse($3,ncursesw,[
2193 #ifndef WACS_BSSB
2194         make an error
2195 #endif
2196 ])[
2197 printf("%s\n", NCURSES_VERSION);
2198 #else
2199 #ifdef __NCURSES_H
2200 printf("old\n");
2201 #else
2202         make an error
2203 #endif
2204 #endif
2205         ]
2206         ,[$1=$2]
2207         ,[$1=no])
2208 ])dnl
2209 dnl ---------------------------------------------------------------------------
2210 dnl CF_NCURSES_CONFIG version: 17 updated: 2015/07/07 04:22:07
2211 dnl -----------------
2212 dnl Tie together the configure-script macros for ncurses, preferring these in
2213 dnl order:
2214 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2215 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2216 dnl c) just plain libraries
2217 dnl
2218 dnl $1 is the root library name (default: "ncurses")
2219 AC_DEFUN([CF_NCURSES_CONFIG],[
2220 AC_REQUIRE([CF_PKG_CONFIG])
2221 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2222 cf_have_ncuconfig=no
2223
2224 if test "x${PKG_CONFIG:=none}" != xnone; then
2225         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2226         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2227                 AC_MSG_RESULT(yes)
2228
2229                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2230                 cf_have_ncuconfig=unknown
2231
2232                 cf_save_CPPFLAGS="$CPPFLAGS"
2233                 cf_save_LIBS="$LIBS"
2234
2235                 CPPFLAGS="$CPPFLAGS `$PKG_CONFIG --cflags $cf_ncuconfig_root`"
2236                 CF_ADD_LIBS(`$PKG_CONFIG --libs $cf_ncuconfig_root`)
2237
2238                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2239                         [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2240                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2241                                 int main(void)
2242                                 { char *xx = curses_version(); return (xx == 0); }],
2243                                 [cf_have_ncuconfig=yes],
2244                                 [cf_have_ncuconfig=no],
2245                                 [cf_have_ncuconfig=maybe])],
2246                         [cf_have_ncuconfig=no])
2247                 AC_MSG_RESULT($cf_have_ncuconfig)
2248                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2249                 if test "$cf_have_ncuconfig" != "yes"
2250                 then
2251                         CPPFLAGS="$cf_save_CPPFLAGS"
2252                         LIBS="$cf_save_LIBS"
2253                         NCURSES_CONFIG_PKG=none
2254                 else
2255                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2256                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2257                 fi
2258
2259         else
2260                 AC_MSG_RESULT(no)
2261                 NCURSES_CONFIG_PKG=none
2262         fi
2263 else
2264         NCURSES_CONFIG_PKG=none
2265 fi
2266
2267 if test "x$cf_have_ncuconfig" = "xno"; then
2268         echo "Looking for ${cf_ncuconfig_root}-config"
2269
2270         CF_ACVERSION_CHECK(2.52,
2271                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncuconfig_root}-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2272                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncuconfig_root}-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2273
2274         if test "$NCURSES_CONFIG" != none ; then
2275
2276                 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
2277                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2278
2279                 # even with config script, some packages use no-override for curses.h
2280                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2281
2282                 dnl like CF_NCURSES_CPPFLAGS
2283                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2284
2285                 dnl like CF_NCURSES_LIBS
2286                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2287                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2288
2289                 dnl like CF_NCURSES_VERSION
2290                 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2291
2292         else
2293
2294                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2295                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2296
2297         fi
2298 else
2299         NCURSES_CONFIG=none
2300 fi
2301 ])dnl
2302 dnl ---------------------------------------------------------------------------
2303 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2304 dnl -------------------
2305 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2306 dnl the CPPFLAGS variable so we can include its header.
2307 dnl
2308 dnl The header files may be installed as either curses.h, or ncurses.h (would
2309 dnl be obsolete, except that some packagers prefer this name to distinguish it
2310 dnl from a "native" curses implementation).  If not installed for overwrite,
2311 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2312 dnl /usr/include/ncurses), but someone may have installed overwriting the
2313 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2314 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2315 dnl the header.
2316 dnl
2317 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2318 dnl is already in the include-path, don't even bother with this, since we cannot
2319 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2320 dnl
2321 dnl The optional parameter gives the root name of the library, in case it is
2322 dnl not installed as the default curses library.  That is how the
2323 dnl wide-character version of ncurses is installed.
2324 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2325 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2326
2327 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2328 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2329
2330 test -n "$cf_cv_curses_dir" && \
2331 test "$cf_cv_curses_dir" != "no" && { \
2332   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2333 }
2334
2335 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2336         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2337         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2338         for cf_header in $cf_header_list
2339         do
2340                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2341                 test "$cf_cv_ncurses_h" != no && break
2342         done
2343 ])
2344
2345 CF_NCURSES_HEADER
2346 CF_TERM_HEADER
2347
2348 # some applications need this, but should check for NCURSES_VERSION
2349 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2350
2351 CF_NCURSES_VERSION
2352 ])dnl
2353 dnl ---------------------------------------------------------------------------
2354 dnl CF_NCURSES_HEADER version: 4 updated: 2015/04/15 19:08:48
2355 dnl -----------------
2356 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2357 dnl variations of ncurses' installs.
2358 dnl
2359 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2360 AC_DEFUN([CF_NCURSES_HEADER],[
2361
2362 if test "$cf_cv_ncurses_h" != no ; then
2363         cf_cv_ncurses_header=$cf_cv_ncurses_h
2364 else
2365
2366 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2367         test -n "$verbose" && echo
2368         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2369         test -n "$verbose" && echo search path $cf_search
2370         cf_save2_CPPFLAGS="$CPPFLAGS"
2371         for cf_incdir in $cf_search
2372         do
2373                 CF_ADD_INCDIR($cf_incdir)
2374                 for cf_header in \
2375                         ncurses.h \
2376                         curses.h
2377                 do
2378                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2379                         if test "$cf_cv_ncurses_h2" != no ; then
2380                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2381                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2382                                 break
2383                         fi
2384                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2385                 done
2386                 CPPFLAGS="$cf_save2_CPPFLAGS"
2387                 test "$cf_cv_ncurses_h2" != no && break
2388         done
2389         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2390         ])
2391
2392         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2393         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2394         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2395                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2396         fi
2397         CF_ADD_INCDIR($cf_1st_incdir)
2398
2399 fi
2400
2401 # Set definitions to allow ifdef'ing for ncurses.h
2402
2403 case $cf_cv_ncurses_header in
2404 (*ncurses.h)
2405         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2406         ;;
2407 esac
2408
2409 case $cf_cv_ncurses_header in
2410 (ncurses/curses.h|ncurses/ncurses.h)
2411         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2412         ;;
2413 (ncursesw/curses.h|ncursesw/ncurses.h)
2414         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2415         ;;
2416 esac
2417
2418 ])dnl
2419 dnl ---------------------------------------------------------------------------
2420 dnl CF_NCURSES_LIBS version: 17 updated: 2015/04/15 19:08:48
2421 dnl ---------------
2422 dnl Look for the ncurses library.  This is a little complicated on Linux,
2423 dnl because it may be linked with the gpm (general purpose mouse) library.
2424 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2425 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2426 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2427 dnl and the linker will record a dependency.
2428 dnl
2429 dnl The optional parameter gives the root name of the library, in case it is
2430 dnl not installed as the default curses library.  That is how the
2431 dnl wide-character version of ncurses is installed.
2432 AC_DEFUN([CF_NCURSES_LIBS],
2433 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2434
2435 cf_nculib_root=ifelse($1,,ncurses,$1)
2436         # This works, except for the special case where we find gpm, but
2437         # ncurses is in a nonstandard location via $LIBS, and we really want
2438         # to link gpm.
2439 cf_ncurses_LIBS=""
2440 cf_ncurses_SAVE="$LIBS"
2441 AC_CHECK_LIB(gpm,Gpm_Open,
2442         [AC_CHECK_LIB(gpm,initscr,
2443                 [LIBS="$cf_ncurses_SAVE"],
2444                 [cf_ncurses_LIBS="-lgpm"])])
2445
2446 case $host_os in
2447 (freebsd*)
2448         # This is only necessary if you are linking against an obsolete
2449         # version of ncurses (but it should do no harm, since it's static).
2450         if test "$cf_nculib_root" = ncurses ; then
2451                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2452         fi
2453         ;;
2454 esac
2455
2456 CF_ADD_LIBS($cf_ncurses_LIBS)
2457
2458 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2459 then
2460         CF_ADD_LIBS(-l$cf_nculib_root)
2461 else
2462         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2463                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2464                 [initscr()],
2465                 initscr)
2466 fi
2467
2468 if test -n "$cf_ncurses_LIBS" ; then
2469         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2470         cf_ncurses_SAVE="$LIBS"
2471         for p in $cf_ncurses_LIBS ; do
2472                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2473                 if test "$q" != "$LIBS" ; then
2474                         LIBS="$q"
2475                 fi
2476         done
2477         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2478                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2479                 [AC_MSG_RESULT(yes)],
2480                 [AC_MSG_RESULT(no)
2481                  LIBS="$cf_ncurses_SAVE"])
2482 fi
2483
2484 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2485 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2486 ])dnl
2487 dnl ---------------------------------------------------------------------------
2488 dnl CF_NCURSES_VERSION version: 14 updated: 2012/10/06 08:57:51
2489 dnl ------------------
2490 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2491 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2492 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2493 AC_DEFUN([CF_NCURSES_VERSION],
2494 [
2495 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2496 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2497         cf_cv_ncurses_version=no
2498         cf_tempfile=out$$
2499         rm -f $cf_tempfile
2500         AC_TRY_RUN([
2501 #include <${cf_cv_ncurses_header:-curses.h}>
2502 #include <stdio.h>
2503 int main()
2504 {
2505         FILE *fp = fopen("$cf_tempfile", "w");
2506 #ifdef NCURSES_VERSION
2507 # ifdef NCURSES_VERSION_PATCH
2508         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2509 # else
2510         fprintf(fp, "%s\n", NCURSES_VERSION);
2511 # endif
2512 #else
2513 # ifdef __NCURSES_H
2514         fprintf(fp, "old\n");
2515 # else
2516         make an error
2517 # endif
2518 #endif
2519         ${cf_cv_main_return:-return}(0);
2520 }],[
2521         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2522
2523         # This will not work if the preprocessor splits the line after the
2524         # Autoconf token.  The 'unproto' program does that.
2525         cat > conftest.$ac_ext <<EOF
2526 #include <${cf_cv_ncurses_header:-curses.h}>
2527 #undef Autoconf
2528 #ifdef NCURSES_VERSION
2529 Autoconf NCURSES_VERSION
2530 #else
2531 #ifdef __NCURSES_H
2532 Autoconf "old"
2533 #endif
2534 ;
2535 #endif
2536 EOF
2537         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2538         AC_TRY_EVAL(cf_try)
2539         if test -f conftest.out ; then
2540                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2541                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2542                 rm -f conftest.out
2543         fi
2544 ])
2545         rm -f $cf_tempfile
2546 ])
2547 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2548 ])dnl
2549 dnl ---------------------------------------------------------------------------
2550 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
2551 dnl -------------
2552 dnl Compute the object-directory name from the given model name
2553 AC_DEFUN([CF_OBJ_SUBDIR],
2554 [
2555         case $1 in
2556         (libtool) $2='obj_lo'  ;;
2557         (normal)  $2='objects' ;;
2558         (debug)   $2='obj_g' ;;
2559         (profile) $2='obj_p' ;;
2560         (shared)
2561                 case $cf_cv_system_name in
2562                 (cygwin|msys)
2563                         $2='objects' ;;
2564                 (*)
2565                         $2='obj_s' ;;
2566                 esac
2567         esac
2568 ])dnl
2569 dnl ---------------------------------------------------------------------------
2570 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
2571 dnl ----------
2572 dnl Provide a value for the $PATH and similar separator (or amend the value
2573 dnl as provided in autoconf 2.5x).
2574 AC_DEFUN([CF_PATHSEP],
2575 [
2576         AC_MSG_CHECKING(for PATH separator)
2577         case $cf_cv_system_name in
2578         (os2*)  PATH_SEPARATOR=';'  ;;
2579         (*)     ${PATH_SEPARATOR:=':'}  ;;
2580         esac
2581 ifelse([$1],,,[$1=$PATH_SEPARATOR])
2582         AC_SUBST(PATH_SEPARATOR)
2583         AC_MSG_RESULT($PATH_SEPARATOR)
2584 ])dnl
2585 dnl ---------------------------------------------------------------------------
2586 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
2587 dnl --------------
2588 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2589 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2590 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2591 dnl delayed evaluation of those symbols.
2592 AC_DEFUN([CF_PATH_SYNTAX],[
2593 if test "x$prefix" != xNONE; then
2594         cf_path_syntax="$prefix"
2595 else
2596         cf_path_syntax="$ac_default_prefix"
2597 fi
2598
2599 case ".[$]$1" in
2600 (.\[$]\(*\)*|.\'*\'*)
2601         ;;
2602 (..|./*|.\\*)
2603         ;;
2604 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
2605         ;;
2606 (.\[$]{*prefix}*|.\[$]{*dir}*)
2607         eval $1="[$]$1"
2608         case ".[$]$1" in
2609         (.NONE/*)
2610                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2611                 ;;
2612         esac
2613         ;;
2614 (.no|.NONE/*)
2615         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2616         ;;
2617 (*)
2618         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2619         ;;
2620 esac
2621 ])dnl
2622 dnl ---------------------------------------------------------------------------
2623 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
2624 dnl -------------
2625 dnl Check for the package-config program, unless disabled by command-line.
2626 AC_DEFUN([CF_PKG_CONFIG],
2627 [
2628 AC_MSG_CHECKING(if you want to use pkg-config)
2629 AC_ARG_WITH(pkg-config,
2630         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2631         [cf_pkg_config=$withval],
2632         [cf_pkg_config=yes])
2633 AC_MSG_RESULT($cf_pkg_config)
2634
2635 case $cf_pkg_config in
2636 (no)
2637         PKG_CONFIG=none
2638         ;;
2639 (yes)
2640         CF_ACVERSION_CHECK(2.52,
2641                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2642                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2643         ;;
2644 (*)
2645         PKG_CONFIG=$withval
2646         ;;
2647 esac
2648
2649 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2650 if test "$PKG_CONFIG" != none ; then
2651         CF_PATH_SYNTAX(PKG_CONFIG)
2652 elif test "x$cf_pkg_config" != xno ; then
2653         AC_MSG_WARN(pkg-config is not installed)
2654 fi
2655
2656 AC_SUBST(PKG_CONFIG)
2657 ])dnl
2658 dnl ---------------------------------------------------------------------------
2659 dnl CF_POSIX_C_SOURCE version: 9 updated: 2015/04/12 15:39:00
2660 dnl -----------------
2661 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2662 dnl
2663 dnl     POSIX.1-1990                            _POSIX_SOURCE
2664 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2665 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2666 dnl             Bindings Option
2667 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2668 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2669 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2670 dnl
2671 dnl Parameters:
2672 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2673 AC_DEFUN([CF_POSIX_C_SOURCE],
2674 [
2675 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2676
2677 cf_save_CFLAGS="$CFLAGS"
2678 cf_save_CPPFLAGS="$CPPFLAGS"
2679
2680 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2681 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2682
2683 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2684         CF_MSG_LOG(if the symbol is already defined go no further)
2685         AC_TRY_COMPILE([#include <sys/types.h>],[
2686 #ifndef _POSIX_C_SOURCE
2687 make an error
2688 #endif],
2689         [cf_cv_posix_c_source=no],
2690         [cf_want_posix_source=no
2691          case .$cf_POSIX_C_SOURCE in
2692          (.[[12]]??*)
2693                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2694                 ;;
2695          (.2)
2696                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2697                 cf_want_posix_source=yes
2698                 ;;
2699          (.*)
2700                 cf_want_posix_source=yes
2701                 ;;
2702          esac
2703          if test "$cf_want_posix_source" = yes ; then
2704                 AC_TRY_COMPILE([#include <sys/types.h>],[
2705 #ifdef _POSIX_SOURCE
2706 make an error
2707 #endif],[],
2708                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2709          fi
2710          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2711          CFLAGS="$cf_trim_CFLAGS"
2712          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2713          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2714          AC_TRY_COMPILE([#include <sys/types.h>],[
2715 #ifndef _POSIX_C_SOURCE
2716 make an error
2717 #endif],,
2718          [cf_cv_posix_c_source=no])
2719          CFLAGS="$cf_save_CFLAGS"
2720          CPPFLAGS="$cf_save_CPPFLAGS"
2721         ])
2722 ])
2723
2724 if test "$cf_cv_posix_c_source" != no ; then
2725         CFLAGS="$cf_trim_CFLAGS"
2726         CPPFLAGS="$cf_trim_CPPFLAGS"
2727         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2728 fi
2729
2730 ])dnl
2731 dnl ---------------------------------------------------------------------------
2732 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
2733 dnl ----------
2734 dnl Check for archiver "ar".
2735 AC_DEFUN([CF_PROG_AR],[
2736 AC_CHECK_TOOL(AR, ar, ar)
2737 ])
2738 dnl ---------------------------------------------------------------------------
2739 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
2740 dnl -----------
2741 dnl Check for awk, ensure that the check found something.
2742 AC_DEFUN([CF_PROG_AWK],
2743 [
2744 AC_PROG_AWK
2745 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
2746 ])dnl
2747 dnl ---------------------------------------------------------------------------
2748 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
2749 dnl ----------
2750 dnl standard check for CC, plus followup sanity checks
2751 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
2752 AC_DEFUN([CF_PROG_CC],[
2753 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
2754 CF_GCC_VERSION
2755 CF_ACVERSION_CHECK(2.52,
2756         [AC_PROG_CC_STDC],
2757         [CF_ANSI_CC_REQD])
2758 CF_CC_ENV_FLAGS
2759 ])dnl
2760 dnl ---------------------------------------------------------------------------
2761 dnl CF_PROG_CC_C_O version: 4 updated: 2016/05/21 18:08:09
2762 dnl --------------
2763 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
2764 dnl the output file can be renamed, and allows for a shell variable that can
2765 dnl be used later.  The parameter is either CC or CXX.  The result is the
2766 dnl cache variable:
2767 dnl     $cf_cv_prog_CC_c_o
2768 dnl     $cf_cv_prog_CXX_c_o
2769 dnl
2770 dnl $1 = compiler
2771 dnl $2 = compiler options, if any
2772 AC_DEFUN([CF_PROG_CC_C_O],
2773 [AC_REQUIRE([AC_PROG_CC])dnl
2774 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
2775 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
2776 [
2777 cat > conftest.$ac_ext <<CF_EOF
2778 int main()
2779 {
2780         ${cf_cv_main_return:-return}(0);
2781 }
2782 CF_EOF
2783 # We do the test twice because some compilers refuse to overwrite an
2784 # existing .o file with -o, though they will create one.
2785 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
2786 if AC_TRY_EVAL(ac_try) &&
2787   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
2788 then
2789   eval cf_cv_prog_$1_c_o=yes
2790 else
2791   eval cf_cv_prog_$1_c_o=no
2792 fi
2793 rm -rf conftest*
2794 ])dnl
2795 if test $cf_cv_prog_$1_c_o = yes; then
2796   AC_MSG_RESULT([yes])
2797 else
2798   AC_MSG_RESULT([no])
2799 fi
2800 ])dnl
2801 dnl ---------------------------------------------------------------------------
2802 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
2803 dnl -------------
2804 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
2805 dnl This macro adds a check to ensure the script found something.
2806 AC_DEFUN([CF_PROG_EGREP],
2807 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
2808         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
2809                 then ac_cv_prog_egrep='grep -E'
2810                 else ac_cv_prog_egrep='egrep'
2811         fi])
2812         EGREP=$ac_cv_prog_egrep
2813         AC_SUBST([EGREP])
2814         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
2815 ])dnl
2816 dnl ---------------------------------------------------------------------------
2817 dnl CF_PROG_EXT version: 13 updated: 2015/04/18 09:03:58
2818 dnl -----------
2819 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
2820 AC_DEFUN([CF_PROG_EXT],
2821 [
2822 AC_REQUIRE([CF_CHECK_CACHE])
2823 case $cf_cv_system_name in
2824 (os2*)
2825         CFLAGS="$CFLAGS -Zmt"
2826         CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
2827         CXXFLAGS="$CXXFLAGS -Zmt"
2828         # autoconf's macro sets -Zexe and suffix both, which conflict:w
2829         LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
2830         ac_cv_exeext=.exe
2831         ;;
2832 esac
2833
2834 AC_EXEEXT
2835 AC_OBJEXT
2836
2837 PROG_EXT="$EXEEXT"
2838 AC_SUBST(PROG_EXT)
2839 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
2840 ])dnl
2841 dnl ---------------------------------------------------------------------------
2842 dnl CF_PROG_GNAT version: 3 updated: 2015/04/18 08:56:57
2843 dnl ------------
2844 dnl Check for gnatmake, ensure that it is complete.
2845 AC_DEFUN([CF_PROG_GNAT],[
2846 cf_ada_make=gnatmake
2847 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
2848 if test "$ac_cv_prog_gnat_exists" = no; then
2849         cf_ada_make=
2850         cf_cv_prog_gnat_correct=no
2851 else
2852         CF_GNAT_VERSION
2853         AC_CHECK_PROG(M4_exists, m4, yes, no)
2854         if test "$ac_cv_prog_M4_exists" = no; then
2855                 cf_cv_prog_gnat_correct=no
2856                 echo Ada95 binding required program m4 not found. Ada95 binding disabled.
2857         fi
2858         if test "$cf_cv_prog_gnat_correct" = yes; then
2859                 AC_MSG_CHECKING(if GNAT works)
2860                 CF_GNAT_TRY_RUN([procedure conftest;],
2861 [with Text_IO;
2862 with GNAT.OS_Lib;
2863 procedure conftest is
2864 begin
2865    Text_IO.Put ("Hello World");
2866    Text_IO.New_Line;
2867    GNAT.OS_Lib.OS_Exit (0);
2868 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
2869                 AC_MSG_RESULT($cf_cv_prog_gnat_correct)
2870         fi
2871 fi
2872
2873 AC_SUBST(cf_ada_make)
2874 ])dnl
2875 dnl ---------------------------------------------------------------------------
2876 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
2877 dnl ------------
2878 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
2879 dnl option if it is supported.
2880 AC_DEFUN([CF_PROG_LN_S],[
2881 AC_PROG_LN_S
2882 AC_MSG_CHECKING(if $LN_S -f options work)
2883
2884 rm -f conf$$.src conf$$dst
2885 echo >conf$$.dst
2886 echo first >conf$$.src
2887 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
2888         cf_prog_ln_sf=yes
2889 else
2890         cf_prog_ln_sf=no
2891 fi
2892 rm -f conf$$.dst conf$$src
2893 AC_MSG_RESULT($cf_prog_ln_sf)
2894
2895 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
2896 ])dnl
2897 dnl ---------------------------------------------------------------------------
2898 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2899 dnl ----------------
2900 dnl Remove all -U and -D options that refer to the given symbol from a list
2901 dnl of C compiler options.  This works around the problem that not all
2902 dnl compilers process -U and -D options from left-to-right, so a -U option
2903 dnl cannot be used to cancel the effect of a preceding -D option.
2904 dnl
2905 dnl $1 = target (which could be the same as the source variable)
2906 dnl $2 = source (including '$')
2907 dnl $3 = symbol to remove
2908 define([CF_REMOVE_DEFINE],
2909 [
2910 $1=`echo "$2" | \
2911         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2912                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2913 ])dnl
2914 dnl ---------------------------------------------------------------------------
2915 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
2916 dnl -------------
2917 dnl Remove the given library from the symbol
2918 dnl
2919 dnl $1 = target (which could be the same as the source variable)
2920 dnl $2 = source (including '$')
2921 dnl $3 = library to remove
2922 define([CF_REMOVE_LIB],
2923 [
2924 # remove $3 library from $2
2925 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
2926 ])dnl
2927 dnl ---------------------------------------------------------------------------
2928 dnl CF_SHARED_OPTS version: 89 updated: 2015/08/15 18:38:59
2929 dnl --------------
2930 dnl --------------
2931 dnl Attempt to determine the appropriate CC/LD options for creating a shared
2932 dnl library.
2933 dnl
2934 dnl Notes:
2935 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
2936 dnl the build-tree, i.e., by making use of the libraries that are compiled in
2937 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
2938 dnl shared library since that can lead to unexpected results at runtime.
2939 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
2940 dnl libraries are compiled in ../../lib
2941 dnl
2942 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
2943 dnl to install symbolic links to the rel/abi versions of shared libraries.
2944 dnl
2945 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
2946 dnl version when making symbolic links.
2947 dnl
2948 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
2949 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
2950 dnl (ex: libncurses.so.<ver>).
2951 dnl
2952 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
2953 AC_DEFUN([CF_SHARED_OPTS],
2954 [
2955         AC_REQUIRE([CF_LD_RPATH_OPT])
2956         RM_SHARED_OPTS=
2957         LOCAL_LDFLAGS=
2958         LOCAL_LDFLAGS2=
2959         LD_SHARED_OPTS=
2960         INSTALL_LIB="-m 644"
2961         : ${rel_builddir:=.}
2962
2963         shlibdir=$libdir
2964         AC_SUBST(shlibdir)
2965
2966         MAKE_DLLS="#"
2967         AC_SUBST(MAKE_DLLS)
2968
2969         cf_cv_do_symlinks=no
2970         cf_ld_rpath_opt=
2971         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
2972
2973         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
2974         AC_ARG_WITH(shlib-version,
2975         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
2976         [test -z "$withval" && withval=auto
2977         case $withval in
2978         (yes)
2979                 cf_cv_shlib_version=auto
2980                 ;;
2981         (rel|abi|auto)
2982                 cf_cv_shlib_version=$withval
2983                 ;;
2984         (*)
2985                 AC_MSG_RESULT($withval)
2986                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
2987                 ;;
2988         esac
2989         ],[cf_cv_shlib_version=auto])
2990         AC_MSG_RESULT($cf_cv_shlib_version)
2991
2992         cf_cv_rm_so_locs=no
2993         cf_try_cflags=
2994
2995         # Some less-capable ports of gcc support only -fpic
2996         CC_SHARED_OPTS=
2997         if test "$GCC" = yes
2998         then
2999                 AC_MSG_CHECKING(which $CC option to use)
3000                 cf_save_CFLAGS="$CFLAGS"
3001                 for CC_SHARED_OPTS in -fPIC -fpic ''
3002                 do
3003                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
3004                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
3005                 done
3006                 AC_MSG_RESULT($CC_SHARED_OPTS)
3007                 CFLAGS="$cf_save_CFLAGS"
3008         fi
3009
3010         cf_cv_shlib_version_infix=no
3011
3012         case $cf_cv_system_name in
3013         (aix4.[3-9]*|aix[[5-7]]*)
3014                 if test "$GCC" = yes; then
3015                         CC_SHARED_OPTS='-Wl,-brtl'
3016                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3017                 else
3018                         CC_SHARED_OPTS='-brtl'
3019                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
3020                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3021                 fi
3022                 ;;
3023         (beos*)
3024                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
3025                 ;;
3026         (cygwin*)
3027                 CC_SHARED_OPTS=
3028                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3029                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3030                 cf_cv_shlib_version=cygdll
3031                 cf_cv_shlib_version_infix=cygdll
3032                 shlibdir=$bindir
3033                 MAKE_DLLS=
3034                 cat >mk_shared_lib.sh <<-CF_EOF
3035                 #!$SHELL
3036                 SHARED_LIB=\[$]1
3037                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3038                 shift
3039                 cat <<-EOF
3040                 Linking shared library
3041                 ** SHARED_LIB \[$]SHARED_LIB
3042                 ** IMPORT_LIB \[$]IMPORT_LIB
3043 EOF
3044                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3045 CF_EOF
3046                 chmod +x mk_shared_lib.sh
3047                 ;;
3048         (msys*)
3049                 CC_SHARED_OPTS=
3050                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3051                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3052                 cf_cv_shlib_version=msysdll
3053                 cf_cv_shlib_version_infix=msysdll
3054                 shlibdir=$bindir
3055                 MAKE_DLLS=
3056                 cat >mk_shared_lib.sh <<-CF_EOF
3057                 #!$SHELL
3058                 SHARED_LIB=\[$]1
3059                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3060                 shift
3061                 cat <<-EOF
3062                 Linking shared library
3063                 ** SHARED_LIB \[$]SHARED_LIB
3064                 ** IMPORT_LIB \[$]IMPORT_LIB
3065 EOF
3066                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3067 CF_EOF
3068                 chmod +x mk_shared_lib.sh
3069                 ;;
3070         (darwin*)
3071                 cf_try_cflags="no-cpp-precomp"
3072                 CC_SHARED_OPTS="-dynamic"
3073                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
3074                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
3075                 cf_cv_shlib_version_infix=yes
3076                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
3077                         cf_save_LDFLAGS=$LDFLAGS
3078                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3079                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
3080                                 LDFLAGS=$cf_save_LDFLAGS])
3081                 if test $cf_cv_ldflags_search_paths_first = yes; then
3082                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3083                 fi
3084                 ;;
3085         (hpux[[7-8]]*)
3086                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
3087                 if test "$GCC" != yes; then
3088                         CC_SHARED_OPTS='+Z'
3089                 fi
3090                 MK_SHARED_LIB='${LD} -b -o $[@]'
3091                 INSTALL_LIB="-m 555"
3092                 ;;
3093         (hpux*)
3094                 # (tested with gcc 2.7.2 -- I don't have c89)
3095                 if test "$GCC" = yes; then
3096                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
3097                 else
3098                         CC_SHARED_OPTS='+Z'
3099                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
3100                 fi
3101                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
3102                 # HP-UX shared libraries must be executable, and should be
3103                 # readonly to exploit a quirk in the memory manager.
3104                 INSTALL_LIB="-m 555"
3105                 ;;
3106         (interix*)
3107                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3108                 if test "$cf_cv_shlib_version" = rel; then
3109                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
3110                 else
3111                         cf_shared_soname='`basename $@`'
3112                 fi
3113                 CC_SHARED_OPTS=
3114                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
3115                 ;;
3116         (irix*)
3117                 if test "$cf_cv_enable_rpath" = yes ; then
3118                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3119                 fi
3120                 # tested with IRIX 5.2 and 'cc'.
3121                 if test "$GCC" != yes; then
3122                         CC_SHARED_OPTS='-KPIC'
3123                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
3124                 else
3125                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
3126                 fi
3127                 cf_cv_rm_so_locs=yes
3128                 ;;
3129         (linux*|gnu*|k*bsd*-gnu)
3130                 if test "$DFT_LWR_MODEL" = "shared" ; then
3131                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3132                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3133                 fi
3134                 if test "$cf_cv_enable_rpath" = yes ; then
3135                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3136                 fi
3137                 CF_SHARED_SONAME
3138                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3139                 ;;
3140         (mingw*)
3141                 cf_cv_shlib_version=mingw
3142                 cf_cv_shlib_version_infix=mingw
3143                 shlibdir=$bindir
3144                 MAKE_DLLS=
3145                 if test "$DFT_LWR_MODEL" = "shared" ; then
3146                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
3147                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3148                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
3149                 fi
3150                 CC_SHARED_OPTS=
3151                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3152                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3153                 cat >mk_shared_lib.sh <<-CF_EOF
3154                 #!$SHELL
3155                 SHARED_LIB=\[$]1
3156                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3157                 shift
3158                 cat <<-EOF
3159                 Linking shared library
3160                 ** SHARED_LIB \[$]SHARED_LIB
3161                 ** IMPORT_LIB \[$]IMPORT_LIB
3162 EOF
3163                 exec \[$]* -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3164 CF_EOF
3165                 chmod +x mk_shared_lib.sh
3166                 ;;
3167         (openbsd[[2-9]].*|mirbsd*)
3168                 if test "$DFT_LWR_MODEL" = "shared" ; then
3169                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3170                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3171                 fi
3172                 if test "$cf_cv_enable_rpath" = yes ; then
3173                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3174                 fi
3175                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3176                 CF_SHARED_SONAME
3177                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3178                 ;;
3179         (nto-qnx*|openbsd*|freebsd[[12]].*)
3180                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3181                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
3182                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3183                 ;;
3184         (dragonfly*|freebsd*)
3185                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3186                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3187                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3188                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
3189                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3190                 fi
3191                 CF_SHARED_SONAME
3192                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3193                 ;;
3194         (netbsd*)
3195                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3196                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3197                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3198                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3199                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3200                         if test "$cf_cv_shlib_version" = auto; then
3201                         if test -f /usr/libexec/ld.elf_so; then
3202                                 cf_cv_shlib_version=abi
3203                         else
3204                                 cf_cv_shlib_version=rel
3205                         fi
3206                         fi
3207                         CF_SHARED_SONAME
3208                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
3209                 else
3210                         MK_SHARED_LIB='${CC} -Wl,-shared -Wl,-Bshareable -o $[@]'
3211                 fi
3212                 ;;
3213         (osf*|mls+*)
3214                 # tested with OSF/1 V3.2 and 'cc'
3215                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
3216                 # link with shared libs).
3217                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
3218                 case $host_os in
3219                 (osf4*)
3220                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
3221                         ;;
3222                 esac
3223                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
3224                 if test "$DFT_LWR_MODEL" = "shared" ; then
3225                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3226                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3227                 fi
3228                 cf_cv_rm_so_locs=yes
3229                 ;;
3230         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
3231                 # tested with osr5.0.5
3232                 if test "$GCC" != yes; then
3233                         CC_SHARED_OPTS='-belf -KPIC'
3234                 fi
3235                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
3236                 if test "$cf_cv_enable_rpath" = yes ; then
3237                         # only way is to set LD_RUN_PATH but no switch for it
3238                         RUN_PATH=$libdir
3239                 fi
3240                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3241                 LINK_PROGS='LD_RUN_PATH=${libdir}'
3242                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
3243                 ;;
3244         (sunos4*)
3245                 # tested with SunOS 4.1.1 and gcc 2.7.0
3246                 if test "$GCC" != yes; then
3247                         CC_SHARED_OPTS='-KPIC'
3248                 fi
3249                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
3250                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3251                 ;;
3252         (solaris2*)
3253                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
3254                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
3255                 if test "$DFT_LWR_MODEL" = "shared" ; then
3256                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
3257                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3258                 fi
3259                 if test "$cf_cv_enable_rpath" = yes ; then
3260                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
3261                 fi
3262                 CF_SHARED_SONAME
3263                 if test "$GCC" != yes; then
3264                         cf_save_CFLAGS="$CFLAGS"
3265                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
3266                         do
3267                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
3268                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
3269                         done
3270                         CFLAGS="$cf_save_CFLAGS"
3271                         CC_SHARED_OPTS=$cf_shared_opts
3272                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3273                 else
3274                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3275                 fi
3276                 ;;
3277         (sysv5uw7*|unix_sv*)
3278                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
3279                 if test "$GCC" != yes; then
3280                         CC_SHARED_OPTS='-KPIC'
3281                 fi
3282                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
3283                 ;;
3284         (*)
3285                 CC_SHARED_OPTS='unknown'
3286                 MK_SHARED_LIB='echo unknown'
3287                 ;;
3288         esac
3289
3290         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
3291         case "$cf_cv_shlib_version" in
3292         (rel|abi)
3293                 case "$MK_SHARED_LIB" in
3294                 (*'-o $[@]')
3295                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
3296                         ;;
3297                 (*)
3298                         AC_MSG_WARN(ignored --with-shlib-version)
3299                         ;;
3300                 esac
3301                 ;;
3302         esac
3303
3304         if test -n "$cf_try_cflags"
3305         then
3306 cat > conftest.$ac_ext <<EOF
3307 #line __oline__ "${as_me:-configure}"
3308 #include <stdio.h>
3309 int main(int argc, char *argv[[]])
3310 {
3311         printf("hello\n");
3312         return (argv[[argc-1]] == 0) ;
3313 }
3314 EOF
3315                 cf_save_CFLAGS="$CFLAGS"
3316                 for cf_opt in $cf_try_cflags
3317                 do
3318                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
3319                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
3320                         if AC_TRY_EVAL(ac_compile); then
3321                                 AC_MSG_RESULT(yes)
3322                                 cf_save_CFLAGS="$CFLAGS"
3323                         else
3324                                 AC_MSG_RESULT(no)
3325                         fi
3326                 done
3327                 CFLAGS="$cf_save_CFLAGS"
3328         fi
3329
3330
3331         # RPATH_LIST is a colon-separated list of directories
3332         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
3333         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
3334
3335         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
3336
3337         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
3338         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
3339
3340         AC_SUBST(CC_SHARED_OPTS)
3341         AC_SUBST(LD_RPATH_OPT)
3342         AC_SUBST(LD_SHARED_OPTS)
3343         AC_SUBST(MK_SHARED_LIB)
3344         AC_SUBST(RM_SHARED_OPTS)
3345
3346         AC_SUBST(LINK_PROGS)
3347         AC_SUBST(LINK_TESTS)
3348
3349         AC_SUBST(EXTRA_LDFLAGS)
3350         AC_SUBST(LOCAL_LDFLAGS)
3351         AC_SUBST(LOCAL_LDFLAGS2)
3352
3353         AC_SUBST(INSTALL_LIB)
3354         AC_SUBST(RPATH_LIST)
3355 ])dnl
3356 dnl ---------------------------------------------------------------------------
3357 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
3358 dnl ----------------
3359 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
3360 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
3361 dnl option.
3362 dnl
3363 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
3364 dnl If missing, use "rel".
3365 define([CF_SHARED_SONAME],
3366 [
3367         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
3368         if test "$cf_cv_shlib_version" = rel; then
3369                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3370         else
3371                 cf_cv_shared_soname='`basename $[@]`'
3372         fi
3373 ])
3374 dnl ---------------------------------------------------------------------------
3375 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
3376 dnl --------------
3377 dnl     Remove "-g" option from the compiler options
3378 AC_DEFUN([CF_STRIP_G_OPT],
3379 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
3380 dnl ---------------------------------------------------------------------------
3381 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
3382 dnl --------------
3383 dnl Construct a search-list for a nonstandard header/lib-file
3384 dnl     $1 = the variable to return as result
3385 dnl     $2 = the package name
3386 dnl     $3 = the subdirectory, e.g., bin, include or lib
3387 AC_DEFUN([CF_SUBDIR_PATH],
3388 [
3389 $1=
3390
3391 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3392
3393 for cf_subdir_prefix in \
3394         /usr \
3395         /usr/local \
3396         /usr/pkg \
3397         /opt \
3398         /opt/local \
3399         [$]HOME
3400 do
3401         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
3402 done
3403 ])dnl
3404 dnl ---------------------------------------------------------------------------
3405 dnl CF_TERM_HEADER version: 4 updated: 2015/04/15 19:08:48
3406 dnl --------------
3407 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3408 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3409 dnl but some packagers change this, breaking various applications.
3410 AC_DEFUN([CF_TERM_HEADER],[
3411 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3412 case ${cf_cv_ncurses_header} in
3413 (*/ncurses.h|*/ncursesw.h)
3414         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3415         ;;
3416 (*)
3417         cf_term_header=term.h
3418         ;;
3419 esac
3420
3421 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3422 do
3423 AC_TRY_COMPILE([#include <stdio.h>
3424 #include <${cf_cv_ncurses_header:-curses.h}>
3425 #include <$cf_test>
3426 ],[int x = auto_left_margin],[
3427         cf_cv_term_header="$cf_test"],[
3428         cf_cv_term_header=unknown
3429         ])
3430         test "$cf_cv_term_header" != unknown && break
3431 done
3432 ])
3433
3434 # Set definitions to allow ifdef'ing to accommodate subdirectories
3435
3436 case $cf_cv_term_header in
3437 (*term.h)
3438         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
3439         ;;
3440 esac
3441
3442 case $cf_cv_term_header in
3443 (ncurses/term.h)
3444         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
3445         ;;
3446 (ncursesw/term.h)
3447         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
3448         ;;
3449 esac
3450 ])dnl
3451 dnl ---------------------------------------------------------------------------
3452 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
3453 dnl ---------------
3454 dnl Define a top_builddir symbol, for applications that need an absolute path.
3455 AC_DEFUN([CF_TOP_BUILDDIR],
3456 [
3457 top_builddir=ifelse($1,,`pwd`,$1)
3458 AC_SUBST(top_builddir)
3459 ])dnl
3460 dnl ---------------------------------------------------------------------------
3461 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
3462 dnl -------------------
3463 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
3464 dnl can define it successfully.
3465 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
3466 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3467         AC_TRY_COMPILE([
3468 #include <stdlib.h>
3469 #include <string.h>
3470 #include <sys/types.h>
3471 ],[
3472 #ifndef _XOPEN_SOURCE
3473 make an error
3474 #endif],
3475         [cf_cv_xopen_source=no],
3476         [cf_save="$CPPFLAGS"
3477          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3478          AC_TRY_COMPILE([
3479 #include <stdlib.h>
3480 #include <string.h>
3481 #include <sys/types.h>
3482 ],[
3483 #ifdef _XOPEN_SOURCE
3484 make an error
3485 #endif],
3486         [cf_cv_xopen_source=no],
3487         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3488         CPPFLAGS="$cf_save"
3489         ])
3490 ])
3491
3492 if test "$cf_cv_xopen_source" != no ; then
3493         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3494         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3495         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3496         CF_ADD_CFLAGS($cf_temp_xopen_source)
3497 fi
3498 ])
3499 dnl ---------------------------------------------------------------------------
3500 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3501 dnl --------
3502 dnl Make an uppercase version of a variable
3503 dnl $1=uppercase($2)
3504 AC_DEFUN([CF_UPPER],
3505 [
3506 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3507 ])dnl
3508 dnl ---------------------------------------------------------------------------
3509 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
3510 dnl -----------
3511 dnl Check for multibyte support, and if not found, utf8 compatibility library
3512 AC_DEFUN([CF_UTF8_LIB],
3513 [
3514 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3515         cf_save_LIBS="$LIBS"
3516         AC_TRY_LINK([
3517 #include <stdlib.h>],[putwc(0,0);],
3518         [cf_cv_utf8_lib=yes],
3519         [CF_FIND_LINKAGE([
3520 #include <libutf8.h>],[putwc(0,0);],utf8,
3521                 [cf_cv_utf8_lib=add-on],
3522                 [cf_cv_utf8_lib=no])
3523 ])])
3524
3525 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3526 # ncurses/ncursesw:
3527 if test "$cf_cv_utf8_lib" = "add-on" ; then
3528         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
3529         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3530         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3531         CF_ADD_LIBS($cf_cv_library_file_utf8)
3532 fi
3533 ])dnl
3534 dnl ---------------------------------------------------------------------------
3535 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3536 dnl ----------
3537 dnl Use AC_VERBOSE w/o the warnings
3538 AC_DEFUN([CF_VERBOSE],
3539 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3540 CF_MSG_LOG([$1])
3541 ])dnl
3542 dnl ---------------------------------------------------------------------------
3543 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
3544 dnl ---------------
3545 dnl Check for compiler-support for weak symbols.
3546 dnl This works with "recent" gcc.
3547 AC_DEFUN([CF_WEAK_SYMBOLS],[
3548 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
3549
3550 AC_TRY_COMPILE([
3551 #include <stdio.h>],
3552 [
3553 #if defined(__GNUC__)
3554 #  if defined __USE_ISOC99
3555 #    define _cat_pragma(exp)    _Pragma(#exp)
3556 #    define _weak_pragma(exp)   _cat_pragma(weak name)
3557 #  else
3558 #    define _weak_pragma(exp)
3559 #  endif
3560 #  define _declare(name)        __extension__ extern __typeof__(name) name
3561 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
3562 #endif
3563
3564 weak_symbol(fopen);
3565 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
3566 ])
3567 ])dnl
3568 dnl ---------------------------------------------------------------------------
3569 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
3570 dnl --------------------
3571 dnl Command-line option to specify the Ada95 compiler.
3572 AC_DEFUN([CF_WITH_ADA_COMPILER],[
3573 AC_MSG_CHECKING(for ada-compiler)
3574 AC_ARG_WITH(ada-compiler,
3575         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
3576         [cf_ada_compiler=$withval],
3577         [cf_ada_compiler=gnatmake])
3578 AC_SUBST(cf_ada_compiler)
3579 AC_MSG_RESULT($cf_ada_compiler)
3580 ])dnl
3581 dnl ---------------------------------------------------------------------------
3582 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
3583 dnl -------------------
3584 dnl Command-line option to specify where Ada includes will install.
3585 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
3586 AC_MSG_CHECKING(for ada-include)
3587 CF_WITH_PATH(ada-include,
3588    [  --with-ada-include=DIR  Ada includes are in DIR],
3589    ADA_INCLUDE,
3590    PREFIX/share/ada/adainclude,
3591    [$]prefix/share/ada/adainclude)
3592 AC_SUBST(ADA_INCLUDE)
3593 AC_MSG_RESULT($ADA_INCLUDE)
3594 ])dnl
3595 dnl ---------------------------------------------------------------------------
3596 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
3597 dnl -------------------
3598 dnl Command-line option to specify where Ada objects will install.
3599 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
3600 AC_MSG_CHECKING(for ada-objects)
3601 CF_WITH_PATH(ada-objects,
3602    [  --with-ada-objects=DIR  Ada objects are in DIR],
3603    ADA_OBJECTS,
3604    PREFIX/lib/ada/adalib,
3605    [$]prefix/lib/ada/adalib)
3606 AC_SUBST(ADA_OBJECTS)
3607 AC_MSG_RESULT($ADA_OBJECTS)
3608 ])dnl
3609 dnl ---------------------------------------------------------------------------
3610 dnl CF_WITH_ADA_SHAREDLIB version: 4 updated: 2014/05/31 21:08:37
3611 dnl ---------------------
3612 dnl Command-line option to specify if an Ada95 shared-library should be built,
3613 dnl and optionally what its soname should be.
3614 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
3615 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
3616 AC_ARG_WITH(ada-sharedlib,
3617         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
3618         [with_ada_sharedlib=$withval],
3619         [with_ada_sharedlib=no])
3620 AC_MSG_RESULT($with_ada_sharedlib)
3621
3622 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
3623 MAKE_ADA_SHAREDLIB="#"
3624
3625 if test "x$with_ada_sharedlib" != xno
3626 then
3627         MAKE_ADA_SHAREDLIB=
3628         if test "x$with_ada_sharedlib" != xyes
3629         then
3630                 ADA_SHAREDLIB="$with_ada_sharedlib"
3631         fi
3632 fi
3633
3634 AC_SUBST(ADA_SHAREDLIB)
3635 AC_SUBST(MAKE_ADA_SHAREDLIB)
3636 ])dnl
3637 dnl ---------------------------------------------------------------------------
3638 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3639 dnl ------------------
3640 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3641 dnl libraries.
3642 AC_DEFUN([CF_WITH_CURSES_DIR],[
3643
3644 AC_MSG_CHECKING(for specific curses-directory)
3645 AC_ARG_WITH(curses-dir,
3646         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3647         [cf_cv_curses_dir=$withval],
3648         [cf_cv_curses_dir=no])
3649 AC_MSG_RESULT($cf_cv_curses_dir)
3650
3651 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3652 then
3653         CF_PATH_SYNTAX(withval)
3654         if test -d "$cf_cv_curses_dir"
3655         then
3656                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3657                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3658         fi
3659 fi
3660 ])dnl
3661 dnl ---------------------------------------------------------------------------
3662 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
3663 dnl ------------------
3664 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
3665 dnl "lib" prefix, e.g., because it used the dll naming convention.
3666 dnl
3667 dnl $1 = variable to set
3668 AC_DEFUN([CF_WITH_LIB_PREFIX],
3669 [
3670 AC_MSG_CHECKING(if you want to have a library-prefix)
3671 AC_ARG_WITH(lib-prefix,
3672         [  --with-lib-prefix       override library-prefix],
3673         [with_lib_prefix=$withval],
3674         [with_lib_prefix=auto])
3675 AC_MSG_RESULT($with_lib_prefix)
3676
3677 if test $with_lib_prefix = auto
3678 then
3679         CF_LIB_PREFIX($1)
3680 elif test $with_lib_prefix = no
3681 then
3682         LIB_PREFIX=
3683 else
3684         LIB_PREFIX=$with_lib_prefix
3685 fi
3686 ])dnl
3687 dnl ---------------------------------------------------------------------------
3688 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
3689 dnl ------------
3690 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
3691 dnl defaulting to yes/no.
3692 dnl
3693 dnl $1 = option name
3694 dnl $2 = help-text
3695 dnl $3 = environment variable to set
3696 dnl $4 = default value, shown in the help-message, must be a constant
3697 dnl $5 = default value, if it's an expression & cannot be in the help-message
3698 dnl
3699 AC_DEFUN([CF_WITH_PATH],
3700 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
3701 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
3702 if ifelse([$5],,true,[test -n "$5"]) ; then
3703 CF_PATH_SYNTAX(withval)
3704 fi
3705 eval $3="$withval"
3706 AC_SUBST($3)dnl
3707 ])dnl
3708 dnl ---------------------------------------------------------------------------
3709 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
3710 dnl -------------------------
3711 dnl Allow the choice of the pkg-config library directory to be overridden.
3712 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
3713
3714 case $PKG_CONFIG in
3715 (no|none|yes)
3716         AC_MSG_CHECKING(for pkg-config library directory)
3717         ;;
3718 (*)
3719         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
3720         ;;
3721 esac
3722
3723 PKG_CONFIG_LIBDIR=no
3724 AC_ARG_WITH(pkg-config-libdir,
3725         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
3726         [PKG_CONFIG_LIBDIR=$withval],
3727         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
3728
3729 case x$PKG_CONFIG_LIBDIR in
3730 (x/*)
3731         ;;
3732 (xyes)
3733         # Look for the library directory using the same prefix as the executable
3734         if test "x$PKG_CONFIG" = xnone
3735         then
3736                 cf_path=$prefix
3737         else
3738                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
3739         fi
3740
3741         # If you don't like using the default architecture, you have to specify the
3742         # intended library directory and corresponding compiler/linker options.
3743         #
3744         # This case allows for Debian's 2014-flavor of multiarch, along with the
3745         # most common variations before that point.  Some other variants spell the
3746         # directory differently, e.g., "pkg-config", and put it in unusual places.
3747         # pkg-config has always been poorly standardized, which is ironic...
3748         case x`(arch) 2>/dev/null` in
3749         (*64)
3750                 cf_search_path="\
3751                         $cf_path/lib/*64-linux-gnu \
3752                         $cf_path/share \
3753                         $cf_path/lib64 \
3754                         $cf_path/lib32 \
3755                         $cf_path/lib"
3756                 ;;
3757         (*)
3758                 cf_search_path="\
3759                         $cf_path/lib/*-linux-gnu \
3760                         $cf_path/share \
3761                         $cf_path/lib32 \
3762                         $cf_path/lib \
3763                         $cf_path/libdata"
3764                 ;;
3765         esac
3766
3767         CF_VERBOSE(list...)
3768         for cf_config in $cf_search_path
3769         do
3770                 CF_VERBOSE(checking $cf_config/pkgconfig)
3771                 if test -d $cf_config/pkgconfig
3772                 then
3773                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
3774                         AC_MSG_CHECKING(done)
3775                         break
3776                 fi
3777         done
3778         ;;
3779 (*)
3780         ;;
3781 esac
3782
3783 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
3784         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
3785 fi
3786
3787 AC_SUBST(PKG_CONFIG_LIBDIR)
3788 ])dnl
3789 dnl ---------------------------------------------------------------------------
3790 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
3791 dnl ---------------
3792 dnl Check for POSIX thread library.
3793 AC_DEFUN([CF_WITH_PTHREAD],
3794 [
3795 AC_MSG_CHECKING(if you want to link with the pthread library)
3796 AC_ARG_WITH(pthread,
3797         [  --with-pthread          use POSIX thread library],
3798         [with_pthread=$withval],
3799         [with_pthread=no])
3800 AC_MSG_RESULT($with_pthread)
3801
3802 if test "$with_pthread" != no ; then
3803         AC_CHECK_HEADER(pthread.h,[
3804         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
3805
3806         for cf_lib_pthread in pthread c_r
3807         do
3808             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
3809             cf_save_LIBS="$LIBS"
3810             CF_ADD_LIB($cf_lib_pthread)
3811             AC_TRY_LINK([
3812 #include <pthread.h>
3813 ],[
3814                 int rc = pthread_create(0,0,0,0);
3815                 int r2 = pthread_mutexattr_settype(0, 0);
3816 ],[with_pthread=yes],[with_pthread=no])
3817             LIBS="$cf_save_LIBS"
3818             AC_MSG_RESULT($with_pthread)
3819             test "$with_pthread" = yes && break
3820         done
3821
3822         if test "$with_pthread" = yes ; then
3823             CF_ADD_LIB($cf_lib_pthread)
3824             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
3825         else
3826             AC_MSG_ERROR(Cannot link with pthread library)
3827         fi
3828         ])
3829 fi
3830 ])
3831 dnl ---------------------------------------------------------------------------
3832 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
3833 dnl ---------------
3834 dnl For testing, override the derived host system-type which is used to decide
3835 dnl things such as the linker commands used to build shared libraries.  This is
3836 dnl normally chosen automatically based on the type of system which you are
3837 dnl building on.  We use it for testing the configure script.
3838 dnl
3839 dnl This is different from the --host option: it is used only for testing parts
3840 dnl of the configure script which would not be reachable with --host since that
3841 dnl relies on the build environment being real, rather than mocked up.
3842 AC_DEFUN([CF_WITH_SYSTYPE],[
3843 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
3844 AC_ARG_WITH(system-type,
3845         [  --with-system-type=XXX  test: override derived host system-type],
3846 [AC_MSG_WARN(overriding system type to $withval)
3847         cf_cv_system_name=$withval
3848         host_os=$withval
3849 ])
3850 ])dnl
3851 dnl ---------------------------------------------------------------------------
3852 dnl CF_XOPEN_SOURCE version: 52 updated: 2016/08/27 12:21:42
3853 dnl ---------------
3854 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
3855 dnl or adapt to the vendor's definitions to get equivalent functionality,
3856 dnl without losing the common non-POSIX features.
3857 dnl
3858 dnl Parameters:
3859 dnl     $1 is the nominal value for _XOPEN_SOURCE
3860 dnl     $2 is the nominal value for _POSIX_C_SOURCE
3861 AC_DEFUN([CF_XOPEN_SOURCE],[
3862 AC_REQUIRE([AC_CANONICAL_HOST])
3863
3864 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
3865 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
3866 cf_xopen_source=
3867
3868 case $host_os in
3869 (aix[[4-7]]*)
3870         cf_xopen_source="-D_ALL_SOURCE"
3871         ;;
3872 (msys)
3873         cf_XOPEN_SOURCE=600
3874         ;;
3875 (darwin[[0-8]].*)
3876         cf_xopen_source="-D_APPLE_C_SOURCE"
3877         ;;
3878 (darwin*)
3879         cf_xopen_source="-D_DARWIN_C_SOURCE"
3880         cf_XOPEN_SOURCE=
3881         ;;
3882 (freebsd*|dragonfly*)
3883         # 5.x headers associate
3884         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
3885         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
3886         cf_POSIX_C_SOURCE=200112L
3887         cf_XOPEN_SOURCE=600
3888         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3889         ;;
3890 (hpux11*)
3891         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
3892         ;;
3893 (hpux*)
3894         cf_xopen_source="-D_HPUX_SOURCE"
3895         ;;
3896 (irix[[56]].*)
3897         cf_xopen_source="-D_SGI_SOURCE"
3898         cf_XOPEN_SOURCE=
3899         ;;
3900 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
3901         CF_GNU_SOURCE
3902         ;;
3903 (minix*)
3904         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
3905         ;;
3906 (mirbsd*)
3907         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
3908         cf_XOPEN_SOURCE=
3909         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3910         ;;
3911 (netbsd*)
3912         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
3913         ;;
3914 (openbsd[[4-9]]*)
3915         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
3916         cf_xopen_source="-D_BSD_SOURCE"
3917         cf_XOPEN_SOURCE=600
3918         ;;
3919 (openbsd*)
3920         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
3921         ;;
3922 (osf[[45]]*)
3923         cf_xopen_source="-D_OSF_SOURCE"
3924         ;;
3925 (nto-qnx*)
3926         cf_xopen_source="-D_QNX_SOURCE"
3927         ;;
3928 (sco*)
3929         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
3930         ;;
3931 (solaris2.*)
3932         cf_xopen_source="-D__EXTENSIONS__"
3933         cf_cv_xopen_source=broken
3934         ;;
3935 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
3936         cf_XOPEN_SOURCE=
3937         cf_POSIX_C_SOURCE=
3938         ;;
3939 (*)
3940         CF_TRY_XOPEN_SOURCE
3941         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3942         ;;
3943 esac
3944
3945 if test -n "$cf_xopen_source" ; then
3946         CF_ADD_CFLAGS($cf_xopen_source,true)
3947 fi
3948
3949 dnl In anything but the default case, we may have system-specific setting
3950 dnl which is still not guaranteed to provide all of the entrypoints that
3951 dnl _XOPEN_SOURCE would yield.
3952 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
3953         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
3954         AC_TRY_COMPILE([#include <stdlib.h>],[
3955 #ifndef _XOPEN_SOURCE
3956 make an error
3957 #endif],
3958         [cf_XOPEN_SOURCE_set=yes],
3959         [cf_XOPEN_SOURCE_set=no])
3960         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
3961         if test $cf_XOPEN_SOURCE_set = yes
3962         then
3963                 AC_TRY_COMPILE([#include <stdlib.h>],[
3964 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
3965 make an error
3966 #endif],
3967                 [cf_XOPEN_SOURCE_set_ok=yes],
3968                 [cf_XOPEN_SOURCE_set_ok=no])
3969                 if test $cf_XOPEN_SOURCE_set_ok = no
3970                 then
3971                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
3972                 fi
3973         else
3974                 CF_TRY_XOPEN_SOURCE
3975         fi
3976 fi
3977 ])