aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2014,2015 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.743 2015/04/18 13:01:42 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54         [AC_TRY_LINK([#include <langinfo.h>],
  55         [char* cs = nl_langinfo(CODESET);],
  56         am_cv_langinfo_codeset=yes,
  57         am_cv_langinfo_codeset=no)
  58         ])
  59         if test $am_cv_langinfo_codeset = yes; then
  60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62         fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
  66 dnl ------------------
  67 dnl Conditionally generate script according to whether we're using a given autoconf.
  68 dnl
  69 dnl $1 = version to compare against
  70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  71 dnl $3 = code to use if AC_ACVERSION is older than $1.
  72 define([CF_ACVERSION_CHECK],
  73 [
  74 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
  75 ifdef([m4_version_compare],
  76 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  77 [CF_ACVERSION_COMPARE(
  78 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  79 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  80 dnl ---------------------------------------------------------------------------
  81 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  82 dnl --------------------
  83 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  84 dnl                      MAJOR2, MINOR2, TERNARY2,
  85 dnl                      PRINTABLE2, not FOUND, FOUND)
  86 define([CF_ACVERSION_COMPARE],
  87 [ifelse(builtin([eval], [$2 < $5]), 1,
  88 [ifelse([$8], , ,[$8])],
  89 [ifelse([$9], , ,[$9])])])dnl
  90 dnl ---------------------------------------------------------------------------
  91 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
  92 dnl -------------------
  93 dnl Construct the list of include-options for the C programs in the Ada95
  94 dnl binding.
  95 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  96 [
  97 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  98 if test "$srcdir" != "."; then
  99         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 100 fi
 101 if test "$GCC" != yes; then
 102         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 103 elif test "$includedir" != "/usr/include"; then
 104         if test "$includedir" = '${prefix}/include' ; then
 105                 if test x$prefix != x/usr ; then
 106                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 107                 fi
 108         else
 109                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 110         fi
 111 fi
 112 AC_SUBST(ACPPFLAGS)
 113 ])dnl
 114 dnl ---------------------------------------------------------------------------
 115 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 116 dnl ---------------
 117 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 118 AC_DEFUN([CF_ADD_ADAFLAGS],[
 119         ADAFLAGS="$ADAFLAGS $1"
 120         AC_SUBST(ADAFLAGS)
 121 ])dnl
 122 dnl ---------------------------------------------------------------------------
 123 dnl CF_ADD_CFLAGS version: 12 updated: 2015/04/12 15:39:00
 124 dnl -------------
 125 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 126 dnl The second parameter if given makes this macro verbose.
 127 dnl
 128 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 129 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 130 dnl confused by the quotes (which require backslashes to keep them usable).
 131 AC_DEFUN([CF_ADD_CFLAGS],
 132 [
 133 cf_fix_cppflags=no
 134 cf_new_cflags=
 135 cf_new_cppflags=
 136 cf_new_extra_cppflags=
 137
 138 for cf_add_cflags in $1
 139 do
 140 case $cf_fix_cppflags in
 141 (no)
 142         case $cf_add_cflags in
 143         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 144                 case $cf_add_cflags in
 145                 (-D*)
 146                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 147
 148                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 149                                 && test -z "${cf_tst_cflags}" \
 150                                 && cf_fix_cppflags=yes
 151
 152                         if test $cf_fix_cppflags = yes ; then
 153                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 154                                 continue
 155                         elif test "${cf_tst_cflags}" = "\"'" ; then
 156                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 157                                 continue
 158                         fi
 159                         ;;
 160                 esac
 161                 case "$CPPFLAGS" in
 162                 (*$cf_add_cflags)
 163                         ;;
 164                 (*)
 165                         case $cf_add_cflags in
 166                         (-D*)
 167                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 168                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 169                                 ;;
 170                         esac
 171                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 172                         ;;
 173                 esac
 174                 ;;
 175         (*)
 176                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 177                 ;;
 178         esac
 179         ;;
 180 (yes)
 181         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 182
 183         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 184
 185         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 186                 && test -z "${cf_tst_cflags}" \
 187                 && cf_fix_cppflags=no
 188         ;;
 189 esac
 190 done
 191
 192 if test -n "$cf_new_cflags" ; then
 193         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 194         CFLAGS="$CFLAGS $cf_new_cflags"
 195 fi
 196
 197 if test -n "$cf_new_cppflags" ; then
 198         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 199         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 200 fi
 201
 202 if test -n "$cf_new_extra_cppflags" ; then
 203         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 204         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 205 fi
 206
 207 AC_SUBST(EXTRA_CPPFLAGS)
 208
 209 ])dnl
 210 dnl ---------------------------------------------------------------------------
 211 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 212 dnl -------------
 213 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 214 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 215 dnl but old versions (and some misinstalled ones) need that.  To make things
 216 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 217 dnl the include-path).
 218 AC_DEFUN([CF_ADD_INCDIR],
 219 [
 220 if test -n "$1" ; then
 221   for cf_add_incdir in $1
 222   do
 223         while test $cf_add_incdir != /usr/include
 224         do
 225           if test -d $cf_add_incdir
 226           then
 227                 cf_have_incdir=no
 228                 if test -n "$CFLAGS$CPPFLAGS" ; then
 229                   # a loop is needed to ensure we can add subdirs of existing dirs
 230                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 231                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 232                           cf_have_incdir=yes; break
 233                         fi
 234                   done
 235                 fi
 236
 237                 if test "$cf_have_incdir" = no ; then
 238                   if test "$cf_add_incdir" = /usr/local/include ; then
 239                         if test "$GCC" = yes
 240                         then
 241                           cf_save_CPPFLAGS=$CPPFLAGS
 242                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 243                           AC_TRY_COMPILE([#include <stdio.h>],
 244                                   [printf("Hello")],
 245                                   [],
 246                                   [cf_have_incdir=yes])
 247                           CPPFLAGS=$cf_save_CPPFLAGS
 248                         fi
 249                   fi
 250                 fi
 251
 252                 if test "$cf_have_incdir" = no ; then
 253                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 254                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 255
 256                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 257                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 258                   cf_add_incdir="$cf_top_incdir"
 259                 else
 260                   break
 261                 fi
 262           fi
 263         done
 264   done
 265 fi
 266 ])dnl
 267 dnl ---------------------------------------------------------------------------
 268 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 269 dnl ----------
 270 dnl Add a library, used to enforce consistency.
 271 dnl
 272 dnl $1 = library to add, without the "-l"
 273 dnl $2 = variable to update (default $LIBS)
 274 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 275 dnl ---------------------------------------------------------------------------
 276 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 277 dnl -------------
 278 dnl     Adds to the library-path
 279 dnl
 280 dnl     Some machines have trouble with multiple -L options.
 281 dnl
 282 dnl $1 is the (list of) directory(s) to add
 283 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 284 dnl
 285 AC_DEFUN([CF_ADD_LIBDIR],
 286 [
 287 if test -n "$1" ; then
 288         for cf_add_libdir in $1
 289         do
 290                 if test $cf_add_libdir = /usr/lib ; then
 291                         :
 292                 elif test -d $cf_add_libdir
 293                 then
 294                         cf_have_libdir=no
 295                         if test -n "$LDFLAGS$LIBS" ; then
 296                                 # a loop is needed to ensure we can add subdirs of existing dirs
 297                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 298                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 299                                                 cf_have_libdir=yes; break
 300                                         fi
 301                                 done
 302                         fi
 303                         if test "$cf_have_libdir" = no ; then
 304                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 305                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 306                         fi
 307                 fi
 308         done
 309 fi
 310 ])dnl
 311 dnl ---------------------------------------------------------------------------
 312 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 313 dnl -----------
 314 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 315 dnl prepended to an existing list, since their dependencies are assumed to
 316 dnl already exist in the list.
 317 dnl
 318 dnl $1 = libraries to add, with the "-l", etc.
 319 dnl $2 = variable to update (default $LIBS)
 320 AC_DEFUN([CF_ADD_LIBS],[
 321 cf_add_libs="$1"
 322 # Filter out duplicates - this happens with badly-designed ".pc" files...
 323 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 324 do
 325         for cf_add_2lib in $cf_add_libs
 326         do
 327                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 328                 then
 329                         cf_add_1lib=
 330                         break
 331                 fi
 332         done
 333         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 334 done
 335 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 336 ])dnl
 337 dnl ---------------------------------------------------------------------------
 338 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 339 dnl ------------------
 340 dnl Append to a search-list for a nonstandard header/lib-file
 341 dnl     $1 = the variable to return as result
 342 dnl     $2 = the package name
 343 dnl     $3 = the subdirectory, e.g., bin, include or lib
 344 dnl $4 = the directory under which we will test for subdirectories
 345 dnl $5 = a directory that we do not want $4 to match
 346 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 347 [
 348 test "x$4" != "x$5" && \
 349 test -d "$4" && \
 350 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 351         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 352         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 353         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 354         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 355         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 356         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 357 }
 358 ])dnl
 359 dnl ---------------------------------------------------------------------------
 360 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 361 dnl --------------
 362 dnl Allow user to disable a normally-on option.
 363 AC_DEFUN([CF_ARG_DISABLE],
 364 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 365 dnl ---------------------------------------------------------------------------
 366 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 367 dnl -------------
 368 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 369 dnl values.
 370 dnl
 371 dnl Parameters:
 372 dnl $1 = option name
 373 dnl $2 = help-string
 374 dnl $3 = action to perform if option is not default
 375 dnl $4 = action if perform if option is default
 376 dnl $5 = default option value (either 'yes' or 'no')
 377 AC_DEFUN([CF_ARG_OPTION],
 378 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 379   if test "$enableval" != "$5" ; then
 380 ifelse([$3],,[    :]dnl
 381 ,[    $3]) ifelse([$4],,,[
 382   else
 383     $4])
 384   fi],[enableval=$5 ifelse([$4],,,[
 385   $4
 386 ])dnl
 387   ])])dnl
 388 dnl ---------------------------------------------------------------------------
 389 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 390 dnl -----------
 391 dnl Check for suitable "ar" (archiver) options for updating an archive.
 392 AC_DEFUN([CF_AR_FLAGS],[
 393 AC_REQUIRE([CF_PROG_AR])
 394
 395 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 396         cf_cv_ar_flags=unknown
 397         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 398         do
 399
 400                 # check if $ARFLAGS already contains this choice
 401                 if test "x$ARFLAGS" != "x" ; then
 402                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 403                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 404                                 cf_cv_ar_flags=
 405                                 break
 406                         fi
 407                 fi
 408
 409                 rm -f conftest.$ac_cv_objext
 410                 rm -f conftest.a
 411
 412                 cat >conftest.$ac_ext <<EOF
 413 #line __oline__ "configure"
 414 int     testdata[[3]] = { 123, 456, 789 };
 415 EOF
 416                 if AC_TRY_EVAL(ac_compile) ; then
 417                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 418                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 419                         if test -f conftest.a ; then
 420                                 cf_cv_ar_flags=$cf_ar_flags
 421                                 break
 422                         fi
 423                 else
 424                         CF_VERBOSE(cannot compile test-program)
 425                         break
 426                 fi
 427         done
 428         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 429 ])
 430
 431 if test -n "$ARFLAGS" ; then
 432         if test -n "$cf_cv_ar_flags" ; then
 433                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 434         fi
 435 else
 436         ARFLAGS=$cf_cv_ar_flags
 437 fi
 438
 439 AC_SUBST(ARFLAGS)
 440 ])
 441 dnl ---------------------------------------------------------------------------
 442 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 443 dnl -----------------
 444 dnl Check if awk can handle big strings using printf.  Some older versions of
 445 dnl awk choke on large strings passed via "%s".
 446 dnl
 447 dnl $1 = desired string size
 448 dnl $2 = variable to set with result
 449 AC_DEFUN([CF_AWK_BIG_PRINTF],
 450 [
 451         case x$AWK in
 452         (x)
 453                 eval $2=no
 454                 ;;
 455         (*)
 456                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 457                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 458                         eval $2=yes
 459                 else
 460                         eval $2=no
 461                 fi
 462                 ;;
 463         esac
 464 ])dnl
 465 dnl ---------------------------------------------------------------------------
 466 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 467 dnl ------------
 468 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 469 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 470 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 471 dnl
 472 dnl Treat the configuration-variable specially here, since we're directly
 473 dnl substituting its value (i.e., 1/0).
 474 dnl
 475 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 476 AC_DEFUN([CF_BOOL_DECL],
 477 [
 478 AC_MSG_CHECKING(if we should include stdbool.h)
 479
 480 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 481         AC_TRY_COMPILE([],[bool foo = false],
 482                 [cf_cv_header_stdbool_h=0],
 483                 [AC_TRY_COMPILE([
 484 #ifndef __BEOS__
 485 #include <stdbool.h>
 486 #endif
 487 ],[bool foo = false],
 488                         [cf_cv_header_stdbool_h=1],
 489                         [cf_cv_header_stdbool_h=0])])])
 490
 491 if test "$cf_cv_header_stdbool_h" = 1
 492 then    AC_MSG_RESULT(yes)
 493 else    AC_MSG_RESULT(no)
 494 fi
 495
 496 AC_MSG_CHECKING([for builtin bool type])
 497
 498 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 499         AC_TRY_COMPILE([
 500 #include <stdio.h>
 501 #include <sys/types.h>
 502 ],[bool x = false],
 503                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 504                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 505         ])
 506
 507 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 508 then    AC_MSG_RESULT(yes)
 509 else    AC_MSG_RESULT(no)
 510 fi
 511 ])dnl
 512 dnl ---------------------------------------------------------------------------
 513 dnl CF_BOOL_SIZE version: 14 updated: 2015/04/17 21:13:04
 514 dnl ------------
 515 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 516 dnl Don't bother looking for bool.h, since it's been deprecated.
 517 dnl
 518 dnl If the current compiler is C rather than C++, we get the bool definition
 519 dnl from <stdbool.h>.
 520 AC_DEFUN([CF_BOOL_SIZE],
 521 [
 522 AC_MSG_CHECKING([for size of bool])
 523 AC_CACHE_VAL(cf_cv_type_of_bool,[
 524         rm -f cf_test.out
 525         AC_TRY_RUN([
 526 #include <stdlib.h>
 527 #include <stdio.h>
 528
 529 #if defined(__cplusplus)
 530
 531 #ifdef HAVE_GXX_BUILTIN_H
 532 #include <g++/builtin.h>
 533 #elif HAVE_GPP_BUILTIN_H
 534 #include <gpp/builtin.h>
 535 #elif HAVE_BUILTIN_H
 536 #include <builtin.h>
 537 #endif
 538
 539 #else
 540
 541 #if $cf_cv_header_stdbool_h
 542 #include <stdbool.h>
 543 #endif
 544
 545 #endif
 546
 547 int main()
 548 {
 549         FILE *fp = fopen("cf_test.out", "w");
 550         if (fp != 0) {
 551                 bool x = true;
 552                 if ((bool)(-x) >= 0)
 553                         fputs("unsigned ", fp);
 554                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 555                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 556                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 557                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 558                 fclose(fp);
 559         }
 560         ${cf_cv_main_return:-return}(0);
 561 }
 562                 ],
 563                 [cf_cv_type_of_bool=`cat cf_test.out`
 564                  if test -z "$cf_cv_type_of_bool"; then
 565                    cf_cv_type_of_bool=unknown
 566                  fi],
 567                 [cf_cv_type_of_bool=unknown],
 568                 [cf_cv_type_of_bool=unknown])
 569         ])
 570         rm -f cf_test.out
 571 AC_MSG_RESULT($cf_cv_type_of_bool)
 572 if test "$cf_cv_type_of_bool" = unknown ; then
 573         case .$NCURSES_BOOL in
 574         (.auto|.) NCURSES_BOOL=unsigned;;
 575         esac
 576         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 577         cf_cv_type_of_bool=$NCURSES_BOOL
 578 fi
 579 ])dnl
 580 dnl ---------------------------------------------------------------------------
 581 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 582 dnl -----------
 583 dnl If we're cross-compiling, allow the user to override the tools and their
 584 dnl options.  The configure script is oriented toward identifying the host
 585 dnl compiler, etc., but we need a build compiler to generate parts of the
 586 dnl source.
 587 dnl
 588 dnl $1 = default for $CPPFLAGS
 589 dnl $2 = default for $LIBS
 590 AC_DEFUN([CF_BUILD_CC],[
 591 CF_ACVERSION_CHECK(2.52,,
 592         [AC_REQUIRE([CF_PROG_EXT])])
 593 if test "$cross_compiling" = yes ; then
 594
 595         # defaults that we might want to override
 596         : ${BUILD_CFLAGS:=''}
 597         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 598         : ${BUILD_LDFLAGS:=''}
 599         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 600         : ${BUILD_EXEEXT:='$x'}
 601         : ${BUILD_OBJEXT:='o'}
 602
 603         AC_ARG_WITH(build-cc,
 604                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 605                 [BUILD_CC="$withval"],
 606                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 607         AC_MSG_CHECKING(for native build C compiler)
 608         AC_MSG_RESULT($BUILD_CC)
 609
 610         AC_MSG_CHECKING(for native build C preprocessor)
 611         AC_ARG_WITH(build-cpp,
 612                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 613                 [BUILD_CPP="$withval"],
 614                 [BUILD_CPP='${BUILD_CC} -E'])
 615         AC_MSG_RESULT($BUILD_CPP)
 616
 617         AC_MSG_CHECKING(for native build C flags)
 618         AC_ARG_WITH(build-cflags,
 619                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 620                 [BUILD_CFLAGS="$withval"])
 621         AC_MSG_RESULT($BUILD_CFLAGS)
 622
 623         AC_MSG_CHECKING(for native build C preprocessor-flags)
 624         AC_ARG_WITH(build-cppflags,
 625                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 626                 [BUILD_CPPFLAGS="$withval"])
 627         AC_MSG_RESULT($BUILD_CPPFLAGS)
 628
 629         AC_MSG_CHECKING(for native build linker-flags)
 630         AC_ARG_WITH(build-ldflags,
 631                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 632                 [BUILD_LDFLAGS="$withval"])
 633         AC_MSG_RESULT($BUILD_LDFLAGS)
 634
 635         AC_MSG_CHECKING(for native build linker-libraries)
 636         AC_ARG_WITH(build-libs,
 637                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 638                 [BUILD_LIBS="$withval"])
 639         AC_MSG_RESULT($BUILD_LIBS)
 640
 641         # this assumes we're on Unix.
 642         BUILD_EXEEXT=
 643         BUILD_OBJEXT=o
 644
 645         : ${BUILD_CC:='${CC}'}
 646
 647         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 648                 AC_MSG_ERROR([Cross-build requires two compilers.
 649 Use --with-build-cc to specify the native compiler.])
 650         fi
 651
 652 else
 653         : ${BUILD_CC:='${CC}'}
 654         : ${BUILD_CPP:='${CPP}'}
 655         : ${BUILD_CFLAGS:='${CFLAGS}'}
 656         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 657         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 658         : ${BUILD_LIBS:='${LIBS}'}
 659         : ${BUILD_EXEEXT:='$x'}
 660         : ${BUILD_OBJEXT:='o'}
 661 fi
 662
 663 AC_SUBST(BUILD_CC)
 664 AC_SUBST(BUILD_CPP)
 665 AC_SUBST(BUILD_CFLAGS)
 666 AC_SUBST(BUILD_CPPFLAGS)
 667 AC_SUBST(BUILD_LDFLAGS)
 668 AC_SUBST(BUILD_LIBS)
 669 AC_SUBST(BUILD_EXEEXT)
 670 AC_SUBST(BUILD_OBJEXT)
 671 ])dnl
 672 dnl ---------------------------------------------------------------------------
 673 dnl CF_CC_ENV_FLAGS version: 2 updated: 2015/04/12 15:39:00
 674 dnl ---------------
 675 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 676 dnl into CC.  This will not help with broken scripts that wrap the compiler with
 677 dnl options, but eliminates a more common category of user confusion.
 678 AC_DEFUN([CF_CC_ENV_FLAGS],
 679 [
 680 # This should have been defined by AC_PROG_CC
 681 : ${CC:=cc}
 682
 683 AC_MSG_CHECKING(\$CC variable)
 684 case "$CC" in
 685 (*[[\ \ ]]-[[IUD]]*)
 686         AC_MSG_RESULT(broken)
 687         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 688         # humor him...
 689         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 690         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 691         CF_ADD_CFLAGS($cf_flags)
 692         ;;
 693 (*)
 694         AC_MSG_RESULT(ok)
 695         ;;
 696 esac
 697 ])dnl
 698 dnl ---------------------------------------------------------------------------
 699 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 700 dnl ---------------
 701 dnl Determine the default configuration into which we'll install ncurses.  This
 702 dnl can be overridden by the user's command-line options.  There's two items to
 703 dnl look for:
 704 dnl     1. the prefix (e.g., /usr)
 705 dnl     2. the header files (e.g., /usr/include/ncurses)
 706 dnl We'll look for a previous installation of ncurses and use the same defaults.
 707 dnl
 708 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 709 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 710 dnl programs from a vendor's.
 711 AC_DEFUN([CF_CFG_DEFAULTS],
 712 [
 713 AC_MSG_CHECKING(for prefix)
 714 if test "x$prefix" = "xNONE" ; then
 715         case "$cf_cv_system_name" in
 716                 # non-vendor systems don't have a conflict
 717         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 718                 prefix=/usr
 719                 ;;
 720         (*)     prefix=$ac_default_prefix
 721                 ;;
 722         esac
 723 fi
 724 AC_MSG_RESULT($prefix)
 725
 726 if test "x$prefix" = "xNONE" ; then
 727 AC_MSG_CHECKING(for default include-directory)
 728 test -n "$verbose" && echo 1>&AC_FD_MSG
 729 for cf_symbol in \
 730         $includedir \
 731         $includedir/ncurses \
 732         $prefix/include \
 733         $prefix/include/ncurses \
 734         /usr/local/include \
 735         /usr/local/include/ncurses \
 736         /usr/include \
 737         /usr/include/ncurses
 738 do
 739         cf_dir=`eval echo $cf_symbol`
 740         if test -f $cf_dir/curses.h ; then
 741         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 742                 includedir="$cf_symbol"
 743                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 744                 break
 745         fi
 746         fi
 747         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 748 done
 749 AC_MSG_RESULT($includedir)
 750 fi
 751 ])dnl
 752 dnl ---------------------------------------------------------------------------
 753 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
 754 dnl ----------
 755 dnl Check if the terminal-capability database functions are available.  If not,
 756 dnl ncurses has a much-reduced version.
 757 AC_DEFUN([CF_CGETENT],[
 758 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 759 AC_TRY_LINK([
 760 #include <stdlib.h>],[
 761         char temp[128];
 762         char *buf = temp;
 763         char *db_array = temp;
 764         cgetent(&buf, &db_array, "vt100");
 765         cgetcap(buf, "tc", '=');
 766         cgetmatch(buf, "tc");
 767         ],
 768         [cf_cv_cgetent=yes],
 769         [cf_cv_cgetent=no])
 770 ])
 771
 772 if test "$cf_cv_cgetent" = yes
 773 then
 774         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 775 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 776 AC_TRY_LINK([
 777 #include <stdlib.h>],[
 778         char temp[128];
 779         char *buf = temp;
 780 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 781         const char *db_array = temp;
 782         cgetent(&buf, &db_array, "vt100");
 783 #endif
 784         cgetcap(buf, "tc", '=');
 785         cgetmatch(buf, "tc");
 786         ],
 787         [cf_cv_cgetent_const=yes],
 788         [cf_cv_cgetent_const=no])
 789 ])
 790         if test "$cf_cv_cgetent_const" = yes
 791         then
 792                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 793         fi
 794 fi
 795 ])dnl
 796 dnl ---------------------------------------------------------------------------
 797 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 798 dnl --------------
 799 dnl Check if we're accidentally using a cache from a different machine.
 800 dnl Derive the system name, as a check for reusing the autoconf cache.
 801 dnl
 802 dnl If we've packaged config.guess and config.sub, run that (since it does a
 803 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 804 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 805 dnl which is useful in cross-compiles.
 806 dnl
 807 dnl Note: we would use $ac_config_sub, but that is one of the places where
 808 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 809 AC_DEFUN([CF_CHECK_CACHE],
 810 [
 811 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 812         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 813         system_name="$host_os"
 814 else
 815         system_name="`(uname -s -r) 2>/dev/null`"
 816         if test -z "$system_name" ; then
 817                 system_name="`(hostname) 2>/dev/null`"
 818         fi
 819 fi
 820 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 821 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 822
 823 test -z "$system_name" && system_name="$cf_cv_system_name"
 824 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 825
 826 if test ".$system_name" != ".$cf_cv_system_name" ; then
 827         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 828         AC_MSG_ERROR("Please remove config.cache and try again.")
 829 fi
 830 ])dnl
 831 dnl ---------------------------------------------------------------------------
 832 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
 833 dnl --------------
 834 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 835 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 836 dnl ourselves.
 837 dnl
 838 dnl $1 = the name to check
 839 dnl $2 = the assumed type
 840 AC_DEFUN([CF_CHECK_ERRNO],
 841 [
 842 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 843         AC_TRY_COMPILE([
 844 #ifdef HAVE_STDLIB_H
 845 #include <stdlib.h>
 846 #endif
 847 #include <stdio.h>
 848 #include <sys/types.h>
 849 #include <errno.h> ],
 850         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 851         [cf_cv_dcl_$1=yes],
 852         [cf_cv_dcl_$1=no])
 853 ])
 854
 855 if test "$cf_cv_dcl_$1" = no ; then
 856         CF_UPPER(cf_result,decl_$1)
 857         AC_DEFINE_UNQUOTED($cf_result)
 858 fi
 859
 860 # It's possible (for near-UNIX clones) that the data doesn't exist
 861 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 862 ])dnl
 863 dnl ---------------------------------------------------------------------------
 864 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
 865 dnl --------------------
 866 dnl Check for existence of external data in the current set of libraries.  If
 867 dnl we can modify it, it's real enough.
 868 dnl $1 = the name to check
 869 dnl $2 = its type
 870 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 871 [
 872 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 873         AC_TRY_LINK([
 874 #undef $1
 875 extern $2 $1;
 876 ],
 877         [$1 = 2],
 878         [cf_cv_have_$1=yes],
 879         [cf_cv_have_$1=no])
 880 ])
 881
 882 if test "$cf_cv_have_$1" = yes ; then
 883         CF_UPPER(cf_result,have_$1)
 884         AC_DEFINE_UNQUOTED($cf_result)
 885 fi
 886
 887 ])dnl
 888 dnl ---------------------------------------------------------------------------
 889 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 890 dnl -------------------
 891 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 892 dnl is not "weak" - warn about this because it can create problems linking
 893 dnl applications with ncurses.
 894 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 895 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 896
 897 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 898 cf_cv_check_gpm_wgetch=unknown
 899 if test "$cross_compiling" != yes ; then
 900
 901 cat >conftest.$ac_ext <<CF_EOF
 902 #include <gpm.h>
 903 int main()
 904 {
 905         Gpm_Wgetch();
 906         ${cf_cv_main_return:-return}(0);
 907 }
 908 CF_EOF
 909
 910         cf_save_LIBS="$LIBS"
 911         # This only works if we can look at the symbol table.  If a shared
 912         # library is stripped for install, we cannot use that.  So we're forced
 913         # to rely on the static library, noting that some packagers may not
 914         # include it.
 915         LIBS="-static -lgpm -dynamic $LIBS"
 916         if AC_TRY_EVAL(ac_compile) ; then
 917                 if AC_TRY_EVAL(ac_link) ; then
 918                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 919                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 920                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 921                 fi
 922         fi
 923         rm -rf conftest*
 924         LIBS="$cf_save_LIBS"
 925 fi
 926 ])
 927
 928 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 929         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 930 fi
 931 ])])dnl
 932 dnl ---------------------------------------------------------------------------
 933 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
 934 dnl ------------------------
 935 dnl Show the version of libtool
 936 dnl
 937 dnl Save the version in a cache variable - this is not entirely a good thing,
 938 dnl but the version string from libtool is very ugly, and for bug reports it
 939 dnl might be useful to have the original string.
 940 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
 941 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
 942 then
 943         AC_MSG_CHECKING(version of $LIBTOOL)
 944         CF_LIBTOOL_VERSION
 945         AC_MSG_RESULT($cf_cv_libtool_version)
 946         if test -z "$cf_cv_libtool_version" ; then
 947                 AC_MSG_ERROR(This is not GNU libtool)
 948         fi
 949 else
 950         AC_MSG_ERROR(GNU libtool has not been found)
 951 fi
 952 ])dnl
 953 dnl ---------------------------------------------------------------------------
 954 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
 955 dnl ----------------
 956 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
 957 AC_DEFUN([CF_CHECK_WCHAR_H],[
 958 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
 959 AC_TRY_COMPILE(
 960 [
 961 #include <stdlib.h>
 962 #include <wchar.h>
 963 ],[
 964         wint_t foo = 0;
 965         int bar = iswpunct(foo)],
 966         [cf_cv_wchar_h_okay=yes],
 967         [cf_cv_wchar_h_okay=no])])
 968
 969 if test $cf_cv_wchar_h_okay = no
 970 then
 971         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 972 fi
 973 ])dnl
 974 dnl ---------------------------------------------------------------------------
 975 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
 976 dnl -----------------
 977 dnl Check if the given compiler is really clang.  clang's C driver defines
 978 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 979 dnl not ignore some gcc options.
 980 dnl
 981 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 982 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 983 dnl the wrappers for gcc and g++ warnings.
 984 dnl
 985 dnl $1 = GCC (default) or GXX
 986 dnl $2 = CLANG_COMPILER (default)
 987 dnl $3 = CFLAGS (default) or CXXFLAGS
 988 AC_DEFUN([CF_CLANG_COMPILER],[
 989 ifelse([$2],,CLANG_COMPILER,[$2])=no
 990
 991 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 992         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 993         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 994         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 995         AC_TRY_COMPILE([],[
 996 #ifdef __clang__
 997 #else
 998 make an error
 999 #endif
1000 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1001 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1002 ],[])
1003         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1004         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1005 fi
1006 ])
1007 dnl ---------------------------------------------------------------------------
1008 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
1009 dnl -----------------
1010 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1011 dnl is a late feature for the standard and is not in some recent compilers
1012 dnl (1999/9/11).
1013 AC_DEFUN([CF_CPP_PARAM_INIT],
1014 [
1015 if test -n "$CXX"; then
1016 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1017         AC_LANG_SAVE
1018         AC_LANG_CPLUSPLUS
1019         AC_TRY_RUN([
1020 class TEST {
1021 private:
1022         int value;
1023 public:
1024         TEST(int x = 1);
1025         ~TEST();
1026 };
1027
1028 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1029 {
1030         value = x;
1031 }
1032 int main() { }
1033 ],
1034         [cf_cv_cpp_param_init=yes],
1035         [cf_cv_cpp_param_init=no],
1036         [cf_cv_cpp_param_init=unknown])
1037         AC_LANG_RESTORE
1038 ])
1039 fi
1040 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1041 ])dnl
1042 dnl ---------------------------------------------------------------------------
1043 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1044 dnl ------------------
1045 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1046 dnl not be supported in g++ before 3.0
1047 AC_DEFUN([CF_CPP_STATIC_CAST],
1048 [
1049 if test -n "$CXX"; then
1050
1051 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1052         AC_LANG_SAVE
1053         AC_LANG_CPLUSPLUS
1054
1055         AC_TRY_COMPILE([
1056 class NCursesPanel
1057 {
1058 public:
1059   NCursesPanel(int nlines,
1060                int ncols,
1061                int begin_y = 0,
1062                int begin_x = 0)
1063   {
1064   }
1065   NCursesPanel();
1066   ~NCursesPanel();
1067 };
1068
1069 template<class T> class NCursesUserPanel : public NCursesPanel
1070 {
1071 public:
1072   NCursesUserPanel (int nlines,
1073                     int ncols,
1074                     int begin_y = 0,
1075                     int begin_x = 0,
1076                     const T* p_UserData = static_cast<T*>(0))
1077     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1078   {
1079   };
1080   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1081   {
1082   };
1083
1084   virtual ~NCursesUserPanel() {};
1085 };
1086 ],[
1087         const char* p_UserData = static_cast<char*>(0)],
1088         [cf_cv_cpp_static_cast=yes],
1089         [cf_cv_cpp_static_cast=no])
1090
1091         AC_LANG_RESTORE
1092 ])
1093
1094 fi
1095
1096 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1097 ])dnl
1098 dnl ---------------------------------------------------------------------------
1099 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1100 dnl ---------------
1101 dnl Setup special archiver flags for given compilers.
1102 AC_DEFUN([CF_CXX_AR_FLAGS],[
1103         CXX_AR='$(AR)'
1104         CXX_ARFLAGS='$(ARFLAGS)'
1105         case $cf_cv_system_name in
1106         (irix*)
1107             if test "$GXX" != yes ; then
1108                 CXX_AR='$(CXX)'
1109                 CXX_ARFLAGS='-ar -o'
1110             fi
1111             ;;
1112         (sco3.2v5*)
1113             CXXLDFLAGS="-u main"
1114             ;;
1115         (solaris2*)
1116             if test "$GXX" != yes ; then
1117                 CXX_AR='$(CXX)'
1118                 CXX_ARFLAGS='-xar -o'
1119             fi
1120             ;;
1121         esac
1122         AC_SUBST(CXXLDFLAGS)
1123         AC_SUBST(CXX_AR)
1124         AC_SUBST(CXX_ARFLAGS)
1125 ])dnl
1126 dnl ---------------------------------------------------------------------------
1127 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1128 dnl -------------------------
1129 dnl For c++, check if iostream uses "std::" namespace.
1130 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1131 AC_CHECK_HEADERS(iostream)
1132 if test x"$ac_cv_header_iostream" = xyes ; then
1133         AC_MSG_CHECKING(if iostream uses std-namespace)
1134         AC_TRY_COMPILE([
1135 #include <iostream>
1136 using std::endl;
1137 using std::cerr;],[
1138 cerr << "testing" << endl;
1139 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1140         AC_MSG_RESULT($cf_iostream_namespace)
1141         if test "$cf_iostream_namespace" = yes ; then
1142                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1143         fi
1144 fi
1145 ])dnl
1146 dnl ---------------------------------------------------------------------------
1147 dnl CF_C_INLINE version: 5 updated: 2015/04/18 08:56:57
1148 dnl -----------
1149 dnl Check if the C compiler supports "inline".
1150 dnl $1 is the name of a shell variable to set if inline is supported
1151 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1152 AC_DEFUN([CF_C_INLINE],[
1153 AC_C_INLINE
1154 $1=
1155 if test "$ac_cv_c_inline" != no ; then
1156         $1=inline
1157         if test "$INTEL_COMPILER" = yes
1158         then
1159                 :
1160         elif test "$CLANG_COMPILER" = yes
1161         then
1162                 :
1163         elif test "$GCC" = yes
1164         then
1165                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1166                 cf_save_CFLAGS=$CFLAGS
1167                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1168                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1169                 [${cf_cv_main_return:-return} foo()],
1170                 [cf_cv_gcc_inline=yes],
1171                 [cf_cv_gcc_inline=no])
1172                 CFLAGS=$cf_save_CFLAGS
1173                 ])
1174                 if test "$cf_cv_gcc_inline" = yes ; then
1175                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1176                 fi
1177         fi
1178 fi
1179 AC_SUBST($1)
1180 ])dnl
1181 dnl ---------------------------------------------------------------------------
1182 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1183 dnl ----------
1184 dnl "dirname" is not portable, so we fake it with a shell script.
1185 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1186 dnl ---------------------------------------------------------------------------
1187 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1188 dnl ---------------
1189 AC_DEFUN([CF_DIRS_TO_MAKE],
1190 [
1191 DIRS_TO_MAKE="lib"
1192 for cf_item in $cf_list_models
1193 do
1194         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1195         for cf_item2 in $DIRS_TO_MAKE
1196         do
1197                 test $cf_item2 = $cf_subdir && break
1198         done
1199         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1200 done
1201 for cf_dir in $DIRS_TO_MAKE
1202 do
1203         test ! -d $cf_dir && mkdir $cf_dir
1204 done
1205 AC_SUBST(DIRS_TO_MAKE)
1206 ])dnl
1207 dnl ---------------------------------------------------------------------------
1208 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1209 dnl ---------------
1210 dnl You can always use "make -n" to see the actual options, but it's hard to
1211 dnl pick out/analyze warning messages when the compile-line is long.
1212 dnl
1213 dnl Sets:
1214 dnl     ECHO_LT - symbol to control if libtool is verbose
1215 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1216 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1217 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1218 dnl     ECHO_CC - symbol to put before any "cc" line
1219 dnl
1220 AC_DEFUN([CF_DISABLE_ECHO],[
1221 AC_MSG_CHECKING(if you want to see long compiling messages)
1222 CF_ARG_DISABLE(echo,
1223         [  --disable-echo          do not display "compiling" commands],
1224         [
1225         ECHO_LT='--silent'
1226         ECHO_LD='@echo linking [$]@;'
1227         RULE_CC='@echo compiling [$]<'
1228         SHOW_CC='@echo compiling [$]@'
1229         ECHO_CC='@'
1230 ],[
1231         ECHO_LT=''
1232         ECHO_LD=''
1233         RULE_CC=''
1234         SHOW_CC=''
1235         ECHO_CC=''
1236 ])
1237 AC_MSG_RESULT($enableval)
1238 AC_SUBST(ECHO_LT)
1239 AC_SUBST(ECHO_LD)
1240 AC_SUBST(RULE_CC)
1241 AC_SUBST(SHOW_CC)
1242 AC_SUBST(ECHO_CC)
1243 ])dnl
1244 dnl ---------------------------------------------------------------------------
1245 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1246 dnl ------------------------
1247 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1248 AC_MSG_CHECKING(if we want to use GNAT projects)
1249 CF_ARG_DISABLE(gnat-projects,
1250         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1251         [enable_gnat_projects=no],
1252         [enable_gnat_projects=yes])
1253 AC_MSG_RESULT($enable_gnat_projects)
1254 ])dnl
1255 dnl ---------------------------------------------------------------------------
1256 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1257 dnl ----------------
1258 dnl Combine no-leak checks with the libraries or tools that are used for the
1259 dnl checks.
1260 AC_DEFUN([CF_DISABLE_LEAKS],[
1261
1262 AC_REQUIRE([CF_WITH_DMALLOC])
1263 AC_REQUIRE([CF_WITH_DBMALLOC])
1264 AC_REQUIRE([CF_WITH_VALGRIND])
1265
1266 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1267 AC_ARG_ENABLE(leaks,
1268         [  --disable-leaks         test: free permanent memory, analyze leaks],
1269         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1270         : ${with_no_leaks:=no})
1271 AC_MSG_RESULT($with_no_leaks)
1272
1273 if test "$with_no_leaks" = yes ; then
1274         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1275         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1276 fi
1277 ])dnl
1278 dnl ---------------------------------------------------------------------------
1279 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1280 dnl --------------------------
1281 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1282 dnl the older "-version-info" feature.  The newer feature allows us to use
1283 dnl version numbering on shared libraries which make them compatible with
1284 dnl various systems.
1285 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1286 [
1287 AC_MSG_CHECKING(if libtool -version-number should be used)
1288 CF_ARG_DISABLE(libtool-version,
1289         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1290         [cf_libtool_version=no],
1291         [cf_libtool_version=yes])
1292 AC_MSG_RESULT($cf_libtool_version)
1293
1294 if test "$cf_libtool_version" = yes ; then
1295         LIBTOOL_VERSION="-version-number"
1296 else
1297         LIBTOOL_VERSION="-version-info"
1298         case "x$VERSION" in
1299         (x)
1300                 AC_MSG_WARN(VERSION was not set)
1301                 ;;
1302         (x*.*.*)
1303                 ABI_VERSION="$VERSION"
1304                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1305                 ;;
1306         (x*:*:*)
1307                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1308                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1309                 ;;
1310         (*)
1311                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1312                 ;;
1313         esac
1314 fi
1315
1316 AC_SUBST(ABI_VERSION)
1317 AC_SUBST(LIBTOOL_VERSION)
1318 ])dnl
1319 dnl ---------------------------------------------------------------------------
1320 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1321 dnl ---------------------
1322 dnl The rpath-hack makes it simpler to build programs, particularly with the
1323 dnl *BSD ports which may have essential libraries in unusual places.  But it
1324 dnl can interfere with building an executable for the base system.  Use this
1325 dnl option in that case.
1326 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1327 [
1328 AC_MSG_CHECKING(if rpath-hack should be disabled)
1329 CF_ARG_DISABLE(rpath-hack,
1330         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1331         [cf_disable_rpath_hack=yes],
1332         [cf_disable_rpath_hack=no])
1333 AC_MSG_RESULT($cf_disable_rpath_hack)
1334 if test "$cf_disable_rpath_hack" = no ; then
1335         CF_RPATH_HACK
1336 fi
1337 ])
1338 dnl ---------------------------------------------------------------------------
1339 dnl CF_ENABLE_PC_FILES version: 12 updated: 2015/04/17 21:13:04
1340 dnl ------------------
1341 dnl This is the "--enable-pc-files" option, which is available if there is a
1342 dnl pkg-config configuration on the local machine.
1343 AC_DEFUN([CF_ENABLE_PC_FILES],[
1344 AC_REQUIRE([CF_PKG_CONFIG])
1345 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1346
1347 if test "x$PKG_CONFIG" != xnone
1348 then
1349         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1350 else
1351         AC_MSG_CHECKING(if we should install .pc files)
1352 fi
1353
1354 AC_ARG_ENABLE(pc-files,
1355         [  --enable-pc-files       generate and install .pc files for pkg-config],
1356         [enable_pc_files=$enableval],
1357         [enable_pc_files=no])
1358 AC_MSG_RESULT($enable_pc_files)
1359
1360 if test "x$enable_pc_files" != xno
1361 then
1362         case "x$PKG_CONFIG_LIBDIR" in
1363         (xno|xyes)
1364                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1365                 MAKE_PC_FILES="#"
1366                 ;;
1367         (*)
1368                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1369                 MAKE_PC_FILES=
1370                 ;;
1371         esac
1372 else
1373         MAKE_PC_FILES="#"
1374 fi
1375 AC_SUBST(MAKE_PC_FILES)
1376 ])dnl
1377 dnl ---------------------------------------------------------------------------
1378 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1379 dnl ---------------
1380 dnl Check if the rpath option should be used, setting cache variable
1381 dnl cf_cv_enable_rpath if so.
1382 AC_DEFUN([CF_ENABLE_RPATH],
1383 [
1384 AC_MSG_CHECKING(if rpath option should be used)
1385 AC_ARG_ENABLE(rpath,
1386 [  --enable-rpath          use rpath option when generating shared libraries],
1387 [cf_cv_enable_rpath=$enableval],
1388 [cf_cv_enable_rpath=no])
1389 AC_MSG_RESULT($cf_cv_enable_rpath)
1390 ])dnl
1391 dnl ---------------------------------------------------------------------------
1392 dnl CF_ENABLE_STRING_HACKS version: 3 updated: 2013/01/26 16:26:12
1393 dnl ----------------------
1394 dnl On a few platforms, the compiler and/or loader nags with untruthful
1395 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1396 dnl and implying that most uses of the recommended alternatives are correct.
1397 dnl
1398 dnl Factually speaking, no one has actually counted the number of uses of these
1399 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1400 dnl instances are meaningless compared to the hundreds of millions of lines of
1401 dnl existing C code.
1402 dnl
1403 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1404 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1405 dnl standard - but evolved through phases, and older implementations are likely
1406 dnl to yield surprising results, as documented in manpages on various systems.
1407 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1408 [
1409 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1410 AC_ARG_ENABLE(string-hacks,
1411         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1412         [with_string_hacks=$enableval],
1413         [with_string_hacks=no])
1414 AC_MSG_RESULT($with_string_hacks)
1415
1416 if test "x$with_string_hacks" = "xyes"; then
1417         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1418         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1419         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1420 fi
1421 ])dnl
1422 dnl ---------------------------------------------------------------------------
1423 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1424 dnl --------
1425 dnl Check if 'errno' is declared in <errno.h>
1426 AC_DEFUN([CF_ERRNO],
1427 [
1428 CF_CHECK_ERRNO(errno)
1429 ])dnl
1430 dnl ---------------------------------------------------------------------------
1431 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1432 dnl ---------------
1433 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1434 dnl math.h and builtin.h, only for ncurses
1435 AC_DEFUN([CF_ETIP_DEFINES],
1436 [
1437 AC_MSG_CHECKING(for special defines needed for etip.h)
1438 cf_save_CXXFLAGS="$CXXFLAGS"
1439 cf_result="none"
1440
1441 # etip.h includes ncurses.h which includes ncurses_dll.h
1442 # But ncurses_dll.h is generated - fix here.
1443 test -d include || mkdir include
1444 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1445
1446 for cf_math in "" MATH_H
1447 do
1448 for cf_excp in "" MATH_EXCEPTION
1449 do
1450         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1451         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1452         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1453 AC_TRY_COMPILE([
1454 #include <etip.h.in>
1455 ],[],[
1456         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1457         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1458         cf_result="$cf_math $cf_excp"
1459         break 2
1460 ],[])
1461 done
1462 done
1463 AC_MSG_RESULT($cf_result)
1464 CXXFLAGS="$cf_save_CXXFLAGS"
1465 ])
1466 dnl ---------------------------------------------------------------------------
1467 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
1468 dnl ---------------
1469 dnl Find a library (specifically the linkage used in the code fragment),
1470 dnl searching for it if it is not already in the library path.
1471 dnl See also CF_ADD_SEARCHPATH.
1472 dnl
1473 dnl Parameters (4-on are optional):
1474 dnl     $1 = headers for library entrypoint
1475 dnl     $2 = code fragment for library entrypoint
1476 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1477 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1478 dnl     $5 = action to perform if not successful
1479 dnl     $6 = module name, if not the same as the library name
1480 dnl     $7 = extra libraries
1481 dnl
1482 dnl Sets these variables:
1483 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1484 dnl     $cf_cv_header_path_$3 - include-directory if needed
1485 dnl     $cf_cv_library_path_$3 - library-directory if needed
1486 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1487 AC_DEFUN([CF_FIND_LINKAGE],[
1488
1489 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1490 # will be set on completion of the AC_TRY_LINK below.
1491 cf_cv_header_path_$3=
1492 cf_cv_library_path_$3=
1493
1494 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1495
1496 cf_save_LIBS="$LIBS"
1497
1498 AC_TRY_LINK([$1],[$2],[
1499         cf_cv_find_linkage_$3=yes
1500         cf_cv_header_path_$3=/usr/include
1501         cf_cv_library_path_$3=/usr/lib
1502 ],[
1503
1504 LIBS="-l$3 $7 $cf_save_LIBS"
1505
1506 AC_TRY_LINK([$1],[$2],[
1507         cf_cv_find_linkage_$3=yes
1508         cf_cv_header_path_$3=/usr/include
1509         cf_cv_library_path_$3=/usr/lib
1510         cf_cv_library_file_$3="-l$3"
1511 ],[
1512         cf_cv_find_linkage_$3=no
1513         LIBS="$cf_save_LIBS"
1514
1515         CF_VERBOSE(find linkage for $3 library)
1516         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1517
1518         cf_save_CPPFLAGS="$CPPFLAGS"
1519         cf_test_CPPFLAGS="$CPPFLAGS"
1520
1521         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1522         for cf_cv_header_path_$3 in $cf_search
1523         do
1524                 if test -d $cf_cv_header_path_$3 ; then
1525                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1526                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1527                         AC_TRY_COMPILE([$1],[$2],[
1528                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1529                                 cf_cv_find_linkage_$3=maybe
1530                                 cf_test_CPPFLAGS="$CPPFLAGS"
1531                                 break],[
1532                                 CPPFLAGS="$cf_save_CPPFLAGS"
1533                                 ])
1534                 fi
1535         done
1536
1537         if test "$cf_cv_find_linkage_$3" = maybe ; then
1538
1539                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1540
1541                 cf_save_LIBS="$LIBS"
1542                 cf_save_LDFLAGS="$LDFLAGS"
1543
1544                 ifelse([$6],,,[
1545                 CPPFLAGS="$cf_test_CPPFLAGS"
1546                 LIBS="-l$3 $7 $cf_save_LIBS"
1547                 AC_TRY_LINK([$1],[$2],[
1548                         CF_VERBOSE(... found $3 library in system)
1549                         cf_cv_find_linkage_$3=yes])
1550                         CPPFLAGS="$cf_save_CPPFLAGS"
1551                         LIBS="$cf_save_LIBS"
1552                         ])
1553
1554                 if test "$cf_cv_find_linkage_$3" != yes ; then
1555                         CF_LIBRARY_PATH(cf_search,$3)
1556                         for cf_cv_library_path_$3 in $cf_search
1557                         do
1558                                 if test -d $cf_cv_library_path_$3 ; then
1559                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1560                                         CPPFLAGS="$cf_test_CPPFLAGS"
1561                                         LIBS="-l$3 $7 $cf_save_LIBS"
1562                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1563                                         AC_TRY_LINK([$1],[$2],[
1564                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1565                                         cf_cv_find_linkage_$3=yes
1566                                         cf_cv_library_file_$3="-l$3"
1567                                         break],[
1568                                         CPPFLAGS="$cf_save_CPPFLAGS"
1569                                         LIBS="$cf_save_LIBS"
1570                                         LDFLAGS="$cf_save_LDFLAGS"
1571                                         ])
1572                                 fi
1573                         done
1574                         CPPFLAGS="$cf_save_CPPFLAGS"
1575                         LDFLAGS="$cf_save_LDFLAGS"
1576                 fi
1577
1578         else
1579                 cf_cv_find_linkage_$3=no
1580         fi
1581         ],$7)
1582 ])
1583
1584 LIBS="$cf_save_LIBS"
1585
1586 if test "$cf_cv_find_linkage_$3" = yes ; then
1587 ifelse([$4],,[
1588         CF_ADD_INCDIR($cf_cv_header_path_$3)
1589         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1590         CF_ADD_LIB($3)
1591 ],[$4])
1592 else
1593 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1594 fi
1595 ])dnl
1596 dnl ---------------------------------------------------------------------------
1597 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
1598 dnl ------------------
1599 dnl Find an include-directory with the given leaf-name.  This is useful for
1600 dnl example with FreeBSD ports, which use this convention to distinguish
1601 dnl different versions of the same port.
1602 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1603         CF_SUBDIR_PATH(cf_search,$1,include)
1604         for cf_item in $cf_search
1605         do
1606                 case $cf_item in
1607                 (*/$1)
1608                         CF_ADD_INCDIR($cf_item)
1609                         ;;
1610                 esac
1611         done
1612 ])dnl
1613 dnl ---------------------------------------------------------------------------
1614 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
1615 dnl ------------------
1616 dnl Find a library-directory with the given leaf-name.  This is useful for
1617 dnl example with FreeBSD ports, which use this convention to distinguish
1618 dnl different versions of the same port.
1619 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1620         CF_SUBDIR_PATH(cf_search,$1,lib)
1621         for cf_item in $cf_search
1622         do
1623                 case $cf_item in
1624                 (*/$1)
1625                         CF_ADD_LIBDIR($cf_item)
1626                         ;;
1627                 esac
1628         done
1629 ])dnl
1630 dnl ---------------------------------------------------------------------------
1631 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1632 dnl -----------------
1633 dnl make ADAFLAGS consistent with CFLAGS
1634 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1635         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1636         case "$CFLAGS" in
1637         (*-g*)
1638                 CF_ADD_ADAFLAGS(-g)
1639                 ;;
1640         esac
1641         case "$CFLAGS" in
1642         (*-O*)
1643                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1644                 CF_ADD_ADAFLAGS($cf_O_flag)
1645                 ;;
1646         esac
1647         AC_MSG_RESULT($ADAFLAGS)
1648 ])dnl
1649 dnl ---------------------------------------------------------------------------
1650 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1651 dnl --------------
1652 dnl Forget that we saw the given tool.
1653 AC_DEFUN([CF_FORGET_TOOL],[
1654 unset ac_cv_prog_ac_ct_$1
1655 unset ac_ct_$1
1656 unset $1
1657 ])dnl
1658 dnl ---------------------------------------------------------------------------
1659 dnl CF_FUNC_DLSYM version: 3 updated: 2012/10/06 11:17:15
1660 dnl -------------
1661 dnl Test for dlsym() and related functions, as well as libdl.
1662 dnl
1663 dnl Sets
1664 dnl     $cf_have_dlsym
1665 dnl     $cf_have_libdl
1666 AC_DEFUN([CF_FUNC_DLSYM],[
1667 cf_have_dlsym=no
1668 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1669
1670 cf_have_libdl=no
1671 AC_CHECK_LIB(dl,dlsym,[
1672         cf_have_dlsym=yes
1673         cf_have_libdl=yes])])
1674
1675 if test "$cf_have_dlsym" = yes ; then
1676         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1677
1678         AC_MSG_CHECKING(whether able to link to dl*() functions)
1679         AC_TRY_LINK([#include <dlfcn.h>],[
1680                 void *obj;
1681                 if ((obj = dlopen("filename", 0)) != 0) {
1682                         if (dlsym(obj, "symbolname") == 0) {
1683                         dlclose(obj);
1684                         }
1685                 }],[
1686                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1687                 AC_MSG_ERROR(Cannot link test program for libdl)])
1688         AC_MSG_RESULT(ok)
1689 else
1690         AC_MSG_ERROR(Cannot find dlsym function)
1691 fi
1692 ])
1693 dnl ---------------------------------------------------------------------------
1694 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1695 dnl ---------------
1696 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1697 dnl is found, add our own version of memmove to the list of objects.
1698 AC_DEFUN([CF_FUNC_MEMMOVE],
1699 [
1700 AC_CHECK_FUNC(memmove,,[
1701 AC_CHECK_FUNC(bcopy,[
1702         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1703                 AC_TRY_RUN([
1704 int main() {
1705         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1706         char temp[40];
1707         bcopy(data, temp, sizeof(data));
1708         bcopy(temp+10, temp, 15);
1709         bcopy(temp+5, temp+15, 10);
1710         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1711 }
1712                 ],
1713                 [cf_cv_good_bcopy=yes],
1714                 [cf_cv_good_bcopy=no],
1715                 [cf_cv_good_bcopy=unknown])
1716                 ])
1717         ],[cf_cv_good_bcopy=no])
1718         if test "$cf_cv_good_bcopy" = yes ; then
1719                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1720         else
1721                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1722         fi
1723 ])])dnl
1724 dnl ---------------------------------------------------------------------------
1725 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1726 dnl -----------------
1727 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1728 dnl AIX 4.x, provide a non-working version.
1729 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1730 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1731 AC_TRY_RUN([
1732 #include <stdio.h>
1733 #include <errno.h>
1734 #include <time.h>
1735
1736 #ifdef HAVE_SYS_TIME_H
1737 #include <sys/time.h>
1738 #endif
1739
1740 int main() {
1741         struct timespec ts1, ts2;
1742         int code;
1743         ts1.tv_sec  = 0;
1744         ts1.tv_nsec = 750000000;
1745         ts2.tv_sec  = 0;
1746         ts2.tv_nsec = 0;
1747         errno = 0;
1748         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1749         ${cf_cv_main_return:-return}(code != 0);
1750 }
1751 ],
1752         [cf_cv_func_nanosleep=yes],
1753         [cf_cv_func_nanosleep=no],
1754         [cf_cv_func_nanosleep=unknown])])
1755
1756 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1757 ])
1758 dnl ---------------------------------------------------------------------------
1759 dnl CF_FUNC_OPENPTY version: 4 updated: 2015/04/18 08:56:57
1760 dnl ---------------
1761 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1762 dnl "util" library as well.
1763 AC_DEFUN([CF_FUNC_OPENPTY],
1764 [
1765 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1766 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1767         cf_save_LIBS="$LIBS"
1768         test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1769         for cf_header in pty.h libutil.h util.h
1770         do
1771         AC_TRY_LINK([
1772 #include <$cf_header>
1773 ],[
1774         int x = openpty((int *)0, (int *)0, (char *)0,
1775                                    (struct termios *)0, (struct winsize *)0);
1776 ],[
1777                 cf_cv_func_openpty=$cf_header
1778                 break
1779 ],[
1780                 cf_cv_func_openpty=no
1781 ])
1782         done
1783         LIBS="$cf_save_LIBS"
1784 ])
1785 ])dnl
1786 dnl ---------------------------------------------------------------------------
1787 dnl CF_FUNC_POLL version: 8 updated: 2012/10/04 05:24:07
1788 dnl ------------
1789 dnl See if the poll function really works.  Some platforms have poll(), but
1790 dnl it does not work for terminals or files.
1791 AC_DEFUN([CF_FUNC_POLL],[
1792 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1793 AC_TRY_RUN([
1794 #include <stdlib.h>
1795 #include <stdio.h>
1796 #include <unistd.h>
1797 #include <fcntl.h>
1798 #ifdef HAVE_POLL_H
1799 #include <poll.h>
1800 #else
1801 #include <sys/poll.h>
1802 #endif
1803 int main() {
1804         struct pollfd myfds;
1805         int ret;
1806
1807         /* check for Darwin bug with respect to "devices" */
1808         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
1809         if (myfds.fd < 0)
1810                 myfds.fd = 0;
1811         myfds.events = POLLIN;
1812         myfds.revents = 0;
1813
1814         ret = poll(&myfds, 1, 100);
1815
1816         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1817                 ret = -1;
1818         } else {
1819                 int fd = 0;
1820                 if (!isatty(fd)) {
1821                         fd = open("/dev/tty", 2);       /* O_RDWR */
1822                 }
1823
1824                 if (fd >= 0) {
1825                         /* also check with standard input */
1826                         myfds.fd = fd;
1827                         myfds.events = POLLIN;
1828                         myfds.revents = 0;
1829                         ret = poll(&myfds, 1, 100);
1830                 } else {
1831                         ret = -1;
1832                 }
1833         }
1834         ${cf_cv_main_return:-return}(ret < 0);
1835 }],
1836         [cf_cv_working_poll=yes],
1837         [cf_cv_working_poll=no],
1838         [cf_cv_working_poll=unknown])])
1839 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
1840 ])dnl
1841 dnl ---------------------------------------------------------------------------
1842 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
1843 dnl ---------------
1844 dnl Some old/broken variations define tcgetattr() only as a macro in
1845 dnl termio(s).h
1846 AC_DEFUN([CF_FUNC_TERMIOS],[
1847 AC_REQUIRE([CF_STRUCT_TERMIOS])
1848 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1849 AC_TRY_LINK([
1850 #include <sys/types.h>
1851 #ifdef HAVE_UNISTD_H
1852 #include <unistd.h>
1853 #endif
1854 #ifdef HAVE_TERMIOS_H
1855 #include <termios.h>
1856 #define TTY struct termios
1857 #else
1858 #ifdef HAVE_TERMIO_H
1859 #include <termio.h>
1860 #define TTY struct termio
1861 #endif
1862 #endif
1863 ],[
1864 TTY foo;
1865 tcgetattr(1, &foo);],
1866 [cf_cv_have_tcgetattr=yes],
1867 [cf_cv_have_tcgetattr=no])])
1868 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
1869 ])dnl
1870 dnl ---------------------------------------------------------------------------
1871 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
1872 dnl ---------------
1873 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1874 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1875 dnl other functions.
1876 AC_DEFUN([CF_FUNC_VSSCANF],
1877 [
1878 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1879 AC_TRY_LINK([
1880 #include <stdarg.h>
1881 #include <stdio.h>],[
1882         va_list ap;
1883         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1884 AC_TRY_LINK([
1885 #include <stdarg.h>
1886 #include <stdio.h>],[
1887         FILE strbuf;
1888         char *str = "from";
1889
1890         strbuf._flag = _IOREAD;
1891         strbuf._ptr = strbuf._base = (unsigned char *) str;
1892         strbuf._cnt = strlen(str);
1893         strbuf._file = _NFILE;
1894         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1895 AC_TRY_LINK([
1896 #include <stdarg.h>
1897 #include <stdio.h>],[
1898         FILE strbuf;
1899         char *str = "from";
1900
1901         strbuf._flag = _IOREAD;
1902         strbuf._ptr = strbuf._base = (unsigned char *) str;
1903         strbuf._cnt = strlen(str);
1904         strbuf._file = _NFILE;
1905         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1906 cf_cv_func_vsscanf=no])])])])
1907
1908 case $cf_cv_func_vsscanf in
1909 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
1910 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
1911 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
1912 esac
1913
1914 ])dnl
1915 dnl ---------------------------------------------------------------------------
1916 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
1917 dnl -----------------
1918 dnl Test for availability of useful gcc __attribute__ directives to quiet
1919 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1920 dnl to documentation, unrecognized directives cause older compilers to barf.
1921 AC_DEFUN([CF_GCC_ATTRIBUTES],
1922 [
1923 if test "$GCC" = yes
1924 then
1925 cat > conftest.i <<EOF
1926 #ifndef GCC_PRINTF
1927 #define GCC_PRINTF 0
1928 #endif
1929 #ifndef GCC_SCANF
1930 #define GCC_SCANF 0
1931 #endif
1932 #ifndef GCC_NORETURN
1933 #define GCC_NORETURN /* nothing */
1934 #endif
1935 #ifndef GCC_UNUSED
1936 #define GCC_UNUSED /* nothing */
1937 #endif
1938 EOF
1939 if test "$GCC" = yes
1940 then
1941         AC_CHECKING([for $CC __attribute__ directives])
1942 cat > conftest.$ac_ext <<EOF
1943 #line __oline__ "${as_me:-configure}"
1944 #include "confdefs.h"
1945 #include "conftest.h"
1946 #include "conftest.i"
1947 #if     GCC_PRINTF
1948 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1949 #else
1950 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1951 #endif
1952 #if     GCC_SCANF
1953 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1954 #else
1955 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1956 #endif
1957 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1958 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1959 extern void foo(void) GCC_NORETURN;
1960 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1961 EOF
1962         cf_printf_attribute=no
1963         cf_scanf_attribute=no
1964         for cf_attribute in scanf printf unused noreturn
1965         do
1966                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1967                 cf_directive="__attribute__(($cf_attribute))"
1968                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1969
1970                 case $cf_attribute in
1971                 (printf)
1972                         cf_printf_attribute=yes
1973                         cat >conftest.h <<EOF
1974 #define GCC_$cf_ATTRIBUTE 1
1975 EOF
1976                         ;;
1977                 (scanf)
1978                         cf_scanf_attribute=yes
1979                         cat >conftest.h <<EOF
1980 #define GCC_$cf_ATTRIBUTE 1
1981 EOF
1982                         ;;
1983                 (*)
1984                         cat >conftest.h <<EOF
1985 #define GCC_$cf_ATTRIBUTE $cf_directive
1986 EOF
1987                         ;;
1988                 esac
1989
1990                 if AC_TRY_EVAL(ac_compile); then
1991                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1992                         cat conftest.h >>confdefs.h
1993                         case $cf_attribute in
1994                         (noreturn)
1995                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1996                                 ;;
1997                         (printf)
1998                                 cf_value='/* nothing */'
1999                                 if test "$cf_printf_attribute" != no ; then
2000                                         cf_value='__attribute__((format(printf,fmt,var)))'
2001                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2002                                 fi
2003                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2004                                 ;;
2005                         (scanf)
2006                                 cf_value='/* nothing */'
2007                                 if test "$cf_scanf_attribute" != no ; then
2008                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2009                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2010                                 fi
2011                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2012                                 ;;
2013                         (unused)
2014                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2015                                 ;;
2016                         esac
2017                 fi
2018         done
2019 else
2020         fgrep define conftest.i >>confdefs.h
2021 fi
2022 rm -rf conftest*
2023 fi
2024 ])dnl
2025 dnl ---------------------------------------------------------------------------
2026 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2027 dnl --------------
2028 dnl Find version of gcc
2029 AC_DEFUN([CF_GCC_VERSION],[
2030 AC_REQUIRE([AC_PROG_CC])
2031 GCC_VERSION=none
2032 if test "$GCC" = yes ; then
2033         AC_MSG_CHECKING(version of $CC)
2034         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2035         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2036         AC_MSG_RESULT($GCC_VERSION)
2037 fi
2038 ])dnl
2039 dnl ---------------------------------------------------------------------------
2040 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
2041 dnl ---------------
2042 dnl Check if the compiler supports useful warning options.  There's a few that
2043 dnl we don't use, simply because they're too noisy:
2044 dnl
2045 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2046 dnl     -Wredundant-decls (system headers make this too noisy)
2047 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2048 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2049 dnl             is enabled for ncurses using "--enable-const".
2050 dnl     -pedantic
2051 dnl
2052 dnl Parameter:
2053 dnl     $1 is an optional list of gcc warning flags that a particular
2054 dnl             application might want to use, e.g., "no-unused" for
2055 dnl             -Wno-unused
2056 dnl Special:
2057 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2058 dnl
2059 AC_DEFUN([CF_GCC_WARNINGS],
2060 [
2061 AC_REQUIRE([CF_GCC_VERSION])
2062 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2063 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2064
2065 cat > conftest.$ac_ext <<EOF
2066 #line __oline__ "${as_me:-configure}"
2067 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2068 EOF
2069
2070 if test "$INTEL_COMPILER" = yes
2071 then
2072 # The "-wdXXX" options suppress warnings:
2073 # remark #1419: external declaration in primary source file
2074 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2075 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2076 # remark #193: zero used for undefined preprocessing identifier
2077 # remark #593: variable "curs_sb_left_arrow" was set but never used
2078 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2079 # remark #869: parameter "tw" was never referenced
2080 # remark #981: operands are evaluated in unspecified order
2081 # warning #279: controlling expression is constant
2082
2083         AC_CHECKING([for $CC warning options])
2084         cf_save_CFLAGS="$CFLAGS"
2085         EXTRA_CFLAGS="-Wall"
2086         for cf_opt in \
2087                 wd1419 \
2088                 wd1683 \
2089                 wd1684 \
2090                 wd193 \
2091                 wd593 \
2092                 wd279 \
2093                 wd810 \
2094                 wd869 \
2095                 wd981
2096         do
2097                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2098                 if AC_TRY_EVAL(ac_compile); then
2099                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2100                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2101                 fi
2102         done
2103         CFLAGS="$cf_save_CFLAGS"
2104
2105 elif test "$GCC" = yes
2106 then
2107         AC_CHECKING([for $CC warning options])
2108         cf_save_CFLAGS="$CFLAGS"
2109         EXTRA_CFLAGS=
2110         cf_warn_CONST=""
2111         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2112         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2113         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2114         for cf_opt in W Wall \
2115                 Wbad-function-cast \
2116                 Wcast-align \
2117                 Wcast-qual \
2118                 Wdeclaration-after-statement \
2119                 Wextra \
2120                 Winline \
2121                 Wmissing-declarations \
2122                 Wmissing-prototypes \
2123                 Wnested-externs \
2124                 Wpointer-arith \
2125                 Wshadow \
2126                 Wstrict-prototypes \
2127                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2128         do
2129                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2130                 if AC_TRY_EVAL(ac_compile); then
2131                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2132                         case $cf_opt in
2133                         (Wcast-qual)
2134                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2135                                 ;;
2136                         (Winline)
2137                                 case $GCC_VERSION in
2138                                 ([[34]].*)
2139                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2140                                         continue;;
2141                                 esac
2142                                 ;;
2143                         (Wpointer-arith)
2144                                 case $GCC_VERSION in
2145                                 ([[12]].*)
2146                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2147                                         continue;;
2148                                 esac
2149                                 ;;
2150                         esac
2151                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2152                 fi
2153         done
2154         CFLAGS="$cf_save_CFLAGS"
2155 fi
2156 rm -rf conftest*
2157
2158 AC_SUBST(EXTRA_CFLAGS)
2159 ])dnl
2160 dnl ---------------------------------------------------------------------------
2161 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2162 dnl ----------------
2163 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2164 dnl unistd.h or (nonstandard) in getopt.h
2165 AC_DEFUN([CF_GETOPT_HEADER],
2166 [
2167 AC_HAVE_HEADERS(unistd.h getopt.h)
2168 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2169 cf_cv_getopt_header=none
2170 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2171 do
2172 AC_TRY_COMPILE([
2173 #include <$cf_header>],
2174 [int x = optind; char *y = optarg],
2175 [cf_cv_getopt_header=$cf_header
2176  break])
2177 done
2178 ])
2179 if test $cf_cv_getopt_header != none ; then
2180         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2181 fi
2182 if test $cf_cv_getopt_header = getopt.h ; then
2183         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2184 fi
2185 ])dnl
2186 dnl ---------------------------------------------------------------------------
2187 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2188 dnl -----------------
2189 AC_DEFUN([CF_GNATPREP_OPT_T],[
2190 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2191 cf_cv_gnatprep_opt_t=no
2192 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2193 ])
2194 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2195 AC_SUBST(GNATPREP_OPTS)
2196 ])dnl
2197 dnl ---------------------------------------------------------------------------
2198 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2199 dnl ----------------
2200 AC_DEFUN([CF_GNAT_GENERICS],
2201 [
2202 AC_REQUIRE([CF_GNAT_VERSION])
2203
2204 AC_MSG_CHECKING(if GNAT supports generics)
2205 case $cf_gnat_version in
2206 (3.[[1-9]]*|[[4-9]].*)
2207         cf_gnat_generics=yes
2208         ;;
2209 (*)
2210         cf_gnat_generics=no
2211         ;;
2212 esac
2213 AC_MSG_RESULT($cf_gnat_generics)
2214
2215 if test "$cf_gnat_generics" = yes
2216 then
2217         cf_compile_generics=generics
2218         cf_generic_objects="\${GENOBJS}"
2219 else
2220         cf_compile_generics=
2221         cf_generic_objects=
2222 fi
2223
2224 AC_SUBST(cf_compile_generics)
2225 AC_SUBST(cf_generic_objects)
2226 ])dnl
2227 dnl ---------------------------------------------------------------------------
2228 dnl CF_GNAT_PROJECTS version: 8 updated: 2015/04/17 21:13:04
2229 dnl ----------------
2230 dnl GNAT projects are configured with ".gpr" project files.
2231 dnl GNAT libraries are a further development, using the project feature.
2232 AC_DEFUN([CF_GNAT_PROJECTS],
2233 [
2234 AC_REQUIRE([CF_GNAT_VERSION])
2235 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2236
2237 cf_gnat_libraries=no
2238 cf_gnat_projects=no
2239
2240 if test "$enable_gnat_projects" != no ; then
2241 AC_MSG_CHECKING(if GNAT supports project files)
2242 case $cf_gnat_version in
2243 (3.[[0-9]]*)
2244         ;;
2245 (*)
2246         case $cf_cv_system_name in
2247         (cygwin*|msys*)
2248                 ;;
2249         (*)
2250                 mkdir conftest.src conftest.bin conftest.lib
2251                 cd conftest.src
2252                 rm -rf conftest* *~conftest*
2253                 cat >>library.gpr <<CF_EOF
2254 project Library is
2255   Kind := External ("LIB_KIND");
2256   for Library_Name use "ConfTest";
2257   for Object_Dir use ".";
2258   for Library_ALI_Dir use External("LIBRARY_DIR");
2259   for Library_Version use External ("SONAME");
2260   for Library_Kind use Kind;
2261   for Library_Dir use External("BUILD_DIR");
2262   Source_Dir := External ("SOURCE_DIR");
2263   for Source_Dirs use (Source_Dir);
2264 end Library;
2265 CF_EOF
2266                 cat >>confpackage.ads <<CF_EOF
2267 package ConfPackage is
2268    procedure conftest;
2269 end ConfPackage;
2270 CF_EOF
2271                 cat >>confpackage.adb <<CF_EOF
2272 with Text_IO;
2273 package body ConfPackage is
2274    procedure conftest is
2275    begin
2276       Text_IO.Put ("Hello World");
2277       Text_IO.New_Line;
2278    end conftest;
2279 end ConfPackage;
2280 CF_EOF
2281                 if ( $cf_ada_make $ADAFLAGS \
2282                                 -Plibrary.gpr \
2283                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2284                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2285                                 -XSOURCE_DIR=`pwd` \
2286                                 -XSONAME=libConfTest.so.1 \
2287                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2288                         cf_gnat_projects=yes
2289                 fi
2290                 cd ..
2291                 if test -f conftest.lib/confpackage.ali
2292                 then
2293                         cf_gnat_libraries=yes
2294                 fi
2295                 rm -rf conftest* *~conftest*
2296                 ;;
2297         esac
2298         ;;
2299 esac
2300 AC_MSG_RESULT($cf_gnat_projects)
2301 fi # enable_gnat_projects
2302
2303 if test $cf_gnat_projects = yes
2304 then
2305         AC_MSG_CHECKING(if GNAT supports libraries)
2306         AC_MSG_RESULT($cf_gnat_libraries)
2307 fi
2308
2309 if test "$cf_gnat_projects" = yes
2310 then
2311         USE_OLD_MAKERULES="#"
2312         USE_GNAT_PROJECTS=""
2313 else
2314         USE_OLD_MAKERULES=""
2315         USE_GNAT_PROJECTS="#"
2316 fi
2317
2318 if test "$cf_gnat_libraries" = yes
2319 then
2320         USE_GNAT_LIBRARIES=""
2321 else
2322         USE_GNAT_LIBRARIES="#"
2323 fi
2324
2325 AC_SUBST(USE_OLD_MAKERULES)
2326 AC_SUBST(USE_GNAT_PROJECTS)
2327 AC_SUBST(USE_GNAT_LIBRARIES)
2328 ])dnl
2329 dnl ---------------------------------------------------------------------------
2330 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2331 dnl --------------
2332 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2333 dnl is noted that gnat may compile a tasking unit even for configurations which
2334 dnl fail at runtime.
2335 AC_DEFUN([CF_GNAT_SIGINT],[
2336 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2337 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2338
2339 package ConfTest is
2340
2341    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2342    pragma Unreserve_All_Interrupts;
2343    pragma Warnings (On);
2344
2345    protected Process is
2346       procedure Stop;
2347       function Continue return Boolean;
2348       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2349    private
2350       Done : Boolean := False;
2351    end Process;
2352
2353 end ConfTest;],
2354 [package body ConfTest is
2355    protected body Process is
2356       procedure Stop is
2357       begin
2358          Done := True;
2359       end Stop;
2360       function Continue return Boolean is
2361       begin
2362          return not Done;
2363       end Continue;
2364    end Process;
2365 end ConfTest;],
2366         [cf_cv_gnat_sigint=yes],
2367         [cf_cv_gnat_sigint=no])])
2368
2369 if test $cf_cv_gnat_sigint = yes ; then
2370         USE_GNAT_SIGINT=""
2371 else
2372         USE_GNAT_SIGINT="#"
2373 fi
2374 AC_SUBST(USE_GNAT_SIGINT)
2375 ])dnl
2376 dnl ---------------------------------------------------------------------------
2377 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2378 dnl ----------------
2379 dnl Verify that a test program compiles/links with GNAT.
2380 dnl $cf_ada_make is set to the program that compiles/links
2381 dnl $ADAFLAGS may be set to the GNAT flags.
2382 dnl
2383 dnl $1 is the text of the spec
2384 dnl $2 is the text of the body
2385 dnl $3 is the shell command to execute if successful
2386 dnl $4 is the shell command to execute if not successful
2387 AC_DEFUN([CF_GNAT_TRY_LINK],
2388 [
2389 rm -rf conftest* *~conftest*
2390 cat >>conftest.ads <<CF_EOF
2391 $1
2392 CF_EOF
2393 cat >>conftest.adb <<CF_EOF
2394 $2
2395 CF_EOF
2396 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2397 ifelse($3,,      :,[      $3])
2398 ifelse($4,,,[else
2399    $4])
2400 fi
2401 rm -rf conftest* *~conftest*
2402 ])dnl
2403 dnl ---------------------------------------------------------------------------
2404 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2405 dnl ---------------
2406 dnl Verify that a test program compiles and runs with GNAT
2407 dnl $cf_ada_make is set to the program that compiles/links
2408 dnl $ADAFLAGS may be set to the GNAT flags.
2409 dnl
2410 dnl $1 is the text of the spec
2411 dnl $2 is the text of the body
2412 dnl $3 is the shell command to execute if successful
2413 dnl $4 is the shell command to execute if not successful
2414 AC_DEFUN([CF_GNAT_TRY_RUN],
2415 [
2416 rm -rf conftest* *~conftest*
2417 cat >>conftest.ads <<CF_EOF
2418 $1
2419 CF_EOF
2420 cat >>conftest.adb <<CF_EOF
2421 $2
2422 CF_EOF
2423 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2424    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2425 ifelse($3,,      :,[      $3])
2426 ifelse($4,,,[   else
2427       $4])
2428    fi
2429 ifelse($4,,,[else
2430    $4])
2431 fi
2432 rm -rf conftest* *~conftest*
2433 ])dnl
2434 dnl ---------------------------------------------------------------------------
2435 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
2436 dnl ---------------
2437 dnl Verify version of GNAT.
2438 AC_DEFUN([CF_GNAT_VERSION],
2439 [
2440 AC_MSG_CHECKING(for gnat version)
2441 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2442         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2443         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2444 AC_MSG_RESULT($cf_gnat_version)
2445
2446 case $cf_gnat_version in
2447 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
2448         cf_cv_prog_gnat_correct=yes
2449         ;;
2450 (*)
2451         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2452         cf_cv_prog_gnat_correct=no
2453         ;;
2454 esac
2455 ])
2456 dnl ---------------------------------------------------------------------------
2457 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2458 dnl -------------
2459 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2460 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2461 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2462 dnl since it is interwoven with GNU extensions.
2463 dnl
2464 dnl Well, yes we could work around it...
2465 AC_DEFUN([CF_GNU_SOURCE],
2466 [
2467 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2468 AC_TRY_COMPILE([#include <sys/types.h>],[
2469 #ifndef _XOPEN_SOURCE
2470 make an error
2471 #endif],
2472         [cf_cv_gnu_source=no],
2473         [cf_save="$CPPFLAGS"
2474          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2475          AC_TRY_COMPILE([#include <sys/types.h>],[
2476 #ifdef _XOPEN_SOURCE
2477 make an error
2478 #endif],
2479         [cf_cv_gnu_source=no],
2480         [cf_cv_gnu_source=yes])
2481         CPPFLAGS="$cf_save"
2482         ])
2483 ])
2484 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2485 ])dnl
2486 dnl ---------------------------------------------------------------------------
2487 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
2488 dnl --------------
2489 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2490 dnl problem :-).  If we have the compiler but no library, we'll be able to
2491 dnl configure, but won't be able to build the c++ demo program.
2492 AC_DEFUN([CF_GPP_LIBRARY],
2493 [
2494 cf_cxx_library=unknown
2495 case $cf_cv_system_name in
2496 (os2*)
2497         cf_gpp_libname=gpp
2498         ;;
2499 (*)
2500         cf_gpp_libname=g++
2501         ;;
2502 esac
2503 if test "$GXX" = yes; then
2504         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2505         cf_save="$LIBS"
2506         CF_ADD_LIB($cf_gpp_libname)
2507         AC_TRY_LINK([
2508 #include <$cf_gpp_libname/builtin.h>
2509         ],
2510         [two_arg_error_handler_t foo2 = lib_error_handler],
2511         [cf_cxx_library=yes
2512          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2513          if test "$cf_gpp_libname" = cpp ; then
2514             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2515          else
2516             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2517          fi],
2518         [AC_TRY_LINK([
2519 #include <builtin.h>
2520         ],
2521         [two_arg_error_handler_t foo2 = lib_error_handler],
2522         [cf_cxx_library=yes
2523          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2524          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2525         [cf_cxx_library=no])])
2526         LIBS="$cf_save"
2527         AC_MSG_RESULT($cf_cxx_library)
2528 fi
2529 ])dnl
2530 dnl ---------------------------------------------------------------------------
2531 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2532 dnl --------------
2533 dnl Check for version of g++
2534 AC_DEFUN([CF_GXX_VERSION],[
2535 AC_REQUIRE([AC_PROG_CPP])
2536 GXX_VERSION=none
2537 if test "$GXX" = yes; then
2538         AC_MSG_CHECKING(version of ${CXX:-g++})
2539         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2540         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2541         AC_MSG_RESULT($GXX_VERSION)
2542 fi
2543 ])dnl
2544 dnl ---------------------------------------------------------------------------
2545 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
2546 dnl ---------------
2547 dnl Check if the compiler supports useful warning options.
2548 dnl
2549 dnl Most of gcc's options apply to g++, except:
2550 dnl     -Wbad-function-cast
2551 dnl     -Wmissing-declarations
2552 dnl     -Wnested-externs
2553 dnl
2554 dnl Omit a few (for now):
2555 dnl     -Winline
2556 dnl
2557 dnl Parameter:
2558 dnl     $1 is an optional list of g++ warning flags that a particular
2559 dnl             application might want to use, e.g., "no-unused" for
2560 dnl             -Wno-unused
2561 dnl Special:
2562 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2563 dnl
2564 AC_DEFUN([CF_GXX_WARNINGS],
2565 [
2566
2567 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2568 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2569
2570 AC_REQUIRE([CF_GXX_VERSION])
2571
2572 AC_LANG_SAVE
2573 AC_LANG_CPLUSPLUS
2574
2575 cat > conftest.$ac_ext <<EOF
2576 #line __oline__ "configure"
2577 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2578 EOF
2579
2580 if test "$INTEL_CPLUSPLUS" = yes
2581 then
2582 # The "-wdXXX" options suppress warnings:
2583 # remark #1419: external declaration in primary source file
2584 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2585 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2586 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2587 # remark #193: zero used for undefined preprocessing identifier
2588 # remark #593: variable "curs_sb_left_arrow" was set but never used
2589 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2590 # remark #869: parameter "tw" was never referenced
2591 # remark #981: operands are evaluated in unspecified order
2592 # warning #269: invalid format string conversion
2593
2594         AC_CHECKING([for $CC warning options])
2595         cf_save_CXXFLAGS="$CXXFLAGS"
2596         EXTRA_CXXFLAGS="-Wall"
2597         for cf_opt in \
2598                 wd1419 \
2599                 wd1682 \
2600                 wd1683 \
2601                 wd1684 \
2602                 wd193 \
2603                 wd279 \
2604                 wd593 \
2605                 wd810 \
2606                 wd869 \
2607                 wd981
2608         do
2609                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2610                 if AC_TRY_EVAL(ac_compile); then
2611                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2612                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2613                 fi
2614         done
2615         CXXFLAGS="$cf_save_CXXFLAGS"
2616
2617 elif test "$GXX" = yes
2618 then
2619         AC_CHECKING([for $CXX warning options])
2620         cf_save_CXXFLAGS="$CXXFLAGS"
2621         EXTRA_CXXFLAGS="-W -Wall"
2622         cf_gxx_extra_warnings=""
2623         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2624         case "$GCC_VERSION" in
2625         ([[1-2]].*)
2626                 ;;
2627         (*)
2628                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2629                 ;;
2630         esac
2631         for cf_opt in \
2632                 Wabi \
2633                 fabi-version=0 \
2634                 Wextra \
2635                 Wignored-qualifiers \
2636                 Wlogical-op \
2637                 Woverloaded-virtual \
2638                 Wsign-promo \
2639                 Wsynth \
2640                 Wold-style-cast \
2641                 Wcast-align \
2642                 Wcast-qual \
2643                 Wpointer-arith \
2644                 Wshadow \
2645                 Wundef $cf_gxx_extra_warnings $1
2646         do
2647                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2648                 if AC_TRY_EVAL(ac_compile); then
2649                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2650                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2651                 else
2652                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2653                 fi
2654         done
2655         CXXFLAGS="$cf_save_CXXFLAGS"
2656 fi
2657
2658 rm -rf conftest*
2659 AC_LANG_RESTORE
2660 AC_SUBST(EXTRA_CXXFLAGS)
2661 ])dnl
2662 dnl ---------------------------------------------------------------------------
2663 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
2664 dnl ------------
2665 dnl Look for an instance of the Berkeley hashed database.
2666 dnl
2667 dnl $1 = optional parameter, to specify install-prefix for the database.
2668 AC_DEFUN([CF_HASHED_DB],
2669 [
2670 ifelse([$1],,,[
2671 case $1 in
2672 (yes|*able*)
2673         ;;
2674 (*)
2675         if test -d "$1" ; then
2676                 CF_ADD_INCDIR($1/include)
2677                 CF_ADD_LIBDIR($1/lib)
2678         else
2679                 case "$1" in
2680                 (./*|../*|/*)
2681                         AC_MSG_WARN(no such directory $1)
2682                         ;;
2683                 (*)
2684                         CF_FIND_SUB_INCDIR($1)
2685                         CF_FIND_SUB_LIBDIR($1)
2686                         ;;
2687                 esac
2688         fi
2689 esac
2690 ])
2691 AC_CHECK_HEADER(db.h,[
2692 CF_HASHED_DB_VERSION
2693 if test "$cf_cv_hashed_db_version" = unknown ; then
2694         AC_MSG_ERROR(Cannot determine version of db)
2695 else
2696         CF_HASHED_DB_LIBS
2697         if test "$cf_cv_hashed_db_libs" = unknown ; then
2698                 AC_MSG_ERROR(Cannot determine library for db)
2699         elif test "$cf_cv_hashed_db_libs" != default ; then
2700                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2701         fi
2702 fi
2703 ],[
2704         AC_MSG_ERROR(Cannot find db.h)
2705 ])
2706 ])dnl
2707 dnl ---------------------------------------------------------------------------
2708 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2709 dnl -----------------
2710 dnl Given that we have the header and version for hashed database, find the
2711 dnl library information.
2712 AC_DEFUN([CF_HASHED_DB_LIBS],
2713 [
2714 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2715 cf_cv_hashed_db_libs=unknown
2716 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2717 do
2718         cf_save_libs="$LIBS"
2719         if test -n "$cf_db_libs"; then
2720                 CF_ADD_LIB($cf_db_libs)
2721         fi
2722         CF_MSG_LOG(checking for library "$cf_db_libs")
2723         AC_TRY_LINK([
2724 $ac_includes_default
2725 #include <db.h>
2726 ],[
2727         char *path = "/tmp/foo";
2728 #ifdef DB_VERSION_MAJOR
2729 #if DB_VERSION_MAJOR >= 4
2730         DB *result = 0;
2731         db_create(&result, NULL, 0);
2732         result->open(result,
2733                 NULL,
2734                 path,
2735                 path,
2736                 DB_HASH,
2737                 DB_CREATE,
2738                 0644);
2739 #elif DB_VERSION_MAJOR >= 3
2740         DB *result = 0;
2741         db_create(&result, NULL, 0);
2742         result->open(result,
2743                 path,
2744                 path,
2745                 DB_HASH,
2746                 DB_CREATE,
2747                 0644);
2748 #elif DB_VERSION_MAJOR >= 2
2749         DB *result = 0;
2750         db_open(path,
2751                 DB_HASH,
2752                 DB_CREATE,
2753                 0644,
2754                 (DB_ENV *) 0,
2755                 (DB_INFO *) 0,
2756                 &result);
2757 #endif /* DB_VERSION_MAJOR */
2758 #else
2759         DB *result = dbopen(path,
2760                      2,
2761                      0644,
2762                      DB_HASH,
2763                      0);
2764 #endif
2765         ${cf_cv_main_return:-return}(result != 0)
2766 ],[
2767         if test -n "$cf_db_libs" ; then
2768                 cf_cv_hashed_db_libs=$cf_db_libs
2769         else
2770                 cf_cv_hashed_db_libs=default
2771         fi
2772         LIBS="$cf_save_libs"
2773         break
2774 ])
2775         LIBS="$cf_save_libs"
2776 done
2777 ])
2778 ])dnl
2779 dnl ---------------------------------------------------------------------------
2780 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
2781 dnl --------------------
2782 dnl Given that we have the header file for hashed database, find the version
2783 dnl information.
2784 AC_DEFUN([CF_HASHED_DB_VERSION],
2785 [
2786 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2787 cf_cv_hashed_db_version=unknown
2788
2789 for cf_db_version in 1 2 3 4 5 6
2790 do
2791         CF_MSG_LOG(checking for db version $cf_db_version)
2792         AC_TRY_COMPILE([
2793 $ac_includes_default
2794 #include <db.h>
2795
2796 #ifdef DB_VERSION_MAJOR
2797         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2798 #if $cf_db_version == DB_VERSION_MAJOR
2799         /* ok */
2800 #else
2801         make an error
2802 #endif
2803 #else
2804 #if $cf_db_version == 1
2805         /* ok: assuming this is DB 1.8.5 */
2806 #else
2807         make an error
2808 #endif
2809 #endif
2810 ],[DBT *foo = 0],[
2811         cf_cv_hashed_db_version=$cf_db_version
2812         break
2813         ])
2814 done
2815 ])
2816 ])dnl
2817 dnl ---------------------------------------------------------------------------
2818 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
2819 dnl --------------
2820 dnl Construct a search-list of directories for a nonstandard header-file
2821 dnl
2822 dnl Parameters
2823 dnl     $1 = the variable to return as result
2824 dnl     $2 = the package name
2825 AC_DEFUN([CF_HEADER_PATH],
2826 [
2827 $1=
2828
2829 # collect the current set of include-directories from compiler flags
2830 cf_header_path_list=""
2831 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2832         for cf_header_path in $CPPFLAGS $CFLAGS
2833         do
2834                 case $cf_header_path in
2835                 (-I*)
2836                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2837                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2838                         cf_header_path_list="$cf_header_path_list [$]$1"
2839                         ;;
2840                 esac
2841         done
2842 fi
2843
2844 # add the variations for the package we are looking for
2845 CF_SUBDIR_PATH($1,$2,include)
2846
2847 test "$includedir" != NONE && \
2848 test "$includedir" != "/usr/include" && \
2849 test -d "$includedir" && {
2850         test -d $includedir &&    $1="[$]$1 $includedir"
2851         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2852 }
2853
2854 test "$oldincludedir" != NONE && \
2855 test "$oldincludedir" != "/usr/include" && \
2856 test -d "$oldincludedir" && {
2857         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2858         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2859 }
2860
2861 $1="[$]$1 $cf_header_path_list"
2862 ])dnl
2863 dnl ---------------------------------------------------------------------------
2864 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2865 dnl ---------------
2866 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2867 AC_DEFUN([CF_HELP_MESSAGE],
2868 [AC_DIVERT_HELP([$1])dnl
2869 ])dnl
2870 dnl ---------------------------------------------------------------------------
2871 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
2872 dnl ---------------
2873 dnl Construct the list of include-options according to whether we're building
2874 dnl in the source directory or using '--srcdir=DIR' option.
2875 AC_DEFUN([CF_INCLUDE_DIRS],
2876 [
2877 if test "$srcdir" != "."; then
2878         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
2879 fi
2880 CPPFLAGS="-I../include $CPPFLAGS"
2881 if test "$srcdir" != "."; then
2882         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
2883 fi
2884 CPPFLAGS="-I. $CPPFLAGS"
2885 AC_SUBST(CPPFLAGS)
2886 ])dnl
2887 dnl ---------------------------------------------------------------------------
2888 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
2889 dnl -----------------
2890 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2891 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2892 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2893 dnl
2894 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2895 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2896 dnl the wrappers for gcc and g++ warnings.
2897 dnl
2898 dnl $1 = GCC (default) or GXX
2899 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2900 dnl $3 = CFLAGS (default) or CXXFLAGS
2901 AC_DEFUN([CF_INTEL_COMPILER],[
2902 AC_REQUIRE([AC_CANONICAL_HOST])
2903 ifelse([$2],,INTEL_COMPILER,[$2])=no
2904
2905 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2906         case $host_os in
2907         (linux*|gnu*)
2908                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2909                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2910                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2911                 AC_TRY_COMPILE([],[
2912 #ifdef __INTEL_COMPILER
2913 #else
2914 make an error
2915 #endif
2916 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2917 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2918 ],[])
2919                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2920                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2921                 ;;
2922         esac
2923 fi
2924 ])dnl
2925 dnl ---------------------------------------------------------------------------
2926 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
2927 dnl ----------
2928 dnl Check if we have either a function or macro for 'isascii()'.
2929 AC_DEFUN([CF_ISASCII],
2930 [
2931 AC_MSG_CHECKING(for isascii)
2932 AC_CACHE_VAL(cf_cv_have_isascii,[
2933         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2934         [cf_cv_have_isascii=yes],
2935         [cf_cv_have_isascii=no])
2936 ])dnl
2937 AC_MSG_RESULT($cf_cv_have_isascii)
2938 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
2939 ])dnl
2940 dnl ---------------------------------------------------------------------------
2941 dnl CF_LARGEFILE version: 9 updated: 2015/04/18 08:56:57
2942 dnl ------------
2943 dnl Add checks for large file support.
2944 AC_DEFUN([CF_LARGEFILE],[
2945 ifdef([AC_FUNC_FSEEKO],[
2946         AC_SYS_LARGEFILE
2947         if test "$enable_largefile" != no ; then
2948         AC_FUNC_FSEEKO
2949
2950         # Normally we would collect these definitions in the config.h,
2951         # but (like _XOPEN_SOURCE), some environments rely on having these
2952         # defined before any of the system headers are included.  Another
2953         # case comes up with C++, e.g., on AIX the compiler compiles the
2954         # header files by themselves before looking at the body files it is
2955         # told to compile.  For ncurses, those header files do not include
2956         # the config.h
2957         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2958         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2959         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2960
2961         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2962                 AC_TRY_COMPILE([
2963 #include <sys/types.h>
2964 #include <dirent.h>
2965                 ],[
2966                 /* if transitional largefile support is setup, this is true */
2967                 extern struct dirent64 * readdir(DIR *);
2968                 struct dirent64 *x = readdir((DIR *)0);
2969                 struct dirent *y = readdir((DIR *)0);
2970                 int z = x - y;
2971                 ],
2972                 [cf_cv_struct_dirent64=yes],
2973                 [cf_cv_struct_dirent64=no])
2974         ])
2975         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
2976         fi
2977 ])
2978 ])
2979 dnl ---------------------------------------------------------------------------
2980 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
2981 dnl -----------------
2982 dnl Check for compiler/linker flags used to temporarily force usage of static
2983 dnl libraries.  This depends on the compiler and platform.  Use this to help
2984 dnl ensure that the linker picks up a given library based on its position in
2985 dnl the list of linker options and libraries.
2986 AC_DEFUN([CF_LDFLAGS_STATIC],[
2987
2988 if test "$GCC" = yes ; then
2989         case $cf_cv_system_name in
2990         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
2991                 LDFLAGS_STATIC=
2992                 LDFLAGS_SHARED=
2993                 ;;
2994         (*)     # normally, except when broken
2995                 LDFLAGS_STATIC=-static
2996                 LDFLAGS_SHARED=-dynamic
2997                 ;;
2998         esac
2999 else
3000         case $cf_cv_system_name in
3001         (aix[[4-7]]*)   # from ld manpage
3002                 LDFLAGS_STATIC=-bstatic
3003                 LDFLAGS_SHARED=-bdynamic
3004                 ;;
3005         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3006                 # We could also use just "archive" and "shared".
3007                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3008                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3009                 ;;
3010         (irix*)         # from ld manpage IRIX64
3011                 LDFLAGS_STATIC=-Bstatic
3012                 LDFLAGS_SHARED=-Bdynamic
3013                 ;;
3014         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3015                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3016                 LDFLAGS_STATIC=-noso
3017                 LDFLAGS_SHARED=-so_archive
3018                 ;;
3019         (solaris2*)
3020                 LDFLAGS_STATIC=-Bstatic
3021                 LDFLAGS_SHARED=-Bdynamic
3022                 ;;
3023         esac
3024 fi
3025
3026 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3027 then
3028         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3029
3030         rm -f libconftest.a
3031         cat >conftest.$ac_ext <<EOF
3032 #line __oline__ "configure"
3033 #include <stdio.h>
3034 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3035 EOF
3036         if AC_TRY_EVAL(ac_compile) ; then
3037                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3038                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3039         fi
3040         rm -f conftest.*
3041
3042         cf_save_LIBS="$LIBS"
3043
3044         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3045         AC_TRY_LINK([
3046 #line __oline__ "configure"
3047 #include <stdio.h>
3048 int cf_ldflags_static(FILE *fp);
3049 ],[
3050         return cf_ldflags_static(stdin);
3051 ],[
3052         # some linkers simply ignore the -dynamic
3053         case x`file conftest$ac_exeext 2>/dev/null` in
3054         (*static*)
3055                 cf_ldflags_static=no
3056                 ;;
3057         (*)
3058                 cf_ldflags_static=yes
3059                 ;;
3060         esac
3061 ],[cf_ldflags_static=no])
3062
3063         rm -f libconftest.*
3064         LIBS="$cf_save_LIBS"
3065
3066         AC_MSG_RESULT($cf_ldflags_static)
3067
3068         if test $cf_ldflags_static != yes
3069         then
3070                 LDFLAGS_STATIC=
3071                 LDFLAGS_SHARED=
3072         fi
3073 else
3074         LDFLAGS_STATIC=
3075         LDFLAGS_SHARED=
3076 fi
3077
3078 AC_SUBST(LDFLAGS_STATIC)
3079 AC_SUBST(LDFLAGS_SHARED)
3080 ])
3081 dnl ---------------------------------------------------------------------------
3082 dnl CF_LD_RPATH_OPT version: 6 updated: 2015/04/12 15:39:00
3083 dnl ---------------
3084 dnl For the given system and compiler, find the compiler flags to pass to the
3085 dnl loader to use the "rpath" feature.
3086 AC_DEFUN([CF_LD_RPATH_OPT],
3087 [
3088 AC_REQUIRE([CF_CHECK_CACHE])
3089
3090 LD_RPATH_OPT=
3091 AC_MSG_CHECKING(for an rpath option)
3092 case $cf_cv_system_name in
3093 (irix*)
3094         if test "$GCC" = yes; then
3095                 LD_RPATH_OPT="-Wl,-rpath,"
3096         else
3097                 LD_RPATH_OPT="-rpath "
3098         fi
3099         ;;
3100 (linux*|gnu*|k*bsd*-gnu)
3101         LD_RPATH_OPT="-Wl,-rpath,"
3102         ;;
3103 (openbsd[[2-9]].*|mirbsd*)
3104         LD_RPATH_OPT="-Wl,-rpath,"
3105         ;;
3106 (dragonfly*|freebsd*)
3107         LD_RPATH_OPT="-rpath "
3108         ;;
3109 (netbsd*)
3110         LD_RPATH_OPT="-Wl,-rpath,"
3111         ;;
3112 (osf*|mls+*)
3113         LD_RPATH_OPT="-rpath "
3114         ;;
3115 (solaris2*)
3116         LD_RPATH_OPT="-R"
3117         ;;
3118 (*)
3119         ;;
3120 esac
3121 AC_MSG_RESULT($LD_RPATH_OPT)
3122
3123 case "x$LD_RPATH_OPT" in
3124 (x-R*)
3125         AC_MSG_CHECKING(if we need a space after rpath option)
3126         cf_save_LIBS="$LIBS"
3127         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3128         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3129         LIBS="$cf_save_LIBS"
3130         AC_MSG_RESULT($cf_rpath_space)
3131         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3132         ;;
3133 esac
3134 ])dnl
3135 dnl ---------------------------------------------------------------------------
3136 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3137 dnl ---------------
3138 dnl Construct a search-list of directories for a nonstandard library-file
3139 dnl
3140 dnl Parameters
3141 dnl     $1 = the variable to return as result
3142 dnl     $2 = the package name
3143 AC_DEFUN([CF_LIBRARY_PATH],
3144 [
3145 $1=
3146 cf_library_path_list=""
3147 if test -n "${LDFLAGS}${LIBS}" ; then
3148         for cf_library_path in $LDFLAGS $LIBS
3149         do
3150                 case $cf_library_path in
3151                 (-L*)
3152                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3153                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3154                         cf_library_path_list="$cf_library_path_list [$]$1"
3155                         ;;
3156                 esac
3157         done
3158 fi
3159
3160 CF_SUBDIR_PATH($1,$2,lib)
3161
3162 $1="$cf_library_path_list [$]$1"
3163 ])dnl
3164 dnl ---------------------------------------------------------------------------
3165 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3166 dnl ------------------
3167 AC_DEFUN([CF_LIBTOOL_VERSION],[
3168 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3169 then
3170         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3171 else
3172         cf_cv_libtool_version=
3173 fi
3174 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3175 ])dnl
3176 dnl ---------------------------------------------------------------------------
3177 dnl CF_LIB_PREFIX version: 11 updated: 2015/04/18 08:56:57
3178 dnl -------------
3179 dnl Compute the library-prefix for the given host system
3180 dnl $1 = variable to set
3181 define([CF_LIB_PREFIX],
3182 [
3183         case $cf_cv_system_name in
3184         (OS/2*|os2*)
3185                 LIB_PREFIX=''
3186                 ;;
3187         (*)     LIB_PREFIX='lib'
3188                 ;;
3189         esac
3190 ifelse($1,,,[$1=$LIB_PREFIX])
3191         AC_SUBST(LIB_PREFIX)
3192 ])dnl
3193 dnl ---------------------------------------------------------------------------
3194 dnl CF_LIB_RULES version: 80 updated: 2015/04/17 21:13:04
3195 dnl ------------
3196 dnl Append definitions and rules for the given models to the subdirectory
3197 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3198 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3199 dnl the corresponding makefile to list the models that we'll generate.
3200 dnl
3201 dnl For shared libraries, make a list of symbolic links to construct when
3202 dnl generating each library.  The convention used for Linux is the simplest
3203 dnl one:
3204 dnl     lib<name>.so    ->
3205 dnl     lib<name>.so.<major>    ->
3206 dnl     lib<name>.so.<maj>.<minor>
3207 dnl
3208 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3209 AC_DEFUN([CF_LIB_RULES],
3210 [
3211 cf_prefix=$LIB_PREFIX
3212 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3213
3214 case $cf_cv_shlib_version in
3215 (cygdll|msysdll|mingw)
3216         TINFO_NAME=$TINFO_ARG_SUFFIX
3217         TINFO_SUFFIX=.dll
3218         ;;
3219 esac
3220
3221 if test -n "$TINFO_SUFFIX" ; then
3222         case $TINFO_SUFFIX in
3223         (tw*)
3224                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
3225                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
3226                 ;;
3227         (t*)
3228                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
3229                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
3230                 ;;
3231         (w*)
3232                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
3233                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
3234                 ;;
3235         esac
3236 fi
3237
3238 for cf_dir in $SRC_SUBDIRS
3239 do
3240         if test ! -d $srcdir/$cf_dir ; then
3241                 continue
3242         elif test -f $srcdir/$cf_dir/modules; then
3243
3244                 SHARED_LIB=
3245                 Libs_To_Make=
3246
3247                 cf_sed_options=
3248                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3249                 then
3250                         cf_sed_options="$cf_sed_options -e \"s/NCURSES\\([[WT]]\\+\\)\?_/NCURSES\\1${cf_cv_abi_version}_/g\""
3251                 fi
3252
3253                 if test "x$WILDCARD_SYMS" = xno
3254                 then
3255                         cf_sed_options="$cf_sed_options -e \"s/_\*;//g\""
3256                 fi
3257
3258                 if test "x$cf_sed_options" != "x"
3259                 then
3260                         cat >>$cf_dir/Makefile <<CF_EOF
3261
3262 # Generated by CF_LIB_RULES
3263 resulting.map: $UNALTERED_SYMS
3264         sed $cf_sed_options < $UNALTERED_SYMS >\[$]@
3265
3266 clean::
3267         rm -f resulting.map
3268 CF_EOF
3269                 fi
3270
3271                 for cf_item in $cf_LIST_MODELS
3272                 do
3273                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3274                         cf_libname=$cf_dir
3275                         test "$cf_dir" = c++ && cf_libname=ncurses++
3276                         if test $cf_item = shared ; then
3277                                 if test -n "${LIB_SUFFIX}"
3278                                 then
3279                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3280                                 else
3281                                         cf_shared_suffix="$cf_suffix"
3282                                 fi
3283                                 if test "$cf_cv_do_symlinks" = yes ; then
3284                                         cf_version_name=
3285
3286                                         case "$cf_cv_shlib_version" in
3287                                         (rel)
3288                                                 cf_version_name=REL_VERSION
3289                                                 ;;
3290                                         (abi)
3291                                                 cf_version_name=ABI_VERSION
3292                                                 ;;
3293                                         esac
3294
3295                                         if test -n "$cf_version_name"
3296                                         then
3297                                                 case "$cf_cv_system_name" in
3298                                                 (darwin*)
3299                                                         # "w", etc?
3300                                                         cf_suffix="${LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3301                                                         ;;
3302                                                 (*)
3303                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3304                                                         ;;
3305                                                 esac
3306                                         fi
3307                                         if test -n "${USE_LIB_SUFFIX}"
3308                                         then
3309                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3310                                         else
3311                                                 cf_shared_suffix="$cf_suffix"
3312                                         fi
3313                                 fi
3314                                 # cygwin needs import library, and has unique naming convention
3315                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3316                                 # use 'cyg' prefix for shared lib.
3317                                 case $cf_cv_shlib_version in
3318                                 (cygdll)
3319                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3320                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
3321                                         ;;
3322                                 (msysdll)
3323                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3324                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
3325                                         ;;
3326                                 (mingw)
3327                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3328                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
3329                                         ;;
3330                                 (*)
3331                                         cf_add_lib=
3332                                         ;;
3333                                 esac
3334                                 if test -n "$cf_add_lib"
3335                                 then
3336                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3337                                         continue
3338                                 fi
3339                         fi
3340                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3341                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3342                 done
3343
3344                 if test $cf_dir = ncurses ; then
3345                         cf_subsets="$LIB_SUBSETS"
3346                         cf_r_parts="$cf_subsets"
3347                         cf_liblist="$Libs_To_Make"
3348
3349                         while test -n "$cf_r_parts"
3350                         do
3351                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3352                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3353                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3354                                         cf_add_lib=
3355                                         case $cf_l_parts in
3356                                         (*termlib*)
3357                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3358                                                 ;;
3359                                         (*ticlib*)
3360                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3361                                                 ;;
3362                                         (*)
3363                                                 break
3364                                                 ;;
3365                                         esac
3366                                         if test -n "$cf_add_lib"; then
3367                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
3368                                         fi
3369                                 else
3370                                         break
3371                                 fi
3372                         done
3373                 else
3374                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3375                 fi
3376
3377                 if test $cf_dir = c++; then
3378                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3379                                 cf_list=
3380                                 for cf_item in $Libs_To_Make
3381                                 do
3382                                         case $cf_item in
3383                                         (*.a)
3384                                                 ;;
3385                                         (*)
3386                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3387                                                 ;;
3388                                         esac
3389                                         for cf_test in $cf_list
3390                                         do
3391                                                 if test "$cf_test" = "$cf_item"
3392                                                 then
3393                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3394                                                         cf_item=
3395                                                         break
3396                                                 fi
3397                                         done
3398                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3399                                 done
3400                                 Libs_To_Make="$cf_list"
3401                         fi
3402                 fi
3403
3404                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3405                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3406                         $cf_dir/Makefile >$cf_dir/Makefile.out
3407                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3408
3409                 $AWK -f $srcdir/mk-0th.awk \
3410                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3411                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3412
3413                 for cf_subset in $cf_subsets
3414                 do
3415                         cf_subdirs=
3416                         for cf_item in $cf_LIST_MODELS
3417                         do
3418
3419                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3420                         CF_UPPER(cf_ITEM,$cf_item)
3421
3422                         CXX_MODEL=$cf_ITEM
3423                         if test "$CXX_MODEL" = SHARED; then
3424                                 case $cf_cv_shlib_version in
3425                                 (cygdll|msysdll|mingw)
3426                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3427                                         with_shared_cxx=yes
3428                                         ;;
3429                                 (*)
3430                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3431                                         ;;
3432                                 esac
3433                         fi
3434
3435                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3436                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3437
3438                         # Test for case where we build libtinfo with a different name.
3439                         cf_libname=$cf_dir
3440                         if test $cf_dir = ncurses ; then
3441                                 case $cf_subset in
3442                                 (*base*)
3443                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
3444                                         ;;
3445                                 (*termlib*)
3446                                         cf_libname=$TINFO_LIB_SUFFIX
3447                                         ;;
3448                                 (ticlib*)
3449                                         cf_libname=$TICS_LIB_SUFFIX
3450                                         ;;
3451                                 esac
3452                         elif test $cf_dir = c++ ; then
3453                                 cf_libname=ncurses++$USE_LIB_SUFFIX
3454                         else
3455                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
3456                         fi
3457                         if test -n "${USE_ARG_SUFFIX}" ; then
3458                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
3459                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
3460                         fi
3461
3462                         # These dependencies really are for development, not
3463                         # builds, but they are useful in porting, too.
3464                         cf_depend="../include/ncurses_cfg.h"
3465                         if test "$srcdir" = "."; then
3466                                 cf_reldir="."
3467                         else
3468                                 cf_reldir="\${srcdir}"
3469                         fi
3470
3471                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3472                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3473                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3474                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3475                         fi
3476
3477                         cf_dir_suffix=
3478                         old_cf_suffix="$cf_suffix"
3479                         if test "$cf_cv_shlib_version_infix" = yes ; then
3480                         if test -n "$USE_LIB_SUFFIX" ; then
3481                                 case $USE_LIB_SUFFIX in
3482                                 (tw*)
3483                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3484                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
3485                                         cf_dir_suffix=tw
3486                                         ;;
3487                                 (t*)
3488                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3489                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
3490                                         cf_dir_suffix=t
3491                                         ;;
3492                                 (w*)
3493                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3494                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
3495                                         cf_dir_suffix=w
3496                                         ;;
3497                                 (*)
3498                                         cf_libname=`echo $cf_libname | sed 's/$//'`
3499                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
3500                                         cf_dir_suffix=
3501                                         ;;
3502                                 esac
3503                         fi
3504                         fi
3505
3506                         $AWK -f $srcdir/mk-1st.awk \
3507                                 name=${cf_libname}${cf_dir_suffix} \
3508                                 traces=$LIB_TRACING \
3509                                 MODEL=$cf_ITEM \
3510                                 CXX_MODEL=$CXX_MODEL \
3511                                 model=$cf_subdir \
3512                                 prefix=$cf_prefix \
3513                                 suffix=$cf_suffix \
3514                                 subset=$cf_subset \
3515                                 driver=$cf_cv_term_driver \
3516                                 SymLink="$LN_S" \
3517                                 TermlibRoot=$TINFO_NAME \
3518                                 TermlibSuffix=$TINFO_SUFFIX \
3519                                 ShlibVer=$cf_cv_shlib_version \
3520                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3521                                 ReLink=${cf_cv_do_relink:-no} \
3522                                 DoLinks=$cf_cv_do_symlinks \
3523                                 rmSoLocs=$cf_cv_rm_so_locs \
3524                                 ldconfig="$LDCONFIG" \
3525                                 overwrite=$WITH_OVERWRITE \
3526                                 depend="$cf_depend" \
3527                                 host="$host" \
3528                                 libtool_version="$LIBTOOL_VERSION" \
3529                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3530
3531                         cf_suffix="$old_cf_suffix"
3532
3533                         for cf_subdir2 in $cf_subdirs lib
3534                         do
3535                                 test $cf_subdir = $cf_subdir2 && break
3536                         done
3537                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3538                         $AWK -f $srcdir/mk-2nd.awk \
3539                                 name=$cf_dir \
3540                                 traces=$LIB_TRACING \
3541                                 MODEL=$cf_ITEM \
3542                                 model=$cf_subdir \
3543                                 subset=$cf_subset \
3544                                 srcdir=$srcdir \
3545                                 echo=$WITH_ECHO \
3546                                 crenames=$cf_cv_prog_CC_c_o \
3547                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3548                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3549                         cf_subdirs="$cf_subdirs $cf_subdir"
3550                         done
3551                 done
3552         fi
3553
3554         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3555 done
3556
3557 for cf_dir in $SRC_SUBDIRS
3558 do
3559         if test ! -d $srcdir/$cf_dir ; then
3560                 continue
3561         fi
3562
3563         if test -f $cf_dir/Makefile ; then
3564                 case "$cf_dir" in
3565                 (Ada95)
3566                         echo 'libs \' >> Makefile
3567                         echo 'install.libs \' >> Makefile
3568                         echo 'uninstall.libs ::' >> Makefile
3569                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3570                         ;;
3571                 esac
3572         fi
3573
3574         if test -f $srcdir/$cf_dir/modules; then
3575                 echo >> Makefile
3576                 if test -f $srcdir/$cf_dir/headers; then
3577 cat >> Makefile <<CF_EOF
3578 install.includes \\
3579 uninstall.includes \\
3580 CF_EOF
3581                 fi
3582 if test "$cf_dir" != "c++" ; then
3583 echo 'lint \' >> Makefile
3584 fi
3585 cat >> Makefile <<CF_EOF
3586 libs \\
3587 lintlib \\
3588 install.libs \\
3589 uninstall.libs \\
3590 install.$cf_dir \\
3591 uninstall.$cf_dir ::
3592         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3593 CF_EOF
3594         elif test -f $srcdir/$cf_dir/headers; then
3595 cat >> Makefile <<CF_EOF
3596
3597 libs \\
3598 install.libs \\
3599 uninstall.libs \\
3600 install.includes \\
3601 uninstall.includes ::
3602         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3603 CF_EOF
3604 fi
3605 done
3606
3607 if test "x$cf_with_db_install" = xyes; then
3608 cat >> Makefile <<CF_EOF
3609
3610 install.libs uninstall.libs \\
3611 install.data uninstall.data ::
3612 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3613 CF_EOF
3614 else
3615 cat >> Makefile <<CF_EOF
3616
3617 install.libs uninstall.libs ::
3618         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3619 CF_EOF
3620 fi
3621
3622 if test "x$cf_with_manpages" = xyes; then
3623 cat >> Makefile <<CF_EOF
3624
3625 install.man \\
3626 uninstall.man ::
3627         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3628 CF_EOF
3629 fi
3630
3631 cat >> Makefile <<CF_EOF
3632
3633 distclean ::
3634         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3635         rm -f headers.sh headers.sed mk_shared_lib.sh
3636         rm -f edit_man.* man_alias.*
3637         rm -rf \${DIRS_TO_MAKE}
3638 CF_EOF
3639
3640 # Special case: tack's manpage lives in its own directory.
3641 if test "x$cf_with_manpages" = xyes; then
3642 if test -d tack ; then
3643 if test -f $srcdir/$tack.h; then
3644 cat >> Makefile <<CF_EOF
3645
3646 install.man \\
3647 uninstall.man ::
3648         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3649 CF_EOF
3650 fi
3651 fi
3652 fi
3653
3654 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3655 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3656 dnl anything, and will make it more standardized.  It's awkward to decide this
3657 dnl at configuration because of quoting, so we'll simply make all headers
3658 dnl installed via a script that can do the right thing.
3659
3660 rm -f headers.sed headers.sh
3661
3662 dnl ( generating this script makes the makefiles a little tidier :-)
3663 echo creating headers.sh
3664 cat >headers.sh <<CF_EOF
3665 #! /bin/sh
3666 # This shell script is generated by the 'configure' script.  It is invoked in a
3667 # subdirectory of the build tree.  It generates a sed-script in the parent
3668 # directory that is used to adjust includes for header files that reside in a
3669 # subdirectory of /usr/include, etc.
3670 PRG=""
3671 while test \[$]# != 3
3672 do
3673 PRG="\$PRG \[$]1"; shift
3674 done
3675 DST=\[$]1
3676 REF=\[$]2
3677 SRC=\[$]3
3678 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3679 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3680 echo installing \$SRC in \$DST
3681 CF_EOF
3682
3683 if test $WITH_CURSES_H = yes; then
3684         cat >>headers.sh <<CF_EOF
3685 case \$DST in
3686 (/*/include/*)
3687         END=\`basename \$DST\`
3688         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3689         do
3690                 NAME=\`basename \$i\`
3691                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3692         done
3693         ;;
3694 (*)
3695         echo "" >> \$TMPSED
3696         ;;
3697 esac
3698 CF_EOF
3699
3700 else
3701         cat >>headers.sh <<CF_EOF
3702 case \$DST in
3703 (/*/include/*)
3704         END=\`basename \$DST\`
3705         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3706         do
3707                 NAME=\`basename \$i\`
3708                 if test "\$NAME" = "curses.h"
3709                 then
3710                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3711                         NAME=ncurses.h
3712                 fi
3713                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3714         done
3715         ;;
3716 (*)
3717         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3718         ;;
3719 esac
3720 CF_EOF
3721 fi
3722 cat >>headers.sh <<CF_EOF
3723 rm -f \$TMPSRC
3724 sed -f \$TMPSED \$SRC > \$TMPSRC
3725 NAME=\`basename \$SRC\`
3726 CF_EOF
3727 if test $WITH_CURSES_H != yes; then
3728         cat >>headers.sh <<CF_EOF
3729 test "\$NAME" = "curses.h" && NAME=ncurses.h
3730 CF_EOF
3731 fi
3732 cat >>headers.sh <<CF_EOF
3733 # Just in case someone gzip'd manpages, remove the conflicting copy.
3734 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3735
3736 eval \$PRG \$TMPSRC \$DST/\$NAME
3737 rm -f \$TMPSRC \$TMPSED
3738 CF_EOF
3739
3740 chmod 0755 headers.sh
3741
3742 for cf_dir in $SRC_SUBDIRS
3743 do
3744         if test ! -d $srcdir/$cf_dir ; then
3745                 continue
3746         fi
3747
3748         if test -f $srcdir/$cf_dir/headers; then
3749                 $AWK -f $srcdir/mk-hdr.awk \
3750                         subset="$LIB_SUBSETS" \
3751                         compat="$WITH_CURSES_H" \
3752                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3753         fi
3754
3755         if test -f $srcdir/$cf_dir/modules; then
3756                 if test "$cf_dir" != "c++" ; then
3757                         cat >>$cf_dir/Makefile <<"CF_EOF"
3758 depend : ${AUTO_SRC}
3759         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3760
3761 # DO NOT DELETE THIS LINE -- make depend depends on it.
3762 CF_EOF
3763                 fi
3764         fi
3765 done
3766 AC_SUBST(Libs_To_Make)
3767 ])dnl
3768 dnl ---------------------------------------------------------------------------
3769 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3770 dnl -------------
3771 dnl Find the and soname for the given shared library.  Set the cache variable
3772 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3773 dnl variable to "unknown".
3774 dnl
3775 dnl $1 = headers
3776 dnl $2 = code
3777 dnl $3 = library name
3778 AC_DEFUN([CF_LIB_SONAME],
3779 [
3780 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3781
3782 cf_cv_$3_soname=unknown
3783 if test "$cross_compiling" != yes ; then
3784 cat >conftest.$ac_ext <<CF_EOF
3785 $1
3786 int main()
3787 {
3788 $2
3789         ${cf_cv_main_return:-return}(0);
3790 }
3791 CF_EOF
3792 cf_save_LIBS="$LIBS"
3793         CF_ADD_LIB($3)
3794         if AC_TRY_EVAL(ac_compile) ; then
3795                 if AC_TRY_EVAL(ac_link) ; then
3796                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3797                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3798                 fi
3799         fi
3800 rm -rf conftest*
3801 LIBS="$cf_save_LIBS"
3802 fi
3803 ])
3804 ])
3805 dnl ---------------------------------------------------------------------------
3806 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
3807 dnl -------------
3808 dnl Compute the library file-suffix from the given model name
3809 dnl $1 = model name
3810 dnl $2 = variable to set (the nominal library suffix)
3811 dnl $3 = dependency variable to set (actual filename)
3812 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3813 AC_DEFUN([CF_LIB_SUFFIX],
3814 [
3815         case X$1 in
3816         (Xlibtool)
3817                 $2='.la'
3818                 $3=[$]$2
3819                 ;;
3820         (Xdebug)
3821                 $2='_g.a'
3822                 $3=[$]$2
3823                 ;;
3824         (Xprofile)
3825                 $2='_p.a'
3826                 $3=[$]$2
3827                 ;;
3828         (Xshared)
3829                 case $cf_cv_system_name in
3830                 (aix[[5-7]]*)
3831                         $2='.so'
3832                         $3=[$]$2
3833                         ;;
3834                 (cygwin*|msys*|mingw*)
3835                         $2='.dll'
3836                         $3='.dll.a'
3837                         ;;
3838                 (darwin*)
3839                         $2='.dylib'
3840                         $3=[$]$2
3841                         ;;
3842                 (hpux*)
3843                         case $target in
3844                         (ia64*)
3845                                 $2='.so'
3846                                 $3=[$]$2
3847                                 ;;
3848                         (*)
3849                                 $2='.sl'
3850                                 $3=[$]$2
3851                                 ;;
3852                         esac
3853                         ;;
3854                 (*)
3855                         $2='.so'
3856                         $3=[$]$2
3857                         ;;
3858                 esac
3859                 ;;
3860         (*)
3861                 $2='.a'
3862                 $3=[$]$2
3863                 ;;
3864         esac
3865         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
3866         then
3867                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
3868                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
3869         fi
3870 ])dnl
3871 dnl ---------------------------------------------------------------------------
3872 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
3873 dnl -----------
3874 dnl Compute the string to append to -library from the given model name
3875 dnl $1 = model name
3876 dnl $2 = variable to set
3877 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3878 AC_DEFUN([CF_LIB_TYPE],
3879 [
3880         case $1 in
3881         (libtool) $2=''   ;;
3882         (normal)  $2=''   ;;
3883         (debug)   $2='_g' ;;
3884         (profile) $2='_p' ;;
3885         (shared)  $2=''   ;;
3886         esac
3887         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3888 ])dnl
3889 dnl ---------------------------------------------------------------------------
3890 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
3891 dnl ----------------
3892 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3893 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3894 dnl have to provide wrappers for global tables to ensure they're linked
3895 dnl properly.
3896 AC_DEFUN([CF_LINK_DATAONLY],
3897 [
3898 AC_MSG_CHECKING([if data-only library module links])
3899 AC_CACHE_VAL(cf_cv_link_dataonly,[
3900         rm -f conftest.a
3901         cat >conftest.$ac_ext <<EOF
3902 #line __oline__ "configure"
3903 int     testdata[[3]] = { 123, 456, 789 };
3904 EOF
3905         if AC_TRY_EVAL(ac_compile) ; then
3906                 mv conftest.o data.o && \
3907                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3908         fi
3909         rm -f conftest.$ac_ext data.o
3910         cat >conftest.$ac_ext <<EOF
3911 #line __oline__ "configure"
3912 int     testfunc()
3913 {
3914 #if defined(NeXT)
3915         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3916 #else
3917         extern int testdata[[3]];
3918         return testdata[[0]] == 123
3919            &&  testdata[[1]] == 456
3920            &&  testdata[[2]] == 789;
3921 #endif
3922 }
3923 EOF
3924         if AC_TRY_EVAL(ac_compile); then
3925                 mv conftest.o func.o && \
3926                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3927         fi
3928         rm -f conftest.$ac_ext func.o
3929         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3930         cf_saveLIBS="$LIBS"
3931         LIBS="conftest.a $LIBS"
3932         AC_TRY_RUN([
3933         int main()
3934         {
3935                 extern int testfunc();
3936                 ${cf_cv_main_return:-return} (!testfunc());
3937         }
3938         ],
3939         [cf_cv_link_dataonly=yes],
3940         [cf_cv_link_dataonly=no],
3941         [cf_cv_link_dataonly=unknown])
3942         LIBS="$cf_saveLIBS"
3943         ])
3944 AC_MSG_RESULT($cf_cv_link_dataonly)
3945
3946 if test "$cf_cv_link_dataonly" = no ; then
3947         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
3948         BROKEN_LINKER=1
3949 fi
3950
3951 ])dnl
3952 dnl ---------------------------------------------------------------------------
3953 dnl CF_LINK_FUNCS version: 8 updated: 2012/10/06 17:56:13
3954 dnl -------------
3955 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3956 dnl A few non-Unix systems implement symlink, but not link.
3957 dnl A few non-systems implement neither (or have nonfunctional versions).
3958 AC_DEFUN([CF_LINK_FUNCS],
3959 [
3960 AC_CHECK_FUNCS( \
3961         remove \
3962         unlink )
3963
3964 if test "$cross_compiling" = yes ; then
3965         AC_CHECK_FUNCS( \
3966                 link \
3967                 symlink )
3968 else
3969         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3970                 cf_cv_link_funcs=
3971                 for cf_func in link symlink ; do
3972                         AC_TRY_RUN([
3973 #include <sys/types.h>
3974 #include <sys/stat.h>
3975 #ifdef HAVE_UNISTD_H
3976 #include <unistd.h>
3977 #endif
3978 int main()
3979 {
3980         int fail = 0;
3981         char *src = "config.log";
3982         char *dst = "conftest.chk";
3983         struct stat src_sb;
3984         struct stat dst_sb;
3985
3986         stat(src, &src_sb);
3987         fail = ($cf_func("config.log", "conftest.chk") < 0)
3988             || (stat(dst, &dst_sb) < 0)
3989             || (dst_sb.st_mtime != src_sb.st_mtime);
3990 #ifdef HAVE_UNLINK
3991         unlink(dst);
3992 #else
3993         remove(dst);
3994 #endif
3995         ${cf_cv_main_return:-return} (fail);
3996 }
3997                         ],[
3998                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3999                         eval 'ac_cv_func_'$cf_func'=yes'],[
4000                         eval 'ac_cv_func_'$cf_func'=no'],[
4001                         eval 'ac_cv_func_'$cf_func'=error'])
4002                 done
4003                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
4004         ])
4005         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
4006         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
4007 fi
4008 ])dnl
4009 dnl ---------------------------------------------------------------------------
4010 dnl CF_MAKEFLAGS version: 16 updated: 2015/04/15 19:08:48
4011 dnl ------------
4012 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
4013 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
4014 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
4015 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
4016 AC_DEFUN([CF_MAKEFLAGS],
4017 [
4018 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
4019         cf_cv_makeflags=''
4020         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
4021         do
4022                 cat >cf_makeflags.tmp <<CF_EOF
4023 SHELL = /bin/sh
4024 all :
4025         @ echo '.$cf_option'
4026 CF_EOF
4027                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
4028                 case "$cf_result" in
4029                 (.*k|.*kw)
4030                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
4031                         case "$cf_result" in
4032                         (.*CC=*)        cf_cv_makeflags=
4033                                 ;;
4034                         (*)     cf_cv_makeflags=$cf_option
4035                                 ;;
4036                         esac
4037                         break
4038                         ;;
4039                 (.-)    ;;
4040                 (*)     echo "given option \"$cf_option\", no match \"$cf_result\""
4041                         ;;
4042                 esac
4043         done
4044         rm -f cf_makeflags.tmp
4045 ])
4046
4047 AC_SUBST(cf_cv_makeflags)
4048 ])dnl
4049 dnl ---------------------------------------------------------------------------
4050 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
4051 dnl ------------
4052 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
4053 dnl a monocase filesystem.
4054 AC_DEFUN([CF_MAKE_TAGS],[
4055 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
4056
4057 AC_CHECK_PROGS(CTAGS, exctags ctags)
4058 AC_CHECK_PROGS(ETAGS, exetags etags)
4059
4060 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
4061
4062 if test "$cf_cv_mixedcase" = yes ; then
4063         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
4064 else
4065         MAKE_UPPER_TAGS=no
4066 fi
4067
4068 if test "$MAKE_UPPER_TAGS" = yes ; then
4069         MAKE_UPPER_TAGS=
4070 else
4071         MAKE_UPPER_TAGS="#"
4072 fi
4073
4074 if test "$MAKE_LOWER_TAGS" = yes ; then
4075         MAKE_LOWER_TAGS=
4076 else
4077         MAKE_LOWER_TAGS="#"
4078 fi
4079
4080 AC_SUBST(CTAGS)
4081 AC_SUBST(ETAGS)
4082
4083 AC_SUBST(MAKE_UPPER_TAGS)
4084 AC_SUBST(MAKE_LOWER_TAGS)
4085 ])dnl
4086 dnl ---------------------------------------------------------------------------
4087 dnl CF_MANPAGE_FORMAT version: 11 updated: 2015/04/18 08:56:57
4088 dnl -----------------
4089 dnl Option to allow user to override automatic configuration of manpage format.
4090 dnl There are several special cases:
4091 dnl
4092 dnl     gzip - man checks for, can display gzip'd files
4093 dnl     compress - man checks for, can display compressed files
4094 dnl     BSDI - files in the cat-directories are suffixed ".0"
4095 dnl     formatted - installer should format (put files in cat-directory)
4096 dnl     catonly - installer should only format, e.g., for a turnkey system.
4097 dnl
4098 dnl There are other configurations which this macro does not test, e.g., HPUX's
4099 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
4100 dnl convention would not match our use).
4101 AC_DEFUN([CF_MANPAGE_FORMAT],
4102 [
4103 AC_REQUIRE([CF_PATHSEP])
4104 AC_MSG_CHECKING(format of man-pages)
4105
4106 AC_ARG_WITH(manpage-format,
4107         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
4108                           optionally formatted/catonly, e.g., gzip,formatted],
4109         [MANPAGE_FORMAT=$withval],
4110         [MANPAGE_FORMAT=unknown])
4111
4112 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
4113 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
4114
4115 cf_unknown=
4116
4117 case $MANPAGE_FORMAT in
4118 (unknown)
4119         if test -z "$MANPATH" ; then
4120                 MANPATH="/usr/man:/usr/share/man"
4121         fi
4122
4123         # look for the 'date' man-page (it's most likely to be installed!)
4124         MANPAGE_FORMAT=
4125         cf_preform=no
4126         cf_catonly=yes
4127         cf_example=date
4128
4129         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
4130         for cf_dir in $MANPATH; do
4131                 test -z "$cf_dir" && cf_dir=/usr/man
4132                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
4133                 do
4134                         cf_test=`echo $cf_name | sed -e 's/*//'`
4135                         if test "x$cf_test" = "x$cf_name" ; then
4136
4137                                 case "$cf_name" in
4138                                 (*.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
4139                                 (*.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
4140                                 (*.0)  MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
4141                                 (*)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
4142                                 esac
4143
4144                                 case "$cf_name" in
4145                                 ($cf_dir/man*)
4146                                         cf_catonly=no
4147                                         ;;
4148                                 ($cf_dir/cat*)
4149                                         cf_preform=yes
4150                                         ;;
4151                                 esac
4152                                 break
4153                         fi
4154
4155                         # if we found a match in either man* or cat*, stop looking
4156                         if test -n "$MANPAGE_FORMAT" ; then
4157                                 cf_found=no
4158                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
4159                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
4160                                 case "$cf_name" in
4161                                 ($cf_dir/cat*)
4162                                         cf_found=yes
4163                                         ;;
4164                                 esac
4165                                 test $cf_found=yes && break
4166                         fi
4167                 done
4168                 # only check the first directory in $MANPATH where we find manpages
4169                 if test -n "$MANPAGE_FORMAT" ; then
4170                         break
4171                 fi
4172         done
4173         # if we did not find the example, just assume it is normal
4174         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4175         IFS="$ac_save_ifs"
4176         ;;
4177 (*)
4178         for cf_option in $MANPAGE_FORMAT; do
4179         case $cf_option in
4180         (gzip|compress|BSDI|normal|formatted|catonly)
4181                 ;;
4182         (*)
4183                 cf_unknown="$cf_unknown $cf_option"
4184                 ;;
4185         esac
4186         done
4187         ;;
4188 esac
4189
4190 AC_MSG_RESULT($MANPAGE_FORMAT)
4191 if test -n "$cf_unknown" ; then
4192         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4193 fi
4194 ])dnl
4195 dnl ---------------------------------------------------------------------------
4196 dnl CF_MANPAGE_RENAMES version: 9 updated: 2015/04/18 08:56:57
4197 dnl ------------------
4198 dnl The Debian people have their own naming convention for manpages.  This
4199 dnl option lets us override the name of the file containing renaming, or
4200 dnl disable it altogether.
4201 AC_DEFUN([CF_MANPAGE_RENAMES],
4202 [
4203 AC_MSG_CHECKING(for manpage renaming)
4204
4205 AC_ARG_WITH(manpage-renames,
4206         [  --with-manpage-renames  specify manpage-renaming],
4207         [MANPAGE_RENAMES=$withval],
4208         [MANPAGE_RENAMES=yes])
4209
4210 case ".$MANPAGE_RENAMES" in
4211 (.no)
4212         ;;
4213 (.|.yes)
4214         # Debian 'man' program?
4215         if test -f /etc/debian_version ; then
4216                 MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4217         else
4218                 MANPAGE_RENAMES=no
4219         fi
4220         ;;
4221 esac
4222
4223 if test "$MANPAGE_RENAMES" != no ; then
4224         if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4225                 MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4226         elif test ! -f $MANPAGE_RENAMES ; then
4227                 AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4228         fi
4229
4230         test ! -d man && mkdir man
4231
4232         # Construct a sed-script to perform renaming within man-pages
4233         if test -n "$MANPAGE_RENAMES" ; then
4234                 test ! -d man && mkdir man
4235                 sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4236         fi
4237 fi
4238
4239 AC_MSG_RESULT($MANPAGE_RENAMES)
4240 AC_SUBST(MANPAGE_RENAMES)
4241 ])dnl
4242 dnl ---------------------------------------------------------------------------
4243 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
4244 dnl -------------------
4245 dnl Some people expect each tool to make all aliases for manpages in the
4246 dnl man-directory.  This accommodates the older, less-capable implementations
4247 dnl of 'man', and is optional.
4248 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4249 [
4250 AC_MSG_CHECKING(if manpage aliases will be installed)
4251
4252 AC_ARG_WITH(manpage-aliases,
4253         [  --with-manpage-aliases  specify manpage-aliases using .so],
4254         [MANPAGE_ALIASES=$withval],
4255         [MANPAGE_ALIASES=yes])
4256
4257 AC_MSG_RESULT($MANPAGE_ALIASES)
4258
4259 case "x$LN_S" in
4260 (xln*)
4261         cf_use_symlinks=yes
4262         ;;
4263 (*)
4264         cf_use_symlinks=no
4265         ;;
4266 esac
4267
4268 MANPAGE_SYMLINKS=no
4269 if test "$MANPAGE_ALIASES" = yes ; then
4270 AC_MSG_CHECKING(if manpage symlinks should be used)
4271
4272 AC_ARG_WITH(manpage-symlinks,
4273         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4274         [MANPAGE_SYMLINKS=$withval],
4275         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4276
4277 if test "$$cf_use_symlinks" = no; then
4278 if test "$MANPAGE_SYMLINKS" = yes ; then
4279         AC_MSG_WARN(cannot make symlinks, will use .so files)
4280         MANPAGE_SYMLINKS=no
4281 fi
4282 fi
4283
4284 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4285 fi
4286
4287 ])dnl
4288 dnl ---------------------------------------------------------------------------
4289 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4290 dnl --------------
4291 dnl This option causes manpages to be run through tbl(1) to generate tables
4292 dnl correctly.
4293 AC_DEFUN([CF_MANPAGE_TBL],
4294 [
4295 AC_MSG_CHECKING(for manpage tbl)
4296
4297 AC_ARG_WITH(manpage-tbl,
4298         [  --with-manpage-tbl      specify manpage processing with tbl],
4299         [MANPAGE_TBL=$withval],
4300         [MANPAGE_TBL=no])
4301
4302 AC_MSG_RESULT($MANPAGE_TBL)
4303 ])dnl
4304 dnl ---------------------------------------------------------------------------
4305 dnl CF_MAN_PAGES version: 45 updated: 2015/04/18 08:56:57
4306 dnl ------------
4307 dnl Try to determine if the man-pages on the system are compressed, and if
4308 dnl so, what format is used.  Use this information to construct a script that
4309 dnl will install man-pages.
4310 AC_DEFUN([CF_MAN_PAGES],
4311 [
4312 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4313 CF_MANPAGE_FORMAT
4314 CF_MANPAGE_RENAMES
4315 CF_MANPAGE_SYMLINKS
4316 CF_MANPAGE_TBL
4317
4318 if test "$prefix" = "NONE" ; then
4319         cf_prefix="$ac_default_prefix"
4320 else
4321         cf_prefix="$prefix"
4322 fi
4323
4324 case "$MANPAGE_FORMAT" in
4325 (*catonly*)
4326         cf_format=yes
4327         cf_inboth=no
4328         ;;
4329 (*formatted*)
4330         cf_format=yes
4331         cf_inboth=yes
4332         ;;
4333 (*)
4334         cf_format=no
4335         cf_inboth=no
4336         ;;
4337 esac
4338
4339 test ! -d man && mkdir man
4340
4341 cf_so_strip=
4342 cf_compress=
4343 case "$MANPAGE_FORMAT" in
4344 (*compress*)
4345         cf_so_strip="Z"
4346         cf_compress=compress
4347         ;;
4348 (*gzip*)
4349         cf_so_strip="gz"
4350         cf_compress=gzip
4351         ;;
4352 esac
4353
4354 cf_edit_man=./edit_man.sh
4355 cf_man_alias=`pwd`/man_alias.sed
4356
4357 cat >$cf_edit_man <<CF_EOF
4358 #! /bin/sh
4359 # this script is generated by the configure-script CF_MAN_PAGES macro.
4360
4361 prefix="$cf_prefix"
4362 datarootdir="$datarootdir"
4363 datadir="$datadir"
4364
4365 NCURSES_MAJOR="$NCURSES_MAJOR"
4366 NCURSES_MINOR="$NCURSES_MINOR"
4367 NCURSES_PATCH="$NCURSES_PATCH"
4368
4369 NCURSES_OSPEED="$NCURSES_OSPEED"
4370 TERMINFO="$TERMINFO"
4371
4372 INSTALL="$INSTALL"
4373 INSTALL_DATA="$INSTALL_DATA"
4374
4375 transform="$program_transform_name"
4376
4377 TMP=\${TMPDIR:=/tmp}/man\$\$
4378 trap "rm -f \$TMP" 0 1 2 5 15
4379
4380 form=\[$]1
4381 shift || exit 1
4382
4383 verb=\[$]1
4384 shift || exit 1
4385
4386 mandir=\[$]1
4387 shift || exit 1
4388
4389 srcdir=\[$]1
4390 top_srcdir=\[$]srcdir/..
4391 shift || exit 1
4392
4393 if test "\$form" = normal ; then
4394         if test "$cf_format" = yes ; then
4395         if test "$cf_inboth" = no ; then
4396                 sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4397                 exit $?
4398         fi
4399         fi
4400         cf_subdir=\$mandir/man
4401         cf_tables=$MANPAGE_TBL
4402 else
4403         cf_subdir=\$mandir/cat
4404         cf_tables=yes
4405 fi
4406
4407 # process the list of source-files
4408 for i in \[$]* ; do
4409 case \$i in
4410 (*.orig|*.rej) ;;
4411 (*.[[0-9]]*)
4412         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4413         if test \$verb = installing ; then
4414         if test ! -d \$cf_subdir\${section} ; then
4415                 mkdir -p \$cf_subdir\$section
4416         fi
4417         fi
4418
4419         # replace variables in man page
4420         if test ! -f $cf_man_alias ; then
4421 cat >>$cf_man_alias <<-CF_EOF2
4422                 s,@DATADIR@,\$datadir,g
4423                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
4424                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
4425                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
4426                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
4427                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
4428                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
4429 CF_EOF
4430         ifelse($1,,,[
4431         for cf_name in $1
4432         do
4433                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4434                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4435 cat >>$cf_edit_man <<-CF_EOF
4436                 s,@$cf_NAME@,$cf_name,g
4437 CF_EOF
4438         done
4439         ])
4440 cat >>$cf_edit_man <<CF_EOF
4441 CF_EOF2
4442                 echo "...made $cf_man_alias"
4443         fi
4444
4445         aliases=
4446         cf_source=\`basename \$i\`
4447         inalias=\$cf_source
4448         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4449         if test ! -f \$inalias ; then
4450                 echo .. skipped \$cf_source
4451                 continue
4452         fi
4453 CF_EOF
4454
4455 if test "$MANPAGE_ALIASES" != no ; then
4456 cat >>$cf_edit_man <<CF_EOF
4457         nCurses=ignore.3x
4458         test $with_curses_h = yes && nCurses=ncurses.3x
4459         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4460 CF_EOF
4461 fi
4462
4463 if test "$MANPAGE_RENAMES" = no ; then
4464 cat >>$cf_edit_man <<CF_EOF
4465         # perform program transformations for section 1 man pages
4466         if test \$section = 1 ; then
4467                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4468         else
4469                 cf_target=\$cf_subdir\${section}/\$cf_source
4470         fi
4471 CF_EOF
4472 else
4473 cat >>$cf_edit_man <<CF_EOF
4474         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4475         if test -z "\$cf_target" ; then
4476                 echo '? missing rename for '\$cf_source
4477                 cf_target="\$cf_source"
4478         fi
4479         cf_target="\$cf_subdir\${section}/\${cf_target}"
4480
4481 CF_EOF
4482 fi
4483
4484 cat >>$cf_edit_man <<CF_EOF
4485         sed     -f $cf_man_alias \\
4486 CF_EOF
4487
4488 if test -f $MANPAGE_RENAMES ; then
4489 cat >>$cf_edit_man <<CF_EOF
4490                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4491 CF_EOF
4492 else
4493 cat >>$cf_edit_man <<CF_EOF
4494                 < \$i >\$TMP
4495 CF_EOF
4496 fi
4497
4498 cat >>$cf_edit_man <<CF_EOF
4499 if test \$cf_tables = yes ; then
4500         tbl \$TMP >\$TMP.out
4501         mv \$TMP.out \$TMP
4502 fi
4503 CF_EOF
4504
4505 if test $with_overwrite != yes ; then
4506 cat >>$cf_edit_man <<CF_EOF
4507         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4508         mv \$TMP.out \$TMP
4509 CF_EOF
4510 fi
4511
4512 if test $with_curses_h != yes ; then
4513 cat >>$cf_edit_man <<CF_EOF
4514         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4515         mv \$TMP.out \$TMP
4516 CF_EOF
4517 fi
4518
4519 cat >>$cf_edit_man <<CF_EOF
4520         if test \$form = format ; then
4521                 nroff -man \$TMP >\$TMP.out
4522                 mv \$TMP.out \$TMP
4523         fi
4524 CF_EOF
4525
4526 if test -n "$cf_compress" ; then
4527 cat >>$cf_edit_man <<CF_EOF
4528         if test \$verb = installing ; then
4529         if ( $cf_compress -f \$TMP )
4530         then
4531                 mv \$TMP.$cf_so_strip \$TMP
4532         fi
4533         fi
4534         cf_target="\$cf_target.$cf_so_strip"
4535 CF_EOF
4536 fi
4537
4538 case "$MANPAGE_FORMAT" in
4539 (*BSDI*)
4540 cat >>$cf_edit_man <<CF_EOF
4541         if test \$form = format ; then
4542                 # BSDI installs only .0 suffixes in the cat directories
4543                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4544         fi
4545 CF_EOF
4546   ;;
4547 esac
4548
4549 cat >>$cf_edit_man <<CF_EOF
4550         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4551         if test \$verb = installing ; then
4552                 echo \$verb \$cf_target
4553                 \$INSTALL_DATA \$TMP \$cf_target
4554                 test -d \$cf_subdir\${section} &&
4555                 test -n "\$aliases" && (
4556                         cd \$cf_subdir\${section} && (
4557                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4558                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4559                                 cf_target=\`basename \$cf_target\`
4560                                 for cf_alias in \$aliases
4561                                 do
4562                                         if test \$section = 1 ; then
4563                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4564                                         fi
4565
4566                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4567                                                 if test -f \$cf_alias\${suffix} ; then
4568                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4569                                                         then
4570                                                                 continue
4571                                                         fi
4572                                                 fi
4573                                                 echo .. \$verb alias \$cf_alias\${suffix}
4574 CF_EOF
4575 case "x$LN_S" in
4576 (*-f)
4577 cat >>$cf_edit_man <<CF_EOF
4578                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4579 CF_EOF
4580         ;;
4581 (*)
4582 cat >>$cf_edit_man <<CF_EOF
4583                                                 rm -f \$cf_alias\${suffix}
4584                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4585 CF_EOF
4586         ;;
4587 esac
4588 cat >>$cf_edit_man <<CF_EOF
4589                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4590                                                 echo ".so \$cf_source" >\$TMP
4591 CF_EOF
4592 if test -n "$cf_compress" ; then
4593 cat >>$cf_edit_man <<CF_EOF
4594                                                 if test -n "$cf_so_strip" ; then
4595                                                         $cf_compress -f \$TMP
4596                                                         mv \$TMP.$cf_so_strip \$TMP
4597                                                 fi
4598 CF_EOF
4599 fi
4600 cat >>$cf_edit_man <<CF_EOF
4601                                                 echo .. \$verb alias \$cf_alias\${suffix}
4602                                                 rm -f \$cf_alias\${suffix}
4603                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4604                                         fi
4605                                 done
4606                         )
4607                 )
4608         elif test \$verb = removing ; then
4609                 test -f \$cf_target && (
4610                         echo \$verb \$cf_target
4611                         rm -f \$cf_target
4612                 )
4613                 test -d \$cf_subdir\${section} &&
4614                 test -n "\$aliases" && (
4615                         cd \$cf_subdir\${section} && (
4616                                 for cf_alias in \$aliases
4617                                 do
4618                                         if test \$section = 1 ; then
4619                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4620                                         fi
4621
4622                                         echo .. \$verb alias \$cf_alias\${suffix}
4623                                         rm -f \$cf_alias\${suffix}
4624                                 done
4625                         )
4626                 )
4627         else
4628 #               echo ".hy 0"
4629                 cat \$TMP
4630         fi
4631         ;;
4632 esac
4633 done
4634
4635 if test $cf_inboth = yes ; then
4636 if test \$form != format ; then
4637         sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4638 fi
4639 fi
4640
4641 exit 0
4642 CF_EOF
4643 chmod 755 $cf_edit_man
4644
4645 ])dnl
4646 dnl ---------------------------------------------------------------------------
4647 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4648 dnl -----------
4649 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4650 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4651 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4652 AC_DEFUN([CF_MATH_LIB],
4653 [
4654 AC_CACHE_CHECK(if -lm needed for math functions,
4655         cf_cv_need_libm,[
4656         AC_TRY_LINK([
4657         #include <stdio.h>
4658         #include <math.h>
4659         ],
4660         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4661         [cf_cv_need_libm=no],
4662         [cf_cv_need_libm=yes])])
4663 if test "$cf_cv_need_libm" = yes
4664 then
4665 ifelse($1,,[
4666         CF_ADD_LIB(m)
4667 ],[$1=-lm])
4668 fi
4669 ])
4670 dnl ---------------------------------------------------------------------------
4671 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
4672 dnl ----------------------
4673 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4674 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4675 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4676 [
4677 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4678 if test "$cross_compiling" = yes ; then
4679         case $target_alias in
4680         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
4681                 cf_cv_mixedcase=no
4682                 ;;
4683         (*)
4684                 cf_cv_mixedcase=yes
4685                 ;;
4686         esac
4687 else
4688         rm -f conftest CONFTEST
4689         echo test >conftest
4690         if test -f CONFTEST ; then
4691                 cf_cv_mixedcase=no
4692         else
4693                 cf_cv_mixedcase=yes
4694         fi
4695         rm -f conftest CONFTEST
4696 fi
4697 ])
4698 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
4699 ])dnl
4700 dnl ---------------------------------------------------------------------------
4701 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
4702 dnl ----------
4703 dnl Check for a working mkstemp.  This creates two files, checks that they are
4704 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4705 AC_DEFUN([CF_MKSTEMP],[
4706 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4707 rm -rf conftest*
4708 AC_TRY_RUN([
4709 #include <sys/types.h>
4710 #include <stdlib.h>
4711 #include <stdio.h>
4712 #include <string.h>
4713 #include <sys/stat.h>
4714 int main()
4715 {
4716         char *tmpl = "conftestXXXXXX";
4717         char name[2][80];
4718         int n;
4719         int result = 0;
4720         int fd;
4721         struct stat sb;
4722
4723         umask(077);
4724         for (n = 0; n < 2; ++n) {
4725                 strcpy(name[n], tmpl);
4726                 if ((fd = mkstemp(name[n])) >= 0) {
4727                         if (!strcmp(name[n], tmpl)
4728                          || stat(name[n], &sb) != 0
4729                          || (sb.st_mode & S_IFMT) != S_IFREG
4730                          || (sb.st_mode & 077) != 0) {
4731                                 result = 1;
4732                         }
4733                         close(fd);
4734                 }
4735         }
4736         if (result == 0
4737          && !strcmp(name[0], name[1]))
4738                 result = 1;
4739         ${cf_cv_main_return:-return}(result);
4740 }
4741 ],[cf_cv_func_mkstemp=yes
4742 ],[cf_cv_func_mkstemp=no
4743 ],[cf_cv_func_mkstemp=maybe])
4744 ])
4745 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
4746         AC_CHECK_FUNC(mkstemp)
4747 fi
4748 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4749         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
4750 fi
4751 ])dnl
4752 dnl ---------------------------------------------------------------------------
4753 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4754 dnl ----------
4755 dnl Write a debug message to config.log, along with the line number in the
4756 dnl configure script.
4757 AC_DEFUN([CF_MSG_LOG],[
4758 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
4759 ])dnl
4760 dnl ---------------------------------------------------------------------------
4761 dnl CF_NCURSES_ABI_6 version: 2 updated: 2015/04/17 21:13:04
4762 dnl ----------------
4763 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
4764 dnl warn about this.
4765 AC_DEFUN([CF_NCURSES_ABI_6],[
4766 if test "${with_abi_version+set}" != set; then
4767         case $cf_cv_rel_version in
4768         (5.*)
4769                 cf_cv_rel_version=6.0
4770                 cf_cv_abi_version=6
4771                 AC_MSG_WARN(Overriding ABI version to $cf_cv_abi_version)
4772                 ;;
4773         esac
4774 fi
4775 ])dnl
4776 dnl ---------------------------------------------------------------------------
4777 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
4778 dnl ------------------
4779 dnl see CF_WITH_NO_LEAKS
4780 AC_DEFUN([CF_NO_LEAKS_OPTION],[
4781 AC_MSG_CHECKING(if you want to use $1 for testing)
4782 AC_ARG_WITH($1,
4783         [$2],
4784         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
4785          $4
4786 ])
4787         : ${with_cflags:=-g}
4788         : ${with_no_leaks:=yes}
4789          with_$1=yes],
4790         [with_$1=])
4791 AC_MSG_RESULT(${with_$1:-no})
4792
4793 case .$with_cflags in
4794 (.*-g*)
4795         case .$CFLAGS in
4796         (.*-g*)
4797                 ;;
4798         (*)
4799                 CF_ADD_CFLAGS([-g])
4800                 ;;
4801         esac
4802         ;;
4803 esac
4804 ])dnl
4805 dnl ---------------------------------------------------------------------------
4806 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
4807 dnl ----------------
4808 dnl Check if the given variable is a number.  If not, report an error.
4809 dnl $1 is the variable
4810 dnl $2 is the message
4811 AC_DEFUN([CF_NUMBER_SYNTAX],[
4812 if test -n "$1" ; then
4813   case $1 in
4814   ([[0-9]]*)
4815         ;;
4816   (*)
4817         AC_MSG_ERROR($2 is not a number: $1)
4818         ;;
4819   esac
4820 else
4821   AC_MSG_ERROR($2 value is empty)
4822 fi
4823 ])dnl
4824 dnl ---------------------------------------------------------------------------
4825 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
4826 dnl -------------
4827 dnl Compute the object-directory name from the given model name
4828 AC_DEFUN([CF_OBJ_SUBDIR],
4829 [
4830         case $1 in
4831         (libtool) $2='obj_lo'  ;;
4832         (normal)  $2='objects' ;;
4833         (debug)   $2='obj_g' ;;
4834         (profile) $2='obj_p' ;;
4835         (shared)
4836                 case $cf_cv_system_name in
4837                 (cygwin|msys)
4838                         $2='objects' ;;
4839                 (*)
4840                         $2='obj_s' ;;
4841                 esac
4842         esac
4843 ])dnl
4844 dnl ---------------------------------------------------------------------------
4845 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
4846 dnl ----------
4847 dnl Provide a value for the $PATH and similar separator (or amend the value
4848 dnl as provided in autoconf 2.5x).
4849 AC_DEFUN([CF_PATHSEP],
4850 [
4851         AC_MSG_CHECKING(for PATH separator)
4852         case $cf_cv_system_name in
4853         (os2*)  PATH_SEPARATOR=';'  ;;
4854         (*)     ${PATH_SEPARATOR:=':'}  ;;
4855         esac
4856 ifelse([$1],,,[$1=$PATH_SEPARATOR])
4857         AC_SUBST(PATH_SEPARATOR)
4858         AC_MSG_RESULT($PATH_SEPARATOR)
4859 ])dnl
4860 dnl ---------------------------------------------------------------------------
4861 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
4862 dnl --------------
4863 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
4864 dnl begins with one of the prefix/exec_prefix variables, and then again if the
4865 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
4866 dnl delayed evaluation of those symbols.
4867 AC_DEFUN([CF_PATH_SYNTAX],[
4868 if test "x$prefix" != xNONE; then
4869         cf_path_syntax="$prefix"
4870 else
4871         cf_path_syntax="$ac_default_prefix"
4872 fi
4873
4874 case ".[$]$1" in
4875 (.\[$]\(*\)*|.\'*\'*)
4876         ;;
4877 (..|./*|.\\*)
4878         ;;
4879 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
4880         ;;
4881 (.\[$]{*prefix}*|.\[$]{*dir}*)
4882         eval $1="[$]$1"
4883         case ".[$]$1" in
4884         (.NONE/*)
4885                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4886                 ;;
4887         esac
4888         ;;
4889 (.no|.NONE/*)
4890         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4891         ;;
4892 (*)
4893         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
4894         ;;
4895 esac
4896 ])dnl
4897 dnl ---------------------------------------------------------------------------
4898 dnl CF_PKG_CONFIG version: 9 updated: 2015/04/12 15:39:00
4899 dnl -------------
4900 dnl Check for the package-config program, unless disabled by command-line.
4901 AC_DEFUN([CF_PKG_CONFIG],
4902 [
4903 AC_MSG_CHECKING(if you want to use pkg-config)
4904 AC_ARG_WITH(pkg-config,
4905         [  --with-pkg-config{=path} enable/disable use of pkg-config],
4906         [cf_pkg_config=$withval],
4907         [cf_pkg_config=yes])
4908 AC_MSG_RESULT($cf_pkg_config)
4909
4910 case $cf_pkg_config in
4911 (no)
4912         PKG_CONFIG=none
4913         ;;
4914 (yes)
4915         CF_ACVERSION_CHECK(2.52,
4916                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
4917                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
4918         ;;
4919 (*)
4920         PKG_CONFIG=$withval
4921         ;;
4922 esac
4923
4924 test -z "$PKG_CONFIG" && PKG_CONFIG=none
4925 if test "$PKG_CONFIG" != none ; then
4926         CF_PATH_SYNTAX(PKG_CONFIG)
4927 else
4928         AC_MSG_WARN(pkg-config is not installed)
4929 fi
4930
4931 AC_SUBST(PKG_CONFIG)
4932 ])dnl
4933 dnl ---------------------------------------------------------------------------
4934 dnl CF_POSIX_C_SOURCE version: 9 updated: 2015/04/12 15:39:00
4935 dnl -----------------
4936 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
4937 dnl
4938 dnl     POSIX.1-1990                            _POSIX_SOURCE
4939 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
4940 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
4941 dnl             Bindings Option
4942 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
4943 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
4944 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
4945 dnl
4946 dnl Parameters:
4947 dnl     $1 is the nominal value for _POSIX_C_SOURCE
4948 AC_DEFUN([CF_POSIX_C_SOURCE],
4949 [
4950 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
4951
4952 cf_save_CFLAGS="$CFLAGS"
4953 cf_save_CPPFLAGS="$CPPFLAGS"
4954
4955 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
4956 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
4957
4958 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
4959         CF_MSG_LOG(if the symbol is already defined go no further)
4960         AC_TRY_COMPILE([#include <sys/types.h>],[
4961 #ifndef _POSIX_C_SOURCE
4962 make an error
4963 #endif],
4964         [cf_cv_posix_c_source=no],
4965         [cf_want_posix_source=no
4966          case .$cf_POSIX_C_SOURCE in
4967          (.[[12]]??*)
4968                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4969                 ;;
4970          (.2)
4971                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4972                 cf_want_posix_source=yes
4973                 ;;
4974          (.*)
4975                 cf_want_posix_source=yes
4976                 ;;
4977          esac
4978          if test "$cf_want_posix_source" = yes ; then
4979                 AC_TRY_COMPILE([#include <sys/types.h>],[
4980 #ifdef _POSIX_SOURCE
4981 make an error
4982 #endif],[],
4983                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
4984          fi
4985          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
4986          CFLAGS="$cf_trim_CFLAGS"
4987          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
4988          CF_MSG_LOG(if the second compile does not leave our definition intact error)
4989          AC_TRY_COMPILE([#include <sys/types.h>],[
4990 #ifndef _POSIX_C_SOURCE
4991 make an error
4992 #endif],,
4993          [cf_cv_posix_c_source=no])
4994          CFLAGS="$cf_save_CFLAGS"
4995          CPPFLAGS="$cf_save_CPPFLAGS"
4996         ])
4997 ])
4998
4999 if test "$cf_cv_posix_c_source" != no ; then
5000         CFLAGS="$cf_trim_CFLAGS"
5001         CPPFLAGS="$cf_trim_CPPFLAGS"
5002         CF_ADD_CFLAGS($cf_cv_posix_c_source)
5003 fi
5004
5005 ])dnl
5006 dnl ---------------------------------------------------------------------------
5007 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
5008 dnl ------------
5009 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
5010 dnl
5011 dnl $1 = symbol to test
5012 dnl $2 = value (if any) to use for a predefinition
5013 AC_DEFUN([CF_PREDEFINE],
5014 [
5015 AC_MSG_CHECKING(if we must define $1)
5016 AC_TRY_COMPILE([#include <sys/types.h>
5017 ],[
5018 #ifndef $1
5019 make an error
5020 #endif],[cf_result=no],[cf_result=yes])
5021 AC_MSG_RESULT($cf_result)
5022
5023 if test "$cf_result" = yes ; then
5024         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
5025 elif test "x$2" != "x" ; then
5026         AC_MSG_CHECKING(checking for compatible value versus $2)
5027         AC_TRY_COMPILE([#include <sys/types.h>
5028 ],[
5029 #if $1-$2 < 0
5030 make an error
5031 #endif],[cf_result=yes],[cf_result=no])
5032         AC_MSG_RESULT($cf_result)
5033         if test "$cf_result" = no ; then
5034                 # perhaps we can override it - try...
5035                 CPPFLAGS="$CPPFLAGS -D$1=$2"
5036         fi
5037 fi
5038 ])dnl
5039 dnl ---------------------------------------------------------------------------
5040 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
5041 dnl ------------
5042 dnl Append definitions and rules for the given programs to the subdirectory
5043 dnl Makefiles, and the recursion rule for the top-level Makefile.
5044 dnl
5045 dnl parameters
5046 dnl     $1 = script to run
5047 dnl     $2 = list of subdirectories
5048 dnl
5049 dnl variables
5050 dnl     $AWK
5051 AC_DEFUN([CF_PRG_RULES],
5052 [
5053 for cf_dir in $2
5054 do
5055         if test ! -d $srcdir/$cf_dir; then
5056                 continue
5057         elif test -f $srcdir/$cf_dir/programs; then
5058                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
5059         fi
5060 done
5061
5062 ])dnl
5063 dnl ---------------------------------------------------------------------------
5064 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
5065 dnl ----------
5066 dnl Check for archiver "ar".
5067 AC_DEFUN([CF_PROG_AR],[
5068 AC_CHECK_TOOL(AR, ar, ar)
5069 ])
5070 dnl ---------------------------------------------------------------------------
5071 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
5072 dnl -----------
5073 dnl Check for awk, ensure that the check found something.
5074 AC_DEFUN([CF_PROG_AWK],
5075 [
5076 AC_PROG_AWK
5077 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
5078 ])dnl
5079 dnl ---------------------------------------------------------------------------
5080 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
5081 dnl ----------
5082 dnl standard check for CC, plus followup sanity checks
5083 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
5084 AC_DEFUN([CF_PROG_CC],[
5085 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
5086 CF_GCC_VERSION
5087 CF_ACVERSION_CHECK(2.52,
5088         [AC_PROG_CC_STDC],
5089         [CF_ANSI_CC_REQD])
5090 CF_CC_ENV_FLAGS
5091 ])dnl
5092 dnl ---------------------------------------------------------------------------
5093 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
5094 dnl --------------
5095 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
5096 dnl the output file can be renamed, and allows for a shell variable that can
5097 dnl be used later.  The parameter is either CC or CXX.  The result is the
5098 dnl cache variable:
5099 dnl     $cf_cv_prog_CC_c_o
5100 dnl     $cf_cv_prog_CXX_c_o
5101 AC_DEFUN([CF_PROG_CC_C_O],
5102 [AC_REQUIRE([AC_PROG_CC])dnl
5103 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
5104 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
5105 [
5106 cat > conftest.$ac_ext <<CF_EOF
5107 #include <stdio.h>
5108 int main()
5109 {
5110         ${cf_cv_main_return:-return}(0);
5111 }
5112 CF_EOF
5113 # We do the test twice because some compilers refuse to overwrite an
5114 # existing .o file with -o, though they will create one.
5115 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
5116 if AC_TRY_EVAL(ac_try) &&
5117   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
5118 then
5119   eval cf_cv_prog_$1_c_o=yes
5120 else
5121   eval cf_cv_prog_$1_c_o=no
5122 fi
5123 rm -rf conftest*
5124 ])dnl
5125 if test $cf_cv_prog_$1_c_o = yes; then
5126   AC_MSG_RESULT([yes])
5127 else
5128   AC_MSG_RESULT([no])
5129 fi
5130 ])dnl
5131 dnl ---------------------------------------------------------------------------
5132 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
5133 dnl -------------
5134 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
5135 dnl This macro adds a check to ensure the script found something.
5136 AC_DEFUN([CF_PROG_EGREP],
5137 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
5138         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
5139                 then ac_cv_prog_egrep='grep -E'
5140                 else ac_cv_prog_egrep='egrep'
5141         fi])
5142         EGREP=$ac_cv_prog_egrep
5143         AC_SUBST([EGREP])
5144         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
5145 ])dnl
5146 dnl ---------------------------------------------------------------------------
5147 dnl CF_PROG_GNAT version: 3 updated: 2015/04/18 08:56:57
5148 dnl ------------
5149 dnl Check for gnatmake, ensure that it is complete.
5150 AC_DEFUN([CF_PROG_GNAT],[
5151 cf_ada_make=gnatmake
5152 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
5153 if test "$ac_cv_prog_gnat_exists" = no; then
5154         cf_ada_make=
5155         cf_cv_prog_gnat_correct=no
5156 else
5157         CF_GNAT_VERSION
5158         AC_CHECK_PROG(M4_exists, m4, yes, no)
5159         if test "$ac_cv_prog_M4_exists" = no; then
5160                 cf_cv_prog_gnat_correct=no
5161                 echo Ada95 binding required program m4 not found. Ada95 binding disabled.
5162         fi
5163         if test "$cf_cv_prog_gnat_correct" = yes; then
5164                 AC_MSG_CHECKING(if GNAT works)
5165                 CF_GNAT_TRY_RUN([procedure conftest;],
5166 [with Text_IO;
5167 with GNAT.OS_Lib;
5168 procedure conftest is
5169 begin
5170    Text_IO.Put ("Hello World");
5171    Text_IO.New_Line;
5172    GNAT.OS_Lib.OS_Exit (0);
5173 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
5174                 AC_MSG_RESULT($cf_cv_prog_gnat_correct)
5175         fi
5176 fi
5177
5178 AC_SUBST(cf_ada_make)
5179 ])dnl
5180 dnl ---------------------------------------------------------------------------
5181 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
5182 dnl ---------------
5183 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
5184 dnl misc/tabset install won't work properly.  Usually this happens only when
5185 dnl using the fallback mkinstalldirs script
5186 AC_DEFUN([CF_PROG_INSTALL],
5187 [AC_PROG_INSTALL
5188 case $INSTALL in
5189 (/*)
5190         ;;
5191 (*)
5192         CF_DIRNAME(cf_dir,$INSTALL)
5193         test -z "$cf_dir" && cf_dir=.
5194         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
5195         ;;
5196 esac
5197 ])dnl
5198 dnl ---------------------------------------------------------------------------
5199 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
5200 dnl ----------------
5201 dnl Check for ldconfig, needed to fixup shared libraries that would be built
5202 dnl and then used in the install.
5203 AC_DEFUN([CF_PROG_LDCONFIG],[
5204 if test "$cross_compiling" = yes ; then
5205         LDCONFIG=:
5206 else
5207         case "$cf_cv_system_name" in
5208         (dragonfly*|mirbsd*|freebsd*)
5209                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
5210                 ;;
5211         (*) LDPATH=$PATH:/sbin:/usr/sbin
5212                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
5213                 ;;
5214         esac
5215 fi
5216 AC_SUBST(LDCONFIG)
5217 ])dnl
5218 dnl ---------------------------------------------------------------------------
5219 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
5220 dnl ------------
5221 AC_DEFUN([CF_PROG_LINT],
5222 [
5223 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
5224 AC_SUBST(LINT_OPTS)
5225 ])dnl
5226 dnl ---------------------------------------------------------------------------
5227 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
5228 dnl ------------
5229 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
5230 dnl option if it is supported.
5231 AC_DEFUN([CF_PROG_LN_S],[
5232 AC_PROG_LN_S
5233 AC_MSG_CHECKING(if $LN_S -f options work)
5234
5235 rm -f conf$$.src conf$$dst
5236 echo >conf$$.dst
5237 echo first >conf$$.src
5238 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
5239         cf_prog_ln_sf=yes
5240 else
5241         cf_prog_ln_sf=no
5242 fi
5243 rm -f conf$$.dst conf$$src
5244 AC_MSG_RESULT($cf_prog_ln_sf)
5245
5246 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
5247 ])dnl
5248 dnl ---------------------------------------------------------------------------
5249 dnl CF_REGEX version: 12 updated: 2015/04/18 08:56:57
5250 dnl --------
5251 dnl Attempt to determine if we've got one of the flavors of regular-expression
5252 dnl code that we can support.
5253 AC_DEFUN([CF_REGEX],
5254 [
5255
5256 cf_regex_func=no
5257
5258 cf_regex_libs="regex re"
5259 case $host_os in
5260 (mingw*)
5261         cf_regex_libs="gnurx $cf_regex_libs"
5262         ;;
5263 esac
5264
5265 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5266         for cf_regex_lib in $cf_regex_libs
5267         do
5268                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5269                                 CF_ADD_LIB($cf_regex_lib)
5270                                 cf_regex_func=regcomp
5271                                 break])
5272         done
5273 ])
5274
5275 if test "$cf_regex_func" = no ; then
5276         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5277                 AC_CHECK_LIB(gen,compile,[
5278                                 CF_ADD_LIB(gen)
5279                                 cf_regex_func=compile])])
5280 fi
5281
5282 if test "$cf_regex_func" = no ; then
5283         AC_MSG_WARN(cannot find regular expression library)
5284 fi
5285
5286 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5287
5288 cf_cv_regex_hdrs=no
5289 case $cf_regex_func in
5290 (compile)
5291         for cf_regex_hdr in regexp.h regexpr.h
5292         do
5293                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5294                         char *p = compile("", "", "", 0);
5295                         int x = step("", "");
5296                 ],[
5297                         cf_cv_regex_hdrs=$cf_regex_hdr
5298                         break
5299                 ])
5300         done
5301         ;;
5302 (*)
5303         for cf_regex_hdr in regex.h
5304         do
5305                 AC_TRY_LINK([#include <sys/types.h>
5306 #include <$cf_regex_hdr>],[
5307                         regex_t *p;
5308                         int x = regcomp(p, "", 0);
5309                         int y = regexec(p, "", 0, 0, 0);
5310                         regfree(p);
5311                 ],[
5312                         cf_cv_regex_hdrs=$cf_regex_hdr
5313                         break
5314                 ])
5315         done
5316         ;;
5317 esac
5318
5319 ])
5320
5321 case $cf_cv_regex_hdrs in
5322         (no)            AC_MSG_WARN(no regular expression header found) ;;
5323         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
5324         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
5325         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
5326 esac
5327 ])dnl
5328 dnl ---------------------------------------------------------------------------
5329 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5330 dnl ----------------
5331 dnl Remove all -U and -D options that refer to the given symbol from a list
5332 dnl of C compiler options.  This works around the problem that not all
5333 dnl compilers process -U and -D options from left-to-right, so a -U option
5334 dnl cannot be used to cancel the effect of a preceding -D option.
5335 dnl
5336 dnl $1 = target (which could be the same as the source variable)
5337 dnl $2 = source (including '$')
5338 dnl $3 = symbol to remove
5339 define([CF_REMOVE_DEFINE],
5340 [
5341 $1=`echo "$2" | \
5342         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5343                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5344 ])dnl
5345 dnl ---------------------------------------------------------------------------
5346 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5347 dnl -------------
5348 dnl Remove the given library from the symbol
5349 dnl
5350 dnl $1 = target (which could be the same as the source variable)
5351 dnl $2 = source (including '$')
5352 dnl $3 = library to remove
5353 define([CF_REMOVE_LIB],
5354 [
5355 # remove $3 library from $2
5356 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5357 ])dnl
5358 dnl ---------------------------------------------------------------------------
5359 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
5360 dnl -------------
5361 AC_DEFUN([CF_RPATH_HACK],
5362 [
5363 AC_REQUIRE([CF_LD_RPATH_OPT])
5364 AC_MSG_CHECKING(for updated LDFLAGS)
5365 if test -n "$LD_RPATH_OPT" ; then
5366         AC_MSG_RESULT(maybe)
5367
5368         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5369         cf_rpath_list="/usr/lib /lib"
5370         if test "$cf_ldd_prog" != no
5371         then
5372                 cf_rpath_oops=
5373
5374 AC_TRY_LINK([#include <stdio.h>],
5375                 [printf("Hello");],
5376                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
5377                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
5378
5379                 # If we passed the link-test, but get a "not found" on a given library,
5380                 # this could be due to inept reconfiguration of gcc to make it only
5381                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5382                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5383                 # /usr/local libraries.
5384                 if test -n "$cf_rpath_oops"
5385                 then
5386                         for cf_rpath_src in $cf_rpath_oops
5387                         do
5388                                 for cf_rpath_dir in \
5389                                         /usr/local \
5390                                         /usr/pkg \
5391                                         /opt/sfw
5392                                 do
5393                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5394                                         then
5395                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5396                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5397                                                 break
5398                                         fi
5399                                 done
5400                         done
5401                 fi
5402         fi
5403
5404         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5405
5406         CF_RPATH_HACK_2(LDFLAGS)
5407         CF_RPATH_HACK_2(LIBS)
5408
5409         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5410 else
5411         AC_MSG_RESULT(no)
5412 fi
5413 AC_SUBST(EXTRA_LDFLAGS)
5414 ])dnl
5415 dnl ---------------------------------------------------------------------------
5416 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
5417 dnl ---------------
5418 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5419 dnl EXTRA_LDFLAGS for each -L option found.
5420 dnl
5421 dnl $cf_rpath_list contains a list of directories to ignore.
5422 dnl
5423 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5424 dnl      but LIBS often has misplaced -L options.
5425 AC_DEFUN([CF_RPATH_HACK_2],
5426 [
5427 CF_VERBOSE(...checking $1 [$]$1)
5428
5429 cf_rpath_dst=
5430 for cf_rpath_src in [$]$1
5431 do
5432         case $cf_rpath_src in
5433         (-L*)
5434
5435                 # check if this refers to a directory which we will ignore
5436                 cf_rpath_skip=no
5437                 if test -n "$cf_rpath_list"
5438                 then
5439                         for cf_rpath_item in $cf_rpath_list
5440                         do
5441                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5442                                 then
5443                                         cf_rpath_skip=yes
5444                                         break
5445                                 fi
5446                         done
5447                 fi
5448
5449                 if test "$cf_rpath_skip" = no
5450                 then
5451                         # transform the option
5452                         if test "$LD_RPATH_OPT" = "-R " ; then
5453                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5454                         else
5455                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5456                         fi
5457
5458                         # if we have not already added this, add it now
5459                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5460                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5461                         then
5462                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5463                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5464                         fi
5465                 fi
5466                 ;;
5467         esac
5468         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5469 done
5470 $1=$cf_rpath_dst
5471
5472 CF_VERBOSE(...checked $1 [$]$1)
5473 AC_SUBST(EXTRA_LDFLAGS)
5474 ])dnl
5475 dnl ---------------------------------------------------------------------------
5476 dnl CF_SHARED_OPTS version: 87 updated: 2015/04/17 21:13:04
5477 dnl --------------
5478 dnl --------------
5479 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5480 dnl library.
5481 dnl
5482 dnl Notes:
5483 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
5484 dnl the build-tree, i.e., by making use of the libraries that are compiled in
5485 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
5486 dnl shared library since that can lead to unexpected results at runtime.
5487 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
5488 dnl libraries are compiled in ../../lib
5489 dnl
5490 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5491 dnl to install symbolic links to the rel/abi versions of shared libraries.
5492 dnl
5493 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5494 dnl version when making symbolic links.
5495 dnl
5496 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5497 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5498 dnl (ex: libncurses.so.<ver>).
5499 dnl
5500 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5501 AC_DEFUN([CF_SHARED_OPTS],
5502 [
5503         AC_REQUIRE([CF_LD_RPATH_OPT])
5504         RM_SHARED_OPTS=
5505         LOCAL_LDFLAGS=
5506         LOCAL_LDFLAGS2=
5507         LD_SHARED_OPTS=
5508         INSTALL_LIB="-m 644"
5509         : ${rel_builddir:=.}
5510
5511         shlibdir=$libdir
5512         AC_SUBST(shlibdir)
5513
5514         MAKE_DLLS="#"
5515         AC_SUBST(MAKE_DLLS)
5516
5517         cf_cv_do_symlinks=no
5518         cf_ld_rpath_opt=
5519         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5520
5521         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5522         AC_ARG_WITH(shlib-version,
5523         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5524         [test -z "$withval" && withval=auto
5525         case $withval in
5526         (yes)
5527                 cf_cv_shlib_version=auto
5528                 ;;
5529         (rel|abi|auto|no)
5530                 cf_cv_shlib_version=$withval
5531                 ;;
5532         (*)
5533                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
5534                 ;;
5535         esac
5536         ],[cf_cv_shlib_version=auto])
5537         AC_MSG_RESULT($cf_cv_shlib_version)
5538
5539         cf_cv_rm_so_locs=no
5540         cf_try_cflags=
5541
5542         # Some less-capable ports of gcc support only -fpic
5543         CC_SHARED_OPTS=
5544         if test "$GCC" = yes
5545         then
5546                 AC_MSG_CHECKING(which $CC option to use)
5547                 cf_save_CFLAGS="$CFLAGS"
5548                 for CC_SHARED_OPTS in -fPIC -fpic ''
5549                 do
5550                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5551                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5552                 done
5553                 AC_MSG_RESULT($CC_SHARED_OPTS)
5554                 CFLAGS="$cf_save_CFLAGS"
5555         fi
5556
5557         cf_cv_shlib_version_infix=no
5558
5559         case $cf_cv_system_name in
5560         (aix4.[3-9]*|aix[[5-7]]*)
5561                 if test "$GCC" = yes; then
5562                         CC_SHARED_OPTS='-Wl,-brtl'
5563                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5564                 else
5565                         CC_SHARED_OPTS='-brtl'
5566                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
5567                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5568                 fi
5569                 ;;
5570         (beos*)
5571                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5572                 ;;
5573         (cygwin*)
5574                 CC_SHARED_OPTS=
5575                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5576                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5577                 cf_cv_shlib_version=cygdll
5578                 cf_cv_shlib_version_infix=cygdll
5579                 shlibdir=$bindir
5580                 MAKE_DLLS=
5581                 cat >mk_shared_lib.sh <<-CF_EOF
5582                 #!/bin/sh
5583                 SHARED_LIB=\[$]1
5584                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5585                 shift
5586                 cat <<-EOF
5587                 Linking shared library
5588                 ** SHARED_LIB \[$]SHARED_LIB
5589                 ** IMPORT_LIB \[$]IMPORT_LIB
5590 EOF
5591                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5592 CF_EOF
5593                 chmod +x mk_shared_lib.sh
5594                 ;;
5595         (msys*)
5596                 CC_SHARED_OPTS=
5597                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5598                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5599                 cf_cv_shlib_version=msysdll
5600                 cf_cv_shlib_version_infix=msysdll
5601                 shlibdir=$bindir
5602                 MAKE_DLLS=
5603                 cat >mk_shared_lib.sh <<-CF_EOF
5604                 #!/bin/sh
5605                 SHARED_LIB=\[$]1
5606                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5607                 shift
5608                 cat <<-EOF
5609                 Linking shared library
5610                 ** SHARED_LIB \[$]SHARED_LIB
5611                 ** IMPORT_LIB \[$]IMPORT_LIB
5612 EOF
5613                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5614 CF_EOF
5615                 chmod +x mk_shared_lib.sh
5616                 ;;
5617         (darwin*)
5618                 cf_try_cflags="no-cpp-precomp"
5619                 CC_SHARED_OPTS="-dynamic"
5620                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5621                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5622                 cf_cv_shlib_version_infix=yes
5623                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5624                         cf_save_LDFLAGS=$LDFLAGS
5625                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5626                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5627                                 LDFLAGS=$cf_save_LDFLAGS])
5628                 if test $cf_cv_ldflags_search_paths_first = yes; then
5629                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5630                 fi
5631                 ;;
5632         (hpux[[7-8]]*)
5633                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
5634                 if test "$GCC" != yes; then
5635                         CC_SHARED_OPTS='+Z'
5636                 fi
5637                 MK_SHARED_LIB='${LD} -b -o $[@]'
5638                 INSTALL_LIB="-m 555"
5639                 ;;
5640         (hpux*)
5641                 # (tested with gcc 2.7.2 -- I don't have c89)
5642                 if test "$GCC" = yes; then
5643                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5644                 else
5645                         CC_SHARED_OPTS='+Z'
5646                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5647                 fi
5648                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5649                 # HP-UX shared libraries must be executable, and should be
5650                 # readonly to exploit a quirk in the memory manager.
5651                 INSTALL_LIB="-m 555"
5652                 ;;
5653         (interix*)
5654                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5655                 if test "$cf_cv_shlib_version" = rel; then
5656                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5657                 else
5658                         cf_shared_soname='`basename $@`'
5659                 fi
5660                 CC_SHARED_OPTS=
5661                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5662                 ;;
5663         (irix*)
5664                 if test "$cf_cv_enable_rpath" = yes ; then
5665                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5666                 fi
5667                 # tested with IRIX 5.2 and 'cc'.
5668                 if test "$GCC" != yes; then
5669                         CC_SHARED_OPTS='-KPIC'
5670                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5671                 else
5672                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5673                 fi
5674                 cf_cv_rm_so_locs=yes
5675                 ;;
5676         (linux*|gnu*|k*bsd*-gnu)
5677                 if test "$DFT_LWR_MODEL" = "shared" ; then
5678                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5679                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5680                 fi
5681                 if test "$cf_cv_enable_rpath" = yes ; then
5682                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5683                 fi
5684                 CF_SHARED_SONAME
5685                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5686                 ;;
5687         (mingw*)
5688                 cf_cv_shlib_version=mingw
5689                 cf_cv_shlib_version_infix=mingw
5690                 shlibdir=$bindir
5691                 MAKE_DLLS=
5692                 if test "$DFT_LWR_MODEL" = "shared" ; then
5693                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
5694                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5695                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
5696                 fi
5697                 CC_SHARED_OPTS=
5698                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5699                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5700                 cat >mk_shared_lib.sh <<-CF_EOF
5701                 #!/bin/sh
5702                 SHARED_LIB=\[$]1
5703                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5704                 shift
5705                 cat <<-EOF
5706                 Linking shared library
5707                 ** SHARED_LIB \[$]SHARED_LIB
5708                 ** IMPORT_LIB \[$]IMPORT_LIB
5709 EOF
5710                 exec \[$]* -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5711 CF_EOF
5712                 chmod +x mk_shared_lib.sh
5713                 ;;
5714         (openbsd[[2-9]].*|mirbsd*)
5715                 if test "$DFT_LWR_MODEL" = "shared" ; then
5716                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5717                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5718                 fi
5719                 if test "$cf_cv_enable_rpath" = yes ; then
5720                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5721                 fi
5722                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5723                 CF_SHARED_SONAME
5724                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5725                 ;;
5726         (nto-qnx*|openbsd*|freebsd[[12]].*)
5727                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5728                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5729                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5730                 ;;
5731         (dragonfly*|freebsd*)
5732                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5733                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5734                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5735                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
5736                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5737                 fi
5738                 CF_SHARED_SONAME
5739                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5740                 ;;
5741         (netbsd*)
5742                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5743                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5744                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5745                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5746                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5747                         if test "$cf_cv_shlib_version" = auto; then
5748                         if test -f /usr/libexec/ld.elf_so; then
5749                                 cf_cv_shlib_version=abi
5750                         else
5751                                 cf_cv_shlib_version=rel
5752                         fi
5753                         fi
5754                         CF_SHARED_SONAME
5755                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
5756                 else
5757                         MK_SHARED_LIB='${CC} -Wl,-shared -Wl,-Bshareable -o $[@]'
5758                 fi
5759                 ;;
5760         (osf*|mls+*)
5761                 # tested with OSF/1 V3.2 and 'cc'
5762                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
5763                 # link with shared libs).
5764                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
5765                 case $host_os in
5766                 (osf4*)
5767                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
5768                         ;;
5769                 esac
5770                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
5771                 if test "$DFT_LWR_MODEL" = "shared" ; then
5772                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5773                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5774                 fi
5775                 cf_cv_rm_so_locs=yes
5776                 ;;
5777         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
5778                 # tested with osr5.0.5
5779                 if test "$GCC" != yes; then
5780                         CC_SHARED_OPTS='-belf -KPIC'
5781                 fi
5782                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
5783                 if test "$cf_cv_enable_rpath" = yes ; then
5784                         # only way is to set LD_RUN_PATH but no switch for it
5785                         RUN_PATH=$libdir
5786                 fi
5787                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5788                 LINK_PROGS='LD_RUN_PATH=${libdir}'
5789                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
5790                 ;;
5791         (sunos4*)
5792                 # tested with SunOS 4.1.1 and gcc 2.7.0
5793                 if test "$GCC" != yes; then
5794                         CC_SHARED_OPTS='-KPIC'
5795                 fi
5796                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
5797                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5798                 ;;
5799         (solaris2*)
5800                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
5801                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
5802                 if test "$DFT_LWR_MODEL" = "shared" ; then
5803                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
5804                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5805                 fi
5806                 if test "$cf_cv_enable_rpath" = yes ; then
5807                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
5808                 fi
5809                 CF_SHARED_SONAME
5810                 if test "$GCC" != yes; then
5811                         cf_save_CFLAGS="$CFLAGS"
5812                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
5813                         do
5814                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
5815                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
5816                         done
5817                         CFLAGS="$cf_save_CFLAGS"
5818                         CC_SHARED_OPTS=$cf_shared_opts
5819                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5820                 else
5821                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5822                 fi
5823                 ;;
5824         (sysv5uw7*|unix_sv*)
5825                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
5826                 if test "$GCC" != yes; then
5827                         CC_SHARED_OPTS='-KPIC'
5828                 fi
5829                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
5830                 ;;
5831         (*)
5832                 CC_SHARED_OPTS='unknown'
5833                 MK_SHARED_LIB='echo unknown'
5834                 ;;
5835         esac
5836
5837         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
5838         case "$cf_cv_shlib_version" in
5839         (rel|abi)
5840                 case "$MK_SHARED_LIB" in
5841                 (*'-o $[@]')
5842                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
5843                         ;;
5844                 (*)
5845                         AC_MSG_WARN(ignored --with-shlib-version)
5846                         ;;
5847                 esac
5848                 ;;
5849         esac
5850
5851         if test -n "$cf_try_cflags"
5852         then
5853 cat > conftest.$ac_ext <<EOF
5854 #line __oline__ "${as_me:-configure}"
5855 #include <stdio.h>
5856 int main(int argc, char *argv[[]])
5857 {
5858         printf("hello\n");
5859         return (argv[[argc-1]] == 0) ;
5860 }
5861 EOF
5862                 cf_save_CFLAGS="$CFLAGS"
5863                 for cf_opt in $cf_try_cflags
5864                 do
5865                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
5866                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
5867                         if AC_TRY_EVAL(ac_compile); then
5868                                 AC_MSG_RESULT(yes)
5869                                 cf_save_CFLAGS="$CFLAGS"
5870                         else
5871                                 AC_MSG_RESULT(no)
5872                         fi
5873                 done
5874                 CFLAGS="$cf_save_CFLAGS"
5875         fi
5876
5877
5878         # RPATH_LIST is a colon-separated list of directories
5879         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
5880         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
5881
5882         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
5883
5884         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
5885         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
5886
5887         AC_SUBST(CC_SHARED_OPTS)
5888         AC_SUBST(LD_RPATH_OPT)
5889         AC_SUBST(LD_SHARED_OPTS)
5890         AC_SUBST(MK_SHARED_LIB)
5891         AC_SUBST(RM_SHARED_OPTS)
5892
5893         AC_SUBST(LINK_PROGS)
5894         AC_SUBST(LINK_TESTS)
5895
5896         AC_SUBST(EXTRA_LDFLAGS)
5897         AC_SUBST(LOCAL_LDFLAGS)
5898         AC_SUBST(LOCAL_LDFLAGS2)
5899
5900         AC_SUBST(INSTALL_LIB)
5901         AC_SUBST(RPATH_LIST)
5902 ])dnl
5903 dnl ---------------------------------------------------------------------------
5904 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
5905 dnl ----------------
5906 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
5907 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
5908 dnl option.
5909 dnl
5910 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
5911 dnl If missing, use "rel".
5912 define([CF_SHARED_SONAME],
5913 [
5914         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
5915         if test "$cf_cv_shlib_version" = rel; then
5916                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
5917         else
5918                 cf_cv_shared_soname='`basename $[@]`'
5919         fi
5920 ])
5921 dnl ---------------------------------------------------------------------------
5922 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
5923 dnl -----------
5924 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
5925 dnl programs need this test).
5926 dnl
5927 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
5928 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
5929 dnl winsize declaration is left alone - we may revisit this if Apple choose to
5930 dnl break that part of the interface as well.
5931 AC_DEFUN([CF_SIGWINCH],
5932 [
5933 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
5934         AC_TRY_COMPILE([
5935 #include <sys/types.h>
5936 #include <sys/signal.h>
5937 ],[int x = SIGWINCH],
5938         [cf_cv_define_sigwinch=yes],
5939         [AC_TRY_COMPILE([
5940 #undef _XOPEN_SOURCE
5941 #undef _POSIX_SOURCE
5942 #undef _POSIX_C_SOURCE
5943 #include <sys/types.h>
5944 #include <sys/signal.h>
5945 ],[int x = SIGWINCH],
5946         [cf_cv_define_sigwinch=maybe],
5947         [cf_cv_define_sigwinch=no])
5948 ])
5949 ])
5950
5951 if test "$cf_cv_define_sigwinch" = maybe ; then
5952 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
5953 cf_cv_fixup_sigwinch=unknown
5954 cf_sigwinch=32
5955 while test $cf_sigwinch != 1
5956 do
5957         AC_TRY_COMPILE([
5958 #undef _XOPEN_SOURCE
5959 #undef _POSIX_SOURCE
5960 #undef _POSIX_C_SOURCE
5961 #include <sys/types.h>
5962 #include <sys/signal.h>
5963 ],[
5964 #if SIGWINCH != $cf_sigwinch
5965 make an error
5966 #endif
5967 int x = SIGWINCH],
5968         [cf_cv_fixup_sigwinch=$cf_sigwinch
5969          break])
5970
5971 cf_sigwinch=`expr $cf_sigwinch - 1`
5972 done
5973 ])
5974
5975         if test "$cf_cv_fixup_sigwinch" != unknown ; then
5976                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
5977         fi
5978 fi
5979 ])dnl
5980 dnl ---------------------------------------------------------------------------
5981 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
5982 dnl ---------------
5983 dnl signal handler, but there are some gcc depedencies in that recommendation.
5984 dnl Try anyway.
5985 AC_DEFUN([CF_SIG_ATOMIC_T],
5986 [
5987 AC_MSG_CHECKING(for signal global datatype)
5988 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
5989         for cf_type in \
5990                 "volatile sig_atomic_t" \
5991                 "sig_atomic_t" \
5992                 "int"
5993         do
5994         AC_TRY_COMPILE([
5995 #include <sys/types.h>
5996 #include <signal.h>
5997 #include <stdio.h>
5998
5999 extern $cf_type x;
6000 $cf_type x;
6001 static void handler(int sig)
6002 {
6003         x = 5;
6004 }],
6005                 [signal(SIGINT, handler);
6006                  x = 1],
6007                 [cf_cv_sig_atomic_t=$cf_type],
6008                 [cf_cv_sig_atomic_t=no])
6009                 test "$cf_cv_sig_atomic_t" != no && break
6010         done
6011         ])
6012 AC_MSG_RESULT($cf_cv_sig_atomic_t)
6013 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
6014 ])dnl
6015 dnl ---------------------------------------------------------------------------
6016 dnl CF_SIZECHANGE version: 11 updated: 2015/04/18 08:56:57
6017 dnl -------------
6018 dnl Check for definitions & structures needed for window size-changing
6019 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
6020 AC_DEFUN([CF_SIZECHANGE],
6021 [
6022 AC_REQUIRE([CF_STRUCT_TERMIOS])
6023 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
6024         cf_cv_sizechange=unknown
6025         cf_save_CPPFLAGS="$CPPFLAGS"
6026
6027 for cf_opts in "" "NEED_PTEM_H"
6028 do
6029
6030         CPPFLAGS="$cf_save_CPPFLAGS"
6031         test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
6032         AC_TRY_COMPILE([#include <sys/types.h>
6033 #ifdef HAVE_TERMIOS_H
6034 #include <termios.h>
6035 #else
6036 #ifdef HAVE_TERMIO_H
6037 #include <termio.h>
6038 #endif
6039 #endif
6040 #ifdef NEED_PTEM_H
6041 /* This is a workaround for SCO:  they neglected to define struct winsize in
6042  * termios.h -- it's only in termio.h and ptem.h
6043  */
6044 #include        <sys/stream.h>
6045 #include        <sys/ptem.h>
6046 #endif
6047 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
6048 #include <sys/ioctl.h>
6049 #endif
6050 ],[
6051 #ifdef TIOCGSIZE
6052         struct ttysize win;     /* FIXME: what system is this? */
6053         int y = win.ts_lines;
6054         int x = win.ts_cols;
6055 #else
6056 #ifdef TIOCGWINSZ
6057         struct winsize win;
6058         int y = win.ws_row;
6059         int x = win.ws_col;
6060 #else
6061         no TIOCGSIZE or TIOCGWINSZ
6062 #endif /* TIOCGWINSZ */
6063 #endif /* TIOCGSIZE */
6064         ],
6065         [cf_cv_sizechange=yes],
6066         [cf_cv_sizechange=no])
6067
6068         CPPFLAGS="$cf_save_CPPFLAGS"
6069         if test "$cf_cv_sizechange" = yes ; then
6070                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
6071                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
6072                 break
6073         fi
6074 done
6075 ])
6076 if test "$cf_cv_sizechange" != no ; then
6077         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechar declarations are provided])
6078         case $cf_cv_sizechange in
6079         (NEED*)
6080                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
6081                 ;;
6082         esac
6083 fi
6084 ])dnl
6085 dnl ---------------------------------------------------------------------------
6086 dnl CF_SRC_MODULES version: 29 updated: 2015/04/12 11:42:01
6087 dnl --------------
6088 dnl For each parameter, test if the source-directory exists, and if it contains
6089 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
6090 dnl use in CF_LIB_RULES.
6091 dnl
6092 dnl This uses the configured value to make the lists SRC_SUBDIRS and
6093 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
6094 AC_DEFUN([CF_SRC_MODULES],
6095 [
6096 AC_MSG_CHECKING(for src modules)
6097
6098 # dependencies and linker-arguments for test-programs
6099 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
6100 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
6101 if test "$DFT_LWR_MODEL" = "libtool"; then
6102         TEST_ARGS="${TEST_DEPS}"
6103         TEST_ARG2="${TEST_DEP2}"
6104 else
6105         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
6106         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
6107 fi
6108
6109 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
6110 cf_cv_src_modules=
6111 for cf_dir in $1
6112 do
6113         if test -f $srcdir/$cf_dir/modules; then
6114
6115                 # We may/may not have tack in the distribution, though the
6116                 # makefile is.
6117                 if test $cf_dir = tack ; then
6118                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
6119                                 continue
6120                         fi
6121                 fi
6122
6123                 if test -z "$cf_cv_src_modules"; then
6124                         cf_cv_src_modules=$cf_dir
6125                 else
6126                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
6127                 fi
6128
6129                 # Make the ncurses_cfg.h file record the library interface files as
6130                 # well.  These are header files that are the same name as their
6131                 # directory.  Ncurses is the only library that does not follow
6132                 # that pattern.
6133                 if test $cf_dir = tack ; then
6134                         continue
6135                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
6136                         CF_UPPER(cf_have_include,$cf_dir)
6137                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
6138                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
6139                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
6140                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
6141                         if test "$DFT_LWR_MODEL" = "libtool"; then
6142                                 TEST_ARGS="${TEST_DEPS}"
6143                                 TEST_ARG2="${TEST_DEP2}"
6144                         else
6145                                 TEST_ARGS="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARGS"
6146                                 TEST_ARG2="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARG2"
6147                         fi
6148                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
6149                 fi
6150         fi
6151 done
6152 AC_MSG_RESULT($cf_cv_src_modules)
6153
6154 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
6155 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
6156
6157 AC_SUBST(TEST_ARGS)
6158 AC_SUBST(TEST_DEPS)
6159
6160 AC_SUBST(TEST_ARG2)
6161 AC_SUBST(TEST_DEP2)
6162
6163 SRC_SUBDIRS=
6164 if test "x$cf_with_manpages" != xno ; then
6165         SRC_SUBDIRS="$SRC_SUBDIRS man"
6166 fi
6167 SRC_SUBDIRS="$SRC_SUBDIRS include"
6168 for cf_dir in $cf_cv_src_modules
6169 do
6170         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
6171 done
6172 if test "x$cf_with_tests" != "xno" ; then
6173         SRC_SUBDIRS="$SRC_SUBDIRS test"
6174 fi
6175 # always make this, to install the ncurses-config script
6176 SRC_SUBDIRS="$SRC_SUBDIRS misc"
6177 if test "$cf_with_cxx_binding" != no; then
6178         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
6179         SRC_SUBDIRS="$SRC_SUBDIRS c++"
6180 fi
6181
6182 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
6183 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
6184
6185 AC_SUBST(PC_MODULES_TO_MAKE)
6186
6187 ADA_SUBDIRS=
6188 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
6189         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
6190         ADA_SUBDIRS="gen src"
6191         if test "x$cf_with_tests" != "xno" ; then
6192                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
6193         fi
6194 fi
6195
6196 SUB_MAKEFILES=
6197 for cf_dir in $SRC_SUBDIRS
6198 do
6199         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
6200 done
6201
6202 if test -n "$ADA_SUBDIRS"; then
6203         for cf_dir in $ADA_SUBDIRS
6204         do
6205                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
6206         done
6207         AC_SUBST(ADA_SUBDIRS)
6208 fi
6209 ])dnl
6210 dnl ---------------------------------------------------------------------------
6211 dnl CF_STDCPP_LIBRARY version: 8 updated: 2015/04/17 21:13:04
6212 dnl -----------------
6213 dnl Check for -lstdc++, which is GNU's standard C++ library.
6214 AC_DEFUN([CF_STDCPP_LIBRARY],
6215 [
6216 if test -n "$GXX" ; then
6217 case $cf_cv_system_name in
6218 (os2*)
6219         cf_stdcpp_libname=stdcpp
6220         ;;
6221 (*)
6222         cf_stdcpp_libname=stdc++
6223         ;;
6224 esac
6225 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
6226         cf_save="$LIBS"
6227         CF_ADD_LIB($cf_stdcpp_libname)
6228 AC_TRY_LINK([
6229 #include <strstream.h>],[
6230 char buf[80];
6231 strstreambuf foo(buf, sizeof(buf))
6232 ],
6233         [cf_cv_libstdcpp=yes],
6234         [cf_cv_libstdcpp=no])
6235         LIBS="$cf_save"
6236 ])
6237 test "$cf_cv_libstdcpp" = yes && CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS)
6238 fi
6239 ])dnl
6240 dnl ---------------------------------------------------------------------------
6241 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
6242 dnl --------------
6243 dnl     Remove "-g" option from the compiler options
6244 AC_DEFUN([CF_STRIP_G_OPT],
6245 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
6246 dnl ---------------------------------------------------------------------------
6247 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
6248 dnl -------------------
6249 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
6250 dnl do this if we've found the sigaction function.
6251 AC_DEFUN([CF_STRUCT_SIGACTION],[
6252 AC_REQUIRE([CF_XOPEN_SOURCE])
6253
6254 if test "$ac_cv_func_sigaction" = yes; then
6255 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
6256 AC_TRY_COMPILE([
6257 #include <sys/types.h>
6258 #include <signal.h>],
6259         [struct sigaction act],
6260         [sigact_bad=no],
6261         [
6262 AC_TRY_COMPILE([
6263 #define _POSIX_SOURCE
6264 #include <sys/types.h>
6265 #include <signal.h>],
6266         [struct sigaction act],
6267         [sigact_bad=yes
6268          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
6269          [sigact_bad=unknown])])
6270 AC_MSG_RESULT($sigact_bad)
6271 fi
6272 ])dnl
6273 dnl ---------------------------------------------------------------------------
6274 dnl CF_STRUCT_TERMIOS version: 8 updated: 2015/04/15 19:08:48
6275 dnl -----------------
6276 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
6277 AC_DEFUN([CF_STRUCT_TERMIOS],[
6278 AC_REQUIRE([CF_XOPEN_SOURCE])
6279
6280 AC_CHECK_HEADERS( \
6281 termio.h \
6282 termios.h \
6283 unistd.h \
6284 )
6285
6286 if test "$ISC" = yes ; then
6287         AC_CHECK_HEADERS( sys/termio.h )
6288 fi
6289 if test "$ac_cv_header_termios_h" = yes ; then
6290         case "$CFLAGS $CPPFLAGS" in
6291         (*-D_POSIX_SOURCE*)
6292                 termios_bad=dunno ;;
6293         (*)     termios_bad=maybe ;;
6294         esac
6295         if test "$termios_bad" = maybe ; then
6296         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
6297         AC_TRY_COMPILE([#include <termios.h>],
6298                 [struct termios foo; int x = foo.c_iflag],
6299                 termios_bad=no, [
6300                 AC_TRY_COMPILE([
6301 #define _POSIX_SOURCE
6302 #include <termios.h>],
6303                         [struct termios foo; int x = foo.c_iflag],
6304                         termios_bad=unknown,
6305                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
6306                         ])
6307         AC_MSG_RESULT($termios_bad)
6308         fi
6309 fi
6310 ])dnl
6311 dnl ---------------------------------------------------------------------------
6312 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
6313 dnl --------------
6314 dnl Construct a search-list for a nonstandard header/lib-file
6315 dnl     $1 = the variable to return as result
6316 dnl     $2 = the package name
6317 dnl     $3 = the subdirectory, e.g., bin, include or lib
6318 AC_DEFUN([CF_SUBDIR_PATH],
6319 [
6320 $1=
6321
6322 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
6323
6324 for cf_subdir_prefix in \
6325         /usr \
6326         /usr/local \
6327         /usr/pkg \
6328         /opt \
6329         /opt/local \
6330         [$]HOME
6331 do
6332         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
6333 done
6334 ])dnl
6335 dnl ---------------------------------------------------------------------------
6336 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
6337 dnl -----------
6338 dnl     Shorthand macro for substituting things that the user may override
6339 dnl     with an environment variable.
6340 dnl
6341 dnl     $1 = condition to pass to "test"
6342 dnl     $2 = environment variable
6343 dnl     $3 = value if the test succeeds
6344 dnl     $4 = value if the test fails
6345 AC_DEFUN([CF_SUBST_IF],
6346 [
6347 if test $1 ; then
6348         $2=$3
6349 ifelse($4,,,[else
6350         $2=$4])
6351 fi
6352 AC_SUBST($2)
6353 ])dnl
6354 dnl ---------------------------------------------------------------------------
6355 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
6356 dnl ------------------------
6357 dnl Get the version-number for use in shared-library naming, etc.
6358 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
6359 [
6360 AC_REQUIRE([CF_PROG_EGREP])
6361 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6362 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6363 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6364 cf_cv_abi_version=${NCURSES_MAJOR}
6365 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
6366 dnl Show the computed version, for logging
6367 cf_cv_timestamp=`date`
6368 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
6369 dnl We need these values in the generated headers
6370 AC_SUBST(NCURSES_MAJOR)
6371 AC_SUBST(NCURSES_MINOR)
6372 AC_SUBST(NCURSES_PATCH)
6373 dnl We need these values in the generated makefiles
6374 AC_SUBST(cf_cv_rel_version)
6375 AC_SUBST(cf_cv_abi_version)
6376 AC_SUBST(cf_cv_builtin_bool)
6377 AC_SUBST(cf_cv_header_stdbool_h)
6378 AC_SUBST(cf_cv_type_of_bool)dnl
6379 ])dnl
6380 dnl ---------------------------------------------------------------------------
6381 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
6382 dnl ------------------
6383 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6384 dnl older SCO configurations.
6385 AC_DEFUN([CF_SYS_TIME_SELECT],
6386 [
6387 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6388 AC_CACHE_VAL(cf_cv_sys_time_select,[
6389 AC_TRY_COMPILE([
6390 #include <sys/types.h>
6391 #ifdef HAVE_SYS_TIME_H
6392 #include <sys/time.h>
6393 #endif
6394 #ifdef HAVE_SYS_SELECT_H
6395 #include <sys/select.h>
6396 #endif
6397 ],[],[cf_cv_sys_time_select=yes],
6398          [cf_cv_sys_time_select=no])
6399          ])
6400 AC_MSG_RESULT($cf_cv_sys_time_select)
6401 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
6402 ])dnl
6403 dnl ---------------------------------------------------------------------------
6404 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
6405 dnl ---------------
6406 dnl Define a top_builddir symbol, for applications that need an absolute path.
6407 AC_DEFUN([CF_TOP_BUILDDIR],
6408 [
6409 top_builddir=ifelse($1,,`pwd`,$1)
6410 AC_SUBST(top_builddir)
6411 ])dnl
6412 dnl ---------------------------------------------------------------------------
6413 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6414 dnl -------------------
6415 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6416 dnl can define it successfully.
6417 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6418 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6419         AC_TRY_COMPILE([
6420 #include <stdlib.h>
6421 #include <string.h>
6422 #include <sys/types.h>
6423 ],[
6424 #ifndef _XOPEN_SOURCE
6425 make an error
6426 #endif],
6427         [cf_cv_xopen_source=no],
6428         [cf_save="$CPPFLAGS"
6429          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6430          AC_TRY_COMPILE([
6431 #include <stdlib.h>
6432 #include <string.h>
6433 #include <sys/types.h>
6434 ],[
6435 #ifdef _XOPEN_SOURCE
6436 make an error
6437 #endif],
6438         [cf_cv_xopen_source=no],
6439         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6440         CPPFLAGS="$cf_save"
6441         ])
6442 ])
6443
6444 if test "$cf_cv_xopen_source" != no ; then
6445         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6446         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6447         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6448         CF_ADD_CFLAGS($cf_temp_xopen_source)
6449 fi
6450 ])
6451 dnl ---------------------------------------------------------------------------
6452 dnl CF_TYPEOF_CHTYPE version: 9 updated: 2012/10/06 17:56:13
6453 dnl ----------------
6454 dnl Determine the type we should use for chtype (and attr_t, which is treated
6455 dnl as the same thing).  We want around 32 bits, so on most machines want a
6456 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6457 dnl wide characters, we have to have a type compatible with that, as well.
6458 AC_DEFUN([CF_TYPEOF_CHTYPE],
6459 [
6460 AC_MSG_CHECKING([for type of chtype])
6461 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6462                 AC_TRY_RUN([
6463 #define WANT_BITS 31
6464 #include <stdio.h>
6465 int main()
6466 {
6467         FILE *fp = fopen("cf_test.out", "w");
6468         if (fp != 0) {
6469                 char *result = "long";
6470                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6471                         int n;
6472                         unsigned int x, y;
6473                         for (n = 0; n < WANT_BITS; n++) {
6474                                 x = (1 << n);
6475                                 y = (x >> n);
6476                                 if (y != 1 || x == 0) {
6477                                         x = 0;
6478                                         break;
6479                                 }
6480                         }
6481                         /*
6482                          * If x is nonzero, an int is big enough for the bits
6483                          * that we want.
6484                          */
6485                         result = (x != 0) ? "int" : "long";
6486                 }
6487                 fputs(result, fp);
6488                 fclose(fp);
6489         }
6490         ${cf_cv_main_return:-return}(0);
6491 }
6492                 ],
6493                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6494                 [cf_cv_typeof_chtype=long],
6495                 [cf_cv_typeof_chtype=long])
6496                 rm -f cf_test.out
6497         ])
6498 AC_MSG_RESULT($cf_cv_typeof_chtype)
6499
6500 AC_SUBST(cf_cv_typeof_chtype)
6501 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
6502 ])dnl
6503 dnl ---------------------------------------------------------------------------
6504 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
6505 dnl -----------------
6506 dnl
6507 AC_DEFUN([CF_TYPE_SIGACTION],
6508 [
6509 AC_MSG_CHECKING([for type sigaction_t])
6510 AC_CACHE_VAL(cf_cv_type_sigaction,[
6511         AC_TRY_COMPILE([
6512 #include <signal.h>],
6513                 [sigaction_t x],
6514                 [cf_cv_type_sigaction=yes],
6515                 [cf_cv_type_sigaction=no])])
6516 AC_MSG_RESULT($cf_cv_type_sigaction)
6517 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
6518 ])dnl
6519 dnl ---------------------------------------------------------------------------
6520 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6521 dnl --------------------
6522 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6523 dnl won't, but they're still there.
6524 AC_DEFUN([CF_UNSIGNED_LITERALS],
6525 [
6526 AC_MSG_CHECKING([if unsigned literals are legal])
6527 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6528         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6529                 [cf_cv_unsigned_literals=yes],
6530                 [cf_cv_unsigned_literals=no])
6531         ])
6532 AC_MSG_RESULT($cf_cv_unsigned_literals)
6533 ])dnl
6534 dnl ---------------------------------------------------------------------------
6535 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6536 dnl --------
6537 dnl Make an uppercase version of a variable
6538 dnl $1=uppercase($2)
6539 AC_DEFUN([CF_UPPER],
6540 [
6541 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6542 ])dnl
6543 dnl ---------------------------------------------------------------------------
6544 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
6545 dnl -----------
6546 dnl Check for multibyte support, and if not found, utf8 compatibility library
6547 AC_DEFUN([CF_UTF8_LIB],
6548 [
6549 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6550         cf_save_LIBS="$LIBS"
6551         AC_TRY_LINK([
6552 #include <stdlib.h>],[putwc(0,0);],
6553         [cf_cv_utf8_lib=yes],
6554         [CF_FIND_LINKAGE([
6555 #include <libutf8.h>],[putwc(0,0);],utf8,
6556                 [cf_cv_utf8_lib=add-on],
6557                 [cf_cv_utf8_lib=no])
6558 ])])
6559
6560 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6561 # ncurses/ncursesw:
6562 if test "$cf_cv_utf8_lib" = "add-on" ; then
6563         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
6564         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6565         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6566         CF_ADD_LIBS($cf_cv_library_file_utf8)
6567 fi
6568 ])dnl
6569 dnl ---------------------------------------------------------------------------
6570 dnl CF_VA_COPY version: 3 updated: 2012/10/06 11:17:15
6571 dnl ----------
6572 dnl check for va_copy, part of stdarg.h
6573 dnl Also, workaround for glibc's __va_copy, by checking for both.
6574 AC_DEFUN([CF_VA_COPY],[
6575 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6576 AC_TRY_LINK([
6577 #include <stdarg.h>
6578 ],[
6579         static va_list dst;
6580         static va_list src;
6581         va_copy(dst, src)],
6582         cf_cv_have_va_copy=yes,
6583         cf_cv_have_va_copy=no)])
6584
6585 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
6586
6587 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6588 AC_TRY_LINK([
6589 #include <stdarg.h>
6590 ],[
6591         static va_list dst;
6592         static va_list src;
6593         __va_copy(dst, src)],
6594         cf_cv_have___va_copy=yes,
6595         cf_cv_have___va_copy=no)])
6596
6597 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
6598 ])
6599 dnl ---------------------------------------------------------------------------
6600 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6601 dnl ----------
6602 dnl Use AC_VERBOSE w/o the warnings
6603 AC_DEFUN([CF_VERBOSE],
6604 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6605 CF_MSG_LOG([$1])
6606 ])dnl
6607 dnl ---------------------------------------------------------------------------
6608 dnl CF_VERSION_INFO version: 7 updated: 2015/04/17 21:13:04
6609 dnl ---------------
6610 dnl Define several useful symbols derived from the VERSION file.  A separate
6611 dnl file is preferred to embedding the version numbers in various scripts.
6612 dnl (automake is a textbook-example of why the latter is a bad idea, but there
6613 dnl are others).
6614 dnl
6615 dnl The file contents are:
6616 dnl     libtool-version release-version patch-version
6617 dnl or
6618 dnl     release-version
6619 dnl where
6620 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
6621 dnl     release-version consists of a major version and minor version
6622 dnl             separated by '.', optionally followed by a patch-version
6623 dnl             separated by '-'.  The minor version need not be an
6624 dnl             integer (but it is preferred).
6625 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
6626 dnl             scripts can easily compare versions.
6627 dnl
6628 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
6629 dnl simply extracts the first field using 'cut -f1'.
6630 dnl
6631 dnl Optional parameters:
6632 dnl $1 = internal name for package
6633 dnl $2 = external name for package
6634 AC_DEFUN([CF_VERSION_INFO],
6635 [
6636 if test -f $srcdir/VERSION ; then
6637         AC_MSG_CHECKING(for package version)
6638
6639         # if there are not enough fields, cut returns the last one...
6640         cf_field1=`sed -e '2,$d' $srcdir/VERSION|cut -f1`
6641         cf_field2=`sed -e '2,$d' $srcdir/VERSION|cut -f2`
6642         cf_field3=`sed -e '2,$d' $srcdir/VERSION|cut -f3`
6643
6644         # this is how CF_BUNDLED_INTL uses $VERSION:
6645         VERSION="$cf_field1"
6646
6647         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
6648         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
6649
6650         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
6651         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
6652
6653         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
6654
6655         AC_MSG_CHECKING(for package patch date)
6656         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
6657         case .$VERSION_PATCH in
6658         (.)
6659                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
6660                 ;;
6661         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
6662                 ;;
6663         (*)
6664                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
6665                 ;;
6666         esac
6667         AC_MSG_RESULT($VERSION_PATCH)
6668 else
6669         AC_MSG_ERROR(did not find $srcdir/VERSION)
6670 fi
6671
6672 # show the actual data that we have for versions:
6673 CF_VERBOSE(ABI VERSION $VERSION)
6674 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
6675 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
6676 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
6677
6678 AC_SUBST(VERSION)
6679 AC_SUBST(VERSION_MAJOR)
6680 AC_SUBST(VERSION_MINOR)
6681 AC_SUBST(VERSION_PATCH)
6682
6683 dnl if a package name is given, define its corresponding version info.  We
6684 dnl need the package name to ensure that the defined symbols are unique.
6685 ifelse($1,,,[
6686         cf_PACKAGE=$1
6687         PACKAGE=ifelse($2,,$1,$2)
6688         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
6689         AC_SUBST(PACKAGE)
6690         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
6691         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
6692         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
6693 ])
6694 ])dnl
6695 dnl ---------------------------------------------------------------------------
6696 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
6697 dnl -------------
6698 dnl Check if type wide-character type $1 is declared, and if so, which header
6699 dnl file is needed.  The second parameter is used to set a shell variable when
6700 dnl the type is not found.  The first parameter sets a shell variable for the
6701 dnl opposite sense.
6702 AC_DEFUN([CF_WCHAR_TYPE],
6703 [
6704 # This is needed on Tru64 5.0 to declare $1
6705 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6706 AC_TRY_COMPILE([
6707 #include <stdlib.h>
6708 #include <stdarg.h>
6709 #include <stdio.h>
6710 #ifdef HAVE_LIBUTF8_H
6711 #include <libutf8.h>
6712 #endif],
6713         [$1 state],
6714         [cf_cv_$1=no],
6715         [AC_TRY_COMPILE([
6716 #include <stdlib.h>
6717 #include <stdarg.h>
6718 #include <stdio.h>
6719 #include <wchar.h>
6720 #ifdef HAVE_LIBUTF8_H
6721 #include <libutf8.h>
6722 #endif],
6723         [$1 value],
6724         [cf_cv_$1=yes],
6725         [cf_cv_$1=unknown])])])
6726
6727 if test "$cf_cv_$1" = yes ; then
6728         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
6729         NEED_WCHAR_H=1
6730 fi
6731
6732 ifelse([$2],,,[
6733 # if we do not find $1 in either place, use substitution to provide a fallback.
6734 if test "$cf_cv_$1" = unknown ; then
6735         $2=1
6736 fi
6737 ])
6738 ifelse($3,,,[
6739 # if we find $1 in either place, use substitution to provide a fallback.
6740 if test "$cf_cv_$1" != unknown ; then
6741         $3=1
6742 fi
6743 ])
6744 ])dnl
6745 dnl ---------------------------------------------------------------------------
6746 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
6747 dnl ---------------
6748 dnl Check for compiler-support for weak symbols.
6749 dnl This works with "recent" gcc.
6750 AC_DEFUN([CF_WEAK_SYMBOLS],[
6751 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
6752
6753 AC_TRY_COMPILE([
6754 #include <stdio.h>],
6755 [
6756 #if defined(__GNUC__)
6757 #  if defined __USE_ISOC99
6758 #    define _cat_pragma(exp)    _Pragma(#exp)
6759 #    define _weak_pragma(exp)   _cat_pragma(weak name)
6760 #  else
6761 #    define _weak_pragma(exp)
6762 #  endif
6763 #  define _declare(name)        __extension__ extern __typeof__(name) name
6764 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
6765 #endif
6766
6767 weak_symbol(fopen);
6768 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
6769 ])
6770 ])dnl
6771 dnl ---------------------------------------------------------------------------
6772 dnl CF_WITH_ABI_VERSION version: 1 updated: 2003/09/20 18:12:49
6773 dnl -------------------
6774 dnl Allow library's ABI to be overridden.  Generally this happens when a
6775 dnl packager has incremented the ABI past that used in the original package,
6776 dnl and wishes to keep doing this.
6777 dnl
6778 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6779 dnl symbol.
6780 AC_DEFUN([CF_WITH_ABI_VERSION],[
6781 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
6782 AC_ARG_WITH(abi-version,
6783 [  --with-abi-version=XXX  override derived ABI version],
6784 [AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
6785  cf_cv_abi_version=$withval])
6786  CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
6787 ifelse($1,,,[
6788 $1_ABI=$cf_cv_abi_version
6789 ])
6790 ])dnl
6791 dnl ---------------------------------------------------------------------------
6792 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
6793 dnl --------------------
6794 dnl Command-line option to specify the Ada95 compiler.
6795 AC_DEFUN([CF_WITH_ADA_COMPILER],[
6796 AC_MSG_CHECKING(for ada-compiler)
6797 AC_ARG_WITH(ada-compiler,
6798         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
6799         [cf_ada_compiler=$withval],
6800         [cf_ada_compiler=gnatmake])
6801 AC_SUBST(cf_ada_compiler)
6802 AC_MSG_RESULT($cf_ada_compiler)
6803 ])dnl
6804 dnl ---------------------------------------------------------------------------
6805 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
6806 dnl -------------------
6807 dnl Command-line option to specify where Ada includes will install.
6808 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
6809 AC_MSG_CHECKING(for ada-include)
6810 CF_WITH_PATH(ada-include,
6811    [  --with-ada-include=DIR  Ada includes are in DIR],
6812    ADA_INCLUDE,
6813    PREFIX/share/ada/adainclude,
6814    [$]prefix/share/ada/adainclude)
6815 AC_SUBST(ADA_INCLUDE)
6816 AC_MSG_RESULT($ADA_INCLUDE)
6817 ])dnl
6818 dnl ---------------------------------------------------------------------------
6819 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
6820 dnl -------------------
6821 dnl Command-line option to specify where Ada objects will install.
6822 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
6823 AC_MSG_CHECKING(for ada-objects)
6824 CF_WITH_PATH(ada-objects,
6825    [  --with-ada-objects=DIR  Ada objects are in DIR],
6826    ADA_OBJECTS,
6827    PREFIX/lib/ada/adalib,
6828    [$]prefix/lib/ada/adalib)
6829 AC_SUBST(ADA_OBJECTS)
6830 AC_MSG_RESULT($ADA_OBJECTS)
6831 ])dnl
6832 dnl ---------------------------------------------------------------------------
6833 dnl CF_WITH_ADA_SHAREDLIB version: 4 updated: 2014/05/31 21:08:37
6834 dnl ---------------------
6835 dnl Command-line option to specify if an Ada95 shared-library should be built,
6836 dnl and optionally what its soname should be.
6837 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
6838 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
6839 AC_ARG_WITH(ada-sharedlib,
6840         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
6841         [with_ada_sharedlib=$withval],
6842         [with_ada_sharedlib=no])
6843 AC_MSG_RESULT($with_ada_sharedlib)
6844
6845 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
6846 MAKE_ADA_SHAREDLIB="#"
6847
6848 if test "x$with_ada_sharedlib" != xno
6849 then
6850         MAKE_ADA_SHAREDLIB=
6851         if test "x$with_ada_sharedlib" != xyes
6852         then
6853                 ADA_SHAREDLIB="$with_ada_sharedlib"
6854         fi
6855 fi
6856
6857 AC_SUBST(ADA_SHAREDLIB)
6858 AC_SUBST(MAKE_ADA_SHAREDLIB)
6859 ])dnl
6860 dnl ---------------------------------------------------------------------------
6861 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
6862 dnl ----------------
6863 dnl Configure-option for dbmalloc.  The optional parameter is used to override
6864 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6865 AC_DEFUN([CF_WITH_DBMALLOC],[
6866 CF_NO_LEAKS_OPTION(dbmalloc,
6867         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
6868         [USE_DBMALLOC])
6869
6870 if test "$with_dbmalloc" = yes ; then
6871         AC_CHECK_HEADER(dbmalloc.h,
6872                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
6873 fi
6874 ])dnl
6875 dnl ---------------------------------------------------------------------------
6876 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
6877 dnl ---------------
6878 dnl Configure-option for dmalloc.  The optional parameter is used to override
6879 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6880 AC_DEFUN([CF_WITH_DMALLOC],[
6881 CF_NO_LEAKS_OPTION(dmalloc,
6882         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
6883         [USE_DMALLOC])
6884
6885 if test "$with_dmalloc" = yes ; then
6886         AC_CHECK_HEADER(dmalloc.h,
6887                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
6888 fi
6889 ])dnl
6890 dnl ---------------------------------------------------------------------------
6891 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
6892 dnl -------------------
6893 dnl Use this with libtool to specify the list of symbols that may be exported.
6894 dnl The input file contains one symbol per line; comments work with "#".
6895 dnl
6896 dnl $1 = basename of the ".sym" file (default $PACKAGE)
6897 AC_DEFUN([CF_WITH_EXPORT_SYMS],
6898 [
6899 AC_MSG_CHECKING(if exported-symbols file should be used)
6900 AC_ARG_WITH(export-syms,
6901         [  --with-export-syms=XXX  limit exported symbols using libtool],
6902         [with_export_syms=$withval],
6903         [with_export_syms=no])
6904 if test "x$with_export_syms" = xyes
6905 then
6906         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
6907         AC_SUBST(PACKAGE)
6908 fi
6909 AC_MSG_RESULT($with_export_syms)
6910 if test "x$with_export_syms" != xno
6911 then
6912         EXPORT_SYMS="-export-symbols $with_export_syms"
6913         AC_SUBST(EXPORT_SYMS)
6914 fi
6915 ])dnl
6916 dnl ---------------------------------------------------------------------------
6917 dnl CF_WITH_GPM version: 8 updated: 2012/10/06 17:56:13
6918 dnl -----------
6919 dnl
6920 dnl The option parameter (if neither yes/no) is assumed to be the name of
6921 dnl the gpm library, e.g., for dynamic loading.
6922 AC_DEFUN([CF_WITH_GPM],
6923 [
6924 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
6925 AC_ARG_WITH(gpm,
6926         [  --with-gpm              use Alessandro Rubini's GPM library],
6927         [with_gpm=$withval],
6928         [with_gpm=maybe])
6929 AC_MSG_RESULT($with_gpm)
6930
6931 if test "$with_gpm" != no ; then
6932         AC_CHECK_HEADER(gpm.h,[
6933                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
6934                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
6935                         CF_VERBOSE(assuming we really have GPM library)
6936                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
6937                 else
6938                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
6939                                 AC_MSG_ERROR(Cannot link with GPM library)
6940                 fi
6941                 with_gpm=yes
6942                 ])
6943         ],[
6944                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
6945                 with_gpm=no
6946         ])
6947 fi
6948 ])
6949 dnl ---------------------------------------------------------------------------
6950 dnl CF_WITH_LIBTOOL version: 32 updated: 2015/04/17 21:13:04
6951 dnl ---------------
6952 dnl Provide a configure option to incorporate libtool.  Define several useful
6953 dnl symbols for the makefile rules.
6954 dnl
6955 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
6956 dnl macros from libtool.m4 which is in the aclocal directory of automake.
6957 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
6958 dnl But that still does not work properly since the macro is expanded outside
6959 dnl the CF_WITH_LIBTOOL macro:
6960 dnl
6961 dnl     #!/bin/sh
6962 dnl     ACLOCAL=`aclocal --print-ac-dir`
6963 dnl     if test -z "$ACLOCAL" ; then
6964 dnl             echo cannot find aclocal directory
6965 dnl             exit 1
6966 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
6967 dnl             echo cannot find libtool.m4 file
6968 dnl             exit 1
6969 dnl     fi
6970 dnl
6971 dnl     LOCAL=aclocal.m4
6972 dnl     ORIG=aclocal.m4.orig
6973 dnl
6974 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
6975 dnl     rm -f $ORIG
6976 dnl     mv $LOCAL $ORIG
6977 dnl
6978 dnl     # sed the LIBTOOL= assignment to omit the current directory?
6979 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
6980 dnl     cat $ORIG >>$LOCAL
6981 dnl
6982 dnl     autoconf-257 $*
6983 dnl
6984 AC_DEFUN([CF_WITH_LIBTOOL],
6985 [
6986 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
6987 ifdef([AC_PROG_LIBTOOL],,[
6988 LIBTOOL=
6989 ])
6990 # common library maintenance symbols that are convenient for libtool scripts:
6991 LIB_CREATE='${AR} -cr'
6992 LIB_OBJECT='${OBJECTS}'
6993 LIB_SUFFIX=.a
6994 LIB_PREP="$RANLIB"
6995
6996 # symbols used to prop libtool up to enable it to determine what it should be
6997 # doing:
6998 LIB_CLEAN=
6999 LIB_COMPILE=
7000 LIB_LINK='${CC}'
7001 LIB_INSTALL=
7002 LIB_UNINSTALL=
7003
7004 AC_MSG_CHECKING(if you want to build libraries with libtool)
7005 AC_ARG_WITH(libtool,
7006         [  --with-libtool          generate libraries with libtool],
7007         [with_libtool=$withval],
7008         [with_libtool=no])
7009 AC_MSG_RESULT($with_libtool)
7010 if test "$with_libtool" != "no"; then
7011 ifdef([AC_PROG_LIBTOOL],[
7012         # missing_content_AC_PROG_LIBTOOL{{
7013         AC_PROG_LIBTOOL
7014         # missing_content_AC_PROG_LIBTOOL}}
7015 ],[
7016         if test "$with_libtool" != "yes" ; then
7017                 CF_PATH_SYNTAX(with_libtool)
7018                 LIBTOOL=$with_libtool
7019         else
7020                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
7021                 CF_LIBTOOL_VERSION
7022                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
7023                 then
7024                         CF_FORGET_TOOL(LIBTOOL)
7025                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
7026                         CF_LIBTOOL_VERSION
7027                 fi
7028         fi
7029         if test -z "$LIBTOOL" ; then
7030                 AC_MSG_ERROR(Cannot find libtool)
7031         fi
7032 ])dnl
7033         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${DESTDIR}${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
7034         LIB_OBJECT='${OBJECTS:.o=.lo}'
7035         LIB_SUFFIX=.la
7036         LIB_CLEAN='${LIBTOOL} --mode=clean'
7037         LIB_COMPILE='${LIBTOOL} --mode=compile'
7038         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
7039         LIB_INSTALL='${LIBTOOL} --mode=install'
7040         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
7041         LIB_PREP=:
7042
7043         CF_CHECK_LIBTOOL_VERSION
7044
7045         # special hack to add -no-undefined (which libtool should do for itself)
7046         LT_UNDEF=
7047         case "$cf_cv_system_name" in
7048         (cygwin*|msys*|mingw32*|uwin*|aix[[4-7]])
7049                 LT_UNDEF=-no-undefined
7050                 ;;
7051         esac
7052         AC_SUBST([LT_UNDEF])
7053
7054         # special hack to add --tag option for C++ compiler
7055         case $cf_cv_libtool_version in
7056         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
7057                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
7058                 LIBTOOL="$LIBTOOL --tag=CC"
7059                 ;;
7060         (*)
7061                 LIBTOOL_CXX="$LIBTOOL"
7062                 ;;
7063         esac
7064 else
7065         LIBTOOL=""
7066         LIBTOOL_CXX=""
7067 fi
7068
7069 test -z "$LIBTOOL" && ECHO_LT=
7070
7071 AC_SUBST(LIBTOOL)
7072 AC_SUBST(LIBTOOL_CXX)
7073 AC_SUBST(LIBTOOL_OPTS)
7074
7075 AC_SUBST(LIB_CREATE)
7076 AC_SUBST(LIB_OBJECT)
7077 AC_SUBST(LIB_SUFFIX)
7078 AC_SUBST(LIB_PREP)
7079
7080 AC_SUBST(LIB_CLEAN)
7081 AC_SUBST(LIB_COMPILE)
7082 AC_SUBST(LIB_LINK)
7083 AC_SUBST(LIB_INSTALL)
7084 AC_SUBST(LIB_UNINSTALL)
7085
7086 ])dnl
7087 dnl ---------------------------------------------------------------------------
7088 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
7089 dnl --------------------
7090 dnl Allow user to pass additional libtool options into the library creation
7091 dnl and link steps.  The main use for this is to do something like
7092 dnl     ./configure --with-libtool-opts=-static
7093 dnl to get the same behavior as automake-flavored
7094 dnl     ./configure --enable-static
7095 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
7096 AC_MSG_CHECKING(for additional libtool options)
7097 AC_ARG_WITH(libtool-opts,
7098         [  --with-libtool-opts=XXX specify additional libtool options],
7099         [with_libtool_opts=$withval],
7100         [with_libtool_opts=no])
7101 AC_MSG_RESULT($with_libtool_opts)
7102
7103 case .$with_libtool_opts in
7104 (.yes|.no|.)
7105         ;;
7106 (*)
7107         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
7108         ;;
7109 esac
7110
7111 AC_SUBST(LIBTOOL_OPTS)
7112 ])dnl
7113 dnl ---------------------------------------------------------------------------
7114 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
7115 dnl ------------------
7116 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
7117 dnl "lib" prefix, e.g., because it used the dll naming convention.
7118 dnl
7119 dnl $1 = variable to set
7120 AC_DEFUN([CF_WITH_LIB_PREFIX],
7121 [
7122 AC_MSG_CHECKING(if you want to have a library-prefix)
7123 AC_ARG_WITH(lib-prefix,
7124         [  --with-lib-prefix       override library-prefix],
7125         [with_lib_prefix=$withval],
7126         [with_lib_prefix=auto])
7127 AC_MSG_RESULT($with_lib_prefix)
7128
7129 if test $with_lib_prefix = auto
7130 then
7131         CF_LIB_PREFIX($1)
7132 elif test $with_lib_prefix = no
7133 then
7134         LIB_PREFIX=
7135 else
7136         LIB_PREFIX=$with_lib_prefix
7137 fi
7138 ])dnl
7139 dnl ---------------------------------------------------------------------------
7140 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
7141 dnl ------------
7142 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
7143 dnl defaulting to yes/no.
7144 dnl
7145 dnl $1 = option name
7146 dnl $2 = help-text
7147 dnl $3 = environment variable to set
7148 dnl $4 = default value, shown in the help-message, must be a constant
7149 dnl $5 = default value, if it's an expression & cannot be in the help-message
7150 dnl
7151 AC_DEFUN([CF_WITH_PATH],
7152 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
7153 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
7154 if ifelse([$5],,true,[test -n "$5"]) ; then
7155 CF_PATH_SYNTAX(withval)
7156 fi
7157 eval $3="$withval"
7158 AC_SUBST($3)dnl
7159 ])dnl
7160 dnl ---------------------------------------------------------------------------
7161 dnl CF_WITH_PATHLIST version: 10 updated: 2015/04/17 21:13:04
7162 dnl ----------------
7163 dnl Process an option specifying a list of colon-separated paths.
7164 dnl
7165 dnl $1 = option name
7166 dnl $2 = help-text
7167 dnl $3 = environment variable to set
7168 dnl $4 = default value, shown in the help-message, must be a constant
7169 dnl $5 = default value, if it's an expression & cannot be in the help-message
7170 dnl $6 = flag to tell if we want to define or substitute
7171 dnl
7172 AC_DEFUN([CF_WITH_PATHLIST],[
7173 AC_REQUIRE([CF_PATHSEP])
7174 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
7175 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
7176
7177 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
7178 cf_dst_path=
7179 for cf_src_path in $withval
7180 do
7181   CF_PATH_SYNTAX(cf_src_path)
7182   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
7183   cf_dst_path="${cf_dst_path}${cf_src_path}"
7184 done
7185 IFS="$ac_save_ifs"
7186
7187 ifelse($6,define,[
7188 # Strip single quotes from the value, e.g., when it was supplied as a literal
7189 # for $4 or $5.
7190 case $cf_dst_path in
7191 (\'*)
7192   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
7193   ;;
7194 esac
7195 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
7196 ])
7197
7198 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
7199 # so we have to check/work around.  We do prefer the result of "eval"...
7200 eval cf_dst_eval="$cf_dst_path"
7201 case "x$cf_dst_eval" in
7202 (xNONE*)
7203         $3=$cf_dst_path
7204         ;;
7205 (*)
7206         $3="$cf_dst_eval"
7207         ;;
7208 esac
7209 AC_SUBST($3)dnl
7210
7211 ])dnl
7212 dnl ---------------------------------------------------------------------------
7213 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 6 updated: 2015/04/17 21:13:04
7214 dnl -------------------------
7215 dnl Allow the choice of the pkg-config library directory to be overridden.
7216 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
7217 AC_MSG_CHECKING(for $PKG_CONFIG library directory)
7218 AC_ARG_WITH(pkg-config-libdir,
7219         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
7220         [PKG_CONFIG_LIBDIR=$withval],
7221         [PKG_CONFIG_LIBDIR=yes])
7222
7223 case x$PKG_CONFIG_LIBDIR in
7224 (x/*)
7225         ;;
7226 (xyes)
7227         # Look for the library directory using the same prefix as the executable
7228         if test "x$PKG_CONFIG" = xnone
7229         then
7230                 cf_path=$prefix
7231         else
7232                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
7233         fi
7234
7235         # If you don't like using the default architecture, you have to specify the
7236         # intended library directory and corresponding compiler/linker options.
7237         #
7238         # This case allows for Debian's 2014-flavor of multiarch, along with the
7239         # most common variations before that point.  Some other variants spell the
7240         # directory differently, e.g., "pkg-config", and put it in unusual places.
7241         # pkg-config has always been poorly standardized, which is ironic...
7242         case x`(arch) 2>/dev/null` in
7243         (*64)
7244                 cf_search_path="\
7245                         $cf_path/lib/*64-linux-gnu \
7246                         $cf_path/share \
7247                         $cf_path/lib64 \
7248                         $cf_path/lib32 \
7249                         $cf_path/lib"
7250                 ;;
7251         (*)
7252                 cf_search_path="\
7253                         $cf_path/lib/*-linux-gnu \
7254                         $cf_path/share \
7255                         $cf_path/lib32 \
7256                         $cf_path/lib \
7257                         $cf_path/libdata"
7258                 ;;
7259         esac
7260
7261         CF_VERBOSE(list...)
7262         for cf_config in $cf_search_path
7263         do
7264                 CF_VERBOSE(checking $cf_config/pkgconfig)
7265                 if test -d $cf_config/pkgconfig
7266                 then
7267                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
7268                         AC_MSG_CHECKING(done)
7269                         break
7270                 fi
7271         done
7272         ;;
7273 (*)
7274         ;;
7275 esac
7276
7277 AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
7278
7279 AC_SUBST(PKG_CONFIG_LIBDIR)
7280 ])dnl
7281 dnl ---------------------------------------------------------------------------
7282 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
7283 dnl ---------------
7284 dnl Check for POSIX thread library.
7285 AC_DEFUN([CF_WITH_PTHREAD],
7286 [
7287 AC_MSG_CHECKING(if you want to link with the pthread library)
7288 AC_ARG_WITH(pthread,
7289         [  --with-pthread          use POSIX thread library],
7290         [with_pthread=$withval],
7291         [with_pthread=no])
7292 AC_MSG_RESULT($with_pthread)
7293
7294 if test "$with_pthread" != no ; then
7295         AC_CHECK_HEADER(pthread.h,[
7296         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
7297
7298         for cf_lib_pthread in pthread c_r
7299         do
7300             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
7301             cf_save_LIBS="$LIBS"
7302             CF_ADD_LIB($cf_lib_pthread)
7303             AC_TRY_LINK([
7304 #include <pthread.h>
7305 ],[
7306                 int rc = pthread_create(0,0,0,0);
7307                 int r2 = pthread_mutexattr_settype(0, 0);
7308 ],[with_pthread=yes],[with_pthread=no])
7309             LIBS="$cf_save_LIBS"
7310             AC_MSG_RESULT($with_pthread)
7311             test "$with_pthread" = yes && break
7312         done
7313
7314         if test "$with_pthread" = yes ; then
7315             CF_ADD_LIB($cf_lib_pthread)
7316             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
7317         else
7318             AC_MSG_ERROR(Cannot link with pthread library)
7319         fi
7320         ])
7321 fi
7322 ])
7323 dnl ---------------------------------------------------------------------------
7324 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
7325 dnl -------------------
7326 dnl Allow library's release-version to be overridden.  Generally this happens when a
7327 dnl packager has incremented the release-version past that used in the original package,
7328 dnl and wishes to keep doing this.
7329 dnl
7330 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
7331 dnl and {package}_MINOR symbols
7332 dnl symbol.
7333 AC_DEFUN([CF_WITH_REL_VERSION],[
7334 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
7335 AC_ARG_WITH(rel-version,
7336 [  --with-rel-version=XXX  override derived release version],
7337 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
7338  cf_cv_rel_version=$withval])
7339 ifelse($1,,[
7340  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
7341 ],[
7342  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
7343  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
7344  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
7345  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
7346 ])
7347 ])dnl
7348 dnl ---------------------------------------------------------------------------
7349 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
7350 dnl ----------------
7351 dnl If we can compile with sysmouse, make it available unless it is not wanted.
7352 AC_DEFUN([CF_WITH_SYSMOUSE],[
7353 # not everyone has "test -c"
7354 if test -c /dev/sysmouse 2>/dev/null ; then
7355 AC_MSG_CHECKING(if you want to use sysmouse)
7356 AC_ARG_WITH(sysmouse,
7357         [  --with-sysmouse         use sysmouse (FreeBSD console)],
7358         [cf_with_sysmouse=$withval],
7359         [cf_with_sysmouse=maybe])
7360         if test "$cf_with_sysmouse" != no ; then
7361         AC_TRY_COMPILE([
7362 #include <osreldate.h>
7363 #if (__FreeBSD_version >= 400017)
7364 #include <sys/consio.h>
7365 #include <sys/fbio.h>
7366 #else
7367 #include <machine/console.h>
7368 #endif
7369 ],[
7370         struct mouse_info the_mouse;
7371         ioctl(0, CONS_MOUSECTL, &the_mouse);
7372 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
7373         fi
7374 AC_MSG_RESULT($cf_with_sysmouse)
7375 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
7376 fi
7377 ])dnl
7378 dnl ---------------------------------------------------------------------------
7379 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
7380 dnl ---------------
7381 dnl For testing, override the derived host system-type which is used to decide
7382 dnl things such as the linker commands used to build shared libraries.  This is
7383 dnl normally chosen automatically based on the type of system which you are
7384 dnl building on.  We use it for testing the configure script.
7385 dnl
7386 dnl This is different from the --host option: it is used only for testing parts
7387 dnl of the configure script which would not be reachable with --host since that
7388 dnl relies on the build environment being real, rather than mocked up.
7389 AC_DEFUN([CF_WITH_SYSTYPE],[
7390 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
7391 AC_ARG_WITH(system-type,
7392         [  --with-system-type=XXX  test: override derived host system-type],
7393 [AC_MSG_WARN(overriding system type to $withval)
7394         cf_cv_system_name=$withval
7395         host_os=$withval
7396 ])
7397 ])dnl
7398 dnl ---------------------------------------------------------------------------
7399 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
7400 dnl ----------------
7401 AC_DEFUN([CF_WITH_VALGRIND],[
7402 CF_NO_LEAKS_OPTION(valgrind,
7403         [  --with-valgrind         test: use valgrind],
7404         [USE_VALGRIND])
7405 ])dnl
7406 dnl ---------------------------------------------------------------------------
7407 dnl CF_WITH_VERSIONED_SYMS version: 5 updated: 2015/04/17 21:13:04
7408 dnl ----------------------
7409 dnl Use this when building shared library with ELF, to markup symbols with the
7410 dnl version identifier from the given input file.  Generally that identifier is
7411 dnl the same as the SONAME at which the symbol was first introduced.
7412 dnl
7413 dnl $1 = basename of the ".map" file (default $PACKAGE)
7414 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
7415 [
7416 AC_MSG_CHECKING(if versioned-symbols file should be used)
7417 AC_ARG_WITH(versioned-syms,
7418         [  --with-versioned-syms=X markup versioned symbols using ld],
7419         [with_versioned_syms=$withval],
7420         [with_versioned_syms=no])
7421 if test "x$with_versioned_syms" = xyes
7422 then
7423         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
7424         AC_SUBST(PACKAGE)
7425 fi
7426 AC_MSG_RESULT($with_versioned_syms)
7427
7428 RESULTING_SYMS=
7429 VERSIONED_SYMS=
7430 WILDCARD_SYMS=
7431
7432 if test "x$with_versioned_syms" != xno
7433 then
7434         RESULTING_SYMS=$with_versioned_syms
7435         case "x$MK_SHARED_LIB" in
7436         (*-Wl,*)
7437                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
7438                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
7439                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7440                 ;;
7441         (*-dy\ *)
7442                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
7443                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
7444                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7445                 ;;
7446         (*)
7447                 AC_MSG_WARN(this system does not support versioned-symbols)
7448                 ;;
7449         esac
7450
7451         # Linux ld can selectively override scope, e.g., of symbols beginning with
7452         # "_" by first declaring some as global, and then using a wildcard to
7453         # declare the others as local.  Some other loaders cannot do this.  Check
7454         # by constructing a (very) simple shared library and inspecting its
7455         # symbols.
7456         if test "x$VERSIONED_SYMS" != "x"
7457         then
7458                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
7459                 WILDCARD_SYMS=no
7460
7461                 # make sources
7462                 rm -f conftest.*
7463
7464                 cat >conftest.ver <<EOF
7465 module_1.0 {
7466 global:
7467         globalf1;
7468 local:
7469         localf1;
7470 };
7471 module_2.0 {
7472 global:
7473         globalf2;
7474 local:
7475         localf2;
7476         _*;
7477 } module_1.0;
7478 submodule_1.0 {
7479 global:
7480         subglobalf1;
7481         _ismissing;
7482 local:
7483         sublocalf1;
7484 };
7485 submodule_2.0 {
7486 global:
7487         subglobalf2;
7488 local:
7489         sublocalf2;
7490         _*;
7491 } submodule_1.0;
7492 EOF
7493                 cat >conftest.$ac_ext <<EOF
7494 #line __oline__ "configure"
7495 int     _ismissing(void) { return 1; }
7496 int     _localf1(void) { return 1; }
7497 int     _localf2(void) { return 2; }
7498 int     globalf1(void) { return 1; }
7499 int     globalf2(void) { return 2; }
7500 int     _sublocalf1(void) { return 1; }
7501 int     _sublocalf2(void) { return 2; }
7502 int     subglobalf1(void) { return 1; }
7503 int     subglobalf2(void) { return 2; }
7504 EOF
7505                 cat >conftest.mk <<EOF
7506 CC=${CC}
7507 CFLAGS=${CFLAGS}
7508 CPPFLAGS=${CPPFLAGS}
7509 LDFLAGS=${LDFLAGS}
7510 LIBS=${LIBS}
7511 VERSIONED_SYMS=${VERSIONED_SYMS}
7512 RESULTING_SYMS=conftest.ver
7513 MK_SHARED_LIB=${MK_SHARED_LIB}
7514 conftest.so: conftest.$ac_cv_objext
7515                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
7516 EOF
7517
7518                 # compile source, make library
7519                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
7520                 then
7521                         # test for missing symbol
7522                         cf_missing=`nm -P conftest.so 2>&AC_FD_CC |fgrep _ismissing | egrep '[[         ]]T[[   ]]'`
7523                         test -n "$cf_missing" && WILDCARD_SYMS=yes
7524                 fi
7525                 AC_MSG_RESULT($WILDCARD_SYMS)
7526                 rm -f conftest.*
7527         fi
7528 fi
7529 AC_SUBST(RESULTING_SYMS)
7530 AC_SUBST(VERSIONED_SYMS)
7531 AC_SUBST(WILDCARD_SYMS)
7532 ])dnl
7533 dnl ---------------------------------------------------------------------------
7534 dnl CF_XOPEN_SOURCE version: 49 updated: 2015/04/12 15:39:00
7535 dnl ---------------
7536 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
7537 dnl or adapt to the vendor's definitions to get equivalent functionality,
7538 dnl without losing the common non-POSIX features.
7539 dnl
7540 dnl Parameters:
7541 dnl     $1 is the nominal value for _XOPEN_SOURCE
7542 dnl     $2 is the nominal value for _POSIX_C_SOURCE
7543 AC_DEFUN([CF_XOPEN_SOURCE],[
7544 AC_REQUIRE([AC_CANONICAL_HOST])
7545
7546 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
7547 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
7548 cf_xopen_source=
7549
7550 case $host_os in
7551 (aix[[4-7]]*)
7552         cf_xopen_source="-D_ALL_SOURCE"
7553         ;;
7554 (cygwin|msys)
7555         cf_XOPEN_SOURCE=600
7556         ;;
7557 (darwin[[0-8]].*)
7558         cf_xopen_source="-D_APPLE_C_SOURCE"
7559         ;;
7560 (darwin*)
7561         cf_xopen_source="-D_DARWIN_C_SOURCE"
7562         cf_XOPEN_SOURCE=
7563         ;;
7564 (freebsd*|dragonfly*)
7565         # 5.x headers associate
7566         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
7567         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
7568         cf_POSIX_C_SOURCE=200112L
7569         cf_XOPEN_SOURCE=600
7570         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
7571         ;;
7572 (hpux11*)
7573         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
7574         ;;
7575 (hpux*)
7576         cf_xopen_source="-D_HPUX_SOURCE"
7577         ;;
7578 (irix[[56]].*)
7579         cf_xopen_source="-D_SGI_SOURCE"
7580         cf_XOPEN_SOURCE=
7581         ;;
7582 (linux*|gnu*|mint*|k*bsd*-gnu)
7583         CF_GNU_SOURCE
7584         ;;
7585 (minix*)
7586         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
7587         ;;
7588 (mirbsd*)
7589         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
7590         cf_XOPEN_SOURCE=
7591         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7592         ;;
7593 (netbsd*)
7594         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
7595         ;;
7596 (openbsd[[4-9]]*)
7597         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
7598         cf_xopen_source="-D_BSD_SOURCE"
7599         cf_XOPEN_SOURCE=600
7600         ;;
7601 (openbsd*)
7602         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
7603         ;;
7604 (osf[[45]]*)
7605         cf_xopen_source="-D_OSF_SOURCE"
7606         ;;
7607 (nto-qnx*)
7608         cf_xopen_source="-D_QNX_SOURCE"
7609         ;;
7610 (sco*)
7611         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
7612         ;;
7613 (solaris2.*)
7614         cf_xopen_source="-D__EXTENSIONS__"
7615         cf_cv_xopen_source=broken
7616         ;;
7617 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
7618         cf_XOPEN_SOURCE=
7619         cf_POSIX_C_SOURCE=
7620         ;;
7621 (*)
7622         CF_TRY_XOPEN_SOURCE
7623         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7624         ;;
7625 esac
7626
7627 if test -n "$cf_xopen_source" ; then
7628         CF_ADD_CFLAGS($cf_xopen_source,true)
7629 fi
7630
7631 dnl In anything but the default case, we may have system-specific setting
7632 dnl which is still not guaranteed to provide all of the entrypoints that
7633 dnl _XOPEN_SOURCE would yield.
7634 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
7635         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
7636         AC_TRY_COMPILE([#include <stdlib.h>],[
7637 #ifndef _XOPEN_SOURCE
7638 make an error
7639 #endif],
7640         [cf_XOPEN_SOURCE_set=yes],
7641         [cf_XOPEN_SOURCE_set=no])
7642         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
7643         if test $cf_XOPEN_SOURCE_set = yes
7644         then
7645                 AC_TRY_COMPILE([#include <stdlib.h>],[
7646 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
7647 make an error
7648 #endif],
7649                 [cf_XOPEN_SOURCE_set_ok=yes],
7650                 [cf_XOPEN_SOURCE_set_ok=no])
7651                 if test $cf_XOPEN_SOURCE_set_ok = no
7652                 then
7653                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
7654                 fi
7655         else
7656                 CF_TRY_XOPEN_SOURCE
7657         fi
7658 fi
7659 ])