aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2015,2016 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.803 2016/12/31 17:09:35 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54         [AC_TRY_LINK([#include <langinfo.h>],
  55         [char* cs = nl_langinfo(CODESET);],
  56         am_cv_langinfo_codeset=yes,
  57         am_cv_langinfo_codeset=no)
  58         ])
  59         if test $am_cv_langinfo_codeset = yes; then
  60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62         fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  66 dnl ---------------
  67 dnl Provide configure-script defaults for different ncurses ABIs.
  68 AC_DEFUN([CF_ABI_DEFAULTS],[
  69 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  70 case x$cf_cv_abi_version in
  71 (x[[6789]])
  72         cf_dft_ext_colors=yes
  73         cf_dft_ext_const=yes
  74         cf_dft_ext_mouse=yes
  75         cf_dft_ext_putwin=yes
  76         cf_dft_ext_spfuncs=yes
  77         cf_dft_filter_syms=yes
  78         cf_dft_chtype=uint32_t
  79         cf_dft_mmask_t=uint32_t
  80         cf_dft_interop=yes
  81         cf_dft_tparm_arg=intptr_t
  82         cf_dft_with_lp64=yes
  83         ;;
  84 (*)
  85         cf_dft_ext_colors=no
  86         cf_dft_ext_const=no
  87         cf_dft_ext_mouse=no
  88         cf_dft_ext_putwin=no
  89         cf_dft_ext_spfuncs=no
  90         cf_dft_filter_syms=no
  91         cf_dft_chtype=auto
  92         cf_dft_mmask_t=auto
  93         cf_dft_interop=no
  94         cf_dft_tparm_arg=long
  95         cf_dft_with_lp64=no
  96         ;;
  97 esac
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 101 dnl ------------------
 102 dnl Conditionally generate script according to whether we're using a given autoconf.
 103 dnl
 104 dnl $1 = version to compare against
 105 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 106 dnl $3 = code to use if AC_ACVERSION is older than $1.
 107 define([CF_ACVERSION_CHECK],
 108 [
 109 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 110 ifdef([m4_version_compare],
 111 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 112 [CF_ACVERSION_COMPARE(
 113 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 114 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 115 dnl ---------------------------------------------------------------------------
 116 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 117 dnl --------------------
 118 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 119 dnl                      MAJOR2, MINOR2, TERNARY2,
 120 dnl                      PRINTABLE2, not FOUND, FOUND)
 121 define([CF_ACVERSION_COMPARE],
 122 [ifelse(builtin([eval], [$2 < $5]), 1,
 123 [ifelse([$8], , ,[$8])],
 124 [ifelse([$9], , ,[$9])])])dnl
 125 dnl ---------------------------------------------------------------------------
 126 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 127 dnl -------------------
 128 dnl Construct the list of include-options for the C programs in the Ada95
 129 dnl binding.
 130 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 131 [
 132 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 133 if test "$srcdir" != "."; then
 134         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 135 fi
 136 if test "$GCC" != yes; then
 137         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 138 elif test "$includedir" != "/usr/include"; then
 139         if test "$includedir" = '${prefix}/include' ; then
 140                 if test x$prefix != x/usr ; then
 141                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 142                 fi
 143         else
 144                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145         fi
 146 fi
 147 AC_SUBST(ACPPFLAGS)
 148 ])dnl
 149 dnl ---------------------------------------------------------------------------
 150 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 151 dnl ---------------
 152 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 153 AC_DEFUN([CF_ADD_ADAFLAGS],[
 154         ADAFLAGS="$ADAFLAGS $1"
 155         AC_SUBST(ADAFLAGS)
 156 ])dnl
 157 dnl ---------------------------------------------------------------------------
 158 dnl CF_ADD_CFLAGS version: 12 updated: 2015/04/12 15:39:00
 159 dnl -------------
 160 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 161 dnl The second parameter if given makes this macro verbose.
 162 dnl
 163 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 164 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 165 dnl confused by the quotes (which require backslashes to keep them usable).
 166 AC_DEFUN([CF_ADD_CFLAGS],
 167 [
 168 cf_fix_cppflags=no
 169 cf_new_cflags=
 170 cf_new_cppflags=
 171 cf_new_extra_cppflags=
 172
 173 for cf_add_cflags in $1
 174 do
 175 case $cf_fix_cppflags in
 176 (no)
 177         case $cf_add_cflags in
 178         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 179                 case $cf_add_cflags in
 180                 (-D*)
 181                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 182
 183                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 184                                 && test -z "${cf_tst_cflags}" \
 185                                 && cf_fix_cppflags=yes
 186
 187                         if test $cf_fix_cppflags = yes ; then
 188                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 189                                 continue
 190                         elif test "${cf_tst_cflags}" = "\"'" ; then
 191                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 192                                 continue
 193                         fi
 194                         ;;
 195                 esac
 196                 case "$CPPFLAGS" in
 197                 (*$cf_add_cflags)
 198                         ;;
 199                 (*)
 200                         case $cf_add_cflags in
 201                         (-D*)
 202                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 203                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 204                                 ;;
 205                         esac
 206                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 207                         ;;
 208                 esac
 209                 ;;
 210         (*)
 211                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 212                 ;;
 213         esac
 214         ;;
 215 (yes)
 216         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 217
 218         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 219
 220         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 221                 && test -z "${cf_tst_cflags}" \
 222                 && cf_fix_cppflags=no
 223         ;;
 224 esac
 225 done
 226
 227 if test -n "$cf_new_cflags" ; then
 228         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 229         CFLAGS="$CFLAGS $cf_new_cflags"
 230 fi
 231
 232 if test -n "$cf_new_cppflags" ; then
 233         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 234         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 235 fi
 236
 237 if test -n "$cf_new_extra_cppflags" ; then
 238         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 239         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 240 fi
 241
 242 AC_SUBST(EXTRA_CPPFLAGS)
 243
 244 ])dnl
 245 dnl ---------------------------------------------------------------------------
 246 dnl CF_ADD_INCDIR version: 14 updated: 2015/05/25 20:53:04
 247 dnl -------------
 248 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 249 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 250 dnl but old versions (and some misinstalled ones) need that.  To make things
 251 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 252 dnl the include-path).
 253 AC_DEFUN([CF_ADD_INCDIR],
 254 [
 255 if test -n "$1" ; then
 256   for cf_add_incdir in $1
 257   do
 258         while test $cf_add_incdir != /usr/include
 259         do
 260           if test -d $cf_add_incdir
 261           then
 262                 cf_have_incdir=no
 263                 if test -n "$CFLAGS$CPPFLAGS" ; then
 264                   # a loop is needed to ensure we can add subdirs of existing dirs
 265                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 266                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 267                           cf_have_incdir=yes; break
 268                         fi
 269                   done
 270                 fi
 271
 272                 if test "$cf_have_incdir" = no ; then
 273                   if test "$cf_add_incdir" = /usr/local/include ; then
 274                         if test "$GCC" = yes
 275                         then
 276                           cf_save_CPPFLAGS=$CPPFLAGS
 277                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 278                           AC_TRY_COMPILE([#include <stdio.h>],
 279                                   [printf("Hello")],
 280                                   [],
 281                                   [cf_have_incdir=yes])
 282                           CPPFLAGS=$cf_save_CPPFLAGS
 283                         fi
 284                   fi
 285                 fi
 286
 287                 if test "$cf_have_incdir" = no ; then
 288                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 289                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 290
 291                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 292                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 293                   cf_add_incdir="$cf_top_incdir"
 294                 else
 295                   break
 296                 fi
 297           else
 298                 break
 299           fi
 300         done
 301   done
 302 fi
 303 ])dnl
 304 dnl ---------------------------------------------------------------------------
 305 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 306 dnl ----------
 307 dnl Add a library, used to enforce consistency.
 308 dnl
 309 dnl $1 = library to add, without the "-l"
 310 dnl $2 = variable to update (default $LIBS)
 311 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 312 dnl ---------------------------------------------------------------------------
 313 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 314 dnl -------------
 315 dnl     Adds to the library-path
 316 dnl
 317 dnl     Some machines have trouble with multiple -L options.
 318 dnl
 319 dnl $1 is the (list of) directory(s) to add
 320 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 321 dnl
 322 AC_DEFUN([CF_ADD_LIBDIR],
 323 [
 324 if test -n "$1" ; then
 325         for cf_add_libdir in $1
 326         do
 327                 if test $cf_add_libdir = /usr/lib ; then
 328                         :
 329                 elif test -d $cf_add_libdir
 330                 then
 331                         cf_have_libdir=no
 332                         if test -n "$LDFLAGS$LIBS" ; then
 333                                 # a loop is needed to ensure we can add subdirs of existing dirs
 334                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 335                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 336                                                 cf_have_libdir=yes; break
 337                                         fi
 338                                 done
 339                         fi
 340                         if test "$cf_have_libdir" = no ; then
 341                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 342                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 343                         fi
 344                 fi
 345         done
 346 fi
 347 ])dnl
 348 dnl ---------------------------------------------------------------------------
 349 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 350 dnl -----------
 351 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 352 dnl prepended to an existing list, since their dependencies are assumed to
 353 dnl already exist in the list.
 354 dnl
 355 dnl $1 = libraries to add, with the "-l", etc.
 356 dnl $2 = variable to update (default $LIBS)
 357 AC_DEFUN([CF_ADD_LIBS],[
 358 cf_add_libs="$1"
 359 # Filter out duplicates - this happens with badly-designed ".pc" files...
 360 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 361 do
 362         for cf_add_2lib in $cf_add_libs
 363         do
 364                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 365                 then
 366                         cf_add_1lib=
 367                         break
 368                 fi
 369         done
 370         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 371 done
 372 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 373 ])dnl
 374 dnl ---------------------------------------------------------------------------
 375 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 376 dnl ------------------
 377 dnl Append to a search-list for a nonstandard header/lib-file
 378 dnl     $1 = the variable to return as result
 379 dnl     $2 = the package name
 380 dnl     $3 = the subdirectory, e.g., bin, include or lib
 381 dnl $4 = the directory under which we will test for subdirectories
 382 dnl $5 = a directory that we do not want $4 to match
 383 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 384 [
 385 test "x$4" != "x$5" && \
 386 test -d "$4" && \
 387 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 388         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 389         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 390         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 391         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 392         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 393         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 394 }
 395 ])dnl
 396 dnl ---------------------------------------------------------------------------
 397 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 398 dnl --------------
 399 dnl Allow user to disable a normally-on option.
 400 AC_DEFUN([CF_ARG_DISABLE],
 401 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 402 dnl ---------------------------------------------------------------------------
 403 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 404 dnl -------------
 405 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 406 dnl values.
 407 dnl
 408 dnl Parameters:
 409 dnl $1 = option name
 410 dnl $2 = help-string
 411 dnl $3 = action to perform if option is not default
 412 dnl $4 = action if perform if option is default
 413 dnl $5 = default option value (either 'yes' or 'no')
 414 AC_DEFUN([CF_ARG_OPTION],
 415 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 416         if test "$enableval" != "$5" ; then
 417 ifelse([$3],,[    :]dnl
 418 ,[    $3]) ifelse([$4],,,[
 419         else
 420                 $4])
 421         fi],[enableval=$5 ifelse([$4],,,[
 422         $4
 423 ])dnl
 424 ])])dnl
 425 dnl ---------------------------------------------------------------------------
 426 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 427 dnl -----------
 428 dnl Check for suitable "ar" (archiver) options for updating an archive.
 429 dnl
 430 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 431 dnl as well as a workaround for breakage of make's archive rules by the GNU
 432 dnl binutils "ar" program.
 433 AC_DEFUN([CF_AR_FLAGS],[
 434 AC_REQUIRE([CF_PROG_AR])
 435
 436 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 437         cf_cv_ar_flags=unknown
 438         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 439         do
 440
 441                 # check if $ARFLAGS already contains this choice
 442                 if test "x$ARFLAGS" != "x" ; then
 443                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 444                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 445                                 cf_cv_ar_flags=
 446                                 break
 447                         fi
 448                 fi
 449
 450                 rm -f conftest.$ac_cv_objext
 451                 rm -f conftest.a
 452
 453                 cat >conftest.$ac_ext <<EOF
 454 #line __oline__ "configure"
 455 int     testdata[[3]] = { 123, 456, 789 };
 456 EOF
 457                 if AC_TRY_EVAL(ac_compile) ; then
 458                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 459                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 460                         if test -f conftest.a ; then
 461                                 cf_cv_ar_flags=$cf_ar_flags
 462                                 break
 463                         fi
 464                 else
 465                         CF_VERBOSE(cannot compile test-program)
 466                         break
 467                 fi
 468         done
 469         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 470 ])
 471
 472 if test -n "$ARFLAGS" ; then
 473         if test -n "$cf_cv_ar_flags" ; then
 474                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 475         fi
 476 else
 477         ARFLAGS=$cf_cv_ar_flags
 478 fi
 479
 480 AC_SUBST(ARFLAGS)
 481 ])
 482 dnl ---------------------------------------------------------------------------
 483 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 484 dnl -----------------
 485 dnl Check if awk can handle big strings using printf.  Some older versions of
 486 dnl awk choke on large strings passed via "%s".
 487 dnl
 488 dnl $1 = desired string size
 489 dnl $2 = variable to set with result
 490 AC_DEFUN([CF_AWK_BIG_PRINTF],
 491 [
 492         case x$AWK in
 493         (x)
 494                 eval $2=no
 495                 ;;
 496         (*)
 497                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 498                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 499                         eval $2=yes
 500                 else
 501                         eval $2=no
 502                 fi
 503                 ;;
 504         esac
 505 ])dnl
 506 dnl ---------------------------------------------------------------------------
 507 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 508 dnl ------------
 509 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 510 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 511 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 512 dnl
 513 dnl Treat the configuration-variable specially here, since we're directly
 514 dnl substituting its value (i.e., 1/0).
 515 dnl
 516 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 517 AC_DEFUN([CF_BOOL_DECL],
 518 [
 519 AC_MSG_CHECKING(if we should include stdbool.h)
 520
 521 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 522         AC_TRY_COMPILE([],[bool foo = false],
 523                 [cf_cv_header_stdbool_h=0],
 524                 [AC_TRY_COMPILE([
 525 #ifndef __BEOS__
 526 #include <stdbool.h>
 527 #endif
 528 ],[bool foo = false],
 529                         [cf_cv_header_stdbool_h=1],
 530                         [cf_cv_header_stdbool_h=0])])])
 531
 532 if test "$cf_cv_header_stdbool_h" = 1
 533 then    AC_MSG_RESULT(yes)
 534 else    AC_MSG_RESULT(no)
 535 fi
 536
 537 AC_MSG_CHECKING([for builtin bool type])
 538
 539 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 540         AC_TRY_COMPILE([
 541 #include <stdio.h>
 542 #include <sys/types.h>
 543 ],[bool x = false],
 544                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 545                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 546         ])
 547
 548 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 549 then    AC_MSG_RESULT(yes)
 550 else    AC_MSG_RESULT(no)
 551 fi
 552 ])dnl
 553 dnl ---------------------------------------------------------------------------
 554 dnl CF_BOOL_SIZE version: 14 updated: 2015/04/17 21:13:04
 555 dnl ------------
 556 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 557 dnl Don't bother looking for bool.h, since it's been deprecated.
 558 dnl
 559 dnl If the current compiler is C rather than C++, we get the bool definition
 560 dnl from <stdbool.h>.
 561 AC_DEFUN([CF_BOOL_SIZE],
 562 [
 563 AC_MSG_CHECKING([for size of bool])
 564 AC_CACHE_VAL(cf_cv_type_of_bool,[
 565         rm -f cf_test.out
 566         AC_TRY_RUN([
 567 #include <stdlib.h>
 568 #include <stdio.h>
 569
 570 #if defined(__cplusplus)
 571
 572 #ifdef HAVE_GXX_BUILTIN_H
 573 #include <g++/builtin.h>
 574 #elif HAVE_GPP_BUILTIN_H
 575 #include <gpp/builtin.h>
 576 #elif HAVE_BUILTIN_H
 577 #include <builtin.h>
 578 #endif
 579
 580 #else
 581
 582 #if $cf_cv_header_stdbool_h
 583 #include <stdbool.h>
 584 #endif
 585
 586 #endif
 587
 588 int main()
 589 {
 590         FILE *fp = fopen("cf_test.out", "w");
 591         if (fp != 0) {
 592                 bool x = true;
 593                 if ((bool)(-x) >= 0)
 594                         fputs("unsigned ", fp);
 595                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 596                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 597                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 598                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 599                 fclose(fp);
 600         }
 601         ${cf_cv_main_return:-return}(0);
 602 }
 603                 ],
 604                 [cf_cv_type_of_bool=`cat cf_test.out`
 605                  if test -z "$cf_cv_type_of_bool"; then
 606                    cf_cv_type_of_bool=unknown
 607                  fi],
 608                 [cf_cv_type_of_bool=unknown],
 609                 [cf_cv_type_of_bool=unknown])
 610         ])
 611         rm -f cf_test.out
 612 AC_MSG_RESULT($cf_cv_type_of_bool)
 613 if test "$cf_cv_type_of_bool" = unknown ; then
 614         case .$NCURSES_BOOL in
 615         (.auto|.) NCURSES_BOOL=unsigned;;
 616         esac
 617         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 618         cf_cv_type_of_bool=$NCURSES_BOOL
 619 fi
 620 ])dnl
 621 dnl ---------------------------------------------------------------------------
 622 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 623 dnl -----------
 624 dnl If we're cross-compiling, allow the user to override the tools and their
 625 dnl options.  The configure script is oriented toward identifying the host
 626 dnl compiler, etc., but we need a build compiler to generate parts of the
 627 dnl source.
 628 dnl
 629 dnl $1 = default for $CPPFLAGS
 630 dnl $2 = default for $LIBS
 631 AC_DEFUN([CF_BUILD_CC],[
 632 CF_ACVERSION_CHECK(2.52,,
 633         [AC_REQUIRE([CF_PROG_EXT])])
 634 if test "$cross_compiling" = yes ; then
 635
 636         # defaults that we might want to override
 637         : ${BUILD_CFLAGS:=''}
 638         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 639         : ${BUILD_LDFLAGS:=''}
 640         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 641         : ${BUILD_EXEEXT:='$x'}
 642         : ${BUILD_OBJEXT:='o'}
 643
 644         AC_ARG_WITH(build-cc,
 645                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 646                 [BUILD_CC="$withval"],
 647                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 648         AC_MSG_CHECKING(for native build C compiler)
 649         AC_MSG_RESULT($BUILD_CC)
 650
 651         AC_MSG_CHECKING(for native build C preprocessor)
 652         AC_ARG_WITH(build-cpp,
 653                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 654                 [BUILD_CPP="$withval"],
 655                 [BUILD_CPP='${BUILD_CC} -E'])
 656         AC_MSG_RESULT($BUILD_CPP)
 657
 658         AC_MSG_CHECKING(for native build C flags)
 659         AC_ARG_WITH(build-cflags,
 660                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 661                 [BUILD_CFLAGS="$withval"])
 662         AC_MSG_RESULT($BUILD_CFLAGS)
 663
 664         AC_MSG_CHECKING(for native build C preprocessor-flags)
 665         AC_ARG_WITH(build-cppflags,
 666                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 667                 [BUILD_CPPFLAGS="$withval"])
 668         AC_MSG_RESULT($BUILD_CPPFLAGS)
 669
 670         AC_MSG_CHECKING(for native build linker-flags)
 671         AC_ARG_WITH(build-ldflags,
 672                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 673                 [BUILD_LDFLAGS="$withval"])
 674         AC_MSG_RESULT($BUILD_LDFLAGS)
 675
 676         AC_MSG_CHECKING(for native build linker-libraries)
 677         AC_ARG_WITH(build-libs,
 678                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 679                 [BUILD_LIBS="$withval"])
 680         AC_MSG_RESULT($BUILD_LIBS)
 681
 682         # this assumes we're on Unix.
 683         BUILD_EXEEXT=
 684         BUILD_OBJEXT=o
 685
 686         : ${BUILD_CC:='${CC}'}
 687
 688         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 689                 AC_MSG_ERROR([Cross-build requires two compilers.
 690 Use --with-build-cc to specify the native compiler.])
 691         fi
 692
 693 else
 694         : ${BUILD_CC:='${CC}'}
 695         : ${BUILD_CPP:='${CPP}'}
 696         : ${BUILD_CFLAGS:='${CFLAGS}'}
 697         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 698         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 699         : ${BUILD_LIBS:='${LIBS}'}
 700         : ${BUILD_EXEEXT:='$x'}
 701         : ${BUILD_OBJEXT:='o'}
 702 fi
 703
 704 AC_SUBST(BUILD_CC)
 705 AC_SUBST(BUILD_CPP)
 706 AC_SUBST(BUILD_CFLAGS)
 707 AC_SUBST(BUILD_CPPFLAGS)
 708 AC_SUBST(BUILD_LDFLAGS)
 709 AC_SUBST(BUILD_LIBS)
 710 AC_SUBST(BUILD_EXEEXT)
 711 AC_SUBST(BUILD_OBJEXT)
 712 ])dnl
 713 dnl ---------------------------------------------------------------------------
 714 dnl CF_CC_ENV_FLAGS version: 6 updated: 2016/08/29 20:57:00
 715 dnl ---------------
 716 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 717 dnl into CC.  This will not help with broken scripts that wrap the compiler
 718 dnl with options, but eliminates a more common category of user confusion.
 719 dnl
 720 dnl In particular, it addresses the problem of being able to run the C
 721 dnl preprocessor in a consistent manner.
 722 dnl
 723 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 724 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 725 dnl outweighs that limitation.
 726 AC_DEFUN([CF_CC_ENV_FLAGS],
 727 [
 728 # This should have been defined by AC_PROG_CC
 729 : ${CC:=cc}
 730
 731 AC_MSG_CHECKING(\$CC variable)
 732 case "$CC" in
 733 (*[[\ \ ]]-*)
 734         AC_MSG_RESULT(broken)
 735         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 736         # humor him...
 737         cf_flags=`echo "$CC" | sed -e 's/^.*[[  ]]\(-[[^        ]]\)/\1/'`
 738         CC=`echo "$CC " | sed -e 's/[[  ]]-[[^  ]].*$//' -e 's/[[       ]]*$//'`
 739         for cf_arg in $cf_flags
 740         do
 741                 case "x$cf_arg" in
 742                 (x-[[IUDfgOW]]*)
 743                         CF_ADD_CFLAGS($cf_flags)
 744                         ;;
 745                 (*)
 746                         CC="$CC $cf_arg"
 747                         ;;
 748                 esac
 749         done
 750         CF_VERBOSE(resulting CC: '$CC')
 751         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 752         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 753         ;;
 754 (*)
 755         AC_MSG_RESULT(ok)
 756         ;;
 757 esac
 758 ])dnl
 759 dnl ---------------------------------------------------------------------------
 760 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 761 dnl ---------------
 762 dnl Determine the default configuration into which we'll install ncurses.  This
 763 dnl can be overridden by the user's command-line options.  There's two items to
 764 dnl look for:
 765 dnl     1. the prefix (e.g., /usr)
 766 dnl     2. the header files (e.g., /usr/include/ncurses)
 767 dnl We'll look for a previous installation of ncurses and use the same defaults.
 768 dnl
 769 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 770 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 771 dnl programs from a vendor's.
 772 AC_DEFUN([CF_CFG_DEFAULTS],
 773 [
 774 AC_MSG_CHECKING(for prefix)
 775 if test "x$prefix" = "xNONE" ; then
 776         case "$cf_cv_system_name" in
 777                 # non-vendor systems don't have a conflict
 778         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 779                 prefix=/usr
 780                 ;;
 781         (*)     prefix=$ac_default_prefix
 782                 ;;
 783         esac
 784 fi
 785 AC_MSG_RESULT($prefix)
 786
 787 if test "x$prefix" = "xNONE" ; then
 788 AC_MSG_CHECKING(for default include-directory)
 789 test -n "$verbose" && echo 1>&AC_FD_MSG
 790 for cf_symbol in \
 791         $includedir \
 792         $includedir/ncurses \
 793         $prefix/include \
 794         $prefix/include/ncurses \
 795         /usr/local/include \
 796         /usr/local/include/ncurses \
 797         /usr/include \
 798         /usr/include/ncurses
 799 do
 800         cf_dir=`eval echo $cf_symbol`
 801         if test -f $cf_dir/curses.h ; then
 802         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 803                 includedir="$cf_symbol"
 804                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 805                 break
 806         fi
 807         fi
 808         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 809 done
 810 AC_MSG_RESULT($includedir)
 811 fi
 812 ])dnl
 813 dnl ---------------------------------------------------------------------------
 814 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
 815 dnl ----------
 816 dnl Check if the terminal-capability database functions are available.  If not,
 817 dnl ncurses has a much-reduced version.
 818 AC_DEFUN([CF_CGETENT],[
 819 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 820 AC_TRY_LINK([
 821 #include <stdlib.h>],[
 822         char temp[128];
 823         char *buf = temp;
 824         char *db_array = temp;
 825         cgetent(&buf, &db_array, "vt100");
 826         cgetcap(buf, "tc", '=');
 827         cgetmatch(buf, "tc");
 828         ],
 829         [cf_cv_cgetent=yes],
 830         [cf_cv_cgetent=no])
 831 ])
 832
 833 if test "$cf_cv_cgetent" = yes
 834 then
 835         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 836 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 837 AC_TRY_LINK([
 838 #include <stdlib.h>],[
 839         char temp[128];
 840         char *buf = temp;
 841 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 842         const char *db_array = temp;
 843         cgetent(&buf, &db_array, "vt100");
 844 #endif
 845         cgetcap(buf, "tc", '=');
 846         cgetmatch(buf, "tc");
 847         ],
 848         [cf_cv_cgetent_const=yes],
 849         [cf_cv_cgetent_const=no])
 850 ])
 851         if test "$cf_cv_cgetent_const" = yes
 852         then
 853                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 854         fi
 855 fi
 856 ])dnl
 857 dnl ---------------------------------------------------------------------------
 858 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 859 dnl --------------
 860 dnl Check if we're accidentally using a cache from a different machine.
 861 dnl Derive the system name, as a check for reusing the autoconf cache.
 862 dnl
 863 dnl If we've packaged config.guess and config.sub, run that (since it does a
 864 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 865 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 866 dnl which is useful in cross-compiles.
 867 dnl
 868 dnl Note: we would use $ac_config_sub, but that is one of the places where
 869 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 870 AC_DEFUN([CF_CHECK_CACHE],
 871 [
 872 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 873         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 874         system_name="$host_os"
 875 else
 876         system_name="`(uname -s -r) 2>/dev/null`"
 877         if test -z "$system_name" ; then
 878                 system_name="`(hostname) 2>/dev/null`"
 879         fi
 880 fi
 881 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 882 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 883
 884 test -z "$system_name" && system_name="$cf_cv_system_name"
 885 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 886
 887 if test ".$system_name" != ".$cf_cv_system_name" ; then
 888         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 889         AC_MSG_ERROR("Please remove config.cache and try again.")
 890 fi
 891 ])dnl
 892 dnl ---------------------------------------------------------------------------
 893 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
 894 dnl --------------
 895 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 896 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 897 dnl ourselves.
 898 dnl
 899 dnl $1 = the name to check
 900 dnl $2 = the assumed type
 901 AC_DEFUN([CF_CHECK_ERRNO],
 902 [
 903 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 904         AC_TRY_COMPILE([
 905 #ifdef HAVE_STDLIB_H
 906 #include <stdlib.h>
 907 #endif
 908 #include <stdio.h>
 909 #include <sys/types.h>
 910 #include <errno.h> ],
 911         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 912         [cf_cv_dcl_$1=yes],
 913         [cf_cv_dcl_$1=no])
 914 ])
 915
 916 if test "$cf_cv_dcl_$1" = no ; then
 917         CF_UPPER(cf_result,decl_$1)
 918         AC_DEFINE_UNQUOTED($cf_result)
 919 fi
 920
 921 # It's possible (for near-UNIX clones) that the data doesn't exist
 922 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 923 ])dnl
 924 dnl ---------------------------------------------------------------------------
 925 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
 926 dnl --------------------
 927 dnl Check for existence of external data in the current set of libraries.  If
 928 dnl we can modify it, it's real enough.
 929 dnl $1 = the name to check
 930 dnl $2 = its type
 931 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 932 [
 933 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 934         AC_TRY_LINK([
 935 #undef $1
 936 extern $2 $1;
 937 ],
 938         [$1 = 2],
 939         [cf_cv_have_$1=yes],
 940         [cf_cv_have_$1=no])
 941 ])
 942
 943 if test "$cf_cv_have_$1" = yes ; then
 944         CF_UPPER(cf_result,have_$1)
 945         AC_DEFINE_UNQUOTED($cf_result)
 946 fi
 947
 948 ])dnl
 949 dnl ---------------------------------------------------------------------------
 950 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 951 dnl -------------------
 952 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 953 dnl is not "weak" - warn about this because it can create problems linking
 954 dnl applications with ncurses.
 955 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 956 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 957
 958 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 959 cf_cv_check_gpm_wgetch=unknown
 960 if test "$cross_compiling" != yes ; then
 961
 962 cat >conftest.$ac_ext <<CF_EOF
 963 #include <gpm.h>
 964 int main()
 965 {
 966         Gpm_Wgetch();
 967         ${cf_cv_main_return:-return}(0);
 968 }
 969 CF_EOF
 970
 971         cf_save_LIBS="$LIBS"
 972         # This only works if we can look at the symbol table.  If a shared
 973         # library is stripped for install, we cannot use that.  So we're forced
 974         # to rely on the static library, noting that some packagers may not
 975         # include it.
 976         LIBS="-static -lgpm -dynamic $LIBS"
 977         if AC_TRY_EVAL(ac_compile) ; then
 978                 if AC_TRY_EVAL(ac_link) ; then
 979                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 980                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 981                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 982                 fi
 983         fi
 984         rm -rf conftest*
 985         LIBS="$cf_save_LIBS"
 986 fi
 987 ])
 988
 989 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 990         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 991 fi
 992 ])])dnl
 993 dnl ---------------------------------------------------------------------------
 994 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
 995 dnl ------------------------
 996 dnl Show the version of libtool
 997 dnl
 998 dnl Save the version in a cache variable - this is not entirely a good thing,
 999 dnl but the version string from libtool is very ugly, and for bug reports it
