aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2014,2015 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.785 2015/11/08 01:03:06 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54         [AC_TRY_LINK([#include <langinfo.h>],
  55         [char* cs = nl_langinfo(CODESET);],
  56         am_cv_langinfo_codeset=yes,
  57         am_cv_langinfo_codeset=no)
  58         ])
  59         if test $am_cv_langinfo_codeset = yes; then
  60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62         fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  66 dnl ---------------
  67 dnl Provide configure-script defaults for different ncurses ABIs.
  68 AC_DEFUN([CF_ABI_DEFAULTS],[
  69 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  70 case x$cf_cv_abi_version in
  71 (x[[6789]])
  72         cf_dft_ext_colors=yes
  73         cf_dft_ext_const=yes
  74         cf_dft_ext_mouse=yes
  75         cf_dft_ext_putwin=yes
  76         cf_dft_ext_spfuncs=yes
  77         cf_dft_filter_syms=yes
  78         cf_dft_chtype=uint32_t
  79         cf_dft_mmask_t=uint32_t
  80         cf_dft_interop=yes
  81         cf_dft_tparm_arg=intptr_t
  82         cf_dft_with_lp64=yes
  83         ;;
  84 (*)
  85         cf_dft_ext_colors=no
  86         cf_dft_ext_const=no
  87         cf_dft_ext_mouse=no
  88         cf_dft_ext_putwin=no
  89         cf_dft_ext_spfuncs=no
  90         cf_dft_filter_syms=no
  91         cf_dft_chtype=auto
  92         cf_dft_mmask_t=auto
  93         cf_dft_interop=no
  94         cf_dft_tparm_arg=long
  95         cf_dft_with_lp64=no
  96         ;;
  97 esac
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 101 dnl ------------------
 102 dnl Conditionally generate script according to whether we're using a given autoconf.
 103 dnl
 104 dnl $1 = version to compare against
 105 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 106 dnl $3 = code to use if AC_ACVERSION is older than $1.
 107 define([CF_ACVERSION_CHECK],
 108 [
 109 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 110 ifdef([m4_version_compare],
 111 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 112 [CF_ACVERSION_COMPARE(
 113 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 114 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 115 dnl ---------------------------------------------------------------------------
 116 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 117 dnl --------------------
 118 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 119 dnl                      MAJOR2, MINOR2, TERNARY2,
 120 dnl                      PRINTABLE2, not FOUND, FOUND)
 121 define([CF_ACVERSION_COMPARE],
 122 [ifelse(builtin([eval], [$2 < $5]), 1,
 123 [ifelse([$8], , ,[$8])],
 124 [ifelse([$9], , ,[$9])])])dnl
 125 dnl ---------------------------------------------------------------------------
 126 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 127 dnl -------------------
 128 dnl Construct the list of include-options for the C programs in the Ada95
 129 dnl binding.
 130 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 131 [
 132 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 133 if test "$srcdir" != "."; then
 134         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 135 fi
 136 if test "$GCC" != yes; then
 137         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 138 elif test "$includedir" != "/usr/include"; then
 139         if test "$includedir" = '${prefix}/include' ; then
 140                 if test x$prefix != x/usr ; then
 141                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 142                 fi
 143         else
 144                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145         fi
 146 fi
 147 AC_SUBST(ACPPFLAGS)
 148 ])dnl
 149 dnl ---------------------------------------------------------------------------
 150 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 151 dnl ---------------
 152 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 153 AC_DEFUN([CF_ADD_ADAFLAGS],[
 154         ADAFLAGS="$ADAFLAGS $1"
 155         AC_SUBST(ADAFLAGS)
 156 ])dnl
 157 dnl ---------------------------------------------------------------------------
 158 dnl CF_ADD_CFLAGS version: 12 updated: 2015/04/12 15:39:00
 159 dnl -------------
 160 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 161 dnl The second parameter if given makes this macro verbose.
 162 dnl
 163 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 164 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 165 dnl confused by the quotes (which require backslashes to keep them usable).
 166 AC_DEFUN([CF_ADD_CFLAGS],
 167 [
 168 cf_fix_cppflags=no
 169 cf_new_cflags=
 170 cf_new_cppflags=
 171 cf_new_extra_cppflags=
 172
 173 for cf_add_cflags in $1
 174 do
 175 case $cf_fix_cppflags in
 176 (no)
 177         case $cf_add_cflags in
 178         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 179                 case $cf_add_cflags in
 180                 (-D*)
 181                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 182
 183                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 184                                 && test -z "${cf_tst_cflags}" \
 185                                 && cf_fix_cppflags=yes
 186
 187                         if test $cf_fix_cppflags = yes ; then
 188                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 189                                 continue
 190                         elif test "${cf_tst_cflags}" = "\"'" ; then
 191                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 192                                 continue
 193                         fi
 194                         ;;
 195                 esac
 196                 case "$CPPFLAGS" in
 197                 (*$cf_add_cflags)
 198                         ;;
 199                 (*)
 200                         case $cf_add_cflags in
 201                         (-D*)
 202                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 203                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 204                                 ;;
 205                         esac
 206                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 207                         ;;
 208                 esac
 209                 ;;
 210         (*)
 211                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 212                 ;;
 213         esac
 214         ;;
 215 (yes)
 216         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 217
 218         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 219
 220         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 221                 && test -z "${cf_tst_cflags}" \
 222                 && cf_fix_cppflags=no
 223         ;;
 224 esac
 225 done
 226
 227 if test -n "$cf_new_cflags" ; then
 228         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 229         CFLAGS="$CFLAGS $cf_new_cflags"
 230 fi
 231
 232 if test -n "$cf_new_cppflags" ; then
 233         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 234         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 235 fi
 236
 237 if test -n "$cf_new_extra_cppflags" ; then
 238         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 239         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 240 fi
 241
 242 AC_SUBST(EXTRA_CPPFLAGS)
 243
 244 ])dnl
 245 dnl ---------------------------------------------------------------------------
 246 dnl CF_ADD_INCDIR version: 14 updated: 2015/05/25 20:53:04
 247 dnl -------------
 248 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 249 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 250 dnl but old versions (and some misinstalled ones) need that.  To make things
 251 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 252 dnl the include-path).
 253 AC_DEFUN([CF_ADD_INCDIR],
 254 [
 255 if test -n "$1" ; then
 256   for cf_add_incdir in $1
 257   do
 258         while test $cf_add_incdir != /usr/include
 259         do
 260           if test -d $cf_add_incdir
 261           then
 262                 cf_have_incdir=no
 263                 if test -n "$CFLAGS$CPPFLAGS" ; then
 264                   # a loop is needed to ensure we can add subdirs of existing dirs
 265                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 266                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 267                           cf_have_incdir=yes; break
 268                         fi
 269                   done
 270                 fi
 271
 272                 if test "$cf_have_incdir" = no ; then
 273                   if test "$cf_add_incdir" = /usr/local/include ; then
 274                         if test "$GCC" = yes
 275                         then
 276                           cf_save_CPPFLAGS=$CPPFLAGS
 277                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 278                           AC_TRY_COMPILE([#include <stdio.h>],
 279                                   [printf("Hello")],
 280                                   [],
 281                                   [cf_have_incdir=yes])
 282                           CPPFLAGS=$cf_save_CPPFLAGS
 283                         fi
 284                   fi
 285                 fi
 286
 287                 if test "$cf_have_incdir" = no ; then
 288                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 289                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 290
 291                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 292                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 293                   cf_add_incdir="$cf_top_incdir"
 294                 else
 295                   break
 296                 fi
 297           else
 298                 break
 299           fi
 300         done
 301   done
 302 fi
 303 ])dnl
 304 dnl ---------------------------------------------------------------------------
 305 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 306 dnl ----------
 307 dnl Add a library, used to enforce consistency.
 308 dnl
 309 dnl $1 = library to add, without the "-l"
 310 dnl $2 = variable to update (default $LIBS)
 311 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 312 dnl ---------------------------------------------------------------------------
 313 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 314 dnl -------------
 315 dnl     Adds to the library-path
 316 dnl
 317 dnl     Some machines have trouble with multiple -L options.
 318 dnl
 319 dnl $1 is the (list of) directory(s) to add
 320 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 321 dnl
 322 AC_DEFUN([CF_ADD_LIBDIR],
 323 [
 324 if test -n "$1" ; then
 325         for cf_add_libdir in $1
 326         do
 327                 if test $cf_add_libdir = /usr/lib ; then
 328                         :
 329                 elif test -d $cf_add_libdir
 330                 then
 331                         cf_have_libdir=no
 332                         if test -n "$LDFLAGS$LIBS" ; then
 333                                 # a loop is needed to ensure we can add subdirs of existing dirs
 334                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 335                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 336                                                 cf_have_libdir=yes; break
 337                                         fi
 338                                 done
 339                         fi
 340                         if test "$cf_have_libdir" = no ; then
 341                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 342                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 343                         fi
 344                 fi
 345         done
 346 fi
 347 ])dnl
 348 dnl ---------------------------------------------------------------------------
 349 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 350 dnl -----------
 351 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 352 dnl prepended to an existing list, since their dependencies are assumed to
 353 dnl already exist in the list.
 354 dnl
 355 dnl $1 = libraries to add, with the "-l", etc.
 356 dnl $2 = variable to update (default $LIBS)
 357 AC_DEFUN([CF_ADD_LIBS],[
 358 cf_add_libs="$1"
 359 # Filter out duplicates - this happens with badly-designed ".pc" files...
 360 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 361 do
 362         for cf_add_2lib in $cf_add_libs
 363         do
 364                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 365                 then
 366                         cf_add_1lib=
 367                         break
 368                 fi
 369         done
 370         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 371 done
 372 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 373 ])dnl
 374 dnl ---------------------------------------------------------------------------
 375 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 376 dnl ------------------
 377 dnl Append to a search-list for a nonstandard header/lib-file
 378 dnl     $1 = the variable to return as result
 379 dnl     $2 = the package name
 380 dnl     $3 = the subdirectory, e.g., bin, include or lib
 381 dnl $4 = the directory under which we will test for subdirectories
 382 dnl $5 = a directory that we do not want $4 to match
 383 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 384 [
 385 test "x$4" != "x$5" && \
 386 test -d "$4" && \
 387 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 388         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 389         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 390         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 391         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 392         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 393         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 394 }
 395 ])dnl
 396 dnl ---------------------------------------------------------------------------
 397 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 398 dnl --------------
 399 dnl Allow user to disable a normally-on option.
 400 AC_DEFUN([CF_ARG_DISABLE],
 401 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 402 dnl ---------------------------------------------------------------------------
 403 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 404 dnl -------------
 405 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 406 dnl values.
 407 dnl
 408 dnl Parameters:
 409 dnl $1 = option name
 410 dnl $2 = help-string
 411 dnl $3 = action to perform if option is not default
 412 dnl $4 = action if perform if option is default
 413 dnl $5 = default option value (either 'yes' or 'no')
 414 AC_DEFUN([CF_ARG_OPTION],
 415 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 416         if test "$enableval" != "$5" ; then
 417 ifelse([$3],,[    :]dnl
 418 ,[    $3]) ifelse([$4],,,[
 419         else
 420                 $4])
 421         fi],[enableval=$5 ifelse([$4],,,[
 422         $4
 423 ])dnl
 424 ])])dnl
 425 dnl ---------------------------------------------------------------------------
 426 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 427 dnl -----------
 428 dnl Check for suitable "ar" (archiver) options for updating an archive.
 429 dnl
 430 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 431 dnl as well as a workaround for breakage of make's archive rules by the GNU
 432 dnl binutils "ar" program.
 433 AC_DEFUN([CF_AR_FLAGS],[
 434 AC_REQUIRE([CF_PROG_AR])
 435
 436 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 437         cf_cv_ar_flags=unknown
 438         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 439         do
 440
 441                 # check if $ARFLAGS already contains this choice
 442                 if test "x$ARFLAGS" != "x" ; then
 443                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 444                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 445                                 cf_cv_ar_flags=
 446                                 break
 447                         fi
 448                 fi
 449
 450                 rm -f conftest.$ac_cv_objext
 451                 rm -f conftest.a
 452
 453                 cat >conftest.$ac_ext <<EOF
 454 #line __oline__ "configure"
 455 int     testdata[[3]] = { 123, 456, 789 };
 456 EOF
 457                 if AC_TRY_EVAL(ac_compile) ; then
 458                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 459                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 460                         if test -f conftest.a ; then
 461                                 cf_cv_ar_flags=$cf_ar_flags
 462                                 break
 463                         fi
 464                 else
 465                         CF_VERBOSE(cannot compile test-program)
 466                         break
 467                 fi
 468         done
 469         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 470 ])
 471
 472 if test -n "$ARFLAGS" ; then
 473         if test -n "$cf_cv_ar_flags" ; then
 474                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 475         fi
 476 else
 477         ARFLAGS=$cf_cv_ar_flags
 478 fi
 479
 480 AC_SUBST(ARFLAGS)
 481 ])
 482 dnl ---------------------------------------------------------------------------
 483 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 484 dnl -----------------
 485 dnl Check if awk can handle big strings using printf.  Some older versions of
 486 dnl awk choke on large strings passed via "%s".
 487 dnl
 488 dnl $1 = desired string size
 489 dnl $2 = variable to set with result
 490 AC_DEFUN([CF_AWK_BIG_PRINTF],
 491 [
 492         case x$AWK in
 493         (x)
 494                 eval $2=no
 495                 ;;
 496         (*)
 497                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 498                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 499                         eval $2=yes
 500                 else
 501                         eval $2=no
 502                 fi
 503                 ;;
 504         esac
 505 ])dnl
 506 dnl ---------------------------------------------------------------------------
 507 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 508 dnl ------------
 509 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 510 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 511 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 512 dnl
 513 dnl Treat the configuration-variable specially here, since we're directly
 514 dnl substituting its value (i.e., 1/0).
 515 dnl
 516 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 517 AC_DEFUN([CF_BOOL_DECL],
 518 [
 519 AC_MSG_CHECKING(if we should include stdbool.h)
 520
 521 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 522         AC_TRY_COMPILE([],[bool foo = false],
 523                 [cf_cv_header_stdbool_h=0],
 524                 [AC_TRY_COMPILE([
 525 #ifndef __BEOS__
 526 #include <stdbool.h>
 527 #endif
 528 ],[bool foo = false],
 529                         [cf_cv_header_stdbool_h=1],
 530                         [cf_cv_header_stdbool_h=0])])])
 531
 532 if test "$cf_cv_header_stdbool_h" = 1
 533 then    AC_MSG_RESULT(yes)
 534 else    AC_MSG_RESULT(no)
 535 fi
 536
 537 AC_MSG_CHECKING([for builtin bool type])
 538
 539 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 540         AC_TRY_COMPILE([
 541 #include <stdio.h>
 542 #include <sys/types.h>
 543 ],[bool x = false],
 544                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 545                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 546         ])
 547
 548 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 549 then    AC_MSG_RESULT(yes)
 550 else    AC_MSG_RESULT(no)
 551 fi
 552 ])dnl
 553 dnl ---------------------------------------------------------------------------
 554 dnl CF_BOOL_SIZE version: 14 updated: 2015/04/17 21:13:04
 555 dnl ------------
 556 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 557 dnl Don't bother looking for bool.h, since it's been deprecated.
 558 dnl
 559 dnl If the current compiler is C rather than C++, we get the bool definition
 560 dnl from <stdbool.h>.
 561 AC_DEFUN([CF_BOOL_SIZE],
 562 [
 563 AC_MSG_CHECKING([for size of bool])
 564 AC_CACHE_VAL(cf_cv_type_of_bool,[
 565         rm -f cf_test.out
 566         AC_TRY_RUN([
 567 #include <stdlib.h>
 568 #include <stdio.h>
 569
 570 #if defined(__cplusplus)
 571
 572 #ifdef HAVE_GXX_BUILTIN_H
 573 #include <g++/builtin.h>
 574 #elif HAVE_GPP_BUILTIN_H
 575 #include <gpp/builtin.h>
 576 #elif HAVE_BUILTIN_H
 577 #include <builtin.h>
 578 #endif
 579
 580 #else
 581
 582 #if $cf_cv_header_stdbool_h
 583 #include <stdbool.h>
 584 #endif
 585
 586 #endif
 587
 588 int main()
 589 {
 590         FILE *fp = fopen("cf_test.out", "w");
 591         if (fp != 0) {
 592                 bool x = true;
 593                 if ((bool)(-x) >= 0)
 594                         fputs("unsigned ", fp);
 595                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 596                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 597                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 598                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 599                 fclose(fp);
 600         }
 601         ${cf_cv_main_return:-return}(0);
 602 }
 603                 ],
 604                 [cf_cv_type_of_bool=`cat cf_test.out`
 605                  if test -z "$cf_cv_type_of_bool"; then
 606                    cf_cv_type_of_bool=unknown
 607                  fi],
 608                 [cf_cv_type_of_bool=unknown],
 609                 [cf_cv_type_of_bool=unknown])
 610         ])
 611         rm -f cf_test.out
 612 AC_MSG_RESULT($cf_cv_type_of_bool)
 613 if test "$cf_cv_type_of_bool" = unknown ; then
 614         case .$NCURSES_BOOL in
 615         (.auto|.) NCURSES_BOOL=unsigned;;
 616         esac
 617         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 618         cf_cv_type_of_bool=$NCURSES_BOOL
 619 fi
 620 ])dnl
 621 dnl ---------------------------------------------------------------------------
 622 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 623 dnl -----------
 624 dnl If we're cross-compiling, allow the user to override the tools and their
 625 dnl options.  The configure script is oriented toward identifying the host
 626 dnl compiler, etc., but we need a build compiler to generate parts of the
 627 dnl source.
 628 dnl
 629 dnl $1 = default for $CPPFLAGS
 630 dnl $2 = default for $LIBS
 631 AC_DEFUN([CF_BUILD_CC],[
 632 CF_ACVERSION_CHECK(2.52,,
 633         [AC_REQUIRE([CF_PROG_EXT])])
 634 if test "$cross_compiling" = yes ; then
 635
 636         # defaults that we might want to override
 637         : ${BUILD_CFLAGS:=''}
 638         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 639         : ${BUILD_LDFLAGS:=''}
 640         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 641         : ${BUILD_EXEEXT:='$x'}
 642         : ${BUILD_OBJEXT:='o'}
 643
 644         AC_ARG_WITH(build-cc,
 645                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 646                 [BUILD_CC="$withval"],
 647                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 648         AC_MSG_CHECKING(for native build C compiler)
 649         AC_MSG_RESULT($BUILD_CC)
 650
 651         AC_MSG_CHECKING(for native build C preprocessor)
 652         AC_ARG_WITH(build-cpp,
 653                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 654                 [BUILD_CPP="$withval"],
 655                 [BUILD_CPP='${BUILD_CC} -E'])
 656         AC_MSG_RESULT($BUILD_CPP)
 657
 658         AC_MSG_CHECKING(for native build C flags)
 659         AC_ARG_WITH(build-cflags,
 660                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 661                 [BUILD_CFLAGS="$withval"])
 662         AC_MSG_RESULT($BUILD_CFLAGS)
 663
 664         AC_MSG_CHECKING(for native build C preprocessor-flags)
 665         AC_ARG_WITH(build-cppflags,
 666                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 667                 [BUILD_CPPFLAGS="$withval"])
 668         AC_MSG_RESULT($BUILD_CPPFLAGS)
 669
 670         AC_MSG_CHECKING(for native build linker-flags)
 671         AC_ARG_WITH(build-ldflags,
 672                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 673                 [BUILD_LDFLAGS="$withval"])
 674         AC_MSG_RESULT($BUILD_LDFLAGS)
 675
 676         AC_MSG_CHECKING(for native build linker-libraries)
 677         AC_ARG_WITH(build-libs,
 678                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 679                 [BUILD_LIBS="$withval"])
 680         AC_MSG_RESULT($BUILD_LIBS)
 681
 682         # this assumes we're on Unix.
 683         BUILD_EXEEXT=
 684         BUILD_OBJEXT=o
 685
 686         : ${BUILD_CC:='${CC}'}
 687
 688         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 689                 AC_MSG_ERROR([Cross-build requires two compilers.
 690 Use --with-build-cc to specify the native compiler.])
 691         fi
 692
 693 else
 694         : ${BUILD_CC:='${CC}'}
 695         : ${BUILD_CPP:='${CPP}'}
 696         : ${BUILD_CFLAGS:='${CFLAGS}'}
 697         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 698         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 699         : ${BUILD_LIBS:='${LIBS}'}
 700         : ${BUILD_EXEEXT:='$x'}
 701         : ${BUILD_OBJEXT:='o'}
 702 fi
 703
 704 AC_SUBST(BUILD_CC)
 705 AC_SUBST(BUILD_CPP)
 706 AC_SUBST(BUILD_CFLAGS)
 707 AC_SUBST(BUILD_CPPFLAGS)
 708 AC_SUBST(BUILD_LDFLAGS)
 709 AC_SUBST(BUILD_LIBS)
 710 AC_SUBST(BUILD_EXEEXT)
 711 AC_SUBST(BUILD_OBJEXT)
 712 ])dnl
 713 dnl ---------------------------------------------------------------------------
 714 dnl CF_CC_ENV_FLAGS version: 2 updated: 2015/04/12 15:39:00
 715 dnl ---------------
 716 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 717 dnl into CC.  This will not help with broken scripts that wrap the compiler with
 718 dnl options, but eliminates a more common category of user confusion.
 719 AC_DEFUN([CF_CC_ENV_FLAGS],
 720 [
 721 # This should have been defined by AC_PROG_CC
 722 : ${CC:=cc}
 723
 724 AC_MSG_CHECKING(\$CC variable)
 725 case "$CC" in
 726 (*[[\ \ ]]-[[IUD]]*)
 727         AC_MSG_RESULT(broken)
 728         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 729         # humor him...
 730         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 731         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 732         CF_ADD_CFLAGS($cf_flags)
 733         ;;
 734 (*)
 735         AC_MSG_RESULT(ok)
 736         ;;
 737 esac
 738 ])dnl
 739 dnl ---------------------------------------------------------------------------
 740 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 741 dnl ---------------
 742 dnl Determine the default configuration into which we'll install ncurses.  This
 743 dnl can be overridden by the user's command-line options.  There's two items to
 744 dnl look for:
 745 dnl     1. the prefix (e.g., /usr)
 746 dnl     2. the header files (e.g., /usr/include/ncurses)
 747 dnl We'll look for a previous installation of ncurses and use the same defaults.
 748 dnl
 749 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 750 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 751 dnl programs from a vendor's.
 752 AC_DEFUN([CF_CFG_DEFAULTS],
 753 [
 754 AC_MSG_CHECKING(for prefix)
 755 if test "x$prefix" = "xNONE" ; then
 756         case "$cf_cv_system_name" in
 757                 # non-vendor systems don't have a conflict
 758         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 759                 prefix=/usr
 760                 ;;
 761         (*)     prefix=$ac_default_prefix
 762                 ;;
 763         esac
 764 fi
 765 AC_MSG_RESULT($prefix)
 766
 767 if test "x$prefix" = "xNONE" ; then
 768 AC_MSG_CHECKING(for default include-directory)
 769 test -n "$verbose" && echo 1>&AC_FD_MSG
 770 for cf_symbol in \
 771         $includedir \
 772         $includedir/ncurses \
 773         $prefix/include \
 774         $prefix/include/ncurses \
 775         /usr/local/include \
 776         /usr/local/include/ncurses \
 777         /usr/include \
 778         /usr/include/ncurses
 779 do
 780         cf_dir=`eval echo $cf_symbol`
 781         if test -f $cf_dir/curses.h ; then
 782         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 783                 includedir="$cf_symbol"
 784                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 785                 break
 786         fi
 787         fi
 788         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 789 done
 790 AC_MSG_RESULT($includedir)
 791 fi
 792 ])dnl
 793 dnl ---------------------------------------------------------------------------
 794 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
 795 dnl ----------
 796 dnl Check if the terminal-capability database functions are available.  If not,
 797 dnl ncurses has a much-reduced version.
 798 AC_DEFUN([CF_CGETENT],[
 799 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 800 AC_TRY_LINK([
 801 #include <stdlib.h>],[
 802         char temp[128];
 803         char *buf = temp;
 804         char *db_array = temp;
 805         cgetent(&buf, &db_array, "vt100");
 806         cgetcap(buf, "tc", '=');
 807         cgetmatch(buf, "tc");
 808         ],
 809         [cf_cv_cgetent=yes],
 810         [cf_cv_cgetent=no])
 811 ])
 812
 813 if test "$cf_cv_cgetent" = yes
 814 then
 815         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 816 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 817 AC_TRY_LINK([
 818 #include <stdlib.h>],[
 819         char temp[128];
 820         char *buf = temp;
 821 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 822         const char *db_array = temp;
 823         cgetent(&buf, &db_array, "vt100");
 824 #endif
 825         cgetcap(buf, "tc", '=');
 826         cgetmatch(buf, "tc");
 827         ],
 828         [cf_cv_cgetent_const=yes],
 829         [cf_cv_cgetent_const=no])
 830 ])
 831         if test "$cf_cv_cgetent_const" = yes
 832         then
 833                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 834         fi
 835 fi
 836 ])dnl
 837 dnl ---------------------------------------------------------------------------
 838 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 839 dnl --------------
 840 dnl Check if we're accidentally using a cache from a different machine.
 841 dnl Derive the system name, as a check for reusing the autoconf cache.
 842 dnl
 843 dnl If we've packaged config.guess and config.sub, run that (since it does a
 844 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 845 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 846 dnl which is useful in cross-compiles.
 847 dnl
 848 dnl Note: we would use $ac_config_sub, but that is one of the places where
 849 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 850 AC_DEFUN([CF_CHECK_CACHE],
 851 [
 852 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 853         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 854         system_name="$host_os"
 855 else
 856         system_name="`(uname -s -r) 2>/dev/null`"
 857         if test -z "$system_name" ; then
 858                 system_name="`(hostname) 2>/dev/null`"
 859         fi
 860 fi
 861 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 862 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 863
 864 test -z "$system_name" && system_name="$cf_cv_system_name"
 865 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 866
 867 if test ".$system_name" != ".$cf_cv_system_name" ; then
 868         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 869         AC_MSG_ERROR("Please remove config.cache and try again.")
 870 fi
 871 ])dnl
 872 dnl ---------------------------------------------------------------------------
 873 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
 874 dnl --------------
 875 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 876 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 877 dnl ourselves.
 878 dnl
 879 dnl $1 = the name to check
 880 dnl $2 = the assumed type
 881 AC_DEFUN([CF_CHECK_ERRNO],
 882 [
 883 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 884         AC_TRY_COMPILE([
 885 #ifdef HAVE_STDLIB_H
 886 #include <stdlib.h>
 887 #endif
 888 #include <stdio.h>
 889 #include <sys/types.h>
 890 #include <errno.h> ],
 891         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 892         [cf_cv_dcl_$1=yes],
 893         [cf_cv_dcl_$1=no])
 894 ])
 895
 896 if test "$cf_cv_dcl_$1" = no ; then
 897         CF_UPPER(cf_result,decl_$1)
 898         AC_DEFINE_UNQUOTED($cf_result)
 899 fi
 900
 901 # It's possible (for near-UNIX clones) that the data doesn't exist
 902 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 903 ])dnl
 904 dnl ---------------------------------------------------------------------------
 905 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
 906 dnl --------------------
 907 dnl Check for existence of external data in the current set of libraries.  If
 908 dnl we can modify it, it's real enough.
 909 dnl $1 = the name to check
 910 dnl $2 = its type
 911 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 912 [
 913 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 914         AC_TRY_LINK([
 915 #undef $1
 916 extern $2 $1;
 917 ],
 918         [$1 = 2],
 919         [cf_cv_have_$1=yes],
 920         [cf_cv_have_$1=no])
 921 ])
 922
 923 if test "$cf_cv_have_$1" = yes ; then
 924         CF_UPPER(cf_result,have_$1)
 925         AC_DEFINE_UNQUOTED($cf_result)
 926 fi
 927
 928 ])dnl
 929 dnl ---------------------------------------------------------------------------
 930 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 931 dnl -------------------
 932 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 933 dnl is not "weak" - warn about this because it can create problems linking
 934 dnl applications with ncurses.
 935 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 936 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 937
 938 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 939 cf_cv_check_gpm_wgetch=unknown
 940 if test "$cross_compiling" != yes ; then
 941
 942 cat >conftest.$ac_ext <<CF_EOF
 943 #include <gpm.h>
 944 int main()
 945 {
 946         Gpm_Wgetch();
 947         ${cf_cv_main_return:-return}(0);
 948 }
 949 CF_EOF
 950
 951         cf_save_LIBS="$LIBS"
 952         # This only works if we can look at the symbol table.  If a shared
 953         # library is stripped for install, we cannot use that.  So we're forced
 954         # to rely on the static library, noting that some packagers may not
 955         # include it.
 956         LIBS="-static -lgpm -dynamic $LIBS"
 957         if AC_TRY_EVAL(ac_compile) ; then
 958                 if AC_TRY_EVAL(ac_link) ; then
 959                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 960                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 961                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 962                 fi
 963         fi
 964         rm -rf conftest*
 965         LIBS="$cf_save_LIBS"
 966 fi
 967 ])
 968
 969 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 970         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 971 fi
 972 ])])dnl
 973 dnl ---------------------------------------------------------------------------
 974 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
 975 dnl ------------------------
 976 dnl Show the version of libtool
 977 dnl
 978 dnl Save the version in a cache variable - this is not entirely a good thing,
 979 dnl but the version string from libtool is very ugly, and for bug reports it
 980 dnl might be useful to have the original string.
 981 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
 982 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
 983 then
 984         AC_MSG_CHECKING(version of $LIBTOOL)
 985         CF_LIBTOOL_VERSION
 986         AC_MSG_RESULT($cf_cv_libtool_version)
 987         if test -z "$cf_cv_libtool_version" ; then
 988                 AC_MSG_ERROR(This is not GNU libtool)
 989         fi
 990 else
 991         AC_MSG_ERROR(GNU libtool has not been found)
 992 fi
 993 ])dnl
 994 dnl ---------------------------------------------------------------------------
 995 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
 996 dnl ----------------
 997 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
 998 AC_DEFUN([CF_CHECK_WCHAR_H],[
 999 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1000 AC_TRY_COMPILE(
1001 [
1002 #include <stdlib.h>
1003 #include <wchar.h>
1004 ],[
1005         wint_t foo = 0;
1006         int bar = iswpunct(foo)],
1007         [cf_cv_wchar_h_okay=yes],
1008         [cf_cv_wchar_h_okay=no])])
1009
1010 if test $cf_cv_wchar_h_okay = no
1011 then
1012         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1013 fi
1014 ])dnl
1015 dnl ---------------------------------------------------------------------------
1016 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1017 dnl -----------------
1018 dnl Check if the given compiler is really clang.  clang's C driver defines
1019 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1020 dnl not ignore some gcc options.
1021 dnl
1022 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1023 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1024 dnl the wrappers for gcc and g++ warnings.
1025 dnl
1026 dnl $1 = GCC (default) or GXX
1027 dnl $2 = CLANG_COMPILER (default)
1028 dnl $3 = CFLAGS (default) or CXXFLAGS
1029 AC_DEFUN([CF_CLANG_COMPILER],[
1030 ifelse([$2],,CLANG_COMPILER,[$2])=no
1031
1032 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1033         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1034         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1035         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1036         AC_TRY_COMPILE([],[
1037 #ifdef __clang__
1038 #else
1039 make an error
1040 #endif
1041 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1042 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1043 ],[])
1044         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1045         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1046 fi
1047 ])
1048 dnl ---------------------------------------------------------------------------
1049 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
1050 dnl -----------------
1051 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1052 dnl is a late feature for the standard and is not in some recent compilers
1053 dnl (1999/9/11).
1054 AC_DEFUN([CF_CPP_PARAM_INIT],
1055 [
1056 if test -n "$CXX"; then
1057 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1058         AC_LANG_SAVE
1059         AC_LANG_CPLUSPLUS
1060         AC_TRY_RUN([
1061 class TEST {
1062 private:
1063         int value;
1064 public:
1065         TEST(int x = 1);
1066         ~TEST();
1067 };
1068
1069 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1070 {
1071         value = x;
1072 }
1073 int main() { }
1074 ],
1075         [cf_cv_cpp_param_init=yes],
1076         [cf_cv_cpp_param_init=no],
1077         [cf_cv_cpp_param_init=unknown])
1078         AC_LANG_RESTORE
1079 ])
1080 fi
1081 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1082 ])dnl
1083 dnl ---------------------------------------------------------------------------
1084 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1085 dnl ------------------
1086 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1087 dnl not be supported in g++ before 3.0
1088 AC_DEFUN([CF_CPP_STATIC_CAST],
1089 [
1090 if test -n "$CXX"; then
1091
1092 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1093         AC_LANG_SAVE
1094         AC_LANG_CPLUSPLUS
1095
1096         AC_TRY_COMPILE([
1097 class NCursesPanel
1098 {
1099 public:
1100   NCursesPanel(int nlines,
1101                int ncols,
1102                int begin_y = 0,
1103                int begin_x = 0)
1104   {
1105   }
1106   NCursesPanel();
1107   ~NCursesPanel();
1108 };
1109
1110 template<class T> class NCursesUserPanel : public NCursesPanel
1111 {
1112 public:
1113   NCursesUserPanel (int nlines,
1114                     int ncols,
1115                     int begin_y = 0,
1116                     int begin_x = 0,
1117                     const T* p_UserData = static_cast<T*>(0))
1118     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1119   {
1120   };
1121   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1122   {
1123   };
1124
1125   virtual ~NCursesUserPanel() {};
1126 };
1127 ],[
1128         const char* p_UserData = static_cast<char*>(0)],
1129         [cf_cv_cpp_static_cast=yes],
1130         [cf_cv_cpp_static_cast=no])
1131
1132         AC_LANG_RESTORE
1133 ])
1134
1135 fi
1136
1137 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1138 ])dnl
1139 dnl ---------------------------------------------------------------------------
1140 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1141 dnl ---------------
1142 dnl Setup special archiver flags for given compilers.
1143 AC_DEFUN([CF_CXX_AR_FLAGS],[
1144         CXX_AR='$(AR)'
1145         CXX_ARFLAGS='$(ARFLAGS)'
1146         case $cf_cv_system_name in
1147         (irix*)
1148             if test "$GXX" != yes ; then
1149                 CXX_AR='$(CXX)'
1150                 CXX_ARFLAGS='-ar -o'
1151             fi
1152             ;;
1153         (sco3.2v5*)
1154             CXXLDFLAGS="-u main"
1155             ;;
1156         (solaris2*)
1157             if test "$GXX" != yes ; then
1158                 CXX_AR='$(CXX)'
1159                 CXX_ARFLAGS='-xar -o'
1160             fi
1161             ;;
1162         esac
1163         AC_SUBST(CXXLDFLAGS)
1164         AC_SUBST(CXX_AR)
1165         AC_SUBST(CXX_ARFLAGS)
1166 ])dnl
1167 dnl ---------------------------------------------------------------------------
1168 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1169 dnl -------------------------
1170 dnl For c++, check if iostream uses "std::" namespace.
1171 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1172 AC_CHECK_HEADERS(iostream)
1173 if test x"$ac_cv_header_iostream" = xyes ; then
1174         AC_MSG_CHECKING(if iostream uses std-namespace)
1175         AC_TRY_COMPILE([
1176 #include <iostream>
1177 using std::endl;
1178 using std::cerr;],[
1179 cerr << "testing" << endl;
1180 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1181         AC_MSG_RESULT($cf_iostream_namespace)
1182         if test "$cf_iostream_namespace" = yes ; then
1183                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1184         fi
1185 fi
1186 ])dnl
1187 dnl ---------------------------------------------------------------------------
1188 dnl CF_C_INLINE version: 5 updated: 2015/04/18 08:56:57
1189 dnl -----------
1190 dnl Check if the C compiler supports "inline".
1191 dnl $1 is the name of a shell variable to set if inline is supported
1192 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1193 AC_DEFUN([CF_C_INLINE],[
1194 AC_C_INLINE
1195 $1=
1196 if test "$ac_cv_c_inline" != no ; then
1197         $1=inline
1198         if test "$INTEL_COMPILER" = yes
1199         then
1200                 :
1201         elif test "$CLANG_COMPILER" = yes
1202         then
1203                 :
1204         elif test "$GCC" = yes
1205         then
1206                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1207                 cf_save_CFLAGS=$CFLAGS
1208                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1209                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1210                 [${cf_cv_main_return:-return} foo()],
1211                 [cf_cv_gcc_inline=yes],
1212                 [cf_cv_gcc_inline=no])
1213                 CFLAGS=$cf_save_CFLAGS
1214                 ])
1215                 if test "$cf_cv_gcc_inline" = yes ; then
1216                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1217                 fi
1218         fi
1219 fi
1220 AC_SUBST($1)
1221 ])dnl
1222 dnl ---------------------------------------------------------------------------
1223 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1224 dnl ----------
1225 dnl "dirname" is not portable, so we fake it with a shell script.
1226 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1227 dnl ---------------------------------------------------------------------------
1228 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1229 dnl ---------------
1230 AC_DEFUN([CF_DIRS_TO_MAKE],
1231 [
1232 DIRS_TO_MAKE="lib"
1233 for cf_item in $cf_list_models
1234 do
1235         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1236         for cf_item2 in $DIRS_TO_MAKE
1237         do
1238                 test $cf_item2 = $cf_subdir && break
1239         done
1240         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1241 done
1242 for cf_dir in $DIRS_TO_MAKE
1243 do
1244         test ! -d $cf_dir && mkdir $cf_dir
1245 done
1246 AC_SUBST(DIRS_TO_MAKE)
1247 ])dnl
1248 dnl ---------------------------------------------------------------------------
1249 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1250 dnl ---------------
1251 dnl You can always use "make -n" to see the actual options, but it's hard to
1252 dnl pick out/analyze warning messages when the compile-line is long.
1253 dnl
1254 dnl Sets:
1255 dnl     ECHO_LT - symbol to control if libtool is verbose
1256 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1257 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1258 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1259 dnl     ECHO_CC - symbol to put before any "cc" line
1260 dnl
1261 AC_DEFUN([CF_DISABLE_ECHO],[
1262 AC_MSG_CHECKING(if you want to see long compiling messages)
1263 CF_ARG_DISABLE(echo,
1264         [  --disable-echo          do not display "compiling" commands],
1265         [
1266         ECHO_LT='--silent'
1267         ECHO_LD='@echo linking [$]@;'
1268         RULE_CC='@echo compiling [$]<'
1269         SHOW_CC='@echo compiling [$]@'
1270         ECHO_CC='@'
1271 ],[
1272         ECHO_LT=''
1273         ECHO_LD=''
1274         RULE_CC=''
1275         SHOW_CC=''
1276         ECHO_CC=''
1277 ])
1278 AC_MSG_RESULT($enableval)
1279 AC_SUBST(ECHO_LT)
1280 AC_SUBST(ECHO_LD)
1281 AC_SUBST(RULE_CC)
1282 AC_SUBST(SHOW_CC)
1283 AC_SUBST(ECHO_CC)
1284 ])dnl
1285 dnl ---------------------------------------------------------------------------
1286 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1287 dnl ------------------------
1288 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1289 AC_MSG_CHECKING(if we want to use GNAT projects)
1290 CF_ARG_DISABLE(gnat-projects,
1291         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1292         [enable_gnat_projects=no],
1293         [enable_gnat_projects=yes])
1294 AC_MSG_RESULT($enable_gnat_projects)
1295 ])dnl
1296 dnl ---------------------------------------------------------------------------
1297 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1298 dnl ----------------
1299 dnl Combine no-leak checks with the libraries or tools that are used for the
1300 dnl checks.
1301 AC_DEFUN([CF_DISABLE_LEAKS],[
1302
1303 AC_REQUIRE([CF_WITH_DMALLOC])
1304 AC_REQUIRE([CF_WITH_DBMALLOC])
1305 AC_REQUIRE([CF_WITH_VALGRIND])
1306
1307 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1308 AC_ARG_ENABLE(leaks,
1309         [  --disable-leaks         test: free permanent memory, analyze leaks],
1310         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1311         : ${with_no_leaks:=no})
1312 AC_MSG_RESULT($with_no_leaks)
1313
1314 if test "$with_no_leaks" = yes ; then
1315         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1316         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1317 fi
1318 ])dnl
1319 dnl ---------------------------------------------------------------------------
1320 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1321 dnl --------------------------
1322 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1323 dnl the older "-version-info" feature.  The newer feature allows us to use
1324 dnl version numbering on shared libraries which make them compatible with
1325 dnl various systems.
1326 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1327 [
1328 AC_MSG_CHECKING(if libtool -version-number should be used)
1329 CF_ARG_DISABLE(libtool-version,
1330         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1331         [cf_libtool_version=no],
1332         [cf_libtool_version=yes])
1333 AC_MSG_RESULT($cf_libtool_version)
1334
1335 if test "$cf_libtool_version" = yes ; then
1336         LIBTOOL_VERSION="-version-number"
1337 else
1338         LIBTOOL_VERSION="-version-info"
1339         case "x$VERSION" in
1340         (x)
1341                 AC_MSG_WARN(VERSION was not set)
1342                 ;;
1343         (x*.*.*)
1344                 ABI_VERSION="$VERSION"
1345                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1346                 ;;
1347         (x*:*:*)
1348                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1349                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1350                 ;;
1351         (*)
1352                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1353                 ;;
1354         esac
1355 fi
1356
1357 AC_SUBST(ABI_VERSION)
1358 AC_SUBST(LIBTOOL_VERSION)
1359 ])dnl
1360 dnl ---------------------------------------------------------------------------
1361 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1362 dnl ---------------------
1363 dnl The rpath-hack makes it simpler to build programs, particularly with the
1364 dnl *BSD ports which may have essential libraries in unusual places.  But it
1365 dnl can interfere with building an executable for the base system.  Use this
1366 dnl option in that case.
1367 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1368 [
1369 AC_MSG_CHECKING(if rpath-hack should be disabled)
1370 CF_ARG_DISABLE(rpath-hack,
1371         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1372         [cf_disable_rpath_hack=yes],
1373         [cf_disable_rpath_hack=no])
1374 AC_MSG_RESULT($cf_disable_rpath_hack)
1375 if test "$cf_disable_rpath_hack" = no ; then
1376         CF_RPATH_HACK
1377 fi
1378 ])
1379 dnl ---------------------------------------------------------------------------
1380 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1381 dnl ------------------
1382 dnl This is the "--enable-pc-files" option, which is available if there is a
1383 dnl pkg-config configuration on the local machine.
1384 AC_DEFUN([CF_ENABLE_PC_FILES],[
1385 AC_REQUIRE([CF_PKG_CONFIG])
1386 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1387
1388 if test "x$PKG_CONFIG" != xnone
1389 then
1390         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1391 else
1392         AC_MSG_CHECKING(if we should install .pc files)
1393 fi
1394
1395 AC_ARG_ENABLE(pc-files,
1396         [  --enable-pc-files       generate and install .pc files for pkg-config],
1397         [enable_pc_files=$enableval],
1398         [enable_pc_files=no])
1399 AC_MSG_RESULT($enable_pc_files)
1400
1401 if test "x$enable_pc_files" != xno
1402 then
1403         MAKE_PC_FILES=
1404         case "x$PKG_CONFIG_LIBDIR" in
1405         (xno|xyes)
1406                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1407                 ;;
1408         (*)
1409                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1410                 ;;
1411         esac
1412 else
1413         MAKE_PC_FILES="#"
1414 fi
1415 AC_SUBST(MAKE_PC_FILES)
1416 ])dnl
1417 dnl ---------------------------------------------------------------------------
1418 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1419 dnl ---------------
1420 dnl Check if the rpath option should be used, setting cache variable
1421 dnl cf_cv_enable_rpath if so.
1422 AC_DEFUN([CF_ENABLE_RPATH],
1423 [
1424 AC_MSG_CHECKING(if rpath option should be used)
1425 AC_ARG_ENABLE(rpath,
1426 [  --enable-rpath          use rpath option when generating shared libraries],
1427 [cf_cv_enable_rpath=$enableval],
1428 [cf_cv_enable_rpath=no])
1429 AC_MSG_RESULT($cf_cv_enable_rpath)
1430 ])dnl
1431 dnl ---------------------------------------------------------------------------
1432 dnl CF_ENABLE_STRING_HACKS version: 3 updated: 2013/01/26 16:26:12
1433 dnl ----------------------
1434 dnl On a few platforms, the compiler and/or loader nags with untruthful
1435 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1436 dnl and implying that most uses of the recommended alternatives are correct.
1437 dnl
1438 dnl Factually speaking, no one has actually counted the number of uses of these
1439 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1440 dnl instances are meaningless compared to the hundreds of millions of lines of
1441 dnl existing C code.
1442 dnl
1443 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1444 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1445 dnl standard - but evolved through phases, and older implementations are likely
1446 dnl to yield surprising results, as documented in manpages on various systems.
1447 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1448 [
1449 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1450 AC_ARG_ENABLE(string-hacks,
1451         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1452         [with_string_hacks=$enableval],
1453         [with_string_hacks=no])
1454 AC_MSG_RESULT($with_string_hacks)
1455
1456 if test "x$with_string_hacks" = "xyes"; then
1457         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1458         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1459         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1460 fi
1461 ])dnl
1462 dnl ---------------------------------------------------------------------------
1463 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1464 dnl --------
1465 dnl Check if 'errno' is declared in <errno.h>
1466 AC_DEFUN([CF_ERRNO],
1467 [
1468 CF_CHECK_ERRNO(errno)
1469 ])dnl
1470 dnl ---------------------------------------------------------------------------
1471 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1472 dnl ---------------
1473 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1474 dnl math.h and builtin.h, only for ncurses
1475 AC_DEFUN([CF_ETIP_DEFINES],
1476 [
1477 AC_MSG_CHECKING(for special defines needed for etip.h)
1478 cf_save_CXXFLAGS="$CXXFLAGS"
1479 cf_result="none"
1480
1481 # etip.h includes ncurses.h which includes ncurses_dll.h
1482 # But ncurses_dll.h is generated - fix here.
1483 test -d include || mkdir include
1484 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1485
1486 for cf_math in "" MATH_H
1487 do
1488 for cf_excp in "" MATH_EXCEPTION
1489 do
1490         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1491         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1492         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1493 AC_TRY_COMPILE([
1494 #include <etip.h.in>
1495 ],[],[
1496         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1497         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1498         cf_result="$cf_math $cf_excp"
1499         break 2
1500 ],[])
1501 done
1502 done
1503 AC_MSG_RESULT($cf_result)
1504 CXXFLAGS="$cf_save_CXXFLAGS"
1505 ])
1506 dnl ---------------------------------------------------------------------------
1507 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
1508 dnl ---------------
1509 dnl Find a library (specifically the linkage used in the code fragment),
1510 dnl searching for it if it is not already in the library path.
1511 dnl See also CF_ADD_SEARCHPATH.
1512 dnl
1513 dnl Parameters (4-on are optional):
1514 dnl     $1 = headers for library entrypoint
1515 dnl     $2 = code fragment for library entrypoint
1516 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1517 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1518 dnl     $5 = action to perform if not successful
1519 dnl     $6 = module name, if not the same as the library name
1520 dnl     $7 = extra libraries
1521 dnl
1522 dnl Sets these variables:
1523 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1524 dnl     $cf_cv_header_path_$3 - include-directory if needed
1525 dnl     $cf_cv_library_path_$3 - library-directory if needed
1526 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1527 AC_DEFUN([CF_FIND_LINKAGE],[
1528
1529 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1530 # will be set on completion of the AC_TRY_LINK below.
1531 cf_cv_header_path_$3=
1532 cf_cv_library_path_$3=
1533
1534 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1535
1536 cf_save_LIBS="$LIBS"
1537
1538 AC_TRY_LINK([$1],[$2],[
1539         cf_cv_find_linkage_$3=yes
1540         cf_cv_header_path_$3=/usr/include
1541         cf_cv_library_path_$3=/usr/lib
1542 ],[
1543
1544 LIBS="-l$3 $7 $cf_save_LIBS"
1545
1546 AC_TRY_LINK([$1],[$2],[
1547         cf_cv_find_linkage_$3=yes
1548         cf_cv_header_path_$3=/usr/include
1549         cf_cv_library_path_$3=/usr/lib
1550         cf_cv_library_file_$3="-l$3"
1551 ],[
1552         cf_cv_find_linkage_$3=no
1553         LIBS="$cf_save_LIBS"
1554
1555         CF_VERBOSE(find linkage for $3 library)
1556         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1557
1558         cf_save_CPPFLAGS="$CPPFLAGS"
1559         cf_test_CPPFLAGS="$CPPFLAGS"
1560
1561         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1562         for cf_cv_header_path_$3 in $cf_search
1563         do
1564                 if test -d $cf_cv_header_path_$3 ; then
1565                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1566                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1567                         AC_TRY_COMPILE([$1],[$2],[
1568                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1569                                 cf_cv_find_linkage_$3=maybe
1570                                 cf_test_CPPFLAGS="$CPPFLAGS"
1571                                 break],[
1572                                 CPPFLAGS="$cf_save_CPPFLAGS"
1573                                 ])
1574                 fi
1575         done
1576
1577         if test "$cf_cv_find_linkage_$3" = maybe ; then
1578
1579                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1580
1581                 cf_save_LIBS="$LIBS"
1582                 cf_save_LDFLAGS="$LDFLAGS"
1583
1584                 ifelse([$6],,,[
1585                 CPPFLAGS="$cf_test_CPPFLAGS"
1586                 LIBS="-l$3 $7 $cf_save_LIBS"
1587                 AC_TRY_LINK([$1],[$2],[
1588                         CF_VERBOSE(... found $3 library in system)
1589                         cf_cv_find_linkage_$3=yes])
1590                         CPPFLAGS="$cf_save_CPPFLAGS"
1591                         LIBS="$cf_save_LIBS"
1592                         ])
1593
1594                 if test "$cf_cv_find_linkage_$3" != yes ; then
1595                         CF_LIBRARY_PATH(cf_search,$3)
1596                         for cf_cv_library_path_$3 in $cf_search
1597                         do
1598                                 if test -d $cf_cv_library_path_$3 ; then
1599                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1600                                         CPPFLAGS="$cf_test_CPPFLAGS"
1601                                         LIBS="-l$3 $7 $cf_save_LIBS"
1602                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1603                                         AC_TRY_LINK([$1],[$2],[
1604                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1605                                         cf_cv_find_linkage_$3=yes
1606                                         cf_cv_library_file_$3="-l$3"
1607                                         break],[
1608                                         CPPFLAGS="$cf_save_CPPFLAGS"
1609                                         LIBS="$cf_save_LIBS"
1610                                         LDFLAGS="$cf_save_LDFLAGS"
1611                                         ])
1612                                 fi
1613                         done
1614                         CPPFLAGS="$cf_save_CPPFLAGS"
1615                         LDFLAGS="$cf_save_LDFLAGS"
1616                 fi
1617
1618         else
1619                 cf_cv_find_linkage_$3=no
1620         fi
1621         ],$7)
1622 ])
1623
1624 LIBS="$cf_save_LIBS"
1625
1626 if test "$cf_cv_find_linkage_$3" = yes ; then
1627 ifelse([$4],,[
1628         CF_ADD_INCDIR($cf_cv_header_path_$3)
1629         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1630         CF_ADD_LIB($3)
1631 ],[$4])
1632 else
1633 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1634 fi
1635 ])dnl
1636 dnl ---------------------------------------------------------------------------
1637 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
1638 dnl ------------------
1639 dnl Find an include-directory with the given leaf-name.  This is useful for
1640 dnl example with FreeBSD ports, which use this convention to distinguish
1641 dnl different versions of the same port.
1642 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1643         CF_SUBDIR_PATH(cf_search,$1,include)
1644         for cf_item in $cf_search
1645         do
1646                 case $cf_item in
1647                 (*/$1)
1648                         CF_ADD_INCDIR($cf_item)
1649                         ;;
1650                 esac
1651         done
1652 ])dnl
1653 dnl ---------------------------------------------------------------------------
1654 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
1655 dnl ------------------
1656 dnl Find a library-directory with the given leaf-name.  This is useful for
1657 dnl example with FreeBSD ports, which use this convention to distinguish
1658 dnl different versions of the same port.
1659 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1660         CF_SUBDIR_PATH(cf_search,$1,lib)
1661         for cf_item in $cf_search
1662         do
1663                 case $cf_item in
1664                 (*/$1)
1665                         CF_ADD_LIBDIR($cf_item)
1666                         ;;
1667                 esac
1668         done
1669 ])dnl
1670 dnl ---------------------------------------------------------------------------
1671 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1672 dnl -----------------
1673 dnl make ADAFLAGS consistent with CFLAGS
1674 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1675         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1676         case "$CFLAGS" in
1677         (*-g*)
1678                 CF_ADD_ADAFLAGS(-g)
1679                 ;;
1680         esac
1681         case "$CFLAGS" in
1682         (*-O*)
1683                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1684                 CF_ADD_ADAFLAGS($cf_O_flag)
1685                 ;;
1686         esac
1687         AC_MSG_RESULT($ADAFLAGS)
1688 ])dnl
1689 dnl ---------------------------------------------------------------------------
1690 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1691 dnl --------------
1692 dnl Forget that we saw the given tool.
1693 AC_DEFUN([CF_FORGET_TOOL],[
1694 unset ac_cv_prog_ac_ct_$1
1695 unset ac_ct_$1
1696 unset $1
1697 ])dnl
1698 dnl ---------------------------------------------------------------------------
1699 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
1700 dnl -------------
1701 dnl Test for dlsym() and related functions, as well as libdl.
1702 dnl
1703 dnl Sets
1704 dnl     $cf_have_dlsym
1705 dnl     $cf_have_libdl
1706 AC_DEFUN([CF_FUNC_DLSYM],[
1707 cf_have_dlsym=no
1708 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1709
1710 cf_have_libdl=no
1711 AC_CHECK_LIB(dl,dlsym,[
1712         cf_have_dlsym=yes
1713         cf_have_libdl=yes])])
1714
1715 if test "$cf_have_dlsym" = yes ; then
1716         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
1717
1718         AC_MSG_CHECKING(whether able to link to dl*() functions)
1719         AC_TRY_LINK([#include <dlfcn.h>],[
1720                 void *obj;
1721                 if ((obj = dlopen("filename", 0)) != 0) {
1722                         if (dlsym(obj, "symbolname") == 0) {
1723                         dlclose(obj);
1724                         }
1725                 }],[
1726                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1727                 AC_MSG_ERROR(Cannot link test program for libdl)])
1728         AC_MSG_RESULT(ok)
1729 else
1730         AC_MSG_ERROR(Cannot find dlsym function)
1731 fi
1732 ])
1733 dnl ---------------------------------------------------------------------------
1734 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1735 dnl ---------------
1736 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1737 dnl is found, add our own version of memmove to the list of objects.
1738 AC_DEFUN([CF_FUNC_MEMMOVE],
1739 [
1740 AC_CHECK_FUNC(memmove,,[
1741 AC_CHECK_FUNC(bcopy,[
1742         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1743                 AC_TRY_RUN([
1744 int main() {
1745         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1746         char temp[40];
1747         bcopy(data, temp, sizeof(data));
1748         bcopy(temp+10, temp, 15);
1749         bcopy(temp+5, temp+15, 10);
1750         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1751 }
1752                 ],
1753                 [cf_cv_good_bcopy=yes],
1754                 [cf_cv_good_bcopy=no],
1755                 [cf_cv_good_bcopy=unknown])
1756                 ])
1757         ],[cf_cv_good_bcopy=no])
1758         if test "$cf_cv_good_bcopy" = yes ; then
1759                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1760         else
1761                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1762         fi
1763 ])])dnl
1764 dnl ---------------------------------------------------------------------------
1765 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1766 dnl -----------------
1767 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1768 dnl AIX 4.x, provide a non-working version.
1769 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1770 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1771 AC_TRY_RUN([
1772 #include <stdio.h>
1773 #include <errno.h>
1774 #include <time.h>
1775
1776 #ifdef HAVE_SYS_TIME_H
1777 #include <sys/time.h>
1778 #endif
1779
1780 int main() {
1781         struct timespec ts1, ts2;
1782         int code;
1783         ts1.tv_sec  = 0;
1784         ts1.tv_nsec = 750000000;
1785         ts2.tv_sec  = 0;
1786         ts2.tv_nsec = 0;
1787         errno = 0;
1788         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1789         ${cf_cv_main_return:-return}(code != 0);
1790 }
1791 ],
1792         [cf_cv_func_nanosleep=yes],
1793         [cf_cv_func_nanosleep=no],
1794         [cf_cv_func_nanosleep=unknown])])
1795
1796 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1797 ])
1798 dnl ---------------------------------------------------------------------------
1799 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
1800 dnl ---------------
1801 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1802 dnl "util" library as well.
1803 AC_DEFUN([CF_FUNC_OPENPTY],
1804 [
1805 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1806 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1807         cf_save_LIBS="$LIBS"
1808         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
1809         for cf_header in pty.h libutil.h util.h
1810         do
1811         AC_TRY_LINK([
1812 #include <$cf_header>
1813 ],[
1814         int x = openpty((int *)0, (int *)0, (char *)0,
1815                                    (struct termios *)0, (struct winsize *)0);
1816 ],[
1817                 cf_cv_func_openpty=$cf_header
1818                 break
1819 ],[
1820                 cf_cv_func_openpty=no
1821 ])
1822         done
1823         LIBS="$cf_save_LIBS"
1824 ])
1825 ])dnl
1826 dnl ---------------------------------------------------------------------------
1827 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
1828 dnl ------------
1829 dnl See if the poll function really works.  Some platforms have poll(), but
1830 dnl it does not work for terminals or files.
1831 AC_DEFUN([CF_FUNC_POLL],[
1832 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
1833 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1834 AC_TRY_RUN([
1835 #include <stdlib.h>
1836 #include <stdio.h>
1837 #include <unistd.h>
1838 #include <fcntl.h>
1839 #ifdef HAVE_POLL_H
1840 #include <poll.h>
1841 #else
1842 #include <sys/poll.h>
1843 #endif
1844 int main(void) {
1845         struct pollfd myfds;
1846         int ret;
1847
1848         /* check for Darwin bug with respect to "devices" */
1849         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
1850         if (myfds.fd < 0)
1851                 myfds.fd = 0;
1852         myfds.events = POLLIN;
1853         myfds.revents = 0;
1854
1855         ret = poll(&myfds, 1, 100);
1856
1857         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1858                 ret = -1;
1859         } else {
1860                 int fd = 0;
1861                 if (!isatty(fd)) {
1862                         fd = open("/dev/tty", 2);       /* O_RDWR */
1863                 }
1864 #ifdef HAVE_POSIX_OPENPT
1865                 if (fd < 0) {
1866                         fd = posix_openpt(O_RDWR);
1867                 }
1868 #endif
1869
1870                 if (fd >= 0) {
1871                         /* also check with standard input */
1872                         myfds.fd = fd;
1873                         myfds.events = POLLIN;
1874                         myfds.revents = 0;
1875                         ret = poll(&myfds, 1, 100);
1876                 } else {
1877                         ret = -1;
1878                 }
1879         }
1880         ${cf_cv_main_return:-return}(ret < 0);
1881 }],
1882         [cf_cv_working_poll=yes],
1883         [cf_cv_working_poll=no],
1884         [cf_cv_working_poll=unknown])])
1885 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
1886 ])dnl
1887 dnl ---------------------------------------------------------------------------
1888 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
1889 dnl ---------------
1890 dnl Some old/broken variations define tcgetattr() only as a macro in
1891 dnl termio(s).h
1892 AC_DEFUN([CF_FUNC_TERMIOS],[
1893 AC_REQUIRE([CF_STRUCT_TERMIOS])
1894 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1895 AC_TRY_LINK([
1896 #include <sys/types.h>
1897 #ifdef HAVE_UNISTD_H
1898 #include <unistd.h>
1899 #endif
1900 #ifdef HAVE_TERMIOS_H
1901 #include <termios.h>
1902 #define TTY struct termios
1903 #else
1904 #ifdef HAVE_TERMIO_H
1905 #include <termio.h>
1906 #define TTY struct termio
1907 #endif
1908 #endif
1909 ],[
1910 TTY foo;
1911 tcgetattr(1, &foo);],
1912 [cf_cv_have_tcgetattr=yes],
1913 [cf_cv_have_tcgetattr=no])])
1914 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
1915 ])dnl
1916 dnl ---------------------------------------------------------------------------
1917 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
1918 dnl ---------------
1919 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1920 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1921 dnl other functions.
1922 AC_DEFUN([CF_FUNC_VSSCANF],
1923 [
1924 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1925 AC_TRY_LINK([
1926 #include <stdarg.h>
1927 #include <stdio.h>],[
1928         va_list ap;
1929         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1930 AC_TRY_LINK([
1931 #include <stdarg.h>
1932 #include <stdio.h>],[
1933         FILE strbuf;
1934         char *str = "from";
1935
1936         strbuf._flag = _IOREAD;
1937         strbuf._ptr = strbuf._base = (unsigned char *) str;
1938         strbuf._cnt = strlen(str);
1939         strbuf._file = _NFILE;
1940         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1941 AC_TRY_LINK([
1942 #include <stdarg.h>
1943 #include <stdio.h>],[
1944         FILE strbuf;
1945         char *str = "from";
1946
1947         strbuf._flag = _IOREAD;
1948         strbuf._ptr = strbuf._base = (unsigned char *) str;
1949         strbuf._cnt = strlen(str);
1950         strbuf._file = _NFILE;
1951         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1952 cf_cv_func_vsscanf=no])])])])
1953
1954 case $cf_cv_func_vsscanf in
1955 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
1956 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
1957 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
1958 esac
1959
1960 ])dnl
1961 dnl ---------------------------------------------------------------------------
1962 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
1963 dnl -----------------
1964 dnl Test for availability of useful gcc __attribute__ directives to quiet
1965 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1966 dnl to documentation, unrecognized directives cause older compilers to barf.
1967 AC_DEFUN([CF_GCC_ATTRIBUTES],
1968 [
1969 if test "$GCC" = yes
1970 then
1971 cat > conftest.i <<EOF
1972 #ifndef GCC_PRINTF
1973 #define GCC_PRINTF 0
1974 #endif
1975 #ifndef GCC_SCANF
1976 #define GCC_SCANF 0
1977 #endif
1978 #ifndef GCC_NORETURN
1979 #define GCC_NORETURN /* nothing */
1980 #endif
1981 #ifndef GCC_UNUSED
1982 #define GCC_UNUSED /* nothing */
1983 #endif
1984 EOF
1985 if test "$GCC" = yes
1986 then
1987         AC_CHECKING([for $CC __attribute__ directives])
1988 cat > conftest.$ac_ext <<EOF
1989 #line __oline__ "${as_me:-configure}"
1990 #include "confdefs.h"
1991 #include "conftest.h"
1992 #include "conftest.i"
1993 #if     GCC_PRINTF
1994 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1995 #else
1996 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1997 #endif
1998 #if     GCC_SCANF
1999 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2000 #else
2001 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2002 #endif
2003 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2004 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2005 extern void foo(void) GCC_NORETURN;
2006 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
2007 EOF
2008         cf_printf_attribute=no
2009         cf_scanf_attribute=no
2010         for cf_attribute in scanf printf unused noreturn
2011         do
2012                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2013                 cf_directive="__attribute__(($cf_attribute))"
2014                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2015
2016                 case $cf_attribute in
2017                 (printf)
2018                         cf_printf_attribute=yes
2019                         cat >conftest.h <<EOF
2020 #define GCC_$cf_ATTRIBUTE 1
2021 EOF
2022                         ;;
2023                 (scanf)
2024                         cf_scanf_attribute=yes
2025                         cat >conftest.h <<EOF
2026 #define GCC_$cf_ATTRIBUTE 1
2027 EOF
2028                         ;;
2029                 (*)
2030                         cat >conftest.h <<EOF
2031 #define GCC_$cf_ATTRIBUTE $cf_directive
2032 EOF
2033                         ;;
2034                 esac
2035
2036                 if AC_TRY_EVAL(ac_compile); then
2037                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2038                         cat conftest.h >>confdefs.h
2039                         case $cf_attribute in
2040                         (noreturn)
2041                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2042                                 ;;
2043                         (printf)
2044                                 cf_value='/* nothing */'
2045                                 if test "$cf_printf_attribute" != no ; then
2046                                         cf_value='__attribute__((format(printf,fmt,var)))'
2047                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2048                                 fi
2049                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2050                                 ;;
2051                         (scanf)
2052                                 cf_value='/* nothing */'
2053                                 if test "$cf_scanf_attribute" != no ; then
2054                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2055                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2056                                 fi
2057                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2058                                 ;;
2059                         (unused)
2060                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2061                                 ;;
2062                         esac
2063                 fi
2064         done
2065 else
2066         fgrep define conftest.i >>confdefs.h
2067 fi
2068 rm -rf conftest*
2069 fi
2070 ])dnl
2071 dnl ---------------------------------------------------------------------------
2072 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2073 dnl --------------
2074 dnl Find version of gcc
2075 AC_DEFUN([CF_GCC_VERSION],[
2076 AC_REQUIRE([AC_PROG_CC])
2077 GCC_VERSION=none
2078 if test "$GCC" = yes ; then
2079         AC_MSG_CHECKING(version of $CC)
2080         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2081         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2082         AC_MSG_RESULT($GCC_VERSION)
2083 fi
2084 ])dnl
2085 dnl ---------------------------------------------------------------------------
2086 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
2087 dnl ---------------
2088 dnl Check if the compiler supports useful warning options.  There's a few that
2089 dnl we don't use, simply because they're too noisy:
2090 dnl
2091 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2092 dnl     -Wredundant-decls (system headers make this too noisy)
2093 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2094 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2095 dnl             is enabled for ncurses using "--enable-const".
2096 dnl     -pedantic
2097 dnl
2098 dnl Parameter:
2099 dnl     $1 is an optional list of gcc warning flags that a particular
2100 dnl             application might want to use, e.g., "no-unused" for
2101 dnl             -Wno-unused
2102 dnl Special:
2103 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2104 dnl
2105 AC_DEFUN([CF_GCC_WARNINGS],
2106 [
2107 AC_REQUIRE([CF_GCC_VERSION])
2108 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2109 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2110
2111 cat > conftest.$ac_ext <<EOF
2112 #line __oline__ "${as_me:-configure}"
2113 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2114 EOF
2115
2116 if test "$INTEL_COMPILER" = yes
2117 then
2118 # The "-wdXXX" options suppress warnings:
2119 # remark #1419: external declaration in primary source file
2120 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2121 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2122 # remark #193: zero used for undefined preprocessing identifier
2123 # remark #593: variable "curs_sb_left_arrow" was set but never used
2124 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2125 # remark #869: parameter "tw" was never referenced
2126 # remark #981: operands are evaluated in unspecified order
2127 # warning #279: controlling expression is constant
2128
2129         AC_CHECKING([for $CC warning options])
2130         cf_save_CFLAGS="$CFLAGS"
2131         EXTRA_CFLAGS="-Wall"
2132         for cf_opt in \
2133                 wd1419 \
2134                 wd1683 \
2135                 wd1684 \
2136                 wd193 \
2137                 wd593 \
2138                 wd279 \
2139                 wd810 \
2140                 wd869 \
2141                 wd981
2142         do
2143                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2144                 if AC_TRY_EVAL(ac_compile); then
2145                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2146                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2147                 fi
2148         done
2149         CFLAGS="$cf_save_CFLAGS"
2150
2151 elif test "$GCC" = yes
2152 then
2153         AC_CHECKING([for $CC warning options])
2154         cf_save_CFLAGS="$CFLAGS"
2155         EXTRA_CFLAGS=
2156         cf_warn_CONST=""
2157         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2158         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2159         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2160         for cf_opt in W Wall \
2161                 Wbad-function-cast \
2162                 Wcast-align \
2163                 Wcast-qual \
2164                 Wdeclaration-after-statement \
2165                 Wextra \
2166                 Winline \
2167                 Wmissing-declarations \
2168                 Wmissing-prototypes \
2169                 Wnested-externs \
2170                 Wpointer-arith \
2171                 Wshadow \
2172                 Wstrict-prototypes \
2173                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2174         do
2175                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2176                 if AC_TRY_EVAL(ac_compile); then
2177                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2178                         case $cf_opt in
2179                         (Wcast-qual)
2180                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2181                                 ;;
2182                         (Winline)
2183                                 case $GCC_VERSION in
2184                                 ([[34]].*)
2185                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2186                                         continue;;
2187                                 esac
2188                                 ;;
2189                         (Wpointer-arith)
2190                                 case $GCC_VERSION in
2191                                 ([[12]].*)
2192                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2193                                         continue;;
2194                                 esac
2195                                 ;;
2196                         esac
2197                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2198                 fi
2199         done
2200         CFLAGS="$cf_save_CFLAGS"
2201 fi
2202 rm -rf conftest*
2203
2204 AC_SUBST(EXTRA_CFLAGS)
2205 ])dnl
2206 dnl ---------------------------------------------------------------------------
2207 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2208 dnl ----------------
2209 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2210 dnl unistd.h or (nonstandard) in getopt.h
2211 AC_DEFUN([CF_GETOPT_HEADER],
2212 [
2213 AC_HAVE_HEADERS(unistd.h getopt.h)
2214 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2215 cf_cv_getopt_header=none
2216 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2217 do
2218 AC_TRY_COMPILE([
2219 #include <$cf_header>],
2220 [int x = optind; char *y = optarg],
2221 [cf_cv_getopt_header=$cf_header
2222  break])
2223 done
2224 ])
2225 if test $cf_cv_getopt_header != none ; then
2226         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2227 fi
2228 if test $cf_cv_getopt_header = getopt.h ; then
2229         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2230 fi
2231 ])dnl
2232 dnl ---------------------------------------------------------------------------
2233 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2234 dnl -----------------
2235 AC_DEFUN([CF_GNATPREP_OPT_T],[
2236 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2237 cf_cv_gnatprep_opt_t=no
2238 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2239 ])
2240 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2241 AC_SUBST(GNATPREP_OPTS)
2242 ])dnl
2243 dnl ---------------------------------------------------------------------------
2244 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2245 dnl ----------------
2246 AC_DEFUN([CF_GNAT_GENERICS],
2247 [
2248 AC_REQUIRE([CF_GNAT_VERSION])
2249
2250 AC_MSG_CHECKING(if GNAT supports generics)
2251 case $cf_gnat_version in
2252 (3.[[1-9]]*|[[4-9]].*)
2253         cf_gnat_generics=yes
2254         ;;
2255 (*)
2256         cf_gnat_generics=no
2257         ;;
2258 esac
2259 AC_MSG_RESULT($cf_gnat_generics)
2260
2261 if test "$cf_gnat_generics" = yes
2262 then
2263         cf_compile_generics=generics
2264         cf_generic_objects="\${GENOBJS}"
2265 else
2266         cf_compile_generics=
2267         cf_generic_objects=
2268 fi
2269
2270 AC_SUBST(cf_compile_generics)
2271 AC_SUBST(cf_generic_objects)
2272 ])dnl
2273 dnl ---------------------------------------------------------------------------
2274 dnl CF_GNAT_PROJECTS version: 8 updated: 2015/04/17 21:13:04
2275 dnl ----------------
2276 dnl GNAT projects are configured with ".gpr" project files.
2277 dnl GNAT libraries are a further development, using the project feature.
2278 AC_DEFUN([CF_GNAT_PROJECTS],
2279 [
2280 AC_REQUIRE([CF_GNAT_VERSION])
2281 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2282
2283 cf_gnat_libraries=no
2284 cf_gnat_projects=no
2285
2286 if test "$enable_gnat_projects" != no ; then
2287 AC_MSG_CHECKING(if GNAT supports project files)
2288 case $cf_gnat_version in
2289 (3.[[0-9]]*)
2290         ;;
2291 (*)
2292         case $cf_cv_system_name in
2293         (cygwin*|msys*)
2294                 ;;
2295         (*)
2296                 mkdir conftest.src conftest.bin conftest.lib
2297                 cd conftest.src
2298                 rm -rf conftest* *~conftest*
2299                 cat >>library.gpr <<CF_EOF
2300 project Library is
2301   Kind := External ("LIB_KIND");
2302   for Library_Name use "ConfTest";
2303   for Object_Dir use ".";
2304   for Library_ALI_Dir use External("LIBRARY_DIR");
2305   for Library_Version use External ("SONAME");
2306   for Library_Kind use Kind;
2307   for Library_Dir use External("BUILD_DIR");
2308   Source_Dir := External ("SOURCE_DIR");
2309   for Source_Dirs use (Source_Dir);
2310 end Library;
2311 CF_EOF
2312                 cat >>confpackage.ads <<CF_EOF
2313 package ConfPackage is
2314    procedure conftest;
2315 end ConfPackage;
2316 CF_EOF
2317                 cat >>confpackage.adb <<CF_EOF
2318 with Text_IO;
2319 package body ConfPackage is
2320    procedure conftest is
2321    begin
2322       Text_IO.Put ("Hello World");
2323       Text_IO.New_Line;
2324    end conftest;
2325 end ConfPackage;
2326 CF_EOF
2327                 if ( $cf_ada_make $ADAFLAGS \
2328                                 -Plibrary.gpr \
2329                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2330                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2331                                 -XSOURCE_DIR=`pwd` \
2332                                 -XSONAME=libConfTest.so.1 \
2333                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2334                         cf_gnat_projects=yes
2335                 fi
2336                 cd ..
2337                 if test -f conftest.lib/confpackage.ali
2338                 then
2339                         cf_gnat_libraries=yes
2340                 fi
2341                 rm -rf conftest* *~conftest*
2342                 ;;
2343         esac
2344         ;;
2345 esac
2346 AC_MSG_RESULT($cf_gnat_projects)
2347 fi # enable_gnat_projects
2348
2349 if test $cf_gnat_projects = yes
2350 then
2351         AC_MSG_CHECKING(if GNAT supports libraries)
2352         AC_MSG_RESULT($cf_gnat_libraries)
2353 fi
2354
2355 if test "$cf_gnat_projects" = yes
2356 then
2357         USE_OLD_MAKERULES="#"
2358         USE_GNAT_PROJECTS=""
2359 else
2360         USE_OLD_MAKERULES=""
2361         USE_GNAT_PROJECTS="#"
2362 fi
2363
2364 if test "$cf_gnat_libraries" = yes
2365 then
2366         USE_GNAT_LIBRARIES=""
2367 else
2368         USE_GNAT_LIBRARIES="#"
2369 fi
2370
2371 AC_SUBST(USE_OLD_MAKERULES)
2372 AC_SUBST(USE_GNAT_PROJECTS)
2373 AC_SUBST(USE_GNAT_LIBRARIES)
2374 ])dnl
2375 dnl ---------------------------------------------------------------------------
2376 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2377 dnl --------------
2378 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2379 dnl is noted that gnat may compile a tasking unit even for configurations which
2380 dnl fail at runtime.
2381 AC_DEFUN([CF_GNAT_SIGINT],[
2382 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2383 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2384
2385 package ConfTest is
2386
2387    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2388    pragma Unreserve_All_Interrupts;
2389    pragma Warnings (On);
2390
2391    protected Process is
2392       procedure Stop;
2393       function Continue return Boolean;
2394       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2395    private
2396       Done : Boolean := False;
2397    end Process;
2398
2399 end ConfTest;],
2400 [package body ConfTest is
2401    protected body Process is
2402       procedure Stop is
2403       begin
2404          Done := True;
2405       end Stop;
2406       function Continue return Boolean is
2407       begin
2408          return not Done;
2409       end Continue;
2410    end Process;
2411 end ConfTest;],
2412         [cf_cv_gnat_sigint=yes],
2413         [cf_cv_gnat_sigint=no])])
2414
2415 if test $cf_cv_gnat_sigint = yes ; then
2416         USE_GNAT_SIGINT=""
2417 else
2418         USE_GNAT_SIGINT="#"
2419 fi
2420 AC_SUBST(USE_GNAT_SIGINT)
2421 ])dnl
2422 dnl ---------------------------------------------------------------------------
2423 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2424 dnl ----------------
2425 dnl Verify that a test program compiles/links with GNAT.
2426 dnl $cf_ada_make is set to the program that compiles/links
2427 dnl $ADAFLAGS may be set to the GNAT flags.
2428 dnl
2429 dnl $1 is the text of the spec
2430 dnl $2 is the text of the body
2431 dnl $3 is the shell command to execute if successful
2432 dnl $4 is the shell command to execute if not successful
2433 AC_DEFUN([CF_GNAT_TRY_LINK],
2434 [
2435 rm -rf conftest* *~conftest*
2436 cat >>conftest.ads <<CF_EOF
2437 $1
2438 CF_EOF
2439 cat >>conftest.adb <<CF_EOF
2440 $2
2441 CF_EOF
2442 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2443 ifelse($3,,      :,[      $3])
2444 ifelse($4,,,[else
2445    $4])
2446 fi
2447 rm -rf conftest* *~conftest*
2448 ])dnl
2449 dnl ---------------------------------------------------------------------------
2450 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2451 dnl ---------------
2452 dnl Verify that a test program compiles and runs with GNAT
2453 dnl $cf_ada_make is set to the program that compiles/links
2454 dnl $ADAFLAGS may be set to the GNAT flags.
2455 dnl
2456 dnl $1 is the text of the spec
2457 dnl $2 is the text of the body
2458 dnl $3 is the shell command to execute if successful
2459 dnl $4 is the shell command to execute if not successful
2460 AC_DEFUN([CF_GNAT_TRY_RUN],
2461 [
2462 rm -rf conftest* *~conftest*
2463 cat >>conftest.ads <<CF_EOF
2464 $1
2465 CF_EOF
2466 cat >>conftest.adb <<CF_EOF
2467 $2
2468 CF_EOF
2469 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2470    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2471 ifelse($3,,      :,[      $3])
2472 ifelse($4,,,[   else
2473       $4])
2474    fi
2475 ifelse($4,,,[else
2476    $4])
2477 fi
2478 rm -rf conftest* *~conftest*
2479 ])dnl
2480 dnl ---------------------------------------------------------------------------
2481 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
2482 dnl ---------------
2483 dnl Verify version of GNAT.
2484 AC_DEFUN([CF_GNAT_VERSION],
2485 [
2486 AC_MSG_CHECKING(for gnat version)
2487 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2488         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2489         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2490 AC_MSG_RESULT($cf_gnat_version)
2491
2492 case $cf_gnat_version in
2493 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
2494         cf_cv_prog_gnat_correct=yes
2495         ;;
2496 (*)
2497         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2498         cf_cv_prog_gnat_correct=no
2499         ;;
2500 esac
2501 ])
2502 dnl ---------------------------------------------------------------------------
2503 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2504 dnl -------------
2505 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2506 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2507 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2508 dnl since it is interwoven with GNU extensions.
2509 dnl
2510 dnl Well, yes we could work around it...
2511 AC_DEFUN([CF_GNU_SOURCE],
2512 [
2513 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2514 AC_TRY_COMPILE([#include <sys/types.h>],[
2515 #ifndef _XOPEN_SOURCE
2516 make an error
2517 #endif],
2518         [cf_cv_gnu_source=no],
2519         [cf_save="$CPPFLAGS"
2520          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2521          AC_TRY_COMPILE([#include <sys/types.h>],[
2522 #ifdef _XOPEN_SOURCE
2523 make an error
2524 #endif],
2525         [cf_cv_gnu_source=no],
2526         [cf_cv_gnu_source=yes])
2527         CPPFLAGS="$cf_save"
2528         ])
2529 ])
2530 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2531 ])dnl
2532 dnl ---------------------------------------------------------------------------
2533 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
2534 dnl --------------
2535 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2536 dnl problem :-).  If we have the compiler but no library, we'll be able to
2537 dnl configure, but won't be able to build the c++ demo program.
2538 AC_DEFUN([CF_GPP_LIBRARY],
2539 [
2540 cf_cxx_library=unknown
2541 case $cf_cv_system_name in
2542 (os2*)
2543         cf_gpp_libname=gpp
2544         ;;
2545 (*)
2546         cf_gpp_libname=g++
2547         ;;
2548 esac
2549 if test "$GXX" = yes; then
2550         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2551         cf_save="$LIBS"
2552         CF_ADD_LIB($cf_gpp_libname)
2553         AC_TRY_LINK([
2554 #include <$cf_gpp_libname/builtin.h>
2555         ],
2556         [two_arg_error_handler_t foo2 = lib_error_handler],
2557         [cf_cxx_library=yes
2558          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2559          if test "$cf_gpp_libname" = cpp ; then
2560             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2561          else
2562             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2563          fi],
2564         [AC_TRY_LINK([
2565 #include <builtin.h>
2566         ],
2567         [two_arg_error_handler_t foo2 = lib_error_handler],
2568         [cf_cxx_library=yes
2569          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2570          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2571         [cf_cxx_library=no])])
2572         LIBS="$cf_save"
2573         AC_MSG_RESULT($cf_cxx_library)
2574 fi
2575 ])dnl
2576 dnl ---------------------------------------------------------------------------
2577 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2578 dnl --------------
2579 dnl Check for version of g++
2580 AC_DEFUN([CF_GXX_VERSION],[
2581 AC_REQUIRE([AC_PROG_CPP])
2582 GXX_VERSION=none
2583 if test "$GXX" = yes; then
2584         AC_MSG_CHECKING(version of ${CXX:-g++})
2585         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2586         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2587         AC_MSG_RESULT($GXX_VERSION)
2588 fi
2589 ])dnl
2590 dnl ---------------------------------------------------------------------------
2591 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
2592 dnl ---------------
2593 dnl Check if the compiler supports useful warning options.
2594 dnl
2595 dnl Most of gcc's options apply to g++, except:
2596 dnl     -Wbad-function-cast
2597 dnl     -Wmissing-declarations
2598 dnl     -Wnested-externs
2599 dnl
2600 dnl Omit a few (for now):
2601 dnl     -Winline
2602 dnl
2603 dnl Parameter:
2604 dnl     $1 is an optional list of g++ warning flags that a particular
2605 dnl             application might want to use, e.g., "no-unused" for
2606 dnl             -Wno-unused
2607 dnl Special:
2608 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2609 dnl
2610 AC_DEFUN([CF_GXX_WARNINGS],
2611 [
2612
2613 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2614 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2615
2616 AC_REQUIRE([CF_GXX_VERSION])
2617
2618 AC_LANG_SAVE
2619 AC_LANG_CPLUSPLUS
2620
2621 cat > conftest.$ac_ext <<EOF
2622 #line __oline__ "configure"
2623 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2624 EOF
2625
2626 if test "$INTEL_CPLUSPLUS" = yes
2627 then
2628 # The "-wdXXX" options suppress warnings:
2629 # remark #1419: external declaration in primary source file
2630 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2631 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2632 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2633 # remark #193: zero used for undefined preprocessing identifier
2634 # remark #593: variable "curs_sb_left_arrow" was set but never used
2635 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2636 # remark #869: parameter "tw" was never referenced
2637 # remark #981: operands are evaluated in unspecified order
2638 # warning #269: invalid format string conversion
2639
2640         AC_CHECKING([for $CC warning options])
2641         cf_save_CXXFLAGS="$CXXFLAGS"
2642         EXTRA_CXXFLAGS="-Wall"
2643         for cf_opt in \
2644                 wd1419 \
2645                 wd1682 \
2646                 wd1683 \
2647                 wd1684 \
2648                 wd193 \
2649                 wd279 \
2650                 wd593 \
2651                 wd810 \
2652                 wd869 \
2653                 wd981
2654         do
2655                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2656                 if AC_TRY_EVAL(ac_compile); then
2657                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2658                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2659                 fi
2660         done
2661         CXXFLAGS="$cf_save_CXXFLAGS"
2662
2663 elif test "$GXX" = yes
2664 then
2665         AC_CHECKING([for $CXX warning options])
2666         cf_save_CXXFLAGS="$CXXFLAGS"
2667         EXTRA_CXXFLAGS="-W -Wall"
2668         cf_gxx_extra_warnings=""
2669         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2670         case "$GCC_VERSION" in
2671         ([[1-2]].*)
2672                 ;;
2673         (*)
2674                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2675                 ;;
2676         esac
2677         for cf_opt in \
2678                 Wabi \
2679                 fabi-version=0 \
2680                 Wextra \
2681                 Wignored-qualifiers \
2682                 Wlogical-op \
2683                 Woverloaded-virtual \
2684                 Wsign-promo \
2685                 Wsynth \
2686                 Wold-style-cast \
2687                 Wcast-align \
2688                 Wcast-qual \
2689                 Wpointer-arith \
2690                 Wshadow \
2691                 Wundef $cf_gxx_extra_warnings $1
2692         do
2693                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2694                 if AC_TRY_EVAL(ac_compile); then
2695                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2696                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2697                 else
2698                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2699                 fi
2700         done
2701         CXXFLAGS="$cf_save_CXXFLAGS"
2702 fi
2703
2704 rm -rf conftest*
2705 AC_LANG_RESTORE
2706 AC_SUBST(EXTRA_CXXFLAGS)
2707 ])dnl
2708 dnl ---------------------------------------------------------------------------
2709 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
2710 dnl ------------
2711 dnl Look for an instance of the Berkeley hashed database.
2712 dnl
2713 dnl $1 = optional parameter, to specify install-prefix for the database.
2714 AC_DEFUN([CF_HASHED_DB],
2715 [
2716 ifelse([$1],,,[
2717 case $1 in
2718 (yes|*able*)
2719         ;;
2720 (*)
2721         if test -d "$1" ; then
2722                 CF_ADD_INCDIR($1/include)
2723                 CF_ADD_LIBDIR($1/lib)
2724         else
2725                 case "$1" in
2726                 (./*|../*|/*)
2727                         AC_MSG_WARN(no such directory $1)
2728                         ;;
2729                 (*)
2730                         CF_FIND_SUB_INCDIR($1)
2731                         CF_FIND_SUB_LIBDIR($1)
2732                         ;;
2733                 esac
2734         fi
2735 esac
2736 ])
2737 AC_CHECK_HEADER(db.h,[
2738 CF_HASHED_DB_VERSION
2739 if test "$cf_cv_hashed_db_version" = unknown ; then
2740         AC_MSG_ERROR(Cannot determine version of db)
2741 else
2742         CF_HASHED_DB_LIBS
2743         if test "$cf_cv_hashed_db_libs" = unknown ; then
2744                 AC_MSG_ERROR(Cannot determine library for db)
2745         elif test "$cf_cv_hashed_db_libs" != default ; then
2746                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2747         fi
2748 fi
2749 ],[
2750         AC_MSG_ERROR(Cannot find db.h)
2751 ])
2752 ])dnl
2753 dnl ---------------------------------------------------------------------------
2754 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2755 dnl -----------------
2756 dnl Given that we have the header and version for hashed database, find the
2757 dnl library information.
2758 AC_DEFUN([CF_HASHED_DB_LIBS],
2759 [
2760 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2761 cf_cv_hashed_db_libs=unknown
2762 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2763 do
2764         cf_save_libs="$LIBS"
2765         if test -n "$cf_db_libs"; then
2766                 CF_ADD_LIB($cf_db_libs)
2767         fi
2768         CF_MSG_LOG(checking for library "$cf_db_libs")
2769         AC_TRY_LINK([
2770 $ac_includes_default
2771 #include <db.h>
2772 ],[
2773         char *path = "/tmp/foo";
2774 #ifdef DB_VERSION_MAJOR
2775 #if DB_VERSION_MAJOR >= 4
2776         DB *result = 0;
2777         db_create(&result, NULL, 0);
2778         result->open(result,
2779                 NULL,
2780                 path,
2781                 path,
2782                 DB_HASH,
2783                 DB_CREATE,
2784                 0644);
2785 #elif DB_VERSION_MAJOR >= 3
2786         DB *result = 0;
2787         db_create(&result, NULL, 0);
2788         result->open(result,
2789                 path,
2790                 path,
2791                 DB_HASH,
2792                 DB_CREATE,
2793                 0644);
2794 #elif DB_VERSION_MAJOR >= 2
2795         DB *result = 0;
2796         db_open(path,
2797                 DB_HASH,
2798                 DB_CREATE,
2799                 0644,
2800                 (DB_ENV *) 0,
2801                 (DB_INFO *) 0,
2802                 &result);
2803 #endif /* DB_VERSION_MAJOR */
2804 #else
2805         DB *result = dbopen(path,
2806                      2,
2807                      0644,
2808                      DB_HASH,
2809                      0);
2810 #endif
2811         ${cf_cv_main_return:-return}(result != 0)
2812 ],[
2813         if test -n "$cf_db_libs" ; then
2814                 cf_cv_hashed_db_libs=$cf_db_libs
2815         else
2816                 cf_cv_hashed_db_libs=default
2817         fi
2818         LIBS="$cf_save_libs"
2819         break
2820 ])
2821         LIBS="$cf_save_libs"
2822 done
2823 ])
2824 ])dnl
2825 dnl ---------------------------------------------------------------------------
2826 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
2827 dnl --------------------
2828 dnl Given that we have the header file for hashed database, find the version
2829 dnl information.
2830 AC_DEFUN([CF_HASHED_DB_VERSION],
2831 [
2832 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2833 cf_cv_hashed_db_version=unknown
2834
2835 for cf_db_version in 1 2 3 4 5 6
2836 do
2837         CF_MSG_LOG(checking for db version $cf_db_version)
2838         AC_TRY_COMPILE([
2839 $ac_includes_default
2840 #include <db.h>
2841
2842 #ifdef DB_VERSION_MAJOR
2843         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2844 #if $cf_db_version == DB_VERSION_MAJOR
2845         /* ok */
2846 #else
2847         make an error
2848 #endif
2849 #else
2850 #if $cf_db_version == 1
2851         /* ok: assuming this is DB 1.8.5 */
2852 #else
2853         make an error
2854 #endif
2855 #endif
2856 ],[DBT *foo = 0],[
2857         cf_cv_hashed_db_version=$cf_db_version
2858         break
2859         ])
2860 done
2861 ])
2862 ])dnl
2863 dnl ---------------------------------------------------------------------------
2864 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
2865 dnl --------------
2866 dnl Construct a search-list of directories for a nonstandard header-file
2867 dnl
2868 dnl Parameters
2869 dnl     $1 = the variable to return as result
2870 dnl     $2 = the package name
2871 AC_DEFUN([CF_HEADER_PATH],
2872 [
2873 $1=
2874
2875 # collect the current set of include-directories from compiler flags
2876 cf_header_path_list=""
2877 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2878         for cf_header_path in $CPPFLAGS $CFLAGS
2879         do
2880                 case $cf_header_path in
2881                 (-I*)
2882                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2883                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2884                         cf_header_path_list="$cf_header_path_list [$]$1"
2885                         ;;
2886                 esac
2887         done
2888 fi
2889
2890 # add the variations for the package we are looking for
2891 CF_SUBDIR_PATH($1,$2,include)
2892
2893 test "$includedir" != NONE && \
2894 test "$includedir" != "/usr/include" && \
2895 test -d "$includedir" && {
2896         test -d $includedir &&    $1="[$]$1 $includedir"
2897         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2898 }
2899
2900 test "$oldincludedir" != NONE && \
2901 test "$oldincludedir" != "/usr/include" && \
2902 test -d "$oldincludedir" && {
2903         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2904         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2905 }
2906
2907 $1="[$]$1 $cf_header_path_list"
2908 ])dnl
2909 dnl ---------------------------------------------------------------------------
2910 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2911 dnl ---------------
2912 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2913 AC_DEFUN([CF_HELP_MESSAGE],
2914 [AC_DIVERT_HELP([$1])dnl
2915 ])dnl
2916 dnl ---------------------------------------------------------------------------
2917 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
2918 dnl ---------------
2919 dnl Construct the list of include-options according to whether we're building
2920 dnl in the source directory or using '--srcdir=DIR' option.
2921 AC_DEFUN([CF_INCLUDE_DIRS],
2922 [
2923 if test "$srcdir" != "."; then
2924         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
2925 fi
2926 CPPFLAGS="-I../include $CPPFLAGS"
2927 if test "$srcdir" != "."; then
2928         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
2929 fi
2930 CPPFLAGS="-I. $CPPFLAGS"
2931 AC_SUBST(CPPFLAGS)
2932 ])dnl
2933 dnl ---------------------------------------------------------------------------
2934 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
2935 dnl -----------------
2936 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2937 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2938 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2939 dnl
2940 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2941 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2942 dnl the wrappers for gcc and g++ warnings.
2943 dnl
2944 dnl $1 = GCC (default) or GXX
2945 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2946 dnl $3 = CFLAGS (default) or CXXFLAGS
2947 AC_DEFUN([CF_INTEL_COMPILER],[
2948 AC_REQUIRE([AC_CANONICAL_HOST])
2949 ifelse([$2],,INTEL_COMPILER,[$2])=no
2950
2951 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2952         case $host_os in
2953         (linux*|gnu*)
2954                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2955                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2956                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2957                 AC_TRY_COMPILE([],[
2958 #ifdef __INTEL_COMPILER
2959 #else
2960 make an error
2961 #endif
2962 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2963 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2964 ],[])
2965                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2966                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2967                 ;;
2968         esac
2969 fi
2970 ])dnl
2971 dnl ---------------------------------------------------------------------------
2972 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
2973 dnl ----------
2974 dnl Check if we have either a function or macro for 'isascii()'.
2975 AC_DEFUN([CF_ISASCII],
2976 [
2977 AC_MSG_CHECKING(for isascii)
2978 AC_CACHE_VAL(cf_cv_have_isascii,[
2979         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2980         [cf_cv_have_isascii=yes],
2981         [cf_cv_have_isascii=no])
2982 ])dnl
2983 AC_MSG_RESULT($cf_cv_have_isascii)
2984 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
2985 ])dnl
2986 dnl ---------------------------------------------------------------------------
2987 dnl CF_LARGEFILE version: 9 updated: 2015/04/18 08:56:57
2988 dnl ------------
2989 dnl Add checks for large file support.
2990 AC_DEFUN([CF_LARGEFILE],[
2991 ifdef([AC_FUNC_FSEEKO],[
2992         AC_SYS_LARGEFILE
2993         if test "$enable_largefile" != no ; then
2994         AC_FUNC_FSEEKO
2995
2996         # Normally we would collect these definitions in the config.h,
2997         # but (like _XOPEN_SOURCE), some environments rely on having these
2998         # defined before any of the system headers are included.  Another
2999         # case comes up with C++, e.g., on AIX the compiler compiles the
3000         # header files by themselves before looking at the body files it is
3001         # told to compile.  For ncurses, those header files do not include
3002         # the config.h
3003         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
3004         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
3005         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
3006
3007         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3008                 AC_TRY_COMPILE([
3009 #include <sys/types.h>
3010 #include <dirent.h>
3011                 ],[
3012                 /* if transitional largefile support is setup, this is true */
3013                 extern struct dirent64 * readdir(DIR *);
3014                 struct dirent64 *x = readdir((DIR *)0);
3015                 struct dirent *y = readdir((DIR *)0);
3016                 int z = x - y;
3017                 ],
3018                 [cf_cv_struct_dirent64=yes],
3019                 [cf_cv_struct_dirent64=no])
3020         ])
3021         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3022         fi
3023 ])
3024 ])
3025 dnl ---------------------------------------------------------------------------
3026 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3027 dnl -----------------
3028 dnl Check for compiler/linker flags used to temporarily force usage of static
3029 dnl libraries.  This depends on the compiler and platform.  Use this to help
3030 dnl ensure that the linker picks up a given library based on its position in
3031 dnl the list of linker options and libraries.
3032 AC_DEFUN([CF_LDFLAGS_STATIC],[
3033
3034 if test "$GCC" = yes ; then
3035         case $cf_cv_system_name in
3036         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3037                 LDFLAGS_STATIC=
3038                 LDFLAGS_SHARED=
3039                 ;;
3040         (*)     # normally, except when broken
3041                 LDFLAGS_STATIC=-static
3042                 LDFLAGS_SHARED=-dynamic
3043                 ;;
3044         esac
3045 else
3046         case $cf_cv_system_name in
3047         (aix[[4-7]]*)   # from ld manpage
3048                 LDFLAGS_STATIC=-bstatic
3049                 LDFLAGS_SHARED=-bdynamic
3050                 ;;
3051         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3052                 # We could also use just "archive" and "shared".
3053                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3054                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3055                 ;;
3056         (irix*)         # from ld manpage IRIX64
3057                 LDFLAGS_STATIC=-Bstatic
3058                 LDFLAGS_SHARED=-Bdynamic
3059                 ;;
3060         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3061                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3062                 LDFLAGS_STATIC=-noso
3063                 LDFLAGS_SHARED=-so_archive
3064                 ;;
3065         (solaris2*)
3066                 LDFLAGS_STATIC=-Bstatic
3067                 LDFLAGS_SHARED=-Bdynamic
3068                 ;;
3069         esac
3070 fi
3071
3072 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3073 then
3074         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3075
3076         rm -f libconftest.a
3077         cat >conftest.$ac_ext <<EOF
3078 #line __oline__ "configure"
3079 #include <stdio.h>
3080 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3081 EOF
3082         if AC_TRY_EVAL(ac_compile) ; then
3083                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3084                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3085         fi
3086         rm -f conftest.*
3087
3088         cf_save_LIBS="$LIBS"
3089
3090         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3091         AC_TRY_LINK([
3092 #line __oline__ "configure"
3093 #include <stdio.h>
3094 int cf_ldflags_static(FILE *fp);
3095 ],[
3096         return cf_ldflags_static(stdin);
3097 ],[
3098         # some linkers simply ignore the -dynamic
3099         case x`file conftest$ac_exeext 2>/dev/null` in
3100         (*static*)
3101                 cf_ldflags_static=no
3102                 ;;
3103         (*)
3104                 cf_ldflags_static=yes
3105                 ;;
3106         esac
3107 ],[cf_ldflags_static=no])
3108
3109         rm -f libconftest.*
3110         LIBS="$cf_save_LIBS"
3111
3112         AC_MSG_RESULT($cf_ldflags_static)
3113
3114         if test $cf_ldflags_static != yes
3115         then
3116                 LDFLAGS_STATIC=
3117                 LDFLAGS_SHARED=
3118         fi
3119 else
3120         LDFLAGS_STATIC=
3121         LDFLAGS_SHARED=
3122 fi
3123
3124 AC_SUBST(LDFLAGS_STATIC)
3125 AC_SUBST(LDFLAGS_SHARED)
3126 ])
3127 dnl ---------------------------------------------------------------------------
3128 dnl CF_LD_RPATH_OPT version: 6 updated: 2015/04/12 15:39:00
3129 dnl ---------------
3130 dnl For the given system and compiler, find the compiler flags to pass to the
3131 dnl loader to use the "rpath" feature.
3132 AC_DEFUN([CF_LD_RPATH_OPT],
3133 [
3134 AC_REQUIRE([CF_CHECK_CACHE])
3135
3136 LD_RPATH_OPT=
3137 AC_MSG_CHECKING(for an rpath option)
3138 case $cf_cv_system_name in
3139 (irix*)
3140         if test "$GCC" = yes; then
3141                 LD_RPATH_OPT="-Wl,-rpath,"
3142         else
3143                 LD_RPATH_OPT="-rpath "
3144         fi
3145         ;;
3146 (linux*|gnu*|k*bsd*-gnu)
3147         LD_RPATH_OPT="-Wl,-rpath,"
3148         ;;
3149 (openbsd[[2-9]].*|mirbsd*)
3150         LD_RPATH_OPT="-Wl,-rpath,"
3151         ;;
3152 (dragonfly*|freebsd*)
3153         LD_RPATH_OPT="-rpath "
3154         ;;
3155 (netbsd*)
3156         LD_RPATH_OPT="-Wl,-rpath,"
3157         ;;
3158 (osf*|mls+*)
3159         LD_RPATH_OPT="-rpath "
3160         ;;
3161 (solaris2*)
3162         LD_RPATH_OPT="-R"
3163         ;;
3164 (*)
3165         ;;
3166 esac
3167 AC_MSG_RESULT($LD_RPATH_OPT)
3168
3169 case "x$LD_RPATH_OPT" in
3170 (x-R*)
3171         AC_MSG_CHECKING(if we need a space after rpath option)
3172         cf_save_LIBS="$LIBS"
3173         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3174         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3175         LIBS="$cf_save_LIBS"
3176         AC_MSG_RESULT($cf_rpath_space)
3177         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3178         ;;
3179 esac
3180 ])dnl
3181 dnl ---------------------------------------------------------------------------
3182 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3183 dnl ---------------
3184 dnl Construct a search-list of directories for a nonstandard library-file
3185 dnl
3186 dnl Parameters
3187 dnl     $1 = the variable to return as result
3188 dnl     $2 = the package name
3189 AC_DEFUN([CF_LIBRARY_PATH],
3190 [
3191 $1=
3192 cf_library_path_list=""
3193 if test -n "${LDFLAGS}${LIBS}" ; then
3194         for cf_library_path in $LDFLAGS $LIBS
3195         do
3196                 case $cf_library_path in
3197                 (-L*)
3198                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3199                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3200                         cf_library_path_list="$cf_library_path_list [$]$1"
3201                         ;;
3202                 esac
3203         done
3204 fi
3205
3206 CF_SUBDIR_PATH($1,$2,lib)
3207
3208 $1="$cf_library_path_list [$]$1"
3209 ])dnl
3210 dnl ---------------------------------------------------------------------------
3211 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3212 dnl ------------------
3213 AC_DEFUN([CF_LIBTOOL_VERSION],[
3214 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3215 then
3216         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3217 else
3218         cf_cv_libtool_version=
3219 fi
3220 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3221 ])dnl
3222 dnl ---------------------------------------------------------------------------
3223 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
3224 dnl -------------
3225 dnl Compute the library-prefix for the given host system
3226 dnl $1 = variable to set
3227 define([CF_LIB_PREFIX],
3228 [
3229         case $cf_cv_system_name in
3230         (OS/2*|os2*)
3231                 if test "$DFT_LWR_MODEL" = libtool; then
3232                         LIB_PREFIX='lib'
3233                 else
3234                         LIB_PREFIX=''
3235                 fi
3236                 ;;
3237         (*)     LIB_PREFIX='lib'
3238                 ;;
3239         esac
3240 ifelse($1,,,[$1=$LIB_PREFIX])
3241         AC_SUBST(LIB_PREFIX)
3242 ])dnl
3243 dnl ---------------------------------------------------------------------------
3244 dnl CF_LIB_RULES version: 86 updated: 2015/11/07 20:01:34
3245 dnl ------------
3246 dnl Append definitions and rules for the given models to the subdirectory
3247 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3248 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3249 dnl the corresponding makefile to list the models that we'll generate.
3250 dnl
3251 dnl For shared libraries, make a list of symbolic links to construct when
3252 dnl generating each library.  The convention used for Linux is the simplest
3253 dnl one:
3254 dnl     lib<name>.so    ->
3255 dnl     lib<name>.so.<major>    ->
3256 dnl     lib<name>.so.<maj>.<minor>
3257 dnl
3258 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3259 AC_DEFUN([CF_LIB_RULES],
3260 [
3261 cf_prefix=$LIB_PREFIX
3262 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3263
3264 case $cf_cv_shlib_version in
3265 (cygdll|msysdll|mingw)
3266         TINFO_NAME=$TINFO_ARG_SUFFIX
3267         TINFO_SUFFIX=.dll
3268         ;;
3269 esac
3270
3271 if test -n "$TINFO_SUFFIX" ; then
3272         case $TINFO_SUFFIX in
3273         (tw*)
3274                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
3275                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
3276                 ;;
3277         (t*)
3278                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
3279                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
3280                 ;;
3281         (w*)
3282                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
3283                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
3284                 ;;
3285         esac
3286 fi
3287
3288 for cf_dir in $SRC_SUBDIRS
3289 do
3290         if test ! -d $srcdir/$cf_dir ; then
3291                 continue
3292         elif test -f $srcdir/$cf_dir/modules; then
3293
3294                 SHARED_LIB=
3295                 Libs_To_Make=
3296                 cf_awk_program=
3297                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3298                 then
3299                         cf_awk_program="$cf_awk_program\
3300 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
3301 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
3302 "
3303                 fi
3304
3305                 if test "x$WILDCARD_SYMS" = xno
3306                 then
3307                         cf_awk_program="$cf_awk_program\
3308 /[[     ]]_\\*;/ { skip=1; next; }\
3309 "
3310                 fi
3311
3312                 if test "x$cf_awk_program" != "x"
3313                 then
3314                         cat >>$cf_dir/Makefile <<CF_EOF
3315
3316 # Generated by CF_LIB_RULES
3317 resulting.map: $UNALTERED_SYMS
3318         $AWK 'BEGIN { skip = 1; last=""; } \
3319 $cf_awk_program \
3320 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
3321  skip = 0; last = \[$]\[$]0; } \
3322 END { print last; }' < $UNALTERED_SYMS >\[$]@
3323
3324 distclean::
3325         rm -f resulting.map
3326 CF_EOF
3327                 fi
3328
3329                 for cf_item in $cf_LIST_MODELS
3330                 do
3331                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3332                         cf_libname=$cf_dir
3333                         test "$cf_dir" = c++ && cf_libname=ncurses++
3334                         if test $cf_item = shared ; then
3335                                 if test -n "${LIB_SUFFIX}"
3336                                 then
3337                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3338                                 else
3339                                         cf_shared_suffix="$cf_suffix"
3340                                 fi
3341                                 if test "$cf_cv_do_symlinks" = yes ; then
3342                                         cf_version_name=
3343
3344                                         case "$cf_cv_shlib_version" in
3345                                         (rel)
3346                                                 cf_version_name=REL_VERSION
3347                                                 ;;
3348                                         (abi)
3349                                                 cf_version_name=ABI_VERSION
3350                                                 ;;
3351                                         esac
3352
3353                                         if test -n "$cf_version_name"
3354                                         then
3355                                                 case "$cf_cv_system_name" in
3356                                                 (darwin*)
3357                                                         # "w", etc?
3358                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3359                                                         ;;
3360                                                 (*)
3361                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3362                                                         ;;
3363                                                 esac
3364                                         fi
3365                                         if test -n "${USE_LIB_SUFFIX}"
3366                                         then
3367                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3368                                         else
3369                                                 cf_shared_suffix="$cf_suffix"
3370                                         fi
3371                                 fi
3372                                 # cygwin needs import library, and has unique naming convention
3373                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3374                                 # use 'cyg' prefix for shared lib.
3375                                 case $cf_cv_shlib_version in
3376                                 (cygdll)
3377                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3378                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
3379                                         ;;
3380                                 (msysdll)
3381                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3382                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
3383                                         ;;
3384                                 (mingw)
3385                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3386                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
3387                                         ;;
3388                                 (*)
3389                                         cf_add_lib=
3390                                         ;;
3391                                 esac
3392                                 if test -n "$cf_add_lib"
3393                                 then
3394                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3395                                         continue
3396                                 fi
3397                         fi
3398                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3399                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3400                 done
3401
3402                 if test $cf_dir = ncurses ; then
3403                         cf_subsets="$LIB_SUBSETS"
3404                         cf_r_parts="$cf_subsets"
3405                         cf_liblist="$Libs_To_Make"
3406
3407                         while test -n "$cf_r_parts"
3408                         do
3409                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3410                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3411                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3412                                         cf_add_lib=
3413                                         case $cf_l_parts in
3414                                         (*termlib*)
3415                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3416                                                 ;;
3417                                         (*ticlib*)
3418                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3419                                                 ;;
3420                                         (*)
3421                                                 break
3422                                                 ;;
3423                                         esac
3424                                         if test -n "$cf_add_lib"; then
3425                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
3426                                         fi
3427                                 else
3428                                         break
3429                                 fi
3430                         done
3431                 else
3432                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3433                 fi
3434
3435                 if test $cf_dir = c++; then
3436                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3437                                 cf_list=
3438                                 for cf_item in $Libs_To_Make
3439                                 do
3440                                         case $cf_item in
3441                                         (*.a)
3442                                                 ;;
3443                                         (*)
3444                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3445                                                 ;;
3446                                         esac
3447                                         for cf_test in $cf_list
3448                                         do
3449                                                 if test "$cf_test" = "$cf_item"
3450                                                 then
3451                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3452                                                         cf_item=
3453                                                         break
3454                                                 fi
3455                                         done
3456                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3457                                 done
3458                                 Libs_To_Make="$cf_list"
3459                         fi
3460                 fi
3461
3462                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3463                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3464                         $cf_dir/Makefile >$cf_dir/Makefile.out
3465                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3466
3467                 $AWK -f $srcdir/mk-0th.awk \
3468                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3469                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3470
3471                 for cf_subset in $cf_subsets
3472                 do
3473                         cf_subdirs=
3474                         for cf_item in $cf_LIST_MODELS
3475                         do
3476
3477                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3478                         CF_UPPER(cf_ITEM,$cf_item)
3479
3480                         CXX_MODEL=$cf_ITEM
3481                         if test "$CXX_MODEL" = SHARED; then
3482                                 case $cf_cv_shlib_version in
3483                                 (cygdll|msysdll|mingw)
3484                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3485                                         with_shared_cxx=yes
3486                                         ;;
3487                                 (*)
3488                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3489                                         ;;
3490                                 esac
3491                         fi
3492
3493                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3494                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3495
3496                         # Test for case where we build libtinfo with a different name.
3497                         cf_libname=$cf_dir
3498                         if test $cf_dir = ncurses ; then
3499                                 case $cf_subset in
3500                                 (*base*)
3501                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
3502                                         ;;
3503                                 (*termlib*)
3504                                         cf_libname=$TINFO_LIB_SUFFIX
3505                                         ;;
3506                                 (ticlib*)
3507                                         cf_libname=$TICS_LIB_SUFFIX
3508                                         ;;
3509                                 esac
3510                         elif test $cf_dir = c++ ; then
3511                                 cf_libname=ncurses++$USE_LIB_SUFFIX
3512                         else
3513                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
3514                         fi
3515                         if test -n "${USE_ARG_SUFFIX}" ; then
3516                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
3517                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
3518                         fi
3519
3520                         # These dependencies really are for development, not
3521                         # builds, but they are useful in porting, too.
3522                         cf_depend="../include/ncurses_cfg.h"
3523                         if test "$srcdir" = "."; then
3524                                 cf_reldir="."
3525                         else
3526                                 cf_reldir="\${srcdir}"
3527                         fi
3528
3529                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3530                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3531                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3532                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3533                         fi
3534
3535                         cf_dir_suffix=
3536                         old_cf_suffix="$cf_suffix"
3537                         if test "$cf_cv_shlib_version_infix" = yes ; then
3538                         if test -n "$USE_LIB_SUFFIX" ; then
3539                                 case $USE_LIB_SUFFIX in
3540                                 (tw*)
3541                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
3542                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
3543                                         cf_dir_suffix=tw$EXTRA_SUFFIX
3544                                         ;;
3545                                 (t*)
3546                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
3547                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
3548                                         cf_dir_suffix=t$EXTRA_SUFFIX
3549                                         ;;
3550                                 (w*)
3551                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
3552                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
3553                                         cf_dir_suffix=w$EXTRA_SUFFIX
3554                                         ;;
3555                                 (*)
3556                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
3557                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
3558                                         cf_dir_suffix=$EXTRA_SUFFIX
3559                                         ;;
3560                                 esac
3561                         fi
3562                         fi
3563
3564                         $AWK -f $srcdir/mk-1st.awk \
3565                                 name=${cf_libname}${cf_dir_suffix} \
3566                                 traces=$LIB_TRACING \
3567                                 MODEL=$cf_ITEM \
3568                                 CXX_MODEL=$CXX_MODEL \
3569                                 model=$cf_subdir \
3570                                 prefix=$cf_prefix \
3571                                 suffix=$cf_suffix \
3572                                 subset=$cf_subset \
3573                                 driver=$cf_cv_term_driver \
3574                                 SymLink="$LN_S" \
3575                                 TermlibRoot=$TINFO_NAME \
3576                                 TermlibSuffix=$TINFO_SUFFIX \
3577                                 ShlibVer=$cf_cv_shlib_version \
3578                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3579                                 ReLink=${cf_cv_do_relink:-no} \
3580                                 DoLinks=$cf_cv_do_symlinks \
3581                                 rmSoLocs=$cf_cv_rm_so_locs \
3582                                 ldconfig="$LDCONFIG" \
3583                                 overwrite=$WITH_OVERWRITE \
3584                                 depend="$cf_depend" \
3585                                 host="$host" \
3586                                 libtool_version="$LIBTOOL_VERSION" \
3587                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3588
3589                         cf_suffix="$old_cf_suffix"
3590
3591                         for cf_subdir2 in $cf_subdirs lib
3592                         do
3593                                 test $cf_subdir = $cf_subdir2 && break
3594                         done
3595                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3596                         $AWK -f $srcdir/mk-2nd.awk \
3597                                 name=$cf_dir \
3598                                 traces=$LIB_TRACING \
3599                                 MODEL=$cf_ITEM \
3600                                 model=$cf_subdir \
3601                                 subset=$cf_subset \
3602                                 srcdir=$srcdir \
3603                                 echo=$WITH_ECHO \
3604                                 crenames=$cf_cv_prog_CC_c_o \
3605                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3606                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3607                         cf_subdirs="$cf_subdirs $cf_subdir"
3608                         done
3609                 done
3610         fi
3611
3612         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3613 done
3614
3615 for cf_dir in $SRC_SUBDIRS
3616 do
3617         if test ! -d $srcdir/$cf_dir ; then
3618                 continue
3619         fi
3620
3621         if test -f $cf_dir/Makefile ; then
3622                 case "$cf_dir" in
3623                 (Ada95)
3624                         echo 'libs \' >> Makefile
3625                         echo 'install.libs \' >> Makefile
3626                         echo 'uninstall.libs ::' >> Makefile
3627                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3628                         ;;
3629                 esac
3630         fi
3631
3632         if test -f $srcdir/$cf_dir/modules; then
3633                 echo >> Makefile
3634                 if test -f $srcdir/$cf_dir/headers; then
3635 cat >> Makefile <<CF_EOF
3636 install.includes \\
3637 uninstall.includes \\
3638 CF_EOF
3639                 fi
3640 if test "$cf_dir" != "c++" ; then
3641 echo 'lint \' >> Makefile
3642 fi
3643 cat >> Makefile <<CF_EOF
3644 libs \\
3645 lintlib \\
3646 install.libs \\
3647 uninstall.libs \\
3648 install.$cf_dir \\
3649 uninstall.$cf_dir ::
3650         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3651 CF_EOF
3652         elif test -f $srcdir/$cf_dir/headers; then
3653 cat >> Makefile <<CF_EOF
3654
3655 libs \\
3656 install.libs \\
3657 uninstall.libs \\
3658 install.includes \\
3659 uninstall.includes ::
3660         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3661 CF_EOF
3662 fi
3663 done
3664
3665 if test "x$cf_with_db_install" = xyes; then
3666 cat >> Makefile <<CF_EOF
3667
3668 install.libs uninstall.libs \\
3669 install.data uninstall.data ::
3670 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3671 CF_EOF
3672 else
3673 cat >> Makefile <<CF_EOF
3674
3675 install.libs uninstall.libs ::
3676         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3677 CF_EOF
3678 fi
3679
3680 if test "x$cf_with_manpages" = xyes; then
3681 cat >> Makefile <<CF_EOF
3682
3683 install.man \\
3684 uninstall.man ::
3685         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3686 CF_EOF
3687 fi
3688
3689 cat >> Makefile <<CF_EOF
3690
3691 distclean ::
3692         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3693         rm -f headers.sh headers.sed mk_shared_lib.sh
3694         rm -f edit_man.* man_alias.*
3695         rm -rf \${DIRS_TO_MAKE}
3696 CF_EOF
3697
3698 # Special case: tack's manpage lives in its own directory.
3699 if test "x$cf_with_manpages" = xyes; then
3700 if test -d tack ; then
3701 if test -f $srcdir/$tack.h; then
3702 cat >> Makefile <<CF_EOF
3703
3704 install.man \\
3705 uninstall.man ::
3706         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3707 CF_EOF
3708 fi
3709 fi
3710 fi
3711
3712 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3713 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3714 dnl anything, and will make it more standardized.  It's awkward to decide this
3715 dnl at configuration because of quoting, so we'll simply make all headers
3716 dnl installed via a script that can do the right thing.
3717
3718 rm -f headers.sed headers.sh
3719
3720 dnl ( generating this script makes the makefiles a little tidier :-)
3721 echo creating headers.sh
3722 cat >headers.sh <<CF_EOF
3723 #! $SHELL
3724 # This shell script is generated by the 'configure' script.  It is invoked in a
3725 # subdirectory of the build tree.  It generates a sed-script in the parent
3726 # directory that is used to adjust includes for header files that reside in a
3727 # subdirectory of /usr/include, etc.
3728 PRG=""
3729 while test \[$]# != 3
3730 do
3731 PRG="\$PRG \[$]1"; shift
3732 done
3733 DST=\[$]1
3734 REF=\[$]2
3735 SRC=\[$]3
3736 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3737 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3738 echo installing \$SRC in \$DST
3739 CF_EOF
3740
3741 if test $WITH_CURSES_H = yes; then
3742         cat >>headers.sh <<CF_EOF
3743 case \$DST in
3744 (/*/include/*)
3745         END=\`basename \$DST\`
3746         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3747         do
3748                 NAME=\`basename \$i\`
3749                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3750         done
3751         ;;
3752 (*)
3753         echo "" >> \$TMPSED
3754         ;;
3755 esac
3756 CF_EOF
3757
3758 else
3759         cat >>headers.sh <<CF_EOF
3760 case \$DST in
3761 (/*/include/*)
3762         END=\`basename \$DST\`
3763         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3764         do
3765                 NAME=\`basename \$i\`
3766                 if test "\$NAME" = "curses.h"
3767                 then
3768                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3769                         NAME=ncurses.h
3770                 fi
3771                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3772         done
3773         ;;
3774 (*)
3775         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3776         ;;
3777 esac
3778 CF_EOF
3779 fi
3780 cat >>headers.sh <<CF_EOF
3781 rm -f \$TMPSRC
3782 sed -f \$TMPSED \$SRC > \$TMPSRC
3783 NAME=\`basename \$SRC\`
3784 CF_EOF
3785 if test $WITH_CURSES_H != yes; then
3786         cat >>headers.sh <<CF_EOF
3787 test "\$NAME" = "curses.h" && NAME=ncurses.h
3788 CF_EOF
3789 fi
3790 cat >>headers.sh <<CF_EOF
3791 # Just in case someone gzip'd manpages, remove the conflicting copy.
3792 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3793
3794 eval \$PRG \$TMPSRC \$DST/\$NAME
3795 rm -f \$TMPSRC \$TMPSED
3796 CF_EOF
3797
3798 chmod 0755 headers.sh
3799
3800 for cf_dir in $SRC_SUBDIRS
3801 do
3802         if test ! -d $srcdir/$cf_dir ; then
3803                 continue
3804         fi
3805
3806         if test -f $srcdir/$cf_dir/headers; then
3807                 $AWK -f $srcdir/mk-hdr.awk \
3808                         subset="$LIB_SUBSETS" \
3809                         compat="$WITH_CURSES_H" \
3810                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3811         fi
3812
3813         if test -f $srcdir/$cf_dir/modules; then
3814                 if test "$cf_dir" != "c++" ; then
3815                         cat >>$cf_dir/Makefile <<"CF_EOF"
3816 depend : ${AUTO_SRC}
3817         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3818
3819 # DO NOT DELETE THIS LINE -- make depend depends on it.
3820 CF_EOF
3821                 fi
3822         fi
3823 done
3824 AC_SUBST(Libs_To_Make)
3825 ])dnl
3826 dnl ---------------------------------------------------------------------------
3827 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3828 dnl -------------
3829 dnl Find the and soname for the given shared library.  Set the cache variable
3830 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3831 dnl variable to "unknown".
3832 dnl
3833 dnl $1 = headers
3834 dnl $2 = code
3835 dnl $3 = library name
3836 AC_DEFUN([CF_LIB_SONAME],
3837 [
3838 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3839
3840 cf_cv_$3_soname=unknown
3841 if test "$cross_compiling" != yes ; then
3842 cat >conftest.$ac_ext <<CF_EOF
3843 $1
3844 int main()
3845 {
3846 $2
3847         ${cf_cv_main_return:-return}(0);
3848 }
3849 CF_EOF
3850 cf_save_LIBS="$LIBS"
3851         CF_ADD_LIB($3)
3852         if AC_TRY_EVAL(ac_compile) ; then
3853                 if AC_TRY_EVAL(ac_link) ; then
3854                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3855                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3856                 fi
3857         fi
3858 rm -rf conftest*
3859 LIBS="$cf_save_LIBS"
3860 fi
3861 ])
3862 ])
3863 dnl ---------------------------------------------------------------------------
3864 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
3865 dnl -------------
3866 dnl Compute the library file-suffix from the given model name
3867 dnl $1 = model name
3868 dnl $2 = variable to set (the nominal library suffix)
3869 dnl $3 = dependency variable to set (actual filename)
3870 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3871 AC_DEFUN([CF_LIB_SUFFIX],
3872 [
3873         case X$1 in
3874         (Xlibtool)
3875                 $2='.la'
3876                 $3=[$]$2
3877                 ;;
3878         (Xdebug)
3879                 $2='_g.a'
3880                 $3=[$]$2
3881                 ;;
3882         (Xprofile)
3883                 $2='_p.a'
3884                 $3=[$]$2
3885                 ;;
3886         (Xshared)
3887                 case $cf_cv_system_name in
3888                 (aix[[5-7]]*)
3889                         $2='.so'
3890                         $3=[$]$2
3891                         ;;
3892                 (cygwin*|msys*|mingw*)
3893                         $2='.dll'
3894                         $3='.dll.a'
3895                         ;;
3896                 (darwin*)
3897                         $2='.dylib'
3898                         $3=[$]$2
3899                         ;;
3900                 (hpux*)
3901                         case $target in
3902                         (ia64*)
3903                                 $2='.so'
3904                                 $3=[$]$2
3905                                 ;;
3906                         (*)
3907                                 $2='.sl'
3908                                 $3=[$]$2
3909                                 ;;
3910                         esac
3911                         ;;
3912                 (*)
3913                         $2='.so'
3914                         $3=[$]$2
3915                         ;;
3916                 esac
3917                 ;;
3918         (*)
3919                 $2='.a'
3920                 $3=[$]$2
3921                 ;;
3922         esac
3923         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
3924         then
3925                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
3926                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
3927         fi
3928 ])dnl
3929 dnl ---------------------------------------------------------------------------
3930 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
3931 dnl -----------
3932 dnl Compute the string to append to -library from the given model name
3933 dnl $1 = model name
3934 dnl $2 = variable to set
3935 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3936 AC_DEFUN([CF_LIB_TYPE],
3937 [
3938         case $1 in
3939         (libtool) $2=''   ;;
3940         (normal)  $2=''   ;;
3941         (debug)   $2='_g' ;;
3942         (profile) $2='_p' ;;
3943         (shared)  $2=''   ;;
3944         esac
3945         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3946 ])dnl
3947 dnl ---------------------------------------------------------------------------
3948 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
3949 dnl ----------------
3950 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3951 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3952 dnl have to provide wrappers for global tables to ensure they're linked
3953 dnl properly.
3954 AC_DEFUN([CF_LINK_DATAONLY],
3955 [
3956 AC_MSG_CHECKING([if data-only library module links])
3957 AC_CACHE_VAL(cf_cv_link_dataonly,[
3958         rm -f conftest.a
3959         cat >conftest.$ac_ext <<EOF
3960 #line __oline__ "configure"
3961 int     testdata[[3]] = { 123, 456, 789 };
3962 EOF
3963         if AC_TRY_EVAL(ac_compile) ; then
3964                 mv conftest.o data.o && \
3965                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3966         fi
3967         rm -f conftest.$ac_ext data.o
3968         cat >conftest.$ac_ext <<EOF
3969 #line __oline__ "configure"
3970 int     testfunc()
3971 {
3972 #if defined(NeXT)
3973         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3974 #else
3975         extern int testdata[[3]];
3976         return testdata[[0]] == 123
3977            &&  testdata[[1]] == 456
3978            &&  testdata[[2]] == 789;
3979 #endif
3980 }
3981 EOF
3982         if AC_TRY_EVAL(ac_compile); then
3983                 mv conftest.o func.o && \
3984                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3985         fi
3986         rm -f conftest.$ac_ext func.o
3987         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3988         cf_saveLIBS="$LIBS"
3989         LIBS="conftest.a $LIBS"
3990         AC_TRY_RUN([
3991         int main()
3992         {
3993                 extern int testfunc();
3994                 ${cf_cv_main_return:-return} (!testfunc());
3995         }
3996         ],
3997         [cf_cv_link_dataonly=yes],
3998         [cf_cv_link_dataonly=no],
3999         [cf_cv_link_dataonly=unknown])
4000         LIBS="$cf_saveLIBS"
4001         ])
4002 AC_MSG_RESULT($cf_cv_link_dataonly)
4003
4004 if test "$cf_cv_link_dataonly" = no ; then
4005         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
4006         BROKEN_LINKER=1
4007 fi
4008
4009 ])dnl
4010 dnl ---------------------------------------------------------------------------
4011 dnl CF_LINK_FUNCS version: 8 updated: 2012/10/06 17:56:13
4012 dnl -------------
4013 dnl Most Unix systems have both link and symlink, a few don't have symlink.
4014 dnl A few non-Unix systems implement symlink, but not link.
4015 dnl A few non-systems implement neither (or have nonfunctional versions).
4016 AC_DEFUN([CF_LINK_FUNCS],
4017 [
4018 AC_CHECK_FUNCS( \
4019         remove \
4020         unlink )
4021
4022 if test "$cross_compiling" = yes ; then
4023         AC_CHECK_FUNCS( \
4024                 link \
4025                 symlink )
4026 else
4027         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
4028                 cf_cv_link_funcs=
4029                 for cf_func in link symlink ; do
4030                         AC_TRY_RUN([
4031 #include <sys/types.h>
4032 #include <sys/stat.h>
4033 #ifdef HAVE_UNISTD_H
4034 #include <unistd.h>
4035 #endif
4036 int main()
4037 {
4038         int fail = 0;
4039         char *src = "config.log";
4040         char *dst = "conftest.chk";
4041         struct stat src_sb;
4042         struct stat dst_sb;
4043
4044         stat(src, &src_sb);
4045         fail = ($cf_func("config.log", "conftest.chk") < 0)
4046             || (stat(dst, &dst_sb) < 0)
4047             || (dst_sb.st_mtime != src_sb.st_mtime);
4048 #ifdef HAVE_UNLINK
4049         unlink(dst);
4050 #else
4051         remove(dst);
4052 #endif
4053         ${cf_cv_main_return:-return} (fail);
4054 }
4055                         ],[
4056                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
4057                         eval 'ac_cv_func_'$cf_func'=yes'],[
4058                         eval 'ac_cv_func_'$cf_func'=no'],[
4059                         eval 'ac_cv_func_'$cf_func'=error'])
4060                 done
4061                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
4062         ])
4063         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
4064         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
4065 fi
4066 ])dnl
4067 dnl ---------------------------------------------------------------------------
4068 dnl CF_MAKEFLAGS version: 17 updated: 2015/08/05 20:44:28
4069 dnl ------------
4070 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
4071 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
4072 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
4073 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
4074 AC_DEFUN([CF_MAKEFLAGS],
4075 [
4076 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
4077         cf_cv_makeflags=''
4078         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
4079         do
4080                 cat >cf_makeflags.tmp <<CF_EOF
4081 SHELL = $SHELL
4082 all :
4083         @ echo '.$cf_option'
4084 CF_EOF
4085                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
4086                 case "$cf_result" in
4087                 (.*k|.*kw)
4088                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
4089                         case "$cf_result" in
4090                         (.*CC=*)        cf_cv_makeflags=
4091                                 ;;
4092                         (*)     cf_cv_makeflags=$cf_option
4093                                 ;;
4094                         esac
4095                         break
4096                         ;;
4097                 (.-)    ;;
4098                 (*)     echo "given option \"$cf_option\", no match \"$cf_result\""
4099                         ;;
4100                 esac
4101         done
4102         rm -f cf_makeflags.tmp
4103 ])
4104
4105 AC_SUBST(cf_cv_makeflags)
4106 ])dnl
4107 dnl ---------------------------------------------------------------------------
4108 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
4109 dnl ------------
4110 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
4111 dnl a monocase filesystem.
4112 AC_DEFUN([CF_MAKE_TAGS],[
4113 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
4114
4115 AC_CHECK_PROGS(CTAGS, exctags ctags)
4116 AC_CHECK_PROGS(ETAGS, exetags etags)
4117
4118 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
4119
4120 if test "$cf_cv_mixedcase" = yes ; then
4121         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
4122 else
4123         MAKE_UPPER_TAGS=no
4124 fi
4125
4126 if test "$MAKE_UPPER_TAGS" = yes ; then
4127         MAKE_UPPER_TAGS=
4128 else
4129         MAKE_UPPER_TAGS="#"
4130 fi
4131
4132 if test "$MAKE_LOWER_TAGS" = yes ; then
4133         MAKE_LOWER_TAGS=
4134 else
4135         MAKE_LOWER_TAGS="#"
4136 fi
4137
4138 AC_SUBST(CTAGS)
4139 AC_SUBST(ETAGS)
4140
4141 AC_SUBST(MAKE_UPPER_TAGS)
4142 AC_SUBST(MAKE_LOWER_TAGS)
4143 ])dnl
4144 dnl ---------------------------------------------------------------------------
4145 dnl CF_MANPAGE_FORMAT version: 11 updated: 2015/04/18 08:56:57
4146 dnl -----------------
4147 dnl Option to allow user to override automatic configuration of manpage format.
4148 dnl There are several special cases:
4149 dnl
4150 dnl     gzip - man checks for, can display gzip'd files
4151 dnl     compress - man checks for, can display compressed files
4152 dnl     BSDI - files in the cat-directories are suffixed ".0"
4153 dnl     formatted - installer should format (put files in cat-directory)
4154 dnl     catonly - installer should only format, e.g., for a turnkey system.
4155 dnl
4156 dnl There are other configurations which this macro does not test, e.g., HPUX's
4157 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
4158 dnl convention would not match our use).
4159 AC_DEFUN([CF_MANPAGE_FORMAT],
4160 [
4161 AC_REQUIRE([CF_PATHSEP])
4162 AC_MSG_CHECKING(format of man-pages)
4163
4164 AC_ARG_WITH(manpage-format,
4165         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
4166                           optionally formatted/catonly, e.g., gzip,formatted],
4167         [MANPAGE_FORMAT=$withval],
4168         [MANPAGE_FORMAT=unknown])
4169
4170 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
4171 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
4172
4173 cf_unknown=
4174
4175 case $MANPAGE_FORMAT in
4176 (unknown)
4177         if test -z "$MANPATH" ; then
4178                 MANPATH="/usr/man:/usr/share/man"
4179         fi
4180
4181         # look for the 'date' man-page (it's most likely to be installed!)
4182         MANPAGE_FORMAT=
4183         cf_preform=no
4184         cf_catonly=yes
4185         cf_example=date
4186
4187         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
4188         for cf_dir in $MANPATH; do
4189                 test -z "$cf_dir" && cf_dir=/usr/man
4190                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
4191                 do
4192                         cf_test=`echo $cf_name | sed -e 's/*//'`
4193                         if test "x$cf_test" = "x$cf_name" ; then
4194
4195                                 case "$cf_name" in
4196                                 (*.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
4197                                 (*.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
4198                                 (*.0)  MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
4199                                 (*)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
4200                                 esac
4201
4202                                 case "$cf_name" in
4203                                 ($cf_dir/man*)
4204                                         cf_catonly=no
4205                                         ;;
4206                                 ($cf_dir/cat*)
4207                                         cf_preform=yes
4208                                         ;;
4209                                 esac
4210                                 break
4211                         fi
4212
4213                         # if we found a match in either man* or cat*, stop looking
4214                         if test -n "$MANPAGE_FORMAT" ; then
4215                                 cf_found=no
4216                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
4217                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
4218                                 case "$cf_name" in
4219                                 ($cf_dir/cat*)
4220                                         cf_found=yes
4221                                         ;;
4222                                 esac
4223                                 test $cf_found=yes && break
4224                         fi
4225                 done
4226                 # only check the first directory in $MANPATH where we find manpages
4227                 if test -n "$MANPAGE_FORMAT" ; then
4228                         break
4229                 fi
4230         done
4231         # if we did not find the example, just assume it is normal
4232         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4233         IFS="$ac_save_ifs"
4234         ;;
4235 (*)
4236         for cf_option in $MANPAGE_FORMAT; do
4237         case $cf_option in
4238         (gzip|compress|BSDI|normal|formatted|catonly)
4239                 ;;
4240         (*)
4241                 cf_unknown="$cf_unknown $cf_option"
4242                 ;;
4243         esac
4244         done
4245         ;;
4246 esac
4247
4248 AC_MSG_RESULT($MANPAGE_FORMAT)
4249 if test -n "$cf_unknown" ; then
4250         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4251 fi
4252 ])dnl
4253 dnl ---------------------------------------------------------------------------
4254 dnl CF_MANPAGE_RENAMES version: 10 updated: 2015/08/05 20:44:28
4255 dnl ------------------
4256 dnl The Debian people have their own naming convention for manpages.  This
4257 dnl option lets us override the name of the file containing renaming, or
4258 dnl disable it altogether.
4259 AC_DEFUN([CF_MANPAGE_RENAMES],
4260 [
4261 AC_MSG_CHECKING(for manpage renaming)
4262
4263 AC_ARG_WITH(manpage-renames,
4264         [  --with-manpage-renames  specify manpage-renaming],
4265         [MANPAGE_RENAMES=$withval],
4266         [MANPAGE_RENAMES=yes])
4267
4268 case ".$MANPAGE_RENAMES" in
4269 (.no)
4270         ;;
4271 (.|.yes)
4272         # Debian 'man' program?
4273         if test -f /etc/debian_version ; then
4274                 MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4275         else
4276                 MANPAGE_RENAMES=no
4277         fi
4278         ;;
4279 esac
4280
4281 if test "$MANPAGE_RENAMES" != no ; then
4282         if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4283                 MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4284         elif test ! -f $MANPAGE_RENAMES ; then
4285                 AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4286         fi
4287
4288         test ! -d man && mkdir man
4289
4290         # Construct a sed-script to perform renaming within man-pages
4291         if test -n "$MANPAGE_RENAMES" ; then
4292                 test ! -d man && mkdir man
4293                 $SHELL $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4294         fi
4295 fi
4296
4297 AC_MSG_RESULT($MANPAGE_RENAMES)
4298 AC_SUBST(MANPAGE_RENAMES)
4299 ])dnl
4300 dnl ---------------------------------------------------------------------------
4301 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
4302 dnl -------------------
4303 dnl Some people expect each tool to make all aliases for manpages in the
4304 dnl man-directory.  This accommodates the older, less-capable implementations
4305 dnl of 'man', and is optional.
4306 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4307 [
4308 AC_MSG_CHECKING(if manpage aliases will be installed)
4309
4310 AC_ARG_WITH(manpage-aliases,
4311         [  --with-manpage-aliases  specify manpage-aliases using .so],
4312         [MANPAGE_ALIASES=$withval],
4313         [MANPAGE_ALIASES=yes])
4314
4315 AC_MSG_RESULT($MANPAGE_ALIASES)
4316
4317 case "x$LN_S" in
4318 (xln*)
4319         cf_use_symlinks=yes
4320         ;;
4321 (*)
4322         cf_use_symlinks=no
4323         ;;
4324 esac
4325
4326 MANPAGE_SYMLINKS=no
4327 if test "$MANPAGE_ALIASES" = yes ; then
4328 AC_MSG_CHECKING(if manpage symlinks should be used)
4329
4330 AC_ARG_WITH(manpage-symlinks,
4331         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4332         [MANPAGE_SYMLINKS=$withval],
4333         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4334
4335 if test "$$cf_use_symlinks" = no; then
4336 if test "$MANPAGE_SYMLINKS" = yes ; then
4337         AC_MSG_WARN(cannot make symlinks, will use .so files)
4338         MANPAGE_SYMLINKS=no
4339 fi
4340 fi
4341
4342 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4343 fi
4344
4345 ])dnl
4346 dnl ---------------------------------------------------------------------------
4347 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4348 dnl --------------
4349 dnl This option causes manpages to be run through tbl(1) to generate tables
4350 dnl correctly.
4351 AC_DEFUN([CF_MANPAGE_TBL],
4352 [
4353 AC_MSG_CHECKING(for manpage tbl)
4354
4355 AC_ARG_WITH(manpage-tbl,
4356         [  --with-manpage-tbl      specify manpage processing with tbl],
4357         [MANPAGE_TBL=$withval],
4358         [MANPAGE_TBL=no])
4359
4360 AC_MSG_RESULT($MANPAGE_TBL)
4361 ])dnl
4362 dnl ---------------------------------------------------------------------------
4363 dnl CF_MAN_PAGES version: 46 updated: 2015/08/05 20:44:28
4364 dnl ------------
4365 dnl Try to determine if the man-pages on the system are compressed, and if
4366 dnl so, what format is used.  Use this information to construct a script that
4367 dnl will install man-pages.
4368 AC_DEFUN([CF_MAN_PAGES],
4369 [
4370 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4371 CF_MANPAGE_FORMAT
4372 CF_MANPAGE_RENAMES
4373 CF_MANPAGE_SYMLINKS
4374 CF_MANPAGE_TBL
4375
4376 if test "$prefix" = "NONE" ; then
4377         cf_prefix="$ac_default_prefix"
4378 else
4379         cf_prefix="$prefix"
4380 fi
4381
4382 case "$MANPAGE_FORMAT" in
4383 (*catonly*)
4384         cf_format=yes
4385         cf_inboth=no
4386         ;;
4387 (*formatted*)
4388         cf_format=yes
4389         cf_inboth=yes
4390         ;;
4391 (*)
4392         cf_format=no
4393         cf_inboth=no
4394         ;;
4395 esac
4396
4397 test ! -d man && mkdir man
4398
4399 cf_so_strip=
4400 cf_compress=
4401 case "$MANPAGE_FORMAT" in
4402 (*compress*)
4403         cf_so_strip="Z"
4404         cf_compress=compress
4405         ;;
4406 (*gzip*)
4407         cf_so_strip="gz"
4408         cf_compress=gzip
4409         ;;
4410 esac
4411
4412 cf_edit_man=./edit_man.sh
4413 cf_man_alias=`pwd`/man_alias.sed
4414
4415 cat >$cf_edit_man <<CF_EOF
4416 #! $SHELL
4417 # this script is generated by the configure-script CF_MAN_PAGES macro.
4418
4419 prefix="$cf_prefix"
4420 datarootdir="$datarootdir"
4421 datadir="$datadir"
4422
4423 NCURSES_MAJOR="$NCURSES_MAJOR"
4424 NCURSES_MINOR="$NCURSES_MINOR"
4425 NCURSES_PATCH="$NCURSES_PATCH"
4426
4427 NCURSES_OSPEED="$NCURSES_OSPEED"
4428 TERMINFO="$TERMINFO"
4429
4430 INSTALL="$INSTALL"
4431 INSTALL_DATA="$INSTALL_DATA"
4432
4433 transform="$program_transform_name"
4434
4435 TMP=\${TMPDIR:=/tmp}/man\$\$
4436 trap "rm -f \$TMP" 0 1 2 5 15
4437
4438 form=\[$]1
4439 shift || exit 1
4440
4441 verb=\[$]1
4442 shift || exit 1
4443
4444 mandir=\[$]1
4445 shift || exit 1
4446
4447 srcdir=\[$]1
4448 top_srcdir=\[$]srcdir/..
4449 shift || exit 1
4450
4451 if test "\$form" = normal ; then
4452         if test "$cf_format" = yes ; then
4453         if test "$cf_inboth" = no ; then
4454                 $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
4455                 exit $?
4456         fi
4457         fi
4458         cf_subdir=\$mandir/man
4459         cf_tables=$MANPAGE_TBL
4460 else
4461         cf_subdir=\$mandir/cat
4462         cf_tables=yes
4463 fi
4464
4465 # process the list of source-files
4466 for i in \[$]* ; do
4467 case \$i in
4468 (*.orig|*.rej) ;;
4469 (*.[[0-9]]*)
4470         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4471         if test \$verb = installing ; then
4472         if test ! -d \$cf_subdir\${section} ; then
4473                 mkdir -p \$cf_subdir\$section
4474         fi
4475         fi
4476
4477         # replace variables in man page
4478         if test ! -f $cf_man_alias ; then
4479 cat >>$cf_man_alias <<-CF_EOF2
4480                 s,@DATADIR@,\$datadir,g
4481                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
4482                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
4483                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
4484                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
4485                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
4486                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
4487 CF_EOF
4488         ifelse($1,,,[
4489         for cf_name in $1
4490         do
4491                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4492                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4493 cat >>$cf_edit_man <<-CF_EOF
4494                 s,@$cf_NAME@,$cf_name,g
4495 CF_EOF
4496         done
4497         ])
4498 cat >>$cf_edit_man <<CF_EOF
4499 CF_EOF2
4500                 echo "...made $cf_man_alias"
4501         fi
4502
4503         aliases=
4504         cf_source=\`basename \$i\`
4505         inalias=\$cf_source
4506         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4507         if test ! -f \$inalias ; then
4508                 echo .. skipped \$cf_source
4509                 continue
4510         fi
4511 CF_EOF
4512
4513 if test "$MANPAGE_ALIASES" != no ; then
4514 cat >>$cf_edit_man <<CF_EOF
4515         nCurses=ignore.3x
4516         test $with_curses_h = yes && nCurses=ncurses.3x
4517         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4518 CF_EOF
4519 fi
4520
4521 if test "$MANPAGE_RENAMES" = no ; then
4522 cat >>$cf_edit_man <<CF_EOF
4523         # perform program transformations for section 1 man pages
4524         if test \$section = 1 ; then
4525                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4526         else
4527                 cf_target=\$cf_subdir\${section}/\$cf_source
4528         fi
4529 CF_EOF
4530 else
4531 cat >>$cf_edit_man <<CF_EOF
4532         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4533         if test -z "\$cf_target" ; then
4534                 echo '? missing rename for '\$cf_source
4535                 cf_target="\$cf_source"
4536         fi
4537         cf_target="\$cf_subdir\${section}/\${cf_target}"
4538
4539 CF_EOF
4540 fi
4541
4542 cat >>$cf_edit_man <<CF_EOF
4543         sed     -f $cf_man_alias \\
4544 CF_EOF
4545
4546 if test -f $MANPAGE_RENAMES ; then
4547 cat >>$cf_edit_man <<CF_EOF
4548                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4549 CF_EOF
4550 else
4551 cat >>$cf_edit_man <<CF_EOF
4552                 < \$i >\$TMP
4553 CF_EOF
4554 fi
4555
4556 cat >>$cf_edit_man <<CF_EOF
4557 if test \$cf_tables = yes ; then
4558         tbl \$TMP >\$TMP.out
4559         mv \$TMP.out \$TMP
4560 fi
4561 CF_EOF
4562
4563 if test $with_overwrite != yes ; then
4564 cat >>$cf_edit_man <<CF_EOF
4565         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4566         mv \$TMP.out \$TMP
4567 CF_EOF
4568 fi
4569
4570 if test $with_curses_h != yes ; then
4571 cat >>$cf_edit_man <<CF_EOF
4572         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4573         mv \$TMP.out \$TMP
4574 CF_EOF
4575 fi
4576
4577 cat >>$cf_edit_man <<CF_EOF
4578         if test \$form = format ; then
4579                 nroff -man \$TMP >\$TMP.out
4580                 mv \$TMP.out \$TMP
4581         fi
4582 CF_EOF
4583
4584 if test -n "$cf_compress" ; then
4585 cat >>$cf_edit_man <<CF_EOF
4586         if test \$verb = installing ; then
4587         if ( $cf_compress -f \$TMP )
4588         then
4589                 mv \$TMP.$cf_so_strip \$TMP
4590         fi
4591         fi
4592         cf_target="\$cf_target.$cf_so_strip"
4593 CF_EOF
4594 fi
4595
4596 case "$MANPAGE_FORMAT" in
4597 (*BSDI*)
4598 cat >>$cf_edit_man <<CF_EOF
4599         if test \$form = format ; then
4600                 # BSDI installs only .0 suffixes in the cat directories
4601                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4602         fi
4603 CF_EOF
4604   ;;
4605 esac
4606
4607 cat >>$cf_edit_man <<CF_EOF
4608         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4609         if test \$verb = installing ; then
4610                 echo \$verb \$cf_target
4611                 \$INSTALL_DATA \$TMP \$cf_target
4612                 test -d \$cf_subdir\${section} &&
4613                 test -n "\$aliases" && (
4614                         cd \$cf_subdir\${section} && (
4615                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4616                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4617                                 cf_target=\`basename \$cf_target\`
4618                                 for cf_alias in \$aliases
4619                                 do
4620                                         if test \$section = 1 ; then
4621                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4622                                         fi
4623
4624                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4625                                                 if test -f \$cf_alias\${suffix} ; then
4626                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4627                                                         then
4628                                                                 continue
4629                                                         fi
4630                                                 fi
4631                                                 echo .. \$verb alias \$cf_alias\${suffix}
4632 CF_EOF
4633 case "x$LN_S" in
4634 (*-f)
4635 cat >>$cf_edit_man <<CF_EOF
4636                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4637 CF_EOF
4638         ;;
4639 (*)
4640 cat >>$cf_edit_man <<CF_EOF
4641                                                 rm -f \$cf_alias\${suffix}
4642                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4643 CF_EOF
4644         ;;
4645 esac
4646 cat >>$cf_edit_man <<CF_EOF
4647                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4648                                                 echo ".so \$cf_source" >\$TMP
4649 CF_EOF
4650 if test -n "$cf_compress" ; then
4651 cat >>$cf_edit_man <<CF_EOF
4652                                                 if test -n "$cf_so_strip" ; then
4653                                                         $cf_compress -f \$TMP
4654                                                         mv \$TMP.$cf_so_strip \$TMP
4655                                                 fi
4656 CF_EOF
4657 fi
4658 cat >>$cf_edit_man <<CF_EOF
4659                                                 echo .. \$verb alias \$cf_alias\${suffix}
4660                                                 rm -f \$cf_alias\${suffix}
4661                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4662                                         fi
4663                                 done
4664                         )
4665                 )
4666         elif test \$verb = removing ; then
4667                 test -f \$cf_target && (
4668                         echo \$verb \$cf_target
4669                         rm -f \$cf_target
4670                 )
4671                 test -d \$cf_subdir\${section} &&
4672                 test -n "\$aliases" && (
4673                         cd \$cf_subdir\${section} && (
4674                                 for cf_alias in \$aliases
4675                                 do
4676                                         if test \$section = 1 ; then
4677                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4678                                         fi
4679
4680                                         echo .. \$verb alias \$cf_alias\${suffix}
4681                                         rm -f \$cf_alias\${suffix}
4682                                 done
4683                         )
4684                 )
4685         else
4686 #               echo ".hy 0"
4687                 cat \$TMP
4688         fi
4689         ;;
4690 esac
4691 done
4692
4693 if test $cf_inboth = yes ; then
4694 if test \$form != format ; then
4695         $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
4696 fi
4697 fi
4698
4699 exit 0
4700 CF_EOF
4701 chmod 755 $cf_edit_man
4702
4703 ])dnl
4704 dnl ---------------------------------------------------------------------------
4705 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4706 dnl -----------
4707 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4708 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4709 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4710 AC_DEFUN([CF_MATH_LIB],
4711 [
4712 AC_CACHE_CHECK(if -lm needed for math functions,
4713         cf_cv_need_libm,[
4714         AC_TRY_LINK([
4715         #include <stdio.h>
4716         #include <math.h>
4717         ],
4718         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4719         [cf_cv_need_libm=no],
4720         [cf_cv_need_libm=yes])])
4721 if test "$cf_cv_need_libm" = yes
4722 then
4723 ifelse($1,,[
4724         CF_ADD_LIB(m)
4725 ],[$1=-lm])
4726 fi
4727 ])
4728 dnl ---------------------------------------------------------------------------
4729 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
4730 dnl ----------------------
4731 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4732 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4733 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4734 [
4735 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4736 if test "$cross_compiling" = yes ; then
4737         case $target_alias in
4738         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
4739                 cf_cv_mixedcase=no
4740                 ;;
4741         (*)
4742                 cf_cv_mixedcase=yes
4743                 ;;
4744         esac
4745 else
4746         rm -f conftest CONFTEST
4747         echo test >conftest
4748         if test -f CONFTEST ; then
4749                 cf_cv_mixedcase=no
4750         else
4751                 cf_cv_mixedcase=yes
4752         fi
4753         rm -f conftest CONFTEST
4754 fi
4755 ])
4756 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
4757 ])dnl
4758 dnl ---------------------------------------------------------------------------
4759 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
4760 dnl ----------
4761 dnl Check for a working mkstemp.  This creates two files, checks that they are
4762 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4763 AC_DEFUN([CF_MKSTEMP],[
4764 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4765 rm -rf conftest*
4766 AC_TRY_RUN([
4767 #include <sys/types.h>
4768 #include <stdlib.h>
4769 #include <stdio.h>
4770 #include <string.h>
4771 #include <sys/stat.h>
4772 int main()
4773 {
4774         char *tmpl = "conftestXXXXXX";
4775         char name[2][80];
4776         int n;
4777         int result = 0;
4778         int fd;
4779         struct stat sb;
4780
4781         umask(077);
4782         for (n = 0; n < 2; ++n) {
4783                 strcpy(name[n], tmpl);
4784                 if ((fd = mkstemp(name[n])) >= 0) {
4785                         if (!strcmp(name[n], tmpl)
4786                          || stat(name[n], &sb) != 0
4787                          || (sb.st_mode & S_IFMT) != S_IFREG
4788                          || (sb.st_mode & 077) != 0) {
4789                                 result = 1;
4790                         }
4791                         close(fd);
4792                 }
4793         }
4794         if (result == 0
4795          && !strcmp(name[0], name[1]))
4796                 result = 1;
4797         ${cf_cv_main_return:-return}(result);
4798 }
4799 ],[cf_cv_func_mkstemp=yes
4800 ],[cf_cv_func_mkstemp=no
4801 ],[cf_cv_func_mkstemp=maybe])
4802 ])
4803 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
4804         AC_CHECK_FUNC(mkstemp)
4805 fi
4806 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4807         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
4808 fi
4809 ])dnl
4810 dnl ---------------------------------------------------------------------------
4811 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4812 dnl ----------
4813 dnl Write a debug message to config.log, along with the line number in the
4814 dnl configure script.
4815 AC_DEFUN([CF_MSG_LOG],[
4816 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
4817 ])dnl
4818 dnl ---------------------------------------------------------------------------
4819 dnl CF_NCURSES_ABI_6 version: 3 updated: 2015/06/06 16:10:11
4820 dnl ----------------
4821 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
4822 dnl warn about this.
4823 AC_DEFUN([CF_NCURSES_ABI_6],[
4824 if test "${with_abi_version+set}" != set; then
4825         case $cf_cv_rel_version in
4826         (5.*)
4827                 cf_cv_rel_version=6.0
4828                 cf_cv_abi_version=6
4829                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_version)
4830                 ;;
4831         esac
4832 fi
4833 ])dnl
4834 dnl ---------------------------------------------------------------------------
4835 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
4836 dnl ------------------
4837 dnl see CF_WITH_NO_LEAKS
4838 AC_DEFUN([CF_NO_LEAKS_OPTION],[
4839 AC_MSG_CHECKING(if you want to use $1 for testing)
4840 AC_ARG_WITH($1,
4841         [$2],
4842         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
4843          $4
4844 ])
4845         : ${with_cflags:=-g}
4846         : ${with_no_leaks:=yes}
4847          with_$1=yes],
4848         [with_$1=])
4849 AC_MSG_RESULT(${with_$1:-no})
4850
4851 case .$with_cflags in
4852 (.*-g*)
4853         case .$CFLAGS in
4854         (.*-g*)
4855                 ;;
4856         (*)
4857                 CF_ADD_CFLAGS([-g])
4858                 ;;
4859         esac
4860         ;;
4861 esac
4862 ])dnl
4863 dnl ---------------------------------------------------------------------------
4864 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
4865 dnl ----------------
4866 dnl Check if the given variable is a number.  If not, report an error.
4867 dnl $1 is the variable
4868 dnl $2 is the message
4869 AC_DEFUN([CF_NUMBER_SYNTAX],[
4870 if test -n "$1" ; then
4871   case $1 in
4872   ([[0-9]]*)
4873         ;;
4874   (*)
4875         AC_MSG_ERROR($2 is not a number: $1)
4876         ;;
4877   esac
4878 else
4879   AC_MSG_ERROR($2 value is empty)
4880 fi
4881 ])dnl
4882 dnl ---------------------------------------------------------------------------
4883 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
4884 dnl -------------
4885 dnl Compute the object-directory name from the given model name
4886 AC_DEFUN([CF_OBJ_SUBDIR],
4887 [
4888         case $1 in
4889         (libtool) $2='obj_lo'  ;;
4890         (normal)  $2='objects' ;;
4891         (debug)   $2='obj_g' ;;
4892         (profile) $2='obj_p' ;;
4893         (shared)
4894                 case $cf_cv_system_name in
4895                 (cygwin|msys)
4896                         $2='objects' ;;
4897                 (*)
4898                         $2='obj_s' ;;
4899                 esac
4900         esac
4901 ])dnl
4902 dnl ---------------------------------------------------------------------------
4903 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
4904 dnl ----------
4905 dnl Provide a value for the $PATH and similar separator (or amend the value
4906 dnl as provided in autoconf 2.5x).
4907 AC_DEFUN([CF_PATHSEP],
4908 [
4909         AC_MSG_CHECKING(for PATH separator)
4910         case $cf_cv_system_name in
4911         (os2*)  PATH_SEPARATOR=';'  ;;
4912         (*)     ${PATH_SEPARATOR:=':'}  ;;
4913         esac
4914 ifelse([$1],,,[$1=$PATH_SEPARATOR])
4915         AC_SUBST(PATH_SEPARATOR)
4916         AC_MSG_RESULT($PATH_SEPARATOR)
4917 ])dnl
4918 dnl ---------------------------------------------------------------------------
4919 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
4920 dnl --------------
4921 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
4922 dnl begins with one of the prefix/exec_prefix variables, and then again if the
4923 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
4924 dnl delayed evaluation of those symbols.
4925 AC_DEFUN([CF_PATH_SYNTAX],[
4926 if test "x$prefix" != xNONE; then
4927         cf_path_syntax="$prefix"
4928 else
4929         cf_path_syntax="$ac_default_prefix"
4930 fi
4931
4932 case ".[$]$1" in
4933 (.\[$]\(*\)*|.\'*\'*)
4934         ;;
4935 (..|./*|.\\*)
4936         ;;
4937 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
4938         ;;
4939 (.\[$]{*prefix}*|.\[$]{*dir}*)
4940         eval $1="[$]$1"
4941         case ".[$]$1" in
4942         (.NONE/*)
4943                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4944                 ;;
4945         esac
4946         ;;
4947 (.no|.NONE/*)
4948         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4949         ;;
4950 (*)
4951         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
4952         ;;
4953 esac
4954 ])dnl
4955 dnl ---------------------------------------------------------------------------
4956 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
4957 dnl -------------
4958 dnl Check for the package-config program, unless disabled by command-line.
4959 AC_DEFUN([CF_PKG_CONFIG],
4960 [
4961 AC_MSG_CHECKING(if you want to use pkg-config)
4962 AC_ARG_WITH(pkg-config,
4963         [  --with-pkg-config{=path} enable/disable use of pkg-config],
4964         [cf_pkg_config=$withval],
4965         [cf_pkg_config=yes])
4966 AC_MSG_RESULT($cf_pkg_config)
4967
4968 case $cf_pkg_config in
4969 (no)
4970         PKG_CONFIG=none
4971         ;;
4972 (yes)
4973         CF_ACVERSION_CHECK(2.52,
4974                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
4975                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
4976         ;;
4977 (*)
4978         PKG_CONFIG=$withval
4979         ;;
4980 esac
4981
4982 test -z "$PKG_CONFIG" && PKG_CONFIG=none
4983 if test "$PKG_CONFIG" != none ; then
4984         CF_PATH_SYNTAX(PKG_CONFIG)
4985 elif test "x$cf_pkg_config" != xno ; then
4986         AC_MSG_WARN(pkg-config is not installed)
4987 fi
4988
4989 AC_SUBST(PKG_CONFIG)
4990 ])dnl
4991 dnl ---------------------------------------------------------------------------
4992 dnl CF_POSIX_C_SOURCE version: 9 updated: 2015/04/12 15:39:00
4993 dnl -----------------
4994 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
4995 dnl
4996 dnl     POSIX.1-1990                            _POSIX_SOURCE
4997 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
4998 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
4999 dnl             Bindings Option
5000 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
5001 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
5002 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
5003 dnl
5004 dnl Parameters:
5005 dnl     $1 is the nominal value for _POSIX_C_SOURCE
5006 AC_DEFUN([CF_POSIX_C_SOURCE],
5007 [
5008 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
5009
5010 cf_save_CFLAGS="$CFLAGS"
5011 cf_save_CPPFLAGS="$CPPFLAGS"
5012
5013 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
5014 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
5015
5016 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
5017         CF_MSG_LOG(if the symbol is already defined go no further)
5018         AC_TRY_COMPILE([#include <sys/types.h>],[
5019 #ifndef _POSIX_C_SOURCE
5020 make an error
5021 #endif],
5022         [cf_cv_posix_c_source=no],
5023         [cf_want_posix_source=no
5024          case .$cf_POSIX_C_SOURCE in
5025          (.[[12]]??*)
5026                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5027                 ;;
5028          (.2)
5029                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5030                 cf_want_posix_source=yes
5031                 ;;
5032          (.*)
5033                 cf_want_posix_source=yes
5034                 ;;
5035          esac
5036          if test "$cf_want_posix_source" = yes ; then
5037                 AC_TRY_COMPILE([#include <sys/types.h>],[
5038 #ifdef _POSIX_SOURCE
5039 make an error
5040 #endif],[],
5041                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
5042          fi
5043          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
5044          CFLAGS="$cf_trim_CFLAGS"
5045          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
5046          CF_MSG_LOG(if the second compile does not leave our definition intact error)
5047          AC_TRY_COMPILE([#include <sys/types.h>],[
5048 #ifndef _POSIX_C_SOURCE
5049 make an error
5050 #endif],,
5051          [cf_cv_posix_c_source=no])
5052          CFLAGS="$cf_save_CFLAGS"
5053          CPPFLAGS="$cf_save_CPPFLAGS"
5054         ])
5055 ])
5056
5057 if test "$cf_cv_posix_c_source" != no ; then
5058         CFLAGS="$cf_trim_CFLAGS"
5059         CPPFLAGS="$cf_trim_CPPFLAGS"
5060         CF_ADD_CFLAGS($cf_cv_posix_c_source)
5061 fi
5062
5063 ])dnl
5064 dnl ---------------------------------------------------------------------------
5065 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
5066 dnl ------------
5067 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
5068 dnl
5069 dnl $1 = symbol to test
5070 dnl $2 = value (if any) to use for a predefinition
5071 AC_DEFUN([CF_PREDEFINE],
5072 [
5073 AC_MSG_CHECKING(if we must define $1)
5074 AC_TRY_COMPILE([#include <sys/types.h>
5075 ],[
5076 #ifndef $1
5077 make an error
5078 #endif],[cf_result=no],[cf_result=yes])
5079 AC_MSG_RESULT($cf_result)
5080
5081 if test "$cf_result" = yes ; then
5082         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
5083 elif test "x$2" != "x" ; then
5084         AC_MSG_CHECKING(checking for compatible value versus $2)
5085         AC_TRY_COMPILE([#include <sys/types.h>
5086 ],[
5087 #if $1-$2 < 0
5088 make an error
5089 #endif],[cf_result=yes],[cf_result=no])
5090         AC_MSG_RESULT($cf_result)
5091         if test "$cf_result" = no ; then
5092                 # perhaps we can override it - try...
5093                 CPPFLAGS="$CPPFLAGS -D$1=$2"
5094         fi
5095 fi
5096 ])dnl
5097 dnl ---------------------------------------------------------------------------
5098 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
5099 dnl ------------
5100 dnl Append definitions and rules for the given programs to the subdirectory
5101 dnl Makefiles, and the recursion rule for the top-level Makefile.
5102 dnl
5103 dnl parameters
5104 dnl     $1 = script to run
5105 dnl     $2 = list of subdirectories
5106 dnl
5107 dnl variables
5108 dnl     $AWK
5109 AC_DEFUN([CF_PRG_RULES],
5110 [
5111 for cf_dir in $2
5112 do
5113         if test ! -d $srcdir/$cf_dir; then
5114                 continue
5115         elif test -f $srcdir/$cf_dir/programs; then
5116                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
5117         fi
5118 done
5119
5120 ])dnl
5121 dnl ---------------------------------------------------------------------------
5122 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
5123 dnl ----------
5124 dnl Check for archiver "ar".
5125 AC_DEFUN([CF_PROG_AR],[
5126 AC_CHECK_TOOL(AR, ar, ar)
5127 ])
5128 dnl ---------------------------------------------------------------------------
5129 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
5130 dnl -----------
5131 dnl Check for awk, ensure that the check found something.
5132 AC_DEFUN([CF_PROG_AWK],
5133 [
5134 AC_PROG_AWK
5135 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
5136 ])dnl
5137 dnl ---------------------------------------------------------------------------
5138 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
5139 dnl ----------
5140 dnl standard check for CC, plus followup sanity checks
5141 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
5142 AC_DEFUN([CF_PROG_CC],[
5143 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
5144 CF_GCC_VERSION
5145 CF_ACVERSION_CHECK(2.52,
5146         [AC_PROG_CC_STDC],
5147         [CF_ANSI_CC_REQD])
5148 CF_CC_ENV_FLAGS
5149 ])dnl
5150 dnl ---------------------------------------------------------------------------
5151 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
5152 dnl --------------
5153 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
5154 dnl the output file can be renamed, and allows for a shell variable that can
5155 dnl be used later.  The parameter is either CC or CXX.  The result is the
5156 dnl cache variable:
5157 dnl     $cf_cv_prog_CC_c_o
5158 dnl     $cf_cv_prog_CXX_c_o
5159 AC_DEFUN([CF_PROG_CC_C_O],
5160 [AC_REQUIRE([AC_PROG_CC])dnl
5161 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
5162 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
5163 [
5164 cat > conftest.$ac_ext <<CF_EOF
5165 #include <stdio.h>
5166 int main()
5167 {
5168         ${cf_cv_main_return:-return}(0);
5169 }
5170 CF_EOF
5171 # We do the test twice because some compilers refuse to overwrite an
5172 # existing .o file with -o, though they will create one.
5173 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
5174 if AC_TRY_EVAL(ac_try) &&
5175   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
5176 then
5177   eval cf_cv_prog_$1_c_o=yes
5178 else
5179   eval cf_cv_prog_$1_c_o=no
5180 fi
5181 rm -rf conftest*
5182 ])dnl
5183 if test $cf_cv_prog_$1_c_o = yes; then
5184   AC_MSG_RESULT([yes])
5185 else
5186   AC_MSG_RESULT([no])
5187 fi
5188 ])dnl
5189 dnl ---------------------------------------------------------------------------
5190 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
5191 dnl -------------
5192 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
5193 dnl This macro adds a check to ensure the script found something.
5194 AC_DEFUN([CF_PROG_EGREP],
5195 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
5196         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
5197                 then ac_cv_prog_egrep='grep -E'
5198                 else ac_cv_prog_egrep='egrep'
5199         fi])
5200         EGREP=$ac_cv_prog_egrep
5201         AC_SUBST([EGREP])
5202         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
5203 ])dnl
5204 dnl ---------------------------------------------------------------------------
5205 dnl CF_PROG_GNAT version: 3 updated: 2015/04/18 08:56:57
5206 dnl ------------
5207 dnl Check for gnatmake, ensure that it is complete.
5208 AC_DEFUN([CF_PROG_GNAT],[
5209 cf_ada_make=gnatmake
5210 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
5211 if test "$ac_cv_prog_gnat_exists" = no; then
5212         cf_ada_make=
5213         cf_cv_prog_gnat_correct=no
5214 else
5215         CF_GNAT_VERSION
5216         AC_CHECK_PROG(M4_exists, m4, yes, no)
5217         if test "$ac_cv_prog_M4_exists" = no; then
5218                 cf_cv_prog_gnat_correct=no
5219                 echo Ada95 binding required program m4 not found. Ada95 binding disabled.
5220         fi
5221         if test "$cf_cv_prog_gnat_correct" = yes; then
5222                 AC_MSG_CHECKING(if GNAT works)
5223                 CF_GNAT_TRY_RUN([procedure conftest;],
5224 [with Text_IO;
5225 with GNAT.OS_Lib;
5226 procedure conftest is
5227 begin
5228    Text_IO.Put ("Hello World");
5229    Text_IO.New_Line;
5230    GNAT.OS_Lib.OS_Exit (0);
5231 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
5232                 AC_MSG_RESULT($cf_cv_prog_gnat_correct)
5233         fi
5234 fi
5235
5236 AC_SUBST(cf_ada_make)
5237 ])dnl
5238 dnl ---------------------------------------------------------------------------
5239 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
5240 dnl ---------------
5241 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
5242 dnl misc/tabset install won't work properly.  Usually this happens only when
5243 dnl using the fallback mkinstalldirs script
5244 AC_DEFUN([CF_PROG_INSTALL],
5245 [AC_PROG_INSTALL
5246 case $INSTALL in
5247 (/*)
5248         ;;
5249 (*)
5250         CF_DIRNAME(cf_dir,$INSTALL)
5251         test -z "$cf_dir" && cf_dir=.
5252         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
5253         ;;
5254 esac
5255 ])dnl
5256 dnl ---------------------------------------------------------------------------
5257 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
5258 dnl ----------------
5259 dnl Check for ldconfig, needed to fixup shared libraries that would be built
5260 dnl and then used in the install.
5261 AC_DEFUN([CF_PROG_LDCONFIG],[
5262 if test "$cross_compiling" = yes ; then
5263         LDCONFIG=:
5264 else
5265         case "$cf_cv_system_name" in
5266         (dragonfly*|mirbsd*|freebsd*)
5267                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
5268                 ;;
5269         (*) LDPATH=$PATH:/sbin:/usr/sbin
5270                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
5271                 ;;
5272         esac
5273 fi
5274 AC_SUBST(LDCONFIG)
5275 ])dnl
5276 dnl ---------------------------------------------------------------------------
5277 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
5278 dnl ------------
5279 AC_DEFUN([CF_PROG_LINT],
5280 [
5281 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
5282 AC_SUBST(LINT_OPTS)
5283 ])dnl
5284 dnl ---------------------------------------------------------------------------
5285 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
5286 dnl ------------
5287 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
5288 dnl option if it is supported.
5289 AC_DEFUN([CF_PROG_LN_S],[
5290 AC_PROG_LN_S
5291 AC_MSG_CHECKING(if $LN_S -f options work)
5292
5293 rm -f conf$$.src conf$$dst
5294 echo >conf$$.dst
5295 echo first >conf$$.src
5296 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
5297         cf_prog_ln_sf=yes
5298 else
5299         cf_prog_ln_sf=no
5300 fi
5301 rm -f conf$$.dst conf$$src
5302 AC_MSG_RESULT($cf_prog_ln_sf)
5303
5304 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
5305 ])dnl
5306 dnl ---------------------------------------------------------------------------
5307 dnl CF_REGEX version: 12 updated: 2015/04/18 08:56:57
5308 dnl --------
5309 dnl Attempt to determine if we've got one of the flavors of regular-expression
5310 dnl code that we can support.
5311 AC_DEFUN([CF_REGEX],
5312 [
5313
5314 cf_regex_func=no
5315
5316 cf_regex_libs="regex re"
5317 case $host_os in
5318 (mingw*)
5319         cf_regex_libs="gnurx $cf_regex_libs"
5320         ;;
5321 esac
5322
5323 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5324         for cf_regex_lib in $cf_regex_libs
5325         do
5326                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5327                                 CF_ADD_LIB($cf_regex_lib)
5328                                 cf_regex_func=regcomp
5329                                 break])
5330         done
5331 ])
5332
5333 if test "$cf_regex_func" = no ; then
5334         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5335                 AC_CHECK_LIB(gen,compile,[
5336                                 CF_ADD_LIB(gen)
5337                                 cf_regex_func=compile])])
5338 fi
5339
5340 if test "$cf_regex_func" = no ; then
5341         AC_MSG_WARN(cannot find regular expression library)
5342 fi
5343
5344 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5345
5346 cf_cv_regex_hdrs=no
5347 case $cf_regex_func in
5348 (compile)
5349         for cf_regex_hdr in regexp.h regexpr.h
5350         do
5351                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5352                         char *p = compile("", "", "", 0);
5353                         int x = step("", "");
5354                 ],[
5355                         cf_cv_regex_hdrs=$cf_regex_hdr
5356                         break
5357                 ])
5358         done
5359         ;;
5360 (*)
5361         for cf_regex_hdr in regex.h
5362         do
5363                 AC_TRY_LINK([#include <sys/types.h>
5364 #include <$cf_regex_hdr>],[
5365                         regex_t *p;
5366                         int x = regcomp(p, "", 0);
5367                         int y = regexec(p, "", 0, 0, 0);
5368                         regfree(p);
5369                 ],[
5370                         cf_cv_regex_hdrs=$cf_regex_hdr
5371                         break
5372                 ])
5373         done
5374         ;;
5375 esac
5376
5377 ])
5378
5379 case $cf_cv_regex_hdrs in
5380         (no)            AC_MSG_WARN(no regular expression header found) ;;
5381         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
5382         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
5383         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
5384 esac
5385 ])dnl
5386 dnl ---------------------------------------------------------------------------
5387 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5388 dnl ----------------
5389 dnl Remove all -U and -D options that refer to the given symbol from a list
5390 dnl of C compiler options.  This works around the problem that not all
5391 dnl compilers process -U and -D options from left-to-right, so a -U option
5392 dnl cannot be used to cancel the effect of a preceding -D option.
5393 dnl
5394 dnl $1 = target (which could be the same as the source variable)
5395 dnl $2 = source (including '$')
5396 dnl $3 = symbol to remove
5397 define([CF_REMOVE_DEFINE],
5398 [
5399 $1=`echo "$2" | \
5400         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5401                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5402 ])dnl
5403 dnl ---------------------------------------------------------------------------
5404 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5405 dnl -------------
5406 dnl Remove the given library from the symbol
5407 dnl
5408 dnl $1 = target (which could be the same as the source variable)
5409 dnl $2 = source (including '$')
5410 dnl $3 = library to remove
5411 define([CF_REMOVE_LIB],
5412 [
5413 # remove $3 library from $2
5414 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5415 ])dnl
5416 dnl ---------------------------------------------------------------------------
5417 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
5418 dnl -------------
5419 AC_DEFUN([CF_RPATH_HACK],
5420 [
5421 AC_REQUIRE([CF_LD_RPATH_OPT])
5422 AC_MSG_CHECKING(for updated LDFLAGS)
5423 if test -n "$LD_RPATH_OPT" ; then
5424         AC_MSG_RESULT(maybe)
5425
5426         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5427         cf_rpath_list="/usr/lib /lib"
5428         if test "$cf_ldd_prog" != no
5429         then
5430                 cf_rpath_oops=
5431
5432 AC_TRY_LINK([#include <stdio.h>],
5433                 [printf("Hello");],
5434                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
5435                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
5436
5437                 # If we passed the link-test, but get a "not found" on a given library,
5438                 # this could be due to inept reconfiguration of gcc to make it only
5439                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5440                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5441                 # /usr/local libraries.
5442                 if test -n "$cf_rpath_oops"
5443                 then
5444                         for cf_rpath_src in $cf_rpath_oops
5445                         do
5446                                 for cf_rpath_dir in \
5447                                         /usr/local \
5448                                         /usr/pkg \
5449                                         /opt/sfw
5450                                 do
5451                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5452                                         then
5453                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5454                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5455                                                 break
5456                                         fi
5457                                 done
5458                         done
5459                 fi
5460         fi
5461
5462         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5463
5464         CF_RPATH_HACK_2(LDFLAGS)
5465         CF_RPATH_HACK_2(LIBS)
5466
5467         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5468 else
5469         AC_MSG_RESULT(no)
5470 fi
5471 AC_SUBST(EXTRA_LDFLAGS)
5472 ])dnl
5473 dnl ---------------------------------------------------------------------------
5474 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
5475 dnl ---------------
5476 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5477 dnl EXTRA_LDFLAGS for each -L option found.
5478 dnl
5479 dnl $cf_rpath_list contains a list of directories to ignore.
5480 dnl
5481 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5482 dnl      but LIBS often has misplaced -L options.
5483 AC_DEFUN([CF_RPATH_HACK_2],
5484 [
5485 CF_VERBOSE(...checking $1 [$]$1)
5486
5487 cf_rpath_dst=
5488 for cf_rpath_src in [$]$1
5489 do
5490         case $cf_rpath_src in
5491         (-L*)
5492
5493                 # check if this refers to a directory which we will ignore
5494                 cf_rpath_skip=no
5495                 if test -n "$cf_rpath_list"
5496                 then
5497                         for cf_rpath_item in $cf_rpath_list
5498                         do
5499                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5500                                 then
5501                                         cf_rpath_skip=yes
5502                                         break
5503                                 fi
5504                         done
5505                 fi
5506
5507                 if test "$cf_rpath_skip" = no
5508                 then
5509                         # transform the option
5510                         if test "$LD_RPATH_OPT" = "-R " ; then
5511                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5512                         else
5513                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5514                         fi
5515
5516                         # if we have not already added this, add it now
5517                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5518                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5519                         then
5520                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5521                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5522                         fi
5523                 fi
5524                 ;;
5525         esac
5526         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5527 done
5528 $1=$cf_rpath_dst
5529
5530 CF_VERBOSE(...checked $1 [$]$1)
5531 AC_SUBST(EXTRA_LDFLAGS)
5532 ])dnl
5533 dnl ---------------------------------------------------------------------------
5534 dnl CF_SHARED_OPTS version: 89 updated: 2015/08/15 18:38:59
5535 dnl --------------
5536 dnl --------------
5537 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5538 dnl library.
5539 dnl
5540 dnl Notes:
5541 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
5542 dnl the build-tree, i.e., by making use of the libraries that are compiled in
5543 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
5544 dnl shared library since that can lead to unexpected results at runtime.
5545 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
5546 dnl libraries are compiled in ../../lib
5547 dnl
5548 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5549 dnl to install symbolic links to the rel/abi versions of shared libraries.
5550 dnl
5551 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5552 dnl version when making symbolic links.
5553 dnl
5554 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5555 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5556 dnl (ex: libncurses.so.<ver>).
5557 dnl
5558 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5559 AC_DEFUN([CF_SHARED_OPTS],
5560 [
5561         AC_REQUIRE([CF_LD_RPATH_OPT])
5562         RM_SHARED_OPTS=
5563         LOCAL_LDFLAGS=
5564         LOCAL_LDFLAGS2=
5565         LD_SHARED_OPTS=
5566         INSTALL_LIB="-m 644"
5567         : ${rel_builddir:=.}
5568
5569         shlibdir=$libdir
5570         AC_SUBST(shlibdir)
5571
5572         MAKE_DLLS="#"
5573         AC_SUBST(MAKE_DLLS)
5574
5575         cf_cv_do_symlinks=no
5576         cf_ld_rpath_opt=
5577         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5578
5579         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5580         AC_ARG_WITH(shlib-version,
5581         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5582         [test -z "$withval" && withval=auto
5583         case $withval in
5584         (yes)
5585                 cf_cv_shlib_version=auto
5586                 ;;
5587         (rel|abi|auto)
5588                 cf_cv_shlib_version=$withval
5589                 ;;
5590         (*)
5591                 AC_MSG_RESULT($withval)
5592                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
5593                 ;;
5594         esac
5595         ],[cf_cv_shlib_version=auto])
5596         AC_MSG_RESULT($cf_cv_shlib_version)
5597
5598         cf_cv_rm_so_locs=no
5599         cf_try_cflags=
5600
5601         # Some less-capable ports of gcc support only -fpic
5602         CC_SHARED_OPTS=
5603         if test "$GCC" = yes
5604         then
5605                 AC_MSG_CHECKING(which $CC option to use)
5606                 cf_save_CFLAGS="$CFLAGS"
5607                 for CC_SHARED_OPTS in -fPIC -fpic ''
5608                 do
5609                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5610                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5611                 done
5612                 AC_MSG_RESULT($CC_SHARED_OPTS)
5613                 CFLAGS="$cf_save_CFLAGS"
5614         fi
5615
5616         cf_cv_shlib_version_infix=no
5617
5618         case $cf_cv_system_name in
5619         (aix4.[3-9]*|aix[[5-7]]*)
5620                 if test "$GCC" = yes; then
5621                         CC_SHARED_OPTS='-Wl,-brtl'
5622                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5623                 else
5624                         CC_SHARED_OPTS='-brtl'
5625                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
5626                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5627                 fi
5628                 ;;
5629         (beos*)
5630                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5631                 ;;
5632         (cygwin*)
5633                 CC_SHARED_OPTS=
5634                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5635                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5636                 cf_cv_shlib_version=cygdll
5637                 cf_cv_shlib_version_infix=cygdll
5638                 shlibdir=$bindir
5639                 MAKE_DLLS=
5640                 cat >mk_shared_lib.sh <<-CF_EOF
5641                 #!$SHELL
5642                 SHARED_LIB=\[$]1
5643                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5644                 shift
5645                 cat <<-EOF
5646                 Linking shared library
5647                 ** SHARED_LIB \[$]SHARED_LIB
5648                 ** IMPORT_LIB \[$]IMPORT_LIB
5649 EOF
5650                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5651 CF_EOF
5652                 chmod +x mk_shared_lib.sh
5653                 ;;
5654         (msys*)
5655                 CC_SHARED_OPTS=
5656                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5657                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5658                 cf_cv_shlib_version=msysdll
5659                 cf_cv_shlib_version_infix=msysdll
5660                 shlibdir=$bindir
5661                 MAKE_DLLS=
5662                 cat >mk_shared_lib.sh <<-CF_EOF
5663                 #!$SHELL
5664                 SHARED_LIB=\[$]1
5665                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5666                 shift
5667                 cat <<-EOF
5668                 Linking shared library
5669                 ** SHARED_LIB \[$]SHARED_LIB
5670                 ** IMPORT_LIB \[$]IMPORT_LIB
5671 EOF
5672                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5673 CF_EOF
5674                 chmod +x mk_shared_lib.sh
5675                 ;;
5676         (darwin*)
5677                 cf_try_cflags="no-cpp-precomp"
5678                 CC_SHARED_OPTS="-dynamic"
5679                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5680                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5681                 cf_cv_shlib_version_infix=yes
5682                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5683                         cf_save_LDFLAGS=$LDFLAGS
5684                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5685                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5686                                 LDFLAGS=$cf_save_LDFLAGS])
5687                 if test $cf_cv_ldflags_search_paths_first = yes; then
5688                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5689                 fi
5690                 ;;
5691         (hpux[[7-8]]*)
5692                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
5693                 if test "$GCC" != yes; then
5694                         CC_SHARED_OPTS='+Z'
5695                 fi
5696                 MK_SHARED_LIB='${LD} -b -o $[@]'
5697                 INSTALL_LIB="-m 555"
5698                 ;;
5699         (hpux*)
5700                 # (tested with gcc 2.7.2 -- I don't have c89)
5701                 if test "$GCC" = yes; then
5702                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5703                 else
5704                         CC_SHARED_OPTS='+Z'
5705                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5706                 fi
5707                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5708                 # HP-UX shared libraries must be executable, and should be
5709                 # readonly to exploit a quirk in the memory manager.
5710                 INSTALL_LIB="-m 555"
5711                 ;;
5712         (interix*)
5713                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5714                 if test "$cf_cv_shlib_version" = rel; then
5715                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5716                 else
5717                         cf_shared_soname='`basename $@`'
5718                 fi
5719                 CC_SHARED_OPTS=
5720                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5721                 ;;
5722         (irix*)
5723                 if test "$cf_cv_enable_rpath" = yes ; then
5724                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5725                 fi
5726                 # tested with IRIX 5.2 and 'cc'.
5727                 if test "$GCC" != yes; then
5728                         CC_SHARED_OPTS='-KPIC'
5729                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5730                 else
5731                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5732                 fi
5733                 cf_cv_rm_so_locs=yes
5734                 ;;
5735         (linux*|gnu*|k*bsd*-gnu)
5736                 if test "$DFT_LWR_MODEL" = "shared" ; then
5737                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5738                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5739                 fi
5740                 if test "$cf_cv_enable_rpath" = yes ; then
5741                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5742                 fi
5743                 CF_SHARED_SONAME
5744                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5745                 ;;
5746         (mingw*)
5747                 cf_cv_shlib_version=mingw
5748                 cf_cv_shlib_version_infix=mingw
5749                 shlibdir=$bindir
5750                 MAKE_DLLS=
5751                 if test "$DFT_LWR_MODEL" = "shared" ; then
5752                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
5753                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5754                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
5755                 fi
5756                 CC_SHARED_OPTS=
5757                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5758                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5759                 cat >mk_shared_lib.sh <<-CF_EOF
5760                 #!$SHELL
5761                 SHARED_LIB=\[$]1
5762                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5763                 shift
5764                 cat <<-EOF
5765                 Linking shared library
5766                 ** SHARED_LIB \[$]SHARED_LIB
5767                 ** IMPORT_LIB \[$]IMPORT_LIB
5768 EOF
5769                 exec \[$]* -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5770 CF_EOF
5771                 chmod +x mk_shared_lib.sh
5772                 ;;
5773         (openbsd[[2-9]].*|mirbsd*)
5774                 if test "$DFT_LWR_MODEL" = "shared" ; then
5775                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5776                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5777                 fi
5778                 if test "$cf_cv_enable_rpath" = yes ; then
5779                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5780                 fi
5781                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5782                 CF_SHARED_SONAME
5783                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5784                 ;;
5785         (nto-qnx*|openbsd*|freebsd[[12]].*)
5786                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5787                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5788                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5789                 ;;
5790         (dragonfly*|freebsd*)
5791                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5792                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5793                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5794                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
5795                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5796                 fi
5797                 CF_SHARED_SONAME
5798                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5799                 ;;
5800         (netbsd*)
5801                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5802                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5803                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5804                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5805                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5806                         if test "$cf_cv_shlib_version" = auto; then
5807                         if test -f /usr/libexec/ld.elf_so; then
5808                                 cf_cv_shlib_version=abi
5809                         else
5810                                 cf_cv_shlib_version=rel
5811                         fi
5812                         fi
5813                         CF_SHARED_SONAME
5814                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
5815                 else
5816                         MK_SHARED_LIB='${CC} -Wl,-shared -Wl,-Bshareable -o $[@]'
5817                 fi
5818                 ;;
5819         (osf*|mls+*)
5820                 # tested with OSF/1 V3.2 and 'cc'
5821                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
5822                 # link with shared libs).
5823                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
5824                 case $host_os in
5825                 (osf4*)
5826                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
5827                         ;;
5828                 esac
5829                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
5830                 if test "$DFT_LWR_MODEL" = "shared" ; then
5831                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5832                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5833                 fi
5834                 cf_cv_rm_so_locs=yes
5835                 ;;
5836         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
5837                 # tested with osr5.0.5
5838                 if test "$GCC" != yes; then
5839                         CC_SHARED_OPTS='-belf -KPIC'
5840                 fi
5841                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
5842                 if test "$cf_cv_enable_rpath" = yes ; then
5843                         # only way is to set LD_RUN_PATH but no switch for it
5844                         RUN_PATH=$libdir
5845                 fi
5846                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5847                 LINK_PROGS='LD_RUN_PATH=${libdir}'
5848                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
5849                 ;;
5850         (sunos4*)
5851                 # tested with SunOS 4.1.1 and gcc 2.7.0
5852                 if test "$GCC" != yes; then
5853                         CC_SHARED_OPTS='-KPIC'
5854                 fi
5855                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
5856                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5857                 ;;
5858         (solaris2*)
5859                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
5860                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
5861                 if test "$DFT_LWR_MODEL" = "shared" ; then
5862                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
5863                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5864                 fi
5865                 if test "$cf_cv_enable_rpath" = yes ; then
5866                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
5867                 fi
5868                 CF_SHARED_SONAME
5869                 if test "$GCC" != yes; then
5870                         cf_save_CFLAGS="$CFLAGS"
5871                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
5872                         do
5873                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
5874                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
5875                         done
5876                         CFLAGS="$cf_save_CFLAGS"
5877                         CC_SHARED_OPTS=$cf_shared_opts
5878                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5879                 else
5880                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5881                 fi
5882                 ;;
5883         (sysv5uw7*|unix_sv*)
5884                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
5885                 if test "$GCC" != yes; then
5886                         CC_SHARED_OPTS='-KPIC'
5887                 fi
5888                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
5889                 ;;
5890         (*)
5891                 CC_SHARED_OPTS='unknown'
5892                 MK_SHARED_LIB='echo unknown'
5893                 ;;
5894         esac
5895
5896         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
5897         case "$cf_cv_shlib_version" in
5898         (rel|abi)
5899                 case "$MK_SHARED_LIB" in
5900                 (*'-o $[@]')
5901                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
5902                         ;;
5903                 (*)
5904                         AC_MSG_WARN(ignored --with-shlib-version)
5905                         ;;
5906                 esac
5907                 ;;
5908         esac
5909
5910         if test -n "$cf_try_cflags"
5911         then
5912 cat > conftest.$ac_ext <<EOF
5913 #line __oline__ "${as_me:-configure}"
5914 #include <stdio.h>
5915 int main(int argc, char *argv[[]])
5916 {
5917         printf("hello\n");
5918         return (argv[[argc-1]] == 0) ;
5919 }
5920 EOF
5921                 cf_save_CFLAGS="$CFLAGS"
5922                 for cf_opt in $cf_try_cflags
5923                 do
5924                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
5925                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
5926                         if AC_TRY_EVAL(ac_compile); then
5927                                 AC_MSG_RESULT(yes)
5928                                 cf_save_CFLAGS="$CFLAGS"
5929                         else
5930                                 AC_MSG_RESULT(no)
5931                         fi
5932                 done
5933                 CFLAGS="$cf_save_CFLAGS"
5934         fi
5935
5936
5937         # RPATH_LIST is a colon-separated list of directories
5938         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
5939         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
5940
5941         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
5942
5943         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
5944         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
5945
5946         AC_SUBST(CC_SHARED_OPTS)
5947         AC_SUBST(LD_RPATH_OPT)
5948         AC_SUBST(LD_SHARED_OPTS)
5949         AC_SUBST(MK_SHARED_LIB)
5950         AC_SUBST(RM_SHARED_OPTS)
5951
5952         AC_SUBST(LINK_PROGS)
5953         AC_SUBST(LINK_TESTS)
5954
5955         AC_SUBST(EXTRA_LDFLAGS)
5956         AC_SUBST(LOCAL_LDFLAGS)
5957         AC_SUBST(LOCAL_LDFLAGS2)
5958
5959         AC_SUBST(INSTALL_LIB)
5960         AC_SUBST(RPATH_LIST)
5961 ])dnl
5962 dnl ---------------------------------------------------------------------------
5963 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
5964 dnl ----------------
5965 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
5966 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
5967 dnl option.
5968 dnl
5969 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
5970 dnl If missing, use "rel".
5971 define([CF_SHARED_SONAME],
5972 [
5973         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
5974         if test "$cf_cv_shlib_version" = rel; then
5975                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
5976         else
5977                 cf_cv_shared_soname='`basename $[@]`'
5978         fi
5979 ])
5980 dnl ---------------------------------------------------------------------------
5981 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
5982 dnl -----------
5983 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
5984 dnl programs need this test).
5985 dnl
5986 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
5987 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
5988 dnl winsize declaration is left alone - we may revisit this if Apple choose to
5989 dnl break that part of the interface as well.
5990 AC_DEFUN([CF_SIGWINCH],
5991 [
5992 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
5993         AC_TRY_COMPILE([
5994 #include <sys/types.h>
5995 #include <sys/signal.h>
5996 ],[int x = SIGWINCH],
5997         [cf_cv_define_sigwinch=yes],
5998         [AC_TRY_COMPILE([
5999 #undef _XOPEN_SOURCE
6000 #undef _POSIX_SOURCE
6001 #undef _POSIX_C_SOURCE
6002 #include <sys/types.h>
6003 #include <sys/signal.h>
6004 ],[int x = SIGWINCH],
6005         [cf_cv_define_sigwinch=maybe],
6006         [cf_cv_define_sigwinch=no])
6007 ])
6008 ])
6009
6010 if test "$cf_cv_define_sigwinch" = maybe ; then
6011 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
6012 cf_cv_fixup_sigwinch=unknown
6013 cf_sigwinch=32
6014 while test $cf_sigwinch != 1
6015 do
6016         AC_TRY_COMPILE([
6017 #undef _XOPEN_SOURCE
6018 #undef _POSIX_SOURCE
6019 #undef _POSIX_C_SOURCE
6020 #include <sys/types.h>
6021 #include <sys/signal.h>
6022 ],[
6023 #if SIGWINCH != $cf_sigwinch
6024 make an error
6025 #endif
6026 int x = SIGWINCH],
6027         [cf_cv_fixup_sigwinch=$cf_sigwinch
6028          break])
6029
6030 cf_sigwinch=`expr $cf_sigwinch - 1`
6031 done
6032 ])
6033
6034         if test "$cf_cv_fixup_sigwinch" != unknown ; then
6035                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
6036         fi
6037 fi
6038 ])dnl
6039 dnl ---------------------------------------------------------------------------
6040 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
6041 dnl ---------------
6042 dnl signal handler, but there are some gcc depedencies in that recommendation.
6043 dnl Try anyway.
6044 AC_DEFUN([CF_SIG_ATOMIC_T],
6045 [
6046 AC_MSG_CHECKING(for signal global datatype)
6047 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
6048         for cf_type in \
6049                 "volatile sig_atomic_t" \
6050                 "sig_atomic_t" \
6051                 "int"
6052         do
6053         AC_TRY_COMPILE([
6054 #include <sys/types.h>
6055 #include <signal.h>
6056 #include <stdio.h>
6057
6058 extern $cf_type x;
6059 $cf_type x;
6060 static void handler(int sig)
6061 {
6062         x = 5;
6063 }],
6064                 [signal(SIGINT, handler);
6065                  x = 1],
6066                 [cf_cv_sig_atomic_t=$cf_type],
6067                 [cf_cv_sig_atomic_t=no])
6068                 test "$cf_cv_sig_atomic_t" != no && break
6069         done
6070         ])
6071 AC_MSG_RESULT($cf_cv_sig_atomic_t)
6072 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
6073 ])dnl
6074 dnl ---------------------------------------------------------------------------
6075 dnl CF_SIZECHANGE version: 11 updated: 2015/04/18 08:56:57
6076 dnl -------------
6077 dnl Check for definitions & structures needed for window size-changing
6078 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
6079 AC_DEFUN([CF_SIZECHANGE],
6080 [
6081 AC_REQUIRE([CF_STRUCT_TERMIOS])
6082 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
6083         cf_cv_sizechange=unknown
6084         cf_save_CPPFLAGS="$CPPFLAGS"
6085
6086 for cf_opts in "" "NEED_PTEM_H"
6087 do
6088
6089         CPPFLAGS="$cf_save_CPPFLAGS"
6090         test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
6091         AC_TRY_COMPILE([#include <sys/types.h>
6092 #ifdef HAVE_TERMIOS_H
6093 #include <termios.h>
6094 #else
6095 #ifdef HAVE_TERMIO_H
6096 #include <termio.h>
6097 #endif
6098 #endif
6099 #ifdef NEED_PTEM_H
6100 /* This is a workaround for SCO:  they neglected to define struct winsize in
6101  * termios.h -- it's only in termio.h and ptem.h
6102  */
6103 #include        <sys/stream.h>
6104 #include        <sys/ptem.h>
6105 #endif
6106 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
6107 #include <sys/ioctl.h>
6108 #endif
6109 ],[
6110 #ifdef TIOCGSIZE
6111         struct ttysize win;     /* FIXME: what system is this? */
6112         int y = win.ts_lines;
6113         int x = win.ts_cols;
6114 #else
6115 #ifdef TIOCGWINSZ
6116         struct winsize win;
6117         int y = win.ws_row;
6118         int x = win.ws_col;
6119 #else
6120         no TIOCGSIZE or TIOCGWINSZ
6121 #endif /* TIOCGWINSZ */
6122 #endif /* TIOCGSIZE */
6123         ],
6124         [cf_cv_sizechange=yes],
6125         [cf_cv_sizechange=no])
6126
6127         CPPFLAGS="$cf_save_CPPFLAGS"
6128         if test "$cf_cv_sizechange" = yes ; then
6129                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
6130                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
6131                 break
6132         fi
6133 done
6134 ])
6135 if test "$cf_cv_sizechange" != no ; then
6136         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechar declarations are provided])
6137         case $cf_cv_sizechange in
6138         (NEED*)
6139                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
6140                 ;;
6141         esac
6142 fi
6143 ])dnl
6144 dnl ---------------------------------------------------------------------------
6145 dnl CF_SRC_MODULES version: 29 updated: 2015/04/12 11:42:01
6146 dnl --------------
6147 dnl For each parameter, test if the source-directory exists, and if it contains
6148 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
6149 dnl use in CF_LIB_RULES.
6150 dnl
6151 dnl This uses the configured value to make the lists SRC_SUBDIRS and
6152 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
6153 AC_DEFUN([CF_SRC_MODULES],
6154 [
6155 AC_MSG_CHECKING(for src modules)
6156
6157 # dependencies and linker-arguments for test-programs
6158 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
6159 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
6160 if test "$DFT_LWR_MODEL" = "libtool"; then
6161         TEST_ARGS="${TEST_DEPS}"
6162         TEST_ARG2="${TEST_DEP2}"
6163 else
6164         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
6165         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
6166 fi
6167
6168 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
6169 cf_cv_src_modules=
6170 for cf_dir in $1
6171 do
6172         if test -f $srcdir/$cf_dir/modules; then
6173
6174                 # We may/may not have tack in the distribution, though the
6175                 # makefile is.
6176                 if test $cf_dir = tack ; then
6177                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
6178                                 continue
6179                         fi
6180                 fi
6181
6182                 if test -z "$cf_cv_src_modules"; then
6183                         cf_cv_src_modules=$cf_dir
6184                 else
6185                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
6186                 fi
6187
6188                 # Make the ncurses_cfg.h file record the library interface files as
6189                 # well.  These are header files that are the same name as their
6190                 # directory.  Ncurses is the only library that does not follow
6191                 # that pattern.
6192                 if test $cf_dir = tack ; then
6193                         continue
6194                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
6195                         CF_UPPER(cf_have_include,$cf_dir)
6196                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
6197                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
6198                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
6199                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
6200                         if test "$DFT_LWR_MODEL" = "libtool"; then
6201                                 TEST_ARGS="${TEST_DEPS}"
6202                                 TEST_ARG2="${TEST_DEP2}"
6203                         else
6204                                 TEST_ARGS="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARGS"
6205                                 TEST_ARG2="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARG2"
6206                         fi
6207                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
6208                 fi
6209         fi
6210 done
6211 AC_MSG_RESULT($cf_cv_src_modules)
6212
6213 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
6214 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
6215
6216 AC_SUBST(TEST_ARGS)
6217 AC_SUBST(TEST_DEPS)
6218
6219 AC_SUBST(TEST_ARG2)
6220 AC_SUBST(TEST_DEP2)
6221
6222 SRC_SUBDIRS=
6223 if test "x$cf_with_manpages" != xno ; then
6224         SRC_SUBDIRS="$SRC_SUBDIRS man"
6225 fi
6226 SRC_SUBDIRS="$SRC_SUBDIRS include"
6227 for cf_dir in $cf_cv_src_modules
6228 do
6229         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
6230 done
6231 if test "x$cf_with_tests" != "xno" ; then
6232         SRC_SUBDIRS="$SRC_SUBDIRS test"
6233 fi
6234 # always make this, to install the ncurses-config script
6235 SRC_SUBDIRS="$SRC_SUBDIRS misc"
6236 if test "$cf_with_cxx_binding" != no; then
6237         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
6238         SRC_SUBDIRS="$SRC_SUBDIRS c++"
6239 fi
6240
6241 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
6242 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
6243
6244 AC_SUBST(PC_MODULES_TO_MAKE)
6245
6246 ADA_SUBDIRS=
6247 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
6248         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
6249         ADA_SUBDIRS="gen src"
6250         if test "x$cf_with_tests" != "xno" ; then
6251                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
6252         fi
6253 fi
6254
6255 SUB_MAKEFILES=
6256 for cf_dir in $SRC_SUBDIRS
6257 do
6258         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
6259 done
6260
6261 if test -n "$ADA_SUBDIRS"; then
6262         for cf_dir in $ADA_SUBDIRS
6263         do
6264                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
6265         done
6266         AC_SUBST(ADA_SUBDIRS)
6267 fi
6268 ])dnl
6269 dnl ---------------------------------------------------------------------------
6270 dnl CF_STDCPP_LIBRARY version: 11 updated: 2015/10/17 19:03:33
6271 dnl -----------------
6272 dnl Check for -lstdc++, which is GNU's standard C++ library.
6273 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
6274 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
6275 dnl add it to $CXXLIBS.
6276 AC_DEFUN([CF_STDCPP_LIBRARY],
6277 [
6278 if test -n "$GXX" ; then
6279
6280         cf_save="$LIBS"
6281         LIBS="$LIBS $CXXLIBS"
6282         AC_MSG_CHECKING(if we already have C++ library)
6283         AC_TRY_LINK([
6284                         #include <iostream>],[
6285                         std::cout << "Hello World!" << std::endl;],
6286                 [cf_have_libstdcpp=yes],
6287                 [cf_have_libstdcpp=no])
6288         AC_MSG_RESULT($cf_have_libstdcpp)
6289         LIBS="$cf_save"
6290
6291         if test $cf_have_libstdcpp != yes
6292         then
6293                 case $cf_cv_system_name in
6294                 (os2*)
6295                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
6296                                 cf_stdcpp_libname=stdcpp
6297                         else
6298                                 cf_stdcpp_libname=stdc++
6299                         fi
6300                         ;;
6301                 (*)
6302                         cf_stdcpp_libname=stdc++
6303                         ;;
6304                 esac
6305
6306                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
6307                         cf_save="$LIBS"
6308                         LIBS="$LIBS $CXXLIBS"
6309                         CF_ADD_LIB($cf_stdcpp_libname)
6310                 AC_TRY_LINK([
6311                                 #include <iostream>],[
6312                                 std::cout << "Hello World!" << std::endl;],
6313                         [cf_cv_libstdcpp=yes],
6314                         [cf_cv_libstdcpp=no])
6315                         LIBS="$cf_save"
6316                 ])
6317                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
6318         fi
6319 fi
6320 ])dnl
6321 dnl ---------------------------------------------------------------------------
6322 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
6323 dnl --------------
6324 dnl     Remove "-g" option from the compiler options
6325 AC_DEFUN([CF_STRIP_G_OPT],
6326 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
6327 dnl ---------------------------------------------------------------------------
6328 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
6329 dnl -------------------
6330 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
6331 dnl do this if we've found the sigaction function.
6332 AC_DEFUN([CF_STRUCT_SIGACTION],[
6333 AC_REQUIRE([CF_XOPEN_SOURCE])
6334
6335 if test "$ac_cv_func_sigaction" = yes; then
6336 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
6337 AC_TRY_COMPILE([
6338 #include <sys/types.h>
6339 #include <signal.h>],
6340         [struct sigaction act],
6341         [sigact_bad=no],
6342         [
6343 AC_TRY_COMPILE([
6344 #define _POSIX_SOURCE
6345 #include <sys/types.h>
6346 #include <signal.h>],
6347         [struct sigaction act],
6348         [sigact_bad=yes
6349          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
6350          [sigact_bad=unknown])])
6351 AC_MSG_RESULT($sigact_bad)
6352 fi
6353 ])dnl
6354 dnl ---------------------------------------------------------------------------
6355 dnl CF_STRUCT_TERMIOS version: 8 updated: 2015/04/15 19:08:48
6356 dnl -----------------
6357 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
6358 AC_DEFUN([CF_STRUCT_TERMIOS],[
6359 AC_REQUIRE([CF_XOPEN_SOURCE])
6360
6361 AC_CHECK_HEADERS( \
6362 termio.h \
6363 termios.h \
6364 unistd.h \
6365 )
6366
6367 if test "$ISC" = yes ; then
6368         AC_CHECK_HEADERS( sys/termio.h )
6369 fi
6370 if test "$ac_cv_header_termios_h" = yes ; then
6371         case "$CFLAGS $CPPFLAGS" in
6372         (*-D_POSIX_SOURCE*)
6373                 termios_bad=dunno ;;
6374         (*)     termios_bad=maybe ;;
6375         esac
6376         if test "$termios_bad" = maybe ; then
6377         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
6378         AC_TRY_COMPILE([#include <termios.h>],
6379                 [struct termios foo; int x = foo.c_iflag],
6380                 termios_bad=no, [
6381                 AC_TRY_COMPILE([
6382 #define _POSIX_SOURCE
6383 #include <termios.h>],
6384                         [struct termios foo; int x = foo.c_iflag],
6385                         termios_bad=unknown,
6386                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
6387                         ])
6388         AC_MSG_RESULT($termios_bad)
6389         fi
6390 fi
6391 ])dnl
6392 dnl ---------------------------------------------------------------------------
6393 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
6394 dnl --------------
6395 dnl Construct a search-list for a nonstandard header/lib-file
6396 dnl     $1 = the variable to return as result
6397 dnl     $2 = the package name
6398 dnl     $3 = the subdirectory, e.g., bin, include or lib
6399 AC_DEFUN([CF_SUBDIR_PATH],
6400 [
6401 $1=
6402
6403 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
6404
6405 for cf_subdir_prefix in \
6406         /usr \
6407         /usr/local \
6408         /usr/pkg \
6409         /opt \
6410         /opt/local \
6411         [$]HOME
6412 do
6413         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
6414 done
6415 ])dnl
6416 dnl ---------------------------------------------------------------------------
6417 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
6418 dnl -----------
6419 dnl     Shorthand macro for substituting things that the user may override
6420 dnl     with an environment variable.
6421 dnl
6422 dnl     $1 = condition to pass to "test"
6423 dnl     $2 = environment variable
6424 dnl     $3 = value if the test succeeds
6425 dnl     $4 = value if the test fails
6426 AC_DEFUN([CF_SUBST_IF],
6427 [
6428 if test $1 ; then
6429         $2=$3
6430 ifelse($4,,,[else
6431         $2=$4])
6432 fi
6433 AC_SUBST($2)
6434 ])dnl
6435 dnl ---------------------------------------------------------------------------
6436 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
6437 dnl ------------------------
6438 dnl Get the version-number for use in shared-library naming, etc.
6439 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
6440 [
6441 AC_REQUIRE([CF_PROG_EGREP])
6442 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6443 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6444 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6445 cf_cv_abi_version=${NCURSES_MAJOR}
6446 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
6447 dnl Show the computed version, for logging
6448 cf_cv_timestamp=`date`
6449 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
6450 dnl We need these values in the generated headers
6451 AC_SUBST(NCURSES_MAJOR)
6452 AC_SUBST(NCURSES_MINOR)
6453 AC_SUBST(NCURSES_PATCH)
6454 dnl We need these values in the generated makefiles
6455 AC_SUBST(cf_cv_rel_version)
6456 AC_SUBST(cf_cv_abi_version)
6457 AC_SUBST(cf_cv_builtin_bool)
6458 AC_SUBST(cf_cv_header_stdbool_h)
6459 AC_SUBST(cf_cv_type_of_bool)dnl
6460 ])dnl
6461 dnl ---------------------------------------------------------------------------
6462 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
6463 dnl ------------------
6464 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6465 dnl older SCO configurations.
6466 AC_DEFUN([CF_SYS_TIME_SELECT],
6467 [
6468 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6469 AC_CACHE_VAL(cf_cv_sys_time_select,[
6470 AC_TRY_COMPILE([
6471 #include <sys/types.h>
6472 #ifdef HAVE_SYS_TIME_H
6473 #include <sys/time.h>
6474 #endif
6475 #ifdef HAVE_SYS_SELECT_H
6476 #include <sys/select.h>
6477 #endif
6478 ],[],[cf_cv_sys_time_select=yes],
6479          [cf_cv_sys_time_select=no])
6480          ])
6481 AC_MSG_RESULT($cf_cv_sys_time_select)
6482 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
6483 ])dnl
6484 dnl ---------------------------------------------------------------------------
6485 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
6486 dnl ---------------
6487 dnl Define a top_builddir symbol, for applications that need an absolute path.
6488 AC_DEFUN([CF_TOP_BUILDDIR],
6489 [
6490 top_builddir=ifelse($1,,`pwd`,$1)
6491 AC_SUBST(top_builddir)
6492 ])dnl
6493 dnl ---------------------------------------------------------------------------
6494 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6495 dnl -------------------
6496 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6497 dnl can define it successfully.
6498 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6499 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6500         AC_TRY_COMPILE([
6501 #include <stdlib.h>
6502 #include <string.h>
6503 #include <sys/types.h>
6504 ],[
6505 #ifndef _XOPEN_SOURCE
6506 make an error
6507 #endif],
6508         [cf_cv_xopen_source=no],
6509         [cf_save="$CPPFLAGS"
6510          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6511          AC_TRY_COMPILE([
6512 #include <stdlib.h>
6513 #include <string.h>
6514 #include <sys/types.h>
6515 ],[
6516 #ifdef _XOPEN_SOURCE
6517 make an error
6518 #endif],
6519         [cf_cv_xopen_source=no],
6520         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6521         CPPFLAGS="$cf_save"
6522         ])
6523 ])
6524
6525 if test "$cf_cv_xopen_source" != no ; then
6526         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6527         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6528         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6529         CF_ADD_CFLAGS($cf_temp_xopen_source)
6530 fi
6531 ])
6532 dnl ---------------------------------------------------------------------------
6533 dnl CF_TYPEOF_CHTYPE version: 9 updated: 2012/10/06 17:56:13
6534 dnl ----------------
6535 dnl Determine the type we should use for chtype (and attr_t, which is treated
6536 dnl as the same thing).  We want around 32 bits, so on most machines want a
6537 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6538 dnl wide characters, we have to have a type compatible with that, as well.
6539 AC_DEFUN([CF_TYPEOF_CHTYPE],
6540 [
6541 AC_MSG_CHECKING([for type of chtype])
6542 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6543                 AC_TRY_RUN([
6544 #define WANT_BITS 31
6545 #include <stdio.h>
6546 int main()
6547 {
6548         FILE *fp = fopen("cf_test.out", "w");
6549         if (fp != 0) {
6550                 char *result = "long";
6551                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6552                         int n;
6553                         unsigned int x, y;
6554                         for (n = 0; n < WANT_BITS; n++) {
6555                                 x = (1 << n);
6556                                 y = (x >> n);
6557                                 if (y != 1 || x == 0) {
6558                                         x = 0;
6559                                         break;
6560                                 }
6561                         }
6562                         /*
6563                          * If x is nonzero, an int is big enough for the bits
6564                          * that we want.
6565                          */
6566                         result = (x != 0) ? "int" : "long";
6567                 }
6568                 fputs(result, fp);
6569                 fclose(fp);
6570         }
6571         ${cf_cv_main_return:-return}(0);
6572 }
6573                 ],
6574                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6575                 [cf_cv_typeof_chtype=long],
6576                 [cf_cv_typeof_chtype=long])
6577                 rm -f cf_test.out
6578         ])
6579 AC_MSG_RESULT($cf_cv_typeof_chtype)
6580
6581 AC_SUBST(cf_cv_typeof_chtype)
6582 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
6583 ])dnl
6584 dnl ---------------------------------------------------------------------------
6585 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
6586 dnl -----------------
6587 dnl
6588 AC_DEFUN([CF_TYPE_SIGACTION],
6589 [
6590 AC_MSG_CHECKING([for type sigaction_t])
6591 AC_CACHE_VAL(cf_cv_type_sigaction,[
6592         AC_TRY_COMPILE([
6593 #include <signal.h>],
6594                 [sigaction_t x],
6595                 [cf_cv_type_sigaction=yes],
6596                 [cf_cv_type_sigaction=no])])
6597 AC_MSG_RESULT($cf_cv_type_sigaction)
6598 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
6599 ])dnl
6600 dnl ---------------------------------------------------------------------------
6601 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6602 dnl --------------------
6603 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6604 dnl won't, but they're still there.
6605 AC_DEFUN([CF_UNSIGNED_LITERALS],
6606 [
6607 AC_MSG_CHECKING([if unsigned literals are legal])
6608 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6609         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6610                 [cf_cv_unsigned_literals=yes],
6611                 [cf_cv_unsigned_literals=no])
6612         ])
6613 AC_MSG_RESULT($cf_cv_unsigned_literals)
6614 ])dnl
6615 dnl ---------------------------------------------------------------------------
6616 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6617 dnl --------
6618 dnl Make an uppercase version of a variable
6619 dnl $1=uppercase($2)
6620 AC_DEFUN([CF_UPPER],
6621 [
6622 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6623 ])dnl
6624 dnl ---------------------------------------------------------------------------
6625 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
6626 dnl -----------
6627 dnl Check for multibyte support, and if not found, utf8 compatibility library
6628 AC_DEFUN([CF_UTF8_LIB],
6629 [
6630 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6631         cf_save_LIBS="$LIBS"
6632         AC_TRY_LINK([
6633 #include <stdlib.h>],[putwc(0,0);],
6634         [cf_cv_utf8_lib=yes],
6635         [CF_FIND_LINKAGE([
6636 #include <libutf8.h>],[putwc(0,0);],utf8,
6637                 [cf_cv_utf8_lib=add-on],
6638                 [cf_cv_utf8_lib=no])
6639 ])])
6640
6641 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6642 # ncurses/ncursesw:
6643 if test "$cf_cv_utf8_lib" = "add-on" ; then
6644         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
6645         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6646         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6647         CF_ADD_LIBS($cf_cv_library_file_utf8)
6648 fi
6649 ])dnl
6650 dnl ---------------------------------------------------------------------------
6651 dnl CF_VA_COPY version: 3 updated: 2012/10/06 11:17:15
6652 dnl ----------
6653 dnl check for va_copy, part of stdarg.h
6654 dnl Also, workaround for glibc's __va_copy, by checking for both.
6655 AC_DEFUN([CF_VA_COPY],[
6656 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6657 AC_TRY_LINK([
6658 #include <stdarg.h>
6659 ],[
6660         static va_list dst;
6661         static va_list src;
6662         va_copy(dst, src)],
6663         cf_cv_have_va_copy=yes,
6664         cf_cv_have_va_copy=no)])
6665
6666 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
6667
6668 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6669 AC_TRY_LINK([
6670 #include <stdarg.h>
6671 ],[
6672         static va_list dst;
6673         static va_list src;
6674         __va_copy(dst, src)],
6675         cf_cv_have___va_copy=yes,
6676         cf_cv_have___va_copy=no)])
6677
6678 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
6679 ])
6680 dnl ---------------------------------------------------------------------------
6681 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6682 dnl ----------
6683 dnl Use AC_VERBOSE w/o the warnings
6684 AC_DEFUN([CF_VERBOSE],
6685 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6686 CF_MSG_LOG([$1])
6687 ])dnl
6688 dnl ---------------------------------------------------------------------------
6689 dnl CF_VERSION_INFO version: 7 updated: 2015/04/17 21:13:04
6690 dnl ---------------
6691 dnl Define several useful symbols derived from the VERSION file.  A separate
6692 dnl file is preferred to embedding the version numbers in various scripts.
6693 dnl (automake is a textbook-example of why the latter is a bad idea, but there
6694 dnl are others).
6695 dnl
6696 dnl The file contents are:
6697 dnl     libtool-version release-version patch-version
6698 dnl or
6699 dnl     release-version
6700 dnl where
6701 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
6702 dnl     release-version consists of a major version and minor version
6703 dnl             separated by '.', optionally followed by a patch-version
6704 dnl             separated by '-'.  The minor version need not be an
6705 dnl             integer (but it is preferred).
6706 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
6707 dnl             scripts can easily compare versions.
6708 dnl
6709 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
6710 dnl simply extracts the first field using 'cut -f1'.
6711 dnl
6712 dnl Optional parameters:
6713 dnl $1 = internal name for package
6714 dnl $2 = external name for package
6715 AC_DEFUN([CF_VERSION_INFO],
6716 [
6717 if test -f $srcdir/VERSION ; then
6718         AC_MSG_CHECKING(for package version)
6719
6720         # if there are not enough fields, cut returns the last one...
6721         cf_field1=`sed -e '2,$d' $srcdir/VERSION|cut -f1`
6722         cf_field2=`sed -e '2,$d' $srcdir/VERSION|cut -f2`
6723         cf_field3=`sed -e '2,$d' $srcdir/VERSION|cut -f3`
6724
6725         # this is how CF_BUNDLED_INTL uses $VERSION:
6726         VERSION="$cf_field1"
6727
6728         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
6729         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
6730
6731         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
6732         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
6733
6734         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
6735
6736         AC_MSG_CHECKING(for package patch date)
6737         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
6738         case .$VERSION_PATCH in
6739         (.)
6740                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
6741                 ;;
6742         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
6743                 ;;
6744         (*)
6745                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
6746                 ;;
6747         esac
6748         AC_MSG_RESULT($VERSION_PATCH)
6749 else
6750         AC_MSG_ERROR(did not find $srcdir/VERSION)
6751 fi
6752
6753 # show the actual data that we have for versions:
6754 CF_VERBOSE(ABI VERSION $VERSION)
6755 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
6756 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
6757 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
6758
6759 AC_SUBST(VERSION)
6760 AC_SUBST(VERSION_MAJOR)
6761 AC_SUBST(VERSION_MINOR)
6762 AC_SUBST(VERSION_PATCH)
6763
6764 dnl if a package name is given, define its corresponding version info.  We
6765 dnl need the package name to ensure that the defined symbols are unique.
6766 ifelse($1,,,[
6767         cf_PACKAGE=$1
6768         PACKAGE=ifelse($2,,$1,$2)
6769         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
6770         AC_SUBST(PACKAGE)
6771         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
6772         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
6773         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
6774 ])
6775 ])dnl
6776 dnl ---------------------------------------------------------------------------
6777 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
6778 dnl -------------
6779 dnl Check if type wide-character type $1 is declared, and if so, which header
6780 dnl file is needed.  The second parameter is used to set a shell variable when
6781 dnl the type is not found.  The first parameter sets a shell variable for the
6782 dnl opposite sense.
6783 AC_DEFUN([CF_WCHAR_TYPE],
6784 [
6785 # This is needed on Tru64 5.0 to declare $1
6786 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6787 AC_TRY_COMPILE([
6788 #include <stdlib.h>
6789 #include <stdarg.h>
6790 #include <stdio.h>
6791 #ifdef HAVE_LIBUTF8_H
6792 #include <libutf8.h>
6793 #endif],
6794         [$1 state],
6795         [cf_cv_$1=no],
6796         [AC_TRY_COMPILE([
6797 #include <stdlib.h>
6798 #include <stdarg.h>
6799 #include <stdio.h>
6800 #include <wchar.h>
6801 #ifdef HAVE_LIBUTF8_H
6802 #include <libutf8.h>
6803 #endif],
6804         [$1 value],
6805         [cf_cv_$1=yes],
6806         [cf_cv_$1=unknown])])])
6807
6808 if test "$cf_cv_$1" = yes ; then
6809         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
6810         NEED_WCHAR_H=1
6811 fi
6812
6813 ifelse([$2],,,[
6814 # if we do not find $1 in either place, use substitution to provide a fallback.
6815 if test "$cf_cv_$1" = unknown ; then
6816         $2=1
6817 fi
6818 ])
6819 ifelse($3,,,[
6820 # if we find $1 in either place, use substitution to provide a fallback.
6821 if test "$cf_cv_$1" != unknown ; then
6822         $3=1
6823 fi
6824 ])
6825 ])dnl
6826 dnl ---------------------------------------------------------------------------
6827 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
6828 dnl ---------------
6829 dnl Check for compiler-support for weak symbols.
6830 dnl This works with "recent" gcc.
6831 AC_DEFUN([CF_WEAK_SYMBOLS],[
6832 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
6833
6834 AC_TRY_COMPILE([
6835 #include <stdio.h>],
6836 [
6837 #if defined(__GNUC__)
6838 #  if defined __USE_ISOC99
6839 #    define _cat_pragma(exp)    _Pragma(#exp)
6840 #    define _weak_pragma(exp)   _cat_pragma(weak name)
6841 #  else
6842 #    define _weak_pragma(exp)
6843 #  endif
6844 #  define _declare(name)        __extension__ extern __typeof__(name) name
6845 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
6846 #endif
6847
6848 weak_symbol(fopen);
6849 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
6850 ])
6851 ])dnl
6852 dnl ---------------------------------------------------------------------------
6853 dnl CF_WITH_ABI_VERSION version: 3 updated: 2015/06/06 16:10:11
6854 dnl -------------------
6855 dnl Allow library's ABI to be overridden.  Generally this happens when a
6856 dnl packager has incremented the ABI past that used in the original package,
6857 dnl and wishes to keep doing this.
6858 dnl
6859 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6860 dnl symbol.
6861 AC_DEFUN([CF_WITH_ABI_VERSION],[
6862 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
6863 AC_ARG_WITH(abi-version,
6864 [  --with-abi-version=XXX  override derived ABI version],[
6865         if test "x$cf_cv_abi_version" != "x$withval"
6866         then
6867                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
6868                 case $cf_cv_rel_version in
6869                 (5.*)
6870                         cf_cv_rel_version=$withval.0
6871                         ;;
6872                 (6.*)
6873                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
6874                         ;;
6875                 esac
6876         fi
6877         cf_cv_abi_version=$withval])
6878         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
6879 ifelse($1,,,[
6880 $1_ABI=$cf_cv_abi_version
6881 ])
6882 ])dnl
6883 dnl ---------------------------------------------------------------------------
6884 dnl CF_NCURSES_WITH_ABI_VERSION version: 1 updated: 2015/06/06 13:49:58
6885 dnl ---------------------------
6886 dnl CF_WITH_ABI_VERSION version: 1 updated: 2003/09/20 18:12:49
6887 dnl -------------------
6888 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
6889 dnl packager has incremented the ABI past that used in the original package,
6890 dnl and wishes to keep doing this.
6891 dnl
6892 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6893 dnl symbol.
6894 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
6895 CF_WITH_ABI_VERSION($1)
6896 if test "x$cf_cv_abi_version" != "x$with_abi_version"
6897 then
6898         case $cf_cv_rel_version in
6899         (5.*)
6900                 cf_cv_rel_version=$with_abi_version.0
6901                 ;;
6902         esac
6903 fi
6904 ])dnl
6905 dnl ---------------------------------------------------------------------------
6906 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
6907 dnl --------------------
6908 dnl Command-line option to specify the Ada95 compiler.
6909 AC_DEFUN([CF_WITH_ADA_COMPILER],[
6910 AC_MSG_CHECKING(for ada-compiler)
6911 AC_ARG_WITH(ada-compiler,
6912         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
6913         [cf_ada_compiler=$withval],
6914         [cf_ada_compiler=gnatmake])
6915 AC_SUBST(cf_ada_compiler)
6916 AC_MSG_RESULT($cf_ada_compiler)
6917 ])dnl
6918 dnl ---------------------------------------------------------------------------
6919 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
6920 dnl -------------------
6921 dnl Command-line option to specify where Ada includes will install.
6922 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
6923 AC_MSG_CHECKING(for ada-include)
6924 CF_WITH_PATH(ada-include,
6925    [  --with-ada-include=DIR  Ada includes are in DIR],
6926    ADA_INCLUDE,
6927    PREFIX/share/ada/adainclude,
6928    [$]prefix/share/ada/adainclude)
6929 AC_SUBST(ADA_INCLUDE)
6930 AC_MSG_RESULT($ADA_INCLUDE)
6931 ])dnl
6932 dnl ---------------------------------------------------------------------------
6933 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
6934 dnl -------------------
6935 dnl Command-line option to specify where Ada objects will install.
6936 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
6937 AC_MSG_CHECKING(for ada-objects)
6938 CF_WITH_PATH(ada-objects,
6939    [  --with-ada-objects=DIR  Ada objects are in DIR],
6940    ADA_OBJECTS,
6941    PREFIX/lib/ada/adalib,
6942    [$]prefix/lib/ada/adalib)
6943 AC_SUBST(ADA_OBJECTS)
6944 AC_MSG_RESULT($ADA_OBJECTS)
6945 ])dnl
6946 dnl ---------------------------------------------------------------------------
6947 dnl CF_WITH_ADA_SHAREDLIB version: 4 updated: 2014/05/31 21:08:37
6948 dnl ---------------------
6949 dnl Command-line option to specify if an Ada95 shared-library should be built,
6950 dnl and optionally what its soname should be.
6951 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
6952 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
6953 AC_ARG_WITH(ada-sharedlib,
6954         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
6955         [with_ada_sharedlib=$withval],
6956         [with_ada_sharedlib=no])
6957 AC_MSG_RESULT($with_ada_sharedlib)
6958
6959 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
6960 MAKE_ADA_SHAREDLIB="#"
6961
6962 if test "x$with_ada_sharedlib" != xno
6963 then
6964         MAKE_ADA_SHAREDLIB=
6965         if test "x$with_ada_sharedlib" != xyes
6966         then
6967                 ADA_SHAREDLIB="$with_ada_sharedlib"
6968         fi
6969 fi
6970
6971 AC_SUBST(ADA_SHAREDLIB)
6972 AC_SUBST(MAKE_ADA_SHAREDLIB)
6973 ])dnl
6974 dnl ---------------------------------------------------------------------------
6975 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
6976 dnl ----------------
6977 dnl Configure-option for dbmalloc.  The optional parameter is used to override
6978 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6979 AC_DEFUN([CF_WITH_DBMALLOC],[
6980 CF_NO_LEAKS_OPTION(dbmalloc,
6981         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
6982         [USE_DBMALLOC])
6983
6984 if test "$with_dbmalloc" = yes ; then
6985         AC_CHECK_HEADER(dbmalloc.h,
6986                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
6987 fi
6988 ])dnl
6989 dnl ---------------------------------------------------------------------------
6990 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
6991 dnl ---------------
6992 dnl Configure-option for dmalloc.  The optional parameter is used to override
6993 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6994 AC_DEFUN([CF_WITH_DMALLOC],[
6995 CF_NO_LEAKS_OPTION(dmalloc,
6996         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
6997         [USE_DMALLOC])
6998
6999 if test "$with_dmalloc" = yes ; then
7000         AC_CHECK_HEADER(dmalloc.h,
7001                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
7002 fi
7003 ])dnl
7004 dnl ---------------------------------------------------------------------------
7005 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
7006 dnl -------------------
7007 dnl Use this with libtool to specify the list of symbols that may be exported.
7008 dnl The input file contains one symbol per line; comments work with "#".
7009 dnl
7010 dnl $1 = basename of the ".sym" file (default $PACKAGE)
7011 AC_DEFUN([CF_WITH_EXPORT_SYMS],
7012 [
7013 AC_MSG_CHECKING(if exported-symbols file should be used)
7014 AC_ARG_WITH(export-syms,
7015         [  --with-export-syms=XXX  limit exported symbols using libtool],
7016         [with_export_syms=$withval],
7017         [with_export_syms=no])
7018 if test "x$with_export_syms" = xyes
7019 then
7020         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
7021         AC_SUBST(PACKAGE)
7022 fi
7023 AC_MSG_RESULT($with_export_syms)
7024 if test "x$with_export_syms" != xno
7025 then
7026         EXPORT_SYMS="-export-symbols $with_export_syms"
7027         AC_SUBST(EXPORT_SYMS)
7028 fi
7029 ])dnl
7030 dnl ---------------------------------------------------------------------------
7031 dnl CF_WITH_GPM version: 8 updated: 2012/10/06 17:56:13
7032 dnl -----------
7033 dnl
7034 dnl The option parameter (if neither yes/no) is assumed to be the name of
7035 dnl the gpm library, e.g., for dynamic loading.
7036 AC_DEFUN([CF_WITH_GPM],
7037 [
7038 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
7039 AC_ARG_WITH(gpm,
7040         [  --with-gpm              use Alessandro Rubini's GPM library],
7041         [with_gpm=$withval],
7042         [with_gpm=maybe])
7043 AC_MSG_RESULT($with_gpm)
7044
7045 if test "$with_gpm" != no ; then
7046         AC_CHECK_HEADER(gpm.h,[
7047                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
7048                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
7049                         CF_VERBOSE(assuming we really have GPM library)
7050                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
7051                 else
7052                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
7053                                 AC_MSG_ERROR(Cannot link with GPM library)
7054                 fi
7055                 with_gpm=yes
7056                 ])
7057         ],[
7058                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
7059                 with_gpm=no
7060         ])
7061 fi
7062 ])
7063 dnl ---------------------------------------------------------------------------
7064 dnl CF_WITH_LIBTOOL version: 33 updated: 2015/10/17 19:03:33
7065 dnl ---------------
7066 dnl Provide a configure option to incorporate libtool.  Define several useful
7067 dnl symbols for the makefile rules.
7068 dnl
7069 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
7070 dnl macros from libtool.m4 which is in the aclocal directory of automake.
7071 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
7072 dnl But that still does not work properly since the macro is expanded outside
7073 dnl the CF_WITH_LIBTOOL macro:
7074 dnl
7075 dnl     #!/bin/sh
7076 dnl     ACLOCAL=`aclocal --print-ac-dir`
7077 dnl     if test -z "$ACLOCAL" ; then
7078 dnl             echo cannot find aclocal directory
7079 dnl             exit 1
7080 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
7081 dnl             echo cannot find libtool.m4 file
7082 dnl             exit 1
7083 dnl     fi
7084 dnl
7085 dnl     LOCAL=aclocal.m4
7086 dnl     ORIG=aclocal.m4.orig
7087 dnl
7088 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
7089 dnl     rm -f $ORIG
7090 dnl     mv $LOCAL $ORIG
7091 dnl
7092 dnl     # sed the LIBTOOL= assignment to omit the current directory?
7093 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
7094 dnl     cat $ORIG >>$LOCAL
7095 dnl
7096 dnl     autoconf-257 $*
7097 dnl
7098 AC_DEFUN([CF_WITH_LIBTOOL],
7099 [
7100 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
7101 ifdef([AC_PROG_LIBTOOL],,[
7102 LIBTOOL=
7103 ])
7104 # common library maintenance symbols that are convenient for libtool scripts:
7105 LIB_CREATE='${AR} -cr'
7106 LIB_OBJECT='${OBJECTS}'
7107 LIB_SUFFIX=.a
7108 LIB_PREP="$RANLIB"
7109
7110 # symbols used to prop libtool up to enable it to determine what it should be
7111 # doing:
7112 LIB_CLEAN=
7113 LIB_COMPILE=
7114 LIB_LINK='${CC}'
7115 LIB_INSTALL=
7116 LIB_UNINSTALL=
7117
7118 AC_MSG_CHECKING(if you want to build libraries with libtool)
7119 AC_ARG_WITH(libtool,
7120         [  --with-libtool          generate libraries with libtool],
7121         [with_libtool=$withval],
7122         [with_libtool=no])
7123 AC_MSG_RESULT($with_libtool)
7124 if test "$with_libtool" != "no"; then
7125 ifdef([AC_PROG_LIBTOOL],[
7126         # missing_content_AC_PROG_LIBTOOL{{
7127         AC_PROG_LIBTOOL
7128         # missing_content_AC_PROG_LIBTOOL}}
7129 ],[
7130         if test "$with_libtool" != "yes" ; then
7131                 CF_PATH_SYNTAX(with_libtool)
7132                 LIBTOOL=$with_libtool
7133         else
7134                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
7135                 CF_LIBTOOL_VERSION
7136                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
7137                 then
7138                         CF_FORGET_TOOL(LIBTOOL)
7139                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
7140                         CF_LIBTOOL_VERSION
7141                 fi
7142         fi
7143         if test -z "$LIBTOOL" ; then
7144                 AC_MSG_ERROR(Cannot find libtool)
7145         fi
7146 ])dnl
7147         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${DESTDIR}${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
7148         LIB_OBJECT='${OBJECTS:.o=.lo}'
7149         LIB_SUFFIX=.la
7150         LIB_CLEAN='${LIBTOOL} --mode=clean'
7151         LIB_COMPILE='${LIBTOOL} --mode=compile'
7152         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
7153         LIB_INSTALL='${LIBTOOL} --mode=install'
7154         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
7155         LIB_PREP=:
7156
7157         CF_CHECK_LIBTOOL_VERSION
7158
7159         # special hack to add -no-undefined (which libtool should do for itself)
7160         LT_UNDEF=
7161         case "$cf_cv_system_name" in
7162         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
7163                 LT_UNDEF=-no-undefined
7164                 ;;
7165         esac
7166         AC_SUBST([LT_UNDEF])
7167
7168         # special hack to add --tag option for C++ compiler
7169         case $cf_cv_libtool_version in
7170         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
7171                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
7172                 LIBTOOL="$LIBTOOL --tag=CC"
7173                 ;;
7174         (*)
7175                 LIBTOOL_CXX="$LIBTOOL"
7176                 ;;
7177         esac
7178 else
7179         LIBTOOL=""
7180         LIBTOOL_CXX=""
7181 fi
7182
7183 test -z "$LIBTOOL" && ECHO_LT=
7184
7185 AC_SUBST(LIBTOOL)
7186 AC_SUBST(LIBTOOL_CXX)
7187 AC_SUBST(LIBTOOL_OPTS)
7188
7189 AC_SUBST(LIB_CREATE)
7190 AC_SUBST(LIB_OBJECT)
7191 AC_SUBST(LIB_SUFFIX)
7192 AC_SUBST(LIB_PREP)
7193
7194 AC_SUBST(LIB_CLEAN)
7195 AC_SUBST(LIB_COMPILE)
7196 AC_SUBST(LIB_LINK)
7197 AC_SUBST(LIB_INSTALL)
7198 AC_SUBST(LIB_UNINSTALL)
7199
7200 ])dnl
7201 dnl ---------------------------------------------------------------------------
7202 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
7203 dnl --------------------
7204 dnl Allow user to pass additional libtool options into the library creation
7205 dnl and link steps.  The main use for this is to do something like
7206 dnl     ./configure --with-libtool-opts=-static
7207 dnl to get the same behavior as automake-flavored
7208 dnl     ./configure --enable-static
7209 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
7210 AC_MSG_CHECKING(for additional libtool options)
7211 AC_ARG_WITH(libtool-opts,
7212         [  --with-libtool-opts=XXX specify additional libtool options],
7213         [with_libtool_opts=$withval],
7214         [with_libtool_opts=no])
7215 AC_MSG_RESULT($with_libtool_opts)
7216
7217 case .$with_libtool_opts in
7218 (.yes|.no|.)
7219         ;;
7220 (*)
7221         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
7222         ;;
7223 esac
7224
7225 AC_SUBST(LIBTOOL_OPTS)
7226 ])dnl
7227 dnl ---------------------------------------------------------------------------
7228 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
7229 dnl ------------------
7230 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
7231 dnl "lib" prefix, e.g., because it used the dll naming convention.
7232 dnl
7233 dnl $1 = variable to set
7234 AC_DEFUN([CF_WITH_LIB_PREFIX],
7235 [
7236 AC_MSG_CHECKING(if you want to have a library-prefix)
7237 AC_ARG_WITH(lib-prefix,
7238         [  --with-lib-prefix       override library-prefix],
7239         [with_lib_prefix=$withval],
7240         [with_lib_prefix=auto])
7241 AC_MSG_RESULT($with_lib_prefix)
7242
7243 if test $with_lib_prefix = auto
7244 then
7245         CF_LIB_PREFIX($1)
7246 elif test $with_lib_prefix = no
7247 then
7248         LIB_PREFIX=
7249 else
7250         LIB_PREFIX=$with_lib_prefix
7251 fi
7252 ])dnl
7253 dnl ---------------------------------------------------------------------------
7254 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
7255 dnl ------------
7256 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
7257 dnl defaulting to yes/no.
7258 dnl
7259 dnl $1 = option name
7260 dnl $2 = help-text
7261 dnl $3 = environment variable to set
7262 dnl $4 = default value, shown in the help-message, must be a constant
7263 dnl $5 = default value, if it's an expression & cannot be in the help-message
7264 dnl
7265 AC_DEFUN([CF_WITH_PATH],
7266 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
7267 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
7268 if ifelse([$5],,true,[test -n "$5"]) ; then
7269 CF_PATH_SYNTAX(withval)
7270 fi
7271 eval $3="$withval"
7272 AC_SUBST($3)dnl
7273 ])dnl
7274 dnl ---------------------------------------------------------------------------
7275 dnl CF_WITH_PATHLIST version: 10 updated: 2015/04/17 21:13:04
7276 dnl ----------------
7277 dnl Process an option specifying a list of colon-separated paths.
7278 dnl
7279 dnl $1 = option name
7280 dnl $2 = help-text
7281 dnl $3 = environment variable to set
7282 dnl $4 = default value, shown in the help-message, must be a constant
7283 dnl $5 = default value, if it's an expression & cannot be in the help-message
7284 dnl $6 = flag to tell if we want to define or substitute
7285 dnl
7286 AC_DEFUN([CF_WITH_PATHLIST],[
7287 AC_REQUIRE([CF_PATHSEP])
7288 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
7289 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
7290
7291 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
7292 cf_dst_path=
7293 for cf_src_path in $withval
7294 do
7295   CF_PATH_SYNTAX(cf_src_path)
7296   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
7297   cf_dst_path="${cf_dst_path}${cf_src_path}"
7298 done
7299 IFS="$ac_save_ifs"
7300
7301 ifelse($6,define,[
7302 # Strip single quotes from the value, e.g., when it was supplied as a literal
7303 # for $4 or $5.
7304 case $cf_dst_path in
7305 (\'*)
7306   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
7307   ;;
7308 esac
7309 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
7310 ])
7311
7312 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
7313 # so we have to check/work around.  We do prefer the result of "eval"...
7314 eval cf_dst_eval="$cf_dst_path"
7315 case "x$cf_dst_eval" in
7316 (xNONE*)
7317         $3=$cf_dst_path
7318         ;;
7319 (*)
7320         $3="$cf_dst_eval"
7321         ;;
7322 esac
7323 AC_SUBST($3)dnl
7324
7325 ])dnl
7326 dnl ---------------------------------------------------------------------------
7327 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
7328 dnl -------------------------
7329 dnl Allow the choice of the pkg-config library directory to be overridden.
7330 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
7331
7332 case $PKG_CONFIG in
7333 (no|none|yes)
7334         AC_MSG_CHECKING(for pkg-config library directory)
7335         ;;
7336 (*)
7337         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
7338         ;;
7339 esac
7340
7341 PKG_CONFIG_LIBDIR=no
7342 AC_ARG_WITH(pkg-config-libdir,
7343         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
7344         [PKG_CONFIG_LIBDIR=$withval],
7345         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
7346
7347 case x$PKG_CONFIG_LIBDIR in
7348 (x/*)
7349         ;;
7350 (xyes)
7351         # Look for the library directory using the same prefix as the executable
7352         if test "x$PKG_CONFIG" = xnone
7353         then
7354                 cf_path=$prefix
7355         else
7356                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
7357         fi
7358
7359         # If you don't like using the default architecture, you have to specify the
7360         # intended library directory and corresponding compiler/linker options.
7361         #
7362         # This case allows for Debian's 2014-flavor of multiarch, along with the
7363         # most common variations before that point.  Some other variants spell the
7364         # directory differently, e.g., "pkg-config", and put it in unusual places.
7365         # pkg-config has always been poorly standardized, which is ironic...
7366         case x`(arch) 2>/dev/null` in
7367         (*64)
7368                 cf_search_path="\
7369                         $cf_path/lib/*64-linux-gnu \
7370                         $cf_path/share \
7371                         $cf_path/lib64 \
7372                         $cf_path/lib32 \
7373                         $cf_path/lib"
7374                 ;;
7375         (*)
7376                 cf_search_path="\
7377                         $cf_path/lib/*-linux-gnu \
7378                         $cf_path/share \
7379                         $cf_path/lib32 \
7380                         $cf_path/lib \
7381                         $cf_path/libdata"
7382                 ;;
7383         esac
7384
7385         CF_VERBOSE(list...)
7386         for cf_config in $cf_search_path
7387         do
7388                 CF_VERBOSE(checking $cf_config/pkgconfig)
7389                 if test -d $cf_config/pkgconfig
7390                 then
7391                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
7392                         AC_MSG_CHECKING(done)
7393                         break
7394                 fi
7395         done
7396         ;;
7397 (*)
7398         ;;
7399 esac
7400
7401 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
7402         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
7403 fi
7404
7405 AC_SUBST(PKG_CONFIG_LIBDIR)
7406 ])dnl
7407 dnl ---------------------------------------------------------------------------
7408 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
7409 dnl ---------------
7410 dnl Check for POSIX thread library.
7411 AC_DEFUN([CF_WITH_PTHREAD],
7412 [
7413 AC_MSG_CHECKING(if you want to link with the pthread library)
7414 AC_ARG_WITH(pthread,
7415         [  --with-pthread          use POSIX thread library],
7416         [with_pthread=$withval],
7417         [with_pthread=no])
7418 AC_MSG_RESULT($with_pthread)
7419
7420 if test "$with_pthread" != no ; then
7421         AC_CHECK_HEADER(pthread.h,[
7422         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
7423
7424         for cf_lib_pthread in pthread c_r
7425         do
7426             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
7427             cf_save_LIBS="$LIBS"
7428             CF_ADD_LIB($cf_lib_pthread)
7429             AC_TRY_LINK([
7430 #include <pthread.h>
7431 ],[
7432                 int rc = pthread_create(0,0,0,0);
7433                 int r2 = pthread_mutexattr_settype(0, 0);
7434 ],[with_pthread=yes],[with_pthread=no])
7435             LIBS="$cf_save_LIBS"
7436             AC_MSG_RESULT($with_pthread)
7437             test "$with_pthread" = yes && break
7438         done
7439
7440         if test "$with_pthread" = yes ; then
7441             CF_ADD_LIB($cf_lib_pthread)
7442             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
7443         else
7444             AC_MSG_ERROR(Cannot link with pthread library)
7445         fi
7446         ])
7447 fi
7448 ])
7449 dnl ---------------------------------------------------------------------------
7450 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
7451 dnl -------------------
7452 dnl Allow library's release-version to be overridden.  Generally this happens when a
7453 dnl packager has incremented the release-version past that used in the original package,
7454 dnl and wishes to keep doing this.
7455 dnl
7456 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
7457 dnl and {package}_MINOR symbols
7458 dnl symbol.
7459 AC_DEFUN([CF_WITH_REL_VERSION],[
7460 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
7461 AC_ARG_WITH(rel-version,
7462 [  --with-rel-version=XXX  override derived release version],
7463 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
7464  cf_cv_rel_version=$withval])
7465 ifelse($1,,[
7466  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
7467 ],[
7468  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
7469  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
7470  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
7471  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
7472 ])
7473 ])dnl
7474 dnl ---------------------------------------------------------------------------
7475 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
7476 dnl ----------------
7477 dnl If we can compile with sysmouse, make it available unless it is not wanted.
7478 AC_DEFUN([CF_WITH_SYSMOUSE],[
7479 # not everyone has "test -c"
7480 if test -c /dev/sysmouse 2>/dev/null ; then
7481 AC_MSG_CHECKING(if you want to use sysmouse)
7482 AC_ARG_WITH(sysmouse,
7483         [  --with-sysmouse         use sysmouse (FreeBSD console)],
7484         [cf_with_sysmouse=$withval],
7485         [cf_with_sysmouse=maybe])
7486         if test "$cf_with_sysmouse" != no ; then
7487         AC_TRY_COMPILE([
7488 #include <osreldate.h>
7489 #if (__FreeBSD_version >= 400017)
7490 #include <sys/consio.h>
7491 #include <sys/fbio.h>
7492 #else
7493 #include <machine/console.h>
7494 #endif
7495 ],[
7496         struct mouse_info the_mouse;
7497         ioctl(0, CONS_MOUSECTL, &the_mouse);
7498 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
7499         fi
7500 AC_MSG_RESULT($cf_with_sysmouse)
7501 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
7502 fi
7503 ])dnl
7504 dnl ---------------------------------------------------------------------------
7505 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
7506 dnl ---------------
7507 dnl For testing, override the derived host system-type which is used to decide
7508 dnl things such as the linker commands used to build shared libraries.  This is
7509 dnl normally chosen automatically based on the type of system which you are
7510 dnl building on.  We use it for testing the configure script.
7511 dnl
7512 dnl This is different from the --host option: it is used only for testing parts
7513 dnl of the configure script which would not be reachable with --host since that
7514 dnl relies on the build environment being real, rather than mocked up.
7515 AC_DEFUN([CF_WITH_SYSTYPE],[
7516 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
7517 AC_ARG_WITH(system-type,
7518         [  --with-system-type=XXX  test: override derived host system-type],
7519 [AC_MSG_WARN(overriding system type to $withval)
7520         cf_cv_system_name=$withval
7521         host_os=$withval
7522 ])
7523 ])dnl
7524 dnl ---------------------------------------------------------------------------
7525 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
7526 dnl ----------------
7527 AC_DEFUN([CF_WITH_VALGRIND],[
7528 CF_NO_LEAKS_OPTION(valgrind,
7529         [  --with-valgrind         test: use valgrind],
7530         [USE_VALGRIND])
7531 ])dnl
7532 dnl ---------------------------------------------------------------------------
7533 dnl CF_WITH_VERSIONED_SYMS version: 7 updated: 2015/10/24 20:50:26
7534 dnl ----------------------
7535 dnl Use this when building shared library with ELF, to markup symbols with the
7536 dnl version identifier from the given input file.  Generally that identifier is
7537 dnl the same as the SONAME at which the symbol was first introduced.
7538 dnl
7539 dnl $1 = basename of the ".map" file (default $PACKAGE)
7540 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
7541 [
7542 AC_MSG_CHECKING(if versioned-symbols file should be used)
7543 AC_ARG_WITH(versioned-syms,
7544         [  --with-versioned-syms=X markup versioned symbols using ld],
7545         [with_versioned_syms=$withval],
7546         [with_versioned_syms=no])
7547 if test "x$with_versioned_syms" = xyes
7548 then
7549         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
7550         AC_SUBST(PACKAGE)
7551 fi
7552 AC_MSG_RESULT($with_versioned_syms)
7553
7554 RESULTING_SYMS=
7555 VERSIONED_SYMS=
7556 WILDCARD_SYMS=
7557
7558 if test "x$with_versioned_syms" != xno
7559 then
7560         RESULTING_SYMS=$with_versioned_syms
7561         case "x$MK_SHARED_LIB" in
7562         (*-Wl,*)
7563                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
7564                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
7565                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7566                 ;;
7567         (*-dy\ *)
7568                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
7569                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
7570                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7571                 ;;
7572         (*)
7573                 AC_MSG_WARN(this system does not support versioned-symbols)
7574                 ;;
7575         esac
7576
7577         # Linux ld can selectively override scope, e.g., of symbols beginning with
7578         # "_" by first declaring some as global, and then using a wildcard to
7579         # declare the others as local.  Some other loaders cannot do this.  Check
7580         # by constructing a (very) simple shared library and inspecting its
7581         # symbols.
7582         if test "x$VERSIONED_SYMS" != "x"
7583         then
7584                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
7585                 WILDCARD_SYMS=no
7586
7587                 # make sources
7588                 rm -f conftest.*
7589
7590                 cat >conftest.ver <<EOF
7591 module_1.0 {
7592 global:
7593         globalf1;
7594 local:
7595         localf1;
7596 };
7597 module_2.0 {
7598 global:
7599         globalf2;
7600 local:
7601         localf2;
7602         _*;
7603 } module_1.0;
7604 submodule_1.0 {
7605 global:
7606         subglobalf1;
7607         _ismissing;
7608 local:
7609         sublocalf1;
7610 };
7611 submodule_2.0 {
7612 global:
7613         subglobalf2;
7614 local:
7615         sublocalf2;
7616         _*;
7617 } submodule_1.0;
7618 EOF
7619                 cat >conftest.$ac_ext <<EOF
7620 #line __oline__ "configure"
7621 int     _ismissing(void) { return 1; }
7622 int     _localf1(void) { return 1; }
7623 int     _localf2(void) { return 2; }
7624 int     globalf1(void) { return 1; }
7625 int     globalf2(void) { return 2; }
7626 int     _sublocalf1(void) { return 1; }
7627 int     _sublocalf2(void) { return 2; }
7628 int     subglobalf1(void) { return 1; }
7629 int     subglobalf2(void) { return 2; }
7630 EOF
7631                 cat >conftest.mk <<EOF
7632 CC=${CC}
7633 CFLAGS=${CFLAGS}
7634 CPPFLAGS=${CPPFLAGS}
7635 LDFLAGS=${LDFLAGS}
7636 LIBS=${LIBS}
7637 VERSIONED_SYMS=${VERSIONED_SYMS}
7638 RESULTING_SYMS=conftest.ver
7639 MK_SHARED_LIB=${MK_SHARED_LIB}
7640 conftest.so: conftest.$ac_cv_objext
7641                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
7642 EOF
7643
7644                 # compile source, make library
7645                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
7646                 then
7647                         # test for missing symbol in either Data or Text section
7648                         cf_missing=`nm -P conftest.so 2>&AC_FD_CC |fgrep _ismissing | egrep '[[         ]][[DT]][[      ]]'`
7649                         test -n "$cf_missing" && WILDCARD_SYMS=yes
7650                 fi
7651                 AC_MSG_RESULT($WILDCARD_SYMS)
7652                 rm -f conftest.*
7653         fi
7654 fi
7655 AC_SUBST(RESULTING_SYMS)
7656 AC_SUBST(VERSIONED_SYMS)
7657 AC_SUBST(WILDCARD_SYMS)
7658 ])dnl
7659 dnl ---------------------------------------------------------------------------
7660 dnl CF_XOPEN_SOURCE version: 50 updated: 2015/10/17 19:03:33
7661 dnl ---------------
7662 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
7663 dnl or adapt to the vendor's definitions to get equivalent functionality,
7664 dnl without losing the common non-POSIX features.
7665 dnl
7666 dnl Parameters:
7667 dnl     $1 is the nominal value for _XOPEN_SOURCE
7668 dnl     $2 is the nominal value for _POSIX_C_SOURCE
7669 AC_DEFUN([CF_XOPEN_SOURCE],[
7670 AC_REQUIRE([AC_CANONICAL_HOST])
7671
7672 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
7673 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
7674 cf_xopen_source=
7675
7676 case $host_os in
7677 (aix[[4-7]]*)
7678         cf_xopen_source="-D_ALL_SOURCE"
7679         ;;
7680 (cygwin|msys)
7681         cf_XOPEN_SOURCE=600
7682         ;;
7683 (darwin[[0-8]].*)
7684         cf_xopen_source="-D_APPLE_C_SOURCE"
7685         ;;
7686 (darwin*)
7687         cf_xopen_source="-D_DARWIN_C_SOURCE"
7688         cf_XOPEN_SOURCE=
7689         ;;
7690 (freebsd*|dragonfly*)
7691         # 5.x headers associate
7692         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
7693         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
7694         cf_POSIX_C_SOURCE=200112L
7695         cf_XOPEN_SOURCE=600
7696         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
7697         ;;
7698 (hpux11*)
7699         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
7700         ;;
7701 (hpux*)
7702         cf_xopen_source="-D_HPUX_SOURCE"
7703         ;;
7704 (irix[[56]].*)
7705         cf_xopen_source="-D_SGI_SOURCE"
7706         cf_XOPEN_SOURCE=
7707         ;;
7708 (linux*|gnu*|mint*|k*bsd*-gnu)
7709         CF_GNU_SOURCE
7710         ;;
7711 (minix*)
7712         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
7713         ;;
7714 (mirbsd*)
7715         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
7716         cf_XOPEN_SOURCE=
7717         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7718         ;;
7719 (netbsd*)
7720         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
7721         ;;
7722 (openbsd[[4-9]]*)
7723         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
7724         cf_xopen_source="-D_BSD_SOURCE"
7725         cf_XOPEN_SOURCE=600
7726         ;;
7727 (openbsd*)
7728         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
7729         ;;
7730 (os2*)
7731         cf_XOPEN_SOURCE=
7732         ;;
7733 (osf[[45]]*)
7734         cf_xopen_source="-D_OSF_SOURCE"
7735         ;;
7736 (nto-qnx*)
7737         cf_xopen_source="-D_QNX_SOURCE"
7738         ;;
7739 (sco*)
7740         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
7741         ;;
7742 (solaris2.*)
7743         cf_xopen_source="-D__EXTENSIONS__"
7744         cf_cv_xopen_source=broken
7745         ;;
7746 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
7747         cf_XOPEN_SOURCE=
7748         cf_POSIX_C_SOURCE=
7749         ;;
7750 (*)
7751         CF_TRY_XOPEN_SOURCE
7752         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7753         ;;
7754 esac
7755
7756 if test -n "$cf_xopen_source" ; then
7757         CF_ADD_CFLAGS($cf_xopen_source,true)
7758 fi
7759
7760 dnl In anything but the default case, we may have system-specific setting
7761 dnl which is still not guaranteed to provide all of the entrypoints that
7762 dnl _XOPEN_SOURCE would yield.
7763 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
7764         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
7765         AC_TRY_COMPILE([#include <stdlib.h>],[
7766 #ifndef _XOPEN_SOURCE
7767 make an error
7768 #endif],
7769         [cf_XOPEN_SOURCE_set=yes],
7770         [cf_XOPEN_SOURCE_set=no])
7771         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
7772         if test $cf_XOPEN_SOURCE_set = yes
7773         then
7774                 AC_TRY_COMPILE([#include <stdlib.h>],[
7775 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
7776 make an error
7777 #endif],
7778                 [cf_XOPEN_SOURCE_set_ok=yes],
7779                 [cf_XOPEN_SOURCE_set_ok=no])
7780                 if test $cf_XOPEN_SOURCE_set_ok = no
7781                 then
7782                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
7783                 fi
7784         else
7785                 CF_TRY_XOPEN_SOURCE
7786         fi
7787 fi
7788 ])