ncurses 5.9 - patch 20140726
[ncurses.git] / Ada95 / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright (c) 2010-2013,2014 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey
30 dnl
31 dnl $Id: aclocal.m4,v 1.90 2014/07/26 22:58:13 tom Exp $
32 dnl Macros used in NCURSES Ada95 auto-configuration script.
33 dnl
34 dnl These macros are maintained separately from NCURSES.  The copyright on
35 dnl this file applies to the aggregation of macros and does not affect use of
36 dnl these macros in other applications.
37 dnl
38 dnl See http://invisible-island.net/autoconf/ for additional information.
39 dnl
40 dnl ---------------------------------------------------------------------------
41 dnl ---------------------------------------------------------------------------
42 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
43 dnl ------------------
44 dnl Conditionally generate script according to whether we're using a given autoconf.
45 dnl
46 dnl $1 = version to compare against
47 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
48 dnl $3 = code to use if AC_ACVERSION is older than $1.
49 define([CF_ACVERSION_CHECK],
50 [
51 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
52 ifdef([m4_version_compare],
53 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
54 [CF_ACVERSION_COMPARE(
55 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
56 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
57 dnl ---------------------------------------------------------------------------
58 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
59 dnl --------------------
60 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
61 dnl                      MAJOR2, MINOR2, TERNARY2,
62 dnl                      PRINTABLE2, not FOUND, FOUND)
63 define([CF_ACVERSION_COMPARE],
64 [ifelse(builtin([eval], [$2 < $5]), 1,
65 [ifelse([$8], , ,[$8])],
66 [ifelse([$9], , ,[$9])])])dnl
67 dnl ---------------------------------------------------------------------------
68 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
69 dnl -------------------
70 dnl Construct the list of include-options for the C programs in the Ada95
71 dnl binding.
72 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
73 [
74 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
75 if test "$srcdir" != "."; then
76         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
77 fi
78 if test "$GCC" != yes; then
79         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
80 elif test "$includedir" != "/usr/include"; then
81         if test "$includedir" = '${prefix}/include' ; then
82                 if test x$prefix != x/usr ; then
83                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
84                 fi
85         else
86                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
87         fi
88 fi
89 AC_SUBST(ACPPFLAGS)
90 ])dnl
91 dnl ---------------------------------------------------------------------------
92 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
93 dnl ---------------
94 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
95 AC_DEFUN([CF_ADD_ADAFLAGS],[
96         ADAFLAGS="$ADAFLAGS $1"
97         AC_SUBST(ADAFLAGS)
98 ])dnl
99 dnl ---------------------------------------------------------------------------
100 dnl CF_ADD_CFLAGS version: 11 updated: 2014/07/22 05:32:57
101 dnl -------------
102 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
103 dnl The second parameter if given makes this macro verbose.
104 dnl
105 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
106 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
107 dnl confused by the quotes (which require backslashes to keep them usable).
108 AC_DEFUN([CF_ADD_CFLAGS],
109 [
110 cf_fix_cppflags=no
111 cf_new_cflags=
112 cf_new_cppflags=
113 cf_new_extra_cppflags=
114
115 for cf_add_cflags in $1
116 do
117 case $cf_fix_cppflags in
118 no)
119         case $cf_add_cflags in #(vi
120         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
121                 case $cf_add_cflags in
122                 -D*)
123                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
124
125                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
126                                 && test -z "${cf_tst_cflags}" \
127                                 && cf_fix_cppflags=yes
128
129                         if test $cf_fix_cppflags = yes ; then
130                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
131                                 continue
132                         elif test "${cf_tst_cflags}" = "\"'" ; then
133                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
134                                 continue
135                         fi
136                         ;;
137                 esac
138                 case "$CPPFLAGS" in
139                 *$cf_add_cflags) #(vi
140                         ;;
141                 *) #(vi
142                         case $cf_add_cflags in #(vi
143                         -D*)
144                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
145                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
146                                 ;;
147                         esac
148                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
149                         ;;
150                 esac
151                 ;;
152         *)
153                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
154                 ;;
155         esac
156         ;;
157 yes)
158         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
159
160         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
161
162         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
163                 && test -z "${cf_tst_cflags}" \
164                 && cf_fix_cppflags=no
165         ;;
166 esac
167 done
168
169 if test -n "$cf_new_cflags" ; then
170         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
171         CFLAGS="$CFLAGS $cf_new_cflags"
172 fi
173
174 if test -n "$cf_new_cppflags" ; then
175         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
176         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
177 fi
178
179 if test -n "$cf_new_extra_cppflags" ; then
180         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
181         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
182 fi
183
184 AC_SUBST(EXTRA_CPPFLAGS)
185
186 ])dnl
187 dnl ---------------------------------------------------------------------------
188 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
189 dnl -------------
190 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
191 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
192 dnl but old versions (and some misinstalled ones) need that.  To make things
193 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
194 dnl the include-path).
195 AC_DEFUN([CF_ADD_INCDIR],
196 [
197 if test -n "$1" ; then
198   for cf_add_incdir in $1
199   do
200         while test $cf_add_incdir != /usr/include
201         do
202           if test -d $cf_add_incdir
203           then
204                 cf_have_incdir=no
205                 if test -n "$CFLAGS$CPPFLAGS" ; then
206                   # a loop is needed to ensure we can add subdirs of existing dirs
207                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
208                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
209                           cf_have_incdir=yes; break
210                         fi
211                   done
212                 fi
213
214                 if test "$cf_have_incdir" = no ; then
215                   if test "$cf_add_incdir" = /usr/local/include ; then
216                         if test "$GCC" = yes
217                         then
218                           cf_save_CPPFLAGS=$CPPFLAGS
219                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
220                           AC_TRY_COMPILE([#include <stdio.h>],
221                                   [printf("Hello")],
222                                   [],
223                                   [cf_have_incdir=yes])
224                           CPPFLAGS=$cf_save_CPPFLAGS
225                         fi
226                   fi
227                 fi
228
229                 if test "$cf_have_incdir" = no ; then
230                   CF_VERBOSE(adding $cf_add_incdir to include-path)
231                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
232
233                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
234                   test "$cf_top_incdir" = "$cf_add_incdir" && break
235                   cf_add_incdir="$cf_top_incdir"
236                 else
237                   break
238                 fi
239           fi
240         done
241   done
242 fi
243 ])dnl
244 dnl ---------------------------------------------------------------------------
245 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
246 dnl ----------
247 dnl Add a library, used to enforce consistency.
248 dnl
249 dnl $1 = library to add, without the "-l"
250 dnl $2 = variable to update (default $LIBS)
251 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
252 dnl ---------------------------------------------------------------------------
253 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
254 dnl -------------
255 dnl     Adds to the library-path
256 dnl
257 dnl     Some machines have trouble with multiple -L options.
258 dnl
259 dnl $1 is the (list of) directory(s) to add
260 dnl $2 is the optional name of the variable to update (default LDFLAGS)
261 dnl
262 AC_DEFUN([CF_ADD_LIBDIR],
263 [
264 if test -n "$1" ; then
265   for cf_add_libdir in $1
266   do
267     if test $cf_add_libdir = /usr/lib ; then
268       :
269     elif test -d $cf_add_libdir
270     then
271       cf_have_libdir=no
272       if test -n "$LDFLAGS$LIBS" ; then
273         # a loop is needed to ensure we can add subdirs of existing dirs
274         for cf_test_libdir in $LDFLAGS $LIBS ; do
275           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
276             cf_have_libdir=yes; break
277           fi
278         done
279       fi
280       if test "$cf_have_libdir" = no ; then
281         CF_VERBOSE(adding $cf_add_libdir to library-path)
282         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
283       fi
284     fi
285   done
286 fi
287 ])dnl
288 dnl ---------------------------------------------------------------------------
289 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
290 dnl -----------
291 dnl Add one or more libraries, used to enforce consistency.  Libraries are
292 dnl prepended to an existing list, since their dependencies are assumed to
293 dnl already exist in the list.
294 dnl
295 dnl $1 = libraries to add, with the "-l", etc.
296 dnl $2 = variable to update (default $LIBS)
297 AC_DEFUN([CF_ADD_LIBS],[
298 cf_add_libs="$1"
299 # Filter out duplicates - this happens with badly-designed ".pc" files...
300 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
301 do
302         for cf_add_2lib in $cf_add_libs
303         do
304                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
305                 then
306                         cf_add_1lib=
307                         break
308                 fi
309         done
310         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
311 done
312 ifelse($2,,LIBS,[$2])="$cf_add_libs"
313 ])dnl
314 dnl ---------------------------------------------------------------------------
315 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
316 dnl ------------------
317 dnl Append to a search-list for a nonstandard header/lib-file
318 dnl     $1 = the variable to return as result
319 dnl     $2 = the package name
320 dnl     $3 = the subdirectory, e.g., bin, include or lib
321 dnl $4 = the directory under which we will test for subdirectories
322 dnl $5 = a directory that we do not want $4 to match
323 AC_DEFUN([CF_ADD_SUBDIR_PATH],
324 [
325 test "x$4" != "x$5" && \
326 test -d "$4" && \
327 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
328         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
329         test -d $4/$3 &&          $1="[$]$1 $4/$3"
330         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
331         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
332         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
333         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
334 }
335 ])dnl
336 dnl ---------------------------------------------------------------------------
337 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
338 dnl --------------
339 dnl Allow user to disable a normally-on option.
340 AC_DEFUN([CF_ARG_DISABLE],
341 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
342 dnl ---------------------------------------------------------------------------
343 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
344 dnl -------------
345 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
346 dnl values.
347 dnl
348 dnl Parameters:
349 dnl $1 = option name
350 dnl $2 = help-string
351 dnl $3 = action to perform if option is not default
352 dnl $4 = action if perform if option is default
353 dnl $5 = default option value (either 'yes' or 'no')
354 AC_DEFUN([CF_ARG_OPTION],
355 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
356   if test "$enableval" != "$5" ; then
357 ifelse([$3],,[    :]dnl
358 ,[    $3]) ifelse([$4],,,[
359   else
360     $4])
361   fi],[enableval=$5 ifelse([$4],,,[
362   $4
363 ])dnl
364   ])])dnl
365 dnl ---------------------------------------------------------------------------
366 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
367 dnl -----------
368 dnl Check for suitable "ar" (archiver) options for updating an archive.
369 AC_DEFUN([CF_AR_FLAGS],[
370 AC_REQUIRE([CF_PROG_AR])
371
372 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
373         cf_cv_ar_flags=unknown
374         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
375         do
376
377                 # check if $ARFLAGS already contains this choice
378                 if test "x$ARFLAGS" != "x" ; then
379                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
380                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
381                                 cf_cv_ar_flags=
382                                 break
383                         fi
384                 fi
385
386                 rm -f conftest.$ac_cv_objext
387                 rm -f conftest.a
388
389                 cat >conftest.$ac_ext <<EOF
390 #line __oline__ "configure"
391 int     testdata[[3]] = { 123, 456, 789 };
392 EOF
393                 if AC_TRY_EVAL(ac_compile) ; then
394                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
395                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
396                         if test -f conftest.a ; then
397                                 cf_cv_ar_flags=$cf_ar_flags
398                                 break
399                         fi
400                 else
401                         CF_VERBOSE(cannot compile test-program)
402                         break
403                 fi
404         done
405         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
406 ])
407
408 if test -n "$ARFLAGS" ; then
409         if test -n "$cf_cv_ar_flags" ; then
410                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
411         fi
412 else
413         ARFLAGS=$cf_cv_ar_flags
414 fi
415
416 AC_SUBST(ARFLAGS)
417 ])
418 dnl ---------------------------------------------------------------------------
419 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
420 dnl -----------
421 dnl If we're cross-compiling, allow the user to override the tools and their
422 dnl options.  The configure script is oriented toward identifying the host
423 dnl compiler, etc., but we need a build compiler to generate parts of the
424 dnl source.
425 dnl
426 dnl $1 = default for $CPPFLAGS
427 dnl $2 = default for $LIBS
428 AC_DEFUN([CF_BUILD_CC],[
429 CF_ACVERSION_CHECK(2.52,,
430         [AC_REQUIRE([CF_PROG_EXT])])
431 if test "$cross_compiling" = yes ; then
432
433         # defaults that we might want to override
434         : ${BUILD_CFLAGS:=''}
435         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
436         : ${BUILD_LDFLAGS:=''}
437         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
438         : ${BUILD_EXEEXT:='$x'}
439         : ${BUILD_OBJEXT:='o'}
440
441         AC_ARG_WITH(build-cc,
442                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
443                 [BUILD_CC="$withval"],
444                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
445         AC_MSG_CHECKING(for native build C compiler)
446         AC_MSG_RESULT($BUILD_CC)
447
448         AC_MSG_CHECKING(for native build C preprocessor)
449         AC_ARG_WITH(build-cpp,
450                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
451                 [BUILD_CPP="$withval"],
452                 [BUILD_CPP='${BUILD_CC} -E'])
453         AC_MSG_RESULT($BUILD_CPP)
454
455         AC_MSG_CHECKING(for native build C flags)
456         AC_ARG_WITH(build-cflags,
457                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
458                 [BUILD_CFLAGS="$withval"])
459         AC_MSG_RESULT($BUILD_CFLAGS)
460
461         AC_MSG_CHECKING(for native build C preprocessor-flags)
462         AC_ARG_WITH(build-cppflags,
463                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
464                 [BUILD_CPPFLAGS="$withval"])
465         AC_MSG_RESULT($BUILD_CPPFLAGS)
466
467         AC_MSG_CHECKING(for native build linker-flags)
468         AC_ARG_WITH(build-ldflags,
469                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
470                 [BUILD_LDFLAGS="$withval"])
471         AC_MSG_RESULT($BUILD_LDFLAGS)
472
473         AC_MSG_CHECKING(for native build linker-libraries)
474         AC_ARG_WITH(build-libs,
475                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
476                 [BUILD_LIBS="$withval"])
477         AC_MSG_RESULT($BUILD_LIBS)
478
479         # this assumes we're on Unix.
480         BUILD_EXEEXT=
481         BUILD_OBJEXT=o
482
483         : ${BUILD_CC:='${CC}'}
484
485         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
486                 AC_MSG_ERROR([Cross-build requires two compilers.
487 Use --with-build-cc to specify the native compiler.])
488         fi
489
490 else
491         : ${BUILD_CC:='${CC}'}
492         : ${BUILD_CPP:='${CPP}'}
493         : ${BUILD_CFLAGS:='${CFLAGS}'}
494         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
495         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
496         : ${BUILD_LIBS:='${LIBS}'}
497         : ${BUILD_EXEEXT:='$x'}
498         : ${BUILD_OBJEXT:='o'}
499 fi
500
501 AC_SUBST(BUILD_CC)
502 AC_SUBST(BUILD_CPP)
503 AC_SUBST(BUILD_CFLAGS)
504 AC_SUBST(BUILD_CPPFLAGS)
505 AC_SUBST(BUILD_LDFLAGS)
506 AC_SUBST(BUILD_LIBS)
507 AC_SUBST(BUILD_EXEEXT)
508 AC_SUBST(BUILD_OBJEXT)
509 ])dnl
510 dnl ---------------------------------------------------------------------------
511 dnl CF_CC_ENV_FLAGS version: 1 updated: 2012/10/03 05:25:49
512 dnl ---------------
513 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
514 dnl into CC.  This will not help with broken scripts that wrap the compiler with
515 dnl options, but eliminates a more common category of user confusion.
516 AC_DEFUN([CF_CC_ENV_FLAGS],
517 [
518 # This should have been defined by AC_PROG_CC
519 : ${CC:=cc}
520
521 AC_MSG_CHECKING(\$CC variable)
522 case "$CC" in #(vi
523 *[[\ \  ]]-[[IUD]]*)
524         AC_MSG_RESULT(broken)
525         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
526         # humor him...
527         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
528         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
529         CF_ADD_CFLAGS($cf_flags)
530         ;;
531 *)
532         AC_MSG_RESULT(ok)
533         ;;
534 esac
535 ])dnl
536 dnl ---------------------------------------------------------------------------
537 dnl CF_CFG_DEFAULTS version: 10 updated: 2013/09/07 13:54:05
538 dnl ---------------
539 dnl Determine the default configuration into which we'll install ncurses.  This
540 dnl can be overridden by the user's command-line options.  There's two items to
541 dnl look for:
542 dnl     1. the prefix (e.g., /usr)
543 dnl     2. the header files (e.g., /usr/include/ncurses)
544 dnl We'll look for a previous installation of ncurses and use the same defaults.
545 dnl
546 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
547 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
548 dnl programs from a vendor's.
549 AC_DEFUN([CF_CFG_DEFAULTS],
550 [
551 AC_MSG_CHECKING(for prefix)
552 if test "x$prefix" = "xNONE" ; then
553         case "$cf_cv_system_name" in
554                 # non-vendor systems don't have a conflict
555         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
556                 prefix=/usr
557                 ;;
558         *)      prefix=$ac_default_prefix
559                 ;;
560         esac
561 fi
562 AC_MSG_RESULT($prefix)
563
564 if test "x$prefix" = "xNONE" ; then
565 AC_MSG_CHECKING(for default include-directory)
566 test -n "$verbose" && echo 1>&AC_FD_MSG
567 for cf_symbol in \
568         $includedir \
569         $includedir/ncurses \
570         $prefix/include \
571         $prefix/include/ncurses \
572         /usr/local/include \
573         /usr/local/include/ncurses \
574         /usr/include \
575         /usr/include/ncurses
576 do
577         cf_dir=`eval echo $cf_symbol`
578         if test -f $cf_dir/curses.h ; then
579         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
580                 includedir="$cf_symbol"
581                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
582                 break
583         fi
584         fi
585         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
586 done
587 AC_MSG_RESULT($includedir)
588 fi
589 ])dnl
590 dnl ---------------------------------------------------------------------------
591 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
592 dnl --------------
593 dnl Check if we're accidentally using a cache from a different machine.
594 dnl Derive the system name, as a check for reusing the autoconf cache.
595 dnl
596 dnl If we've packaged config.guess and config.sub, run that (since it does a
597 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
598 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
599 dnl which is useful in cross-compiles.
600 dnl
601 dnl Note: we would use $ac_config_sub, but that is one of the places where
602 dnl autoconf 2.5x broke compatibility with autoconf 2.13
603 AC_DEFUN([CF_CHECK_CACHE],
604 [
605 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
606         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
607         system_name="$host_os"
608 else
609         system_name="`(uname -s -r) 2>/dev/null`"
610         if test -z "$system_name" ; then
611                 system_name="`(hostname) 2>/dev/null`"
612         fi
613 fi
614 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
615 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
616
617 test -z "$system_name" && system_name="$cf_cv_system_name"
618 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
619
620 if test ".$system_name" != ".$cf_cv_system_name" ; then
621         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
622         AC_MSG_ERROR("Please remove config.cache and try again.")
623 fi
624 ])dnl
625 dnl ---------------------------------------------------------------------------
626 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
627 dnl -----------------
628 dnl Check if the given compiler is really clang.  clang's C driver defines
629 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
630 dnl not ignore some gcc options.
631 dnl
632 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
633 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
634 dnl the wrappers for gcc and g++ warnings.
635 dnl
636 dnl $1 = GCC (default) or GXX
637 dnl $2 = CLANG_COMPILER (default)
638 dnl $3 = CFLAGS (default) or CXXFLAGS
639 AC_DEFUN([CF_CLANG_COMPILER],[
640 ifelse([$2],,CLANG_COMPILER,[$2])=no
641
642 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
643         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
644         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
645         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
646         AC_TRY_COMPILE([],[
647 #ifdef __clang__
648 #else
649 make an error
650 #endif
651 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
652 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
653 ],[])
654         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
655         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
656 fi
657 ])
658 dnl ---------------------------------------------------------------------------
659 dnl CF_CURSES_HEADER version: 3 updated: 2011/05/01 19:47:45
660 dnl ----------------
661 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
662 dnl variations of ncurses' installs.
663 dnl
664 dnl $1 = ncurses when looking for ncurses, or is empty
665 AC_DEFUN([CF_CURSES_HEADER],[
666 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
667 cf_cv_ncurses_header=none
668 for cf_header in ifelse($1,,,[ \
669     $1/ncurses.h \
670         $1/curses.h]) \
671         ncurses.h \
672         curses.h ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
673 do
674 AC_TRY_COMPILE([#include <${cf_header}>],
675         [initscr(); tgoto("?", 0,0)],
676         [cf_cv_ncurses_header=$cf_header; break],[])
677 done
678 ])
679
680 if test "$cf_cv_ncurses_header" = none ; then
681         AC_MSG_ERROR(No curses header-files found)
682 fi
683
684 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
685 AC_CHECK_HEADERS($cf_cv_ncurses_header)
686 ])dnl
687 dnl ---------------------------------------------------------------------------
688 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
689 dnl ----------
690 dnl "dirname" is not portable, so we fake it with a shell script.
691 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
692 dnl ---------------------------------------------------------------------------
693 dnl CF_DISABLE_ECHO version: 12 updated: 2012/10/06 16:30:28
694 dnl ---------------
695 dnl You can always use "make -n" to see the actual options, but it's hard to
696 dnl pick out/analyze warning messages when the compile-line is long.
697 dnl
698 dnl Sets:
699 dnl     ECHO_LT - symbol to control if libtool is verbose
700 dnl     ECHO_LD - symbol to prefix "cc -o" lines
701 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
702 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
703 dnl     ECHO_CC - symbol to put before any "cc" line
704 dnl
705 AC_DEFUN([CF_DISABLE_ECHO],[
706 AC_MSG_CHECKING(if you want to see long compiling messages)
707 CF_ARG_DISABLE(echo,
708         [  --disable-echo          do not display "compiling" commands],
709         [
710     ECHO_LT='--silent'
711     ECHO_LD='@echo linking [$]@;'
712     RULE_CC='@echo compiling [$]<'
713     SHOW_CC='@echo compiling [$]@'
714     ECHO_CC='@'
715 ],[
716     ECHO_LT=''
717     ECHO_LD=''
718     RULE_CC=''
719     SHOW_CC=''
720     ECHO_CC=''
721 ])
722 AC_MSG_RESULT($enableval)
723 AC_SUBST(ECHO_LT)
724 AC_SUBST(ECHO_LD)
725 AC_SUBST(RULE_CC)
726 AC_SUBST(SHOW_CC)
727 AC_SUBST(ECHO_CC)
728 ])dnl
729 dnl ---------------------------------------------------------------------------
730 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
731 dnl ------------------------
732 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
733 AC_MSG_CHECKING(if we want to use GNAT projects)
734 CF_ARG_DISABLE(gnat-projects,
735         [  --disable-gnat-projects test: disable GNAT projects even if usable],
736         [enable_gnat_projects=no],
737         [enable_gnat_projects=yes])
738 AC_MSG_RESULT($enable_gnat_projects)
739 ])dnl
740 dnl ---------------------------------------------------------------------------
741 dnl CF_ENABLE_PC_FILES version: 9 updated: 2012/08/04 13:59:54
742 dnl ------------------
743 dnl This is the "--enable-pc-files" option, which is available if there is a
744 dnl pkg-config configuration on the local machine.
745 AC_DEFUN([CF_ENABLE_PC_FILES],[
746 AC_REQUIRE([CF_PKG_CONFIG])
747 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
748
749 if test "$PKG_CONFIG" != none ; then
750         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
751         AC_ARG_ENABLE(pc-files,
752                 [  --enable-pc-files       generate and install .pc files for pkg-config],
753                 [enable_pc_files=$enableval],
754                 [enable_pc_files=no])
755         AC_MSG_RESULT($enable_pc_files)
756         if test "$enable_pc_files" != no
757         then
758                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
759         fi
760 else
761         enable_pc_files=no
762 fi
763 ])dnl
764 dnl ---------------------------------------------------------------------------
765 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
766 dnl ---------------
767 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
768 dnl prefer a standard location, and use -L options only if we do not find the
769 dnl library in the standard library location(s).
770 dnl     $1 = library name
771 dnl     $2 = library class, usually the same as library name
772 dnl     $3 = includes
773 dnl     $4 = code fragment to compile/link
774 dnl     $5 = corresponding function-name
775 dnl     $6 = flag, nonnull if failure should not cause an error-exit
776 dnl
777 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
778 dnl to use a -L option.
779 AC_DEFUN([CF_FIND_LIBRARY],
780 [
781         eval 'cf_cv_have_lib_'$1'=no'
782         cf_libdir=""
783         AC_CHECK_FUNC($5,
784                 eval 'cf_cv_have_lib_'$1'=yes',[
785                 cf_save_LIBS="$LIBS"
786                 AC_MSG_CHECKING(for $5 in -l$1)
787                 LIBS="-l$1 $LIBS"
788                 AC_TRY_LINK([$3],[$4],
789                         [AC_MSG_RESULT(yes)
790                          eval 'cf_cv_have_lib_'$1'=yes'
791                         ],
792                         [AC_MSG_RESULT(no)
793                         CF_LIBRARY_PATH(cf_search,$2)
794                         for cf_libdir in $cf_search
795                         do
796                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
797                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
798                                 AC_TRY_LINK([$3],[$4],
799                                         [AC_MSG_RESULT(yes)
800                                          eval 'cf_cv_have_lib_'$1'=yes'
801                                          break],
802                                         [AC_MSG_RESULT(no)
803                                          LIBS="$cf_save_LIBS"])
804                         done
805                         ])
806                 ])
807 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
808 ifelse($6,,[
809 if test $cf_found_library = no ; then
810         AC_MSG_ERROR(Cannot link $1 library)
811 fi
812 ])
813 ])dnl
814 dnl ---------------------------------------------------------------------------
815 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
816 dnl ---------------
817 dnl Find a library (specifically the linkage used in the code fragment),
818 dnl searching for it if it is not already in the library path.
819 dnl See also CF_ADD_SEARCHPATH.
820 dnl
821 dnl Parameters (4-on are optional):
822 dnl     $1 = headers for library entrypoint
823 dnl     $2 = code fragment for library entrypoint
824 dnl     $3 = the library name without the "-l" option or ".so" suffix.
825 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
826 dnl     $5 = action to perform if not successful
827 dnl     $6 = module name, if not the same as the library name
828 dnl     $7 = extra libraries
829 dnl
830 dnl Sets these variables:
831 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
832 dnl     $cf_cv_header_path_$3 - include-directory if needed
833 dnl     $cf_cv_library_path_$3 - library-directory if needed
834 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
835 AC_DEFUN([CF_FIND_LINKAGE],[
836
837 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
838 # will be set on completion of the AC_TRY_LINK below.
839 cf_cv_header_path_$3=
840 cf_cv_library_path_$3=
841
842 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
843
844 cf_save_LIBS="$LIBS"
845
846 AC_TRY_LINK([$1],[$2],[
847         cf_cv_find_linkage_$3=yes
848         cf_cv_header_path_$3=/usr/include
849         cf_cv_library_path_$3=/usr/lib
850 ],[
851
852 LIBS="-l$3 $7 $cf_save_LIBS"
853
854 AC_TRY_LINK([$1],[$2],[
855         cf_cv_find_linkage_$3=yes
856         cf_cv_header_path_$3=/usr/include
857         cf_cv_library_path_$3=/usr/lib
858         cf_cv_library_file_$3="-l$3"
859 ],[
860         cf_cv_find_linkage_$3=no
861         LIBS="$cf_save_LIBS"
862
863     CF_VERBOSE(find linkage for $3 library)
864     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
865
866     cf_save_CPPFLAGS="$CPPFLAGS"
867     cf_test_CPPFLAGS="$CPPFLAGS"
868
869     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
870     for cf_cv_header_path_$3 in $cf_search
871     do
872       if test -d $cf_cv_header_path_$3 ; then
873         CF_VERBOSE(... testing $cf_cv_header_path_$3)
874         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
875         AC_TRY_COMPILE([$1],[$2],[
876             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
877             cf_cv_find_linkage_$3=maybe
878             cf_test_CPPFLAGS="$CPPFLAGS"
879             break],[
880             CPPFLAGS="$cf_save_CPPFLAGS"
881             ])
882       fi
883     done
884
885     if test "$cf_cv_find_linkage_$3" = maybe ; then
886
887       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
888
889       cf_save_LIBS="$LIBS"
890       cf_save_LDFLAGS="$LDFLAGS"
891
892       ifelse([$6],,,[
893         CPPFLAGS="$cf_test_CPPFLAGS"
894         LIBS="-l$3 $7 $cf_save_LIBS"
895         AC_TRY_LINK([$1],[$2],[
896             CF_VERBOSE(... found $3 library in system)
897             cf_cv_find_linkage_$3=yes])
898             CPPFLAGS="$cf_save_CPPFLAGS"
899             LIBS="$cf_save_LIBS"
900             ])
901
902       if test "$cf_cv_find_linkage_$3" != yes ; then
903         CF_LIBRARY_PATH(cf_search,$3)
904         for cf_cv_library_path_$3 in $cf_search
905         do
906           if test -d $cf_cv_library_path_$3 ; then
907             CF_VERBOSE(... testing $cf_cv_library_path_$3)
908             CPPFLAGS="$cf_test_CPPFLAGS"
909             LIBS="-l$3 $7 $cf_save_LIBS"
910             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
911             AC_TRY_LINK([$1],[$2],[
912                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
913                 cf_cv_find_linkage_$3=yes
914                 cf_cv_library_file_$3="-l$3"
915                 break],[
916                 CPPFLAGS="$cf_save_CPPFLAGS"
917                 LIBS="$cf_save_LIBS"
918                 LDFLAGS="$cf_save_LDFLAGS"
919                 ])
920           fi
921         done
922         CPPFLAGS="$cf_save_CPPFLAGS"
923         LDFLAGS="$cf_save_LDFLAGS"
924       fi
925
926     else
927       cf_cv_find_linkage_$3=no
928     fi
929     ],$7)
930 ])
931
932 LIBS="$cf_save_LIBS"
933
934 if test "$cf_cv_find_linkage_$3" = yes ; then
935 ifelse([$4],,[
936         CF_ADD_INCDIR($cf_cv_header_path_$3)
937         CF_ADD_LIBDIR($cf_cv_library_path_$3)
938         CF_ADD_LIB($3)
939 ],[$4])
940 else
941 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
942 fi
943 ])dnl
944 dnl ---------------------------------------------------------------------------
945 dnl CF_FIXUP_ADAFLAGS version: 1 updated: 2012/03/31 18:48:10
946 dnl -----------------
947 dnl make ADAFLAGS consistent with CFLAGS
948 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
949         AC_MSG_CHECKING(optimization options for ADAFLAGS)
950         case "$CFLAGS" in
951         *-g*)
952                 CF_ADD_ADAFLAGS(-g)
953                 ;;
954         esac
955         case "$CFLAGS" in
956         *-O*)
957                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
958                 CF_ADD_ADAFLAGS($cf_O_flag)
959                 ;;
960         esac
961         AC_MSG_RESULT($ADAFLAGS)
962 ])dnl
963 dnl ---------------------------------------------------------------------------
964 dnl CF_GCC_ATTRIBUTES version: 16 updated: 2012/10/02 20:55:03
965 dnl -----------------
966 dnl Test for availability of useful gcc __attribute__ directives to quiet
967 dnl compiler warnings.  Though useful, not all are supported -- and contrary
968 dnl to documentation, unrecognized directives cause older compilers to barf.
969 AC_DEFUN([CF_GCC_ATTRIBUTES],
970 [
971 if test "$GCC" = yes
972 then
973 cat > conftest.i <<EOF
974 #ifndef GCC_PRINTF
975 #define GCC_PRINTF 0
976 #endif
977 #ifndef GCC_SCANF
978 #define GCC_SCANF 0
979 #endif
980 #ifndef GCC_NORETURN
981 #define GCC_NORETURN /* nothing */
982 #endif
983 #ifndef GCC_UNUSED
984 #define GCC_UNUSED /* nothing */
985 #endif
986 EOF
987 if test "$GCC" = yes
988 then
989         AC_CHECKING([for $CC __attribute__ directives])
990 cat > conftest.$ac_ext <<EOF
991 #line __oline__ "${as_me:-configure}"
992 #include "confdefs.h"
993 #include "conftest.h"
994 #include "conftest.i"
995 #if     GCC_PRINTF
996 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
997 #else
998 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
999 #endif
1000 #if     GCC_SCANF
1001 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1002 #else
1003 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1004 #endif
1005 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1006 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1007 extern void foo(void) GCC_NORETURN;
1008 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1009 EOF
1010         cf_printf_attribute=no
1011         cf_scanf_attribute=no
1012         for cf_attribute in scanf printf unused noreturn
1013         do
1014                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1015                 cf_directive="__attribute__(($cf_attribute))"
1016                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1017
1018                 case $cf_attribute in #(vi
1019                 printf) #(vi
1020                         cf_printf_attribute=yes
1021                         cat >conftest.h <<EOF
1022 #define GCC_$cf_ATTRIBUTE 1
1023 EOF
1024                         ;;
1025                 scanf) #(vi
1026                         cf_scanf_attribute=yes
1027                         cat >conftest.h <<EOF
1028 #define GCC_$cf_ATTRIBUTE 1
1029 EOF
1030                         ;;
1031                 *) #(vi
1032                         cat >conftest.h <<EOF
1033 #define GCC_$cf_ATTRIBUTE $cf_directive
1034 EOF
1035                         ;;
1036                 esac
1037
1038                 if AC_TRY_EVAL(ac_compile); then
1039                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1040                         cat conftest.h >>confdefs.h
1041                         case $cf_attribute in #(vi
1042                         noreturn) #(vi
1043                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1044                                 ;;
1045                         printf) #(vi
1046                                 cf_value='/* nothing */'
1047                                 if test "$cf_printf_attribute" != no ; then
1048                                         cf_value='__attribute__((format(printf,fmt,var)))'
1049                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1050                                 fi
1051                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1052                                 ;;
1053                         scanf) #(vi
1054                                 cf_value='/* nothing */'
1055                                 if test "$cf_scanf_attribute" != no ; then
1056                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1057                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1058                                 fi
1059                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1060                                 ;;
1061                         unused) #(vi
1062                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1063                                 ;;
1064                         esac
1065                 fi
1066         done
1067 else
1068         fgrep define conftest.i >>confdefs.h
1069 fi
1070 rm -rf conftest*
1071 fi
1072 ])dnl
1073 dnl ---------------------------------------------------------------------------
1074 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1075 dnl --------------
1076 dnl Find version of gcc
1077 AC_DEFUN([CF_GCC_VERSION],[
1078 AC_REQUIRE([AC_PROG_CC])
1079 GCC_VERSION=none
1080 if test "$GCC" = yes ; then
1081         AC_MSG_CHECKING(version of $CC)
1082         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1083         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1084         AC_MSG_RESULT($GCC_VERSION)
1085 fi
1086 ])dnl
1087 dnl ---------------------------------------------------------------------------
1088 dnl CF_GCC_WARNINGS version: 31 updated: 2013/11/19 19:23:35
1089 dnl ---------------
1090 dnl Check if the compiler supports useful warning options.  There's a few that
1091 dnl we don't use, simply because they're too noisy:
1092 dnl
1093 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1094 dnl     -Wredundant-decls (system headers make this too noisy)
1095 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1096 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1097 dnl             is enabled for ncurses using "--enable-const".
1098 dnl     -pedantic
1099 dnl
1100 dnl Parameter:
1101 dnl     $1 is an optional list of gcc warning flags that a particular
1102 dnl             application might want to use, e.g., "no-unused" for
1103 dnl             -Wno-unused
1104 dnl Special:
1105 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1106 dnl
1107 AC_DEFUN([CF_GCC_WARNINGS],
1108 [
1109 AC_REQUIRE([CF_GCC_VERSION])
1110 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1111 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1112
1113 cat > conftest.$ac_ext <<EOF
1114 #line __oline__ "${as_me:-configure}"
1115 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1116 EOF
1117
1118 if test "$INTEL_COMPILER" = yes
1119 then
1120 # The "-wdXXX" options suppress warnings:
1121 # remark #1419: external declaration in primary source file
1122 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1123 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1124 # remark #193: zero used for undefined preprocessing identifier
1125 # remark #593: variable "curs_sb_left_arrow" was set but never used
1126 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1127 # remark #869: parameter "tw" was never referenced
1128 # remark #981: operands are evaluated in unspecified order
1129 # warning #279: controlling expression is constant
1130
1131         AC_CHECKING([for $CC warning options])
1132         cf_save_CFLAGS="$CFLAGS"
1133         EXTRA_CFLAGS="-Wall"
1134         for cf_opt in \
1135                 wd1419 \
1136                 wd1683 \
1137                 wd1684 \
1138                 wd193 \
1139                 wd593 \
1140                 wd279 \
1141                 wd810 \
1142                 wd869 \
1143                 wd981
1144         do
1145                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1146                 if AC_TRY_EVAL(ac_compile); then
1147                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1148                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1149                 fi
1150         done
1151         CFLAGS="$cf_save_CFLAGS"
1152
1153 elif test "$GCC" = yes
1154 then
1155         AC_CHECKING([for $CC warning options])
1156         cf_save_CFLAGS="$CFLAGS"
1157         EXTRA_CFLAGS=
1158         cf_warn_CONST=""
1159         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1160         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1161         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1162         for cf_opt in W Wall \
1163                 Wbad-function-cast \
1164                 Wcast-align \
1165                 Wcast-qual \
1166                 Wdeclaration-after-statement \
1167                 Wextra \
1168                 Winline \
1169                 Wmissing-declarations \
1170                 Wmissing-prototypes \
1171                 Wnested-externs \
1172                 Wpointer-arith \
1173                 Wshadow \
1174                 Wstrict-prototypes \
1175                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
1176         do
1177                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1178                 if AC_TRY_EVAL(ac_compile); then
1179                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1180                         case $cf_opt in #(vi
1181                         Wcast-qual) #(vi
1182                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1183                                 ;;
1184                         Winline) #(vi
1185                                 case $GCC_VERSION in
1186                                 [[34]].*)
1187                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1188                                         continue;;
1189                                 esac
1190                                 ;;
1191                         Wpointer-arith) #(vi
1192                                 case $GCC_VERSION in
1193                                 [[12]].*)
1194                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1195                                         continue;;
1196                                 esac
1197                                 ;;
1198                         esac
1199                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1200                 fi
1201         done
1202         CFLAGS="$cf_save_CFLAGS"
1203 fi
1204 rm -rf conftest*
1205
1206 AC_SUBST(EXTRA_CFLAGS)
1207 ])dnl
1208 dnl ---------------------------------------------------------------------------
1209 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
1210 dnl ----------------
1211 AC_DEFUN([CF_GNAT_GENERICS],
1212 [
1213 AC_REQUIRE([CF_GNAT_VERSION])
1214
1215 AC_MSG_CHECKING(if GNAT supports generics)
1216 case $cf_gnat_version in #(vi
1217 3.[[1-9]]*|[[4-9]].*) #(vi
1218         cf_gnat_generics=yes
1219         ;;
1220 *)
1221         cf_gnat_generics=no
1222         ;;
1223 esac
1224 AC_MSG_RESULT($cf_gnat_generics)
1225
1226 if test "$cf_gnat_generics" = yes
1227 then
1228         cf_compile_generics=generics
1229         cf_generic_objects="\${GENOBJS}"
1230 else
1231         cf_compile_generics=
1232         cf_generic_objects=
1233 fi
1234
1235 AC_SUBST(cf_compile_generics)
1236 AC_SUBST(cf_generic_objects)
1237 ])dnl
1238 dnl ---------------------------------------------------------------------------
1239 dnl CF_GNAT_PROJECTS version: 7 updated: 2014/06/01 10:46:34
1240 dnl ----------------
1241 dnl GNAT projects are configured with ".gpr" project files.
1242 dnl GNAT libraries are a further development, using the project feature.
1243 AC_DEFUN([CF_GNAT_PROJECTS],
1244 [
1245 AC_REQUIRE([CF_GNAT_VERSION])
1246 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
1247
1248 cf_gnat_libraries=no
1249 cf_gnat_projects=no
1250
1251 if test "$enable_gnat_projects" != no ; then
1252 AC_MSG_CHECKING(if GNAT supports project files)
1253 case $cf_gnat_version in #(vi
1254 3.[[0-9]]*) #(vi
1255         ;;
1256 *)
1257         case $cf_cv_system_name in #(vi
1258         cygwin*|msys*) #(vi
1259                 ;;
1260         *)
1261                 mkdir conftest.src conftest.bin conftest.lib
1262                 cd conftest.src
1263                 rm -rf conftest* *~conftest*
1264                 cat >>library.gpr <<CF_EOF
1265 project Library is
1266   Kind := External ("LIB_KIND");
1267   for Library_Name use "ConfTest";
1268   for Object_Dir use ".";
1269   for Library_ALI_Dir use External("LIBRARY_DIR");
1270   for Library_Version use External ("SONAME");
1271   for Library_Kind use Kind;
1272   for Library_Dir use External("BUILD_DIR");
1273   Source_Dir := External ("SOURCE_DIR");
1274   for Source_Dirs use (Source_Dir);
1275 end Library;
1276 CF_EOF
1277                 cat >>confpackage.ads <<CF_EOF
1278 package ConfPackage is
1279    procedure conftest;
1280 end ConfPackage;
1281 CF_EOF
1282                 cat >>confpackage.adb <<CF_EOF
1283 with Text_IO;
1284 package body ConfPackage is
1285    procedure conftest is
1286    begin
1287       Text_IO.Put ("Hello World");
1288       Text_IO.New_Line;
1289    end conftest;
1290 end ConfPackage;
1291 CF_EOF
1292                 if ( $cf_ada_make $ADAFLAGS \
1293                                 -Plibrary.gpr \
1294                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
1295                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
1296                                 -XSOURCE_DIR=`pwd` \
1297                                 -XSONAME=libConfTest.so.1 \
1298                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1299                         cf_gnat_projects=yes
1300                 fi
1301                 cd ..
1302                 if test -f conftest.lib/confpackage.ali
1303                 then
1304                         cf_gnat_libraries=yes
1305                 fi
1306                 rm -rf conftest* *~conftest*
1307                 ;;
1308         esac
1309         ;;
1310 esac
1311 AC_MSG_RESULT($cf_gnat_projects)
1312 fi # enable_gnat_projects
1313
1314 if test $cf_gnat_projects = yes
1315 then
1316         AC_MSG_CHECKING(if GNAT supports libraries)
1317         AC_MSG_RESULT($cf_gnat_libraries)
1318 fi
1319
1320 if test "$cf_gnat_projects" = yes
1321 then
1322         USE_OLD_MAKERULES="#"
1323         USE_GNAT_PROJECTS=""
1324 else
1325         USE_OLD_MAKERULES=""
1326         USE_GNAT_PROJECTS="#"
1327 fi
1328
1329 if test "$cf_gnat_libraries" = yes
1330 then
1331         USE_GNAT_LIBRARIES=""
1332 else
1333         USE_GNAT_LIBRARIES="#"
1334 fi
1335
1336 AC_SUBST(USE_OLD_MAKERULES)
1337 AC_SUBST(USE_GNAT_PROJECTS)
1338 AC_SUBST(USE_GNAT_LIBRARIES)
1339 ])dnl
1340 dnl ---------------------------------------------------------------------------
1341 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
1342 dnl --------------
1343 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1344 dnl is noted that gnat may compile a tasking unit even for configurations which
1345 dnl fail at runtime.
1346 AC_DEFUN([CF_GNAT_SIGINT],[
1347 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1348 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1349
1350 package ConfTest is
1351
1352    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1353    pragma Unreserve_All_Interrupts;
1354    pragma Warnings (On);
1355
1356    protected Process is
1357       procedure Stop;
1358       function Continue return Boolean;
1359       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1360    private
1361       Done : Boolean := False;
1362    end Process;
1363
1364 end ConfTest;],
1365 [package body ConfTest is
1366    protected body Process is
1367       procedure Stop is
1368       begin
1369          Done := True;
1370       end Stop;
1371       function Continue return Boolean is
1372       begin
1373          return not Done;
1374       end Continue;
1375    end Process;
1376 end ConfTest;],
1377         [cf_cv_gnat_sigint=yes],
1378         [cf_cv_gnat_sigint=no])])
1379
1380 if test $cf_cv_gnat_sigint = yes ; then
1381         USE_GNAT_SIGINT=""
1382 else
1383         USE_GNAT_SIGINT="#"
1384 fi
1385 AC_SUBST(USE_GNAT_SIGINT)
1386 ])dnl
1387 dnl ---------------------------------------------------------------------------
1388 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
1389 dnl ----------------
1390 dnl Verify that a test program compiles/links with GNAT.
1391 dnl $cf_ada_make is set to the program that compiles/links
1392 dnl $ADAFLAGS may be set to the GNAT flags.
1393 dnl
1394 dnl $1 is the text of the spec
1395 dnl $2 is the text of the body
1396 dnl $3 is the shell command to execute if successful
1397 dnl $4 is the shell command to execute if not successful
1398 AC_DEFUN([CF_GNAT_TRY_LINK],
1399 [
1400 rm -rf conftest* *~conftest*
1401 cat >>conftest.ads <<CF_EOF
1402 $1
1403 CF_EOF
1404 cat >>conftest.adb <<CF_EOF
1405 $2
1406 CF_EOF
1407 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1408 ifelse($3,,      :,[      $3])
1409 ifelse($4,,,[else
1410    $4])
1411 fi
1412 rm -rf conftest* *~conftest*
1413 ])dnl
1414 dnl ---------------------------------------------------------------------------
1415 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
1416 dnl ---------------
1417 dnl Verify that a test program compiles and runs with GNAT
1418 dnl $cf_ada_make is set to the program that compiles/links
1419 dnl $ADAFLAGS may be set to the GNAT flags.
1420 dnl
1421 dnl $1 is the text of the spec
1422 dnl $2 is the text of the body
1423 dnl $3 is the shell command to execute if successful
1424 dnl $4 is the shell command to execute if not successful
1425 AC_DEFUN([CF_GNAT_TRY_RUN],
1426 [
1427 rm -rf conftest* *~conftest*
1428 cat >>conftest.ads <<CF_EOF
1429 $1
1430 CF_EOF
1431 cat >>conftest.adb <<CF_EOF
1432 $2
1433 CF_EOF
1434 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1435    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1436 ifelse($3,,      :,[      $3])
1437 ifelse($4,,,[   else
1438       $4])
1439    fi
1440 ifelse($4,,,[else
1441    $4])
1442 fi
1443 rm -rf conftest* *~conftest*
1444 ])dnl
1445 dnl ---------------------------------------------------------------------------
1446 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
1447 dnl ---------------
1448 dnl Verify version of GNAT.
1449 AC_DEFUN([CF_GNAT_VERSION],
1450 [
1451 AC_MSG_CHECKING(for gnat version)
1452 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
1453         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1454     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1455 AC_MSG_RESULT($cf_gnat_version)
1456
1457 case $cf_gnat_version in #(vi
1458 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
1459         cf_cv_prog_gnat_correct=yes
1460         ;;
1461 *)
1462         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1463         cf_cv_prog_gnat_correct=no
1464         ;;
1465 esac
1466 ])
1467 dnl ---------------------------------------------------------------------------
1468 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
1469 dnl -------------
1470 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1471 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1472 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1473 dnl since it is interwoven with GNU extensions.
1474 dnl
1475 dnl Well, yes we could work around it...
1476 AC_DEFUN([CF_GNU_SOURCE],
1477 [
1478 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1479 AC_TRY_COMPILE([#include <sys/types.h>],[
1480 #ifndef _XOPEN_SOURCE
1481 make an error
1482 #endif],
1483         [cf_cv_gnu_source=no],
1484         [cf_save="$CPPFLAGS"
1485          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1486          AC_TRY_COMPILE([#include <sys/types.h>],[
1487 #ifdef _XOPEN_SOURCE
1488 make an error
1489 #endif],
1490         [cf_cv_gnu_source=no],
1491         [cf_cv_gnu_source=yes])
1492         CPPFLAGS="$cf_save"
1493         ])
1494 ])
1495 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1496 ])dnl
1497 dnl ---------------------------------------------------------------------------
1498 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
1499 dnl --------------
1500 dnl Construct a search-list of directories for a nonstandard header-file
1501 dnl
1502 dnl Parameters
1503 dnl     $1 = the variable to return as result
1504 dnl     $2 = the package name
1505 AC_DEFUN([CF_HEADER_PATH],
1506 [
1507 $1=
1508
1509 # collect the current set of include-directories from compiler flags
1510 cf_header_path_list=""
1511 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1512         for cf_header_path in $CPPFLAGS $CFLAGS
1513         do
1514                 case $cf_header_path in #(vi
1515                 -I*)
1516                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1517                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1518                         cf_header_path_list="$cf_header_path_list [$]$1"
1519                         ;;
1520                 esac
1521         done
1522 fi
1523
1524 # add the variations for the package we are looking for
1525 CF_SUBDIR_PATH($1,$2,include)
1526
1527 test "$includedir" != NONE && \
1528 test "$includedir" != "/usr/include" && \
1529 test -d "$includedir" && {
1530         test -d $includedir &&    $1="[$]$1 $includedir"
1531         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1532 }
1533
1534 test "$oldincludedir" != NONE && \
1535 test "$oldincludedir" != "/usr/include" && \
1536 test -d "$oldincludedir" && {
1537         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1538         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1539 }
1540
1541 $1="[$]$1 $cf_header_path_list"
1542 ])dnl
1543 dnl ---------------------------------------------------------------------------
1544 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1545 dnl ---------------
1546 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1547 AC_DEFUN([CF_HELP_MESSAGE],
1548 [AC_DIVERT_HELP([$1])dnl
1549 ])dnl
1550 dnl ---------------------------------------------------------------------------
1551 dnl CF_INCLUDE_DIRS version: 9 updated: 2014/07/26 18:54:28
1552 dnl ---------------
1553 dnl Construct the list of include-options according to whether we're building
1554 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
1555 dnl with gcc, don't append the includedir if it happens to be /usr/include,
1556 dnl since that usually breaks gcc's shadow-includes.
1557 AC_DEFUN([CF_INCLUDE_DIRS],
1558 [
1559 if test "$GCC" != yes; then
1560         CPPFLAGS="-I\${includedir} $CPPFLAGS"
1561 elif test "$includedir" != "/usr/include"; then
1562         if test "$includedir" = '${prefix}/include' ; then
1563                 if test x$prefix != x/usr ; then
1564                         CPPFLAGS="-I\${includedir} $CPPFLAGS"
1565                 fi
1566         else
1567                 CPPFLAGS="-I\${includedir} $CPPFLAGS"
1568         fi
1569 fi
1570 if test "$srcdir" != "."; then
1571         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
1572 fi
1573 CPPFLAGS="-I../include $CPPFLAGS"
1574 if test "$srcdir" != "."; then
1575         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
1576 fi
1577 CPPFLAGS="-I. $CPPFLAGS"
1578 AC_SUBST(CPPFLAGS)
1579 ])dnl
1580 dnl ---------------------------------------------------------------------------
1581 dnl CF_INTEL_COMPILER version: 6 updated: 2014/03/17 13:13:07
1582 dnl -----------------
1583 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1584 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1585 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1586 dnl
1587 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1588 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1589 dnl the wrappers for gcc and g++ warnings.
1590 dnl
1591 dnl $1 = GCC (default) or GXX
1592 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1593 dnl $3 = CFLAGS (default) or CXXFLAGS
1594 AC_DEFUN([CF_INTEL_COMPILER],[
1595 AC_REQUIRE([AC_CANONICAL_HOST])
1596 ifelse([$2],,INTEL_COMPILER,[$2])=no
1597
1598 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1599         case $host_os in
1600         linux*|gnu*)
1601                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1602                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1603                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1604                 AC_TRY_COMPILE([],[
1605 #ifdef __INTEL_COMPILER
1606 #else
1607 make an error
1608 #endif
1609 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1610 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
1611 ],[])
1612                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1613                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1614                 ;;
1615         esac
1616 fi
1617 ])dnl
1618 dnl ---------------------------------------------------------------------------
1619 dnl CF_LARGEFILE version: 8 updated: 2012/10/06 08:57:51
1620 dnl ------------
1621 dnl Add checks for large file support.
1622 AC_DEFUN([CF_LARGEFILE],[
1623 ifdef([AC_FUNC_FSEEKO],[
1624     AC_SYS_LARGEFILE
1625     if test "$enable_largefile" != no ; then
1626         AC_FUNC_FSEEKO
1627
1628         # Normally we would collect these definitions in the config.h,
1629         # but (like _XOPEN_SOURCE), some environments rely on having these
1630         # defined before any of the system headers are included.  Another
1631         # case comes up with C++, e.g., on AIX the compiler compiles the
1632         # header files by themselves before looking at the body files it is
1633         # told to compile.  For ncurses, those header files do not include
1634         # the config.h
1635         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
1636         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
1637         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
1638
1639         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
1640                 AC_TRY_COMPILE([
1641 #include <sys/types.h>
1642 #include <dirent.h>
1643                 ],[
1644                 /* if transitional largefile support is setup, this is true */
1645                 extern struct dirent64 * readdir(DIR *);
1646                 struct dirent64 *x = readdir((DIR *)0);
1647                 struct dirent *y = readdir((DIR *)0);
1648                 int z = x - y;
1649                 ],
1650                 [cf_cv_struct_dirent64=yes],
1651                 [cf_cv_struct_dirent64=no])
1652         ])
1653         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
1654     fi
1655 ])
1656 ])
1657 dnl ---------------------------------------------------------------------------
1658 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
1659 dnl ---------------
1660 dnl For the given system and compiler, find the compiler flags to pass to the
1661 dnl loader to use the "rpath" feature.
1662 AC_DEFUN([CF_LD_RPATH_OPT],
1663 [
1664 AC_REQUIRE([CF_CHECK_CACHE])
1665
1666 LD_RPATH_OPT=
1667 AC_MSG_CHECKING(for an rpath option)
1668 case $cf_cv_system_name in #(vi
1669 irix*) #(vi
1670         if test "$GCC" = yes; then
1671                 LD_RPATH_OPT="-Wl,-rpath,"
1672         else
1673                 LD_RPATH_OPT="-rpath "
1674         fi
1675         ;;
1676 linux*|gnu*|k*bsd*-gnu) #(vi
1677         LD_RPATH_OPT="-Wl,-rpath,"
1678         ;;
1679 openbsd[[2-9]].*|mirbsd*) #(vi
1680         LD_RPATH_OPT="-Wl,-rpath,"
1681         ;;
1682 dragonfly*|freebsd*) #(vi
1683         LD_RPATH_OPT="-rpath "
1684         ;;
1685 netbsd*) #(vi
1686         LD_RPATH_OPT="-Wl,-rpath,"
1687         ;;
1688 osf*|mls+*) #(vi
1689         LD_RPATH_OPT="-rpath "
1690         ;;
1691 solaris2*) #(vi
1692         LD_RPATH_OPT="-R"
1693         ;;
1694 *)
1695         ;;
1696 esac
1697 AC_MSG_RESULT($LD_RPATH_OPT)
1698
1699 case "x$LD_RPATH_OPT" in #(vi
1700 x-R*)
1701         AC_MSG_CHECKING(if we need a space after rpath option)
1702         cf_save_LIBS="$LIBS"
1703         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1704         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1705         LIBS="$cf_save_LIBS"
1706         AC_MSG_RESULT($cf_rpath_space)
1707         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1708         ;;
1709 esac
1710 ])dnl
1711 dnl ---------------------------------------------------------------------------
1712 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
1713 dnl ---------------
1714 dnl Construct a search-list of directories for a nonstandard library-file
1715 dnl
1716 dnl Parameters
1717 dnl     $1 = the variable to return as result
1718 dnl     $2 = the package name
1719 AC_DEFUN([CF_LIBRARY_PATH],
1720 [
1721 $1=
1722 cf_library_path_list=""
1723 if test -n "${LDFLAGS}${LIBS}" ; then
1724         for cf_library_path in $LDFLAGS $LIBS
1725         do
1726                 case $cf_library_path in #(vi
1727                 -L*)
1728                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1729                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1730                         cf_library_path_list="$cf_library_path_list [$]$1"
1731                         ;;
1732                 esac
1733         done
1734 fi
1735
1736 CF_SUBDIR_PATH($1,$2,lib)
1737
1738 $1="$cf_library_path_list [$]$1"
1739 ])dnl
1740 dnl ---------------------------------------------------------------------------
1741 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
1742 dnl -------------
1743 dnl Compute the library-prefix for the given host system
1744 dnl $1 = variable to set
1745 define([CF_LIB_PREFIX],
1746 [
1747         case $cf_cv_system_name in #(vi
1748         OS/2*|os2*) #(vi
1749         LIB_PREFIX=''
1750         ;;
1751         *)      LIB_PREFIX='lib'
1752         ;;
1753         esac
1754 ifelse($1,,,[$1=$LIB_PREFIX])
1755         AC_SUBST(LIB_PREFIX)
1756 ])dnl
1757 dnl ---------------------------------------------------------------------------
1758 dnl CF_LIB_SUFFIX version: 23 updated: 2014/06/21 17:47:12
1759 dnl -------------
1760 dnl Compute the library file-suffix from the given model name
1761 dnl $1 = model name
1762 dnl $2 = variable to set (the nominal library suffix)
1763 dnl $3 = dependency variable to set (actual filename)
1764 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1765 AC_DEFUN([CF_LIB_SUFFIX],
1766 [
1767         case X$1 in #(vi
1768         Xlibtool) #(vi
1769                 $2='.la'
1770                 $3=[$]$2
1771                 ;;
1772         Xdebug) #(vi
1773                 $2='_g.a'
1774                 $3=[$]$2
1775                 ;;
1776         Xprofile) #(vi
1777                 $2='_p.a'
1778                 $3=[$]$2
1779                 ;;
1780         Xshared) #(vi
1781                 case $cf_cv_system_name in
1782                 aix[[5-7]]*) #(vi
1783                         $2='.so'
1784                         $3=[$]$2
1785                         ;;
1786                 cygwin*|msys*|mingw*) #(vi
1787                         $2='.dll'
1788                         $3='.dll.a'
1789                         ;;
1790                 darwin*) #(vi
1791                         $2='.dylib'
1792                         $3=[$]$2
1793                         ;;
1794                 hpux*) #(vi
1795                         case $target in
1796                         ia64*) #(vi
1797                                 $2='.so'
1798                                 $3=[$]$2
1799                                 ;;
1800                         *) #(vi
1801                                 $2='.sl'
1802                                 $3=[$]$2
1803                                 ;;
1804                         esac
1805                         ;;
1806                 *) #(vi
1807                         $2='.so'
1808                         $3=[$]$2
1809                         ;;
1810                 esac
1811                 ;;
1812         *)
1813                 $2='.a'
1814                 $3=[$]$2
1815                 ;;
1816         esac
1817         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1818         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
1819 ])dnl
1820 dnl ---------------------------------------------------------------------------
1821 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
1822 dnl -----------
1823 dnl Compute the string to append to -library from the given model name
1824 dnl $1 = model name
1825 dnl $2 = variable to set
1826 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1827 AC_DEFUN([CF_LIB_TYPE],
1828 [
1829         case $1 in
1830         libtool) $2=''   ;;
1831         normal)  $2=''   ;;
1832         debug)   $2='_g' ;;
1833         profile) $2='_p' ;;
1834         shared)  $2=''   ;;
1835         esac
1836         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1837 ])dnl
1838 dnl ---------------------------------------------------------------------------
1839 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
1840 dnl ----------------
1841 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
1842 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
1843 dnl have to provide wrappers for global tables to ensure they're linked
1844 dnl properly.
1845 AC_DEFUN([CF_LINK_DATAONLY],
1846 [
1847 AC_MSG_CHECKING([if data-only library module links])
1848 AC_CACHE_VAL(cf_cv_link_dataonly,[
1849         rm -f conftest.a
1850         cat >conftest.$ac_ext <<EOF
1851 #line __oline__ "configure"
1852 int     testdata[[3]] = { 123, 456, 789 };
1853 EOF
1854         if AC_TRY_EVAL(ac_compile) ; then
1855                 mv conftest.o data.o && \
1856                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
1857         fi
1858         rm -f conftest.$ac_ext data.o
1859         cat >conftest.$ac_ext <<EOF
1860 #line __oline__ "configure"
1861 int     testfunc()
1862 {
1863 #if defined(NeXT)
1864         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
1865 #else
1866         extern int testdata[[3]];
1867         return testdata[[0]] == 123
1868            &&  testdata[[1]] == 456
1869            &&  testdata[[2]] == 789;
1870 #endif
1871 }
1872 EOF
1873         if AC_TRY_EVAL(ac_compile); then
1874                 mv conftest.o func.o && \
1875                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
1876         fi
1877         rm -f conftest.$ac_ext func.o
1878         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
1879         cf_saveLIBS="$LIBS"
1880         LIBS="conftest.a $LIBS"
1881         AC_TRY_RUN([
1882         int main()
1883         {
1884                 extern int testfunc();
1885                 ${cf_cv_main_return:-return} (!testfunc());
1886         }
1887         ],
1888         [cf_cv_link_dataonly=yes],
1889         [cf_cv_link_dataonly=no],
1890         [cf_cv_link_dataonly=unknown])
1891         LIBS="$cf_saveLIBS"
1892         ])
1893 AC_MSG_RESULT($cf_cv_link_dataonly)
1894
1895 if test "$cf_cv_link_dataonly" = no ; then
1896         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
1897         BROKEN_LINKER=1
1898 fi
1899
1900 ])dnl
1901 dnl ---------------------------------------------------------------------------
1902 dnl CF_MAKEFLAGS version: 15 updated: 2014/05/10 16:43:23
1903 dnl ------------
1904 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
1905 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
1906 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
1907 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
1908 AC_DEFUN([CF_MAKEFLAGS],
1909 [
1910 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
1911         cf_cv_makeflags=''
1912         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
1913         do
1914                 cat >cf_makeflags.tmp <<CF_EOF
1915 SHELL = /bin/sh
1916 all :
1917         @ echo '.$cf_option'
1918 CF_EOF
1919                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
1920                 case "$cf_result" in
1921                 .*k|.*kw)
1922                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
1923                         case "$cf_result" in
1924                         .*CC=*) cf_cv_makeflags=
1925                                 ;;
1926                         *)      cf_cv_makeflags=$cf_option
1927                                 ;;
1928                         esac
1929                         break
1930                         ;;
1931                 .-)     ;;
1932                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
1933                         ;;
1934                 esac
1935         done
1936         rm -f cf_makeflags.tmp
1937 ])
1938
1939 AC_SUBST(cf_cv_makeflags)
1940 ])dnl
1941 dnl ---------------------------------------------------------------------------
1942 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1943 dnl ------------
1944 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1945 dnl a monocase filesystem.
1946 AC_DEFUN([CF_MAKE_TAGS],[
1947 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1948
1949 AC_CHECK_PROGS(CTAGS, exctags ctags)
1950 AC_CHECK_PROGS(ETAGS, exetags etags)
1951
1952 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1953
1954 if test "$cf_cv_mixedcase" = yes ; then
1955         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1956 else
1957         MAKE_UPPER_TAGS=no
1958 fi
1959
1960 if test "$MAKE_UPPER_TAGS" = yes ; then
1961         MAKE_UPPER_TAGS=
1962 else
1963         MAKE_UPPER_TAGS="#"
1964 fi
1965
1966 if test "$MAKE_LOWER_TAGS" = yes ; then
1967         MAKE_LOWER_TAGS=
1968 else
1969         MAKE_LOWER_TAGS="#"
1970 fi
1971
1972 AC_SUBST(CTAGS)
1973 AC_SUBST(ETAGS)
1974
1975 AC_SUBST(MAKE_UPPER_TAGS)
1976 AC_SUBST(MAKE_LOWER_TAGS)
1977 ])dnl
1978 dnl ---------------------------------------------------------------------------
1979 dnl CF_MIXEDCASE_FILENAMES version: 6 updated: 2013/10/08 17:47:05
1980 dnl ----------------------
1981 dnl Check if the file-system supports mixed-case filenames.  If we're able to
1982 dnl create a lowercase name and see it as uppercase, it doesn't support that.
1983 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
1984 [
1985 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
1986 if test "$cross_compiling" = yes ; then
1987         case $target_alias in #(vi
1988         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*) #(vi
1989                 cf_cv_mixedcase=no
1990                 ;;
1991         *)
1992                 cf_cv_mixedcase=yes
1993                 ;;
1994         esac
1995 else
1996         rm -f conftest CONFTEST
1997         echo test >conftest
1998         if test -f CONFTEST ; then
1999                 cf_cv_mixedcase=no
2000         else
2001                 cf_cv_mixedcase=yes
2002         fi
2003         rm -f conftest CONFTEST
2004 fi
2005 ])
2006 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2007 ])dnl
2008 dnl ---------------------------------------------------------------------------
2009 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
2010 dnl ----------
2011 dnl Check for a working mkstemp.  This creates two files, checks that they are
2012 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2013 AC_DEFUN([CF_MKSTEMP],[
2014 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2015 rm -rf conftest*
2016 AC_TRY_RUN([
2017 #include <sys/types.h>
2018 #include <stdlib.h>
2019 #include <stdio.h>
2020 #include <string.h>
2021 #include <sys/stat.h>
2022 int main()
2023 {
2024         char *tmpl = "conftestXXXXXX";
2025         char name[2][80];
2026         int n;
2027         int result = 0;
2028         int fd;
2029         struct stat sb;
2030
2031         umask(077);
2032         for (n = 0; n < 2; ++n) {
2033                 strcpy(name[n], tmpl);
2034                 if ((fd = mkstemp(name[n])) >= 0) {
2035                         if (!strcmp(name[n], tmpl)
2036                          || stat(name[n], &sb) != 0
2037                          || (sb.st_mode & S_IFMT) != S_IFREG
2038                          || (sb.st_mode & 077) != 0) {
2039                                 result = 1;
2040                         }
2041                         close(fd);
2042                 }
2043         }
2044         if (result == 0
2045          && !strcmp(name[0], name[1]))
2046                 result = 1;
2047         ${cf_cv_main_return:-return}(result);
2048 }
2049 ],[cf_cv_func_mkstemp=yes
2050 ],[cf_cv_func_mkstemp=no
2051 ],[cf_cv_func_mkstemp=maybe])
2052 ])
2053 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2054         AC_CHECK_FUNC(mkstemp)
2055 fi
2056 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2057         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2058 fi
2059 ])dnl
2060 dnl ---------------------------------------------------------------------------
2061 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2062 dnl ----------
2063 dnl Write a debug message to config.log, along with the line number in the
2064 dnl configure script.
2065 AC_DEFUN([CF_MSG_LOG],[
2066 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2067 ])dnl
2068 dnl ---------------------------------------------------------------------------
2069 dnl CF_NCURSES_ADDON version: 4 updated: 2011/03/27 17:10:13
2070 dnl ----------------
2071 dnl Configure an ncurses add-on, built outside the ncurses tree.
2072 AC_DEFUN([CF_NCURSES_ADDON],[
2073
2074 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2075
2076 AC_MSG_CHECKING(if you want wide-character code)
2077 AC_ARG_ENABLE(widec,
2078         [  --enable-widec          compile with wide-char/UTF-8 code],
2079         [with_widec=$enableval],
2080         [with_widec=no])
2081 AC_MSG_RESULT($with_widec)
2082 if test "$with_widec" = yes ; then
2083         CF_UTF8_LIB 
2084         CF_NCURSES_CONFIG(ncursesw)
2085 else
2086         CF_NCURSES_CONFIG(ncurses)
2087 fi
2088
2089 if test "$NCURSES_CONFIG" != none ; then
2090
2091 cf_version=`$NCURSES_CONFIG --version`
2092
2093 NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2094 NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2095 NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2096
2097 # ABI version is not available from headers
2098 cf_cv_abi_version=`$NCURSES_CONFIG --abi-version`
2099
2100 else
2101
2102 for cf_name in MAJOR MINOR PATCH
2103 do
2104 cat >conftest.$ac_ext <<CF_EOF
2105 #include <${cf_cv_ncurses_header:-curses.h}>
2106 AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2107 CF_EOF
2108         cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2109         AC_TRY_EVAL(cf_try)
2110         if test -f conftest.out ; then
2111                 cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]][[    ]]*//"`
2112                 eval NCURSES_$cf_name=\"$cf_result\"
2113                 # cat conftest.$ac_ext
2114                 # cat conftest.out
2115         fi
2116 done
2117
2118 cf_cv_abi_version=${NCURSES_MAJOR}
2119
2120 fi
2121
2122 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2123
2124 dnl Show the computed version, for logging
2125 cf_cv_timestamp=`date`
2126
2127 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2128
2129 dnl We need these values in the generated headers
2130 AC_SUBST(NCURSES_MAJOR)
2131 AC_SUBST(NCURSES_MINOR)
2132 AC_SUBST(NCURSES_PATCH)
2133
2134 dnl We need these values in the generated makefiles
2135 AC_SUBST(cf_cv_rel_version)
2136 AC_SUBST(cf_cv_abi_version)
2137
2138 dnl FIXME - not needed for Ada95
2139 AC_SUBST(cf_cv_builtin_bool)
2140 AC_SUBST(cf_cv_header_stdbool_h)
2141 AC_SUBST(cf_cv_type_of_bool)dnl
2142
2143 ])
2144 dnl ---------------------------------------------------------------------------
2145 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2146 dnl -------------------
2147 dnl Check if we can compile with ncurses' header file
2148 dnl $1 is the cache variable to set
2149 dnl $2 is the header-file to include
2150 dnl $3 is the root name (ncurses or ncursesw)
2151 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2152         AC_TRY_COMPILE([
2153 ]ifelse($3,ncursesw,[
2154 #define _XOPEN_SOURCE_EXTENDED
2155 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2156 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2157 ])[
2158 #include <$2>],[
2159 #ifdef NCURSES_VERSION
2160 ]ifelse($3,ncursesw,[
2161 #ifndef WACS_BSSB
2162         make an error
2163 #endif
2164 ])[
2165 printf("%s\n", NCURSES_VERSION);
2166 #else
2167 #ifdef __NCURSES_H
2168 printf("old\n");
2169 #else
2170         make an error
2171 #endif
2172 #endif
2173         ]
2174         ,[$1=$2]
2175         ,[$1=no])
2176 ])dnl
2177 dnl ---------------------------------------------------------------------------
2178 dnl CF_NCURSES_CONFIG version: 10 updated: 2012/10/06 08:57:51
2179 dnl -----------------
2180 dnl Tie together the configure-script macros for ncurses.
2181 dnl Prefer the "-config" script from ncurses 6.x, to simplify analysis.
2182 dnl Allow that to be overridden using the $NCURSES_CONFIG environment variable.
2183 dnl
2184 dnl $1 is the root library name (default: "ncurses")
2185 AC_DEFUN([CF_NCURSES_CONFIG],
2186 [
2187 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2188
2189 echo "Looking for ${cf_ncuconfig_root}-config"
2190
2191 CF_ACVERSION_CHECK(2.52,
2192         [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2193         [AC_PATH_PROGS(NCURSES_CONFIG, ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2194
2195 if test "$NCURSES_CONFIG" != none ; then
2196
2197 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
2198 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2199
2200 # even with config script, some packages use no-override for curses.h
2201 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2202
2203 dnl like CF_NCURSES_CPPFLAGS
2204 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2205
2206 dnl like CF_NCURSES_LIBS
2207 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2208 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2209
2210 dnl like CF_NCURSES_VERSION
2211 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2212
2213 else
2214
2215 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2216 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2217
2218 fi
2219 ])dnl
2220 dnl ---------------------------------------------------------------------------
2221 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2222 dnl -------------------
2223 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2224 dnl the CPPFLAGS variable so we can include its header.
2225 dnl
2226 dnl The header files may be installed as either curses.h, or ncurses.h (would
2227 dnl be obsolete, except that some packagers prefer this name to distinguish it
2228 dnl from a "native" curses implementation).  If not installed for overwrite,
2229 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2230 dnl /usr/include/ncurses), but someone may have installed overwriting the
2231 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2232 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2233 dnl the header.
2234 dnl
2235 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2236 dnl is already in the include-path, don't even bother with this, since we cannot
2237 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2238 dnl
2239 dnl The optional parameter gives the root name of the library, in case it is
2240 dnl not installed as the default curses library.  That is how the
2241 dnl wide-character version of ncurses is installed.
2242 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2243 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2244
2245 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2246 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2247
2248 test -n "$cf_cv_curses_dir" && \
2249 test "$cf_cv_curses_dir" != "no" && { \
2250   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2251 }
2252
2253 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2254         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2255         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2256         for cf_header in $cf_header_list
2257         do
2258                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2259                 test "$cf_cv_ncurses_h" != no && break
2260         done
2261 ])
2262
2263 CF_NCURSES_HEADER
2264 CF_TERM_HEADER
2265
2266 # some applications need this, but should check for NCURSES_VERSION
2267 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2268
2269 CF_NCURSES_VERSION
2270 ])dnl
2271 dnl ---------------------------------------------------------------------------
2272 dnl CF_NCURSES_HEADER version: 3 updated: 2012/10/06 08:57:51
2273 dnl -----------------
2274 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2275 dnl variations of ncurses' installs.
2276 dnl
2277 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2278 AC_DEFUN([CF_NCURSES_HEADER],[
2279
2280 if test "$cf_cv_ncurses_h" != no ; then
2281         cf_cv_ncurses_header=$cf_cv_ncurses_h
2282 else
2283
2284 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2285         test -n "$verbose" && echo
2286         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2287         test -n "$verbose" && echo search path $cf_search
2288         cf_save2_CPPFLAGS="$CPPFLAGS"
2289         for cf_incdir in $cf_search
2290         do
2291                 CF_ADD_INCDIR($cf_incdir)
2292                 for cf_header in \
2293                         ncurses.h \
2294                         curses.h
2295                 do
2296                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2297                         if test "$cf_cv_ncurses_h2" != no ; then
2298                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2299                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2300                                 break
2301                         fi
2302                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2303                 done
2304                 CPPFLAGS="$cf_save2_CPPFLAGS"
2305                 test "$cf_cv_ncurses_h2" != no && break
2306         done
2307         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2308         ])
2309
2310         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2311         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2312         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2313                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2314         fi
2315         CF_ADD_INCDIR($cf_1st_incdir)
2316
2317 fi
2318
2319 # Set definitions to allow ifdef'ing for ncurses.h
2320
2321 case $cf_cv_ncurses_header in # (vi
2322 *ncurses.h)
2323         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2324         ;;
2325 esac
2326
2327 case $cf_cv_ncurses_header in # (vi
2328 ncurses/curses.h|ncurses/ncurses.h)
2329         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2330         ;;
2331 ncursesw/curses.h|ncursesw/ncurses.h)
2332         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2333         ;;
2334 esac
2335
2336 ])dnl
2337 dnl ---------------------------------------------------------------------------
2338 dnl CF_NCURSES_LIBS version: 16 updated: 2010/11/20 17:02:38
2339 dnl ---------------
2340 dnl Look for the ncurses library.  This is a little complicated on Linux,
2341 dnl because it may be linked with the gpm (general purpose mouse) library.
2342 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2343 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2344 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2345 dnl and the linker will record a dependency.
2346 dnl
2347 dnl The optional parameter gives the root name of the library, in case it is
2348 dnl not installed as the default curses library.  That is how the
2349 dnl wide-character version of ncurses is installed.
2350 AC_DEFUN([CF_NCURSES_LIBS],
2351 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2352
2353 cf_nculib_root=ifelse($1,,ncurses,$1)
2354         # This works, except for the special case where we find gpm, but
2355         # ncurses is in a nonstandard location via $LIBS, and we really want
2356         # to link gpm.
2357 cf_ncurses_LIBS=""
2358 cf_ncurses_SAVE="$LIBS"
2359 AC_CHECK_LIB(gpm,Gpm_Open,
2360         [AC_CHECK_LIB(gpm,initscr,
2361                 [LIBS="$cf_ncurses_SAVE"],
2362                 [cf_ncurses_LIBS="-lgpm"])])
2363
2364 case $host_os in #(vi
2365 freebsd*)
2366         # This is only necessary if you are linking against an obsolete
2367         # version of ncurses (but it should do no harm, since it's static).
2368         if test "$cf_nculib_root" = ncurses ; then
2369                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2370         fi
2371         ;;
2372 esac
2373
2374 CF_ADD_LIBS($cf_ncurses_LIBS)
2375
2376 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2377 then
2378         CF_ADD_LIBS(-l$cf_nculib_root)
2379 else
2380         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2381                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2382                 [initscr()],
2383                 initscr)
2384 fi
2385
2386 if test -n "$cf_ncurses_LIBS" ; then
2387         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2388         cf_ncurses_SAVE="$LIBS"
2389         for p in $cf_ncurses_LIBS ; do
2390                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2391                 if test "$q" != "$LIBS" ; then
2392                         LIBS="$q"
2393                 fi
2394         done
2395         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2396                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2397                 [AC_MSG_RESULT(yes)],
2398                 [AC_MSG_RESULT(no)
2399                  LIBS="$cf_ncurses_SAVE"])
2400 fi
2401
2402 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2403 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2404 ])dnl
2405 dnl ---------------------------------------------------------------------------
2406 dnl CF_NCURSES_VERSION version: 14 updated: 2012/10/06 08:57:51
2407 dnl ------------------
2408 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2409 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2410 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2411 AC_DEFUN([CF_NCURSES_VERSION],
2412 [
2413 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2414 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2415         cf_cv_ncurses_version=no
2416         cf_tempfile=out$$
2417         rm -f $cf_tempfile
2418         AC_TRY_RUN([
2419 #include <${cf_cv_ncurses_header:-curses.h}>
2420 #include <stdio.h>
2421 int main()
2422 {
2423         FILE *fp = fopen("$cf_tempfile", "w");
2424 #ifdef NCURSES_VERSION
2425 # ifdef NCURSES_VERSION_PATCH
2426         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2427 # else
2428         fprintf(fp, "%s\n", NCURSES_VERSION);
2429 # endif
2430 #else
2431 # ifdef __NCURSES_H
2432         fprintf(fp, "old\n");
2433 # else
2434         make an error
2435 # endif
2436 #endif
2437         ${cf_cv_main_return:-return}(0);
2438 }],[
2439         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2440
2441         # This will not work if the preprocessor splits the line after the
2442         # Autoconf token.  The 'unproto' program does that.
2443         cat > conftest.$ac_ext <<EOF
2444 #include <${cf_cv_ncurses_header:-curses.h}>
2445 #undef Autoconf
2446 #ifdef NCURSES_VERSION
2447 Autoconf NCURSES_VERSION
2448 #else
2449 #ifdef __NCURSES_H
2450 Autoconf "old"
2451 #endif
2452 ;
2453 #endif
2454 EOF
2455         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2456         AC_TRY_EVAL(cf_try)
2457         if test -f conftest.out ; then
2458                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2459                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2460                 rm -f conftest.out
2461         fi
2462 ])
2463         rm -f $cf_tempfile
2464 ])
2465 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2466 ])dnl
2467 dnl ---------------------------------------------------------------------------
2468 dnl CF_OBJ_SUBDIR version: 6 updated: 2013/09/07 14:06:10
2469 dnl -------------
2470 dnl Compute the object-directory name from the given model name
2471 AC_DEFUN([CF_OBJ_SUBDIR],
2472 [
2473         case $1 in
2474         libtool) $2='obj_lo'  ;;
2475         normal)  $2='objects' ;;
2476         debug)   $2='obj_g' ;;
2477         profile) $2='obj_p' ;;
2478         shared)
2479                 case $cf_cv_system_name in #(vi
2480                 cygwin|msys) #(vi
2481                         $2='objects' ;;
2482                 *)
2483                         $2='obj_s' ;;
2484                 esac
2485         esac
2486 ])dnl
2487 dnl ---------------------------------------------------------------------------
2488 dnl CF_PATHSEP version: 6 updated: 2012/09/29 18:38:12
2489 dnl ----------
2490 dnl Provide a value for the $PATH and similar separator (or amend the value
2491 dnl as provided in autoconf 2.5x).
2492 AC_DEFUN([CF_PATHSEP],
2493 [
2494         AC_MSG_CHECKING(for PATH separator)
2495         case $cf_cv_system_name in
2496         os2*)   PATH_SEPARATOR=';'  ;;
2497         *)      ${PATH_SEPARATOR:=':'}  ;;
2498         esac
2499 ifelse([$1],,,[$1=$PATH_SEPARATOR])
2500         AC_SUBST(PATH_SEPARATOR)
2501         AC_MSG_RESULT($PATH_SEPARATOR)
2502 ])dnl
2503 dnl ---------------------------------------------------------------------------
2504 dnl CF_PATH_SYNTAX version: 14 updated: 2012/06/19 20:58:54
2505 dnl --------------
2506 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2507 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2508 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2509 dnl delayed evaluation of those symbols.
2510 AC_DEFUN([CF_PATH_SYNTAX],[
2511 if test "x$prefix" != xNONE; then
2512   cf_path_syntax="$prefix"
2513 else
2514   cf_path_syntax="$ac_default_prefix"
2515 fi
2516
2517 case ".[$]$1" in #(vi
2518 .\[$]\(*\)*|.\'*\'*) #(vi
2519   ;;
2520 ..|./*|.\\*) #(vi
2521   ;;
2522 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
2523   ;;
2524 .\[$]{*prefix}*|.\[$]{*dir}*) #(vi
2525   eval $1="[$]$1"
2526   case ".[$]$1" in #(vi
2527   .NONE/*)
2528     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2529     ;;
2530   esac
2531   ;; #(vi
2532 .no|.NONE/*)
2533   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2534   ;;
2535 *)
2536   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2537   ;;
2538 esac
2539 ])dnl
2540 dnl ---------------------------------------------------------------------------
2541 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
2542 dnl -------------
2543 dnl Check for the package-config program, unless disabled by command-line.
2544 AC_DEFUN([CF_PKG_CONFIG],
2545 [
2546 AC_MSG_CHECKING(if you want to use pkg-config)
2547 AC_ARG_WITH(pkg-config,
2548         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2549         [cf_pkg_config=$withval],
2550         [cf_pkg_config=yes])
2551 AC_MSG_RESULT($cf_pkg_config)
2552
2553 case $cf_pkg_config in #(vi
2554 no) #(vi
2555         PKG_CONFIG=none
2556         ;;
2557 yes) #(vi
2558         CF_ACVERSION_CHECK(2.52,
2559                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2560                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2561         ;;
2562 *)
2563         PKG_CONFIG=$withval
2564         ;;
2565 esac
2566
2567 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2568 if test "$PKG_CONFIG" != none ; then
2569         CF_PATH_SYNTAX(PKG_CONFIG)
2570 fi
2571
2572 AC_SUBST(PKG_CONFIG)
2573 ])dnl
2574 dnl ---------------------------------------------------------------------------
2575 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
2576 dnl -----------------
2577 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2578 dnl
2579 dnl     POSIX.1-1990                            _POSIX_SOURCE
2580 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2581 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2582 dnl             Bindings Option
2583 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2584 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2585 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2586 dnl
2587 dnl Parameters:
2588 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2589 AC_DEFUN([CF_POSIX_C_SOURCE],
2590 [
2591 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2592
2593 cf_save_CFLAGS="$CFLAGS"
2594 cf_save_CPPFLAGS="$CPPFLAGS"
2595
2596 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2597 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2598
2599 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2600         CF_MSG_LOG(if the symbol is already defined go no further)
2601         AC_TRY_COMPILE([#include <sys/types.h>],[
2602 #ifndef _POSIX_C_SOURCE
2603 make an error
2604 #endif],
2605         [cf_cv_posix_c_source=no],
2606         [cf_want_posix_source=no
2607          case .$cf_POSIX_C_SOURCE in #(vi
2608          .[[12]]??*) #(vi
2609                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2610                 ;;
2611          .2) #(vi
2612                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2613                 cf_want_posix_source=yes
2614                 ;;
2615          .*)
2616                 cf_want_posix_source=yes
2617                 ;;
2618          esac
2619          if test "$cf_want_posix_source" = yes ; then
2620                 AC_TRY_COMPILE([#include <sys/types.h>],[
2621 #ifdef _POSIX_SOURCE
2622 make an error
2623 #endif],[],
2624                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2625          fi
2626          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2627          CFLAGS="$cf_trim_CFLAGS"
2628          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2629          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2630          AC_TRY_COMPILE([#include <sys/types.h>],[
2631 #ifndef _POSIX_C_SOURCE
2632 make an error
2633 #endif],,
2634          [cf_cv_posix_c_source=no])
2635          CFLAGS="$cf_save_CFLAGS"
2636          CPPFLAGS="$cf_save_CPPFLAGS"
2637         ])
2638 ])
2639
2640 if test "$cf_cv_posix_c_source" != no ; then
2641         CFLAGS="$cf_trim_CFLAGS"
2642         CPPFLAGS="$cf_trim_CPPFLAGS"
2643         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2644 fi
2645
2646 ])dnl
2647 dnl ---------------------------------------------------------------------------
2648 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
2649 dnl ----------
2650 dnl Check for archiver "ar".
2651 AC_DEFUN([CF_PROG_AR],[
2652 AC_CHECK_TOOL(AR, ar, ar)
2653 ])
2654 dnl ---------------------------------------------------------------------------
2655 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
2656 dnl -----------
2657 dnl Check for awk, ensure that the check found something.
2658 AC_DEFUN([CF_PROG_AWK],
2659 [
2660 AC_PROG_AWK
2661 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
2662 ])dnl
2663 dnl ---------------------------------------------------------------------------
2664 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
2665 dnl ----------
2666 dnl standard check for CC, plus followup sanity checks
2667 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
2668 AC_DEFUN([CF_PROG_CC],[
2669 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
2670 CF_GCC_VERSION
2671 CF_ACVERSION_CHECK(2.52,
2672         [AC_PROG_CC_STDC],
2673         [CF_ANSI_CC_REQD])
2674 CF_CC_ENV_FLAGS
2675 ])dnl
2676 dnl ---------------------------------------------------------------------------
2677 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
2678 dnl --------------
2679 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
2680 dnl the output file can be renamed, and allows for a shell variable that can
2681 dnl be used later.  The parameter is either CC or CXX.  The result is the
2682 dnl cache variable:
2683 dnl     $cf_cv_prog_CC_c_o
2684 dnl     $cf_cv_prog_CXX_c_o
2685 AC_DEFUN([CF_PROG_CC_C_O],
2686 [AC_REQUIRE([AC_PROG_CC])dnl
2687 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
2688 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
2689 [
2690 cat > conftest.$ac_ext <<CF_EOF
2691 #include <stdio.h>
2692 int main()
2693 {
2694         ${cf_cv_main_return:-return}(0);
2695 }
2696 CF_EOF
2697 # We do the test twice because some compilers refuse to overwrite an
2698 # existing .o file with -o, though they will create one.
2699 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
2700 if AC_TRY_EVAL(ac_try) &&
2701   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
2702 then
2703   eval cf_cv_prog_$1_c_o=yes
2704 else
2705   eval cf_cv_prog_$1_c_o=no
2706 fi
2707 rm -rf conftest*
2708 ])dnl
2709 if test $cf_cv_prog_$1_c_o = yes; then
2710   AC_MSG_RESULT([yes])
2711 else
2712   AC_MSG_RESULT([no])
2713 fi
2714 ])dnl
2715 dnl ---------------------------------------------------------------------------
2716 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
2717 dnl -------------
2718 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
2719 dnl This macro adds a check to ensure the script found something.
2720 AC_DEFUN([CF_PROG_EGREP],
2721 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
2722    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
2723     then ac_cv_prog_egrep='grep -E'
2724     else ac_cv_prog_egrep='egrep'
2725     fi])
2726  EGREP=$ac_cv_prog_egrep
2727  AC_SUBST([EGREP])
2728 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
2729 ])dnl
2730 dnl ---------------------------------------------------------------------------
2731 dnl CF_PROG_EXT version: 11 updated: 2012/10/06 08:57:51
2732 dnl -----------
2733 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
2734 AC_DEFUN([CF_PROG_EXT],
2735 [
2736 AC_REQUIRE([CF_CHECK_CACHE])
2737 case $cf_cv_system_name in
2738 os2*)
2739     CFLAGS="$CFLAGS -Zmt"
2740     CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
2741     CXXFLAGS="$CXXFLAGS -Zmt"
2742     # autoconf's macro sets -Zexe and suffix both, which conflict:w
2743     LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
2744     ac_cv_exeext=.exe
2745     ;;
2746 esac
2747
2748 AC_EXEEXT
2749 AC_OBJEXT
2750
2751 PROG_EXT="$EXEEXT"
2752 AC_SUBST(PROG_EXT)
2753 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
2754 ])dnl
2755 dnl ---------------------------------------------------------------------------
2756 dnl CF_PROG_GNAT version: 2 updated: 2011/10/22 14:01:47
2757 dnl ------------
2758 dnl Check for gnatmake, ensure that it is complete.
2759 AC_DEFUN([CF_PROG_GNAT],[
2760 cf_ada_make=gnatmake
2761 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
2762 if test "$ac_cv_prog_gnat_exists" = no; then
2763    cf_ada_make=
2764    cf_cv_prog_gnat_correct=no
2765 else
2766    CF_GNAT_VERSION
2767    AC_CHECK_PROG(M4_exists, m4, yes, no)
2768    if test "$ac_cv_prog_M4_exists" = no; then
2769       cf_cv_prog_gnat_correct=no
2770       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
2771    fi
2772    if test "$cf_cv_prog_gnat_correct" = yes; then
2773       AC_MSG_CHECKING(if GNAT works)
2774       CF_GNAT_TRY_RUN([procedure conftest;],
2775 [with Text_IO;
2776 with GNAT.OS_Lib;
2777 procedure conftest is
2778 begin
2779    Text_IO.Put ("Hello World");
2780    Text_IO.New_Line;
2781    GNAT.OS_Lib.OS_Exit (0);
2782 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
2783       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
2784    fi
2785 fi
2786
2787 AC_SUBST(cf_ada_make)
2788 ])dnl
2789 dnl ---------------------------------------------------------------------------
2790 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
2791 dnl ------------
2792 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
2793 dnl option if it is supported.
2794 AC_DEFUN([CF_PROG_LN_S],[
2795 AC_PROG_LN_S
2796 AC_MSG_CHECKING(if $LN_S -f options work)
2797
2798 rm -f conf$$.src conf$$dst
2799 echo >conf$$.dst
2800 echo first >conf$$.src
2801 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
2802         cf_prog_ln_sf=yes
2803 else
2804         cf_prog_ln_sf=no
2805 fi
2806 rm -f conf$$.dst conf$$src
2807 AC_MSG_RESULT($cf_prog_ln_sf)
2808
2809 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
2810 ])dnl
2811 dnl ---------------------------------------------------------------------------
2812 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2813 dnl ----------------
2814 dnl Remove all -U and -D options that refer to the given symbol from a list
2815 dnl of C compiler options.  This works around the problem that not all
2816 dnl compilers process -U and -D options from left-to-right, so a -U option
2817 dnl cannot be used to cancel the effect of a preceding -D option.
2818 dnl
2819 dnl $1 = target (which could be the same as the source variable)
2820 dnl $2 = source (including '$')
2821 dnl $3 = symbol to remove
2822 define([CF_REMOVE_DEFINE],
2823 [
2824 $1=`echo "$2" | \
2825         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2826                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2827 ])dnl
2828 dnl ---------------------------------------------------------------------------
2829 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
2830 dnl -------------
2831 dnl Remove the given library from the symbol
2832 dnl
2833 dnl $1 = target (which could be the same as the source variable)
2834 dnl $2 = source (including '$')
2835 dnl $3 = library to remove
2836 define([CF_REMOVE_LIB],
2837 [
2838 # remove $3 library from $2
2839 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
2840 ])dnl
2841 dnl ---------------------------------------------------------------------------
2842 dnl CF_SHARED_OPTS version: 84 updated: 2013/11/03 06:26:10
2843 dnl --------------
2844 dnl --------------
2845 dnl Attempt to determine the appropriate CC/LD options for creating a shared
2846 dnl library.
2847 dnl
2848 dnl Notes:
2849 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
2850 dnl the build-tree, i.e., by making use of the libraries that are compiled in
2851 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
2852 dnl shared library since that can lead to unexpected results at runtime.
2853 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
2854 dnl libraries are compiled in ../../lib
2855 dnl
2856 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
2857 dnl to install symbolic links to the rel/abi versions of shared libraries.
2858 dnl
2859 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
2860 dnl version when making symbolic links.
2861 dnl
2862 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
2863 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
2864 dnl (ex: libncurses.so.<ver>).
2865 dnl
2866 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
2867 AC_DEFUN([CF_SHARED_OPTS],
2868 [
2869         AC_REQUIRE([CF_LD_RPATH_OPT])
2870         RM_SHARED_OPTS=
2871         LOCAL_LDFLAGS=
2872         LOCAL_LDFLAGS2=
2873         LD_SHARED_OPTS=
2874         INSTALL_LIB="-m 644"
2875         : ${rel_builddir:=.}
2876
2877         shlibdir=$libdir
2878         AC_SUBST(shlibdir)
2879
2880         MAKE_DLLS="#"
2881         AC_SUBST(MAKE_DLLS)
2882
2883         cf_cv_do_symlinks=no
2884         cf_ld_rpath_opt=
2885         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
2886
2887         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
2888         AC_ARG_WITH(shlib-version,
2889         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
2890         [test -z "$withval" && withval=auto
2891         case $withval in #(vi
2892         yes) #(vi
2893                 cf_cv_shlib_version=auto
2894                 ;;
2895         rel|abi|auto|no) #(vi
2896                 cf_cv_shlib_version=$withval
2897                 ;;
2898         *)
2899                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
2900                 ;;
2901         esac
2902         ],[cf_cv_shlib_version=auto])
2903         AC_MSG_RESULT($cf_cv_shlib_version)
2904
2905         cf_cv_rm_so_locs=no
2906         cf_try_cflags=
2907
2908         # Some less-capable ports of gcc support only -fpic
2909         CC_SHARED_OPTS=
2910         if test "$GCC" = yes
2911         then
2912                 AC_MSG_CHECKING(which $CC option to use)
2913                 cf_save_CFLAGS="$CFLAGS"
2914                 for CC_SHARED_OPTS in -fPIC -fpic ''
2915                 do
2916                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
2917                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
2918                 done
2919                 AC_MSG_RESULT($CC_SHARED_OPTS)
2920                 CFLAGS="$cf_save_CFLAGS"
2921         fi
2922
2923         cf_cv_shlib_version_infix=no
2924
2925         case $cf_cv_system_name in #(vi
2926         aix4.[3-9]*|aix[[5-7]]*) #(vi
2927                 if test "$GCC" = yes; then
2928                         CC_SHARED_OPTS=
2929                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
2930                 else
2931                         # CC_SHARED_OPTS='-qpic=large -G'
2932                         # perhaps "-bM:SRE -bnoentry -bexpall"
2933                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
2934                 fi
2935                 ;;
2936         beos*) #(vi
2937                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
2938                 ;;
2939         cygwin*) #(vi
2940                 CC_SHARED_OPTS=
2941                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
2942                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
2943                 cf_cv_shlib_version=cygdll
2944                 cf_cv_shlib_version_infix=cygdll
2945                 shlibdir=$bindir
2946                 MAKE_DLLS=
2947                 cat >mk_shared_lib.sh <<-CF_EOF
2948                 #!/bin/sh
2949                 SHARED_LIB=\[$]1
2950                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
2951                 shift
2952                 cat <<-EOF
2953                 Linking shared library
2954                 ** SHARED_LIB \[$]SHARED_LIB
2955                 ** IMPORT_LIB \[$]IMPORT_LIB
2956 EOF
2957                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
2958 CF_EOF
2959                 chmod +x mk_shared_lib.sh
2960                 ;;
2961         msys*) #(vi
2962                 CC_SHARED_OPTS=
2963                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
2964                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
2965                 cf_cv_shlib_version=msysdll
2966                 cf_cv_shlib_version_infix=msysdll
2967                 shlibdir=$bindir
2968                 MAKE_DLLS=
2969                 cat >mk_shared_lib.sh <<-CF_EOF
2970                 #!/bin/sh
2971                 SHARED_LIB=\[$]1
2972                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
2973                 shift
2974                 cat <<-EOF
2975                 Linking shared library
2976                 ** SHARED_LIB \[$]SHARED_LIB
2977                 ** IMPORT_LIB \[$]IMPORT_LIB
2978 EOF
2979                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
2980 CF_EOF
2981                 chmod +x mk_shared_lib.sh
2982                 ;;
2983         darwin*) #(vi
2984                 cf_try_cflags="no-cpp-precomp"
2985                 CC_SHARED_OPTS="-dynamic"
2986                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
2987                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
2988                 cf_cv_shlib_version_infix=yes
2989                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
2990                         cf_save_LDFLAGS=$LDFLAGS
2991                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
2992                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
2993                                 LDFLAGS=$cf_save_LDFLAGS])
2994                 if test $cf_cv_ldflags_search_paths_first = yes; then
2995                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
2996                 fi
2997                 ;;
2998         hpux[[7-8]]*) #(vi
2999                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list 
3000                 if test "$GCC" != yes; then
3001                         CC_SHARED_OPTS='+Z'
3002                 fi
3003                 MK_SHARED_LIB='${LD} -b -o $[@]'
3004                 INSTALL_LIB="-m 555"
3005                 ;;
3006         hpux*) #(vi
3007                 # (tested with gcc 2.7.2 -- I don't have c89)
3008                 if test "$GCC" = yes; then
3009                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
3010                 else
3011                         CC_SHARED_OPTS='+Z'
3012                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
3013                 fi
3014                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
3015                 # HP-UX shared libraries must be executable, and should be
3016                 # readonly to exploit a quirk in the memory manager.
3017                 INSTALL_LIB="-m 555"
3018                 ;;
3019         interix*)
3020                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3021                 if test "$cf_cv_shlib_version" = rel; then
3022                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
3023                 else
3024                         cf_shared_soname='`basename $@`'
3025                 fi
3026                 CC_SHARED_OPTS=
3027                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
3028                 ;;
3029         irix*) #(vi
3030                 if test "$cf_cv_enable_rpath" = yes ; then
3031                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3032                 fi
3033                 # tested with IRIX 5.2 and 'cc'.
3034                 if test "$GCC" != yes; then
3035                         CC_SHARED_OPTS='-KPIC'
3036                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
3037                 else
3038                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
3039                 fi
3040                 cf_cv_rm_so_locs=yes
3041                 ;;
3042         linux*|gnu*|k*bsd*-gnu) #(vi
3043                 if test "$DFT_LWR_MODEL" = "shared" ; then
3044                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3045                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3046                 fi
3047                 if test "$cf_cv_enable_rpath" = yes ; then
3048                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3049                 fi
3050                 CF_SHARED_SONAME
3051                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3052                 ;;
3053         mingw*) #(vi
3054                 cf_cv_shlib_version=mingw
3055                 cf_cv_shlib_version_infix=mingw
3056                 shlibdir=$bindir
3057                 MAKE_DLLS=
3058                 if test "$DFT_LWR_MODEL" = "shared" ; then
3059                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
3060                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3061                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
3062                 fi
3063                 CC_SHARED_OPTS=
3064                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3065                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3066                 cat >mk_shared_lib.sh <<-CF_EOF
3067                 #!/bin/sh
3068                 SHARED_LIB=\[$]1
3069                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3070                 shift
3071                 cat <<-EOF
3072                 Linking shared library
3073                 ** SHARED_LIB \[$]SHARED_LIB
3074                 ** IMPORT_LIB \[$]IMPORT_LIB
3075 EOF
3076                 exec \[$]* -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3077 CF_EOF
3078                 chmod +x mk_shared_lib.sh
3079                 ;;
3080         openbsd[[2-9]].*|mirbsd*) #(vi
3081                 if test "$DFT_LWR_MODEL" = "shared" ; then
3082                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3083                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3084                 fi
3085                 if test "$cf_cv_enable_rpath" = yes ; then
3086                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3087                 fi
3088                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3089                 CF_SHARED_SONAME
3090                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3091                 ;;
3092         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
3093                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3094                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
3095                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3096                 ;;
3097         dragonfly*|freebsd*) #(vi
3098                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3099                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3100                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3101                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
3102                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3103                 fi
3104                 CF_SHARED_SONAME
3105                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
3106                 ;;
3107         netbsd*) #(vi
3108                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3109                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3110                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3111                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3112                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3113                         if test "$cf_cv_shlib_version" = auto; then
3114                         if test -f /usr/libexec/ld.elf_so; then
3115                                 cf_cv_shlib_version=abi
3116                         else
3117                                 cf_cv_shlib_version=rel
3118                         fi
3119                         fi
3120                         CF_SHARED_SONAME
3121                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
3122                 else
3123                         MK_SHARED_LIB='${CC} -Wl,-shared -Wl,-Bshareable -o $[@]'
3124                 fi
3125                 ;;
3126         osf*|mls+*) #(vi
3127                 # tested with OSF/1 V3.2 and 'cc'
3128                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
3129                 # link with shared libs).
3130                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
3131                 case $host_os in #(vi
3132                 osf4*)
3133                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
3134                         ;;
3135                 esac
3136                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
3137                 if test "$DFT_LWR_MODEL" = "shared" ; then
3138                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3139                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3140                 fi
3141                 cf_cv_rm_so_locs=yes
3142                 ;;
3143         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
3144                 # tested with osr5.0.5
3145                 if test "$GCC" != yes; then
3146                         CC_SHARED_OPTS='-belf -KPIC'
3147                 fi
3148                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
3149                 if test "$cf_cv_enable_rpath" = yes ; then
3150                         # only way is to set LD_RUN_PATH but no switch for it
3151                         RUN_PATH=$libdir
3152                 fi
3153                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3154                 LINK_PROGS='LD_RUN_PATH=${libdir}'
3155                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
3156                 ;;
3157         sunos4*) #(vi
3158                 # tested with SunOS 4.1.1 and gcc 2.7.0
3159                 if test "$GCC" != yes; then
3160                         CC_SHARED_OPTS='-KPIC'
3161                 fi
3162                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
3163                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3164                 ;;
3165         solaris2*) #(vi
3166                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
3167                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
3168                 if test "$DFT_LWR_MODEL" = "shared" ; then
3169                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
3170                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3171                 fi
3172                 if test "$cf_cv_enable_rpath" = yes ; then
3173                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
3174                 fi
3175                 CF_SHARED_SONAME
3176                 if test "$GCC" != yes; then
3177                         cf_save_CFLAGS="$CFLAGS"
3178                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
3179                         do
3180                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
3181                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
3182                         done
3183                         CFLAGS="$cf_save_CFLAGS"
3184                         CC_SHARED_OPTS=$cf_shared_opts
3185                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3186                 else
3187                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3188                 fi
3189                 ;;
3190         sysv5uw7*|unix_sv*) #(vi
3191                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
3192                 if test "$GCC" != yes; then
3193                         CC_SHARED_OPTS='-KPIC'
3194                 fi
3195                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
3196                 ;;
3197         *)
3198                 CC_SHARED_OPTS='unknown'
3199                 MK_SHARED_LIB='echo unknown'
3200                 ;;
3201         esac
3202
3203         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
3204         case "$cf_cv_shlib_version" in #(vi
3205         rel|abi)
3206                 case "$MK_SHARED_LIB" in #(vi
3207                 *'-o $[@]') #(vi
3208                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
3209                         ;;
3210                 *)
3211                         AC_MSG_WARN(ignored --with-shlib-version)
3212                         ;;
3213                 esac
3214                 ;;
3215         esac
3216
3217         if test -n "$cf_try_cflags"
3218         then
3219 cat > conftest.$ac_ext <<EOF
3220 #line __oline__ "${as_me:-configure}"
3221 #include <stdio.h>
3222 int main(int argc, char *argv[[]])
3223 {
3224         printf("hello\n");
3225         return (argv[[argc-1]] == 0) ;
3226 }
3227 EOF
3228                 cf_save_CFLAGS="$CFLAGS"
3229                 for cf_opt in $cf_try_cflags
3230                 do
3231                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
3232                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
3233                         if AC_TRY_EVAL(ac_compile); then
3234                                 AC_MSG_RESULT(yes)
3235                                 cf_save_CFLAGS="$CFLAGS"
3236                         else
3237                                 AC_MSG_RESULT(no)
3238                         fi
3239                 done
3240                 CFLAGS="$cf_save_CFLAGS"
3241         fi
3242
3243
3244         # RPATH_LIST is a colon-separated list of directories
3245         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
3246         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
3247
3248         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
3249
3250         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
3251         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
3252
3253         AC_SUBST(CC_SHARED_OPTS)
3254         AC_SUBST(LD_RPATH_OPT)
3255         AC_SUBST(LD_SHARED_OPTS)
3256         AC_SUBST(MK_SHARED_LIB)
3257         AC_SUBST(RM_SHARED_OPTS)
3258
3259         AC_SUBST(LINK_PROGS)
3260         AC_SUBST(LINK_TESTS)
3261
3262         AC_SUBST(EXTRA_LDFLAGS)
3263         AC_SUBST(LOCAL_LDFLAGS)
3264         AC_SUBST(LOCAL_LDFLAGS2)
3265
3266         AC_SUBST(INSTALL_LIB)
3267         AC_SUBST(RPATH_LIST)
3268 ])dnl
3269 dnl ---------------------------------------------------------------------------
3270 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
3271 dnl ----------------
3272 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
3273 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
3274 dnl option.
3275 dnl
3276 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
3277 dnl If missing, use "rel".
3278 define([CF_SHARED_SONAME],
3279 [
3280         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
3281         if test "$cf_cv_shlib_version" = rel; then
3282                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3283         else
3284                 cf_cv_shared_soname='`basename $[@]`'
3285         fi
3286 ])
3287 dnl ---------------------------------------------------------------------------
3288 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
3289 dnl --------------
3290 dnl     Remove "-g" option from the compiler options
3291 AC_DEFUN([CF_STRIP_G_OPT],
3292 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
3293 dnl ---------------------------------------------------------------------------
3294 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
3295 dnl --------------
3296 dnl Construct a search-list for a nonstandard header/lib-file
3297 dnl     $1 = the variable to return as result
3298 dnl     $2 = the package name
3299 dnl     $3 = the subdirectory, e.g., bin, include or lib
3300 AC_DEFUN([CF_SUBDIR_PATH],
3301 [
3302 $1=
3303
3304 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
3305 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3306 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
3307 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
3308 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
3309 ])dnl
3310 dnl ---------------------------------------------------------------------------
3311 dnl CF_TERM_HEADER version: 3 updated: 2012/10/06 08:57:51
3312 dnl --------------
3313 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3314 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3315 dnl but some packagers change this, breaking various applications.
3316 AC_DEFUN([CF_TERM_HEADER],[
3317 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3318 case ${cf_cv_ncurses_header} in #(vi
3319 */ncurses.h|*/ncursesw.h) #(vi
3320         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3321         ;;
3322 *)
3323         cf_term_header=term.h
3324         ;;
3325 esac
3326
3327 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3328 do
3329 AC_TRY_COMPILE([#include <stdio.h>
3330 #include <${cf_cv_ncurses_header:-curses.h}>
3331 #include <$cf_test>
3332 ],[int x = auto_left_margin],[
3333         cf_cv_term_header="$cf_test"],[
3334         cf_cv_term_header=unknown
3335         ])
3336         test "$cf_cv_term_header" != unknown && break
3337 done
3338 ])
3339
3340 # Set definitions to allow ifdef'ing to accommodate subdirectories
3341
3342 case $cf_cv_term_header in # (vi
3343 *term.h)
3344         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
3345         ;;
3346 esac
3347
3348 case $cf_cv_term_header in # (vi
3349 ncurses/term.h) #(vi
3350         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
3351         ;;
3352 ncursesw/term.h)
3353         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
3354         ;;
3355 esac
3356 ])dnl
3357 dnl ---------------------------------------------------------------------------
3358 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
3359 dnl ---------------
3360 dnl Define a top_builddir symbol, for applications that need an absolute path.
3361 AC_DEFUN([CF_TOP_BUILDDIR],
3362 [
3363 top_builddir=ifelse($1,,`pwd`,$1)
3364 AC_SUBST(top_builddir)
3365 ])dnl
3366 dnl ---------------------------------------------------------------------------
3367 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
3368 dnl -------------------
3369 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
3370 dnl can define it successfully.
3371 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
3372 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3373         AC_TRY_COMPILE([
3374 #include <stdlib.h>
3375 #include <string.h>
3376 #include <sys/types.h>
3377 ],[
3378 #ifndef _XOPEN_SOURCE
3379 make an error
3380 #endif],
3381         [cf_cv_xopen_source=no],
3382         [cf_save="$CPPFLAGS"
3383          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3384          AC_TRY_COMPILE([
3385 #include <stdlib.h>
3386 #include <string.h>
3387 #include <sys/types.h>
3388 ],[
3389 #ifdef _XOPEN_SOURCE
3390 make an error
3391 #endif],
3392         [cf_cv_xopen_source=no],
3393         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3394         CPPFLAGS="$cf_save"
3395         ])
3396 ])
3397
3398 if test "$cf_cv_xopen_source" != no ; then
3399         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3400         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3401         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3402         CF_ADD_CFLAGS($cf_temp_xopen_source)
3403 fi
3404 ])
3405 dnl ---------------------------------------------------------------------------
3406 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3407 dnl --------
3408 dnl Make an uppercase version of a variable
3409 dnl $1=uppercase($2)
3410 AC_DEFUN([CF_UPPER],
3411 [
3412 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3413 ])dnl
3414 dnl ---------------------------------------------------------------------------
3415 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
3416 dnl -----------
3417 dnl Check for multibyte support, and if not found, utf8 compatibility library
3418 AC_DEFUN([CF_UTF8_LIB],
3419 [
3420 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3421         cf_save_LIBS="$LIBS"
3422         AC_TRY_LINK([
3423 #include <stdlib.h>],[putwc(0,0);],
3424         [cf_cv_utf8_lib=yes],
3425         [CF_FIND_LINKAGE([
3426 #include <libutf8.h>],[putwc(0,0);],utf8,
3427                 [cf_cv_utf8_lib=add-on],
3428                 [cf_cv_utf8_lib=no])
3429 ])])
3430
3431 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3432 # ncurses/ncursesw:
3433 if test "$cf_cv_utf8_lib" = "add-on" ; then
3434         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
3435         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3436         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3437         CF_ADD_LIBS($cf_cv_library_file_utf8)
3438 fi
3439 ])dnl
3440 dnl ---------------------------------------------------------------------------
3441 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3442 dnl ----------
3443 dnl Use AC_VERBOSE w/o the warnings
3444 AC_DEFUN([CF_VERBOSE],
3445 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3446 CF_MSG_LOG([$1])
3447 ])dnl
3448 dnl ---------------------------------------------------------------------------
3449 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
3450 dnl ---------------
3451 dnl Check for compiler-support for weak symbols.
3452 dnl This works with "recent" gcc.
3453 AC_DEFUN([CF_WEAK_SYMBOLS],[
3454 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
3455
3456 AC_TRY_COMPILE([
3457 #include <stdio.h>],
3458 [
3459 #if defined(__GNUC__)
3460 #  if defined __USE_ISOC99
3461 #    define _cat_pragma(exp)    _Pragma(#exp)
3462 #    define _weak_pragma(exp)   _cat_pragma(weak name)
3463 #  else
3464 #    define _weak_pragma(exp)
3465 #  endif
3466 #  define _declare(name)        __extension__ extern __typeof__(name) name
3467 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
3468 #endif
3469
3470 weak_symbol(fopen);
3471 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
3472 ])
3473 ])dnl
3474 dnl ---------------------------------------------------------------------------
3475 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
3476 dnl --------------------
3477 dnl Command-line option to specify the Ada95 compiler.
3478 AC_DEFUN([CF_WITH_ADA_COMPILER],[
3479 AC_MSG_CHECKING(for ada-compiler)
3480 AC_ARG_WITH(ada-compiler,
3481         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
3482         [cf_ada_compiler=$withval],
3483         [cf_ada_compiler=gnatmake])
3484 AC_SUBST(cf_ada_compiler)
3485 AC_MSG_RESULT($cf_ada_compiler)
3486 ])dnl
3487 dnl ---------------------------------------------------------------------------
3488 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
3489 dnl -------------------
3490 dnl Command-line option to specify where Ada includes will install.
3491 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
3492 AC_MSG_CHECKING(for ada-include)
3493 CF_WITH_PATH(ada-include,
3494    [  --with-ada-include=DIR  Ada includes are in DIR],
3495    ADA_INCLUDE,
3496    PREFIX/share/ada/adainclude,
3497    [$]prefix/share/ada/adainclude)
3498 AC_SUBST(ADA_INCLUDE)
3499 AC_MSG_RESULT($ADA_INCLUDE)
3500 ])dnl
3501 dnl ---------------------------------------------------------------------------
3502 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
3503 dnl -------------------
3504 dnl Command-line option to specify where Ada objects will install.
3505 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
3506 AC_MSG_CHECKING(for ada-objects)
3507 CF_WITH_PATH(ada-objects,
3508    [  --with-ada-objects=DIR  Ada objects are in DIR],
3509    ADA_OBJECTS,
3510    PREFIX/lib/ada/adalib,
3511    [$]prefix/lib/ada/adalib)
3512 AC_SUBST(ADA_OBJECTS)
3513 AC_MSG_RESULT($ADA_OBJECTS)
3514 ])dnl
3515 dnl ---------------------------------------------------------------------------
3516 dnl CF_WITH_ADA_SHAREDLIB version: 4 updated: 2014/05/31 21:08:37
3517 dnl ---------------------
3518 dnl Command-line option to specify if an Ada95 shared-library should be built,
3519 dnl and optionally what its soname should be.
3520 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
3521 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
3522 AC_ARG_WITH(ada-sharedlib,
3523         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
3524         [with_ada_sharedlib=$withval],
3525         [with_ada_sharedlib=no])
3526 AC_MSG_RESULT($with_ada_sharedlib)
3527
3528 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
3529 MAKE_ADA_SHAREDLIB="#"
3530
3531 if test "x$with_ada_sharedlib" != xno
3532 then
3533         MAKE_ADA_SHAREDLIB=
3534         if test "x$with_ada_sharedlib" != xyes
3535         then
3536                 ADA_SHAREDLIB="$with_ada_sharedlib"
3537         fi
3538 fi
3539
3540 AC_SUBST(ADA_SHAREDLIB)
3541 AC_SUBST(MAKE_ADA_SHAREDLIB)
3542 ])dnl
3543 dnl ---------------------------------------------------------------------------
3544 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3545 dnl ------------------
3546 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3547 dnl libraries.
3548 AC_DEFUN([CF_WITH_CURSES_DIR],[
3549
3550 AC_MSG_CHECKING(for specific curses-directory)
3551 AC_ARG_WITH(curses-dir,
3552         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3553         [cf_cv_curses_dir=$withval],
3554         [cf_cv_curses_dir=no])
3555 AC_MSG_RESULT($cf_cv_curses_dir)
3556
3557 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3558 then
3559         CF_PATH_SYNTAX(withval)
3560         if test -d "$cf_cv_curses_dir"
3561         then
3562                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3563                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3564         fi
3565 fi
3566 ])dnl
3567 dnl ---------------------------------------------------------------------------
3568 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
3569 dnl ------------------
3570 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
3571 dnl "lib" prefix, e.g., because it used the dll naming convention.
3572 dnl
3573 dnl $1 = variable to set
3574 AC_DEFUN([CF_WITH_LIB_PREFIX],
3575 [
3576 AC_MSG_CHECKING(if you want to have a library-prefix)
3577 AC_ARG_WITH(lib-prefix,
3578         [  --with-lib-prefix       override library-prefix],
3579         [with_lib_prefix=$withval],
3580         [with_lib_prefix=auto])
3581 AC_MSG_RESULT($with_lib_prefix)
3582
3583 if test $with_lib_prefix = auto
3584 then
3585         CF_LIB_PREFIX($1)
3586 elif test $with_lib_prefix = no
3587 then
3588         LIB_PREFIX=
3589 else
3590         LIB_PREFIX=$with_lib_prefix
3591 fi
3592 ])dnl
3593 dnl ---------------------------------------------------------------------------
3594 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
3595 dnl ------------
3596 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
3597 dnl defaulting to yes/no.
3598 dnl
3599 dnl $1 = option name
3600 dnl $2 = help-text
3601 dnl $3 = environment variable to set
3602 dnl $4 = default value, shown in the help-message, must be a constant
3603 dnl $5 = default value, if it's an expression & cannot be in the help-message
3604 dnl
3605 AC_DEFUN([CF_WITH_PATH],
3606 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
3607 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
3608 if ifelse([$5],,true,[test -n "$5"]) ; then
3609 CF_PATH_SYNTAX(withval)
3610 fi
3611 eval $3="$withval"
3612 AC_SUBST($3)dnl
3613 ])dnl
3614 dnl ---------------------------------------------------------------------------
3615 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 2 updated: 2011/12/10 18:58:47
3616 dnl -------------------------
3617 dnl Allow the choice of the pkg-config library directory to be overridden.
3618 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
3619 if test "$PKG_CONFIG" != none ; then
3620         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
3621         AC_ARG_WITH(pkg-config-libdir,
3622                 [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
3623                 [PKG_CONFIG_LIBDIR=$withval],
3624                 [PKG_CONFIG_LIBDIR=yes])
3625
3626         case x$PKG_CONFIG_LIBDIR in #(vi
3627         x/*) #(vi
3628                 ;;
3629         xyes) #(vi
3630                 # look for the library directory using the same prefix as the executable
3631                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
3632                 case x`(arch) 2>/dev/null` in #(vi
3633                 *64) #(vi
3634                         for cf_config in $cf_path/share $cf_path/lib64 $cf_path/lib32 $cf_path/lib
3635                         do
3636                                 if test -d $cf_config/pkgconfig
3637                                 then
3638                                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
3639                                         break
3640                                 fi
3641                         done
3642                         ;;
3643                 *)
3644                         PKG_CONFIG_LIBDIR=$cf_path/lib/pkgconfig
3645                         ;;
3646                 esac
3647                 ;;
3648         *)
3649                 ;;
3650         esac
3651
3652         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
3653 fi
3654
3655 AC_SUBST(PKG_CONFIG_LIBDIR)
3656 ])dnl
3657 dnl ---------------------------------------------------------------------------
3658 dnl CF_WITH_PTHREAD version: 6 updated: 2012/10/06 17:41:51
3659 dnl ---------------
3660 dnl Check for POSIX thread library.
3661 AC_DEFUN([CF_WITH_PTHREAD],
3662 [
3663 AC_MSG_CHECKING(if you want to link with the pthread library)
3664 AC_ARG_WITH(pthread,
3665     [  --with-pthread          use POSIX thread library],
3666     [with_pthread=$withval],
3667     [with_pthread=no])
3668 AC_MSG_RESULT($with_pthread)
3669
3670 if test "$with_pthread" != no ; then
3671     AC_CHECK_HEADER(pthread.h,[
3672         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
3673
3674         for cf_lib_pthread in pthread c_r
3675         do
3676             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
3677             cf_save_LIBS="$LIBS"
3678             CF_ADD_LIB($cf_lib_pthread)
3679             AC_TRY_LINK([
3680 #include <pthread.h>
3681 ],[
3682                 int rc = pthread_create(0,0,0,0);
3683                 int r2 = pthread_mutexattr_settype(0, 0);
3684 ],[with_pthread=yes],[with_pthread=no])
3685             LIBS="$cf_save_LIBS"
3686             AC_MSG_RESULT($with_pthread)
3687             test "$with_pthread" = yes && break
3688         done
3689
3690         if test "$with_pthread" = yes ; then
3691             CF_ADD_LIB($cf_lib_pthread)
3692             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
3693         else
3694             AC_MSG_ERROR(Cannot link with pthread library)
3695         fi
3696     ])
3697 fi
3698 ])
3699 dnl ---------------------------------------------------------------------------
3700 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
3701 dnl ---------------
3702 dnl For testing, override the derived host system-type which is used to decide
3703 dnl things such as the linker commands used to build shared libraries.  This is
3704 dnl normally chosen automatically based on the type of system which you are
3705 dnl building on.  We use it for testing the configure script.
3706 dnl
3707 dnl This is different from the --host option: it is used only for testing parts
3708 dnl of the configure script which would not be reachable with --host since that
3709 dnl relies on the build environment being real, rather than mocked up.
3710 AC_DEFUN([CF_WITH_SYSTYPE],[
3711 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
3712 AC_ARG_WITH(system-type,
3713         [  --with-system-type=XXX  test: override derived host system-type],
3714 [AC_MSG_WARN(overriding system type to $withval)
3715         cf_cv_system_name=$withval
3716         host_os=$withval
3717 ])
3718 ])dnl
3719 dnl ---------------------------------------------------------------------------
3720 dnl CF_XOPEN_SOURCE version: 47 updated: 2014/07/23 17:11:49
3721 dnl ---------------
3722 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
3723 dnl or adapt to the vendor's definitions to get equivalent functionality,
3724 dnl without losing the common non-POSIX features.
3725 dnl
3726 dnl Parameters:
3727 dnl     $1 is the nominal value for _XOPEN_SOURCE
3728 dnl     $2 is the nominal value for _POSIX_C_SOURCE
3729 AC_DEFUN([CF_XOPEN_SOURCE],[
3730 AC_REQUIRE([AC_CANONICAL_HOST])
3731
3732 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
3733 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
3734 cf_xopen_source=
3735
3736 case $host_os in #(vi
3737 aix[[4-7]]*) #(vi
3738         cf_xopen_source="-D_ALL_SOURCE"
3739         ;;
3740 cygwin|msys) #(vi
3741         cf_XOPEN_SOURCE=600
3742         ;;
3743 darwin[[0-8]].*) #(vi
3744         cf_xopen_source="-D_APPLE_C_SOURCE"
3745         ;;
3746 darwin*) #(vi
3747         cf_xopen_source="-D_DARWIN_C_SOURCE"
3748         cf_XOPEN_SOURCE=
3749         ;;
3750 freebsd*|dragonfly*) #(vi
3751         # 5.x headers associate
3752         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
3753         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
3754         cf_POSIX_C_SOURCE=200112L
3755         cf_XOPEN_SOURCE=600
3756         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3757         ;;
3758 hpux11*) #(vi
3759         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
3760         ;;
3761 hpux*) #(vi
3762         cf_xopen_source="-D_HPUX_SOURCE"
3763         ;;
3764 irix[[56]].*) #(vi
3765         cf_xopen_source="-D_SGI_SOURCE"
3766         cf_XOPEN_SOURCE=
3767         ;;
3768 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
3769         CF_GNU_SOURCE
3770         ;;
3771 minix*) #(vi
3772         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
3773         ;;
3774 mirbsd*) #(vi
3775         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
3776         cf_XOPEN_SOURCE=
3777         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3778         ;;
3779 netbsd*) #(vi
3780         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
3781         ;;
3782 openbsd[[4-9]]*) #(vi
3783         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
3784         cf_xopen_source="-D_BSD_SOURCE"
3785         cf_XOPEN_SOURCE=600
3786         ;;
3787 openbsd*) #(vi
3788         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
3789         ;;
3790 osf[[45]]*) #(vi
3791         cf_xopen_source="-D_OSF_SOURCE"
3792         ;;
3793 nto-qnx*) #(vi
3794         cf_xopen_source="-D_QNX_SOURCE"
3795         ;;
3796 sco*) #(vi
3797         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
3798         ;;
3799 solaris2.*) #(vi
3800         cf_xopen_source="-D__EXTENSIONS__"
3801         cf_cv_xopen_source=broken
3802         ;;
3803 *)
3804         CF_TRY_XOPEN_SOURCE
3805         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3806         ;;
3807 esac
3808
3809 if test -n "$cf_xopen_source" ; then
3810         CF_ADD_CFLAGS($cf_xopen_source,true)
3811 fi
3812
3813 dnl In anything but the default case, we may have system-specific setting
3814 dnl which is still not guaranteed to provide all of the entrypoints that
3815 dnl _XOPEN_SOURCE would yield.
3816 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
3817         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
3818         AC_TRY_COMPILE([#include <stdlib.h>],[
3819 #ifndef _XOPEN_SOURCE
3820 make an error
3821 #endif],
3822         [cf_XOPEN_SOURCE_set=yes],
3823         [cf_XOPEN_SOURCE_set=no])
3824         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
3825         if test $cf_XOPEN_SOURCE_set = yes
3826         then
3827                 AC_TRY_COMPILE([#include <stdlib.h>],[
3828 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
3829 make an error
3830 #endif],
3831                 [cf_XOPEN_SOURCE_set_ok=yes],
3832                 [cf_XOPEN_SOURCE_set_ok=no])
3833                 if test $cf_XOPEN_SOURCE_set_ok = no
3834                 then
3835                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
3836                 fi
3837         else
3838                 CF_TRY_XOPEN_SOURCE
3839         fi
3840 fi
3841 ])