aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2011,2012 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.608 2012/02/25 20:21:19 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54     [AC_TRY_LINK([#include <langinfo.h>],
  55       [char* cs = nl_langinfo(CODESET);],
  56       am_cv_langinfo_codeset=yes,
  57       am_cv_langinfo_codeset=no)
  58     ])
  59   if test $am_cv_langinfo_codeset = yes; then
  60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62   fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ACVERSION_CHECK version: 2 updated: 2011/05/08 11:22:03
  66 dnl ------------------
  67 dnl Conditionally generate script according to whether we're using a given autoconf.
  68 dnl
  69 dnl $1 = version to compare against
  70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  71 dnl $3 = code to use if AC_ACVERSION is older than $1.
  72 define(CF_ACVERSION_CHECK,
  73 [
  74 ifdef([m4_version_compare],
  75 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  76 [CF_ACVERSION_COMPARE(
  77 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  78 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  79 dnl ---------------------------------------------------------------------------
  80 dnl CF_ACVERSION_COMPARE version: 2 updated: 2011/04/14 20:56:50
  81 dnl --------------------
  82 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  83 dnl                      MAJOR2, MINOR2, TERNARY2,
  84 dnl                      PRINTABLE2, not FOUND, FOUND)
  85 define(CF_ACVERSION_COMPARE,
  86 [ifelse(builtin([eval], [$2 < $5]), 1,
  87 [ifelse([$8], , ,[$8])],
  88 [ifelse([$9], , ,[$9])])])dnl
  89 dnl ---------------------------------------------------------------------------
  90 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
  91 dnl -------------------
  92 dnl Construct the list of include-options for the C programs in the Ada95
  93 dnl binding.
  94 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  95 [
  96 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  97 if test "$srcdir" != "."; then
  98         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  99 fi
 100 if test "$GCC" != yes; then
 101         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 102 elif test "$includedir" != "/usr/include"; then
 103         if test "$includedir" = '${prefix}/include' ; then
 104                 if test $prefix != /usr ; then
 105                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 106                 fi
 107         else
 108                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 109         fi
 110 fi
 111 AC_SUBST(ACPPFLAGS)
 112 ])dnl
 113 dnl ---------------------------------------------------------------------------
 114 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 115 dnl ---------------
 116 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 117 AC_DEFUN([CF_ADD_ADAFLAGS],[
 118         ADAFLAGS="$ADAFLAGS $1"
 119         AC_SUBST(ADAFLAGS)
 120 ])dnl
 121 dnl ---------------------------------------------------------------------------
 122 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
 123 dnl -------------
 124 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 125 dnl The second parameter if given makes this macro verbose.
 126 dnl
 127 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 128 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 129 dnl confused by the quotes (which require backslashes to keep them usable).
 130 AC_DEFUN([CF_ADD_CFLAGS],
 131 [
 132 cf_fix_cppflags=no
 133 cf_new_cflags=
 134 cf_new_cppflags=
 135 cf_new_extra_cppflags=
 136
 137 for cf_add_cflags in $1
 138 do
 139 case $cf_fix_cppflags in
 140 no)
 141         case $cf_add_cflags in #(vi
 142         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 143                 case $cf_add_cflags in
 144                 -D*)
 145                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 146
 147                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 148                                 && test -z "${cf_tst_cflags}" \
 149                                 && cf_fix_cppflags=yes
 150
 151                         if test $cf_fix_cppflags = yes ; then
 152                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 153                                 continue
 154                         elif test "${cf_tst_cflags}" = "\"'" ; then
 155                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 156                                 continue
 157                         fi
 158                         ;;
 159                 esac
 160                 case "$CPPFLAGS" in
 161                 *$cf_add_cflags) #(vi
 162                         ;;
 163                 *) #(vi
 164                         case $cf_add_cflags in #(vi
 165                         -D*)
 166                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 167                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 168                                 ;;
 169                         esac
 170                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 171                         ;;
 172                 esac
 173                 ;;
 174         *)
 175                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 176                 ;;
 177         esac
 178         ;;
 179 yes)
 180         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 181
 182         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 183
 184         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 185                 && test -z "${cf_tst_cflags}" \
 186                 && cf_fix_cppflags=no
 187         ;;
 188 esac
 189 done
 190
 191 if test -n "$cf_new_cflags" ; then
 192         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 193         CFLAGS="$CFLAGS $cf_new_cflags"
 194 fi
 195
 196 if test -n "$cf_new_cppflags" ; then
 197         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 198         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 199 fi
 200
 201 if test -n "$cf_new_extra_cppflags" ; then
 202         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 203         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 204 fi
 205
 206 AC_SUBST(EXTRA_CPPFLAGS)
 207
 208 ])dnl
 209 dnl ---------------------------------------------------------------------------
 210 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 211 dnl -------------
 212 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 213 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 214 dnl but old versions (and some misinstalled ones) need that.  To make things
 215 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 216 dnl the include-path).
 217 AC_DEFUN([CF_ADD_INCDIR],
 218 [
 219 if test -n "$1" ; then
 220   for cf_add_incdir in $1
 221   do
 222         while test $cf_add_incdir != /usr/include
 223         do
 224           if test -d $cf_add_incdir
 225           then
 226                 cf_have_incdir=no
 227                 if test -n "$CFLAGS$CPPFLAGS" ; then
 228                   # a loop is needed to ensure we can add subdirs of existing dirs
 229                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 230                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 231                           cf_have_incdir=yes; break
 232                         fi
 233                   done
 234                 fi
 235
 236                 if test "$cf_have_incdir" = no ; then
 237                   if test "$cf_add_incdir" = /usr/local/include ; then
 238                         if test "$GCC" = yes
 239                         then
 240                           cf_save_CPPFLAGS=$CPPFLAGS
 241                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 242                           AC_TRY_COMPILE([#include <stdio.h>],
 243                                   [printf("Hello")],
 244                                   [],
 245                                   [cf_have_incdir=yes])
 246                           CPPFLAGS=$cf_save_CPPFLAGS
 247                         fi
 248                   fi
 249                 fi
 250
 251                 if test "$cf_have_incdir" = no ; then
 252                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 253                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 254
 255                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 256                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 257                   cf_add_incdir="$cf_top_incdir"
 258                 else
 259                   break
 260                 fi
 261           fi
 262         done
 263   done
 264 fi
 265 ])dnl
 266 dnl ---------------------------------------------------------------------------
 267 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 268 dnl ----------
 269 dnl Add a library, used to enforce consistency.
 270 dnl
 271 dnl $1 = library to add, without the "-l"
 272 dnl $2 = variable to update (default $LIBS)
 273 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 274 dnl ---------------------------------------------------------------------------
 275 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 276 dnl -------------
 277 dnl     Adds to the library-path
 278 dnl
 279 dnl     Some machines have trouble with multiple -L options.
 280 dnl
 281 dnl $1 is the (list of) directory(s) to add
 282 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 283 dnl
 284 AC_DEFUN([CF_ADD_LIBDIR],
 285 [
 286 if test -n "$1" ; then
 287   for cf_add_libdir in $1
 288   do
 289     if test $cf_add_libdir = /usr/lib ; then
 290       :
 291     elif test -d $cf_add_libdir
 292     then
 293       cf_have_libdir=no
 294       if test -n "$LDFLAGS$LIBS" ; then
 295         # a loop is needed to ensure we can add subdirs of existing dirs
 296         for cf_test_libdir in $LDFLAGS $LIBS ; do
 297           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 298             cf_have_libdir=yes; break
 299           fi
 300         done
 301       fi
 302       if test "$cf_have_libdir" = no ; then
 303         CF_VERBOSE(adding $cf_add_libdir to library-path)
 304         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 305       fi
 306     fi
 307   done
 308 fi
 309 ])dnl
 310 dnl ---------------------------------------------------------------------------
 311 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 312 dnl -----------
 313 dnl Add one or more libraries, used to enforce consistency.
 314 dnl
 315 dnl $1 = libraries to add, with the "-l", etc.
 316 dnl $2 = variable to update (default $LIBS)
 317 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 318 dnl ---------------------------------------------------------------------------
 319 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 320 dnl ------------------
 321 dnl Append to a search-list for a nonstandard header/lib-file
 322 dnl     $1 = the variable to return as result
 323 dnl     $2 = the package name
 324 dnl     $3 = the subdirectory, e.g., bin, include or lib
 325 dnl $4 = the directory under which we will test for subdirectories
 326 dnl $5 = a directory that we do not want $4 to match
 327 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 328 [
 329 test "$4" != "$5" && \
 330 test -d "$4" && \
 331 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 332         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 333         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 334         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 335         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 336         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 337         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 338 }
 339 ])dnl
 340 dnl ---------------------------------------------------------------------------
 341 dnl CF_ANSI_CC_CHECK version: 11 updated: 2011/07/01 19:47:45
 342 dnl ----------------
 343 dnl This was originally adapted from the macros 'fp_PROG_CC_STDC' and
 344 dnl 'fp_C_PROTOTYPES' in the sharutils 4.2 distribution.
 345 AC_DEFUN([CF_ANSI_CC_CHECK],
 346 [
 347 # This should have been defined by AC_PROG_CC
 348 : ${CC:=cc}
 349
 350 # Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 351 # into CC.  This will not help with broken scripts that wrap the compiler with
 352 # options, but eliminates a more common category of user confusion.
 353 AC_MSG_CHECKING(\$CC variable)
 354 case "$CC" in #(vi
 355 *[[\ \  ]]-[[IUD]]*)
 356         AC_MSG_RESULT(broken)
 357         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 358         # humor him...
 359         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 360         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 361         CF_ADD_CFLAGS($cf_flags)
 362         ;;
 363 *)
 364         AC_MSG_RESULT(ok)
 365         ;;
 366 esac
 367
 368 AC_CACHE_CHECK(for ${CC:-cc} option to accept ANSI C, cf_cv_ansi_cc,[
 369 cf_cv_ansi_cc=no
 370 cf_save_CFLAGS="$CFLAGS"
 371 cf_save_CPPFLAGS="$CPPFLAGS"
 372 # Don't try gcc -ansi; that turns off useful extensions and
 373 # breaks some systems' header files.
 374 # AIX                   -qlanglvl=ansi
 375 # Ultrix and OSF/1      -std1
 376 # HP-UX                 -Aa -D_HPUX_SOURCE
 377 # SVR4                  -Xc
 378 # UnixWare 1.2          (cannot use -Xc, since ANSI/POSIX clashes)
 379 for cf_arg in "-DCC_HAS_PROTOS" \
 380         "" \
 381         -qlanglvl=ansi \
 382         -std1 \
 383         -Ae \
 384         "-Aa -D_HPUX_SOURCE" \
 385         -Xc
 386 do
 387         CF_ADD_CFLAGS($cf_arg)
 388         AC_TRY_COMPILE(
 389 [
 390 #ifndef CC_HAS_PROTOS
 391 #if !defined(__STDC__) || (__STDC__ != 1)
 392 choke me
 393 #endif
 394 #endif
 395 ],[
 396         int test (int i, double x);
 397         struct s1 {int (*f) (int a);};
 398         struct s2 {int (*f) (double a);};],
 399         [cf_cv_ansi_cc="$cf_arg"; break])
 400 done
 401 CFLAGS="$cf_save_CFLAGS"
 402 CPPFLAGS="$cf_save_CPPFLAGS"
 403 ])
 404
 405 if test "$cf_cv_ansi_cc" != "no"; then
 406 if test ".$cf_cv_ansi_cc" != ".-DCC_HAS_PROTOS"; then
 407         CF_ADD_CFLAGS($cf_cv_ansi_cc)
 408 else
 409         AC_DEFINE(CC_HAS_PROTOS)
 410 fi
 411 fi
 412 ])dnl
 413 dnl ---------------------------------------------------------------------------
 414 dnl CF_ANSI_CC_REQD version: 4 updated: 2008/03/23 14:48:54
 415 dnl ---------------
 416 dnl For programs that must use an ANSI compiler, obtain compiler options that
 417 dnl will make it recognize prototypes.  We'll do preprocessor checks in other
 418 dnl macros, since tools such as unproto can fake prototypes, but only part of
 419 dnl the preprocessor.
 420 AC_DEFUN([CF_ANSI_CC_REQD],
 421 [AC_REQUIRE([CF_ANSI_CC_CHECK])
 422 if test "$cf_cv_ansi_cc" = "no"; then
 423         AC_MSG_ERROR(
 424 [Your compiler does not appear to recognize prototypes.
 425 You have the following choices:
 426         a. adjust your compiler options
 427         b. get an up-to-date compiler
 428         c. use a wrapper such as unproto])
 429 fi
 430 ])dnl
 431 dnl ---------------------------------------------------------------------------
 432 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 433 dnl --------------
 434 dnl Allow user to disable a normally-on option.
 435 AC_DEFUN([CF_ARG_DISABLE],
 436 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 437 dnl ---------------------------------------------------------------------------
 438 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 439 dnl -------------
 440 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 441 dnl values.
 442 dnl
 443 dnl Parameters:
 444 dnl $1 = option name
 445 dnl $2 = help-string
 446 dnl $3 = action to perform if option is not default
 447 dnl $4 = action if perform if option is default
 448 dnl $5 = default option value (either 'yes' or 'no')
 449 AC_DEFUN([CF_ARG_OPTION],
 450 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 451   if test "$enableval" != "$5" ; then
 452 ifelse([$3],,[    :]dnl
 453 ,[    $3]) ifelse([$4],,,[
 454   else
 455     $4])
 456   fi],[enableval=$5 ifelse([$4],,,[
 457   $4
 458 ])dnl
 459   ])])dnl
 460 dnl ---------------------------------------------------------------------------
 461 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 462 dnl -----------
 463 dnl Check for suitable "ar" (archiver) options for updating an archive.
 464 AC_DEFUN([CF_AR_FLAGS],[
 465 AC_REQUIRE([CF_PROG_AR])
 466
 467 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 468         cf_cv_ar_flags=unknown
 469         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 470         do
 471
 472                 # check if $ARFLAGS already contains this choice
 473                 if test "x$ARFLAGS" != "x" ; then
 474                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 475                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 476                                 cf_cv_ar_flags=
 477                                 break
 478                         fi
 479                 fi
 480
 481                 rm -f conftest.$ac_cv_objext
 482                 rm -f conftest.a
 483
 484                 cat >conftest.$ac_ext <<EOF
 485 #line __oline__ "configure"
 486 int     testdata[[3]] = { 123, 456, 789 };
 487 EOF
 488                 if AC_TRY_EVAL(ac_compile) ; then
 489                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 490                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 491                         if test -f conftest.a ; then
 492                                 cf_cv_ar_flags=$cf_ar_flags
 493                                 break
 494                         fi
 495                 else
 496                         CF_VERBOSE(cannot compile test-program)
 497                         break
 498                 fi
 499         done
 500         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 501 ])
 502
 503 if test -n "$ARFLAGS" ; then
 504         if test -n "$cf_cv_ar_flags" ; then
 505                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 506         fi
 507 else
 508         ARFLAGS=$cf_cv_ar_flags
 509 fi
 510
 511 AC_SUBST(ARFLAGS)
 512 ])
 513 dnl ---------------------------------------------------------------------------
 514 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
 515 dnl -----------------
 516 dnl Check if awk can handle big strings using printf.  Some older versions of
 517 dnl awk choke on large strings passed via "%s".
 518 dnl
 519 dnl $1 = desired string size
 520 dnl $2 = variable to set with result
 521 AC_DEFUN([CF_AWK_BIG_PRINTF],
 522 [
 523         case x$AWK in #(vi
 524         x)
 525                 eval $2=no
 526                 ;;
 527         *) #(vi
 528                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 529                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 530                         eval $2=yes
 531                 else
 532                         eval $2=no
 533                 fi
 534                 ;;
 535         esac
 536 ])dnl
 537 dnl ---------------------------------------------------------------------------
 538 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 539 dnl ------------
 540 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 541 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 542 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 543 dnl
 544 dnl Treat the configuration-variable specially here, since we're directly
 545 dnl substituting its value (i.e., 1/0).
 546 dnl
 547 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 548 AC_DEFUN([CF_BOOL_DECL],
 549 [
 550 AC_MSG_CHECKING(if we should include stdbool.h)
 551
 552 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 553         AC_TRY_COMPILE([],[bool foo = false],
 554                 [cf_cv_header_stdbool_h=0],
 555                 [AC_TRY_COMPILE([
 556 #ifndef __BEOS__
 557 #include <stdbool.h>
 558 #endif
 559 ],[bool foo = false],
 560                         [cf_cv_header_stdbool_h=1],
 561                         [cf_cv_header_stdbool_h=0])])])
 562
 563 if test "$cf_cv_header_stdbool_h" = 1
 564 then    AC_MSG_RESULT(yes)
 565 else    AC_MSG_RESULT(no)
 566 fi
 567
 568 AC_MSG_CHECKING([for builtin bool type])
 569
 570 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 571         AC_TRY_COMPILE([
 572 #include <stdio.h>
 573 #include <sys/types.h>
 574 ],[bool x = false],
 575                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 576                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 577         ])
 578
 579 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 580 then    AC_MSG_RESULT(yes)
 581 else    AC_MSG_RESULT(no)
 582 fi
 583 ])dnl
 584 dnl ---------------------------------------------------------------------------
 585 dnl CF_BOOL_SIZE version: 12 updated: 2006/12/16 12:33:30
 586 dnl ------------
 587 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 588 dnl Don't bother looking for bool.h, since it's been deprecated.
 589 dnl
 590 dnl If the current compiler is C rather than C++, we get the bool definition
 591 dnl from <stdbool.h>.
 592 AC_DEFUN([CF_BOOL_SIZE],
 593 [
 594 AC_MSG_CHECKING([for size of bool])
 595 AC_CACHE_VAL(cf_cv_type_of_bool,[
 596         rm -f cf_test.out
 597         AC_TRY_RUN([
 598 #include <stdlib.h>
 599 #include <stdio.h>
 600
 601 #if defined(__cplusplus)
 602
 603 #ifdef HAVE_GXX_BUILTIN_H
 604 #include <g++/builtin.h>
 605 #elif HAVE_GPP_BUILTIN_H
 606 #include <gpp/builtin.h>
 607 #elif HAVE_BUILTIN_H
 608 #include <builtin.h>
 609 #endif
 610
 611 #else
 612
 613 #if $cf_cv_header_stdbool_h
 614 #include <stdbool.h>
 615 #endif
 616
 617 #endif
 618
 619 main()
 620 {
 621         FILE *fp = fopen("cf_test.out", "w");
 622         if (fp != 0) {
 623                 bool x = true;
 624                 if ((bool)(-x) >= 0)
 625                         fputs("unsigned ", fp);
 626                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 627                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 628                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 629                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 630                 fclose(fp);
 631         }
 632         ${cf_cv_main_return:-return}(0);
 633 }
 634                 ],
 635                 [cf_cv_type_of_bool=`cat cf_test.out`
 636                  if test -z "$cf_cv_type_of_bool"; then
 637                    cf_cv_type_of_bool=unknown
 638                  fi],
 639                 [cf_cv_type_of_bool=unknown],
 640                 [cf_cv_type_of_bool=unknown])
 641         ])
 642         rm -f cf_test.out
 643 AC_MSG_RESULT($cf_cv_type_of_bool)
 644 if test "$cf_cv_type_of_bool" = unknown ; then
 645         case .$NCURSES_BOOL in #(vi
 646         .auto|.) NCURSES_BOOL=unsigned;;
 647         esac
 648         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 649         cf_cv_type_of_bool=$NCURSES_BOOL
 650 fi
 651 ])dnl
 652 dnl ---------------------------------------------------------------------------
 653 dnl CF_BUILD_CC version: 6 updated: 2006/10/14 15:23:15
 654 dnl -----------
 655 dnl If we're cross-compiling, allow the user to override the tools and their
 656 dnl options.  The configure script is oriented toward identifying the host
 657 dnl compiler, etc., but we need a build compiler to generate parts of the
 658 dnl source.
 659 dnl
 660 dnl $1 = default for $CPPFLAGS
 661 dnl $2 = default for $LIBS
 662 AC_DEFUN([CF_BUILD_CC],[
 663 AC_REQUIRE([CF_PROG_EXT])
 664 if test "$cross_compiling" = yes ; then
 665
 666         # defaults that we might want to override
 667         : ${BUILD_CFLAGS:=''}
 668         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 669         : ${BUILD_LDFLAGS:=''}
 670         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 671         : ${BUILD_EXEEXT:='$x'}
 672         : ${BUILD_OBJEXT:='o'}
 673
 674         AC_ARG_WITH(build-cc,
 675                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 676                 [BUILD_CC="$withval"],
 677                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 678         AC_MSG_CHECKING(for native build C compiler)
 679         AC_MSG_RESULT($BUILD_CC)
 680
 681         AC_MSG_CHECKING(for native build C preprocessor)
 682         AC_ARG_WITH(build-cpp,
 683                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 684                 [BUILD_CPP="$withval"],
 685                 [BUILD_CPP='${BUILD_CC} -E'])
 686         AC_MSG_RESULT($BUILD_CPP)
 687
 688         AC_MSG_CHECKING(for native build C flags)
 689         AC_ARG_WITH(build-cflags,
 690                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 691                 [BUILD_CFLAGS="$withval"])
 692         AC_MSG_RESULT($BUILD_CFLAGS)
 693
 694         AC_MSG_CHECKING(for native build C preprocessor-flags)
 695         AC_ARG_WITH(build-cppflags,
 696                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 697                 [BUILD_CPPFLAGS="$withval"])
 698         AC_MSG_RESULT($BUILD_CPPFLAGS)
 699
 700         AC_MSG_CHECKING(for native build linker-flags)
 701         AC_ARG_WITH(build-ldflags,
 702                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 703                 [BUILD_LDFLAGS="$withval"])
 704         AC_MSG_RESULT($BUILD_LDFLAGS)
 705
 706         AC_MSG_CHECKING(for native build linker-libraries)
 707         AC_ARG_WITH(build-libs,
 708                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 709                 [BUILD_LIBS="$withval"])
 710         AC_MSG_RESULT($BUILD_LIBS)
 711
 712         # this assumes we're on Unix.
 713         BUILD_EXEEXT=
 714         BUILD_OBJEXT=o
 715
 716         : ${BUILD_CC:='${CC}'}
 717
 718         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 719                 AC_MSG_ERROR([Cross-build requires two compilers.
 720 Use --with-build-cc to specify the native compiler.])
 721         fi
 722
 723 else
 724         : ${BUILD_CC:='${CC}'}
 725         : ${BUILD_CPP:='${CPP}'}
 726         : ${BUILD_CFLAGS:='${CFLAGS}'}
 727         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 728         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 729         : ${BUILD_LIBS:='${LIBS}'}
 730         : ${BUILD_EXEEXT:='$x'}
 731         : ${BUILD_OBJEXT:='o'}
 732 fi
 733
 734 AC_SUBST(BUILD_CC)
 735 AC_SUBST(BUILD_CPP)
 736 AC_SUBST(BUILD_CFLAGS)
 737 AC_SUBST(BUILD_CPPFLAGS)
 738 AC_SUBST(BUILD_LDFLAGS)
 739 AC_SUBST(BUILD_LIBS)
 740 AC_SUBST(BUILD_EXEEXT)
 741 AC_SUBST(BUILD_OBJEXT)
 742 ])dnl
 743 dnl ---------------------------------------------------------------------------
 744 dnl CF_CFG_DEFAULTS version: 8 updated: 2011/06/04 20:09:13
 745 dnl ---------------
 746 dnl Determine the default configuration into which we'll install ncurses.  This
 747 dnl can be overridden by the user's command-line options.  There's two items to
 748 dnl look for:
 749 dnl     1. the prefix (e.g., /usr)
 750 dnl     2. the header files (e.g., /usr/include/ncurses)
 751 dnl We'll look for a previous installation of ncurses and use the same defaults.
 752 dnl
 753 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 754 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 755 dnl programs from a vendor's.
 756 AC_DEFUN([CF_CFG_DEFAULTS],
 757 [
 758 AC_MSG_CHECKING(for prefix)
 759 if test "x$prefix" = "xNONE" ; then
 760         case "$cf_cv_system_name" in
 761                 # non-vendor systems don't have a conflict
 762         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|k*bsd*-gnu)
 763                 prefix=/usr
 764                 ;;
 765         *)      prefix=$ac_default_prefix
 766                 ;;
 767         esac
 768 fi
 769 AC_MSG_RESULT($prefix)
 770
 771 if test "x$prefix" = "xNONE" ; then
 772 AC_MSG_CHECKING(for default include-directory)
 773 test -n "$verbose" && echo 1>&AC_FD_MSG
 774 for cf_symbol in \
 775         $includedir \
 776         $includedir/ncurses \
 777         $prefix/include \
 778         $prefix/include/ncurses \
 779         /usr/local/include \
 780         /usr/local/include/ncurses \
 781         /usr/include \
 782         /usr/include/ncurses
 783 do
 784         cf_dir=`eval echo $cf_symbol`
 785         if test -f $cf_dir/curses.h ; then
 786         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 787                 includedir="$cf_symbol"
 788                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 789                 break
 790         fi
 791         fi
 792         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 793 done
 794 AC_MSG_RESULT($includedir)
 795 fi
 796 ])dnl
 797 dnl ---------------------------------------------------------------------------
 798 dnl CF_CGETENT version: 4 updated: 2011/08/07 14:54:41
 799 dnl ----------
 800 dnl Check if the terminal-capability database functions are available.  If not,
 801 dnl ncurses has a much-reduced version.
 802 AC_DEFUN([CF_CGETENT],[
 803 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 804 AC_TRY_LINK([
 805 #include <stdlib.h>],[
 806         char temp[128];
 807         char *buf = temp;
 808         char *db_array = temp;
 809         cgetent(&buf, &db_array, "vt100");
 810         cgetcap(buf, "tc", '=');
 811         cgetmatch(buf, "tc");
 812         ],
 813         [cf_cv_cgetent=yes],
 814         [cf_cv_cgetent=no])
 815 ])
 816
 817 if test "$cf_cv_cgetent" = yes
 818 then
 819         AC_DEFINE(HAVE_BSD_CGETENT)
 820 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 821 AC_TRY_LINK([
 822 #include <stdlib.h>],[
 823         char temp[128];
 824         char *buf = temp;
 825 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 826         const char *db_array = temp;
 827         cgetent(&buf, &db_array, "vt100");
 828 #endif
 829         cgetcap(buf, "tc", '=');
 830         cgetmatch(buf, "tc");
 831         ],
 832         [cf_cv_cgetent_const=yes],
 833         [cf_cv_cgetent_const=no])
 834 ])
 835         if test "$cf_cv_cgetent_const" = yes
 836         then
 837                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const)
 838         fi
 839 fi
 840 ])dnl
 841 dnl ---------------------------------------------------------------------------
 842 dnl CF_CHECK_CACHE version: 11 updated: 2008/03/23 14:45:59
 843 dnl --------------
 844 dnl Check if we're accidentally using a cache from a different machine.
 845 dnl Derive the system name, as a check for reusing the autoconf cache.
 846 dnl
 847 dnl If we've packaged config.guess and config.sub, run that (since it does a
 848 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 849 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 850 dnl which is useful in cross-compiles.
 851 dnl
 852 dnl Note: we would use $ac_config_sub, but that is one of the places where
 853 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 854 AC_DEFUN([CF_CHECK_CACHE],
 855 [
 856 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 857         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 858         system_name="$host_os"
 859 else
 860         system_name="`(uname -s -r) 2>/dev/null`"
 861         if test -z "$system_name" ; then
 862                 system_name="`(hostname) 2>/dev/null`"
 863         fi
 864 fi
 865 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name")
 866 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 867
 868 test -z "$system_name" && system_name="$cf_cv_system_name"
 869 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 870
 871 if test ".$system_name" != ".$cf_cv_system_name" ; then
 872         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 873         AC_MSG_ERROR("Please remove config.cache and try again.")
 874 fi
 875 ])dnl
 876 dnl ---------------------------------------------------------------------------
 877 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
 878 dnl --------------
 879 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 880 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 881 dnl ourselves.
 882 dnl
 883 dnl $1 = the name to check
 884 dnl $2 = the assumed type
 885 AC_DEFUN([CF_CHECK_ERRNO],
 886 [
 887 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 888     AC_TRY_COMPILE([
 889 #ifdef HAVE_STDLIB_H
 890 #include <stdlib.h>
 891 #endif
 892 #include <stdio.h>
 893 #include <sys/types.h>
 894 #include <errno.h> ],
 895     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 896     [cf_cv_dcl_$1=yes],
 897     [cf_cv_dcl_$1=no])
 898 ])
 899
 900 if test "$cf_cv_dcl_$1" = no ; then
 901     CF_UPPER(cf_result,decl_$1)
 902     AC_DEFINE_UNQUOTED($cf_result)
 903 fi
 904
 905 # It's possible (for near-UNIX clones) that the data doesn't exist
 906 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 907 ])dnl
 908 dnl ---------------------------------------------------------------------------
 909 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
 910 dnl --------------------
 911 dnl Check for existence of external data in the current set of libraries.  If
 912 dnl we can modify it, it's real enough.
 913 dnl $1 = the name to check
 914 dnl $2 = its type
 915 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 916 [
 917 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 918     AC_TRY_LINK([
 919 #undef $1
 920 extern $2 $1;
 921 ],
 922     [$1 = 2],
 923     [cf_cv_have_$1=yes],
 924     [cf_cv_have_$1=no])
 925 ])
 926
 927 if test "$cf_cv_have_$1" = yes ; then
 928     CF_UPPER(cf_result,have_$1)
 929     AC_DEFINE_UNQUOTED($cf_result)
 930 fi
 931
 932 ])dnl
 933 dnl ---------------------------------------------------------------------------
 934 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 935 dnl -------------------
 936 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 937 dnl is not "weak" - warn about this because it can create problems linking
 938 dnl applications with ncurses.
 939 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 940 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 941
 942 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 943 cf_cv_check_gpm_wgetch=unknown
 944 if test "$cross_compiling" != yes ; then
 945
 946 cat >conftest.$ac_ext <<CF_EOF
 947 #include <gpm.h>
 948 int main()
 949 {
 950         Gpm_Wgetch();
 951         ${cf_cv_main_return:-return}(0);
 952 }
 953 CF_EOF
 954
 955         cf_save_LIBS="$LIBS"
 956         # This only works if we can look at the symbol table.  If a shared
 957         # library is stripped for install, we cannot use that.  So we're forced
 958         # to rely on the static library, noting that some packagers may not
 959         # include it.
 960         LIBS="-static -lgpm -dynamic $LIBS"
 961         if AC_TRY_EVAL(ac_compile) ; then
 962                 if AC_TRY_EVAL(ac_link) ; then
 963                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 964                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 965                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 966                 fi
 967         fi
 968         rm -rf conftest*
 969         LIBS="$cf_save_LIBS"
 970 fi
 971 ])
 972
 973 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 974         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 975 fi
 976 ])])dnl
 977 dnl ---------------------------------------------------------------------------
 978 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
 979 dnl ----------------
 980 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
 981 AC_DEFUN([CF_CHECK_WCHAR_H],[
 982 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
 983 AC_TRY_COMPILE(
 984 [
 985 #include <stdlib.h>
 986 #include <wchar.h>
 987 ],[
 988         wint_t foo = 0;
 989         int bar = iswpunct(foo)],
 990         [cf_cv_wchar_h_okay=yes],
 991         [cf_cv_wchar_h_okay=no])])
 992
 993 if test $cf_cv_wchar_h_okay = no
 994 then
 995         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 996 fi
 997 ])dnl
 998 dnl ---------------------------------------------------------------------------
 999 dnl CF_CPP_PARAM_INIT version: 5 updated: 2011/12/03 16:54:03
