ncurses 6.1 - patch 20180623
[ncurses.git] / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2017,2018 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: aclocal.m4,v 1.839 2018/06/21 00:23:13 tom Exp $
32 dnl Macros used in NCURSES auto-configuration script.
33 dnl
34 dnl These macros are maintained separately from NCURSES.  The copyright on
35 dnl this file applies to the aggregation of macros and does not affect use of
36 dnl these macros in other applications.
37 dnl
38 dnl See https://invisible-island.net/autoconf/ for additional information.
39 dnl
40 dnl ---------------------------------------------------------------------------
41 dnl ---------------------------------------------------------------------------
42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
43 dnl -------------------
44 dnl Inserted as requested by gettext 0.10.40
45 dnl File from /usr/share/aclocal
46 dnl codeset.m4
47 dnl ====================
48 dnl serial AM1
49 dnl
50 dnl From Bruno Haible.
51 AC_DEFUN([AM_LANGINFO_CODESET],
52 [
53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
54         [AC_TRY_LINK([#include <langinfo.h>],
55         [char* cs = nl_langinfo(CODESET);],
56         am_cv_langinfo_codeset=yes,
57         am_cv_langinfo_codeset=no)
58         ])
59         if test $am_cv_langinfo_codeset = yes; then
60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
62         fi
63 ])dnl
64 dnl ---------------------------------------------------------------------------
65 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
66 dnl ---------------
67 dnl Provide configure-script defaults for different ncurses ABIs.
68 AC_DEFUN([CF_ABI_DEFAULTS],[
69 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
70 case x$cf_cv_abi_version in
71 (x[[6789]])
72         cf_dft_ext_colors=yes
73         cf_dft_ext_const=yes
74         cf_dft_ext_mouse=yes
75         cf_dft_ext_putwin=yes
76         cf_dft_ext_spfuncs=yes
77         cf_dft_filter_syms=yes
78         cf_dft_chtype=uint32_t
79         cf_dft_mmask_t=uint32_t
80         cf_dft_interop=yes
81         cf_dft_tparm_arg=intptr_t
82         cf_dft_with_lp64=yes
83         ;;
84 (*)
85         cf_dft_ext_colors=no
86         cf_dft_ext_const=no
87         cf_dft_ext_mouse=no
88         cf_dft_ext_putwin=no
89         cf_dft_ext_spfuncs=no
90         cf_dft_filter_syms=no
91         cf_dft_chtype=auto
92         cf_dft_mmask_t=auto
93         cf_dft_interop=no
94         cf_dft_tparm_arg=long
95         cf_dft_with_lp64=no
96         ;;
97 esac
98 ])dnl
99 dnl ---------------------------------------------------------------------------
100 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
101 dnl ------------------
102 dnl Conditionally generate script according to whether we're using a given autoconf.
103 dnl
104 dnl $1 = version to compare against
105 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
106 dnl $3 = code to use if AC_ACVERSION is older than $1.
107 define([CF_ACVERSION_CHECK],
108 [
109 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
110 ifdef([m4_version_compare],
111 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
112 [CF_ACVERSION_COMPARE(
113 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
114 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
115 dnl ---------------------------------------------------------------------------
116 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
117 dnl --------------------
118 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
119 dnl                      MAJOR2, MINOR2, TERNARY2,
120 dnl                      PRINTABLE2, not FOUND, FOUND)
121 define([CF_ACVERSION_COMPARE],
122 [ifelse(builtin([eval], [$2 < $5]), 1,
123 [ifelse([$8], , ,[$8])],
124 [ifelse([$9], , ,[$9])])])dnl
125 dnl ---------------------------------------------------------------------------
126 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
127 dnl -------------------
128 dnl Construct the list of include-options for the C programs in the Ada95
129 dnl binding.
130 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
131 [
132 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
133 if test "$srcdir" != "."; then
134         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
135 fi
136 if test "$GCC" != yes; then
137         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
138 elif test "$includedir" != "/usr/include"; then
139         if test "$includedir" = '${prefix}/include' ; then
140                 if test x$prefix != x/usr ; then
141                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
142                 fi
143         else
144                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
145         fi
146 fi
147 AC_SUBST(ACPPFLAGS)
148 ])dnl
149 dnl ---------------------------------------------------------------------------
150 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
151 dnl ---------------
152 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
153 AC_DEFUN([CF_ADD_ADAFLAGS],[
154         ADAFLAGS="$ADAFLAGS $1"
155         AC_SUBST(ADAFLAGS)
156 ])dnl
157 dnl ---------------------------------------------------------------------------
158 dnl CF_ADD_CFLAGS version: 13 updated: 2017/02/25 18:57:40
159 dnl -------------
160 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
161 dnl The second parameter if given makes this macro verbose.
162 dnl
163 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
164 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
165 dnl confused by the quotes (which require backslashes to keep them usable).
166 AC_DEFUN([CF_ADD_CFLAGS],
167 [
168 cf_fix_cppflags=no
169 cf_new_cflags=
170 cf_new_cppflags=
171 cf_new_extra_cppflags=
172
173 for cf_add_cflags in $1
174 do
175 case $cf_fix_cppflags in
176 (no)
177         case $cf_add_cflags in
178         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
179                 case $cf_add_cflags in
180                 (-D*)
181                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
182
183                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
184                                 && test -z "${cf_tst_cflags}" \
185                                 && cf_fix_cppflags=yes
186
187                         if test $cf_fix_cppflags = yes ; then
188                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
189                                 continue
190                         elif test "${cf_tst_cflags}" = "\"'" ; then
191                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
192                                 continue
193                         fi
194                         ;;
195                 esac
196                 case "$CPPFLAGS" in
197                 (*$cf_add_cflags)
198                         ;;
199                 (*)
200                         case $cf_add_cflags in
201                         (-D*)
202                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
203                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
204                                 ;;
205                         esac
206                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
207                         ;;
208                 esac
209                 ;;
210         (*)
211                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
212                 ;;
213         esac
214         ;;
215 (yes)
216         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
217
218         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
219
220         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
221                 && test -z "${cf_tst_cflags}" \
222                 && cf_fix_cppflags=no
223         ;;
224 esac
225 done
226
227 if test -n "$cf_new_cflags" ; then
228         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
229         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
230 fi
231
232 if test -n "$cf_new_cppflags" ; then
233         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
234         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
235 fi
236
237 if test -n "$cf_new_extra_cppflags" ; then
238         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
239         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
240 fi
241
242 AC_SUBST(EXTRA_CPPFLAGS)
243
244 ])dnl
245 dnl ---------------------------------------------------------------------------
246 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
247 dnl -------------
248 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
249 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
250 dnl but old versions (and some misinstalled ones) need that.  To make things
251 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
252 dnl the include-path).
253 AC_DEFUN([CF_ADD_INCDIR],
254 [
255 if test -n "$1" ; then
256   for cf_add_incdir in $1
257   do
258         while test $cf_add_incdir != /usr/include
259         do
260           if test -d $cf_add_incdir
261           then
262                 cf_have_incdir=no
263                 if test -n "$CFLAGS$CPPFLAGS" ; then
264                   # a loop is needed to ensure we can add subdirs of existing dirs
265                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
266                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
267                           cf_have_incdir=yes; break
268                         fi
269                   done
270                 fi
271
272                 if test "$cf_have_incdir" = no ; then
273                   if test "$cf_add_incdir" = /usr/local/include ; then
274                         if test "$GCC" = yes
275                         then
276                           cf_save_CPPFLAGS=$CPPFLAGS
277                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
278                           AC_TRY_COMPILE([#include <stdio.h>],
279                                   [printf("Hello")],
280                                   [],
281                                   [cf_have_incdir=yes])
282                           CPPFLAGS=$cf_save_CPPFLAGS
283                         fi
284                   fi
285                 fi
286
287                 if test "$cf_have_incdir" = no ; then
288                   CF_VERBOSE(adding $cf_add_incdir to include-path)
289                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
290
291                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
292                   test "$cf_top_incdir" = "$cf_add_incdir" && break
293                   cf_add_incdir="$cf_top_incdir"
294                 else
295                   break
296                 fi
297           else
298                 break
299           fi
300         done
301   done
302 fi
303 ])dnl
304 dnl ---------------------------------------------------------------------------
305 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
306 dnl ----------
307 dnl Add a library, used to enforce consistency.
308 dnl
309 dnl $1 = library to add, without the "-l"
310 dnl $2 = variable to update (default $LIBS)
311 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
312 dnl ---------------------------------------------------------------------------
313 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
314 dnl -------------
315 dnl     Adds to the library-path
316 dnl
317 dnl     Some machines have trouble with multiple -L options.
318 dnl
319 dnl $1 is the (list of) directory(s) to add
320 dnl $2 is the optional name of the variable to update (default LDFLAGS)
321 dnl
322 AC_DEFUN([CF_ADD_LIBDIR],
323 [
324 if test -n "$1" ; then
325         for cf_add_libdir in $1
326         do
327                 if test $cf_add_libdir = /usr/lib ; then
328                         :
329                 elif test -d $cf_add_libdir
330                 then
331                         cf_have_libdir=no
332                         if test -n "$LDFLAGS$LIBS" ; then
333                                 # a loop is needed to ensure we can add subdirs of existing dirs
334                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
335                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
336                                                 cf_have_libdir=yes; break
337                                         fi
338                                 done
339                         fi
340                         if test "$cf_have_libdir" = no ; then
341                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
342                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
343                         fi
344                 fi
345         done
346 fi
347 ])dnl
348 dnl ---------------------------------------------------------------------------
349 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
350 dnl -----------
351 dnl Add one or more libraries, used to enforce consistency.  Libraries are
352 dnl prepended to an existing list, since their dependencies are assumed to
353 dnl already exist in the list.
354 dnl
355 dnl $1 = libraries to add, with the "-l", etc.
356 dnl $2 = variable to update (default $LIBS)
357 AC_DEFUN([CF_ADD_LIBS],[
358 cf_add_libs="$1"
359 # Filter out duplicates - this happens with badly-designed ".pc" files...
360 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
361 do
362         for cf_add_2lib in $cf_add_libs
363         do
364                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
365                 then
366                         cf_add_1lib=
367                         break
368                 fi
369         done
370         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
371 done
372 ifelse($2,,LIBS,[$2])="$cf_add_libs"
373 ])dnl
374 dnl ---------------------------------------------------------------------------
375 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
376 dnl ------------------
377 dnl Append to a search-list for a nonstandard header/lib-file
378 dnl     $1 = the variable to return as result
379 dnl     $2 = the package name
380 dnl     $3 = the subdirectory, e.g., bin, include or lib
381 dnl $4 = the directory under which we will test for subdirectories
382 dnl $5 = a directory that we do not want $4 to match
383 AC_DEFUN([CF_ADD_SUBDIR_PATH],
384 [
385 test "x$4" != "x$5" && \
386 test -d "$4" && \
387 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
388         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
389         test -d $4/$3 &&          $1="[$]$1 $4/$3"
390         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
391         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
392         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
393         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
394 }
395 ])dnl
396 dnl ---------------------------------------------------------------------------
397 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
398 dnl --------------
399 dnl use this macro for appending text without introducing an extra blank at
400 dnl the beginning
401 define([CF_APPEND_TEXT],
402 [
403         test -n "[$]$1" && $1="[$]$1 "
404         $1="[$]{$1}$2"
405 ])dnl
406 dnl ---------------------------------------------------------------------------
407 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
408 dnl --------------
409 dnl Allow user to disable a normally-on option.
410 AC_DEFUN([CF_ARG_DISABLE],
411 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
412 dnl ---------------------------------------------------------------------------
413 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
414 dnl -------------
415 dnl Allow user to enable a normally-off option.
416 AC_DEFUN([CF_ARG_ENABLE],
417 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
418 dnl ---------------------------------------------------------------------------
419 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
420 dnl -------------
421 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
422 dnl values.
423 dnl
424 dnl Parameters:
425 dnl $1 = option name
426 dnl $2 = help-string
427 dnl $3 = action to perform if option is not default
428 dnl $4 = action if perform if option is default
429 dnl $5 = default option value (either 'yes' or 'no')
430 AC_DEFUN([CF_ARG_OPTION],
431 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
432         if test "$enableval" != "$5" ; then
433 ifelse([$3],,[    :]dnl
434 ,[    $3]) ifelse([$4],,,[
435         else
436                 $4])
437         fi],[enableval=$5 ifelse([$4],,,[
438         $4
439 ])dnl
440 ])])dnl
441 dnl ---------------------------------------------------------------------------
442 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
443 dnl -----------
444 dnl Check for suitable "ar" (archiver) options for updating an archive.
445 dnl
446 dnl In particular, handle some obsolete cases where the "-" might be omitted,
447 dnl as well as a workaround for breakage of make's archive rules by the GNU
448 dnl binutils "ar" program.
449 AC_DEFUN([CF_AR_FLAGS],[
450 AC_REQUIRE([CF_PROG_AR])
451
452 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
453         cf_cv_ar_flags=unknown
454         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
455         do
456
457                 # check if $ARFLAGS already contains this choice
458                 if test "x$ARFLAGS" != "x" ; then
459                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
460                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
461                                 cf_cv_ar_flags=
462                                 break
463                         fi
464                 fi
465
466                 rm -f conftest.$ac_cv_objext
467                 rm -f conftest.a
468
469                 cat >conftest.$ac_ext <<EOF
470 #line __oline__ "configure"
471 int     testdata[[3]] = { 123, 456, 789 };
472 EOF
473                 if AC_TRY_EVAL(ac_compile) ; then
474                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
475                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
476                         if test -f conftest.a ; then
477                                 cf_cv_ar_flags=$cf_ar_flags
478                                 break
479                         fi
480                 else
481                         CF_VERBOSE(cannot compile test-program)
482                         break
483                 fi
484         done
485         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
486 ])
487
488 if test -n "$ARFLAGS" ; then
489         if test -n "$cf_cv_ar_flags" ; then
490                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
491         fi
492 else
493         ARFLAGS=$cf_cv_ar_flags
494 fi
495
496 AC_SUBST(ARFLAGS)
497 ])
498 dnl ---------------------------------------------------------------------------
499 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
500 dnl -----------------
501 dnl Check if awk can handle big strings using printf.  Some older versions of
502 dnl awk choke on large strings passed via "%s".
503 dnl
504 dnl $1 = desired string size
505 dnl $2 = variable to set with result
506 AC_DEFUN([CF_AWK_BIG_PRINTF],
507 [
508         case x$AWK in
509         (x)
510                 eval $2=no
511                 ;;
512         (*)
513                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
514                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
515                         eval $2=yes
516                 else
517                         eval $2=no
518                 fi
519                 ;;
520         esac
521 ])dnl
522 dnl ---------------------------------------------------------------------------
523 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
524 dnl ------------
525 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
526 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
527 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
528 dnl
529 dnl Treat the configuration-variable specially here, since we're directly
530 dnl substituting its value (i.e., 1/0).
531 dnl
532 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
533 AC_DEFUN([CF_BOOL_DECL],
534 [
535 AC_MSG_CHECKING(if we should include stdbool.h)
536
537 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
538         AC_TRY_COMPILE([],[bool foo = false],
539                 [cf_cv_header_stdbool_h=0],
540                 [AC_TRY_COMPILE([
541 #ifndef __BEOS__
542 #include <stdbool.h>
543 #endif
544 ],[bool foo = false],
545                         [cf_cv_header_stdbool_h=1],
546                         [cf_cv_header_stdbool_h=0])])])
547
548 if test "$cf_cv_header_stdbool_h" = 1
549 then    AC_MSG_RESULT(yes)
550 else    AC_MSG_RESULT(no)
551 fi
552
553 AC_MSG_CHECKING([for builtin bool type])
554
555 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
556         AC_TRY_COMPILE([
557 #include <stdio.h>
558 #include <sys/types.h>
559 ],[bool x = false],
560                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
561                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
562         ])
563
564 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
565 then    AC_MSG_RESULT(yes)
566 else    AC_MSG_RESULT(no)
567 fi
568 ])dnl
569 dnl ---------------------------------------------------------------------------
570 dnl CF_BOOL_SIZE version: 15 updated: 2017/01/21 11:06:25
571 dnl ------------
572 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
573 dnl Don't bother looking for bool.h, since it's been deprecated.
574 dnl
575 dnl If the current compiler is C rather than C++, we get the bool definition
576 dnl from <stdbool.h>.
577 AC_DEFUN([CF_BOOL_SIZE],
578 [
579 AC_MSG_CHECKING([for size of bool])
580 AC_CACHE_VAL(cf_cv_type_of_bool,[
581         rm -f cf_test.out
582         AC_TRY_RUN([
583 #include <stdlib.h>
584 #include <stdio.h>
585
586 #if defined(__cplusplus)
587
588 #ifdef HAVE_GXX_BUILTIN_H
589 #include <g++/builtin.h>
590 #elif HAVE_GPP_BUILTIN_H
591 #include <gpp/builtin.h>
592 #elif HAVE_BUILTIN_H
593 #include <builtin.h>
594 #endif
595
596 #else
597
598 #if $cf_cv_header_stdbool_h
599 #include <stdbool.h>
600 #endif
601
602 #endif
603
604 int main(void)
605 {
606         FILE *fp = fopen("cf_test.out", "w");
607         if (fp != 0) {
608                 bool x = true;
609                 if ((bool)(-x) >= 0)
610                         fputs("unsigned ", fp);
611                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
612                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
613                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
614                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
615                 fclose(fp);
616         }
617         ${cf_cv_main_return:-return}(0);
618 }
619                 ],
620                 [cf_cv_type_of_bool=`cat cf_test.out`
621                  if test -z "$cf_cv_type_of_bool"; then
622                    cf_cv_type_of_bool=unknown
623                  fi],
624                 [cf_cv_type_of_bool=unknown],
625                 [cf_cv_type_of_bool=unknown])
626         ])
627         rm -f cf_test.out
628 AC_MSG_RESULT($cf_cv_type_of_bool)
629 if test "$cf_cv_type_of_bool" = unknown ; then
630         case .$NCURSES_BOOL in
631         (.auto|.) NCURSES_BOOL=unsigned;;
632         esac
633         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
634         cf_cv_type_of_bool=$NCURSES_BOOL
635 fi
636 ])dnl
637 dnl ---------------------------------------------------------------------------
638 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
639 dnl -----------
640 dnl If we're cross-compiling, allow the user to override the tools and their
641 dnl options.  The configure script is oriented toward identifying the host
642 dnl compiler, etc., but we need a build compiler to generate parts of the
643 dnl source.
644 dnl
645 dnl $1 = default for $CPPFLAGS
646 dnl $2 = default for $LIBS
647 AC_DEFUN([CF_BUILD_CC],[
648 CF_ACVERSION_CHECK(2.52,,
649         [AC_REQUIRE([CF_PROG_EXT])])
650 if test "$cross_compiling" = yes ; then
651
652         # defaults that we might want to override
653         : ${BUILD_CFLAGS:=''}
654         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
655         : ${BUILD_LDFLAGS:=''}
656         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
657         : ${BUILD_EXEEXT:='$x'}
658         : ${BUILD_OBJEXT:='o'}
659
660         AC_ARG_WITH(build-cc,
661                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
662                 [BUILD_CC="$withval"],
663                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
664         AC_MSG_CHECKING(for native build C compiler)
665         AC_MSG_RESULT($BUILD_CC)
666
667         AC_MSG_CHECKING(for native build C preprocessor)
668         AC_ARG_WITH(build-cpp,
669                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
670                 [BUILD_CPP="$withval"],
671                 [BUILD_CPP='${BUILD_CC} -E'])
672         AC_MSG_RESULT($BUILD_CPP)
673
674         AC_MSG_CHECKING(for native build C flags)
675         AC_ARG_WITH(build-cflags,
676                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
677                 [BUILD_CFLAGS="$withval"])
678         AC_MSG_RESULT($BUILD_CFLAGS)
679
680         AC_MSG_CHECKING(for native build C preprocessor-flags)
681         AC_ARG_WITH(build-cppflags,
682                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
683                 [BUILD_CPPFLAGS="$withval"])
684         AC_MSG_RESULT($BUILD_CPPFLAGS)
685
686         AC_MSG_CHECKING(for native build linker-flags)
687         AC_ARG_WITH(build-ldflags,
688                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
689                 [BUILD_LDFLAGS="$withval"])
690         AC_MSG_RESULT($BUILD_LDFLAGS)
691
692         AC_MSG_CHECKING(for native build linker-libraries)
693         AC_ARG_WITH(build-libs,
694                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
695                 [BUILD_LIBS="$withval"])
696         AC_MSG_RESULT($BUILD_LIBS)
697
698         # this assumes we're on Unix.
699         BUILD_EXEEXT=
700         BUILD_OBJEXT=o
701
702         : ${BUILD_CC:='${CC}'}
703
704         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
705                 AC_MSG_ERROR([Cross-build requires two compilers.
706 Use --with-build-cc to specify the native compiler.])
707         fi
708
709 else
710         : ${BUILD_CC:='${CC}'}
711         : ${BUILD_CPP:='${CPP}'}
712         : ${BUILD_CFLAGS:='${CFLAGS}'}
713         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
714         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
715         : ${BUILD_LIBS:='${LIBS}'}
716         : ${BUILD_EXEEXT:='$x'}
717         : ${BUILD_OBJEXT:='o'}
718 fi
719
720 AC_SUBST(BUILD_CC)
721 AC_SUBST(BUILD_CPP)
722 AC_SUBST(BUILD_CFLAGS)
723 AC_SUBST(BUILD_CPPFLAGS)
724 AC_SUBST(BUILD_LDFLAGS)
725 AC_SUBST(BUILD_LIBS)
726 AC_SUBST(BUILD_EXEEXT)
727 AC_SUBST(BUILD_OBJEXT)
728 ])dnl
729 dnl ---------------------------------------------------------------------------
730 dnl CF_CC_ENV_FLAGS version: 8 updated: 2017/09/23 08:50:24
731 dnl ---------------
732 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
733 dnl into CC.  This will not help with broken scripts that wrap the compiler
734 dnl with options, but eliminates a more common category of user confusion.
735 dnl
736 dnl In particular, it addresses the problem of being able to run the C
737 dnl preprocessor in a consistent manner.
738 dnl
739 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
740 dnl the nuisance of having inconsistent settings for compiler and preprocessor
741 dnl outweighs that limitation.
742 AC_DEFUN([CF_CC_ENV_FLAGS],
743 [
744 # This should have been defined by AC_PROG_CC
745 : ${CC:=cc}
746
747 AC_MSG_CHECKING(\$CC variable)
748 case "$CC" in
749 (*[[\ \ ]]-*)
750         AC_MSG_RESULT(broken)
751         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
752         # humor him...
753         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
754         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
755         CC="$cf_prog"
756         for cf_arg in $cf_flags
757         do
758                 case "x$cf_arg" in
759                 (x-[[IUDfgOW]]*)
760                         CF_ADD_CFLAGS($cf_arg)
761                         ;;
762                 (*)
763                         CC="$CC $cf_arg"
764                         ;;
765                 esac
766         done
767         CF_VERBOSE(resulting CC: '$CC')
768         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
769         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
770         ;;
771 (*)
772         AC_MSG_RESULT(ok)
773         ;;
774 esac
775 ])dnl
776 dnl ---------------------------------------------------------------------------
777 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
778 dnl ---------------
779 dnl Determine the default configuration into which we'll install ncurses.  This
780 dnl can be overridden by the user's command-line options.  There's two items to
781 dnl look for:
782 dnl     1. the prefix (e.g., /usr)
783 dnl     2. the header files (e.g., /usr/include/ncurses)
784 dnl We'll look for a previous installation of ncurses and use the same defaults.
785 dnl
786 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
787 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
788 dnl programs from a vendor's.
789 AC_DEFUN([CF_CFG_DEFAULTS],
790 [
791 AC_MSG_CHECKING(for prefix)
792 if test "x$prefix" = "xNONE" ; then
793         case "$cf_cv_system_name" in
794                 # non-vendor systems don't have a conflict
795         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
796                 prefix=/usr
797                 ;;
798         (*)     prefix=$ac_default_prefix
799                 ;;
800         esac
801 fi
802 AC_MSG_RESULT($prefix)
803
804 if test "x$prefix" = "xNONE" ; then
805 AC_MSG_CHECKING(for default include-directory)
806 test -n "$verbose" && echo 1>&AC_FD_MSG
807 for cf_symbol in \
808         $includedir \
809         $includedir/ncurses \
810         $prefix/include \
811         $prefix/include/ncurses \
812         /usr/local/include \
813         /usr/local/include/ncurses \
814         /usr/include \
815         /usr/include/ncurses
816 do
817         cf_dir=`eval echo $cf_symbol`
818         if test -f $cf_dir/curses.h ; then
819         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
820                 includedir="$cf_symbol"
821                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
822                 break
823         fi
824         fi
825         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
826 done
827 AC_MSG_RESULT($includedir)
828 fi
829 ])dnl
830 dnl ---------------------------------------------------------------------------
831 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
832 dnl ----------
833 dnl Check if the terminal-capability database functions are available.  If not,
834 dnl ncurses has a much-reduced version.
835 AC_DEFUN([CF_CGETENT],[
836 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
837 AC_TRY_LINK([
838 #include <stdlib.h>],[
839         char temp[128];
840         char *buf = temp;
841         char *db_array = temp;
842         cgetent(&buf, &db_array, "vt100");
843         cgetcap(buf, "tc", '=');
844         cgetmatch(buf, "tc");
845         ],
846         [cf_cv_cgetent=yes],
847         [cf_cv_cgetent=no])
848 ])
849
850 if test "$cf_cv_cgetent" = yes
851 then
852         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
853 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
854 AC_TRY_LINK([
855 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
856 #include <stdlib.h>],[
857         char temp[128];
858         char *buf = temp;
859 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
860         const char *db_array = temp;
861         cgetent(&buf, &db_array, "vt100");
862 #endif
863         cgetcap(buf, "tc", '=');
864         cgetmatch(buf, "tc");
865         ],
866         [cf_cv_cgetent_const=yes],
867         [cf_cv_cgetent_const=no])
868 ])
869         if test "$cf_cv_cgetent_const" = yes
870         then
871                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
872         fi
873 fi
874 ])dnl
875 dnl ---------------------------------------------------------------------------
876 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
877 dnl --------------
878 dnl Check if we're accidentally using a cache from a different machine.
879 dnl Derive the system name, as a check for reusing the autoconf cache.
880 dnl
881 dnl If we've packaged config.guess and config.sub, run that (since it does a
882 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
883 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
884 dnl which is useful in cross-compiles.
885 dnl
886 dnl Note: we would use $ac_config_sub, but that is one of the places where
887 dnl autoconf 2.5x broke compatibility with autoconf 2.13
888 AC_DEFUN([CF_CHECK_CACHE],
889 [
890 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
891         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
892         system_name="$host_os"
893 else
894         system_name="`(uname -s -r) 2>/dev/null`"
895         if test -z "$system_name" ; then
896                 system_name="`(hostname) 2>/dev/null`"
897         fi
898 fi
899 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
900 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
901
902 test -z "$system_name" && system_name="$cf_cv_system_name"
903 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
904
905 if test ".$system_name" != ".$cf_cv_system_name" ; then
906         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
907         AC_MSG_ERROR("Please remove config.cache and try again.")
908 fi
909 ])dnl
910 dnl ---------------------------------------------------------------------------
911 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
912 dnl --------------
913 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
914 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
915 dnl ourselves.
916 dnl
917 dnl $1 = the name to check
918 dnl $2 = the assumed type
919 AC_DEFUN([CF_CHECK_ERRNO],
920 [
921 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
922         AC_TRY_COMPILE([
923 #ifdef HAVE_STDLIB_H
924 #include <stdlib.h>
925 #endif
926 #include <stdio.h>
927 #include <sys/types.h>
928 #include <errno.h> ],
929         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
930         [cf_cv_dcl_$1=yes],
931         [cf_cv_dcl_$1=no])
932 ])
933
934 if test "$cf_cv_dcl_$1" = no ; then
935         CF_UPPER(cf_result,decl_$1)
936         AC_DEFINE_UNQUOTED($cf_result)
937 fi
938
939 # It's possible (for near-UNIX clones) that the data doesn't exist
940 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
941 ])dnl
942 dnl ---------------------------------------------------------------------------
943 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
944 dnl --------------------
945 dnl Check for existence of external data in the current set of libraries.  If
946 dnl we can modify it, it's real enough.
947 dnl $1 = the name to check
948 dnl $2 = its type
949 AC_DEFUN([CF_CHECK_EXTERN_DATA],
950 [
951 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
952         AC_TRY_LINK([
953 #undef $1
954 extern $2 $1;
955 ],
956         [$1 = 2],
957         [cf_cv_have_$1=yes],
958         [cf_cv_have_$1=no])
959 ])
960
961 if test "$cf_cv_have_$1" = yes ; then
962         CF_UPPER(cf_result,have_$1)
963         AC_DEFINE_UNQUOTED($cf_result)
964 fi
965
966 ])dnl
967 dnl ---------------------------------------------------------------------------
968 dnl CF_CHECK_GPM_WGETCH version: 3 updated: 2017/01/21 11:06:25
969 dnl -------------------
970 dnl Check if GPM is already linked with curses.  If so - and if the linkage
971 dnl is not "weak" - warn about this because it can create problems linking
972 dnl applications with ncurses.
973 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
974 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
975
976 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
977 cf_cv_check_gpm_wgetch=unknown
978 if test "$cross_compiling" != yes ; then
979
980 cat >conftest.$ac_ext <<CF_EOF
981 #include <gpm.h>
982 int main(void)
983 {
984         Gpm_Wgetch();
985         ${cf_cv_main_return:-return}(0);
986 }
987 CF_EOF
988
989         cf_save_LIBS="$LIBS"
990         # This only works if we can look at the symbol table.  If a shared
991         # library is stripped for install, we cannot use that.  So we're forced
992         # to rely on the static library, noting that some packagers may not
993         # include it.
994         LIBS="-static -lgpm -dynamic $LIBS"
995         if AC_TRY_EVAL(ac_compile) ; then
996                 if AC_TRY_EVAL(ac_link) ; then
997                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
998                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
999                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1000                 fi
1001         fi
1002         rm -rf conftest*
1003         LIBS="$cf_save_LIBS"
1004 fi
1005 ])
1006
1007 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1008         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1009 fi
1010 ])])dnl
1011 dnl ---------------------------------------------------------------------------
1012 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
1013 dnl ------------------------
1014 dnl Show the version of libtool
1015 dnl
1016 dnl Save the version in a cache variable - this is not entirely a good thing,
1017 dnl but the version string from libtool is very ugly, and for bug reports it
1018 dnl might be useful to have the original string.
1019 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1020 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1021 then
1022         AC_MSG_CHECKING(version of $LIBTOOL)
1023         CF_LIBTOOL_VERSION
1024         AC_MSG_RESULT($cf_cv_libtool_version)
1025         if test -z "$cf_cv_libtool_version" ; then
1026                 AC_MSG_ERROR(This is not GNU libtool)
1027         fi
1028 else
1029         AC_MSG_ERROR(GNU libtool has not been found)
1030 fi
1031 ])dnl
1032 dnl ---------------------------------------------------------------------------
1033 dnl CF_CHECK_WCHAR_H version: 2 updated: 2017/01/21 11:06:25
1034 dnl ----------------
1035 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1036 AC_DEFUN([CF_CHECK_WCHAR_H],[
1037 AC_CHECK_HEADERS( \
1038 wchar.h \
1039 wctype.h \
1040 )
1041 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1042 AC_TRY_COMPILE(
1043 [
1044 #include <stdlib.h>
1045 #ifdef HAVE_WCHAR_H
1046 #include <wchar.h>
1047 #endif
1048 #ifdef HAVE_WCTYPE_H
1049 #include <wctype.h>
1050 #endif
1051 ],[
1052         wint_t foo = 0;
1053         int bar = iswpunct(foo)],
1054         [cf_cv_wchar_h_okay=yes],
1055         [cf_cv_wchar_h_okay=no])])
1056
1057 if test $cf_cv_wchar_h_okay = no
1058 then
1059         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1060 fi
1061 ])dnl
1062 dnl ---------------------------------------------------------------------------
1063 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1064 dnl -------------------------
1065 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1066 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1067 dnl
1068 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1069 dnl all of those were combined into a page of useful graphics characters.
1070 dnl
1071 dnl So far, so good.
1072 dnl
1073 dnl However, while they are useful, there are other considerations.  CJK
1074 dnl is (because of poor device resolution) often rendered as double-width
1075 dnl characters.  So... for these generally-useful characters, what should
1076 dnl be the width (to make them consistent with adjacent characters)?
1077 dnl
1078 dnl The obvious choice would have been to make this locale-dependent, and use
1079 dnl wcwidth() to tell applications what the actual width is.  That was too
1080 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1081 dnl See for example
1082 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1083 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1084 dnl
1085 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1086 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1087 dnl instance, it lists half (44/96) of the Latin-1 characters as
1088 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1089 dnl
1090 dnl What this means for the implementor is that on some systems wcwidth() can
1091 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1092 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1093 dnl characters).  These do not necessarily match the behavior of the terminal
1094 dnl emulator.  xterm, for instance, does an optional startup check to find if
1095 dnl this problem (or similar) exists with the system's locale tables, rejecting
1096 dnl them if they are too unreliable.
1097 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1098 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1099 cat >conftest.in <<CF_EOF
1100 -       VT100 symbols
1101 0x250c  upper left corner
1102 0x2514  lower left corner
1103 0x2510  upper right corner
1104 0x2518  lower right corner
1105 0x251c  tee pointing left
1106 0x2524  tee pointing right
1107 0x2534  tee pointing up
1108 0x252c  tee pointing down
1109 0x2500  horizontal line
1110 0x2502  vertical line
1111 0x253c  large plus or crossover
1112 0x23ba  scan line 1
1113 0x23bd  scan line 9
1114 0x25c6  diamond
1115 0x2592  checker board (stipple)
1116 0x00b0  degree symbol
1117 0x00b1  plus/minus
1118 0x00b7  bullet
1119 -       Teletype 5410v1 symbols
1120 0x2190  arrow pointing left
1121 0x2192  arrow pointing right
1122 0x2193  arrow pointing down
1123 0x2191  arrow pointing up
1124 0x2592  board of squares
1125 0x2603  lantern symbol
1126 0x25ae  solid square block
1127 -       these defaults were invented for ncurses
1128 0x23bb  scan line 3
1129 0x23bc  scan line 7
1130 0x2264  less-than-or-equal-to
1131 0x2265  greater-than-or-equal-to
1132 0x03c0  greek pi
1133 0x2260  not-equal
1134 0x00a3  pound-sterling symbol
1135 -       thick-line-drawing
1136 0x250f  upper left corner
1137 0x2517  lower left corner
1138 0x2513  upper right corner
1139 0x251b  lower right corner
1140 0x2523  tee pointing left
1141 0x252b  tee pointing right
1142 0x253b  tee pointing up
1143 0x2533  tee pointing down
1144 0x2501  horizontal line
1145 0x2503  vertical line
1146 0x254b  large plus or crossover
1147 -       double-line-drawing
1148 0x2554  upper left corner
1149 0x255a  lower left corner
1150 0x2557  upper right corner
1151 0x255d  lower right corner
1152 0x2563  tee pointing left
1153 0x2560  tee pointing right
1154 0x2569  tee pointing up
1155 0x2566  tee pointing down
1156 0x2550  horizontal line
1157 0x2551  vertical line
1158 0x256c  large plus or crossover
1159 CF_EOF
1160 AC_TRY_RUN([
1161 #include <locale.h>
1162 #include <stdio.h>
1163 #include <wchar.h>
1164
1165 #define MY_LEN 80
1166
1167 int
1168 main(void)
1169 {
1170         FILE *fp;
1171         int value;
1172         char buffer[MY_LEN + 1];
1173         char notes[MY_LEN + 1];
1174         int totals = 0;
1175         int passed = 0;
1176
1177         if (setlocale(LC_ALL, "en_US.UTF8") ||
1178                 setlocale(LC_ALL, "en_US.UTF-8") ||
1179                 setlocale(LC_ALL, "en_US.utf8") ||
1180                 setlocale(LC_ALL, "en_US.utf-8")) {
1181                 if ((fp = fopen("conftest.in", "r")) != 0) {
1182                         while (fgets(buffer, MY_LEN, fp) != 0) {
1183                                 if (*buffer == '-') {
1184                                         fprintf(stderr, "\t%s", buffer);
1185                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1186                                         ++totals;
1187                                         if (wcwidth(value) == 1)
1188                                                 ++passed;
1189                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1190                                 } else {
1191                                         fprintf(stderr, "?\t%s", buffer);
1192                                 }
1193                         }
1194                 }
1195         }
1196         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1197         return (totals == passed) ? 0 : 1;
1198 }
1199 ],
1200 [cf_cv_wcwidth_graphics=yes],
1201 [cf_cv_wcwidth_graphics=no],
1202 [cf_cv_wcwidth_graphics=unknown])
1203 ])
1204 ])dnl
1205 dnl ---------------------------------------------------------------------------
1206 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1207 dnl -----------------
1208 dnl Check if the given compiler is really clang.  clang's C driver defines
1209 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1210 dnl not ignore some gcc options.
1211 dnl
1212 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1213 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1214 dnl the wrappers for gcc and g++ warnings.
1215 dnl
1216 dnl $1 = GCC (default) or GXX
1217 dnl $2 = CLANG_COMPILER (default)
1218 dnl $3 = CFLAGS (default) or CXXFLAGS
1219 AC_DEFUN([CF_CLANG_COMPILER],[
1220 ifelse([$2],,CLANG_COMPILER,[$2])=no
1221
1222 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1223         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1224         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1225         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1226         AC_TRY_COMPILE([],[
1227 #ifdef __clang__
1228 #else
1229 make an error
1230 #endif
1231 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1232 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1233 ],[])
1234         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1235         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1236 fi
1237 ])
1238 dnl ---------------------------------------------------------------------------
1239 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1240 dnl -----------------
1241 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1242 dnl is a late feature for the standard and is not in some recent compilers
1243 dnl (1999/9/11).
1244 AC_DEFUN([CF_CPP_PARAM_INIT],
1245 [
1246 if test -n "$CXX"; then
1247 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1248         AC_LANG_SAVE
1249         AC_LANG_CPLUSPLUS
1250         AC_TRY_RUN([
1251 class TEST {
1252 private:
1253         int value;
1254 public:
1255         TEST(int x = 1);
1256         ~TEST();
1257 };
1258
1259 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1260 {
1261         value = x;
1262 }
1263 int main(void) { }
1264 ],
1265         [cf_cv_cpp_param_init=yes],
1266         [cf_cv_cpp_param_init=no],
1267         [cf_cv_cpp_param_init=unknown])
1268         AC_LANG_RESTORE
1269 ])
1270 fi
1271 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1272 ])dnl
1273 dnl ---------------------------------------------------------------------------
1274 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1275 dnl ------------------
1276 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1277 dnl not be supported in g++ before 3.0
1278 AC_DEFUN([CF_CPP_STATIC_CAST],
1279 [
1280 if test -n "$CXX"; then
1281
1282 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1283         AC_LANG_SAVE
1284         AC_LANG_CPLUSPLUS
1285
1286         AC_TRY_COMPILE([
1287 class NCursesPanel
1288 {
1289 public:
1290   NCursesPanel(int nlines,
1291                int ncols,
1292                int begin_y = 0,
1293                int begin_x = 0)
1294   {
1295   }
1296   NCursesPanel();
1297   ~NCursesPanel();
1298 };
1299
1300 template<class T> class NCursesUserPanel : public NCursesPanel
1301 {
1302 public:
1303   NCursesUserPanel (int nlines,
1304                     int ncols,
1305                     int begin_y = 0,
1306                     int begin_x = 0,
1307                     const T* p_UserData = static_cast<T*>(0))
1308     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1309   {
1310   };
1311   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1312   {
1313   };
1314
1315   virtual ~NCursesUserPanel() {};
1316 };
1317 ],[
1318         const char* p_UserData = static_cast<char*>(0)],
1319         [cf_cv_cpp_static_cast=yes],
1320         [cf_cv_cpp_static_cast=no])
1321
1322         AC_LANG_RESTORE
1323 ])
1324
1325 fi
1326
1327 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1328 ])dnl
1329 dnl ---------------------------------------------------------------------------
1330 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1331 dnl ---------------
1332 dnl Setup special archiver flags for given compilers.
1333 AC_DEFUN([CF_CXX_AR_FLAGS],[
1334         CXX_AR='$(AR)'
1335         CXX_ARFLAGS='$(ARFLAGS)'
1336         case $cf_cv_system_name in
1337         (irix*)
1338             if test "$GXX" != yes ; then
1339                 CXX_AR='$(CXX)'
1340                 CXX_ARFLAGS='-ar -o'
1341             fi
1342             ;;
1343         (sco3.2v5*)
1344             CXXLDFLAGS="-u main"
1345             ;;
1346         (solaris2*)
1347             if test "$GXX" != yes ; then
1348                 CXX_AR='$(CXX)'
1349                 CXX_ARFLAGS='-xar -o'
1350             fi
1351             ;;
1352         esac
1353         AC_SUBST(CXXLDFLAGS)
1354         AC_SUBST(CXX_AR)
1355         AC_SUBST(CXX_ARFLAGS)
1356 ])dnl
1357 dnl ---------------------------------------------------------------------------
1358 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1359 dnl -------------------------
1360 dnl For c++, check if iostream uses "std::" namespace.
1361 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1362 AC_CHECK_HEADERS(iostream)
1363 if test x"$ac_cv_header_iostream" = xyes ; then
1364         AC_MSG_CHECKING(if iostream uses std-namespace)
1365         AC_TRY_COMPILE([
1366 #include <iostream>
1367 using std::endl;
1368 using std::cerr;],[
1369 cerr << "testing" << endl;
1370 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1371         AC_MSG_RESULT($cf_iostream_namespace)
1372         if test "$cf_iostream_namespace" = yes ; then
1373                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1374         fi
1375 fi
1376 ])dnl
1377 dnl ---------------------------------------------------------------------------
1378 dnl CF_C_INLINE version: 5 updated: 2015/04/18 08:56:57
1379 dnl -----------
1380 dnl Check if the C compiler supports "inline".
1381 dnl $1 is the name of a shell variable to set if inline is supported
1382 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1383 AC_DEFUN([CF_C_INLINE],[
1384 AC_C_INLINE
1385 $1=
1386 if test "$ac_cv_c_inline" != no ; then
1387         $1=inline
1388         if test "$INTEL_COMPILER" = yes
1389         then
1390                 :
1391         elif test "$CLANG_COMPILER" = yes
1392         then
1393                 :
1394         elif test "$GCC" = yes
1395         then
1396                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1397                 cf_save_CFLAGS=$CFLAGS
1398                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1399                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1400                 [${cf_cv_main_return:-return} foo()],
1401                 [cf_cv_gcc_inline=yes],
1402                 [cf_cv_gcc_inline=no])
1403                 CFLAGS=$cf_save_CFLAGS
1404                 ])
1405                 if test "$cf_cv_gcc_inline" = yes ; then
1406                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1407                 fi
1408         fi
1409 fi
1410 AC_SUBST($1)
1411 ])dnl
1412 dnl ---------------------------------------------------------------------------
1413 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1414 dnl ----------
1415 dnl "dirname" is not portable, so we fake it with a shell script.
1416 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1417 dnl ---------------------------------------------------------------------------
1418 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1419 dnl ---------------
1420 AC_DEFUN([CF_DIRS_TO_MAKE],
1421 [
1422 DIRS_TO_MAKE="lib"
1423 for cf_item in $cf_list_models
1424 do
1425         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1426         for cf_item2 in $DIRS_TO_MAKE
1427         do
1428                 test $cf_item2 = $cf_subdir && break
1429         done
1430         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1431 done
1432 for cf_dir in $DIRS_TO_MAKE
1433 do
1434         test ! -d $cf_dir && mkdir $cf_dir
1435 done
1436 AC_SUBST(DIRS_TO_MAKE)
1437 ])dnl
1438 dnl ---------------------------------------------------------------------------
1439 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1440 dnl ---------------
1441 dnl You can always use "make -n" to see the actual options, but it's hard to
1442 dnl pick out/analyze warning messages when the compile-line is long.
1443 dnl
1444 dnl Sets:
1445 dnl     ECHO_LT - symbol to control if libtool is verbose
1446 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1447 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1448 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1449 dnl     ECHO_CC - symbol to put before any "cc" line
1450 dnl
1451 AC_DEFUN([CF_DISABLE_ECHO],[
1452 AC_MSG_CHECKING(if you want to see long compiling messages)
1453 CF_ARG_DISABLE(echo,
1454         [  --disable-echo          do not display "compiling" commands],
1455         [
1456         ECHO_LT='--silent'
1457         ECHO_LD='@echo linking [$]@;'
1458         RULE_CC='@echo compiling [$]<'
1459         SHOW_CC='@echo compiling [$]@'
1460         ECHO_CC='@'
1461 ],[
1462         ECHO_LT=''
1463         ECHO_LD=''
1464         RULE_CC=''
1465         SHOW_CC=''
1466         ECHO_CC=''
1467 ])
1468 AC_MSG_RESULT($enableval)
1469 AC_SUBST(ECHO_LT)
1470 AC_SUBST(ECHO_LD)
1471 AC_SUBST(RULE_CC)
1472 AC_SUBST(SHOW_CC)
1473 AC_SUBST(ECHO_CC)
1474 ])dnl
1475 dnl ---------------------------------------------------------------------------
1476 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1477 dnl ------------------------
1478 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1479 AC_MSG_CHECKING(if we want to use GNAT projects)
1480 CF_ARG_DISABLE(gnat-projects,
1481         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1482         [enable_gnat_projects=no],
1483         [enable_gnat_projects=yes])
1484 AC_MSG_RESULT($enable_gnat_projects)
1485 ])dnl
1486 dnl ---------------------------------------------------------------------------
1487 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1488 dnl ----------------
1489 dnl Combine no-leak checks with the libraries or tools that are used for the
1490 dnl checks.
1491 AC_DEFUN([CF_DISABLE_LEAKS],[
1492
1493 AC_REQUIRE([CF_WITH_DMALLOC])
1494 AC_REQUIRE([CF_WITH_DBMALLOC])
1495 AC_REQUIRE([CF_WITH_VALGRIND])
1496
1497 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1498 AC_ARG_ENABLE(leaks,
1499         [  --disable-leaks         test: free permanent memory, analyze leaks],
1500         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1501         : ${with_no_leaks:=no})
1502 AC_MSG_RESULT($with_no_leaks)
1503
1504 if test "$with_no_leaks" = yes ; then
1505         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1506         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1507 fi
1508 ])dnl
1509 dnl ---------------------------------------------------------------------------
1510 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1511 dnl --------------------------
1512 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1513 dnl the older "-version-info" feature.  The newer feature allows us to use
1514 dnl version numbering on shared libraries which make them compatible with
1515 dnl various systems.
1516 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1517 [
1518 AC_MSG_CHECKING(if libtool -version-number should be used)
1519 CF_ARG_DISABLE(libtool-version,
1520         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1521         [cf_libtool_version=no],
1522         [cf_libtool_version=yes])
1523 AC_MSG_RESULT($cf_libtool_version)
1524
1525 if test "$cf_libtool_version" = yes ; then
1526         LIBTOOL_VERSION="-version-number"
1527 else
1528         LIBTOOL_VERSION="-version-info"
1529         case "x$VERSION" in
1530         (x)
1531                 AC_MSG_WARN(VERSION was not set)
1532                 ;;
1533         (x*.*.*)
1534                 ABI_VERSION="$VERSION"
1535                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1536                 ;;
1537         (x*:*:*)
1538                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1539                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1540                 ;;
1541         (*)
1542                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1543                 ;;
1544         esac
1545 fi
1546
1547 AC_SUBST(ABI_VERSION)
1548 AC_SUBST(LIBTOOL_VERSION)
1549 ])dnl
1550 dnl ---------------------------------------------------------------------------
1551 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1552 dnl ---------------------
1553 dnl The rpath-hack makes it simpler to build programs, particularly with the
1554 dnl *BSD ports which may have essential libraries in unusual places.  But it
1555 dnl can interfere with building an executable for the base system.  Use this
1556 dnl option in that case.
1557 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1558 [
1559 AC_MSG_CHECKING(if rpath-hack should be disabled)
1560 CF_ARG_DISABLE(rpath-hack,
1561         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1562         [cf_disable_rpath_hack=yes],
1563         [cf_disable_rpath_hack=no])
1564 AC_MSG_RESULT($cf_disable_rpath_hack)
1565 if test "$cf_disable_rpath_hack" = no ; then
1566         CF_RPATH_HACK
1567 fi
1568 ])
1569 dnl ---------------------------------------------------------------------------
1570 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1571 dnl ------------------
1572 dnl This is the "--enable-pc-files" option, which is available if there is a
1573 dnl pkg-config configuration on the local machine.
1574 AC_DEFUN([CF_ENABLE_PC_FILES],[
1575 AC_REQUIRE([CF_PKG_CONFIG])
1576 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1577
1578 if test "x$PKG_CONFIG" != xnone
1579 then
1580         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1581 else
1582         AC_MSG_CHECKING(if we should install .pc files)
1583 fi
1584
1585 AC_ARG_ENABLE(pc-files,
1586         [  --enable-pc-files       generate and install .pc files for pkg-config],
1587         [enable_pc_files=$enableval],
1588         [enable_pc_files=no])
1589 AC_MSG_RESULT($enable_pc_files)
1590
1591 if test "x$enable_pc_files" != xno
1592 then
1593         MAKE_PC_FILES=
1594         case "x$PKG_CONFIG_LIBDIR" in
1595         (xno|xyes)
1596                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1597                 ;;
1598         (*)
1599                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1600                 ;;
1601         esac
1602 else
1603         MAKE_PC_FILES="#"
1604 fi
1605 AC_SUBST(MAKE_PC_FILES)
1606 ])dnl
1607 dnl ---------------------------------------------------------------------------
1608 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1609 dnl ---------------
1610 dnl Check if the rpath option should be used, setting cache variable
1611 dnl cf_cv_enable_rpath if so.
1612 AC_DEFUN([CF_ENABLE_RPATH],
1613 [
1614 AC_MSG_CHECKING(if rpath option should be used)
1615 AC_ARG_ENABLE(rpath,
1616 [  --enable-rpath          use rpath option when generating shared libraries],
1617 [cf_cv_enable_rpath=$enableval],
1618 [cf_cv_enable_rpath=no])
1619 AC_MSG_RESULT($cf_cv_enable_rpath)
1620 ])dnl
1621 dnl ---------------------------------------------------------------------------
1622 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
1623 dnl ----------------------
1624 dnl On a few platforms, the compiler and/or loader nags with untruthful
1625 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1626 dnl and implying that most uses of the recommended alternatives are correct.
1627 dnl
1628 dnl Factually speaking, no one has actually counted the number of uses of these
1629 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1630 dnl instances are meaningless compared to the hundreds of millions of lines of
1631 dnl existing C code.
1632 dnl
1633 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1634 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1635 dnl standard - but evolved through phases, and older implementations are likely
1636 dnl to yield surprising results, as documented in manpages on various systems.
1637 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1638 [
1639 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1640 AC_ARG_ENABLE(string-hacks,
1641         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1642         [with_string_hacks=$enableval],
1643         [with_string_hacks=no])
1644 AC_MSG_RESULT($with_string_hacks)
1645
1646 if test "x$with_string_hacks" = "xyes"; then
1647         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1648         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1649         AC_CHECK_FUNC(strlcat,[
1650                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1651                 ],[
1652                 AC_CHECK_LIB(bsd,strlcat,[
1653                         CF_ADD_LIB(bsd)
1654                         AC_CHECK_HEADERS(bsd/string.h)
1655                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1656                         ])
1657                 ])
1658         AC_CHECK_FUNCS( strlcpy snprintf )
1659 fi
1660 ])dnl
1661 dnl ---------------------------------------------------------------------------
1662 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1663 dnl --------
1664 dnl Check if 'errno' is declared in <errno.h>
1665 AC_DEFUN([CF_ERRNO],
1666 [
1667 CF_CHECK_ERRNO(errno)
1668 ])dnl
1669 dnl ---------------------------------------------------------------------------
1670 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1671 dnl ---------------
1672 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1673 dnl math.h and builtin.h, only for ncurses
1674 AC_DEFUN([CF_ETIP_DEFINES],
1675 [
1676 AC_MSG_CHECKING(for special defines needed for etip.h)
1677 cf_save_CXXFLAGS="$CXXFLAGS"
1678 cf_result="none"
1679
1680 # etip.h includes ncurses.h which includes ncurses_dll.h
1681 # But ncurses_dll.h is generated - fix here.
1682 test -d include || mkdir include
1683 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1684
1685 for cf_math in "" MATH_H
1686 do
1687 for cf_excp in "" MATH_EXCEPTION
1688 do
1689         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1690         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1691         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1692 AC_TRY_COMPILE([
1693 #include <etip.h.in>
1694 ],[],[
1695         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1696         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1697         cf_result="$cf_math $cf_excp"
1698         break 2
1699 ],[])
1700 done
1701 done
1702 AC_MSG_RESULT($cf_result)
1703 CXXFLAGS="$cf_save_CXXFLAGS"
1704 ])
1705 dnl ---------------------------------------------------------------------------
1706 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
1707 dnl ---------------
1708 dnl Find a library (specifically the linkage used in the code fragment),
1709 dnl searching for it if it is not already in the library path.
1710 dnl See also CF_ADD_SEARCHPATH.
1711 dnl
1712 dnl Parameters (4-on are optional):
1713 dnl     $1 = headers for library entrypoint
1714 dnl     $2 = code fragment for library entrypoint
1715 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1716 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1717 dnl     $5 = action to perform if not successful
1718 dnl     $6 = module name, if not the same as the library name
1719 dnl     $7 = extra libraries
1720 dnl
1721 dnl Sets these variables:
1722 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1723 dnl     $cf_cv_header_path_$3 - include-directory if needed
1724 dnl     $cf_cv_library_path_$3 - library-directory if needed
1725 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1726 AC_DEFUN([CF_FIND_LINKAGE],[
1727
1728 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1729 # will be set on completion of the AC_TRY_LINK below.
1730 cf_cv_header_path_$3=
1731 cf_cv_library_path_$3=
1732
1733 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1734
1735 cf_save_LIBS="$LIBS"
1736
1737 AC_TRY_LINK([$1],[$2],[
1738         cf_cv_find_linkage_$3=yes
1739         cf_cv_header_path_$3=/usr/include
1740         cf_cv_library_path_$3=/usr/lib
1741 ],[
1742
1743 LIBS="-l$3 $7 $cf_save_LIBS"
1744
1745 AC_TRY_LINK([$1],[$2],[
1746         cf_cv_find_linkage_$3=yes
1747         cf_cv_header_path_$3=/usr/include
1748         cf_cv_library_path_$3=/usr/lib
1749         cf_cv_library_file_$3="-l$3"
1750 ],[
1751         cf_cv_find_linkage_$3=no
1752         LIBS="$cf_save_LIBS"
1753
1754         CF_VERBOSE(find linkage for $3 library)
1755         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1756
1757         cf_save_CPPFLAGS="$CPPFLAGS"
1758         cf_test_CPPFLAGS="$CPPFLAGS"
1759
1760         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1761         for cf_cv_header_path_$3 in $cf_search
1762         do
1763                 if test -d $cf_cv_header_path_$3 ; then
1764                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1765                         CPPFLAGS="$cf_save_CPPFLAGS"
1766                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1767                         AC_TRY_COMPILE([$1],[$2],[
1768                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1769                                 cf_cv_find_linkage_$3=maybe
1770                                 cf_test_CPPFLAGS="$CPPFLAGS"
1771                                 break],[
1772                                 CPPFLAGS="$cf_save_CPPFLAGS"
1773                                 ])
1774                 fi
1775         done
1776
1777         if test "$cf_cv_find_linkage_$3" = maybe ; then
1778
1779                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1780
1781                 cf_save_LIBS="$LIBS"
1782                 cf_save_LDFLAGS="$LDFLAGS"
1783
1784                 ifelse([$6],,,[
1785                 CPPFLAGS="$cf_test_CPPFLAGS"
1786                 LIBS="-l$3 $7 $cf_save_LIBS"
1787                 AC_TRY_LINK([$1],[$2],[
1788                         CF_VERBOSE(... found $3 library in system)
1789                         cf_cv_find_linkage_$3=yes])
1790                         CPPFLAGS="$cf_save_CPPFLAGS"
1791                         LIBS="$cf_save_LIBS"
1792                         ])
1793
1794                 if test "$cf_cv_find_linkage_$3" != yes ; then
1795                         CF_LIBRARY_PATH(cf_search,$3)
1796                         for cf_cv_library_path_$3 in $cf_search
1797                         do
1798                                 if test -d $cf_cv_library_path_$3 ; then
1799                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1800                                         CPPFLAGS="$cf_test_CPPFLAGS"
1801                                         LIBS="-l$3 $7 $cf_save_LIBS"
1802                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1803                                         AC_TRY_LINK([$1],[$2],[
1804                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1805                                         cf_cv_find_linkage_$3=yes
1806                                         cf_cv_library_file_$3="-l$3"
1807                                         break],[
1808                                         CPPFLAGS="$cf_save_CPPFLAGS"
1809                                         LIBS="$cf_save_LIBS"
1810                                         LDFLAGS="$cf_save_LDFLAGS"
1811                                         ])
1812                                 fi
1813                         done
1814                         CPPFLAGS="$cf_save_CPPFLAGS"
1815                         LDFLAGS="$cf_save_LDFLAGS"
1816                 fi
1817
1818         else
1819                 cf_cv_find_linkage_$3=no
1820         fi
1821         ],$7)
1822 ])
1823
1824 LIBS="$cf_save_LIBS"
1825
1826 if test "$cf_cv_find_linkage_$3" = yes ; then
1827 ifelse([$4],,[
1828         CF_ADD_INCDIR($cf_cv_header_path_$3)
1829         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1830         CF_ADD_LIB($3)
1831 ],[$4])
1832 else
1833 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1834 fi
1835 ])dnl
1836 dnl ---------------------------------------------------------------------------
1837 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
1838 dnl ------------------
1839 dnl Find an include-directory with the given leaf-name.  This is useful for
1840 dnl example with FreeBSD ports, which use this convention to distinguish
1841 dnl different versions of the same port.
1842 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1843         CF_SUBDIR_PATH(cf_search,$1,include)
1844         for cf_item in $cf_search
1845         do
1846                 case $cf_item in
1847                 (*/$1)
1848                         CF_ADD_INCDIR($cf_item)
1849                         ;;
1850                 esac
1851         done
1852 ])dnl
1853 dnl ---------------------------------------------------------------------------
1854 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
1855 dnl ------------------
1856 dnl Find a library-directory with the given leaf-name.  This is useful for
1857 dnl example with FreeBSD ports, which use this convention to distinguish
1858 dnl different versions of the same port.
1859 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1860         CF_SUBDIR_PATH(cf_search,$1,lib)
1861         for cf_item in $cf_search
1862         do
1863                 case $cf_item in
1864                 (*/$1)
1865                         CF_ADD_LIBDIR($cf_item)
1866                         ;;
1867                 esac
1868         done
1869 ])dnl
1870 dnl ---------------------------------------------------------------------------
1871 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1872 dnl -----------------
1873 dnl make ADAFLAGS consistent with CFLAGS
1874 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1875         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1876         case "$CFLAGS" in
1877         (*-g*)
1878                 CF_ADD_ADAFLAGS(-g)
1879                 ;;
1880         esac
1881         case "$CFLAGS" in
1882         (*-O*)
1883                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1884                 CF_ADD_ADAFLAGS($cf_O_flag)
1885                 ;;
1886         esac
1887         AC_MSG_RESULT($ADAFLAGS)
1888 ])dnl
1889 dnl ---------------------------------------------------------------------------
1890 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1891 dnl --------------
1892 dnl Forget that we saw the given tool.
1893 AC_DEFUN([CF_FORGET_TOOL],[
1894 unset ac_cv_prog_ac_ct_$1
1895 unset ac_ct_$1
1896 unset $1
1897 ])dnl
1898 dnl ---------------------------------------------------------------------------
1899 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
1900 dnl -------------
1901 dnl Test for dlsym() and related functions, as well as libdl.
1902 dnl
1903 dnl Sets
1904 dnl     $cf_have_dlsym
1905 dnl     $cf_have_libdl
1906 AC_DEFUN([CF_FUNC_DLSYM],[
1907 cf_have_dlsym=no
1908 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1909
1910 cf_have_libdl=no
1911 AC_CHECK_LIB(dl,dlsym,[
1912         cf_have_dlsym=yes
1913         cf_have_libdl=yes])])
1914
1915 if test "$cf_have_dlsym" = yes ; then
1916         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
1917
1918         AC_MSG_CHECKING(whether able to link to dl*() functions)
1919         AC_TRY_LINK([#include <dlfcn.h>],[
1920                 void *obj;
1921                 if ((obj = dlopen("filename", 0)) != 0) {
1922                         if (dlsym(obj, "symbolname") == 0) {
1923                         dlclose(obj);
1924                         }
1925                 }],[
1926                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1927                 AC_MSG_ERROR(Cannot link test program for libdl)])
1928         AC_MSG_RESULT(ok)
1929 else
1930         AC_MSG_ERROR(Cannot find dlsym function)
1931 fi
1932 ])
1933 dnl ---------------------------------------------------------------------------
1934 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
1935 dnl ---------------
1936 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1937 dnl is found, add our own version of memmove to the list of objects.
1938 AC_DEFUN([CF_FUNC_MEMMOVE],
1939 [
1940 AC_CHECK_FUNC(memmove,,[
1941 AC_CHECK_FUNC(bcopy,[
1942         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1943                 AC_TRY_RUN([
1944 int main(void) {
1945         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1946         char temp[40];
1947         bcopy(data, temp, sizeof(data));
1948         bcopy(temp+10, temp, 15);
1949         bcopy(temp+5, temp+15, 10);
1950         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1951 }
1952                 ],
1953                 [cf_cv_good_bcopy=yes],
1954                 [cf_cv_good_bcopy=no],
1955                 [cf_cv_good_bcopy=unknown])
1956                 ])
1957         ],[cf_cv_good_bcopy=no])
1958         if test "$cf_cv_good_bcopy" = yes ; then
1959                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1960         else
1961                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1962         fi
1963 ])])dnl
1964 dnl ---------------------------------------------------------------------------
1965 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
1966 dnl -----------------
1967 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1968 dnl AIX 4.x, provide a non-working version.
1969 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1970 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1971 AC_TRY_RUN([
1972 #include <stdio.h>
1973 #include <errno.h>
1974 #include <time.h>
1975
1976 #ifdef HAVE_SYS_TIME_H
1977 #include <sys/time.h>
1978 #endif
1979
1980 int main(void) {
1981         struct timespec ts1, ts2;
1982         int code;
1983         ts1.tv_sec  = 0;
1984         ts1.tv_nsec = 750000000;
1985         ts2.tv_sec  = 0;
1986         ts2.tv_nsec = 0;
1987         errno = 0;
1988         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1989         ${cf_cv_main_return:-return}(code != 0);
1990 }
1991 ],
1992         [cf_cv_func_nanosleep=yes],
1993         [cf_cv_func_nanosleep=no],
1994         [cf_cv_func_nanosleep=unknown])])
1995
1996 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1997 ])
1998 dnl ---------------------------------------------------------------------------
1999 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
2000 dnl ---------------
2001 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2002 dnl "util" library as well.
2003 AC_DEFUN([CF_FUNC_OPENPTY],
2004 [
2005 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2006 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2007         cf_save_LIBS="$LIBS"
2008         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
2009         for cf_header in pty.h libutil.h util.h
2010         do
2011         AC_TRY_LINK([
2012 #include <$cf_header>
2013 ],[
2014         int x = openpty((int *)0, (int *)0, (char *)0,
2015                                    (struct termios *)0, (struct winsize *)0);
2016 ],[
2017                 cf_cv_func_openpty=$cf_header
2018                 break
2019 ],[
2020                 cf_cv_func_openpty=no
2021 ])
2022         done
2023         LIBS="$cf_save_LIBS"
2024 ])
2025 ])dnl
2026 dnl ---------------------------------------------------------------------------
2027 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
2028 dnl ------------
2029 dnl See if the poll function really works.  Some platforms have poll(), but
2030 dnl it does not work for terminals or files.
2031 AC_DEFUN([CF_FUNC_POLL],[
2032 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
2033 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2034 AC_TRY_RUN([
2035 #include <stdlib.h>
2036 #include <stdio.h>
2037 #include <unistd.h>
2038 #include <fcntl.h>
2039 #ifdef HAVE_POLL_H
2040 #include <poll.h>
2041 #else
2042 #include <sys/poll.h>
2043 #endif
2044 int main(void) {
2045         struct pollfd myfds;
2046         int ret;
2047
2048         /* check for Darwin bug with respect to "devices" */
2049         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2050         if (myfds.fd < 0)
2051                 myfds.fd = 0;
2052         myfds.events = POLLIN;
2053         myfds.revents = 0;
2054
2055         ret = poll(&myfds, 1, 100);
2056
2057         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2058                 ret = -1;
2059         } else {
2060                 int fd = 0;
2061                 if (!isatty(fd)) {
2062                         fd = open("/dev/tty", 2);       /* O_RDWR */
2063                 }
2064 #ifdef HAVE_POSIX_OPENPT
2065                 if (fd < 0) {
2066                         fd = posix_openpt(O_RDWR);
2067                 }
2068 #endif
2069
2070                 if (fd >= 0) {
2071                         /* also check with standard input */
2072                         myfds.fd = fd;
2073                         myfds.events = POLLIN;
2074                         myfds.revents = 0;
2075                         ret = poll(&myfds, 1, 100);
2076                 } else {
2077                         ret = -1;
2078                 }
2079         }
2080         ${cf_cv_main_return:-return}(ret < 0);
2081 }],
2082         [cf_cv_working_poll=yes],
2083         [cf_cv_working_poll=no],
2084         [cf_cv_working_poll=unknown])])
2085 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2086 ])dnl
2087 dnl ---------------------------------------------------------------------------
2088 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2089 dnl ---------------
2090 dnl Some old/broken variations define tcgetattr() only as a macro in
2091 dnl termio(s).h
2092 AC_DEFUN([CF_FUNC_TERMIOS],[
2093 AC_REQUIRE([CF_STRUCT_TERMIOS])
2094 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2095 AC_TRY_LINK([
2096 #include <sys/types.h>
2097 #ifdef HAVE_UNISTD_H
2098 #include <unistd.h>
2099 #endif
2100 #ifdef HAVE_TERMIOS_H
2101 #include <termios.h>
2102 #define TTY struct termios
2103 #else
2104 #ifdef HAVE_TERMIO_H
2105 #include <termio.h>
2106 #define TTY struct termio
2107 #endif
2108 #endif
2109 ],[
2110 TTY foo;
2111 tcgetattr(1, &foo);],
2112 [cf_cv_have_tcgetattr=yes],
2113 [cf_cv_have_tcgetattr=no])])
2114 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2115 ])dnl
2116 dnl ---------------------------------------------------------------------------
2117 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2118 dnl ---------------
2119 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2120 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2121 dnl other functions.
2122 AC_DEFUN([CF_FUNC_VSSCANF],
2123 [
2124 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2125 AC_TRY_LINK([
2126 #include <stdarg.h>
2127 #include <stdio.h>],[
2128         va_list ap;
2129         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2130 AC_TRY_LINK([
2131 #include <stdarg.h>
2132 #include <stdio.h>],[
2133         FILE strbuf;
2134         char *str = "from";
2135
2136         strbuf._flag = _IOREAD;
2137         strbuf._ptr = strbuf._base = (unsigned char *) str;
2138         strbuf._cnt = strlen(str);
2139         strbuf._file = _NFILE;
2140         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2141 AC_TRY_LINK([
2142 #include <stdarg.h>
2143 #include <stdio.h>],[
2144         FILE strbuf;
2145         char *str = "from";
2146
2147         strbuf._flag = _IOREAD;
2148         strbuf._ptr = strbuf._base = (unsigned char *) str;
2149         strbuf._cnt = strlen(str);
2150         strbuf._file = _NFILE;
2151         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2152 cf_cv_func_vsscanf=no])])])])
2153
2154 case $cf_cv_func_vsscanf in
2155 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2156 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2157 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2158 esac
2159
2160 ])dnl
2161 dnl ---------------------------------------------------------------------------
2162 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
2163 dnl -----------------
2164 dnl Test for availability of useful gcc __attribute__ directives to quiet
2165 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2166 dnl to documentation, unrecognized directives cause older compilers to barf.
2167 AC_DEFUN([CF_GCC_ATTRIBUTES],
2168 [
2169 if test "$GCC" = yes
2170 then
2171 cat > conftest.i <<EOF
2172 #ifndef GCC_PRINTF
2173 #define GCC_PRINTF 0
2174 #endif
2175 #ifndef GCC_SCANF
2176 #define GCC_SCANF 0
2177 #endif
2178 #ifndef GCC_NORETURN
2179 #define GCC_NORETURN /* nothing */
2180 #endif
2181 #ifndef GCC_UNUSED
2182 #define GCC_UNUSED /* nothing */
2183 #endif
2184 EOF
2185 if test "$GCC" = yes
2186 then
2187         AC_CHECKING([for $CC __attribute__ directives])
2188 cat > conftest.$ac_ext <<EOF
2189 #line __oline__ "${as_me:-configure}"
2190 #include "confdefs.h"
2191 #include "conftest.h"
2192 #include "conftest.i"
2193 #if     GCC_PRINTF
2194 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2195 #else
2196 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2197 #endif
2198 #if     GCC_SCANF
2199 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2200 #else
2201 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2202 #endif
2203 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2204 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2205 extern void foo(void) GCC_NORETURN;
2206 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
2207 EOF
2208         cf_printf_attribute=no
2209         cf_scanf_attribute=no
2210         for cf_attribute in scanf printf unused noreturn
2211         do
2212                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2213                 cf_directive="__attribute__(($cf_attribute))"
2214                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2215
2216                 case $cf_attribute in
2217                 (printf)
2218                         cf_printf_attribute=yes
2219                         cat >conftest.h <<EOF
2220 #define GCC_$cf_ATTRIBUTE 1
2221 EOF
2222                         ;;
2223                 (scanf)
2224                         cf_scanf_attribute=yes
2225                         cat >conftest.h <<EOF
2226 #define GCC_$cf_ATTRIBUTE 1
2227 EOF
2228                         ;;
2229                 (*)
2230                         cat >conftest.h <<EOF
2231 #define GCC_$cf_ATTRIBUTE $cf_directive
2232 EOF
2233                         ;;
2234                 esac
2235
2236                 if AC_TRY_EVAL(ac_compile); then
2237                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2238                         cat conftest.h >>confdefs.h
2239                         case $cf_attribute in
2240                         (noreturn)
2241                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2242                                 ;;
2243                         (printf)
2244                                 cf_value='/* nothing */'
2245                                 if test "$cf_printf_attribute" != no ; then
2246                                         cf_value='__attribute__((format(printf,fmt,var)))'
2247                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2248                                 fi
2249                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2250                                 ;;
2251                         (scanf)
2252                                 cf_value='/* nothing */'
2253                                 if test "$cf_scanf_attribute" != no ; then
2254                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2255                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2256                                 fi
2257                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2258                                 ;;
2259                         (unused)
2260                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2261                                 ;;
2262                         esac
2263                 fi
2264         done
2265 else
2266         fgrep define conftest.i >>confdefs.h
2267 fi
2268 rm -rf conftest*
2269 fi
2270 ])dnl
2271 dnl ---------------------------------------------------------------------------
2272 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2273 dnl --------------
2274 dnl Find version of gcc
2275 AC_DEFUN([CF_GCC_VERSION],[
2276 AC_REQUIRE([AC_PROG_CC])
2277 GCC_VERSION=none
2278 if test "$GCC" = yes ; then
2279         AC_MSG_CHECKING(version of $CC)
2280         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2281         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2282         AC_MSG_RESULT($GCC_VERSION)
2283 fi
2284 ])dnl
2285 dnl ---------------------------------------------------------------------------
2286 dnl CF_GCC_WARNINGS version: 33 updated: 2018/06/20 20:23:13
2287 dnl ---------------
2288 dnl Check if the compiler supports useful warning options.  There's a few that
2289 dnl we don't use, simply because they're too noisy:
2290 dnl
2291 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2292 dnl     -Wredundant-decls (system headers make this too noisy)
2293 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2294 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2295 dnl             is enabled for ncurses using "--enable-const".
2296 dnl     -pedantic
2297 dnl
2298 dnl Parameter:
2299 dnl     $1 is an optional list of gcc warning flags that a particular
2300 dnl             application might want to use, e.g., "no-unused" for
2301 dnl             -Wno-unused
2302 dnl Special:
2303 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2304 dnl
2305 AC_DEFUN([CF_GCC_WARNINGS],
2306 [
2307 AC_REQUIRE([CF_GCC_VERSION])
2308 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2309 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2310
2311 cat > conftest.$ac_ext <<EOF
2312 #line __oline__ "${as_me:-configure}"
2313 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2314 EOF
2315
2316 if test "$INTEL_COMPILER" = yes
2317 then
2318 # The "-wdXXX" options suppress warnings:
2319 # remark #1419: external declaration in primary source file
2320 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2321 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2322 # remark #193: zero used for undefined preprocessing identifier
2323 # remark #593: variable "curs_sb_left_arrow" was set but never used
2324 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2325 # remark #869: parameter "tw" was never referenced
2326 # remark #981: operands are evaluated in unspecified order
2327 # warning #279: controlling expression is constant
2328
2329         AC_CHECKING([for $CC warning options])
2330         cf_save_CFLAGS="$CFLAGS"
2331         EXTRA_CFLAGS="-Wall"
2332         for cf_opt in \
2333                 wd1419 \
2334                 wd1683 \
2335                 wd1684 \
2336                 wd193 \
2337                 wd593 \
2338                 wd279 \
2339                 wd810 \
2340                 wd869 \
2341                 wd981
2342         do
2343                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2344                 if AC_TRY_EVAL(ac_compile); then
2345                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2346                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2347                 fi
2348         done
2349         CFLAGS="$cf_save_CFLAGS"
2350
2351 elif test "$GCC" = yes
2352 then
2353         AC_CHECKING([for $CC warning options])
2354         cf_save_CFLAGS="$CFLAGS"
2355         EXTRA_CFLAGS=
2356         cf_warn_CONST=""
2357         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2358         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2359         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2360         for cf_opt in W Wall \
2361                 Wbad-function-cast \
2362                 Wcast-align \
2363                 Wcast-qual \
2364                 Wdeclaration-after-statement \
2365                 Wextra \
2366                 Winline \
2367                 Wmissing-declarations \
2368                 Wmissing-prototypes \
2369                 Wnested-externs \
2370                 Wpointer-arith \
2371                 Wshadow \
2372                 Wstrict-prototypes \
2373                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2374         do
2375                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2376                 if AC_TRY_EVAL(ac_compile); then
2377                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2378                         case $cf_opt in
2379                         (Wcast-qual)
2380                                 CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
2381                                 ;;
2382                         (Winline)
2383                                 case $GCC_VERSION in
2384                                 ([[34]].*)
2385                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2386                                         continue;;
2387                                 esac
2388                                 ;;
2389                         (Wpointer-arith)
2390                                 case $GCC_VERSION in
2391                                 ([[12]].*)
2392                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2393                                         continue;;
2394                                 esac
2395                                 ;;
2396                         esac
2397                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2398                 fi
2399         done
2400         CFLAGS="$cf_save_CFLAGS"
2401 fi
2402 rm -rf conftest*
2403
2404 AC_SUBST(EXTRA_CFLAGS)
2405 ])dnl
2406 dnl ---------------------------------------------------------------------------
2407 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2408 dnl ----------------
2409 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2410 dnl unistd.h or (nonstandard) in getopt.h
2411 AC_DEFUN([CF_GETOPT_HEADER],
2412 [
2413 AC_HAVE_HEADERS(unistd.h getopt.h)
2414 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2415 cf_cv_getopt_header=none
2416 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2417 do
2418 AC_TRY_COMPILE([
2419 #include <$cf_header>],
2420 [int x = optind; char *y = optarg],
2421 [cf_cv_getopt_header=$cf_header
2422  break])
2423 done
2424 ])
2425 if test $cf_cv_getopt_header != none ; then
2426         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2427 fi
2428 if test $cf_cv_getopt_header = getopt.h ; then
2429         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2430 fi
2431 ])dnl
2432 dnl ---------------------------------------------------------------------------
2433 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2434 dnl -----------------
2435 AC_DEFUN([CF_GNATPREP_OPT_T],[
2436 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2437 cf_cv_gnatprep_opt_t=no
2438 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2439 ])
2440 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2441 AC_SUBST(GNATPREP_OPTS)
2442 ])dnl
2443 dnl ---------------------------------------------------------------------------
2444 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2445 dnl ----------------
2446 AC_DEFUN([CF_GNAT_GENERICS],
2447 [
2448 AC_REQUIRE([CF_GNAT_VERSION])
2449
2450 AC_MSG_CHECKING(if GNAT supports generics)
2451 case $cf_gnat_version in
2452 (3.[[1-9]]*|[[4-9]].*)
2453         cf_gnat_generics=yes
2454         ;;
2455 (*)
2456         cf_gnat_generics=no
2457         ;;
2458 esac
2459 AC_MSG_RESULT($cf_gnat_generics)
2460
2461 if test "$cf_gnat_generics" = yes
2462 then
2463         cf_compile_generics=generics
2464         cf_generic_objects="\${GENOBJS}"
2465 else
2466         cf_compile_generics=
2467         cf_generic_objects=
2468 fi
2469
2470 AC_SUBST(cf_compile_generics)
2471 AC_SUBST(cf_generic_objects)
2472 ])dnl
2473 dnl ---------------------------------------------------------------------------
2474 dnl CF_GNAT_PROJECTS version: 9 updated: 2018/01/14 15:46:09
2475 dnl ----------------
2476 dnl GNAT projects are configured with ".gpr" project files.
2477 dnl GNAT libraries are a further development, using the project feature.
2478 AC_DEFUN([CF_GNAT_PROJECTS],
2479 [
2480 AC_REQUIRE([CF_GNAT_VERSION])
2481 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2482
2483 cf_gnat_libraries=no
2484 cf_gnat_projects=no
2485
2486 if test "$enable_gnat_projects" != no ; then
2487 AC_MSG_CHECKING(if GNAT supports project files)
2488 case $cf_gnat_version in
2489 (3.[[0-9]]*)
2490         ;;
2491 (*)
2492         case $cf_cv_system_name in
2493         (cygwin*|msys*)
2494                 ;;
2495         (*)
2496                 rm -rf conftest* *~conftest*
2497                 if mkdir conftest.src conftest.bin conftest.lib
2498                 then
2499                         cd conftest.src
2500                         rm -rf conftest* *~conftest*
2501                         cat >>library.gpr <<CF_EOF
2502 project Library is
2503   Kind := External ("LIB_KIND");
2504   for Library_Name use "ConfTest";
2505   for Object_Dir use ".";
2506   for Library_ALI_Dir use External("LIBRARY_DIR");
2507   for Library_Version use External ("SONAME");
2508   for Library_Kind use Kind;
2509   for Library_Dir use External("BUILD_DIR");
2510   Source_Dir := External ("SOURCE_DIR");
2511   for Source_Dirs use (Source_Dir);
2512 end Library;
2513 CF_EOF
2514                         cat >>confpackage.ads <<CF_EOF
2515 package ConfPackage is
2516    procedure conftest;
2517 end ConfPackage;
2518 CF_EOF
2519                         cat >>confpackage.adb <<CF_EOF
2520 with Text_IO;
2521 package body ConfPackage is
2522    procedure conftest is
2523    begin
2524       Text_IO.Put ("Hello World");
2525       Text_IO.New_Line;
2526    end conftest;
2527 end ConfPackage;
2528 CF_EOF
2529                         if ( $cf_ada_make $ADAFLAGS \
2530                                         -Plibrary.gpr \
2531                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2532                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2533                                         -XSOURCE_DIR=`pwd` \
2534                                         -XSONAME=libConfTest.so.1 \
2535                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2536                                 cf_gnat_projects=yes
2537                         fi
2538                         cd ..
2539                 fi
2540                 if test -f conftest.lib/confpackage.ali
2541                 then
2542                         cf_gnat_libraries=yes
2543                 fi
2544                 rm -rf conftest* *~conftest*
2545                 ;;
2546         esac
2547         ;;
2548 esac
2549 AC_MSG_RESULT($cf_gnat_projects)
2550 fi # enable_gnat_projects
2551
2552 if test $cf_gnat_projects = yes
2553 then
2554         AC_MSG_CHECKING(if GNAT supports libraries)
2555         AC_MSG_RESULT($cf_gnat_libraries)
2556 fi
2557
2558 if test "$cf_gnat_projects" = yes
2559 then
2560         USE_OLD_MAKERULES="#"
2561         USE_GNAT_PROJECTS=""
2562 else
2563         USE_OLD_MAKERULES=""
2564         USE_GNAT_PROJECTS="#"
2565 fi
2566
2567 if test "$cf_gnat_libraries" = yes
2568 then
2569         USE_GNAT_LIBRARIES=""
2570 else
2571         USE_GNAT_LIBRARIES="#"
2572 fi
2573
2574 AC_SUBST(USE_OLD_MAKERULES)
2575 AC_SUBST(USE_GNAT_PROJECTS)
2576 AC_SUBST(USE_GNAT_LIBRARIES)
2577 ])dnl
2578 dnl ---------------------------------------------------------------------------
2579 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2580 dnl --------------
2581 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2582 dnl is noted that gnat may compile a tasking unit even for configurations which
2583 dnl fail at runtime.
2584 AC_DEFUN([CF_GNAT_SIGINT],[
2585 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2586 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2587
2588 package ConfTest is
2589
2590    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2591    pragma Unreserve_All_Interrupts;
2592    pragma Warnings (On);
2593
2594    protected Process is
2595       procedure Stop;
2596       function Continue return Boolean;
2597       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2598    private
2599       Done : Boolean := False;
2600    end Process;
2601
2602 end ConfTest;],
2603 [package body ConfTest is
2604    protected body Process is
2605       procedure Stop is
2606       begin
2607          Done := True;
2608       end Stop;
2609       function Continue return Boolean is
2610       begin
2611          return not Done;
2612       end Continue;
2613    end Process;
2614 end ConfTest;],
2615         [cf_cv_gnat_sigint=yes],
2616         [cf_cv_gnat_sigint=no])])
2617
2618 if test $cf_cv_gnat_sigint = yes ; then
2619         USE_GNAT_SIGINT=""
2620 else
2621         USE_GNAT_SIGINT="#"
2622 fi
2623 AC_SUBST(USE_GNAT_SIGINT)
2624 ])dnl
2625 dnl ---------------------------------------------------------------------------
2626 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2627 dnl ----------------
2628 dnl Verify that a test program compiles/links with GNAT.
2629 dnl $cf_ada_make is set to the program that compiles/links
2630 dnl $ADAFLAGS may be set to the GNAT flags.
2631 dnl
2632 dnl $1 is the text of the spec
2633 dnl $2 is the text of the body
2634 dnl $3 is the shell command to execute if successful
2635 dnl $4 is the shell command to execute if not successful
2636 AC_DEFUN([CF_GNAT_TRY_LINK],
2637 [
2638 rm -rf conftest* *~conftest*
2639 cat >>conftest.ads <<CF_EOF
2640 $1
2641 CF_EOF
2642 cat >>conftest.adb <<CF_EOF
2643 $2
2644 CF_EOF
2645 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2646 ifelse($3,,      :,[      $3])
2647 ifelse($4,,,[else
2648    $4])
2649 fi
2650 rm -rf conftest* *~conftest*
2651 ])dnl
2652 dnl ---------------------------------------------------------------------------
2653 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2654 dnl ---------------
2655 dnl Verify that a test program compiles and runs with GNAT
2656 dnl $cf_ada_make is set to the program that compiles/links
2657 dnl $ADAFLAGS may be set to the GNAT flags.
2658 dnl
2659 dnl $1 is the text of the spec
2660 dnl $2 is the text of the body
2661 dnl $3 is the shell command to execute if successful
2662 dnl $4 is the shell command to execute if not successful
2663 AC_DEFUN([CF_GNAT_TRY_RUN],
2664 [
2665 rm -rf conftest* *~conftest*
2666 cat >>conftest.ads <<CF_EOF
2667 $1
2668 CF_EOF
2669 cat >>conftest.adb <<CF_EOF
2670 $2
2671 CF_EOF
2672 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2673    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2674 ifelse($3,,      :,[      $3])
2675 ifelse($4,,,[   else
2676       $4])
2677    fi
2678 ifelse($4,,,[else
2679    $4])
2680 fi
2681 rm -rf conftest* *~conftest*
2682 ])dnl
2683 dnl ---------------------------------------------------------------------------
2684 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
2685 dnl ---------------
2686 dnl Verify version of GNAT.
2687 AC_DEFUN([CF_GNAT_VERSION],
2688 [
2689 AC_MSG_CHECKING(for gnat version)
2690 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2691         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2692         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2693 AC_MSG_RESULT($cf_gnat_version)
2694
2695 case $cf_gnat_version in
2696 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
2697         cf_cv_prog_gnat_correct=yes
2698         ;;
2699 (*)
2700         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2701         cf_cv_prog_gnat_correct=no
2702         ;;
2703 esac
2704 ])
2705 dnl ---------------------------------------------------------------------------
2706 dnl CF_GNU_SOURCE version: 9 updated: 2018/06/20 20:23:13
2707 dnl -------------
2708 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2709 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2710 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2711 dnl since it is interwoven with GNU extensions.
2712 dnl
2713 dnl Well, yes we could work around it...
2714 dnl
2715 dnl Parameters:
2716 dnl     $1 is the nominal value for _XOPEN_SOURCE
2717 AC_DEFUN([CF_GNU_SOURCE],
2718 [
2719 cf_gnu_xopen_source=ifelse($1,,500,$1)
2720
2721 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
2722 AC_TRY_COMPILE([#include <sys/types.h>],[
2723         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
2724                 return 0;
2725         #else
2726         #       error not GNU C library
2727         #endif],
2728         [cf_cv_gnu_library=yes],
2729         [cf_cv_gnu_library=no])
2730 ])
2731
2732 if test x$cf_cv_gnu_library = xyes; then
2733
2734         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
2735         # was changed to help a little...
2736         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
2737                 cf_save="$CPPFLAGS"
2738                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2739                 AC_TRY_COMPILE([#include <sys/types.h>],[
2740                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
2741                                 return 0;
2742                         #else
2743                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
2744                         #endif],
2745                         [cf_cv_gnu_library_219=yes],
2746                         [cf_cv_gnu_library_219=no])
2747                 CPPFLAGS="$cf_save"
2748         ])
2749
2750         if test "x$cf_cv_gnu_library_219" = xyes; then
2751                 cf_save="$CPPFLAGS"
2752                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
2753                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
2754                         AC_TRY_COMPILE([
2755                                 #include <limits.h>
2756                                 #include <sys/types.h>
2757                                 ],[
2758                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
2759                                         return 0;
2760                                 #else
2761                                 #       error GNU C library is too old
2762                                 #endif],
2763                                 [cf_cv_gnu_dftsrc_219=yes],
2764                                 [cf_cv_gnu_dftsrc_219=no])
2765                         ])
2766                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
2767         else
2768                 cf_cv_gnu_dftsrc_219=maybe
2769         fi
2770
2771         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
2772
2773                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2774                 AC_TRY_COMPILE([#include <sys/types.h>],[
2775                         #ifndef _XOPEN_SOURCE
2776                         #error  expected _XOPEN_SOURCE to be defined
2777                         #endif],
2778                         [cf_cv_gnu_source=no],
2779                         [cf_save="$CPPFLAGS"
2780                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
2781                          AC_TRY_COMPILE([#include <sys/types.h>],[
2782                                 #ifdef _XOPEN_SOURCE
2783                                 #error  expected _XOPEN_SOURCE to be undefined
2784                                 #endif],
2785                                 [cf_cv_gnu_source=no],
2786                                 [cf_cv_gnu_source=yes])
2787                         CPPFLAGS="$cf_save"
2788                         ])
2789                 ])
2790
2791                 if test "$cf_cv_gnu_source" = yes
2792                 then
2793                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
2794                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
2795                         AC_TRY_COMPILE([#include <sys/types.h>],[
2796                                 #ifdef _DEFAULT_SOURCE
2797                                 #error  expected _DEFAULT_SOURCE to be undefined
2798                                 #endif],
2799                                 [cf_cv_default_source=no],
2800                                 [cf_cv_default_source=yes])
2801                         ])
2802                         if test "$cf_cv_default_source" = yes
2803                         then
2804                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2805                         fi
2806                 fi
2807         fi
2808
2809 fi
2810 ])dnl
2811 dnl ---------------------------------------------------------------------------
2812 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
2813 dnl --------------
2814 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2815 dnl problem :-).  If we have the compiler but no library, we'll be able to
2816 dnl configure, but won't be able to build the c++ demo program.
2817 AC_DEFUN([CF_GPP_LIBRARY],
2818 [
2819 cf_cxx_library=unknown
2820 case $cf_cv_system_name in
2821 (os2*)
2822         cf_gpp_libname=gpp
2823         ;;
2824 (*)
2825         cf_gpp_libname=g++
2826         ;;
2827 esac
2828 if test "$GXX" = yes; then
2829         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2830         cf_save="$LIBS"
2831         CF_ADD_LIB($cf_gpp_libname)
2832         AC_TRY_LINK([
2833 #include <$cf_gpp_libname/builtin.h>
2834         ],
2835         [two_arg_error_handler_t foo2 = lib_error_handler],
2836         [cf_cxx_library=yes
2837          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2838          if test "$cf_gpp_libname" = cpp ; then
2839             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2840          else
2841             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2842          fi],
2843         [AC_TRY_LINK([
2844 #include <builtin.h>
2845         ],
2846         [two_arg_error_handler_t foo2 = lib_error_handler],
2847         [cf_cxx_library=yes
2848          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2849          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2850         [cf_cxx_library=no])])
2851         LIBS="$cf_save"
2852         AC_MSG_RESULT($cf_cxx_library)
2853 fi
2854 ])dnl
2855 dnl ---------------------------------------------------------------------------
2856 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
2857 dnl --------------
2858 dnl Check for version of g++
2859 AC_DEFUN([CF_GXX_VERSION],[
2860 AC_REQUIRE([AC_PROG_CPP])
2861 GXX_VERSION=none
2862 if test "$GXX" = yes; then
2863         AC_MSG_CHECKING(version of ${CXX:-g++})
2864         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2865         if test -z "$GXX_VERSION"
2866         then
2867                 GXX_VERSION=unknown
2868                 GXX=no
2869         fi
2870         AC_MSG_RESULT($GXX_VERSION)
2871 fi
2872 ])dnl
2873 dnl ---------------------------------------------------------------------------
2874 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
2875 dnl ---------------
2876 dnl Check if the compiler supports useful warning options.
2877 dnl
2878 dnl Most of gcc's options apply to g++, except:
2879 dnl     -Wbad-function-cast
2880 dnl     -Wmissing-declarations
2881 dnl     -Wnested-externs
2882 dnl
2883 dnl Omit a few (for now):
2884 dnl     -Winline
2885 dnl
2886 dnl Parameter:
2887 dnl     $1 is an optional list of g++ warning flags that a particular
2888 dnl             application might want to use, e.g., "no-unused" for
2889 dnl             -Wno-unused
2890 dnl Special:
2891 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2892 dnl
2893 AC_DEFUN([CF_GXX_WARNINGS],
2894 [
2895
2896 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2897 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2898
2899 AC_REQUIRE([CF_GXX_VERSION])
2900
2901 AC_LANG_SAVE
2902 AC_LANG_CPLUSPLUS
2903
2904 cat > conftest.$ac_ext <<EOF
2905 #line __oline__ "configure"
2906 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2907 EOF
2908
2909 if test "$INTEL_CPLUSPLUS" = yes
2910 then
2911 # The "-wdXXX" options suppress warnings:
2912 # remark #1419: external declaration in primary source file
2913 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2914 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2915 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2916 # remark #193: zero used for undefined preprocessing identifier
2917 # remark #593: variable "curs_sb_left_arrow" was set but never used
2918 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2919 # remark #869: parameter "tw" was never referenced
2920 # remark #981: operands are evaluated in unspecified order
2921 # warning #269: invalid format string conversion
2922
2923         AC_CHECKING([for $CC warning options])
2924         cf_save_CXXFLAGS="$CXXFLAGS"
2925         EXTRA_CXXFLAGS="-Wall"
2926         for cf_opt in \
2927                 wd1419 \
2928                 wd1682 \
2929                 wd1683 \
2930                 wd1684 \
2931                 wd193 \
2932                 wd279 \
2933                 wd593 \
2934                 wd810 \
2935                 wd869 \
2936                 wd981
2937         do
2938                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2939                 if AC_TRY_EVAL(ac_compile); then
2940                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2941                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2942                 fi
2943         done
2944         CXXFLAGS="$cf_save_CXXFLAGS"
2945
2946 elif test "$GXX" = yes
2947 then
2948         AC_CHECKING([for $CXX warning options])
2949         cf_save_CXXFLAGS="$CXXFLAGS"
2950         EXTRA_CXXFLAGS="-W -Wall"
2951         cf_gxx_extra_warnings=""
2952         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2953         case "$GCC_VERSION" in
2954         ([[1-2]].*)
2955                 ;;
2956         (*)
2957                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2958                 ;;
2959         esac
2960         for cf_opt in \
2961                 Wabi \
2962                 fabi-version=0 \
2963                 Wextra \
2964                 Wignored-qualifiers \
2965                 Wlogical-op \
2966                 Woverloaded-virtual \
2967                 Wsign-promo \
2968                 Wsynth \
2969                 Wold-style-cast \
2970                 Wcast-align \
2971                 Wcast-qual \
2972                 Wpointer-arith \
2973                 Wshadow \
2974                 Wundef $cf_gxx_extra_warnings $1
2975         do
2976                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2977                 if AC_TRY_EVAL(ac_compile); then
2978                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2979                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2980                 else
2981                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2982                 fi
2983         done
2984         CXXFLAGS="$cf_save_CXXFLAGS"
2985 fi
2986
2987 rm -rf conftest*
2988 AC_LANG_RESTORE
2989 AC_SUBST(EXTRA_CXXFLAGS)
2990 ])dnl
2991 dnl ---------------------------------------------------------------------------
2992 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
2993 dnl ------------
2994 dnl Look for an instance of the Berkeley hashed database.
2995 dnl
2996 dnl $1 = optional parameter, to specify install-prefix for the database.
2997 AC_DEFUN([CF_HASHED_DB],
2998 [
2999 ifelse([$1],,,[
3000 case $1 in
3001 (yes|*able*)
3002         ;;
3003 (*)
3004         if test -d "$1" ; then
3005                 CF_ADD_INCDIR($1/include)
3006                 CF_ADD_LIBDIR($1/lib)
3007         else
3008                 case "$1" in
3009                 (./*|../*|/*)
3010                         AC_MSG_WARN(no such directory $1)
3011                         ;;
3012                 (*)
3013                         CF_FIND_SUB_INCDIR($1)
3014                         CF_FIND_SUB_LIBDIR($1)
3015                         ;;
3016                 esac
3017         fi
3018 esac
3019 ])
3020 AC_CHECK_HEADER(db.h,[
3021 CF_HASHED_DB_VERSION
3022 if test "$cf_cv_hashed_db_version" = unknown ; then
3023         AC_MSG_ERROR(Cannot determine version of db)
3024 else
3025         CF_HASHED_DB_LIBS
3026         if test "$cf_cv_hashed_db_libs" = unknown ; then
3027                 AC_MSG_ERROR(Cannot determine library for db)
3028         elif test "$cf_cv_hashed_db_libs" != default ; then
3029                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3030         fi
3031 fi
3032 ],[
3033         AC_MSG_ERROR(Cannot find db.h)
3034 ])
3035 ])dnl
3036 dnl ---------------------------------------------------------------------------
3037 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
3038 dnl -----------------
3039 dnl Given that we have the header and version for hashed database, find the
3040 dnl library information.
3041 AC_DEFUN([CF_HASHED_DB_LIBS],
3042 [
3043 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3044 cf_cv_hashed_db_libs=unknown
3045 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3046 do
3047         cf_save_libs="$LIBS"
3048         if test -n "$cf_db_libs"; then
3049                 CF_ADD_LIB($cf_db_libs)
3050         fi
3051         CF_MSG_LOG(checking for library "$cf_db_libs")
3052         AC_TRY_LINK([
3053 $ac_includes_default
3054 #include <db.h>
3055 ],[
3056         char *path = "/tmp/foo";
3057 #ifdef DB_VERSION_MAJOR
3058 #if DB_VERSION_MAJOR >= 4
3059         DB *result = 0;
3060         db_create(&result, NULL, 0);
3061         result->open(result,
3062                 NULL,
3063                 path,
3064                 path,
3065                 DB_HASH,
3066                 DB_CREATE,
3067                 0644);
3068 #elif DB_VERSION_MAJOR >= 3
3069         DB *result = 0;
3070         db_create(&result, NULL, 0);
3071         result->open(result,
3072                 path,
3073                 path,
3074                 DB_HASH,
3075                 DB_CREATE,
3076                 0644);
3077 #elif DB_VERSION_MAJOR >= 2
3078         DB *result = 0;
3079         db_open(path,
3080                 DB_HASH,
3081                 DB_CREATE,
3082                 0644,
3083                 (DB_ENV *) 0,
3084                 (DB_INFO *) 0,
3085                 &result);
3086 #endif /* DB_VERSION_MAJOR */
3087 #else
3088         DB *result = dbopen(path,
3089                      2,
3090                      0644,
3091                      DB_HASH,
3092                      0);
3093 #endif
3094         ${cf_cv_main_return:-return}(result != 0)
3095 ],[
3096         if test -n "$cf_db_libs" ; then
3097                 cf_cv_hashed_db_libs=$cf_db_libs
3098         else
3099                 cf_cv_hashed_db_libs=default
3100         fi
3101         LIBS="$cf_save_libs"
3102         break
3103 ])
3104         LIBS="$cf_save_libs"
3105 done
3106 ])
3107 ])dnl
3108 dnl ---------------------------------------------------------------------------
3109 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3110 dnl --------------------
3111 dnl Given that we have the header file for hashed database, find the version
3112 dnl information.
3113 AC_DEFUN([CF_HASHED_DB_VERSION],
3114 [
3115 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3116 cf_cv_hashed_db_version=unknown
3117
3118 for cf_db_version in 1 2 3 4 5 6
3119 do
3120         CF_MSG_LOG(checking for db version $cf_db_version)
3121         AC_TRY_COMPILE([
3122 $ac_includes_default
3123 #include <db.h>
3124
3125 #ifdef DB_VERSION_MAJOR
3126         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3127 #if $cf_db_version == DB_VERSION_MAJOR
3128         /* ok */
3129 #else
3130         make an error
3131 #endif
3132 #else
3133 #if $cf_db_version == 1
3134         /* ok: assuming this is DB 1.8.5 */
3135 #else
3136         make an error
3137 #endif
3138 #endif
3139 ],[DBT *foo = 0],[
3140         cf_cv_hashed_db_version=$cf_db_version
3141         break
3142         ])
3143 done
3144 ])
3145 ])dnl
3146 dnl ---------------------------------------------------------------------------
3147 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3148 dnl --------------
3149 dnl Construct a search-list of directories for a nonstandard header-file
3150 dnl
3151 dnl Parameters
3152 dnl     $1 = the variable to return as result
3153 dnl     $2 = the package name
3154 AC_DEFUN([CF_HEADER_PATH],
3155 [
3156 $1=
3157
3158 # collect the current set of include-directories from compiler flags
3159 cf_header_path_list=""
3160 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3161         for cf_header_path in $CPPFLAGS $CFLAGS
3162         do
3163                 case $cf_header_path in
3164                 (-I*)
3165                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3166                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3167                         cf_header_path_list="$cf_header_path_list [$]$1"
3168                         ;;
3169                 esac
3170         done
3171 fi
3172
3173 # add the variations for the package we are looking for
3174 CF_SUBDIR_PATH($1,$2,include)
3175
3176 test "$includedir" != NONE && \
3177 test "$includedir" != "/usr/include" && \
3178 test -d "$includedir" && {
3179         test -d $includedir &&    $1="[$]$1 $includedir"
3180         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3181 }
3182
3183 test "$oldincludedir" != NONE && \
3184 test "$oldincludedir" != "/usr/include" && \
3185 test -d "$oldincludedir" && {
3186         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3187         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3188 }
3189
3190 $1="[$]$1 $cf_header_path_list"
3191 ])dnl
3192 dnl ---------------------------------------------------------------------------
3193 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
3194 dnl ---------------
3195 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3196 AC_DEFUN([CF_HELP_MESSAGE],
3197 [AC_DIVERT_HELP([$1])dnl
3198 ])dnl
3199 dnl ---------------------------------------------------------------------------
3200 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3201 dnl ---------------
3202 dnl Construct the list of include-options according to whether we're building
3203 dnl in the source directory or using '--srcdir=DIR' option.
3204 AC_DEFUN([CF_INCLUDE_DIRS],
3205 [
3206 if test "$srcdir" != "."; then
3207         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3208 fi
3209 CPPFLAGS="-I../include $CPPFLAGS"
3210 if test "$srcdir" != "."; then
3211         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3212 fi
3213 CPPFLAGS="-I. $CPPFLAGS"
3214 AC_SUBST(CPPFLAGS)
3215 ])dnl
3216 dnl ---------------------------------------------------------------------------
3217 dnl CF_INSTALL_OPTS version: 1 updated: 2014/07/21 18:19:51
3218 dnl ---------------
3219 dnl prompt for/fill-in useful install-program options
3220 AC_DEFUN([CF_INSTALL_OPTS],
3221 [
3222 CF_INSTALL_OPT_S
3223 CF_INSTALL_OPT_O
3224 ])dnl
3225 dnl ---------------------------------------------------------------------------
3226 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
3227 dnl ----------------
3228 dnl Almost all "install" programs default to the current user's ownership.
3229 dnl Almost - MINIX is an exception.
3230 AC_DEFUN([CF_INSTALL_OPT_O],
3231 [
3232 AC_MSG_CHECKING(if install needs to be told about ownership)
3233 case `$ac_config_guess` in
3234 (*minix)
3235         with_install_o=yes
3236         ;;
3237 (*)
3238         with_install_o=no
3239         ;;
3240 esac
3241
3242 AC_MSG_RESULT($with_install_o)
3243 if test "x$with_install_o" = xyes
3244 then
3245         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
3246 else
3247         INSTALL_OPT_O=
3248 fi
3249
3250 AC_SUBST(INSTALL_OPT_O)
3251 ])dnl
3252 dnl ---------------------------------------------------------------------------
3253 dnl CF_INSTALL_OPT_S version: 1 updated: 2014/07/21 18:19:51
3254 dnl ----------------
3255 dnl By default, we should strip executables which are installed, but leave the
3256 dnl ability to suppress that for unit-testing.
3257 AC_DEFUN([CF_INSTALL_OPT_S],
3258 [
3259 AC_MSG_CHECKING(if you want to install stripped executables)
3260 CF_ARG_DISABLE(stripping,
3261         [  --disable-stripping     do not strip installed executables],
3262         [with_stripping=no],
3263         [with_stripping=yes])
3264 AC_MSG_RESULT($with_stripping)
3265
3266 if test "$with_stripping" = yes
3267 then
3268         INSTALL_OPT_S="-s"
3269 else
3270         INSTALL_OPT_S=
3271 fi
3272 AC_SUBST(INSTALL_OPT_S)
3273 ])dnl
3274 dnl ---------------------------------------------------------------------------
3275 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3276 dnl -----------------
3277 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3278 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3279 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3280 dnl
3281 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3282 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3283 dnl the wrappers for gcc and g++ warnings.
3284 dnl
3285 dnl $1 = GCC (default) or GXX
3286 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3287 dnl $3 = CFLAGS (default) or CXXFLAGS
3288 AC_DEFUN([CF_INTEL_COMPILER],[
3289 AC_REQUIRE([AC_CANONICAL_HOST])
3290 ifelse([$2],,INTEL_COMPILER,[$2])=no
3291
3292 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3293         case $host_os in
3294         (linux*|gnu*)
3295                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3296                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3297                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3298                 AC_TRY_COMPILE([],[
3299 #ifdef __INTEL_COMPILER
3300 #else
3301 make an error
3302 #endif
3303 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3304 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3305 ],[])
3306                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3307                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3308                 ;;
3309         esac
3310 fi
3311 ])dnl
3312 dnl ---------------------------------------------------------------------------
3313 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3314 dnl ----------
3315 dnl Check if we have either a function or macro for 'isascii()'.
3316 AC_DEFUN([CF_ISASCII],
3317 [
3318 AC_MSG_CHECKING(for isascii)
3319 AC_CACHE_VAL(cf_cv_have_isascii,[
3320         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3321         [cf_cv_have_isascii=yes],
3322         [cf_cv_have_isascii=no])
3323 ])dnl
3324 AC_MSG_RESULT($cf_cv_have_isascii)
3325 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3326 ])dnl
3327 dnl ---------------------------------------------------------------------------
3328 dnl CF_LARGEFILE version: 11 updated: 2018/06/20 20:23:13
3329 dnl ------------
3330 dnl Add checks for large file support.
3331 AC_DEFUN([CF_LARGEFILE],[
3332 ifdef([AC_FUNC_FSEEKO],[
3333         AC_SYS_LARGEFILE
3334         if test "$enable_largefile" != no ; then
3335         AC_FUNC_FSEEKO
3336
3337         # Normally we would collect these definitions in the config.h,
3338         # but (like _XOPEN_SOURCE), some environments rely on having these
3339         # defined before any of the system headers are included.  Another
3340         # case comes up with C++, e.g., on AIX the compiler compiles the
3341         # header files by themselves before looking at the body files it is
3342         # told to compile.  For ncurses, those header files do not include
3343         # the config.h
3344         if test "$ac_cv_sys_large_files" != no
3345         then
3346                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
3347         fi
3348         if test "$ac_cv_sys_largefile_source" != no
3349         then
3350                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
3351         fi
3352         if test "$ac_cv_sys_file_offset_bits" != no
3353         then
3354                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
3355         fi
3356
3357         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3358                 AC_TRY_COMPILE([
3359 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
3360 #include <sys/types.h>
3361 #include <dirent.h>
3362                 ],[
3363                 /* if transitional largefile support is setup, this is true */
3364                 extern struct dirent64 * readdir(DIR *);
3365                 struct dirent64 *x = readdir((DIR *)0);
3366                 struct dirent *y = readdir((DIR *)0);
3367                 int z = x - y;
3368                 ],
3369                 [cf_cv_struct_dirent64=yes],
3370                 [cf_cv_struct_dirent64=no])
3371         ])
3372         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3373         fi
3374 ])
3375 ])
3376 dnl ---------------------------------------------------------------------------
3377 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3378 dnl -----------------
3379 dnl Check for compiler/linker flags used to temporarily force usage of static
3380 dnl libraries.  This depends on the compiler and platform.  Use this to help
3381 dnl ensure that the linker picks up a given library based on its position in
3382 dnl the list of linker options and libraries.
3383 AC_DEFUN([CF_LDFLAGS_STATIC],[
3384
3385 if test "$GCC" = yes ; then
3386         case $cf_cv_system_name in
3387         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3388                 LDFLAGS_STATIC=
3389                 LDFLAGS_SHARED=
3390                 ;;
3391         (*)     # normally, except when broken
3392                 LDFLAGS_STATIC=-static
3393                 LDFLAGS_SHARED=-dynamic
3394                 ;;
3395         esac
3396 else
3397         case $cf_cv_system_name in
3398         (aix[[4-7]]*)   # from ld manpage
3399                 LDFLAGS_STATIC=-bstatic
3400                 LDFLAGS_SHARED=-bdynamic
3401                 ;;
3402         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3403                 # We could also use just "archive" and "shared".
3404                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3405                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3406                 ;;
3407         (irix*)         # from ld manpage IRIX64
3408                 LDFLAGS_STATIC=-Bstatic
3409                 LDFLAGS_SHARED=-Bdynamic
3410                 ;;
3411         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3412                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3413                 LDFLAGS_STATIC=-noso
3414                 LDFLAGS_SHARED=-so_archive
3415                 ;;
3416         (solaris2*)
3417                 LDFLAGS_STATIC=-Bstatic
3418                 LDFLAGS_SHARED=-Bdynamic
3419                 ;;
3420         esac
3421 fi
3422
3423 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3424 then
3425         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3426
3427         rm -f libconftest.a
3428         cat >conftest.$ac_ext <<EOF
3429 #line __oline__ "configure"
3430 #include <stdio.h>
3431 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3432 EOF
3433         if AC_TRY_EVAL(ac_compile) ; then
3434                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3435                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3436         fi
3437         rm -f conftest.*
3438
3439         cf_save_LIBS="$LIBS"
3440
3441         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3442         AC_TRY_LINK([
3443 #line __oline__ "configure"
3444 #include <stdio.h>
3445 int cf_ldflags_static(FILE *fp);
3446 ],[
3447         return cf_ldflags_static(stdin);
3448 ],[
3449         # some linkers simply ignore the -dynamic
3450         case x`file conftest$ac_exeext 2>/dev/null` in
3451         (*static*)
3452                 cf_ldflags_static=no
3453                 ;;
3454         (*)
3455                 cf_ldflags_static=yes
3456                 ;;
3457         esac
3458 ],[cf_ldflags_static=no])
3459
3460         rm -f libconftest.*
3461         LIBS="$cf_save_LIBS"
3462
3463         AC_MSG_RESULT($cf_ldflags_static)
3464
3465         if test $cf_ldflags_static != yes
3466         then
3467                 LDFLAGS_STATIC=
3468                 LDFLAGS_SHARED=
3469         fi
3470 else
3471         LDFLAGS_STATIC=
3472         LDFLAGS_SHARED=
3473 fi
3474
3475 AC_SUBST(LDFLAGS_STATIC)
3476 AC_SUBST(LDFLAGS_SHARED)
3477 ])
3478 dnl ---------------------------------------------------------------------------
3479 dnl CF_LD_RPATH_OPT version: 7 updated: 2016/02/20 18:01:19
3480 dnl ---------------
3481 dnl For the given system and compiler, find the compiler flags to pass to the
3482 dnl loader to use the "rpath" feature.
3483 AC_DEFUN([CF_LD_RPATH_OPT],
3484 [
3485 AC_REQUIRE([CF_CHECK_CACHE])
3486
3487 LD_RPATH_OPT=
3488 AC_MSG_CHECKING(for an rpath option)
3489 case $cf_cv_system_name in
3490 (irix*)
3491         if test "$GCC" = yes; then
3492                 LD_RPATH_OPT="-Wl,-rpath,"
3493         else
3494                 LD_RPATH_OPT="-rpath "
3495         fi
3496         ;;
3497 (linux*|gnu*|k*bsd*-gnu|freebsd*)
3498         LD_RPATH_OPT="-Wl,-rpath,"
3499         ;;
3500 (openbsd[[2-9]].*|mirbsd*)
3501         LD_RPATH_OPT="-Wl,-rpath,"
3502         ;;
3503 (dragonfly*)
3504         LD_RPATH_OPT="-rpath "
3505         ;;
3506 (netbsd*)
3507         LD_RPATH_OPT="-Wl,-rpath,"
3508         ;;
3509 (osf*|mls+*)
3510         LD_RPATH_OPT="-rpath "
3511         ;;
3512 (solaris2*)
3513         LD_RPATH_OPT="-R"
3514         ;;
3515 (*)
3516         ;;
3517 esac
3518 AC_MSG_RESULT($LD_RPATH_OPT)
3519
3520 case "x$LD_RPATH_OPT" in
3521 (x-R*)
3522         AC_MSG_CHECKING(if we need a space after rpath option)
3523         cf_save_LIBS="$LIBS"
3524         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3525         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3526         LIBS="$cf_save_LIBS"
3527         AC_MSG_RESULT($cf_rpath_space)
3528         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3529         ;;
3530 esac
3531 ])dnl
3532 dnl ---------------------------------------------------------------------------
3533 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3534 dnl ---------------
3535 dnl Construct a search-list of directories for a nonstandard library-file
3536 dnl
3537 dnl Parameters
3538 dnl     $1 = the variable to return as result
3539 dnl     $2 = the package name
3540 AC_DEFUN([CF_LIBRARY_PATH],
3541 [
3542 $1=
3543 cf_library_path_list=""
3544 if test -n "${LDFLAGS}${LIBS}" ; then
3545         for cf_library_path in $LDFLAGS $LIBS
3546         do
3547                 case $cf_library_path in
3548                 (-L*)
3549                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3550                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3551                         cf_library_path_list="$cf_library_path_list [$]$1"
3552                         ;;
3553                 esac
3554         done
3555 fi
3556
3557 CF_SUBDIR_PATH($1,$2,lib)
3558
3559 $1="$cf_library_path_list [$]$1"
3560 ])dnl
3561 dnl ---------------------------------------------------------------------------
3562 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3563 dnl ------------------
3564 AC_DEFUN([CF_LIBTOOL_VERSION],[
3565 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3566 then
3567         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3568 else
3569         cf_cv_libtool_version=
3570 fi
3571 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3572 ])dnl
3573 dnl ---------------------------------------------------------------------------
3574 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
3575 dnl -------------
3576 dnl Compute the library-prefix for the given host system
3577 dnl $1 = variable to set
3578 define([CF_LIB_PREFIX],
3579 [
3580         case $cf_cv_system_name in
3581         (OS/2*|os2*)
3582                 if test "$DFT_LWR_MODEL" = libtool; then
3583                         LIB_PREFIX='lib'
3584                 else
3585                         LIB_PREFIX=''
3586                 fi
3587                 ;;
3588         (*)     LIB_PREFIX='lib'
3589                 ;;
3590         esac
3591 ifelse($1,,,[$1=$LIB_PREFIX])
3592         AC_SUBST(LIB_PREFIX)
3593 ])dnl
3594 dnl ---------------------------------------------------------------------------
3595 dnl CF_LIB_RULES version: 87 updated: 2017/07/26 17:08:35
3596 dnl ------------
3597 dnl Append definitions and rules for the given models to the subdirectory
3598 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3599 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3600 dnl the corresponding makefile to list the models that we'll generate.
3601 dnl
3602 dnl For shared libraries, make a list of symbolic links to construct when
3603 dnl generating each library.  The convention used for Linux is the simplest
3604 dnl one:
3605 dnl     lib<name>.so    ->
3606 dnl     lib<name>.so.<major>    ->
3607 dnl     lib<name>.so.<maj>.<minor>
3608 dnl
3609 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3610 AC_DEFUN([CF_LIB_RULES],
3611 [
3612 cf_prefix=$LIB_PREFIX
3613 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3614
3615 case $cf_cv_shlib_version in
3616 (cygdll|msysdll|mingw)
3617         TINFO_NAME=$TINFO_ARG_SUFFIX
3618         TINFO_SUFFIX=.dll
3619         ;;
3620 esac
3621
3622 if test -n "$TINFO_SUFFIX" ; then
3623         case $TINFO_SUFFIX in
3624         (tw*)
3625                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
3626                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
3627                 ;;
3628         (t*)
3629                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
3630                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
3631                 ;;
3632         (w*)
3633                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
3634                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
3635                 ;;
3636         esac
3637 fi
3638
3639 for cf_dir in $SRC_SUBDIRS
3640 do
3641         if test ! -d $srcdir/$cf_dir ; then
3642                 continue
3643         elif test -f $srcdir/$cf_dir/modules; then
3644
3645                 SHARED_LIB=
3646                 Libs_To_Make=
3647                 cf_awk_program=
3648                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3649                 then
3650                         cf_awk_program="$cf_awk_program\
3651 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
3652 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
3653 "
3654                 fi
3655
3656                 if test "x$WILDCARD_SYMS" = xno
3657                 then
3658                         cf_awk_program="$cf_awk_program\
3659 /[[     ]]_\\*;/ { skip=1; next; }\
3660 "
3661                 fi
3662
3663                 if test "x$cf_awk_program" != "x"
3664                 then
3665                         cat >>$cf_dir/Makefile <<CF_EOF
3666
3667 # Generated by CF_LIB_RULES
3668 resulting.map: $UNALTERED_SYMS
3669         $AWK 'BEGIN { skip = 1; last=""; } \
3670 $cf_awk_program \
3671 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
3672  skip = 0; last = \[$]\[$]0; } \
3673 END { print last; }' < $UNALTERED_SYMS >\[$]@
3674
3675 distclean::
3676         rm -f resulting.map
3677 CF_EOF
3678                 fi
3679
3680                 for cf_item in $cf_LIST_MODELS
3681                 do
3682                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3683                         cf_libname=$cf_dir
3684                         test "$cf_dir" = c++ && cf_libname=ncurses++
3685                         if test $cf_item = shared ; then
3686                                 if test -n "${LIB_SUFFIX}"
3687                                 then
3688                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3689                                 else
3690                                         cf_shared_suffix="$cf_suffix"
3691                                 fi
3692                                 if test "$cf_cv_do_symlinks" = yes ; then
3693                                         cf_version_name=
3694
3695                                         case "$cf_cv_shlib_version" in
3696                                         (rel)
3697                                                 cf_version_name=REL_VERSION
3698                                                 ;;
3699                                         (abi)
3700                                                 cf_version_name=ABI_VERSION
3701                                                 ;;
3702                                         esac
3703
3704                                         if test -n "$cf_version_name"
3705                                         then
3706                                                 case "$cf_cv_system_name" in
3707                                                 (darwin*)
3708                                                         # "w", etc?
3709                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3710                                                         ;;
3711                                                 (*)
3712                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3713                                                         ;;
3714                                                 esac
3715                                         fi
3716                                         if test -n "${USE_LIB_SUFFIX}"
3717                                         then
3718                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3719                                         else
3720                                                 cf_shared_suffix="$cf_suffix"
3721                                         fi
3722                                 fi
3723                                 # cygwin needs import library, and has unique naming convention
3724                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3725                                 # use 'cyg' prefix for shared lib.
3726                                 case $cf_cv_shlib_version in
3727                                 (cygdll)
3728                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3729                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
3730                                         ;;
3731                                 (msysdll)
3732                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3733                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
3734                                         ;;
3735                                 (mingw)
3736                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3737                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
3738                                         ;;
3739                                 (*)
3740                                         cf_add_lib=
3741                                         ;;
3742                                 esac
3743                                 if test -n "$cf_add_lib"
3744