c7b9e24e1a2651fcb18e14e4afa4a7970c842e90
[ncurses.git] / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2014,2015 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: aclocal.m4,v 1.759 2015/06/27 23:10:38 tom Exp $
32 dnl Macros used in NCURSES auto-configuration script.
33 dnl
34 dnl These macros are maintained separately from NCURSES.  The copyright on
35 dnl this file applies to the aggregation of macros and does not affect use of
36 dnl these macros in other applications.
37 dnl
38 dnl See http://invisible-island.net/autoconf/ for additional information.
39 dnl
40 dnl ---------------------------------------------------------------------------
41 dnl ---------------------------------------------------------------------------
42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
43 dnl -------------------
44 dnl Inserted as requested by gettext 0.10.40
45 dnl File from /usr/share/aclocal
46 dnl codeset.m4
47 dnl ====================
48 dnl serial AM1
49 dnl
50 dnl From Bruno Haible.
51 AC_DEFUN([AM_LANGINFO_CODESET],
52 [
53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
54         [AC_TRY_LINK([#include <langinfo.h>],
55         [char* cs = nl_langinfo(CODESET);],
56         am_cv_langinfo_codeset=yes,
57         am_cv_langinfo_codeset=no)
58         ])
59         if test $am_cv_langinfo_codeset = yes; then
60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
62         fi
63 ])dnl
64 dnl ---------------------------------------------------------------------------
65 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
66 dnl ---------------
67 dnl Provide configure-script defaults for different ncurses ABIs.
68 AC_DEFUN([CF_ABI_DEFAULTS],[
69 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
70 case x$cf_cv_abi_version in
71 (x[[6789]])
72         cf_dft_ext_colors=yes
73         cf_dft_ext_const=yes
74         cf_dft_ext_mouse=yes
75         cf_dft_ext_putwin=yes
76         cf_dft_ext_spfuncs=yes
77         cf_dft_filter_syms=yes
78         cf_dft_chtype=uint32_t
79         cf_dft_mmask_t=uint32_t
80         cf_dft_interop=yes
81         cf_dft_tparm_arg=intptr_t
82         cf_dft_with_lp64=yes
83         ;;
84 (*)
85         cf_dft_ext_colors=no
86         cf_dft_ext_const=no
87         cf_dft_ext_mouse=no
88         cf_dft_ext_putwin=no
89         cf_dft_ext_spfuncs=no
90         cf_dft_filter_syms=no
91         cf_dft_chtype=auto
92         cf_dft_mmask_t=auto
93         cf_dft_interop=no
94         cf_dft_tparm_arg=long
95         cf_dft_with_lp64=no
96         ;;
97 esac
98 ])dnl
99 dnl ---------------------------------------------------------------------------
100 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
101 dnl ------------------
102 dnl Conditionally generate script according to whether we're using a given autoconf.
103 dnl
104 dnl $1 = version to compare against
105 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
106 dnl $3 = code to use if AC_ACVERSION is older than $1.
107 define([CF_ACVERSION_CHECK],
108 [
109 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
110 ifdef([m4_version_compare],
111 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
112 [CF_ACVERSION_COMPARE(
113 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
114 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
115 dnl ---------------------------------------------------------------------------
116 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
117 dnl --------------------
118 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
119 dnl                      MAJOR2, MINOR2, TERNARY2,
120 dnl                      PRINTABLE2, not FOUND, FOUND)
121 define([CF_ACVERSION_COMPARE],
122 [ifelse(builtin([eval], [$2 < $5]), 1,
123 [ifelse([$8], , ,[$8])],
124 [ifelse([$9], , ,[$9])])])dnl
125 dnl ---------------------------------------------------------------------------
126 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
127 dnl -------------------
128 dnl Construct the list of include-options for the C programs in the Ada95
129 dnl binding.
130 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
131 [
132 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
133 if test "$srcdir" != "."; then
134         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
135 fi
136 if test "$GCC" != yes; then
137         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
138 elif test "$includedir" != "/usr/include"; then
139         if test "$includedir" = '${prefix}/include' ; then
140                 if test x$prefix != x/usr ; then
141                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
142                 fi
143         else
144                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
145         fi
146 fi
147 AC_SUBST(ACPPFLAGS)
148 ])dnl
149 dnl ---------------------------------------------------------------------------
150 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
151 dnl ---------------
152 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
153 AC_DEFUN([CF_ADD_ADAFLAGS],[
154         ADAFLAGS="$ADAFLAGS $1"
155         AC_SUBST(ADAFLAGS)
156 ])dnl
157 dnl ---------------------------------------------------------------------------
158 dnl CF_ADD_CFLAGS version: 12 updated: 2015/04/12 15:39:00
159 dnl -------------
160 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
161 dnl The second parameter if given makes this macro verbose.
162 dnl
163 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
164 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
165 dnl confused by the quotes (which require backslashes to keep them usable).
166 AC_DEFUN([CF_ADD_CFLAGS],
167 [
168 cf_fix_cppflags=no
169 cf_new_cflags=
170 cf_new_cppflags=
171 cf_new_extra_cppflags=
172
173 for cf_add_cflags in $1
174 do
175 case $cf_fix_cppflags in
176 (no)
177         case $cf_add_cflags in
178         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
179                 case $cf_add_cflags in
180                 (-D*)
181                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
182
183                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
184                                 && test -z "${cf_tst_cflags}" \
185                                 && cf_fix_cppflags=yes
186
187                         if test $cf_fix_cppflags = yes ; then
188                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
189                                 continue
190                         elif test "${cf_tst_cflags}" = "\"'" ; then
191                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
192                                 continue
193                         fi
194                         ;;
195                 esac
196                 case "$CPPFLAGS" in
197                 (*$cf_add_cflags)
198                         ;;
199                 (*)
200                         case $cf_add_cflags in
201                         (-D*)
202                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
203                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
204                                 ;;
205                         esac
206                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
207                         ;;
208                 esac
209                 ;;
210         (*)
211                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
212                 ;;
213         esac
214         ;;
215 (yes)
216         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
217
218         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
219
220         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
221                 && test -z "${cf_tst_cflags}" \
222                 && cf_fix_cppflags=no
223         ;;
224 esac
225 done
226
227 if test -n "$cf_new_cflags" ; then
228         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
229         CFLAGS="$CFLAGS $cf_new_cflags"
230 fi
231
232 if test -n "$cf_new_cppflags" ; then
233         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
234         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
235 fi
236
237 if test -n "$cf_new_extra_cppflags" ; then
238         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
239         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
240 fi
241
242 AC_SUBST(EXTRA_CPPFLAGS)
243
244 ])dnl
245 dnl ---------------------------------------------------------------------------
246 dnl CF_ADD_INCDIR version: 14 updated: 2015/05/25 20:53:04
247 dnl -------------
248 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
249 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
250 dnl but old versions (and some misinstalled ones) need that.  To make things
251 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
252 dnl the include-path).
253 AC_DEFUN([CF_ADD_INCDIR],
254 [
255 if test -n "$1" ; then
256   for cf_add_incdir in $1
257   do
258         while test $cf_add_incdir != /usr/include
259         do
260           if test -d $cf_add_incdir
261           then
262                 cf_have_incdir=no
263                 if test -n "$CFLAGS$CPPFLAGS" ; then
264                   # a loop is needed to ensure we can add subdirs of existing dirs
265                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
266                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
267                           cf_have_incdir=yes; break
268                         fi
269                   done
270                 fi
271
272                 if test "$cf_have_incdir" = no ; then
273                   if test "$cf_add_incdir" = /usr/local/include ; then
274                         if test "$GCC" = yes
275                         then
276                           cf_save_CPPFLAGS=$CPPFLAGS
277                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
278                           AC_TRY_COMPILE([#include <stdio.h>],
279                                   [printf("Hello")],
280                                   [],
281                                   [cf_have_incdir=yes])
282                           CPPFLAGS=$cf_save_CPPFLAGS
283                         fi
284                   fi
285                 fi
286
287                 if test "$cf_have_incdir" = no ; then
288                   CF_VERBOSE(adding $cf_add_incdir to include-path)
289                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
290
291                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
292                   test "$cf_top_incdir" = "$cf_add_incdir" && break
293                   cf_add_incdir="$cf_top_incdir"
294                 else
295                   break
296                 fi
297           else
298                 break
299           fi
300         done
301   done
302 fi
303 ])dnl
304 dnl ---------------------------------------------------------------------------
305 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
306 dnl ----------
307 dnl Add a library, used to enforce consistency.
308 dnl
309 dnl $1 = library to add, without the "-l"
310 dnl $2 = variable to update (default $LIBS)
311 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
312 dnl ---------------------------------------------------------------------------
313 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
314 dnl -------------
315 dnl     Adds to the library-path
316 dnl
317 dnl     Some machines have trouble with multiple -L options.
318 dnl
319 dnl $1 is the (list of) directory(s) to add
320 dnl $2 is the optional name of the variable to update (default LDFLAGS)
321 dnl
322 AC_DEFUN([CF_ADD_LIBDIR],
323 [
324 if test -n "$1" ; then
325         for cf_add_libdir in $1
326         do
327                 if test $cf_add_libdir = /usr/lib ; then
328                         :
329                 elif test -d $cf_add_libdir
330                 then
331                         cf_have_libdir=no
332                         if test -n "$LDFLAGS$LIBS" ; then
333                                 # a loop is needed to ensure we can add subdirs of existing dirs
334                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
335                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
336                                                 cf_have_libdir=yes; break
337                                         fi
338                                 done
339                         fi
340                         if test "$cf_have_libdir" = no ; then
341                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
342                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
343                         fi
344                 fi
345         done
346 fi
347 ])dnl
348 dnl ---------------------------------------------------------------------------
349 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
350 dnl -----------
351 dnl Add one or more libraries, used to enforce consistency.  Libraries are
352 dnl prepended to an existing list, since their dependencies are assumed to
353 dnl already exist in the list.
354 dnl
355 dnl $1 = libraries to add, with the "-l", etc.
356 dnl $2 = variable to update (default $LIBS)
357 AC_DEFUN([CF_ADD_LIBS],[
358 cf_add_libs="$1"
359 # Filter out duplicates - this happens with badly-designed ".pc" files...
360 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
361 do
362         for cf_add_2lib in $cf_add_libs
363         do
364                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
365                 then
366                         cf_add_1lib=
367                         break
368                 fi
369         done
370         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
371 done
372 ifelse($2,,LIBS,[$2])="$cf_add_libs"
373 ])dnl
374 dnl ---------------------------------------------------------------------------
375 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
376 dnl ------------------
377 dnl Append to a search-list for a nonstandard header/lib-file
378 dnl     $1 = the variable to return as result
379 dnl     $2 = the package name
380 dnl     $3 = the subdirectory, e.g., bin, include or lib
381 dnl $4 = the directory under which we will test for subdirectories
382 dnl $5 = a directory that we do not want $4 to match
383 AC_DEFUN([CF_ADD_SUBDIR_PATH],
384 [
385 test "x$4" != "x$5" && \
386 test -d "$4" && \
387 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
388         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
389         test -d $4/$3 &&          $1="[$]$1 $4/$3"
390         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
391         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
392         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
393         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
394 }
395 ])dnl
396 dnl ---------------------------------------------------------------------------
397 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
398 dnl --------------
399 dnl Allow user to disable a normally-on option.
400 AC_DEFUN([CF_ARG_DISABLE],
401 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
402 dnl ---------------------------------------------------------------------------
403 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
404 dnl -------------
405 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
406 dnl values.
407 dnl
408 dnl Parameters:
409 dnl $1 = option name
410 dnl $2 = help-string
411 dnl $3 = action to perform if option is not default
412 dnl $4 = action if perform if option is default
413 dnl $5 = default option value (either 'yes' or 'no')
414 AC_DEFUN([CF_ARG_OPTION],
415 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
416         if test "$enableval" != "$5" ; then
417 ifelse([$3],,[    :]dnl
418 ,[    $3]) ifelse([$4],,,[
419         else
420                 $4])
421         fi],[enableval=$5 ifelse([$4],,,[
422         $4
423 ])dnl
424 ])])dnl
425 dnl ---------------------------------------------------------------------------
426 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
427 dnl -----------
428 dnl Check for suitable "ar" (archiver) options for updating an archive.
429 AC_DEFUN([CF_AR_FLAGS],[
430 AC_REQUIRE([CF_PROG_AR])
431
432 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
433         cf_cv_ar_flags=unknown
434         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
435         do
436
437                 # check if $ARFLAGS already contains this choice
438                 if test "x$ARFLAGS" != "x" ; then
439                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
440                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
441                                 cf_cv_ar_flags=
442                                 break
443                         fi
444                 fi
445
446                 rm -f conftest.$ac_cv_objext
447                 rm -f conftest.a
448
449                 cat >conftest.$ac_ext <<EOF
450 #line __oline__ "configure"
451 int     testdata[[3]] = { 123, 456, 789 };
452 EOF
453                 if AC_TRY_EVAL(ac_compile) ; then
454                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
455                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
456                         if test -f conftest.a ; then
457                                 cf_cv_ar_flags=$cf_ar_flags
458                                 break
459                         fi
460                 else
461                         CF_VERBOSE(cannot compile test-program)
462                         break
463                 fi
464         done
465         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
466 ])
467
468 if test -n "$ARFLAGS" ; then
469         if test -n "$cf_cv_ar_flags" ; then
470                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
471         fi
472 else
473         ARFLAGS=$cf_cv_ar_flags
474 fi
475
476 AC_SUBST(ARFLAGS)
477 ])
478 dnl ---------------------------------------------------------------------------
479 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
480 dnl -----------------
481 dnl Check if awk can handle big strings using printf.  Some older versions of
482 dnl awk choke on large strings passed via "%s".
483 dnl
484 dnl $1 = desired string size
485 dnl $2 = variable to set with result
486 AC_DEFUN([CF_AWK_BIG_PRINTF],
487 [
488         case x$AWK in
489         (x)
490                 eval $2=no
491                 ;;
492         (*)
493                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
494                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
495                         eval $2=yes
496                 else
497                         eval $2=no
498                 fi
499                 ;;
500         esac
501 ])dnl
502 dnl ---------------------------------------------------------------------------
503 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
504 dnl ------------
505 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
506 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
507 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
508 dnl
509 dnl Treat the configuration-variable specially here, since we're directly
510 dnl substituting its value (i.e., 1/0).
511 dnl
512 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
513 AC_DEFUN([CF_BOOL_DECL],
514 [
515 AC_MSG_CHECKING(if we should include stdbool.h)
516
517 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
518         AC_TRY_COMPILE([],[bool foo = false],
519                 [cf_cv_header_stdbool_h=0],
520                 [AC_TRY_COMPILE([
521 #ifndef __BEOS__
522 #include <stdbool.h>
523 #endif
524 ],[bool foo = false],
525                         [cf_cv_header_stdbool_h=1],
526                         [cf_cv_header_stdbool_h=0])])])
527
528 if test "$cf_cv_header_stdbool_h" = 1
529 then    AC_MSG_RESULT(yes)
530 else    AC_MSG_RESULT(no)
531 fi
532
533 AC_MSG_CHECKING([for builtin bool type])
534
535 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
536         AC_TRY_COMPILE([
537 #include <stdio.h>
538 #include <sys/types.h>
539 ],[bool x = false],
540                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
541                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
542         ])
543
544 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
545 then    AC_MSG_RESULT(yes)
546 else    AC_MSG_RESULT(no)
547 fi
548 ])dnl
549 dnl ---------------------------------------------------------------------------
550 dnl CF_BOOL_SIZE version: 14 updated: 2015/04/17 21:13:04
551 dnl ------------
552 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
553 dnl Don't bother looking for bool.h, since it's been deprecated.
554 dnl
555 dnl If the current compiler is C rather than C++, we get the bool definition
556 dnl from <stdbool.h>.
557 AC_DEFUN([CF_BOOL_SIZE],
558 [
559 AC_MSG_CHECKING([for size of bool])
560 AC_CACHE_VAL(cf_cv_type_of_bool,[
561         rm -f cf_test.out
562         AC_TRY_RUN([
563 #include <stdlib.h>
564 #include <stdio.h>
565
566 #if defined(__cplusplus)
567
568 #ifdef HAVE_GXX_BUILTIN_H
569 #include <g++/builtin.h>
570 #elif HAVE_GPP_BUILTIN_H
571 #include <gpp/builtin.h>
572 #elif HAVE_BUILTIN_H
573 #include <builtin.h>
574 #endif
575
576 #else
577
578 #if $cf_cv_header_stdbool_h
579 #include <stdbool.h>
580 #endif
581
582 #endif
583
584 int main()
585 {
586         FILE *fp = fopen("cf_test.out", "w");
587         if (fp != 0) {
588                 bool x = true;
589                 if ((bool)(-x) >= 0)
590                         fputs("unsigned ", fp);
591                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
592                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
593                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
594                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
595                 fclose(fp);
596         }
597         ${cf_cv_main_return:-return}(0);
598 }
599                 ],
600                 [cf_cv_type_of_bool=`cat cf_test.out`
601                  if test -z "$cf_cv_type_of_bool"; then
602                    cf_cv_type_of_bool=unknown
603                  fi],
604                 [cf_cv_type_of_bool=unknown],
605                 [cf_cv_type_of_bool=unknown])
606         ])
607         rm -f cf_test.out
608 AC_MSG_RESULT($cf_cv_type_of_bool)
609 if test "$cf_cv_type_of_bool" = unknown ; then
610         case .$NCURSES_BOOL in
611         (.auto|.) NCURSES_BOOL=unsigned;;
612         esac
613         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
614         cf_cv_type_of_bool=$NCURSES_BOOL
615 fi
616 ])dnl
617 dnl ---------------------------------------------------------------------------
618 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
619 dnl -----------
620 dnl If we're cross-compiling, allow the user to override the tools and their
621 dnl options.  The configure script is oriented toward identifying the host
622 dnl compiler, etc., but we need a build compiler to generate parts of the
623 dnl source.
624 dnl
625 dnl $1 = default for $CPPFLAGS
626 dnl $2 = default for $LIBS
627 AC_DEFUN([CF_BUILD_CC],[
628 CF_ACVERSION_CHECK(2.52,,
629         [AC_REQUIRE([CF_PROG_EXT])])
630 if test "$cross_compiling" = yes ; then
631
632         # defaults that we might want to override
633         : ${BUILD_CFLAGS:=''}
634         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
635         : ${BUILD_LDFLAGS:=''}
636         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
637         : ${BUILD_EXEEXT:='$x'}
638         : ${BUILD_OBJEXT:='o'}
639
640         AC_ARG_WITH(build-cc,
641                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
642                 [BUILD_CC="$withval"],
643                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
644         AC_MSG_CHECKING(for native build C compiler)
645         AC_MSG_RESULT($BUILD_CC)
646
647         AC_MSG_CHECKING(for native build C preprocessor)
648         AC_ARG_WITH(build-cpp,
649                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
650                 [BUILD_CPP="$withval"],
651                 [BUILD_CPP='${BUILD_CC} -E'])
652         AC_MSG_RESULT($BUILD_CPP)
653
654         AC_MSG_CHECKING(for native build C flags)
655         AC_ARG_WITH(build-cflags,
656                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
657                 [BUILD_CFLAGS="$withval"])
658         AC_MSG_RESULT($BUILD_CFLAGS)
659
660         AC_MSG_CHECKING(for native build C preprocessor-flags)
661         AC_ARG_WITH(build-cppflags,
662                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
663                 [BUILD_CPPFLAGS="$withval"])
664         AC_MSG_RESULT($BUILD_CPPFLAGS)
665
666         AC_MSG_CHECKING(for native build linker-flags)
667         AC_ARG_WITH(build-ldflags,
668                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
669                 [BUILD_LDFLAGS="$withval"])
670         AC_MSG_RESULT($BUILD_LDFLAGS)
671
672         AC_MSG_CHECKING(for native build linker-libraries)
673         AC_ARG_WITH(build-libs,
674                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
675                 [BUILD_LIBS="$withval"])
676         AC_MSG_RESULT($BUILD_LIBS)
677
678         # this assumes we're on Unix.
679         BUILD_EXEEXT=
680         BUILD_OBJEXT=o
681
682         : ${BUILD_CC:='${CC}'}
683
684         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
685                 AC_MSG_ERROR([Cross-build requires two compilers.
686 Use --with-build-cc to specify the native compiler.])
687         fi
688
689 else
690         : ${BUILD_CC:='${CC}'}
691         : ${BUILD_CPP:='${CPP}'}
692         : ${BUILD_CFLAGS:='${CFLAGS}'}
693         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
694         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
695         : ${BUILD_LIBS:='${LIBS}'}
696         : ${BUILD_EXEEXT:='$x'}
697         : ${BUILD_OBJEXT:='o'}
698 fi
699
700 AC_SUBST(BUILD_CC)
701 AC_SUBST(BUILD_CPP)
702 AC_SUBST(BUILD_CFLAGS)
703 AC_SUBST(BUILD_CPPFLAGS)
704 AC_SUBST(BUILD_LDFLAGS)
705 AC_SUBST(BUILD_LIBS)
706 AC_SUBST(BUILD_EXEEXT)
707 AC_SUBST(BUILD_OBJEXT)
708 ])dnl
709 dnl ---------------------------------------------------------------------------
710 dnl CF_CC_ENV_FLAGS version: 2 updated: 2015/04/12 15:39:00
711 dnl ---------------
712 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
713 dnl into CC.  This will not help with broken scripts that wrap the compiler with
714 dnl options, but eliminates a more common category of user confusion.
715 AC_DEFUN([CF_CC_ENV_FLAGS],
716 [
717 # This should have been defined by AC_PROG_CC
718 : ${CC:=cc}
719
720 AC_MSG_CHECKING(\$CC variable)
721 case "$CC" in
722 (*[[\ \ ]]-[[IUD]]*)
723         AC_MSG_RESULT(broken)
724         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
725         # humor him...
726         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
727         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
728         CF_ADD_CFLAGS($cf_flags)
729         ;;
730 (*)
731         AC_MSG_RESULT(ok)
732         ;;
733 esac
734 ])dnl
735 dnl ---------------------------------------------------------------------------
736 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
737 dnl ---------------
738 dnl Determine the default configuration into which we'll install ncurses.  This
739 dnl can be overridden by the user's command-line options.  There's two items to
740 dnl look for:
741 dnl     1. the prefix (e.g., /usr)
742 dnl     2. the header files (e.g., /usr/include/ncurses)
743 dnl We'll look for a previous installation of ncurses and use the same defaults.
744 dnl
745 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
746 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
747 dnl programs from a vendor's.
748 AC_DEFUN([CF_CFG_DEFAULTS],
749 [
750 AC_MSG_CHECKING(for prefix)
751 if test "x$prefix" = "xNONE" ; then
752         case "$cf_cv_system_name" in
753                 # non-vendor systems don't have a conflict
754         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
755                 prefix=/usr
756                 ;;
757         (*)     prefix=$ac_default_prefix
758                 ;;
759         esac
760 fi
761 AC_MSG_RESULT($prefix)
762
763 if test "x$prefix" = "xNONE" ; then
764 AC_MSG_CHECKING(for default include-directory)
765 test -n "$verbose" && echo 1>&AC_FD_MSG
766 for cf_symbol in \
767         $includedir \
768         $includedir/ncurses \
769         $prefix/include \
770         $prefix/include/ncurses \
771         /usr/local/include \
772         /usr/local/include/ncurses \
773         /usr/include \
774         /usr/include/ncurses
775 do
776         cf_dir=`eval echo $cf_symbol`
777         if test -f $cf_dir/curses.h ; then
778         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
779                 includedir="$cf_symbol"
780                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
781                 break
782         fi
783         fi
784         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
785 done
786 AC_MSG_RESULT($includedir)
787 fi
788 ])dnl
789 dnl ---------------------------------------------------------------------------
790 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
791 dnl ----------
792 dnl Check if the terminal-capability database functions are available.  If not,
793 dnl ncurses has a much-reduced version.
794 AC_DEFUN([CF_CGETENT],[
795 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
796 AC_TRY_LINK([
797 #include <stdlib.h>],[
798         char temp[128];
799         char *buf = temp;
800         char *db_array = temp;
801         cgetent(&buf, &db_array, "vt100");
802         cgetcap(buf, "tc", '=');
803         cgetmatch(buf, "tc");
804         ],
805         [cf_cv_cgetent=yes],
806         [cf_cv_cgetent=no])
807 ])
808
809 if test "$cf_cv_cgetent" = yes
810 then
811         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
812 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
813 AC_TRY_LINK([
814 #include <stdlib.h>],[
815         char temp[128];
816         char *buf = temp;
817 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
818         const char *db_array = temp;
819         cgetent(&buf, &db_array, "vt100");
820 #endif
821         cgetcap(buf, "tc", '=');
822         cgetmatch(buf, "tc");
823         ],
824         [cf_cv_cgetent_const=yes],
825         [cf_cv_cgetent_const=no])
826 ])
827         if test "$cf_cv_cgetent_const" = yes
828         then
829                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
830         fi
831 fi
832 ])dnl
833 dnl ---------------------------------------------------------------------------
834 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
835 dnl --------------
836 dnl Check if we're accidentally using a cache from a different machine.
837 dnl Derive the system name, as a check for reusing the autoconf cache.
838 dnl
839 dnl If we've packaged config.guess and config.sub, run that (since it does a
840 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
841 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
842 dnl which is useful in cross-compiles.
843 dnl
844 dnl Note: we would use $ac_config_sub, but that is one of the places where
845 dnl autoconf 2.5x broke compatibility with autoconf 2.13
846 AC_DEFUN([CF_CHECK_CACHE],
847 [
848 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
849         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
850         system_name="$host_os"
851 else
852         system_name="`(uname -s -r) 2>/dev/null`"
853         if test -z "$system_name" ; then
854                 system_name="`(hostname) 2>/dev/null`"
855         fi
856 fi
857 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
858 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
859
860 test -z "$system_name" && system_name="$cf_cv_system_name"
861 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
862
863 if test ".$system_name" != ".$cf_cv_system_name" ; then
864         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
865         AC_MSG_ERROR("Please remove config.cache and try again.")
866 fi
867 ])dnl
868 dnl ---------------------------------------------------------------------------
869 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
870 dnl --------------
871 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
872 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
873 dnl ourselves.
874 dnl
875 dnl $1 = the name to check
876 dnl $2 = the assumed type
877 AC_DEFUN([CF_CHECK_ERRNO],
878 [
879 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
880         AC_TRY_COMPILE([
881 #ifdef HAVE_STDLIB_H
882 #include <stdlib.h>
883 #endif
884 #include <stdio.h>
885 #include <sys/types.h>
886 #include <errno.h> ],
887         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
888         [cf_cv_dcl_$1=yes],
889         [cf_cv_dcl_$1=no])
890 ])
891
892 if test "$cf_cv_dcl_$1" = no ; then
893         CF_UPPER(cf_result,decl_$1)
894         AC_DEFINE_UNQUOTED($cf_result)
895 fi
896
897 # It's possible (for near-UNIX clones) that the data doesn't exist
898 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
899 ])dnl
900 dnl ---------------------------------------------------------------------------
901 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
902 dnl --------------------
903 dnl Check for existence of external data in the current set of libraries.  If
904 dnl we can modify it, it's real enough.
905 dnl $1 = the name to check
906 dnl $2 = its type
907 AC_DEFUN([CF_CHECK_EXTERN_DATA],
908 [
909 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
910         AC_TRY_LINK([
911 #undef $1
912 extern $2 $1;
913 ],
914         [$1 = 2],
915         [cf_cv_have_$1=yes],
916         [cf_cv_have_$1=no])
917 ])
918
919 if test "$cf_cv_have_$1" = yes ; then
920         CF_UPPER(cf_result,have_$1)
921         AC_DEFINE_UNQUOTED($cf_result)
922 fi
923
924 ])dnl
925 dnl ---------------------------------------------------------------------------
926 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
927 dnl -------------------
928 dnl Check if GPM is already linked with curses.  If so - and if the linkage
929 dnl is not "weak" - warn about this because it can create problems linking
930 dnl applications with ncurses.
931 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
932 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
933
934 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
935 cf_cv_check_gpm_wgetch=unknown
936 if test "$cross_compiling" != yes ; then
937
938 cat >conftest.$ac_ext <<CF_EOF
939 #include <gpm.h>
940 int main()
941 {
942         Gpm_Wgetch();
943         ${cf_cv_main_return:-return}(0);
944 }
945 CF_EOF
946
947         cf_save_LIBS="$LIBS"
948         # This only works if we can look at the symbol table.  If a shared
949         # library is stripped for install, we cannot use that.  So we're forced
950         # to rely on the static library, noting that some packagers may not
951         # include it.
952         LIBS="-static -lgpm -dynamic $LIBS"
953         if AC_TRY_EVAL(ac_compile) ; then
954                 if AC_TRY_EVAL(ac_link) ; then
955                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
956                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
957                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
958                 fi
959         fi
960         rm -rf conftest*
961         LIBS="$cf_save_LIBS"
962 fi
963 ])
964
965 if test "$cf_cv_check_gpm_wgetch" != yes ; then
966         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
967 fi
968 ])])dnl
969 dnl ---------------------------------------------------------------------------
970 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
971 dnl ------------------------
972 dnl Show the version of libtool
973 dnl
974 dnl Save the version in a cache variable - this is not entirely a good thing,
975 dnl but the version string from libtool is very ugly, and for bug reports it
976 dnl might be useful to have the original string.
977 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
978 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
979 then
980         AC_MSG_CHECKING(version of $LIBTOOL)
981         CF_LIBTOOL_VERSION
982         AC_MSG_RESULT($cf_cv_libtool_version)
983         if test -z "$cf_cv_libtool_version" ; then
984                 AC_MSG_ERROR(This is not GNU libtool)
985         fi
986 else
987         AC_MSG_ERROR(GNU libtool has not been found)
988 fi
989 ])dnl
990 dnl ---------------------------------------------------------------------------
991 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
992 dnl ----------------
993 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
994 AC_DEFUN([CF_CHECK_WCHAR_H],[
995 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
996 AC_TRY_COMPILE(
997 [
998 #include <stdlib.h>
999 #include <wchar.h>
1000 ],[
1001         wint_t foo = 0;
1002         int bar = iswpunct(foo)],
1003         [cf_cv_wchar_h_okay=yes],
1004         [cf_cv_wchar_h_okay=no])])
1005
1006 if test $cf_cv_wchar_h_okay = no
1007 then
1008         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1009 fi
1010 ])dnl
1011 dnl ---------------------------------------------------------------------------
1012 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1013 dnl -----------------
1014 dnl Check if the given compiler is really clang.  clang's C driver defines
1015 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1016 dnl not ignore some gcc options.
1017 dnl
1018 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1019 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1020 dnl the wrappers for gcc and g++ warnings.
1021 dnl
1022 dnl $1 = GCC (default) or GXX
1023 dnl $2 = CLANG_COMPILER (default)
1024 dnl $3 = CFLAGS (default) or CXXFLAGS
1025 AC_DEFUN([CF_CLANG_COMPILER],[
1026 ifelse([$2],,CLANG_COMPILER,[$2])=no
1027
1028 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1029         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1030         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1031         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1032         AC_TRY_COMPILE([],[
1033 #ifdef __clang__
1034 #else
1035 make an error
1036 #endif
1037 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1038 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1039 ],[])
1040         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1041         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1042 fi
1043 ])
1044 dnl ---------------------------------------------------------------------------
1045 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
1046 dnl -----------------
1047 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1048 dnl is a late feature for the standard and is not in some recent compilers
1049 dnl (1999/9/11).
1050 AC_DEFUN([CF_CPP_PARAM_INIT],
1051 [
1052 if test -n "$CXX"; then
1053 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1054         AC_LANG_SAVE
1055         AC_LANG_CPLUSPLUS
1056         AC_TRY_RUN([
1057 class TEST {
1058 private:
1059         int value;
1060 public:
1061         TEST(int x = 1);
1062         ~TEST();
1063 };
1064
1065 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1066 {
1067         value = x;
1068 }
1069 int main() { }
1070 ],
1071         [cf_cv_cpp_param_init=yes],
1072         [cf_cv_cpp_param_init=no],
1073         [cf_cv_cpp_param_init=unknown])
1074         AC_LANG_RESTORE
1075 ])
1076 fi
1077 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1078 ])dnl
1079 dnl ---------------------------------------------------------------------------
1080 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1081 dnl ------------------
1082 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1083 dnl not be supported in g++ before 3.0
1084 AC_DEFUN([CF_CPP_STATIC_CAST],
1085 [
1086 if test -n "$CXX"; then
1087
1088 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1089         AC_LANG_SAVE
1090         AC_LANG_CPLUSPLUS
1091
1092         AC_TRY_COMPILE([
1093 class NCursesPanel
1094 {
1095 public:
1096   NCursesPanel(int nlines,
1097                int ncols,
1098                int begin_y = 0,
1099                int begin_x = 0)
1100   {
1101   }
1102   NCursesPanel();
1103   ~NCursesPanel();
1104 };
1105
1106 template<class T> class NCursesUserPanel : public NCursesPanel
1107 {
1108 public:
1109   NCursesUserPanel (int nlines,
1110                     int ncols,
1111                     int begin_y = 0,
1112                     int begin_x = 0,
1113                     const T* p_UserData = static_cast<T*>(0))
1114     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1115   {
1116   };
1117   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1118   {
1119   };
1120
1121   virtual ~NCursesUserPanel() {};
1122 };
1123 ],[
1124         const char* p_UserData = static_cast<char*>(0)],
1125         [cf_cv_cpp_static_cast=yes],
1126         [cf_cv_cpp_static_cast=no])
1127
1128         AC_LANG_RESTORE
1129 ])
1130
1131 fi
1132
1133 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1134 ])dnl
1135 dnl ---------------------------------------------------------------------------
1136 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1137 dnl ---------------
1138 dnl Setup special archiver flags for given compilers.
1139 AC_DEFUN([CF_CXX_AR_FLAGS],[
1140         CXX_AR='$(AR)'
1141         CXX_ARFLAGS='$(ARFLAGS)'
1142         case $cf_cv_system_name in
1143         (irix*)
1144             if test "$GXX" != yes ; then
1145                 CXX_AR='$(CXX)'
1146                 CXX_ARFLAGS='-ar -o'
1147             fi
1148             ;;
1149         (sco3.2v5*)
1150             CXXLDFLAGS="-u main"
1151             ;;
1152         (solaris2*)
1153             if test "$GXX" != yes ; then
1154                 CXX_AR='$(CXX)'
1155                 CXX_ARFLAGS='-xar -o'
1156             fi
1157             ;;
1158         esac
1159         AC_SUBST(CXXLDFLAGS)
1160         AC_SUBST(CXX_AR)
1161         AC_SUBST(CXX_ARFLAGS)
1162 ])dnl
1163 dnl ---------------------------------------------------------------------------
1164 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1165 dnl -------------------------
1166 dnl For c++, check if iostream uses "std::" namespace.
1167 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1168 AC_CHECK_HEADERS(iostream)
1169 if test x"$ac_cv_header_iostream" = xyes ; then
1170         AC_MSG_CHECKING(if iostream uses std-namespace)
1171         AC_TRY_COMPILE([
1172 #include <iostream>
1173 using std::endl;
1174 using std::cerr;],[
1175 cerr << "testing" << endl;
1176 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1177         AC_MSG_RESULT($cf_iostream_namespace)
1178         if test "$cf_iostream_namespace" = yes ; then
1179                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1180         fi
1181 fi
1182 ])dnl
1183 dnl ---------------------------------------------------------------------------
1184 dnl CF_C_INLINE version: 5 updated: 2015/04/18 08:56:57
1185 dnl -----------
1186 dnl Check if the C compiler supports "inline".
1187 dnl $1 is the name of a shell variable to set if inline is supported
1188 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1189 AC_DEFUN([CF_C_INLINE],[
1190 AC_C_INLINE
1191 $1=
1192 if test "$ac_cv_c_inline" != no ; then
1193         $1=inline
1194         if test "$INTEL_COMPILER" = yes
1195         then
1196                 :
1197         elif test "$CLANG_COMPILER" = yes
1198         then
1199                 :
1200         elif test "$GCC" = yes
1201         then
1202                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1203                 cf_save_CFLAGS=$CFLAGS
1204                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1205                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1206                 [${cf_cv_main_return:-return} foo()],
1207                 [cf_cv_gcc_inline=yes],
1208                 [cf_cv_gcc_inline=no])
1209                 CFLAGS=$cf_save_CFLAGS
1210                 ])
1211                 if test "$cf_cv_gcc_inline" = yes ; then
1212                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1213                 fi
1214         fi
1215 fi
1216 AC_SUBST($1)
1217 ])dnl
1218 dnl ---------------------------------------------------------------------------
1219 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1220 dnl ----------
1221 dnl "dirname" is not portable, so we fake it with a shell script.
1222 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1223 dnl ---------------------------------------------------------------------------
1224 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1225 dnl ---------------
1226 AC_DEFUN([CF_DIRS_TO_MAKE],
1227 [
1228 DIRS_TO_MAKE="lib"
1229 for cf_item in $cf_list_models
1230 do
1231         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1232         for cf_item2 in $DIRS_TO_MAKE
1233         do
1234                 test $cf_item2 = $cf_subdir && break
1235         done
1236         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1237 done
1238 for cf_dir in $DIRS_TO_MAKE
1239 do
1240         test ! -d $cf_dir && mkdir $cf_dir
1241 done
1242 AC_SUBST(DIRS_TO_MAKE)
1243 ])dnl
1244 dnl ---------------------------------------------------------------------------
1245 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1246 dnl ---------------
1247 dnl You can always use "make -n" to see the actual options, but it's hard to
1248 dnl pick out/analyze warning messages when the compile-line is long.
1249 dnl
1250 dnl Sets:
1251 dnl     ECHO_LT - symbol to control if libtool is verbose
1252 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1253 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1254 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1255 dnl     ECHO_CC - symbol to put before any "cc" line
1256 dnl
1257 AC_DEFUN([CF_DISABLE_ECHO],[
1258 AC_MSG_CHECKING(if you want to see long compiling messages)
1259 CF_ARG_DISABLE(echo,
1260         [  --disable-echo          do not display "compiling" commands],
1261         [
1262         ECHO_LT='--silent'
1263         ECHO_LD='@echo linking [$]@;'
1264         RULE_CC='@echo compiling [$]<'
1265         SHOW_CC='@echo compiling [$]@'
1266         ECHO_CC='@'
1267 ],[
1268         ECHO_LT=''
1269         ECHO_LD=''
1270         RULE_CC=''
1271         SHOW_CC=''
1272         ECHO_CC=''
1273 ])
1274 AC_MSG_RESULT($enableval)
1275 AC_SUBST(ECHO_LT)
1276 AC_SUBST(ECHO_LD)
1277 AC_SUBST(RULE_CC)
1278 AC_SUBST(SHOW_CC)
1279 AC_SUBST(ECHO_CC)
1280 ])dnl
1281 dnl ---------------------------------------------------------------------------
1282 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1283 dnl ------------------------
1284 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1285 AC_MSG_CHECKING(if we want to use GNAT projects)
1286 CF_ARG_DISABLE(gnat-projects,
1287         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1288         [enable_gnat_projects=no],
1289         [enable_gnat_projects=yes])
1290 AC_MSG_RESULT($enable_gnat_projects)
1291 ])dnl
1292 dnl ---------------------------------------------------------------------------
1293 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1294 dnl ----------------
1295 dnl Combine no-leak checks with the libraries or tools that are used for the
1296 dnl checks.
1297 AC_DEFUN([CF_DISABLE_LEAKS],[
1298
1299 AC_REQUIRE([CF_WITH_DMALLOC])
1300 AC_REQUIRE([CF_WITH_DBMALLOC])
1301 AC_REQUIRE([CF_WITH_VALGRIND])
1302
1303 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1304 AC_ARG_ENABLE(leaks,
1305         [  --disable-leaks         test: free permanent memory, analyze leaks],
1306         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1307         : ${with_no_leaks:=no})
1308 AC_MSG_RESULT($with_no_leaks)
1309
1310 if test "$with_no_leaks" = yes ; then
1311         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1312         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1313 fi
1314 ])dnl
1315 dnl ---------------------------------------------------------------------------
1316 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1317 dnl --------------------------
1318 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1319 dnl the older "-version-info" feature.  The newer feature allows us to use
1320 dnl version numbering on shared libraries which make them compatible with
1321 dnl various systems.
1322 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1323 [
1324 AC_MSG_CHECKING(if libtool -version-number should be used)
1325 CF_ARG_DISABLE(libtool-version,
1326         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1327         [cf_libtool_version=no],
1328         [cf_libtool_version=yes])
1329 AC_MSG_RESULT($cf_libtool_version)
1330
1331 if test "$cf_libtool_version" = yes ; then
1332         LIBTOOL_VERSION="-version-number"
1333 else
1334         LIBTOOL_VERSION="-version-info"
1335         case "x$VERSION" in
1336         (x)
1337                 AC_MSG_WARN(VERSION was not set)
1338                 ;;
1339         (x*.*.*)
1340                 ABI_VERSION="$VERSION"
1341                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1342                 ;;
1343         (x*:*:*)
1344                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1345                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1346                 ;;
1347         (*)
1348                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1349                 ;;
1350         esac
1351 fi
1352
1353 AC_SUBST(ABI_VERSION)
1354 AC_SUBST(LIBTOOL_VERSION)
1355 ])dnl
1356 dnl ---------------------------------------------------------------------------
1357 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1358 dnl ---------------------
1359 dnl The rpath-hack makes it simpler to build programs, particularly with the
1360 dnl *BSD ports which may have essential libraries in unusual places.  But it
1361 dnl can interfere with building an executable for the base system.  Use this
1362 dnl option in that case.
1363 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1364 [
1365 AC_MSG_CHECKING(if rpath-hack should be disabled)
1366 CF_ARG_DISABLE(rpath-hack,
1367         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1368         [cf_disable_rpath_hack=yes],
1369         [cf_disable_rpath_hack=no])
1370 AC_MSG_RESULT($cf_disable_rpath_hack)
1371 if test "$cf_disable_rpath_hack" = no ; then
1372         CF_RPATH_HACK
1373 fi
1374 ])
1375 dnl ---------------------------------------------------------------------------
1376 dnl CF_ENABLE_PC_FILES version: 12 updated: 2015/04/17 21:13:04
1377 dnl ------------------
1378 dnl This is the "--enable-pc-files" option, which is available if there is a
1379 dnl pkg-config configuration on the local machine.
1380 AC_DEFUN([CF_ENABLE_PC_FILES],[
1381 AC_REQUIRE([CF_PKG_CONFIG])
1382 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1383
1384 if test "x$PKG_CONFIG" != xnone
1385 then
1386         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1387 else
1388         AC_MSG_CHECKING(if we should install .pc files)
1389 fi
1390
1391 AC_ARG_ENABLE(pc-files,
1392         [  --enable-pc-files       generate and install .pc files for pkg-config],
1393         [enable_pc_files=$enableval],
1394         [enable_pc_files=no])
1395 AC_MSG_RESULT($enable_pc_files)
1396
1397 if test "x$enable_pc_files" != xno
1398 then
1399         case "x$PKG_CONFIG_LIBDIR" in
1400         (xno|xyes)
1401                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1402                 MAKE_PC_FILES="#"
1403                 ;;
1404         (*)
1405                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1406                 MAKE_PC_FILES=
1407                 ;;
1408         esac
1409 else
1410         MAKE_PC_FILES="#"
1411 fi
1412 AC_SUBST(MAKE_PC_FILES)
1413 ])dnl
1414 dnl ---------------------------------------------------------------------------
1415 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1416 dnl ---------------
1417 dnl Check if the rpath option should be used, setting cache variable
1418 dnl cf_cv_enable_rpath if so.
1419 AC_DEFUN([CF_ENABLE_RPATH],
1420 [
1421 AC_MSG_CHECKING(if rpath option should be used)
1422 AC_ARG_ENABLE(rpath,
1423 [  --enable-rpath          use rpath option when generating shared libraries],
1424 [cf_cv_enable_rpath=$enableval],
1425 [cf_cv_enable_rpath=no])
1426 AC_MSG_RESULT($cf_cv_enable_rpath)
1427 ])dnl
1428 dnl ---------------------------------------------------------------------------
1429 dnl CF_ENABLE_STRING_HACKS version: 3 updated: 2013/01/26 16:26:12
1430 dnl ----------------------
1431 dnl On a few platforms, the compiler and/or loader nags with untruthful
1432 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1433 dnl and implying that most uses of the recommended alternatives are correct.
1434 dnl
1435 dnl Factually speaking, no one has actually counted the number of uses of these
1436 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1437 dnl instances are meaningless compared to the hundreds of millions of lines of
1438 dnl existing C code.
1439 dnl
1440 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1441 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1442 dnl standard - but evolved through phases, and older implementations are likely
1443 dnl to yield surprising results, as documented in manpages on various systems.
1444 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1445 [
1446 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1447 AC_ARG_ENABLE(string-hacks,
1448         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1449         [with_string_hacks=$enableval],
1450         [with_string_hacks=no])
1451 AC_MSG_RESULT($with_string_hacks)
1452
1453 if test "x$with_string_hacks" = "xyes"; then
1454         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1455         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1456         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1457 fi
1458 ])dnl
1459 dnl ---------------------------------------------------------------------------
1460 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1461 dnl --------
1462 dnl Check if 'errno' is declared in <errno.h>
1463 AC_DEFUN([CF_ERRNO],
1464 [
1465 CF_CHECK_ERRNO(errno)
1466 ])dnl
1467 dnl ---------------------------------------------------------------------------
1468 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1469 dnl ---------------
1470 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1471 dnl math.h and builtin.h, only for ncurses
1472 AC_DEFUN([CF_ETIP_DEFINES],
1473 [
1474 AC_MSG_CHECKING(for special defines needed for etip.h)
1475 cf_save_CXXFLAGS="$CXXFLAGS"
1476 cf_result="none"
1477
1478 # etip.h includes ncurses.h which includes ncurses_dll.h
1479 # But ncurses_dll.h is generated - fix here.
1480 test -d include || mkdir include
1481 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1482
1483 for cf_math in "" MATH_H
1484 do
1485 for cf_excp in "" MATH_EXCEPTION
1486 do
1487         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1488         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1489         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1490 AC_TRY_COMPILE([
1491 #include <etip.h.in>
1492 ],[],[
1493         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1494         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1495         cf_result="$cf_math $cf_excp"
1496         break 2
1497 ],[])
1498 done
1499 done
1500 AC_MSG_RESULT($cf_result)
1501 CXXFLAGS="$cf_save_CXXFLAGS"
1502 ])
1503 dnl ---------------------------------------------------------------------------
1504 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
1505 dnl ---------------
1506 dnl Find a library (specifically the linkage used in the code fragment),
1507 dnl searching for it if it is not already in the library path.
1508 dnl See also CF_ADD_SEARCHPATH.
1509 dnl
1510 dnl Parameters (4-on are optional):
1511 dnl     $1 = headers for library entrypoint
1512 dnl     $2 = code fragment for library entrypoint
1513 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1514 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1515 dnl     $5 = action to perform if not successful
1516 dnl     $6 = module name, if not the same as the library name
1517 dnl     $7 = extra libraries
1518 dnl
1519 dnl Sets these variables:
1520 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1521 dnl     $cf_cv_header_path_$3 - include-directory if needed
1522 dnl     $cf_cv_library_path_$3 - library-directory if needed
1523 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1524 AC_DEFUN([CF_FIND_LINKAGE],[
1525
1526 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1527 # will be set on completion of the AC_TRY_LINK below.
1528 cf_cv_header_path_$3=
1529 cf_cv_library_path_$3=
1530
1531 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1532
1533 cf_save_LIBS="$LIBS"
1534
1535 AC_TRY_LINK([$1],[$2],[
1536         cf_cv_find_linkage_$3=yes
1537         cf_cv_header_path_$3=/usr/include
1538         cf_cv_library_path_$3=/usr/lib
1539 ],[
1540
1541 LIBS="-l$3 $7 $cf_save_LIBS"
1542
1543 AC_TRY_LINK([$1],[$2],[
1544         cf_cv_find_linkage_$3=yes
1545         cf_cv_header_path_$3=/usr/include
1546         cf_cv_library_path_$3=/usr/lib
1547         cf_cv_library_file_$3="-l$3"
1548 ],[
1549         cf_cv_find_linkage_$3=no
1550         LIBS="$cf_save_LIBS"
1551
1552         CF_VERBOSE(find linkage for $3 library)
1553         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1554
1555         cf_save_CPPFLAGS="$CPPFLAGS"
1556         cf_test_CPPFLAGS="$CPPFLAGS"
1557
1558         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1559         for cf_cv_header_path_$3 in $cf_search
1560         do
1561                 if test -d $cf_cv_header_path_$3 ; then
1562                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1563                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1564                         AC_TRY_COMPILE([$1],[$2],[
1565                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1566                                 cf_cv_find_linkage_$3=maybe
1567                                 cf_test_CPPFLAGS="$CPPFLAGS"
1568                                 break],[
1569                                 CPPFLAGS="$cf_save_CPPFLAGS"
1570                                 ])
1571                 fi
1572         done
1573
1574         if test "$cf_cv_find_linkage_$3" = maybe ; then
1575
1576                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1577
1578                 cf_save_LIBS="$LIBS"
1579                 cf_save_LDFLAGS="$LDFLAGS"
1580
1581                 ifelse([$6],,,[
1582                 CPPFLAGS="$cf_test_CPPFLAGS"
1583                 LIBS="-l$3 $7 $cf_save_LIBS"
1584                 AC_TRY_LINK([$1],[$2],[
1585                         CF_VERBOSE(... found $3 library in system)
1586                         cf_cv_find_linkage_$3=yes])
1587                         CPPFLAGS="$cf_save_CPPFLAGS"
1588                         LIBS="$cf_save_LIBS"
1589                         ])
1590
1591                 if test "$cf_cv_find_linkage_$3" != yes ; then
1592                         CF_LIBRARY_PATH(cf_search,$3)
1593                         for cf_cv_library_path_$3 in $cf_search
1594                         do
1595                                 if test -d $cf_cv_library_path_$3 ; then
1596                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1597                                         CPPFLAGS="$cf_test_CPPFLAGS"
1598                                         LIBS="-l$3 $7 $cf_save_LIBS"
1599                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1600                                         AC_TRY_LINK([$1],[$2],[
1601                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1602                                         cf_cv_find_linkage_$3=yes
1603                                         cf_cv_library_file_$3="-l$3"
1604                                         break],[
1605                                         CPPFLAGS="$cf_save_CPPFLAGS"
1606                                         LIBS="$cf_save_LIBS"
1607                                         LDFLAGS="$cf_save_LDFLAGS"
1608                                         ])
1609                                 fi
1610                         done
1611                         CPPFLAGS="$cf_save_CPPFLAGS"
1612                         LDFLAGS="$cf_save_LDFLAGS"
1613                 fi
1614
1615         else
1616                 cf_cv_find_linkage_$3=no
1617         fi
1618         ],$7)
1619 ])
1620
1621 LIBS="$cf_save_LIBS"
1622
1623 if test "$cf_cv_find_linkage_$3" = yes ; then
1624 ifelse([$4],,[
1625         CF_ADD_INCDIR($cf_cv_header_path_$3)
1626         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1627         CF_ADD_LIB($3)
1628 ],[$4])
1629 else
1630 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1631 fi
1632 ])dnl
1633 dnl ---------------------------------------------------------------------------
1634 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
1635 dnl ------------------
1636 dnl Find an include-directory with the given leaf-name.  This is useful for
1637 dnl example with FreeBSD ports, which use this convention to distinguish
1638 dnl different versions of the same port.
1639 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1640         CF_SUBDIR_PATH(cf_search,$1,include)
1641         for cf_item in $cf_search
1642         do
1643                 case $cf_item in
1644                 (*/$1)
1645                         CF_ADD_INCDIR($cf_item)
1646                         ;;
1647                 esac
1648         done
1649 ])dnl
1650 dnl ---------------------------------------------------------------------------
1651 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
1652 dnl ------------------
1653 dnl Find a library-directory with the given leaf-name.  This is useful for
1654 dnl example with FreeBSD ports, which use this convention to distinguish
1655 dnl different versions of the same port.
1656 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1657         CF_SUBDIR_PATH(cf_search,$1,lib)
1658         for cf_item in $cf_search
1659         do
1660                 case $cf_item in
1661                 (*/$1)
1662                         CF_ADD_LIBDIR($cf_item)
1663                         ;;
1664                 esac
1665         done
1666 ])dnl
1667 dnl ---------------------------------------------------------------------------
1668 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1669 dnl -----------------
1670 dnl make ADAFLAGS consistent with CFLAGS
1671 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1672         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1673         case "$CFLAGS" in
1674         (*-g*)
1675                 CF_ADD_ADAFLAGS(-g)
1676                 ;;
1677         esac
1678         case "$CFLAGS" in
1679         (*-O*)
1680                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1681                 CF_ADD_ADAFLAGS($cf_O_flag)
1682                 ;;
1683         esac
1684         AC_MSG_RESULT($ADAFLAGS)
1685 ])dnl
1686 dnl ---------------------------------------------------------------------------
1687 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1688 dnl --------------
1689 dnl Forget that we saw the given tool.
1690 AC_DEFUN([CF_FORGET_TOOL],[
1691 unset ac_cv_prog_ac_ct_$1
1692 unset ac_ct_$1
1693 unset $1
1694 ])dnl
1695 dnl ---------------------------------------------------------------------------
1696 dnl CF_FUNC_DLSYM version: 3 updated: 2012/10/06 11:17:15
1697 dnl -------------
1698 dnl Test for dlsym() and related functions, as well as libdl.
1699 dnl
1700 dnl Sets
1701 dnl     $cf_have_dlsym
1702 dnl     $cf_have_libdl
1703 AC_DEFUN([CF_FUNC_DLSYM],[
1704 cf_have_dlsym=no
1705 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1706
1707 cf_have_libdl=no
1708 AC_CHECK_LIB(dl,dlsym,[
1709         cf_have_dlsym=yes
1710         cf_have_libdl=yes])])
1711
1712 if test "$cf_have_dlsym" = yes ; then
1713         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1714
1715         AC_MSG_CHECKING(whether able to link to dl*() functions)
1716         AC_TRY_LINK([#include <dlfcn.h>],[
1717                 void *obj;
1718                 if ((obj = dlopen("filename", 0)) != 0) {
1719                         if (dlsym(obj, "symbolname") == 0) {
1720                         dlclose(obj);
1721                         }
1722                 }],[
1723                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1724                 AC_MSG_ERROR(Cannot link test program for libdl)])
1725         AC_MSG_RESULT(ok)
1726 else
1727         AC_MSG_ERROR(Cannot find dlsym function)
1728 fi
1729 ])
1730 dnl ---------------------------------------------------------------------------
1731 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1732 dnl ---------------
1733 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1734 dnl is found, add our own version of memmove to the list of objects.
1735 AC_DEFUN([CF_FUNC_MEMMOVE],
1736 [
1737 AC_CHECK_FUNC(memmove,,[
1738 AC_CHECK_FUNC(bcopy,[
1739         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1740                 AC_TRY_RUN([
1741 int main() {
1742         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1743         char temp[40];
1744         bcopy(data, temp, sizeof(data));
1745         bcopy(temp+10, temp, 15);
1746         bcopy(temp+5, temp+15, 10);
1747         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1748 }
1749                 ],
1750                 [cf_cv_good_bcopy=yes],
1751                 [cf_cv_good_bcopy=no],
1752                 [cf_cv_good_bcopy=unknown])
1753                 ])
1754         ],[cf_cv_good_bcopy=no])
1755         if test "$cf_cv_good_bcopy" = yes ; then
1756                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1757         else
1758                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1759         fi
1760 ])])dnl
1761 dnl ---------------------------------------------------------------------------
1762 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1763 dnl -----------------
1764 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1765 dnl AIX 4.x, provide a non-working version.
1766 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1767 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1768 AC_TRY_RUN([
1769 #include <stdio.h>
1770 #include <errno.h>
1771 #include <time.h>
1772
1773 #ifdef HAVE_SYS_TIME_H
1774 #include <sys/time.h>
1775 #endif
1776
1777 int main() {
1778         struct timespec ts1, ts2;
1779         int code;
1780         ts1.tv_sec  = 0;
1781         ts1.tv_nsec = 750000000;
1782         ts2.tv_sec  = 0;
1783         ts2.tv_nsec = 0;
1784         errno = 0;
1785         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1786         ${cf_cv_main_return:-return}(code != 0);
1787 }
1788 ],
1789         [cf_cv_func_nanosleep=yes],
1790         [cf_cv_func_nanosleep=no],
1791         [cf_cv_func_nanosleep=unknown])])
1792
1793 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1794 ])
1795 dnl ---------------------------------------------------------------------------
1796 dnl CF_FUNC_OPENPTY version: 4 updated: 2015/04/18 08:56:57
1797 dnl ---------------
1798 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1799 dnl "util" library as well.
1800 AC_DEFUN([CF_FUNC_OPENPTY],
1801 [
1802 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1803 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1804         cf_save_LIBS="$LIBS"
1805         test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1806         for cf_header in pty.h libutil.h util.h
1807         do
1808         AC_TRY_LINK([
1809 #include <$cf_header>
1810 ],[
1811         int x = openpty((int *)0, (int *)0, (char *)0,
1812                                    (struct termios *)0, (struct winsize *)0);
1813 ],[
1814                 cf_cv_func_openpty=$cf_header
1815                 break
1816 ],[
1817                 cf_cv_func_openpty=no
1818 ])
1819         done
1820         LIBS="$cf_save_LIBS"
1821 ])
1822 ])dnl
1823 dnl ---------------------------------------------------------------------------
1824 dnl CF_FUNC_POLL version: 8 updated: 2012/10/04 05:24:07
1825 dnl ------------
1826 dnl See if the poll function really works.  Some platforms have poll(), but
1827 dnl it does not work for terminals or files.
1828 AC_DEFUN([CF_FUNC_POLL],[
1829 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1830 AC_TRY_RUN([
1831 #include <stdlib.h>
1832 #include <stdio.h>
1833 #include <unistd.h>
1834 #include <fcntl.h>
1835 #ifdef HAVE_POLL_H
1836 #include <poll.h>
1837 #else
1838 #include <sys/poll.h>
1839 #endif
1840 int main() {
1841         struct pollfd myfds;
1842         int ret;
1843
1844         /* check for Darwin bug with respect to "devices" */
1845         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
1846         if (myfds.fd < 0)
1847                 myfds.fd = 0;
1848         myfds.events = POLLIN;
1849         myfds.revents = 0;
1850
1851         ret = poll(&myfds, 1, 100);
1852
1853         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1854                 ret = -1;
1855         } else {
1856                 int fd = 0;
1857                 if (!isatty(fd)) {
1858                         fd = open("/dev/tty", 2);       /* O_RDWR */
1859                 }
1860
1861                 if (fd >= 0) {
1862                         /* also check with standard input */
1863                         myfds.fd = fd;
1864                         myfds.events = POLLIN;
1865                         myfds.revents = 0;
1866                         ret = poll(&myfds, 1, 100);
1867                 } else {
1868                         ret = -1;
1869                 }
1870         }
1871         ${cf_cv_main_return:-return}(ret < 0);
1872 }],
1873         [cf_cv_working_poll=yes],
1874         [cf_cv_working_poll=no],
1875         [cf_cv_working_poll=unknown])])
1876 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
1877 ])dnl
1878 dnl ---------------------------------------------------------------------------
1879 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
1880 dnl ---------------
1881 dnl Some old/broken variations define tcgetattr() only as a macro in
1882 dnl termio(s).h
1883 AC_DEFUN([CF_FUNC_TERMIOS],[
1884 AC_REQUIRE([CF_STRUCT_TERMIOS])
1885 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1886 AC_TRY_LINK([
1887 #include <sys/types.h>
1888 #ifdef HAVE_UNISTD_H
1889 #include <unistd.h>
1890 #endif
1891 #ifdef HAVE_TERMIOS_H
1892 #include <termios.h>
1893 #define TTY struct termios
1894 #else
1895 #ifdef HAVE_TERMIO_H
1896 #include <termio.h>
1897 #define TTY struct termio
1898 #endif
1899 #endif
1900 ],[
1901 TTY foo;
1902 tcgetattr(1, &foo);],
1903 [cf_cv_have_tcgetattr=yes],
1904 [cf_cv_have_tcgetattr=no])])
1905 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
1906 ])dnl
1907 dnl ---------------------------------------------------------------------------
1908 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
1909 dnl ---------------
1910 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1911 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1912 dnl other functions.
1913 AC_DEFUN([CF_FUNC_VSSCANF],
1914 [
1915 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1916 AC_TRY_LINK([
1917 #include <stdarg.h>
1918 #include <stdio.h>],[
1919         va_list ap;
1920         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1921 AC_TRY_LINK([
1922 #include <stdarg.h>
1923 #include <stdio.h>],[
1924         FILE strbuf;
1925         char *str = "from";
1926
1927         strbuf._flag = _IOREAD;
1928         strbuf._ptr = strbuf._base = (unsigned char *) str;
1929         strbuf._cnt = strlen(str);
1930         strbuf._file = _NFILE;
1931         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1932 AC_TRY_LINK([
1933 #include <stdarg.h>
1934 #include <stdio.h>],[
1935         FILE strbuf;
1936         char *str = "from";
1937
1938         strbuf._flag = _IOREAD;
1939         strbuf._ptr = strbuf._base = (unsigned char *) str;
1940         strbuf._cnt = strlen(str);
1941         strbuf._file = _NFILE;
1942         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1943 cf_cv_func_vsscanf=no])])])])
1944
1945 case $cf_cv_func_vsscanf in
1946 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
1947 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
1948 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
1949 esac
1950
1951 ])dnl
1952 dnl ---------------------------------------------------------------------------
1953 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
1954 dnl -----------------
1955 dnl Test for availability of useful gcc __attribute__ directives to quiet
1956 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1957 dnl to documentation, unrecognized directives cause older compilers to barf.
1958 AC_DEFUN([CF_GCC_ATTRIBUTES],
1959 [
1960 if test "$GCC" = yes
1961 then
1962 cat > conftest.i <<EOF
1963 #ifndef GCC_PRINTF
1964 #define GCC_PRINTF 0
1965 #endif
1966 #ifndef GCC_SCANF
1967 #define GCC_SCANF 0
1968 #endif
1969 #ifndef GCC_NORETURN
1970 #define GCC_NORETURN /* nothing */
1971 #endif
1972 #ifndef GCC_UNUSED
1973 #define GCC_UNUSED /* nothing */
1974 #endif
1975 EOF
1976 if test "$GCC" = yes
1977 then
1978         AC_CHECKING([for $CC __attribute__ directives])
1979 cat > conftest.$ac_ext <<EOF
1980 #line __oline__ "${as_me:-configure}"
1981 #include "confdefs.h"
1982 #include "conftest.h"
1983 #include "conftest.i"
1984 #if     GCC_PRINTF
1985 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1986 #else
1987 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1988 #endif
1989 #if     GCC_SCANF
1990 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1991 #else
1992 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1993 #endif
1994 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1995 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1996 extern void foo(void) GCC_NORETURN;
1997 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1998 EOF
1999         cf_printf_attribute=no
2000         cf_scanf_attribute=no
2001         for cf_attribute in scanf printf unused noreturn
2002         do
2003                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2004                 cf_directive="__attribute__(($cf_attribute))"
2005                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2006
2007                 case $cf_attribute in
2008                 (printf)
2009                         cf_printf_attribute=yes
2010                         cat >conftest.h <<EOF
2011 #define GCC_$cf_ATTRIBUTE 1
2012 EOF
2013                         ;;
2014                 (scanf)
2015                         cf_scanf_attribute=yes
2016                         cat >conftest.h <<EOF
2017 #define GCC_$cf_ATTRIBUTE 1
2018 EOF
2019                         ;;
2020                 (*)
2021                         cat >conftest.h <<EOF
2022 #define GCC_$cf_ATTRIBUTE $cf_directive
2023 EOF
2024                         ;;
2025                 esac
2026
2027                 if AC_TRY_EVAL(ac_compile); then
2028                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2029                         cat conftest.h >>confdefs.h
2030                         case $cf_attribute in
2031                         (noreturn)
2032                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2033                                 ;;
2034                         (printf)
2035                                 cf_value='/* nothing */'
2036                                 if test "$cf_printf_attribute" != no ; then
2037                                         cf_value='__attribute__((format(printf,fmt,var)))'
2038                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2039                                 fi
2040                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2041                                 ;;
2042                         (scanf)
2043                                 cf_value='/* nothing */'
2044                                 if test "$cf_scanf_attribute" != no ; then
2045                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2046                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2047                                 fi
2048                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2049                                 ;;
2050                         (unused)
2051                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2052                                 ;;
2053                         esac
2054                 fi
2055         done
2056 else
2057         fgrep define conftest.i >>confdefs.h
2058 fi
2059 rm -rf conftest*
2060 fi
2061 ])dnl
2062 dnl ---------------------------------------------------------------------------
2063 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2064 dnl --------------
2065 dnl Find version of gcc
2066 AC_DEFUN([CF_GCC_VERSION],[
2067 AC_REQUIRE([AC_PROG_CC])
2068 GCC_VERSION=none
2069 if test "$GCC" = yes ; then
2070         AC_MSG_CHECKING(version of $CC)
2071         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2072         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2073         AC_MSG_RESULT($GCC_VERSION)
2074 fi
2075 ])dnl
2076 dnl ---------------------------------------------------------------------------
2077 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
2078 dnl ---------------
2079 dnl Check if the compiler supports useful warning options.  There's a few that
2080 dnl we don't use, simply because they're too noisy:
2081 dnl
2082 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2083 dnl     -Wredundant-decls (system headers make this too noisy)
2084 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2085 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2086 dnl             is enabled for ncurses using "--enable-const".
2087 dnl     -pedantic
2088 dnl
2089 dnl Parameter:
2090 dnl     $1 is an optional list of gcc warning flags that a particular
2091 dnl             application might want to use, e.g., "no-unused" for
2092 dnl             -Wno-unused
2093 dnl Special:
2094 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2095 dnl
2096 AC_DEFUN([CF_GCC_WARNINGS],
2097 [
2098 AC_REQUIRE([CF_GCC_VERSION])
2099 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2100 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2101
2102 cat > conftest.$ac_ext <<EOF
2103 #line __oline__ "${as_me:-configure}"
2104 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2105 EOF
2106
2107 if test "$INTEL_COMPILER" = yes
2108 then
2109 # The "-wdXXX" options suppress warnings:
2110 # remark #1419: external declaration in primary source file
2111 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2112 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2113 # remark #193: zero used for undefined preprocessing identifier
2114 # remark #593: variable "curs_sb_left_arrow" was set but never used
2115 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2116 # remark #869: parameter "tw" was never referenced
2117 # remark #981: operands are evaluated in unspecified order
2118 # warning #279: controlling expression is constant
2119
2120         AC_CHECKING([for $CC warning options])
2121         cf_save_CFLAGS="$CFLAGS"
2122         EXTRA_CFLAGS="-Wall"
2123         for cf_opt in \
2124                 wd1419 \
2125                 wd1683 \
2126                 wd1684 \
2127                 wd193 \
2128                 wd593 \
2129                 wd279 \
2130                 wd810 \
2131                 wd869 \
2132                 wd981
2133         do
2134                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2135                 if AC_TRY_EVAL(ac_compile); then
2136                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2137                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2138                 fi
2139         done
2140         CFLAGS="$cf_save_CFLAGS"
2141
2142 elif test "$GCC" = yes
2143 then
2144         AC_CHECKING([for $CC warning options])
2145         cf_save_CFLAGS="$CFLAGS"
2146         EXTRA_CFLAGS=
2147         cf_warn_CONST=""
2148         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2149         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2150         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2151         for cf_opt in W Wall \
2152                 Wbad-function-cast \
2153                 Wcast-align \
2154                 Wcast-qual \
2155                 Wdeclaration-after-statement \
2156                 Wextra \
2157                 Winline \
2158                 Wmissing-declarations \
2159                 Wmissing-prototypes \
2160                 Wnested-externs \
2161                 Wpointer-arith \
2162                 Wshadow \
2163                 Wstrict-prototypes \
2164                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2165         do
2166                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2167                 if AC_TRY_EVAL(ac_compile); then
2168                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2169                         case $cf_opt in
2170                         (Wcast-qual)
2171                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2172                                 ;;
2173                         (Winline)
2174                                 case $GCC_VERSION in
2175                                 ([[34]].*)
2176                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2177                                         continue;;
2178                                 esac
2179                                 ;;
2180                         (Wpointer-arith)
2181                                 case $GCC_VERSION in
2182                                 ([[12]].*)
2183                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2184                                         continue;;
2185                                 esac
2186                                 ;;
2187                         esac
2188                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2189                 fi
2190         done
2191         CFLAGS="$cf_save_CFLAGS"
2192 fi
2193 rm -rf conftest*
2194
2195 AC_SUBST(EXTRA_CFLAGS)
2196 ])dnl
2197 dnl ---------------------------------------------------------------------------
2198 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2199 dnl ----------------
2200 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2201 dnl unistd.h or (nonstandard) in getopt.h
2202 AC_DEFUN([CF_GETOPT_HEADER],
2203 [
2204 AC_HAVE_HEADERS(unistd.h getopt.h)
2205 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2206 cf_cv_getopt_header=none
2207 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2208 do
2209 AC_TRY_COMPILE([
2210 #include <$cf_header>],
2211 [int x = optind; char *y = optarg],
2212 [cf_cv_getopt_header=$cf_header
2213  break])
2214 done
2215 ])
2216 if test $cf_cv_getopt_header != none ; then
2217         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2218 fi
2219 if test $cf_cv_getopt_header = getopt.h ; then
2220         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2221 fi
2222 ])dnl
2223 dnl ---------------------------------------------------------------------------
2224 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2225 dnl -----------------
2226 AC_DEFUN([CF_GNATPREP_OPT_T],[
2227 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2228 cf_cv_gnatprep_opt_t=no
2229 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2230 ])
2231 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2232 AC_SUBST(GNATPREP_OPTS)
2233 ])dnl
2234 dnl ---------------------------------------------------------------------------
2235 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2236 dnl ----------------
2237 AC_DEFUN([CF_GNAT_GENERICS],
2238 [
2239 AC_REQUIRE([CF_GNAT_VERSION])
2240
2241 AC_MSG_CHECKING(if GNAT supports generics)
2242 case $cf_gnat_version in
2243 (3.[[1-9]]*|[[4-9]].*)
2244         cf_gnat_generics=yes
2245         ;;
2246 (*)
2247         cf_gnat_generics=no
2248         ;;
2249 esac
2250 AC_MSG_RESULT($cf_gnat_generics)
2251
2252 if test "$cf_gnat_generics" = yes
2253 then
2254         cf_compile_generics=generics
2255         cf_generic_objects="\${GENOBJS}"
2256 else
2257         cf_compile_generics=
2258         cf_generic_objects=
2259 fi
2260
2261 AC_SUBST(cf_compile_generics)
2262 AC_SUBST(cf_generic_objects)
2263 ])dnl
2264 dnl ---------------------------------------------------------------------------
2265 dnl CF_GNAT_PROJECTS version: 8 updated: 2015/04/17 21:13:04
2266 dnl ----------------
2267 dnl GNAT projects are configured with ".gpr" project files.
2268 dnl GNAT libraries are a further development, using the project feature.
2269 AC_DEFUN([CF_GNAT_PROJECTS],
2270 [
2271 AC_REQUIRE([CF_GNAT_VERSION])
2272 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2273
2274 cf_gnat_libraries=no
2275 cf_gnat_projects=no
2276
2277 if test "$enable_gnat_projects" != no ; then
2278 AC_MSG_CHECKING(if GNAT supports project files)
2279 case $cf_gnat_version in
2280 (3.[[0-9]]*)
2281         ;;
2282 (*)
2283         case $cf_cv_system_name in
2284         (cygwin*|msys*)
2285                 ;;
2286         (*)
2287                 mkdir conftest.src conftest.bin conftest.lib
2288                 cd conftest.src
2289                 rm -rf conftest* *~conftest*
2290                 cat >>library.gpr <<CF_EOF
2291 project Library is
2292   Kind := External ("LIB_KIND");
2293   for Library_Name use "ConfTest";
2294   for Object_Dir use ".";
2295   for Library_ALI_Dir use External("LIBRARY_DIR");
2296   for Library_Version use External ("SONAME");
2297   for Library_Kind use Kind;
2298   for Library_Dir use External("BUILD_DIR");
2299   Source_Dir := External ("SOURCE_DIR");
2300   for Source_Dirs use (Source_Dir);
2301 end Library;
2302 CF_EOF
2303                 cat >>confpackage.ads <<CF_EOF
2304 package ConfPackage is
2305    procedure conftest;
2306 end ConfPackage;
2307 CF_EOF
2308                 cat >>confpackage.adb <<CF_EOF
2309 with Text_IO;
2310 package body ConfPackage is
2311    procedure conftest is
2312    begin
2313       Text_IO.Put ("Hello World");
2314       Text_IO.New_Line;
2315    end conftest;
2316 end ConfPackage;
2317 CF_EOF
2318                 if ( $cf_ada_make $ADAFLAGS \
2319                                 -Plibrary.gpr \
2320                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2321                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2322                                 -XSOURCE_DIR=`pwd` \
2323                                 -XSONAME=libConfTest.so.1 \
2324                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2325                         cf_gnat_projects=yes
2326                 fi
2327                 cd ..
2328                 if test -f conftest.lib/confpackage.ali
2329                 then
2330                         cf_gnat_libraries=yes
2331                 fi
2332                 rm -rf conftest* *~conftest*
2333                 ;;
2334         esac
2335         ;;
2336 esac
2337 AC_MSG_RESULT($cf_gnat_projects)
2338 fi # enable_gnat_projects
2339
2340 if test $cf_gnat_projects = yes
2341 then
2342         AC_MSG_CHECKING(if GNAT supports libraries)
2343         AC_MSG_RESULT($cf_gnat_libraries)
2344 fi
2345
2346 if test "$cf_gnat_projects" = yes
2347 then
2348         USE_OLD_MAKERULES="#"
2349         USE_GNAT_PROJECTS=""
2350 else
2351         USE_OLD_MAKERULES=""
2352         USE_GNAT_PROJECTS="#"
2353 fi
2354
2355 if test "$cf_gnat_libraries" = yes
2356 then
2357         USE_GNAT_LIBRARIES=""
2358 else
2359         USE_GNAT_LIBRARIES="#"
2360 fi
2361
2362 AC_SUBST(USE_OLD_MAKERULES)
2363 AC_SUBST(USE_GNAT_PROJECTS)
2364 AC_SUBST(USE_GNAT_LIBRARIES)
2365 ])dnl
2366 dnl ---------------------------------------------------------------------------
2367 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2368 dnl --------------
2369 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2370 dnl is noted that gnat may compile a tasking unit even for configurations which
2371 dnl fail at runtime.
2372 AC_DEFUN([CF_GNAT_SIGINT],[
2373 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2374 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2375
2376 package ConfTest is
2377
2378    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2379    pragma Unreserve_All_Interrupts;
2380    pragma Warnings (On);
2381
2382    protected Process is
2383       procedure Stop;
2384       function Continue return Boolean;
2385       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2386    private
2387       Done : Boolean := False;
2388    end Process;
2389
2390 end ConfTest;],
2391 [package body ConfTest is
2392    protected body Process is
2393       procedure Stop is
2394       begin
2395          Done := True;
2396       end Stop;
2397       function Continue return Boolean is
2398       begin
2399          return not Done;
2400       end Continue;
2401    end Process;
2402 end ConfTest;],
2403         [cf_cv_gnat_sigint=yes],
2404         [cf_cv_gnat_sigint=no])])
2405
2406 if test $cf_cv_gnat_sigint = yes ; then
2407         USE_GNAT_SIGINT=""
2408 else
2409         USE_GNAT_SIGINT="#"
2410 fi
2411 AC_SUBST(USE_GNAT_SIGINT)
2412 ])dnl
2413 dnl ---------------------------------------------------------------------------
2414 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2415 dnl ----------------
2416 dnl Verify that a test program compiles/links with GNAT.
2417 dnl $cf_ada_make is set to the program that compiles/links
2418 dnl $ADAFLAGS may be set to the GNAT flags.
2419 dnl
2420 dnl $1 is the text of the spec
2421 dnl $2 is the text of the body
2422 dnl $3 is the shell command to execute if successful
2423 dnl $4 is the shell command to execute if not successful
2424 AC_DEFUN([CF_GNAT_TRY_LINK],
2425 [
2426 rm -rf conftest* *~conftest*
2427 cat >>conftest.ads <<CF_EOF
2428 $1
2429 CF_EOF
2430 cat >>conftest.adb <<CF_EOF
2431 $2
2432 CF_EOF
2433 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2434 ifelse($3,,      :,[      $3])
2435 ifelse($4,,,[else
2436    $4])
2437 fi
2438 rm -rf conftest* *~conftest*
2439 ])dnl
2440 dnl ---------------------------------------------------------------------------
2441 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2442 dnl ---------------
2443 dnl Verify that a test program compiles and runs with GNAT
2444 dnl $cf_ada_make is set to the program that compiles/links
2445 dnl $ADAFLAGS may be set to the GNAT flags.
2446 dnl
2447 dnl $1 is the text of the spec
2448 dnl $2 is the text of the body
2449 dnl $3 is the shell command to execute if successful
2450 dnl $4 is the shell command to execute if not successful
2451 AC_DEFUN([CF_GNAT_TRY_RUN],
2452 [
2453 rm -rf conftest* *~conftest*
2454 cat >>conftest.ads <<CF_EOF
2455 $1
2456 CF_EOF
2457 cat >>conftest.adb <<CF_EOF
2458 $2
2459 CF_EOF
2460 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2461    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2462 ifelse($3,,      :,[      $3])
2463 ifelse($4,,,[   else
2464       $4])
2465    fi
2466 ifelse($4,,,[else
2467    $4])
2468 fi
2469 rm -rf conftest* *~conftest*
2470 ])dnl
2471 dnl ---------------------------------------------------------------------------
2472 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
2473 dnl ---------------
2474 dnl Verify version of GNAT.
2475 AC_DEFUN([CF_GNAT_VERSION],
2476 [
2477 AC_MSG_CHECKING(for gnat version)
2478 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2479         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2480         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2481 AC_MSG_RESULT($cf_gnat_version)
2482
2483 case $cf_gnat_version in
2484 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
2485         cf_cv_prog_gnat_correct=yes
2486         ;;
2487 (*)
2488         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2489         cf_cv_prog_gnat_correct=no
2490         ;;
2491 esac
2492 ])
2493 dnl ---------------------------------------------------------------------------
2494 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2495 dnl -------------
2496 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2497 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2498 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2499 dnl since it is interwoven with GNU extensions.
2500 dnl
2501 dnl Well, yes we could work around it...
2502 AC_DEFUN([CF_GNU_SOURCE],
2503 [
2504 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2505 AC_TRY_COMPILE([#include <sys/types.h>],[
2506 #ifndef _XOPEN_SOURCE
2507 make an error
2508 #endif],
2509         [cf_cv_gnu_source=no],
2510         [cf_save="$CPPFLAGS"
2511          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2512          AC_TRY_COMPILE([#include <sys/types.h>],[
2513 #ifdef _XOPEN_SOURCE
2514 make an error
2515 #endif],
2516         [cf_cv_gnu_source=no],
2517         [cf_cv_gnu_source=yes])
2518         CPPFLAGS="$cf_save"
2519         ])
2520 ])
2521 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2522 ])dnl
2523 dnl ---------------------------------------------------------------------------
2524 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
2525 dnl --------------
2526 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2527 dnl problem :-).  If we have the compiler but no library, we'll be able to
2528 dnl configure, but won't be able to build the c++ demo program.
2529 AC_DEFUN([CF_GPP_LIBRARY],
2530 [
2531 cf_cxx_library=unknown
2532 case $cf_cv_system_name in
2533 (os2*)
2534         cf_gpp_libname=gpp
2535         ;;
2536 (*)
2537         cf_gpp_libname=g++
2538         ;;
2539 esac
2540 if test "$GXX" = yes; then
2541         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2542         cf_save="$LIBS"
2543         CF_ADD_LIB($cf_gpp_libname)
2544         AC_TRY_LINK([
2545 #include <$cf_gpp_libname/builtin.h>
2546         ],
2547         [two_arg_error_handler_t foo2 = lib_error_handler],
2548         [cf_cxx_library=yes
2549          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2550          if test "$cf_gpp_libname" = cpp ; then
2551             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2552          else
2553             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2554          fi],
2555         [AC_TRY_LINK([
2556 #include <builtin.h>
2557         ],
2558         [two_arg_error_handler_t foo2 = lib_error_handler],
2559         [cf_cxx_library=yes
2560          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2561          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2562         [cf_cxx_library=no])])
2563         LIBS="$cf_save"
2564         AC_MSG_RESULT($cf_cxx_library)
2565 fi
2566 ])dnl
2567 dnl ---------------------------------------------------------------------------
2568 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2569 dnl --------------
2570 dnl Check for version of g++
2571 AC_DEFUN([CF_GXX_VERSION],[
2572 AC_REQUIRE([AC_PROG_CPP])
2573 GXX_VERSION=none
2574 if test "$GXX" = yes; then
2575         AC_MSG_CHECKING(version of ${CXX:-g++})
2576         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2577         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2578         AC_MSG_RESULT($GXX_VERSION)
2579 fi
2580 ])dnl
2581 dnl ---------------------------------------------------------------------------
2582 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
2583 dnl ---------------
2584 dnl Check if the compiler supports useful warning options.
2585 dnl
2586 dnl Most of gcc's options apply to g++, except:
2587 dnl     -Wbad-function-cast
2588 dnl     -Wmissing-declarations
2589 dnl     -Wnested-externs
2590 dnl
2591 dnl Omit a few (for now):
2592 dnl     -Winline
2593 dnl
2594 dnl Parameter:
2595 dnl     $1 is an optional list of g++ warning flags that a particular
2596 dnl             application might want to use, e.g., "no-unused" for
2597 dnl             -Wno-unused
2598 dnl Special:
2599 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2600 dnl
2601 AC_DEFUN([CF_GXX_WARNINGS],
2602 [
2603
2604 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2605 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2606
2607 AC_REQUIRE([CF_GXX_VERSION])
2608
2609 AC_LANG_SAVE
2610 AC_LANG_CPLUSPLUS
2611
2612 cat > conftest.$ac_ext <<EOF
2613 #line __oline__ "configure"
2614 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2615 EOF
2616
2617 if test "$INTEL_CPLUSPLUS" = yes
2618 then
2619 # The "-wdXXX" options suppress warnings:
2620 # remark #1419: external declaration in primary source file
2621 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2622 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2623 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2624 # remark #193: zero used for undefined preprocessing identifier
2625 # remark #593: variable "curs_sb_left_arrow" was set but never used
2626 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2627 # remark #869: parameter "tw" was never referenced
2628 # remark #981: operands are evaluated in unspecified order
2629 # warning #269: invalid format string conversion
2630
2631         AC_CHECKING([for $CC warning options])
2632         cf_save_CXXFLAGS="$CXXFLAGS"
2633         EXTRA_CXXFLAGS="-Wall"
2634         for cf_opt in \
2635                 wd1419 \
2636                 wd1682 \
2637                 wd1683 \
2638                 wd1684 \
2639                 wd193 \
2640                 wd279 \
2641                 wd593 \
2642                 wd810 \
2643                 wd869 \
2644                 wd981
2645         do
2646                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2647                 if AC_TRY_EVAL(ac_compile); then
2648                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2649                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2650                 fi
2651         done
2652         CXXFLAGS="$cf_save_CXXFLAGS"
2653
2654 elif test "$GXX" = yes
2655 then
2656         AC_CHECKING([for $CXX warning options])
2657         cf_save_CXXFLAGS="$CXXFLAGS"
2658         EXTRA_CXXFLAGS="-W -Wall"
2659         cf_gxx_extra_warnings=""
2660         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2661         case "$GCC_VERSION" in
2662         ([[1-2]].*)
2663                 ;;
2664         (*)
2665                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2666                 ;;
2667         esac
2668         for cf_opt in \
2669                 Wabi \
2670                 fabi-version=0 \
2671                 Wextra \
2672                 Wignored-qualifiers \
2673                 Wlogical-op \
2674                 Woverloaded-virtual \
2675                 Wsign-promo \
2676                 Wsynth \
2677                 Wold-style-cast \
2678                 Wcast-align \
2679                 Wcast-qual \
2680                 Wpointer-arith \
2681                 Wshadow \
2682                 Wundef $cf_gxx_extra_warnings $1
2683         do
2684                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2685                 if AC_TRY_EVAL(ac_compile); then
2686                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2687                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2688                 else
2689                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2690                 fi
2691         done
2692         CXXFLAGS="$cf_save_CXXFLAGS"
2693 fi
2694
2695 rm -rf conftest*
2696 AC_LANG_RESTORE
2697 AC_SUBST(EXTRA_CXXFLAGS)
2698 ])dnl
2699 dnl ---------------------------------------------------------------------------
2700 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
2701 dnl ------------
2702 dnl Look for an instance of the Berkeley hashed database.
2703 dnl
2704 dnl $1 = optional parameter, to specify install-prefix for the database.
2705 AC_DEFUN([CF_HASHED_DB],
2706 [
2707 ifelse([$1],,,[
2708 case $1 in
2709 (yes|*able*)
2710         ;;
2711 (*)
2712         if test -d "$1" ; then
2713                 CF_ADD_INCDIR($1/include)
2714                 CF_ADD_LIBDIR($1/lib)
2715         else
2716                 case "$1" in
2717                 (./*|../*|/*)
2718                         AC_MSG_WARN(no such directory $1)
2719                         ;;
2720                 (*)
2721                         CF_FIND_SUB_INCDIR($1)
2722                         CF_FIND_SUB_LIBDIR($1)
2723                         ;;
2724                 esac
2725         fi
2726 esac
2727 ])
2728 AC_CHECK_HEADER(db.h,[
2729 CF_HASHED_DB_VERSION
2730 if test "$cf_cv_hashed_db_version" = unknown ; then
2731         AC_MSG_ERROR(Cannot determine version of db)
2732 else
2733         CF_HASHED_DB_LIBS
2734         if test "$cf_cv_hashed_db_libs" = unknown ; then
2735                 AC_MSG_ERROR(Cannot determine library for db)
2736         elif test "$cf_cv_hashed_db_libs" != default ; then
2737                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2738         fi
2739 fi
2740 ],[
2741         AC_MSG_ERROR(Cannot find db.h)
2742 ])
2743 ])dnl
2744 dnl ---------------------------------------------------------------------------
2745 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2746 dnl -----------------
2747 dnl Given that we have the header and version for hashed database, find the
2748 dnl library information.
2749 AC_DEFUN([CF_HASHED_DB_LIBS],
2750 [
2751 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2752 cf_cv_hashed_db_libs=unknown
2753 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2754 do
2755         cf_save_libs="$LIBS"
2756         if test -n "$cf_db_libs"; then
2757                 CF_ADD_LIB($cf_db_libs)
2758         fi
2759         CF_MSG_LOG(checking for library "$cf_db_libs")
2760         AC_TRY_LINK([
2761 $ac_includes_default
2762 #include <db.h>
2763 ],[
2764         char *path = "/tmp/foo";
2765 #ifdef DB_VERSION_MAJOR
2766 #if DB_VERSION_MAJOR >= 4
2767         DB *result = 0;
2768         db_create(&result, NULL, 0);
2769         result->open(result,
2770                 NULL,
2771                 path,
2772                 path,
2773                 DB_HASH,
2774                 DB_CREATE,
2775                 0644);
2776 #elif DB_VERSION_MAJOR >= 3
2777         DB *result = 0;
2778         db_create(&result, NULL, 0);
2779         result->open(result,
2780                 path,
2781                 path,
2782                 DB_HASH,
2783                 DB_CREATE,
2784                 0644);
2785 #elif DB_VERSION_MAJOR >= 2
2786         DB *result = 0;
2787         db_open(path,
2788                 DB_HASH,
2789                 DB_CREATE,
2790                 0644,
2791                 (DB_ENV *) 0,
2792                 (DB_INFO *) 0,
2793                 &result);
2794 #endif /* DB_VERSION_MAJOR */
2795 #else
2796         DB *result = dbopen(path,
2797                      2,
2798                      0644,
2799                      DB_HASH,
2800                      0);
2801 #endif
2802         ${cf_cv_main_return:-return}(result != 0)
2803 ],[
2804         if test -n "$cf_db_libs" ; then
2805                 cf_cv_hashed_db_libs=$cf_db_libs
2806         else
2807                 cf_cv_hashed_db_libs=default
2808         fi
2809         LIBS="$cf_save_libs"
2810         break
2811 ])
2812         LIBS="$cf_save_libs"
2813 done
2814 ])
2815 ])dnl
2816 dnl ---------------------------------------------------------------------------
2817 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
2818 dnl --------------------
2819 dnl Given that we have the header file for hashed database, find the version
2820 dnl information.
2821 AC_DEFUN([CF_HASHED_DB_VERSION],
2822 [
2823 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2824 cf_cv_hashed_db_version=unknown
2825
2826 for cf_db_version in 1 2 3 4 5 6
2827 do
2828         CF_MSG_LOG(checking for db version $cf_db_version)
2829         AC_TRY_COMPILE([
2830 $ac_includes_default
2831 #include <db.h>
2832
2833 #ifdef DB_VERSION_MAJOR
2834         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2835 #if $cf_db_version == DB_VERSION_MAJOR
2836         /* ok */
2837 #else
2838         make an error
2839 #endif
2840 #else
2841 #if $cf_db_version == 1
2842         /* ok: assuming this is DB 1.8.5 */
2843 #else
2844         make an error
2845 #endif
2846 #endif
2847 ],[DBT *foo = 0],[
2848         cf_cv_hashed_db_version=$cf_db_version
2849         break
2850         ])
2851 done
2852 ])
2853 ])dnl
2854 dnl ---------------------------------------------------------------------------
2855 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
2856 dnl --------------
2857 dnl Construct a search-list of directories for a nonstandard header-file
2858 dnl
2859 dnl Parameters
2860 dnl     $1 = the variable to return as result
2861 dnl     $2 = the package name
2862 AC_DEFUN([CF_HEADER_PATH],
2863 [
2864 $1=
2865
2866 # collect the current set of include-directories from compiler flags
2867 cf_header_path_list=""
2868 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2869         for cf_header_path in $CPPFLAGS $CFLAGS
2870         do
2871                 case $cf_header_path in
2872                 (-I*)
2873                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2874                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2875                         cf_header_path_list="$cf_header_path_list [$]$1"
2876                         ;;
2877                 esac
2878         done
2879 fi
2880
2881 # add the variations for the package we are looking for
2882 CF_SUBDIR_PATH($1,$2,include)
2883
2884 test "$includedir" != NONE && \
2885 test "$includedir" != "/usr/include" && \
2886 test -d "$includedir" && {
2887         test -d $includedir &&    $1="[$]$1 $includedir"
2888         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2889 }
2890
2891 test "$oldincludedir" != NONE && \
2892 test "$oldincludedir" != "/usr/include" && \
2893 test -d "$oldincludedir" && {
2894         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2895         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2896 }
2897
2898 $1="[$]$1 $cf_header_path_list"
2899 ])dnl
2900 dnl ---------------------------------------------------------------------------
2901 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2902 dnl ---------------
2903 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2904 AC_DEFUN([CF_HELP_MESSAGE],
2905 [AC_DIVERT_HELP([$1])dnl
2906 ])dnl
2907 dnl ---------------------------------------------------------------------------
2908 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
2909 dnl ---------------
2910 dnl Construct the list of include-options according to whether we're building
2911 dnl in the source directory or using '--srcdir=DIR' option.
2912 AC_DEFUN([CF_INCLUDE_DIRS],
2913 [
2914 if test "$srcdir" != "."; then
2915         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
2916 fi
2917 CPPFLAGS="-I../include $CPPFLAGS"
2918 if test "$srcdir" != "."; then
2919         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
2920 fi
2921 CPPFLAGS="-I. $CPPFLAGS"
2922 AC_SUBST(CPPFLAGS)
2923 ])dnl
2924 dnl ---------------------------------------------------------------------------
2925 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
2926 dnl -----------------
2927 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2928 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2929 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2930 dnl
2931 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2932 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2933 dnl the wrappers for gcc and g++ warnings.
2934 dnl
2935 dnl $1 = GCC (default) or GXX
2936 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2937 dnl $3 = CFLAGS (default) or CXXFLAGS
2938 AC_DEFUN([CF_INTEL_COMPILER],[
2939 AC_REQUIRE([AC_CANONICAL_HOST])
2940 ifelse([$2],,INTEL_COMPILER,[$2])=no
2941
2942 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2943         case $host_os in
2944         (linux*|gnu*)
2945                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2946                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2947                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2948                 AC_TRY_COMPILE([],[
2949 #ifdef __INTEL_COMPILER
2950 #else
2951 make an error
2952 #endif
2953 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2954 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2955 ],[])
2956                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2957                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2958                 ;;
2959         esac
2960 fi
2961 ])dnl
2962 dnl ---------------------------------------------------------------------------
2963 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
2964 dnl ----------
2965 dnl Check if we have either a function or macro for 'isascii()'.
2966 AC_DEFUN([CF_ISASCII],
2967 [
2968 AC_MSG_CHECKING(for isascii)
2969 AC_CACHE_VAL(cf_cv_have_isascii,[
2970         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2971         [cf_cv_have_isascii=yes],
2972         [cf_cv_have_isascii=no])
2973 ])dnl
2974 AC_MSG_RESULT($cf_cv_have_isascii)
2975 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
2976 ])dnl
2977 dnl ---------------------------------------------------------------------------
2978 dnl CF_LARGEFILE version: 9 updated: 2015/04/18 08:56:57
2979 dnl ------------
2980 dnl Add checks for large file support.
2981 AC_DEFUN([CF_LARGEFILE],[
2982 ifdef([AC_FUNC_FSEEKO],[
2983         AC_SYS_LARGEFILE
2984         if test "$enable_largefile" != no ; then
2985         AC_FUNC_FSEEKO
2986
2987         # Normally we would collect these definitions in the config.h,
2988         # but (like _XOPEN_SOURCE), some environments rely on having these
2989         # defined before any of the system headers are included.  Another
2990         # case comes up with C++, e.g., on AIX the compiler compiles the
2991         # header files by themselves before looking at the body files it is
2992         # told to compile.  For ncurses, those header files do not include
2993         # the config.h
2994         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2995         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2996         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2997
2998         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2999                 AC_TRY_COMPILE([
3000 #include <sys/types.h>
3001 #include <dirent.h>
3002                 ],[
3003                 /* if transitional largefile support is setup, this is true */
3004                 extern struct dirent64 * readdir(DIR *);
3005                 struct dirent64 *x = readdir((DIR *)0);
3006                 struct dirent *y = readdir((DIR *)0);
3007                 int z = x - y;
3008                 ],
3009                 [cf_cv_struct_dirent64=yes],
3010                 [cf_cv_struct_dirent64=no])
3011         ])
3012         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3013         fi
3014 ])
3015 ])
3016 dnl ---------------------------------------------------------------------------
3017 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3018 dnl -----------------
3019 dnl Check for compiler/linker flags used to temporarily force usage of static
3020 dnl libraries.  This depends on the compiler and platform.  Use this to help
3021 dnl ensure that the linker picks up a given library based on its position in
3022 dnl the list of linker options and libraries.
3023 AC_DEFUN([CF_LDFLAGS_STATIC],[
3024
3025 if test "$GCC" = yes ; then
3026         case $cf_cv_system_name in
3027         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3028                 LDFLAGS_STATIC=
3029                 LDFLAGS_SHARED=
3030                 ;;
3031         (*)     # normally, except when broken
3032                 LDFLAGS_STATIC=-static
3033                 LDFLAGS_SHARED=-dynamic
3034                 ;;
3035         esac
3036 else
3037         case $cf_cv_system_name in
3038         (aix[[4-7]]*)   # from ld manpage
3039                 LDFLAGS_STATIC=-bstatic
3040                 LDFLAGS_SHARED=-bdynamic
3041                 ;;
3042         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3043                 # We could also use just "archive" and "shared".
3044                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3045                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3046                 ;;
3047         (irix*)         # from ld manpage IRIX64
3048                 LDFLAGS_STATIC=-Bstatic
3049                 LDFLAGS_SHARED=-Bdynamic
3050                 ;;
3051         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3052                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3053                 LDFLAGS_STATIC=-noso
3054                 LDFLAGS_SHARED=-so_archive
3055                 ;;
3056         (solaris2*)
3057                 LDFLAGS_STATIC=-Bstatic
3058                 LDFLAGS_SHARED=-Bdynamic
3059                 ;;
3060         esac
3061 fi
3062
3063 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3064 then
3065         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3066
3067         rm -f libconftest.a
3068         cat >conftest.$ac_ext <<EOF
3069 #line __oline__ "configure"
3070 #include <stdio.h>
3071 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3072 EOF
3073         if AC_TRY_EVAL(ac_compile) ; then
3074                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3075                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3076         fi
3077         rm -f conftest.*
3078
3079         cf_save_LIBS="$LIBS"
3080
3081         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3082         AC_TRY_LINK([
3083 #line __oline__ "configure"
3084 #include <stdio.h>
3085 int cf_ldflags_static(FILE *fp);
3086 ],[
3087         return cf_ldflags_static(stdin);
3088 ],[
3089         # some linkers simply ignore the -dynamic
3090         case x`file conftest$ac_exeext 2>/dev/null` in
3091         (*static*)
3092                 cf_ldflags_static=no
3093                 ;;
3094         (*)
3095                 cf_ldflags_static=yes
3096                 ;;
3097         esac
3098 ],[cf_ldflags_static=no])
3099
3100         rm -f libconftest.*
3101         LIBS="$cf_save_LIBS"
3102
3103         AC_MSG_RESULT($cf_ldflags_static)
3104
3105         if test $cf_ldflags_static != yes
3106         then
3107                 LDFLAGS_STATIC=
3108                 LDFLAGS_SHARED=
3109         fi
3110 else
3111         LDFLAGS_STATIC=
3112         LDFLAGS_SHARED=
3113 fi
3114
3115 AC_SUBST(LDFLAGS_STATIC)
3116 AC_SUBST(LDFLAGS_SHARED)
3117 ])
3118 dnl ---------------------------------------------------------------------------
3119 dnl CF_LD_RPATH_OPT version: 6 updated: 2015/04/12 15:39:00
3120 dnl ---------------
3121 dnl For the given system and compiler, find the compiler flags to pass to the
3122 dnl loader to use the "rpath" feature.
3123 AC_DEFUN([CF_LD_RPATH_OPT],
3124 [
3125 AC_REQUIRE([CF_CHECK_CACHE])
3126
3127 LD_RPATH_OPT=
3128 AC_MSG_CHECKING(for an rpath option)
3129 case $cf_cv_system_name in
3130 (irix*)
3131         if test "$GCC" = yes; then
3132                 LD_RPATH_OPT="-Wl,-rpath,"
3133         else
3134                 LD_RPATH_OPT="-rpath "
3135         fi
3136         ;;
3137 (linux*|gnu*|k*bsd*-gnu)
3138         LD_RPATH_OPT="-Wl,-rpath,"
3139         ;;
3140 (openbsd[[2-9]].*|mirbsd*)
3141         LD_RPATH_OPT="-Wl,-rpath,"
3142         ;;
3143 (dragonfly*|freebsd*)
3144         LD_RPATH_OPT="-rpath "
3145         ;;
3146 (netbsd*)
3147         LD_RPATH_OPT="-Wl,-rpath,"
3148         ;;
3149 (osf*|mls+*)
3150         LD_RPATH_OPT="-rpath "
3151         ;;
3152 (solaris2*)
3153         LD_RPATH_OPT="-R"
3154         ;;
3155 (*)
3156         ;;
3157 esac
3158 AC_MSG_RESULT($LD_RPATH_OPT)
3159
3160 case "x$LD_RPATH_OPT" in
3161 (x-R*)
3162         AC_MSG_CHECKING(if we need a space after rpath option)
3163         cf_save_LIBS="$LIBS"
3164         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3165         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3166         LIBS="$cf_save_LIBS"
3167         AC_MSG_RESULT($cf_rpath_space)
3168         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3169         ;;
3170 esac
3171 ])dnl
3172 dnl ---------------------------------------------------------------------------
3173 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3174 dnl ---------------
3175 dnl Construct a search-list of directories for a nonstandard library-file
3176 dnl
3177 dnl Parameters
3178 dnl     $1 = the variable to return as result
3179 dnl     $2 = the package name
3180 AC_DEFUN([CF_LIBRARY_PATH],
3181 [
3182 $1=
3183 cf_library_path_list=""
3184 if test -n "${LDFLAGS}${LIBS}" ; then
3185         for cf_library_path in $LDFLAGS $LIBS
3186         do
3187                 case $cf_library_path in
3188                 (-L*)
3189                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3190                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3191                         cf_library_path_list="$cf_library_path_list [$]$1"
3192                         ;;
3193                 esac
3194         done
3195 fi
3196
3197 CF_SUBDIR_PATH($1,$2,lib)
3198
3199 $1="$cf_library_path_list [$]$1"
3200 ])dnl
3201 dnl ---------------------------------------------------------------------------
3202 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3203 dnl ------------------
3204 AC_DEFUN([CF_LIBTOOL_VERSION],[
3205 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3206 then
3207         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3208 else
3209         cf_cv_libtool_version=
3210 fi
3211 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3212 ])dnl
3213 dnl ---------------------------------------------------------------------------
3214 dnl CF_LIB_PREFIX version: 11 updated: 2015/04/18 08:56:57
3215 dnl -------------
3216 dnl Compute the library-prefix for the given host system
3217 dnl $1 = variable to set
3218 define([CF_LIB_PREFIX],
3219 [
3220         case $cf_cv_system_name in
3221         (OS/2*|os2*)
3222                 LIB_PREFIX=''
3223                 ;;
3224         (*)     LIB_PREFIX='lib'
3225                 ;;
3226         esac
3227 ifelse($1,,,[$1=$LIB_PREFIX])
3228         AC_SUBST(LIB_PREFIX)
3229 ])dnl
3230 dnl ---------------------------------------------------------------------------
3231 dnl CF_LIB_RULES version: 82 updated: 2015/06/27 19:09:23
3232 dnl ------------
3233 dnl Append definitions and rules for the given models to the subdirectory
3234 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3235 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3236 dnl the corresponding makefile to list the models that we'll generate.
3237 dnl
3238 dnl For shared libraries, make a list of symbolic links to construct when
3239 dnl generating each library.  The convention used for Linux is the simplest
3240 dnl one:
3241 dnl     lib<name>.so    ->
3242 dnl     lib<name>.so.<major>    ->
3243 dnl     lib<name>.so.<maj>.<minor>
3244 dnl
3245 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3246 AC_DEFUN([CF_LIB_RULES],
3247 [
3248 cf_prefix=$LIB_PREFIX
3249 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3250
3251 case $cf_cv_shlib_version in
3252 (cygdll|msysdll|mingw)
3253         TINFO_NAME=$TINFO_ARG_SUFFIX
3254         TINFO_SUFFIX=.dll
3255         ;;
3256 esac
3257
3258 if test -n "$TINFO_SUFFIX" ; then
3259         case $TINFO_SUFFIX in
3260         (tw*)
3261                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
3262                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
3263                 ;;
3264         (t*)
3265                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
3266                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
3267                 ;;
3268         (w*)
3269                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
3270                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
3271                 ;;
3272         esac
3273 fi
3274
3275 for cf_dir in $SRC_SUBDIRS
3276 do
3277         if test ! -d $srcdir/$cf_dir ; then
3278                 continue
3279         elif test -f $srcdir/$cf_dir/modules; then
3280
3281                 SHARED_LIB=
3282                 Libs_To_Make=
3283
3284                 cf_sed_options=
3285                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3286                 then
3287                         cf_sed_options="$cf_sed_options -e \"s/NCURSES\\([[WT]]\\+\\)\?_/NCURSES\\1${cf_cv_abi_version}_/g\""
3288                         cf_sed_options="$cf_sed_options -e \"/deprecated in ABI${cf_cv_abi_version}/d\""
3289                 fi
3290
3291                 if test "x$WILDCARD_SYMS" = xno
3292                 then
3293                         cf_sed_options="$cf_sed_options -e \"s/_\*;//g\""
3294                 fi
3295
3296                 if test "x$cf_sed_options" != "x"
3297                 then
3298                         cat >>$cf_dir/Makefile <<CF_EOF
3299
3300 # Generated by CF_LIB_RULES
3301 resulting.map: $UNALTERED_SYMS
3302         sed $cf_sed_options < $UNALTERED_SYMS >\[$]@
3303
3304 clean::
3305         rm -f resulting.map
3306 CF_EOF
3307                 fi
3308
3309                 for cf_item in $cf_LIST_MODELS
3310                 do
3311                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3312                         cf_libname=$cf_dir
3313                         test "$cf_dir" = c++ && cf_libname=ncurses++
3314                         if test $cf_item = shared ; then
3315                                 if test -n "${LIB_SUFFIX}"
3316                                 then
3317                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3318                                 else
3319                                         cf_shared_suffix="$cf_suffix"
3320                                 fi
3321                                 if test "$cf_cv_do_symlinks" = yes ; then
3322                                         cf_version_name=
3323
3324                                         case "$cf_cv_shlib_version" in
3325                                         (rel)
3326                                                 cf_version_name=REL_VERSION
3327                                                 ;;
3328                                         (abi)
3329                                                 cf_version_name=ABI_VERSION
3330                                                 ;;
3331                                         esac
3332
3333                                         if test -n "$cf_version_name"
3334                                         then
3335                                                 case "$cf_cv_system_name" in
3336                                                 (darwin*)
3337                                                         # "w", etc?
3338                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3339                                                         ;;
3340                                                 (*)
3341                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3342                                                         ;;
3343                                                 esac
3344                                         fi
3345                                         if test -n "${USE_LIB_SUFFIX}"
3346                                         then
3347                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3348                                         else
3349                                                 cf_shared_suffix="$cf_suffix"
3350                                         fi
3351                                 fi
3352                                 # cygwin needs import library, and has unique naming convention
3353                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3354                                 # use 'cyg' prefix for shared lib.
3355                                 case $cf_cv_shlib_version in
3356                                 (cygdll)
3357                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3358                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
3359                                         ;;
3360                                 (msysdll)
3361                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3362                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
3363                                         ;;
3364                                 (mingw)
3365                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3366                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
3367                                         ;;
3368                                 (*)
3369                                         cf_add_lib=
3370                                         ;;
3371                                 esac
3372                                 if test -n "$cf_add_lib"
3373                                 then
3374                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3375                                         continue
3376                                 fi
3377                         fi
3378                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3379                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3380                 done
3381
3382                 if test $cf_dir = ncurses ; then
3383                         cf_subsets="$LIB_SUBSETS"
3384                         cf_r_parts="$cf_subsets"
3385                         cf_liblist="$Libs_To_Make"
3386
3387                         while test -n "$cf_r_parts"
3388                         do
3389                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3390                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3391                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3392                                         cf_add_lib=
3393                                         case $cf_l_parts in
3394                                         (*termlib*)
3395                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3396                                                 ;;
3397                                         (*ticlib*)
3398                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3399                                                 ;;
3400                                         (*)
3401                                                 break
3402                                                 ;;
3403                                         esac
3404                                         if test -n "$cf_add_lib"; then
3405                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
3406                                         fi
3407                                 else
3408                                         break
3409                                 fi
3410                         done
3411                 else
3412                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3413                 fi
3414
3415                 if test $cf_dir = c++; then
3416                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3417                                 cf_list=
3418                                 for cf_item in $Libs_To_Make
3419                                 do
3420                                         case $cf_item in
3421                                         (*.a)
3422                                                 ;;
3423                                         (*)
3424                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3425                                                 ;;
3426                                         esac
3427                                         for cf_test in $cf_list
3428                                         do
3429                                                 if test "$cf_test" = "$cf_item"
3430                                                 then
3431                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3432                                                         cf_item=
3433                                                         break
3434                                                 fi
3435                                         done
3436                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3437                                 done
3438                                 Libs_To_Make="$cf_list"
3439                         fi
3440                 fi
3441
3442                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3443                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3444                         $cf_dir/Makefile >$cf_dir/Makefile.out
3445                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3446
3447                 $AWK -f $srcdir/mk-0th.awk \
3448                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3449                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3450
3451                 for cf_subset in $cf_subsets
3452                 do
3453                         cf_subdirs=
3454                         for cf_item in $cf_LIST_MODELS
3455                         do
3456
3457                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3458                         CF_UPPER(cf_ITEM,$cf_item)
3459
3460                         CXX_MODEL=$cf_ITEM
3461                         if test "$CXX_MODEL" = SHARED; then
3462                                 case $cf_cv_shlib_version in
3463                                 (cygdll|msysdll|mingw)
3464                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3465                                         with_shared_cxx=yes
3466                                         ;;
3467                                 (*)
3468                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3469                                         ;;
3470                                 esac
3471                         fi
3472
3473                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3474                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3475
3476                         # Test for case where we build libtinfo with a different name.
3477                         cf_libname=$cf_dir
3478                         if test $cf_dir = ncurses ; then
3479                                 case $cf_subset in
3480                                 (*base*)
3481                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
3482                                         ;;
3483                                 (*termlib*)
3484                                         cf_libname=$TINFO_LIB_SUFFIX
3485                                         ;;
3486                                 (ticlib*)
3487                                         cf_libname=$TICS_LIB_SUFFIX
3488                                         ;;
3489                                 esac
3490                         elif test $cf_dir = c++ ; then
3491                                 cf_libname=ncurses++$USE_LIB_SUFFIX
3492                         else
3493                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
3494                         fi
3495                         if test -n "${USE_ARG_SUFFIX}" ; then
3496                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
3497                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
3498                         fi
3499
3500                         # These dependencies really are for development, not
3501                         # builds, but they are useful in porting, too.
3502                         cf_depend="../include/ncurses_cfg.h"
3503                         if test "$srcdir" = "."; then
3504                                 cf_reldir="."
3505                         else
3506                                 cf_reldir="\${srcdir}"
3507                         fi
3508
3509                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3510                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3511                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3512                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3513                         fi
3514
3515                         cf_dir_suffix=
3516                         old_cf_suffix="$cf_suffix"
3517                         if test "$cf_cv_shlib_version_infix" = yes ; then
3518                         if test -n "$USE_LIB_SUFFIX" ; then
3519                                 case $USE_LIB_SUFFIX in
3520                                 (tw*)
3521                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
3522                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
3523                                         cf_dir_suffix=tw$EXTRA_SUFFIX
3524                                         ;;
3525                                 (t*)
3526                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
3527                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
3528                                         cf_dir_suffix=t$EXTRA_SUFFIX
3529                                         ;;
3530                                 (w*)
3531                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
3532                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
3533                                         cf_dir_suffix=w$EXTRA_SUFFIX
3534                                         ;;
3535                                 (*)
3536                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
3537                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
3538                                         cf_dir_suffix=$EXTRA_SUFFIX
3539                                         ;;
3540                                 esac
3541                         fi
3542                         fi
3543
3544                         $AWK -f $srcdir/mk-1st.awk \
3545                                 name=${cf_libname}${cf_dir_suffix} \
3546                                 traces=$LIB_TRACING \
3547                                 MODEL=$cf_ITEM \
3548                                 CXX_MODEL=$CXX_MODEL \
3549                                 model=$cf_subdir \
3550                                 prefix=$cf_prefix \
3551                                 suffix=$cf_suffix \
3552                                 subset=$cf_subset \
3553                                 driver=$cf_cv_term_driver \
3554                                 SymLink="$LN_S" \
3555                                 TermlibRoot=$TINFO_NAME \
3556                                 TermlibSuffix=$TINFO_SUFFIX \
3557                                 ShlibVer=$cf_cv_shlib_version \
3558                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3559                                 ReLink=${cf_cv_do_relink:-no} \
3560                                 DoLinks=$cf_cv_do_symlinks \
3561                                 rmSoLocs=$cf_cv_rm_so_locs \
3562                                 ldconfig="$LDCONFIG" \
3563                                 overwrite=$WITH_OVERWRITE \
3564                                 depend="$cf_depend" \
3565                                 host="$host" \
3566                                 libtool_version="$LIBTOOL_VERSION" \
3567                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3568
3569                         cf_suffix="$old_cf_suffix"
3570
3571                         for cf_subdir2 in $cf_subdirs lib
3572                         do
3573                                 test $cf_subdir = $cf_subdir2 && break
3574                         done
3575                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3576                         $AWK -f $srcdir/mk-2nd.awk \
3577                                 name=$cf_dir \
3578                                 traces=$LIB_TRACING \
3579                                 MODEL=$cf_ITEM \
3580                                 model=$cf_subdir \
3581                                 subset=$cf_subset \
3582                                 srcdir=$srcdir \
3583                                 echo=$WITH_ECHO \
3584                                 crenames=$cf_cv_prog_CC_c_o \
3585                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3586                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3587                         cf_subdirs="$cf_subdirs $cf_subdir"
3588                         done
3589                 done
3590         fi
3591
3592         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3593 done
3594
3595 for cf_dir in $SRC_SUBDIRS
3596 do
3597         if test ! -d $srcdir/$cf_dir ; then
3598                 continue
3599         fi
3600
3601         if test -f $cf_dir/Makefile ; then
3602                 case "$cf_dir" in
3603                 (Ada95)
3604                         echo 'libs \' >> Makefile
3605                         echo 'install.libs \' >> Makefile
3606                         echo 'uninstall.libs ::' >> Makefile
3607                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3608                         ;;
3609                 esac
3610         fi
3611
3612         if test -f $srcdir/$cf_dir/modules; then
3613                 echo >> Makefile
3614                 if test -f $srcdir/$cf_dir/headers; then
3615 cat >> Makefile <<CF_EOF
3616 install.includes \\
3617 uninstall.includes \\
3618 CF_EOF
3619                 fi
3620 if test "$cf_dir" != "c++" ; then
3621 echo 'lint \' >> Makefile
3622 fi
3623 cat >> Makefile <<CF_EOF
3624 libs \\
3625 lintlib \\
3626 install.libs \\
3627 uninstall.libs \\
3628 install.$cf_dir \\
3629 uninstall.$cf_dir ::
3630         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3631 CF_EOF
3632         elif test -f $srcdir/$cf_dir/headers; then
3633 cat >> Makefile <<CF_EOF
3634
3635 libs \\
3636 install.libs \\
3637 uninstall.libs \\
3638 install.includes \\
3639 uninstall.includes ::
3640         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3641 CF_EOF
3642 fi
3643 done
3644
3645 if test "x$cf_with_db_install" = xyes; then
3646 cat >> Makefile <<CF_EOF
3647
3648 install.libs uninstall.libs \\
3649 install.data uninstall.data ::
3650 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3651 CF_EOF
3652 else
3653 cat >> Makefile <<CF_EOF
3654
3655 install.libs uninstall.libs ::
3656         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3657 CF_EOF
3658 fi
3659
3660 if test "x$cf_with_manpages" = xyes; then
3661 cat >> Makefile <<CF_EOF
3662
3663 install.man \\
3664 uninstall.man ::
3665         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3666 CF_EOF
3667 fi
3668
3669 cat >> Makefile <<CF_EOF
3670
3671 distclean ::
3672         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3673         rm -f headers.sh headers.sed mk_shared_lib.sh
3674         rm -f edit_man.* man_alias.*
3675         rm -rf \${DIRS_TO_MAKE}
3676 CF_EOF
3677
3678 # Special case: tack's manpage lives in its own directory.
3679 if test "x$cf_with_manpages" = xyes; then
3680 if test -d tack ; then
3681 if test -f $srcdir/$tack.h; then
3682 cat >> Makefile <<CF_EOF
3683
3684 install.man \\
3685 uninstall.man ::
3686         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3687 CF_EOF
3688 fi
3689 fi
3690 fi
3691
3692 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3693 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3694 dnl anything, and will make it more standardized.  It's awkward to decide this
3695 dnl at configuration because of quoting, so we'll simply make all headers
3696 dnl installed via a script that can do the right thing.
3697
3698 rm -f headers.sed headers.sh
3699
3700 dnl ( generating this script makes the makefiles a little tidier :-)
3701 echo creating headers.sh
3702 cat >headers.sh <<CF_EOF
3703 #! /bin/sh
3704 # This shell script is generated by the 'configure' script.  It is invoked in a
3705 # subdirectory of the build tree.  It generates a sed-script in the parent
3706 # directory that is used to adjust includes for header files that reside in a
3707 # subdirectory of /usr/include, etc.
3708 PRG=""
3709 while test \[$]# != 3
3710 do
3711 PRG="\$PRG \[$]1"; shift
3712 done
3713 DST=\[$]1
3714 REF=\[$]2
3715 SRC=\[$]3
3716 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3717 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3718 echo installing \$SRC in \$DST
3719 CF_EOF
3720
3721 if test $WITH_CURSES_H = yes; then
3722         cat >>headers.sh <<CF_EOF
3723 case \$DST in
3724 (/*/include/*)
3725         END=\`basename \$DST\`
3726         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3727         do
3728                 NAME=\`basename \$i\`
3729                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3730         done
3731         ;;
3732 (*)
3733         echo "" >> \$TMPSED
3734         ;;
3735 esac
3736 CF_EOF
3737
3738 else
3739         cat >>headers.sh <<CF_EOF
3740 case \$DST in
3741 (/*/include/*)
3742         END=\`basename \$DST\`
3743         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3744         do
3745                 NAME=\`basename \$i\`
3746                 if test "\$NAME" = "curses.h"
3747                 then
3748                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3749                         NAME=ncurses.h
3750                 fi
3751                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3752         done
3753         ;;
3754 (*)
3755         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3756         ;;
3757 esac
3758 CF_EOF
3759 fi
3760 cat >>headers.sh <<CF_EOF
3761 rm -f \$TMPSRC
3762 sed -f \$TMPSED \$SRC > \$TMPSRC
3763 NAME=\`basename \$SRC\`
3764 CF_EOF
3765 if test $WITH_CURSES_H != yes; then
3766         cat >>headers.sh <<CF_EOF
3767 test "\$NAME" = "curses.h" && NAME=ncurses.h
3768 CF_EOF
3769 fi
3770 cat >>headers.sh <<CF_EOF
3771 # Just in case someone gzip'd manpages, remove the conflicting copy.
3772 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3773
3774 eval \$PRG \$TMPSRC \$DST/\$NAME
3775 rm -f \$TMPSRC \$TMPSED
3776 CF_EOF
3777
3778 chmod 0755 headers.sh
3779
3780 for cf_dir in $SRC_SUBDIRS
3781 do
3782         if test ! -d $srcdir/$cf_dir ; then
3783                 continue
3784         fi
3785
3786         if test -f $srcdir/$cf_dir/headers; then
3787                 $AWK -f $srcdir/mk-hdr.awk \
3788                         subset="$LIB_SUBSETS" \
3789                         compat="$WITH_CURSES_H" \
3790                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3791         fi
3792
3793         if test -f $srcdir/$cf_dir/modules; then
3794                 if test "$cf_dir" != "c++" ; then
3795                         cat >>$cf_dir/Makefile <<"CF_EOF"
3796 depend : ${AUTO_SRC}
3797         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3798
3799 # DO NOT DELETE THIS LINE -- make depend depends on it.
3800 CF_EOF
3801                 fi
3802         fi
3803 done
3804 AC_SUBST(Libs_To_Make)
3805 ])dnl
3806 dnl ---------------------------------------------------------------------------
3807 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3808 dnl -------------
3809 dnl Find the and soname for the given shared library.  Set the cache variable
3810 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3811 dnl variable to "unknown".
3812 dnl
3813 dnl $1 = headers
3814 dnl $2 = code
3815 dnl $3 = library name
3816 AC_DEFUN([CF_LIB_SONAME],
3817 [
3818 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3819
3820 cf_cv_$3_soname=unknown
3821 if test "$cross_compiling" != yes ; then
3822 cat >conftest.$ac_ext <<CF_EOF
3823 $1
3824 int main()
3825 {
3826 $2
3827         ${cf_cv_main_return:-return}(0);
3828 }
3829 CF_EOF
3830 cf_save_LIBS="$LIBS"
3831         CF_ADD_LIB($3)
3832         if AC_TRY_EVAL(ac_compile) ; then
3833                 if AC_TRY_EVAL(ac_link) ; then
3834                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3835                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3836                 fi
3837         fi
3838 rm -rf conftest*
3839 LIBS="$cf_save_LIBS"
3840 fi
3841 ])
3842 ])
3843 dnl ---------------------------------------------------------------------------
3844 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
3845 dnl -------------
3846 dnl Compute the library file-suffix from the given model name
3847 dnl $1 = model name
3848 dnl $2 = variable to set (the nominal library suffix)
3849 dnl $3 = dependency variable to set (actual filename)
3850 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3851 AC_DEFUN([CF_LIB_SUFFIX],
3852 [
3853         case X$1 in
3854         (Xlibtool)
3855                 $2='.la'
3856                 $3=[$]$2
3857                 ;;
3858         (Xdebug)
3859                 $2='_g.a'
3860                 $3=[$]$2
3861                 ;;
3862         (Xprofile)
3863                 $2='_p.a'
3864                 $3=[$]$2
3865                 ;;
3866         (Xshared)
3867                 case $cf_cv_system_name in
3868                 (aix[[5-7]]*)
3869                         $2='.so'
3870                         $3=[$]$2
3871                         ;;
3872                 (cygwin*|msys*|mingw*)
3873                         $2='.dll'
3874                         $3='.dll.a'
3875                         ;;
3876                 (darwin*)
3877                         $2='.dylib'
3878                         $3=[$]$2
3879                         ;;
3880                 (hpux*)
3881                         case $target in
3882                         (ia64*)
3883                                 $2='.so'
3884                                 $3=[$]$2
3885                                 ;;
3886                         (*)
3887                                 $2='.sl'
3888                                 $3=[$]$2
3889                                 ;;
3890                         esac
3891                         ;;
3892                 (*)
3893                         $2='.so'
3894                         $3=[$]$2
3895                         ;;
3896                 esac
3897                 ;;
3898         (*)
3899                 $2='.a'
3900                 $3=[$]$2
3901                 ;;
3902         esac
3903         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
3904         then
3905                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
3906                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
3907         fi
3908 ])dnl
3909 dnl ---------------------------------------------------------------------------
3910 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
3911 dnl -----------
3912 dnl Compute the string to append to -library from the given model name
3913 dnl $1 = model name
3914 dnl $2 = variable to set
3915 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3916 AC_DEFUN([CF_LIB_TYPE],
3917 [
3918         case $1 in
3919         (libtool) $2=''   ;;
3920         (normal)  $2=''   ;;
3921         (debug)   $2='_g' ;;
3922         (profile) $2='_p' ;;
3923         (shared)  $2=''   ;;
3924         esac
3925         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3926 ])dnl
3927 dnl ---------------------------------------------------------------------------
3928 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
3929 dnl ----------------
3930 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3931 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3932 dnl have to provide wrappers for global tables to ensure they're linked
3933 dnl properly.
3934 AC_DEFUN([CF_LINK_DATAONLY],
3935 [
3936 AC_MSG_CHECKING([if data-only library module links])
3937 AC_CACHE_VAL(cf_cv_link_dataonly,[
3938         rm -f conftest.a
3939         cat >conftest.$ac_ext <<EOF
3940 #line __oline__ "configure"
3941 int     testdata[[3]] = { 123, 456, 789 };
3942 EOF
3943         if AC_TRY_EVAL(ac_compile) ; then
3944                 mv conftest.o data.o && \
3945                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3946         fi
3947         rm -f conftest.$ac_ext data.o
3948         cat >conftest.$ac_ext <<EOF
3949 #line __oline__ "configure"
3950 int     testfunc()
3951 {
3952 #if defined(NeXT)
3953         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3954 #else
3955         extern int testdata[[3]];
3956         return testdata[[0]] == 123
3957            &&  testdata[[1]] == 456
3958            &&  testdata[[2]] == 789;
3959 #endif
3960 }
3961 EOF
3962         if AC_TRY_EVAL(ac_compile); then
3963                 mv conftest.o func.o && \
3964                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3965         fi
3966         rm -f conftest.$ac_ext func.o
3967         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3968         cf_saveLIBS="$LIBS"
3969         LIBS="conftest.a $LIBS"
3970         AC_TRY_RUN([
3971         int main()
3972         {
3973                 extern int testfunc();
3974                 ${cf_cv_main_return:-return} (!testfunc());
3975         }
3976         ],
3977         [cf_cv_link_dataonly=yes],
3978         [cf_cv_link_dataonly=no],
3979         [cf_cv_link_dataonly=unknown])
3980         LIBS="$cf_saveLIBS"
3981         ])
3982 AC_MSG_RESULT($cf_cv_link_dataonly)
3983
3984 if test "$cf_cv_link_dataonly" = no ; then
3985         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
3986         BROKEN_LINKER=1
3987 fi
3988
3989 ])dnl
3990 dnl ---------------------------------------------------------------------------
3991 dnl CF_LINK_FUNCS version: 8 updated: 2012/10/06 17:56:13
3992 dnl -------------
3993 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3994 dnl A few non-Unix systems implement symlink, but not link.
3995 dnl A few non-systems implement neither (or have nonfunctional versions).
3996 AC_DEFUN([CF_LINK_FUNCS],
3997 [
3998 AC_CHECK_FUNCS( \
3999         remove \
4000         unlink )
4001
4002 if test "$cross_compiling" = yes ; then
4003         AC_CHECK_FUNCS( \
4004                 link \
4005                 symlink )
4006 else
4007         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
4008                 cf_cv_link_funcs=
4009                 for cf_func in link symlink ; do
4010                         AC_TRY_RUN([
4011 #include <sys/types.h>
4012 #include <sys/stat.h>
4013 #ifdef HAVE_UNISTD_H
4014 #include <unistd.h>
4015 #endif
4016 int main()
4017 {
4018         int fail = 0;
4019         char *src = "config.log";
4020         char *dst = "conftest.chk";
4021         struct stat src_sb;
4022         struct stat dst_sb;
4023
4024         stat(src, &src_sb);
4025         fail = ($cf_func("config.log", "conftest.chk") < 0)
4026             || (stat(dst, &dst_sb) < 0)
4027             || (dst_sb.st_mtime != src_sb.st_mtime);
4028 #ifdef HAVE_UNLINK
4029         unlink(dst);
4030 #else
4031         remove(dst);
4032 #endif
4033         ${cf_cv_main_return:-return} (fail);
4034 }
4035                         ],[
4036                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
4037                         eval 'ac_cv_func_'$cf_func'=yes'],[
4038                         eval 'ac_cv_func_'$cf_func'=no'],[
4039                         eval 'ac_cv_func_'$cf_func'=error'])
4040                 done
4041                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
4042         ])
4043         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
4044         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
4045 fi
4046 ])dnl
4047 dnl ---------------------------------------------------------------------------
4048 dnl CF_MAKEFLAGS version: 16 updated: 2015/04/15 19:08:48
4049 dnl ------------
4050 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
4051 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
4052 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
4053 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
4054 AC_DEFUN([CF_MAKEFLAGS],
4055 [
4056 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
4057         cf_cv_makeflags=''
4058         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
4059         do
4060                 cat >cf_makeflags.tmp <<CF_EOF
4061 SHELL = /bin/sh
4062 all :
4063         @ echo '.$cf_option'
4064 CF_EOF
4065                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
4066                 case "$cf_result" in
4067                 (.*k|.*kw)
4068                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
4069                         case "$cf_result" in
4070                         (.*CC=*)        cf_cv_makeflags=
4071                                 ;;
4072                         (*)     cf_cv_makeflags=$cf_option
4073                                 ;;
4074                         esac
4075                         break
4076                         ;;
4077                 (.-)    ;;
4078                 (*)     echo "given option \"$cf_option\", no match \"$cf_result\""
4079                         ;;
4080                 esac
4081         done
4082         rm -f cf_makeflags.tmp
4083 ])
4084
4085 AC_SUBST(cf_cv_makeflags)
4086 ])dnl
4087 dnl ---------------------------------------------------------------------------
4088 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
4089 dnl ------------
4090 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
4091 dnl a monocase filesystem.
4092 AC_DEFUN([CF_MAKE_TAGS],[
4093 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
4094
4095 AC_CHECK_PROGS(CTAGS, exctags ctags)
4096 AC_CHECK_PROGS(ETAGS, exetags etags)
4097
4098 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
4099
4100 if test "$cf_cv_mixedcase" = yes ; then
4101         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
4102 else
4103         MAKE_UPPER_TAGS=no
4104 fi
4105
4106 if test "$MAKE_UPPER_TAGS" = yes ; then
4107         MAKE_UPPER_TAGS=
4108 else
4109         MAKE_UPPER_TAGS="#"
4110 fi
4111
4112 if test "$MAKE_LOWER_TAGS" = yes ; then
4113         MAKE_LOWER_TAGS=
4114 else
4115         MAKE_LOWER_TAGS="#"
4116 fi
4117
4118 AC_SUBST(CTAGS)
4119 AC_SUBST(ETAGS)
4120
4121 AC_SUBST(MAKE_UPPER_TAGS)
4122 AC_SUBST(MAKE_LOWER_TAGS)
4123 ])dnl
4124 dnl ---------------------------------------------------------------------------
4125 dnl CF_MANPAGE_FORMAT version: 11 updated: 2015/04/18 08:56:57
4126 dnl -----------------
4127 dnl Option to allow user to override automatic configuration of manpage format.
4128 dnl There are several special cases:
4129 dnl
4130 dnl     gzip - man checks for, can display gzip'd files
4131 dnl     compress - man checks for, can display compressed files
4132 dnl     BSDI - files in the cat-directories are suffixed ".0"
4133 dnl     formatted - installer should format (put files in cat-directory)
4134 dnl     catonly - installer should only format, e.g., for a turnkey system.
4135 dnl
4136 dnl There are other configurations which this macro does not test, e.g., HPUX's
4137 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
4138 dnl convention would not match our use).
4139 AC_DEFUN([CF_MANPAGE_FORMAT],
4140 [
4141 AC_REQUIRE([CF_PATHSEP])
4142 AC_MSG_CHECKING(format of man-pages)
4143
4144 AC_ARG_WITH(manpage-format,
4145         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
4146                           optionally formatted/catonly, e.g., gzip,formatted],
4147         [MANPAGE_FORMAT=$withval],
4148         [MANPAGE_FORMAT=unknown])
4149
4150 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
4151 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
4152
4153 cf_unknown=
4154
4155 case $MANPAGE_FORMAT in
4156 (unknown)
4157         if test -z "$MANPATH" ; then
4158                 MANPATH="/usr/man:/usr/share/man"
4159         fi
4160
4161         # look for the 'date' man-page (it's most likely to be installed!)
4162         MANPAGE_FORMAT=
4163         cf_preform=no
4164         cf_catonly=yes
4165         cf_example=date
4166
4167         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
4168         for cf_dir in $MANPATH; do
4169                 test -z "$cf_dir" && cf_dir=/usr/man
4170                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
4171                 do
4172                         cf_test=`echo $cf_name | sed -e 's/*//'`
4173                         if test "x$cf_test" = "x$cf_name" ; then
4174
4175                                 case "$cf_name" in
4176                                 (*.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
4177                                 (*.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
4178                                 (*.0)  MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
4179                                 (*)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
4180                                 esac
4181
4182                                 case "$cf_name" in
4183                                 ($cf_dir/man*)
4184                                         cf_catonly=no
4185                                         ;;
4186                                 ($cf_dir/cat*)
4187                                         cf_preform=yes
4188                                         ;;
4189                                 esac
4190                                 break
4191                         fi
4192
4193                         # if we found a match in either man* or cat*, stop looking
4194                         if test -n "$MANPAGE_FORMAT" ; then
4195                                 cf_found=no
4196                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
4197                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
4198                                 case "$cf_name" in
4199                                 ($cf_dir/cat*)
4200                                         cf_found=yes
4201                                         ;;
4202                                 esac
4203                                 test $cf_found=yes && break
4204                         fi
4205                 done
4206                 # only check the first directory in $MANPATH where we find manpages
4207                 if test -n "$MANPAGE_FORMAT" ; then
4208                         break
4209                 fi
4210         done
4211         # if we did not find the example, just assume it is normal
4212         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4213         IFS="$ac_save_ifs"
4214         ;;
4215 (*)
4216         for cf_option in $MANPAGE_FORMAT; do
4217         case $cf_option in
4218         (gzip|compress|BSDI|normal|formatted|catonly)
4219                 ;;
4220         (*)
4221                 cf_unknown="$cf_unknown $cf_option"
4222                 ;;
4223         esac
4224         done
4225         ;;
4226 esac
4227
4228 AC_MSG_RESULT($MANPAGE_FORMAT)
4229 if test -n "$cf_unknown" ; then
4230         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4231 fi
4232 ])dnl
4233 dnl ---------------------------------------------------------------------------
4234 dnl CF_MANPAGE_RENAMES version: 9 updated: 2015/04/18 08:56:57
4235 dnl ------------------
4236 dnl The Debian people have their own naming convention for manpages.  This
4237 dnl option lets us override the name of the file containing renaming, or
4238 dnl disable it altogether.
4239 AC_DEFUN([CF_MANPAGE_RENAMES],
4240 [
4241 AC_MSG_CHECKING(for manpage renaming)
4242
4243 AC_ARG_WITH(manpage-renames,
4244         [  --with-manpage-renames  specify manpage-renaming],
4245         [MANPAGE_RENAMES=$withval],
4246         [MANPAGE_RENAMES=yes])
4247
4248 case ".$MANPAGE_RENAMES" in
4249 (.no)
4250         ;;
4251 (.|.yes)
4252         # Debian 'man' program?
4253         if test -f /etc/debian_version ; then
4254                 MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4255         else
4256                 MANPAGE_RENAMES=no
4257         fi
4258         ;;
4259 esac
4260
4261 if test "$MANPAGE_RENAMES" != no ; then
4262         if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4263                 MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4264         elif test ! -f $MANPAGE_RENAMES ; then
4265                 AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4266         fi
4267
4268         test ! -d man && mkdir man
4269
4270         # Construct a sed-script to perform renaming within man-pages
4271         if test -n "$MANPAGE_RENAMES" ; then
4272                 test ! -d man && mkdir man
4273                 sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4274         fi
4275 fi
4276
4277 AC_MSG_RESULT($MANPAGE_RENAMES)
4278 AC_SUBST(MANPAGE_RENAMES)
4279 ])dnl
4280 dnl ---------------------------------------------------------------------------
4281 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
4282 dnl -------------------
4283 dnl Some people expect each tool to make all aliases for manpages in the
4284 dnl man-directory.  This accommodates the older, less-capable implementations
4285 dnl of 'man', and is optional.
4286 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4287 [
4288 AC_MSG_CHECKING(if manpage aliases will be installed)
4289
4290 AC_ARG_WITH(manpage-aliases,
4291         [  --with-manpage-aliases  specify manpage-aliases using .so],
4292         [MANPAGE_ALIASES=$withval],
4293         [MANPAGE_ALIASES=yes])
4294
4295 AC_MSG_RESULT($MANPAGE_ALIASES)
4296
4297 case "x$LN_S" in
4298 (xln*)
4299         cf_use_symlinks=yes
4300         ;;
4301 (*)
4302         cf_use_symlinks=no
4303         ;;
4304 esac
4305
4306 MANPAGE_SYMLINKS=no
4307 if test "$MANPAGE_ALIASES" = yes ; then
4308 AC_MSG_CHECKING(if manpage symlinks should be used)
4309
4310 AC_ARG_WITH(manpage-symlinks,
4311         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4312         [MANPAGE_SYMLINKS=$withval],
4313         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4314
4315 if test "$$cf_use_symlinks" = no; then
4316 if test "$MANPAGE_SYMLINKS" = yes ; then
4317         AC_MSG_WARN(cannot make symlinks, will use .so files)
4318         MANPAGE_SYMLINKS=no
4319 fi
4320 fi
4321
4322 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4323 fi
4324
4325 ])dnl
4326 dnl ---------------------------------------------------------------------------
4327 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4328 dnl --------------
4329 dnl This option causes manpages to be run through tbl(1) to generate tables
4330 dnl correctly.
4331 AC_DEFUN([CF_MANPAGE_TBL],
4332 [
4333 AC_MSG_CHECKING(for manpage tbl)
4334
4335 AC_ARG_WITH(manpage-tbl,
4336         [  --with-manpage-tbl      specify manpage processing with tbl],
4337         [MANPAGE_TBL=$withval],
4338         [MANPAGE_TBL=no])
4339
4340 AC_MSG_RESULT($MANPAGE_TBL)
4341 ])dnl
4342 dnl ---------------------------------------------------------------------------
4343 dnl CF_MAN_PAGES version: 45 updated: 2015/04/18 08:56:57
4344 dnl ------------
4345 dnl Try to determine if the man-pages on the system are compressed, and if
4346 dnl so, what format is used.  Use this information to construct a script that
4347 dnl will install man-pages.
4348 AC_DEFUN([CF_MAN_PAGES],
4349 [
4350 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4351 CF_MANPAGE_FORMAT
4352 CF_MANPAGE_RENAMES
4353 CF_MANPAGE_SYMLINKS
4354 CF_MANPAGE_TBL
4355
4356 if test "$prefix" = "NONE" ; then
4357         cf_prefix="$ac_default_prefix"
4358 else
4359         cf_prefix="$prefix"
4360 fi
4361
4362 case "$MANPAGE_FORMAT" in
4363 (*catonly*)
4364         cf_format=yes
4365         cf_inboth=no
4366         ;;
4367 (*formatted*)