aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2009,2010 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.546 2010/10/23 20:14:30 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54     [AC_TRY_LINK([#include <langinfo.h>],
  55       [char* cs = nl_langinfo(CODESET);],
  56       am_cv_langinfo_codeset=yes,
  57       am_cv_langinfo_codeset=no)
  58     ])
  59   if test $am_cv_langinfo_codeset = yes; then
  60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62   fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
  66 dnl -------------------
  67 dnl Construct the list of include-options for the C programs in the Ada95
  68 dnl binding.
  69 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  70 [
  71 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  72 if test "$srcdir" != "."; then
  73         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  74 fi
  75 if test "$GCC" != yes; then
  76         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  77 elif test "$includedir" != "/usr/include"; then
  78         if test "$includedir" = '${prefix}/include' ; then
  79                 if test $prefix != /usr ; then
  80                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  81                 fi
  82         else
  83                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  84         fi
  85 fi
  86 AC_SUBST(ACPPFLAGS)
  87 ])dnl
  88 dnl ---------------------------------------------------------------------------
  89 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
  90 dnl ---------------
  91 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
  92 AC_DEFUN([CF_ADD_ADAFLAGS],[
  93         ADAFLAGS="$ADAFLAGS $1"
  94         AC_SUBST(ADAFLAGS)
  95 ])dnl
  96 dnl ---------------------------------------------------------------------------
  97 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
  98 dnl -------------
  99 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 100 dnl The second parameter if given makes this macro verbose.
 101 dnl
 102 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 103 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 104 dnl confused by the quotes (which require backslashes to keep them usable).
 105 AC_DEFUN([CF_ADD_CFLAGS],
 106 [
 107 cf_fix_cppflags=no
 108 cf_new_cflags=
 109 cf_new_cppflags=
 110 cf_new_extra_cppflags=
 111
 112 for cf_add_cflags in $1
 113 do
 114 case $cf_fix_cppflags in
 115 no)
 116         case $cf_add_cflags in #(vi
 117         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 118                 case $cf_add_cflags in
 119                 -D*)
 120                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 121
 122                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 123                                 && test -z "${cf_tst_cflags}" \
 124                                 && cf_fix_cppflags=yes
 125
 126                         if test $cf_fix_cppflags = yes ; then
 127                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 128                                 continue
 129                         elif test "${cf_tst_cflags}" = "\"'" ; then
 130                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 131                                 continue
 132                         fi
 133                         ;;
 134                 esac
 135                 case "$CPPFLAGS" in
 136                 *$cf_add_cflags) #(vi
 137                         ;;
 138                 *) #(vi
 139                         case $cf_add_cflags in #(vi
 140                         -D*)
 141                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 142                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 143                                 ;;
 144                         esac
 145                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 146                         ;;
 147                 esac
 148                 ;;
 149         *)
 150                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 151                 ;;
 152         esac
 153         ;;
 154 yes)
 155         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 156
 157         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 158
 159         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 160                 && test -z "${cf_tst_cflags}" \
 161                 && cf_fix_cppflags=no
 162         ;;
 163 esac
 164 done
 165
 166 if test -n "$cf_new_cflags" ; then
 167         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 168         CFLAGS="$CFLAGS $cf_new_cflags"
 169 fi
 170
 171 if test -n "$cf_new_cppflags" ; then
 172         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 173         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 174 fi
 175
 176 if test -n "$cf_new_extra_cppflags" ; then
 177         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 178         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 179 fi
 180
 181 AC_SUBST(EXTRA_CPPFLAGS)
 182
 183 ])dnl
 184 dnl ---------------------------------------------------------------------------
 185 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 186 dnl -------------
 187 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 188 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 189 dnl but old versions (and some misinstalled ones) need that.  To make things
 190 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 191 dnl the include-path).
 192 AC_DEFUN([CF_ADD_INCDIR],
 193 [
 194 if test -n "$1" ; then
 195   for cf_add_incdir in $1
 196   do
 197         while test $cf_add_incdir != /usr/include
 198         do
 199           if test -d $cf_add_incdir
 200           then
 201                 cf_have_incdir=no
 202                 if test -n "$CFLAGS$CPPFLAGS" ; then
 203                   # a loop is needed to ensure we can add subdirs of existing dirs
 204                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 205                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 206                           cf_have_incdir=yes; break
 207                         fi
 208                   done
 209                 fi
 210
 211                 if test "$cf_have_incdir" = no ; then
 212                   if test "$cf_add_incdir" = /usr/local/include ; then
 213                         if test "$GCC" = yes
 214                         then
 215                           cf_save_CPPFLAGS=$CPPFLAGS
 216                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 217                           AC_TRY_COMPILE([#include <stdio.h>],
 218                                   [printf("Hello")],
 219                                   [],
 220                                   [cf_have_incdir=yes])
 221                           CPPFLAGS=$cf_save_CPPFLAGS
 222                         fi
 223                   fi
 224                 fi
 225
 226                 if test "$cf_have_incdir" = no ; then
 227                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 228                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 229
 230                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 231                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 232                   cf_add_incdir="$cf_top_incdir"
 233                 else
 234                   break
 235                 fi
 236           fi
 237         done
 238   done
 239 fi
 240 ])dnl
 241 dnl ---------------------------------------------------------------------------
 242 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 243 dnl ----------
 244 dnl Add a library, used to enforce consistency.
 245 dnl
 246 dnl $1 = library to add, without the "-l"
 247 dnl $2 = variable to update (default $LIBS)
 248 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 249 dnl ---------------------------------------------------------------------------
 250 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 251 dnl -------------
 252 dnl     Adds to the library-path
 253 dnl
 254 dnl     Some machines have trouble with multiple -L options.
 255 dnl
 256 dnl $1 is the (list of) directory(s) to add
 257 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 258 dnl
 259 AC_DEFUN([CF_ADD_LIBDIR],
 260 [
 261 if test -n "$1" ; then
 262   for cf_add_libdir in $1
 263   do
 264     if test $cf_add_libdir = /usr/lib ; then
 265       :
 266     elif test -d $cf_add_libdir
 267     then
 268       cf_have_libdir=no
 269       if test -n "$LDFLAGS$LIBS" ; then
 270         # a loop is needed to ensure we can add subdirs of existing dirs
 271         for cf_test_libdir in $LDFLAGS $LIBS ; do
 272           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 273             cf_have_libdir=yes; break
 274           fi
 275         done
 276       fi
 277       if test "$cf_have_libdir" = no ; then
 278         CF_VERBOSE(adding $cf_add_libdir to library-path)
 279         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 280       fi
 281     fi
 282   done
 283 fi
 284 ])dnl
 285 dnl ---------------------------------------------------------------------------
 286 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 287 dnl -----------
 288 dnl Add one or more libraries, used to enforce consistency.
 289 dnl
 290 dnl $1 = libraries to add, with the "-l", etc.
 291 dnl $2 = variable to update (default $LIBS)
 292 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 293 dnl ---------------------------------------------------------------------------
 294 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 295 dnl ------------------
 296 dnl Append to a search-list for a nonstandard header/lib-file
 297 dnl     $1 = the variable to return as result
 298 dnl     $2 = the package name
 299 dnl     $3 = the subdirectory, e.g., bin, include or lib
 300 dnl $4 = the directory under which we will test for subdirectories
 301 dnl $5 = a directory that we do not want $4 to match
 302 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 303 [
 304 test "$4" != "$5" && \
 305 test -d "$4" && \
 306 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 307         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 308         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 309         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 310         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 311         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 312         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 313 }
 314 ])dnl
 315 dnl ---------------------------------------------------------------------------
 316 dnl CF_ANSI_CC_CHECK version: 10 updated: 2010/10/23 15:52:32
 317 dnl ----------------
 318 dnl This is adapted from the macros 'fp_PROG_CC_STDC' and 'fp_C_PROTOTYPES'
 319 dnl in the sharutils 4.2 distribution.
 320 AC_DEFUN([CF_ANSI_CC_CHECK],
 321 [
 322 AC_CACHE_CHECK(for ${CC:-cc} option to accept ANSI C, cf_cv_ansi_cc,[
 323 cf_cv_ansi_cc=no
 324 cf_save_CFLAGS="$CFLAGS"
 325 cf_save_CPPFLAGS="$CPPFLAGS"
 326 # Don't try gcc -ansi; that turns off useful extensions and
 327 # breaks some systems' header files.
 328 # AIX                   -qlanglvl=ansi
 329 # Ultrix and OSF/1      -std1
 330 # HP-UX                 -Aa -D_HPUX_SOURCE
 331 # SVR4                  -Xc
 332 # UnixWare 1.2          (cannot use -Xc, since ANSI/POSIX clashes)
 333 for cf_arg in "-DCC_HAS_PROTOS" \
 334         "" \
 335         -qlanglvl=ansi \
 336         -std1 \
 337         -Ae \
 338         "-Aa -D_HPUX_SOURCE" \
 339         -Xc
 340 do
 341         CF_ADD_CFLAGS($cf_arg)
 342         AC_TRY_COMPILE(
 343 [
 344 #ifndef CC_HAS_PROTOS
 345 #if !defined(__STDC__) || (__STDC__ != 1)
 346 choke me
 347 #endif
 348 #endif
 349 ],[
 350         int test (int i, double x);
 351         struct s1 {int (*f) (int a);};
 352         struct s2 {int (*f) (double a);};],
 353         [cf_cv_ansi_cc="$cf_arg"; break])
 354 done
 355 CFLAGS="$cf_save_CFLAGS"
 356 CPPFLAGS="$cf_save_CPPFLAGS"
 357 ])
 358
 359 if test "$cf_cv_ansi_cc" != "no"; then
 360 if test ".$cf_cv_ansi_cc" != ".-DCC_HAS_PROTOS"; then
 361         CF_ADD_CFLAGS($cf_cv_ansi_cc)
 362 else
 363         AC_DEFINE(CC_HAS_PROTOS)
 364 fi
 365 fi
 366 ])dnl
 367 dnl ---------------------------------------------------------------------------
 368 dnl CF_ANSI_CC_REQD version: 4 updated: 2008/03/23 14:48:54
 369 dnl ---------------
 370 dnl For programs that must use an ANSI compiler, obtain compiler options that
 371 dnl will make it recognize prototypes.  We'll do preprocessor checks in other
 372 dnl macros, since tools such as unproto can fake prototypes, but only part of
 373 dnl the preprocessor.
 374 AC_DEFUN([CF_ANSI_CC_REQD],
 375 [AC_REQUIRE([CF_ANSI_CC_CHECK])
 376 if test "$cf_cv_ansi_cc" = "no"; then
 377         AC_MSG_ERROR(
 378 [Your compiler does not appear to recognize prototypes.
 379 You have the following choices:
 380         a. adjust your compiler options
 381         b. get an up-to-date compiler
 382         c. use a wrapper such as unproto])
 383 fi
 384 ])dnl
 385 dnl ---------------------------------------------------------------------------
 386 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 387 dnl --------------
 388 dnl Allow user to disable a normally-on option.
 389 AC_DEFUN([CF_ARG_DISABLE],
 390 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 391 dnl ---------------------------------------------------------------------------
 392 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 393 dnl -------------
 394 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 395 dnl values.
 396 dnl
 397 dnl Parameters:
 398 dnl $1 = option name
 399 dnl $2 = help-string
 400 dnl $3 = action to perform if option is not default
 401 dnl $4 = action if perform if option is default
 402 dnl $5 = default option value (either 'yes' or 'no')
 403 AC_DEFUN([CF_ARG_OPTION],
 404 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 405   if test "$enableval" != "$5" ; then
 406 ifelse([$3],,[    :]dnl
 407 ,[    $3]) ifelse([$4],,,[
 408   else
 409     $4])
 410   fi],[enableval=$5 ifelse([$4],,,[
 411   $4
 412 ])dnl
 413   ])])dnl
 414 dnl ---------------------------------------------------------------------------
 415 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 416 dnl -----------
 417 dnl Check for suitable "ar" (archiver) options for updating an archive.
 418 AC_DEFUN([CF_AR_FLAGS],[
 419 AC_REQUIRE([CF_PROG_AR])
 420
 421 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 422         cf_cv_ar_flags=unknown
 423         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 424         do
 425
 426                 # check if $ARFLAGS already contains this choice
 427                 if test "x$ARFLAGS" != "x" ; then
 428                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 429                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 430                                 cf_cv_ar_flags=
 431                                 break
 432                         fi
 433                 fi
 434
 435                 rm -f conftest.$ac_cv_objext
 436                 rm -f conftest.a
 437
 438                 cat >conftest.$ac_ext <<EOF
 439 #line __oline__ "configure"
 440 int     testdata[[3]] = { 123, 456, 789 };
 441 EOF
 442                 if AC_TRY_EVAL(ac_compile) ; then
 443                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 444                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 445                         if test -f conftest.a ; then
 446                                 cf_cv_ar_flags=$cf_ar_flags
 447                                 break
 448                         fi
 449                 else
 450                         CF_VERBOSE(cannot compile test-program)
 451                         break
 452                 fi
 453         done
 454         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 455 ])
 456
 457 if test -n "$ARFLAGS" ; then
 458         if test -n "$cf_cv_ar_flags" ; then
 459                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 460         fi
 461 else
 462         ARFLAGS=$cf_cv_ar_flags
 463 fi
 464
 465 AC_SUBST(ARFLAGS)
 466 ])
 467 dnl ---------------------------------------------------------------------------
 468 dnl CF_AWK_BIG_PRINTF version: 3 updated: 2008/12/27 12:30:03
 469 dnl -----------------
 470 dnl Check if awk can handle big strings using printf.  Some older versions of
 471 dnl awk choke on large strings passed via "%s".
 472 dnl
 473 dnl $1 = desired string size
 474 dnl $2 = variable to set with result
 475 AC_DEFUN([CF_AWK_BIG_PRINTF],
 476 [
 477         case x$AWK in #(vi
 478         x)
 479                 eval $2=no
 480                 ;;
 481         *) #(vi
 482                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' \
 483                         | $AWK '{ printf "%d\n", length([$]0); }' | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 484                         eval $2=yes
 485                 else
 486                         eval $2=no
 487                 fi
 488                 ;;
 489         esac
 490 ])dnl
 491 dnl ---------------------------------------------------------------------------
 492 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 493 dnl ------------
 494 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 495 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 496 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 497 dnl
 498 dnl Treat the configuration-variable specially here, since we're directly
 499 dnl substituting its value (i.e., 1/0).
 500 dnl
 501 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 502 AC_DEFUN([CF_BOOL_DECL],
 503 [
 504 AC_MSG_CHECKING(if we should include stdbool.h)
 505
 506 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 507         AC_TRY_COMPILE([],[bool foo = false],
 508                 [cf_cv_header_stdbool_h=0],
 509                 [AC_TRY_COMPILE([
 510 #ifndef __BEOS__
 511 #include <stdbool.h>
 512 #endif
 513 ],[bool foo = false],
 514                         [cf_cv_header_stdbool_h=1],
 515                         [cf_cv_header_stdbool_h=0])])])
 516
 517 if test "$cf_cv_header_stdbool_h" = 1
 518 then    AC_MSG_RESULT(yes)
 519 else    AC_MSG_RESULT(no)
 520 fi
 521
 522 AC_MSG_CHECKING([for builtin bool type])
 523
 524 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 525         AC_TRY_COMPILE([
 526 #include <stdio.h>
 527 #include <sys/types.h>
 528 ],[bool x = false],
 529                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 530                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 531         ])
 532
 533 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 534 then    AC_MSG_RESULT(yes)
 535 else    AC_MSG_RESULT(no)
 536 fi
 537 ])dnl
 538 dnl ---------------------------------------------------------------------------
 539 dnl CF_BOOL_SIZE version: 12 updated: 2006/12/16 12:33:30
 540 dnl ------------
 541 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 542 dnl Don't bother looking for bool.h, since it's been deprecated.
 543 dnl
 544 dnl If the current compiler is C rather than C++, we get the bool definition
 545 dnl from <stdbool.h>.
 546 AC_DEFUN([CF_BOOL_SIZE],
 547 [
 548 AC_MSG_CHECKING([for size of bool])
 549 AC_CACHE_VAL(cf_cv_type_of_bool,[
 550         rm -f cf_test.out
 551         AC_TRY_RUN([
 552 #include <stdlib.h>
 553 #include <stdio.h>
 554
 555 #if defined(__cplusplus)
 556
 557 #ifdef HAVE_GXX_BUILTIN_H
 558 #include <g++/builtin.h>
 559 #elif HAVE_GPP_BUILTIN_H
 560 #include <gpp/builtin.h>
 561 #elif HAVE_BUILTIN_H
 562 #include <builtin.h>
 563 #endif
 564
 565 #else
 566
 567 #if $cf_cv_header_stdbool_h
 568 #include <stdbool.h>
 569 #endif
 570
 571 #endif
 572
 573 main()
 574 {
 575         FILE *fp = fopen("cf_test.out", "w");
 576         if (fp != 0) {
 577                 bool x = true;
 578                 if ((bool)(-x) >= 0)
 579                         fputs("unsigned ", fp);
 580                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 581                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 582                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 583                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 584                 fclose(fp);
 585         }
 586         ${cf_cv_main_return:-return}(0);
 587 }
 588                 ],
 589                 [cf_cv_type_of_bool=`cat cf_test.out`
 590                  if test -z "$cf_cv_type_of_bool"; then
 591                    cf_cv_type_of_bool=unknown
 592                  fi],
 593                 [cf_cv_type_of_bool=unknown],
 594                 [cf_cv_type_of_bool=unknown])
 595         ])
 596         rm -f cf_test.out
 597 AC_MSG_RESULT($cf_cv_type_of_bool)
 598 if test "$cf_cv_type_of_bool" = unknown ; then
 599         case .$NCURSES_BOOL in #(vi
 600         .auto|.) NCURSES_BOOL=unsigned;;
 601         esac
 602         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 603         cf_cv_type_of_bool=$NCURSES_BOOL
 604 fi
 605 ])dnl
 606 dnl ---------------------------------------------------------------------------
 607 dnl CF_BUILD_CC version: 6 updated: 2006/10/14 15:23:15
 608 dnl -----------
 609 dnl If we're cross-compiling, allow the user to override the tools and their
 610 dnl options.  The configure script is oriented toward identifying the host
 611 dnl compiler, etc., but we need a build compiler to generate parts of the
 612 dnl source.
 613 dnl
 614 dnl $1 = default for $CPPFLAGS
 615 dnl $2 = default for $LIBS
 616 AC_DEFUN([CF_BUILD_CC],[
 617 AC_REQUIRE([CF_PROG_EXT])
 618 if test "$cross_compiling" = yes ; then
 619
 620         # defaults that we might want to override
 621         : ${BUILD_CFLAGS:=''}
 622         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 623         : ${BUILD_LDFLAGS:=''}
 624         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 625         : ${BUILD_EXEEXT:='$x'}
 626         : ${BUILD_OBJEXT:='o'}
 627
 628         AC_ARG_WITH(build-cc,
 629                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 630                 [BUILD_CC="$withval"],
 631                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 632         AC_MSG_CHECKING(for native build C compiler)
 633         AC_MSG_RESULT($BUILD_CC)
 634
 635         AC_MSG_CHECKING(for native build C preprocessor)
 636         AC_ARG_WITH(build-cpp,
 637                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 638                 [BUILD_CPP="$withval"],
 639                 [BUILD_CPP='${BUILD_CC} -E'])
 640         AC_MSG_RESULT($BUILD_CPP)
 641
 642         AC_MSG_CHECKING(for native build C flags)
 643         AC_ARG_WITH(build-cflags,
 644                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 645                 [BUILD_CFLAGS="$withval"])
 646         AC_MSG_RESULT($BUILD_CFLAGS)
 647
 648         AC_MSG_CHECKING(for native build C preprocessor-flags)
 649         AC_ARG_WITH(build-cppflags,
 650                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 651                 [BUILD_CPPFLAGS="$withval"])
 652         AC_MSG_RESULT($BUILD_CPPFLAGS)
 653
 654         AC_MSG_CHECKING(for native build linker-flags)
 655         AC_ARG_WITH(build-ldflags,
 656                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 657                 [BUILD_LDFLAGS="$withval"])
 658         AC_MSG_RESULT($BUILD_LDFLAGS)
 659
 660         AC_MSG_CHECKING(for native build linker-libraries)
 661         AC_ARG_WITH(build-libs,
 662                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 663                 [BUILD_LIBS="$withval"])
 664         AC_MSG_RESULT($BUILD_LIBS)
 665
 666         # this assumes we're on Unix.
 667         BUILD_EXEEXT=
 668         BUILD_OBJEXT=o
 669
 670         : ${BUILD_CC:='${CC}'}
 671
 672         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 673                 AC_MSG_ERROR([Cross-build requires two compilers.
 674 Use --with-build-cc to specify the native compiler.])
 675         fi
 676
 677 else
 678         : ${BUILD_CC:='${CC}'}
 679         : ${BUILD_CPP:='${CPP}'}
 680         : ${BUILD_CFLAGS:='${CFLAGS}'}
 681         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 682         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 683         : ${BUILD_LIBS:='${LIBS}'}
 684         : ${BUILD_EXEEXT:='$x'}
 685         : ${BUILD_OBJEXT:='o'}
 686 fi
 687
 688 AC_SUBST(BUILD_CC)
 689 AC_SUBST(BUILD_CPP)
 690 AC_SUBST(BUILD_CFLAGS)
 691 AC_SUBST(BUILD_CPPFLAGS)
 692 AC_SUBST(BUILD_LDFLAGS)
 693 AC_SUBST(BUILD_LIBS)
 694 AC_SUBST(BUILD_EXEEXT)
 695 AC_SUBST(BUILD_OBJEXT)
 696 ])dnl
 697 dnl ---------------------------------------------------------------------------
 698 dnl CF_CFG_DEFAULTS version: 7 updated: 2005/09/24 16:15:00
 699 dnl ---------------
 700 dnl Determine the default configuration into which we'll install ncurses.  This
 701 dnl can be overridden by the user's command-line options.  There's two items to
 702 dnl look for:
 703 dnl     1. the prefix (e.g., /usr)
 704 dnl     2. the header files (e.g., /usr/include/ncurses)
 705 dnl We'll look for a previous installation of ncurses and use the same defaults.
 706 dnl
 707 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 708 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 709 dnl programs from a vendor's.
 710 AC_DEFUN([CF_CFG_DEFAULTS],
 711 [
 712 AC_MSG_CHECKING(for prefix)
 713 if test "x$prefix" = "xNONE" ; then
 714         case "$cf_cv_system_name" in
 715                 # non-vendor systems don't have a conflict
 716         openbsd*|freebsd*|linux*|cygwin*|k*bsd*-gnu)
 717                 prefix=/usr
 718                 ;;
 719         *)      prefix=$ac_default_prefix
 720                 ;;
 721         esac
 722 fi
 723 AC_MSG_RESULT($prefix)
 724
 725 if test "x$prefix" = "xNONE" ; then
 726 AC_MSG_CHECKING(for default include-directory)
 727 test -n "$verbose" && echo 1>&AC_FD_MSG
 728 for cf_symbol in \
 729         $includedir \
 730         $includedir/ncurses \
 731         $prefix/include \
 732         $prefix/include/ncurses \
 733         /usr/local/include \
 734         /usr/local/include/ncurses \
 735         /usr/include \
 736         /usr/include/ncurses
 737 do
 738         cf_dir=`eval echo $cf_symbol`
 739         if test -f $cf_dir/curses.h ; then
 740         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 741                 includedir="$cf_symbol"
 742                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 743                 break
 744         fi
 745         fi
 746         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 747 done
 748 AC_MSG_RESULT($includedir)
 749 fi
 750 ])dnl
 751 dnl ---------------------------------------------------------------------------
 752 dnl CF_CGETENT version: 3 updated: 2000/08/12 23:18:52
 753 dnl ----------
 754 dnl Check if the terminal-capability database functions are available.  If not,
 755 dnl ncurses has a much-reduced version.
 756 AC_DEFUN([CF_CGETENT],[
 757 AC_MSG_CHECKING(for terminal-capability database functions)
 758 AC_CACHE_VAL(cf_cv_cgetent,[
 759 AC_TRY_LINK([
 760 #include <stdlib.h>],[
 761         char temp[128];
 762         char *buf = temp;
 763         char *db_array = temp;
 764         cgetent(&buf, /* int *, */ &db_array, "vt100");
 765         cgetcap(buf, "tc", '=');
 766         cgetmatch(buf, "tc");
 767         ],
 768         [cf_cv_cgetent=yes],
 769         [cf_cv_cgetent=no])
 770 ])
 771 AC_MSG_RESULT($cf_cv_cgetent)
 772 test "$cf_cv_cgetent" = yes && AC_DEFINE(HAVE_BSD_CGETENT)
 773 ])dnl
 774 dnl ---------------------------------------------------------------------------
 775 dnl CF_CHECK_CACHE version: 11 updated: 2008/03/23 14:45:59
 776 dnl --------------
 777 dnl Check if we're accidentally using a cache from a different machine.
 778 dnl Derive the system name, as a check for reusing the autoconf cache.
 779 dnl
 780 dnl If we've packaged config.guess and config.sub, run that (since it does a
 781 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 782 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 783 dnl which is useful in cross-compiles.
 784 dnl
 785 dnl Note: we would use $ac_config_sub, but that is one of the places where
 786 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 787 AC_DEFUN([CF_CHECK_CACHE],
 788 [
 789 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 790         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 791         system_name="$host_os"
 792 else
 793         system_name="`(uname -s -r) 2>/dev/null`"
 794         if test -z "$system_name" ; then
 795                 system_name="`(hostname) 2>/dev/null`"
 796         fi
 797 fi
 798 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name")
 799 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 800
 801 test -z "$system_name" && system_name="$cf_cv_system_name"
 802 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 803
 804 if test ".$system_name" != ".$cf_cv_system_name" ; then
 805         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 806         AC_MSG_ERROR("Please remove config.cache and try again.")
 807 fi
 808 ])dnl
 809 dnl ---------------------------------------------------------------------------
 810 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
 811 dnl --------------
 812 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 813 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 814 dnl ourselves.
 815 dnl
 816 dnl $1 = the name to check
 817 dnl $2 = the assumed type
 818 AC_DEFUN([CF_CHECK_ERRNO],
 819 [
 820 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 821     AC_TRY_COMPILE([
 822 #ifdef HAVE_STDLIB_H
 823 #include <stdlib.h>
 824 #endif
 825 #include <stdio.h>
 826 #include <sys/types.h>
 827 #include <errno.h> ],
 828     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 829     [cf_cv_dcl_$1=yes],
 830     [cf_cv_dcl_$1=no])
 831 ])
 832
 833 if test "$cf_cv_dcl_$1" = no ; then
 834     CF_UPPER(cf_result,decl_$1)
 835     AC_DEFINE_UNQUOTED($cf_result)
 836 fi
 837
 838 # It's possible (for near-UNIX clones) that the data doesn't exist
 839 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 840 ])dnl
 841 dnl ---------------------------------------------------------------------------
 842 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
 843 dnl --------------------
 844 dnl Check for existence of external data in the current set of libraries.  If
 845 dnl we can modify it, it's real enough.
 846 dnl $1 = the name to check
 847 dnl $2 = its type
 848 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 849 [
 850 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 851     AC_TRY_LINK([
 852 #undef $1
 853 extern $2 $1;
 854 ],
 855     [$1 = 2],
 856     [cf_cv_have_$1=yes],
 857     [cf_cv_have_$1=no])
 858 ])
 859
 860 if test "$cf_cv_have_$1" = yes ; then
 861     CF_UPPER(cf_result,have_$1)
 862     AC_DEFINE_UNQUOTED($cf_result)
 863 fi
 864
 865 ])dnl
 866 dnl ---------------------------------------------------------------------------
 867 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 868 dnl -------------------
 869 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 870 dnl is not "weak" - warn about this because it can create problems linking
 871 dnl applications with ncurses.
 872 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 873 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 874
 875 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 876 cf_cv_check_gpm_wgetch=unknown
 877 if test "$cross_compiling" != yes ; then
 878
 879 cat >conftest.$ac_ext <<CF_EOF
 880 #include <gpm.h>
 881 int main()
 882 {
 883         Gpm_Wgetch();
 884         ${cf_cv_main_return:-return}(0);
 885 }
 886 CF_EOF
 887
 888         cf_save_LIBS="$LIBS"
 889         # This only works if we can look at the symbol table.  If a shared
 890         # library is stripped for install, we cannot use that.  So we're forced
 891         # to rely on the static library, noting that some packagers may not
 892         # include it.
 893         LIBS="-static -lgpm -dynamic $LIBS"
 894         if AC_TRY_EVAL(ac_compile) ; then
 895                 if AC_TRY_EVAL(ac_link) ; then
 896                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 897                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 898                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 899                 fi
 900         fi
 901         rm -rf conftest*
 902         LIBS="$cf_save_LIBS"
 903 fi
 904 ])
 905
 906 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 907         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 908 fi
 909 ])])dnl
 910 dnl ---------------------------------------------------------------------------
 911 dnl CF_CPP_PARAM_INIT version: 4 updated: 2001/04/07 22:31:18
 912 dnl -----------------
 913 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
 914 dnl is a late feature for the standard and is not in some recent compilers
 915 dnl (1999/9/11).
 916 AC_DEFUN([CF_CPP_PARAM_INIT],
 917 [
 918 if test -n "$CXX"; then
 919 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
 920         AC_LANG_SAVE
 921         AC_LANG_CPLUSPLUS
 922         AC_TRY_RUN([
 923 class TEST {
 924 private:
 925         int value;
 926 public:
 927         TEST(int x = 1);
 928         ~TEST();
 929 };
 930
 931 TEST::TEST(int x = 1)   // some compilers do not like second initializer
 932 {
 933         value = x;
 934 }
 935 void main() { }
 936 ],
 937         [cf_cv_cpp_param_init=yes],
 938         [cf_cv_cpp_param_init=no],
 939         [cf_cv_cpp_param_init=unknown])
 940         AC_LANG_RESTORE
 941 ])
 942 fi
 943 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT)
 944 ])dnl
 945 dnl ---------------------------------------------------------------------------
 946 dnl CF_CPP_STATIC_CAST version: 1 updated: 2005/07/23 16:52:43
 947 dnl ------------------
 948 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
 949 dnl not be supported in g++ before 3.0
 950 AC_DEFUN([CF_CPP_STATIC_CAST],
 951 [
 952 if test -n "$CXX"; then
 953
 954 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
 955         AC_LANG_SAVE
 956         AC_LANG_CPLUSPLUS
 957
 958         AC_TRY_COMPILE([
 959 class NCursesPanel
 960 {
 961 public:
 962   NCursesPanel(int nlines,
 963                int ncols,
 964                int begin_y = 0,
 965                int begin_x = 0)
 966   {
 967   }
 968
 969   ~NCursesPanel();
 970 };
 971
 972 template<class T> class NCursesUserPanel : public NCursesPanel
 973 {
 974 public:
 975   NCursesUserPanel (int nlines,
 976                     int ncols,
 977                     int begin_y = 0,
 978                     int begin_x = 0,
 979                     const T* p_UserData = static_cast<T*>(0))
 980     : NCursesPanel (nlines, ncols, begin_y, begin_x)
 981   {
 982   };
 983   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
 984   {
 985   };
 986
 987   virtual ~NCursesUserPanel() {};
 988 };
 989 ],[
 990         const char* p_UserData = static_cast<char*>(0)],
 991         [cf_cv_cpp_static_cast=yes],
 992         [cf_cv_cpp_static_cast=no])
 993
 994         AC_LANG_RESTORE
 995 ])
 996
 997 fi
 998
 999 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST)