1000 dnl -----------------
1001 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1002 dnl is a late feature for the standard and is not in some recent compilers
1003 dnl (1999/9/11).
1004 AC_DEFUN([CF_CPP_PARAM_INIT],
1005 [
1006 if test -n "$CXX"; then
1007 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1008         AC_LANG_SAVE
1009         AC_LANG_CPLUSPLUS
1010         AC_TRY_RUN([
1011 class TEST {
1012 private:
1013         int value;
1014 public:
1015         TEST(int x = 1);
1016         ~TEST();
1017 };
1018
1019 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1020 {
1021         value = x;
1022 }
1023 int main() { }
1024 ],
1025         [cf_cv_cpp_param_init=yes],
1026         [cf_cv_cpp_param_init=no],
1027         [cf_cv_cpp_param_init=unknown])
1028         AC_LANG_RESTORE
1029 ])
1030 fi
1031 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT)
1032 ])dnl
1033 dnl ---------------------------------------------------------------------------
1034 dnl CF_CPP_STATIC_CAST version: 1 updated: 2005/07/23 16:52:43
1035 dnl ------------------
1036 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1037 dnl not be supported in g++ before 3.0
1038 AC_DEFUN([CF_CPP_STATIC_CAST],
1039 [
1040 if test -n "$CXX"; then
1041
1042 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1043         AC_LANG_SAVE
1044         AC_LANG_CPLUSPLUS
1045
1046         AC_TRY_COMPILE([
1047 class NCursesPanel
1048 {
1049 public:
1050   NCursesPanel(int nlines,
1051                int ncols,
1052                int begin_y = 0,
1053                int begin_x = 0)
1054   {
1055   }
1056
1057   ~NCursesPanel();
1058 };
1059
1060 template<class T> class NCursesUserPanel : public NCursesPanel
1061 {
1062 public:
1063   NCursesUserPanel (int nlines,
1064                     int ncols,
1065                     int begin_y = 0,
1066                     int begin_x = 0,
1067                     const T* p_UserData = static_cast<T*>(0))
1068     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1069   {
1070   };
1071   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1072   {
1073   };
1074
1075   virtual ~NCursesUserPanel() {};
1076 };
1077 ],[
1078         const char* p_UserData = static_cast<char*>(0)],
1079         [cf_cv_cpp_static_cast=yes],
1080         [cf_cv_cpp_static_cast=no])
1081
1082         AC_LANG_RESTORE
1083 ])
1084
1085 fi
1086
1087 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST)
1088 ])dnl
1089 dnl ---------------------------------------------------------------------------
1090 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1091 dnl ---------------
1092 dnl Setup special archiver flags for given compilers.
1093 AC_DEFUN([CF_CXX_AR_FLAGS],[
1094         CXX_AR='$(AR)'
1095         CXX_ARFLAGS='$(ARFLAGS)'
1096         case $cf_cv_system_name in #(vi
1097         irix*) #(vi
1098             if test "$GXX" != yes ; then
1099                 CXX_AR='$(CXX)'
1100                 CXX_ARFLAGS='-ar -o'
1101             fi
1102             ;;
1103         sco3.2v5*) #(vi
1104             CXXLDFLAGS="-u main"
1105             ;;
1106         solaris2*)
1107             if test "$GXX" != yes ; then
1108                 CXX_AR='$(CXX)'
1109                 CXX_ARFLAGS='-xar -o'
1110             fi
1111             ;;
1112         esac
1113         AC_SUBST(CXXLDFLAGS)
1114         AC_SUBST(CXX_AR)
1115         AC_SUBST(CXX_ARFLAGS)
1116 ])dnl
1117 dnl ---------------------------------------------------------------------------
1118 dnl CF_CXX_IOSTREAM_NAMESPACE version: 1 updated: 2011/10/29 08:35:34
1119 dnl -------------------------
1120 dnl For c++, check if iostream uses "std::" namespace.
1121 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1122 AC_CHECK_HEADERS(iostream)
1123 if test x"$ac_cv_header_iostream" = xyes ; then
1124         AC_MSG_CHECKING(if iostream uses std-namespace)
1125         AC_TRY_COMPILE([
1126 #include <iostream>
1127 using std::endl;
1128 using std::cerr;],[
1129 cerr << "testing" << endl;
1130 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1131         AC_MSG_RESULT($cf_iostream_namespace)
1132         if test "$cf_iostream_namespace" = yes ; then
1133                 AC_DEFINE(IOSTREAM_NAMESPACE)
1134         fi
1135 fi
1136 ])dnl
1137 dnl ---------------------------------------------------------------------------
1138 dnl CF_C_INLINE version: 3 updated: 2010/05/01 15:14:41
1139 dnl -----------
1140 dnl Check if the C compiler supports "inline".
1141 dnl $1 is the name of a shell variable to set if inline is supported
1142 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1143 AC_DEFUN([CF_C_INLINE],[
1144 AC_C_INLINE
1145 $1=
1146 if test "$ac_cv_c_inline" != no ; then
1147   $1=inline
1148   if test "$INTEL_COMPILER" = yes
1149   then
1150     :
1151   elif test "$GCC" = yes
1152   then
1153     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1154       cf_save_CFLAGS=$CFLAGS
1155       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1156       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1157       [${cf_cv_main_return:-return} foo()],
1158       [cf_cv_gcc_inline=yes],
1159       [cf_cv_gcc_inline=no])
1160       CFLAGS=$cf_save_CFLAGS
1161     ])
1162     if test "$cf_cv_gcc_inline" = yes ; then
1163         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1164     fi
1165   fi
1166 fi
1167 AC_SUBST($1)
1168 ])dnl
1169 dnl ---------------------------------------------------------------------------
1170 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1171 dnl ----------
1172 dnl "dirname" is not portable, so we fake it with a shell script.
1173 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1174 dnl ---------------------------------------------------------------------------
1175 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1176 dnl ---------------
1177 AC_DEFUN([CF_DIRS_TO_MAKE],
1178 [
1179 DIRS_TO_MAKE="lib"
1180 for cf_item in $cf_list_models
1181 do
1182         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1183         for cf_item2 in $DIRS_TO_MAKE
1184         do
1185                 test $cf_item2 = $cf_subdir && break
1186         done
1187         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1188 done
1189 for cf_dir in $DIRS_TO_MAKE
1190 do
1191         test ! -d $cf_dir && mkdir $cf_dir
1192 done
1193 AC_SUBST(DIRS_TO_MAKE)
1194 ])dnl
1195 dnl ---------------------------------------------------------------------------
1196 dnl CF_DISABLE_LEAKS version: 6 updated: 2010/07/23 04:14:32
1197 dnl ----------------
1198 dnl Combine no-leak checks with the libraries or tools that are used for the
1199 dnl checks.
1200 AC_DEFUN([CF_DISABLE_LEAKS],[
1201
1202 AC_REQUIRE([CF_WITH_DMALLOC])
1203 AC_REQUIRE([CF_WITH_DBMALLOC])
1204 AC_REQUIRE([CF_WITH_VALGRIND])
1205
1206 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1207 AC_ARG_ENABLE(leaks,
1208         [  --disable-leaks         test: free permanent memory, analyze leaks],
1209         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1210         : ${with_no_leaks:=no})
1211 AC_MSG_RESULT($with_no_leaks)
1212
1213 if test "$with_no_leaks" = yes ; then
1214         AC_DEFINE(NO_LEAKS)
1215         AC_DEFINE(YY_NO_LEAKS)
1216 fi
1217 ])dnl
1218 dnl ---------------------------------------------------------------------------
1219 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1220 dnl --------------------------
1221 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1222 dnl the older "-version-info" feature.  The newer feature allows us to use
1223 dnl version numbering on shared libraries which make them compatible with
1224 dnl various systems.
1225 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1226 [
1227 AC_MSG_CHECKING(if libtool -version-number should be used)
1228 CF_ARG_DISABLE(libtool-version,
1229         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1230         [cf_libtool_version=no],
1231         [cf_libtool_version=yes])
1232 AC_MSG_RESULT($cf_libtool_version)
1233
1234 if test "$cf_libtool_version" = yes ; then
1235         LIBTOOL_VERSION="-version-number"
1236 else
1237         LIBTOOL_VERSION="-version-info"
1238 fi
1239
1240 AC_SUBST(LIBTOOL_VERSION)
1241 ])dnl
1242 dnl ---------------------------------------------------------------------------
1243 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1244 dnl ---------------------
1245 dnl The rpath-hack makes it simpler to build programs, particularly with the
1246 dnl *BSD ports which may have essential libraries in unusual places.  But it
1247 dnl can interfere with building an executable for the base system.  Use this
1248 dnl option in that case.
1249 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1250 [
1251 AC_MSG_CHECKING(if rpath-hack should be disabled)
1252 CF_ARG_DISABLE(rpath-hack,
1253         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1254         [cf_disable_rpath_hack=yes],
1255         [cf_disable_rpath_hack=no])
1256 AC_MSG_RESULT($cf_disable_rpath_hack)
1257 if test "$cf_disable_rpath_hack" = no ; then
1258         CF_RPATH_HACK
1259 fi
1260 ])
1261 dnl ---------------------------------------------------------------------------
1262 dnl CF_ENABLE_PC_FILES version: 7 updated: 2011/12/10 18:58:47
1263 dnl ------------------
1264 dnl This is the "--enable-pc-files" option, which is available if there is a
1265 dnl pkg-config configuration on the local machine.
1266 AC_DEFUN([CF_ENABLE_PC_FILES],[
1267 AC_REQUIRE([CF_PKG_CONFIG])
1268 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1269
1270 if test "$PKG_CONFIG" != none ; then
1271         if test -n "$PKG_CONFIG_LIBDIR" && test -d "$PKG_CONFIG_LIBDIR" ; then
1272                 AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1273                 AC_ARG_ENABLE(pc-files,
1274                         [  --enable-pc-files       generate and install .pc files for pkg-config],
1275                         [enable_pc_files=$enableval],
1276                         [enable_pc_files=no])
1277                 AC_MSG_RESULT($enable_pc_files)
1278         elif test -z "$PKG_CONFIG_LIBDIR" || test "$PKG_CONFIG_LIBDIR" != no; then
1279                 enable_pc_files=no
1280                 AC_MSG_WARN(did not find $PKG_CONFIG library)
1281         fi
1282 else
1283         enable_pc_files=no
1284 fi
1285 ])dnl
1286 dnl ---------------------------------------------------------------------------
1287 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1288 dnl ---------------
1289 dnl Check if the rpath option should be used, setting cache variable
1290 dnl cf_cv_enable_rpath if so.
1291 AC_DEFUN([CF_ENABLE_RPATH],
1292 [
1293 AC_MSG_CHECKING(if rpath option should be used)
1294 AC_ARG_ENABLE(rpath,
1295 [  --enable-rpath          use rpath option when generating shared libraries],
1296 [cf_cv_enable_rpath=$enableval],
1297 [cf_cv_enable_rpath=no])
1298 AC_MSG_RESULT($cf_cv_enable_rpath)
1299 ])dnl
1300 dnl ---------------------------------------------------------------------------
1301 dnl CF_ENABLE_STRING_HACKS version: 1 updated: 2012/02/25 06:33:21
1302 dnl ----------------------
1303 dnl On a few platforms, the compiler and/or loader nags with untruthful
1304 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1305 dnl and implying that most uses of the recommended alternatives are correct.
1306 dnl
1307 dnl Factually speaking, no one has actually counted the number of uses of these
1308 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1309 dnl instances are meaningless compared to the hundreds of millions of lines of
1310 dnl existing C code.
1311 dnl
1312 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1313 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1314 dnl standard - but evolved through phases, and older implementations are likely
1315 dnl to yield surprising results, as documented in manpages on various systems.
1316 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1317 [
1318 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1319 AC_ARG_ENABLE(string-hacks,
1320         [  --enable-string-hacks  work around bogus compiler/loader warnings],
1321         [with_string_hacks=$enableval],
1322         [with_string_hacks=no])
1323 AC_MSG_RESULT($with_string_hacks)
1324
1325 if test "x$with_string_hacks" = "xyes"; then
1326         AC_DEFINE(USE_STRING_HACKS)
1327         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1328         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1329 fi
1330 ])dnl
1331 dnl ---------------------------------------------------------------------------
1332 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1333 dnl --------
1334 dnl Check if 'errno' is declared in <errno.h>
1335 AC_DEFUN([CF_ERRNO],
1336 [
1337 CF_CHECK_ERRNO(errno)
1338 ])dnl
1339 dnl ---------------------------------------------------------------------------
1340 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1341 dnl ---------------
1342 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1343 dnl math.h and builtin.h, only for ncurses
1344 AC_DEFUN([CF_ETIP_DEFINES],
1345 [
1346 AC_MSG_CHECKING(for special defines needed for etip.h)
1347 cf_save_CXXFLAGS="$CXXFLAGS"
1348 cf_result="none"
1349
1350 # etip.h includes ncurses.h which includes ncurses_dll.h
1351 # But ncurses_dll.h is generated - fix here.
1352 test -d include || mkdir include
1353 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1354
1355 for cf_math in "" MATH_H
1356 do
1357 for cf_excp in "" MATH_EXCEPTION
1358 do
1359         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1360         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1361         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1362 AC_TRY_COMPILE([
1363 #include <etip.h.in>
1364 ],[],[
1365         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1366         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1367         cf_result="$cf_math $cf_excp"
1368         break 2
1369 ],[])
1370 done
1371 done
1372 AC_MSG_RESULT($cf_result)
1373 CXXFLAGS="$cf_save_CXXFLAGS"
1374 ])
1375 dnl ---------------------------------------------------------------------------
1376 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1377 dnl ---------------
1378 dnl Find a library (specifically the linkage used in the code fragment),
1379 dnl searching for it if it is not already in the library path.
1380 dnl See also CF_ADD_SEARCHPATH.
1381 dnl
1382 dnl Parameters (4-on are optional):
1383 dnl     $1 = headers for library entrypoint
1384 dnl     $2 = code fragment for library entrypoint
1385 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1386 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1387 dnl     $5 = action to perform if not successful
1388 dnl     $6 = module name, if not the same as the library name
1389 dnl     $7 = extra libraries
1390 dnl
1391 dnl Sets these variables:
1392 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1393 dnl     $cf_cv_header_path_$3 - include-directory if needed
1394 dnl     $cf_cv_library_path_$3 - library-directory if needed
1395 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1396 AC_DEFUN([CF_FIND_LINKAGE],[
1397
1398 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1399 # will be set on completion of the AC_TRY_LINK below.
1400 cf_cv_header_path_$3=
1401 cf_cv_library_path_$3=
1402
1403 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1404
1405 cf_save_LIBS="$LIBS"
1406
1407 AC_TRY_LINK([$1],[$2],[
1408         cf_cv_find_linkage_$3=yes
1409         cf_cv_header_path_$3=/usr/include
1410         cf_cv_library_path_$3=/usr/lib
1411 ],[
1412
1413 LIBS="-l$3 $7 $cf_save_LIBS"
1414
1415 AC_TRY_LINK([$1],[$2],[
1416         cf_cv_find_linkage_$3=yes
1417         cf_cv_header_path_$3=/usr/include
1418         cf_cv_library_path_$3=/usr/lib
1419         cf_cv_library_file_$3="-l$3"
1420 ],[
1421         cf_cv_find_linkage_$3=no
1422         LIBS="$cf_save_LIBS"
1423
1424     CF_VERBOSE(find linkage for $3 library)
1425     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1426
1427     cf_save_CPPFLAGS="$CPPFLAGS"
1428     cf_test_CPPFLAGS="$CPPFLAGS"
1429
1430     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1431     for cf_cv_header_path_$3 in $cf_search
1432     do
1433       if test -d $cf_cv_header_path_$3 ; then
1434         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1435         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1436         AC_TRY_COMPILE([$1],[$2],[
1437             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1438             cf_cv_find_linkage_$3=maybe
1439             cf_test_CPPFLAGS="$CPPFLAGS"
1440             break],[
1441             CPPFLAGS="$cf_save_CPPFLAGS"
1442             ])
1443       fi
1444     done
1445
1446     if test "$cf_cv_find_linkage_$3" = maybe ; then
1447
1448       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1449
1450       cf_save_LIBS="$LIBS"
1451       cf_save_LDFLAGS="$LDFLAGS"
1452
1453       ifelse([$6],,,[
1454         CPPFLAGS="$cf_test_CPPFLAGS"
1455         LIBS="-l$3 $7 $cf_save_LIBS"
1456         AC_TRY_LINK([$1],[$2],[
1457             CF_VERBOSE(... found $3 library in system)
1458             cf_cv_find_linkage_$3=yes])
1459             CPPFLAGS="$cf_save_CPPFLAGS"
1460             LIBS="$cf_save_LIBS"
1461             ])
1462
1463       if test "$cf_cv_find_linkage_$3" != yes ; then
1464         CF_LIBRARY_PATH(cf_search,$3)
1465         for cf_cv_library_path_$3 in $cf_search
1466         do
1467           if test -d $cf_cv_library_path_$3 ; then
1468             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1469             CPPFLAGS="$cf_test_CPPFLAGS"
1470             LIBS="-l$3 $7 $cf_save_LIBS"
1471             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1472             AC_TRY_LINK([$1],[$2],[
1473                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1474                 cf_cv_find_linkage_$3=yes
1475                 cf_cv_library_file_$3="-l$3"
1476                 break],[
1477                 CPPFLAGS="$cf_save_CPPFLAGS"
1478                 LIBS="$cf_save_LIBS"
1479                 LDFLAGS="$cf_save_LDFLAGS"
1480                 ])
1481           fi
1482         done
1483         CPPFLAGS="$cf_save_CPPFLAGS"
1484         LDFLAGS="$cf_save_LDFLAGS"
1485       fi
1486
1487     else
1488       cf_cv_find_linkage_$3=no
1489     fi
1490     ],$7)
1491 ])
1492
1493 LIBS="$cf_save_LIBS"
1494
1495 if test "$cf_cv_find_linkage_$3" = yes ; then
1496 ifelse([$4],,[
1497         CF_ADD_INCDIR($cf_cv_header_path_$3)
1498         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1499         CF_ADD_LIB($3)
1500 ],[$4])
1501 else
1502 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1503 fi
1504 ])dnl
1505 dnl ---------------------------------------------------------------------------
1506 dnl CF_FUNC_DLSYM version: 2 updated: 2010/05/29 16:31:02
1507 dnl -------------
1508 dnl Test for dlsym() and related functions, as well as libdl.
1509 dnl
1510 dnl Sets
1511 dnl     $cf_have_dlsym
1512 dnl     $cf_have_libdl
1513 AC_DEFUN([CF_FUNC_DLSYM],[
1514 cf_have_dlsym=no
1515 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1516
1517 cf_have_libdl=no
1518 AC_CHECK_LIB(dl,dlsym,[
1519         cf_have_dlsym=yes
1520         cf_have_libdl=yes])])
1521
1522 if test "$cf_have_dlsym" = yes ; then
1523         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1524
1525         AC_MSG_CHECKING(whether able to link to dl*() functions)
1526         AC_TRY_LINK([#include <dlfcn.h>],[
1527                 void *obj;
1528                 if ((obj = dlopen("filename", 0)) != 0) {
1529                         if (dlsym(obj, "symbolname") == 0) {
1530                         dlclose(obj);
1531                         }
1532                 }],[
1533                 AC_DEFINE(HAVE_LIBDL)],[
1534                 AC_MSG_ERROR(Cannot link test program for libdl)])
1535         AC_MSG_RESULT(ok)
1536 else
1537         AC_MSG_ERROR(Cannot find dlsym function)
1538 fi
1539 ])
1540 dnl ---------------------------------------------------------------------------
1541 dnl CF_FUNC_MEMMOVE version: 7 updated: 2006/12/16 12:33:30
1542 dnl ---------------
1543 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1544 dnl is found, add our own version of memmove to the list of objects.
1545 AC_DEFUN([CF_FUNC_MEMMOVE],
1546 [
1547 AC_CHECK_FUNC(memmove,,[
1548 AC_CHECK_FUNC(bcopy,[
1549         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1550                 AC_TRY_RUN([
1551 int main() {
1552         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1553         char temp[40];
1554         bcopy(data, temp, sizeof(data));
1555         bcopy(temp+10, temp, 15);
1556         bcopy(temp+5, temp+15, 10);
1557         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1558 }
1559                 ],
1560                 [cf_cv_good_bcopy=yes],
1561                 [cf_cv_good_bcopy=no],
1562                 [cf_cv_good_bcopy=unknown])
1563                 ])
1564         ],[cf_cv_good_bcopy=no])
1565         if test "$cf_cv_good_bcopy" = yes ; then
1566                 AC_DEFINE(USE_OK_BCOPY)
1567         else
1568                 AC_DEFINE(USE_MY_MEMMOVE)
1569         fi
1570 ])])dnl
1571 dnl ---------------------------------------------------------------------------
1572 dnl CF_FUNC_NANOSLEEP version: 3 updated: 2006/12/16 12:33:30
1573 dnl -----------------
1574 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1575 dnl AIX 4.x, provide a non-working version.
1576 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1577 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1578 AC_TRY_RUN([
1579 #include <stdio.h>
1580 #include <errno.h>
1581 #include <time.h>
1582
1583 #ifdef HAVE_SYS_TIME_H
1584 #include <sys/time.h>
1585 #endif
1586
1587 int main() {
1588         struct timespec ts1, ts2;
1589         int code;
1590         ts1.tv_sec  = 0;
1591         ts1.tv_nsec = 750000000;
1592         ts2.tv_sec  = 0;
1593         ts2.tv_nsec = 0;
1594         errno = 0;
1595         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1596         ${cf_cv_main_return:-return}(code != 0);
1597 }
1598 ],
1599         [cf_cv_func_nanosleep=yes],
1600         [cf_cv_func_nanosleep=no],
1601         [cf_cv_func_nanosleep=unknown])])
1602
1603 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP)
1604 ])
1605 dnl ---------------------------------------------------------------------------
1606 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1607 dnl ---------------
1608 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1609 dnl "util" library as well.
1610 AC_DEFUN([CF_FUNC_OPENPTY],
1611 [
1612 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1613 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1614     cf_save_LIBS="$LIBS"
1615     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1616     for cf_header in pty.h libutil.h util.h
1617     do
1618     AC_TRY_LINK([
1619 #include <$cf_header>
1620 ],[
1621     int x = openpty((int *)0, (int *)0, (char *)0,
1622                    (struct termios *)0, (struct winsize *)0);
1623 ],[
1624         cf_cv_func_openpty=$cf_header
1625         break
1626 ],[
1627         cf_cv_func_openpty=no
1628 ])
1629     done
1630     LIBS="$cf_save_LIBS"
1631 ])
1632 ])dnl
1633 dnl ---------------------------------------------------------------------------
1634 dnl CF_FUNC_POLL version: 5 updated: 2012/01/25 17:55:38
1635 dnl ------------
1636 dnl See if the poll function really works.  Some platforms have poll(), but
1637 dnl it does not work for terminals or files.
1638 AC_DEFUN([CF_FUNC_POLL],[
1639 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1640 AC_TRY_RUN([
1641 #include <stdio.h>
1642 #ifdef HAVE_POLL_H
1643 #include <poll.h>
1644 #else
1645 #include <sys/poll.h>
1646 #endif
1647 int main() {
1648         struct pollfd myfds;
1649         int ret;
1650
1651         /* check for Darwin bug with respect to "devices" */
1652         myfds.fd = open("/dev/null", 1);
1653         if (myfds.fd < 0)
1654                 myfds.fd = 0;
1655         myfds.events = POLLIN;
1656         myfds.revents = 0;
1657
1658         ret = poll(&myfds, 1, 100);
1659
1660         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1661                 ret = -1;
1662         } else {
1663
1664                 /* also check with standard input */
1665                 myfds.fd = 0;
1666                 myfds.events = POLLIN;
1667                 myfds.revents = 0;
1668
1669                 ret = poll(&myfds, 1, 100);
1670                 if (ret < 0) {
1671                         ret = 0;
1672                 }
1673         }
1674         ${cf_cv_main_return:-return}(ret != 0);
1675 }],
1676         [cf_cv_working_poll=yes],
1677         [cf_cv_working_poll=no],
1678         [cf_cv_working_poll=unknown])])
1679 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL)
1680 ])dnl
1681 dnl ---------------------------------------------------------------------------
1682 dnl CF_FUNC_TERMIOS version: 2 updated: 2000/07/22 23:37:24
1683 dnl ---------------
1684 dnl Some old/broken variations define tcgetattr() only as a macro in
1685 dnl termio(s).h
1686 AC_DEFUN([CF_FUNC_TERMIOS],[
1687 AC_REQUIRE([CF_STRUCT_TERMIOS])
1688 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1689 AC_TRY_LINK([
1690 #include <sys/types.h>
1691 #ifdef HAVE_UNISTD_H
1692 #include <unistd.h>
1693 #endif
1694 #ifdef HAVE_TERMIOS_H
1695 #include <termios.h>
1696 #define TTY struct termios
1697 #else
1698 #ifdef HAVE_TERMIO_H
1699 #include <termio.h>
1700 #define TTY struct termio
1701 #endif
1702 #endif
1703 ],[
1704 TTY foo;
1705 tcgetattr(1, &foo);],
1706 [cf_cv_have_tcgetattr=yes],
1707 [cf_cv_have_tcgetattr=no])])
1708 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR)
1709 ])dnl
1710 dnl ---------------------------------------------------------------------------
1711 dnl CF_FUNC_VSSCANF version: 3 updated: 2001/12/19 00:50:10
1712 dnl ---------------
1713 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1714 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1715 dnl other functions.
1716 AC_DEFUN([CF_FUNC_VSSCANF],
1717 [
1718 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1719 AC_TRY_LINK([
1720 #include <stdarg.h>
1721 #include <stdio.h>],[
1722         va_list ap;
1723         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1724 AC_TRY_LINK([
1725 #include <stdarg.h>
1726 #include <stdio.h>],[
1727     FILE strbuf;
1728     char *str = "from";
1729
1730     strbuf._flag = _IOREAD;
1731     strbuf._ptr = strbuf._base = (unsigned char *) str;
1732     strbuf._cnt = strlen(str);
1733     strbuf._file = _NFILE;
1734     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1735 AC_TRY_LINK([
1736 #include <stdarg.h>
1737 #include <stdio.h>],[
1738     FILE strbuf;
1739     char *str = "from";
1740
1741     strbuf._flag = _IOREAD;
1742     strbuf._ptr = strbuf._base = (unsigned char *) str;
1743     strbuf._cnt = strlen(str);
1744     strbuf._file = _NFILE;
1745     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1746 cf_cv_func_vsscanf=no])])])])
1747
1748 case $cf_cv_func_vsscanf in #(vi
1749 vsscanf) AC_DEFINE(HAVE_VSSCANF);; #(vi
1750 vfscanf) AC_DEFINE(HAVE_VFSCANF);; #(vi
1751 _doscan) AC_DEFINE(HAVE__DOSCAN);;
1752 esac
1753
1754 ])dnl
1755 dnl ---------------------------------------------------------------------------
1756 dnl CF_GCC_ATTRIBUTES version: 14 updated: 2010/10/23 15:52:32
1757 dnl -----------------
1758 dnl Test for availability of useful gcc __attribute__ directives to quiet
1759 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1760 dnl to documentation, unrecognized directives cause older compilers to barf.
1761 AC_DEFUN([CF_GCC_ATTRIBUTES],
1762 [
1763 if test "$GCC" = yes
1764 then
1765 cat > conftest.i <<EOF
1766 #ifndef GCC_PRINTF
1767 #define GCC_PRINTF 0
1768 #endif
1769 #ifndef GCC_SCANF
1770 #define GCC_SCANF 0
1771 #endif
1772 #ifndef GCC_NORETURN
1773 #define GCC_NORETURN /* nothing */
1774 #endif
1775 #ifndef GCC_UNUSED
1776 #define GCC_UNUSED /* nothing */
1777 #endif
1778 EOF
1779 if test "$GCC" = yes
1780 then
1781         AC_CHECKING([for $CC __attribute__ directives])
1782 cat > conftest.$ac_ext <<EOF
1783 #line __oline__ "${as_me:-configure}"
1784 #include "confdefs.h"
1785 #include "conftest.h"
1786 #include "conftest.i"
1787 #if     GCC_PRINTF
1788 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1789 #else
1790 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1791 #endif
1792 #if     GCC_SCANF
1793 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1794 #else
1795 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1796 #endif
1797 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1798 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1799 extern void foo(void) GCC_NORETURN;
1800 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1801 EOF
1802         cf_printf_attribute=no
1803         cf_scanf_attribute=no
1804         for cf_attribute in scanf printf unused noreturn
1805         do
1806                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1807                 cf_directive="__attribute__(($cf_attribute))"
1808                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1809
1810                 case $cf_attribute in #(vi
1811                 printf) #(vi
1812                         cf_printf_attribute=yes
1813                         cat >conftest.h <<EOF
1814 #define GCC_$cf_ATTRIBUTE 1
1815 EOF
1816                         ;;
1817                 scanf) #(vi
1818                         cf_scanf_attribute=yes
1819                         cat >conftest.h <<EOF
1820 #define GCC_$cf_ATTRIBUTE 1
1821 EOF
1822                         ;;
1823                 *) #(vi
1824                         cat >conftest.h <<EOF
1825 #define GCC_$cf_ATTRIBUTE $cf_directive
1826 EOF
1827                         ;;
1828                 esac
1829
1830                 if AC_TRY_EVAL(ac_compile); then
1831                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1832                         cat conftest.h >>confdefs.h
1833                         case $cf_attribute in #(vi
1834                         printf) #(vi
1835                                 if test "$cf_printf_attribute" = no ; then
1836                                         cat >>confdefs.h <<EOF
1837 #define GCC_PRINTFLIKE(fmt,var) /* nothing */
1838 EOF
1839                                 else
1840                                         cat >>confdefs.h <<EOF
1841 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1842 EOF
1843                                 fi
1844                                 ;;
1845                         scanf) #(vi
1846                                 if test "$cf_scanf_attribute" = no ; then
1847                                         cat >>confdefs.h <<EOF
1848 #define GCC_SCANFLIKE(fmt,var) /* nothing */
1849 EOF
1850                                 else
1851                                         cat >>confdefs.h <<EOF
1852 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1853 EOF
1854                                 fi
1855                                 ;;
1856                         esac
1857                 fi
1858         done
1859 else
1860         fgrep define conftest.i >>confdefs.h
1861 fi
1862 rm -rf conftest*
1863 fi
1864 ])dnl
1865 dnl ---------------------------------------------------------------------------
1866 dnl CF_GCC_VERSION version: 5 updated: 2010/04/24 11:02:31
1867 dnl --------------
1868 dnl Find version of gcc
1869 AC_DEFUN([CF_GCC_VERSION],[
1870 AC_REQUIRE([AC_PROG_CC])
1871 GCC_VERSION=none
1872 if test "$GCC" = yes ; then
1873         AC_MSG_CHECKING(version of $CC)
1874         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1875         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1876         AC_MSG_RESULT($GCC_VERSION)
1877 fi
1878 ])dnl
1879 dnl ---------------------------------------------------------------------------
1880 dnl CF_GCC_WARNINGS version: 27 updated: 2010/10/23 15:52:32
1881 dnl ---------------
1882 dnl Check if the compiler supports useful warning options.  There's a few that
1883 dnl we don't use, simply because they're too noisy:
1884 dnl
1885 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1886 dnl     -Wredundant-decls (system headers make this too noisy)
1887 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1888 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1889 dnl             is enabled for ncurses using "--enable-const".
1890 dnl     -pedantic
1891 dnl
1892 dnl Parameter:
1893 dnl     $1 is an optional list of gcc warning flags that a particular
1894 dnl             application might want to use, e.g., "no-unused" for
1895 dnl             -Wno-unused
1896 dnl Special:
1897 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1898 dnl
1899 AC_DEFUN([CF_GCC_WARNINGS],
1900 [
1901 AC_REQUIRE([CF_GCC_VERSION])
1902 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1903
1904 cat > conftest.$ac_ext <<EOF
1905 #line __oline__ "${as_me:-configure}"
1906 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1907 EOF
1908
1909 if test "$INTEL_COMPILER" = yes
1910 then
1911 # The "-wdXXX" options suppress warnings:
1912 # remark #1419: external declaration in primary source file
1913 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1914 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1915 # remark #193: zero used for undefined preprocessing identifier
1916 # remark #593: variable "curs_sb_left_arrow" was set but never used
1917 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1918 # remark #869: parameter "tw" was never referenced
1919 # remark #981: operands are evaluated in unspecified order
1920 # warning #279: controlling expression is constant
1921
1922         AC_CHECKING([for $CC warning options])
1923         cf_save_CFLAGS="$CFLAGS"
1924         EXTRA_CFLAGS="-Wall"
1925         for cf_opt in \
1926                 wd1419 \
1927                 wd1683 \
1928                 wd1684 \
1929                 wd193 \
1930                 wd593 \
1931                 wd279 \
1932                 wd810 \
1933                 wd869 \
1934                 wd981
1935         do
1936                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1937                 if AC_TRY_EVAL(ac_compile); then
1938                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1939                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1940                 fi
1941         done
1942         CFLAGS="$cf_save_CFLAGS"
1943
1944 elif test "$GCC" = yes
1945 then
1946         AC_CHECKING([for $CC warning options])
1947         cf_save_CFLAGS="$CFLAGS"
1948         EXTRA_CFLAGS=
1949         cf_warn_CONST=""
1950         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1951         for cf_opt in W Wall \
1952                 Wbad-function-cast \
1953                 Wcast-align \
1954                 Wcast-qual \
1955                 Winline \
1956                 Wmissing-declarations \
1957                 Wmissing-prototypes \
1958                 Wnested-externs \
1959                 Wpointer-arith \
1960                 Wshadow \
1961                 Wstrict-prototypes \
1962                 Wundef $cf_warn_CONST $1
1963         do
1964                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1965                 if AC_TRY_EVAL(ac_compile); then
1966                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1967                         case $cf_opt in #(vi
1968                         Wcast-qual) #(vi
1969                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1970                                 ;;
1971                         Winline) #(vi
1972                                 case $GCC_VERSION in
1973                                 [[34]].*)
1974                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1975                                         continue;;
1976                                 esac
1977                                 ;;
1978                         esac
1979                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1980                 fi
1981         done
1982         CFLAGS="$cf_save_CFLAGS"
1983 fi
1984 rm -rf conftest*
1985
1986 AC_SUBST(EXTRA_CFLAGS)
1987 ])dnl
1988 dnl ---------------------------------------------------------------------------
1989 dnl CF_GETOPT_HEADER version: 4 updated: 2009/08/31 20:07:52
1990 dnl ----------------
1991 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1992 dnl unistd.h or (nonstandard) in getopt.h
1993 AC_DEFUN([CF_GETOPT_HEADER],
1994 [
1995 AC_HAVE_HEADERS(unistd.h getopt.h)
1996 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1997 cf_cv_getopt_header=none
1998 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1999 do
2000 AC_TRY_COMPILE([
2001 #include <$cf_header>],
2002 [int x = optind; char *y = optarg],
2003 [cf_cv_getopt_header=$cf_header
2004  break])
2005 done
2006 ])
2007 if test $cf_cv_getopt_header != none ; then
2008         AC_DEFINE(HAVE_GETOPT_HEADER)
2009 fi
2010 ])dnl
2011 dnl ---------------------------------------------------------------------------
2012 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
2013 dnl ----------------
2014 AC_DEFUN([CF_GNAT_GENERICS],
2015 [
2016 AC_REQUIRE([CF_GNAT_VERSION])
2017
2018 AC_MSG_CHECKING(if GNAT supports generics)
2019 case $cf_gnat_version in #(vi
2020 3.[[1-9]]*|[[4-9]].*) #(vi
2021         cf_gnat_generics=yes
2022         ;;
2023 *)
2024         cf_gnat_generics=no
2025         ;;
2026 esac
2027 AC_MSG_RESULT($cf_gnat_generics)
2028
2029 if test "$cf_gnat_generics" = yes
2030 then
2031         cf_compile_generics=generics
2032         cf_generic_objects="\${GENOBJS}"
2033 else
2034         cf_compile_generics=
2035         cf_generic_objects=
2036 fi
2037
2038 AC_SUBST(cf_compile_generics)
2039 AC_SUBST(cf_generic_objects)
2040 ])dnl
2041 dnl ---------------------------------------------------------------------------
2042 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
2043 dnl --------------------
2044 dnl Check if the gnat pragma "Unreferenced" works.
2045 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
2046 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
2047 CF_GNAT_TRY_LINK([procedure conftest;],
2048 [with Text_IO;
2049 with GNAT.OS_Lib;
2050 procedure conftest is
2051    test : Integer;
2052    pragma Unreferenced (test);
2053 begin
2054    test := 1;
2055    Text_IO.Put ("Hello World");
2056    Text_IO.New_Line;
2057    GNAT.OS_Lib.OS_Exit (0);
2058 end conftest;],
2059         [cf_cv_pragma_unreferenced=yes],
2060         [cf_cv_pragma_unreferenced=no])])
2061
2062 # if the pragma is supported, use it (needed in the Trace code).
2063 if test $cf_cv_pragma_unreferenced = yes ; then
2064         PRAGMA_UNREF=TRUE
2065 else
2066         PRAGMA_UNREF=FALSE
2067 fi
2068 AC_SUBST(PRAGMA_UNREF)
2069 ])dnl
2070 dnl ---------------------------------------------------------------------------
2071 dnl CF_GNAT_PROJECTS version: 2 updated: 2011/03/23 20:24:41
2072 dnl ----------------
2073 dnl GNAT projects are configured with ".gpr" project files.
2074 dnl GNAT libraries are a further development, using the project feature.
2075 AC_DEFUN([CF_GNAT_PROJECTS],
2076 [
2077 AC_REQUIRE([CF_GNAT_VERSION])
2078
2079 cf_gnat_libraries=no
2080 cf_gnat_projects=no
2081
2082 AC_MSG_CHECKING(if GNAT supports project files)
2083 case $cf_gnat_version in #(vi
2084 3.[[0-9]]*) #(vi
2085         ;;
2086 *)
2087         case $cf_cv_system_name in #(vi
2088         cygwin*) #(vi
2089                 ;;
2090         *)
2091                 mkdir conftest.src conftest.bin conftest.lib
2092                 cd conftest.src
2093                 rm -rf conftest* *~conftest*
2094                 cat >>library.gpr <<CF_EOF
2095 project Library is
2096   Kind := External ("LIB_KIND");
2097   for Library_Name use "ConfTest";
2098   for Object_Dir use ".";
2099   for Library_ALI_Dir use External("LIBRARY_DIR");
2100   for Library_Version use External ("SONAME");
2101   for Library_Kind use Kind;
2102   for Library_Dir use External("BUILD_DIR");
2103   Source_Dir := External ("SOURCE_DIR");
2104   for Source_Dirs use (Source_Dir);
2105   package Compiler is
2106      for Default_Switches ("Ada") use
2107        ("-g",
2108         "-O2",
2109         "-gnatafno",
2110         "-gnatVa",   -- All validity checks
2111         "-gnatwa");  -- Activate all optional errors
2112   end Compiler;
2113 end Library;
2114 CF_EOF
2115                 cat >>confpackage.ads <<CF_EOF
2116 package ConfPackage is
2117    procedure conftest;
2118 end ConfPackage;
2119 CF_EOF
2120                 cat >>confpackage.adb <<CF_EOF
2121 with Text_IO;
2122 package body ConfPackage is
2123    procedure conftest is
2124    begin
2125       Text_IO.Put ("Hello World");
2126       Text_IO.New_Line;
2127    end conftest;
2128 end ConfPackage;
2129 CF_EOF
2130                 if ( $cf_ada_make $ADAFLAGS \
2131                                 -Plibrary.gpr \
2132                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2133                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2134                                 -XSOURCE_DIR=`pwd` \
2135                                 -XSONAME=libConfTest.so.1 \
2136                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2137                         cf_gnat_projects=yes
2138                 fi
2139                 cd ..
2140                 if test -f conftest.lib/confpackage.ali
2141                 then
2142                         cf_gnat_libraries=yes
2143                 fi
2144                 rm -rf conftest* *~conftest*
2145                 ;;
2146         esac
2147         ;;
2148 esac
2149 AC_MSG_RESULT($cf_gnat_projects)
2150
2151 if test $cf_gnat_projects = yes
2152 then
2153         AC_MSG_CHECKING(if GNAT supports libraries)
2154         AC_MSG_RESULT($cf_gnat_libraries)
2155 fi
2156
2157 if test "$cf_gnat_projects" = yes
2158 then
2159         USE_OLD_MAKERULES="#"
2160         USE_GNAT_PROJECTS=""
2161 else
2162         USE_OLD_MAKERULES=""
2163         USE_GNAT_PROJECTS="#"
2164 fi
2165
2166 if test "$cf_gnat_libraries" = yes
2167 then
2168         USE_GNAT_LIBRARIES=""
2169 else
2170         USE_GNAT_LIBRARIES="#"
2171 fi
2172
2173 AC_SUBST(USE_OLD_MAKERULES)
2174 AC_SUBST(USE_GNAT_PROJECTS)
2175 AC_SUBST(USE_GNAT_LIBRARIES)
2176 ])dnl
2177 dnl ---------------------------------------------------------------------------
2178 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2179 dnl --------------
2180 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2181 dnl is noted that gnat may compile a tasking unit even for configurations which
2182 dnl fail at runtime.
2183 AC_DEFUN([CF_GNAT_SIGINT],[
2184 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2185 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2186
2187 package ConfTest is
2188
2189    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2190    pragma Unreserve_All_Interrupts;
2191    pragma Warnings (On);
2192
2193    protected Process is
2194       procedure Stop;
2195       function Continue return Boolean;
2196       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2197    private
2198       Done : Boolean := False;
2199    end Process;
2200
2201 end ConfTest;],
2202 [package body ConfTest is
2203    protected body Process is
2204       procedure Stop is
2205       begin
2206          Done := True;
2207       end Stop;
2208       function Continue return Boolean is
2209       begin
2210          return not Done;
2211       end Continue;
2212    end Process;
2213 end ConfTest;],
2214         [cf_cv_gnat_sigint=yes],
2215         [cf_cv_gnat_sigint=no])])
2216
2217 if test $cf_cv_gnat_sigint = yes ; then
2218         USE_GNAT_SIGINT=""
2219 else
2220         USE_GNAT_SIGINT="#"
2221 fi
2222 AC_SUBST(USE_GNAT_SIGINT)
2223 ])dnl
2224 dnl ---------------------------------------------------------------------------
2225 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2226 dnl ----------------
2227 dnl Verify that a test program compiles/links with GNAT.
2228 dnl $cf_ada_make is set to the program that compiles/links
2229 dnl $ADAFLAGS may be set to the GNAT flags.
2230 dnl
2231 dnl $1 is the text of the spec
2232 dnl $2 is the text of the body
2233 dnl $3 is the shell command to execute if successful
2234 dnl $4 is the shell command to execute if not successful
2235 AC_DEFUN([CF_GNAT_TRY_LINK],
2236 [
2237 rm -rf conftest* *~conftest*
2238 cat >>conftest.ads <<CF_EOF
2239 $1
2240 CF_EOF
2241 cat >>conftest.adb <<CF_EOF
2242 $2
2243 CF_EOF
2244 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2245 ifelse($3,,      :,[      $3])
2246 ifelse($4,,,[else
2247    $4])
2248 fi
2249 rm -rf conftest* *~conftest*
2250 ])dnl
2251 dnl ---------------------------------------------------------------------------
2252 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2253 dnl ---------------
2254 dnl Verify that a test program compiles and runs with GNAT
2255 dnl $cf_ada_make is set to the program that compiles/links
2256 dnl $ADAFLAGS may be set to the GNAT flags.
2257 dnl
2258 dnl $1 is the text of the spec
2259 dnl $2 is the text of the body
2260 dnl $3 is the shell command to execute if successful
2261 dnl $4 is the shell command to execute if not successful
2262 AC_DEFUN([CF_GNAT_TRY_RUN],
2263 [
2264 rm -rf conftest* *~conftest*
2265 cat >>conftest.ads <<CF_EOF
2266 $1
2267 CF_EOF
2268 cat >>conftest.adb <<CF_EOF
2269 $2
2270 CF_EOF
2271 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2272    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2273 ifelse($3,,      :,[      $3])
2274 ifelse($4,,,[   else
2275       $4])
2276    fi
2277 ifelse($4,,,[else
2278    $4])
2279 fi
2280 rm -rf conftest* *~conftest*
2281 ])dnl
2282 dnl ---------------------------------------------------------------------------
2283 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
2284 dnl ---------------
2285 dnl Verify version of GNAT.
2286 AC_DEFUN([CF_GNAT_VERSION],
2287 [
2288 AC_MSG_CHECKING(for gnat version)
2289 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2290         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2291     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2292 AC_MSG_RESULT($cf_gnat_version)
2293
2294 case $cf_gnat_version in #(vi
2295 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
2296         cf_cv_prog_gnat_correct=yes
2297         ;;
2298 *)
2299         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2300         cf_cv_prog_gnat_correct=no
2301         ;;
2302 esac
2303 ])
2304 dnl ---------------------------------------------------------------------------
2305 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2306 dnl -------------
2307 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2308 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2309 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2310 dnl since it is interwoven with GNU extensions.
2311 dnl
2312 dnl Well, yes we could work around it...
2313 AC_DEFUN([CF_GNU_SOURCE],
2314 [
2315 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2316 AC_TRY_COMPILE([#include <sys/types.h>],[
2317 #ifndef _XOPEN_SOURCE
2318 make an error
2319 #endif],
2320         [cf_cv_gnu_source=no],
2321         [cf_save="$CPPFLAGS"
2322          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2323          AC_TRY_COMPILE([#include <sys/types.h>],[
2324 #ifdef _XOPEN_SOURCE
2325 make an error
2326 #endif],
2327         [cf_cv_gnu_source=no],
2328         [cf_cv_gnu_source=yes])
2329         CPPFLAGS="$cf_save"
2330         ])
2331 ])
2332 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2333 ])dnl
2334 dnl ---------------------------------------------------------------------------
2335 dnl CF_GPP_LIBRARY version: 10 updated: 2010/05/29 16:31:02
2336 dnl --------------
2337 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2338 dnl problem :-).  If we have the compiler but no library, we'll be able to
2339 dnl configure, but won't be able to build the c++ demo program.
2340 AC_DEFUN([CF_GPP_LIBRARY],
2341 [
2342 cf_cxx_library=unknown
2343 case $cf_cv_system_name in #(vi
2344 os2*) #(vi
2345         cf_gpp_libname=gpp
2346         ;;
2347 *)
2348         cf_gpp_libname=g++
2349         ;;
2350 esac
2351 if test "$GXX" = yes; then
2352         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2353         cf_save="$LIBS"
2354         CF_ADD_LIB($cf_gpp_libname)
2355         AC_TRY_LINK([
2356 #include <$cf_gpp_libname/builtin.h>
2357         ],
2358         [two_arg_error_handler_t foo2 = lib_error_handler],
2359         [cf_cxx_library=yes
2360          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2361          if test "$cf_gpp_libname" = cpp ; then
2362             AC_DEFINE(HAVE_GPP_BUILTIN_H)
2363          else
2364             AC_DEFINE(HAVE_GXX_BUILTIN_H)
2365          fi],
2366         [AC_TRY_LINK([
2367 #include <builtin.h>
2368         ],
2369         [two_arg_error_handler_t foo2 = lib_error_handler],
2370         [cf_cxx_library=yes
2371          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2372          AC_DEFINE(HAVE_BUILTIN_H)],
2373         [cf_cxx_library=no])])
2374         LIBS="$cf_save"
2375         AC_MSG_RESULT($cf_cxx_library)
2376 fi
2377 ])dnl
2378 dnl ---------------------------------------------------------------------------
2379 dnl CF_GXX_VERSION version: 6 updated: 2010/10/23 15:44:18
2380 dnl --------------
2381 dnl Check for version of g++
2382 AC_DEFUN([CF_GXX_VERSION],[
2383 AC_REQUIRE([AC_PROG_CPP])
2384 GXX_VERSION=none
2385 if test "$GXX" = yes; then
2386         AC_MSG_CHECKING(version of g++)
2387         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2388         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2389         AC_MSG_RESULT($GXX_VERSION)
2390 fi
2391 ])dnl
2392 dnl ---------------------------------------------------------------------------
2393 dnl CF_GXX_WARNINGS version: 6 updated: 2010/08/14 18:25:37
2394 dnl ---------------
2395 dnl Check if the compiler supports useful warning options.
2396 dnl
2397 dnl Most of gcc's options apply to g++, except:
2398 dnl     -Wbad-function-cast
2399 dnl     -Wmissing-declarations
2400 dnl     -Wnested-externs
2401 dnl
2402 dnl Omit a few (for now):
2403 dnl     -Winline
2404 dnl
2405 dnl Parameter:
2406 dnl     $1 is an optional list of g++ warning flags that a particular
2407 dnl             application might want to use, e.g., "no-unused" for
2408 dnl             -Wno-unused
2409 dnl Special:
2410 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2411 dnl
2412 AC_DEFUN([CF_GXX_WARNINGS],
2413 [
2414
2415 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2416
2417 AC_REQUIRE([CF_GXX_VERSION])
2418
2419 AC_LANG_SAVE
2420 AC_LANG_CPLUSPLUS
2421
2422 cat > conftest.$ac_ext <<EOF
2423 #line __oline__ "configure"
2424 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2425 EOF
2426
2427 if test "$INTEL_CPLUSPLUS" = yes
2428 then
2429 # The "-wdXXX" options suppress warnings:
2430 # remark #1419: external declaration in primary source file
2431 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2432 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2433 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2434 # remark #193: zero used for undefined preprocessing identifier
2435 # remark #593: variable "curs_sb_left_arrow" was set but never used
2436 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2437 # remark #869: parameter "tw" was never referenced
2438 # remark #981: operands are evaluated in unspecified order
2439 # warning #269: invalid format string conversion
2440
2441         AC_CHECKING([for $CC warning options])
2442         cf_save_CXXFLAGS="$CXXFLAGS"
2443         EXTRA_CXXFLAGS="-Wall"
2444         for cf_opt in \
2445                 wd1419 \
2446                 wd1682 \
2447                 wd1683 \
2448                 wd1684 \
2449                 wd193 \
2450                 wd279 \
2451                 wd593 \
2452                 wd810 \
2453                 wd869 \
2454                 wd981
2455         do
2456                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2457                 if AC_TRY_EVAL(ac_compile); then
2458                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2459                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2460                 fi
2461         done
2462         CXXFLAGS="$cf_save_CXXFLAGS"
2463
2464 elif test "$GXX" = yes
2465 then
2466         AC_CHECKING([for $CXX warning options])
2467         cf_save_CXXFLAGS="$CXXFLAGS"
2468         EXTRA_CXXFLAGS="-W -Wall"
2469         cf_gxx_extra_warnings=""
2470         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2471         case "$GCC_VERSION" in
2472         [[1-2]].*)
2473                 ;;
2474         *)
2475                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2476                 ;;
2477         esac
2478         for cf_opt in \
2479                 Wabi \
2480                 fabi-version=0 \
2481                 Woverloaded-virtual \
2482                 Wsign-promo \
2483                 Wsynth \
2484                 Wold-style-cast \
2485                 Wcast-align \
2486                 Wcast-qual \
2487                 Wmissing-prototypes \
2488                 Wpointer-arith \
2489                 Wshadow \
2490                 Wstrict-prototypes \
2491                 Wundef $cf_gxx_extra_warnings $1
2492         do
2493                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2494                 if AC_TRY_EVAL(ac_compile); then
2495                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2496                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2497                 else
2498                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2499                 fi
2500         done
2501         CXXFLAGS="$cf_save_CXXFLAGS"
2502 fi
2503
2504 rm -rf conftest*
2505 AC_LANG_RESTORE
2506 AC_SUBST(EXTRA_CXXFLAGS)
2507 ])dnl
2508 dnl ---------------------------------------------------------------------------
2509 dnl CF_HASHED_DB version: 4 updated: 2010/05/29 16:31:02
2510 dnl ------------
2511 dnl Look for an instance of the Berkeley hashed database.
2512 dnl
2513 dnl $1 = optional parameter, to specify install-prefix for the database.
2514 AC_DEFUN([CF_HASHED_DB],
2515 [
2516 ifelse([$1],,,[
2517 case $1 in #(vi
2518 yes|*able*) #(vi
2519     ;;
2520 *)
2521     if test -d "$1" ; then
2522         CF_ADD_INCDIR($1/include)
2523         CF_ADD_LIBDIR($1/lib)
2524     fi
2525 esac
2526 ])
2527 AC_CHECK_HEADER(db.h,[
2528 CF_HASHED_DB_VERSION
2529 if test "$cf_cv_hashed_db_version" = unknown ; then
2530         AC_MSG_ERROR(Cannot determine version of db)
2531 else
2532         CF_HASHED_DB_LIBS
2533         if test "$cf_cv_hashed_db_libs" = unknown ; then
2534                 AC_MSG_ERROR(Cannot determine library for db)
2535         elif test "$cf_cv_hashed_db_libs" != default ; then
2536                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2537         fi
2538 fi
2539 ],[
2540         AC_MSG_ERROR(Cannot find db.h)
2541 ])
2542 ])dnl
2543 dnl ---------------------------------------------------------------------------
2544 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2545 dnl -----------------
2546 dnl Given that we have the header and version for hashed database, find the
2547 dnl library information.
2548 AC_DEFUN([CF_HASHED_DB_LIBS],
2549 [
2550 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2551 cf_cv_hashed_db_libs=unknown
2552 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2553 do
2554         cf_save_libs="$LIBS"
2555         if test -n "$cf_db_libs"; then
2556                 CF_ADD_LIB($cf_db_libs)
2557         fi
2558         CF_MSG_LOG(checking for library "$cf_db_libs")
2559         AC_TRY_LINK([
2560 $ac_includes_default
2561 #include <db.h>
2562 ],[
2563         char *path = "/tmp/foo";
2564 #ifdef DB_VERSION_MAJOR
2565 #if DB_VERSION_MAJOR >= 4
2566         DB *result = 0;
2567         db_create(&result, NULL, 0);
2568         result->open(result,
2569                 NULL,
2570                 path,
2571                 path,
2572                 DB_HASH,
2573                 DB_CREATE,
2574                 0644);
2575 #elif DB_VERSION_MAJOR >= 3
2576         DB *result = 0;
2577         db_create(&result, NULL, 0);
2578         result->open(result,
2579                 path,
2580                 path,
2581                 DB_HASH,
2582                 DB_CREATE,
2583                 0644);
2584 #elif DB_VERSION_MAJOR >= 2
2585         DB *result = 0;
2586         db_open(path,
2587                 DB_HASH,
2588                 DB_CREATE,
2589                 0644,
2590                 (DB_ENV *) 0,
2591                 (DB_INFO *) 0,
2592                 &result);
2593 #endif /* DB_VERSION_MAJOR */
2594 #else
2595         DB *result = dbopen(path,
2596                      2,
2597                      0644,
2598                      DB_HASH,
2599                      0);
2600 #endif
2601         ${cf_cv_main_return:-return}(result != 0)
2602 ],[
2603         if test -n "$cf_db_libs" ; then
2604                 cf_cv_hashed_db_libs=$cf_db_libs
2605         else
2606                 cf_cv_hashed_db_libs=default
2607         fi
2608         LIBS="$cf_save_libs"
2609         break
2610 ])
2611         LIBS="$cf_save_libs"
2612 done
2613 ])
2614 ])dnl
2615 dnl ---------------------------------------------------------------------------
2616 dnl CF_HASHED_DB_VERSION version: 3 updated: 2007/12/01 15:01:37
2617 dnl --------------------
2618 dnl Given that we have the header file for hashed database, find the version
2619 dnl information.
2620 AC_DEFUN([CF_HASHED_DB_VERSION],
2621 [
2622 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2623 cf_cv_hashed_db_version=unknown
2624
2625 for cf_db_version in 1 2 3 4 5
2626 do
2627         CF_MSG_LOG(checking for db version $cf_db_version)
2628         AC_TRY_COMPILE([
2629 $ac_includes_default
2630 #include <db.h>
2631
2632 #ifdef DB_VERSION_MAJOR
2633         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2634 #if $cf_db_version == DB_VERSION_MAJOR
2635         /* ok */
2636 #else
2637         make an error
2638 #endif
2639 #else
2640 #if $cf_db_version == 1
2641         /* ok: assuming this is DB 1.8.5 */
2642 #else
2643         make an error
2644 #endif
2645 #endif
2646 ],[DBT *foo = 0],[
2647         cf_cv_hashed_db_version=$cf_db_version
2648         break
2649         ])
2650 done
2651 ])
2652 ])dnl
2653 dnl ---------------------------------------------------------------------------
2654 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2655 dnl --------------
2656 dnl Construct a search-list of directories for a nonstandard header-file
2657 dnl
2658 dnl Parameters
2659 dnl     $1 = the variable to return as result
2660 dnl     $2 = the package name
2661 AC_DEFUN([CF_HEADER_PATH],
2662 [
2663 $1=
2664
2665 # collect the current set of include-directories from compiler flags
2666 cf_header_path_list=""
2667 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2668         for cf_header_path in $CPPFLAGS $CFLAGS
2669         do
2670                 case $cf_header_path in #(vi
2671                 -I*)
2672                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2673                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2674                         cf_header_path_list="$cf_header_path_list [$]$1"
2675                         ;;
2676                 esac
2677         done
2678 fi
2679
2680 # add the variations for the package we are looking for
2681 CF_SUBDIR_PATH($1,$2,include)
2682
2683 test "$includedir" != NONE && \
2684 test "$includedir" != "/usr/include" && \
2685 test -d "$includedir" && {
2686         test -d $includedir &&    $1="[$]$1 $includedir"
2687         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2688 }
2689
2690 test "$oldincludedir" != NONE && \
2691 test "$oldincludedir" != "/usr/include" && \
2692 test -d "$oldincludedir" && {
2693         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2694         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2695 }
2696
2697 $1="[$]$1 $cf_header_path_list"
2698 ])dnl
2699 dnl ---------------------------------------------------------------------------
2700 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2701 dnl ---------------
2702 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2703 AC_DEFUN([CF_HELP_MESSAGE],
2704 [AC_DIVERT_HELP([$1])dnl
2705 ])dnl
2706 dnl ---------------------------------------------------------------------------
2707 dnl CF_INCLUDE_DIRS version: 6 updated: 2009/01/06 19:37:40
2708 dnl ---------------
2709 dnl Construct the list of include-options according to whether we're building
2710 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2711 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2712 dnl since that usually breaks gcc's shadow-includes.
2713 AC_DEFUN([CF_INCLUDE_DIRS],
2714 [
2715 CPPFLAGS="$CPPFLAGS -I. -I../include"
2716 if test "$srcdir" != "."; then
2717         CPPFLAGS="$CPPFLAGS -I\${srcdir}/../include"
2718 fi
2719 if test "$GCC" != yes; then
2720         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2721 elif test "$includedir" != "/usr/include"; then
2722         if test "$includedir" = '${prefix}/include' ; then
2723                 if test $prefix != /usr ; then
2724                         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2725                 fi
2726         else
2727                 CPPFLAGS="$CPPFLAGS -I\${includedir}"
2728         fi
2729 fi
2730 AC_SUBST(CPPFLAGS)
2731 ])dnl
2732 dnl ---------------------------------------------------------------------------
2733 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
2734 dnl -----------------
2735 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2736 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2737 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2738 dnl
2739 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2740 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2741 dnl the wrappers for gcc and g++ warnings.
2742 dnl
2743 dnl $1 = GCC (default) or GXX
2744 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2745 dnl $3 = CFLAGS (default) or CXXFLAGS
2746 AC_DEFUN([CF_INTEL_COMPILER],[
2747 ifelse([$2],,INTEL_COMPILER,[$2])=no
2748
2749 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2750         case $host_os in
2751         linux*|gnu*)
2752                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2753                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2754                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2755                 AC_TRY_COMPILE([],[
2756 #ifdef __INTEL_COMPILER
2757 #else
2758 make an error
2759 #endif
2760 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2761 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
2762 ],[])
2763                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2764                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2765                 ;;
2766         esac
2767 fi
2768 ])dnl
2769 dnl ---------------------------------------------------------------------------
2770 dnl CF_ISASCII version: 3 updated: 2000/08/12 23:18:52
2771 dnl ----------
2772 dnl Check if we have either a function or macro for 'isascii()'.
2773 AC_DEFUN([CF_ISASCII],
2774 [
2775 AC_MSG_CHECKING(for isascii)
2776 AC_CACHE_VAL(cf_cv_have_isascii,[
2777         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2778         [cf_cv_have_isascii=yes],
2779         [cf_cv_have_isascii=no])
2780 ])dnl
2781 AC_MSG_RESULT($cf_cv_have_isascii)
2782 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII)
2783 ])dnl
2784 dnl ---------------------------------------------------------------------------
2785 dnl CF_LARGEFILE version: 7 updated: 2007/06/02 11:58:50
2786 dnl ------------
2787 dnl Add checks for large file support.
2788 AC_DEFUN([CF_LARGEFILE],[
2789 ifdef([AC_FUNC_FSEEKO],[
2790     AC_SYS_LARGEFILE
2791     if test "$enable_largefile" != no ; then
2792         AC_FUNC_FSEEKO
2793
2794         # Normally we would collect these definitions in the config.h,
2795         # but (like _XOPEN_SOURCE), some environments rely on having these
2796         # defined before any of the system headers are included.  Another
2797         # case comes up with C++, e.g., on AIX the compiler compiles the
2798         # header files by themselves before looking at the body files it is
2799         # told to compile.  For ncurses, those header files do not include
2800         # the config.h
2801         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2802         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2803         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2804
2805         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2806                 AC_TRY_COMPILE([
2807 #include <sys/types.h>
2808 #include <dirent.h>
2809                 ],[
2810                 /* if transitional largefile support is setup, this is true */
2811                 extern struct dirent64 * readdir(DIR *);
2812                 struct dirent64 *x = readdir((DIR *)0);
2813                 struct dirent *y = readdir((DIR *)0);
2814                 int z = x - y;
2815                 ],
2816                 [cf_cv_struct_dirent64=yes],
2817                 [cf_cv_struct_dirent64=no])
2818         ])
2819         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64)
2820     fi
2821 ])
2822 ])
2823 dnl ---------------------------------------------------------------------------
2824 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2825 dnl -----------------
2826 dnl Check for compiler/linker flags used to temporarily force usage of static
2827 dnl libraries.  This depends on the compiler and platform.  Use this to help
2828 dnl ensure that the linker picks up a given library based on its position in
2829 dnl the list of linker options and libraries.
2830 AC_DEFUN([CF_LDFLAGS_STATIC],[
2831
2832 if test "$GCC" = yes ; then
2833         case $cf_cv_system_name in #(
2834         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2835                 LDFLAGS_STATIC=
2836                 LDFLAGS_SHARED=
2837                 ;;
2838     *)  #( normally, except when broken
2839         LDFLAGS_STATIC=-static
2840         LDFLAGS_SHARED=-dynamic
2841         ;;
2842     esac
2843 else
2844         case $cf_cv_system_name in #(
2845         aix[[4-7]]*)    #( from ld manpage
2846                 LDFLAGS_STATIC=-bstatic
2847                 LDFLAGS_SHARED=-bdynamic
2848                 ;;
2849         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2850                 # We could also use just "archive" and "shared".
2851                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2852                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2853                 ;;
2854         irix*)          #( from ld manpage IRIX64
2855                 LDFLAGS_STATIC=-Bstatic
2856                 LDFLAGS_SHARED=-Bdynamic
2857                 ;;
2858         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2859                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2860                 LDFLAGS_STATIC=-noso
2861                 LDFLAGS_SHARED=-so_archive
2862                 ;;
2863         solaris2*)
2864                 LDFLAGS_STATIC=-Bstatic
2865                 LDFLAGS_SHARED=-Bdynamic
2866                 ;;
2867         esac
2868 fi
2869
2870 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
2871 then
2872         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
2873
2874         rm -f libconftest.a
2875         cat >conftest.$ac_ext <<EOF
2876 #line __oline__ "configure"
2877 #include <stdio.h>
2878 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
2879 EOF
2880         if AC_TRY_EVAL(ac_compile) ; then
2881                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
2882                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
2883         fi
2884         rm -f conftest.*
2885
2886         cf_save_LIBS="$LIBS"
2887
2888         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
2889         AC_TRY_LINK([
2890 #line __oline__ "configure"
2891 #include <stdio.h>
2892 int cf_ldflags_static(FILE *fp);
2893 ],[
2894         return cf_ldflags_static(stdin);
2895 ],[
2896         # some linkers simply ignore the -dynamic
2897         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
2898         *static*) # (vi
2899                 cf_ldflags_static=no
2900                 ;;
2901         *)
2902                 cf_ldflags_static=yes
2903                 ;;
2904         esac
2905 ],[cf_ldflags_static=no])
2906
2907         rm -f libconftest.*
2908         LIBS="$cf_save_LIBS"
2909
2910         AC_MSG_RESULT($cf_ldflags_static)
2911
2912         if test $cf_ldflags_static != yes
2913         then
2914                 LDFLAGS_STATIC=
2915                 LDFLAGS_SHARED=
2916         fi
2917 else
2918         LDFLAGS_STATIC=
2919         LDFLAGS_SHARED=
2920 fi
2921
2922 AC_SUBST(LDFLAGS_STATIC)
2923 AC_SUBST(LDFLAGS_SHARED)
2924 ])
2925 dnl ---------------------------------------------------------------------------
2926 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
2927 dnl ---------------
2928 dnl For the given system and compiler, find the compiler flags to pass to the
2929 dnl loader to use the "rpath" feature.
2930 AC_DEFUN([CF_LD_RPATH_OPT],
2931 [
2932 AC_REQUIRE([CF_CHECK_CACHE])
2933
2934 LD_RPATH_OPT=
2935 AC_MSG_CHECKING(for an rpath option)
2936 case $cf_cv_system_name in #(vi
2937 irix*) #(vi
2938         if test "$GCC" = yes; then
2939                 LD_RPATH_OPT="-Wl,-rpath,"
2940         else
2941                 LD_RPATH_OPT="-rpath "
2942         fi
2943         ;;
2944 linux*|gnu*|k*bsd*-gnu) #(vi
2945         LD_RPATH_OPT="-Wl,-rpath,"
2946         ;;
2947 openbsd[[2-9]].*|mirbsd*) #(vi
2948         LD_RPATH_OPT="-Wl,-rpath,"
2949         ;;
2950 dragonfly*|freebsd*) #(vi
2951         LD_RPATH_OPT="-rpath "
2952         ;;
2953 netbsd*) #(vi
2954         LD_RPATH_OPT="-Wl,-rpath,"
2955         ;;
2956 osf*|mls+*) #(vi
2957         LD_RPATH_OPT="-rpath "
2958         ;;
2959 solaris2*) #(vi
2960         LD_RPATH_OPT="-R"
2961         ;;
2962 *)
2963         ;;
2964 esac
2965 AC_MSG_RESULT($LD_RPATH_OPT)
2966
2967 case "x$LD_RPATH_OPT" in #(vi
2968 x-R*)
2969         AC_MSG_CHECKING(if we need a space after rpath option)
2970         cf_save_LIBS="$LIBS"
2971         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2972         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2973         LIBS="$cf_save_LIBS"
2974         AC_MSG_RESULT($cf_rpath_space)
2975         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2976         ;;
2977 esac
2978 ])dnl
2979 dnl ---------------------------------------------------------------------------
2980 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
2981 dnl ---------------
2982 dnl Construct a search-list of directories for a nonstandard library-file
2983 dnl
2984 dnl Parameters
2985 dnl     $1 = the variable to return as result
2986 dnl     $2 = the package name
2987 AC_DEFUN([CF_LIBRARY_PATH],
2988 [
2989 $1=
2990 cf_library_path_list=""
2991 if test -n "${LDFLAGS}${LIBS}" ; then
2992         for cf_library_path in $LDFLAGS $LIBS
2993         do
2994                 case $cf_library_path in #(vi
2995                 -L*)
2996                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2997                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2998                         cf_library_path_list="$cf_library_path_list [$]$1"
2999                         ;;
3000                 esac
3001         done
3002 fi
3003
3004 CF_SUBDIR_PATH($1,$2,lib)
3005
3006 $1="$cf_library_path_list [$]$1"
3007 ])dnl
3008 dnl ---------------------------------------------------------------------------
3009 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
3010 dnl -------------
3011 dnl Compute the library-prefix for the given host system
3012 dnl $1 = variable to set
3013 define([CF_LIB_PREFIX],
3014 [
3015         case $cf_cv_system_name in #(vi
3016         OS/2*|os2*) #(vi
3017         LIB_PREFIX=''
3018         ;;
3019         *)      LIB_PREFIX='lib'
3020         ;;
3021         esac
3022 ifelse($1,,,[$1=$LIB_PREFIX])
3023         AC_SUBST(LIB_PREFIX)
3024 ])dnl
3025 dnl ---------------------------------------------------------------------------
3026 dnl CF_LIB_RULES version: 64 updated: 2012/02/25 15:20:07
3027 dnl ------------
3028 dnl Append definitions and rules for the given models to the subdirectory
3029 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3030 dnl subdirectory is a library-source directory, modify the LIBS_TO_MAKE list in
3031 dnl the corresponding makefile to list the models that we'll generate.
3032 dnl
3033 dnl For shared libraries, make a list of symbolic links to construct when
3034 dnl generating each library.  The convention used for Linux is the simplest
3035 dnl one:
3036 dnl     lib<name>.so    ->
3037 dnl     lib<name>.so.<major>    ->
3038 dnl     lib<name>.so.<maj>.<minor>
3039 AC_DEFUN([CF_LIB_RULES],
3040 [
3041 cf_prefix=$LIB_PREFIX
3042 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3043
3044 case $cf_cv_shlib_version in #(vi
3045 cygdll|mingw)
3046         TINFO_NAME=$TINFO_ARG_SUFFIX
3047         TINFO_SUFFIX=.dll
3048         ;;
3049 esac
3050
3051 if test -n "$TINFO_SUFFIX" ; then
3052         case $TINFO_SUFFIX in
3053         tw*)
3054                 TINFO_NAME="${TINFO_NAME}tw"
3055                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
3056                 ;;
3057         t*)
3058                 TINFO_NAME="${TINFO_NAME}t"
3059                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3060                 ;;
3061         w*)
3062                 TINFO_NAME="${TINFO_NAME}w"
3063                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3064                 ;;
3065         esac
3066 fi
3067
3068 for cf_dir in $SRC_SUBDIRS
3069 do
3070         if test ! -d $srcdir/$cf_dir ; then
3071                 continue
3072         elif test -f $srcdir/$cf_dir/modules; then
3073
3074                 SHARED_LIB=
3075                 LIBS_TO_MAKE=
3076                 for cf_item in $cf_LIST_MODELS
3077                 do
3078                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3079                         if test $cf_item = shared ; then
3080                         if test "$cf_cv_do_symlinks" = yes ; then
3081                                 case "$cf_cv_shlib_version" in #(vi
3082                                 rel) #(vi
3083                                         case "$cf_cv_system_name" in #(vi
3084                                         darwin*)
3085                                         case .${LIB_SUFFIX} in
3086                                         .tw*)
3087                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3088                                                 cf_suffix=tw'.${REL_VERSION}'"$cf_suffix"
3089                                                 ;;
3090                                         .t*)
3091                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3092                                                 cf_suffix=t'.${REL_VERSION}'"$cf_suffix"
3093                                                 ;;
3094                                         .w*)
3095                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3096                                                 cf_suffix=w'.${REL_VERSION}'"$cf_suffix"
3097                                                 ;;
3098                                         *)
3099                                                 cf_suffix='.${REL_VERSION}'"$cf_suffix"
3100                                                 ;;
3101                                         esac
3102                                         ;; #(vi
3103                                         *) cf_suffix="$cf_suffix"'.${REL_VERSION}' ;;
3104                                         esac
3105                                         ;;
3106                                 abi)
3107                                         case "$cf_cv_system_name" in #(vi
3108                                         darwin*)
3109                                         case .${LIB_SUFFIX} in
3110                                         .tw*)
3111                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3112                                                 cf_suffix=tw'.${ABI_VERSION}'"$cf_suffix"
3113                                                 ;;
3114                                         .t*)
3115                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3116                                                 cf_suffix=t'.${ABI_VERSION}'"$cf_suffix"
3117                                                 ;;
3118                                         .w*)
3119                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3120                                                 cf_suffix=w'.${ABI_VERSION}'"$cf_suffix"
3121                                                 ;;
3122                                         *)
3123                                                 cf_suffix='.${ABI_VERSION}'"$cf_suffix"
3124                                                 ;;
3125                                         esac
3126                                         ;; #(vi
3127                                         *) cf_suffix="$cf_suffix"'.${ABI_VERSION}' ;;
3128                                         esac
3129                                         ;;
3130                                 esac
3131                         fi
3132                         # cygwin needs import library, and has unique naming convention
3133                         # use autodetected ${cf_prefix} for import lib and static lib, but
3134                         # use 'cyg' prefix for shared lib.
3135                         case $cf_cv_shlib_version in #(vi
3136                         cygdll) #(vi
3137                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3138                                 LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/cyg${cf_dir}${cf_cygsuf}"
3139                                 continue
3140                                 ;;
3141                         mingw)
3142                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3143                                 LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/lib${cf_dir}${cf_cygsuf}"
3144                                 continue
3145                                 ;;
3146                         esac
3147                         fi
3148                         LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/${cf_prefix}${cf_dir}${cf_suffix}"
3149                 done
3150
3151                 if test $cf_dir = ncurses ; then
3152                         cf_subsets="$LIB_SUBSETS"
3153                         cf_r_parts="$cf_subsets"
3154                         cf_liblist="$LIBS_TO_MAKE"
3155
3156                         while test -n "$cf_r_parts"
3157                         do
3158                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3159                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3160                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3161                                         cf_item=
3162                                         case $cf_l_parts in #(vi
3163                                         *termlib*) #(vi
3164                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3165                                                 ;;
3166                                         *ticlib*)
3167                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3168                                                 ;;
3169                                         *)
3170                                                 break
3171                                                 ;;
3172                                         esac
3173                                         if test -n "$cf_item"; then
3174                                                 LIBS_TO_MAKE="$cf_item $LIBS_TO_MAKE"
3175                                         fi
3176                                 else
3177                                         break
3178                                 fi
3179                         done
3180                 else
3181                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3182                 fi
3183
3184                 sed -e "s%@LIBS_TO_MAKE@%$LIBS_TO_MAKE%" \
3185                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3186                         $cf_dir/Makefile >$cf_dir/Makefile.out
3187                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3188
3189                 $AWK -f $srcdir/mk-0th.awk \
3190                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" \
3191                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3192
3193                 for cf_subset in $cf_subsets
3194                 do
3195                         cf_subdirs=
3196                         for cf_item in $cf_LIST_MODELS
3197                         do
3198                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3199                         CF_UPPER(cf_ITEM,$cf_item)
3200                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3201                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3202
3203                         # Test for case where we build libtinfo with a different name.
3204                         cf_libname=$cf_dir
3205                         if test $cf_dir = ncurses ; then
3206                                 case $cf_subset in
3207                                 *base*)
3208                                         cf_libname=${cf_libname}$LIB_SUFFIX
3209                                         ;;
3210                                 *termlib*)
3211                                         cf_libname=$TINFO_LIB_SUFFIX
3212                                         ;;
3213                                 ticlib*)
3214                                         cf_libname=$TICS_LIB_SUFFIX
3215                                         ;;
3216                                 esac
3217                         else
3218                                 cf_libname=${cf_libname}$LIB_SUFFIX
3219                         fi
3220                         if test -n "${DFT_ARG_SUFFIX}" ; then
3221                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3222                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3223                         fi
3224
3225                         # These dependencies really are for development, not
3226                         # builds, but they are useful in porting, too.
3227                         cf_depend="../include/ncurses_cfg.h"
3228                         if test "$srcdir" = "."; then
3229                                 cf_reldir="."
3230                         else
3231                                 cf_reldir="\${srcdir}"
3232                         fi
3233
3234                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3235                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3236                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3237                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3238                         fi
3239
3240                         cf_dir_suffix=
3241                         old_cf_suffix="$cf_suffix"
3242                         if test "$cf_cv_shlib_version_infix" = yes ; then
3243                         if test -n "$LIB_SUFFIX" ; then
3244                                 case $LIB_SUFFIX in
3245                                 tw*)
3246                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3247                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3248                                         cf_dir_suffix=tw
3249                                         ;;
3250                                 t*)
3251                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3252                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3253                                         cf_dir_suffix=t
3254                                         ;;
3255                                 w*)
3256                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3257                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3258                                         cf_dir_suffix=w
3259                                         ;;
3260                                 esac
3261                         fi
3262                         fi
3263
3264                         $AWK -f $srcdir/mk-1st.awk \
3265                                 name=${cf_libname}${cf_dir_suffix} \
3266                                 traces=$LIB_TRACING \
3267                                 MODEL=$cf_ITEM \
3268                                 model=$cf_subdir \
3269                                 prefix=$cf_prefix \
3270                                 suffix=$cf_suffix \
3271                                 subset=$cf_subset \
3272                                 driver=$cf_cv_term_driver \
3273                                 SymLink="$LN_S" \
3274                                 TermlibRoot=$TINFO_NAME \
3275                                 TermlibSuffix=$TINFO_SUFFIX \
3276                                 ShlibVer=$cf_cv_shlib_version \
3277                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3278                                 ReLink=${cf_cv_do_relink:-no} \
3279                                 DoLinks=$cf_cv_do_symlinks \
3280                                 rmSoLocs=$cf_cv_rm_so_locs \
3281                                 ldconfig="$LDCONFIG" \
3282                                 overwrite=$WITH_OVERWRITE \
3283                                 depend="$cf_depend" \
3284                                 host="$host" \
3285                                 libtool_version="$LIBTOOL_VERSION" \
3286                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3287
3288                         cf_suffix="$old_cf_suffix"
3289
3290                         for cf_subdir2 in $cf_subdirs lib
3291                         do
3292                                 test $cf_subdir = $cf_subdir2 && break
3293                         done
3294                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3295                         $AWK -f $srcdir/mk-2nd.awk \
3296                                 name=$cf_dir \
3297                                 traces=$LIB_TRACING \
3298                                 MODEL=$cf_ITEM \
3299                                 model=$cf_subdir \
3300                                 subset=$cf_subset \
3301                                 srcdir=$srcdir \
3302                                 echo=$WITH_ECHO \
3303                                 crenames=$cf_cv_prog_CC_c_o \
3304                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3305                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3306                         cf_subdirs="$cf_subdirs $cf_subdir"
3307                         done
3308                 done
3309         fi
3310
3311         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >>Makefile
3312 done
3313
3314 for cf_dir in $SRC_SUBDIRS
3315 do
3316         if test ! -d $srcdir/$cf_dir ; then
3317                 continue
3318         fi
3319
3320         if test -f $cf_dir/Makefile ; then
3321                 case "$cf_dir" in
3322                 Ada95) #(vi
3323                         echo 'libs \' >> Makefile
3324                         echo 'install.libs \' >> Makefile
3325                         echo 'uninstall.libs ::' >> Makefile
3326                         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >> Makefile
3327                         ;;
3328                 esac
3329         fi
3330
3331         if test -f $srcdir/$cf_dir/modules; then
3332                 echo >> Makefile
3333                 if test -f $srcdir/$cf_dir/headers; then
3334 cat >> Makefile <<CF_EOF
3335 install.includes \\
3336 uninstall.includes \\
3337 CF_EOF
3338                 fi
3339 if test "$cf_dir" != "c++" ; then
3340 echo 'lint \' >> Makefile
3341 fi
3342 cat >> Makefile <<CF_EOF
3343 libs \\
3344 lintlib \\
3345 install.libs \\
3346 uninstall.libs \\
3347 install.$cf_dir \\
3348 uninstall.$cf_dir ::
3349         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3350 CF_EOF
3351         elif test -f $srcdir/$cf_dir/headers; then
3352 cat >> Makefile <<CF_EOF
3353
3354 libs \\
3355 install.libs \\
3356 uninstall.libs \\
3357 install.includes \\
3358 uninstall.includes ::
3359         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3360 CF_EOF
3361 fi
3362 done
3363
3364 cat >> Makefile <<CF_EOF
3365
3366 install.libs uninstall.libs \\
3367 install.data uninstall.data ::
3368 $MAKE_TERMINFO  cd misc && \${MAKE} \${CF_MFLAGS} \[$]@
3369 CF_EOF
3370
3371 if test "x$cf_with_manpages" = xyes; then
3372 cat >> Makefile <<CF_EOF
3373
3374 install.man \\
3375 uninstall.man ::
3376         cd man && \${MAKE} \${CF_MFLAGS} \[$]@
3377 CF_EOF
3378 fi
3379
3380 cat >> Makefile <<CF_EOF
3381
3382 distclean ::
3383         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3384         rm -f headers.sh headers.sed mk_shared_lib.sh
3385         rm -f edit_man.* man_alias.*
3386         rm -rf \${DIRS_TO_MAKE}
3387 CF_EOF
3388
3389 # Special case: tack's manpage lives in its own directory.
3390 if test "x$cf_with_manpages" = xyes; then
3391 if test -d tack ; then
3392 if test -f $srcdir/$tack.h; then
3393 cat >> Makefile <<CF_EOF
3394
3395 install.man \\
3396 uninstall.man ::
3397         cd tack && \${MAKE} \${CF_MFLAGS} \[$]@
3398 CF_EOF
3399 fi
3400 fi
3401 fi
3402
3403 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3404 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3405 dnl anything, and will make it more standardized.  It's awkward to decide this
3406 dnl at configuration because of quoting, so we'll simply make all headers
3407 dnl installed via a script that can do the right thing.
3408
3409 rm -f headers.sed headers.sh
3410
3411 dnl ( generating this script makes the makefiles a little tidier :-)
3412 echo creating headers.sh
3413 cat >headers.sh <<CF_EOF
3414 #! /bin/sh
3415 # This shell script is generated by the 'configure' script.  It is invoked in a
3416 # subdirectory of the build tree.  It generates a sed-script in the parent
3417 # directory that is used to adjust includes for header files that reside in a
3418 # subdirectory of /usr/include, etc.
3419 PRG=""
3420 while test \[$]# != 3
3421 do
3422 PRG="\$PRG \[$]1"; shift
3423 done
3424 DST=\[$]1
3425 REF=\[$]2
3426 SRC=\[$]3
3427 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3428 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3429 echo installing \$SRC in \$DST
3430 CF_EOF
3431
3432 if test $WITH_CURSES_H = yes; then
3433         cat >>headers.sh <<CF_EOF
3434 case \$DST in
3435 /*/include/*)
3436         END=\`basename \$DST\`
3437         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3438         do
3439                 NAME=\`basename \$i\`
3440                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3441         done
3442         ;;
3443 *)
3444         echo "" >> \$TMPSED
3445         ;;
3446 esac
3447 CF_EOF
3448
3449 else
3450         cat >>headers.sh <<CF_EOF
3451 case \$DST in
3452 /*/include/*)
3453         END=\`basename \$DST\`
3454         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3455         do
3456                 NAME=\`basename \$i\`
3457                 if test "\$NAME" = "curses.h"
3458                 then
3459                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3460                         NAME=ncurses.h
3461                 fi
3462                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3463         done
3464         ;;
3465 *)
3466         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3467         ;;
3468 esac
3469 CF_EOF
3470 fi
3471 cat >>headers.sh <<CF_EOF
3472 rm -f \$TMPSRC
3473 sed -f \$TMPSED \$SRC > \$TMPSRC
3474 NAME=\`basename \$SRC\`
3475 CF_EOF
3476 if test $WITH_CURSES_H != yes; then
3477         cat >>headers.sh <<CF_EOF
3478 test "\$NAME" = "curses.h" && NAME=ncurses.h
3479 CF_EOF
3480 fi
3481 cat >>headers.sh <<CF_EOF
3482 # Just in case someone gzip'd manpages, remove the conflicting copy.
3483 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3484
3485 eval \$PRG \$TMPSRC \$DST/\$NAME
3486 rm -f \$TMPSRC \$TMPSED
3487 CF_EOF
3488
3489 chmod 0755 headers.sh
3490
3491 for cf_dir in $SRC_SUBDIRS
3492 do
3493         if test ! -d $srcdir/$cf_dir ; then
3494                 continue
3495         fi
3496
3497         if test -f $srcdir/$cf_dir/headers; then
3498                 $AWK -f $srcdir/mk-hdr.awk \
3499                         subset="$LIB_SUBSETS" \
3500                         compat="$WITH_CURSES_H" \
3501                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3502         fi
3503
3504         if test -f $srcdir/$cf_dir/modules; then
3505                 if test "$cf_dir" != "c++" ; then
3506                         cat >>$cf_dir/Makefile <<"CF_EOF"
3507 depend : ${AUTO_SRC}
3508         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3509
3510 # DO NOT DELETE THIS LINE -- make depend depends on it.
3511 CF_EOF
3512                 fi
3513         fi
3514 done
3515 AC_SUBST(LIBS_TO_MAKE)
3516 ])dnl
3517 dnl ---------------------------------------------------------------------------
3518 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3519 dnl -------------
3520 dnl Find the and soname for the given shared library.  Set the cache variable
3521 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3522 dnl variable to "unknown".
3523 dnl
3524 dnl $1 = headers
3525 dnl $2 = code
3526 dnl $3 = library name
3527 AC_DEFUN([CF_LIB_SONAME],
3528 [
3529 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3530
3531 cf_cv_$3_soname=unknown
3532 if test "$cross_compiling" != yes ; then
3533 cat >conftest.$ac_ext <<CF_EOF
3534 $1
3535 int main()
3536 {
3537 $2
3538         ${cf_cv_main_return:-return}(0);
3539 }
3540 CF_EOF
3541 cf_save_LIBS="$LIBS"
3542         CF_ADD_LIB($3)
3543         if AC_TRY_EVAL(ac_compile) ; then
3544                 if AC_TRY_EVAL(ac_link) ; then
3545                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3546                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3547                 fi
3548         fi
3549 rm -rf conftest*
3550 LIBS="$cf_save_LIBS"
3551 fi
3552 ])
3553 ])
3554 dnl ---------------------------------------------------------------------------
3555 dnl CF_LIB_SUFFIX version: 18 updated: 2012/02/25 15:20:07
3556 dnl -------------
3557 dnl Compute the library file-suffix from the given model name
3558 dnl $1 = model name
3559 dnl $2 = variable to set (the nominal library suffix)
3560 dnl $3 = dependency variable to set (actual filename)
3561 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3562 AC_DEFUN([CF_LIB_SUFFIX],
3563 [
3564         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3565         case $1 in #(vi
3566         libtool) #(vi
3567                 $2='.la'
3568                 $3=[$]$2
3569                 ;;
3570         normal) #(vi
3571                 $2='.a'
3572                 $3=[$]$2
3573                 ;;
3574         debug) #(vi
3575                 $2='_g.a'
3576                 $3=[$]$2
3577                 ;;
3578         profile) #(vi
3579                 $2='_p.a'
3580                 $3=[$]$2
3581                 ;;
3582         shared) #(vi
3583                 case $cf_cv_system_name in
3584                 aix[[5-7]]*) #(vi
3585                         $2='.a'
3586                         $3=[$]$2
3587                         ;;
3588                 cygwin*|mingw*) #(vi
3589                         $2='.dll'
3590                         $3='.dll.a'
3591                         ;;
3592                 darwin*) #(vi
3593                         $2='.dylib'
3594                         $3=[$]$2
3595                         ;;
3596                 hpux*) #(vi
3597                         case $target in
3598                         ia64*) #(vi
3599                                 $2='.so'
3600                                 $3=[$]$2
3601                                 ;;
3602                         *) #(vi
3603                                 $2='.sl'
3604                                 $3=[$]$2
3605                                 ;;
3606                         esac
3607                         ;;
3608                 *)      $2='.so'
3609                         $3=[$]$2
3610                         ;;
3611                 esac
3612         esac
3613         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3614         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3615 ])dnl
3616 dnl ---------------------------------------------------------------------------
3617 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3618 dnl -----------
3619 dnl Compute the string to append to -library from the given model name
3620 dnl $1 = model name
3621 dnl $2 = variable to set
3622 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3623 AC_DEFUN([CF_LIB_TYPE],
3624 [
3625         case $1 in
3626         libtool) $2=''   ;;
3627         normal)  $2=''   ;;
3628         debug)   $2='_g' ;;
3629         profile) $2='_p' ;;
3630         shared)  $2=''   ;;
3631         esac
3632         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3633 ])dnl
3634 dnl ---------------------------------------------------------------------------
3635 dnl CF_LINK_DATAONLY version: 9 updated: 2009/01/01 20:21:38
3636 dnl ----------------
3637 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3638 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3639 dnl have to provide wrappers for global tables to ensure they're linked
3640 dnl properly.
3641 AC_DEFUN([CF_LINK_DATAONLY],
3642 [
3643 AC_MSG_CHECKING([if data-only library module links])
3644 AC_CACHE_VAL(cf_cv_link_dataonly,[
3645         rm -f conftest.a
3646         cat >conftest.$ac_ext <<EOF
3647 #line __oline__ "configure"
3648 int     testdata[[3]] = { 123, 456, 789 };
3649 EOF
3650         if AC_TRY_EVAL(ac_compile) ; then
3651                 mv conftest.o data.o && \
3652                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3653         fi
3654         rm -f conftest.$ac_ext data.o
3655         cat >conftest.$ac_ext <<EOF
3656 #line __oline__ "configure"
3657 int     testfunc()
3658 {
3659 #if defined(NeXT)
3660         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3661 #else
3662         extern int testdata[[3]];
3663         return testdata[[0]] == 123
3664            &&  testdata[[1]] == 456
3665            &&  testdata[[2]] == 789;
3666 #endif
3667 }
3668 EOF
3669         if AC_TRY_EVAL(ac_compile); then
3670                 mv conftest.o func.o && \
3671                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3672         fi
3673         rm -f conftest.$ac_ext func.o
3674         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3675         cf_saveLIBS="$LIBS"
3676         LIBS="conftest.a $LIBS"
3677         AC_TRY_RUN([
3678         int main()
3679         {
3680                 extern int testfunc();
3681                 ${cf_cv_main_return:-return} (!testfunc());
3682         }
3683         ],
3684         [cf_cv_link_dataonly=yes],
3685         [cf_cv_link_dataonly=no],
3686         [cf_cv_link_dataonly=unknown])
3687         LIBS="$cf_saveLIBS"
3688         ])
3689 AC_MSG_RESULT($cf_cv_link_dataonly)
3690
3691 if test "$cf_cv_link_dataonly" = no ; then
3692         AC_DEFINE(BROKEN_LINKER)
3693         BROKEN_LINKER=1
3694 fi
3695
3696 ])dnl
3697 dnl ---------------------------------------------------------------------------
3698 dnl CF_LINK_FUNCS version: 7 updated: 2006/12/16 12:33:30
3699 dnl -------------
3700 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3701 dnl A few non-Unix systems implement symlink, but not link.
3702 dnl A few non-systems implement neither (or have nonfunctional versions).
3703 AC_DEFUN([CF_LINK_FUNCS],
3704 [
3705 AC_CHECK_FUNCS( \
3706         remove \
3707         unlink )
3708
3709 if test "$cross_compiling" = yes ; then
3710         AC_CHECK_FUNCS( \
3711                 link \
3712                 symlink )
3713 else
3714         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3715                 cf_cv_link_funcs=
3716                 for cf_func in link symlink ; do
3717                         AC_TRY_RUN([
3718 #include <sys/types.h>
3719 #include <sys/stat.h>
3720 #ifdef HAVE_UNISTD_H
3721 #include <unistd.h>
3722 #endif
3723 int main()
3724 {
3725         int fail = 0;
3726         char *src = "config.log";
3727         char *dst = "conftest.chk";
3728         struct stat src_sb;
3729         struct stat dst_sb;
3730
3731         stat(src, &src_sb);
3732         fail = ($cf_func("config.log", "conftest.chk") < 0)
3733             || (stat(dst, &dst_sb) < 0)
3734             || (dst_sb.st_mtime != src_sb.st_mtime);
3735 #ifdef HAVE_UNLINK
3736         unlink(dst);
3737 #else
3738         remove(dst);
3739 #endif
3740         ${cf_cv_main_return:-return} (fail);
3741 }
3742                         ],[
3743                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3744                         eval 'ac_cv_func_'$cf_func'=yes'],[
3745                         eval 'ac_cv_func_'$cf_func'=no'],[
3746                         eval 'ac_cv_func_'$cf_func'=error'])
3747                 done
3748                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
3749         ])
3750         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK)
3751         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK)
3752 fi
3753 ])dnl
3754 dnl ---------------------------------------------------------------------------
3755 dnl CF_MAIN_RETURN version: 1 updated: 2006/12/10 09:51:54
3756 dnl --------------
3757 dnl Check if a return from main to the shell actually returns the same exit
3758 dnl code.  This is true for almost any POSIX environment.
3759 dnl
3760 dnl Some very old environments did not flush stdout, etc., on an exit.  That
3761 dnl would be a useful case to test for also.
3762 AC_DEFUN([CF_MAIN_RETURN],
3763 [
3764 cf_cv_main_return=return
3765 ])dnl
3766 dnl ---------------------------------------------------------------------------
3767 dnl CF_MAKEFLAGS version: 14 updated: 2011/03/31 19:29:46
3768 dnl ------------
3769 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
3770 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
3771 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
3772 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
3773 AC_DEFUN([CF_MAKEFLAGS],
3774 [
3775 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
3776         cf_cv_makeflags=''
3777         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
3778         do
3779                 cat >cf_makeflags.tmp <<CF_EOF
3780 SHELL = /bin/sh
3781 all :
3782         @ echo '.$cf_option'
3783 CF_EOF
3784                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
3785                 case "$cf_result" in
3786                 .*k)
3787                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
3788                         case "$cf_result" in
3789                         .*CC=*) cf_cv_makeflags=
3790                                 ;;
3791                         *)      cf_cv_makeflags=$cf_option
3792                                 ;;
3793                         esac
3794                         break
3795                         ;;
3796                 .-)     ;;
3797                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
3798                         ;;
3799                 esac
3800         done
3801         rm -f cf_makeflags.tmp
3802 ])
3803
3804 AC_SUBST(cf_cv_makeflags)
3805 ])dnl
3806 dnl ---------------------------------------------------------------------------
3807 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
3808 dnl ------------
3809 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
3810 dnl a monocase filesystem.
3811 AC_DEFUN([CF_MAKE_TAGS],[
3812 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
3813
3814 AC_CHECK_PROGS(CTAGS, exctags ctags)
3815 AC_CHECK_PROGS(ETAGS, exetags etags)
3816
3817 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
3818
3819 if test "$cf_cv_mixedcase" = yes ; then
3820         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
3821 else
3822         MAKE_UPPER_TAGS=no
3823 fi
3824
3825 if test "$MAKE_UPPER_TAGS" = yes ; then
3826         MAKE_UPPER_TAGS=
3827 else
3828         MAKE_UPPER_TAGS="#"
3829 fi
3830
3831 if test "$MAKE_LOWER_TAGS" = yes ; then
3832         MAKE_LOWER_TAGS=
3833 else
3834         MAKE_LOWER_TAGS="#"
3835 fi
3836
3837 AC_SUBST(CTAGS)
3838 AC_SUBST(ETAGS)
3839
3840 AC_SUBST(MAKE_UPPER_TAGS)
3841 AC_SUBST(MAKE_LOWER_TAGS)
3842 ])dnl
3843 dnl ---------------------------------------------------------------------------
3844 dnl CF_MANPAGE_FORMAT version: 9 updated: 2010/10/23 16:10:30
3845 dnl -----------------
3846 dnl Option to allow user to override automatic configuration of manpage format.
3847 dnl There are several special cases:
3848 dnl
3849 dnl     gzip - man checks for, can display gzip'd files
3850 dnl     compress - man checks for, can display compressed files
3851 dnl     BSDI - files in the cat-directories are suffixed ".0"
3852 dnl     formatted - installer should format (put files in cat-directory)
3853 dnl     catonly - installer should only format, e.g., for a turnkey system.
3854 dnl
3855 dnl There are other configurations which this macro does not test, e.g., HPUX's
3856 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
3857 dnl convention would not match our use).
3858 AC_DEFUN([CF_MANPAGE_FORMAT],
3859 [
3860 AC_REQUIRE([CF_PATHSEP])
3861 AC_MSG_CHECKING(format of man-pages)
3862
3863 AC_ARG_WITH(manpage-format,
3864         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
3865                           optionally formatted/catonly, e.g., gzip,formatted],
3866         [MANPAGE_FORMAT=$withval],
3867         [MANPAGE_FORMAT=unknown])
3868
3869 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
3870 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
3871
3872 cf_unknown=
3873
3874 case $MANPAGE_FORMAT in
3875 unknown)
3876   if test -z "$MANPATH" ; then
3877     MANPATH="/usr/man:/usr/share/man"
3878   fi
3879
3880   # look for the 'date' man-page (it's most likely to be installed!)
3881   MANPAGE_FORMAT=
3882   cf_preform=no
3883   cf_catonly=yes
3884   cf_example=date
3885
3886   IFS="${IFS:-  }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
3887   for cf_dir in $MANPATH; do
3888     test -z "$cf_dir" && cf_dir=/usr/man
3889     for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
3890     do
3891       cf_test=`echo $cf_name | sed -e 's/*//'`
3892       if test "x$cf_test" = "x$cf_name" ; then
3893
3894         case "$cf_name" in
3895         *.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
3896         *.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
3897         *.0)    MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
3898         *)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
3899         esac
3900
3901         case "$cf_name" in
3902         $cf_dir/man*)
3903           cf_catonly=no
3904           ;;
3905         $cf_dir/cat*)
3906           cf_preform=yes
3907           ;;
3908         esac
3909         break
3910       fi
3911
3912       # if we found a match in either man* or cat*, stop looking
3913       if test -n "$MANPAGE_FORMAT" ; then
3914         cf_found=no
3915         test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
3916         test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
3917         case "$cf_name" in
3918         $cf_dir/cat*)
3919           cf_found=yes
3920           ;;
3921         esac
3922         test $cf_found=yes && break
3923       fi
3924     done
3925     # only check the first directory in $MANPATH where we find manpages
3926     if test -n "$MANPAGE_FORMAT" ; then
3927        break
3928     fi
3929   done
3930   # if we did not find the example, just assume it is normal
3931   test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
3932   IFS="$ac_save_ifs"
3933   ;;
3934 *)
3935   for cf_option in $MANPAGE_FORMAT; do
3936      case $cf_option in #(vi
3937      gzip|compress|BSDI|normal|formatted|catonly)
3938        ;;
3939      *)
3940        cf_unknown="$cf_unknown $cf_option"
3941        ;;
3942      esac
3943   done
3944   ;;
3945 esac
3946
3947 AC_MSG_RESULT($MANPAGE_FORMAT)
3948 if test -n "$cf_unknown" ; then
3949   AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
3950 fi
3951 ])dnl
3952 dnl ---------------------------------------------------------------------------
3953 dnl CF_MANPAGE_RENAMES version: 7 updated: 2005/06/18 18:51:57
3954 dnl ------------------
3955 dnl The Debian people have their own naming convention for manpages.  This
3956 dnl option lets us override the name of the file containing renaming, or
3957 dnl disable it altogether.
3958 AC_DEFUN([CF_MANPAGE_RENAMES],
3959 [
3960 AC_MSG_CHECKING(for manpage renaming)
3961
3962 AC_ARG_WITH(manpage-renames,
3963         [  --with-manpage-renames  specify manpage-renaming],
3964         [MANPAGE_RENAMES=$withval],
3965         [MANPAGE_RENAMES=yes])
3966
3967 case ".$MANPAGE_RENAMES" in #(vi
3968 .no) #(vi
3969   ;;
3970 .|.yes)
3971   # Debian 'man' program?
3972   if test -f /etc/debian_version ; then
3973     MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
3974   else
3975     MANPAGE_RENAMES=no
3976   fi
3977   ;;
3978 esac
3979
3980 if test "$MANPAGE_RENAMES" != no ; then
3981   if test -f $srcdir/man/$MANPAGE_RENAMES ; then
3982     MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
3983   elif test ! -f $MANPAGE_RENAMES ; then
3984     AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
3985   fi
3986
3987   test ! -d man && mkdir man
3988
3989   # Construct a sed-script to perform renaming within man-pages
3990   if test -n "$MANPAGE_RENAMES" ; then
3991     test ! -d man && mkdir man
3992     sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
3993   fi
3994 fi
3995
3996 AC_MSG_RESULT($MANPAGE_RENAMES)
3997 AC_SUBST(MANPAGE_RENAMES)
3998 ])dnl
3999 dnl ---------------------------------------------------------------------------
4000 dnl CF_MANPAGE_SYMLINKS version: 5 updated: 2010/07/24 17:12:40
4001 dnl -------------------
4002 dnl Some people expect each tool to make all aliases for manpages in the
4003 dnl man-directory.  This accommodates the older, less-capable implementations
4004 dnl of 'man', and is optional.
4005 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4006 [
4007 AC_MSG_CHECKING(if manpage aliases will be installed)
4008
4009 AC_ARG_WITH(manpage-aliases,
4010         [  --with-manpage-aliases  specify manpage-aliases using .so],
4011         [MANPAGE_ALIASES=$withval],
4012         [MANPAGE_ALIASES=yes])
4013
4014 AC_MSG_RESULT($MANPAGE_ALIASES)
4015
4016 case "x$LN_S" in #(vi
4017 xln*) #(vi
4018         cf_use_symlinks=yes
4019         ;;
4020 *)
4021         cf_use_symlinks=no
4022         ;;
4023 esac
4024
4025 MANPAGE_SYMLINKS=no
4026 if test "$MANPAGE_ALIASES" = yes ; then
4027 AC_MSG_CHECKING(if manpage symlinks should be used)
4028
4029 AC_ARG_WITH(manpage-symlinks,
4030         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4031         [MANPAGE_SYMLINKS=$withval],
4032         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4033
4034 if test "$$cf_use_symlinks" = no; then
4035 if test "$MANPAGE_SYMLINKS" = yes ; then
4036         AC_MSG_WARN(cannot make symlinks, will use .so files)
4037         MANPAGE_SYMLINKS=no
4038 fi
4039 fi
4040
4041 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4042 fi
4043
4044 ])dnl
4045 dnl ---------------------------------------------------------------------------
4046 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4047 dnl --------------
4048 dnl This option causes manpages to be run through tbl(1) to generate tables
4049 dnl correctly.
4050 AC_DEFUN([CF_MANPAGE_TBL],
4051 [
4052 AC_MSG_CHECKING(for manpage tbl)
4053
4054 AC_ARG_WITH(manpage-tbl,
4055         [  --with-manpage-tbl      specify manpage processing with tbl],
4056         [MANPAGE_TBL=$withval],
4057         [MANPAGE_TBL=no])
4058
4059 AC_MSG_RESULT($MANPAGE_TBL)
4060 ])dnl
4061 dnl ---------------------------------------------------------------------------
4062 dnl CF_MAN_PAGES version: 40 updated: 2011/09/10 16:20:21
4063 dnl ------------
4064 dnl Try to determine if the man-pages on the system are compressed, and if
4065 dnl so, what format is used.  Use this information to construct a script that
4066 dnl will install man-pages.
4067 AC_DEFUN([CF_MAN_PAGES],
4068 [
4069 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4070 CF_MANPAGE_FORMAT
4071 CF_MANPAGE_RENAMES
4072 CF_MANPAGE_SYMLINKS
4073 CF_MANPAGE_TBL
4074
4075   if test "$prefix" = "NONE" ; then
4076      cf_prefix="$ac_default_prefix"
4077   else
4078      cf_prefix="$prefix"
4079   fi
4080
4081   case "$MANPAGE_FORMAT" in # (vi
4082   *catonly*) # (vi
4083     cf_format=yes
4084     cf_inboth=no
4085     ;;
4086   *formatted*) # (vi
4087     cf_format=yes
4088     cf_inboth=yes
4089     ;;
4090   *)
4091     cf_format=no
4092     cf_inboth=no
4093     ;;
4094   esac
4095
4096 test ! -d man && mkdir man
4097
4098 cf_so_strip=
4099 cf_compress=
4100 case "$MANPAGE_FORMAT" in #(vi
4101 *compress*) #(vi
4102         cf_so_strip="Z"
4103         cf_compress=compress
4104   ;;
4105 *gzip*)
4106         cf_so_strip="gz"
4107         cf_compress=gzip
4108   ;;
4109 esac
4110
4111 cf_edit_man=./edit_man.sh
4112 cf_man_alias=`pwd`/man_alias.sed
4113
4114 cat >$cf_edit_man <<CF_EOF
4115 #! /bin/sh
4116 # this script is generated by the configure-script CF_MAN_PAGES macro.
4117
4118 prefix="$cf_prefix"
4119 datadir="$datadir"
4120
4121 NCURSES_MAJOR="$NCURSES_MAJOR"
4122 NCURSES_MINOR="$NCURSES_MINOR"
4123 NCURSES_PATCH="$NCURSES_PATCH"
4124
4125 NCURSES_OSPEED="$NCURSES_OSPEED"
4126 TERMINFO="$TERMINFO"
4127
4128 INSTALL="$INSTALL"
4129 INSTALL_DATA="$INSTALL_DATA"
4130
4131 transform="$program_transform_name"
4132
4133 TMP=\${TMPDIR:=/tmp}/man\$\$
4134 trap "rm -f \$TMP" 0 1 2 5 15
4135
4136 form=\[$]1
4137 shift || exit 1
4138
4139 verb=\[$]1
4140 shift || exit 1
4141
4142 mandir=\[$]1
4143 shift || exit 1
4144
4145 srcdir=\[$]1
4146 top_srcdir=\[$]srcdir/..
4147 shift || exit 1
4148
4149 if test "\$form" = normal ; then
4150         if test "$cf_format" = yes ; then
4151         if test "$cf_inboth" = no ; then
4152                 sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4153                 exit $?
4154         fi
4155         fi
4156         cf_subdir=\$mandir/man
4157         cf_tables=$MANPAGE_TBL
4158 else
4159         cf_subdir=\$mandir/cat
4160         cf_tables=yes
4161 fi
4162
4163 # process the list of source-files
4164 for i in \[$]* ; do
4165 case \$i in #(vi
4166 *.orig|*.rej) ;; #(vi
4167 *.[[0-9]]*)
4168         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4169         if test \$verb = installing ; then
4170         if test ! -d \$cf_subdir\${section} ; then
4171                 mkdir -p \$cf_subdir\$section
4172         fi
4173         fi
4174
4175         # replace variables in man page
4176         if test ! -f $cf_man_alias ; then
4177 cat >>$cf_man_alias <<-CF_EOF2
4178                 s,@DATADIR@,\$datadir,g
4179                 s,@TERMINFO@,\$TERMINFO,g
4180                 s,@NCURSES_MAJOR@,\$NCURSES_MAJOR,g
4181                 s,@NCURSES_MINOR@,\$NCURSES_MINOR,g
4182                 s,@NCURSES_PATCH@,\$NCURSES_PATCH,g
4183                 s,@NCURSES_OSPEED@,\$NCURSES_OSPEED,g
4184 CF_EOF
4185         ifelse($1,,,[
4186         for cf_name in $1
4187         do
4188                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4189                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4190 cat >>$cf_edit_man <<-CF_EOF
4191                 s,@$cf_NAME@,$cf_name,g
4192 CF_EOF
4193         done
4194         ])
4195 cat >>$cf_edit_man <<CF_EOF
4196 CF_EOF2
4197                 echo "...made $cf_man_alias"
4198         fi
4199
4200         aliases=
4201         cf_source=\`basename \$i\`
4202         inalias=\$cf_source
4203         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4204         if test ! -f \$inalias ; then
4205                 echo .. skipped \$cf_source
4206                 continue
4207         fi
4208 CF_EOF
4209
4210 if test "$MANPAGE_ALIASES" != no ; then
4211 cat >>$cf_edit_man <<CF_EOF
4212         nCurses=ignore.3x
4213         test $with_curses_h = yes && nCurses=ncurses.3x
4214         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4215 CF_EOF
4216 fi
4217
4218 if test "$MANPAGE_RENAMES" = no ; then
4219 cat >>$cf_edit_man <<CF_EOF
4220         # perform program transformations for section 1 man pages
4221         if test \$section = 1 ; then
4222                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4223         else
4224                 cf_target=\$cf_subdir\${section}/\$cf_source
4225         fi
4226 CF_EOF
4227 else
4228 cat >>$cf_edit_man <<CF_EOF
4229         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4230         if test -z "\$cf_target" ; then
4231                 echo '? missing rename for '\$cf_source
4232                 cf_target="\$cf_source"
4233         fi
4234         cf_target="\$cf_subdir\${section}/\${cf_target}"
4235
4236 CF_EOF
4237 fi
4238
4239 cat >>$cf_edit_man <<CF_EOF
4240         sed     -f $cf_man_alias \\
4241 CF_EOF
4242
4243 if test -f $MANPAGE_RENAMES ; then
4244 cat >>$cf_edit_man <<CF_EOF
4245                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4246 CF_EOF
4247 else
4248 cat >>$cf_edit_man <<CF_EOF
4249                 < \$i >\$TMP
4250 CF_EOF
4251 fi
4252
4253 cat >>$cf_edit_man <<CF_EOF
4254 if test \$cf_tables = yes ; then
4255         tbl \$TMP >\$TMP.out
4256         mv \$TMP.out \$TMP
4257 fi
4258 CF_EOF
4259
4260 if test $with_overwrite != yes ; then
4261 cat >>$cf_edit_man <<CF_EOF
4262         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4263         mv \$TMP.out \$TMP
4264 CF_EOF
4265 fi
4266
4267 if test $with_curses_h != yes ; then
4268 cat >>$cf_edit_man <<CF_EOF
4269         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4270         mv \$TMP.out \$TMP
4271 CF_EOF
4272 fi
4273
4274 cat >>$cf_edit_man <<CF_EOF
4275         if test \$form = format ; then
4276                 nroff -man \$TMP >\$TMP.out
4277                 mv \$TMP.out \$TMP
4278         fi
4279 CF_EOF
4280
4281 if test -n "$cf_compress" ; then
4282 cat >>$cf_edit_man <<CF_EOF
4283         if test \$verb = installing ; then
4284         if ( $cf_compress -f \$TMP )
4285         then
4286                 mv \$TMP.$cf_so_strip \$TMP
4287         fi
4288         fi
4289         cf_target="\$cf_target.$cf_so_strip"
4290 CF_EOF
4291 fi
4292
4293 case "$MANPAGE_FORMAT" in #(vi
4294 *BSDI*)
4295 cat >>$cf_edit_man <<CF_EOF
4296         if test \$form = format ; then
4297                 # BSDI installs only .0 suffixes in the cat directories
4298                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4299         fi
4300 CF_EOF
4301   ;;
4302 esac
4303
4304 cat >>$cf_edit_man <<CF_EOF
4305         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4306         if test \$verb = installing ; then
4307                 echo \$verb \$cf_target
4308                 \$INSTALL_DATA \$TMP \$cf_target
4309                 test -d \$cf_subdir\${section} &&
4310                 test -n "\$aliases" && (
4311                         cd \$cf_subdir\${section} && (
4312                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4313                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4314                                 cf_target=\`basename \$cf_target\`
4315                                 for cf_alias in \$aliases
4316                                 do
4317                                         if test \$section = 1 ; then
4318                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4319                                         fi
4320
4321                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4322                                                 if test -f \$cf_alias\${suffix} ; then
4323                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4324                                                         then
4325                                                                 continue
4326                                                         fi
4327                                                 fi
4328                                                 echo .. \$verb alias \$cf_alias\${suffix}
4329 CF_EOF
4330 case "x$LN_S" in #(vi
4331 *-f) #(vi
4332 cat >>$cf_edit_man <<CF_EOF
4333                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4334 CF_EOF
4335         ;;
4336 *)
4337 cat >>$cf_edit_man <<CF_EOF
4338                                                 rm -f \$cf_alias\${suffix}
4339                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4340 CF_EOF
4341         ;;
4342 esac
4343 cat >>$cf_edit_man <<CF_EOF
4344                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4345                                                 echo ".so \$cf_source" >\$TMP
4346 CF_EOF
4347 if test -n "$cf_compress" ; then
4348 cat >>$cf_edit_man <<CF_EOF
4349                                                 if test -n "$cf_so_strip" ; then
4350                                                         $cf_compress -f \$TMP
4351                                                         mv \$TMP.$cf_so_strip \$TMP
4352                                                 fi
4353 CF_EOF
4354 fi
4355 cat >>$cf_edit_man <<CF_EOF
4356                                                 echo .. \$verb alias \$cf_alias\${suffix}
4357                                                 rm -f \$cf_alias\${suffix}
4358                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4359                                         fi
4360                                 done
4361                         )
4362                 )
4363         elif test \$verb = removing ; then
4364                 test -f \$cf_target && (
4365                         echo \$verb \$cf_target
4366                         rm -f \$cf_target
4367                 )
4368                 test -d \$cf_subdir\${section} &&
4369                 test -n "\$aliases" && (
4370                         cd \$cf_subdir\${section} && (
4371                                 for cf_alias in \$aliases
4372                                 do
4373                                         if test \$section = 1 ; then
4374                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4375                                         fi
4376
4377                                         echo .. \$verb alias \$cf_alias\${suffix}
4378                                         rm -f \$cf_alias\${suffix}
4379                                 done
4380                         )
4381                 )
4382         else
4383 #               echo ".hy 0"
4384                 cat \$TMP
4385         fi
4386         ;;
4387 esac
4388 done
4389
4390 if test $cf_inboth = yes ; then
4391 if test \$form != format ; then
4392         sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4393 fi
4394 fi
4395
4396 exit 0
4397 CF_EOF
4398 chmod 755 $cf_edit_man
4399
4400 ])dnl
4401 dnl ---------------------------------------------------------------------------
4402 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4403 dnl -----------
4404 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4405 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4406 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4407 AC_DEFUN([CF_MATH_LIB],
4408 [
4409 AC_CACHE_CHECK(if -lm needed for math functions,
4410         cf_cv_need_libm,[
4411         AC_TRY_LINK([
4412         #include <stdio.h>
4413         #include <math.h>
4414         ],
4415         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4416         [cf_cv_need_libm=no],
4417         [cf_cv_need_libm=yes])])
4418 if test "$cf_cv_need_libm" = yes
4419 then
4420 ifelse($1,,[
4421         CF_ADD_LIB(m)
4422 ],[$1=-lm])
4423 fi
4424 ])
4425 dnl ---------------------------------------------------------------------------
4426 dnl CF_MIXEDCASE_FILENAMES version: 3 updated: 2003/09/20 17:07:55
4427 dnl ----------------------
4428 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4429 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4430 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4431 [
4432 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4433 if test "$cross_compiling" = yes ; then
4434         case $target_alias in #(vi
4435         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-mingw32*|*-uwin*) #(vi
4436                 cf_cv_mixedcase=no
4437                 ;;
4438         *)
4439                 cf_cv_mixedcase=yes
4440                 ;;
4441         esac
4442 else
4443         rm -f conftest CONFTEST
4444         echo test >conftest
4445         if test -f CONFTEST ; then
4446                 cf_cv_mixedcase=no
4447         else
4448                 cf_cv_mixedcase=yes
4449         fi
4450         rm -f conftest CONFTEST
4451 fi
4452 ])
4453 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES)
4454 ])dnl
4455 dnl ---------------------------------------------------------------------------
4456 dnl CF_MKSTEMP version: 8 updated: 2012/02/13 20:34:56
4457 dnl ----------
4458 dnl Check for a working mkstemp.  This creates two files, checks that they are
4459 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4460 AC_DEFUN([CF_MKSTEMP],[
4461 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4462 rm -rf conftest*
4463 AC_TRY_RUN([
4464 #include <sys/types.h>
4465 #include <stdlib.h>
4466 #include <stdio.h>
4467 #include <string.h>
4468 #include <sys/stat.h>
4469 int main()
4470 {
4471         char *tmpl = "conftestXXXXXX";
4472         char name[2][80];
4473         int n;
4474         int result = 0;
4475         int fd;
4476         struct stat sb;
4477
4478         umask(077);
4479         for (n = 0; n < 2; ++n) {
4480                 strcpy(name[n], tmpl);
4481                 if ((fd = mkstemp(name[n])) >= 0) {
4482                         if (!strcmp(name[n], tmpl)
4483                          || stat(name[n], &sb) != 0
4484                          || (sb.st_mode & S_IFMT) != S_IFREG
4485                          || (sb.st_mode & 077) != 0) {
4486                                 result = 1;
4487                         }
4488                         close(fd);
4489                 }
4490         }
4491         if (result == 0
4492          && !strcmp(name[0], name[1]))
4493                 result = 1;
4494         ${cf_cv_main_return:-return}(result);
4495 }
4496 ],[cf_cv_func_mkstemp=yes
4497 ],[cf_cv_func_mkstemp=no
4498 ],[cf_cv_func_mkstemp=maybe])
4499 ])
4500 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
4501         AC_CHECK_FUNC(mkstemp)
4502 fi
4503 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4504         AC_DEFINE(HAVE_MKSTEMP)
4505 fi
4506 ])dnl
4507 dnl ---------------------------------------------------------------------------
4508 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4509 dnl ----------
4510 dnl Write a debug message to config.log, along with the line number in the
4511 dnl configure script.
4512 AC_DEFUN([CF_MSG_LOG],[
4513 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
4514 ])dnl
4515 dnl ---------------------------------------------------------------------------
4516 dnl CF_NCURSES_ABI_6 version: 1 updated: 2005/09/17 18:42:49
4517 dnl ----------------
4518 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
4519 dnl warn about this.
4520 AC_DEFUN([CF_NCURSES_ABI_6],[
4521 if test "${with_abi_version+set}" != set; then
4522         case $cf_cv_rel_version in
4523         5.*)
4524                 cf_cv_rel_version=6.0
4525                 cf_cv_abi_version=6
4526                 AC_MSG_WARN(Overriding ABI version to $cf_cv_abi_version)
4527                 ;;
4528         esac
4529 fi
4530 ])dnl
4531 dnl ---------------------------------------------------------------------------
4532 dnl CF_NO_LEAKS_OPTION version: 4 updated: 2006/12/16 14:24:05
4533 dnl ------------------
4534 dnl see CF_WITH_NO_LEAKS
4535 AC_DEFUN([CF_NO_LEAKS_OPTION],[
4536 AC_MSG_CHECKING(if you want to use $1 for testing)
4537 AC_ARG_WITH($1,
4538         [$2],
4539         [AC_DEFINE($3)ifelse([$4],,[
4540          $4
4541 ])
4542         : ${with_cflags:=-g}
4543         : ${with_no_leaks:=yes}
4544          with_$1=yes],
4545         [with_$1=])
4546 AC_MSG_RESULT(${with_$1:-no})
4547
4548 case .$with_cflags in #(vi
4549 .*-g*)
4550         case .$CFLAGS in #(vi
4551         .*-g*) #(vi
4552                 ;;
4553         *)
4554                 CF_ADD_CFLAGS([-g])
4555                 ;;
4556         esac
4557         ;;
4558 esac
4559 ])dnl
4560 dnl ---------------------------------------------------------------------------
4561 dnl CF_NUMBER_SYNTAX version: 1 updated: 2003/09/20 18:12:49
4562 dnl ----------------
4563 dnl Check if the given variable is a number.  If not, report an error.
4564 dnl $1 is the variable
4565 dnl $2 is the message
4566 AC_DEFUN([CF_NUMBER_SYNTAX],[
4567 if test -n "$1" ; then
4568   case $1 in #(vi
4569   [[0-9]]*) #(vi
4570         ;;
4571   *)
4572         AC_MSG_ERROR($2 is not a number: $1)
4573         ;;
4574   esac
4575 else
4576   AC_MSG_ERROR($2 value is empty)
4577 fi
4578 ])dnl
4579 dnl ---------------------------------------------------------------------------
4580 dnl CF_OBJ_SUBDIR version: 4 updated: 2002/02/23 20:38:31
4581 dnl -------------
4582 dnl Compute the object-directory name from the given model name
4583 AC_DEFUN([CF_OBJ_SUBDIR],
4584 [
4585         case $1 in
4586         libtool) $2='obj_lo'  ;;
4587         normal)  $2='objects' ;;
4588         debug)   $2='obj_g' ;;
4589         profile) $2='obj_p' ;;
4590         shared)
4591                 case $cf_cv_system_name in #(vi
4592                 cygwin) #(vi
4593                         $2='objects' ;;
4594                 *)
4595                         $2='obj_s' ;;
4596                 esac
4597         esac
4598 ])dnl
4599 dnl ---------------------------------------------------------------------------
4600 dnl CF_PATHSEP version: 5 updated: 2010/05/26 05:38:42
4601 dnl ----------
4602 dnl Provide a value for the $PATH and similar separator
4603 AC_DEFUN([CF_PATHSEP],
4604 [
4605         case $cf_cv_system_name in
4606         os2*)   PATH_SEPARATOR=';'  ;;
4607         *)      PATH_SEPARATOR=':'  ;;
4608         esac
4609 ifelse([$1],,,[$1=$PATH_SEPARATOR])
4610         AC_SUBST(PATH_SEPARATOR)
4611 ])dnl
4612 dnl ---------------------------------------------------------------------------
4613 dnl CF_PATH_SYNTAX version: 13 updated: 2010/05/26 05:38:42
4614 dnl --------------
4615 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
4616 dnl begins with one of the prefix/exec_prefix variables, and then again if the
4617 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
4618 dnl delayed evaluation of those symbols.
4619 AC_DEFUN([CF_PATH_SYNTAX],[
4620 if test "x$prefix" != xNONE; then
4621   cf_path_syntax="$prefix"
4622 else
4623   cf_path_syntax="$ac_default_prefix"
4624 fi
4625
4626 case ".[$]$1" in #(vi
4627 .\[$]\(*\)*|.\'*\'*) #(vi
4628   ;;
4629 ..|./*|.\\*) #(vi
4630   ;;
4631 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
4632   ;;
4633 .\[$]{*prefix}*) #(vi
4634   eval $1="[$]$1"
4635   case ".[$]$1" in #(vi
4636   .NONE/*)
4637     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4638     ;;
4639   esac
4640   ;; #(vi
4641 .no|.NONE/*)
4642   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4643   ;;
4644 *)
4645   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
4646   ;;
4647 esac
4648 ])dnl
4649 dnl ---------------------------------------------------------------------------
4650 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
4651 dnl -------------
4652 dnl Check for the package-config program, unless disabled by command-line.
4653 AC_DEFUN([CF_PKG_CONFIG],
4654 [
4655 AC_MSG_CHECKING(if you want to use pkg-config)
4656 AC_ARG_WITH(pkg-config,
4657         [  --with-pkg-config{=path} enable/disable use of pkg-config],
4658         [cf_pkg_config=$withval],
4659         [cf_pkg_config=yes])
4660 AC_MSG_RESULT($cf_pkg_config)
4661
4662 case $cf_pkg_config in #(vi
4663 no) #(vi
4664         PKG_CONFIG=none
4665         ;;
4666 yes) #(vi
4667         CF_ACVERSION_CHECK(2.52,
4668                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
4669                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
4670         ;;
4671 *)
4672         PKG_CONFIG=$withval
4673         ;;
4674 esac
4675
4676 test -z "$PKG_CONFIG" && PKG_CONFIG=none
4677 if test "$PKG_CONFIG" != none ; then
4678         CF_PATH_SYNTAX(PKG_CONFIG)
4679 fi
4680
4681 AC_SUBST(PKG_CONFIG)
4682 ])dnl
4683 dnl ---------------------------------------------------------------------------
4684 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
4685 dnl -----------------
4686 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
4687 dnl
4688 dnl     POSIX.1-1990                            _POSIX_SOURCE
4689 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
4690 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
4691 dnl             Bindings Option
4692 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
4693 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
4694 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
4695 dnl
4696 dnl Parameters:
4697 dnl     $1 is the nominal value for _POSIX_C_SOURCE
4698 AC_DEFUN([CF_POSIX_C_SOURCE],
4699 [
4700 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
4701
4702 cf_save_CFLAGS="$CFLAGS"
4703 cf_save_CPPFLAGS="$CPPFLAGS"
4704
4705 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
4706 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
4707
4708 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
4709         CF_MSG_LOG(if the symbol is already defined go no further)
4710         AC_TRY_COMPILE([#include <sys/types.h>],[
4711 #ifndef _POSIX_C_SOURCE
4712 make an error
4713 #endif],
4714         [cf_cv_posix_c_source=no],
4715         [cf_want_posix_source=no
4716          case .$cf_POSIX_C_SOURCE in #(vi
4717          .[[12]]??*) #(vi
4718                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4719                 ;;
4720          .2) #(vi
4721                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4722                 cf_want_posix_source=yes
4723                 ;;
4724          .*)
4725                 cf_want_posix_source=yes
4726                 ;;
4727          esac
4728          if test "$cf_want_posix_source" = yes ; then
4729                 AC_TRY_COMPILE([#include <sys/types.h>],[
4730 #ifdef _POSIX_SOURCE
4731 make an error
4732 #endif],[],
4733                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
4734          fi
4735          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
4736          CFLAGS="$cf_trim_CFLAGS"
4737          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
4738          CF_MSG_LOG(if the second compile does not leave our definition intact error)
4739          AC_TRY_COMPILE([#include <sys/types.h>],[
4740 #ifndef _POSIX_C_SOURCE
4741 make an error
4742 #endif],,
4743          [cf_cv_posix_c_source=no])
4744          CFLAGS="$cf_save_CFLAGS"
4745          CPPFLAGS="$cf_save_CPPFLAGS"
4746         ])
4747 ])
4748
4749 if test "$cf_cv_posix_c_source" != no ; then
4750         CFLAGS="$cf_trim_CFLAGS"
4751         CPPFLAGS="$cf_trim_CPPFLAGS"
4752         CF_ADD_CFLAGS($cf_cv_posix_c_source)
4753 fi
4754
4755 ])dnl
4756 dnl ---------------------------------------------------------------------------
4757 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
4758 dnl ------------
4759 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
4760 dnl
4761 dnl $1 = symbol to test
4762 dnl $2 = value (if any) to use for a predefinition
4763 AC_DEFUN([CF_PREDEFINE],
4764 [
4765 AC_MSG_CHECKING(if we must define $1)
4766 AC_TRY_COMPILE([#include <sys/types.h>
4767 ],[
4768 #ifndef $1
4769 make an error
4770 #endif],[cf_result=no],[cf_result=yes])
4771 AC_MSG_RESULT($cf_result)
4772
4773 if test "$cf_result" = yes ; then
4774         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
4775 elif test "x$2" != "x" ; then
4776         AC_MSG_CHECKING(checking for compatible value versus $2)
4777         AC_TRY_COMPILE([#include <sys/types.h>
4778 ],[
4779 #if $1-$2 < 0
4780 make an error
4781 #endif],[cf_result=yes],[cf_result=no])
4782         AC_MSG_RESULT($cf_result)
4783         if test "$cf_result" = no ; then
4784                 # perhaps we can override it - try...
4785                 CPPFLAGS="$CPPFLAGS -D$1=$2"
4786         fi
4787 fi
4788 ])dnl
4789 dnl ---------------------------------------------------------------------------
4790 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
4791 dnl ------------
4792 dnl Append definitions and rules for the given programs to the subdirectory
4793 dnl Makefiles, and the recursion rule for the top-level Makefile.
4794 dnl
4795 dnl parameters
4796 dnl     $1 = script to run
4797 dnl     $2 = list of subdirectories
4798 dnl
4799 dnl variables
4800 dnl     $AWK
4801 AC_DEFUN([CF_PRG_RULES],
4802 [
4803 for cf_dir in $2
4804 do
4805         if test ! -d $srcdir/$cf_dir; then
4806                 continue
4807         elif test -f $srcdir/$cf_dir/programs; then
4808                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
4809         fi
4810 done
4811
4812 ])dnl
4813 dnl ---------------------------------------------------------------------------
4814 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
4815 dnl ----------
4816 dnl Check for archiver "ar".
4817 AC_DEFUN([CF_PROG_AR],[
4818 AC_CHECK_TOOL(AR, ar, ar)
4819 ])
4820 dnl ---------------------------------------------------------------------------
4821 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
4822 dnl -----------
4823 dnl Check for awk, ensure that the check found something.
4824 AC_DEFUN([CF_PROG_AWK],
4825 [
4826 AC_PROG_AWK
4827 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
4828 ])dnl
4829 dnl ---------------------------------------------------------------------------
4830 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
4831 dnl --------------
4832 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
4833 dnl the output file can be renamed, and allows for a shell variable that can
4834 dnl be used later.  The parameter is either CC or CXX.  The result is the
4835 dnl cache variable:
4836 dnl     $cf_cv_prog_CC_c_o
4837 dnl     $cf_cv_prog_CXX_c_o
4838 AC_DEFUN([CF_PROG_CC_C_O],
4839 [AC_REQUIRE([AC_PROG_CC])dnl
4840 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
4841 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
4842 [
4843 cat > conftest.$ac_ext <<CF_EOF
4844 #include <stdio.h>
4845 int main()
4846 {
4847         ${cf_cv_main_return:-return}(0);
4848 }
4849 CF_EOF
4850 # We do the test twice because some compilers refuse to overwrite an
4851 # existing .o file with -o, though they will create one.
4852 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
4853 if AC_TRY_EVAL(ac_try) &&
4854   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
4855 then
4856   eval cf_cv_prog_$1_c_o=yes
4857 else
4858   eval cf_cv_prog_$1_c_o=no
4859 fi
4860 rm -rf conftest*
4861 ])dnl
4862 if test $cf_cv_prog_$1_c_o = yes; then
4863   AC_MSG_RESULT([yes])
4864 else
4865   AC_MSG_RESULT([no])
4866 fi
4867 ])dnl
4868 dnl ---------------------------------------------------------------------------
4869 dnl CF_PROG_CC_U_D version: 1 updated: 2005/07/14 16:59:30
4870 dnl --------------
4871 dnl Check if C (preprocessor) -U and -D options are processed in the order
4872 dnl given rather than by type of option.  Some compilers insist on apply all
4873 dnl of the -U options after all of the -D options.  Others allow mixing them,
4874 dnl and may predefine symbols that conflict with those we define.
4875 AC_DEFUN([CF_PROG_CC_U_D],
4876 [
4877 AC_CACHE_CHECK(if $CC -U and -D options work together,cf_cv_cc_u_d_options,[
4878         cf_save_CPPFLAGS="$CPPFLAGS"
4879         CPPFLAGS="-UU_D_OPTIONS -DU_D_OPTIONS -DD_U_OPTIONS -UD_U_OPTIONS"
4880         AC_TRY_COMPILE([],[
4881 #ifndef U_D_OPTIONS
4882 make an undefined-error
4883 #endif
4884 #ifdef  D_U_OPTIONS
4885 make a defined-error
4886 #endif
4887         ],[
4888         cf_cv_cc_u_d_options=yes],[
4889         cf_cv_cc_u_d_options=no])
4890         CPPFLAGS="$cf_save_CPPFLAGS"
4891 ])
4892 ])dnl
4893 dnl ---------------------------------------------------------------------------
4894 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
4895 dnl -------------
4896 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
4897 dnl This macro adds a check to ensure the script found something.
4898 AC_DEFUN([CF_PROG_EGREP],
4899 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
4900    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
4901     then ac_cv_prog_egrep='grep -E'
4902     else ac_cv_prog_egrep='egrep'
4903     fi])
4904  EGREP=$ac_cv_prog_egrep
4905  AC_SUBST([EGREP])
4906 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
4907 ])dnl
4908 dnl ---------------------------------------------------------------------------
4909 dnl CF_PROG_EXT version: 10 updated: 2004/01/03 19:28:18
4910 dnl -----------
4911 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
4912 AC_DEFUN([CF_PROG_EXT],
4913 [
4914 AC_REQUIRE([CF_CHECK_CACHE])
4915 case $cf_cv_system_name in
4916 os2*)
4917     CFLAGS="$CFLAGS -Zmt"
4918     CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
4919     CXXFLAGS="$CXXFLAGS -Zmt"
4920     # autoconf's macro sets -Zexe and suffix both, which conflict:w
4921     LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
4922     ac_cv_exeext=.exe
4923     ;;
4924 esac
4925
4926 AC_EXEEXT
4927 AC_OBJEXT
4928
4929 PROG_EXT="$EXEEXT"
4930 AC_SUBST(PROG_EXT)
4931 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT")
4932 ])dnl
4933 dnl ---------------------------------------------------------------------------
4934 dnl CF_PROG_GNAT version: 2 updated: 2011/10/22 14:01:47
4935 dnl ------------
4936 dnl Check for gnatmake, ensure that it is complete.
4937 AC_DEFUN([CF_PROG_GNAT],[
4938 cf_ada_make=gnatmake
4939 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
4940 if test "$ac_cv_prog_gnat_exists" = no; then
4941    cf_ada_make=
4942    cf_cv_prog_gnat_correct=no
4943 else
4944    CF_GNAT_VERSION
4945    AC_CHECK_PROG(M4_exists, m4, yes, no)
4946    if test "$ac_cv_prog_M4_exists" = no; then
4947       cf_cv_prog_gnat_correct=no
4948       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
4949    fi
4950    if test "$cf_cv_prog_gnat_correct" = yes; then
4951       AC_MSG_CHECKING(if GNAT works)
4952       CF_GNAT_TRY_RUN([procedure conftest;],
4953 [with Text_IO;
4954 with GNAT.OS_Lib;
4955 procedure conftest is
4956 begin
4957    Text_IO.Put ("Hello World");
4958    Text_IO.New_Line;
4959    GNAT.OS_Lib.OS_Exit (0);
4960 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
4961       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
4962    fi
4963 fi
4964
4965 AC_SUBST(cf_ada_make)
4966 ])dnl
4967 dnl ---------------------------------------------------------------------------
4968 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
4969 dnl ---------------
4970 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
4971 dnl misc/tabset install won't work properly.  Usually this happens only when
4972 dnl using the fallback mkinstalldirs script
4973 AC_DEFUN([CF_PROG_INSTALL],
4974 [AC_PROG_INSTALL
4975 case $INSTALL in
4976 /*)
4977   ;;
4978 *)
4979   CF_DIRNAME(cf_dir,$INSTALL)
4980   test -z "$cf_dir" && cf_dir=.
4981   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
4982   ;;
4983 esac
4984 ])dnl
4985 dnl ---------------------------------------------------------------------------
4986 dnl CF_PROG_LDCONFIG version: 3 updated: 2011/06/04 20:09:13
4987 dnl ----------------
4988 dnl Check for ldconfig, needed to fixup shared libraries that would be built
4989 dnl and then used in the install.
4990 AC_DEFUN([CF_PROG_LDCONFIG],[
4991 if test "$cross_compiling" = yes ; then
4992   LDCONFIG=:
4993 else
4994 case "$cf_cv_system_name" in #(vi
4995 dragonfly*|mirbsd*|freebsd*) #(vi
4996   test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
4997   ;;
4998 *) LDPATH=$PATH:/sbin:/usr/sbin
4999   AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
5000   ;;
5001 esac
5002 fi
5003 AC_SUBST(LDCONFIG)
5004 ])dnl
5005 dnl ---------------------------------------------------------------------------
5006 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
5007 dnl ------------
5008 AC_DEFUN([CF_PROG_LINT],
5009 [
5010 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
5011 AC_SUBST(LINT_OPTS)
5012 ])dnl
5013 dnl ---------------------------------------------------------------------------
5014 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
5015 dnl ------------
5016 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
5017 dnl option if it is supported.
5018 AC_DEFUN([CF_PROG_LN_S],[
5019 AC_PROG_LN_S
5020 AC_MSG_CHECKING(if $LN_S -f options work)
5021
5022 rm -f conf$$.src conf$$dst
5023 echo >conf$$.dst
5024 echo first >conf$$.src
5025 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
5026         cf_prog_ln_sf=yes
5027 else
5028         cf_prog_ln_sf=no
5029 fi
5030 rm -f conf$$.dst conf$$src
5031 AC_MSG_RESULT($cf_prog_ln_sf)
5032
5033 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
5034 ])dnl
5035 dnl ---------------------------------------------------------------------------
5036 dnl CF_REGEX version: 9 updated: 2012/01/07 15:08:24
5037 dnl --------
5038 dnl Attempt to determine if we've got one of the flavors of regular-expression
5039 dnl code that we can support.
5040 AC_DEFUN([CF_REGEX],
5041 [
5042
5043 cf_regex_func=no
5044
5045 cf_regex_libs="regex re"
5046 case $host_os in #(vi
5047 mingw*)
5048         cf_regex_libs="gnurx $cf_regex_libs"
5049         ;;
5050 esac
5051
5052 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5053         for cf_regex_lib in $cf_regex_libs
5054         do
5055                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5056                                 CF_ADD_LIB($cf_regex_lib)
5057                                 cf_regex_func=regcomp
5058                                 break])
5059         done
5060 ])
5061
5062 if test "$cf_regex_func" = no ; then
5063         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5064                 AC_CHECK_LIB(gen,compile,[
5065                                 CF_ADD_LIB(gen)
5066                                 cf_regex_func=compile])])
5067 fi
5068
5069 if test "$cf_regex_func" = no ; then
5070         AC_MSG_WARN(cannot find regular expression library)
5071 fi
5072
5073 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5074
5075 cf_cv_regex_hdrs=no
5076 case $cf_regex_func in #(vi
5077 compile) #(vi
5078         for cf_regex_hdr in regexp.h regexpr.h
5079         do
5080                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5081                         char *p = compile("", "", "", 0);
5082                         int x = step("", "");
5083                 ],[
5084                         cf_cv_regex_hdrs=$cf_regex_hdr
5085                         break
5086                 ])
5087         done
5088         ;;
5089 *)
5090         for cf_regex_hdr in regex.h
5091         do
5092                 AC_TRY_LINK([#include <sys/types.h>
5093 #include <$cf_regex_hdr>],[
5094                         regex_t *p;
5095                         int x = regcomp(p, "", 0);
5096                         int y = regexec(p, "", 0, 0, 0);
5097                         regfree(p);
5098                 ],[
5099                         cf_cv_regex_hdrs=$cf_regex_hdr
5100                         break
5101                 ])
5102         done
5103         ;;
5104 esac
5105
5106 ])
5107
5108 case $cf_cv_regex_hdrs in #(vi
5109     no)        AC_MSG_WARN(no regular expression header found) ;; #(vi
5110     regex.h)   AC_DEFINE(HAVE_REGEX_H_FUNCS) ;; #(vi
5111     regexp.h)  AC_DEFINE(HAVE_REGEXP_H_FUNCS) ;; #(vi
5112     regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS) ;;
5113 esac
5114 ])dnl
5115 dnl ---------------------------------------------------------------------------
5116 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5117 dnl ----------------
5118 dnl Remove all -U and -D options that refer to the given symbol from a list
5119 dnl of C compiler options.  This works around the problem that not all
5120 dnl compilers process -U and -D options from left-to-right, so a -U option
5121 dnl cannot be used to cancel the effect of a preceding -D option.
5122 dnl
5123 dnl $1 = target (which could be the same as the source variable)
5124 dnl $2 = source (including '$')
5125 dnl $3 = symbol to remove
5126 define([CF_REMOVE_DEFINE],
5127 [
5128 $1=`echo "$2" | \
5129         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5130                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5131 ])dnl
5132 dnl ---------------------------------------------------------------------------
5133 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5134 dnl -------------
5135 dnl Remove the given library from the symbol
5136 dnl
5137 dnl $1 = target (which could be the same as the source variable)
5138 dnl $2 = source (including '$')
5139 dnl $3 = library to remove
5140 define([CF_REMOVE_LIB],
5141 [
5142 # remove $3 library from $2
5143 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5144 ])dnl
5145 dnl ---------------------------------------------------------------------------
5146 dnl CF_RPATH_HACK version: 9 updated: 2011/02/13 13:31:33
5147 dnl -------------
5148 AC_DEFUN([CF_RPATH_HACK],
5149 [
5150 AC_REQUIRE([CF_LD_RPATH_OPT])
5151 AC_MSG_CHECKING(for updated LDFLAGS)
5152 if test -n "$LD_RPATH_OPT" ; then
5153         AC_MSG_RESULT(maybe)
5154
5155         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5156         cf_rpath_list="/usr/lib /lib"
5157         if test "$cf_ldd_prog" != no
5158         then
5159                 cf_rpath_oops=
5160
5161 AC_TRY_LINK([#include <stdio.h>],
5162                 [printf("Hello");],
5163                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort -u`
5164                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort -u`])
5165
5166                 # If we passed the link-test, but get a "not found" on a given library,
5167                 # this could be due to inept reconfiguration of gcc to make it only
5168                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5169                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5170                 # /usr/local libraries.
5171                 if test -n "$cf_rpath_oops"
5172                 then
5173                         for cf_rpath_src in $cf_rpath_oops
5174                         do
5175                                 for cf_rpath_dir in \
5176                                         /usr/local \
5177                                         /usr/pkg \
5178                                         /opt/sfw
5179                                 do
5180                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5181                                         then
5182                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5183                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5184                                                 break
5185                                         fi
5186                                 done
5187                         done
5188                 fi
5189         fi
5190
5191         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5192
5193         CF_RPATH_HACK_2(LDFLAGS)
5194         CF_RPATH_HACK_2(LIBS)
5195
5196         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5197 fi
5198 AC_SUBST(EXTRA_LDFLAGS)
5199 ])dnl
5200 dnl ---------------------------------------------------------------------------
5201 dnl CF_RPATH_HACK_2 version: 6 updated: 2010/04/17 16:31:24
5202 dnl ---------------
5203 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5204 dnl EXTRA_LDFLAGS for each -L option found.
5205 dnl
5206 dnl $cf_rpath_list contains a list of directories to ignore.
5207 dnl
5208 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5209 dnl      but LIBS often has misplaced -L options.
5210 AC_DEFUN([CF_RPATH_HACK_2],
5211 [
5212 CF_VERBOSE(...checking $1 [$]$1)
5213
5214 cf_rpath_dst=
5215 for cf_rpath_src in [$]$1
5216 do
5217         case $cf_rpath_src in #(vi
5218         -L*) #(vi
5219
5220                 # check if this refers to a directory which we will ignore
5221                 cf_rpath_skip=no
5222                 if test -n "$cf_rpath_list"
5223                 then
5224                         for cf_rpath_item in $cf_rpath_list
5225                         do
5226                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5227                                 then
5228                                         cf_rpath_skip=yes
5229                                         break
5230                                 fi
5231                         done
5232                 fi
5233
5234                 if test "$cf_rpath_skip" = no
5235                 then
5236                         # transform the option
5237                         if test "$LD_RPATH_OPT" = "-R " ; then
5238                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5239                         else
5240                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5241                         fi
5242
5243                         # if we have not already added this, add it now
5244                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5245                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5246                         then
5247                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5248                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5249                         fi
5250                 fi
5251                 ;;
5252         esac
5253         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5254 done
5255 $1=$cf_rpath_dst
5256
5257 CF_VERBOSE(...checked $1 [$]$1)
5258 AC_SUBST(EXTRA_LDFLAGS)
5259 ])dnl
5260 dnl ---------------------------------------------------------------------------
5261 dnl CF_SHARED_OPTS version: 70 updated: 2012/02/25 15:20:07
5262 dnl --------------
5263 dnl --------------
5264 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5265 dnl library.
5266 dnl
5267 dnl Note: ${LOCAL_LDFLAGS} is used to link executables that will run within the
5268 dnl build-tree, i.e., by making use of the libraries that are compiled in ../lib
5269 dnl We avoid compiling-in a ../lib path for the shared library since that can
5270 dnl lead to unexpected results at runtime.
5271 dnl ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared libraries
5272 dnl are compiled in ../../lib
5273 dnl
5274 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5275 dnl to install symbolic links to the rel/abi versions of shared libraries.
5276 dnl
5277 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5278 dnl version when making symbolic links.
5279 dnl
5280 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5281 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5282 dnl (ex: libncurses.so.<ver>).
5283 dnl
5284 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5285 AC_DEFUN([CF_SHARED_OPTS],
5286 [
5287         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
5288         AC_REQUIRE([CF_LD_RPATH_OPT])
5289         LOCAL_LDFLAGS=
5290         LOCAL_LDFLAGS2=
5291         LD_SHARED_OPTS=
5292         INSTALL_LIB="-m 644"
5293
5294         cf_cv_do_symlinks=no
5295         cf_ld_rpath_opt=
5296         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5297
5298         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5299         AC_ARG_WITH(shlib-version,
5300         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5301         [test -z "$withval" && withval=auto
5302         case $withval in #(vi
5303         yes) #(vi
5304                 cf_cv_shlib_version=auto
5305                 ;;
5306         rel|abi|auto|no) #(vi
5307                 cf_cv_shlib_version=$withval
5308                 ;;
5309         *)
5310                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
5311                 ;;
5312         esac
5313         ],[cf_cv_shlib_version=auto])
5314         AC_MSG_RESULT($cf_cv_shlib_version)
5315
5316         cf_cv_rm_so_locs=no
5317
5318         # Some less-capable ports of gcc support only -fpic
5319         CC_SHARED_OPTS=
5320         if test "$GCC" = yes
5321         then
5322                 AC_MSG_CHECKING(which $CC option to use)
5323                 cf_save_CFLAGS="$CFLAGS"
5324                 for CC_SHARED_OPTS in -fPIC -fpic ''
5325                 do
5326                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5327                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5328                 done
5329                 AC_MSG_RESULT($CC_SHARED_OPTS)
5330                 CFLAGS="$cf_save_CFLAGS"
5331         fi
5332
5333         cf_cv_shlib_version_infix=no
5334
5335         case $cf_cv_system_name in #(vi
5336         aix4.[3-9]*|aix[[5-7]]*) #(vi
5337                 if test "$GCC" = yes; then
5338                         CC_SHARED_OPTS=
5339                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5340                 else
5341                         # CC_SHARED_OPTS='-qpic=large -G'
5342                         # perhaps "-bM:SRE -bnoentry -bexpall"
5343                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5344                 fi
5345                 ;;
5346         beos*) #(vi
5347                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5348                 ;;
5349         cygwin*) #(vi
5350                 CC_SHARED_OPTS=
5351                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5352                 cf_cv_shlib_version=cygdll
5353                 cf_cv_shlib_version_infix=cygdll
5354                 cat >mk_shared_lib.sh <<-CF_EOF
5355                 #!/bin/sh
5356                 SHARED_LIB=\[$]1
5357                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5358                 shift
5359                 cat <<-EOF
5360                 Linking shared library
5361                 ** SHARED_LIB \[$]SHARED_LIB
5362                 ** IMPORT_LIB \[$]IMPORT_LIB
5363 EOF
5364                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
5365 CF_EOF
5366                 chmod +x mk_shared_lib.sh
5367                 ;;
5368         darwin*) #(vi
5369                 EXTRA_CFLAGS="-no-cpp-precomp"
5370                 CC_SHARED_OPTS="-dynamic"
5371                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5372                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5373                 cf_cv_shlib_version_infix=yes
5374                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5375                         cf_save_LDFLAGS=$LDFLAGS
5376                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5377                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5378                                 LDFLAGS=$cf_save_LDFLAGS])
5379                 if test $cf_cv_ldflags_search_paths_first = yes; then
5380                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5381                 fi
5382                 ;;
5383         hpux*) #(vi
5384                 # (tested with gcc 2.7.2 -- I don't have c89)
5385                 if test "$GCC" = yes; then
5386                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5387                 else
5388                         CC_SHARED_OPTS='+Z'
5389                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5390                 fi
5391                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5392                 # HP-UX shared libraries must be executable, and should be
5393                 # readonly to exploit a quirk in the memory manager.
5394                 INSTALL_LIB="-m 555"
5395                 ;;
5396         interix*)
5397                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5398                 if test "$cf_cv_shlib_version" = rel; then
5399                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5400                 else
5401                         cf_shared_soname='`basename $@`'
5402                 fi
5403                 CC_SHARED_OPTS=
5404                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5405                 ;;
5406         irix*) #(vi
5407                 if test "$cf_cv_enable_rpath" = yes ; then
5408                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5409                 fi
5410                 # tested with IRIX 5.2 and 'cc'.
5411                 if test "$GCC" != yes; then
5412                         CC_SHARED_OPTS='-KPIC'
5413                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5414                 else
5415                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5416                 fi
5417                 cf_cv_rm_so_locs=yes
5418                 ;;
5419         linux*|gnu*|k*bsd*-gnu) #(vi
5420                 if test "$DFT_LWR_MODEL" = "shared" ; then
5421                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5422                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5423                 fi
5424                 if test "$cf_cv_enable_rpath" = yes ; then
5425                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5426                 fi
5427                 CF_SHARED_SONAME
5428                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5429                 ;;
5430         mingw*) #(vi
5431                 cf_cv_shlib_version=mingw
5432                 cf_cv_shlib_version_infix=mingw
5433                 CC_SHARED_OPTS=
5434                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5435                 #MK_SHARED_LIB='${CC} ${CFLAGS} -mdll -Wl,-soname,'$cf_cv_shared_soname',-stats -o $[@]'
5436                 #MK_SHARED_LIB='${DLLTOOL} --export-all-symbols --output-exp --output-lib $[@]'
5437                 cat >mk_shared_lib.sh <<-CF_EOF
5438                 #!/bin/sh
5439                 SHARED_LIB=\[$]1
5440                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5441                 shift
5442                 cat <<-EOF
5443                 Linking shared library
5444                 ** SHARED_LIB \[$]SHARED_LIB
5445                 ** IMPORT_LIB \[$]IMPORT_LIB
5446 EOF
5447                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
5448 CF_EOF
5449                 chmod +x mk_shared_lib.sh
5450                 ;;
5451         openbsd[[2-9]].*|mirbsd*) #(vi
5452                 if test "$DFT_LWR_MODEL" = "shared" ; then
5453                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5454                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5455                 fi
5456                 if test "$cf_cv_enable_rpath" = yes ; then
5457                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5458                 fi
5459                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5460                 CF_SHARED_SONAME
5461                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5462                 ;;
5463         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
5464                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5465                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5466                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5467                 ;;
5468         dragonfly*|freebsd*) #(vi
5469                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5470                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5471                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5472                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
5473                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5474                 fi
5475                 CF_SHARED_SONAME
5476                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
5477                 ;;
5478         netbsd*) #(vi
5479                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5480                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5481                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5482                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5483                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5484                         if test "$cf_cv_shlib_version" = auto; then
5485                         if test -f /usr/libexec/ld.elf_so; then
5486                                 cf_cv_shlib_version=abi
5487                         else
5488                                 cf_cv_shlib_version=rel
5489                         fi
5490                         fi
5491                         CF_SHARED_SONAME
5492                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
5493                 else
5494                         MK_SHARED_LIB='${LD} -shared -Bshareable -o $[@]'
5495                 fi
5496                 ;;
5497         osf*|mls+*) #(vi
5498                 # tested with OSF/1 V3.2 and 'cc'
5499                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
5500                 # link with shared libs).
5501                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
5502                 case $host_os in #(vi
5503                 osf4*)
5504                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
5505                         ;;
5506                 esac
5507                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
5508                 if test "$DFT_LWR_MODEL" = "shared" ; then
5509                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5510                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5511                 fi
5512                 cf_cv_rm_so_locs=yes
5513                 ;;
5514         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
5515                 # tested with osr5.0.5
5516                 if test "$GCC" != yes; then
5517                         CC_SHARED_OPTS='-belf -KPIC'
5518                 fi
5519                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
5520                 if test "$cf_cv_enable_rpath" = yes ; then
5521                         # only way is to set LD_RUN_PATH but no switch for it
5522                         RUN_PATH=$libdir
5523                 fi
5524                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5525                 LINK_PROGS='LD_RUN_PATH=${libdir}'
5526                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
5527                 ;;
5528         sunos4*) #(vi
5529                 # tested with SunOS 4.1.1 and gcc 2.7.0
5530                 if test "$GCC" != yes; then
5531                         CC_SHARED_OPTS='-KPIC'
5532                 fi
5533                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
5534                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5535                 ;;
5536         solaris2*) #(vi
5537                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
5538                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
5539                 if test "$DFT_LWR_MODEL" = "shared" ; then
5540                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
5541                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5542                 fi
5543                 if test "$cf_cv_enable_rpath" = yes ; then
5544                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
5545                 fi
5546                 CF_SHARED_SONAME
5547                 if test "$GCC" != yes; then
5548                         cf_save_CFLAGS="$CFLAGS"
5549                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
5550                         do
5551                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
5552                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
5553                         done
5554                         CFLAGS="$cf_save_CFLAGS"
5555                         CC_SHARED_OPTS=$cf_shared_opts
5556                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5557                 else
5558                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5559                 fi
5560                 ;;
5561         sysv5uw7*|unix_sv*) #(vi
5562                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
5563                 if test "$GCC" != yes; then
5564                         CC_SHARED_OPTS='-KPIC'
5565                 fi
5566                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
5567                 ;;
5568         *)
5569                 CC_SHARED_OPTS='unknown'
5570                 MK_SHARED_LIB='echo unknown'
5571                 ;;
5572         esac
5573
5574         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
5575         case "$cf_cv_shlib_version" in #(vi
5576         rel|abi)
5577                 case "$MK_SHARED_LIB" in #(vi
5578                 *'-o $[@]') #(vi
5579                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
5580                         ;;
5581                 *)
5582                         AC_MSG_WARN(ignored --with-shlib-version)
5583                         ;;
5584                 esac
5585                 ;;
5586         esac
5587
5588         # RPATH_LIST is a colon-separated list of directories
5589         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
5590         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
5591
5592         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
5593         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
5594
5595         AC_SUBST(CC_SHARED_OPTS)
5596         AC_SUBST(LD_RPATH_OPT)
5597         AC_SUBST(LD_SHARED_OPTS)
5598         AC_SUBST(MK_SHARED_LIB)
5599         AC_SUBST(LINK_PROGS)
5600         AC_SUBST(LINK_TESTS)
5601         AC_SUBST(EXTRA_LDFLAGS)
5602         AC_SUBST(LOCAL_LDFLAGS)
5603         AC_SUBST(LOCAL_LDFLAGS2)
5604         AC_SUBST(INSTALL_LIB)
5605         AC_SUBST(RPATH_LIST)
5606 ])dnl
5607 dnl ---------------------------------------------------------------------------
5608 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
5609 dnl ----------------
5610 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
5611 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
5612 dnl option.
5613 dnl
5614 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
5615 dnl If missing, use "rel".
5616 define([CF_SHARED_SONAME],
5617 [
5618         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
5619         if test "$cf_cv_shlib_version" = rel; then
5620                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
5621         else
5622                 cf_cv_shared_soname='`basename $[@]`'
5623         fi
5624 ])
5625 dnl ---------------------------------------------------------------------------
5626 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
5627 dnl -----------
5628 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
5629 dnl programs need this test).
5630 dnl
5631 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
5632 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
5633 dnl winsize declaration is left alone - we may revisit this if Apple choose to
5634 dnl break that part of the interface as well.
5635 AC_DEFUN([CF_SIGWINCH],
5636 [
5637 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
5638         AC_TRY_COMPILE([
5639 #include <sys/types.h>
5640 #include <sys/signal.h>
5641 ],[int x = SIGWINCH],
5642         [cf_cv_define_sigwinch=yes],
5643         [AC_TRY_COMPILE([
5644 #undef _XOPEN_SOURCE
5645 #undef _POSIX_SOURCE
5646 #undef _POSIX_C_SOURCE
5647 #include <sys/types.h>
5648 #include <sys/signal.h>
5649 ],[int x = SIGWINCH],
5650         [cf_cv_define_sigwinch=maybe],
5651         [cf_cv_define_sigwinch=no])
5652 ])
5653 ])
5654
5655 if test "$cf_cv_define_sigwinch" = maybe ; then
5656 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
5657 cf_cv_fixup_sigwinch=unknown
5658 cf_sigwinch=32
5659 while test $cf_sigwinch != 1
5660 do
5661         AC_TRY_COMPILE([
5662 #undef _XOPEN_SOURCE
5663 #undef _POSIX_SOURCE
5664 #undef _POSIX_C_SOURCE
5665 #include <sys/types.h>
5666 #include <sys/signal.h>
5667 ],[
5668 #if SIGWINCH != $cf_sigwinch
5669 make an error
5670 #endif
5671 int x = SIGWINCH],
5672         [cf_cv_fixup_sigwinch=$cf_sigwinch
5673          break])
5674
5675 cf_sigwinch=`expr $cf_sigwinch - 1`
5676 done
5677 ])
5678
5679         if test "$cf_cv_fixup_sigwinch" != unknown ; then
5680                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
5681         fi
5682 fi
5683 ])dnl
5684 dnl ---------------------------------------------------------------------------
5685 dnl CF_SIG_ATOMIC_T version: 2 updated: 2005/09/18 17:27:12
5686 dnl ---------------
5687 dnl signal handler, but there are some gcc depedencies in that recommendation.
5688 dnl Try anyway.
5689 AC_DEFUN([CF_SIG_ATOMIC_T],
5690 [
5691 AC_MSG_CHECKING(for signal global datatype)
5692 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
5693         for cf_type in \
5694                 "volatile sig_atomic_t" \
5695                 "sig_atomic_t" \
5696                 "int"
5697         do
5698         AC_TRY_COMPILE([
5699 #include <sys/types.h>
5700 #include <signal.h>
5701 #include <stdio.h>
5702
5703 extern $cf_type x;
5704 $cf_type x;
5705 static void handler(int sig)
5706 {
5707         x = 5;
5708 }],
5709                 [signal(SIGINT, handler);
5710                  x = 1],
5711                 [cf_cv_sig_atomic_t=$cf_type],
5712                 [cf_cv_sig_atomic_t=no])
5713                 test "$cf_cv_sig_atomic_t" != no && break
5714         done
5715         ])
5716 AC_MSG_RESULT($cf_cv_sig_atomic_t)
5717 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t)
5718 ])dnl
5719 dnl ---------------------------------------------------------------------------
5720 dnl CF_SIZECHANGE version: 8 updated: 2000/11/04 12:22:16
5721 dnl -------------
5722 dnl Check for definitions & structures needed for window size-changing
5723 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
5724 AC_DEFUN([CF_SIZECHANGE],
5725 [
5726 AC_REQUIRE([CF_STRUCT_TERMIOS])
5727 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
5728     cf_cv_sizechange=unknown
5729     cf_save_CPPFLAGS="$CPPFLAGS"
5730
5731 for cf_opts in "" "NEED_PTEM_H"
5732 do
5733
5734     CPPFLAGS="$cf_save_CPPFLAGS"
5735     test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
5736     AC_TRY_COMPILE([#include <sys/types.h>
5737 #ifdef HAVE_TERMIOS_H
5738 #include <termios.h>
5739 #else
5740 #ifdef HAVE_TERMIO_H
5741 #include <termio.h>
5742 #endif
5743 #endif
5744 #ifdef NEED_PTEM_H
5745 /* This is a workaround for SCO:  they neglected to define struct winsize in
5746  * termios.h -- it's only in termio.h and ptem.h
5747  */
5748 #include        <sys/stream.h>
5749 #include        <sys/ptem.h>
5750 #endif
5751 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
5752 #include <sys/ioctl.h>
5753 #endif
5754 ],[
5755 #ifdef TIOCGSIZE
5756         struct ttysize win;     /* FIXME: what system is this? */
5757         int y = win.ts_lines;
5758         int x = win.ts_cols;
5759 #else
5760 #ifdef TIOCGWINSZ
5761         struct winsize win;
5762         int y = win.ws_row;
5763         int x = win.ws_col;
5764 #else
5765         no TIOCGSIZE or TIOCGWINSZ
5766 #endif /* TIOCGWINSZ */
5767 #endif /* TIOCGSIZE */
5768         ],
5769         [cf_cv_sizechange=yes],
5770         [cf_cv_sizechange=no])
5771
5772         CPPFLAGS="$cf_save_CPPFLAGS"
5773         if test "$cf_cv_sizechange" = yes ; then
5774                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
5775                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
5776                 break
5777         fi
5778 done
5779 ])
5780 if test "$cf_cv_sizechange" != no ; then
5781         AC_DEFINE(HAVE_SIZECHANGE)
5782         case $cf_cv_sizechange in #(vi
5783         NEED*)
5784                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
5785                 ;;
5786         esac
5787 fi
5788 ])dnl
5789 dnl ---------------------------------------------------------------------------
5790 dnl CF_SRC_MODULES version: 26 updated: 2012/01/07 15:08:24
5791 dnl --------------
5792 dnl For each parameter, test if the source-directory exists, and if it contains
5793 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
5794 dnl use in CF_LIB_RULES.
5795 dnl
5796 dnl This uses the configured value to make the lists SRC_SUBDIRS and
5797 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
5798 AC_DEFUN([CF_SRC_MODULES],
5799 [
5800 AC_MSG_CHECKING(for src modules)
5801
5802 # dependencies and linker-arguments for test-programs
5803 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
5804 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
5805 if test "$DFT_LWR_MODEL" = "libtool"; then
5806         TEST_ARGS="${TEST_DEPS}"
5807         TEST_ARG2="${TEST_DEP2}"
5808 else
5809         TEST_ARGS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
5810         TEST_ARG2="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARG2"
5811 fi
5812
5813 PC_MODULES_TO_MAKE="ncurses${DFT_ARG_SUFFIX}"
5814 cf_cv_src_modules=
5815 for cf_dir in $1
5816 do
5817         if test -f $srcdir/$cf_dir/modules; then
5818
5819                 # We may/may not have tack in the distribution, though the
5820                 # makefile is.
5821                 if test $cf_dir = tack ; then
5822                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
5823                                 continue
5824                         fi
5825                 fi
5826
5827                 if test -z "$cf_cv_src_modules"; then
5828                         cf_cv_src_modules=$cf_dir
5829                 else
5830                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
5831                 fi
5832
5833                 # Make the ncurses_cfg.h file record the library interface files as
5834                 # well.  These are header files that are the same name as their
5835                 # directory.  Ncurses is the only library that does not follow
5836                 # that pattern.
5837                 if test $cf_dir = tack ; then
5838                         continue
5839                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
5840                         CF_UPPER(cf_have_include,$cf_dir)
5841                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
5842                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
5843                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
5844                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
5845                         if test "$DFT_LWR_MODEL" = "libtool"; then
5846                                 TEST_ARGS="${TEST_DEPS}"
5847                                 TEST_ARG2="${TEST_DEP2}"
5848                         else
5849                                 TEST_ARGS="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARGS"
5850                                 TEST_ARG2="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARG2"
5851                         fi
5852                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${DFT_ARG_SUFFIX}"
5853                 fi
5854         fi
5855 done
5856 AC_MSG_RESULT($cf_cv_src_modules)
5857
5858 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
5859 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
5860
5861 AC_SUBST(TEST_ARGS)
5862 AC_SUBST(TEST_DEPS)
5863
5864 AC_SUBST(TEST_ARG2)
5865 AC_SUBST(TEST_DEP2)
5866
5867 SRC_SUBDIRS=
5868 if test "x$cf_with_manpages" != xno ; then
5869         SRC_SUBDIRS="$SRC_SUBDIRS man"
5870 fi
5871 SRC_SUBDIRS="$SRC_SUBDIRS include"
5872 for cf_dir in $cf_cv_src_modules
5873 do
5874         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
5875 done
5876 if test "x$cf_with_tests" != "xno" ; then
5877         SRC_SUBDIRS="$SRC_SUBDIRS test"
5878 fi
5879 test -z "$MAKE_TERMINFO" && SRC_SUBDIRS="$SRC_SUBDIRS misc"
5880 if test "$cf_with_cxx_binding" != no; then
5881         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${DFT_ARG_SUFFIX}"
5882         SRC_SUBDIRS="$SRC_SUBDIRS c++"
5883 fi
5884
5885 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
5886 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
5887
5888 AC_SUBST(PC_MODULES_TO_MAKE)
5889
5890 ADA_SUBDIRS=
5891 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
5892         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
5893         ADA_SUBDIRS="gen src"
5894         if test "x$cf_with_tests" != "xno" ; then
5895                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
5896         fi
5897 fi
5898
5899 SUB_MAKEFILES=
5900 for cf_dir in $SRC_SUBDIRS
5901 do
5902         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
5903 done
5904
5905 if test -n "$ADA_SUBDIRS"; then
5906         for cf_dir in $ADA_SUBDIRS
5907         do
5908                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
5909         done
5910         AC_SUBST(ADA_SUBDIRS)
5911 fi
5912 ])dnl
5913 dnl ---------------------------------------------------------------------------
5914 dnl CF_STDCPP_LIBRARY version: 7 updated: 2010/05/29 16:31:02
5915 dnl -----------------
5916 dnl Check for -lstdc++, which is GNU's standard C++ library.
5917 AC_DEFUN([CF_STDCPP_LIBRARY],
5918 [
5919 if test -n "$GXX" ; then
5920 case $cf_cv_system_name in #(vi
5921 os2*) #(vi
5922         cf_stdcpp_libname=stdcpp
5923         ;;
5924 *)
5925         cf_stdcpp_libname=stdc++
5926         ;;
5927 esac
5928 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
5929         cf_save="$LIBS"
5930         CF_ADD_LIB($cf_stdcpp_libname)
5931 AC_TRY_LINK([
5932 #include <strstream.h>],[
5933 char buf[80];
5934 strstreambuf foo(buf, sizeof(buf))
5935 ],
5936         [cf_cv_libstdcpp=yes],
5937         [cf_cv_libstdcpp=no])
5938         LIBS="$cf_save"
5939 ])
5940 test "$cf_cv_libstdcpp" = yes && CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS)
5941 fi
5942 ])dnl
5943 dnl ---------------------------------------------------------------------------
5944 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
5945 dnl --------------
5946 dnl     Remove "-g" option from the compiler options
5947 AC_DEFUN([CF_STRIP_G_OPT],
5948 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
5949 dnl ---------------------------------------------------------------------------
5950 dnl CF_STRUCT_SIGACTION version: 4 updated: 2011/04/16 11:52:53
5951 dnl -------------------
5952 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
5953 dnl do this if we've found the sigaction function.
5954 AC_DEFUN([CF_STRUCT_SIGACTION],[
5955 AC_REQUIRE([CF_XOPEN_SOURCE])
5956
5957 if test "$ac_cv_func_sigaction" = yes; then
5958 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
5959 AC_TRY_COMPILE([
5960 #include <sys/types.h>
5961 #include <signal.h>],
5962         [struct sigaction act],
5963         [sigact_bad=no],
5964         [
5965 AC_TRY_COMPILE([
5966 #define _POSIX_SOURCE
5967 #include <sys/types.h>
5968 #include <signal.h>],
5969         [struct sigaction act],
5970         [sigact_bad=yes
5971          AC_DEFINE(_POSIX_SOURCE)],
5972          [sigact_bad=unknown])])
5973 AC_MSG_RESULT($sigact_bad)
5974 fi
5975 ])dnl
5976 dnl ---------------------------------------------------------------------------
5977 dnl CF_STRUCT_TERMIOS version: 6 updated: 2011/04/16 11:52:53
5978 dnl -----------------
5979 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
5980 AC_DEFUN([CF_STRUCT_TERMIOS],[
5981 AC_REQUIRE([CF_XOPEN_SOURCE])
5982
5983 AC_CHECK_HEADERS( \
5984 termio.h \
5985 termios.h \
5986 unistd.h \
5987 )
5988
5989 if test "$ISC" = yes ; then
5990         AC_CHECK_HEADERS( sys/termio.h )
5991 fi
5992 if test "$ac_cv_header_termios_h" = yes ; then
5993         case "$CFLAGS $CPPFLAGS" in
5994         *-D_POSIX_SOURCE*)
5995                 termios_bad=dunno ;;
5996         *)      termios_bad=maybe ;;
5997         esac
5998         if test "$termios_bad" = maybe ; then
5999         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
6000         AC_TRY_COMPILE([#include <termios.h>],
6001                 [struct termios foo; int x = foo.c_iflag],
6002                 termios_bad=no, [
6003                 AC_TRY_COMPILE([
6004 #define _POSIX_SOURCE
6005 #include <termios.h>],
6006                         [struct termios foo; int x = foo.c_iflag],
6007                         termios_bad=unknown,
6008                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE))
6009                         ])
6010         AC_MSG_RESULT($termios_bad)
6011         fi
6012 fi
6013 ])dnl
6014 dnl ---------------------------------------------------------------------------
6015 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
6016 dnl --------------
6017 dnl Construct a search-list for a nonstandard header/lib-file
6018 dnl     $1 = the variable to return as result
6019 dnl     $2 = the package name
6020 dnl     $3 = the subdirectory, e.g., bin, include or lib
6021 AC_DEFUN([CF_SUBDIR_PATH],
6022 [
6023 $1=
6024
6025 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
6026 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
6027 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
6028 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
6029 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
6030 ])dnl
6031 dnl ---------------------------------------------------------------------------
6032 dnl CF_SUBST version: 4 updated: 2006/06/17 12:33:03
6033 dnl --------
6034 dnl     Shorthand macro for substituting things that the user may override
6035 dnl     with an environment variable.
6036 dnl
6037 dnl     $1 = long/descriptive name
6038 dnl     $2 = environment variable
6039 dnl     $3 = default value
6040 AC_DEFUN([CF_SUBST],
6041 [AC_CACHE_VAL(cf_cv_subst_$2,[
6042 AC_MSG_CHECKING(for $1 (symbol $2))
6043 CF_SUBST_IF([-z "[$]$2"], [$2], [$3])
6044 cf_cv_subst_$2=[$]$2
6045 AC_MSG_RESULT([$]$2)
6046 ])
6047 ])dnl
6048 dnl ---------------------------------------------------------------------------
6049 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
6050 dnl -----------
6051 dnl     Shorthand macro for substituting things that the user may override
6052 dnl     with an environment variable.
6053 dnl
6054 dnl     $1 = condition to pass to "test"
6055 dnl     $2 = environment variable
6056 dnl     $3 = value if the test succeeds
6057 dnl     $4 = value if the test fails
6058 AC_DEFUN([CF_SUBST_IF],
6059 [
6060 if test $1 ; then
6061         $2=$3
6062 ifelse($4,,,[else
6063         $2=$4])
6064 fi
6065 AC_SUBST($2)
6066 ])dnl
6067 dnl ---------------------------------------------------------------------------
6068 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
6069 dnl ------------------------
6070 dnl Get the version-number for use in shared-library naming, etc.
6071 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
6072 [
6073 AC_REQUIRE([CF_PROG_EGREP])
6074 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6075 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6076 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6077 cf_cv_abi_version=${NCURSES_MAJOR}
6078 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
6079 dnl Show the computed version, for logging
6080 cf_cv_timestamp=`date`
6081 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
6082 dnl We need these values in the generated headers
6083 AC_SUBST(NCURSES_MAJOR)
6084 AC_SUBST(NCURSES_MINOR)
6085 AC_SUBST(NCURSES_PATCH)
6086 dnl We need these values in the generated makefiles
6087 AC_SUBST(cf_cv_rel_version)
6088 AC_SUBST(cf_cv_abi_version)
6089 AC_SUBST(cf_cv_builtin_bool)
6090 AC_SUBST(cf_cv_header_stdbool_h)
6091 AC_SUBST(cf_cv_type_of_bool)dnl
6092 ])dnl
6093 dnl ---------------------------------------------------------------------------
6094 dnl CF_SYS_TIME_SELECT version: 4 updated: 2000/10/04 09:18:40
6095 dnl ------------------
6096 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6097 dnl older SCO configurations.
6098 AC_DEFUN([CF_SYS_TIME_SELECT],
6099 [
6100 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6101 AC_CACHE_VAL(cf_cv_sys_time_select,[
6102 AC_TRY_COMPILE([
6103 #include <sys/types.h>
6104 #ifdef HAVE_SYS_TIME_H
6105 #include <sys/time.h>
6106 #endif
6107 #ifdef HAVE_SYS_SELECT_H
6108 #include <sys/select.h>
6109 #endif
6110 ],[],[cf_cv_sys_time_select=yes],
6111      [cf_cv_sys_time_select=no])
6112      ])
6113 AC_MSG_RESULT($cf_cv_sys_time_select)
6114 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT)
6115 ])dnl
6116 dnl ---------------------------------------------------------------------------
6117 dnl CF_TOP_BUILDDIR version: 1 updated: 2006/10/15 16:33:23
6118 dnl ---------------
6119 dnl Define a top_builddir symbol, for applications that need an absolute path.
6120 AC_DEFUN([CF_TOP_BUILDDIR],
6121 [
6122 top_builddir=`pwd`
6123 AC_SUBST(top_builddir)
6124 ])dnl
6125 dnl ---------------------------------------------------------------------------
6126 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6127 dnl -------------------
6128 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6129 dnl can define it successfully.
6130 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6131 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6132         AC_TRY_COMPILE([
6133 #include <stdlib.h>
6134 #include <string.h>
6135 #include <sys/types.h>
6136 ],[
6137 #ifndef _XOPEN_SOURCE
6138 make an error
6139 #endif],
6140         [cf_cv_xopen_source=no],
6141         [cf_save="$CPPFLAGS"
6142          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6143          AC_TRY_COMPILE([
6144 #include <stdlib.h>
6145 #include <string.h>
6146 #include <sys/types.h>
6147 ],[
6148 #ifdef _XOPEN_SOURCE
6149 make an error
6150 #endif],
6151         [cf_cv_xopen_source=no],
6152         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6153         CPPFLAGS="$cf_save"
6154         ])
6155 ])
6156
6157 if test "$cf_cv_xopen_source" != no ; then
6158         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6159         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6160         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6161         CF_ADD_CFLAGS($cf_temp_xopen_source)
6162 fi
6163 ])
6164 dnl ---------------------------------------------------------------------------
6165 dnl CF_TYPEOF_CHTYPE version: 8 updated: 2006/12/16 12:33:30
6166 dnl ----------------
6167 dnl Determine the type we should use for chtype (and attr_t, which is treated
6168 dnl as the same thing).  We want around 32 bits, so on most machines want a
6169 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6170 dnl wide characters, we have to have a type compatible with that, as well.
6171 AC_DEFUN([CF_TYPEOF_CHTYPE],
6172 [
6173 AC_MSG_CHECKING([for type of chtype])
6174 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6175                 AC_TRY_RUN([
6176 #define WANT_BITS 31
6177 #include <stdio.h>
6178 int main()
6179 {
6180         FILE *fp = fopen("cf_test.out", "w");
6181         if (fp != 0) {
6182                 char *result = "long";
6183                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6184                         int n;
6185                         unsigned int x, y;
6186                         for (n = 0; n < WANT_BITS; n++) {
6187                                 x = (1 << n);
6188                                 y = (x >> n);
6189                                 if (y != 1 || x == 0) {
6190                                         x = 0;
6191                                         break;
6192                                 }
6193                         }
6194                         /*
6195                          * If x is nonzero, an int is big enough for the bits
6196                          * that we want.
6197                          */
6198                         result = (x != 0) ? "int" : "long";
6199                 }
6200                 fputs(result, fp);
6201                 fclose(fp);
6202         }
6203         ${cf_cv_main_return:-return}(0);
6204 }
6205                 ],
6206                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6207                 [cf_cv_typeof_chtype=long],
6208                 [cf_cv_typeof_chtype=long])
6209                 rm -f cf_test.out
6210         ])
6211 AC_MSG_RESULT($cf_cv_typeof_chtype)
6212
6213 AC_SUBST(cf_cv_typeof_chtype)
6214 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype)
6215 ])dnl
6216 dnl ---------------------------------------------------------------------------
6217 dnl CF_TYPE_SIGACTION version: 3 updated: 2000/08/12 23:18:52
6218 dnl -----------------
6219 dnl
6220 AC_DEFUN([CF_TYPE_SIGACTION],
6221 [
6222 AC_MSG_CHECKING([for type sigaction_t])
6223 AC_CACHE_VAL(cf_cv_type_sigaction,[
6224         AC_TRY_COMPILE([
6225 #include <signal.h>],
6226                 [sigaction_t x],
6227                 [cf_cv_type_sigaction=yes],
6228                 [cf_cv_type_sigaction=no])])
6229 AC_MSG_RESULT($cf_cv_type_sigaction)
6230 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION)
6231 ])dnl
6232 dnl ---------------------------------------------------------------------------
6233 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6234 dnl --------------------
6235 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6236 dnl won't, but they're still there.
6237 AC_DEFUN([CF_UNSIGNED_LITERALS],
6238 [
6239 AC_MSG_CHECKING([if unsigned literals are legal])
6240 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6241         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6242                 [cf_cv_unsigned_literals=yes],
6243                 [cf_cv_unsigned_literals=no])
6244         ])
6245 AC_MSG_RESULT($cf_cv_unsigned_literals)
6246 ])dnl
6247 dnl ---------------------------------------------------------------------------
6248 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6249 dnl --------
6250 dnl Make an uppercase version of a variable
6251 dnl $1=uppercase($2)
6252 AC_DEFUN([CF_UPPER],
6253 [
6254 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6255 ])dnl
6256 dnl ---------------------------------------------------------------------------
6257 dnl CF_UTF8_LIB version: 7 updated: 2010/06/20 09:24:28
6258 dnl -----------
6259 dnl Check for multibyte support, and if not found, utf8 compatibility library
6260 AC_DEFUN([CF_UTF8_LIB],
6261 [
6262 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6263         cf_save_LIBS="$LIBS"
6264         AC_TRY_LINK([
6265 #include <stdlib.h>],[putwc(0,0);],
6266         [cf_cv_utf8_lib=yes],
6267         [CF_FIND_LINKAGE([
6268 #include <libutf8.h>],[putwc(0,0);],utf8,
6269                 [cf_cv_utf8_lib=add-on],
6270                 [cf_cv_utf8_lib=no])
6271 ])])
6272
6273 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6274 # ncurses/ncursesw:
6275 if test "$cf_cv_utf8_lib" = "add-on" ; then
6276         AC_DEFINE(HAVE_LIBUTF8_H)
6277         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6278         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6279         CF_ADD_LIBS($cf_cv_library_file_utf8)
6280 fi
6281 ])dnl
6282 dnl ---------------------------------------------------------------------------
6283 dnl CF_VA_COPY version: 2 updated: 2010/03/04 05:37:29
6284 dnl ----------
6285 dnl check for va_copy, part of stdarg.h
6286 dnl Also, workaround for glibc's __va_copy, by checking for both.
6287 AC_DEFUN([CF_VA_COPY],[
6288 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6289 AC_TRY_LINK([
6290 #include <stdarg.h>
6291 ],[
6292         static va_list dst;
6293         static va_list src;
6294         va_copy(dst, src)],
6295         cf_cv_have_va_copy=yes,
6296         cf_cv_have_va_copy=no)])
6297
6298 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY)
6299
6300 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6301 AC_TRY_LINK([
6302 #include <stdarg.h>
6303 ],[
6304         static va_list dst;
6305         static va_list src;
6306         __va_copy(dst, src)],
6307         cf_cv_have___va_copy=yes,
6308         cf_cv_have___va_copy=no)])
6309
6310 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY)
6311 ])
6312 dnl ---------------------------------------------------------------------------
6313 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6314 dnl ----------
6315 dnl Use AC_VERBOSE w/o the warnings
6316 AC_DEFUN([CF_VERBOSE],
6317 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6318 CF_MSG_LOG([$1])
6319 ])dnl
6320 dnl ---------------------------------------------------------------------------
6321 dnl CF_WCHAR_TYPE version: 3 updated: 2010/05/26 16:44:57
6322 dnl -------------
6323 dnl Check if type wide-character type $1 is declared, and if so, which header
6324 dnl file is needed.  The second parameter is used to set a shell variable when
6325 dnl the type is not found.  The first parameter sets a shell variable for the
6326 dnl opposite sense.
6327 AC_DEFUN([CF_WCHAR_TYPE],
6328 [
6329 # This is needed on Tru64 5.0 to declare $1
6330 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6331 AC_TRY_COMPILE([
6332 #include <stdlib.h>
6333 #include <stdarg.h>
6334 #include <stdio.h>
6335 #ifdef HAVE_LIBUTF8_H
6336 #include <libutf8.h>
6337 #endif],
6338         [$1 state],
6339         [cf_cv_$1=no],
6340         [AC_TRY_COMPILE([
6341 #include <stdlib.h>
6342 #include <stdarg.h>
6343 #include <stdio.h>
6344 #include <wchar.h>
6345 #ifdef HAVE_LIBUTF8_H
6346 #include <libutf8.h>
6347 #endif],
6348         [$1 value],
6349         [cf_cv_$1=yes],
6350         [cf_cv_$1=unknown])])])
6351
6352 if test "$cf_cv_$1" = yes ; then
6353         AC_DEFINE(NEED_WCHAR_H)
6354         NEED_WCHAR_H=1
6355 fi
6356
6357 ifelse([$2],,,[
6358 # if we do not find $1 in either place, use substitution to provide a fallback.
6359 if test "$cf_cv_$1" = unknown ; then
6360         $2=1
6361 fi
6362 ])
6363 ifelse($3,,,[
6364 # if we find $1 in either place, use substitution to provide a fallback.
6365 if test "$cf_cv_$1" != unknown ; then
6366         $3=1
6367 fi
6368 ])
6369 ])dnl
6370 dnl ---------------------------------------------------------------------------
6371 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
6372 dnl ---------------
6373 dnl Check for compiler-support for weak symbols.
6374 dnl This works with "recent" gcc.
6375 AC_DEFUN([CF_WEAK_SYMBOLS],[
6376 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
6377
6378 AC_TRY_COMPILE([
6379 #include <stdio.h>],
6380 [
6381 #if defined(__GNUC__)
6382 #  if defined __USE_ISOC99
6383 #    define _cat_pragma(exp)    _Pragma(#exp)
6384 #    define _weak_pragma(exp)   _cat_pragma(weak name)
6385 #  else
6386 #    define _weak_pragma(exp)
6387 #  endif
6388 #  define _declare(name)        __extension__ extern __typeof__(name) name
6389 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
6390 #endif
6391
6392 weak_symbol(fopen);
6393 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
6394 ])
6395 ])dnl
6396 dnl ---------------------------------------------------------------------------
6397 dnl CF_WITH_ABI_VERSION version: 1 updated: 2003/09/20 18:12:49
6398 dnl -------------------
6399 dnl Allow library's ABI to be overridden.  Generally this happens when a
6400 dnl packager has incremented the ABI past that used in the original package,
6401 dnl and wishes to keep doing this.
6402 dnl
6403 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6404 dnl symbol.
6405 AC_DEFUN([CF_WITH_ABI_VERSION],[
6406 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
6407 AC_ARG_WITH(abi-version,
6408 [  --with-abi-version=XXX  override derived ABI version],
6409 [AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
6410  cf_cv_abi_version=$withval])
6411  CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
6412 ifelse($1,,,[
6413 $1_ABI=$cf_cv_abi_version
6414 ])
6415 ])dnl
6416 dnl ---------------------------------------------------------------------------
6417 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
6418 dnl --------------------
6419 dnl Command-line option to specify the Ada95 compiler.
6420 AC_DEFUN([CF_WITH_ADA_COMPILER],[
6421 AC_MSG_CHECKING(for ada-compiler)
6422 AC_ARG_WITH(ada-compiler,
6423         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
6424         [cf_ada_compiler=$withval],
6425         [cf_ada_compiler=gnatmake])
6426 AC_SUBST(cf_ada_compiler)
6427 AC_MSG_RESULT($cf_ada_compiler)
6428 ])dnl
6429 dnl ---------------------------------------------------------------------------
6430 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
6431 dnl -------------------
6432 dnl Command-line option to specify where Ada includes will install.
6433 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
6434 AC_MSG_CHECKING(for ada-include)
6435 CF_WITH_PATH(ada-include,
6436    [  --with-ada-include=DIR  Ada includes are in DIR],
6437    ADA_INCLUDE,
6438    PREFIX/share/ada/adainclude,
6439    [$]prefix/share/ada/adainclude)
6440 AC_SUBST(ADA_INCLUDE)
6441 AC_MSG_RESULT($ADA_INCLUDE)
6442 ])dnl
6443 dnl ---------------------------------------------------------------------------
6444 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
6445 dnl -------------------
6446 dnl Command-line option to specify where Ada objects will install.
6447 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
6448 AC_MSG_CHECKING(for ada-objects)
6449 CF_WITH_PATH(ada-objects,
6450    [  --with-ada-objects=DIR  Ada objects are in DIR],
6451    ADA_OBJECTS,
6452    PREFIX/lib/ada/adalib,
6453    [$]prefix/lib/ada/adalib)
6454 AC_SUBST(ADA_OBJECTS)
6455 AC_MSG_RESULT($ADA_OBJECTS)
6456 ])dnl
6457 dnl ---------------------------------------------------------------------------
6458 dnl CF_WITH_ADA_SHAREDLIB version: 2 updated: 2010/06/26 17:35:58
6459 dnl ---------------------
6460 dnl Command-line option to specify if an Ada95 shared-library should be built,
6461 dnl and optionally what its soname should be.
6462 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
6463 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
6464 AC_ARG_WITH(ada-sharedlib,
6465         [  --with-ada-sharedlib=XX build Ada95 shared-library],
6466         [with_ada_sharedlib=$withval],
6467         [with_ada_sharedlib=no])
6468 AC_MSG_RESULT($with_ada_sharedlib)
6469
6470 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
6471 MAKE_ADA_SHAREDLIB="#"
6472
6473 if test "x$with_ada_sharedlib" != xno
6474 then
6475         MAKE_ADA_SHAREDLIB=
6476         if test "x$with_ada_sharedlib" != xyes
6477         then
6478                 ADA_SHAREDLIB="$with_ada_sharedlib"
6479         fi
6480 fi
6481
6482 AC_SUBST(ADA_SHAREDLIB)
6483 AC_SUBST(MAKE_ADA_SHAREDLIB)
6484 ])dnl
6485 dnl ---------------------------------------------------------------------------
6486 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
6487 dnl ----------------
6488 dnl Configure-option for dbmalloc.  The optional parameter is used to override
6489 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6490 AC_DEFUN([CF_WITH_DBMALLOC],[
6491 CF_NO_LEAKS_OPTION(dbmalloc,
6492         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
6493         [USE_DBMALLOC])
6494
6495 if test "$with_dbmalloc" = yes ; then
6496         AC_CHECK_HEADER(dbmalloc.h,
6497                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
6498 fi
6499 ])dnl
6500 dnl ---------------------------------------------------------------------------
6501 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
6502 dnl ---------------
6503 dnl Configure-option for dmalloc.  The optional parameter is used to override
6504 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6505 AC_DEFUN([CF_WITH_DMALLOC],[
6506 CF_NO_LEAKS_OPTION(dmalloc,
6507         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
6508         [USE_DMALLOC])
6509
6510 if test "$with_dmalloc" = yes ; then
6511         AC_CHECK_HEADER(dmalloc.h,
6512                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
6513 fi
6514 ])dnl
6515 dnl ---------------------------------------------------------------------------
6516 dnl CF_WITH_GPM version: 7 updated: 2008/03/23 14:48:54
6517 dnl -----------
6518 dnl
6519 dnl The option parameter (if neither yes/no) is assumed to be the name of
6520 dnl the gpm library, e.g., for dynamic loading.
6521 AC_DEFUN([CF_WITH_GPM],
6522 [
6523 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
6524 AC_ARG_WITH(gpm,
6525         [  --with-gpm              use Alessandro Rubini's GPM library],
6526         [with_gpm=$withval],
6527         [with_gpm=maybe])
6528 AC_MSG_RESULT($with_gpm)
6529
6530 if test "$with_gpm" != no ; then
6531         AC_CHECK_HEADER(gpm.h,[
6532                 AC_DEFINE(HAVE_GPM_H)
6533                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
6534                         CF_VERBOSE(assuming we really have GPM library)
6535                         AC_DEFINE(HAVE_LIBGPM)
6536                 else
6537                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
6538                                 AC_MSG_ERROR(Cannot link with GPM library)
6539                 fi
6540                 with_gpm=yes
6541                 ])
6542         ],[
6543                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
6544                 with_gpm=no
6545         ])
6546 fi
6547 ])
6548 dnl ---------------------------------------------------------------------------
6549 dnl CF_WITH_LIBTOOL version: 28 updated: 2011/07/02 15:40:32
6550 dnl ---------------
6551 dnl Provide a configure option to incorporate libtool.  Define several useful
6552 dnl symbols for the makefile rules.
6553 dnl
6554 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
6555 dnl macros from libtool.m4 which is in the aclocal directory of automake.
6556 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
6557 dnl But that still does not work properly since the macro is expanded outside
6558 dnl the CF_WITH_LIBTOOL macro:
6559 dnl
6560 dnl     #!/bin/sh
6561 dnl     ACLOCAL=`aclocal --print-ac-dir`
6562 dnl     if test -z "$ACLOCAL" ; then
6563 dnl             echo cannot find aclocal directory
6564 dnl             exit 1
6565 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
6566 dnl             echo cannot find libtool.m4 file
6567 dnl             exit 1
6568 dnl     fi
6569 dnl
6570 dnl     LOCAL=aclocal.m4
6571 dnl     ORIG=aclocal.m4.orig
6572 dnl
6573 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
6574 dnl     rm -f $ORIG
6575 dnl     mv $LOCAL $ORIG
6576 dnl
6577 dnl     # sed the LIBTOOL= assignment to omit the current directory?
6578 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
6579 dnl     cat $ORIG >>$LOCAL
6580 dnl
6581 dnl     autoconf-257 $*
6582 dnl
6583 AC_DEFUN([CF_WITH_LIBTOOL],
6584 [
6585 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
6586 ifdef([AC_PROG_LIBTOOL],,[
6587 LIBTOOL=
6588 ])
6589 # common library maintenance symbols that are convenient for libtool scripts:
6590 LIB_CREATE='${AR} -cr'
6591 LIB_OBJECT='${OBJECTS}'
6592 LIB_SUFFIX=.a
6593 LIB_PREP="$RANLIB"
6594
6595 # symbols used to prop libtool up to enable it to determine what it should be
6596 # doing:
6597 LIB_CLEAN=
6598 LIB_COMPILE=
6599 LIB_LINK='${CC}'
6600 LIB_INSTALL=
6601 LIB_UNINSTALL=
6602
6603 AC_MSG_CHECKING(if you want to build libraries with libtool)
6604 AC_ARG_WITH(libtool,
6605         [  --with-libtool          generate libraries with libtool],
6606         [with_libtool=$withval],
6607         [with_libtool=no])
6608 AC_MSG_RESULT($with_libtool)
6609 if test "$with_libtool" != "no"; then
6610 ifdef([AC_PROG_LIBTOOL],[
6611         # missing_content_AC_PROG_LIBTOOL{{
6612         AC_PROG_LIBTOOL
6613         # missing_content_AC_PROG_LIBTOOL}}
6614 ],[
6615         if test "$with_libtool" != "yes" ; then
6616                 CF_PATH_SYNTAX(with_libtool)
6617                 LIBTOOL=$with_libtool
6618         else
6619                 AC_PATH_PROG(LIBTOOL,libtool)
6620         fi
6621         if test -z "$LIBTOOL" ; then
6622                 AC_MSG_ERROR(Cannot find libtool)
6623         fi
6624 ])dnl
6625         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${DESTDIR}${libdir} ${LIBTOOL_VERSION} `cut -f1 ${srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
6626         LIB_OBJECT='${OBJECTS:.o=.lo}'
6627         LIB_SUFFIX=.la
6628         LIB_CLEAN='${LIBTOOL} --mode=clean'
6629         LIB_COMPILE='${LIBTOOL} --mode=compile'
6630         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
6631         LIB_INSTALL='${LIBTOOL} --mode=install'
6632         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
6633         LIB_PREP=:
6634
6635         # Show the version of libtool
6636         AC_MSG_CHECKING(version of libtool)
6637
6638         # Save the version in a cache variable - this is not entirely a good
6639         # thing, but the version string from libtool is very ugly, and for
6640         # bug reports it might be useful to have the original string. "("
6641         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
6642         AC_MSG_RESULT($cf_cv_libtool_version)
6643         if test -z "$cf_cv_libtool_version" ; then
6644                 AC_MSG_ERROR(This is not GNU libtool)
6645         fi
6646
6647         # special hack to add -no-undefined (which libtool should do for itself)
6648         LT_UNDEF=
6649         case "$cf_cv_system_name" in #(vi
6650         cygwin*|mingw32*|uwin*|aix[[4-7]]) #(vi
6651                 LT_UNDEF=-no-undefined
6652                 ;;
6653         esac
6654         AC_SUBST([LT_UNDEF])
6655
6656         # special hack to add --tag option for C++ compiler
6657         case $cf_cv_libtool_version in #(vi
6658         1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*) #(vi
6659                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
6660                 LIBTOOL="$LIBTOOL --tag=CC"
6661                 ;;
6662         *)
6663                 LIBTOOL_CXX="$LIBTOOL"
6664                 ;;
6665         esac
6666 else
6667         LIBTOOL=""
6668         LIBTOOL_CXX=""
6669 fi
6670
6671 test -z "$LIBTOOL" && ECHO_LT=
6672
6673 AC_SUBST(LIBTOOL)
6674 AC_SUBST(LIBTOOL_CXX)
6675 AC_SUBST(LIBTOOL_OPTS)
6676
6677 AC_SUBST(LIB_CREATE)
6678 AC_SUBST(LIB_OBJECT)
6679 AC_SUBST(LIB_SUFFIX)
6680 AC_SUBST(LIB_PREP)
6681
6682 AC_SUBST(LIB_CLEAN)
6683 AC_SUBST(LIB_COMPILE)
6684 AC_SUBST(LIB_LINK)
6685 AC_SUBST(LIB_INSTALL)
6686 AC_SUBST(LIB_UNINSTALL)
6687
6688 ])dnl
6689 dnl ---------------------------------------------------------------------------
6690 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
6691 dnl ------------------
6692 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
6693 dnl "lib" prefix, e.g., because it used the dll naming convention.
6694 dnl
6695 dnl $1 = variable to set
6696 AC_DEFUN([CF_WITH_LIB_PREFIX],
6697 [
6698 AC_MSG_CHECKING(if you want to have a library-prefix)
6699 AC_ARG_WITH(lib-prefix,
6700         [  --with-lib-prefix       override library-prefix],
6701         [with_lib_prefix=$withval],
6702         [with_lib_prefix=auto])
6703 AC_MSG_RESULT($with_lib_prefix)
6704
6705 if test $with_lib_prefix = auto
6706 then
6707         CF_LIB_PREFIX($1)
6708 elif test $with_lib_prefix = no
6709 then
6710         LIB_PREFIX=
6711 else
6712         LIB_PREFIX=$with_lib_prefix
6713 fi
6714 ])dnl
6715 dnl ---------------------------------------------------------------------------
6716 dnl CF_WITH_PATH version: 10 updated: 2010/10/23 15:44:18
6717 dnl ------------
6718 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
6719 dnl defaulting to yes/no.
6720 dnl
6721 dnl $1 = option name
6722 dnl $2 = help-text
6723 dnl $3 = environment variable to set
6724 dnl $4 = default value, shown in the help-message, must be a constant
6725 dnl $5 = default value, if it's an expression & cannot be in the help-message
6726 dnl
6727 AC_DEFUN([CF_WITH_PATH],
6728 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
6729 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
6730 if ifelse([$5],,true,[test -n "$5"]) ; then
6731 CF_PATH_SYNTAX(withval)
6732 fi
6733 $3="$withval"
6734 AC_SUBST($3)dnl
6735 ])dnl
6736 dnl ---------------------------------------------------------------------------
6737 dnl CF_WITH_PATHLIST version: 7 updated: 2010/10/23 16:10:30
6738 dnl ----------------
6739 dnl Process an option specifying a list of colon-separated paths.
6740 dnl
6741 dnl $1 = option name
6742 dnl $2 = help-text
6743 dnl $3 = environment variable to set
6744 dnl $4 = default value, shown in the help-message, must be a constant
6745 dnl $5 = default value, if it's an expression & cannot be in the help-message
6746 dnl $6 = flag to tell if we want to define or substitute
6747 dnl
6748 AC_DEFUN([CF_WITH_PATHLIST],[
6749 AC_REQUIRE([CF_PATHSEP])
6750 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
6751 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
6752
6753 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
6754 cf_dst_path=
6755 for cf_src_path in $withval
6756 do
6757   CF_PATH_SYNTAX(cf_src_path)
6758   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}:"
6759   cf_dst_path="${cf_dst_path}${cf_src_path}"
6760 done
6761 IFS="$ac_save_ifs"
6762
6763 ifelse($6,define,[
6764 # Strip single quotes from the value, e.g., when it was supplied as a literal
6765 # for $4 or $5.
6766 case $cf_dst_path in #(vi
6767 \'*)
6768   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
6769   ;;
6770 esac
6771 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
6772 ])
6773
6774 eval '$3="$cf_dst_path"'
6775 AC_SUBST($3)dnl
6776
6777 ])dnl
6778 dnl ---------------------------------------------------------------------------
6779 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 2 updated: 2011/12/10 18:58:47
6780 dnl -------------------------
6781 dnl Allow the choice of the pkg-config library directory to be overridden.
6782 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
6783 if test "$PKG_CONFIG" != none ; then
6784         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
6785         AC_ARG_WITH(pkg-config-libdir,
6786                 [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
6787                 [PKG_CONFIG_LIBDIR=$withval],
6788                 [PKG_CONFIG_LIBDIR=yes])
6789
6790         case x$PKG_CONFIG_LIBDIR in #(vi
6791         x/*) #(vi
6792                 ;;
6793         xyes) #(vi
6794                 # look for the library directory using the same prefix as the executable
6795                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
6796                 case x`(arch) 2>/dev/null` in #(vi
6797                 *64) #(vi
6798                         for cf_config in $cf_path/share $cf_path/lib64 $cf_path/lib32 $cf_path/lib
6799                         do
6800                                 if test -d $cf_config/pkgconfig
6801                                 then
6802                                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
6803                                         break
6804                                 fi
6805                         done
6806                         ;;
6807                 *)
6808                         PKG_CONFIG_LIBDIR=$cf_path/lib/pkgconfig
6809                         ;;
6810                 esac
6811                 ;;
6812         *)
6813                 ;;
6814         esac
6815
6816         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
6817 fi
6818
6819 AC_SUBST(PKG_CONFIG_LIBDIR)
6820 ])dnl
6821 dnl ---------------------------------------------------------------------------
6822 dnl CF_WITH_PTHREAD version: 5 updated: 2011/12/10 19:01:56
6823 dnl ---------------
6824 dnl Check for POSIX thread library.
6825 AC_DEFUN([CF_WITH_PTHREAD],
6826 [
6827 AC_MSG_CHECKING(if you want to link with the pthread library)
6828 AC_ARG_WITH(pthread,
6829     [  --with-pthread          use POSIX thread library],
6830     [with_pthread=$withval],
6831     [with_pthread=no])
6832 AC_MSG_RESULT($with_pthread)
6833
6834 if test "$with_pthread" != no ; then
6835     AC_CHECK_HEADER(pthread.h,[
6836         AC_DEFINE(HAVE_PTHREADS_H)
6837
6838         for cf_lib_pthread in pthread c_r
6839         do
6840             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
6841             cf_save_LIBS="$LIBS"
6842             CF_ADD_LIB($cf_lib_pthread)
6843             AC_TRY_LINK([
6844 #include <pthread.h>
6845 ],[
6846                 int rc = pthread_create(0,0,0,0);
6847                 int r2 = pthread_mutexattr_settype(0, 0);
6848 ],[with_pthread=yes],[with_pthread=no])
6849             LIBS="$cf_save_LIBS"
6850             AC_MSG_RESULT($with_pthread)
6851             test "$with_pthread" = yes && break
6852         done
6853
6854         if test "$with_pthread" = yes ; then
6855             CF_ADD_LIB($cf_lib_pthread)
6856             AC_DEFINE(HAVE_LIBPTHREADS)
6857         else
6858             AC_MSG_ERROR(Cannot link with pthread library)
6859         fi
6860     ])
6861 fi
6862 ])
6863 dnl ---------------------------------------------------------------------------
6864 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
6865 dnl -------------------
6866 dnl Allow library's release-version to be overridden.  Generally this happens when a
6867 dnl packager has incremented the release-version past that used in the original package,
6868 dnl and wishes to keep doing this.
6869 dnl
6870 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
6871 dnl and {package}_MINOR symbols
6872 dnl symbol.
6873 AC_DEFUN([CF_WITH_REL_VERSION],[
6874 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
6875 AC_ARG_WITH(rel-version,
6876 [  --with-rel-version=XXX  override derived release version],
6877 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
6878  cf_cv_rel_version=$withval])
6879 ifelse($1,,[
6880  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
6881 ],[
6882  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
6883  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
6884  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
6885  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
6886 ])
6887 ])dnl
6888 dnl ---------------------------------------------------------------------------
6889 dnl CF_WITH_SYSMOUSE version: 2 updated: 2003/03/22 19:13:43
6890 dnl ----------------
6891 dnl If we can compile with sysmouse, make it available unless it is not wanted.
6892 AC_DEFUN([CF_WITH_SYSMOUSE],[
6893 # not everyone has "test -c"
6894 if test -c /dev/sysmouse 2>/dev/null ; then
6895 AC_MSG_CHECKING(if you want to use sysmouse)
6896 AC_ARG_WITH(sysmouse,
6897         [  --with-sysmouse         use sysmouse (FreeBSD console)],
6898         [cf_with_sysmouse=$withval],
6899         [cf_with_sysmouse=maybe])
6900         if test "$cf_with_sysmouse" != no ; then
6901         AC_TRY_COMPILE([
6902 #include <osreldate.h>
6903 #if (__FreeBSD_version >= 400017)
6904 #include <sys/consio.h>
6905 #include <sys/fbio.h>
6906 #else
6907 #include <machine/console.h>
6908 #endif
6909 ],[
6910         struct mouse_info the_mouse;
6911         ioctl(0, CONS_MOUSECTL, &the_mouse);
6912 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
6913         fi
6914 AC_MSG_RESULT($cf_with_sysmouse)
6915 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE)
6916 fi
6917 ])dnl
6918 dnl ---------------------------------------------------------------------------
6919 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
6920 dnl ----------------
6921 AC_DEFUN([CF_WITH_VALGRIND],[
6922 CF_NO_LEAKS_OPTION(valgrind,
6923         [  --with-valgrind         test: use valgrind],
6924         [USE_VALGRIND])
6925 ])dnl
6926 dnl ---------------------------------------------------------------------------
6927 dnl CF_XOPEN_SOURCE version: 42 updated: 2012/01/07 08:26:49
6928 dnl ---------------
6929 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
6930 dnl or adapt to the vendor's definitions to get equivalent functionality,
6931 dnl without losing the common non-POSIX features.
6932 dnl
6933 dnl Parameters:
6934 dnl     $1 is the nominal value for _XOPEN_SOURCE
6935 dnl     $2 is the nominal value for _POSIX_C_SOURCE
6936 AC_DEFUN([CF_XOPEN_SOURCE],[
6937
6938 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
6939 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
6940 cf_xopen_source=
6941
6942 case $host_os in #(vi
6943 aix[[4-7]]*) #(vi
6944         cf_xopen_source="-D_ALL_SOURCE"
6945         ;;
6946 cygwin) #(vi
6947         cf_XOPEN_SOURCE=600
6948         ;;
6949 darwin[[0-8]].*) #(vi
6950         cf_xopen_source="-D_APPLE_C_SOURCE"
6951         ;;
6952 darwin*) #(vi
6953         cf_xopen_source="-D_DARWIN_C_SOURCE"
6954         cf_XOPEN_SOURCE=
6955         ;;
6956 freebsd*|dragonfly*) #(vi
6957         # 5.x headers associate
6958         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
6959         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
6960         cf_POSIX_C_SOURCE=200112L
6961         cf_XOPEN_SOURCE=600
6962         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6963         ;;
6964 hpux11*) #(vi
6965         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
6966         ;;
6967 hpux*) #(vi
6968         cf_xopen_source="-D_HPUX_SOURCE"
6969         ;;
6970 irix[[56]].*) #(vi
6971         cf_xopen_source="-D_SGI_SOURCE"
6972         cf_XOPEN_SOURCE=
6973         ;;
6974 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
6975         CF_GNU_SOURCE
6976         ;;
6977 mirbsd*) #(vi
6978         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
6979         cf_XOPEN_SOURCE=
6980         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
6981         ;;
6982 netbsd*) #(vi
6983         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
6984         ;;
6985 openbsd[[4-9]]*) #(vi
6986         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
6987         cf_xopen_source="-D_BSD_SOURCE"
6988         cf_XOPEN_SOURCE=600
6989         ;;
6990 openbsd*) #(vi
6991         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
6992         ;;
6993 osf[[45]]*) #(vi
6994         cf_xopen_source="-D_OSF_SOURCE"
6995         ;;
6996 nto-qnx*) #(vi
6997         cf_xopen_source="-D_QNX_SOURCE"
6998         ;;
6999 sco*) #(vi
7000         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
7001         ;;
7002 solaris2.*) #(vi
7003         cf_xopen_source="-D__EXTENSIONS__"
7004         ;;
7005 *)
7006         CF_TRY_XOPEN_SOURCE
7007         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7008         ;;
7009 esac
7010
7011 if test -n "$cf_xopen_source" ; then
7012         CF_ADD_CFLAGS($cf_xopen_source)
7013 fi
7014
7015 dnl In anything but the default case, we may have system-specific setting
7016 dnl which is still not guaranteed to provide all of the entrypoints that
7017 dnl _XOPEN_SOURCE would yield.
7018 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
7019         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
7020         AC_TRY_COMPILE([#include <stdlib.h>],[
7021 #ifndef _XOPEN_SOURCE
7022 make an error
7023 #endif],
7024         [cf_XOPEN_SOURCE_set=yes],
7025         [cf_XOPEN_SOURCE_set=no])
7026         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
7027         if test $cf_XOPEN_SOURCE_set = yes
7028         then
7029                 AC_TRY_COMPILE([#include <stdlib.h>],[
7030 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
7031 make an error
7032 #endif],
7033                 [cf_XOPEN_SOURCE_set_ok=yes],
7034                 [cf_XOPEN_SOURCE_set_ok=no])
7035                 if test $cf_XOPEN_SOURCE_set_ok = no
7036                 then
7037                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
7038                 fi
7039         else
7040                 CF_TRY_XOPEN_SOURCE
7041         fi
7042 fi
7043 ])