aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2012,2013 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.648 2013/01/26 21:29:17 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54     [AC_TRY_LINK([#include <langinfo.h>],
  55       [char* cs = nl_langinfo(CODESET);],
  56       am_cv_langinfo_codeset=yes,
  57       am_cv_langinfo_codeset=no)
  58     ])
  59   if test $am_cv_langinfo_codeset = yes; then
  60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62   fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ACVERSION_CHECK version: 3 updated: 2012/10/03 18:39:53
  66 dnl ------------------
  67 dnl Conditionally generate script according to whether we're using a given autoconf.
  68 dnl
  69 dnl $1 = version to compare against
  70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  71 dnl $3 = code to use if AC_ACVERSION is older than $1.
  72 define([CF_ACVERSION_CHECK],
  73 [
  74 ifdef([m4_version_compare],
  75 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  76 [CF_ACVERSION_COMPARE(
  77 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  78 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  79 dnl ---------------------------------------------------------------------------
  80 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  81 dnl --------------------
  82 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  83 dnl                      MAJOR2, MINOR2, TERNARY2,
  84 dnl                      PRINTABLE2, not FOUND, FOUND)
  85 define([CF_ACVERSION_COMPARE],
  86 [ifelse(builtin([eval], [$2 < $5]), 1,
  87 [ifelse([$8], , ,[$8])],
  88 [ifelse([$9], , ,[$9])])])dnl
  89 dnl ---------------------------------------------------------------------------
  90 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
  91 dnl -------------------
  92 dnl Construct the list of include-options for the C programs in the Ada95
  93 dnl binding.
  94 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  95 [
  96 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  97 if test "$srcdir" != "."; then
  98         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  99 fi
 100 if test "$GCC" != yes; then
 101         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 102 elif test "$includedir" != "/usr/include"; then
 103         if test "$includedir" = '${prefix}/include' ; then
 104                 if test $prefix != /usr ; then
 105                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 106                 fi
 107         else
 108                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 109         fi
 110 fi
 111 AC_SUBST(ACPPFLAGS)
 112 ])dnl
 113 dnl ---------------------------------------------------------------------------
 114 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 115 dnl ---------------
 116 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 117 AC_DEFUN([CF_ADD_ADAFLAGS],[
 118         ADAFLAGS="$ADAFLAGS $1"
 119         AC_SUBST(ADAFLAGS)
 120 ])dnl
 121 dnl ---------------------------------------------------------------------------
 122 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
 123 dnl -------------
 124 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 125 dnl The second parameter if given makes this macro verbose.
 126 dnl
 127 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 128 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 129 dnl confused by the quotes (which require backslashes to keep them usable).
 130 AC_DEFUN([CF_ADD_CFLAGS],
 131 [
 132 cf_fix_cppflags=no
 133 cf_new_cflags=
 134 cf_new_cppflags=
 135 cf_new_extra_cppflags=
 136
 137 for cf_add_cflags in $1
 138 do
 139 case $cf_fix_cppflags in
 140 no)
 141         case $cf_add_cflags in #(vi
 142         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 143                 case $cf_add_cflags in
 144                 -D*)
 145                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 146
 147                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 148                                 && test -z "${cf_tst_cflags}" \
 149                                 && cf_fix_cppflags=yes
 150
 151                         if test $cf_fix_cppflags = yes ; then
 152                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 153                                 continue
 154                         elif test "${cf_tst_cflags}" = "\"'" ; then
 155                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 156                                 continue
 157                         fi
 158                         ;;
 159                 esac
 160                 case "$CPPFLAGS" in
 161                 *$cf_add_cflags) #(vi
 162                         ;;
 163                 *) #(vi
 164                         case $cf_add_cflags in #(vi
 165                         -D*)
 166                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 167                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 168                                 ;;
 169                         esac
 170                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 171                         ;;
 172                 esac
 173                 ;;
 174         *)
 175                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 176                 ;;
 177         esac
 178         ;;
 179 yes)
 180         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 181
 182         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 183
 184         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 185                 && test -z "${cf_tst_cflags}" \
 186                 && cf_fix_cppflags=no
 187         ;;
 188 esac
 189 done
 190
 191 if test -n "$cf_new_cflags" ; then
 192         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 193         CFLAGS="$CFLAGS $cf_new_cflags"
 194 fi
 195
 196 if test -n "$cf_new_cppflags" ; then
 197         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 198         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 199 fi
 200
 201 if test -n "$cf_new_extra_cppflags" ; then
 202         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 203         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 204 fi
 205
 206 AC_SUBST(EXTRA_CPPFLAGS)
 207
 208 ])dnl
 209 dnl ---------------------------------------------------------------------------
 210 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 211 dnl -------------
 212 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 213 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 214 dnl but old versions (and some misinstalled ones) need that.  To make things
 215 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 216 dnl the include-path).
 217 AC_DEFUN([CF_ADD_INCDIR],
 218 [
 219 if test -n "$1" ; then
 220   for cf_add_incdir in $1
 221   do
 222         while test $cf_add_incdir != /usr/include
 223         do
 224           if test -d $cf_add_incdir
 225           then
 226                 cf_have_incdir=no
 227                 if test -n "$CFLAGS$CPPFLAGS" ; then
 228                   # a loop is needed to ensure we can add subdirs of existing dirs
 229                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 230                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 231                           cf_have_incdir=yes; break
 232                         fi
 233                   done
 234                 fi
 235
 236                 if test "$cf_have_incdir" = no ; then
 237                   if test "$cf_add_incdir" = /usr/local/include ; then
 238                         if test "$GCC" = yes
 239                         then
 240                           cf_save_CPPFLAGS=$CPPFLAGS
 241                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 242                           AC_TRY_COMPILE([#include <stdio.h>],
 243                                   [printf("Hello")],
 244                                   [],
 245                                   [cf_have_incdir=yes])
 246                           CPPFLAGS=$cf_save_CPPFLAGS
 247                         fi
 248                   fi
 249                 fi
 250
 251                 if test "$cf_have_incdir" = no ; then
 252                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 253                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 254
 255                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 256                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 257                   cf_add_incdir="$cf_top_incdir"
 258                 else
 259                   break
 260                 fi
 261           fi
 262         done
 263   done
 264 fi
 265 ])dnl
 266 dnl ---------------------------------------------------------------------------
 267 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 268 dnl ----------
 269 dnl Add a library, used to enforce consistency.
 270 dnl
 271 dnl $1 = library to add, without the "-l"
 272 dnl $2 = variable to update (default $LIBS)
 273 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 274 dnl ---------------------------------------------------------------------------
 275 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 276 dnl -------------
 277 dnl     Adds to the library-path
 278 dnl
 279 dnl     Some machines have trouble with multiple -L options.
 280 dnl
 281 dnl $1 is the (list of) directory(s) to add
 282 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 283 dnl
 284 AC_DEFUN([CF_ADD_LIBDIR],
 285 [
 286 if test -n "$1" ; then
 287   for cf_add_libdir in $1
 288   do
 289     if test $cf_add_libdir = /usr/lib ; then
 290       :
 291     elif test -d $cf_add_libdir
 292     then
 293       cf_have_libdir=no
 294       if test -n "$LDFLAGS$LIBS" ; then
 295         # a loop is needed to ensure we can add subdirs of existing dirs
 296         for cf_test_libdir in $LDFLAGS $LIBS ; do
 297           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 298             cf_have_libdir=yes; break
 299           fi
 300         done
 301       fi
 302       if test "$cf_have_libdir" = no ; then
 303         CF_VERBOSE(adding $cf_add_libdir to library-path)
 304         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 305       fi
 306     fi
 307   done
 308 fi
 309 ])dnl
 310 dnl ---------------------------------------------------------------------------
 311 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 312 dnl -----------
 313 dnl Add one or more libraries, used to enforce consistency.
 314 dnl
 315 dnl $1 = libraries to add, with the "-l", etc.
 316 dnl $2 = variable to update (default $LIBS)
 317 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 318 dnl ---------------------------------------------------------------------------
 319 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 320 dnl ------------------
 321 dnl Append to a search-list for a nonstandard header/lib-file
 322 dnl     $1 = the variable to return as result
 323 dnl     $2 = the package name
 324 dnl     $3 = the subdirectory, e.g., bin, include or lib
 325 dnl $4 = the directory under which we will test for subdirectories
 326 dnl $5 = a directory that we do not want $4 to match
 327 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 328 [
 329 test "$4" != "$5" && \
 330 test -d "$4" && \
 331 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 332         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 333         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 334         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 335         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 336         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 337         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 338 }
 339 ])dnl
 340 dnl ---------------------------------------------------------------------------
 341 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 342 dnl --------------
 343 dnl Allow user to disable a normally-on option.
 344 AC_DEFUN([CF_ARG_DISABLE],
 345 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 346 dnl ---------------------------------------------------------------------------
 347 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 348 dnl -------------
 349 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 350 dnl values.
 351 dnl
 352 dnl Parameters:
 353 dnl $1 = option name
 354 dnl $2 = help-string
 355 dnl $3 = action to perform if option is not default
 356 dnl $4 = action if perform if option is default
 357 dnl $5 = default option value (either 'yes' or 'no')
 358 AC_DEFUN([CF_ARG_OPTION],
 359 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 360   if test "$enableval" != "$5" ; then
 361 ifelse([$3],,[    :]dnl
 362 ,[    $3]) ifelse([$4],,,[
 363   else
 364     $4])
 365   fi],[enableval=$5 ifelse([$4],,,[
 366   $4
 367 ])dnl
 368   ])])dnl
 369 dnl ---------------------------------------------------------------------------
 370 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 371 dnl -----------
 372 dnl Check for suitable "ar" (archiver) options for updating an archive.
 373 AC_DEFUN([CF_AR_FLAGS],[
 374 AC_REQUIRE([CF_PROG_AR])
 375
 376 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 377         cf_cv_ar_flags=unknown
 378         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 379         do
 380
 381                 # check if $ARFLAGS already contains this choice
 382                 if test "x$ARFLAGS" != "x" ; then
 383                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 384                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 385                                 cf_cv_ar_flags=
 386                                 break
 387                         fi
 388                 fi
 389
 390                 rm -f conftest.$ac_cv_objext
 391                 rm -f conftest.a
 392
 393                 cat >conftest.$ac_ext <<EOF
 394 #line __oline__ "configure"
 395 int     testdata[[3]] = { 123, 456, 789 };
 396 EOF
 397                 if AC_TRY_EVAL(ac_compile) ; then
 398                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 399                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 400                         if test -f conftest.a ; then
 401                                 cf_cv_ar_flags=$cf_ar_flags
 402                                 break
 403                         fi
 404                 else
 405                         CF_VERBOSE(cannot compile test-program)
 406                         break
 407                 fi
 408         done
 409         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 410 ])
 411
 412 if test -n "$ARFLAGS" ; then
 413         if test -n "$cf_cv_ar_flags" ; then
 414                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 415         fi
 416 else
 417         ARFLAGS=$cf_cv_ar_flags
 418 fi
 419
 420 AC_SUBST(ARFLAGS)
 421 ])
 422 dnl ---------------------------------------------------------------------------
 423 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
 424 dnl -----------------
 425 dnl Check if awk can handle big strings using printf.  Some older versions of
 426 dnl awk choke on large strings passed via "%s".
 427 dnl
 428 dnl $1 = desired string size
 429 dnl $2 = variable to set with result
 430 AC_DEFUN([CF_AWK_BIG_PRINTF],
 431 [
 432         case x$AWK in #(vi
 433         x)
 434                 eval $2=no
 435                 ;;
 436         *) #(vi
 437                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 438                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 439                         eval $2=yes
 440                 else
 441                         eval $2=no
 442                 fi
 443                 ;;
 444         esac
 445 ])dnl
 446 dnl ---------------------------------------------------------------------------
 447 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 448 dnl ------------
 449 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 450 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 451 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 452 dnl
 453 dnl Treat the configuration-variable specially here, since we're directly
 454 dnl substituting its value (i.e., 1/0).
 455 dnl
 456 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 457 AC_DEFUN([CF_BOOL_DECL],
 458 [
 459 AC_MSG_CHECKING(if we should include stdbool.h)
 460
 461 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 462         AC_TRY_COMPILE([],[bool foo = false],
 463                 [cf_cv_header_stdbool_h=0],
 464                 [AC_TRY_COMPILE([
 465 #ifndef __BEOS__
 466 #include <stdbool.h>
 467 #endif
 468 ],[bool foo = false],
 469                         [cf_cv_header_stdbool_h=1],
 470                         [cf_cv_header_stdbool_h=0])])])
 471
 472 if test "$cf_cv_header_stdbool_h" = 1
 473 then    AC_MSG_RESULT(yes)
 474 else    AC_MSG_RESULT(no)
 475 fi
 476
 477 AC_MSG_CHECKING([for builtin bool type])
 478
 479 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 480         AC_TRY_COMPILE([
 481 #include <stdio.h>
 482 #include <sys/types.h>
 483 ],[bool x = false],
 484                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 485                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 486         ])
 487
 488 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 489 then    AC_MSG_RESULT(yes)
 490 else    AC_MSG_RESULT(no)
 491 fi
 492 ])dnl
 493 dnl ---------------------------------------------------------------------------
 494 dnl CF_BOOL_SIZE version: 12 updated: 2006/12/16 12:33:30
 495 dnl ------------
 496 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 497 dnl Don't bother looking for bool.h, since it's been deprecated.
 498 dnl
 499 dnl If the current compiler is C rather than C++, we get the bool definition
 500 dnl from <stdbool.h>.
 501 AC_DEFUN([CF_BOOL_SIZE],
 502 [
 503 AC_MSG_CHECKING([for size of bool])
 504 AC_CACHE_VAL(cf_cv_type_of_bool,[
 505         rm -f cf_test.out
 506         AC_TRY_RUN([
 507 #include <stdlib.h>
 508 #include <stdio.h>
 509
 510 #if defined(__cplusplus)
 511
 512 #ifdef HAVE_GXX_BUILTIN_H
 513 #include <g++/builtin.h>
 514 #elif HAVE_GPP_BUILTIN_H
 515 #include <gpp/builtin.h>
 516 #elif HAVE_BUILTIN_H
 517 #include <builtin.h>
 518 #endif
 519
 520 #else
 521
 522 #if $cf_cv_header_stdbool_h
 523 #include <stdbool.h>
 524 #endif
 525
 526 #endif
 527
 528 main()
 529 {
 530         FILE *fp = fopen("cf_test.out", "w");
 531         if (fp != 0) {
 532                 bool x = true;
 533                 if ((bool)(-x) >= 0)
 534                         fputs("unsigned ", fp);
 535                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 536                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 537                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 538                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 539                 fclose(fp);
 540         }
 541         ${cf_cv_main_return:-return}(0);
 542 }
 543                 ],
 544                 [cf_cv_type_of_bool=`cat cf_test.out`
 545                  if test -z "$cf_cv_type_of_bool"; then
 546                    cf_cv_type_of_bool=unknown
 547                  fi],
 548                 [cf_cv_type_of_bool=unknown],
 549                 [cf_cv_type_of_bool=unknown])
 550         ])
 551         rm -f cf_test.out
 552 AC_MSG_RESULT($cf_cv_type_of_bool)
 553 if test "$cf_cv_type_of_bool" = unknown ; then
 554         case .$NCURSES_BOOL in #(vi
 555         .auto|.) NCURSES_BOOL=unsigned;;
 556         esac
 557         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 558         cf_cv_type_of_bool=$NCURSES_BOOL
 559 fi
 560 ])dnl
 561 dnl ---------------------------------------------------------------------------
 562 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 563 dnl -----------
 564 dnl If we're cross-compiling, allow the user to override the tools and their
 565 dnl options.  The configure script is oriented toward identifying the host
 566 dnl compiler, etc., but we need a build compiler to generate parts of the
 567 dnl source.
 568 dnl
 569 dnl $1 = default for $CPPFLAGS
 570 dnl $2 = default for $LIBS
 571 AC_DEFUN([CF_BUILD_CC],[
 572 CF_ACVERSION_CHECK(2.52,,
 573         [AC_REQUIRE([CF_PROG_EXT])])
 574 if test "$cross_compiling" = yes ; then
 575
 576         # defaults that we might want to override
 577         : ${BUILD_CFLAGS:=''}
 578         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 579         : ${BUILD_LDFLAGS:=''}
 580         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 581         : ${BUILD_EXEEXT:='$x'}
 582         : ${BUILD_OBJEXT:='o'}
 583
 584         AC_ARG_WITH(build-cc,
 585                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 586                 [BUILD_CC="$withval"],
 587                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 588         AC_MSG_CHECKING(for native build C compiler)
 589         AC_MSG_RESULT($BUILD_CC)
 590
 591         AC_MSG_CHECKING(for native build C preprocessor)
 592         AC_ARG_WITH(build-cpp,
 593                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 594                 [BUILD_CPP="$withval"],
 595                 [BUILD_CPP='${BUILD_CC} -E'])
 596         AC_MSG_RESULT($BUILD_CPP)
 597
 598         AC_MSG_CHECKING(for native build C flags)
 599         AC_ARG_WITH(build-cflags,
 600                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 601                 [BUILD_CFLAGS="$withval"])
 602         AC_MSG_RESULT($BUILD_CFLAGS)
 603
 604         AC_MSG_CHECKING(for native build C preprocessor-flags)
 605         AC_ARG_WITH(build-cppflags,
 606                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 607                 [BUILD_CPPFLAGS="$withval"])
 608         AC_MSG_RESULT($BUILD_CPPFLAGS)
 609
 610         AC_MSG_CHECKING(for native build linker-flags)
 611         AC_ARG_WITH(build-ldflags,
 612                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 613                 [BUILD_LDFLAGS="$withval"])
 614         AC_MSG_RESULT($BUILD_LDFLAGS)
 615
 616         AC_MSG_CHECKING(for native build linker-libraries)
 617         AC_ARG_WITH(build-libs,
 618                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 619                 [BUILD_LIBS="$withval"])
 620         AC_MSG_RESULT($BUILD_LIBS)
 621
 622         # this assumes we're on Unix.
 623         BUILD_EXEEXT=
 624         BUILD_OBJEXT=o
 625
 626         : ${BUILD_CC:='${CC}'}
 627
 628         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 629                 AC_MSG_ERROR([Cross-build requires two compilers.
 630 Use --with-build-cc to specify the native compiler.])
 631         fi
 632
 633 else
 634         : ${BUILD_CC:='${CC}'}
 635         : ${BUILD_CPP:='${CPP}'}
 636         : ${BUILD_CFLAGS:='${CFLAGS}'}
 637         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 638         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 639         : ${BUILD_LIBS:='${LIBS}'}
 640         : ${BUILD_EXEEXT:='$x'}
 641         : ${BUILD_OBJEXT:='o'}
 642 fi
 643
 644 AC_SUBST(BUILD_CC)
 645 AC_SUBST(BUILD_CPP)
 646 AC_SUBST(BUILD_CFLAGS)
 647 AC_SUBST(BUILD_CPPFLAGS)
 648 AC_SUBST(BUILD_LDFLAGS)
 649 AC_SUBST(BUILD_LIBS)
 650 AC_SUBST(BUILD_EXEEXT)
 651 AC_SUBST(BUILD_OBJEXT)
 652 ])dnl
 653 dnl ---------------------------------------------------------------------------
 654 dnl CF_CC_ENV_FLAGS version: 1 updated: 2012/10/03 05:25:49
 655 dnl ---------------
 656 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 657 dnl into CC.  This will not help with broken scripts that wrap the compiler with
 658 dnl options, but eliminates a more common category of user confusion.
 659 AC_DEFUN([CF_CC_ENV_FLAGS],
 660 [
 661 # This should have been defined by AC_PROG_CC
 662 : ${CC:=cc}
 663
 664 AC_MSG_CHECKING(\$CC variable)
 665 case "$CC" in #(vi
 666 *[[\ \  ]]-[[IUD]]*)
 667         AC_MSG_RESULT(broken)
 668         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 669         # humor him...
 670         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 671         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 672         CF_ADD_CFLAGS($cf_flags)
 673         ;;
 674 *)
 675         AC_MSG_RESULT(ok)
 676         ;;
 677 esac
 678 ])dnl
 679 dnl ---------------------------------------------------------------------------
 680 dnl CF_CFG_DEFAULTS version: 8 updated: 2011/06/04 20:09:13
 681 dnl ---------------
 682 dnl Determine the default configuration into which we'll install ncurses.  This
 683 dnl can be overridden by the user's command-line options.  There's two items to
 684 dnl look for:
 685 dnl     1. the prefix (e.g., /usr)
 686 dnl     2. the header files (e.g., /usr/include/ncurses)
 687 dnl We'll look for a previous installation of ncurses and use the same defaults.
 688 dnl
 689 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 690 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 691 dnl programs from a vendor's.
 692 AC_DEFUN([CF_CFG_DEFAULTS],
 693 [
 694 AC_MSG_CHECKING(for prefix)
 695 if test "x$prefix" = "xNONE" ; then
 696         case "$cf_cv_system_name" in
 697                 # non-vendor systems don't have a conflict
 698         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|k*bsd*-gnu)
 699                 prefix=/usr
 700                 ;;
 701         *)      prefix=$ac_default_prefix
 702                 ;;
 703         esac
 704 fi
 705 AC_MSG_RESULT($prefix)
 706
 707 if test "x$prefix" = "xNONE" ; then
 708 AC_MSG_CHECKING(for default include-directory)
 709 test -n "$verbose" && echo 1>&AC_FD_MSG
 710 for cf_symbol in \
 711         $includedir \
 712         $includedir/ncurses \
 713         $prefix/include \
 714         $prefix/include/ncurses \
 715         /usr/local/include \
 716         /usr/local/include/ncurses \
 717         /usr/include \
 718         /usr/include/ncurses
 719 do
 720         cf_dir=`eval echo $cf_symbol`
 721         if test -f $cf_dir/curses.h ; then
 722         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 723                 includedir="$cf_symbol"
 724                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 725                 break
 726         fi
 727         fi
 728         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 729 done
 730 AC_MSG_RESULT($includedir)
 731 fi
 732 ])dnl
 733 dnl ---------------------------------------------------------------------------
 734 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
 735 dnl ----------
 736 dnl Check if the terminal-capability database functions are available.  If not,
 737 dnl ncurses has a much-reduced version.
 738 AC_DEFUN([CF_CGETENT],[
 739 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 740 AC_TRY_LINK([
 741 #include <stdlib.h>],[
 742         char temp[128];
 743         char *buf = temp;
 744         char *db_array = temp;
 745         cgetent(&buf, &db_array, "vt100");
 746         cgetcap(buf, "tc", '=');
 747         cgetmatch(buf, "tc");
 748         ],
 749         [cf_cv_cgetent=yes],
 750         [cf_cv_cgetent=no])
 751 ])
 752
 753 if test "$cf_cv_cgetent" = yes
 754 then
 755         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 756 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 757 AC_TRY_LINK([
 758 #include <stdlib.h>],[
 759         char temp[128];
 760         char *buf = temp;
 761 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 762         const char *db_array = temp;
 763         cgetent(&buf, &db_array, "vt100");
 764 #endif
 765         cgetcap(buf, "tc", '=');
 766         cgetmatch(buf, "tc");
 767         ],
 768         [cf_cv_cgetent_const=yes],
 769         [cf_cv_cgetent_const=no])
 770 ])
 771         if test "$cf_cv_cgetent_const" = yes
 772         then
 773                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 774         fi
 775 fi
 776 ])dnl
 777 dnl ---------------------------------------------------------------------------
 778 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 779 dnl --------------
 780 dnl Check if we're accidentally using a cache from a different machine.
 781 dnl Derive the system name, as a check for reusing the autoconf cache.
 782 dnl
 783 dnl If we've packaged config.guess and config.sub, run that (since it does a
 784 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 785 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 786 dnl which is useful in cross-compiles.
 787 dnl
 788 dnl Note: we would use $ac_config_sub, but that is one of the places where
 789 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 790 AC_DEFUN([CF_CHECK_CACHE],
 791 [
 792 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 793         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 794         system_name="$host_os"
 795 else
 796         system_name="`(uname -s -r) 2>/dev/null`"
 797         if test -z "$system_name" ; then
 798                 system_name="`(hostname) 2>/dev/null`"
 799         fi
 800 fi
 801 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 802 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 803
 804 test -z "$system_name" && system_name="$cf_cv_system_name"
 805 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 806
 807 if test ".$system_name" != ".$cf_cv_system_name" ; then
 808         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 809         AC_MSG_ERROR("Please remove config.cache and try again.")
 810 fi
 811 ])dnl
 812 dnl ---------------------------------------------------------------------------
 813 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
 814 dnl --------------
 815 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 816 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 817 dnl ourselves.
 818 dnl
 819 dnl $1 = the name to check
 820 dnl $2 = the assumed type
 821 AC_DEFUN([CF_CHECK_ERRNO],
 822 [
 823 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 824     AC_TRY_COMPILE([
 825 #ifdef HAVE_STDLIB_H
 826 #include <stdlib.h>
 827 #endif
 828 #include <stdio.h>
 829 #include <sys/types.h>
 830 #include <errno.h> ],
 831     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 832     [cf_cv_dcl_$1=yes],
 833     [cf_cv_dcl_$1=no])
 834 ])
 835
 836 if test "$cf_cv_dcl_$1" = no ; then
 837     CF_UPPER(cf_result,decl_$1)
 838     AC_DEFINE_UNQUOTED($cf_result)
 839 fi
 840
 841 # It's possible (for near-UNIX clones) that the data doesn't exist
 842 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 843 ])dnl
 844 dnl ---------------------------------------------------------------------------
 845 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
 846 dnl --------------------
 847 dnl Check for existence of external data in the current set of libraries.  If
 848 dnl we can modify it, it's real enough.
 849 dnl $1 = the name to check
 850 dnl $2 = its type
 851 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 852 [
 853 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 854     AC_TRY_LINK([
 855 #undef $1
 856 extern $2 $1;
 857 ],
 858     [$1 = 2],
 859     [cf_cv_have_$1=yes],
 860     [cf_cv_have_$1=no])
 861 ])
 862
 863 if test "$cf_cv_have_$1" = yes ; then
 864     CF_UPPER(cf_result,have_$1)
 865     AC_DEFINE_UNQUOTED($cf_result)
 866 fi
 867
 868 ])dnl
 869 dnl ---------------------------------------------------------------------------
 870 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 871 dnl -------------------
 872 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 873 dnl is not "weak" - warn about this because it can create problems linking
 874 dnl applications with ncurses.
 875 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 876 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 877
 878 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 879 cf_cv_check_gpm_wgetch=unknown
 880 if test "$cross_compiling" != yes ; then
 881
 882 cat >conftest.$ac_ext <<CF_EOF
 883 #include <gpm.h>
 884 int main()
 885 {
 886         Gpm_Wgetch();
 887         ${cf_cv_main_return:-return}(0);
 888 }
 889 CF_EOF
 890
 891         cf_save_LIBS="$LIBS"
 892         # This only works if we can look at the symbol table.  If a shared
 893         # library is stripped for install, we cannot use that.  So we're forced
 894         # to rely on the static library, noting that some packagers may not
 895         # include it.
 896         LIBS="-static -lgpm -dynamic $LIBS"
 897         if AC_TRY_EVAL(ac_compile) ; then
 898                 if AC_TRY_EVAL(ac_link) ; then
 899                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 900                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 901                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 902                 fi
 903         fi
 904         rm -rf conftest*
 905         LIBS="$cf_save_LIBS"
 906 fi
 907 ])
 908
 909 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 910         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 911 fi
 912 ])])dnl
 913 dnl ---------------------------------------------------------------------------
 914 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
 915 dnl ----------------
 916 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
 917 AC_DEFUN([CF_CHECK_WCHAR_H],[
 918 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
 919 AC_TRY_COMPILE(
 920 [
 921 #include <stdlib.h>
 922 #include <wchar.h>
 923 ],[
 924         wint_t foo = 0;
 925         int bar = iswpunct(foo)],
 926         [cf_cv_wchar_h_okay=yes],
 927         [cf_cv_wchar_h_okay=no])])
 928
 929 if test $cf_cv_wchar_h_okay = no
 930 then
 931         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 932 fi
 933 ])dnl
 934 dnl ---------------------------------------------------------------------------
 935 dnl CF_CLANG_COMPILER version: 1 updated: 2012/06/16 14:55:39
 936 dnl -----------------
 937 dnl Check if the given compiler is really clang.  clang's C driver defines
 938 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 939 dnl not ignore some gcc options.
 940 dnl
 941 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 942 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 943 dnl the wrappers for gcc and g++ warnings.
 944 dnl
 945 dnl $1 = GCC (default) or GXX
 946 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
 947 dnl $3 = CFLAGS (default) or CXXFLAGS
 948 AC_DEFUN([CF_CLANG_COMPILER],[
 949 ifelse([$2],,CLANG_COMPILER,[$2])=no
 950
 951 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 952         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 953         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 954         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 955         AC_TRY_COMPILE([],[
 956 #ifdef __clang__
 957 #else
 958 make an error
 959 #endif
 960 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 961 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
 962 ],[])
 963         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 964         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 965 fi
 966 ])
 967 dnl ---------------------------------------------------------------------------
 968 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
 969 dnl -----------------
 970 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
 971 dnl is a late feature for the standard and is not in some recent compilers
 972 dnl (1999/9/11).
 973 AC_DEFUN([CF_CPP_PARAM_INIT],
 974 [
 975 if test -n "$CXX"; then
 976 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
 977         AC_LANG_SAVE
 978         AC_LANG_CPLUSPLUS
 979         AC_TRY_RUN([
 980 class TEST {
 981 private:
 982         int value;
 983 public:
 984         TEST(int x = 1);
 985         ~TEST();
 986 };
 987
 988 TEST::TEST(int x = 1)   // some compilers do not like second initializer
 989 {
 990         value = x;
 991 }
 992 int main() { }
 993 ],
 994         [cf_cv_cpp_param_init=yes],
 995         [cf_cv_cpp_param_init=no],
 996         [cf_cv_cpp_param_init=unknown])
 997         AC_LANG_RESTORE
 998 ])
 999 fi
