aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2021,2022 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: aclocal.m4,v 1.1001 2022/01/23 00:15:35 tom Exp $
  33 dnl Macros used in NCURSES auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See these pages for additional information:
  40 dnl             https://invisible-island.net/autoconf/
  41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  42 dnl
  43 dnl ---------------------------------------------------------------------------
  44 dnl ---------------------------------------------------------------------------
  45 dnl AM_LANGINFO_CODESET version: 6 updated: 2021/01/01 16:53:59
  46 dnl -------------------
  47 dnl Inserted as requested by gettext 0.10.40
  48 dnl File from /usr/share/aclocal
  49 dnl codeset.m4
  50 dnl ====================
  51 dnl serial AM1
  52 dnl
  53 dnl From Bruno Haible.
  54 AC_DEFUN([AM_LANGINFO_CODESET],
  55 [
  56 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  57         [AC_TRY_LINK([#include <langinfo.h>],
  58         [char* cs = nl_langinfo(CODESET); (void)cs],
  59         am_cv_langinfo_codeset=yes,
  60         am_cv_langinfo_codeset=no)
  61         ])
  62         if test "$am_cv_langinfo_codeset" = yes; then
  63                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  64                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  65         fi
  66 ])dnl
  67 dnl ---------------------------------------------------------------------------
  68 dnl CF_ABI_DEFAULTS version: 3 updated: 2022/01/22 19:13:38
  69 dnl ---------------
  70 dnl Provide configure-script defaults for different ncurses ABIs.
  71 AC_DEFUN([CF_ABI_DEFAULTS],[
  72 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  73
  74 # ABI 5 defaults:
  75 cf_dft_ccharw_max=5
  76 cf_dft_chtype=auto
  77 cf_dft_ext_colors=no
  78 cf_dft_ext_const=no
  79 cf_dft_ext_mouse=no
  80 cf_dft_ext_putwin=no
  81 cf_dft_ext_spfuncs=no
  82 cf_dft_filter_syms=no
  83 cf_dft_interop=no
  84 cf_dft_mmask_t=auto
  85 cf_dft_opaque_curses=no
  86 cf_dft_ordinate_type=short
  87 cf_dft_signed_char=no
  88 cf_dft_tparm_arg=long
  89 cf_dft_with_lp64=no
  90
  91 # ABI 6 defaults:
  92 case x$cf_cv_abi_version in
  93 (x[[6789]])
  94         cf_dft_chtype=uint32_t
  95         cf_dft_ext_colors=yes
  96         cf_dft_ext_const=yes
  97         cf_dft_ext_mouse=yes
  98         cf_dft_ext_putwin=yes
  99         cf_dft_ext_spfuncs=yes
 100         cf_dft_filter_syms=yes
 101         cf_dft_interop=yes
 102         cf_dft_mmask_t=uint32_t
 103         cf_dft_tparm_arg=intptr_t
 104         cf_dft_with_lp64=yes
 105         ;;
 106 esac
 107
 108 # ABI 7 defaults:
 109 case x$cf_cv_abi_version in
 110 (x[[789]])
 111         cf_dft_ccharw_max=6
 112         cf_dft_mmask_t=uint64_t
 113         cf_dft_opaque_curses=yes
 114         cf_dft_ordinate_type=int
 115         cf_dft_signed_char=yes
 116         # also: remove the wgetch-events feature in ABI 7
 117         ;;
 118 esac
 119 ])dnl
 120 dnl ---------------------------------------------------------------------------
 121 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 122 dnl ------------------
 123 dnl Conditionally generate script according to whether we're using a given autoconf.
 124 dnl
 125 dnl $1 = version to compare against
 126 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 127 dnl $3 = code to use if AC_ACVERSION is older than $1.
 128 define([CF_ACVERSION_CHECK],
 129 [
 130 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 131 ifdef([m4_version_compare],
 132 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 133 [CF_ACVERSION_COMPARE(
 134 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 135 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 136 dnl ---------------------------------------------------------------------------
 137 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 138 dnl --------------------
 139 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 140 dnl                      MAJOR2, MINOR2, TERNARY2,
 141 dnl                      PRINTABLE2, not FOUND, FOUND)
 142 define([CF_ACVERSION_COMPARE],
 143 [ifelse(builtin([eval], [$2 < $5]), 1,
 144 [ifelse([$8], , ,[$8])],
 145 [ifelse([$9], , ,[$9])])])dnl
 146 dnl ---------------------------------------------------------------------------
 147 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 148 dnl -------------------
 149 dnl Construct the list of include-options for the C programs in the Ada95
 150 dnl binding.
 151 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 152 [
 153 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 154 if test "$srcdir" != "."; then
 155         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 156 fi
 157 if test "$GCC" != yes; then
 158         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 159 elif test "$includedir" != "/usr/include"; then
 160         if test "$includedir" = '${prefix}/include' ; then
 161                 if test x$prefix != x/usr ; then
 162                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 163                 fi
 164         else
 165                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 166         fi
 167 fi
 168 AC_SUBST(ACPPFLAGS)
 169 ])dnl
 170 dnl ---------------------------------------------------------------------------
 171 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 172 dnl ---------------
 173 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 174 AC_DEFUN([CF_ADD_ADAFLAGS],[
 175         ADAFLAGS="$ADAFLAGS $1"
 176         AC_SUBST(ADAFLAGS)
 177 ])dnl
 178 dnl ---------------------------------------------------------------------------
 179 dnl CF_ADD_CFLAGS version: 15 updated: 2020/12/31 10:54:15
 180 dnl -------------
 181 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 182 dnl $1 = flags to add
 183 dnl $2 = if given makes this macro verbose.
 184 dnl
 185 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 186 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 187 dnl confused by the quotes (which require backslashes to keep them usable).
 188 AC_DEFUN([CF_ADD_CFLAGS],
 189 [
 190 cf_fix_cppflags=no
 191 cf_new_cflags=
 192 cf_new_cppflags=
 193 cf_new_extra_cppflags=
 194
 195 for cf_add_cflags in $1
 196 do
 197 case "$cf_fix_cppflags" in
 198 (no)
 199         case "$cf_add_cflags" in
 200         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 201                 case "$cf_add_cflags" in
 202                 (-D*)
 203                         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 204
 205                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 206                                 && test -z "${cf_tst_cflags}" \
 207                                 && cf_fix_cppflags=yes
 208
 209                         if test "$cf_fix_cppflags" = yes ; then
 210                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 211                                 continue
 212                         elif test "${cf_tst_cflags}" = "\"'" ; then
 213                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 214                                 continue
 215                         fi
 216                         ;;
 217                 esac
 218                 case "$CPPFLAGS" in
 219                 (*$cf_add_cflags)
 220                         ;;
 221                 (*)
 222                         case "$cf_add_cflags" in
 223                         (-D*)
 224                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 225                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 226                                 ;;
 227                         esac
 228                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 229                         ;;
 230                 esac
 231                 ;;
 232         (*)
 233                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 234                 ;;
 235         esac
 236         ;;
 237 (yes)
 238         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 239
 240         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^[[^"]]*"'\''//'`
 241
 242         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 243                 && test -z "${cf_tst_cflags}" \
 244                 && cf_fix_cppflags=no
 245         ;;
 246 esac
 247 done
 248
 249 if test -n "$cf_new_cflags" ; then
 250         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 251         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 252 fi
 253
 254 if test -n "$cf_new_cppflags" ; then
 255         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 256         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 257 fi
 258
 259 if test -n "$cf_new_extra_cppflags" ; then
 260         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 261         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 262 fi
 263
 264 AC_SUBST(EXTRA_CPPFLAGS)
 265
 266 ])dnl
 267 dnl ---------------------------------------------------------------------------
 268 dnl CF_ADD_CXXFLAGS version: 1 updated: 2020/04/04 16:16:13
 269 dnl ---------------
 270 dnl Copy non-preprocessor flags to $CXXFLAGS, preprocessor flags to $CPPFLAGS
 271 dnl The second parameter if given makes this macro verbose.
 272 dnl
 273 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 274 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 275 dnl confused by the quotes (which require backslashes to keep them usable).
 276 AC_DEFUN([CF_ADD_CXXFLAGS],
 277 [
 278 cf_save_CXXFLAGS="$CFLAGS"
 279 CFLAGS="$CXXFLAGS"
 280 CF_ADD_CFLAGS($1 ifelse($2,,,[,$2]))
 281 CXXFLAGS="$CFLAGS"
 282 CFLAGS="$cf_save_CXXFLAGS"
 283 ])dnl
 284 dnl ---------------------------------------------------------------------------
 285 dnl CF_ADD_INCDIR version: 17 updated: 2021/09/04 06:35:04
 286 dnl -------------
 287 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it is
 288 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 289 dnl but old versions (and some misinstalled ones) need that.  To make things
 290 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 291 dnl the include-path).
 292 AC_DEFUN([CF_ADD_INCDIR],
 293 [
 294 if test -n "$1" ; then
 295   for cf_add_incdir in $1
 296   do
 297         while test "$cf_add_incdir" != /usr/include
 298         do
 299           if test -d "$cf_add_incdir"
 300           then
 301                 cf_have_incdir=no
 302                 if test -n "$CFLAGS$CPPFLAGS" ; then
 303                   # a loop is needed to ensure we can add subdirs of existing dirs
 304                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 305                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 306                           cf_have_incdir=yes; break
 307                         fi
 308                   done
 309                 fi
 310
 311                 if test "$cf_have_incdir" = no ; then
 312                   if test "$cf_add_incdir" = /usr/local/include ; then
 313                         if test "$GCC" = yes
 314                         then
 315                           cf_save_CPPFLAGS=$CPPFLAGS
 316                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 317                           AC_TRY_COMPILE([#include <stdio.h>],
 318                                   [printf("Hello")],
 319                                   [],
 320                                   [cf_have_incdir=yes])
 321                           CPPFLAGS=$cf_save_CPPFLAGS
 322                         fi
 323                   fi
 324                 fi
 325
 326                 if test "$cf_have_incdir" = no ; then
 327                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 328                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 329
 330                   cf_top_incdir=`echo "$cf_add_incdir" | sed -e 's%/include/.*$%/include%'`
 331                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 332                   cf_add_incdir="$cf_top_incdir"
 333                 else
 334                   break
 335                 fi
 336           else
 337                 break
 338           fi
 339         done
 340   done
 341 fi
 342 ])dnl
 343 dnl ---------------------------------------------------------------------------
 344 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 345 dnl ----------
 346 dnl Add a library, used to enforce consistency.
 347 dnl
 348 dnl $1 = library to add, without the "-l"
 349 dnl $2 = variable to update (default $LIBS)
 350 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 351 dnl ---------------------------------------------------------------------------
 352 dnl CF_ADD_LIBDIR version: 11 updated: 2020/12/31 20:19:42
 353 dnl -------------
 354 dnl     Adds to the library-path
 355 dnl
 356 dnl     Some machines have trouble with multiple -L options.
 357 dnl
 358 dnl $1 is the (list of) directory(s) to add
 359 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 360 dnl
 361 AC_DEFUN([CF_ADD_LIBDIR],
 362 [
 363 if test -n "$1" ; then
 364         for cf_add_libdir in $1
 365         do
 366                 if test "$cf_add_libdir" = /usr/lib ; then
 367                         :
 368                 elif test -d "$cf_add_libdir"
 369                 then
 370                         cf_have_libdir=no
 371                         if test -n "$LDFLAGS$LIBS" ; then
 372                                 # a loop is needed to ensure we can add subdirs of existing dirs
 373                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 374                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 375                                                 cf_have_libdir=yes; break
 376                                         fi
 377                                 done
 378                         fi
 379                         if test "$cf_have_libdir" = no ; then
 380                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 381                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 382                         fi
 383                 fi
 384         done
 385 fi
 386 ])dnl
 387 dnl ---------------------------------------------------------------------------
 388 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 389 dnl -----------
 390 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 391 dnl prepended to an existing list, since their dependencies are assumed to
 392 dnl already exist in the list.
 393 dnl
 394 dnl $1 = libraries to add, with the "-l", etc.
 395 dnl $2 = variable to update (default $LIBS)
 396 AC_DEFUN([CF_ADD_LIBS],[
 397 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 398 # reverse order
 399 cf_add_0lib=
 400 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 401 # filter duplicates
 402 for cf_add_1lib in $cf_add_0lib; do
 403         for cf_add_2lib in $cf_add_libs; do
 404                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 405                         cf_add_1lib=
 406                         break
 407                 fi
 408         done
 409         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 410 done
 411 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 412 ])dnl
 413 dnl ---------------------------------------------------------------------------
 414 dnl CF_ADD_SUBDIR_PATH version: 5 updated: 2020/12/31 20:19:42
 415 dnl ------------------
 416 dnl Append to a search-list for a nonstandard header/lib-file
 417 dnl     $1 = the variable to return as result
 418 dnl     $2 = the package name
 419 dnl     $3 = the subdirectory, e.g., bin, include or lib
 420 dnl $4 = the directory under which we will test for subdirectories
 421 dnl $5 = a directory that we do not want $4 to match
 422 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 423 [
 424 test "x$4" != "x$5" && \
 425 test -d "$4" && \
 426 ifelse([$5],NONE,,[{ test -z "$5" || test "x$5" = xNONE || test "x$4" != "x$5"; } &&]) {
 427         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 428         test -d "$4/$3" &&          $1="[$]$1 $4/$3"
 429         test -d "$4/$3/$2" &&       $1="[$]$1 $4/$3/$2"
 430         test -d "$4/$3/$2/$3" &&    $1="[$]$1 $4/$3/$2/$3"
 431         test -d "$4/$2/$3" &&       $1="[$]$1 $4/$2/$3"
 432         test -d "$4/$2/$3/$2" &&    $1="[$]$1 $4/$2/$3/$2"
 433 }
 434 ])dnl
 435 dnl ---------------------------------------------------------------------------
 436 dnl CF_APPEND_CFLAGS version: 3 updated: 2021/09/05 17:25:40
 437 dnl ----------------
 438 dnl Use CF_ADD_CFLAGS after first checking for potential redefinitions.
 439 dnl $1 = flags to add
 440 dnl $2 = if given makes this macro verbose.
 441 define([CF_APPEND_CFLAGS],
 442 [
 443 for cf_add_cflags in $1
 444 do
 445         case "x$cf_add_cflags" in
 446         (x-[[DU]]*)
 447                 CF_REMOVE_CFLAGS($cf_add_cflags,CFLAGS,[$2])
 448                 CF_REMOVE_CFLAGS($cf_add_cflags,CPPFLAGS,[$2])
 449                 ;;
 450         esac
 451         CF_ADD_CFLAGS([$cf_add_cflags],[$2])
 452 done
 453 ])dnl
 454 dnl ---------------------------------------------------------------------------
 455 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 456 dnl --------------
 457 dnl use this macro for appending text without introducing an extra blank at
 458 dnl the beginning
 459 define([CF_APPEND_TEXT],
 460 [
 461         test -n "[$]$1" && $1="[$]$1 "
 462         $1="[$]{$1}$2"
 463 ])dnl
 464 dnl ---------------------------------------------------------------------------
 465 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 466 dnl --------------
 467 dnl Allow user to disable a normally-on option.
 468 AC_DEFUN([CF_ARG_DISABLE],
 469 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 470 dnl ---------------------------------------------------------------------------
 471 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 472 dnl -------------
 473 dnl Allow user to enable a normally-off option.
 474 AC_DEFUN([CF_ARG_ENABLE],
 475 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 476 dnl ---------------------------------------------------------------------------
 477 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 478 dnl -------------
 479 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 480 dnl values.
 481 dnl
 482 dnl Parameters:
 483 dnl $1 = option name
 484 dnl $2 = help-string
 485 dnl $3 = action to perform if option is not default
 486 dnl $4 = action if perform if option is default
 487 dnl $5 = default option value (either 'yes' or 'no')
 488 AC_DEFUN([CF_ARG_OPTION],
 489 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 490         if test "$enableval" != "$5" ; then
 491 ifelse([$3],,[    :]dnl
 492 ,[    $3]) ifelse([$4],,,[
 493         else
 494                 $4])
 495         fi],[enableval=$5 ifelse([$4],,,[
 496         $4
 497 ])dnl
 498 ])])dnl
 499 dnl ---------------------------------------------------------------------------
 500 dnl CF_AR_FLAGS version: 9 updated: 2021/01/01 13:31:04
 501 dnl -----------
 502 dnl Check for suitable "ar" (archiver) options for updating an archive.
 503 dnl
 504 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 505 dnl as well as a workaround for breakage of make's archive rules by the GNU
 506 dnl binutils "ar" program.
 507 AC_DEFUN([CF_AR_FLAGS],[
 508 AC_REQUIRE([CF_PROG_AR])
 509
 510 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 511         case "$cf_cv_system_name" in
 512         (*-msvc*)
 513                 cf_cv_ar_flags=''
 514                 cat >mk_static_lib.sh <<-EOF
 515                 #!$SHELL
 516                 MSVC_BIN="[$]AR"
 517                 out="\[$]1"
 518                 shift
 519                 exec \[$]MSVC_BIN -out:"\[$]out" \[$]@
 520                 EOF
 521                 chmod +x mk_static_lib.sh
 522                 AR=`pwd`/mk_static_lib.sh
 523                 ;;
 524         (*)
 525                 cf_cv_ar_flags=unknown
 526                 for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 527                 do
 528
 529                         # check if $ARFLAGS already contains this choice
 530                         if test "x$ARFLAGS" != "x" ; then
 531                                 cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 532                                 if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 533                                         cf_cv_ar_flags=
 534                                         break
 535                                 fi
 536                         fi
 537
 538                         rm -f "conftest.$ac_cv_objext"
 539                         rm -f conftest.a
 540
 541                         cat >"conftest.$ac_ext" <<EOF
 542 #line __oline__ "configure"
 543 int     testdata[[3]] = { 123, 456, 789 };
 544 EOF
 545                         if AC_TRY_EVAL(ac_compile) ; then
 546                                 echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 547                                 $AR $ARFLAGS "$cf_ar_flags" conftest.a "conftest.$ac_cv_objext" 2>&AC_FD_CC 1>/dev/null
 548                                 if test -f conftest.a ; then
 549                                         cf_cv_ar_flags="$cf_ar_flags"
 550                                         break
 551                                 fi
 552                         else
 553                                 CF_VERBOSE(cannot compile test-program)
 554                                 break
 555                         fi
 556                 done
 557                 rm -f conftest.a "conftest.$ac_ext" "conftest.$ac_cv_objext"
 558                 ;;
 559         esac
 560 ])
 561
 562 if test -n "$ARFLAGS" ; then
 563         if test -n "$cf_cv_ar_flags" ; then
 564                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 565         fi
 566 else
 567         ARFLAGS=$cf_cv_ar_flags
 568 fi
 569
 570 AC_SUBST(ARFLAGS)
 571 ])
 572 dnl ---------------------------------------------------------------------------
 573 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 574 dnl -----------------
 575 dnl Check if awk can handle big strings using printf.  Some older versions of
 576 dnl awk choke on large strings passed via "%s".
 577 dnl
 578 dnl $1 = desired string size
 579 dnl $2 = variable to set with result
 580 AC_DEFUN([CF_AWK_BIG_PRINTF],
 581 [
 582         case x$AWK in
 583         (x)
 584                 eval $2=no
 585                 ;;
 586         (*)
 587                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 588                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 589                         eval $2=yes
 590                 else
 591                         eval $2=no
 592                 fi
 593                 ;;
 594         esac
 595 ])dnl
 596 dnl ---------------------------------------------------------------------------
 597 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 598 dnl ------------
 599 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 600 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 601 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 602 dnl
 603 dnl Treat the configuration-variable specially here, since we're directly
 604 dnl substituting its value (i.e., 1/0).
 605 dnl
 606 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 607 AC_DEFUN([CF_BOOL_DECL],
 608 [
 609 AC_MSG_CHECKING(if we should include stdbool.h)
 610
 611 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 612         AC_TRY_COMPILE([],[bool foo = false],
 613                 [cf_cv_header_stdbool_h=0],
 614                 [AC_TRY_COMPILE([
 615 #ifndef __BEOS__
 616 #include <stdbool.h>
 617 #endif
 618 ],[bool foo = false],
 619                         [cf_cv_header_stdbool_h=1],
 620                         [cf_cv_header_stdbool_h=0])])])
 621
 622 if test "$cf_cv_header_stdbool_h" = 1
 623 then    AC_MSG_RESULT(yes)
 624 else    AC_MSG_RESULT(no)
 625 fi
 626
 627 AC_MSG_CHECKING([for builtin bool type])
 628
 629 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 630         AC_TRY_COMPILE([
 631 #include <stdio.h>
 632 #include <sys/types.h>
 633 ],[bool x = false],
 634                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 635                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 636         ])
 637
 638 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 639 then    AC_MSG_RESULT(yes)
 640 else    AC_MSG_RESULT(no)
 641 fi
 642 ])dnl
 643 dnl ---------------------------------------------------------------------------
 644 dnl CF_BOOL_SIZE version: 18 updated: 2021/09/04 06:35:04
 645 dnl ------------
 646 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 647 dnl Don't bother looking for bool.h, since it has been deprecated.
 648 dnl
 649 dnl If the current compiler is C rather than C++, we get the bool definition
 650 dnl from <stdbool.h>.
 651 AC_DEFUN([CF_BOOL_SIZE],
 652 [
 653 AC_CHECK_SIZEOF(bool,,[
 654 #include <stdlib.h>
 655 #include <stdio.h>
 656
 657 #if defined(__cplusplus)
 658
 659 #ifdef HAVE_GXX_BUILTIN_H
 660 #include <g++/builtin.h>
 661 #elif HAVE_GPP_BUILTIN_H
 662 #include <gpp/builtin.h>
 663 #elif HAVE_BUILTIN_H
 664 #include <builtin.h>
 665 #endif
 666
 667 #else
 668
 669 #if $cf_cv_header_stdbool_h
 670 #include <stdbool.h>
 671 #endif
 672
 673 #endif
 674 ])
 675
 676 AC_CACHE_CHECK(for type of bool, cf_cv_type_of_bool,[
 677         rm -f cf_test.out
 678         AC_TRY_RUN([
 679 #include <stdlib.h>
 680 #include <stdio.h>
 681
 682 #if defined(__cplusplus)
 683
 684 #ifdef HAVE_GXX_BUILTIN_H
 685 #include <g++/builtin.h>
 686 #elif HAVE_GPP_BUILTIN_H
 687 #include <gpp/builtin.h>
 688 #elif HAVE_BUILTIN_H
 689 #include <builtin.h>
 690 #endif
 691
 692 #else
 693
 694 #if $cf_cv_header_stdbool_h
 695 #include <stdbool.h>
 696 #endif
 697
 698 #endif
 699
 700 int main(void)
 701 {
 702         FILE *fp = fopen("cf_test.out", "w");
 703         if (fp != 0) {
 704                 bool x = true;
 705                 if ((bool)(-x) >= 0)
 706                         fputs("unsigned ", fp);
 707                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 708                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 709                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 710                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 711                 fclose(fp);
 712         }
 713         ${cf_cv_main_return:-return}(0);
 714 }
 715                 ],
 716                 [cf_cv_type_of_bool=`cat cf_test.out`
 717                  if test -z "$cf_cv_type_of_bool"; then
 718                    cf_cv_type_of_bool=unknown
 719                  fi],
 720                 [cf_cv_type_of_bool=unknown],
 721                 [
 722                 case x$ac_cv_sizeof_bool in
 723                 (x1) cf_cv_type_of_bool="unsigned char";;
 724                 (x2) cf_cv_type_of_bool="unsigned short";;
 725                 (x4) cf_cv_type_of_bool="unsigned int";;
 726                 (x8) cf_cv_type_of_bool="unsigned long";;
 727                 (*)  cf_cv_type_of_bool=unknown;;
 728                 esac
 729                 ])
 730         rm -f cf_test.out
 731 ])
 732
 733 if test "$cf_cv_type_of_bool" = unknown ; then
 734         case .$NCURSES_BOOL in
 735         (.auto|.) NCURSES_BOOL=unsigned;;
 736         esac
 737         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 738         cf_cv_type_of_bool=$NCURSES_BOOL
 739 fi
 740 ])dnl
 741 dnl ---------------------------------------------------------------------------
 742 dnl CF_BUILD_CC version: 9 updated: 2021/01/02 09:31:20
 743 dnl -----------
 744 dnl If we're cross-compiling, allow the user to override the tools and their
 745 dnl options.  The configure script is oriented toward identifying the host
 746 dnl compiler, etc., but we need a build compiler to generate parts of the
 747 dnl source.
 748 dnl
 749 dnl $1 = default for $CPPFLAGS
 750 dnl $2 = default for $LIBS
 751 AC_DEFUN([CF_BUILD_CC],[
 752 CF_ACVERSION_CHECK(2.52,,
 753         [AC_REQUIRE([CF_PROG_EXT])])
 754 if test "$cross_compiling" = yes ; then
 755
 756         # defaults that we might want to override
 757         : ${BUILD_CFLAGS:=''}
 758         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 759         : ${BUILD_LDFLAGS:=''}
 760         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 761         : ${BUILD_EXEEXT:='$x'}
 762         : ${BUILD_OBJEXT:='o'}
 763
 764         AC_ARG_WITH(build-cc,
 765                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 766                 [BUILD_CC="$withval"],
 767                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 768         AC_MSG_CHECKING(for native build C compiler)
 769         AC_MSG_RESULT($BUILD_CC)
 770
 771         AC_MSG_CHECKING(for native build C preprocessor)
 772         AC_ARG_WITH(build-cpp,
 773                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 774                 [BUILD_CPP="$withval"],
 775                 [BUILD_CPP='${BUILD_CC} -E'])
 776         AC_MSG_RESULT($BUILD_CPP)
 777
 778         AC_MSG_CHECKING(for native build C flags)
 779         AC_ARG_WITH(build-cflags,
 780                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 781                 [BUILD_CFLAGS="$withval"])
 782         AC_MSG_RESULT($BUILD_CFLAGS)
 783
 784         AC_MSG_CHECKING(for native build C preprocessor-flags)
 785         AC_ARG_WITH(build-cppflags,
 786                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 787                 [BUILD_CPPFLAGS="$withval"])
 788         AC_MSG_RESULT($BUILD_CPPFLAGS)
 789
 790         AC_MSG_CHECKING(for native build linker-flags)
 791         AC_ARG_WITH(build-ldflags,
 792                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 793                 [BUILD_LDFLAGS="$withval"])
 794         AC_MSG_RESULT($BUILD_LDFLAGS)
 795
 796         AC_MSG_CHECKING(for native build linker-libraries)
 797         AC_ARG_WITH(build-libs,
 798                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 799                 [BUILD_LIBS="$withval"])
 800         AC_MSG_RESULT($BUILD_LIBS)
 801
 802         # this assumes we're on Unix.
 803         BUILD_EXEEXT=
 804         BUILD_OBJEXT=o
 805
 806         : ${BUILD_CC:='${CC}'}
 807
 808         if { test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}'; } ; then
 809                 AC_MSG_ERROR([Cross-build requires two compilers.
 810 Use --with-build-cc to specify the native compiler.])
 811         fi
 812
 813 else
 814         : ${BUILD_CC:='${CC}'}
 815         : ${BUILD_CPP:='${CPP}'}
 816         : ${BUILD_CFLAGS:='${CFLAGS}'}
 817         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 818         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 819         : ${BUILD_LIBS:='${LIBS}'}
 820         : ${BUILD_EXEEXT:='$x'}
 821         : ${BUILD_OBJEXT:='o'}
 822 fi
 823
 824 AC_SUBST(BUILD_CC)
 825 AC_SUBST(BUILD_CPP)
 826 AC_SUBST(BUILD_CFLAGS)
 827 AC_SUBST(BUILD_CPPFLAGS)
 828 AC_SUBST(BUILD_LDFLAGS)
 829 AC_SUBST(BUILD_LIBS)
 830 AC_SUBST(BUILD_EXEEXT)
 831 AC_SUBST(BUILD_OBJEXT)
 832 ])dnl
 833 dnl ---------------------------------------------------------------------------
 834 dnl CF_C11_NORETURN version: 3 updated: 2021/03/28 11:36:23
 835 dnl ---------------
 836 AC_DEFUN([CF_C11_NORETURN],
 837 [
 838 AC_MSG_CHECKING(if you want to use C11 _Noreturn feature)
 839 CF_ARG_ENABLE(stdnoreturn,
 840         [  --enable-stdnoreturn    enable C11 _Noreturn feature for diagnostics],
 841         [enable_stdnoreturn=yes],
 842         [enable_stdnoreturn=no])
 843 AC_MSG_RESULT($enable_stdnoreturn)
 844
 845 if test $enable_stdnoreturn = yes; then
 846 AC_CACHE_CHECK([for C11 _Noreturn feature], cf_cv_c11_noreturn,
 847         [AC_TRY_COMPILE([
 848 #include <stdio.h>
 849 #include <stdlib.h>
 850 #include <stdnoreturn.h>
 851 static _Noreturn void giveup(void) { exit(0); }
 852         ],
 853         [if (feof(stdin)) giveup()],
 854         cf_cv_c11_noreturn=yes,
 855         cf_cv_c11_noreturn=no)
 856         ])
 857 else
 858         cf_cv_c11_noreturn=no,
 859 fi
 860
 861 if test "$cf_cv_c11_noreturn" = yes; then
 862         AC_DEFINE(HAVE_STDNORETURN_H, 1,[Define if <stdnoreturn.h> header is available and working])
 863         AC_DEFINE_UNQUOTED(STDC_NORETURN,_Noreturn,[Define if C11 _Noreturn keyword is supported])
 864         HAVE_STDNORETURN_H=1
 865 else
 866         HAVE_STDNORETURN_H=0
 867 fi
 868
 869 AC_SUBST(HAVE_STDNORETURN_H)
 870 AC_SUBST(STDC_NORETURN)
 871 ])dnl
 872 dnl ---------------------------------------------------------------------------
 873 dnl CF_CC_ENV_FLAGS version: 10 updated: 2020/12/31 18:40:20
 874 dnl ---------------
 875 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 876 dnl into CC.  This will not help with broken scripts that wrap the compiler
 877 dnl with options, but eliminates a more common category of user confusion.
 878 dnl
 879 dnl In particular, it addresses the problem of being able to run the C
 880 dnl preprocessor in a consistent manner.
 881 dnl
 882 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 883 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 884 dnl outweighs that limitation.
 885 AC_DEFUN([CF_CC_ENV_FLAGS],
 886 [
 887 # This should have been defined by AC_PROG_CC
 888 : "${CC:=cc}"
 889
 890 AC_MSG_CHECKING(\$CFLAGS variable)
 891 case "x$CFLAGS" in
 892 (*-[[IUD]]*)
 893         AC_MSG_RESULT(broken)
 894         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 895         cf_flags="$CFLAGS"
 896         CFLAGS=
 897         for cf_arg in $cf_flags
 898         do
 899                 CF_ADD_CFLAGS($cf_arg)
 900         done
 901         ;;
 902 (*)
 903         AC_MSG_RESULT(ok)
 904         ;;
 905 esac
 906
 907 AC_MSG_CHECKING(\$CC variable)
 908 case "$CC" in
 909 (*[[\ \ ]]-*)
 910         AC_MSG_RESULT(broken)
 911         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 912         # humor him...
 913         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 914         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 915         CC="$cf_prog"
 916         for cf_arg in $cf_flags
 917         do
 918                 case "x$cf_arg" in
 919                 (x-[[IUDfgOW]]*)
 920                         CF_ADD_CFLAGS($cf_arg)
 921                         ;;
 922                 (*)
 923                         CC="$CC $cf_arg"
 924                         ;;
 925                 esac
 926         done
 927         CF_VERBOSE(resulting CC: '$CC')
 928         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 929         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 930         ;;
 931 (*)
 932         AC_MSG_RESULT(ok)
 933         ;;
 934 esac
 935 ])dnl
 936 dnl ---------------------------------------------------------------------------
 937 dnl CF_CFG_DEFAULTS version: 16 updated: 2021/01/04 19:33:05
 938 dnl ---------------
 939 dnl Determine the default configuration into which we'll install ncurses.  This
 940 dnl can be overridden by the user's command-line options.  There's two items to
 941 dnl look for:
 942 dnl     1. the prefix (e.g., /usr)
 943 dnl     2. the header files (e.g., /usr/include/ncurses)
 944 dnl We'll look for a previous installation of ncurses and use the same defaults.
 945 dnl
 946 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 947 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 948 dnl programs from a vendor's.
 949 AC_DEFUN([CF_CFG_DEFAULTS],
 950 [AC_REQUIRE([AC_PROG_FGREP])dnl
 951
 952 AC_MSG_CHECKING(for prefix)
 953 if test "x$prefix" = "xNONE" ; then
 954         case "$cf_cv_system_name" in
 955                 # non-vendor systems don't have a conflict
 956         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 957                 prefix=/usr
 958                 ;;
 959         (*)     prefix=$ac_default_prefix
 960                 ;;
 961         esac
 962 fi
 963 AC_MSG_RESULT($prefix)
 964
 965 if test "x$prefix" = "xNONE" ; then
 966 AC_MSG_CHECKING(for default include-directory)
 967 test -n "$verbose" && echo 1>&AC_FD_MSG
 968 for cf_symbol in \
 969         "$includedir" \
 970         "$includedir/ncurses" \
 971         "$prefix/include" \
 972         "$prefix/include/ncurses" \
 973         /usr/local/include \
 974         /usr/local/include/ncurses \
 975         /usr/include \
 976         /usr/include/ncurses
 977 do
 978         cf_dir=`eval echo "$cf_symbol"`
 979         if test -f "$cf_dir/curses.h" ; then
 980         if ( ${FGREP-fgrep} NCURSES_VERSION "$cf_dir/curses.h" >/dev/null 2>&1 ) ; then
 981                 includedir="$cf_symbol"
 982                 test -n "$verbose"  && echo $ECHO_N "   found " 1>&AC_FD_MSG
 983                 break
 984         fi
 985         fi
 986         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 987 done
 988 AC_MSG_RESULT($includedir)
 989 fi
 990 ])dnl
 991 dnl ---------------------------------------------------------------------------
 992 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
 993 dnl ----------
 994 dnl Check if the terminal-capability database functions are available.  If not,
 995 dnl ncurses has a much-reduced version.
 996 AC_DEFUN([CF_CGETENT],[
 997 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 998 AC_TRY_LINK([
 999 #include <stdlib.h>],[
1000         char temp[128];
1001         char *buf = temp;
1002         char *db_array = temp;
1003         cgetent(&buf, &db_array, "vt100");
1004         cgetcap(buf, "tc", '=');
1005         cgetmatch(buf, "tc");
1006         ],
1007         [cf_cv_cgetent=yes],
1008         [cf_cv_cgetent=no])
1009 ])
1010
1011 if test "$cf_cv_cgetent" = yes
1012 then
1013         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
1014 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
1015 AC_TRY_LINK([
1016 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
1017 #include <stdlib.h>],[
1018         char temp[128];
1019         char *buf = temp;
1020 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
1021         const char *db_array = temp;
1022         cgetent(&buf, &db_array, "vt100");
1023 #endif
1024         cgetcap(buf, "tc", '=');
1025         cgetmatch(buf, "tc");
1026         ],
1027         [cf_cv_cgetent_const=yes],
1028         [cf_cv_cgetent_const=no])
1029 ])
1030         if test "$cf_cv_cgetent_const" = yes
1031         then
1032                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
1033         fi
1034 fi
1035 ])dnl
1036 dnl ---------------------------------------------------------------------------
1037 dnl CF_CHECK_CACHE version: 13 updated: 2020/12/31 10:54:15
1038 dnl --------------
1039 dnl Check if we're accidentally using a cache from a different machine.
1040 dnl Derive the system name, as a check for reusing the autoconf cache.
1041 dnl
1042 dnl If we've packaged config.guess and config.sub, run that (since it does a
1043 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
1044 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
1045 dnl which is useful in cross-compiles.
1046 dnl
1047 dnl Note: we would use $ac_config_sub, but that is one of the places where
1048 dnl autoconf 2.5x broke compatibility with autoconf 2.13
1049 AC_DEFUN([CF_CHECK_CACHE],
1050 [
1051 if test -f "$srcdir/config.guess" || test -f "$ac_aux_dir/config.guess" ; then
1052         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
1053         system_name="$host_os"
1054 else
1055         system_name="`(uname -s -r) 2>/dev/null`"
1056         if test -z "$system_name" ; then
1057                 system_name="`(hostname) 2>/dev/null`"
1058         fi
1059 fi
1060 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
1061 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
1062
1063 test -z "$system_name" && system_name="$cf_cv_system_name"
1064 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
1065
1066 if test ".$system_name" != ".$cf_cv_system_name" ; then
1067         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
1068         AC_MSG_ERROR("Please remove config.cache and try again.")
1069 fi
1070 ])dnl
1071 dnl ---------------------------------------------------------------------------
1072 dnl CF_CHECK_ENVIRON version: 3 updated: 2010/05/26 16:44:57
1073 dnl ----------------
1074 dnl Check for data that is usually declared in <unistd.h>, e.g., the 'environ'
1075 dnl variable.  Define a DECL_xxx symbol if we must declare it ourselves.
1076 dnl
1077 dnl $1 = the name to check
1078 dnl $2 = the assumed type
1079 AC_DEFUN([CF_CHECK_ENVIRON],
1080 [
1081 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1082     AC_TRY_COMPILE([
1083 #ifdef HAVE_STDLIB_H
1084 #include <stdlib.h>
1085 #endif
1086 #include <unistd.h> ],
1087     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
1088     [cf_cv_dcl_$1=yes],
1089     [cf_cv_dcl_$1=no])
1090 ])
1091
1092 if test "$cf_cv_dcl_$1" = no ; then
1093     CF_UPPER(cf_result,decl_$1)
1094     AC_DEFINE_UNQUOTED($cf_result)
1095 fi
1096
1097 # It's possible (for near-UNIX clones) that the data doesn't exist
1098 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1099 ])dnl
1100 dnl ---------------------------------------------------------------------------
1101 dnl CF_CHECK_ERRNO version: 13 updated: 2020/03/10 18:53:47
1102 dnl --------------
1103 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
1104 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
1105 dnl ourselves.
1106 dnl
1107 dnl $1 = the name to check
1108 dnl $2 = the assumed type
1109 AC_DEFUN([CF_CHECK_ERRNO],
1110 [
1111 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1112         AC_TRY_COMPILE([
1113 #ifdef HAVE_STDLIB_H
1114 #include <stdlib.h>
1115 #endif
1116 #include <stdio.h>
1117 #include <sys/types.h>
1118 #include <errno.h> ],
1119         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1; (void)x,
1120         [cf_cv_dcl_$1=yes],
1121         [cf_cv_dcl_$1=no])
1122 ])
1123
1124 if test "$cf_cv_dcl_$1" = no ; then
1125         CF_UPPER(cf_result,decl_$1)
1126         AC_DEFINE_UNQUOTED($cf_result)
1127 fi
1128
1129 # It's possible (for near-UNIX clones) that the data doesn't exist
1130 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1131 ])dnl
1132 dnl ---------------------------------------------------------------------------
1133 dnl CF_CHECK_EXTERN_DATA version: 5 updated: 2021/09/04 06:35:04
1134 dnl --------------------
1135 dnl Check for existence of external data in the current set of libraries.  If
1136 dnl we can modify it, it is real enough.
1137 dnl $1 = the name to check
1138 dnl $2 = its type
1139 AC_DEFUN([CF_CHECK_EXTERN_DATA],
1140 [
1141 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
1142         AC_TRY_LINK([
1143 #undef $1
1144 extern $2 $1;
1145 ],
1146         [$1 = 2],
1147         [cf_cv_have_$1=yes],
1148         [cf_cv_have_$1=no])
1149 ])
1150
1151 if test "$cf_cv_have_$1" = yes ; then
1152         CF_UPPER(cf_result,have_$1)
1153         AC_DEFINE_UNQUOTED($cf_result)
1154 fi
1155
1156 ])dnl
1157 dnl ---------------------------------------------------------------------------
1158 dnl CF_CHECK_FVISIBILITY version: 2 updated: 2020/04/04 16:16:13
1159 dnl --------------------
1160 dnl Check whether the compiler understands -fvisibility=hidden
1161 dnl
1162 dnl $1 = compiler
1163 dnl $2 = compiler-flags variable name
1164 dnl $3 = cache variable to set
1165 AC_DEFUN([CF_CHECK_FVISIBILITY],[
1166 AC_CACHE_CHECK(if $1 -fvisibility=hidden option works,$3,[
1167     cf_save_cflags="[$]$2"
1168     $2="[$]$2 -fvisibility=hidden"
1169     AC_TRY_LINK([
1170 __attribute__ ((visibility("default"))) int somefunc() {return 42;}
1171         ],[
1172         if (somefunc()) return 1;
1173 ],
1174     [$3=yes],
1175     [$3=no])
1176     $2=$cf_save_cflags
1177 ])
1178 ])dnl
1179 dnl ---------------------------------------------------------------------------
1180 dnl CF_CHECK_GETENV version: 2 updated: 2021/01/02 17:09:14
1181 dnl ---------------
1182 dnl Check if repeated getenv calls return the same pointer, e.g., it does not
1183 dnl discard the previous pointer when returning a new one.
1184 AC_DEFUN([CF_CHECK_GETENV],
1185 [
1186 AC_REQUIRE([CF_CHECK_ENVIRON])
1187 AC_CHECK_FUNC( getenv, ,, AC_MSG_ERROR(getenv not found) )
1188 AC_CHECK_FUNCS( putenv setenv strdup )
1189 AC_CACHE_CHECK(if getenv returns consistent values,cf_cv_consistent_getenv,[
1190 AC_TRY_RUN([
1191 #include <stdlib.h>
1192 #include <unistd.h>
1193 #include <stdio.h>
1194 #include <string.h>
1195 #include <sys/types.h>
1196
1197 #if defined(HAVE_ENVIRON) && defined(DECL_ENVIRON) && !defined(environ)
1198 extern char **environ;  /* POSIX, but some systems are not... */
1199 #endif
1200
1201 #if defined(HAVE_STRDUP)
1202 #define str_alloc(s) strdup(s)
1203 #else
1204 #define str_alloc(s) strcpy(malloc(strlen(s) + 1, s))
1205 #endif
1206
1207 static void set_value(const char *name, const char *value)
1208 {
1209 #if defined(HAVE_SETENV)
1210         setenv(name, value, 1);
1211 #elif defined(HAVE_PUTENV)
1212         char buffer[1024];
1213         sprintf(buffer, "%s=%s", name, value);
1214         putenv(str_alloc(buffer));
1215 #else
1216 #error neither putenv/setenv found
1217 #endif
1218 }
1219 int main(void)
1220 {
1221         int pass;
1222         size_t numenv, limit, j;
1223         char **mynames;
1224         char **myvalues;
1225         char **mypointer;
1226         char *equals;
1227         for (numenv = 0; environ[numenv]; ++numenv) ;
1228         limit = numenv + 10;
1229         mynames = (char **) calloc(limit + 1, sizeof(char *));
1230         myvalues = (char **) calloc(limit + 1, sizeof(char *));
1231         mypointer = (char **) calloc(limit + 1, sizeof(char *));
1232 #if defined(HAVE_ENVIRON)
1233         for (j = 0; environ[j]; ++j) {
1234                 mynames[j] = str_alloc(environ[j]);
1235                 equals = strchr(mynames[j], '=');
1236                 if (equals != 0) {
1237                         *equals++ = '\\0';
1238                         myvalues[j] = str_alloc(equals);
1239                 } else {
1240                         myvalues[j] = str_alloc("");
1241                 }
1242         }
1243 #endif
1244         for (j = numenv; j < limit; ++j) {
1245                 char name[80];
1246                 char value[80];
1247                 size_t found;
1248                 size_t k = 0;
1249                 do {
1250                         size_t jk;
1251                         found = 0;
1252                         sprintf(name, "TERM%lu", (unsigned long) k);
1253                         for (jk = 0; jk < j; ++jk) {
1254                                 if (!strcmp(name, mynames[jk])) {
1255                                         found = 1;
1256                                         ++k;
1257                                         break;
1258                                 }
1259                         }
1260                 } while (found);
1261                 sprintf(value, "%lu:%p", (unsigned long) k, &mynames[j]);
1262                 set_value(name, value);
1263                 mynames[j] = str_alloc(name);
1264                 myvalues[j] = str_alloc(value);
1265         }
1266         for (pass = 0; pass < 3; ++pass) {
1267                 for (j = 0; j < limit; ++j) {
1268                         char *value = getenv(mynames[j]);
1269                         if (pass) {
1270                                 if (value == 0) {
1271                                         fprintf(stderr, "getenv returned null for %s\\n", mynames[j]);
1272                                         ${cf_cv_main_return:-return}(1);
1273                                 } else if (value != mypointer[j]) {
1274                                         fprintf(stderr, "getenv returned different pointer for %s\\n", mynames[j]);
1275                                         ${cf_cv_main_return:-return}(1);
1276                                 } else if (strcmp(value, myvalues[j])) {
1277                                         fprintf(stderr, "getenv returned different value for %s\\n", mynames[j]);
1278                                         ${cf_cv_main_return:-return}(1);
1279                                 }
1280                         } else {
1281                                 size_t k;
1282                                 mypointer[j] = value;
1283                                 for (k = 0; k < j; ++k) {
1284                                         if (mypointer[j] == mypointer[k]) {
1285                                                 fprintf(stderr, "getenv returned same pointer for %s and %s\\n", mynames[j], mynames[k]);
1286                                                 ${cf_cv_main_return:-return}(1);
1287                                         }
1288                                 }
1289                         }
1290                 }
1291         }
1292         ${cf_cv_main_return:-return}(0);
1293 }
1294 ],
1295 [cf_cv_consistent_getenv=yes],
1296 [cf_cv_consistent_getenv=no],
1297 [cf_cv_consistent_getenv=unknown])
1298 ])
1299
1300 if test "x$cf_cv_consistent_getenv" = xno
1301 then
1302         AC_DEFINE(HAVE_CONSISTENT_GETENV,1,[Define to 1 if getenv repeatably returns the same value for a given name])
1303 fi
1304 ])dnl
1305 dnl ---------------------------------------------------------------------------
1306 dnl CF_CHECK_GNAT_VERSION version: 4 updated: 2021/01/01 13:31:04
1307 dnl ---------------------
1308 AC_DEFUN([CF_CHECK_GNAT_VERSION],
1309 [
1310 AC_REQUIRE([CF_GNAT_VERSION])
1311 case "$cf_cv_gnat_version" in
1312 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
1313         cf_cv_prog_gnat_correct=yes
1314         ;;
1315 (*)
1316         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1317         cf_cv_prog_gnat_correct=no
1318         ;;
1319 esac
1320 ])
1321 dnl ---------------------------------------------------------------------------
1322 dnl CF_CHECK_GPM_WGETCH version: 6 updated: 2021/01/04 18:48:01
1323 dnl -------------------
1324 dnl Check if GPM is already linked with curses.  If so - and if the linkage
1325 dnl is not "weak" - warn about this because it can create problems linking
1326 dnl applications with ncurses.
1327 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
1328 AC_REQUIRE([AC_PROG_EGREP])dnl
1329
1330 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
1331
1332 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
1333 cf_cv_check_gpm_wgetch=unknown
1334 if test "$cross_compiling" != yes ; then
1335
1336 cat >conftest.$ac_ext <<CF_EOF
1337 #include <gpm.h>
1338 int main(void)
1339 {
1340         Gpm_Wgetch();
1341         ${cf_cv_main_return:-return}(0);
1342 }
1343 CF_EOF
1344
1345         cf_save_LIBS="$LIBS"
1346         # This only works if we can look at the symbol table.  If a shared
1347         # library is stripped for install, we cannot use that.  So we're forced
1348         # to rely on the static library, noting that some packagers may not
1349         # include it.
1350         LIBS="-static -lgpm -dynamic $LIBS"
1351         if AC_TRY_EVAL(ac_compile) ; then
1352                 if AC_TRY_EVAL(ac_link) ; then
1353                         cf_cv_check_gpm_wgetch="`nm \"conftest$ac_exeext\" | ${EGREP-egrep} '\<wgetch\>' | ${EGREP-egrep} '\<[[vVwW]]\>'`"
1354                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1355                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1356                 fi
1357         fi
1358         rm -rf ./conftest*
1359         LIBS="$cf_save_LIBS"
1360 fi
1361 ])
1362
1363 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1364         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1365 fi
1366 ])])dnl
1367 dnl ---------------------------------------------------------------------------
1368 dnl CF_CHECK_LIBSSP version: 1 updated: 2021/10/30 10:40:19
1369 dnl ---------------
1370 dnl Check if libssp is needed, e.g., to work around misconfigured libraries
1371 dnl used in cross-compiling to MinGW.
1372 AC_DEFUN([CF_CHECK_LIBSSP],[
1373 AC_CACHE_CHECK(if ssp library is needed,cf_cv_need_libssp,[
1374 AC_TRY_LINK([
1375 #include <sys/types.h>
1376 #include <dirent.h>
1377 ],[
1378        DIR *dp = opendir(".");
1379 ],cf_cv_need_libssp=no,[
1380         cf_save_LIBS="$LIBS"
1381         LIBS="$LIBS -lssp"
1382         AC_TRY_LINK([
1383 #include <sys/types.h>
1384 #include <dirent.h>
1385         ],[
1386                    DIR *dp = opendir(".");
1387         ],cf_cv_need_libssp=yes,
1388           cf_cv_need_libssp=maybe)
1389         LIBS="$cf_save_LIBS"
1390 ])dnl
1391 ])
1392
1393 if test "x$cf_cv_need_libssp" = xyes
1394 then
1395         CF_ADD_LIB(ssp)
1396 fi
1397 ])dnl
1398 dnl ---------------------------------------------------------------------------
1399 dnl CF_CHECK_LIBTOOL_VERSION version: 2 updated: 2021/05/01 16:24:34
1400 dnl ------------------------
1401 dnl Show the version of libtool
1402 dnl
1403 dnl Save the version in a cache variable - this is not entirely a good thing,
1404 dnl but the version string from libtool is very ugly, and for bug reports it
1405 dnl might be useful to have the original string.
1406 dnl
1407 dnl There is an imitation in OpenBSD, which has no apparent use other than to
1408 dnl deny that it is GNU libtool.  Just ignore it.
1409 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1410 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1411 then
1412         AC_MSG_CHECKING(version of $LIBTOOL)
1413         CF_LIBTOOL_VERSION
1414         AC_MSG_RESULT($cf_cv_libtool_version)
1415         if test -n "$cf_cv_libtool_version"
1416         then
1417                 cf_check_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' -e 's,[[()]],...,g' -e 's,[[ ]],-,g' -e '2,$d'`
1418                 case "x$cf_check_libtool_version" in
1419                 (*...GNU-libtool...*)
1420                         ;;
1421                 (*)
1422                         AC_MSG_ERROR(This is not GNU libtool)
1423                         ;;
1424                 esac
1425         else
1426                 AC_MSG_ERROR(No version found for $LIBTOOL)
1427         fi
1428 else
1429         AC_MSG_ERROR(GNU libtool has not been found)
1430 fi
1431 ])dnl
1432 dnl ---------------------------------------------------------------------------
1433 dnl CF_CHECK_WCHAR_H version: 3 updated: 2021/01/01 13:31:04
1434 dnl ----------------
1435 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1436 AC_DEFUN([CF_CHECK_WCHAR_H],[
1437 AC_CHECK_HEADERS( \
1438 wchar.h \
1439 wctype.h \
1440 )
1441 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1442 AC_TRY_COMPILE(
1443 [
1444 #include <stdlib.h>
1445 #ifdef HAVE_WCHAR_H
1446 #include <wchar.h>
1447 #endif
1448 #ifdef HAVE_WCTYPE_H
1449 #include <wctype.h>
1450 #endif
1451 ],[
1452         wint_t foo = 0;
1453         int bar = iswpunct(foo)],
1454         [cf_cv_wchar_h_okay=yes],
1455         [cf_cv_wchar_h_okay=no])])
1456
1457 if test "$cf_cv_wchar_h_okay" = no
1458 then
1459         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1460 fi
1461 ])dnl
1462 dnl ---------------------------------------------------------------------------
1463 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 2 updated: 2021/01/02 17:09:14
1464 dnl -------------------------
1465 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1466 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1467 dnl
1468 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1469 dnl all of those were combined into a page of useful graphics characters.
1470 dnl
1471 dnl So far, so good.
1472 dnl
1473 dnl However, while they are useful, there are other considerations.  CJK
1474 dnl is (because of poor device resolution) often rendered as double-width
1475 dnl characters.  So... for these generally-useful characters, what should
1476 dnl be the width (to make them consistent with adjacent characters)?
1477 dnl
1478 dnl The obvious choice would have been to make this locale-dependent, and use
1479 dnl wcwidth() to tell applications what the actual width is.  That was too
1480 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1481 dnl See for example
1482 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1483 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1484 dnl
1485 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1486 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1487 dnl instance, it lists half (44/96) of the Latin-1 characters as
1488 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1489 dnl
1490 dnl What this means for the implementor is that on some systems wcwidth() can
1491 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1492 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1493 dnl characters).  These do not necessarily match the behavior of the terminal
1494 dnl emulator.  xterm, for instance, does an optional startup check to find if
1495 dnl this problem (or similar) exists with the system's locale tables, rejecting
1496 dnl them if they are too unreliable.
1497 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1498 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1499 cat >conftest.in <<CF_EOF
1500 -       VT100 symbols
1501 0x250c  upper left corner
1502 0x2514  lower left corner
1503 0x2510  upper right corner
1504 0x2518  lower right corner
1505 0x251c  tee pointing left
1506 0x2524  tee pointing right
1507 0x2534  tee pointing up
1508 0x252c  tee pointing down
1509 0x2500  horizontal line
1510 0x2502  vertical line
1511 0x253c  large plus or crossover
1512 0x23ba  scan line 1
1513 0x23bd  scan line 9
1514 0x25c6  diamond
1515 0x2592  checker board (stipple)
1516 0x00b0  degree symbol
1517 0x00b1  plus/minus
1518 0x00b7  bullet
1519 -       Teletype 5410v1 symbols
1520 0x2190  arrow pointing left
1521 0x2192  arrow pointing right
1522 0x2193  arrow pointing down
1523 0x2191  arrow pointing up
1524 0x2592  board of squares
1525 0x2603  lantern symbol
1526 0x25ae  solid square block
1527 -       these defaults were invented for ncurses
1528 0x23bb  scan line 3
1529 0x23bc  scan line 7
1530 0x2264  less-than-or-equal-to
1531 0x2265  greater-than-or-equal-to
1532 0x03c0  greek pi
1533 0x2260  not-equal
1534 0x00a3  pound-sterling symbol
1535 -       thick-line-drawing
1536 0x250f  upper left corner
1537 0x2517  lower left corner
1538 0x2513  upper right corner
1539 0x251b  lower right corner
1540 0x2523  tee pointing left
1541 0x252b  tee pointing right
1542 0x253b  tee pointing up
1543 0x2533  tee pointing down
1544 0x2501  horizontal line
1545 0x2503  vertical line
1546 0x254b  large plus or crossover
1547 -       double-line-drawing
1548 0x2554  upper left corner
1549 0x255a  lower left corner
1550 0x2557  upper right corner
1551 0x255d  lower right corner
1552 0x2563  tee pointing left
1553 0x2560  tee pointing right
1554 0x2569  tee pointing up
1555 0x2566  tee pointing down
1556 0x2550  horizontal line
1557 0x2551  vertical line
1558 0x256c  large plus or crossover
1559 CF_EOF
1560 AC_TRY_RUN([
1561 #include <locale.h>
1562 #include <stdio.h>
1563 #include <wchar.h>
1564
1565 #define MY_LEN 80
1566
1567 int
1568 main(void)
1569 {
1570         FILE *fp;
1571         int value;
1572         char buffer[MY_LEN + 1];
1573         char notes[MY_LEN + 1];
1574         int totals = 0;
1575         int passed = 0;
1576
1577         if (setlocale(LC_ALL, "en_US.UTF8") ||
1578                 setlocale(LC_ALL, "en_US.UTF-8") ||
1579                 setlocale(LC_ALL, "en_US.utf8") ||
1580                 setlocale(LC_ALL, "en_US.utf-8")) {
1581                 if ((fp = fopen("conftest.in", "r")) != 0) {
1582                         while (fgets(buffer, MY_LEN, fp) != 0) {
1583                                 if (*buffer == '-') {
1584                                         fprintf(stderr, "\\t%s", buffer);
1585                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1586                                         ++totals;
1587                                         if (wcwidth(value) == 1)
1588                                                 ++passed;
1589                                         fprintf(stderr, "%d\\t%s", wcwidth(value), buffer);
1590                                 } else {
1591                                         fprintf(stderr, "?\\t%s", buffer);
1592                                 }
1593                         }
1594                 }
1595         }
1596         fprintf(stderr, "%d/%d passed wcwidth/graphics check\\n", passed, totals);
1597         return (totals == passed) ? 0 : 1;
1598 }
1599 ],
1600 [cf_cv_wcwidth_graphics=yes],
1601 [cf_cv_wcwidth_graphics=no],
1602 [cf_cv_wcwidth_graphics=unknown])
1603 ])
1604 ])dnl
1605 dnl ---------------------------------------------------------------------------
1606 dnl CF_CLANG_COMPILER version: 8 updated: 2021/01/01 13:31:04
1607 dnl -----------------
1608 dnl Check if the given compiler is really clang.  clang's C driver defines
1609 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1610 dnl not ignore some gcc options.
1611 dnl
1612 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1613 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1614 dnl the wrappers for gcc and g++ warnings.
1615 dnl
1616 dnl $1 = GCC (default) or GXX
1617 dnl $2 = CLANG_COMPILER (default)
1618 dnl $3 = CFLAGS (default) or CXXFLAGS
1619 AC_DEFUN([CF_CLANG_COMPILER],[
1620 ifelse([$2],,CLANG_COMPILER,[$2])=no
1621
1622 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1623         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1624         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1625         AC_TRY_COMPILE([],[
1626 #ifdef __clang__
1627 #else
1628 make an error
1629 #endif
1630 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1631 ],[])
1632         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1633         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1634 fi
1635
1636 CLANG_VERSION=none
1637
1638 if test "x$ifelse([$2],,CLANG_COMPILER,[$2])" = "xyes" ; then
1639         case "$CC" in
1640         (c[[1-9]][[0-9]]|*/c[[1-9]][[0-9]])
1641                 AC_MSG_WARN(replacing broken compiler alias $CC)
1642                 CFLAGS="$CFLAGS -std=`echo "$CC" | sed -e 's%.*/%%'`"
1643                 CC=clang
1644                 ;;
1645         esac
1646
1647         AC_MSG_CHECKING(version of $CC)
1648         CLANG_VERSION="`$CC --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(CLANG[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1649         test -z "$CLANG_VERSION" && CLANG_VERSION=unknown
1650         AC_MSG_RESULT($CLANG_VERSION)
1651
1652         for cf_clang_opt in \
1653                 -Qunused-arguments \
1654                 -Wno-error=implicit-function-declaration
1655         do
1656                 AC_MSG_CHECKING(if option $cf_clang_opt works)
1657                 cf_save_CFLAGS="$CFLAGS"
1658                 CFLAGS="$CFLAGS $cf_clang_opt"
1659                 AC_TRY_LINK([
1660                         #include <stdio.h>],[
1661                         printf("hello!\\n");],[
1662                         cf_clang_optok=yes],[
1663                         cf_clang_optok=no])
1664                 AC_MSG_RESULT($cf_clang_optok)
1665                 CFLAGS="$cf_save_CFLAGS"
1666                 if test "$cf_clang_optok" = yes; then
1667                         CF_VERBOSE(adding option $cf_clang_opt)
1668                         CF_APPEND_TEXT(CFLAGS,$cf_clang_opt)
1669                 fi
1670         done
1671 fi
1672 ])
1673 dnl ---------------------------------------------------------------------------
1674 dnl CF_CONST_X_STRING version: 7 updated: 2021/06/07 17:39:17
1675 dnl -----------------
1676 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
1677 dnl character-strings.
1678 dnl
1679 dnl It is ambiguous because the specification accommodated the pre-ANSI
1680 dnl compilers bundled by more than one vendor in lieu of providing a standard C
1681 dnl compiler other than by costly add-ons.  Because of this, the specification
1682 dnl did not take into account the use of const for telling the compiler that
1683 dnl string literals would be in readonly memory.
1684 dnl
1685 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
1686 dnl let the compiler decide how to represent Xt's strings which were #define'd.
1687 dnl That does not solve the problem of using the block of Xt's strings which
1688 dnl are compiled into the library (and is less efficient than one might want).
1689 dnl
1690 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
1691 dnl when compiling the library and compiling using the library, to tell the
1692 dnl compiler that String is const.
1693 AC_DEFUN([CF_CONST_X_STRING],
1694 [
1695 AC_REQUIRE([AC_PATH_XTRA])
1696
1697 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
1698
1699 AC_TRY_COMPILE(
1700 [
1701 #include <stdlib.h>
1702 #include <X11/Intrinsic.h>
1703 ],
1704 [String foo = malloc(1); free((void*)foo)],[
1705
1706 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
1707         AC_TRY_COMPILE(
1708                 [
1709 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
1710 #undef  XTSTRINGDEFINES /* X11R5 and later */
1711 #include <stdlib.h>
1712 #include <X11/Intrinsic.h>
1713                 ],[String foo = malloc(1); *foo = 0],[
1714                         cf_cv_const_x_string=no
1715                 ],[
1716                         cf_cv_const_x_string=yes
1717                 ])
1718 ])
1719
1720 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
1721
1722 case "$cf_cv_const_x_string" in
1723 (no)
1724         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
1725         ;;
1726 (*)
1727         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
1728         ;;
1729 esac
1730
1731 ])
1732 ])dnl
1733 dnl ---------------------------------------------------------------------------
1734 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1735 dnl -----------------
1736 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1737 dnl is a late feature for the standard and is not in some recent compilers
1738 dnl (1999/9/11).
1739 AC_DEFUN([CF_CPP_PARAM_INIT],
1740 [
1741 if test -n "$CXX"; then
1742 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1743         AC_LANG_SAVE
1744         AC_LANG_CPLUSPLUS
1745         AC_TRY_RUN([
1746 class TEST {
1747 private:
1748         int value;
1749 public:
1750         TEST(int x = 1);
1751         ~TEST();
1752 };
1753
1754 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1755 {
1756         value = x;
1757 }
1758 int main(void) { }
1759 ],
1760         [cf_cv_cpp_param_init=yes],
1761         [cf_cv_cpp_param_init=no],
1762         [cf_cv_cpp_param_init=unknown])
1763         AC_LANG_RESTORE
1764 ])
1765 fi
1766 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1767 ])dnl
1768 dnl ---------------------------------------------------------------------------
1769 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1770 dnl ------------------
1771 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1772 dnl not be supported in g++ before 3.0
1773 AC_DEFUN([CF_CPP_STATIC_CAST],
1774 [
1775 if test -n "$CXX"; then
1776
1777 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1778         AC_LANG_SAVE
1779         AC_LANG_CPLUSPLUS
1780
1781         AC_TRY_COMPILE([
1782 class NCursesPanel
1783 {
1784 public:
1785   NCursesPanel(int nlines,
1786                int ncols,
1787                int begin_y = 0,
1788                int begin_x = 0)
1789   {
1790   }
1791   NCursesPanel();
1792   ~NCursesPanel();
1793 };
1794
1795 template<class T> class NCursesUserPanel : public NCursesPanel
1796 {
1797 public:
1798   NCursesUserPanel (int nlines,
1799                     int ncols,
1800                     int begin_y = 0,
1801                     int begin_x = 0,
1802                     const T* p_UserData = static_cast<T*>(0))
1803     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1804   {
1805   };
1806   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1807   {
1808   };
1809
1810   virtual ~NCursesUserPanel() {};
1811 };
1812 ],[
1813         const char* p_UserData = static_cast<char*>(0)],
1814         [cf_cv_cpp_static_cast=yes],
1815         [cf_cv_cpp_static_cast=no])
1816
1817         AC_LANG_RESTORE
1818 ])
1819
1820 fi
1821
1822 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1823 ])dnl
1824 dnl ---------------------------------------------------------------------------
1825 dnl CF_CXX_AR_FLAGS version: 3 updated: 2021/01/01 13:31:04
1826 dnl ---------------
1827 dnl Setup special archiver flags for given compilers.
1828 AC_DEFUN([CF_CXX_AR_FLAGS],[
1829         CXX_AR='$(AR)'
1830         CXX_ARFLAGS='$(ARFLAGS)'
1831         case "$cf_cv_system_name" in
1832         (irix*)
1833             if test "$GXX" != yes ; then
1834                 CXX_AR='$(CXX)'
1835                 CXX_ARFLAGS='-ar -o'
1836             fi
1837             ;;
1838         (sco3.2v5*)
1839             CXXLDFLAGS="-u main"
1840             ;;
1841         (solaris2*)
1842             if test "$GXX" != yes ; then
1843                 CXX_AR='$(CXX)'
1844                 CXX_ARFLAGS='-xar -o'
1845             fi
1846             ;;
1847         esac
1848         AC_SUBST(CXXLDFLAGS)
1849         AC_SUBST(CXX_AR)
1850         AC_SUBST(CXX_ARFLAGS)
1851 ])dnl
1852 dnl ---------------------------------------------------------------------------
1853 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1854 dnl -------------------------
1855 dnl For c++, check if iostream uses "std::" namespace.
1856 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1857 AC_CHECK_HEADERS(iostream)
1858 if test x"$ac_cv_header_iostream" = xyes ; then
1859         AC_MSG_CHECKING(if iostream uses std-namespace)
1860         AC_TRY_COMPILE([
1861 #include <iostream>
1862 using std::endl;
1863 using std::cerr;],[
1864 cerr << "testing" << endl;
1865 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1866         AC_MSG_RESULT($cf_iostream_namespace)
1867         if test "$cf_iostream_namespace" = yes ; then
1868                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1869         fi
1870 fi
1871 ])dnl
1872 dnl ---------------------------------------------------------------------------
1873 dnl CF_C_INLINE version: 6 updated: 2019/09/07 13:38:36
1874 dnl -----------
1875 dnl Check if the C compiler supports "inline".
1876 dnl $1 is the name of a shell variable to set if inline is supported
1877 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1878 AC_DEFUN([CF_C_INLINE],[
1879 AC_REQUIRE([CF_GCC_VERSION])
1880 AC_C_INLINE
1881 $1=
1882 if test "$ac_cv_c_inline" != no ; then
1883         $1=inline
1884         if test "$INTEL_COMPILER" = yes
1885         then
1886                 :
1887         elif test "$CLANG_COMPILER" = yes
1888         then
1889                 :
1890         elif test "$GCC" = yes
1891         then
1892                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1893                 cf_save_CFLAGS=$CFLAGS
1894                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1895                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1896                 [${cf_cv_main_return:-return} foo()],
1897                 [cf_cv_gcc_inline=yes],
1898                 [cf_cv_gcc_inline=no])
1899                 CFLAGS=$cf_save_CFLAGS
1900                 ])
1901                 if test "$cf_cv_gcc_inline" = yes ; then
1902                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1903                 fi
1904         fi
1905 fi
1906 AC_SUBST($1)
1907 ])dnl
1908 dnl ---------------------------------------------------------------------------
1909 dnl CF_DIRNAME version: 5 updated: 2020/12/31 20:19:42
1910 dnl ----------
1911 dnl "dirname" is not portable, so we fake it with a shell script.
1912 AC_DEFUN([CF_DIRNAME],[$1=`echo "$2" | sed -e 's%/[[^/]]*$%%'`])dnl
1913 dnl ---------------------------------------------------------------------------
1914 dnl CF_DIRS_TO_MAKE version: 4 updated: 2021/01/01 13:31:04
1915 dnl ---------------
1916 AC_DEFUN([CF_DIRS_TO_MAKE],
1917 [
1918 DIRS_TO_MAKE="lib"
1919 for cf_item in $cf_list_models
1920 do
1921         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1922         for cf_item2 in $DIRS_TO_MAKE
1923         do
1924                 test "$cf_item2" = "$cf_subdir" && break
1925         done
1926         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1927 done
1928 for cf_dir in $DIRS_TO_MAKE
1929 do
1930         test ! -d "$cf_dir" && mkdir "$cf_dir"
1931 done
1932 AC_SUBST(DIRS_TO_MAKE)
1933 ])dnl
1934 dnl ---------------------------------------------------------------------------
1935 dnl CF_DISABLE_ECHO version: 14 updated: 2021/09/04 06:35:04
1936 dnl ---------------
1937 dnl You can always use "make -n" to see the actual options, but it is hard to
1938 dnl pick out/analyze warning messages when the compile-line is long.
1939 dnl
1940 dnl Sets:
1941 dnl     ECHO_LT - symbol to control if libtool is verbose
1942 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1943 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1944 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1945 dnl     ECHO_CC - symbol to put before any "cc" line
1946 dnl
1947 AC_DEFUN([CF_DISABLE_ECHO],[
1948 AC_MSG_CHECKING(if you want to see long compiling messages)
1949 CF_ARG_DISABLE(echo,
1950         [  --disable-echo          do not display "compiling" commands],
1951         [
1952         ECHO_LT='--silent'
1953         ECHO_LD='@echo linking [$]@;'
1954         RULE_CC='@echo compiling [$]<'
1955         SHOW_CC='@echo compiling [$]@'
1956         ECHO_CC='@'
1957 ],[
1958         ECHO_LT=''
1959         ECHO_LD=''
1960         RULE_CC=''
1961         SHOW_CC=''
1962         ECHO_CC=''
1963 ])
1964 AC_MSG_RESULT($enableval)
1965 AC_SUBST(ECHO_LT)
1966 AC_SUBST(ECHO_LD)
1967 AC_SUBST(RULE_CC)
1968 AC_SUBST(SHOW_CC)
1969 AC_SUBST(ECHO_CC)
1970 ])dnl
1971 dnl ---------------------------------------------------------------------------
1972 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1973 dnl ------------------------
1974 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1975 AC_MSG_CHECKING(if we want to use GNAT projects)
1976 CF_ARG_DISABLE(gnat-projects,
1977         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1978         [enable_gnat_projects=no],
1979         [enable_gnat_projects=yes])
1980 AC_MSG_RESULT($enable_gnat_projects)
1981 ])dnl
1982 dnl ---------------------------------------------------------------------------
1983 dnl CF_DISABLE_LEAKS version: 9 updated: 2021/04/03 16:41:50
1984 dnl ----------------
1985 dnl Combine no-leak checks with the libraries or tools that are used for the
1986 dnl checks.
1987 AC_DEFUN([CF_DISABLE_LEAKS],[
1988
1989 AC_REQUIRE([CF_WITH_DMALLOC])
1990 AC_REQUIRE([CF_WITH_DBMALLOC])
1991 AC_REQUIRE([CF_WITH_VALGRIND])
1992
1993 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1994 AC_ARG_ENABLE(leaks,
1995         [  --disable-leaks         test: free permanent memory, analyze leaks],
1996         [enable_leaks=$enableval],
1997         [enable_leaks=yes])
1998 dnl with_no_leaks is more readable...
1999 if test "x$enable_leaks" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi
2000 AC_MSG_RESULT($with_no_leaks)
2001
2002 if test "$enable_leaks" = no ; then
2003         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
2004         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
2005 fi
2006 ])dnl
2007 dnl ---------------------------------------------------------------------------
2008 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
2009 dnl --------------------------
2010 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
2011 dnl the older "-version-info" feature.  The newer feature allows us to use
2012 dnl version numbering on shared libraries which make them compatible with
2013 dnl various systems.
2014 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
2015 [
2016 AC_MSG_CHECKING(if libtool -version-number should be used)
2017 CF_ARG_DISABLE(libtool-version,
2018         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
2019         [cf_libtool_version=no],
2020         [cf_libtool_version=yes])
2021 AC_MSG_RESULT($cf_libtool_version)
2022
2023 if test "$cf_libtool_version" = yes ; then
2024         LIBTOOL_VERSION="-version-number"
2025 else
2026         LIBTOOL_VERSION="-version-info"
2027         case "x$VERSION" in
2028         (x)
2029                 AC_MSG_WARN(VERSION was not set)
2030                 ;;
2031         (x*.*.*)
2032                 ABI_VERSION="$VERSION"
2033                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
2034                 ;;
2035         (x*:*:*)
2036                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
2037                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
2038                 ;;
2039         (*)
2040                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
2041                 ;;
2042         esac
2043 fi
2044
2045 AC_SUBST(ABI_VERSION)
2046 AC_SUBST(LIBTOOL_VERSION)
2047 ])dnl
2048 dnl ---------------------------------------------------------------------------
2049 dnl CF_DISABLE_RPATH_HACK version: 3 updated: 2021/01/05 20:14:44
2050 dnl ---------------------
2051 dnl The rpath-hack makes it simpler to build programs, particularly with the
2052 dnl *BSD ports which may have essential libraries in unusual places.  But it
2053 dnl can interfere with building an executable for the base system.  Use this
2054 dnl option in that case.
2055 AC_DEFUN([CF_DISABLE_RPATH_HACK],
2056 [
2057 AC_MSG_CHECKING(if rpath-hack should be disabled)
2058 CF_ARG_DISABLE(rpath-hack,
2059         [  --disable-rpath-hack    don't add rpath options for additional libraries],
2060         [enable_rpath_hack=no],
2061         [enable_rpath_hack=yes])
2062 dnl TODO - drop cf_disable_rpath_hack
2063 if test "x$enable_rpath_hack" = xno; then cf_disable_rpath_hack=yes; else cf_disable_rpath_hack=no; fi
2064 AC_MSG_RESULT($cf_disable_rpath_hack)
2065
2066 if test "$enable_rpath_hack" = yes ; then
2067         CF_RPATH_HACK
2068 fi
2069 ])
2070 dnl ---------------------------------------------------------------------------
2071 dnl CF_ENABLE_BROKEN_LINKER version: 2 updated: 2021/01/02 17:09:14
2072 dnl -----------------------
2073 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
2074 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
2075 dnl an unconditional feature.
2076 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
2077
2078 AC_MSG_CHECKING(if you want broken-linker support code)
2079 AC_ARG_ENABLE(broken_linker,
2080         [  --enable-broken_linker  compile with broken-linker support code],
2081         [with_broken_linker=$enableval],
2082         [with_broken_linker=no])
2083 AC_MSG_RESULT($with_broken_linker)
2084
2085 : "${BROKEN_LINKER:=0}"
2086 if test "x$with_broken_linker" = xyes ; then
2087         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
2088         BROKEN_LINKER=1
2089 fi
2090 AC_SUBST(BROKEN_LINKER)
2091 ])dnl
2092 dnl ---------------------------------------------------------------------------
2093 dnl CF_ENABLE_PC_FILES version: 16 updated: 2021/11/20 12:48:37
2094 dnl ------------------
2095 dnl This is the "--enable-pc-files" option, which is available if there is a
2096 dnl pkg-config configuration on the local machine.
2097 AC_DEFUN([CF_ENABLE_PC_FILES],[
2098 AC_REQUIRE([CF_PKG_CONFIG])
2099 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
2100
2101 if test "x$PKG_CONFIG" != xnone
2102 then
2103         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
2104 else
2105         AC_MSG_CHECKING(if we should install .pc files)
2106 fi
2107
2108 AC_ARG_ENABLE(pc-files,
2109         [  --enable-pc-files       generate and install .pc files for pkg-config],
2110         [enable_pc_files=$enableval],
2111         [enable_pc_files=no])
2112 AC_MSG_RESULT($enable_pc_files)
2113
2114 if test "x$enable_pc_files" != xno
2115 then
2116         MAKE_PC_FILES=
2117         case "x$PKG_CONFIG_LIBDIR" in
2118         (xno|xnone|xyes|x)
2119                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
2120                 ;;
2121         (*)
2122                 cf_pkg_config_libdir="$PKG_CONFIG_LIBDIR"
2123                 CF_PATH_SYNTAX(cf_pkg_config_libdir)
2124                 ;;
2125         esac
2126 else
2127         MAKE_PC_FILES="#"
2128 fi
2129 AC_SUBST(MAKE_PC_FILES)
2130 ])dnl
2131 dnl ---------------------------------------------------------------------------
2132 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
2133 dnl ---------------
2134 dnl Check if the rpath option should be used, setting cache variable
2135 dnl cf_cv_enable_rpath if so.
2136 AC_DEFUN([CF_ENABLE_RPATH],
2137 [
2138 AC_MSG_CHECKING(if rpath option should be used)
2139 AC_ARG_ENABLE(rpath,
2140 [  --enable-rpath          use rpath option when generating shared libraries],
2141 [cf_cv_enable_rpath=$enableval],
2142 [cf_cv_enable_rpath=no])
2143 AC_MSG_RESULT($cf_cv_enable_rpath)
2144 ])dnl
2145 dnl ---------------------------------------------------------------------------
2146 dnl CF_ENABLE_STRING_HACKS version: 6 updated: 2021/01/05 19:23:48
2147 dnl ----------------------
2148 dnl On a few platforms, the compiler and/or loader nags with untruthful
2149 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
2150 dnl and implying that most uses of the recommended alternatives are correct.
2151 dnl
2152 dnl Factually speaking, no one has actually counted the number of uses of these
2153 dnl functions versus the total of incorrect uses.  Samples of a few thousand
2154 dnl instances are meaningless compared to the hundreds of millions of lines of
2155 dnl existing C code.
2156 dnl
2157 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
2158 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
2159 dnl standard - but evolved through phases, and older implementations are likely
2160 dnl to yield surprising results, as documented in manpages on various systems.
2161 AC_DEFUN([CF_ENABLE_STRING_HACKS],
2162 [
2163 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
2164 AC_ARG_ENABLE(string-hacks,
2165         [  --enable-string-hacks   work around bogus compiler/loader warnings],
2166         [enable_string_hacks=$enableval],
2167         [enable_string_hacks=no])
2168 AC_MSG_RESULT($enable_string_hacks)
2169
2170 if test "x$enable_string_hacks" = "xyes"; then
2171         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
2172         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
2173         AC_CHECK_FUNC(strlcat,[
2174                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2175                 ],[
2176                 AC_CHECK_LIB(bsd,strlcat,[
2177                         CF_ADD_LIB(bsd)
2178                         AC_CHECK_HEADERS(bsd/string.h)
2179                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2180                         ])
2181                 ])
2182         AC_CHECK_FUNCS( strlcpy snprintf )
2183 fi
2184 ])dnl
2185 dnl ---------------------------------------------------------------------------
2186 dnl CF_ENABLE_WARNINGS version: 9 updated: 2021/01/05 19:40:50
2187 dnl ------------------
2188 dnl Configure-option to enable gcc warnings
2189 dnl
2190 dnl $1 = extra options to add, if supported
2191 dnl $2 = option for checking attributes.  By default, this is done when
2192 dnl      warnings are enabled.  For other values:
2193 dnl      yes: always do this, e.g., to use in generated library-headers
2194 dnl      no: never do this
2195 AC_DEFUN([CF_ENABLE_WARNINGS],[
2196 if test "$GCC" = yes || test "$GXX" = yes
2197 then
2198 CF_FIX_WARNINGS(CFLAGS)
2199 CF_FIX_WARNINGS(CPPFLAGS)
2200 CF_FIX_WARNINGS(LDFLAGS)
2201 AC_MSG_CHECKING(if you want to turn on gcc warnings)
2202 CF_ARG_ENABLE(warnings,
2203         [  --enable-warnings       test: turn on gcc compiler warnings],
2204         [enable_warnings=yes],
2205         [enable_warnings=no])
2206 AC_MSG_RESULT($enable_warnings)
2207 if test "$enable_warnings" = "yes"
2208 then
2209         ifelse($2,,[CF_GCC_ATTRIBUTES])
2210         CF_GCC_WARNINGS($1)
2211 fi
2212 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
2213 fi
2214 ])dnl
2215 dnl ---------------------------------------------------------------------------
2216 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
2217 dnl --------
2218 dnl Check if 'errno' is declared in <errno.h>
2219 AC_DEFUN([CF_ERRNO],
2220 [
2221 CF_CHECK_ERRNO(errno)
2222 ])dnl
2223 dnl ---------------------------------------------------------------------------
2224 dnl CF_ETIP_DEFINES version: 6 updated: 2021/01/02 17:09:14
2225 dnl ---------------
2226 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
2227 dnl math.h and builtin.h, only for ncurses
2228 AC_DEFUN([CF_ETIP_DEFINES],
2229 [
2230 AC_MSG_CHECKING(for special defines needed for etip.h)
2231 cf_save_CXXFLAGS="$CXXFLAGS"
2232 cf_result="none"
2233
2234 # etip.h includes ncurses.h which includes ncurses_dll.h
2235 # But ncurses_dll.h is generated - fix here.
2236 test -d include || mkdir include
2237 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' "${srcdir}/include/ncurses_dll.h.in" >include/ncurses_dll.h
2238
2239 for cf_math in "" MATH_H
2240 do
2241 for cf_excp in "" MATH_EXCEPTION
2242 do
2243         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
2244         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
2245         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
2246 AC_TRY_COMPILE([
2247 #include <etip.h.in>
2248 ],[],[
2249         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
2250         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
2251         cf_result="$cf_math $cf_excp"
2252         break 2
2253 ],[])
2254 done
2255 done
2256 AC_MSG_RESULT($cf_result)
2257 CXXFLAGS="$cf_save_CXXFLAGS"
2258 ])
2259 dnl ---------------------------------------------------------------------------
2260 dnl CF_FIND_LINKAGE version: 22 updated: 2020/12/31 20:19:42
2261 dnl ---------------
2262 dnl Find a library (specifically the linkage used in the code fragment),
2263 dnl searching for it if it is not already in the library path.
2264 dnl See also CF_ADD_SEARCHPATH.
2265 dnl
2266 dnl Parameters (4-on are optional):
2267 dnl     $1 = headers for library entrypoint
2268 dnl     $2 = code fragment for library entrypoint
2269 dnl     $3 = the library name without the "-l" option or ".so" suffix.
2270 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
2271 dnl     $5 = action to perform if not successful
2272 dnl     $6 = module name, if not the same as the library name
2273 dnl     $7 = extra libraries
2274 dnl
2275 dnl Sets these variables:
2276 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
2277 dnl     $cf_cv_header_path_$3 - include-directory if needed
2278 dnl     $cf_cv_library_path_$3 - library-directory if needed
2279 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
2280 AC_DEFUN([CF_FIND_LINKAGE],[
2281
2282 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
2283 # will be set on completion of the AC_TRY_LINK below.
2284 cf_cv_header_path_$3=
2285 cf_cv_library_path_$3=
2286
2287 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
2288
2289 cf_save_LIBS="$LIBS"
2290
2291 AC_TRY_LINK([$1],[$2],[
2292         cf_cv_find_linkage_$3=yes
2293         cf_cv_header_path_$3=/usr/include
2294         cf_cv_library_path_$3=/usr/lib
2295 ],[
2296
2297 LIBS="-l$3 $7 $cf_save_LIBS"
2298
2299 AC_TRY_LINK([$1],[$2],[
2300         cf_cv_find_linkage_$3=yes
2301         cf_cv_header_path_$3=/usr/include
2302         cf_cv_library_path_$3=/usr/lib
2303         cf_cv_library_file_$3="-l$3"
2304 ],[
2305         cf_cv_find_linkage_$3=no
2306         LIBS="$cf_save_LIBS"
2307
2308         CF_VERBOSE(find linkage for $3 library)
2309         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
2310
2311         cf_save_CPPFLAGS="$CPPFLAGS"
2312         cf_test_CPPFLAGS="$CPPFLAGS"
2313
2314         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
2315         for cf_cv_header_path_$3 in $cf_search
2316         do
2317                 if test -d "$cf_cv_header_path_$3" ; then
2318                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
2319                         CPPFLAGS="$cf_save_CPPFLAGS"
2320                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
2321                         AC_TRY_COMPILE([$1],[$2],[
2322                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
2323                                 cf_cv_find_linkage_$3=maybe
2324                                 cf_test_CPPFLAGS="$CPPFLAGS"
2325                                 break],[
2326                                 CPPFLAGS="$cf_save_CPPFLAGS"
2327                                 ])
2328                 fi
2329         done
2330
2331         if test "$cf_cv_find_linkage_$3" = maybe ; then
2332
2333                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
2334
2335                 cf_save_LIBS="$LIBS"
2336                 cf_save_LDFLAGS="$LDFLAGS"
2337
2338                 ifelse([$6],,,[
2339                 CPPFLAGS="$cf_test_CPPFLAGS"
2340                 LIBS="-l$3 $7 $cf_save_LIBS"
2341                 AC_TRY_LINK([$1],[$2],[
2342                         CF_VERBOSE(... found $3 library in system)
2343                         cf_cv_find_linkage_$3=yes])
2344                         CPPFLAGS="$cf_save_CPPFLAGS"
2345                         LIBS="$cf_save_LIBS"
2346                         ])
2347
2348                 if test "$cf_cv_find_linkage_$3" != yes ; then
2349                         CF_LIBRARY_PATH(cf_search,$3)
2350                         for cf_cv_library_path_$3 in $cf_search
2351                         do
2352                                 if test -d "$cf_cv_library_path_$3" ; then
2353                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
2354                                         CPPFLAGS="$cf_test_CPPFLAGS"
2355                                         LIBS="-l$3 $7 $cf_save_LIBS"
2356                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
2357                                         AC_TRY_LINK([$1],[$2],[
2358                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
2359                                         cf_cv_find_linkage_$3=yes
2360                                         cf_cv_library_file_$3="-l$3"
2361                                         break],[
2362                                         CPPFLAGS="$cf_save_CPPFLAGS"
2363                                         LIBS="$cf_save_LIBS"
2364                                         LDFLAGS="$cf_save_LDFLAGS"
2365                                         ])
2366                                 fi
2367                         done
2368                         CPPFLAGS="$cf_save_CPPFLAGS"
2369                         LDFLAGS="$cf_save_LDFLAGS"
2370                 fi
2371
2372         else
2373                 cf_cv_find_linkage_$3=no
2374         fi
2375         ],$7)
2376 ])
2377
2378 LIBS="$cf_save_LIBS"
2379
2380 if test "$cf_cv_find_linkage_$3" = yes ; then
2381 ifelse([$4],,[
2382         CF_ADD_INCDIR($cf_cv_header_path_$3)
2383         CF_ADD_LIBDIR($cf_cv_library_path_$3)
2384         CF_ADD_LIB($3)
2385 ],[$4])
2386 else
2387 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
2388 fi
2389 ])dnl
2390 dnl ---------------------------------------------------------------------------
2391 dnl CF_FIND_SUB_INCDIR version: 3 updated: 2021/01/01 13:31:04
2392 dnl ------------------
2393 dnl Find an include-directory with the given leaf-name.  This is useful for
2394 dnl example with FreeBSD ports, which use this convention to distinguish
2395 dnl different versions of the same port.
2396 AC_DEFUN([CF_FIND_SUB_INCDIR],[
2397         CF_SUBDIR_PATH(cf_search,$1,include)
2398         for cf_item in $cf_search
2399         do
2400                 case "$cf_item" in
2401                 (*/$1)
2402                         CF_ADD_INCDIR($cf_item)
2403                         ;;
2404                 esac
2405         done
2406 ])dnl
2407 dnl ---------------------------------------------------------------------------
2408 dnl CF_FIND_SUB_LIBDIR version: 3 updated: 2021/01/01 13:31:04
2409 dnl ------------------
2410 dnl Find a library-directory with the given leaf-name.  This is useful for
2411 dnl example with FreeBSD ports, which use this convention to distinguish
2412 dnl different versions of the same port.
2413 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
2414         CF_SUBDIR_PATH(cf_search,$1,lib)
2415         for cf_item in $cf_search
2416         do
2417                 case "$cf_item" in
2418                 (*/$1)
2419                         CF_ADD_LIBDIR($cf_item)
2420                         ;;
2421                 esac
2422         done
2423 ])dnl
2424 dnl ---------------------------------------------------------------------------
2425 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
2426 dnl -----------------
2427 dnl make ADAFLAGS consistent with CFLAGS
2428 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
2429         AC_MSG_CHECKING(optimization options for ADAFLAGS)
2430         case "$CFLAGS" in
2431         (*-g*)
2432                 CF_ADD_ADAFLAGS(-g)
2433                 ;;
2434         esac
2435         case "$CFLAGS" in
2436         (*-O*)
2437                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
2438                 CF_ADD_ADAFLAGS($cf_O_flag)
2439                 ;;
2440         esac
2441         AC_MSG_RESULT($ADAFLAGS)
2442 ])dnl
2443 dnl ---------------------------------------------------------------------------
2444 dnl CF_FIX_WARNINGS version: 4 updated: 2021/12/16 18:22:31
2445 dnl ---------------
2446 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
2447 dnl "-Werror" flags can interfere with configure-checks.  Those go into
2448 dnl EXTRA_CFLAGS.
2449 dnl
2450 dnl $1 = variable name to repair
2451 define([CF_FIX_WARNINGS],[
2452 if test "$GCC" = yes || test "$GXX" = yes
2453 then
2454         case [$]$1 in
2455         (*-Werror=*)
2456                 cf_temp_flags=
2457                 for cf_temp_scan in [$]$1
2458                 do
2459                         case "x$cf_temp_scan" in
2460                         (x-Werror=format*)
2461                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
2462                                 ;;
2463                         (x-Werror=*)
2464                                 CF_APPEND_TEXT(EXTRA_CFLAGS,$cf_temp_scan)
2465                                 ;;
2466                         (*)
2467                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
2468                                 ;;
2469                         esac
2470                 done
2471                 if test "x[$]$1" != "x$cf_temp_flags"
2472                 then
2473                         CF_VERBOSE(repairing $1: [$]$1)
2474                         $1="$cf_temp_flags"
2475                         CF_VERBOSE(... fixed [$]$1)
2476                         CF_VERBOSE(... extra $EXTRA_CFLAGS)
2477                 fi
2478                 ;;
2479         esac
2480 fi
2481 AC_SUBST(EXTRA_CFLAGS)
2482 ])dnl
2483 dnl ---------------------------------------------------------------------------
2484 dnl CF_FOPEN_BIN_R version: 2 updated: 2019/12/31 08:53:54
2485 dnl --------------
2486 dnl Check if fopen works when the "b" (binary) flag is added to the mode
2487 dnl parameter.  POSIX ignores the "b", which c89 specified.  Some very old
2488 dnl systems do not accept it.
2489 AC_DEFUN([CF_FOPEN_BIN_R],[
2490 AC_CACHE_CHECK(if fopen accepts explicit binary mode,cf_cv_fopen_bin_r,[
2491         AC_TRY_RUN([
2492 #include <stdio.h>
2493 int main(void) {
2494         FILE *fp = fopen("conftest.tmp", "wb");
2495         int rc = 0;
2496         if (fp != 0) {
2497                 int p, q;
2498                 for (p = 0; p < 256; ++p) {
2499                         fputc(p, fp);
2500                 }
2501                 fclose(fp);
2502                 fp = fopen("conftest.tmp", "rb");
2503                 if (fp != 0) {
2504                         for (p = 0; p < 256; ++p) {
2505                                 q = fgetc(fp);
2506                                 if (q != p) {
2507                                         rc = 1;
2508                                         break;
2509                                 }
2510                         }
2511                 } else {
2512                         rc = 1;
2513                 }
2514         } else {
2515                 rc = 1;
2516         }
2517         ${cf_cv_main_return:-return} (rc);
2518 }
2519 ],
2520                 [cf_cv_fopen_bin_r=yes],
2521                 [cf_cv_fopen_bin_r=no],
2522                 [cf_cv_fopen_bin_r=unknown])
2523 ])
2524 test "x$cf_cv_fopen_bin_r" != xno && AC_DEFINE(USE_FOPEN_BIN_R,1,[Define to 1 if fopen accepts explicit binary mode])
2525 ])dnl
2526 dnl ---------------------------------------------------------------------------
2527 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
2528 dnl --------------
2529 dnl Forget that we saw the given tool.
2530 AC_DEFUN([CF_FORGET_TOOL],[
2531 unset ac_cv_prog_ac_ct_$1
2532 unset ac_ct_$1
2533 unset $1
2534 ])dnl
2535 dnl ---------------------------------------------------------------------------
2536 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
2537 dnl -------------
2538 dnl Test for dlsym() and related functions, as well as libdl.
2539 dnl
2540 dnl Sets
2541 dnl     $cf_have_dlsym
2542 dnl     $cf_have_libdl
2543 AC_DEFUN([CF_FUNC_DLSYM],[
2544 cf_have_dlsym=no
2545 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
2546
2547 cf_have_libdl=no
2548 AC_CHECK_LIB(dl,dlsym,[
2549         cf_have_dlsym=yes
2550         cf_have_libdl=yes])])
2551
2552 if test "$cf_have_dlsym" = yes ; then
2553         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
2554
2555         AC_MSG_CHECKING(whether able to link to dl*() functions)
2556         AC_TRY_LINK([#include <dlfcn.h>],[
2557                 void *obj;
2558                 if ((obj = dlopen("filename", 0)) != 0) {
2559                         if (dlsym(obj, "symbolname") == 0) {
2560                         dlclose(obj);
2561                         }
2562                 }],[
2563                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
2564                 AC_MSG_ERROR(Cannot link test program for libdl)])
2565         AC_MSG_RESULT(ok)
2566 else
2567         AC_MSG_ERROR(Cannot find dlsym function)
2568 fi
2569 ])
2570 dnl ---------------------------------------------------------------------------
2571 dnl CF_FUNC_GETTTYNAM version: 1 updated: 2021/12/04 18:29:47
2572 dnl -----------------
2573 dnl Check if the 4.3BSD function getttyname exists, as well as if <ttyent.h>
2574 dnl defines the _PATH_TTYS symbol.  If the corresponding file exists, but the
2575 dnl other checks fail, just define HAVE_PATH_TTYS.
2576 AC_DEFUN([CF_FUNC_GETTTYNAM],[
2577 AC_CACHE_CHECK(if _PATH_TTYS is defined in ttyent.h,cf_cv_PATH_TTYS,[
2578 AC_TRY_COMPILE([
2579 #include <stdio.h>
2580 #include <ttyent.h>],[
2581 FILE *fp = fopen(_PATH_TTYS, "r"); (void)fp],
2582         [cf_cv_PATH_TTYS=yes],
2583         [cf_cv_PATH_TTYS=no])])
2584
2585 if test $cf_cv_PATH_TTYS = no
2586 then
2587         for cf_ttys in /etc/ttytype /etc/ttys
2588         do
2589                 if test -f $cf_ttys
2590                 then
2591                         cf_cv_PATH_TTYS=maybe
2592                         AC_DEFINE(_PATH_TTYS,$cf_ttys,[define to pathname of file containing mapping from tty name to terminal type])
2593                         break
2594                 fi
2595         done
2596 fi
2597
2598 if test $cf_cv_PATH_TTYS != no
2599 then
2600         AC_CACHE_CHECK(if _PATH_TTYS file exists,cf_cv_have_PATH_TTYS,[
2601                 AC_TRY_RUN([
2602 #include <stdio.h>
2603 #include <ttyent.h>
2604 int main(void) {
2605         FILE *fp = fopen(_PATH_TTYS, "r");
2606         ${cf_cv_main_return:-return} (fp == 0);
2607 }],
2608                         [cf_cv_have_PATH_TTYS=yes],
2609                         [cf_cv_have_PATH_TTYS=no],
2610                         [cf_cv_have_PATH_TTYS=unknown])])
2611         test "$cf_cv_have_PATH_TTYS" = no && cf_cv_PATH_TTYS=no
2612 fi
2613
2614 if test $cf_cv_PATH_TTYS != no
2615 then
2616         AC_DEFINE(HAVE_PATH_TTYS,1,[define to 1 if system can map tty name to terminal type])
2617         AC_CACHE_CHECK(for getttynam,cf_cv_func_getttynam,[
2618                 AC_TRY_LINK([#include <ttyent.h>],
2619                 [struct ttyent *fp = getttynam("/dev/tty"); (void)fp],
2620                 [cf_cv_func_getttynam=yes],
2621                 [cf_cv_func_getttynam=no])])
2622         test "$cf_cv_func_getttynam" = yes && AC_DEFINE(HAVE_GETTTYNAM)
2623 fi
2624 ])dnl
2625 dnl ---------------------------------------------------------------------------
2626 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
2627 dnl ---------------
2628 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
2629 dnl is found, add our own version of memmove to the list of objects.
2630 AC_DEFUN([CF_FUNC_MEMMOVE],
2631 [
2632 AC_CHECK_FUNC(memmove,,[
2633 AC_CHECK_FUNC(bcopy,[
2634         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
2635                 AC_TRY_RUN([
2636 int main(void) {
2637         static char data[] = "abcdefghijklmnopqrstuwwxyz";
2638         char temp[40];
2639         bcopy(data, temp, sizeof(data));
2640         bcopy(temp+10, temp, 15);
2641         bcopy(temp+5, temp+15, 10);
2642         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
2643 }
2644                 ],
2645                 [cf_cv_good_bcopy=yes],
2646                 [cf_cv_good_bcopy=no],
2647                 [cf_cv_good_bcopy=unknown])
2648                 ])
2649         ],[cf_cv_good_bcopy=no])
2650         if test "$cf_cv_good_bcopy" = yes ; then
2651                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
2652         else
2653                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
2654         fi
2655 ])])dnl
2656 dnl ---------------------------------------------------------------------------
2657 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
2658 dnl -----------------
2659 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
2660 dnl AIX 4.x, provide a non-working version.
2661 AC_DEFUN([CF_FUNC_NANOSLEEP],[
2662 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
2663 AC_TRY_RUN([
2664 #include <stdio.h>
2665 #include <errno.h>
2666 #include <time.h>
2667
2668 #ifdef HAVE_SYS_TIME_H
2669 #include <sys/time.h>
2670 #endif
2671
2672 int main(void) {
2673         struct timespec ts1, ts2;
2674         int code;
2675         ts1.tv_sec  = 0;
2676         ts1.tv_nsec = 750000000;
2677         ts2.tv_sec  = 0;
2678         ts2.tv_nsec = 0;
2679         errno = 0;
2680         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2681         ${cf_cv_main_return:-return}(code != 0);
2682 }
2683 ],
2684         [cf_cv_func_nanosleep=yes],
2685         [cf_cv_func_nanosleep=no],
2686         [cf_cv_func_nanosleep=unknown])])
2687
2688 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2689 ])
2690 dnl ---------------------------------------------------------------------------
2691 dnl CF_FUNC_OPENPTY version: 6 updated: 2021/01/01 13:31:04
2692 dnl ---------------
2693 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2694 dnl "util" library as well.
2695 AC_DEFUN([CF_FUNC_OPENPTY],
2696 [
2697 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2698 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2699         cf_save_LIBS="$LIBS"
2700         test "$cf_cv_lib_util" = yes && { CF_ADD_LIB(util) }
2701         for cf_header in pty.h libutil.h util.h
2702         do
2703         AC_TRY_LINK([
2704 #include <$cf_header>
2705 ],[
2706         int x = openpty((int *)0, (int *)0, (char *)0,
2707                                    (struct termios *)0, (struct winsize *)0);
2708 ],[
2709                 cf_cv_func_openpty=$cf_header
2710                 break
2711 ],[
2712                 cf_cv_func_openpty=no
2713 ])
2714         done
2715         LIBS="$cf_save_LIBS"
2716 ])
2717 ])dnl
2718 dnl ---------------------------------------------------------------------------
2719 dnl CF_FUNC_POLL version: 10 updated: 2021/01/04 19:13:57
2720 dnl ------------
2721 dnl See if the poll function really works.  Some platforms have poll(), but
2722 dnl it does not work for terminals or files.
2723 AC_DEFUN([CF_FUNC_POLL],[
2724 tty >/dev/null 2>&1 || { AC_CHECK_FUNCS(posix_openpt) }
2725 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2726 AC_TRY_RUN([
2727 #include <stdlib.h>
2728 #include <stdio.h>
2729 #include <unistd.h>
2730 #include <fcntl.h>
2731 #ifdef HAVE_POLL_H
2732 #include <poll.h>
2733 #else
2734 #include <sys/poll.h>
2735 #endif
2736 int main(void) {
2737         struct pollfd myfds;
2738         int ret;
2739
2740         /* check for Darwin bug with respect to "devices" */
2741         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2742         if (myfds.fd < 0)
2743                 myfds.fd = 0;
2744         myfds.events = POLLIN;
2745         myfds.revents = 0;
2746
2747         ret = poll(&myfds, 1, 100);
2748
2749         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2750                 ret = -1;
2751         } else {
2752                 int fd = 0;
2753                 if (!isatty(fd)) {
2754                         fd = open("/dev/tty", 2);       /* O_RDWR */
2755                 }
2756 #ifdef HAVE_POSIX_OPENPT
2757                 if (fd < 0) {
2758                         fd = posix_openpt(O_RDWR);
2759                 }
2760 #endif
2761
2762                 if (fd >= 0) {
2763                         /* also check with standard input */
2764                         myfds.fd = fd;
2765                         myfds.events = POLLIN;
2766                         myfds.revents = 0;
2767                         ret = poll(&myfds, 1, 100);
2768                 } else {
2769                         ret = -1;
2770                 }
2771         }
2772         ${cf_cv_main_return:-return}(ret < 0);
2773 }],
2774         [cf_cv_working_poll=yes],
2775         [cf_cv_working_poll=no],
2776         [cf_cv_working_poll=unknown])])
2777 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2778 ])dnl
2779 dnl ---------------------------------------------------------------------------
2780 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2781 dnl ---------------
2782 dnl Some old/broken variations define tcgetattr() only as a macro in
2783 dnl termio(s).h
2784 AC_DEFUN([CF_FUNC_TERMIOS],[
2785 AC_REQUIRE([CF_STRUCT_TERMIOS])
2786 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2787 AC_TRY_LINK([
2788 #include <sys/types.h>
2789 #ifdef HAVE_UNISTD_H
2790 #include <unistd.h>
2791 #endif
2792 #ifdef HAVE_TERMIOS_H
2793 #include <termios.h>
2794 #define TTY struct termios
2795 #else
2796 #ifdef HAVE_TERMIO_H
2797 #include <termio.h>
2798 #define TTY struct termio
2799 #endif
2800 #endif
2801 ],[
2802 TTY foo;
2803 tcgetattr(1, &foo);],
2804 [cf_cv_have_tcgetattr=yes],
2805 [cf_cv_have_tcgetattr=no])])
2806 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2807 ])dnl
2808 dnl ---------------------------------------------------------------------------
2809 dnl CF_FUNC_VSSCANF version: 7 updated: 2021/01/01 13:31:04
2810 dnl ---------------
2811 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2812 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2813 dnl other functions.
2814 AC_DEFUN([CF_FUNC_VSSCANF],
2815 [
2816 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2817 AC_TRY_LINK([
2818 #include <stdarg.h>
2819 #include <stdio.h>],[
2820         va_list ap;
2821         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2822 AC_TRY_LINK([
2823 #include <stdarg.h>
2824 #include <stdio.h>],[
2825         FILE strbuf;
2826         char *str = "from";
2827
2828         strbuf._flag = _IOREAD;
2829         strbuf._ptr = strbuf._base = (unsigned char *) str;
2830         strbuf._cnt = strlen(str);
2831         strbuf._file = _NFILE;
2832         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2833 AC_TRY_LINK([
2834 #include <stdarg.h>
2835 #include <stdio.h>],[
2836         FILE strbuf;
2837         char *str = "from";
2838
2839         strbuf._flag = _IOREAD;
2840         strbuf._ptr = strbuf._base = (unsigned char *) str;
2841         strbuf._cnt = strlen(str);
2842         strbuf._file = _NFILE;
2843         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2844 cf_cv_func_vsscanf=no])])])])
2845
2846 case "$cf_cv_func_vsscanf" in
2847 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2848 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2849 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2850 esac
2851
2852 ])dnl
2853 dnl ---------------------------------------------------------------------------
2854 dnl CF_GCC_ATTRIBUTES version: 24 updated: 2021/03/20 12:00:25
2855 dnl -----------------
2856 dnl Test for availability of useful gcc __attribute__ directives to quiet
2857 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2858 dnl to documentation, unrecognized directives cause older compilers to barf.
2859 AC_DEFUN([CF_GCC_ATTRIBUTES],
2860 [AC_REQUIRE([AC_PROG_FGREP])dnl
2861 AC_REQUIRE([CF_C11_NORETURN])dnl
2862
2863 if test "$GCC" = yes || test "$GXX" = yes
2864 then
2865 cat > conftest.i <<EOF
2866 #ifndef GCC_PRINTF
2867 #define GCC_PRINTF 0
2868 #endif
2869 #ifndef GCC_SCANF
2870 #define GCC_SCANF 0
2871 #endif
2872 #ifndef GCC_NORETURN
2873 #define GCC_NORETURN /* nothing */
2874 #endif
2875 #ifndef GCC_UNUSED
2876 #define GCC_UNUSED /* nothing */
2877 #endif
2878 EOF
2879 if test "$GCC" = yes
2880 then
2881         AC_CHECKING([for $CC __attribute__ directives])
2882 cat > "conftest.$ac_ext" <<EOF
2883 #line __oline__ "${as_me:-configure}"
2884 #include "confdefs.h"
2885 #include "conftest.h"
2886 #include "conftest.i"
2887 #if     GCC_PRINTF
2888 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2889 #else
2890 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2891 #endif
2892 #if     GCC_SCANF
2893 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2894 #else
2895 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2896 #endif
2897 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2898 extern GCC_NORETURN void oops(char *,...) GCC_PRINTFLIKE(1,2);
2899 extern GCC_NORETURN void foo(void);
2900 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
2901 EOF
2902         cf_printf_attribute=no
2903         cf_scanf_attribute=no
2904         for cf_attribute in scanf printf unused noreturn
2905         do
2906                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2907                 cf_directive="__attribute__(($cf_attribute))"
2908                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2909
2910                 case "$cf_attribute" in
2911                 (printf)
2912                         cf_printf_attribute=yes
2913                         cat >conftest.h <<EOF
2914 #define GCC_$cf_ATTRIBUTE 1
2915 EOF
2916                         ;;
2917                 (scanf)
2918                         cf_scanf_attribute=yes
2919                         cat >conftest.h <<EOF
2920 #define GCC_$cf_ATTRIBUTE 1
2921 EOF
2922                         ;;
2923                 (*)
2924                         cat >conftest.h <<EOF
2925 #define GCC_$cf_ATTRIBUTE $cf_directive
2926 EOF
2927                         ;;
2928                 esac
2929
2930                 if AC_TRY_EVAL(ac_compile); then
2931                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2932                         cat conftest.h >>confdefs.h
2933                         case "$cf_attribute" in
2934                         (noreturn)
2935                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2936                                 ;;
2937                         (printf)
2938                                 cf_value='/* nothing */'
2939                                 if test "$cf_printf_attribute" != no ; then
2940                                         cf_value='__attribute__((format(printf,fmt,var)))'
2941                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2942                                 fi
2943                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2944                                 ;;
2945                         (scanf)
2946                                 cf_value='/* nothing */'
2947                                 if test "$cf_scanf_attribute" != no ; then
2948                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2949                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2950                                 fi
2951                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2952                                 ;;
2953                         (unused)
2954                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2955                                 ;;
2956                         esac
2957                 fi
2958         done
2959 else
2960         ${FGREP-fgrep} define conftest.i >>confdefs.h
2961 fi
2962 rm -rf ./conftest*
2963 fi
2964 ])dnl
2965 dnl ---------------------------------------------------------------------------
2966 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
2967 dnl --------------
2968 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
2969 dnl compatible), attempt to determine if icc/clang is actually used.
2970 AC_DEFUN([CF_GCC_VERSION],[
2971 AC_REQUIRE([AC_PROG_CC])
2972 GCC_VERSION=none
2973 if test "$GCC" = yes ; then
2974         AC_MSG_CHECKING(version of $CC)
2975         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2976         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2977         AC_MSG_RESULT($GCC_VERSION)
2978 fi
2979 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2980 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2981 ])dnl
2982 dnl ---------------------------------------------------------------------------
2983 dnl CF_GCC_WARNINGS version: 41 updated: 2021/01/01 16:53:59
2984 dnl ---------------
2985 dnl Check if the compiler supports useful warning options.  There's a few that
2986 dnl we don't use, simply because they're too noisy:
2987 dnl
2988 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2989 dnl     -Winline (usually not worthwhile)
2990 dnl     -Wredundant-decls (system headers make this too noisy)
2991 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2992 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2993 dnl             is enabled for ncurses using "--enable-const".
2994 dnl     -pedantic
2995 dnl
2996 dnl Parameter:
2997 dnl     $1 is an optional list of gcc warning flags that a particular
2998 dnl             application might want to use, e.g., "no-unused" for
2999 dnl             -Wno-unused
3000 dnl Special:
3001 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3002 dnl
3003 AC_DEFUN([CF_GCC_WARNINGS],
3004 [
3005 AC_REQUIRE([CF_GCC_VERSION])
3006 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
3007 cat > "conftest.$ac_ext" <<EOF
3008 #line __oline__ "${as_me:-configure}"
3009 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3010 EOF
3011 if test "$INTEL_COMPILER" = yes
3012 then
3013 # The "-wdXXX" options suppress warnings:
3014 # remark #1419: external declaration in primary source file
3015 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3016 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3017 # remark #193: zero used for undefined preprocessing identifier
3018 # remark #593: variable "curs_sb_left_arrow" was set but never used
3019 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3020 # remark #869: parameter "tw" was never referenced
3021 # remark #981: operands are evaluated in unspecified order
3022 # warning #279: controlling expression is constant
3023
3024         AC_CHECKING([for $CC warning options])
3025         cf_save_CFLAGS="$CFLAGS"
3026         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
3027         for cf_opt in \
3028                 wd1419 \
3029                 wd1683 \
3030                 wd1684 \
3031                 wd193 \
3032                 wd593 \
3033                 wd279 \
3034                 wd810 \
3035                 wd869 \
3036                 wd981
3037         do
3038                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
3039                 if AC_TRY_EVAL(ac_compile); then
3040                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3041                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
3042                 fi
3043         done
3044         CFLAGS="$cf_save_CFLAGS"
3045 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
3046 then
3047         AC_CHECKING([for $CC warning options])
3048         cf_save_CFLAGS="$CFLAGS"
3049         cf_warn_CONST=""
3050         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
3051         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
3052         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
3053         for cf_opt in W Wall \
3054                 Wbad-function-cast \
3055                 Wcast-align \
3056                 Wcast-qual \
3057                 Wdeclaration-after-statement \
3058                 Wextra \
3059                 Winline \
3060                 Wmissing-declarations \
3061                 Wmissing-prototypes \
3062                 Wnested-externs \
3063                 Wpointer-arith \
3064                 Wshadow \
3065                 Wstrict-prototypes \
3066                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
3067         do
3068                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
3069                 if AC_TRY_EVAL(ac_compile); then
3070                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3071                         case "$cf_opt" in
3072                         (Winline)
3073                                 case "$GCC_VERSION" in
3074                                 ([[34]].*)
3075                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
3076                                         continue;;
3077                                 esac
3078                                 ;;
3079                         (Wpointer-arith)
3080                                 case "$GCC_VERSION" in
3081                                 ([[12]].*)
3082                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
3083                                         continue;;
3084                                 esac
3085                                 ;;
3086                         esac
3087                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
3088                 fi
3089         done
3090         CFLAGS="$cf_save_CFLAGS"
3091 fi
3092 rm -rf ./conftest*
3093
3094 AC_SUBST(EXTRA_CFLAGS)
3095 ])dnl
3096 dnl ---------------------------------------------------------------------------
3097 dnl CF_GETOPT_HEADER version: 8 updated: 2021/06/19 19:16:16
3098 dnl ----------------
3099 dnl Check for getopt's variables which are commonly defined in stdlib.h,
3100 dnl unistd.h or (nonstandard) in getopt.h
3101 AC_DEFUN([CF_GETOPT_HEADER],
3102 [
3103 AC_HAVE_HEADERS(unistd.h getopt.h)
3104 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
3105 cf_cv_getopt_header=none
3106 for cf_header in stdio.h stdlib.h unistd.h getopt.h
3107 do
3108 AC_TRY_COMPILE([
3109 #include <$cf_header>],
3110 [int x = optind; char *y = optarg; (void)x; (void)y],
3111 [cf_cv_getopt_header=$cf_header
3112  break])
3113 done
3114 ])
3115 if test "$cf_cv_getopt_header" != none ; then
3116         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
3117 fi
3118 if test "$cf_cv_getopt_header" = getopt.h ; then
3119         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
3120 fi
3121 ])dnl
3122 dnl ---------------------------------------------------------------------------
3123 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
3124 dnl -----------------
3125 AC_DEFUN([CF_GNATPREP_OPT_T],[
3126 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
3127 cf_cv_gnatprep_opt_t=no
3128 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
3129 ])
3130 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
3131 AC_SUBST(GNATPREP_OPTS)
3132 ])dnl
3133 dnl ---------------------------------------------------------------------------
3134 dnl CF_GNAT_GENERICS version: 7 updated: 2021/01/01 13:31:04
3135 dnl ----------------
3136 AC_DEFUN([CF_GNAT_GENERICS],
3137 [
3138 AC_REQUIRE([CF_GNAT_VERSION])
3139
3140 AC_MSG_CHECKING(if GNAT supports generics)
3141 case "$cf_cv_gnat_version" in
3142 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
3143         cf_gnat_generics=yes
3144         ;;
3145 (*)
3146         cf_gnat_generics=no
3147         ;;
3148 esac
3149 AC_MSG_RESULT($cf_gnat_generics)
3150
3151 if test "$cf_gnat_generics" = yes
3152 then
3153         cf_compile_generics=generics
3154         cf_generic_objects="\${GENOBJS}"
3155 else
3156         cf_compile_generics=
3157         cf_generic_objects=
3158 fi
3159
3160 AC_SUBST(cf_compile_generics)
3161 AC_SUBST(cf_generic_objects)
3162 ])dnl
3163 dnl ---------------------------------------------------------------------------
3164 dnl CF_GNAT_PROJECTS version: 13 updated: 2021/01/02 17:09:14
3165 dnl ----------------
3166 dnl GNAT projects are configured with ".gpr" project files.
3167 dnl GNAT libraries are a further development, using the project feature.
3168 AC_DEFUN([CF_GNAT_PROJECTS],
3169 [
3170 AC_REQUIRE([CF_GNAT_VERSION])
3171 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
3172
3173 cf_gnat_libraries=no
3174 cf_gnat_projects=no
3175
3176 if test "$enable_gnat_projects" != no ; then
3177 AC_MSG_CHECKING(if GNAT supports project files)
3178 case "$cf_cv_gnat_version" in
3179 (3.[[0-9]]*)
3180         ;;
3181 (*)
3182         case "$cf_cv_system_name" in
3183         (cygwin*|msys*)
3184                 ;;
3185         (*)
3186                 rm -rf ./conftest* ./*~conftest*
3187                 if mkdir conftest.src conftest.bin conftest.lib
3188                 then
3189                         cd conftest.src
3190                         rm -rf ./conftest* ./*~conftest*
3191                         cat >>library.gpr <<CF_EOF
3192 project Library is
3193   Kind := External ("LIB_KIND");
3194   for Library_Name use "ConfTest";
3195   for Object_Dir use ".";
3196   for Library_ALI_Dir use External("LIBRARY_DIR");
3197   for Library_Version use External ("SONAME");
3198   for Library_Kind use Kind;
3199   for Library_Dir use External("BUILD_DIR");
3200   Source_Dir := External ("SOURCE_DIR");
3201   for Source_Dirs use (Source_Dir);
3202 end Library;
3203 CF_EOF
3204                         cat >>confpackage.ads <<CF_EOF
3205 package ConfPackage is
3206    procedure conftest;
3207 end ConfPackage;
3208 CF_EOF
3209                         cat >>confpackage.adb <<CF_EOF
3210 with Text_IO;
3211 package body ConfPackage is
3212    procedure conftest is
3213    begin
3214       Text_IO.Put ("Hello World");
3215       Text_IO.New_Line;
3216    end conftest;
3217 end ConfPackage;
3218 CF_EOF
3219                         if ( "$cf_ada_make" $ADAFLAGS \
3220                                         -Plibrary.gpr \
3221                                         -XBUILD_DIR="`cd ../conftest.bin;pwd`" \
3222                                         -XLIBRARY_DIR="`cd ../conftest.lib;pwd`" \
3223                                         -XSOURCE_DIR="`pwd`" \
3224                                         -XSONAME=libConfTest.so.1 \
3225                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
3226                                 cf_gnat_projects=yes
3227                         fi
3228                         cd ..
3229                 fi
3230                 if test -f conftest.lib/confpackage.ali
3231                 then
3232                         cf_gnat_libraries=yes
3233                 fi
3234                 rm -rf ./conftest* ./*~conftest*
3235                 ;;
3236         esac
3237         ;;
3238 esac
3239 AC_MSG_RESULT($cf_gnat_projects)
3240 fi # enable_gnat_projects
3241
3242 if test "$cf_gnat_projects" = yes
3243 then
3244         AC_MSG_CHECKING(if GNAT supports libraries)
3245         AC_MSG_RESULT($cf_gnat_libraries)
3246 fi
3247
3248 USE_OLD_MAKERULES=""
3249 USE_GNAT_PROJECTS="#"
3250 USE_GNAT_MAKE_GPR="#"
3251 USE_GNAT_GPRBUILD="#"
3252
3253 if test "$cf_gnat_projects" = yes
3254 then
3255         USE_OLD_MAKERULES="#"
3256         USE_GNAT_PROJECTS=""
3257         if test "$cf_cv_VERSION_GPRBUILD" != no
3258         then
3259                 USE_GNAT_GPRBUILD=""
3260         elif test "$cf_cv_VERSION_GNATMAKE" != no
3261         then
3262                 USE_GNAT_MAKE_GPR=""
3263         else
3264                 AC_MSG_WARN(use old makefile rules since tools are missing)
3265         fi
3266 fi
3267
3268 if test "$cf_gnat_libraries" = yes
3269 then
3270         USE_GNAT_LIBRARIES=""
3271 else
3272         USE_GNAT_LIBRARIES="#"
3273 fi
3274
3275 AC_SUBST(USE_OLD_MAKERULES)
3276 AC_SUBST(USE_GNAT_PROJECTS)
3277 AC_SUBST(USE_GNAT_LIBRARIES)
3278 AC_SUBST(USE_GNAT_MAKE_GPR)
3279 AC_SUBST(USE_GNAT_GPRBUILD)
3280 ])dnl
3281 dnl ---------------------------------------------------------------------------
3282 dnl CF_GNAT_SIGINT version: 2 updated: 2021/01/01 13:31:04
3283 dnl --------------
3284 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
3285 dnl is noted that gnat may compile a tasking unit even for configurations which
3286 dnl fail at runtime.
3287 AC_DEFUN([CF_GNAT_SIGINT],[
3288 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
3289 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
3290
3291 package ConfTest is
3292
3293    pragma Warnings (Off);  --  the next pragma exists since 3.11p
3294    pragma Unreserve_All_Interrupts;
3295    pragma Warnings (On);
3296
3297    protected Process is
3298       procedure Stop;
3299       function Continue return Boolean;
3300       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
3301    private
3302       Done : Boolean := False;
3303    end Process;
3304
3305 end ConfTest;],
3306 [package body ConfTest is
3307    protected body Process is
3308       procedure Stop is
3309       begin
3310          Done := True;
3311       end Stop;
3312       function Continue return Boolean is
3313       begin
3314          return not Done;
3315       end Continue;
3316    end Process;
3317 end ConfTest;],
3318         [cf_cv_gnat_sigint=yes],
3319         [cf_cv_gnat_sigint=no])])
3320
3321 if test "$cf_cv_gnat_sigint" = yes ; then
3322         USE_GNAT_SIGINT=""
3323 else
3324         USE_GNAT_SIGINT="#"
3325 fi
3326 AC_SUBST(USE_GNAT_SIGINT)
3327 ])dnl
3328 dnl ---------------------------------------------------------------------------
3329 dnl CF_GNAT_TRY_LINK version: 4 updated: 2021/01/01 13:31:04
3330 dnl ----------------
3331 dnl Verify that a test program compiles/links with GNAT.
3332 dnl $cf_ada_make is set to the program that compiles/links
3333 dnl $ADAFLAGS may be set to the GNAT flags.
3334 dnl
3335 dnl $1 is the text of the spec
3336 dnl $2 is the text of the body
3337 dnl $3 is the shell command to execute if successful
3338 dnl $4 is the shell command to execute if not successful
3339 AC_DEFUN([CF_GNAT_TRY_LINK],
3340 [
3341 rm -rf ./conftest* ./*~conftest*
3342 cat >>conftest.ads <<CF_EOF
3343 $1
3344 CF_EOF
3345 cat >>conftest.adb <<CF_EOF
3346 $2
3347 CF_EOF
3348 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3349 ifelse($3,,      :,[      $3])
3350 ifelse($4,,,[else
3351    $4])
3352 fi
3353 rm -rf ./conftest* ./*~conftest*
3354 ])dnl
3355 dnl ---------------------------------------------------------------------------
3356 dnl CF_GNAT_TRY_RUN version: 6 updated: 2021/01/01 13:31:04
3357 dnl ---------------
3358 dnl Verify that a test program compiles and runs with GNAT
3359 dnl $cf_ada_make is set to the program that compiles/links
3360 dnl $ADAFLAGS may be set to the GNAT flags.
3361 dnl
3362 dnl $1 is the text of the spec
3363 dnl $2 is the text of the body
3364 dnl $3 is the shell command to execute if successful
3365 dnl $4 is the shell command to execute if not successful
3366 AC_DEFUN([CF_GNAT_TRY_RUN],
3367 [
3368 rm -rf ./conftest* ./*~conftest*
3369 cat >>conftest.ads <<CF_EOF
3370 $1
3371 CF_EOF
3372 cat >>conftest.adb <<CF_EOF
3373 $2
3374 CF_EOF
3375 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3376    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
3377 ifelse($3,,      :,[      $3])
3378 ifelse($4,,,[   else
3379       $4])
3380    fi
3381 ifelse($4,,,[else
3382    $4])
3383 fi
3384 rm -rf ./conftest* ./*~conftest*
3385 ])dnl
3386 dnl ---------------------------------------------------------------------------
3387 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
3388 dnl ---------------
3389 dnl $1 = cache variable to update
3390 dnl $2 = program name
3391 dnl Verify version of GNAT or related tool
3392 AC_DEFUN([CF_GNAT_VERSION],
3393 [
3394 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
3395 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
3396         grep '[[0-9]].[[0-9]][[0-9]]*' |\
3397         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
3398 ])
3399 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
3400 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
3401 ])dnl
3402 dnl ---------------------------------------------------------------------------
3403 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
3404 dnl -------------
3405 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
3406 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
3407 dnl (or misfeature) of glibc2, which breaks portability of many applications,
3408 dnl since it is interwoven with GNU extensions.
3409 dnl
3410 dnl Well, yes we could work around it...
3411 dnl
3412 dnl Parameters:
3413 dnl     $1 is the nominal value for _XOPEN_SOURCE
3414 AC_DEFUN([CF_GNU_SOURCE],
3415 [
3416 cf_gnu_xopen_source=ifelse($1,,500,$1)
3417
3418 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
3419 AC_TRY_COMPILE([#include <sys/types.h>],[
3420         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
3421                 return 0;
3422         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
3423                 return 0;
3424         #else
3425         #       error not GNU C library
3426         #endif],
3427         [cf_cv_gnu_library=yes],
3428         [cf_cv_gnu_library=no])
3429 ])
3430
3431 if test x$cf_cv_gnu_library = xyes; then
3432
3433         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
3434         # was changed to help a little.  newlib incorporated the change about 4
3435         # years later.
3436         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
3437                 cf_save="$CPPFLAGS"
3438                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3439                 AC_TRY_COMPILE([#include <sys/types.h>],[
3440                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
3441                                 return 0;
3442                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
3443                                 return 0;
3444                         #else
3445                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
3446                         #endif],
3447                         [cf_cv_gnu_library_219=yes],
3448                         [cf_cv_gnu_library_219=no])
3449                 CPPFLAGS="$cf_save"
3450         ])
3451
3452         if test "x$cf_cv_gnu_library_219" = xyes; then
3453                 cf_save="$CPPFLAGS"
3454                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
3455                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
3456                         AC_TRY_COMPILE([
3457                                 #include <limits.h>
3458                                 #include <sys/types.h>
3459                                 ],[
3460                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
3461                                         return 0;
3462                                 #else
3463                                 #       error GNU C library is too old
3464                                 #endif],
3465                                 [cf_cv_gnu_dftsrc_219=yes],
3466                                 [cf_cv_gnu_dftsrc_219=no])
3467                         ])
3468                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
3469         else
3470                 cf_cv_gnu_dftsrc_219=maybe
3471         fi
3472
3473         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
3474
3475                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
3476                 AC_TRY_COMPILE([#include <sys/types.h>],[
3477                         #ifndef _XOPEN_SOURCE
3478                         #error  expected _XOPEN_SOURCE to be defined
3479                         #endif],
3480                         [cf_cv_gnu_source=no],
3481                         [cf_save="$CPPFLAGS"
3482                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
3483                          AC_TRY_COMPILE([#include <sys/types.h>],[
3484                                 #ifdef _XOPEN_SOURCE
3485                                 #error  expected _XOPEN_SOURCE to be undefined
3486                                 #endif],
3487                                 [cf_cv_gnu_source=no],
3488                                 [cf_cv_gnu_source=yes])
3489                         CPPFLAGS="$cf_save"
3490                         ])
3491                 ])
3492
3493                 if test "$cf_cv_gnu_source" = yes
3494                 then
3495                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
3496                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
3497                         AC_TRY_COMPILE([#include <sys/types.h>],[
3498                                 #ifdef _DEFAULT_SOURCE
3499                                 #error  expected _DEFAULT_SOURCE to be undefined
3500                                 #endif],
3501                                 [cf_cv_default_source=no],
3502                                 [cf_cv_default_source=yes])
3503                         ])
3504                         if test "$cf_cv_default_source" = yes
3505                         then
3506                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3507                         fi
3508                 fi
3509         fi
3510
3511 fi
3512 ])dnl
3513 dnl ---------------------------------------------------------------------------
3514 dnl CF_GPP_LIBRARY version: 13 updated: 2021/01/01 13:31:04
3515 dnl --------------
3516 dnl If we're trying to use g++, test if libg++ is installed (a rather common
3517 dnl problem :-).  If we have the compiler but no library, we'll be able to
3518 dnl configure, but won't be able to build the c++ demo program.
3519 AC_DEFUN([CF_GPP_LIBRARY],
3520 [
3521 cf_cxx_library=unknown
3522 case "$cf_cv_system_name" in
3523 (os2*)
3524         cf_gpp_libname=gpp
3525         ;;
3526 (*)
3527         cf_gpp_libname=g++
3528         ;;
3529 esac
3530 if test "$GXX" = yes; then
3531         AC_MSG_CHECKING([for lib$cf_gpp_libname])
3532         cf_save="$LIBS"
3533         CF_ADD_LIB($cf_gpp_libname)
3534         AC_TRY_LINK([
3535 #include <$cf_gpp_libname/builtin.h>
3536         ],
3537         [two_arg_error_handler_t foo2 = lib_error_handler],
3538         [cf_cxx_library=yes
3539          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3540          if test "$cf_gpp_libname" = cpp ; then
3541             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
3542          else
3543             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
3544          fi],
3545         [AC_TRY_LINK([
3546 #include <builtin.h>
3547         ],
3548         [two_arg_error_handler_t foo2 = lib_error_handler],
3549         [cf_cxx_library=yes
3550          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3551          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
3552         [cf_cxx_library=no])])
3553         LIBS="$cf_save"
3554         AC_MSG_RESULT($cf_cxx_library)
3555 fi
3556 ])dnl
3557 dnl ---------------------------------------------------------------------------
3558 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
3559 dnl --------------
3560 dnl Check for version of g++
3561 AC_DEFUN([CF_GXX_VERSION],[
3562 AC_REQUIRE([AC_PROG_CPP])
3563 GXX_VERSION=none
3564 if test "$GXX" = yes; then
3565         AC_MSG_CHECKING(version of ${CXX:-g++})
3566         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3567         if test -z "$GXX_VERSION"
3568         then
3569                 GXX_VERSION=unknown
3570                 GXX=no
3571         fi
3572         AC_MSG_RESULT($GXX_VERSION)
3573 fi
3574 ])dnl
3575 dnl ---------------------------------------------------------------------------
3576 dnl CF_GXX_WARNINGS version: 11 updated: 2021/01/08 16:50:55
3577 dnl ---------------
3578 dnl Check if the compiler supports useful warning options.
3579 dnl
3580 dnl Most of gcc's options apply to g++, except:
3581 dnl     -Wbad-function-cast
3582 dnl     -Wmissing-declarations
3583 dnl     -Wnested-externs
3584 dnl
3585 dnl Omit a few (for now):
3586 dnl     -Winline
3587 dnl
3588 dnl Parameter:
3589 dnl     $1 is an optional list of g++ warning flags that a particular
3590 dnl             application might want to use, e.g., "no-unused" for
3591 dnl             -Wno-unused
3592 dnl Special:
3593 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3594 dnl
3595 AC_DEFUN([CF_GXX_WARNINGS],
3596 [
3597
3598 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
3599 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
3600
3601 AC_REQUIRE([CF_GXX_VERSION])
3602
3603 AC_LANG_SAVE
3604 AC_LANG_CPLUSPLUS
3605
3606 cat > conftest.$ac_ext <<EOF
3607 #line __oline__ "configure"
3608 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3609 EOF
3610
3611 if test "$INTEL_CPLUSPLUS" = yes
3612 then
3613 # The "-wdXXX" options suppress warnings:
3614 # remark #1419: external declaration in primary source file
3615 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3616 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3617 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3618 # remark #193: zero used for undefined preprocessing identifier
3619 # remark #593: variable "curs_sb_left_arrow" was set but never used
3620 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3621 # remark #869: parameter "tw" was never referenced
3622 # remark #981: operands are evaluated in unspecified order
3623 # warning #269: invalid format string conversion
3624
3625         AC_CHECKING([for $CC warning options])
3626         cf_save_CXXFLAGS="$CXXFLAGS"
3627         EXTRA_CXXFLAGS="-Wall"
3628         for cf_opt in \
3629                 wd1419 \
3630                 wd1682 \
3631                 wd1683 \
3632                 wd1684 \
3633                 wd193 \
3634                 wd279 \
3635                 wd593 \
3636                 wd810 \
3637                 wd869 \
3638                 wd981
3639         do
3640                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
3641                 if AC_TRY_EVAL(ac_compile); then
3642                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3643                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3644                 fi
3645         done
3646         CXXFLAGS="$cf_save_CXXFLAGS"
3647
3648 elif test "$GXX" = yes
3649 then
3650         AC_CHECKING([for $CXX warning options])
3651         cf_save_CXXFLAGS="$CXXFLAGS"
3652         EXTRA_CXXFLAGS="-W -Wall"
3653         cf_gxx_extra_warnings=""
3654         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
3655         case "$GXX_VERSION" in
3656         ([[1-2]].*)
3657                 ;;
3658         (*)
3659                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
3660                 ;;
3661         esac
3662         for cf_opt in \
3663                 Wabi \
3664                 fabi-version=0 \
3665                 Wextra \
3666                 Wignored-qualifiers \
3667                 Wlogical-op \
3668                 Woverloaded-virtual \
3669                 Wsign-promo \
3670                 Wsynth \
3671                 Wold-style-cast \
3672                 Wcast-align \
3673                 Wcast-qual \
3674                 Wpointer-arith \
3675                 Wshadow \
3676                 Wundef $cf_gxx_extra_warnings $1
3677         do
3678                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
3679                 if AC_TRY_EVAL(ac_compile); then
3680                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3681                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3682                 else
3683                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
3684                 fi
3685         done
3686         CXXFLAGS="$cf_save_CXXFLAGS"
3687 fi
3688
3689 rm -rf ./conftest*
3690 AC_LANG_RESTORE
3691 AC_SUBST(EXTRA_CXXFLAGS)
3692 ])dnl
3693 dnl ---------------------------------------------------------------------------
3694 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3695 dnl ------------
3696 dnl Look for an instance of the Berkeley hashed database.
3697 dnl
3698 dnl $1 = optional parameter, to specify install-prefix for the database.
3699 AC_DEFUN([CF_HASHED_DB],
3700 [
3701 ifelse([$1],,,[
3702 case $1 in
3703 (yes|*able*)
3704         ;;
3705 (*)
3706         if test -d "$1" ; then
3707                 CF_ADD_INCDIR($1/include)
3708                 CF_ADD_LIBDIR($1/lib)
3709         else
3710                 case "$1" in
3711                 (./*|../*|/*)
3712                         AC_MSG_WARN(no such directory $1)
3713                         ;;
3714                 (*)
3715                         CF_FIND_SUB_INCDIR($1)
3716                         CF_FIND_SUB_LIBDIR($1)
3717                         ;;
3718                 esac
3719         fi
3720 esac
3721 ])
3722 AC_CHECK_HEADER(db.h,[
3723 CF_HASHED_DB_VERSION
3724 if test "$cf_cv_hashed_db_version" = unknown ; then
3725         AC_MSG_ERROR(Cannot determine version of db)
3726 else
3727         CF_HASHED_DB_LIBS
3728         if test "$cf_cv_hashed_db_libs" = unknown ; then
3729                 AC_MSG_ERROR(Cannot determine library for db)
3730         elif test "$cf_cv_hashed_db_libs" != default ; then
3731                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3732         fi
3733 fi
3734 ],[
3735         AC_MSG_ERROR(Cannot find db.h)
3736 ])
3737 ])dnl
3738 dnl ---------------------------------------------------------------------------
3739 dnl CF_HASHED_DB_LIBS version: 10 updated: 2021/01/02 17:09:14
3740 dnl -----------------
3741 dnl Given that we have the header and version for hashed database, find the
3742 dnl library information.
3743 AC_DEFUN([CF_HASHED_DB_LIBS],
3744 [
3745 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3746 cf_cv_hashed_db_libs=unknown
3747 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3748 do
3749         cf_save_libs="$LIBS"
3750         if test -n "$cf_db_libs"; then
3751                 CF_ADD_LIB($cf_db_libs)
3752         fi
3753         CF_MSG_LOG(checking for library $cf_db_libs)
3754         AC_TRY_LINK([
3755 $ac_includes_default
3756 #include <db.h>
3757 ],[
3758         char *path = "/tmp/foo";
3759 #ifdef DB_VERSION_MAJOR
3760 #if DB_VERSION_MAJOR >= 4
3761         DB *result = 0;
3762         db_create(&result, NULL, 0);
3763         result->open(result,
3764                 NULL,
3765                 path,
3766                 path,
3767                 DB_HASH,
3768                 DB_CREATE,
3769                 0644);
3770 #elif DB_VERSION_MAJOR >= 3
3771         DB *result = 0;
3772         db_create(&result, NULL, 0);
3773         result->open(result,
3774                 path,
3775                 path,
3776                 DB_HASH,
3777                 DB_CREATE,
3778                 0644);
3779 #elif DB_VERSION_MAJOR >= 2
3780         DB *result = 0;
3781         db_open(path,
3782                 DB_HASH,
3783                 DB_CREATE,
3784                 0644,
3785                 (DB_ENV *) 0,
3786                 (DB_INFO *) 0,
3787                 &result);
3788 #endif /* DB_VERSION_MAJOR */
3789 #else
3790         DB *result = dbopen(path,
3791                      2,
3792                      0644,
3793                      DB_HASH,
3794                      0);
3795 #endif
3796         ${cf_cv_main_return:-return}(result != 0)
3797 ],[
3798         if test -n "$cf_db_libs" ; then
3799                 cf_cv_hashed_db_libs=$cf_db_libs
3800         else
3801                 cf_cv_hashed_db_libs=default
3802         fi
3803         LIBS="$cf_save_libs"
3804         break
3805 ])
3806         LIBS="$cf_save_libs"
3807 done
3808 ])
3809 ])dnl
3810 dnl ---------------------------------------------------------------------------
3811 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3812 dnl --------------------
3813 dnl Given that we have the header file for hashed database, find the version
3814 dnl information.
3815 AC_DEFUN([CF_HASHED_DB_VERSION],
3816 [
3817 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3818 cf_cv_hashed_db_version=unknown
3819
3820 for cf_db_version in 1 2 3 4 5 6
3821 do
3822         CF_MSG_LOG(checking for db version $cf_db_version)
3823         AC_TRY_COMPILE([
3824 $ac_includes_default
3825 #include <db.h>
3826
3827 #ifdef DB_VERSION_MAJOR
3828         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3829 #if $cf_db_version == DB_VERSION_MAJOR
3830         /* ok */
3831 #else
3832         make an error
3833 #endif
3834 #else
3835 #if $cf_db_version == 1
3836         /* ok: assuming this is DB 1.8.5 */
3837 #else
3838         make an error
3839 #endif
3840 #endif
3841 ],[DBT *foo = 0],[
3842         cf_cv_hashed_db_version=$cf_db_version
3843         break
3844         ])
3845 done
3846 ])
3847 ])dnl
3848 dnl ---------------------------------------------------------------------------
3849 dnl CF_HEADER_PATH version: 15 updated: 2021/01/01 13:31:04
3850 dnl --------------
3851 dnl Construct a search-list of directories for a nonstandard header-file
3852 dnl
3853 dnl Parameters
3854 dnl     $1 = the variable to return as result
3855 dnl     $2 = the package name
3856 AC_DEFUN([CF_HEADER_PATH],
3857 [
3858 $1=
3859
3860 # collect the current set of include-directories from compiler flags
3861 cf_header_path_list=""
3862 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3863         for cf_header_path in $CPPFLAGS $CFLAGS
3864         do
3865                 case "$cf_header_path" in
3866                 (-I*)
3867                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3868                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3869                         cf_header_path_list="$cf_header_path_list [$]$1"
3870                         ;;
3871                 esac
3872         done
3873 fi
3874
3875 # add the variations for the package we are looking for
3876 CF_SUBDIR_PATH($1,$2,include)
3877
3878 test "$includedir" != NONE && \
3879 test "$includedir" != "/usr/include" && \
3880 test -d "$includedir" && {
3881         test -d "$includedir" &&    $1="[$]$1 $includedir"
3882         test -d "$includedir/$2" && $1="[$]$1 $includedir/$2"
3883 }
3884
3885 test "$oldincludedir" != NONE && \
3886 test "$oldincludedir" != "/usr/include" && \
3887 test -d "$oldincludedir" && {
3888         test -d "$oldincludedir"    && $1="[$]$1 $oldincludedir"
3889         test -d "$oldincludedir/$2" && $1="[$]$1 $oldincludedir/$2"
3890 }
3891
3892 $1="[$]$1 $cf_header_path_list"
3893 ])dnl
3894 dnl ---------------------------------------------------------------------------
3895 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
3896 dnl ---------------
3897 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3898 AC_DEFUN([CF_HELP_MESSAGE],
3899 [CF_ACVERSION_CHECK(2.53,[],[
3900 AC_DIVERT_HELP($1)])dnl
3901 ])dnl
3902 dnl ---------------------------------------------------------------------------
3903 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3904 dnl ---------------
3905 dnl Construct the list of include-options according to whether we're building
3906 dnl in the source directory or using '--srcdir=DIR' option.
3907 AC_DEFUN([CF_INCLUDE_DIRS],
3908 [
3909 if test "$srcdir" != "."; then
3910         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3911 fi
3912 CPPFLAGS="-I../include $CPPFLAGS"
3913 if test "$srcdir" != "."; then
3914         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3915 fi
3916 CPPFLAGS="-I. $CPPFLAGS"
3917 AC_SUBST(CPPFLAGS)
3918 ])dnl
3919 dnl ---------------------------------------------------------------------------
3920 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
3921 dnl ---------------
3922 dnl prompt for/fill-in useful install-program options
3923 AC_DEFUN([CF_INSTALL_OPTS],
3924 [
3925 CF_INSTALL_OPT_S
3926 CF_INSTALL_OPT_P
3927 CF_INSTALL_OPT_O
3928 ])dnl
3929 dnl ---------------------------------------------------------------------------
3930 dnl CF_INSTALL_OPT_O version: 3 updated: 2020/12/31 20:19:42
3931 dnl ----------------
3932 dnl Almost all "install" programs default to the current user's ownership.
3933 dnl Almost - MINIX is an exception.
3934 AC_DEFUN([CF_INSTALL_OPT_O],
3935 [
3936 AC_MSG_CHECKING(if install needs to be told about ownership)
3937 case `$ac_config_guess` in
3938 (*minix)
3939         with_install_o=yes
3940         ;;
3941 (*)
3942         with_install_o=no
3943         ;;
3944 esac
3945
3946 AC_MSG_RESULT($with_install_o)
3947 if test "x$with_install_o" = xyes
3948 then
3949         INSTALL_OPT_O="`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`"
3950 else
3951         INSTALL_OPT_O=
3952 fi
3953
3954 AC_SUBST(INSTALL_OPT_O)
3955 ])dnl
3956 dnl ---------------------------------------------------------------------------
3957 dnl CF_INSTALL_OPT_P version: 3 updated: 2021/01/01 13:31:04
3958 dnl ----------------
3959 dnl Some install-programs accept a "-p" option to preserve file modification
3960 dnl timestamps.  That can be useful as an install option, as well as a way to
3961 dnl avoid the need for ranlib after copying a static archive.
3962 AC_DEFUN([CF_INSTALL_OPT_P],
3963 [
3964 : "${INSTALL:=install}"
3965 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
3966         rm -rf ./conftest*
3967         date >conftest.in
3968         mkdir conftest.out
3969         sleep 3
3970         if $INSTALL -p conftest.in conftest.out 2>/dev/null
3971         then
3972                 if test -f conftest.out/conftest.in
3973                 then
3974                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
3975                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
3976                         if test -s conftest.err
3977                         then
3978                                 cf_cv_install_p=no
3979                         else
3980                                 cf_cv_install_p=yes
3981                         fi
3982                 else
3983                         cf_cv_install_p=no
3984                 fi
3985         else
3986                 cf_cv_install_p=no
3987         fi
3988         rm -rf ./conftest*
3989 ])
3990 ])dnl
3991 dnl ---------------------------------------------------------------------------
3992 dnl CF_INSTALL_OPT_S version: 3 updated: 2021/01/05 19:23:48
3993 dnl ----------------
3994 dnl By default, we should strip executables which are installed, but leave the
3995 dnl ability to suppress that for unit-testing.
3996 AC_DEFUN([CF_INSTALL_OPT_S],
3997 [
3998 AC_MSG_CHECKING(if you want to install stripped executables)
3999 CF_ARG_DISABLE(stripping,
4000         [  --disable-stripping     do not strip (debug info) installed executables],
4001         [enable_stripping=no],
4002         [enable_stripping=yes])
4003 AC_MSG_RESULT($enable_stripping)
4004
4005 if test "$enable_stripping" = yes
4006 then
4007         INSTALL_OPT_S="-s"
4008 else
4009         INSTALL_OPT_S=
4010 fi
4011 AC_SUBST(INSTALL_OPT_S)
4012 ])dnl
4013 dnl ---------------------------------------------------------------------------
4014 dnl CF_INTEL_COMPILER version: 8 updated: 2021/01/01 16:53:59
4015 dnl -----------------
4016 dnl Check if the given compiler is really the Intel compiler for Linux.  It
4017 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
4018 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
4019 dnl
4020 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
4021 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
4022 dnl the wrappers for gcc and g++ warnings.
4023 dnl
4024 dnl $1 = GCC (default) or GXX
4025 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
4026 dnl $3 = CFLAGS (default) or CXXFLAGS
4027 AC_DEFUN([CF_INTEL_COMPILER],[
4028 AC_REQUIRE([AC_CANONICAL_HOST])
4029 ifelse([$2],,INTEL_COMPILER,[$2])=no
4030
4031 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
4032         case "$host_os" in
4033         (linux*|gnu*)
4034                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
4035                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
4036                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
4037                 AC_TRY_COMPILE([],[
4038 #ifdef __INTEL_COMPILER
4039 #else
4040 make an error
4041 #endif
4042 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
4043 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
4044 ],[])
4045                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
4046                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
4047                 ;;
4048         esac
4049 fi
4050 ])dnl
4051 dnl ---------------------------------------------------------------------------
4052 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
4053 dnl ----------
4054 dnl Check if we have either a function or macro for 'isascii()'.
4055 AC_DEFUN([CF_ISASCII],
4056 [
4057 AC_MSG_CHECKING(for isascii)
4058 AC_CACHE_VAL(cf_cv_have_isascii,[
4059         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
4060         [cf_cv_have_isascii=yes],
4061         [cf_cv_have_isascii=no])
4062 ])dnl
4063 AC_MSG_RESULT($cf_cv_have_isascii)
4064 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
4065 ])dnl
4066 dnl ---------------------------------------------------------------------------
4067 dnl CF_LARGEFILE version: 12 updated: 2020/03/19 20:23:48
4068 dnl ------------
4069 dnl Add checks for large file support.
4070 AC_DEFUN([CF_LARGEFILE],[
4071 ifdef([AC_FUNC_FSEEKO],[
4072         AC_SYS_LARGEFILE
4073         if test "$enable_largefile" != no ; then
4074         AC_FUNC_FSEEKO
4075
4076         # Normally we would collect these definitions in the config.h,
4077         # but (like _XOPEN_SOURCE), some environments rely on having these
4078         # defined before any of the system headers are included.  Another
4079         # case comes up with C++, e.g., on AIX the compiler compiles the
4080         # header files by themselves before looking at the body files it is
4081         # told to compile.  For ncurses, those header files do not include
4082         # the config.h
4083         if test "$ac_cv_sys_large_files" != no
4084         then
4085                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
4086         fi
4087         if test "$ac_cv_sys_largefile_source" != no
4088         then
4089                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
4090         fi
4091         if test "$ac_cv_sys_file_offset_bits" != no
4092         then
4093                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
4094         fi
4095
4096         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
4097                 AC_TRY_COMPILE([
4098 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
4099 #include <sys/types.h>
4100 #include <dirent.h>
4101                 ],[
4102                 /* if transitional largefile support is setup, this is true */
4103                 extern struct dirent64 * readdir(DIR *);
4104                 struct dirent64 *x = readdir((DIR *)0);
4105                 struct dirent *y = readdir((DIR *)0);
4106                 int z = x - y;
4107                 (void)z;
4108                 ],
4109                 [cf_cv_struct_dirent64=yes],
4110                 [cf_cv_struct_dirent64=no])
4111         ])
4112         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
4113         fi
4114 ])
4115 ])
4116 dnl ---------------------------------------------------------------------------
4117 dnl CF_LDFLAGS_STATIC version: 14 updated: 2021/01/02 17:09:14
4118 dnl -----------------
4119 dnl Check for compiler/linker flags used to temporarily force usage of static
4120 dnl libraries.  This depends on the compiler and platform.  Use this to help
4121 dnl ensure that the linker picks up a given library based on its position in
4122 dnl the list of linker options and libraries.
4123 AC_DEFUN([CF_LDFLAGS_STATIC],[
4124
4125 if test "$GCC" = yes ; then
4126         case "$cf_cv_system_name" in
4127         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
4128                 LDFLAGS_STATIC=
4129                 LDFLAGS_SHARED=
4130                 ;;
4131         (*)     # normally, except when broken
4132                 LDFLAGS_STATIC=-static
4133                 LDFLAGS_SHARED=-dynamic
4134                 ;;
4135         esac
4136 else
4137         case "$cf_cv_system_name" in
4138         (aix[[4-7]]*)   # from ld manpage
4139                 LDFLAGS_STATIC=-bstatic
4140                 LDFLAGS_SHARED=-bdynamic
4141                 ;;
4142         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
4143                 # We could also use just "archive" and "shared".
4144                 LDFLAGS_STATIC=-Wl,-a,archive_shared
4145                 LDFLAGS_SHARED=-Wl,-a,shared_archive
4146                 ;;
4147         (irix*)         # from ld manpage IRIX64
4148                 LDFLAGS_STATIC=-Bstatic
4149                 LDFLAGS_SHARED=-Bdynamic
4150                 ;;
4151         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
4152                 # alternative "-oldstyle_liblookup" (not in cc manpage)
4153                 LDFLAGS_STATIC=-noso
4154                 LDFLAGS_SHARED=-so_archive
4155                 ;;
4156         (solaris2*)
4157                 LDFLAGS_STATIC=-Bstatic
4158                 LDFLAGS_SHARED=-Bdynamic
4159                 ;;
4160         esac
4161 fi
4162
4163 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
4164 then
4165         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
4166
4167         rm -f libconftest.a
4168         cat >conftest.$ac_ext <<EOF
4169 #line __oline__ "configure"
4170 #include <stdio.h>
4171 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
4172 EOF
4173         if AC_TRY_EVAL(ac_compile) ; then
4174                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
4175                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
4176         fi
4177         rm -f conftest.*
4178
4179         cf_save_LIBS="$LIBS"
4180
4181         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
4182         AC_TRY_LINK([
4183 #line __oline__ "configure"
4184 #include <stdio.h>
4185 int cf_ldflags_static(FILE *fp);
4186 ],[
4187         return cf_ldflags_static(stdin);
4188 ],[
4189         # some linkers simply ignore the -dynamic
4190         case x`file "conftest$ac_exeext" 2>/dev/null` in
4191         (*static*)
4192                 cf_ldflags_static=no
4193                 ;;
4194         (*)
4195                 cf_ldflags_static=yes
4196                 ;;
4197         esac
4198 ],[cf_ldflags_static=no])
4199
4200         rm -f libconftest.*
4201         LIBS="$cf_save_LIBS"
4202
4203         AC_MSG_RESULT($cf_ldflags_static)
4204
4205         if test "$cf_ldflags_static" != yes
4206         then
4207                 LDFLAGS_STATIC=
4208                 LDFLAGS_SHARED=
4209         fi
4210 else
4211         LDFLAGS_STATIC=
4212         LDFLAGS_SHARED=
4213 fi
4214
4215 AC_SUBST(LDFLAGS_STATIC)
4216 AC_SUBST(LDFLAGS_SHARED)
4217 ])
4218 dnl ---------------------------------------------------------------------------
4219 dnl CF_LD_RPATH_OPT version: 9 updated: 2021/01/01 13:31:04
4220 dnl ---------------
4221 dnl For the given system and compiler, find the compiler flags to pass to the
4222 dnl loader to use the "rpath" feature.
4223 AC_DEFUN([CF_LD_RPATH_OPT],
4224 [
4225 AC_REQUIRE([CF_CHECK_CACHE])
4226
4227 LD_RPATH_OPT=
4228 if test "x$cf_cv_enable_rpath" != xno
4229 then
4230         AC_MSG_CHECKING(for an rpath option)
4231         case "$cf_cv_system_name" in
4232         (irix*)
4233                 if test "$GCC" = yes; then
4234                         LD_RPATH_OPT="-Wl,-rpath,"
4235                 else
4236                         LD_RPATH_OPT="-rpath "
4237                 fi
4238                 ;;
4239         (linux*|gnu*|k*bsd*-gnu|freebsd*)
4240                 LD_RPATH_OPT="-Wl,-rpath,"
4241                 ;;
4242         (openbsd[[2-9]].*|mirbsd*)
4243                 LD_RPATH_OPT="-Wl,-rpath,"
4244                 ;;
4245         (dragonfly*)
4246                 LD_RPATH_OPT="-rpath "
4247                 ;;
4248         (netbsd*)
4249                 LD_RPATH_OPT="-Wl,-rpath,"
4250                 ;;
4251         (osf*|mls+*)
4252                 LD_RPATH_OPT="-rpath "
4253                 ;;
4254         (solaris2*)
4255                 LD_RPATH_OPT="-R"
4256                 ;;
4257         (*)
4258                 ;;
4259         esac
4260         AC_MSG_RESULT($LD_RPATH_OPT)
4261
4262         case "x$LD_RPATH_OPT" in
4263         (x-R*)
4264                 AC_MSG_CHECKING(if we need a space after rpath option)
4265                 cf_save_LIBS="$LIBS"
4266                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
4267                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
4268                 LIBS="$cf_save_LIBS"
4269                 AC_MSG_RESULT($cf_rpath_space)
4270                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
4271                 ;;
4272         esac
4273 fi
4274 ])dnl
4275 dnl ---------------------------------------------------------------------------
4276 dnl CF_LD_SEARCHPATH version: 3 updated: 2021/03/05 19:13:35
4277 dnl ----------------
4278 dnl Try to obtain the linker's search-path, for use in scripts.
4279 dnl
4280 dnl Ignore LD_LIBRARY_PATH, etc.
4281 AC_DEFUN([CF_LD_SEARCHPATH],[
4282 AC_CACHE_CHECK(for linker search path,cf_cv_ld_searchpath,[
4283
4284 if test "$cross_compiling" != yes ; then
4285
4286 # GNU binutils' ld does not involve permissions which may stop ldconfig.
4287 cf_pathlist=`ld --verbose 2>/dev/null | grep SEARCH_DIR | sed -e 's,SEARCH_DIR[[("=]][[("=]]*,,g' -e 's/"[[)]];//gp' | sort -u`
4288
4289 # The -NX options tell newer versions of Linux ldconfig to not attempt to
4290 # update the cache, which makes it run faster.
4291 test -z "$cf_pathlist" && \
4292         cf_pathlist=`(ldconfig -NX -v) 2>/dev/null | sed -e '/^[[       ]]/d' -e 's/:$//' | sort -u`
4293
4294 test -z "$cf_pathlist" &&
4295         cf_pathlist=`(ldconfig -v) 2>/dev/null | sed -n -e '/^[[        ]]/d' -e 's/:$//p' | sort -u`
4296
4297 # This works with OpenBSD 6.5, which lists only filenames
4298 test -z "$cf_pathlist" &&
4299         cf_pathlist=`(ldconfig -v) 2>/dev/null | sed -n -e 's,^Adding \(.*\)/.*[$],\1,p' | sort -u`
4300
4301 if test -z "$cf_pathlist"
4302 then
4303         # dyld default path with MacOS
4304         if test -f /usr/bin/otool && test "x`uname -s`" = xDarwin
4305         then
4306                 # do this to bypass check
4307                 cf_cv_ld_searchpath='$HOME/lib'
4308                 cf_pathlist="/usr/local/lib /lib /usr/lib"
4309         fi
4310 fi
4311
4312 if test -z "$cf_pathlist"
4313 then
4314         # Solaris is "SunOS"
4315         if test -f /usr/bin/isainfo && test "x`uname -s`" = xSunOS
4316         then
4317                 case x`(isainfo -b)` in
4318                 (x64)
4319                         cf_pathlist="$cf_pathlist /lib/64 /usr/lib/64"
4320                         ;;
4321                 (x32)
4322                         test -d /usr/ccs/lib && cf_pathlist="$cf_pathlist /usr/ccs/lib"