aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2010,2011 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.594 2011/12/11 00:03:00 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54     [AC_TRY_LINK([#include <langinfo.h>],
  55       [char* cs = nl_langinfo(CODESET);],
  56       am_cv_langinfo_codeset=yes,
  57       am_cv_langinfo_codeset=no)
  58     ])
  59   if test $am_cv_langinfo_codeset = yes; then
  60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62   fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ACVERSION_CHECK version: 2 updated: 2011/05/08 11:22:03
  66 dnl ------------------
  67 dnl Conditionally generate script according to whether we're using a given autoconf.
  68 dnl
  69 dnl $1 = version to compare against
  70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  71 dnl $3 = code to use if AC_ACVERSION is older than $1.
  72 define(CF_ACVERSION_CHECK,
  73 [
  74 ifdef([m4_version_compare],
  75 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  76 [CF_ACVERSION_COMPARE(
  77 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  78 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  79 dnl ---------------------------------------------------------------------------
  80 dnl CF_ACVERSION_COMPARE version: 2 updated: 2011/04/14 20:56:50
  81 dnl --------------------
  82 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  83 dnl                      MAJOR2, MINOR2, TERNARY2,
  84 dnl                      PRINTABLE2, not FOUND, FOUND)
  85 define(CF_ACVERSION_COMPARE,
  86 [ifelse(builtin([eval], [$2 < $5]), 1,
  87 [ifelse([$8], , ,[$8])],
  88 [ifelse([$9], , ,[$9])])])dnl
  89 dnl ---------------------------------------------------------------------------
  90 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
  91 dnl -------------------
  92 dnl Construct the list of include-options for the C programs in the Ada95
  93 dnl binding.
  94 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  95 [
  96 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  97 if test "$srcdir" != "."; then
  98         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  99 fi
 100 if test "$GCC" != yes; then
 101         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 102 elif test "$includedir" != "/usr/include"; then
 103         if test "$includedir" = '${prefix}/include' ; then
 104                 if test $prefix != /usr ; then
 105                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 106                 fi
 107         else
 108                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 109         fi
 110 fi
 111 AC_SUBST(ACPPFLAGS)
 112 ])dnl
 113 dnl ---------------------------------------------------------------------------
 114 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 115 dnl ---------------
 116 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 117 AC_DEFUN([CF_ADD_ADAFLAGS],[
 118         ADAFLAGS="$ADAFLAGS $1"
 119         AC_SUBST(ADAFLAGS)
 120 ])dnl
 121 dnl ---------------------------------------------------------------------------
 122 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
 123 dnl -------------
 124 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 125 dnl The second parameter if given makes this macro verbose.
 126 dnl
 127 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 128 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 129 dnl confused by the quotes (which require backslashes to keep them usable).
 130 AC_DEFUN([CF_ADD_CFLAGS],
 131 [
 132 cf_fix_cppflags=no
 133 cf_new_cflags=
 134 cf_new_cppflags=
 135 cf_new_extra_cppflags=
 136
 137 for cf_add_cflags in $1
 138 do
 139 case $cf_fix_cppflags in
 140 no)
 141         case $cf_add_cflags in #(vi
 142         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 143                 case $cf_add_cflags in
 144                 -D*)
 145                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 146
 147                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 148                                 && test -z "${cf_tst_cflags}" \
 149                                 && cf_fix_cppflags=yes
 150
 151                         if test $cf_fix_cppflags = yes ; then
 152                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 153                                 continue
 154                         elif test "${cf_tst_cflags}" = "\"'" ; then
 155                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 156                                 continue
 157                         fi
 158                         ;;
 159                 esac
 160                 case "$CPPFLAGS" in
 161                 *$cf_add_cflags) #(vi
 162                         ;;
 163                 *) #(vi
 164                         case $cf_add_cflags in #(vi
 165                         -D*)
 166                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 167                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 168                                 ;;
 169                         esac
 170                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 171                         ;;
 172                 esac
 173                 ;;
 174         *)
 175                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 176                 ;;
 177         esac
 178         ;;
 179 yes)
 180         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 181
 182         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 183
 184         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 185                 && test -z "${cf_tst_cflags}" \
 186                 && cf_fix_cppflags=no
 187         ;;
 188 esac
 189 done
 190
 191 if test -n "$cf_new_cflags" ; then
 192         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 193         CFLAGS="$CFLAGS $cf_new_cflags"
 194 fi
 195
 196 if test -n "$cf_new_cppflags" ; then
 197         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 198         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 199 fi
 200
 201 if test -n "$cf_new_extra_cppflags" ; then
 202         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 203         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 204 fi
 205
 206 AC_SUBST(EXTRA_CPPFLAGS)
 207
 208 ])dnl
 209 dnl ---------------------------------------------------------------------------
 210 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 211 dnl -------------
 212 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 213 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 214 dnl but old versions (and some misinstalled ones) need that.  To make things
 215 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 216 dnl the include-path).
 217 AC_DEFUN([CF_ADD_INCDIR],
 218 [
 219 if test -n "$1" ; then
 220   for cf_add_incdir in $1
 221   do
 222         while test $cf_add_incdir != /usr/include
 223         do
 224           if test -d $cf_add_incdir
 225           then
 226                 cf_have_incdir=no
 227                 if test -n "$CFLAGS$CPPFLAGS" ; then
 228                   # a loop is needed to ensure we can add subdirs of existing dirs
 229                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 230                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 231                           cf_have_incdir=yes; break
 232                         fi
 233                   done
 234                 fi
 235
 236                 if test "$cf_have_incdir" = no ; then
 237                   if test "$cf_add_incdir" = /usr/local/include ; then
 238                         if test "$GCC" = yes
 239                         then
 240                           cf_save_CPPFLAGS=$CPPFLAGS
 241                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 242                           AC_TRY_COMPILE([#include <stdio.h>],
 243                                   [printf("Hello")],
 244                                   [],
 245                                   [cf_have_incdir=yes])
 246                           CPPFLAGS=$cf_save_CPPFLAGS
 247                         fi
 248                   fi
 249                 fi
 250
 251                 if test "$cf_have_incdir" = no ; then
 252                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 253                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 254
 255                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 256                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 257                   cf_add_incdir="$cf_top_incdir"
 258                 else
 259                   break
 260                 fi
 261           fi
 262         done
 263   done
 264 fi
 265 ])dnl
 266 dnl ---------------------------------------------------------------------------
 267 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 268 dnl ----------
 269 dnl Add a library, used to enforce consistency.
 270 dnl
 271 dnl $1 = library to add, without the "-l"
 272 dnl $2 = variable to update (default $LIBS)
 273 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 274 dnl ---------------------------------------------------------------------------
 275 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 276 dnl -------------
 277 dnl     Adds to the library-path
 278 dnl
 279 dnl     Some machines have trouble with multiple -L options.
 280 dnl
 281 dnl $1 is the (list of) directory(s) to add
 282 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 283 dnl
 284 AC_DEFUN([CF_ADD_LIBDIR],
 285 [
 286 if test -n "$1" ; then
 287   for cf_add_libdir in $1
 288   do
 289     if test $cf_add_libdir = /usr/lib ; then
 290       :
 291     elif test -d $cf_add_libdir
 292     then
 293       cf_have_libdir=no
 294       if test -n "$LDFLAGS$LIBS" ; then
 295         # a loop is needed to ensure we can add subdirs of existing dirs
 296         for cf_test_libdir in $LDFLAGS $LIBS ; do
 297           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 298             cf_have_libdir=yes; break
 299           fi
 300         done
 301       fi
 302       if test "$cf_have_libdir" = no ; then
 303         CF_VERBOSE(adding $cf_add_libdir to library-path)
 304         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 305       fi
 306     fi
 307   done
 308 fi
 309 ])dnl
 310 dnl ---------------------------------------------------------------------------
 311 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 312 dnl -----------
 313 dnl Add one or more libraries, used to enforce consistency.
 314 dnl
 315 dnl $1 = libraries to add, with the "-l", etc.
 316 dnl $2 = variable to update (default $LIBS)
 317 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 318 dnl ---------------------------------------------------------------------------
 319 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 320 dnl ------------------
 321 dnl Append to a search-list for a nonstandard header/lib-file
 322 dnl     $1 = the variable to return as result
 323 dnl     $2 = the package name
 324 dnl     $3 = the subdirectory, e.g., bin, include or lib
 325 dnl $4 = the directory under which we will test for subdirectories
 326 dnl $5 = a directory that we do not want $4 to match
 327 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 328 [
 329 test "$4" != "$5" && \
 330 test -d "$4" && \
 331 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 332         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 333         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 334         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 335         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 336         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 337         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 338 }
 339 ])dnl
 340 dnl ---------------------------------------------------------------------------
 341 dnl CF_ANSI_CC_CHECK version: 11 updated: 2011/07/01 19:47:45
 342 dnl ----------------
 343 dnl This was originally adapted from the macros 'fp_PROG_CC_STDC' and
 344 dnl 'fp_C_PROTOTYPES' in the sharutils 4.2 distribution.
 345 AC_DEFUN([CF_ANSI_CC_CHECK],
 346 [
 347 # This should have been defined by AC_PROG_CC
 348 : ${CC:=cc}
 349
 350 # Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 351 # into CC.  This will not help with broken scripts that wrap the compiler with
 352 # options, but eliminates a more common category of user confusion.
 353 AC_MSG_CHECKING(\$CC variable)
 354 case "$CC" in #(vi
 355 *[[\ \  ]]-[[IUD]]*)
 356         AC_MSG_RESULT(broken)
 357         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 358         # humor him...
 359         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 360         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 361         CF_ADD_CFLAGS($cf_flags)
 362         ;;
 363 *)
 364         AC_MSG_RESULT(ok)
 365         ;;
 366 esac
 367
 368 AC_CACHE_CHECK(for ${CC:-cc} option to accept ANSI C, cf_cv_ansi_cc,[
 369 cf_cv_ansi_cc=no
 370 cf_save_CFLAGS="$CFLAGS"
 371 cf_save_CPPFLAGS="$CPPFLAGS"
 372 # Don't try gcc -ansi; that turns off useful extensions and
 373 # breaks some systems' header files.
 374 # AIX                   -qlanglvl=ansi
 375 # Ultrix and OSF/1      -std1
 376 # HP-UX                 -Aa -D_HPUX_SOURCE
 377 # SVR4                  -Xc
 378 # UnixWare 1.2          (cannot use -Xc, since ANSI/POSIX clashes)
 379 for cf_arg in "-DCC_HAS_PROTOS" \
 380         "" \
 381         -qlanglvl=ansi \
 382         -std1 \
 383         -Ae \
 384         "-Aa -D_HPUX_SOURCE" \
 385         -Xc
 386 do
 387         CF_ADD_CFLAGS($cf_arg)
 388         AC_TRY_COMPILE(
 389 [
 390 #ifndef CC_HAS_PROTOS
 391 #if !defined(__STDC__) || (__STDC__ != 1)
 392 choke me
 393 #endif
 394 #endif
 395 ],[
 396         int test (int i, double x);
 397         struct s1 {int (*f) (int a);};
 398         struct s2 {int (*f) (double a);};],
 399         [cf_cv_ansi_cc="$cf_arg"; break])
 400 done
 401 CFLAGS="$cf_save_CFLAGS"
 402 CPPFLAGS="$cf_save_CPPFLAGS"
 403 ])
 404
 405 if test "$cf_cv_ansi_cc" != "no"; then
 406 if test ".$cf_cv_ansi_cc" != ".-DCC_HAS_PROTOS"; then
 407         CF_ADD_CFLAGS($cf_cv_ansi_cc)
 408 else
 409         AC_DEFINE(CC_HAS_PROTOS)
 410 fi
 411 fi
 412 ])dnl
 413 dnl ---------------------------------------------------------------------------
 414 dnl CF_ANSI_CC_REQD version: 4 updated: 2008/03/23 14:48:54
 415 dnl ---------------
 416 dnl For programs that must use an ANSI compiler, obtain compiler options that
 417 dnl will make it recognize prototypes.  We'll do preprocessor checks in other
 418 dnl macros, since tools such as unproto can fake prototypes, but only part of
 419 dnl the preprocessor.
 420 AC_DEFUN([CF_ANSI_CC_REQD],
 421 [AC_REQUIRE([CF_ANSI_CC_CHECK])
 422 if test "$cf_cv_ansi_cc" = "no"; then
 423         AC_MSG_ERROR(
 424 [Your compiler does not appear to recognize prototypes.
 425 You have the following choices:
 426         a. adjust your compiler options
 427         b. get an up-to-date compiler
 428         c. use a wrapper such as unproto])
 429 fi
 430 ])dnl
 431 dnl ---------------------------------------------------------------------------
 432 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 433 dnl --------------
 434 dnl Allow user to disable a normally-on option.
 435 AC_DEFUN([CF_ARG_DISABLE],
 436 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 437 dnl ---------------------------------------------------------------------------
 438 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 439 dnl -------------
 440 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 441 dnl values.
 442 dnl
 443 dnl Parameters:
 444 dnl $1 = option name
 445 dnl $2 = help-string
 446 dnl $3 = action to perform if option is not default
 447 dnl $4 = action if perform if option is default
 448 dnl $5 = default option value (either 'yes' or 'no')
 449 AC_DEFUN([CF_ARG_OPTION],
 450 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 451   if test "$enableval" != "$5" ; then
 452 ifelse([$3],,[    :]dnl
 453 ,[    $3]) ifelse([$4],,,[
 454   else
 455     $4])
 456   fi],[enableval=$5 ifelse([$4],,,[
 457   $4
 458 ])dnl
 459   ])])dnl
 460 dnl ---------------------------------------------------------------------------
 461 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 462 dnl -----------
 463 dnl Check for suitable "ar" (archiver) options for updating an archive.
 464 AC_DEFUN([CF_AR_FLAGS],[
 465 AC_REQUIRE([CF_PROG_AR])
 466
 467 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 468         cf_cv_ar_flags=unknown
 469         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 470         do
 471
 472                 # check if $ARFLAGS already contains this choice
 473                 if test "x$ARFLAGS" != "x" ; then
 474                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 475                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 476                                 cf_cv_ar_flags=
 477                                 break
 478                         fi
 479                 fi
 480
 481                 rm -f conftest.$ac_cv_objext
 482                 rm -f conftest.a
 483
 484                 cat >conftest.$ac_ext <<EOF
 485 #line __oline__ "configure"
 486 int     testdata[[3]] = { 123, 456, 789 };
 487 EOF
 488                 if AC_TRY_EVAL(ac_compile) ; then
 489                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 490                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 491                         if test -f conftest.a ; then
 492                                 cf_cv_ar_flags=$cf_ar_flags
 493                                 break
 494                         fi
 495                 else
 496                         CF_VERBOSE(cannot compile test-program)
 497                         break
 498                 fi
 499         done
 500         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 501 ])
 502
 503 if test -n "$ARFLAGS" ; then
 504         if test -n "$cf_cv_ar_flags" ; then
 505                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 506         fi
 507 else
 508         ARFLAGS=$cf_cv_ar_flags
 509 fi
 510
 511 AC_SUBST(ARFLAGS)
 512 ])
 513 dnl ---------------------------------------------------------------------------
 514 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
 515 dnl -----------------
 516 dnl Check if awk can handle big strings using printf.  Some older versions of
 517 dnl awk choke on large strings passed via "%s".
 518 dnl
 519 dnl $1 = desired string size
 520 dnl $2 = variable to set with result
 521 AC_DEFUN([CF_AWK_BIG_PRINTF],
 522 [
 523         case x$AWK in #(vi
 524         x)
 525                 eval $2=no
 526                 ;;
 527         *) #(vi
 528                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 529                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 530                         eval $2=yes
 531                 else
 532                         eval $2=no
 533                 fi
 534                 ;;
 535         esac
 536 ])dnl
 537 dnl ---------------------------------------------------------------------------
 538 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 539 dnl ------------
 540 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 541 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 542 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 543 dnl
 544 dnl Treat the configuration-variable specially here, since we're directly
 545 dnl substituting its value (i.e., 1/0).
 546 dnl
 547 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 548 AC_DEFUN([CF_BOOL_DECL],
 549 [
 550 AC_MSG_CHECKING(if we should include stdbool.h)
 551
 552 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 553         AC_TRY_COMPILE([],[bool foo = false],
 554                 [cf_cv_header_stdbool_h=0],
 555                 [AC_TRY_COMPILE([
 556 #ifndef __BEOS__
 557 #include <stdbool.h>
 558 #endif
 559 ],[bool foo = false],
 560                         [cf_cv_header_stdbool_h=1],
 561                         [cf_cv_header_stdbool_h=0])])])
 562
 563 if test "$cf_cv_header_stdbool_h" = 1
 564 then    AC_MSG_RESULT(yes)
 565 else    AC_MSG_RESULT(no)
 566 fi
 567
 568 AC_MSG_CHECKING([for builtin bool type])
 569
 570 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 571         AC_TRY_COMPILE([
 572 #include <stdio.h>
 573 #include <sys/types.h>
 574 ],[bool x = false],
 575                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 576                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 577         ])
 578
 579 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 580 then    AC_MSG_RESULT(yes)
 581 else    AC_MSG_RESULT(no)
 582 fi
 583 ])dnl
 584 dnl ---------------------------------------------------------------------------
 585 dnl CF_BOOL_SIZE version: 12 updated: 2006/12/16 12:33:30
 586 dnl ------------
 587 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 588 dnl Don't bother looking for bool.h, since it's been deprecated.
 589 dnl
 590 dnl If the current compiler is C rather than C++, we get the bool definition
 591 dnl from <stdbool.h>.
 592 AC_DEFUN([CF_BOOL_SIZE],
 593 [
 594 AC_MSG_CHECKING([for size of bool])
 595 AC_CACHE_VAL(cf_cv_type_of_bool,[
 596         rm -f cf_test.out
 597         AC_TRY_RUN([
 598 #include <stdlib.h>
 599 #include <stdio.h>
 600
 601 #if defined(__cplusplus)
 602
 603 #ifdef HAVE_GXX_BUILTIN_H
 604 #include <g++/builtin.h>
 605 #elif HAVE_GPP_BUILTIN_H
 606 #include <gpp/builtin.h>
 607 #elif HAVE_BUILTIN_H
 608 #include <builtin.h>
 609 #endif
 610
 611 #else
 612
 613 #if $cf_cv_header_stdbool_h
 614 #include <stdbool.h>
 615 #endif
 616
 617 #endif
 618
 619 main()
 620 {
 621         FILE *fp = fopen("cf_test.out", "w");
 622         if (fp != 0) {
 623                 bool x = true;
 624                 if ((bool)(-x) >= 0)
 625                         fputs("unsigned ", fp);
 626                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 627                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 628                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 629                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 630                 fclose(fp);
 631         }
 632         ${cf_cv_main_return:-return}(0);
 633 }
 634                 ],
 635                 [cf_cv_type_of_bool=`cat cf_test.out`
 636                  if test -z "$cf_cv_type_of_bool"; then
 637                    cf_cv_type_of_bool=unknown
 638                  fi],
 639                 [cf_cv_type_of_bool=unknown],
 640                 [cf_cv_type_of_bool=unknown])
 641         ])
 642         rm -f cf_test.out
 643 AC_MSG_RESULT($cf_cv_type_of_bool)
 644 if test "$cf_cv_type_of_bool" = unknown ; then
 645         case .$NCURSES_BOOL in #(vi
 646         .auto|.) NCURSES_BOOL=unsigned;;
 647         esac
 648         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 649         cf_cv_type_of_bool=$NCURSES_BOOL
 650 fi
 651 ])dnl
 652 dnl ---------------------------------------------------------------------------
 653 dnl CF_BUILD_CC version: 6 updated: 2006/10/14 15:23:15
 654 dnl -----------
 655 dnl If we're cross-compiling, allow the user to override the tools and their
 656 dnl options.  The configure script is oriented toward identifying the host
 657 dnl compiler, etc., but we need a build compiler to generate parts of the
 658 dnl source.
 659 dnl
 660 dnl $1 = default for $CPPFLAGS
 661 dnl $2 = default for $LIBS
 662 AC_DEFUN([CF_BUILD_CC],[
 663 AC_REQUIRE([CF_PROG_EXT])
 664 if test "$cross_compiling" = yes ; then
 665
 666         # defaults that we might want to override
 667         : ${BUILD_CFLAGS:=''}
 668         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 669         : ${BUILD_LDFLAGS:=''}
 670         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 671         : ${BUILD_EXEEXT:='$x'}
 672         : ${BUILD_OBJEXT:='o'}
 673
 674         AC_ARG_WITH(build-cc,
 675                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 676                 [BUILD_CC="$withval"],
 677                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 678         AC_MSG_CHECKING(for native build C compiler)
 679         AC_MSG_RESULT($BUILD_CC)
 680
 681         AC_MSG_CHECKING(for native build C preprocessor)
 682         AC_ARG_WITH(build-cpp,
 683                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 684                 [BUILD_CPP="$withval"],
 685                 [BUILD_CPP='${BUILD_CC} -E'])
 686         AC_MSG_RESULT($BUILD_CPP)
 687
 688         AC_MSG_CHECKING(for native build C flags)
 689         AC_ARG_WITH(build-cflags,
 690                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 691                 [BUILD_CFLAGS="$withval"])
 692         AC_MSG_RESULT($BUILD_CFLAGS)
 693
 694         AC_MSG_CHECKING(for native build C preprocessor-flags)
 695         AC_ARG_WITH(build-cppflags,
 696                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 697                 [BUILD_CPPFLAGS="$withval"])
 698         AC_MSG_RESULT($BUILD_CPPFLAGS)
 699
 700         AC_MSG_CHECKING(for native build linker-flags)
 701         AC_ARG_WITH(build-ldflags,
 702                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 703                 [BUILD_LDFLAGS="$withval"])
 704         AC_MSG_RESULT($BUILD_LDFLAGS)
 705
 706         AC_MSG_CHECKING(for native build linker-libraries)
 707         AC_ARG_WITH(build-libs,
 708                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 709                 [BUILD_LIBS="$withval"])
 710         AC_MSG_RESULT($BUILD_LIBS)
 711
 712         # this assumes we're on Unix.
 713         BUILD_EXEEXT=
 714         BUILD_OBJEXT=o
 715
 716         : ${BUILD_CC:='${CC}'}
 717
 718         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 719                 AC_MSG_ERROR([Cross-build requires two compilers.
 720 Use --with-build-cc to specify the native compiler.])
 721         fi
 722
 723 else
 724         : ${BUILD_CC:='${CC}'}
 725         : ${BUILD_CPP:='${CPP}'}
 726         : ${BUILD_CFLAGS:='${CFLAGS}'}
 727         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 728         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 729         : ${BUILD_LIBS:='${LIBS}'}
 730         : ${BUILD_EXEEXT:='$x'}
 731         : ${BUILD_OBJEXT:='o'}
 732 fi
 733
 734 AC_SUBST(BUILD_CC)
 735 AC_SUBST(BUILD_CPP)
 736 AC_SUBST(BUILD_CFLAGS)
 737 AC_SUBST(BUILD_CPPFLAGS)
 738 AC_SUBST(BUILD_LDFLAGS)
 739 AC_SUBST(BUILD_LIBS)
 740 AC_SUBST(BUILD_EXEEXT)
 741 AC_SUBST(BUILD_OBJEXT)
 742 ])dnl
 743 dnl ---------------------------------------------------------------------------
 744 dnl CF_CFG_DEFAULTS version: 8 updated: 2011/06/04 20:09:13
 745 dnl ---------------
 746 dnl Determine the default configuration into which we'll install ncurses.  This
 747 dnl can be overridden by the user's command-line options.  There's two items to
 748 dnl look for:
 749 dnl     1. the prefix (e.g., /usr)
 750 dnl     2. the header files (e.g., /usr/include/ncurses)
 751 dnl We'll look for a previous installation of ncurses and use the same defaults.
 752 dnl
 753 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 754 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 755 dnl programs from a vendor's.
 756 AC_DEFUN([CF_CFG_DEFAULTS],
 757 [
 758 AC_MSG_CHECKING(for prefix)
 759 if test "x$prefix" = "xNONE" ; then
 760         case "$cf_cv_system_name" in
 761                 # non-vendor systems don't have a conflict
 762         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|k*bsd*-gnu)
 763                 prefix=/usr
 764                 ;;
 765         *)      prefix=$ac_default_prefix
 766                 ;;
 767         esac
 768 fi
 769 AC_MSG_RESULT($prefix)
 770
 771 if test "x$prefix" = "xNONE" ; then
 772 AC_MSG_CHECKING(for default include-directory)
 773 test -n "$verbose" && echo 1>&AC_FD_MSG
 774 for cf_symbol in \
 775         $includedir \
 776         $includedir/ncurses \
 777         $prefix/include \
 778         $prefix/include/ncurses \
 779         /usr/local/include \
 780         /usr/local/include/ncurses \
 781         /usr/include \
 782         /usr/include/ncurses
 783 do
 784         cf_dir=`eval echo $cf_symbol`
 785         if test -f $cf_dir/curses.h ; then
 786         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 787                 includedir="$cf_symbol"
 788                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 789                 break
 790         fi
 791         fi
 792         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 793 done
 794 AC_MSG_RESULT($includedir)
 795 fi
 796 ])dnl
 797 dnl ---------------------------------------------------------------------------
 798 dnl CF_CGETENT version: 4 updated: 2011/08/07 14:54:41
 799 dnl ----------
 800 dnl Check if the terminal-capability database functions are available.  If not,
 801 dnl ncurses has a much-reduced version.
 802 AC_DEFUN([CF_CGETENT],[
 803 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 804 AC_TRY_LINK([
 805 #include <stdlib.h>],[
 806         char temp[128];
 807         char *buf = temp;
 808         char *db_array = temp;
 809         cgetent(&buf, &db_array, "vt100");
 810         cgetcap(buf, "tc", '=');
 811         cgetmatch(buf, "tc");
 812         ],
 813         [cf_cv_cgetent=yes],
 814         [cf_cv_cgetent=no])
 815 ])
 816
 817 if test "$cf_cv_cgetent" = yes
 818 then
 819         AC_DEFINE(HAVE_BSD_CGETENT)
 820 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 821 AC_TRY_LINK([
 822 #include <stdlib.h>],[
 823         char temp[128];
 824         char *buf = temp;
 825 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 826         const char *db_array = temp;
 827         cgetent(&buf, &db_array, "vt100");
 828 #endif
 829         cgetcap(buf, "tc", '=');
 830         cgetmatch(buf, "tc");
 831         ],
 832         [cf_cv_cgetent_const=yes],
 833         [cf_cv_cgetent_const=no])
 834 ])
 835         if test "$cf_cv_cgetent_const" = yes
 836         then
 837                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const)
 838         fi
 839 fi
 840 ])dnl
 841 dnl ---------------------------------------------------------------------------
 842 dnl CF_CHECK_CACHE version: 11 updated: 2008/03/23 14:45:59
 843 dnl --------------
 844 dnl Check if we're accidentally using a cache from a different machine.
 845 dnl Derive the system name, as a check for reusing the autoconf cache.
 846 dnl
 847 dnl If we've packaged config.guess and config.sub, run that (since it does a
 848 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 849 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 850 dnl which is useful in cross-compiles.
 851 dnl
 852 dnl Note: we would use $ac_config_sub, but that is one of the places where
 853 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 854 AC_DEFUN([CF_CHECK_CACHE],
 855 [
 856 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 857         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 858         system_name="$host_os"
 859 else
 860         system_name="`(uname -s -r) 2>/dev/null`"
 861         if test -z "$system_name" ; then
 862                 system_name="`(hostname) 2>/dev/null`"
 863         fi
 864 fi
 865 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name")
 866 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 867
 868 test -z "$system_name" && system_name="$cf_cv_system_name"
 869 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 870
 871 if test ".$system_name" != ".$cf_cv_system_name" ; then
 872         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 873         AC_MSG_ERROR("Please remove config.cache and try again.")
 874 fi
 875 ])dnl
 876 dnl ---------------------------------------------------------------------------
 877 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
 878 dnl --------------
 879 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 880 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 881 dnl ourselves.
 882 dnl
 883 dnl $1 = the name to check
 884 dnl $2 = the assumed type
 885 AC_DEFUN([CF_CHECK_ERRNO],
 886 [
 887 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 888     AC_TRY_COMPILE([
 889 #ifdef HAVE_STDLIB_H
 890 #include <stdlib.h>
 891 #endif
 892 #include <stdio.h>
 893 #include <sys/types.h>
 894 #include <errno.h> ],
 895     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 896     [cf_cv_dcl_$1=yes],
 897     [cf_cv_dcl_$1=no])
 898 ])
 899
 900 if test "$cf_cv_dcl_$1" = no ; then
 901     CF_UPPER(cf_result,decl_$1)
 902     AC_DEFINE_UNQUOTED($cf_result)
 903 fi
 904
 905 # It's possible (for near-UNIX clones) that the data doesn't exist
 906 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 907 ])dnl
 908 dnl ---------------------------------------------------------------------------
 909 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
 910 dnl --------------------
 911 dnl Check for existence of external data in the current set of libraries.  If
 912 dnl we can modify it, it's real enough.
 913 dnl $1 = the name to check
 914 dnl $2 = its type
 915 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 916 [
 917 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 918     AC_TRY_LINK([
 919 #undef $1
 920 extern $2 $1;
 921 ],
 922     [$1 = 2],
 923     [cf_cv_have_$1=yes],
 924     [cf_cv_have_$1=no])
 925 ])
 926
 927 if test "$cf_cv_have_$1" = yes ; then
 928     CF_UPPER(cf_result,have_$1)
 929     AC_DEFINE_UNQUOTED($cf_result)
 930 fi
 931
 932 ])dnl
 933 dnl ---------------------------------------------------------------------------
 934 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 935 dnl -------------------
 936 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 937 dnl is not "weak" - warn about this because it can create problems linking
 938 dnl applications with ncurses.
 939 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 940 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 941
 942 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 943 cf_cv_check_gpm_wgetch=unknown
 944 if test "$cross_compiling" != yes ; then
 945
 946 cat >conftest.$ac_ext <<CF_EOF
 947 #include <gpm.h>
 948 int main()
 949 {
 950         Gpm_Wgetch();
 951         ${cf_cv_main_return:-return}(0);
 952 }
 953 CF_EOF
 954
 955         cf_save_LIBS="$LIBS"
 956         # This only works if we can look at the symbol table.  If a shared
 957         # library is stripped for install, we cannot use that.  So we're forced
 958         # to rely on the static library, noting that some packagers may not
 959         # include it.
 960         LIBS="-static -lgpm -dynamic $LIBS"
 961         if AC_TRY_EVAL(ac_compile) ; then
 962                 if AC_TRY_EVAL(ac_link) ; then
 963                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 964                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 965                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 966                 fi
 967         fi
 968         rm -rf conftest*
 969         LIBS="$cf_save_LIBS"
 970 fi
 971 ])
 972
 973 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 974         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 975 fi
 976 ])])dnl
 977 dnl ---------------------------------------------------------------------------
 978 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
 979 dnl ----------------
 980 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
 981 AC_DEFUN([CF_CHECK_WCHAR_H],[
 982 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
 983 AC_TRY_COMPILE(
 984 [
 985 #include <stdlib.h>
 986 #include <wchar.h>
 987 ],[
 988         wint_t foo = 0;
 989         int bar = iswpunct(foo)],
 990         [cf_cv_wchar_h_okay=yes],
 991         [cf_cv_wchar_h_okay=no])])
 992
 993 if test $cf_cv_wchar_h_okay = no
 994 then
 995         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 996 fi
 997 ])dnl
 998 dnl ---------------------------------------------------------------------------
 999 dnl CF_CPP_PARAM_INIT version: 5 updated: 2011/12/03 16:54:03
