aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2015,2016 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.791 2016/06/25 20:25:03 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54         [AC_TRY_LINK([#include <langinfo.h>],
  55         [char* cs = nl_langinfo(CODESET);],
  56         am_cv_langinfo_codeset=yes,
  57         am_cv_langinfo_codeset=no)
  58         ])
  59         if test $am_cv_langinfo_codeset = yes; then
  60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62         fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  66 dnl ---------------
  67 dnl Provide configure-script defaults for different ncurses ABIs.
  68 AC_DEFUN([CF_ABI_DEFAULTS],[
  69 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  70 case x$cf_cv_abi_version in
  71 (x[[6789]])
  72         cf_dft_ext_colors=yes
  73         cf_dft_ext_const=yes
  74         cf_dft_ext_mouse=yes
  75         cf_dft_ext_putwin=yes
  76         cf_dft_ext_spfuncs=yes
  77         cf_dft_filter_syms=yes
  78         cf_dft_chtype=uint32_t
  79         cf_dft_mmask_t=uint32_t
  80         cf_dft_interop=yes
  81         cf_dft_tparm_arg=intptr_t
  82         cf_dft_with_lp64=yes
  83         ;;
  84 (*)
  85         cf_dft_ext_colors=no
  86         cf_dft_ext_const=no
  87         cf_dft_ext_mouse=no
  88         cf_dft_ext_putwin=no
  89         cf_dft_ext_spfuncs=no
  90         cf_dft_filter_syms=no
  91         cf_dft_chtype=auto
  92         cf_dft_mmask_t=auto
  93         cf_dft_interop=no
  94         cf_dft_tparm_arg=long
  95         cf_dft_with_lp64=no
  96         ;;
  97 esac
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 101 dnl ------------------
 102 dnl Conditionally generate script according to whether we're using a given autoconf.
 103 dnl
 104 dnl $1 = version to compare against
 105 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 106 dnl $3 = code to use if AC_ACVERSION is older than $1.
 107 define([CF_ACVERSION_CHECK],
 108 [
 109 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 110 ifdef([m4_version_compare],
 111 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 112 [CF_ACVERSION_COMPARE(
 113 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 114 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 115 dnl ---------------------------------------------------------------------------
 116 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 117 dnl --------------------
 118 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 119 dnl                      MAJOR2, MINOR2, TERNARY2,
 120 dnl                      PRINTABLE2, not FOUND, FOUND)
 121 define([CF_ACVERSION_COMPARE],
 122 [ifelse(builtin([eval], [$2 < $5]), 1,
 123 [ifelse([$8], , ,[$8])],
 124 [ifelse([$9], , ,[$9])])])dnl
 125 dnl ---------------------------------------------------------------------------
 126 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 127 dnl -------------------
 128 dnl Construct the list of include-options for the C programs in the Ada95
 129 dnl binding.
 130 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 131 [
 132 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 133 if test "$srcdir" != "."; then
 134         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 135 fi
 136 if test "$GCC" != yes; then
 137         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 138 elif test "$includedir" != "/usr/include"; then
 139         if test "$includedir" = '${prefix}/include' ; then
 140                 if test x$prefix != x/usr ; then
 141                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 142                 fi
 143         else
 144                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145         fi
 146 fi
 147 AC_SUBST(ACPPFLAGS)
 148 ])dnl
 149 dnl ---------------------------------------------------------------------------
 150 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 151 dnl ---------------
 152 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 153 AC_DEFUN([CF_ADD_ADAFLAGS],[
 154         ADAFLAGS="$ADAFLAGS $1"
 155         AC_SUBST(ADAFLAGS)
 156 ])dnl
 157 dnl ---------------------------------------------------------------------------
 158 dnl CF_ADD_CFLAGS version: 12 updated: 2015/04/12 15:39:00
 159 dnl -------------
 160 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 161 dnl The second parameter if given makes this macro verbose.
 162 dnl
 163 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 164 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 165 dnl confused by the quotes (which require backslashes to keep them usable).
 166 AC_DEFUN([CF_ADD_CFLAGS],
 167 [
 168 cf_fix_cppflags=no
 169 cf_new_cflags=
 170 cf_new_cppflags=
 171 cf_new_extra_cppflags=
 172
 173 for cf_add_cflags in $1
 174 do
 175 case $cf_fix_cppflags in
 176 (no)
 177         case $cf_add_cflags in
 178         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 179                 case $cf_add_cflags in
 180                 (-D*)
 181                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 182
 183                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 184                                 && test -z "${cf_tst_cflags}" \
 185                                 && cf_fix_cppflags=yes
 186
 187                         if test $cf_fix_cppflags = yes ; then
 188                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 189                                 continue
 190                         elif test "${cf_tst_cflags}" = "\"'" ; then
 191                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 192                                 continue
 193                         fi
 194                         ;;
 195                 esac
 196                 case "$CPPFLAGS" in
 197                 (*$cf_add_cflags)
 198                         ;;
 199                 (*)
 200                         case $cf_add_cflags in
 201                         (-D*)
 202                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 203                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 204                                 ;;
 205                         esac
 206                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 207                         ;;
 208                 esac
 209                 ;;
 210         (*)
 211                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 212                 ;;
 213         esac
 214         ;;
 215 (yes)
 216         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 217
 218         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 219
 220         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 221                 && test -z "${cf_tst_cflags}" \
 222                 && cf_fix_cppflags=no
 223         ;;
 224 esac
 225 done
 226
 227 if test -n "$cf_new_cflags" ; then
 228         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 229         CFLAGS="$CFLAGS $cf_new_cflags"
 230 fi
 231
 232 if test -n "$cf_new_cppflags" ; then
 233         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 234         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 235 fi
 236
 237 if test -n "$cf_new_extra_cppflags" ; then
 238         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 239         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 240 fi
 241
 242 AC_SUBST(EXTRA_CPPFLAGS)
 243
 244 ])dnl
 245 dnl ---------------------------------------------------------------------------
 246 dnl CF_ADD_INCDIR version: 14 updated: 2015/05/25 20:53:04
 247 dnl -------------
 248 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 249 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 250 dnl but old versions (and some misinstalled ones) need that.  To make things
 251 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 252 dnl the include-path).
 253 AC_DEFUN([CF_ADD_INCDIR],
 254 [
 255 if test -n "$1" ; then
 256   for cf_add_incdir in $1
 257   do
 258         while test $cf_add_incdir != /usr/include
 259         do
 260           if test -d $cf_add_incdir
 261           then
 262                 cf_have_incdir=no
 263                 if test -n "$CFLAGS$CPPFLAGS" ; then
 264                   # a loop is needed to ensure we can add subdirs of existing dirs
 265                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 266                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 267                           cf_have_incdir=yes; break
 268                         fi
 269                   done
 270                 fi
 271
 272                 if test "$cf_have_incdir" = no ; then
 273                   if test "$cf_add_incdir" = /usr/local/include ; then
 274                         if test "$GCC" = yes
 275                         then
 276                           cf_save_CPPFLAGS=$CPPFLAGS
 277                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 278                           AC_TRY_COMPILE([#include <stdio.h>],
 279                                   [printf("Hello")],
 280                                   [],
 281                                   [cf_have_incdir=yes])
 282                           CPPFLAGS=$cf_save_CPPFLAGS
 283                         fi
 284                   fi
 285                 fi
 286
 287                 if test "$cf_have_incdir" = no ; then
 288                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 289                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 290
 291                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 292                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 293                   cf_add_incdir="$cf_top_incdir"
 294                 else
 295                   break
 296                 fi
 297           else
 298                 break
 299           fi
 300         done
 301   done
 302 fi
 303 ])dnl
 304 dnl ---------------------------------------------------------------------------
 305 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 306 dnl ----------
 307 dnl Add a library, used to enforce consistency.
 308 dnl
 309 dnl $1 = library to add, without the "-l"
 310 dnl $2 = variable to update (default $LIBS)
 311 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 312 dnl ---------------------------------------------------------------------------
 313 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 314 dnl -------------
 315 dnl     Adds to the library-path
 316 dnl
 317 dnl     Some machines have trouble with multiple -L options.
 318 dnl
 319 dnl $1 is the (list of) directory(s) to add
 320 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 321 dnl
 322 AC_DEFUN([CF_ADD_LIBDIR],
 323 [
 324 if test -n "$1" ; then
 325         for cf_add_libdir in $1
 326         do
 327                 if test $cf_add_libdir = /usr/lib ; then
 328                         :
 329                 elif test -d $cf_add_libdir
 330                 then
 331                         cf_have_libdir=no
 332                         if test -n "$LDFLAGS$LIBS" ; then
 333                                 # a loop is needed to ensure we can add subdirs of existing dirs
 334                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 335                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 336                                                 cf_have_libdir=yes; break
 337                                         fi
 338                                 done
 339                         fi
 340                         if test "$cf_have_libdir" = no ; then
 341                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 342                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 343                         fi
 344                 fi
 345         done
 346 fi
 347 ])dnl
 348 dnl ---------------------------------------------------------------------------
 349 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 350 dnl -----------
 351 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 352 dnl prepended to an existing list, since their dependencies are assumed to
 353 dnl already exist in the list.
 354 dnl
 355 dnl $1 = libraries to add, with the "-l", etc.
 356 dnl $2 = variable to update (default $LIBS)
 357 AC_DEFUN([CF_ADD_LIBS],[
 358 cf_add_libs="$1"
 359 # Filter out duplicates - this happens with badly-designed ".pc" files...
 360 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 361 do
 362         for cf_add_2lib in $cf_add_libs
 363         do
 364                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 365                 then
 366                         cf_add_1lib=
 367                         break
 368                 fi
 369         done
 370         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 371 done
 372 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 373 ])dnl
 374 dnl ---------------------------------------------------------------------------
 375 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 376 dnl ------------------
 377 dnl Append to a search-list for a nonstandard header/lib-file
 378 dnl     $1 = the variable to return as result
 379 dnl     $2 = the package name
 380 dnl     $3 = the subdirectory, e.g., bin, include or lib
 381 dnl $4 = the directory under which we will test for subdirectories
 382 dnl $5 = a directory that we do not want $4 to match
 383 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 384 [
 385 test "x$4" != "x$5" && \
 386 test -d "$4" && \
 387 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 388         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 389         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 390         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 391         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 392         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 393         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 394 }
 395 ])dnl
 396 dnl ---------------------------------------------------------------------------
 397 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 398 dnl --------------
 399 dnl Allow user to disable a normally-on option.
 400 AC_DEFUN([CF_ARG_DISABLE],
 401 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 402 dnl ---------------------------------------------------------------------------
 403 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 404 dnl -------------
 405 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 406 dnl values.
 407 dnl
 408 dnl Parameters:
 409 dnl $1 = option name
 410 dnl $2 = help-string
 411 dnl $3 = action to perform if option is not default
 412 dnl $4 = action if perform if option is default
 413 dnl $5 = default option value (either 'yes' or 'no')
 414 AC_DEFUN([CF_ARG_OPTION],
 415 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 416         if test "$enableval" != "$5" ; then
 417 ifelse([$3],,[    :]dnl
 418 ,[    $3]) ifelse([$4],,,[
 419         else
 420                 $4])
 421         fi],[enableval=$5 ifelse([$4],,,[
 422         $4
 423 ])dnl
 424 ])])dnl
 425 dnl ---------------------------------------------------------------------------
 426 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 427 dnl -----------
 428 dnl Check for suitable "ar" (archiver) options for updating an archive.
 429 dnl
 430 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 431 dnl as well as a workaround for breakage of make's archive rules by the GNU
 432 dnl binutils "ar" program.
 433 AC_DEFUN([CF_AR_FLAGS],[
 434 AC_REQUIRE([CF_PROG_AR])
 435
 436 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 437         cf_cv_ar_flags=unknown
 438         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 439         do
 440
 441                 # check if $ARFLAGS already contains this choice
 442                 if test "x$ARFLAGS" != "x" ; then
 443                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 444                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 445                                 cf_cv_ar_flags=
 446                                 break
 447                         fi
 448                 fi
 449
 450                 rm -f conftest.$ac_cv_objext
 451                 rm -f conftest.a
 452
 453                 cat >conftest.$ac_ext <<EOF
 454 #line __oline__ "configure"
 455 int     testdata[[3]] = { 123, 456, 789 };
 456 EOF
 457                 if AC_TRY_EVAL(ac_compile) ; then
 458                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 459                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 460                         if test -f conftest.a ; then
 461                                 cf_cv_ar_flags=$cf_ar_flags
 462                                 break
 463                         fi
 464                 else
 465                         CF_VERBOSE(cannot compile test-program)
 466                         break
 467                 fi
 468         done
 469         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 470 ])
 471
 472 if test -n "$ARFLAGS" ; then
 473         if test -n "$cf_cv_ar_flags" ; then
 474                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 475         fi
 476 else
 477         ARFLAGS=$cf_cv_ar_flags
 478 fi
 479
 480 AC_SUBST(ARFLAGS)
 481 ])
 482 dnl ---------------------------------------------------------------------------
 483 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 484 dnl -----------------
 485 dnl Check if awk can handle big strings using printf.  Some older versions of
 486 dnl awk choke on large strings passed via "%s".
 487 dnl
 488 dnl $1 = desired string size
 489 dnl $2 = variable to set with result
 490 AC_DEFUN([CF_AWK_BIG_PRINTF],
 491 [
 492         case x$AWK in
 493         (x)
 494                 eval $2=no
 495                 ;;
 496         (*)
 497                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 498                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 499                         eval $2=yes
 500                 else
 501                         eval $2=no
 502                 fi
 503                 ;;
 504         esac
 505 ])dnl
 506 dnl ---------------------------------------------------------------------------
 507 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 508 dnl ------------
 509 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 510 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 511 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 512 dnl
 513 dnl Treat the configuration-variable specially here, since we're directly
 514 dnl substituting its value (i.e., 1/0).
 515 dnl
 516 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 517 AC_DEFUN([CF_BOOL_DECL],
 518 [
 519 AC_MSG_CHECKING(if we should include stdbool.h)
 520
 521 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 522         AC_TRY_COMPILE([],[bool foo = false],
 523                 [cf_cv_header_stdbool_h=0],
 524                 [AC_TRY_COMPILE([
 525 #ifndef __BEOS__
 526 #include <stdbool.h>
 527 #endif
 528 ],[bool foo = false],
 529                         [cf_cv_header_stdbool_h=1],
 530                         [cf_cv_header_stdbool_h=0])])])
 531
 532 if test "$cf_cv_header_stdbool_h" = 1
 533 then    AC_MSG_RESULT(yes)
 534 else    AC_MSG_RESULT(no)
 535 fi
 536
 537 AC_MSG_CHECKING([for builtin bool type])
 538
 539 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 540         AC_TRY_COMPILE([
 541 #include <stdio.h>
 542 #include <sys/types.h>
 543 ],[bool x = false],
 544                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 545                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 546         ])
 547
 548 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 549 then    AC_MSG_RESULT(yes)
 550 else    AC_MSG_RESULT(no)
 551 fi
 552 ])dnl
 553 dnl ---------------------------------------------------------------------------
 554 dnl CF_BOOL_SIZE version: 14 updated: 2015/04/17 21:13:04
 555 dnl ------------
 556 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 557 dnl Don't bother looking for bool.h, since it's been deprecated.
 558 dnl
 559 dnl If the current compiler is C rather than C++, we get the bool definition
 560 dnl from <stdbool.h>.
 561 AC_DEFUN([CF_BOOL_SIZE],
 562 [
 563 AC_MSG_CHECKING([for size of bool])
 564 AC_CACHE_VAL(cf_cv_type_of_bool,[
 565         rm -f cf_test.out
 566         AC_TRY_RUN([
 567 #include <stdlib.h>
 568 #include <stdio.h>
 569
 570 #if defined(__cplusplus)
 571
 572 #ifdef HAVE_GXX_BUILTIN_H
 573 #include <g++/builtin.h>
 574 #elif HAVE_GPP_BUILTIN_H
 575 #include <gpp/builtin.h>
 576 #elif HAVE_BUILTIN_H
 577 #include <builtin.h>
 578 #endif
 579
 580 #else
 581
 582 #if $cf_cv_header_stdbool_h
 583 #include <stdbool.h>
 584 #endif
 585
 586 #endif
 587
 588 int main()
 589 {
 590         FILE *fp = fopen("cf_test.out", "w");
 591         if (fp != 0) {
 592                 bool x = true;
 593                 if ((bool)(-x) >= 0)
 594                         fputs("unsigned ", fp);
 595                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 596                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 597                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 598                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 599                 fclose(fp);
 600         }
 601         ${cf_cv_main_return:-return}(0);
 602 }
 603                 ],
 604                 [cf_cv_type_of_bool=`cat cf_test.out`
 605                  if test -z "$cf_cv_type_of_bool"; then
 606                    cf_cv_type_of_bool=unknown
 607                  fi],
 608                 [cf_cv_type_of_bool=unknown],
 609                 [cf_cv_type_of_bool=unknown])
 610         ])
 611         rm -f cf_test.out
 612 AC_MSG_RESULT($cf_cv_type_of_bool)
 613 if test "$cf_cv_type_of_bool" = unknown ; then
 614         case .$NCURSES_BOOL in
 615         (.auto|.) NCURSES_BOOL=unsigned;;
 616         esac
 617         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 618         cf_cv_type_of_bool=$NCURSES_BOOL
 619 fi
 620 ])dnl
 621 dnl ---------------------------------------------------------------------------
 622 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 623 dnl -----------
 624 dnl If we're cross-compiling, allow the user to override the tools and their
 625 dnl options.  The configure script is oriented toward identifying the host
 626 dnl compiler, etc., but we need a build compiler to generate parts of the
 627 dnl source.
 628 dnl
 629 dnl $1 = default for $CPPFLAGS
 630 dnl $2 = default for $LIBS
 631 AC_DEFUN([CF_BUILD_CC],[
 632 CF_ACVERSION_CHECK(2.52,,
 633         [AC_REQUIRE([CF_PROG_EXT])])
 634 if test "$cross_compiling" = yes ; then
 635
 636         # defaults that we might want to override
 637         : ${BUILD_CFLAGS:=''}
 638         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 639         : ${BUILD_LDFLAGS:=''}
 640         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 641         : ${BUILD_EXEEXT:='$x'}
 642         : ${BUILD_OBJEXT:='o'}
 643
 644         AC_ARG_WITH(build-cc,
 645                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 646                 [BUILD_CC="$withval"],
 647                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 648         AC_MSG_CHECKING(for native build C compiler)
 649         AC_MSG_RESULT($BUILD_CC)
 650
 651         AC_MSG_CHECKING(for native build C preprocessor)
 652         AC_ARG_WITH(build-cpp,
 653                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 654                 [BUILD_CPP="$withval"],
 655                 [BUILD_CPP='${BUILD_CC} -E'])
 656         AC_MSG_RESULT($BUILD_CPP)
 657
 658         AC_MSG_CHECKING(for native build C flags)
 659         AC_ARG_WITH(build-cflags,
 660                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 661                 [BUILD_CFLAGS="$withval"])
 662         AC_MSG_RESULT($BUILD_CFLAGS)
 663
 664         AC_MSG_CHECKING(for native build C preprocessor-flags)
 665         AC_ARG_WITH(build-cppflags,
 666                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 667                 [BUILD_CPPFLAGS="$withval"])
 668         AC_MSG_RESULT($BUILD_CPPFLAGS)
 669
 670         AC_MSG_CHECKING(for native build linker-flags)
 671         AC_ARG_WITH(build-ldflags,
 672                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 673                 [BUILD_LDFLAGS="$withval"])
 674         AC_MSG_RESULT($BUILD_LDFLAGS)
 675
 676         AC_MSG_CHECKING(for native build linker-libraries)
 677         AC_ARG_WITH(build-libs,
 678                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 679                 [BUILD_LIBS="$withval"])
 680         AC_MSG_RESULT($BUILD_LIBS)
 681
 682         # this assumes we're on Unix.
 683         BUILD_EXEEXT=
 684         BUILD_OBJEXT=o
 685
 686         : ${BUILD_CC:='${CC}'}
 687
 688         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 689                 AC_MSG_ERROR([Cross-build requires two compilers.
 690 Use --with-build-cc to specify the native compiler.])
 691         fi
 692
 693 else
 694         : ${BUILD_CC:='${CC}'}
 695         : ${BUILD_CPP:='${CPP}'}
 696         : ${BUILD_CFLAGS:='${CFLAGS}'}
 697         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 698         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 699         : ${BUILD_LIBS:='${LIBS}'}
 700         : ${BUILD_EXEEXT:='$x'}
 701         : ${BUILD_OBJEXT:='o'}
 702 fi
 703
 704 AC_SUBST(BUILD_CC)
 705 AC_SUBST(BUILD_CPP)
 706 AC_SUBST(BUILD_CFLAGS)
 707 AC_SUBST(BUILD_CPPFLAGS)
 708 AC_SUBST(BUILD_LDFLAGS)
 709 AC_SUBST(BUILD_LIBS)
 710 AC_SUBST(BUILD_EXEEXT)
 711 AC_SUBST(BUILD_OBJEXT)
 712 ])dnl
 713 dnl ---------------------------------------------------------------------------
 714 dnl CF_CC_ENV_FLAGS version: 4 updated: 2016/06/25 16:23:40
 715 dnl ---------------
 716 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 717 dnl into CC.  This will not help with broken scripts that wrap the compiler with
 718 dnl options, but eliminates a more common category of user confusion.
 719 dnl
 720 dnl In particular, it addresses the problem of being able to run the C
 721 dnl preprocessor in a consistent manner.
 722 dnl
 723 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 724 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 725 dnl outweighs that limitation.
 726 AC_DEFUN([CF_CC_ENV_FLAGS],
 727 [
 728 # This should have been defined by AC_PROG_CC
 729 : ${CC:=cc}
 730
 731 AC_MSG_CHECKING(\$CC variable)
 732 case "$CC" in
 733 (*[[\ \ ]]-*)
 734         AC_MSG_RESULT(broken)
 735         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 736         # humor him...
 737         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]][[    ]]*//'`
 738         CC=`echo "$CC " | sed -e 's/[[  ]]-[[IUD]][[^   ]][[^   ]]*//g' -e 's/[[        ]]*$//'`
 739         CF_ADD_CFLAGS($cf_flags)
 740         CF_VERBOSE(resulting CC: '$CC')
 741         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 742         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 743         ;;
 744 (*)
 745         AC_MSG_RESULT(ok)
 746         ;;
 747 esac
 748 ])dnl
 749 dnl ---------------------------------------------------------------------------
 750 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 751 dnl ---------------
 752 dnl Determine the default configuration into which we'll install ncurses.  This
 753 dnl can be overridden by the user's command-line options.  There's two items to
 754 dnl look for:
 755 dnl     1. the prefix (e.g., /usr)
 756 dnl     2. the header files (e.g., /usr/include/ncurses)
 757 dnl We'll look for a previous installation of ncurses and use the same defaults.
 758 dnl
 759 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 760 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 761 dnl programs from a vendor's.
 762 AC_DEFUN([CF_CFG_DEFAULTS],
 763 [
 764 AC_MSG_CHECKING(for prefix)
 765 if test "x$prefix" = "xNONE" ; then
 766         case "$cf_cv_system_name" in
 767                 # non-vendor systems don't have a conflict
 768         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 769                 prefix=/usr
 770                 ;;
 771         (*)     prefix=$ac_default_prefix
 772                 ;;
 773         esac
 774 fi
 775 AC_MSG_RESULT($prefix)
 776
 777 if test "x$prefix" = "xNONE" ; then
 778 AC_MSG_CHECKING(for default include-directory)
 779 test -n "$verbose" && echo 1>&AC_FD_MSG
 780 for cf_symbol in \
 781         $includedir \
 782         $includedir/ncurses \
 783         $prefix/include \
 784         $prefix/include/ncurses \
 785         /usr/local/include \
 786         /usr/local/include/ncurses \
 787         /usr/include \
 788         /usr/include/ncurses
 789 do
 790         cf_dir=`eval echo $cf_symbol`
 791         if test -f $cf_dir/curses.h ; then
 792         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 793                 includedir="$cf_symbol"
 794                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 795                 break
 796         fi
 797         fi
 798         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 799 done
 800 AC_MSG_RESULT($includedir)
 801 fi
 802 ])dnl
 803 dnl ---------------------------------------------------------------------------
 804 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
 805 dnl ----------
 806 dnl Check if the terminal-capability database functions are available.  If not,
 807 dnl ncurses has a much-reduced version.
 808 AC_DEFUN([CF_CGETENT],[
 809 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 810 AC_TRY_LINK([
 811 #include <stdlib.h>],[
 812         char temp[128];
 813         char *buf = temp;
 814         char *db_array = temp;
 815         cgetent(&buf, &db_array, "vt100");
 816         cgetcap(buf, "tc", '=');
 817         cgetmatch(buf, "tc");
 818         ],
 819         [cf_cv_cgetent=yes],
 820         [cf_cv_cgetent=no])
 821 ])
 822
 823 if test "$cf_cv_cgetent" = yes
 824 then
 825         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 826 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 827 AC_TRY_LINK([
 828 #include <stdlib.h>],[
 829         char temp[128];
 830         char *buf = temp;
 831 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 832         const char *db_array = temp;
 833         cgetent(&buf, &db_array, "vt100");
 834 #endif
 835         cgetcap(buf, "tc", '=');
 836         cgetmatch(buf, "tc");
 837         ],
 838         [cf_cv_cgetent_const=yes],
 839         [cf_cv_cgetent_const=no])
 840 ])
 841         if test "$cf_cv_cgetent_const" = yes
 842         then
 843                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 844         fi
 845 fi
 846 ])dnl
 847 dnl ---------------------------------------------------------------------------
 848 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 849 dnl --------------
 850 dnl Check if we're accidentally using a cache from a different machine.
 851 dnl Derive the system name, as a check for reusing the autoconf cache.
 852 dnl
 853 dnl If we've packaged config.guess and config.sub, run that (since it does a
 854 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 855 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 856 dnl which is useful in cross-compiles.
 857 dnl
 858 dnl Note: we would use $ac_config_sub, but that is one of the places where
 859 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 860 AC_DEFUN([CF_CHECK_CACHE],
 861 [
 862 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 863         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 864         system_name="$host_os"
 865 else
 866         system_name="`(uname -s -r) 2>/dev/null`"
 867         if test -z "$system_name" ; then
 868                 system_name="`(hostname) 2>/dev/null`"
 869         fi
 870 fi
 871 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 872 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 873
 874 test -z "$system_name" && system_name="$cf_cv_system_name"
 875 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 876
 877 if test ".$system_name" != ".$cf_cv_system_name" ; then
 878         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 879         AC_MSG_ERROR("Please remove config.cache and try again.")
 880 fi
 881 ])dnl
 882 dnl ---------------------------------------------------------------------------
 883 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
 884 dnl --------------
 885 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 886 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 887 dnl ourselves.
 888 dnl
 889 dnl $1 = the name to check
 890 dnl $2 = the assumed type
 891 AC_DEFUN([CF_CHECK_ERRNO],
 892 [
 893 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 894         AC_TRY_COMPILE([
 895 #ifdef HAVE_STDLIB_H
 896 #include <stdlib.h>
 897 #endif
 898 #include <stdio.h>
 899 #include <sys/types.h>
 900 #include <errno.h> ],
 901         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 902         [cf_cv_dcl_$1=yes],
 903         [cf_cv_dcl_$1=no])
 904 ])
 905
 906 if test "$cf_cv_dcl_$1" = no ; then
 907         CF_UPPER(cf_result,decl_$1)
 908         AC_DEFINE_UNQUOTED($cf_result)
 909 fi
 910
 911 # It's possible (for near-UNIX clones) that the data doesn't exist
 912 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 913 ])dnl
 914 dnl ---------------------------------------------------------------------------
 915 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
 916 dnl --------------------
 917 dnl Check for existence of external data in the current set of libraries.  If
 918 dnl we can modify it, it's real enough.
 919 dnl $1 = the name to check
 920 dnl $2 = its type
 921 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 922 [
 923 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 924         AC_TRY_LINK([
 925 #undef $1
 926 extern $2 $1;
 927 ],
 928         [$1 = 2],
 929         [cf_cv_have_$1=yes],
 930         [cf_cv_have_$1=no])
 931 ])
 932
 933 if test "$cf_cv_have_$1" = yes ; then
 934         CF_UPPER(cf_result,have_$1)
 935         AC_DEFINE_UNQUOTED($cf_result)
 936 fi
 937
 938 ])dnl
 939 dnl ---------------------------------------------------------------------------
 940 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 941 dnl -------------------
 942 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 943 dnl is not "weak" - warn about this because it can create problems linking
 944 dnl applications with ncurses.
 945 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 946 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 947
 948 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 949 cf_cv_check_gpm_wgetch=unknown
 950 if test "$cross_compiling" != yes ; then
 951
 952 cat >conftest.$ac_ext <<CF_EOF
 953 #include <gpm.h>
 954 int main()
 955 {
 956         Gpm_Wgetch();
 957         ${cf_cv_main_return:-return}(0);
 958 }
 959 CF_EOF
 960
 961         cf_save_LIBS="$LIBS"
 962         # This only works if we can look at the symbol table.  If a shared
 963         # library is stripped for install, we cannot use that.  So we're forced
 964         # to rely on the static library, noting that some packagers may not
 965         # include it.
 966         LIBS="-static -lgpm -dynamic $LIBS"
 967         if AC_TRY_EVAL(ac_compile) ; then
 968                 if AC_TRY_EVAL(ac_link) ; then
 969                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 970                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 971                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 972                 fi
 973         fi
 974         rm -rf conftest*
 975         LIBS="$cf_save_LIBS"
 976 fi
 977 ])
 978
 979 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 980         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 981 fi
 982 ])])dnl
 983 dnl ---------------------------------------------------------------------------
 984 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
 985 dnl ------------------------
 986 dnl Show the version of libtool
 987 dnl
 988 dnl Save the version in a cache variable - this is not entirely a good thing,
 989 dnl but the version string from libtool is very ugly, and for bug reports it
 990 dnl might be useful to have the original string.
 991 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
 992 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
 993 then
 994         AC_MSG_CHECKING(version of $LIBTOOL)
 995         CF_LIBTOOL_VERSION
 996         AC_MSG_RESULT($cf_cv_libtool_version)
 997         if test -z "$cf_cv_libtool_version" ; then
 998                 AC_MSG_ERROR(This is not GNU libtool)
 999         fi