1000 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1001 ])dnl
1002 dnl ---------------------------------------------------------------------------
1003 dnl CF_CPP_STATIC_CAST version: 2 updated: 2012/10/06 17:56:13
1004 dnl ------------------
1005 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1006 dnl not be supported in g++ before 3.0
1007 AC_DEFUN([CF_CPP_STATIC_CAST],
1008 [
1009 if test -n "$CXX"; then
1010
1011 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1012         AC_LANG_SAVE
1013         AC_LANG_CPLUSPLUS
1014
1015         AC_TRY_COMPILE([
1016 class NCursesPanel
1017 {
1018 public:
1019   NCursesPanel(int nlines,
1020                int ncols,
1021                int begin_y = 0,
1022                int begin_x = 0)
1023   {
1024   }
1025
1026   ~NCursesPanel();
1027 };
1028
1029 template<class T> class NCursesUserPanel : public NCursesPanel
1030 {
1031 public:
1032   NCursesUserPanel (int nlines,
1033                     int ncols,
1034                     int begin_y = 0,
1035                     int begin_x = 0,
1036                     const T* p_UserData = static_cast<T*>(0))
1037     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1038   {
1039   };
1040   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1041   {
1042   };
1043
1044   virtual ~NCursesUserPanel() {};
1045 };
1046 ],[
1047         const char* p_UserData = static_cast<char*>(0)],
1048         [cf_cv_cpp_static_cast=yes],
1049         [cf_cv_cpp_static_cast=no])
1050
1051         AC_LANG_RESTORE
1052 ])
1053
1054 fi
1055
1056 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1057 ])dnl
1058 dnl ---------------------------------------------------------------------------
1059 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1060 dnl ---------------
1061 dnl Setup special archiver flags for given compilers.
1062 AC_DEFUN([CF_CXX_AR_FLAGS],[
1063         CXX_AR='$(AR)'
1064         CXX_ARFLAGS='$(ARFLAGS)'
1065         case $cf_cv_system_name in #(vi
1066         irix*) #(vi
1067             if test "$GXX" != yes ; then
1068                 CXX_AR='$(CXX)'
1069                 CXX_ARFLAGS='-ar -o'
1070             fi
1071             ;;
1072         sco3.2v5*) #(vi
1073             CXXLDFLAGS="-u main"
1074             ;;
1075         solaris2*)
1076             if test "$GXX" != yes ; then
1077                 CXX_AR='$(CXX)'
1078                 CXX_ARFLAGS='-xar -o'
1079             fi
1080             ;;
1081         esac
1082         AC_SUBST(CXXLDFLAGS)
1083         AC_SUBST(CXX_AR)
1084         AC_SUBST(CXX_ARFLAGS)
1085 ])dnl
1086 dnl ---------------------------------------------------------------------------
1087 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1088 dnl -------------------------
1089 dnl For c++, check if iostream uses "std::" namespace.
1090 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1091 AC_CHECK_HEADERS(iostream)
1092 if test x"$ac_cv_header_iostream" = xyes ; then
1093         AC_MSG_CHECKING(if iostream uses std-namespace)
1094         AC_TRY_COMPILE([
1095 #include <iostream>
1096 using std::endl;
1097 using std::cerr;],[
1098 cerr << "testing" << endl;
1099 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1100         AC_MSG_RESULT($cf_iostream_namespace)
1101         if test "$cf_iostream_namespace" = yes ; then
1102                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1103         fi
1104 fi
1105 ])dnl
1106 dnl ---------------------------------------------------------------------------
1107 dnl CF_C_INLINE version: 4 updated: 2012/06/16 14:55:39
1108 dnl -----------
1109 dnl Check if the C compiler supports "inline".
1110 dnl $1 is the name of a shell variable to set if inline is supported
1111 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1112 AC_DEFUN([CF_C_INLINE],[
1113 AC_C_INLINE
1114 $1=
1115 if test "$ac_cv_c_inline" != no ; then
1116   $1=inline
1117   if test "$INTEL_COMPILER" = yes
1118   then
1119     :
1120   elif test "$CLANG_COMPILER" = yes
1121   then
1122     :
1123   elif test "$GCC" = yes
1124   then
1125     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1126       cf_save_CFLAGS=$CFLAGS
1127       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1128       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1129       [${cf_cv_main_return:-return} foo()],
1130       [cf_cv_gcc_inline=yes],
1131       [cf_cv_gcc_inline=no])
1132       CFLAGS=$cf_save_CFLAGS
1133     ])
1134     if test "$cf_cv_gcc_inline" = yes ; then
1135         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1136     fi
1137   fi
1138 fi
1139 AC_SUBST($1)
1140 ])dnl
1141 dnl ---------------------------------------------------------------------------
1142 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1143 dnl ----------
1144 dnl "dirname" is not portable, so we fake it with a shell script.
1145 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1146 dnl ---------------------------------------------------------------------------
1147 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1148 dnl ---------------
1149 AC_DEFUN([CF_DIRS_TO_MAKE],
1150 [
1151 DIRS_TO_MAKE="lib"
1152 for cf_item in $cf_list_models
1153 do
1154         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1155         for cf_item2 in $DIRS_TO_MAKE
1156         do
1157                 test $cf_item2 = $cf_subdir && break
1158         done
1159         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1160 done
1161 for cf_dir in $DIRS_TO_MAKE
1162 do
1163         test ! -d $cf_dir && mkdir $cf_dir
1164 done
1165 AC_SUBST(DIRS_TO_MAKE)
1166 ])dnl
1167 dnl ---------------------------------------------------------------------------
1168 dnl CF_DISABLE_ECHO version: 12 updated: 2012/10/06 16:30:28
1169 dnl ---------------
1170 dnl You can always use "make -n" to see the actual options, but it's hard to
1171 dnl pick out/analyze warning messages when the compile-line is long.
1172 dnl
1173 dnl Sets:
1174 dnl     ECHO_LT - symbol to control if libtool is verbose
1175 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1176 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1177 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1178 dnl     ECHO_CC - symbol to put before any "cc" line
1179 dnl
1180 AC_DEFUN([CF_DISABLE_ECHO],[
1181 AC_MSG_CHECKING(if you want to see long compiling messages)
1182 CF_ARG_DISABLE(echo,
1183         [  --disable-echo          do not display "compiling" commands],
1184         [
1185     ECHO_LT='--silent'
1186     ECHO_LD='@echo linking [$]@;'
1187     RULE_CC='@echo compiling [$]<'
1188     SHOW_CC='@echo compiling [$]@'
1189     ECHO_CC='@'
1190 ],[
1191     ECHO_LT=''
1192     ECHO_LD=''
1193     RULE_CC=''
1194     SHOW_CC=''
1195     ECHO_CC=''
1196 ])
1197 AC_MSG_RESULT($enableval)
1198 AC_SUBST(ECHO_LT)
1199 AC_SUBST(ECHO_LD)
1200 AC_SUBST(RULE_CC)
1201 AC_SUBST(SHOW_CC)
1202 AC_SUBST(ECHO_CC)
1203 ])dnl
1204 dnl ---------------------------------------------------------------------------
1205 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1206 dnl ----------------
1207 dnl Combine no-leak checks with the libraries or tools that are used for the
1208 dnl checks.
1209 AC_DEFUN([CF_DISABLE_LEAKS],[
1210
1211 AC_REQUIRE([CF_WITH_DMALLOC])
1212 AC_REQUIRE([CF_WITH_DBMALLOC])
1213 AC_REQUIRE([CF_WITH_VALGRIND])
1214
1215 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1216 AC_ARG_ENABLE(leaks,
1217         [  --disable-leaks         test: free permanent memory, analyze leaks],
1218         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1219         : ${with_no_leaks:=no})
1220 AC_MSG_RESULT($with_no_leaks)
1221
1222 if test "$with_no_leaks" = yes ; then
1223         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1224         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1225 fi
1226 ])dnl
1227 dnl ---------------------------------------------------------------------------
1228 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1229 dnl --------------------------
1230 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1231 dnl the older "-version-info" feature.  The newer feature allows us to use
1232 dnl version numbering on shared libraries which make them compatible with
1233 dnl various systems.
1234 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1235 [
1236 AC_MSG_CHECKING(if libtool -version-number should be used)
1237 CF_ARG_DISABLE(libtool-version,
1238         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1239         [cf_libtool_version=no],
1240         [cf_libtool_version=yes])
1241 AC_MSG_RESULT($cf_libtool_version)
1242
1243 if test "$cf_libtool_version" = yes ; then
1244         LIBTOOL_VERSION="-version-number"
1245 else
1246         LIBTOOL_VERSION="-version-info"
1247 fi
1248
1249 AC_SUBST(LIBTOOL_VERSION)
1250 ])dnl
1251 dnl ---------------------------------------------------------------------------
1252 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1253 dnl ---------------------
1254 dnl The rpath-hack makes it simpler to build programs, particularly with the
1255 dnl *BSD ports which may have essential libraries in unusual places.  But it
1256 dnl can interfere with building an executable for the base system.  Use this
1257 dnl option in that case.
1258 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1259 [
1260 AC_MSG_CHECKING(if rpath-hack should be disabled)
1261 CF_ARG_DISABLE(rpath-hack,
1262         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1263         [cf_disable_rpath_hack=yes],
1264         [cf_disable_rpath_hack=no])
1265 AC_MSG_RESULT($cf_disable_rpath_hack)
1266 if test "$cf_disable_rpath_hack" = no ; then
1267         CF_RPATH_HACK
1268 fi
1269 ])
1270 dnl ---------------------------------------------------------------------------
1271 dnl CF_ENABLE_PC_FILES version: 9 updated: 2012/08/04 13:59:54
1272 dnl ------------------
1273 dnl This is the "--enable-pc-files" option, which is available if there is a
1274 dnl pkg-config configuration on the local machine.
1275 AC_DEFUN([CF_ENABLE_PC_FILES],[
1276 AC_REQUIRE([CF_PKG_CONFIG])
1277 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1278
1279 if test "$PKG_CONFIG" != none ; then
1280         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1281         AC_ARG_ENABLE(pc-files,
1282                 [  --enable-pc-files       generate and install .pc files for pkg-config],
1283                 [enable_pc_files=$enableval],
1284                 [enable_pc_files=no])
1285         AC_MSG_RESULT($enable_pc_files)
1286         if test "$enable_pc_files" != no
1287         then
1288                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1289         fi
1290 else
1291         enable_pc_files=no
1292 fi
1293 ])dnl
1294 dnl ---------------------------------------------------------------------------
1295 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1296 dnl ---------------
1297 dnl Check if the rpath option should be used, setting cache variable
1298 dnl cf_cv_enable_rpath if so.
1299 AC_DEFUN([CF_ENABLE_RPATH],
1300 [
1301 AC_MSG_CHECKING(if rpath option should be used)
1302 AC_ARG_ENABLE(rpath,
1303 [  --enable-rpath          use rpath option when generating shared libraries],
1304 [cf_cv_enable_rpath=$enableval],
1305 [cf_cv_enable_rpath=no])
1306 AC_MSG_RESULT($cf_cv_enable_rpath)
1307 ])dnl
1308 dnl ---------------------------------------------------------------------------
1309 dnl CF_ENABLE_STRING_HACKS version: 3 updated: 2013/01/26 16:26:12
1310 dnl ----------------------
1311 dnl On a few platforms, the compiler and/or loader nags with untruthful
1312 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1313 dnl and implying that most uses of the recommended alternatives are correct.
1314 dnl
1315 dnl Factually speaking, no one has actually counted the number of uses of these
1316 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1317 dnl instances are meaningless compared to the hundreds of millions of lines of
1318 dnl existing C code.
1319 dnl
1320 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1321 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1322 dnl standard - but evolved through phases, and older implementations are likely
1323 dnl to yield surprising results, as documented in manpages on various systems.
1324 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1325 [
1326 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1327 AC_ARG_ENABLE(string-hacks,
1328         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1329         [with_string_hacks=$enableval],
1330         [with_string_hacks=no])
1331 AC_MSG_RESULT($with_string_hacks)
1332
1333 if test "x$with_string_hacks" = "xyes"; then
1334         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1335         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1336         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1337 fi
1338 ])dnl
1339 dnl ---------------------------------------------------------------------------
1340 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1341 dnl --------
1342 dnl Check if 'errno' is declared in <errno.h>
1343 AC_DEFUN([CF_ERRNO],
1344 [
1345 CF_CHECK_ERRNO(errno)
1346 ])dnl
1347 dnl ---------------------------------------------------------------------------
1348 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1349 dnl ---------------
1350 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1351 dnl math.h and builtin.h, only for ncurses
1352 AC_DEFUN([CF_ETIP_DEFINES],
1353 [
1354 AC_MSG_CHECKING(for special defines needed for etip.h)
1355 cf_save_CXXFLAGS="$CXXFLAGS"
1356 cf_result="none"
1357
1358 # etip.h includes ncurses.h which includes ncurses_dll.h
1359 # But ncurses_dll.h is generated - fix here.
1360 test -d include || mkdir include
1361 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1362
1363 for cf_math in "" MATH_H
1364 do
1365 for cf_excp in "" MATH_EXCEPTION
1366 do
1367         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1368         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1369         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1370 AC_TRY_COMPILE([
1371 #include <etip.h.in>
1372 ],[],[
1373         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1374         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1375         cf_result="$cf_math $cf_excp"
1376         break 2
1377 ],[])
1378 done
1379 done
1380 AC_MSG_RESULT($cf_result)
1381 CXXFLAGS="$cf_save_CXXFLAGS"
1382 ])
1383 dnl ---------------------------------------------------------------------------
1384 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1385 dnl ---------------
1386 dnl Find a library (specifically the linkage used in the code fragment),
1387 dnl searching for it if it is not already in the library path.
1388 dnl See also CF_ADD_SEARCHPATH.
1389 dnl
1390 dnl Parameters (4-on are optional):
1391 dnl     $1 = headers for library entrypoint
1392 dnl     $2 = code fragment for library entrypoint
1393 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1394 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1395 dnl     $5 = action to perform if not successful
1396 dnl     $6 = module name, if not the same as the library name
1397 dnl     $7 = extra libraries
1398 dnl
1399 dnl Sets these variables:
1400 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1401 dnl     $cf_cv_header_path_$3 - include-directory if needed
1402 dnl     $cf_cv_library_path_$3 - library-directory if needed
1403 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1404 AC_DEFUN([CF_FIND_LINKAGE],[
1405
1406 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1407 # will be set on completion of the AC_TRY_LINK below.
1408 cf_cv_header_path_$3=
1409 cf_cv_library_path_$3=
1410
1411 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1412
1413 cf_save_LIBS="$LIBS"
1414
1415 AC_TRY_LINK([$1],[$2],[
1416         cf_cv_find_linkage_$3=yes
1417         cf_cv_header_path_$3=/usr/include
1418         cf_cv_library_path_$3=/usr/lib
1419 ],[
1420
1421 LIBS="-l$3 $7 $cf_save_LIBS"
1422
1423 AC_TRY_LINK([$1],[$2],[
1424         cf_cv_find_linkage_$3=yes
1425         cf_cv_header_path_$3=/usr/include
1426         cf_cv_library_path_$3=/usr/lib
1427         cf_cv_library_file_$3="-l$3"
1428 ],[
1429         cf_cv_find_linkage_$3=no
1430         LIBS="$cf_save_LIBS"
1431
1432     CF_VERBOSE(find linkage for $3 library)
1433     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1434
1435     cf_save_CPPFLAGS="$CPPFLAGS"
1436     cf_test_CPPFLAGS="$CPPFLAGS"
1437
1438     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1439     for cf_cv_header_path_$3 in $cf_search
1440     do
1441       if test -d $cf_cv_header_path_$3 ; then
1442         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1443         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1444         AC_TRY_COMPILE([$1],[$2],[
1445             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1446             cf_cv_find_linkage_$3=maybe
1447             cf_test_CPPFLAGS="$CPPFLAGS"
1448             break],[
1449             CPPFLAGS="$cf_save_CPPFLAGS"
1450             ])
1451       fi
1452     done
1453
1454     if test "$cf_cv_find_linkage_$3" = maybe ; then
1455
1456       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1457
1458       cf_save_LIBS="$LIBS"
1459       cf_save_LDFLAGS="$LDFLAGS"
1460
1461       ifelse([$6],,,[
1462         CPPFLAGS="$cf_test_CPPFLAGS"
1463         LIBS="-l$3 $7 $cf_save_LIBS"
1464         AC_TRY_LINK([$1],[$2],[
1465             CF_VERBOSE(... found $3 library in system)
1466             cf_cv_find_linkage_$3=yes])
1467             CPPFLAGS="$cf_save_CPPFLAGS"
1468             LIBS="$cf_save_LIBS"
1469             ])
1470
1471       if test "$cf_cv_find_linkage_$3" != yes ; then
1472         CF_LIBRARY_PATH(cf_search,$3)
1473         for cf_cv_library_path_$3 in $cf_search
1474         do
1475           if test -d $cf_cv_library_path_$3 ; then
1476             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1477             CPPFLAGS="$cf_test_CPPFLAGS"
1478             LIBS="-l$3 $7 $cf_save_LIBS"
1479             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1480             AC_TRY_LINK([$1],[$2],[
1481                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1482                 cf_cv_find_linkage_$3=yes
1483                 cf_cv_library_file_$3="-l$3"
1484                 break],[
1485                 CPPFLAGS="$cf_save_CPPFLAGS"
1486                 LIBS="$cf_save_LIBS"
1487                 LDFLAGS="$cf_save_LDFLAGS"
1488                 ])
1489           fi
1490         done
1491         CPPFLAGS="$cf_save_CPPFLAGS"
1492         LDFLAGS="$cf_save_LDFLAGS"
1493       fi
1494
1495     else
1496       cf_cv_find_linkage_$3=no
1497     fi
1498     ],$7)
1499 ])
1500
1501 LIBS="$cf_save_LIBS"
1502
1503 if test "$cf_cv_find_linkage_$3" = yes ; then
1504 ifelse([$4],,[
1505         CF_ADD_INCDIR($cf_cv_header_path_$3)
1506         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1507         CF_ADD_LIB($3)
1508 ],[$4])
1509 else
1510 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1511 fi
1512 ])dnl
1513 dnl ---------------------------------------------------------------------------
1514 dnl CF_FIXUP_ADAFLAGS version: 1 updated: 2012/03/31 18:48:10
1515 dnl -----------------
1516 dnl make ADAFLAGS consistent with CFLAGS
1517 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1518         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1519         case "$CFLAGS" in
1520         *-g*)
1521                 CF_ADD_ADAFLAGS(-g)
1522                 ;;
1523         esac
1524         case "$CFLAGS" in
1525         *-O*)
1526                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1527                 CF_ADD_ADAFLAGS($cf_O_flag)
1528                 ;;
1529         esac
1530         AC_MSG_RESULT($ADAFLAGS)
1531 ])dnl
1532 dnl ---------------------------------------------------------------------------
1533 dnl CF_FUNC_DLSYM version: 3 updated: 2012/10/06 11:17:15
1534 dnl -------------
1535 dnl Test for dlsym() and related functions, as well as libdl.
1536 dnl
1537 dnl Sets
1538 dnl     $cf_have_dlsym
1539 dnl     $cf_have_libdl
1540 AC_DEFUN([CF_FUNC_DLSYM],[
1541 cf_have_dlsym=no
1542 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1543
1544 cf_have_libdl=no
1545 AC_CHECK_LIB(dl,dlsym,[
1546         cf_have_dlsym=yes
1547         cf_have_libdl=yes])])
1548
1549 if test "$cf_have_dlsym" = yes ; then
1550         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1551
1552         AC_MSG_CHECKING(whether able to link to dl*() functions)
1553         AC_TRY_LINK([#include <dlfcn.h>],[
1554                 void *obj;
1555                 if ((obj = dlopen("filename", 0)) != 0) {
1556                         if (dlsym(obj, "symbolname") == 0) {
1557                         dlclose(obj);
1558                         }
1559                 }],[
1560                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1561                 AC_MSG_ERROR(Cannot link test program for libdl)])
1562         AC_MSG_RESULT(ok)
1563 else
1564         AC_MSG_ERROR(Cannot find dlsym function)
1565 fi
1566 ])
1567 dnl ---------------------------------------------------------------------------
1568 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1569 dnl ---------------
1570 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1571 dnl is found, add our own version of memmove to the list of objects.
1572 AC_DEFUN([CF_FUNC_MEMMOVE],
1573 [
1574 AC_CHECK_FUNC(memmove,,[
1575 AC_CHECK_FUNC(bcopy,[
1576         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1577                 AC_TRY_RUN([
1578 int main() {
1579         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1580         char temp[40];
1581         bcopy(data, temp, sizeof(data));
1582         bcopy(temp+10, temp, 15);
1583         bcopy(temp+5, temp+15, 10);
1584         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1585 }
1586                 ],
1587                 [cf_cv_good_bcopy=yes],
1588                 [cf_cv_good_bcopy=no],
1589                 [cf_cv_good_bcopy=unknown])
1590                 ])
1591         ],[cf_cv_good_bcopy=no])
1592         if test "$cf_cv_good_bcopy" = yes ; then
1593                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1594         else
1595                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1596         fi
1597 ])])dnl
1598 dnl ---------------------------------------------------------------------------
1599 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1600 dnl -----------------
1601 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1602 dnl AIX 4.x, provide a non-working version.
1603 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1604 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1605 AC_TRY_RUN([
1606 #include <stdio.h>
1607 #include <errno.h>
1608 #include <time.h>
1609
1610 #ifdef HAVE_SYS_TIME_H
1611 #include <sys/time.h>
1612 #endif
1613
1614 int main() {
1615         struct timespec ts1, ts2;
1616         int code;
1617         ts1.tv_sec  = 0;
1618         ts1.tv_nsec = 750000000;
1619         ts2.tv_sec  = 0;
1620         ts2.tv_nsec = 0;
1621         errno = 0;
1622         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1623         ${cf_cv_main_return:-return}(code != 0);
1624 }
1625 ],
1626         [cf_cv_func_nanosleep=yes],
1627         [cf_cv_func_nanosleep=no],
1628         [cf_cv_func_nanosleep=unknown])])
1629
1630 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1631 ])
1632 dnl ---------------------------------------------------------------------------
1633 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1634 dnl ---------------
1635 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1636 dnl "util" library as well.
1637 AC_DEFUN([CF_FUNC_OPENPTY],
1638 [
1639 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1640 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1641     cf_save_LIBS="$LIBS"
1642     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1643     for cf_header in pty.h libutil.h util.h
1644     do
1645     AC_TRY_LINK([
1646 #include <$cf_header>
1647 ],[
1648     int x = openpty((int *)0, (int *)0, (char *)0,
1649                    (struct termios *)0, (struct winsize *)0);
1650 ],[
1651         cf_cv_func_openpty=$cf_header
1652         break
1653 ],[
1654         cf_cv_func_openpty=no
1655 ])
1656     done
1657     LIBS="$cf_save_LIBS"
1658 ])
1659 ])dnl
1660 dnl ---------------------------------------------------------------------------
1661 dnl CF_FUNC_POLL version: 8 updated: 2012/10/04 05:24:07
1662 dnl ------------
1663 dnl See if the poll function really works.  Some platforms have poll(), but
1664 dnl it does not work for terminals or files.
1665 AC_DEFUN([CF_FUNC_POLL],[
1666 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1667 AC_TRY_RUN([
1668 #include <stdlib.h>
1669 #include <stdio.h>
1670 #include <unistd.h>
1671 #include <fcntl.h>
1672 #ifdef HAVE_POLL_H
1673 #include <poll.h>
1674 #else
1675 #include <sys/poll.h>
1676 #endif
1677 int main() {
1678         struct pollfd myfds;
1679         int ret;
1680
1681         /* check for Darwin bug with respect to "devices" */
1682         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
1683         if (myfds.fd < 0)
1684                 myfds.fd = 0;
1685         myfds.events = POLLIN;
1686         myfds.revents = 0;
1687
1688         ret = poll(&myfds, 1, 100);
1689
1690         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1691                 ret = -1;
1692         } else {
1693                 int fd = 0;
1694                 if (!isatty(fd)) {
1695                         fd = open("/dev/tty", 2);       /* O_RDWR */
1696                 }
1697
1698                 if (fd >= 0) {
1699                         /* also check with standard input */
1700                         myfds.fd = fd;
1701                         myfds.events = POLLIN;
1702                         myfds.revents = 0;
1703                         ret = poll(&myfds, 1, 100);
1704                 } else {
1705                         ret = -1;
1706                 }
1707         }
1708         ${cf_cv_main_return:-return}(ret < 0);
1709 }],
1710         [cf_cv_working_poll=yes],
1711         [cf_cv_working_poll=no],
1712         [cf_cv_working_poll=unknown])])
1713 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
1714 ])dnl
1715 dnl ---------------------------------------------------------------------------
1716 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
1717 dnl ---------------
1718 dnl Some old/broken variations define tcgetattr() only as a macro in
1719 dnl termio(s).h
1720 AC_DEFUN([CF_FUNC_TERMIOS],[
1721 AC_REQUIRE([CF_STRUCT_TERMIOS])
1722 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1723 AC_TRY_LINK([
1724 #include <sys/types.h>
1725 #ifdef HAVE_UNISTD_H
1726 #include <unistd.h>
1727 #endif
1728 #ifdef HAVE_TERMIOS_H
1729 #include <termios.h>
1730 #define TTY struct termios
1731 #else
1732 #ifdef HAVE_TERMIO_H
1733 #include <termio.h>
1734 #define TTY struct termio
1735 #endif
1736 #endif
1737 ],[
1738 TTY foo;
1739 tcgetattr(1, &foo);],
1740 [cf_cv_have_tcgetattr=yes],
1741 [cf_cv_have_tcgetattr=no])])
1742 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
1743 ])dnl
1744 dnl ---------------------------------------------------------------------------
1745 dnl CF_FUNC_VSSCANF version: 4 updated: 2012/10/06 17:56:13
1746 dnl ---------------
1747 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1748 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1749 dnl other functions.
1750 AC_DEFUN([CF_FUNC_VSSCANF],
1751 [
1752 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1753 AC_TRY_LINK([
1754 #include <stdarg.h>
1755 #include <stdio.h>],[
1756         va_list ap;
1757         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1758 AC_TRY_LINK([
1759 #include <stdarg.h>
1760 #include <stdio.h>],[
1761     FILE strbuf;
1762     char *str = "from";
1763
1764     strbuf._flag = _IOREAD;
1765     strbuf._ptr = strbuf._base = (unsigned char *) str;
1766     strbuf._cnt = strlen(str);
1767     strbuf._file = _NFILE;
1768     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1769 AC_TRY_LINK([
1770 #include <stdarg.h>
1771 #include <stdio.h>],[
1772     FILE strbuf;
1773     char *str = "from";
1774
1775     strbuf._flag = _IOREAD;
1776     strbuf._ptr = strbuf._base = (unsigned char *) str;
1777     strbuf._cnt = strlen(str);
1778     strbuf._file = _NFILE;
1779     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1780 cf_cv_func_vsscanf=no])])])])
1781
1782 case $cf_cv_func_vsscanf in #(vi
1783 vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);; #(vi
1784 vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);; #(vi
1785 _doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
1786 esac
1787
1788 ])dnl
1789 dnl ---------------------------------------------------------------------------
1790 dnl CF_GCC_ATTRIBUTES version: 16 updated: 2012/10/02 20:55:03
1791 dnl -----------------
1792 dnl Test for availability of useful gcc __attribute__ directives to quiet
1793 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1794 dnl to documentation, unrecognized directives cause older compilers to barf.
1795 AC_DEFUN([CF_GCC_ATTRIBUTES],
1796 [
1797 if test "$GCC" = yes
1798 then
1799 cat > conftest.i <<EOF
1800 #ifndef GCC_PRINTF
1801 #define GCC_PRINTF 0
1802 #endif
1803 #ifndef GCC_SCANF
1804 #define GCC_SCANF 0
1805 #endif
1806 #ifndef GCC_NORETURN
1807 #define GCC_NORETURN /* nothing */
1808 #endif
1809 #ifndef GCC_UNUSED
1810 #define GCC_UNUSED /* nothing */
1811 #endif
1812 EOF
1813 if test "$GCC" = yes
1814 then
1815         AC_CHECKING([for $CC __attribute__ directives])
1816 cat > conftest.$ac_ext <<EOF
1817 #line __oline__ "${as_me:-configure}"
1818 #include "confdefs.h"
1819 #include "conftest.h"
1820 #include "conftest.i"
1821 #if     GCC_PRINTF
1822 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1823 #else
1824 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1825 #endif
1826 #if     GCC_SCANF
1827 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1828 #else
1829 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1830 #endif
1831 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1832 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1833 extern void foo(void) GCC_NORETURN;
1834 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1835 EOF
1836         cf_printf_attribute=no
1837         cf_scanf_attribute=no
1838         for cf_attribute in scanf printf unused noreturn
1839         do
1840                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1841                 cf_directive="__attribute__(($cf_attribute))"
1842                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1843
1844                 case $cf_attribute in #(vi
1845                 printf) #(vi
1846                         cf_printf_attribute=yes
1847                         cat >conftest.h <<EOF
1848 #define GCC_$cf_ATTRIBUTE 1
1849 EOF
1850                         ;;
1851                 scanf) #(vi
1852                         cf_scanf_attribute=yes
1853                         cat >conftest.h <<EOF
1854 #define GCC_$cf_ATTRIBUTE 1
1855 EOF
1856                         ;;
1857                 *) #(vi
1858                         cat >conftest.h <<EOF
1859 #define GCC_$cf_ATTRIBUTE $cf_directive
1860 EOF
1861                         ;;
1862                 esac
1863
1864                 if AC_TRY_EVAL(ac_compile); then
1865                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1866                         cat conftest.h >>confdefs.h
1867                         case $cf_attribute in #(vi
1868                         noreturn) #(vi
1869                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1870                                 ;;
1871                         printf) #(vi
1872                                 cf_value='/* nothing */'
1873                                 if test "$cf_printf_attribute" != no ; then
1874                                         cf_value='__attribute__((format(printf,fmt,var)))'
1875                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1876                                 fi
1877                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1878                                 ;;
1879                         scanf) #(vi
1880                                 cf_value='/* nothing */'
1881                                 if test "$cf_scanf_attribute" != no ; then
1882                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1883                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1884                                 fi
1885                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1886                                 ;;
1887                         unused) #(vi
1888                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1889                                 ;;
1890                         esac
1891                 fi
1892         done
1893 else
1894         fgrep define conftest.i >>confdefs.h
1895 fi
1896 rm -rf conftest*
1897 fi
1898 ])dnl
1899 dnl ---------------------------------------------------------------------------
1900 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1901 dnl --------------
1902 dnl Find version of gcc
1903 AC_DEFUN([CF_GCC_VERSION],[
1904 AC_REQUIRE([AC_PROG_CC])
1905 GCC_VERSION=none
1906 if test "$GCC" = yes ; then
1907         AC_MSG_CHECKING(version of $CC)
1908         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1909         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1910         AC_MSG_RESULT($GCC_VERSION)
1911 fi
1912 ])dnl
1913 dnl ---------------------------------------------------------------------------
1914 dnl CF_GCC_WARNINGS version: 29 updated: 2012/06/16 14:55:39
1915 dnl ---------------
1916 dnl Check if the compiler supports useful warning options.  There's a few that
1917 dnl we don't use, simply because they're too noisy:
1918 dnl
1919 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1920 dnl     -Wredundant-decls (system headers make this too noisy)
1921 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1922 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1923 dnl             is enabled for ncurses using "--enable-const".
1924 dnl     -pedantic
1925 dnl
1926 dnl Parameter:
1927 dnl     $1 is an optional list of gcc warning flags that a particular
1928 dnl             application might want to use, e.g., "no-unused" for
1929 dnl             -Wno-unused
1930 dnl Special:
1931 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1932 dnl
1933 AC_DEFUN([CF_GCC_WARNINGS],
1934 [
1935 AC_REQUIRE([CF_GCC_VERSION])
1936 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1937 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1938
1939 cat > conftest.$ac_ext <<EOF
1940 #line __oline__ "${as_me:-configure}"
1941 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1942 EOF
1943
1944 if test "$INTEL_COMPILER" = yes
1945 then
1946 # The "-wdXXX" options suppress warnings:
1947 # remark #1419: external declaration in primary source file
1948 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1949 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1950 # remark #193: zero used for undefined preprocessing identifier
1951 # remark #593: variable "curs_sb_left_arrow" was set but never used
1952 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1953 # remark #869: parameter "tw" was never referenced
1954 # remark #981: operands are evaluated in unspecified order
1955 # warning #279: controlling expression is constant
1956
1957         AC_CHECKING([for $CC warning options])
1958         cf_save_CFLAGS="$CFLAGS"
1959         EXTRA_CFLAGS="-Wall"
1960         for cf_opt in \
1961                 wd1419 \
1962                 wd1683 \
1963                 wd1684 \
1964                 wd193 \
1965                 wd593 \
1966                 wd279 \
1967                 wd810 \
1968                 wd869 \
1969                 wd981
1970         do
1971                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1972                 if AC_TRY_EVAL(ac_compile); then
1973                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1974                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1975                 fi
1976         done
1977         CFLAGS="$cf_save_CFLAGS"
1978
1979 elif test "$GCC" = yes
1980 then
1981         AC_CHECKING([for $CC warning options])
1982         cf_save_CFLAGS="$CFLAGS"
1983         EXTRA_CFLAGS=
1984         cf_warn_CONST=""
1985         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1986         for cf_opt in W Wall \
1987                 Wbad-function-cast \
1988                 Wcast-align \
1989                 Wcast-qual \
1990                 Winline \
1991                 Wmissing-declarations \
1992                 Wmissing-prototypes \
1993                 Wnested-externs \
1994                 Wpointer-arith \
1995                 Wshadow \
1996                 Wstrict-prototypes \
1997                 Wundef $cf_warn_CONST $1
1998         do
1999                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2000                 if AC_TRY_EVAL(ac_compile); then
2001                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2002                         case $cf_opt in #(vi
2003                         Wcast-qual) #(vi
2004                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2005                                 ;;
2006                         Winline) #(vi
2007                                 case $GCC_VERSION in
2008                                 [[34]].*)
2009                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2010                                         continue;;
2011                                 esac
2012                                 ;;
2013                         Wpointer-arith) #(vi
2014                                 case $GCC_VERSION in
2015                                 [[12]].*)
2016                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2017                                         continue;;
2018                                 esac
2019                                 ;;
2020                         esac
2021                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2022                 fi
2023         done
2024         CFLAGS="$cf_save_CFLAGS"
2025 fi
2026 rm -rf conftest*
2027
2028 AC_SUBST(EXTRA_CFLAGS)
2029 ])dnl
2030 dnl ---------------------------------------------------------------------------
2031 dnl CF_GETOPT_HEADER version: 5 updated: 2012/10/06 16:39:58
2032 dnl ----------------
2033 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2034 dnl unistd.h or (nonstandard) in getopt.h
2035 AC_DEFUN([CF_GETOPT_HEADER],
2036 [
2037 AC_HAVE_HEADERS(unistd.h getopt.h)
2038 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2039 cf_cv_getopt_header=none
2040 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2041 do
2042 AC_TRY_COMPILE([
2043 #include <$cf_header>],
2044 [int x = optind; char *y = optarg],
2045 [cf_cv_getopt_header=$cf_header
2046  break])
2047 done
2048 ])
2049 if test $cf_cv_getopt_header != none ; then
2050         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if we need to include getopt.h])
2051 fi
2052 ])dnl
2053 dnl ---------------------------------------------------------------------------
2054 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
2055 dnl ----------------
2056 AC_DEFUN([CF_GNAT_GENERICS],
2057 [
2058 AC_REQUIRE([CF_GNAT_VERSION])
2059
2060 AC_MSG_CHECKING(if GNAT supports generics)
2061 case $cf_gnat_version in #(vi
2062 3.[[1-9]]*|[[4-9]].*) #(vi
2063         cf_gnat_generics=yes
2064         ;;
2065 *)
2066         cf_gnat_generics=no
2067         ;;
2068 esac
2069 AC_MSG_RESULT($cf_gnat_generics)
2070
2071 if test "$cf_gnat_generics" = yes
2072 then
2073         cf_compile_generics=generics
2074         cf_generic_objects="\${GENOBJS}"
2075 else
2076         cf_compile_generics=
2077         cf_generic_objects=
2078 fi
2079
2080 AC_SUBST(cf_compile_generics)
2081 AC_SUBST(cf_generic_objects)
2082 ])dnl
2083 dnl ---------------------------------------------------------------------------
2084 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
2085 dnl --------------------
2086 dnl Check if the gnat pragma "Unreferenced" works.
2087 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
2088 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
2089 CF_GNAT_TRY_LINK([procedure conftest;],
2090 [with Text_IO;
2091 with GNAT.OS_Lib;
2092 procedure conftest is
2093    test : Integer;
2094    pragma Unreferenced (test);
2095 begin
2096    test := 1;
2097    Text_IO.Put ("Hello World");
2098    Text_IO.New_Line;
2099    GNAT.OS_Lib.OS_Exit (0);
2100 end conftest;],
2101         [cf_cv_pragma_unreferenced=yes],
2102         [cf_cv_pragma_unreferenced=no])])
2103
2104 # if the pragma is supported, use it (needed in the Trace code).
2105 if test $cf_cv_pragma_unreferenced = yes ; then
2106         PRAGMA_UNREF=TRUE
2107 else
2108         PRAGMA_UNREF=FALSE
2109 fi
2110 AC_SUBST(PRAGMA_UNREF)
2111 ])dnl
2112 dnl ---------------------------------------------------------------------------
2113 dnl CF_GNAT_PROJECTS version: 2 updated: 2011/03/23 20:24:41
2114 dnl ----------------
2115 dnl GNAT projects are configured with ".gpr" project files.
2116 dnl GNAT libraries are a further development, using the project feature.
2117 AC_DEFUN([CF_GNAT_PROJECTS],
2118 [
2119 AC_REQUIRE([CF_GNAT_VERSION])
2120
2121 cf_gnat_libraries=no
2122 cf_gnat_projects=no
2123
2124 AC_MSG_CHECKING(if GNAT supports project files)
2125 case $cf_gnat_version in #(vi
2126 3.[[0-9]]*) #(vi
2127         ;;
2128 *)
2129         case $cf_cv_system_name in #(vi
2130         cygwin*) #(vi
2131                 ;;
2132         *)
2133                 mkdir conftest.src conftest.bin conftest.lib
2134                 cd conftest.src
2135                 rm -rf conftest* *~conftest*
2136                 cat >>library.gpr <<CF_EOF
2137 project Library is
2138   Kind := External ("LIB_KIND");
2139   for Library_Name use "ConfTest";
2140   for Object_Dir use ".";
2141   for Library_ALI_Dir use External("LIBRARY_DIR");
2142   for Library_Version use External ("SONAME");
2143   for Library_Kind use Kind;
2144   for Library_Dir use External("BUILD_DIR");
2145   Source_Dir := External ("SOURCE_DIR");
2146   for Source_Dirs use (Source_Dir);
2147   package Compiler is
2148      for Default_Switches ("Ada") use
2149        ("-g",
2150         "-O2",
2151         "-gnatafno",
2152         "-gnatVa",   -- All validity checks
2153         "-gnatwa");  -- Activate all optional errors
2154   end Compiler;
2155 end Library;
2156 CF_EOF
2157                 cat >>confpackage.ads <<CF_EOF
2158 package ConfPackage is
2159    procedure conftest;
2160 end ConfPackage;
2161 CF_EOF
2162                 cat >>confpackage.adb <<CF_EOF
2163 with Text_IO;
2164 package body ConfPackage is
2165    procedure conftest is
2166    begin
2167       Text_IO.Put ("Hello World");
2168       Text_IO.New_Line;
2169    end conftest;
2170 end ConfPackage;
2171 CF_EOF
2172                 if ( $cf_ada_make $ADAFLAGS \
2173                                 -Plibrary.gpr \
2174                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2175                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2176                                 -XSOURCE_DIR=`pwd` \
2177                                 -XSONAME=libConfTest.so.1 \
2178                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2179                         cf_gnat_projects=yes
2180                 fi
2181                 cd ..
2182                 if test -f conftest.lib/confpackage.ali
2183                 then
2184                         cf_gnat_libraries=yes
2185                 fi
2186                 rm -rf conftest* *~conftest*
2187                 ;;
2188         esac
2189         ;;
2190 esac
2191 AC_MSG_RESULT($cf_gnat_projects)
2192
2193 if test $cf_gnat_projects = yes
2194 then
2195         AC_MSG_CHECKING(if GNAT supports libraries)
2196         AC_MSG_RESULT($cf_gnat_libraries)
2197 fi
2198
2199 if test "$cf_gnat_projects" = yes
2200 then
2201         USE_OLD_MAKERULES="#"
2202         USE_GNAT_PROJECTS=""
2203 else
2204         USE_OLD_MAKERULES=""
2205         USE_GNAT_PROJECTS="#"
2206 fi
2207
2208 if test "$cf_gnat_libraries" = yes
2209 then
2210         USE_GNAT_LIBRARIES=""
2211 else
2212         USE_GNAT_LIBRARIES="#"
2213 fi
2214
2215 AC_SUBST(USE_OLD_MAKERULES)
2216 AC_SUBST(USE_GNAT_PROJECTS)
2217 AC_SUBST(USE_GNAT_LIBRARIES)
2218 ])dnl
2219 dnl ---------------------------------------------------------------------------
2220 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2221 dnl --------------
2222 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2223 dnl is noted that gnat may compile a tasking unit even for configurations which
2224 dnl fail at runtime.
2225 AC_DEFUN([CF_GNAT_SIGINT],[
2226 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2227 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2228
2229 package ConfTest is
2230
2231    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2232    pragma Unreserve_All_Interrupts;
2233    pragma Warnings (On);
2234
2235    protected Process is
2236       procedure Stop;
2237       function Continue return Boolean;
2238       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2239    private
2240       Done : Boolean := False;
2241    end Process;
2242
2243 end ConfTest;],
2244 [package body ConfTest is
2245    protected body Process is
2246       procedure Stop is
2247       begin
2248          Done := True;
2249       end Stop;
2250       function Continue return Boolean is
2251       begin
2252          return not Done;
2253       end Continue;
2254    end Process;
2255 end ConfTest;],
2256         [cf_cv_gnat_sigint=yes],
2257         [cf_cv_gnat_sigint=no])])
2258
2259 if test $cf_cv_gnat_sigint = yes ; then
2260         USE_GNAT_SIGINT=""
2261 else
2262         USE_GNAT_SIGINT="#"
2263 fi
2264 AC_SUBST(USE_GNAT_SIGINT)
2265 ])dnl
2266 dnl ---------------------------------------------------------------------------
2267 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2268 dnl ----------------
2269 dnl Verify that a test program compiles/links with GNAT.
2270 dnl $cf_ada_make is set to the program that compiles/links
2271 dnl $ADAFLAGS may be set to the GNAT flags.
2272 dnl
2273 dnl $1 is the text of the spec
2274 dnl $2 is the text of the body
2275 dnl $3 is the shell command to execute if successful
2276 dnl $4 is the shell command to execute if not successful
2277 AC_DEFUN([CF_GNAT_TRY_LINK],
2278 [
2279 rm -rf conftest* *~conftest*
2280 cat >>conftest.ads <<CF_EOF
2281 $1
2282 CF_EOF
2283 cat >>conftest.adb <<CF_EOF
2284 $2
2285 CF_EOF
2286 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2287 ifelse($3,,      :,[      $3])
2288 ifelse($4,,,[else
2289    $4])
2290 fi
2291 rm -rf conftest* *~conftest*
2292 ])dnl
2293 dnl ---------------------------------------------------------------------------
2294 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2295 dnl ---------------
2296 dnl Verify that a test program compiles and runs with GNAT
2297 dnl $cf_ada_make is set to the program that compiles/links
2298 dnl $ADAFLAGS may be set to the GNAT flags.
2299 dnl
2300 dnl $1 is the text of the spec
2301 dnl $2 is the text of the body
2302 dnl $3 is the shell command to execute if successful
2303 dnl $4 is the shell command to execute if not successful
2304 AC_DEFUN([CF_GNAT_TRY_RUN],
2305 [
2306 rm -rf conftest* *~conftest*
2307 cat >>conftest.ads <<CF_EOF
2308 $1
2309 CF_EOF
2310 cat >>conftest.adb <<CF_EOF
2311 $2
2312 CF_EOF
2313 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2314    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2315 ifelse($3,,      :,[      $3])
2316 ifelse($4,,,[   else
2317       $4])
2318    fi
2319 ifelse($4,,,[else
2320    $4])
2321 fi
2322 rm -rf conftest* *~conftest*
2323 ])dnl
2324 dnl ---------------------------------------------------------------------------
2325 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
2326 dnl ---------------
2327 dnl Verify version of GNAT.
2328 AC_DEFUN([CF_GNAT_VERSION],
2329 [
2330 AC_MSG_CHECKING(for gnat version)
2331 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2332         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2333     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2334 AC_MSG_RESULT($cf_gnat_version)
2335
2336 case $cf_gnat_version in #(vi
2337 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
2338         cf_cv_prog_gnat_correct=yes
2339         ;;
2340 *)
2341         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2342         cf_cv_prog_gnat_correct=no
2343         ;;
2344 esac
2345 ])
2346 dnl ---------------------------------------------------------------------------
2347 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2348 dnl -------------
2349 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2350 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2351 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2352 dnl since it is interwoven with GNU extensions.
2353 dnl
2354 dnl Well, yes we could work around it...
2355 AC_DEFUN([CF_GNU_SOURCE],
2356 [
2357 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2358 AC_TRY_COMPILE([#include <sys/types.h>],[
2359 #ifndef _XOPEN_SOURCE
2360 make an error
2361 #endif],
2362         [cf_cv_gnu_source=no],
2363         [cf_save="$CPPFLAGS"
2364          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2365          AC_TRY_COMPILE([#include <sys/types.h>],[
2366 #ifdef _XOPEN_SOURCE
2367 make an error
2368 #endif],
2369         [cf_cv_gnu_source=no],
2370         [cf_cv_gnu_source=yes])
2371         CPPFLAGS="$cf_save"
2372         ])
2373 ])
2374 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2375 ])dnl
2376 dnl ---------------------------------------------------------------------------
2377 dnl CF_GPP_LIBRARY version: 11 updated: 2012/10/06 17:56:13
2378 dnl --------------
2379 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2380 dnl problem :-).  If we have the compiler but no library, we'll be able to
2381 dnl configure, but won't be able to build the c++ demo program.
2382 AC_DEFUN([CF_GPP_LIBRARY],
2383 [
2384 cf_cxx_library=unknown
2385 case $cf_cv_system_name in #(vi
2386 os2*) #(vi
2387         cf_gpp_libname=gpp
2388         ;;
2389 *)
2390         cf_gpp_libname=g++
2391         ;;
2392 esac
2393 if test "$GXX" = yes; then
2394         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2395         cf_save="$LIBS"
2396         CF_ADD_LIB($cf_gpp_libname)
2397         AC_TRY_LINK([
2398 #include <$cf_gpp_libname/builtin.h>
2399         ],
2400         [two_arg_error_handler_t foo2 = lib_error_handler],
2401         [cf_cxx_library=yes
2402          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2403          if test "$cf_gpp_libname" = cpp ; then
2404             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2405          else
2406             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2407          fi],
2408         [AC_TRY_LINK([
2409 #include <builtin.h>
2410         ],
2411         [two_arg_error_handler_t foo2 = lib_error_handler],
2412         [cf_cxx_library=yes
2413          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2414          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2415         [cf_cxx_library=no])])
2416         LIBS="$cf_save"
2417         AC_MSG_RESULT($cf_cxx_library)
2418 fi
2419 ])dnl
2420 dnl ---------------------------------------------------------------------------
2421 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2422 dnl --------------
2423 dnl Check for version of g++
2424 AC_DEFUN([CF_GXX_VERSION],[
2425 AC_REQUIRE([AC_PROG_CPP])
2426 GXX_VERSION=none
2427 if test "$GXX" = yes; then
2428         AC_MSG_CHECKING(version of ${CXX:-g++})
2429         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2430         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2431         AC_MSG_RESULT($GXX_VERSION)
2432 fi
2433 ])dnl
2434 dnl ---------------------------------------------------------------------------
2435 dnl CF_GXX_WARNINGS version: 7 updated: 2012/06/16 14:55:39
2436 dnl ---------------
2437 dnl Check if the compiler supports useful warning options.
2438 dnl
2439 dnl Most of gcc's options apply to g++, except:
2440 dnl     -Wbad-function-cast
2441 dnl     -Wmissing-declarations
2442 dnl     -Wnested-externs
2443 dnl
2444 dnl Omit a few (for now):
2445 dnl     -Winline
2446 dnl
2447 dnl Parameter:
2448 dnl     $1 is an optional list of g++ warning flags that a particular
2449 dnl             application might want to use, e.g., "no-unused" for
2450 dnl             -Wno-unused
2451 dnl Special:
2452 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2453 dnl
2454 AC_DEFUN([CF_GXX_WARNINGS],
2455 [
2456
2457 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2458 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2459
2460 AC_REQUIRE([CF_GXX_VERSION])
2461
2462 AC_LANG_SAVE
2463 AC_LANG_CPLUSPLUS
2464
2465 cat > conftest.$ac_ext <<EOF
2466 #line __oline__ "configure"
2467 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2468 EOF
2469
2470 if test "$INTEL_CPLUSPLUS" = yes
2471 then
2472 # The "-wdXXX" options suppress warnings:
2473 # remark #1419: external declaration in primary source file
2474 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2475 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2476 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2477 # remark #193: zero used for undefined preprocessing identifier
2478 # remark #593: variable "curs_sb_left_arrow" was set but never used
2479 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2480 # remark #869: parameter "tw" was never referenced
2481 # remark #981: operands are evaluated in unspecified order
2482 # warning #269: invalid format string conversion
2483
2484         AC_CHECKING([for $CC warning options])
2485         cf_save_CXXFLAGS="$CXXFLAGS"
2486         EXTRA_CXXFLAGS="-Wall"
2487         for cf_opt in \
2488                 wd1419 \
2489                 wd1682 \
2490                 wd1683 \
2491                 wd1684 \
2492                 wd193 \
2493                 wd279 \
2494                 wd593 \
2495                 wd810 \
2496                 wd869 \
2497                 wd981
2498         do
2499                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2500                 if AC_TRY_EVAL(ac_compile); then
2501                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2502                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2503                 fi
2504         done
2505         CXXFLAGS="$cf_save_CXXFLAGS"
2506
2507 elif test "$GXX" = yes
2508 then
2509         AC_CHECKING([for $CXX warning options])
2510         cf_save_CXXFLAGS="$CXXFLAGS"
2511         EXTRA_CXXFLAGS="-W -Wall"
2512         cf_gxx_extra_warnings=""
2513         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2514         case "$GCC_VERSION" in
2515         [[1-2]].*)
2516                 ;;
2517         *)
2518                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2519                 ;;
2520         esac
2521         for cf_opt in \
2522                 Wabi \
2523                 fabi-version=0 \
2524                 Woverloaded-virtual \
2525                 Wsign-promo \
2526                 Wsynth \
2527                 Wold-style-cast \
2528                 Wcast-align \
2529                 Wcast-qual \
2530                 Wmissing-prototypes \
2531                 Wpointer-arith \
2532                 Wshadow \
2533                 Wstrict-prototypes \
2534                 Wundef $cf_gxx_extra_warnings $1
2535         do
2536                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2537                 if AC_TRY_EVAL(ac_compile); then
2538                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2539                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2540                 else
2541                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2542                 fi
2543         done
2544         CXXFLAGS="$cf_save_CXXFLAGS"
2545 fi
2546
2547 rm -rf conftest*
2548 AC_LANG_RESTORE
2549 AC_SUBST(EXTRA_CXXFLAGS)
2550 ])dnl
2551 dnl ---------------------------------------------------------------------------
2552 dnl CF_HASHED_DB version: 4 updated: 2010/05/29 16:31:02
2553 dnl ------------
2554 dnl Look for an instance of the Berkeley hashed database.
2555 dnl
2556 dnl $1 = optional parameter, to specify install-prefix for the database.
2557 AC_DEFUN([CF_HASHED_DB],
2558 [
2559 ifelse([$1],,,[
2560 case $1 in #(vi
2561 yes|*able*) #(vi
2562     ;;
2563 *)
2564     if test -d "$1" ; then
2565         CF_ADD_INCDIR($1/include)
2566         CF_ADD_LIBDIR($1/lib)
2567     fi
2568 esac
2569 ])
2570 AC_CHECK_HEADER(db.h,[
2571 CF_HASHED_DB_VERSION
2572 if test "$cf_cv_hashed_db_version" = unknown ; then
2573         AC_MSG_ERROR(Cannot determine version of db)
2574 else
2575         CF_HASHED_DB_LIBS
2576         if test "$cf_cv_hashed_db_libs" = unknown ; then
2577                 AC_MSG_ERROR(Cannot determine library for db)
2578         elif test "$cf_cv_hashed_db_libs" != default ; then
2579                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2580         fi
2581 fi
2582 ],[
2583         AC_MSG_ERROR(Cannot find db.h)
2584 ])
2585 ])dnl
2586 dnl ---------------------------------------------------------------------------
2587 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2588 dnl -----------------
2589 dnl Given that we have the header and version for hashed database, find the
2590 dnl library information.
2591 AC_DEFUN([CF_HASHED_DB_LIBS],
2592 [
2593 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2594 cf_cv_hashed_db_libs=unknown
2595 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2596 do
2597         cf_save_libs="$LIBS"
2598         if test -n "$cf_db_libs"; then
2599                 CF_ADD_LIB($cf_db_libs)
2600         fi
2601         CF_MSG_LOG(checking for library "$cf_db_libs")
2602         AC_TRY_LINK([
2603 $ac_includes_default
2604 #include <db.h>
2605 ],[
2606         char *path = "/tmp/foo";
2607 #ifdef DB_VERSION_MAJOR
2608 #if DB_VERSION_MAJOR >= 4
2609         DB *result = 0;
2610         db_create(&result, NULL, 0);
2611         result->open(result,
2612                 NULL,
2613                 path,
2614                 path,
2615                 DB_HASH,
2616                 DB_CREATE,
2617                 0644);
2618 #elif DB_VERSION_MAJOR >= 3
2619         DB *result = 0;
2620         db_create(&result, NULL, 0);
2621         result->open(result,
2622                 path,
2623                 path,
2624                 DB_HASH,
2625                 DB_CREATE,
2626                 0644);
2627 #elif DB_VERSION_MAJOR >= 2
2628         DB *result = 0;
2629         db_open(path,
2630                 DB_HASH,
2631                 DB_CREATE,
2632                 0644,
2633                 (DB_ENV *) 0,
2634                 (DB_INFO *) 0,
2635                 &result);
2636 #endif /* DB_VERSION_MAJOR */
2637 #else
2638         DB *result = dbopen(path,
2639                      2,
2640                      0644,
2641                      DB_HASH,
2642                      0);
2643 #endif
2644         ${cf_cv_main_return:-return}(result != 0)
2645 ],[
2646         if test -n "$cf_db_libs" ; then
2647                 cf_cv_hashed_db_libs=$cf_db_libs
2648         else
2649                 cf_cv_hashed_db_libs=default
2650         fi
2651         LIBS="$cf_save_libs"
2652         break
2653 ])
2654         LIBS="$cf_save_libs"
2655 done
2656 ])
2657 ])dnl
2658 dnl ---------------------------------------------------------------------------
2659 dnl CF_HASHED_DB_VERSION version: 3 updated: 2007/12/01 15:01:37
2660 dnl --------------------
2661 dnl Given that we have the header file for hashed database, find the version
2662 dnl information.
2663 AC_DEFUN([CF_HASHED_DB_VERSION],
2664 [
2665 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2666 cf_cv_hashed_db_version=unknown
2667
2668 for cf_db_version in 1 2 3 4 5
2669 do
2670         CF_MSG_LOG(checking for db version $cf_db_version)
2671         AC_TRY_COMPILE([
2672 $ac_includes_default
2673 #include <db.h>
2674
2675 #ifdef DB_VERSION_MAJOR
2676         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2677 #if $cf_db_version == DB_VERSION_MAJOR
2678         /* ok */
2679 #else
2680         make an error
2681 #endif
2682 #else
2683 #if $cf_db_version == 1
2684         /* ok: assuming this is DB 1.8.5 */
2685 #else
2686         make an error
2687 #endif
2688 #endif
2689 ],[DBT *foo = 0],[
2690         cf_cv_hashed_db_version=$cf_db_version
2691         break
2692         ])
2693 done
2694 ])
2695 ])dnl
2696 dnl ---------------------------------------------------------------------------
2697 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2698 dnl --------------
2699 dnl Construct a search-list of directories for a nonstandard header-file
2700 dnl
2701 dnl Parameters
2702 dnl     $1 = the variable to return as result
2703 dnl     $2 = the package name
2704 AC_DEFUN([CF_HEADER_PATH],
2705 [
2706 $1=
2707
2708 # collect the current set of include-directories from compiler flags
2709 cf_header_path_list=""
2710 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2711         for cf_header_path in $CPPFLAGS $CFLAGS
2712         do
2713                 case $cf_header_path in #(vi
2714                 -I*)
2715                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2716                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2717                         cf_header_path_list="$cf_header_path_list [$]$1"
2718                         ;;
2719                 esac
2720         done
2721 fi
2722
2723 # add the variations for the package we are looking for
2724 CF_SUBDIR_PATH($1,$2,include)
2725
2726 test "$includedir" != NONE && \
2727 test "$includedir" != "/usr/include" && \
2728 test -d "$includedir" && {
2729         test -d $includedir &&    $1="[$]$1 $includedir"
2730         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2731 }
2732
2733 test "$oldincludedir" != NONE && \
2734 test "$oldincludedir" != "/usr/include" && \
2735 test -d "$oldincludedir" && {
2736         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2737         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2738 }
2739
2740 $1="[$]$1 $cf_header_path_list"
2741 ])dnl
2742 dnl ---------------------------------------------------------------------------
2743 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2744 dnl ---------------
2745 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2746 AC_DEFUN([CF_HELP_MESSAGE],
2747 [AC_DIVERT_HELP([$1])dnl
2748 ])dnl
2749 dnl ---------------------------------------------------------------------------
2750 dnl CF_INCLUDE_DIRS version: 7 updated: 2012/11/10 19:15:05
2751 dnl ---------------
2752 dnl Construct the list of include-options according to whether we're building
2753 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2754 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2755 dnl since that usually breaks gcc's shadow-includes.
2756 AC_DEFUN([CF_INCLUDE_DIRS],
2757 [
2758 if test "$GCC" != yes; then
2759         CPPFLAGS="-I\${includedir} $CPPFLAGS"
2760 elif test "$includedir" != "/usr/include"; then
2761         if test "$includedir" = '${prefix}/include' ; then
2762                 if test $prefix != /usr ; then
2763                         CPPFLAGS="-I\${includedir} $CPPFLAGS"
2764                 fi
2765         else
2766                 CPPFLAGS="-I\${includedir} $CPPFLAGS"
2767         fi
2768 fi
2769 if test "$srcdir" != "."; then
2770         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
2771 fi
2772 CPPFLAGS="-I. -I../include $CPPFLAGS"
2773 AC_SUBST(CPPFLAGS)
2774 ])dnl
2775 dnl ---------------------------------------------------------------------------
2776 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
2777 dnl -----------------
2778 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2779 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2780 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2781 dnl
2782 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2783 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2784 dnl the wrappers for gcc and g++ warnings.
2785 dnl
2786 dnl $1 = GCC (default) or GXX
2787 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2788 dnl $3 = CFLAGS (default) or CXXFLAGS
2789 AC_DEFUN([CF_INTEL_COMPILER],[
2790 ifelse([$2],,INTEL_COMPILER,[$2])=no
2791
2792 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2793         case $host_os in
2794         linux*|gnu*)
2795                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2796                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2797                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2798                 AC_TRY_COMPILE([],[
2799 #ifdef __INTEL_COMPILER
2800 #else
2801 make an error
2802 #endif
2803 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2804 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
2805 ],[])
2806                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2807                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2808                 ;;
2809         esac
2810 fi
2811 ])dnl
2812 dnl ---------------------------------------------------------------------------
2813 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
2814 dnl ----------
2815 dnl Check if we have either a function or macro for 'isascii()'.
2816 AC_DEFUN([CF_ISASCII],
2817 [
2818 AC_MSG_CHECKING(for isascii)
2819 AC_CACHE_VAL(cf_cv_have_isascii,[
2820         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2821         [cf_cv_have_isascii=yes],
2822         [cf_cv_have_isascii=no])
2823 ])dnl
2824 AC_MSG_RESULT($cf_cv_have_isascii)
2825 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
2826 ])dnl
2827 dnl ---------------------------------------------------------------------------
2828 dnl CF_LARGEFILE version: 8 updated: 2012/10/06 08:57:51
2829 dnl ------------
2830 dnl Add checks for large file support.
2831 AC_DEFUN([CF_LARGEFILE],[
2832 ifdef([AC_FUNC_FSEEKO],[
2833     AC_SYS_LARGEFILE
2834     if test "$enable_largefile" != no ; then
2835         AC_FUNC_FSEEKO
2836
2837         # Normally we would collect these definitions in the config.h,
2838         # but (like _XOPEN_SOURCE), some environments rely on having these
2839         # defined before any of the system headers are included.  Another
2840         # case comes up with C++, e.g., on AIX the compiler compiles the
2841         # header files by themselves before looking at the body files it is
2842         # told to compile.  For ncurses, those header files do not include
2843         # the config.h
2844         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2845         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2846         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2847
2848         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2849                 AC_TRY_COMPILE([
2850 #include <sys/types.h>
2851 #include <dirent.h>
2852                 ],[
2853                 /* if transitional largefile support is setup, this is true */
2854                 extern struct dirent64 * readdir(DIR *);
2855                 struct dirent64 *x = readdir((DIR *)0);
2856                 struct dirent *y = readdir((DIR *)0);
2857                 int z = x - y;
2858                 ],
2859                 [cf_cv_struct_dirent64=yes],
2860                 [cf_cv_struct_dirent64=no])
2861         ])
2862         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
2863     fi
2864 ])
2865 ])
2866 dnl ---------------------------------------------------------------------------
2867 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2868 dnl -----------------
2869 dnl Check for compiler/linker flags used to temporarily force usage of static
2870 dnl libraries.  This depends on the compiler and platform.  Use this to help
2871 dnl ensure that the linker picks up a given library based on its position in
2872 dnl the list of linker options and libraries.
2873 AC_DEFUN([CF_LDFLAGS_STATIC],[
2874
2875 if test "$GCC" = yes ; then
2876         case $cf_cv_system_name in #(
2877         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2878                 LDFLAGS_STATIC=
2879                 LDFLAGS_SHARED=
2880                 ;;
2881     *)  #( normally, except when broken
2882         LDFLAGS_STATIC=-static
2883         LDFLAGS_SHARED=-dynamic
2884         ;;
2885     esac
2886 else
2887         case $cf_cv_system_name in #(
2888         aix[[4-7]]*)    #( from ld manpage
2889                 LDFLAGS_STATIC=-bstatic
2890                 LDFLAGS_SHARED=-bdynamic
2891                 ;;
2892         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2893                 # We could also use just "archive" and "shared".
2894                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2895                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2896                 ;;
2897         irix*)          #( from ld manpage IRIX64
2898                 LDFLAGS_STATIC=-Bstatic
2899                 LDFLAGS_SHARED=-Bdynamic
2900                 ;;
2901         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2902                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2903                 LDFLAGS_STATIC=-noso
2904                 LDFLAGS_SHARED=-so_archive
2905                 ;;
2906         solaris2*)
2907                 LDFLAGS_STATIC=-Bstatic
2908                 LDFLAGS_SHARED=-Bdynamic
2909                 ;;
2910         esac
2911 fi
2912
2913 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
2914 then
2915         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
2916
2917         rm -f libconftest.a
2918         cat >conftest.$ac_ext <<EOF
2919 #line __oline__ "configure"
2920 #include <stdio.h>
2921 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
2922 EOF
2923         if AC_TRY_EVAL(ac_compile) ; then
2924                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
2925                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
2926         fi
2927         rm -f conftest.*
2928
2929         cf_save_LIBS="$LIBS"
2930
2931         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
2932         AC_TRY_LINK([
2933 #line __oline__ "configure"
2934 #include <stdio.h>
2935 int cf_ldflags_static(FILE *fp);
2936 ],[
2937         return cf_ldflags_static(stdin);
2938 ],[
2939         # some linkers simply ignore the -dynamic
2940         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
2941         *static*) # (vi
2942                 cf_ldflags_static=no
2943                 ;;
2944         *)
2945                 cf_ldflags_static=yes
2946                 ;;
2947         esac
2948 ],[cf_ldflags_static=no])
2949
2950         rm -f libconftest.*
2951         LIBS="$cf_save_LIBS"
2952
2953         AC_MSG_RESULT($cf_ldflags_static)
2954
2955         if test $cf_ldflags_static != yes
2956         then
2957                 LDFLAGS_STATIC=
2958                 LDFLAGS_SHARED=
2959         fi
2960 else
2961         LDFLAGS_STATIC=
2962         LDFLAGS_SHARED=
2963 fi
2964
2965 AC_SUBST(LDFLAGS_STATIC)
2966 AC_SUBST(LDFLAGS_SHARED)
2967 ])
2968 dnl ---------------------------------------------------------------------------
2969 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
2970 dnl ---------------
2971 dnl For the given system and compiler, find the compiler flags to pass to the
2972 dnl loader to use the "rpath" feature.
2973 AC_DEFUN([CF_LD_RPATH_OPT],
2974 [
2975 AC_REQUIRE([CF_CHECK_CACHE])
2976
2977 LD_RPATH_OPT=
2978 AC_MSG_CHECKING(for an rpath option)
2979 case $cf_cv_system_name in #(vi
2980 irix*) #(vi
2981         if test "$GCC" = yes; then
2982                 LD_RPATH_OPT="-Wl,-rpath,"
2983         else
2984                 LD_RPATH_OPT="-rpath "
2985         fi
2986         ;;
2987 linux*|gnu*|k*bsd*-gnu) #(vi
2988         LD_RPATH_OPT="-Wl,-rpath,"
2989         ;;
2990 openbsd[[2-9]].*|mirbsd*) #(vi
2991         LD_RPATH_OPT="-Wl,-rpath,"
2992         ;;
2993 dragonfly*|freebsd*) #(vi
2994         LD_RPATH_OPT="-rpath "
2995         ;;
2996 netbsd*) #(vi
2997         LD_RPATH_OPT="-Wl,-rpath,"
2998         ;;
2999 osf*|mls+*) #(vi
3000         LD_RPATH_OPT="-rpath "
3001         ;;
3002 solaris2*) #(vi
3003         LD_RPATH_OPT="-R"
3004         ;;
3005 *)
3006         ;;
3007 esac
3008 AC_MSG_RESULT($LD_RPATH_OPT)
3009
3010 case "x$LD_RPATH_OPT" in #(vi
3011 x-R*)
3012         AC_MSG_CHECKING(if we need a space after rpath option)
3013         cf_save_LIBS="$LIBS"
3014         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3015         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3016         LIBS="$cf_save_LIBS"
3017         AC_MSG_RESULT($cf_rpath_space)
3018         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3019         ;;
3020 esac
3021 ])dnl
3022 dnl ---------------------------------------------------------------------------
3023 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
3024 dnl ---------------
3025 dnl Construct a search-list of directories for a nonstandard library-file
3026 dnl
3027 dnl Parameters
3028 dnl     $1 = the variable to return as result
3029 dnl     $2 = the package name
3030 AC_DEFUN([CF_LIBRARY_PATH],
3031 [
3032 $1=
3033 cf_library_path_list=""
3034 if test -n "${LDFLAGS}${LIBS}" ; then
3035         for cf_library_path in $LDFLAGS $LIBS
3036         do
3037                 case $cf_library_path in #(vi
3038                 -L*)
3039                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3040                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3041                         cf_library_path_list="$cf_library_path_list [$]$1"
3042                         ;;
3043                 esac
3044         done
3045 fi
3046
3047 CF_SUBDIR_PATH($1,$2,lib)
3048
3049 $1="$cf_library_path_list [$]$1"
3050 ])dnl
3051 dnl ---------------------------------------------------------------------------
3052 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
3053 dnl -------------
3054 dnl Compute the library-prefix for the given host system
3055 dnl $1 = variable to set
3056 define([CF_LIB_PREFIX],
3057 [
3058         case $cf_cv_system_name in #(vi
3059         OS/2*|os2*) #(vi
3060         LIB_PREFIX=''
3061         ;;
3062         *)      LIB_PREFIX='lib'
3063         ;;
3064         esac
3065 ifelse($1,,,[$1=$LIB_PREFIX])
3066         AC_SUBST(LIB_PREFIX)
3067 ])dnl
3068 dnl ---------------------------------------------------------------------------
3069 dnl CF_LIB_RULES version: 67 updated: 2012/10/06 13:36:35
3070 dnl ------------
3071 dnl Append definitions and rules for the given models to the subdirectory
3072 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3073 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3074 dnl the corresponding makefile to list the models that we'll generate.
3075 dnl
3076 dnl For shared libraries, make a list of symbolic links to construct when
3077 dnl generating each library.  The convention used for Linux is the simplest
3078 dnl one:
3079 dnl     lib<name>.so    ->
3080 dnl     lib<name>.so.<major>    ->
3081 dnl     lib<name>.so.<maj>.<minor>
3082 dnl
3083 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3084 AC_DEFUN([CF_LIB_RULES],
3085 [
3086 cf_prefix=$LIB_PREFIX
3087 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3088
3089 case $cf_cv_shlib_version in #(vi
3090 cygdll|mingw)
3091         TINFO_NAME=$TINFO_ARG_SUFFIX
3092         TINFO_SUFFIX=.dll
3093         ;;
3094 esac
3095
3096 if test -n "$TINFO_SUFFIX" ; then
3097         case $TINFO_SUFFIX in
3098         tw*)
3099                 TINFO_NAME="${TINFO_NAME}tw"
3100                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
3101                 ;;
3102         t*)
3103                 TINFO_NAME="${TINFO_NAME}t"
3104                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3105                 ;;
3106         w*)
3107                 TINFO_NAME="${TINFO_NAME}w"
3108                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3109                 ;;
3110         esac
3111 fi
3112
3113 for cf_dir in $SRC_SUBDIRS
3114 do
3115         if test ! -d $srcdir/$cf_dir ; then
3116                 continue
3117         elif test -f $srcdir/$cf_dir/modules; then
3118
3119                 SHARED_LIB=
3120                 Libs_To_Make=
3121                 for cf_item in $cf_LIST_MODELS
3122                 do
3123                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3124                         if test $cf_item = shared ; then
3125                         if test "$cf_cv_do_symlinks" = yes ; then
3126                                 case "$cf_cv_shlib_version" in #(vi
3127                                 rel) #(vi
3128                                         case "$cf_cv_system_name" in #(vi
3129                                         darwin*)
3130                                         case .${LIB_SUFFIX} in
3131                                         .tw*)
3132                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3133                                                 cf_suffix=tw'.${REL_VERSION}'"$cf_suffix"
3134                                                 ;;
3135                                         .t*)
3136                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3137                                                 cf_suffix=t'.${REL_VERSION}'"$cf_suffix"
3138                                                 ;;
3139                                         .w*)
3140                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3141                                                 cf_suffix=w'.${REL_VERSION}'"$cf_suffix"
3142                                                 ;;
3143                                         *)
3144                                                 cf_suffix='.${REL_VERSION}'"$cf_suffix"
3145                                                 ;;
3146                                         esac
3147                                         ;; #(vi
3148                                         *) cf_suffix="$cf_suffix"'.${REL_VERSION}' ;;
3149                                         esac
3150                                         ;;
3151                                 abi)
3152                                         case "$cf_cv_system_name" in #(vi
3153                                         darwin*)
3154                                         case .${LIB_SUFFIX} in
3155                                         .tw*)
3156                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3157                                                 cf_suffix=tw'.${ABI_VERSION}'"$cf_suffix"
3158                                                 ;;
3159                                         .t*)
3160                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3161                                                 cf_suffix=t'.${ABI_VERSION}'"$cf_suffix"
3162                                                 ;;
3163                                         .w*)
3164                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3165                                                 cf_suffix=w'.${ABI_VERSION}'"$cf_suffix"
3166                                                 ;;
3167                                         *)
3168                                                 cf_suffix='.${ABI_VERSION}'"$cf_suffix"
3169                                                 ;;
3170                                         esac
3171                                         ;; #(vi
3172                                         *) cf_suffix="$cf_suffix"'.${ABI_VERSION}' ;;
3173                                         esac
3174                                         ;;
3175                                 esac
3176                         fi
3177                         # cygwin needs import library, and has unique naming convention
3178                         # use autodetected ${cf_prefix} for import lib and static lib, but
3179                         # use 'cyg' prefix for shared lib.
3180                         case $cf_cv_shlib_version in #(vi
3181                         cygdll) #(vi
3182                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3183                                 Libs_To_Make="$Libs_To_Make ../lib/cyg${cf_dir}${cf_cygsuf}"
3184                                 continue
3185                                 ;;
3186                         mingw)
3187                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3188                                 Libs_To_Make="$Libs_To_Make ../lib/lib${cf_dir}${cf_cygsuf}"
3189                                 continue
3190                                 ;;
3191                         esac
3192                         fi
3193                         Libs_To_Make="$Libs_To_Make ../lib/${cf_prefix}${cf_dir}${cf_suffix}"
3194                 done
3195
3196                 if test $cf_dir = ncurses ; then
3197                         cf_subsets="$LIB_SUBSETS"
3198                         cf_r_parts="$cf_subsets"
3199                         cf_liblist="$Libs_To_Make"
3200
3201                         while test -n "$cf_r_parts"
3202                         do
3203                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3204                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3205                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3206                                         cf_item=
3207                                         case $cf_l_parts in #(vi
3208                                         *termlib*) #(vi
3209                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3210                                                 ;;
3211                                         *ticlib*)
3212                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3213                                                 ;;
3214                                         *)
3215                                                 break
3216                                                 ;;
3217                                         esac
3218                                         if test -n "$cf_item"; then
3219                                                 Libs_To_Make="$cf_item $Libs_To_Make"
3220                                         fi
3221                                 else
3222                                         break
3223                                 fi
3224                         done
3225                 else
3226                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3227                 fi
3228
3229                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3230                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3231                         $cf_dir/Makefile >$cf_dir/Makefile.out
3232                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3233
3234                 $AWK -f $srcdir/mk-0th.awk \
3235                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3236                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3237
3238                 for cf_subset in $cf_subsets
3239                 do
3240                         cf_subdirs=
3241                         for cf_item in $cf_LIST_MODELS
3242                         do
3243                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3244                         CF_UPPER(cf_ITEM,$cf_item)
3245                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3246                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3247
3248                         # Test for case where we build libtinfo with a different name.
3249                         cf_libname=$cf_dir
3250                         if test $cf_dir = ncurses ; then
3251                                 case $cf_subset in
3252                                 *base*)
3253                                         cf_libname=${cf_libname}$LIB_SUFFIX
3254                                         ;;
3255                                 *termlib*)
3256                                         cf_libname=$TINFO_LIB_SUFFIX
3257                                         ;;
3258                                 ticlib*)
3259                                         cf_libname=$TICS_LIB_SUFFIX
3260                                         ;;
3261                                 esac
3262                         else
3263                                 cf_libname=${cf_libname}$LIB_SUFFIX
3264                         fi
3265                         if test -n "${DFT_ARG_SUFFIX}" ; then
3266                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3267                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3268                         fi
3269
3270                         # These dependencies really are for development, not
3271                         # builds, but they are useful in porting, too.
3272                         cf_depend="../include/ncurses_cfg.h"
3273                         if test "$srcdir" = "."; then
3274                                 cf_reldir="."
3275                         else
3276                                 cf_reldir="\${srcdir}"
3277                         fi
3278
3279                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3280                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3281                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3282                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3283                         fi
3284
3285                         cf_dir_suffix=
3286                         old_cf_suffix="$cf_suffix"
3287                         if test "$cf_cv_shlib_version_infix" = yes ; then
3288                         if test -n "$LIB_SUFFIX" ; then
3289                                 case $LIB_SUFFIX in
3290                                 tw*)
3291                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3292                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3293                                         cf_dir_suffix=tw
3294                                         ;;
3295                                 t*)
3296                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3297                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3298                                         cf_dir_suffix=t
3299                                         ;;
3300                                 w*)
3301                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3302                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3303                                         cf_dir_suffix=w
3304                                         ;;
3305                                 esac
3306                         fi
3307                         fi
3308
3309                         $AWK -f $srcdir/mk-1st.awk \
3310                                 name=${cf_libname}${cf_dir_suffix} \
3311                                 traces=$LIB_TRACING \
3312                                 MODEL=$cf_ITEM \
3313                                 model=$cf_subdir \
3314                                 prefix=$cf_prefix \
3315                                 suffix=$cf_suffix \
3316                                 subset=$cf_subset \
3317                                 driver=$cf_cv_term_driver \
3318                                 SymLink="$LN_S" \
3319                                 TermlibRoot=$TINFO_NAME \
3320                                 TermlibSuffix=$TINFO_SUFFIX \
3321                                 ShlibVer=$cf_cv_shlib_version \
3322                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3323                                 ReLink=${cf_cv_do_relink:-no} \
3324                                 DoLinks=$cf_cv_do_symlinks \
3325                                 rmSoLocs=$cf_cv_rm_so_locs \
3326                                 ldconfig="$LDCONFIG" \
3327                                 overwrite=$WITH_OVERWRITE \
3328                                 depend="$cf_depend" \
3329                                 host="$host" \
3330                                 libtool_version="$LIBTOOL_VERSION" \
3331                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3332
3333                         cf_suffix="$old_cf_suffix"
3334
3335                         for cf_subdir2 in $cf_subdirs lib
3336                         do
3337                                 test $cf_subdir = $cf_subdir2 && break
3338                         done
3339                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3340                         $AWK -f $srcdir/mk-2nd.awk \
3341                                 name=$cf_dir \
3342                                 traces=$LIB_TRACING \
3343                                 MODEL=$cf_ITEM \
3344                                 model=$cf_subdir \
3345                                 subset=$cf_subset \
3346                                 srcdir=$srcdir \
3347                                 echo=$WITH_ECHO \
3348                                 crenames=$cf_cv_prog_CC_c_o \
3349                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3350                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3351                         cf_subdirs="$cf_subdirs $cf_subdir"
3352                         done
3353                 done
3354         fi
3355
3356         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3357 done
3358
3359 for cf_dir in $SRC_SUBDIRS
3360 do
3361         if test ! -d $srcdir/$cf_dir ; then
3362                 continue
3363         fi
3364
3365         if test -f $cf_dir/Makefile ; then
3366                 case "$cf_dir" in
3367                 Ada95) #(vi
3368                         echo 'libs \' >> Makefile
3369                         echo 'install.libs \' >> Makefile
3370                         echo 'uninstall.libs ::' >> Makefile
3371                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3372                         ;;
3373                 esac
3374         fi
3375
3376         if test -f $srcdir/$cf_dir/modules; then
3377                 echo >> Makefile
3378                 if test -f $srcdir/$cf_dir/headers; then
3379 cat >> Makefile <<CF_EOF
3380 install.includes \\
3381 uninstall.includes \\
3382 CF_EOF
3383                 fi
3384 if test "$cf_dir" != "c++" ; then
3385 echo 'lint \' >> Makefile
3386 fi
3387 cat >> Makefile <<CF_EOF
3388 libs \\
3389 lintlib \\
3390 install.libs \\
3391 uninstall.libs \\
3392 install.$cf_dir \\
3393 uninstall.$cf_dir ::
3394         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3395 CF_EOF
3396         elif test -f $srcdir/$cf_dir/headers; then
3397 cat >> Makefile <<CF_EOF
3398
3399 libs \\
3400 install.libs \\
3401 uninstall.libs \\
3402 install.includes \\
3403 uninstall.includes ::
3404         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3405 CF_EOF
3406 fi
3407 done
3408
3409 cat >> Makefile <<CF_EOF
3410
3411 install.libs uninstall.libs \\
3412 install.data uninstall.data ::
3413 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3414 CF_EOF
3415
3416 if test "x$cf_with_manpages" = xyes; then
3417 cat >> Makefile <<CF_EOF
3418
3419 install.man \\
3420 uninstall.man ::
3421         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3422 CF_EOF
3423 fi
3424
3425 cat >> Makefile <<CF_EOF
3426
3427 distclean ::
3428         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3429         rm -f headers.sh headers.sed mk_shared_lib.sh
3430         rm -f edit_man.* man_alias.*
3431         rm -rf \${DIRS_TO_MAKE}
3432 CF_EOF
3433
3434 # Special case: tack's manpage lives in its own directory.
3435 if test "x$cf_with_manpages" = xyes; then
3436 if test -d tack ; then
3437 if test -f $srcdir/$tack.h; then
3438 cat >> Makefile <<CF_EOF
3439
3440 install.man \\
3441 uninstall.man ::
3442         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3443 CF_EOF
3444 fi
3445 fi
3446 fi
3447
3448 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3449 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3450 dnl anything, and will make it more standardized.  It's awkward to decide this
3451 dnl at configuration because of quoting, so we'll simply make all headers
3452 dnl installed via a script that can do the right thing.
3453
3454 rm -f headers.sed headers.sh
3455
3456 dnl ( generating this script makes the makefiles a little tidier :-)
3457 echo creating headers.sh
3458 cat >headers.sh <<CF_EOF
3459 #! /bin/sh
3460 # This shell script is generated by the 'configure' script.  It is invoked in a
3461 # subdirectory of the build tree.  It generates a sed-script in the parent
3462 # directory that is used to adjust includes for header files that reside in a
3463 # subdirectory of /usr/include, etc.
3464 PRG=""
3465 while test \[$]# != 3
3466 do
3467 PRG="\$PRG \[$]1"; shift
3468 done
3469 DST=\[$]1
3470 REF=\[$]2
3471 SRC=\[$]3
3472 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3473 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3474 echo installing \$SRC in \$DST
3475 CF_EOF
3476
3477 if test $WITH_CURSES_H = yes; then
3478         cat >>headers.sh <<CF_EOF
3479 case \$DST in
3480 /*/include/*)
3481         END=\`basename \$DST\`
3482         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3483         do
3484                 NAME=\`basename \$i\`
3485                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3486         done
3487         ;;
3488 *)
3489         echo "" >> \$TMPSED
3490         ;;
3491 esac
3492 CF_EOF
3493
3494 else
3495         cat >>headers.sh <<CF_EOF
3496 case \$DST in
3497 /*/include/*)
3498         END=\`basename \$DST\`
3499         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3500         do
3501                 NAME=\`basename \$i\`
3502                 if test "\$NAME" = "curses.h"
3503                 then
3504                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3505                         NAME=ncurses.h
3506                 fi
3507                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3508         done
3509         ;;
3510 *)
3511         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3512         ;;
3513 esac
3514 CF_EOF
3515 fi
3516 cat >>headers.sh <<CF_EOF
3517 rm -f \$TMPSRC
3518 sed -f \$TMPSED \$SRC > \$TMPSRC
3519 NAME=\`basename \$SRC\`
3520 CF_EOF
3521 if test $WITH_CURSES_H != yes; then
3522         cat >>headers.sh <<CF_EOF
3523 test "\$NAME" = "curses.h" && NAME=ncurses.h
3524 CF_EOF
3525 fi
3526 cat >>headers.sh <<CF_EOF
3527 # Just in case someone gzip'd manpages, remove the conflicting copy.
3528 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3529
3530 eval \$PRG \$TMPSRC \$DST/\$NAME
3531 rm -f \$TMPSRC \$TMPSED
3532 CF_EOF
3533
3534 chmod 0755 headers.sh
3535
3536 for cf_dir in $SRC_SUBDIRS
3537 do
3538         if test ! -d $srcdir/$cf_dir ; then
3539                 continue
3540         fi
3541
3542         if test -f $srcdir/$cf_dir/headers; then
3543                 $AWK -f $srcdir/mk-hdr.awk \
3544                         subset="$LIB_SUBSETS" \
3545                         compat="$WITH_CURSES_H" \
3546                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3547         fi
3548
3549         if test -f $srcdir/$cf_dir/modules; then
3550                 if test "$cf_dir" != "c++" ; then
3551                         cat >>$cf_dir/Makefile <<"CF_EOF"
3552 depend : ${AUTO_SRC}
3553         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3554
3555 # DO NOT DELETE THIS LINE -- make depend depends on it.
3556 CF_EOF
3557                 fi
3558         fi
3559 done
3560 AC_SUBST(Libs_To_Make)
3561 ])dnl
3562 dnl ---------------------------------------------------------------------------
3563 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3564 dnl -------------
3565 dnl Find the and soname for the given shared library.  Set the cache variable
3566 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3567 dnl variable to "unknown".
3568 dnl
3569 dnl $1 = headers
3570 dnl $2 = code
3571 dnl $3 = library name
3572 AC_DEFUN([CF_LIB_SONAME],
3573 [
3574 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3575
3576 cf_cv_$3_soname=unknown
3577 if test "$cross_compiling" != yes ; then
3578 cat >conftest.$ac_ext <<CF_EOF
3579 $1
3580 int main()
3581 {
3582 $2
3583         ${cf_cv_main_return:-return}(0);
3584 }
3585 CF_EOF
3586 cf_save_LIBS="$LIBS"
3587         CF_ADD_LIB($3)
3588         if AC_TRY_EVAL(ac_compile) ; then
3589                 if AC_TRY_EVAL(ac_link) ; then
3590                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3591                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3592                 fi
3593         fi
3594 rm -rf conftest*
3595 LIBS="$cf_save_LIBS"
3596 fi
3597 ])
3598 ])
3599 dnl ---------------------------------------------------------------------------
3600 dnl CF_LIB_SUFFIX version: 18 updated: 2012/02/25 15:20:07
3601 dnl -------------
3602 dnl Compute the library file-suffix from the given model name
3603 dnl $1 = model name
3604 dnl $2 = variable to set (the nominal library suffix)
3605 dnl $3 = dependency variable to set (actual filename)
3606 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3607 AC_DEFUN([CF_LIB_SUFFIX],
3608 [
3609         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3610         case $1 in #(vi
3611         libtool) #(vi
3612                 $2='.la'
3613                 $3=[$]$2
3614                 ;;
3615         normal) #(vi
3616                 $2='.a'
3617                 $3=[$]$2
3618                 ;;
3619         debug) #(vi
3620                 $2='_g.a'
3621                 $3=[$]$2
3622                 ;;
3623         profile) #(vi
3624                 $2='_p.a'
3625                 $3=[$]$2
3626                 ;;
3627         shared) #(vi
3628                 case $cf_cv_system_name in
3629                 aix[[5-7]]*) #(vi
3630                         $2='.a'
3631                         $3=[$]$2
3632                         ;;
3633                 cygwin*|mingw*) #(vi
3634                         $2='.dll'
3635                         $3='.dll.a'
3636                         ;;
3637                 darwin*) #(vi
3638                         $2='.dylib'
3639                         $3=[$]$2
3640                         ;;
3641                 hpux*) #(vi
3642                         case $target in
3643                         ia64*) #(vi
3644                                 $2='.so'
3645                                 $3=[$]$2
3646                                 ;;
3647                         *) #(vi
3648                                 $2='.sl'
3649                                 $3=[$]$2
3650                                 ;;
3651                         esac
3652                         ;;
3653                 *)      $2='.so'
3654                         $3=[$]$2
3655                         ;;
3656                 esac
3657         esac
3658         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3659         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3660 ])dnl
3661 dnl ---------------------------------------------------------------------------
3662 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3663 dnl -----------
3664 dnl Compute the string to append to -library from the given model name
3665 dnl $1 = model name
3666 dnl $2 = variable to set
3667 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3668 AC_DEFUN([CF_LIB_TYPE],
3669 [
3670         case $1 in
3671         libtool) $2=''   ;;
3672         normal)  $2=''   ;;
3673         debug)   $2='_g' ;;
3674         profile) $2='_p' ;;
3675         shared)  $2=''   ;;
3676         esac
3677         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3678 ])dnl
3679 dnl ---------------------------------------------------------------------------
3680 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
3681 dnl ----------------
3682 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3683 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3684 dnl have to provide wrappers for global tables to ensure they're linked
3685 dnl properly.
3686 AC_DEFUN([CF_LINK_DATAONLY],
3687 [
3688 AC_MSG_CHECKING([if data-only library module links])
3689 AC_CACHE_VAL(cf_cv_link_dataonly,[
3690         rm -f conftest.a
3691         cat >conftest.$ac_ext <<EOF
3692 #line __oline__ "configure"
3693 int     testdata[[3]] = { 123, 456, 789 };
3694 EOF
3695         if AC_TRY_EVAL(ac_compile) ; then
3696                 mv conftest.o data.o && \
3697                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3698         fi
3699         rm -f conftest.$ac_ext data.o
3700         cat >conftest.$ac_ext <<EOF
3701 #line __oline__ "configure"
3702 int     testfunc()
3703 {
3704 #if defined(NeXT)
3705         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3706 #else
3707         extern int testdata[[3]];
3708         return testdata[[0]] == 123
3709            &&  testdata[[1]] == 456
3710            &&  testdata[[2]] == 789;
3711 #endif
3712 }
3713 EOF
3714         if AC_TRY_EVAL(ac_compile); then
3715                 mv conftest.o func.o && \
3716                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3717         fi
3718         rm -f conftest.$ac_ext func.o
3719         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3720         cf_saveLIBS="$LIBS"
3721         LIBS="conftest.a $LIBS"
3722         AC_TRY_RUN([
3723         int main()
3724         {
3725                 extern int testfunc();
3726                 ${cf_cv_main_return:-return} (!testfunc());
3727         }
3728         ],
3729         [cf_cv_link_dataonly=yes],
3730         [cf_cv_link_dataonly=no],
3731         [cf_cv_link_dataonly=unknown])
3732         LIBS="$cf_saveLIBS"
3733         ])
3734 AC_MSG_RESULT($cf_cv_link_dataonly)
3735
3736 if test "$cf_cv_link_dataonly" = n