1000 dnl -----------------
1001 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1002 dnl is a late feature for the standard and is not in some recent compilers
1003 dnl (1999/9/11).
1004 AC_DEFUN([CF_CPP_PARAM_INIT],
1005 [
1006 if test -n "$CXX"; then
1007 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1008         AC_LANG_SAVE
1009         AC_LANG_CPLUSPLUS
1010         AC_TRY_RUN([
1011 class TEST {
1012 private:
1013         int value;
1014 public:
1015         TEST(int x = 1);
1016         ~TEST();
1017 };
1018
1019 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1020 {
1021         value = x;
1022 }
1023 int main() { }
1024 ],
1025         [cf_cv_cpp_param_init=yes],
1026         [cf_cv_cpp_param_init=no],
1027         [cf_cv_cpp_param_init=unknown])
1028         AC_LANG_RESTORE
1029 ])
1030 fi
1031 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT)
1032 ])dnl
1033 dnl ---------------------------------------------------------------------------
1034 dnl CF_CPP_STATIC_CAST version: 1 updated: 2005/07/23 16:52:43
1035 dnl ------------------
1036 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1037 dnl not be supported in g++ before 3.0
1038 AC_DEFUN([CF_CPP_STATIC_CAST],
1039 [
1040 if test -n "$CXX"; then
1041
1042 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1043         AC_LANG_SAVE
1044         AC_LANG_CPLUSPLUS
1045
1046         AC_TRY_COMPILE([
1047 class NCursesPanel
1048 {
1049 public:
1050   NCursesPanel(int nlines,
1051                int ncols,
1052                int begin_y = 0,
1053                int begin_x = 0)
1054   {
1055   }
1056
1057   ~NCursesPanel();
1058 };
1059
1060 template<class T> class NCursesUserPanel : public NCursesPanel
1061 {
1062 public:
1063   NCursesUserPanel (int nlines,
1064                     int ncols,
1065                     int begin_y = 0,
1066                     int begin_x = 0,
1067                     const T* p_UserData = static_cast<T*>(0))
1068     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1069   {
1070   };
1071   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1072   {
1073   };
1074
1075   virtual ~NCursesUserPanel() {};
1076 };
1077 ],[
1078         const char* p_UserData = static_cast<char*>(0)],
1079         [cf_cv_cpp_static_cast=yes],
1080         [cf_cv_cpp_static_cast=no])
1081
1082         AC_LANG_RESTORE
1083 ])
1084
1085 fi
1086
1087 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST)
1088 ])dnl
1089 dnl ---------------------------------------------------------------------------
1090 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1091 dnl ---------------
1092 dnl Setup special archiver flags for given compilers.
1093 AC_DEFUN([CF_CXX_AR_FLAGS],[
1094         CXX_AR='$(AR)'
1095         CXX_ARFLAGS='$(ARFLAGS)'
1096         case $cf_cv_system_name in #(vi
1097         irix*) #(vi
1098             if test "$GXX" != yes ; then
1099                 CXX_AR='$(CXX)'
1100                 CXX_ARFLAGS='-ar -o'
1101             fi
1102             ;;
1103         sco3.2v5*) #(vi
1104             CXXLDFLAGS="-u main"
1105             ;;
1106         solaris2*)
1107             if test "$GXX" != yes ; then
1108                 CXX_AR='$(CXX)'
1109                 CXX_ARFLAGS='-xar -o'
1110             fi
1111             ;;
1112         esac
1113         AC_SUBST(CXXLDFLAGS)
1114         AC_SUBST(CXX_AR)
1115         AC_SUBST(CXX_ARFLAGS)
1116 ])dnl
1117 dnl ---------------------------------------------------------------------------
1118 dnl CF_CXX_IOSTREAM_NAMESPACE version: 1 updated: 2011/10/29 08:35:34
1119 dnl -------------------------
1120 dnl For c++, check if iostream uses "std::" namespace.
1121 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1122 AC_CHECK_HEADERS(iostream)
1123 if test x"$ac_cv_header_iostream" = xyes ; then
1124         AC_MSG_CHECKING(if iostream uses std-namespace)
1125         AC_TRY_COMPILE([
1126 #include <iostream>
1127 using std::endl;
1128 using std::cerr;],[
1129 cerr << "testing" << endl;
1130 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1131         AC_MSG_RESULT($cf_iostream_namespace)
1132         if test "$cf_iostream_namespace" = yes ; then
1133                 AC_DEFINE(IOSTREAM_NAMESPACE)
1134         fi
1135 fi
1136 ])dnl
1137 dnl ---------------------------------------------------------------------------
1138 dnl CF_C_INLINE version: 3 updated: 2010/05/01 15:14:41
1139 dnl -----------
1140 dnl Check if the C compiler supports "inline".
1141 dnl $1 is the name of a shell variable to set if inline is supported
1142 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1143 AC_DEFUN([CF_C_INLINE],[
1144 AC_C_INLINE
1145 $1=
1146 if test "$ac_cv_c_inline" != no ; then
1147   $1=inline
1148   if test "$INTEL_COMPILER" = yes
1149   then
1150     :
1151   elif test "$GCC" = yes
1152   then
1153     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1154       cf_save_CFLAGS=$CFLAGS
1155       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1156       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1157       [${cf_cv_main_return:-return} foo()],
1158       [cf_cv_gcc_inline=yes],
1159       [cf_cv_gcc_inline=no])
1160       CFLAGS=$cf_save_CFLAGS
1161     ])
1162     if test "$cf_cv_gcc_inline" = yes ; then
1163         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1164     fi
1165   fi
1166 fi
1167 AC_SUBST($1)
1168 ])dnl
1169 dnl ---------------------------------------------------------------------------
1170 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1171 dnl ----------
1172 dnl "dirname" is not portable, so we fake it with a shell script.
1173 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1174 dnl ---------------------------------------------------------------------------
1175 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1176 dnl ---------------
1177 AC_DEFUN([CF_DIRS_TO_MAKE],
1178 [
1179 DIRS_TO_MAKE="lib"
1180 for cf_item in $cf_list_models
1181 do
1182         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1183         for cf_item2 in $DIRS_TO_MAKE
1184         do
1185                 test $cf_item2 = $cf_subdir && break
1186         done
1187         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1188 done
1189 for cf_dir in $DIRS_TO_MAKE
1190 do
1191         test ! -d $cf_dir && mkdir $cf_dir
1192 done
1193 AC_SUBST(DIRS_TO_MAKE)
1194 ])dnl
1195 dnl ---------------------------------------------------------------------------
1196 dnl CF_DISABLE_LEAKS version: 6 updated: 2010/07/23 04:14:32
1197 dnl ----------------
1198 dnl Combine no-leak checks with the libraries or tools that are used for the
1199 dnl checks.
1200 AC_DEFUN([CF_DISABLE_LEAKS],[
1201
1202 AC_REQUIRE([CF_WITH_DMALLOC])
1203 AC_REQUIRE([CF_WITH_DBMALLOC])
1204 AC_REQUIRE([CF_WITH_VALGRIND])
1205
1206 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1207 AC_ARG_ENABLE(leaks,
1208         [  --disable-leaks         test: free permanent memory, analyze leaks],
1209         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1210         : ${with_no_leaks:=no})
1211 AC_MSG_RESULT($with_no_leaks)
1212
1213 if test "$with_no_leaks" = yes ; then
1214         AC_DEFINE(NO_LEAKS)
1215         AC_DEFINE(YY_NO_LEAKS)
1216 fi
1217 ])dnl
1218 dnl ---------------------------------------------------------------------------
1219 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1220 dnl --------------------------
1221 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1222 dnl the older "-version-info" feature.  The newer feature allows us to use
1223 dnl version numbering on shared libraries which make them compatible with
1224 dnl various systems.
1225 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1226 [
1227 AC_MSG_CHECKING(if libtool -version-number should be used)
1228 CF_ARG_DISABLE(libtool-version,
1229         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1230         [cf_libtool_version=no],
1231         [cf_libtool_version=yes])
1232 AC_MSG_RESULT($cf_libtool_version)
1233
1234 if test "$cf_libtool_version" = yes ; then
1235         LIBTOOL_VERSION="-version-number"
1236 else
1237         LIBTOOL_VERSION="-version-info"
1238 fi
1239
1240 AC_SUBST(LIBTOOL_VERSION)
1241 ])dnl
1242 dnl ---------------------------------------------------------------------------
1243 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1244 dnl ---------------------
1245 dnl The rpath-hack makes it simpler to build programs, particularly with the
1246 dnl *BSD ports which may have essential libraries in unusual places.  But it
1247 dnl can interfere with building an executable for the base system.  Use this
1248 dnl option in that case.
1249 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1250 [
1251 AC_MSG_CHECKING(if rpath-hack should be disabled)
1252 CF_ARG_DISABLE(rpath-hack,
1253         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1254         [cf_disable_rpath_hack=yes],
1255         [cf_disable_rpath_hack=no])
1256 AC_MSG_RESULT($cf_disable_rpath_hack)
1257 if test "$cf_disable_rpath_hack" = no ; then
1258         CF_RPATH_HACK
1259 fi
1260 ])
1261 dnl ---------------------------------------------------------------------------
1262 dnl CF_ENABLE_PC_FILES version: 7 updated: 2011/12/10 18:58:47
1263 dnl ------------------
1264 dnl This is the "--enable-pc-files" option, which is available if there is a
1265 dnl pkg-config configuration on the local machine.
1266 AC_DEFUN([CF_ENABLE_PC_FILES],[
1267 AC_REQUIRE([CF_PKG_CONFIG])
1268 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1269
1270 if test "$PKG_CONFIG" != none ; then
1271         if test -n "$PKG_CONFIG_LIBDIR" && test -d "$PKG_CONFIG_LIBDIR" ; then
1272                 AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1273                 AC_ARG_ENABLE(pc-files,
1274                         [  --enable-pc-files       generate and install .pc files for pkg-config],
1275                         [enable_pc_files=$enableval],
1276                         [enable_pc_files=no])
1277                 AC_MSG_RESULT($enable_pc_files)
1278         elif test -z "$PKG_CONFIG_LIBDIR" || test "$PKG_CONFIG_LIBDIR" != no; then
1279                 enable_pc_files=no
1280                 AC_MSG_WARN(did not find $PKG_CONFIG library)
1281         fi
1282 else
1283         enable_pc_files=no
1284 fi
1285 ])dnl
1286 dnl ---------------------------------------------------------------------------
1287 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1288 dnl ---------------
1289 dnl Check if the rpath option should be used, setting cache variable
1290 dnl cf_cv_enable_rpath if so.
1291 AC_DEFUN([CF_ENABLE_RPATH],
1292 [
1293 AC_MSG_CHECKING(if rpath option should be used)
1294 AC_ARG_ENABLE(rpath,
1295 [  --enable-rpath          use rpath option when generating shared libraries],
1296 [cf_cv_enable_rpath=$enableval],
1297 [cf_cv_enable_rpath=no])
1298 AC_MSG_RESULT($cf_cv_enable_rpath)
1299 ])dnl
1300 dnl ---------------------------------------------------------------------------
1301 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1302 dnl --------
1303 dnl Check if 'errno' is declared in <errno.h>
1304 AC_DEFUN([CF_ERRNO],
1305 [
1306 CF_CHECK_ERRNO(errno)
1307 ])dnl
1308 dnl ---------------------------------------------------------------------------
1309 dnl CF_ETIP_DEFINES version: 4 updated: 2011/12/03 16:54:03
1310 dnl ---------------
1311 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1312 dnl math.h and builtin.h, only for ncurses
1313 AC_DEFUN([CF_ETIP_DEFINES],
1314 [
1315 AC_MSG_CHECKING(for special defines needed for etip.h)
1316 cf_save_CXXFLAGS="$CXXFLAGS"
1317 cf_result="none"
1318
1319 # etip.h includes ncurses.h which includes ncurses_dll.h
1320 # But ncurses_dll.h is generated - fix here.
1321 test -d include || mkdir include
1322 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1323
1324 for cf_math in "" MATH_H
1325 do
1326 for cf_excp in "" MATH_EXCEPTION
1327 do
1328         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1329         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1330         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1331 AC_TRY_COMPILE([
1332 #include <etip.h.in>
1333 ],[],[
1334         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1335         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1336         cf_result="$cf_math $cf_excp"
1337         break
1338 ],[])
1339 done
1340 done
1341 AC_MSG_RESULT($cf_result)
1342 CXXFLAGS="$cf_save_CXXFLAGS"
1343 ])
1344 dnl ---------------------------------------------------------------------------
1345 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1346 dnl ---------------
1347 dnl Find a library (specifically the linkage used in the code fragment),
1348 dnl searching for it if it is not already in the library path.
1349 dnl See also CF_ADD_SEARCHPATH.
1350 dnl
1351 dnl Parameters (4-on are optional):
1352 dnl     $1 = headers for library entrypoint
1353 dnl     $2 = code fragment for library entrypoint
1354 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1355 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1356 dnl     $5 = action to perform if not successful
1357 dnl     $6 = module name, if not the same as the library name
1358 dnl     $7 = extra libraries
1359 dnl
1360 dnl Sets these variables:
1361 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1362 dnl     $cf_cv_header_path_$3 - include-directory if needed
1363 dnl     $cf_cv_library_path_$3 - library-directory if needed
1364 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1365 AC_DEFUN([CF_FIND_LINKAGE],[
1366
1367 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1368 # will be set on completion of the AC_TRY_LINK below.
1369 cf_cv_header_path_$3=
1370 cf_cv_library_path_$3=
1371
1372 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1373
1374 cf_save_LIBS="$LIBS"
1375
1376 AC_TRY_LINK([$1],[$2],[
1377         cf_cv_find_linkage_$3=yes
1378         cf_cv_header_path_$3=/usr/include
1379         cf_cv_library_path_$3=/usr/lib
1380 ],[
1381
1382 LIBS="-l$3 $7 $cf_save_LIBS"
1383
1384 AC_TRY_LINK([$1],[$2],[
1385         cf_cv_find_linkage_$3=yes
1386         cf_cv_header_path_$3=/usr/include
1387         cf_cv_library_path_$3=/usr/lib
1388         cf_cv_library_file_$3="-l$3"
1389 ],[
1390         cf_cv_find_linkage_$3=no
1391         LIBS="$cf_save_LIBS"
1392
1393     CF_VERBOSE(find linkage for $3 library)
1394     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1395
1396     cf_save_CPPFLAGS="$CPPFLAGS"
1397     cf_test_CPPFLAGS="$CPPFLAGS"
1398
1399     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1400     for cf_cv_header_path_$3 in $cf_search
1401     do
1402       if test -d $cf_cv_header_path_$3 ; then
1403         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1404         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1405         AC_TRY_COMPILE([$1],[$2],[
1406             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1407             cf_cv_find_linkage_$3=maybe
1408             cf_test_CPPFLAGS="$CPPFLAGS"
1409             break],[
1410             CPPFLAGS="$cf_save_CPPFLAGS"
1411             ])
1412       fi
1413     done
1414
1415     if test "$cf_cv_find_linkage_$3" = maybe ; then
1416
1417       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1418
1419       cf_save_LIBS="$LIBS"
1420       cf_save_LDFLAGS="$LDFLAGS"
1421
1422       ifelse([$6],,,[
1423         CPPFLAGS="$cf_test_CPPFLAGS"
1424         LIBS="-l$3 $7 $cf_save_LIBS"
1425         AC_TRY_LINK([$1],[$2],[
1426             CF_VERBOSE(... found $3 library in system)
1427             cf_cv_find_linkage_$3=yes])
1428             CPPFLAGS="$cf_save_CPPFLAGS"
1429             LIBS="$cf_save_LIBS"
1430             ])
1431
1432       if test "$cf_cv_find_linkage_$3" != yes ; then
1433         CF_LIBRARY_PATH(cf_search,$3)
1434         for cf_cv_library_path_$3 in $cf_search
1435         do
1436           if test -d $cf_cv_library_path_$3 ; then
1437             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1438             CPPFLAGS="$cf_test_CPPFLAGS"
1439             LIBS="-l$3 $7 $cf_save_LIBS"
1440             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1441             AC_TRY_LINK([$1],[$2],[
1442                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1443                 cf_cv_find_linkage_$3=yes
1444                 cf_cv_library_file_$3="-l$3"
1445                 break],[
1446                 CPPFLAGS="$cf_save_CPPFLAGS"
1447                 LIBS="$cf_save_LIBS"
1448                 LDFLAGS="$cf_save_LDFLAGS"
1449                 ])
1450           fi
1451         done
1452         CPPFLAGS="$cf_save_CPPFLAGS"
1453         LDFLAGS="$cf_save_LDFLAGS"
1454       fi
1455
1456     else
1457       cf_cv_find_linkage_$3=no
1458     fi
1459     ],$7)
1460 ])
1461
1462 LIBS="$cf_save_LIBS"
1463
1464 if test "$cf_cv_find_linkage_$3" = yes ; then
1465 ifelse([$4],,[
1466         CF_ADD_INCDIR($cf_cv_header_path_$3)
1467         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1468         CF_ADD_LIB($3)
1469 ],[$4])
1470 else
1471 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1472 fi
1473 ])dnl
1474 dnl ---------------------------------------------------------------------------
1475 dnl CF_FUNC_DLSYM version: 2 updated: 2010/05/29 16:31:02
1476 dnl -------------
1477 dnl Test for dlsym() and related functions, as well as libdl.
1478 dnl
1479 dnl Sets
1480 dnl     $cf_have_dlsym
1481 dnl     $cf_have_libdl
1482 AC_DEFUN([CF_FUNC_DLSYM],[
1483 cf_have_dlsym=no
1484 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1485
1486 cf_have_libdl=no
1487 AC_CHECK_LIB(dl,dlsym,[
1488         cf_have_dlsym=yes
1489         cf_have_libdl=yes])])
1490
1491 if test "$cf_have_dlsym" = yes ; then
1492         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1493
1494         AC_MSG_CHECKING(whether able to link to dl*() functions)
1495         AC_TRY_LINK([#include <dlfcn.h>],[
1496                 void *obj;
1497                 if ((obj = dlopen("filename", 0)) != 0) {
1498                         if (dlsym(obj, "symbolname") == 0) {
1499                         dlclose(obj);
1500                         }
1501                 }],[
1502                 AC_DEFINE(HAVE_LIBDL)],[
1503                 AC_MSG_ERROR(Cannot link test program for libdl)])
1504         AC_MSG_RESULT(ok)
1505 else
1506         AC_MSG_ERROR(Cannot find dlsym function)
1507 fi
1508 ])
1509 dnl ---------------------------------------------------------------------------
1510 dnl CF_FUNC_MEMMOVE version: 7 updated: 2006/12/16 12:33:30
1511 dnl ---------------
1512 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1513 dnl is found, add our own version of memmove to the list of objects.
1514 AC_DEFUN([CF_FUNC_MEMMOVE],
1515 [
1516 AC_CHECK_FUNC(memmove,,[
1517 AC_CHECK_FUNC(bcopy,[
1518         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1519                 AC_TRY_RUN([
1520 int main() {
1521         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1522         char temp[40];
1523         bcopy(data, temp, sizeof(data));
1524         bcopy(temp+10, temp, 15);
1525         bcopy(temp+5, temp+15, 10);
1526         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1527 }
1528                 ],
1529                 [cf_cv_good_bcopy=yes],
1530                 [cf_cv_good_bcopy=no],
1531                 [cf_cv_good_bcopy=unknown])
1532                 ])
1533         ],[cf_cv_good_bcopy=no])
1534         if test "$cf_cv_good_bcopy" = yes ; then
1535                 AC_DEFINE(USE_OK_BCOPY)
1536         else
1537                 AC_DEFINE(USE_MY_MEMMOVE)
1538         fi
1539 ])])dnl
1540 dnl ---------------------------------------------------------------------------
1541 dnl CF_FUNC_NANOSLEEP version: 3 updated: 2006/12/16 12:33:30
1542 dnl -----------------
1543 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1544 dnl AIX 4.x, provide a non-working version.
1545 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1546 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1547 AC_TRY_RUN([
1548 #include <stdio.h>
1549 #include <errno.h>
1550 #include <time.h>
1551
1552 #ifdef HAVE_SYS_TIME_H
1553 #include <sys/time.h>
1554 #endif
1555
1556 int main() {
1557         struct timespec ts1, ts2;
1558         int code;
1559         ts1.tv_sec  = 0;
1560         ts1.tv_nsec = 750000000;
1561         ts2.tv_sec  = 0;
1562         ts2.tv_nsec = 0;
1563         errno = 0;
1564         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1565         ${cf_cv_main_return:-return}(code != 0);
1566 }
1567 ],
1568         [cf_cv_func_nanosleep=yes],
1569         [cf_cv_func_nanosleep=no],
1570         [cf_cv_func_nanosleep=unknown])])
1571
1572 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP)
1573 ])
1574 dnl ---------------------------------------------------------------------------
1575 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1576 dnl ---------------
1577 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1578 dnl "util" library as well.
1579 AC_DEFUN([CF_FUNC_OPENPTY],
1580 [
1581 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1582 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1583     cf_save_LIBS="$LIBS"
1584     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1585     for cf_header in pty.h libutil.h util.h
1586     do
1587     AC_TRY_LINK([
1588 #include <$cf_header>
1589 ],[
1590     int x = openpty((int *)0, (int *)0, (char *)0,
1591                    (struct termios *)0, (struct winsize *)0);
1592 ],[
1593         cf_cv_func_openpty=$cf_header
1594         break
1595 ],[
1596         cf_cv_func_openpty=no
1597 ])
1598     done
1599     LIBS="$cf_save_LIBS"
1600 ])
1601 ])dnl
1602 dnl ---------------------------------------------------------------------------
1603 dnl CF_FUNC_POLL version: 4 updated: 2006/12/16 12:33:30
1604 dnl ------------
1605 dnl See if the poll function really works.  Some platforms have poll(), but
1606 dnl it does not work for terminals or files.
1607 AC_DEFUN([CF_FUNC_POLL],[
1608 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1609 AC_TRY_RUN([
1610 #include <stdio.h>
1611 #ifdef HAVE_POLL_H
1612 #include <poll.h>
1613 #else
1614 #include <sys/poll.h>
1615 #endif
1616 int main() {
1617         struct pollfd myfds;
1618         int ret;
1619
1620         myfds.fd = 0;
1621         myfds.events = POLLIN;
1622
1623         ret = poll(&myfds, 1, 100);
1624         ${cf_cv_main_return:-return}(ret != 0);
1625 }],
1626         [cf_cv_working_poll=yes],
1627         [cf_cv_working_poll=no],
1628         [cf_cv_working_poll=unknown])])
1629 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL)
1630 ])dnl
1631 dnl ---------------------------------------------------------------------------
1632 dnl CF_FUNC_TERMIOS version: 2 updated: 2000/07/22 23:37:24
1633 dnl ---------------
1634 dnl Some old/broken variations define tcgetattr() only as a macro in
1635 dnl termio(s).h
1636 AC_DEFUN([CF_FUNC_TERMIOS],[
1637 AC_REQUIRE([CF_STRUCT_TERMIOS])
1638 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1639 AC_TRY_LINK([
1640 #include <sys/types.h>
1641 #ifdef HAVE_UNISTD_H
1642 #include <unistd.h>
1643 #endif
1644 #ifdef HAVE_TERMIOS_H
1645 #include <termios.h>
1646 #define TTY struct termios
1647 #else
1648 #ifdef HAVE_TERMIO_H
1649 #include <termio.h>
1650 #define TTY struct termio
1651 #endif
1652 #endif
1653 ],[
1654 TTY foo;
1655 tcgetattr(1, &foo);],
1656 [cf_cv_have_tcgetattr=yes],
1657 [cf_cv_have_tcgetattr=no])])
1658 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR)
1659 ])dnl
1660 dnl ---------------------------------------------------------------------------
1661 dnl CF_FUNC_VSSCANF version: 3 updated: 2001/12/19 00:50:10
1662 dnl ---------------
1663 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1664 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1665 dnl other functions.
1666 AC_DEFUN([CF_FUNC_VSSCANF],
1667 [
1668 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1669 AC_TRY_LINK([
1670 #include <stdarg.h>
1671 #include <stdio.h>],[
1672         va_list ap;
1673         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1674 AC_TRY_LINK([
1675 #include <stdarg.h>
1676 #include <stdio.h>],[
1677     FILE strbuf;
1678     char *str = "from";
1679
1680     strbuf._flag = _IOREAD;
1681     strbuf._ptr = strbuf._base = (unsigned char *) str;
1682     strbuf._cnt = strlen(str);
1683     strbuf._file = _NFILE;
1684     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1685 AC_TRY_LINK([
1686 #include <stdarg.h>
1687 #include <stdio.h>],[
1688     FILE strbuf;
1689     char *str = "from";
1690
1691     strbuf._flag = _IOREAD;
1692     strbuf._ptr = strbuf._base = (unsigned char *) str;
1693     strbuf._cnt = strlen(str);
1694     strbuf._file = _NFILE;
1695     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1696 cf_cv_func_vsscanf=no])])])])
1697
1698 case $cf_cv_func_vsscanf in #(vi
1699 vsscanf) AC_DEFINE(HAVE_VSSCANF);; #(vi
1700 vfscanf) AC_DEFINE(HAVE_VFSCANF);; #(vi
1701 _doscan) AC_DEFINE(HAVE__DOSCAN);;
1702 esac
1703
1704 ])dnl
1705 dnl ---------------------------------------------------------------------------
1706 dnl CF_GCC_ATTRIBUTES version: 14 updated: 2010/10/23 15:52:32
1707 dnl -----------------
1708 dnl Test for availability of useful gcc __attribute__ directives to quiet
1709 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1710 dnl to documentation, unrecognized directives cause older compilers to barf.
1711 AC_DEFUN([CF_GCC_ATTRIBUTES],
1712 [
1713 if test "$GCC" = yes
1714 then
1715 cat > conftest.i <<EOF
1716 #ifndef GCC_PRINTF
1717 #define GCC_PRINTF 0
1718 #endif
1719 #ifndef GCC_SCANF
1720 #define GCC_SCANF 0
1721 #endif
1722 #ifndef GCC_NORETURN
1723 #define GCC_NORETURN /* nothing */
1724 #endif
1725 #ifndef GCC_UNUSED
1726 #define GCC_UNUSED /* nothing */
1727 #endif
1728 EOF
1729 if test "$GCC" = yes
1730 then
1731         AC_CHECKING([for $CC __attribute__ directives])
1732 cat > conftest.$ac_ext <<EOF
1733 #line __oline__ "${as_me:-configure}"
1734 #include "confdefs.h"
1735 #include "conftest.h"
1736 #include "conftest.i"
1737 #if     GCC_PRINTF
1738 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1739 #else
1740 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1741 #endif
1742 #if     GCC_SCANF
1743 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1744 #else
1745 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1746 #endif
1747 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1748 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1749 extern void foo(void) GCC_NORETURN;
1750 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1751 EOF
1752         cf_printf_attribute=no
1753         cf_scanf_attribute=no
1754         for cf_attribute in scanf printf unused noreturn
1755         do
1756                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1757                 cf_directive="__attribute__(($cf_attribute))"
1758                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1759
1760                 case $cf_attribute in #(vi
1761                 printf) #(vi
1762                         cf_printf_attribute=yes
1763                         cat >conftest.h <<EOF
1764 #define GCC_$cf_ATTRIBUTE 1
1765 EOF
1766                         ;;
1767                 scanf) #(vi
1768                         cf_scanf_attribute=yes
1769                         cat >conftest.h <<EOF
1770 #define GCC_$cf_ATTRIBUTE 1
1771 EOF
1772                         ;;
1773                 *) #(vi
1774                         cat >conftest.h <<EOF
1775 #define GCC_$cf_ATTRIBUTE $cf_directive
1776 EOF
1777                         ;;
1778                 esac
1779
1780                 if AC_TRY_EVAL(ac_compile); then
1781                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1782                         cat conftest.h >>confdefs.h
1783                         case $cf_attribute in #(vi
1784                         printf) #(vi
1785                                 if test "$cf_printf_attribute" = no ; then
1786                                         cat >>confdefs.h <<EOF
1787 #define GCC_PRINTFLIKE(fmt,var) /* nothing */
1788 EOF
1789                                 else
1790                                         cat >>confdefs.h <<EOF
1791 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1792 EOF
1793                                 fi
1794                                 ;;
1795                         scanf) #(vi
1796                                 if test "$cf_scanf_attribute" = no ; then
1797                                         cat >>confdefs.h <<EOF
1798 #define GCC_SCANFLIKE(fmt,var) /* nothing */
1799 EOF
1800                                 else
1801                                         cat >>confdefs.h <<EOF
1802 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1803 EOF
1804                                 fi
1805                                 ;;
1806                         esac
1807                 fi
1808         done
1809 else
1810         fgrep define conftest.i >>confdefs.h
1811 fi
1812 rm -rf conftest*
1813 fi
1814 ])dnl
1815 dnl ---------------------------------------------------------------------------
1816 dnl CF_GCC_VERSION version: 5 updated: 2010/04/24 11:02:31
1817 dnl --------------
1818 dnl Find version of gcc
1819 AC_DEFUN([CF_GCC_VERSION],[
1820 AC_REQUIRE([AC_PROG_CC])
1821 GCC_VERSION=none
1822 if test "$GCC" = yes ; then
1823         AC_MSG_CHECKING(version of $CC)
1824         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1825         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1826         AC_MSG_RESULT($GCC_VERSION)
1827 fi
1828 ])dnl
1829 dnl ---------------------------------------------------------------------------
1830 dnl CF_GCC_WARNINGS version: 27 updated: 2010/10/23 15:52:32
1831 dnl ---------------
1832 dnl Check if the compiler supports useful warning options.  There's a few that
1833 dnl we don't use, simply because they're too noisy:
1834 dnl
1835 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1836 dnl     -Wredundant-decls (system headers make this too noisy)
1837 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1838 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1839 dnl             is enabled for ncurses using "--enable-const".
1840 dnl     -pedantic
1841 dnl
1842 dnl Parameter:
1843 dnl     $1 is an optional list of gcc warning flags that a particular
1844 dnl             application might want to use, e.g., "no-unused" for
1845 dnl             -Wno-unused
1846 dnl Special:
1847 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1848 dnl
1849 AC_DEFUN([CF_GCC_WARNINGS],
1850 [
1851 AC_REQUIRE([CF_GCC_VERSION])
1852 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1853
1854 cat > conftest.$ac_ext <<EOF
1855 #line __oline__ "${as_me:-configure}"
1856 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1857 EOF
1858
1859 if test "$INTEL_COMPILER" = yes
1860 then
1861 # The "-wdXXX" options suppress warnings:
1862 # remark #1419: external declaration in primary source file
1863 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1864 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1865 # remark #193: zero used for undefined preprocessing identifier
1866 # remark #593: variable "curs_sb_left_arrow" was set but never used
1867 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1868 # remark #869: parameter "tw" was never referenced
1869 # remark #981: operands are evaluated in unspecified order
1870 # warning #279: controlling expression is constant
1871
1872         AC_CHECKING([for $CC warning options])
1873         cf_save_CFLAGS="$CFLAGS"
1874         EXTRA_CFLAGS="-Wall"
1875         for cf_opt in \
1876                 wd1419 \
1877                 wd1683 \
1878                 wd1684 \
1879                 wd193 \
1880                 wd593 \
1881                 wd279 \
1882                 wd810 \
1883                 wd869 \
1884                 wd981
1885         do
1886                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1887                 if AC_TRY_EVAL(ac_compile); then
1888                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1889                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1890                 fi
1891         done
1892         CFLAGS="$cf_save_CFLAGS"
1893
1894 elif test "$GCC" = yes
1895 then
1896         AC_CHECKING([for $CC warning options])
1897         cf_save_CFLAGS="$CFLAGS"
1898         EXTRA_CFLAGS=
1899         cf_warn_CONST=""
1900         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1901         for cf_opt in W Wall \
1902                 Wbad-function-cast \
1903                 Wcast-align \
1904                 Wcast-qual \
1905                 Winline \
1906                 Wmissing-declarations \
1907                 Wmissing-prototypes \
1908                 Wnested-externs \
1909                 Wpointer-arith \
1910                 Wshadow \
1911                 Wstrict-prototypes \
1912                 Wundef $cf_warn_CONST $1
1913         do
1914                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1915                 if AC_TRY_EVAL(ac_compile); then
1916                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1917                         case $cf_opt in #(vi
1918                         Wcast-qual) #(vi
1919                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1920                                 ;;
1921                         Winline) #(vi
1922                                 case $GCC_VERSION in
1923                                 [[34]].*)
1924                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1925                                         continue;;
1926                                 esac
1927                                 ;;
1928                         esac
1929                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1930                 fi
1931         done
1932         CFLAGS="$cf_save_CFLAGS"
1933 fi
1934 rm -rf conftest*
1935
1936 AC_SUBST(EXTRA_CFLAGS)
1937 ])dnl
1938 dnl ---------------------------------------------------------------------------
1939 dnl CF_GETOPT_HEADER version: 4 updated: 2009/08/31 20:07:52
1940 dnl ----------------
1941 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1942 dnl unistd.h or (nonstandard) in getopt.h
1943 AC_DEFUN([CF_GETOPT_HEADER],
1944 [
1945 AC_HAVE_HEADERS(unistd.h getopt.h)
1946 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1947 cf_cv_getopt_header=none
1948 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1949 do
1950 AC_TRY_COMPILE([
1951 #include <$cf_header>],
1952 [int x = optind; char *y = optarg],
1953 [cf_cv_getopt_header=$cf_header
1954  break])
1955 done
1956 ])
1957 if test $cf_cv_getopt_header != none ; then
1958         AC_DEFINE(HAVE_GETOPT_HEADER)
1959 fi
1960 ])dnl
1961 dnl ---------------------------------------------------------------------------
1962 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
1963 dnl ----------------
1964 AC_DEFUN([CF_GNAT_GENERICS],
1965 [
1966 AC_REQUIRE([CF_GNAT_VERSION])
1967
1968 AC_MSG_CHECKING(if GNAT supports generics)
1969 case $cf_gnat_version in #(vi
1970 3.[[1-9]]*|[[4-9]].*) #(vi
1971         cf_gnat_generics=yes
1972         ;;
1973 *)
1974         cf_gnat_generics=no
1975         ;;
1976 esac
1977 AC_MSG_RESULT($cf_gnat_generics)
1978
1979 if test "$cf_gnat_generics" = yes
1980 then
1981         cf_compile_generics=generics
1982         cf_generic_objects="\${GENOBJS}"
1983 else
1984         cf_compile_generics=
1985         cf_generic_objects=
1986 fi
1987
1988 AC_SUBST(cf_compile_generics)
1989 AC_SUBST(cf_generic_objects)
1990 ])dnl
1991 dnl ---------------------------------------------------------------------------
1992 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
1993 dnl --------------------
1994 dnl Check if the gnat pragma "Unreferenced" works.
1995 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
1996 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
1997 CF_GNAT_TRY_LINK([procedure conftest;],
1998 [with Text_IO;
1999 with GNAT.OS_Lib;
2000 procedure conftest is
2001    test : Integer;
2002    pragma Unreferenced (test);
2003 begin
2004    test := 1;
2005    Text_IO.Put ("Hello World");
2006    Text_IO.New_Line;
2007    GNAT.OS_Lib.OS_Exit (0);
2008 end conftest;],
2009         [cf_cv_pragma_unreferenced=yes],
2010         [cf_cv_pragma_unreferenced=no])])
2011
2012 # if the pragma is supported, use it (needed in the Trace code).
2013 if test $cf_cv_pragma_unreferenced = yes ; then
2014         PRAGMA_UNREF=TRUE
2015 else
2016         PRAGMA_UNREF=FALSE
2017 fi
2018 AC_SUBST(PRAGMA_UNREF)
2019 ])dnl
2020 dnl ---------------------------------------------------------------------------
2021 dnl CF_GNAT_PROJECTS version: 2 updated: 2011/03/23 20:24:41
2022 dnl ----------------
2023 dnl GNAT projects are configured with ".gpr" project files.
2024 dnl GNAT libraries are a further development, using the project feature.
2025 AC_DEFUN([CF_GNAT_PROJECTS],
2026 [
2027 AC_REQUIRE([CF_GNAT_VERSION])
2028
2029 cf_gnat_libraries=no
2030 cf_gnat_projects=no
2031
2032 AC_MSG_CHECKING(if GNAT supports project files)
2033 case $cf_gnat_version in #(vi
2034 3.[[0-9]]*) #(vi
2035         ;;
2036 *)
2037         case $cf_cv_system_name in #(vi
2038         cygwin*) #(vi
2039                 ;;
2040         *)
2041                 mkdir conftest.src conftest.bin conftest.lib
2042                 cd conftest.src
2043                 rm -rf conftest* *~conftest*
2044                 cat >>library.gpr <<CF_EOF
2045 project Library is
2046   Kind := External ("LIB_KIND");
2047   for Library_Name use "ConfTest";
2048   for Object_Dir use ".";
2049   for Library_ALI_Dir use External("LIBRARY_DIR");
2050   for Library_Version use External ("SONAME");
2051   for Library_Kind use Kind;
2052   for Library_Dir use External("BUILD_DIR");
2053   Source_Dir := External ("SOURCE_DIR");
2054   for Source_Dirs use (Source_Dir);
2055   package Compiler is
2056      for Default_Switches ("Ada") use
2057        ("-g",
2058         "-O2",
2059         "-gnatafno",
2060         "-gnatVa",   -- All validity checks
2061         "-gnatwa");  -- Activate all optional errors
2062   end Compiler;
2063 end Library;
2064 CF_EOF
2065                 cat >>confpackage.ads <<CF_EOF
2066 package ConfPackage is
2067    procedure conftest;
2068 end ConfPackage;
2069 CF_EOF
2070                 cat >>confpackage.adb <<CF_EOF
2071 with Text_IO;
2072 package body ConfPackage is
2073    procedure conftest is
2074    begin
2075       Text_IO.Put ("Hello World");
2076       Text_IO.New_Line;
2077    end conftest;
2078 end ConfPackage;
2079 CF_EOF
2080                 if ( $cf_ada_make $ADAFLAGS \
2081                                 -Plibrary.gpr \
2082                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2083                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2084                                 -XSOURCE_DIR=`pwd` \
2085                                 -XSONAME=libConfTest.so.1 \
2086                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2087                         cf_gnat_projects=yes
2088                 fi
2089                 cd ..
2090                 if test -f conftest.lib/confpackage.ali
2091                 then
2092                         cf_gnat_libraries=yes
2093                 fi
2094                 rm -rf conftest* *~conftest*
2095                 ;;
2096         esac
2097         ;;
2098 esac
2099 AC_MSG_RESULT($cf_gnat_projects)
2100
2101 if test $cf_gnat_projects = yes
2102 then
2103         AC_MSG_CHECKING(if GNAT supports libraries)
2104         AC_MSG_RESULT($cf_gnat_libraries)
2105 fi
2106
2107 if test "$cf_gnat_projects" = yes
2108 then
2109         USE_OLD_MAKERULES="#"
2110         USE_GNAT_PROJECTS=""
2111 else
2112         USE_OLD_MAKERULES=""
2113         USE_GNAT_PROJECTS="#"
2114 fi
2115
2116 if test "$cf_gnat_libraries" = yes
2117 then
2118         USE_GNAT_LIBRARIES=""
2119 else
2120         USE_GNAT_LIBRARIES="#"
2121 fi
2122
2123 AC_SUBST(USE_OLD_MAKERULES)
2124 AC_SUBST(USE_GNAT_PROJECTS)
2125 AC_SUBST(USE_GNAT_LIBRARIES)
2126 ])dnl
2127 dnl ---------------------------------------------------------------------------
2128 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2129 dnl --------------
2130 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2131 dnl is noted that gnat may compile a tasking unit even for configurations which
2132 dnl fail at runtime.
2133 AC_DEFUN([CF_GNAT_SIGINT],[
2134 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2135 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2136
2137 package ConfTest is
2138
2139    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2140    pragma Unreserve_All_Interrupts;
2141    pragma Warnings (On);
2142
2143    protected Process is
2144       procedure Stop;
2145       function Continue return Boolean;
2146       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2147    private
2148       Done : Boolean := False;
2149    end Process;
2150
2151 end ConfTest;],
2152 [package body ConfTest is
2153    protected body Process is
2154       procedure Stop is
2155       begin
2156          Done := True;
2157       end Stop;
2158       function Continue return Boolean is
2159       begin
2160          return not Done;
2161       end Continue;
2162    end Process;
2163 end ConfTest;],
2164         [cf_cv_gnat_sigint=yes],
2165         [cf_cv_gnat_sigint=no])])
2166
2167 if test $cf_cv_gnat_sigint = yes ; then
2168         USE_GNAT_SIGINT=""
2169 else
2170         USE_GNAT_SIGINT="#"
2171 fi
2172 AC_SUBST(USE_GNAT_SIGINT)
2173 ])dnl
2174 dnl ---------------------------------------------------------------------------
2175 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2176 dnl ----------------
2177 dnl Verify that a test program compiles/links with GNAT.
2178 dnl $cf_ada_make is set to the program that compiles/links
2179 dnl $ADAFLAGS may be set to the GNAT flags.
2180 dnl
2181 dnl $1 is the text of the spec
2182 dnl $2 is the text of the body
2183 dnl $3 is the shell command to execute if successful
2184 dnl $4 is the shell command to execute if not successful
2185 AC_DEFUN([CF_GNAT_TRY_LINK],
2186 [
2187 rm -rf conftest* *~conftest*
2188 cat >>conftest.ads <<CF_EOF
2189 $1
2190 CF_EOF
2191 cat >>conftest.adb <<CF_EOF
2192 $2
2193 CF_EOF
2194 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2195 ifelse($3,,      :,[      $3])
2196 ifelse($4,,,[else
2197    $4])
2198 fi
2199 rm -rf conftest* *~conftest*
2200 ])dnl
2201 dnl ---------------------------------------------------------------------------
2202 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2203 dnl ---------------
2204 dnl Verify that a test program compiles and runs with GNAT
2205 dnl $cf_ada_make is set to the program that compiles/links
2206 dnl $ADAFLAGS may be set to the GNAT flags.
2207 dnl
2208 dnl $1 is the text of the spec
2209 dnl $2 is the text of the body
2210 dnl $3 is the shell command to execute if successful
2211 dnl $4 is the shell command to execute if not successful
2212 AC_DEFUN([CF_GNAT_TRY_RUN],
2213 [
2214 rm -rf conftest* *~conftest*
2215 cat >>conftest.ads <<CF_EOF
2216 $1
2217 CF_EOF
2218 cat >>conftest.adb <<CF_EOF
2219 $2
2220 CF_EOF
2221 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2222    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2223 ifelse($3,,      :,[      $3])
2224 ifelse($4,,,[   else
2225       $4])
2226    fi
2227 ifelse($4,,,[else
2228    $4])
2229 fi
2230 rm -rf conftest* *~conftest*
2231 ])dnl
2232 dnl ---------------------------------------------------------------------------
2233 dnl CF_GNAT_VERSION version: 17 updated: 2011/03/23 20:24:41
2234 dnl ---------------
2235 dnl Verify version of GNAT.
2236 AC_DEFUN([CF_GNAT_VERSION],
2237 [
2238 AC_MSG_CHECKING(for gnat version)
2239 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2240         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2241     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2242 AC_MSG_RESULT($cf_gnat_version)
2243
2244 case $cf_gnat_version in #(vi
2245 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*) #(vi
2246         cf_cv_prog_gnat_correct=yes
2247         ;;
2248 *)
2249         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2250         cf_cv_prog_gnat_correct=no
2251         ;;
2252 esac
2253 ])
2254 dnl ---------------------------------------------------------------------------
2255 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2256 dnl -------------
2257 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2258 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2259 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2260 dnl since it is interwoven with GNU extensions.
2261 dnl
2262 dnl Well, yes we could work around it...
2263 AC_DEFUN([CF_GNU_SOURCE],
2264 [
2265 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2266 AC_TRY_COMPILE([#include <sys/types.h>],[
2267 #ifndef _XOPEN_SOURCE
2268 make an error
2269 #endif],
2270         [cf_cv_gnu_source=no],
2271         [cf_save="$CPPFLAGS"
2272          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2273          AC_TRY_COMPILE([#include <sys/types.h>],[
2274 #ifdef _XOPEN_SOURCE
2275 make an error
2276 #endif],
2277         [cf_cv_gnu_source=no],
2278         [cf_cv_gnu_source=yes])
2279         CPPFLAGS="$cf_save"
2280         ])
2281 ])
2282 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2283 ])dnl
2284 dnl ---------------------------------------------------------------------------
2285 dnl CF_GPP_LIBRARY version: 10 updated: 2010/05/29 16:31:02
2286 dnl --------------
2287 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2288 dnl problem :-).  If we have the compiler but no library, we'll be able to
2289 dnl configure, but won't be able to build the c++ demo program.
2290 AC_DEFUN([CF_GPP_LIBRARY],
2291 [
2292 cf_cxx_library=unknown
2293 case $cf_cv_system_name in #(vi
2294 os2*) #(vi
2295         cf_gpp_libname=gpp
2296         ;;
2297 *)
2298         cf_gpp_libname=g++
2299         ;;
2300 esac
2301 if test "$GXX" = yes; then
2302         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2303         cf_save="$LIBS"
2304         CF_ADD_LIB($cf_gpp_libname)
2305         AC_TRY_LINK([
2306 #include <$cf_gpp_libname/builtin.h>
2307         ],
2308         [two_arg_error_handler_t foo2 = lib_error_handler],
2309         [cf_cxx_library=yes
2310          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2311          if test "$cf_gpp_libname" = cpp ; then
2312             AC_DEFINE(HAVE_GPP_BUILTIN_H)
2313          else
2314             AC_DEFINE(HAVE_GXX_BUILTIN_H)
2315          fi],
2316         [AC_TRY_LINK([
2317 #include <builtin.h>
2318         ],
2319         [two_arg_error_handler_t foo2 = lib_error_handler],
2320         [cf_cxx_library=yes
2321          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2322          AC_DEFINE(HAVE_BUILTIN_H)],
2323         [cf_cxx_library=no])])
2324         LIBS="$cf_save"
2325         AC_MSG_RESULT($cf_cxx_library)
2326 fi
2327 ])dnl
2328 dnl ---------------------------------------------------------------------------
2329 dnl CF_GXX_VERSION version: 6 updated: 2010/10/23 15:44:18
2330 dnl --------------
2331 dnl Check for version of g++
2332 AC_DEFUN([CF_GXX_VERSION],[
2333 AC_REQUIRE([AC_PROG_CPP])
2334 GXX_VERSION=none
2335 if test "$GXX" = yes; then
2336         AC_MSG_CHECKING(version of g++)
2337         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2338         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2339         AC_MSG_RESULT($GXX_VERSION)
2340 fi
2341 ])dnl
2342 dnl ---------------------------------------------------------------------------
2343 dnl CF_GXX_WARNINGS version: 6 updated: 2010/08/14 18:25:37
2344 dnl ---------------
2345 dnl Check if the compiler supports useful warning options.
2346 dnl
2347 dnl Most of gcc's options apply to g++, except:
2348 dnl     -Wbad-function-cast
2349 dnl     -Wmissing-declarations
2350 dnl     -Wnested-externs
2351 dnl
2352 dnl Omit a few (for now):
2353 dnl     -Winline
2354 dnl
2355 dnl Parameter:
2356 dnl     $1 is an optional list of g++ warning flags that a particular
2357 dnl             application might want to use, e.g., "no-unused" for
2358 dnl             -Wno-unused
2359 dnl Special:
2360 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2361 dnl
2362 AC_DEFUN([CF_GXX_WARNINGS],
2363 [
2364
2365 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2366
2367 AC_REQUIRE([CF_GXX_VERSION])
2368
2369 AC_LANG_SAVE
2370 AC_LANG_CPLUSPLUS
2371
2372 cat > conftest.$ac_ext <<EOF
2373 #line __oline__ "configure"
2374 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2375 EOF
2376
2377 if test "$INTEL_CPLUSPLUS" = yes
2378 then
2379 # The "-wdXXX" options suppress warnings:
2380 # remark #1419: external declaration in primary source file
2381 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2382 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2383 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2384 # remark #193: zero used for undefined preprocessing identifier
2385 # remark #593: variable "curs_sb_left_arrow" was set but never used
2386 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2387 # remark #869: parameter "tw" was never referenced
2388 # remark #981: operands are evaluated in unspecified order
2389 # warning #269: invalid format string conversion
2390
2391         AC_CHECKING([for $CC warning options])
2392         cf_save_CXXFLAGS="$CXXFLAGS"
2393         EXTRA_CXXFLAGS="-Wall"
2394         for cf_opt in \
2395                 wd1419 \
2396                 wd1682 \
2397                 wd1683 \
2398                 wd1684 \
2399                 wd193 \
2400                 wd279 \
2401                 wd593 \
2402                 wd810 \
2403                 wd869 \
2404                 wd981
2405         do
2406                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2407                 if AC_TRY_EVAL(ac_compile); then
2408                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2409                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2410                 fi
2411         done
2412         CXXFLAGS="$cf_save_CXXFLAGS"
2413
2414 elif test "$GXX" = yes
2415 then
2416         AC_CHECKING([for $CXX warning options])
2417         cf_save_CXXFLAGS="$CXXFLAGS"
2418         EXTRA_CXXFLAGS="-W -Wall"
2419         cf_gxx_extra_warnings=""
2420         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2421         case "$GCC_VERSION" in
2422         [[1-2]].*)
2423                 ;;
2424         *)
2425                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2426                 ;;
2427         esac
2428         for cf_opt in \
2429                 Wabi \
2430                 fabi-version=0 \
2431                 Woverloaded-virtual \
2432                 Wsign-promo \
2433                 Wsynth \
2434                 Wold-style-cast \
2435                 Wcast-align \
2436                 Wcast-qual \
2437                 Wmissing-prototypes \
2438                 Wpointer-arith \
2439                 Wshadow \
2440                 Wstrict-prototypes \
2441                 Wundef $cf_gxx_extra_warnings $1
2442         do
2443                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2444                 if AC_TRY_EVAL(ac_compile); then
2445                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2446                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2447                 else
2448                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2449                 fi
2450         done
2451         CXXFLAGS="$cf_save_CXXFLAGS"
2452 fi
2453
2454 rm -rf conftest*
2455 AC_LANG_RESTORE
2456 AC_SUBST(EXTRA_CXXFLAGS)
2457 ])dnl
2458 dnl ---------------------------------------------------------------------------
2459 dnl CF_HASHED_DB version: 4 updated: 2010/05/29 16:31:02
2460 dnl ------------
2461 dnl Look for an instance of the Berkeley hashed database.
2462 dnl
2463 dnl $1 = optional parameter, to specify install-prefix for the database.
2464 AC_DEFUN([CF_HASHED_DB],
2465 [
2466 ifelse([$1],,,[
2467 case $1 in #(vi
2468 yes|*able*) #(vi
2469     ;;
2470 *)
2471     if test -d "$1" ; then
2472         CF_ADD_INCDIR($1/include)
2473         CF_ADD_LIBDIR($1/lib)
2474     fi
2475 esac
2476 ])
2477 AC_CHECK_HEADER(db.h,[
2478 CF_HASHED_DB_VERSION
2479 if test "$cf_cv_hashed_db_version" = unknown ; then
2480         AC_MSG_ERROR(Cannot determine version of db)
2481 else
2482         CF_HASHED_DB_LIBS
2483         if test "$cf_cv_hashed_db_libs" = unknown ; then
2484                 AC_MSG_ERROR(Cannot determine library for db)
2485         elif test "$cf_cv_hashed_db_libs" != default ; then
2486                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2487         fi
2488 fi
2489 ],[
2490         AC_MSG_ERROR(Cannot find db.h)
2491 ])
2492 ])dnl
2493 dnl ---------------------------------------------------------------------------
2494 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2495 dnl -----------------
2496 dnl Given that we have the header and version for hashed database, find the
2497 dnl library information.
2498 AC_DEFUN([CF_HASHED_DB_LIBS],
2499 [
2500 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2501 cf_cv_hashed_db_libs=unknown
2502 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2503 do
2504         cf_save_libs="$LIBS"
2505         if test -n "$cf_db_libs"; then
2506                 CF_ADD_LIB($cf_db_libs)
2507         fi
2508         CF_MSG_LOG(checking for library "$cf_db_libs")
2509         AC_TRY_LINK([
2510 $ac_includes_default
2511 #include <db.h>
2512 ],[
2513         char *path = "/tmp/foo";
2514 #ifdef DB_VERSION_MAJOR
2515 #if DB_VERSION_MAJOR >= 4
2516         DB *result = 0;
2517         db_create(&result, NULL, 0);
2518         result->open(result,
2519                 NULL,
2520                 path,
2521                 path,
2522                 DB_HASH,
2523                 DB_CREATE,
2524                 0644);
2525 #elif DB_VERSION_MAJOR >= 3
2526         DB *result = 0;
2527         db_create(&result, NULL, 0);
2528         result->open(result,
2529                 path,
2530                 path,
2531                 DB_HASH,
2532                 DB_CREATE,
2533                 0644);
2534 #elif DB_VERSION_MAJOR >= 2
2535         DB *result = 0;
2536         db_open(path,
2537                 DB_HASH,
2538                 DB_CREATE,
2539                 0644,
2540                 (DB_ENV *) 0,
2541                 (DB_INFO *) 0,
2542                 &result);
2543 #endif /* DB_VERSION_MAJOR */
2544 #else
2545         DB *result = dbopen(path,
2546                      2,
2547                      0644,
2548                      DB_HASH,
2549                      0);
2550 #endif
2551         ${cf_cv_main_return:-return}(result != 0)
2552 ],[
2553         if test -n "$cf_db_libs" ; then
2554                 cf_cv_hashed_db_libs=$cf_db_libs
2555         else
2556                 cf_cv_hashed_db_libs=default
2557         fi
2558         LIBS="$cf_save_libs"
2559         break
2560 ])
2561         LIBS="$cf_save_libs"
2562 done
2563 ])
2564 ])dnl
2565 dnl ---------------------------------------------------------------------------
2566 dnl CF_HASHED_DB_VERSION version: 3 updated: 2007/12/01 15:01:37
2567 dnl --------------------
2568 dnl Given that we have the header file for hashed database, find the version
2569 dnl information.
2570 AC_DEFUN([CF_HASHED_DB_VERSION],
2571 [
2572 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2573 cf_cv_hashed_db_version=unknown
2574
2575 for cf_db_version in 1 2 3 4 5
2576 do
2577         CF_MSG_LOG(checking for db version $cf_db_version)
2578         AC_TRY_COMPILE([
2579 $ac_includes_default
2580 #include <db.h>
2581
2582 #ifdef DB_VERSION_MAJOR
2583         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2584 #if $cf_db_version == DB_VERSION_MAJOR
2585         /* ok */
2586 #else
2587         make an error
2588 #endif
2589 #else
2590 #if $cf_db_version == 1
2591         /* ok: assuming this is DB 1.8.5 */
2592 #else
2593         make an error
2594 #endif
2595 #endif
2596 ],[DBT *foo = 0],[
2597         cf_cv_hashed_db_version=$cf_db_version
2598         break
2599         ])
2600 done
2601 ])
2602 ])dnl
2603 dnl ---------------------------------------------------------------------------
2604 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2605 dnl --------------
2606 dnl Construct a search-list of directories for a nonstandard header-file
2607 dnl
2608 dnl Parameters
2609 dnl     $1 = the variable to return as result
2610 dnl     $2 = the package name
2611 AC_DEFUN([CF_HEADER_PATH],
2612 [
2613 $1=
2614
2615 # collect the current set of include-directories from compiler flags
2616 cf_header_path_list=""
2617 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2618         for cf_header_path in $CPPFLAGS $CFLAGS
2619         do
2620                 case $cf_header_path in #(vi
2621                 -I*)
2622                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2623                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2624                         cf_header_path_list="$cf_header_path_list [$]$1"
2625                         ;;
2626                 esac
2627         done
2628 fi
2629
2630 # add the variations for the package we are looking for
2631 CF_SUBDIR_PATH($1,$2,include)
2632
2633 test "$includedir" != NONE && \
2634 test "$includedir" != "/usr/include" && \
2635 test -d "$includedir" && {
2636         test -d $includedir &&    $1="[$]$1 $includedir"
2637         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2638 }
2639
2640 test "$oldincludedir" != NONE && \
2641 test "$oldincludedir" != "/usr/include" && \
2642 test -d "$oldincludedir" && {
2643         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2644         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2645 }
2646
2647 $1="[$]$1 $cf_header_path_list"
2648 ])dnl
2649 dnl ---------------------------------------------------------------------------
2650 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2651 dnl ---------------
2652 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2653 AC_DEFUN([CF_HELP_MESSAGE],
2654 [AC_DIVERT_HELP([$1])dnl
2655 ])dnl
2656 dnl ---------------------------------------------------------------------------
2657 dnl CF_INCLUDE_DIRS version: 6 updated: 2009/01/06 19:37:40
2658 dnl ---------------
2659 dnl Construct the list of include-options according to whether we're building
2660 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2661 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2662 dnl since that usually breaks gcc's shadow-includes.
2663 AC_DEFUN([CF_INCLUDE_DIRS],
2664 [
2665 CPPFLAGS="$CPPFLAGS -I. -I../include"
2666 if test "$srcdir" != "."; then
2667         CPPFLAGS="$CPPFLAGS -I\${srcdir}/../include"
2668 fi
2669 if test "$GCC" != yes; then
2670         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2671 elif test "$includedir" != "/usr/include"; then
2672         if test "$includedir" = '${prefix}/include' ; then
2673                 if test $prefix != /usr ; then
2674                         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2675                 fi
2676         else
2677                 CPPFLAGS="$CPPFLAGS -I\${includedir}"
2678         fi
2679 fi
2680 AC_SUBST(CPPFLAGS)
2681 ])dnl
2682 dnl ---------------------------------------------------------------------------
2683 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
2684 dnl -----------------
2685 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2686 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2687 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2688 dnl
2689 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2690 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2691 dnl the wrappers for gcc and g++ warnings.
2692 dnl
2693 dnl $1 = GCC (default) or GXX
2694 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2695 dnl $3 = CFLAGS (default) or CXXFLAGS
2696 AC_DEFUN([CF_INTEL_COMPILER],[
2697 ifelse([$2],,INTEL_COMPILER,[$2])=no
2698
2699 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2700         case $host_os in
2701         linux*|gnu*)
2702                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2703                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2704                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2705                 AC_TRY_COMPILE([],[
2706 #ifdef __INTEL_COMPILER
2707 #else
2708 make an error
2709 #endif
2710 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2711 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
2712 ],[])
2713                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2714                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2715                 ;;
2716         esac
2717 fi
2718 ])dnl
2719 dnl ---------------------------------------------------------------------------
2720 dnl CF_ISASCII version: 3 updated: 2000/08/12 23:18:52
2721 dnl ----------
2722 dnl Check if we have either a function or macro for 'isascii()'.
2723 AC_DEFUN([CF_ISASCII],
2724 [
2725 AC_MSG_CHECKING(for isascii)
2726 AC_CACHE_VAL(cf_cv_have_isascii,[
2727         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2728         [cf_cv_have_isascii=yes],
2729         [cf_cv_have_isascii=no])
2730 ])dnl
2731 AC_MSG_RESULT($cf_cv_have_isascii)
2732 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII)
2733 ])dnl
2734 dnl ---------------------------------------------------------------------------
2735 dnl CF_LARGEFILE version: 7 updated: 2007/06/02 11:58:50
2736 dnl ------------
2737 dnl Add checks for large file support.
2738 AC_DEFUN([CF_LARGEFILE],[
2739 ifdef([AC_FUNC_FSEEKO],[
2740     AC_SYS_LARGEFILE
2741     if test "$enable_largefile" != no ; then
2742         AC_FUNC_FSEEKO
2743
2744         # Normally we would collect these definitions in the config.h,
2745         # but (like _XOPEN_SOURCE), some environments rely on having these
2746         # defined before any of the system headers are included.  Another
2747         # case comes up with C++, e.g., on AIX the compiler compiles the
2748         # header files by themselves before looking at the body files it is
2749         # told to compile.  For ncurses, those header files do not include
2750         # the config.h
2751         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2752         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2753         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2754
2755         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2756                 AC_TRY_COMPILE([
2757 #include <sys/types.h>
2758 #include <dirent.h>
2759                 ],[
2760                 /* if transitional largefile support is setup, this is true */
2761                 extern struct dirent64 * readdir(DIR *);
2762                 struct dirent64 *x = readdir((DIR *)0);
2763                 struct dirent *y = readdir((DIR *)0);
2764                 int z = x - y;
2765                 ],
2766                 [cf_cv_struct_dirent64=yes],
2767                 [cf_cv_struct_dirent64=no])
2768         ])
2769         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64)
2770     fi
2771 ])
2772 ])
2773 dnl ---------------------------------------------------------------------------
2774 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2775 dnl -----------------
2776 dnl Check for compiler/linker flags used to temporarily force usage of static
2777 dnl libraries.  This depends on the compiler and platform.  Use this to help
2778 dnl ensure that the linker picks up a given library based on its position in
2779 dnl the list of linker options and libraries.
2780 AC_DEFUN([CF_LDFLAGS_STATIC],[
2781
2782 if test "$GCC" = yes ; then
2783         case $cf_cv_system_name in #(
2784         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2785                 LDFLAGS_STATIC=
2786                 LDFLAGS_SHARED=
2787                 ;;
2788     *)  #( normally, except when broken
2789         LDFLAGS_STATIC=-static
2790         LDFLAGS_SHARED=-dynamic
2791         ;;
2792     esac
2793 else
2794         case $cf_cv_system_name in #(
2795         aix[[4-7]]*)    #( from ld manpage
2796                 LDFLAGS_STATIC=-bstatic
2797                 LDFLAGS_SHARED=-bdynamic
2798                 ;;
2799         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2800                 # We could also use just "archive" and "shared".
2801                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2802                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2803                 ;;
2804         irix*)          #( from ld manpage IRIX64
2805                 LDFLAGS_STATIC=-Bstatic
2806                 LDFLAGS_SHARED=-Bdynamic
2807                 ;;
2808         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2809                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2810                 LDFLAGS_STATIC=-noso
2811                 LDFLAGS_SHARED=-so_archive
2812                 ;;
2813         solaris2*)
2814                 LDFLAGS_STATIC=-Bstatic
2815                 LDFLAGS_SHARED=-Bdynamic
2816                 ;;
2817         esac
2818 fi
2819
2820 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
2821 then
2822         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
2823
2824         rm -f libconftest.a
2825         cat >conftest.$ac_ext <<EOF
2826 #line __oline__ "configure"
2827 #include <stdio.h>
2828 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
2829 EOF
2830         if AC_TRY_EVAL(ac_compile) ; then
2831                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
2832                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
2833         fi
2834         rm -f conftest.*
2835
2836         cf_save_LIBS="$LIBS"
2837
2838         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
2839         AC_TRY_LINK([
2840 #line __oline__ "configure"
2841 #include <stdio.h>
2842 int cf_ldflags_static(FILE *fp);
2843 ],[
2844         return cf_ldflags_static(stdin);
2845 ],[
2846         # some linkers simply ignore the -dynamic
2847         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
2848         *static*) # (vi
2849                 cf_ldflags_static=no
2850                 ;;
2851         *)
2852                 cf_ldflags_static=yes
2853                 ;;
2854         esac
2855 ],[cf_ldflags_static=no])
2856
2857         rm -f libconftest.*
2858         LIBS="$cf_save_LIBS"
2859
2860         AC_MSG_RESULT($cf_ldflags_static)
2861
2862         if test $cf_ldflags_static != yes
2863         then
2864                 LDFLAGS_STATIC=
2865                 LDFLAGS_SHARED=
2866         fi
2867 else
2868         LDFLAGS_STATIC=
2869         LDFLAGS_SHARED=
2870 fi
2871
2872 AC_SUBST(LDFLAGS_STATIC)
2873 AC_SUBST(LDFLAGS_SHARED)
2874 ])
2875 dnl ---------------------------------------------------------------------------
2876 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
2877 dnl ---------------
2878 dnl For the given system and compiler, find the compiler flags to pass to the
2879 dnl loader to use the "rpath" feature.
2880 AC_DEFUN([CF_LD_RPATH_OPT],
2881 [
2882 AC_REQUIRE([CF_CHECK_CACHE])
2883
2884 LD_RPATH_OPT=
2885 AC_MSG_CHECKING(for an rpath option)
2886 case $cf_cv_system_name in #(vi
2887 irix*) #(vi
2888         if test "$GCC" = yes; then
2889                 LD_RPATH_OPT="-Wl,-rpath,"
2890         else
2891                 LD_RPATH_OPT="-rpath "
2892         fi
2893         ;;
2894 linux*|gnu*|k*bsd*-gnu) #(vi
2895         LD_RPATH_OPT="-Wl,-rpath,"
2896         ;;
2897 openbsd[[2-9]].*|mirbsd*) #(vi
2898         LD_RPATH_OPT="-Wl,-rpath,"
2899         ;;
2900 dragonfly*|freebsd*) #(vi
2901         LD_RPATH_OPT="-rpath "
2902         ;;
2903 netbsd*) #(vi
2904         LD_RPATH_OPT="-Wl,-rpath,"
2905         ;;
2906 osf*|mls+*) #(vi
2907         LD_RPATH_OPT="-rpath "
2908         ;;
2909 solaris2*) #(vi
2910         LD_RPATH_OPT="-R"
2911         ;;
2912 *)
2913         ;;
2914 esac
2915 AC_MSG_RESULT($LD_RPATH_OPT)
2916
2917 case "x$LD_RPATH_OPT" in #(vi
2918 x-R*)
2919         AC_MSG_CHECKING(if we need a space after rpath option)
2920         cf_save_LIBS="$LIBS"
2921         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2922         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2923         LIBS="$cf_save_LIBS"
2924         AC_MSG_RESULT($cf_rpath_space)
2925         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2926         ;;
2927 esac
2928 ])dnl
2929 dnl ---------------------------------------------------------------------------
2930 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
2931 dnl ---------------
2932 dnl Construct a search-list of directories for a nonstandard library-file
2933 dnl
2934 dnl Parameters
2935 dnl     $1 = the variable to return as result
2936 dnl     $2 = the package name
2937 AC_DEFUN([CF_LIBRARY_PATH],
2938 [
2939 $1=
2940 cf_library_path_list=""
2941 if test -n "${LDFLAGS}${LIBS}" ; then
2942         for cf_library_path in $LDFLAGS $LIBS
2943         do
2944                 case $cf_library_path in #(vi
2945                 -L*)
2946                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2947                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2948                         cf_library_path_list="$cf_library_path_list [$]$1"
2949                         ;;
2950                 esac
2951         done
2952 fi
2953
2954 CF_SUBDIR_PATH($1,$2,lib)
2955
2956 $1="$cf_library_path_list [$]$1"
2957 ])dnl
2958 dnl ---------------------------------------------------------------------------
2959 dnl CF_LIB_PREFIX version: 8 updated: 2008/09/13 11:34:16
2960 dnl -------------
2961 dnl Compute the library-prefix for the given host system
2962 dnl $1 = variable to set
2963 AC_DEFUN([CF_LIB_PREFIX],
2964 [
2965         case $cf_cv_system_name in #(vi
2966         OS/2*|os2*) #(vi
2967         LIB_PREFIX=''
2968         ;;
2969         *)      LIB_PREFIX='lib'
2970         ;;
2971         esac
2972 ifelse($1,,,[$1=$LIB_PREFIX])
2973         AC_SUBST(LIB_PREFIX)
2974 ])dnl
2975 dnl ---------------------------------------------------------------------------
2976 dnl CF_LIB_RULES version: 61 updated: 2010/10/23 16:10:30
2977 dnl ------------
2978 dnl Append definitions and rules for the given models to the subdirectory
2979 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
2980 dnl subdirectory is a library-source directory, modify the LIBS_TO_MAKE list in
2981 dnl the corresponding makefile to list the models that we'll generate.
2982 dnl
2983 dnl For shared libraries, make a list of symbolic links to construct when
2984 dnl generating each library.  The convention used for Linux is the simplest
2985 dnl one:
2986 dnl     lib<name>.so    ->
2987 dnl     lib<name>.so.<major>    ->
2988 dnl     lib<name>.so.<maj>.<minor>
2989 AC_DEFUN([CF_LIB_RULES],
2990 [
2991 CF_LIB_PREFIX(cf_prefix)
2992 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
2993
2994 if test $cf_cv_shlib_version = cygdll ; then
2995         TINFO_NAME=$TINFO_ARG_SUFFIX
2996         TINFO_SUFFIX=.dll
2997 fi
2998
2999 if test -n "$TINFO_SUFFIX" ; then
3000         case $TINFO_SUFFIX in
3001         tw*)
3002                 TINFO_NAME="${TINFO_NAME}tw"
3003                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
3004                 ;;
3005         t*)
3006                 TINFO_NAME="${TINFO_NAME}t"
3007                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3008                 ;;
3009         w*)
3010                 TINFO_NAME="${TINFO_NAME}w"
3011                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3012                 ;;
3013         esac
3014 fi
3015
3016 for cf_dir in $SRC_SUBDIRS
3017 do
3018         if test ! -d $srcdir/$cf_dir ; then
3019                 continue
3020         elif test -f $srcdir/$cf_dir/modules; then
3021
3022                 SHARED_LIB=
3023                 LIBS_TO_MAKE=
3024                 for cf_item in $cf_LIST_MODELS
3025                 do
3026                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3027                         if test $cf_item = shared ; then
3028                         if test "$cf_cv_do_symlinks" = yes ; then
3029                                 case "$cf_cv_shlib_version" in #(vi
3030                                 rel) #(vi
3031                                         case "$cf_cv_system_name" in #(vi
3032                                         darwin*)
3033                                         case .${LIB_SUFFIX} in
3034                                         .tw*)
3035                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3036                                                 cf_suffix=tw'.${REL_VERSION}'"$cf_suffix"
3037                                                 ;;
3038                                         .t*)
3039                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3040                                                 cf_suffix=t'.${REL_VERSION}'"$cf_suffix"
3041                                                 ;;
3042                                         .w*)
3043                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3044                                                 cf_suffix=w'.${REL_VERSION}'"$cf_suffix"
3045                                                 ;;
3046                                         *)
3047                                                 cf_suffix='.${REL_VERSION}'"$cf_suffix"
3048                                                 ;;
3049                                         esac
3050                                         ;; #(vi
3051                                         *) cf_suffix="$cf_suffix"'.${REL_VERSION}' ;;
3052                                         esac
3053                                         ;;
3054                                 abi)
3055                                         case "$cf_cv_system_name" in #(vi
3056                                         darwin*)
3057                                         case .${LIB_SUFFIX} in
3058                                         .tw*)
3059                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3060                                                 cf_suffix=tw'.${ABI_VERSION}'"$cf_suffix"
3061                                                 ;;
3062                                         .t*)
3063                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3064                                                 cf_suffix=t'.${ABI_VERSION}'"$cf_suffix"
3065                                                 ;;
3066                                         .w*)
3067                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3068                                                 cf_suffix=w'.${ABI_VERSION}'"$cf_suffix"
3069                                                 ;;
3070                                         *)
3071                                                 cf_suffix='.${ABI_VERSION}'"$cf_suffix"
3072                                                 ;;
3073                                         esac
3074                                         ;; #(vi
3075                                         *) cf_suffix="$cf_suffix"'.${ABI_VERSION}' ;;
3076                                         esac
3077                                         ;;
3078                                 esac
3079                         fi
3080                         # cygwin needs import library, and has unique naming convention
3081                         # use autodetected ${cf_prefix} for import lib and static lib, but
3082                         # use 'cyg' prefix for shared lib.
3083                         if test $cf_cv_shlib_version = cygdll ; then
3084                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3085                                 LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/cyg${cf_dir}${cf_cygsuf}"
3086                                 continue
3087                         fi
3088                         fi
3089                         LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/${cf_prefix}${cf_dir}${cf_suffix}"
3090                 done
3091
3092                 if test $cf_dir = ncurses ; then
3093                         cf_subsets="$LIB_SUBSETS"
3094                         cf_r_parts="$cf_subsets"
3095                         cf_liblist="$LIBS_TO_MAKE"
3096
3097                         while test -n "$cf_r_parts"
3098                         do
3099                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3100                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3101                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3102                                         cf_item=
3103                                         case $cf_l_parts in #(vi
3104                                         *termlib*) #(vi
3105                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3106                                                 ;;
3107                                         *ticlib*)
3108                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3109                                                 ;;
3110                                         *)
3111                                                 break
3112                                                 ;;
3113                                         esac
3114                                         if test -n "$cf_item"; then
3115                                                 LIBS_TO_MAKE="$cf_item $LIBS_TO_MAKE"
3116                                         fi
3117                                 else
3118                                         break
3119                                 fi
3120                         done
3121                 else
3122                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3123                 fi
3124
3125                 sed -e "s%@LIBS_TO_MAKE@%$LIBS_TO_MAKE%" \
3126                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3127                         $cf_dir/Makefile >$cf_dir/Makefile.out
3128                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3129
3130                 $AWK -f $srcdir/mk-0th.awk \
3131                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" \
3132                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3133
3134                 for cf_subset in $cf_subsets
3135                 do
3136                         cf_subdirs=
3137                         for cf_item in $cf_LIST_MODELS
3138                         do
3139                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3140                         CF_UPPER(cf_ITEM,$cf_item)
3141                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3142                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3143
3144                         # Test for case where we build libtinfo with a different name.
3145                         cf_libname=$cf_dir
3146                         if test $cf_dir = ncurses ; then
3147                                 case $cf_subset in
3148                                 *base*)
3149                                         cf_libname=${cf_libname}$LIB_SUFFIX
3150                                         ;;
3151                                 *termlib*)
3152                                         cf_libname=$TINFO_LIB_SUFFIX
3153                                         ;;
3154                                 ticlib*)
3155                                         cf_libname=$TICS_LIB_SUFFIX
3156                                         ;;
3157                                 esac
3158                         else
3159                                 cf_libname=${cf_libname}$LIB_SUFFIX
3160                         fi
3161                         if test -n "${DFT_ARG_SUFFIX}" ; then
3162                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3163                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3164                         fi
3165
3166                         # These dependencies really are for development, not
3167                         # builds, but they are useful in porting, too.
3168                         cf_depend="../include/ncurses_cfg.h"
3169                         if test "$srcdir" = "."; then
3170                                 cf_reldir="."
3171                         else
3172                                 cf_reldir="\${srcdir}"
3173                         fi
3174
3175                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3176                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3177                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3178                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3179                         fi
3180
3181                         cf_dir_suffix=
3182                         old_cf_suffix="$cf_suffix"
3183                         if test "$cf_cv_shlib_version_infix" = yes ; then
3184                         if test -n "$LIB_SUFFIX" ; then
3185                                 case $LIB_SUFFIX in
3186                                 tw*)
3187                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3188                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3189                                         cf_dir_suffix=tw
3190                                         ;;
3191                                 t*)
3192                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3193                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3194                                         cf_dir_suffix=t
3195                                         ;;
3196                                 w*)
3197                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3198                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3199                                         cf_dir_suffix=w
3200                                         ;;
3201                                 esac
3202                         fi
3203                         fi
3204
3205                         $AWK -f $srcdir/mk-1st.awk \
3206                                 name=${cf_libname}${cf_dir_suffix} \
3207                                 traces=$LIB_TRACING \
3208                                 MODEL=$cf_ITEM \
3209                                 model=$cf_subdir \
3210                                 prefix=$cf_prefix \
3211                                 suffix=$cf_suffix \
3212                                 subset=$cf_subset \
3213                                 SymLink="$LN_S" \
3214                                 TermlibRoot=$TINFO_NAME \
3215                                 TermlibSuffix=$TINFO_SUFFIX \
3216                                 ShlibVer=$cf_cv_shlib_version \
3217                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3218                                 ReLink=${cf_cv_do_relink:-no} \
3219                                 DoLinks=$cf_cv_do_symlinks \
3220                                 rmSoLocs=$cf_cv_rm_so_locs \
3221                                 ldconfig="$LDCONFIG" \
3222                                 overwrite=$WITH_OVERWRITE \
3223                                 depend="$cf_depend" \
3224                                 host="$host" \
3225                                 libtool_version="$LIBTOOL_VERSION" \
3226                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3227
3228                         cf_suffix="$old_cf_suffix"
3229
3230                         for cf_subdir2 in $cf_subdirs lib
3231                         do
3232                                 test $cf_subdir = $cf_subdir2 && break
3233                         done
3234                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3235                         $AWK -f $srcdir/mk-2nd.awk \
3236                                 name=$cf_dir \
3237                                 traces=$LIB_TRACING \
3238                                 MODEL=$cf_ITEM \
3239                                 model=$cf_subdir \
3240                                 subset=$cf_subset \
3241                                 srcdir=$srcdir \
3242                                 echo=$WITH_ECHO \
3243                                 crenames=$cf_cv_prog_CC_c_o \
3244                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3245                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3246                         cf_subdirs="$cf_subdirs $cf_subdir"
3247                         done
3248                 done
3249         fi
3250
3251         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >>Makefile
3252 done
3253
3254 for cf_dir in $SRC_SUBDIRS
3255 do
3256         if test ! -d $srcdir/$cf_dir ; then
3257                 continue
3258         fi
3259
3260         if test -f $cf_dir/Makefile ; then
3261                 case "$cf_dir" in
3262                 Ada95) #(vi
3263                         echo 'libs \' >> Makefile
3264                         echo 'install.libs \' >> Makefile
3265                         echo 'uninstall.libs ::' >> Makefile
3266                         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >> Makefile
3267                         ;;
3268                 esac
3269         fi
3270
3271         if test -f $srcdir/$cf_dir/modules; then
3272                 echo >> Makefile
3273                 if test -f $srcdir/$cf_dir/headers; then
3274 cat >> Makefile <<CF_EOF
3275 install.includes \\
3276 uninstall.includes \\
3277 CF_EOF
3278                 fi
3279 if test "$cf_dir" != "c++" ; then
3280 echo 'lint \' >> Makefile
3281 fi
3282 cat >> Makefile <<CF_EOF
3283 libs \\
3284 lintlib \\
3285 install.libs \\
3286 uninstall.libs \\
3287 install.$cf_dir \\
3288 uninstall.$cf_dir ::
3289         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3290 CF_EOF
3291         elif test -f $srcdir/$cf_dir/headers; then
3292 cat >> Makefile <<CF_EOF
3293
3294 libs \\
3295 install.libs \\
3296 uninstall.libs \\
3297 install.includes \\
3298 uninstall.includes ::
3299         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3300 CF_EOF
3301 fi
3302 done
3303
3304 cat >> Makefile <<CF_EOF
3305
3306 install.libs uninstall.libs \\
3307 install.data uninstall.data ::
3308 $MAKE_TERMINFO  cd misc && \${MAKE} \${CF_MFLAGS} \[$]@
3309 CF_EOF
3310
3311 if test "x$cf_with_manpages" = xyes; then
3312 cat >> Makefile <<CF_EOF
3313
3314 install.man \\
3315 uninstall.man ::
3316         cd man && \${MAKE} \${CF_MFLAGS} \[$]@
3317 CF_EOF
3318 fi
3319
3320 cat >> Makefile <<CF_EOF
3321
3322 distclean ::
3323         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3324         rm -f headers.sh headers.sed mk_shared_lib.sh
3325         rm -f edit_man.* man_alias.*
3326         rm -rf \${DIRS_TO_MAKE}
3327 CF_EOF
3328
3329 # Special case: tack's manpage lives in its own directory.
3330 if test "x$cf_with_manpages" = xyes; then
3331 if test -d tack ; then
3332 if test -f $srcdir/$tack.h; then
3333 cat >> Makefile <<CF_EOF
3334
3335 install.man \\
3336 uninstall.man ::
3337         cd tack && \${MAKE} \${CF_MFLAGS} \[$]@
3338 CF_EOF
3339 fi
3340 fi
3341 fi
3342
3343 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3344 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3345 dnl anything, and will make it more standardized.  It's awkward to decide this
3346 dnl at configuration because of quoting, so we'll simply make all headers
3347 dnl installed via a script that can do the right thing.
3348
3349 rm -f headers.sed headers.sh
3350
3351 dnl ( generating this script makes the makefiles a little tidier :-)
3352 echo creating headers.sh
3353 cat >headers.sh <<CF_EOF
3354 #! /bin/sh
3355 # This shell script is generated by the 'configure' script.  It is invoked in a
3356 # subdirectory of the build tree.  It generates a sed-script in the parent
3357 # directory that is used to adjust includes for header files that reside in a
3358 # subdirectory of /usr/include, etc.
3359 PRG=""
3360 while test \[$]# != 3
3361 do
3362 PRG="\$PRG \[$]1"; shift
3363 done
3364 DST=\[$]1
3365 REF=\[$]2
3366 SRC=\[$]3
3367 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3368 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3369 echo installing \$SRC in \$DST
3370 CF_EOF
3371
3372 if test $WITH_CURSES_H = yes; then
3373         cat >>headers.sh <<CF_EOF
3374 case \$DST in
3375 /*/include/*)
3376         END=\`basename \$DST\`
3377         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3378         do
3379                 NAME=\`basename \$i\`
3380                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3381         done
3382         ;;
3383 *)
3384         echo "" >> \$TMPSED
3385         ;;
3386 esac
3387 CF_EOF
3388
3389 else
3390         cat >>headers.sh <<CF_EOF
3391 case \$DST in
3392 /*/include/*)
3393         END=\`basename \$DST\`
3394         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3395         do
3396                 NAME=\`basename \$i\`
3397                 if test "\$NAME" = "curses.h"
3398                 then
3399                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3400                         NAME=ncurses.h
3401                 fi
3402                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3403         done
3404         ;;
3405 *)
3406         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3407         ;;
3408 esac
3409 CF_EOF
3410 fi
3411 cat >>headers.sh <<CF_EOF
3412 rm -f \$TMPSRC
3413 sed -f \$TMPSED \$SRC > \$TMPSRC
3414 NAME=\`basename \$SRC\`
3415 CF_EOF
3416 if test $WITH_CURSES_H != yes; then
3417         cat >>headers.sh <<CF_EOF
3418 test "\$NAME" = "curses.h" && NAME=ncurses.h
3419 CF_EOF
3420 fi
3421 cat >>headers.sh <<CF_EOF
3422 # Just in case someone gzip'd manpages, remove the conflicting copy.
3423 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3424
3425 eval \$PRG \$TMPSRC \$DST/\$NAME
3426 rm -f \$TMPSRC \$TMPSED
3427 CF_EOF
3428
3429 chmod 0755 headers.sh
3430
3431 for cf_dir in $SRC_SUBDIRS
3432 do
3433         if test ! -d $srcdir/$cf_dir ; then
3434                 continue
3435         fi
3436
3437         if test -f $srcdir/$cf_dir/headers; then
3438                 $AWK -f $srcdir/mk-hdr.awk \
3439                         subset="$LIB_SUBSETS" \
3440                         compat="$WITH_CURSES_H" \
3441                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3442         fi
3443
3444         if test -f $srcdir/$cf_dir/modules; then
3445                 if test "$cf_dir" != "c++" ; then
3446                         cat >>$cf_dir/Makefile <<"CF_EOF"
3447 depend : ${AUTO_SRC}
3448         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3449
3450 # DO NOT DELETE THIS LINE -- make depend depends on it.
3451 CF_EOF
3452                 fi
3453         fi
3454 done
3455 AC_SUBST(LIBS_TO_MAKE)
3456 ])dnl
3457 dnl ---------------------------------------------------------------------------
3458 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3459 dnl -------------
3460 dnl Find the and soname for the given shared library.  Set the cache variable
3461 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3462 dnl variable to "unknown".
3463 dnl
3464 dnl $1 = headers
3465 dnl $2 = code
3466 dnl $3 = library name
3467 AC_DEFUN([CF_LIB_SONAME],
3468 [
3469 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3470
3471 cf_cv_$3_soname=unknown
3472 if test "$cross_compiling" != yes ; then
3473 cat >conftest.$ac_ext <<CF_EOF
3474 $1
3475 int main()
3476 {
3477 $2
3478         ${cf_cv_main_return:-return}(0);
3479 }
3480 CF_EOF
3481 cf_save_LIBS="$LIBS"
3482         CF_ADD_LIB($3)
3483         if AC_TRY_EVAL(ac_compile) ; then
3484                 if AC_TRY_EVAL(ac_link) ; then
3485                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3486                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3487                 fi
3488         fi
3489 rm -rf conftest*
3490 LIBS="$cf_save_LIBS"
3491 fi
3492 ])
3493 ])
3494 dnl ---------------------------------------------------------------------------
3495 dnl CF_LIB_SUFFIX version: 17 updated: 2011/07/02 15:36:04
3496 dnl -------------
3497 dnl Compute the library file-suffix from the given model name
3498 dnl $1 = model name
3499 dnl $2 = variable to set (the nominal library suffix)
3500 dnl $3 = dependency variable to set (actual filename)
3501 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3502 AC_DEFUN([CF_LIB_SUFFIX],
3503 [
3504         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3505         case $1 in #(vi
3506         libtool) #(vi
3507                 $2='.la'
3508                 $3=[$]$2
3509                 ;;
3510         normal) #(vi
3511                 $2='.a'
3512                 $3=[$]$2
3513                 ;;
3514         debug) #(vi
3515                 $2='_g.a'
3516                 $3=[$]$2
3517                 ;;
3518         profile) #(vi
3519                 $2='_p.a'
3520                 $3=[$]$2
3521                 ;;
3522         shared) #(vi
3523                 case $cf_cv_system_name in
3524                 aix[[5-7]]*) #(vi
3525                         $2='.a'
3526                         $3=[$]$2
3527                         ;;
3528                 cygwin*) #(vi
3529                         $2='.dll'
3530                         $3='.dll.a'
3531                         ;;
3532                 darwin*) #(vi
3533                         $2='.dylib'
3534                         $3=[$]$2
3535                         ;;
3536                 hpux*) #(vi
3537                         case $target in
3538                         ia64*) #(vi
3539                                 $2='.so'
3540                                 $3=[$]$2
3541                                 ;;
3542                         *) #(vi
3543                                 $2='.sl'
3544                                 $3=[$]$2
3545                                 ;;
3546                         esac
3547                         ;;
3548                 *)      $2='.so'
3549                         $3=[$]$2
3550                         ;;
3551                 esac
3552         esac
3553         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3554         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3555 ])dnl
3556 dnl ---------------------------------------------------------------------------
3557 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3558 dnl -----------
3559 dnl Compute the string to append to -library from the given model name
3560 dnl $1 = model name
3561 dnl $2 = variable to set
3562 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3563 AC_DEFUN([CF_LIB_TYPE],
3564 [
3565         case $1 in
3566         libtool) $2=''   ;;
3567         normal)  $2=''   ;;
3568         debug)   $2='_g' ;;
3569         profile) $2='_p' ;;
3570         shared)  $2=''   ;;
3571         esac
3572         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3573 ])dnl
3574 dnl ---------------------------------------------------------------------------
3575 dnl CF_LINK_DATAONLY version: 9 updated: 2009/01/01 20:21:38
3576 dnl ----------------
3577 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3578 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3579 dnl have to provide wrappers for global tables to ensure they're linked
3580 dnl properly.
3581 AC_DEFUN([CF_LINK_DATAONLY],
3582 [
3583 AC_MSG_CHECKING([if data-only library module links])
3584 AC_CACHE_VAL(cf_cv_link_dataonly,[
3585         rm -f conftest.a
3586         cat >conftest.$ac_ext <<EOF
3587 #line __oline__ "configure"
3588 int     testdata[[3]] = { 123, 456, 789 };
3589 EOF
3590         if AC_TRY_EVAL(ac_compile) ; then
3591                 mv conftest.o data.o && \
3592                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3593         fi
3594         rm -f conftest.$ac_ext data.o
3595         cat >conftest.$ac_ext <<EOF
3596 #line __oline__ "configure"
3597 int     testfunc()
3598 {
3599 #if defined(NeXT)
3600         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3601 #else
3602         extern int testdata[[3]];
3603         return testdata[[0]] == 123
3604            &&  testdata[[1]] == 456
3605            &&  testdata[[2]] == 789;
3606 #endif
3607 }
3608 EOF
3609         if AC_TRY_EVAL(ac_compile); then
3610                 mv conftest.o func.o && \
3611                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3612         fi
3613         rm -f conftest.$ac_ext func.o
3614         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3615         cf_saveLIBS="$LIBS"
3616         LIBS="conftest.a $LIBS"
3617         AC_TRY_RUN([
3618         int main()
3619         {
3620                 extern int testfunc();
3621                 ${cf_cv_main_return:-return} (!testfunc());
3622         }
3623         ],
3624         [cf_cv_link_dataonly=yes],
3625         [cf_cv_link_dataonly=no],
3626         [cf_cv_link_dataonly=unknown])
3627         LIBS="$cf_saveLIBS"
3628         ])
3629 AC_MSG_RESULT($cf_cv_link_dataonly)
3630
3631 if test "$cf_cv_link_dataonly" = no ; then
3632         AC_DEFINE(BROKEN_LINKER)
3633         BROKEN_LINKER=1
3634 fi
3635
3636 ])dnl
3637 dnl ---------------------------------------------------------------------------
3638 dnl CF_LINK_FUNCS version: 7 updated: 2006/12/16 12:33:30
3639 dnl -------------
3640 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3641 dnl A few non-Unix systems implement symlink, but not link.
3642 dnl A few non-systems implement neither (or have nonfunctional versions).
3643 AC_DEFUN([CF_LINK_FUNCS],
3644 [
3645 AC_CHECK_FUNCS( \
3646         remove \
3647         unlink )
3648
3649 if test "$cross_compiling" = yes ; then
3650         AC_CHECK_FUNCS( \
3651                 link \
3652                 symlink )
3653 else
3654         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3655                 cf_cv_link_funcs=
3656                 for cf_func in link symlink ; do
3657                         AC_TRY_RUN([
3658 #include <sys/types.h>
3659 #include <sys/stat.h>
3660 #ifdef HAVE_UNISTD_H
3661 #include <unistd.h>
3662 #endif
3663 int main()
3664 {
3665         int fail = 0;
3666         char *src = "config.log";
3667         char *dst = "conftest.chk";
3668         struct stat src_sb;
3669         struct stat dst_sb;
3670
3671         stat(src, &src_sb);
3672         fail = ($cf_func("config.log", "conftest.chk") < 0)
3673             || (stat(dst, &dst_sb) < 0)
3674             || (dst_sb.st_mtime != src_sb.st_mtime);
3675 #ifdef HAVE_UNLINK
3676         unlink(dst);
3677 #else
3678         remove(dst);
3679 #endif
3680         ${cf_cv_main_return:-return} (fail);
3681 }
3682                         ],[
3683                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3684                         eval 'ac_cv_func_'$cf_func'=yes'],[
3685                         eval 'ac_cv_func_'$cf_func'=no'],[
3686                         eval 'ac_cv_func_'$cf_func'=error'])
3687                 done
3688                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
3689         ])
3690         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK)
3691         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK)
3692 fi
3693 ])dnl
3694 dnl ---------------------------------------------------------------------------
3695 dnl CF_MAIN_RETURN version: 1 updated: 2006/12/10 09:51:54
3696 dnl --------------
3697 dnl Check if a return from main to the shell actually returns the same exit
3698 dnl code.  This is true for almost any POSIX environment.
3699 dnl
3700 dnl Some very old environments did not flush stdout, etc., on an exit.  That
3701 dnl would be a useful case to test for also.
3702 AC_DEFUN([CF_MAIN_RETURN],
3703 [
3704 cf_cv_main_return=return
3705 ])dnl
3706 dnl ---------------------------------------------------------------------------
3707 dnl CF_MAKEFLAGS version: 14 updated: 2011/03/31 19:29:46
3708 dnl ------------
3709 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
3710 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
3711 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
3712 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
3713 AC_DEFUN([CF_MAKEFLAGS],
3714 [
3715 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
3716         cf_cv_makeflags=''
3717         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
3718         do
3719                 cat >cf_makeflags.tmp <<CF_EOF
3720 SHELL = /bin/sh
3721 all :
3722         @ echo '.$cf_option'
3723 CF_EOF
3724                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
3725                 case "$cf_result" in
3726                 .*k)
3727                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
3728                         case "$cf_result" in
3729                         .*CC=*) cf_cv_makeflags=
3730                                 ;;
3731                         *)      cf_cv_makeflags=$cf_option
3732                                 ;;
3733                         esac
3734                         break
3735                         ;;
3736                 .-)     ;;
3737                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
3738                         ;;
3739                 esac
3740         done
3741         rm -f cf_makeflags.tmp
3742 ])
3743
3744 AC_SUBST(cf_cv_makeflags)
3745 ])dnl
3746 dnl ---------------------------------------------------------------------------
3747 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
3748 dnl ------------
3749 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
3750 dnl a monocase filesystem.
3751 AC_DEFUN([CF_MAKE_TAGS],[
3752 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
3753
3754 AC_CHECK_PROGS(CTAGS, exctags ctags)
3755 AC_CHECK_PROGS(ETAGS, exetags etags)
3756
3757 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
3758
3759 if test "$cf_cv_mixedcase" = yes ; then
3760         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
3761 else
3762         MAKE_UPPER_TAGS=no
3763 fi
3764
3765 if test "$MAKE_UPPER_TAGS" = yes ; then
3766         MAKE_UPPER_TAGS=
3767 else
3768         MAKE_UPPER_TAGS="#"
3769 fi
3770
3771 if test "$MAKE_LOWER_TAGS" = yes ; then
3772         MAKE_LOWER_TAGS=
3773 else
3774         MAKE_LOWER_TAGS="#"
3775 fi
3776
3777 AC_SUBST(CTAGS)
3778 AC_SUBST(ETAGS)
3779
3780 AC_SUBST(MAKE_UPPER_TAGS)
3781 AC_SUBST(MAKE_LOWER_TAGS)
3782 ])dnl
3783 dnl ---------------------------------------------------------------------------
3784 dnl CF_MANPAGE_FORMAT version: 9 updated: 2010/10/23 16:10:30
3785 dnl -----------------
3786 dnl Option to allow user to override automatic configuration of manpage format.
3787 dnl There are several special cases:
3788 dnl
3789 dnl     gzip - man checks for, can display gzip'd files
3790 dnl     compress - man checks for, can display compressed files
3791 dnl     BSDI - files in the cat-directories are suffixed ".0"
3792 dnl     formatted - installer should format (put files in cat-directory)
3793 dnl     catonly - installer should only format, e.g., for a turnkey system.
3794 dnl
3795 dnl There are other configurations which this macro does not test, e.g., HPUX's
3796 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
3797 dnl convention would not match our use).
3798 AC_DEFUN([CF_MANPAGE_FORMAT],
3799 [
3800 AC_REQUIRE([CF_PATHSEP])
3801 AC_MSG_CHECKING(format of man-pages)
3802
3803 AC_ARG_WITH(manpage-format,
3804         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
3805                           optionally formatted/catonly, e.g., gzip,formatted],
3806         [MANPAGE_FORMAT=$withval],
3807         [MANPAGE_FORMAT=unknown])
3808
3809 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
3810 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
3811
3812 cf_unknown=
3813
3814 case $MANPAGE_FORMAT in
3815 unknown)
3816   if test -z "$MANPATH" ; then
3817     MANPATH="/usr/man:/usr/share/man"
3818   fi
3819
3820   # look for the 'date' man-page (it's most likely to be installed!)
3821   MANPAGE_FORMAT=
3822   cf_preform=no
3823   cf_catonly=yes
3824   cf_example=date
3825
3826   IFS="${IFS:-  }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
3827   for cf_dir in $MANPATH; do
3828     test -z "$cf_dir" && cf_dir=/usr/man
3829     for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
3830     do
3831       cf_test=`echo $cf_name | sed -e 's/*//'`
3832       if test "x$cf_test" = "x$cf_name" ; then
3833
3834         case "$cf_name" in
3835         *.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
3836         *.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
3837         *.0)    MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
3838         *)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
3839         esac
3840
3841         case "$cf_name" in
3842         $cf_dir/man*)
3843           cf_catonly=no
3844           ;;
3845         $cf_dir/cat*)
3846           cf_preform=yes
3847           ;;
3848         esac
3849         break
3850       fi
3851
3852       # if we found a match in either man* or cat*, stop looking
3853       if test -n "$MANPAGE_FORMAT" ; then
3854         cf_found=no
3855         test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
3856         test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
3857         case "$cf_name" in
3858         $cf_dir/cat*)
3859           cf_found=yes
3860           ;;
3861         esac
3862         test $cf_found=yes && break
3863       fi
3864     done
3865     # only check the first directory in $MANPATH where we find manpages
3866     if test -n "$MANPAGE_FORMAT" ; then
3867        break
3868     fi
3869   done
3870   # if we did not find the example, just assume it is normal
3871   test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
3872   IFS="$ac_save_ifs"
3873   ;;
3874 *)
3875   for cf_option in $MANPAGE_FORMAT; do
3876      case $cf_option in #(vi
3877      gzip|compress|BSDI|normal|formatted|catonly)
3878        ;;
3879      *)
3880        cf_unknown="$cf_unknown $cf_option"
3881        ;;
3882      esac
3883   done
3884   ;;
3885 esac
3886
3887 AC_MSG_RESULT($MANPAGE_FORMAT)
3888 if test -n "$cf_unknown" ; then
3889   AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
3890 fi
3891 ])dnl
3892 dnl ---------------------------------------------------------------------------
3893 dnl CF_MANPAGE_RENAMES version: 7 updated: 2005/06/18 18:51:57
3894 dnl ------------------
3895 dnl The Debian people have their own naming convention for manpages.  This
3896 dnl option lets us override the name of the file containing renaming, or
3897 dnl disable it altogether.
3898 AC_DEFUN([CF_MANPAGE_RENAMES],
3899 [
3900 AC_MSG_CHECKING(for manpage renaming)
3901
3902 AC_ARG_WITH(manpage-renames,
3903         [  --with-manpage-renames  specify manpage-renaming],
3904         [MANPAGE_RENAMES=$withval],
3905         [MANPAGE_RENAMES=yes])
3906
3907 case ".$MANPAGE_RENAMES" in #(vi
3908 .no) #(vi
3909   ;;
3910 .|.yes)
3911   # Debian 'man' program?
3912   if test -f /etc/debian_version ; then
3913     MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
3914   else
3915     MANPAGE_RENAMES=no
3916   fi
3917   ;;
3918 esac
3919
3920 if test "$MANPAGE_RENAMES" != no ; then
3921   if test -f $srcdir/man/$MANPAGE_RENAMES ; then
3922     MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
3923   elif test ! -f $MANPAGE_RENAMES ; then
3924     AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
3925   fi
3926
3927   test ! -d man && mkdir man
3928
3929   # Construct a sed-script to perform renaming within man-pages
3930   if test -n "$MANPAGE_RENAMES" ; then
3931     test ! -d man && mkdir man
3932     sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
3933   fi
3934 fi
3935
3936 AC_MSG_RESULT($MANPAGE_RENAMES)
3937 AC_SUBST(MANPAGE_RENAMES)
3938 ])dnl
3939 dnl ---------------------------------------------------------------------------
3940 dnl CF_MANPAGE_SYMLINKS version: 5 updated: 2010/07/24 17:12:40
3941 dnl -------------------
3942 dnl Some people expect each tool to make all aliases for manpages in the
3943 dnl man-directory.  This accommodates the older, less-capable implementations
3944 dnl of 'man', and is optional.
3945 AC_DEFUN([CF_MANPAGE_SYMLINKS],
3946 [
3947 AC_MSG_CHECKING(if manpage aliases will be installed)
3948
3949 AC_ARG_WITH(manpage-aliases,
3950         [  --with-manpage-aliases  specify manpage-aliases using .so],
3951         [MANPAGE_ALIASES=$withval],
3952         [MANPAGE_ALIASES=yes])
3953
3954 AC_MSG_RESULT($MANPAGE_ALIASES)
3955
3956 case "x$LN_S" in #(vi
3957 xln*) #(vi
3958         cf_use_symlinks=yes
3959         ;;
3960 *)
3961         cf_use_symlinks=no
3962         ;;
3963 esac
3964
3965 MANPAGE_SYMLINKS=no
3966 if test "$MANPAGE_ALIASES" = yes ; then
3967 AC_MSG_CHECKING(if manpage symlinks should be used)
3968
3969 AC_ARG_WITH(manpage-symlinks,
3970         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
3971         [MANPAGE_SYMLINKS=$withval],
3972         [MANPAGE_SYMLINKS=$cf_use_symlinks])
3973
3974 if test "$$cf_use_symlinks" = no; then
3975 if test "$MANPAGE_SYMLINKS" = yes ; then
3976         AC_MSG_WARN(cannot make symlinks, will use .so files)
3977         MANPAGE_SYMLINKS=no
3978 fi
3979 fi
3980
3981 AC_MSG_RESULT($MANPAGE_SYMLINKS)
3982 fi
3983
3984 ])dnl
3985 dnl ---------------------------------------------------------------------------
3986 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
3987 dnl --------------
3988 dnl This option causes manpages to be run through tbl(1) to generate tables
3989 dnl correctly.
3990 AC_DEFUN([CF_MANPAGE_TBL],
3991 [
3992 AC_MSG_CHECKING(for manpage tbl)
3993
3994 AC_ARG_WITH(manpage-tbl,
3995         [  --with-manpage-tbl      specify manpage processing with tbl],
3996         [MANPAGE_TBL=$withval],
3997         [MANPAGE_TBL=no])
3998
3999 AC_MSG_RESULT($MANPAGE_TBL)
4000 ])dnl
4001 dnl ---------------------------------------------------------------------------
4002 dnl CF_MAN_PAGES version: 40 updated: 2011/09/10 16:20:21
4003 dnl ------------
4004 dnl Try to determine if the man-pages on the system are compressed, and if
4005 dnl so, what format is used.  Use this information to construct a script that
4006 dnl will install man-pages.
4007 AC_DEFUN([CF_MAN_PAGES],
4008 [
4009 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4010 CF_MANPAGE_FORMAT
4011 CF_MANPAGE_RENAMES
4012 CF_MANPAGE_SYMLINKS
4013 CF_MANPAGE_TBL
4014
4015   if test "$prefix" = "NONE" ; then
4016      cf_prefix="$ac_default_prefix"
4017   else
4018      cf_prefix="$prefix"
4019   fi
4020
4021   case "$MANPAGE_FORMAT" in # (vi
4022   *catonly*) # (vi
4023     cf_format=yes
4024     cf_inboth=no
4025     ;;
4026   *formatted*) # (vi
4027     cf_format=yes
4028     cf_inboth=yes
4029     ;;
4030   *)
4031     cf_format=no
4032     cf_inboth=no
4033     ;;
4034   esac
4035
4036 test ! -d man && mkdir man
4037
4038 cf_so_strip=
4039 cf_compress=
4040 case "$MANPAGE_FORMAT" in #(vi
4041 *compress*) #(vi
4042         cf_so_strip="Z"
4043         cf_compress=compress
4044   ;;
4045 *gzip*)
4046         cf_so_strip="gz"
4047         cf_compress=gzip
4048   ;;
4049 esac
4050
4051 cf_edit_man=./edit_man.sh
4052 cf_man_alias=`pwd`/man_alias.sed
4053
4054 cat >$cf_edit_man <<CF_EOF
4055 #! /bin/sh
4056 # this script is generated by the configure-script CF_MAN_PAGES macro.
4057
4058 prefix="$cf_prefix"
4059 datadir="$datadir"
4060
4061 NCURSES_MAJOR="$NCURSES_MAJOR"
4062 NCURSES_MINOR="$NCURSES_MINOR"
4063 NCURSES_PATCH="$NCURSES_PATCH"
4064
4065 NCURSES_OSPEED="$NCURSES_OSPEED"
4066 TERMINFO="$TERMINFO"
4067
4068 INSTALL="$INSTALL"
4069 INSTALL_DATA="$INSTALL_DATA"
4070
4071 transform="$program_transform_name"
4072
4073 TMP=\${TMPDIR:=/tmp}/man\$\$
4074 trap "rm -f \$TMP" 0 1 2 5 15
4075
4076 form=\[$]1
4077 shift || exit 1
4078
4079 verb=\[$]1
4080 shift || exit 1
4081
4082 mandir=\[$]1
4083 shift || exit 1
4084
4085 srcdir=\[$]1
4086 top_srcdir=\[$]srcdir/..
4087 shift || exit 1
4088
4089 if test "\$form" = normal ; then
4090         if test "$cf_format" = yes ; then
4091         if test "$cf_inboth" = no ; then
4092                 sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4093                 exit $?
4094         fi
4095         fi
4096         cf_subdir=\$mandir/man
4097         cf_tables=$MANPAGE_TBL
4098 else
4099         cf_subdir=\$mandir/cat
4100         cf_tables=yes
4101 fi
4102
4103 # process the list of source-files
4104 for i in \[$]* ; do
4105 case \$i in #(vi
4106 *.orig|*.rej) ;; #(vi
4107 *.[[0-9]]*)
4108         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4109         if test \$verb = installing ; then
4110         if test ! -d \$cf_subdir\${section} ; then
4111                 mkdir -p \$cf_subdir\$section
4112         fi
4113         fi
4114
4115         # replace variables in man page
4116         if test ! -f $cf_man_alias ; then
4117 cat >>$cf_man_alias <<-CF_EOF2
4118                 s,@DATADIR@,\$datadir,g
4119                 s,@TERMINFO@,\$TERMINFO,g
4120                 s,@NCURSES_MAJOR@,\$NCURSES_MAJOR,g
4121                 s,@NCURSES_MINOR@,\$NCURSES_MINOR,g
4122                 s,@NCURSES_PATCH@,\$NCURSES_PATCH,g
4123                 s,@NCURSES_OSPEED@,\$NCURSES_OSPEED,g
4124 CF_EOF
4125         ifelse($1,,,[
4126         for cf_name in $1
4127         do
4128                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4129                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4130 cat >>$cf_edit_man <<-CF_EOF
4131                 s,@$cf_NAME@,$cf_name,g
4132 CF_EOF
4133         done
4134         ])
4135 cat >>$cf_edit_man <<CF_EOF
4136 CF_EOF2
4137                 echo "...made $cf_man_alias"
4138         fi
4139
4140         aliases=
4141         cf_source=\`basename \$i\`
4142         inalias=\$cf_source
4143         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4144         if test ! -f \$inalias ; then
4145                 echo .. skipped \$cf_source
4146                 continue
4147         fi
4148 CF_EOF
4149
4150 if test "$MANPAGE_ALIASES" != no ; then
4151 cat >>$cf_edit_man <<CF_EOF
4152         nCurses=ignore.3x
4153         test $with_curses_h = yes && nCurses=ncurses.3x
4154         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4155 CF_EOF
4156 fi
4157
4158 if test "$MANPAGE_RENAMES" = no ; then
4159 cat >>$cf_edit_man <<CF_EOF
4160         # perform program transformations for section 1 man pages
4161         if test \$section = 1 ; then
4162                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4163         else
4164                 cf_target=\$cf_subdir\${section}/\$cf_source
4165         fi
4166 CF_EOF
4167 else
4168 cat >>$cf_edit_man <<CF_EOF
4169         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4170         if test -z "\$cf_target" ; then
4171                 echo '? missing rename for '\$cf_source
4172                 cf_target="\$cf_source"
4173         fi
4174         cf_target="\$cf_subdir\${section}/\${cf_target}"
4175
4176 CF_EOF
4177 fi
4178
4179 cat >>$cf_edit_man <<CF_EOF
4180         sed     -f $cf_man_alias \\
4181 CF_EOF
4182
4183 if test -f $MANPAGE_RENAMES ; then
4184 cat >>$cf_edit_man <<CF_EOF
4185                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4186 CF_EOF
4187 else
4188 cat >>$cf_edit_man <<CF_EOF
4189                 < \$i >\$TMP
4190 CF_EOF
4191 fi
4192
4193 cat >>$cf_edit_man <<CF_EOF
4194 if test \$cf_tables = yes ; then
4195         tbl \$TMP >\$TMP.out
4196         mv \$TMP.out \$TMP
4197 fi
4198 CF_EOF
4199
4200 if test $with_overwrite != yes ; then
4201 cat >>$cf_edit_man <<CF_EOF
4202         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4203         mv \$TMP.out \$TMP
4204 CF_EOF
4205 fi
4206
4207 if test $with_curses_h != yes ; then
4208 cat >>$cf_edit_man <<CF_EOF
4209         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4210         mv \$TMP.out \$TMP
4211 CF_EOF
4212 fi
4213
4214 cat >>$cf_edit_man <<CF_EOF
4215         if test \$form = format ; then
4216                 nroff -man \$TMP >\$TMP.out
4217                 mv \$TMP.out \$TMP
4218         fi
4219 CF_EOF
4220
4221 if test -n "$cf_compress" ; then
4222 cat >>$cf_edit_man <<CF_EOF
4223         if test \$verb = installing ; then
4224         if ( $cf_compress -f \$TMP )
4225         then
4226                 mv \$TMP.$cf_so_strip \$TMP
4227         fi
4228         fi
4229         cf_target="\$cf_target.$cf_so_strip"
4230 CF_EOF
4231 fi
4232
4233 case "$MANPAGE_FORMAT" in #(vi
4234 *BSDI*)
4235 cat >>$cf_edit_man <<CF_EOF
4236         if test \$form = format ; then
4237                 # BSDI installs only .0 suffixes in the cat directories
4238                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4239         fi
4240 CF_EOF
4241   ;;
4242 esac
4243
4244 cat >>$cf_edit_man <<CF_EOF
4245         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4246         if test \$verb = installing ; then
4247                 echo \$verb \$cf_target
4248                 \$INSTALL_DATA \$TMP \$cf_target
4249                 test -d \$cf_subdir\${section} &&
4250                 test -n "\$aliases" && (
4251                         cd \$cf_subdir\${section} && (
4252                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4253                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4254                                 cf_target=\`basename \$cf_target\`
4255                                 for cf_alias in \$aliases
4256                                 do
4257                                         if test \$section = 1 ; then
4258                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4259                                         fi
4260
4261                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4262                                                 if test -f \$cf_alias\${suffix} ; then
4263                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4264                                                         then
4265                                                                 continue
4266                                                         fi
4267                                                 fi
4268                                                 echo .. \$verb alias \$cf_alias\${suffix}
4269 CF_EOF
4270 case "x$LN_S" in #(vi
4271 *-f) #(vi
4272 cat >>$cf_edit_man <<CF_EOF
4273                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4274 CF_EOF
4275         ;;
4276 *)
4277 cat >>$cf_edit_man <<CF_EOF
4278                                                 rm -f \$cf_alias\${suffix}
4279                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4280 CF_EOF
4281         ;;
4282 esac
4283 cat >>$cf_edit_man <<CF_EOF
4284                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4285                                                 echo ".so \$cf_source" >\$TMP
4286 CF_EOF
4287 if test -n "$cf_compress" ; then
4288 cat >>$cf_edit_man <<CF_EOF
4289                                                 if test -n "$cf_so_strip" ; then
4290                                                         $cf_compress -f \$TMP
4291                                                         mv \$TMP.$cf_so_strip \$TMP
4292                                                 fi
4293 CF_EOF
4294 fi
4295 cat >>$cf_edit_man <<CF_EOF
4296                                                 echo .. \$verb alias \$cf_alias\${suffix}
4297                                                 rm -f \$cf_alias\${suffix}
4298                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4299                                         fi
4300                                 done
4301                         )
4302                 )
4303         elif test \$verb = removing ; then
4304                 test -f \$cf_target && (
4305                         echo \$verb \$cf_target
4306                         rm -f \$cf_target
4307                 )
4308                 test -d \$cf_subdir\${section} &&
4309                 test -n "\$aliases" && (
4310                         cd \$cf_subdir\${section} && (
4311                                 for cf_alias in \$aliases
4312                                 do
4313                                         if test \$section = 1 ; then
4314                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4315                                         fi
4316
4317                                         echo .. \$verb alias \$cf_alias\${suffix}
4318                                         rm -f \$cf_alias\${suffix}
4319                                 done
4320                         )
4321                 )
4322         else
4323 #               echo ".hy 0"
4324                 cat \$TMP
4325         fi
4326         ;;
4327 esac
4328 done
4329
4330 if test $cf_inboth = yes ; then
4331 if test \$form != format ; then
4332         sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4333 fi
4334 fi
4335
4336 exit 0
4337 CF_EOF
4338 chmod 755 $cf_edit_man
4339
4340 ])dnl
4341 dnl ---------------------------------------------------------------------------
4342 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4343 dnl -----------
4344 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4345 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4346 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4347 AC_DEFUN([CF_MATH_LIB],
4348 [
4349 AC_CACHE_CHECK(if -lm needed for math functions,
4350         cf_cv_need_libm,[
4351         AC_TRY_LINK([
4352         #include <stdio.h>
4353         #include <math.h>
4354         ],
4355         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4356         [cf_cv_need_libm=no],
4357         [cf_cv_need_libm=yes])])
4358 if test "$cf_cv_need_libm" = yes
4359 then
4360 ifelse($1,,[
4361         CF_ADD_LIB(m)
4362 ],[$1=-lm])
4363 fi
4364 ])
4365 dnl ---------------------------------------------------------------------------
4366 dnl CF_MIXEDCASE_FILENAMES version: 3 updated: 2003/09/20 17:07:55
4367 dnl ----------------------
4368 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4369 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4370 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4371 [
4372 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4373 if test "$cross_compiling" = yes ; then
4374         case $target_alias in #(vi
4375         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-mingw32*|*-uwin*) #(vi
4376                 cf_cv_mixedcase=no
4377                 ;;
4378         *)
4379                 cf_cv_mixedcase=yes
4380                 ;;
4381         esac
4382 else
4383         rm -f conftest CONFTEST
4384         echo test >conftest
4385         if test -f CONFTEST ; then
4386                 cf_cv_mixedcase=no
4387         else
4388                 cf_cv_mixedcase=yes
4389         fi
4390         rm -f conftest CONFTEST
4391 fi
4392 ])
4393 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES)
4394 ])dnl
4395 dnl ---------------------------------------------------------------------------
4396 dnl CF_MKSTEMP version: 7 updated: 2010/08/14 18:25:37
4397 dnl ----------
4398 dnl Check for a working mkstemp.  This creates two files, checks that they are
4399 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4400 AC_DEFUN([CF_MKSTEMP],[
4401 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4402 rm -rf conftest*
4403 AC_TRY_RUN([
4404 #include <sys/types.h>
4405 #include <stdlib.h>
4406 #include <stdio.h>
4407 #include <string.h>
4408 #include <sys/stat.h>
4409 int main()
4410 {
4411         char *tmpl = "conftestXXXXXX";
4412         char name[2][80];
4413         int n;
4414         int result = 0;
4415         int fd;
4416         struct stat sb;
4417
4418         umask(077);
4419         for (n = 0; n < 2; ++n) {
4420                 strcpy(name[n], tmpl);
4421                 if ((fd = mkstemp(name[n])) >= 0) {
4422                         if (!strcmp(name[n], tmpl)
4423                          || stat(name[n], &sb) != 0
4424                          || (sb.st_mode & S_IFMT) != S_IFREG
4425                          || (sb.st_mode & 077) != 0) {
4426                                 result = 1;
4427                         }
4428                         close(fd);
4429                 }
4430         }
4431         if (result == 0
4432          && !strcmp(name[0], name[1]))
4433                 result = 1;
4434         ${cf_cv_main_return:-return}(result);
4435 }
4436 ],[cf_cv_func_mkstemp=yes
4437 ],[cf_cv_func_mkstemp=no
4438 ],[AC_CHECK_FUNC(mkstemp)
4439 ])
4440 ])
4441 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4442         AC_DEFINE(HAVE_MKSTEMP)
4443 fi
4444 ])dnl
4445 dnl ---------------------------------------------------------------------------
4446 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4447 dnl ----------
4448 dnl Write a debug message to config.log, along with the line number in the
4449 dnl configure script.
4450 AC_DEFUN([CF_MSG_LOG],[
4451 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
4452 ])dnl
4453 dnl ---------------------------------------------------------------------------
4454 dnl CF_NCURSES_ABI_6 version: 1 updated: 2005/09/17 18:42:49
4455 dnl ----------------
4456 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
4457 dnl warn about this.
4458 AC_DEFUN([CF_NCURSES_ABI_6],[
4459 if test "${with_abi_version+set}" != set; then
4460         case $cf_cv_rel_version in
4461         5.*)
4462                 cf_cv_rel_version=6.0
4463                 cf_cv_abi_version=6
4464                 AC_MSG_WARN(Overriding ABI version to $cf_cv_abi_version)
4465                 ;;
4466         esac
4467 fi
4468 ])dnl
4469 dnl ---------------------------------------------------------------------------
4470 dnl CF_NO_LEAKS_OPTION version: 4 updated: 2006/12/16 14:24:05
4471 dnl ------------------
4472 dnl see CF_WITH_NO_LEAKS
4473 AC_DEFUN([CF_NO_LEAKS_OPTION],[
4474 AC_MSG_CHECKING(if you want to use $1 for testing)
4475 AC_ARG_WITH($1,
4476         [$2],
4477         [AC_DEFINE($3)ifelse([$4],,[
4478          $4
4479 ])
4480         : ${with_cflags:=-g}
4481         : ${with_no_leaks:=yes}
4482          with_$1=yes],
4483         [with_$1=])
4484 AC_MSG_RESULT(${with_$1:-no})
4485
4486 case .$with_cflags in #(vi
4487 .*-g*)
4488         case .$CFLAGS in #(vi
4489         .*-g*) #(vi
4490                 ;;
4491         *)
4492                 CF_ADD_CFLAGS([-g])
4493                 ;;
4494         esac
4495         ;;
4496 esac
4497 ])dnl
4498 dnl ---------------------------------------------------------------------------
4499 dnl CF_NUMBER_SYNTAX version: 1 updated: 2003/09/20 18:12:49
4500 dnl ----------------
4501 dnl Check if the given variable is a number.  If not, report an error.
4502 dnl $1 is the variable
4503 dnl $2 is the message
4504 AC_DEFUN([CF_NUMBER_SYNTAX],[
4505 if test -n "$1" ; then
4506   case $1 in #(vi
4507   [[0-9]]*) #(vi
4508         ;;
4509   *)
4510         AC_MSG_ERROR($2 is not a number: $1)
4511         ;;
4512   esac
4513 else
4514   AC_MSG_ERROR($2 value is empty)
4515 fi
4516 ])dnl
4517 dnl ---------------------------------------------------------------------------
4518 dnl CF_OBJ_SUBDIR version: 4 updated: 2002/02/23 20:38:31
4519 dnl -------------
4520 dnl Compute the object-directory name from the given model name
4521 AC_DEFUN([CF_OBJ_SUBDIR],
4522 [
4523         case $1 in
4524         libtool) $2='obj_lo'  ;;
4525         normal)  $2='objects' ;;
4526         debug)   $2='obj_g' ;;
4527         profile) $2='obj_p' ;;
4528         shared)
4529                 case $cf_cv_system_name in #(vi
4530                 cygwin) #(vi
4531                         $2='objects' ;;
4532                 *)
4533                         $2='obj_s' ;;
4534                 esac
4535         esac
4536 ])dnl
4537 dnl ---------------------------------------------------------------------------
4538 dnl CF_PATHSEP version: 5 updated: 2010/05/26 05:38:42
4539 dnl ----------
4540 dnl Provide a value for the $PATH and similar separator
4541 AC_DEFUN([CF_PATHSEP],
4542 [
4543         case $cf_cv_system_name in
4544         os2*)   PATH_SEPARATOR=';'  ;;
4545         *)      PATH_SEPARATOR=':'  ;;
4546         esac
4547 ifelse([$1],,,[$1=$PATH_SEPARATOR])
4548         AC_SUBST(PATH_SEPARATOR)
4549 ])dnl
4550 dnl ---------------------------------------------------------------------------
4551 dnl CF_PATH_SYNTAX version: 13 updated: 2010/05/26 05:38:42
4552 dnl --------------
4553 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
4554 dnl begins with one of the prefix/exec_prefix variables, and then again if the
4555 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
4556 dnl delayed evaluation of those symbols.
4557 AC_DEFUN([CF_PATH_SYNTAX],[
4558 if test "x$prefix" != xNONE; then
4559   cf_path_syntax="$prefix"
4560 else
4561   cf_path_syntax="$ac_default_prefix"
4562 fi
4563
4564 case ".[$]$1" in #(vi
4565 .\[$]\(*\)*|.\'*\'*) #(vi
4566   ;;
4567 ..|./*|.\\*) #(vi
4568   ;;
4569 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
4570   ;;
4571 .\[$]{*prefix}*) #(vi
4572   eval $1="[$]$1"
4573   case ".[$]$1" in #(vi
4574   .NONE/*)
4575     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4576     ;;
4577   esac
4578   ;; #(vi
4579 .no|.NONE/*)
4580   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4581   ;;
4582 *)
4583   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
4584   ;;
4585 esac
4586 ])dnl
4587 dnl ---------------------------------------------------------------------------
4588 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
4589 dnl -------------
4590 dnl Check for the package-config program, unless disabled by command-line.
4591 AC_DEFUN([CF_PKG_CONFIG],
4592 [
4593 AC_MSG_CHECKING(if you want to use pkg-config)
4594 AC_ARG_WITH(pkg-config,
4595         [  --with-pkg-config{=path} enable/disable use of pkg-config],
4596         [cf_pkg_config=$withval],
4597         [cf_pkg_config=yes])
4598 AC_MSG_RESULT($cf_pkg_config)
4599
4600 case $cf_pkg_config in #(vi
4601 no) #(vi
4602         PKG_CONFIG=none
4603         ;;
4604 yes) #(vi
4605         CF_ACVERSION_CHECK(2.52,
4606                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
4607                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
4608         ;;
4609 *)
4610         PKG_CONFIG=$withval
4611         ;;
4612 esac
4613
4614 test -z "$PKG_CONFIG" && PKG_CONFIG=none
4615 if test "$PKG_CONFIG" != none ; then
4616         CF_PATH_SYNTAX(PKG_CONFIG)
4617 fi
4618
4619 AC_SUBST(PKG_CONFIG)
4620 ])dnl
4621 dnl ---------------------------------------------------------------------------
4622 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
4623 dnl -----------------
4624 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
4625 dnl
4626 dnl     POSIX.1-1990                            _POSIX_SOURCE
4627 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
4628 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
4629 dnl             Bindings Option
4630 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
4631 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
4632 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
4633 dnl
4634 dnl Parameters:
4635 dnl     $1 is the nominal value for _POSIX_C_SOURCE
4636 AC_DEFUN([CF_POSIX_C_SOURCE],
4637 [
4638 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
4639
4640 cf_save_CFLAGS="$CFLAGS"
4641 cf_save_CPPFLAGS="$CPPFLAGS"
4642
4643 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
4644 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
4645
4646 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
4647         CF_MSG_LOG(if the symbol is already defined go no further)
4648         AC_TRY_COMPILE([#include <sys/types.h>],[
4649 #ifndef _POSIX_C_SOURCE
4650 make an error
4651 #endif],
4652         [cf_cv_posix_c_source=no],
4653         [cf_want_posix_source=no
4654          case .$cf_POSIX_C_SOURCE in #(vi
4655          .[[12]]??*) #(vi
4656                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4657                 ;;
4658          .2) #(vi
4659                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4660                 cf_want_posix_source=yes
4661                 ;;
4662          .*)
4663                 cf_want_posix_source=yes
4664                 ;;
4665          esac
4666          if test "$cf_want_posix_source" = yes ; then
4667                 AC_TRY_COMPILE([#include <sys/types.h>],[
4668 #ifdef _POSIX_SOURCE
4669 make an error
4670 #endif],[],
4671                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
4672          fi
4673          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
4674          CFLAGS="$cf_trim_CFLAGS"
4675          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
4676          CF_MSG_LOG(if the second compile does not leave our definition intact error)
4677          AC_TRY_COMPILE([#include <sys/types.h>],[
4678 #ifndef _POSIX_C_SOURCE
4679 make an error
4680 #endif],,
4681          [cf_cv_posix_c_source=no])
4682          CFLAGS="$cf_save_CFLAGS"
4683          CPPFLAGS="$cf_save_CPPFLAGS"
4684         ])
4685 ])
4686
4687 if test "$cf_cv_posix_c_source" != no ; then
4688         CFLAGS="$cf_trim_CFLAGS"
4689         CPPFLAGS="$cf_trim_CPPFLAGS"
4690         CF_ADD_CFLAGS($cf_cv_posix_c_source)
4691 fi
4692
4693 ])dnl
4694 dnl ---------------------------------------------------------------------------
4695 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
4696 dnl ------------
4697 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
4698 dnl
4699 dnl $1 = symbol to test
4700 dnl $2 = value (if any) to use for a predefinition
4701 AC_DEFUN([CF_PREDEFINE],
4702 [
4703 AC_MSG_CHECKING(if we must define $1)
4704 AC_TRY_COMPILE([#include <sys/types.h>
4705 ],[
4706 #ifndef $1
4707 make an error
4708 #endif],[cf_result=no],[cf_result=yes])
4709 AC_MSG_RESULT($cf_result)
4710
4711 if test "$cf_result" = yes ; then
4712         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
4713 elif test "x$2" != "x" ; then
4714         AC_MSG_CHECKING(checking for compatible value versus $2)
4715         AC_TRY_COMPILE([#include <sys/types.h>
4716 ],[
4717 #if $1-$2 < 0
4718 make an error
4719 #endif],[cf_result=yes],[cf_result=no])
4720         AC_MSG_RESULT($cf_result)
4721         if test "$cf_result" = no ; then
4722                 # perhaps we can override it - try...
4723                 CPPFLAGS="$CPPFLAGS -D$1=$2"
4724         fi
4725 fi
4726 ])dnl
4727 dnl ---------------------------------------------------------------------------
4728 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
4729 dnl ------------
4730 dnl Append definitions and rules for the given programs to the subdirectory
4731 dnl Makefiles, and the recursion rule for the top-level Makefile.
4732 dnl
4733 dnl parameters
4734 dnl     $1 = script to run
4735 dnl     $2 = list of subdirectories
4736 dnl
4737 dnl variables
4738 dnl     $AWK
4739 AC_DEFUN([CF_PRG_RULES],
4740 [
4741 for cf_dir in $2
4742 do
4743         if test ! -d $srcdir/$cf_dir; then
4744                 continue
4745         elif test -f $srcdir/$cf_dir/programs; then
4746                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
4747         fi
4748 done
4749
4750 ])dnl
4751 dnl ---------------------------------------------------------------------------
4752 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
4753 dnl ----------
4754 dnl Check for archiver "ar".
4755 AC_DEFUN([CF_PROG_AR],[
4756 AC_CHECK_TOOL(AR, ar, ar)
4757 ])
4758 dnl ---------------------------------------------------------------------------
4759 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
4760 dnl -----------
4761 dnl Check for awk, ensure that the check found something.
4762 AC_DEFUN([CF_PROG_AWK],
4763 [
4764 AC_PROG_AWK
4765 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
4766 ])dnl
4767 dnl ---------------------------------------------------------------------------
4768 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
4769 dnl --------------
4770 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
4771 dnl the output file can be renamed, and allows for a shell variable that can
4772 dnl be used later.  The parameter is either CC or CXX.  The result is the
4773 dnl cache variable:
4774 dnl     $cf_cv_prog_CC_c_o
4775 dnl     $cf_cv_prog_CXX_c_o
4776 AC_DEFUN([CF_PROG_CC_C_O],
4777 [AC_REQUIRE([AC_PROG_CC])dnl
4778 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
4779 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
4780 [
4781 cat > conftest.$ac_ext <<CF_EOF
4782 #include <stdio.h>
4783 int main()
4784 {
4785         ${cf_cv_main_return:-return}(0);
4786 }
4787 CF_EOF
4788 # We do the test twice because some compilers refuse to overwrite an
4789 # existing .o file with -o, though they will create one.
4790 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
4791 if AC_TRY_EVAL(ac_try) &&
4792   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
4793 then
4794   eval cf_cv_prog_$1_c_o=yes
4795 else
4796   eval cf_cv_prog_$1_c_o=no
4797 fi
4798 rm -rf conftest*
4799 ])dnl
4800 if test $cf_cv_prog_$1_c_o = yes; then
4801   AC_MSG_RESULT([yes])
4802 else
4803   AC_MSG_RESULT([no])
4804 fi
4805 ])dnl
4806 dnl ---------------------------------------------------------------------------
4807 dnl CF_PROG_CC_U_D version: 1 updated: 2005/07/14 16:59:30
4808 dnl --------------
4809 dnl Check if C (preprocessor) -U and -D options are processed in the order
4810 dnl given rather than by type of option.  Some compilers insist on apply all
4811 dnl of the -U options after all of the -D options.  Others allow mixing them,
4812 dnl and may predefine symbols that conflict with those we define.
4813 AC_DEFUN([CF_PROG_CC_U_D],
4814 [
4815 AC_CACHE_CHECK(if $CC -U and -D options work together,cf_cv_cc_u_d_options,[
4816         cf_save_CPPFLAGS="$CPPFLAGS"
4817         CPPFLAGS="-UU_D_OPTIONS -DU_D_OPTIONS -DD_U_OPTIONS -UD_U_OPTIONS"
4818         AC_TRY_COMPILE([],[
4819 #ifndef U_D_OPTIONS
4820 make an undefined-error
4821 #endif
4822 #ifdef  D_U_OPTIONS
4823 make a defined-error
4824 #endif
4825         ],[
4826         cf_cv_cc_u_d_options=yes],[
4827         cf_cv_cc_u_d_options=no])
4828         CPPFLAGS="$cf_save_CPPFLAGS"
4829 ])
4830 ])dnl
4831 dnl ---------------------------------------------------------------------------
4832 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
4833 dnl -------------
4834 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
4835 dnl This macro adds a check to ensure the script found something.
4836 AC_DEFUN([CF_PROG_EGREP],
4837 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
4838    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
4839     then ac_cv_prog_egrep='grep -E'
4840     else ac_cv_prog_egrep='egrep'
4841     fi])
4842  EGREP=$ac_cv_prog_egrep
4843  AC_SUBST([EGREP])
4844 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
4845 ])dnl
4846 dnl ---------------------------------------------------------------------------
4847 dnl CF_PROG_EXT version: 10 updated: 2004/01/03 19:28:18
4848 dnl -----------
4849 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
4850 AC_DEFUN([CF_PROG_EXT],
4851 [
4852 AC_REQUIRE([CF_CHECK_CACHE])
4853 case $cf_cv_system_name in
4854 os2*)
4855     CFLAGS="$CFLAGS -Zmt"
4856     CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
4857     CXXFLAGS="$CXXFLAGS -Zmt"
4858     # autoconf's macro sets -Zexe and suffix both, which conflict:w
4859     LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
4860     ac_cv_exeext=.exe
4861     ;;
4862 esac
4863
4864 AC_EXEEXT
4865 AC_OBJEXT
4866
4867 PROG_EXT="$EXEEXT"
4868 AC_SUBST(PROG_EXT)
4869 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT")
4870 ])dnl
4871 dnl ---------------------------------------------------------------------------
4872 dnl CF_PROG_GNAT version: 2 updated: 2011/10/22 14:01:47
4873 dnl ------------
4874 dnl Check for gnatmake, ensure that it is complete.
4875 AC_DEFUN([CF_PROG_GNAT],[
4876 cf_ada_make=gnatmake
4877 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
4878 if test "$ac_cv_prog_gnat_exists" = no; then
4879    cf_ada_make=
4880    cf_cv_prog_gnat_correct=no
4881 else
4882    CF_GNAT_VERSION
4883    AC_CHECK_PROG(M4_exists, m4, yes, no)
4884    if test "$ac_cv_prog_M4_exists" = no; then
4885       cf_cv_prog_gnat_correct=no
4886       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
4887    fi
4888    if test "$cf_cv_prog_gnat_correct" = yes; then
4889       AC_MSG_CHECKING(if GNAT works)
4890       CF_GNAT_TRY_RUN([procedure conftest;],
4891 [with Text_IO;
4892 with GNAT.OS_Lib;
4893 procedure conftest is
4894 begin
4895    Text_IO.Put ("Hello World");
4896    Text_IO.New_Line;
4897    GNAT.OS_Lib.OS_Exit (0);
4898 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
4899       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
4900    fi
4901 fi
4902
4903 AC_SUBST(cf_ada_make)
4904 ])dnl
4905 dnl ---------------------------------------------------------------------------
4906 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
4907 dnl ---------------
4908 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
4909 dnl misc/tabset install won't work properly.  Usually this happens only when
4910 dnl using the fallback mkinstalldirs script
4911 AC_DEFUN([CF_PROG_INSTALL],
4912 [AC_PROG_INSTALL
4913 case $INSTALL in
4914 /*)
4915   ;;
4916 *)
4917   CF_DIRNAME(cf_dir,$INSTALL)
4918   test -z "$cf_dir" && cf_dir=.
4919   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
4920   ;;
4921 esac
4922 ])dnl
4923 dnl ---------------------------------------------------------------------------
4924 dnl CF_PROG_LDCONFIG version: 3 updated: 2011/06/04 20:09:13
4925 dnl ----------------
4926 dnl Check for ldconfig, needed to fixup shared libraries that would be built
4927 dnl and then used in the install.
4928 AC_DEFUN([CF_PROG_LDCONFIG],[
4929 if test "$cross_compiling" = yes ; then
4930   LDCONFIG=:
4931 else
4932 case "$cf_cv_system_name" in #(vi
4933 dragonfly*|mirbsd*|freebsd*) #(vi
4934   test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
4935   ;;
4936 *) LDPATH=$PATH:/sbin:/usr/sbin
4937   AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
4938   ;;
4939 esac
4940 fi
4941 AC_SUBST(LDCONFIG)
4942 ])dnl
4943 dnl ---------------------------------------------------------------------------
4944 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
4945 dnl ------------
4946 AC_DEFUN([CF_PROG_LINT],
4947 [
4948 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
4949 AC_SUBST(LINT_OPTS)
4950 ])dnl
4951 dnl ---------------------------------------------------------------------------
4952 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
4953 dnl ------------
4954 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
4955 dnl option if it is supported.
4956 AC_DEFUN([CF_PROG_LN_S],[
4957 AC_PROG_LN_S
4958 AC_MSG_CHECKING(if $LN_S -f options work)
4959
4960 rm -f conf$$.src conf$$dst
4961 echo >conf$$.dst
4962 echo first >conf$$.src
4963 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
4964         cf_prog_ln_sf=yes
4965 else
4966         cf_prog_ln_sf=no
4967 fi
4968 rm -f conf$$.dst conf$$src
4969 AC_MSG_RESULT($cf_prog_ln_sf)
4970
4971 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
4972 ])dnl
4973 dnl ---------------------------------------------------------------------------
4974 dnl CF_REGEX version: 8 updated: 2010/08/07 14:09:44
4975 dnl --------
4976 dnl Attempt to determine if we've got one of the flavors of regular-expression
4977 dnl code that we can support.
4978 AC_DEFUN([CF_REGEX],
4979 [
4980
4981 cf_regex_func=no
4982
4983 cf_regex_libs="regex re"
4984 case $host_os in #(vi
4985 mingw*)
4986         cf_regex_libs="regex.dll $cf_regex_libs"
4987         ;;
4988 esac
4989
4990 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
4991         for cf_regex_lib in $cf_regex_libs
4992         do
4993                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
4994                                 CF_ADD_LIB($cf_regex_lib)
4995                                 cf_regex_func=regcomp
4996                                 break])
4997         done
4998 ])
4999
5000 if test "$cf_regex_func" = no ; then
5001         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5002                 AC_CHECK_LIB(gen,compile,[
5003                                 CF_ADD_LIB(gen)
5004                                 cf_regex_func=compile])])
5005 fi
5006
5007 if test "$cf_regex_func" = no ; then
5008         AC_MSG_WARN(cannot find regular expression library)
5009 fi
5010
5011 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5012
5013 cf_cv_regex_hdrs=no
5014 case $cf_regex_func in #(vi
5015 compile) #(vi
5016         for cf_regex_hdr in regexp.h regexpr.h
5017         do
5018                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5019                         char *p = compile("", "", "", 0);
5020                         int x = step("", "");
5021                 ],[
5022                         cf_cv_regex_hdrs=$cf_regex_hdr
5023                         break
5024                 ])
5025         done
5026         ;;
5027 *)
5028         for cf_regex_hdr in regex.h
5029         do
5030                 AC_TRY_LINK([#include <sys/types.h>
5031 #include <$cf_regex_hdr>],[
5032                         regex_t *p;
5033                         int x = regcomp(p, "", 0);
5034                         int y = regexec(p, "", 0, 0, 0);
5035                         regfree(p);
5036                 ],[
5037                         cf_cv_regex_hdrs=$cf_regex_hdr
5038                         break
5039                 ])
5040         done
5041         ;;
5042 esac
5043
5044 ])
5045
5046 case $cf_cv_regex_hdrs in #(vi
5047     no)        AC_MSG_WARN(no regular expression header found) ;; #(vi
5048     regex.h)   AC_DEFINE(HAVE_REGEX_H_FUNCS) ;; #(vi
5049     regexp.h)  AC_DEFINE(HAVE_REGEXP_H_FUNCS) ;; #(vi
5050     regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS) ;;
5051 esac
5052 ])dnl
5053 dnl ---------------------------------------------------------------------------
5054 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5055 dnl ----------------
5056 dnl Remove all -U and -D options that refer to the given symbol from a list
5057 dnl of C compiler options.  This works around the problem that not all
5058 dnl compilers process -U and -D options from left-to-right, so a -U option
5059 dnl cannot be used to cancel the effect of a preceding -D option.
5060 dnl
5061 dnl $1 = target (which could be the same as the source variable)
5062 dnl $2 = source (including '$')
5063 dnl $3 = symbol to remove
5064 define([CF_REMOVE_DEFINE],
5065 [
5066 $1=`echo "$2" | \
5067         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5068                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5069 ])dnl
5070 dnl ---------------------------------------------------------------------------
5071 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5072 dnl -------------
5073 dnl Remove the given library from the symbol
5074 dnl
5075 dnl $1 = target (which could be the same as the source variable)
5076 dnl $2 = source (including '$')
5077 dnl $3 = library to remove
5078 define([CF_REMOVE_LIB],
5079 [
5080 # remove $3 library from $2
5081 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5082 ])dnl
5083 dnl ---------------------------------------------------------------------------
5084 dnl CF_RPATH_HACK version: 9 updated: 2011/02/13 13:31:33
5085 dnl -------------
5086 AC_DEFUN([CF_RPATH_HACK],
5087 [
5088 AC_REQUIRE([CF_LD_RPATH_OPT])
5089 AC_MSG_CHECKING(for updated LDFLAGS)
5090 if test -n "$LD_RPATH_OPT" ; then
5091         AC_MSG_RESULT(maybe)
5092
5093         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5094         cf_rpath_list="/usr/lib /lib"
5095         if test "$cf_ldd_prog" != no
5096         then
5097                 cf_rpath_oops=
5098
5099 AC_TRY_LINK([#include <stdio.h>],
5100                 [printf("Hello");],
5101                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort -u`
5102                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort -u`])
5103
5104                 # If we passed the link-test, but get a "not found" on a given library,
5105                 # this could be due to inept reconfiguration of gcc to make it only
5106                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5107                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5108                 # /usr/local libraries.
5109                 if test -n "$cf_rpath_oops"
5110                 then
5111                         for cf_rpath_src in $cf_rpath_oops
5112                         do
5113                                 for cf_rpath_dir in \
5114                                         /usr/local \
5115                                         /usr/pkg \
5116                                         /opt/sfw
5117                                 do
5118                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5119                                         then
5120                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5121                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5122                                                 break
5123                                         fi
5124                                 done
5125                         done
5126                 fi
5127         fi
5128
5129         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5130
5131         CF_RPATH_HACK_2(LDFLAGS)
5132         CF_RPATH_HACK_2(LIBS)
5133
5134         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5135 fi
5136 AC_SUBST(EXTRA_LDFLAGS)
5137 ])dnl
5138 dnl ---------------------------------------------------------------------------
5139 dnl CF_RPATH_HACK_2 version: 6 updated: 2010/04/17 16:31:24
5140 dnl ---------------
5141 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5142 dnl EXTRA_LDFLAGS for each -L option found.
5143 dnl
5144 dnl $cf_rpath_list contains a list of directories to ignore.
5145 dnl
5146 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5147 dnl      but LIBS often has misplaced -L options.
5148 AC_DEFUN([CF_RPATH_HACK_2],
5149 [
5150 CF_VERBOSE(...checking $1 [$]$1)
5151
5152 cf_rpath_dst=
5153 for cf_rpath_src in [$]$1
5154 do
5155         case $cf_rpath_src in #(vi
5156         -L*) #(vi
5157
5158                 # check if this refers to a directory which we will ignore
5159                 cf_rpath_skip=no
5160                 if test -n "$cf_rpath_list"
5161                 then
5162                         for cf_rpath_item in $cf_rpath_list
5163                         do
5164                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5165                                 then
5166                                         cf_rpath_skip=yes
5167                                         break
5168                                 fi
5169                         done
5170                 fi
5171
5172                 if test "$cf_rpath_skip" = no
5173                 then
5174                         # transform the option
5175                         if test "$LD_RPATH_OPT" = "-R " ; then
5176                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5177                         else
5178                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5179                         fi
5180
5181                         # if we have not already added this, add it now
5182                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5183                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5184                         then
5185                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5186                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5187                         fi
5188                 fi
5189                 ;;
5190         esac
5191         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5192 done
5193 $1=$cf_rpath_dst
5194
5195 CF_VERBOSE(...checked $1 [$]$1)
5196 AC_SUBST(EXTRA_LDFLAGS)
5197 ])dnl
5198 dnl ---------------------------------------------------------------------------
5199 dnl CF_SHARED_OPTS version: 69 updated: 2011/07/30 19:31:39
5200 dnl --------------
5201 dnl --------------
5202 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5203 dnl library.
5204 dnl
5205 dnl Note: ${LOCAL_LDFLAGS} is used to link executables that will run within the
5206 dnl build-tree, i.e., by making use of the libraries that are compiled in ../lib
5207 dnl We avoid compiling-in a ../lib path for the shared library since that can
5208 dnl lead to unexpected results at runtime.
5209 dnl ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared libraries
5210 dnl are compiled in ../../lib
5211 dnl
5212 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5213 dnl to install symbolic links to the rel/abi versions of shared libraries.
5214 dnl
5215 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5216 dnl version when making symbolic links.
5217 dnl
5218 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5219 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5220 dnl (ex: libncurses.so.<ver>).
5221 dnl
5222 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5223 AC_DEFUN([CF_SHARED_OPTS],
5224 [
5225         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
5226         AC_REQUIRE([CF_LD_RPATH_OPT])
5227         LOCAL_LDFLAGS=
5228         LOCAL_LDFLAGS2=
5229         LD_SHARED_OPTS=
5230         INSTALL_LIB="-m 644"
5231
5232         cf_cv_do_symlinks=no
5233         cf_ld_rpath_opt=
5234         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5235
5236         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5237         AC_ARG_WITH(shlib-version,
5238         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5239         [test -z "$withval" && withval=auto
5240         case $withval in #(vi
5241         yes) #(vi
5242                 cf_cv_shlib_version=auto
5243                 ;;
5244         rel|abi|auto|no) #(vi
5245                 cf_cv_shlib_version=$withval
5246                 ;;
5247         *)
5248                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
5249                 ;;
5250         esac
5251         ],[cf_cv_shlib_version=auto])
5252         AC_MSG_RESULT($cf_cv_shlib_version)
5253
5254         cf_cv_rm_so_locs=no
5255
5256         # Some less-capable ports of gcc support only -fpic
5257         CC_SHARED_OPTS=
5258         if test "$GCC" = yes
5259         then
5260                 AC_MSG_CHECKING(which $CC option to use)
5261                 cf_save_CFLAGS="$CFLAGS"
5262                 for CC_SHARED_OPTS in -fPIC -fpic ''
5263                 do
5264                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5265                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5266                 done
5267                 AC_MSG_RESULT($CC_SHARED_OPTS)
5268                 CFLAGS="$cf_save_CFLAGS"
5269         fi
5270
5271         cf_cv_shlib_version_infix=no
5272
5273         case $cf_cv_system_name in #(vi
5274         aix4.[3-9]*|aix[[5-7]]*) #(vi
5275                 if test "$GCC" = yes; then
5276                         CC_SHARED_OPTS=
5277                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5278                 else
5279                         # CC_SHARED_OPTS='-qpic=large -G'
5280                         # perhaps "-bM:SRE -bnoentry -bexpall"
5281                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5282                 fi
5283                 ;;
5284         beos*) #(vi
5285                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5286                 ;;
5287         cygwin*) #(vi
5288                 CC_SHARED_OPTS=
5289                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5290                 cf_cv_shlib_version=cygdll
5291                 cf_cv_shlib_version_infix=cygdll
5292                 cat >mk_shared_lib.sh <<-CF_EOF
5293                 #!/bin/sh
5294                 SHARED_LIB=\[$]1
5295                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5296                 shift
5297                 cat <<-EOF
5298                 Linking shared library
5299                 ** SHARED_LIB \[$]SHARED_LIB
5300                 ** IMPORT_LIB \[$]IMPORT_LIB
5301 EOF
5302                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
5303 CF_EOF
5304                 chmod +x mk_shared_lib.sh
5305                 ;;
5306         darwin*) #(vi
5307                 EXTRA_CFLAGS="-no-cpp-precomp"
5308                 CC_SHARED_OPTS="-dynamic"
5309                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5310                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5311                 cf_cv_shlib_version_infix=yes
5312                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5313                         cf_save_LDFLAGS=$LDFLAGS
5314                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5315                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5316                                 LDFLAGS=$cf_save_LDFLAGS])
5317                 if test $cf_cv_ldflags_search_paths_first = yes; then
5318                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5319                 fi
5320                 ;;
5321         hpux*) #(vi
5322                 # (tested with gcc 2.7.2 -- I don't have c89)
5323                 if test "$GCC" = yes; then
5324                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5325                 else
5326                         CC_SHARED_OPTS='+Z'
5327                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5328                 fi
5329                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5330                 # HP-UX shared libraries must be executable, and should be
5331                 # readonly to exploit a quirk in the memory manager.
5332                 INSTALL_LIB="-m 555"
5333                 ;;
5334         interix*)
5335                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5336                 if test "$cf_cv_shlib_version" = rel; then
5337                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5338                 else
5339                         cf_shared_soname='`basename $@`'
5340                 fi
5341                 CC_SHARED_OPTS=
5342                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5343                 ;;
5344         irix*) #(vi
5345                 if test "$cf_cv_enable_rpath" = yes ; then
5346                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5347                 fi
5348                 # tested with IRIX 5.2 and 'cc'.
5349                 if test "$GCC" != yes; then
5350                         CC_SHARED_OPTS='-KPIC'
5351                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5352                 else
5353                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5354                 fi
5355                 cf_cv_rm_so_locs=yes
5356                 ;;
5357         linux*|gnu*|k*bsd*-gnu) #(vi
5358                 if test "$DFT_LWR_MODEL" = "shared" ; then
5359                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5360                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5361                 fi
5362                 if test "$cf_cv_enable_rpath" = yes ; then
5363                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5364                 fi
5365                 CF_SHARED_SONAME
5366                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5367                 ;;
5368         openbsd[[2-9]].*|mirbsd*) #(vi
5369                 if test "$DFT_LWR_MODEL" = "shared" ; then
5370                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5371                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5372                 fi
5373                 if test "$cf_cv_enable_rpath" = yes ; then
5374                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5375                 fi
5376                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5377                 CF_SHARED_SONAME
5378                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5379                 ;;
5380         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
5381                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5382                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5383                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5384                 ;;
5385         dragonfly*|freebsd*) #(vi
5386                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5387                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5388                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5389                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
5390                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5391                 fi
5392                 CF_SHARED_SONAME
5393                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
5394                 ;;
5395         netbsd*) #(vi
5396                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5397                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5398                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5399                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5400                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5401                         if test "$cf_cv_shlib_version" = auto; then
5402                         if test -f /usr/libexec/ld.elf_so; then
5403                                 cf_cv_shlib_version=abi
5404                         else
5405                                 cf_cv_shlib_version=rel
5406                         fi
5407                         fi
5408                         CF_SHARED_SONAME
5409                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
5410                 else
5411                         MK_SHARED_LIB='${LD} -shared -Bshareable -o $[@]'
5412                 fi
5413                 ;;
5414         osf*|mls+*) #(vi
5415                 # tested with OSF/1 V3.2 and 'cc'
5416                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
5417                 # link with shared libs).
5418                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
5419                 case $host_os in #(vi
5420                 osf4*)
5421                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
5422                         ;;
5423                 esac
5424                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
5425                 if test "$DFT_LWR_MODEL" = "shared" ; then
5426                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5427                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5428                 fi
5429                 cf_cv_rm_so_locs=yes
5430                 ;;
5431         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
5432                 # tested with osr5.0.5
5433                 if test "$GCC" != yes; then
5434                         CC_SHARED_OPTS='-belf -KPIC'
5435                 fi
5436                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
5437                 if test "$cf_cv_enable_rpath" = yes ; then
5438                         # only way is to set LD_RUN_PATH but no switch for it
5439                         RUN_PATH=$libdir
5440                 fi
5441                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5442                 LINK_PROGS='LD_RUN_PATH=${libdir}'
5443                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
5444                 ;;
5445         sunos4*) #(vi
5446                 # tested with SunOS 4.1.1 and gcc 2.7.0
5447                 if test "$GCC" != yes; then
5448                         CC_SHARED_OPTS='-KPIC'
5449                 fi
5450                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
5451                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5452                 ;;
5453         solaris2*) #(vi
5454                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
5455                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
5456                 if test "$DFT_LWR_MODEL" = "shared" ; then
5457                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
5458                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5459                 fi
5460                 if test "$cf_cv_enable_rpath" = yes ; then
5461                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
5462                 fi
5463                 CF_SHARED_SONAME
5464                 if test "$GCC" != yes; then
5465                         cf_save_CFLAGS="$CFLAGS"
5466                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
5467                         do
5468                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
5469                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
5470                         done
5471                         CFLAGS="$cf_save_CFLAGS"
5472                         CC_SHARED_OPTS=$cf_shared_opts
5473                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5474                 else
5475                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5476                 fi
5477                 ;;
5478         sysv5uw7*|unix_sv*) #(vi
5479                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
5480                 if test "$GCC" != yes; then
5481                         CC_SHARED_OPTS='-KPIC'
5482                 fi
5483                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
5484                 ;;
5485         *)
5486                 CC_SHARED_OPTS='unknown'
5487                 MK_SHARED_LIB='echo unknown'
5488                 ;;
5489         esac
5490
5491         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
5492         case "$cf_cv_shlib_version" in #(vi
5493         rel|abi)
5494                 case "$MK_SHARED_LIB" in #(vi
5495                 *'-o $[@]') #(vi
5496                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
5497                         ;;
5498                 *)
5499                         AC_MSG_WARN(ignored --with-shlib-version)
5500                         ;;
5501                 esac
5502                 ;;
5503         esac
5504
5505         # RPATH_LIST is a colon-separated list of directories
5506         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
5507         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
5508
5509         AC_SUBST(CC_SHARED_OPTS)
5510         AC_SUBST(LD_RPATH_OPT)
5511         AC_SUBST(LD_SHARED_OPTS)
5512         AC_SUBST(MK_SHARED_LIB)
5513         AC_SUBST(LINK_PROGS)
5514         AC_SUBST(LINK_TESTS)
5515         AC_SUBST(EXTRA_LDFLAGS)
5516         AC_SUBST(LOCAL_LDFLAGS)
5517         AC_SUBST(LOCAL_LDFLAGS2)
5518         AC_SUBST(INSTALL_LIB)
5519         AC_SUBST(RPATH_LIST)
5520 ])dnl
5521 dnl ---------------------------------------------------------------------------
5522 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
5523 dnl ----------------
5524 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
5525 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
5526 dnl option.
5527 dnl
5528 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
5529 dnl If missing, use "rel".
5530 define([CF_SHARED_SONAME],
5531 [
5532         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
5533         if test "$cf_cv_shlib_version" = rel; then
5534                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
5535         else
5536                 cf_cv_shared_soname='`basename $[@]`'
5537         fi
5538 ])
5539 dnl ---------------------------------------------------------------------------
5540 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
5541 dnl -----------
5542 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
5543 dnl programs need this test).
5544 dnl
5545 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
5546 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
5547 dnl winsize declaration is left alone - we may revisit this if Apple choose to
5548 dnl break that part of the interface as well.
5549 AC_DEFUN([CF_SIGWINCH],
5550 [
5551 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
5552         AC_TRY_COMPILE([
5553 #include <sys/types.h>
5554 #include <sys/signal.h>
5555 ],[int x = SIGWINCH],
5556         [cf_cv_define_sigwinch=yes],
5557         [AC_TRY_COMPILE([
5558 #undef _XOPEN_SOURCE
5559 #undef _POSIX_SOURCE
5560 #undef _POSIX_C_SOURCE
5561 #include <sys/types.h>
5562 #include <sys/signal.h>
5563 ],[int x = SIGWINCH],
5564         [cf_cv_define_sigwinch=maybe],
5565         [cf_cv_define_sigwinch=no])
5566 ])
5567 ])
5568
5569 if test "$cf_cv_define_sigwinch" = maybe ; then
5570 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
5571 cf_cv_fixup_sigwinch=unknown
5572 cf_sigwinch=32
5573 while test $cf_sigwinch != 1
5574 do
5575         AC_TRY_COMPILE([
5576 #undef _XOPEN_SOURCE
5577 #undef _POSIX_SOURCE
5578 #undef _POSIX_C_SOURCE
5579 #include <sys/types.h>
5580 #include <sys/signal.h>
5581 ],[
5582 #if SIGWINCH != $cf_sigwinch
5583 make an error
5584 #endif
5585 int x = SIGWINCH],
5586         [cf_cv_fixup_sigwinch=$cf_sigwinch
5587          break])
5588
5589 cf_sigwinch=`expr $cf_sigwinch - 1`
5590 done
5591 ])
5592
5593         if test "$cf_cv_fixup_sigwinch" != unknown ; then
5594                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
5595         fi
5596 fi
5597 ])dnl
5598 dnl ---------------------------------------------------------------------------
5599 dnl CF_SIG_ATOMIC_T version: 2 updated: 2005/09/18 17:27:12
5600 dnl ---------------
5601 dnl signal handler, but there are some gcc depedencies in that recommendation.
5602 dnl Try anyway.
5603 AC_DEFUN([CF_SIG_ATOMIC_T],
5604 [
5605 AC_MSG_CHECKING(for signal global datatype)
5606 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
5607         for cf_type in \
5608                 "volatile sig_atomic_t" \
5609                 "sig_atomic_t" \
5610                 "int"
5611         do
5612         AC_TRY_COMPILE([
5613 #include <sys/types.h>
5614 #include <signal.h>
5615 #include <stdio.h>
5616
5617 extern $cf_type x;
5618 $cf_type x;
5619 static void handler(int sig)
5620 {
5621         x = 5;
5622 }],
5623                 [signal(SIGINT, handler);
5624                  x = 1],
5625                 [cf_cv_sig_atomic_t=$cf_type],
5626                 [cf_cv_sig_atomic_t=no])
5627                 test "$cf_cv_sig_atomic_t" != no && break
5628         done
5629         ])
5630 AC_MSG_RESULT($cf_cv_sig_atomic_t)
5631 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t)
5632 ])dnl
5633 dnl ---------------------------------------------------------------------------
5634 dnl CF_SIZECHANGE version: 8 updated: 2000/11/04 12:22:16
5635 dnl -------------
5636 dnl Check for definitions & structures needed for window size-changing
5637 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
5638 AC_DEFUN([CF_SIZECHANGE],
5639 [
5640 AC_REQUIRE([CF_STRUCT_TERMIOS])
5641 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
5642     cf_cv_sizechange=unknown
5643     cf_save_CPPFLAGS="$CPPFLAGS"
5644
5645 for cf_opts in "" "NEED_PTEM_H"
5646 do
5647
5648     CPPFLAGS="$cf_save_CPPFLAGS"
5649     test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
5650     AC_TRY_COMPILE([#include <sys/types.h>
5651 #ifdef HAVE_TERMIOS_H
5652 #include <termios.h>
5653 #else
5654 #ifdef HAVE_TERMIO_H
5655 #include <termio.h>
5656 #endif
5657 #endif
5658 #ifdef NEED_PTEM_H
5659 /* This is a workaround for SCO:  they neglected to define struct winsize in
5660  * termios.h -- it's only in termio.h and ptem.h
5661  */
5662 #include        <sys/stream.h>
5663 #include        <sys/ptem.h>
5664 #endif
5665 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
5666 #include <sys/ioctl.h>
5667 #endif
5668 ],[
5669 #ifdef TIOCGSIZE
5670         struct ttysize win;     /* FIXME: what system is this? */
5671         int y = win.ts_lines;
5672         int x = win.ts_cols;
5673 #else
5674 #ifdef TIOCGWINSZ
5675         struct winsize win;
5676         int y = win.ws_row;
5677         int x = win.ws_col;
5678 #else
5679         no TIOCGSIZE or TIOCGWINSZ
5680 #endif /* TIOCGWINSZ */
5681 #endif /* TIOCGSIZE */
5682         ],
5683         [cf_cv_sizechange=yes],
5684         [cf_cv_sizechange=no])
5685
5686         CPPFLAGS="$cf_save_CPPFLAGS"
5687         if test "$cf_cv_sizechange" = yes ; then
5688                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
5689                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
5690                 break
5691         fi
5692 done
5693 ])
5694 if test "$cf_cv_sizechange" != no ; then
5695         AC_DEFINE(HAVE_SIZECHANGE)
5696         case $cf_cv_sizechange in #(vi
5697         NEED*)
5698                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
5699                 ;;
5700         esac
5701 fi
5702 ])dnl
5703 dnl ---------------------------------------------------------------------------
5704 dnl CF_SRC_MODULES version: 24 updated: 2011/12/10 18:58:47
5705 dnl --------------
5706 dnl For each parameter, test if the source-directory exists, and if it contains
5707 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
5708 dnl use in CF_LIB_RULES.
5709 dnl
5710 dnl This uses the configured value to make the lists SRC_SUBDIRS and
5711 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
5712 AC_DEFUN([CF_SRC_MODULES],
5713 [
5714 AC_MSG_CHECKING(for src modules)
5715
5716 # dependencies and linker-arguments for test-programs
5717 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
5718 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
5719 if test "$DFT_LWR_MODEL" = "libtool"; then
5720         TEST_ARGS="${TEST_DEPS}"
5721         TEST_ARG2="${TEST_DEP2}"
5722 else
5723         TEST_ARGS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
5724         TEST_ARG2="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARG2"
5725 fi
5726
5727 PC_MODULES_TO_MAKE="ncurses"
5728 cf_cv_src_modules=
5729 for cf_dir in $1
5730 do
5731         if test -f $srcdir/$cf_dir/modules; then
5732
5733                 # We may/may not have tack in the distribution, though the
5734                 # makefile is.
5735                 if test $cf_dir = tack ; then
5736                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
5737                                 continue
5738                         fi
5739                 fi
5740
5741                 if test -z "$cf_cv_src_modules"; then
5742                         cf_cv_src_modules=$cf_dir
5743                 else
5744                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
5745                 fi
5746
5747                 # Make the ncurses_cfg.h file record the library interface files as
5748                 # well.  These are header files that are the same name as their
5749                 # directory.  Ncurses is the only library that does not follow
5750                 # that pattern.
5751                 if test $cf_dir = tack ; then
5752                         continue
5753                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
5754                         CF_UPPER(cf_have_include,$cf_dir)
5755                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
5756                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
5757                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
5758                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
5759                         if test "$DFT_LWR_MODEL" = "libtool"; then
5760                                 TEST_ARGS="${TEST_DEPS}"
5761                                 TEST_ARG2="${TEST_DEP2}"
5762                         else
5763                                 TEST_ARGS="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARGS"
5764                                 TEST_ARG2="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARG2"
5765                         fi
5766                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}"
5767                 fi
5768         fi
5769 done
5770 AC_MSG_RESULT($cf_cv_src_modules)
5771
5772 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
5773 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
5774
5775 AC_SUBST(TEST_ARGS)
5776 AC_SUBST(TEST_DEPS)
5777
5778 AC_SUBST(TEST_ARG2)
5779 AC_SUBST(TEST_DEP2)
5780
5781 SRC_SUBDIRS=
5782 if test "x$cf_with_manpages" != xno ; then
5783         SRC_SUBDIRS="$SRC_SUBDIRS man"
5784 fi
5785 SRC_SUBDIRS="$SRC_SUBDIRS include"
5786 for cf_dir in $cf_cv_src_modules
5787 do
5788         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
5789 done
5790 if test "x$cf_with_tests" != "xno" ; then
5791         SRC_SUBDIRS="$SRC_SUBDIRS test"
5792 fi
5793 test -z "$MAKE_TERMINFO" && SRC_SUBDIRS="$SRC_SUBDIRS misc"
5794 if test "$cf_with_cxx_binding" != no; then
5795         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++"
5796         SRC_SUBDIRS="$SRC_SUBDIRS c++"
5797 fi
5798
5799 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_NAME"
5800 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE tic"
5801
5802 AC_SUBST(PC_MODULES_TO_MAKE)
5803
5804 ADA_SUBDIRS=
5805 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
5806         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
5807         ADA_SUBDIRS="gen src"
5808         if test "x$cf_with_tests" != "xno" ; then
5809                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
5810         fi
5811 fi
5812
5813 SUB_MAKEFILES=
5814 for cf_dir in $SRC_SUBDIRS
5815 do
5816         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
5817 done
5818
5819 if test -n "$ADA_SUBDIRS"; then
5820         for cf_dir in $ADA_SUBDIRS
5821         do
5822                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
5823         done
5824         AC_SUBST(ADA_SUBDIRS)
5825 fi
5826 ])dnl
5827 dnl ---------------------------------------------------------------------------
5828 dnl CF_STDCPP_LIBRARY version: 7 updated: 2010/05/29 16:31:02
5829 dnl -----------------
5830 dnl Check for -lstdc++, which is GNU's standard C++ library.
5831 AC_DEFUN([CF_STDCPP_LIBRARY],
5832 [
5833 if test -n "$GXX" ; then
5834 case $cf_cv_system_name in #(vi
5835 os2*) #(vi
5836         cf_stdcpp_libname=stdcpp
5837         ;;
5838 *)
5839         cf_stdcpp_libname=stdc++
5840         ;;
5841 esac
5842 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
5843         cf_save="$LIBS"
5844         CF_ADD_LIB($cf_stdcpp_libname)
5845 AC_TRY_LINK([
5846 #include <strstream.h>],[
5847 char buf[80];
5848 strstreambuf foo(buf, sizeof(buf))
5849 ],
5850         [cf_cv_libstdcpp=yes],
5851         [cf_cv_libstdcpp=no])
5852         LIBS="$cf_save"
5853 ])
5854 test "$cf_cv_libstdcpp" = yes && CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS)
5855 fi
5856 ])dnl
5857 dnl ---------------------------------------------------------------------------
5858 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
5859 dnl --------------
5860 dnl     Remove "-g" option from the compiler options
5861 AC_DEFUN([CF_STRIP_G_OPT],
5862 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
5863 dnl ---------------------------------------------------------------------------
5864 dnl CF_STRUCT_SIGACTION version: 4 updated: 2011/04/16 11:52:53
5865 dnl -------------------
5866 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
5867 dnl do this if we've found the sigaction function.
5868 AC_DEFUN([CF_STRUCT_SIGACTION],[
5869 AC_REQUIRE([CF_XOPEN_SOURCE])
5870
5871 if test "$ac_cv_func_sigaction" = yes; then
5872 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
5873 AC_TRY_COMPILE([
5874 #include <sys/types.h>
5875 #include <signal.h>],
5876         [struct sigaction act],
5877         [sigact_bad=no],
5878         [
5879 AC_TRY_COMPILE([
5880 #define _POSIX_SOURCE
5881 #include <sys/types.h>
5882 #include <signal.h>],
5883         [struct sigaction act],
5884         [sigact_bad=yes
5885          AC_DEFINE(_POSIX_SOURCE)],
5886          [sigact_bad=unknown])])
5887 AC_MSG_RESULT($sigact_bad)
5888 fi
5889 ])dnl
5890 dnl ---------------------------------------------------------------------------
5891 dnl CF_STRUCT_TERMIOS version: 6 updated: 2011/04/16 11:52:53
5892 dnl -----------------
5893 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
5894 AC_DEFUN([CF_STRUCT_TERMIOS],[
5895 AC_REQUIRE([CF_XOPEN_SOURCE])
5896
5897 AC_CHECK_HEADERS( \
5898 termio.h \
5899 termios.h \
5900 unistd.h \
5901 )
5902
5903 if test "$ISC" = yes ; then
5904         AC_CHECK_HEADERS( sys/termio.h )
5905 fi
5906 if test "$ac_cv_header_termios_h" = yes ; then
5907         case "$CFLAGS $CPPFLAGS" in
5908         *-D_POSIX_SOURCE*)
5909                 termios_bad=dunno ;;
5910         *)      termios_bad=maybe ;;
5911         esac
5912         if test "$termios_bad" = maybe ; then
5913         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
5914         AC_TRY_COMPILE([#include <termios.h>],
5915                 [struct termios foo; int x = foo.c_iflag],
5916                 termios_bad=no, [
5917                 AC_TRY_COMPILE([
5918 #define _POSIX_SOURCE
5919 #include <termios.h>],
5920                         [struct termios foo; int x = foo.c_iflag],
5921                         termios_bad=unknown,
5922                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE))
5923                         ])
5924         AC_MSG_RESULT($termios_bad)
5925         fi
5926 fi
5927 ])dnl
5928 dnl ---------------------------------------------------------------------------
5929 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
5930 dnl --------------
5931 dnl Construct a search-list for a nonstandard header/lib-file
5932 dnl     $1 = the variable to return as result
5933 dnl     $2 = the package name
5934 dnl     $3 = the subdirectory, e.g., bin, include or lib
5935 AC_DEFUN([CF_SUBDIR_PATH],
5936 [
5937 $1=
5938
5939 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
5940 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
5941 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
5942 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
5943 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
5944 ])dnl
5945 dnl ---------------------------------------------------------------------------
5946 dnl CF_SUBST version: 4 updated: 2006/06/17 12:33:03
5947 dnl --------
5948 dnl     Shorthand macro for substituting things that the user may override
5949 dnl     with an environment variable.
5950 dnl
5951 dnl     $1 = long/descriptive name
5952 dnl     $2 = environment variable
5953 dnl     $3 = default value
5954 AC_DEFUN([CF_SUBST],
5955 [AC_CACHE_VAL(cf_cv_subst_$2,[
5956 AC_MSG_CHECKING(for $1 (symbol $2))
5957 CF_SUBST_IF([-z "[$]$2"], [$2], [$3])
5958 cf_cv_subst_$2=[$]$2
5959 AC_MSG_RESULT([$]$2)
5960 ])
5961 ])dnl
5962 dnl ---------------------------------------------------------------------------
5963 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
5964 dnl -----------
5965 dnl     Shorthand macro for substituting things that the user may override
5966 dnl     with an environment variable.
5967 dnl
5968 dnl     $1 = condition to pass to "test"
5969 dnl     $2 = environment variable
5970 dnl     $3 = value if the test succeeds
5971 dnl     $4 = value if the test fails
5972 AC_DEFUN([CF_SUBST_IF],
5973 [
5974 if test $1 ; then
5975         $2=$3
5976 ifelse($4,,,[else
5977         $2=$4])
5978 fi
5979 AC_SUBST($2)
5980 ])dnl
5981 dnl ---------------------------------------------------------------------------
5982 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
5983 dnl ------------------------
5984 dnl Get the version-number for use in shared-library naming, etc.
5985 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
5986 [
5987 AC_REQUIRE([CF_PROG_EGREP])
5988 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
5989 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
5990 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
5991 cf_cv_abi_version=${NCURSES_MAJOR}
5992 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
5993 dnl Show the computed version, for logging
5994 cf_cv_timestamp=`date`
5995 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
5996 dnl We need these values in the generated headers
5997 AC_SUBST(NCURSES_MAJOR)
5998 AC_SUBST(NCURSES_MINOR)
5999 AC_SUBST(NCURSES_PATCH)
6000 dnl We need these values in the generated makefiles
6001 AC_SUBST(cf_cv_rel_version)
6002 AC_SUBST(cf_cv_abi_version)
6003 AC_SUBST(cf_cv_builtin_bool)
6004 AC_SUBST(cf_cv_header_stdbool_h)
6005 AC_SUBST(cf_cv_type_of_bool)dnl
6006 ])dnl
6007 dnl ---------------------------------------------------------------------------
6008 dnl CF_SYS_TIME_SELECT version: 4 updated: 2000/10/04 09:18:40
6009 dnl ------------------
6010 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6011 dnl older SCO configurations.
6012 AC_DEFUN([CF_SYS_TIME_SELECT],
6013 [
6014 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6015 AC_CACHE_VAL(cf_cv_sys_time_select,[
6016 AC_TRY_COMPILE([
6017 #include <sys/types.h>
6018 #ifdef HAVE_SYS_TIME_H
6019 #include <sys/time.h>
6020 #endif
6021 #ifdef HAVE_SYS_SELECT_H
6022 #include <sys/select.h>
6023 #endif
6024 ],[],[cf_cv_sys_time_select=yes],
6025      [cf_cv_sys_time_select=no])
6026      ])
6027 AC_MSG_RESULT($cf_cv_sys_time_select)
6028 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT)
6029 ])dnl
6030 dnl ---------------------------------------------------------------------------
6031 dnl CF_TOP_BUILDDIR version: 1 updated: 2006/10/15 16:33:23
6032 dnl ---------------
6033 dnl Define a top_builddir symbol, for applications that need an absolute path.
6034 AC_DEFUN([CF_TOP_BUILDDIR],
6035 [
6036 top_builddir=`pwd`
6037 AC_SUBST(top_builddir)
6038 ])dnl
6039 dnl ---------------------------------------------------------------------------
6040 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6041 dnl -------------------
6042 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6043 dnl can define it successfully.
6044 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6045 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6046         AC_TRY_COMPILE([
6047 #include <stdlib.h>
6048 #include <string.h>
6049 #include <sys/types.h>
6050 ],[
6051 #ifndef _XOPEN_SOURCE
6052 make an error
6053 #endif],
6054         [cf_cv_xopen_source=no],
6055         [cf_save="$CPPFLAGS"
6056          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6057          AC_TRY_COMPILE([
6058 #include <stdlib.h>
6059 #include <string.h>
6060 #include <sys/types.h>
6061 ],[
6062 #ifdef _XOPEN_SOURCE
6063 make an error
6064 #endif],
6065         [cf_cv_xopen_source=no],
6066         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6067         CPPFLAGS="$cf_save"
6068         ])
6069 ])
6070
6071 if test "$cf_cv_xopen_source" != no ; then
6072         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6073         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6074         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6075         CF_ADD_CFLAGS($cf_temp_xopen_source)
6076 fi
6077 ])
6078 dnl ---------------------------------------------------------------------------
6079 dnl CF_TYPEOF_CHTYPE version: 8 updated: 2006/12/16 12:33:30
6080 dnl ----------------
6081 dnl Determine the type we should use for chtype (and attr_t, which is treated
6082 dnl as the same thing).  We want around 32 bits, so on most machines want a
6083 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6084 dnl wide characters, we have to have a type compatible with that, as well.
6085 AC_DEFUN([CF_TYPEOF_CHTYPE],
6086 [
6087 AC_MSG_CHECKING([for type of chtype])
6088 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6089                 AC_TRY_RUN([
6090 #define WANT_BITS 31
6091 #include <stdio.h>
6092 int main()
6093 {
6094         FILE *fp = fopen("cf_test.out", "w");
6095         if (fp != 0) {
6096                 char *result = "long";
6097                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6098                         int n;
6099                         unsigned int x, y;
6100                         for (n = 0; n < WANT_BITS; n++) {
6101                                 x = (1 << n);
6102                                 y = (x >> n);
6103                                 if (y != 1 || x == 0) {
6104                                         x = 0;
6105                                         break;
6106                                 }
6107                         }
6108                         /*
6109                          * If x is nonzero, an int is big enough for the bits
6110                          * that we want.
6111                          */
6112                         result = (x != 0) ? "int" : "long";
6113                 }
6114                 fputs(result, fp);
6115                 fclose(fp);
6116         }
6117         ${cf_cv_main_return:-return}(0);
6118 }
6119                 ],
6120                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6121                 [cf_cv_typeof_chtype=long],
6122                 [cf_cv_typeof_chtype=long])
6123                 rm -f cf_test.out
6124         ])
6125 AC_MSG_RESULT($cf_cv_typeof_chtype)
6126
6127 AC_SUBST(cf_cv_typeof_chtype)
6128 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype)
6129 ])dnl
6130 dnl ---------------------------------------------------------------------------
6131 dnl CF_TYPE_SIGACTION version: 3 updated: 2000/08/12 23:18:52
6132 dnl -----------------
6133 dnl
6134 AC_DEFUN([CF_TYPE_SIGACTION],
6135 [
6136 AC_MSG_CHECKING([for type sigaction_t])
6137 AC_CACHE_VAL(cf_cv_type_sigaction,[
6138         AC_TRY_COMPILE([
6139 #include <signal.h>],
6140                 [sigaction_t x],
6141                 [cf_cv_type_sigaction=yes],
6142                 [cf_cv_type_sigaction=no])])
6143 AC_MSG_RESULT($cf_cv_type_sigaction)
6144 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION)
6145 ])dnl
6146 dnl ---------------------------------------------------------------------------
6147 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6148 dnl --------------------
6149 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6150 dnl won't, but they're still there.
6151 AC_DEFUN([CF_UNSIGNED_LITERALS],
6152 [
6153 AC_MSG_CHECKING([if unsigned literals are legal])
6154 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6155         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6156                 [cf_cv_unsigned_literals=yes],
6157                 [cf_cv_unsigned_literals=no])
6158         ])
6159 AC_MSG_RESULT($cf_cv_unsigned_literals)
6160 ])dnl
6161 dnl ---------------------------------------------------------------------------
6162 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6163 dnl --------
6164 dnl Make an uppercase version of a variable
6165 dnl $1=uppercase($2)
6166 AC_DEFUN([CF_UPPER],
6167 [
6168 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6169 ])dnl
6170 dnl ---------------------------------------------------------------------------
6171 dnl CF_UTF8_LIB version: 7 updated: 2010/06/20 09:24:28
6172 dnl -----------
6173 dnl Check for multibyte support, and if not found, utf8 compatibility library
6174 AC_DEFUN([CF_UTF8_LIB],
6175 [
6176 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6177         cf_save_LIBS="$LIBS"
6178         AC_TRY_LINK([
6179 #include <stdlib.h>],[putwc(0,0);],
6180         [cf_cv_utf8_lib=yes],
6181         [CF_FIND_LINKAGE([
6182 #include <libutf8.h>],[putwc(0,0);],utf8,
6183                 [cf_cv_utf8_lib=add-on],
6184                 [cf_cv_utf8_lib=no])
6185 ])])
6186
6187 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6188 # ncurses/ncursesw:
6189 if test "$cf_cv_utf8_lib" = "add-on" ; then
6190         AC_DEFINE(HAVE_LIBUTF8_H)
6191         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6192         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6193         CF_ADD_LIBS($cf_cv_library_file_utf8)
6194 fi
6195 ])dnl
6196 dnl ---------------------------------------------------------------------------
6197 dnl CF_VA_COPY version: 2 updated: 2010/03/04 05:37:29
6198 dnl ----------
6199 dnl check for va_copy, part of stdarg.h
6200 dnl Also, workaround for glibc's __va_copy, by checking for both.
6201 AC_DEFUN([CF_VA_COPY],[
6202 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6203 AC_TRY_LINK([
6204 #include <stdarg.h>
6205 ],[
6206         static va_list dst;
6207         static va_list src;
6208         va_copy(dst, src)],
6209         cf_cv_have_va_copy=yes,
6210         cf_cv_have_va_copy=no)])
6211
6212 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY)
6213
6214 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6215 AC_TRY_LINK([
6216 #include <stdarg.h>
6217 ],[
6218         static va_list dst;
6219         static va_list src;
6220         __va_copy(dst, src)],
6221         cf_cv_have___va_copy=yes,
6222         cf_cv_have___va_copy=no)])
6223
6224 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY)
6225 ])
6226 dnl ---------------------------------------------------------------------------
6227 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6228 dnl ----------
6229 dnl Use AC_VERBOSE w/o the warnings
6230 AC_DEFUN([CF_VERBOSE],
6231 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6232 CF_MSG_LOG([$1])
6233 ])dnl
6234 dnl ---------------------------------------------------------------------------
6235 dnl CF_WCHAR_TYPE version: 3 updated: 2010/05/26 16:44:57
6236 dnl -------------
6237 dnl Check if type wide-character type $1 is declared, and if so, which header
6238 dnl file is needed.  The second parameter is used to set a shell variable when
6239 dnl the type is not found.  The first parameter sets a shell variable for the
6240 dnl opposite sense.
6241 AC_DEFUN([CF_WCHAR_TYPE],
6242 [
6243 # This is needed on Tru64 5.0 to declare $1
6244 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6245 AC_TRY_COMPILE([
6246 #include <stdlib.h>
6247 #include <stdarg.h>
6248 #include <stdio.h>
6249 #ifdef HAVE_LIBUTF8_H
6250 #include <libutf8.h>
6251 #endif],
6252         [$1 state],
6253         [cf_cv_$1=no],
6254         [AC_TRY_COMPILE([
6255 #include <stdlib.h>
6256 #include <stdarg.h>
6257 #include <stdio.h>
6258 #include <wchar.h>
6259 #ifdef HAVE_LIBUTF8_H
6260 #include <libutf8.h>
6261 #endif],
6262         [$1 value],
6263         [cf_cv_$1=yes],
6264         [cf_cv_$1=unknown])])])
6265
6266 if test "$cf_cv_$1" = yes ; then
6267         AC_DEFINE(NEED_WCHAR_H)
6268         NEED_WCHAR_H=1
6269 fi
6270
6271 ifelse([$2],,,[
6272 # if we do not find $1 in either place, use substitution to provide a fallback.
6273 if test "$cf_cv_$1" = unknown ; then
6274         $2=1
6275 fi
6276 ])
6277 ifelse($3,,,[
6278 # if we find $1 in either place, use substitution to provide a fallback.
6279 if test "$cf_cv_$1" != unknown ; then
6280         $3=1
6281 fi
6282 ])
6283 ])dnl
6284 dnl ---------------------------------------------------------------------------
6285 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
6286 dnl ---------------
6287 dnl Check for compiler-support for weak symbols.
6288 dnl This works with "recent" gcc.
6289 AC_DEFUN([CF_WEAK_SYMBOLS],[
6290 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
6291
6292 AC_TRY_COMPILE([
6293 #include <stdio.h>],
6294 [
6295 #if defined(__GNUC__)
6296 #  if defined __USE_ISOC99
6297 #    define _cat_pragma(exp)    _Pragma(#exp)
6298 #    define _weak_pragma(exp)   _cat_pragma(weak name)
6299 #  else
6300 #    define _weak_pragma(exp)
6301 #  endif
6302 #  define _declare(name)        __extension__ extern __typeof__(name) name
6303 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
6304 #endif
6305
6306 weak_symbol(fopen);
6307 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
6308 ])
6309 ])dnl
6310 dnl ---------------------------------------------------------------------------
6311 dnl CF_WITH_ABI_VERSION version: 1 updated: 2003/09/20 18:12:49
6312 dnl -------------------
6313 dnl Allow library's ABI to be overridden.  Generally this happens when a
6314 dnl packager has incremented the ABI past that used in the original package,
6315 dnl and wishes to keep doing this.
6316 dnl
6317 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6318 dnl symbol.
6319 AC_DEFUN([CF_WITH_ABI_VERSION],[
6320 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
6321 AC_ARG_WITH(abi-version,
6322 [  --with-abi-version=XXX  override derived ABI version],
6323 [AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
6324  cf_cv_abi_version=$withval])
6325  CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
6326 ifelse($1,,,[
6327 $1_ABI=$cf_cv_abi_version
6328 ])
6329 ])dnl
6330 dnl ---------------------------------------------------------------------------
6331 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
6332 dnl --------------------
6333 dnl Command-line option to specify the Ada95 compiler.
6334 AC_DEFUN([CF_WITH_ADA_COMPILER],[
6335 AC_MSG_CHECKING(for ada-compiler)
6336 AC_ARG_WITH(ada-compiler,
6337         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
6338         [cf_ada_compiler=$withval],
6339         [cf_ada_compiler=gnatmake])
6340 AC_SUBST(cf_ada_compiler)
6341 AC_MSG_RESULT($cf_ada_compiler)
6342 ])dnl
6343 dnl ---------------------------------------------------------------------------
6344 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
6345 dnl -------------------
6346 dnl Command-line option to specify where Ada includes will install.
6347 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
6348 AC_MSG_CHECKING(for ada-include)
6349 CF_WITH_PATH(ada-include,
6350    [  --with-ada-include=DIR  Ada includes are in DIR],
6351    ADA_INCLUDE,
6352    PREFIX/share/ada/adainclude,
6353    [$]prefix/share/ada/adainclude)
6354 AC_SUBST(ADA_INCLUDE)
6355 AC_MSG_RESULT($ADA_INCLUDE)
6356 ])dnl
6357 dnl ---------------------------------------------------------------------------
6358 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
6359 dnl -------------------
6360 dnl Command-line option to specify where Ada objects will install.
6361 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
6362 AC_MSG_CHECKING(for ada-objects)
6363 CF_WITH_PATH(ada-objects,
6364    [  --with-ada-objects=DIR  Ada objects are in DIR],
6365    ADA_OBJECTS,
6366    PREFIX/lib/ada/adalib,
6367    [$]prefix/lib/ada/adalib)
6368 AC_SUBST(ADA_OBJECTS)
6369 AC_MSG_RESULT($ADA_OBJECTS)
6370 ])dnl
6371 dnl ---------------------------------------------------------------------------
6372 dnl CF_WITH_ADA_SHAREDLIB version: 2 updated: 2010/06/26 17:35:58
6373 dnl ---------------------
6374 dnl Command-line option to specify if an Ada95 shared-library should be built,
6375 dnl and optionally what its soname should be.
6376 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
6377 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
6378 AC_ARG_WITH(ada-sharedlib,
6379         [  --with-ada-sharedlib=XX build Ada95 shared-library],
6380         [with_ada_sharedlib=$withval],
6381         [with_ada_sharedlib=no])
6382 AC_MSG_RESULT($with_ada_sharedlib)
6383
6384 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
6385 MAKE_ADA_SHAREDLIB="#"
6386
6387 if test "x$with_ada_sharedlib" != xno
6388 then
6389         MAKE_ADA_SHAREDLIB=
6390         if test "x$with_ada_sharedlib" != xyes
6391         then
6392                 ADA_SHAREDLIB="$with_ada_sharedlib"
6393         fi
6394 fi
6395
6396 AC_SUBST(ADA_SHAREDLIB)
6397 AC_SUBST(MAKE_ADA_SHAREDLIB)
6398 ])dnl
6399 dnl ---------------------------------------------------------------------------
6400 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
6401 dnl ----------------
6402 dnl Configure-option for dbmalloc.  The optional parameter is used to override
6403 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6404 AC_DEFUN([CF_WITH_DBMALLOC],[
6405 CF_NO_LEAKS_OPTION(dbmalloc,
6406         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
6407         [USE_DBMALLOC])
6408
6409 if test "$with_dbmalloc" = yes ; then
6410         AC_CHECK_HEADER(dbmalloc.h,
6411                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
6412 fi
6413 ])dnl
6414 dnl ---------------------------------------------------------------------------
6415 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
6416 dnl ---------------
6417 dnl Configure-option for dmalloc.  The optional parameter is used to override
6418 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6419 AC_DEFUN([CF_WITH_DMALLOC],[
6420 CF_NO_LEAKS_OPTION(dmalloc,
6421         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
6422         [USE_DMALLOC])
6423
6424 if test "$with_dmalloc" = yes ; then
6425         AC_CHECK_HEADER(dmalloc.h,
6426                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
6427 fi
6428 ])dnl
6429 dnl ---------------------------------------------------------------------------
6430 dnl CF_WITH_GPM version: 7 updated: 2008/03/23 14:48:54
6431 dnl -----------
6432 dnl
6433 dnl The option parameter (if neither yes/no) is assumed to be the name of
6434 dnl the gpm library, e.g., for dynamic loading.
6435 AC_DEFUN([CF_WITH_GPM],
6436 [
6437 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
6438 AC_ARG_WITH(gpm,
6439         [  --with-gpm              use Alessandro Rubini's GPM library],
6440         [with_gpm=$withval],
6441         [with_gpm=maybe])
6442 AC_MSG_RESULT($with_gpm)
6443
6444 if test "$with_gpm" != no ; then
6445         AC_CHECK_HEADER(gpm.h,[
6446                 AC_DEFINE(HAVE_GPM_H)
6447                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
6448                         CF_VERBOSE(assuming we really have GPM library)
6449                         AC_DEFINE(HAVE_LIBGPM)
6450                 else
6451                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
6452                                 AC_MSG_ERROR(Cannot link with GPM library)
6453                 fi
6454                 with_gpm=yes
6455                 ])
6456         ],[
6457                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
6458                 with_gpm=no
6459         ])
6460 fi
6461 ])
6462 dnl ---------------------------------------------------------------------------
6463 dnl CF_WITH_LIBTOOL version: 28 updated: 2011/07/02 15:40:32
6464 dnl ---------------
6465 dnl Provide a configure option to incorporate libtool.  Define several useful
6466 dnl symbols for the makefile rules.
6467 dnl
6468 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
6469 dnl macros from libtool.m4 which is in the aclocal directory of automake.
6470 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
6471 dnl But that still does not work properly since the macro is expanded outside
6472 dnl the CF_WITH_LIBTOOL macro:
6473 dnl
6474 dnl     #!/bin/sh
6475 dnl     ACLOCAL=`aclocal --print-ac-dir`
6476 dnl     if test -z "$ACLOCAL" ; then
6477 dnl             echo cannot find aclocal directory
6478 dnl             exit 1
6479 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
6480 dnl             echo cannot find libtool.m4 file
6481 dnl             exit 1
6482 dnl     fi
6483 dnl
6484 dnl     LOCAL=aclocal.m4
6485 dnl     ORIG=aclocal.m4.orig
6486 dnl
6487 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
6488 dnl     rm -f $ORIG
6489 dnl     mv $LOCAL $ORIG
6490 dnl
6491 dnl     # sed the LIBTOOL= assignment to omit the current directory?
6492 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
6493 dnl     cat $ORIG >>$LOCAL
6494 dnl
6495 dnl     autoconf-257 $*
6496 dnl
6497 AC_DEFUN([CF_WITH_LIBTOOL],
6498 [
6499 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
6500 ifdef([AC_PROG_LIBTOOL],,[
6501 LIBTOOL=
6502 ])
6503 # common library maintenance symbols that are convenient for libtool scripts:
6504 LIB_CREATE='${AR} -cr'
6505 LIB_OBJECT='${OBJECTS}'
6506 LIB_SUFFIX=.a
6507 LIB_PREP="$RANLIB"
6508
6509 # symbols used to prop libtool up to enable it to determine what it should be
6510 # doing:
6511 LIB_CLEAN=
6512 LIB_COMPILE=
6513 LIB_LINK='${CC}'
6514 LIB_INSTALL=
6515 LIB_UNINSTALL=
6516
6517 AC_MSG_CHECKING(if you want to build libraries with libtool)
6518 AC_ARG_WITH(libtool,
6519         [  --with-libtool          generate libraries with libtool],
6520         [with_libtool=$withval],
6521         [with_libtool=no])
6522 AC_MSG_RESULT($with_libtool)
6523 if test "$with_libtool" != "no"; then
6524 ifdef([AC_PROG_LIBTOOL],[
6525         # missing_content_AC_PROG_LIBTOOL{{
6526         AC_PROG_LIBTOOL
6527         # missing_content_AC_PROG_LIBTOOL}}
6528 ],[
6529         if test "$with_libtool" != "yes" ; then
6530                 CF_PATH_SYNTAX(with_libtool)
6531                 LIBTOOL=$with_libtool
6532         else
6533                 AC_PATH_PROG(LIBTOOL,libtool)
6534         fi
6535         if test -z "$LIBTOOL" ; then
6536                 AC_MSG_ERROR(Cannot find libtool)
6537         fi
6538 ])dnl
6539         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${DESTDIR}${libdir} ${LIBTOOL_VERSION} `cut -f1 ${srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
6540         LIB_OBJECT='${OBJECTS:.o=.lo}'
6541         LIB_SUFFIX=.la
6542         LIB_CLEAN='${LIBTOOL} --mode=clean'
6543         LIB_COMPILE='${LIBTOOL} --mode=compile'
6544         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
6545         LIB_INSTALL='${LIBTOOL} --mode=install'
6546         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
6547         LIB_PREP=:
6548
6549         # Show the version of libtool
6550         AC_MSG_CHECKING(version of libtool)
6551
6552         # Save the version in a cache variable - this is not entirely a good
6553         # thing, but the version string from libtool is very ugly, and for
6554         # bug reports it might be useful to have the original string. "("
6555         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
6556         AC_MSG_RESULT($cf_cv_libtool_version)
6557         if test -z "$cf_cv_libtool_version" ; then
6558                 AC_MSG_ERROR(This is not GNU libtool)
6559         fi
6560
6561         # special hack to add -no-undefined (which libtool should do for itself)
6562         LT_UNDEF=
6563         case "$cf_cv_system_name" in #(vi
6564         cygwin*|mingw32*|uwin*|aix[[4-7]]) #(vi
6565                 LT_UNDEF=-no-undefined
6566                 ;;
6567         esac
6568         AC_SUBST([LT_UNDEF])
6569
6570         # special hack to add --tag option for C++ compiler
6571         case $cf_cv_libtool_version in #(vi
6572         1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*) #(vi
6573                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
6574                 LIBTOOL="$LIBTOOL --tag=CC"
6575                 ;;
6576         *)
6577                 LIBTOOL_CXX="$LIBTOOL"
6578                 ;;
6579         esac
6580 else
6581         LIBTOOL=""
6582         LIBTOOL_CXX=""
6583 fi
6584
6585 test -z "$LIBTOOL" && ECHO_LT=
6586
6587 AC_SUBST(LIBTOOL)
6588 AC_SUBST(LIBTOOL_CXX)
6589 AC_SUBST(LIBTOOL_OPTS)
6590
6591 AC_SUBST(LIB_CREATE)
6592 AC_SUBST(LIB_OBJECT)
6593 AC_SUBST(LIB_SUFFIX)
6594 AC_SUBST(LIB_PREP)
6595
6596 AC_SUBST(LIB_CLEAN)
6597 AC_SUBST(LIB_COMPILE)
6598 AC_SUBST(LIB_LINK)
6599 AC_SUBST(LIB_INSTALL)
6600 AC_SUBST(LIB_UNINSTALL)
6601
6602 ])dnl
6603 dnl ---------------------------------------------------------------------------
6604 dnl CF_WITH_PATH version: 10 updated: 2010/10/23 15:44:18
6605 dnl ------------
6606 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
6607 dnl defaulting to yes/no.
6608 dnl
6609 dnl $1 = option name
6610 dnl $2 = help-text
6611 dnl $3 = environment variable to set
6612 dnl $4 = default value, shown in the help-message, must be a constant
6613 dnl $5 = default value, if it's an expression & cannot be in the help-message
6614 dnl
6615 AC_DEFUN([CF_WITH_PATH],
6616 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
6617 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
6618 if ifelse([$5],,true,[test -n "$5"]) ; then
6619 CF_PATH_SYNTAX(withval)
6620 fi
6621 $3="$withval"
6622 AC_SUBST($3)dnl
6623 ])dnl
6624 dnl ---------------------------------------------------------------------------
6625 dnl CF_WITH_PATHLIST version: 7 updated: 2010/10/23 16:10:30
6626 dnl ----------------
6627 dnl Process an option specifying a list of colon-separated paths.
6628 dnl
6629 dnl $1 = option name
6630 dnl $2 = help-text
6631 dnl $3 = environment variable to set
6632 dnl $4 = default value, shown in the help-message, must be a constant
6633 dnl $5 = default value, if it's an expression & cannot be in the help-message
6634 dnl $6 = flag to tell if we want to define or substitute
6635 dnl
6636 AC_DEFUN([CF_WITH_PATHLIST],[
6637 AC_REQUIRE([CF_PATHSEP])
6638 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
6639 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
6640
6641 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
6642 cf_dst_path=
6643 for cf_src_path in $withval
6644 do
6645   CF_PATH_SYNTAX(cf_src_path)
6646   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}:"
6647   cf_dst_path="${cf_dst_path}${cf_src_path}"
6648 done
6649 IFS="$ac_save_ifs"
6650
6651 ifelse($6,define,[
6652 # Strip single quotes from the value, e.g., when it was supplied as a literal
6653 # for $4 or $5.
6654 case $cf_dst_path in #(vi
6655 \'*)
6656   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
6657   ;;
6658 esac
6659 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
6660 ])
6661
6662 eval '$3="$cf_dst_path"'
6663 AC_SUBST($3)dnl
6664
6665 ])dnl
6666 dnl ---------------------------------------------------------------------------
6667 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 2 updated: 2011/12/10 18:58:47
6668 dnl -------------------------
6669 dnl Allow the choice of the pkg-config library directory to be overridden.
6670 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
6671 if test "$PKG_CONFIG" != none ; then
6672         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
6673         AC_ARG_WITH(pkg-config-libdir,
6674                 [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
6675                 [PKG_CONFIG_LIBDIR=$withval],
6676                 [PKG_CONFIG_LIBDIR=yes])
6677
6678         case x$PKG_CONFIG_LIBDIR in #(vi
6679         x/*) #(vi
6680                 ;;
6681         xyes) #(vi
6682                 # look for the library directory using the same prefix as the executable
6683                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
6684                 case x`(arch) 2>/dev/null` in #(vi
6685                 *64) #(vi
6686                         for cf_config in $cf_path/share $cf_path/lib64 $cf_path/lib32 $cf_path/lib
6687                         do
6688                                 if test -d $cf_config/pkgconfig
6689                                 then
6690                                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
6691                                         break
6692                                 fi
6693                         done
6694                         ;;
6695                 *)
6696                         PKG_CONFIG_LIBDIR=$cf_path/lib/pkgconfig
6697                         ;;
6698                 esac
6699                 ;;
6700         *)
6701                 ;;
6702         esac
6703
6704         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
6705 fi
6706
6707 AC_SUBST(PKG_CONFIG_LIBDIR)
6708 ])dnl
6709 dnl ---------------------------------------------------------------------------
6710 dnl CF_WITH_PTHREAD version: 5 updated: 2011/12/10 19:01:56
6711 dnl ---------------
6712 dnl Check for POSIX thread library.
6713 AC_DEFUN([CF_WITH_PTHREAD],
6714 [
6715 AC_MSG_CHECKING(if you want to link with the pthread library)
6716 AC_ARG_WITH(pthread,
6717     [  --with-pthread          use POSIX thread library],
6718     [with_pthread=$withval],
6719     [with_pthread=no])
6720 AC_MSG_RESULT($with_pthread)
6721
6722 if test "$with_pthread" != no ; then
6723     AC_CHECK_HEADER(pthread.h,[
6724         AC_DEFINE(HAVE_PTHREADS_H)
6725
6726         for cf_lib_pthread in pthread c_r
6727         do
6728             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
6729             cf_save_LIBS="$LIBS"
6730             CF_ADD_LIB($cf_lib_pthread)
6731             AC_TRY_LINK([
6732 #include <pthread.h>
6733 ],[
6734                 int rc = pthread_create(0,0,0,0);
6735                 int r2 = pthread_mutexattr_settype(0, 0);
6736 ],[with_pthread=yes],[with_pthread=no])
6737             LIBS="$cf_save_LIBS"
6738             AC_MSG_RESULT($with_pthread)
6739             test "$with_pthread" = yes && break
6740         done
6741
6742         if test "$with_pthread" = yes ; then
6743             CF_ADD_LIB($cf_lib_pthread)
6744             AC_DEFINE(HAVE_LIBPTHREADS)
6745         else
6746             AC_MSG_ERROR(Cannot link with pthread library)
6747         fi
6748     ])
6749 fi
6750 ])
6751 dnl ---------------------------------------------------------------------------
6752 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
6753 dnl -------------------
6754 dnl Allow library's release-version to be overridden.  Generally this happens when a
6755 dnl packager has incremented the release-version past that used in the original package,
6756 dnl and wishes to keep doing this.
6757 dnl
6758 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
6759 dnl and {package}_MINOR symbols
6760 dnl symbol.
6761 AC_DEFUN([CF_WITH_REL_VERSION],[
6762 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
6763 AC_ARG_WITH(rel-version,
6764 [  --with-rel-version=XXX  override derived release version],
6765 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
6766  cf_cv_rel_version=$withval])
6767 ifelse($1,,[
6768  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
6769 ],[
6770  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
6771  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
6772  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
6773  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
6774 ])
6775 ])dnl
6776 dnl ---------------------------------------------------------------------------
6777 dnl CF_WITH_SYSMOUSE version: 2 updated: 2003/03/22 19:13:43
6778 dnl ----------------
6779 dnl If we can compile with sysmouse, make it available unless it is not wanted.
6780 AC_DEFUN([CF_WITH_SYSMOUSE],[
6781 # not everyone has "test -c"
6782 if test -c /dev/sysmouse 2>/dev/null ; then
6783 AC_MSG_CHECKING(if you want to use sysmouse)
6784 AC_ARG_WITH(sysmouse,
6785         [  --with-sysmouse         use sysmouse (FreeBSD console)],
6786         [cf_with_sysmouse=$withval],
6787         [cf_with_sysmouse=maybe])
6788         if test "$cf_with_sysmouse" != no ; then
6789         AC_TRY_COMPILE([
6790 #include <osreldate.h>
6791 #if (__FreeBSD_version >= 400017)
6792 #include <sys/consio.h>
6793 #include <sys/fbio.h>
6794 #else
6795 #include <machine/console.h>
6796 #endif
6797 ],[
6798         struct mouse_info the_mouse;
6799         ioctl(0, CONS_MOUSECTL, &the_mouse);
6800 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
6801         fi
6802 AC_MSG_RESULT($cf_with_sysmouse)
6803 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE)
6804 fi
6805 ])dnl
6806 dnl ---------------------------------------------------------------------------
6807 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
6808 dnl ----------------
6809 AC_DEFUN([CF_WITH_VALGRIND],[
6810 CF_NO_LEAKS_OPTION(valgrind,
6811         [  --with-valgrind         test: use valgrind],
6812         [USE_VALGRIND])
6813 ])dnl
6814 dnl ---------------------------------------------------------------------------
6815 dnl CF_XOPEN_SOURCE version: 41 updated: 2011/12/10 18:58:47
6816 dnl ---------------
6817 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
6818 dnl or adapt to the vendor's definitions to get equivalent functionality,
6819 dnl without losing the common non-POSIX features.
6820 dnl
6821 dnl Parameters:
6822 dnl     $1 is the nominal value for _XOPEN_SOURCE
6823 dnl     $2 is the nominal value for _POSIX_C_SOURCE
6824 AC_DEFUN([CF_XOPEN_SOURCE],[
6825
6826 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
6827 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
6828 cf_xopen_source=
6829
6830 case $host_os in #(vi
6831 aix[[4-7]]*) #(vi
6832         cf_xopen_source="-D_ALL_SOURCE"
6833         ;;
6834 cygwin) #(vi
6835         cf_XOPEN_SOURCE=600
6836         ;;
6837 darwin[[0-8]].*) #(vi
6838         cf_xopen_source="-D_APPLE_C_SOURCE"
6839         ;;
6840 darwin*) #(vi
6841         cf_xopen_source="-D_DARWIN_C_SOURCE"
6842         ;;
6843 freebsd*|dragonfly*) #(vi
6844         # 5.x headers associate
6845         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
6846         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
6847         cf_POSIX_C_SOURCE=200112L
6848         cf_XOPEN_SOURCE=600
6849         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6850         ;;
6851 hpux11*) #(vi
6852         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
6853         ;;
6854 hpux*) #(vi
6855         cf_xopen_source="-D_HPUX_SOURCE"
6856         ;;
6857 irix[[56]].*) #(vi
6858         cf_xopen_source="-D_SGI_SOURCE"
6859         cf_XOPEN_SOURCE=
6860         ;;
6861 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
6862         CF_GNU_SOURCE
6863         ;;
6864 mirbsd*) #(vi
6865         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
6866         cf_XOPEN_SOURCE=
6867         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
6868         ;;
6869 netbsd*) #(vi
6870         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
6871         ;;
6872 openbsd[[4-9]]*) #(vi
6873         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
6874         cf_XOPEN_SOURCE=600
6875         ;;
6876 openbsd*) #(vi
6877         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
6878         ;;
6879 osf[[45]]*) #(vi
6880         cf_xopen_source="-D_OSF_SOURCE"
6881         ;;
6882 nto-qnx*) #(vi
6883         cf_xopen_source="-D_QNX_SOURCE"
6884         ;;
6885 sco*) #(vi
6886         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
6887         ;;
6888 solaris2.*) #(vi
6889         cf_xopen_source="-D__EXTENSIONS__"
6890         ;;
6891 *)
6892         CF_TRY_XOPEN_SOURCE
6893         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
6894         ;;
6895 esac
6896
6897 if test -n "$cf_xopen_source" ; then
6898         CF_ADD_CFLAGS($cf_xopen_source)
6899 fi
6900
6901 dnl In anything but the default case, we may have system-specific setting
6902 dnl which is still not guaranteed to provide all of the entrypoints that
6903 dnl _XOPEN_SOURCE would yield.
6904 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
6905         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
6906         AC_TRY_COMPILE([#include <stdlib.h>],[
6907 #ifndef _XOPEN_SOURCE
6908 make an error
6909 #endif],
6910         [cf_XOPEN_SOURCE_set=yes],
6911         [cf_XOPEN_SOURCE_set=no])
6912         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
6913         if test $cf_XOPEN_SOURCE_set = yes
6914         then
6915                 AC_TRY_COMPILE([#include <stdlib.h>],[
6916 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
6917 make an error
6918 #endif],
6919                 [cf_XOPEN_SOURCE_set_ok=yes],
6920                 [cf_XOPEN_SOURCE_set_ok=no])
6921                 if test $cf_XOPEN_SOURCE_set_ok = no
6922                 then
6923                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
6924                 fi
6925         else
6926                 CF_TRY_XOPEN_SOURCE
6927         fi
6928 fi
6929 ])