1000 else
1001         AC_MSG_ERROR(GNU libtool has not been found)
1002 fi
1003 ])dnl
1004 dnl ---------------------------------------------------------------------------
1005 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
1006 dnl ----------------
1007 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1008 AC_DEFUN([CF_CHECK_WCHAR_H],[
1009 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1010 AC_TRY_COMPILE(
1011 [
1012 #include <stdlib.h>
1013 #include <wchar.h>
1014 ],[
1015         wint_t foo = 0;
1016         int bar = iswpunct(foo)],
1017         [cf_cv_wchar_h_okay=yes],
1018         [cf_cv_wchar_h_okay=no])])
1019
1020 if test $cf_cv_wchar_h_okay = no
1021 then
1022         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1023 fi
1024 ])dnl
1025 dnl ---------------------------------------------------------------------------
1026 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1027 dnl -------------------------
1028 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1029 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1030 dnl
1031 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1032 dnl all of those were combined into a page of useful graphics characters.
1033 dnl
1034 dnl So far, so good.
1035 dnl
1036 dnl However, while they are useful, there are other considerations.  CJK
1037 dnl is (because of poor device resolution) often rendered as double-width
1038 dnl characters.  So... for these generally-useful characters, what should
1039 dnl be the width (to make them consistent with adjacent characters)?
1040 dnl
1041 dnl The obvious choice would have been to make this locale-dependent, and use
1042 dnl wcwidth() to tell applications what the actual width is.  That was too
1043 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1044 dnl See for example
1045 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1046 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1047 dnl
1048 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1049 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1050 dnl instance, it lists half (44/96) of the Latin-1 characters as
1051 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1052 dnl
1053 dnl What this means for the implementor is that on some systems wcwidth() can
1054 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1055 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1056 dnl characters).  These do not necessarily match the behavior of the terminal
1057 dnl emulator.  xterm, for instance, does an optional startup check to find if
1058 dnl this problem (or similar) exists with the system's locale tables, rejecting
1059 dnl them if they are too unreliable.
1060 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1061 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1062 cat >conftest.in <<CF_EOF
1063 -       VT100 symbols
1064 0x250c  upper left corner
1065 0x2514  lower left corner
1066 0x2510  upper right corner
1067 0x2518  lower right corner
1068 0x251c  tee pointing left
1069 0x2524  tee pointing right
1070 0x2534  tee pointing up
1071 0x252c  tee pointing down
1072 0x2500  horizontal line
1073 0x2502  vertical line
1074 0x253c  large plus or crossover
1075 0x23ba  scan line 1
1076 0x23bd  scan line 9
1077 0x25c6  diamond
1078 0x2592  checker board (stipple)
1079 0x00b0  degree symbol
1080 0x00b1  plus/minus
1081 0x00b7  bullet
1082 -       Teletype 5410v1 symbols
1083 0x2190  arrow pointing left
1084 0x2192  arrow pointing right
1085 0x2193  arrow pointing down
1086 0x2191  arrow pointing up
1087 0x2592  board of squares
1088 0x2603  lantern symbol
1089 0x25ae  solid square block
1090 -       these defaults were invented for ncurses
1091 0x23bb  scan line 3
1092 0x23bc  scan line 7
1093 0x2264  less-than-or-equal-to
1094 0x2265  greater-than-or-equal-to
1095 0x03c0  greek pi
1096 0x2260  not-equal
1097 0x00a3  pound-sterling symbol
1098 -       thick-line-drawing
1099 0x250f  upper left corner
1100 0x2517  lower left corner
1101 0x2513  upper right corner
1102 0x251b  lower right corner
1103 0x2523  tee pointing left
1104 0x252b  tee pointing right
1105 0x253b  tee pointing up
1106 0x2533  tee pointing down
1107 0x2501  horizontal line
1108 0x2503  vertical line
1109 0x254b  large plus or crossover
1110 -       double-line-drawing
1111 0x2554  upper left corner
1112 0x255a  lower left corner
1113 0x2557  upper right corner
1114 0x255d  lower right corner
1115 0x2563  tee pointing left
1116 0x2560  tee pointing right
1117 0x2569  tee pointing up
1118 0x2566  tee pointing down
1119 0x2550  horizontal line
1120 0x2551  vertical line
1121 0x256c  large plus or crossover
1122 CF_EOF
1123 AC_TRY_RUN([
1124 #include <locale.h>
1125 #include <stdio.h>
1126 #include <wchar.h>
1127
1128 #define MY_LEN 80
1129
1130 int
1131 main(void)
1132 {
1133         FILE *fp;
1134         int value;
1135         char buffer[MY_LEN + 1];
1136         char notes[MY_LEN + 1];
1137         int totals = 0;
1138         int passed = 0;
1139
1140         if (setlocale(LC_ALL, "en_US.UTF8") ||
1141                 setlocale(LC_ALL, "en_US.UTF-8") ||
1142                 setlocale(LC_ALL, "en_US.utf8") ||
1143                 setlocale(LC_ALL, "en_US.utf-8")) {
1144                 if ((fp = fopen("conftest.in", "r")) != 0) {
1145                         while (fgets(buffer, MY_LEN, fp) != 0) {
1146                                 if (*buffer == '-') {
1147                                         fprintf(stderr, "\t%s", buffer);
1148                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1149                                         ++totals;
1150                                         if (wcwidth(value) == 1)
1151                                                 ++passed;
1152                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1153                                 } else {
1154                                         fprintf(stderr, "?\t%s", buffer);
1155                                 }
1156                         }
1157                 }
1158         }
1159         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1160         return (totals == passed) ? 0 : 1;
1161 }
1162 ],
1163 [cf_cv_wcwidth_graphics=yes],
1164 [cf_cv_wcwidth_graphics=no],
1165 [cf_cv_wcwidth_graphics=unknown])
1166 ])
1167 ])dnl
1168 dnl ---------------------------------------------------------------------------
1169 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1170 dnl -----------------
1171 dnl Check if the given compiler is really clang.  clang's C driver defines
1172 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1173 dnl not ignore some gcc options.
1174 dnl
1175 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1176 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1177 dnl the wrappers for gcc and g++ warnings.
1178 dnl
1179 dnl $1 = GCC (default) or GXX
1180 dnl $2 = CLANG_COMPILER (default)
1181 dnl $3 = CFLAGS (default) or CXXFLAGS
1182 AC_DEFUN([CF_CLANG_COMPILER],[
1183 ifelse([$2],,CLANG_COMPILER,[$2])=no
1184
1185 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1186         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1187         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1188         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1189         AC_TRY_COMPILE([],[
1190 #ifdef __clang__
1191 #else
1192 make an error
1193 #endif
1194 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1195 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1196 ],[])
1197         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1198         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1199 fi
1200 ])
1201 dnl ---------------------------------------------------------------------------
1202 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
1203 dnl -----------------
1204 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1205 dnl is a late feature for the standard and is not in some recent compilers
1206 dnl (1999/9/11).
1207 AC_DEFUN([CF_CPP_PARAM_INIT],
1208 [
1209 if test -n "$CXX"; then
1210 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1211         AC_LANG_SAVE
1212         AC_LANG_CPLUSPLUS
1213         AC_TRY_RUN([
1214 class TEST {
1215 private:
1216         int value;
1217 public:
1218         TEST(int x = 1);
1219         ~TEST();
1220 };
1221
1222 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1223 {
1224         value = x;
1225 }
1226 int main() { }
1227 ],
1228         [cf_cv_cpp_param_init=yes],
1229         [cf_cv_cpp_param_init=no],
1230         [cf_cv_cpp_param_init=unknown])
1231         AC_LANG_RESTORE
1232 ])
1233 fi
1234 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1235 ])dnl
1236 dnl ---------------------------------------------------------------------------
1237 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1238 dnl ------------------
1239 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1240 dnl not be supported in g++ before 3.0
1241 AC_DEFUN([CF_CPP_STATIC_CAST],
1242 [
1243 if test -n "$CXX"; then
1244
1245 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1246         AC_LANG_SAVE
1247         AC_LANG_CPLUSPLUS
1248
1249         AC_TRY_COMPILE([
1250 class NCursesPanel
1251 {
1252 public:
1253   NCursesPanel(int nlines,
1254                int ncols,
1255                int begin_y = 0,
1256                int begin_x = 0)
1257   {
1258   }
1259   NCursesPanel();
1260   ~NCursesPanel();
1261 };
1262
1263 template<class T> class NCursesUserPanel : public NCursesPanel
1264 {
1265 public:
1266   NCursesUserPanel (int nlines,
1267                     int ncols,
1268                     int begin_y = 0,
1269                     int begin_x = 0,
1270                     const T* p_UserData = static_cast<T*>(0))
1271     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1272   {
1273   };
1274   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1275   {
1276   };
1277
1278   virtual ~NCursesUserPanel() {};
1279 };
1280 ],[
1281         const char* p_UserData = static_cast<char*>(0)],
1282         [cf_cv_cpp_static_cast=yes],
1283         [cf_cv_cpp_static_cast=no])
1284
1285         AC_LANG_RESTORE
1286 ])
1287
1288 fi
1289
1290 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1291 ])dnl
1292 dnl ---------------------------------------------------------------------------
1293 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1294 dnl ---------------
1295 dnl Setup special archiver flags for given compilers.
1296 AC_DEFUN([CF_CXX_AR_FLAGS],[
1297         CXX_AR='$(AR)'
1298         CXX_ARFLAGS='$(ARFLAGS)'
1299         case $cf_cv_system_name in
1300         (irix*)
1301             if test "$GXX" != yes ; then
1302                 CXX_AR='$(CXX)'
1303                 CXX_ARFLAGS='-ar -o'
1304             fi
1305             ;;
1306         (sco3.2v5*)
1307             CXXLDFLAGS="-u main"
1308             ;;
1309         (solaris2*)
1310             if test "$GXX" != yes ; then
1311                 CXX_AR='$(CXX)'
1312                 CXX_ARFLAGS='-xar -o'
1313             fi
1314             ;;
1315         esac
1316         AC_SUBST(CXXLDFLAGS)
1317         AC_SUBST(CXX_AR)
1318         AC_SUBST(CXX_ARFLAGS)
1319 ])dnl
1320 dnl ---------------------------------------------------------------------------
1321 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1322 dnl -------------------------
1323 dnl For c++, check if iostream uses "std::" namespace.
1324 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1325 AC_CHECK_HEADERS(iostream)
1326 if test x"$ac_cv_header_iostream" = xyes ; then
1327         AC_MSG_CHECKING(if iostream uses std-namespace)
1328         AC_TRY_COMPILE([
1329 #include <iostream>
1330 using std::endl;
1331 using std::cerr;],[
1332 cerr << "testing" << endl;
1333 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1334         AC_MSG_RESULT($cf_iostream_namespace)
1335         if test "$cf_iostream_namespace" = yes ; then
1336                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1337         fi
1338 fi
1339 ])dnl
1340 dnl ---------------------------------------------------------------------------
1341 dnl CF_C_INLINE version: 5 updated: 2015/04/18 08:56:57
1342 dnl -----------
1343 dnl Check if the C compiler supports "inline".
1344 dnl $1 is the name of a shell variable to set if inline is supported
1345 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1346 AC_DEFUN([CF_C_INLINE],[
1347 AC_C_INLINE
1348 $1=
1349 if test "$ac_cv_c_inline" != no ; then
1350         $1=inline
1351         if test "$INTEL_COMPILER" = yes
1352         then
1353                 :
1354         elif test "$CLANG_COMPILER" = yes
1355         then
1356                 :
1357         elif test "$GCC" = yes
1358         then
1359                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1360                 cf_save_CFLAGS=$CFLAGS
1361                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1362                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1363                 [${cf_cv_main_return:-return} foo()],
1364                 [cf_cv_gcc_inline=yes],
1365                 [cf_cv_gcc_inline=no])
1366                 CFLAGS=$cf_save_CFLAGS
1367                 ])
1368                 if test "$cf_cv_gcc_inline" = yes ; then
1369                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1370                 fi
1371         fi
1372 fi
1373 AC_SUBST($1)
1374 ])dnl
1375 dnl ---------------------------------------------------------------------------
1376 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1377 dnl ----------
1378 dnl "dirname" is not portable, so we fake it with a shell script.
1379 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1380 dnl ---------------------------------------------------------------------------
1381 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1382 dnl ---------------
1383 AC_DEFUN([CF_DIRS_TO_MAKE],
1384 [
1385 DIRS_TO_MAKE="lib"
1386 for cf_item in $cf_list_models
1387 do
1388         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1389         for cf_item2 in $DIRS_TO_MAKE
1390         do
1391                 test $cf_item2 = $cf_subdir && break
1392         done
1393         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1394 done
1395 for cf_dir in $DIRS_TO_MAKE
1396 do
1397         test ! -d $cf_dir && mkdir $cf_dir
1398 done
1399 AC_SUBST(DIRS_TO_MAKE)
1400 ])dnl
1401 dnl ---------------------------------------------------------------------------
1402 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1403 dnl ---------------
1404 dnl You can always use "make -n" to see the actual options, but it's hard to
1405 dnl pick out/analyze warning messages when the compile-line is long.
1406 dnl
1407 dnl Sets:
1408 dnl     ECHO_LT - symbol to control if libtool is verbose
1409 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1410 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1411 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1412 dnl     ECHO_CC - symbol to put before any "cc" line
1413 dnl
1414 AC_DEFUN([CF_DISABLE_ECHO],[
1415 AC_MSG_CHECKING(if you want to see long compiling messages)
1416 CF_ARG_DISABLE(echo,
1417         [  --disable-echo          do not display "compiling" commands],
1418         [
1419         ECHO_LT='--silent'
1420         ECHO_LD='@echo linking [$]@;'
1421         RULE_CC='@echo compiling [$]<'
1422         SHOW_CC='@echo compiling [$]@'
1423         ECHO_CC='@'
1424 ],[
1425         ECHO_LT=''
1426         ECHO_LD=''
1427         RULE_CC=''
1428         SHOW_CC=''
1429         ECHO_CC=''
1430 ])
1431 AC_MSG_RESULT($enableval)
1432 AC_SUBST(ECHO_LT)
1433 AC_SUBST(ECHO_LD)
1434 AC_SUBST(RULE_CC)
1435 AC_SUBST(SHOW_CC)
1436 AC_SUBST(ECHO_CC)
1437 ])dnl
1438 dnl ---------------------------------------------------------------------------
1439 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1440 dnl ------------------------
1441 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1442 AC_MSG_CHECKING(if we want to use GNAT projects)
1443 CF_ARG_DISABLE(gnat-projects,
1444         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1445         [enable_gnat_projects=no],
1446         [enable_gnat_projects=yes])
1447 AC_MSG_RESULT($enable_gnat_projects)
1448 ])dnl
1449 dnl ---------------------------------------------------------------------------
1450 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1451 dnl ----------------
1452 dnl Combine no-leak checks with the libraries or tools that are used for the
1453 dnl checks.
1454 AC_DEFUN([CF_DISABLE_LEAKS],[
1455
1456 AC_REQUIRE([CF_WITH_DMALLOC])
1457 AC_REQUIRE([CF_WITH_DBMALLOC])
1458 AC_REQUIRE([CF_WITH_VALGRIND])
1459
1460 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1461 AC_ARG_ENABLE(leaks,
1462         [  --disable-leaks         test: free permanent memory, analyze leaks],
1463         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1464         : ${with_no_leaks:=no})
1465 AC_MSG_RESULT($with_no_leaks)
1466
1467 if test "$with_no_leaks" = yes ; then
1468         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1469         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1470 fi
1471 ])dnl
1472 dnl ---------------------------------------------------------------------------
1473 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1474 dnl --------------------------
1475 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1476 dnl the older "-version-info" feature.  The newer feature allows us to use
1477 dnl version numbering on shared libraries which make them compatible with
1478 dnl various systems.
1479 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1480 [
1481 AC_MSG_CHECKING(if libtool -version-number should be used)
1482 CF_ARG_DISABLE(libtool-version,
1483         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1484         [cf_libtool_version=no],
1485         [cf_libtool_version=yes])
1486 AC_MSG_RESULT($cf_libtool_version)
1487
1488 if test "$cf_libtool_version" = yes ; then
1489         LIBTOOL_VERSION="-version-number"
1490 else
1491         LIBTOOL_VERSION="-version-info"
1492         case "x$VERSION" in
1493         (x)
1494                 AC_MSG_WARN(VERSION was not set)
1495                 ;;
1496         (x*.*.*)
1497                 ABI_VERSION="$VERSION"
1498                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1499                 ;;
1500         (x*:*:*)
1501                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1502                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1503                 ;;
1504         (*)
1505                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1506                 ;;
1507         esac
1508 fi
1509
1510 AC_SUBST(ABI_VERSION)
1511 AC_SUBST(LIBTOOL_VERSION)
1512 ])dnl
1513 dnl ---------------------------------------------------------------------------
1514 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1515 dnl ---------------------
1516 dnl The rpath-hack makes it simpler to build programs, particularly with the
1517 dnl *BSD ports which may have essential libraries in unusual places.  But it
1518 dnl can interfere with building an executable for the base system.  Use this
1519 dnl option in that case.
1520 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1521 [
1522 AC_MSG_CHECKING(if rpath-hack should be disabled)
1523 CF_ARG_DISABLE(rpath-hack,
1524         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1525         [cf_disable_rpath_hack=yes],
1526         [cf_disable_rpath_hack=no])
1527 AC_MSG_RESULT($cf_disable_rpath_hack)
1528 if test "$cf_disable_rpath_hack" = no ; then
1529         CF_RPATH_HACK
1530 fi
1531 ])
1532 dnl ---------------------------------------------------------------------------
1533 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1534 dnl ------------------
1535 dnl This is the "--enable-pc-files" option, which is available if there is a
1536 dnl pkg-config configuration on the local machine.
1537 AC_DEFUN([CF_ENABLE_PC_FILES],[
1538 AC_REQUIRE([CF_PKG_CONFIG])
1539 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1540
1541 if test "x$PKG_CONFIG" != xnone
1542 then
1543         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1544 else
1545         AC_MSG_CHECKING(if we should install .pc files)
1546 fi
1547
1548 AC_ARG_ENABLE(pc-files,
1549         [  --enable-pc-files       generate and install .pc files for pkg-config],
1550         [enable_pc_files=$enableval],
1551         [enable_pc_files=no])
1552 AC_MSG_RESULT($enable_pc_files)
1553
1554 if test "x$enable_pc_files" != xno
1555 then
1556         MAKE_PC_FILES=
1557         case "x$PKG_CONFIG_LIBDIR" in
1558         (xno|xyes)
1559                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1560                 ;;
1561         (*)
1562                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1563                 ;;
1564         esac
1565 else
1566         MAKE_PC_FILES="#"
1567 fi
1568 AC_SUBST(MAKE_PC_FILES)
1569 ])dnl
1570 dnl ---------------------------------------------------------------------------
1571 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1572 dnl ---------------
1573 dnl Check if the rpath option should be used, setting cache variable
1574 dnl cf_cv_enable_rpath if so.
1575 AC_DEFUN([CF_ENABLE_RPATH],
1576 [
1577 AC_MSG_CHECKING(if rpath option should be used)
1578 AC_ARG_ENABLE(rpath,
1579 [  --enable-rpath          use rpath option when generating shared libraries],
1580 [cf_cv_enable_rpath=$enableval],
1581 [cf_cv_enable_rpath=no])
1582 AC_MSG_RESULT($cf_cv_enable_rpath)
1583 ])dnl
1584 dnl ---------------------------------------------------------------------------
1585 dnl CF_ENABLE_STRING_HACKS version: 3 updated: 2013/01/26 16:26:12
1586 dnl ----------------------
1587 dnl On a few platforms, the compiler and/or loader nags with untruthful
1588 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1589 dnl and implying that most uses of the recommended alternatives are correct.
1590 dnl
1591 dnl Factually speaking, no one has actually counted the number of uses of these
1592 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1593 dnl instances are meaningless compared to the hundreds of millions of lines of
1594 dnl existing C code.
1595 dnl
1596 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1597 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1598 dnl standard - but evolved through phases, and older implementations are likely
1599 dnl to yield surprising results, as documented in manpages on various systems.
1600 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1601 [
1602 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1603 AC_ARG_ENABLE(string-hacks,
1604         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1605         [with_string_hacks=$enableval],
1606         [with_string_hacks=no])
1607 AC_MSG_RESULT($with_string_hacks)
1608
1609 if test "x$with_string_hacks" = "xyes"; then
1610         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1611         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1612         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1613 fi
1614 ])dnl
1615 dnl ---------------------------------------------------------------------------
1616 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1617 dnl --------
1618 dnl Check if 'errno' is declared in <errno.h>
1619 AC_DEFUN([CF_ERRNO],
1620 [
1621 CF_CHECK_ERRNO(errno)
1622 ])dnl
1623 dnl ---------------------------------------------------------------------------
1624 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1625 dnl ---------------
1626 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1627 dnl math.h and builtin.h, only for ncurses
1628 AC_DEFUN([CF_ETIP_DEFINES],
1629 [
1630 AC_MSG_CHECKING(for special defines needed for etip.h)
1631 cf_save_CXXFLAGS="$CXXFLAGS"
1632 cf_result="none"
1633
1634 # etip.h includes ncurses.h which includes ncurses_dll.h
1635 # But ncurses_dll.h is generated - fix here.
1636 test -d include || mkdir include
1637 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1638
1639 for cf_math in "" MATH_H
1640 do
1641 for cf_excp in "" MATH_EXCEPTION
1642 do
1643         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1644         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1645         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1646 AC_TRY_COMPILE([
1647 #include <etip.h.in>
1648 ],[],[
1649         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1650         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1651         cf_result="$cf_math $cf_excp"
1652         break 2
1653 ],[])
1654 done
1655 done
1656 AC_MSG_RESULT($cf_result)
1657 CXXFLAGS="$cf_save_CXXFLAGS"
1658 ])
1659 dnl ---------------------------------------------------------------------------
1660 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
1661 dnl ---------------
1662 dnl Find a library (specifically the linkage used in the code fragment),
1663 dnl searching for it if it is not already in the library path.
1664 dnl See also CF_ADD_SEARCHPATH.
1665 dnl
1666 dnl Parameters (4-on are optional):
1667 dnl     $1 = headers for library entrypoint
1668 dnl     $2 = code fragment for library entrypoint
1669 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1670 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1671 dnl     $5 = action to perform if not successful
1672 dnl     $6 = module name, if not the same as the library name
1673 dnl     $7 = extra libraries
1674 dnl
1675 dnl Sets these variables:
1676 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1677 dnl     $cf_cv_header_path_$3 - include-directory if needed
1678 dnl     $cf_cv_library_path_$3 - library-directory if needed
1679 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1680 AC_DEFUN([CF_FIND_LINKAGE],[
1681
1682 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1683 # will be set on completion of the AC_TRY_LINK below.
1684 cf_cv_header_path_$3=
1685 cf_cv_library_path_$3=
1686
1687 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1688
1689 cf_save_LIBS="$LIBS"
1690
1691 AC_TRY_LINK([$1],[$2],[
1692         cf_cv_find_linkage_$3=yes
1693         cf_cv_header_path_$3=/usr/include
1694         cf_cv_library_path_$3=/usr/lib
1695 ],[
1696
1697 LIBS="-l$3 $7 $cf_save_LIBS"
1698
1699 AC_TRY_LINK([$1],[$2],[
1700         cf_cv_find_linkage_$3=yes
1701         cf_cv_header_path_$3=/usr/include
1702         cf_cv_library_path_$3=/usr/lib
1703         cf_cv_library_file_$3="-l$3"
1704 ],[
1705         cf_cv_find_linkage_$3=no
1706         LIBS="$cf_save_LIBS"
1707
1708         CF_VERBOSE(find linkage for $3 library)
1709         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1710
1711         cf_save_CPPFLAGS="$CPPFLAGS"
1712         cf_test_CPPFLAGS="$CPPFLAGS"
1713
1714         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1715         for cf_cv_header_path_$3 in $cf_search
1716         do
1717                 if test -d $cf_cv_header_path_$3 ; then
1718                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1719                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1720                         AC_TRY_COMPILE([$1],[$2],[
1721                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1722                                 cf_cv_find_linkage_$3=maybe
1723                                 cf_test_CPPFLAGS="$CPPFLAGS"
1724                                 break],[
1725                                 CPPFLAGS="$cf_save_CPPFLAGS"
1726                                 ])
1727                 fi
1728         done
1729
1730         if test "$cf_cv_find_linkage_$3" = maybe ; then
1731
1732                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1733
1734                 cf_save_LIBS="$LIBS"
1735                 cf_save_LDFLAGS="$LDFLAGS"
1736
1737                 ifelse([$6],,,[
1738                 CPPFLAGS="$cf_test_CPPFLAGS"
1739                 LIBS="-l$3 $7 $cf_save_LIBS"
1740                 AC_TRY_LINK([$1],[$2],[
1741                         CF_VERBOSE(... found $3 library in system)
1742                         cf_cv_find_linkage_$3=yes])
1743                         CPPFLAGS="$cf_save_CPPFLAGS"
1744                         LIBS="$cf_save_LIBS"
1745                         ])
1746
1747                 if test "$cf_cv_find_linkage_$3" != yes ; then
1748                         CF_LIBRARY_PATH(cf_search,$3)
1749                         for cf_cv_library_path_$3 in $cf_search
1750                         do
1751                                 if test -d $cf_cv_library_path_$3 ; then
1752                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1753                                         CPPFLAGS="$cf_test_CPPFLAGS"
1754                                         LIBS="-l$3 $7 $cf_save_LIBS"
1755                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1756                                         AC_TRY_LINK([$1],[$2],[
1757                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1758                                         cf_cv_find_linkage_$3=yes
1759                                         cf_cv_library_file_$3="-l$3"
1760                                         break],[
1761                                         CPPFLAGS="$cf_save_CPPFLAGS"
1762                                         LIBS="$cf_save_LIBS"
1763                                         LDFLAGS="$cf_save_LDFLAGS"
1764                                         ])
1765                                 fi
1766                         done
1767                         CPPFLAGS="$cf_save_CPPFLAGS"
1768                         LDFLAGS="$cf_save_LDFLAGS"
1769                 fi
1770
1771         else
1772                 cf_cv_find_linkage_$3=no
1773         fi
1774         ],$7)
1775 ])
1776
1777 LIBS="$cf_save_LIBS"
1778
1779 if test "$cf_cv_find_linkage_$3" = yes ; then
1780 ifelse([$4],,[
1781         CF_ADD_INCDIR($cf_cv_header_path_$3)
1782         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1783         CF_ADD_LIB($3)
1784 ],[$4])
1785 else
1786 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1787 fi
1788 ])dnl
1789 dnl ---------------------------------------------------------------------------
1790 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
1791 dnl ------------------
1792 dnl Find an include-directory with the given leaf-name.  This is useful for
1793 dnl example with FreeBSD ports, which use this convention to distinguish
1794 dnl different versions of the same port.
1795 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1796         CF_SUBDIR_PATH(cf_search,$1,include)
1797         for cf_item in $cf_search
1798         do
1799                 case $cf_item in
1800                 (*/$1)
1801                         CF_ADD_INCDIR($cf_item)
1802                         ;;
1803                 esac
1804         done
1805 ])dnl
1806 dnl ---------------------------------------------------------------------------
1807 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
1808 dnl ------------------
1809 dnl Find a library-directory with the given leaf-name.  This is useful for
1810 dnl example with FreeBSD ports, which use this convention to distinguish
1811 dnl different versions of the same port.
1812 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1813         CF_SUBDIR_PATH(cf_search,$1,lib)
1814         for cf_item in $cf_search
1815         do
1816                 case $cf_item in
1817                 (*/$1)
1818                         CF_ADD_LIBDIR($cf_item)
1819                         ;;
1820                 esac
1821         done
1822 ])dnl
1823 dnl ---------------------------------------------------------------------------
1824 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1825 dnl -----------------
1826 dnl make ADAFLAGS consistent with CFLAGS
1827 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1828         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1829         case "$CFLAGS" in
1830         (*-g*)
1831                 CF_ADD_ADAFLAGS(-g)
1832                 ;;
1833         esac
1834         case "$CFLAGS" in
1835         (*-O*)
1836                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1837                 CF_ADD_ADAFLAGS($cf_O_flag)
1838                 ;;
1839         esac
1840         AC_MSG_RESULT($ADAFLAGS)
1841 ])dnl
1842 dnl ---------------------------------------------------------------------------
1843 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1844 dnl --------------
1845 dnl Forget that we saw the given tool.
1846 AC_DEFUN([CF_FORGET_TOOL],[
1847 unset ac_cv_prog_ac_ct_$1
1848 unset ac_ct_$1
1849 unset $1
1850 ])dnl
1851 dnl ---------------------------------------------------------------------------
1852 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
1853 dnl -------------
1854 dnl Test for dlsym() and related functions, as well as libdl.
1855 dnl
1856 dnl Sets
1857 dnl     $cf_have_dlsym
1858 dnl     $cf_have_libdl
1859 AC_DEFUN([CF_FUNC_DLSYM],[
1860 cf_have_dlsym=no
1861 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1862
1863 cf_have_libdl=no
1864 AC_CHECK_LIB(dl,dlsym,[
1865         cf_have_dlsym=yes
1866         cf_have_libdl=yes])])
1867
1868 if test "$cf_have_dlsym" = yes ; then
1869         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
1870
1871         AC_MSG_CHECKING(whether able to link to dl*() functions)
1872         AC_TRY_LINK([#include <dlfcn.h>],[
1873                 void *obj;
1874                 if ((obj = dlopen("filename", 0)) != 0) {
1875                         if (dlsym(obj, "symbolname") == 0) {
1876                         dlclose(obj);
1877                         }
1878                 }],[
1879                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1880                 AC_MSG_ERROR(Cannot link test program for libdl)])
1881         AC_MSG_RESULT(ok)
1882 else
1883         AC_MSG_ERROR(Cannot find dlsym function)
1884 fi
1885 ])
1886 dnl ---------------------------------------------------------------------------
1887 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1888 dnl ---------------
1889 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1890 dnl is found, add our own version of memmove to the list of objects.
1891 AC_DEFUN([CF_FUNC_MEMMOVE],
1892 [
1893 AC_CHECK_FUNC(memmove,,[
1894 AC_CHECK_FUNC(bcopy,[
1895         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1896                 AC_TRY_RUN([
1897 int main() {
1898         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1899         char temp[40];
1900         bcopy(data, temp, sizeof(data));
1901         bcopy(temp+10, temp, 15);
1902         bcopy(temp+5, temp+15, 10);
1903         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1904 }
1905                 ],
1906                 [cf_cv_good_bcopy=yes],
1907                 [cf_cv_good_bcopy=no],
1908                 [cf_cv_good_bcopy=unknown])
1909                 ])
1910         ],[cf_cv_good_bcopy=no])
1911         if test "$cf_cv_good_bcopy" = yes ; then
1912                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1913         else
1914                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1915         fi
1916 ])])dnl
1917 dnl ---------------------------------------------------------------------------
1918 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1919 dnl -----------------
1920 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1921 dnl AIX 4.x, provide a non-working version.
1922 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1923 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1924 AC_TRY_RUN([
1925 #include <stdio.h>
1926 #include <errno.h>
1927 #include <time.h>
1928
1929 #ifdef HAVE_SYS_TIME_H
1930 #include <sys/time.h>
1931 #endif
1932
1933 int main() {
1934         struct timespec ts1, ts2;
1935         int code;
1936         ts1.tv_sec  = 0;
1937         ts1.tv_nsec = 750000000;
1938         ts2.tv_sec  = 0;
1939         ts2.tv_nsec = 0;
1940         errno = 0;
1941         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1942         ${cf_cv_main_return:-return}(code != 0);
1943 }
1944 ],
1945         [cf_cv_func_nanosleep=yes],
1946         [cf_cv_func_nanosleep=no],
1947         [cf_cv_func_nanosleep=unknown])])
1948
1949 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1950 ])
1951 dnl ---------------------------------------------------------------------------
1952 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
1953 dnl ---------------
1954 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1955 dnl "util" library as well.
1956 AC_DEFUN([CF_FUNC_OPENPTY],
1957 [
1958 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1959 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1960         cf_save_LIBS="$LIBS"
1961         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
1962         for cf_header in pty.h libutil.h util.h
1963         do
1964         AC_TRY_LINK([
1965 #include <$cf_header>
1966 ],[
1967         int x = openpty((int *)0, (int *)0, (char *)0,
1968                                    (struct termios *)0, (struct winsize *)0);
1969 ],[
1970                 cf_cv_func_openpty=$cf_header
1971                 break
1972 ],[
1973                 cf_cv_func_openpty=no
1974 ])
1975         done
1976         LIBS="$cf_save_LIBS"
1977 ])
1978 ])dnl
1979 dnl ---------------------------------------------------------------------------
1980 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
1981 dnl ------------
1982 dnl See if the poll function really works.  Some platforms have poll(), but
1983 dnl it does not work for terminals or files.
1984 AC_DEFUN([CF_FUNC_POLL],[
1985 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
1986 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1987 AC_TRY_RUN([
1988 #include <stdlib.h>
1989 #include <stdio.h>
1990 #include <unistd.h>
1991 #include <fcntl.h>
1992 #ifdef HAVE_POLL_H
1993 #include <poll.h>
1994 #else
1995 #include <sys/poll.h>
1996 #endif
1997 int main(void) {
1998         struct pollfd myfds;
1999         int ret;
2000
2001         /* check for Darwin bug with respect to "devices" */
2002         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2003         if (myfds.fd < 0)
2004                 myfds.fd = 0;
2005         myfds.events = POLLIN;
2006         myfds.revents = 0;
2007
2008         ret = poll(&myfds, 1, 100);
2009
2010         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2011                 ret = -1;
2012         } else {
2013                 int fd = 0;
2014                 if (!isatty(fd)) {
2015                         fd = open("/dev/tty", 2);       /* O_RDWR */
2016                 }
2017 #ifdef HAVE_POSIX_OPENPT
2018                 if (fd < 0) {
2019                         fd = posix_openpt(O_RDWR);
2020                 }
2021 #endif
2022
2023                 if (fd >= 0) {
2024                         /* also check with standard input */
2025                         myfds.fd = fd;
2026                         myfds.events = POLLIN;
2027                         myfds.revents = 0;
2028                         ret = poll(&myfds, 1, 100);
2029                 } else {
2030                         ret = -1;
2031                 }
2032         }
2033         ${cf_cv_main_return:-return}(ret < 0);
2034 }],
2035         [cf_cv_working_poll=yes],
2036         [cf_cv_working_poll=no],
2037         [cf_cv_working_poll=unknown])])
2038 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2039 ])dnl
2040 dnl ---------------------------------------------------------------------------
2041 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2042 dnl ---------------
2043 dnl Some old/broken variations define tcgetattr() only as a macro in
2044 dnl termio(s).h
2045 AC_DEFUN([CF_FUNC_TERMIOS],[
2046 AC_REQUIRE([CF_STRUCT_TERMIOS])
2047 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2048 AC_TRY_LINK([
2049 #include <sys/types.h>
2050 #ifdef HAVE_UNISTD_H
2051 #include <unistd.h>
2052 #endif
2053 #ifdef HAVE_TERMIOS_H
2054 #include <termios.h>
2055 #define TTY struct termios
2056 #else
2057 #ifdef HAVE_TERMIO_H
2058 #include <termio.h>
2059 #define TTY struct termio
2060 #endif
2061 #endif
2062 ],[
2063 TTY foo;
2064 tcgetattr(1, &foo);],
2065 [cf_cv_have_tcgetattr=yes],
2066 [cf_cv_have_tcgetattr=no])])
2067 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2068 ])dnl
2069 dnl ---------------------------------------------------------------------------
2070 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2071 dnl ---------------
2072 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2073 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2074 dnl other functions.
2075 AC_DEFUN([CF_FUNC_VSSCANF],
2076 [
2077 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2078 AC_TRY_LINK([
2079 #include <stdarg.h>
2080 #include <stdio.h>],[
2081         va_list ap;
2082         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2083 AC_TRY_LINK([
2084 #include <stdarg.h>
2085 #include <stdio.h>],[
2086         FILE strbuf;
2087         char *str = "from";
2088
2089         strbuf._flag = _IOREAD;
2090         strbuf._ptr = strbuf._base = (unsigned char *) str;
2091         strbuf._cnt = strlen(str);
2092         strbuf._file = _NFILE;
2093         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2094 AC_TRY_LINK([
2095 #include <stdarg.h>
2096 #include <stdio.h>],[
2097         FILE strbuf;
2098         char *str = "from";
2099
2100         strbuf._flag = _IOREAD;
2101         strbuf._ptr = strbuf._base = (unsigned char *) str;
2102         strbuf._cnt = strlen(str);
2103         strbuf._file = _NFILE;
2104         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2105 cf_cv_func_vsscanf=no])])])])
2106
2107 case $cf_cv_func_vsscanf in
2108 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2109 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2110 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2111 esac
2112
2113 ])dnl
2114 dnl ---------------------------------------------------------------------------
2115 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
2116 dnl -----------------
2117 dnl Test for availability of useful gcc __attribute__ directives to quiet
2118 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2119 dnl to documentation, unrecognized directives cause older compilers to barf.
2120 AC_DEFUN([CF_GCC_ATTRIBUTES],
2121 [
2122 if test "$GCC" = yes
2123 then
2124 cat > conftest.i <<EOF
2125 #ifndef GCC_PRINTF
2126 #define GCC_PRINTF 0
2127 #endif
2128 #ifndef GCC_SCANF
2129 #define GCC_SCANF 0
2130 #endif
2131 #ifndef GCC_NORETURN
2132 #define GCC_NORETURN /* nothing */
2133 #endif
2134 #ifndef GCC_UNUSED
2135 #define GCC_UNUSED /* nothing */
2136 #endif
2137 EOF
2138 if test "$GCC" = yes
2139 then
2140         AC_CHECKING([for $CC __attribute__ directives])
2141 cat > conftest.$ac_ext <<EOF
2142 #line __oline__ "${as_me:-configure}"
2143 #include "confdefs.h"
2144 #include "conftest.h"
2145 #include "conftest.i"
2146 #if     GCC_PRINTF
2147 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2148 #else
2149 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2150 #endif
2151 #if     GCC_SCANF
2152 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2153 #else
2154 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2155 #endif
2156 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2157 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2158 extern void foo(void) GCC_NORETURN;
2159 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
2160 EOF
2161         cf_printf_attribute=no
2162         cf_scanf_attribute=no
2163         for cf_attribute in scanf printf unused noreturn
2164         do
2165                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2166                 cf_directive="__attribute__(($cf_attribute))"
2167                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2168
2169                 case $cf_attribute in
2170                 (printf)
2171                         cf_printf_attribute=yes
2172                         cat >conftest.h <<EOF
2173 #define GCC_$cf_ATTRIBUTE 1
2174 EOF
2175                         ;;
2176                 (scanf)
2177                         cf_scanf_attribute=yes
2178                         cat >conftest.h <<EOF
2179 #define GCC_$cf_ATTRIBUTE 1
2180 EOF
2181                         ;;
2182                 (*)
2183                         cat >conftest.h <<EOF
2184 #define GCC_$cf_ATTRIBUTE $cf_directive
2185 EOF
2186                         ;;
2187                 esac
2188
2189                 if AC_TRY_EVAL(ac_compile); then
2190                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2191                         cat conftest.h >>confdefs.h
2192                         case $cf_attribute in
2193                         (noreturn)
2194                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2195                                 ;;
2196                         (printf)
2197                                 cf_value='/* nothing */'
2198                                 if test "$cf_printf_attribute" != no ; then
2199                                         cf_value='__attribute__((format(printf,fmt,var)))'
2200                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2201                                 fi
2202                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2203                                 ;;
2204                         (scanf)
2205                                 cf_value='/* nothing */'
2206                                 if test "$cf_scanf_attribute" != no ; then
2207                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2208                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2209                                 fi
2210                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2211                                 ;;
2212                         (unused)
2213                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2214                                 ;;
2215                         esac
2216                 fi
2217         done
2218 else
2219         fgrep define conftest.i >>confdefs.h
2220 fi
2221 rm -rf conftest*
2222 fi
2223 ])dnl
2224 dnl ---------------------------------------------------------------------------
2225 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2226 dnl --------------
2227 dnl Find version of gcc
2228 AC_DEFUN([CF_GCC_VERSION],[
2229 AC_REQUIRE([AC_PROG_CC])
2230 GCC_VERSION=none
2231 if test "$GCC" = yes ; then
2232         AC_MSG_CHECKING(version of $CC)
2233         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2234         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2235         AC_MSG_RESULT($GCC_VERSION)
2236 fi
2237 ])dnl
2238 dnl ---------------------------------------------------------------------------
2239 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
2240 dnl ---------------
2241 dnl Check if the compiler supports useful warning options.  There's a few that
2242 dnl we don't use, simply because they're too noisy:
2243 dnl
2244 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2245 dnl     -Wredundant-decls (system headers make this too noisy)
2246 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2247 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2248 dnl             is enabled for ncurses using "--enable-const".
2249 dnl     -pedantic
2250 dnl
2251 dnl Parameter:
2252 dnl     $1 is an optional list of gcc warning flags that a particular
2253 dnl             application might want to use, e.g., "no-unused" for
2254 dnl             -Wno-unused
2255 dnl Special:
2256 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2257 dnl
2258 AC_DEFUN([CF_GCC_WARNINGS],
2259 [
2260 AC_REQUIRE([CF_GCC_VERSION])
2261 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2262 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2263
2264 cat > conftest.$ac_ext <<EOF
2265 #line __oline__ "${as_me:-configure}"
2266 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2267 EOF
2268
2269 if test "$INTEL_COMPILER" = yes
2270 then
2271 # The "-wdXXX" options suppress warnings:
2272 # remark #1419: external declaration in primary source file
2273 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2274 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2275 # remark #193: zero used for undefined preprocessing identifier
2276 # remark #593: variable "curs_sb_left_arrow" was set but never used
2277 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2278 # remark #869: parameter "tw" was never referenced
2279 # remark #981: operands are evaluated in unspecified order
2280 # warning #279: controlling expression is constant
2281
2282         AC_CHECKING([for $CC warning options])
2283         cf_save_CFLAGS="$CFLAGS"
2284         EXTRA_CFLAGS="-Wall"
2285         for cf_opt in \
2286                 wd1419 \
2287                 wd1683 \
2288                 wd1684 \
2289                 wd193 \
2290                 wd593 \
2291                 wd279 \
2292                 wd810 \
2293                 wd869 \
2294                 wd981
2295         do
2296                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2297                 if AC_TRY_EVAL(ac_compile); then
2298                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2299                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2300                 fi
2301         done
2302         CFLAGS="$cf_save_CFLAGS"
2303
2304 elif test "$GCC" = yes
2305 then
2306         AC_CHECKING([for $CC warning options])
2307         cf_save_CFLAGS="$CFLAGS"
2308         EXTRA_CFLAGS=
2309         cf_warn_CONST=""
2310         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2311         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2312         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2313         for cf_opt in W Wall \
2314                 Wbad-function-cast \
2315                 Wcast-align \
2316                 Wcast-qual \
2317                 Wdeclaration-after-statement \
2318                 Wextra \
2319                 Winline \
2320                 Wmissing-declarations \
2321                 Wmissing-prototypes \
2322                 Wnested-externs \
2323                 Wpointer-arith \
2324                 Wshadow \
2325                 Wstrict-prototypes \
2326                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2327         do
2328                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2329                 if AC_TRY_EVAL(ac_compile); then
2330                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2331                         case $cf_opt in
2332                         (Wcast-qual)
2333                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2334                                 ;;
2335                         (Winline)
2336                                 case $GCC_VERSION in
2337                                 ([[34]].*)
2338                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2339                                         continue;;
2340                                 esac
2341                                 ;;
2342                         (Wpointer-arith)
2343                                 case $GCC_VERSION in
2344                                 ([[12]].*)
2345                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2346                                         continue;;
2347                                 esac
2348                                 ;;
2349                         esac
2350                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2351                 fi
2352         done
2353         CFLAGS="$cf_save_CFLAGS"
2354 fi
2355 rm -rf conftest*
2356
2357 AC_SUBST(EXTRA_CFLAGS)
2358 ])dnl
2359 dnl ---------------------------------------------------------------------------
2360 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2361 dnl ----------------
2362 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2363 dnl unistd.h or (nonstandard) in getopt.h
2364 AC_DEFUN([CF_GETOPT_HEADER],
2365 [
2366 AC_HAVE_HEADERS(unistd.h getopt.h)
2367 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2368 cf_cv_getopt_header=none
2369 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2370 do
2371 AC_TRY_COMPILE([
2372 #include <$cf_header>],
2373 [int x = optind; char *y = optarg],
2374 [cf_cv_getopt_header=$cf_header
2375  break])
2376 done
2377 ])
2378 if test $cf_cv_getopt_header != none ; then
2379         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2380 fi
2381 if test $cf_cv_getopt_header = getopt.h ; then
2382         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2383 fi
2384 ])dnl
2385 dnl ---------------------------------------------------------------------------
2386 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2387 dnl -----------------
2388 AC_DEFUN([CF_GNATPREP_OPT_T],[
2389 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2390 cf_cv_gnatprep_opt_t=no
2391 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2392 ])
2393 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2394 AC_SUBST(GNATPREP_OPTS)
2395 ])dnl
2396 dnl ---------------------------------------------------------------------------
2397 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2398 dnl ----------------
2399 AC_DEFUN([CF_GNAT_GENERICS],
2400 [
2401 AC_REQUIRE([CF_GNAT_VERSION])
2402
2403 AC_MSG_CHECKING(if GNAT supports generics)
2404 case $cf_gnat_version in
2405 (3.[[1-9]]*|[[4-9]].*)
2406         cf_gnat_generics=yes
2407         ;;
2408 (*)
2409         cf_gnat_generics=no
2410         ;;
2411 esac
2412 AC_MSG_RESULT($cf_gnat_generics)
2413
2414 if test "$cf_gnat_generics" = yes
2415 then
2416         cf_compile_generics=generics
2417         cf_generic_objects="\${GENOBJS}"
2418 else
2419         cf_compile_generics=
2420         cf_generic_objects=
2421 fi
2422
2423 AC_SUBST(cf_compile_generics)
2424 AC_SUBST(cf_generic_objects)
2425 ])dnl
2426 dnl ---------------------------------------------------------------------------
2427 dnl CF_GNAT_PROJECTS version: 8 updated: 2015/04/17 21:13:04
2428 dnl ----------------
2429 dnl GNAT projects are configured with ".gpr" project files.
2430 dnl GNAT libraries are a further development, using the project feature.
2431 AC_DEFUN([CF_GNAT_PROJECTS],
2432 [
2433 AC_REQUIRE([CF_GNAT_VERSION])
2434 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2435
2436 cf_gnat_libraries=no
2437 cf_gnat_projects=no
2438
2439 if test "$enable_gnat_projects" != no ; then
2440 AC_MSG_CHECKING(if GNAT supports project files)
2441 case $cf_gnat_version in
2442 (3.[[0-9]]*)
2443         ;;
2444 (*)
2445         case $cf_cv_system_name in
2446         (cygwin*|msys*)
2447                 ;;
2448         (*)
2449                 mkdir conftest.src conftest.bin conftest.lib
2450                 cd conftest.src
2451                 rm -rf conftest* *~conftest*
2452                 cat >>library.gpr <<CF_EOF
2453 project Library is
2454   Kind := External ("LIB_KIND");
2455   for Library_Name use "ConfTest";
2456   for Object_Dir use ".";
2457   for Library_ALI_Dir use External("LIBRARY_DIR");
2458   for Library_Version use External ("SONAME");
2459   for Library_Kind use Kind;
2460   for Library_Dir use External("BUILD_DIR");
2461   Source_Dir := External ("SOURCE_DIR");
2462   for Source_Dirs use (Source_Dir);
2463 end Library;
2464 CF_EOF
2465                 cat >>confpackage.ads <<CF_EOF
2466 package ConfPackage is
2467    procedure conftest;
2468 end ConfPackage;
2469 CF_EOF
2470                 cat >>confpackage.adb <<CF_EOF
2471 with Text_IO;
2472 package body ConfPackage is
2473    procedure conftest is
2474    begin
2475       Text_IO.Put ("Hello World");
2476       Text_IO.New_Line;
2477    end conftest;
2478 end ConfPackage;
2479 CF_EOF
2480                 if ( $cf_ada_make $ADAFLAGS \
2481                                 -Plibrary.gpr \
2482                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2483                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2484                                 -XSOURCE_DIR=`pwd` \
2485                                 -XSONAME=libConfTest.so.1 \
2486                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2487                         cf_gnat_projects=yes
2488                 fi
2489                 cd ..
2490                 if test -f conftest.lib/confpackage.ali
2491                 then
2492                         cf_gnat_libraries=yes
2493                 fi
2494                 rm -rf conftest* *~conftest*
2495                 ;;
2496         esac
2497         ;;
2498 esac
2499 AC_MSG_RESULT($cf_gnat_projects)
2500 fi # enable_gnat_projects
2501
2502 if test $cf_gnat_projects = yes
2503 then
2504         AC_MSG_CHECKING(if GNAT supports libraries)
2505         AC_MSG_RESULT($cf_gnat_libraries)
2506 fi
2507
2508 if test "$cf_gnat_projects" = yes
2509 then
2510         USE_OLD_MAKERULES="#"
2511         USE_GNAT_PROJECTS=""
2512 else
2513         USE_OLD_MAKERULES=""
2514         USE_GNAT_PROJECTS="#"
2515 fi
2516
2517 if test "$cf_gnat_libraries" = yes
2518 then
2519         USE_GNAT_LIBRARIES=""
2520 else
2521         USE_GNAT_LIBRARIES="#"
2522 fi
2523
2524 AC_SUBST(USE_OLD_MAKERULES)
2525 AC_SUBST(USE_GNAT_PROJECTS)
2526 AC_SUBST(USE_GNAT_LIBRARIES)
2527 ])dnl
2528 dnl ---------------------------------------------------------------------------
2529 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2530 dnl --------------
2531 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2532 dnl is noted that gnat may compile a tasking unit even for configurations which
2533 dnl fail at runtime.
2534 AC_DEFUN([CF_GNAT_SIGINT],[
2535 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2536 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2537
2538 package ConfTest is
2539
2540    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2541    pragma Unreserve_All_Interrupts;
2542    pragma Warnings (On);
2543
2544    protected Process is
2545       procedure Stop;
2546       function Continue return Boolean;
2547       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2548    private
2549       Done : Boolean := False;
2550    end Process;
2551
2552 end ConfTest;],
2553 [package body ConfTest is
2554    protected body Process is
2555       procedure Stop is
2556       begin
2557          Done := True;
2558       end Stop;
2559       function Continue return Boolean is
2560       begin
2561          return not Done;
2562       end Continue;
2563    end Process;
2564 end ConfTest;],
2565         [cf_cv_gnat_sigint=yes],
2566         [cf_cv_gnat_sigint=no])])
2567
2568 if test $cf_cv_gnat_sigint = yes ; then
2569         USE_GNAT_SIGINT=""
2570 else
2571         USE_GNAT_SIGINT="#"
2572 fi
2573 AC_SUBST(USE_GNAT_SIGINT)
2574 ])dnl
2575 dnl ---------------------------------------------------------------------------
2576 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2577 dnl ----------------
2578 dnl Verify that a test program compiles/links with GNAT.
2579 dnl $cf_ada_make is set to the program that compiles/links
2580 dnl $ADAFLAGS may be set to the GNAT flags.
2581 dnl
2582 dnl $1 is the text of the spec
2583 dnl $2 is the text of the body
2584 dnl $3 is the shell command to execute if successful
2585 dnl $4 is the shell command to execute if not successful
2586 AC_DEFUN([CF_GNAT_TRY_LINK],
2587 [
2588 rm -rf conftest* *~conftest*
2589 cat >>conftest.ads <<CF_EOF
2590 $1
2591 CF_EOF
2592 cat >>conftest.adb <<CF_EOF
2593 $2
2594 CF_EOF
2595 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2596 ifelse($3,,      :,[      $3])
2597 ifelse($4,,,[else
2598    $4])
2599 fi
2600 rm -rf conftest* *~conftest*
2601 ])dnl
2602 dnl ---------------------------------------------------------------------------
2603 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2604 dnl ---------------
2605 dnl Verify that a test program compiles and runs with GNAT
2606 dnl $cf_ada_make is set to the program that compiles/links
2607 dnl $ADAFLAGS may be set to the GNAT flags.
2608 dnl
2609 dnl $1 is the text of the spec
2610 dnl $2 is the text of the body
2611 dnl $3 is the shell command to execute if successful
2612 dnl $4 is the shell command to execute if not successful
2613 AC_DEFUN([CF_GNAT_TRY_RUN],
2614 [
2615 rm -rf conftest* *~conftest*
2616 cat >>conftest.ads <<CF_EOF
2617 $1
2618 CF_EOF
2619 cat >>conftest.adb <<CF_EOF
2620 $2
2621 CF_EOF
2622 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2623    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2624 ifelse($3,,      :,[      $3])
2625 ifelse($4,,,[   else
2626       $4])
2627    fi
2628 ifelse($4,,,[else
2629    $4])
2630 fi
2631 rm -rf conftest* *~conftest*
2632 ])dnl
2633 dnl ---------------------------------------------------------------------------
2634 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
2635 dnl ---------------
2636 dnl Verify version of GNAT.
2637 AC_DEFUN([CF_GNAT_VERSION],
2638 [
2639 AC_MSG_CHECKING(for gnat version)
2640 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2641         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2642         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2643 AC_MSG_RESULT($cf_gnat_version)
2644
2645 case $cf_gnat_version in
2646 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
2647         cf_cv_prog_gnat_correct=yes
2648         ;;
2649 (*)
2650         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2651         cf_cv_prog_gnat_correct=no
2652         ;;
2653 esac
2654 ])
2655 dnl ---------------------------------------------------------------------------
2656 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2657 dnl -------------
2658 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2659 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2660 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2661 dnl since it is interwoven with GNU extensions.
2662 dnl
2663 dnl Well, yes we could work around it...
2664 AC_DEFUN([CF_GNU_SOURCE],
2665 [
2666 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2667 AC_TRY_COMPILE([#include <sys/types.h>],[
2668 #ifndef _XOPEN_SOURCE
2669 make an error
2670 #endif],
2671         [cf_cv_gnu_source=no],
2672         [cf_save="$CPPFLAGS"
2673          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2674          AC_TRY_COMPILE([#include <sys/types.h>],[
2675 #ifdef _XOPEN_SOURCE
2676 make an error
2677 #endif],
2678         [cf_cv_gnu_source=no],
2679         [cf_cv_gnu_source=yes])
2680         CPPFLAGS="$cf_save"
2681         ])
2682 ])
2683 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2684 ])dnl
2685 dnl ---------------------------------------------------------------------------
2686 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
2687 dnl --------------
2688 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2689 dnl problem :-).  If we have the compiler but no library, we'll be able to
2690 dnl configure, but won't be able to build the c++ demo program.
2691 AC_DEFUN([CF_GPP_LIBRARY],
2692 [
2693 cf_cxx_library=unknown
2694 case $cf_cv_system_name in
2695 (os2*)
2696         cf_gpp_libname=gpp
2697         ;;
2698 (*)
2699         cf_gpp_libname=g++
2700         ;;
2701 esac
2702 if test "$GXX" = yes; then
2703         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2704         cf_save="$LIBS"
2705         CF_ADD_LIB($cf_gpp_libname)
2706         AC_TRY_LINK([
2707 #include <$cf_gpp_libname/builtin.h>
2708         ],
2709         [two_arg_error_handler_t foo2 = lib_error_handler],
2710         [cf_cxx_library=yes
2711          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2712          if test "$cf_gpp_libname" = cpp ; then
2713             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2714          else
2715             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2716          fi],
2717         [AC_TRY_LINK([
2718 #include <builtin.h>
2719         ],
2720         [two_arg_error_handler_t foo2 = lib_error_handler],
2721         [cf_cxx_library=yes
2722          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2723          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2724         [cf_cxx_library=no])])
2725         LIBS="$cf_save"
2726         AC_MSG_RESULT($cf_cxx_library)
2727 fi
2728 ])dnl
2729 dnl ---------------------------------------------------------------------------
2730 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2731 dnl --------------
2732 dnl Check for version of g++
2733 AC_DEFUN([CF_GXX_VERSION],[
2734 AC_REQUIRE([AC_PROG_CPP])
2735 GXX_VERSION=none
2736 if test "$GXX" = yes; then
2737         AC_MSG_CHECKING(version of ${CXX:-g++})
2738         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2739         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2740         AC_MSG_RESULT($GXX_VERSION)
2741 fi
2742 ])dnl
2743 dnl ---------------------------------------------------------------------------
2744 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
2745 dnl ---------------
2746 dnl Check if the compiler supports useful warning options.
2747 dnl
2748 dnl Most of gcc's options apply to g++, except:
2749 dnl     -Wbad-function-cast
2750 dnl     -Wmissing-declarations
2751 dnl     -Wnested-externs
2752 dnl
2753 dnl Omit a few (for now):
2754 dnl     -Winline
2755 dnl
2756 dnl Parameter:
2757 dnl     $1 is an optional list of g++ warning flags that a particular
2758 dnl             application might want to use, e.g., "no-unused" for
2759 dnl             -Wno-unused
2760 dnl Special:
2761 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2762 dnl
2763 AC_DEFUN([CF_GXX_WARNINGS],
2764 [
2765
2766 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2767 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2768
2769 AC_REQUIRE([CF_GXX_VERSION])
2770
2771 AC_LANG_SAVE
2772 AC_LANG_CPLUSPLUS
2773
2774 cat > conftest.$ac_ext <<EOF
2775 #line __oline__ "configure"
2776 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2777 EOF
2778
2779 if test "$INTEL_CPLUSPLUS" = yes
2780 then
2781 # The "-wdXXX" options suppress warnings:
2782 # remark #1419: external declaration in primary source file
2783 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2784 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2785 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2786 # remark #193: zero used for undefined preprocessing identifier
2787 # remark #593: variable "curs_sb_left_arrow" was set but never used
2788 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2789 # remark #869: parameter "tw" was never referenced
2790 # remark #981: operands are evaluated in unspecified order
2791 # warning #269: invalid format string conversion
2792
2793         AC_CHECKING([for $CC warning options])
2794         cf_save_CXXFLAGS="$CXXFLAGS"
2795         EXTRA_CXXFLAGS="-Wall"
2796         for cf_opt in \
2797                 wd1419 \
2798                 wd1682 \
2799                 wd1683 \
2800                 wd1684 \
2801                 wd193 \
2802                 wd279 \
2803                 wd593 \
2804                 wd810 \
2805                 wd869 \
2806                 wd981
2807         do
2808                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2809                 if AC_TRY_EVAL(ac_compile); then
2810                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2811                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2812                 fi
2813         done
2814         CXXFLAGS="$cf_save_CXXFLAGS"
2815
2816 elif test "$GXX" = yes
2817 then
2818         AC_CHECKING([for $CXX warning options])
2819         cf_save_CXXFLAGS="$CXXFLAGS"
2820         EXTRA_CXXFLAGS="-W -Wall"
2821         cf_gxx_extra_warnings=""
2822         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2823         case "$GCC_VERSION" in
2824         ([[1-2]].*)
2825                 ;;
2826         (*)
2827                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2828                 ;;
2829         esac
2830         for cf_opt in \
2831                 Wabi \
2832                 fabi-version=0 \
2833                 Wextra \
2834                 Wignored-qualifiers \
2835                 Wlogical-op \
2836                 Woverloaded-virtual \
2837                 Wsign-promo \
2838                 Wsynth \
2839                 Wold-style-cast \
2840                 Wcast-align \
2841                 Wcast-qual \
2842                 Wpointer-arith \
2843                 Wshadow \
2844                 Wundef $cf_gxx_extra_warnings $1
2845         do
2846                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2847                 if AC_TRY_EVAL(ac_compile); then
2848                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2849                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2850                 else
2851                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2852                 fi
2853         done
2854         CXXFLAGS="$cf_save_CXXFLAGS"
2855 fi
2856
2857 rm -rf conftest*
2858 AC_LANG_RESTORE
2859 AC_SUBST(EXTRA_CXXFLAGS)
2860 ])dnl
2861 dnl ---------------------------------------------------------------------------
2862 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
2863 dnl ------------
2864 dnl Look for an instance of the Berkeley hashed database.
2865 dnl
2866 dnl $1 = optional parameter, to specify install-prefix for the database.
2867 AC_DEFUN([CF_HASHED_DB],
2868 [
2869 ifelse([$1],,,[
2870 case $1 in
2871 (yes|*able*)
2872         ;;
2873 (*)
2874         if test -d "$1" ; then
2875                 CF_ADD_INCDIR($1/include)
2876                 CF_ADD_LIBDIR($1/lib)
2877         else
2878                 case "$1" in
2879                 (./*|../*|/*)
2880                         AC_MSG_WARN(no such directory $1)
2881                         ;;
2882                 (*)
2883                         CF_FIND_SUB_INCDIR($1)
2884                         CF_FIND_SUB_LIBDIR($1)
2885                         ;;
2886                 esac
2887         fi
2888 esac
2889 ])
2890 AC_CHECK_HEADER(db.h,[
2891 CF_HASHED_DB_VERSION
2892 if test "$cf_cv_hashed_db_version" = unknown ; then
2893         AC_MSG_ERROR(Cannot determine version of db)
2894 else
2895         CF_HASHED_DB_LIBS
2896         if test "$cf_cv_hashed_db_libs" = unknown ; then
2897                 AC_MSG_ERROR(Cannot determine library for db)
2898         elif test "$cf_cv_hashed_db_libs" != default ; then
2899                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2900         fi
2901 fi
2902 ],[
2903         AC_MSG_ERROR(Cannot find db.h)
2904 ])
2905 ])dnl
2906 dnl ---------------------------------------------------------------------------
2907 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2908 dnl -----------------
2909 dnl Given that we have the header and version for hashed database, find the
2910 dnl library information.
2911 AC_DEFUN([CF_HASHED_DB_LIBS],
2912 [
2913 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2914 cf_cv_hashed_db_libs=unknown
2915 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2916 do
2917         cf_save_libs="$LIBS"
2918         if test -n "$cf_db_libs"; then
2919                 CF_ADD_LIB($cf_db_libs)
2920         fi
2921         CF_MSG_LOG(checking for library "$cf_db_libs")
2922         AC_TRY_LINK([
2923 $ac_includes_default
2924 #include <db.h>
2925 ],[
2926         char *path = "/tmp/foo";
2927 #ifdef DB_VERSION_MAJOR
2928 #if DB_VERSION_MAJOR >= 4
2929         DB *result = 0;
2930         db_create(&result, NULL, 0);
2931         result->open(result,
2932                 NULL,
2933                 path,
2934                 path,
2935                 DB_HASH,
2936                 DB_CREATE,
2937                 0644);
2938 #elif DB_VERSION_MAJOR >= 3
2939         DB *result = 0;
2940         db_create(&result, NULL, 0);
2941         result->open(result,
2942                 path,
2943                 path,
2944                 DB_HASH,
2945                 DB_CREATE,
2946                 0644);
2947 #elif DB_VERSION_MAJOR >= 2
2948         DB *result = 0;
2949         db_open(path,
2950                 DB_HASH,
2951                 DB_CREATE,
2952                 0644,
2953                 (DB_ENV *) 0,
2954                 (DB_INFO *) 0,
2955                 &result);
2956 #endif /* DB_VERSION_MAJOR */
2957 #else
2958         DB *result = dbopen(path,
2959                      2,
2960                      0644,
2961                      DB_HASH,
2962                      0);
2963 #endif
2964         ${cf_cv_main_return:-return}(result != 0)
2965 ],[
2966         if test -n "$cf_db_libs" ; then
2967                 cf_cv_hashed_db_libs=$cf_db_libs
2968         else
2969                 cf_cv_hashed_db_libs=default
2970         fi
2971         LIBS="$cf_save_libs"
2972         break
2973 ])
2974         LIBS="$cf_save_libs"
2975 done
2976 ])
2977 ])dnl
2978 dnl ---------------------------------------------------------------------------
2979 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
2980 dnl --------------------
2981 dnl Given that we have the header file for hashed database, find the version
2982 dnl information.
2983 AC_DEFUN([CF_HASHED_DB_VERSION],
2984 [
2985 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2986 cf_cv_hashed_db_version=unknown
2987
2988 for cf_db_version in 1 2 3 4 5 6
2989 do
2990         CF_MSG_LOG(checking for db version $cf_db_version)
2991         AC_TRY_COMPILE([
2992 $ac_includes_default
2993 #include <db.h>
2994
2995 #ifdef DB_VERSION_MAJOR
2996         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2997 #if $cf_db_version == DB_VERSION_MAJOR
2998         /* ok */
2999 #else
3000         make an error
3001 #endif
3002 #else
3003 #if $cf_db_version == 1
3004         /* ok: assuming this is DB 1.8.5 */
3005 #else
3006         make an error
3007 #endif
3008 #endif
3009 ],[DBT *foo = 0],[
3010         cf_cv_hashed_db_version=$cf_db_version
3011         break
3012         ])
3013 done
3014 ])
3015 ])dnl
3016 dnl ---------------------------------------------------------------------------
3017 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3018 dnl --------------
3019 dnl Construct a search-list of directories for a nonstandard header-file
3020 dnl
3021 dnl Parameters
3022 dnl     $1 = the variable to return as result
3023 dnl     $2 = the package name
3024 AC_DEFUN([CF_HEADER_PATH],
3025 [
3026 $1=
3027
3028 # collect the current set of include-directories from compiler flags
3029 cf_header_path_list=""
3030 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3031         for cf_header_path in $CPPFLAGS $CFLAGS
3032         do
3033                 case $cf_header_path in
3034                 (-I*)
3035                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3036                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3037                         cf_header_path_list="$cf_header_path_list [$]$1"
3038                         ;;
3039                 esac
3040         done
3041 fi
3042
3043 # add the variations for the package we are looking for
3044 CF_SUBDIR_PATH($1,$2,include)
3045
3046 test "$includedir" != NONE && \
3047 test "$includedir" != "/usr/include" && \
3048 test -d "$includedir" && {
3049         test -d $includedir &&    $1="[$]$1 $includedir"
3050         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3051 }
3052
3053 test "$oldincludedir" != NONE && \
3054 test "$oldincludedir" != "/usr/include" && \
3055 test -d "$oldincludedir" && {
3056         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3057         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3058 }
3059
3060 $1="[$]$1 $cf_header_path_list"
3061 ])dnl
3062 dnl ---------------------------------------------------------------------------
3063 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
3064 dnl ---------------
3065 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3066 AC_DEFUN([CF_HELP_MESSAGE],
3067 [AC_DIVERT_HELP([$1])dnl
3068 ])dnl
3069 dnl ---------------------------------------------------------------------------
3070 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3071 dnl ---------------
3072 dnl Construct the list of include-options according to whether we're building
3073 dnl in the source directory or using '--srcdir=DIR' option.
3074 AC_DEFUN([CF_INCLUDE_DIRS],
3075 [
3076 if test "$srcdir" != "."; then
3077         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3078 fi
3079 CPPFLAGS="-I../include $CPPFLAGS"
3080 if test "$srcdir" != "."; then
3081         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3082 fi
3083 CPPFLAGS="-I. $CPPFLAGS"
3084 AC_SUBST(CPPFLAGS)
3085 ])dnl
3086 dnl ---------------------------------------------------------------------------
3087 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3088 dnl -----------------
3089 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3090 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3091 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3092 dnl
3093 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3094 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3095 dnl the wrappers for gcc and g++ warnings.
3096 dnl
3097 dnl $1 = GCC (default) or GXX
3098 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3099 dnl $3 = CFLAGS (default) or CXXFLAGS
3100 AC_DEFUN([CF_INTEL_COMPILER],[
3101 AC_REQUIRE([AC_CANONICAL_HOST])
3102 ifelse([$2],,INTEL_COMPILER,[$2])=no
3103
3104 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3105         case $host_os in
3106         (linux*|gnu*)
3107                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3108                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3109                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3110                 AC_TRY_COMPILE([],[
3111 #ifdef __INTEL_COMPILER
3112 #else
3113 make an error
3114 #endif
3115 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3116 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3117 ],[])
3118                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3119                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3120                 ;;
3121         esac
3122 fi
3123 ])dnl
3124 dnl ---------------------------------------------------------------------------
3125 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3126 dnl ----------
3127 dnl Check if we have either a function or macro for 'isascii()'.
3128 AC_DEFUN([CF_ISASCII],
3129 [
3130 AC_MSG_CHECKING(for isascii)
3131 AC_CACHE_VAL(cf_cv_have_isascii,[
3132         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3133         [cf_cv_have_isascii=yes],
3134         [cf_cv_have_isascii=no])
3135 ])dnl
3136 AC_MSG_RESULT($cf_cv_have_isascii)
3137 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3138 ])dnl
3139 dnl ---------------------------------------------------------------------------
3140 dnl CF_LARGEFILE version: 9 updated: 2015/04/18 08:56:57
3141 dnl ------------
3142 dnl Add checks for large file support.
3143 AC_DEFUN([CF_LARGEFILE],[
3144 ifdef([AC_FUNC_FSEEKO],[
3145         AC_SYS_LARGEFILE
3146         if test "$enable_largefile" != no ; then
3147         AC_FUNC_FSEEKO
3148
3149         # Normally we would collect these definitions in the config.h,
3150         # but (like _XOPEN_SOURCE), some environments rely on having these
3151         # defined before any of the system headers are included.  Another
3152         # case comes up with C++, e.g., on AIX the compiler compiles the
3153         # header files by themselves before looking at the body files it is
3154         # told to compile.  For ncurses, those header files do not include
3155         # the config.h
3156         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
3157         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
3158         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
3159
3160         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3161                 AC_TRY_COMPILE([
3162 #include <sys/types.h>
3163 #include <dirent.h>
3164                 ],[
3165                 /* if transitional largefile support is setup, this is true */
3166                 extern struct dirent64 * readdir(DIR *);
3167                 struct dirent64 *x = readdir((DIR *)0);
3168                 struct dirent *y = readdir((DIR *)0);
3169                 int z = x - y;
3170                 ],
3171                 [cf_cv_struct_dirent64=yes],
3172                 [cf_cv_struct_dirent64=no])
3173         ])
3174         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3175         fi
3176 ])
3177 ])
3178 dnl ---------------------------------------------------------------------------
3179 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3180 dnl -----------------
3181 dnl Check for compiler/linker flags used to temporarily force usage of static
3182 dnl libraries.  This depends on the compiler and platform.  Use this to help
3183 dnl ensure that the linker picks up a given library based on its position in
3184 dnl the list of linker options and libraries.
3185 AC_DEFUN([CF_LDFLAGS_STATIC],[
3186
3187 if test "$GCC" = yes ; then
3188         case $cf_cv_system_name in
3189         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3190                 LDFLAGS_STATIC=
3191                 LDFLAGS_SHARED=
3192                 ;;
3193         (*)     # normally, except when broken
3194                 LDFLAGS_STATIC=-static
3195                 LDFLAGS_SHARED=-dynamic
3196                 ;;
3197         esac
3198 else
3199         case $cf_cv_system_name in
3200         (aix[[4-7]]*)   # from ld manpage
3201                 LDFLAGS_STATIC=-bstatic
3202                 LDFLAGS_SHARED=-bdynamic
3203                 ;;
3204         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3205                 # We could also use just "archive" and "shared".
3206                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3207                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3208                 ;;
3209         (irix*)         # from ld manpage IRIX64
3210                 LDFLAGS_STATIC=-Bstatic
3211                 LDFLAGS_SHARED=-Bdynamic
3212                 ;;
3213         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3214                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3215                 LDFLAGS_STATIC=-noso
3216                 LDFLAGS_SHARED=-so_archive
3217                 ;;
3218         (solaris2*)
3219                 LDFLAGS_STATIC=-Bstatic
3220                 LDFLAGS_SHARED=-Bdynamic
3221                 ;;
3222         esac
3223 fi
3224
3225 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3226 then
3227         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3228
3229         rm -f libconftest.a
3230         cat >conftest.$ac_ext <<EOF
3231 #line __oline__ "configure"
3232 #include <stdio.h>
3233 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3234 EOF
3235         if AC_TRY_EVAL(ac_compile) ; then
3236                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3237                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3238         fi
3239         rm -f conftest.*
3240
3241         cf_save_LIBS="$LIBS"
3242
3243         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3244         AC_TRY_LINK([
3245 #line __oline__ "configure"
3246 #include <stdio.h>
3247 int cf_ldflags_static(FILE *fp);
3248 ],[
3249         return cf_ldflags_static(stdin);
3250 ],[
3251         # some linkers simply ignore the -dynamic
3252         case x`file conftest$ac_exeext 2>/dev/null` in
3253         (*static*)
3254                 cf_ldflags_static=no
3255                 ;;
3256         (*)
3257                 cf_ldflags_static=yes
3258                 ;;
3259         esac
3260 ],[cf_ldflags_static=no])
3261
3262         rm -f libconftest.*
3263         LIBS="$cf_save_LIBS"
3264
3265         AC_MSG_RESULT($cf_ldflags_static)
3266
3267         if test $cf_ldflags_static != yes
3268         then
3269                 LDFLAGS_STATIC=
3270                 LDFLAGS_SHARED=
3271         fi
3272 else
3273         LDFLAGS_STATIC=
3274         LDFLAGS_SHARED=
3275 fi
3276
3277 AC_SUBST(LDFLAGS_STATIC)
3278 AC_SUBST(LDFLAGS_SHARED)
3279 ])
3280 dnl ---------------------------------------------------------------------------
3281 dnl CF_LD_RPATH_OPT version: 7 updated: 2016/02/20 18:01:19
3282 dnl ---------------
3283 dnl For the given system and compiler, find the compiler flags to pass to the
3284 dnl loader to use the "rpath" feature.
3285 AC_DEFUN([CF_LD_RPATH_OPT],
3286 [
3287 AC_REQUIRE([CF_CHECK_CACHE])
3288
3289 LD_RPATH_OPT=
3290 AC_MSG_CHECKING(for an rpath option)
3291 case $cf_cv_system_name in
3292 (irix*)
3293         if test "$GCC" = yes; then
3294                 LD_RPATH_OPT="-Wl,-rpath,"
3295         else
3296                 LD_RPATH_OPT="-rpath "
3297         fi
3298         ;;
3299 (linux*|gnu*|k*bsd*-gnu|freebsd*)
3300         LD_RPATH_OPT="-Wl,-rpath,"
3301         ;;
3302 (openbsd[[2-9]].*|mirbsd*)
3303         LD_RPATH_OPT="-Wl,-rpath,"
3304         ;;
3305 (dragonfly*)
3306         LD_RPATH_OPT="-rpath "
3307         ;;
3308 (netbsd*)
3309         LD_RPATH_OPT="-Wl,-rpath,"
3310         ;;
3311 (osf*|mls+*)
3312         LD_RPATH_OPT="-rpath "
3313         ;;
3314 (solaris2*)
3315         LD_RPATH_OPT="-R"
3316         ;;
3317 (*)
3318         ;;
3319 esac
3320 AC_MSG_RESULT($LD_RPATH_OPT)
3321
3322 case "x$LD_RPATH_OPT" in
3323 (x-R*)
3324         AC_MSG_CHECKING(if we need a space after rpath option)
3325         cf_save_LIBS="$LIBS"
3326         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3327         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3328         LIBS="$cf_save_LIBS"
3329         AC_MSG_RESULT($cf_rpath_space)
3330         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3331         ;;
3332 esac
3333 ])dnl
3334 dnl ---------------------------------------------------------------------------
3335 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3336 dnl ---------------
3337 dnl Construct a search-list of directories for a nonstandard library-file
3338 dnl
3339 dnl Parameters
3340 dnl     $1 = the variable to return as result
3341 dnl     $2 = the package name
3342 AC_DEFUN([CF_LIBRARY_PATH],
3343 [
3344 $1=
3345 cf_library_path_list=""
3346 if test -n "${LDFLAGS}${LIBS}" ; then
3347         for cf_library_path in $LDFLAGS $LIBS
3348         do
3349                 case $cf_library_path in
3350                 (-L*)
3351                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3352                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3353                         cf_library_path_list="$cf_library_path_list [$]$1"
3354                         ;;
3355                 esac
3356         done
3357 fi
3358
3359 CF_SUBDIR_PATH($1,$2,lib)
3360
3361 $1="$cf_library_path_list [$]$1"
3362 ])dnl
3363 dnl ---------------------------------------------------------------------------
3364 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3365 dnl ------------------
3366 AC_DEFUN([CF_LIBTOOL_VERSION],[
3367 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3368 then
3369         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3370 else
3371         cf_cv_libtool_version=
3372 fi
3373 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3374 ])dnl
3375 dnl ---------------------------------------------------------------------------
3376 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
3377 dnl -------------
3378 dnl Compute the library-prefix for the given host system
3379 dnl $1 = variable to set
3380 define([CF_LIB_PREFIX],
3381 [
3382         case $cf_cv_system_name in
3383         (OS/2*|os2*)
3384                 if test "$DFT_LWR_MODEL" = libtool; then
3385                         LIB_PREFIX='lib'
3386                 else
3387                         LIB_PREFIX=''
3388                 fi
3389                 ;;
3390         (*)     LIB_PREFIX='lib'
3391                 ;;
3392         esac
3393 ifelse($1,,,[$1=$LIB_PREFIX])
3394         AC_SUBST(LIB_PREFIX)
3395 ])dnl
3396 dnl ---------------------------------------------------------------------------
3397 dnl CF_LIB_RULES version: 86 updated: 2015/11/07 20:01:34
3398 dnl ------------
3399 dnl Append definitions and rules for the given models to the subdirectory
3400 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3401 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3402 dnl the corresponding makefile to list the models that we'll generate.
3403 dnl
3404 dnl For shared libraries, make a list of symbolic links to construct when
3405 dnl generating each library.  The convention used for Linux is the simplest
3406 dnl one:
3407 dnl     lib<name>.so    ->
3408 dnl     lib<name>.so.<major>    ->
3409 dnl     lib<name>.so.<maj>.<minor>
3410 dnl
3411 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3412 AC_DEFUN([CF_LIB_RULES],
3413 [
3414 cf_prefix=$LIB_PREFIX
3415 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3416
3417 case $cf_cv_shlib_version in
3418 (cygdll|msysdll|mingw)
3419         TINFO_NAME=$TINFO_ARG_SUFFIX
3420         TINFO_SUFFIX=.dll
3421         ;;
3422 esac
3423
3424 if test -n "$TINFO_SUFFIX" ; then
3425         case $TINFO_SUFFIX in
3426         (tw*)
3427                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
3428                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
3429                 ;;
3430         (t*)
3431                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
3432                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
3433                 ;;
3434         (w*)
3435                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
3436                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
3437                 ;;
3438         esac
3439 fi
3440
3441 for cf_dir in $SRC_SUBDIRS
3442 do
3443         if test ! -d $srcdir/$cf_dir ; then
3444                 continue
3445         elif test -f $srcdir/$cf_dir/modules; then
3446
3447                 SHARED_LIB=
3448                 Libs_To_Make=
3449                 cf_awk_program=
3450                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3451                 then
3452                         cf_awk_program="$cf_awk_program\
3453 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
3454 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
3455 "
3456                 fi
3457
3458                 if test "x$WILDCARD_SYMS" = xno
3459                 then
3460                         cf_awk_program="$cf_awk_program\
3461 /[[     ]]_\\*;/ { skip=1; next; }\
3462 "
3463                 fi
3464
3465                 if test "x$cf_awk_program" != "x"
3466                 then
3467                         cat >>$cf_dir/Makefile <<CF_EOF
3468
3469 # Generated by CF_LIB_RULES
3470 resulting.map: $UNALTERED_SYMS
3471         $AWK 'BEGIN { skip = 1; last=""; } \
3472 $cf_awk_program \
3473 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
3474  skip = 0; last = \[$]\[$]0; } \
3475 END { print last; }' < $UNALTERED_SYMS >\[$]@
3476
3477 distclean::
3478         rm -f resulting.map
3479 CF_EOF
3480                 fi
3481
3482                 for cf_item in $cf_LIST_MODELS
3483                 do
3484                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3485                         cf_libname=$cf_dir
3486                         test "$cf_dir" = c++ && cf_libname=ncurses++
3487                         if test $cf_item = shared ; then
3488                                 if test -n "${LIB_SUFFIX}"
3489                                 then
3490                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3491                                 else
3492                                         cf_shared_suffix="$cf_suffix"
3493                                 fi
3494                                 if test "$cf_cv_do_symlinks" = yes ; then
3495                                         cf_version_name=
3496
3497                                         case "$cf_cv_shlib_version" in
3498                                         (rel)
3499                                                 cf_version_name=REL_VERSION
3500                                                 ;;
3501                                         (abi)
3502                                                 cf_version_name=ABI_VERSION
3503                                                 ;;
3504                                         esac
3505
3506                                         if test -n "$cf_version_name"
3507                                         then
3508                                                 case "$cf_cv_system_name" in
3509                                                 (darwin*)
3510                                                         # "w", etc?
3511                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3512                                                         ;;
3513                                                 (*)
3514                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3515                                                         ;;
3516                                                 esac
3517                                         fi
3518                                         if test -n "${USE_LIB_SUFFIX}"
3519                                         then
3520                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3521                                         else
3522                                                 cf_shared_suffix="$cf_suffix"
3523                                         fi
3524                                 fi
3525                                 # cygwin needs import library, and has unique naming convention
3526                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3527                                 # use 'cyg' prefix for shared lib.
3528                                 case $cf_cv_shlib_version in
3529                                 (cygdll)
3530                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3531                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
3532                                         ;;
3533                                 (msysdll)
3534                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3535                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
3536                                         ;;
3537                                 (mingw)
3538                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3539                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
3540                                         ;;
3541                                 (*)
3542                                         cf_add_lib=
3543                                         ;;
3544                                 esac
3545                                 if test -n "$cf_add_lib"
3546                                 then
3547                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3548                                         continue
3549                                 fi
3550                         fi
3551                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3552                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3553                 done
3554
3555                 if test $cf_dir = ncurses ; then
3556                         cf_subsets="$LIB_SUBSETS"
3557                         cf_r_parts="$cf_subsets"
3558                         cf_liblist="$Libs_To_Make"
3559
3560                         while test -n "$cf_r_parts"
3561                         do
3562                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3563                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3564                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3565                                         cf_add_lib=
3566                                         case $cf_l_parts in
3567                                         (*termlib*)
3568                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3569                                                 ;;
3570                                         (*ticlib*)
3571                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3572                                                 ;;
3573                                         (*)
3574                                                 break
3575                                                 ;;
3576                                         esac
3577                                         if test -n "$cf_add_lib"; then
3578                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
3579                                         fi
3580                                 else
3581                                         break
3582                                 fi
3583                         done
3584                 else
3585                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3586                 fi
3587
3588                 if test $cf_dir = c++; then
3589                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3590                                 cf_list=
3591                                 for cf_item in $Libs_To_Make
3592                                 do
3593                                         case $cf_item in
3594                                         (*.a)
3595                                                 ;;
3596                                         (*)
3597                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3598                                                 ;;
3599                                         esac
3600                                         for cf_test in $cf_list
3601                                         do
3602                                                 if test "$cf_test" = "$cf_item"
3603                                                 then
3604                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3605                                                         cf_item=
3606                                                         break
3607                                                 fi
3608                                         done
3609                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3610                                 done
3611                                 Libs_To_Make="$cf_list"
3612                         fi
3613                 fi
3614
3615                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3616                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3617                         $cf_dir/Makefile >$cf_dir/Makefile.out
3618                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3619
3620                 $AWK -f $srcdir/mk-0th.awk \
3621                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3622                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3623
3624                 for cf_subset in $cf_subsets
3625                 do
3626                         cf_subdirs=
3627                         for cf_item in $cf_LIST_MODELS
3628                         do
3629
3630                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3631                         CF_UPPER(cf_ITEM,$cf_item)
3632
3633                         CXX_MODEL=$cf_ITEM
3634                         if test "$CXX_MODEL" = SHARED; then
3635                                 case $cf_cv_shlib_version in
3636                                 (cygdll|msysdll|mingw)
3637                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3638                                         with_shared_cxx=yes
3639                                         ;;
3640                                 (*)
3641                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3642                                         ;;
3643                                 esac
3644                         fi
3645
3646                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3647                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3648
3649                         # Test for case where we build libtinfo with a different name.
3650                         cf_libname=$cf_dir
3651                         if test $cf_dir = ncurses ; then
3652                                 case $cf_subset in
3653                                 (*base*)
3654                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
3655                                         ;;
3656                                 (*termlib*)
3657                                         cf_libname=$TINFO_LIB_SUFFIX
3658                                         ;;
3659                                 (ticlib*)
3660                                         cf_libname=$TICS_LIB_SUFFIX
3661                                         ;;
3662                                 esac
3663                         elif test $cf_dir = c++ ; then
3664                                 cf_libname=ncurses++$USE_LIB_SUFFIX
3665                         else
3666                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
3667                         fi
3668                         if test -n "${USE_ARG_SUFFIX}" ; then
3669                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
3670                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
3671                         fi
3672
3673                         # These dependencies really are for development, not
3674                         # builds, but they are useful in porting, too.
3675                         cf_depend="../include/ncurses_cfg.h"
3676                         if test "$srcdir" = "."; then
3677                                 cf_reldir="."
3678                         else
3679                                 cf_reldir="\${srcdir}"
3680                         fi
3681
3682                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3683                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3684                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3685                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3686                         fi
3687
3688                         cf_dir_suffix=
3689                         old_cf_suffix="$cf_suffix"
3690                         if test "$cf_cv_shlib_version_infix" = yes ; then
3691                         if test -n "$USE_LIB_SUFFIX" ; then
3692                                 case $USE_LIB_SUFFIX in
3693                                 (tw*)
3694                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
3695                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
3696                                         cf_dir_suffix=tw$EXTRA_SUFFIX
3697                                         ;;
3698                                 (t*)
3699                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
3700                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
3701                                         cf_dir_suffix=t$EXTRA_SUFFIX
3702                                         ;;
3703                                 (w*)
3704                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
3705                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
3706                                         cf_dir_suffix=w$EXTRA_SUFFIX
3707                                         ;;
3708                                 (*)
3709                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
3710                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
3711                                         cf_dir_suffix=$EXTRA_SUFFIX
3712                                         ;;
3713                                 esac
3714                         fi
3715                         fi
3716
3717                         $AWK -f $srcdir/mk-1st.awk \
3718                                 name=${cf_libname}${cf_dir_suffix} \
3719                                 traces=$LIB_TRACING \
3720                                 MODEL=$cf_ITEM \
3721                                 CXX_MODEL=$CXX_MODEL \
3722                                 model=$cf_subdir \
3723                                 prefix=$cf_prefix \
3724                                 suffix=$cf_suffix \
3725                                 subset=$cf_subset \
3726                                 driver=$cf_cv_term_driver \
3727                                 SymLink="$LN_S" \
3728                                 TermlibRoot=$TINFO_NAME \
3729                                 TermlibSuffix=$TINFO_SUFFIX \
3730                                 ShlibVer=$cf_cv_shlib_version \
3731                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3732                                 ReLink=${cf_cv_do_relink:-no} \
3733                                 DoLinks=$cf_cv_do_symlinks \
3734                                 rmSoLocs=$cf_cv_rm_so_locs \
3735                                 ldconfig="$LDCONFIG" \
3736                                 overwrite=$WITH_OVERWRITE \
3737                                 depend="$cf_depend" \
3738                                 host="$host" \
3739                                 libtool_version="$LIBTOOL_VERSION" \
3740                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3741
3742                         cf_suffix="$old_cf_suffix"
3743
3744                         for cf_subdir2 in $cf_subdirs lib
3745                         do
3746                                 test $cf_subdir = $cf_subdir2 && break
3747                         done
3748                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3749                         $AWK -f $srcdir/mk-2nd.awk \
3750                                 name=$cf_dir \
3751                                 traces=$LIB_TRACING \
3752                                 MODEL=$cf_ITEM \
3753                                 model=$cf_subdir \
3754                                 subset=$cf_subset \
3755                                 srcdir=$srcdir \
3756                                 echo=$WITH_ECHO \
3757                                 crenames=$cf_cv_prog_CC_c_o \
3758                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3759                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3760                         cf_subdirs="$cf_subdirs $cf_subdir"
3761                         done
3762                 done
3763         fi
3764
3765         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3766 done
3767
3768 for cf_dir in $SRC_SUBDIRS
3769 do
3770         if test ! -d $srcdir/$cf_dir ; then
3771                 continue
3772         fi
3773
3774         if test -f $cf_dir/Makefile ; then
3775                 case "$cf_dir" in
3776                 (Ada95)
3777                         echo 'libs \' >> Makefile
3778                         echo 'install.libs \' >> Makefile
3779                         echo 'uninstall.libs ::' >> Makefile
3780                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3781                         ;;
3782                 esac
3783         fi
3784
3785         if test -f $srcdir/$cf_dir/modules; then
3786                 echo >> Makefile
3787                 if test -f $srcdir/$cf_dir/headers; then
3788 cat >> Makefile <<CF_EOF
3789 install.includes \\
3790 uninstall.includes \\
3791 CF_EOF
3792                 fi
3793 if test "$cf_dir" != "c++" ; then
3794 echo 'lint \' >> Makefile
3795 fi
3796 cat >> Makefile <<CF_EOF
3797 libs \\
3798 lintlib \\
3799 install.libs \\
3800 uninstall.libs \\
3801 install.$cf_dir \\
3802 uninstall.$cf_dir ::
3803         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3804 CF_EOF
3805         elif test -f $srcdir/$cf_dir/headers; then
3806 cat >> Makefile <<CF_EOF
3807
3808 libs \\
3809 install.libs \\
3810 uninstall.libs \\
3811 install.includes \\
3812 uninstall.includes ::
3813         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3814 CF_EOF
3815 fi
3816 done
3817
3818 if test "x$cf_with_db_install" = xyes; then
3819 cat >> Makefile <<CF_EOF
3820
3821 install.libs uninstall.libs \\
3822 install.data uninstall.data ::
3823 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3824 CF_EOF
3825 else
3826 cat >> Makefile <<CF_EOF
3827
3828 install.libs uninstall.libs ::
3829         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3830 CF_EOF
3831 fi
3832
3833 if test "x$cf_with_manpages" = xyes; then
3834 cat >> Makefile <<CF_EOF
3835
3836 install.man \\
3837 uninstall.man ::
3838         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3839 CF_EOF
3840 fi
3841
3842 cat >> Makefile <<CF_EOF
3843
3844 distclean ::
3845         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3846         rm -f headers.sh headers.sed mk_shared_lib.sh
3847         rm -f edit_man.* man_alias.*
3848         rm -rf \${DIRS_TO_MAKE}
3849 CF_EOF
3850
3851 # Special case: tack's manpage lives in its own directory.
3852 if test "x$cf_with_manpages" = xyes; then
3853 if test -d tack ; then
3854 if test -f $srcdir/$tack.h; then
3855 cat >> Makefile <<CF_EOF
3856
3857 install.man \\
3858 uninstall.man ::
3859         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3860 CF_EOF
3861 fi
3862 fi
3863 fi
3864
3865 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3866 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3867 dnl anything, and will make it more standardized.  It's awkward to decide this
3868 dnl at configuration because of quoting, so we'll simply make all headers
3869 dnl installed via a script that can do the right thing.
3870
3871 rm -f headers.sed headers.sh
3872
3873 dnl ( generating this script makes the makefiles a little tidier :-)
3874 echo creating headers.sh
3875 cat >headers.sh <<CF_EOF
3876 #! $SHELL
3877 # This shell script is generated by the 'configure' script.  It is invoked in a
3878 # subdirectory of the build tree.  It generates a sed-script in the parent
3879 # directory that is used to adjust includes for header files that reside in a
3880 # subdirectory of /usr/include, etc.
3881 PRG=""
3882 while test \[$]# != 3
3883 do
3884 PRG="\$PRG \[$]1"; shift
3885 done
3886 DST=\[$]1
3887 REF=\[$]2
3888 SRC=\[$]3
3889 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3890 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3891 echo installing \$SRC in \$DST
3892 CF_EOF
3893
3894 if test $WITH_CURSES_H = yes; then
3895         cat >>headers.sh <<CF_EOF
3896 case \$DST in
3897 (/*/include/*)
3898         END=\`basename \$DST\`
3899         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3900         do
3901                 NAME=\`basename \$i\`
3902                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3903         done
3904         ;;
3905 (*)
3906         echo "" >> \$TMPSED
3907         ;;
3908 esac
3909 CF_EOF
3910
3911 else
3912         cat >>headers.sh <<CF_EOF
3913 case \$DST in
3914 (/*/include/*)
3915         END=\`basename \$DST\`
3916         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3917         do
3918                 NAME=\`basename \$i\`
3919                 if test "\$NAME" = "curses.h"
3920                 then
3921                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3922                         NAME=ncurses.h
3923                 fi
3924                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3925         done
3926         ;;
3927 (*)
3928         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3929         ;;
3930 esac
3931 CF_EOF
3932 fi
3933 cat >>headers.sh <<CF_EOF
3934 rm -f \$TMPSRC
3935 sed -f \$TMPSED \$SRC > \$TMPSRC
3936 NAME=\`basename \$SRC\`
3937 CF_EOF
3938 if test $WITH_CURSES_H != yes; then
3939         cat >>headers.sh <<CF_EOF
3940 test "\$NAME" = "curses.h" && NAME=ncurses.h
3941 CF_EOF
3942 fi
3943 cat >>headers.sh <<CF_EOF
3944 # Just in case someone gzip'd manpages, remove the conflicting copy.
3945 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3946
3947 eval \$PRG \$TMPSRC \$DST/\$NAME
3948 rm -f \$TMPSRC \$TMPSED
3949 CF_EOF
3950
3951 chmod 0755 headers.sh
3952
3953 for cf_dir in $SRC_SUBDIRS
3954 do
3955         if test ! -d $srcdir/$cf_dir ; then
3956                 continue
3957         fi
3958
3959         if test -f $srcdir/$cf_dir/headers; then
3960                 $AWK -f $srcdir/mk-hdr.awk \
3961                         subset="$LIB_SUBSETS" \
3962                         compat="$WITH_CURSES_H" \
3963                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3964         fi
3965
3966         if test -f $srcdir/$cf_dir/modules; then
3967                 if test "$cf_dir" != "c++" ; then
3968                         cat >>$cf_dir/Makefile <<"CF_EOF"
3969 depend : ${AUTO_SRC}
3970         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3971
3972 # DO NOT DELETE THIS LINE -- make depend depends on it.
3973 CF_EOF
3974                 fi
3975         fi
3976 done
3977 AC_SUBST(Libs_To_Make)
3978 ])dnl
3979 dnl ---------------------------------------------------------------------------
3980 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3981 dnl -------------
3982 dnl Find the and soname for the given shared library.  Set the cache variable
3983 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3984 dnl variable to "unknown".
3985 dnl
3986 dnl $1 = headers
3987 dnl $2 = code
3988 dnl $3 = library name
3989 AC_DEFUN([CF_LIB_SONAME],
3990 [
3991 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3992
3993 cf_cv_$3_soname=unknown
3994 if test "$cross_compiling" != yes ; then
3995 cat >conftest.$ac_ext <<CF_EOF
3996 $1
3997 int main()
3998 {
3999 $2
4000         ${cf_cv_main_return:-return}(0);
4001 }
4002 CF_EOF
4003 cf_save_LIBS="$LIBS"
4004         CF_ADD_LIB($3)
4005         if AC_TRY_EVAL(ac_compile) ; then
4006                 if AC_TRY_EVAL(ac_link) ; then
4007                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
4008                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4009                 fi
4010         fi
4011 rm -rf conftest*
4012 LIBS="$cf_save_LIBS"
4013 fi
4014 ])
4015 ])
4016 dnl ---------------------------------------------------------------------------
4017 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
4018 dnl -------------
4019 dnl Compute the library file-suffix from the given model name
4020 dnl $1 = model name
4021 dnl $2 = variable to set (the nominal library suffix)
4022 dnl $3 = dependency variable to set (actual filename)
4023 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4024 AC_DEFUN([CF_LIB_SUFFIX],
4025 [
4026         case X$1 in
4027         (Xlibtool)
4028                 $2='.la'
4029                 $3=[$]$2
4030                 ;;
4031         (Xdebug)
4032                 $2='_g.a'
4033                 $3=[$]$2
4034                 ;;
4035         (Xprofile)
4036                 $2='_p.a'
4037                 $3=[$]$2
4038                 ;;
4039         (Xshared)
4040                 case $cf_cv_system_name in
4041                 (aix[[5-7]]*)
4042                         $2='.so'
4043                         $3=[$]$2
4044                         ;;
4045                 (cygwin*|msys*|mingw*)
4046                         $2='.dll'
4047                         $3='.dll.a'
4048                         ;;
4049                 (darwin*)
4050                         $2='.dylib'
4051                         $3=[$]$2
4052                         ;;
4053                 (hpux*)
4054                         case $target in
4055                         (ia64*)
4056                                 $2='.so'
4057                                 $3=[$]$2
4058                                 ;;
4059                         (*)
4060                                 $2='.sl'
4061                                 $3=[$]$2
4062                                 ;;
4063                         esac
4064                         ;;
4065                 (*)
4066                         $2='.so'
4067                         $3=[$]$2
4068                         ;;
4069                 esac
4070                 ;;
4071         (*)
4072                 $2='.a'
4073                 $3=[$]$2
4074                 ;;
4075         esac
4076         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
4077         then
4078                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
4079                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
4080         fi
4081 ])dnl
4082 dnl ---------------------------------------------------------------------------
4083 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
4084 dnl -----------
4085 dnl Compute the string to append to -library from the given model name
4086 dnl $1 = model name
4087 dnl $2 = variable to set
4088 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4089 AC_DEFUN([CF_LIB_TYPE],
4090 [
4091         case $1 in
4092         (libtool) $2=''   ;;
4093         (normal)  $2=''   ;;
4094         (debug)   $2='_g' ;;
4095         (profile) $2='_p' ;;
4096         (shared)  $2=''   ;;
4097         esac
4098         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
4099 ])dnl
4100 dnl ---------------------------------------------------------------------------
4101 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
4102 dnl ----------------
4103 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
4104 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
4105 dnl have to provide wrappers for global tables to ensure they're linked
4106 dnl properly.
4107 AC_DEFUN([CF_LINK_DATAONLY],
4108 [
4109 AC_MSG_CHECKING([if data-only library module links])
4110 AC_CACHE_VAL(cf_cv_link_dataonly,[
4111         rm -f conftest.a
4112         cat >conftest.$ac_ext <<EOF
4113 #line __oline__ "configure"
4114 int     testdata[[3]] = { 123, 456, 789 };
4115 EOF
4116         if AC_TRY_EVAL(ac_compile) ; then
4117                 mv conftest.o data.o && \
4118                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
4119         fi
4120         rm -f conftest.$ac_ext data.o
4121         cat >conftest.$ac_ext <<EOF
4122 #line __oline__ "configure"
4123 int     testfunc()
4124 {
4125 #if defined(NeXT)
4126         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
4127 #else
4128         extern int testdata[[3]];
4129         return testdata[[0]] == 123
4130            &&  testdata[[1]] == 456
4131            &&  testdata[[2]] == 789;
4132 #endif
4133 }
4134 EOF
4135         if AC_TRY_EVAL(ac_compile); then
4136                 mv conftest.o func.o && \
4137                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
4138         fi
4139         rm -f conftest.$ac_ext func.o
4140         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
4141         cf_saveLIBS="$LIBS"
4142         LIBS="conftest.a $LIBS"
4143         AC_TRY_RUN([
4144         int main()
4145         {
4146                 extern int testfunc();
4147                 ${cf_cv_main_return:-return} (!testfunc());
4148         }
4149         ],
4150         [cf_cv_link_dataonly=yes],
4151         [cf_cv_link_dataonly=no],
4152         [cf_cv_link_dataonly=unknown])
4153         LIBS="$cf_saveLIBS"
4154         ])
4155 AC_MSG_RESULT($cf_cv_link_dataonly)
4156
4157 if test "$cf_cv_link_dataonly" = no ; then
4158         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
4159         BROKEN_LINKER=1
4160 fi
4161
4162 ])dnl
4163 dnl ---------------------------------------------------------------------------
4164 dnl CF_LINK_FUNCS version: 8 updated: 2012/10/06 17:56:13
4165 dnl -------------
4166 dnl Most Unix systems have both link and symlink, a few don't have symlink.
4167 dnl A few non-Unix systems implement symlink, but not link.
4168 dnl A few non-systems implement neither (or have nonfunctional versions).
4169 AC_DEFUN([CF_LINK_FUNCS],
4170 [
4171 AC_CHECK_FUNCS( \
4172         remove \
4173         unlink )
4174
4175 if test "$cross_compiling" = yes ; then
4176         AC_CHECK_FUNCS( \
4177                 link \
4178                 symlink )
4179 else
4180         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
4181                 cf_cv_link_funcs=
4182                 for cf_func in link symlink ; do
4183                         AC_TRY_RUN([
4184 #include <sys/types.h>
4185 #include <sys/stat.h>
4186 #ifdef HAVE_UNISTD_H
4187 #include <unistd.h>
4188 #endif
4189 int main()
4190 {
4191         int fail = 0;
4192         char *src = "config.log";
4193         char *dst = "conftest.chk";
4194         struct stat src_sb;
4195         struct stat dst_sb;
4196
4197         stat(src, &src_sb);
4198         fail = ($cf_func("config.log", "conftest.chk") < 0)
4199             || (stat(dst, &dst_sb) < 0)
4200             || (dst_sb.st_mtime != src_sb.st_mtime);
4201 #ifdef HAVE_UNLINK
4202         unlink(dst);
4203 #else
4204         remove(dst);
4205 #endif
4206         ${cf_cv_main_return:-return} (fail);
4207 }
4208                         ],[
4209                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
4210                         eval 'ac_cv_func_'$cf_func'=yes'],[
4211                         eval 'ac_cv_func_'$cf_func'=no'],[
4212                         eval 'ac_cv_func_'$cf_func'=error'])
4213                 done
4214                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
4215         ])
4216         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
4217         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
4218 fi
4219 ])dnl
4220 dnl ---------------------------------------------------------------------------
4221 dnl CF_MAKEFLAGS version: 17 updated: 2015/08/05 20:44:28
4222 dnl ------------
4223 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
4224 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
4225 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
4226 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
4227 AC_DEFUN([CF_MAKEFLAGS],
4228 [
4229 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
4230         cf_cv_makeflags=''
4231         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
4232         do
4233                 cat >cf_makeflags.tmp <<CF_EOF
4234 SHELL = $SHELL
4235 all :
4236         @ echo '.$cf_option'
4237 CF_EOF
4238                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
4239                 case "$cf_result" in
4240                 (.*k|.*kw)
4241                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
4242                         case "$cf_result" in
4243                         (.*CC=*)        cf_cv_makeflags=
4244                                 ;;
4245                         (*)     cf_cv_makeflags=$cf_option
4246                                 ;;
4247                         esac
4248                         break
4249                         ;;
4250                 (.-)    ;;
4251                 (*)     echo "given option \"$cf_option\", no match \"$cf_result\""
4252                         ;;
4253                 esac
4254         done
4255         rm -f cf_makeflags.tmp
4256 ])
4257
4258 AC_SUBST(cf_cv_makeflags)
4259 ])dnl
4260 dnl ---------------------------------------------------------------------------
4261 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
4262 dnl ------------
4263 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
4264 dnl a monocase filesystem.
4265 AC_DEFUN([CF_MAKE_TAGS],[
4266 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
4267
4268 AC_CHECK_PROGS(CTAGS, exctags ctags)
4269 AC_CHECK_PROGS(ETAGS, exetags etags)
4270
4271 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
4272
4273 if test "$cf_cv_mixedcase" = yes ; then
4274         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
4275 else
4276         MAKE_UPPER_TAGS=no
4277 fi
4278
4279 if test "$MAKE_UPPER_TAGS" = yes ; then
4280         MAKE_UPPER_TAGS=
4281 else
4282         MAKE_UPPER_TAGS="#"
4283 fi
4284
4285 if test "$MAKE_LOWER_TAGS" = yes ; then
4286         MAKE_LOWER_TAGS=
4287 else
4288         MAKE_LOWER_TAGS="#"
4289 fi
4290
4291 AC_SUBST(CTAGS)
4292 AC_SUBST(ETAGS)
4293
4294 AC_SUBST(MAKE_UPPER_TAGS)
4295 AC_SUBST(MAKE_LOWER_TAGS)
4296 ])dnl
4297 dnl ---------------------------------------------------------------------------
4298 dnl CF_MANPAGE_FORMAT version: 11 updated: 2015/04/18 08:56:57
4299 dnl -----------------
4300 dnl Option to allow user to override automatic configuration of manpage format.
4301 dnl There are several special cases:
4302 dnl
4303 dnl     gzip - man checks for, can display gzip'd files
4304 dnl     compress - man checks for, can display compressed files
4305 dnl     BSDI - files in the cat-directories are suffixed ".0"
4306 dnl     formatted - installer should format (put files in cat-directory)
4307 dnl     catonly - installer should only format, e.g., for a turnkey system.
4308 dnl
4309 dnl There are other configurations which this macro does not test, e.g., HPUX's
4310 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
4311 dnl convention would not match our use).
4312 AC_DEFUN([CF_MANPAGE_FORMAT],
4313 [
4314 AC_REQUIRE([CF_PATHSEP])
4315 AC_MSG_CHECKING(format of man-pages)
4316
4317 AC_ARG_WITH(manpage-format,
4318         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
4319                           optionally formatted/catonly, e.g., gzip,formatted],
4320         [MANPAGE_FORMAT=$withval],
4321         [MANPAGE_FORMAT=unknown])
4322
4323 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
4324 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
4325
4326 cf_unknown=
4327
4328 case $MANPAGE_FORMAT in
4329 (unknown)
4330         if test -z "$MANPATH" ; then
4331                 MANPATH="/usr/man:/usr/share/man"
4332         fi
4333
4334         # look for the 'date' man-page (it's most likely to be installed!)
4335         MANPAGE_FORMAT=
4336         cf_preform=no
4337         cf_catonly=yes
4338         cf_example=date
4339
4340         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
4341         for cf_dir in $MANPATH; do
4342                 test -z "$cf_dir" && cf_dir=/usr/man
4343                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
4344                 do
4345                         cf_test=`echo $cf_name | sed -e 's/*//'`
4346                         if test "x$cf_test" = "x$cf_name" ; then
4347
4348                                 case "$cf_name" in
4349                                 (*.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
4350                                 (*.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
4351                                 (*.0)  MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
4352                                 (*)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
4353                                 esac
4354
4355                                 case "$cf_name" in
4356                                 ($cf_dir/man*)
4357                                         cf_catonly=no
4358                                         ;;
4359                                 ($cf_dir/cat*)
4360                                         cf_preform=yes
4361                                         ;;
4362                                 esac
4363                                 break
4364                         fi
4365
4366                         # if we found a match in either man* or cat*, stop looking
4367                         if test -n "$MANPAGE_FORMAT" ; then
4368                                 cf_found=no
4369                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
4370                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
4371                                 case "$cf_name" in
4372                                 ($cf_dir/cat*)
4373                                         cf_found=yes
4374                                         ;;
4375                                 esac
4376                                 test $cf_found=yes && break
4377                         fi
4378                 done
4379                 # only check the first directory in $MANPATH where we find manpages
4380                 if test -n "$MANPAGE_FORMAT" ; then
4381                         break
4382                 fi
4383         done
4384         # if we did not find the example, just assume it is normal
4385         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4386         IFS="$ac_save_ifs"
4387         ;;
4388 (*)
4389         for cf_option in $MANPAGE_FORMAT; do
4390         case $cf_option in
4391         (gzip|compress|BSDI|normal|formatted|catonly)
4392                 ;;
4393         (*)
4394                 cf_unknown="$cf_unknown $cf_option"
4395                 ;;
4396         esac
4397         done
4398         ;;
4399 esac
4400
4401 AC_MSG_RESULT($MANPAGE_FORMAT)
4402 if test -n "$cf_unknown" ; then
4403         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4404 fi
4405 ])dnl
4406 dnl ---------------------------------------------------------------------------
4407 dnl CF_MANPAGE_RENAMES version: 10 updated: 2015/08/05 20:44:28
4408 dnl ------------------
4409 dnl The Debian people have their own naming convention for manpages.  This
4410 dnl option lets us override the name of the file containing renaming, or
4411 dnl disable it altogether.
4412 AC_DEFUN([CF_MANPAGE_RENAMES],
4413 [
4414 AC_MSG_CHECKING(for manpage renaming)
4415
4416 AC_ARG_WITH(manpage-renames,
4417         [  --with-manpage-renames  specify manpage-renaming],
4418         [MANPAGE_RENAMES=$withval],
4419         [MANPAGE_RENAMES=yes])
4420
4421 case ".$MANPAGE_RENAMES" in
4422 (.no)
4423         ;;
4424 (.|.yes)
4425         # Debian 'man' program?
4426         if test -f /etc/debian_version ; then
4427                 MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4428         else
4429                 MANPAGE_RENAMES=no
4430         fi
4431         ;;
4432 esac
4433
4434 if test "$MANPAGE_RENAMES" != no ; then
4435         if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4436                 MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4437         elif test ! -f $MANPAGE_RENAMES ; then
4438                 AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4439         fi
4440
4441         test ! -d man && mkdir man
4442
4443         # Construct a sed-script to perform renaming within man-pages
4444         if test -n "$MANPAGE_RENAMES" ; then
4445                 test ! -d man && mkdir man
4446                 $SHELL $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4447         fi
4448 fi
4449
4450 AC_MSG_RESULT($MANPAGE_RENAMES)
4451 AC_SUBST(MANPAGE_RENAMES)
4452 ])dnl
4453 dnl ---------------------------------------------------------------------------
4454 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
4455 dnl -------------------
4456 dnl Some people expect each tool to make all aliases for manpages in the
4457 dnl man-directory.  This accommodates the older, less-capable implementations
4458 dnl of 'man', and is optional.
4459 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4460 [
4461 AC_MSG_CHECKING(if manpage aliases will be installed)
4462
4463 AC_ARG_WITH(manpage-aliases,
4464         [  --with-manpage-aliases  specify manpage-aliases using .so],
4465         [MANPAGE_ALIASES=$withval],
4466         [MANPAGE_ALIASES=yes])
4467
4468 AC_MSG_RESULT($MANPAGE_ALIASES)
4469
4470 case "x$LN_S" in
4471 (xln*)
4472         cf_use_symlinks=yes
4473         ;;
4474 (*)
4475         cf_use_symlinks=no
4476         ;;
4477 esac
4478
4479 MANPAGE_SYMLINKS=no
4480 if test "$MANPAGE_ALIASES" = yes ; then
4481 AC_MSG_CHECKING(if manpage symlinks should be used)
4482
4483 AC_ARG_WITH(manpage-symlinks,
4484         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4485         [MANPAGE_SYMLINKS=$withval],
4486         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4487
4488 if test "$$cf_use_symlinks" = no; then
4489 if test "$MANPAGE_SYMLINKS" = yes ; then
4490         AC_MSG_WARN(cannot make symlinks, will use .so files)
4491         MANPAGE_SYMLINKS=no
4492 fi
4493 fi
4494
4495 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4496 fi
4497
4498 ])dnl
4499 dnl ---------------------------------------------------------------------------
4500 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4501 dnl --------------
4502 dnl This option causes manpages to be run through tbl(1) to generate tables
4503 dnl correctly.
4504 AC_DEFUN([CF_MANPAGE_TBL],
4505 [
4506 AC_MSG_CHECKING(for manpage tbl)
4507
4508 AC_ARG_WITH(manpage-tbl,
4509         [  --with-manpage-tbl      specify manpage processing with tbl],
4510         [MANPAGE_TBL=$withval],
4511         [MANPAGE_TBL=no])
4512
4513 AC_MSG_RESULT($MANPAGE_TBL)
4514 ])dnl
4515 dnl ---------------------------------------------------------------------------
4516 dnl CF_MAN_PAGES version: 46 updated: 2015/08/05 20:44:28
4517 dnl ------------
4518 dnl Try to determine if the man-pages on the system are compressed, and if
4519 dnl so, what format is used.  Use this information to construct a script that
4520 dnl will install man-pages.
4521 AC_DEFUN([CF_MAN_PAGES],
4522 [
4523 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4524 CF_MANPAGE_FORMAT
4525 CF_MANPAGE_RENAMES
4526 CF_MANPAGE_SYMLINKS
4527 CF_MANPAGE_TBL
4528
4529 if test "$prefix" = "NONE" ; then
4530         cf_prefix="$ac_default_prefix"
4531 else
4532         cf_prefix="$prefix"
4533 fi
4534
4535 case "$MANPAGE_FORMAT" in
4536 (*catonly*)
4537         cf_format=yes
4538         cf_inboth=no
4539         ;;
4540 (*formatted*)
4541         cf_format=yes
4542         cf_inboth=yes
4543         ;;
4544 (*)
4545         cf_format=no
4546         cf_inboth=no
4547         ;;
4548 esac
4549
4550 test ! -d man && mkdir man
4551
4552 cf_so_strip=
4553 cf_compress=
4554 case "$MANPAGE_FORMAT" in
4555 (*compress*)
4556         cf_so_strip="Z"
4557         cf_compress=compress
4558         ;;
4559 (*gzip*)
4560         cf_so_strip="gz"
4561         cf_compress=gzip
4562         ;;
4563 esac
4564
4565 cf_edit_man=./edit_man.sh
4566 cf_man_alias=`pwd`/man_alias.sed
4567
4568 cat >$cf_edit_man <<CF_EOF
4569 #! $SHELL
4570 # this script is generated by the configure-script CF_MAN_PAGES macro.
4571
4572 prefix="$cf_prefix"
4573 datarootdir="$datarootdir"
4574 datadir="$datadir"
4575
4576 NCURSES_MAJOR="$NCURSES_MAJOR"
4577 NCURSES_MINOR="$NCURSES_MINOR"
4578 NCURSES_PATCH="$NCURSES_PATCH"
4579
4580 NCURSES_OSPEED="$NCURSES_OSPEED"
4581 TERMINFO="$TERMINFO"
4582
4583 INSTALL="$INSTALL"
4584 INSTALL_DATA="$INSTALL_DATA"
4585
4586 transform="$program_transform_name"
4587
4588 TMP=\${TMPDIR:=/tmp}/man\$\$
4589 trap "rm -f \$TMP" 0 1 2 5 15
4590
4591 form=\[$]1
4592 shift || exit 1
4593
4594 verb=\[$]1
4595 shift || exit 1
4596
4597 mandir=\[$]1
4598 shift || exit 1
4599
4600 srcdir=\[$]1
4601 top_srcdir=\[$]srcdir/..
4602 shift || exit 1
4603
4604 if test "\$form" = normal ; then
4605         if test "$cf_format" = yes ; then
4606         if test "$cf_inboth" = no ; then
4607                 $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
4608                 exit $?
4609         fi
4610         fi
4611         cf_subdir=\$mandir/man
4612         cf_tables=$MANPAGE_TBL
4613 else
4614         cf_subdir=\$mandir/cat
4615         cf_tables=yes
4616 fi
4617
4618 # process the list of source-files
4619 for i in \[$]* ; do
4620 case \$i in
4621 (*.orig|*.rej) ;;
4622 (*.[[0-9]]*)
4623         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4624         if test \$verb = installing ; then
4625         if test ! -d \$cf_subdir\${section} ; then
4626                 mkdir -p \$cf_subdir\$section
4627         fi
4628         fi
4629
4630         # replace variables in man page
4631         if test ! -f $cf_man_alias ; then
4632 cat >>$cf_man_alias <<-CF_EOF2
4633                 s,@DATADIR@,\$datadir,g
4634                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
4635                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
4636                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
4637                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
4638                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
4639                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
4640 CF_EOF
4641         ifelse($1,,,[
4642         for cf_name in $1
4643         do
4644                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4645                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4646 cat >>$cf_edit_man <<-CF_EOF
4647                 s,@$cf_NAME@,$cf_name,g
4648 CF_EOF
4649         done
4650         ])
4651 cat >>$cf_edit_man <<CF_EOF
4652 CF_EOF2
4653                 echo "...made $cf_man_alias"
4654         fi
4655
4656         aliases=
4657         cf_source=\`basename \$i\`
4658         inalias=\$cf_source
4659         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4660         if test ! -f \$inalias ; then
4661                 echo .. skipped \$cf_source
4662                 continue
4663         fi
4664 CF_EOF
4665
4666 if test "$MANPAGE_ALIASES" != no ; then
4667 cat >>$cf_edit_man <<CF_EOF
4668         nCurses=ignore.3x
4669         test $with_curses_h = yes && nCurses=ncurses.3x
4670         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4671 CF_EOF
4672 fi
4673
4674 if test "$MANPAGE_RENAMES" = no ; then
4675 cat >>$cf_edit_man <<CF_EOF
4676         # perform program transformations for section 1 man pages
4677         if test \$section = 1 ; then
4678                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4679         else
4680                 cf_target=\$cf_subdir\${section}/\$cf_source
4681         fi
4682 CF_EOF
4683 else
4684 cat >>$cf_edit_man <<CF_EOF
4685         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4686         if test -z "\$cf_target" ; then
4687                 echo '? missing rename for '\$cf_source
4688                 cf_target="\$cf_source"
4689         fi
4690         cf_target="\$cf_subdir\${section}/\${cf_target}"
4691
4692 CF_EOF
4693 fi
4694
4695 cat >>$cf_edit_man <<CF_EOF
4696         sed     -f $cf_man_alias \\
4697 CF_EOF
4698
4699 if test -f $MANPAGE_RENAMES ; then
4700 cat >>$cf_edit_man <<CF_EOF
4701                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4702 CF_EOF
4703 else
4704 cat >>$cf_edit_man <<CF_EOF
4705                 < \$i >\$TMP
4706 CF_EOF
4707 fi
4708
4709 cat >>$cf_edit_man <<CF_EOF
4710 if test \$cf_tables = yes ; then
4711         tbl \$TMP >\$TMP.out
4712         mv \$TMP.out \$TMP
4713 fi
4714 CF_EOF
4715
4716 if test $with_overwrite != yes ; then
4717 cat >>$cf_edit_man <<CF_EOF
4718         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4719         mv \$TMP.out \$TMP
4720 CF_EOF
4721 fi
4722
4723 if test $with_curses_h != yes ; then
4724 cat >>$cf_edit_man <<CF_EOF
4725         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4726         mv \$TMP.out \$TMP
4727 CF_EOF
4728 fi
4729
4730 cat >>$cf_edit_man <<CF_EOF
4731         if test \$form = format ; then
4732                 nroff -man \$TMP >\$TMP.out
4733                 mv \$TMP.out \$TMP
4734         fi
4735 CF_EOF
4736
4737 if test -n "$cf_compress" ; then
4738 cat >>$cf_edit_man <<CF_EOF
4739         if test \$verb = installing ; then
4740         if ( $cf_compress -f \$TMP )
4741         then
4742                 mv \$TMP.$cf_so_strip \$TMP
4743         fi
4744         fi
4745         cf_target="\$cf_target.$cf_so_strip"
4746 CF_EOF
4747 fi
4748
4749 case "$MANPAGE_FORMAT" in
4750 (*BSDI*)
4751 cat >>$cf_edit_man <<CF_EOF
4752         if test \$form = format ; then
4753                 # BSDI installs only .0 suffixes in the cat directories
4754                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4755         fi
4756 CF_EOF
4757   ;;
4758 esac
4759
4760 cat >>$cf_edit_man <<CF_EOF
4761         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4762         if test \$verb = installing ; then
4763                 echo \$verb \$cf_target
4764                 \$INSTALL_DATA \$TMP \$cf_target
4765                 test -d \$cf_subdir\${section} &&
4766                 test -n "\$aliases" && (
4767                         cd \$cf_subdir\${section} && (
4768                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4769                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4770                                 cf_target=\`basename \$cf_target\`
4771                                 for cf_alias in \$aliases
4772                                 do
4773                                         if test \$section = 1 ; then
4774                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4775                                         fi
4776
4777                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4778                                                 if test -f \$cf_alias\${suffix} ; then
4779                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4780                                                         then
4781                                                                 continue
4782                                                         fi
4783                                                 fi
4784                                                 echo .. \$verb alias \$cf_alias\${suffix}
4785 CF_EOF
4786 case "x$LN_S" in
4787 (*-f)
4788 cat >>$cf_edit_man <<CF_EOF
4789                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4790 CF_EOF
4791         ;;
4792 (*)
4793 cat >>$cf_edit_man <<CF_EOF
4794                                                 rm -f \$cf_alias\${suffix}
4795                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4796 CF_EOF
4797         ;;
4798 esac
4799 cat >>$cf_edit_man <<CF_EOF
4800                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4801                                                 echo ".so \$cf_source" >\$TMP
4802 CF_EOF
4803 if test -n "$cf_compress" ; then
4804 cat >>$cf_edit_man <<CF_EOF
4805                                                 if test -n "$cf_so_strip" ; then
4806                                                         $cf_compress -f \$TMP
4807                                                         mv \$TMP.$cf_so_strip \$TMP
4808                                                 fi
4809 CF_EOF
4810 fi
4811 cat >>$cf_edit_man <<CF_EOF
4812                                                 echo .. \$verb alias \$cf_alias\${suffix}
4813                                                 rm -f \$cf_alias\${suffix}
4814                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4815                                         fi
4816                                 done
4817                         )
4818                 )
4819         elif test \$verb = removing ; then
4820                 test -f \$cf_target && (
4821                         echo \$verb \$cf_target
4822                         rm -f \$cf_target
4823                 )
4824                 test -d \$cf_subdir\${section} &&
4825                 test -n "\$aliases" && (
4826                         cd \$cf_subdir\${section} && (
4827                                 for cf_alias in \$aliases
4828                                 do
4829                                         if test \$section = 1 ; then
4830                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4831                                         fi
4832
4833                                         echo .. \$verb alias \$cf_alias\${suffix}
4834                                         rm -f \$cf_alias\${suffix}
4835                                 done
4836                         )
4837                 )
4838         else
4839 #               echo ".hy 0"
4840                 cat \$TMP
4841         fi
4842         ;;
4843 esac
4844 done
4845
4846 if test $cf_inboth = yes ; then
4847 if test \$form != format ; then
4848         $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
4849 fi
4850 fi
4851
4852 exit 0
4853 CF_EOF
4854 chmod 755 $cf_edit_man
4855
4856 ])dnl
4857 dnl ---------------------------------------------------------------------------
4858 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4859 dnl -----------
4860 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4861 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4862 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4863 AC_DEFUN([CF_MATH_LIB],
4864 [
4865 AC_CACHE_CHECK(if -lm needed for math functions,
4866         cf_cv_need_libm,[
4867         AC_TRY_LINK([
4868         #include <stdio.h>
4869         #include <math.h>
4870         ],
4871         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4872         [cf_cv_need_libm=no],
4873         [cf_cv_need_libm=yes])])
4874 if test "$cf_cv_need_libm" = yes
4875 then
4876 ifelse($1,,[
4877         CF_ADD_LIB(m)
4878 ],[$1=-lm])
4879 fi
4880 ])
4881 dnl ---------------------------------------------------------------------------
4882 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
4883 dnl ----------------------
4884 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4885 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4886 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4887 [
4888 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4889 if test "$cross_compiling" = yes ; then
4890         case $target_alias in
4891         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
4892                 cf_cv_mixedcase=no
4893                 ;;
4894         (*)
4895                 cf_cv_mixedcase=yes
4896                 ;;
4897         esac
4898 else
4899         rm -f conftest CONFTEST
4900         echo test >conftest
4901         if test -f CONFTEST ; then
4902                 cf_cv_mixedcase=no
4903         else
4904                 cf_cv_mixedcase=yes
4905         fi
4906         rm -f conftest CONFTEST
4907 fi
4908 ])
4909 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
4910 ])dnl
4911 dnl ---------------------------------------------------------------------------
4912 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
4913 dnl ----------
4914 dnl Check for a working mkstemp.  This creates two files, checks that they are
4915 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4916 AC_DEFUN([CF_MKSTEMP],[
4917 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4918 rm -rf conftest*
4919 AC_TRY_RUN([
4920 #include <sys/types.h>
4921 #include <stdlib.h>
4922 #include <stdio.h>
4923 #include <string.h>
4924 #include <sys/stat.h>
4925 int main()
4926 {
4927         char *tmpl = "conftestXXXXXX";
4928         char name[2][80];
4929         int n;
4930         int result = 0;
4931         int fd;
4932         struct stat sb;
4933
4934         umask(077);
4935         for (n = 0; n < 2; ++n) {
4936                 strcpy(name[n], tmpl);
4937                 if ((fd = mkstemp(name[n])) >= 0) {
4938                         if (!strcmp(name[n], tmpl)
4939                          || stat(name[n], &sb) != 0
4940                          || (sb.st_mode & S_IFMT) != S_IFREG
4941                          || (sb.st_mode & 077) != 0) {
4942                                 result = 1;
4943                         }
4944                         close(fd);
4945                 }
4946         }
4947         if (result == 0
4948          && !strcmp(name[0], name[1]))
4949                 result = 1;
4950         ${cf_cv_main_return:-return}(result);
4951 }
4952 ],[cf_cv_func_mkstemp=yes
4953 ],[cf_cv_func_mkstemp=no
4954 ],[cf_cv_func_mkstemp=maybe])
4955 ])
4956 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
4957         AC_CHECK_FUNC(mkstemp)
4958 fi
4959 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4960         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
4961 fi
4962 ])dnl
4963 dnl ---------------------------------------------------------------------------
4964 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4965 dnl ----------
4966 dnl Write a debug message to config.log, along with the line number in the
4967 dnl configure script.
4968 AC_DEFUN([CF_MSG_LOG],[
4969 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
4970 ])dnl
4971 dnl ---------------------------------------------------------------------------
4972 dnl CF_NCURSES_ABI_6 version: 3 updated: 2015/06/06 16:10:11
4973 dnl ----------------
4974 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
4975 dnl warn about this.
4976 AC_DEFUN([CF_NCURSES_ABI_6],[
4977 if test "${with_abi_version+set}" != set; then
4978         case $cf_cv_rel_version in
4979         (5.*)
4980                 cf_cv_rel_version=6.0
4981                 cf_cv_abi_version=6
4982                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_version)
4983                 ;;
4984         esac
4985 fi
4986 ])dnl
4987 dnl ---------------------------------------------------------------------------
4988 dnl CF_NCURSES_WITH_ABI_VERSION version: 2 updated: 2015/12/19 17:51:52
4989 dnl ---------------------------
4990 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
4991 dnl packager has incremented the ABI past that used in the original package,
4992 dnl and wishes to keep doing this.
4993 dnl
4994 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
4995 dnl symbol.
4996 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
4997 CF_WITH_ABI_VERSION($1)
4998 if test "x$cf_cv_abi_version" != "x$with_abi_version"
4999 then
5000         case $cf_cv_rel_version in
5001         (5.*)
5002                 cf_cv_rel_version=$with_abi_version.0
5003                 ;;
5004         esac
5005 fi
5006 ])dnl
5007 dnl ---------------------------------------------------------------------------
5008 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
5009 dnl ------------------
5010 dnl see CF_WITH_NO_LEAKS
5011 AC_DEFUN([CF_NO_LEAKS_OPTION],[
5012 AC_MSG_CHECKING(if you want to use $1 for testing)
5013 AC_ARG_WITH($1,
5014         [$2],
5015         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
5016          $4
5017 ])
5018         : ${with_cflags:=-g}
5019         : ${with_no_leaks:=yes}
5020          with_$1=yes],
5021         [with_$1=])
5022 AC_MSG_RESULT(${with_$1:-no})
5023
5024 case .$with_cflags in
5025 (.*-g*)
5026         case .$CFLAGS in
5027         (.*-g*)
5028                 ;;
5029         (*)
5030                 CF_ADD_CFLAGS([-g])
5031                 ;;
5032         esac
5033         ;;
5034 esac
5035 ])dnl
5036 dnl ---------------------------------------------------------------------------
5037 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
5038 dnl ----------------
5039 dnl Check if the given variable is a number.  If not, report an error.
5040 dnl $1 is the variable
5041 dnl $2 is the message
5042 AC_DEFUN([CF_NUMBER_SYNTAX],[
5043 if test -n "$1" ; then
5044   case $1 in
5045   ([[0-9]]*)
5046         ;;
5047   (*)
5048         AC_MSG_ERROR($2 is not a number: $1)
5049         ;;
5050   esac
5051 else
5052   AC_MSG_ERROR($2 value is empty)
5053 fi
5054 ])dnl
5055 dnl ---------------------------------------------------------------------------
5056 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
5057 dnl -------------
5058 dnl Compute the object-directory name from the given model name
5059 AC_DEFUN([CF_OBJ_SUBDIR],
5060 [
5061         case $1 in
5062         (libtool) $2='obj_lo'  ;;
5063         (normal)  $2='objects' ;;
5064         (debug)   $2='obj_g' ;;
5065         (profile) $2='obj_p' ;;
5066         (shared)
5067                 case $cf_cv_system_name in
5068                 (cygwin|msys)
5069                         $2='objects' ;;
5070                 (*)
5071                         $2='obj_s' ;;
5072                 esac
5073         esac
5074 ])dnl
5075 dnl ---------------------------------------------------------------------------
5076 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
5077 dnl ----------
5078 dnl Provide a value for the $PATH and similar separator (or amend the value
5079 dnl as provided in autoconf 2.5x).
5080 AC_DEFUN([CF_PATHSEP],
5081 [
5082         AC_MSG_CHECKING(for PATH separator)
5083         case $cf_cv_system_name in
5084         (os2*)  PATH_SEPARATOR=';'  ;;
5085         (*)     ${PATH_SEPARATOR:=':'}  ;;
5086         esac
5087 ifelse([$1],,,[$1=$PATH_SEPARATOR])
5088         AC_SUBST(PATH_SEPARATOR)
5089         AC_MSG_RESULT($PATH_SEPARATOR)
5090 ])dnl
5091 dnl ---------------------------------------------------------------------------
5092 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
5093 dnl --------------
5094 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
5095 dnl begins with one of the prefix/exec_prefix variables, and then again if the
5096 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
5097 dnl delayed evaluation of those symbols.
5098 AC_DEFUN([CF_PATH_SYNTAX],[
5099 if test "x$prefix" != xNONE; then
5100         cf_path_syntax="$prefix"
5101 else
5102         cf_path_syntax="$ac_default_prefix"
5103 fi
5104
5105 case ".[$]$1" in
5106 (.\[$]\(*\)*|.\'*\'*)
5107         ;;
5108 (..|./*|.\\*)
5109         ;;
5110 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
5111         ;;
5112 (.\[$]{*prefix}*|.\[$]{*dir}*)
5113         eval $1="[$]$1"
5114         case ".[$]$1" in
5115         (.NONE/*)
5116                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5117                 ;;
5118         esac
5119         ;;
5120 (.no|.NONE/*)
5121         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5122         ;;
5123 (*)
5124         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
5125         ;;
5126 esac
5127 ])dnl
5128 dnl ---------------------------------------------------------------------------
5129 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
5130 dnl -------------
5131 dnl Check for the package-config program, unless disabled by command-line.
5132 AC_DEFUN([CF_PKG_CONFIG],
5133 [
5134 AC_MSG_CHECKING(if you want to use pkg-config)
5135 AC_ARG_WITH(pkg-config,
5136         [  --with-pkg-config{=path} enable/disable use of pkg-config],
5137         [cf_pkg_config=$withval],
5138         [cf_pkg_config=yes])
5139 AC_MSG_RESULT($cf_pkg_config)
5140
5141 case $cf_pkg_config in
5142 (no)
5143         PKG_CONFIG=none
5144         ;;
5145 (yes)
5146         CF_ACVERSION_CHECK(2.52,
5147                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
5148                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
5149         ;;
5150 (*)
5151         PKG_CONFIG=$withval
5152         ;;
5153 esac
5154
5155 test -z "$PKG_CONFIG" && PKG_CONFIG=none
5156 if test "$PKG_CONFIG" != none ; then
5157         CF_PATH_SYNTAX(PKG_CONFIG)
5158 elif test "x$cf_pkg_config" != xno ; then
5159         AC_MSG_WARN(pkg-config is not installed)
5160 fi
5161
5162 AC_SUBST(PKG_CONFIG)
5163 ])dnl
5164 dnl ---------------------------------------------------------------------------
5165 dnl CF_POSIX_C_SOURCE version: 9 updated: 2015/04/12 15:39:00
5166 dnl -----------------
5167 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
5168 dnl
5169 dnl     POSIX.1-1990                            _POSIX_SOURCE
5170 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
5171 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
5172 dnl             Bindings Option
5173 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
5174 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
5175 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
5176 dnl
5177 dnl Parameters:
5178 dnl     $1 is the nominal value for _POSIX_C_SOURCE
5179 AC_DEFUN([CF_POSIX_C_SOURCE],
5180 [
5181 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
5182
5183 cf_save_CFLAGS="$CFLAGS"
5184 cf_save_CPPFLAGS="$CPPFLAGS"
5185
5186 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
5187 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
5188
5189 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
5190         CF_MSG_LOG(if the symbol is already defined go no further)
5191         AC_TRY_COMPILE([#include <sys/types.h>],[
5192 #ifndef _POSIX_C_SOURCE
5193 make an error
5194 #endif],
5195         [cf_cv_posix_c_source=no],
5196         [cf_want_posix_source=no
5197          case .$cf_POSIX_C_SOURCE in
5198          (.[[12]]??*)
5199                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5200                 ;;
5201          (.2)
5202                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5203                 cf_want_posix_source=yes
5204                 ;;
5205          (.*)
5206                 cf_want_posix_source=yes
5207                 ;;
5208          esac
5209          if test "$cf_want_posix_source" = yes ; then
5210                 AC_TRY_COMPILE([#include <sys/types.h>],[
5211 #ifdef _POSIX_SOURCE
5212 make an error
5213 #endif],[],
5214                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
5215          fi
5216          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
5217          CFLAGS="$cf_trim_CFLAGS"
5218          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
5219          CF_MSG_LOG(if the second compile does not leave our definition intact error)
5220          AC_TRY_COMPILE([#include <sys/types.h>],[
5221 #ifndef _POSIX_C_SOURCE
5222 make an error
5223 #endif],,
5224          [cf_cv_posix_c_source=no])
5225          CFLAGS="$cf_save_CFLAGS"
5226          CPPFLAGS="$cf_save_CPPFLAGS"
5227         ])
5228 ])
5229
5230 if test "$cf_cv_posix_c_source" != no ; then
5231         CFLAGS="$cf_trim_CFLAGS"
5232         CPPFLAGS="$cf_trim_CPPFLAGS"
5233         CF_ADD_CFLAGS($cf_cv_posix_c_source)
5234 fi
5235
5236 ])dnl
5237 dnl ---------------------------------------------------------------------------
5238 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
5239 dnl ------------
5240 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
5241 dnl
5242 dnl $1 = symbol to test
5243 dnl $2 = value (if any) to use for a predefinition
5244 AC_DEFUN([CF_PREDEFINE],
5245 [
5246 AC_MSG_CHECKING(if we must define $1)
5247 AC_TRY_COMPILE([#include <sys/types.h>
5248 ],[
5249 #ifndef $1
5250 make an error
5251 #endif],[cf_result=no],[cf_result=yes])
5252 AC_MSG_RESULT($cf_result)
5253
5254 if test "$cf_result" = yes ; then
5255         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
5256 elif test "x$2" != "x" ; then
5257         AC_MSG_CHECKING(checking for compatible value versus $2)
5258         AC_TRY_COMPILE([#include <sys/types.h>
5259 ],[
5260 #if $1-$2 < 0
5261 make an error
5262 #endif],[cf_result=yes],[cf_result=no])
5263         AC_MSG_RESULT($cf_result)
5264         if test "$cf_result" = no ; then
5265                 # perhaps we can override it - try...
5266                 CPPFLAGS="$CPPFLAGS -D$1=$2"
5267         fi
5268 fi
5269 ])dnl
5270 dnl ---------------------------------------------------------------------------
5271 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
5272 dnl ------------
5273 dnl Append definitions and rules for the given programs to the subdirectory
5274 dnl Makefiles, and the recursion rule for the top-level Makefile.
5275 dnl
5276 dnl parameters
5277 dnl     $1 = script to run
5278 dnl     $2 = list of subdirectories
5279 dnl
5280 dnl variables
5281 dnl     $AWK
5282 AC_DEFUN([CF_PRG_RULES],
5283 [
5284 for cf_dir in $2
5285 do
5286         if test ! -d $srcdir/$cf_dir; then
5287                 continue
5288         elif test -f $srcdir/$cf_dir/programs; then
5289                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
5290         fi
5291 done
5292
5293 ])dnl
5294 dnl ---------------------------------------------------------------------------
5295 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
5296 dnl ----------
5297 dnl Check for archiver "ar".
5298 AC_DEFUN([CF_PROG_AR],[
5299 AC_CHECK_TOOL(AR, ar, ar)
5300 ])
5301 dnl ---------------------------------------------------------------------------
5302 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
5303 dnl -----------
5304 dnl Check for awk, ensure that the check found something.
5305 AC_DEFUN([CF_PROG_AWK],
5306 [
5307 AC_PROG_AWK
5308 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
5309 ])dnl
5310 dnl ---------------------------------------------------------------------------
5311 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
5312 dnl ----------
5313 dnl standard check for CC, plus followup sanity checks
5314 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
5315 AC_DEFUN([CF_PROG_CC],[
5316 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
5317 CF_GCC_VERSION
5318 CF_ACVERSION_CHECK(2.52,
5319         [AC_PROG_CC_STDC],
5320         [CF_ANSI_CC_REQD])
5321 CF_CC_ENV_FLAGS
5322 ])dnl
5323 dnl ---------------------------------------------------------------------------
5324 dnl CF_PROG_CC_C_O version: 4 updated: 2016/05/21 18:08:09
5325 dnl --------------
5326 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
5327 dnl the output file can be renamed, and allows for a shell variable that can
5328 dnl be used later.  The parameter is either CC or CXX.  The result is the
5329 dnl cache variable:
5330 dnl     $cf_cv_prog_CC_c_o
5331 dnl     $cf_cv_prog_CXX_c_o
5332 dnl
5333 dnl $1 = compiler
5334 dnl $2 = compiler options, if any
5335 AC_DEFUN([CF_PROG_CC_C_O],
5336 [AC_REQUIRE([AC_PROG_CC])dnl
5337 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
5338 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
5339 [
5340 cat > conftest.$ac_ext <<CF_EOF
5341 int main()
5342 {
5343         ${cf_cv_main_return:-return}(0);
5344 }
5345 CF_EOF
5346 # We do the test twice because some compilers refuse to overwrite an
5347 # existing .o file with -o, though they will create one.
5348 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
5349 if AC_TRY_EVAL(ac_try) &&
5350   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
5351 then
5352   eval cf_cv_prog_$1_c_o=yes
5353 else
5354   eval cf_cv_prog_$1_c_o=no
5355 fi
5356 rm -rf conftest*
5357 ])dnl
5358 if test $cf_cv_prog_$1_c_o = yes; then
5359   AC_MSG_RESULT([yes])
5360 else
5361   AC_MSG_RESULT([no])
5362 fi
5363 ])dnl
5364 dnl ---------------------------------------------------------------------------
5365 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
5366 dnl -------------
5367 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
5368 dnl This macro adds a check to ensure the script found something.
5369 AC_DEFUN([CF_PROG_EGREP],
5370 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
5371         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
5372                 then ac_cv_prog_egrep='grep -E'
5373                 else ac_cv_prog_egrep='egrep'
5374         fi])
5375         EGREP=$ac_cv_prog_egrep
5376         AC_SUBST([EGREP])
5377         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
5378 ])dnl
5379 dnl ---------------------------------------------------------------------------
5380 dnl CF_PROG_GNAT version: 3 updated: 2015/04/18 08:56:57
5381 dnl ------------
5382 dnl Check for gnatmake, ensure that it is complete.
5383 AC_DEFUN([CF_PROG_GNAT],[
5384 cf_ada_make=gnatmake
5385 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
5386 if test "$ac_cv_prog_gnat_exists" = no; then
5387         cf_ada_make=
5388         cf_cv_prog_gnat_correct=no
5389 else
5390         CF_GNAT_VERSION
5391         AC_CHECK_PROG(M4_exists, m4, yes, no)
5392         if test "$ac_cv_prog_M4_exists" = no; then
5393                 cf_cv_prog_gnat_correct=no
5394                 echo Ada95 binding required program m4 not found. Ada95 binding disabled.
5395         fi
5396         if test "$cf_cv_prog_gnat_correct" = yes; then
5397                 AC_MSG_CHECKING(if GNAT works)
5398                 CF_GNAT_TRY_RUN([procedure conftest;],
5399 [with Text_IO;
5400 with GNAT.OS_Lib;
5401 procedure conftest is
5402 begin
5403    Text_IO.Put ("Hello World");
5404    Text_IO.New_Line;
5405    GNAT.OS_Lib.OS_Exit (0);
5406 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
5407                 AC_MSG_RESULT($cf_cv_prog_gnat_correct)
5408         fi
5409 fi
5410
5411 AC_SUBST(cf_ada_make)
5412 ])dnl
5413 dnl ---------------------------------------------------------------------------
5414 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
5415 dnl ---------------
5416 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
5417 dnl misc/tabset install won't work properly.  Usually this happens only when
5418 dnl using the fallback mkinstalldirs script
5419 AC_DEFUN([CF_PROG_INSTALL],
5420 [AC_PROG_INSTALL
5421 case $INSTALL in
5422 (/*)
5423         ;;
5424 (*)
5425         CF_DIRNAME(cf_dir,$INSTALL)
5426         test -z "$cf_dir" && cf_dir=.
5427         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
5428         ;;
5429 esac
5430 ])dnl
5431 dnl ---------------------------------------------------------------------------
5432 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
5433 dnl ----------------
5434 dnl Check for ldconfig, needed to fixup shared libraries that would be built
5435 dnl and then used in the install.
5436 AC_DEFUN([CF_PROG_LDCONFIG],[
5437 if test "$cross_compiling" = yes ; then
5438         LDCONFIG=:
5439 else
5440         case "$cf_cv_system_name" in
5441         (dragonfly*|mirbsd*|freebsd*)
5442                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
5443                 ;;
5444         (*) LDPATH=$PATH:/sbin:/usr/sbin
5445                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
5446                 ;;
5447         esac
5448 fi
5449 AC_SUBST(LDCONFIG)
5450 ])dnl
5451 dnl ---------------------------------------------------------------------------
5452 dnl CF_PROG_LINT version: 3 updated: 2016/05/22 15:25:54
5453 dnl ------------
5454 AC_DEFUN([CF_PROG_LINT],
5455 [
5456 AC_CHECK_PROGS(LINT, lint cppcheck splint)
5457 AC_SUBST(LINT_OPTS)
5458 ])dnl
5459 dnl ---------------------------------------------------------------------------
5460 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
5461 dnl ------------
5462 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
5463 dnl option if it is supported.
5464 AC_DEFUN([CF_PROG_LN_S],[
5465 AC_PROG_LN_S
5466 AC_MSG_CHECKING(if $LN_S -f options work)
5467
5468 rm -f conf$$.src conf$$dst
5469 echo >conf$$.dst
5470 echo first >conf$$.src
5471 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
5472         cf_prog_ln_sf=yes
5473 else
5474         cf_prog_ln_sf=no
5475 fi
5476 rm -f conf$$.dst conf$$src
5477 AC_MSG_RESULT($cf_prog_ln_sf)
5478
5479 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
5480 ])dnl
5481 dnl ---------------------------------------------------------------------------
5482 dnl CF_REGEX version: 12 updated: 2015/04/18 08:56:57
5483 dnl --------
5484 dnl Attempt to determine if we've got one of the flavors of regular-expression
5485 dnl code that we can support.
5486 AC_DEFUN([CF_REGEX],
5487 [
5488
5489 cf_regex_func=no
5490
5491 cf_regex_libs="regex re"
5492 case $host_os in
5493 (mingw*)
5494         cf_regex_libs="gnurx $cf_regex_libs"
5495         ;;
5496 esac
5497
5498 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5499         for cf_regex_lib in $cf_regex_libs
5500         do
5501                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5502                                 CF_ADD_LIB($cf_regex_lib)
5503                                 cf_regex_func=regcomp
5504                                 break])
5505         done
5506 ])
5507
5508 if test "$cf_regex_func" = no ; then
5509         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5510                 AC_CHECK_LIB(gen,compile,[
5511                                 CF_ADD_LIB(gen)
5512                                 cf_regex_func=compile])])
5513 fi
5514
5515 if test "$cf_regex_func" = no ; then
5516         AC_MSG_WARN(cannot find regular expression library)
5517 fi
5518
5519 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5520
5521 cf_cv_regex_hdrs=no
5522 case $cf_regex_func in
5523 (compile)
5524         for cf_regex_hdr in regexp.h regexpr.h
5525         do
5526                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5527                         char *p = compile("", "", "", 0);
5528                         int x = step("", "");
5529                 ],[
5530                         cf_cv_regex_hdrs=$cf_regex_hdr
5531                         break
5532                 ])
5533         done
5534         ;;
5535 (*)
5536         for cf_regex_hdr in regex.h
5537         do
5538                 AC_TRY_LINK([#include <sys/types.h>
5539 #include <$cf_regex_hdr>],[
5540                         regex_t *p;
5541                         int x = regcomp(p, "", 0);
5542                         int y = regexec(p, "", 0, 0, 0);
5543                         regfree(p);
5544                 ],[
5545                         cf_cv_regex_hdrs=$cf_regex_hdr
5546                         break
5547                 ])
5548         done
5549         ;;
5550 esac
5551
5552 ])
5553
5554 case $cf_cv_regex_hdrs in
5555         (no)            AC_MSG_WARN(no regular expression header found) ;;
5556         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
5557         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
5558         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
5559 esac
5560 ])dnl
5561 dnl ---------------------------------------------------------------------------
5562 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5563 dnl ----------------
5564 dnl Remove all -U and -D options that refer to the given symbol from a list
5565 dnl of C compiler options.  This works around the problem that not all
5566 dnl compilers process -U and -D options from left-to-right, so a -U option
5567 dnl cannot be used to cancel the effect of a preceding -D option.
5568 dnl
5569 dnl $1 = target (which could be the same as the source variable)
5570 dnl $2 = source (including '$')
5571 dnl $3 = symbol to remove
5572 define([CF_REMOVE_DEFINE],
5573 [
5574 $1=`echo "$2" | \
5575         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5576                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5577 ])dnl
5578 dnl ---------------------------------------------------------------------------
5579 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5580 dnl -------------
5581 dnl Remove the given library from the symbol
5582 dnl
5583 dnl $1 = target (which could be the same as the source variable)
5584 dnl $2 = source (including '$')
5585 dnl $3 = library to remove
5586 define([CF_REMOVE_LIB],
5587 [
5588 # remove $3 library from $2
5589 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5590 ])dnl
5591 dnl ---------------------------------------------------------------------------
5592 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
5593 dnl -------------
5594 AC_DEFUN([CF_RPATH_HACK],
5595 [
5596 AC_REQUIRE([CF_LD_RPATH_OPT])
5597 AC_MSG_CHECKING(for updated LDFLAGS)
5598 if test -n "$LD_RPATH_OPT" ; then
5599         AC_MSG_RESULT(maybe)
5600
5601         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5602         cf_rpath_list="/usr/lib /lib"
5603         if test "$cf_ldd_prog" != no
5604         then
5605                 cf_rpath_oops=
5606
5607 AC_TRY_LINK([#include <stdio.h>],
5608                 [printf("Hello");],
5609                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
5610                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
5611
5612                 # If we passed the link-test, but get a "not found" on a given library,
5613                 # this could be due to inept reconfiguration of gcc to make it only
5614                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5615                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5616                 # /usr/local libraries.
5617                 if test -n "$cf_rpath_oops"
5618                 then
5619                         for cf_rpath_src in $cf_rpath_oops
5620                         do
5621                                 for cf_rpath_dir in \
5622                                         /usr/local \
5623                                         /usr/pkg \
5624                                         /opt/sfw
5625                                 do
5626                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5627                                         then
5628                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5629                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5630                                                 break
5631                                         fi
5632                                 done
5633                         done
5634                 fi
5635         fi
5636
5637         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5638
5639         CF_RPATH_HACK_2(LDFLAGS)
5640         CF_RPATH_HACK_2(LIBS)
5641
5642         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5643 else
5644         AC_MSG_RESULT(no)
5645 fi
5646 AC_SUBST(EXTRA_LDFLAGS)
5647 ])dnl
5648 dnl ---------------------------------------------------------------------------
5649 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
5650 dnl ---------------
5651 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5652 dnl EXTRA_LDFLAGS for each -L option found.
5653 dnl
5654 dnl $cf_rpath_list contains a list of directories to ignore.
5655 dnl
5656 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5657 dnl      but LIBS often has misplaced -L options.
5658 AC_DEFUN([CF_RPATH_HACK_2],
5659 [
5660 CF_VERBOSE(...checking $1 [$]$1)
5661
5662 cf_rpath_dst=
5663 for cf_rpath_src in [$]$1
5664 do
5665         case $cf_rpath_src in
5666         (-L*)
5667
5668                 # check if this refers to a directory which we will ignore
5669                 cf_rpath_skip=no
5670                 if test -n "$cf_rpath_list"
5671                 then
5672                         for cf_rpath_item in $cf_rpath_list
5673                         do
5674                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5675                                 then
5676                                         cf_rpath_skip=yes
5677                                         break
5678                                 fi
5679                         done
5680                 fi
5681
5682                 if test "$cf_rpath_skip" = no
5683                 then
5684                         # transform the option
5685                         if test "$LD_RPATH_OPT" = "-R " ; then
5686                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5687                         else
5688                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5689                         fi
5690
5691                         # if we have not already added this, add it now
5692                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5693                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5694                         then
5695                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5696                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5697                         fi
5698                 fi
5699                 ;;
5700         esac
5701         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5702 done
5703 $1=$cf_rpath_dst
5704
5705 CF_VERBOSE(...checked $1 [$]$1)
5706 AC_SUBST(EXTRA_LDFLAGS)
5707 ])dnl
5708 dnl ---------------------------------------------------------------------------
5709 dnl CF_SHARED_OPTS version: 89 updated: 2015/08/15 18:38:59
5710 dnl --------------
5711 dnl --------------
5712 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5713 dnl library.
5714 dnl
5715 dnl Notes:
5716 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
5717 dnl the build-tree, i.e., by making use of the libraries that are compiled in
5718 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
5719 dnl shared library since that can lead to unexpected results at runtime.
5720 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
5721 dnl libraries are compiled in ../../lib
5722 dnl
5723 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5724 dnl to install symbolic links to the rel/abi versions of shared libraries.
5725 dnl
5726 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5727 dnl version when making symbolic links.
5728 dnl
5729 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5730 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5731 dnl (ex: libncurses.so.<ver>).
5732 dnl
5733 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5734 AC_DEFUN([CF_SHARED_OPTS],
5735 [
5736         AC_REQUIRE([CF_LD_RPATH_OPT])
5737         RM_SHARED_OPTS=
5738         LOCAL_LDFLAGS=
5739         LOCAL_LDFLAGS2=
5740         LD_SHARED_OPTS=
5741         INSTALL_LIB="-m 644"
5742         : ${rel_builddir:=.}
5743
5744         shlibdir=$libdir
5745         AC_SUBST(shlibdir)
5746
5747         MAKE_DLLS="#"
5748         AC_SUBST(MAKE_DLLS)
5749
5750         cf_cv_do_symlinks=no
5751         cf_ld_rpath_opt=
5752         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5753
5754         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5755         AC_ARG_WITH(shlib-version,
5756         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5757         [test -z "$withval" && withval=auto
5758         case $withval in
5759         (yes)
5760                 cf_cv_shlib_version=auto
5761                 ;;
5762         (rel|abi|auto)
5763                 cf_cv_shlib_version=$withval
5764                 ;;
5765         (*)
5766                 AC_MSG_RESULT($withval)
5767                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
5768                 ;;
5769         esac
5770         ],[cf_cv_shlib_version=auto])
5771         AC_MSG_RESULT($cf_cv_shlib_version)
5772
5773         cf_cv_rm_so_locs=no
5774         cf_try_cflags=
5775
5776         # Some less-capable ports of gcc support only -fpic
5777         CC_SHARED_OPTS=
5778         if test "$GCC" = yes
5779         then
5780                 AC_MSG_CHECKING(which $CC option to use)
5781                 cf_save_CFLAGS="$CFLAGS"
5782                 for CC_SHARED_OPTS in -fPIC -fpic ''
5783                 do
5784                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5785                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5786                 done
5787                 AC_MSG_RESULT($CC_SHARED_OPTS)
5788                 CFLAGS="$cf_save_CFLAGS"
5789         fi
5790
5791         cf_cv_shlib_version_infix=no
5792
5793         case $cf_cv_system_name in
5794         (aix4.[3-9]*|aix[[5-7]]*)
5795                 if test "$GCC" = yes; then
5796                         CC_SHARED_OPTS='-Wl,-brtl'
5797                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5798                 else
5799                         CC_SHARED_OPTS='-brtl'
5800                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
5801                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5802                 fi
5803                 ;;
5804         (beos*)
5805                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5806                 ;;
5807         (cygwin*)
5808                 CC_SHARED_OPTS=
5809                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5810                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5811                 cf_cv_shlib_version=cygdll
5812                 cf_cv_shlib_version_infix=cygdll
5813                 shlibdir=$bindir
5814                 MAKE_DLLS=
5815                 cat >mk_shared_lib.sh <<-CF_EOF
5816                 #!$SHELL
5817                 SHARED_LIB=\[$]1
5818                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5819                 shift
5820                 cat <<-EOF
5821                 Linking shared library
5822                 ** SHARED_LIB \[$]SHARED_LIB
5823                 ** IMPORT_LIB \[$]IMPORT_LIB
5824 EOF
5825                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5826 CF_EOF
5827                 chmod +x mk_shared_lib.sh
5828                 ;;
5829         (msys*)
5830                 CC_SHARED_OPTS=
5831                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5832                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5833                 cf_cv_shlib_version=msysdll
5834                 cf_cv_shlib_version_infix=msysdll
5835                 shlibdir=$bindir
5836                 MAKE_DLLS=
5837                 cat >mk_shared_lib.sh <<-CF_EOF
5838                 #!$SHELL
5839                 SHARED_LIB=\[$]1
5840                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5841                 shift
5842                 cat <<-EOF
5843                 Linking shared library
5844                 ** SHARED_LIB \[$]SHARED_LIB
5845                 ** IMPORT_LIB \[$]IMPORT_LIB
5846 EOF
5847                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5848 CF_EOF
5849                 chmod +x mk_shared_lib.sh
5850                 ;;
5851         (darwin*)
5852                 cf_try_cflags="no-cpp-precomp"
5853                 CC_SHARED_OPTS="-dynamic"
5854                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5855                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5856                 cf_cv_shlib_version_infix=yes
5857                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5858                         cf_save_LDFLAGS=$LDFLAGS
5859                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5860                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5861                                 LDFLAGS=$cf_save_LDFLAGS])
5862                 if test $cf_cv_ldflags_search_paths_first = yes; then
5863                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5864                 fi
5865                 ;;
5866         (hpux[[7-8]]*)
5867                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
5868                 if test "$GCC" != yes; then
5869                         CC_SHARED_OPTS='+Z'
5870                 fi
5871                 MK_SHARED_LIB='${LD} -b -o $[@]'
5872                 INSTALL_LIB="-m 555"
5873                 ;;
5874         (hpux*)
5875                 # (tested with gcc 2.7.2 -- I don't have c89)
5876                 if test "$GCC" = yes; then
5877                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5878                 else
5879                         CC_SHARED_OPTS='+Z'
5880                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5881                 fi
5882                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5883                 # HP-UX shared libraries must be executable, and should be
5884                 # readonly to exploit a quirk in the memory manager.
5885                 INSTALL_LIB="-m 555"
5886                 ;;
5887         (interix*)
5888                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5889                 if test "$cf_cv_shlib_version" = rel; then
5890                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5891                 else
5892                         cf_shared_soname='`basename $@`'
5893                 fi
5894                 CC_SHARED_OPTS=
5895                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5896                 ;;
5897         (irix*)
5898                 if test "$cf_cv_enable_rpath" = yes ; then
5899                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5900                 fi
5901                 # tested with IRIX 5.2 and 'cc'.
5902                 if test "$GCC" != yes; then
5903                         CC_SHARED_OPTS='-KPIC'
5904                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5905                 else
5906                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5907                 fi
5908                 cf_cv_rm_so_locs=yes
5909                 ;;
5910         (linux*|gnu*|k*bsd*-gnu)
5911                 if test "$DFT_LWR_MODEL" = "shared" ; then
5912                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5913                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5914                 fi
5915                 if test "$cf_cv_enable_rpath" = yes ; then
5916                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5917                 fi
5918                 CF_SHARED_SONAME
5919                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5920                 ;;
5921         (mingw*)
5922                 cf_cv_shlib_version=mingw
5923                 cf_cv_shlib_version_infix=mingw
5924                 shlibdir=$bindir
5925                 MAKE_DLLS=
5926                 if test "$DFT_LWR_MODEL" = "shared" ; then
5927                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
5928                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5929                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
5930                 fi
5931                 CC_SHARED_OPTS=
5932                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5933                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5934                 cat >mk_shared_lib.sh <<-CF_EOF
5935                 #!$SHELL
5936                 SHARED_LIB=\[$]1
5937                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5938                 shift
5939                 cat <<-EOF
5940                 Linking shared library
5941                 ** SHARED_LIB \[$]SHARED_LIB
5942                 ** IMPORT_LIB \[$]IMPORT_LIB
5943 EOF
5944                 exec \[$]* -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5945 CF_EOF
5946                 chmod +x mk_shared_lib.sh
5947                 ;;
5948         (openbsd[[2-9]].*|mirbsd*)
5949                 if test "$DFT_LWR_MODEL" = "shared" ; then
5950                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5951                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5952                 fi
5953                 if test "$cf_cv_enable_rpath" = yes ; then
5954                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5955                 fi
5956                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5957                 CF_SHARED_SONAME
5958                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5959                 ;;
5960         (nto-qnx*|openbsd*|freebsd[[12]].*)
5961                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5962                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5963                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5964                 ;;
5965         (dragonfly*|freebsd*)
5966                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5967                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5968                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5969                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
5970                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5971                 fi
5972                 CF_SHARED_SONAME
5973                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5974                 ;;
5975         (netbsd*)
5976                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5977                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5978                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5979                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5980                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5981                         if test "$cf_cv_shlib_version" = auto; then
5982                         if test -f /usr/libexec/ld.elf_so; then
5983                                 cf_cv_shlib_version=abi
5984                         else
5985                                 cf_cv_shlib_version=rel
5986                         fi
5987                         fi
5988                         CF_SHARED_SONAME
5989                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
5990                 else
5991                         MK_SHARED_LIB='${CC} -Wl,-shared -Wl,-Bshareable -o $[@]'
5992                 fi
5993                 ;;
5994         (osf*|mls+*)
5995                 # tested with OSF/1 V3.2 and 'cc'
5996                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
5997                 # link with shared libs).
5998                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
5999                 case $host_os in
6000                 (osf4*)
6001                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
6002                         ;;
6003                 esac
6004                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
6005                 if test "$DFT_LWR_MODEL" = "shared" ; then
6006                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6007                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6008                 fi
6009                 cf_cv_rm_so_locs=yes
6010                 ;;
6011         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
6012                 # tested with osr5.0.5
6013                 if test "$GCC" != yes; then
6014                         CC_SHARED_OPTS='-belf -KPIC'
6015                 fi
6016                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
6017                 if test "$cf_cv_enable_rpath" = yes ; then
6018                         # only way is to set LD_RUN_PATH but no switch for it
6019                         RUN_PATH=$libdir
6020                 fi
6021                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6022                 LINK_PROGS='LD_RUN_PATH=${libdir}'
6023                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
6024                 ;;
6025         (sunos4*)
6026                 # tested with SunOS 4.1.1 and gcc 2.7.0
6027                 if test "$GCC" != yes; then
6028                         CC_SHARED_OPTS='-KPIC'
6029                 fi
6030                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
6031                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6032                 ;;
6033         (solaris2*)
6034                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
6035                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
6036                 if test "$DFT_LWR_MODEL" = "shared" ; then
6037                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
6038                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6039                 fi
6040                 if test "$cf_cv_enable_rpath" = yes ; then
6041                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
6042                 fi
6043                 CF_SHARED_SONAME
6044                 if test "$GCC" != yes; then
6045                         cf_save_CFLAGS="$CFLAGS"
6046                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
6047                         do
6048                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
6049                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
6050                         done
6051                         CFLAGS="$cf_save_CFLAGS"
6052                         CC_SHARED_OPTS=$cf_shared_opts
6053                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
6054                 else
6055                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
6056                 fi
6057                 ;;
6058         (sysv5uw7*|unix_sv*)
6059                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
6060                 if test "$GCC" != yes; then
6061                         CC_SHARED_OPTS='-KPIC'
6062                 fi
6063                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
6064                 ;;
6065         (*)
6066                 CC_SHARED_OPTS='unknown'
6067                 MK_SHARED_LIB='echo unknown'
6068                 ;;
6069         esac
6070
6071         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
6072         case "$cf_cv_shlib_version" in
6073         (rel|abi)
6074                 case "$MK_SHARED_LIB" in
6075                 (*'-o $[@]')
6076                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
6077                         ;;
6078                 (*)
6079                         AC_MSG_WARN(ignored --with-shlib-version)
6080                         ;;
6081                 esac
6082                 ;;
6083         esac
6084
6085         if test -n "$cf_try_cflags"
6086         then
6087 cat > conftest.$ac_ext <<EOF
6088 #line __oline__ "${as_me:-configure}"
6089 #include <stdio.h>
6090 int main(int argc, char *argv[[]])
6091 {
6092         printf("hello\n");
6093         return (argv[[argc-1]] == 0) ;
6094 }
6095 EOF
6096                 cf_save_CFLAGS="$CFLAGS"
6097                 for cf_opt in $cf_try_cflags
6098                 do
6099                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
6100                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
6101                         if AC_TRY_EVAL(ac_compile); then
6102                                 AC_MSG_RESULT(yes)
6103                                 cf_save_CFLAGS="$CFLAGS"
6104                         else
6105                                 AC_MSG_RESULT(no)
6106                         fi
6107                 done
6108                 CFLAGS="$cf_save_CFLAGS"
6109         fi
6110
6111
6112         # RPATH_LIST is a colon-separated list of directories
6113         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
6114         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
6115
6116         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
6117
6118         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
6119         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
6120
6121         AC_SUBST(CC_SHARED_OPTS)
6122         AC_SUBST(LD_RPATH_OPT)
6123         AC_SUBST(LD_SHARED_OPTS)
6124         AC_SUBST(MK_SHARED_LIB)
6125         AC_SUBST(RM_SHARED_OPTS)
6126
6127         AC_SUBST(LINK_PROGS)
6128         AC_SUBST(LINK_TESTS)
6129
6130         AC_SUBST(EXTRA_LDFLAGS)
6131         AC_SUBST(LOCAL_LDFLAGS)
6132         AC_SUBST(LOCAL_LDFLAGS2)
6133
6134         AC_SUBST(INSTALL_LIB)
6135         AC_SUBST(RPATH_LIST)
6136 ])dnl
6137 dnl ---------------------------------------------------------------------------
6138 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
6139 dnl ----------------
6140 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
6141 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
6142 dnl option.
6143 dnl
6144 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
6145 dnl If missing, use "rel".
6146 define([CF_SHARED_SONAME],
6147 [
6148         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
6149         if test "$cf_cv_shlib_version" = rel; then
6150                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
6151         else
6152                 cf_cv_shared_soname='`basename $[@]`'
6153         fi
6154 ])
6155 dnl ---------------------------------------------------------------------------
6156 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
6157 dnl -----------
6158 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
6159 dnl programs need this test).
6160 dnl
6161 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
6162 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
6163 dnl winsize declaration is left alone - we may revisit this if Apple choose to
6164 dnl break that part of the interface as well.
6165 AC_DEFUN([CF_SIGWINCH],
6166 [
6167 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
6168         AC_TRY_COMPILE([
6169 #include <sys/types.h>
6170 #include <sys/signal.h>
6171 ],[int x = SIGWINCH],
6172         [cf_cv_define_sigwinch=yes],
6173         [AC_TRY_COMPILE([
6174 #undef _XOPEN_SOURCE
6175 #undef _POSIX_SOURCE
6176 #undef _POSIX_C_SOURCE
6177 #include <sys/types.h>
6178 #include <sys/signal.h>
6179 ],[int x = SIGWINCH],
6180         [cf_cv_define_sigwinch=maybe],
6181         [cf_cv_define_sigwinch=no])
6182 ])
6183 ])
6184
6185 if test "$cf_cv_define_sigwinch" = maybe ; then
6186 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
6187 cf_cv_fixup_sigwinch=unknown
6188 cf_sigwinch=32
6189 while test $cf_sigwinch != 1
6190 do
6191         AC_TRY_COMPILE([
6192 #undef _XOPEN_SOURCE
6193 #undef _POSIX_SOURCE
6194 #undef _POSIX_C_SOURCE
6195 #include <sys/types.h>
6196 #include <sys/signal.h>
6197 ],[
6198 #if SIGWINCH != $cf_sigwinch
6199 make an error
6200 #endif
6201 int x = SIGWINCH],
6202         [cf_cv_fixup_sigwinch=$cf_sigwinch
6203          break])
6204
6205 cf_sigwinch=`expr $cf_sigwinch - 1`
6206 done
6207 ])
6208
6209         if test "$cf_cv_fixup_sigwinch" != unknown ; then
6210                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
6211         fi
6212 fi
6213 ])dnl
6214 dnl ---------------------------------------------------------------------------
6215 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
6216 dnl ---------------
6217 dnl signal handler, but there are some gcc depedencies in that recommendation.
6218 dnl Try anyway.
6219 AC_DEFUN([CF_SIG_ATOMIC_T],
6220 [
6221 AC_MSG_CHECKING(for signal global datatype)
6222 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
6223         for cf_type in \
6224                 "volatile sig_atomic_t" \
6225                 "sig_atomic_t" \
6226                 "int"
6227         do
6228         AC_TRY_COMPILE([
6229 #include <sys/types.h>
6230 #include <signal.h>
6231 #include <stdio.h>
6232
6233 extern $cf_type x;
6234 $cf_type x;
6235 static void handler(int sig)
6236 {
6237         x = 5;
6238 }],
6239                 [signal(SIGINT, handler);
6240                  x = 1],
6241                 [cf_cv_sig_atomic_t=$cf_type],
6242                 [cf_cv_sig_atomic_t=no])
6243                 test "$cf_cv_sig_atomic_t" != no && break
6244         done
6245         ])
6246 AC_MSG_RESULT($cf_cv_sig_atomic_t)
6247 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
6248 ])dnl
6249 dnl ---------------------------------------------------------------------------
6250 dnl CF_SIZECHANGE version: 11 updated: 2015/04/18 08:56:57
6251 dnl -------------
6252 dnl Check for definitions & structures needed for window size-changing
6253 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
6254 AC_DEFUN([CF_SIZECHANGE],
6255 [
6256 AC_REQUIRE([CF_STRUCT_TERMIOS])
6257 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
6258         cf_cv_sizechange=unknown
6259         cf_save_CPPFLAGS="$CPPFLAGS"
6260
6261 for cf_opts in "" "NEED_PTEM_H"
6262 do
6263
6264         CPPFLAGS="$cf_save_CPPFLAGS"
6265         test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
6266         AC_TRY_COMPILE([#include <sys/types.h>
6267 #ifdef HAVE_TERMIOS_H
6268 #include <termios.h>
6269 #else
6270 #ifdef HAVE_TERMIO_H
6271 #include <termio.h>
6272 #endif
6273 #endif
6274 #ifdef NEED_PTEM_H
6275 /* This is a workaround for SCO:  they neglected to define struct winsize in
6276  * termios.h -- it's only in termio.h and ptem.h
6277  */
6278 #include        <sys/stream.h>
6279 #include        <sys/ptem.h>
6280 #endif
6281 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
6282 #include <sys/ioctl.h>
6283 #endif
6284 ],[
6285 #ifdef TIOCGSIZE
6286         struct ttysize win;     /* FIXME: what system is this? */
6287         int y = win.ts_lines;
6288         int x = win.ts_cols;
6289 #else
6290 #ifdef TIOCGWINSZ
6291         struct winsize win;
6292         int y = win.ws_row;
6293         int x = win.ws_col;
6294 #else
6295         no TIOCGSIZE or TIOCGWINSZ
6296 #endif /* TIOCGWINSZ */
6297 #endif /* TIOCGSIZE */
6298         ],
6299         [cf_cv_sizechange=yes],
6300         [cf_cv_sizechange=no])
6301
6302         CPPFLAGS="$cf_save_CPPFLAGS"
6303         if test "$cf_cv_sizechange" = yes ; then
6304                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
6305                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
6306                 break
6307         fi
6308 done
6309 ])
6310 if test "$cf_cv_sizechange" != no ; then
6311         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechar declarations are provided])
6312         case $cf_cv_sizechange in
6313         (NEED*)
6314                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
6315                 ;;
6316         esac
6317 fi
6318 ])dnl
6319 dnl ---------------------------------------------------------------------------
6320 dnl CF_SRC_MODULES version: 29 updated: 2015/04/12 11:42:01
6321 dnl --------------
6322 dnl For each parameter, test if the source-directory exists, and if it contains
6323 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
6324 dnl use in CF_LIB_RULES.
6325 dnl
6326 dnl This uses the configured value to make the lists SRC_SUBDIRS and
6327 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
6328 AC_DEFUN([CF_SRC_MODULES],
6329 [
6330 AC_MSG_CHECKING(for src modules)
6331
6332 # dependencies and linker-arguments for test-programs
6333 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
6334 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
6335 if test "$DFT_LWR_MODEL" = "libtool"; then
6336         TEST_ARGS="${TEST_DEPS}"
6337         TEST_ARG2="${TEST_DEP2}"
6338 else
6339         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
6340         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
6341 fi
6342
6343 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
6344 cf_cv_src_modules=
6345 for cf_dir in $1
6346 do
6347         if test -f $srcdir/$cf_dir/modules; then
6348
6349                 # We may/may not have tack in the distribution, though the
6350                 # makefile is.
6351                 if test $cf_dir = tack ; then
6352                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
6353                                 continue
6354                         fi
6355                 fi
6356
6357                 if test -z "$cf_cv_src_modules"; then
6358                         cf_cv_src_modules=$cf_dir
6359                 else
6360                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
6361                 fi
6362
6363                 # Make the ncurses_cfg.h file record the library interface files as
6364                 # well.  These are header files that are the same name as their
6365                 # directory.  Ncurses is the only library that does not follow
6366                 # that pattern.
6367                 if test $cf_dir = tack ; then
6368                         continue
6369                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
6370                         CF_UPPER(cf_have_include,$cf_dir)
6371                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
6372                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
6373                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
6374                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
6375                         if test "$DFT_LWR_MODEL" = "libtool"; then
6376                                 TEST_ARGS="${TEST_DEPS}"
6377                                 TEST_ARG2="${TEST_DEP2}"
6378                         else
6379                                 TEST_ARGS="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARGS"
6380                                 TEST_ARG2="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARG2"
6381                         fi
6382                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
6383                 fi
6384         fi
6385 done
6386 AC_MSG_RESULT($cf_cv_src_modules)
6387
6388 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
6389 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
6390
6391 AC_SUBST(TEST_ARGS)
6392 AC_SUBST(TEST_DEPS)
6393
6394 AC_SUBST(TEST_ARG2)
6395 AC_SUBST(TEST_DEP2)
6396
6397 SRC_SUBDIRS=
6398 if test "x$cf_with_manpages" != xno ; then
6399         SRC_SUBDIRS="$SRC_SUBDIRS man"
6400 fi
6401 SRC_SUBDIRS="$SRC_SUBDIRS include"
6402 for cf_dir in $cf_cv_src_modules
6403 do
6404         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
6405 done
6406 if test "x$cf_with_tests" != "xno" ; then
6407         SRC_SUBDIRS="$SRC_SUBDIRS test"
6408 fi
6409 # always make this, to install the ncurses-config script
6410 SRC_SUBDIRS="$SRC_SUBDIRS misc"
6411 if test "$cf_with_cxx_binding" != no; then
6412         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
6413         SRC_SUBDIRS="$SRC_SUBDIRS c++"
6414 fi
6415
6416 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
6417 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
6418
6419 AC_SUBST(PC_MODULES_TO_MAKE)
6420
6421 ADA_SUBDIRS=
6422 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
6423         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
6424         ADA_SUBDIRS="gen src"
6425         if test "x$cf_with_tests" != "xno" ; then
6426                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
6427         fi
6428 fi
6429
6430 SUB_MAKEFILES=
6431 for cf_dir in $SRC_SUBDIRS
6432 do
6433         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
6434 done
6435
6436 if test -n "$ADA_SUBDIRS"; then
6437         for cf_dir in $ADA_SUBDIRS
6438         do
6439                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
6440         done
6441         AC_SUBST(ADA_SUBDIRS)
6442 fi
6443 ])dnl
6444 dnl ---------------------------------------------------------------------------
6445 dnl CF_STDCPP_LIBRARY version: 11 updated: 2015/10/17 19:03:33
6446 dnl -----------------
6447 dnl Check for -lstdc++, which is GNU's standard C++ library.
6448 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
6449 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
6450 dnl add it to $CXXLIBS.
6451 AC_DEFUN([CF_STDCPP_LIBRARY],
6452 [
6453 if test -n "$GXX" ; then
6454
6455         cf_save="$LIBS"
6456         LIBS="$LIBS $CXXLIBS"
6457         AC_MSG_CHECKING(if we already have C++ library)
6458         AC_TRY_LINK([
6459                         #include <iostream>],[
6460                         std::cout << "Hello World!" << std::endl;],
6461                 [cf_have_libstdcpp=yes],
6462                 [cf_have_libstdcpp=no])
6463         AC_MSG_RESULT($cf_have_libstdcpp)
6464         LIBS="$cf_save"
6465
6466         if test $cf_have_libstdcpp != yes
6467         then
6468                 case $cf_cv_system_name in
6469                 (os2*)
6470                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
6471                                 cf_stdcpp_libname=stdcpp
6472                         else
6473                                 cf_stdcpp_libname=stdc++
6474                         fi
6475                         ;;
6476                 (*)
6477                         cf_stdcpp_libname=stdc++
6478                         ;;
6479                 esac
6480
6481                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
6482                         cf_save="$LIBS"
6483                         LIBS="$LIBS $CXXLIBS"
6484                         CF_ADD_LIB($cf_stdcpp_libname)
6485                 AC_TRY_LINK([
6486                                 #include <iostream>],[
6487                                 std::cout << "Hello World!" << std::endl;],
6488                         [cf_cv_libstdcpp=yes],
6489                         [cf_cv_libstdcpp=no])
6490                         LIBS="$cf_save"
6491                 ])
6492                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
6493         fi
6494 fi
6495 ])dnl
6496 dnl ---------------------------------------------------------------------------
6497 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
6498 dnl --------------
6499 dnl     Remove "-g" option from the compiler options
6500 AC_DEFUN([CF_STRIP_G_OPT],
6501 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
6502 dnl ---------------------------------------------------------------------------
6503 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
6504 dnl -------------------
6505 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
6506 dnl do this if we've found the sigaction function.
6507 AC_DEFUN([CF_STRUCT_SIGACTION],[
6508 AC_REQUIRE([CF_XOPEN_SOURCE])
6509
6510 if test "$ac_cv_func_sigaction" = yes; then
6511 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
6512 AC_TRY_COMPILE([
6513 #include <sys/types.h>
6514 #include <signal.h>],
6515         [struct sigaction act],
6516         [sigact_bad=no],
6517         [
6518 AC_TRY_COMPILE([
6519 #define _POSIX_SOURCE
6520 #include <sys/types.h>
6521 #include <signal.h>],
6522         [struct sigaction act],
6523         [sigact_bad=yes
6524          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
6525          [sigact_bad=unknown])])
6526 AC_MSG_RESULT($sigact_bad)
6527 fi
6528 ])dnl
6529 dnl ---------------------------------------------------------------------------
6530 dnl CF_STRUCT_TERMIOS version: 8 updated: 2015/04/15 19:08:48
6531 dnl -----------------
6532 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
6533 AC_DEFUN([CF_STRUCT_TERMIOS],[
6534 AC_REQUIRE([CF_XOPEN_SOURCE])
6535
6536 AC_CHECK_HEADERS( \
6537 termio.h \
6538 termios.h \
6539 unistd.h \
6540 )
6541
6542 if test "$ISC" = yes ; then
6543         AC_CHECK_HEADERS( sys/termio.h )
6544 fi
6545 if test "$ac_cv_header_termios_h" = yes ; then
6546         case "$CFLAGS $CPPFLAGS" in
6547         (*-D_POSIX_SOURCE*)
6548                 termios_bad=dunno ;;
6549         (*)     termios_bad=maybe ;;
6550         esac
6551         if test "$termios_bad" = maybe ; then
6552         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
6553         AC_TRY_COMPILE([#include <termios.h>],
6554                 [struct termios foo; int x = foo.c_iflag],
6555                 termios_bad=no, [
6556                 AC_TRY_COMPILE([
6557 #define _POSIX_SOURCE
6558 #include <termios.h>],
6559                         [struct termios foo; int x = foo.c_iflag],
6560                         termios_bad=unknown,
6561                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
6562                         ])
6563         AC_MSG_RESULT($termios_bad)
6564         fi
6565 fi
6566 ])dnl
6567 dnl ---------------------------------------------------------------------------
6568 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
6569 dnl --------------
6570 dnl Construct a search-list for a nonstandard header/lib-file
6571 dnl     $1 = the variable to return as result
6572 dnl     $2 = the package name
6573 dnl     $3 = the subdirectory, e.g., bin, include or lib
6574 AC_DEFUN([CF_SUBDIR_PATH],
6575 [
6576 $1=
6577
6578 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
6579
6580 for cf_subdir_prefix in \
6581         /usr \
6582         /usr/local \
6583         /usr/pkg \
6584         /opt \
6585         /opt/local \
6586         [$]HOME
6587 do
6588         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
6589 done
6590 ])dnl
6591 dnl ---------------------------------------------------------------------------
6592 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
6593 dnl -----------
6594 dnl     Shorthand macro for substituting things that the user may override
6595 dnl     with an environment variable.
6596 dnl
6597 dnl     $1 = condition to pass to "test"
6598 dnl     $2 = environment variable
6599 dnl     $3 = value if the test succeeds
6600 dnl     $4 = value if the test fails
6601 AC_DEFUN([CF_SUBST_IF],
6602 [
6603 if test $1 ; then
6604         $2=$3
6605 ifelse($4,,,[else
6606         $2=$4])
6607 fi
6608 AC_SUBST($2)
6609 ])dnl
6610 dnl ---------------------------------------------------------------------------
6611 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
6612 dnl ------------------------
6613 dnl Get the version-number for use in shared-library naming, etc.
6614 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
6615 [
6616 AC_REQUIRE([CF_PROG_EGREP])
6617 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6618 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6619 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6620 cf_cv_abi_version=${NCURSES_MAJOR}
6621 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
6622 dnl Show the computed version, for logging
6623 cf_cv_timestamp=`date`
6624 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
6625 dnl We need these values in the generated headers
6626 AC_SUBST(NCURSES_MAJOR)
6627 AC_SUBST(NCURSES_MINOR)
6628 AC_SUBST(NCURSES_PATCH)
6629 dnl We need these values in the generated makefiles
6630 AC_SUBST(cf_cv_rel_version)
6631 AC_SUBST(cf_cv_abi_version)
6632 AC_SUBST(cf_cv_builtin_bool)
6633 AC_SUBST(cf_cv_header_stdbool_h)
6634 AC_SUBST(cf_cv_type_of_bool)dnl
6635 ])dnl
6636 dnl ---------------------------------------------------------------------------
6637 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
6638 dnl ------------------
6639 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6640 dnl older SCO configurations.
6641 AC_DEFUN([CF_SYS_TIME_SELECT],
6642 [
6643 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6644 AC_CACHE_VAL(cf_cv_sys_time_select,[
6645 AC_TRY_COMPILE([
6646 #include <sys/types.h>
6647 #ifdef HAVE_SYS_TIME_H
6648 #include <sys/time.h>
6649 #endif
6650 #ifdef HAVE_SYS_SELECT_H
6651 #include <sys/select.h>
6652 #endif
6653 ],[],[cf_cv_sys_time_select=yes],
6654          [cf_cv_sys_time_select=no])
6655          ])
6656 AC_MSG_RESULT($cf_cv_sys_time_select)
6657 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
6658 ])dnl
6659 dnl ---------------------------------------------------------------------------
6660 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
6661 dnl ---------------
6662 dnl Define a top_builddir symbol, for applications that need an absolute path.
6663 AC_DEFUN([CF_TOP_BUILDDIR],
6664 [
6665 top_builddir=ifelse($1,,`pwd`,$1)
6666 AC_SUBST(top_builddir)
6667 ])dnl
6668 dnl ---------------------------------------------------------------------------
6669 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6670 dnl -------------------
6671 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6672 dnl can define it successfully.
6673 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6674 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6675         AC_TRY_COMPILE([
6676 #include <stdlib.h>
6677 #include <string.h>
6678 #include <sys/types.h>
6679 ],[
6680 #ifndef _XOPEN_SOURCE
6681 make an error
6682 #endif],
6683         [cf_cv_xopen_source=no],
6684         [cf_save="$CPPFLAGS"
6685          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6686          AC_TRY_COMPILE([
6687 #include <stdlib.h>
6688 #include <string.h>
6689 #include <sys/types.h>
6690 ],[
6691 #ifdef _XOPEN_SOURCE
6692 make an error
6693 #endif],
6694         [cf_cv_xopen_source=no],
6695         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6696         CPPFLAGS="$cf_save"
6697         ])
6698 ])
6699
6700 if test "$cf_cv_xopen_source" != no ; then
6701         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6702         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6703         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6704         CF_ADD_CFLAGS($cf_temp_xopen_source)
6705 fi
6706 ])
6707 dnl ---------------------------------------------------------------------------
6708 dnl CF_TYPEOF_CHTYPE version: 9 updated: 2012/10/06 17:56:13
6709 dnl ----------------
6710 dnl Determine the type we should use for chtype (and attr_t, which is treated
6711 dnl as the same thing).  We want around 32 bits, so on most machines want a
6712 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6713 dnl wide characters, we have to have a type compatible with that, as well.
6714 AC_DEFUN([CF_TYPEOF_CHTYPE],
6715 [
6716 AC_MSG_CHECKING([for type of chtype])
6717 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6718                 AC_TRY_RUN([
6719 #define WANT_BITS 31
6720 #include <stdio.h>
6721 int main()
6722 {
6723         FILE *fp = fopen("cf_test.out", "w");
6724         if (fp != 0) {
6725                 char *result = "long";
6726                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6727                         int n;
6728                         unsigned int x, y;
6729                         for (n = 0; n < WANT_BITS; n++) {
6730                                 x = (1 << n);
6731                                 y = (x >> n);
6732                                 if (y != 1 || x == 0) {
6733                                         x = 0;
6734                                         break;
6735                                 }
6736                         }
6737                         /*
6738                          * If x is nonzero, an int is big enough for the bits
6739                          * that we want.
6740                          */
6741                         result = (x != 0) ? "int" : "long";
6742                 }
6743                 fputs(result, fp);
6744                 fclose(fp);
6745         }
6746         ${cf_cv_main_return:-return}(0);
6747 }
6748                 ],
6749                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6750                 [cf_cv_typeof_chtype=long],
6751                 [cf_cv_typeof_chtype=long])
6752                 rm -f cf_test.out
6753         ])
6754 AC_MSG_RESULT($cf_cv_typeof_chtype)
6755
6756 AC_SUBST(cf_cv_typeof_chtype)
6757 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
6758 ])dnl
6759 dnl ---------------------------------------------------------------------------
6760 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
6761 dnl -----------------
6762 dnl
6763 AC_DEFUN([CF_TYPE_SIGACTION],
6764 [
6765 AC_MSG_CHECKING([for type sigaction_t])
6766 AC_CACHE_VAL(cf_cv_type_sigaction,[
6767         AC_TRY_COMPILE([
6768 #include <signal.h>],
6769                 [sigaction_t x],
6770                 [cf_cv_type_sigaction=yes],
6771                 [cf_cv_type_sigaction=no])])
6772 AC_MSG_RESULT($cf_cv_type_sigaction)
6773 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
6774 ])dnl
6775 dnl ---------------------------------------------------------------------------
6776 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6777 dnl --------------------
6778 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6779 dnl won't, but they're still there.
6780 AC_DEFUN([CF_UNSIGNED_LITERALS],
6781 [
6782 AC_MSG_CHECKING([if unsigned literals are legal])
6783 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6784         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6785                 [cf_cv_unsigned_literals=yes],
6786                 [cf_cv_unsigned_literals=no])
6787         ])
6788 AC_MSG_RESULT($cf_cv_unsigned_literals)
6789 ])dnl
6790 dnl ---------------------------------------------------------------------------
6791 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6792 dnl --------
6793 dnl Make an uppercase version of a variable
6794 dnl $1=uppercase($2)
6795 AC_DEFUN([CF_UPPER],
6796 [
6797 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6798 ])dnl
6799 dnl ---------------------------------------------------------------------------
6800 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
6801 dnl -----------
6802 dnl Check for multibyte support, and if not found, utf8 compatibility library
6803 AC_DEFUN([CF_UTF8_LIB],
6804 [
6805 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6806         cf_save_LIBS="$LIBS"
6807         AC_TRY_LINK([
6808 #include <stdlib.h>],[putwc(0,0);],
6809         [cf_cv_utf8_lib=yes],
6810         [CF_FIND_LINKAGE([
6811 #include <libutf8.h>],[putwc(0,0);],utf8,
6812                 [cf_cv_utf8_lib=add-on],
6813                 [cf_cv_utf8_lib=no])
6814 ])])
6815
6816 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6817 # ncurses/ncursesw:
6818 if test "$cf_cv_utf8_lib" = "add-on" ; then
6819         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
6820         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6821         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6822         CF_ADD_LIBS($cf_cv_library_file_utf8)
6823 fi
6824 ])dnl
6825 dnl ---------------------------------------------------------------------------
6826 dnl CF_VA_COPY version: 3 updated: 2012/10/06 11:17:15
6827 dnl ----------
6828 dnl check for va_copy, part of stdarg.h
6829 dnl Also, workaround for glibc's __va_copy, by checking for both.
6830 AC_DEFUN([CF_VA_COPY],[
6831 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6832 AC_TRY_LINK([
6833 #include <stdarg.h>
6834 ],[
6835         static va_list dst;
6836         static va_list src;
6837         va_copy(dst, src)],
6838         cf_cv_have_va_copy=yes,
6839         cf_cv_have_va_copy=no)])
6840
6841 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
6842
6843 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6844 AC_TRY_LINK([
6845 #include <stdarg.h>
6846 ],[
6847         static va_list dst;
6848         static va_list src;
6849         __va_copy(dst, src)],
6850         cf_cv_have___va_copy=yes,
6851         cf_cv_have___va_copy=no)])
6852
6853 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
6854 ])
6855 dnl ---------------------------------------------------------------------------
6856 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6857 dnl ----------
6858 dnl Use AC_VERBOSE w/o the warnings
6859 AC_DEFUN([CF_VERBOSE],
6860 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6861 CF_MSG_LOG([$1])
6862 ])dnl
6863 dnl ---------------------------------------------------------------------------
6864 dnl CF_VERSION_INFO version: 7 updated: 2015/04/17 21:13:04
6865 dnl ---------------
6866 dnl Define several useful symbols derived from the VERSION file.  A separate
6867 dnl file is preferred to embedding the version numbers in various scripts.
6868 dnl (automake is a textbook-example of why the latter is a bad idea, but there
6869 dnl are others).
6870 dnl
6871 dnl The file contents are:
6872 dnl     libtool-version release-version patch-version
6873 dnl or
6874 dnl     release-version
6875 dnl where
6876 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
6877 dnl     release-version consists of a major version and minor version
6878 dnl             separated by '.', optionally followed by a patch-version
6879 dnl             separated by '-'.  The minor version need not be an
6880 dnl             integer (but it is preferred).
6881 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
6882 dnl             scripts can easily compare versions.
6883 dnl
6884 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
6885 dnl simply extracts the first field using 'cut -f1'.
6886 dnl
6887 dnl Optional parameters:
6888 dnl $1 = internal name for package
6889 dnl $2 = external name for package
6890 AC_DEFUN([CF_VERSION_INFO],
6891 [
6892 if test -f $srcdir/VERSION ; then
6893         AC_MSG_CHECKING(for package version)
6894
6895         # if there are not enough fields, cut returns the last one...
6896         cf_field1=`sed -e '2,$d' $srcdir/VERSION|cut -f1`
6897         cf_field2=`sed -e '2,$d' $srcdir/VERSION|cut -f2`
6898         cf_field3=`sed -e '2,$d' $srcdir/VERSION|cut -f3`
6899
6900         # this is how CF_BUNDLED_INTL uses $VERSION:
6901         VERSION="$cf_field1"
6902
6903         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
6904         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
6905
6906         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
6907         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
6908
6909         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
6910
6911         AC_MSG_CHECKING(for package patch date)
6912         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
6913         case .$VERSION_PATCH in
6914         (.)
6915                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
6916                 ;;
6917         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
6918                 ;;
6919         (*)
6920                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
6921                 ;;
6922         esac
6923         AC_MSG_RESULT($VERSION_PATCH)
6924 else
6925         AC_MSG_ERROR(did not find $srcdir/VERSION)
6926 fi
6927
6928 # show the actual data that we have for versions:
6929 CF_VERBOSE(ABI VERSION $VERSION)
6930 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
6931 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
6932 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
6933
6934 AC_SUBST(VERSION)
6935 AC_SUBST(VERSION_MAJOR)
6936 AC_SUBST(VERSION_MINOR)
6937 AC_SUBST(VERSION_PATCH)
6938
6939 dnl if a package name is given, define its corresponding version info.  We
6940 dnl need the package name to ensure that the defined symbols are unique.
6941 ifelse($1,,,[
6942         cf_PACKAGE=$1
6943         PACKAGE=ifelse($2,,$1,$2)
6944         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
6945         AC_SUBST(PACKAGE)
6946         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
6947         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
6948         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
6949 ])
6950 ])dnl
6951 dnl ---------------------------------------------------------------------------
6952 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
6953 dnl -------------
6954 dnl Check if type wide-character type $1 is declared, and if so, which header
6955 dnl file is needed.  The second parameter is used to set a shell variable when
6956 dnl the type is not found.  The first parameter sets a shell variable for the
6957 dnl opposite sense.
6958 AC_DEFUN([CF_WCHAR_TYPE],
6959 [
6960 # This is needed on Tru64 5.0 to declare $1
6961 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6962 AC_TRY_COMPILE([
6963 #include <stdlib.h>
6964 #include <stdarg.h>
6965 #include <stdio.h>
6966 #ifdef HAVE_LIBUTF8_H
6967 #include <libutf8.h>
6968 #endif],
6969         [$1 state],
6970         [cf_cv_$1=no],
6971         [AC_TRY_COMPILE([
6972 #include <stdlib.h>
6973 #include <stdarg.h>
6974 #include <stdio.h>
6975 #include <wchar.h>
6976 #ifdef HAVE_LIBUTF8_H
6977 #include <libutf8.h>
6978 #endif],
6979         [$1 value],
6980         [cf_cv_$1=yes],
6981         [cf_cv_$1=unknown])])])
6982
6983 if test "$cf_cv_$1" = yes ; then
6984         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
6985         NEED_WCHAR_H=1
6986 fi
6987
6988 ifelse([$2],,,[
6989 # if we do not find $1 in either place, use substitution to provide a fallback.
6990 if test "$cf_cv_$1" = unknown ; then
6991         $2=1
6992 fi
6993 ])
6994 ifelse($3,,,[
6995 # if we find $1 in either place, use substitution to provide a fallback.
6996 if test "$cf_cv_$1" != unknown ; then
6997         $3=1
6998 fi
6999 ])
7000 ])dnl
7001 dnl ---------------------------------------------------------------------------
7002 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
7003 dnl ---------------
7004 dnl Check for compiler-support for weak symbols.
7005 dnl This works with "recent" gcc.
7006 AC_DEFUN([CF_WEAK_SYMBOLS],[
7007 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
7008
7009 AC_TRY_COMPILE([
7010 #include <stdio.h>],
7011 [
7012 #if defined(__GNUC__)
7013 #  if defined __USE_ISOC99
7014 #    define _cat_pragma(exp)    _Pragma(#exp)
7015 #    define _weak_pragma(exp)   _cat_pragma(weak name)
7016 #  else
7017 #    define _weak_pragma(exp)
7018 #  endif
7019 #  define _declare(name)        __extension__ extern __typeof__(name) name
7020 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
7021 #endif
7022
7023 weak_symbol(fopen);
7024 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
7025 ])
7026 ])dnl
7027 dnl ---------------------------------------------------------------------------
7028 dnl CF_WITH_ABI_VERSION version: 3 updated: 2015/06/06 16:10:11
7029 dnl -------------------
7030 dnl Allow library's ABI to be overridden.  Generally this happens when a
7031 dnl packager has incremented the ABI past that used in the original package,
7032 dnl and wishes to keep doing this.
7033 dnl
7034 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
7035 dnl symbol.
7036 AC_DEFUN([CF_WITH_ABI_VERSION],[
7037 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
7038 AC_ARG_WITH(abi-version,
7039 [  --with-abi-version=XXX  override derived ABI version],[
7040         if test "x$cf_cv_abi_version" != "x$withval"
7041         then
7042                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
7043                 case $cf_cv_rel_version in
7044                 (5.*)
7045                         cf_cv_rel_version=$withval.0
7046                         ;;
7047                 (6.*)
7048                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
7049                         ;;
7050                 esac
7051         fi
7052         cf_cv_abi_version=$withval])
7053         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
7054 ifelse($1,,,[
7055 $1_ABI=$cf_cv_abi_version
7056 ])
7057 ])dnl
7058 dnl ---------------------------------------------------------------------------
7059 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
7060 dnl --------------------
7061 dnl Command-line option to specify the Ada95 compiler.
7062 AC_DEFUN([CF_WITH_ADA_COMPILER],[
7063 AC_MSG_CHECKING(for ada-compiler)
7064 AC_ARG_WITH(ada-compiler,
7065         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
7066         [cf_ada_compiler=$withval],
7067         [cf_ada_compiler=gnatmake])
7068 AC_SUBST(cf_ada_compiler)
7069 AC_MSG_RESULT($cf_ada_compiler)
7070 ])dnl
7071 dnl ---------------------------------------------------------------------------
7072 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
7073 dnl -------------------
7074 dnl Command-line option to specify where Ada includes will install.
7075 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
7076 AC_MSG_CHECKING(for ada-include)
7077 CF_WITH_PATH(ada-include,
7078    [  --with-ada-include=DIR  Ada includes are in DIR],
7079    ADA_INCLUDE,
7080    PREFIX/share/ada/adainclude,
7081    [$]prefix/share/ada/adainclude)
7082 AC_SUBST(ADA_INCLUDE)
7083 AC_MSG_RESULT($ADA_INCLUDE)
7084 ])dnl
7085 dnl ---------------------------------------------------------------------------
7086 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
7087 dnl -------------------
7088 dnl Command-line option to specify where Ada objects will install.
7089 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
7090 AC_MSG_CHECKING(for ada-objects)
7091 CF_WITH_PATH(ada-objects,
7092    [  --with-ada-objects=DIR  Ada objects are in DIR],
7093    ADA_OBJECTS,
7094    PREFIX/lib/ada/adalib,
7095    [$]prefix/lib/ada/adalib)
7096 AC_SUBST(ADA_OBJECTS)
7097 AC_MSG_RESULT($ADA_OBJECTS)
7098 ])dnl
7099 dnl ---------------------------------------------------------------------------
7100 dnl CF_WITH_ADA_SHAREDLIB version: 4 updated: 2014/05/31 21:08:37
7101 dnl ---------------------
7102 dnl Command-line option to specify if an Ada95 shared-library should be built,
7103 dnl and optionally what its soname should be.
7104 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
7105 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
7106 AC_ARG_WITH(ada-sharedlib,
7107         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
7108         [with_ada_sharedlib=$withval],
7109         [with_ada_sharedlib=no])
7110 AC_MSG_RESULT($with_ada_sharedlib)
7111
7112 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
7113 MAKE_ADA_SHAREDLIB="#"
7114
7115 if test "x$with_ada_sharedlib" != xno
7116 then
7117         MAKE_ADA_SHAREDLIB=
7118         if test "x$with_ada_sharedlib" != xyes
7119         then
7120                 ADA_SHAREDLIB="$with_ada_sharedlib"
7121         fi
7122 fi
7123
7124 AC_SUBST(ADA_SHAREDLIB)
7125 AC_SUBST(MAKE_ADA_SHAREDLIB)
7126 ])dnl
7127 dnl ---------------------------------------------------------------------------
7128 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
7129 dnl ----------------
7130 dnl Configure-option for dbmalloc.  The optional parameter is used to override
7131 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
7132 AC_DEFUN([CF_WITH_DBMALLOC],[
7133 CF_NO_LEAKS_OPTION(dbmalloc,
7134         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
7135         [USE_DBMALLOC])
7136
7137 if test "$with_dbmalloc" = yes ; then
7138         AC_CHECK_HEADER(dbmalloc.h,
7139                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
7140 fi
7141 ])dnl
7142 dnl ---------------------------------------------------------------------------
7143 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
7144 dnl ---------------
7145 dnl Configure-option for dmalloc.  The optional parameter is used to override
7146 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
7147 AC_DEFUN([CF_WITH_DMALLOC],[
7148 CF_NO_LEAKS_OPTION(dmalloc,
7149         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
7150         [USE_DMALLOC])
7151
7152 if test "$with_dmalloc" = yes ; then
7153         AC_CHECK_HEADER(dmalloc.h,
7154                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
7155 fi
7156 ])dnl
7157 dnl ---------------------------------------------------------------------------
7158 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
7159 dnl -------------------
7160 dnl Use this with libtool to specify the list of symbols that may be exported.
7161 dnl The input file contains one symbol per line; comments work with "#".
7162 dnl
7163 dnl $1 = basename of the ".sym" file (default $PACKAGE)
7164 AC_DEFUN([CF_WITH_EXPORT_SYMS],
7165 [
7166 AC_MSG_CHECKING(if exported-symbols file should be used)
7167 AC_ARG_WITH(export-syms,
7168         [  --with-export-syms=XXX  limit exported symbols using libtool],
7169         [with_export_syms=$withval],
7170         [with_export_syms=no])
7171 if test "x$with_export_syms" = xyes
7172 then
7173         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
7174         AC_SUBST(PACKAGE)
7175 fi
7176 AC_MSG_RESULT($with_export_syms)
7177 if test "x$with_export_syms" != xno
7178 then
7179         EXPORT_SYMS="-export-symbols $with_export_syms"
7180         AC_SUBST(EXPORT_SYMS)
7181 fi
7182 ])dnl
7183 dnl ---------------------------------------------------------------------------
7184 dnl CF_WITH_GPM version: 9 updated: 2016/05/28 20:33:31
7185 dnl -----------
7186 dnl
7187 dnl The option parameter (if neither yes/no) is assumed to be the name of
7188 dnl the gpm library, e.g., for dynamic loading.
7189 AC_DEFUN([CF_WITH_GPM],
7190 [
7191 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
7192 AC_ARG_WITH(gpm,
7193         [  --with-gpm              use Alessandro Rubini's GPM library],
7194         [with_gpm=$withval],
7195         [with_gpm=maybe])
7196 AC_MSG_RESULT($with_gpm)
7197
7198 if test "$with_gpm" != no ; then
7199         AC_CHECK_HEADER(gpm.h,[
7200                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
7201                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
7202                         CF_VERBOSE(assuming we really have GPM library)
7203                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
7204                         with_gpm=yes
7205                 else
7206                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
7207                                 if test "$with_gpm" = maybe; then
7208                                         AC_MSG_WARN(Cannot link with GPM library)
7209                                         with_gpm=no
7210                                 else
7211                                         AC_MSG_ERROR(Cannot link with GPM library)
7212                                 fi
7213                         ])
7214                 fi
7215         ],[
7216                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
7217                 with_gpm=no
7218         ])
7219 fi
7220 ])
7221 dnl ---------------------------------------------------------------------------
7222 dnl CF_WITH_LIBTOOL version: 33 updated: 2015/10/17 19:03:33
7223 dnl ---------------
7224 dnl Provide a configure option to incorporate libtool.  Define several useful
7225 dnl symbols for the makefile rules.
7226 dnl
7227 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
7228 dnl macros from libtool.m4 which is in the aclocal directory of automake.
7229 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
7230 dnl But that still does not work properly since the macro is expanded outside
7231 dnl the CF_WITH_LIBTOOL macro:
7232 dnl
7233 dnl     #!/bin/sh
7234 dnl     ACLOCAL=`aclocal --print-ac-dir`
7235 dnl     if test -z "$ACLOCAL" ; then
7236 dnl             echo cannot find aclocal directory
7237 dnl             exit 1
7238 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
7239 dnl             echo cannot find libtool.m4 file
7240 dnl             exit 1
7241 dnl     fi
7242 dnl
7243 dnl     LOCAL=aclocal.m4
7244 dnl     ORIG=aclocal.m4.orig
7245 dnl
7246 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
7247 dnl     rm -f $ORIG
7248 dnl     mv $LOCAL $ORIG
7249 dnl
7250 dnl     # sed the LIBTOOL= assignment to omit the current directory?
7251 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
7252 dnl     cat $ORIG >>$LOCAL
7253 dnl
7254 dnl     autoconf-257 $*
7255 dnl
7256 AC_DEFUN([CF_WITH_LIBTOOL],
7257 [
7258 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
7259 ifdef([AC_PROG_LIBTOOL],,[
7260 LIBTOOL=
7261 ])
7262 # common library maintenance symbols that are convenient for libtool scripts:
7263 LIB_CREATE='${AR} -cr'
7264 LIB_OBJECT='${OBJECTS}'
7265 LIB_SUFFIX=.a
7266 LIB_PREP="$RANLIB"
7267
7268 # symbols used to prop libtool up to enable it to determine what it should be
7269 # doing:
7270 LIB_CLEAN=
7271 LIB_COMPILE=
7272 LIB_LINK='${CC}'
7273 LIB_INSTALL=
7274 LIB_UNINSTALL=
7275
7276 AC_MSG_CHECKING(if you want to build libraries with libtool)
7277 AC_ARG_WITH(libtool,
7278         [  --with-libtool          generate libraries with libtool],
7279         [with_libtool=$withval],
7280         [with_libtool=no])
7281 AC_MSG_RESULT($with_libtool)
7282 if test "$with_libtool" != "no"; then
7283 ifdef([AC_PROG_LIBTOOL],[
7284         # missing_content_AC_PROG_LIBTOOL{{
7285         AC_PROG_LIBTOOL
7286         # missing_content_AC_PROG_LIBTOOL}}
7287 ],[
7288         if test "$with_libtool" != "yes" ; then
7289                 CF_PATH_SYNTAX(with_libtool)
7290                 LIBTOOL=$with_libtool
7291         else
7292                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
7293                 CF_LIBTOOL_VERSION
7294                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
7295                 then
7296                         CF_FORGET_TOOL(LIBTOOL)
7297                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
7298                         CF_LIBTOOL_VERSION
7299                 fi
7300         fi
7301         if test -z "$LIBTOOL" ; then
7302                 AC_MSG_ERROR(Cannot find libtool)
7303         fi
7304 ])dnl
7305         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${DESTDIR}${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
7306         LIB_OBJECT='${OBJECTS:.o=.lo}'
7307         LIB_SUFFIX=.la
7308         LIB_CLEAN='${LIBTOOL} --mode=clean'
7309         LIB_COMPILE='${LIBTOOL} --mode=compile'
7310         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
7311         LIB_INSTALL='${LIBTOOL} --mode=install'
7312         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
7313         LIB_PREP=:
7314
7315         CF_CHECK_LIBTOOL_VERSION
7316
7317         # special hack to add -no-undefined (which libtool should do for itself)
7318         LT_UNDEF=
7319         case "$cf_cv_system_name" in
7320         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
7321                 LT_UNDEF=-no-undefined
7322                 ;;
7323         esac
7324         AC_SUBST([LT_UNDEF])
7325
7326         # special hack to add --tag option for C++ compiler
7327         case $cf_cv_libtool_version in
7328         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
7329                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
7330                 LIBTOOL="$LIBTOOL --tag=CC"
7331                 ;;
7332         (*)
7333                 LIBTOOL_CXX="$LIBTOOL"
7334                 ;;
7335         esac
7336 else
7337         LIBTOOL=""
7338         LIBTOOL_CXX=""
7339 fi
7340
7341 test -z "$LIBTOOL" && ECHO_LT=
7342
7343 AC_SUBST(LIBTOOL)
7344 AC_SUBST(LIBTOOL_CXX)
7345 AC_SUBST(LIBTOOL_OPTS)
7346
7347 AC_SUBST(LIB_CREATE)
7348 AC_SUBST(LIB_OBJECT)
7349 AC_SUBST(LIB_SUFFIX)
7350 AC_SUBST(LIB_PREP)
7351
7352 AC_SUBST(LIB_CLEAN)
7353 AC_SUBST(LIB_COMPILE)
7354 AC_SUBST(LIB_LINK)
7355 AC_SUBST(LIB_INSTALL)
7356 AC_SUBST(LIB_UNINSTALL)
7357
7358 ])dnl
7359 dnl ---------------------------------------------------------------------------
7360 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
7361 dnl --------------------
7362 dnl Allow user to pass additional libtool options into the library creation
7363 dnl and link steps.  The main use for this is to do something like
7364 dnl     ./configure --with-libtool-opts=-static
7365 dnl to get the same behavior as automake-flavored
7366 dnl     ./configure --enable-static
7367 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
7368 AC_MSG_CHECKING(for additional libtool options)
7369 AC_ARG_WITH(libtool-opts,
7370         [  --with-libtool-opts=XXX specify additional libtool options],
7371         [with_libtool_opts=$withval],
7372         [with_libtool_opts=no])
7373 AC_MSG_RESULT($with_libtool_opts)
7374
7375 case .$with_libtool_opts in
7376 (.yes|.no|.)
7377         ;;
7378 (*)
7379         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
7380         ;;
7381 esac
7382
7383 AC_SUBST(LIBTOOL_OPTS)
7384 ])dnl
7385 dnl ---------------------------------------------------------------------------
7386 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
7387 dnl ------------------
7388 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
7389 dnl "lib" prefix, e.g., because it used the dll naming convention.
7390 dnl
7391 dnl $1 = variable to set
7392 AC_DEFUN([CF_WITH_LIB_PREFIX],
7393 [
7394 AC_MSG_CHECKING(if you want to have a library-prefix)
7395 AC_ARG_WITH(lib-prefix,
7396         [  --with-lib-prefix       override library-prefix],
7397         [with_lib_prefix=$withval],
7398         [with_lib_prefix=auto])
7399 AC_MSG_RESULT($with_lib_prefix)
7400
7401 if test $with_lib_prefix = auto
7402 then
7403         CF_LIB_PREFIX($1)
7404 elif test $with_lib_prefix = no
7405 then
7406         LIB_PREFIX=
7407 else
7408         LIB_PREFIX=$with_lib_prefix
7409 fi
7410 ])dnl
7411 dnl ---------------------------------------------------------------------------
7412 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
7413 dnl ------------
7414 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
7415 dnl defaulting to yes/no.
7416 dnl
7417 dnl $1 = option name
7418 dnl $2 = help-text
7419 dnl $3 = environment variable to set
7420 dnl $4 = default value, shown in the help-message, must be a constant
7421 dnl $5 = default value, if it's an expression & cannot be in the help-message
7422 dnl
7423 AC_DEFUN([CF_WITH_PATH],
7424 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
7425 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
7426 if ifelse([$5],,true,[test -n "$5"]) ; then
7427 CF_PATH_SYNTAX(withval)
7428 fi
7429 eval $3="$withval"
7430 AC_SUBST($3)dnl
7431 ])dnl
7432 dnl ---------------------------------------------------------------------------
7433 dnl CF_WITH_PATHLIST version: 10 updated: 2015/04/17 21:13:04
7434 dnl ----------------
7435 dnl Process an option specifying a list of colon-separated paths.
7436 dnl
7437 dnl $1 = option name
7438 dnl $2 = help-text
7439 dnl $3 = environment variable to set
7440 dnl $4 = default value, shown in the help-message, must be a constant
7441 dnl $5 = default value, if it's an expression & cannot be in the help-message
7442 dnl $6 = flag to tell if we want to define or substitute
7443 dnl
7444 AC_DEFUN([CF_WITH_PATHLIST],[
7445 AC_REQUIRE([CF_PATHSEP])
7446 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
7447 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
7448
7449 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
7450 cf_dst_path=
7451 for cf_src_path in $withval
7452 do
7453   CF_PATH_SYNTAX(cf_src_path)
7454   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
7455   cf_dst_path="${cf_dst_path}${cf_src_path}"
7456 done
7457 IFS="$ac_save_ifs"
7458
7459 ifelse($6,define,[
7460 # Strip single quotes from the value, e.g., when it was supplied as a literal
7461 # for $4 or $5.
7462 case $cf_dst_path in
7463 (\'*)
7464   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
7465   ;;
7466 esac
7467 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
7468 ])
7469
7470 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
7471 # so we have to check/work around.  We do prefer the result of "eval"...
7472 eval cf_dst_eval="$cf_dst_path"
7473 case "x$cf_dst_eval" in
7474 (xNONE*)
7475         $3=$cf_dst_path
7476         ;;
7477 (*)
7478         $3="$cf_dst_eval"
7479         ;;
7480 esac
7481 AC_SUBST($3)dnl
7482
7483 ])dnl
7484 dnl ---------------------------------------------------------------------------
7485 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
7486 dnl -------------------------
7487 dnl Allow the choice of the pkg-config library directory to be overridden.
7488 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
7489
7490 case $PKG_CONFIG in
7491 (no|none|yes)
7492         AC_MSG_CHECKING(for pkg-config library directory)
7493         ;;
7494 (*)
7495         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
7496         ;;
7497 esac
7498
7499 PKG_CONFIG_LIBDIR=no
7500 AC_ARG_WITH(pkg-config-libdir,
7501         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
7502         [PKG_CONFIG_LIBDIR=$withval],
7503         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
7504
7505 case x$PKG_CONFIG_LIBDIR in
7506 (x/*)
7507         ;;
7508 (xyes)
7509         # Look for the library directory using the same prefix as the executable
7510         if test "x$PKG_CONFIG" = xnone
7511         then
7512                 cf_path=$prefix
7513         else
7514                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
7515         fi
7516
7517         # If you don't like using the default architecture, you have to specify the
7518         # intended library directory and corresponding compiler/linker options.
7519         #
7520         # This case allows for Debian's 2014-flavor of multiarch, along with the
7521         # most common variations before that point.  Some other variants spell the
7522         # directory differently, e.g., "pkg-config", and put it in unusual places.
7523         # pkg-config has always been poorly standardized, which is ironic...
7524         case x`(arch) 2>/dev/null` in
7525         (*64)
7526                 cf_search_path="\
7527                         $cf_path/lib/*64-linux-gnu \
7528                         $cf_path/share \
7529                         $cf_path/lib64 \
7530                         $cf_path/lib32 \
7531                         $cf_path/lib"
7532                 ;;
7533         (*)
7534                 cf_search_path="\
7535                         $cf_path/lib/*-linux-gnu \
7536                         $cf_path/share \
7537                         $cf_path/lib32 \
7538                         $cf_path/lib \
7539                         $cf_path/libdata"
7540                 ;;
7541         esac
7542
7543         CF_VERBOSE(list...)
7544         for cf_config in $cf_search_path
7545         do
7546                 CF_VERBOSE(checking $cf_config/pkgconfig)
7547                 if test -d $cf_config/pkgconfig
7548                 then
7549                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
7550                         AC_MSG_CHECKING(done)
7551                         break
7552                 fi
7553         done
7554         ;;
7555 (*)
7556         ;;
7557 esac
7558
7559 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
7560         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
7561 fi
7562
7563 AC_SUBST(PKG_CONFIG_LIBDIR)
7564 ])dnl
7565 dnl ---------------------------------------------------------------------------
7566 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
7567 dnl ---------------
7568 dnl Check for POSIX thread library.
7569 AC_DEFUN([CF_WITH_PTHREAD],
7570 [
7571 AC_MSG_CHECKING(if you want to link with the pthread library)
7572 AC_ARG_WITH(pthread,
7573         [  --with-pthread          use POSIX thread library],
7574         [with_pthread=$withval],
7575         [with_pthread=no])
7576 AC_MSG_RESULT($with_pthread)
7577
7578 if test "$with_pthread" != no ; then
7579         AC_CHECK_HEADER(pthread.h,[
7580         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
7581
7582         for cf_lib_pthread in pthread c_r
7583         do
7584             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
7585             cf_save_LIBS="$LIBS"
7586             CF_ADD_LIB($cf_lib_pthread)
7587             AC_TRY_LINK([
7588 #include <pthread.h>
7589 ],[
7590                 int rc = pthread_create(0,0,0,0);
7591                 int r2 = pthread_mutexattr_settype(0, 0);
7592 ],[with_pthread=yes],[with_pthread=no])
7593             LIBS="$cf_save_LIBS"
7594             AC_MSG_RESULT($with_pthread)
7595             test "$with_pthread" = yes && break
7596         done
7597
7598         if test "$with_pthread" = yes ; then
7599             CF_ADD_LIB($cf_lib_pthread)
7600             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
7601         else
7602             AC_MSG_ERROR(Cannot link with pthread library)
7603         fi
7604         ])
7605 fi
7606 ])
7607 dnl ---------------------------------------------------------------------------
7608 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
7609 dnl -------------------
7610 dnl Allow library's release-version to be overridden.  Generally this happens when a
7611 dnl packager has incremented the release-version past that used in the original package,
7612 dnl and wishes to keep doing this.
7613 dnl
7614 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
7615 dnl and {package}_MINOR symbols
7616 dnl symbol.
7617 AC_DEFUN([CF_WITH_REL_VERSION],[
7618 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
7619 AC_ARG_WITH(rel-version,
7620 [  --with-rel-version=XXX  override derived release version],
7621 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
7622  cf_cv_rel_version=$withval])
7623 ifelse($1,,[
7624  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
7625 ],[
7626  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
7627  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
7628  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
7629  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
7630 ])
7631 ])dnl
7632 dnl ---------------------------------------------------------------------------
7633 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
7634 dnl ----------------
7635 dnl If we can compile with sysmouse, make it available unless it is not wanted.
7636 AC_DEFUN([CF_WITH_SYSMOUSE],[
7637 # not everyone has "test -c"
7638 if test -c /dev/sysmouse 2>/dev/null ; then
7639 AC_MSG_CHECKING(if you want to use sysmouse)
7640 AC_ARG_WITH(sysmouse,
7641         [  --with-sysmouse         use sysmouse (FreeBSD console)],
7642         [cf_with_sysmouse=$withval],
7643         [cf_with_sysmouse=maybe])
7644         if test "$cf_with_sysmouse" != no ; then
7645         AC_TRY_COMPILE([
7646 #include <osreldate.h>
7647 #if (__FreeBSD_version >= 400017)
7648 #include <sys/consio.h>
7649 #include <sys/fbio.h>
7650 #else
7651 #include <machine/console.h>
7652 #endif
7653 ],[
7654         struct mouse_info the_mouse;
7655         ioctl(0, CONS_MOUSECTL, &the_mouse);
7656 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
7657         fi
7658 AC_MSG_RESULT($cf_with_sysmouse)
7659 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
7660 fi
7661 ])dnl
7662 dnl ---------------------------------------------------------------------------
7663 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
7664 dnl ---------------
7665 dnl For testing, override the derived host system-type which is used to decide
7666 dnl things such as the linker commands used to build shared libraries.  This is
7667 dnl normally chosen automatically based on the type of system which you are
7668 dnl building on.  We use it for testing the configure script.
7669 dnl
7670 dnl This is different from the --host option: it is used only for testing parts
7671 dnl of the configure script which would not be reachable with --host since that
7672 dnl relies on the build environment being real, rather than mocked up.
7673 AC_DEFUN([CF_WITH_SYSTYPE],[
7674 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
7675 AC_ARG_WITH(system-type,
7676         [  --with-system-type=XXX  test: override derived host system-type],
7677 [AC_MSG_WARN(overriding system type to $withval)
7678         cf_cv_system_name=$withval
7679         host_os=$withval
7680 ])
7681 ])dnl
7682 dnl ---------------------------------------------------------------------------
7683 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
7684 dnl ----------------
7685 AC_DEFUN([CF_WITH_VALGRIND],[
7686 CF_NO_LEAKS_OPTION(valgrind,
7687         [  --with-valgrind         test: use valgrind],
7688         [USE_VALGRIND])
7689 ])dnl
7690 dnl ---------------------------------------------------------------------------
7691 dnl CF_WITH_VERSIONED_SYMS version: 7 updated: 2015/10/24 20:50:26
7692 dnl ----------------------
7693 dnl Use this when building shared library with ELF, to markup symbols with the
7694 dnl version identifier from the given input file.  Generally that identifier is
7695 dnl the same as the SONAME at which the symbol was first introduced.
7696 dnl
7697 dnl $1 = basename of the ".map" file (default $PACKAGE)
7698 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
7699 [
7700 AC_MSG_CHECKING(if versioned-symbols file should be used)
7701 AC_ARG_WITH(versioned-syms,
7702         [  --with-versioned-syms=X markup versioned symbols using ld],
7703         [with_versioned_syms=$withval],
7704         [with_versioned_syms=no])
7705 if test "x$with_versioned_syms" = xyes
7706 then
7707         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
7708         AC_SUBST(PACKAGE)
7709 fi
7710 AC_MSG_RESULT($with_versioned_syms)
7711
7712 RESULTING_SYMS=
7713 VERSIONED_SYMS=
7714 WILDCARD_SYMS=
7715
7716 if test "x$with_versioned_syms" != xno
7717 then
7718         RESULTING_SYMS=$with_versioned_syms
7719         case "x$MK_SHARED_LIB" in
7720         (*-Wl,*)
7721                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
7722                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
7723                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7724                 ;;
7725         (*-dy\ *)
7726                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
7727                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
7728                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7729                 ;;
7730         (*)
7731                 AC_MSG_WARN(this system does not support versioned-symbols)
7732                 ;;
7733         esac
7734
7735         # Linux ld can selectively override scope, e.g., of symbols beginning with
7736         # "_" by first declaring some as global, and then using a wildcard to
7737         # declare the others as local.  Some other loaders cannot do this.  Check
7738         # by constructing a (very) simple shared library and inspecting its
7739         # symbols.
7740         if test "x$VERSIONED_SYMS" != "x"
7741         then
7742                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
7743                 WILDCARD_SYMS=no
7744
7745                 # make sources
7746                 rm -f conftest.*
7747
7748                 cat >conftest.ver <<EOF
7749 module_1.0 {
7750 global:
7751         globalf1;
7752 local:
7753         localf1;
7754 };
7755 module_2.0 {
7756 global:
7757         globalf2;
7758 local:
7759         localf2;
7760         _*;
7761 } module_1.0;
7762 submodule_1.0 {
7763 global:
7764         subglobalf1;
7765         _ismissing;
7766 local:
7767         sublocalf1;
7768 };
7769 submodule_2.0 {
7770 global:
7771         subglobalf2;
7772 local:
7773         sublocalf2;
7774         _*;
7775 } submodule_1.0;
7776 EOF
7777                 cat >conftest.$ac_ext <<EOF
7778 #line __oline__ "configure"
7779 int     _ismissing(void) { return 1; }
7780 int     _localf1(void) { return 1; }
7781 int     _localf2(void) { return 2; }
7782 int     globalf1(void) { return 1; }
7783 int     globalf2(void) { return 2; }
7784 int     _sublocalf1(void) { return 1; }
7785 int     _sublocalf2(void) { return 2; }
7786 int     subglobalf1(void) { return 1; }
7787 int     subglobalf2(void) { return 2; }
7788 EOF
7789                 cat >conftest.mk <<EOF
7790 CC=${CC}
7791 CFLAGS=${CFLAGS}
7792 CPPFLAGS=${CPPFLAGS}
7793 LDFLAGS=${LDFLAGS}
7794 LIBS=${LIBS}
7795 VERSIONED_SYMS=${VERSIONED_SYMS}
7796 RESULTING_SYMS=conftest.ver
7797 MK_SHARED_LIB=${MK_SHARED_LIB}
7798 conftest.so: conftest.$ac_cv_objext
7799                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
7800 EOF
7801
7802                 # compile source, make library
7803                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
7804                 then
7805                         # test for missing symbol in either Data or Text section
7806                         cf_missing=`nm -P conftest.so 2>&AC_FD_CC |fgrep _ismissing | egrep '[[         ]][[DT]][[      ]]'`
7807                         test -n "$cf_missing" && WILDCARD_SYMS=yes
7808                 fi
7809                 AC_MSG_RESULT($WILDCARD_SYMS)
7810                 rm -f conftest.*
7811         fi
7812 fi
7813 AC_SUBST(RESULTING_SYMS)
7814 AC_SUBST(VERSIONED_SYMS)
7815 AC_SUBST(WILDCARD_SYMS)
7816 ])dnl
7817 dnl ---------------------------------------------------------------------------
7818 dnl CF_XOPEN_SOURCE version: 50 updated: 2015/10/17 19:03:33
7819 dnl ---------------
7820 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
7821 dnl or adapt to the vendor's definitions to get equivalent functionality,
7822 dnl without losing the common non-POSIX features.
7823 dnl
7824 dnl Parameters:
7825 dnl     $1 is the nominal value for _XOPEN_SOURCE
7826 dnl     $2 is the nominal value for _POSIX_C_SOURCE
7827 AC_DEFUN([CF_XOPEN_SOURCE],[
7828 AC_REQUIRE([AC_CANONICAL_HOST])
7829
7830 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
7831 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
7832 cf_xopen_source=
7833
7834 case $host_os in
7835 (aix[[4-7]]*)
7836         cf_xopen_source="-D_ALL_SOURCE"
7837         ;;
7838 (cygwin|msys)
7839         cf_XOPEN_SOURCE=600
7840         ;;
7841 (darwin[[0-8]].*)
7842         cf_xopen_source="-D_APPLE_C_SOURCE"
7843         ;;
7844 (darwin*)
7845         cf_xopen_source="-D_DARWIN_C_SOURCE"
7846         cf_XOPEN_SOURCE=
7847         ;;
7848 (freebsd*|dragonfly*)
7849         # 5.x headers associate
7850         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
7851         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
7852         cf_POSIX_C_SOURCE=200112L
7853         cf_XOPEN_SOURCE=600
7854         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
7855         ;;
7856 (hpux11*)
7857         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
7858         ;;
7859 (hpux*)
7860         cf_xopen_source="-D_HPUX_SOURCE"
7861         ;;
7862 (irix[[56]].*)
7863         cf_xopen_source="-D_SGI_SOURCE"
7864         cf_XOPEN_SOURCE=
7865         ;;
7866 (linux*|gnu*|mint*|k*bsd*-gnu)
7867         CF_GNU_SOURCE
7868         ;;
7869 (minix*)
7870         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
7871         ;;
7872 (mirbsd*)
7873         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
7874         cf_XOPEN_SOURCE=
7875         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7876         ;;
7877 (netbsd*)
7878         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
7879         ;;
7880 (openbsd[[4-9]]*)
7881         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
7882         cf_xopen_source="-D_BSD_SOURCE"
7883         cf_XOPEN_SOURCE=600
7884         ;;
7885 (openbsd*)
7886         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
7887         ;;
7888 (os2*)
7889         cf_XOPEN_SOURCE=
7890         ;;
7891 (osf[[45]]*)
7892         cf_xopen_source="-D_OSF_SOURCE"
7893         ;;
7894 (nto-qnx*)
7895         cf_xopen_source="-D_QNX_SOURCE"
7896         ;;
7897 (sco*)
7898         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
7899         ;;
7900 (solaris2.*)
7901         cf_xopen_source="-D__EXTENSIONS__"
7902         cf_cv_xopen_source=broken
7903         ;;
7904 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
7905         cf_XOPEN_SOURCE=
7906         cf_POSIX_C_SOURCE=
7907         ;;
7908 (*)
7909         CF_TRY_XOPEN_SOURCE
7910         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7911         ;;
7912 esac
7913
7914 if test -n "$cf_xopen_source" ; then
7915         CF_ADD_CFLAGS($cf_xopen_source,true)
7916 fi
7917
7918 dnl In anything but the default case, we may have system-specific setting
7919 dnl which is still not guaranteed to provide all of the entrypoints that
7920 dnl _XOPEN_SOURCE would yield.
7921 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
7922         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
7923         AC_TRY_COMPILE([#include <stdlib.h>],[
7924 #ifndef _XOPEN_SOURCE
7925 make an error
7926 #endif],
7927         [cf_XOPEN_SOURCE_set=yes],
7928         [cf_XOPEN_SOURCE_set=no])
7929         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
7930         if test $cf_XOPEN_SOURCE_set = yes
7931         then
7932                 AC_TRY_COMPILE([#include <stdlib.h>],[
7933 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
7934 make an error
7935 #endif],
7936                 [cf_XOPEN_SOURCE_set_ok=yes],
7937                 [cf_XOPEN_SOURCE_set_ok=no])
7938                 if test $cf_XOPEN_SOURCE_set_ok = no
7939                 then
7940                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
7941                 fi
7942         else
7943                 CF_TRY_XOPEN_SOURCE
7944         fi
7945 fi
7946 ])