ncurses 6.0 - patch 20160625
[ncurses.git] / Ada95 / samples / sample-keyboard_handler.adb
1 ------------------------------------------------------------------------------
2 --                                                                          --
3 --                       GNAT ncurses Binding Samples                       --
4 --                                                                          --
5 --                            Sample.Keyboard_Handler                       --
6 --                                                                          --
7 --                                 B O D Y                                  --
8 --                                                                          --
9 ------------------------------------------------------------------------------
10 -- Copyright (c) 1998-2006,2011 Free Software Foundation, Inc.              --
11 --                                                                          --
12 -- Permission is hereby granted, free of charge, to any person obtaining a  --
13 -- copy of this software and associated documentation files (the            --
14 -- "Software"), to deal in the Software without restriction, including      --
15 -- without limitation the rights to use, copy, modify, merge, publish,      --
16 -- distribute, distribute with modifications, sublicense, and/or sell       --
17 -- copies of the Software, and to permit persons to whom the Software is    --
18 -- furnished to do so, subject to the following conditions:                 --
19 --                                                                          --
20 -- The above copyright notice and this permission notice shall be included  --
21 -- in all copies or substantial portions of the Software.                   --
22 --                                                                          --
23 -- THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  --
24 -- OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               --
25 -- MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   --
26 -- IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   --
27 -- DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    --
28 -- OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    --
29 -- THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               --
30 --                                                                          --
31 -- Except as contained in this notice, the name(s) of the above copyright   --
32 -- holders shall not be used in advertising or otherwise to promote the     --
33 -- sale, use or other dealings in this Software without prior written       --
34 -- authorization.                                                           --
35 ------------------------------------------------------------------------------
36 --  Author:  Juergen Pfeifer, 1996
37 --  Version Control
38 --  $Revision: 1.16 $
39 --  $Date: 2011/03/23 00:34:24 $
40 --  Binding Version 01.00
41 ------------------------------------------------------------------------------
42 with Ada.Strings; use Ada.Strings;
43 with Ada.Strings.Fixed; use Ada.Strings.Fixed;
44 with Ada.Strings.Maps.Constants; use Ada.Strings.Maps.Constants;
45 with Ada.Characters.Latin_1; use Ada.Characters.Latin_1;
46 with Ada.Characters.Handling; use Ada.Characters.Handling;
47
48 with Terminal_Interface.Curses.Panels; use Terminal_Interface.Curses.Panels;
49 with Terminal_Interface.Curses.Forms; use Terminal_Interface.Curses.Forms;
50 with Terminal_Interface.Curses.Forms.Field_Types.Enumeration;
51 use  Terminal_Interface.Curses.Forms.Field_Types.Enumeration;
52
53 with Sample.Header_Handler; use Sample.Header_Handler;
54 with Sample.Form_Demo.Aux; use Sample.Form_Demo.Aux;
55 with Sample.Manifest; use Sample.Manifest;
56 with Sample.Form_Demo.Handler;
57
58 --  This package contains a centralized keyboard handler used throughout
59 --  this example. The handler establishes a timeout mechanism that provides
60 --  periodical updates of the common header lines used in this example.
61 --
62
63 package body Sample.Keyboard_Handler is
64
65    In_Command : Boolean := False;
66
67    function Get_Key (Win : Window := Standard_Window) return Real_Key_Code
68    is
69       K : Real_Key_Code;
70
71       function Command return Real_Key_Code;
72
73       function Command return Real_Key_Code
74       is
75          function My_Driver (F : Form;
76                              C : Key_Code;
77                              P : Panel) return Boolean;
78          package Fh is new Sample.Form_Demo.Handler (My_Driver);
79
80          type Label_Array is array (Label_Number) of String (1 .. 8);
81
82          Labels : Label_Array;
83
84          FA : Field_Array_Access := new Field_Array'
85            (Make (0, 0, "Command:"),
86             Make (Top => 0, Left => 9, Width => Columns - 11),
87             Null_Field);
88
89          K  : Real_Key_Code := Key_None;
90          N  : Natural := 0;
91
92          function My_Driver (F : Form;
93                              C : Key_Code;
94                              P : Panel) return Boolean
95          is
96             Ch : Character;
97          begin
98             if P = Null_Panel then
99                raise Panel_Exception;
100             end if;
101             if C in User_Key_Code'Range and then C = QUIT then
102                if Driver (F, F_Validate_Field) = Form_Ok  then
103                   K := Key_None;
104                   return True;
105                end if;
106             elsif C in Normal_Key_Code'Range then
107                Ch := Character'Val (C);
108                if Ch = LF or else Ch = CR then
109                   if Driver (F, F_Validate_Field) = Form_Ok  then
110                      declare
111                         Buffer : String (1 .. Positive (Columns - 11));
112                         Cmdc : String (1 .. 8);
113                      begin
114                         Get_Buffer (Fld => FA.all (2), Str => Buffer);
115                         Trim (Buffer, Left);
116                         if Buffer (1) /= ' ' then
117                            Cmdc := To_Upper (Buffer (Cmdc'Range));
118                            for I in Labels'Range loop
119                               if Cmdc = Labels (I) then
120                                  K := Function_Key_Code
121                                    (Function_Key_Number (I));
122                                  exit;
123                               end if;
124                            end loop;
125                         end if;
126                         return True;
127                      end;
128                   end if;
129                end if;
130             end if;
131             return False;
132          end My_Driver;
133
134       begin
135          In_Command := True;
136          for I in Label_Number'Range loop
137             Get_Soft_Label_Key (I, Labels (I));
138             Trim (Labels (I), Left);
139             Translate (Labels (I), Upper_Case_Map);
140             if Labels (I) (1) /= ' ' then
141                N := N + 1;
142             end if;
143          end loop;
144          if N > 0 then --  some labels were really set
145             declare
146                Enum_Info    : Enumeration_Info (N);
147                Enum_Field   : Enumeration_Field;
148                J : Positive := Enum_Info.Names'First;
149
150                Frm : Form := Create (FA);
151
152             begin
153                for I in Label_Number'Range loop
154                   if Labels (I) (1) /= ' ' then
155                      Enum_Info.Names (J) := new String'(Labels (I));
156                      J := J + 1;
157                   end if;
158                end loop;
159                Enum_Field := Create (Enum_Info, True);
160                Set_Field_Type (FA.all (2), Enum_Field);
161                Set_Background (FA.all (2), Normal_Video);
162
163                Fh.Drive_Me (Frm, Lines - 3, 0);
164                Delete (Frm);
165                Update_Panels; Update_Screen;
166             end;
167          end if;
168          Free (FA, True);
169          In_Command := False;
170          return K;
171       end Command;
172
173    begin
174       Set_Timeout_Mode (Win, Delayed, 30000);
175       loop
176          K := Get_Keystroke (Win);
177          if K = Key_None then  -- a timeout occurred
178             Update_Header_Window;
179          elsif K = 3 and then not In_Command  then  -- CTRL-C
180             K := Command;
181             exit when K /= Key_None;
182          else
183             exit;
184          end if;
185       end loop;
186       return K;
187    end Get_Key;
188
189    procedure Init_Keyboard_Handler is
190    begin
191       null;
192    end Init_Keyboard_Handler;
193
194 end Sample.Keyboard_Handler;