ncurses 5.9 - patch 20121102
[ncurses.git] / Ada95 / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 2010-2011,2012 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey
30 dnl
31 dnl $Id: configure.in,v 1.45 2012/10/06 22:42:31 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See http://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.52.20030208)
38 AC_REVISION($Revision: 1.45 $)
39 AC_INIT(gen/gen.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43
44 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
45 AC_ARG_WITH(system-type,
46 [  --with-system-type=XXX  test: override derived host system-type],
47 [AC_MSG_WARN(overriding system type to $withval)
48  cf_cv_system_name=$withval])
49
50 ###     Save the given $CFLAGS to allow user-override.
51 cf_user_CFLAGS="$CFLAGS"
52
53 ###     Default install-location
54 CF_CFG_DEFAULTS
55
56 ###     Checks for programs.
57 CF_PROG_CC(gnatgcc gcc cc)
58 AC_PROG_CPP
59 AC_PROG_GCC_TRADITIONAL
60 CF_PROG_CC_C_O(CC)
61
62 AC_ARG_PROGRAM
63
64 CF_PROG_AWK
65 CF_PROG_EGREP
66 AC_PROG_INSTALL
67 CF_PROG_LN_S
68
69 AC_SYS_LONG_FILE_NAMES
70
71 # if we find pkg-config, check if we should install the ".pc" files.
72 CF_PKG_CONFIG
73 CF_WITH_PKG_CONFIG_LIBDIR
74 CF_ENABLE_PC_FILES
75
76 AC_MSG_CHECKING(if you want to build test-programs)
77 AC_ARG_WITH(tests,
78         [  --without-tests         suppress build with test-programs],
79         [cf_with_tests=$withval],
80         [cf_with_tests=yes])
81 AC_MSG_RESULT($cf_with_tests)
82
83 AC_MSG_CHECKING(if we should assume mixed-case filenames)
84 AC_ARG_ENABLE(mixed-case,
85         [  --enable-mixed-case     tic should assume mixed-case filenames],
86         [enable_mixedcase=$enableval],
87         [enable_mixedcase=auto])
88 AC_MSG_RESULT($enable_mixedcase)
89 if test "$enable_mixedcase" = "auto" ; then
90     CF_MIXEDCASE_FILENAMES
91 else
92     cf_cv_mixedcase=$enable_mixedcase
93     if test "$enable_mixedcase" = "yes" ; then
94         AC_DEFINE(MIXEDCASE_FILENAMES)
95     fi
96 fi
97
98 # do this after mixed-case option (tags/TAGS is not as important as tic).
99 AC_PROG_MAKE_SET
100 CF_MAKE_TAGS
101 CF_MAKEFLAGS
102
103 dnl These are standard among *NIX systems, but not when cross-compiling
104 AC_CHECK_TOOL(RANLIB, ranlib, ':')
105 AC_CHECK_TOOL(LD, ld, ld)
106 AC_CHECK_TOOL(AR, ar, ar)
107 CF_AR_FLAGS
108 CF_PATHSEP
109
110 dnl Special option for use by system-builders: the install-prefix is used to
111 dnl adjust the location into which the actual install is done, so that an
112 dnl archive can be built without modifying the host system's configuration.
113 AC_MSG_CHECKING(if you have specified an install-prefix)
114 AC_ARG_WITH(install-prefix,
115         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
116         [case "$withval" in #(vi
117         yes|no) #(vi
118                 ;;
119         *)      DESTDIR="$withval"
120                 ;;
121         esac])
122 AC_MSG_RESULT($DESTDIR)
123 AC_SUBST(DESTDIR)
124
125 ###############################################################################
126 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
127 # If we're cross-compiling, allow the user to override the tools and their
128 # options.  The configure script is oriented toward identifying the host
129 # compiler, etc., but we need a build compiler to generate parts of the source.
130 CF_BUILD_CC
131
132 ###############################################################################
133 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
134
135 ### Options to allow the user to specify the set of libraries which are used.
136 ### Use "--without-normal --with-shared" to allow the default model to be
137 ### shared, for example.
138 cf_list_models=""
139
140 AC_MSG_CHECKING(if you want to build shared C-objects)
141 AC_ARG_WITH(shared,
142         [  --with-shared           generate shared C-objects (needed for --with-ada-sharedlib)],
143         [with_shared=$withval],
144         [with_shared=no])
145 AC_MSG_RESULT($with_shared)
146 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
147
148 AC_MSG_CHECKING(for specified models)
149 test -z "$cf_list_models" && cf_list_models=normal
150 AC_MSG_RESULT($cf_list_models)
151
152 ### Use the first model as the default, and save its suffix for use in building
153 ### up test-applications.
154 AC_MSG_CHECKING(for default model)
155 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
156 AC_MSG_RESULT($DFT_LWR_MODEL)
157
158 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
159
160 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
161 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
162
163 CF_NCURSES_ADDON
164
165 CF_WITH_LIB_PREFIX(cf_prefix)
166
167 LIB_SUFFIX=
168 AC_SUBST(LIB_SUFFIX)
169
170 ###############################################################################
171
172 dnl Not all ports of gcc support the -g option
173
174 if test X"$CC_G_OPT" = X"" ; then
175         CC_G_OPT='-g'
176         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
177 fi
178 AC_SUBST(CC_G_OPT)
179
180 AC_MSG_CHECKING(for default loader flags)
181 case $DFT_LWR_MODEL in
182 normal)  LD_MODEL=''   ;;
183 debug)   LD_MODEL=$CC_G_OPT ;;
184 profile) LD_MODEL='-pg';;
185 shared)  LD_MODEL=''   ;;
186 esac
187 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
188 AC_MSG_RESULT($LD_MODEL)
189
190 CF_SHARED_OPTS
191
192 # The test/sample programs in the original tree link using rpath option.
193 # Make it optional for packagers.
194 if test -n "$LOCAL_LDFLAGS"
195 then
196         AC_MSG_CHECKING(if you want to link sample programs with rpath option)
197         AC_ARG_ENABLE(rpath-link,
198                 [  --enable-rpath-link     link sample programs with rpath option],
199                 [with_rpath_link=$enableval],
200                 [with_rpath_link=yes])
201         AC_MSG_RESULT($with_rpath_link)
202         if test "$with_rpath_link" = no
203         then
204                 LOCAL_LDFLAGS=
205                 LOCAL_LDFLAGS2=
206         fi
207 fi
208
209 ###############################################################################
210 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
211
212 ###   use option --enable-broken-linker to force on use of broken-linker support
213 AC_MSG_CHECKING(if you want broken-linker support code)
214 AC_ARG_ENABLE(broken_linker,
215         [  --enable-broken_linker  compile with broken-linker support code],
216         [with_broken_linker=$enableval],
217         [with_broken_linker=${BROKEN_LINKER:-no}])
218 AC_MSG_RESULT($with_broken_linker)
219
220 BROKEN_LINKER=0
221 if test "$with_broken_linker" = yes ; then
222         AC_DEFINE(BROKEN_LINKER)
223         BROKEN_LINKER=1
224 elif test "$DFT_LWR_MODEL" = shared ; then
225         case $cf_cv_system_name in #(vi
226         cygwin*)
227                 AC_DEFINE(BROKEN_LINKER)
228                 BROKEN_LINKER=1
229                 CF_VERBOSE(cygwin linker is broken anyway)
230                 ;;
231         esac
232 fi
233 AC_SUBST(BROKEN_LINKER)
234
235 # Check to define _XOPEN_SOURCE "automatically"
236 CF_XOPEN_SOURCE
237
238 CF_LARGEFILE
239
240 ### Enable compiling-in rcs id's
241 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
242 AC_ARG_WITH(rcs-ids,
243         [  --with-rcs-ids          compile-in RCS identifiers],
244         [with_rcs_ids=$withval],
245         [with_rcs_ids=no])
246 AC_MSG_RESULT($with_rcs_ids)
247 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 if RCS identifiers should be compiled-in)])
248
249 ###############################################################################
250 CF_HELP_MESSAGE(Extensions:)
251
252 ### Note that some functions (such as const) are normally disabled anyway.
253 AC_MSG_CHECKING(if you want to build with function extensions)
254 AC_ARG_ENABLE(ext-funcs,
255         [  --disable-ext-funcs     disable function-extensions],
256         [with_ext_funcs=$enableval],
257         [with_ext_funcs=yes])
258 AC_MSG_RESULT($with_ext_funcs)
259 if test "$with_ext_funcs" = yes ; then
260         NCURSES_EXT_FUNCS=1
261         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 if we have use_default_colors function])
262         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 if we have ncurses extended functions])
263 else
264         NCURSES_EXT_FUNCS=0
265 fi
266 AC_SUBST(NCURSES_EXT_FUNCS)
267
268 ###   use option --enable-const to turn on use of const beyond that in XSI.
269 AC_MSG_CHECKING(for extended use of const keyword)
270 AC_ARG_ENABLE(const,
271         [  --enable-const          compile with extra/non-standard const],
272         [with_ext_const=$enableval],
273         [with_ext_const=no])
274 AC_MSG_RESULT($with_ext_const)
275 NCURSES_CONST='/*nothing*/'
276 if test "$with_ext_const" = yes ; then
277         NCURSES_CONST=const
278 fi
279 AC_SUBST(NCURSES_CONST)
280
281 ###############################################################################
282 # These options are relatively safe to experiment with.
283 CF_HELP_MESSAGE(Development Code:)
284 AC_MSG_CHECKING(if you want all development code)
285 AC_ARG_WITH(develop,
286         [  --without-develop       disable development options],
287         [with_develop=$withval],
288         [with_develop=no])
289 AC_MSG_RESULT($with_develop)
290
291 ###############################################################################
292 # These are just experimental, probably should not be in a package:
293 CF_HELP_MESSAGE(Experimental Code:)
294
295 # This is still experimental (20080329), but should ultimately be moved to
296 # the script-block --with-normal, etc.
297 CF_WITH_PTHREAD
298
299 AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
300 AC_ARG_ENABLE(weak-symbols,
301     [  --enable-weak-symbols   enable weak-symbols for pthreads],
302     [use_weak_symbols=$withval],
303     [use_weak_symbols=no])
304 AC_MSG_RESULT($use_weak_symbols)
305 if test "$use_weak_symbols" = yes ; then
306     CF_WEAK_SYMBOLS
307 else
308     cf_cv_weak_symbols=no
309 fi
310
311 if test $cf_cv_weak_symbols = yes ; then
312     AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
313 fi
314
315 PTHREAD=
316 if test "$with_pthread" = "yes" ; then
317     AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use the pthreads library])
318     enable_reentrant=yes
319     if test $cf_cv_weak_symbols = yes ; then
320         PTHREAD=-lpthread
321     fi
322 fi
323 AC_SUBST(PTHREAD)
324
325 # OpenSUSE is installing ncurses6, using reentrant option.
326 AC_CHECK_FUNC(_nc_TABSIZE,[assume_reentrant=yes], [assume_reentrant=no])
327
328 # Reentrant code has to be opaque; there's little advantage to making ncurses
329 # opaque outside of that, so there is no --enable-opaque option.  We can use
330 # this option without --with-pthreads, but this will be always set for
331 # pthreads.
332 AC_MSG_CHECKING(if you want experimental reentrant code)
333 AC_ARG_ENABLE(reentrant,
334         [  --enable-reentrant      compile with experimental reentrant code],
335         [with_reentrant=$enableval],
336         [with_reentrant=$assume_reentrant])
337 AC_MSG_RESULT($with_reentrant)
338 if test "$with_reentrant" = yes ; then
339         cf_cv_enable_reentrant=1
340         if test $cf_cv_weak_symbols = yes ; then
341                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
342         elif test "$assume_reentrant" = no ; then
343                 LIB_SUFFIX="t${LIB_SUFFIX}"
344         fi
345         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to compile with experimental reentrant code])
346 else
347         cf_cv_enable_reentrant=0
348 fi
349 AC_SUBST(cf_cv_enable_reentrant)
350
351 ### Allow using a different wrap-prefix
352 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
353         AC_MSG_CHECKING(for prefix used to wrap public variables)
354         AC_ARG_WITH(wrap-prefix,
355                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
356                 [NCURSES_WRAP_PREFIX=$withval],
357                 [NCURSES_WRAP_PREFIX=_nc_])
358         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
359 else
360         NCURSES_WRAP_PREFIX=_nc_
361 fi
362 AC_SUBST(NCURSES_WRAP_PREFIX)
363 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ ncurses internal prefix])
364
365 ###############################################################################
366 CF_HELP_MESSAGE(Testing/development Options:)
367
368 ###     use option --disable-echo to suppress full display compiling commands
369 CF_DISABLE_ECHO
370
371 ###     use option --enable-warnings to turn on all gcc warnings
372 AC_MSG_CHECKING(if you want to see compiler warnings)
373 AC_ARG_ENABLE(warnings,
374         [  --enable-warnings       build: turn on GCC compiler warnings],
375         [with_warnings=$enableval])
376 AC_MSG_RESULT($with_warnings)
377
378 if test "x$with_warnings" = "xyes"; then
379         CF_ADD_ADAFLAGS(-gnatg)
380         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
381 fi
382 CF_GCC_ATTRIBUTES
383
384 ###     use option --enable-assertions to turn on generation of assertion code
385 AC_MSG_CHECKING(if you want to enable runtime assertions)
386 AC_ARG_ENABLE(assertions,
387         [  --enable-assertions     test: turn on generation of assertion code],
388         [with_assertions=$enableval],
389         [with_assertions=no])
390 AC_MSG_RESULT($with_assertions)
391 if test -n "$GCC"
392 then
393         if test "$with_assertions" = no
394         then
395                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
396         else
397                 CF_ADD_ADAFLAGS(-gnata)
398         fi
399 fi
400
401 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
402 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
403
404 ###     use option --enable-expanded to generate certain macros as functions
405 AC_ARG_ENABLE(expanded,
406         [  --enable-expanded       test: generate functions for certain macros],
407         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 if ncurses macros should be expanded as functions])])
408
409 ###     use option --disable-macros to suppress macros in favor of functions
410 AC_ARG_ENABLE(macros,
411         [  --disable-macros        test: use functions rather than macros],
412         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 if ncurses macros should be expanded as functions])])
413
414 # Normally we only add trace() to the debug-library.  Allow this to be
415 # extended to all models of the ncurses library:
416 cf_all_traces=no
417 case "$CFLAGS $CPPFLAGS" in
418 *-DTRACE*)
419         cf_all_traces=yes
420         ;;
421 esac
422
423 AC_MSG_CHECKING(whether to add trace feature to all models)
424 AC_ARG_WITH(trace,
425 [  --with-trace            test: add trace() function to all models of ncurses],
426 [cf_with_trace=$withval],
427 [cf_with_trace=$cf_all_traces])
428 AC_MSG_RESULT($cf_with_trace)
429
430 if test "$cf_with_trace" = yes ; then
431         ADA_TRACE=TRUE
432         CF_ADD_CFLAGS(-DTRACE)
433 else
434         ADA_TRACE=FALSE
435 fi
436
437 AC_SUBST(ADA_TRACE)
438
439 ###     Checks for libraries.
440 case $cf_cv_system_name in #(vi
441 *mingw32*) #(vi
442         ;;
443 *)
444 AC_CHECK_FUNC(gettimeofday,
445         AC_DEFINE(HAVE_GETTIMEOFDAY),[
446
447 AC_CHECK_LIB(bsd, gettimeofday,
448         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday])
449         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
450         ;;
451 esac
452
453 ###     Checks for header files.
454 AC_STDC_HEADERS
455 AC_HEADER_DIRENT
456 AC_HEADER_TIME
457
458 ###     checks for compiler characteristics
459 AC_LANG_C
460 AC_C_CONST
461
462 ###     Checks for external-data
463 CF_LINK_DATAONLY
464
465 ###     Checks for library functions.
466 CF_MKSTEMP
467
468 AC_TYPE_SIGNAL
469
470 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
471 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
472         CF_STRIP_G_OPT(CFLAGS)
473         CF_STRIP_G_OPT(CXXFLAGS)
474 fi
475
476 CF_HELP_MESSAGE(Ada95 Binding Options:)
477 cf_with_ada=yes
478 dnl Check for availability of GNU Ada Translator (GNAT).
479 dnl At the moment we support no other Ada95 compiler.
480 if test "$cf_with_ada" != "no" ; then
481         CF_PROG_GNAT
482         if test "$cf_cv_prog_gnat_correct" = yes; then
483                 CF_FIXUP_ADAFLAGS
484
485                 CF_GNAT_GENERICS
486                 CF_GNAT_SIGINT
487                 CF_GNAT_PRAGMA_UNREF
488                 CF_GNAT_PROJECTS
489
490                 CF_WITH_ADA_COMPILER
491
492                 cf_ada_package=terminal_interface
493                 AC_SUBST(cf_ada_package)
494
495                 CF_WITH_ADA_INCLUDE
496                 CF_WITH_ADA_OBJECTS
497                 CF_WITH_ADA_SHAREDLIB
498         else
499                 AC_MSG_ERROR(No usable Ada compiler found)
500         fi
501 else
502         AC_MSG_ERROR(The Ada compiler is needed for this package)
503 fi
504
505 ################################################################################
506
507 # not needed
508 TINFO_LDFLAGS2=
509 AC_SUBST(TINFO_LDFLAGS2)
510 TINFO_LIBS=
511 AC_SUBST(TINFO_LIBS)
512
513 ### Construct the list of include-directories to be generated
514 CF_INCLUDE_DIRS
515 CF_ADA_INCLUDE_DIRS
516
517 ### Build up pieces for makefile rules
518 AC_MSG_CHECKING(default library suffix)
519 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
520 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
521 AC_MSG_RESULT($DFT_ARG_SUFFIX)
522
523 AC_MSG_CHECKING(default library-dependency suffix)
524 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
525 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
526 AC_MSG_RESULT($DFT_DEP_SUFFIX)
527
528 AC_MSG_CHECKING(default object directory)
529 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
530 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
531 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
532
533 ### Set up low-level terminfo dependencies for makefiles.
534
535 if test "$DFT_LWR_MODEL" = shared ; then
536         case $cf_cv_system_name in #(vi
537         cygwin*)
538                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
539                 ;;
540         esac
541 fi
542
543 ### Construct the list of subdirectories for which we'll customize makefiles
544 ### with the appropriate compile-rules.
545
546 SUB_MAKEFILES="gen/adacurses${DFT_ARG_SUFFIX}-config:gen/adacurses-config.in"
547
548 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as the library path-separator])
549
550 ### Now that we're done running tests, add the compiler-warnings, if any
551 CF_ADD_CFLAGS($EXTRA_CFLAGS)
552
553 ################################################################################
554
555 if test x"$enable_pc_files" = xyes ; then \
556 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
557 MAKE_PC_FILES=
558 else
559 MAKE_PC_FILES="#"
560 fi
561 AC_SUBST(MAKE_PC_FILES)
562 AC_SUBST(cross_compiling)
563
564 ################################################################################
565
566 TEST_ARG2=
567 AC_SUBST(TEST_ARG2)
568
569 TEST_LIBS2=
570 AC_SUBST(TEST_LIBS2)
571
572 dnl for separate build, this is good enough for "sh $(top_srcdir)/misc/shlib"
573 NCURSES_SHLIB2="sh -c"
574 AC_SUBST(NCURSES_SHLIB2)
575
576 ADA_SUBDIRS="include gen src doc"
577 if test "x$cf_with_tests" != "xno" ; then
578         ADA_SUBDIRS="$ADA_SUBDIRS samples"
579 fi
580 for cf_dir in $ADA_SUBDIRS
581 do
582         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
583 done
584 AC_SUBST(ADA_SUBDIRS)
585
586 NCURSES_TREE="#"
587 AC_SUBST(NCURSES_TREE)
588
589 EXTERNAL_TREE=
590 AC_SUBST(EXTERNAL_TREE)
591
592 # match layout used by make-tar.sh
593 ADAHTML_DIR=../doc/ada
594 AC_SUBST(ADAHTML_DIR)
595
596 AC_OUTPUT( \
597         $SUB_MAKEFILES \
598         doc/adacurses${DFT_ARG_SUFFIX}-config.1:doc/MKada_config.in \
599         Makefile,[
600 if test -z "$USE_OLD_MAKERULES" ; then
601         $AWK -f $srcdir/mk-1st.awk <$srcdir/src/modules >>src/Makefile
602 fi
603 ],[
604 ### Special initialization commands, used to pass information from the
605 ### configuration-run into config.status
606
607 AWK="$AWK"
608 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
609 DFT_LWR_MODEL="$DFT_LWR_MODEL"
610 LIB_NAME="$LIB_NAME"
611 LIB_PREFIX="$LIB_PREFIX"
612 LIB_SUFFIX="$LIB_SUFFIX"
613 LN_S="$LN_S"
614 NCURSES_MAJOR="$NCURSES_MAJOR"
615 NCURSES_MINOR="$NCURSES_MINOR"
616 NCURSES_PATCH="$NCURSES_PATCH"
617 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
618 cf_cv_abi_version="$cf_cv_abi_version"
619 cf_cv_rel_version="$cf_cv_rel_version"
620 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
621 cf_cv_shared_soname='$cf_cv_shared_soname'
622 cf_cv_shlib_version="$cf_cv_shlib_version"
623 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
624 cf_cv_system_name="$cf_cv_system_name"
625 host="$host"
626 target="$target"
627
628 ],cat)dnl
629 ${MAKE:-make} preinstall