1000 dnl might be useful to have the original string.
1001 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1002 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1003 then
1004         AC_MSG_CHECKING(version of $LIBTOOL)
1005         CF_LIBTOOL_VERSION
1006         AC_MSG_RESULT($cf_cv_libtool_version)
1007         if test -z "$cf_cv_libtool_version" ; then
1008                 AC_MSG_ERROR(This is not GNU libtool)
1009         fi
1010 else
1011         AC_MSG_ERROR(GNU libtool has not been found)
1012 fi
1013 ])dnl
1014 dnl ---------------------------------------------------------------------------
1015 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
1016 dnl ----------------
1017 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1018 AC_DEFUN([CF_CHECK_WCHAR_H],[
1019 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1020 AC_TRY_COMPILE(
1021 [
1022 #include <stdlib.h>
1023 #include <wchar.h>
1024 ],[
1025         wint_t foo = 0;
1026         int bar = iswpunct(foo)],
1027         [cf_cv_wchar_h_okay=yes],
1028         [cf_cv_wchar_h_okay=no])])
1029
1030 if test $cf_cv_wchar_h_okay = no
1031 then
1032         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1033 fi
1034 ])dnl
1035 dnl ---------------------------------------------------------------------------
1036 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1037 dnl -------------------------
1038 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1039 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1040 dnl
1041 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1042 dnl all of those were combined into a page of useful graphics characters.
1043 dnl
1044 dnl So far, so good.
1045 dnl
1046 dnl However, while they are useful, there are other considerations.  CJK
1047 dnl is (because of poor device resolution) often rendered as double-width
1048 dnl characters.  So... for these generally-useful characters, what should
1049 dnl be the width (to make them consistent with adjacent characters)?
1050 dnl
1051 dnl The obvious choice would have been to make this locale-dependent, and use
1052 dnl wcwidth() to tell applications what the actual width is.  That was too
1053 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1054 dnl See for example
1055 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1056 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1057 dnl
1058 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1059 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1060 dnl instance, it lists half (44/96) of the Latin-1 characters as
1061 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1062 dnl
1063 dnl What this means for the implementor is that on some systems wcwidth() can
1064 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1065 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1066 dnl characters).  These do not necessarily match the behavior of the terminal
1067 dnl emulator.  xterm, for instance, does an optional startup check to find if
1068 dnl this problem (or similar) exists with the system's locale tables, rejecting
1069 dnl them if they are too unreliable.
1070 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1071 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1072 cat >conftest.in <<CF_EOF
1073 -       VT100 symbols
1074 0x250c  upper left corner
1075 0x2514  lower left corner
1076 0x2510  upper right corner
1077 0x2518  lower right corner
1078 0x251c  tee pointing left
1079 0x2524  tee pointing right
1080 0x2534  tee pointing up
1081 0x252c  tee pointing down
1082 0x2500  horizontal line
1083 0x2502  vertical line
1084 0x253c  large plus or crossover
1085 0x23ba  scan line 1
1086 0x23bd  scan line 9
1087 0x25c6  diamond
1088 0x2592  checker board (stipple)
1089 0x00b0  degree symbol
1090 0x00b1  plus/minus
1091 0x00b7  bullet
1092 -       Teletype 5410v1 symbols
1093 0x2190  arrow pointing left
1094 0x2192  arrow pointing right
1095 0x2193  arrow pointing down
1096 0x2191  arrow pointing up
1097 0x2592  board of squares
1098 0x2603  lantern symbol
1099 0x25ae  solid square block
1100 -       these defaults were invented for ncurses
1101 0x23bb  scan line 3
1102 0x23bc  scan line 7
1103 0x2264  less-than-or-equal-to
1104 0x2265  greater-than-or-equal-to
1105 0x03c0  greek pi
1106 0x2260  not-equal
1107 0x00a3  pound-sterling symbol
1108 -       thick-line-drawing
1109 0x250f  upper left corner
1110 0x2517  lower left corner
1111 0x2513  upper right corner
1112 0x251b  lower right corner
1113 0x2523  tee pointing left
1114 0x252b  tee pointing right
1115 0x253b  tee pointing up
1116 0x2533  tee pointing down
1117 0x2501  horizontal line
1118 0x2503  vertical line
1119 0x254b  large plus or crossover
1120 -       double-line-drawing
1121 0x2554  upper left corner
1122 0x255a  lower left corner
1123 0x2557  upper right corner
1124 0x255d  lower right corner
1125 0x2563  tee pointing left
1126 0x2560  tee pointing right
1127 0x2569  tee pointing up
1128 0x2566  tee pointing down
1129 0x2550  horizontal line
1130 0x2551  vertical line
1131 0x256c  large plus or crossover
1132 CF_EOF
1133 AC_TRY_RUN([
1134 #include <locale.h>
1135 #include <stdio.h>
1136 #include <wchar.h>
1137
1138 #define MY_LEN 80
1139
1140 int
1141 main(void)
1142 {
1143         FILE *fp;
1144         int value;
1145         char buffer[MY_LEN + 1];
1146         char notes[MY_LEN + 1];
1147         int totals = 0;
1148         int passed = 0;
1149
1150         if (setlocale(LC_ALL, "en_US.UTF8") ||
1151                 setlocale(LC_ALL, "en_US.UTF-8") ||
1152                 setlocale(LC_ALL, "en_US.utf8") ||
1153                 setlocale(LC_ALL, "en_US.utf-8")) {
1154                 if ((fp = fopen("conftest.in", "r")) != 0) {
1155                         while (fgets(buffer, MY_LEN, fp) != 0) {
1156                                 if (*buffer == '-') {
1157                                         fprintf(stderr, "\t%s", buffer);
1158                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1159                                         ++totals;
1160                                         if (wcwidth(value) == 1)
1161                                                 ++passed;
1162                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1163                                 } else {
1164                                         fprintf(stderr, "?\t%s", buffer);
1165                                 }
1166                         }
1167                 }
1168         }
1169         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1170         return (totals == passed) ? 0 : 1;
1171 }
1172 ],
1173 [cf_cv_wcwidth_graphics=yes],
1174 [cf_cv_wcwidth_graphics=no],
1175 [cf_cv_wcwidth_graphics=unknown])
1176 ])
1177 ])dnl
1178 dnl ---------------------------------------------------------------------------
1179 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1180 dnl -----------------
1181 dnl Check if the given compiler is really clang.  clang's C driver defines
1182 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1183 dnl not ignore some gcc options.
1184 dnl
1185 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1186 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1187 dnl the wrappers for gcc and g++ warnings.
1188 dnl
1189 dnl $1 = GCC (default) or GXX
1190 dnl $2 = CLANG_COMPILER (default)
1191 dnl $3 = CFLAGS (default) or CXXFLAGS
1192 AC_DEFUN([CF_CLANG_COMPILER],[
1193 ifelse([$2],,CLANG_COMPILER,[$2])=no
1194
1195 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1196         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1197         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1198         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1199         AC_TRY_COMPILE([],[
1200 #ifdef __clang__
1201 #else
1202 make an error
1203 #endif
1204 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1205 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1206 ],[])
1207         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1208         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1209 fi
1210 ])
1211 dnl ---------------------------------------------------------------------------
1212 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
1213 dnl -----------------
1214 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1215 dnl is a late feature for the standard and is not in some recent compilers
1216 dnl (1999/9/11).
1217 AC_DEFUN([CF_CPP_PARAM_INIT],
1218 [
1219 if test -n "$CXX"; then
1220 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1221         AC_LANG_SAVE
1222         AC_LANG_CPLUSPLUS
1223         AC_TRY_RUN([
1224 class TEST {
1225 private:
1226         int value;
1227 public:
1228         TEST(int x = 1);
1229         ~TEST();
1230 };
1231
1232 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1233 {
1234         value = x;
1235 }
1236 int main() { }
1237 ],
1238         [cf_cv_cpp_param_init=yes],
1239         [cf_cv_cpp_param_init=no],
1240         [cf_cv_cpp_param_init=unknown])
1241         AC_LANG_RESTORE
1242 ])
1243 fi
1244 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1245 ])dnl
1246 dnl ---------------------------------------------------------------------------
1247 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1248 dnl ------------------
1249 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1250 dnl not be supported in g++ before 3.0
1251 AC_DEFUN([CF_CPP_STATIC_CAST],
1252 [
1253 if test -n "$CXX"; then
1254
1255 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1256         AC_LANG_SAVE
1257         AC_LANG_CPLUSPLUS
1258
1259         AC_TRY_COMPILE([
1260 class NCursesPanel
1261 {
1262 public:
1263   NCursesPanel(int nlines,
1264                int ncols,
1265                int begin_y = 0,
1266                int begin_x = 0)
1267   {
1268   }
1269   NCursesPanel();
1270   ~NCursesPanel();
1271 };
1272
1273 template<class T> class NCursesUserPanel : public NCursesPanel
1274 {
1275 public:
1276   NCursesUserPanel (int nlines,
1277                     int ncols,
1278                     int begin_y = 0,
1279                     int begin_x = 0,
1280                     const T* p_UserData = static_cast<T*>(0))
1281     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1282   {
1283   };
1284   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1285   {
1286   };
1287
1288   virtual ~NCursesUserPanel() {};
1289 };
1290 ],[
1291         const char* p_UserData = static_cast<char*>(0)],
1292         [cf_cv_cpp_static_cast=yes],
1293         [cf_cv_cpp_static_cast=no])
1294
1295         AC_LANG_RESTORE
1296 ])
1297
1298 fi
1299
1300 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1301 ])dnl
1302 dnl ---------------------------------------------------------------------------
1303 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1304 dnl ---------------
1305 dnl Setup special archiver flags for given compilers.
1306 AC_DEFUN([CF_CXX_AR_FLAGS],[
1307         CXX_AR='$(AR)'
1308         CXX_ARFLAGS='$(ARFLAGS)'
1309         case $cf_cv_system_name in
1310         (irix*)
1311             if test "$GXX" != yes ; then
1312                 CXX_AR='$(CXX)'
1313                 CXX_ARFLAGS='-ar -o'
1314             fi
1315             ;;
1316         (sco3.2v5*)
1317             CXXLDFLAGS="-u main"
1318             ;;
1319         (solaris2*)
1320             if test "$GXX" != yes ; then
1321                 CXX_AR='$(CXX)'
1322                 CXX_ARFLAGS='-xar -o'
1323             fi
1324             ;;
1325         esac
1326         AC_SUBST(CXXLDFLAGS)
1327         AC_SUBST(CXX_AR)
1328         AC_SUBST(CXX_ARFLAGS)
1329 ])dnl
1330 dnl ---------------------------------------------------------------------------
1331 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1332 dnl -------------------------
1333 dnl For c++, check if iostream uses "std::" namespace.
1334 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1335 AC_CHECK_HEADERS(iostream)
1336 if test x"$ac_cv_header_iostream" = xyes ; then
1337         AC_MSG_CHECKING(if iostream uses std-namespace)
1338         AC_TRY_COMPILE([
1339 #include <iostream>
1340 using std::endl;
1341 using std::cerr;],[
1342 cerr << "testing" << endl;
1343 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1344         AC_MSG_RESULT($cf_iostream_namespace)
1345         if test "$cf_iostream_namespace" = yes ; then
1346                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1347         fi
1348 fi
1349 ])dnl
1350 dnl ---------------------------------------------------------------------------
1351 dnl CF_C_INLINE version: 5 updated: 2015/04/18 08:56:57
1352 dnl -----------
1353 dnl Check if the C compiler supports "inline".
1354 dnl $1 is the name of a shell variable to set if inline is supported
1355 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1356 AC_DEFUN([CF_C_INLINE],[
1357 AC_C_INLINE
1358 $1=
1359 if test "$ac_cv_c_inline" != no ; then
1360         $1=inline
1361         if test "$INTEL_COMPILER" = yes
1362         then
1363                 :
1364         elif test "$CLANG_COMPILER" = yes
1365         then
1366                 :
1367         elif test "$GCC" = yes
1368         then
1369                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1370                 cf_save_CFLAGS=$CFLAGS
1371                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1372                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1373                 [${cf_cv_main_return:-return} foo()],
1374                 [cf_cv_gcc_inline=yes],
1375                 [cf_cv_gcc_inline=no])
1376                 CFLAGS=$cf_save_CFLAGS
1377                 ])
1378                 if test "$cf_cv_gcc_inline" = yes ; then
1379                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1380                 fi
1381         fi
1382 fi
1383 AC_SUBST($1)
1384 ])dnl
1385 dnl ---------------------------------------------------------------------------
1386 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1387 dnl ----------
1388 dnl "dirname" is not portable, so we fake it with a shell script.
1389 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1390 dnl ---------------------------------------------------------------------------
1391 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1392 dnl ---------------
1393 AC_DEFUN([CF_DIRS_TO_MAKE],
1394 [
1395 DIRS_TO_MAKE="lib"
1396 for cf_item in $cf_list_models
1397 do
1398         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1399         for cf_item2 in $DIRS_TO_MAKE
1400         do
1401                 test $cf_item2 = $cf_subdir && break
1402         done
1403         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1404 done
1405 for cf_dir in $DIRS_TO_MAKE
1406 do
1407         test ! -d $cf_dir && mkdir $cf_dir
1408 done
1409 AC_SUBST(DIRS_TO_MAKE)
1410 ])dnl
1411 dnl ---------------------------------------------------------------------------
1412 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1413 dnl ---------------
1414 dnl You can always use "make -n" to see the actual options, but it's hard to
1415 dnl pick out/analyze warning messages when the compile-line is long.
1416 dnl
1417 dnl Sets:
1418 dnl     ECHO_LT - symbol to control if libtool is verbose
1419 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1420 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1421 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1422 dnl     ECHO_CC - symbol to put before any "cc" line
1423 dnl
1424 AC_DEFUN([CF_DISABLE_ECHO],[
1425 AC_MSG_CHECKING(if you want to see long compiling messages)
1426 CF_ARG_DISABLE(echo,
1427         [  --disable-echo          do not display "compiling" commands],
1428         [
1429         ECHO_LT='--silent'
1430         ECHO_LD='@echo linking [$]@;'
1431         RULE_CC='@echo compiling [$]<'
1432         SHOW_CC='@echo compiling [$]@'
1433         ECHO_CC='@'
1434 ],[
1435         ECHO_LT=''
1436         ECHO_LD=''
1437         RULE_CC=''
1438         SHOW_CC=''
1439         ECHO_CC=''
1440 ])
1441 AC_MSG_RESULT($enableval)
1442 AC_SUBST(ECHO_LT)
1443 AC_SUBST(ECHO_LD)
1444 AC_SUBST(RULE_CC)
1445 AC_SUBST(SHOW_CC)
1446 AC_SUBST(ECHO_CC)
1447 ])dnl
1448 dnl ---------------------------------------------------------------------------
1449 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1450 dnl ------------------------
1451 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1452 AC_MSG_CHECKING(if we want to use GNAT projects)
1453 CF_ARG_DISABLE(gnat-projects,
1454         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1455         [enable_gnat_projects=no],
1456         [enable_gnat_projects=yes])
1457 AC_MSG_RESULT($enable_gnat_projects)
1458 ])dnl
1459 dnl ---------------------------------------------------------------------------
1460 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1461 dnl ----------------
1462 dnl Combine no-leak checks with the libraries or tools that are used for the
1463 dnl checks.
1464 AC_DEFUN([CF_DISABLE_LEAKS],[
1465
1466 AC_REQUIRE([CF_WITH_DMALLOC])
1467 AC_REQUIRE([CF_WITH_DBMALLOC])
1468 AC_REQUIRE([CF_WITH_VALGRIND])
1469
1470 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1471 AC_ARG_ENABLE(leaks,
1472         [  --disable-leaks         test: free permanent memory, analyze leaks],
1473         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1474         : ${with_no_leaks:=no})
1475 AC_MSG_RESULT($with_no_leaks)
1476
1477 if test "$with_no_leaks" = yes ; then
1478         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1479         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1480 fi
1481 ])dnl
1482 dnl ---------------------------------------------------------------------------
1483 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1484 dnl --------------------------
1485 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1486 dnl the older "-version-info" feature.  The newer feature allows us to use
1487 dnl version numbering on shared libraries which make them compatible with
1488 dnl various systems.
1489 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1490 [
1491 AC_MSG_CHECKING(if libtool -version-number should be used)
1492 CF_ARG_DISABLE(libtool-version,
1493         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1494         [cf_libtool_version=no],
1495         [cf_libtool_version=yes])
1496 AC_MSG_RESULT($cf_libtool_version)
1497
1498 if test "$cf_libtool_version" = yes ; then
1499         LIBTOOL_VERSION="-version-number"
1500 else
1501         LIBTOOL_VERSION="-version-info"
1502         case "x$VERSION" in
1503         (x)
1504                 AC_MSG_WARN(VERSION was not set)
1505                 ;;
1506         (x*.*.*)
1507                 ABI_VERSION="$VERSION"
1508                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1509                 ;;
1510         (x*:*:*)
1511                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1512                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1513                 ;;
1514         (*)
1515                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1516                 ;;
1517         esac
1518 fi
1519
1520 AC_SUBST(ABI_VERSION)
1521 AC_SUBST(LIBTOOL_VERSION)
1522 ])dnl
1523 dnl ---------------------------------------------------------------------------
1524 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1525 dnl ---------------------
1526 dnl The rpath-hack makes it simpler to build programs, particularly with the
1527 dnl *BSD ports which may have essential libraries in unusual places.  But it
1528 dnl can interfere with building an executable for the base system.  Use this
1529 dnl option in that case.
1530 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1531 [
1532 AC_MSG_CHECKING(if rpath-hack should be disabled)
1533 CF_ARG_DISABLE(rpath-hack,
1534         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1535         [cf_disable_rpath_hack=yes],
1536         [cf_disable_rpath_hack=no])
1537 AC_MSG_RESULT($cf_disable_rpath_hack)
1538 if test "$cf_disable_rpath_hack" = no ; then
1539         CF_RPATH_HACK
1540 fi
1541 ])
1542 dnl ---------------------------------------------------------------------------
1543 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1544 dnl ------------------
1545 dnl This is the "--enable-pc-files" option, which is available if there is a
1546 dnl pkg-config configuration on the local machine.
1547 AC_DEFUN([CF_ENABLE_PC_FILES],[
1548 AC_REQUIRE([CF_PKG_CONFIG])
1549 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1550
1551 if test "x$PKG_CONFIG" != xnone
1552 then
1553         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1554 else
1555         AC_MSG_CHECKING(if we should install .pc files)
1556 fi
1557
1558 AC_ARG_ENABLE(pc-files,
1559         [  --enable-pc-files       generate and install .pc files for pkg-config],
1560         [enable_pc_files=$enableval],
1561         [enable_pc_files=no])
1562 AC_MSG_RESULT($enable_pc_files)
1563
1564 if test "x$enable_pc_files" != xno
1565 then
1566         MAKE_PC_FILES=
1567         case "x$PKG_CONFIG_LIBDIR" in
1568         (xno|xyes)
1569                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1570                 ;;
1571         (*)
1572                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1573                 ;;
1574         esac
1575 else
1576         MAKE_PC_FILES="#"
1577 fi
1578 AC_SUBST(MAKE_PC_FILES)
1579 ])dnl
1580 dnl ---------------------------------------------------------------------------
1581 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1582 dnl ---------------
1583 dnl Check if the rpath option should be used, setting cache variable
1584 dnl cf_cv_enable_rpath if so.
1585 AC_DEFUN([CF_ENABLE_RPATH],
1586 [
1587 AC_MSG_CHECKING(if rpath option should be used)
1588 AC_ARG_ENABLE(rpath,
1589 [  --enable-rpath          use rpath option when generating shared libraries],
1590 [cf_cv_enable_rpath=$enableval],
1591 [cf_cv_enable_rpath=no])
1592 AC_MSG_RESULT($cf_cv_enable_rpath)
1593 ])dnl
1594 dnl ---------------------------------------------------------------------------
1595 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
1596 dnl ----------------------
1597 dnl On a few platforms, the compiler and/or loader nags with untruthful
1598 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1599 dnl and implying that most uses of the recommended alternatives are correct.
1600 dnl
1601 dnl Factually speaking, no one has actually counted the number of uses of these
1602 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1603 dnl instances are meaningless compared to the hundreds of millions of lines of
1604 dnl existing C code.
1605 dnl
1606 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1607 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1608 dnl standard - but evolved through phases, and older implementations are likely
1609 dnl to yield surprising results, as documented in manpages on various systems.
1610 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1611 [
1612 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1613 AC_ARG_ENABLE(string-hacks,
1614         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1615         [with_string_hacks=$enableval],
1616         [with_string_hacks=no])
1617 AC_MSG_RESULT($with_string_hacks)
1618
1619 if test "x$with_string_hacks" = "xyes"; then
1620         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1621         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1622         AC_CHECK_FUNC(strlcat,[
1623                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1624                 ],[
1625                 AC_CHECK_LIB(bsd,strlcat,[
1626                         CF_ADD_LIB(bsd)
1627                         AC_CHECK_HEADERS(bsd/string.h)
1628                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1629                         ])
1630                 ])
1631         AC_CHECK_FUNCS( strlcpy snprintf )
1632 fi
1633 ])dnl
1634 dnl ---------------------------------------------------------------------------
1635 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1636 dnl --------
1637 dnl Check if 'errno' is declared in <errno.h>
1638 AC_DEFUN([CF_ERRNO],
1639 [
1640 CF_CHECK_ERRNO(errno)
1641 ])dnl
1642 dnl ---------------------------------------------------------------------------
1643 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1644 dnl ---------------
1645 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1646 dnl math.h and builtin.h, only for ncurses
1647 AC_DEFUN([CF_ETIP_DEFINES],
1648 [
1649 AC_MSG_CHECKING(for special defines needed for etip.h)
1650 cf_save_CXXFLAGS="$CXXFLAGS"
1651 cf_result="none"
1652
1653 # etip.h includes ncurses.h which includes ncurses_dll.h
1654 # But ncurses_dll.h is generated - fix here.
1655 test -d include || mkdir include
1656 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1657
1658 for cf_math in "" MATH_H
1659 do
1660 for cf_excp in "" MATH_EXCEPTION
1661 do
1662         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1663         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1664         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1665 AC_TRY_COMPILE([
1666 #include <etip.h.in>
1667 ],[],[
1668         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1669         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1670         cf_result="$cf_math $cf_excp"
1671         break 2
1672 ],[])
1673 done
1674 done
1675 AC_MSG_RESULT($cf_result)
1676 CXXFLAGS="$cf_save_CXXFLAGS"
1677 ])
1678 dnl ---------------------------------------------------------------------------
1679 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
1680 dnl ---------------
1681 dnl Find a library (specifically the linkage used in the code fragment),
1682 dnl searching for it if it is not already in the library path.
1683 dnl See also CF_ADD_SEARCHPATH.
1684 dnl
1685 dnl Parameters (4-on are optional):
1686 dnl     $1 = headers for library entrypoint
1687 dnl     $2 = code fragment for library entrypoint
1688 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1689 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1690 dnl     $5 = action to perform if not successful
1691 dnl     $6 = module name, if not the same as the library name
1692 dnl     $7 = extra libraries
1693 dnl
1694 dnl Sets these variables:
1695 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1696 dnl     $cf_cv_header_path_$3 - include-directory if needed
1697 dnl     $cf_cv_library_path_$3 - library-directory if needed
1698 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1699 AC_DEFUN([CF_FIND_LINKAGE],[
1700
1701 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1702 # will be set on completion of the AC_TRY_LINK below.
1703 cf_cv_header_path_$3=
1704 cf_cv_library_path_$3=
1705
1706 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1707
1708 cf_save_LIBS="$LIBS"
1709
1710 AC_TRY_LINK([$1],[$2],[
1711         cf_cv_find_linkage_$3=yes
1712         cf_cv_header_path_$3=/usr/include
1713         cf_cv_library_path_$3=/usr/lib
1714 ],[
1715
1716 LIBS="-l$3 $7 $cf_save_LIBS"
1717
1718 AC_TRY_LINK([$1],[$2],[
1719         cf_cv_find_linkage_$3=yes
1720         cf_cv_header_path_$3=/usr/include
1721         cf_cv_library_path_$3=/usr/lib
1722         cf_cv_library_file_$3="-l$3"
1723 ],[
1724         cf_cv_find_linkage_$3=no
1725         LIBS="$cf_save_LIBS"
1726
1727         CF_VERBOSE(find linkage for $3 library)
1728         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1729
1730         cf_save_CPPFLAGS="$CPPFLAGS"
1731         cf_test_CPPFLAGS="$CPPFLAGS"
1732
1733         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1734         for cf_cv_header_path_$3 in $cf_search
1735         do
1736                 if test -d $cf_cv_header_path_$3 ; then
1737                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1738                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1739                         AC_TRY_COMPILE([$1],[$2],[
1740                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1741                                 cf_cv_find_linkage_$3=maybe
1742                                 cf_test_CPPFLAGS="$CPPFLAGS"
1743                                 break],[
1744                                 CPPFLAGS="$cf_save_CPPFLAGS"
1745                                 ])
1746                 fi
1747         done
1748
1749         if test "$cf_cv_find_linkage_$3" = maybe ; then
1750
1751                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1752
1753                 cf_save_LIBS="$LIBS"
1754                 cf_save_LDFLAGS="$LDFLAGS"
1755
1756                 ifelse([$6],,,[
1757                 CPPFLAGS="$cf_test_CPPFLAGS"
1758                 LIBS="-l$3 $7 $cf_save_LIBS"
1759                 AC_TRY_LINK([$1],[$2],[
1760                         CF_VERBOSE(... found $3 library in system)
1761                         cf_cv_find_linkage_$3=yes])
1762                         CPPFLAGS="$cf_save_CPPFLAGS"
1763                         LIBS="$cf_save_LIBS"
1764                         ])
1765
1766                 if test "$cf_cv_find_linkage_$3" != yes ; then
1767                         CF_LIBRARY_PATH(cf_search,$3)
1768                         for cf_cv_library_path_$3 in $cf_search
1769                         do
1770                                 if test -d $cf_cv_library_path_$3 ; then
1771                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1772                                         CPPFLAGS="$cf_test_CPPFLAGS"
1773                                         LIBS="-l$3 $7 $cf_save_LIBS"
1774                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1775                                         AC_TRY_LINK([$1],[$2],[
1776                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1777                                         cf_cv_find_linkage_$3=yes
1778                                         cf_cv_library_file_$3="-l$3"
1779                                         break],[
1780                                         CPPFLAGS="$cf_save_CPPFLAGS"
1781                                         LIBS="$cf_save_LIBS"
1782                                         LDFLAGS="$cf_save_LDFLAGS"
1783                                         ])
1784                                 fi
1785                         done
1786                         CPPFLAGS="$cf_save_CPPFLAGS"
1787                         LDFLAGS="$cf_save_LDFLAGS"
1788                 fi
1789
1790         else
1791                 cf_cv_find_linkage_$3=no
1792         fi
1793         ],$7)
1794 ])
1795
1796 LIBS="$cf_save_LIBS"
1797
1798 if test "$cf_cv_find_linkage_$3" = yes ; then
1799 ifelse([$4],,[
1800         CF_ADD_INCDIR($cf_cv_header_path_$3)
1801         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1802         CF_ADD_LIB($3)
1803 ],[$4])
1804 else
1805 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1806 fi
1807 ])dnl
1808 dnl ---------------------------------------------------------------------------
1809 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
1810 dnl ------------------
1811 dnl Find an include-directory with the given leaf-name.  This is useful for
1812 dnl example with FreeBSD ports, which use this convention to distinguish
1813 dnl different versions of the same port.
1814 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1815         CF_SUBDIR_PATH(cf_search,$1,include)
1816         for cf_item in $cf_search
1817         do
1818                 case $cf_item in
1819                 (*/$1)
1820                         CF_ADD_INCDIR($cf_item)
1821                         ;;
1822                 esac
1823         done
1824 ])dnl
1825 dnl ---------------------------------------------------------------------------
1826 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
1827 dnl ------------------
1828 dnl Find a library-directory with the given leaf-name.  This is useful for
1829 dnl example with FreeBSD ports, which use this convention to distinguish
1830 dnl different versions of the same port.
1831 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1832         CF_SUBDIR_PATH(cf_search,$1,lib)
1833         for cf_item in $cf_search
1834         do
1835                 case $cf_item in
1836                 (*/$1)
1837                         CF_ADD_LIBDIR($cf_item)
1838                         ;;
1839                 esac
1840         done
1841 ])dnl
1842 dnl ---------------------------------------------------------------------------
1843 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1844 dnl -----------------
1845 dnl make ADAFLAGS consistent with CFLAGS
1846 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1847         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1848         case "$CFLAGS" in
1849         (*-g*)
1850                 CF_ADD_ADAFLAGS(-g)
1851                 ;;
1852         esac
1853         case "$CFLAGS" in
1854         (*-O*)
1855                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1856                 CF_ADD_ADAFLAGS($cf_O_flag)
1857                 ;;
1858         esac
1859         AC_MSG_RESULT($ADAFLAGS)
1860 ])dnl
1861 dnl ---------------------------------------------------------------------------
1862 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1863 dnl --------------
1864 dnl Forget that we saw the given tool.
1865 AC_DEFUN([CF_FORGET_TOOL],[
1866 unset ac_cv_prog_ac_ct_$1
1867 unset ac_ct_$1
1868 unset $1
1869 ])dnl
1870 dnl ---------------------------------------------------------------------------
1871 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
1872 dnl -------------
1873 dnl Test for dlsym() and related functions, as well as libdl.
1874 dnl
1875 dnl Sets
1876 dnl     $cf_have_dlsym
1877 dnl     $cf_have_libdl
1878 AC_DEFUN([CF_FUNC_DLSYM],[
1879 cf_have_dlsym=no
1880 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1881
1882 cf_have_libdl=no
1883 AC_CHECK_LIB(dl,dlsym,[
1884         cf_have_dlsym=yes
1885         cf_have_libdl=yes])])
1886
1887 if test "$cf_have_dlsym" = yes ; then
1888         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
1889
1890         AC_MSG_CHECKING(whether able to link to dl*() functions)
1891         AC_TRY_LINK([#include <dlfcn.h>],[
1892                 void *obj;
1893                 if ((obj = dlopen("filename", 0)) != 0) {
1894                         if (dlsym(obj, "symbolname") == 0) {
1895                         dlclose(obj);
1896                         }
1897                 }],[
1898                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1899                 AC_MSG_ERROR(Cannot link test program for libdl)])
1900         AC_MSG_RESULT(ok)
1901 else
1902         AC_MSG_ERROR(Cannot find dlsym function)
1903 fi
1904 ])
1905 dnl ---------------------------------------------------------------------------
1906 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1907 dnl ---------------
1908 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1909 dnl is found, add our own version of memmove to the list of objects.
1910 AC_DEFUN([CF_FUNC_MEMMOVE],
1911 [
1912 AC_CHECK_FUNC(memmove,,[
1913 AC_CHECK_FUNC(bcopy,[
1914         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1915                 AC_TRY_RUN([
1916 int main() {
1917         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1918         char temp[40];
1919         bcopy(data, temp, sizeof(data));
1920         bcopy(temp+10, temp, 15);
1921         bcopy(temp+5, temp+15, 10);
1922         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1923 }
1924                 ],
1925                 [cf_cv_good_bcopy=yes],
1926                 [cf_cv_good_bcopy=no],
1927                 [cf_cv_good_bcopy=unknown])
1928                 ])
1929         ],[cf_cv_good_bcopy=no])
1930         if test "$cf_cv_good_bcopy" = yes ; then
1931                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1932         else
1933                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1934         fi
1935 ])])dnl
1936 dnl ---------------------------------------------------------------------------
1937 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1938 dnl -----------------
1939 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1940 dnl AIX 4.x, provide a non-working version.
1941 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1942 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1943 AC_TRY_RUN([
1944 #include <stdio.h>
1945 #include <errno.h>
1946 #include <time.h>
1947
1948 #ifdef HAVE_SYS_TIME_H
1949 #include <sys/time.h>
1950 #endif
1951
1952 int main() {
1953         struct timespec ts1, ts2;
1954         int code;
1955         ts1.tv_sec  = 0;
1956         ts1.tv_nsec = 750000000;
1957         ts2.tv_sec  = 0;
1958         ts2.tv_nsec = 0;
1959         errno = 0;
1960         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1961         ${cf_cv_main_return:-return}(code != 0);
1962 }
1963 ],
1964         [cf_cv_func_nanosleep=yes],
1965         [cf_cv_func_nanosleep=no],
1966         [cf_cv_func_nanosleep=unknown])])
1967
1968 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1969 ])
1970 dnl ---------------------------------------------------------------------------
1971 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
1972 dnl ---------------
1973 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1974 dnl "util" library as well.
1975 AC_DEFUN([CF_FUNC_OPENPTY],
1976 [
1977 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1978 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1979         cf_save_LIBS="$LIBS"
1980         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
1981         for cf_header in pty.h libutil.h util.h
1982         do
1983         AC_TRY_LINK([
1984 #include <$cf_header>
1985 ],[
1986         int x = openpty((int *)0, (int *)0, (char *)0,
1987                                    (struct termios *)0, (struct winsize *)0);
1988 ],[
1989                 cf_cv_func_openpty=$cf_header
1990                 break
1991 ],[
1992                 cf_cv_func_openpty=no
1993 ])
1994         done
1995         LIBS="$cf_save_LIBS"
1996 ])
1997 ])dnl
1998 dnl ---------------------------------------------------------------------------
1999 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
2000 dnl ------------
2001 dnl See if the poll function really works.  Some platforms have poll(), but
2002 dnl it does not work for terminals or files.
2003 AC_DEFUN([CF_FUNC_POLL],[
2004 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
2005 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2006 AC_TRY_RUN([
2007 #include <stdlib.h>
2008 #include <stdio.h>
2009 #include <unistd.h>
2010 #include <fcntl.h>
2011 #ifdef HAVE_POLL_H
2012 #include <poll.h>
2013 #else
2014 #include <sys/poll.h>
2015 #endif
2016 int main(void) {
2017         struct pollfd myfds;
2018         int ret;
2019
2020         /* check for Darwin bug with respect to "devices" */
2021         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2022         if (myfds.fd < 0)
2023                 myfds.fd = 0;
2024         myfds.events = POLLIN;
2025         myfds.revents = 0;
2026
2027         ret = poll(&myfds, 1, 100);
2028
2029         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2030                 ret = -1;
2031         } else {
2032                 int fd = 0;
2033                 if (!isatty(fd)) {
2034                         fd = open("/dev/tty", 2);       /* O_RDWR */
2035                 }
2036 #ifdef HAVE_POSIX_OPENPT
2037                 if (fd < 0) {
2038                         fd = posix_openpt(O_RDWR);
2039                 }
2040 #endif
2041
2042                 if (fd >= 0) {
2043                         /* also check with standard input */
2044                         myfds.fd = fd;
2045                         myfds.events = POLLIN;
2046                         myfds.revents = 0;
2047                         ret = poll(&myfds, 1, 100);
2048                 } else {
2049                         ret = -1;
2050                 }
2051         }
2052         ${cf_cv_main_return:-return}(ret < 0);
2053 }],
2054         [cf_cv_working_poll=yes],
2055         [cf_cv_working_poll=no],
2056         [cf_cv_working_poll=unknown])])
2057 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2058 ])dnl
2059 dnl ---------------------------------------------------------------------------
2060 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2061 dnl ---------------
2062 dnl Some old/broken variations define tcgetattr() only as a macro in
2063 dnl termio(s).h
2064 AC_DEFUN([CF_FUNC_TERMIOS],[
2065 AC_REQUIRE([CF_STRUCT_TERMIOS])
2066 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2067 AC_TRY_LINK([
2068 #include <sys/types.h>
2069 #ifdef HAVE_UNISTD_H
2070 #include <unistd.h>
2071 #endif
2072 #ifdef HAVE_TERMIOS_H
2073 #include <termios.h>
2074 #define TTY struct termios
2075 #else
2076 #ifdef HAVE_TERMIO_H
2077 #include <termio.h>
2078 #define TTY struct termio
2079 #endif
2080 #endif
2081 ],[
2082 TTY foo;
2083 tcgetattr(1, &foo);],
2084 [cf_cv_have_tcgetattr=yes],
2085 [cf_cv_have_tcgetattr=no])])
2086 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2087 ])dnl
2088 dnl ---------------------------------------------------------------------------
2089 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2090 dnl ---------------
2091 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2092 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2093 dnl other functions.
2094 AC_DEFUN([CF_FUNC_VSSCANF],
2095 [
2096 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2097 AC_TRY_LINK([
2098 #include <stdarg.h>
2099 #include <stdio.h>],[
2100         va_list ap;
2101         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2102 AC_TRY_LINK([
2103 #include <stdarg.h>
2104 #include <stdio.h>],[
2105         FILE strbuf;
2106         char *str = "from";
2107
2108         strbuf._flag = _IOREAD;
2109         strbuf._ptr = strbuf._base = (unsigned char *) str;
2110         strbuf._cnt = strlen(str);
2111         strbuf._file = _NFILE;
2112         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2113 AC_TRY_LINK([
2114 #include <stdarg.h>
2115 #include <stdio.h>],[
2116         FILE strbuf;
2117         char *str = "from";
2118
2119         strbuf._flag = _IOREAD;
2120         strbuf._ptr = strbuf._base = (unsigned char *) str;
2121         strbuf._cnt = strlen(str);
2122         strbuf._file = _NFILE;
2123         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2124 cf_cv_func_vsscanf=no])])])])
2125
2126 case $cf_cv_func_vsscanf in
2127 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2128 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2129 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2130 esac
2131
2132 ])dnl
2133 dnl ---------------------------------------------------------------------------
2134 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
2135 dnl -----------------
2136 dnl Test for availability of useful gcc __attribute__ directives to quiet
2137 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2138 dnl to documentation, unrecognized directives cause older compilers to barf.
2139 AC_DEFUN([CF_GCC_ATTRIBUTES],
2140 [
2141 if test "$GCC" = yes
2142 then
2143 cat > conftest.i <<EOF
2144 #ifndef GCC_PRINTF
2145 #define GCC_PRINTF 0
2146 #endif
2147 #ifndef GCC_SCANF
2148 #define GCC_SCANF 0
2149 #endif
2150 #ifndef GCC_NORETURN
2151 #define GCC_NORETURN /* nothing */
2152 #endif
2153 #ifndef GCC_UNUSED
2154 #define GCC_UNUSED /* nothing */
2155 #endif
2156 EOF
2157 if test "$GCC" = yes
2158 then
2159         AC_CHECKING([for $CC __attribute__ directives])
2160 cat > conftest.$ac_ext <<EOF
2161 #line __oline__ "${as_me:-configure}"
2162 #include "confdefs.h"
2163 #include "conftest.h"
2164 #include "conftest.i"
2165 #if     GCC_PRINTF
2166 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2167 #else
2168 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2169 #endif
2170 #if     GCC_SCANF
2171 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2172 #else
2173 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2174 #endif
2175 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2176 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2177 extern void foo(void) GCC_NORETURN;
2178 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
2179 EOF
2180         cf_printf_attribute=no
2181         cf_scanf_attribute=no
2182         for cf_attribute in scanf printf unused noreturn
2183         do
2184                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2185                 cf_directive="__attribute__(($cf_attribute))"
2186                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2187
2188                 case $cf_attribute in
2189                 (printf)
2190                         cf_printf_attribute=yes
2191                         cat >conftest.h <<EOF
2192 #define GCC_$cf_ATTRIBUTE 1
2193 EOF
2194                         ;;
2195                 (scanf)
2196                         cf_scanf_attribute=yes
2197                         cat >conftest.h <<EOF
2198 #define GCC_$cf_ATTRIBUTE 1
2199 EOF
2200                         ;;
2201                 (*)
2202                         cat >conftest.h <<EOF
2203 #define GCC_$cf_ATTRIBUTE $cf_directive
2204 EOF
2205                         ;;
2206                 esac
2207
2208                 if AC_TRY_EVAL(ac_compile); then
2209                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2210                         cat conftest.h >>confdefs.h
2211                         case $cf_attribute in
2212                         (noreturn)
2213                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2214                                 ;;
2215                         (printf)
2216                                 cf_value='/* nothing */'
2217                                 if test "$cf_printf_attribute" != no ; then
2218                                         cf_value='__attribute__((format(printf,fmt,var)))'
2219                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2220                                 fi
2221                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2222                                 ;;
2223                         (scanf)
2224                                 cf_value='/* nothing */'
2225                                 if test "$cf_scanf_attribute" != no ; then
2226                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2227                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2228                                 fi
2229                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2230                                 ;;
2231                         (unused)
2232                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2233                                 ;;
2234                         esac
2235                 fi
2236         done
2237 else
2238         fgrep define conftest.i >>confdefs.h
2239 fi
2240 rm -rf conftest*
2241 fi
2242 ])dnl
2243 dnl ---------------------------------------------------------------------------
2244 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2245 dnl --------------
2246 dnl Find version of gcc
2247 AC_DEFUN([CF_GCC_VERSION],[
2248 AC_REQUIRE([AC_PROG_CC])
2249 GCC_VERSION=none
2250 if test "$GCC" = yes ; then
2251         AC_MSG_CHECKING(version of $CC)
2252         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2253         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2254         AC_MSG_RESULT($GCC_VERSION)
2255 fi
2256 ])dnl
2257 dnl ---------------------------------------------------------------------------
2258 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
2259 dnl ---------------
2260 dnl Check if the compiler supports useful warning options.  There's a few that
2261 dnl we don't use, simply because they're too noisy:
2262 dnl
2263 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2264 dnl     -Wredundant-decls (system headers make this too noisy)
2265 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2266 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2267 dnl             is enabled for ncurses using "--enable-const".
2268 dnl     -pedantic
2269 dnl
2270 dnl Parameter:
2271 dnl     $1 is an optional list of gcc warning flags that a particular
2272 dnl             application might want to use, e.g., "no-unused" for
2273 dnl             -Wno-unused
2274 dnl Special:
2275 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2276 dnl
2277 AC_DEFUN([CF_GCC_WARNINGS],
2278 [
2279 AC_REQUIRE([CF_GCC_VERSION])
2280 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2281 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2282
2283 cat > conftest.$ac_ext <<EOF
2284 #line __oline__ "${as_me:-configure}"
2285 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2286 EOF
2287
2288 if test "$INTEL_COMPILER" = yes
2289 then
2290 # The "-wdXXX" options suppress warnings:
2291 # remark #1419: external declaration in primary source file
2292 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2293 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2294 # remark #193: zero used for undefined preprocessing identifier
2295 # remark #593: variable "curs_sb_left_arrow" was set but never used
2296 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2297 # remark #869: parameter "tw" was never referenced
2298 # remark #981: operands are evaluated in unspecified order
2299 # warning #279: controlling expression is constant
2300
2301         AC_CHECKING([for $CC warning options])
2302         cf_save_CFLAGS="$CFLAGS"
2303         EXTRA_CFLAGS="-Wall"
2304         for cf_opt in \
2305                 wd1419 \
2306                 wd1683 \
2307                 wd1684 \
2308                 wd193 \
2309                 wd593 \
2310                 wd279 \
2311                 wd810 \
2312                 wd869 \
2313                 wd981
2314         do
2315                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2316                 if AC_TRY_EVAL(ac_compile); then
2317                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2318                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2319                 fi
2320         done
2321         CFLAGS="$cf_save_CFLAGS"
2322
2323 elif test "$GCC" = yes
2324 then
2325         AC_CHECKING([for $CC warning options])
2326         cf_save_CFLAGS="$CFLAGS"
2327         EXTRA_CFLAGS=
2328         cf_warn_CONST=""
2329         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2330         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2331         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2332         for cf_opt in W Wall \
2333                 Wbad-function-cast \
2334                 Wcast-align \
2335                 Wcast-qual \
2336                 Wdeclaration-after-statement \
2337                 Wextra \
2338                 Winline \
2339                 Wmissing-declarations \
2340                 Wmissing-prototypes \
2341                 Wnested-externs \
2342                 Wpointer-arith \
2343                 Wshadow \
2344                 Wstrict-prototypes \
2345                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2346         do
2347                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2348                 if AC_TRY_EVAL(ac_compile); then
2349                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2350                         case $cf_opt in
2351                         (Wcast-qual)
2352                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2353                                 ;;
2354                         (Winline)
2355                                 case $GCC_VERSION in
2356                                 ([[34]].*)
2357                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2358                                         continue;;
2359                                 esac
2360                                 ;;
2361                         (Wpointer-arith)
2362                                 case $GCC_VERSION in
2363                                 ([[12]].*)
2364                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2365                                         continue;;
2366                                 esac
2367                                 ;;
2368                         esac
2369                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2370                 fi
2371         done
2372         CFLAGS="$cf_save_CFLAGS"
2373 fi
2374 rm -rf conftest*
2375
2376 AC_SUBST(EXTRA_CFLAGS)
2377 ])dnl
2378 dnl ---------------------------------------------------------------------------
2379 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2380 dnl ----------------
2381 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2382 dnl unistd.h or (nonstandard) in getopt.h
2383 AC_DEFUN([CF_GETOPT_HEADER],
2384 [
2385 AC_HAVE_HEADERS(unistd.h getopt.h)
2386 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2387 cf_cv_getopt_header=none
2388 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2389 do
2390 AC_TRY_COMPILE([
2391 #include <$cf_header>],
2392 [int x = optind; char *y = optarg],
2393 [cf_cv_getopt_header=$cf_header
2394  break])
2395 done
2396 ])
2397 if test $cf_cv_getopt_header != none ; then
2398         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2399 fi
2400 if test $cf_cv_getopt_header = getopt.h ; then
2401         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2402 fi
2403 ])dnl
2404 dnl ---------------------------------------------------------------------------
2405 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2406 dnl -----------------
2407 AC_DEFUN([CF_GNATPREP_OPT_T],[
2408 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2409 cf_cv_gnatprep_opt_t=no
2410 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2411 ])
2412 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2413 AC_SUBST(GNATPREP_OPTS)
2414 ])dnl
2415 dnl ---------------------------------------------------------------------------
2416 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2417 dnl ----------------
2418 AC_DEFUN([CF_GNAT_GENERICS],
2419 [
2420 AC_REQUIRE([CF_GNAT_VERSION])
2421
2422 AC_MSG_CHECKING(if GNAT supports generics)
2423 case $cf_gnat_version in
2424 (3.[[1-9]]*|[[4-9]].*)
2425         cf_gnat_generics=yes
2426         ;;
2427 (*)
2428         cf_gnat_generics=no
2429         ;;
2430 esac
2431 AC_MSG_RESULT($cf_gnat_generics)
2432
2433 if test "$cf_gnat_generics" = yes
2434 then
2435         cf_compile_generics=generics
2436         cf_generic_objects="\${GENOBJS}"
2437 else
2438         cf_compile_generics=
2439         cf_generic_objects=
2440 fi
2441
2442 AC_SUBST(cf_compile_generics)
2443 AC_SUBST(cf_generic_objects)
2444 ])dnl
2445 dnl ---------------------------------------------------------------------------
2446 dnl CF_GNAT_PROJECTS version: 8 updated: 2015/04/17 21:13:04
2447 dnl ----------------
2448 dnl GNAT projects are configured with ".gpr" project files.
2449 dnl GNAT libraries are a further development, using the project feature.
2450 AC_DEFUN([CF_GNAT_PROJECTS],
2451 [
2452 AC_REQUIRE([CF_GNAT_VERSION])
2453 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2454
2455 cf_gnat_libraries=no
2456 cf_gnat_projects=no
2457
2458 if test "$enable_gnat_projects" != no ; then
2459 AC_MSG_CHECKING(if GNAT supports project files)
2460 case $cf_gnat_version in
2461 (3.[[0-9]]*)
2462         ;;
2463 (*)
2464         case $cf_cv_system_name in
2465         (cygwin*|msys*)
2466                 ;;
2467         (*)
2468                 mkdir conftest.src conftest.bin conftest.lib
2469                 cd conftest.src
2470                 rm -rf conftest* *~conftest*
2471                 cat >>library.gpr <<CF_EOF
2472 project Library is
2473   Kind := External ("LIB_KIND");
2474   for Library_Name use "ConfTest";
2475   for Object_Dir use ".";
2476   for Library_ALI_Dir use External("LIBRARY_DIR");
2477   for Library_Version use External ("SONAME");
2478   for Library_Kind use Kind;
2479   for Library_Dir use External("BUILD_DIR");
2480   Source_Dir := External ("SOURCE_DIR");
2481   for Source_Dirs use (Source_Dir);
2482 end Library;
2483 CF_EOF
2484                 cat >>confpackage.ads <<CF_EOF
2485 package ConfPackage is
2486    procedure conftest;
2487 end ConfPackage;
2488 CF_EOF
2489                 cat >>confpackage.adb <<CF_EOF
2490 with Text_IO;
2491 package body ConfPackage is
2492    procedure conftest is
2493    begin
2494       Text_IO.Put ("Hello World");
2495       Text_IO.New_Line;
2496    end conftest;
2497 end ConfPackage;
2498 CF_EOF
2499                 if ( $cf_ada_make $ADAFLAGS \
2500                                 -Plibrary.gpr \
2501                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2502                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2503                                 -XSOURCE_DIR=`pwd` \
2504                                 -XSONAME=libConfTest.so.1 \
2505                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2506                         cf_gnat_projects=yes
2507                 fi
2508                 cd ..
2509                 if test -f conftest.lib/confpackage.ali
2510                 then
2511                         cf_gnat_libraries=yes
2512                 fi
2513                 rm -rf conftest* *~conftest*
2514                 ;;
2515         esac
2516         ;;
2517 esac
2518 AC_MSG_RESULT($cf_gnat_projects)
2519 fi # enable_gnat_projects
2520
2521 if test $cf_gnat_projects = yes
2522 then
2523         AC_MSG_CHECKING(if GNAT supports libraries)
2524         AC_MSG_RESULT($cf_gnat_libraries)
2525 fi
2526
2527 if test "$cf_gnat_projects" = yes
2528 then
2529         USE_OLD_MAKERULES="#"
2530         USE_GNAT_PROJECTS=""
2531 else
2532         USE_OLD_MAKERULES=""
2533         USE_GNAT_PROJECTS="#"
2534 fi
2535
2536 if test "$cf_gnat_libraries" = yes
2537 then
2538         USE_GNAT_LIBRARIES=""
2539 else
2540         USE_GNAT_LIBRARIES="#"
2541 fi
2542
2543 AC_SUBST(USE_OLD_MAKERULES)
2544 AC_SUBST(USE_GNAT_PROJECTS)
2545 AC_SUBST(USE_GNAT_LIBRARIES)
2546 ])dnl
2547 dnl ---------------------------------------------------------------------------
2548 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2549 dnl --------------
2550 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2551 dnl is noted that gnat may compile a tasking unit even for configurations which
2552 dnl fail at runtime.
2553 AC_DEFUN([CF_GNAT_SIGINT],[
2554 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2555 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2556
2557 package ConfTest is
2558
2559    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2560    pragma Unreserve_All_Interrupts;
2561    pragma Warnings (On);
2562
2563    protected Process is
2564       procedure Stop;
2565       function Continue return Boolean;
2566       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2567    private
2568       Done : Boolean := False;
2569    end Process;
2570
2571 end ConfTest;],
2572 [package body ConfTest is
2573    protected body Process is
2574       procedure Stop is
2575       begin
2576          Done := True;
2577       end Stop;
2578       function Continue return Boolean is
2579       begin
2580          return not Done;
2581       end Continue;
2582    end Process;
2583 end ConfTest;],
2584         [cf_cv_gnat_sigint=yes],
2585         [cf_cv_gnat_sigint=no])])
2586
2587 if test $cf_cv_gnat_sigint = yes ; then
2588         USE_GNAT_SIGINT=""
2589 else
2590         USE_GNAT_SIGINT="#"
2591 fi
2592 AC_SUBST(USE_GNAT_SIGINT)
2593 ])dnl
2594 dnl ---------------------------------------------------------------------------
2595 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2596 dnl ----------------
2597 dnl Verify that a test program compiles/links with GNAT.
2598 dnl $cf_ada_make is set to the program that compiles/links
2599 dnl $ADAFLAGS may be set to the GNAT flags.
2600 dnl
2601 dnl $1 is the text of the spec
2602 dnl $2 is the text of the body
2603 dnl $3 is the shell command to execute if successful
2604 dnl $4 is the shell command to execute if not successful
2605 AC_DEFUN([CF_GNAT_TRY_LINK],
2606 [
2607 rm -rf conftest* *~conftest*
2608 cat >>conftest.ads <<CF_EOF
2609 $1
2610 CF_EOF
2611 cat >>conftest.adb <<CF_EOF
2612 $2
2613 CF_EOF
2614 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2615 ifelse($3,,      :,[      $3])
2616 ifelse($4,,,[else
2617    $4])
2618 fi
2619 rm -rf conftest* *~conftest*
2620 ])dnl
2621 dnl ---------------------------------------------------------------------------
2622 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2623 dnl ---------------
2624 dnl Verify that a test program compiles and runs with GNAT
2625 dnl $cf_ada_make is set to the program that compiles/links
2626 dnl $ADAFLAGS may be set to the GNAT flags.
2627 dnl
2628 dnl $1 is the text of the spec
2629 dnl $2 is the text of the body
2630 dnl $3 is the shell command to execute if successful
2631 dnl $4 is the shell command to execute if not successful
2632 AC_DEFUN([CF_GNAT_TRY_RUN],
2633 [
2634 rm -rf conftest* *~conftest*
2635 cat >>conftest.ads <<CF_EOF
2636 $1
2637 CF_EOF
2638 cat >>conftest.adb <<CF_EOF
2639 $2
2640 CF_EOF
2641 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2642    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2643 ifelse($3,,      :,[      $3])
2644 ifelse($4,,,[   else
2645       $4])
2646    fi
2647 ifelse($4,,,[else
2648    $4])
2649 fi
2650 rm -rf conftest* *~conftest*
2651 ])dnl
2652 dnl ---------------------------------------------------------------------------
2653 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
2654 dnl ---------------
2655 dnl Verify version of GNAT.
2656 AC_DEFUN([CF_GNAT_VERSION],
2657 [
2658 AC_MSG_CHECKING(for gnat version)
2659 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2660         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2661         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2662 AC_MSG_RESULT($cf_gnat_version)
2663
2664 case $cf_gnat_version in
2665 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
2666         cf_cv_prog_gnat_correct=yes
2667         ;;
2668 (*)
2669         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2670         cf_cv_prog_gnat_correct=no
2671         ;;
2672 esac
2673 ])
2674 dnl ---------------------------------------------------------------------------
2675 dnl CF_GNU_SOURCE version: 7 updated: 2016/08/05 05:15:37
2676 dnl -------------
2677 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2678 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2679 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2680 dnl since it is interwoven with GNU extensions.
2681 dnl
2682 dnl Well, yes we could work around it...
2683 AC_DEFUN([CF_GNU_SOURCE],
2684 [
2685 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2686 AC_TRY_COMPILE([#include <sys/types.h>],[
2687 #ifndef _XOPEN_SOURCE
2688 make an error
2689 #endif],
2690         [cf_cv_gnu_source=no],
2691         [cf_save="$CPPFLAGS"
2692          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2693          AC_TRY_COMPILE([#include <sys/types.h>],[
2694 #ifdef _XOPEN_SOURCE
2695 make an error
2696 #endif],
2697         [cf_cv_gnu_source=no],
2698         [cf_cv_gnu_source=yes])
2699         CPPFLAGS="$cf_save"
2700         ])
2701 ])
2702
2703 if test "$cf_cv_gnu_source" = yes
2704 then
2705 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
2706 CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2707         AC_TRY_COMPILE([#include <sys/types.h>],[
2708 #ifdef _DEFAULT_SOURCE
2709 make an error
2710 #endif],
2711                 [cf_cv_default_source=no],
2712                 [cf_cv_default_source=yes])
2713         ])
2714 test "$cf_cv_default_source" = yes && CPPFLAGS="$CPPFLAGS -D_DEFAULT_SOURCE"
2715 fi
2716 ])dnl
2717 dnl ---------------------------------------------------------------------------
2718 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
2719 dnl --------------
2720 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2721 dnl problem :-).  If we have the compiler but no library, we'll be able to
2722 dnl configure, but won't be able to build the c++ demo program.
2723 AC_DEFUN([CF_GPP_LIBRARY],
2724 [
2725 cf_cxx_library=unknown
2726 case $cf_cv_system_name in
2727 (os2*)
2728         cf_gpp_libname=gpp
2729         ;;
2730 (*)
2731         cf_gpp_libname=g++
2732         ;;
2733 esac
2734 if test "$GXX" = yes; then
2735         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2736         cf_save="$LIBS"
2737         CF_ADD_LIB($cf_gpp_libname)
2738         AC_TRY_LINK([
2739 #include <$cf_gpp_libname/builtin.h>
2740         ],
2741         [two_arg_error_handler_t foo2 = lib_error_handler],
2742         [cf_cxx_library=yes
2743          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2744          if test "$cf_gpp_libname" = cpp ; then
2745             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2746          else
2747             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2748          fi],
2749         [AC_TRY_LINK([
2750 #include <builtin.h>
2751         ],
2752         [two_arg_error_handler_t foo2 = lib_error_handler],
2753         [cf_cxx_library=yes
2754          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2755          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2756         [cf_cxx_library=no])])
2757         LIBS="$cf_save"
2758         AC_MSG_RESULT($cf_cxx_library)
2759 fi
2760 ])dnl
2761 dnl ---------------------------------------------------------------------------
2762 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2763 dnl --------------
2764 dnl Check for version of g++
2765 AC_DEFUN([CF_GXX_VERSION],[
2766 AC_REQUIRE([AC_PROG_CPP])
2767 GXX_VERSION=none
2768 if test "$GXX" = yes; then
2769         AC_MSG_CHECKING(version of ${CXX:-g++})
2770         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2771         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2772         AC_MSG_RESULT($GXX_VERSION)
2773 fi
2774 ])dnl
2775 dnl ---------------------------------------------------------------------------
2776 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
2777 dnl ---------------
2778 dnl Check if the compiler supports useful warning options.
2779 dnl
2780 dnl Most of gcc's options apply to g++, except:
2781 dnl     -Wbad-function-cast
2782 dnl     -Wmissing-declarations
2783 dnl     -Wnested-externs
2784 dnl
2785 dnl Omit a few (for now):
2786 dnl     -Winline
2787 dnl
2788 dnl Parameter:
2789 dnl     $1 is an optional list of g++ warning flags that a particular
2790 dnl             application might want to use, e.g., "no-unused" for
2791 dnl             -Wno-unused
2792 dnl Special:
2793 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2794 dnl
2795 AC_DEFUN([CF_GXX_WARNINGS],
2796 [
2797
2798 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2799 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2800
2801 AC_REQUIRE([CF_GXX_VERSION])
2802
2803 AC_LANG_SAVE
2804 AC_LANG_CPLUSPLUS
2805
2806 cat > conftest.$ac_ext <<EOF
2807 #line __oline__ "configure"
2808 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2809 EOF
2810
2811 if test "$INTEL_CPLUSPLUS" = yes
2812 then
2813 # The "-wdXXX" options suppress warnings:
2814 # remark #1419: external declaration in primary source file
2815 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2816 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2817 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2818 # remark #193: zero used for undefined preprocessing identifier
2819 # remark #593: variable "curs_sb_left_arrow" was set but never used
2820 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2821 # remark #869: parameter "tw" was never referenced
2822 # remark #981: operands are evaluated in unspecified order
2823 # warning #269: invalid format string conversion
2824
2825         AC_CHECKING([for $CC warning options])
2826         cf_save_CXXFLAGS="$CXXFLAGS"
2827         EXTRA_CXXFLAGS="-Wall"
2828         for cf_opt in \
2829                 wd1419 \
2830                 wd1682 \
2831                 wd1683 \
2832                 wd1684 \
2833                 wd193 \
2834                 wd279 \
2835                 wd593 \
2836                 wd810 \
2837                 wd869 \
2838                 wd981
2839         do
2840                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2841                 if AC_TRY_EVAL(ac_compile); then
2842                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2843                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2844                 fi
2845         done
2846         CXXFLAGS="$cf_save_CXXFLAGS"
2847
2848 elif test "$GXX" = yes
2849 then
2850         AC_CHECKING([for $CXX warning options])
2851         cf_save_CXXFLAGS="$CXXFLAGS"
2852         EXTRA_CXXFLAGS="-W -Wall"
2853         cf_gxx_extra_warnings=""
2854         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2855         case "$GCC_VERSION" in
2856         ([[1-2]].*)
2857                 ;;
2858         (*)
2859                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2860                 ;;
2861         esac
2862         for cf_opt in \
2863                 Wabi \
2864                 fabi-version=0 \
2865                 Wextra \
2866                 Wignored-qualifiers \
2867                 Wlogical-op \
2868                 Woverloaded-virtual \
2869                 Wsign-promo \
2870                 Wsynth \
2871                 Wold-style-cast \
2872                 Wcast-align \
2873                 Wcast-qual \
2874                 Wpointer-arith \
2875                 Wshadow \
2876                 Wundef $cf_gxx_extra_warnings $1
2877         do
2878                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2879                 if AC_TRY_EVAL(ac_compile); then
2880                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2881                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2882                 else
2883                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2884                 fi
2885         done
2886         CXXFLAGS="$cf_save_CXXFLAGS"
2887 fi
2888
2889 rm -rf conftest*
2890 AC_LANG_RESTORE
2891 AC_SUBST(EXTRA_CXXFLAGS)
2892 ])dnl
2893 dnl ---------------------------------------------------------------------------
2894 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
2895 dnl ------------
2896 dnl Look for an instance of the Berkeley hashed database.
2897 dnl
2898 dnl $1 = optional parameter, to specify install-prefix for the database.
2899 AC_DEFUN([CF_HASHED_DB],
2900 [
2901 ifelse([$1],,,[
2902 case $1 in
2903 (yes|*able*)
2904         ;;
2905 (*)
2906         if test -d "$1" ; then
2907                 CF_ADD_INCDIR($1/include)
2908                 CF_ADD_LIBDIR($1/lib)
2909         else
2910                 case "$1" in
2911                 (./*|../*|/*)
2912                         AC_MSG_WARN(no such directory $1)
2913                         ;;
2914                 (*)
2915                         CF_FIND_SUB_INCDIR($1)
2916                         CF_FIND_SUB_LIBDIR($1)
2917                         ;;
2918                 esac
2919         fi
2920 esac
2921 ])
2922 AC_CHECK_HEADER(db.h,[
2923 CF_HASHED_DB_VERSION
2924 if test "$cf_cv_hashed_db_version" = unknown ; then
2925         AC_MSG_ERROR(Cannot determine version of db)
2926 else
2927         CF_HASHED_DB_LIBS
2928         if test "$cf_cv_hashed_db_libs" = unknown ; then
2929                 AC_MSG_ERROR(Cannot determine library for db)
2930         elif test "$cf_cv_hashed_db_libs" != default ; then
2931                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2932         fi
2933 fi
2934 ],[
2935         AC_MSG_ERROR(Cannot find db.h)
2936 ])
2937 ])dnl
2938 dnl ---------------------------------------------------------------------------
2939 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2940 dnl -----------------
2941 dnl Given that we have the header and version for hashed database, find the
2942 dnl library information.
2943 AC_DEFUN([CF_HASHED_DB_LIBS],
2944 [
2945 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2946 cf_cv_hashed_db_libs=unknown
2947 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2948 do
2949         cf_save_libs="$LIBS"
2950         if test -n "$cf_db_libs"; then
2951                 CF_ADD_LIB($cf_db_libs)
2952         fi
2953         CF_MSG_LOG(checking for library "$cf_db_libs")
2954         AC_TRY_LINK([
2955 $ac_includes_default
2956 #include <db.h>
2957 ],[
2958         char *path = "/tmp/foo";
2959 #ifdef DB_VERSION_MAJOR
2960 #if DB_VERSION_MAJOR >= 4
2961         DB *result = 0;
2962         db_create(&result, NULL, 0);
2963         result->open(result,
2964                 NULL,
2965                 path,
2966                 path,
2967                 DB_HASH,
2968                 DB_CREATE,
2969                 0644);
2970 #elif DB_VERSION_MAJOR >= 3
2971         DB *result = 0;
2972         db_create(&result, NULL, 0);
2973         result->open(result,
2974                 path,
2975                 path,
2976                 DB_HASH,
2977                 DB_CREATE,
2978                 0644);
2979 #elif DB_VERSION_MAJOR >= 2
2980         DB *result = 0;
2981         db_open(path,
2982                 DB_HASH,
2983                 DB_CREATE,
2984                 0644,
2985                 (DB_ENV *) 0,
2986                 (DB_INFO *) 0,
2987                 &result);
2988 #endif /* DB_VERSION_MAJOR */
2989 #else
2990         DB *result = dbopen(path,
2991                      2,
2992                      0644,
2993                      DB_HASH,
2994                      0);
2995 #endif
2996         ${cf_cv_main_return:-return}(result != 0)
2997 ],[
2998         if test -n "$cf_db_libs" ; then
2999                 cf_cv_hashed_db_libs=$cf_db_libs
3000         else
3001                 cf_cv_hashed_db_libs=default
3002         fi
3003         LIBS="$cf_save_libs"
3004         break
3005 ])
3006         LIBS="$cf_save_libs"
3007 done
3008 ])
3009 ])dnl
3010 dnl ---------------------------------------------------------------------------
3011 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3012 dnl --------------------
3013 dnl Given that we have the header file for hashed database, find the version
3014 dnl information.
3015 AC_DEFUN([CF_HASHED_DB_VERSION],
3016 [
3017 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3018 cf_cv_hashed_db_version=unknown
3019
3020 for cf_db_version in 1 2 3 4 5 6
3021 do
3022         CF_MSG_LOG(checking for db version $cf_db_version)
3023         AC_TRY_COMPILE([
3024 $ac_includes_default
3025 #include <db.h>
3026
3027 #ifdef DB_VERSION_MAJOR
3028         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3029 #if $cf_db_version == DB_VERSION_MAJOR
3030         /* ok */
3031 #else
3032         make an error
3033 #endif
3034 #else
3035 #if $cf_db_version == 1
3036         /* ok: assuming this is DB 1.8.5 */
3037 #else
3038         make an error
3039 #endif
3040 #endif
3041 ],[DBT *foo = 0],[
3042         cf_cv_hashed_db_version=$cf_db_version
3043         break
3044         ])
3045 done
3046 ])
3047 ])dnl
3048 dnl ---------------------------------------------------------------------------
3049 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3050 dnl --------------
3051 dnl Construct a search-list of directories for a nonstandard header-file
3052 dnl
3053 dnl Parameters
3054 dnl     $1 = the variable to return as result
3055 dnl     $2 = the package name
3056 AC_DEFUN([CF_HEADER_PATH],
3057 [
3058 $1=
3059
3060 # collect the current set of include-directories from compiler flags
3061 cf_header_path_list=""
3062 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3063         for cf_header_path in $CPPFLAGS $CFLAGS
3064         do
3065                 case $cf_header_path in
3066                 (-I*)
3067                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3068                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3069                         cf_header_path_list="$cf_header_path_list [$]$1"
3070                         ;;
3071                 esac
3072         done
3073 fi
3074
3075 # add the variations for the package we are looking for
3076 CF_SUBDIR_PATH($1,$2,include)
3077
3078 test "$includedir" != NONE && \
3079 test "$includedir" != "/usr/include" && \
3080 test -d "$includedir" && {
3081         test -d $includedir &&    $1="[$]$1 $includedir"
3082         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3083 }
3084
3085 test "$oldincludedir" != NONE && \
3086 test "$oldincludedir" != "/usr/include" && \
3087 test -d "$oldincludedir" && {
3088         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3089         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3090 }
3091
3092 $1="[$]$1 $cf_header_path_list"
3093 ])dnl
3094 dnl ---------------------------------------------------------------------------
3095 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
3096 dnl ---------------
3097 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3098 AC_DEFUN([CF_HELP_MESSAGE],
3099 [AC_DIVERT_HELP([$1])dnl
3100 ])dnl
3101 dnl ---------------------------------------------------------------------------
3102 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3103 dnl ---------------
3104 dnl Construct the list of include-options according to whether we're building
3105 dnl in the source directory or using '--srcdir=DIR' option.
3106 AC_DEFUN([CF_INCLUDE_DIRS],
3107 [
3108 if test "$srcdir" != "."; then
3109         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3110 fi
3111 CPPFLAGS="-I../include $CPPFLAGS"
3112 if test "$srcdir" != "."; then
3113         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3114 fi
3115 CPPFLAGS="-I. $CPPFLAGS"
3116 AC_SUBST(CPPFLAGS)
3117 ])dnl
3118 dnl ---------------------------------------------------------------------------
3119 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3120 dnl -----------------
3121 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3122 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3123 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3124 dnl
3125 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3126 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3127 dnl the wrappers for gcc and g++ warnings.
3128 dnl
3129 dnl $1 = GCC (default) or GXX
3130 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3131 dnl $3 = CFLAGS (default) or CXXFLAGS
3132 AC_DEFUN([CF_INTEL_COMPILER],[
3133 AC_REQUIRE([AC_CANONICAL_HOST])
3134 ifelse([$2],,INTEL_COMPILER,[$2])=no
3135
3136 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3137         case $host_os in
3138         (linux*|gnu*)
3139                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3140                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3141                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3142                 AC_TRY_COMPILE([],[
3143 #ifdef __INTEL_COMPILER
3144 #else
3145 make an error
3146 #endif
3147 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3148 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3149 ],[])
3150                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3151                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3152                 ;;
3153         esac
3154 fi
3155 ])dnl
3156 dnl ---------------------------------------------------------------------------
3157 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3158 dnl ----------
3159 dnl Check if we have either a function or macro for 'isascii()'.
3160 AC_DEFUN([CF_ISASCII],
3161 [
3162 AC_MSG_CHECKING(for isascii)
3163 AC_CACHE_VAL(cf_cv_have_isascii,[
3164         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3165         [cf_cv_have_isascii=yes],
3166         [cf_cv_have_isascii=no])
3167 ])dnl
3168 AC_MSG_RESULT($cf_cv_have_isascii)
3169 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3170 ])dnl
3171 dnl ---------------------------------------------------------------------------
3172 dnl CF_LARGEFILE version: 9 updated: 2015/04/18 08:56:57
3173 dnl ------------
3174 dnl Add checks for large file support.
3175 AC_DEFUN([CF_LARGEFILE],[
3176 ifdef([AC_FUNC_FSEEKO],[
3177         AC_SYS_LARGEFILE
3178         if test "$enable_largefile" != no ; then
3179         AC_FUNC_FSEEKO
3180
3181         # Normally we would collect these definitions in the config.h,
3182         # but (like _XOPEN_SOURCE), some environments rely on having these
3183         # defined before any of the system headers are included.  Another
3184         # case comes up with C++, e.g., on AIX the compiler compiles the
3185         # header files by themselves before looking at the body files it is
3186         # told to compile.  For ncurses, those header files do not include
3187         # the config.h
3188         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
3189         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
3190         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
3191
3192         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3193                 AC_TRY_COMPILE([
3194 #include <sys/types.h>
3195 #include <dirent.h>
3196                 ],[
3197                 /* if transitional largefile support is setup, this is true */
3198                 extern struct dirent64 * readdir(DIR *);
3199                 struct dirent64 *x = readdir((DIR *)0);
3200                 struct dirent *y = readdir((DIR *)0);
3201                 int z = x - y;
3202                 ],
3203                 [cf_cv_struct_dirent64=yes],
3204                 [cf_cv_struct_dirent64=no])
3205         ])
3206         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3207         fi
3208 ])
3209 ])
3210 dnl ---------------------------------------------------------------------------
3211 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3212 dnl -----------------
3213 dnl Check for compiler/linker flags used to temporarily force usage of static
3214 dnl libraries.  This depends on the compiler and platform.  Use this to help
3215 dnl ensure that the linker picks up a given library based on its position in
3216 dnl the list of linker options and libraries.
3217 AC_DEFUN([CF_LDFLAGS_STATIC],[
3218
3219 if test "$GCC" = yes ; then
3220         case $cf_cv_system_name in
3221         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3222                 LDFLAGS_STATIC=
3223                 LDFLAGS_SHARED=
3224                 ;;
3225         (*)     # normally, except when broken
3226                 LDFLAGS_STATIC=-static
3227                 LDFLAGS_SHARED=-dynamic
3228                 ;;
3229         esac
3230 else
3231         case $cf_cv_system_name in
3232         (aix[[4-7]]*)   # from ld manpage
3233                 LDFLAGS_STATIC=-bstatic
3234                 LDFLAGS_SHARED=-bdynamic
3235                 ;;
3236         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3237                 # We could also use just "archive" and "shared".
3238                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3239                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3240                 ;;
3241         (irix*)         # from ld manpage IRIX64
3242                 LDFLAGS_STATIC=-Bstatic
3243                 LDFLAGS_SHARED=-Bdynamic
3244                 ;;
3245         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3246                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3247                 LDFLAGS_STATIC=-noso
3248                 LDFLAGS_SHARED=-so_archive
3249                 ;;
3250         (solaris2*)
3251                 LDFLAGS_STATIC=-Bstatic
3252                 LDFLAGS_SHARED=-Bdynamic
3253                 ;;
3254         esac
3255 fi
3256
3257 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3258 then
3259         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3260
3261         rm -f libconftest.a
3262         cat >conftest.$ac_ext <<EOF
3263 #line __oline__ "configure"
3264 #include <stdio.h>
3265 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3266 EOF
3267         if AC_TRY_EVAL(ac_compile) ; then
3268                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3269                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3270         fi
3271         rm -f conftest.*
3272
3273         cf_save_LIBS="$LIBS"
3274
3275         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3276         AC_TRY_LINK([
3277 #line __oline__ "configure"
3278 #include <stdio.h>
3279 int cf_ldflags_static(FILE *fp);
3280 ],[
3281         return cf_ldflags_static(stdin);
3282 ],[
3283         # some linkers simply ignore the -dynamic
3284         case x`file conftest$ac_exeext 2>/dev/null` in
3285         (*static*)
3286                 cf_ldflags_static=no
3287                 ;;
3288         (*)
3289                 cf_ldflags_static=yes
3290                 ;;
3291         esac
3292 ],[cf_ldflags_static=no])
3293
3294         rm -f libconftest.*
3295         LIBS="$cf_save_LIBS"
3296
3297         AC_MSG_RESULT($cf_ldflags_static)
3298
3299         if test $cf_ldflags_static != yes
3300         then
3301                 LDFLAGS_STATIC=
3302                 LDFLAGS_SHARED=
3303         fi
3304 else
3305         LDFLAGS_STATIC=
3306         LDFLAGS_SHARED=
3307 fi
3308
3309 AC_SUBST(LDFLAGS_STATIC)
3310 AC_SUBST(LDFLAGS_SHARED)
3311 ])
3312 dnl ---------------------------------------------------------------------------
3313 dnl CF_LD_RPATH_OPT version: 7 updated: 2016/02/20 18:01:19
3314 dnl ---------------
3315 dnl For the given system and compiler, find the compiler flags to pass to the
3316 dnl loader to use the "rpath" feature.
3317 AC_DEFUN([CF_LD_RPATH_OPT],
3318 [
3319 AC_REQUIRE([CF_CHECK_CACHE])
3320
3321 LD_RPATH_OPT=
3322 AC_MSG_CHECKING(for an rpath option)
3323 case $cf_cv_system_name in
3324 (irix*)
3325         if test "$GCC" = yes; then
3326                 LD_RPATH_OPT="-Wl,-rpath,"
3327         else
3328                 LD_RPATH_OPT="-rpath "
3329         fi
3330         ;;
3331 (linux*|gnu*|k*bsd*-gnu|freebsd*)
3332         LD_RPATH_OPT="-Wl,-rpath,"
3333         ;;
3334 (openbsd[[2-9]].*|mirbsd*)
3335         LD_RPATH_OPT="-Wl,-rpath,"
3336         ;;
3337 (dragonfly*)
3338         LD_RPATH_OPT="-rpath "
3339         ;;
3340 (netbsd*)
3341         LD_RPATH_OPT="-Wl,-rpath,"
3342         ;;
3343 (osf*|mls+*)
3344         LD_RPATH_OPT="-rpath "
3345         ;;
3346 (solaris2*)
3347         LD_RPATH_OPT="-R"
3348         ;;
3349 (*)
3350         ;;
3351 esac
3352 AC_MSG_RESULT($LD_RPATH_OPT)
3353
3354 case "x$LD_RPATH_OPT" in
3355 (x-R*)
3356         AC_MSG_CHECKING(if we need a space after rpath option)
3357         cf_save_LIBS="$LIBS"
3358         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3359         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3360         LIBS="$cf_save_LIBS"
3361         AC_MSG_RESULT($cf_rpath_space)
3362         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3363         ;;
3364 esac
3365 ])dnl
3366 dnl ---------------------------------------------------------------------------
3367 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3368 dnl ---------------
3369 dnl Construct a search-list of directories for a nonstandard library-file
3370 dnl
3371 dnl Parameters
3372 dnl     $1 = the variable to return as result
3373 dnl     $2 = the package name
3374 AC_DEFUN([CF_LIBRARY_PATH],
3375 [
3376 $1=
3377 cf_library_path_list=""
3378 if test -n "${LDFLAGS}${LIBS}" ; then
3379         for cf_library_path in $LDFLAGS $LIBS
3380         do
3381                 case $cf_library_path in
3382                 (-L*)
3383                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3384                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3385                         cf_library_path_list="$cf_library_path_list [$]$1"
3386                         ;;
3387                 esac
3388         done
3389 fi
3390
3391 CF_SUBDIR_PATH($1,$2,lib)
3392
3393 $1="$cf_library_path_list [$]$1"
3394 ])dnl
3395 dnl ---------------------------------------------------------------------------
3396 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3397 dnl ------------------
3398 AC_DEFUN([CF_LIBTOOL_VERSION],[
3399 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3400 then
3401         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3402 else
3403         cf_cv_libtool_version=
3404 fi
3405 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3406 ])dnl
3407 dnl ---------------------------------------------------------------------------
3408 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
3409 dnl -------------
3410 dnl Compute the library-prefix for the given host system
3411 dnl $1 = variable to set
3412 define([CF_LIB_PREFIX],
3413 [
3414         case $cf_cv_system_name in
3415         (OS/2*|os2*)
3416                 if test "$DFT_LWR_MODEL" = libtool; then
3417                         LIB_PREFIX='lib'
3418                 else
3419                         LIB_PREFIX=''
3420                 fi
3421                 ;;
3422         (*)     LIB_PREFIX='lib'
3423                 ;;
3424         esac
3425 ifelse($1,,,[$1=$LIB_PREFIX])
3426         AC_SUBST(LIB_PREFIX)
3427 ])dnl
3428 dnl ---------------------------------------------------------------------------
3429 dnl CF_LIB_RULES version: 86 updated: 2015/11/07 20:01:34
3430 dnl ------------
3431 dnl Append definitions and rules for the given models to the subdirectory
3432 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3433 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3434 dnl the corresponding makefile to list the models that we'll generate.
3435 dnl
3436 dnl For shared libraries, make a list of symbolic links to construct when
3437 dnl generating each library.  The convention used for Linux is the simplest
3438 dnl one:
3439 dnl     lib<name>.so    ->
3440 dnl     lib<name>.so.<major>    ->
3441 dnl     lib<name>.so.<maj>.<minor>
3442 dnl
3443 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3444 AC_DEFUN([CF_LIB_RULES],
3445 [
3446 cf_prefix=$LIB_PREFIX
3447 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3448
3449 case $cf_cv_shlib_version in
3450 (cygdll|msysdll|mingw)
3451         TINFO_NAME=$TINFO_ARG_SUFFIX
3452         TINFO_SUFFIX=.dll
3453         ;;
3454 esac
3455
3456 if test -n "$TINFO_SUFFIX" ; then
3457         case $TINFO_SUFFIX in
3458         (tw*)
3459                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
3460                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
3461                 ;;
3462         (t*)
3463                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
3464                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
3465                 ;;
3466         (w*)
3467                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
3468                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
3469                 ;;
3470         esac
3471 fi
3472
3473 for cf_dir in $SRC_SUBDIRS
3474 do
3475         if test ! -d $srcdir/$cf_dir ; then
3476                 continue
3477         elif test -f $srcdir/$cf_dir/modules; then
3478
3479                 SHARED_LIB=
3480                 Libs_To_Make=
3481                 cf_awk_program=
3482                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3483                 then
3484                         cf_awk_program="$cf_awk_program\
3485 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
3486 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
3487 "
3488                 fi
3489
3490                 if test "x$WILDCARD_SYMS" = xno
3491                 then
3492                         cf_awk_program="$cf_awk_program\
3493 /[[     ]]_\\*;/ { skip=1; next; }\
3494 "
3495                 fi
3496
3497                 if test "x$cf_awk_program" != "x"
3498                 then
3499                         cat >>$cf_dir/Makefile <<CF_EOF
3500
3501 # Generated by CF_LIB_RULES
3502 resulting.map: $UNALTERED_SYMS
3503         $AWK 'BEGIN { skip = 1; last=""; } \
3504 $cf_awk_program \
3505 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
3506  skip = 0; last = \[$]\[$]0; } \
3507 END { print last; }' < $UNALTERED_SYMS >\[$]@
3508
3509 distclean::
3510         rm -f resulting.map
3511 CF_EOF
3512                 fi
3513
3514                 for cf_item in $cf_LIST_MODELS
3515                 do
3516                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3517                         cf_libname=$cf_dir
3518                         test "$cf_dir" = c++ && cf_libname=ncurses++
3519                         if test $cf_item = shared ; then
3520                                 if test -n "${LIB_SUFFIX}"
3521                                 then
3522                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3523                                 else
3524                                         cf_shared_suffix="$cf_suffix"
3525                                 fi
3526                                 if test "$cf_cv_do_symlinks" = yes ; then
3527                                         cf_version_name=
3528
3529                                         case "$cf_cv_shlib_version" in
3530                                         (rel)
3531                                                 cf_version_name=REL_VERSION
3532                                                 ;;
3533                                         (abi)
3534                                                 cf_version_name=ABI_VERSION
3535                                                 ;;
3536                                         esac
3537
3538                                         if test -n "$cf_version_name"
3539                                         then
3540                                                 case "$cf_cv_system_name" in
3541                                                 (darwin*)
3542                                                         # "w", etc?
3543                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3544                                                         ;;
3545                                                 (*)
3546                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3547                                                         ;;
3548                                                 esac
3549                                         fi
3550                                         if test -n "${USE_LIB_SUFFIX}"
3551                                         then
3552                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3553                                         else
3554                                                 cf_shared_suffix="$cf_suffix"
3555                                         fi
3556                                 fi
3557                                 # cygwin needs import library, and has unique naming convention
3558                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3559                                 # use 'cyg' prefix for shared lib.
3560                                 case $cf_cv_shlib_version in
3561                                 (cygdll)
3562                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3563                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
3564                                         ;;
3565                                 (msysdll)
3566                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3567                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
3568                                         ;;
3569                                 (mingw)
3570                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3571                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
3572                                         ;;
3573                                 (*)
3574                                         cf_add_lib=
3575                                         ;;
3576                                 esac
3577                                 if test -n "$cf_add_lib"
3578                                 then
3579                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3580                                         continue
3581                                 fi
3582                         fi
3583                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3584                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3585                 done
3586
3587                 if test $cf_dir = ncurses ; then
3588                         cf_subsets="$LIB_SUBSETS"
3589                         cf_r_parts="$cf_subsets"
3590                         cf_liblist="$Libs_To_Make"
3591
3592                         while test -n "$cf_r_parts"
3593                         do
3594                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3595                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3596                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3597                                         cf_add_lib=
3598                                         case $cf_l_parts in
3599                                         (*termlib*)
3600                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3601                                                 ;;
3602                                         (*ticlib*)
3603                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3604                                                 ;;
3605                                         (*)
3606                                                 break
3607                                                 ;;
3608                                         esac
3609                                         if test -n "$cf_add_lib"; then
3610                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
3611                                         fi
3612                                 else
3613                                         break
3614                                 fi
3615                         done
3616                 else
3617                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3618                 fi
3619
3620                 if test $cf_dir = c++; then
3621                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3622                                 cf_list=
3623                                 for cf_item in $Libs_To_Make
3624                                 do
3625                                         case $cf_item in
3626                                         (*.a)
3627                                                 ;;
3628                                         (*)
3629                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3630                                                 ;;
3631                                         esac
3632                                         for cf_test in $cf_list
3633                                         do
3634                                                 if test "$cf_test" = "$cf_item"
3635                                                 then
3636                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3637                                                         cf_item=
3638                                                         break
3639                                                 fi
3640                                         done
3641                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3642                                 done
3643                                 Libs_To_Make="$cf_list"
3644                         fi
3645                 fi
3646
3647                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3648                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3649                         $cf_dir/Makefile >$cf_dir/Makefile.out
3650                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3651
3652                 $AWK -f $srcdir/mk-0th.awk \
3653                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3654                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3655
3656                 for cf_subset in $cf_subsets
3657                 do
3658                         cf_subdirs=
3659                         for cf_item in $cf_LIST_MODELS
3660                         do
3661
3662                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3663                         CF_UPPER(cf_ITEM,$cf_item)
3664
3665                         CXX_MODEL=$cf_ITEM
3666                         if test "$CXX_MODEL" = SHARED; then
3667                                 case $cf_cv_shlib_version in
3668                                 (cygdll|msysdll|mingw)
3669                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3670                                         with_shared_cxx=yes
3671                                         ;;
3672                                 (*)
3673                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3674                                         ;;
3675                                 esac
3676                         fi
3677
3678                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3679                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3680
3681                         # Test for case where we build libtinfo with a different name.
3682                         cf_libname=$cf_dir
3683                         if test $cf_dir = ncurses ; then
3684                                 case $cf_subset in
3685                                 (*base*)
3686                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
3687                                         ;;
3688                                 (*termlib*)
3689                                         cf_libname=$TINFO_LIB_SUFFIX
3690                                         ;;
3691                                 (ticlib*)
3692                                         cf_libname=$TICS_LIB_SUFFIX
3693                                         ;;
3694                                 esac
3695                         elif test $cf_dir = c++ ; then
3696                                 cf_libname=ncurses++$USE_LIB_SUFFIX
3697                         else
3698                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
3699                         fi
3700                         if test -n "${USE_ARG_SUFFIX}" ; then
3701                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
3702                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
3703                         fi
3704
3705                         # These dependencies really are for development, not
3706                         # builds, but they are useful in porting, too.
3707                         cf_depend="../include/ncurses_cfg.h"
3708                         if test "$srcdir" = "."; then
3709                                 cf_reldir="."
3710                         else
3711                                 cf_reldir="\${srcdir}"
3712                         fi
3713
3714                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3715                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3716                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3717                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3718                         fi
3719
3720                         cf_dir_suffix=
3721                         old_cf_suffix="$cf_suffix"
3722                         if test "$cf_cv_shlib_version_infix" = yes ; then
3723                         if test -n "$USE_LIB_SUFFIX" ; then
3724                                 case $USE_LIB_SUFFIX in
3725                                 (tw*)
3726                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
3727                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
3728                                         cf_dir_suffix=tw$EXTRA_SUFFIX
3729                                         ;;
3730                                 (t*)
3731                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
3732                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
3733                                         cf_dir_suffix=t$EXTRA_SUFFIX
3734                                         ;;
3735                                 (w*)
3736                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
3737                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
3738                                         cf_dir_suffix=w$EXTRA_SUFFIX
3739                                         ;;
3740                                 (*)
3741                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
3742                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
3743                                         cf_dir_suffix=$EXTRA_SUFFIX
3744                                         ;;
3745                                 esac
3746                         fi
3747                         fi
3748
3749                         $AWK -f $srcdir/mk-1st.awk \
3750                                 name=${cf_libname}${cf_dir_suffix} \
3751                                 traces=$LIB_TRACING \
3752                                 MODEL=$cf_ITEM \
3753                                 CXX_MODEL=$CXX_MODEL \
3754                                 model=$cf_subdir \
3755                                 prefix=$cf_prefix \
3756                                 suffix=$cf_suffix \
3757                                 subset=$cf_subset \
3758                                 driver=$cf_cv_term_driver \
3759                                 SymLink="$LN_S" \
3760                                 TermlibRoot=$TINFO_NAME \
3761                                 TermlibSuffix=$TINFO_SUFFIX \
3762                                 ShlibVer=$cf_cv_shlib_version \
3763                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3764                                 ReLink=${cf_cv_do_relink:-no} \
3765                                 DoLinks=$cf_cv_do_symlinks \
3766                                 rmSoLocs=$cf_cv_rm_so_locs \
3767                                 ldconfig="$LDCONFIG" \
3768                                 overwrite=$WITH_OVERWRITE \
3769                                 depend="$cf_depend" \
3770                                 host="$host" \
3771                                 libtool_version="$LIBTOOL_VERSION" \
3772                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3773
3774                         cf_suffix="$old_cf_suffix"
3775
3776                         for cf_subdir2 in $cf_subdirs lib
3777                         do
3778                                 test $cf_subdir = $cf_subdir2 && break
3779                         done
3780                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3781                         $AWK -f $srcdir/mk-2nd.awk \
3782                                 name=$cf_dir \
3783                                 traces=$LIB_TRACING \
3784                                 MODEL=$cf_ITEM \
3785                                 model=$cf_subdir \
3786                                 subset=$cf_subset \
3787                                 srcdir=$srcdir \
3788                                 echo=$WITH_ECHO \
3789                                 crenames=$cf_cv_prog_CC_c_o \
3790                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3791                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3792                         cf_subdirs="$cf_subdirs $cf_subdir"
3793                         done
3794                 done
3795         fi
3796
3797         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3798 done
3799
3800 for cf_dir in $SRC_SUBDIRS
3801 do
3802         if test ! -d $srcdir/$cf_dir ; then
3803                 continue
3804         fi
3805
3806         if test -f $cf_dir/Makefile ; then
3807                 case "$cf_dir" in
3808                 (Ada95)
3809                         echo 'libs \' >> Makefile
3810                         echo 'install.libs \' >> Makefile
3811                         echo 'uninstall.libs ::' >> Makefile
3812                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3813                         ;;
3814                 esac
3815         fi
3816
3817         if test -f $srcdir/$cf_dir/modules; then
3818                 echo >> Makefile
3819                 if test -f $srcdir/$cf_dir/headers; then
3820 cat >> Makefile <<CF_EOF
3821 install.includes \\
3822 uninstall.includes \\
3823 CF_EOF
3824                 fi
3825 if test "$cf_dir" != "c++" ; then
3826 echo 'lint \' >> Makefile
3827 fi
3828 cat >> Makefile <<CF_EOF
3829 libs \\
3830 lintlib \\
3831 install.libs \\
3832 uninstall.libs \\
3833 install.$cf_dir \\
3834 uninstall.$cf_dir ::
3835         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3836 CF_EOF
3837         elif test -f $srcdir/$cf_dir/headers; then
3838 cat >> Makefile <<CF_EOF
3839
3840 libs \\
3841 install.libs \\
3842 uninstall.libs \\
3843 install.includes \\
3844 uninstall.includes ::
3845         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3846 CF_EOF
3847 fi
3848 done
3849
3850 if test "x$cf_with_db_install" = xyes; then
3851 cat >> Makefile <<CF_EOF
3852
3853 install.libs uninstall.libs \\
3854 install.data uninstall.data ::
3855 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3856 CF_EOF
3857 else
3858 cat >> Makefile <<CF_EOF
3859
3860 install.libs uninstall.libs ::
3861         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3862 CF_EOF
3863 fi
3864
3865 if test "x$cf_with_manpages" = xyes; then
3866 cat >> Makefile <<CF_EOF
3867
3868 install.man \\
3869 uninstall.man ::
3870         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3871 CF_EOF
3872 fi
3873
3874 cat >> Makefile <<CF_EOF
3875
3876 distclean ::
3877         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3878         rm -f headers.sh headers.sed mk_shared_lib.sh
3879         rm -f edit_man.* man_alias.*
3880         rm -rf \${DIRS_TO_MAKE}
3881 CF_EOF
3882
3883 # Special case: tack's manpage lives in its own directory.
3884 if test "x$cf_with_manpages" = xyes; then
3885 if test -d tack ; then
3886 if test -f $srcdir/$tack.h; then
3887 cat >> Makefile <<CF_EOF
3888
3889 install.man \\
3890 uninstall.man ::
3891         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3892 CF_EOF
3893 fi
3894 fi
3895 fi
3896
3897 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3898 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3899 dnl anything, and will make it more standardized.  It's awkward to decide this
3900 dnl at configuration because of quoting, so we'll simply make all headers
3901 dnl installed via a script that can do the right thing.
3902
3903 rm -f headers.sed headers.sh
3904
3905 dnl ( generating this script makes the makefiles a little tidier :-)
3906 echo creating headers.sh
3907 cat >headers.sh <<CF_EOF
3908 #! $SHELL
3909 # This shell script is generated by the 'configure' script.  It is invoked in a
3910 # subdirectory of the build tree.  It generates a sed-script in the parent
3911 # directory that is used to adjust includes for header files that reside in a
3912 # subdirectory of /usr/include, etc.
3913 PRG=""
3914 while test \[$]# != 3
3915 do
3916 PRG="\$PRG \[$]1"; shift
3917 done
3918 DST=\[$]1
3919 REF=\[$]2
3920 SRC=\[$]3
3921 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3922 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3923 echo installing \$SRC in \$DST
3924 CF_EOF
3925
3926 if test $WITH_CURSES_H = yes; then
3927         cat >>headers.sh <<CF_EOF
3928 case \$DST in
3929 (/*/include/*)
3930         END=\`basename \$DST\`
3931         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3932         do
3933                 NAME=\`basename \$i\`
3934                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3935         done
3936         ;;
3937 (*)
3938         echo "" >> \$TMPSED
3939         ;;
3940 esac
3941 CF_EOF
3942
3943 else
3944         cat >>headers.sh <<CF_EOF
3945 case \$DST in
3946 (/*/include/*)
3947         END=\`basename \$DST\`
3948         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3949         do
3950                 NAME=\`basename \$i\`
3951                 if test "\$NAME" = "curses.h"
3952                 then
3953                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3954                         NAME=ncurses.h
3955                 fi
3956                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3957         done
3958         ;;
3959 (*)
3960         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3961         ;;
3962 esac
3963 CF_EOF
3964 fi
3965 cat >>headers.sh <<CF_EOF
3966 rm -f \$TMPSRC
3967 sed -f \$TMPSED \$SRC > \$TMPSRC
3968 NAME=\`basename \$SRC\`
3969 CF_EOF
3970 if test $WITH_CURSES_H != yes; then
3971         cat >>headers.sh <<CF_EOF
3972 test "\$NAME" = "curses.h" && NAME=ncurses.h
3973 CF_EOF
3974 fi
3975 cat >>headers.sh <<CF_EOF
3976 # Just in case someone gzip'd manpages, remove the conflicting copy.
3977 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3978
3979 eval \$PRG \$TMPSRC \$DST/\$NAME
3980 rm -f \$TMPSRC \$TMPSED
3981 CF_EOF
3982
3983 chmod 0755 headers.sh
3984
3985 for cf_dir in $SRC_SUBDIRS
3986 do
3987         if test ! -d $srcdir/$cf_dir ; then
3988                 continue
3989         fi
3990
3991         if test -f $srcdir/$cf_dir/headers; then
3992                 $AWK -f $srcdir/mk-hdr.awk \
3993                         subset="$LIB_SUBSETS" \
3994                         compat="$WITH_CURSES_H" \
3995                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3996         fi
3997
3998         if test -f $srcdir/$cf_dir/modules; then
3999                 if test "$cf_dir" != "c++" ; then
4000                         cat >>$cf_dir/Makefile <<"CF_EOF"
4001 depend : ${AUTO_SRC}
4002         makedepend -- ${CPPFLAGS} -- ${C_SRC}
4003
4004 # DO NOT DELETE THIS LINE -- make depend depends on it.
4005 CF_EOF
4006                 fi
4007         fi
4008 done
4009 AC_SUBST(Libs_To_Make)
4010 ])dnl
4011 dnl ---------------------------------------------------------------------------
4012 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
4013 dnl -------------
4014 dnl Find the and soname for the given shared library.  Set the cache variable
4015 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
4016 dnl variable to "unknown".
4017 dnl
4018 dnl $1 = headers
4019 dnl $2 = code
4020 dnl $3 = library name
4021 AC_DEFUN([CF_LIB_SONAME],
4022 [
4023 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
4024
4025 cf_cv_$3_soname=unknown
4026 if test "$cross_compiling" != yes ; then
4027 cat >conftest.$ac_ext <<CF_EOF
4028 $1
4029 int main()
4030 {
4031 $2
4032         ${cf_cv_main_return:-return}(0);
4033 }
4034 CF_EOF
4035 cf_save_LIBS="$LIBS"
4036         CF_ADD_LIB($3)
4037         if AC_TRY_EVAL(ac_compile) ; then
4038                 if AC_TRY_EVAL(ac_link) ; then
4039                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
4040                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4041                 fi
4042         fi
4043 rm -rf conftest*
4044 LIBS="$cf_save_LIBS"
4045 fi
4046 ])
4047 ])
4048 dnl ---------------------------------------------------------------------------
4049 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
4050 dnl -------------
4051 dnl Compute the library file-suffix from the given model name
4052 dnl $1 = model name
4053 dnl $2 = variable to set (the nominal library suffix)
4054 dnl $3 = dependency variable to set (actual filename)
4055 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4056 AC_DEFUN([CF_LIB_SUFFIX],
4057 [
4058         case X$1 in
4059         (Xlibtool)
4060                 $2='.la'
4061                 $3=[$]$2
4062                 ;;
4063         (Xdebug)
4064                 $2='_g.a'
4065                 $3=[$]$2
4066                 ;;
4067         (Xprofile)
4068                 $2='_p.a'
4069                 $3=[$]$2
4070                 ;;
4071         (Xshared)
4072                 case $cf_cv_system_name in
4073                 (aix[[5-7]]*)
4074                         $2='.so'
4075                         $3=[$]$2
4076                         ;;
4077                 (cygwin*|msys*|mingw*)
4078                         $2='.dll'
4079                         $3='.dll.a'
4080                         ;;
4081                 (darwin*)
4082                         $2='.dylib'
4083                         $3=[$]$2
4084                         ;;
4085                 (hpux*)
4086                         case $target in
4087                         (ia64*)
4088                                 $2='.so'
4089                                 $3=[$]$2
4090                                 ;;
4091                         (*)
4092                                 $2='.sl'
4093                                 $3=[$]$2
4094                                 ;;
4095                         esac
4096                         ;;
4097                 (*)
4098                         $2='.so'
4099                         $3=[$]$2
4100                         ;;
4101                 esac
4102                 ;;
4103         (*)
4104                 $2='.a'
4105                 $3=[$]$2
4106                 ;;
4107         esac
4108         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
4109         then
4110                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
4111                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
4112         fi
4113 ])dnl
4114 dnl ---------------------------------------------------------------------------
4115 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
4116 dnl -----------
4117 dnl Compute the string to append to -library from the given model name
4118 dnl $1 = model name
4119 dnl $2 = variable to set
4120 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4121 AC_DEFUN([CF_LIB_TYPE],
4122 [
4123         case $1 in
4124         (libtool) $2=''   ;;
4125         (normal)  $2=''   ;;
4126         (debug)   $2='_g' ;;
4127         (profile) $2='_p' ;;
4128         (shared)  $2=''   ;;
4129         esac
4130         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
4131 ])dnl
4132 dnl ---------------------------------------------------------------------------
4133 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
4134 dnl ----------------
4135 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
4136 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
4137 dnl have to provide wrappers for global tables to ensure they're linked
4138 dnl properly.
4139 AC_DEFUN([CF_LINK_DATAONLY],
4140 [
4141 AC_MSG_CHECKING([if data-only library module links])
4142 AC_CACHE_VAL(cf_cv_link_dataonly,[
4143         rm -f conftest.a
4144         cat >conftest.$ac_ext <<EOF
4145 #line __oline__ "configure"
4146 int     testdata[[3]] = { 123, 456, 789 };
4147 EOF
4148         if AC_TRY_EVAL(ac_compile) ; then
4149                 mv conftest.o data.o && \
4150                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
4151         fi
4152         rm -f conftest.$ac_ext data.o
4153         cat >conftest.$ac_ext <<EOF
4154 #line __oline__ "configure"
4155 int     testfunc()
4156 {
4157 #if defined(NeXT)
4158         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
4159 #else
4160         extern int testdata[[3]];
4161         return testdata[[0]] == 123
4162            &&  testdata[[1]] == 456
4163            &&  testdata[[2]] == 789;
4164 #endif
4165 }
4166 EOF
4167         if AC_TRY_EVAL(ac_compile); then
4168                 mv conftest.o func.o && \
4169                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
4170         fi
4171         rm -f conftest.$ac_ext func.o
4172         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
4173         cf_saveLIBS="$LIBS"
4174         LIBS="conftest.a $LIBS"
4175         AC_TRY_RUN([
4176         int main()
4177         {
4178                 extern int testfunc();
4179                 ${cf_cv_main_return:-return} (!testfunc());
4180         }
4181         ],
4182         [cf_cv_link_dataonly=yes],
4183         [cf_cv_link_dataonly=no],
4184         [cf_cv_link_dataonly=unknown])
4185         LIBS="$cf_saveLIBS"
4186         ])
4187 AC_MSG_RESULT($cf_cv_link_dataonly)
4188
4189 if test "$cf_cv_link_dataonly" = no ; then
4190         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
4191         BROKEN_LINKER=1
4192 fi
4193
4194 ])dnl
4195 dnl ---------------------------------------------------------------------------
4196 dnl CF_LINK_FUNCS version: 8 updated: 2012/10/06 17:56:13
4197 dnl -------------
4198 dnl Most Unix systems have both link and symlink, a few don't have symlink.
4199 dnl A few non-Unix systems implement symlink, but not link.
4200 dnl A few non-systems implement neither (or have nonfunctional versions).
4201 AC_DEFUN([CF_LINK_FUNCS],
4202 [
4203 AC_CHECK_FUNCS( \
4204         remove \
4205         unlink )
4206
4207 if test "$cross_compiling" = yes ; then
4208         AC_CHECK_FUNCS( \
4209                 link \
4210                 symlink )
4211 else
4212         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
4213                 cf_cv_link_funcs=
4214                 for cf_func in link symlink ; do
4215                         AC_TRY_RUN([
4216 #include <sys/types.h>
4217 #include <sys/stat.h>
4218 #ifdef HAVE_UNISTD_H
4219 #include <unistd.h>
4220 #endif
4221 int main()
4222 {
4223         int fail = 0;
4224         char *src = "config.log";
4225         char *dst = "conftest.chk";
4226         struct stat src_sb;
4227         struct stat dst_sb;
4228
4229         stat(src, &src_sb);
4230         fail = ($cf_func("config.log", "conftest.chk") < 0)
4231             || (stat(dst, &dst_sb) < 0)
4232             || (dst_sb.st_mtime != src_sb.st_mtime);
4233 #ifdef HAVE_UNLINK
4234         unlink(dst);
4235 #else
4236         remove(dst);
4237 #endif
4238         ${cf_cv_main_return:-return} (fail);
4239 }
4240                         ],[
4241                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
4242                         eval 'ac_cv_func_'$cf_func'=yes'],[
4243                         eval 'ac_cv_func_'$cf_func'=no'],[
4244                         eval 'ac_cv_func_'$cf_func'=error'])
4245                 done
4246                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
4247         ])
4248         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
4249         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
4250 fi
4251 ])dnl
4252 dnl ---------------------------------------------------------------------------
4253 dnl CF_MAKEFLAGS version: 17 updated: 2015/08/05 20:44:28
4254 dnl ------------
4255 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
4256 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
4257 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
4258 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
4259 AC_DEFUN([CF_MAKEFLAGS],
4260 [
4261 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
4262         cf_cv_makeflags=''
4263         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
4264         do
4265                 cat >cf_makeflags.tmp <<CF_EOF
4266 SHELL = $SHELL
4267 all :
4268         @ echo '.$cf_option'
4269 CF_EOF
4270                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
4271                 case "$cf_result" in
4272                 (.*k|.*kw)
4273                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
4274                         case "$cf_result" in
4275                         (.*CC=*)        cf_cv_makeflags=
4276                                 ;;
4277                         (*)     cf_cv_makeflags=$cf_option
4278                                 ;;
4279                         esac
4280                         break
4281                         ;;
4282                 (.-)    ;;
4283                 (*)     echo "given option \"$cf_option\", no match \"$cf_result\""
4284                         ;;
4285                 esac
4286         done
4287         rm -f cf_makeflags.tmp
4288 ])
4289
4290 AC_SUBST(cf_cv_makeflags)
4291 ])dnl
4292 dnl ---------------------------------------------------------------------------
4293 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
4294 dnl ------------
4295 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
4296 dnl a monocase filesystem.
4297 AC_DEFUN([CF_MAKE_TAGS],[
4298 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
4299
4300 AC_CHECK_PROGS(CTAGS, exctags ctags)
4301 AC_CHECK_PROGS(ETAGS, exetags etags)
4302
4303 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
4304
4305 if test "$cf_cv_mixedcase" = yes ; then
4306         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
4307 else
4308         MAKE_UPPER_TAGS=no
4309 fi
4310
4311 if test "$MAKE_UPPER_TAGS" = yes ; then
4312         MAKE_UPPER_TAGS=
4313 else
4314         MAKE_UPPER_TAGS="#"
4315 fi
4316
4317 if test "$MAKE_LOWER_TAGS" = yes ; then
4318         MAKE_LOWER_TAGS=
4319 else
4320         MAKE_LOWER_TAGS="#"
4321 fi
4322
4323 AC_SUBST(CTAGS)
4324 AC_SUBST(ETAGS)
4325
4326 AC_SUBST(MAKE_UPPER_TAGS)
4327 AC_SUBST(MAKE_LOWER_TAGS)
4328 ])dnl
4329 dnl ---------------------------------------------------------------------------
4330 dnl CF_MANPAGE_FORMAT version: 11 updated: 2015/04/18 08:56:57
4331 dnl -----------------
4332 dnl Option to allow user to override automatic configuration of manpage format.
4333 dnl There are several special cases:
4334 dnl
4335 dnl     gzip - man checks for, can display gzip'd files
4336 dnl     compress - man checks for, can display compressed files
4337 dnl     BSDI - files in the cat-directories are suffixed ".0"
4338 dnl     formatted - installer should format (put files in cat-directory)
4339 dnl     catonly - installer should only format, e.g., for a turnkey system.
4340 dnl
4341 dnl There are other configurations which this macro does not test, e.g., HPUX's
4342 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
4343 dnl convention would not match our use).
4344 AC_DEFUN([CF_MANPAGE_FORMAT],
4345 [
4346 AC_REQUIRE([CF_PATHSEP])
4347 AC_MSG_CHECKING(format of man-pages)
4348
4349 AC_ARG_WITH(manpage-format,
4350         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
4351                           optionally formatted/catonly, e.g., gzip,formatted],
4352         [MANPAGE_FORMAT=$withval],
4353         [MANPAGE_FORMAT=unknown])
4354
4355 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
4356 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
4357
4358 cf_unknown=
4359
4360 case $MANPAGE_FORMAT in
4361 (unknown)
4362         if test -z "$MANPATH" ; then
4363                 MANPATH="/usr/man:/usr/share/man"
4364         fi
4365
4366         # look for the 'date' man-page (it's most likely to be installed!)
4367         MANPAGE_FORMAT=
4368         cf_preform=no
4369         cf_catonly=yes
4370         cf_example=date
4371
4372         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
4373         for cf_dir in $MANPATH; do
4374                 test -z "$cf_dir" && cf_dir=/usr/man
4375                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
4376                 do
4377                         cf_test=`echo $cf_name | sed -e 's/*//'`
4378                         if test "x$cf_test" = "x$cf_name" ; then
4379
4380                                 case "$cf_name" in
4381                                 (*.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
4382                                 (*.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
4383                                 (*.0)  MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
4384                                 (*)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
4385                                 esac
4386
4387                                 case "$cf_name" in
4388                                 ($cf_dir/man*)
4389                                         cf_catonly=no
4390                                         ;;
4391                                 ($cf_dir/cat*)
4392                                         cf_preform=yes
4393                                         ;;
4394                                 esac
4395                                 break
4396                         fi
4397
4398                         # if we found a match in either man* or cat*, stop looking
4399                         if test -n "$MANPAGE_FORMAT" ; then
4400                                 cf_found=no
4401                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
4402                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
4403                                 case "$cf_name" in
4404                                 ($cf_dir/cat*)
4405                                         cf_found=yes
4406                                         ;;
4407                                 esac
4408                                 test $cf_found=yes && break
4409                         fi
4410                 done
4411                 # only check the first directory in $MANPATH where we find manpages
4412                 if test -n "$MANPAGE_FORMAT" ; then
4413                         break
4414                 fi
4415         done
4416         # if we did not find the example, just assume it is normal
4417         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4418         IFS="$ac_save_ifs"
4419         ;;
4420 (*)
4421         for cf_option in $MANPAGE_FORMAT; do
4422         case $cf_option in
4423         (gzip|compress|BSDI|normal|formatted|catonly)
4424                 ;;
4425         (*)
4426                 cf_unknown="$cf_unknown $cf_option"
4427                 ;;
4428         esac
4429         done
4430         ;;
4431 esac
4432
4433 AC_MSG_RESULT($MANPAGE_FORMAT)
4434 if test -n "$cf_unknown" ; then
4435         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4436 fi
4437 ])dnl
4438 dnl ---------------------------------------------------------------------------
4439 dnl CF_MANPAGE_RENAMES version: 10 updated: 2015/08/05 20:44:28
4440 dnl ------------------
4441 dnl The Debian people have their own naming convention for manpages.  This
4442 dnl option lets us override the name of the file containing renaming, or
4443 dnl disable it altogether.
4444 AC_DEFUN([CF_MANPAGE_RENAMES],
4445 [
4446 AC_MSG_CHECKING(for manpage renaming)
4447
4448 AC_ARG_WITH(manpage-renames,
4449         [  --with-manpage-renames  specify manpage-renaming],
4450         [MANPAGE_RENAMES=$withval],
4451         [MANPAGE_RENAMES=yes])
4452
4453 case ".$MANPAGE_RENAMES" in
4454 (.no)
4455         ;;
4456 (.|.yes)
4457         # Debian 'man' program?
4458         if test -f /etc/debian_version ; then
4459                 MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4460         else
4461                 MANPAGE_RENAMES=no
4462         fi
4463         ;;
4464 esac
4465
4466 if test "$MANPAGE_RENAMES" != no ; then
4467         if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4468                 MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4469         elif test ! -f $MANPAGE_RENAMES ; then
4470                 AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4471         fi
4472
4473         test ! -d man && mkdir man
4474
4475         # Construct a sed-script to perform renaming within man-pages
4476         if test -n "$MANPAGE_RENAMES" ; then
4477                 test ! -d man && mkdir man
4478                 $SHELL $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4479         fi
4480 fi
4481
4482 AC_MSG_RESULT($MANPAGE_RENAMES)
4483 AC_SUBST(MANPAGE_RENAMES)
4484 ])dnl
4485 dnl ---------------------------------------------------------------------------
4486 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
4487 dnl -------------------
4488 dnl Some people expect each tool to make all aliases for manpages in the
4489 dnl man-directory.  This accommodates the older, less-capable implementations
4490 dnl of 'man', and is optional.
4491 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4492 [
4493 AC_MSG_CHECKING(if manpage aliases will be installed)
4494
4495 AC_ARG_WITH(manpage-aliases,
4496         [  --with-manpage-aliases  specify manpage-aliases using .so],
4497         [MANPAGE_ALIASES=$withval],
4498         [MANPAGE_ALIASES=yes])
4499
4500 AC_MSG_RESULT($MANPAGE_ALIASES)
4501
4502 case "x$LN_S" in
4503 (xln*)
4504         cf_use_symlinks=yes
4505         ;;
4506 (*)
4507         cf_use_symlinks=no
4508         ;;
4509 esac
4510
4511 MANPAGE_SYMLINKS=no
4512 if test "$MANPAGE_ALIASES" = yes ; then
4513 AC_MSG_CHECKING(if manpage symlinks should be used)
4514
4515 AC_ARG_WITH(manpage-symlinks,
4516         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4517         [MANPAGE_SYMLINKS=$withval],
4518         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4519
4520 if test "$$cf_use_symlinks" = no; then
4521 if test "$MANPAGE_SYMLINKS" = yes ; then
4522         AC_MSG_WARN(cannot make symlinks, will use .so files)
4523         MANPAGE_SYMLINKS=no
4524 fi
4525 fi
4526
4527 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4528 fi
4529
4530 ])dnl
4531 dnl ---------------------------------------------------------------------------
4532 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4533 dnl --------------
4534 dnl This option causes manpages to be run through tbl(1) to generate tables
4535 dnl correctly.
4536 AC_DEFUN([CF_MANPAGE_TBL],
4537 [
4538 AC_MSG_CHECKING(for manpage tbl)
4539
4540 AC_ARG_WITH(manpage-tbl,
4541         [  --with-manpage-tbl      specify manpage processing with tbl],
4542         [MANPAGE_TBL=$withval],
4543         [MANPAGE_TBL=no])
4544
4545 AC_MSG_RESULT($MANPAGE_TBL)
4546 ])dnl
4547 dnl ---------------------------------------------------------------------------
4548 dnl CF_MAN_PAGES version: 46 updated: 2015/08/05 20:44:28
4549 dnl ------------
4550 dnl Try to determine if the man-pages on the system are compressed, and if
4551 dnl so, what format is used.  Use this information to construct a script that
4552 dnl will install man-pages.
4553 AC_DEFUN([CF_MAN_PAGES],
4554 [
4555 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4556 CF_MANPAGE_FORMAT
4557 CF_MANPAGE_RENAMES
4558 CF_MANPAGE_SYMLINKS
4559 CF_MANPAGE_TBL
4560
4561 if test "$prefix" = "NONE" ; then
4562         cf_prefix="$ac_default_prefix"
4563 else
4564         cf_prefix="$prefix"
4565 fi
4566
4567 case "$MANPAGE_FORMAT" in
4568 (*catonly*)
4569         cf_format=yes
4570         cf_inboth=no
4571         ;;
4572 (*formatted*)
4573         cf_format=yes
4574         cf_inboth=yes
4575         ;;
4576 (*)
4577         cf_format=no
4578         cf_inboth=no
4579         ;;
4580 esac
4581
4582 test ! -d man && mkdir man
4583
4584 cf_so_strip=
4585 cf_compress=
4586 case "$MANPAGE_FORMAT" in
4587 (*compress*)
4588         cf_so_strip="Z"
4589         cf_compress=compress
4590         ;;
4591 (*gzip*)
4592         cf_so_strip="gz"
4593         cf_compress=gzip
4594         ;;
4595 esac
4596
4597 cf_edit_man=./edit_man.sh
4598 cf_man_alias=`pwd`/man_alias.sed
4599
4600 cat >$cf_edit_man <<CF_EOF
4601 #! $SHELL
4602 # this script is generated by the configure-script CF_MAN_PAGES macro.
4603
4604 prefix="$cf_prefix"
4605 datarootdir="$datarootdir"
4606 datadir="$datadir"
4607
4608 NCURSES_MAJOR="$NCURSES_MAJOR"
4609 NCURSES_MINOR="$NCURSES_MINOR"
4610 NCURSES_PATCH="$NCURSES_PATCH"
4611
4612 NCURSES_OSPEED="$NCURSES_OSPEED"
4613 TERMINFO="$TERMINFO"
4614
4615 INSTALL="$INSTALL"
4616 INSTALL_DATA="$INSTALL_DATA"
4617
4618 transform="$program_transform_name"
4619
4620 TMP=\${TMPDIR:=/tmp}/man\$\$
4621 trap "rm -f \$TMP" 0 1 2 5 15
4622
4623 form=\[$]1
4624 shift || exit 1
4625
4626 verb=\[$]1
4627 shift || exit 1
4628
4629 mandir=\[$]1
4630 shift || exit 1
4631
4632 srcdir=\[$]1
4633 top_srcdir=\[$]srcdir/..
4634 shift || exit 1
4635
4636 if test "\$form" = normal ; then
4637         if test "$cf_format" = yes ; then
4638         if test "$cf_inboth" = no ; then
4639                 $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
4640                 exit $?
4641         fi
4642         fi
4643         cf_subdir=\$mandir/man
4644         cf_tables=$MANPAGE_TBL
4645 else
4646         cf_subdir=\$mandir/cat
4647         cf_tables=yes
4648 fi
4649
4650 # process the list of source-files
4651 for i in \[$]* ; do
4652 case \$i in
4653 (*.orig|*.rej) ;;
4654 (*.[[0-9]]*)
4655         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4656         if test \$verb = installing ; then
4657         if test ! -d \$cf_subdir\${section} ; then
4658                 mkdir -p \$cf_subdir\$section
4659         fi
4660         fi
4661
4662         # replace variables in man page
4663         if test ! -f $cf_man_alias ; then
4664 cat >>$cf_man_alias <<-CF_EOF2
4665                 s,@DATADIR@,\$datadir,g
4666                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
4667                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
4668                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
4669                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
4670                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
4671                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
4672 CF_EOF
4673         ifelse($1,,,[
4674         for cf_name in $1
4675         do
4676                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4677                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4678 cat >>$cf_edit_man <<-CF_EOF
4679                 s,@$cf_NAME@,$cf_name,g
4680 CF_EOF
4681         done
4682         ])
4683 cat >>$cf_edit_man <<CF_EOF
4684 CF_EOF2
4685                 echo "...made $cf_man_alias"
4686         fi
4687
4688         aliases=
4689         cf_source=\`basename \$i\`
4690         inalias=\$cf_source
4691         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4692         if test ! -f \$inalias ; then
4693                 echo .. skipped \$cf_source
4694                 continue
4695         fi
4696 CF_EOF
4697
4698 if test "$MANPAGE_ALIASES" != no ; then
4699 cat >>$cf_edit_man <<CF_EOF
4700         nCurses=ignore.3x
4701         test $with_curses_h = yes && nCurses=ncurses.3x
4702         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4703 CF_EOF
4704 fi
4705
4706 if test "$MANPAGE_RENAMES" = no ; then
4707 cat >>$cf_edit_man <<CF_EOF
4708         # perform program transformations for section 1 man pages
4709         if test \$section = 1 ; then
4710                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4711         else
4712                 cf_target=\$cf_subdir\${section}/\$cf_source
4713         fi
4714 CF_EOF
4715 else
4716 cat >>$cf_edit_man <<CF_EOF
4717         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4718         if test -z "\$cf_target" ; then
4719                 echo '? missing rename for '\$cf_source
4720                 cf_target="\$cf_source"
4721         fi
4722         cf_target="\$cf_subdir\${section}/\${cf_target}"
4723
4724 CF_EOF
4725 fi
4726
4727 cat >>$cf_edit_man <<CF_EOF
4728         sed     -f $cf_man_alias \\
4729 CF_EOF
4730
4731 if test -f $MANPAGE_RENAMES ; then
4732 cat >>$cf_edit_man <<CF_EOF
4733                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4734 CF_EOF
4735 else
4736 cat >>$cf_edit_man <<CF_EOF
4737                 < \$i >\$TMP
4738 CF_EOF
4739 fi
4740
4741 cat >>$cf_edit_man <<CF_EOF
4742 if test \$cf_tables = yes ; then
4743         tbl \$TMP >\$TMP.out
4744         mv \$TMP.out \$TMP
4745 fi
4746 CF_EOF
4747
4748 if test $with_overwrite != yes ; then
4749 cat >>$cf_edit_man <<CF_EOF
4750         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4751         mv \$TMP.out \$TMP
4752 CF_EOF
4753 fi
4754
4755 if test $with_curses_h != yes ; then
4756 cat >>$cf_edit_man <<CF_EOF
4757         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4758         mv \$TMP.out \$TMP
4759 CF_EOF
4760 fi
4761
4762 cat >>$cf_edit_man <<CF_EOF
4763         if test \$form = format ; then
4764                 nroff -man \$TMP >\$TMP.out
4765                 mv \$TMP.out \$TMP
4766         fi
4767 CF_EOF
4768
4769 if test -n "$cf_compress" ; then
4770 cat >>$cf_edit_man <<CF_EOF
4771         if test \$verb = installing ; then
4772         if ( $cf_compress -f \$TMP )
4773         then
4774                 mv \$TMP.$cf_so_strip \$TMP
4775         fi
4776         fi
4777         cf_target="\$cf_target.$cf_so_strip"
4778 CF_EOF
4779 fi
4780
4781 case "$MANPAGE_FORMAT" in
4782 (*BSDI*)
4783 cat >>$cf_edit_man <<CF_EOF
4784         if test \$form = format ; then
4785                 # BSDI installs only .0 suffixes in the cat directories
4786                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4787         fi
4788 CF_EOF
4789   ;;
4790 esac
4791
4792 cat >>$cf_edit_man <<CF_EOF
4793         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4794         if test \$verb = installing ; then
4795                 echo \$verb \$cf_target
4796                 \$INSTALL_DATA \$TMP \$cf_target
4797                 test -d \$cf_subdir\${section} &&
4798                 test -n "\$aliases" && (
4799                         cd \$cf_subdir\${section} && (
4800                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4801                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4802                                 cf_target=\`basename \$cf_target\`
4803                                 for cf_alias in \$aliases
4804                                 do
4805                                         if test \$section = 1 ; then
4806                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4807                                         fi
4808
4809                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4810                                                 if test -f \$cf_alias\${suffix} ; then
4811                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4812                                                         then
4813                                                                 continue
4814                                                         fi
4815                                                 fi
4816                                                 echo .. \$verb alias \$cf_alias\${suffix}
4817 CF_EOF
4818 case "x$LN_S" in
4819 (*-f)
4820 cat >>$cf_edit_man <<CF_EOF
4821                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4822 CF_EOF
4823         ;;
4824 (*)
4825 cat >>$cf_edit_man <<CF_EOF
4826                                                 rm -f \$cf_alias\${suffix}
4827                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4828 CF_EOF
4829         ;;
4830 esac
4831 cat >>$cf_edit_man <<CF_EOF
4832                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4833                                                 echo ".so \$cf_source" >\$TMP
4834 CF_EOF
4835 if test -n "$cf_compress" ; then
4836 cat >>$cf_edit_man <<CF_EOF
4837                                                 if test -n "$cf_so_strip" ; then
4838                                                         $cf_compress -f \$TMP
4839                                                         mv \$TMP.$cf_so_strip \$TMP
4840                                                 fi
4841 CF_EOF
4842 fi
4843 cat >>$cf_edit_man <<CF_EOF
4844                                                 echo .. \$verb alias \$cf_alias\${suffix}
4845                                                 rm -f \$cf_alias\${suffix}
4846                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4847                                         fi
4848                                 done
4849                         )
4850                 )
4851         elif test \$verb = removing ; then
4852                 test -f \$cf_target && (
4853                         echo \$verb \$cf_target
4854                         rm -f \$cf_target
4855                 )
4856                 test -d \$cf_subdir\${section} &&
4857                 test -n "\$aliases" && (
4858                         cd \$cf_subdir\${section} && (
4859                                 for cf_alias in \$aliases
4860                                 do
4861                                         if test \$section = 1 ; then
4862                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4863                                         fi
4864
4865                                         echo .. \$verb alias \$cf_alias\${suffix}
4866                                         rm -f \$cf_alias\${suffix}
4867                                 done
4868                         )
4869                 )
4870         else
4871 #               echo ".hy 0"
4872                 cat \$TMP
4873         fi
4874         ;;
4875 esac
4876 done
4877
4878 if test $cf_inboth = yes ; then
4879 if test \$form != format ; then
4880         $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
4881 fi
4882 fi
4883
4884 exit 0
4885 CF_EOF
4886 chmod 755 $cf_edit_man
4887
4888 ])dnl
4889 dnl ---------------------------------------------------------------------------
4890 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4891 dnl -----------
4892 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4893 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4894 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4895 AC_DEFUN([CF_MATH_LIB],
4896 [
4897 AC_CACHE_CHECK(if -lm needed for math functions,
4898         cf_cv_need_libm,[
4899         AC_TRY_LINK([
4900         #include <stdio.h>
4901         #include <math.h>
4902         ],
4903         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4904         [cf_cv_need_libm=no],
4905         [cf_cv_need_libm=yes])])
4906 if test "$cf_cv_need_libm" = yes
4907 then
4908 ifelse($1,,[
4909         CF_ADD_LIB(m)
4910 ],[$1=-lm])
4911 fi
4912 ])
4913 dnl ---------------------------------------------------------------------------
4914 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
4915 dnl ----------------------
4916 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4917 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4918 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4919 [
4920 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4921 if test "$cross_compiling" = yes ; then
4922         case $target_alias in
4923         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
4924                 cf_cv_mixedcase=no
4925                 ;;
4926         (*)
4927                 cf_cv_mixedcase=yes
4928                 ;;
4929         esac
4930 else
4931         rm -f conftest CONFTEST
4932         echo test >conftest
4933         if test -f CONFTEST ; then
4934                 cf_cv_mixedcase=no
4935         else
4936                 cf_cv_mixedcase=yes
4937         fi
4938         rm -f conftest CONFTEST
4939 fi
4940 ])
4941 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
4942 ])dnl
4943 dnl ---------------------------------------------------------------------------
4944 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
4945 dnl ----------
4946 dnl Check for a working mkstemp.  This creates two files, checks that they are
4947 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4948 AC_DEFUN([CF_MKSTEMP],[
4949 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4950 rm -rf conftest*
4951 AC_TRY_RUN([
4952 #include <sys/types.h>
4953 #include <stdlib.h>
4954 #include <stdio.h>
4955 #include <string.h>
4956 #include <sys/stat.h>
4957 int main()
4958 {
4959         char *tmpl = "conftestXXXXXX";
4960         char name[2][80];
4961         int n;
4962         int result = 0;
4963         int fd;
4964         struct stat sb;
4965
4966         umask(077);
4967         for (n = 0; n < 2; ++n) {
4968                 strcpy(name[n], tmpl);
4969                 if ((fd = mkstemp(name[n])) >= 0) {
4970                         if (!strcmp(name[n], tmpl)
4971                          || stat(name[n], &sb) != 0
4972                          || (sb.st_mode & S_IFMT) != S_IFREG
4973                          || (sb.st_mode & 077) != 0) {
4974                                 result = 1;
4975                         }
4976                         close(fd);
4977                 }
4978         }
4979         if (result == 0
4980          && !strcmp(name[0], name[1]))
4981                 result = 1;
4982         ${cf_cv_main_return:-return}(result);
4983 }
4984 ],[cf_cv_func_mkstemp=yes
4985 ],[cf_cv_func_mkstemp=no
4986 ],[cf_cv_func_mkstemp=maybe])
4987 ])
4988 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
4989         AC_CHECK_FUNC(mkstemp)
4990 fi
4991 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4992         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
4993 fi
4994 ])dnl
4995 dnl ---------------------------------------------------------------------------
4996 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4997 dnl ----------
4998 dnl Write a debug message to config.log, along with the line number in the
4999 dnl configure script.
5000 AC_DEFUN([CF_MSG_LOG],[
5001 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
5002 ])dnl
5003 dnl ---------------------------------------------------------------------------
5004 dnl CF_NCURSES_ABI_6 version: 3 updated: 2015/06/06 16:10:11
5005 dnl ----------------
5006 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
5007 dnl warn about this.
5008 AC_DEFUN([CF_NCURSES_ABI_6],[
5009 if test "${with_abi_version+set}" != set; then
5010         case $cf_cv_rel_version in
5011         (5.*)
5012                 cf_cv_rel_version=6.0
5013                 cf_cv_abi_version=6
5014                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_version)
5015                 ;;
5016         esac
5017 fi
5018 ])dnl
5019 dnl ---------------------------------------------------------------------------
5020 dnl CF_NCURSES_WITH_ABI_VERSION version: 2 updated: 2015/12/19 17:51:52
5021 dnl ---------------------------
5022 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
5023 dnl packager has incremented the ABI past that used in the original package,
5024 dnl and wishes to keep doing this.
5025 dnl
5026 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
5027 dnl symbol.
5028 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
5029 CF_WITH_ABI_VERSION($1)
5030 if test "x$cf_cv_abi_version" != "x$with_abi_version"
5031 then
5032         case $cf_cv_rel_version in
5033         (5.*)
5034                 cf_cv_rel_version=$with_abi_version.0
5035                 ;;
5036         esac
5037 fi
5038 ])dnl
5039 dnl ---------------------------------------------------------------------------
5040 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
5041 dnl ------------------
5042 dnl see CF_WITH_NO_LEAKS
5043 AC_DEFUN([CF_NO_LEAKS_OPTION],[
5044 AC_MSG_CHECKING(if you want to use $1 for testing)
5045 AC_ARG_WITH($1,
5046         [$2],
5047         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
5048          $4
5049 ])
5050         : ${with_cflags:=-g}
5051         : ${with_no_leaks:=yes}
5052          with_$1=yes],
5053         [with_$1=])
5054 AC_MSG_RESULT(${with_$1:-no})
5055
5056 case .$with_cflags in
5057 (.*-g*)
5058         case .$CFLAGS in
5059         (.*-g*)
5060                 ;;
5061         (*)
5062                 CF_ADD_CFLAGS([-g])
5063                 ;;
5064         esac
5065         ;;
5066 esac
5067 ])dnl
5068 dnl ---------------------------------------------------------------------------
5069 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
5070 dnl ----------------
5071 dnl Check if the given variable is a number.  If not, report an error.
5072 dnl $1 is the variable
5073 dnl $2 is the message
5074 AC_DEFUN([CF_NUMBER_SYNTAX],[
5075 if test -n "$1" ; then
5076   case $1 in
5077   ([[0-9]]*)
5078         ;;
5079   (*)
5080         AC_MSG_ERROR($2 is not a number: $1)
5081         ;;
5082   esac
5083 else
5084   AC_MSG_ERROR($2 value is empty)
5085 fi
5086 ])dnl
5087 dnl ---------------------------------------------------------------------------
5088 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
5089 dnl -------------
5090 dnl Compute the object-directory name from the given model name
5091 AC_DEFUN([CF_OBJ_SUBDIR],
5092 [
5093         case $1 in
5094         (libtool) $2='obj_lo'  ;;
5095         (normal)  $2='objects' ;;
5096         (debug)   $2='obj_g' ;;
5097         (profile) $2='obj_p' ;;
5098         (shared)
5099                 case $cf_cv_system_name in
5100                 (cygwin|msys)
5101                         $2='objects' ;;
5102                 (*)
5103                         $2='obj_s' ;;
5104                 esac
5105         esac
5106 ])dnl
5107 dnl ---------------------------------------------------------------------------
5108 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
5109 dnl ----------
5110 dnl Provide a value for the $PATH and similar separator (or amend the value
5111 dnl as provided in autoconf 2.5x).
5112 AC_DEFUN([CF_PATHSEP],
5113 [
5114         AC_MSG_CHECKING(for PATH separator)
5115         case $cf_cv_system_name in
5116         (os2*)  PATH_SEPARATOR=';'  ;;
5117         (*)     ${PATH_SEPARATOR:=':'}  ;;
5118         esac
5119 ifelse([$1],,,[$1=$PATH_SEPARATOR])
5120         AC_SUBST(PATH_SEPARATOR)
5121         AC_MSG_RESULT($PATH_SEPARATOR)
5122 ])dnl
5123 dnl ---------------------------------------------------------------------------
5124 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
5125 dnl --------------
5126 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
5127 dnl begins with one of the prefix/exec_prefix variables, and then again if the
5128 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
5129 dnl delayed evaluation of those symbols.
5130 AC_DEFUN([CF_PATH_SYNTAX],[
5131 if test "x$prefix" != xNONE; then
5132         cf_path_syntax="$prefix"
5133 else
5134         cf_path_syntax="$ac_default_prefix"
5135 fi
5136
5137 case ".[$]$1" in
5138 (.\[$]\(*\)*|.\'*\'*)
5139         ;;
5140 (..|./*|.\\*)
5141         ;;
5142 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
5143         ;;
5144 (.\[$]{*prefix}*|.\[$]{*dir}*)
5145         eval $1="[$]$1"
5146         case ".[$]$1" in
5147         (.NONE/*)
5148                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5149                 ;;
5150         esac
5151         ;;
5152 (.no|.NONE/*)
5153         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5154         ;;
5155 (*)
5156         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
5157         ;;
5158 esac
5159 ])dnl
5160 dnl ---------------------------------------------------------------------------
5161 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
5162 dnl -------------
5163 dnl Check for the package-config program, unless disabled by command-line.
5164 AC_DEFUN([CF_PKG_CONFIG],
5165 [
5166 AC_MSG_CHECKING(if you want to use pkg-config)
5167 AC_ARG_WITH(pkg-config,
5168         [  --with-pkg-config{=path} enable/disable use of pkg-config],
5169         [cf_pkg_config=$withval],
5170         [cf_pkg_config=yes])
5171 AC_MSG_RESULT($cf_pkg_config)
5172
5173 case $cf_pkg_config in
5174 (no)
5175         PKG_CONFIG=none
5176         ;;
5177 (yes)
5178         CF_ACVERSION_CHECK(2.52,
5179                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
5180                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
5181         ;;
5182 (*)
5183         PKG_CONFIG=$withval
5184         ;;
5185 esac
5186
5187 test -z "$PKG_CONFIG" && PKG_CONFIG=none
5188 if test "$PKG_CONFIG" != none ; then
5189         CF_PATH_SYNTAX(PKG_CONFIG)
5190 elif test "x$cf_pkg_config" != xno ; then
5191         AC_MSG_WARN(pkg-config is not installed)
5192 fi
5193
5194 AC_SUBST(PKG_CONFIG)
5195 ])dnl
5196 dnl ---------------------------------------------------------------------------
5197 dnl CF_POSIX_C_SOURCE version: 9 updated: 2015/04/12 15:39:00
5198 dnl -----------------
5199 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
5200 dnl
5201 dnl     POSIX.1-1990                            _POSIX_SOURCE
5202 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
5203 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
5204 dnl             Bindings Option
5205 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
5206 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
5207 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
5208 dnl
5209 dnl Parameters:
5210 dnl     $1 is the nominal value for _POSIX_C_SOURCE
5211 AC_DEFUN([CF_POSIX_C_SOURCE],
5212 [
5213 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
5214
5215 cf_save_CFLAGS="$CFLAGS"
5216 cf_save_CPPFLAGS="$CPPFLAGS"
5217
5218 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
5219 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
5220
5221 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
5222         CF_MSG_LOG(if the symbol is already defined go no further)
5223         AC_TRY_COMPILE([#include <sys/types.h>],[
5224 #ifndef _POSIX_C_SOURCE
5225 make an error
5226 #endif],
5227         [cf_cv_posix_c_source=no],
5228         [cf_want_posix_source=no
5229          case .$cf_POSIX_C_SOURCE in
5230          (.[[12]]??*)
5231                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5232                 ;;
5233          (.2)
5234                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5235                 cf_want_posix_source=yes
5236                 ;;
5237          (.*)
5238                 cf_want_posix_source=yes
5239                 ;;
5240          esac
5241          if test "$cf_want_posix_source" = yes ; then
5242                 AC_TRY_COMPILE([#include <sys/types.h>],[
5243 #ifdef _POSIX_SOURCE
5244 make an error
5245 #endif],[],
5246                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
5247          fi
5248          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
5249          CFLAGS="$cf_trim_CFLAGS"
5250          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
5251          CF_MSG_LOG(if the second compile does not leave our definition intact error)
5252          AC_TRY_COMPILE([#include <sys/types.h>],[
5253 #ifndef _POSIX_C_SOURCE
5254 make an error
5255 #endif],,
5256          [cf_cv_posix_c_source=no])
5257          CFLAGS="$cf_save_CFLAGS"
5258          CPPFLAGS="$cf_save_CPPFLAGS"
5259         ])
5260 ])
5261
5262 if test "$cf_cv_posix_c_source" != no ; then
5263         CFLAGS="$cf_trim_CFLAGS"
5264         CPPFLAGS="$cf_trim_CPPFLAGS"
5265         CF_ADD_CFLAGS($cf_cv_posix_c_source)
5266 fi
5267
5268 ])dnl
5269 dnl ---------------------------------------------------------------------------
5270 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
5271 dnl ------------
5272 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
5273 dnl
5274 dnl $1 = symbol to test
5275 dnl $2 = value (if any) to use for a predefinition
5276 AC_DEFUN([CF_PREDEFINE],
5277 [
5278 AC_MSG_CHECKING(if we must define $1)
5279 AC_TRY_COMPILE([#include <sys/types.h>
5280 ],[
5281 #ifndef $1
5282 make an error
5283 #endif],[cf_result=no],[cf_result=yes])
5284 AC_MSG_RESULT($cf_result)
5285
5286 if test "$cf_result" = yes ; then
5287         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
5288 elif test "x$2" != "x" ; then
5289         AC_MSG_CHECKING(checking for compatible value versus $2)
5290         AC_TRY_COMPILE([#include <sys/types.h>
5291 ],[
5292 #if $1-$2 < 0
5293 make an error
5294 #endif],[cf_result=yes],[cf_result=no])
5295         AC_MSG_RESULT($cf_result)
5296         if test "$cf_result" = no ; then
5297                 # perhaps we can override it - try...
5298                 CPPFLAGS="$CPPFLAGS -D$1=$2"
5299         fi
5300 fi
5301 ])dnl
5302 dnl ---------------------------------------------------------------------------
5303 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
5304 dnl ------------
5305 dnl Append definitions and rules for the given programs to the subdirectory
5306 dnl Makefiles, and the recursion rule for the top-level Makefile.
5307 dnl
5308 dnl parameters
5309 dnl     $1 = script to run
5310 dnl     $2 = list of subdirectories
5311 dnl
5312 dnl variables
5313 dnl     $AWK
5314 AC_DEFUN([CF_PRG_RULES],
5315 [
5316 for cf_dir in $2
5317 do
5318         if test ! -d $srcdir/$cf_dir; then
5319                 continue
5320         elif test -f $srcdir/$cf_dir/programs; then
5321                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
5322         fi
5323 done
5324
5325 ])dnl
5326 dnl ---------------------------------------------------------------------------
5327 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
5328 dnl ----------
5329 dnl Check for archiver "ar".
5330 AC_DEFUN([CF_PROG_AR],[
5331 AC_CHECK_TOOL(AR, ar, ar)
5332 ])
5333 dnl ---------------------------------------------------------------------------
5334 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
5335 dnl -----------
5336 dnl Check for awk, ensure that the check found something.
5337 AC_DEFUN([CF_PROG_AWK],
5338 [
5339 AC_PROG_AWK
5340 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
5341 ])dnl
5342 dnl ---------------------------------------------------------------------------
5343 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
5344 dnl ----------
5345 dnl standard check for CC, plus followup sanity checks
5346 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
5347 AC_DEFUN([CF_PROG_CC],[
5348 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
5349 CF_GCC_VERSION
5350 CF_ACVERSION_CHECK(2.52,
5351         [AC_PROG_CC_STDC],
5352         [CF_ANSI_CC_REQD])
5353 CF_CC_ENV_FLAGS
5354 ])dnl
5355 dnl ---------------------------------------------------------------------------
5356 dnl CF_PROG_CC_C_O version: 4 updated: 2016/05/21 18:08:09
5357 dnl --------------
5358 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
5359 dnl the output file can be renamed, and allows for a shell variable that can
5360 dnl be used later.  The parameter is either CC or CXX.  The result is the
5361 dnl cache variable:
5362 dnl     $cf_cv_prog_CC_c_o
5363 dnl     $cf_cv_prog_CXX_c_o
5364 dnl
5365 dnl $1 = compiler
5366 dnl $2 = compiler options, if any
5367 AC_DEFUN([CF_PROG_CC_C_O],
5368 [AC_REQUIRE([AC_PROG_CC])dnl
5369 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
5370 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
5371 [
5372 cat > conftest.$ac_ext <<CF_EOF
5373 int main()
5374 {
5375         ${cf_cv_main_return:-return}(0);
5376 }
5377 CF_EOF
5378 # We do the test twice because some compilers refuse to overwrite an
5379 # existing .o file with -o, though they will create one.
5380 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
5381 if AC_TRY_EVAL(ac_try) &&
5382   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
5383 then
5384   eval cf_cv_prog_$1_c_o=yes
5385 else
5386   eval cf_cv_prog_$1_c_o=no
5387 fi
5388 rm -rf conftest*
5389 ])dnl
5390 if test $cf_cv_prog_$1_c_o = yes; then
5391   AC_MSG_RESULT([yes])
5392 else
5393   AC_MSG_RESULT([no])
5394 fi
5395 ])dnl
5396 dnl ---------------------------------------------------------------------------
5397 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
5398 dnl -------------
5399 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
5400 dnl This macro adds a check to ensure the script found something.
5401 AC_DEFUN([CF_PROG_EGREP],
5402 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
5403         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
5404                 then ac_cv_prog_egrep='grep -E'
5405                 else ac_cv_prog_egrep='egrep'
5406         fi])
5407         EGREP=$ac_cv_prog_egrep
5408         AC_SUBST([EGREP])
5409         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
5410 ])dnl
5411 dnl ---------------------------------------------------------------------------
5412 dnl CF_PROG_GNAT version: 3 updated: 2015/04/18 08:56:57
5413 dnl ------------
5414 dnl Check for gnatmake, ensure that it is complete.
5415 AC_DEFUN([CF_PROG_GNAT],[
5416 cf_ada_make=gnatmake
5417 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
5418 if test "$ac_cv_prog_gnat_exists" = no; then
5419         cf_ada_make=
5420         cf_cv_prog_gnat_correct=no
5421 else
5422         CF_GNAT_VERSION
5423         AC_CHECK_PROG(M4_exists, m4, yes, no)
5424         if test "$ac_cv_prog_M4_exists" = no; then
5425                 cf_cv_prog_gnat_correct=no
5426                 echo Ada95 binding required program m4 not found. Ada95 binding disabled.
5427         fi
5428         if test "$cf_cv_prog_gnat_correct" = yes; then
5429                 AC_MSG_CHECKING(if GNAT works)
5430                 CF_GNAT_TRY_RUN([procedure conftest;],
5431 [with Text_IO;
5432 with GNAT.OS_Lib;
5433 procedure conftest is
5434 begin
5435    Text_IO.Put ("Hello World");
5436    Text_IO.New_Line;
5437    GNAT.OS_Lib.OS_Exit (0);
5438 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
5439                 AC_MSG_RESULT($cf_cv_prog_gnat_correct)
5440         fi
5441 fi
5442
5443 AC_SUBST(cf_ada_make)
5444 ])dnl
5445 dnl ---------------------------------------------------------------------------
5446 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
5447 dnl ---------------
5448 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
5449 dnl misc/tabset install won't work properly.  Usually this happens only when
5450 dnl using the fallback mkinstalldirs script
5451 AC_DEFUN([CF_PROG_INSTALL],
5452 [AC_PROG_INSTALL
5453 case $INSTALL in
5454 (/*)
5455         ;;
5456 (*)
5457         CF_DIRNAME(cf_dir,$INSTALL)
5458         test -z "$cf_dir" && cf_dir=.
5459         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
5460         ;;
5461 esac
5462 ])dnl
5463 dnl ---------------------------------------------------------------------------
5464 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
5465 dnl ----------------
5466 dnl Check for ldconfig, needed to fixup shared libraries that would be built
5467 dnl and then used in the install.
5468 AC_DEFUN([CF_PROG_LDCONFIG],[
5469 if test "$cross_compiling" = yes ; then
5470         LDCONFIG=:
5471 else
5472         case "$cf_cv_system_name" in
5473         (dragonfly*|mirbsd*|freebsd*)
5474                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
5475                 ;;
5476         (*) LDPATH=$PATH:/sbin:/usr/sbin
5477                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
5478                 ;;
5479         esac
5480 fi
5481 AC_SUBST(LDCONFIG)
5482 ])dnl
5483 dnl ---------------------------------------------------------------------------
5484 dnl CF_PROG_LINT version: 3 updated: 2016/05/22 15:25:54
5485 dnl ------------
5486 AC_DEFUN([CF_PROG_LINT],
5487 [
5488 AC_CHECK_PROGS(LINT, lint cppcheck splint)
5489 AC_SUBST(LINT_OPTS)
5490 ])dnl
5491 dnl ---------------------------------------------------------------------------
5492 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
5493 dnl ------------
5494 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
5495 dnl option if it is supported.
5496 AC_DEFUN([CF_PROG_LN_S],[
5497 AC_PROG_LN_S
5498 AC_MSG_CHECKING(if $LN_S -f options work)
5499
5500 rm -f conf$$.src conf$$dst
5501 echo >conf$$.dst
5502 echo first >conf$$.src
5503 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
5504         cf_prog_ln_sf=yes
5505 else
5506         cf_prog_ln_sf=no
5507 fi
5508 rm -f conf$$.dst conf$$src
5509 AC_MSG_RESULT($cf_prog_ln_sf)
5510
5511 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
5512 ])dnl
5513 dnl ---------------------------------------------------------------------------
5514 dnl CF_REGEX version: 12 updated: 2015/04/18 08:56:57
5515 dnl --------
5516 dnl Attempt to determine if we've got one of the flavors of regular-expression
5517 dnl code that we can support.
5518 AC_DEFUN([CF_REGEX],
5519 [
5520
5521 cf_regex_func=no
5522
5523 cf_regex_libs="regex re"
5524 case $host_os in
5525 (mingw*)
5526         cf_regex_libs="gnurx $cf_regex_libs"
5527         ;;
5528 esac
5529
5530 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5531         for cf_regex_lib in $cf_regex_libs
5532         do
5533                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5534                                 CF_ADD_LIB($cf_regex_lib)
5535                                 cf_regex_func=regcomp
5536                                 break])
5537         done
5538 ])
5539
5540 if test "$cf_regex_func" = no ; then
5541         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5542                 AC_CHECK_LIB(gen,compile,[
5543                                 CF_ADD_LIB(gen)
5544                                 cf_regex_func=compile])])
5545 fi
5546
5547 if test "$cf_regex_func" = no ; then
5548         AC_MSG_WARN(cannot find regular expression library)
5549 fi
5550
5551 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5552
5553 cf_cv_regex_hdrs=no
5554 case $cf_regex_func in
5555 (compile)
5556         for cf_regex_hdr in regexp.h regexpr.h
5557         do
5558                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5559                         char *p = compile("", "", "", 0);
5560                         int x = step("", "");
5561                 ],[
5562                         cf_cv_regex_hdrs=$cf_regex_hdr
5563                         break
5564                 ])
5565         done
5566         ;;
5567 (*)
5568         for cf_regex_hdr in regex.h
5569         do
5570                 AC_TRY_LINK([#include <sys/types.h>
5571 #include <$cf_regex_hdr>],[
5572                         regex_t *p;
5573                         int x = regcomp(p, "", 0);
5574                         int y = regexec(p, "", 0, 0, 0);
5575                         regfree(p);
5576                 ],[
5577                         cf_cv_regex_hdrs=$cf_regex_hdr
5578                         break
5579                 ])
5580         done
5581         ;;
5582 esac
5583
5584 ])
5585
5586 case $cf_cv_regex_hdrs in
5587         (no)            AC_MSG_WARN(no regular expression header found) ;;
5588         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
5589         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
5590         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
5591 esac
5592 ])dnl
5593 dnl ---------------------------------------------------------------------------
5594 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5595 dnl ----------------
5596 dnl Remove all -U and -D options that refer to the given symbol from a list
5597 dnl of C compiler options.  This works around the problem that not all
5598 dnl compilers process -U and -D options from left-to-right, so a -U option
5599 dnl cannot be used to cancel the effect of a preceding -D option.
5600 dnl
5601 dnl $1 = target (which could be the same as the source variable)
5602 dnl $2 = source (including '$')
5603 dnl $3 = symbol to remove
5604 define([CF_REMOVE_DEFINE],
5605 [
5606 $1=`echo "$2" | \
5607         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5608                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5609 ])dnl
5610 dnl ---------------------------------------------------------------------------
5611 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5612 dnl -------------
5613 dnl Remove the given library from the symbol
5614 dnl
5615 dnl $1 = target (which could be the same as the source variable)
5616 dnl $2 = source (including '$')
5617 dnl $3 = library to remove
5618 define([CF_REMOVE_LIB],
5619 [
5620 # remove $3 library from $2
5621 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5622 ])dnl
5623 dnl ---------------------------------------------------------------------------
5624 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
5625 dnl -------------
5626 AC_DEFUN([CF_RPATH_HACK],
5627 [
5628 AC_REQUIRE([CF_LD_RPATH_OPT])
5629 AC_MSG_CHECKING(for updated LDFLAGS)
5630 if test -n "$LD_RPATH_OPT" ; then
5631         AC_MSG_RESULT(maybe)
5632
5633         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5634         cf_rpath_list="/usr/lib /lib"
5635         if test "$cf_ldd_prog" != no
5636         then
5637                 cf_rpath_oops=
5638
5639 AC_TRY_LINK([#include <stdio.h>],
5640                 [printf("Hello");],
5641                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
5642                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
5643
5644                 # If we passed the link-test, but get a "not found" on a given library,
5645                 # this could be due to inept reconfiguration of gcc to make it only
5646                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5647                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5648                 # /usr/local libraries.
5649                 if test -n "$cf_rpath_oops"
5650                 then
5651                         for cf_rpath_src in $cf_rpath_oops
5652                         do
5653                                 for cf_rpath_dir in \
5654                                         /usr/local \
5655                                         /usr/pkg \
5656                                         /opt/sfw
5657                                 do
5658                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5659                                         then
5660                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5661                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5662                                                 break
5663                                         fi
5664                                 done
5665                         done
5666                 fi
5667         fi
5668
5669         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5670
5671         CF_RPATH_HACK_2(LDFLAGS)
5672         CF_RPATH_HACK_2(LIBS)
5673
5674         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5675 else
5676         AC_MSG_RESULT(no)
5677 fi
5678 AC_SUBST(EXTRA_LDFLAGS)
5679 ])dnl
5680 dnl ---------------------------------------------------------------------------
5681 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
5682 dnl ---------------
5683 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5684 dnl EXTRA_LDFLAGS for each -L option found.
5685 dnl
5686 dnl $cf_rpath_list contains a list of directories to ignore.
5687 dnl
5688 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5689 dnl      but LIBS often has misplaced -L options.
5690 AC_DEFUN([CF_RPATH_HACK_2],
5691 [
5692 CF_VERBOSE(...checking $1 [$]$1)
5693
5694 cf_rpath_dst=
5695 for cf_rpath_src in [$]$1
5696 do
5697         case $cf_rpath_src in
5698         (-L*)
5699
5700                 # check if this refers to a directory which we will ignore
5701                 cf_rpath_skip=no
5702                 if test -n "$cf_rpath_list"
5703                 then
5704                         for cf_rpath_item in $cf_rpath_list
5705                         do
5706                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5707                                 then
5708                                         cf_rpath_skip=yes
5709                                         break
5710                                 fi
5711                         done
5712                 fi
5713
5714                 if test "$cf_rpath_skip" = no
5715                 then
5716                         # transform the option
5717                         if test "$LD_RPATH_OPT" = "-R " ; then
5718                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5719                         else
5720                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5721                         fi
5722
5723                         # if we have not already added this, add it now
5724                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5725                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5726                         then
5727                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5728                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5729                         fi
5730                 fi
5731                 ;;
5732         esac
5733         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5734 done
5735 $1=$cf_rpath_dst
5736
5737 CF_VERBOSE(...checked $1 [$]$1)
5738 AC_SUBST(EXTRA_LDFLAGS)
5739 ])dnl
5740 dnl ---------------------------------------------------------------------------
5741 dnl CF_SHARED_OPTS version: 89 updated: 2015/08/15 18:38:59
5742 dnl --------------
5743 dnl --------------
5744 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5745 dnl library.
5746 dnl
5747 dnl Notes:
5748 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
5749 dnl the build-tree, i.e., by making use of the libraries that are compiled in
5750 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
5751 dnl shared library since that can lead to unexpected results at runtime.
5752 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
5753 dnl libraries are compiled in ../../lib
5754 dnl
5755 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5756 dnl to install symbolic links to the rel/abi versions of shared libraries.
5757 dnl
5758 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5759 dnl version when making symbolic links.
5760 dnl
5761 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5762 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5763 dnl (ex: libncurses.so.<ver>).
5764 dnl
5765 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5766 AC_DEFUN([CF_SHARED_OPTS],
5767 [
5768         AC_REQUIRE([CF_LD_RPATH_OPT])
5769         RM_SHARED_OPTS=
5770         LOCAL_LDFLAGS=
5771         LOCAL_LDFLAGS2=
5772         LD_SHARED_OPTS=
5773         INSTALL_LIB="-m 644"
5774         : ${rel_builddir:=.}
5775
5776         shlibdir=$libdir
5777         AC_SUBST(shlibdir)
5778
5779         MAKE_DLLS="#"
5780         AC_SUBST(MAKE_DLLS)
5781
5782         cf_cv_do_symlinks=no
5783         cf_ld_rpath_opt=
5784         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5785
5786         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5787         AC_ARG_WITH(shlib-version,
5788         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5789         [test -z "$withval" && withval=auto
5790         case $withval in
5791         (yes)
5792                 cf_cv_shlib_version=auto
5793                 ;;
5794         (rel|abi|auto)
5795                 cf_cv_shlib_version=$withval
5796                 ;;
5797         (*)
5798                 AC_MSG_RESULT($withval)
5799                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
5800                 ;;
5801         esac
5802         ],[cf_cv_shlib_version=auto])
5803         AC_MSG_RESULT($cf_cv_shlib_version)
5804
5805         cf_cv_rm_so_locs=no
5806         cf_try_cflags=
5807
5808         # Some less-capable ports of gcc support only -fpic
5809         CC_SHARED_OPTS=
5810         if test "$GCC" = yes
5811         then
5812                 AC_MSG_CHECKING(which $CC option to use)
5813                 cf_save_CFLAGS="$CFLAGS"
5814                 for CC_SHARED_OPTS in -fPIC -fpic ''
5815                 do
5816                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5817                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5818                 done
5819                 AC_MSG_RESULT($CC_SHARED_OPTS)
5820                 CFLAGS="$cf_save_CFLAGS"
5821         fi
5822
5823         cf_cv_shlib_version_infix=no
5824
5825         case $cf_cv_system_name in
5826         (aix4.[3-9]*|aix[[5-7]]*)
5827                 if test "$GCC" = yes; then
5828                         CC_SHARED_OPTS='-Wl,-brtl'
5829                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5830                 else
5831                         CC_SHARED_OPTS='-brtl'
5832                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
5833                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5834                 fi
5835                 ;;
5836         (beos*)
5837                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5838                 ;;
5839         (cygwin*)
5840                 CC_SHARED_OPTS=
5841                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5842                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5843                 cf_cv_shlib_version=cygdll
5844                 cf_cv_shlib_version_infix=cygdll
5845                 shlibdir=$bindir
5846                 MAKE_DLLS=
5847                 cat >mk_shared_lib.sh <<-CF_EOF
5848                 #!$SHELL
5849                 SHARED_LIB=\[$]1
5850                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5851                 shift
5852                 cat <<-EOF
5853                 Linking shared library
5854                 ** SHARED_LIB \[$]SHARED_LIB
5855                 ** IMPORT_LIB \[$]IMPORT_LIB
5856 EOF
5857                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5858 CF_EOF
5859                 chmod +x mk_shared_lib.sh
5860                 ;;
5861         (msys*)
5862                 CC_SHARED_OPTS=
5863                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5864                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5865                 cf_cv_shlib_version=msysdll
5866                 cf_cv_shlib_version_infix=msysdll
5867                 shlibdir=$bindir
5868                 MAKE_DLLS=
5869                 cat >mk_shared_lib.sh <<-CF_EOF
5870                 #!$SHELL
5871                 SHARED_LIB=\[$]1
5872                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5873                 shift
5874                 cat <<-EOF
5875                 Linking shared library
5876                 ** SHARED_LIB \[$]SHARED_LIB
5877                 ** IMPORT_LIB \[$]IMPORT_LIB
5878 EOF
5879                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5880 CF_EOF
5881                 chmod +x mk_shared_lib.sh
5882                 ;;
5883         (darwin*)
5884                 cf_try_cflags="no-cpp-precomp"
5885                 CC_SHARED_OPTS="-dynamic"
5886                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5887                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5888                 cf_cv_shlib_version_infix=yes
5889                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5890                         cf_save_LDFLAGS=$LDFLAGS
5891                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5892                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5893                                 LDFLAGS=$cf_save_LDFLAGS])
5894                 if test $cf_cv_ldflags_search_paths_first = yes; then
5895                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5896                 fi
5897                 ;;
5898         (hpux[[7-8]]*)
5899                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
5900                 if test "$GCC" != yes; then
5901                         CC_SHARED_OPTS='+Z'
5902                 fi
5903                 MK_SHARED_LIB='${LD} -b -o $[@]'
5904                 INSTALL_LIB="-m 555"
5905                 ;;
5906         (hpux*)
5907                 # (tested with gcc 2.7.2 -- I don't have c89)
5908                 if test "$GCC" = yes; then
5909                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5910                 else
5911                         CC_SHARED_OPTS='+Z'
5912                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5913                 fi
5914                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5915                 # HP-UX shared libraries must be executable, and should be
5916                 # readonly to exploit a quirk in the memory manager.
5917                 INSTALL_LIB="-m 555"
5918                 ;;
5919         (interix*)
5920                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5921                 if test "$cf_cv_shlib_version" = rel; then
5922                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5923                 else
5924                         cf_shared_soname='`basename $@`'
5925                 fi
5926                 CC_SHARED_OPTS=
5927                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5928                 ;;
5929         (irix*)
5930                 if test "$cf_cv_enable_rpath" = yes ; then
5931                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5932                 fi
5933                 # tested with IRIX 5.2 and 'cc'.
5934                 if test "$GCC" != yes; then
5935                         CC_SHARED_OPTS='-KPIC'
5936                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5937                 else
5938                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5939                 fi
5940                 cf_cv_rm_so_locs=yes
5941                 ;;
5942         (linux*|gnu*|k*bsd*-gnu)
5943                 if test "$DFT_LWR_MODEL" = "shared" ; then
5944                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5945                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5946                 fi
5947                 if test "$cf_cv_enable_rpath" = yes ; then
5948                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5949                 fi
5950                 CF_SHARED_SONAME
5951                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5952                 ;;
5953         (mingw*)
5954                 cf_cv_shlib_version=mingw
5955                 cf_cv_shlib_version_infix=mingw
5956                 shlibdir=$bindir
5957                 MAKE_DLLS=
5958                 if test "$DFT_LWR_MODEL" = "shared" ; then
5959                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
5960                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5961                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
5962                 fi
5963                 CC_SHARED_OPTS=
5964                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5965                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5966                 cat >mk_shared_lib.sh <<-CF_EOF
5967                 #!$SHELL
5968                 SHARED_LIB=\[$]1
5969                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5970                 shift
5971                 cat <<-EOF
5972                 Linking shared library
5973                 ** SHARED_LIB \[$]SHARED_LIB
5974                 ** IMPORT_LIB \[$]IMPORT_LIB
5975 EOF
5976                 exec \[$]* -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5977 CF_EOF
5978                 chmod +x mk_shared_lib.sh
5979                 ;;
5980         (openbsd[[2-9]].*|mirbsd*)
5981                 if test "$DFT_LWR_MODEL" = "shared" ; then
5982                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5983                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5984                 fi
5985                 if test "$cf_cv_enable_rpath" = yes ; then
5986                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5987                 fi
5988                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5989                 CF_SHARED_SONAME
5990                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5991                 ;;
5992         (nto-qnx*|openbsd*|freebsd[[12]].*)
5993                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5994                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5995                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5996                 ;;
5997         (dragonfly*|freebsd*)
5998                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5999                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
6000                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
6001                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
6002                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6003                 fi
6004                 CF_SHARED_SONAME
6005                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6006                 ;;
6007         (netbsd*)
6008                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6009                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
6010                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
6011                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6012                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6013                         if test "$cf_cv_shlib_version" = auto; then
6014                         if test -f /usr/libexec/ld.elf_so; then
6015                                 cf_cv_shlib_version=abi
6016                         else
6017                                 cf_cv_shlib_version=rel
6018                         fi
6019                         fi
6020                         CF_SHARED_SONAME
6021                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
6022                 else
6023                         MK_SHARED_LIB='${CC} -Wl,-shared -Wl,-Bshareable -o $[@]'
6024                 fi
6025                 ;;
6026         (osf*|mls+*)
6027                 # tested with OSF/1 V3.2 and 'cc'
6028                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
6029                 # link with shared libs).
6030                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
6031                 case $host_os in
6032                 (osf4*)
6033                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
6034                         ;;
6035                 esac
6036                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
6037                 if test "$DFT_LWR_MODEL" = "shared" ; then
6038                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6039                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6040                 fi
6041                 cf_cv_rm_so_locs=yes
6042                 ;;
6043         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
6044                 # tested with osr5.0.5
6045                 if test "$GCC" != yes; then
6046                         CC_SHARED_OPTS='-belf -KPIC'
6047                 fi
6048                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
6049                 if test "$cf_cv_enable_rpath" = yes ; then
6050                         # only way is to set LD_RUN_PATH but no switch for it
6051                         RUN_PATH=$libdir
6052                 fi
6053                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6054                 LINK_PROGS='LD_RUN_PATH=${libdir}'
6055                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
6056                 ;;
6057         (sunos4*)
6058                 # tested with SunOS 4.1.1 and gcc 2.7.0
6059                 if test "$GCC" != yes; then
6060                         CC_SHARED_OPTS='-KPIC'
6061                 fi
6062                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
6063                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6064                 ;;
6065         (solaris2*)
6066                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
6067                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
6068                 if test "$DFT_LWR_MODEL" = "shared" ; then
6069                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
6070                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6071                 fi
6072                 if test "$cf_cv_enable_rpath" = yes ; then
6073                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
6074                 fi
6075                 CF_SHARED_SONAME
6076                 if test "$GCC" != yes; then
6077                         cf_save_CFLAGS="$CFLAGS"
6078                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
6079                         do
6080                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
6081                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
6082                         done
6083                         CFLAGS="$cf_save_CFLAGS"
6084                         CC_SHARED_OPTS=$cf_shared_opts
6085                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
6086                 else
6087                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
6088                 fi
6089                 ;;
6090         (sysv5uw7*|unix_sv*)
6091                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
6092                 if test "$GCC" != yes; then
6093                         CC_SHARED_OPTS='-KPIC'
6094                 fi
6095                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
6096                 ;;
6097         (*)
6098                 CC_SHARED_OPTS='unknown'
6099                 MK_SHARED_LIB='echo unknown'
6100                 ;;
6101         esac
6102
6103         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
6104         case "$cf_cv_shlib_version" in
6105         (rel|abi)
6106                 case "$MK_SHARED_LIB" in
6107                 (*'-o $[@]')
6108                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
6109                         ;;
6110                 (*)
6111                         AC_MSG_WARN(ignored --with-shlib-version)
6112                         ;;
6113                 esac
6114                 ;;
6115         esac
6116
6117         if test -n "$cf_try_cflags"
6118         then
6119 cat > conftest.$ac_ext <<EOF
6120 #line __oline__ "${as_me:-configure}"
6121 #include <stdio.h>
6122 int main(int argc, char *argv[[]])
6123 {
6124         printf("hello\n");
6125         return (argv[[argc-1]] == 0) ;
6126 }
6127 EOF
6128                 cf_save_CFLAGS="$CFLAGS"
6129                 for cf_opt in $cf_try_cflags
6130                 do
6131                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
6132                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
6133                         if AC_TRY_EVAL(ac_compile); then
6134                                 AC_MSG_RESULT(yes)
6135                                 cf_save_CFLAGS="$CFLAGS"
6136                         else
6137                                 AC_MSG_RESULT(no)
6138                         fi
6139                 done
6140                 CFLAGS="$cf_save_CFLAGS"
6141         fi
6142
6143
6144         # RPATH_LIST is a colon-separated list of directories
6145         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
6146         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
6147
6148         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
6149
6150         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
6151         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
6152
6153         AC_SUBST(CC_SHARED_OPTS)
6154         AC_SUBST(LD_RPATH_OPT)
6155         AC_SUBST(LD_SHARED_OPTS)
6156         AC_SUBST(MK_SHARED_LIB)
6157         AC_SUBST(RM_SHARED_OPTS)
6158
6159         AC_SUBST(LINK_PROGS)
6160         AC_SUBST(LINK_TESTS)
6161
6162         AC_SUBST(EXTRA_LDFLAGS)
6163         AC_SUBST(LOCAL_LDFLAGS)
6164         AC_SUBST(LOCAL_LDFLAGS2)
6165
6166         AC_SUBST(INSTALL_LIB)
6167         AC_SUBST(RPATH_LIST)
6168 ])dnl
6169 dnl ---------------------------------------------------------------------------
6170 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
6171 dnl ----------------
6172 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
6173 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
6174 dnl option.
6175 dnl
6176 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
6177 dnl If missing, use "rel".
6178 define([CF_SHARED_SONAME],
6179 [
6180         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
6181         if test "$cf_cv_shlib_version" = rel; then
6182                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
6183         else
6184                 cf_cv_shared_soname='`basename $[@]`'
6185         fi
6186 ])
6187 dnl ---------------------------------------------------------------------------
6188 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
6189 dnl -----------
6190 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
6191 dnl programs need this test).
6192 dnl
6193 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
6194 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
6195 dnl winsize declaration is left alone - we may revisit this if Apple choose to
6196 dnl break that part of the interface as well.
6197 AC_DEFUN([CF_SIGWINCH],
6198 [
6199 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
6200         AC_TRY_COMPILE([
6201 #include <sys/types.h>
6202 #include <sys/signal.h>
6203 ],[int x = SIGWINCH],
6204         [cf_cv_define_sigwinch=yes],
6205         [AC_TRY_COMPILE([
6206 #undef _XOPEN_SOURCE
6207 #undef _POSIX_SOURCE
6208 #undef _POSIX_C_SOURCE
6209 #include <sys/types.h>
6210 #include <sys/signal.h>
6211 ],[int x = SIGWINCH],
6212         [cf_cv_define_sigwinch=maybe],
6213         [cf_cv_define_sigwinch=no])
6214 ])
6215 ])
6216
6217 if test "$cf_cv_define_sigwinch" = maybe ; then
6218 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
6219 cf_cv_fixup_sigwinch=unknown
6220 cf_sigwinch=32
6221 while test $cf_sigwinch != 1
6222 do
6223         AC_TRY_COMPILE([
6224 #undef _XOPEN_SOURCE
6225 #undef _POSIX_SOURCE
6226 #undef _POSIX_C_SOURCE
6227 #include <sys/types.h>
6228 #include <sys/signal.h>
6229 ],[
6230 #if SIGWINCH != $cf_sigwinch
6231 make an error
6232 #endif
6233 int x = SIGWINCH],
6234         [cf_cv_fixup_sigwinch=$cf_sigwinch
6235          break])
6236
6237 cf_sigwinch=`expr $cf_sigwinch - 1`
6238 done
6239 ])
6240
6241         if test "$cf_cv_fixup_sigwinch" != unknown ; then
6242                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
6243         fi
6244 fi
6245 ])dnl
6246 dnl ---------------------------------------------------------------------------
6247 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
6248 dnl ---------------
6249 dnl signal handler, but there are some gcc depedencies in that recommendation.
6250 dnl Try anyway.
6251 AC_DEFUN([CF_SIG_ATOMIC_T],
6252 [
6253 AC_MSG_CHECKING(for signal global datatype)
6254 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
6255         for cf_type in \
6256                 "volatile sig_atomic_t" \
6257                 "sig_atomic_t" \
6258                 "int"
6259         do
6260         AC_TRY_COMPILE([
6261 #include <sys/types.h>
6262 #include <signal.h>
6263 #include <stdio.h>
6264
6265 extern $cf_type x;
6266 $cf_type x;
6267 static void handler(int sig)
6268 {
6269         x = 5;
6270 }],
6271                 [signal(SIGINT, handler);
6272                  x = 1],
6273                 [cf_cv_sig_atomic_t=$cf_type],
6274                 [cf_cv_sig_atomic_t=no])
6275                 test "$cf_cv_sig_atomic_t" != no && break
6276         done
6277         ])
6278 AC_MSG_RESULT($cf_cv_sig_atomic_t)
6279 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
6280 ])dnl
6281 dnl ---------------------------------------------------------------------------
6282 dnl CF_SIZECHANGE version: 11 updated: 2015/04/18 08:56:57
6283 dnl -------------
6284 dnl Check for definitions & structures needed for window size-changing
6285 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
6286 AC_DEFUN([CF_SIZECHANGE],
6287 [
6288 AC_REQUIRE([CF_STRUCT_TERMIOS])
6289 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
6290         cf_cv_sizechange=unknown
6291         cf_save_CPPFLAGS="$CPPFLAGS"
6292
6293 for cf_opts in "" "NEED_PTEM_H"
6294 do
6295
6296         CPPFLAGS="$cf_save_CPPFLAGS"
6297         test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
6298         AC_TRY_COMPILE([#include <sys/types.h>
6299 #ifdef HAVE_TERMIOS_H
6300 #include <termios.h>
6301 #else
6302 #ifdef HAVE_TERMIO_H
6303 #include <termio.h>
6304 #endif
6305 #endif
6306 #ifdef NEED_PTEM_H
6307 /* This is a workaround for SCO:  they neglected to define struct winsize in
6308  * termios.h -- it's only in termio.h and ptem.h
6309  */
6310 #include        <sys/stream.h>
6311 #include        <sys/ptem.h>
6312 #endif
6313 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
6314 #include <sys/ioctl.h>
6315 #endif
6316 ],[
6317 #ifdef TIOCGSIZE
6318         struct ttysize win;     /* FIXME: what system is this? */
6319         int y = win.ts_lines;
6320         int x = win.ts_cols;
6321 #else
6322 #ifdef TIOCGWINSZ
6323         struct winsize win;
6324         int y = win.ws_row;
6325         int x = win.ws_col;
6326 #else
6327         no TIOCGSIZE or TIOCGWINSZ
6328 #endif /* TIOCGWINSZ */
6329 #endif /* TIOCGSIZE */
6330         ],
6331         [cf_cv_sizechange=yes],
6332         [cf_cv_sizechange=no])
6333
6334         CPPFLAGS="$cf_save_CPPFLAGS"
6335         if test "$cf_cv_sizechange" = yes ; then
6336                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
6337                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
6338                 break
6339         fi
6340 done
6341 ])
6342 if test "$cf_cv_sizechange" != no ; then
6343         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechar declarations are provided])
6344         case $cf_cv_sizechange in
6345         (NEED*)
6346                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
6347                 ;;
6348         esac
6349 fi
6350 ])dnl
6351 dnl ---------------------------------------------------------------------------
6352 dnl CF_SRC_MODULES version: 29 updated: 2015/04/12 11:42:01
6353 dnl --------------
6354 dnl For each parameter, test if the source-directory exists, and if it contains
6355 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
6356 dnl use in CF_LIB_RULES.
6357 dnl
6358 dnl This uses the configured value to make the lists SRC_SUBDIRS and
6359 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
6360 AC_DEFUN([CF_SRC_MODULES],
6361 [
6362 AC_MSG_CHECKING(for src modules)
6363
6364 # dependencies and linker-arguments for test-programs
6365 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
6366 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
6367 if test "$DFT_LWR_MODEL" = "libtool"; then
6368         TEST_ARGS="${TEST_DEPS}"
6369         TEST_ARG2="${TEST_DEP2}"
6370 else
6371         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
6372         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
6373 fi
6374
6375 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
6376 cf_cv_src_modules=
6377 for cf_dir in $1
6378 do
6379         if test -f $srcdir/$cf_dir/modules; then
6380
6381                 # We may/may not have tack in the distribution, though the
6382                 # makefile is.
6383                 if test $cf_dir = tack ; then
6384                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
6385                                 continue
6386                         fi
6387                 fi
6388
6389                 if test -z "$cf_cv_src_modules"; then
6390                         cf_cv_src_modules=$cf_dir
6391                 else
6392                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
6393                 fi
6394
6395                 # Make the ncurses_cfg.h file record the library interface files as
6396                 # well.  These are header files that are the same name as their
6397                 # directory.  Ncurses is the only library that does not follow
6398                 # that pattern.
6399                 if test $cf_dir = tack ; then
6400                         continue
6401                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
6402                         CF_UPPER(cf_have_include,$cf_dir)
6403                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
6404                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
6405                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
6406                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
6407                         if test "$DFT_LWR_MODEL" = "libtool"; then
6408                                 TEST_ARGS="${TEST_DEPS}"
6409                                 TEST_ARG2="${TEST_DEP2}"
6410                         else
6411                                 TEST_ARGS="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARGS"
6412                                 TEST_ARG2="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARG2"
6413                         fi
6414                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
6415                 fi
6416         fi
6417 done
6418 AC_MSG_RESULT($cf_cv_src_modules)
6419
6420 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
6421 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
6422
6423 AC_SUBST(TEST_ARGS)
6424 AC_SUBST(TEST_DEPS)
6425
6426 AC_SUBST(TEST_ARG2)
6427 AC_SUBST(TEST_DEP2)
6428
6429 SRC_SUBDIRS=
6430 if test "x$cf_with_manpages" != xno ; then
6431         SRC_SUBDIRS="$SRC_SUBDIRS man"
6432 fi
6433 SRC_SUBDIRS="$SRC_SUBDIRS include"
6434 for cf_dir in $cf_cv_src_modules
6435 do
6436         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
6437 done
6438 if test "x$cf_with_tests" != "xno" ; then
6439         SRC_SUBDIRS="$SRC_SUBDIRS test"
6440 fi
6441 # always make this, to install the ncurses-config script
6442 SRC_SUBDIRS="$SRC_SUBDIRS misc"
6443 if test "$cf_with_cxx_binding" != no; then
6444         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
6445         SRC_SUBDIRS="$SRC_SUBDIRS c++"
6446 fi
6447
6448 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
6449 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
6450
6451 AC_SUBST(PC_MODULES_TO_MAKE)
6452
6453 ADA_SUBDIRS=
6454 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
6455         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
6456         ADA_SUBDIRS="gen src"
6457         if test "x$cf_with_tests" != "xno" ; then
6458                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
6459         fi
6460 fi
6461
6462 SUB_MAKEFILES=
6463 for cf_dir in $SRC_SUBDIRS
6464 do
6465         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
6466 done
6467
6468 if test -n "$ADA_SUBDIRS"; then
6469         for cf_dir in $ADA_SUBDIRS
6470         do
6471                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
6472         done
6473         AC_SUBST(ADA_SUBDIRS)
6474 fi
6475 ])dnl
6476 dnl ---------------------------------------------------------------------------
6477 dnl CF_STDCPP_LIBRARY version: 11 updated: 2015/10/17 19:03:33
6478 dnl -----------------
6479 dnl Check for -lstdc++, which is GNU's standard C++ library.
6480 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
6481 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
6482 dnl add it to $CXXLIBS.
6483 AC_DEFUN([CF_STDCPP_LIBRARY],
6484 [
6485 if test -n "$GXX" ; then
6486
6487         cf_save="$LIBS"
6488         LIBS="$LIBS $CXXLIBS"
6489         AC_MSG_CHECKING(if we already have C++ library)
6490         AC_TRY_LINK([
6491                         #include <iostream>],[
6492                         std::cout << "Hello World!" << std::endl;],
6493                 [cf_have_libstdcpp=yes],
6494                 [cf_have_libstdcpp=no])
6495         AC_MSG_RESULT($cf_have_libstdcpp)
6496         LIBS="$cf_save"
6497
6498         if test $cf_have_libstdcpp != yes
6499         then
6500                 case $cf_cv_system_name in
6501                 (os2*)
6502                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
6503                                 cf_stdcpp_libname=stdcpp
6504                         else
6505                                 cf_stdcpp_libname=stdc++
6506                         fi
6507                         ;;
6508                 (*)
6509                         cf_stdcpp_libname=stdc++
6510                         ;;
6511                 esac
6512
6513                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
6514                         cf_save="$LIBS"
6515                         LIBS="$LIBS $CXXLIBS"
6516                         CF_ADD_LIB($cf_stdcpp_libname)
6517                 AC_TRY_LINK([
6518                                 #include <iostream>],[
6519                                 std::cout << "Hello World!" << std::endl;],
6520                         [cf_cv_libstdcpp=yes],
6521                         [cf_cv_libstdcpp=no])
6522                         LIBS="$cf_save"
6523                 ])
6524                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
6525         fi
6526 fi
6527 ])dnl
6528 dnl ---------------------------------------------------------------------------
6529 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
6530 dnl --------------
6531 dnl     Remove "-g" option from the compiler options
6532 AC_DEFUN([CF_STRIP_G_OPT],
6533 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
6534 dnl ---------------------------------------------------------------------------
6535 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
6536 dnl -------------------
6537 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
6538 dnl do this if we've found the sigaction function.
6539 AC_DEFUN([CF_STRUCT_SIGACTION],[
6540 AC_REQUIRE([CF_XOPEN_SOURCE])
6541
6542 if test "$ac_cv_func_sigaction" = yes; then
6543 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
6544 AC_TRY_COMPILE([
6545 #include <sys/types.h>
6546 #include <signal.h>],
6547         [struct sigaction act],
6548         [sigact_bad=no],
6549         [
6550 AC_TRY_COMPILE([
6551 #define _POSIX_SOURCE
6552 #include <sys/types.h>
6553 #include <signal.h>],
6554         [struct sigaction act],
6555         [sigact_bad=yes
6556          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
6557          [sigact_bad=unknown])])
6558 AC_MSG_RESULT($sigact_bad)
6559 fi
6560 ])dnl
6561 dnl ---------------------------------------------------------------------------
6562 dnl CF_STRUCT_TERMIOS version: 8 updated: 2015/04/15 19:08:48
6563 dnl -----------------
6564 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
6565 AC_DEFUN([CF_STRUCT_TERMIOS],[
6566 AC_REQUIRE([CF_XOPEN_SOURCE])
6567
6568 AC_CHECK_HEADERS( \
6569 termio.h \
6570 termios.h \
6571 unistd.h \
6572 )
6573
6574 if test "$ISC" = yes ; then
6575         AC_CHECK_HEADERS( sys/termio.h )
6576 fi
6577 if test "$ac_cv_header_termios_h" = yes ; then
6578         case "$CFLAGS $CPPFLAGS" in
6579         (*-D_POSIX_SOURCE*)
6580                 termios_bad=dunno ;;
6581         (*)     termios_bad=maybe ;;
6582         esac
6583         if test "$termios_bad" = maybe ; then
6584         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
6585         AC_TRY_COMPILE([#include <termios.h>],
6586                 [struct termios foo; int x = foo.c_iflag],
6587                 termios_bad=no, [
6588                 AC_TRY_COMPILE([
6589 #define _POSIX_SOURCE
6590 #include <termios.h>],
6591                         [struct termios foo; int x = foo.c_iflag],
6592                         termios_bad=unknown,
6593                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
6594                         ])
6595         AC_MSG_RESULT($termios_bad)
6596         fi
6597 fi
6598 ])dnl
6599 dnl ---------------------------------------------------------------------------
6600 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
6601 dnl --------------
6602 dnl Construct a search-list for a nonstandard header/lib-file
6603 dnl     $1 = the variable to return as result
6604 dnl     $2 = the package name
6605 dnl     $3 = the subdirectory, e.g., bin, include or lib
6606 AC_DEFUN([CF_SUBDIR_PATH],
6607 [
6608 $1=
6609
6610 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
6611
6612 for cf_subdir_prefix in \
6613         /usr \
6614         /usr/local \
6615         /usr/pkg \
6616         /opt \
6617         /opt/local \
6618         [$]HOME
6619 do
6620         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
6621 done
6622 ])dnl
6623 dnl ---------------------------------------------------------------------------
6624 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
6625 dnl -----------
6626 dnl     Shorthand macro for substituting things that the user may override
6627 dnl     with an environment variable.
6628 dnl
6629 dnl     $1 = condition to pass to "test"
6630 dnl     $2 = environment variable
6631 dnl     $3 = value if the test succeeds
6632 dnl     $4 = value if the test fails
6633 AC_DEFUN([CF_SUBST_IF],
6634 [
6635 if test $1 ; then
6636         $2=$3
6637 ifelse($4,,,[else
6638         $2=$4])
6639 fi
6640 AC_SUBST($2)
6641 ])dnl
6642 dnl ---------------------------------------------------------------------------
6643 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
6644 dnl ------------------------
6645 dnl Get the version-number for use in shared-library naming, etc.
6646 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
6647 [
6648 AC_REQUIRE([CF_PROG_EGREP])
6649 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6650 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6651 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6652 cf_cv_abi_version=${NCURSES_MAJOR}
6653 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
6654 dnl Show the computed version, for logging
6655 cf_cv_timestamp=`date`
6656 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
6657 dnl We need these values in the generated headers
6658 AC_SUBST(NCURSES_MAJOR)
6659 AC_SUBST(NCURSES_MINOR)
6660 AC_SUBST(NCURSES_PATCH)
6661 dnl We need these values in the generated makefiles
6662 AC_SUBST(cf_cv_rel_version)
6663 AC_SUBST(cf_cv_abi_version)
6664 AC_SUBST(cf_cv_builtin_bool)
6665 AC_SUBST(cf_cv_header_stdbool_h)
6666 AC_SUBST(cf_cv_type_of_bool)dnl
6667 ])dnl
6668 dnl ---------------------------------------------------------------------------
6669 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
6670 dnl ------------------
6671 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6672 dnl older SCO configurations.
6673 AC_DEFUN([CF_SYS_TIME_SELECT],
6674 [
6675 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6676 AC_CACHE_VAL(cf_cv_sys_time_select,[
6677 AC_TRY_COMPILE([
6678 #include <sys/types.h>
6679 #ifdef HAVE_SYS_TIME_H
6680 #include <sys/time.h>
6681 #endif
6682 #ifdef HAVE_SYS_SELECT_H
6683 #include <sys/select.h>
6684 #endif
6685 ],[],[cf_cv_sys_time_select=yes],
6686          [cf_cv_sys_time_select=no])
6687          ])
6688 AC_MSG_RESULT($cf_cv_sys_time_select)
6689 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
6690 ])dnl
6691 dnl ---------------------------------------------------------------------------
6692 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
6693 dnl ---------------
6694 dnl Define a top_builddir symbol, for applications that need an absolute path.
6695 AC_DEFUN([CF_TOP_BUILDDIR],
6696 [
6697 top_builddir=ifelse($1,,`pwd`,$1)
6698 AC_SUBST(top_builddir)
6699 ])dnl
6700 dnl ---------------------------------------------------------------------------
6701 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6702 dnl -------------------
6703 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6704 dnl can define it successfully.
6705 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6706 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6707         AC_TRY_COMPILE([
6708 #include <stdlib.h>
6709 #include <string.h>
6710 #include <sys/types.h>
6711 ],[
6712 #ifndef _XOPEN_SOURCE
6713 make an error
6714 #endif],
6715         [cf_cv_xopen_source=no],
6716         [cf_save="$CPPFLAGS"
6717          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6718          AC_TRY_COMPILE([
6719 #include <stdlib.h>
6720 #include <string.h>
6721 #include <sys/types.h>
6722 ],[
6723 #ifdef _XOPEN_SOURCE
6724 make an error
6725 #endif],
6726         [cf_cv_xopen_source=no],
6727         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6728         CPPFLAGS="$cf_save"
6729         ])
6730 ])
6731
6732 if test "$cf_cv_xopen_source" != no ; then
6733         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6734         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6735         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6736         CF_ADD_CFLAGS($cf_temp_xopen_source)
6737 fi
6738 ])
6739 dnl ---------------------------------------------------------------------------
6740 dnl CF_TYPEOF_CHTYPE version: 9 updated: 2012/10/06 17:56:13
6741 dnl ----------------
6742 dnl Determine the type we should use for chtype (and attr_t, which is treated
6743 dnl as the same thing).  We want around 32 bits, so on most machines want a
6744 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6745 dnl wide characters, we have to have a type compatible with that, as well.
6746 AC_DEFUN([CF_TYPEOF_CHTYPE],
6747 [
6748 AC_MSG_CHECKING([for type of chtype])
6749 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6750                 AC_TRY_RUN([
6751 #define WANT_BITS 31
6752 #include <stdio.h>
6753 int main()
6754 {
6755         FILE *fp = fopen("cf_test.out", "w");
6756         if (fp != 0) {
6757                 char *result = "long";
6758                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6759                         int n;
6760                         unsigned int x, y;
6761                         for (n = 0; n < WANT_BITS; n++) {
6762                                 x = (1 << n);
6763                                 y = (x >> n);
6764                                 if (y != 1 || x == 0) {
6765                                         x = 0;
6766                                         break;
6767                                 }
6768                         }
6769                         /*
6770                          * If x is nonzero, an int is big enough for the bits
6771                          * that we want.
6772                          */
6773                         result = (x != 0) ? "int" : "long";
6774                 }
6775                 fputs(result, fp);
6776                 fclose(fp);
6777         }
6778         ${cf_cv_main_return:-return}(0);
6779 }
6780                 ],
6781                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6782                 [cf_cv_typeof_chtype=long],
6783                 [cf_cv_typeof_chtype=long])
6784                 rm -f cf_test.out
6785         ])
6786 AC_MSG_RESULT($cf_cv_typeof_chtype)
6787
6788 AC_SUBST(cf_cv_typeof_chtype)
6789 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
6790 ])dnl
6791 dnl ---------------------------------------------------------------------------
6792 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
6793 dnl -----------------
6794 dnl
6795 AC_DEFUN([CF_TYPE_SIGACTION],
6796 [
6797 AC_MSG_CHECKING([for type sigaction_t])
6798 AC_CACHE_VAL(cf_cv_type_sigaction,[
6799         AC_TRY_COMPILE([
6800 #include <signal.h>],
6801                 [sigaction_t x],
6802                 [cf_cv_type_sigaction=yes],
6803                 [cf_cv_type_sigaction=no])])
6804 AC_MSG_RESULT($cf_cv_type_sigaction)
6805 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
6806 ])dnl
6807 dnl ---------------------------------------------------------------------------
6808 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6809 dnl --------------------
6810 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6811 dnl won't, but they're still there.
6812 AC_DEFUN([CF_UNSIGNED_LITERALS],
6813 [
6814 AC_MSG_CHECKING([if unsigned literals are legal])
6815 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6816         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6817                 [cf_cv_unsigned_literals=yes],
6818                 [cf_cv_unsigned_literals=no])
6819         ])
6820 AC_MSG_RESULT($cf_cv_unsigned_literals)
6821 ])dnl
6822 dnl ---------------------------------------------------------------------------
6823 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6824 dnl --------
6825 dnl Make an uppercase version of a variable
6826 dnl $1=uppercase($2)
6827 AC_DEFUN([CF_UPPER],
6828 [
6829 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6830 ])dnl
6831 dnl ---------------------------------------------------------------------------
6832 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
6833 dnl -----------
6834 dnl Check for multibyte support, and if not found, utf8 compatibility library
6835 AC_DEFUN([CF_UTF8_LIB],
6836 [
6837 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6838         cf_save_LIBS="$LIBS"
6839         AC_TRY_LINK([
6840 #include <stdlib.h>],[putwc(0,0);],
6841         [cf_cv_utf8_lib=yes],
6842         [CF_FIND_LINKAGE([
6843 #include <libutf8.h>],[putwc(0,0);],utf8,
6844                 [cf_cv_utf8_lib=add-on],
6845                 [cf_cv_utf8_lib=no])
6846 ])])
6847
6848 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6849 # ncurses/ncursesw:
6850 if test "$cf_cv_utf8_lib" = "add-on" ; then
6851         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
6852         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6853         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6854         CF_ADD_LIBS($cf_cv_library_file_utf8)
6855 fi
6856 ])dnl
6857 dnl ---------------------------------------------------------------------------
6858 dnl CF_VA_COPY version: 3 updated: 2012/10/06 11:17:15
6859 dnl ----------
6860 dnl check for va_copy, part of stdarg.h
6861 dnl Also, workaround for glibc's __va_copy, by checking for both.
6862 AC_DEFUN([CF_VA_COPY],[
6863 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6864 AC_TRY_LINK([
6865 #include <stdarg.h>
6866 ],[
6867         static va_list dst;
6868         static va_list src;
6869         va_copy(dst, src)],
6870         cf_cv_have_va_copy=yes,
6871         cf_cv_have_va_copy=no)])
6872
6873 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
6874
6875 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6876 AC_TRY_LINK([
6877 #include <stdarg.h>
6878 ],[
6879         static va_list dst;
6880         static va_list src;
6881         __va_copy(dst, src)],
6882         cf_cv_have___va_copy=yes,
6883         cf_cv_have___va_copy=no)])
6884
6885 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
6886 ])
6887 dnl ---------------------------------------------------------------------------
6888 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6889 dnl ----------
6890 dnl Use AC_VERBOSE w/o the warnings
6891 AC_DEFUN([CF_VERBOSE],
6892 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6893 CF_MSG_LOG([$1])
6894 ])dnl
6895 dnl ---------------------------------------------------------------------------
6896 dnl CF_VERSION_INFO version: 7 updated: 2015/04/17 21:13:04
6897 dnl ---------------
6898 dnl Define several useful symbols derived from the VERSION file.  A separate
6899 dnl file is preferred to embedding the version numbers in various scripts.
6900 dnl (automake is a textbook-example of why the latter is a bad idea, but there
6901 dnl are others).
6902 dnl
6903 dnl The file contents are:
6904 dnl     libtool-version release-version patch-version
6905 dnl or
6906 dnl     release-version
6907 dnl where
6908 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
6909 dnl     release-version consists of a major version and minor version
6910 dnl             separated by '.', optionally followed by a patch-version
6911 dnl             separated by '-'.  The minor version need not be an
6912 dnl             integer (but it is preferred).
6913 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
6914 dnl             scripts can easily compare versions.
6915 dnl
6916 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
6917 dnl simply extracts the first field using 'cut -f1'.
6918 dnl
6919 dnl Optional parameters:
6920 dnl $1 = internal name for package
6921 dnl $2 = external name for package
6922 AC_DEFUN([CF_VERSION_INFO],
6923 [
6924 if test -f $srcdir/VERSION ; then
6925         AC_MSG_CHECKING(for package version)
6926
6927         # if there are not enough fields, cut returns the last one...
6928         cf_field1=`sed -e '2,$d' $srcdir/VERSION|cut -f1`
6929         cf_field2=`sed -e '2,$d' $srcdir/VERSION|cut -f2`
6930         cf_field3=`sed -e '2,$d' $srcdir/VERSION|cut -f3`
6931
6932         # this is how CF_BUNDLED_INTL uses $VERSION:
6933         VERSION="$cf_field1"
6934
6935         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
6936         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
6937
6938         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
6939         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
6940
6941         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
6942
6943         AC_MSG_CHECKING(for package patch date)
6944         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
6945         case .$VERSION_PATCH in
6946         (.)
6947                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
6948                 ;;
6949         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
6950                 ;;
6951         (*)
6952                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
6953                 ;;
6954         esac
6955         AC_MSG_RESULT($VERSION_PATCH)
6956 else
6957         AC_MSG_ERROR(did not find $srcdir/VERSION)
6958 fi
6959
6960 # show the actual data that we have for versions:
6961 CF_VERBOSE(ABI VERSION $VERSION)
6962 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
6963 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
6964 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
6965
6966 AC_SUBST(VERSION)
6967 AC_SUBST(VERSION_MAJOR)
6968 AC_SUBST(VERSION_MINOR)
6969 AC_SUBST(VERSION_PATCH)
6970
6971 dnl if a package name is given, define its corresponding version info.  We
6972 dnl need the package name to ensure that the defined symbols are unique.
6973 ifelse($1,,,[
6974         cf_PACKAGE=$1
6975         PACKAGE=ifelse($2,,$1,$2)
6976         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
6977         AC_SUBST(PACKAGE)
6978         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
6979         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
6980         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
6981 ])
6982 ])dnl
6983 dnl ---------------------------------------------------------------------------
6984 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
6985 dnl -------------
6986 dnl Check if type wide-character type $1 is declared, and if so, which header
6987 dnl file is needed.  The second parameter is used to set a shell variable when
6988 dnl the type is not found.  The first parameter sets a shell variable for the
6989 dnl opposite sense.
6990 AC_DEFUN([CF_WCHAR_TYPE],
6991 [
6992 # This is needed on Tru64 5.0 to declare $1
6993 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6994 AC_TRY_COMPILE([
6995 #include <stdlib.h>
6996 #include <stdarg.h>
6997 #include <stdio.h>
6998 #ifdef HAVE_LIBUTF8_H
6999 #include <libutf8.h>
7000 #endif],
7001         [$1 state],
7002         [cf_cv_$1=no],
7003         [AC_TRY_COMPILE([
7004 #include <stdlib.h>
7005 #include <stdarg.h>
7006 #include <stdio.h>
7007 #include <wchar.h>
7008 #ifdef HAVE_LIBUTF8_H
7009 #include <libutf8.h>
7010 #endif],
7011         [$1 value],
7012         [cf_cv_$1=yes],
7013         [cf_cv_$1=unknown])])])
7014
7015 if test "$cf_cv_$1" = yes ; then
7016         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
7017         NEED_WCHAR_H=1
7018 fi
7019
7020 ifelse([$2],,,[
7021 # if we do not find $1 in either place, use substitution to provide a fallback.
7022 if test "$cf_cv_$1" = unknown ; then
7023         $2=1
7024 fi
7025 ])
7026 ifelse($3,,,[
7027 # if we find $1 in either place, use substitution to provide a fallback.
7028 if test "$cf_cv_$1" != unknown ; then
7029         $3=1
7030 fi
7031 ])
7032 ])dnl
7033 dnl ---------------------------------------------------------------------------
7034 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
7035 dnl ---------------
7036 dnl Check for compiler-support for weak symbols.
7037 dnl This works with "recent" gcc.
7038 AC_DEFUN([CF_WEAK_SYMBOLS],[
7039 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
7040
7041 AC_TRY_COMPILE([
7042 #include <stdio.h>],
7043 [
7044 #if defined(__GNUC__)
7045 #  if defined __USE_ISOC99
7046 #    define _cat_pragma(exp)    _Pragma(#exp)
7047 #    define _weak_pragma(exp)   _cat_pragma(weak name)
7048 #  else
7049 #    define _weak_pragma(exp)
7050 #  endif
7051 #  define _declare(name)        __extension__ extern __typeof__(name) name
7052 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
7053 #endif
7054
7055 weak_symbol(fopen);
7056 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
7057 ])
7058 ])dnl
7059 dnl ---------------------------------------------------------------------------
7060 dnl CF_WITH_ABI_VERSION version: 3 updated: 2015/06/06 16:10:11
7061 dnl -------------------
7062 dnl Allow library's ABI to be overridden.  Generally this happens when a
7063 dnl packager has incremented the ABI past that used in the original package,
7064 dnl and wishes to keep doing this.
7065 dnl
7066 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
7067 dnl symbol.
7068 AC_DEFUN([CF_WITH_ABI_VERSION],[
7069 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
7070 AC_ARG_WITH(abi-version,
7071 [  --with-abi-version=XXX  override derived ABI version],[
7072         if test "x$cf_cv_abi_version" != "x$withval"
7073         then
7074                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
7075                 case $cf_cv_rel_version in
7076                 (5.*)
7077                         cf_cv_rel_version=$withval.0
7078                         ;;
7079                 (6.*)
7080                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
7081                         ;;
7082                 esac
7083         fi
7084         cf_cv_abi_version=$withval])
7085         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
7086 ifelse($1,,,[
7087 $1_ABI=$cf_cv_abi_version
7088 ])
7089 ])dnl
7090 dnl ---------------------------------------------------------------------------
7091 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
7092 dnl --------------------
7093 dnl Command-line option to specify the Ada95 compiler.
7094 AC_DEFUN([CF_WITH_ADA_COMPILER],[
7095 AC_MSG_CHECKING(for ada-compiler)
7096 AC_ARG_WITH(ada-compiler,
7097         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
7098         [cf_ada_compiler=$withval],
7099         [cf_ada_compiler=gnatmake])
7100 AC_SUBST(cf_ada_compiler)
7101 AC_MSG_RESULT($cf_ada_compiler)
7102 ])dnl
7103 dnl ---------------------------------------------------------------------------
7104 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
7105 dnl -------------------
7106 dnl Command-line option to specify where Ada includes will install.
7107 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
7108 AC_MSG_CHECKING(for ada-include)
7109 CF_WITH_PATH(ada-include,
7110    [  --with-ada-include=DIR  Ada includes are in DIR],
7111    ADA_INCLUDE,
7112    PREFIX/share/ada/adainclude,
7113    [$]prefix/share/ada/adainclude)
7114 AC_SUBST(ADA_INCLUDE)
7115 AC_MSG_RESULT($ADA_INCLUDE)
7116 ])dnl
7117 dnl ---------------------------------------------------------------------------
7118 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
7119 dnl -------------------
7120 dnl Command-line option to specify where Ada objects will install.
7121 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
7122 AC_MSG_CHECKING(for ada-objects)
7123 CF_WITH_PATH(ada-objects,
7124    [  --with-ada-objects=DIR  Ada objects are in DIR],
7125    ADA_OBJECTS,
7126    PREFIX/lib/ada/adalib,
7127    [$]prefix/lib/ada/adalib)
7128 AC_SUBST(ADA_OBJECTS)
7129 AC_MSG_RESULT($ADA_OBJECTS)
7130 ])dnl
7131 dnl ---------------------------------------------------------------------------
7132 dnl CF_WITH_ADA_SHAREDLIB version: 4 updated: 2014/05/31 21:08:37
7133 dnl ---------------------
7134 dnl Command-line option to specify if an Ada95 shared-library should be built,
7135 dnl and optionally what its soname should be.
7136 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
7137 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
7138 AC_ARG_WITH(ada-sharedlib,
7139         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
7140         [with_ada_sharedlib=$withval],
7141         [with_ada_sharedlib=no])
7142 AC_MSG_RESULT($with_ada_sharedlib)
7143
7144 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
7145 MAKE_ADA_SHAREDLIB="#"
7146
7147 if test "x$with_ada_sharedlib" != xno
7148 then
7149         MAKE_ADA_SHAREDLIB=
7150         if test "x$with_ada_sharedlib" != xyes
7151         then
7152                 ADA_SHAREDLIB="$with_ada_sharedlib"
7153         fi
7154 fi
7155
7156 AC_SUBST(ADA_SHAREDLIB)
7157 AC_SUBST(MAKE_ADA_SHAREDLIB)
7158 ])dnl
7159 dnl ---------------------------------------------------------------------------
7160 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
7161 dnl ----------------
7162 dnl Configure-option for dbmalloc.  The optional parameter is used to override
7163 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
7164 AC_DEFUN([CF_WITH_DBMALLOC],[
7165 CF_NO_LEAKS_OPTION(dbmalloc,
7166         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
7167         [USE_DBMALLOC])
7168
7169 if test "$with_dbmalloc" = yes ; then
7170         AC_CHECK_HEADER(dbmalloc.h,
7171                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
7172 fi
7173 ])dnl
7174 dnl ---------------------------------------------------------------------------
7175 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
7176 dnl ---------------
7177 dnl Configure-option for dmalloc.  The optional parameter is used to override
7178 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
7179 AC_DEFUN([CF_WITH_DMALLOC],[
7180 CF_NO_LEAKS_OPTION(dmalloc,
7181         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
7182         [USE_DMALLOC])
7183
7184 if test "$with_dmalloc" = yes ; then
7185         AC_CHECK_HEADER(dmalloc.h,
7186                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
7187 fi
7188 ])dnl
7189 dnl ---------------------------------------------------------------------------
7190 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
7191 dnl -------------------
7192 dnl Use this with libtool to specify the list of symbols that may be exported.
7193 dnl The input file contains one symbol per line; comments work with "#".
7194 dnl
7195 dnl $1 = basename of the ".sym" file (default $PACKAGE)
7196 AC_DEFUN([CF_WITH_EXPORT_SYMS],
7197 [
7198 AC_MSG_CHECKING(if exported-symbols file should be used)
7199 AC_ARG_WITH(export-syms,
7200         [  --with-export-syms=XXX  limit exported symbols using libtool],
7201         [with_export_syms=$withval],
7202         [with_export_syms=no])
7203 if test "x$with_export_syms" = xyes
7204 then
7205         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
7206         AC_SUBST(PACKAGE)
7207 fi
7208 AC_MSG_RESULT($with_export_syms)
7209 if test "x$with_export_syms" != xno
7210 then
7211         EXPORT_SYMS="-export-symbols $with_export_syms"
7212         AC_SUBST(EXPORT_SYMS)
7213 fi
7214 ])dnl
7215 dnl ---------------------------------------------------------------------------
7216 dnl CF_WITH_GPM version: 9 updated: 2016/05/28 20:33:31
7217 dnl -----------
7218 dnl
7219 dnl The option parameter (if neither yes/no) is assumed to be the name of
7220 dnl the gpm library, e.g., for dynamic loading.
7221 AC_DEFUN([CF_WITH_GPM],
7222 [
7223 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
7224 AC_ARG_WITH(gpm,
7225         [  --with-gpm              use Alessandro Rubini's GPM library],
7226         [with_gpm=$withval],
7227         [with_gpm=maybe])
7228 AC_MSG_RESULT($with_gpm)
7229
7230 if test "$with_gpm" != no ; then
7231         AC_CHECK_HEADER(gpm.h,[
7232                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
7233                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
7234                         CF_VERBOSE(assuming we really have GPM library)
7235                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
7236                         with_gpm=yes
7237                 else
7238                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
7239                                 if test "$with_gpm" = maybe; then
7240                                         AC_MSG_WARN(Cannot link with GPM library)
7241                                         with_gpm=no
7242                                 else
7243                                         AC_MSG_ERROR(Cannot link with GPM library)
7244                                 fi
7245                         ])
7246                 fi
7247         ],[
7248                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
7249                 with_gpm=no
7250         ])
7251 fi
7252 ])
7253 dnl ---------------------------------------------------------------------------
7254 dnl CF_WITH_LIBTOOL version: 34 updated: 2016/12/31 12:04:57
7255 dnl ---------------
7256 dnl Provide a configure option to incorporate libtool.  Define several useful
7257 dnl symbols for the makefile rules.
7258 dnl
7259 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
7260 dnl macros from libtool.m4 which is in the aclocal directory of automake.
7261 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
7262 dnl But that still does not work properly since the macro is expanded outside
7263 dnl the CF_WITH_LIBTOOL macro:
7264 dnl
7265 dnl     #!/bin/sh
7266 dnl     ACLOCAL=`aclocal --print-ac-dir`
7267 dnl     if test -z "$ACLOCAL" ; then
7268 dnl             echo cannot find aclocal directory
7269 dnl             exit 1
7270 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
7271 dnl             echo cannot find libtool.m4 file
7272 dnl             exit 1
7273 dnl     fi
7274 dnl
7275 dnl     LOCAL=aclocal.m4
7276 dnl     ORIG=aclocal.m4.orig
7277 dnl
7278 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
7279 dnl     rm -f $ORIG
7280 dnl     mv $LOCAL $ORIG
7281 dnl
7282 dnl     # sed the LIBTOOL= assignment to omit the current directory?
7283 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
7284 dnl     cat $ORIG >>$LOCAL
7285 dnl
7286 dnl     autoconf-257 $*
7287 dnl
7288 AC_DEFUN([CF_WITH_LIBTOOL],
7289 [
7290 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
7291 ifdef([AC_PROG_LIBTOOL],,[
7292 LIBTOOL=
7293 ])
7294 # common library maintenance symbols that are convenient for libtool scripts:
7295 LIB_CREATE='${AR} -cr'
7296 LIB_OBJECT='${OBJECTS}'
7297 LIB_SUFFIX=.a
7298 LIB_PREP="$RANLIB"
7299
7300 # symbols used to prop libtool up to enable it to determine what it should be
7301 # doing:
7302 LIB_CLEAN=
7303 LIB_COMPILE=
7304 LIB_LINK='${CC}'
7305 LIB_INSTALL=
7306 LIB_UNINSTALL=
7307
7308 AC_MSG_CHECKING(if you want to build libraries with libtool)
7309 AC_ARG_WITH(libtool,
7310         [  --with-libtool          generate libraries with libtool],
7311         [with_libtool=$withval],
7312         [with_libtool=no])
7313 AC_MSG_RESULT($with_libtool)
7314 if test "$with_libtool" != "no"; then
7315 ifdef([AC_PROG_LIBTOOL],[
7316         # missing_content_AC_PROG_LIBTOOL{{
7317         AC_PROG_LIBTOOL
7318         # missing_content_AC_PROG_LIBTOOL}}
7319 ],[
7320         if test "$with_libtool" != "yes" ; then
7321                 CF_PATH_SYNTAX(with_libtool)
7322                 LIBTOOL=$with_libtool
7323         else
7324                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
7325                 CF_LIBTOOL_VERSION
7326                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
7327                 then
7328                         CF_FORGET_TOOL(LIBTOOL)
7329                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
7330                         CF_LIBTOOL_VERSION
7331                 fi
7332         fi
7333         if test -z "$LIBTOOL" ; then
7334                 AC_MSG_ERROR(Cannot find libtool)
7335         fi
7336 ])dnl
7337         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
7338         LIB_OBJECT='${OBJECTS:.o=.lo}'
7339         LIB_SUFFIX=.la
7340         LIB_CLEAN='${LIBTOOL} --mode=clean'
7341         LIB_COMPILE='${LIBTOOL} --mode=compile'
7342         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
7343         LIB_INSTALL='${LIBTOOL} --mode=install'
7344         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
7345         LIB_PREP=:
7346
7347         CF_CHECK_LIBTOOL_VERSION
7348
7349         # special hack to add -no-undefined (which libtool should do for itself)
7350         LT_UNDEF=
7351         case "$cf_cv_system_name" in
7352         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
7353                 LT_UNDEF=-no-undefined
7354                 ;;
7355         esac
7356         AC_SUBST([LT_UNDEF])
7357
7358         # special hack to add --tag option for C++ compiler
7359         case $cf_cv_libtool_version in
7360         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
7361                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
7362                 LIBTOOL="$LIBTOOL --tag=CC"
7363                 ;;
7364         (*)
7365                 LIBTOOL_CXX="$LIBTOOL"
7366                 ;;
7367         esac
7368 else
7369         LIBTOOL=""
7370         LIBTOOL_CXX=""
7371 fi
7372
7373 test -z "$LIBTOOL" && ECHO_LT=
7374
7375 AC_SUBST(LIBTOOL)
7376 AC_SUBST(LIBTOOL_CXX)
7377 AC_SUBST(LIBTOOL_OPTS)
7378
7379 AC_SUBST(LIB_CREATE)
7380 AC_SUBST(LIB_OBJECT)
7381 AC_SUBST(LIB_SUFFIX)
7382 AC_SUBST(LIB_PREP)
7383
7384 AC_SUBST(LIB_CLEAN)
7385 AC_SUBST(LIB_COMPILE)
7386 AC_SUBST(LIB_LINK)
7387 AC_SUBST(LIB_INSTALL)
7388 AC_SUBST(LIB_UNINSTALL)
7389
7390 ])dnl
7391 dnl ---------------------------------------------------------------------------
7392 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
7393 dnl --------------------
7394 dnl Allow user to pass additional libtool options into the library creation
7395 dnl and link steps.  The main use for this is to do something like
7396 dnl     ./configure --with-libtool-opts=-static
7397 dnl to get the same behavior as automake-flavored
7398 dnl     ./configure --enable-static
7399 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
7400 AC_MSG_CHECKING(for additional libtool options)
7401 AC_ARG_WITH(libtool-opts,
7402         [  --with-libtool-opts=XXX specify additional libtool options],
7403         [with_libtool_opts=$withval],
7404         [with_libtool_opts=no])
7405 AC_MSG_RESULT($with_libtool_opts)
7406
7407 case .$with_libtool_opts in
7408 (.yes|.no|.)
7409         ;;
7410 (*)
7411         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
7412         ;;
7413 esac
7414
7415 AC_SUBST(LIBTOOL_OPTS)
7416 ])dnl
7417 dnl ---------------------------------------------------------------------------
7418 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
7419 dnl ------------------
7420 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
7421 dnl "lib" prefix, e.g., because it used the dll naming convention.
7422 dnl
7423 dnl $1 = variable to set
7424 AC_DEFUN([CF_WITH_LIB_PREFIX],
7425 [
7426 AC_MSG_CHECKING(if you want to have a library-prefix)
7427 AC_ARG_WITH(lib-prefix,
7428         [  --with-lib-prefix       override library-prefix],
7429         [with_lib_prefix=$withval],
7430         [with_lib_prefix=auto])
7431 AC_MSG_RESULT($with_lib_prefix)
7432
7433 if test $with_lib_prefix = auto
7434 then
7435         CF_LIB_PREFIX($1)
7436 elif test $with_lib_prefix = no
7437 then
7438         LIB_PREFIX=
7439 else
7440         LIB_PREFIX=$with_lib_prefix
7441 fi
7442 ])dnl
7443 dnl ---------------------------------------------------------------------------
7444 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
7445 dnl ------------
7446 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
7447 dnl defaulting to yes/no.
7448 dnl
7449 dnl $1 = option name
7450 dnl $2 = help-text
7451 dnl $3 = environment variable to set
7452 dnl $4 = default value, shown in the help-message, must be a constant
7453 dnl $5 = default value, if it's an expression & cannot be in the help-message
7454 dnl
7455 AC_DEFUN([CF_WITH_PATH],
7456 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
7457 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
7458 if ifelse([$5],,true,[test -n "$5"]) ; then
7459 CF_PATH_SYNTAX(withval)
7460 fi
7461 eval $3="$withval"
7462 AC_SUBST($3)dnl
7463 ])dnl
7464 dnl ---------------------------------------------------------------------------
7465 dnl CF_WITH_PATHLIST version: 10 updated: 2015/04/17 21:13:04
7466 dnl ----------------
7467 dnl Process an option specifying a list of colon-separated paths.
7468 dnl
7469 dnl $1 = option name
7470 dnl $2 = help-text
7471 dnl $3 = environment variable to set
7472 dnl $4 = default value, shown in the help-message, must be a constant
7473 dnl $5 = default value, if it's an expression & cannot be in the help-message
7474 dnl $6 = flag to tell if we want to define or substitute
7475 dnl
7476 AC_DEFUN([CF_WITH_PATHLIST],[
7477 AC_REQUIRE([CF_PATHSEP])
7478 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
7479 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
7480
7481 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
7482 cf_dst_path=
7483 for cf_src_path in $withval
7484 do
7485   CF_PATH_SYNTAX(cf_src_path)
7486   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
7487   cf_dst_path="${cf_dst_path}${cf_src_path}"
7488 done
7489 IFS="$ac_save_ifs"
7490
7491 ifelse($6,define,[
7492 # Strip single quotes from the value, e.g., when it was supplied as a literal
7493 # for $4 or $5.
7494 case $cf_dst_path in
7495 (\'*)
7496   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
7497   ;;
7498 esac
7499 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
7500 ])
7501
7502 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
7503 # so we have to check/work around.  We do prefer the result of "eval"...
7504 eval cf_dst_eval="$cf_dst_path"
7505 case "x$cf_dst_eval" in
7506 (xNONE*)
7507         $3=$cf_dst_path
7508         ;;
7509 (*)
7510         $3="$cf_dst_eval"
7511         ;;
7512 esac
7513 AC_SUBST($3)dnl
7514
7515 ])dnl
7516 dnl ---------------------------------------------------------------------------
7517 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
7518 dnl -------------------------
7519 dnl Allow the choice of the pkg-config library directory to be overridden.
7520 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
7521
7522 case $PKG_CONFIG in
7523 (no|none|yes)
7524         AC_MSG_CHECKING(for pkg-config library directory)
7525         ;;
7526 (*)
7527         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
7528         ;;
7529 esac
7530
7531 PKG_CONFIG_LIBDIR=no
7532 AC_ARG_WITH(pkg-config-libdir,
7533         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
7534         [PKG_CONFIG_LIBDIR=$withval],
7535         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
7536
7537 case x$PKG_CONFIG_LIBDIR in
7538 (x/*)
7539         ;;
7540 (xyes)
7541         # Look for the library directory using the same prefix as the executable
7542         if test "x$PKG_CONFIG" = xnone
7543         then
7544                 cf_path=$prefix
7545         else
7546                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
7547         fi
7548
7549         # If you don't like using the default architecture, you have to specify the
7550         # intended library directory and corresponding compiler/linker options.
7551         #
7552         # This case allows for Debian's 2014-flavor of multiarch, along with the
7553         # most common variations before that point.  Some other variants spell the
7554         # directory differently, e.g., "pkg-config", and put it in unusual places.
7555         # pkg-config has always been poorly standardized, which is ironic...
7556         case x`(arch) 2>/dev/null` in
7557         (*64)
7558                 cf_search_path="\
7559                         $cf_path/lib/*64-linux-gnu \
7560                         $cf_path/share \
7561                         $cf_path/lib64 \
7562                         $cf_path/lib32 \
7563                         $cf_path/lib"
7564                 ;;
7565         (*)
7566                 cf_search_path="\
7567                         $cf_path/lib/*-linux-gnu \
7568                         $cf_path/share \
7569                         $cf_path/lib32 \
7570                         $cf_path/lib \
7571                         $cf_path/libdata"
7572                 ;;
7573         esac
7574
7575         CF_VERBOSE(list...)
7576         for cf_config in $cf_search_path
7577         do
7578                 CF_VERBOSE(checking $cf_config/pkgconfig)
7579                 if test -d $cf_config/pkgconfig
7580                 then
7581                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
7582                         AC_MSG_CHECKING(done)
7583                         break
7584                 fi
7585         done
7586         ;;
7587 (*)
7588         ;;
7589 esac
7590
7591 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
7592         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
7593 fi
7594
7595 AC_SUBST(PKG_CONFIG_LIBDIR)
7596 ])dnl
7597 dnl ---------------------------------------------------------------------------
7598 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
7599 dnl ---------------
7600 dnl Check for POSIX thread library.
7601 AC_DEFUN([CF_WITH_PTHREAD],
7602 [
7603 AC_MSG_CHECKING(if you want to link with the pthread library)
7604 AC_ARG_WITH(pthread,
7605         [  --with-pthread          use POSIX thread library],
7606         [with_pthread=$withval],
7607         [with_pthread=no])
7608 AC_MSG_RESULT($with_pthread)
7609
7610 if test "$with_pthread" != no ; then
7611         AC_CHECK_HEADER(pthread.h,[
7612         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
7613
7614         for cf_lib_pthread in pthread c_r
7615         do
7616             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
7617             cf_save_LIBS="$LIBS"
7618             CF_ADD_LIB($cf_lib_pthread)
7619             AC_TRY_LINK([
7620 #include <pthread.h>
7621 ],[
7622                 int rc = pthread_create(0,0,0,0);
7623                 int r2 = pthread_mutexattr_settype(0, 0);
7624 ],[with_pthread=yes],[with_pthread=no])
7625             LIBS="$cf_save_LIBS"
7626             AC_MSG_RESULT($with_pthread)
7627             test "$with_pthread" = yes && break
7628         done
7629
7630         if test "$with_pthread" = yes ; then
7631             CF_ADD_LIB($cf_lib_pthread)
7632             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
7633         else
7634             AC_MSG_ERROR(Cannot link with pthread library)
7635         fi
7636         ])
7637 fi
7638 ])
7639 dnl ---------------------------------------------------------------------------
7640 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
7641 dnl -------------------
7642 dnl Allow library's release-version to be overridden.  Generally this happens when a
7643 dnl packager has incremented the release-version past that used in the original package,
7644 dnl and wishes to keep doing this.
7645 dnl
7646 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
7647 dnl and {package}_MINOR symbols
7648 dnl symbol.
7649 AC_DEFUN([CF_WITH_REL_VERSION],[
7650 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
7651 AC_ARG_WITH(rel-version,
7652 [  --with-rel-version=XXX  override derived release version],
7653 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
7654  cf_cv_rel_version=$withval])
7655 ifelse($1,,[
7656  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
7657 ],[
7658  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
7659  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
7660  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
7661  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
7662 ])
7663 ])dnl
7664 dnl ---------------------------------------------------------------------------
7665 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
7666 dnl ----------------
7667 dnl If we can compile with sysmouse, make it available unless it is not wanted.
7668 AC_DEFUN([CF_WITH_SYSMOUSE],[
7669 # not everyone has "test -c"
7670 if test -c /dev/sysmouse 2>/dev/null ; then
7671 AC_MSG_CHECKING(if you want to use sysmouse)
7672 AC_ARG_WITH(sysmouse,
7673         [  --with-sysmouse         use sysmouse (FreeBSD console)],
7674         [cf_with_sysmouse=$withval],
7675         [cf_with_sysmouse=maybe])
7676         if test "$cf_with_sysmouse" != no ; then
7677         AC_TRY_COMPILE([
7678 #include <osreldate.h>
7679 #if (__FreeBSD_version >= 400017)
7680 #include <sys/consio.h>
7681 #include <sys/fbio.h>
7682 #else
7683 #include <machine/console.h>
7684 #endif
7685 ],[
7686         struct mouse_info the_mouse;
7687         ioctl(0, CONS_MOUSECTL, &the_mouse);
7688 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
7689         fi
7690 AC_MSG_RESULT($cf_with_sysmouse)
7691 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
7692 fi
7693 ])dnl
7694 dnl ---------------------------------------------------------------------------
7695 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
7696 dnl ---------------
7697 dnl For testing, override the derived host system-type which is used to decide
7698 dnl things such as the linker commands used to build shared libraries.  This is
7699 dnl normally chosen automatically based on the type of system which you are
7700 dnl building on.  We use it for testing the configure script.
7701 dnl
7702 dnl This is different from the --host option: it is used only for testing parts
7703 dnl of the configure script which would not be reachable with --host since that
7704 dnl relies on the build environment being real, rather than mocked up.
7705 AC_DEFUN([CF_WITH_SYSTYPE],[
7706 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
7707 AC_ARG_WITH(system-type,
7708         [  --with-system-type=XXX  test: override derived host system-type],
7709 [AC_MSG_WARN(overriding system type to $withval)
7710         cf_cv_system_name=$withval
7711         host_os=$withval
7712 ])
7713 ])dnl
7714 dnl ---------------------------------------------------------------------------
7715 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
7716 dnl ----------------
7717 AC_DEFUN([CF_WITH_VALGRIND],[
7718 CF_NO_LEAKS_OPTION(valgrind,
7719         [  --with-valgrind         test: use valgrind],
7720         [USE_VALGRIND])
7721 ])dnl
7722 dnl ---------------------------------------------------------------------------
7723 dnl CF_WITH_VERSIONED_SYMS version: 7 updated: 2015/10/24 20:50:26
7724 dnl ----------------------
7725 dnl Use this when building shared library with ELF, to markup symbols with the
7726 dnl version identifier from the given input file.  Generally that identifier is
7727 dnl the same as the SONAME at which the symbol was first introduced.
7728 dnl
7729 dnl $1 = basename of the ".map" file (default $PACKAGE)
7730 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
7731 [
7732 AC_MSG_CHECKING(if versioned-symbols file should be used)
7733 AC_ARG_WITH(versioned-syms,
7734         [  --with-versioned-syms=X markup versioned symbols using ld],
7735         [with_versioned_syms=$withval],
7736         [with_versioned_syms=no])
7737 if test "x$with_versioned_syms" = xyes
7738 then
7739         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
7740         AC_SUBST(PACKAGE)
7741 fi
7742 AC_MSG_RESULT($with_versioned_syms)
7743
7744 RESULTING_SYMS=
7745 VERSIONED_SYMS=
7746 WILDCARD_SYMS=
7747
7748 if test "x$with_versioned_syms" != xno
7749 then
7750         RESULTING_SYMS=$with_versioned_syms
7751         case "x$MK_SHARED_LIB" in
7752         (*-Wl,*)
7753                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
7754                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
7755                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7756                 ;;
7757         (*-dy\ *)
7758                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
7759                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
7760                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7761                 ;;
7762         (*)
7763                 AC_MSG_WARN(this system does not support versioned-symbols)
7764                 ;;
7765         esac
7766
7767         # Linux ld can selectively override scope, e.g., of symbols beginning with
7768         # "_" by first declaring some as global, and then using a wildcard to
7769         # declare the others as local.  Some other loaders cannot do this.  Check
7770         # by constructing a (very) simple shared library and inspecting its
7771         # symbols.
7772         if test "x$VERSIONED_SYMS" != "x"
7773         then
7774                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
7775                 WILDCARD_SYMS=no
7776
7777                 # make sources
7778                 rm -f conftest.*
7779
7780                 cat >conftest.ver <<EOF
7781 module_1.0 {
7782 global:
7783         globalf1;
7784 local:
7785         localf1;
7786 };
7787 module_2.0 {
7788 global:
7789         globalf2;
7790 local:
7791         localf2;
7792         _*;
7793 } module_1.0;
7794 submodule_1.0 {
7795 global:
7796         subglobalf1;
7797         _ismissing;
7798 local:
7799         sublocalf1;
7800 };
7801 submodule_2.0 {
7802 global:
7803         subglobalf2;
7804 local:
7805         sublocalf2;
7806         _*;
7807 } submodule_1.0;
7808 EOF
7809                 cat >conftest.$ac_ext <<EOF
7810 #line __oline__ "configure"
7811 int     _ismissing(void) { return 1; }
7812 int     _localf1(void) { return 1; }
7813 int     _localf2(void) { return 2; }
7814 int     globalf1(void) { return 1; }
7815 int     globalf2(void) { return 2; }
7816 int     _sublocalf1(void) { return 1; }
7817 int     _sublocalf2(void) { return 2; }
7818 int     subglobalf1(void) { return 1; }
7819 int     subglobalf2(void) { return 2; }
7820 EOF
7821                 cat >conftest.mk <<EOF
7822 CC=${CC}
7823 CFLAGS=${CFLAGS}
7824 CPPFLAGS=${CPPFLAGS}
7825 LDFLAGS=${LDFLAGS}
7826 LIBS=${LIBS}
7827 VERSIONED_SYMS=${VERSIONED_SYMS}
7828 RESULTING_SYMS=conftest.ver
7829 MK_SHARED_LIB=${MK_SHARED_LIB}
7830 conftest.so: conftest.$ac_cv_objext
7831                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
7832 EOF
7833
7834                 # compile source, make library
7835                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
7836                 then
7837                         # test for missing symbol in either Data or Text section
7838                         cf_missing=`nm -P conftest.so 2>&AC_FD_CC |fgrep _ismissing | egrep '[[         ]][[DT]][[      ]]'`
7839                         test -n "$cf_missing" && WILDCARD_SYMS=yes
7840                 fi
7841                 AC_MSG_RESULT($WILDCARD_SYMS)
7842                 rm -f conftest.*
7843         fi
7844 fi
7845 AC_SUBST(RESULTING_SYMS)
7846 AC_SUBST(VERSIONED_SYMS)
7847 AC_SUBST(WILDCARD_SYMS)
7848 ])dnl
7849 dnl ---------------------------------------------------------------------------
7850 dnl CF_XOPEN_SOURCE version: 52 updated: 2016/08/27 12:21:42
7851 dnl ---------------
7852 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
7853 dnl or adapt to the vendor's definitions to get equivalent functionality,
7854 dnl without losing the common non-POSIX features.
7855 dnl
7856 dnl Parameters:
7857 dnl     $1 is the nominal value for _XOPEN_SOURCE
7858 dnl     $2 is the nominal value for _POSIX_C_SOURCE
7859 AC_DEFUN([CF_XOPEN_SOURCE],[
7860 AC_REQUIRE([AC_CANONICAL_HOST])
7861
7862 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
7863 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
7864 cf_xopen_source=
7865
7866 case $host_os in
7867 (aix[[4-7]]*)
7868         cf_xopen_source="-D_ALL_SOURCE"
7869         ;;
7870 (msys)
7871         cf_XOPEN_SOURCE=600
7872         ;;
7873 (darwin[[0-8]].*)
7874         cf_xopen_source="-D_APPLE_C_SOURCE"
7875         ;;
7876 (darwin*)
7877         cf_xopen_source="-D_DARWIN_C_SOURCE"
7878         cf_XOPEN_SOURCE=
7879         ;;
7880 (freebsd*|dragonfly*)
7881         # 5.x headers associate
7882         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
7883         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
7884         cf_POSIX_C_SOURCE=200112L
7885         cf_XOPEN_SOURCE=600
7886         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
7887         ;;
7888 (hpux11*)
7889         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
7890         ;;
7891 (hpux*)
7892         cf_xopen_source="-D_HPUX_SOURCE"
7893         ;;
7894 (irix[[56]].*)
7895         cf_xopen_source="-D_SGI_SOURCE"
7896         cf_XOPEN_SOURCE=
7897         ;;
7898 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
7899         CF_GNU_SOURCE
7900         ;;
7901 (minix*)
7902         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
7903         ;;
7904 (mirbsd*)
7905         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
7906         cf_XOPEN_SOURCE=
7907         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7908         ;;
7909 (netbsd*)
7910         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
7911         ;;
7912 (openbsd[[4-9]]*)
7913         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
7914         cf_xopen_source="-D_BSD_SOURCE"
7915         cf_XOPEN_SOURCE=600
7916         ;;
7917 (openbsd*)
7918         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
7919         ;;
7920 (osf[[45]]*)
7921         cf_xopen_source="-D_OSF_SOURCE"
7922         ;;
7923 (nto-qnx*)
7924         cf_xopen_source="-D_QNX_SOURCE"
7925         ;;
7926 (sco*)
7927         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
7928         ;;
7929 (solaris2.*)
7930         cf_xopen_source="-D__EXTENSIONS__"
7931         cf_cv_xopen_source=broken
7932         ;;
7933 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
7934         cf_XOPEN_SOURCE=
7935         cf_POSIX_C_SOURCE=
7936         ;;
7937 (*)
7938         CF_TRY_XOPEN_SOURCE
7939         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7940         ;;
7941 esac
7942
7943 if test -n "$cf_xopen_source" ; then
7944         CF_ADD_CFLAGS($cf_xopen_source,true)
7945 fi
7946
7947 dnl In anything but the default case, we may have system-specific setting
7948 dnl which is still not guaranteed to provide all of the entrypoints that
7949 dnl _XOPEN_SOURCE would yield.
7950 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
7951         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
7952         AC_TRY_COMPILE([#include <stdlib.h>],[
7953 #ifndef _XOPEN_SOURCE
7954 make an error
7955 #endif],
7956         [cf_XOPEN_SOURCE_set=yes],
7957         [cf_XOPEN_SOURCE_set=no])
7958         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
7959         if test $cf_XOPEN_SOURCE_set = yes
7960         then
7961                 AC_TRY_COMPILE([#include <stdlib.h>],[
7962 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
7963 make an error
7964 #endif],
7965                 [cf_XOPEN_SOURCE_set_ok=yes],
7966                 [cf_XOPEN_SOURCE_set_ok=no])
7967                 if test $cf_XOPEN_SOURCE_set_ok = no
7968                 then
7969                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
7970                 fi
7971         else
7972                 CF_TRY_XOPEN_SOURCE
7973         fi
7974 fi
7975 ])