aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2012,2013 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.668 2013/06/15 16:22:56 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54     [AC_TRY_LINK([#include <langinfo.h>],
  55       [char* cs = nl_langinfo(CODESET);],
  56       am_cv_langinfo_codeset=yes,
  57       am_cv_langinfo_codeset=no)
  58     ])
  59   if test $am_cv_langinfo_codeset = yes; then
  60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62   fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ACVERSION_CHECK version: 4 updated: 2013/03/04 19:52:56
  66 dnl ------------------
  67 dnl Conditionally generate script according to whether we're using a given autoconf.
  68 dnl
  69 dnl $1 = version to compare against
  70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  71 dnl $3 = code to use if AC_ACVERSION is older than $1.
  72 define([CF_ACVERSION_CHECK],
  73 [
  74 ifdef([AC_ACVERSION], ,[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])dnl
  75 ifdef([m4_version_compare],
  76 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  77 [CF_ACVERSION_COMPARE(
  78 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  79 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  80 dnl ---------------------------------------------------------------------------
  81 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  82 dnl --------------------
  83 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  84 dnl                      MAJOR2, MINOR2, TERNARY2,
  85 dnl                      PRINTABLE2, not FOUND, FOUND)
  86 define([CF_ACVERSION_COMPARE],
  87 [ifelse(builtin([eval], [$2 < $5]), 1,
  88 [ifelse([$8], , ,[$8])],
  89 [ifelse([$9], , ,[$9])])])dnl
  90 dnl ---------------------------------------------------------------------------
  91 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
  92 dnl -------------------
  93 dnl Construct the list of include-options for the C programs in the Ada95
  94 dnl binding.
  95 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  96 [
  97 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  98 if test "$srcdir" != "."; then
  99         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 100 fi
 101 if test "$GCC" != yes; then
 102         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 103 elif test "$includedir" != "/usr/include"; then
 104         if test "$includedir" = '${prefix}/include' ; then
 105                 if test $prefix != /usr ; then
 106                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 107                 fi
 108         else
 109                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 110         fi
 111 fi
 112 AC_SUBST(ACPPFLAGS)
 113 ])dnl
 114 dnl ---------------------------------------------------------------------------
 115 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 116 dnl ---------------
 117 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 118 AC_DEFUN([CF_ADD_ADAFLAGS],[
 119         ADAFLAGS="$ADAFLAGS $1"
 120         AC_SUBST(ADAFLAGS)
 121 ])dnl
 122 dnl ---------------------------------------------------------------------------
 123 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
 124 dnl -------------
 125 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 126 dnl The second parameter if given makes this macro verbose.
 127 dnl
 128 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 129 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 130 dnl confused by the quotes (which require backslashes to keep them usable).
 131 AC_DEFUN([CF_ADD_CFLAGS],
 132 [
 133 cf_fix_cppflags=no
 134 cf_new_cflags=
 135 cf_new_cppflags=
 136 cf_new_extra_cppflags=
 137
 138 for cf_add_cflags in $1
 139 do
 140 case $cf_fix_cppflags in
 141 no)
 142         case $cf_add_cflags in #(vi
 143         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 144                 case $cf_add_cflags in
 145                 -D*)
 146                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 147
 148                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 149                                 && test -z "${cf_tst_cflags}" \
 150                                 && cf_fix_cppflags=yes
 151
 152                         if test $cf_fix_cppflags = yes ; then
 153                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 154                                 continue
 155                         elif test "${cf_tst_cflags}" = "\"'" ; then
 156                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 157                                 continue
 158                         fi
 159                         ;;
 160                 esac
 161                 case "$CPPFLAGS" in
 162                 *$cf_add_cflags) #(vi
 163                         ;;
 164                 *) #(vi
 165                         case $cf_add_cflags in #(vi
 166                         -D*)
 167                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 168                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 169                                 ;;
 170                         esac
 171                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 172                         ;;
 173                 esac
 174                 ;;
 175         *)
 176                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 177                 ;;
 178         esac
 179         ;;
 180 yes)
 181         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 182
 183         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 184
 185         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 186                 && test -z "${cf_tst_cflags}" \
 187                 && cf_fix_cppflags=no
 188         ;;
 189 esac
 190 done
 191
 192 if test -n "$cf_new_cflags" ; then
 193         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 194         CFLAGS="$CFLAGS $cf_new_cflags"
 195 fi
 196
 197 if test -n "$cf_new_cppflags" ; then
 198         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 199         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 200 fi
 201
 202 if test -n "$cf_new_extra_cppflags" ; then
 203         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 204         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 205 fi
 206
 207 AC_SUBST(EXTRA_CPPFLAGS)
 208
 209 ])dnl
 210 dnl ---------------------------------------------------------------------------
 211 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 212 dnl -------------
 213 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 214 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 215 dnl but old versions (and some misinstalled ones) need that.  To make things
 216 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 217 dnl the include-path).
 218 AC_DEFUN([CF_ADD_INCDIR],
 219 [
 220 if test -n "$1" ; then
 221   for cf_add_incdir in $1
 222   do
 223         while test $cf_add_incdir != /usr/include
 224         do
 225           if test -d $cf_add_incdir
 226           then
 227                 cf_have_incdir=no
 228                 if test -n "$CFLAGS$CPPFLAGS" ; then
 229                   # a loop is needed to ensure we can add subdirs of existing dirs
 230                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 231                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 232                           cf_have_incdir=yes; break
 233                         fi
 234                   done
 235                 fi
 236
 237                 if test "$cf_have_incdir" = no ; then
 238                   if test "$cf_add_incdir" = /usr/local/include ; then
 239                         if test "$GCC" = yes
 240                         then
 241                           cf_save_CPPFLAGS=$CPPFLAGS
 242                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 243                           AC_TRY_COMPILE([#include <stdio.h>],
 244                                   [printf("Hello")],
 245                                   [],
 246                                   [cf_have_incdir=yes])
 247                           CPPFLAGS=$cf_save_CPPFLAGS
 248                         fi
 249                   fi
 250                 fi
 251
 252                 if test "$cf_have_incdir" = no ; then
 253                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 254                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 255
 256                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 257                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 258                   cf_add_incdir="$cf_top_incdir"
 259                 else
 260                   break
 261                 fi
 262           fi
 263         done
 264   done
 265 fi
 266 ])dnl
 267 dnl ---------------------------------------------------------------------------
 268 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 269 dnl ----------
 270 dnl Add a library, used to enforce consistency.
 271 dnl
 272 dnl $1 = library to add, without the "-l"
 273 dnl $2 = variable to update (default $LIBS)
 274 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 275 dnl ---------------------------------------------------------------------------
 276 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 277 dnl -------------
 278 dnl     Adds to the library-path
 279 dnl
 280 dnl     Some machines have trouble with multiple -L options.
 281 dnl
 282 dnl $1 is the (list of) directory(s) to add
 283 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 284 dnl
 285 AC_DEFUN([CF_ADD_LIBDIR],
 286 [
 287 if test -n "$1" ; then
 288   for cf_add_libdir in $1
 289   do
 290     if test $cf_add_libdir = /usr/lib ; then
 291       :
 292     elif test -d $cf_add_libdir
 293     then
 294       cf_have_libdir=no
 295       if test -n "$LDFLAGS$LIBS" ; then
 296         # a loop is needed to ensure we can add subdirs of existing dirs
 297         for cf_test_libdir in $LDFLAGS $LIBS ; do
 298           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 299             cf_have_libdir=yes; break
 300           fi
 301         done
 302       fi
 303       if test "$cf_have_libdir" = no ; then
 304         CF_VERBOSE(adding $cf_add_libdir to library-path)
 305         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 306       fi
 307     fi
 308   done
 309 fi
 310 ])dnl
 311 dnl ---------------------------------------------------------------------------
 312 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 313 dnl -----------
 314 dnl Add one or more libraries, used to enforce consistency.
 315 dnl
 316 dnl $1 = libraries to add, with the "-l", etc.
 317 dnl $2 = variable to update (default $LIBS)
 318 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 319 dnl ---------------------------------------------------------------------------
 320 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 321 dnl ------------------
 322 dnl Append to a search-list for a nonstandard header/lib-file
 323 dnl     $1 = the variable to return as result
 324 dnl     $2 = the package name
 325 dnl     $3 = the subdirectory, e.g., bin, include or lib
 326 dnl $4 = the directory under which we will test for subdirectories
 327 dnl $5 = a directory that we do not want $4 to match
 328 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 329 [
 330 test "$4" != "$5" && \
 331 test -d "$4" && \
 332 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 333         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 334         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 335         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 336         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 337         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 338         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 339 }
 340 ])dnl
 341 dnl ---------------------------------------------------------------------------
 342 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 343 dnl --------------
 344 dnl Allow user to disable a normally-on option.
 345 AC_DEFUN([CF_ARG_DISABLE],
 346 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 347 dnl ---------------------------------------------------------------------------
 348 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 349 dnl -------------
 350 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 351 dnl values.
 352 dnl
 353 dnl Parameters:
 354 dnl $1 = option name
 355 dnl $2 = help-string
 356 dnl $3 = action to perform if option is not default
 357 dnl $4 = action if perform if option is default
 358 dnl $5 = default option value (either 'yes' or 'no')
 359 AC_DEFUN([CF_ARG_OPTION],
 360 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 361   if test "$enableval" != "$5" ; then
 362 ifelse([$3],,[    :]dnl
 363 ,[    $3]) ifelse([$4],,,[
 364   else
 365     $4])
 366   fi],[enableval=$5 ifelse([$4],,,[
 367   $4
 368 ])dnl
 369   ])])dnl
 370 dnl ---------------------------------------------------------------------------
 371 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 372 dnl -----------
 373 dnl Check for suitable "ar" (archiver) options for updating an archive.
 374 AC_DEFUN([CF_AR_FLAGS],[
 375 AC_REQUIRE([CF_PROG_AR])
 376
 377 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 378         cf_cv_ar_flags=unknown
 379         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 380         do
 381
 382                 # check if $ARFLAGS already contains this choice
 383                 if test "x$ARFLAGS" != "x" ; then
 384                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 385                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 386                                 cf_cv_ar_flags=
 387                                 break
 388                         fi
 389                 fi
 390
 391                 rm -f conftest.$ac_cv_objext
 392                 rm -f conftest.a
 393
 394                 cat >conftest.$ac_ext <<EOF
 395 #line __oline__ "configure"
 396 int     testdata[[3]] = { 123, 456, 789 };
 397 EOF
 398                 if AC_TRY_EVAL(ac_compile) ; then
 399                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 400                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 401                         if test -f conftest.a ; then
 402                                 cf_cv_ar_flags=$cf_ar_flags
 403                                 break
 404                         fi
 405                 else
 406                         CF_VERBOSE(cannot compile test-program)
 407                         break
 408                 fi
 409         done
 410         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 411 ])
 412
 413 if test -n "$ARFLAGS" ; then
 414         if test -n "$cf_cv_ar_flags" ; then
 415                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 416         fi
 417 else
 418         ARFLAGS=$cf_cv_ar_flags
 419 fi
 420
 421 AC_SUBST(ARFLAGS)
 422 ])
 423 dnl ---------------------------------------------------------------------------
 424 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
 425 dnl -----------------
 426 dnl Check if awk can handle big strings using printf.  Some older versions of
 427 dnl awk choke on large strings passed via "%s".
 428 dnl
 429 dnl $1 = desired string size
 430 dnl $2 = variable to set with result
 431 AC_DEFUN([CF_AWK_BIG_PRINTF],
 432 [
 433         case x$AWK in #(vi
 434         x)
 435                 eval $2=no
 436                 ;;
 437         *) #(vi
 438                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 439                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 440                         eval $2=yes
 441                 else
 442                         eval $2=no
 443                 fi
 444                 ;;
 445         esac
 446 ])dnl
 447 dnl ---------------------------------------------------------------------------
 448 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 449 dnl ------------
 450 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 451 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 452 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 453 dnl
 454 dnl Treat the configuration-variable specially here, since we're directly
 455 dnl substituting its value (i.e., 1/0).
 456 dnl
 457 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 458 AC_DEFUN([CF_BOOL_DECL],
 459 [
 460 AC_MSG_CHECKING(if we should include stdbool.h)
 461
 462 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 463         AC_TRY_COMPILE([],[bool foo = false],
 464                 [cf_cv_header_stdbool_h=0],
 465                 [AC_TRY_COMPILE([
 466 #ifndef __BEOS__
 467 #include <stdbool.h>
 468 #endif
 469 ],[bool foo = false],
 470                         [cf_cv_header_stdbool_h=1],
 471                         [cf_cv_header_stdbool_h=0])])])
 472
 473 if test "$cf_cv_header_stdbool_h" = 1
 474 then    AC_MSG_RESULT(yes)
 475 else    AC_MSG_RESULT(no)
 476 fi
 477
 478 AC_MSG_CHECKING([for builtin bool type])
 479
 480 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 481         AC_TRY_COMPILE([
 482 #include <stdio.h>
 483 #include <sys/types.h>
 484 ],[bool x = false],
 485                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 486                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 487         ])
 488
 489 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 490 then    AC_MSG_RESULT(yes)
 491 else    AC_MSG_RESULT(no)
 492 fi
 493 ])dnl
 494 dnl ---------------------------------------------------------------------------
 495 dnl CF_BOOL_SIZE version: 13 updated: 2013/04/13 18:03:21
 496 dnl ------------
 497 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 498 dnl Don't bother looking for bool.h, since it's been deprecated.
 499 dnl
 500 dnl If the current compiler is C rather than C++, we get the bool definition
 501 dnl from <stdbool.h>.
 502 AC_DEFUN([CF_BOOL_SIZE],
 503 [
 504 AC_MSG_CHECKING([for size of bool])
 505 AC_CACHE_VAL(cf_cv_type_of_bool,[
 506         rm -f cf_test.out
 507         AC_TRY_RUN([
 508 #include <stdlib.h>
 509 #include <stdio.h>
 510
 511 #if defined(__cplusplus)
 512
 513 #ifdef HAVE_GXX_BUILTIN_H
 514 #include <g++/builtin.h>
 515 #elif HAVE_GPP_BUILTIN_H
 516 #include <gpp/builtin.h>
 517 #elif HAVE_BUILTIN_H
 518 #include <builtin.h>
 519 #endif
 520
 521 #else
 522
 523 #if $cf_cv_header_stdbool_h
 524 #include <stdbool.h>
 525 #endif
 526
 527 #endif
 528
 529 int main()
 530 {
 531         FILE *fp = fopen("cf_test.out", "w");
 532         if (fp != 0) {
 533                 bool x = true;
 534                 if ((bool)(-x) >= 0)
 535                         fputs("unsigned ", fp);
 536                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 537                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 538                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 539                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 540                 fclose(fp);
 541         }
 542         ${cf_cv_main_return:-return}(0);
 543 }
 544                 ],
 545                 [cf_cv_type_of_bool=`cat cf_test.out`
 546                  if test -z "$cf_cv_type_of_bool"; then
 547                    cf_cv_type_of_bool=unknown
 548                  fi],
 549                 [cf_cv_type_of_bool=unknown],
 550                 [cf_cv_type_of_bool=unknown])
 551         ])
 552         rm -f cf_test.out
 553 AC_MSG_RESULT($cf_cv_type_of_bool)
 554 if test "$cf_cv_type_of_bool" = unknown ; then
 555         case .$NCURSES_BOOL in #(vi
 556         .auto|.) NCURSES_BOOL=unsigned;;
 557         esac
 558         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 559         cf_cv_type_of_bool=$NCURSES_BOOL
 560 fi
 561 ])dnl
 562 dnl ---------------------------------------------------------------------------
 563 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 564 dnl -----------
 565 dnl If we're cross-compiling, allow the user to override the tools and their
 566 dnl options.  The configure script is oriented toward identifying the host
 567 dnl compiler, etc., but we need a build compiler to generate parts of the
 568 dnl source.
 569 dnl
 570 dnl $1 = default for $CPPFLAGS
 571 dnl $2 = default for $LIBS
 572 AC_DEFUN([CF_BUILD_CC],[
 573 CF_ACVERSION_CHECK(2.52,,
 574         [AC_REQUIRE([CF_PROG_EXT])])
 575 if test "$cross_compiling" = yes ; then
 576
 577         # defaults that we might want to override
 578         : ${BUILD_CFLAGS:=''}
 579         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 580         : ${BUILD_LDFLAGS:=''}
 581         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 582         : ${BUILD_EXEEXT:='$x'}
 583         : ${BUILD_OBJEXT:='o'}
 584
 585         AC_ARG_WITH(build-cc,
 586                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 587                 [BUILD_CC="$withval"],
 588                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 589         AC_MSG_CHECKING(for native build C compiler)
 590         AC_MSG_RESULT($BUILD_CC)
 591
 592         AC_MSG_CHECKING(for native build C preprocessor)
 593         AC_ARG_WITH(build-cpp,
 594                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 595                 [BUILD_CPP="$withval"],
 596                 [BUILD_CPP='${BUILD_CC} -E'])
 597         AC_MSG_RESULT($BUILD_CPP)
 598
 599         AC_MSG_CHECKING(for native build C flags)
 600         AC_ARG_WITH(build-cflags,
 601                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 602                 [BUILD_CFLAGS="$withval"])
 603         AC_MSG_RESULT($BUILD_CFLAGS)
 604
 605         AC_MSG_CHECKING(for native build C preprocessor-flags)
 606         AC_ARG_WITH(build-cppflags,
 607                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 608                 [BUILD_CPPFLAGS="$withval"])
 609         AC_MSG_RESULT($BUILD_CPPFLAGS)
 610
 611         AC_MSG_CHECKING(for native build linker-flags)
 612         AC_ARG_WITH(build-ldflags,
 613                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 614                 [BUILD_LDFLAGS="$withval"])
 615         AC_MSG_RESULT($BUILD_LDFLAGS)
 616
 617         AC_MSG_CHECKING(for native build linker-libraries)
 618         AC_ARG_WITH(build-libs,
 619                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 620                 [BUILD_LIBS="$withval"])
 621         AC_MSG_RESULT($BUILD_LIBS)
 622
 623         # this assumes we're on Unix.
 624         BUILD_EXEEXT=
 625         BUILD_OBJEXT=o
 626
 627         : ${BUILD_CC:='${CC}'}
 628
 629         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 630                 AC_MSG_ERROR([Cross-build requires two compilers.
 631 Use --with-build-cc to specify the native compiler.])
 632         fi
 633
 634 else
 635         : ${BUILD_CC:='${CC}'}
 636         : ${BUILD_CPP:='${CPP}'}
 637         : ${BUILD_CFLAGS:='${CFLAGS}'}
 638         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 639         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 640         : ${BUILD_LIBS:='${LIBS}'}
 641         : ${BUILD_EXEEXT:='$x'}
 642         : ${BUILD_OBJEXT:='o'}
 643 fi
 644
 645 AC_SUBST(BUILD_CC)
 646 AC_SUBST(BUILD_CPP)
 647 AC_SUBST(BUILD_CFLAGS)
 648 AC_SUBST(BUILD_CPPFLAGS)
 649 AC_SUBST(BUILD_LDFLAGS)
 650 AC_SUBST(BUILD_LIBS)
 651 AC_SUBST(BUILD_EXEEXT)
 652 AC_SUBST(BUILD_OBJEXT)
 653 ])dnl
 654 dnl ---------------------------------------------------------------------------
 655 dnl CF_CC_ENV_FLAGS version: 1 updated: 2012/10/03 05:25:49
 656 dnl ---------------
 657 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 658 dnl into CC.  This will not help with broken scripts that wrap the compiler with
 659 dnl options, but eliminates a more common category of user confusion.
 660 AC_DEFUN([CF_CC_ENV_FLAGS],
 661 [
 662 # This should have been defined by AC_PROG_CC
 663 : ${CC:=cc}
 664
 665 AC_MSG_CHECKING(\$CC variable)
 666 case "$CC" in #(vi
 667 *[[\ \  ]]-[[IUD]]*)
 668         AC_MSG_RESULT(broken)
 669         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 670         # humor him...
 671         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 672         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 673         CF_ADD_CFLAGS($cf_flags)
 674         ;;
 675 *)
 676         AC_MSG_RESULT(ok)
 677         ;;
 678 esac
 679 ])dnl
 680 dnl ---------------------------------------------------------------------------
 681 dnl CF_CFG_DEFAULTS version: 9 updated: 2013/04/13 18:58:32
 682 dnl ---------------
 683 dnl Determine the default configuration into which we'll install ncurses.  This
 684 dnl can be overridden by the user's command-line options.  There's two items to
 685 dnl look for:
 686 dnl     1. the prefix (e.g., /usr)
 687 dnl     2. the header files (e.g., /usr/include/ncurses)
 688 dnl We'll look for a previous installation of ncurses and use the same defaults.
 689 dnl
 690 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 691 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 692 dnl programs from a vendor's.
 693 AC_DEFUN([CF_CFG_DEFAULTS],
 694 [
 695 AC_MSG_CHECKING(for prefix)
 696 if test "x$prefix" = "xNONE" ; then
 697         case "$cf_cv_system_name" in
 698                 # non-vendor systems don't have a conflict
 699         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|k*bsd*-gnu|mingw*)
 700                 prefix=/usr
 701                 ;;
 702         *)      prefix=$ac_default_prefix
 703                 ;;
 704         esac
 705 fi
 706 AC_MSG_RESULT($prefix)
 707
 708 if test "x$prefix" = "xNONE" ; then
 709 AC_MSG_CHECKING(for default include-directory)
 710 test -n "$verbose" && echo 1>&AC_FD_MSG
 711 for cf_symbol in \
 712         $includedir \
 713         $includedir/ncurses \
 714         $prefix/include \
 715         $prefix/include/ncurses \
 716         /usr/local/include \
 717         /usr/local/include/ncurses \
 718         /usr/include \
 719         /usr/include/ncurses
 720 do
 721         cf_dir=`eval echo $cf_symbol`
 722         if test -f $cf_dir/curses.h ; then
 723         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 724                 includedir="$cf_symbol"
 725                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 726                 break
 727         fi
 728         fi
 729         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 730 done
 731 AC_MSG_RESULT($includedir)
 732 fi
 733 ])dnl
 734 dnl ---------------------------------------------------------------------------
 735 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
 736 dnl ----------
 737 dnl Check if the terminal-capability database functions are available.  If not,
 738 dnl ncurses has a much-reduced version.
 739 AC_DEFUN([CF_CGETENT],[
 740 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 741 AC_TRY_LINK([
 742 #include <stdlib.h>],[
 743         char temp[128];
 744         char *buf = temp;
 745         char *db_array = temp;
 746         cgetent(&buf, &db_array, "vt100");
 747         cgetcap(buf, "tc", '=');
 748         cgetmatch(buf, "tc");
 749         ],
 750         [cf_cv_cgetent=yes],
 751         [cf_cv_cgetent=no])
 752 ])
 753
 754 if test "$cf_cv_cgetent" = yes
 755 then
 756         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 757 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 758 AC_TRY_LINK([
 759 #include <stdlib.h>],[
 760         char temp[128];
 761         char *buf = temp;
 762 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 763         const char *db_array = temp;
 764         cgetent(&buf, &db_array, "vt100");
 765 #endif
 766         cgetcap(buf, "tc", '=');
 767         cgetmatch(buf, "tc");
 768         ],
 769         [cf_cv_cgetent_const=yes],
 770         [cf_cv_cgetent_const=no])
 771 ])
 772         if test "$cf_cv_cgetent_const" = yes
 773         then
 774                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 775         fi
 776 fi
 777 ])dnl
 778 dnl ---------------------------------------------------------------------------
 779 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 780 dnl --------------
 781 dnl Check if we're accidentally using a cache from a different machine.
 782 dnl Derive the system name, as a check for reusing the autoconf cache.
 783 dnl
 784 dnl If we've packaged config.guess and config.sub, run that (since it does a
 785 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 786 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 787 dnl which is useful in cross-compiles.
 788 dnl
 789 dnl Note: we would use $ac_config_sub, but that is one of the places where
 790 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 791 AC_DEFUN([CF_CHECK_CACHE],
 792 [
 793 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 794         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 795         system_name="$host_os"
 796 else
 797         system_name="`(uname -s -r) 2>/dev/null`"
 798         if test -z "$system_name" ; then
 799                 system_name="`(hostname) 2>/dev/null`"
 800         fi
 801 fi
 802 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 803 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 804
 805 test -z "$system_name" && system_name="$cf_cv_system_name"
 806 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 807
 808 if test ".$system_name" != ".$cf_cv_system_name" ; then
 809         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 810         AC_MSG_ERROR("Please remove config.cache and try again.")
 811 fi
 812 ])dnl
 813 dnl ---------------------------------------------------------------------------
 814 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
 815 dnl --------------
 816 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 817 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 818 dnl ourselves.
 819 dnl
 820 dnl $1 = the name to check
 821 dnl $2 = the assumed type
 822 AC_DEFUN([CF_CHECK_ERRNO],
 823 [
 824 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 825     AC_TRY_COMPILE([
 826 #ifdef HAVE_STDLIB_H
 827 #include <stdlib.h>
 828 #endif
 829 #include <stdio.h>
 830 #include <sys/types.h>
 831 #include <errno.h> ],
 832     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 833     [cf_cv_dcl_$1=yes],
 834     [cf_cv_dcl_$1=no])
 835 ])
 836
 837 if test "$cf_cv_dcl_$1" = no ; then
 838     CF_UPPER(cf_result,decl_$1)
 839     AC_DEFINE_UNQUOTED($cf_result)
 840 fi
 841
 842 # It's possible (for near-UNIX clones) that the data doesn't exist
 843 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 844 ])dnl
 845 dnl ---------------------------------------------------------------------------
 846 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
 847 dnl --------------------
 848 dnl Check for existence of external data in the current set of libraries.  If
 849 dnl we can modify it, it's real enough.
 850 dnl $1 = the name to check
 851 dnl $2 = its type
 852 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 853 [
 854 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 855     AC_TRY_LINK([
 856 #undef $1
 857 extern $2 $1;
 858 ],
 859     [$1 = 2],
 860     [cf_cv_have_$1=yes],
 861     [cf_cv_have_$1=no])
 862 ])
 863
 864 if test "$cf_cv_have_$1" = yes ; then
 865     CF_UPPER(cf_result,have_$1)
 866     AC_DEFINE_UNQUOTED($cf_result)
 867 fi
 868
 869 ])dnl
 870 dnl ---------------------------------------------------------------------------
 871 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 872 dnl -------------------
 873 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 874 dnl is not "weak" - warn about this because it can create problems linking
 875 dnl applications with ncurses.
 876 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 877 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 878
 879 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 880 cf_cv_check_gpm_wgetch=unknown
 881 if test "$cross_compiling" != yes ; then
 882
 883 cat >conftest.$ac_ext <<CF_EOF
 884 #include <gpm.h>
 885 int main()
 886 {
 887         Gpm_Wgetch();
 888         ${cf_cv_main_return:-return}(0);
 889 }
 890 CF_EOF
 891
 892         cf_save_LIBS="$LIBS"
 893         # This only works if we can look at the symbol table.  If a shared
 894         # library is stripped for install, we cannot use that.  So we're forced
 895         # to rely on the static library, noting that some packagers may not
 896         # include it.
 897         LIBS="-static -lgpm -dynamic $LIBS"
 898         if AC_TRY_EVAL(ac_compile) ; then
 899                 if AC_TRY_EVAL(ac_link) ; then
 900                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 901                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 902                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 903                 fi
 904         fi
 905         rm -rf conftest*
 906         LIBS="$cf_save_LIBS"
 907 fi
 908 ])
 909
 910 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 911         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 912 fi
 913 ])])dnl
 914 dnl ---------------------------------------------------------------------------
 915 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
 916 dnl ------------------------
 917 dnl Show the version of libtool
 918 dnl
 919 dnl Save the version in a cache variable - this is not entirely a good thing,
 920 dnl but the version string from libtool is very ugly, and for bug reports it
 921 dnl might be useful to have the original string.
 922 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
 923 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
 924 then
 925         AC_MSG_CHECKING(version of $LIBTOOL)
 926         CF_LIBTOOL_VERSION
 927         AC_MSG_RESULT($cf_cv_libtool_version)
 928         if test -z "$cf_cv_libtool_version" ; then
 929                 AC_MSG_ERROR(This is not GNU libtool)
 930         fi
 931 else
 932         AC_MSG_ERROR(GNU libtool has not been found)
 933 fi
 934 ])dnl
 935 dnl ---------------------------------------------------------------------------
 936 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
 937 dnl ----------------
 938 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
 939 AC_DEFUN([CF_CHECK_WCHAR_H],[
 940 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
 941 AC_TRY_COMPILE(
 942 [
 943 #include <stdlib.h>
 944 #include <wchar.h>
 945 ],[
 946         wint_t foo = 0;
 947         int bar = iswpunct(foo)],
 948         [cf_cv_wchar_h_okay=yes],
 949         [cf_cv_wchar_h_okay=no])])
 950
 951 if test $cf_cv_wchar_h_okay = no
 952 then
 953         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 954 fi
 955 ])dnl
 956 dnl ---------------------------------------------------------------------------
 957 dnl CF_CLANG_COMPILER version: 1 updated: 2012/06/16 14:55:39
 958 dnl -----------------
 959 dnl Check if the given compiler is really clang.  clang's C driver defines
 960 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 961 dnl not ignore some gcc options.
 962 dnl
 963 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 964 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 965 dnl the wrappers for gcc and g++ warnings.
 966 dnl
 967 dnl $1 = GCC (default) or GXX
 968 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
 969 dnl $3 = CFLAGS (default) or CXXFLAGS
 970 AC_DEFUN([CF_CLANG_COMPILER],[
 971 ifelse([$2],,CLANG_COMPILER,[$2])=no
 972
 973 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 974         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 975         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 976         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 977         AC_TRY_COMPILE([],[
 978 #ifdef __clang__
 979 #else
 980 make an error
 981 #endif
 982 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 983 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
 984 ],[])
 985         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 986         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 987 fi
 988 ])
 989 dnl ---------------------------------------------------------------------------
 990 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
 991 dnl -----------------
 992 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
 993 dnl is a late feature for the standard and is not in some recent compilers
 994 dnl (1999/9/11).
 995 AC_DEFUN([CF_CPP_PARAM_INIT],
 996 [
 997 if test -n "$CXX"; then
 998 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
 999         AC_LANG_SAVE
1000         AC_LANG_CPLUSPLUS
1001         AC_TRY_RUN([
1002 class TEST {
1003 private:
1004         int value;
1005 public:
1006         TEST(int x = 1);
1007         ~TEST();
1008 };
1009
1010 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1011 {
1012         value = x;
1013 }
1014 int main() { }
1015 ],
1016         [cf_cv_cpp_param_init=yes],
1017         [cf_cv_cpp_param_init=no],
1018         [cf_cv_cpp_param_init=unknown])
1019         AC_LANG_RESTORE
1020 ])
1021 fi
1022 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1023 ])dnl
1024 dnl ---------------------------------------------------------------------------
1025 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1026 dnl ------------------
1027 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1028 dnl not be supported in g++ before 3.0
1029 AC_DEFUN([CF_CPP_STATIC_CAST],
1030 [
1031 if test -n "$CXX"; then
1032
1033 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1034         AC_LANG_SAVE
1035         AC_LANG_CPLUSPLUS
1036
1037         AC_TRY_COMPILE([
1038 class NCursesPanel
1039 {
1040 public:
1041   NCursesPanel(int nlines,
1042                int ncols,
1043                int begin_y = 0,
1044                int begin_x = 0)
1045   {
1046   }
1047   NCursesPanel();
1048   ~NCursesPanel();
1049 };
1050
1051 template<class T> class NCursesUserPanel : public NCursesPanel
1052 {
1053 public:
1054   NCursesUserPanel (int nlines,
1055                     int ncols,
1056                     int begin_y = 0,
1057                     int begin_x = 0,
1058                     const T* p_UserData = static_cast<T*>(0))
1059     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1060   {
1061   };
1062   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1063   {
1064   };
1065
1066   virtual ~NCursesUserPanel() {};
1067 };
1068 ],[
1069         const char* p_UserData = static_cast<char*>(0)],
1070         [cf_cv_cpp_static_cast=yes],
1071         [cf_cv_cpp_static_cast=no])
1072
1073         AC_LANG_RESTORE
1074 ])
1075
1076 fi
1077
1078 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1079 ])dnl
1080 dnl ---------------------------------------------------------------------------
1081 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1082 dnl ---------------
1083 dnl Setup special archiver flags for given compilers.
1084 AC_DEFUN([CF_CXX_AR_FLAGS],[
1085         CXX_AR='$(AR)'
1086         CXX_ARFLAGS='$(ARFLAGS)'
1087         case $cf_cv_system_name in #(vi
1088         irix*) #(vi
1089             if test "$GXX" != yes ; then
1090                 CXX_AR='$(CXX)'
1091                 CXX_ARFLAGS='-ar -o'
1092             fi
1093             ;;
1094         sco3.2v5*) #(vi
1095             CXXLDFLAGS="-u main"
1096             ;;
1097         solaris2*)
1098             if test "$GXX" != yes ; then
1099                 CXX_AR='$(CXX)'
1100                 CXX_ARFLAGS='-xar -o'
1101             fi
1102             ;;
1103         esac
1104         AC_SUBST(CXXLDFLAGS)
1105         AC_SUBST(CXX_AR)
1106         AC_SUBST(CXX_ARFLAGS)
1107 ])dnl
1108 dnl ---------------------------------------------------------------------------
1109 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1110 dnl -------------------------
1111 dnl For c++, check if iostream uses "std::" namespace.
1112 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1113 AC_CHECK_HEADERS(iostream)
1114 if test x"$ac_cv_header_iostream" = xyes ; then
1115         AC_MSG_CHECKING(if iostream uses std-namespace)
1116         AC_TRY_COMPILE([
1117 #include <iostream>
1118 using std::endl;
1119 using std::cerr;],[
1120 cerr << "testing" << endl;
1121 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1122         AC_MSG_RESULT($cf_iostream_namespace)
1123         if test "$cf_iostream_namespace" = yes ; then
1124                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1125         fi
1126 fi
1127 ])dnl
1128 dnl ---------------------------------------------------------------------------
1129 dnl CF_C_INLINE version: 4 updated: 2012/06/16 14:55:39
1130 dnl -----------
1131 dnl Check if the C compiler supports "inline".
1132 dnl $1 is the name of a shell variable to set if inline is supported
1133 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1134 AC_DEFUN([CF_C_INLINE],[
1135 AC_C_INLINE
1136 $1=
1137 if test "$ac_cv_c_inline" != no ; then
1138   $1=inline
1139   if test "$INTEL_COMPILER" = yes
1140   then
1141     :
1142   elif test "$CLANG_COMPILER" = yes
1143   then
1144     :
1145   elif test "$GCC" = yes
1146   then
1147     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1148       cf_save_CFLAGS=$CFLAGS
1149       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1150       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1151       [${cf_cv_main_return:-return} foo()],
1152       [cf_cv_gcc_inline=yes],
1153       [cf_cv_gcc_inline=no])
1154       CFLAGS=$cf_save_CFLAGS
1155     ])
1156     if test "$cf_cv_gcc_inline" = yes ; then
1157         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1158     fi
1159   fi
1160 fi
1161 AC_SUBST($1)
1162 ])dnl
1163 dnl ---------------------------------------------------------------------------
1164 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1165 dnl ----------
1166 dnl "dirname" is not portable, so we fake it with a shell script.
1167 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1168 dnl ---------------------------------------------------------------------------
1169 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1170 dnl ---------------
1171 AC_DEFUN([CF_DIRS_TO_MAKE],
1172 [
1173 DIRS_TO_MAKE="lib"
1174 for cf_item in $cf_list_models
1175 do
1176         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1177         for cf_item2 in $DIRS_TO_MAKE
1178         do
1179                 test $cf_item2 = $cf_subdir && break
1180         done
1181         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1182 done
1183 for cf_dir in $DIRS_TO_MAKE
1184 do
1185         test ! -d $cf_dir && mkdir $cf_dir
1186 done
1187 AC_SUBST(DIRS_TO_MAKE)
1188 ])dnl
1189 dnl ---------------------------------------------------------------------------
1190 dnl CF_DISABLE_ECHO version: 12 updated: 2012/10/06 16:30:28
1191 dnl ---------------
1192 dnl You can always use "make -n" to see the actual options, but it's hard to
1193 dnl pick out/analyze warning messages when the compile-line is long.
1194 dnl
1195 dnl Sets:
1196 dnl     ECHO_LT - symbol to control if libtool is verbose
1197 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1198 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1199 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1200 dnl     ECHO_CC - symbol to put before any "cc" line
1201 dnl
1202 AC_DEFUN([CF_DISABLE_ECHO],[
1203 AC_MSG_CHECKING(if you want to see long compiling messages)
1204 CF_ARG_DISABLE(echo,
1205         [  --disable-echo          do not display "compiling" commands],
1206         [
1207     ECHO_LT='--silent'
1208     ECHO_LD='@echo linking [$]@;'
1209     RULE_CC='@echo compiling [$]<'
1210     SHOW_CC='@echo compiling [$]@'
1211     ECHO_CC='@'
1212 ],[
1213     ECHO_LT=''
1214     ECHO_LD=''
1215     RULE_CC=''
1216     SHOW_CC=''
1217     ECHO_CC=''
1218 ])
1219 AC_MSG_RESULT($enableval)
1220 AC_SUBST(ECHO_LT)
1221 AC_SUBST(ECHO_LD)
1222 AC_SUBST(RULE_CC)
1223 AC_SUBST(SHOW_CC)
1224 AC_SUBST(ECHO_CC)
1225 ])dnl
1226 dnl ---------------------------------------------------------------------------
1227 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1228 dnl ----------------
1229 dnl Combine no-leak checks with the libraries or tools that are used for the
1230 dnl checks.
1231 AC_DEFUN([CF_DISABLE_LEAKS],[
1232
1233 AC_REQUIRE([CF_WITH_DMALLOC])
1234 AC_REQUIRE([CF_WITH_DBMALLOC])
1235 AC_REQUIRE([CF_WITH_VALGRIND])
1236
1237 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1238 AC_ARG_ENABLE(leaks,
1239         [  --disable-leaks         test: free permanent memory, analyze leaks],
1240         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1241         : ${with_no_leaks:=no})
1242 AC_MSG_RESULT($with_no_leaks)
1243
1244 if test "$with_no_leaks" = yes ; then
1245         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1246         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1247 fi
1248 ])dnl
1249 dnl ---------------------------------------------------------------------------
1250 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1251 dnl --------------------------
1252 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1253 dnl the older "-version-info" feature.  The newer feature allows us to use
1254 dnl version numbering on shared libraries which make them compatible with
1255 dnl various systems.
1256 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1257 [
1258 AC_MSG_CHECKING(if libtool -version-number should be used)
1259 CF_ARG_DISABLE(libtool-version,
1260         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1261         [cf_libtool_version=no],
1262         [cf_libtool_version=yes])
1263 AC_MSG_RESULT($cf_libtool_version)
1264
1265 if test "$cf_libtool_version" = yes ; then
1266         LIBTOOL_VERSION="-version-number"
1267 else
1268         LIBTOOL_VERSION="-version-info"
1269 fi
1270
1271 AC_SUBST(LIBTOOL_VERSION)
1272 ])dnl
1273 dnl ---------------------------------------------------------------------------
1274 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1275 dnl ---------------------
1276 dnl The rpath-hack makes it simpler to build programs, particularly with the
1277 dnl *BSD ports which may have essential libraries in unusual places.  But it
1278 dnl can interfere with building an executable for the base system.  Use this
1279 dnl option in that case.
1280 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1281 [
1282 AC_MSG_CHECKING(if rpath-hack should be disabled)
1283 CF_ARG_DISABLE(rpath-hack,
1284         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1285         [cf_disable_rpath_hack=yes],
1286         [cf_disable_rpath_hack=no])
1287 AC_MSG_RESULT($cf_disable_rpath_hack)
1288 if test "$cf_disable_rpath_hack" = no ; then
1289         CF_RPATH_HACK
1290 fi
1291 ])
1292 dnl ---------------------------------------------------------------------------
1293 dnl CF_ENABLE_PC_FILES version: 9 updated: 2012/08/04 13:59:54
1294 dnl ------------------
1295 dnl This is the "--enable-pc-files" option, which is available if there is a
1296 dnl pkg-config configuration on the local machine.
1297 AC_DEFUN([CF_ENABLE_PC_FILES],[
1298 AC_REQUIRE([CF_PKG_CONFIG])
1299 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1300
1301 if test "$PKG_CONFIG" != none ; then
1302         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1303         AC_ARG_ENABLE(pc-files,
1304                 [  --enable-pc-files       generate and install .pc files for pkg-config],
1305                 [enable_pc_files=$enableval],
1306                 [enable_pc_files=no])
1307         AC_MSG_RESULT($enable_pc_files)
1308         if test "$enable_pc_files" != no
1309         then
1310                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1311         fi
1312 else
1313         enable_pc_files=no
1314 fi
1315 ])dnl
1316 dnl ---------------------------------------------------------------------------
1317 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1318 dnl ---------------
1319 dnl Check if the rpath option should be used, setting cache variable
1320 dnl cf_cv_enable_rpath if so.
1321 AC_DEFUN([CF_ENABLE_RPATH],
1322 [
1323 AC_MSG_CHECKING(if rpath option should be used)
1324 AC_ARG_ENABLE(rpath,
1325 [  --enable-rpath          use rpath option when generating shared libraries],
1326 [cf_cv_enable_rpath=$enableval],
1327 [cf_cv_enable_rpath=no])
1328 AC_MSG_RESULT($cf_cv_enable_rpath)
1329 ])dnl
1330 dnl ---------------------------------------------------------------------------
1331 dnl CF_ENABLE_STRING_HACKS version: 3 updated: 2013/01/26 16:26:12
1332 dnl ----------------------
1333 dnl On a few platforms, the compiler and/or loader nags with untruthful
1334 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1335 dnl and implying that most uses of the recommended alternatives are correct.
1336 dnl
1337 dnl Factually speaking, no one has actually counted the number of uses of these
1338 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1339 dnl instances are meaningless compared to the hundreds of millions of lines of
1340 dnl existing C code.
1341 dnl
1342 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1343 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1344 dnl standard - but evolved through phases, and older implementations are likely
1345 dnl to yield surprising results, as documented in manpages on various systems.
1346 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1347 [
1348 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1349 AC_ARG_ENABLE(string-hacks,
1350         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1351         [with_string_hacks=$enableval],
1352         [with_string_hacks=no])
1353 AC_MSG_RESULT($with_string_hacks)
1354
1355 if test "x$with_string_hacks" = "xyes"; then
1356         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1357         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1358         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1359 fi
1360 ])dnl
1361 dnl ---------------------------------------------------------------------------
1362 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1363 dnl --------
1364 dnl Check if 'errno' is declared in <errno.h>
1365 AC_DEFUN([CF_ERRNO],
1366 [
1367 CF_CHECK_ERRNO(errno)
1368 ])dnl
1369 dnl ---------------------------------------------------------------------------
1370 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1371 dnl ---------------
1372 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1373 dnl math.h and builtin.h, only for ncurses
1374 AC_DEFUN([CF_ETIP_DEFINES],
1375 [
1376 AC_MSG_CHECKING(for special defines needed for etip.h)
1377 cf_save_CXXFLAGS="$CXXFLAGS"
1378 cf_result="none"
1379
1380 # etip.h includes ncurses.h which includes ncurses_dll.h
1381 # But ncurses_dll.h is generated - fix here.
1382 test -d include || mkdir include
1383 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1384
1385 for cf_math in "" MATH_H
1386 do
1387 for cf_excp in "" MATH_EXCEPTION
1388 do
1389         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1390         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1391         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1392 AC_TRY_COMPILE([
1393 #include <etip.h.in>
1394 ],[],[
1395         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1396         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1397         cf_result="$cf_math $cf_excp"
1398         break 2
1399 ],[])
1400 done
1401 done
1402 AC_MSG_RESULT($cf_result)
1403 CXXFLAGS="$cf_save_CXXFLAGS"
1404 ])
1405 dnl ---------------------------------------------------------------------------
1406 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1407 dnl ---------------
1408 dnl Find a library (specifically the linkage used in the code fragment),
1409 dnl searching for it if it is not already in the library path.
1410 dnl See also CF_ADD_SEARCHPATH.
1411 dnl
1412 dnl Parameters (4-on are optional):
1413 dnl     $1 = headers for library entrypoint
1414 dnl     $2 = code fragment for library entrypoint
1415 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1416 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1417 dnl     $5 = action to perform if not successful
1418 dnl     $6 = module name, if not the same as the library name
1419 dnl     $7 = extra libraries
1420 dnl
1421 dnl Sets these variables:
1422 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1423 dnl     $cf_cv_header_path_$3 - include-directory if needed
1424 dnl     $cf_cv_library_path_$3 - library-directory if needed
1425 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1426 AC_DEFUN([CF_FIND_LINKAGE],[
1427
1428 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1429 # will be set on completion of the AC_TRY_LINK below.
1430 cf_cv_header_path_$3=
1431 cf_cv_library_path_$3=
1432
1433 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1434
1435 cf_save_LIBS="$LIBS"
1436
1437 AC_TRY_LINK([$1],[$2],[
1438         cf_cv_find_linkage_$3=yes
1439         cf_cv_header_path_$3=/usr/include
1440         cf_cv_library_path_$3=/usr/lib
1441 ],[
1442
1443 LIBS="-l$3 $7 $cf_save_LIBS"
1444
1445 AC_TRY_LINK([$1],[$2],[
1446         cf_cv_find_linkage_$3=yes
1447         cf_cv_header_path_$3=/usr/include
1448         cf_cv_library_path_$3=/usr/lib
1449         cf_cv_library_file_$3="-l$3"
1450 ],[
1451         cf_cv_find_linkage_$3=no
1452         LIBS="$cf_save_LIBS"
1453
1454     CF_VERBOSE(find linkage for $3 library)
1455     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1456
1457     cf_save_CPPFLAGS="$CPPFLAGS"
1458     cf_test_CPPFLAGS="$CPPFLAGS"
1459
1460     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1461     for cf_cv_header_path_$3 in $cf_search
1462     do
1463       if test -d $cf_cv_header_path_$3 ; then
1464         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1465         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1466         AC_TRY_COMPILE([$1],[$2],[
1467             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1468             cf_cv_find_linkage_$3=maybe
1469             cf_test_CPPFLAGS="$CPPFLAGS"
1470             break],[
1471             CPPFLAGS="$cf_save_CPPFLAGS"
1472             ])
1473       fi
1474     done
1475
1476     if test "$cf_cv_find_linkage_$3" = maybe ; then
1477
1478       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1479
1480       cf_save_LIBS="$LIBS"
1481       cf_save_LDFLAGS="$LDFLAGS"
1482
1483       ifelse([$6],,,[
1484         CPPFLAGS="$cf_test_CPPFLAGS"
1485         LIBS="-l$3 $7 $cf_save_LIBS"
1486         AC_TRY_LINK([$1],[$2],[
1487             CF_VERBOSE(... found $3 library in system)
1488             cf_cv_find_linkage_$3=yes])
1489             CPPFLAGS="$cf_save_CPPFLAGS"
1490             LIBS="$cf_save_LIBS"
1491             ])
1492
1493       if test "$cf_cv_find_linkage_$3" != yes ; then
1494         CF_LIBRARY_PATH(cf_search,$3)
1495         for cf_cv_library_path_$3 in $cf_search
1496         do
1497           if test -d $cf_cv_library_path_$3 ; then
1498             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1499             CPPFLAGS="$cf_test_CPPFLAGS"
1500             LIBS="-l$3 $7 $cf_save_LIBS"
1501             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1502             AC_TRY_LINK([$1],[$2],[
1503                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1504                 cf_cv_find_linkage_$3=yes
1505                 cf_cv_library_file_$3="-l$3"
1506                 break],[
1507                 CPPFLAGS="$cf_save_CPPFLAGS"
1508                 LIBS="$cf_save_LIBS"
1509                 LDFLAGS="$cf_save_LDFLAGS"
1510                 ])
1511           fi
1512         done
1513         CPPFLAGS="$cf_save_CPPFLAGS"
1514         LDFLAGS="$cf_save_LDFLAGS"
1515       fi
1516
1517     else
1518       cf_cv_find_linkage_$3=no
1519     fi
1520     ],$7)
1521 ])
1522
1523 LIBS="$cf_save_LIBS"
1524
1525 if test "$cf_cv_find_linkage_$3" = yes ; then
1526 ifelse([$4],,[
1527         CF_ADD_INCDIR($cf_cv_header_path_$3)
1528         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1529         CF_ADD_LIB($3)
1530 ],[$4])
1531 else
1532 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1533 fi
1534 ])dnl
1535 dnl ---------------------------------------------------------------------------
1536 dnl CF_FIXUP_ADAFLAGS version: 1 updated: 2012/03/31 18:48:10
1537 dnl -----------------
1538 dnl make ADAFLAGS consistent with CFLAGS
1539 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1540         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1541         case "$CFLAGS" in
1542         *-g*)
1543                 CF_ADD_ADAFLAGS(-g)
1544                 ;;
1545         esac
1546         case "$CFLAGS" in
1547         *-O*)
1548                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1549                 CF_ADD_ADAFLAGS($cf_O_flag)
1550                 ;;
1551         esac
1552         AC_MSG_RESULT($ADAFLAGS)
1553 ])dnl
1554 dnl ---------------------------------------------------------------------------
1555 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1556 dnl --------------
1557 dnl Forget that we saw the given tool.
1558 AC_DEFUN([CF_FORGET_TOOL],[
1559 unset ac_cv_prog_ac_ct_$1
1560 unset ac_ct_$1
1561 unset $1
1562 ])dnl
1563 dnl ---------------------------------------------------------------------------
1564 dnl CF_FUNC_DLSYM version: 3 updated: 2012/10/06 11:17:15
1565 dnl -------------
1566 dnl Test for dlsym() and related functions, as well as libdl.
1567 dnl
1568 dnl Sets
1569 dnl     $cf_have_dlsym
1570 dnl     $cf_have_libdl
1571 AC_DEFUN([CF_FUNC_DLSYM],[
1572 cf_have_dlsym=no
1573 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1574
1575 cf_have_libdl=no
1576 AC_CHECK_LIB(dl,dlsym,[
1577         cf_have_dlsym=yes
1578         cf_have_libdl=yes])])
1579
1580 if test "$cf_have_dlsym" = yes ; then
1581         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1582
1583         AC_MSG_CHECKING(whether able to link to dl*() functions)
1584         AC_TRY_LINK([#include <dlfcn.h>],[
1585                 void *obj;
1586                 if ((obj = dlopen("filename", 0)) != 0) {
1587                         if (dlsym(obj, "symbolname") == 0) {
1588                         dlclose(obj);
1589                         }
1590                 }],[
1591                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1592                 AC_MSG_ERROR(Cannot link test program for libdl)])
1593         AC_MSG_RESULT(ok)
1594 else
1595         AC_MSG_ERROR(Cannot find dlsym function)
1596 fi
1597 ])
1598 dnl ---------------------------------------------------------------------------
1599 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1600 dnl ---------------
1601 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1602 dnl is found, add our own version of memmove to the list of objects.
1603 AC_DEFUN([CF_FUNC_MEMMOVE],
1604 [
1605 AC_CHECK_FUNC(memmove,,[
1606 AC_CHECK_FUNC(bcopy,[
1607         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1608                 AC_TRY_RUN([
1609 int main() {
1610         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1611         char temp[40];
1612         bcopy(data, temp, sizeof(data));
1613         bcopy(temp+10, temp, 15);
1614         bcopy(temp+5, temp+15, 10);
1615         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1616 }
1617                 ],
1618                 [cf_cv_good_bcopy=yes],
1619                 [cf_cv_good_bcopy=no],
1620                 [cf_cv_good_bcopy=unknown])
1621                 ])
1622         ],[cf_cv_good_bcopy=no])
1623         if test "$cf_cv_good_bcopy" = yes ; then
1624                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1625         else
1626                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1627         fi
1628 ])])dnl
1629 dnl ---------------------------------------------------------------------------
1630 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1631 dnl -----------------
1632 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1633 dnl AIX 4.x, provide a non-working version.
1634 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1635 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1636 AC_TRY_RUN([
1637 #include <stdio.h>
1638 #include <errno.h>
1639 #include <time.h>
1640
1641 #ifdef HAVE_SYS_TIME_H
1642 #include <sys/time.h>
1643 #endif
1644
1645 int main() {
1646         struct timespec ts1, ts2;
1647         int code;
1648         ts1.tv_sec  = 0;
1649         ts1.tv_nsec = 750000000;
1650         ts2.tv_sec  = 0;
1651         ts2.tv_nsec = 0;
1652         errno = 0;
1653         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1654         ${cf_cv_main_return:-return}(code != 0);
1655 }
1656 ],
1657         [cf_cv_func_nanosleep=yes],
1658         [cf_cv_func_nanosleep=no],
1659         [cf_cv_func_nanosleep=unknown])])
1660
1661 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1662 ])
1663 dnl ---------------------------------------------------------------------------
1664 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1665 dnl ---------------
1666 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1667 dnl "util" library as well.
1668 AC_DEFUN([CF_FUNC_OPENPTY],
1669 [
1670 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1671 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1672     cf_save_LIBS="$LIBS"
1673     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1674     for cf_header in pty.h libutil.h util.h
1675     do
1676     AC_TRY_LINK([
1677 #include <$cf_header>
1678 ],[
1679     int x = openpty((int *)0, (int *)0, (char *)0,
1680                    (struct termios *)0, (struct winsize *)0);
1681 ],[
1682         cf_cv_func_openpty=$cf_header
1683         break
1684 ],[
1685         cf_cv_func_openpty=no
1686 ])
1687     done
1688     LIBS="$cf_save_LIBS"
1689 ])
1690 ])dnl
1691 dnl ---------------------------------------------------------------------------
1692 dnl CF_FUNC_POLL version: 8 updated: 2012/10/04 05:24:07
1693 dnl ------------
1694 dnl See if the poll function really works.  Some platforms have poll(), but
1695 dnl it does not work for terminals or files.
1696 AC_DEFUN([CF_FUNC_POLL],[
1697 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1698 AC_TRY_RUN([
1699 #include <stdlib.h>
1700 #include <stdio.h>
1701 #include <unistd.h>
1702 #include <fcntl.h>
1703 #ifdef HAVE_POLL_H
1704 #include <poll.h>
1705 #else
1706 #include <sys/poll.h>
1707 #endif
1708 int main() {
1709         struct pollfd myfds;
1710         int ret;
1711
1712         /* check for Darwin bug with respect to "devices" */
1713         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
1714         if (myfds.fd < 0)
1715                 myfds.fd = 0;
1716         myfds.events = POLLIN;
1717         myfds.revents = 0;
1718
1719         ret = poll(&myfds, 1, 100);
1720
1721         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1722                 ret = -1;
1723         } else {
1724                 int fd = 0;
1725                 if (!isatty(fd)) {
1726                         fd = open("/dev/tty", 2);       /* O_RDWR */
1727                 }
1728
1729                 if (fd >= 0) {
1730                         /* also check with standard input */
1731                         myfds.fd = fd;
1732                         myfds.events = POLLIN;
1733                         myfds.revents = 0;
1734                         ret = poll(&myfds, 1, 100);
1735                 } else {
1736                         ret = -1;
1737                 }
1738         }
1739         ${cf_cv_main_return:-return}(ret < 0);
1740 }],
1741         [cf_cv_working_poll=yes],
1742         [cf_cv_working_poll=no],
1743         [cf_cv_working_poll=unknown])])
1744 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
1745 ])dnl
1746 dnl ---------------------------------------------------------------------------
1747 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
1748 dnl ---------------
1749 dnl Some old/broken variations define tcgetattr() only as a macro in
1750 dnl termio(s).h
1751 AC_DEFUN([CF_FUNC_TERMIOS],[
1752 AC_REQUIRE([CF_STRUCT_TERMIOS])
1753 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1754 AC_TRY_LINK([
1755 #include <sys/types.h>
1756 #ifdef HAVE_UNISTD_H
1757 #include <unistd.h>
1758 #endif
1759 #ifdef HAVE_TERMIOS_H
1760 #include <termios.h>
1761 #define TTY struct termios
1762 #else
1763 #ifdef HAVE_TERMIO_H
1764 #include <termio.h>
1765 #define TTY struct termio
1766 #endif
1767 #endif
1768 ],[
1769 TTY foo;
1770 tcgetattr(1, &foo);],
1771 [cf_cv_have_tcgetattr=yes],
1772 [cf_cv_have_tcgetattr=no])])
1773 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
1774 ])dnl
1775 dnl ---------------------------------------------------------------------------
1776 dnl CF_FUNC_VSSCANF version: 4 updated: 2012/10/06 17:56:13
1777 dnl ---------------
1778 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1779 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1780 dnl other functions.
1781 AC_DEFUN([CF_FUNC_VSSCANF],
1782 [
1783 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1784 AC_TRY_LINK([
1785 #include <stdarg.h>
1786 #include <stdio.h>],[
1787         va_list ap;
1788         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1789 AC_TRY_LINK([
1790 #include <stdarg.h>
1791 #include <stdio.h>],[
1792     FILE strbuf;
1793     char *str = "from";
1794
1795     strbuf._flag = _IOREAD;
1796     strbuf._ptr = strbuf._base = (unsigned char *) str;
1797     strbuf._cnt = strlen(str);
1798     strbuf._file = _NFILE;
1799     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1800 AC_TRY_LINK([
1801 #include <stdarg.h>
1802 #include <stdio.h>],[
1803     FILE strbuf;
1804     char *str = "from";
1805
1806     strbuf._flag = _IOREAD;
1807     strbuf._ptr = strbuf._base = (unsigned char *) str;
1808     strbuf._cnt = strlen(str);
1809     strbuf._file = _NFILE;
1810     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1811 cf_cv_func_vsscanf=no])])])])
1812
1813 case $cf_cv_func_vsscanf in #(vi
1814 vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);; #(vi
1815 vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);; #(vi
1816 _doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
1817 esac
1818
1819 ])dnl
1820 dnl ---------------------------------------------------------------------------
1821 dnl CF_GCC_ATTRIBUTES version: 16 updated: 2012/10/02 20:55:03
1822 dnl -----------------
1823 dnl Test for availability of useful gcc __attribute__ directives to quiet
1824 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1825 dnl to documentation, unrecognized directives cause older compilers to barf.
1826 AC_DEFUN([CF_GCC_ATTRIBUTES],
1827 [
1828 if test "$GCC" = yes
1829 then
1830 cat > conftest.i <<EOF
1831 #ifndef GCC_PRINTF
1832 #define GCC_PRINTF 0
1833 #endif
1834 #ifndef GCC_SCANF
1835 #define GCC_SCANF 0
1836 #endif
1837 #ifndef GCC_NORETURN
1838 #define GCC_NORETURN /* nothing */
1839 #endif
1840 #ifndef GCC_UNUSED
1841 #define GCC_UNUSED /* nothing */
1842 #endif
1843 EOF
1844 if test "$GCC" = yes
1845 then
1846         AC_CHECKING([for $CC __attribute__ directives])
1847 cat > conftest.$ac_ext <<EOF
1848 #line __oline__ "${as_me:-configure}"
1849 #include "confdefs.h"
1850 #include "conftest.h"
1851 #include "conftest.i"
1852 #if     GCC_PRINTF
1853 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1854 #else
1855 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1856 #endif
1857 #if     GCC_SCANF
1858 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1859 #else
1860 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1861 #endif
1862 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1863 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1864 extern void foo(void) GCC_NORETURN;
1865 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1866 EOF
1867         cf_printf_attribute=no
1868         cf_scanf_attribute=no
1869         for cf_attribute in scanf printf unused noreturn
1870         do
1871                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1872                 cf_directive="__attribute__(($cf_attribute))"
1873                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1874
1875                 case $cf_attribute in #(vi
1876                 printf) #(vi
1877                         cf_printf_attribute=yes
1878                         cat >conftest.h <<EOF
1879 #define GCC_$cf_ATTRIBUTE 1
1880 EOF
1881                         ;;
1882                 scanf) #(vi
1883                         cf_scanf_attribute=yes
1884                         cat >conftest.h <<EOF
1885 #define GCC_$cf_ATTRIBUTE 1
1886 EOF
1887                         ;;
1888                 *) #(vi
1889                         cat >conftest.h <<EOF
1890 #define GCC_$cf_ATTRIBUTE $cf_directive
1891 EOF
1892                         ;;
1893                 esac
1894
1895                 if AC_TRY_EVAL(ac_compile); then
1896                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1897                         cat conftest.h >>confdefs.h
1898                         case $cf_attribute in #(vi
1899                         noreturn) #(vi
1900                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1901                                 ;;
1902                         printf) #(vi
1903                                 cf_value='/* nothing */'
1904                                 if test "$cf_printf_attribute" != no ; then
1905                                         cf_value='__attribute__((format(printf,fmt,var)))'
1906                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1907                                 fi
1908                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1909                                 ;;
1910                         scanf) #(vi
1911                                 cf_value='/* nothing */'
1912                                 if test "$cf_scanf_attribute" != no ; then
1913                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1914                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1915                                 fi
1916                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1917                                 ;;
1918                         unused) #(vi
1919                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1920                                 ;;
1921                         esac
1922                 fi
1923         done
1924 else
1925         fgrep define conftest.i >>confdefs.h
1926 fi
1927 rm -rf conftest*
1928 fi
1929 ])dnl
1930 dnl ---------------------------------------------------------------------------
1931 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1932 dnl --------------
1933 dnl Find version of gcc
1934 AC_DEFUN([CF_GCC_VERSION],[
1935 AC_REQUIRE([AC_PROG_CC])
1936 GCC_VERSION=none
1937 if test "$GCC" = yes ; then
1938         AC_MSG_CHECKING(version of $CC)
1939         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1940         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1941         AC_MSG_RESULT($GCC_VERSION)
1942 fi
1943 ])dnl
1944 dnl ---------------------------------------------------------------------------
1945 dnl CF_GCC_WARNINGS version: 29 updated: 2012/06/16 14:55:39
1946 dnl ---------------
1947 dnl Check if the compiler supports useful warning options.  There's a few that
1948 dnl we don't use, simply because they're too noisy:
1949 dnl
1950 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1951 dnl     -Wredundant-decls (system headers make this too noisy)
1952 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1953 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1954 dnl             is enabled for ncurses using "--enable-const".
1955 dnl     -pedantic
1956 dnl
1957 dnl Parameter:
1958 dnl     $1 is an optional list of gcc warning flags that a particular
1959 dnl             application might want to use, e.g., "no-unused" for
1960 dnl             -Wno-unused
1961 dnl Special:
1962 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1963 dnl
1964 AC_DEFUN([CF_GCC_WARNINGS],
1965 [
1966 AC_REQUIRE([CF_GCC_VERSION])
1967 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1968 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1969
1970 cat > conftest.$ac_ext <<EOF
1971 #line __oline__ "${as_me:-configure}"
1972 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1973 EOF
1974
1975 if test "$INTEL_COMPILER" = yes
1976 then
1977 # The "-wdXXX" options suppress warnings:
1978 # remark #1419: external declaration in primary source file
1979 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1980 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1981 # remark #193: zero used for undefined preprocessing identifier
1982 # remark #593: variable "curs_sb_left_arrow" was set but never used
1983 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1984 # remark #869: parameter "tw" was never referenced
1985 # remark #981: operands are evaluated in unspecified order
1986 # warning #279: controlling expression is constant
1987
1988         AC_CHECKING([for $CC warning options])
1989         cf_save_CFLAGS="$CFLAGS"
1990         EXTRA_CFLAGS="-Wall"
1991         for cf_opt in \
1992                 wd1419 \
1993                 wd1683 \
1994                 wd1684 \
1995                 wd193 \
1996                 wd593 \
1997                 wd279 \
1998                 wd810 \
1999                 wd869 \
2000                 wd981
2001         do
2002                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2003                 if AC_TRY_EVAL(ac_compile); then
2004                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2005                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2006                 fi
2007         done
2008         CFLAGS="$cf_save_CFLAGS"
2009
2010 elif test "$GCC" = yes
2011 then
2012         AC_CHECKING([for $CC warning options])
2013         cf_save_CFLAGS="$CFLAGS"
2014         EXTRA_CFLAGS=
2015         cf_warn_CONST=""
2016         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2017         for cf_opt in W Wall \
2018                 Wbad-function-cast \
2019                 Wcast-align \
2020                 Wcast-qual \
2021                 Winline \
2022                 Wmissing-declarations \
2023                 Wmissing-prototypes \
2024                 Wnested-externs \
2025                 Wpointer-arith \
2026                 Wshadow \
2027                 Wstrict-prototypes \
2028                 Wundef $cf_warn_CONST $1
2029         do
2030                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2031                 if AC_TRY_EVAL(ac_compile); then
2032                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2033                         case $cf_opt in #(vi
2034                         Wcast-qual) #(vi
2035                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2036                                 ;;
2037                         Winline) #(vi
2038                                 case $GCC_VERSION in
2039                                 [[34]].*)
2040                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2041                                         continue;;
2042                                 esac
2043                                 ;;
2044                         Wpointer-arith) #(vi
2045                                 case $GCC_VERSION in
2046                                 [[12]].*)
2047                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2048                                         continue;;
2049                                 esac
2050                                 ;;
2051                         esac
2052                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2053                 fi
2054         done
2055         CFLAGS="$cf_save_CFLAGS"
2056 fi
2057 rm -rf conftest*
2058
2059 AC_SUBST(EXTRA_CFLAGS)
2060 ])dnl
2061 dnl ---------------------------------------------------------------------------
2062 dnl CF_GETOPT_HEADER version: 5 updated: 2012/10/06 16:39:58
2063 dnl ----------------
2064 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2065 dnl unistd.h or (nonstandard) in getopt.h
2066 AC_DEFUN([CF_GETOPT_HEADER],
2067 [
2068 AC_HAVE_HEADERS(unistd.h getopt.h)
2069 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2070 cf_cv_getopt_header=none
2071 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2072 do
2073 AC_TRY_COMPILE([
2074 #include <$cf_header>],
2075 [int x = optind; char *y = optarg],
2076 [cf_cv_getopt_header=$cf_header
2077  break])
2078 done
2079 ])
2080 if test $cf_cv_getopt_header != none ; then
2081         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if we need to include getopt.h])
2082 fi
2083 ])dnl
2084 dnl ---------------------------------------------------------------------------
2085 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
2086 dnl ----------------
2087 AC_DEFUN([CF_GNAT_GENERICS],
2088 [
2089 AC_REQUIRE([CF_GNAT_VERSION])
2090
2091 AC_MSG_CHECKING(if GNAT supports generics)
2092 case $cf_gnat_version in #(vi
2093 3.[[1-9]]*|[[4-9]].*) #(vi
2094         cf_gnat_generics=yes
2095         ;;
2096 *)
2097         cf_gnat_generics=no
2098         ;;
2099 esac
2100 AC_MSG_RESULT($cf_gnat_generics)
2101
2102 if test "$cf_gnat_generics" = yes
2103 then
2104         cf_compile_generics=generics
2105         cf_generic_objects="\${GENOBJS}"
2106 else
2107         cf_compile_generics=
2108         cf_generic_objects=
2109 fi
2110
2111 AC_SUBST(cf_compile_generics)
2112 AC_SUBST(cf_generic_objects)
2113 ])dnl
2114 dnl ---------------------------------------------------------------------------
2115 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
2116 dnl --------------------
2117 dnl Check if the gnat pragma "Unreferenced" works.
2118 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
2119 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
2120 CF_GNAT_TRY_LINK([procedure conftest;],
2121 [with Text_IO;
2122 with GNAT.OS_Lib;
2123 procedure conftest is
2124    test : Integer;
2125    pragma Unreferenced (test);
2126 begin
2127    test := 1;
2128    Text_IO.Put ("Hello World");
2129    Text_IO.New_Line;
2130    GNAT.OS_Lib.OS_Exit (0);
2131 end conftest;],
2132         [cf_cv_pragma_unreferenced=yes],
2133         [cf_cv_pragma_unreferenced=no])])
2134
2135 # if the pragma is supported, use it (needed in the Trace code).
2136 if test $cf_cv_pragma_unreferenced = yes ; then
2137         PRAGMA_UNREF=TRUE
2138 else
2139         PRAGMA_UNREF=FALSE
2140 fi
2141 AC_SUBST(PRAGMA_UNREF)
2142 ])dnl
2143 dnl ---------------------------------------------------------------------------
2144 dnl CF_GNAT_PROJECTS version: 2 updated: 2011/03/23 20:24:41
2145 dnl ----------------
2146 dnl GNAT projects are configured with ".gpr" project files.
2147 dnl GNAT libraries are a further development, using the project feature.
2148 AC_DEFUN([CF_GNAT_PROJECTS],
2149 [
2150 AC_REQUIRE([CF_GNAT_VERSION])
2151
2152 cf_gnat_libraries=no
2153 cf_gnat_projects=no
2154
2155 AC_MSG_CHECKING(if GNAT supports project files)
2156 case $cf_gnat_version in #(vi
2157 3.[[0-9]]*) #(vi
2158         ;;
2159 *)
2160         case $cf_cv_system_name in #(vi
2161         cygwin*) #(vi
2162                 ;;
2163         *)
2164                 mkdir conftest.src conftest.bin conftest.lib
2165                 cd conftest.src
2166                 rm -rf conftest* *~conftest*
2167                 cat >>library.gpr <<CF_EOF
2168 project Library is
2169   Kind := External ("LIB_KIND");
2170   for Library_Name use "ConfTest";
2171   for Object_Dir use ".";
2172   for Library_ALI_Dir use External("LIBRARY_DIR");
2173   for Library_Version use External ("SONAME");
2174   for Library_Kind use Kind;
2175   for Library_Dir use External("BUILD_DIR");
2176   Source_Dir := External ("SOURCE_DIR");
2177   for Source_Dirs use (Source_Dir);
2178   package Compiler is
2179      for Default_Switches ("Ada") use
2180        ("-g",
2181         "-O2",
2182         "-gnatafno",
2183         "-gnatVa",   -- All validity checks
2184         "-gnatwa");  -- Activate all optional errors
2185   end Compiler;
2186 end Library;
2187 CF_EOF
2188                 cat >>confpackage.ads <<CF_EOF
2189 package ConfPackage is
2190    procedure conftest;
2191 end ConfPackage;
2192 CF_EOF
2193                 cat >>confpackage.adb <<CF_EOF
2194 with Text_IO;
2195 package body ConfPackage is
2196    procedure conftest is
2197    begin
2198       Text_IO.Put ("Hello World");
2199       Text_IO.New_Line;
2200    end conftest;
2201 end ConfPackage;
2202 CF_EOF
2203                 if ( $cf_ada_make $ADAFLAGS \
2204                                 -Plibrary.gpr \
2205                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2206                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2207                                 -XSOURCE_DIR=`pwd` \
2208                                 -XSONAME=libConfTest.so.1 \
2209                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2210                         cf_gnat_projects=yes
2211                 fi
2212                 cd ..
2213                 if test -f conftest.lib/confpackage.ali
2214                 then
2215                         cf_gnat_libraries=yes
2216                 fi
2217                 rm -rf conftest* *~conftest*
2218                 ;;
2219         esac
2220         ;;
2221 esac
2222 AC_MSG_RESULT($cf_gnat_projects)
2223
2224 if test $cf_gnat_projects = yes
2225 then
2226         AC_MSG_CHECKING(if GNAT supports libraries)
2227         AC_MSG_RESULT($cf_gnat_libraries)
2228 fi
2229
2230 if test "$cf_gnat_projects" = yes
2231 then
2232         USE_OLD_MAKERULES="#"
2233         USE_GNAT_PROJECTS=""
2234 else
2235         USE_OLD_MAKERULES=""
2236         USE_GNAT_PROJECTS="#"
2237 fi
2238
2239 if test "$cf_gnat_libraries" = yes
2240 then
2241         USE_GNAT_LIBRARIES=""
2242 else
2243         USE_GNAT_LIBRARIES="#"
2244 fi
2245
2246 AC_SUBST(USE_OLD_MAKERULES)
2247 AC_SUBST(USE_GNAT_PROJECTS)
2248 AC_SUBST(USE_GNAT_LIBRARIES)
2249 ])dnl
2250 dnl ---------------------------------------------------------------------------
2251 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2252 dnl --------------
2253 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2254 dnl is noted that gnat may compile a tasking unit even for configurations which
2255 dnl fail at runtime.
2256 AC_DEFUN([CF_GNAT_SIGINT],[
2257 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2258 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2259
2260 package ConfTest is
2261
2262    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2263    pragma Unreserve_All_Interrupts;
2264    pragma Warnings (On);
2265
2266    protected Process is
2267       procedure Stop;
2268       function Continue return Boolean;
2269       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2270    private
2271       Done : Boolean := False;
2272    end Process;
2273
2274 end ConfTest;],
2275 [package body ConfTest is
2276    protected body Process is
2277       procedure Stop is
2278       begin
2279          Done := True;
2280       end Stop;
2281       function Continue return Boolean is
2282       begin
2283          return not Done;
2284       end Continue;
2285    end Process;
2286 end ConfTest;],
2287         [cf_cv_gnat_sigint=yes],
2288         [cf_cv_gnat_sigint=no])])
2289
2290 if test $cf_cv_gnat_sigint = yes ; then
2291         USE_GNAT_SIGINT=""
2292 else
2293         USE_GNAT_SIGINT="#"
2294 fi
2295 AC_SUBST(USE_GNAT_SIGINT)
2296 ])dnl
2297 dnl ---------------------------------------------------------------------------
2298 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2299 dnl ----------------
2300 dnl Verify that a test program compiles/links with GNAT.
2301 dnl $cf_ada_make is set to the program that compiles/links
2302 dnl $ADAFLAGS may be set to the GNAT flags.
2303 dnl
2304 dnl $1 is the text of the spec
2305 dnl $2 is the text of the body
2306 dnl $3 is the shell command to execute if successful
2307 dnl $4 is the shell command to execute if not successful
2308 AC_DEFUN([CF_GNAT_TRY_LINK],
2309 [
2310 rm -rf conftest* *~conftest*
2311 cat >>conftest.ads <<CF_EOF
2312 $1
2313 CF_EOF
2314 cat >>conftest.adb <<CF_EOF
2315 $2
2316 CF_EOF
2317 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2318 ifelse($3,,      :,[      $3])
2319 ifelse($4,,,[else
2320    $4])
2321 fi
2322 rm -rf conftest* *~conftest*
2323 ])dnl
2324 dnl ---------------------------------------------------------------------------
2325 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2326 dnl ---------------
2327 dnl Verify that a test program compiles and runs with GNAT
2328 dnl $cf_ada_make is set to the program that compiles/links
2329 dnl $ADAFLAGS may be set to the GNAT flags.
2330 dnl
2331 dnl $1 is the text of the spec
2332 dnl $2 is the text of the body
2333 dnl $3 is the shell command to execute if successful
2334 dnl $4 is the shell command to execute if not successful
2335 AC_DEFUN([CF_GNAT_TRY_RUN],
2336 [
2337 rm -rf conftest* *~conftest*
2338 cat >>conftest.ads <<CF_EOF
2339 $1
2340 CF_EOF
2341 cat >>conftest.adb <<CF_EOF
2342 $2
2343 CF_EOF
2344 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2345    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2346 ifelse($3,,      :,[      $3])
2347 ifelse($4,,,[   else
2348       $4])
2349    fi
2350 ifelse($4,,,[else
2351    $4])
2352 fi
2353 rm -rf conftest* *~conftest*
2354 ])dnl
2355 dnl ---------------------------------------------------------------------------
2356 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
2357 dnl ---------------
2358 dnl Verify version of GNAT.
2359 AC_DEFUN([CF_GNAT_VERSION],
2360 [
2361 AC_MSG_CHECKING(for gnat version)
2362 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2363         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2364     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2365 AC_MSG_RESULT($cf_gnat_version)
2366
2367 case $cf_gnat_version in #(vi
2368 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
2369         cf_cv_prog_gnat_correct=yes
2370         ;;
2371 *)
2372         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2373         cf_cv_prog_gnat_correct=no
2374         ;;
2375 esac
2376 ])
2377 dnl ---------------------------------------------------------------------------
2378 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2379 dnl -------------
2380 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2381 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2382 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2383 dnl since it is interwoven with GNU extensions.
2384 dnl
2385 dnl Well, yes we could work around it...
2386 AC_DEFUN([CF_GNU_SOURCE],
2387 [
2388 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2389 AC_TRY_COMPILE([#include <sys/types.h>],[
2390 #ifndef _XOPEN_SOURCE
2391 make an error
2392 #endif],
2393         [cf_cv_gnu_source=no],
2394         [cf_save="$CPPFLAGS"
2395          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2396          AC_TRY_COMPILE([#include <sys/types.h>],[
2397 #ifdef _XOPEN_SOURCE
2398 make an error
2399 #endif],
2400         [cf_cv_gnu_source=no],
2401         [cf_cv_gnu_source=yes])
2402         CPPFLAGS="$cf_save"
2403         ])
2404 ])
2405 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2406 ])dnl
2407 dnl ---------------------------------------------------------------------------
2408 dnl CF_GPP_LIBRARY version: 11 updated: 2012/10/06 17:56:13
2409 dnl --------------
2410 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2411 dnl problem :-).  If we have the compiler but no library, we'll be able to
2412 dnl configure, but won't be able to build the c++ demo program.
2413 AC_DEFUN([CF_GPP_LIBRARY],
2414 [
2415 cf_cxx_library=unknown
2416 case $cf_cv_system_name in #(vi
2417 os2*) #(vi
2418         cf_gpp_libname=gpp
2419         ;;
2420 *)
2421         cf_gpp_libname=g++
2422         ;;
2423 esac
2424 if test "$GXX" = yes; then
2425         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2426         cf_save="$LIBS"
2427         CF_ADD_LIB($cf_gpp_libname)
2428         AC_TRY_LINK([
2429 #include <$cf_gpp_libname/builtin.h>
2430         ],
2431         [two_arg_error_handler_t foo2 = lib_error_handler],
2432         [cf_cxx_library=yes
2433          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2434          if test "$cf_gpp_libname" = cpp ; then
2435             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2436          else
2437             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2438          fi],
2439         [AC_TRY_LINK([
2440 #include <builtin.h>
2441         ],
2442         [two_arg_error_handler_t foo2 = lib_error_handler],
2443         [cf_cxx_library=yes
2444          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2445          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2446         [cf_cxx_library=no])])
2447         LIBS="$cf_save"
2448         AC_MSG_RESULT($cf_cxx_library)
2449 fi
2450 ])dnl
2451 dnl ---------------------------------------------------------------------------
2452 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2453 dnl --------------
2454 dnl Check for version of g++
2455 AC_DEFUN([CF_GXX_VERSION],[
2456 AC_REQUIRE([AC_PROG_CPP])
2457 GXX_VERSION=none
2458 if test "$GXX" = yes; then
2459         AC_MSG_CHECKING(version of ${CXX:-g++})
2460         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2461         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2462         AC_MSG_RESULT($GXX_VERSION)
2463 fi
2464 ])dnl
2465 dnl ---------------------------------------------------------------------------
2466 dnl CF_GXX_WARNINGS version: 7 updated: 2012/06/16 14:55:39
2467 dnl ---------------
2468 dnl Check if the compiler supports useful warning options.
2469 dnl
2470 dnl Most of gcc's options apply to g++, except:
2471 dnl     -Wbad-function-cast
2472 dnl     -Wmissing-declarations
2473 dnl     -Wnested-externs
2474 dnl
2475 dnl Omit a few (for now):
2476 dnl     -Winline
2477 dnl
2478 dnl Parameter:
2479 dnl     $1 is an optional list of g++ warning flags that a particular
2480 dnl             application might want to use, e.g., "no-unused" for
2481 dnl             -Wno-unused
2482 dnl Special:
2483 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2484 dnl
2485 AC_DEFUN([CF_GXX_WARNINGS],
2486 [
2487
2488 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2489 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2490
2491 AC_REQUIRE([CF_GXX_VERSION])
2492
2493 AC_LANG_SAVE
2494 AC_LANG_CPLUSPLUS
2495
2496 cat > conftest.$ac_ext <<EOF
2497 #line __oline__ "configure"
2498 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2499 EOF
2500
2501 if test "$INTEL_CPLUSPLUS" = yes
2502 then
2503 # The "-wdXXX" options suppress warnings:
2504 # remark #1419: external declaration in primary source file
2505 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2506 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2507 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2508 # remark #193: zero used for undefined preprocessing identifier
2509 # remark #593: variable "curs_sb_left_arrow" was set but never used
2510 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2511 # remark #869: parameter "tw" was never referenced
2512 # remark #981: operands are evaluated in unspecified order
2513 # warning #269: invalid format string conversion
2514
2515         AC_CHECKING([for $CC warning options])
2516         cf_save_CXXFLAGS="$CXXFLAGS"
2517         EXTRA_CXXFLAGS="-Wall"
2518         for cf_opt in \
2519                 wd1419 \
2520                 wd1682 \
2521                 wd1683 \
2522                 wd1684 \
2523                 wd193 \
2524                 wd279 \
2525                 wd593 \
2526                 wd810 \
2527                 wd869 \
2528                 wd981
2529         do
2530                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2531                 if AC_TRY_EVAL(ac_compile); then
2532                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2533                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2534                 fi
2535         done
2536         CXXFLAGS="$cf_save_CXXFLAGS"
2537
2538 elif test "$GXX" = yes
2539 then
2540         AC_CHECKING([for $CXX warning options])
2541         cf_save_CXXFLAGS="$CXXFLAGS"
2542         EXTRA_CXXFLAGS="-W -Wall"
2543         cf_gxx_extra_warnings=""
2544         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2545         case "$GCC_VERSION" in
2546         [[1-2]].*)
2547                 ;;
2548         *)
2549                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2550                 ;;
2551         esac
2552         for cf_opt in \
2553                 Wabi \
2554                 fabi-version=0 \
2555                 Woverloaded-virtual \
2556                 Wsign-promo \
2557                 Wsynth \
2558                 Wold-style-cast \
2559                 Wcast-align \
2560                 Wcast-qual \
2561                 Wmissing-prototypes \
2562                 Wpointer-arith \
2563                 Wshadow \
2564                 Wstrict-prototypes \
2565                 Wundef $cf_gxx_extra_warnings $1
2566         do
2567                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2568                 if AC_TRY_EVAL(ac_compile); then
2569                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2570                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2571                 else
2572                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2573                 fi
2574         done
2575         CXXFLAGS="$cf_save_CXXFLAGS"
2576 fi
2577
2578 rm -rf conftest*
2579 AC_LANG_RESTORE
2580 AC_SUBST(EXTRA_CXXFLAGS)
2581 ])dnl
2582 dnl ---------------------------------------------------------------------------
2583 dnl CF_HASHED_DB version: 4 updated: 2010/05/29 16:31:02
2584 dnl ------------
2585 dnl Look for an instance of the Berkeley hashed database.
2586 dnl
2587 dnl $1 = optional parameter, to specify install-prefix for the database.
2588 AC_DEFUN([CF_HASHED_DB],
2589 [
2590 ifelse([$1],,,[
2591 case $1 in #(vi
2592 yes|*able*) #(vi
2593     ;;
2594 *)
2595     if test -d "$1" ; then
2596         CF_ADD_INCDIR($1/include)
2597         CF_ADD_LIBDIR($1/lib)
2598     fi
2599 esac
2600 ])
2601 AC_CHECK_HEADER(db.h,[
2602 CF_HASHED_DB_VERSION
2603 if test "$cf_cv_hashed_db_version" = unknown ; then
2604         AC_MSG_ERROR(Cannot determine version of db)
2605 else
2606         CF_HASHED_DB_LIBS
2607         if test "$cf_cv_hashed_db_libs" = unknown ; then
2608                 AC_MSG_ERROR(Cannot determine library for db)
2609         elif test "$cf_cv_hashed_db_libs" != default ; then
2610                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2611         fi
2612 fi
2613 ],[
2614         AC_MSG_ERROR(Cannot find db.h)
2615 ])
2616 ])dnl
2617 dnl ---------------------------------------------------------------------------
2618 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2619 dnl -----------------
2620 dnl Given that we have the header and version for hashed database, find the
2621 dnl library information.
2622 AC_DEFUN([CF_HASHED_DB_LIBS],
2623 [
2624 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2625 cf_cv_hashed_db_libs=unknown
2626 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2627 do
2628         cf_save_libs="$LIBS"
2629         if test -n "$cf_db_libs"; then
2630                 CF_ADD_LIB($cf_db_libs)
2631         fi
2632         CF_MSG_LOG(checking for library "$cf_db_libs")
2633         AC_TRY_LINK([
2634 $ac_includes_default
2635 #include <db.h>
2636 ],[
2637         char *path = "/tmp/foo";
2638 #ifdef DB_VERSION_MAJOR
2639 #if DB_VERSION_MAJOR >= 4
2640         DB *result = 0;
2641         db_create(&result, NULL, 0);
2642         result->open(result,
2643                 NULL,
2644                 path,
2645                 path,
2646                 DB_HASH,
2647                 DB_CREATE,
2648                 0644);
2649 #elif DB_VERSION_MAJOR >= 3
2650         DB *result = 0;
2651         db_create(&result, NULL, 0);
2652         result->open(result,
2653                 path,
2654                 path,
2655                 DB_HASH,
2656                 DB_CREATE,
2657                 0644);
2658 #elif DB_VERSION_MAJOR >= 2
2659         DB *result = 0;
2660         db_open(path,
2661                 DB_HASH,
2662                 DB_CREATE,
2663                 0644,
2664                 (DB_ENV *) 0,
2665                 (DB_INFO *) 0,
2666                 &result);
2667 #endif /* DB_VERSION_MAJOR */
2668 #else
2669         DB *result = dbopen(path,
2670                      2,
2671                      0644,
2672                      DB_HASH,
2673                      0);
2674 #endif
2675         ${cf_cv_main_return:-return}(result != 0)
2676 ],[
2677         if test -n "$cf_db_libs" ; then
2678                 cf_cv_hashed_db_libs=$cf_db_libs
2679         else
2680                 cf_cv_hashed_db_libs=default
2681         fi
2682         LIBS="$cf_save_libs"
2683         break
2684 ])
2685         LIBS="$cf_save_libs"
2686 done
2687 ])
2688 ])dnl
2689 dnl ---------------------------------------------------------------------------
2690 dnl CF_HASHED_DB_VERSION version: 3 updated: 2007/12/01 15:01:37
2691 dnl --------------------
2692 dnl Given that we have the header file for hashed database, find the version
2693 dnl information.
2694 AC_DEFUN([CF_HASHED_DB_VERSION],
2695 [
2696 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2697 cf_cv_hashed_db_version=unknown
2698
2699 for cf_db_version in 1 2 3 4 5
2700 do
2701         CF_MSG_LOG(checking for db version $cf_db_version)
2702         AC_TRY_COMPILE([
2703 $ac_includes_default
2704 #include <db.h>
2705
2706 #ifdef DB_VERSION_MAJOR
2707         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2708 #if $cf_db_version == DB_VERSION_MAJOR
2709         /* ok */
2710 #else
2711         make an error
2712 #endif
2713 #else
2714 #if $cf_db_version == 1
2715         /* ok: assuming this is DB 1.8.5 */
2716 #else
2717         make an error
2718 #endif
2719 #endif
2720 ],[DBT *foo = 0],[
2721         cf_cv_hashed_db_version=$cf_db_version
2722         break
2723         ])
2724 done
2725 ])
2726 ])dnl
2727 dnl ---------------------------------------------------------------------------
2728 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2729 dnl --------------
2730 dnl Construct a search-list of directories for a nonstandard header-file
2731 dnl
2732 dnl Parameters
2733 dnl     $1 = the variable to return as result
2734 dnl     $2 = the package name
2735 AC_DEFUN([CF_HEADER_PATH],
2736 [
2737 $1=
2738
2739 # collect the current set of include-directories from compiler flags
2740 cf_header_path_list=""
2741 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2742         for cf_header_path in $CPPFLAGS $CFLAGS
2743         do
2744                 case $cf_header_path in #(vi
2745                 -I*)
2746                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2747                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2748                         cf_header_path_list="$cf_header_path_list [$]$1"
2749                         ;;
2750                 esac
2751         done
2752 fi
2753
2754 # add the variations for the package we are looking for
2755 CF_SUBDIR_PATH($1,$2,include)
2756
2757 test "$includedir" != NONE && \
2758 test "$includedir" != "/usr/include" && \
2759 test -d "$includedir" && {
2760         test -d $includedir &&    $1="[$]$1 $includedir"
2761         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2762 }
2763
2764 test "$oldincludedir" != NONE && \
2765 test "$oldincludedir" != "/usr/include" && \
2766 test -d "$oldincludedir" && {
2767         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2768         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2769 }
2770
2771 $1="[$]$1 $cf_header_path_list"
2772 ])dnl
2773 dnl ---------------------------------------------------------------------------
2774 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2775 dnl ---------------
2776 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2777 AC_DEFUN([CF_HELP_MESSAGE],
2778 [AC_DIVERT_HELP([$1])dnl
2779 ])dnl
2780 dnl ---------------------------------------------------------------------------
2781 dnl CF_INCLUDE_DIRS version: 7 updated: 2012/11/10 19:15:05
2782 dnl ---------------
2783 dnl Construct the list of include-options according to whether we're building
2784 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2785 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2786 dnl since that usually breaks gcc's shadow-includes.
2787 AC_DEFUN([CF_INCLUDE_DIRS],
2788 [
2789 if test "$GCC" != yes; then
2790         CPPFLAGS="-I\${includedir} $CPPFLAGS"
2791 elif test "$includedir" != "/usr/include"; then
2792         if test "$includedir" = '${prefix}/include' ; then
2793                 if test $prefix != /usr ; then
2794                         CPPFLAGS="-I\${includedir} $CPPFLAGS"
2795                 fi
2796         else
2797                 CPPFLAGS="-I\${includedir} $CPPFLAGS"
2798         fi
2799 fi
2800 if test "$srcdir" != "."; then
2801         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
2802 fi
2803 CPPFLAGS="-I. -I../include $CPPFLAGS"
2804 AC_SUBST(CPPFLAGS)
2805 ])dnl
2806 dnl ---------------------------------------------------------------------------
2807 dnl CF_INTEL_COMPILER version: 5 updated: 2013/02/10 10:41:05
2808 dnl -----------------
2809 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2810 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2811 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2812 dnl
2813 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2814 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2815 dnl the wrappers for gcc and g++ warnings.
2816 dnl
2817 dnl $1 = GCC (default) or GXX
2818 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2819 dnl $3 = CFLAGS (default) or CXXFLAGS
2820 AC_DEFUN([CF_INTEL_COMPILER],[
2821 AC_REQUIRE([AC_CANONICAL_HOST])
2822 ifelse([$2],,INTEL_COMPILER,[$2])=no
2823
2824 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2825         case $host_os in
2826         linux*|gnu*)
2827                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2828                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2829                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2830                 AC_TRY_COMPILE([],[
2831 #ifdef __INTEL_COMPILER
2832 #else
2833 make an error
2834 #endif
2835 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2836 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
2837 ],[])
2838                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2839                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2840                 ;;
2841         esac
2842 fi
2843 ])dnl
2844 dnl ---------------------------------------------------------------------------
2845 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
2846 dnl ----------
2847 dnl Check if we have either a function or macro for 'isascii()'.
2848 AC_DEFUN([CF_ISASCII],
2849 [
2850 AC_MSG_CHECKING(for isascii)
2851 AC_CACHE_VAL(cf_cv_have_isascii,[
2852         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2853         [cf_cv_have_isascii=yes],
2854         [cf_cv_have_isascii=no])
2855 ])dnl
2856 AC_MSG_RESULT($cf_cv_have_isascii)
2857 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
2858 ])dnl
2859 dnl ---------------------------------------------------------------------------
2860 dnl CF_LARGEFILE version: 8 updated: 2012/10/06 08:57:51
2861 dnl ------------
2862 dnl Add checks for large file support.
2863 AC_DEFUN([CF_LARGEFILE],[
2864 ifdef([AC_FUNC_FSEEKO],[
2865     AC_SYS_LARGEFILE
2866     if test "$enable_largefile" != no ; then
2867         AC_FUNC_FSEEKO
2868
2869         # Normally we would collect these definitions in the config.h,
2870         # but (like _XOPEN_SOURCE), some environments rely on having these
2871         # defined before any of the system headers are included.  Another
2872         # case comes up with C++, e.g., on AIX the compiler compiles the
2873         # header files by themselves before looking at the body files it is
2874         # told to compile.  For ncurses, those header files do not include
2875         # the config.h
2876         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2877         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2878         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2879
2880         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2881                 AC_TRY_COMPILE([
2882 #include <sys/types.h>
2883 #include <dirent.h>
2884                 ],[
2885                 /* if transitional largefile support is setup, this is true */
2886                 extern struct dirent64 * readdir(DIR *);
2887                 struct dirent64 *x = readdir((DIR *)0);
2888                 struct dirent *y = readdir((DIR *)0);
2889                 int z = x - y;
2890                 ],
2891                 [cf_cv_struct_dirent64=yes],
2892                 [cf_cv_struct_dirent64=no])
2893         ])
2894         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
2895     fi
2896 ])
2897 ])
2898 dnl ---------------------------------------------------------------------------
2899 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2900 dnl -----------------
2901 dnl Check for compiler/linker flags used to temporarily force usage of static
2902 dnl libraries.  This depends on the compiler and platform.  Use this to help
2903 dnl ensure that the linker picks up a given library based on its position in
2904 dnl the list of linker options and libraries.
2905 AC_DEFUN([CF_LDFLAGS_STATIC],[
2906
2907 if test "$GCC" = yes ; then
2908         case $cf_cv_system_name in #(
2909         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2910                 LDFLAGS_STATIC=
2911                 LDFLAGS_SHARED=
2912                 ;;
2913     *)  #( normally, except when broken
2914         LDFLAGS_STATIC=-static
2915         LDFLAGS_SHARED=-dynamic
2916         ;;
2917     esac
2918 else
2919         case $cf_cv_system_name in #(
2920         aix[[4-7]]*)    #( from ld manpage
2921                 LDFLAGS_STATIC=-bstatic
2922                 LDFLAGS_SHARED=-bdynamic
2923                 ;;
2924         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2925                 # We could also use just "archive" and "shared".
2926                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2927                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2928                 ;;
2929         irix*)          #( from ld manpage IRIX64
2930                 LDFLAGS_STATIC=-Bstatic
2931                 LDFLAGS_SHARED=-Bdynamic
2932                 ;;
2933         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2934                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2935                 LDFLAGS_STATIC=-noso
2936                 LDFLAGS_SHARED=-so_archive
2937                 ;;
2938         solaris2*)
2939                 LDFLAGS_STATIC=-Bstatic
2940                 LDFLAGS_SHARED=-Bdynamic
2941                 ;;
2942         esac
2943 fi
2944
2945 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
2946 then
2947         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
2948
2949         rm -f libconftest.a
2950         cat >conftest.$ac_ext <<EOF
2951 #line __oline__ "configure"
2952 #include <stdio.h>
2953 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
2954 EOF
2955         if AC_TRY_EVAL(ac_compile) ; then
2956                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
2957                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
2958         fi
2959         rm -f conftest.*
2960
2961         cf_save_LIBS="$LIBS"
2962
2963         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
2964         AC_TRY_LINK([
2965 #line __oline__ "configure"
2966 #include <stdio.h>
2967 int cf_ldflags_static(FILE *fp);
2968 ],[
2969         return cf_ldflags_static(stdin);
2970 ],[
2971         # some linkers simply ignore the -dynamic
2972         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
2973         *static*) # (vi
2974                 cf_ldflags_static=no
2975                 ;;
2976         *)
2977                 cf_ldflags_static=yes
2978                 ;;
2979         esac
2980 ],[cf_ldflags_static=no])
2981
2982         rm -f libconftest.*
2983         LIBS="$cf_save_LIBS"
2984
2985         AC_MSG_RESULT($cf_ldflags_static)
2986
2987         if test $cf_ldflags_static != yes
2988         then
2989                 LDFLAGS_STATIC=
2990                 LDFLAGS_SHARED=
2991         fi
2992 else
2993         LDFLAGS_STATIC=
2994         LDFLAGS_SHARED=
2995 fi
2996
2997 AC_SUBST(LDFLAGS_STATIC)
2998 AC_SUBST(LDFLAGS_SHARED)
2999 ])
3000 dnl ---------------------------------------------------------------------------
3001 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
3002 dnl ---------------
3003 dnl For the given system and compiler, find the compiler flags to pass to the
3004 dnl loader to use the "rpath" feature.
3005 AC_DEFUN([CF_LD_RPATH_OPT],
3006 [
3007 AC_REQUIRE([CF_CHECK_CACHE])
3008
3009 LD_RPATH_OPT=
3010 AC_MSG_CHECKING(for an rpath option)
3011 case $cf_cv_system_name in #(vi
3012 irix*) #(vi
3013         if test "$GCC" = yes; then
3014                 LD_RPATH_OPT="-Wl,-rpath,"
3015         else
3016                 LD_RPATH_OPT="-rpath "
3017         fi
3018         ;;
3019 linux*|gnu*|k*bsd*-gnu) #(vi
3020         LD_RPATH_OPT="-Wl,-rpath,"
3021         ;;
3022 openbsd[[2-9]].*|mirbsd*) #(vi
3023         LD_RPATH_OPT="-Wl,-rpath,"
3024         ;;
3025 dragonfly*|freebsd*) #(vi
3026         LD_RPATH_OPT="-rpath "
3027         ;;
3028 netbsd*) #(vi
3029         LD_RPATH_OPT="-Wl,-rpath,"
3030         ;;
3031 osf*|mls+*) #(vi
3032         LD_RPATH_OPT="-rpath "
3033         ;;
3034 solaris2*) #(vi
3035         LD_RPATH_OPT="-R"
3036         ;;
3037 *)
3038         ;;
3039 esac
3040 AC_MSG_RESULT($LD_RPATH_OPT)
3041
3042 case "x$LD_RPATH_OPT" in #(vi
3043 x-R*)
3044         AC_MSG_CHECKING(if we need a space after rpath option)
3045         cf_save_LIBS="$LIBS"
3046         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3047         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3048         LIBS="$cf_save_LIBS"
3049         AC_MSG_RESULT($cf_rpath_space)
3050         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3051         ;;
3052 esac
3053 ])dnl
3054 dnl ---------------------------------------------------------------------------
3055 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
3056 dnl ---------------
3057 dnl Construct a search-list of directories for a nonstandard library-file
3058 dnl
3059 dnl Parameters
3060 dnl     $1 = the variable to return as result
3061 dnl     $2 = the package name
3062 AC_DEFUN([CF_LIBRARY_PATH],
3063 [
3064 $1=
3065 cf_library_path_list=""
3066 if test -n "${LDFLAGS}${LIBS}" ; then
3067         for cf_library_path in $LDFLAGS $LIBS
3068         do
3069                 case $cf_library_path in #(vi
3070                 -L*)
3071                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3072                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3073                         cf_library_path_list="$cf_library_path_list [$]$1"
3074                         ;;
3075                 esac
3076         done
3077 fi
3078
3079 CF_SUBDIR_PATH($1,$2,lib)
3080
3081 $1="$cf_library_path_list [$]$1"
3082 ])dnl
3083 dnl ---------------------------------------------------------------------------
3084 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3085 dnl ------------------
3086 AC_DEFUN([CF_LIBTOOL_VERSION],[
3087 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3088 then
3089         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3090 else
3091         cf_cv_libtool_version=
3092 fi
3093 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3094 ])dnl
3095 dnl ---------------------------------------------------------------------------
3096 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
3097 dnl -------------
3098 dnl Compute the library-prefix for the given host system
3099 dnl $1 = variable to set
3100 define([CF_LIB_PREFIX],
3101 [
3102         case $cf_cv_system_name in #(vi
3103         OS/2*|os2*) #(vi
3104         LIB_PREFIX=''
3105         ;;
3106         *)      LIB_PREFIX='lib'
3107         ;;
3108         esac
3109 ifelse($1,,,[$1=$LIB_PREFIX])
3110         AC_SUBST(LIB_PREFIX)
3111 ])dnl
3112 dnl ---------------------------------------------------------------------------
3113 dnl CF_LIB_RULES version: 72 updated: 2013/03/24 17:10:41
3114 dnl ------------
3115 dnl Append definitions and rules for the given models to the subdirectory
3116 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3117 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3118 dnl the corresponding makefile to list the models that we'll generate.
3119 dnl
3120 dnl For shared libraries, make a list of symbolic links to construct when
3121 dnl generating each library.  The convention used for Linux is the simplest
3122 dnl one:
3123 dnl     lib<name>.so    ->
3124 dnl     lib<name>.so.<major>    ->
3125 dnl     lib<name>.so.<maj>.<minor>
3126 dnl
3127 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3128 AC_DEFUN([CF_LIB_RULES],
3129 [
3130 cf_prefix=$LIB_PREFIX
3131 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3132
3133 case $cf_cv_shlib_version in #(vi
3134 cygdll|mingw)
3135         TINFO_NAME=$TINFO_ARG_SUFFIX
3136         TINFO_SUFFIX=.dll
3137         ;;
3138 esac
3139
3140 if test -n "$TINFO_SUFFIX" ; then
3141         case $TINFO_SUFFIX in
3142         tw*)
3143                 TINFO_NAME="${TINFO_NAME}tw"
3144                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
3145                 ;;
3146         t*)
3147                 TINFO_NAME="${TINFO_NAME}t"
3148                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3149                 ;;
3150         w*)
3151                 TINFO_NAME="${TINFO_NAME}w"
3152                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3153                 ;;
3154         esac
3155 fi
3156
3157 for cf_dir in $SRC_SUBDIRS
3158 do
3159         if test ! -d $srcdir/$cf_dir ; then
3160                 continue
3161         elif test -f $srcdir/$cf_dir/modules; then
3162
3163                 SHARED_LIB=
3164                 Libs_To_Make=
3165                 for cf_item in $cf_LIST_MODELS
3166                 do
3167                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3168                         cf_libname=$cf_dir
3169                         test "$cf_dir" = c++ && cf_libname=ncurses++
3170                         if test $cf_item = shared ; then
3171                                 if test -n "${LIB_SUFFIX}"
3172                                 then
3173                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${LIB_SUFFIX}"'//'`
3174                                 else
3175                                         cf_shared_suffix="$cf_suffix"
3176                                 fi
3177                                 if test "$cf_cv_do_symlinks" = yes ; then
3178                                         cf_version_name=
3179
3180                                         case "$cf_cv_shlib_version" in #(vi
3181                                         rel) #(vi
3182                                                 cf_version_name=REL_VERSION
3183                                                 ;;
3184                                         abi)
3185                                                 cf_version_name=ABI_VERSION
3186                                                 ;;
3187                                         esac
3188
3189                                         if test -n "$cf_version_name"
3190                                         then
3191                                                 case "$cf_cv_system_name" in #(vi
3192                                                 darwin*)
3193                                                         # "w", etc?
3194                                                         cf_suffix="${LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3195                                                         ;; #(vi
3196                                                 *)
3197                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3198                                                         ;;
3199                                                 esac
3200                                         fi
3201                                         if test -n "${LIB_SUFFIX}"
3202                                         then
3203                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${LIB_SUFFIX}"'//'`
3204                                         else
3205                                                 cf_shared_suffix="$cf_suffix"
3206                                         fi
3207                                 fi
3208                                 # cygwin needs import library, and has unique naming convention
3209                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3210                                 # use 'cyg' prefix for shared lib.
3211                                 case $cf_cv_shlib_version in #(vi
3212                                 cygdll) #(vi
3213                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3214                                         Libs_To_Make="$Libs_To_Make ../lib/cyg${cf_libname}${cf_cygsuf}"
3215                                         continue
3216                                         ;;
3217                                 mingw)
3218                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3219                                         Libs_To_Make="$Libs_To_Make ../lib/lib${cf_libname}${cf_cygsuf}"
3220                                         continue
3221                                         ;;
3222                                 esac
3223                         fi
3224                         Libs_To_Make="$Libs_To_Make ../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3225                 done
3226
3227                 if test $cf_dir = ncurses ; then
3228                         cf_subsets="$LIB_SUBSETS"
3229                         cf_r_parts="$cf_subsets"
3230                         cf_liblist="$Libs_To_Make"
3231
3232                         while test -n "$cf_r_parts"
3233                         do
3234                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3235                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3236                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3237                                         cf_item=
3238                                         case $cf_l_parts in #(vi
3239                                         *termlib*) #(vi
3240                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3241                                                 ;;
3242                                         *ticlib*)
3243                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3244                                                 ;;
3245                                         *)
3246                                                 break
3247                                                 ;;
3248                                         esac
3249                                         if test -n "$cf_item"; then
3250                                                 Libs_To_Make="$cf_item $Libs_To_Make"
3251                                         fi
3252                                 else
3253                                         break
3254                                 fi
3255                         done
3256                 else
3257                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3258                 fi
3259
3260                 if test $cf_dir = c++; then
3261                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3262                                 cf_list=
3263                                 for cf_item in $Libs_To_Make
3264                                 do
3265                                         case $cf_item in
3266                                         *.a)
3267                                                 ;;
3268                                         *)
3269                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3270                                                 ;;
3271                                         esac
3272                                         for cf_test in $cf_list
3273                                         do
3274                                                 if test "$cf_test" = "$cf_item"
3275                                                 then
3276                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3277                                                         cf_item=
3278                                                         break
3279                                                 fi
3280                                         done
3281                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3282                                 done
3283                                 Libs_To_Make="$cf_list"
3284                         fi
3285                 fi
3286
3287                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3288                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3289                         $cf_dir/Makefile >$cf_dir/Makefile.out
3290                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3291
3292                 $AWK -f $srcdir/mk-0th.awk \
3293                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3294                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3295
3296                 for cf_subset in $cf_subsets
3297                 do
3298                         cf_subdirs=
3299                         for cf_item in $cf_LIST_MODELS
3300                         do
3301
3302                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3303                         CF_UPPER(cf_ITEM,$cf_item)
3304
3305                         CXX_MODEL=$cf_ITEM
3306                         if test "$CXX_MODEL" = SHARED; then
3307                                 case $cf_cv_shlib_version in #(vi
3308                                 cygdll|mingw) #(vi
3309                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3310                                         with_shared_cxx=yes
3311                                         ;;
3312                                 *)
3313                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3314                                         ;;
3315                                 esac
3316                         fi
3317
3318                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3319                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3320
3321                         # Test for case where we build libtinfo with a different name.
3322                         cf_libname=$cf_dir
3323                         if test $cf_dir = ncurses ; then
3324                                 case $cf_subset in
3325                                 *base*)
3326                                         cf_libname=${cf_libname}$LIB_SUFFIX
3327                                         ;;
3328                                 *termlib*)
3329                                         cf_libname=$TINFO_LIB_SUFFIX
3330                                         ;;
3331                                 ticlib*)
3332                                         cf_libname=$TICS_LIB_SUFFIX
3333                                         ;;
3334                                 esac
3335                         elif test $cf_dir = c++ ; then
3336                                 cf_libname=ncurses++$LIB_SUFFIX
3337                         else
3338                                 cf_libname=${cf_libname}$LIB_SUFFIX
3339                         fi
3340                         if test -n "${DFT_ARG_SUFFIX}" ; then
3341                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3342                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3343                         fi
3344
3345                         # These dependencies really are for development, not
3346                         # builds, but they are useful in porting, too.
3347                         cf_depend="../include/ncurses_cfg.h"
3348                         if test "$srcdir" = "."; then
3349                                 cf_reldir="."
3350                         else
3351                                 cf_reldir="\${srcdir}"
3352                         fi
3353
3354                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3355                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3356                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3357                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3358                         fi
3359
3360                         cf_dir_suffix=
3361                         old_cf_suffix="$cf_suffix"
3362                         if test "$cf_cv_shlib_version_infix" = yes ; then
3363                         if test -n "$LIB_SUFFIX" ; then
3364                                 case $LIB_SUFFIX in
3365                                 tw*)
3366                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3367                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3368                                         cf_dir_suffix=tw
3369                                         ;;
3370                                 t*)
3371                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3372                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3373                                         cf_dir_suffix=t
3374                                         ;;
3375                                 w*)
3376                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3377                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3378                                         cf_dir_suffix=w
3379                                         ;;
3380                                 esac
3381                         fi
3382                         fi
3383
3384                         $AWK -f $srcdir/mk-1st.awk \
3385                                 name=${cf_libname}${cf_dir_suffix} \
3386                                 traces=$LIB_TRACING \
3387                                 MODEL=$cf_ITEM \
3388                                 CXX_MODEL=$CXX_MODEL \
3389                                 model=$cf_subdir \
3390                                 prefix=$cf_prefix \
3391                                 suffix=$cf_suffix \
3392                                 subset=$cf_subset \
3393                                 driver=$cf_cv_term_driver \
3394                                 SymLink="$LN_S" \
3395                                 TermlibRoot=$TINFO_NAME \
3396                                 TermlibSuffix=$TINFO_SUFFIX \
3397                                 ShlibVer=$cf_cv_shlib_version \
3398                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3399                                 ReLink=${cf_cv_do_relink:-no} \
3400                                 DoLinks=$cf_cv_do_symlinks \
3401                                 rmSoLocs=$cf_cv_rm_so_locs \
3402                                 ldconfig="$LDCONFIG" \
3403                                 overwrite=$WITH_OVERWRITE \
3404                                 depend="$cf_depend" \
3405                                 host="$host" \
3406                                 libtool_version="$LIBTOOL_VERSION" \
3407                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3408
3409                         cf_suffix="$old_cf_suffix"
3410
3411                         for cf_subdir2 in $cf_subdirs lib
3412                         do
3413                                 test $cf_subdir = $cf_subdir2 && break
3414                         done
3415                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3416                         $AWK -f $srcdir/mk-2nd.awk \
3417                                 name=$cf_dir \
3418                                 traces=$LIB_TRACING \
3419                                 MODEL=$cf_ITEM \
3420                                 model=$cf_subdir \
3421                                 subset=$cf_subset \
3422                                 srcdir=$srcdir \
3423                                 echo=$WITH_ECHO \
3424                                 crenames=$cf_cv_prog_CC_c_o \
3425                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3426                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3427                         cf_subdirs="$cf_subdirs $cf_subdir"
3428                         done
3429                 done
3430         fi
3431
3432         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3433 done
3434
3435 for cf_dir in $SRC_SUBDIRS
3436 do
3437         if test ! -d $srcdir/$cf_dir ; then
3438                 continue
3439         fi
3440
3441         if test -f $cf_dir/Makefile ; then
3442                 case "$cf_dir" in
3443                 Ada95) #(vi
3444                         echo 'libs \' >> Makefile
3445                         echo 'install.libs \' >> Makefile
3446                         echo 'uninstall.libs ::' >> Makefile
3447                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3448                         ;;
3449                 esac
3450         fi
3451
3452         if test -f $srcdir/$cf_dir/modules; then
3453                 echo >> Makefile
3454                 if test -f $srcdir/$cf_dir/headers; then
3455 cat >> Makefile <<CF_EOF
3456 install.includes \\
3457 uninstall.includes \\
3458 CF_EOF
3459                 fi
3460 if test "$cf_dir" != "c++" ; then
3461 echo 'lint \' >> Makefile
3462 fi
3463 cat >> Makefile <<CF_EOF
3464 libs \\
3465 lintlib \\
3466 install.libs \\
3467 uninstall.libs \\
3468 install.$cf_dir \\
3469 uninstall.$cf_dir ::
3470         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3471 CF_EOF
3472         elif test -f $srcdir/$cf_dir/headers; then
3473 cat >> Makefile <<CF_EOF
3474
3475 libs \\
3476 install.libs \\
3477 uninstall.libs \\
3478 install.includes \\
3479 uninstall.includes ::
3480         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3481 CF_EOF
3482 fi
3483 done
3484
3485 cat >> Makefile <<CF_EOF
3486
3487 install.libs uninstall.libs \\
3488 install.data uninstall.data ::
3489 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3490 CF_EOF
3491
3492 if test "x$cf_with_manpages" = xyes; then
3493 cat >> Makefile <<CF_EOF
3494
3495 install.man \\
3496 uninstall.man ::
3497         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3498 CF_EOF
3499 fi
3500
3501 cat >> Makefile <<CF_EOF
3502
3503 distclean ::
3504         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3505         rm -f headers.sh headers.sed mk_shared_lib.sh
3506         rm -f edit_man.* man_alias.*
3507         rm -rf \${DIRS_TO_MAKE}
3508 CF_EOF
3509
3510 # Special case: tack's manpage lives in its own directory.
3511 if test "x$cf_with_manpages" = xyes; then
3512 if test -d tack ; then
3513 if test -f $srcdir/$tack.h; then
3514 cat >> Makefile <<CF_EOF
3515
3516 install.man \\
3517 uninstall.man ::
3518         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3519 CF_EOF
3520 fi
3521 fi
3522 fi
3523
3524 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3525 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3526 dnl anything, and will make it more standardized.  It's awkward to decide this
3527 dnl at configuration because of quoting, so we'll simply make all headers
3528 dnl installed via a script that can do the right thing.
3529
3530 rm -f headers.sed headers.sh
3531
3532 dnl ( generating this script makes the makefiles a little tidier :-)
3533 echo creating headers.sh
3534 cat >headers.sh <<CF_EOF
3535 #! /bin/sh
3536 # This shell script is generated by the 'configure' script.  It is invoked in a
3537 # subdirectory of the build tree.  It generates a sed-script in the parent
3538 # directory that is used to adjust includes for header files that reside in a
3539 # subdirectory of /usr/include, etc.
3540 PRG=""
3541 while test \[$]# != 3
3542 do
3543 PRG="\$PRG \[$]1"; shift
3544 done
3545 DST=\[$]1
3546 REF=\[$]2
3547 SRC=\[$]3
3548 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3549 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3550 echo installing \$SRC in \$DST
3551 CF_EOF
3552
3553 if test $WITH_CURSES_H = yes; then
3554         cat >>headers.sh <<CF_EOF
3555 case \$DST in
3556 /*/include/*)
3557         END=\`basename \$DST\`
3558         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3559         do
3560                 NAME=\`basename \$i\`
3561                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3562         done
3563         ;;
3564 *)
3565         echo "" >> \$TMPSED
3566         ;;
3567 esac
3568 CF_EOF
3569
3570 else
3571         cat >>headers.sh <<CF_EOF
3572 case \$DST in
3573 /*/include/*)
3574         END=\`basename \$DST\`
3575         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3576         do
3577                 NAME=\`basename \$i\`
3578                 if test "\$NAME" = "curses.h"
3579                 then
3580                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3581                         NAME=ncurses.h
3582                 fi
3583                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3584         done
3585         ;;
3586 *)
3587         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3588         ;;
3589 esac
3590 CF_EOF
3591 fi
3592 cat >>headers.sh <<CF_EOF
3593 rm -f \$TMPSRC
3594 sed -f \$TMPSED \$SRC > \$TMPSRC
3595 NAME=\`basename \$SRC\`
3596 CF_EOF
3597 if test $WITH_CURSES_H != yes; then
3598         cat >>headers.sh <<CF_EOF
3599 test "\$NAME" = "curses.h" && NAME=ncurses.h
3600 CF_EOF
3601 fi
3602 cat >>headers.sh <<CF_EOF
3603 # Just in case someone gzip'd manpages, remove the conflicting copy.
3604 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3605
3606 eval \$PRG \$TMPSRC \$DST/\$NAME
3607 rm -f \$TMPSRC \$TMPSED
3608 CF_EOF
3609
3610 chmod 0755 headers.sh
3611
3612 for cf_dir in $SRC_SUBDIRS
3613 do
3614         if test ! -d $srcdir/$cf_dir ; then
3615                 continue
3616         fi
3617
3618         if test -f $srcdir/$cf_dir/headers; then
3619                 $AWK -f $srcdir/mk-hdr.awk \
3620                         subset="$LIB_SUBSETS" \
3621                         compat="$WITH_CURSES_H" \
3622                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3623         fi
3624
3625         if test -f $srcdir/$cf_dir/modules; then
3626                 if test "$cf_dir" != "c++" ; then
3627                         cat >>$cf_dir/Makefile <<"CF_EOF"
3628 depend : ${AUTO_SRC}
3629         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3630
3631 # DO NOT DELETE THIS LINE -- make depend depends on it.
3632 CF_EOF
3633                 fi
3634         fi
3635 done
3636 AC_SUBST(Libs_To_Make)
3637 ])dnl
3638 dnl ---------------------------------------------------------------------------
3639 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3640 dnl -------------
3641 dnl Find the and soname for the given shared library.  Set the cache variable
3642 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3643 dnl variable to "unknown".
3644 dnl
3645 dnl $1 = headers
3646 dnl $2 = code
3647 dnl $3 = library name
3648 AC_DEFUN([CF_LIB_SONAME],
3649 [
3650 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3651
3652 cf_cv_$3_soname=unknown
3653 if test "$cross_compiling" != yes ; then
3654 cat >conftest.$ac_ext <<CF_EOF
3655 $1
3656 int main()
3657 {
3658 $2
3659         ${cf_cv_main_return:-return}(0);
3660 }
3661 CF_EOF
3662 cf_save_LIBS="$LIBS"
3663         CF_ADD_LIB($3)
3664         if AC_TRY_EVAL(ac_compile) ; then
3665                 if AC_TRY_EVAL(ac_link) ; then
3666                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3667                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3668                 fi
3669         fi
3670 rm -rf conftest*
3671 LIBS="$cf_save_LIBS"
3672 fi
3673 ])
3674 ])
3675 dnl ---------------------------------------------------------------------------
3676 dnl CF_LIB_SUFFIX version: 19 updated: 2013/06/15 11:58:48
3677 dnl -------------
3678 dnl Compute the library file-suffix from the given model name
3679 dnl $1 = model name
3680 dnl $2 = variable to set (the nominal library suffix)
3681 dnl $3 = dependency variable to set (actual filename)
3682 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3683 AC_DEFUN([CF_LIB_SUFFIX],
3684 [
3685         case $1 in #(vi
3686         libtool) #(vi
3687                 $2='.la'
3688                 $3=[$]$2
3689                 ;;
3690         normal) #(vi
3691                 $2='.a'
3692                 $3=[$]$2
3693                 ;;
3694         debug) #(vi
3695                 $2='_g.a'
3696                 $3=[$]$2
3697                 ;;
3698         profile) #(vi
3699                 $2='_p.a'
3700                 $3=[$]$2
3701                 ;;
3702         shared) #(vi
3703                 case $cf_cv_system_name in
3704                 aix[[5-7]]*) #(vi
3705                         $2='.a'
3706                         $3=[$]$2
3707                         ;;
3708                 cygwin*|mingw*) #(vi
3709                         $2='.dll'
3710                         $3='.dll.a'
3711                         ;;
3712                 darwin*) #(vi
3713                         $2='.dylib'
3714                         $3=[$]$2
3715                         ;;
3716                 hpux*) #(vi
3717                         case $target in
3718                         ia64*) #(vi
3719                                 $2='.so'
3720                                 $3=[$]$2
3721                                 ;;
3722                         *) #(vi
3723                                 $2='.sl'
3724                                 $3=[$]$2
3725                                 ;;
3726                         esac
3727                         ;;
3728                 *)      $2='.so'
3729                         $3=[$]$2
3730                         ;;
3731                 esac
3732         esac
3733         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3734         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3735 ])dnl
3736 dnl ---------------------------------------------------------------------------
3737 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3738 dnl -----------
3739 dnl Compute the string to append to -library from the given model name
3740 dnl $1 = model name
3741 dnl $2 = variable to set
3742 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3743 AC_DEFUN([CF_LIB_TYPE],
3744 [
3745         case $1 in
3746         libtool) $2=''   ;;
3747         normal)  $2=''   ;;
3748         debug)   $2='_g' ;;
3749         profile) $2='_p' ;;
3750         shared)  $2=''   ;;
3751         esac
3752         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3753 ])dnl
3754 dnl ---------------------------------------------------------------------------
3755 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
3756 dnl ----------------
3757 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3758 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3759 dnl have to provide wrappers for global tables to ensure they're linked
3760 dnl properly.
3761 AC_DEFUN([CF_LINK_DATAONLY],
3762 [
3763 AC_MSG_CHECKING([if data-only library module links])
3764 AC_CACHE_VAL(cf_cv_link_dataonly,[
3765         rm -f conftest.a
3766         cat >conftest.$ac_ext <<EOF
3767 #line __oline__ "configure"
3768 int     testdata[[3]] = { 123, 456, 789 };
3769 EOF
3770         if AC_TRY_EVAL(ac_compile) ; then
3771                 mv conftest.o data.o && \
3772                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3773         fi
3774         rm -f conftest.$ac_ext data.o
3775         cat >conftest.$ac_ext <<EOF
3776 #line __oline__ "configure"
3777 int     testfunc()
3778 {
3779 #if defined(NeXT)
3780         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3781 #else
3782         extern int testdata[[3]];
3783         return testdata[[0]] == 123
3784            &&  testdata[[1]] == 456
3785            &&  testdata[[2]] == 789;
3786 #endif
3787 }
3788 EOF
3789         if AC_TRY_EVAL(ac_compile); then
3790                 mv conftest.o func.o && \
3791                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3792         fi
3793         rm -f conftest.$ac_ext func.o
3794         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3795         cf_saveLIBS="$LIBS"
3796         LIBS="conftest.a $LIBS"
3797         AC_TRY_RUN([
3798         int main()
3799         {
3800                 extern int testfunc();
3801                 ${cf_cv_main_return:-return} (!testfunc());
3802         }
3803         ],
3804         [cf_cv_link_dataonly=yes],
3805         [cf_cv_link_dataonly=no],
3806         [cf_cv_link_dataonly=unknown])
3807         LIBS="$cf_saveLIBS"
3808         ])
3809 AC_MSG_RESULT($cf_cv_link_dataonly)
3810
3811 if test "$cf_cv_link_dataonly" = no ; then
3812         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
3813         BROKEN_LINKER=1
3814 fi
3815
3816 ])dnl
3817 dnl ---------------------------------------------------------------------------
3818 dnl CF_LINK_FUNCS version: 8 updated: 2012/10/06 17:56:13
3819 dnl -------------
3820 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3821 dnl A few non-Unix systems implement symlink, but not link.
3822 dnl A few non-systems implement neither (or have nonfunctional versions).
3823 AC_DEFUN([CF_LINK_FUNCS],
3824 [
3825 AC_CHECK_FUNCS( \
3826         remove \
3827         unlink )
3828
3829 if test "$cross_compiling" = yes ; then
3830         AC_CHECK_FUNCS( \
3831                 link \
3832                 symlink )
3833 else
3834         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3835                 cf_cv_link_funcs=
3836                 for cf_func in link symlink ; do
3837                         AC_TRY_RUN([
3838 #include <sys/types.h>
3839 #include <sys/stat.h>
3840 #ifdef HAVE_UNISTD_H
3841 #include <unistd.h>
3842 #endif
3843 int main()
3844 {
3845         int fail = 0;
3846         char *src = "config.log";
3847         char *dst = "conftest.chk";
3848         struct stat src_sb;
3849         struct stat dst_sb;
3850
3851         stat(src, &src_sb);
3852         fail = ($cf_func("config.log", "conftest.chk") < 0)
3853             || (stat(dst, &dst_sb) < 0)
3854             || (dst_sb.st_mtime != src_sb.st_mtime);
3855 #ifdef HAVE_UNLINK
3856         unlink(dst);
3857 #else
3858         remove(dst);
3859 #endif
3860         ${cf_cv_main_return:-return} (fail);
3861 }
3862                         ],[
3863                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3864                         eval 'ac_cv_func_'$cf_func'=yes'],[
3865                         eval 'ac_cv_func_'$cf_func'=no'],[
3866                         eval 'ac_cv_func_'$cf_func'=error'])
3867                 done
3868                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
3869         ])
3870         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
3871         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
3872 fi
3873 ])dnl
3874 dnl ---------------------------------------------------------------------------
3875 dnl CF_MAKEFLAGS version: 14 updated: 2011/03/31 19:29:46
3876 dnl ------------
3877 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
3878 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
3879 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
3880 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
3881 AC_DEFUN([CF_MAKEFLAGS],
3882 [
3883 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
3884         cf_cv_makeflags=''
3885         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
3886         do
3887                 cat >cf_makeflags.tmp <<CF_EOF
3888 SHELL = /bin/sh
3889 all :
3890         @ echo '.$cf_option'
3891 CF_EOF
3892                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
3893                 case "$cf_result" in
3894                 .*k)
3895                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
3896                         case "$cf_result" in
3897                         .*CC=*) cf_cv_makeflags=
3898                                 ;;
3899                         *)      cf_cv_makeflags=$cf_option
3900                                 ;;
3901                         esac
3902                         break
3903                         ;;
3904                 .-)     ;;
3905                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
3906                         ;;
3907                 esac
3908         done
3909         rm -f cf_makeflags.tmp
3910 ])
3911
3912 AC_SUBST(cf_cv_makeflags)
3913 ])dnl
3914 dnl ---------------------------------------------------------------------------
3915 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
3916 dnl ------------
3917 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
3918 dnl a monocase filesystem.
3919 AC_DEFUN([CF_MAKE_TAGS],[
3920 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
3921
3922 AC_CHECK_PROGS(CTAGS, exctags ctags)
3923 AC_CHECK_PROGS(ETAGS, exetags etags)
3924
3925 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
3926
3927 if test "$cf_cv_mixedcase" = yes ; then
3928         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
3929 else
3930         MAKE_UPPER_TAGS=no
3931 fi
3932
3933 if test "$MAKE_UPPER_TAGS" = yes ; then
3934         MAKE_UPPER_TAGS=
3935 else
3936         MAKE_UPPER_TAGS="#"
3937 fi
3938
3939 if test "$MAKE_LOWER_TAGS" = yes ; then
3940         MAKE_LOWER_TAGS=
3941 else
3942         MAKE_LOWER_TAGS="#"
3943 fi
3944
3945 AC_SUBST(CTAGS)
3946 AC_SUBST(ETAGS)
3947
3948 AC_SUBST(MAKE_UPPER_TAGS)
3949 AC_SUBST(MAKE_LOWER_TAGS)
3950 ])dnl
3951 dnl ---------------------------------------------------------------------------
3952 dnl CF_MANPAGE_FORMAT version: 9 updated: 2010/10/23 16:10:30
3953 dnl -----------------
3954 dnl Option to allow user to override automatic configuration of manpage format.
3955 dnl There are several special cases:
3956 dnl
3957 dnl     gzip - man checks for, can display gzip'd files
3958 dnl     compress - man checks for, can display compressed files
3959 dnl     BSDI - files in the cat-directories are suffixed ".0"
3960 dnl     formatted - installer should format (put files in cat-directory)
3961 dnl     catonly - installer should only format, e.g., for a turnkey system.
3962 dnl
3963 dnl There are other configurations which this macro does not test, e.g., HPUX's
3964 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
3965 dnl convention would not match our use).
3966 AC_DEFUN([CF_MANPAGE_FORMAT],
3967 [
3968 AC_REQUIRE([CF_PATHSEP])
3969 AC_MSG_CHECKING(format of man-pages)
3970
3971 AC_ARG_WITH(manpage-format,
3972         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
3973                           optionally formatted/catonly, e.g., gzip,formatted],
3974         [MANPAGE_FORMAT=$withval],
3975         [MANPAGE_FORMAT=unknown])
3976
3977 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
3978 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
3979
3980 cf_unknown=
3981
3982 case $MANPAGE_FORMAT in
3983 unknown)
3984   if test -z "$MANPATH" ; then
3985     MANPATH="/usr/man:/usr/share/man"
3986   fi
3987
3988   # look for the 'date' man-page (it's most likely to be installed!)
3989   MANPAGE_FORMAT=
3990   cf_preform=no
3991   cf_catonly=yes
3992   cf_example=date
3993
3994   IFS="${IFS:-  }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
3995   for cf_dir in $MANPATH; do
3996     test -z "$cf_dir" && cf_dir=/usr/man
3997     for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
3998     do
3999       cf_test=`echo $cf_name | sed -e 's/*//'`
4000       if test "x$cf_test" = "x$cf_name" ; then
4001
4002         case "$cf_name" in
4003         *.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
4004         *.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
4005         *.0)    MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
4006         *)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
4007         esac
4008
4009         case "$cf_name" in
4010         $cf_dir/man*)
4011           cf_catonly=no
4012           ;;
4013         $cf_dir/cat*)
4014           cf_preform=yes
4015           ;;
4016         esac
4017         break
4018       fi
4019
4020       # if we found a match in either man* or cat*, stop looking
4021       if test -n "$MANPAGE_FORMAT" ; then
4022         cf_found=no
4023         test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
4024         test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
4025         case "$cf_name" in
4026         $cf_dir/cat*)
4027           cf_found=yes
4028           ;;
4029         esac
4030         test $cf_found=yes && break
4031       fi
4032     done
4033     # only check the first directory in $MANPATH where we find manpages
4034     if test -n "$MANPAGE_FORMAT" ; then
4035        break
4036     fi
4037   done
4038   # if we did not find the example, just assume it is normal
4039   test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4040   IFS="$ac_save_ifs"
4041   ;;
4042 *)
4043   for cf_option in $MANPAGE_FORMAT; do
4044      case $cf_option in #(vi
4045      gzip|compress|BSDI|normal|formatted|catonly)
4046        ;;
4047      *)
4048        cf_unknown="$cf_unknown $cf_option"
4049        ;;
4050      esac
4051   done
4052   ;;
4053 esac
4054
4055 AC_MSG_RESULT($MANPAGE_FORMAT)
4056 if test -n "$cf_unknown" ; then
4057   AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4058 fi
4059 ])dnl
4060 dnl ---------------------------------------------------------------------------
4061 dnl CF_MANPAGE_RENAMES version: 7 updated: 2005/06/18 18:51:57
4062 dnl ------------------
4063 dnl The Debian people have their own naming convention for manpages.  This
4064 dnl option lets us override the name of the file containing renaming, or
4065 dnl disable it altogether.
4066 AC_DEFUN([CF_MANPAGE_RENAMES],
4067 [
4068 AC_MSG_CHECKING(for manpage renaming)
4069
4070 AC_ARG_WITH(manpage-renames,
4071         [  --with-manpage-renames  specify manpage-renaming],
4072         [MANPAGE_RENAMES=$withval],
4073         [MANPAGE_RENAMES=yes])
4074
4075 case ".$MANPAGE_RENAMES" in #(vi
4076 .no) #(vi
4077   ;;
4078 .|.yes)
4079   # Debian 'man' program?
4080   if test -f /etc/debian_version ; then
4081     MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4082   else
4083     MANPAGE_RENAMES=no
4084   fi
4085   ;;
4086 esac
4087
4088 if test "$MANPAGE_RENAMES" != no ; then
4089   if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4090     MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4091   elif test ! -f $MANPAGE_RENAMES ; then
4092     AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4093   fi
4094
4095   test ! -d man && mkdir man
4096
4097   # Construct a sed-script to perform renaming within man-pages
4098   if test -n "$MANPAGE_RENAMES" ; then
4099     test ! -d man && mkdir man
4100     sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4101   fi
4102 fi
4103
4104 AC_MSG_RESULT($MANPAGE_RENAMES)
4105 AC_SUBST(MANPAGE_RENAMES)
4106 ])dnl
4107 dnl ---------------------------------------------------------------------------
4108 dnl CF_MANPAGE_SYMLINKS version: 5 updated: 2010/07/24 17:12:40
4109 dnl -------------------
4110 dnl Some people expect each tool to make all aliases for manpages in the
4111 dnl man-directory.  This accommodates the older, less-capable implementations
4112 dnl of 'man', and is optional.
4113 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4114 [
4115 AC_MSG_CHECKING(if manpage aliases will be installed)
4116
4117 AC_ARG_WITH(manpage-aliases,
4118         [  --with-manpage-aliases  specify manpage-aliases using .so],
4119         [MANPAGE_ALIASES=$withval],
4120         [MANPAGE_ALIASES=yes])
4121
4122 AC_MSG_RESULT($MANPAGE_ALIASES)
4123
4124 case "x$LN_S" in #(vi
4125 xln*) #(vi
4126         cf_use_symlinks=yes
4127         ;;
4128 *)
4129         cf_use_symlinks=no
4130         ;;
4131 esac
4132
4133 MANPAGE_SYMLINKS=no
4134 if test "$MANPAGE_ALIASES" = yes ; then
4135 AC_MSG_CHECKING(if manpage symlinks should be used)
4136
4137 AC_ARG_WITH(manpage-symlinks,
4138         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4139         [MANPAGE_SYMLINKS=$withval],
4140         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4141
4142 if test "$$cf_use_symlinks" = no; then
4143 if test "$MANPAGE_SYMLINKS" = yes ; then
4144         AC_MSG_WARN(cannot make symlinks, will use .so files)
4145         MANPAGE_SYMLINKS=no
4146 fi
4147 fi
4148
4149 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4150 fi
4151
4152 ])dnl
4153 dnl ---------------------------------------------------------------------------
4154 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4155 dnl --------------
4156 dnl This option causes manpages to be run through tbl(1) to generate tables
4157 dnl correctly.
4158 AC_DEFUN([CF_MANPAGE_TBL],
4159 [
4160 AC_MSG_CHECKING(for manpage tbl)
4161
4162 AC_ARG_WITH(manpage-tbl,
4163         [  --with-manpage-tbl      specify manpage processing with tbl],
4164         [MANPAGE_TBL=$withval],
4165         [MANPAGE_TBL=no])
4166
4167 AC_MSG_RESULT($MANPAGE_TBL)
4168 ])dnl
4169 dnl ---------------------------------------------------------------------------
4170 dnl CF_MAN_PAGES version: 43 updated: 2013/02/09 12:53:45
4171 dnl ------------
4172 dnl Try to determine if the man-pages on the system are compressed, and if
4173 dnl so, what format is used.  Use this information to construct a script that
4174 dnl will install man-pages.
4175 AC_DEFUN([CF_MAN_PAGES],
4176 [
4177 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4178 CF_MANPAGE_FORMAT
4179 CF_MANPAGE_RENAMES
4180 CF_MANPAGE_SYMLINKS
4181 CF_MANPAGE_TBL
4182
4183   if test "$prefix" = "NONE" ; then
4184      cf_prefix="$ac_default_prefix"
4185   else
4186      cf_prefix="$prefix"
4187   fi
4188
4189   case "$MANPAGE_FORMAT" in # (vi
4190   *catonly*) # (vi
4191     cf_format=yes
4192     cf_inboth=no
4193     ;;
4194   *formatted*) # (vi
4195     cf_format=yes
4196     cf_inboth=yes
4197     ;;
4198   *)
4199     cf_format=no
4200     cf_inboth=no
4201     ;;
4202   esac
4203
4204 test ! -d man && mkdir man
4205
4206 cf_so_strip=
4207 cf_compress=
4208 case "$MANPAGE_FORMAT" in #(vi
4209 *compress*) #(vi
4210         cf_so_strip="Z"
4211         cf_compress=compress
4212   ;;
4213 *gzip*)
4214         cf_so_strip="gz"
4215         cf_compress=gzip
4216   ;;
4217 esac
4218
4219 cf_edit_man=./edit_man.sh
4220 cf_man_alias=`pwd`/man_alias.sed
4221
4222 cat >$cf_edit_man <<CF_EOF
4223 #! /bin/sh
4224 # this script is generated by the configure-script CF_MAN_PAGES macro.
4225
4226 prefix="$cf_prefix"
4227 datarootdir="$datarootdir"
4228 datadir="$datadir"
4229
4230 NCURSES_MAJOR="$NCURSES_MAJOR"
4231 NCURSES_MINOR="$NCURSES_MINOR"
4232 NCURSES_PATCH="$NCURSES_PATCH"
4233
4234 NCURSES_OSPEED="$NCURSES_OSPEED"
4235 TERMINFO="$TERMINFO"
4236
4237 INSTALL="$INSTALL"
4238 INSTALL_DATA="$INSTALL_DATA"
4239
4240 transform="$program_transform_name"
4241
4242 TMP=\${TMPDIR:=/tmp}/man\$\$
4243 trap "rm -f \$TMP" 0 1 2 5 15
4244
4245 form=\[$]1
4246 shift || exit 1
4247
4248 verb=\[$]1
4249 shift || exit 1
4250
4251 mandir=\[$]1
4252 shift || exit 1
4253
4254 srcdir=\[$]1
4255 top_srcdir=\[$]srcdir/..
4256 shift || exit 1
4257
4258 if test "\$form" = normal ; then
4259         if test "$cf_format" = yes ; then
4260         if test "$cf_inboth" = no ; then
4261                 sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4262                 exit $?
4263         fi
4264         fi
4265         cf_subdir=\$mandir/man
4266         cf_tables=$MANPAGE_TBL
4267 else
4268         cf_subdir=\$mandir/cat
4269         cf_tables=yes
4270 fi
4271
4272 # process the list of source-files
4273 for i in \[$]* ; do
4274 case \$i in #(vi
4275 *.orig|*.rej) ;; #(vi
4276 *.[[0-9]]*)
4277         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4278         if test \$verb = installing ; then
4279         if test ! -d \$cf_subdir\${section} ; then
4280                 mkdir -p \$cf_subdir\$section
4281         fi
4282         fi
4283
4284         # replace variables in man page
4285         if test ! -f $cf_man_alias ; then
4286 cat >>$cf_man_alias <<-CF_EOF2
4287                 s,@DATADIR@,\$datadir,g
4288                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
4289                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
4290                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
4291                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
4292                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
4293                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
4294 CF_EOF
4295         ifelse($1,,,[
4296         for cf_name in $1
4297         do
4298                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4299                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4300 cat >>$cf_edit_man <<-CF_EOF
4301                 s,@$cf_NAME@,$cf_name,g
4302 CF_EOF
4303         done
4304         ])
4305 cat >>$cf_edit_man <<CF_EOF
4306 CF_EOF2
4307                 echo "...made $cf_man_alias"
4308         fi
4309
4310         aliases=
4311         cf_source=\`basename \$i\`
4312         inalias=\$cf_source
4313         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4314         if test ! -f \$inalias ; then
4315                 echo .. skipped \$cf_source
4316                 continue
4317         fi
4318 CF_EOF
4319
4320 if test "$MANPAGE_ALIASES" != no ; then
4321 cat >>$cf_edit_man <<CF_EOF
4322         nCurses=ignore.3x
4323         test $with_curses_h = yes && nCurses=ncurses.3x
4324         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4325 CF_EOF
4326 fi
4327
4328 if test "$MANPAGE_RENAMES" = no ; then
4329 cat >>$cf_edit_man <<CF_EOF
4330         # perform program transformations for section 1 man pages
4331         if test \$section = 1 ; then
4332                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4333         else
4334                 cf_target=\$cf_subdir\${section}/\$cf_source
4335         fi
4336 CF_EOF
4337 else
4338 cat >>$cf_edit_man <<CF_EOF
4339         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4340         if test -z "\$cf_target" ; then
4341                 echo '? missing rename for '\$cf_source
4342                 cf_target="\$cf_source"
4343         fi
4344         cf_target="\$cf_subdir\${section}/\${cf_target}"
4345
4346 CF_EOF
4347 fi
4348
4349 cat >>$cf_edit_man <<CF_EOF
4350         sed     -f $cf_man_alias \\
4351 CF_EOF
4352
4353 if test -f $MANPAGE_RENAMES ; then
4354 cat >>$cf_edit_man <<CF_EOF
4355                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4356 CF_EOF
4357 else
4358 cat >>$cf_edit_man <<CF_EOF
4359                 < \$i >\$TMP
4360 CF_EOF
4361 fi
4362
4363 cat >>$cf_edit_man <<CF_EOF
4364 if test \$cf_tables = yes ; then
4365         tbl \$TMP >\$TMP.out
4366         mv \$TMP.out \$TMP
4367 fi
4368 CF_EOF
4369
4370 if test $with_overwrite != yes ; then
4371 cat >>$cf_edit_man <<CF_EOF
4372         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4373         mv \$TMP.out \$TMP
4374 CF_EOF
4375 fi
4376
4377 if test $with_curses_h != yes ; then
4378 cat >>$cf_edit_man <<CF_EOF
4379         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4380         mv \$TMP.out \$TMP
4381 CF_EOF
4382 fi
4383
4384 cat >>$cf_edit_man <<CF_EOF
4385         if test \$form = format ; then
4386                 nroff -man \$TMP >\$TMP.out
4387                 mv \$TMP.out \$TMP
4388         fi
4389 CF_EOF
4390
4391 if test -n "$cf_compress" ; then
4392 cat >>$cf_edit_man <<CF_EOF
4393         if test \$verb = installing ; then
4394         if ( $cf_compress -f \$TMP )
4395         then
4396                 mv \$TMP.$cf_so_strip \$TMP
4397         fi
4398         fi
4399         cf_target="\$cf_target.$cf_so_strip"
4400 CF_EOF
4401 fi
4402
4403 case "$MANPAGE_FORMAT" in #(vi
4404 *BSDI*)
4405 cat >>$cf_edit_man <<CF_EOF
4406         if test \$form = format ; then
4407                 # BSDI installs only .0 suffixes in the cat directories
4408                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4409         fi
4410 CF_EOF
4411   ;;
4412 esac
4413
4414 cat >>$cf_edit_man <<CF_EOF
4415         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4416         if test \$verb = installing ; then
4417                 echo \$verb \$cf_target
4418                 \$INSTALL_DATA \$TMP \$cf_target
4419                 test -d \$cf_subdir\${section} &&
4420                 test -n "\$aliases" && (
4421                         cd \$cf_subdir\${section} && (
4422                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4423                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4424                                 cf_target=\`basename \$cf_target\`
4425                                 for cf_alias in \$aliases
4426                                 do
4427                                         if test \$section = 1 ; then
4428                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4429                                         fi
4430
4431                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4432                                                 if test -f \$cf_alias\${suffix} ; then
4433                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4434                                                         then
4435                                                                 continue
4436                                                         fi
4437                                                 fi
4438                                                 echo .. \$verb alias \$cf_alias\${suffix}
4439 CF_EOF
4440 case "x$LN_S" in #(vi
4441 *-f) #(vi
4442 cat >>$cf_edit_man <<CF_EOF
4443                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4444 CF_EOF
4445         ;;
4446 *)
4447 cat >>$cf_edit_man <<CF_EOF
4448                                                 rm -f \$cf_alias\${suffix}
4449                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4450 CF_EOF
4451         ;;
4452 esac
4453 cat >>$cf_edit_man <<CF_EOF
4454                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4455                                                 echo ".so \$cf_source" >\$TMP
4456 CF_EOF
4457 if test -n "$cf_compress" ; then
4458 cat >>$cf_edit_man <<CF_EOF
4459                                                 if test -n "$cf_so_strip" ; then
4460                                                         $cf_compress -f \$TMP
4461                                                         mv \$TMP.$cf_so_strip \$TMP
4462                                                 fi
4463 CF_EOF
4464 fi
4465 cat >>$cf_edit_man <<CF_EOF
4466                                                 echo .. \$verb alias \$cf_alias\${suffix}
4467                                                 rm -f \$cf_alias\${suffix}
4468                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4469                                         fi
4470                                 done
4471                         )
4472                 )
4473         elif test \$verb = removing ; then
4474                 test -f \$cf_target && (
4475                         echo \$verb \$cf_target
4476                         rm -f \$cf_target
4477                 )
4478                 test -d \$cf_subdir\${section} &&
4479                 test -n "\$aliases" && (
4480                         cd \$cf_subdir\${section} && (
4481                                 for cf_alias in \$aliases
4482                                 do
4483                                         if test \$section = 1 ; then
4484                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4485                                         fi
4486
4487                                         echo .. \$verb alias \$cf_alias\${suffix}
4488                                         rm -f \$cf_alias\${suffix}
4489                                 done
4490                         )
4491                 )
4492         else
4493 #               echo ".hy 0"
4494                 cat \$TMP
4495         fi
4496         ;;
4497 esac
4498 done
4499
4500 if test $cf_inboth = yes ; then
4501 if test \$form != format ; then
4502         sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4503 fi
4504 fi
4505
4506 exit 0
4507 CF_EOF
4508 chmod 755 $cf_edit_man
4509
4510 ])dnl
4511 dnl ---------------------------------------------------------------------------
4512 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4513 dnl -----------
4514 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4515 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4516 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4517 AC_DEFUN([CF_MATH_LIB],
4518 [
4519 AC_CACHE_CHECK(if -lm needed for math functions,
4520         cf_cv_need_libm,[
4521         AC_TRY_LINK([
4522         #include <stdio.h>
4523         #include <math.h>
4524         ],
4525         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4526         [cf_cv_need_libm=no],
4527         [cf_cv_need_libm=yes])])
4528 if test "$cf_cv_need_libm" = yes
4529 then
4530 ifelse($1,,[
4531         CF_ADD_LIB(m)
4532 ],[$1=-lm])
4533 fi
4534 ])
4535 dnl ---------------------------------------------------------------------------
4536 dnl CF_MIXEDCASE_FILENAMES version: 4 updated: 2012/10/02 20:55:03
4537 dnl ----------------------
4538 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4539 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4540 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4541 [
4542 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4543 if test "$cross_compiling" = yes ; then
4544         case $target_alias in #(vi
4545         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-mingw32*|*-uwin*) #(vi
4546                 cf_cv_mixedcase=no
4547                 ;;
4548         *)
4549                 cf_cv_mixedcase=yes
4550                 ;;
4551         esac
4552 else
4553         rm -f conftest CONFTEST
4554         echo test >conftest
4555         if test -f CONFTEST ; then
4556                 cf_cv_mixedcase=no
4557         else
4558                 cf_cv_mixedcase=yes
4559         fi
4560         rm -f conftest CONFTEST
4561 fi
4562 ])
4563 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
4564 ])dnl
4565 dnl ---------------------------------------------------------------------------
4566 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
4567 dnl ----------
4568 dnl Check for a working mkstemp.  This creates two files, checks that they are
4569 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4570 AC_DEFUN([CF_MKSTEMP],[
4571 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4572 rm -rf conftest*
4573 AC_TRY_RUN([
4574 #include <sys/types.h>
4575 #include <stdlib.h>
4576 #include <stdio.h>
4577 #include <string.h>
4578 #include <sys/stat.h>
4579 int main()
4580 {
4581         char *tmpl = "conftestXXXXXX";
4582         char name[2][80];
4583         int n;
4584         int result = 0;
4585         int fd;
4586         struct stat sb;
4587
4588         umask(077);
4589         for (n = 0; n < 2; ++n) {
4590                 strcpy(name[n], tmpl);
4591                 if ((fd = mkstemp(name[n])) >= 0) {
4592                         if (!strcmp(name[n], tmpl)
4593                          || stat(name[n], &sb) != 0
4594                          || (sb.st_mode & S_IFMT) != S_IFREG
4595                          || (sb.st_mode & 077) != 0) {
4596                                 result = 1;
4597                         }
4598                         close(fd);
4599                 }
4600         }
4601         if (result == 0
4602          && !strcmp(name[0], name[1]))
4603                 result = 1;
4604         ${cf_cv_main_return:-return}(result);
4605 }
4606 ],[cf_cv_func_mkstemp=yes
4607 ],[cf_cv_func_mkstemp=no
4608 ],[cf_cv_func_mkstemp=maybe])
4609 ])
4610 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
4611         AC_CHECK_FUNC(mkstemp)
4612 fi
4613 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4614         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
4615 fi
4616 ])dnl
4617 dnl ---------------------------------------------------------------------------
4618 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4619 dnl ----------
4620 dnl Write a debug message to config.log, along with the line number in the
4621 dnl configure script.
4622 AC_DEFUN([CF_MSG_LOG],[
4623 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
4624 ])dnl
4625 dnl ---------------------------------------------------------------------------
4626 dnl CF_NCURSES_ABI_6 version: 1 updated: 2005/09/17 18:42:49
4627 dnl ----------------
4628 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
4629 dnl warn about this.
4630 AC_DEFUN([CF_NCURSES_ABI_6],[
4631 if test "${with_abi_version+set}" != set; then
4632         case $cf_cv_rel_version in
4633         5.*)
4634                 cf_cv_rel_version=6.0
4635                 cf_cv_abi_version=6
4636                 AC_MSG_WARN(Overriding ABI version to $cf_cv_abi_version)
4637                 ;;
4638         esac
4639 fi
4640 ])dnl
4641 dnl ---------------------------------------------------------------------------
4642 dnl CF_NO_LEAKS_OPTION version: 5 updated: 2012/10/02 20:55:03
4643 dnl ------------------
4644 dnl see CF_WITH_NO_LEAKS
4645 AC_DEFUN([CF_NO_LEAKS_OPTION],[
4646 AC_MSG_CHECKING(if you want to use $1 for testing)
4647 AC_ARG_WITH($1,
4648         [$2],
4649         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
4650          $4
4651 ])
4652         : ${with_cflags:=-g}
4653         : ${with_no_leaks:=yes}
4654          with_$1=yes],
4655         [with_$1=])
4656 AC_MSG_RESULT(${with_$1:-no})
4657
4658 case .$with_cflags in #(vi
4659 .*-g*)
4660         case .$CFLAGS in #(vi
4661         .*-g*) #(vi
4662                 ;;
4663         *)
4664                 CF_ADD_CFLAGS([-g])
4665                 ;;
4666         esac
4667         ;;
4668 esac
4669 ])dnl
4670 dnl ---------------------------------------------------------------------------
4671 dnl CF_NUMBER_SYNTAX version: 1 updated: 2003/09/20 18:12:49
4672 dnl ----------------
4673 dnl Check if the given variable is a number.  If not, report an error.
4674 dnl $1 is the variable
4675 dnl $2 is the message
4676 AC_DEFUN([CF_NUMBER_SYNTAX],[
4677 if test -n "$1" ; then
4678   case $1 in #(vi
4679   [[0-9]]*) #(vi
4680         ;;
4681   *)
4682         AC_MSG_ERROR($2 is not a number: $1)
4683         ;;
4684   esac
4685 else
4686   AC_MSG_ERROR($2 value is empty)
4687 fi
4688 ])dnl
4689 dnl ---------------------------------------------------------------------------
4690 dnl CF_OBJ_SUBDIR version: 4 updated: 2002/02/23 20:38:31
4691 dnl -------------
4692 dnl Compute the object-directory name from the given model name
4693 AC_DEFUN([CF_OBJ_SUBDIR],
4694 [
4695         case $1 in
4696         libtool) $2='obj_lo'  ;;
4697         normal)  $2='objects' ;;
4698         debug)   $2='obj_g' ;;
4699         profile) $2='obj_p' ;;
4700         shared)
4701                 case $cf_cv_system_name in #(vi
4702                 cygwin) #(vi
4703                         $2='objects' ;;
4704                 *)
4705                         $2='obj_s' ;;
4706                 esac
4707         esac
4708 ])dnl
4709 dnl ---------------------------------------------------------------------------
4710 dnl CF_PATHSEP version: 6 updated: 2012/09/29 18:38:12
4711 dnl ----------
4712 dnl Provide a value for the $PATH and similar separator (or amend the value
4713 dnl as provided in autoconf 2.5x).
4714 AC_DEFUN([CF_PATHSEP],
4715 [
4716         AC_MSG_CHECKING(for PATH separator)
4717         case $cf_cv_system_name in
4718         os2*)   PATH_SEPARATOR=';'  ;;
4719         *)      ${PATH_SEPARATOR:=':'}  ;;
4720         esac
4721 ifelse([$1],,,[$1=$PATH_SEPARATOR])
4722         AC_SUBST(PATH_SEPARATOR)
4723         AC_MSG_RESULT($PATH_SEPARATOR)
4724 ])dnl
4725 dnl ---------------------------------------------------------------------------
4726 dnl CF_PATH_SYNTAX version: 14 updated: 2012/06/19 20:58:54
4727 dnl --------------
4728 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
4729 dnl begins with one of the prefix/exec_prefix variables, and then again if the
4730 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
4731 dnl delayed evaluation of those symbols.
4732 AC_DEFUN([CF_PATH_SYNTAX],[
4733 if test "x$prefix" != xNONE; then
4734   cf_path_syntax="$prefix"
4735 else
4736   cf_path_syntax="$ac_default_prefix"
4737 fi
4738
4739 case ".[$]$1" in #(vi
4740 .\[$]\(*\)*|.\'*\'*) #(vi
4741   ;;
4742 ..|./*|.\\*) #(vi
4743   ;;
4744 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
4745   ;;
4746 .\[$]{*prefix}*|.\[$]{*dir}*) #(vi
4747   eval $1="[$]$1"
4748   case ".[$]$1" in #(vi
4749   .NONE/*)
4750     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4751     ;;
4752   esac
4753   ;; #(vi
4754 .no|.NONE/*)
4755   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4756   ;;
4757 *)
4758   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
4759   ;;
4760 esac
4761 ])dnl
4762 dnl ---------------------------------------------------------------------------
4763 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
4764 dnl -------------
4765 dnl Check for the package-config program, unless disabled by command-line.
4766 AC_DEFUN([CF_PKG_CONFIG],
4767 [
4768 AC_MSG_CHECKING(if you want to use pkg-config)
4769 AC_ARG_WITH(pkg-config,
4770         [  --with-pkg-config{=path} enable/disable use of pkg-config],
4771         [cf_pkg_config=$withval],
4772         [cf_pkg_config=yes])
4773 AC_MSG_RESULT($cf_pkg_config)
4774
4775 case $cf_pkg_config in #(vi
4776 no) #(vi
4777         PKG_CONFIG=none
4778         ;;
4779 yes) #(vi
4780         CF_ACVERSION_CHECK(2.52,
4781                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
4782                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
4783         ;;
4784 *)
4785         PKG_CONFIG=$withval
4786         ;;
4787 esac
4788
4789 test -z "$PKG_CONFIG" && PKG_CONFIG=none
4790 if test "$PKG_CONFIG" != none ; then
4791         CF_PATH_SYNTAX(PKG_CONFIG)
4792 fi
4793
4794 AC_SUBST(PKG_CONFIG)
4795 ])dnl
4796 dnl ---------------------------------------------------------------------------
4797 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
4798 dnl -----------------
4799 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
4800 dnl
4801 dnl     POSIX.1-1990                            _POSIX_SOURCE
4802 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
4803 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
4804 dnl             Bindings Option
4805 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
4806 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
4807 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
4808 dnl
4809 dnl Parameters:
4810 dnl     $1 is the nominal value for _POSIX_C_SOURCE
4811 AC_DEFUN([CF_POSIX_C_SOURCE],
4812 [
4813 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
4814
4815 cf_save_CFLAGS="$CFLAGS"
4816 cf_save_CPPFLAGS="$CPPFLAGS"
4817
4818 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
4819 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
4820
4821 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
4822         CF_MSG_LOG(if the symbol is already defined go no further)
4823         AC_TRY_COMPILE([#include <sys/types.h>],[
4824 #ifndef _POSIX_C_SOURCE
4825 make an error
4826 #endif],
4827         [cf_cv_posix_c_source=no],
4828         [cf_want_posix_source=no
4829          case .$cf_POSIX_C_SOURCE in #(vi
4830          .[[12]]??*) #(vi
4831                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4832                 ;;
4833          .2) #(vi
4834                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4835                 cf_want_posix_source=yes
4836                 ;;
4837          .*)
4838                 cf_want_posix_source=yes
4839                 ;;
4840          esac
4841          if test "$cf_want_posix_source" = yes ; then
4842                 AC_TRY_COMPILE([#include <sys/types.h>],[
4843 #ifdef _POSIX_SOURCE
4844 make an error
4845 #endif],[],
4846                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
4847          fi
4848          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
4849          CFLAGS="$cf_trim_CFLAGS"
4850          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
4851          CF_MSG_LOG(if the second compile does not leave our definition intact error)
4852          AC_TRY_COMPILE([#include <sys/types.h>],[
4853 #ifndef _POSIX_C_SOURCE
4854 make an error
4855 #endif],,
4856          [cf_cv_posix_c_source=no])
4857          CFLAGS="$cf_save_CFLAGS"
4858          CPPFLAGS="$cf_save_CPPFLAGS"
4859         ])
4860 ])
4861
4862 if test "$cf_cv_posix_c_source" != no ; then
4863         CFLAGS="$cf_trim_CFLAGS"
4864         CPPFLAGS="$cf_trim_CPPFLAGS"
4865         CF_ADD_CFLAGS($cf_cv_posix_c_source)
4866 fi
4867
4868 ])dnl
4869 dnl ---------------------------------------------------------------------------
4870 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
4871 dnl ------------
4872 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
4873 dnl
4874 dnl $1 = symbol to test
4875 dnl $2 = value (if any) to use for a predefinition
4876 AC_DEFUN([CF_PREDEFINE],
4877 [
4878 AC_MSG_CHECKING(if we must define $1)
4879 AC_TRY_COMPILE([#include <sys/types.h>
4880 ],[
4881 #ifndef $1
4882 make an error
4883 #endif],[cf_result=no],[cf_result=yes])
4884 AC_MSG_RESULT($cf_result)
4885
4886 if test "$cf_result" = yes ; then
4887         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
4888 elif test "x$2" != "x" ; then
4889         AC_MSG_CHECKING(checking for compatible value versus $2)
4890         AC_TRY_COMPILE([#include <sys/types.h>
4891 ],[
4892 #if $1-$2 < 0
4893 make an error
4894 #endif],[cf_result=yes],[cf_result=no])
4895         AC_MSG_RESULT($cf_result)
4896         if test "$cf_result" = no ; then
4897                 # perhaps we can override it - try...
4898                 CPPFLAGS="$CPPFLAGS -D$1=$2"
4899         fi
4900 fi
4901 ])dnl
4902 dnl ---------------------------------------------------------------------------
4903 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
4904 dnl ------------
4905 dnl Append definitions and rules for the given programs to the subdirectory
4906 dnl Makefiles, and the recursion rule for the top-level Makefile.
4907 dnl
4908 dnl parameters
4909 dnl     $1 = script to run
4910 dnl     $2 = list of subdirectories
4911 dnl
4912 dnl variables
4913 dnl     $AWK
4914 AC_DEFUN([CF_PRG_RULES],
4915 [
4916 for cf_dir in $2
4917 do
4918         if test ! -d $srcdir/$cf_dir; then
4919                 continue
4920         elif test -f $srcdir/$cf_dir/programs; then
4921                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
4922         fi
4923 done
4924
4925 ])dnl
4926 dnl ---------------------------------------------------------------------------
4927 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
4928 dnl ----------
4929 dnl Check for archiver "ar".
4930 AC_DEFUN([CF_PROG_AR],[
4931 AC_CHECK_TOOL(AR, ar, ar)
4932 ])
4933 dnl ---------------------------------------------------------------------------
4934 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
4935 dnl -----------
4936 dnl Check for awk, ensure that the check found something.
4937 AC_DEFUN([CF_PROG_AWK],
4938 [
4939 AC_PROG_AWK
4940 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
4941 ])dnl
4942 dnl ---------------------------------------------------------------------------
4943 dnl CF_PROG_CC version: 3 updated: 2012/10/06 15:31:55
4944 dnl ----------
4945 dnl standard check for CC, plus followup sanity checks
4946 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
4947 AC_DEFUN([CF_PROG_CC],[
4948 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
4949 CF_GCC_VERSION
4950 CF_ACVERSION_CHECK(2.52,
4951         [AC_PROG_CC_STDC],
4952         [CF_ANSI_CC_REQD])
4953 CF_CC_ENV_FLAGS
4954 ])dnl
4955 dnl ---------------------------------------------------------------------------
4956 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
4957 dnl --------------
4958 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
4959 dnl the output file can be renamed, and allows for a shell variable that can
4960 dnl be used later.  The parameter is either CC or CXX.  The result is the
4961 dnl cache variable:
4962 dnl     $cf_cv_prog_CC_c_o
4963 dnl     $cf_cv_prog_CXX_c_o
4964 AC_DEFUN([CF_PROG_CC_C_O],
4965 [AC_REQUIRE([AC_PROG_CC])dnl
4966 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
4967 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
4968 [
4969 cat > conftest.$ac_ext <<CF_EOF
4970 #include <stdio.h>
4971 int main()
4972 {
4973         ${cf_cv_main_return:-return}(0);
4974 }
4975 CF_EOF
4976 # We do the test twice because some compilers refuse to overwrite an
4977 # existing .o file with -o, though they will create one.
4978 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
4979 if AC_TRY_EVAL(ac_try) &&
4980   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
4981 then
4982   eval cf_cv_prog_$1_c_o=yes
4983 else
4984   eval cf_cv_prog_$1_c_o=no
4985 fi
4986 rm -rf conftest*
4987 ])dnl
4988 if test $cf_cv_prog_$1_c_o = yes; then
4989   AC_MSG_RESULT([yes])
4990 else
4991   AC_MSG_RESULT([no])
4992 fi
4993 ])dnl
4994 dnl ---------------------------------------------------------------------------
4995 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
4996 dnl -------------
4997 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
4998 dnl This macro adds a check to ensure the script found something.
4999 AC_DEFUN([CF_PROG_EGREP],
5000 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
5001    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
5002     then ac_cv_prog_egrep='grep -E'
5003     else ac_cv_prog_egrep='egrep'
5004     fi])
5005  EGREP=$ac_cv_prog_egrep
5006  AC_SUBST([EGREP])
5007 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
5008 ])dnl
5009 dnl ---------------------------------------------------------------------------
5010 dnl CF_PROG_GNAT version: 2 updated: 2011/10/22 14:01:47
5011 dnl ------------
5012 dnl Check for gnatmake, ensure that it is complete.
5013 AC_DEFUN([CF_PROG_GNAT],[
5014 cf_ada_make=gnatmake
5015 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
5016 if test "$ac_cv_prog_gnat_exists" = no; then
5017    cf_ada_make=
5018    cf_cv_prog_gnat_correct=no
5019 else
5020    CF_GNAT_VERSION
5021    AC_CHECK_PROG(M4_exists, m4, yes, no)
5022    if test "$ac_cv_prog_M4_exists" = no; then
5023       cf_cv_prog_gnat_correct=no
5024       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
5025    fi
5026    if test "$cf_cv_prog_gnat_correct" = yes; then
5027       AC_MSG_CHECKING(if GNAT works)
5028       CF_GNAT_TRY_RUN([procedure conftest;],
5029 [with Text_IO;
5030 with GNAT.OS_Lib;
5031 procedure conftest is
5032 begin
5033    Text_IO.Put ("Hello World");
5034    Text_IO.New_Line;
5035    GNAT.OS_Lib.OS_Exit (0);
5036 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
5037       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
5038    fi
5039 fi
5040
5041 AC_SUBST(cf_ada_make)
5042 ])dnl
5043 dnl ---------------------------------------------------------------------------
5044 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
5045 dnl ---------------
5046 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
5047 dnl misc/tabset install won't work properly.  Usually this happens only when
5048 dnl using the fallback mkinstalldirs script
5049 AC_DEFUN([CF_PROG_INSTALL],
5050 [AC_PROG_INSTALL
5051 case $INSTALL in
5052 /*)
5053   ;;
5054 *)
5055   CF_DIRNAME(cf_dir,$INSTALL)
5056   test -z "$cf_dir" && cf_dir=.
5057   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
5058   ;;
5059 esac
5060 ])dnl
5061 dnl ---------------------------------------------------------------------------
5062 dnl CF_PROG_LDCONFIG version: 3 updated: 2011/06/04 20:09:13
5063 dnl ----------------
5064 dnl Check for ldconfig, needed to fixup shared libraries that would be built
5065 dnl and then used in the install.
5066 AC_DEFUN([CF_PROG_LDCONFIG],[
5067 if test "$cross_compiling" = yes ; then
5068   LDCONFIG=:
5069 else
5070 case "$cf_cv_system_name" in #(vi
5071 dragonfly*|mirbsd*|freebsd*) #(vi
5072   test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
5073   ;;
5074 *) LDPATH=$PATH:/sbin:/usr/sbin
5075   AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
5076   ;;
5077 esac
5078 fi
5079 AC_SUBST(LDCONFIG)
5080 ])dnl
5081 dnl ---------------------------------------------------------------------------
5082 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
5083 dnl ------------
5084 AC_DEFUN([CF_PROG_LINT],
5085 [
5086 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
5087 AC_SUBST(LINT_OPTS)
5088 ])dnl
5089 dnl ---------------------------------------------------------------------------
5090 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
5091 dnl ------------
5092 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
5093 dnl option if it is supported.
5094 AC_DEFUN([CF_PROG_LN_S],[
5095 AC_PROG_LN_S
5096 AC_MSG_CHECKING(if $LN_S -f options work)
5097
5098 rm -f conf$$.src conf$$dst
5099 echo >conf$$.dst
5100 echo first >conf$$.src
5101 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
5102         cf_prog_ln_sf=yes
5103 else
5104         cf_prog_ln_sf=no
5105 fi
5106 rm -f conf$$.dst conf$$src
5107 AC_MSG_RESULT($cf_prog_ln_sf)
5108
5109 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
5110 ])dnl
5111 dnl ---------------------------------------------------------------------------
5112 dnl CF_REGEX version: 10 updated: 2012/10/04 20:12:20
5113 dnl --------
5114 dnl Attempt to determine if we've got one of the flavors of regular-expression
5115 dnl code that we can support.
5116 AC_DEFUN([CF_REGEX],
5117 [
5118
5119 cf_regex_func=no
5120
5121 cf_regex_libs="regex re"
5122 case $host_os in #(vi
5123 mingw*)
5124         cf_regex_libs="gnurx $cf_regex_libs"
5125         ;;
5126 esac
5127
5128 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5129         for cf_regex_lib in $cf_regex_libs
5130         do
5131                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5132                                 CF_ADD_LIB($cf_regex_lib)
5133                                 cf_regex_func=regcomp
5134                                 break])
5135         done
5136 ])
5137
5138 if test "$cf_regex_func" = no ; then
5139         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5140                 AC_CHECK_LIB(gen,compile,[
5141                                 CF_ADD_LIB(gen)
5142                                 cf_regex_func=compile])])
5143 fi
5144
5145 if test "$cf_regex_func" = no ; then
5146         AC_MSG_WARN(cannot find regular expression library)
5147 fi
5148
5149 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5150
5151 cf_cv_regex_hdrs=no
5152 case $cf_regex_func in #(vi
5153 compile) #(vi
5154         for cf_regex_hdr in regexp.h regexpr.h
5155         do
5156                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5157                         char *p = compile("", "", "", 0);
5158                         int x = step("", "");
5159                 ],[
5160                         cf_cv_regex_hdrs=$cf_regex_hdr
5161                         break
5162                 ])
5163         done
5164         ;;
5165 *)
5166         for cf_regex_hdr in regex.h
5167         do
5168                 AC_TRY_LINK([#include <sys/types.h>
5169 #include <$cf_regex_hdr>],[
5170                         regex_t *p;
5171                         int x = regcomp(p, "", 0);
5172                         int y = regexec(p, "", 0, 0, 0);
5173                         regfree(p);
5174                 ],[
5175                         cf_cv_regex_hdrs=$cf_regex_hdr
5176                         break
5177                 ])
5178         done
5179         ;;
5180 esac
5181
5182 ])
5183
5184 case $cf_cv_regex_hdrs in #(vi
5185     no)        AC_MSG_WARN(no regular expression header found) ;; #(vi
5186     regex.h)   AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;; #(vi
5187     regexp.h)  AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;; #(vi
5188     regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
5189 esac
5190 ])dnl
5191 dnl ---------------------------------------------------------------------------
5192 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5193 dnl ----------------
5194 dnl Remove all -U and -D options that refer to the given symbol from a list
5195 dnl of C compiler options.  This works around the problem that not all
5196 dnl compilers process -U and -D options from left-to-right, so a -U option
5197 dnl cannot be used to cancel the effect of a preceding -D option.
5198 dnl
5199 dnl $1 = target (which could be the same as the source variable)
5200 dnl $2 = source (including '$')
5201 dnl $3 = symbol to remove
5202 define([CF_REMOVE_DEFINE],
5203 [
5204 $1=`echo "$2" | \
5205         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5206                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5207 ])dnl
5208 dnl ---------------------------------------------------------------------------
5209 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5210 dnl -------------
5211 dnl Remove the given library from the symbol
5212 dnl
5213 dnl $1 = target (which could be the same as the source variable)
5214 dnl $2 = source (including '$')
5215 dnl $3 = library to remove
5216 define([CF_REMOVE_LIB],
5217 [
5218 # remove $3 library from $2
5219 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5220 ])dnl
5221 dnl ---------------------------------------------------------------------------
5222 dnl CF_RPATH_HACK version: 9 updated: 2011/02/13 13:31:33
5223 dnl -------------
5224 AC_DEFUN([CF_RPATH_HACK],
5225 [
5226 AC_REQUIRE([CF_LD_RPATH_OPT])
5227 AC_MSG_CHECKING(for updated LDFLAGS)
5228 if test -n "$LD_RPATH_OPT" ; then
5229         AC_MSG_RESULT(maybe)
5230
5231         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5232         cf_rpath_list="/usr/lib /lib"
5233         if test "$cf_ldd_prog" != no
5234         then
5235                 cf_rpath_oops=
5236
5237 AC_TRY_LINK([#include <stdio.h>],
5238                 [printf("Hello");],
5239                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort -u`
5240                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort -u`])
5241
5242                 # If we passed the link-test, but get a "not found" on a given library,
5243                 # this could be due to inept reconfiguration of gcc to make it only
5244                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5245                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5246                 # /usr/local libraries.
5247                 if test -n "$cf_rpath_oops"
5248                 then
5249                         for cf_rpath_src in $cf_rpath_oops
5250                         do
5251                                 for cf_rpath_dir in \
5252                                         /usr/local \
5253                                         /usr/pkg \
5254                                         /opt/sfw
5255                                 do
5256                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5257                                         then
5258                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5259                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5260                                                 break
5261                                         fi
5262                                 done
5263                         done
5264                 fi
5265         fi
5266
5267         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5268
5269         CF_RPATH_HACK_2(LDFLAGS)
5270         CF_RPATH_HACK_2(LIBS)
5271
5272         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5273 fi
5274 AC_SUBST(EXTRA_LDFLAGS)
5275 ])dnl
5276 dnl ---------------------------------------------------------------------------
5277 dnl CF_RPATH_HACK_2 version: 6 updated: 2010/04/17 16:31:24
5278 dnl ---------------
5279 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5280 dnl EXTRA_LDFLAGS for each -L option found.
5281 dnl
5282 dnl $cf_rpath_list contains a list of directories to ignore.
5283 dnl
5284 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5285 dnl      but LIBS often has misplaced -L options.
5286 AC_DEFUN([CF_RPATH_HACK_2],
5287 [
5288 CF_VERBOSE(...checking $1 [$]$1)
5289
5290 cf_rpath_dst=
5291 for cf_rpath_src in [$]$1
5292 do
5293         case $cf_rpath_src in #(vi
5294         -L*) #(vi
5295
5296                 # check if this refers to a directory which we will ignore
5297                 cf_rpath_skip=no
5298                 if test -n "$cf_rpath_list"
5299                 then
5300                         for cf_rpath_item in $cf_rpath_list
5301                         do
5302                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5303                                 then
5304                                         cf_rpath_skip=yes
5305                                         break
5306                                 fi
5307                         done
5308                 fi
5309
5310                 if test "$cf_rpath_skip" = no
5311                 then
5312                         # transform the option
5313                         if test "$LD_RPATH_OPT" = "-R " ; then
5314                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5315                         else
5316                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5317                         fi
5318
5319                         # if we have not already added this, add it now
5320                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5321                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5322                         then
5323                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5324                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5325                         fi
5326                 fi
5327                 ;;
5328         esac
5329         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5330 done
5331 $1=$cf_rpath_dst
5332
5333 CF_VERBOSE(...checked $1 [$]$1)
5334 AC_SUBST(EXTRA_LDFLAGS)
5335 ])dnl
5336 dnl ---------------------------------------------------------------------------
5337 dnl CF_SHARED_OPTS version: 73 updated: 2013/06/15 12:17:19
5338 dnl --------------
5339 dnl --------------
5340 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5341 dnl library.
5342 dnl
5343 dnl Note: ${LOCAL_LDFLAGS} is used to link executables that will run within the
5344 dnl build-tree, i.e., by making use of the libraries that are compiled in ../lib
5345 dnl We avoid compiling-in a ../lib path for the shared library since that can
5346 dnl lead to unexpected results at runtime.
5347 dnl ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared libraries
5348 dnl are compiled in ../../lib
5349 dnl
5350 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5351 dnl to install symbolic links to the rel/abi versions of shared libraries.
5352 dnl
5353 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5354 dnl version when making symbolic links.
5355 dnl
5356 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5357 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5358 dnl (ex: libncurses.so.<ver>).
5359 dnl
5360 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5361 AC_DEFUN([CF_SHARED_OPTS],
5362 [
5363         AC_REQUIRE([CF_LD_RPATH_OPT])
5364         LOCAL_LDFLAGS=
5365         LOCAL_LDFLAGS2=
5366         LD_SHARED_OPTS=
5367         INSTALL_LIB="-m 644"
5368
5369         cf_cv_do_symlinks=no
5370         cf_ld_rpath_opt=
5371         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5372
5373         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5374         AC_ARG_WITH(shlib-version,
5375         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5376         [test -z "$withval" && withval=auto
5377         case $withval in #(vi
5378         yes) #(vi
5379                 cf_cv_shlib_version=auto
5380                 ;;
5381         rel|abi|auto|no) #(vi
5382                 cf_cv_shlib_version=$withval
5383                 ;;
5384         *)
5385                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
5386                 ;;
5387         esac
5388         ],[cf_cv_shlib_version=auto])
5389         AC_MSG_RESULT($cf_cv_shlib_version)
5390
5391         cf_cv_rm_so_locs=no
5392         cf_try_cflags=
5393
5394         # Some less-capable ports of gcc support only -fpic
5395         CC_SHARED_OPTS=
5396         if test "$GCC" = yes
5397         then
5398                 AC_MSG_CHECKING(which $CC option to use)
5399                 cf_save_CFLAGS="$CFLAGS"
5400                 for CC_SHARED_OPTS in -fPIC -fpic ''
5401                 do
5402                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5403                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5404                 done
5405                 AC_MSG_RESULT($CC_SHARED_OPTS)
5406                 CFLAGS="$cf_save_CFLAGS"
5407         fi
5408
5409         cf_cv_shlib_version_infix=no
5410
5411         case $cf_cv_system_name in #(vi
5412         aix4.[3-9]*|aix[[5-7]]*) #(vi
5413                 if test "$GCC" = yes; then
5414                         CC_SHARED_OPTS=
5415                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5416                 else
5417                         # CC_SHARED_OPTS='-qpic=large -G'
5418                         # perhaps "-bM:SRE -bnoentry -bexpall"
5419                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5420                 fi
5421                 ;;
5422         beos*) #(vi
5423                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5424                 ;;
5425         cygwin*) #(vi
5426                 CC_SHARED_OPTS=
5427                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5428                 cf_cv_shlib_version=cygdll
5429                 cf_cv_shlib_version_infix=cygdll
5430                 cat >mk_shared_lib.sh <<-CF_EOF
5431                 #!/bin/sh
5432                 SHARED_LIB=\[$]1
5433                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5434                 shift
5435                 cat <<-EOF
5436                 Linking shared library
5437                 ** SHARED_LIB \[$]SHARED_LIB
5438                 ** IMPORT_LIB \[$]IMPORT_LIB
5439 EOF
5440                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
5441 CF_EOF
5442                 chmod +x mk_shared_lib.sh
5443                 ;;
5444         darwin*) #(vi
5445                 cf_try_cflags="no-cpp-precomp"
5446                 CC_SHARED_OPTS="-dynamic"
5447                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5448                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5449                 cf_cv_shlib_version_infix=yes
5450                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5451                         cf_save_LDFLAGS=$LDFLAGS
5452                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5453                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5454                                 LDFLAGS=$cf_save_LDFLAGS])
5455                 if test $cf_cv_ldflags_search_paths_first = yes; then
5456                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5457                 fi
5458                 ;;
5459         hpux[[7-8]]*) #(vi
5460                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
5461                 if test "$GCC" != yes; then
5462                         CC_SHARED_OPTS='+Z'
5463                 fi
5464                 MK_SHARED_LIB='${LD} -b -o $[@]'
5465                 INSTALL_LIB="-m 555"
5466                 ;;
5467         hpux*) #(vi
5468                 # (tested with gcc 2.7.2 -- I don't have c89)
5469                 if test "$GCC" = yes; then
5470                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5471                 else
5472                         CC_SHARED_OPTS='+Z'
5473                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5474                 fi
5475                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5476                 # HP-UX shared libraries must be executable, and should be
5477                 # readonly to exploit a quirk in the memory manager.
5478                 INSTALL_LIB="-m 555"
5479                 ;;
5480         interix*)
5481                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5482                 if test "$cf_cv_shlib_version" = rel; then
5483                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5484                 else
5485                         cf_shared_soname='`basename $@`'
5486                 fi
5487                 CC_SHARED_OPTS=
5488                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5489                 ;;
5490         irix*) #(vi
5491                 if test "$cf_cv_enable_rpath" = yes ; then
5492                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5493                 fi
5494                 # tested with IRIX 5.2 and 'cc'.
5495                 if test "$GCC" != yes; then
5496                         CC_SHARED_OPTS='-KPIC'
5497                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5498                 else
5499                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5500                 fi
5501                 cf_cv_rm_so_locs=yes
5502                 ;;
5503         linux*|gnu*|k*bsd*-gnu) #(vi
5504                 if test "$DFT_LWR_MODEL" = "shared" ; then
5505                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5506                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5507                 fi
5508                 if test "$cf_cv_enable_rpath" = yes ; then
5509                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5510                 fi
5511                 CF_SHARED_SONAME
5512                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5513                 ;;
5514         mingw*) #(vi
5515                 cf_cv_shlib_version=mingw
5516                 cf_cv_shlib_version_infix=mingw
5517                 CC_SHARED_OPTS=
5518                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5519                 #MK_SHARED_LIB='${CC} ${CFLAGS} -mdll -Wl,-soname,'$cf_cv_shared_soname',-stats -o $[@]'
5520                 #MK_SHARED_LIB='${DLLTOOL} --export-all-symbols --output-exp --output-lib $[@]'
5521                 cat >mk_shared_lib.sh <<-CF_EOF
5522                 #!/bin/sh
5523                 SHARED_LIB=\[$]1
5524                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5525                 shift
5526                 cat <<-EOF
5527                 Linking shared library
5528                 ** SHARED_LIB \[$]SHARED_LIB
5529                 ** IMPORT_LIB \[$]IMPORT_LIB
5530 EOF
5531                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
5532 CF_EOF
5533                 chmod +x mk_shared_lib.sh
5534                 ;;
5535         openbsd[[2-9]].*|mirbsd*) #(vi
5536                 if test "$DFT_LWR_MODEL" = "shared" ; then
5537                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5538                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5539                 fi
5540                 if test "$cf_cv_enable_rpath" = yes ; then
5541                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5542                 fi
5543                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5544                 CF_SHARED_SONAME
5545                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5546                 ;;
5547         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
5548                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5549                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5550                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5551                 ;;
5552         dragonfly*|freebsd*) #(vi
5553                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5554                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5555                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5556                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
5557                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5558                 fi
5559                 CF_SHARED_SONAME
5560                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
5561                 ;;
5562         netbsd*) #(vi
5563                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5564                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5565                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5566                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5567                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5568                         if test "$cf_cv_shlib_version" = auto; then
5569                         if test -f /usr/libexec/ld.elf_so; then
5570                                 cf_cv_shlib_version=abi
5571                         else
5572                                 cf_cv_shlib_version=rel
5573                         fi
5574                         fi
5575                         CF_SHARED_SONAME
5576                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
5577                 else
5578                         MK_SHARED_LIB='${LD} -shared -Bshareable -o $[@]'
5579                 fi
5580                 ;;
5581         osf*|mls+*) #(vi
5582                 # tested with OSF/1 V3.2 and 'cc'
5583                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
5584                 # link with shared libs).
5585                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
5586                 case $host_os in #(vi
5587                 osf4*)
5588                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
5589                         ;;
5590                 esac
5591                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
5592                 if test "$DFT_LWR_MODEL" = "shared" ; then
5593                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5594                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5595                 fi
5596                 cf_cv_rm_so_locs=yes
5597                 ;;
5598         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
5599                 # tested with osr5.0.5
5600                 if test "$GCC" != yes; then
5601                         CC_SHARED_OPTS='-belf -KPIC'
5602                 fi
5603                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
5604                 if test "$cf_cv_enable_rpath" = yes ; then
5605                         # only way is to set LD_RUN_PATH but no switch for it
5606                         RUN_PATH=$libdir
5607                 fi
5608                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5609                 LINK_PROGS='LD_RUN_PATH=${libdir}'
5610                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
5611                 ;;
5612         sunos4*) #(vi
5613                 # tested with SunOS 4.1.1 and gcc 2.7.0
5614                 if test "$GCC" != yes; then
5615                         CC_SHARED_OPTS='-KPIC'
5616                 fi
5617                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
5618                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5619                 ;;
5620         solaris2*) #(vi
5621                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
5622                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
5623                 if test "$DFT_LWR_MODEL" = "shared" ; then
5624                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
5625                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5626                 fi
5627                 if test "$cf_cv_enable_rpath" = yes ; then
5628                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
5629                 fi
5630                 CF_SHARED_SONAME
5631                 if test "$GCC" != yes; then
5632                         cf_save_CFLAGS="$CFLAGS"
5633                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
5634                         do
5635                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
5636                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
5637                         done
5638                         CFLAGS="$cf_save_CFLAGS"
5639                         CC_SHARED_OPTS=$cf_shared_opts
5640                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5641                 else
5642                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5643                 fi
5644                 ;;
5645         sysv5uw7*|unix_sv*) #(vi
5646                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
5647                 if test "$GCC" != yes; then
5648                         CC_SHARED_OPTS='-KPIC'
5649                 fi
5650                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
5651                 ;;
5652         *)
5653                 CC_SHARED_OPTS='unknown'
5654                 MK_SHARED_LIB='echo unknown'
5655                 ;;
5656         esac
5657
5658         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
5659         case "$cf_cv_shlib_version" in #(vi
5660         rel|abi)
5661                 case "$MK_SHARED_LIB" in #(vi
5662                 *'-o $[@]') #(vi
5663                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
5664                         ;;
5665                 *)
5666                         AC_MSG_WARN(ignored --with-shlib-version)
5667                         ;;
5668                 esac
5669                 ;;
5670         esac
5671
5672         if test -n "$cf_try_cflags"
5673         then
5674 cat > conftest.$ac_ext <<EOF
5675 #line __oline__ "${as_me:-configure}"
5676 #include <stdio.h>
5677 int main(int argc, char *argv[[]])
5678 {
5679         printf("hello\n");
5680         return (argv[[argc-1]] == 0) ;
5681 }
5682 EOF
5683                 cf_save_CFLAGS="$CFLAGS"
5684                 for cf_opt in $cf_try_cflags
5685                 do
5686                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
5687                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
5688                         if AC_TRY_EVAL(ac_compile); then
5689                                 AC_MSG_RESULT(yes)
5690                                 cf_save_CFLAGS="$CFLAGS"
5691                         else
5692                                 AC_MSG_RESULT(no)
5693                         fi
5694                 done
5695                 CFLAGS="$cf_save_CFLAGS"
5696         fi
5697
5698
5699         # RPATH_LIST is a colon-separated list of directories
5700         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
5701         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
5702
5703         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
5704         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
5705
5706         AC_SUBST(CC_SHARED_OPTS)
5707         AC_SUBST(LD_RPATH_OPT)
5708         AC_SUBST(LD_SHARED_OPTS)
5709         AC_SUBST(MK_SHARED_LIB)
5710         AC_SUBST(LINK_PROGS)
5711         AC_SUBST(LINK_TESTS)
5712         AC_SUBST(EXTRA_LDFLAGS)
5713         AC_SUBST(LOCAL_LDFLAGS)
5714         AC_SUBST(LOCAL_LDFLAGS2)
5715         AC_SUBST(INSTALL_LIB)
5716         AC_SUBST(RPATH_LIST)
5717 ])dnl
5718 dnl ---------------------------------------------------------------------------
5719 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
5720 dnl ----------------
5721 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
5722 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
5723 dnl option.
5724 dnl
5725 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
5726 dnl If missing, use "rel".
5727 define([CF_SHARED_SONAME],
5728 [
5729         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
5730         if test "$cf_cv_shlib_version" = rel; then
5731                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
5732         else
5733                 cf_cv_shared_soname='`basename $[@]`'
5734         fi
5735 ])
5736 dnl ---------------------------------------------------------------------------
5737 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
5738 dnl -----------
5739 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
5740 dnl programs need this test).
5741 dnl
5742 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
5743 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
5744 dnl winsize declaration is left alone - we may revisit this if Apple choose to
5745 dnl break that part of the interface as well.
5746 AC_DEFUN([CF_SIGWINCH],
5747 [
5748 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
5749         AC_TRY_COMPILE([
5750 #include <sys/types.h>
5751 #include <sys/signal.h>
5752 ],[int x = SIGWINCH],
5753         [cf_cv_define_sigwinch=yes],
5754         [AC_TRY_COMPILE([
5755 #undef _XOPEN_SOURCE
5756 #undef _POSIX_SOURCE
5757 #undef _POSIX_C_SOURCE
5758 #include <sys/types.h>
5759 #include <sys/signal.h>
5760 ],[int x = SIGWINCH],
5761         [cf_cv_define_sigwinch=maybe],
5762         [cf_cv_define_sigwinch=no])
5763 ])
5764 ])
5765
5766 if test "$cf_cv_define_sigwinch" = maybe ; then
5767 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
5768 cf_cv_fixup_sigwinch=unknown
5769 cf_sigwinch=32
5770 while test $cf_sigwinch != 1
5771 do
5772         AC_TRY_COMPILE([
5773 #undef _XOPEN_SOURCE
5774 #undef _POSIX_SOURCE
5775 #undef _POSIX_C_SOURCE
5776 #include <sys/types.h>
5777 #include <sys/signal.h>
5778 ],[
5779 #if SIGWINCH != $cf_sigwinch
5780 make an error
5781 #endif
5782 int x = SIGWINCH],
5783         [cf_cv_fixup_sigwinch=$cf_sigwinch
5784          break])
5785
5786 cf_sigwinch=`expr $cf_sigwinch - 1`
5787 done
5788 ])
5789
5790         if test "$cf_cv_fixup_sigwinch" != unknown ; then
5791                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
5792         fi
5793 fi
5794 ])dnl
5795 dnl ---------------------------------------------------------------------------
5796 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
5797 dnl ---------------
5798 dnl signal handler, but there are some gcc depedencies in that recommendation.
5799 dnl Try anyway.
5800 AC_DEFUN([CF_SIG_ATOMIC_T],
5801 [
5802 AC_MSG_CHECKING(for signal global datatype)
5803 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
5804         for cf_type in \
5805                 "volatile sig_atomic_t" \
5806                 "sig_atomic_t" \
5807                 "int"
5808         do
5809         AC_TRY_COMPILE([
5810 #include <sys/types.h>
5811 #include <signal.h>
5812 #include <stdio.h>
5813
5814 extern $cf_type x;
5815 $cf_type x;
5816 static void handler(int sig)
5817 {
5818         x = 5;
5819 }],
5820                 [signal(SIGINT, handler);
5821                  x = 1],
5822                 [cf_cv_sig_atomic_t=$cf_type],
5823                 [cf_cv_sig_atomic_t=no])
5824                 test "$cf_cv_sig_atomic_t" != no && break
5825         done
5826         ])
5827 AC_MSG_RESULT($cf_cv_sig_atomic_t)
5828 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
5829 ])dnl
5830 dnl ---------------------------------------------------------------------------
5831 dnl CF_SIZECHANGE version: 9 updated: 2012/10/06 11:17:15
5832 dnl -------------
5833 dnl Check for definitions & structures needed for window size-changing
5834 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
5835 AC_DEFUN([CF_SIZECHANGE],
5836 [
5837 AC_REQUIRE([CF_STRUCT_TERMIOS])
5838 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
5839     cf_cv_sizechange=unknown
5840     cf_save_CPPFLAGS="$CPPFLAGS"
5841
5842 for cf_opts in "" "NEED_PTEM_H"
5843 do
5844
5845     CPPFLAGS="$cf_save_CPPFLAGS"
5846     test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
5847     AC_TRY_COMPILE([#include <sys/types.h>
5848 #ifdef HAVE_TERMIOS_H
5849 #include <termios.h>
5850 #else
5851 #ifdef HAVE_TERMIO_H
5852 #include <termio.h>
5853 #endif
5854 #endif
5855 #ifdef NEED_PTEM_H
5856 /* This is a workaround for SCO:  they neglected to define struct winsize in
5857  * termios.h -- it's only in termio.h and ptem.h
5858  */
5859 #include        <sys/stream.h>
5860 #include        <sys/ptem.h>
5861 #endif
5862 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
5863 #include <sys/ioctl.h>
5864 #endif
5865 ],[
5866 #ifdef TIOCGSIZE
5867         struct ttysize win;     /* FIXME: what system is this? */
5868         int y = win.ts_lines;
5869         int x = win.ts_cols;
5870 #else
5871 #ifdef TIOCGWINSZ
5872         struct winsize win;
5873         int y = win.ws_row;
5874         int x = win.ws_col;
5875 #else
5876         no TIOCGSIZE or TIOCGWINSZ
5877 #endif /* TIOCGWINSZ */
5878 #endif /* TIOCGSIZE */
5879         ],
5880         [cf_cv_sizechange=yes],
5881         [cf_cv_sizechange=no])
5882
5883         CPPFLAGS="$cf_save_CPPFLAGS"
5884         if test "$cf_cv_sizechange" = yes ; then
5885                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
5886                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
5887                 break
5888         fi
5889 done
5890 ])
5891 if test "$cf_cv_sizechange" != no ; then
5892         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechar declarations are provided])
5893         case $cf_cv_sizechange in #(vi
5894         NEED*)
5895                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
5896                 ;;
5897         esac
5898 fi
5899 ])dnl
5900 dnl ---------------------------------------------------------------------------
5901 dnl CF_SRC_MODULES version: 26 updated: 2012/01/07 15:08:24
5902 dnl --------------
5903 dnl For each parameter, test if the source-directory exists, and if it contains
5904 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
5905 dnl use in CF_LIB_RULES.
5906 dnl
5907 dnl This uses the configured value to make the lists SRC_SUBDIRS and
5908 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
5909 AC_DEFUN([CF_SRC_MODULES],
5910 [
5911 AC_MSG_CHECKING(for src modules)
5912
5913 # dependencies and linker-arguments for test-programs
5914 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
5915 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
5916 if test "$DFT_LWR_MODEL" = "libtool"; then
5917         TEST_ARGS="${TEST_DEPS}"
5918         TEST_ARG2="${TEST_DEP2}"
5919 else
5920         TEST_ARGS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
5921         TEST_ARG2="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARG2"
5922 fi
5923
5924 PC_MODULES_TO_MAKE="ncurses${DFT_ARG_SUFFIX}"
5925 cf_cv_src_modules=
5926 for cf_dir in $1
5927 do
5928         if test -f $srcdir/$cf_dir/modules; then
5929
5930                 # We may/may not have tack in the distribution, though the
5931                 # makefile is.
5932                 if test $cf_dir = tack ; then
5933                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
5934                                 continue
5935                         fi
5936                 fi
5937
5938                 if test -z "$cf_cv_src_modules"; then
5939                         cf_cv_src_modules=$cf_dir
5940                 else
5941                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
5942                 fi
5943
5944                 # Make the ncurses_cfg.h file record the library interface files as
5945                 # well.  These are header files that are the same name as their
5946                 # directory.  Ncurses is the only library that does not follow
5947                 # that pattern.
5948                 if test $cf_dir = tack ; then
5949                         continue
5950                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
5951                         CF_UPPER(cf_have_include,$cf_dir)
5952                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
5953                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
5954                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
5955                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
5956                         if test "$DFT_LWR_MODEL" = "libtool"; then
5957                                 TEST_ARGS="${TEST_DEPS}"
5958                                 TEST_ARG2="${TEST_DEP2}"
5959                         else
5960                                 TEST_ARGS="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARGS"
5961                                 TEST_ARG2="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARG2"
5962                         fi
5963                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${DFT_ARG_SUFFIX}"
5964                 fi
5965         fi
5966 done
5967 AC_MSG_RESULT($cf_cv_src_modules)
5968
5969 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
5970 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
5971
5972 AC_SUBST(TEST_ARGS)
5973 AC_SUBST(TEST_DEPS)
5974
5975 AC_SUBST(TEST_ARG2)
5976 AC_SUBST(TEST_DEP2)
5977
5978 SRC_SUBDIRS=
5979 if test "x$cf_with_manpages" != xno ; then
5980         SRC_SUBDIRS="$SRC_SUBDIRS man"
5981 fi
5982 SRC_SUBDIRS="$SRC_SUBDIRS include"
5983 for cf_dir in $cf_cv_src_modules
5984 do
5985         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
5986 done
5987 if test "x$cf_with_tests" != "xno" ; then
5988         SRC_SUBDIRS="$SRC_SUBDIRS test"
5989 fi
5990 test -z "$MAKE_TERMINFO" && SRC_SUBDIRS="$SRC_SUBDIRS misc"
5991 if test "$cf_with_cxx_binding" != no; then
5992         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${DFT_ARG_SUFFIX}"
5993         SRC_SUBDIRS="$SRC_SUBDIRS c++"
5994 fi
5995
5996 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
5997 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
5998
5999 AC_SUBST(PC_MODULES_TO_MAKE)
6000
6001 ADA_SUBDIRS=
6002 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
6003         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
6004         ADA_SUBDIRS="gen src"
6005         if test "x$cf_with_tests" != "xno" ; then
6006                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
6007         fi
6008 fi
6009
6010 SUB_MAKEFILES=
6011 for cf_dir in $SRC_SUBDIRS
6012 do
6013         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
6014 done
6015
6016 if test -n "$ADA_SUBDIRS"; then
6017         for cf_dir in $ADA_SUBDIRS
6018         do
6019                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
6020         done
6021         AC_SUBST(ADA_SUBDIRS)
6022 fi
6023 ])dnl
6024 dnl ---------------------------------------------------------------------------
6025 dnl CF_STDCPP_LIBRARY version: 7 updated: 2010/05/29 16:31:02
6026 dnl -----------------
6027 dnl Check for -lstdc++, which is GNU's standard C++ library.
6028 AC_DEFUN([CF_STDCPP_LIBRARY],
6029 [
6030 if test -n "$GXX" ; then
6031 case $cf_cv_system_name in #(vi
6032 os2*) #(vi
6033         cf_stdcpp_libname=stdcpp
6034         ;;
6035 *)
6036         cf_stdcpp_libname=stdc++
6037         ;;
6038 esac
6039 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
6040         cf_save="$LIBS"
6041         CF_ADD_LIB($cf_stdcpp_libname)
6042 AC_TRY_LINK([
6043 #include <strstream.h>],[
6044 char buf[80];
6045 strstreambuf foo(buf, sizeof(buf))
6046 ],
6047         [cf_cv_libstdcpp=yes],
6048         [cf_cv_libstdcpp=no])
6049         LIBS="$cf_save"
6050 ])
6051 test "$cf_cv_libstdcpp" = yes && CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS)
6052 fi
6053 ])dnl
6054 dnl ---------------------------------------------------------------------------
6055 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
6056 dnl --------------
6057 dnl     Remove "-g" option from the compiler options
6058 AC_DEFUN([CF_STRIP_G_OPT],
6059 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
6060 dnl ---------------------------------------------------------------------------
6061 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
6062 dnl -------------------
6063 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
6064 dnl do this if we've found the sigaction function.
6065 AC_DEFUN([CF_STRUCT_SIGACTION],[
6066 AC_REQUIRE([CF_XOPEN_SOURCE])
6067
6068 if test "$ac_cv_func_sigaction" = yes; then
6069 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
6070 AC_TRY_COMPILE([
6071 #include <sys/types.h>
6072 #include <signal.h>],
6073         [struct sigaction act],
6074         [sigact_bad=no],
6075         [
6076 AC_TRY_COMPILE([
6077 #define _POSIX_SOURCE
6078 #include <sys/types.h>
6079 #include <signal.h>],
6080         [struct sigaction act],
6081         [sigact_bad=yes
6082          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
6083          [sigact_bad=unknown])])
6084 AC_MSG_RESULT($sigact_bad)
6085 fi
6086 ])dnl
6087 dnl ---------------------------------------------------------------------------
6088 dnl CF_STRUCT_TERMIOS version: 7 updated: 2012/10/06 17:56:13
6089 dnl -----------------
6090 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
6091 AC_DEFUN([CF_STRUCT_TERMIOS],[
6092 AC_REQUIRE([CF_XOPEN_SOURCE])
6093
6094 AC_CHECK_HEADERS( \
6095 termio.h \
6096 termios.h \
6097 unistd.h \
6098 )
6099
6100 if test "$ISC" = yes ; then
6101         AC_CHECK_HEADERS( sys/termio.h )
6102 fi
6103 if test "$ac_cv_header_termios_h" = yes ; then
6104         case "$CFLAGS $CPPFLAGS" in
6105         *-D_POSIX_SOURCE*)
6106                 termios_bad=dunno ;;
6107         *)      termios_bad=maybe ;;
6108         esac
6109         if test "$termios_bad" = maybe ; then
6110         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
6111         AC_TRY_COMPILE([#include <termios.h>],
6112                 [struct termios foo; int x = foo.c_iflag],
6113                 termios_bad=no, [
6114                 AC_TRY_COMPILE([
6115 #define _POSIX_SOURCE
6116 #include <termios.h>],
6117                         [struct termios foo; int x = foo.c_iflag],
6118                         termios_bad=unknown,
6119                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
6120                         ])
6121         AC_MSG_RESULT($termios_bad)
6122         fi
6123 fi
6124 ])dnl
6125 dnl ---------------------------------------------------------------------------
6126 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
6127 dnl --------------
6128 dnl Construct a search-list for a nonstandard header/lib-file
6129 dnl     $1 = the variable to return as result
6130 dnl     $2 = the package name
6131 dnl     $3 = the subdirectory, e.g., bin, include or lib
6132 AC_DEFUN([CF_SUBDIR_PATH],
6133 [
6134 $1=
6135
6136 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
6137 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
6138 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
6139 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
6140 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
6141 ])dnl
6142 dnl ---------------------------------------------------------------------------
6143 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
6144 dnl -----------
6145 dnl     Shorthand macro for substituting things that the user may override
6146 dnl     with an environment variable.
6147 dnl
6148 dnl     $1 = condition to pass to "test"
6149 dnl     $2 = environment variable
6150 dnl     $3 = value if the test succeeds
6151 dnl     $4 = value if the test fails
6152 AC_DEFUN([CF_SUBST_IF],
6153 [
6154 if test $1 ; then
6155         $2=$3
6156 ifelse($4,,,[else
6157         $2=$4])
6158 fi
6159 AC_SUBST($2)
6160 ])dnl
6161 dnl ---------------------------------------------------------------------------
6162 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
6163 dnl ------------------------
6164 dnl Get the version-number for use in shared-library naming, etc.
6165 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
6166 [
6167 AC_REQUIRE([CF_PROG_EGREP])
6168 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6169 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6170 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6171 cf_cv_abi_version=${NCURSES_MAJOR}
6172 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
6173 dnl Show the computed version, for logging
6174 cf_cv_timestamp=`date`
6175 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
6176 dnl We need these values in the generated headers
6177 AC_SUBST(NCURSES_MAJOR)
6178 AC_SUBST(NCURSES_MINOR)
6179 AC_SUBST(NCURSES_PATCH)
6180 dnl We need these values in the generated makefiles
6181 AC_SUBST(cf_cv_rel_version)
6182 AC_SUBST(cf_cv_abi_version)
6183 AC_SUBST(cf_cv_builtin_bool)
6184 AC_SUBST(cf_cv_header_stdbool_h)
6185 AC_SUBST(cf_cv_type_of_bool)dnl
6186 ])dnl
6187 dnl ---------------------------------------------------------------------------
6188 dnl CF_SYS_TIME_SELECT version: 5 updated: 2012/10/04 05:24:07
6189 dnl ------------------
6190 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6191 dnl older SCO configurations.
6192 AC_DEFUN([CF_SYS_TIME_SELECT],
6193 [
6194 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6195 AC_CACHE_VAL(cf_cv_sys_time_select,[
6196 AC_TRY_COMPILE([
6197 #include <sys/types.h>
6198 #ifdef HAVE_SYS_TIME_H
6199 #include <sys/time.h>
6200 #endif
6201 #ifdef HAVE_SYS_SELECT_H
6202 #include <sys/select.h>
6203 #endif
6204 ],[],[cf_cv_sys_time_select=yes],
6205      [cf_cv_sys_time_select=no])
6206      ])
6207 AC_MSG_RESULT($cf_cv_sys_time_select)
6208 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
6209 ])dnl
6210 dnl ---------------------------------------------------------------------------
6211 dnl CF_TOP_BUILDDIR version: 1 updated: 2006/10/15 16:33:23
6212 dnl ---------------
6213 dnl Define a top_builddir symbol, for applications that need an absolute path.
6214 AC_DEFUN([CF_TOP_BUILDDIR],
6215 [
6216 top_builddir=`pwd`
6217 AC_SUBST(top_builddir)
6218 ])dnl
6219 dnl ---------------------------------------------------------------------------
6220 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6221 dnl -------------------
6222 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6223 dnl can define it successfully.
6224 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6225 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6226         AC_TRY_COMPILE([
6227 #include <stdlib.h>
6228 #include <string.h>
6229 #include <sys/types.h>
6230 ],[
6231 #ifndef _XOPEN_SOURCE
6232 make an error
6233 #endif],
6234         [cf_cv_xopen_source=no],
6235         [cf_save="$CPPFLAGS"
6236          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6237          AC_TRY_COMPILE([
6238 #include <stdlib.h>
6239 #include <string.h>
6240 #include <sys/types.h>
6241 ],[
6242 #ifdef _XOPEN_SOURCE
6243 make an error
6244 #endif],
6245         [cf_cv_xopen_source=no],
6246         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6247         CPPFLAGS="$cf_save"
6248         ])
6249 ])
6250
6251 if test "$cf_cv_xopen_source" != no ; then
6252         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6253         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6254         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6255         CF_ADD_CFLAGS($cf_temp_xopen_source)
6256 fi
6257 ])
6258 dnl ---------------------------------------------------------------------------
6259 dnl CF_TYPEOF_CHTYPE version: 9 updated: 2012/10/06 17:56:13
6260 dnl ----------------
6261 dnl Determine the type we should use for chtype (and attr_t, which is treated
6262 dnl as the same thing).  We want around 32 bits, so on most machines want a
6263 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6264 dnl wide characters, we have to have a type compatible with that, as well.
6265 AC_DEFUN([CF_TYPEOF_CHTYPE],
6266 [
6267 AC_MSG_CHECKING([for type of chtype])
6268 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6269                 AC_TRY_RUN([
6270 #define WANT_BITS 31
6271 #include <stdio.h>
6272 int main()
6273 {
6274         FILE *fp = fopen("cf_test.out", "w");
6275         if (fp != 0) {
6276                 char *result = "long";
6277                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6278                         int n;
6279                         unsigned int x, y;
6280                         for (n = 0; n < WANT_BITS; n++) {
6281                                 x = (1 << n);
6282                                 y = (x >> n);
6283                                 if (y != 1 || x == 0) {
6284                                         x = 0;
6285                                         break;
6286                                 }
6287                         }
6288                         /*
6289                          * If x is nonzero, an int is big enough for the bits
6290                          * that we want.
6291                          */
6292                         result = (x != 0) ? "int" : "long";
6293                 }
6294                 fputs(result, fp);
6295                 fclose(fp);
6296         }
6297         ${cf_cv_main_return:-return}(0);
6298 }
6299                 ],
6300                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6301                 [cf_cv_typeof_chtype=long],
6302                 [cf_cv_typeof_chtype=long])
6303                 rm -f cf_test.out
6304         ])
6305 AC_MSG_RESULT($cf_cv_typeof_chtype)
6306
6307 AC_SUBST(cf_cv_typeof_chtype)
6308 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
6309 ])dnl
6310 dnl ---------------------------------------------------------------------------
6311 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
6312 dnl -----------------
6313 dnl
6314 AC_DEFUN([CF_TYPE_SIGACTION],
6315 [
6316 AC_MSG_CHECKING([for type sigaction_t])
6317 AC_CACHE_VAL(cf_cv_type_sigaction,[
6318         AC_TRY_COMPILE([
6319 #include <signal.h>],
6320                 [sigaction_t x],
6321                 [cf_cv_type_sigaction=yes],
6322                 [cf_cv_type_sigaction=no])])
6323 AC_MSG_RESULT($cf_cv_type_sigaction)
6324 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
6325 ])dnl
6326 dnl ---------------------------------------------------------------------------
6327 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6328 dnl --------------------
6329 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6330 dnl won't, but they're still there.
6331 AC_DEFUN([CF_UNSIGNED_LITERALS],
6332 [
6333 AC_MSG_CHECKING([if unsigned literals are legal])
6334 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6335         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6336                 [cf_cv_unsigned_literals=yes],
6337                 [cf_cv_unsigned_literals=no])
6338         ])
6339 AC_MSG_RESULT($cf_cv_unsigned_literals)
6340 ])dnl
6341 dnl ---------------------------------------------------------------------------
6342 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6343 dnl --------
6344 dnl Make an uppercase version of a variable
6345 dnl $1=uppercase($2)
6346 AC_DEFUN([CF_UPPER],
6347 [
6348 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6349 ])dnl
6350 dnl ---------------------------------------------------------------------------
6351 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
6352 dnl -----------
6353 dnl Check for multibyte support, and if not found, utf8 compatibility library
6354 AC_DEFUN([CF_UTF8_LIB],
6355 [
6356 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6357         cf_save_LIBS="$LIBS"
6358         AC_TRY_LINK([
6359 #include <stdlib.h>],[putwc(0,0);],
6360         [cf_cv_utf8_lib=yes],
6361         [CF_FIND_LINKAGE([
6362 #include <libutf8.h>],[putwc(0,0);],utf8,
6363                 [cf_cv_utf8_lib=add-on],
6364                 [cf_cv_utf8_lib=no])
6365 ])])
6366
6367 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6368 # ncurses/ncursesw:
6369 if test "$cf_cv_utf8_lib" = "add-on" ; then
6370         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
6371         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6372         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6373         CF_ADD_LIBS($cf_cv_library_file_utf8)
6374 fi
6375 ])dnl
6376 dnl ---------------------------------------------------------------------------
6377 dnl CF_VA_COPY version: 3 updated: 2012/10/06 11:17:15
6378 dnl ----------
6379 dnl check for va_copy, part of stdarg.h
6380 dnl Also, workaround for glibc's __va_copy, by checking for both.
6381 AC_DEFUN([CF_VA_COPY],[
6382 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6383 AC_TRY_LINK([
6384 #include <stdarg.h>
6385 ],[
6386         static va_list dst;
6387         static va_list src;
6388         va_copy(dst, src)],
6389         cf_cv_have_va_copy=yes,
6390         cf_cv_have_va_copy=no)])
6391
6392 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
6393
6394 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6395 AC_TRY_LINK([
6396 #include <stdarg.h>
6397 ],[
6398         static va_list dst;
6399         static va_list src;
6400         __va_copy(dst, src)],
6401         cf_cv_have___va_copy=yes,
6402         cf_cv_have___va_copy=no)])
6403
6404 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
6405 ])
6406 dnl ---------------------------------------------------------------------------
6407 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6408 dnl ----------
6409 dnl Use AC_VERBOSE w/o the warnings
6410 AC_DEFUN([CF_VERBOSE],
6411 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6412 CF_MSG_LOG([$1])
6413 ])dnl
6414 dnl ---------------------------------------------------------------------------
6415 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
6416 dnl -------------
6417 dnl Check if type wide-character type $1 is declared, and if so, which header
6418 dnl file is needed.  The second parameter is used to set a shell variable when
6419 dnl the type is not found.  The first parameter sets a shell variable for the
6420 dnl opposite sense.
6421 AC_DEFUN([CF_WCHAR_TYPE],
6422 [
6423 # This is needed on Tru64 5.0 to declare $1
6424 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6425 AC_TRY_COMPILE([
6426 #include <stdlib.h>
6427 #include <stdarg.h>
6428 #include <stdio.h>
6429 #ifdef HAVE_LIBUTF8_H
6430 #include <libutf8.h>
6431 #endif],
6432         [$1 state],
6433         [cf_cv_$1=no],
6434         [AC_TRY_COMPILE([
6435 #include <stdlib.h>
6436 #include <stdarg.h>
6437 #include <stdio.h>
6438 #include <wchar.h>
6439 #ifdef HAVE_LIBUTF8_H
6440 #include <libutf8.h>
6441 #endif],
6442         [$1 value],
6443         [cf_cv_$1=yes],
6444         [cf_cv_$1=unknown])])])
6445
6446 if test "$cf_cv_$1" = yes ; then
6447         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
6448         NEED_WCHAR_H=1
6449 fi
6450
6451 ifelse([$2],,,[
6452 # if we do not find $1 in either place, use substitution to provide a fallback.
6453 if test "$cf_cv_$1" = unknown ; then
6454         $2=1
6455 fi
6456 ])
6457 ifelse($3,,,[
6458 # if we find $1 in either place, use substitution to provide a fallback.
6459 if test "$cf_cv_$1" != unknown ; then
6460         $3=1
6461 fi
6462 ])
6463 ])dnl
6464 dnl ---------------------------------------------------------------------------
6465 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
6466 dnl ---------------
6467 dnl Check for compiler-support for weak symbols.
6468 dnl This works with "recent" gcc.
6469 AC_DEFUN([CF_WEAK_SYMBOLS],[
6470 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
6471
6472 AC_TRY_COMPILE([
6473 #include <stdio.h>],
6474 [
6475 #if defined(__GNUC__)
6476 #  if defined __USE_ISOC99
6477 #    define _cat_pragma(exp)    _Pragma(#exp)
6478 #    define _weak_pragma(exp)   _cat_pragma(weak name)
6479 #  else
6480 #    define _weak_pragma(exp)
6481 #  endif
6482 #  define _declare(name)        __extension__ extern __typeof__(name) name
6483 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
6484 #endif
6485
6486 weak_symbol(fopen);
6487 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
6488 ])
6489 ])dnl
6490 dnl ---------------------------------------------------------------------------
6491 dnl CF_WITH_ABI_VERSION version: 1 updated: 2003/09/20 18:12:49
6492 dnl -------------------
6493 dnl Allow library's ABI to be overridden.  Generally this happens when a
6494 dnl packager has incremented the ABI past that used in the original package,
6495 dnl and wishes to keep doing this.
6496 dnl
6497 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6498 dnl symbol.
6499 AC_DEFUN([CF_WITH_ABI_VERSION],[
6500 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
6501 AC_ARG_WITH(abi-version,
6502 [  --with-abi-version=XXX  override derived ABI version],
6503 [AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
6504  cf_cv_abi_version=$withval])
6505  CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
6506 ifelse($1,,,[
6507 $1_ABI=$cf_cv_abi_version
6508 ])
6509 ])dnl
6510 dnl ---------------------------------------------------------------------------
6511 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
6512 dnl --------------------
6513 dnl Command-line option to specify the Ada95 compiler.
6514 AC_DEFUN([CF_WITH_ADA_COMPILER],[
6515 AC_MSG_CHECKING(for ada-compiler)
6516 AC_ARG_WITH(ada-compiler,
6517         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
6518         [cf_ada_compiler=$withval],
6519         [cf_ada_compiler=gnatmake])
6520 AC_SUBST(cf_ada_compiler)
6521 AC_MSG_RESULT($cf_ada_compiler)
6522 ])dnl
6523 dnl ---------------------------------------------------------------------------
6524 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
6525 dnl -------------------
6526 dnl Command-line option to specify where Ada includes will install.
6527 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
6528 AC_MSG_CHECKING(for ada-include)
6529 CF_WITH_PATH(ada-include,
6530    [  --with-ada-include=DIR  Ada includes are in DIR],
6531    ADA_INCLUDE,
6532    PREFIX/share/ada/adainclude,
6533    [$]prefix/share/ada/adainclude)
6534 AC_SUBST(ADA_INCLUDE)
6535 AC_MSG_RESULT($ADA_INCLUDE)
6536 ])dnl
6537 dnl ---------------------------------------------------------------------------
6538 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
6539 dnl -------------------
6540 dnl Command-line option to specify where Ada objects will install.
6541 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
6542 AC_MSG_CHECKING(for ada-objects)
6543 CF_WITH_PATH(ada-objects,
6544    [  --with-ada-objects=DIR  Ada objects are in DIR],
6545    ADA_OBJECTS,
6546    PREFIX/lib/ada/adalib,
6547    [$]prefix/lib/ada/adalib)
6548 AC_SUBST(ADA_OBJECTS)
6549 AC_MSG_RESULT($ADA_OBJECTS)
6550 ])dnl
6551 dnl ---------------------------------------------------------------------------
6552 dnl CF_WITH_ADA_SHAREDLIB version: 2 updated: 2010/06/26 17:35:58
6553 dnl ---------------------
6554 dnl Command-line option to specify if an Ada95 shared-library should be built,
6555 dnl and optionally what its soname should be.
6556 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
6557 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
6558 AC_ARG_WITH(ada-sharedlib,
6559         [  --with-ada-sharedlib=XX build Ada95 shared-library],
6560         [with_ada_sharedlib=$withval],
6561         [with_ada_sharedlib=no])
6562 AC_MSG_RESULT($with_ada_sharedlib)
6563
6564 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
6565 MAKE_ADA_SHAREDLIB="#"
6566
6567 if test "x$with_ada_sharedlib" != xno
6568 then
6569         MAKE_ADA_SHAREDLIB=
6570         if test "x$with_ada_sharedlib" != xyes
6571         then
6572                 ADA_SHAREDLIB="$with_ada_sharedlib"
6573         fi
6574 fi
6575
6576 AC_SUBST(ADA_SHAREDLIB)
6577 AC_SUBST(MAKE_ADA_SHAREDLIB)
6578 ])dnl
6579 dnl ---------------------------------------------------------------------------
6580 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
6581 dnl ----------------
6582 dnl Configure-option for dbmalloc.  The optional parameter is used to override
6583 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6584 AC_DEFUN([CF_WITH_DBMALLOC],[
6585 CF_NO_LEAKS_OPTION(dbmalloc,
6586         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
6587         [USE_DBMALLOC])
6588
6589 if test "$with_dbmalloc" = yes ; then
6590         AC_CHECK_HEADER(dbmalloc.h,
6591                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
6592 fi
6593 ])dnl
6594 dnl ---------------------------------------------------------------------------
6595 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
6596 dnl ---------------
6597 dnl Configure-option for dmalloc.  The optional parameter is used to override
6598 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6599 AC_DEFUN([CF_WITH_DMALLOC],[
6600 CF_NO_LEAKS_OPTION(dmalloc,
6601         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
6602         [USE_DMALLOC])
6603
6604 if test "$with_dmalloc" = yes ; then
6605         AC_CHECK_HEADER(dmalloc.h,
6606                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
6607 fi
6608 ])dnl
6609 dnl ---------------------------------------------------------------------------
6610 dnl CF_WITH_GPM version: 8 updated: 2012/10/06 17:56:13
6611 dnl -----------
6612 dnl
6613 dnl The option parameter (if neither yes/no) is assumed to be the name of
6614 dnl the gpm library, e.g., for dynamic loading.
6615 AC_DEFUN([CF_WITH_GPM],
6616 [
6617 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
6618 AC_ARG_WITH(gpm,
6619         [  --with-gpm              use Alessandro Rubini's GPM library],
6620         [with_gpm=$withval],
6621         [with_gpm=maybe])
6622 AC_MSG_RESULT($with_gpm)
6623
6624 if test "$with_gpm" != no ; then
6625         AC_CHECK_HEADER(gpm.h,[
6626                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
6627                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
6628                         CF_VERBOSE(assuming we really have GPM library)
6629                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
6630                 else
6631                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
6632                                 AC_MSG_ERROR(Cannot link with GPM library)
6633                 fi
6634                 with_gpm=yes
6635                 ])
6636         ],[
6637                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
6638                 with_gpm=no
6639         ])
6640 fi
6641 ])
6642 dnl ---------------------------------------------------------------------------
6643 dnl CF_WITH_LIBTOOL version: 29 updated: 2013/04/06 18:03:09
6644 dnl ---------------
6645 dnl Provide a configure option to incorporate libtool.  Define several useful
6646 dnl symbols for the makefile rules.
6647 dnl
6648 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
6649 dnl macros from libtool.m4 which is in the aclocal directory of automake.
6650 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
6651 dnl But that still does not work properly since the macro is expanded outside
6652 dnl the CF_WITH_LIBTOOL macro:
6653 dnl
6654 dnl     #!/bin/sh
6655 dnl     ACLOCAL=`aclocal --print-ac-dir`
6656 dnl     if test -z "$ACLOCAL" ; then
6657 dnl             echo cannot find aclocal directory
6658 dnl             exit 1
6659 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
6660 dnl             echo cannot find libtool.m4 file
6661 dnl             exit 1
6662 dnl     fi
6663 dnl
6664 dnl     LOCAL=aclocal.m4
6665 dnl     ORIG=aclocal.m4.orig
6666 dnl
6667 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
6668 dnl     rm -f $ORIG
6669 dnl     mv $LOCAL $ORIG
6670 dnl
6671 dnl     # sed the LIBTOOL= assignment to omit the current directory?
6672 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
6673 dnl     cat $ORIG >>$LOCAL
6674 dnl
6675 dnl     autoconf-257 $*
6676 dnl
6677 AC_DEFUN([CF_WITH_LIBTOOL],
6678 [
6679 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
6680 ifdef([AC_PROG_LIBTOOL],,[
6681 LIBTOOL=
6682 ])
6683 # common library maintenance symbols that are convenient for libtool scripts:
6684 LIB_CREATE='${AR} -cr'
6685 LIB_OBJECT='${OBJECTS}'
6686 LIB_SUFFIX=.a
6687 LIB_PREP="$RANLIB"
6688
6689 # symbols used to prop libtool up to enable it to determine what it should be
6690 # doing:
6691 LIB_CLEAN=
6692 LIB_COMPILE=
6693 LIB_LINK='${CC}'
6694 LIB_INSTALL=
6695 LIB_UNINSTALL=
6696
6697 AC_MSG_CHECKING(if you want to build libraries with libtool)
6698 AC_ARG_WITH(libtool,
6699         [  --with-libtool          generate libraries with libtool],
6700         [with_libtool=$withval],
6701         [with_libtool=no])
6702 AC_MSG_RESULT($with_libtool)
6703 if test "$with_libtool" != "no"; then
6704 ifdef([AC_PROG_LIBTOOL],[
6705         # missing_content_AC_PROG_LIBTOOL{{
6706         AC_PROG_LIBTOOL
6707         # missing_content_AC_PROG_LIBTOOL}}
6708 ],[
6709         if test "$with_libtool" != "yes" ; then
6710                 CF_PATH_SYNTAX(with_libtool)
6711                 LIBTOOL=$with_libtool
6712         else
6713                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
6714                 CF_LIBTOOL_VERSION
6715                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
6716                 then
6717                         CF_FORGET_TOOL(LIBTOOL)
6718                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
6719                         CF_LIBTOOL_VERSION
6720                 fi
6721         fi
6722         if test -z "$LIBTOOL" ; then
6723                 AC_MSG_ERROR(Cannot find libtool)
6724         fi
6725 ])dnl
6726         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${DESTDIR}${libdir} ${LIBTOOL_VERSION} `cut -f1 ${srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
6727         LIB_OBJECT='${OBJECTS:.o=.lo}'
6728         LIB_SUFFIX=.la
6729         LIB_CLEAN='${LIBTOOL} --mode=clean'
6730         LIB_COMPILE='${LIBTOOL} --mode=compile'
6731         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
6732         LIB_INSTALL='${LIBTOOL} --mode=install'
6733         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
6734         LIB_PREP=:
6735
6736         CF_CHECK_LIBTOOL_VERSION
6737
6738         # special hack to add -no-undefined (which libtool should do for itself)
6739         LT_UNDEF=
6740         case "$cf_cv_system_name" in #(vi
6741         cygwin*|mingw32*|uwin*|aix[[4-7]]) #(vi
6742                 LT_UNDEF=-no-undefined
6743                 ;;
6744         esac
6745         AC_SUBST([LT_UNDEF])
6746
6747         # special hack to add --tag option for C++ compiler
6748         case $cf_cv_libtool_version in #(vi
6749         1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*) #(vi
6750                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
6751                 LIBTOOL="$LIBTOOL --tag=CC"
6752                 ;;
6753         *)
6754                 LIBTOOL_CXX="$LIBTOOL"
6755                 ;;
6756         esac
6757 else
6758         LIBTOOL=""
6759         LIBTOOL_CXX=""
6760 fi
6761
6762 test -z "$LIBTOOL" && ECHO_LT=
6763
6764 AC_SUBST(LIBTOOL)
6765 AC_SUBST(LIBTOOL_CXX)
6766 AC_SUBST(LIBTOOL_OPTS)
6767
6768 AC_SUBST(LIB_CREATE)
6769 AC_SUBST(LIB_OBJECT)
6770 AC_SUBST(LIB_SUFFIX)
6771 AC_SUBST(LIB_PREP)
6772
6773 AC_SUBST(LIB_CLEAN)
6774 AC_SUBST(LIB_COMPILE)
6775 AC_SUBST(LIB_LINK)
6776 AC_SUBST(LIB_INSTALL)
6777 AC_SUBST(LIB_UNINSTALL)
6778
6779 ])dnl
6780 dnl ---------------------------------------------------------------------------
6781 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
6782 dnl ------------------
6783 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
6784 dnl "lib" prefix, e.g., because it used the dll naming convention.
6785 dnl
6786 dnl $1 = variable to set
6787 AC_DEFUN([CF_WITH_LIB_PREFIX],
6788 [
6789 AC_MSG_CHECKING(if you want to have a library-prefix)
6790 AC_ARG_WITH(lib-prefix,
6791         [  --with-lib-prefix       override library-prefix],
6792         [with_lib_prefix=$withval],
6793         [with_lib_prefix=auto])
6794 AC_MSG_RESULT($with_lib_prefix)
6795
6796 if test $with_lib_prefix = auto
6797 then
6798         CF_LIB_PREFIX($1)
6799 elif test $with_lib_prefix = no
6800 then
6801         LIB_PREFIX=
6802 else
6803         LIB_PREFIX=$with_lib_prefix
6804 fi
6805 ])dnl
6806 dnl ---------------------------------------------------------------------------
6807 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
6808 dnl ------------
6809 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
6810 dnl defaulting to yes/no.
6811 dnl
6812 dnl $1 = option name
6813 dnl $2 = help-text
6814 dnl $3 = environment variable to set
6815 dnl $4 = default value, shown in the help-message, must be a constant
6816 dnl $5 = default value, if it's an expression & cannot be in the help-message
6817 dnl
6818 AC_DEFUN([CF_WITH_PATH],
6819 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
6820 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
6821 if ifelse([$5],,true,[test -n "$5"]) ; then
6822 CF_PATH_SYNTAX(withval)
6823 fi
6824 eval $3="$withval"
6825 AC_SUBST($3)dnl
6826 ])dnl
6827 dnl ---------------------------------------------------------------------------
6828 dnl CF_WITH_PATHLIST version: 9 updated: 2012/10/18 05:05:24
6829 dnl ----------------
6830 dnl Process an option specifying a list of colon-separated paths.
6831 dnl
6832 dnl $1 = option name
6833 dnl $2 = help-text
6834 dnl $3 = environment variable to set
6835 dnl $4 = default value, shown in the help-message, must be a constant
6836 dnl $5 = default value, if it's an expression & cannot be in the help-message
6837 dnl $6 = flag to tell if we want to define or substitute
6838 dnl
6839 AC_DEFUN([CF_WITH_PATHLIST],[
6840 AC_REQUIRE([CF_PATHSEP])
6841 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
6842 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
6843
6844 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
6845 cf_dst_path=
6846 for cf_src_path in $withval
6847 do
6848   CF_PATH_SYNTAX(cf_src_path)
6849   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
6850   cf_dst_path="${cf_dst_path}${cf_src_path}"
6851 done
6852 IFS="$ac_save_ifs"
6853
6854 ifelse($6,define,[
6855 # Strip single quotes from the value, e.g., when it was supplied as a literal
6856 # for $4 or $5.
6857 case $cf_dst_path in #(vi
6858 \'*)
6859   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
6860   ;;
6861 esac
6862 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
6863 ])
6864
6865 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
6866 # so we have to check/work around.  We do prefer the result of "eval"...
6867 eval cf_dst_eval="$cf_dst_path"
6868 case "x$cf_dst_eval" in #(vi
6869 xNONE*) #(vi
6870         $3=$cf_dst_path
6871         ;;
6872 *)
6873         $3="$cf_dst_eval"
6874         ;;
6875 esac
6876 AC_SUBST($3)dnl
6877
6878 ])dnl
6879 dnl ---------------------------------------------------------------------------
6880 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 2 updated: 2011/12/10 18:58:47
6881 dnl -------------------------
6882 dnl Allow the choice of the pkg-config library directory to be overridden.
6883 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
6884 if test "$PKG_CONFIG" != none ; then
6885         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
6886         AC_ARG_WITH(pkg-config-libdir,
6887                 [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
6888                 [PKG_CONFIG_LIBDIR=$withval],
6889                 [PKG_CONFIG_LIBDIR=yes])
6890
6891         case x$PKG_CONFIG_LIBDIR in #(vi
6892         x/*) #(vi
6893                 ;;
6894         xyes) #(vi
6895                 # look for the library directory using the same prefix as the executable
6896                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
6897                 case x`(arch) 2>/dev/null` in #(vi
6898                 *64) #(vi
6899                         for cf_config in $cf_path/share $cf_path/lib64 $cf_path/lib32 $cf_path/lib
6900                         do
6901                                 if test -d $cf_config/pkgconfig
6902                                 then
6903                                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
6904                                         break
6905                                 fi
6906                         done
6907                         ;;
6908                 *)
6909                         PKG_CONFIG_LIBDIR=$cf_path/lib/pkgconfig
6910                         ;;
6911                 esac
6912                 ;;
6913         *)
6914                 ;;
6915         esac
6916
6917         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
6918 fi
6919
6920 AC_SUBST(PKG_CONFIG_LIBDIR)
6921 ])dnl
6922 dnl ---------------------------------------------------------------------------
6923 dnl CF_WITH_PTHREAD version: 6 updated: 2012/10/06 17:41:51
6924 dnl ---------------
6925 dnl Check for POSIX thread library.
6926 AC_DEFUN([CF_WITH_PTHREAD],
6927 [
6928 AC_MSG_CHECKING(if you want to link with the pthread library)
6929 AC_ARG_WITH(pthread,
6930     [  --with-pthread          use POSIX thread library],
6931     [with_pthread=$withval],
6932     [with_pthread=no])
6933 AC_MSG_RESULT($with_pthread)
6934
6935 if test "$with_pthread" != no ; then
6936     AC_CHECK_HEADER(pthread.h,[
6937         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
6938
6939         for cf_lib_pthread in pthread c_r
6940         do
6941             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
6942             cf_save_LIBS="$LIBS"
6943             CF_ADD_LIB($cf_lib_pthread)
6944             AC_TRY_LINK([
6945 #include <pthread.h>
6946 ],[
6947                 int rc = pthread_create(0,0,0,0);
6948                 int r2 = pthread_mutexattr_settype(0, 0);
6949 ],[with_pthread=yes],[with_pthread=no])
6950             LIBS="$cf_save_LIBS"
6951             AC_MSG_RESULT($with_pthread)
6952             test "$with_pthread" = yes && break
6953         done
6954
6955         if test "$with_pthread" = yes ; then
6956             CF_ADD_LIB($cf_lib_pthread)
6957             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
6958         else
6959             AC_MSG_ERROR(Cannot link with pthread library)
6960         fi
6961     ])
6962 fi
6963 ])
6964 dnl ---------------------------------------------------------------------------
6965 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
6966 dnl -------------------
6967 dnl Allow library's release-version to be overridden.  Generally this happens when a
6968 dnl packager has incremented the release-version past that used in the original package,
6969 dnl and wishes to keep doing this.
6970 dnl
6971 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
6972 dnl and {package}_MINOR symbols
6973 dnl symbol.
6974 AC_DEFUN([CF_WITH_REL_VERSION],[
6975 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
6976 AC_ARG_WITH(rel-version,
6977 [  --with-rel-version=XXX  override derived release version],
6978 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
6979  cf_cv_rel_version=$withval])
6980 ifelse($1,,[
6981  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
6982 ],[
6983  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
6984  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
6985  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
6986  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
6987 ])
6988 ])dnl
6989 dnl ---------------------------------------------------------------------------
6990 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
6991 dnl ----------------
6992 dnl If we can compile with sysmouse, make it available unless it is not wanted.
6993 AC_DEFUN([CF_WITH_SYSMOUSE],[
6994 # not everyone has "test -c"
6995 if test -c /dev/sysmouse 2>/dev/null ; then
6996 AC_MSG_CHECKING(if you want to use sysmouse)
6997 AC_ARG_WITH(sysmouse,
6998         [  --with-sysmouse         use sysmouse (FreeBSD console)],
6999         [cf_with_sysmouse=$withval],
7000         [cf_with_sysmouse=maybe])
7001         if test "$cf_with_sysmouse" != no ; then
7002         AC_TRY_COMPILE([
7003 #include <osreldate.h>
7004 #if (__FreeBSD_version >= 400017)
7005 #include <sys/consio.h>
7006 #include <sys/fbio.h>
7007 #else
7008 #include <machine/console.h>
7009 #endif
7010 ],[
7011         struct mouse_info the_mouse;
7012         ioctl(0, CONS_MOUSECTL, &the_mouse);
7013 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
7014         fi
7015 AC_MSG_RESULT($cf_with_sysmouse)
7016 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
7017 fi
7018 ])dnl
7019 dnl ---------------------------------------------------------------------------
7020 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
7021 dnl ---------------
7022 dnl For testing, override the derived host system-type which is used to decide
7023 dnl things such as the linker commands used to build shared libraries.  This is
7024 dnl normally chosen automatically based on the type of system which you are
7025 dnl building on.  We use it for testing the configure script.
7026 dnl
7027 dnl This is different from the --host option: it is used only for testing parts
7028 dnl of the configure script which would not be reachable with --host since that
7029 dnl relies on the build environment being real, rather than mocked up.
7030 AC_DEFUN([CF_WITH_SYSTYPE],[
7031 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
7032 AC_ARG_WITH(system-type,
7033         [  --with-system-type=XXX  test: override derived host system-type],
7034 [AC_MSG_WARN(overriding system type to $withval)
7035         cf_cv_system_name=$withval
7036         host_os=$withval
7037 ])
7038 ])dnl
7039 dnl ---------------------------------------------------------------------------
7040 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
7041 dnl ----------------
7042 AC_DEFUN([CF_WITH_VALGRIND],[
7043 CF_NO_LEAKS_OPTION(valgrind,
7044         [  --with-valgrind         test: use valgrind],
7045         [USE_VALGRIND])
7046 ])dnl
7047 dnl ---------------------------------------------------------------------------
7048 dnl CF_XOPEN_SOURCE version: 43 updated: 2013/02/10 10:41:05
7049 dnl ---------------
7050 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
7051 dnl or adapt to the vendor's definitions to get equivalent functionality,
7052 dnl without losing the common non-POSIX features.
7053 dnl
7054 dnl Parameters:
7055 dnl     $1 is the nominal value for _XOPEN_SOURCE
7056 dnl     $2 is the nominal value for _POSIX_C_SOURCE
7057 AC_DEFUN([CF_XOPEN_SOURCE],[
7058 AC_REQUIRE([AC_CANONICAL_HOST])
7059
7060 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
7061 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
7062 cf_xopen_source=
7063
7064 case $host_os in #(vi
7065 aix[[4-7]]*) #(vi
7066         cf_xopen_source="-D_ALL_SOURCE"
7067         ;;
7068 cygwin) #(vi
7069         cf_XOPEN_SOURCE=600
7070         ;;
7071 darwin[[0-8]].*) #(vi
7072         cf_xopen_source="-D_APPLE_C_SOURCE"
7073         ;;
7074 darwin*) #(vi
7075         cf_xopen_source="-D_DARWIN_C_SOURCE"
7076         cf_XOPEN_SOURCE=
7077         ;;
7078 freebsd*|dragonfly*) #(vi
7079         # 5.x headers associate
7080         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
7081         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
7082         cf_POSIX_C_SOURCE=200112L
7083         cf_XOPEN_SOURCE=600
7084         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
7085         ;;
7086 hpux11*) #(vi
7087         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
7088         ;;
7089 hpux*) #(vi
7090         cf_xopen_source="-D_HPUX_SOURCE"
7091         ;;
7092 irix[[56]].*) #(vi
7093         cf_xopen_source="-D_SGI_SOURCE"
7094         cf_XOPEN_SOURCE=
7095         ;;
7096 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
7097         CF_GNU_SOURCE
7098         ;;
7099 mirbsd*) #(vi
7100         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
7101         cf_XOPEN_SOURCE=
7102         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7103         ;;
7104 netbsd*) #(vi
7105         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
7106         ;;
7107 openbsd[[4-9]]*) #(vi
7108         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
7109         cf_xopen_source="-D_BSD_SOURCE"
7110         cf_XOPEN_SOURCE=600
7111         ;;
7112 openbsd*) #(vi
7113         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
7114         ;;
7115 osf[[45]]*) #(vi
7116         cf_xopen_source="-D_OSF_SOURCE"
7117         ;;
7118 nto-qnx*) #(vi
7119         cf_xopen_source="-D_QNX_SOURCE"
7120         ;;
7121 sco*) #(vi
7122         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
7123         ;;
7124 solaris2.*) #(vi
7125         cf_xopen_source="-D__EXTENSIONS__"
7126         ;;
7127 *)
7128         CF_TRY_XOPEN_SOURCE
7129         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7130         ;;
7131 esac
7132
7133 if test -n "$cf_xopen_source" ; then
7134         CF_ADD_CFLAGS($cf_xopen_source)
7135 fi
7136
7137 dnl In anything but the default case, we may have system-specific setting
7138 dnl which is still not guaranteed to provide all of the entrypoints that
7139 dnl _XOPEN_SOURCE would yield.
7140 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
7141         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
7142         AC_TRY_COMPILE([#include <stdlib.h>],[
7143 #ifndef _XOPEN_SOURCE
7144 make an error
7145 #endif],
7146         [cf_XOPEN_SOURCE_set=yes],
7147         [cf_XOPEN_SOURCE_set=no])
7148         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
7149         if test $cf_XOPEN_SOURCE_set = yes
7150         then
7151                 AC_TRY_COMPILE([#include <stdlib.h>],[
7152 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
7153 make an error
7154 #endif],
7155                 [cf_XOPEN_SOURCE_set_ok=yes],
7156                 [cf_XOPEN_SOURCE_set_ok=no])
7157                 if test $cf_XOPEN_SOURCE_set_ok = no
7158                 then
7159                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
7160                 fi
7161         else
7162                 CF_TRY_XOPEN_SOURCE
7163         fi
7164 fi
7165 ])