1000 ])dnl
1001 dnl ---------------------------------------------------------------------------
1002 dnl CF_C_INLINE version: 3 updated: 2010/05/01 15:14:41
1003 dnl -----------
1004 dnl Check if the C compiler supports "inline".
1005 dnl $1 is the name of a shell variable to set if inline is supported
1006 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1007 AC_DEFUN([CF_C_INLINE],[
1008 AC_C_INLINE
1009 $1=
1010 if test "$ac_cv_c_inline" != no ; then
1011   $1=inline
1012   if test "$INTEL_COMPILER" = yes
1013   then
1014     :
1015   elif test "$GCC" = yes
1016   then
1017     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1018       cf_save_CFLAGS=$CFLAGS
1019       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1020       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1021       [${cf_cv_main_return:-return} foo()],
1022       [cf_cv_gcc_inline=yes],
1023       [cf_cv_gcc_inline=no])
1024       CFLAGS=$cf_save_CFLAGS
1025     ])
1026     if test "$cf_cv_gcc_inline" = yes ; then
1027         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1028     fi
1029   fi
1030 fi
1031 AC_SUBST($1)
1032 ])dnl
1033 dnl ---------------------------------------------------------------------------
1034 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1035 dnl ----------
1036 dnl "dirname" is not portable, so we fake it with a shell script.
1037 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1038 dnl ---------------------------------------------------------------------------
1039 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1040 dnl ---------------
1041 AC_DEFUN([CF_DIRS_TO_MAKE],
1042 [
1043 DIRS_TO_MAKE="lib"
1044 for cf_item in $cf_list_models
1045 do
1046         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1047         for cf_item2 in $DIRS_TO_MAKE
1048         do
1049                 test $cf_item2 = $cf_subdir && break
1050         done
1051         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1052 done
1053 for cf_dir in $DIRS_TO_MAKE
1054 do
1055         test ! -d $cf_dir && mkdir $cf_dir
1056 done
1057 AC_SUBST(DIRS_TO_MAKE)
1058 ])dnl
1059 dnl ---------------------------------------------------------------------------
1060 dnl CF_DISABLE_LEAKS version: 6 updated: 2010/07/23 04:14:32
1061 dnl ----------------
1062 dnl Combine no-leak checks with the libraries or tools that are used for the
1063 dnl checks.
1064 AC_DEFUN([CF_DISABLE_LEAKS],[
1065
1066 AC_REQUIRE([CF_WITH_DMALLOC])
1067 AC_REQUIRE([CF_WITH_DBMALLOC])
1068 AC_REQUIRE([CF_WITH_VALGRIND])
1069
1070 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1071 AC_ARG_ENABLE(leaks,
1072         [  --disable-leaks         test: free permanent memory, analyze leaks],
1073         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1074         : ${with_no_leaks:=no})
1075 AC_MSG_RESULT($with_no_leaks)
1076
1077 if test "$with_no_leaks" = yes ; then
1078         AC_DEFINE(NO_LEAKS)
1079         AC_DEFINE(YY_NO_LEAKS)
1080 fi
1081 ])dnl
1082 dnl ---------------------------------------------------------------------------
1083 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1084 dnl --------------------------
1085 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1086 dnl the older "-version-info" feature.  The newer feature allows us to use
1087 dnl version numbering on shared libraries which make them compatible with
1088 dnl various systems.
1089 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1090 [
1091 AC_MSG_CHECKING(if libtool -version-number should be used)
1092 CF_ARG_DISABLE(libtool-version,
1093         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1094         [cf_libtool_version=no],
1095         [cf_libtool_version=yes])
1096 AC_MSG_RESULT($cf_libtool_version)
1097
1098 if test "$cf_libtool_version" = yes ; then
1099         LIBTOOL_VERSION="-version-number"
1100 else
1101         LIBTOOL_VERSION="-version-info"
1102 fi
1103
1104 AC_SUBST(LIBTOOL_VERSION)
1105 ])dnl
1106 dnl ---------------------------------------------------------------------------
1107 dnl CF_DISABLE_RPATH_HACK version: 1 updated: 2010/04/11 10:54:00
1108 dnl ---------------------
1109 dnl The rpath-hack makes it simpler to build programs, particularly with the
1110 dnl *BSD ports which may have essential libraries in unusual places.  But it
1111 dnl can interfere with building an executable for the base system.  Use this
1112 dnl option in that case.
1113 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1114 [
1115 AC_MSG_CHECKING(if rpath should be not be set)
1116 CF_ARG_DISABLE(rpath-hack,
1117         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1118         [cf_disable_rpath_hack=yes],
1119         [cf_disable_rpath_hack=no])
1120 AC_MSG_RESULT($cf_disable_rpath_hack)
1121 if test "$cf_disable_rpath_hack" = no ; then
1122         CF_RPATH_HACK
1123 fi
1124 ])
1125 dnl ---------------------------------------------------------------------------
1126 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1127 dnl ---------------
1128 dnl Check if the rpath option should be used, setting cache variable
1129 dnl cf_cv_enable_rpath if so.
1130 AC_DEFUN([CF_ENABLE_RPATH],
1131 [
1132 AC_MSG_CHECKING(if rpath option should be used)
1133 AC_ARG_ENABLE(rpath,
1134 [  --enable-rpath          use rpath option when generating shared libraries],
1135 [cf_cv_enable_rpath=$enableval],
1136 [cf_cv_enable_rpath=no])
1137 AC_MSG_RESULT($cf_cv_enable_rpath)
1138 ])dnl
1139 dnl ---------------------------------------------------------------------------
1140 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1141 dnl --------
1142 dnl Check if 'errno' is declared in <errno.h>
1143 AC_DEFUN([CF_ERRNO],
1144 [
1145 CF_CHECK_ERRNO(errno)
1146 ])dnl
1147 dnl ---------------------------------------------------------------------------
1148 dnl CF_ETIP_DEFINES version: 3 updated: 2003/03/22 19:13:43
1149 dnl ---------------
1150 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1151 dnl math.h and builtin.h, only for ncurses
1152 AC_DEFUN([CF_ETIP_DEFINES],
1153 [
1154 AC_MSG_CHECKING(for special defines needed for etip.h)
1155 cf_save_CXXFLAGS="$CXXFLAGS"
1156 cf_result="none"
1157 for cf_math in "" MATH_H
1158 do
1159 for cf_excp in "" MATH_EXCEPTION
1160 do
1161         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -I${srcdir}/include"
1162         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1163         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1164 AC_TRY_COMPILE([
1165 #include <etip.h.in>
1166 ],[],[
1167         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1168         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1169         cf_result="$cf_math $cf_excp"
1170         break
1171 ],[])
1172 done
1173 done
1174 AC_MSG_RESULT($cf_result)
1175 CXXFLAGS="$cf_save_CXXFLAGS"
1176 ])
1177 dnl ---------------------------------------------------------------------------
1178 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1179 dnl ---------------
1180 dnl Find a library (specifically the linkage used in the code fragment),
1181 dnl searching for it if it is not already in the library path.
1182 dnl See also CF_ADD_SEARCHPATH.
1183 dnl
1184 dnl Parameters (4-on are optional):
1185 dnl     $1 = headers for library entrypoint
1186 dnl     $2 = code fragment for library entrypoint
1187 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1188 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1189 dnl     $5 = action to perform if not successful
1190 dnl     $6 = module name, if not the same as the library name
1191 dnl     $7 = extra libraries
1192 dnl
1193 dnl Sets these variables:
1194 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1195 dnl     $cf_cv_header_path_$3 - include-directory if needed
1196 dnl     $cf_cv_library_path_$3 - library-directory if needed
1197 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1198 AC_DEFUN([CF_FIND_LINKAGE],[
1199
1200 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1201 # will be set on completion of the AC_TRY_LINK below.
1202 cf_cv_header_path_$3=
1203 cf_cv_library_path_$3=
1204
1205 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1206
1207 cf_save_LIBS="$LIBS"
1208
1209 AC_TRY_LINK([$1],[$2],[
1210         cf_cv_find_linkage_$3=yes
1211         cf_cv_header_path_$3=/usr/include
1212         cf_cv_library_path_$3=/usr/lib
1213 ],[
1214
1215 LIBS="-l$3 $7 $cf_save_LIBS"
1216
1217 AC_TRY_LINK([$1],[$2],[
1218         cf_cv_find_linkage_$3=yes
1219         cf_cv_header_path_$3=/usr/include
1220         cf_cv_library_path_$3=/usr/lib
1221         cf_cv_library_file_$3="-l$3"
1222 ],[
1223         cf_cv_find_linkage_$3=no
1224         LIBS="$cf_save_LIBS"
1225
1226     CF_VERBOSE(find linkage for $3 library)
1227     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1228
1229     cf_save_CPPFLAGS="$CPPFLAGS"
1230     cf_test_CPPFLAGS="$CPPFLAGS"
1231
1232     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1233     for cf_cv_header_path_$3 in $cf_search
1234     do
1235       if test -d $cf_cv_header_path_$3 ; then
1236         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1237         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1238         AC_TRY_COMPILE([$1],[$2],[
1239             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1240             cf_cv_find_linkage_$3=maybe
1241             cf_test_CPPFLAGS="$CPPFLAGS"
1242             break],[
1243             CPPFLAGS="$cf_save_CPPFLAGS"
1244             ])
1245       fi
1246     done
1247
1248     if test "$cf_cv_find_linkage_$3" = maybe ; then
1249
1250       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1251
1252       cf_save_LIBS="$LIBS"
1253       cf_save_LDFLAGS="$LDFLAGS"
1254
1255       ifelse([$6],,,[
1256         CPPFLAGS="$cf_test_CPPFLAGS"
1257         LIBS="-l$3 $7 $cf_save_LIBS"
1258         AC_TRY_LINK([$1],[$2],[
1259             CF_VERBOSE(... found $3 library in system)
1260             cf_cv_find_linkage_$3=yes])
1261             CPPFLAGS="$cf_save_CPPFLAGS"
1262             LIBS="$cf_save_LIBS"
1263             ])
1264
1265       if test "$cf_cv_find_linkage_$3" != yes ; then
1266         CF_LIBRARY_PATH(cf_search,$3)
1267         for cf_cv_library_path_$3 in $cf_search
1268         do
1269           if test -d $cf_cv_library_path_$3 ; then
1270             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1271             CPPFLAGS="$cf_test_CPPFLAGS"
1272             LIBS="-l$3 $7 $cf_save_LIBS"
1273             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1274             AC_TRY_LINK([$1],[$2],[
1275                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1276                 cf_cv_find_linkage_$3=yes
1277                 cf_cv_library_file_$3="-l$3"
1278                 break],[
1279                 CPPFLAGS="$cf_save_CPPFLAGS"
1280                 LIBS="$cf_save_LIBS"
1281                 LDFLAGS="$cf_save_LDFLAGS"
1282                 ])
1283           fi
1284         done
1285         CPPFLAGS="$cf_save_CPPFLAGS"
1286         LDFLAGS="$cf_save_LDFLAGS"
1287       fi
1288
1289     else
1290       cf_cv_find_linkage_$3=no
1291     fi
1292     ],$7)
1293 ])
1294
1295 LIBS="$cf_save_LIBS"
1296
1297 if test "$cf_cv_find_linkage_$3" = yes ; then
1298 ifelse([$4],,[
1299         CF_ADD_INCDIR($cf_cv_header_path_$3)
1300         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1301         CF_ADD_LIB($3)
1302 ],[$4])
1303 else
1304 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1305 fi
1306 ])dnl
1307 dnl ---------------------------------------------------------------------------
1308 dnl CF_FUNC_DLSYM version: 2 updated: 2010/05/29 16:31:02
1309 dnl -------------
1310 dnl Test for dlsym() and related functions, as well as libdl.
1311 dnl
1312 dnl Sets
1313 dnl     $cf_have_dlsym
1314 dnl     $cf_have_libdl
1315 AC_DEFUN([CF_FUNC_DLSYM],[
1316 cf_have_dlsym=no
1317 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1318
1319 cf_have_libdl=no
1320 AC_CHECK_LIB(dl,dlsym,[
1321         cf_have_dlsym=yes
1322         cf_have_libdl=yes])])
1323
1324 if test "$cf_have_dlsym" = yes ; then
1325         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1326
1327         AC_MSG_CHECKING(whether able to link to dl*() functions)
1328         AC_TRY_LINK([#include <dlfcn.h>],[
1329                 void *obj;
1330                 if ((obj = dlopen("filename", 0)) != 0) {
1331                         if (dlsym(obj, "symbolname") == 0) {
1332                         dlclose(obj);
1333                         }
1334                 }],[
1335                 AC_DEFINE(HAVE_LIBDL)],[
1336                 AC_MSG_ERROR(Cannot link test program for libdl)])
1337         AC_MSG_RESULT(ok)
1338 else
1339         AC_MSG_ERROR(Cannot find dlsym function)
1340 fi
1341 ])
1342 dnl ---------------------------------------------------------------------------
1343 dnl CF_FUNC_MEMMOVE version: 7 updated: 2006/12/16 12:33:30
1344 dnl ---------------
1345 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1346 dnl is found, add our own version of memmove to the list of objects.
1347 AC_DEFUN([CF_FUNC_MEMMOVE],
1348 [
1349 AC_CHECK_FUNC(memmove,,[
1350 AC_CHECK_FUNC(bcopy,[
1351         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1352                 AC_TRY_RUN([
1353 int main() {
1354         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1355         char temp[40];
1356         bcopy(data, temp, sizeof(data));
1357         bcopy(temp+10, temp, 15);
1358         bcopy(temp+5, temp+15, 10);
1359         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1360 }
1361                 ],
1362                 [cf_cv_good_bcopy=yes],
1363                 [cf_cv_good_bcopy=no],
1364                 [cf_cv_good_bcopy=unknown])
1365                 ])
1366         ],[cf_cv_good_bcopy=no])
1367         if test "$cf_cv_good_bcopy" = yes ; then
1368                 AC_DEFINE(USE_OK_BCOPY)
1369         else
1370                 AC_DEFINE(USE_MY_MEMMOVE)
1371         fi
1372 ])])dnl
1373 dnl ---------------------------------------------------------------------------
1374 dnl CF_FUNC_NANOSLEEP version: 3 updated: 2006/12/16 12:33:30
1375 dnl -----------------
1376 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1377 dnl AIX 4.x, provide a non-working version.
1378 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1379 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1380 AC_TRY_RUN([
1381 #include <stdio.h>
1382 #include <errno.h>
1383 #include <time.h>
1384
1385 #ifdef HAVE_SYS_TIME_H
1386 #include <sys/time.h>
1387 #endif
1388
1389 int main() {
1390         struct timespec ts1, ts2;
1391         int code;
1392         ts1.tv_sec  = 0;
1393         ts1.tv_nsec = 750000000;
1394         ts2.tv_sec  = 0;
1395         ts2.tv_nsec = 0;
1396         errno = 0;
1397         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1398         ${cf_cv_main_return:-return}(code != 0);
1399 }
1400 ],
1401         [cf_cv_func_nanosleep=yes],
1402         [cf_cv_func_nanosleep=no],
1403         [cf_cv_func_nanosleep=unknown])])
1404
1405 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP)
1406 ])
1407 dnl ---------------------------------------------------------------------------
1408 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1409 dnl ---------------
1410 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1411 dnl "util" library as well.
1412 AC_DEFUN([CF_FUNC_OPENPTY],
1413 [
1414 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1415 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1416     cf_save_LIBS="$LIBS"
1417     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1418     for cf_header in pty.h libutil.h util.h
1419     do
1420     AC_TRY_LINK([
1421 #include <$cf_header>
1422 ],[
1423     int x = openpty((int *)0, (int *)0, (char *)0,
1424                    (struct termios *)0, (struct winsize *)0);
1425 ],[
1426         cf_cv_func_openpty=$cf_header
1427         break
1428 ],[
1429         cf_cv_func_openpty=no
1430 ])
1431     done
1432     LIBS="$cf_save_LIBS"
1433 ])
1434 ])dnl
1435 dnl ---------------------------------------------------------------------------
1436 dnl CF_FUNC_POLL version: 4 updated: 2006/12/16 12:33:30
1437 dnl ------------
1438 dnl See if the poll function really works.  Some platforms have poll(), but
1439 dnl it does not work for terminals or files.
1440 AC_DEFUN([CF_FUNC_POLL],[
1441 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1442 AC_TRY_RUN([
1443 #include <stdio.h>
1444 #ifdef HAVE_POLL_H
1445 #include <poll.h>
1446 #else
1447 #include <sys/poll.h>
1448 #endif
1449 int main() {
1450         struct pollfd myfds;
1451         int ret;
1452
1453         myfds.fd = 0;
1454         myfds.events = POLLIN;
1455
1456         ret = poll(&myfds, 1, 100);
1457         ${cf_cv_main_return:-return}(ret != 0);
1458 }],
1459         [cf_cv_working_poll=yes],
1460         [cf_cv_working_poll=no],
1461         [cf_cv_working_poll=unknown])])
1462 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL)
1463 ])dnl
1464 dnl ---------------------------------------------------------------------------
1465 dnl CF_FUNC_TERMIOS version: 2 updated: 2000/07/22 23:37:24
1466 dnl ---------------
1467 dnl Some old/broken variations define tcgetattr() only as a macro in
1468 dnl termio(s).h
1469 AC_DEFUN([CF_FUNC_TERMIOS],[
1470 AC_REQUIRE([CF_STRUCT_TERMIOS])
1471 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1472 AC_TRY_LINK([
1473 #include <sys/types.h>
1474 #ifdef HAVE_UNISTD_H
1475 #include <unistd.h>
1476 #endif
1477 #ifdef HAVE_TERMIOS_H
1478 #include <termios.h>
1479 #define TTY struct termios
1480 #else
1481 #ifdef HAVE_TERMIO_H
1482 #include <termio.h>
1483 #define TTY struct termio
1484 #endif
1485 #endif
1486 ],[
1487 TTY foo;
1488 tcgetattr(1, &foo);],
1489 [cf_cv_have_tcgetattr=yes],
1490 [cf_cv_have_tcgetattr=no])])
1491 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR)
1492 ])dnl
1493 dnl ---------------------------------------------------------------------------
1494 dnl CF_FUNC_VSSCANF version: 3 updated: 2001/12/19 00:50:10
1495 dnl ---------------
1496 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1497 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1498 dnl other functions.
1499 AC_DEFUN([CF_FUNC_VSSCANF],
1500 [
1501 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1502 AC_TRY_LINK([
1503 #include <stdarg.h>
1504 #include <stdio.h>],[
1505         va_list ap;
1506         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1507 AC_TRY_LINK([
1508 #include <stdarg.h>
1509 #include <stdio.h>],[
1510     FILE strbuf;
1511     char *str = "from";
1512
1513     strbuf._flag = _IOREAD;
1514     strbuf._ptr = strbuf._base = (unsigned char *) str;
1515     strbuf._cnt = strlen(str);
1516     strbuf._file = _NFILE;
1517     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1518 AC_TRY_LINK([
1519 #include <stdarg.h>
1520 #include <stdio.h>],[
1521     FILE strbuf;
1522     char *str = "from";
1523
1524     strbuf._flag = _IOREAD;
1525     strbuf._ptr = strbuf._base = (unsigned char *) str;
1526     strbuf._cnt = strlen(str);
1527     strbuf._file = _NFILE;
1528     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1529 cf_cv_func_vsscanf=no])])])])
1530
1531 case $cf_cv_func_vsscanf in #(vi
1532 vsscanf) AC_DEFINE(HAVE_VSSCANF);; #(vi
1533 vfscanf) AC_DEFINE(HAVE_VFSCANF);; #(vi
1534 _doscan) AC_DEFINE(HAVE__DOSCAN);;
1535 esac
1536
1537 ])dnl
1538 dnl ---------------------------------------------------------------------------
1539 dnl CF_GCC_ATTRIBUTES version: 14 updated: 2010/10/23 15:52:32
1540 dnl -----------------
1541 dnl Test for availability of useful gcc __attribute__ directives to quiet
1542 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1543 dnl to documentation, unrecognized directives cause older compilers to barf.
1544 AC_DEFUN([CF_GCC_ATTRIBUTES],
1545 [
1546 if test "$GCC" = yes
1547 then
1548 cat > conftest.i <<EOF
1549 #ifndef GCC_PRINTF
1550 #define GCC_PRINTF 0
1551 #endif
1552 #ifndef GCC_SCANF
1553 #define GCC_SCANF 0
1554 #endif
1555 #ifndef GCC_NORETURN
1556 #define GCC_NORETURN /* nothing */
1557 #endif
1558 #ifndef GCC_UNUSED
1559 #define GCC_UNUSED /* nothing */
1560 #endif
1561 EOF
1562 if test "$GCC" = yes
1563 then
1564         AC_CHECKING([for $CC __attribute__ directives])
1565 cat > conftest.$ac_ext <<EOF
1566 #line __oline__ "${as_me:-configure}"
1567 #include "confdefs.h"
1568 #include "conftest.h"
1569 #include "conftest.i"
1570 #if     GCC_PRINTF
1571 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1572 #else
1573 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1574 #endif
1575 #if     GCC_SCANF
1576 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1577 #else
1578 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1579 #endif
1580 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1581 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1582 extern void foo(void) GCC_NORETURN;
1583 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1584 EOF
1585         cf_printf_attribute=no
1586         cf_scanf_attribute=no
1587         for cf_attribute in scanf printf unused noreturn
1588         do
1589                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1590                 cf_directive="__attribute__(($cf_attribute))"
1591                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1592
1593                 case $cf_attribute in #(vi
1594                 printf) #(vi
1595                         cf_printf_attribute=yes
1596                         cat >conftest.h <<EOF
1597 #define GCC_$cf_ATTRIBUTE 1
1598 EOF
1599                         ;;
1600                 scanf) #(vi
1601                         cf_scanf_attribute=yes
1602                         cat >conftest.h <<EOF
1603 #define GCC_$cf_ATTRIBUTE 1
1604 EOF
1605                         ;;
1606                 *) #(vi
1607                         cat >conftest.h <<EOF
1608 #define GCC_$cf_ATTRIBUTE $cf_directive
1609 EOF
1610                         ;;
1611                 esac
1612
1613                 if AC_TRY_EVAL(ac_compile); then
1614                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1615                         cat conftest.h >>confdefs.h
1616                         case $cf_attribute in #(vi
1617                         printf) #(vi
1618                                 if test "$cf_printf_attribute" = no ; then
1619                                         cat >>confdefs.h <<EOF
1620 #define GCC_PRINTFLIKE(fmt,var) /* nothing */
1621 EOF
1622                                 else
1623                                         cat >>confdefs.h <<EOF
1624 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1625 EOF
1626                                 fi
1627                                 ;;
1628                         scanf) #(vi
1629                                 if test "$cf_scanf_attribute" = no ; then
1630                                         cat >>confdefs.h <<EOF
1631 #define GCC_SCANFLIKE(fmt,var) /* nothing */
1632 EOF
1633                                 else
1634                                         cat >>confdefs.h <<EOF
1635 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1636 EOF
1637                                 fi
1638                                 ;;
1639                         esac
1640                 fi
1641         done
1642 else
1643         fgrep define conftest.i >>confdefs.h
1644 fi
1645 rm -rf conftest*
1646 fi
1647 ])dnl
1648 dnl ---------------------------------------------------------------------------
1649 dnl CF_GCC_VERSION version: 5 updated: 2010/04/24 11:02:31
1650 dnl --------------
1651 dnl Find version of gcc
1652 AC_DEFUN([CF_GCC_VERSION],[
1653 AC_REQUIRE([AC_PROG_CC])
1654 GCC_VERSION=none
1655 if test "$GCC" = yes ; then
1656         AC_MSG_CHECKING(version of $CC)
1657         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1658         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1659         AC_MSG_RESULT($GCC_VERSION)
1660 fi
1661 ])dnl
1662 dnl ---------------------------------------------------------------------------
1663 dnl CF_GCC_WARNINGS version: 27 updated: 2010/10/23 15:52:32
1664 dnl ---------------
1665 dnl Check if the compiler supports useful warning options.  There's a few that
1666 dnl we don't use, simply because they're too noisy:
1667 dnl
1668 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1669 dnl     -Wredundant-decls (system headers make this too noisy)
1670 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1671 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1672 dnl             is enabled for ncurses using "--enable-const".
1673 dnl     -pedantic
1674 dnl
1675 dnl Parameter:
1676 dnl     $1 is an optional list of gcc warning flags that a particular
1677 dnl             application might want to use, e.g., "no-unused" for
1678 dnl             -Wno-unused
1679 dnl Special:
1680 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1681 dnl
1682 AC_DEFUN([CF_GCC_WARNINGS],
1683 [
1684 AC_REQUIRE([CF_GCC_VERSION])
1685 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1686
1687 cat > conftest.$ac_ext <<EOF
1688 #line __oline__ "${as_me:-configure}"
1689 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1690 EOF
1691
1692 if test "$INTEL_COMPILER" = yes
1693 then
1694 # The "-wdXXX" options suppress warnings:
1695 # remark #1419: external declaration in primary source file
1696 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1697 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1698 # remark #193: zero used for undefined preprocessing identifier
1699 # remark #593: variable "curs_sb_left_arrow" was set but never used
1700 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1701 # remark #869: parameter "tw" was never referenced
1702 # remark #981: operands are evaluated in unspecified order
1703 # warning #279: controlling expression is constant
1704
1705         AC_CHECKING([for $CC warning options])
1706         cf_save_CFLAGS="$CFLAGS"
1707         EXTRA_CFLAGS="-Wall"
1708         for cf_opt in \
1709                 wd1419 \
1710                 wd1683 \
1711                 wd1684 \
1712                 wd193 \
1713                 wd593 \
1714                 wd279 \
1715                 wd810 \
1716                 wd869 \
1717                 wd981
1718         do
1719                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1720                 if AC_TRY_EVAL(ac_compile); then
1721                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1722                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1723                 fi
1724         done
1725         CFLAGS="$cf_save_CFLAGS"
1726
1727 elif test "$GCC" = yes
1728 then
1729         AC_CHECKING([for $CC warning options])
1730         cf_save_CFLAGS="$CFLAGS"
1731         EXTRA_CFLAGS=
1732         cf_warn_CONST=""
1733         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1734         for cf_opt in W Wall \
1735                 Wbad-function-cast \
1736                 Wcast-align \
1737                 Wcast-qual \
1738                 Winline \
1739                 Wmissing-declarations \
1740                 Wmissing-prototypes \
1741                 Wnested-externs \
1742                 Wpointer-arith \
1743                 Wshadow \
1744                 Wstrict-prototypes \
1745                 Wundef $cf_warn_CONST $1
1746         do
1747                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1748                 if AC_TRY_EVAL(ac_compile); then
1749                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1750                         case $cf_opt in #(vi
1751                         Wcast-qual) #(vi
1752                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1753                                 ;;
1754                         Winline) #(vi
1755                                 case $GCC_VERSION in
1756                                 [[34]].*)
1757                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1758                                         continue;;
1759                                 esac
1760                                 ;;
1761                         esac
1762                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1763                 fi
1764         done
1765         CFLAGS="$cf_save_CFLAGS"
1766 fi
1767 rm -rf conftest*
1768
1769 AC_SUBST(EXTRA_CFLAGS)
1770 ])dnl
1771 dnl ---------------------------------------------------------------------------
1772 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
1773 dnl --------------------
1774 dnl Check if the gnat pragma "Unreferenced" works.
1775 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
1776 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
1777 CF_GNAT_TRY_LINK([procedure conftest;],
1778 [with Text_IO;
1779 with GNAT.OS_Lib;
1780 procedure conftest is
1781    test : Integer;
1782    pragma Unreferenced (test);
1783 begin
1784    test := 1;
1785    Text_IO.Put ("Hello World");
1786    Text_IO.New_Line;
1787    GNAT.OS_Lib.OS_Exit (0);
1788 end conftest;],
1789         [cf_cv_pragma_unreferenced=yes],
1790         [cf_cv_pragma_unreferenced=no])])
1791
1792 # if the pragma is supported, use it (needed in the Trace code).
1793 if test $cf_cv_pragma_unreferenced = yes ; then
1794         PRAGMA_UNREF=TRUE
1795 else
1796         PRAGMA_UNREF=FALSE
1797 fi
1798 AC_SUBST(PRAGMA_UNREF)
1799 ])dnl
1800 dnl ---------------------------------------------------------------------------
1801 dnl CF_GNAT_TRY_LINK version: 2 updated: 2010/08/14 18:25:37
1802 dnl ----------------
1803 dnl Verify that a test program compiles/links with GNAT.
1804 dnl $cf_ada_make is set to the program that compiles/links
1805 dnl $ADAFLAGS may be set to the GNAT flags.
1806 dnl
1807 dnl $1 is the text of the spec
1808 dnl $2 is the text of the body
1809 dnl $3 is the shell command to execute if successful
1810 dnl $4 is the shell command to execute if not successful
1811 AC_DEFUN([CF_GNAT_TRY_LINK],
1812 [
1813 rm -rf conftest*
1814 cat >>conftest.ads <<CF_EOF
1815 $1
1816 CF_EOF
1817 cat >>conftest.adb <<CF_EOF
1818 $2
1819 CF_EOF
1820 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1821 ifelse($3,,      :,[      $3])
1822 ifelse($4,,,[else
1823    $4])
1824 fi
1825 rm -rf conftest*
1826 ])dnl
1827 dnl ---------------------------------------------------------------------------
1828 dnl CF_GNAT_TRY_RUN version: 4 updated: 2010/08/14 18:25:37
1829 dnl ---------------
1830 dnl Verify that a test program compiles and runs with GNAT
1831 dnl $cf_ada_make is set to the program that compiles/links
1832 dnl $ADAFLAGS may be set to the GNAT flags.
1833 dnl
1834 dnl $1 is the text of the spec
1835 dnl $2 is the text of the body
1836 dnl $3 is the shell command to execute if successful
1837 dnl $4 is the shell command to execute if not successful
1838 AC_DEFUN([CF_GNAT_TRY_RUN],
1839 [
1840 rm -rf conftest*
1841 cat >>conftest.ads <<CF_EOF
1842 $1
1843 CF_EOF
1844 cat >>conftest.adb <<CF_EOF
1845 $2
1846 CF_EOF
1847 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1848    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1849 ifelse($3,,      :,[      $3])
1850 ifelse($4,,,[   else
1851       $4])
1852    fi
1853 ifelse($4,,,[else
1854    $4])
1855 fi
1856 rm -rf conftest*
1857 ])dnl
1858 dnl ---------------------------------------------------------------------------
1859 dnl CF_GNAT_VERSION version: 15 updated: 2010/10/23 15:52:32
1860 dnl ---------------
1861 dnl Verify version of GNAT.
1862 AC_DEFUN([CF_GNAT_VERSION],
1863 [
1864 AC_MSG_CHECKING(for gnat version)
1865 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | grep '[[0-9]].[[0-9]][[0-9]]*' |\
1866   sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1867 AC_MSG_RESULT($cf_gnat_version)
1868
1869 case $cf_gnat_version in
1870   3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*)
1871     cf_cv_prog_gnat_correct=yes
1872     ;;
1873   *) echo Unsupported GNAT version $cf_gnat_version. Required is 3.11 or better. Disabling Ada95 binding.
1874      cf_cv_prog_gnat_correct=no
1875      ;;
1876 esac
1877
1878 case $cf_gnat_version in
1879   3.[[1-9]]*|[[4-9]].*)
1880       cf_compile_generics=generics
1881       cf_generic_objects="\${GENOBJS}"
1882       ;;
1883   *)  cf_compile_generics=
1884       cf_generic_objects=
1885       ;;
1886 esac
1887
1888 case $cf_gnat_version in
1889   3.[[0-9]]*)
1890     USE_OLD_MAKERULES=""
1891     USE_GNAT_PROJECTS="#"
1892     ;;
1893   *)
1894     USE_OLD_MAKERULES="#"
1895     USE_GNAT_PROJECTS=""
1896     ;;
1897 esac
1898
1899 AC_SUBST(cf_compile_generics)
1900 AC_SUBST(cf_generic_objects)
1901
1902 AC_SUBST(USE_OLD_MAKERULES)
1903 AC_SUBST(USE_GNAT_PROJECTS)
1904 ])
1905 dnl ---------------------------------------------------------------------------
1906 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
1907 dnl -------------
1908 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1909 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1910 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1911 dnl since it is interwoven with GNU extensions.
1912 dnl
1913 dnl Well, yes we could work around it...
1914 AC_DEFUN([CF_GNU_SOURCE],
1915 [
1916 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1917 AC_TRY_COMPILE([#include <sys/types.h>],[
1918 #ifndef _XOPEN_SOURCE
1919 make an error
1920 #endif],
1921         [cf_cv_gnu_source=no],
1922         [cf_save="$CPPFLAGS"
1923          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1924          AC_TRY_COMPILE([#include <sys/types.h>],[
1925 #ifdef _XOPEN_SOURCE
1926 make an error
1927 #endif],
1928         [cf_cv_gnu_source=no],
1929         [cf_cv_gnu_source=yes])
1930         CPPFLAGS="$cf_save"
1931         ])
1932 ])
1933 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1934 ])dnl
1935 dnl ---------------------------------------------------------------------------
1936 dnl CF_GPP_LIBRARY version: 10 updated: 2010/05/29 16:31:02
1937 dnl --------------
1938 dnl If we're trying to use g++, test if libg++ is installed (a rather common
1939 dnl problem :-).  If we have the compiler but no library, we'll be able to
1940 dnl configure, but won't be able to build the c++ demo program.
1941 AC_DEFUN([CF_GPP_LIBRARY],
1942 [
1943 cf_cxx_library=unknown
1944 case $cf_cv_system_name in #(vi
1945 os2*) #(vi
1946         cf_gpp_libname=gpp
1947         ;;
1948 *)
1949         cf_gpp_libname=g++
1950         ;;
1951 esac
1952 if test "$GXX" = yes; then
1953         AC_MSG_CHECKING([for lib$cf_gpp_libname])
1954         cf_save="$LIBS"
1955         CF_ADD_LIB($cf_gpp_libname)
1956         AC_TRY_LINK([
1957 #include <$cf_gpp_libname/builtin.h>
1958         ],
1959         [two_arg_error_handler_t foo2 = lib_error_handler],
1960         [cf_cxx_library=yes
1961          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
1962          if test "$cf_gpp_libname" = cpp ; then
1963             AC_DEFINE(HAVE_GPP_BUILTIN_H)
1964          else
1965             AC_DEFINE(HAVE_GXX_BUILTIN_H)
1966          fi],
1967         [AC_TRY_LINK([
1968 #include <builtin.h>
1969         ],
1970         [two_arg_error_handler_t foo2 = lib_error_handler],
1971         [cf_cxx_library=yes
1972          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
1973          AC_DEFINE(HAVE_BUILTIN_H)],
1974         [cf_cxx_library=no])])
1975         LIBS="$cf_save"
1976         AC_MSG_RESULT($cf_cxx_library)
1977 fi
1978 ])dnl
1979 dnl ---------------------------------------------------------------------------
1980 dnl CF_GXX_VERSION version: 6 updated: 2010/10/23 15:44:18
1981 dnl --------------
1982 dnl Check for version of g++
1983 AC_DEFUN([CF_GXX_VERSION],[
1984 AC_REQUIRE([AC_PROG_CPP])
1985 GXX_VERSION=none
1986 if test "$GXX" = yes; then
1987         AC_MSG_CHECKING(version of g++)
1988         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1989         test -z "$GXX_VERSION" && GXX_VERSION=unknown
1990         AC_MSG_RESULT($GXX_VERSION)
1991 fi
1992 ])dnl
1993 dnl ---------------------------------------------------------------------------
1994 dnl CF_GXX_WARNINGS version: 6 updated: 2010/08/14 18:25:37
1995 dnl ---------------
1996 dnl Check if the compiler supports useful warning options.
1997 dnl
1998 dnl Most of gcc's options apply to g++, except:
1999 dnl     -Wbad-function-cast
2000 dnl     -Wmissing-declarations
2001 dnl     -Wnested-externs
2002 dnl
2003 dnl Omit a few (for now):
2004 dnl     -Winline
2005 dnl
2006 dnl Parameter:
2007 dnl     $1 is an optional list of g++ warning flags that a particular
2008 dnl             application might want to use, e.g., "no-unused" for
2009 dnl             -Wno-unused
2010 dnl Special:
2011 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2012 dnl
2013 AC_DEFUN([CF_GXX_WARNINGS],
2014 [
2015
2016 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2017
2018 AC_REQUIRE([CF_GXX_VERSION])
2019
2020 AC_LANG_SAVE
2021 AC_LANG_CPLUSPLUS
2022
2023 cat > conftest.$ac_ext <<EOF
2024 #line __oline__ "configure"
2025 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2026 EOF
2027
2028 if test "$INTEL_CPLUSPLUS" = yes
2029 then
2030 # The "-wdXXX" options suppress warnings:
2031 # remark #1419: external declaration in primary source file
2032 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2033 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2034 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2035 # remark #193: zero used for undefined preprocessing identifier
2036 # remark #593: variable "curs_sb_left_arrow" was set but never used
2037 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2038 # remark #869: parameter "tw" was never referenced
2039 # remark #981: operands are evaluated in unspecified order
2040 # warning #269: invalid format string conversion
2041
2042         AC_CHECKING([for $CC warning options])
2043         cf_save_CXXFLAGS="$CXXFLAGS"
2044         EXTRA_CXXFLAGS="-Wall"
2045         for cf_opt in \
2046                 wd1419 \
2047                 wd1682 \
2048                 wd1683 \
2049                 wd1684 \
2050                 wd193 \
2051                 wd279 \
2052                 wd593 \
2053                 wd810 \
2054                 wd869 \
2055                 wd981
2056         do
2057                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2058                 if AC_TRY_EVAL(ac_compile); then
2059                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2060                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2061                 fi
2062         done
2063         CXXFLAGS="$cf_save_CXXFLAGS"
2064
2065 elif test "$GXX" = yes
2066 then
2067         AC_CHECKING([for $CXX warning options])
2068         cf_save_CXXFLAGS="$CXXFLAGS"
2069         EXTRA_CXXFLAGS="-W -Wall"
2070         cf_gxx_extra_warnings=""
2071         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2072         case "$GCC_VERSION" in
2073         [[1-2]].*)
2074                 ;;
2075         *)
2076                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2077                 ;;
2078         esac
2079         for cf_opt in \
2080                 Wabi \
2081                 fabi-version=0 \
2082                 Woverloaded-virtual \
2083                 Wsign-promo \
2084                 Wsynth \
2085                 Wold-style-cast \
2086                 Wcast-align \
2087                 Wcast-qual \
2088                 Wmissing-prototypes \
2089                 Wpointer-arith \
2090                 Wshadow \
2091                 Wstrict-prototypes \
2092                 Wundef $cf_gxx_extra_warnings $1
2093         do
2094                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2095                 if AC_TRY_EVAL(ac_compile); then
2096                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2097                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2098                 else
2099                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2100                 fi
2101         done
2102         CXXFLAGS="$cf_save_CXXFLAGS"
2103 fi
2104
2105 rm -rf conftest*
2106 AC_LANG_RESTORE
2107 AC_SUBST(EXTRA_CXXFLAGS)
2108 ])dnl
2109 dnl ---------------------------------------------------------------------------
2110 dnl CF_HASHED_DB version: 4 updated: 2010/05/29 16:31:02
2111 dnl ------------
2112 dnl Look for an instance of the Berkeley hashed database.
2113 dnl
2114 dnl $1 = optional parameter, to specify install-prefix for the database.
2115 AC_DEFUN([CF_HASHED_DB],
2116 [
2117 ifelse([$1],,,[
2118 case $1 in #(vi
2119 yes|*able*) #(vi
2120     ;;
2121 *)
2122     if test -d "$1" ; then
2123         CF_ADD_INCDIR($1/include)
2124         CF_ADD_LIBDIR($1/lib)
2125     fi
2126 esac
2127 ])
2128 AC_CHECK_HEADER(db.h,[
2129 CF_HASHED_DB_VERSION
2130 if test "$cf_cv_hashed_db_version" = unknown ; then
2131         AC_MSG_ERROR(Cannot determine version of db)
2132 else
2133         CF_HASHED_DB_LIBS
2134         if test "$cf_cv_hashed_db_libs" = unknown ; then
2135                 AC_MSG_ERROR(Cannot determine library for db)
2136         elif test "$cf_cv_hashed_db_libs" != default ; then
2137                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2138         fi
2139 fi
2140 ],[
2141         AC_MSG_ERROR(Cannot find db.h)
2142 ])
2143 ])dnl
2144 dnl ---------------------------------------------------------------------------
2145 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2146 dnl -----------------
2147 dnl Given that we have the header and version for hashed database, find the
2148 dnl library information.
2149 AC_DEFUN([CF_HASHED_DB_LIBS],
2150 [
2151 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2152 cf_cv_hashed_db_libs=unknown
2153 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2154 do
2155         cf_save_libs="$LIBS"
2156         if test -n "$cf_db_libs"; then
2157                 CF_ADD_LIB($cf_db_libs)
2158         fi
2159         CF_MSG_LOG(checking for library "$cf_db_libs")
2160         AC_TRY_LINK([
2161 $ac_includes_default
2162 #include <db.h>
2163 ],[
2164         char *path = "/tmp/foo";
2165 #ifdef DB_VERSION_MAJOR
2166 #if DB_VERSION_MAJOR >= 4
2167         DB *result = 0;
2168         db_create(&result, NULL, 0);
2169         result->open(result,
2170                 NULL,
2171                 path,
2172                 path,
2173                 DB_HASH,
2174                 DB_CREATE,
2175                 0644);
2176 #elif DB_VERSION_MAJOR >= 3
2177         DB *result = 0;
2178         db_create(&result, NULL, 0);
2179         result->open(result,
2180                 path,
2181                 path,
2182                 DB_HASH,
2183                 DB_CREATE,
2184                 0644);
2185 #elif DB_VERSION_MAJOR >= 2
2186         DB *result = 0;
2187         db_open(path,
2188                 DB_HASH,
2189                 DB_CREATE,
2190                 0644,
2191                 (DB_ENV *) 0,
2192                 (DB_INFO *) 0,
2193                 &result);
2194 #endif /* DB_VERSION_MAJOR */
2195 #else
2196         DB *result = dbopen(path,
2197                      2,
2198                      0644,
2199                      DB_HASH,
2200                      0);
2201 #endif
2202         ${cf_cv_main_return:-return}(result != 0)
2203 ],[
2204         if test -n "$cf_db_libs" ; then
2205                 cf_cv_hashed_db_libs=$cf_db_libs
2206         else
2207                 cf_cv_hashed_db_libs=default
2208         fi
2209         LIBS="$cf_save_libs"
2210         break
2211 ])
2212         LIBS="$cf_save_libs"
2213 done
2214 ])
2215 ])dnl
2216 dnl ---------------------------------------------------------------------------
2217 dnl CF_HASHED_DB_VERSION version: 3 updated: 2007/12/01 15:01:37
2218 dnl --------------------
2219 dnl Given that we have the header file for hashed database, find the version
2220 dnl information.
2221 AC_DEFUN([CF_HASHED_DB_VERSION],
2222 [
2223 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2224 cf_cv_hashed_db_version=unknown
2225
2226 for cf_db_version in 1 2 3 4 5
2227 do
2228         CF_MSG_LOG(checking for db version $cf_db_version)
2229         AC_TRY_COMPILE([
2230 $ac_includes_default
2231 #include <db.h>
2232
2233 #ifdef DB_VERSION_MAJOR
2234         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2235 #if $cf_db_version == DB_VERSION_MAJOR
2236         /* ok */
2237 #else
2238         make an error
2239 #endif
2240 #else
2241 #if $cf_db_version == 1
2242         /* ok: assuming this is DB 1.8.5 */
2243 #else
2244         make an error
2245 #endif
2246 #endif
2247 ],[DBT *foo = 0],[
2248         cf_cv_hashed_db_version=$cf_db_version
2249         break
2250         ])
2251 done
2252 ])
2253 ])dnl
2254 dnl ---------------------------------------------------------------------------
2255 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2256 dnl --------------
2257 dnl Construct a search-list of directories for a nonstandard header-file
2258 dnl
2259 dnl Parameters
2260 dnl     $1 = the variable to return as result
2261 dnl     $2 = the package name
2262 AC_DEFUN([CF_HEADER_PATH],
2263 [
2264 $1=
2265
2266 # collect the current set of include-directories from compiler flags
2267 cf_header_path_list=""
2268 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2269         for cf_header_path in $CPPFLAGS $CFLAGS
2270         do
2271                 case $cf_header_path in #(vi
2272                 -I*)
2273                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2274                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2275                         cf_header_path_list="$cf_header_path_list [$]$1"
2276                         ;;
2277                 esac
2278         done
2279 fi
2280
2281 # add the variations for the package we are looking for
2282 CF_SUBDIR_PATH($1,$2,include)
2283
2284 test "$includedir" != NONE && \
2285 test "$includedir" != "/usr/include" && \
2286 test -d "$includedir" && {
2287         test -d $includedir &&    $1="[$]$1 $includedir"
2288         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2289 }
2290
2291 test "$oldincludedir" != NONE && \
2292 test "$oldincludedir" != "/usr/include" && \
2293 test -d "$oldincludedir" && {
2294         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2295         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2296 }
2297
2298 $1="[$]$1 $cf_header_path_list"
2299 ])dnl
2300 dnl ---------------------------------------------------------------------------
2301 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2302 dnl ---------------
2303 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2304 AC_DEFUN([CF_HELP_MESSAGE],
2305 [AC_DIVERT_HELP([$1])dnl
2306 ])dnl
2307 dnl ---------------------------------------------------------------------------
2308 dnl CF_INCLUDE_DIRS version: 6 updated: 2009/01/06 19:37:40
2309 dnl ---------------
2310 dnl Construct the list of include-options according to whether we're building
2311 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2312 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2313 dnl since that usually breaks gcc's shadow-includes.
2314 AC_DEFUN([CF_INCLUDE_DIRS],
2315 [
2316 CPPFLAGS="$CPPFLAGS -I. -I../include"
2317 if test "$srcdir" != "."; then
2318         CPPFLAGS="$CPPFLAGS -I\${srcdir}/../include"
2319 fi
2320 if test "$GCC" != yes; then
2321         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2322 elif test "$includedir" != "/usr/include"; then
2323         if test "$includedir" = '${prefix}/include' ; then
2324                 if test $prefix != /usr ; then
2325                         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2326                 fi
2327         else
2328                 CPPFLAGS="$CPPFLAGS -I\${includedir}"
2329         fi
2330 fi
2331 AC_SUBST(CPPFLAGS)
2332 ])dnl
2333 dnl ---------------------------------------------------------------------------
2334 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
2335 dnl -----------------
2336 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2337 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2338 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2339 dnl
2340 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2341 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2342 dnl the wrappers for gcc and g++ warnings.
2343 dnl
2344 dnl $1 = GCC (default) or GXX
2345 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2346 dnl $3 = CFLAGS (default) or CXXFLAGS
2347 AC_DEFUN([CF_INTEL_COMPILER],[
2348 ifelse([$2],,INTEL_COMPILER,[$2])=no
2349
2350 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2351         case $host_os in
2352         linux*|gnu*)
2353                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2354                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2355                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2356                 AC_TRY_COMPILE([],[
2357 #ifdef __INTEL_COMPILER
2358 #else
2359 make an error
2360 #endif
2361 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2362 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
2363 ],[])
2364                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2365                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2366                 ;;
2367         esac
2368 fi
2369 ])dnl
2370 dnl ---------------------------------------------------------------------------
2371 dnl CF_ISASCII version: 3 updated: 2000/08/12 23:18:52
2372 dnl ----------
2373 dnl Check if we have either a function or macro for 'isascii()'.
2374 AC_DEFUN([CF_ISASCII],
2375 [
2376 AC_MSG_CHECKING(for isascii)
2377 AC_CACHE_VAL(cf_cv_have_isascii,[
2378         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2379         [cf_cv_have_isascii=yes],
2380         [cf_cv_have_isascii=no])
2381 ])dnl
2382 AC_MSG_RESULT($cf_cv_have_isascii)
2383 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII)
2384 ])dnl
2385 dnl ---------------------------------------------------------------------------
2386 dnl CF_LARGEFILE version: 7 updated: 2007/06/02 11:58:50
2387 dnl ------------
2388 dnl Add checks for large file support.
2389 AC_DEFUN([CF_LARGEFILE],[
2390 ifdef([AC_FUNC_FSEEKO],[
2391     AC_SYS_LARGEFILE
2392     if test "$enable_largefile" != no ; then
2393         AC_FUNC_FSEEKO
2394
2395         # Normally we would collect these definitions in the config.h,
2396         # but (like _XOPEN_SOURCE), some environments rely on having these
2397         # defined before any of the system headers are included.  Another
2398         # case comes up with C++, e.g., on AIX the compiler compiles the
2399         # header files by themselves before looking at the body files it is
2400         # told to compile.  For ncurses, those header files do not include
2401         # the config.h
2402         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2403         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2404         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2405
2406         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2407                 AC_TRY_COMPILE([
2408 #include <sys/types.h>
2409 #include <dirent.h>
2410                 ],[
2411                 /* if transitional largefile support is setup, this is true */
2412                 extern struct dirent64 * readdir(DIR *);
2413                 struct dirent64 *x = readdir((DIR *)0);
2414                 struct dirent *y = readdir((DIR *)0);
2415                 int z = x - y;
2416                 ],
2417                 [cf_cv_struct_dirent64=yes],
2418                 [cf_cv_struct_dirent64=no])
2419         ])
2420         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64)
2421     fi
2422 ])
2423 ])
2424 dnl ---------------------------------------------------------------------------
2425 dnl CF_LDFLAGS_STATIC version: 8 updated: 2010/10/23 14:39:56
2426 dnl -----------------
2427 dnl Check for compiler/linker flags used to temporarily force usage of static
2428 dnl libraries.  This depends on the compiler and platform.  Use this to help
2429 dnl ensure that the linker picks up a given library based on its position in
2430 dnl the list of linker options and libraries.
2431 AC_DEFUN([CF_LDFLAGS_STATIC],[
2432
2433 if test "$GCC" = yes ; then
2434         case $cf_cv_system_name in #(
2435         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2436                 LDFLAGS_STATIC=
2437                 LDFLAGS_SHARED=
2438                 ;;
2439     *)  #( normally, except when broken
2440         LDFLAGS_STATIC=-static
2441         LDFLAGS_SHARED=-dynamic
2442         ;;
2443     esac
2444 else
2445         case $cf_cv_system_name in #(
2446         aix[[456]]*)    #( from ld manpage
2447                 LDFLAGS_STATIC=-bstatic
2448                 LDFLAGS_SHARED=-bdynamic
2449                 ;;
2450         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2451                 # We could also use just "archive" and "shared".
2452                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2453                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2454                 ;;
2455         irix*)          #( from ld manpage IRIX64
2456                 LDFLAGS_STATIC=-Bstatic
2457                 LDFLAGS_SHARED=-Bdynamic
2458                 ;;
2459         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2460                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2461                 LDFLAGS_STATIC=-noso
2462                 LDFLAGS_SHARED=-so_archive
2463                 ;;
2464         solaris2*)
2465                 LDFLAGS_STATIC=-Bstatic
2466                 LDFLAGS_SHARED=-Bdynamic
2467                 ;;
2468         esac
2469 fi
2470
2471 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
2472 then
2473         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
2474
2475         rm -f libconftest.a
2476         cat >conftest.$ac_ext <<EOF
2477 #line __oline__ "configure"
2478 #include <stdio.h>
2479 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
2480 EOF
2481         if AC_TRY_EVAL(ac_compile) ; then
2482                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
2483                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
2484         fi
2485         rm -f conftest.*
2486
2487         cf_save_LIBS="$LIBS"
2488
2489         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
2490         AC_TRY_LINK([
2491 #line __oline__ "configure"
2492 #include <stdio.h>
2493 int cf_ldflags_static(FILE *fp);
2494 ],[
2495         return cf_ldflags_static(stdin);
2496 ],[cf_ldflags_static=yes],[cf_ldflags_static=no])
2497
2498         rm -f libconftest.*
2499         LIBS="$cf_save_LIBS"
2500
2501         AC_MSG_RESULT($cf_ldflags_static)
2502
2503         if test $cf_ldflags_static != yes
2504         then
2505                 LDFLAGS_STATIC=
2506                 LDFLAGS_SHARED=
2507         fi
2508 else
2509         LDFLAGS_STATIC=
2510         LDFLAGS_SHARED=
2511 fi
2512
2513 AC_SUBST(LDFLAGS_STATIC)
2514 AC_SUBST(LDFLAGS_SHARED)
2515 ])
2516 dnl ---------------------------------------------------------------------------
2517 dnl CF_LD_RPATH_OPT version: 3 updated: 2010/06/02 05:03:05
2518 dnl ---------------
2519 dnl For the given system and compiler, find the compiler flags to pass to the
2520 dnl loader to use the "rpath" feature.
2521 AC_DEFUN([CF_LD_RPATH_OPT],
2522 [
2523 AC_REQUIRE([CF_CHECK_CACHE])
2524
2525 LD_RPATH_OPT=
2526 AC_MSG_CHECKING(for an rpath option)
2527 case $cf_cv_system_name in #(vi
2528 irix*) #(vi
2529         if test "$GCC" = yes; then
2530                 LD_RPATH_OPT="-Wl,-rpath,"
2531         else
2532                 LD_RPATH_OPT="-rpath "
2533         fi
2534         ;;
2535 linux*|gnu*|k*bsd*-gnu) #(vi
2536         LD_RPATH_OPT="-Wl,-rpath,"
2537         ;;
2538 openbsd[[2-9]].*) #(vi
2539         LD_RPATH_OPT="-Wl,-rpath,"
2540         ;;
2541 freebsd*) #(vi
2542         LD_RPATH_OPT="-rpath "
2543         ;;
2544 netbsd*) #(vi
2545         LD_RPATH_OPT="-Wl,-rpath,"
2546         ;;
2547 osf*|mls+*) #(vi
2548         LD_RPATH_OPT="-rpath "
2549         ;;
2550 solaris2*) #(vi
2551         LD_RPATH_OPT="-R"
2552         ;;
2553 *)
2554         ;;
2555 esac
2556 AC_MSG_RESULT($LD_RPATH_OPT)
2557
2558 case "x$LD_RPATH_OPT" in #(vi
2559 x-R*)
2560         AC_MSG_CHECKING(if we need a space after rpath option)
2561         cf_save_LIBS="$LIBS"
2562         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2563         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2564         LIBS="$cf_save_LIBS"
2565         AC_MSG_RESULT($cf_rpath_space)
2566         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2567         ;;
2568 esac
2569 ])dnl
2570 dnl ---------------------------------------------------------------------------
2571 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
2572 dnl ---------------
2573 dnl Construct a search-list of directories for a nonstandard library-file
2574 dnl
2575 dnl Parameters
2576 dnl     $1 = the variable to return as result
2577 dnl     $2 = the package name
2578 AC_DEFUN([CF_LIBRARY_PATH],
2579 [
2580 $1=
2581 cf_library_path_list=""
2582 if test -n "${LDFLAGS}${LIBS}" ; then
2583         for cf_library_path in $LDFLAGS $LIBS
2584         do
2585                 case $cf_library_path in #(vi
2586                 -L*)
2587                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2588                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2589                         cf_library_path_list="$cf_library_path_list [$]$1"
2590                         ;;
2591                 esac
2592         done
2593 fi
2594
2595 CF_SUBDIR_PATH($1,$2,lib)
2596
2597 $1="$cf_library_path_list [$]$1"
2598 ])dnl
2599 dnl ---------------------------------------------------------------------------
2600 dnl CF_LIB_PREFIX version: 8 updated: 2008/09/13 11:34:16
2601 dnl -------------
2602 dnl Compute the library-prefix for the given host system
2603 dnl $1 = variable to set
2604 AC_DEFUN([CF_LIB_PREFIX],
2605 [
2606         case $cf_cv_system_name in #(vi
2607         OS/2*|os2*) #(vi
2608         LIB_PREFIX=''
2609         ;;
2610         *)      LIB_PREFIX='lib'
2611         ;;
2612         esac
2613 ifelse($1,,,[$1=$LIB_PREFIX])
2614         AC_SUBST(LIB_PREFIX)
2615 ])dnl
2616 dnl ---------------------------------------------------------------------------
2617 dnl CF_LIB_RULES version: 61 updated: 2010/10/23 16:10:30
2618 dnl ------------
2619 dnl Append definitions and rules for the given models to the subdirectory
2620 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
2621 dnl subdirectory is a library-source directory, modify the LIBS_TO_MAKE list in
2622 dnl the corresponding makefile to list the models that we'll generate.
2623 dnl
2624 dnl For shared libraries, make a list of symbolic links to construct when
2625 dnl generating each library.  The convention used for Linux is the simplest
2626 dnl one:
2627 dnl     lib<name>.so    ->
2628 dnl     lib<name>.so.<major>    ->
2629 dnl     lib<name>.so.<maj>.<minor>
2630 AC_DEFUN([CF_LIB_RULES],
2631 [
2632 CF_LIB_PREFIX(cf_prefix)
2633 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
2634
2635 if test $cf_cv_shlib_version = cygdll ; then
2636         TINFO_NAME=$TINFO_ARG_SUFFIX
2637         TINFO_SUFFIX=.dll
2638 fi
2639
2640 if test -n "$TINFO_SUFFIX" ; then
2641         case $TINFO_SUFFIX in
2642         tw*)
2643                 TINFO_NAME="${TINFO_NAME}tw"
2644                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
2645                 ;;
2646         t*)
2647                 TINFO_NAME="${TINFO_NAME}t"
2648                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
2649                 ;;
2650         w*)
2651                 TINFO_NAME="${TINFO_NAME}w"
2652                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
2653                 ;;
2654         esac
2655 fi
2656
2657 for cf_dir in $SRC_SUBDIRS
2658 do
2659         if test ! -d $srcdir/$cf_dir ; then
2660                 continue
2661         elif test -f $srcdir/$cf_dir/modules; then
2662
2663                 SHARED_LIB=
2664                 LIBS_TO_MAKE=
2665                 for cf_item in $cf_LIST_MODELS
2666                 do
2667                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
2668                         if test $cf_item = shared ; then
2669                         if test "$cf_cv_do_symlinks" = yes ; then
2670                                 case "$cf_cv_shlib_version" in #(vi
2671                                 rel) #(vi
2672                                         case "$cf_cv_system_name" in #(vi
2673                                         darwin*)
2674                                         case .${LIB_SUFFIX} in
2675                                         .tw*)
2676                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
2677                                                 cf_suffix=tw'.${REL_VERSION}'"$cf_suffix"
2678                                                 ;;
2679                                         .t*)
2680                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
2681                                                 cf_suffix=t'.${REL_VERSION}'"$cf_suffix"
2682                                                 ;;
2683                                         .w*)
2684                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
2685                                                 cf_suffix=w'.${REL_VERSION}'"$cf_suffix"
2686                                                 ;;
2687                                         *)
2688                                                 cf_suffix='.${REL_VERSION}'"$cf_suffix"
2689                                                 ;;
2690                                         esac
2691                                         ;; #(vi
2692                                         *) cf_suffix="$cf_suffix"'.${REL_VERSION}' ;;
2693                                         esac
2694                                         ;;
2695                                 abi)
2696                                         case "$cf_cv_system_name" in #(vi
2697                                         darwin*)
2698                                         case .${LIB_SUFFIX} in
2699                                         .tw*)
2700                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
2701                                                 cf_suffix=tw'.${ABI_VERSION}'"$cf_suffix"
2702                                                 ;;
2703                                         .t*)
2704                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
2705                                                 cf_suffix=t'.${ABI_VERSION}'"$cf_suffix"
2706                                                 ;;
2707                                         .w*)
2708                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
2709                                                 cf_suffix=w'.${ABI_VERSION}'"$cf_suffix"
2710                                                 ;;
2711                                         *)
2712                                                 cf_suffix='.${ABI_VERSION}'"$cf_suffix"
2713                                                 ;;
2714                                         esac
2715                                         ;; #(vi
2716                                         *) cf_suffix="$cf_suffix"'.${ABI_VERSION}' ;;
2717                                         esac
2718                                         ;;
2719                                 esac
2720                         fi
2721                         # cygwin needs import library, and has unique naming convention
2722                         # use autodetected ${cf_prefix} for import lib and static lib, but
2723                         # use 'cyg' prefix for shared lib.
2724                         if test $cf_cv_shlib_version = cygdll ; then
2725                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
2726                                 LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/cyg${cf_dir}${cf_cygsuf}"
2727                                 continue
2728                         fi
2729                         fi
2730                         LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/${cf_prefix}${cf_dir}${cf_suffix}"
2731                 done
2732
2733                 if test $cf_dir = ncurses ; then
2734                         cf_subsets="$LIB_SUBSETS"
2735                         cf_r_parts="$cf_subsets"
2736                         cf_liblist="$LIBS_TO_MAKE"
2737
2738                         while test -n "$cf_r_parts"
2739                         do
2740                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
2741                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
2742                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
2743                                         cf_item=
2744                                         case $cf_l_parts in #(vi
2745                                         *termlib*) #(vi
2746                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
2747                                                 ;;
2748                                         *ticlib*)
2749                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
2750                                                 ;;
2751                                         *)
2752                                                 break
2753                                                 ;;
2754                                         esac
2755                                         if test -n "$cf_item"; then
2756                                                 LIBS_TO_MAKE="$cf_item $LIBS_TO_MAKE"
2757                                         fi
2758                                 else
2759                                         break
2760                                 fi
2761                         done
2762                 else
2763                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
2764                 fi
2765
2766                 sed -e "s%@LIBS_TO_MAKE@%$LIBS_TO_MAKE%" \
2767                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
2768                         $cf_dir/Makefile >$cf_dir/Makefile.out
2769                 mv $cf_dir/Makefile.out $cf_dir/Makefile
2770
2771                 $AWK -f $srcdir/mk-0th.awk \
2772                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" \
2773                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
2774
2775                 for cf_subset in $cf_subsets
2776                 do
2777                         cf_subdirs=
2778                         for cf_item in $cf_LIST_MODELS
2779                         do
2780                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
2781                         CF_UPPER(cf_ITEM,$cf_item)
2782                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
2783                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
2784
2785                         # Test for case where we build libtinfo with a different name.
2786                         cf_libname=$cf_dir
2787                         if test $cf_dir = ncurses ; then
2788                                 case $cf_subset in
2789                                 *base*)
2790                                         cf_libname=${cf_libname}$LIB_SUFFIX
2791                                         ;;
2792                                 *termlib*)
2793                                         cf_libname=$TINFO_LIB_SUFFIX
2794                                         ;;
2795                                 ticlib*)
2796                                         cf_libname=$TICS_LIB_SUFFIX
2797                                         ;;
2798                                 esac
2799                         else
2800                                 cf_libname=${cf_libname}$LIB_SUFFIX
2801                         fi
2802                         if test -n "${DFT_ARG_SUFFIX}" ; then
2803                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
2804                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
2805                         fi
2806
2807                         # These dependencies really are for development, not
2808                         # builds, but they are useful in porting, too.
2809                         cf_depend="../include/ncurses_cfg.h"
2810                         if test "$srcdir" = "."; then
2811                                 cf_reldir="."
2812                         else
2813                                 cf_reldir="\${srcdir}"
2814                         fi
2815
2816                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
2817                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
2818                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
2819                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
2820                         fi
2821
2822                         cf_dir_suffix=
2823                         old_cf_suffix="$cf_suffix"
2824                         if test "$cf_cv_shlib_version_infix" = yes ; then
2825                         if test -n "$LIB_SUFFIX" ; then
2826                                 case $LIB_SUFFIX in
2827                                 tw*)
2828                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
2829                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
2830                                         cf_dir_suffix=tw
2831                                         ;;
2832                                 t*)
2833                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
2834                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
2835                                         cf_dir_suffix=t
2836                                         ;;
2837                                 w*)
2838                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
2839                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
2840                                         cf_dir_suffix=w
2841                                         ;;
2842                                 esac
2843                         fi
2844                         fi
2845
2846                         $AWK -f $srcdir/mk-1st.awk \
2847                                 name=${cf_libname}${cf_dir_suffix} \
2848                                 traces=$LIB_TRACING \
2849                                 MODEL=$cf_ITEM \
2850                                 model=$cf_subdir \
2851                                 prefix=$cf_prefix \
2852                                 suffix=$cf_suffix \
2853                                 subset=$cf_subset \
2854                                 SymLink="$LN_S" \
2855                                 TermlibRoot=$TINFO_NAME \
2856                                 TermlibSuffix=$TINFO_SUFFIX \
2857                                 ShlibVer=$cf_cv_shlib_version \
2858                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
2859                                 ReLink=${cf_cv_do_relink:-no} \
2860                                 DoLinks=$cf_cv_do_symlinks \
2861                                 rmSoLocs=$cf_cv_rm_so_locs \
2862                                 ldconfig="$LDCONFIG" \
2863                                 overwrite=$WITH_OVERWRITE \
2864                                 depend="$cf_depend" \
2865                                 host="$host" \
2866                                 libtool_version="$LIBTOOL_VERSION" \
2867                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
2868
2869                         cf_suffix="$old_cf_suffix"
2870
2871                         for cf_subdir2 in $cf_subdirs lib
2872                         do
2873                                 test $cf_subdir = $cf_subdir2 && break
2874                         done
2875                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
2876                         $AWK -f $srcdir/mk-2nd.awk \
2877                                 name=$cf_dir \
2878                                 traces=$LIB_TRACING \
2879                                 MODEL=$cf_ITEM \
2880                                 model=$cf_subdir \
2881                                 subset=$cf_subset \
2882                                 srcdir=$srcdir \
2883                                 echo=$WITH_ECHO \
2884                                 crenames=$cf_cv_prog_CC_c_o \
2885                                 cxxrenames=$cf_cv_prog_CXX_c_o \
2886                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
2887                         cf_subdirs="$cf_subdirs $cf_subdir"
2888                         done
2889                 done
2890         fi
2891
2892         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >>Makefile
2893 done
2894
2895 for cf_dir in $SRC_SUBDIRS
2896 do
2897         if test ! -d $srcdir/$cf_dir ; then
2898                 continue
2899         fi
2900
2901         if test -f $cf_dir/Makefile ; then
2902                 case "$cf_dir" in
2903                 Ada95) #(vi
2904                         echo 'libs \' >> Makefile
2905                         echo 'install.libs \' >> Makefile
2906                         echo 'uninstall.libs ::' >> Makefile
2907                         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >> Makefile
2908                         ;;
2909                 esac
2910         fi
2911
2912         if test -f $srcdir/$cf_dir/modules; then
2913                 echo >> Makefile
2914                 if test -f $srcdir/$cf_dir/headers; then
2915 cat >> Makefile <<CF_EOF
2916 install.includes \\
2917 uninstall.includes \\
2918 CF_EOF
2919                 fi
2920 if test "$cf_dir" != "c++" ; then
2921 echo 'lint \' >> Makefile
2922 fi
2923 cat >> Makefile <<CF_EOF
2924 libs \\
2925 lintlib \\
2926 install.libs \\
2927 uninstall.libs \\
2928 install.$cf_dir \\
2929 uninstall.$cf_dir ::
2930         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
2931 CF_EOF
2932         elif test -f $srcdir/$cf_dir/headers; then
2933 cat >> Makefile <<CF_EOF
2934
2935 libs \\
2936 install.libs \\
2937 uninstall.libs \\
2938 install.includes \\
2939 uninstall.includes ::
2940         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
2941 CF_EOF
2942 fi
2943 done
2944
2945 cat >> Makefile <<CF_EOF
2946
2947 install.libs uninstall.libs \\
2948 install.data uninstall.data ::
2949 $MAKE_TERMINFO  cd misc && \${MAKE} \${CF_MFLAGS} \[$]@
2950 CF_EOF
2951
2952 if test "x$cf_with_manpages" = xyes; then
2953 cat >> Makefile <<CF_EOF
2954
2955 install.man \\
2956 uninstall.man ::
2957         cd man && \${MAKE} \${CF_MFLAGS} \[$]@
2958 CF_EOF
2959 fi
2960
2961 cat >> Makefile <<CF_EOF
2962
2963 distclean ::
2964         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
2965         rm -f headers.sh headers.sed mk_shared_lib.sh
2966         rm -f edit_man.* man_alias.*
2967         rm -rf \${DIRS_TO_MAKE}
2968 CF_EOF
2969
2970 # Special case: tack's manpage lives in its own directory.
2971 if test "x$cf_with_manpages" = xyes; then
2972 if test -d tack ; then
2973 if test -f $srcdir/$tack.h; then
2974 cat >> Makefile <<CF_EOF
2975
2976 install.man \\
2977 uninstall.man ::
2978         cd tack && \${MAKE} \${CF_MFLAGS} \[$]@
2979 CF_EOF
2980 fi
2981 fi
2982 fi
2983
2984 dnl If we're installing into a subdirectory of /usr/include, etc., we should
2985 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
2986 dnl anything, and will make it more standardized.  It's awkward to decide this
2987 dnl at configuration because of quoting, so we'll simply make all headers
2988 dnl installed via a script that can do the right thing.
2989
2990 rm -f headers.sed headers.sh
2991
2992 dnl ( generating this script makes the makefiles a little tidier :-)
2993 echo creating headers.sh
2994 cat >headers.sh <<CF_EOF
2995 #! /bin/sh
2996 # This shell script is generated by the 'configure' script.  It is invoked in a
2997 # subdirectory of the build tree.  It generates a sed-script in the parent
2998 # directory that is used to adjust includes for header files that reside in a
2999 # subdirectory of /usr/include, etc.
3000 PRG=""
3001 while test \[$]# != 3
3002 do
3003 PRG="\$PRG \[$]1"; shift
3004 done
3005 DST=\[$]1
3006 REF=\[$]2
3007 SRC=\[$]3
3008 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3009 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3010 echo installing \$SRC in \$DST
3011 CF_EOF
3012
3013 if test $WITH_CURSES_H = yes; then
3014         cat >>headers.sh <<CF_EOF
3015 case \$DST in
3016 /*/include/*)
3017         END=\`basename \$DST\`
3018         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3019         do
3020                 NAME=\`basename \$i\`
3021                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3022         done
3023         ;;
3024 *)
3025         echo "" >> \$TMPSED
3026         ;;
3027 esac
3028 CF_EOF
3029
3030 else
3031         cat >>headers.sh <<CF_EOF
3032 case \$DST in
3033 /*/include/*)
3034         END=\`basename \$DST\`
3035         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3036         do
3037                 NAME=\`basename \$i\`
3038                 if test "\$NAME" = "curses.h"
3039                 then
3040                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3041                         NAME=ncurses.h
3042                 fi
3043                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3044         done
3045         ;;
3046 *)
3047         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3048         ;;
3049 esac
3050 CF_EOF
3051 fi
3052 cat >>headers.sh <<CF_EOF
3053 rm -f \$TMPSRC
3054 sed -f \$TMPSED \$SRC > \$TMPSRC
3055 NAME=\`basename \$SRC\`
3056 CF_EOF
3057 if test $WITH_CURSES_H != yes; then
3058         cat >>headers.sh <<CF_EOF
3059 test "\$NAME" = "curses.h" && NAME=ncurses.h
3060 CF_EOF
3061 fi
3062 cat >>headers.sh <<CF_EOF
3063 # Just in case someone gzip'd manpages, remove the conflicting copy.
3064 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3065
3066 eval \$PRG \$TMPSRC \$DST/\$NAME
3067 rm -f \$TMPSRC \$TMPSED
3068 CF_EOF
3069
3070 chmod 0755 headers.sh
3071
3072 for cf_dir in $SRC_SUBDIRS
3073 do
3074         if test ! -d $srcdir/$cf_dir ; then
3075                 continue
3076         fi
3077
3078         if test -f $srcdir/$cf_dir/headers; then
3079                 $AWK -f $srcdir/mk-hdr.awk \
3080                         subset="$LIB_SUBSETS" \
3081                         compat="$WITH_CURSES_H" \
3082                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3083         fi
3084
3085         if test -f $srcdir/$cf_dir/modules; then
3086                 if test "$cf_dir" != "c++" ; then
3087                         cat >>$cf_dir/Makefile <<"CF_EOF"
3088 depend : ${AUTO_SRC}
3089         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3090
3091 # DO NOT DELETE THIS LINE -- make depend depends on it.
3092 CF_EOF
3093                 fi
3094         fi
3095 done
3096 AC_SUBST(LIBS_TO_MAKE)
3097 ])dnl
3098 dnl ---------------------------------------------------------------------------
3099 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3100 dnl -------------
3101 dnl Find the and soname for the given shared library.  Set the cache variable
3102 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3103 dnl variable to "unknown".
3104 dnl
3105 dnl $1 = headers
3106 dnl $2 = code
3107 dnl $3 = library name
3108 AC_DEFUN([CF_LIB_SONAME],
3109 [
3110 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3111
3112 cf_cv_$3_soname=unknown
3113 if test "$cross_compiling" != yes ; then
3114 cat >conftest.$ac_ext <<CF_EOF
3115 $1
3116 int main()
3117 {
3118 $2
3119         ${cf_cv_main_return:-return}(0);
3120 }
3121 CF_EOF
3122 cf_save_LIBS="$LIBS"
3123         CF_ADD_LIB($3)
3124         if AC_TRY_EVAL(ac_compile) ; then
3125                 if AC_TRY_EVAL(ac_link) ; then
3126                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3127                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3128                 fi
3129         fi
3130 rm -rf conftest*
3131 LIBS="$cf_save_LIBS"
3132 fi
3133 ])
3134 ])
3135 dnl ---------------------------------------------------------------------------
3136 dnl CF_LIB_SUFFIX version: 16 updated: 2008/12/27 12:30:03
3137 dnl -------------
3138 dnl Compute the library file-suffix from the given model name
3139 dnl $1 = model name
3140 dnl $2 = variable to set (the nominal library suffix)
3141 dnl $3 = dependency variable to set (actual filename)
3142 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3143 AC_DEFUN([CF_LIB_SUFFIX],
3144 [
3145         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3146         case $1 in #(vi
3147         libtool) #(vi
3148                 $2='.la'
3149                 $3=[$]$2
3150                 ;;
3151         normal) #(vi
3152                 $2='.a'
3153                 $3=[$]$2
3154                 ;;
3155         debug) #(vi
3156                 $2='_g.a'
3157                 $3=[$]$2
3158                 ;;
3159         profile) #(vi
3160                 $2='_p.a'
3161                 $3=[$]$2
3162                 ;;
3163         shared) #(vi
3164                 case $cf_cv_system_name in
3165                 aix[[56]]*) #(vi
3166                         $2='.a'
3167                         $3=[$]$2
3168                         ;;
3169                 cygwin*) #(vi
3170                         $2='.dll'
3171                         $3='.dll.a'
3172                         ;;
3173                 darwin*) #(vi
3174                         $2='.dylib'
3175                         $3=[$]$2
3176                         ;;
3177                 hpux*) #(vi
3178                         case $target in
3179                         ia64*) #(vi
3180                                 $2='.so'
3181                                 $3=[$]$2
3182                                 ;;
3183                         *) #(vi
3184                                 $2='.sl'
3185                                 $3=[$]$2
3186                                 ;;
3187                         esac
3188                         ;;
3189                 *)      $2='.so'
3190                         $3=[$]$2
3191                         ;;
3192                 esac
3193         esac
3194         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3195         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3196 ])dnl
3197 dnl ---------------------------------------------------------------------------
3198 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3199 dnl -----------
3200 dnl Compute the string to append to -library from the given model name
3201 dnl $1 = model name
3202 dnl $2 = variable to set
3203 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3204 AC_DEFUN([CF_LIB_TYPE],
3205 [
3206         case $1 in
3207         libtool) $2=''   ;;
3208         normal)  $2=''   ;;
3209         debug)   $2='_g' ;;
3210         profile) $2='_p' ;;
3211         shared)  $2=''   ;;
3212         esac
3213         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3214 ])dnl
3215 dnl ---------------------------------------------------------------------------
3216 dnl CF_LINK_DATAONLY version: 9 updated: 2009/01/01 20:21:38
3217 dnl ----------------
3218 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3219 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3220 dnl have to provide wrappers for global tables to ensure they're linked
3221 dnl properly.
3222 AC_DEFUN([CF_LINK_DATAONLY],
3223 [
3224 AC_MSG_CHECKING([if data-only library module links])
3225 AC_CACHE_VAL(cf_cv_link_dataonly,[
3226         rm -f conftest.a
3227         cat >conftest.$ac_ext <<EOF
3228 #line __oline__ "configure"
3229 int     testdata[[3]] = { 123, 456, 789 };
3230 EOF
3231         if AC_TRY_EVAL(ac_compile) ; then
3232                 mv conftest.o data.o && \
3233                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3234         fi
3235         rm -f conftest.$ac_ext data.o
3236         cat >conftest.$ac_ext <<EOF
3237 #line __oline__ "configure"
3238 int     testfunc()
3239 {
3240 #if defined(NeXT)
3241         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3242 #else
3243         extern int testdata[[3]];
3244         return testdata[[0]] == 123
3245            &&  testdata[[1]] == 456
3246            &&  testdata[[2]] == 789;
3247 #endif
3248 }
3249 EOF
3250         if AC_TRY_EVAL(ac_compile); then
3251                 mv conftest.o func.o && \
3252                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3253         fi
3254         rm -f conftest.$ac_ext func.o
3255         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3256         cf_saveLIBS="$LIBS"
3257         LIBS="conftest.a $LIBS"
3258         AC_TRY_RUN([
3259         int main()
3260         {
3261                 extern int testfunc();
3262                 ${cf_cv_main_return:-return} (!testfunc());
3263         }
3264         ],
3265         [cf_cv_link_dataonly=yes],
3266         [cf_cv_link_dataonly=no],
3267         [cf_cv_link_dataonly=unknown])
3268         LIBS="$cf_saveLIBS"
3269         ])
3270 AC_MSG_RESULT($cf_cv_link_dataonly)
3271
3272 if test "$cf_cv_link_dataonly" = no ; then
3273         AC_DEFINE(BROKEN_LINKER)
3274         BROKEN_LINKER=1
3275 fi
3276
3277 ])dnl
3278 dnl ---------------------------------------------------------------------------
3279 dnl CF_LINK_FUNCS version: 7 updated: 2006/12/16 12:33:30
3280 dnl -------------
3281 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3282 dnl A few non-Unix systems implement symlink, but not link.
3283 dnl A few non-systems implement neither (or have nonfunctional versions).
3284 AC_DEFUN([CF_LINK_FUNCS],
3285 [
3286 AC_CHECK_FUNCS( \
3287         remove \
3288         unlink )
3289
3290 if test "$cross_compiling" = yes ; then
3291         AC_CHECK_FUNCS( \
3292                 link \
3293                 symlink )
3294 else
3295         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3296                 cf_cv_link_funcs=
3297                 for cf_func in link symlink ; do
3298                         AC_TRY_RUN([
3299 #include <sys/types.h>
3300 #include <sys/stat.h>
3301 #ifdef HAVE_UNISTD_H
3302 #include <unistd.h>
3303 #endif
3304 int main()
3305 {
3306         int fail = 0;
3307         char *src = "config.log";
3308         char *dst = "conftest.chk";
3309         struct stat src_sb;
3310         struct stat dst_sb;
3311
3312         stat(src, &src_sb);
3313         fail = ($cf_func("config.log", "conftest.chk") < 0)
3314             || (stat(dst, &dst_sb) < 0)
3315             || (dst_sb.st_mtime != src_sb.st_mtime);
3316 #ifdef HAVE_UNLINK
3317         unlink(dst);
3318 #else
3319         remove(dst);
3320 #endif
3321         ${cf_cv_main_return:-return} (fail);
3322 }
3323                         ],[
3324                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3325                         eval 'ac_cv_func_'$cf_func'=yes'],[
3326                         eval 'ac_cv_func_'$cf_func'=no'],[
3327                         eval 'ac_cv_func_'$cf_func'=error'])
3328                 done
3329                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
3330         ])
3331         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK)
3332         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK)
3333 fi
3334 ])dnl
3335 dnl ---------------------------------------------------------------------------
3336 dnl CF_MAIN_RETURN version: 1 updated: 2006/12/10 09:51:54
3337 dnl --------------
3338 dnl Check if a return from main to the shell actually returns the same exit
3339 dnl code.  This is true for almost any POSIX environment.
3340 dnl
3341 dnl Some very old environments did not flush stdout, etc., on an exit.  That
3342 dnl would be a useful case to test for also.
3343 AC_DEFUN([CF_MAIN_RETURN],
3344 [
3345 cf_cv_main_return=return
3346 ])dnl
3347 dnl ---------------------------------------------------------------------------
3348 dnl CF_MAKEFLAGS version: 13 updated: 2010/10/23 15:52:32
3349 dnl ------------
3350 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
3351 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
3352 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
3353 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
3354 AC_DEFUN([CF_MAKEFLAGS],
3355 [
3356 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
3357         cf_cv_makeflags=''
3358         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
3359         do
3360                 cat >cf_makeflags.tmp <<CF_EOF
3361 SHELL = /bin/sh
3362 all :
3363         @ echo '.$cf_option'
3364 CF_EOF
3365                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | sed -e 's,[[      ]]*$,,'`
3366                 case "$cf_result" in
3367                 .*k)
3368                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
3369                         case "$cf_result" in
3370                         .*CC=*) cf_cv_makeflags=
3371                                 ;;
3372                         *)      cf_cv_makeflags=$cf_option
3373                                 ;;
3374                         esac
3375                         break
3376                         ;;
3377                 .-)     ;;
3378                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
3379                         ;;
3380                 esac
3381         done
3382         rm -f cf_makeflags.tmp
3383 ])
3384
3385 AC_SUBST(cf_cv_makeflags)
3386 ])dnl
3387 dnl ---------------------------------------------------------------------------
3388 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
3389 dnl ------------
3390 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
3391 dnl a monocase filesystem.
3392 AC_DEFUN([CF_MAKE_TAGS],[
3393 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
3394
3395 AC_CHECK_PROGS(CTAGS, exctags ctags)
3396 AC_CHECK_PROGS(ETAGS, exetags etags)
3397
3398 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
3399
3400 if test "$cf_cv_mixedcase" = yes ; then
3401         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
3402 else
3403         MAKE_UPPER_TAGS=no
3404 fi
3405
3406 if test "$MAKE_UPPER_TAGS" = yes ; then
3407         MAKE_UPPER_TAGS=
3408 else
3409         MAKE_UPPER_TAGS="#"
3410 fi
3411
3412 if test "$MAKE_LOWER_TAGS" = yes ; then
3413         MAKE_LOWER_TAGS=
3414 else
3415         MAKE_LOWER_TAGS="#"
3416 fi
3417
3418 AC_SUBST(CTAGS)
3419 AC_SUBST(ETAGS)
3420
3421 AC_SUBST(MAKE_UPPER_TAGS)
3422 AC_SUBST(MAKE_LOWER_TAGS)
3423 ])dnl
3424 dnl ---------------------------------------------------------------------------
3425 dnl CF_MANPAGE_FORMAT version: 9 updated: 2010/10/23 16:10:30
3426 dnl -----------------
3427 dnl Option to allow user to override automatic configuration of manpage format.
3428 dnl There are several special cases:
3429 dnl
3430 dnl     gzip - man checks for, can display gzip'd files
3431 dnl     compress - man checks for, can display compressed files
3432 dnl     BSDI - files in the cat-directories are suffixed ".0"
3433 dnl     formatted - installer should format (put files in cat-directory)
3434 dnl     catonly - installer should only format, e.g., for a turnkey system.
3435 dnl
3436 dnl There are other configurations which this macro does not test, e.g., HPUX's
3437 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
3438 dnl convention would not match our use).
3439 AC_DEFUN([CF_MANPAGE_FORMAT],
3440 [
3441 AC_REQUIRE([CF_PATHSEP])
3442 AC_MSG_CHECKING(format of man-pages)
3443
3444 AC_ARG_WITH(manpage-format,
3445         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
3446                           optionally formatted/catonly, e.g., gzip,formatted],
3447         [MANPAGE_FORMAT=$withval],
3448         [MANPAGE_FORMAT=unknown])
3449
3450 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
3451 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
3452
3453 cf_unknown=
3454
3455 case $MANPAGE_FORMAT in
3456 unknown)
3457   if test -z "$MANPATH" ; then
3458     MANPATH="/usr/man:/usr/share/man"
3459   fi
3460
3461   # look for the 'date' man-page (it's most likely to be installed!)
3462   MANPAGE_FORMAT=
3463   cf_preform=no
3464   cf_catonly=yes
3465   cf_example=date
3466
3467   IFS="${IFS:-  }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
3468   for cf_dir in $MANPATH; do
3469     test -z "$cf_dir" && cf_dir=/usr/man
3470     for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
3471     do
3472       cf_test=`echo $cf_name | sed -e 's/*//'`
3473       if test "x$cf_test" = "x$cf_name" ; then
3474
3475         case "$cf_name" in
3476         *.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
3477         *.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
3478         *.0)    MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
3479         *)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
3480         esac
3481
3482         case "$cf_name" in
3483         $cf_dir/man*)
3484           cf_catonly=no
3485           ;;
3486         $cf_dir/cat*)
3487           cf_preform=yes
3488           ;;
3489         esac
3490         break
3491       fi
3492
3493       # if we found a match in either man* or cat*, stop looking
3494       if test -n "$MANPAGE_FORMAT" ; then
3495         cf_found=no
3496         test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
3497         test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
3498         case "$cf_name" in
3499         $cf_dir/cat*)
3500           cf_found=yes
3501           ;;
3502         esac
3503         test $cf_found=yes && break
3504       fi
3505     done
3506     # only check the first directory in $MANPATH where we find manpages
3507     if test -n "$MANPAGE_FORMAT" ; then
3508        break
3509     fi
3510   done
3511   # if we did not find the example, just assume it is normal
3512   test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
3513   IFS="$ac_save_ifs"
3514   ;;
3515 *)
3516   for cf_option in $MANPAGE_FORMAT; do
3517      case $cf_option in #(vi
3518      gzip|compress|BSDI|normal|formatted|catonly)
3519        ;;
3520      *)
3521        cf_unknown="$cf_unknown $cf_option"
3522        ;;
3523      esac
3524   done
3525   ;;
3526 esac
3527
3528 AC_MSG_RESULT($MANPAGE_FORMAT)
3529 if test -n "$cf_unknown" ; then
3530   AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
3531 fi
3532 ])dnl
3533 dnl ---------------------------------------------------------------------------
3534 dnl CF_MANPAGE_RENAMES version: 7 updated: 2005/06/18 18:51:57
3535 dnl ------------------
3536 dnl The Debian people have their own naming convention for manpages.  This
3537 dnl option lets us override the name of the file containing renaming, or
3538 dnl disable it altogether.
3539 AC_DEFUN([CF_MANPAGE_RENAMES],
3540 [
3541 AC_MSG_CHECKING(for manpage renaming)
3542
3543 AC_ARG_WITH(manpage-renames,
3544         [  --with-manpage-renames  specify manpage-renaming],
3545         [MANPAGE_RENAMES=$withval],
3546         [MANPAGE_RENAMES=yes])
3547
3548 case ".$MANPAGE_RENAMES" in #(vi
3549 .no) #(vi
3550   ;;
3551 .|.yes)
3552   # Debian 'man' program?
3553   if test -f /etc/debian_version ; then
3554     MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
3555   else
3556     MANPAGE_RENAMES=no
3557   fi
3558   ;;
3559 esac
3560
3561 if test "$MANPAGE_RENAMES" != no ; then
3562   if test -f $srcdir/man/$MANPAGE_RENAMES ; then
3563     MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
3564   elif test ! -f $MANPAGE_RENAMES ; then
3565     AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
3566   fi
3567
3568   test ! -d man && mkdir man
3569
3570   # Construct a sed-script to perform renaming within man-pages
3571   if test -n "$MANPAGE_RENAMES" ; then
3572     test ! -d man && mkdir man
3573     sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
3574   fi
3575 fi
3576
3577 AC_MSG_RESULT($MANPAGE_RENAMES)
3578 AC_SUBST(MANPAGE_RENAMES)
3579 ])dnl
3580 dnl ---------------------------------------------------------------------------
3581 dnl CF_MANPAGE_SYMLINKS version: 5 updated: 2010/07/24 17:12:40
3582 dnl -------------------
3583 dnl Some people expect each tool to make all aliases for manpages in the
3584 dnl man-directory.  This accommodates the older, less-capable implementations
3585 dnl of 'man', and is optional.
3586 AC_DEFUN([CF_MANPAGE_SYMLINKS],
3587 [
3588 AC_MSG_CHECKING(if manpage aliases will be installed)
3589
3590 AC_ARG_WITH(manpage-aliases,
3591         [  --with-manpage-aliases  specify manpage-aliases using .so],
3592         [MANPAGE_ALIASES=$withval],
3593         [MANPAGE_ALIASES=yes])
3594
3595 AC_MSG_RESULT($MANPAGE_ALIASES)
3596
3597 case "x$LN_S" in #(vi
3598 xln*) #(vi
3599         cf_use_symlinks=yes
3600         ;;
3601 *)
3602         cf_use_symlinks=no
3603         ;;
3604 esac
3605
3606 MANPAGE_SYMLINKS=no
3607 if test "$MANPAGE_ALIASES" = yes ; then
3608 AC_MSG_CHECKING(if manpage symlinks should be used)
3609
3610 AC_ARG_WITH(manpage-symlinks,
3611         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
3612         [MANPAGE_SYMLINKS=$withval],
3613         [MANPAGE_SYMLINKS=$cf_use_symlinks])
3614
3615 if test "$$cf_use_symlinks" = no; then
3616 if test "$MANPAGE_SYMLINKS" = yes ; then
3617         AC_MSG_WARN(cannot make symlinks, will use .so files)
3618         MANPAGE_SYMLINKS=no
3619 fi
3620 fi
3621
3622 AC_MSG_RESULT($MANPAGE_SYMLINKS)
3623 fi
3624
3625 ])dnl
3626 dnl ---------------------------------------------------------------------------
3627 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
3628 dnl --------------
3629 dnl This option causes manpages to be run through tbl(1) to generate tables
3630 dnl correctly.
3631 AC_DEFUN([CF_MANPAGE_TBL],
3632 [
3633 AC_MSG_CHECKING(for manpage tbl)
3634
3635 AC_ARG_WITH(manpage-tbl,
3636         [  --with-manpage-tbl      specify manpage processing with tbl],
3637         [MANPAGE_TBL=$withval],
3638         [MANPAGE_TBL=no])
3639
3640 AC_MSG_RESULT($MANPAGE_TBL)
3641 ])dnl
3642 dnl ---------------------------------------------------------------------------
3643 dnl CF_MAN_PAGES version: 39 updated: 2010/10/23 15:44:18
3644 dnl ------------
3645 dnl Try to determine if the man-pages on the system are compressed, and if
3646 dnl so, what format is used.  Use this information to construct a script that
3647 dnl will install man-pages.
3648 AC_DEFUN([CF_MAN_PAGES],
3649 [
3650 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
3651 CF_MANPAGE_FORMAT
3652 CF_MANPAGE_RENAMES
3653 CF_MANPAGE_SYMLINKS
3654 CF_MANPAGE_TBL
3655
3656   if test "$prefix" = "NONE" ; then
3657      cf_prefix="$ac_default_prefix"
3658   else
3659      cf_prefix="$prefix"
3660   fi
3661
3662   case "$MANPAGE_FORMAT" in # (vi
3663   *catonly*) # (vi
3664     cf_format=yes
3665     cf_inboth=no
3666     ;;
3667   *formatted*) # (vi
3668     cf_format=yes
3669     cf_inboth=yes
3670     ;;
3671   *)
3672     cf_format=no
3673     cf_inboth=no
3674     ;;
3675   esac
3676
3677 test ! -d man && mkdir man
3678
3679 cf_so_strip=
3680 cf_compress=
3681 case "$MANPAGE_FORMAT" in #(vi
3682 *compress*) #(vi
3683         cf_so_strip="Z"
3684         cf_compress=compress
3685   ;;
3686 *gzip*)
3687         cf_so_strip="gz"
3688         cf_compress=gzip
3689   ;;
3690 esac
3691
3692 cf_edit_man=./edit_man.sh
3693 cf_man_alias=`pwd`/man_alias.sed
3694
3695 cat >$cf_edit_man <<CF_EOF
3696 #! /bin/sh
3697 # this script is generated by the configure-script CF_MAN_PAGES macro.
3698
3699 prefix="$cf_prefix"
3700 datadir="$datadir"
3701
3702 NCURSES_MAJOR="$NCURSES_MAJOR"
3703 NCURSES_MINOR="$NCURSES_MINOR"
3704 NCURSES_PATCH="$NCURSES_PATCH"
3705
3706 NCURSES_OSPEED="$NCURSES_OSPEED"
3707 TERMINFO="$TERMINFO"
3708
3709 INSTALL="$INSTALL"
3710 INSTALL_DATA="$INSTALL_DATA"
3711
3712 transform="$program_transform_name"
3713
3714 TMP=\${TMPDIR:=/tmp}/man\$\$
3715 trap "rm -f \$TMP" 0 1 2 5 15
3716
3717 form=\[$]1
3718 shift || exit 1
3719
3720 verb=\[$]1
3721 shift || exit 1
3722
3723 mandir=\[$]1
3724 shift || exit 1
3725
3726 srcdir=\[$]1
3727 top_srcdir=\[$]srcdir/..
3728 shift || exit 1
3729
3730 if test "\$form" = normal ; then
3731         if test "$cf_format" = yes ; then
3732         if test "$cf_inboth" = no ; then
3733                 sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
3734                 exit $?
3735         fi
3736         fi
3737         cf_subdir=\$mandir/man
3738         cf_tables=$MANPAGE_TBL
3739 else
3740         cf_subdir=\$mandir/cat
3741         cf_tables=yes
3742 fi
3743
3744 # process the list of source-files
3745 for i in \[$]* ; do
3746 case \$i in #(vi
3747 *.orig|*.rej) ;; #(vi
3748 *.[[0-9]]*)
3749         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
3750         if test \$verb = installing ; then
3751         if test ! -d \$cf_subdir\${section} ; then
3752                 mkdir -p \$cf_subdir\$section
3753         fi
3754         fi
3755
3756         # replace variables in man page
3757         if test ! -f $cf_man_alias ; then
3758 cat >>$cf_man_alias <<-CF_EOF2
3759                 s,@DATADIR@,\$datadir,g
3760                 s,@TERMINFO@,\$TERMINFO,g
3761                 s,@NCURSES_MAJOR@,\$NCURSES_MAJOR,g
3762                 s,@NCURSES_MINOR@,\$NCURSES_MINOR,g
3763                 s,@NCURSES_PATCH@,\$NCURSES_PATCH,g
3764                 s,@NCURSES_OSPEED@,\$NCURSES_OSPEED,g
3765 CF_EOF
3766         ifelse($1,,,[
3767         for cf_name in $1
3768         do
3769                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3770                 cf_name=`echo $cf_name|sed "$program_transform_name"`
3771 cat >>$cf_edit_man <<-CF_EOF
3772                 s,@$cf_NAME@,$cf_name,g
3773 CF_EOF
3774         done
3775         ])
3776 cat >>$cf_edit_man <<CF_EOF
3777 CF_EOF2
3778                 echo "...made $cf_man_alias"