6e348b93dd2b34e1ae3c03bb98b10d57283ccfe5
[ncurses.git] / Ada95 / src / terminal_interface-curses-forms-field_types-user.adb
1 ------------------------------------------------------------------------------
2 --                                                                          --
3 --                           GNAT ncurses Binding                           --
4 --                                                                          --
5 --              Terminal_Interface.Curses.Forms.Field_Types.User            --
6 --                                                                          --
7 --                                 B O D Y                                  --
8 --                                                                          --
9 ------------------------------------------------------------------------------
10 -- Copyright (c) 1998 Free Software Foundation, Inc.                        --
11 --                                                                          --
12 -- Permission is hereby granted, free of charge, to any person obtaining a  --
13 -- copy of this software and associated documentation files (the            --
14 -- "Software"), to deal in the Software without restriction, including      --
15 -- without limitation the rights to use, copy, modify, merge, publish,      --
16 -- distribute, distribute with modifications, sublicense, and/or sell       --
17 -- copies of the Software, and to permit persons to whom the Software is    --
18 -- furnished to do so, subject to the following conditions:                 --
19 --                                                                          --
20 -- The above copyright notice and this permission notice shall be included  --
21 -- in all copies or substantial portions of the Software.                   --
22 --                                                                          --
23 -- THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  --
24 -- OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               --
25 -- MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   --
26 -- IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   --
27 -- DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    --
28 -- OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    --
29 -- THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               --
30 --                                                                          --
31 -- Except as contained in this notice, the name(s) of the above copyright   --
32 -- holders shall not be used in advertising or otherwise to promote the     --
33 -- sale, use or other dealings in this Software without prior written       --
34 -- authorization.                                                           --
35 ------------------------------------------------------------------------------
36 --  Author:  Juergen Pfeifer, 1996
37 --  Version Control:
38 --  $Revision: 1.10 $
39 --  Binding Version 01.00
40 ------------------------------------------------------------------------------
41 with Ada.Unchecked_Conversion;
42 with Interfaces.C;
43 with Terminal_Interface.Curses.Aux; use Terminal_Interface.Curses.Aux;
44
45 package body Terminal_Interface.Curses.Forms.Field_Types.User is
46
47    use type Interfaces.C.int;
48
49    procedure Set_Field_Type (Fld : in Field;
50                              Typ : in User_Defined_Field_Type)
51    is
52       function Allocate_Arg (T : User_Defined_Field_Type'Class)
53                              return Argument_Access;
54
55       function Set_Fld_Type (F    : Field := Fld;
56                              Cft  : C_Field_Type := C_Generic_Type;
57                              Arg1 : Argument_Access)
58                              return C_Int;
59       pragma Import (C, Set_Fld_Type, "set_field_type");
60
61       Res : Eti_Error;
62
63       function Allocate_Arg (T : User_Defined_Field_Type'Class)
64                              return Argument_Access
65       is
66          Ptr : Field_Type_Access := new User_Defined_Field_Type'Class'(T);
67       begin
68          return new Argument'(Usr => System.Null_Address,
69                               Typ => Ptr,
70                               Cft => Null_Field_Type);
71       end Allocate_Arg;
72
73    begin
74       Res := Set_Fld_Type (Arg1 => Allocate_Arg (Typ));
75       if Res /= E_Ok then
76          Eti_Exception (Res);
77       end if;
78    end Set_Field_Type;
79
80    function To_Argument_Access is new Ada.Unchecked_Conversion
81      (System.Address, Argument_Access);
82
83    function Generic_Field_Check (Fld : Field;
84                                  Usr : System.Address) return C_Int
85    is
86       Result : Boolean;
87       Udf    : User_Defined_Field_Type_Access :=
88         User_Defined_Field_Type_Access (To_Argument_Access (Usr).Typ);
89    begin
90       Result := Field_Check (Fld, Udf.all);
91       return C_Int (Boolean'Pos (Result));
92    end Generic_Field_Check;
93
94    function Generic_Char_Check (Ch  : C_Int;
95                                 Usr : System.Address) return C_Int
96    is
97       Result : Boolean;
98       Udf    : User_Defined_Field_Type_Access :=
99         User_Defined_Field_Type_Access (To_Argument_Access (Usr).Typ);
100    begin
101       Result := Character_Check (Character'Val (Ch), Udf.all);
102       return C_Int (Boolean'Pos (Result));
103    end Generic_Char_Check;
104
105    --  -----------------------------------------------------------------------
106    --
107    function C_Generic_Type return C_Field_Type
108    is
109       Res : Eti_Error;
110       T   : C_Field_Type;
111    begin
112       if M_Generic_Type = Null_Field_Type then
113          T := New_Fieldtype (Generic_Field_Check'Access,
114                              Generic_Char_Check'Access);
115          if T = Null_Field_Type then
116             raise Form_Exception;
117          else
118             Res := Set_Fieldtype_Arg (T,
119                                       Make_Arg'Access,
120                                       Copy_Arg'Access,
121                                       Free_Arg'Access);
122             if Res /= E_Ok then
123                Eti_Exception (Res);
124             end if;
125          end if;
126          M_Generic_Type := T;
127       end if;
128       pragma Assert (M_Generic_Type /= Null_Field_Type);
129       return M_Generic_Type;
130    end C_Generic_Type;
131
132 end Terminal_Interface.Curses.Forms.Field_Types.User;