ncurses 6.0 - patch 20151017
[ncurses.git] / Ada95 / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright (c) 2010-2014,2015 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey
30 dnl
31 dnl $Id: aclocal.m4,v 1.108 2015/10/17 23:07:06 tom Exp $
32 dnl Macros used in NCURSES Ada95 auto-configuration script.
33 dnl
34 dnl These macros are maintained separately from NCURSES.  The copyright on
35 dnl this file applies to the aggregation of macros and does not affect use of
36 dnl these macros in other applications.
37 dnl
38 dnl See http://invisible-island.net/autoconf/ for additional information.
39 dnl
40 dnl ---------------------------------------------------------------------------
41 dnl ---------------------------------------------------------------------------
42 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
43 dnl ------------------
44 dnl Conditionally generate script according to whether we're using a given autoconf.
45 dnl
46 dnl $1 = version to compare against
47 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
48 dnl $3 = code to use if AC_ACVERSION is older than $1.
49 define([CF_ACVERSION_CHECK],
50 [
51 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
52 ifdef([m4_version_compare],
53 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
54 [CF_ACVERSION_COMPARE(
55 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
56 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
57 dnl ---------------------------------------------------------------------------
58 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
59 dnl --------------------
60 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
61 dnl                      MAJOR2, MINOR2, TERNARY2,
62 dnl                      PRINTABLE2, not FOUND, FOUND)
63 define([CF_ACVERSION_COMPARE],
64 [ifelse(builtin([eval], [$2 < $5]), 1,
65 [ifelse([$8], , ,[$8])],
66 [ifelse([$9], , ,[$9])])])dnl
67 dnl ---------------------------------------------------------------------------
68 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
69 dnl -------------------
70 dnl Construct the list of include-options for the C programs in the Ada95
71 dnl binding.
72 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
73 [
74 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
75 if test "$srcdir" != "."; then
76         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
77 fi
78 if test "$GCC" != yes; then
79         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
80 elif test "$includedir" != "/usr/include"; then
81         if test "$includedir" = '${prefix}/include' ; then
82                 if test x$prefix != x/usr ; then
83                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
84                 fi
85         else
86                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
87         fi
88 fi
89 AC_SUBST(ACPPFLAGS)
90 ])dnl
91 dnl ---------------------------------------------------------------------------
92 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
93 dnl ---------------
94 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
95 AC_DEFUN([CF_ADD_ADAFLAGS],[
96         ADAFLAGS="$ADAFLAGS $1"
97         AC_SUBST(ADAFLAGS)
98 ])dnl
99 dnl ---------------------------------------------------------------------------
100 dnl CF_ADD_CFLAGS version: 12 updated: 2015/04/12 15:39:00
101 dnl -------------
102 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
103 dnl The second parameter if given makes this macro verbose.
104 dnl
105 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
106 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
107 dnl confused by the quotes (which require backslashes to keep them usable).
108 AC_DEFUN([CF_ADD_CFLAGS],
109 [
110 cf_fix_cppflags=no
111 cf_new_cflags=
112 cf_new_cppflags=
113 cf_new_extra_cppflags=
114
115 for cf_add_cflags in $1
116 do
117 case $cf_fix_cppflags in
118 (no)
119         case $cf_add_cflags in
120         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
121                 case $cf_add_cflags in
122                 (-D*)
123                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
124
125                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
126                                 && test -z "${cf_tst_cflags}" \
127                                 && cf_fix_cppflags=yes
128
129                         if test $cf_fix_cppflags = yes ; then
130                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
131                                 continue
132                         elif test "${cf_tst_cflags}" = "\"'" ; then
133                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
134                                 continue
135                         fi
136                         ;;
137                 esac
138                 case "$CPPFLAGS" in
139                 (*$cf_add_cflags)
140                         ;;
141                 (*)
142                         case $cf_add_cflags in
143                         (-D*)
144                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
145                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
146                                 ;;
147                         esac
148                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
149                         ;;
150                 esac
151                 ;;
152         (*)
153                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
154                 ;;
155         esac
156         ;;
157 (yes)
158         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
159
160         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
161
162         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
163                 && test -z "${cf_tst_cflags}" \
164                 && cf_fix_cppflags=no
165         ;;
166 esac
167 done
168
169 if test -n "$cf_new_cflags" ; then
170         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
171         CFLAGS="$CFLAGS $cf_new_cflags"
172 fi
173
174 if test -n "$cf_new_cppflags" ; then
175         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
176         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
177 fi
178
179 if test -n "$cf_new_extra_cppflags" ; then
180         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
181         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
182 fi
183
184 AC_SUBST(EXTRA_CPPFLAGS)
185
186 ])dnl
187 dnl ---------------------------------------------------------------------------
188 dnl CF_ADD_INCDIR version: 14 updated: 2015/05/25 20:53:04
189 dnl -------------
190 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
191 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
192 dnl but old versions (and some misinstalled ones) need that.  To make things
193 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
194 dnl the include-path).
195 AC_DEFUN([CF_ADD_INCDIR],
196 [
197 if test -n "$1" ; then
198   for cf_add_incdir in $1
199   do
200         while test $cf_add_incdir != /usr/include
201         do
202           if test -d $cf_add_incdir
203           then
204                 cf_have_incdir=no
205                 if test -n "$CFLAGS$CPPFLAGS" ; then
206                   # a loop is needed to ensure we can add subdirs of existing dirs
207                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
208                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
209                           cf_have_incdir=yes; break
210                         fi
211                   done
212                 fi
213
214                 if test "$cf_have_incdir" = no ; then
215                   if test "$cf_add_incdir" = /usr/local/include ; then
216                         if test "$GCC" = yes
217                         then
218                           cf_save_CPPFLAGS=$CPPFLAGS
219                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
220                           AC_TRY_COMPILE([#include <stdio.h>],
221                                   [printf("Hello")],
222                                   [],
223                                   [cf_have_incdir=yes])
224                           CPPFLAGS=$cf_save_CPPFLAGS
225                         fi
226                   fi
227                 fi
228
229                 if test "$cf_have_incdir" = no ; then
230                   CF_VERBOSE(adding $cf_add_incdir to include-path)
231                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
232
233                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
234                   test "$cf_top_incdir" = "$cf_add_incdir" && break
235                   cf_add_incdir="$cf_top_incdir"
236                 else
237                   break
238                 fi
239           else
240                 break
241           fi
242         done
243   done
244 fi
245 ])dnl
246 dnl ---------------------------------------------------------------------------
247 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
248 dnl ----------
249 dnl Add a library, used to enforce consistency.
250 dnl
251 dnl $1 = library to add, without the "-l"
252 dnl $2 = variable to update (default $LIBS)
253 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
254 dnl ---------------------------------------------------------------------------
255 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
256 dnl -------------
257 dnl     Adds to the library-path
258 dnl
259 dnl     Some machines have trouble with multiple -L options.
260 dnl
261 dnl $1 is the (list of) directory(s) to add
262 dnl $2 is the optional name of the variable to update (default LDFLAGS)
263 dnl
264 AC_DEFUN([CF_ADD_LIBDIR],
265 [
266 if test -n "$1" ; then
267         for cf_add_libdir in $1
268         do
269                 if test $cf_add_libdir = /usr/lib ; then
270                         :
271                 elif test -d $cf_add_libdir
272                 then
273                         cf_have_libdir=no
274                         if test -n "$LDFLAGS$LIBS" ; then
275                                 # a loop is needed to ensure we can add subdirs of existing dirs
276                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
277                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
278                                                 cf_have_libdir=yes; break
279                                         fi
280                                 done
281                         fi
282                         if test "$cf_have_libdir" = no ; then
283                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
284                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
285                         fi
286                 fi
287         done
288 fi
289 ])dnl
290 dnl ---------------------------------------------------------------------------
291 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
292 dnl -----------
293 dnl Add one or more libraries, used to enforce consistency.  Libraries are
294 dnl prepended to an existing list, since their dependencies are assumed to
295 dnl already exist in the list.
296 dnl
297 dnl $1 = libraries to add, with the "-l", etc.
298 dnl $2 = variable to update (default $LIBS)
299 AC_DEFUN([CF_ADD_LIBS],[
300 cf_add_libs="$1"
301 # Filter out duplicates - this happens with badly-designed ".pc" files...
302 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
303 do
304         for cf_add_2lib in $cf_add_libs
305         do
306                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
307                 then
308                         cf_add_1lib=
309                         break
310                 fi
311         done
312         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
313 done
314 ifelse($2,,LIBS,[$2])="$cf_add_libs"
315 ])dnl
316 dnl ---------------------------------------------------------------------------
317 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
318 dnl ------------------
319 dnl Append to a search-list for a nonstandard header/lib-file
320 dnl     $1 = the variable to return as result
321 dnl     $2 = the package name
322 dnl     $3 = the subdirectory, e.g., bin, include or lib
323 dnl $4 = the directory under which we will test for subdirectories
324 dnl $5 = a directory that we do not want $4 to match
325 AC_DEFUN([CF_ADD_SUBDIR_PATH],
326 [
327 test "x$4" != "x$5" && \
328 test -d "$4" && \
329 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
330         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
331         test -d $4/$3 &&          $1="[$]$1 $4/$3"
332         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
333         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
334         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
335         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
336 }
337 ])dnl
338 dnl ---------------------------------------------------------------------------
339 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
340 dnl --------------
341 dnl Allow user to disable a normally-on option.
342 AC_DEFUN([CF_ARG_DISABLE],
343 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
344 dnl ---------------------------------------------------------------------------
345 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
346 dnl -------------
347 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
348 dnl values.
349 dnl
350 dnl Parameters:
351 dnl $1 = option name
352 dnl $2 = help-string
353 dnl $3 = action to perform if option is not default
354 dnl $4 = action if perform if option is default
355 dnl $5 = default option value (either 'yes' or 'no')
356 AC_DEFUN([CF_ARG_OPTION],
357 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
358         if test "$enableval" != "$5" ; then
359 ifelse([$3],,[    :]dnl
360 ,[    $3]) ifelse([$4],,,[
361         else
362                 $4])
363         fi],[enableval=$5 ifelse([$4],,,[
364         $4
365 ])dnl
366 ])])dnl
367 dnl ---------------------------------------------------------------------------
368 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
369 dnl -----------
370 dnl Check for suitable "ar" (archiver) options for updating an archive.
371 dnl
372 dnl In particular, handle some obsolete cases where the "-" might be omitted,
373 dnl as well as a workaround for breakage of make's archive rules by the GNU
374 dnl binutils "ar" program.
375 AC_DEFUN([CF_AR_FLAGS],[
376 AC_REQUIRE([CF_PROG_AR])
377
378 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
379         cf_cv_ar_flags=unknown
380         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
381         do
382
383                 # check if $ARFLAGS already contains this choice
384                 if test "x$ARFLAGS" != "x" ; then
385                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
386                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
387                                 cf_cv_ar_flags=
388                                 break
389                         fi
390                 fi
391
392                 rm -f conftest.$ac_cv_objext
393                 rm -f conftest.a
394
395                 cat >conftest.$ac_ext <<EOF
396 #line __oline__ "configure"
397 int     testdata[[3]] = { 123, 456, 789 };
398 EOF
399                 if AC_TRY_EVAL(ac_compile) ; then
400                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
401                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
402                         if test -f conftest.a ; then
403                                 cf_cv_ar_flags=$cf_ar_flags
404                                 break
405                         fi
406                 else
407                         CF_VERBOSE(cannot compile test-program)
408                         break
409                 fi
410         done
411         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
412 ])
413
414 if test -n "$ARFLAGS" ; then
415         if test -n "$cf_cv_ar_flags" ; then
416                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
417         fi
418 else
419         ARFLAGS=$cf_cv_ar_flags
420 fi
421
422 AC_SUBST(ARFLAGS)
423 ])
424 dnl ---------------------------------------------------------------------------
425 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
426 dnl -----------
427 dnl If we're cross-compiling, allow the user to override the tools and their
428 dnl options.  The configure script is oriented toward identifying the host
429 dnl compiler, etc., but we need a build compiler to generate parts of the
430 dnl source.
431 dnl
432 dnl $1 = default for $CPPFLAGS
433 dnl $2 = default for $LIBS
434 AC_DEFUN([CF_BUILD_CC],[
435 CF_ACVERSION_CHECK(2.52,,
436         [AC_REQUIRE([CF_PROG_EXT])])
437 if test "$cross_compiling" = yes ; then
438
439         # defaults that we might want to override
440         : ${BUILD_CFLAGS:=''}
441         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
442         : ${BUILD_LDFLAGS:=''}
443         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
444         : ${BUILD_EXEEXT:='$x'}
445         : ${BUILD_OBJEXT:='o'}
446
447         AC_ARG_WITH(build-cc,
448                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
449                 [BUILD_CC="$withval"],
450                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
451         AC_MSG_CHECKING(for native build C compiler)
452         AC_MSG_RESULT($BUILD_CC)
453
454         AC_MSG_CHECKING(for native build C preprocessor)
455         AC_ARG_WITH(build-cpp,
456                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
457                 [BUILD_CPP="$withval"],
458                 [BUILD_CPP='${BUILD_CC} -E'])
459         AC_MSG_RESULT($BUILD_CPP)
460
461         AC_MSG_CHECKING(for native build C flags)
462         AC_ARG_WITH(build-cflags,
463                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
464                 [BUILD_CFLAGS="$withval"])
465         AC_MSG_RESULT($BUILD_CFLAGS)
466
467         AC_MSG_CHECKING(for native build C preprocessor-flags)
468         AC_ARG_WITH(build-cppflags,
469                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
470                 [BUILD_CPPFLAGS="$withval"])
471         AC_MSG_RESULT($BUILD_CPPFLAGS)
472
473         AC_MSG_CHECKING(for native build linker-flags)
474         AC_ARG_WITH(build-ldflags,
475                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
476                 [BUILD_LDFLAGS="$withval"])
477         AC_MSG_RESULT($BUILD_LDFLAGS)
478
479         AC_MSG_CHECKING(for native build linker-libraries)
480         AC_ARG_WITH(build-libs,
481                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
482                 [BUILD_LIBS="$withval"])
483         AC_MSG_RESULT($BUILD_LIBS)
484
485         # this assumes we're on Unix.
486         BUILD_EXEEXT=
487         BUILD_OBJEXT=o
488
489         : ${BUILD_CC:='${CC}'}
490
491         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
492                 AC_MSG_ERROR([Cross-build requires two compilers.
493 Use --with-build-cc to specify the native compiler.])
494         fi
495
496 else
497         : ${BUILD_CC:='${CC}'}
498         : ${BUILD_CPP:='${CPP}'}
499         : ${BUILD_CFLAGS:='${CFLAGS}'}
500         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
501         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
502         : ${BUILD_LIBS:='${LIBS}'}
503         : ${BUILD_EXEEXT:='$x'}
504         : ${BUILD_OBJEXT:='o'}
505 fi
506
507 AC_SUBST(BUILD_CC)
508 AC_SUBST(BUILD_CPP)
509 AC_SUBST(BUILD_CFLAGS)
510 AC_SUBST(BUILD_CPPFLAGS)
511 AC_SUBST(BUILD_LDFLAGS)
512 AC_SUBST(BUILD_LIBS)
513 AC_SUBST(BUILD_EXEEXT)
514 AC_SUBST(BUILD_OBJEXT)
515 ])dnl
516 dnl ---------------------------------------------------------------------------
517 dnl CF_CC_ENV_FLAGS version: 2 updated: 2015/04/12 15:39:00
518 dnl ---------------
519 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
520 dnl into CC.  This will not help with broken scripts that wrap the compiler with
521 dnl options, but eliminates a more common category of user confusion.
522 AC_DEFUN([CF_CC_ENV_FLAGS],
523 [
524 # This should have been defined by AC_PROG_CC
525 : ${CC:=cc}
526
527 AC_MSG_CHECKING(\$CC variable)
528 case "$CC" in
529 (*[[\ \ ]]-[[IUD]]*)
530         AC_MSG_RESULT(broken)
531         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
532         # humor him...
533         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
534         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
535         CF_ADD_CFLAGS($cf_flags)
536         ;;
537 (*)
538         AC_MSG_RESULT(ok)
539         ;;
540 esac
541 ])dnl
542 dnl ---------------------------------------------------------------------------
543 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
544 dnl ---------------
545 dnl Determine the default configuration into which we'll install ncurses.  This
546 dnl can be overridden by the user's command-line options.  There's two items to
547 dnl look for:
548 dnl     1. the prefix (e.g., /usr)
549 dnl     2. the header files (e.g., /usr/include/ncurses)
550 dnl We'll look for a previous installation of ncurses and use the same defaults.
551 dnl
552 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
553 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
554 dnl programs from a vendor's.
555 AC_DEFUN([CF_CFG_DEFAULTS],
556 [
557 AC_MSG_CHECKING(for prefix)
558 if test "x$prefix" = "xNONE" ; then
559         case "$cf_cv_system_name" in
560                 # non-vendor systems don't have a conflict
561         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
562                 prefix=/usr
563                 ;;
564         (*)     prefix=$ac_default_prefix
565                 ;;
566         esac
567 fi
568 AC_MSG_RESULT($prefix)
569
570 if test "x$prefix" = "xNONE" ; then
571 AC_MSG_CHECKING(for default include-directory)
572 test -n "$verbose" && echo 1>&AC_FD_MSG
573 for cf_symbol in \
574         $includedir \
575         $includedir/ncurses \
576         $prefix/include \
577         $prefix/include/ncurses \
578         /usr/local/include \
579         /usr/local/include/ncurses \
580         /usr/include \
581         /usr/include/ncurses
582 do
583         cf_dir=`eval echo $cf_symbol`
584         if test -f $cf_dir/curses.h ; then
585         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
586                 includedir="$cf_symbol"
587                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
588                 break
589         fi
590         fi
591         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
592 done
593 AC_MSG_RESULT($includedir)
594 fi
595 ])dnl
596 dnl ---------------------------------------------------------------------------
597 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
598 dnl --------------
599 dnl Check if we're accidentally using a cache from a different machine.
600 dnl Derive the system name, as a check for reusing the autoconf cache.
601 dnl
602 dnl If we've packaged config.guess and config.sub, run that (since it does a
603 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
604 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
605 dnl which is useful in cross-compiles.
606 dnl
607 dnl Note: we would use $ac_config_sub, but that is one of the places where
608 dnl autoconf 2.5x broke compatibility with autoconf 2.13
609 AC_DEFUN([CF_CHECK_CACHE],
610 [
611 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
612         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
613         system_name="$host_os"
614 else
615         system_name="`(uname -s -r) 2>/dev/null`"
616         if test -z "$system_name" ; then
617                 system_name="`(hostname) 2>/dev/null`"
618         fi
619 fi
620 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
621 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
622
623 test -z "$system_name" && system_name="$cf_cv_system_name"
624 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
625
626 if test ".$system_name" != ".$cf_cv_system_name" ; then
627         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
628         AC_MSG_ERROR("Please remove config.cache and try again.")
629 fi
630 ])dnl
631 dnl ---------------------------------------------------------------------------
632 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
633 dnl -----------------
634 dnl Check if the given compiler is really clang.  clang's C driver defines
635 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
636 dnl not ignore some gcc options.
637 dnl
638 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
639 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
640 dnl the wrappers for gcc and g++ warnings.
641 dnl
642 dnl $1 = GCC (default) or GXX
643 dnl $2 = CLANG_COMPILER (default)
644 dnl $3 = CFLAGS (default) or CXXFLAGS
645 AC_DEFUN([CF_CLANG_COMPILER],[
646 ifelse([$2],,CLANG_COMPILER,[$2])=no
647
648 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
649         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
650         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
651         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
652         AC_TRY_COMPILE([],[
653 #ifdef __clang__
654 #else
655 make an error
656 #endif
657 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
658 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
659 ],[])
660         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
661         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
662 fi
663 ])
664 dnl ---------------------------------------------------------------------------
665 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
666 dnl ----------------
667 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
668 dnl variations of ncurses' installs.
669 dnl
670 dnl $1 = ncurses when looking for ncurses, or is empty
671 AC_DEFUN([CF_CURSES_HEADER],[
672 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
673 cf_cv_ncurses_header=none
674 for cf_header in \
675         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
676         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
677 do
678 AC_TRY_COMPILE([#include <${cf_header}>],
679         [initscr(); tgoto("?", 0,0)],
680         [cf_cv_ncurses_header=$cf_header; break],[])
681 done
682 ])
683
684 if test "$cf_cv_ncurses_header" = none ; then
685         AC_MSG_ERROR(No curses header-files found)
686 fi
687
688 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
689 AC_CHECK_HEADERS($cf_cv_ncurses_header)
690 ])dnl
691 dnl ---------------------------------------------------------------------------
692 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
693 dnl ----------
694 dnl "dirname" is not portable, so we fake it with a shell script.
695 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
696 dnl ---------------------------------------------------------------------------
697 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
698 dnl ---------------
699 dnl You can always use "make -n" to see the actual options, but it's hard to
700 dnl pick out/analyze warning messages when the compile-line is long.
701 dnl
702 dnl Sets:
703 dnl     ECHO_LT - symbol to control if libtool is verbose
704 dnl     ECHO_LD - symbol to prefix "cc -o" lines
705 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
706 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
707 dnl     ECHO_CC - symbol to put before any "cc" line
708 dnl
709 AC_DEFUN([CF_DISABLE_ECHO],[
710 AC_MSG_CHECKING(if you want to see long compiling messages)
711 CF_ARG_DISABLE(echo,
712         [  --disable-echo          do not display "compiling" commands],
713         [
714         ECHO_LT='--silent'
715         ECHO_LD='@echo linking [$]@;'
716         RULE_CC='@echo compiling [$]<'
717         SHOW_CC='@echo compiling [$]@'
718         ECHO_CC='@'
719 ],[
720         ECHO_LT=''
721         ECHO_LD=''
722         RULE_CC=''
723         SHOW_CC=''
724         ECHO_CC=''
725 ])
726 AC_MSG_RESULT($enableval)
727 AC_SUBST(ECHO_LT)
728 AC_SUBST(ECHO_LD)
729 AC_SUBST(RULE_CC)
730 AC_SUBST(SHOW_CC)
731 AC_SUBST(ECHO_CC)
732 ])dnl
733 dnl ---------------------------------------------------------------------------
734 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
735 dnl ------------------------
736 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
737 AC_MSG_CHECKING(if we want to use GNAT projects)
738 CF_ARG_DISABLE(gnat-projects,
739         [  --disable-gnat-projects test: disable GNAT projects even if usable],
740         [enable_gnat_projects=no],
741         [enable_gnat_projects=yes])
742 AC_MSG_RESULT($enable_gnat_projects)
743 ])dnl
744 dnl ---------------------------------------------------------------------------
745 dnl CF_ENABLE_PC_FILES version: 12 updated: 2015/04/17 21:13:04
746 dnl ------------------
747 dnl This is the "--enable-pc-files" option, which is available if there is a
748 dnl pkg-config configuration on the local machine.
749 AC_DEFUN([CF_ENABLE_PC_FILES],[
750 AC_REQUIRE([CF_PKG_CONFIG])
751 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
752
753 if test "x$PKG_CONFIG" != xnone
754 then
755         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
756 else
757         AC_MSG_CHECKING(if we should install .pc files)
758 fi
759
760 AC_ARG_ENABLE(pc-files,
761         [  --enable-pc-files       generate and install .pc files for pkg-config],
762         [enable_pc_files=$enableval],
763         [enable_pc_files=no])
764 AC_MSG_RESULT($enable_pc_files)
765
766 if test "x$enable_pc_files" != xno
767 then
768         case "x$PKG_CONFIG_LIBDIR" in
769         (xno|xyes)
770                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
771                 MAKE_PC_FILES="#"
772                 ;;
773         (*)
774                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
775                 MAKE_PC_FILES=
776                 ;;
777         esac
778 else
779         MAKE_PC_FILES="#"
780 fi
781 AC_SUBST(MAKE_PC_FILES)
782 ])dnl
783 dnl ---------------------------------------------------------------------------
784 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
785 dnl ---------------
786 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
787 dnl prefer a standard location, and use -L options only if we do not find the
788 dnl library in the standard library location(s).
789 dnl     $1 = library name
790 dnl     $2 = library class, usually the same as library name
791 dnl     $3 = includes
792 dnl     $4 = code fragment to compile/link
793 dnl     $5 = corresponding function-name
794 dnl     $6 = flag, nonnull if failure should not cause an error-exit
795 dnl
796 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
797 dnl to use a -L option.
798 AC_DEFUN([CF_FIND_LIBRARY],
799 [
800         eval 'cf_cv_have_lib_'$1'=no'
801         cf_libdir=""
802         AC_CHECK_FUNC($5,
803                 eval 'cf_cv_have_lib_'$1'=yes',[
804                 cf_save_LIBS="$LIBS"
805                 AC_MSG_CHECKING(for $5 in -l$1)
806                 LIBS="-l$1 $LIBS"
807                 AC_TRY_LINK([$3],[$4],
808                         [AC_MSG_RESULT(yes)
809                          eval 'cf_cv_have_lib_'$1'=yes'
810                         ],
811                         [AC_MSG_RESULT(no)
812                         CF_LIBRARY_PATH(cf_search,$2)
813                         for cf_libdir in $cf_search
814                         do
815                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
816                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
817                                 AC_TRY_LINK([$3],[$4],
818                                         [AC_MSG_RESULT(yes)
819                                          eval 'cf_cv_have_lib_'$1'=yes'
820                                          break],
821                                         [AC_MSG_RESULT(no)
822                                          LIBS="$cf_save_LIBS"])
823                         done
824                         ])
825                 ])
826 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
827 ifelse($6,,[
828 if test $cf_found_library = no ; then
829         AC_MSG_ERROR(Cannot link $1 library)
830 fi
831 ])
832 ])dnl
833 dnl ---------------------------------------------------------------------------
834 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
835 dnl ---------------
836 dnl Find a library (specifically the linkage used in the code fragment),
837 dnl searching for it if it is not already in the library path.
838 dnl See also CF_ADD_SEARCHPATH.
839 dnl
840 dnl Parameters (4-on are optional):
841 dnl     $1 = headers for library entrypoint
842 dnl     $2 = code fragment for library entrypoint
843 dnl     $3 = the library name without the "-l" option or ".so" suffix.
844 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
845 dnl     $5 = action to perform if not successful
846 dnl     $6 = module name, if not the same as the library name
847 dnl     $7 = extra libraries
848 dnl
849 dnl Sets these variables:
850 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
851 dnl     $cf_cv_header_path_$3 - include-directory if needed
852 dnl     $cf_cv_library_path_$3 - library-directory if needed
853 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
854 AC_DEFUN([CF_FIND_LINKAGE],[
855
856 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
857 # will be set on completion of the AC_TRY_LINK below.
858 cf_cv_header_path_$3=
859 cf_cv_library_path_$3=
860
861 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
862
863 cf_save_LIBS="$LIBS"
864
865 AC_TRY_LINK([$1],[$2],[
866         cf_cv_find_linkage_$3=yes
867         cf_cv_header_path_$3=/usr/include
868         cf_cv_library_path_$3=/usr/lib
869 ],[
870
871 LIBS="-l$3 $7 $cf_save_LIBS"
872
873 AC_TRY_LINK([$1],[$2],[
874         cf_cv_find_linkage_$3=yes
875         cf_cv_header_path_$3=/usr/include
876         cf_cv_library_path_$3=/usr/lib
877         cf_cv_library_file_$3="-l$3"
878 ],[
879         cf_cv_find_linkage_$3=no
880         LIBS="$cf_save_LIBS"
881
882         CF_VERBOSE(find linkage for $3 library)
883         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
884
885         cf_save_CPPFLAGS="$CPPFLAGS"
886         cf_test_CPPFLAGS="$CPPFLAGS"
887
888         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
889         for cf_cv_header_path_$3 in $cf_search
890         do
891                 if test -d $cf_cv_header_path_$3 ; then
892                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
893                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
894                         AC_TRY_COMPILE([$1],[$2],[
895                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
896                                 cf_cv_find_linkage_$3=maybe
897                                 cf_test_CPPFLAGS="$CPPFLAGS"
898                                 break],[
899                                 CPPFLAGS="$cf_save_CPPFLAGS"
900                                 ])
901                 fi
902         done
903
904         if test "$cf_cv_find_linkage_$3" = maybe ; then
905
906                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
907
908                 cf_save_LIBS="$LIBS"
909                 cf_save_LDFLAGS="$LDFLAGS"
910
911                 ifelse([$6],,,[
912                 CPPFLAGS="$cf_test_CPPFLAGS"
913                 LIBS="-l$3 $7 $cf_save_LIBS"
914                 AC_TRY_LINK([$1],[$2],[
915                         CF_VERBOSE(... found $3 library in system)
916                         cf_cv_find_linkage_$3=yes])
917                         CPPFLAGS="$cf_save_CPPFLAGS"
918                         LIBS="$cf_save_LIBS"
919                         ])
920
921                 if test "$cf_cv_find_linkage_$3" != yes ; then
922                         CF_LIBRARY_PATH(cf_search,$3)
923                         for cf_cv_library_path_$3 in $cf_search
924                         do
925                                 if test -d $cf_cv_library_path_$3 ; then
926                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
927                                         CPPFLAGS="$cf_test_CPPFLAGS"
928                                         LIBS="-l$3 $7 $cf_save_LIBS"
929                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
930                                         AC_TRY_LINK([$1],[$2],[
931                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
932                                         cf_cv_find_linkage_$3=yes
933                                         cf_cv_library_file_$3="-l$3"
934                                         break],[
935                                         CPPFLAGS="$cf_save_CPPFLAGS"
936                                         LIBS="$cf_save_LIBS"
937                                         LDFLAGS="$cf_save_LDFLAGS"
938                                         ])
939                                 fi
940                         done
941                         CPPFLAGS="$cf_save_CPPFLAGS"
942                         LDFLAGS="$cf_save_LDFLAGS"
943                 fi
944
945         else
946                 cf_cv_find_linkage_$3=no
947         fi
948         ],$7)
949 ])
950
951 LIBS="$cf_save_LIBS"
952
953 if test "$cf_cv_find_linkage_$3" = yes ; then
954 ifelse([$4],,[
955         CF_ADD_INCDIR($cf_cv_header_path_$3)
956         CF_ADD_LIBDIR($cf_cv_library_path_$3)
957         CF_ADD_LIB($3)
958 ],[$4])
959 else
960 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
961 fi
962 ])dnl
963 dnl ---------------------------------------------------------------------------
964 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
965 dnl -----------------
966 dnl make ADAFLAGS consistent with CFLAGS
967 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
968         AC_MSG_CHECKING(optimization options for ADAFLAGS)
969         case "$CFLAGS" in
970         (*-g*)
971                 CF_ADD_ADAFLAGS(-g)
972                 ;;
973         esac
974         case "$CFLAGS" in
975         (*-O*)
976                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
977                 CF_ADD_ADAFLAGS($cf_O_flag)
978                 ;;
979         esac
980         AC_MSG_RESULT($ADAFLAGS)
981 ])dnl
982 dnl ---------------------------------------------------------------------------
983 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
984 dnl -----------------
985 dnl Test for availability of useful gcc __attribute__ directives to quiet
986 dnl compiler warnings.  Though useful, not all are supported -- and contrary
987 dnl to documentation, unrecognized directives cause older compilers to barf.
988 AC_DEFUN([CF_GCC_ATTRIBUTES],
989 [
990 if test "$GCC" = yes
991 then
992 cat > conftest.i <<EOF
993 #ifndef GCC_PRINTF
994 #define GCC_PRINTF 0
995 #endif
996 #ifndef GCC_SCANF
997 #define GCC_SCANF 0
998 #endif
999 #ifndef GCC_NORETURN
1000 #define GCC_NORETURN /* nothing */
1001 #endif
1002 #ifndef GCC_UNUSED
1003 #define GCC_UNUSED /* nothing */
1004 #endif
1005 EOF
1006 if test "$GCC" = yes
1007 then
1008         AC_CHECKING([for $CC __attribute__ directives])
1009 cat > conftest.$ac_ext <<EOF
1010 #line __oline__ "${as_me:-configure}"
1011 #include "confdefs.h"
1012 #include "conftest.h"
1013 #include "conftest.i"
1014 #if     GCC_PRINTF
1015 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1016 #else
1017 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1018 #endif
1019 #if     GCC_SCANF
1020 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1021 #else
1022 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1023 #endif
1024 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1025 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1026 extern void foo(void) GCC_NORETURN;
1027 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1028 EOF
1029         cf_printf_attribute=no
1030         cf_scanf_attribute=no
1031         for cf_attribute in scanf printf unused noreturn
1032         do
1033                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1034                 cf_directive="__attribute__(($cf_attribute))"
1035                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1036
1037                 case $cf_attribute in
1038                 (printf)
1039                         cf_printf_attribute=yes
1040                         cat >conftest.h <<EOF
1041 #define GCC_$cf_ATTRIBUTE 1
1042 EOF
1043                         ;;
1044                 (scanf)
1045                         cf_scanf_attribute=yes
1046                         cat >conftest.h <<EOF
1047 #define GCC_$cf_ATTRIBUTE 1
1048 EOF
1049                         ;;
1050                 (*)
1051                         cat >conftest.h <<EOF
1052 #define GCC_$cf_ATTRIBUTE $cf_directive
1053 EOF
1054                         ;;
1055                 esac
1056
1057                 if AC_TRY_EVAL(ac_compile); then
1058                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1059                         cat conftest.h >>confdefs.h
1060                         case $cf_attribute in
1061                         (noreturn)
1062                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1063                                 ;;
1064                         (printf)
1065                                 cf_value='/* nothing */'
1066                                 if test "$cf_printf_attribute" != no ; then
1067                                         cf_value='__attribute__((format(printf,fmt,var)))'
1068                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1069                                 fi
1070                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1071                                 ;;
1072                         (scanf)
1073                                 cf_value='/* nothing */'
1074                                 if test "$cf_scanf_attribute" != no ; then
1075                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1076                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1077                                 fi
1078                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1079                                 ;;
1080                         (unused)
1081                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1082                                 ;;
1083                         esac
1084                 fi
1085         done
1086 else
1087         fgrep define conftest.i >>confdefs.h
1088 fi
1089 rm -rf conftest*
1090 fi
1091 ])dnl
1092 dnl ---------------------------------------------------------------------------
1093 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1094 dnl --------------
1095 dnl Find version of gcc
1096 AC_DEFUN([CF_GCC_VERSION],[
1097 AC_REQUIRE([AC_PROG_CC])
1098 GCC_VERSION=none
1099 if test "$GCC" = yes ; then
1100         AC_MSG_CHECKING(version of $CC)
1101         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1102         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1103         AC_MSG_RESULT($GCC_VERSION)
1104 fi
1105 ])dnl
1106 dnl ---------------------------------------------------------------------------
1107 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
1108 dnl ---------------
1109 dnl Check if the compiler supports useful warning options.  There's a few that
1110 dnl we don't use, simply because they're too noisy:
1111 dnl
1112 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1113 dnl     -Wredundant-decls (system headers make this too noisy)
1114 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1115 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1116 dnl             is enabled for ncurses using "--enable-const".
1117 dnl     -pedantic
1118 dnl
1119 dnl Parameter:
1120 dnl     $1 is an optional list of gcc warning flags that a particular
1121 dnl             application might want to use, e.g., "no-unused" for
1122 dnl             -Wno-unused
1123 dnl Special:
1124 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1125 dnl
1126 AC_DEFUN([CF_GCC_WARNINGS],
1127 [
1128 AC_REQUIRE([CF_GCC_VERSION])
1129 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1130 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1131
1132 cat > conftest.$ac_ext <<EOF
1133 #line __oline__ "${as_me:-configure}"
1134 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1135 EOF
1136
1137 if test "$INTEL_COMPILER" = yes
1138 then
1139 # The "-wdXXX" options suppress warnings:
1140 # remark #1419: external declaration in primary source file
1141 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1142 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1143 # remark #193: zero used for undefined preprocessing identifier
1144 # remark #593: variable "curs_sb_left_arrow" was set but never used
1145 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1146 # remark #869: parameter "tw" was never referenced
1147 # remark #981: operands are evaluated in unspecified order
1148 # warning #279: controlling expression is constant
1149
1150         AC_CHECKING([for $CC warning options])
1151         cf_save_CFLAGS="$CFLAGS"
1152         EXTRA_CFLAGS="-Wall"
1153         for cf_opt in \
1154                 wd1419 \
1155                 wd1683 \
1156                 wd1684 \
1157                 wd193 \
1158                 wd593 \
1159                 wd279 \
1160                 wd810 \
1161                 wd869 \
1162                 wd981
1163         do
1164                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1165                 if AC_TRY_EVAL(ac_compile); then
1166                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1167                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1168                 fi
1169         done
1170         CFLAGS="$cf_save_CFLAGS"
1171
1172 elif test "$GCC" = yes
1173 then
1174         AC_CHECKING([for $CC warning options])
1175         cf_save_CFLAGS="$CFLAGS"
1176         EXTRA_CFLAGS=
1177         cf_warn_CONST=""
1178         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1179         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1180         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1181         for cf_opt in W Wall \
1182                 Wbad-function-cast \
1183                 Wcast-align \
1184                 Wcast-qual \
1185                 Wdeclaration-after-statement \
1186                 Wextra \
1187                 Winline \
1188                 Wmissing-declarations \
1189                 Wmissing-prototypes \
1190                 Wnested-externs \
1191                 Wpointer-arith \
1192                 Wshadow \
1193                 Wstrict-prototypes \
1194                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
1195         do
1196                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1197                 if AC_TRY_EVAL(ac_compile); then
1198                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1199                         case $cf_opt in
1200                         (Wcast-qual)
1201                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1202                                 ;;
1203                         (Winline)
1204                                 case $GCC_VERSION in
1205                                 ([[34]].*)
1206                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1207                                         continue;;
1208                                 esac
1209                                 ;;
1210                         (Wpointer-arith)
1211                                 case $GCC_VERSION in
1212                                 ([[12]].*)
1213                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1214                                         continue;;
1215                                 esac
1216                                 ;;
1217                         esac
1218                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1219                 fi
1220         done
1221         CFLAGS="$cf_save_CFLAGS"
1222 fi
1223 rm -rf conftest*
1224
1225 AC_SUBST(EXTRA_CFLAGS)
1226 ])dnl
1227 dnl ---------------------------------------------------------------------------
1228 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
1229 dnl -----------------
1230 AC_DEFUN([CF_GNATPREP_OPT_T],[
1231 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
1232 cf_cv_gnatprep_opt_t=no
1233 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
1234 ])
1235 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
1236 AC_SUBST(GNATPREP_OPTS)
1237 ])dnl
1238 dnl ---------------------------------------------------------------------------
1239 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
1240 dnl ----------------
1241 AC_DEFUN([CF_GNAT_GENERICS],
1242 [
1243 AC_REQUIRE([CF_GNAT_VERSION])
1244
1245 AC_MSG_CHECKING(if GNAT supports generics)
1246 case $cf_gnat_version in
1247 (3.[[1-9]]*|[[4-9]].*)
1248         cf_gnat_generics=yes
1249         ;;
1250 (*)
1251         cf_gnat_generics=no
1252         ;;
1253 esac
1254 AC_MSG_RESULT($cf_gnat_generics)
1255
1256 if test "$cf_gnat_generics" = yes
1257 then
1258         cf_compile_generics=generics
1259         cf_generic_objects="\${GENOBJS}"
1260 else
1261         cf_compile_generics=
1262         cf_generic_objects=
1263 fi
1264
1265 AC_SUBST(cf_compile_generics)
1266 AC_SUBST(cf_generic_objects)
1267 ])dnl
1268 dnl ---------------------------------------------------------------------------
1269 dnl CF_GNAT_PROJECTS version: 8 updated: 2015/04/17 21:13:04
1270 dnl ----------------
1271 dnl GNAT projects are configured with ".gpr" project files.
1272 dnl GNAT libraries are a further development, using the project feature.
1273 AC_DEFUN([CF_GNAT_PROJECTS],
1274 [
1275 AC_REQUIRE([CF_GNAT_VERSION])
1276 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
1277
1278 cf_gnat_libraries=no
1279 cf_gnat_projects=no
1280
1281 if test "$enable_gnat_projects" != no ; then
1282 AC_MSG_CHECKING(if GNAT supports project files)
1283 case $cf_gnat_version in
1284 (3.[[0-9]]*)
1285         ;;
1286 (*)
1287         case $cf_cv_system_name in
1288         (cygwin*|msys*)
1289                 ;;
1290         (*)
1291                 mkdir conftest.src conftest.bin conftest.lib
1292                 cd conftest.src
1293                 rm -rf conftest* *~conftest*
1294                 cat >>library.gpr <<CF_EOF
1295 project Library is
1296   Kind := External ("LIB_KIND");
1297   for Library_Name use "ConfTest";
1298   for Object_Dir use ".";
1299   for Library_ALI_Dir use External("LIBRARY_DIR");
1300   for Library_Version use External ("SONAME");
1301   for Library_Kind use Kind;
1302   for Library_Dir use External("BUILD_DIR");
1303   Source_Dir := External ("SOURCE_DIR");
1304   for Source_Dirs use (Source_Dir);
1305 end Library;
1306 CF_EOF
1307                 cat >>confpackage.ads <<CF_EOF
1308 package ConfPackage is
1309    procedure conftest;
1310 end ConfPackage;
1311 CF_EOF
1312                 cat >>confpackage.adb <<CF_EOF
1313 with Text_IO;
1314 package body ConfPackage is
1315    procedure conftest is
1316    begin
1317       Text_IO.Put ("Hello World");
1318       Text_IO.New_Line;
1319    end conftest;
1320 end ConfPackage;
1321 CF_EOF
1322                 if ( $cf_ada_make $ADAFLAGS \
1323                                 -Plibrary.gpr \
1324                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
1325                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
1326                                 -XSOURCE_DIR=`pwd` \
1327                                 -XSONAME=libConfTest.so.1 \
1328                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1329                         cf_gnat_projects=yes
1330                 fi
1331                 cd ..
1332                 if test -f conftest.lib/confpackage.ali
1333                 then
1334                         cf_gnat_libraries=yes
1335                 fi
1336                 rm -rf conftest* *~conftest*
1337                 ;;
1338         esac
1339         ;;
1340 esac
1341 AC_MSG_RESULT($cf_gnat_projects)
1342 fi # enable_gnat_projects
1343
1344 if test $cf_gnat_projects = yes
1345 then
1346         AC_MSG_CHECKING(if GNAT supports libraries)
1347         AC_MSG_RESULT($cf_gnat_libraries)
1348 fi
1349
1350 if test "$cf_gnat_projects" = yes
1351 then
1352         USE_OLD_MAKERULES="#"
1353         USE_GNAT_PROJECTS=""
1354 else
1355         USE_OLD_MAKERULES=""
1356         USE_GNAT_PROJECTS="#"
1357 fi
1358
1359 if test "$cf_gnat_libraries" = yes
1360 then
1361         USE_GNAT_LIBRARIES=""
1362 else
1363         USE_GNAT_LIBRARIES="#"
1364 fi
1365
1366 AC_SUBST(USE_OLD_MAKERULES)
1367 AC_SUBST(USE_GNAT_PROJECTS)
1368 AC_SUBST(USE_GNAT_LIBRARIES)
1369 ])dnl
1370 dnl ---------------------------------------------------------------------------
1371 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
1372 dnl --------------
1373 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1374 dnl is noted that gnat may compile a tasking unit even for configurations which
1375 dnl fail at runtime.
1376 AC_DEFUN([CF_GNAT_SIGINT],[
1377 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1378 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1379
1380 package ConfTest is
1381
1382    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1383    pragma Unreserve_All_Interrupts;
1384    pragma Warnings (On);
1385
1386    protected Process is
1387       procedure Stop;
1388       function Continue return Boolean;
1389       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1390    private
1391       Done : Boolean := False;
1392    end Process;
1393
1394 end ConfTest;],
1395 [package body ConfTest is
1396    protected body Process is
1397       procedure Stop is
1398       begin
1399          Done := True;
1400       end Stop;
1401       function Continue return Boolean is
1402       begin
1403          return not Done;
1404       end Continue;
1405    end Process;
1406 end ConfTest;],
1407         [cf_cv_gnat_sigint=yes],
1408         [cf_cv_gnat_sigint=no])])
1409
1410 if test $cf_cv_gnat_sigint = yes ; then
1411         USE_GNAT_SIGINT=""
1412 else
1413         USE_GNAT_SIGINT="#"
1414 fi
1415 AC_SUBST(USE_GNAT_SIGINT)
1416 ])dnl
1417 dnl ---------------------------------------------------------------------------
1418 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
1419 dnl ----------------
1420 dnl Verify that a test program compiles/links with GNAT.
1421 dnl $cf_ada_make is set to the program that compiles/links
1422 dnl $ADAFLAGS may be set to the GNAT flags.
1423 dnl
1424 dnl $1 is the text of the spec
1425 dnl $2 is the text of the body
1426 dnl $3 is the shell command to execute if successful
1427 dnl $4 is the shell command to execute if not successful
1428 AC_DEFUN([CF_GNAT_TRY_LINK],
1429 [
1430 rm -rf conftest* *~conftest*
1431 cat >>conftest.ads <<CF_EOF
1432 $1
1433 CF_EOF
1434 cat >>conftest.adb <<CF_EOF
1435 $2
1436 CF_EOF
1437 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1438 ifelse($3,,      :,[      $3])
1439 ifelse($4,,,[else
1440    $4])
1441 fi
1442 rm -rf conftest* *~conftest*
1443 ])dnl
1444 dnl ---------------------------------------------------------------------------
1445 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
1446 dnl ---------------
1447 dnl Verify that a test program compiles and runs with GNAT
1448 dnl $cf_ada_make is set to the program that compiles/links
1449 dnl $ADAFLAGS may be set to the GNAT flags.
1450 dnl
1451 dnl $1 is the text of the spec
1452 dnl $2 is the text of the body
1453 dnl $3 is the shell command to execute if successful
1454 dnl $4 is the shell command to execute if not successful
1455 AC_DEFUN([CF_GNAT_TRY_RUN],
1456 [
1457 rm -rf conftest* *~conftest*
1458 cat >>conftest.ads <<CF_EOF
1459 $1
1460 CF_EOF
1461 cat >>conftest.adb <<CF_EOF
1462 $2
1463 CF_EOF
1464 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1465    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1466 ifelse($3,,      :,[      $3])
1467 ifelse($4,,,[   else
1468       $4])
1469    fi
1470 ifelse($4,,,[else
1471    $4])
1472 fi
1473 rm -rf conftest* *~conftest*
1474 ])dnl
1475 dnl ---------------------------------------------------------------------------
1476 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
1477 dnl ---------------
1478 dnl Verify version of GNAT.
1479 AC_DEFUN([CF_GNAT_VERSION],
1480 [
1481 AC_MSG_CHECKING(for gnat version)
1482 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
1483         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1484         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1485 AC_MSG_RESULT($cf_gnat_version)
1486
1487 case $cf_gnat_version in
1488 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
1489         cf_cv_prog_gnat_correct=yes
1490         ;;
1491 (*)
1492         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1493         cf_cv_prog_gnat_correct=no
1494         ;;
1495 esac
1496 ])
1497 dnl ---------------------------------------------------------------------------
1498 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
1499 dnl -------------
1500 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1501 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1502 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1503 dnl since it is interwoven with GNU extensions.
1504 dnl
1505 dnl Well, yes we could work around it...
1506 AC_DEFUN([CF_GNU_SOURCE],
1507 [
1508 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1509 AC_TRY_COMPILE([#include <sys/types.h>],[
1510 #ifndef _XOPEN_SOURCE
1511 make an error
1512 #endif],
1513         [cf_cv_gnu_source=no],
1514         [cf_save="$CPPFLAGS"
1515          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1516          AC_TRY_COMPILE([#include <sys/types.h>],[
1517 #ifdef _XOPEN_SOURCE
1518 make an error
1519 #endif],
1520         [cf_cv_gnu_source=no],
1521         [cf_cv_gnu_source=yes])
1522         CPPFLAGS="$cf_save"
1523         ])
1524 ])
1525 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1526 ])dnl
1527 dnl ---------------------------------------------------------------------------
1528 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
1529 dnl --------------
1530 dnl Construct a search-list of directories for a nonstandard header-file
1531 dnl
1532 dnl Parameters
1533 dnl     $1 = the variable to return as result
1534 dnl     $2 = the package name
1535 AC_DEFUN([CF_HEADER_PATH],
1536 [
1537 $1=
1538
1539 # collect the current set of include-directories from compiler flags
1540 cf_header_path_list=""
1541 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1542         for cf_header_path in $CPPFLAGS $CFLAGS
1543         do
1544                 case $cf_header_path in
1545                 (-I*)
1546                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1547                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1548                         cf_header_path_list="$cf_header_path_list [$]$1"
1549                         ;;
1550                 esac
1551         done
1552 fi
1553
1554 # add the variations for the package we are looking for
1555 CF_SUBDIR_PATH($1,$2,include)
1556
1557 test "$includedir" != NONE && \
1558 test "$includedir" != "/usr/include" && \
1559 test -d "$includedir" && {
1560         test -d $includedir &&    $1="[$]$1 $includedir"
1561         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1562 }
1563
1564 test "$oldincludedir" != NONE && \
1565 test "$oldincludedir" != "/usr/include" && \
1566 test -d "$oldincludedir" && {
1567         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1568         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1569 }
1570
1571 $1="[$]$1 $cf_header_path_list"
1572 ])dnl
1573 dnl ---------------------------------------------------------------------------
1574 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1575 dnl ---------------
1576 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1577 AC_DEFUN([CF_HELP_MESSAGE],
1578 [AC_DIVERT_HELP([$1])dnl
1579 ])dnl
1580 dnl ---------------------------------------------------------------------------
1581 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
1582 dnl ---------------
1583 dnl Construct the list of include-options according to whether we're building
1584 dnl in the source directory or using '--srcdir=DIR' option.
1585 AC_DEFUN([CF_INCLUDE_DIRS],
1586 [
1587 if test "$srcdir" != "."; then
1588         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
1589 fi
1590 CPPFLAGS="-I../include $CPPFLAGS"
1591 if test "$srcdir" != "."; then
1592         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
1593 fi
1594 CPPFLAGS="-I. $CPPFLAGS"
1595 AC_SUBST(CPPFLAGS)
1596 ])dnl
1597 dnl ---------------------------------------------------------------------------
1598 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
1599 dnl -----------------
1600 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1601 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1602 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1603 dnl
1604 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1605 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1606 dnl the wrappers for gcc and g++ warnings.
1607 dnl
1608 dnl $1 = GCC (default) or GXX
1609 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1610 dnl $3 = CFLAGS (default) or CXXFLAGS
1611 AC_DEFUN([CF_INTEL_COMPILER],[
1612 AC_REQUIRE([AC_CANONICAL_HOST])
1613 ifelse([$2],,INTEL_COMPILER,[$2])=no
1614
1615 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1616         case $host_os in
1617         (linux*|gnu*)
1618                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1619                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1620                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1621                 AC_TRY_COMPILE([],[
1622 #ifdef __INTEL_COMPILER
1623 #else
1624 make an error
1625 #endif
1626 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1627 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
1628 ],[])
1629                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1630                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1631                 ;;
1632         esac
1633 fi
1634 ])dnl
1635 dnl ---------------------------------------------------------------------------
1636 dnl CF_LARGEFILE version: 9 updated: 2015/04/18 08:56:57
1637 dnl ------------
1638 dnl Add checks for large file support.
1639 AC_DEFUN([CF_LARGEFILE],[
1640 ifdef([AC_FUNC_FSEEKO],[
1641         AC_SYS_LARGEFILE
1642         if test "$enable_largefile" != no ; then
1643         AC_FUNC_FSEEKO
1644
1645         # Normally we would collect these definitions in the config.h,
1646         # but (like _XOPEN_SOURCE), some environments rely on having these
1647         # defined before any of the system headers are included.  Another
1648         # case comes up with C++, e.g., on AIX the compiler compiles the
1649         # header files by themselves before looking at the body files it is
1650         # told to compile.  For ncurses, those header files do not include
1651         # the config.h
1652         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
1653         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
1654         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
1655
1656         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
1657                 AC_TRY_COMPILE([
1658 #include <sys/types.h>
1659 #include <dirent.h>
1660                 ],[
1661                 /* if transitional largefile support is setup, this is true */
1662                 extern struct dirent64 * readdir(DIR *);
1663                 struct dirent64 *x = readdir((DIR *)0);
1664                 struct dirent *y = readdir((DIR *)0);
1665                 int z = x - y;
1666                 ],
1667                 [cf_cv_struct_dirent64=yes],
1668                 [cf_cv_struct_dirent64=no])
1669         ])
1670         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
1671         fi
1672 ])
1673 ])
1674 dnl ---------------------------------------------------------------------------
1675 dnl CF_LD_RPATH_OPT version: 6 updated: 2015/04/12 15:39:00
1676 dnl ---------------
1677 dnl For the given system and compiler, find the compiler flags to pass to the
1678 dnl loader to use the "rpath" feature.
1679 AC_DEFUN([CF_LD_RPATH_OPT],
1680 [
1681 AC_REQUIRE([CF_CHECK_CACHE])
1682
1683 LD_RPATH_OPT=
1684 AC_MSG_CHECKING(for an rpath option)
1685 case $cf_cv_system_name in
1686 (irix*)
1687         if test "$GCC" = yes; then
1688                 LD_RPATH_OPT="-Wl,-rpath,"
1689         else
1690                 LD_RPATH_OPT="-rpath "
1691         fi
1692         ;;
1693 (linux*|gnu*|k*bsd*-gnu)
1694         LD_RPATH_OPT="-Wl,-rpath,"
1695         ;;
1696 (openbsd[[2-9]].*|mirbsd*)
1697         LD_RPATH_OPT="-Wl,-rpath,"
1698         ;;
1699 (dragonfly*|freebsd*)
1700         LD_RPATH_OPT="-rpath "
1701         ;;
1702 (netbsd*)
1703         LD_RPATH_OPT="-Wl,-rpath,"
1704         ;;
1705 (osf*|mls+*)
1706         LD_RPATH_OPT="-rpath "
1707         ;;
1708 (solaris2*)
1709         LD_RPATH_OPT="-R"
1710         ;;
1711 (*)
1712         ;;
1713 esac
1714 AC_MSG_RESULT($LD_RPATH_OPT)
1715
1716 case "x$LD_RPATH_OPT" in
1717 (x-R*)
1718         AC_MSG_CHECKING(if we need a space after rpath option)
1719         cf_save_LIBS="$LIBS"
1720         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1721         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1722         LIBS="$cf_save_LIBS"
1723         AC_MSG_RESULT($cf_rpath_space)
1724         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1725         ;;
1726 esac
1727 ])dnl
1728 dnl ---------------------------------------------------------------------------
1729 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
1730 dnl ---------------
1731 dnl Construct a search-list of directories for a nonstandard library-file
1732 dnl
1733 dnl Parameters
1734 dnl     $1 = the variable to return as result
1735 dnl     $2 = the package name
1736 AC_DEFUN([CF_LIBRARY_PATH],
1737 [
1738 $1=
1739 cf_library_path_list=""
1740 if test -n "${LDFLAGS}${LIBS}" ; then
1741         for cf_library_path in $LDFLAGS $LIBS
1742         do
1743                 case $cf_library_path in
1744                 (-L*)
1745                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1746                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1747                         cf_library_path_list="$cf_library_path_list [$]$1"
1748                         ;;
1749                 esac
1750         done
1751 fi
1752
1753 CF_SUBDIR_PATH($1,$2,lib)
1754
1755 $1="$cf_library_path_list [$]$1"
1756 ])dnl
1757 dnl ---------------------------------------------------------------------------
1758 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
1759 dnl -------------
1760 dnl Compute the library-prefix for the given host system
1761 dnl $1 = variable to set
1762 define([CF_LIB_PREFIX],
1763 [
1764         case $cf_cv_system_name in
1765         (OS/2*|os2*)
1766                 if test "$DFT_LWR_MODEL" = libtool; then
1767                         LIB_PREFIX='lib'
1768                 else
1769                         LIB_PREFIX=''
1770                 fi
1771                 ;;
1772         (*)     LIB_PREFIX='lib'
1773                 ;;
1774         esac
1775 ifelse($1,,,[$1=$LIB_PREFIX])
1776         AC_SUBST(LIB_PREFIX)
1777 ])dnl
1778 dnl ---------------------------------------------------------------------------
1779 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
1780 dnl -------------
1781 dnl Compute the library file-suffix from the given model name
1782 dnl $1 = model name
1783 dnl $2 = variable to set (the nominal library suffix)
1784 dnl $3 = dependency variable to set (actual filename)
1785 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1786 AC_DEFUN([CF_LIB_SUFFIX],
1787 [
1788         case X$1 in
1789         (Xlibtool)
1790                 $2='.la'
1791                 $3=[$]$2
1792                 ;;
1793         (Xdebug)
1794                 $2='_g.a'
1795                 $3=[$]$2
1796                 ;;
1797         (Xprofile)
1798                 $2='_p.a'
1799                 $3=[$]$2
1800                 ;;
1801         (Xshared)
1802                 case $cf_cv_system_name in
1803                 (aix[[5-7]]*)
1804                         $2='.so'
1805                         $3=[$]$2
1806                         ;;
1807                 (cygwin*|msys*|mingw*)
1808                         $2='.dll'
1809                         $3='.dll.a'
1810                         ;;
1811                 (darwin*)
1812                         $2='.dylib'
1813                         $3=[$]$2
1814                         ;;
1815                 (hpux*)
1816                         case $target in
1817                         (ia64*)
1818                                 $2='.so'
1819                                 $3=[$]$2
1820                                 ;;
1821                         (*)
1822                                 $2='.sl'
1823                                 $3=[$]$2
1824                                 ;;
1825                         esac
1826                         ;;
1827                 (*)
1828                         $2='.so'
1829                         $3=[$]$2
1830                         ;;
1831                 esac
1832                 ;;
1833         (*)
1834                 $2='.a'
1835                 $3=[$]$2
1836                 ;;
1837         esac
1838         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
1839         then
1840                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
1841                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
1842         fi
1843 ])dnl
1844 dnl ---------------------------------------------------------------------------
1845 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
1846 dnl -----------
1847 dnl Compute the string to append to -library from the given model name
1848 dnl $1 = model name
1849 dnl $2 = variable to set
1850 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1851 AC_DEFUN([CF_LIB_TYPE],
1852 [
1853         case $1 in
1854         (libtool) $2=''   ;;
1855         (normal)  $2=''   ;;
1856         (debug)   $2='_g' ;;
1857         (profile) $2='_p' ;;
1858         (shared)  $2=''   ;;
1859         esac
1860         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1861 ])dnl
1862 dnl ---------------------------------------------------------------------------
1863 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
1864 dnl ----------------
1865 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
1866 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
1867 dnl have to provide wrappers for global tables to ensure they're linked
1868 dnl properly.
1869 AC_DEFUN([CF_LINK_DATAONLY],
1870 [
1871 AC_MSG_CHECKING([if data-only library module links])
1872 AC_CACHE_VAL(cf_cv_link_dataonly,[
1873         rm -f conftest.a
1874         cat >conftest.$ac_ext <<EOF
1875 #line __oline__ "configure"
1876 int     testdata[[3]] = { 123, 456, 789 };
1877 EOF
1878         if AC_TRY_EVAL(ac_compile) ; then
1879                 mv conftest.o data.o && \
1880                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
1881         fi
1882         rm -f conftest.$ac_ext data.o
1883         cat >conftest.$ac_ext <<EOF
1884 #line __oline__ "configure"
1885 int     testfunc()
1886 {
1887 #if defined(NeXT)
1888         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
1889 #else
1890         extern int testdata[[3]];
1891         return testdata[[0]] == 123
1892            &&  testdata[[1]] == 456
1893            &&  testdata[[2]] == 789;
1894 #endif
1895 }
1896 EOF
1897         if AC_TRY_EVAL(ac_compile); then
1898                 mv conftest.o func.o && \
1899                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
1900         fi
1901         rm -f conftest.$ac_ext func.o
1902         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
1903         cf_saveLIBS="$LIBS"
1904         LIBS="conftest.a $LIBS"
1905         AC_TRY_RUN([
1906         int main()
1907         {
1908                 extern int testfunc();
1909                 ${cf_cv_main_return:-return} (!testfunc());
1910         }
1911         ],
1912         [cf_cv_link_dataonly=yes],
1913         [cf_cv_link_dataonly=no],
1914         [cf_cv_link_dataonly=unknown])
1915         LIBS="$cf_saveLIBS"
1916         ])
1917 AC_MSG_RESULT($cf_cv_link_dataonly)
1918
1919 if test "$cf_cv_link_dataonly" = no ; then
1920         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
1921         BROKEN_LINKER=1
1922 fi
1923
1924 ])dnl
1925 dnl ---------------------------------------------------------------------------
1926 dnl CF_MAKEFLAGS version: 17 updated: 2015/08/05 20:44:28
1927 dnl ------------
1928 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
1929 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
1930 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
1931 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
1932 AC_DEFUN([CF_MAKEFLAGS],
1933 [
1934 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
1935         cf_cv_makeflags=''
1936         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
1937         do
1938                 cat >cf_makeflags.tmp <<CF_EOF
1939 SHELL = $SHELL
1940 all :
1941         @ echo '.$cf_option'
1942 CF_EOF
1943                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
1944                 case "$cf_result" in
1945                 (.*k|.*kw)
1946                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
1947                         case "$cf_result" in
1948                         (.*CC=*)        cf_cv_makeflags=
1949                                 ;;
1950                         (*)     cf_cv_makeflags=$cf_option
1951                                 ;;
1952                         esac
1953                         break
1954                         ;;
1955                 (.-)    ;;
1956                 (*)     echo "given option \"$cf_option\", no match \"$cf_result\""
1957                         ;;
1958                 esac
1959         done
1960         rm -f cf_makeflags.tmp
1961 ])
1962
1963 AC_SUBST(cf_cv_makeflags)
1964 ])dnl
1965 dnl ---------------------------------------------------------------------------
1966 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1967 dnl ------------
1968 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1969 dnl a monocase filesystem.
1970 AC_DEFUN([CF_MAKE_TAGS],[
1971 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1972
1973 AC_CHECK_PROGS(CTAGS, exctags ctags)
1974 AC_CHECK_PROGS(ETAGS, exetags etags)
1975
1976 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1977
1978 if test "$cf_cv_mixedcase" = yes ; then
1979         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1980 else
1981         MAKE_UPPER_TAGS=no
1982 fi
1983
1984 if test "$MAKE_UPPER_TAGS" = yes ; then
1985         MAKE_UPPER_TAGS=
1986 else
1987         MAKE_UPPER_TAGS="#"
1988 fi
1989
1990 if test "$MAKE_LOWER_TAGS" = yes ; then
1991         MAKE_LOWER_TAGS=
1992 else
1993         MAKE_LOWER_TAGS="#"
1994 fi
1995
1996 AC_SUBST(CTAGS)
1997 AC_SUBST(ETAGS)
1998
1999 AC_SUBST(MAKE_UPPER_TAGS)
2000 AC_SUBST(MAKE_LOWER_TAGS)
2001 ])dnl
2002 dnl ---------------------------------------------------------------------------
2003 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
2004 dnl ----------------------
2005 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2006 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2007 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2008 [
2009 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2010 if test "$cross_compiling" = yes ; then
2011         case $target_alias in
2012         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
2013                 cf_cv_mixedcase=no
2014                 ;;
2015         (*)
2016                 cf_cv_mixedcase=yes
2017                 ;;
2018         esac
2019 else
2020         rm -f conftest CONFTEST
2021         echo test >conftest
2022         if test -f CONFTEST ; then
2023                 cf_cv_mixedcase=no
2024         else
2025                 cf_cv_mixedcase=yes
2026         fi
2027         rm -f conftest CONFTEST
2028 fi
2029 ])
2030 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2031 ])dnl
2032 dnl ---------------------------------------------------------------------------
2033 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
2034 dnl ----------
2035 dnl Check for a working mkstemp.  This creates two files, checks that they are
2036 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2037 AC_DEFUN([CF_MKSTEMP],[
2038 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2039 rm -rf conftest*
2040 AC_TRY_RUN([
2041 #include <sys/types.h>
2042 #include <stdlib.h>
2043 #include <stdio.h>
2044 #include <string.h>
2045 #include <sys/stat.h>
2046 int main()
2047 {
2048         char *tmpl = "conftestXXXXXX";
2049         char name[2][80];
2050         int n;
2051         int result = 0;
2052         int fd;
2053         struct stat sb;
2054
2055         umask(077);
2056         for (n = 0; n < 2; ++n) {
2057                 strcpy(name[n], tmpl);
2058                 if ((fd = mkstemp(name[n])) >= 0) {
2059                         if (!strcmp(name[n], tmpl)
2060                          || stat(name[n], &sb) != 0
2061                          || (sb.st_mode & S_IFMT) != S_IFREG
2062                          || (sb.st_mode & 077) != 0) {
2063                                 result = 1;
2064                         }
2065                         close(fd);
2066                 }
2067         }
2068         if (result == 0
2069          && !strcmp(name[0], name[1]))
2070                 result = 1;
2071         ${cf_cv_main_return:-return}(result);
2072 }
2073 ],[cf_cv_func_mkstemp=yes
2074 ],[cf_cv_func_mkstemp=no
2075 ],[cf_cv_func_mkstemp=maybe])
2076 ])
2077 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2078         AC_CHECK_FUNC(mkstemp)
2079 fi
2080 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2081         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2082 fi
2083 ])dnl
2084 dnl ---------------------------------------------------------------------------
2085 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2086 dnl ----------
2087 dnl Write a debug message to config.log, along with the line number in the
2088 dnl configure script.
2089 AC_DEFUN([CF_MSG_LOG],[
2090 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2091 ])dnl
2092 dnl ---------------------------------------------------------------------------
2093 dnl CF_NCURSES_ADDON version: 5 updated: 2015/04/26 18:06:58
2094 dnl ----------------
2095 dnl Configure an ncurses add-on, built outside the ncurses tree.
2096 AC_DEFUN([CF_NCURSES_ADDON],[
2097 AC_REQUIRE([CF_NCURSES_CONFIG])
2098
2099 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2100
2101 AC_MSG_CHECKING(if you want wide-character code)
2102 AC_ARG_ENABLE(widec,
2103         [  --enable-widec          compile with wide-char/UTF-8 code],
2104         [with_widec=$enableval],
2105         [with_widec=no])
2106 AC_MSG_RESULT($with_widec)
2107 if test "$with_widec" = yes ; then
2108         CF_UTF8_LIB
2109         CF_NCURSES_CONFIG(ncursesw)
2110 else
2111         CF_NCURSES_CONFIG(ncurses)
2112 fi
2113
2114 if test "$NCURSES_CONFIG_PKG" != none ; then
2115         cf_version=`$PKG_CONFIG --modversion $NCURSES_CONFIG_PKG 2>/dev/null`
2116
2117         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2118         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2119         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2120
2121         cf_cv_abi_version=`$PKG_CONFIG --variable=abi_version $NCURSES_CONFIG_PKG 2>/dev/null`
2122         if test -z "$cf_cv_abi_version"
2123         then
2124                 cf_cv_abi_version=`$PKG_CONFIG --variable=major_version $NCURSES_CONFIG_PKG 2>/dev/null`
2125         fi
2126
2127 elif test "$NCURSES_CONFIG" != none ; then
2128
2129         cf_version=`$NCURSES_CONFIG --version 2>/dev/null`
2130
2131         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2132         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2133         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2134
2135         # ABI version is not available from headers
2136         cf_cv_abi_version=`$NCURSES_CONFIG --abi-version 2>/dev/null`
2137
2138 else
2139
2140         for cf_name in MAJOR MINOR PATCH
2141         do
2142         cat >conftest.$ac_ext <<CF_EOF
2143         #include <${cf_cv_ncurses_header:-curses.h}>
2144         AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2145 CF_EOF
2146                 cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2147                 AC_TRY_EVAL(cf_try)
2148                 if test -f conftest.out ; then
2149                         cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]][[    ]]*//"`
2150                         eval NCURSES_$cf_name=\"$cf_result\"
2151                         # cat conftest.$ac_ext
2152                         # cat conftest.out
2153                 fi
2154         done
2155
2156         cf_cv_abi_version=${NCURSES_MAJOR}
2157
2158 fi
2159
2160 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2161
2162 dnl Show the computed version, for logging
2163 cf_cv_timestamp=`date`
2164
2165 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2166
2167 dnl We need these values in the generated headers
2168 AC_SUBST(NCURSES_MAJOR)
2169 AC_SUBST(NCURSES_MINOR)
2170 AC_SUBST(NCURSES_PATCH)
2171
2172 dnl We need these values in the generated makefiles
2173 AC_SUBST(cf_cv_rel_version)
2174 AC_SUBST(cf_cv_abi_version)
2175
2176 dnl FIXME - not needed for Ada95
2177 AC_SUBST(cf_cv_builtin_bool)
2178 AC_SUBST(cf_cv_header_stdbool_h)
2179 AC_SUBST(cf_cv_type_of_bool)dnl
2180
2181 ])
2182 dnl ---------------------------------------------------------------------------
2183 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2184 dnl -------------------
2185 dnl Check if we can compile with ncurses' header file
2186 dnl $1 is the cache variable to set
2187 dnl $2 is the header-file to include
2188 dnl $3 is the root name (ncurses or ncursesw)
2189 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2190         AC_TRY_COMPILE([
2191 ]ifelse($3,ncursesw,[
2192 #define _XOPEN_SOURCE_EXTENDED
2193 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2194 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2195 ])[
2196 #include <$2>],[
2197 #ifdef NCURSES_VERSION
2198 ]ifelse($3,ncursesw,[
2199 #ifndef WACS_BSSB
2200         make an error
2201 #endif
2202 ])[
2203 printf("%s\n", NCURSES_VERSION);
2204 #else
2205 #ifdef __NCURSES_H
2206 printf("old\n");
2207 #else
2208         make an error
2209 #endif
2210 #endif
2211         ]
2212         ,[$1=$2]
2213         ,[$1=no])
2214 ])dnl
2215 dnl ---------------------------------------------------------------------------
2216 dnl CF_NCURSES_CONFIG version: 17 updated: 2015/07/07 04:22:07
2217 dnl -----------------
2218 dnl Tie together the configure-script macros for ncurses, preferring these in
2219 dnl order:
2220 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2221 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2222 dnl c) just plain libraries
2223 dnl
2224 dnl $1 is the root library name (default: "ncurses")
2225 AC_DEFUN([CF_NCURSES_CONFIG],[
2226 AC_REQUIRE([CF_PKG_CONFIG])
2227 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2228 cf_have_ncuconfig=no
2229
2230 if test "x${PKG_CONFIG:=none}" != xnone; then
2231         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2232         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2233                 AC_MSG_RESULT(yes)
2234
2235                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2236                 cf_have_ncuconfig=unknown
2237
2238                 cf_save_CPPFLAGS="$CPPFLAGS"
2239                 cf_save_LIBS="$LIBS"
2240
2241                 CPPFLAGS="$CPPFLAGS `$PKG_CONFIG --cflags $cf_ncuconfig_root`"
2242                 CF_ADD_LIBS(`$PKG_CONFIG --libs $cf_ncuconfig_root`)
2243
2244                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2245                         [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2246                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2247                                 int main(void)
2248                                 { char *xx = curses_version(); return (xx == 0); }],
2249                                 [cf_have_ncuconfig=yes],
2250                                 [cf_have_ncuconfig=no],
2251                                 [cf_have_ncuconfig=maybe])],
2252                         [cf_have_ncuconfig=no])
2253                 AC_MSG_RESULT($cf_have_ncuconfig)
2254                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2255                 if test "$cf_have_ncuconfig" != "yes"
2256                 then
2257                         CPPFLAGS="$cf_save_CPPFLAGS"
2258                         LIBS="$cf_save_LIBS"
2259                         NCURSES_CONFIG_PKG=none
2260                 else
2261                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2262                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2263                 fi
2264
2265         else
2266                 AC_MSG_RESULT(no)
2267                 NCURSES_CONFIG_PKG=none
2268         fi
2269 else
2270         NCURSES_CONFIG_PKG=none
2271 fi
2272
2273 if test "x$cf_have_ncuconfig" = "xno"; then
2274         echo "Looking for ${cf_ncuconfig_root}-config"
2275
2276         CF_ACVERSION_CHECK(2.52,
2277                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncuconfig_root}-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2278                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncuconfig_root}-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2279
2280         if test "$NCURSES_CONFIG" != none ; then
2281
2282                 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
2283                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2284
2285                 # even with config script, some packages use no-override for curses.h
2286                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2287
2288                 dnl like CF_NCURSES_CPPFLAGS
2289                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2290
2291                 dnl like CF_NCURSES_LIBS
2292                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2293                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2294
2295                 dnl like CF_NCURSES_VERSION
2296                 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2297
2298         else
2299
2300                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2301                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2302
2303         fi
2304 else
2305         NCURSES_CONFIG=none
2306 fi
2307 ])dnl
2308 dnl ---------------------------------------------------------------------------
2309 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2310 dnl -------------------
2311 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2312 dnl the CPPFLAGS variable so we can include its header.
2313 dnl
2314 dnl The header files may be installed as either curses.h, or ncurses.h (would
2315 dnl be obsolete, except that some packagers prefer this name to distinguish it
2316 dnl from a "native" curses implementation).  If not installed for overwrite,
2317 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2318 dnl /usr/include/ncurses), but someone may have installed overwriting the
2319 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2320 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2321 dnl the header.
2322 dnl
2323 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2324 dnl is already in the include-path, don't even bother with this, since we cannot
2325 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2326 dnl
2327 dnl The optional parameter gives the root name of the library, in case it is
2328 dnl not installed as the default curses library.  That is how the
2329 dnl wide-character version of ncurses is installed.
2330 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2331 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2332
2333 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2334 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2335
2336 test -n "$cf_cv_curses_dir" && \
2337 test "$cf_cv_curses_dir" != "no" && { \
2338   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2339 }
2340
2341 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2342         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2343         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2344         for cf_header in $cf_header_list
2345         do
2346                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2347                 test "$cf_cv_ncurses_h" != no && break
2348         done
2349 ])
2350
2351 CF_NCURSES_HEADER
2352 CF_TERM_HEADER
2353
2354 # some applications need this, but should check for NCURSES_VERSION
2355 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2356
2357 CF_NCURSES_VERSION
2358 ])dnl
2359 dnl ---------------------------------------------------------------------------
2360 dnl CF_NCURSES_HEADER version: 4 updated: 2015/04/15 19:08:48
2361 dnl -----------------
2362 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2363 dnl variations of ncurses' installs.
2364 dnl
2365 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2366 AC_DEFUN([CF_NCURSES_HEADER],[
2367
2368 if test "$cf_cv_ncurses_h" != no ; then
2369         cf_cv_ncurses_header=$cf_cv_ncurses_h
2370 else
2371
2372 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2373         test -n "$verbose" && echo
2374         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2375         test -n "$verbose" && echo search path $cf_search
2376         cf_save2_CPPFLAGS="$CPPFLAGS"
2377         for cf_incdir in $cf_search
2378         do
2379                 CF_ADD_INCDIR($cf_incdir)
2380                 for cf_header in \
2381                         ncurses.h \
2382                         curses.h
2383                 do
2384                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2385                         if test "$cf_cv_ncurses_h2" != no ; then
2386                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2387                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2388                                 break
2389                         fi
2390                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2391                 done
2392                 CPPFLAGS="$cf_save2_CPPFLAGS"
2393                 test "$cf_cv_ncurses_h2" != no && break
2394         done
2395         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2396         ])
2397
2398         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2399         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2400         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2401                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2402         fi
2403         CF_ADD_INCDIR($cf_1st_incdir)
2404
2405 fi
2406
2407 # Set definitions to allow ifdef'ing for ncurses.h
2408
2409 case $cf_cv_ncurses_header in
2410 (*ncurses.h)
2411         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2412         ;;
2413 esac
2414
2415 case $cf_cv_ncurses_header in
2416 (ncurses/curses.h|ncurses/ncurses.h)
2417         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2418         ;;
2419 (ncursesw/curses.h|ncursesw/ncurses.h)
2420         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2421         ;;
2422 esac
2423
2424 ])dnl
2425 dnl ---------------------------------------------------------------------------
2426 dnl CF_NCURSES_LIBS version: 17 updated: 2015/04/15 19:08:48
2427 dnl ---------------
2428 dnl Look for the ncurses library.  This is a little complicated on Linux,
2429 dnl because it may be linked with the gpm (general purpose mouse) library.
2430 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2431 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2432 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2433 dnl and the linker will record a dependency.
2434 dnl
2435 dnl The optional parameter gives the root name of the library, in case it is
2436 dnl not installed as the default curses library.  That is how the
2437 dnl wide-character version of ncurses is installed.
2438 AC_DEFUN([CF_NCURSES_LIBS],
2439 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2440
2441 cf_nculib_root=ifelse($1,,ncurses,$1)
2442         # This works, except for the special case where we find gpm, but
2443         # ncurses is in a nonstandard location via $LIBS, and we really want
2444         # to link gpm.
2445 cf_ncurses_LIBS=""
2446 cf_ncurses_SAVE="$LIBS"
2447 AC_CHECK_LIB(gpm,Gpm_Open,
2448         [AC_CHECK_LIB(gpm,initscr,
2449                 [LIBS="$cf_ncurses_SAVE"],
2450                 [cf_ncurses_LIBS="-lgpm"])])
2451
2452 case $host_os in
2453 (freebsd*)
2454         # This is only necessary if you are linking against an obsolete
2455         # version of ncurses (but it should do no harm, since it's static).
2456         if test "$cf_nculib_root" = ncurses ; then
2457                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2458         fi
2459         ;;
2460 esac
2461
2462 CF_ADD_LIBS($cf_ncurses_LIBS)
2463
2464 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2465 then
2466         CF_ADD_LIBS(-l$cf_nculib_root)
2467 else
2468         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2469                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2470                 [initscr()],
2471                 initscr)
2472 fi
2473
2474 if test -n "$cf_ncurses_LIBS" ; then
2475         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2476         cf_ncurses_SAVE="$LIBS"
2477         for p in $cf_ncurses_LIBS ; do
2478                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2479                 if test "$q" != "$LIBS" ; then
2480                         LIBS="$q"
2481                 fi
2482         done
2483         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2484                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2485                 [AC_MSG_RESULT(yes)],
2486                 [AC_MSG_RESULT(no)
2487                  LIBS="$cf_ncurses_SAVE"])
2488 fi
2489
2490 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2491 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2492 ])dnl
2493 dnl ---------------------------------------------------------------------------
2494 dnl CF_NCURSES_VERSION version: 14 updated: 2012/10/06 08:57:51
2495 dnl ------------------
2496 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2497 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2498 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2499 AC_DEFUN([CF_NCURSES_VERSION],
2500 [
2501 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2502 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2503         cf_cv_ncurses_version=no
2504         cf_tempfile=out$$
2505         rm -f $cf_tempfile
2506         AC_TRY_RUN([
2507 #include <${cf_cv_ncurses_header:-curses.h}>
2508 #include <stdio.h>
2509 int main()
2510 {
2511         FILE *fp = fopen("$cf_tempfile", "w");
2512 #ifdef NCURSES_VERSION
2513 # ifdef NCURSES_VERSION_PATCH
2514         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2515 # else
2516         fprintf(fp, "%s\n", NCURSES_VERSION);
2517 # endif
2518 #else
2519 # ifdef __NCURSES_H
2520         fprintf(fp, "old\n");
2521 # else
2522         make an error
2523 # endif
2524 #endif
2525         ${cf_cv_main_return:-return}(0);
2526 }],[
2527         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2528
2529         # This will not work if the preprocessor splits the line after the
2530         # Autoconf token.  The 'unproto' program does that.
2531         cat > conftest.$ac_ext <<EOF
2532 #include <${cf_cv_ncurses_header:-curses.h}>
2533 #undef Autoconf
2534 #ifdef NCURSES_VERSION
2535 Autoconf NCURSES_VERSION
2536 #else
2537 #ifdef __NCURSES_H
2538 Autoconf "old"
2539 #endif
2540 ;
2541 #endif
2542 EOF
2543         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2544         AC_TRY_EVAL(cf_try)
2545         if test -f conftest.out ; then
2546                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2547                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2548                 rm -f conftest.out
2549         fi
2550 ])
2551         rm -f $cf_tempfile
2552 ])
2553 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2554 ])dnl
2555 dnl ---------------------------------------------------------------------------
2556 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
2557 dnl -------------
2558 dnl Compute the object-directory name from the given model name
2559 AC_DEFUN([CF_OBJ_SUBDIR],
2560 [
2561         case $1 in
2562         (libtool) $2='obj_lo'  ;;
2563         (normal)  $2='objects' ;;
2564         (debug)   $2='obj_g' ;;
2565         (profile) $2='obj_p' ;;
2566         (shared)
2567                 case $cf_cv_system_name in
2568                 (cygwin|msys)
2569                         $2='objects' ;;
2570                 (*)
2571                         $2='obj_s' ;;
2572                 esac
2573         esac
2574 ])dnl
2575 dnl ---------------------------------------------------------------------------
2576 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
2577 dnl ----------
2578 dnl Provide a value for the $PATH and similar separator (or amend the value
2579 dnl as provided in autoconf 2.5x).
2580 AC_DEFUN([CF_PATHSEP],
2581 [
2582         AC_MSG_CHECKING(for PATH separator)
2583         case $cf_cv_system_name in
2584         (os2*)  PATH_SEPARATOR=';'  ;;
2585         (*)     ${PATH_SEPARATOR:=':'}  ;;
2586         esac
2587 ifelse([$1],,,[$1=$PATH_SEPARATOR])
2588         AC_SUBST(PATH_SEPARATOR)
2589         AC_MSG_RESULT($PATH_SEPARATOR)
2590 ])dnl
2591 dnl ---------------------------------------------------------------------------
2592 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
2593 dnl --------------
2594 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2595 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2596 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2597 dnl delayed evaluation of those symbols.
2598 AC_DEFUN([CF_PATH_SYNTAX],[
2599 if test "x$prefix" != xNONE; then
2600         cf_path_syntax="$prefix"
2601 else
2602         cf_path_syntax="$ac_default_prefix"
2603 fi
2604
2605 case ".[$]$1" in
2606 (.\[$]\(*\)*|.\'*\'*)
2607         ;;
2608 (..|./*|.\\*)
2609         ;;
2610 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
2611         ;;
2612 (.\[$]{*prefix}*|.\[$]{*dir}*)
2613         eval $1="[$]$1"
2614         case ".[$]$1" in
2615         (.NONE/*)
2616                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2617                 ;;
2618         esac
2619         ;;
2620 (.no|.NONE/*)
2621         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2622         ;;
2623 (*)
2624         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2625         ;;
2626 esac
2627 ])dnl
2628 dnl ---------------------------------------------------------------------------
2629 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
2630 dnl -------------
2631 dnl Check for the package-config program, unless disabled by command-line.
2632 AC_DEFUN([CF_PKG_CONFIG],
2633 [
2634 AC_MSG_CHECKING(if you want to use pkg-config)
2635 AC_ARG_WITH(pkg-config,
2636         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2637         [cf_pkg_config=$withval],
2638         [cf_pkg_config=yes])
2639 AC_MSG_RESULT($cf_pkg_config)
2640
2641 case $cf_pkg_config in
2642 (no)
2643         PKG_CONFIG=none
2644         ;;
2645 (yes)
2646         CF_ACVERSION_CHECK(2.52,
2647                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2648                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2649         ;;
2650 (*)
2651         PKG_CONFIG=$withval
2652         ;;
2653 esac
2654
2655 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2656 if test "$PKG_CONFIG" != none ; then
2657         CF_PATH_SYNTAX(PKG_CONFIG)
2658 elif test "x$cf_pkg_config" != xno ; then
2659         AC_MSG_WARN(pkg-config is not installed)
2660 fi
2661
2662 AC_SUBST(PKG_CONFIG)
2663 ])dnl
2664 dnl ---------------------------------------------------------------------------
2665 dnl CF_POSIX_C_SOURCE version: 9 updated: 2015/04/12 15:39:00
2666 dnl -----------------
2667 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2668 dnl
2669 dnl     POSIX.1-1990                            _POSIX_SOURCE
2670 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2671 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2672 dnl             Bindings Option
2673 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2674 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2675 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2676 dnl
2677 dnl Parameters:
2678 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2679 AC_DEFUN([CF_POSIX_C_SOURCE],
2680 [
2681 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2682
2683 cf_save_CFLAGS="$CFLAGS"
2684 cf_save_CPPFLAGS="$CPPFLAGS"
2685
2686 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2687 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2688
2689 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2690         CF_MSG_LOG(if the symbol is already defined go no further)
2691         AC_TRY_COMPILE([#include <sys/types.h>],[
2692 #ifndef _POSIX_C_SOURCE
2693 make an error
2694 #endif],
2695         [cf_cv_posix_c_source=no],
2696         [cf_want_posix_source=no
2697          case .$cf_POSIX_C_SOURCE in
2698          (.[[12]]??*)
2699                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2700                 ;;
2701          (.2)
2702                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2703                 cf_want_posix_source=yes
2704                 ;;
2705          (.*)
2706                 cf_want_posix_source=yes
2707                 ;;
2708          esac
2709          if test "$cf_want_posix_source" = yes ; then
2710                 AC_TRY_COMPILE([#include <sys/types.h>],[
2711 #ifdef _POSIX_SOURCE
2712 make an error
2713 #endif],[],
2714                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2715          fi
2716          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2717          CFLAGS="$cf_trim_CFLAGS"
2718          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2719          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2720          AC_TRY_COMPILE([#include <sys/types.h>],[
2721 #ifndef _POSIX_C_SOURCE
2722 make an error
2723 #endif],,
2724          [cf_cv_posix_c_source=no])
2725          CFLAGS="$cf_save_CFLAGS"
2726          CPPFLAGS="$cf_save_CPPFLAGS"
2727         ])
2728 ])
2729
2730 if test "$cf_cv_posix_c_source" != no ; then
2731         CFLAGS="$cf_trim_CFLAGS"
2732         CPPFLAGS="$cf_trim_CPPFLAGS"
2733         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2734 fi
2735
2736 ])dnl
2737 dnl ---------------------------------------------------------------------------
2738 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
2739 dnl ----------
2740 dnl Check for archiver "ar".
2741 AC_DEFUN([CF_PROG_AR],[
2742 AC_CHECK_TOOL(AR, ar, ar)
2743 ])
2744 dnl ---------------------------------------------------------------------------
2745 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
2746 dnl -----------
2747 dnl Check for awk, ensure that the check found something.
2748 AC_DEFUN([CF_PROG_AWK],
2749 [
2750 AC_PROG_AWK
2751 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
2752 ])dnl
2753 dnl ---------------------------------------------------------------------------
2754 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
2755 dnl ----------
2756 dnl standard check for CC, plus followup sanity checks
2757 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
2758 AC_DEFUN([CF_PROG_CC],[
2759 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
2760 CF_GCC_VERSION
2761 CF_ACVERSION_CHECK(2.52,
2762         [AC_PROG_CC_STDC],
2763         [CF_ANSI_CC_REQD])
2764 CF_CC_ENV_FLAGS
2765 ])dnl
2766 dnl ---------------------------------------------------------------------------
2767 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
2768 dnl --------------
2769 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
2770 dnl the output file can be renamed, and allows for a shell variable that can
2771 dnl be used later.  The parameter is either CC or CXX.  The result is the
2772 dnl cache variable:
2773 dnl     $cf_cv_prog_CC_c_o
2774 dnl     $cf_cv_prog_CXX_c_o
2775 AC_DEFUN([CF_PROG_CC_C_O],
2776 [AC_REQUIRE([AC_PROG_CC])dnl
2777 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
2778 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
2779 [
2780 cat > conftest.$ac_ext <<CF_EOF
2781 #include <stdio.h>
2782 int main()
2783 {
2784         ${cf_cv_main_return:-return}(0);
2785 }
2786 CF_EOF
2787 # We do the test twice because some compilers refuse to overwrite an
2788 # existing .o file with -o, though they will create one.
2789 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
2790 if AC_TRY_EVAL(ac_try) &&
2791   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
2792 then
2793   eval cf_cv_prog_$1_c_o=yes
2794 else
2795   eval cf_cv_prog_$1_c_o=no
2796 fi
2797 rm -rf conftest*
2798 ])dnl
2799 if test $cf_cv_prog_$1_c_o = yes; then
2800   AC_MSG_RESULT([yes])
2801 else
2802   AC_MSG_RESULT([no])
2803 fi
2804 ])dnl
2805 dnl ---------------------------------------------------------------------------
2806 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
2807 dnl -------------
2808 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
2809 dnl This macro adds a check to ensure the script found something.
2810 AC_DEFUN([CF_PROG_EGREP],
2811 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
2812         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
2813                 then ac_cv_prog_egrep='grep -E'
2814                 else ac_cv_prog_egrep='egrep'
2815         fi])
2816         EGREP=$ac_cv_prog_egrep
2817         AC_SUBST([EGREP])
2818         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
2819 ])dnl
2820 dnl ---------------------------------------------------------------------------
2821 dnl CF_PROG_EXT version: 13 updated: 2015/04/18 09:03:58
2822 dnl -----------
2823 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
2824 AC_DEFUN([CF_PROG_EXT],
2825 [
2826 AC_REQUIRE([CF_CHECK_CACHE])
2827 case $cf_cv_system_name in
2828 (os2*)
2829         CFLAGS="$CFLAGS -Zmt"
2830         CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
2831         CXXFLAGS="$CXXFLAGS -Zmt"
2832         # autoconf's macro sets -Zexe and suffix both, which conflict:w
2833         LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
2834         ac_cv_exeext=.exe
2835         ;;
2836 esac
2837
2838 AC_EXEEXT
2839 AC_OBJEXT
2840
2841 PROG_EXT="$EXEEXT"
2842 AC_SUBST(PROG_EXT)
2843 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
2844 ])dnl
2845 dnl ---------------------------------------------------------------------------
2846 dnl CF_PROG_GNAT version: 3 updated: 2015/04/18 08:56:57
2847 dnl ------------
2848 dnl Check for gnatmake, ensure that it is complete.
2849 AC_DEFUN([CF_PROG_GNAT],[
2850 cf_ada_make=gnatmake
2851 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
2852 if test "$ac_cv_prog_gnat_exists" = no; then
2853         cf_ada_make=
2854         cf_cv_prog_gnat_correct=no
2855 else
2856         CF_GNAT_VERSION
2857         AC_CHECK_PROG(M4_exists, m4, yes, no)
2858         if test "$ac_cv_prog_M4_exists" = no; then
2859                 cf_cv_prog_gnat_correct=no
2860                 echo Ada95 binding required program m4 not found. Ada95 binding disabled.
2861         fi
2862         if test "$cf_cv_prog_gnat_correct" = yes; then
2863                 AC_MSG_CHECKING(if GNAT works)
2864                 CF_GNAT_TRY_RUN([procedure conftest;],
2865 [with Text_IO;
2866 with GNAT.OS_Lib;
2867 procedure conftest is
2868 begin
2869    Text_IO.Put ("Hello World");
2870    Text_IO.New_Line;
2871    GNAT.OS_Lib.OS_Exit (0);
2872 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
2873                 AC_MSG_RESULT($cf_cv_prog_gnat_correct)
2874         fi
2875 fi
2876
2877 AC_SUBST(cf_ada_make)
2878 ])dnl
2879 dnl ---------------------------------------------------------------------------
2880 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
2881 dnl ------------
2882 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
2883 dnl option if it is supported.
2884 AC_DEFUN([CF_PROG_LN_S],[
2885 AC_PROG_LN_S
2886 AC_MSG_CHECKING(if $LN_S -f options work)
2887
2888 rm -f conf$$.src conf$$dst
2889 echo >conf$$.dst
2890 echo first >conf$$.src
2891 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
2892         cf_prog_ln_sf=yes
2893 else
2894         cf_prog_ln_sf=no
2895 fi
2896 rm -f conf$$.dst conf$$src
2897 AC_MSG_RESULT($cf_prog_ln_sf)
2898
2899 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
2900 ])dnl
2901 dnl ---------------------------------------------------------------------------
2902 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2903 dnl ----------------
2904 dnl Remove all -U and -D options that refer to the given symbol from a list
2905 dnl of C compiler options.  This works around the problem that not all
2906 dnl compilers process -U and -D options from left-to-right, so a -U option
2907 dnl cannot be used to cancel the effect of a preceding -D option.
2908 dnl
2909 dnl $1 = target (which could be the same as the source variable)
2910 dnl $2 = source (including '$')
2911 dnl $3 = symbol to remove
2912 define([CF_REMOVE_DEFINE],
2913 [
2914 $1=`echo "$2" | \
2915         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2916                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2917 ])dnl
2918 dnl ---------------------------------------------------------------------------
2919 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
2920 dnl -------------
2921 dnl Remove the given library from the symbol
2922 dnl
2923 dnl $1 = target (which could be the same as the source variable)
2924 dnl $2 = source (including '$')
2925 dnl $3 = library to remove
2926 define([CF_REMOVE_LIB],
2927 [
2928 # remove $3 library from $2
2929 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
2930 ])dnl
2931 dnl ---------------------------------------------------------------------------
2932 dnl CF_SHARED_OPTS version: 89 updated: 2015/08/15 18:38:59
2933 dnl --------------
2934 dnl --------------
2935 dnl Attempt to determine the appropriate CC/LD options for creating a shared
2936 dnl library.
2937 dnl
2938 dnl Notes:
2939 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
2940 dnl the build-tree, i.e., by making use of the libraries that are compiled in
2941 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
2942 dnl shared library since that can lead to unexpected results at runtime.
2943 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
2944 dnl libraries are compiled in ../../lib
2945 dnl
2946 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
2947 dnl to install symbolic links to the rel/abi versions of shared libraries.
2948 dnl
2949 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
2950 dnl version when making symbolic links.
2951 dnl
2952 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
2953 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
2954 dnl (ex: libncurses.so.<ver>).
2955 dnl
2956 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
2957 AC_DEFUN([CF_SHARED_OPTS],
2958 [
2959         AC_REQUIRE([CF_LD_RPATH_OPT])
2960         RM_SHARED_OPTS=
2961         LOCAL_LDFLAGS=
2962         LOCAL_LDFLAGS2=
2963         LD_SHARED_OPTS=
2964         INSTALL_LIB="-m 644"
2965         : ${rel_builddir:=.}
2966
2967         shlibdir=$libdir
2968         AC_SUBST(shlibdir)
2969
2970         MAKE_DLLS="#"
2971         AC_SUBST(MAKE_DLLS)
2972
2973         cf_cv_do_symlinks=no
2974         cf_ld_rpath_opt=
2975         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
2976
2977         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
2978         AC_ARG_WITH(shlib-version,
2979         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
2980         [test -z "$withval" && withval=auto
2981         case $withval in
2982         (yes)
2983                 cf_cv_shlib_version=auto
2984                 ;;
2985         (rel|abi|auto)
2986                 cf_cv_shlib_version=$withval
2987                 ;;
2988         (*)
2989                 AC_MSG_RESULT($withval)
2990                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
2991                 ;;
2992         esac
2993         ],[cf_cv_shlib_version=auto])
2994         AC_MSG_RESULT($cf_cv_shlib_version)
2995
2996         cf_cv_rm_so_locs=no
2997         cf_try_cflags=
2998
2999         # Some less-capable ports of gcc support only -fpic
3000         CC_SHARED_OPTS=
3001         if test "$GCC" = yes
3002         then
3003                 AC_MSG_CHECKING(which $CC option to use)
3004                 cf_save_CFLAGS="$CFLAGS"
3005                 for CC_SHARED_OPTS in -fPIC -fpic ''
3006                 do
3007                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
3008                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
3009                 done
3010                 AC_MSG_RESULT($CC_SHARED_OPTS)
3011                 CFLAGS="$cf_save_CFLAGS"
3012         fi
3013
3014         cf_cv_shlib_version_infix=no
3015
3016         case $cf_cv_system_name in
3017         (aix4.[3-9]*|aix[[5-7]]*)
3018                 if test "$GCC" = yes; then
3019                         CC_SHARED_OPTS='-Wl,-brtl'
3020                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3021                 else
3022                         CC_SHARED_OPTS='-brtl'
3023                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
3024                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3025                 fi
3026                 ;;
3027         (beos*)
3028                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
3029                 ;;
3030         (cygwin*)
3031                 CC_SHARED_OPTS=
3032                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3033                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3034                 cf_cv_shlib_version=cygdll
3035                 cf_cv_shlib_version_infix=cygdll
3036                 shlibdir=$bindir
3037                 MAKE_DLLS=
3038                 cat >mk_shared_lib.sh <<-CF_EOF
3039                 #!$SHELL
3040                 SHARED_LIB=\[$]1
3041                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3042                 shift
3043                 cat <<-EOF
3044                 Linking shared library
3045                 ** SHARED_LIB \[$]SHARED_LIB
3046                 ** IMPORT_LIB \[$]IMPORT_LIB
3047 EOF
3048                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3049 CF_EOF
3050                 chmod +x mk_shared_lib.sh
3051                 ;;
3052         (msys*)
3053                 CC_SHARED_OPTS=
3054                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3055                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3056                 cf_cv_shlib_version=msysdll
3057                 cf_cv_shlib_version_infix=msysdll
3058                 shlibdir=$bindir
3059                 MAKE_DLLS=
3060                 cat >mk_shared_lib.sh <<-CF_EOF
3061                 #!$SHELL
3062                 SHARED_LIB=\[$]1
3063                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3064                 shift
3065                 cat <<-EOF
3066                 Linking shared library
3067                 ** SHARED_LIB \[$]SHARED_LIB
3068                 ** IMPORT_LIB \[$]IMPORT_LIB
3069 EOF
3070                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3071 CF_EOF
3072                 chmod +x mk_shared_lib.sh
3073                 ;;
3074         (darwin*)
3075                 cf_try_cflags="no-cpp-precomp"
3076                 CC_SHARED_OPTS="-dynamic"
3077                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
3078                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
3079                 cf_cv_shlib_version_infix=yes
3080                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
3081                         cf_save_LDFLAGS=$LDFLAGS
3082                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3083                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
3084                                 LDFLAGS=$cf_save_LDFLAGS])
3085                 if test $cf_cv_ldflags_search_paths_first = yes; then
3086                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3087                 fi
3088                 ;;
3089         (hpux[[7-8]]*)
3090                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
3091                 if test "$GCC" != yes; then
3092                         CC_SHARED_OPTS='+Z'
3093                 fi
3094                 MK_SHARED_LIB='${LD} -b -o $[@]'
3095                 INSTALL_LIB="-m 555"
3096                 ;;
3097         (hpux*)
3098                 # (tested with gcc 2.7.2 -- I don't have c89)
3099                 if test "$GCC" = yes; then
3100                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
3101                 else
3102                         CC_SHARED_OPTS='+Z'
3103                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
3104                 fi
3105                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
3106                 # HP-UX shared libraries must be executable, and should be
3107                 # readonly to exploit a quirk in the memory manager.
3108                 INSTALL_LIB="-m 555"
3109                 ;;
3110         (interix*)
3111                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3112                 if test "$cf_cv_shlib_version" = rel; then
3113                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
3114                 else
3115                         cf_shared_soname='`basename $@`'
3116                 fi
3117                 CC_SHARED_OPTS=
3118                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
3119                 ;;
3120         (irix*)
3121                 if test "$cf_cv_enable_rpath" = yes ; then
3122                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3123                 fi
3124                 # tested with IRIX 5.2 and 'cc'.
3125                 if test "$GCC" != yes; then
3126                         CC_SHARED_OPTS='-KPIC'
3127                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
3128                 else
3129                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
3130                 fi
3131                 cf_cv_rm_so_locs=yes
3132                 ;;
3133         (linux*|gnu*|k*bsd*-gnu)
3134                 if test "$DFT_LWR_MODEL" = "shared" ; then
3135                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3136                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3137                 fi
3138                 if test "$cf_cv_enable_rpath" = yes ; then
3139                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3140                 fi
3141                 CF_SHARED_SONAME
3142                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3143                 ;;
3144         (mingw*)
3145                 cf_cv_shlib_version=mingw
3146                 cf_cv_shlib_version_infix=mingw
3147                 shlibdir=$bindir
3148                 MAKE_DLLS=
3149                 if test "$DFT_LWR_MODEL" = "shared" ; then
3150                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
3151                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3152                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
3153                 fi
3154                 CC_SHARED_OPTS=
3155                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3156                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3157                 cat >mk_shared_lib.sh <<-CF_EOF
3158                 #!$SHELL
3159                 SHARED_LIB=\[$]1
3160                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3161                 shift
3162                 cat <<-EOF
3163                 Linking shared library
3164                 ** SHARED_LIB \[$]SHARED_LIB
3165                 ** IMPORT_LIB \[$]IMPORT_LIB
3166 EOF
3167                 exec \[$]* -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3168 CF_EOF
3169                 chmod +x mk_shared_lib.sh
3170                 ;;
3171         (openbsd[[2-9]].*|mirbsd*)
3172                 if test "$DFT_LWR_MODEL" = "shared" ; then
3173                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3174                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3175                 fi
3176                 if test "$cf_cv_enable_rpath" = yes ; then
3177                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3178                 fi
3179                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3180                 CF_SHARED_SONAME
3181                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3182                 ;;
3183         (nto-qnx*|openbsd*|freebsd[[12]].*)
3184                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3185                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
3186                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3187                 ;;
3188         (dragonfly*|freebsd*)
3189                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3190                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3191                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3192                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
3193                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3194                 fi
3195                 CF_SHARED_SONAME
3196                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3197                 ;;
3198         (netbsd*)
3199                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3200                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3201                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3202                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3203                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3204                         if test "$cf_cv_shlib_version" = auto; then
3205                         if test -f /usr/libexec/ld.elf_so; then
3206                                 cf_cv_shlib_version=abi
3207                         else
3208                                 cf_cv_shlib_version=rel
3209                         fi
3210                         fi
3211                         CF_SHARED_SONAME
3212                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
3213                 else
3214                         MK_SHARED_LIB='${CC} -Wl,-shared -Wl,-Bshareable -o $[@]'
3215                 fi
3216                 ;;
3217         (osf*|mls+*)
3218                 # tested with OSF/1 V3.2 and 'cc'
3219                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
3220                 # link with shared libs).
3221                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
3222                 case $host_os in
3223                 (osf4*)
3224                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
3225                         ;;
3226                 esac
3227                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
3228                 if test "$DFT_LWR_MODEL" = "shared" ; then
3229                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3230                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3231                 fi
3232                 cf_cv_rm_so_locs=yes
3233                 ;;
3234         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
3235                 # tested with osr5.0.5
3236                 if test "$GCC" != yes; then
3237                         CC_SHARED_OPTS='-belf -KPIC'
3238                 fi
3239                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
3240                 if test "$cf_cv_enable_rpath" = yes ; then
3241                         # only way is to set LD_RUN_PATH but no switch for it
3242                         RUN_PATH=$libdir
3243                 fi
3244                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3245                 LINK_PROGS='LD_RUN_PATH=${libdir}'
3246                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
3247                 ;;
3248         (sunos4*)
3249                 # tested with SunOS 4.1.1 and gcc 2.7.0
3250                 if test "$GCC" != yes; then
3251                         CC_SHARED_OPTS='-KPIC'
3252                 fi
3253                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
3254                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3255                 ;;
3256         (solaris2*)
3257                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
3258                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
3259                 if test "$DFT_LWR_MODEL" = "shared" ; then
3260                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
3261                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3262                 fi
3263                 if test "$cf_cv_enable_rpath" = yes ; then
3264                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
3265                 fi
3266                 CF_SHARED_SONAME
3267                 if test "$GCC" != yes; then
3268                         cf_save_CFLAGS="$CFLAGS"
3269                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
3270                         do
3271                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
3272                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
3273                         done
3274                         CFLAGS="$cf_save_CFLAGS"
3275                         CC_SHARED_OPTS=$cf_shared_opts
3276                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3277                 else
3278                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3279                 fi
3280                 ;;
3281         (sysv5uw7*|unix_sv*)
3282                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
3283                 if test "$GCC" != yes; then
3284                         CC_SHARED_OPTS='-KPIC'
3285                 fi
3286                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
3287                 ;;
3288         (*)
3289                 CC_SHARED_OPTS='unknown'
3290                 MK_SHARED_LIB='echo unknown'
3291                 ;;
3292         esac
3293
3294         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
3295         case "$cf_cv_shlib_version" in
3296         (rel|abi)
3297                 case "$MK_SHARED_LIB" in
3298                 (*'-o $[@]')
3299                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
3300                         ;;
3301                 (*)
3302                         AC_MSG_WARN(ignored --with-shlib-version)
3303                         ;;
3304                 esac
3305                 ;;
3306         esac
3307
3308         if test -n "$cf_try_cflags"
3309         then
3310 cat > conftest.$ac_ext <<EOF
3311 #line __oline__ "${as_me:-configure}"
3312 #include <stdio.h>
3313 int main(int argc, char *argv[[]])
3314 {
3315         printf("hello\n");
3316         return (argv[[argc-1]] == 0) ;
3317 }
3318 EOF
3319                 cf_save_CFLAGS="$CFLAGS"
3320                 for cf_opt in $cf_try_cflags
3321                 do
3322                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
3323                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
3324                         if AC_TRY_EVAL(ac_compile); then
3325                                 AC_MSG_RESULT(yes)
3326                                 cf_save_CFLAGS="$CFLAGS"
3327                         else
3328                                 AC_MSG_RESULT(no)
3329                         fi
3330                 done
3331                 CFLAGS="$cf_save_CFLAGS"
3332         fi
3333
3334
3335         # RPATH_LIST is a colon-separated list of directories
3336         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
3337         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
3338
3339         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
3340
3341         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
3342         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
3343
3344         AC_SUBST(CC_SHARED_OPTS)
3345         AC_SUBST(LD_RPATH_OPT)
3346         AC_SUBST(LD_SHARED_OPTS)
3347         AC_SUBST(MK_SHARED_LIB)
3348         AC_SUBST(RM_SHARED_OPTS)
3349
3350         AC_SUBST(LINK_PROGS)
3351         AC_SUBST(LINK_TESTS)
3352
3353         AC_SUBST(EXTRA_LDFLAGS)
3354         AC_SUBST(LOCAL_LDFLAGS)
3355         AC_SUBST(LOCAL_LDFLAGS2)
3356
3357         AC_SUBST(INSTALL_LIB)
3358         AC_SUBST(RPATH_LIST)
3359 ])dnl
3360 dnl ---------------------------------------------------------------------------
3361 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
3362 dnl ----------------
3363 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
3364 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
3365 dnl option.
3366 dnl
3367 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
3368 dnl If missing, use "rel".
3369 define([CF_SHARED_SONAME],
3370 [
3371         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
3372         if test "$cf_cv_shlib_version" = rel; then
3373                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3374         else
3375                 cf_cv_shared_soname='`basename $[@]`'
3376         fi
3377 ])
3378 dnl ---------------------------------------------------------------------------
3379 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
3380 dnl --------------
3381 dnl     Remove "-g" option from the compiler options
3382 AC_DEFUN([CF_STRIP_G_OPT],
3383 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
3384 dnl ---------------------------------------------------------------------------
3385 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
3386 dnl --------------
3387 dnl Construct a search-list for a nonstandard header/lib-file
3388 dnl     $1 = the variable to return as result
3389 dnl     $2 = the package name
3390 dnl     $3 = the subdirectory, e.g., bin, include or lib
3391 AC_DEFUN([CF_SUBDIR_PATH],
3392 [
3393 $1=
3394
3395 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3396
3397 for cf_subdir_prefix in \
3398         /usr \
3399         /usr/local \
3400         /usr/pkg \
3401         /opt \
3402         /opt/local \
3403         [$]HOME
3404 do
3405         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
3406 done
3407 ])dnl
3408 dnl ---------------------------------------------------------------------------
3409 dnl CF_TERM_HEADER version: 4 updated: 2015/04/15 19:08:48
3410 dnl --------------
3411 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3412 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3413 dnl but some packagers change this, breaking various applications.
3414 AC_DEFUN([CF_TERM_HEADER],[
3415 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3416 case ${cf_cv_ncurses_header} in
3417 (*/ncurses.h|*/ncursesw.h)
3418         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3419         ;;
3420 (*)
3421         cf_term_header=term.h
3422         ;;
3423 esac
3424
3425 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3426 do
3427 AC_TRY_COMPILE([#include <stdio.h>
3428 #include <${cf_cv_ncurses_header:-curses.h}>
3429 #include <$cf_test>
3430 ],[int x = auto_left_margin],[
3431         cf_cv_term_header="$cf_test"],[
3432         cf_cv_term_header=unknown
3433         ])
3434         test "$cf_cv_term_header" != unknown && break
3435 done
3436 ])
3437
3438 # Set definitions to allow ifdef'ing to accommodate subdirectories
3439
3440 case $cf_cv_term_header in
3441 (*term.h)
3442         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
3443         ;;
3444 esac
3445
3446 case $cf_cv_term_header in
3447 (ncurses/term.h)
3448         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
3449         ;;
3450 (ncursesw/term.h)
3451         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
3452         ;;
3453 esac
3454 ])dnl
3455 dnl ---------------------------------------------------------------------------
3456 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
3457 dnl ---------------
3458 dnl Define a top_builddir symbol, for applications that need an absolute path.
3459 AC_DEFUN([CF_TOP_BUILDDIR],
3460 [
3461 top_builddir=ifelse($1,,`pwd`,$1)
3462 AC_SUBST(top_builddir)
3463 ])dnl
3464 dnl ---------------------------------------------------------------------------
3465 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
3466 dnl -------------------
3467 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
3468 dnl can define it successfully.
3469 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
3470 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3471         AC_TRY_COMPILE([
3472 #include <stdlib.h>
3473 #include <string.h>
3474 #include <sys/types.h>
3475 ],[
3476 #ifndef _XOPEN_SOURCE
3477 make an error
3478 #endif],
3479         [cf_cv_xopen_source=no],
3480         [cf_save="$CPPFLAGS"
3481          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3482          AC_TRY_COMPILE([
3483 #include <stdlib.h>
3484 #include <string.h>
3485 #include <sys/types.h>
3486 ],[
3487 #ifdef _XOPEN_SOURCE
3488 make an error
3489 #endif],
3490         [cf_cv_xopen_source=no],
3491         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3492         CPPFLAGS="$cf_save"
3493         ])
3494 ])
3495
3496 if test "$cf_cv_xopen_source" != no ; then
3497         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3498         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3499         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3500         CF_ADD_CFLAGS($cf_temp_xopen_source)
3501 fi
3502 ])
3503 dnl ---------------------------------------------------------------------------
3504 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3505 dnl --------
3506 dnl Make an uppercase version of a variable
3507 dnl $1=uppercase($2)
3508 AC_DEFUN([CF_UPPER],
3509 [
3510 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3511 ])dnl
3512 dnl ---------------------------------------------------------------------------
3513 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
3514 dnl -----------
3515 dnl Check for multibyte support, and if not found, utf8 compatibility library
3516 AC_DEFUN([CF_UTF8_LIB],
3517 [
3518 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3519         cf_save_LIBS="$LIBS"
3520         AC_TRY_LINK([
3521 #include <stdlib.h>],[putwc(0,0);],
3522         [cf_cv_utf8_lib=yes],
3523         [CF_FIND_LINKAGE([
3524 #include <libutf8.h>],[putwc(0,0);],utf8,
3525                 [cf_cv_utf8_lib=add-on],
3526                 [cf_cv_utf8_lib=no])
3527 ])])
3528
3529 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3530 # ncurses/ncursesw:
3531 if test "$cf_cv_utf8_lib" = "add-on" ; then
3532         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
3533         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3534         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3535         CF_ADD_LIBS($cf_cv_library_file_utf8)
3536 fi
3537 ])dnl
3538 dnl ---------------------------------------------------------------------------
3539 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3540 dnl ----------
3541 dnl Use AC_VERBOSE w/o the warnings
3542 AC_DEFUN([CF_VERBOSE],
3543 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3544 CF_MSG_LOG([$1])
3545 ])dnl
3546 dnl ---------------------------------------------------------------------------
3547 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
3548 dnl ---------------
3549 dnl Check for compiler-support for weak symbols.
3550 dnl This works with "recent" gcc.
3551 AC_DEFUN([CF_WEAK_SYMBOLS],[
3552 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
3553
3554 AC_TRY_COMPILE([
3555 #include <stdio.h>],
3556 [
3557 #if defined(__GNUC__)
3558 #  if defined __USE_ISOC99
3559 #    define _cat_pragma(exp)    _Pragma(#exp)
3560 #    define _weak_pragma(exp)   _cat_pragma(weak name)
3561 #  else
3562 #    define _weak_pragma(exp)
3563 #  endif
3564 #  define _declare(name)        __extension__ extern __typeof__(name) name
3565 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
3566 #endif
3567
3568 weak_symbol(fopen);
3569 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
3570 ])
3571 ])dnl
3572 dnl ---------------------------------------------------------------------------
3573 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
3574 dnl --------------------
3575 dnl Command-line option to specify the Ada95 compiler.
3576 AC_DEFUN([CF_WITH_ADA_COMPILER],[
3577 AC_MSG_CHECKING(for ada-compiler)
3578 AC_ARG_WITH(ada-compiler,
3579         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
3580         [cf_ada_compiler=$withval],
3581         [cf_ada_compiler=gnatmake])
3582 AC_SUBST(cf_ada_compiler)
3583 AC_MSG_RESULT($cf_ada_compiler)
3584 ])dnl
3585 dnl ---------------------------------------------------------------------------
3586 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
3587 dnl -------------------
3588 dnl Command-line option to specify where Ada includes will install.
3589 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
3590 AC_MSG_CHECKING(for ada-include)
3591 CF_WITH_PATH(ada-include,
3592    [  --with-ada-include=DIR  Ada includes are in DIR],
3593    ADA_INCLUDE,
3594    PREFIX/share/ada/adainclude,
3595    [$]prefix/share/ada/adainclude)
3596 AC_SUBST(ADA_INCLUDE)
3597 AC_MSG_RESULT($ADA_INCLUDE)
3598 ])dnl
3599 dnl ---------------------------------------------------------------------------
3600 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
3601 dnl -------------------
3602 dnl Command-line option to specify where Ada objects will install.
3603 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
3604 AC_MSG_CHECKING(for ada-objects)
3605 CF_WITH_PATH(ada-objects,
3606    [  --with-ada-objects=DIR  Ada objects are in DIR],
3607    ADA_OBJECTS,
3608    PREFIX/lib/ada/adalib,
3609    [$]prefix/lib/ada/adalib)
3610 AC_SUBST(ADA_OBJECTS)
3611 AC_MSG_RESULT($ADA_OBJECTS)
3612 ])dnl
3613 dnl ---------------------------------------------------------------------------
3614 dnl CF_WITH_ADA_SHAREDLIB version: 4 updated: 2014/05/31 21:08:37
3615 dnl ---------------------
3616 dnl Command-line option to specify if an Ada95 shared-library should be built,
3617 dnl and optionally what its soname should be.
3618 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
3619 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
3620 AC_ARG_WITH(ada-sharedlib,
3621         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
3622         [with_ada_sharedlib=$withval],
3623         [with_ada_sharedlib=no])
3624 AC_MSG_RESULT($with_ada_sharedlib)
3625
3626 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
3627 MAKE_ADA_SHAREDLIB="#"
3628
3629 if test "x$with_ada_sharedlib" != xno
3630 then
3631         MAKE_ADA_SHAREDLIB=
3632         if test "x$with_ada_sharedlib" != xyes
3633         then
3634                 ADA_SHAREDLIB="$with_ada_sharedlib"
3635         fi
3636 fi
3637
3638 AC_SUBST(ADA_SHAREDLIB)
3639 AC_SUBST(MAKE_ADA_SHAREDLIB)
3640 ])dnl
3641 dnl ---------------------------------------------------------------------------
3642 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3643 dnl ------------------
3644 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3645 dnl libraries.
3646 AC_DEFUN([CF_WITH_CURSES_DIR],[
3647
3648 AC_MSG_CHECKING(for specific curses-directory)
3649 AC_ARG_WITH(curses-dir,
3650         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3651         [cf_cv_curses_dir=$withval],
3652         [cf_cv_curses_dir=no])
3653 AC_MSG_RESULT($cf_cv_curses_dir)
3654
3655 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3656 then
3657         CF_PATH_SYNTAX(withval)
3658         if test -d "$cf_cv_curses_dir"
3659         then
3660                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3661                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3662         fi
3663 fi
3664 ])dnl
3665 dnl ---------------------------------------------------------------------------
3666 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
3667 dnl ------------------
3668 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
3669 dnl "lib" prefix, e.g., because it used the dll naming convention.
3670 dnl
3671 dnl $1 = variable to set
3672 AC_DEFUN([CF_WITH_LIB_PREFIX],
3673 [
3674 AC_MSG_CHECKING(if you want to have a library-prefix)
3675 AC_ARG_WITH(lib-prefix,
3676         [  --with-lib-prefix       override library-prefix],
3677         [with_lib_prefix=$withval],
3678         [with_lib_prefix=auto])
3679 AC_MSG_RESULT($with_lib_prefix)
3680
3681 if test $with_lib_prefix = auto
3682 then
3683         CF_LIB_PREFIX($1)
3684 elif test $with_lib_prefix = no
3685 then
3686         LIB_PREFIX=
3687 else
3688         LIB_PREFIX=$with_lib_prefix
3689 fi
3690 ])dnl
3691 dnl ---------------------------------------------------------------------------
3692 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
3693 dnl ------------
3694 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
3695 dnl defaulting to yes/no.
3696 dnl
3697 dnl $1 = option name
3698 dnl $2 = help-text
3699 dnl $3 = environment variable to set
3700 dnl $4 = default value, shown in the help-message, must be a constant
3701 dnl $5 = default value, if it's an expression & cannot be in the help-message
3702 dnl
3703 AC_DEFUN([CF_WITH_PATH],
3704 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
3705 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
3706 if ifelse([$5],,true,[test -n "$5"]) ; then
3707 CF_PATH_SYNTAX(withval)
3708 fi
3709 eval $3="$withval"
3710 AC_SUBST($3)dnl
3711 ])dnl
3712 dnl ---------------------------------------------------------------------------
3713 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
3714 dnl -------------------------
3715 dnl Allow the choice of the pkg-config library directory to be overridden.
3716 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
3717
3718 case $PKG_CONFIG in
3719 (no|none|yes)
3720         AC_MSG_CHECKING(for pkg-config library directory)
3721         ;;
3722 (*)
3723         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
3724         ;;
3725 esac
3726
3727 PKG_CONFIG_LIBDIR=no
3728 AC_ARG_WITH(pkg-config-libdir,
3729         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
3730         [PKG_CONFIG_LIBDIR=$withval],
3731         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
3732
3733 case x$PKG_CONFIG_LIBDIR in
3734 (x/*)
3735         ;;
3736 (xyes)
3737         # Look for the library directory using the same prefix as the executable
3738         if test "x$PKG_CONFIG" = xnone
3739         then
3740                 cf_path=$prefix
3741         else
3742                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
3743         fi
3744
3745         # If you don't like using the default architecture, you have to specify the
3746         # intended library directory and corresponding compiler/linker options.
3747         #
3748         # This case allows for Debian's 2014-flavor of multiarch, along with the
3749         # most common variations before that point.  Some other variants spell the
3750         # directory differently, e.g., "pkg-config", and put it in unusual places.
3751         # pkg-config has always been poorly standardized, which is ironic...
3752         case x`(arch) 2>/dev/null` in
3753         (*64)
3754                 cf_search_path="\
3755                         $cf_path/lib/*64-linux-gnu \
3756                         $cf_path/share \
3757                         $cf_path/lib64 \
3758                         $cf_path/lib32 \
3759                         $cf_path/lib"
3760                 ;;
3761         (*)
3762                 cf_search_path="\
3763                         $cf_path/lib/*-linux-gnu \
3764                         $cf_path/share \
3765                         $cf_path/lib32 \
3766                         $cf_path/lib \
3767                         $cf_path/libdata"
3768                 ;;
3769         esac
3770
3771         CF_VERBOSE(list...)
3772         for cf_config in $cf_search_path
3773         do
3774                 CF_VERBOSE(checking $cf_config/pkgconfig)
3775                 if test -d $cf_config/pkgconfig
3776                 then
3777                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
3778                         AC_MSG_CHECKING(done)
3779                         break
3780                 fi
3781         done
3782         ;;
3783 (*)
3784         ;;
3785 esac
3786
3787 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
3788         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
3789 fi
3790
3791 AC_SUBST(PKG_CONFIG_LIBDIR)
3792 ])dnl
3793 dnl ---------------------------------------------------------------------------
3794 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
3795 dnl ---------------
3796 dnl Check for POSIX thread library.
3797 AC_DEFUN([CF_WITH_PTHREAD],
3798 [
3799 AC_MSG_CHECKING(if you want to link with the pthread library)
3800 AC_ARG_WITH(pthread,
3801         [  --with-pthread          use POSIX thread library],
3802         [with_pthread=$withval],
3803         [with_pthread=no])
3804 AC_MSG_RESULT($with_pthread)
3805
3806 if test "$with_pthread" != no ; then
3807         AC_CHECK_HEADER(pthread.h,[
3808         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
3809
3810         for cf_lib_pthread in pthread c_r
3811         do
3812             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
3813             cf_save_LIBS="$LIBS"
3814             CF_ADD_LIB($cf_lib_pthread)
3815             AC_TRY_LINK([
3816 #include <pthread.h>
3817 ],[
3818                 int rc = pthread_create(0,0,0,0);
3819                 int r2 = pthread_mutexattr_settype(0, 0);
3820 ],[with_pthread=yes],[with_pthread=no])
3821             LIBS="$cf_save_LIBS"
3822             AC_MSG_RESULT($with_pthread)
3823             test "$with_pthread" = yes && break
3824         done
3825
3826         if test "$with_pthread" = yes ; then
3827             CF_ADD_LIB($cf_lib_pthread)
3828             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
3829         else
3830             AC_MSG_ERROR(Cannot link with pthread library)
3831         fi
3832         ])
3833 fi
3834 ])
3835 dnl ---------------------------------------------------------------------------
3836 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
3837 dnl ---------------
3838 dnl For testing, override the derived host system-type which is used to decide
3839 dnl things such as the linker commands used to build shared libraries.  This is
3840 dnl normally chosen automatically based on the type of system which you are
3841 dnl building on.  We use it for testing the configure script.
3842 dnl
3843 dnl This is different from the --host option: it is used only for testing parts
3844 dnl of the configure script which would not be reachable with --host since that
3845 dnl relies on the build environment being real, rather than mocked up.
3846 AC_DEFUN([CF_WITH_SYSTYPE],[
3847 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
3848 AC_ARG_WITH(system-type,
3849         [  --with-system-type=XXX  test: override derived host system-type],
3850 [AC_MSG_WARN(overriding system type to $withval)
3851         cf_cv_system_name=$withval
3852         host_os=$withval
3853 ])
3854 ])dnl
3855 dnl ---------------------------------------------------------------------------
3856 dnl CF_XOPEN_SOURCE version: 50 updated: 2015/10/17 19:03:33
3857 dnl ---------------
3858 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
3859 dnl or adapt to the vendor's definitions to get equivalent functionality,
3860 dnl without losing the common non-POSIX features.
3861 dnl
3862 dnl Parameters:
3863 dnl     $1 is the nominal value for _XOPEN_SOURCE
3864 dnl     $2 is the nominal value for _POSIX_C_SOURCE
3865 AC_DEFUN([CF_XOPEN_SOURCE],[
3866 AC_REQUIRE([AC_CANONICAL_HOST])
3867
3868 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
3869 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
3870 cf_xopen_source=
3871
3872 case $host_os in
3873 (aix[[4-7]]*)
3874         cf_xopen_source="-D_ALL_SOURCE"
3875         ;;
3876 (cygwin|msys)
3877         cf_XOPEN_SOURCE=600
3878         ;;
3879 (darwin[[0-8]].*)
3880         cf_xopen_source="-D_APPLE_C_SOURCE"
3881         ;;
3882 (darwin*)
3883         cf_xopen_source="-D_DARWIN_C_SOURCE"
3884         cf_XOPEN_SOURCE=
3885         ;;
3886 (freebsd*|dragonfly*)
3887         # 5.x headers associate
3888         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
3889         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
3890         cf_POSIX_C_SOURCE=200112L
3891         cf_XOPEN_SOURCE=600
3892         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3893         ;;
3894 (hpux11*)
3895         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
3896         ;;
3897 (hpux*)
3898         cf_xopen_source="-D_HPUX_SOURCE"
3899         ;;
3900 (irix[[56]].*)
3901         cf_xopen_source="-D_SGI_SOURCE"
3902         cf_XOPEN_SOURCE=
3903         ;;
3904 (linux*|gnu*|mint*|k*bsd*-gnu)
3905         CF_GNU_SOURCE
3906         ;;
3907 (minix*)
3908         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
3909         ;;
3910 (mirbsd*)
3911         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
3912         cf_XOPEN_SOURCE=
3913         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3914         ;;
3915 (netbsd*)
3916         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
3917         ;;
3918 (openbsd[[4-9]]*)
3919         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
3920         cf_xopen_source="-D_BSD_SOURCE"
3921         cf_XOPEN_SOURCE=600
3922         ;;
3923 (openbsd*)
3924         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
3925         ;;
3926 (os2*)
3927         cf_XOPEN_SOURCE=
3928         ;;
3929 (osf[[45]]*)
3930         cf_xopen_source="-D_OSF_SOURCE"
3931         ;;
3932 (nto-qnx*)
3933         cf_xopen_source="-D_QNX_SOURCE"
3934         ;;
3935 (sco*)
3936         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
3937         ;;
3938 (solaris2.*)
3939         cf_xopen_source="-D__EXTENSIONS__"
3940         cf_cv_xopen_source=broken
3941         ;;
3942 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
3943         cf_XOPEN_SOURCE=
3944         cf_POSIX_C_SOURCE=
3945         ;;
3946 (*)
3947         CF_TRY_XOPEN_SOURCE
3948         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3949         ;;
3950 esac
3951
3952 if test -n "$cf_xopen_source" ; then
3953         CF_ADD_CFLAGS($cf_xopen_source,true)
3954 fi
3955
3956 dnl In anything but the default case, we may have system-specific setting
3957 dnl which is still not guaranteed to provide all of the entrypoints that
3958 dnl _XOPEN_SOURCE would yield.
3959 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
3960         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
3961         AC_TRY_COMPILE([#include <stdlib.h>],[
3962 #ifndef _XOPEN_SOURCE
3963 make an error
3964 #endif],
3965         [cf_XOPEN_SOURCE_set=yes],
3966         [cf_XOPEN_SOURCE_set=no])
3967         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
3968         if test $cf_XOPEN_SOURCE_set = yes
3969         then
3970                 AC_TRY_COMPILE([#include <stdlib.h>],[
3971 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
3972 make an error
3973 #endif],
3974                 [cf_XOPEN_SOURCE_set_ok=yes],
3975                 [cf_XOPEN_SOURCE_set_ok=no])
3976                 if test $cf_XOPEN_SOURCE_set_ok = no
3977                 then
3978                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
3979                 fi
3980         else
3981                 CF_TRY_XOPEN_SOURCE
3982         fi
3983 fi
3984 ])