9bff894d0a0282d6b07064ebad36cd0f9c0b97a4
[ncurses.git] / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2011,2012 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: aclocal.m4,v 1.608 2012/02/25 20:21:19 tom Exp $
32 dnl Macros used in NCURSES auto-configuration script.
33 dnl
34 dnl These macros are maintained separately from NCURSES.  The copyright on
35 dnl this file applies to the aggregation of macros and does not affect use of
36 dnl these macros in other applications.
37 dnl
38 dnl See http://invisible-island.net/autoconf/ for additional information.
39 dnl
40 dnl ---------------------------------------------------------------------------
41 dnl ---------------------------------------------------------------------------
42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
43 dnl -------------------
44 dnl Inserted as requested by gettext 0.10.40
45 dnl File from /usr/share/aclocal
46 dnl codeset.m4
47 dnl ====================
48 dnl serial AM1
49 dnl
50 dnl From Bruno Haible.
51 AC_DEFUN([AM_LANGINFO_CODESET],
52 [
53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
54     [AC_TRY_LINK([#include <langinfo.h>],
55       [char* cs = nl_langinfo(CODESET);],
56       am_cv_langinfo_codeset=yes,
57       am_cv_langinfo_codeset=no)
58     ])
59   if test $am_cv_langinfo_codeset = yes; then
60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
62   fi
63 ])dnl
64 dnl ---------------------------------------------------------------------------
65 dnl CF_ACVERSION_CHECK version: 2 updated: 2011/05/08 11:22:03
66 dnl ------------------
67 dnl Conditionally generate script according to whether we're using a given autoconf.
68 dnl
69 dnl $1 = version to compare against
70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
71 dnl $3 = code to use if AC_ACVERSION is older than $1.
72 define(CF_ACVERSION_CHECK,
73 [
74 ifdef([m4_version_compare],
75 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
76 [CF_ACVERSION_COMPARE(
77 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
78 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
79 dnl ---------------------------------------------------------------------------
80 dnl CF_ACVERSION_COMPARE version: 2 updated: 2011/04/14 20:56:50
81 dnl --------------------
82 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
83 dnl                      MAJOR2, MINOR2, TERNARY2,
84 dnl                      PRINTABLE2, not FOUND, FOUND)
85 define(CF_ACVERSION_COMPARE,
86 [ifelse(builtin([eval], [$2 < $5]), 1,
87 [ifelse([$8], , ,[$8])],
88 [ifelse([$9], , ,[$9])])])dnl
89 dnl ---------------------------------------------------------------------------
90 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
91 dnl -------------------
92 dnl Construct the list of include-options for the C programs in the Ada95
93 dnl binding.
94 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
95 [
96 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
97 if test "$srcdir" != "."; then
98         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
99 fi
100 if test "$GCC" != yes; then
101         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
102 elif test "$includedir" != "/usr/include"; then
103         if test "$includedir" = '${prefix}/include' ; then
104                 if test $prefix != /usr ; then
105                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
106                 fi
107         else
108                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
109         fi
110 fi
111 AC_SUBST(ACPPFLAGS)
112 ])dnl
113 dnl ---------------------------------------------------------------------------
114 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
115 dnl ---------------
116 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
117 AC_DEFUN([CF_ADD_ADAFLAGS],[
118         ADAFLAGS="$ADAFLAGS $1"
119         AC_SUBST(ADAFLAGS)
120 ])dnl
121 dnl ---------------------------------------------------------------------------
122 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
123 dnl -------------
124 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
125 dnl The second parameter if given makes this macro verbose.
126 dnl
127 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
128 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
129 dnl confused by the quotes (which require backslashes to keep them usable).
130 AC_DEFUN([CF_ADD_CFLAGS],
131 [
132 cf_fix_cppflags=no
133 cf_new_cflags=
134 cf_new_cppflags=
135 cf_new_extra_cppflags=
136
137 for cf_add_cflags in $1
138 do
139 case $cf_fix_cppflags in
140 no)
141         case $cf_add_cflags in #(vi
142         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
143                 case $cf_add_cflags in
144                 -D*)
145                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
146
147                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
148                                 && test -z "${cf_tst_cflags}" \
149                                 && cf_fix_cppflags=yes
150
151                         if test $cf_fix_cppflags = yes ; then
152                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
153                                 continue
154                         elif test "${cf_tst_cflags}" = "\"'" ; then
155                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
156                                 continue
157                         fi
158                         ;;
159                 esac
160                 case "$CPPFLAGS" in
161                 *$cf_add_cflags) #(vi
162                         ;;
163                 *) #(vi
164                         case $cf_add_cflags in #(vi
165                         -D*)
166                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
167                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
168                                 ;;
169                         esac
170                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
171                         ;;
172                 esac
173                 ;;
174         *)
175                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
176                 ;;
177         esac
178         ;;
179 yes)
180         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
181
182         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
183
184         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
185                 && test -z "${cf_tst_cflags}" \
186                 && cf_fix_cppflags=no
187         ;;
188 esac
189 done
190
191 if test -n "$cf_new_cflags" ; then
192         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
193         CFLAGS="$CFLAGS $cf_new_cflags"
194 fi
195
196 if test -n "$cf_new_cppflags" ; then
197         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
198         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
199 fi
200
201 if test -n "$cf_new_extra_cppflags" ; then
202         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
203         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
204 fi
205
206 AC_SUBST(EXTRA_CPPFLAGS)
207
208 ])dnl
209 dnl ---------------------------------------------------------------------------
210 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
211 dnl -------------
212 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
213 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
214 dnl but old versions (and some misinstalled ones) need that.  To make things
215 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
216 dnl the include-path).
217 AC_DEFUN([CF_ADD_INCDIR],
218 [
219 if test -n "$1" ; then
220   for cf_add_incdir in $1
221   do
222         while test $cf_add_incdir != /usr/include
223         do
224           if test -d $cf_add_incdir
225           then
226                 cf_have_incdir=no
227                 if test -n "$CFLAGS$CPPFLAGS" ; then
228                   # a loop is needed to ensure we can add subdirs of existing dirs
229                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
230                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
231                           cf_have_incdir=yes; break
232                         fi
233                   done
234                 fi
235
236                 if test "$cf_have_incdir" = no ; then
237                   if test "$cf_add_incdir" = /usr/local/include ; then
238                         if test "$GCC" = yes
239                         then
240                           cf_save_CPPFLAGS=$CPPFLAGS
241                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
242                           AC_TRY_COMPILE([#include <stdio.h>],
243                                   [printf("Hello")],
244                                   [],
245                                   [cf_have_incdir=yes])
246                           CPPFLAGS=$cf_save_CPPFLAGS
247                         fi
248                   fi
249                 fi
250
251                 if test "$cf_have_incdir" = no ; then
252                   CF_VERBOSE(adding $cf_add_incdir to include-path)
253                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
254
255                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
256                   test "$cf_top_incdir" = "$cf_add_incdir" && break
257                   cf_add_incdir="$cf_top_incdir"
258                 else
259                   break
260                 fi
261           fi
262         done
263   done
264 fi
265 ])dnl
266 dnl ---------------------------------------------------------------------------
267 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
268 dnl ----------
269 dnl Add a library, used to enforce consistency.
270 dnl
271 dnl $1 = library to add, without the "-l"
272 dnl $2 = variable to update (default $LIBS)
273 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
274 dnl ---------------------------------------------------------------------------
275 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
276 dnl -------------
277 dnl     Adds to the library-path
278 dnl
279 dnl     Some machines have trouble with multiple -L options.
280 dnl
281 dnl $1 is the (list of) directory(s) to add
282 dnl $2 is the optional name of the variable to update (default LDFLAGS)
283 dnl
284 AC_DEFUN([CF_ADD_LIBDIR],
285 [
286 if test -n "$1" ; then
287   for cf_add_libdir in $1
288   do
289     if test $cf_add_libdir = /usr/lib ; then
290       :
291     elif test -d $cf_add_libdir
292     then
293       cf_have_libdir=no
294       if test -n "$LDFLAGS$LIBS" ; then
295         # a loop is needed to ensure we can add subdirs of existing dirs
296         for cf_test_libdir in $LDFLAGS $LIBS ; do
297           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
298             cf_have_libdir=yes; break
299           fi
300         done
301       fi
302       if test "$cf_have_libdir" = no ; then
303         CF_VERBOSE(adding $cf_add_libdir to library-path)
304         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
305       fi
306     fi
307   done
308 fi
309 ])dnl
310 dnl ---------------------------------------------------------------------------
311 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
312 dnl -----------
313 dnl Add one or more libraries, used to enforce consistency.
314 dnl
315 dnl $1 = libraries to add, with the "-l", etc.
316 dnl $2 = variable to update (default $LIBS)
317 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
318 dnl ---------------------------------------------------------------------------
319 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
320 dnl ------------------
321 dnl Append to a search-list for a nonstandard header/lib-file
322 dnl     $1 = the variable to return as result
323 dnl     $2 = the package name
324 dnl     $3 = the subdirectory, e.g., bin, include or lib
325 dnl $4 = the directory under which we will test for subdirectories
326 dnl $5 = a directory that we do not want $4 to match
327 AC_DEFUN([CF_ADD_SUBDIR_PATH],
328 [
329 test "$4" != "$5" && \
330 test -d "$4" && \
331 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
332         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
333         test -d $4/$3 &&          $1="[$]$1 $4/$3"
334         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
335         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
336         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
337         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
338 }
339 ])dnl
340 dnl ---------------------------------------------------------------------------
341 dnl CF_ANSI_CC_CHECK version: 11 updated: 2011/07/01 19:47:45
342 dnl ----------------
343 dnl This was originally adapted from the macros 'fp_PROG_CC_STDC' and
344 dnl 'fp_C_PROTOTYPES' in the sharutils 4.2 distribution.
345 AC_DEFUN([CF_ANSI_CC_CHECK],
346 [
347 # This should have been defined by AC_PROG_CC
348 : ${CC:=cc}
349
350 # Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
351 # into CC.  This will not help with broken scripts that wrap the compiler with
352 # options, but eliminates a more common category of user confusion.
353 AC_MSG_CHECKING(\$CC variable)
354 case "$CC" in #(vi
355 *[[\ \  ]]-[[IUD]]*)
356         AC_MSG_RESULT(broken)
357         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
358         # humor him...
359         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
360         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
361         CF_ADD_CFLAGS($cf_flags)
362         ;;
363 *)
364         AC_MSG_RESULT(ok)
365         ;;
366 esac
367
368 AC_CACHE_CHECK(for ${CC:-cc} option to accept ANSI C, cf_cv_ansi_cc,[
369 cf_cv_ansi_cc=no
370 cf_save_CFLAGS="$CFLAGS"
371 cf_save_CPPFLAGS="$CPPFLAGS"
372 # Don't try gcc -ansi; that turns off useful extensions and
373 # breaks some systems' header files.
374 # AIX                   -qlanglvl=ansi
375 # Ultrix and OSF/1      -std1
376 # HP-UX                 -Aa -D_HPUX_SOURCE
377 # SVR4                  -Xc
378 # UnixWare 1.2          (cannot use -Xc, since ANSI/POSIX clashes)
379 for cf_arg in "-DCC_HAS_PROTOS" \
380         "" \
381         -qlanglvl=ansi \
382         -std1 \
383         -Ae \
384         "-Aa -D_HPUX_SOURCE" \
385         -Xc
386 do
387         CF_ADD_CFLAGS($cf_arg)
388         AC_TRY_COMPILE(
389 [
390 #ifndef CC_HAS_PROTOS
391 #if !defined(__STDC__) || (__STDC__ != 1)
392 choke me
393 #endif
394 #endif
395 ],[
396         int test (int i, double x);
397         struct s1 {int (*f) (int a);};
398         struct s2 {int (*f) (double a);};],
399         [cf_cv_ansi_cc="$cf_arg"; break])
400 done
401 CFLAGS="$cf_save_CFLAGS"
402 CPPFLAGS="$cf_save_CPPFLAGS"
403 ])
404
405 if test "$cf_cv_ansi_cc" != "no"; then
406 if test ".$cf_cv_ansi_cc" != ".-DCC_HAS_PROTOS"; then
407         CF_ADD_CFLAGS($cf_cv_ansi_cc)
408 else
409         AC_DEFINE(CC_HAS_PROTOS)
410 fi
411 fi
412 ])dnl
413 dnl ---------------------------------------------------------------------------
414 dnl CF_ANSI_CC_REQD version: 4 updated: 2008/03/23 14:48:54
415 dnl ---------------
416 dnl For programs that must use an ANSI compiler, obtain compiler options that
417 dnl will make it recognize prototypes.  We'll do preprocessor checks in other
418 dnl macros, since tools such as unproto can fake prototypes, but only part of
419 dnl the preprocessor.
420 AC_DEFUN([CF_ANSI_CC_REQD],
421 [AC_REQUIRE([CF_ANSI_CC_CHECK])
422 if test "$cf_cv_ansi_cc" = "no"; then
423         AC_MSG_ERROR(
424 [Your compiler does not appear to recognize prototypes.
425 You have the following choices:
426         a. adjust your compiler options
427         b. get an up-to-date compiler
428         c. use a wrapper such as unproto])
429 fi
430 ])dnl
431 dnl ---------------------------------------------------------------------------
432 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
433 dnl --------------
434 dnl Allow user to disable a normally-on option.
435 AC_DEFUN([CF_ARG_DISABLE],
436 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
437 dnl ---------------------------------------------------------------------------
438 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
439 dnl -------------
440 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
441 dnl values.
442 dnl
443 dnl Parameters:
444 dnl $1 = option name
445 dnl $2 = help-string
446 dnl $3 = action to perform if option is not default
447 dnl $4 = action if perform if option is default
448 dnl $5 = default option value (either 'yes' or 'no')
449 AC_DEFUN([CF_ARG_OPTION],
450 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
451   if test "$enableval" != "$5" ; then
452 ifelse([$3],,[    :]dnl
453 ,[    $3]) ifelse([$4],,,[
454   else
455     $4])
456   fi],[enableval=$5 ifelse([$4],,,[
457   $4
458 ])dnl
459   ])])dnl
460 dnl ---------------------------------------------------------------------------
461 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
462 dnl -----------
463 dnl Check for suitable "ar" (archiver) options for updating an archive.
464 AC_DEFUN([CF_AR_FLAGS],[
465 AC_REQUIRE([CF_PROG_AR])
466
467 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
468         cf_cv_ar_flags=unknown
469         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
470         do
471
472                 # check if $ARFLAGS already contains this choice
473                 if test "x$ARFLAGS" != "x" ; then
474                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
475                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
476                                 cf_cv_ar_flags=
477                                 break
478                         fi
479                 fi
480
481                 rm -f conftest.$ac_cv_objext
482                 rm -f conftest.a
483
484                 cat >conftest.$ac_ext <<EOF
485 #line __oline__ "configure"
486 int     testdata[[3]] = { 123, 456, 789 };
487 EOF
488                 if AC_TRY_EVAL(ac_compile) ; then
489                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
490                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
491                         if test -f conftest.a ; then
492                                 cf_cv_ar_flags=$cf_ar_flags
493                                 break
494                         fi
495                 else
496                         CF_VERBOSE(cannot compile test-program)
497                         break
498                 fi
499         done
500         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
501 ])
502
503 if test -n "$ARFLAGS" ; then
504         if test -n "$cf_cv_ar_flags" ; then
505                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
506         fi
507 else
508         ARFLAGS=$cf_cv_ar_flags
509 fi
510
511 AC_SUBST(ARFLAGS)
512 ])
513 dnl ---------------------------------------------------------------------------
514 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
515 dnl -----------------
516 dnl Check if awk can handle big strings using printf.  Some older versions of
517 dnl awk choke on large strings passed via "%s".
518 dnl
519 dnl $1 = desired string size
520 dnl $2 = variable to set with result
521 AC_DEFUN([CF_AWK_BIG_PRINTF],
522 [
523         case x$AWK in #(vi
524         x)
525                 eval $2=no
526                 ;;
527         *) #(vi
528                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
529                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
530                         eval $2=yes
531                 else
532                         eval $2=no
533                 fi
534                 ;;
535         esac
536 ])dnl
537 dnl ---------------------------------------------------------------------------
538 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
539 dnl ------------
540 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
541 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
542 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
543 dnl
544 dnl Treat the configuration-variable specially here, since we're directly
545 dnl substituting its value (i.e., 1/0).
546 dnl
547 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
548 AC_DEFUN([CF_BOOL_DECL],
549 [
550 AC_MSG_CHECKING(if we should include stdbool.h)
551
552 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
553         AC_TRY_COMPILE([],[bool foo = false],
554                 [cf_cv_header_stdbool_h=0],
555                 [AC_TRY_COMPILE([
556 #ifndef __BEOS__
557 #include <stdbool.h>
558 #endif
559 ],[bool foo = false],
560                         [cf_cv_header_stdbool_h=1],
561                         [cf_cv_header_stdbool_h=0])])])
562
563 if test "$cf_cv_header_stdbool_h" = 1
564 then    AC_MSG_RESULT(yes)
565 else    AC_MSG_RESULT(no)
566 fi
567
568 AC_MSG_CHECKING([for builtin bool type])
569
570 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
571         AC_TRY_COMPILE([
572 #include <stdio.h>
573 #include <sys/types.h>
574 ],[bool x = false],
575                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
576                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
577         ])
578
579 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
580 then    AC_MSG_RESULT(yes)
581 else    AC_MSG_RESULT(no)
582 fi
583 ])dnl
584 dnl ---------------------------------------------------------------------------
585 dnl CF_BOOL_SIZE version: 12 updated: 2006/12/16 12:33:30
586 dnl ------------
587 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
588 dnl Don't bother looking for bool.h, since it's been deprecated.
589 dnl
590 dnl If the current compiler is C rather than C++, we get the bool definition
591 dnl from <stdbool.h>.
592 AC_DEFUN([CF_BOOL_SIZE],
593 [
594 AC_MSG_CHECKING([for size of bool])
595 AC_CACHE_VAL(cf_cv_type_of_bool,[
596         rm -f cf_test.out
597         AC_TRY_RUN([
598 #include <stdlib.h>
599 #include <stdio.h>
600
601 #if defined(__cplusplus)
602
603 #ifdef HAVE_GXX_BUILTIN_H
604 #include <g++/builtin.h>
605 #elif HAVE_GPP_BUILTIN_H
606 #include <gpp/builtin.h>
607 #elif HAVE_BUILTIN_H
608 #include <builtin.h>
609 #endif
610
611 #else
612
613 #if $cf_cv_header_stdbool_h
614 #include <stdbool.h>
615 #endif
616
617 #endif
618
619 main()
620 {
621         FILE *fp = fopen("cf_test.out", "w");
622         if (fp != 0) {
623                 bool x = true;
624                 if ((bool)(-x) >= 0)
625                         fputs("unsigned ", fp);
626                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
627                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
628                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
629                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
630                 fclose(fp);
631         }
632         ${cf_cv_main_return:-return}(0);
633 }
634                 ],
635                 [cf_cv_type_of_bool=`cat cf_test.out`
636                  if test -z "$cf_cv_type_of_bool"; then
637                    cf_cv_type_of_bool=unknown
638                  fi],
639                 [cf_cv_type_of_bool=unknown],
640                 [cf_cv_type_of_bool=unknown])
641         ])
642         rm -f cf_test.out
643 AC_MSG_RESULT($cf_cv_type_of_bool)
644 if test "$cf_cv_type_of_bool" = unknown ; then
645         case .$NCURSES_BOOL in #(vi
646         .auto|.) NCURSES_BOOL=unsigned;;
647         esac
648         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
649         cf_cv_type_of_bool=$NCURSES_BOOL
650 fi
651 ])dnl
652 dnl ---------------------------------------------------------------------------
653 dnl CF_BUILD_CC version: 6 updated: 2006/10/14 15:23:15
654 dnl -----------
655 dnl If we're cross-compiling, allow the user to override the tools and their
656 dnl options.  The configure script is oriented toward identifying the host
657 dnl compiler, etc., but we need a build compiler to generate parts of the
658 dnl source.
659 dnl
660 dnl $1 = default for $CPPFLAGS
661 dnl $2 = default for $LIBS
662 AC_DEFUN([CF_BUILD_CC],[
663 AC_REQUIRE([CF_PROG_EXT])
664 if test "$cross_compiling" = yes ; then
665
666         # defaults that we might want to override
667         : ${BUILD_CFLAGS:=''}
668         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
669         : ${BUILD_LDFLAGS:=''}
670         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
671         : ${BUILD_EXEEXT:='$x'}
672         : ${BUILD_OBJEXT:='o'}
673
674         AC_ARG_WITH(build-cc,
675                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
676                 [BUILD_CC="$withval"],
677                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
678         AC_MSG_CHECKING(for native build C compiler)
679         AC_MSG_RESULT($BUILD_CC)
680
681         AC_MSG_CHECKING(for native build C preprocessor)
682         AC_ARG_WITH(build-cpp,
683                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
684                 [BUILD_CPP="$withval"],
685                 [BUILD_CPP='${BUILD_CC} -E'])
686         AC_MSG_RESULT($BUILD_CPP)
687
688         AC_MSG_CHECKING(for native build C flags)
689         AC_ARG_WITH(build-cflags,
690                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
691                 [BUILD_CFLAGS="$withval"])
692         AC_MSG_RESULT($BUILD_CFLAGS)
693
694         AC_MSG_CHECKING(for native build C preprocessor-flags)
695         AC_ARG_WITH(build-cppflags,
696                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
697                 [BUILD_CPPFLAGS="$withval"])
698         AC_MSG_RESULT($BUILD_CPPFLAGS)
699
700         AC_MSG_CHECKING(for native build linker-flags)
701         AC_ARG_WITH(build-ldflags,
702                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
703                 [BUILD_LDFLAGS="$withval"])
704         AC_MSG_RESULT($BUILD_LDFLAGS)
705
706         AC_MSG_CHECKING(for native build linker-libraries)
707         AC_ARG_WITH(build-libs,
708                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
709                 [BUILD_LIBS="$withval"])
710         AC_MSG_RESULT($BUILD_LIBS)
711
712         # this assumes we're on Unix.
713         BUILD_EXEEXT=
714         BUILD_OBJEXT=o
715
716         : ${BUILD_CC:='${CC}'}
717
718         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
719                 AC_MSG_ERROR([Cross-build requires two compilers.
720 Use --with-build-cc to specify the native compiler.])
721         fi
722
723 else
724         : ${BUILD_CC:='${CC}'}
725         : ${BUILD_CPP:='${CPP}'}
726         : ${BUILD_CFLAGS:='${CFLAGS}'}
727         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
728         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
729         : ${BUILD_LIBS:='${LIBS}'}
730         : ${BUILD_EXEEXT:='$x'}
731         : ${BUILD_OBJEXT:='o'}
732 fi
733
734 AC_SUBST(BUILD_CC)
735 AC_SUBST(BUILD_CPP)
736 AC_SUBST(BUILD_CFLAGS)
737 AC_SUBST(BUILD_CPPFLAGS)
738 AC_SUBST(BUILD_LDFLAGS)
739 AC_SUBST(BUILD_LIBS)
740 AC_SUBST(BUILD_EXEEXT)
741 AC_SUBST(BUILD_OBJEXT)
742 ])dnl
743 dnl ---------------------------------------------------------------------------
744 dnl CF_CFG_DEFAULTS version: 8 updated: 2011/06/04 20:09:13
745 dnl ---------------
746 dnl Determine the default configuration into which we'll install ncurses.  This
747 dnl can be overridden by the user's command-line options.  There's two items to
748 dnl look for:
749 dnl     1. the prefix (e.g., /usr)
750 dnl     2. the header files (e.g., /usr/include/ncurses)
751 dnl We'll look for a previous installation of ncurses and use the same defaults.
752 dnl
753 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
754 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
755 dnl programs from a vendor's.
756 AC_DEFUN([CF_CFG_DEFAULTS],
757 [
758 AC_MSG_CHECKING(for prefix)
759 if test "x$prefix" = "xNONE" ; then
760         case "$cf_cv_system_name" in
761                 # non-vendor systems don't have a conflict
762         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|k*bsd*-gnu)
763                 prefix=/usr
764                 ;;
765         *)      prefix=$ac_default_prefix
766                 ;;
767         esac
768 fi
769 AC_MSG_RESULT($prefix)
770
771 if test "x$prefix" = "xNONE" ; then
772 AC_MSG_CHECKING(for default include-directory)
773 test -n "$verbose" && echo 1>&AC_FD_MSG
774 for cf_symbol in \
775         $includedir \
776         $includedir/ncurses \
777         $prefix/include \
778         $prefix/include/ncurses \
779         /usr/local/include \
780         /usr/local/include/ncurses \
781         /usr/include \
782         /usr/include/ncurses
783 do
784         cf_dir=`eval echo $cf_symbol`
785         if test -f $cf_dir/curses.h ; then
786         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
787                 includedir="$cf_symbol"
788                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
789                 break
790         fi
791         fi
792         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
793 done
794 AC_MSG_RESULT($includedir)
795 fi
796 ])dnl
797 dnl ---------------------------------------------------------------------------
798 dnl CF_CGETENT version: 4 updated: 2011/08/07 14:54:41
799 dnl ----------
800 dnl Check if the terminal-capability database functions are available.  If not,
801 dnl ncurses has a much-reduced version.
802 AC_DEFUN([CF_CGETENT],[
803 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
804 AC_TRY_LINK([
805 #include <stdlib.h>],[
806         char temp[128];
807         char *buf = temp;
808         char *db_array = temp;
809         cgetent(&buf, &db_array, "vt100");
810         cgetcap(buf, "tc", '=');
811         cgetmatch(buf, "tc");
812         ],
813         [cf_cv_cgetent=yes],
814         [cf_cv_cgetent=no])
815 ])
816
817 if test "$cf_cv_cgetent" = yes
818 then
819         AC_DEFINE(HAVE_BSD_CGETENT)
820 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
821 AC_TRY_LINK([
822 #include <stdlib.h>],[
823         char temp[128];
824         char *buf = temp;
825 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
826         const char *db_array = temp;
827         cgetent(&buf, &db_array, "vt100");
828 #endif
829         cgetcap(buf, "tc", '=');
830         cgetmatch(buf, "tc");
831         ],
832         [cf_cv_cgetent_const=yes],
833         [cf_cv_cgetent_const=no])
834 ])
835         if test "$cf_cv_cgetent_const" = yes
836         then
837                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const)
838         fi
839 fi
840 ])dnl
841 dnl ---------------------------------------------------------------------------
842 dnl CF_CHECK_CACHE version: 11 updated: 2008/03/23 14:45:59
843 dnl --------------
844 dnl Check if we're accidentally using a cache from a different machine.
845 dnl Derive the system name, as a check for reusing the autoconf cache.
846 dnl
847 dnl If we've packaged config.guess and config.sub, run that (since it does a
848 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
849 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
850 dnl which is useful in cross-compiles.
851 dnl
852 dnl Note: we would use $ac_config_sub, but that is one of the places where
853 dnl autoconf 2.5x broke compatibility with autoconf 2.13
854 AC_DEFUN([CF_CHECK_CACHE],
855 [
856 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
857         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
858         system_name="$host_os"
859 else
860         system_name="`(uname -s -r) 2>/dev/null`"
861         if test -z "$system_name" ; then
862                 system_name="`(hostname) 2>/dev/null`"
863         fi
864 fi
865 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name")
866 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
867
868 test -z "$system_name" && system_name="$cf_cv_system_name"
869 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
870
871 if test ".$system_name" != ".$cf_cv_system_name" ; then
872         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
873         AC_MSG_ERROR("Please remove config.cache and try again.")
874 fi
875 ])dnl
876 dnl ---------------------------------------------------------------------------
877 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
878 dnl --------------
879 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
880 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
881 dnl ourselves.
882 dnl
883 dnl $1 = the name to check
884 dnl $2 = the assumed type
885 AC_DEFUN([CF_CHECK_ERRNO],
886 [
887 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
888     AC_TRY_COMPILE([
889 #ifdef HAVE_STDLIB_H
890 #include <stdlib.h>
891 #endif
892 #include <stdio.h>
893 #include <sys/types.h>
894 #include <errno.h> ],
895     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
896     [cf_cv_dcl_$1=yes],
897     [cf_cv_dcl_$1=no])
898 ])
899
900 if test "$cf_cv_dcl_$1" = no ; then
901     CF_UPPER(cf_result,decl_$1)
902     AC_DEFINE_UNQUOTED($cf_result)
903 fi
904
905 # It's possible (for near-UNIX clones) that the data doesn't exist
906 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
907 ])dnl
908 dnl ---------------------------------------------------------------------------
909 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
910 dnl --------------------
911 dnl Check for existence of external data in the current set of libraries.  If
912 dnl we can modify it, it's real enough.
913 dnl $1 = the name to check
914 dnl $2 = its type
915 AC_DEFUN([CF_CHECK_EXTERN_DATA],
916 [
917 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
918     AC_TRY_LINK([
919 #undef $1
920 extern $2 $1;
921 ],
922     [$1 = 2],
923     [cf_cv_have_$1=yes],
924     [cf_cv_have_$1=no])
925 ])
926
927 if test "$cf_cv_have_$1" = yes ; then
928     CF_UPPER(cf_result,have_$1)
929     AC_DEFINE_UNQUOTED($cf_result)
930 fi
931
932 ])dnl
933 dnl ---------------------------------------------------------------------------
934 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
935 dnl -------------------
936 dnl Check if GPM is already linked with curses.  If so - and if the linkage
937 dnl is not "weak" - warn about this because it can create problems linking
938 dnl applications with ncurses.
939 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
940 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
941
942 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
943 cf_cv_check_gpm_wgetch=unknown
944 if test "$cross_compiling" != yes ; then
945
946 cat >conftest.$ac_ext <<CF_EOF
947 #include <gpm.h>
948 int main()
949 {
950         Gpm_Wgetch();
951         ${cf_cv_main_return:-return}(0);
952 }
953 CF_EOF
954
955         cf_save_LIBS="$LIBS"
956         # This only works if we can look at the symbol table.  If a shared
957         # library is stripped for install, we cannot use that.  So we're forced
958         # to rely on the static library, noting that some packagers may not
959         # include it.
960         LIBS="-static -lgpm -dynamic $LIBS"
961         if AC_TRY_EVAL(ac_compile) ; then
962                 if AC_TRY_EVAL(ac_link) ; then
963                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
964                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
965                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
966                 fi
967         fi
968         rm -rf conftest*
969         LIBS="$cf_save_LIBS"
970 fi
971 ])
972
973 if test "$cf_cv_check_gpm_wgetch" != yes ; then
974         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
975 fi
976 ])])dnl
977 dnl ---------------------------------------------------------------------------
978 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
979 dnl ----------------
980 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
981 AC_DEFUN([CF_CHECK_WCHAR_H],[
982 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
983 AC_TRY_COMPILE(
984 [
985 #include <stdlib.h>
986 #include <wchar.h>
987 ],[
988         wint_t foo = 0;
989         int bar = iswpunct(foo)],
990         [cf_cv_wchar_h_okay=yes],
991         [cf_cv_wchar_h_okay=no])])
992
993 if test $cf_cv_wchar_h_okay = no
994 then
995         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
996 fi
997 ])dnl
998 dnl ---------------------------------------------------------------------------
999 dnl CF_CPP_PARAM_INIT version: 5 updated: 2011/12/03 16:54:03
1000 dnl -----------------
1001 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1002 dnl is a late feature for the standard and is not in some recent compilers
1003 dnl (1999/9/11).
1004 AC_DEFUN([CF_CPP_PARAM_INIT],
1005 [
1006 if test -n "$CXX"; then
1007 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1008         AC_LANG_SAVE
1009         AC_LANG_CPLUSPLUS
1010         AC_TRY_RUN([
1011 class TEST {
1012 private:
1013         int value;
1014 public:
1015         TEST(int x = 1);
1016         ~TEST();
1017 };
1018
1019 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1020 {
1021         value = x;
1022 }
1023 int main() { }
1024 ],
1025         [cf_cv_cpp_param_init=yes],
1026         [cf_cv_cpp_param_init=no],
1027         [cf_cv_cpp_param_init=unknown])
1028         AC_LANG_RESTORE
1029 ])
1030 fi
1031 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT)
1032 ])dnl
1033 dnl ---------------------------------------------------------------------------
1034 dnl CF_CPP_STATIC_CAST version: 1 updated: 2005/07/23 16:52:43
1035 dnl ------------------
1036 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1037 dnl not be supported in g++ before 3.0
1038 AC_DEFUN([CF_CPP_STATIC_CAST],
1039 [
1040 if test -n "$CXX"; then
1041
1042 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1043         AC_LANG_SAVE
1044         AC_LANG_CPLUSPLUS
1045
1046         AC_TRY_COMPILE([
1047 class NCursesPanel
1048 {
1049 public:
1050   NCursesPanel(int nlines,
1051                int ncols,
1052                int begin_y = 0,
1053                int begin_x = 0)
1054   {
1055   }
1056
1057   ~NCursesPanel();
1058 };
1059
1060 template<class T> class NCursesUserPanel : public NCursesPanel
1061 {
1062 public:
1063   NCursesUserPanel (int nlines,
1064                     int ncols,
1065                     int begin_y = 0,
1066                     int begin_x = 0,
1067                     const T* p_UserData = static_cast<T*>(0))
1068     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1069   {
1070   };
1071   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1072   {
1073   };
1074
1075   virtual ~NCursesUserPanel() {};
1076 };
1077 ],[
1078         const char* p_UserData = static_cast<char*>(0)],
1079         [cf_cv_cpp_static_cast=yes],
1080         [cf_cv_cpp_static_cast=no])
1081
1082         AC_LANG_RESTORE
1083 ])
1084
1085 fi
1086
1087 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST)
1088 ])dnl
1089 dnl ---------------------------------------------------------------------------
1090 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1091 dnl ---------------
1092 dnl Setup special archiver flags for given compilers.
1093 AC_DEFUN([CF_CXX_AR_FLAGS],[
1094         CXX_AR='$(AR)'
1095         CXX_ARFLAGS='$(ARFLAGS)'
1096         case $cf_cv_system_name in #(vi
1097         irix*) #(vi
1098             if test "$GXX" != yes ; then
1099                 CXX_AR='$(CXX)'
1100                 CXX_ARFLAGS='-ar -o'
1101             fi
1102             ;;
1103         sco3.2v5*) #(vi
1104             CXXLDFLAGS="-u main"
1105             ;;
1106         solaris2*)
1107             if test "$GXX" != yes ; then
1108                 CXX_AR='$(CXX)'
1109                 CXX_ARFLAGS='-xar -o'
1110             fi
1111             ;;
1112         esac
1113         AC_SUBST(CXXLDFLAGS)
1114         AC_SUBST(CXX_AR)
1115         AC_SUBST(CXX_ARFLAGS)
1116 ])dnl
1117 dnl ---------------------------------------------------------------------------
1118 dnl CF_CXX_IOSTREAM_NAMESPACE version: 1 updated: 2011/10/29 08:35:34
1119 dnl -------------------------
1120 dnl For c++, check if iostream uses "std::" namespace.
1121 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1122 AC_CHECK_HEADERS(iostream)
1123 if test x"$ac_cv_header_iostream" = xyes ; then
1124         AC_MSG_CHECKING(if iostream uses std-namespace)
1125         AC_TRY_COMPILE([
1126 #include <iostream>
1127 using std::endl;
1128 using std::cerr;],[
1129 cerr << "testing" << endl;
1130 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1131         AC_MSG_RESULT($cf_iostream_namespace)
1132         if test "$cf_iostream_namespace" = yes ; then
1133                 AC_DEFINE(IOSTREAM_NAMESPACE)
1134         fi
1135 fi
1136 ])dnl
1137 dnl ---------------------------------------------------------------------------
1138 dnl CF_C_INLINE version: 3 updated: 2010/05/01 15:14:41
1139 dnl -----------
1140 dnl Check if the C compiler supports "inline".
1141 dnl $1 is the name of a shell variable to set if inline is supported
1142 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1143 AC_DEFUN([CF_C_INLINE],[
1144 AC_C_INLINE
1145 $1=
1146 if test "$ac_cv_c_inline" != no ; then
1147   $1=inline
1148   if test "$INTEL_COMPILER" = yes
1149   then
1150     :
1151   elif test "$GCC" = yes
1152   then
1153     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1154       cf_save_CFLAGS=$CFLAGS
1155       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1156       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1157       [${cf_cv_main_return:-return} foo()],
1158       [cf_cv_gcc_inline=yes],
1159       [cf_cv_gcc_inline=no])
1160       CFLAGS=$cf_save_CFLAGS
1161     ])
1162     if test "$cf_cv_gcc_inline" = yes ; then
1163         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1164     fi
1165   fi
1166 fi
1167 AC_SUBST($1)
1168 ])dnl
1169 dnl ---------------------------------------------------------------------------
1170 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1171 dnl ----------
1172 dnl "dirname" is not portable, so we fake it with a shell script.
1173 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1174 dnl ---------------------------------------------------------------------------
1175 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1176 dnl ---------------
1177 AC_DEFUN([CF_DIRS_TO_MAKE],
1178 [
1179 DIRS_TO_MAKE="lib"
1180 for cf_item in $cf_list_models
1181 do
1182         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1183         for cf_item2 in $DIRS_TO_MAKE
1184         do
1185                 test $cf_item2 = $cf_subdir && break
1186         done
1187         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1188 done
1189 for cf_dir in $DIRS_TO_MAKE
1190 do
1191         test ! -d $cf_dir && mkdir $cf_dir
1192 done
1193 AC_SUBST(DIRS_TO_MAKE)
1194 ])dnl
1195 dnl ---------------------------------------------------------------------------
1196 dnl CF_DISABLE_LEAKS version: 6 updated: 2010/07/23 04:14:32
1197 dnl ----------------
1198 dnl Combine no-leak checks with the libraries or tools that are used for the
1199 dnl checks.
1200 AC_DEFUN([CF_DISABLE_LEAKS],[
1201
1202 AC_REQUIRE([CF_WITH_DMALLOC])
1203 AC_REQUIRE([CF_WITH_DBMALLOC])
1204 AC_REQUIRE([CF_WITH_VALGRIND])
1205
1206 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1207 AC_ARG_ENABLE(leaks,
1208         [  --disable-leaks         test: free permanent memory, analyze leaks],
1209         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1210         : ${with_no_leaks:=no})
1211 AC_MSG_RESULT($with_no_leaks)
1212
1213 if test "$with_no_leaks" = yes ; then
1214         AC_DEFINE(NO_LEAKS)
1215         AC_DEFINE(YY_NO_LEAKS)
1216 fi
1217 ])dnl
1218 dnl ---------------------------------------------------------------------------
1219 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1220 dnl --------------------------
1221 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1222 dnl the older "-version-info" feature.  The newer feature allows us to use
1223 dnl version numbering on shared libraries which make them compatible with
1224 dnl various systems.
1225 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1226 [
1227 AC_MSG_CHECKING(if libtool -version-number should be used)
1228 CF_ARG_DISABLE(libtool-version,
1229         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1230         [cf_libtool_version=no],
1231         [cf_libtool_version=yes])
1232 AC_MSG_RESULT($cf_libtool_version)
1233
1234 if test "$cf_libtool_version" = yes ; then
1235         LIBTOOL_VERSION="-version-number"
1236 else
1237         LIBTOOL_VERSION="-version-info"
1238 fi
1239
1240 AC_SUBST(LIBTOOL_VERSION)
1241 ])dnl
1242 dnl ---------------------------------------------------------------------------
1243 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1244 dnl ---------------------
1245 dnl The rpath-hack makes it simpler to build programs, particularly with the
1246 dnl *BSD ports which may have essential libraries in unusual places.  But it
1247 dnl can interfere with building an executable for the base system.  Use this
1248 dnl option in that case.
1249 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1250 [
1251 AC_MSG_CHECKING(if rpath-hack should be disabled)
1252 CF_ARG_DISABLE(rpath-hack,
1253         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1254         [cf_disable_rpath_hack=yes],
1255         [cf_disable_rpath_hack=no])
1256 AC_MSG_RESULT($cf_disable_rpath_hack)
1257 if test "$cf_disable_rpath_hack" = no ; then
1258         CF_RPATH_HACK
1259 fi
1260 ])
1261 dnl ---------------------------------------------------------------------------
1262 dnl CF_ENABLE_PC_FILES version: 7 updated: 2011/12/10 18:58:47
1263 dnl ------------------
1264 dnl This is the "--enable-pc-files" option, which is available if there is a
1265 dnl pkg-config configuration on the local machine.
1266 AC_DEFUN([CF_ENABLE_PC_FILES],[
1267 AC_REQUIRE([CF_PKG_CONFIG])
1268 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1269
1270 if test "$PKG_CONFIG" != none ; then
1271         if test -n "$PKG_CONFIG_LIBDIR" && test -d "$PKG_CONFIG_LIBDIR" ; then
1272                 AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1273                 AC_ARG_ENABLE(pc-files,
1274                         [  --enable-pc-files       generate and install .pc files for pkg-config],
1275                         [enable_pc_files=$enableval],
1276                         [enable_pc_files=no])
1277                 AC_MSG_RESULT($enable_pc_files)
1278         elif test -z "$PKG_CONFIG_LIBDIR" || test "$PKG_CONFIG_LIBDIR" != no; then
1279                 enable_pc_files=no
1280                 AC_MSG_WARN(did not find $PKG_CONFIG library)
1281         fi
1282 else
1283         enable_pc_files=no
1284 fi
1285 ])dnl
1286 dnl ---------------------------------------------------------------------------
1287 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1288 dnl ---------------
1289 dnl Check if the rpath option should be used, setting cache variable
1290 dnl cf_cv_enable_rpath if so.
1291 AC_DEFUN([CF_ENABLE_RPATH],
1292 [
1293 AC_MSG_CHECKING(if rpath option should be used)
1294 AC_ARG_ENABLE(rpath,
1295 [  --enable-rpath          use rpath option when generating shared libraries],
1296 [cf_cv_enable_rpath=$enableval],
1297 [cf_cv_enable_rpath=no])
1298 AC_MSG_RESULT($cf_cv_enable_rpath)
1299 ])dnl
1300 dnl ---------------------------------------------------------------------------
1301 dnl CF_ENABLE_STRING_HACKS version: 1 updated: 2012/02/25 06:33:21
1302 dnl ----------------------
1303 dnl On a few platforms, the compiler and/or loader nags with untruthful
1304 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1305 dnl and implying that most uses of the recommended alternatives are correct.
1306 dnl
1307 dnl Factually speaking, no one has actually counted the number of uses of these
1308 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1309 dnl instances are meaningless compared to the hundreds of millions of lines of
1310 dnl existing C code.
1311 dnl
1312 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1313 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1314 dnl standard - but evolved through phases, and older implementations are likely
1315 dnl to yield surprising results, as documented in manpages on various systems.
1316 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1317 [
1318 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1319 AC_ARG_ENABLE(string-hacks,
1320         [  --enable-string-hacks  work around bogus compiler/loader warnings],
1321         [with_string_hacks=$enableval],
1322         [with_string_hacks=no])
1323 AC_MSG_RESULT($with_string_hacks)
1324
1325 if test "x$with_string_hacks" = "xyes"; then
1326         AC_DEFINE(USE_STRING_HACKS)
1327         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1328         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1329 fi
1330 ])dnl
1331 dnl ---------------------------------------------------------------------------
1332 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1333 dnl --------
1334 dnl Check if 'errno' is declared in <errno.h>
1335 AC_DEFUN([CF_ERRNO],
1336 [
1337 CF_CHECK_ERRNO(errno)
1338 ])dnl
1339 dnl ---------------------------------------------------------------------------
1340 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1341 dnl ---------------
1342 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1343 dnl math.h and builtin.h, only for ncurses
1344 AC_DEFUN([CF_ETIP_DEFINES],
1345 [
1346 AC_MSG_CHECKING(for special defines needed for etip.h)
1347 cf_save_CXXFLAGS="$CXXFLAGS"
1348 cf_result="none"
1349
1350 # etip.h includes ncurses.h which includes ncurses_dll.h
1351 # But ncurses_dll.h is generated - fix here.
1352 test -d include || mkdir include
1353 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1354
1355 for cf_math in "" MATH_H
1356 do
1357 for cf_excp in "" MATH_EXCEPTION
1358 do
1359         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1360         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1361         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1362 AC_TRY_COMPILE([
1363 #include <etip.h.in>
1364 ],[],[
1365         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1366         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1367         cf_result="$cf_math $cf_excp"
1368         break 2
1369 ],[])
1370 done
1371 done
1372 AC_MSG_RESULT($cf_result)
1373 CXXFLAGS="$cf_save_CXXFLAGS"
1374 ])
1375 dnl ---------------------------------------------------------------------------
1376 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1377 dnl ---------------
1378 dnl Find a library (specifically the linkage used in the code fragment),
1379 dnl searching for it if it is not already in the library path.
1380 dnl See also CF_ADD_SEARCHPATH.
1381 dnl
1382 dnl Parameters (4-on are optional):
1383 dnl     $1 = headers for library entrypoint
1384 dnl     $2 = code fragment for library entrypoint
1385 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1386 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1387 dnl     $5 = action to perform if not successful
1388 dnl     $6 = module name, if not the same as the library name
1389 dnl     $7 = extra libraries
1390 dnl
1391 dnl Sets these variables:
1392 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1393 dnl     $cf_cv_header_path_$3 - include-directory if needed
1394 dnl     $cf_cv_library_path_$3 - library-directory if needed
1395 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1396 AC_DEFUN([CF_FIND_LINKAGE],[
1397
1398 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1399 # will be set on completion of the AC_TRY_LINK below.
1400 cf_cv_header_path_$3=
1401 cf_cv_library_path_$3=
1402
1403 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1404
1405 cf_save_LIBS="$LIBS"
1406
1407 AC_TRY_LINK([$1],[$2],[
1408         cf_cv_find_linkage_$3=yes
1409         cf_cv_header_path_$3=/usr/include
1410         cf_cv_library_path_$3=/usr/lib
1411 ],[
1412
1413 LIBS="-l$3 $7 $cf_save_LIBS"
1414
1415 AC_TRY_LINK([$1],[$2],[
1416         cf_cv_find_linkage_$3=yes
1417         cf_cv_header_path_$3=/usr/include
1418         cf_cv_library_path_$3=/usr/lib
1419         cf_cv_library_file_$3="-l$3"
1420 ],[
1421         cf_cv_find_linkage_$3=no
1422         LIBS="$cf_save_LIBS"
1423
1424     CF_VERBOSE(find linkage for $3 library)
1425     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1426
1427     cf_save_CPPFLAGS="$CPPFLAGS"
1428     cf_test_CPPFLAGS="$CPPFLAGS"
1429
1430     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1431     for cf_cv_header_path_$3 in $cf_search
1432     do
1433       if test -d $cf_cv_header_path_$3 ; then
1434         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1435         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1436         AC_TRY_COMPILE([$1],[$2],[
1437             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1438             cf_cv_find_linkage_$3=maybe
1439             cf_test_CPPFLAGS="$CPPFLAGS"
1440             break],[
1441             CPPFLAGS="$cf_save_CPPFLAGS"
1442             ])
1443       fi
1444     done
1445
1446     if test "$cf_cv_find_linkage_$3" = maybe ; then
1447
1448       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1449
1450       cf_save_LIBS="$LIBS"
1451       cf_save_LDFLAGS="$LDFLAGS"
1452
1453       ifelse([$6],,,[
1454         CPPFLAGS="$cf_test_CPPFLAGS"
1455         LIBS="-l$3 $7 $cf_save_LIBS"
1456         AC_TRY_LINK([$1],[$2],[
1457             CF_VERBOSE(... found $3 library in system)
1458             cf_cv_find_linkage_$3=yes])
1459             CPPFLAGS="$cf_save_CPPFLAGS"
1460             LIBS="$cf_save_LIBS"
1461             ])
1462
1463       if test "$cf_cv_find_linkage_$3" != yes ; then
1464         CF_LIBRARY_PATH(cf_search,$3)
1465         for cf_cv_library_path_$3 in $cf_search
1466         do
1467           if test -d $cf_cv_library_path_$3 ; then
1468             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1469             CPPFLAGS="$cf_test_CPPFLAGS"
1470             LIBS="-l$3 $7 $cf_save_LIBS"
1471             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1472             AC_TRY_LINK([$1],[$2],[
1473                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1474                 cf_cv_find_linkage_$3=yes
1475                 cf_cv_library_file_$3="-l$3"
1476                 break],[
1477                 CPPFLAGS="$cf_save_CPPFLAGS"
1478                 LIBS="$cf_save_LIBS"
1479                 LDFLAGS="$cf_save_LDFLAGS"
1480                 ])
1481           fi
1482         done
1483         CPPFLAGS="$cf_save_CPPFLAGS"
1484         LDFLAGS="$cf_save_LDFLAGS"
1485       fi
1486
1487     else
1488       cf_cv_find_linkage_$3=no
1489     fi
1490     ],$7)
1491 ])
1492
1493 LIBS="$cf_save_LIBS"
1494
1495 if test "$cf_cv_find_linkage_$3" = yes ; then
1496 ifelse([$4],,[
1497         CF_ADD_INCDIR($cf_cv_header_path_$3)
1498         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1499         CF_ADD_LIB($3)
1500 ],[$4])
1501 else
1502 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1503 fi
1504 ])dnl
1505 dnl ---------------------------------------------------------------------------
1506 dnl CF_FUNC_DLSYM version: 2 updated: 2010/05/29 16:31:02
1507 dnl -------------
1508 dnl Test for dlsym() and related functions, as well as libdl.
1509 dnl
1510 dnl Sets
1511 dnl     $cf_have_dlsym
1512 dnl     $cf_have_libdl
1513 AC_DEFUN([CF_FUNC_DLSYM],[
1514 cf_have_dlsym=no
1515 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1516
1517 cf_have_libdl=no
1518 AC_CHECK_LIB(dl,dlsym,[
1519         cf_have_dlsym=yes
1520         cf_have_libdl=yes])])
1521
1522 if test "$cf_have_dlsym" = yes ; then
1523         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1524
1525         AC_MSG_CHECKING(whether able to link to dl*() functions)
1526         AC_TRY_LINK([#include <dlfcn.h>],[
1527                 void *obj;
1528                 if ((obj = dlopen("filename", 0)) != 0) {
1529                         if (dlsym(obj, "symbolname") == 0) {
1530                         dlclose(obj);
1531                         }
1532                 }],[
1533                 AC_DEFINE(HAVE_LIBDL)],[
1534                 AC_MSG_ERROR(Cannot link test program for libdl)])
1535         AC_MSG_RESULT(ok)
1536 else
1537         AC_MSG_ERROR(Cannot find dlsym function)
1538 fi
1539 ])
1540 dnl ---------------------------------------------------------------------------
1541 dnl CF_FUNC_MEMMOVE version: 7 updated: 2006/12/16 12:33:30
1542 dnl ---------------
1543 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1544 dnl is found, add our own version of memmove to the list of objects.
1545 AC_DEFUN([CF_FUNC_MEMMOVE],
1546 [
1547 AC_CHECK_FUNC(memmove,,[
1548 AC_CHECK_FUNC(bcopy,[
1549         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1550                 AC_TRY_RUN([
1551 int main() {
1552         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1553         char temp[40];
1554         bcopy(data, temp, sizeof(data));
1555         bcopy(temp+10, temp, 15);
1556         bcopy(temp+5, temp+15, 10);
1557         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1558 }
1559                 ],
1560                 [cf_cv_good_bcopy=yes],
1561                 [cf_cv_good_bcopy=no],
1562                 [cf_cv_good_bcopy=unknown])
1563                 ])
1564         ],[cf_cv_good_bcopy=no])
1565         if test "$cf_cv_good_bcopy" = yes ; then
1566                 AC_DEFINE(USE_OK_BCOPY)
1567         else
1568                 AC_DEFINE(USE_MY_MEMMOVE)
1569         fi
1570 ])])dnl
1571 dnl ---------------------------------------------------------------------------
1572 dnl CF_FUNC_NANOSLEEP version: 3 updated: 2006/12/16 12:33:30
1573 dnl -----------------
1574 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1575 dnl AIX 4.x, provide a non-working version.
1576 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1577 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1578 AC_TRY_RUN([
1579 #include <stdio.h>
1580 #include <errno.h>
1581 #include <time.h>
1582
1583 #ifdef HAVE_SYS_TIME_H
1584 #include <sys/time.h>
1585 #endif
1586
1587 int main() {
1588         struct timespec ts1, ts2;
1589         int code;
1590         ts1.tv_sec  = 0;
1591         ts1.tv_nsec = 750000000;
1592         ts2.tv_sec  = 0;
1593         ts2.tv_nsec = 0;
1594         errno = 0;
1595         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1596         ${cf_cv_main_return:-return}(code != 0);
1597 }
1598 ],
1599         [cf_cv_func_nanosleep=yes],
1600         [cf_cv_func_nanosleep=no],
1601         [cf_cv_func_nanosleep=unknown])])
1602
1603 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP)
1604 ])
1605 dnl ---------------------------------------------------------------------------
1606 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1607 dnl ---------------
1608 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1609 dnl "util" library as well.
1610 AC_DEFUN([CF_FUNC_OPENPTY],
1611 [
1612 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1613 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1614     cf_save_LIBS="$LIBS"
1615     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1616     for cf_header in pty.h libutil.h util.h
1617     do
1618     AC_TRY_LINK([
1619 #include <$cf_header>
1620 ],[
1621     int x = openpty((int *)0, (int *)0, (char *)0,
1622                    (struct termios *)0, (struct winsize *)0);
1623 ],[
1624         cf_cv_func_openpty=$cf_header
1625         break
1626 ],[
1627         cf_cv_func_openpty=no
1628 ])
1629     done
1630     LIBS="$cf_save_LIBS"
1631 ])
1632 ])dnl
1633 dnl ---------------------------------------------------------------------------
1634 dnl CF_FUNC_POLL version: 5 updated: 2012/01/25 17:55:38
1635 dnl ------------
1636 dnl See if the poll function really works.  Some platforms have poll(), but
1637 dnl it does not work for terminals or files.
1638 AC_DEFUN([CF_FUNC_POLL],[
1639 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1640 AC_TRY_RUN([
1641 #include <stdio.h>
1642 #ifdef HAVE_POLL_H
1643 #include <poll.h>
1644 #else
1645 #include <sys/poll.h>
1646 #endif
1647 int main() {
1648         struct pollfd myfds;
1649         int ret;
1650
1651         /* check for Darwin bug with respect to "devices" */
1652         myfds.fd = open("/dev/null", 1);
1653         if (myfds.fd < 0)
1654                 myfds.fd = 0;
1655         myfds.events = POLLIN;
1656         myfds.revents = 0;
1657
1658         ret = poll(&myfds, 1, 100);
1659
1660         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1661                 ret = -1;
1662         } else {
1663
1664                 /* also check with standard input */
1665                 myfds.fd = 0;
1666                 myfds.events = POLLIN;
1667                 myfds.revents = 0;
1668
1669                 ret = poll(&myfds, 1, 100);
1670                 if (ret < 0) {
1671                         ret = 0;
1672                 }
1673         }
1674         ${cf_cv_main_return:-return}(ret != 0);
1675 }],
1676         [cf_cv_working_poll=yes],
1677         [cf_cv_working_poll=no],
1678         [cf_cv_working_poll=unknown])])
1679 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL)
1680 ])dnl
1681 dnl ---------------------------------------------------------------------------
1682 dnl CF_FUNC_TERMIOS version: 2 updated: 2000/07/22 23:37:24
1683 dnl ---------------
1684 dnl Some old/broken variations define tcgetattr() only as a macro in
1685 dnl termio(s).h
1686 AC_DEFUN([CF_FUNC_TERMIOS],[
1687 AC_REQUIRE([CF_STRUCT_TERMIOS])
1688 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1689 AC_TRY_LINK([
1690 #include <sys/types.h>
1691 #ifdef HAVE_UNISTD_H
1692 #include <unistd.h>
1693 #endif
1694 #ifdef HAVE_TERMIOS_H
1695 #include <termios.h>
1696 #define TTY struct termios
1697 #else
1698 #ifdef HAVE_TERMIO_H
1699 #include <termio.h>
1700 #define TTY struct termio
1701 #endif
1702 #endif
1703 ],[
1704 TTY foo;
1705 tcgetattr(1, &foo);],
1706 [cf_cv_have_tcgetattr=yes],
1707 [cf_cv_have_tcgetattr=no])])
1708 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR)
1709 ])dnl
1710 dnl ---------------------------------------------------------------------------
1711 dnl CF_FUNC_VSSCANF version: 3 updated: 2001/12/19 00:50:10
1712 dnl ---------------
1713 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1714 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1715 dnl other functions.
1716 AC_DEFUN([CF_FUNC_VSSCANF],
1717 [
1718 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1719 AC_TRY_LINK([
1720 #include <stdarg.h>
1721 #include <stdio.h>],[
1722         va_list ap;
1723         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1724 AC_TRY_LINK([
1725 #include <stdarg.h>
1726 #include <stdio.h>],[
1727     FILE strbuf;
1728     char *str = "from";
1729
1730     strbuf._flag = _IOREAD;
1731     strbuf._ptr = strbuf._base = (unsigned char *) str;
1732     strbuf._cnt = strlen(str);
1733     strbuf._file = _NFILE;
1734     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1735 AC_TRY_LINK([
1736 #include <stdarg.h>
1737 #include <stdio.h>],[
1738     FILE strbuf;
1739     char *str = "from";
1740
1741     strbuf._flag = _IOREAD;
1742     strbuf._ptr = strbuf._base = (unsigned char *) str;
1743     strbuf._cnt = strlen(str);
1744     strbuf._file = _NFILE;
1745     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1746 cf_cv_func_vsscanf=no])])])])
1747
1748 case $cf_cv_func_vsscanf in #(vi
1749 vsscanf) AC_DEFINE(HAVE_VSSCANF);; #(vi
1750 vfscanf) AC_DEFINE(HAVE_VFSCANF);; #(vi
1751 _doscan) AC_DEFINE(HAVE__DOSCAN);;
1752 esac
1753
1754 ])dnl
1755 dnl ---------------------------------------------------------------------------
1756 dnl CF_GCC_ATTRIBUTES version: 14 updated: 2010/10/23 15:52:32
1757 dnl -----------------
1758 dnl Test for availability of useful gcc __attribute__ directives to quiet
1759 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1760 dnl to documentation, unrecognized directives cause older compilers to barf.
1761 AC_DEFUN([CF_GCC_ATTRIBUTES],
1762 [
1763 if test "$GCC" = yes
1764 then
1765 cat > conftest.i <<EOF
1766 #ifndef GCC_PRINTF
1767 #define GCC_PRINTF 0
1768 #endif
1769 #ifndef GCC_SCANF
1770 #define GCC_SCANF 0
1771 #endif
1772 #ifndef GCC_NORETURN
1773 #define GCC_NORETURN /* nothing */
1774 #endif
1775 #ifndef GCC_UNUSED
1776 #define GCC_UNUSED /* nothing */
1777 #endif
1778 EOF
1779 if test "$GCC" = yes
1780 then
1781         AC_CHECKING([for $CC __attribute__ directives])
1782 cat > conftest.$ac_ext <<EOF
1783 #line __oline__ "${as_me:-configure}"
1784 #include "confdefs.h"
1785 #include "conftest.h"
1786 #include "conftest.i"
1787 #if     GCC_PRINTF
1788 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1789 #else
1790 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1791 #endif
1792 #if     GCC_SCANF
1793 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1794 #else
1795 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1796 #endif
1797 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1798 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1799 extern void foo(void) GCC_NORETURN;
1800 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1801 EOF
1802         cf_printf_attribute=no
1803         cf_scanf_attribute=no
1804         for cf_attribute in scanf printf unused noreturn
1805         do
1806                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1807                 cf_directive="__attribute__(($cf_attribute))"
1808                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1809
1810                 case $cf_attribute in #(vi
1811                 printf) #(vi
1812                         cf_printf_attribute=yes
1813                         cat >conftest.h <<EOF
1814 #define GCC_$cf_ATTRIBUTE 1
1815 EOF
1816                         ;;
1817                 scanf) #(vi
1818                         cf_scanf_attribute=yes
1819                         cat >conftest.h <<EOF
1820 #define GCC_$cf_ATTRIBUTE 1
1821 EOF
1822                         ;;
1823                 *) #(vi
1824                         cat >conftest.h <<EOF
1825 #define GCC_$cf_ATTRIBUTE $cf_directive
1826 EOF
1827                         ;;
1828                 esac
1829
1830                 if AC_TRY_EVAL(ac_compile); then
1831                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1832                         cat conftest.h >>confdefs.h
1833                         case $cf_attribute in #(vi
1834                         printf) #(vi
1835                                 if test "$cf_printf_attribute" = no ; then
1836                                         cat >>confdefs.h <<EOF
1837 #define GCC_PRINTFLIKE(fmt,var) /* nothing */
1838 EOF
1839                                 else
1840                                         cat >>confdefs.h <<EOF
1841 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1842 EOF
1843                                 fi
1844                                 ;;
1845                         scanf) #(vi
1846                                 if test "$cf_scanf_attribute" = no ; then
1847                                         cat >>confdefs.h <<EOF
1848 #define GCC_SCANFLIKE(fmt,var) /* nothing */
1849 EOF
1850                                 else
1851                                         cat >>confdefs.h <<EOF
1852 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1853 EOF
1854                                 fi
1855                                 ;;
1856                         esac
1857                 fi
1858         done
1859 else
1860         fgrep define conftest.i >>confdefs.h
1861 fi
1862 rm -rf conftest*
1863 fi
1864 ])dnl
1865 dnl ---------------------------------------------------------------------------
1866 dnl CF_GCC_VERSION version: 5 updated: 2010/04/24 11:02:31
1867 dnl --------------
1868 dnl Find version of gcc
1869 AC_DEFUN([CF_GCC_VERSION],[
1870 AC_REQUIRE([AC_PROG_CC])
1871 GCC_VERSION=none
1872 if test "$GCC" = yes ; then
1873         AC_MSG_CHECKING(version of $CC)
1874         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1875         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1876         AC_MSG_RESULT($GCC_VERSION)
1877 fi
1878 ])dnl
1879 dnl ---------------------------------------------------------------------------
1880 dnl CF_GCC_WARNINGS version: 27 updated: 2010/10/23 15:52:32
1881 dnl ---------------
1882 dnl Check if the compiler supports useful warning options.  There's a few that
1883 dnl we don't use, simply because they're too noisy:
1884 dnl
1885 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1886 dnl     -Wredundant-decls (system headers make this too noisy)
1887 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1888 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1889 dnl             is enabled for ncurses using "--enable-const".
1890 dnl     -pedantic
1891 dnl
1892 dnl Parameter:
1893 dnl     $1 is an optional list of gcc warning flags that a particular
1894 dnl             application might want to use, e.g., "no-unused" for
1895 dnl             -Wno-unused
1896 dnl Special:
1897 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1898 dnl
1899 AC_DEFUN([CF_GCC_WARNINGS],
1900 [
1901 AC_REQUIRE([CF_GCC_VERSION])
1902 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1903
1904 cat > conftest.$ac_ext <<EOF
1905 #line __oline__ "${as_me:-configure}"
1906 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1907 EOF
1908
1909 if test "$INTEL_COMPILER" = yes
1910 then
1911 # The "-wdXXX" options suppress warnings:
1912 # remark #1419: external declaration in primary source file
1913 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1914 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1915 # remark #193: zero used for undefined preprocessing identifier
1916 # remark #593: variable "curs_sb_left_arrow" was set but never used
1917 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1918 # remark #869: parameter "tw" was never referenced
1919 # remark #981: operands are evaluated in unspecified order
1920 # warning #279: controlling expression is constant
1921
1922         AC_CHECKING([for $CC warning options])
1923         cf_save_CFLAGS="$CFLAGS"
1924         EXTRA_CFLAGS="-Wall"
1925         for cf_opt in \
1926                 wd1419 \
1927                 wd1683 \
1928                 wd1684 \
1929                 wd193 \
1930                 wd593 \
1931                 wd279 \
1932                 wd810 \
1933                 wd869 \
1934                 wd981
1935         do
1936                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1937                 if AC_TRY_EVAL(ac_compile); then
1938                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1939                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1940                 fi
1941         done
1942         CFLAGS="$cf_save_CFLAGS"
1943
1944 elif test "$GCC" = yes
1945 then
1946         AC_CHECKING([for $CC warning options])
1947         cf_save_CFLAGS="$CFLAGS"
1948         EXTRA_CFLAGS=
1949         cf_warn_CONST=""
1950         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1951         for cf_opt in W Wall \
1952                 Wbad-function-cast \
1953                 Wcast-align \
1954                 Wcast-qual \
1955                 Winline \
1956                 Wmissing-declarations \
1957                 Wmissing-prototypes \
1958                 Wnested-externs \
1959                 Wpointer-arith \
1960                 Wshadow \
1961                 Wstrict-prototypes \
1962                 Wundef $cf_warn_CONST $1
1963         do
1964                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1965                 if AC_TRY_EVAL(ac_compile); then
1966                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1967                         case $cf_opt in #(vi
1968                         Wcast-qual) #(vi
1969                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1970                                 ;;
1971                         Winline) #(vi
1972                                 case $GCC_VERSION in
1973                                 [[34]].*)
1974                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1975                                         continue;;
1976                                 esac
1977                                 ;;
1978                         esac
1979                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1980                 fi
1981         done
1982         CFLAGS="$cf_save_CFLAGS"
1983 fi
1984 rm -rf conftest*
1985
1986 AC_SUBST(EXTRA_CFLAGS)
1987 ])dnl
1988 dnl ---------------------------------------------------------------------------
1989 dnl CF_GETOPT_HEADER version: 4 updated: 2009/08/31 20:07:52
1990 dnl ----------------
1991 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1992 dnl unistd.h or (nonstandard) in getopt.h
1993 AC_DEFUN([CF_GETOPT_HEADER],
1994 [
1995 AC_HAVE_HEADERS(unistd.h getopt.h)
1996 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1997 cf_cv_getopt_header=none
1998 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1999 do
2000 AC_TRY_COMPILE([
2001 #include <$cf_header>],
2002 [int x = optind; char *y = optarg],
2003 [cf_cv_getopt_header=$cf_header
2004  break])
2005 done
2006 ])
2007 if test $cf_cv_getopt_header != none ; then
2008         AC_DEFINE(HAVE_GETOPT_HEADER)
2009 fi
2010 ])dnl
2011 dnl ---------------------------------------------------------------------------
2012 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
2013 dnl ----------------
2014 AC_DEFUN([CF_GNAT_GENERICS],
2015 [
2016 AC_REQUIRE([CF_GNAT_VERSION])
2017
2018 AC_MSG_CHECKING(if GNAT supports generics)
2019 case $cf_gnat_version in #(vi
2020 3.[[1-9]]*|[[4-9]].*) #(vi
2021         cf_gnat_generics=yes
2022         ;;
2023 *)
2024         cf_gnat_generics=no
2025         ;;
2026 esac
2027 AC_MSG_RESULT($cf_gnat_generics)
2028
2029 if test "$cf_gnat_generics" = yes
2030 then
2031         cf_compile_generics=generics
2032         cf_generic_objects="\${GENOBJS}"
2033 else
2034         cf_compile_generics=
2035         cf_generic_objects=
2036 fi
2037
2038 AC_SUBST(cf_compile_generics)
2039 AC_SUBST(cf_generic_objects)
2040 ])dnl
2041 dnl ---------------------------------------------------------------------------
2042 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
2043 dnl --------------------
2044 dnl Check if the gnat pragma "Unreferenced" works.
2045 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
2046 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
2047 CF_GNAT_TRY_LINK([procedure conftest;],
2048 [with Text_IO;
2049 with GNAT.OS_Lib;
2050 procedure conftest is
2051    test : Integer;
2052    pragma Unreferenced (test);
2053 begin
2054    test := 1;
2055    Text_IO.Put ("Hello World");
2056    Text_IO.New_Line;
2057    GNAT.OS_Lib.OS_Exit (0);
2058 end conftest;],
2059         [cf_cv_pragma_unreferenced=yes],
2060         [cf_cv_pragma_unreferenced=no])])
2061
2062 # if the pragma is supported, use it (needed in the Trace code).
2063 if test $cf_cv_pragma_unreferenced = yes ; then
2064         PRAGMA_UNREF=TRUE
2065 else
2066         PRAGMA_UNREF=FALSE
2067 fi
2068 AC_SUBST(PRAGMA_UNREF)
2069 ])dnl
2070 dnl ---------------------------------------------------------------------------
2071 dnl CF_GNAT_PROJECTS version: 2 updated: 2011/03/23 20:24:41
2072 dnl ----------------
2073 dnl GNAT projects are configured with ".gpr" project files.
2074 dnl GNAT libraries are a further development, using the project feature.
2075 AC_DEFUN([CF_GNAT_PROJECTS],
2076 [
2077 AC_REQUIRE([CF_GNAT_VERSION])
2078
2079 cf_gnat_libraries=no
2080 cf_gnat_projects=no
2081
2082 AC_MSG_CHECKING(if GNAT supports project files)
2083 case $cf_gnat_version in #(vi
2084 3.[[0-9]]*) #(vi
2085         ;;
2086 *)
2087         case $cf_cv_system_name in #(vi
2088         cygwin*) #(vi
2089                 ;;
2090         *)
2091                 mkdir conftest.src conftest.bin conftest.lib
2092                 cd conftest.src
2093                 rm -rf conftest* *~conftest*
2094                 cat >>library.gpr <<CF_EOF
2095 project Library is
2096   Kind := External ("LIB_KIND");
2097   for Library_Name use "ConfTest";
2098   for Object_Dir use ".";
2099   for Library_ALI_Dir use External("LIBRARY_DIR");
2100   for Library_Version use External ("SONAME");
2101   for Library_Kind use Kind;
2102   for Library_Dir use External("BUILD_DIR");
2103   Source_Dir := External ("SOURCE_DIR");
2104   for Source_Dirs use (Source_Dir);
2105   package Compiler is
2106      for Default_Switches ("Ada") use
2107        ("-g",
2108         "-O2",
2109         "-gnatafno",
2110         "-gnatVa",   -- All validity checks
2111         "-gnatwa");  -- Activate all optional errors
2112   end Compiler;
2113 end Library;
2114 CF_EOF
2115                 cat >>confpackage.ads <<CF_EOF
2116 package ConfPackage is
2117    procedure conftest;
2118 end ConfPackage;
2119 CF_EOF
2120                 cat >>confpackage.adb <<CF_EOF
2121 with Text_IO;
2122 package body ConfPackage is
2123    procedure conftest is
2124    begin
2125       Text_IO.Put ("Hello World");
2126       Text_IO.New_Line;
2127    end conftest;
2128 end ConfPackage;
2129 CF_EOF
2130                 if ( $cf_ada_make $ADAFLAGS \
2131                                 -Plibrary.gpr \
2132                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2133                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2134                                 -XSOURCE_DIR=`pwd` \
2135                                 -XSONAME=libConfTest.so.1 \
2136                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2137                         cf_gnat_projects=yes
2138                 fi
2139                 cd ..
2140                 if test -f conftest.lib/confpackage.ali
2141                 then
2142                         cf_gnat_libraries=yes
2143                 fi
2144                 rm -rf conftest* *~conftest*
2145                 ;;
2146         esac
2147         ;;
2148 esac
2149 AC_MSG_RESULT($cf_gnat_projects)
2150
2151 if test $cf_gnat_projects = yes
2152 then
2153         AC_MSG_CHECKING(if GNAT supports libraries)
2154         AC_MSG_RESULT($cf_gnat_libraries)
2155 fi
2156
2157 if test "$cf_gnat_projects" = yes
2158 then
2159         USE_OLD_MAKERULES="#"
2160         USE_GNAT_PROJECTS=""
2161 else
2162         USE_OLD_MAKERULES=""
2163         USE_GNAT_PROJECTS="#"
2164 fi
2165
2166 if test "$cf_gnat_libraries" = yes
2167 then
2168         USE_GNAT_LIBRARIES=""
2169 else
2170         USE_GNAT_LIBRARIES="#"
2171 fi
2172
2173 AC_SUBST(USE_OLD_MAKERULES)
2174 AC_SUBST(USE_GNAT_PROJECTS)
2175 AC_SUBST(USE_GNAT_LIBRARIES)
2176 ])dnl
2177 dnl ---------------------------------------------------------------------------
2178 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2179 dnl --------------
2180 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2181 dnl is noted that gnat may compile a tasking unit even for configurations which
2182 dnl fail at runtime.
2183 AC_DEFUN([CF_GNAT_SIGINT],[
2184 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2185 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2186
2187 package ConfTest is
2188
2189    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2190    pragma Unreserve_All_Interrupts;
2191    pragma Warnings (On);
2192
2193    protected Process is
2194       procedure Stop;
2195       function Continue return Boolean;
2196       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2197    private
2198       Done : Boolean := False;
2199    end Process;
2200
2201 end ConfTest;],
2202 [package body ConfTest is
2203    protected body Process is
2204       procedure Stop is
2205       begin
2206          Done := True;
2207       end Stop;
2208       function Continue return Boolean is
2209       begin
2210          return not Done;
2211       end Continue;
2212    end Process;
2213 end ConfTest;],
2214         [cf_cv_gnat_sigint=yes],
2215         [cf_cv_gnat_sigint=no])])
2216
2217 if test $cf_cv_gnat_sigint = yes ; then
2218         USE_GNAT_SIGINT=""
2219 else
2220         USE_GNAT_SIGINT="#"
2221 fi
2222 AC_SUBST(USE_GNAT_SIGINT)
2223 ])dnl
2224 dnl ---------------------------------------------------------------------------
2225 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2226 dnl ----------------
2227 dnl Verify that a test program compiles/links with GNAT.
2228 dnl $cf_ada_make is set to the program that compiles/links
2229 dnl $ADAFLAGS may be set to the GNAT flags.
2230 dnl
2231 dnl $1 is the text of the spec
2232 dnl $2 is the text of the body
2233 dnl $3 is the shell command to execute if successful
2234 dnl $4 is the shell command to execute if not successful
2235 AC_DEFUN([CF_GNAT_TRY_LINK],
2236 [
2237 rm -rf conftest* *~conftest*
2238 cat >>conftest.ads <<CF_EOF
2239 $1
2240 CF_EOF
2241 cat >>conftest.adb <<CF_EOF
2242 $2
2243 CF_EOF
2244 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2245 ifelse($3,,      :,[      $3])
2246 ifelse($4,,,[else
2247    $4])
2248 fi
2249 rm -rf conftest* *~conftest*
2250 ])dnl
2251 dnl ---------------------------------------------------------------------------
2252 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2253 dnl ---------------
2254 dnl Verify that a test program compiles and runs with GNAT
2255 dnl $cf_ada_make is set to the program that compiles/links
2256 dnl $ADAFLAGS may be set to the GNAT flags.
2257 dnl
2258 dnl $1 is the text of the spec
2259 dnl $2 is the text of the body
2260 dnl $3 is the shell command to execute if successful
2261 dnl $4 is the shell command to execute if not successful
2262 AC_DEFUN([CF_GNAT_TRY_RUN],
2263 [
2264 rm -rf conftest* *~conftest*
2265 cat >>conftest.ads <<CF_EOF
2266 $1
2267 CF_EOF
2268 cat >>conftest.adb <<CF_EOF
2269 $2
2270 CF_EOF
2271 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2272    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2273 ifelse($3,,      :,[      $3])
2274 ifelse($4,,,[   else
2275       $4])
2276    fi
2277 ifelse($4,,,[else
2278    $4])
2279 fi
2280 rm -rf conftest* *~conftest*
2281 ])dnl
2282 dnl ---------------------------------------------------------------------------
2283 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
2284 dnl ---------------
2285 dnl Verify version of GNAT.
2286 AC_DEFUN([CF_GNAT_VERSION],
2287 [
2288 AC_MSG_CHECKING(for gnat version)
2289 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2290         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2291     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2292 AC_MSG_RESULT($cf_gnat_version)
2293
2294 case $cf_gnat_version in #(vi
2295 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
2296         cf_cv_prog_gnat_correct=yes
2297         ;;
2298 *)
2299         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2300         cf_cv_prog_gnat_correct=no
2301         ;;
2302 esac
2303 ])
2304 dnl ---------------------------------------------------------------------------
2305 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2306 dnl -------------
2307 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2308 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2309 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2310 dnl since it is interwoven with GNU extensions.
2311 dnl
2312 dnl Well, yes we could work around it...
2313 AC_DEFUN([CF_GNU_SOURCE],
2314 [
2315 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2316 AC_TRY_COMPILE([#include <sys/types.h>],[
2317 #ifndef _XOPEN_SOURCE
2318 make an error
2319 #endif],
2320         [cf_cv_gnu_source=no],
2321         [cf_save="$CPPFLAGS"
2322          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2323          AC_TRY_COMPILE([#include <sys/types.h>],[
2324 #ifdef _XOPEN_SOURCE
2325 make an error
2326 #endif],
2327         [cf_cv_gnu_source=no],
2328         [cf_cv_gnu_source=yes])
2329         CPPFLAGS="$cf_save"
2330         ])
2331 ])
2332 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2333 ])dnl
2334 dnl ---------------------------------------------------------------------------
2335 dnl CF_GPP_LIBRARY version: 10 updated: 2010/05/29 16:31:02
2336 dnl --------------
2337 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2338 dnl problem :-).  If we have the compiler but no library, we'll be able to
2339 dnl configure, but won't be able to build the c++ demo program.
2340 AC_DEFUN([CF_GPP_LIBRARY],
2341 [
2342 cf_cxx_library=unknown
2343 case $cf_cv_system_name in #(vi
2344 os2*) #(vi
2345         cf_gpp_libname=gpp
2346         ;;
2347 *)
2348         cf_gpp_libname=g++
2349         ;;
2350 esac
2351 if test "$GXX" = yes; then
2352         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2353         cf_save="$LIBS"
2354         CF_ADD_LIB($cf_gpp_libname)
2355         AC_TRY_LINK([
2356 #include <$cf_gpp_libname/builtin.h>
2357         ],
2358         [two_arg_error_handler_t foo2 = lib_error_handler],
2359         [cf_cxx_library=yes
2360          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2361          if test "$cf_gpp_libname" = cpp ; then
2362             AC_DEFINE(HAVE_GPP_BUILTIN_H)
2363          else
2364             AC_DEFINE(HAVE_GXX_BUILTIN_H)
2365          fi],
2366         [AC_TRY_LINK([
2367 #include <builtin.h>
2368         ],
2369         [two_arg_error_handler_t foo2 = lib_error_handler],
2370         [cf_cxx_library=yes
2371          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2372          AC_DEFINE(HAVE_BUILTIN_H)],
2373         [cf_cxx_library=no])])
2374         LIBS="$cf_save"
2375         AC_MSG_RESULT($cf_cxx_library)
2376 fi
2377 ])dnl
2378 dnl ---------------------------------------------------------------------------
2379 dnl CF_GXX_VERSION version: 6 updated: 2010/10/23 15:44:18
2380 dnl --------------
2381 dnl Check for version of g++
2382 AC_DEFUN([CF_GXX_VERSION],[
2383 AC_REQUIRE([AC_PROG_CPP])
2384 GXX_VERSION=none
2385 if test "$GXX" = yes; then
2386         AC_MSG_CHECKING(version of g++)
2387         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2388         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2389         AC_MSG_RESULT($GXX_VERSION)
2390 fi
2391 ])dnl
2392 dnl ---------------------------------------------------------------------------
2393 dnl CF_GXX_WARNINGS version: 6 updated: 2010/08/14 18:25:37
2394 dnl ---------------
2395 dnl Check if the compiler supports useful warning options.
2396 dnl
2397 dnl Most of gcc's options apply to g++, except:
2398 dnl     -Wbad-function-cast
2399 dnl     -Wmissing-declarations
2400 dnl     -Wnested-externs
2401 dnl
2402 dnl Omit a few (for now):
2403 dnl     -Winline
2404 dnl
2405 dnl Parameter:
2406 dnl     $1 is an optional list of g++ warning flags that a particular
2407 dnl             application might want to use, e.g., "no-unused" for
2408 dnl             -Wno-unused
2409 dnl Special:
2410 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2411 dnl
2412 AC_DEFUN([CF_GXX_WARNINGS],
2413 [
2414
2415 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2416
2417 AC_REQUIRE([CF_GXX_VERSION])
2418
2419 AC_LANG_SAVE
2420 AC_LANG_CPLUSPLUS
2421
2422 cat > conftest.$ac_ext <<EOF
2423 #line __oline__ "configure"
2424 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2425 EOF
2426
2427 if test "$INTEL_CPLUSPLUS" = yes
2428 then
2429 # The "-wdXXX" options suppress warnings:
2430 # remark #1419: external declaration in primary source file
2431 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2432 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2433 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2434 # remark #193: zero used for undefined preprocessing identifier
2435 # remark #593: variable "curs_sb_left_arrow" was set but never used
2436 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2437 # remark #869: parameter "tw" was never referenced
2438 # remark #981: operands are evaluated in unspecified order
2439 # warning #269: invalid format string conversion
2440
2441         AC_CHECKING([for $CC warning options])
2442         cf_save_CXXFLAGS="$CXXFLAGS"
2443         EXTRA_CXXFLAGS="-Wall"
2444         for cf_opt in \
2445                 wd1419 \
2446                 wd1682 \
2447                 wd1683 \
2448                 wd1684 \
2449                 wd193 \
2450                 wd279 \
2451                 wd593 \
2452                 wd810 \
2453                 wd869 \
2454                 wd981
2455         do
2456                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2457                 if AC_TRY_EVAL(ac_compile); then
2458                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2459                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2460                 fi
2461         done
2462         CXXFLAGS="$cf_save_CXXFLAGS"
2463
2464 elif test "$GXX" = yes
2465 then
2466         AC_CHECKING([for $CXX warning options])
2467         cf_save_CXXFLAGS="$CXXFLAGS"
2468         EXTRA_CXXFLAGS="-W -Wall"
2469         cf_gxx_extra_warnings=""
2470         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2471         case "$GCC_VERSION" in
2472         [[1-2]].*)
2473                 ;;
2474         *)
2475                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2476                 ;;
2477         esac
2478         for cf_opt in \
2479                 Wabi \
2480                 fabi-version=0 \
2481                 Woverloaded-virtual \
2482                 Wsign-promo \
2483                 Wsynth \
2484                 Wold-style-cast \
2485                 Wcast-align \
2486                 Wcast-qual \
2487                 Wmissing-prototypes \
2488                 Wpointer-arith \
2489                 Wshadow \
2490                 Wstrict-prototypes \
2491                 Wundef $cf_gxx_extra_warnings $1
2492         do
2493                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2494                 if AC_TRY_EVAL(ac_compile); then
2495                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2496                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2497                 else
2498                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2499                 fi
2500         done
2501         CXXFLAGS="$cf_save_CXXFLAGS"
2502 fi
2503
2504 rm -rf conftest*
2505 AC_LANG_RESTORE
2506 AC_SUBST(EXTRA_CXXFLAGS)
2507 ])dnl
2508 dnl ---------------------------------------------------------------------------
2509 dnl CF_HASHED_DB version: 4 updated: 2010/05/29 16:31:02
2510 dnl ------------
2511 dnl Look for an instance of the Berkeley hashed database.
2512 dnl
2513 dnl $1 = optional parameter, to specify install-prefix for the database.
2514 AC_DEFUN([CF_HASHED_DB],
2515 [
2516 ifelse([$1],,,[
2517 case $1 in #(vi
2518 yes|*able*) #(vi
2519     ;;
2520 *)
2521     if test -d "$1" ; then
2522         CF_ADD_INCDIR($1/include)
2523         CF_ADD_LIBDIR($1/lib)
2524     fi
2525 esac
2526 ])
2527 AC_CHECK_HEADER(db.h,[
2528 CF_HASHED_DB_VERSION
2529 if test "$cf_cv_hashed_db_version" = unknown ; then
2530         AC_MSG_ERROR(Cannot determine version of db)
2531 else
2532         CF_HASHED_DB_LIBS
2533         if test "$cf_cv_hashed_db_libs" = unknown ; then
2534                 AC_MSG_ERROR(Cannot determine library for db)
2535         elif test "$cf_cv_hashed_db_libs" != default ; then
2536                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2537         fi
2538 fi
2539 ],[
2540         AC_MSG_ERROR(Cannot find db.h)
2541 ])
2542 ])dnl
2543 dnl ---------------------------------------------------------------------------
2544 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2545 dnl -----------------
2546 dnl Given that we have the header and version for hashed database, find the
2547 dnl library information.
2548 AC_DEFUN([CF_HASHED_DB_LIBS],
2549 [
2550 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2551 cf_cv_hashed_db_libs=unknown
2552 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2553 do
2554         cf_save_libs="$LIBS"
2555         if test -n "$cf_db_libs"; then
2556                 CF_ADD_LIB($cf_db_libs)
2557         fi
2558         CF_MSG_LOG(checking for library "$cf_db_libs")
2559         AC_TRY_LINK([
2560 $ac_includes_default
2561 #include <db.h>
2562 ],[
2563         char *path = "/tmp/foo";
2564 #ifdef DB_VERSION_MAJOR
2565 #if DB_VERSION_MAJOR >= 4
2566         DB *result = 0;
2567         db_create(&result, NULL, 0);
2568         result->open(result,
2569                 NULL,
2570                 path,
2571                 path,
2572                 DB_HASH,
2573                 DB_CREATE,
2574                 0644);
2575 #elif DB_VERSION_MAJOR >= 3
2576         DB *result = 0;
2577         db_create(&result, NULL, 0);
2578         result->open(result,
2579                 path,
2580                 path,
2581                 DB_HASH,
2582                 DB_CREATE,
2583                 0644);
2584 #elif DB_VERSION_MAJOR >= 2
2585         DB *result = 0;
2586         db_open(path,
2587                 DB_HASH,
2588                 DB_CREATE,
2589                 0644,
2590                 (DB_ENV *) 0,
2591                 (DB_INFO *) 0,
2592                 &result);
2593 #endif /* DB_VERSION_MAJOR */
2594 #else
2595         DB *result = dbopen(path,
2596                      2,
2597                      0644,
2598                      DB_HASH,
2599                      0);
2600 #endif
2601         ${cf_cv_main_return:-return}(result != 0)
2602 ],[
2603         if test -n "$cf_db_libs" ; then
2604                 cf_cv_hashed_db_libs=$cf_db_libs
2605         else
2606                 cf_cv_hashed_db_libs=default
2607         fi
2608         LIBS="$cf_save_libs"
2609         break
2610 ])
2611         LIBS="$cf_save_libs"
2612 done
2613 ])
2614 ])dnl
2615 dnl ---------------------------------------------------------------------------
2616 dnl CF_HASHED_DB_VERSION version: 3 updated: 2007/12/01 15:01:37
2617 dnl --------------------
2618 dnl Given that we have the header file for hashed database, find the version
2619 dnl information.
2620 AC_DEFUN([CF_HASHED_DB_VERSION],
2621 [
2622 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2623 cf_cv_hashed_db_version=unknown
2624
2625 for cf_db_version in 1 2 3 4 5
2626 do
2627         CF_MSG_LOG(checking for db version $cf_db_version)
2628         AC_TRY_COMPILE([
2629 $ac_includes_default
2630 #include <db.h>
2631
2632 #ifdef DB_VERSION_MAJOR
2633         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2634 #if $cf_db_version == DB_VERSION_MAJOR
2635         /* ok */
2636 #else
2637         make an error
2638 #endif
2639 #else
2640 #if $cf_db_version == 1
2641         /* ok: assuming this is DB 1.8.5 */
2642 #else
2643         make an error
2644 #endif
2645 #endif
2646 ],[DBT *foo = 0],[
2647         cf_cv_hashed_db_version=$cf_db_version
2648         break
2649         ])
2650 done
2651 ])
2652 ])dnl
2653 dnl ---------------------------------------------------------------------------
2654 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2655 dnl --------------
2656 dnl Construct a search-list of directories for a nonstandard header-file
2657 dnl
2658 dnl Parameters
2659 dnl     $1 = the variable to return as result
2660 dnl     $2 = the package name
2661 AC_DEFUN([CF_HEADER_PATH],
2662 [
2663 $1=
2664
2665 # collect the current set of include-directories from compiler flags
2666 cf_header_path_list=""
2667 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2668         for cf_header_path in $CPPFLAGS $CFLAGS
2669         do
2670                 case $cf_header_path in #(vi
2671                 -I*)
2672                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2673                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2674                         cf_header_path_list="$cf_header_path_list [$]$1"
2675                         ;;
2676                 esac
2677         done
2678 fi
2679
2680 # add the variations for the package we are looking for
2681 CF_SUBDIR_PATH($1,$2,include)
2682
2683 test "$includedir" != NONE && \
2684 test "$includedir" != "/usr/include" && \
2685 test -d "$includedir" && {
2686         test -d $includedir &&    $1="[$]$1 $includedir"
2687         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2688 }
2689
2690 test "$oldincludedir" != NONE && \
2691 test "$oldincludedir" != "/usr/include" && \
2692 test -d "$oldincludedir" && {
2693         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2694         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2695 }
2696
2697 $1="[$]$1 $cf_header_path_list"
2698 ])dnl
2699 dnl ---------------------------------------------------------------------------
2700 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2701 dnl ---------------
2702 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2703 AC_DEFUN([CF_HELP_MESSAGE],
2704 [AC_DIVERT_HELP([$1])dnl
2705 ])dnl
2706 dnl ---------------------------------------------------------------------------
2707 dnl CF_INCLUDE_DIRS version: 6 updated: 2009/01/06 19:37:40
2708 dnl ---------------
2709 dnl Construct the list of include-options according to whether we're building
2710 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2711 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2712 dnl since that usually breaks gcc's shadow-includes.
2713 AC_DEFUN([CF_INCLUDE_DIRS],
2714 [
2715 CPPFLAGS="$CPPFLAGS -I. -I../include"
2716 if test "$srcdir" != "."; then
2717         CPPFLAGS="$CPPFLAGS -I\${srcdir}/../include"
2718 fi
2719 if test "$GCC" != yes; then
2720         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2721 elif test "$includedir" != "/usr/include"; then
2722         if test "$includedir" = '${prefix}/include' ; then
2723                 if test $prefix != /usr ; then
2724                         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2725                 fi
2726         else
2727                 CPPFLAGS="$CPPFLAGS -I\${includedir}"
2728         fi
2729 fi
2730 AC_SUBST(CPPFLAGS)
2731 ])dnl
2732 dnl ---------------------------------------------------------------------------
2733 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
2734 dnl -----------------
2735 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2736 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2737 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2738 dnl
2739 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2740 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2741 dnl the wrappers for gcc and g++ warnings.
2742 dnl
2743 dnl $1 = GCC (default) or GXX
2744 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2745 dnl $3 = CFLAGS (default) or CXXFLAGS
2746 AC_DEFUN([CF_INTEL_COMPILER],[
2747 ifelse([$2],,INTEL_COMPILER,[$2])=no
2748
2749 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2750         case $host_os in
2751         linux*|gnu*)
2752                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2753                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2754                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2755                 AC_TRY_COMPILE([],[
2756 #ifdef __INTEL_COMPILER
2757 #else
2758 make an error
2759 #endif
2760 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2761 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
2762 ],[])
2763                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2764                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2765                 ;;
2766         esac
2767 fi
2768 ])dnl
2769 dnl ---------------------------------------------------------------------------
2770 dnl CF_ISASCII version: 3 updated: 2000/08/12 23:18:52
2771 dnl ----------
2772 dnl Check if we have either a function or macro for 'isascii()'.
2773 AC_DEFUN([CF_ISASCII],
2774 [
2775 AC_MSG_CHECKING(for isascii)
2776 AC_CACHE_VAL(cf_cv_have_isascii,[
2777         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2778         [cf_cv_have_isascii=yes],
2779         [cf_cv_have_isascii=no])
2780 ])dnl
2781 AC_MSG_RESULT($cf_cv_have_isascii)
2782 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII)
2783 ])dnl
2784 dnl ---------------------------------------------------------------------------
2785 dnl CF_LARGEFILE version: 7 updated: 2007/06/02 11:58:50
2786 dnl ------------
2787 dnl Add checks for large file support.
2788 AC_DEFUN([CF_LARGEFILE],[
2789 ifdef([AC_FUNC_FSEEKO],[
2790     AC_SYS_LARGEFILE
2791     if test "$enable_largefile" != no ; then
2792         AC_FUNC_FSEEKO
2793
2794         # Normally we would collect these definitions in the config.h,
2795         # but (like _XOPEN_SOURCE), some environments rely on having these
2796         # defined before any of the system headers are included.  Another
2797         # case comes up with C++, e.g., on AIX the compiler compiles the
2798         # header files by themselves before looking at the body files it is
2799         # told to compile.  For ncurses, those header files do not include
2800         # the config.h
2801         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2802         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2803         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2804
2805         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2806                 AC_TRY_COMPILE([
2807 #include <sys/types.h>
2808 #include <dirent.h>
2809                 ],[
2810                 /* if transitional largefile support is setup, this is true */
2811                 extern struct dirent64 * readdir(DIR *);
2812                 struct dirent64 *x = readdir((DIR *)0);
2813                 struct dirent *y = readdir((DIR *)0);
2814                 int z = x - y;
2815                 ],
2816                 [cf_cv_struct_dirent64=yes],
2817                 [cf_cv_struct_dirent64=no])
2818         ])
2819         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64)
2820     fi
2821 ])
2822 ])
2823 dnl ---------------------------------------------------------------------------
2824 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2825 dnl -----------------
2826 dnl Check for compiler/linker flags used to temporarily force usage of static
2827 dnl libraries.  This depends on the compiler and platform.  Use this to help
2828 dnl ensure that the linker picks up a given library based on its position in
2829 dnl the list of linker options and libraries.
2830 AC_DEFUN([CF_LDFLAGS_STATIC],[
2831
2832 if test "$GCC" = yes ; then
2833         case $cf_cv_system_name in #(
2834         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2835                 LDFLAGS_STATIC=
2836                 LDFLAGS_SHARED=
2837                 ;;
2838     *)  #( normally, except when broken
2839         LDFLAGS_STATIC=-static
2840         LDFLAGS_SHARED=-dynamic
2841         ;;
2842     esac
2843 else
2844         case $cf_cv_system_name in #(
2845         aix[[4-7]]*)    #( from ld manpage
2846                 LDFLAGS_STATIC=-bstatic
2847                 LDFLAGS_SHARED=-bdynamic
2848                 ;;
2849         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2850                 # We could also use just "archive" and "shared".
2851                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2852                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2853                 ;;
2854         irix*)          #( from ld manpage IRIX64
2855                 LDFLAGS_STATIC=-Bstatic
2856                 LDFLAGS_SHARED=-Bdynamic
2857                 ;;
2858         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2859                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2860                 LDFLAGS_STATIC=-noso
2861                 LDFLAGS_SHARED=-so_archive
2862                 ;;
2863         solaris2*)
2864                 LDFLAGS_STATIC=-Bstatic
2865                 LDFLAGS_SHARED=-Bdynamic
2866                 ;;
2867         esac
2868 fi
2869
2870 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
2871 then
2872         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
2873
2874         rm -f libconftest.a
2875         cat >conftest.$ac_ext <<EOF
2876 #line __oline__ "configure"
2877 #include <stdio.h>
2878 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
2879 EOF
2880         if AC_TRY_EVAL(ac_compile) ; then
2881                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
2882                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
2883         fi
2884         rm -f conftest.*
2885
2886         cf_save_LIBS="$LIBS"
2887
2888         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
2889         AC_TRY_LINK([
2890 #line __oline__ "configure"
2891 #include <stdio.h>
2892 int cf_ldflags_static(FILE *fp);
2893 ],[
2894         return cf_ldflags_static(stdin);
2895 ],[
2896         # some linkers simply ignore the -dynamic
2897         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
2898         *static*) # (vi
2899                 cf_ldflags_static=no
2900                 ;;
2901         *)
2902                 cf_ldflags_static=yes
2903                 ;;
2904         esac
2905 ],[cf_ldflags_static=no])
2906
2907         rm -f libconftest.*
2908         LIBS="$cf_save_LIBS"
2909
2910         AC_MSG_RESULT($cf_ldflags_static)
2911
2912         if test $cf_ldflags_static != yes
2913         then
2914                 LDFLAGS_STATIC=
2915                 LDFLAGS_SHARED=
2916         fi
2917 else
2918         LDFLAGS_STATIC=
2919         LDFLAGS_SHARED=
2920 fi
2921
2922 AC_SUBST(LDFLAGS_STATIC)
2923 AC_SUBST(LDFLAGS_SHARED)
2924 ])
2925 dnl ---------------------------------------------------------------------------
2926 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
2927 dnl ---------------
2928 dnl For the given system and compiler, find the compiler flags to pass to the
2929 dnl loader to use the "rpath" feature.
2930 AC_DEFUN([CF_LD_RPATH_OPT],
2931 [
2932 AC_REQUIRE([CF_CHECK_CACHE])
2933
2934 LD_RPATH_OPT=
2935 AC_MSG_CHECKING(for an rpath option)
2936 case $cf_cv_system_name in #(vi
2937 irix*) #(vi
2938         if test "$GCC" = yes; then
2939                 LD_RPATH_OPT="-Wl,-rpath,"
2940         else
2941                 LD_RPATH_OPT="-rpath "
2942         fi
2943         ;;
2944 linux*|gnu*|k*bsd*-gnu) #(vi
2945         LD_RPATH_OPT="-Wl,-rpath,"
2946         ;;
2947 openbsd[[2-9]].*|mirbsd*) #(vi
2948         LD_RPATH_OPT="-Wl,-rpath,"
2949         ;;
2950 dragonfly*|freebsd*) #(vi
2951         LD_RPATH_OPT="-rpath "
2952         ;;
2953 netbsd*) #(vi
2954         LD_RPATH_OPT="-Wl,-rpath,"
2955         ;;
2956 osf*|mls+*) #(vi
2957         LD_RPATH_OPT="-rpath "
2958         ;;
2959 solaris2*) #(vi
2960         LD_RPATH_OPT="-R"
2961         ;;
2962 *)
2963         ;;
2964 esac
2965 AC_MSG_RESULT($LD_RPATH_OPT)
2966
2967 case "x$LD_RPATH_OPT" in #(vi
2968 x-R*)
2969         AC_MSG_CHECKING(if we need a space after rpath option)
2970         cf_save_LIBS="$LIBS"
2971         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2972         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2973         LIBS="$cf_save_LIBS"
2974         AC_MSG_RESULT($cf_rpath_space)
2975         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2976         ;;
2977 esac
2978 ])dnl
2979 dnl ---------------------------------------------------------------------------
2980 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
2981 dnl ---------------
2982 dnl Construct a search-list of directories for a nonstandard library-file
2983 dnl
2984 dnl Parameters
2985 dnl     $1 = the variable to return as result
2986 dnl     $2 = the package name
2987 AC_DEFUN([CF_LIBRARY_PATH],
2988 [
2989 $1=
2990 cf_library_path_list=""
2991 if test -n "${LDFLAGS}${LIBS}" ; then
2992         for cf_library_path in $LDFLAGS $LIBS
2993         do
2994                 case $cf_library_path in #(vi
2995                 -L*)
2996                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2997                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2998                         cf_library_path_list="$cf_library_path_list [$]$1"
2999                         ;;
3000                 esac
3001         done
3002 fi
3003
3004 CF_SUBDIR_PATH($1,$2,lib)
3005
3006 $1="$cf_library_path_list [$]$1"
3007 ])dnl
3008 dnl ---------------------------------------------------------------------------
3009 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
3010 dnl -------------
3011 dnl Compute the library-prefix for the given host system
3012 dnl $1 = variable to set
3013 define([CF_LIB_PREFIX],
3014 [
3015         case $cf_cv_system_name in #(vi
3016         OS/2*|os2*) #(vi
3017         LIB_PREFIX=''
3018         ;;
3019         *)      LIB_PREFIX='lib'
3020         ;;
3021         esac
3022 ifelse($1,,,[$1=$LIB_PREFIX])
3023         AC_SUBST(LIB_PREFIX)
3024 ])dnl
3025 dnl ---------------------------------------------------------------------------
3026 dnl CF_LIB_RULES version: 64 updated: 2012/02/25 15:20:07
3027 dnl ------------
3028 dnl Append definitions and rules for the given models to the subdirectory
3029 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3030 dnl subdirectory is a library-source directory, modify the LIBS_TO_MAKE list in
3031 dnl the corresponding makefile to list the models that we'll generate.
3032 dnl
3033 dnl For shared libraries, make a list of symbolic links to construct when
3034 dnl generating each library.  The convention used for Linux is the simplest
3035 dnl one:
3036 dnl     lib<name>.so    ->
3037 dnl     lib<name>.so.<major>    ->
3038 dnl     lib<name>.so.<maj>.<minor>
3039 AC_DEFUN([CF_LIB_RULES],
3040 [
3041 cf_prefix=$LIB_PREFIX
3042 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3043
3044 case $cf_cv_shlib_version in #(vi
3045 cygdll|mingw)
3046         TINFO_NAME=$TINFO_ARG_SUFFIX
3047         TINFO_SUFFIX=.dll
3048         ;;
3049 esac
3050
3051 if test -n "$TINFO_SUFFIX" ; then
3052         case $TINFO_SUFFIX in
3053         tw*)
3054                 TINFO_NAME="${TINFO_NAME}tw"
3055                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
3056                 ;;
3057         t*)
3058                 TINFO_NAME="${TINFO_NAME}t"
3059                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3060                 ;;
3061         w*)
3062                 TINFO_NAME="${TINFO_NAME}w"
3063                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3064                 ;;
3065         esac
3066 fi
3067
3068 for cf_dir in $SRC_SUBDIRS
3069 do
3070         if test ! -d $srcdir/$cf_dir ; then
3071                 continue
3072         elif test -f $srcdir/$cf_dir/modules; then
3073
3074                 SHARED_LIB=
3075                 LIBS_TO_MAKE=
3076                 for cf_item in $cf_LIST_MODELS
3077                 do
3078                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3079                         if test $cf_item = shared ; then
3080                         if test "$cf_cv_do_symlinks" = yes ; then
3081                                 case "$cf_cv_shlib_version" in #(vi
3082                                 rel) #(vi
3083                                         case "$cf_cv_system_name" in #(vi
3084                                         darwin*)
3085                                         case .${LIB_SUFFIX} in
3086                                         .tw*)
3087                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3088                                                 cf_suffix=tw'.${REL_VERSION}'"$cf_suffix"
3089                                                 ;;
3090                                         .t*)
3091                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3092                                                 cf_suffix=t'.${REL_VERSION}'"$cf_suffix"
3093                                                 ;;
3094                                         .w*)
3095                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3096                                                 cf_suffix=w'.${REL_VERSION}'"$cf_suffix"
3097                                                 ;;
3098                                         *)
3099                                                 cf_suffix='.${REL_VERSION}'"$cf_suffix"
3100                                                 ;;
3101                                         esac
3102                                         ;; #(vi
3103                                         *) cf_suffix="$cf_suffix"'.${REL_VERSION}' ;;
3104                                         esac
3105                                         ;;
3106                                 abi)
3107                                         case "$cf_cv_system_name" in #(vi
3108                                         darwin*)
3109                                         case .${LIB_SUFFIX} in
3110                                         .tw*)
3111                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3112                                                 cf_suffix=tw'.${ABI_VERSION}'"$cf_suffix"
3113                                                 ;;
3114                                         .t*)
3115                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3116                                                 cf_suffix=t'.${ABI_VERSION}'"$cf_suffix"
3117                                                 ;;
3118                                         .w*)
3119                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3120                                                 cf_suffix=w'.${ABI_VERSION}'"$cf_suffix"
3121                                                 ;;
3122                                         *)
3123                                                 cf_suffix='.${ABI_VERSION}'"$cf_suffix"
3124                                                 ;;
3125                                         esac
3126                                         ;; #(vi
3127                                         *) cf_suffix="$cf_suffix"'.${ABI_VERSION}' ;;
3128                                         esac
3129                                         ;;
3130                                 esac
3131                         fi
3132                         # cygwin needs import library, and has unique naming convention
3133                         # use autodetected ${cf_prefix} for import lib and static lib, but
3134                         # use 'cyg' prefix for shared lib.
3135                         case $cf_cv_shlib_version in #(vi
3136                         cygdll) #(vi
3137                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3138                                 LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/cyg${cf_dir}${cf_cygsuf}"
3139                                 continue
3140                                 ;;
3141                         mingw)
3142                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3143                                 LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/lib${cf_dir}${cf_cygsuf}"
3144                                 continue
3145                                 ;;
3146                         esac
3147                         fi
3148                         LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/${cf_prefix}${cf_dir}${cf_suffix}"
3149                 done
3150
3151                 if test $cf_dir = ncurses ; then
3152                         cf_subsets="$LIB_SUBSETS"
3153                         cf_r_parts="$cf_subsets"
3154                         cf_liblist="$LIBS_TO_MAKE"
3155
3156                         while test -n "$cf_r_parts"
3157                         do
3158                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3159                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3160                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3161                                         cf_item=
3162                                         case $cf_l_parts in #(vi
3163                                         *termlib*) #(vi
3164                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3165                                                 ;;
3166                                         *ticlib*)
3167                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3168                                                 ;;
3169                                         *)
3170                                                 break
3171                                                 ;;
3172                                         esac
3173                                         if test -n "$cf_item"; then
3174                                                 LIBS_TO_MAKE="$cf_item $LIBS_TO_MAKE"
3175                                         fi
3176                                 else
3177                                         break
3178                                 fi
3179                         done
3180                 else
3181                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3182                 fi
3183
3184                 sed -e "s%@LIBS_TO_MAKE@%$LIBS_TO_MAKE%" \
3185                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3186                         $cf_dir/Makefile >$cf_dir/Makefile.out
3187                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3188
3189                 $AWK -f $srcdir/mk-0th.awk \
3190                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" \
3191                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3192
3193                 for cf_subset in $cf_subsets
3194                 do
3195                         cf_subdirs=
3196                         for cf_item in $cf_LIST_MODELS
3197                         do
3198                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3199                         CF_UPPER(cf_ITEM,$cf_item)
3200                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3201                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3202
3203                         # Test for case where we build libtinfo with a different name.
3204                         cf_libname=$cf_dir
3205                         if test $cf_dir = ncurses ; then
3206                                 case $cf_subset in
3207                                 *base*)
3208                                         cf_libname=${cf_libname}$LIB_SUFFIX
3209                                         ;;
3210                                 *termlib*)
3211                                         cf_libname=$TINFO_LIB_SUFFIX
3212                                         ;;
3213                                 ticlib*)
3214                                         cf_libname=$TICS_LIB_SUFFIX
3215                                         ;;
3216                                 esac
3217                         else
3218                                 cf_libname=${cf_libname}$LIB_SUFFIX
3219                         fi
3220                         if test -n "${DFT_ARG_SUFFIX}" ; then
3221                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3222                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3223                         fi
3224
3225                         # These dependencies really are for development, not
3226                         # builds, but they are useful in porting, too.
3227                         cf_depend="../include/ncurses_cfg.h"
3228                         if test "$srcdir" = "."; then
3229                                 cf_reldir="."
3230                         else
3231                                 cf_reldir="\${srcdir}"
3232                         fi
3233
3234                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3235                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3236                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3237                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3238                         fi
3239
3240                         cf_dir_suffix=
3241                         old_cf_suffix="$cf_suffix"
3242                         if test "$cf_cv_shlib_version_infix" = yes ; then
3243                         if test -n "$LIB_SUFFIX" ; then
3244                                 case $LIB_SUFFIX in
3245                                 tw*)
3246                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3247                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3248                                         cf_dir_suffix=tw
3249                                         ;;
3250                                 t*)
3251                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3252                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3253                                         cf_dir_suffix=t
3254                                         ;;
3255                                 w*)
3256                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3257                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3258                                         cf_dir_suffix=w
3259                                         ;;
3260                                 esac
3261                         fi
3262                         fi
3263
3264                         $AWK -f $srcdir/mk-1st.awk \
3265                                 name=${cf_libname}${cf_dir_suffix} \
3266                                 traces=$LIB_TRACING \
3267                                 MODEL=$cf_ITEM \
3268                                 model=$cf_subdir \
3269                                 prefix=$cf_prefix \
3270                                 suffix=$cf_suffix \
3271                                 subset=$cf_subset \
3272                                 driver=$cf_cv_term_driver \
3273                                 SymLink="$LN_S" \
3274                                 TermlibRoot=$TINFO_NAME \
3275                                 TermlibSuffix=$TINFO_SUFFIX \
3276                                 ShlibVer=$cf_cv_shlib_version \
3277                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3278                                 ReLink=${cf_cv_do_relink:-no} \
3279                                 DoLinks=$cf_cv_do_symlinks \
3280                                 rmSoLocs=$cf_cv_rm_so_locs \
3281                                 ldconfig="$LDCONFIG" \
3282                                 overwrite=$WITH_OVERWRITE \
3283                                 depend="$cf_depend" \
3284                                 host="$host" \
3285                                 libtool_version="$LIBTOOL_VERSION" \
3286                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3287
3288                         cf_suffix="$old_cf_suffix"
3289
3290                         for cf_subdir2 in $cf_subdirs lib
3291                         do
3292                                 test $cf_subdir = $cf_subdir2 && break
3293                         done
3294                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3295                         $AWK -f $srcdir/mk-2nd.awk \
3296                                 name=$cf_dir \
3297                                 traces=$LIB_TRACING \
3298                                 MODEL=$cf_ITEM \
3299                                 model=$cf_subdir \
3300                                 subset=$cf_subset \
3301                                 srcdir=$srcdir \
3302                                 echo=$WITH_ECHO \
3303                                 crenames=$cf_cv_prog_CC_c_o \
3304                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3305                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3306                         cf_subdirs="$cf_subdirs $cf_subdir"
3307                         done
3308                 done
3309         fi
3310
3311         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >>Makefile
3312 done
3313
3314 for cf_dir in $SRC_SUBDIRS
3315 do
3316         if test ! -d $srcdir/$cf_dir ; then
3317                 continue
3318         fi
3319
3320         if test -f $cf_dir/Makefile ; then
3321                 case "$cf_dir" in
3322                 Ada95) #(vi
3323                         echo 'libs \' >> Makefile
3324                         echo 'install.libs \' >> Makefile
3325                         echo 'uninstall.libs ::' >> Makefile
3326                         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >> Makefile
3327                         ;;
3328                 esac
3329         fi
3330
3331         if test -f $srcdir/$cf_dir/modules; then
3332                 echo >> Makefile
3333                 if test -f $srcdir/$cf_dir/headers; then
3334 cat >> Makefile <<CF_EOF
3335 install.includes \\
3336 uninstall.includes \\
3337 CF_EOF
3338                 fi
3339 if test "$cf_dir" != "c++" ; then
3340 echo 'lint \' >> Makefile
3341 fi
3342 cat >> Makefile <<CF_EOF
3343 libs \\
3344 lintlib \\
3345 install.libs \\
3346 uninstall.libs \\
3347 install.$cf_dir \\
3348 uninstall.$cf_dir ::
3349         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3350 CF_EOF
3351         elif test -f $srcdir/$cf_dir/headers; then
3352 cat >> Makefile <<CF_EOF
3353
3354 libs \\
3355 install.libs \\
3356 uninstall.libs \\
3357 install.includes \\
3358 uninstall.includes ::
3359         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3360 CF_EOF
3361 fi
3362 done
3363
3364 cat >> Makefile <<CF_EOF
3365
3366 install.libs uninstall.libs \\
3367 install.data uninstall.data ::
3368 $MAKE_TERMINFO  cd misc && \${MAKE} \${CF_MFLAGS} \[$]@
3369 CF_EOF
3370
3371 if test "x$cf_with_manpages" = xyes; then
3372 cat >> Makefile <<CF_EOF
3373
3374 install.man \\
3375 uninstall.man ::
3376         cd man && \${MAKE} \${CF_MFLAGS} \[$]@
3377 CF_EOF
3378 fi
3379
3380 cat >> Makefile <<CF_EOF
3381
3382 distclean ::
3383         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3384         rm -f headers.sh headers.sed mk_shared_lib.sh
3385         rm -f edit_man.* man_alias.*
3386         rm -rf \${DIRS_TO_MAKE}
3387 CF_EOF
3388
3389 # Special case: tack's manpage lives in its own directory.
3390 if test "x$cf_with_manpages" = xyes; then
3391 if test -d tack ; then
3392 if test -f $srcdir/$tack.h; then
3393 cat >> Makefile <<CF_EOF
3394
3395 install.man \\
3396 uninstall.man ::
3397         cd tack && \${MAKE} \${CF_MFLAGS} \[$]@
3398 CF_EOF
3399 fi
3400 fi
3401 fi
3402
3403 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3404 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3405 dnl anything, and will make it more standardized.  It's awkward to decide this
3406 dnl at configuration because of quoting, so we'll simply make all headers
3407 dnl installed via a script that can do the right thing.
3408
3409 rm -f headers.sed headers.sh
3410
3411 dnl ( generating this script makes the makefiles a little tidier :-)
3412 echo creating headers.sh
3413 cat >headers.sh <<CF_EOF
3414 #! /bin/sh
3415 # This shell script is generated by the 'configure' script.  It is invoked in a
3416 # subdirectory of the build tree.  It generates a sed-script in the parent
3417 # directory that is used to adjust includes for header files that reside in a
3418 # subdirectory of /usr/include, etc.
3419 PRG=""
3420 while test \[$]# != 3
3421 do
3422 PRG="\$PRG \[$]1"; shift
3423 done
3424 DST=\[$]1
3425 REF=\[$]2
3426 SRC=\[$]3
3427 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3428 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3429 echo installing \$SRC in \$DST
3430 CF_EOF
3431
3432 if test $WITH_CURSES_H = yes; then
3433         cat >>headers.sh <<CF_EOF
3434 case \$DST in
3435 /*/include/*)
3436         END=\`basename \$DST\`
3437         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3438         do
3439                 NAME=\`basename \$i\`
3440                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3441         done
3442         ;;
3443 *)
3444         echo "" >> \$TMPSED
3445         ;;
3446 esac
3447 CF_EOF
3448
3449 else
3450         cat >>headers.sh <<CF_EOF
3451 case \$DST in
3452 /*/include/*)
3453         END=\`basename \$DST\`
3454         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3455         do
3456                 NAME=\`basename \$i\`
3457                 if test "\$NAME" = "curses.h"
3458                 then
3459                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3460                         NAME=ncurses.h
3461                 fi
3462                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3463         done
3464         ;;
3465 *)
3466         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3467         ;;
3468 esac
3469 CF_EOF
3470 fi
3471 cat >>headers.sh <<CF_EOF
3472 rm -f \$TMPSRC
3473 sed -f \$TMPSED \$SRC > \$TMPSRC
3474 NAME=\`basename \$SRC\`
3475 CF_EOF
3476 if test $WITH_CURSES_H != yes; then
3477         cat >>headers.sh <<CF_EOF
3478 test "\$NAME" = "curses.h" && NAME=ncurses.h
3479 CF_EOF
3480 fi
3481 cat >>headers.sh <<CF_EOF
3482 # Just in case someone gzip'd manpages, remove the conflicting copy.
3483 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3484
3485 eval \$PRG \$TMPSRC \$DST/\$NAME
3486 rm -f \$TMPSRC \$TMPSED
3487 CF_EOF
3488
3489 chmod 0755 headers.sh
3490
3491 for cf_dir in $SRC_SUBDIRS
3492 do
3493         if test ! -d $srcdir/$cf_dir ; then
3494                 continue
3495         fi
3496
3497         if test -f $srcdir/$cf_dir/headers; then
3498                 $AWK -f $srcdir/mk-hdr.awk \
3499                         subset="$LIB_SUBSETS" \
3500                         compat="$WITH_CURSES_H" \
3501                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3502         fi
3503
3504         if test -f $srcdir/$cf_dir/modules; then
3505                 if test "$cf_dir" != "c++" ; then
3506                         cat >>$cf_dir/Makefile <<"CF_EOF"
3507 depend : ${AUTO_SRC}
3508         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3509
3510 # DO NOT DELETE THIS LINE -- make depend depends on it.
3511 CF_EOF
3512                 fi
3513         fi
3514 done
3515 AC_SUBST(LIBS_TO_MAKE)
3516 ])dnl
3517 dnl ---------------------------------------------------------------------------
3518 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3519 dnl -------------
3520 dnl Find the and soname for the given shared library.  Set the cache variable
3521 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3522 dnl variable to "unknown".
3523 dnl
3524 dnl $1 = headers
3525 dnl $2 = code
3526 dnl $3 = library name
3527 AC_DEFUN([CF_LIB_SONAME],
3528 [
3529 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3530
3531 cf_cv_$3_soname=unknown
3532 if test "$cross_compiling" != yes ; then
3533 cat >conftest.$ac_ext <<CF_EOF
3534 $1
3535 int main()
3536 {
3537 $2
3538         ${cf_cv_main_return:-return}(0);
3539 }
3540 CF_EOF
3541 cf_save_LIBS="$LIBS"
3542         CF_ADD_LIB($3)
3543         if AC_TRY_EVAL(ac_compile) ; then
3544                 if AC_TRY_EVAL(ac_link) ; then
3545                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3546                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3547                 fi
3548         fi
3549 rm -rf conftest*
3550 LIBS="$cf_save_LIBS"
3551 fi
3552 ])
3553 ])
3554 dnl ---------------------------------------------------------------------------
3555 dnl CF_LIB_SUFFIX version: 18 updated: 2012/02/25 15:20:07
3556 dnl -------------
3557 dnl Compute the library file-suffix from the given model name
3558 dnl $1 = model name
3559 dnl $2 = variable to set (the nominal library suffix)
3560 dnl $3 = dependency variable to set (actual filename)
3561 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3562 AC_DEFUN([CF_LIB_SUFFIX],
3563 [
3564         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3565         case $1 in #(vi
3566         libtool) #(vi
3567                 $2='.la'
3568                 $3=[$]$2
3569                 ;;
3570         normal) #(vi
3571                 $2='.a'
3572                 $3=[$]$2
3573                 ;;
3574         debug) #(vi
3575                 $2='_g.a'
3576                 $3=[$]$2
3577                 ;;
3578         profile) #(vi
3579                 $2='_p.a'
3580                 $3=[$]$2
3581                 ;;
3582         shared) #(vi
3583                 case $cf_cv_system_name in
3584                 aix[[5-7]]*) #(vi
3585                         $2='.a'
3586                         $3=[$]$2
3587                         ;;
3588                 cygwin*|mingw*) #(vi
3589                         $2='.dll'
3590                         $3='.dll.a'
3591                         ;;
3592                 darwin*) #(vi
3593                         $2='.dylib'
3594                         $3=[$]$2
3595                         ;;
3596                 hpux*) #(vi
3597                         case $target in
3598                         ia64*) #(vi
3599                                 $2='.so'
3600                                 $3=[$]$2
3601                                 ;;
3602                         *) #(vi
3603                                 $2='.sl'
3604                                 $3=[$]$2
3605                                 ;;
3606                         esac
3607                         ;;
3608                 *)      $2='.so'
3609                         $3=[$]$2
3610                         ;;
3611                 esac
3612         esac
3613         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3614         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3615 ])dnl
3616 dnl ---------------------------------------------------------------------------
3617 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3618 dnl -----------
3619 dnl Compute the string to append to -library from the given model name
3620 dnl $1 = model name
3621 dnl $2 = variable to set
3622 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3623 AC_DEFUN([CF_LIB_TYPE],
3624 [
3625         case $1 in
3626         libtool) $2=''   ;;
3627         normal)  $2=''   ;;
3628         debug)   $2='_g' ;;
3629         profile) $2='_p' ;;
3630         shared)  $2=''   ;;
3631         esac
3632         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3633 ])dnl
3634 dnl ---------------------------------------------------------------------------
3635 dnl CF_LINK_DATAONLY version: 9 updated: 2009/01/01 20:21:38
3636 dnl ----------------
3637 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3638 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3639 dnl have to provide wrappers for global tables to ensure they're linked
3640 dnl properly.
3641 AC_DEFUN([CF_LINK_DATAONLY],
3642 [
3643 AC_MSG_CHECKING([if data-only library module links])
3644 AC_CACHE_VAL(cf_cv_link_dataonly,[
3645         rm -f conftest.a
3646         cat >conftest.$ac_ext <<EOF
3647 #line __oline__ "configure"
3648 int     testdata[[3]] = { 123, 456, 789 };
3649 EOF
3650         if AC_TRY_EVAL(ac_compile) ; then
3651                 mv conftest.o data.o && \
3652                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3653         fi
3654         rm -f conftest.$ac_ext data.o
3655         cat >conftest.$ac_ext <<EOF
3656 #line __oline__ "configure"
3657 int     testfunc()
3658 {
3659 #if defined(NeXT)
3660         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3661 #else
3662         extern int testdata[[3]];
3663         return testdata[[0]] == 123
3664            &&  testdata[[1]] == 456
3665            &&  testdata[[2]] == 789;
3666 #endif
3667 }
3668 EOF
3669         if AC_TRY_EVAL(ac_compile); then
3670                 mv conftest.o func.o && \
3671                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3672         fi
3673         rm -f conftest.$ac_ext func.o
3674         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3675         cf_saveLIBS="$LIBS"
3676         LIBS="conftest.a $LIBS"
3677         AC_TRY_RUN([
3678         int main()
3679         {
3680                 extern int testfunc();
3681                 ${cf_cv_main_return:-return} (!testfunc());
3682         }
3683         ],
3684         [cf_cv_link_dataonly=yes],
3685         [cf_cv_link_dataonly=no],
3686         [cf_cv_link_dataonly=unknown])
3687         LIBS="$cf_saveLIBS"
3688         ])
3689 AC_MSG_RESULT($cf_cv_link_dataonly)
3690
3691 if test "$cf_cv_link_dataonly" = no ; then
3692         AC_DEFINE(BROKEN_LINKER)
3693         BROKEN_LINKER=1
3694 fi
3695
3696 ])dnl
3697 dnl ---------------------------------------------------------------------------
3698 dnl CF_LINK_FUNCS version: 7 updated: 2006/12/16 12:33:30
3699 dnl -------------
3700 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3701 dnl A few non-Unix systems implement symlink, but not link.
3702 dnl A few non-systems implement neither (or have nonfunctional versions).
3703 AC_DEFUN([CF_LINK_FUNCS],
3704 [
3705 AC_CHECK_FUNCS( \
3706         remove \
3707         unlink )
3708
3709 if test "$cross_compiling" = yes ; then
3710         AC_CHECK_FUNCS( \
3711                 link \
3712                 symlink )
3713 else
3714         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3715                 cf_cv_link_funcs=
3716                 for cf_func in link symlink ; do
3717                         AC_TRY_RUN([
3718 #include <sys/types.h>
3719 #include <sys/stat.h>
3720 #ifdef HAVE_UNISTD_H
3721 #include <unistd.h>
3722 #endif
3723 int main()
3724 {
3725         int fail = 0;
3726         char *src = "config.log";
3727         char *dst = "conftest.chk";
3728         struct stat src_sb;
3729         struct stat dst_sb;
3730
3731         stat(src, &src_sb);
3732         fail = ($cf_func("config.log", "conftest.chk") < 0)
3733             || (stat(dst, &dst_sb) < 0)
3734             || (dst_sb.st_mtime != src_sb.st_mtime);
3735 #ifdef HAVE_UNLINK
3736         unlink(dst);
3737 #else
3738         remove(dst);
3739 #endif
3740         ${cf_cv_main_return:-return} (fail);
3741 }
3742                         ],[
3743                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3744                         eval 'ac_cv_func_'$cf_func'=yes'],[
3745                         eval 'ac_cv_func_'$cf_func'=no'],[
3746                         eval 'ac_cv_func_'$cf_func'=error'])
3747                 done
3748                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
3749         ])
3750         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK)
3751         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK)
3752 fi
3753 ])dnl
3754 dnl ---------------------------------------------------------------------------
3755 dnl CF_MAIN_RETURN version: 1 updated: 2006/12/10 09:51:54
3756 dnl --------------