aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2019,2020 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: aclocal.m4,v 1.941 2020/11/26 22:37:55 tom Exp $
  33 dnl Macros used in NCURSES auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See these pages for additional information:
  40 dnl             https://invisible-island.net/autoconf/
  41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  42 dnl
  43 dnl ---------------------------------------------------------------------------
  44 dnl ---------------------------------------------------------------------------
  45 dnl AM_LANGINFO_CODESET version: 5 updated: 2020/03/10 18:53:47
  46 dnl -------------------
  47 dnl Inserted as requested by gettext 0.10.40
  48 dnl File from /usr/share/aclocal
  49 dnl codeset.m4
  50 dnl ====================
  51 dnl serial AM1
  52 dnl
  53 dnl From Bruno Haible.
  54 AC_DEFUN([AM_LANGINFO_CODESET],
  55 [
  56 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  57         [AC_TRY_LINK([#include <langinfo.h>],
  58         [char* cs = nl_langinfo(CODESET); (void)cs],
  59         am_cv_langinfo_codeset=yes,
  60         am_cv_langinfo_codeset=no)
  61         ])
  62         if test $am_cv_langinfo_codeset = yes; then
  63                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  64                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  65         fi
  66 ])dnl
  67 dnl ---------------------------------------------------------------------------
  68 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  69 dnl ---------------
  70 dnl Provide configure-script defaults for different ncurses ABIs.
  71 AC_DEFUN([CF_ABI_DEFAULTS],[
  72 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  73 case x$cf_cv_abi_version in
  74 (x[[6789]])
  75         cf_dft_ext_colors=yes
  76         cf_dft_ext_const=yes
  77         cf_dft_ext_mouse=yes
  78         cf_dft_ext_putwin=yes
  79         cf_dft_ext_spfuncs=yes
  80         cf_dft_filter_syms=yes
  81         cf_dft_chtype=uint32_t
  82         cf_dft_mmask_t=uint32_t
  83         cf_dft_interop=yes
  84         cf_dft_tparm_arg=intptr_t
  85         cf_dft_with_lp64=yes
  86         ;;
  87 (*)
  88         cf_dft_ext_colors=no
  89         cf_dft_ext_const=no
  90         cf_dft_ext_mouse=no
  91         cf_dft_ext_putwin=no
  92         cf_dft_ext_spfuncs=no
  93         cf_dft_filter_syms=no
  94         cf_dft_chtype=auto
  95         cf_dft_mmask_t=auto
  96         cf_dft_interop=no
  97         cf_dft_tparm_arg=long
  98         cf_dft_with_lp64=no
  99         ;;
 100 esac
 101 ])dnl
 102 dnl ---------------------------------------------------------------------------
 103 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 104 dnl ------------------
 105 dnl Conditionally generate script according to whether we're using a given autoconf.
 106 dnl
 107 dnl $1 = version to compare against
 108 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 109 dnl $3 = code to use if AC_ACVERSION is older than $1.
 110 define([CF_ACVERSION_CHECK],
 111 [
 112 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 113 ifdef([m4_version_compare],
 114 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 115 [CF_ACVERSION_COMPARE(
 116 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 117 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 118 dnl ---------------------------------------------------------------------------
 119 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 120 dnl --------------------
 121 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 122 dnl                      MAJOR2, MINOR2, TERNARY2,
 123 dnl                      PRINTABLE2, not FOUND, FOUND)
 124 define([CF_ACVERSION_COMPARE],
 125 [ifelse(builtin([eval], [$2 < $5]), 1,
 126 [ifelse([$8], , ,[$8])],
 127 [ifelse([$9], , ,[$9])])])dnl
 128 dnl ---------------------------------------------------------------------------
 129 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 130 dnl -------------------
 131 dnl Construct the list of include-options for the C programs in the Ada95
 132 dnl binding.
 133 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 134 [
 135 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 136 if test "$srcdir" != "."; then
 137         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 138 fi
 139 if test "$GCC" != yes; then
 140         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 141 elif test "$includedir" != "/usr/include"; then
 142         if test "$includedir" = '${prefix}/include' ; then
 143                 if test x$prefix != x/usr ; then
 144                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145                 fi
 146         else
 147                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 148         fi
 149 fi
 150 AC_SUBST(ACPPFLAGS)
 151 ])dnl
 152 dnl ---------------------------------------------------------------------------
 153 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 154 dnl ---------------
 155 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 156 AC_DEFUN([CF_ADD_ADAFLAGS],[
 157         ADAFLAGS="$ADAFLAGS $1"
 158         AC_SUBST(ADAFLAGS)
 159 ])dnl
 160 dnl ---------------------------------------------------------------------------
 161 dnl CF_ADD_CFLAGS version: 14 updated: 2020/04/04 16:16:13
 162 dnl -------------
 163 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 164 dnl $1 = flags to add
 165 dnl $2 = if given makes this macro verbose.
 166 dnl
 167 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 168 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 169 dnl confused by the quotes (which require backslashes to keep them usable).
 170 AC_DEFUN([CF_ADD_CFLAGS],
 171 [
 172 cf_fix_cppflags=no
 173 cf_new_cflags=
 174 cf_new_cppflags=
 175 cf_new_extra_cppflags=
 176
 177 for cf_add_cflags in $1
 178 do
 179 case $cf_fix_cppflags in
 180 (no)
 181         case $cf_add_cflags in
 182         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 183                 case $cf_add_cflags in
 184                 (-D*)
 185                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 186
 187                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 188                                 && test -z "${cf_tst_cflags}" \
 189                                 && cf_fix_cppflags=yes
 190
 191                         if test $cf_fix_cppflags = yes ; then
 192                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 193                                 continue
 194                         elif test "${cf_tst_cflags}" = "\"'" ; then
 195                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 196                                 continue
 197                         fi
 198                         ;;
 199                 esac
 200                 case "$CPPFLAGS" in
 201                 (*$cf_add_cflags)
 202                         ;;
 203                 (*)
 204                         case $cf_add_cflags in
 205                         (-D*)
 206                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 207                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 208                                 ;;
 209                         esac
 210                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 211                         ;;
 212                 esac
 213                 ;;
 214         (*)
 215                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 216                 ;;
 217         esac
 218         ;;
 219 (yes)
 220         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 221
 222         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 223
 224         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 225                 && test -z "${cf_tst_cflags}" \
 226                 && cf_fix_cppflags=no
 227         ;;
 228 esac
 229 done
 230
 231 if test -n "$cf_new_cflags" ; then
 232         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 233         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 234 fi
 235
 236 if test -n "$cf_new_cppflags" ; then
 237         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 238         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 239 fi
 240
 241 if test -n "$cf_new_extra_cppflags" ; then
 242         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 243         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 244 fi
 245
 246 AC_SUBST(EXTRA_CPPFLAGS)
 247
 248 ])dnl
 249 dnl ---------------------------------------------------------------------------
 250 dnl CF_ADD_CXXFLAGS version: 1 updated: 2020/04/04 16:16:13
 251 dnl ---------------
 252 dnl Copy non-preprocessor flags to $CXXFLAGS, preprocessor flags to $CPPFLAGS
 253 dnl The second parameter if given makes this macro verbose.
 254 dnl
 255 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 256 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 257 dnl confused by the quotes (which require backslashes to keep them usable).
 258 AC_DEFUN([CF_ADD_CXXFLAGS],
 259 [
 260 cf_save_CXXFLAGS="$CFLAGS"
 261 CFLAGS="$CXXFLAGS"
 262 CF_ADD_CFLAGS($1 ifelse($2,,,[,$2]))
 263 CXXFLAGS="$CFLAGS"
 264 CFLAGS="$cf_save_CXXFLAGS"
 265 ])dnl
 266 dnl ---------------------------------------------------------------------------
 267 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
 268 dnl -------------
 269 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 270 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 271 dnl but old versions (and some misinstalled ones) need that.  To make things
 272 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 273 dnl the include-path).
 274 AC_DEFUN([CF_ADD_INCDIR],
 275 [
 276 if test -n "$1" ; then
 277   for cf_add_incdir in $1
 278   do
 279         while test $cf_add_incdir != /usr/include
 280         do
 281           if test -d $cf_add_incdir
 282           then
 283                 cf_have_incdir=no
 284                 if test -n "$CFLAGS$CPPFLAGS" ; then
 285                   # a loop is needed to ensure we can add subdirs of existing dirs
 286                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 287                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 288                           cf_have_incdir=yes; break
 289                         fi
 290                   done
 291                 fi
 292
 293                 if test "$cf_have_incdir" = no ; then
 294                   if test "$cf_add_incdir" = /usr/local/include ; then
 295                         if test "$GCC" = yes
 296                         then
 297                           cf_save_CPPFLAGS=$CPPFLAGS
 298                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 299                           AC_TRY_COMPILE([#include <stdio.h>],
 300                                   [printf("Hello")],
 301                                   [],
 302                                   [cf_have_incdir=yes])
 303                           CPPFLAGS=$cf_save_CPPFLAGS
 304                         fi
 305                   fi
 306                 fi
 307
 308                 if test "$cf_have_incdir" = no ; then
 309                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 310                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 311
 312                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 313                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 314                   cf_add_incdir="$cf_top_incdir"
 315                 else
 316                   break
 317                 fi
 318           else
 319                 break
 320           fi
 321         done
 322   done
 323 fi
 324 ])dnl
 325 dnl ---------------------------------------------------------------------------
 326 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 327 dnl ----------
 328 dnl Add a library, used to enforce consistency.
 329 dnl
 330 dnl $1 = library to add, without the "-l"
 331 dnl $2 = variable to update (default $LIBS)
 332 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 333 dnl ---------------------------------------------------------------------------
 334 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 335 dnl -------------
 336 dnl     Adds to the library-path
 337 dnl
 338 dnl     Some machines have trouble with multiple -L options.
 339 dnl
 340 dnl $1 is the (list of) directory(s) to add
 341 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 342 dnl
 343 AC_DEFUN([CF_ADD_LIBDIR],
 344 [
 345 if test -n "$1" ; then
 346         for cf_add_libdir in $1
 347         do
 348                 if test $cf_add_libdir = /usr/lib ; then
 349                         :
 350                 elif test -d $cf_add_libdir
 351                 then
 352                         cf_have_libdir=no
 353                         if test -n "$LDFLAGS$LIBS" ; then
 354                                 # a loop is needed to ensure we can add subdirs of existing dirs
 355                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 356                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 357                                                 cf_have_libdir=yes; break
 358                                         fi
 359                                 done
 360                         fi
 361                         if test "$cf_have_libdir" = no ; then
 362                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 363                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 364                         fi
 365                 fi
 366         done
 367 fi
 368 ])dnl
 369 dnl ---------------------------------------------------------------------------
 370 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 371 dnl -----------
 372 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 373 dnl prepended to an existing list, since their dependencies are assumed to
 374 dnl already exist in the list.
 375 dnl
 376 dnl $1 = libraries to add, with the "-l", etc.
 377 dnl $2 = variable to update (default $LIBS)
 378 AC_DEFUN([CF_ADD_LIBS],[
 379 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 380 # reverse order
 381 cf_add_0lib=
 382 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 383 # filter duplicates
 384 for cf_add_1lib in $cf_add_0lib; do
 385         for cf_add_2lib in $cf_add_libs; do
 386                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 387                         cf_add_1lib=
 388                         break
 389                 fi
 390         done
 391         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 392 done
 393 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 394 ])dnl
 395 dnl ---------------------------------------------------------------------------
 396 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 397 dnl ------------------
 398 dnl Append to a search-list for a nonstandard header/lib-file
 399 dnl     $1 = the variable to return as result
 400 dnl     $2 = the package name
 401 dnl     $3 = the subdirectory, e.g., bin, include or lib
 402 dnl $4 = the directory under which we will test for subdirectories
 403 dnl $5 = a directory that we do not want $4 to match
 404 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 405 [
 406 test "x$4" != "x$5" && \
 407 test -d "$4" && \
 408 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 409         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 410         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 411         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 412         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 413         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 414         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 415 }
 416 ])dnl
 417 dnl ---------------------------------------------------------------------------
 418 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 419 dnl --------------
 420 dnl use this macro for appending text without introducing an extra blank at
 421 dnl the beginning
 422 define([CF_APPEND_TEXT],
 423 [
 424         test -n "[$]$1" && $1="[$]$1 "
 425         $1="[$]{$1}$2"
 426 ])dnl
 427 dnl ---------------------------------------------------------------------------
 428 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 429 dnl --------------
 430 dnl Allow user to disable a normally-on option.
 431 AC_DEFUN([CF_ARG_DISABLE],
 432 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 433 dnl ---------------------------------------------------------------------------
 434 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 435 dnl -------------
 436 dnl Allow user to enable a normally-off option.
 437 AC_DEFUN([CF_ARG_ENABLE],
 438 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 439 dnl ---------------------------------------------------------------------------
 440 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 441 dnl -------------
 442 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 443 dnl values.
 444 dnl
 445 dnl Parameters:
 446 dnl $1 = option name
 447 dnl $2 = help-string
 448 dnl $3 = action to perform if option is not default
 449 dnl $4 = action if perform if option is default
 450 dnl $5 = default option value (either 'yes' or 'no')
 451 AC_DEFUN([CF_ARG_OPTION],
 452 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 453         if test "$enableval" != "$5" ; then
 454 ifelse([$3],,[    :]dnl
 455 ,[    $3]) ifelse([$4],,,[
 456         else
 457                 $4])
 458         fi],[enableval=$5 ifelse([$4],,,[
 459         $4
 460 ])dnl
 461 ])])dnl
 462 dnl ---------------------------------------------------------------------------
 463 dnl CF_AR_FLAGS version: 7 updated: 2020/04/04 11:37:29
 464 dnl -----------
 465 dnl Check for suitable "ar" (archiver) options for updating an archive.
 466 dnl
 467 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 468 dnl as well as a workaround for breakage of make's archive rules by the GNU
 469 dnl binutils "ar" program.
 470 AC_DEFUN([CF_AR_FLAGS],[
 471 AC_REQUIRE([CF_PROG_AR])
 472
 473 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 474         case $cf_cv_system_name in
 475         (*-msvc*)
 476                 cf_cv_ar_flags=''
 477                 cat >mk_static_lib.sh <<-EOF
 478                 #!$SHELL
 479                 MSVC_BIN="[$]AR"
 480                 out="\[$]1"
 481                 shift
 482                 exec \[$]MSVC_BIN -out:"\[$]out" \[$]@
 483                 EOF
 484                 chmod +x mk_static_lib.sh
 485                 AR=`pwd`/mk_static_lib.sh
 486                 ;;
 487         (*)
 488                 cf_cv_ar_flags=unknown
 489                 for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 490                 do
 491
 492                         # check if $ARFLAGS already contains this choice
 493                         if test "x$ARFLAGS" != "x" ; then
 494                                 cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 495                                 if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 496                                         cf_cv_ar_flags=
 497                                         break
 498                                 fi
 499                         fi
 500
 501                         rm -f conftest.$ac_cv_objext
 502                         rm -f conftest.a
 503
 504                         cat >conftest.$ac_ext <<EOF
 505 #line __oline__ "configure"
 506 int     testdata[[3]] = { 123, 456, 789 };
 507 EOF
 508                         if AC_TRY_EVAL(ac_compile) ; then
 509                                 echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 510                                 $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 511                                 if test -f conftest.a ; then
 512                                         cf_cv_ar_flags=$cf_ar_flags
 513                                         break
 514                                 fi
 515                         else
 516                                 CF_VERBOSE(cannot compile test-program)
 517                                 break
 518                         fi
 519                 done
 520                 rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 521                 ;;
 522         esac
 523 ])
 524
 525 if test -n "$ARFLAGS" ; then
 526         if test -n "$cf_cv_ar_flags" ; then
 527                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 528         fi
 529 else
 530         ARFLAGS=$cf_cv_ar_flags
 531 fi
 532
 533 AC_SUBST(ARFLAGS)
 534 ])
 535 dnl ---------------------------------------------------------------------------
 536 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 537 dnl -----------------
 538 dnl Check if awk can handle big strings using printf.  Some older versions of
 539 dnl awk choke on large strings passed via "%s".
 540 dnl
 541 dnl $1 = desired string size
 542 dnl $2 = variable to set with result
 543 AC_DEFUN([CF_AWK_BIG_PRINTF],
 544 [
 545         case x$AWK in
 546         (x)
 547                 eval $2=no
 548                 ;;
 549         (*)
 550                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 551                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 552                         eval $2=yes
 553                 else
 554                         eval $2=no
 555                 fi
 556                 ;;
 557         esac
 558 ])dnl
 559 dnl ---------------------------------------------------------------------------
 560 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 561 dnl ------------
 562 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 563 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 564 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 565 dnl
 566 dnl Treat the configuration-variable specially here, since we're directly
 567 dnl substituting its value (i.e., 1/0).
 568 dnl
 569 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 570 AC_DEFUN([CF_BOOL_DECL],
 571 [
 572 AC_MSG_CHECKING(if we should include stdbool.h)
 573
 574 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 575         AC_TRY_COMPILE([],[bool foo = false],
 576                 [cf_cv_header_stdbool_h=0],
 577                 [AC_TRY_COMPILE([
 578 #ifndef __BEOS__
 579 #include <stdbool.h>
 580 #endif
 581 ],[bool foo = false],
 582                         [cf_cv_header_stdbool_h=1],
 583                         [cf_cv_header_stdbool_h=0])])])
 584
 585 if test "$cf_cv_header_stdbool_h" = 1
 586 then    AC_MSG_RESULT(yes)
 587 else    AC_MSG_RESULT(no)
 588 fi
 589
 590 AC_MSG_CHECKING([for builtin bool type])
 591
 592 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 593         AC_TRY_COMPILE([
 594 #include <stdio.h>
 595 #include <sys/types.h>
 596 ],[bool x = false],
 597                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 598                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 599         ])
 600
 601 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 602 then    AC_MSG_RESULT(yes)
 603 else    AC_MSG_RESULT(no)
 604 fi
 605 ])dnl
 606 dnl ---------------------------------------------------------------------------
 607 dnl CF_BOOL_SIZE version: 17 updated: 2020/10/24 19:48:55
 608 dnl ------------
 609 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 610 dnl Don't bother looking for bool.h, since it's been deprecated.
 611 dnl
 612 dnl If the current compiler is C rather than C++, we get the bool definition
 613 dnl from <stdbool.h>.
 614 AC_DEFUN([CF_BOOL_SIZE],
 615 [
 616 AC_CHECK_SIZEOF(bool,,[
 617 #include <stdlib.h>
 618 #include <stdio.h>
 619
 620 #if defined(__cplusplus)
 621
 622 #ifdef HAVE_GXX_BUILTIN_H
 623 #include <g++/builtin.h>
 624 #elif HAVE_GPP_BUILTIN_H
 625 #include <gpp/builtin.h>
 626 #elif HAVE_BUILTIN_H
 627 #include <builtin.h>
 628 #endif
 629
 630 #else
 631
 632 #if $cf_cv_header_stdbool_h
 633 #include <stdbool.h>
 634 #endif
 635
 636 #endif
 637 ])
 638
 639 AC_CACHE_CHECK(for type of bool, cf_cv_type_of_bool,[
 640         rm -f cf_test.out
 641         AC_TRY_RUN([
 642 #include <stdlib.h>
 643 #include <stdio.h>
 644
 645 #if defined(__cplusplus)
 646
 647 #ifdef HAVE_GXX_BUILTIN_H
 648 #include <g++/builtin.h>
 649 #elif HAVE_GPP_BUILTIN_H
 650 #include <gpp/builtin.h>
 651 #elif HAVE_BUILTIN_H
 652 #include <builtin.h>
 653 #endif
 654
 655 #else
 656
 657 #if $cf_cv_header_stdbool_h
 658 #include <stdbool.h>
 659 #endif
 660
 661 #endif
 662
 663 int main(void)
 664 {
 665         FILE *fp = fopen("cf_test.out", "w");
 666         if (fp != 0) {
 667                 bool x = true;
 668                 if ((bool)(-x) >= 0)
 669                         fputs("unsigned ", fp);
 670                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 671                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 672                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 673                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 674                 fclose(fp);
 675         }
 676         ${cf_cv_main_return:-return}(0);
 677 }
 678                 ],
 679                 [cf_cv_type_of_bool=`cat cf_test.out`
 680                  if test -z "$cf_cv_type_of_bool"; then
 681                    cf_cv_type_of_bool=unknown
 682                  fi],
 683                 [cf_cv_type_of_bool=unknown],
 684                 [
 685                 case x$ac_cv_sizeof_bool in
 686                 (x1) cf_cv_type_of_bool="unsigned char";;
 687                 (x2) cf_cv_type_of_bool="unsigned short";;
 688                 (x4) cf_cv_type_of_bool="unsigned int";;
 689                 (x8) cf_cv_type_of_bool="unsigned long";;
 690                 (*)  cf_cv_type_of_bool=unknown;;
 691                 esac
 692                 ])
 693         rm -f cf_test.out
 694 ])
 695
 696 if test "$cf_cv_type_of_bool" = unknown ; then
 697         case .$NCURSES_BOOL in
 698         (.auto|.) NCURSES_BOOL=unsigned;;
 699         esac
 700         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 701         cf_cv_type_of_bool=$NCURSES_BOOL
 702 fi
 703 ])dnl
 704 dnl ---------------------------------------------------------------------------
 705 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
 706 dnl -----------
 707 dnl If we're cross-compiling, allow the user to override the tools and their
 708 dnl options.  The configure script is oriented toward identifying the host
 709 dnl compiler, etc., but we need a build compiler to generate parts of the
 710 dnl source.
 711 dnl
 712 dnl $1 = default for $CPPFLAGS
 713 dnl $2 = default for $LIBS
 714 AC_DEFUN([CF_BUILD_CC],[
 715 CF_ACVERSION_CHECK(2.52,,
 716         [AC_REQUIRE([CF_PROG_EXT])])
 717 if test "$cross_compiling" = yes ; then
 718
 719         # defaults that we might want to override
 720         : ${BUILD_CFLAGS:=''}
 721         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 722         : ${BUILD_LDFLAGS:=''}
 723         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 724         : ${BUILD_EXEEXT:='$x'}
 725         : ${BUILD_OBJEXT:='o'}
 726
 727         AC_ARG_WITH(build-cc,
 728                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 729                 [BUILD_CC="$withval"],
 730                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 731         AC_MSG_CHECKING(for native build C compiler)
 732         AC_MSG_RESULT($BUILD_CC)
 733
 734         AC_MSG_CHECKING(for native build C preprocessor)
 735         AC_ARG_WITH(build-cpp,
 736                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 737                 [BUILD_CPP="$withval"],
 738                 [BUILD_CPP='${BUILD_CC} -E'])
 739         AC_MSG_RESULT($BUILD_CPP)
 740
 741         AC_MSG_CHECKING(for native build C flags)
 742         AC_ARG_WITH(build-cflags,
 743                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 744                 [BUILD_CFLAGS="$withval"])
 745         AC_MSG_RESULT($BUILD_CFLAGS)
 746
 747         AC_MSG_CHECKING(for native build C preprocessor-flags)
 748         AC_ARG_WITH(build-cppflags,
 749                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 750                 [BUILD_CPPFLAGS="$withval"])
 751         AC_MSG_RESULT($BUILD_CPPFLAGS)
 752
 753         AC_MSG_CHECKING(for native build linker-flags)
 754         AC_ARG_WITH(build-ldflags,
 755                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 756                 [BUILD_LDFLAGS="$withval"])
 757         AC_MSG_RESULT($BUILD_LDFLAGS)
 758
 759         AC_MSG_CHECKING(for native build linker-libraries)
 760         AC_ARG_WITH(build-libs,
 761                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 762                 [BUILD_LIBS="$withval"])
 763         AC_MSG_RESULT($BUILD_LIBS)
 764
 765         # this assumes we're on Unix.
 766         BUILD_EXEEXT=
 767         BUILD_OBJEXT=o
 768
 769         : ${BUILD_CC:='${CC}'}
 770
 771         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 772                 AC_MSG_ERROR([Cross-build requires two compilers.
 773 Use --with-build-cc to specify the native compiler.])
 774         fi
 775
 776 else
 777         : ${BUILD_CC:='${CC}'}
 778         : ${BUILD_CPP:='${CPP}'}
 779         : ${BUILD_CFLAGS:='${CFLAGS}'}
 780         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 781         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 782         : ${BUILD_LIBS:='${LIBS}'}
 783         : ${BUILD_EXEEXT:='$x'}
 784         : ${BUILD_OBJEXT:='o'}
 785 fi
 786
 787 AC_SUBST(BUILD_CC)
 788 AC_SUBST(BUILD_CPP)
 789 AC_SUBST(BUILD_CFLAGS)
 790 AC_SUBST(BUILD_CPPFLAGS)
 791 AC_SUBST(BUILD_LDFLAGS)
 792 AC_SUBST(BUILD_LIBS)
 793 AC_SUBST(BUILD_EXEEXT)
 794 AC_SUBST(BUILD_OBJEXT)
 795 ])dnl
 796 dnl ---------------------------------------------------------------------------
 797 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
 798 dnl ---------------
 799 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 800 dnl into CC.  This will not help with broken scripts that wrap the compiler
 801 dnl with options, but eliminates a more common category of user confusion.
 802 dnl
 803 dnl In particular, it addresses the problem of being able to run the C
 804 dnl preprocessor in a consistent manner.
 805 dnl
 806 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 807 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 808 dnl outweighs that limitation.
 809 AC_DEFUN([CF_CC_ENV_FLAGS],
 810 [
 811 # This should have been defined by AC_PROG_CC
 812 : ${CC:=cc}
 813
 814 AC_MSG_CHECKING(\$CFLAGS variable)
 815 case "x$CFLAGS" in
 816 (*-[[IUD]]*)
 817         AC_MSG_RESULT(broken)
 818         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 819         cf_flags="$CFLAGS"
 820         CFLAGS=
 821         for cf_arg in $cf_flags
 822         do
 823                 CF_ADD_CFLAGS($cf_arg)
 824         done
 825         ;;
 826 (*)
 827         AC_MSG_RESULT(ok)
 828         ;;
 829 esac
 830
 831 AC_MSG_CHECKING(\$CC variable)
 832 case "$CC" in
 833 (*[[\ \ ]]-*)
 834         AC_MSG_RESULT(broken)
 835         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 836         # humor him...
 837         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 838         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 839         CC="$cf_prog"
 840         for cf_arg in $cf_flags
 841         do
 842                 case "x$cf_arg" in
 843                 (x-[[IUDfgOW]]*)
 844                         CF_ADD_CFLAGS($cf_arg)
 845                         ;;
 846                 (*)
 847                         CC="$CC $cf_arg"
 848                         ;;
 849                 esac
 850         done
 851         CF_VERBOSE(resulting CC: '$CC')
 852         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 853         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 854         ;;
 855 (*)
 856         AC_MSG_RESULT(ok)
 857         ;;
 858 esac
 859 ])dnl
 860 dnl ---------------------------------------------------------------------------
 861 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 862 dnl ---------------
 863 dnl Determine the default configuration into which we'll install ncurses.  This
 864 dnl can be overridden by the user's command-line options.  There's two items to
 865 dnl look for:
 866 dnl     1. the prefix (e.g., /usr)
 867 dnl     2. the header files (e.g., /usr/include/ncurses)
 868 dnl We'll look for a previous installation of ncurses and use the same defaults.
 869 dnl
 870 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 871 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 872 dnl programs from a vendor's.
 873 AC_DEFUN([CF_CFG_DEFAULTS],
 874 [
 875 AC_MSG_CHECKING(for prefix)
 876 if test "x$prefix" = "xNONE" ; then
 877         case "$cf_cv_system_name" in
 878                 # non-vendor systems don't have a conflict
 879         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 880                 prefix=/usr
 881                 ;;
 882         (*)     prefix=$ac_default_prefix
 883                 ;;
 884         esac
 885 fi
 886 AC_MSG_RESULT($prefix)
 887
 888 if test "x$prefix" = "xNONE" ; then
 889 AC_MSG_CHECKING(for default include-directory)
 890 test -n "$verbose" && echo 1>&AC_FD_MSG
 891 for cf_symbol in \
 892         $includedir \
 893         $includedir/ncurses \
 894         $prefix/include \
 895         $prefix/include/ncurses \
 896         /usr/local/include \
 897         /usr/local/include/ncurses \
 898         /usr/include \
 899         /usr/include/ncurses
 900 do
 901         cf_dir=`eval echo $cf_symbol`
 902         if test -f $cf_dir/curses.h ; then
 903         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 904                 includedir="$cf_symbol"
 905                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 906                 break
 907         fi
 908         fi
 909         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 910 done
 911 AC_MSG_RESULT($includedir)
 912 fi
 913 ])dnl
 914 dnl ---------------------------------------------------------------------------
 915 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
 916 dnl ----------
 917 dnl Check if the terminal-capability database functions are available.  If not,
 918 dnl ncurses has a much-reduced version.
 919 AC_DEFUN([CF_CGETENT],[
 920 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 921 AC_TRY_LINK([
 922 #include <stdlib.h>],[
 923         char temp[128];
 924         char *buf = temp;
 925         char *db_array = temp;
 926         cgetent(&buf, &db_array, "vt100");
 927         cgetcap(buf, "tc", '=');
 928         cgetmatch(buf, "tc");
 929         ],
 930         [cf_cv_cgetent=yes],
 931         [cf_cv_cgetent=no])
 932 ])
 933
 934 if test "$cf_cv_cgetent" = yes
 935 then
 936         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 937 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 938 AC_TRY_LINK([
 939 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
 940 #include <stdlib.h>],[
 941         char temp[128];
 942         char *buf = temp;
 943 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 944         const char *db_array = temp;
 945         cgetent(&buf, &db_array, "vt100");
 946 #endif
 947         cgetcap(buf, "tc", '=');
 948         cgetmatch(buf, "tc");
 949         ],
 950         [cf_cv_cgetent_const=yes],
 951         [cf_cv_cgetent_const=no])
 952 ])
 953         if test "$cf_cv_cgetent_const" = yes
 954         then
 955                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 956         fi
 957 fi
 958 ])dnl
 959 dnl ---------------------------------------------------------------------------
 960 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 961 dnl --------------
 962 dnl Check if we're accidentally using a cache from a different machine.
 963 dnl Derive the system name, as a check for reusing the autoconf cache.
 964 dnl
 965 dnl If we've packaged config.guess and config.sub, run that (since it does a
 966 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 967 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 968 dnl which is useful in cross-compiles.
 969 dnl
 970 dnl Note: we would use $ac_config_sub, but that is one of the places where
 971 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 972 AC_DEFUN([CF_CHECK_CACHE],
 973 [
 974 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 975         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 976         system_name="$host_os"
 977 else
 978         system_name="`(uname -s -r) 2>/dev/null`"
 979         if test -z "$system_name" ; then
 980                 system_name="`(hostname) 2>/dev/null`"
 981         fi
 982 fi
 983 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 984 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 985
 986 test -z "$system_name" && system_name="$cf_cv_system_name"
 987 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 988
 989 if test ".$system_name" != ".$cf_cv_system_name" ; then
 990         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 991         AC_MSG_ERROR("Please remove config.cache and try again.")
 992 fi
 993 ])dnl
 994 dnl ---------------------------------------------------------------------------
 995 dnl CF_CHECK_ENVIRON version: 3 updated: 2010/05/26 16:44:57
 996 dnl ----------------
 997 dnl Check for data that is usually declared in <unistd.h>, e.g., the 'environ'
 998 dnl variable.  Define a DECL_xxx symbol if we must declare it ourselves.
 999 dnl
1000 dnl $1 = the name to check
1001 dnl $2 = the assumed type
1002 AC_DEFUN([CF_CHECK_ENVIRON],
1003 [
1004 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1005     AC_TRY_COMPILE([
1006 #ifdef HAVE_STDLIB_H
1007 #include <stdlib.h>
1008 #endif
1009 #include <unistd.h> ],
1010     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
1011     [cf_cv_dcl_$1=yes],
1012     [cf_cv_dcl_$1=no])
1013 ])
1014
1015 if test "$cf_cv_dcl_$1" = no ; then
1016     CF_UPPER(cf_result,decl_$1)
1017     AC_DEFINE_UNQUOTED($cf_result)
1018 fi
1019
1020 # It's possible (for near-UNIX clones) that the data doesn't exist
1021 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1022 ])dnl
1023 dnl ---------------------------------------------------------------------------
1024 dnl CF_CHECK_ERRNO version: 13 updated: 2020/03/10 18:53:47
1025 dnl --------------
1026 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
1027 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
1028 dnl ourselves.
1029 dnl
1030 dnl $1 = the name to check
1031 dnl $2 = the assumed type
1032 AC_DEFUN([CF_CHECK_ERRNO],
1033 [
1034 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1035         AC_TRY_COMPILE([
1036 #ifdef HAVE_STDLIB_H
1037 #include <stdlib.h>
1038 #endif
1039 #include <stdio.h>
1040 #include <sys/types.h>
1041 #include <errno.h> ],
1042         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1; (void)x,
1043         [cf_cv_dcl_$1=yes],
1044         [cf_cv_dcl_$1=no])
1045 ])
1046
1047 if test "$cf_cv_dcl_$1" = no ; then
1048         CF_UPPER(cf_result,decl_$1)
1049         AC_DEFINE_UNQUOTED($cf_result)
1050 fi
1051
1052 # It's possible (for near-UNIX clones) that the data doesn't exist
1053 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1054 ])dnl
1055 dnl ---------------------------------------------------------------------------
1056 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
1057 dnl --------------------
1058 dnl Check for existence of external data in the current set of libraries.  If
1059 dnl we can modify it, it's real enough.
1060 dnl $1 = the name to check
1061 dnl $2 = its type
1062 AC_DEFUN([CF_CHECK_EXTERN_DATA],
1063 [
1064 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
1065         AC_TRY_LINK([
1066 #undef $1
1067 extern $2 $1;
1068 ],
1069         [$1 = 2],
1070         [cf_cv_have_$1=yes],
1071         [cf_cv_have_$1=no])
1072 ])
1073
1074 if test "$cf_cv_have_$1" = yes ; then
1075         CF_UPPER(cf_result,have_$1)
1076         AC_DEFINE_UNQUOTED($cf_result)
1077 fi
1078
1079 ])dnl
1080 dnl ---------------------------------------------------------------------------
1081 dnl CF_CHECK_FVISIBILITY version: 2 updated: 2020/04/04 16:16:13
1082 dnl --------------------
1083 dnl Check whether the compiler understands -fvisibility=hidden
1084 dnl
1085 dnl $1 = compiler
1086 dnl $2 = compiler-flags variable name
1087 dnl $3 = cache variable to set
1088 AC_DEFUN([CF_CHECK_FVISIBILITY],[
1089 AC_CACHE_CHECK(if $1 -fvisibility=hidden option works,$3,[
1090     cf_save_cflags="[$]$2"
1091     $2="[$]$2 -fvisibility=hidden"
1092     AC_TRY_LINK([
1093 __attribute__ ((visibility("default"))) int somefunc() {return 42;}
1094         ],[
1095         if (somefunc()) return 1;
1096 ],
1097     [$3=yes],
1098     [$3=no])
1099     $2=$cf_save_cflags
1100 ])
1101 ])dnl
1102 dnl ---------------------------------------------------------------------------
1103 dnl CF_CHECK_GETENV version: 1 updated: 2019/06/23 15:28:15
1104 dnl ---------------
1105 dnl Check if repeated getenv calls return the same pointer, e.g., it does not
1106 dnl discard the previous pointer when returning a new one.
1107 AC_DEFUN([CF_CHECK_GETENV],
1108 [
1109 AC_REQUIRE([CF_CHECK_ENVIRON])
1110 AC_CHECK_FUNC( getenv, ,, AC_MSG_ERROR(getenv not found) )
1111 AC_CHECK_FUNCS( putenv setenv strdup )
1112 AC_CACHE_CHECK(if getenv returns consistent values,cf_cv_consistent_getenv,[
1113 AC_TRY_RUN([
1114 #include <stdlib.h>
1115 #include <unistd.h>
1116 #include <stdio.h>
1117 #include <string.h>
1118 #include <sys/types.h>
1119
1120 #if defined(HAVE_ENVIRON) && defined(DECL_ENVIRON) && !defined(environ)
1121 extern char **environ;  /* POSIX, but some systems are not... */
1122 #endif
1123
1124 #if defined(HAVE_STRDUP)
1125 #define str_alloc(s) strdup(s)
1126 #else
1127 #define str_alloc(s) strcpy(malloc(strlen(s) + 1, s))
1128 #endif
1129
1130 static void set_value(const char *name, const char *value)
1131 {
1132 #if defined(HAVE_SETENV)
1133         setenv(name, value, 1);
1134 #elif defined(HAVE_PUTENV)
1135         char buffer[1024];
1136         sprintf(buffer, "%s=%s", name, value);
1137         putenv(str_alloc(buffer));
1138 #else
1139 #error neither putenv/setenv found
1140 #endif
1141 }
1142 int main(void)
1143 {
1144         int pass;
1145         size_t numenv, limit, j;
1146         char **mynames;
1147         char **myvalues;
1148         char **mypointer;
1149         char *equals;
1150         for (numenv = 0; environ[numenv]; ++numenv) ;
1151         limit = numenv + 10;
1152         mynames = (char **) calloc(limit + 1, sizeof(char *));
1153         myvalues = (char **) calloc(limit + 1, sizeof(char *));
1154         mypointer = (char **) calloc(limit + 1, sizeof(char *));
1155 #if defined(HAVE_ENVIRON)
1156         for (j = 0; environ[j]; ++j) {
1157                 mynames[j] = str_alloc(environ[j]);
1158                 equals = strchr(mynames[j], '=');
1159                 if (equals != 0) {
1160                         *equals++ = '\0';
1161                         myvalues[j] = str_alloc(equals);
1162                 } else {
1163                         myvalues[j] = str_alloc("");
1164                 }
1165         }
1166 #endif
1167         for (j = numenv; j < limit; ++j) {
1168                 char name[80];
1169                 char value[80];
1170                 size_t found;
1171                 size_t k = 0;
1172                 do {
1173                         size_t jk;
1174                         found = 0;
1175                         sprintf(name, "TERM%lu", (unsigned long) k);
1176                         for (jk = 0; jk < j; ++jk) {
1177                                 if (!strcmp(name, mynames[jk])) {
1178                                         found = 1;
1179                                         ++k;
1180                                         break;
1181                                 }
1182                         }
1183                 } while (found);
1184                 sprintf(value, "%lu:%p", (unsigned long) k, &mynames[j]);
1185                 set_value(name, value);
1186                 mynames[j] = str_alloc(name);
1187                 myvalues[j] = str_alloc(value);
1188         }
1189         for (pass = 0; pass < 3; ++pass) {
1190                 for (j = 0; j < limit; ++j) {
1191                         char *value = getenv(mynames[j]);
1192                         if (pass) {
1193                                 if (value == 0) {
1194                                         fprintf(stderr, "getenv returned null for %s\n", mynames[j]);
1195                                         ${cf_cv_main_return:-return}(1);
1196                                 } else if (value != mypointer[j]) {
1197                                         fprintf(stderr, "getenv returned different pointer for %s\n", mynames[j]);
1198                                         ${cf_cv_main_return:-return}(1);
1199                                 } else if (strcmp(value, myvalues[j])) {
1200                                         fprintf(stderr, "getenv returned different value for %s\n", mynames[j]);
1201                                         ${cf_cv_main_return:-return}(1);
1202                                 }
1203                         } else {
1204                                 size_t k;
1205                                 mypointer[j] = value;
1206                                 for (k = 0; k < j; ++k) {
1207                                         if (mypointer[j] == mypointer[k]) {
1208                                                 fprintf(stderr, "getenv returned same pointer for %s and %s\n", mynames[j], mynames[k]);
1209                                                 ${cf_cv_main_return:-return}(1);
1210                                         }
1211                                 }
1212                         }
1213                 }
1214         }
1215         ${cf_cv_main_return:-return}(0);
1216 }
1217 ],
1218 [cf_cv_consistent_getenv=yes],
1219 [cf_cv_consistent_getenv=no],
1220 [cf_cv_consistent_getenv=unknown])
1221 ])
1222
1223 if test "x$cf_cv_consistent_getenv" = xno
1224 then
1225         AC_DEFINE(HAVE_CONSISTENT_GETENV,1,[Define to 1 if getenv repeatably returns the same value for a given name])
1226 fi
1227 ])dnl
1228 dnl ---------------------------------------------------------------------------
1229 dnl CF_CHECK_GNAT_VERSION version: 3 updated: 2020/05/23 19:39:36
1230 dnl ---------------------
1231 AC_DEFUN([CF_CHECK_GNAT_VERSION],
1232 [
1233 AC_REQUIRE([CF_GNAT_VERSION])
1234 case $cf_cv_gnat_version in
1235 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
1236         cf_cv_prog_gnat_correct=yes
1237         ;;
1238 (*)
1239         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1240         cf_cv_prog_gnat_correct=no
1241         ;;
1242 esac
1243 ])
1244 dnl ---------------------------------------------------------------------------
1245 dnl CF_CHECK_GPM_WGETCH version: 3 updated: 2017/01/21 11:06:25
1246 dnl -------------------
1247 dnl Check if GPM is already linked with curses.  If so - and if the linkage
1248 dnl is not "weak" - warn about this because it can create problems linking
1249 dnl applications with ncurses.
1250 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
1251 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
1252
1253 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
1254 cf_cv_check_gpm_wgetch=unknown
1255 if test "$cross_compiling" != yes ; then
1256
1257 cat >conftest.$ac_ext <<CF_EOF
1258 #include <gpm.h>
1259 int main(void)
1260 {
1261         Gpm_Wgetch();
1262         ${cf_cv_main_return:-return}(0);
1263 }
1264 CF_EOF
1265
1266         cf_save_LIBS="$LIBS"
1267         # This only works if we can look at the symbol table.  If a shared
1268         # library is stripped for install, we cannot use that.  So we're forced
1269         # to rely on the static library, noting that some packagers may not
1270         # include it.
1271         LIBS="-static -lgpm -dynamic $LIBS"
1272         if AC_TRY_EVAL(ac_compile) ; then
1273                 if AC_TRY_EVAL(ac_link) ; then
1274                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
1275                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1276                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1277                 fi
1278         fi
1279         rm -rf conftest*
1280         LIBS="$cf_save_LIBS"
1281 fi
1282 ])
1283
1284 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1285         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1286 fi
1287 ])])dnl
1288 dnl ---------------------------------------------------------------------------
1289 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
1290 dnl ------------------------
1291 dnl Show the version of libtool
1292 dnl
1293 dnl Save the version in a cache variable - this is not entirely a good thing,
1294 dnl but the version string from libtool is very ugly, and for bug reports it
1295 dnl might be useful to have the original string.
1296 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1297 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1298 then
1299         AC_MSG_CHECKING(version of $LIBTOOL)
1300         CF_LIBTOOL_VERSION
1301         AC_MSG_RESULT($cf_cv_libtool_version)
1302         if test -z "$cf_cv_libtool_version" ; then
1303                 AC_MSG_ERROR(This is not GNU libtool)
1304         fi
1305 else
1306         AC_MSG_ERROR(GNU libtool has not been found)
1307 fi
1308 ])dnl
1309 dnl ---------------------------------------------------------------------------
1310 dnl CF_CHECK_WCHAR_H version: 2 updated: 2017/01/21 11:06:25
1311 dnl ----------------
1312 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1313 AC_DEFUN([CF_CHECK_WCHAR_H],[
1314 AC_CHECK_HEADERS( \
1315 wchar.h \
1316 wctype.h \
1317 )
1318 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1319 AC_TRY_COMPILE(
1320 [
1321 #include <stdlib.h>
1322 #ifdef HAVE_WCHAR_H
1323 #include <wchar.h>
1324 #endif
1325 #ifdef HAVE_WCTYPE_H
1326 #include <wctype.h>
1327 #endif
1328 ],[
1329         wint_t foo = 0;
1330         int bar = iswpunct(foo)],
1331         [cf_cv_wchar_h_okay=yes],
1332         [cf_cv_wchar_h_okay=no])])
1333
1334 if test $cf_cv_wchar_h_okay = no
1335 then
1336         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1337 fi
1338 ])dnl
1339 dnl ---------------------------------------------------------------------------
1340 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1341 dnl -------------------------
1342 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1343 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1344 dnl
1345 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1346 dnl all of those were combined into a page of useful graphics characters.
1347 dnl
1348 dnl So far, so good.
1349 dnl
1350 dnl However, while they are useful, there are other considerations.  CJK
1351 dnl is (because of poor device resolution) often rendered as double-width
1352 dnl characters.  So... for these generally-useful characters, what should
1353 dnl be the width (to make them consistent with adjacent characters)?
1354 dnl
1355 dnl The obvious choice would have been to make this locale-dependent, and use
1356 dnl wcwidth() to tell applications what the actual width is.  That was too
1357 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1358 dnl See for example
1359 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1360 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1361 dnl
1362 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1363 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1364 dnl instance, it lists half (44/96) of the Latin-1 characters as
1365 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1366 dnl
1367 dnl What this means for the implementor is that on some systems wcwidth() can
1368 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1369 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1370 dnl characters).  These do not necessarily match the behavior of the terminal
1371 dnl emulator.  xterm, for instance, does an optional startup check to find if
1372 dnl this problem (or similar) exists with the system's locale tables, rejecting
1373 dnl them if they are too unreliable.
1374 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1375 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1376 cat >conftest.in <<CF_EOF
1377 -       VT100 symbols
1378 0x250c  upper left corner
1379 0x2514  lower left corner
1380 0x2510  upper right corner
1381 0x2518  lower right corner
1382 0x251c  tee pointing left
1383 0x2524  tee pointing right
1384 0x2534  tee pointing up
1385 0x252c  tee pointing down
1386 0x2500  horizontal line
1387 0x2502  vertical line
1388 0x253c  large plus or crossover
1389 0x23ba  scan line 1
1390 0x23bd  scan line 9
1391 0x25c6  diamond
1392 0x2592  checker board (stipple)
1393 0x00b0  degree symbol
1394 0x00b1  plus/minus
1395 0x00b7  bullet
1396 -       Teletype 5410v1 symbols
1397 0x2190  arrow pointing left
1398 0x2192  arrow pointing right
1399 0x2193  arrow pointing down
1400 0x2191  arrow pointing up
1401 0x2592  board of squares
1402 0x2603  lantern symbol
1403 0x25ae  solid square block
1404 -       these defaults were invented for ncurses
1405 0x23bb  scan line 3
1406 0x23bc  scan line 7
1407 0x2264  less-than-or-equal-to
1408 0x2265  greater-than-or-equal-to
1409 0x03c0  greek pi
1410 0x2260  not-equal
1411 0x00a3  pound-sterling symbol
1412 -       thick-line-drawing
1413 0x250f  upper left corner
1414 0x2517  lower left corner
1415 0x2513  upper right corner
1416 0x251b  lower right corner
1417 0x2523  tee pointing left
1418 0x252b  tee pointing right
1419 0x253b  tee pointing up
1420 0x2533  tee pointing down
1421 0x2501  horizontal line
1422 0x2503  vertical line
1423 0x254b  large plus or crossover
1424 -       double-line-drawing
1425 0x2554  upper left corner
1426 0x255a  lower left corner
1427 0x2557  upper right corner
1428 0x255d  lower right corner
1429 0x2563  tee pointing left
1430 0x2560  tee pointing right
1431 0x2569  tee pointing up
1432 0x2566  tee pointing down
1433 0x2550  horizontal line
1434 0x2551  vertical line
1435 0x256c  large plus or crossover
1436 CF_EOF
1437 AC_TRY_RUN([
1438 #include <locale.h>
1439 #include <stdio.h>
1440 #include <wchar.h>
1441
1442 #define MY_LEN 80
1443
1444 int
1445 main(void)
1446 {
1447         FILE *fp;
1448         int value;
1449         char buffer[MY_LEN + 1];
1450         char notes[MY_LEN + 1];
1451         int totals = 0;
1452         int passed = 0;
1453
1454         if (setlocale(LC_ALL, "en_US.UTF8") ||
1455                 setlocale(LC_ALL, "en_US.UTF-8") ||
1456                 setlocale(LC_ALL, "en_US.utf8") ||
1457                 setlocale(LC_ALL, "en_US.utf-8")) {
1458                 if ((fp = fopen("conftest.in", "r")) != 0) {
1459                         while (fgets(buffer, MY_LEN, fp) != 0) {
1460                                 if (*buffer == '-') {
1461                                         fprintf(stderr, "\t%s", buffer);
1462                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1463                                         ++totals;
1464                                         if (wcwidth(value) == 1)
1465                                                 ++passed;
1466                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1467                                 } else {
1468                                         fprintf(stderr, "?\t%s", buffer);
1469                                 }
1470                         }
1471                 }
1472         }
1473         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1474         return (totals == passed) ? 0 : 1;
1475 }
1476 ],
1477 [cf_cv_wcwidth_graphics=yes],
1478 [cf_cv_wcwidth_graphics=no],
1479 [cf_cv_wcwidth_graphics=unknown])
1480 ])
1481 ])dnl
1482 dnl ---------------------------------------------------------------------------
1483 dnl CF_CLANG_COMPILER version: 6 updated: 2020/11/26 17:37:55
1484 dnl -----------------
1485 dnl Check if the given compiler is really clang.  clang's C driver defines
1486 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1487 dnl not ignore some gcc options.
1488 dnl
1489 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1490 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1491 dnl the wrappers for gcc and g++ warnings.
1492 dnl
1493 dnl $1 = GCC (default) or GXX
1494 dnl $2 = CLANG_COMPILER (default)
1495 dnl $3 = CFLAGS (default) or CXXFLAGS
1496 AC_DEFUN([CF_CLANG_COMPILER],[
1497 ifelse([$2],,CLANG_COMPILER,[$2])=no
1498
1499 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1500         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1501         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1502         AC_TRY_COMPILE([],[
1503 #ifdef __clang__
1504 #else
1505 make an error
1506 #endif
1507 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1508 ],[])
1509         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1510         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1511 fi
1512
1513 CLANG_VERSION=none
1514
1515 if test "x$ifelse([$2],,CLANG_COMPILER,[$2])" = "xyes" ; then
1516         case "$CC" in
1517         (c[[1-9]][[0-9]]|*/c[[1-9]][[0-9]])
1518                 AC_MSG_WARN(replacing broken compiler alias $CC)
1519                 CFLAGS="$CFLAGS -std=`echo "$CC" | sed -e 's%.*/%%'`"
1520                 CC=clang
1521                 ;;
1522         esac
1523
1524         AC_MSG_CHECKING(version of $CC)
1525         CLANG_VERSION="`$CC --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(CLANG[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1526         test -z "$CLANG_VERSION" && CLANG_VERSION=unknown
1527         AC_MSG_RESULT($CLANG_VERSION)
1528
1529         for cf_clang_opt in \
1530                 -Qunused-arguments \
1531                 -Wno-error=implicit-function-declaration
1532         do
1533                 AC_MSG_CHECKING(if option $cf_clang_opt works)
1534                 cf_save_CFLAGS="$CFLAGS"
1535                 CFLAGS="$CFLAGS $cf_clang_opt"
1536                 AC_TRY_LINK([
1537                         #include <stdio.h>],[
1538                         printf("hello!\n");],[
1539                         cf_clang_optok=yes],[
1540                         cf_clang_optok=no])
1541                 AC_MSG_RESULT($cf_clang_optok)
1542                 CFLAGS="$cf_save_CFLAGS"
1543                 if test $cf_clang_optok = yes; then
1544                         CF_VERBOSE(adding option $cf_clang_opt)
1545                         CF_APPEND_TEXT(CFLAGS,$cf_clang_opt)
1546                 fi
1547         done
1548 fi
1549 ])
1550 dnl ---------------------------------------------------------------------------
1551 dnl CF_CONST_X_STRING version: 4 updated: 2020/03/10 18:53:47
1552 dnl -----------------
1553 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
1554 dnl character-strings.
1555 dnl
1556 dnl It is ambiguous because the specification accommodated the pre-ANSI
1557 dnl compilers bundled by more than one vendor in lieu of providing a standard C
1558 dnl compiler other than by costly add-ons.  Because of this, the specification
1559 dnl did not take into account the use of const for telling the compiler that
1560 dnl string literals would be in readonly memory.
1561 dnl
1562 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
1563 dnl let the compiler decide how to represent Xt's strings which were #define'd.
1564 dnl That does not solve the problem of using the block of Xt's strings which
1565 dnl are compiled into the library (and is less efficient than one might want).
1566 dnl
1567 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
1568 dnl when compiling the library and compiling using the library, to tell the
1569 dnl compiler that String is const.
1570 AC_DEFUN([CF_CONST_X_STRING],
1571 [
1572 AC_REQUIRE([AC_PATH_XTRA])
1573
1574 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
1575
1576 AC_TRY_COMPILE(
1577 [
1578 #include <stdlib.h>
1579 #include <X11/Intrinsic.h>
1580 ],
1581 [String foo = malloc(1); (void)foo],[
1582
1583 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
1584         AC_TRY_COMPILE(
1585                 [
1586 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
1587 #undef  XTSTRINGDEFINES /* X11R5 and later */
1588 #include <stdlib.h>
1589 #include <X11/Intrinsic.h>
1590                 ],[String foo = malloc(1); *foo = 0],[
1591                         cf_cv_const_x_string=no
1592                 ],[
1593                         cf_cv_const_x_string=yes
1594                 ])
1595 ])
1596
1597 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
1598
1599 case $cf_cv_const_x_string in
1600 (no)
1601         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
1602         ;;
1603 (*)
1604         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
1605         ;;
1606 esac
1607
1608 ])
1609 ])dnl
1610 dnl ---------------------------------------------------------------------------
1611 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1612 dnl -----------------
1613 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1614 dnl is a late feature for the standard and is not in some recent compilers
1615 dnl (1999/9/11).
1616 AC_DEFUN([CF_CPP_PARAM_INIT],
1617 [
1618 if test -n "$CXX"; then
1619 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1620         AC_LANG_SAVE
1621         AC_LANG_CPLUSPLUS
1622         AC_TRY_RUN([
1623 class TEST {
1624 private:
1625         int value;
1626 public:
1627         TEST(int x = 1);
1628         ~TEST();
1629 };
1630
1631 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1632 {
1633         value = x;
1634 }
1635 int main(void) { }
1636 ],
1637         [cf_cv_cpp_param_init=yes],
1638         [cf_cv_cpp_param_init=no],
1639         [cf_cv_cpp_param_init=unknown])
1640         AC_LANG_RESTORE
1641 ])
1642 fi
1643 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1644 ])dnl
1645 dnl ---------------------------------------------------------------------------
1646 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1647 dnl ------------------
1648 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1649 dnl not be supported in g++ before 3.0
1650 AC_DEFUN([CF_CPP_STATIC_CAST],
1651 [
1652 if test -n "$CXX"; then
1653
1654 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1655         AC_LANG_SAVE
1656         AC_LANG_CPLUSPLUS
1657
1658         AC_TRY_COMPILE([
1659 class NCursesPanel
1660 {
1661 public:
1662   NCursesPanel(int nlines,
1663                int ncols,
1664                int begin_y = 0,
1665                int begin_x = 0)
1666   {
1667   }
1668   NCursesPanel();
1669   ~NCursesPanel();
1670 };
1671
1672 template<class T> class NCursesUserPanel : public NCursesPanel
1673 {
1674 public:
1675   NCursesUserPanel (int nlines,
1676                     int ncols,
1677                     int begin_y = 0,
1678                     int begin_x = 0,
1679                     const T* p_UserData = static_cast<T*>(0))
1680     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1681   {
1682   };
1683   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1684   {
1685   };
1686
1687   virtual ~NCursesUserPanel() {};
1688 };
1689 ],[
1690         const char* p_UserData = static_cast<char*>(0)],
1691         [cf_cv_cpp_static_cast=yes],
1692         [cf_cv_cpp_static_cast=no])
1693
1694         AC_LANG_RESTORE
1695 ])
1696
1697 fi
1698
1699 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1700 ])dnl
1701 dnl ---------------------------------------------------------------------------
1702 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1703 dnl ---------------
1704 dnl Setup special archiver flags for given compilers.
1705 AC_DEFUN([CF_CXX_AR_FLAGS],[
1706         CXX_AR='$(AR)'
1707         CXX_ARFLAGS='$(ARFLAGS)'
1708         case $cf_cv_system_name in
1709         (irix*)
1710             if test "$GXX" != yes ; then
1711                 CXX_AR='$(CXX)'
1712                 CXX_ARFLAGS='-ar -o'
1713             fi
1714             ;;
1715         (sco3.2v5*)
1716             CXXLDFLAGS="-u main"
1717             ;;
1718         (solaris2*)
1719             if test "$GXX" != yes ; then
1720                 CXX_AR='$(CXX)'
1721                 CXX_ARFLAGS='-xar -o'
1722             fi
1723             ;;
1724         esac
1725         AC_SUBST(CXXLDFLAGS)
1726         AC_SUBST(CXX_AR)
1727         AC_SUBST(CXX_ARFLAGS)
1728 ])dnl
1729 dnl ---------------------------------------------------------------------------
1730 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1731 dnl -------------------------
1732 dnl For c++, check if iostream uses "std::" namespace.
1733 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1734 AC_CHECK_HEADERS(iostream)
1735 if test x"$ac_cv_header_iostream" = xyes ; then
1736         AC_MSG_CHECKING(if iostream uses std-namespace)
1737         AC_TRY_COMPILE([
1738 #include <iostream>
1739 using std::endl;
1740 using std::cerr;],[
1741 cerr << "testing" << endl;
1742 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1743         AC_MSG_RESULT($cf_iostream_namespace)
1744         if test "$cf_iostream_namespace" = yes ; then
1745                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1746         fi
1747 fi
1748 ])dnl
1749 dnl ---------------------------------------------------------------------------
1750 dnl CF_C_INLINE version: 6 updated: 2019/09/07 13:38:36
1751 dnl -----------
1752 dnl Check if the C compiler supports "inline".
1753 dnl $1 is the name of a shell variable to set if inline is supported
1754 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1755 AC_DEFUN([CF_C_INLINE],[
1756 AC_REQUIRE([CF_GCC_VERSION])
1757 AC_C_INLINE
1758 $1=
1759 if test "$ac_cv_c_inline" != no ; then
1760         $1=inline
1761         if test "$INTEL_COMPILER" = yes
1762         then
1763                 :
1764         elif test "$CLANG_COMPILER" = yes
1765         then
1766                 :
1767         elif test "$GCC" = yes
1768         then
1769                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1770                 cf_save_CFLAGS=$CFLAGS
1771                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1772                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1773                 [${cf_cv_main_return:-return} foo()],
1774                 [cf_cv_gcc_inline=yes],
1775                 [cf_cv_gcc_inline=no])
1776                 CFLAGS=$cf_save_CFLAGS
1777                 ])
1778                 if test "$cf_cv_gcc_inline" = yes ; then
1779                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1780                 fi
1781         fi
1782 fi
1783 AC_SUBST($1)
1784 ])dnl
1785 dnl ---------------------------------------------------------------------------
1786 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1787 dnl ----------
1788 dnl "dirname" is not portable, so we fake it with a shell script.
1789 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1790 dnl ---------------------------------------------------------------------------
1791 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1792 dnl ---------------
1793 AC_DEFUN([CF_DIRS_TO_MAKE],
1794 [
1795 DIRS_TO_MAKE="lib"
1796 for cf_item in $cf_list_models
1797 do
1798         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1799         for cf_item2 in $DIRS_TO_MAKE
1800         do
1801                 test $cf_item2 = $cf_subdir && break
1802         done
1803         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1804 done
1805 for cf_dir in $DIRS_TO_MAKE
1806 do
1807         test ! -d $cf_dir && mkdir $cf_dir
1808 done
1809 AC_SUBST(DIRS_TO_MAKE)
1810 ])dnl
1811 dnl ---------------------------------------------------------------------------
1812 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1813 dnl ---------------
1814 dnl You can always use "make -n" to see the actual options, but it's hard to
1815 dnl pick out/analyze warning messages when the compile-line is long.
1816 dnl
1817 dnl Sets:
1818 dnl     ECHO_LT - symbol to control if libtool is verbose
1819 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1820 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1821 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1822 dnl     ECHO_CC - symbol to put before any "cc" line
1823 dnl
1824 AC_DEFUN([CF_DISABLE_ECHO],[
1825 AC_MSG_CHECKING(if you want to see long compiling messages)
1826 CF_ARG_DISABLE(echo,
1827         [  --disable-echo          do not display "compiling" commands],
1828         [
1829         ECHO_LT='--silent'
1830         ECHO_LD='@echo linking [$]@;'
1831         RULE_CC='@echo compiling [$]<'
1832         SHOW_CC='@echo compiling [$]@'
1833         ECHO_CC='@'
1834 ],[
1835         ECHO_LT=''
1836         ECHO_LD=''
1837         RULE_CC=''
1838         SHOW_CC=''
1839         ECHO_CC=''
1840 ])
1841 AC_MSG_RESULT($enableval)
1842 AC_SUBST(ECHO_LT)
1843 AC_SUBST(ECHO_LD)
1844 AC_SUBST(RULE_CC)
1845 AC_SUBST(SHOW_CC)
1846 AC_SUBST(ECHO_CC)
1847 ])dnl
1848 dnl ---------------------------------------------------------------------------
1849 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1850 dnl ------------------------
1851 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1852 AC_MSG_CHECKING(if we want to use GNAT projects)
1853 CF_ARG_DISABLE(gnat-projects,
1854         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1855         [enable_gnat_projects=no],
1856         [enable_gnat_projects=yes])
1857 AC_MSG_RESULT($enable_gnat_projects)
1858 ])dnl
1859 dnl ---------------------------------------------------------------------------
1860 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1861 dnl ----------------
1862 dnl Combine no-leak checks with the libraries or tools that are used for the
1863 dnl checks.
1864 AC_DEFUN([CF_DISABLE_LEAKS],[
1865
1866 AC_REQUIRE([CF_WITH_DMALLOC])
1867 AC_REQUIRE([CF_WITH_DBMALLOC])
1868 AC_REQUIRE([CF_WITH_VALGRIND])
1869
1870 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1871 AC_ARG_ENABLE(leaks,
1872         [  --disable-leaks         test: free permanent memory, analyze leaks],
1873         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1874         : ${with_no_leaks:=no})
1875 AC_MSG_RESULT($with_no_leaks)
1876
1877 if test "$with_no_leaks" = yes ; then
1878         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1879         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1880 fi
1881 ])dnl
1882 dnl ---------------------------------------------------------------------------
1883 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1884 dnl --------------------------
1885 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1886 dnl the older "-version-info" feature.  The newer feature allows us to use
1887 dnl version numbering on shared libraries which make them compatible with
1888 dnl various systems.
1889 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1890 [
1891 AC_MSG_CHECKING(if libtool -version-number should be used)
1892 CF_ARG_DISABLE(libtool-version,
1893         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1894         [cf_libtool_version=no],
1895         [cf_libtool_version=yes])
1896 AC_MSG_RESULT($cf_libtool_version)
1897
1898 if test "$cf_libtool_version" = yes ; then
1899         LIBTOOL_VERSION="-version-number"
1900 else
1901         LIBTOOL_VERSION="-version-info"
1902         case "x$VERSION" in
1903         (x)
1904                 AC_MSG_WARN(VERSION was not set)
1905                 ;;
1906         (x*.*.*)
1907                 ABI_VERSION="$VERSION"
1908                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1909                 ;;
1910         (x*:*:*)
1911                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1912                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1913                 ;;
1914         (*)
1915                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1916                 ;;
1917         esac
1918 fi
1919
1920 AC_SUBST(ABI_VERSION)
1921 AC_SUBST(LIBTOOL_VERSION)
1922 ])dnl
1923 dnl ---------------------------------------------------------------------------
1924 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1925 dnl ---------------------
1926 dnl The rpath-hack makes it simpler to build programs, particularly with the
1927 dnl *BSD ports which may have essential libraries in unusual places.  But it
1928 dnl can interfere with building an executable for the base system.  Use this
1929 dnl option in that case.
1930 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1931 [
1932 AC_MSG_CHECKING(if rpath-hack should be disabled)
1933 CF_ARG_DISABLE(rpath-hack,
1934         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1935         [cf_disable_rpath_hack=yes],
1936         [cf_disable_rpath_hack=no])
1937 AC_MSG_RESULT($cf_disable_rpath_hack)
1938 if test "$cf_disable_rpath_hack" = no ; then
1939         CF_RPATH_HACK
1940 fi
1941 ])
1942 dnl ---------------------------------------------------------------------------
1943 dnl CF_ENABLE_BROKEN_LINKER version: 1 updated: 2020/02/08 15:59:30
1944 dnl -----------------------
1945 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
1946 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
1947 dnl an unconditional feature.
1948 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
1949
1950 AC_MSG_CHECKING(if you want broken-linker support code)
1951 AC_ARG_ENABLE(broken_linker,
1952         [  --enable-broken_linker  compile with broken-linker support code],
1953         [with_broken_linker=$enableval],
1954         [with_broken_linker=no])
1955 AC_MSG_RESULT($with_broken_linker)
1956
1957 : ${BROKEN_LINKER:=0}
1958 if test "x$with_broken_linker" = xyes ; then
1959         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
1960         BROKEN_LINKER=1
1961 fi
1962 AC_SUBST(BROKEN_LINKER)
1963 ])dnl
1964 dnl ---------------------------------------------------------------------------
1965 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1966 dnl ------------------
1967 dnl This is the "--enable-pc-files" option, which is available if there is a
1968 dnl pkg-config configuration on the local machine.
1969 AC_DEFUN([CF_ENABLE_PC_FILES],[
1970 AC_REQUIRE([CF_PKG_CONFIG])
1971 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1972
1973 if test "x$PKG_CONFIG" != xnone
1974 then
1975         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1976 else
1977         AC_MSG_CHECKING(if we should install .pc files)
1978 fi
1979
1980 AC_ARG_ENABLE(pc-files,
1981         [  --enable-pc-files       generate and install .pc files for pkg-config],
1982         [enable_pc_files=$enableval],
1983         [enable_pc_files=no])
1984 AC_MSG_RESULT($enable_pc_files)
1985
1986 if test "x$enable_pc_files" != xno
1987 then
1988         MAKE_PC_FILES=
1989         case "x$PKG_CONFIG_LIBDIR" in
1990         (xno|xyes)
1991                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1992                 ;;
1993         (*)
1994                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1995                 ;;
1996         esac
1997 else
1998         MAKE_PC_FILES="#"
1999 fi
2000 AC_SUBST(MAKE_PC_FILES)
2001 ])dnl
2002 dnl ---------------------------------------------------------------------------
2003 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
2004 dnl ---------------
2005 dnl Check if the rpath option should be used, setting cache variable
2006 dnl cf_cv_enable_rpath if so.
2007 AC_DEFUN([CF_ENABLE_RPATH],
2008 [
2009 AC_MSG_CHECKING(if rpath option should be used)
2010 AC_ARG_ENABLE(rpath,
2011 [  --enable-rpath          use rpath option when generating shared libraries],
2012 [cf_cv_enable_rpath=$enableval],
2013 [cf_cv_enable_rpath=no])
2014 AC_MSG_RESULT($cf_cv_enable_rpath)
2015 ])dnl
2016 dnl ---------------------------------------------------------------------------
2017 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
2018 dnl ----------------------
2019 dnl On a few platforms, the compiler and/or loader nags with untruthful
2020 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
2021 dnl and implying that most uses of the recommended alternatives are correct.
2022 dnl
2023 dnl Factually speaking, no one has actually counted the number of uses of these
2024 dnl functions versus the total of incorrect uses.  Samples of a few thousand
2025 dnl instances are meaningless compared to the hundreds of millions of lines of
2026 dnl existing C code.
2027 dnl
2028 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
2029 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
2030 dnl standard - but evolved through phases, and older implementations are likely
2031 dnl to yield surprising results, as documented in manpages on various systems.
2032 AC_DEFUN([CF_ENABLE_STRING_HACKS],
2033 [
2034 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
2035 AC_ARG_ENABLE(string-hacks,
2036         [  --enable-string-hacks   work around bogus compiler/loader warnings],
2037         [with_string_hacks=$enableval],
2038         [with_string_hacks=no])
2039 AC_MSG_RESULT($with_string_hacks)
2040
2041 if test "x$with_string_hacks" = "xyes"; then
2042         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
2043         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
2044         AC_CHECK_FUNC(strlcat,[
2045                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2046                 ],[
2047                 AC_CHECK_LIB(bsd,strlcat,[
2048                         CF_ADD_LIB(bsd)
2049                         AC_CHECK_HEADERS(bsd/string.h)
2050                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2051                         ])
2052                 ])
2053         AC_CHECK_FUNCS( strlcpy snprintf )
2054 fi
2055 ])dnl
2056 dnl ---------------------------------------------------------------------------
2057 dnl CF_ENABLE_WARNINGS version: 7 updated: 2020/08/29 09:05:21
2058 dnl ------------------
2059 dnl Configure-option to enable gcc warnings
2060 dnl
2061 dnl $1 = extra options to add, if supported
2062 dnl $2 = option for checking attributes.  By default, this is done when
2063 dnl      warnings are enabled.  For other values:
2064 dnl      yes: always do this, e.g., to use in generated library-headers
2065 dnl      no: never do this
2066 AC_DEFUN([CF_ENABLE_WARNINGS],[
2067 if ( test "$GCC" = yes || test "$GXX" = yes )
2068 then
2069 CF_FIX_WARNINGS(CFLAGS)
2070 CF_FIX_WARNINGS(CPPFLAGS)
2071 CF_FIX_WARNINGS(LDFLAGS)
2072 AC_MSG_CHECKING(if you want to turn on gcc warnings)
2073 CF_ARG_ENABLE(warnings,
2074         [  --enable-warnings       test: turn on gcc compiler warnings],
2075         [with_warnings=yes],
2076         [with_warnings=no])
2077 AC_MSG_RESULT($with_warnings)
2078 if test "$with_warnings" = "yes"
2079 then
2080         ifelse($2,,[CF_GCC_ATTRIBUTES])
2081         CF_GCC_WARNINGS($1)
2082 fi
2083 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
2084 fi
2085 ])dnl
2086 dnl ---------------------------------------------------------------------------
2087 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
2088 dnl --------
2089 dnl Check if 'errno' is declared in <errno.h>
2090 AC_DEFUN([CF_ERRNO],
2091 [
2092 CF_CHECK_ERRNO(errno)
2093 ])dnl
2094 dnl ---------------------------------------------------------------------------
2095 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
2096 dnl ---------------
2097 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
2098 dnl math.h and builtin.h, only for ncurses
2099 AC_DEFUN([CF_ETIP_DEFINES],
2100 [
2101 AC_MSG_CHECKING(for special defines needed for etip.h)
2102 cf_save_CXXFLAGS="$CXXFLAGS"
2103 cf_result="none"
2104
2105 # etip.h includes ncurses.h which includes ncurses_dll.h
2106 # But ncurses_dll.h is generated - fix here.
2107 test -d include || mkdir include
2108 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
2109
2110 for cf_math in "" MATH_H
2111 do
2112 for cf_excp in "" MATH_EXCEPTION
2113 do
2114         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
2115         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
2116         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
2117 AC_TRY_COMPILE([
2118 #include <etip.h.in>
2119 ],[],[
2120         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
2121         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
2122         cf_result="$cf_math $cf_excp"
2123         break 2
2124 ],[])
2125 done
2126 done
2127 AC_MSG_RESULT($cf_result)
2128 CXXFLAGS="$cf_save_CXXFLAGS"
2129 ])
2130 dnl ---------------------------------------------------------------------------
2131 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
2132 dnl ---------------
2133 dnl Find a library (specifically the linkage used in the code fragment),
2134 dnl searching for it if it is not already in the library path.
2135 dnl See also CF_ADD_SEARCHPATH.
2136 dnl
2137 dnl Parameters (4-on are optional):
2138 dnl     $1 = headers for library entrypoint
2139 dnl     $2 = code fragment for library entrypoint
2140 dnl     $3 = the library name without the "-l" option or ".so" suffix.
2141 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
2142 dnl     $5 = action to perform if not successful
2143 dnl     $6 = module name, if not the same as the library name
2144 dnl     $7 = extra libraries
2145 dnl
2146 dnl Sets these variables:
2147 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
2148 dnl     $cf_cv_header_path_$3 - include-directory if needed
2149 dnl     $cf_cv_library_path_$3 - library-directory if needed
2150 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
2151 AC_DEFUN([CF_FIND_LINKAGE],[
2152
2153 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
2154 # will be set on completion of the AC_TRY_LINK below.
2155 cf_cv_header_path_$3=
2156 cf_cv_library_path_$3=
2157
2158 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
2159
2160 cf_save_LIBS="$LIBS"
2161
2162 AC_TRY_LINK([$1],[$2],[
2163         cf_cv_find_linkage_$3=yes
2164         cf_cv_header_path_$3=/usr/include
2165         cf_cv_library_path_$3=/usr/lib
2166 ],[
2167
2168 LIBS="-l$3 $7 $cf_save_LIBS"
2169
2170 AC_TRY_LINK([$1],[$2],[
2171         cf_cv_find_linkage_$3=yes
2172         cf_cv_header_path_$3=/usr/include
2173         cf_cv_library_path_$3=/usr/lib
2174         cf_cv_library_file_$3="-l$3"
2175 ],[
2176         cf_cv_find_linkage_$3=no
2177         LIBS="$cf_save_LIBS"
2178
2179         CF_VERBOSE(find linkage for $3 library)
2180         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
2181
2182         cf_save_CPPFLAGS="$CPPFLAGS"
2183         cf_test_CPPFLAGS="$CPPFLAGS"
2184
2185         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
2186         for cf_cv_header_path_$3 in $cf_search
2187         do
2188                 if test -d $cf_cv_header_path_$3 ; then
2189                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
2190                         CPPFLAGS="$cf_save_CPPFLAGS"
2191                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
2192                         AC_TRY_COMPILE([$1],[$2],[
2193                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
2194                                 cf_cv_find_linkage_$3=maybe
2195                                 cf_test_CPPFLAGS="$CPPFLAGS"
2196                                 break],[
2197                                 CPPFLAGS="$cf_save_CPPFLAGS"
2198                                 ])
2199                 fi
2200         done
2201
2202         if test "$cf_cv_find_linkage_$3" = maybe ; then
2203
2204                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
2205
2206                 cf_save_LIBS="$LIBS"
2207                 cf_save_LDFLAGS="$LDFLAGS"
2208
2209                 ifelse([$6],,,[
2210                 CPPFLAGS="$cf_test_CPPFLAGS"
2211                 LIBS="-l$3 $7 $cf_save_LIBS"
2212                 AC_TRY_LINK([$1],[$2],[
2213                         CF_VERBOSE(... found $3 library in system)
2214                         cf_cv_find_linkage_$3=yes])
2215                         CPPFLAGS="$cf_save_CPPFLAGS"
2216                         LIBS="$cf_save_LIBS"
2217                         ])
2218
2219                 if test "$cf_cv_find_linkage_$3" != yes ; then
2220                         CF_LIBRARY_PATH(cf_search,$3)
2221                         for cf_cv_library_path_$3 in $cf_search
2222                         do
2223                                 if test -d $cf_cv_library_path_$3 ; then
2224                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
2225                                         CPPFLAGS="$cf_test_CPPFLAGS"
2226                                         LIBS="-l$3 $7 $cf_save_LIBS"
2227                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
2228                                         AC_TRY_LINK([$1],[$2],[
2229                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
2230                                         cf_cv_find_linkage_$3=yes
2231                                         cf_cv_library_file_$3="-l$3"
2232                                         break],[
2233                                         CPPFLAGS="$cf_save_CPPFLAGS"
2234                                         LIBS="$cf_save_LIBS"
2235                                         LDFLAGS="$cf_save_LDFLAGS"
2236                                         ])
2237                                 fi
2238                         done
2239                         CPPFLAGS="$cf_save_CPPFLAGS"
2240                         LDFLAGS="$cf_save_LDFLAGS"
2241                 fi
2242
2243         else
2244                 cf_cv_find_linkage_$3=no
2245         fi
2246         ],$7)
2247 ])
2248
2249 LIBS="$cf_save_LIBS"
2250
2251 if test "$cf_cv_find_linkage_$3" = yes ; then
2252 ifelse([$4],,[
2253         CF_ADD_INCDIR($cf_cv_header_path_$3)
2254         CF_ADD_LIBDIR($cf_cv_library_path_$3)
2255         CF_ADD_LIB($3)
2256 ],[$4])
2257 else
2258 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
2259 fi
2260 ])dnl
2261 dnl ---------------------------------------------------------------------------
2262 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
2263 dnl ------------------
2264 dnl Find an include-directory with the given leaf-name.  This is useful for
2265 dnl example with FreeBSD ports, which use this convention to distinguish
2266 dnl different versions of the same port.
2267 AC_DEFUN([CF_FIND_SUB_INCDIR],[
2268         CF_SUBDIR_PATH(cf_search,$1,include)
2269         for cf_item in $cf_search
2270         do
2271                 case $cf_item in
2272                 (*/$1)
2273                         CF_ADD_INCDIR($cf_item)
2274                         ;;
2275                 esac
2276         done
2277 ])dnl
2278 dnl ---------------------------------------------------------------------------
2279 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
2280 dnl ------------------
2281 dnl Find a library-directory with the given leaf-name.  This is useful for
2282 dnl example with FreeBSD ports, which use this convention to distinguish
2283 dnl different versions of the same port.
2284 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
2285         CF_SUBDIR_PATH(cf_search,$1,lib)
2286         for cf_item in $cf_search
2287         do
2288                 case $cf_item in
2289                 (*/$1)
2290                         CF_ADD_LIBDIR($cf_item)
2291                         ;;
2292                 esac
2293         done
2294 ])dnl
2295 dnl ---------------------------------------------------------------------------
2296 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
2297 dnl -----------------
2298 dnl make ADAFLAGS consistent with CFLAGS
2299 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
2300         AC_MSG_CHECKING(optimization options for ADAFLAGS)
2301         case "$CFLAGS" in
2302         (*-g*)
2303                 CF_ADD_ADAFLAGS(-g)
2304                 ;;
2305         esac
2306         case "$CFLAGS" in
2307         (*-O*)
2308                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
2309                 CF_ADD_ADAFLAGS($cf_O_flag)
2310                 ;;
2311         esac
2312         AC_MSG_RESULT($ADAFLAGS)
2313 ])dnl
2314 dnl ---------------------------------------------------------------------------
2315 dnl CF_FIX_WARNINGS version: 2 updated: 2020/08/28 15:08:28
2316 dnl ---------------
2317 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
2318 dnl "-Werror" flags can interfere with configure-checks.  Those go into
2319 dnl EXTRA_CFLAGS.
2320 dnl
2321 dnl $1 = variable name to repair
2322 define([CF_FIX_WARNINGS],[
2323 if ( test "$GCC" = yes || test "$GXX" = yes )
2324 then
2325         case [$]$1 in
2326         (*-Werror=*)
2327                 CF_VERBOSE(repairing $1: [$]$1)
2328                 cf_temp_flags=
2329                 for cf_temp_scan in [$]$1
2330                 do
2331                         case "x$cf_temp_scan" in
2332                         (x-Werror=*)
2333                                 CF_APPEND_TEXT(EXTRA_CFLAGS,"$cf_temp_scan")
2334                                 ;;
2335                         (*)
2336                                 CF_APPEND_TEXT(cf_temp_flags,"$cf_temp_scan")
2337                                 ;;
2338                         esac
2339                 done
2340                 $1="$cf_temp_flags"
2341                 CF_VERBOSE(... fixed [$]$1)
2342                 CF_VERBOSE(... extra $EXTRA_CFLAGS)
2343                 ;;
2344         esac
2345 fi
2346 AC_SUBST(EXTRA_CFLAGS)
2347 ])dnl
2348 dnl ---------------------------------------------------------------------------
2349 dnl CF_FOPEN_BIN_R version: 2 updated: 2019/12/31 08:53:54
2350 dnl --------------
2351 dnl Check if fopen works when the "b" (binary) flag is added to the mode
2352 dnl parameter.  POSIX ignores the "b", which c89 specified.  Some very old
2353 dnl systems do not accept it.
2354 AC_DEFUN([CF_FOPEN_BIN_R],[
2355 AC_CACHE_CHECK(if fopen accepts explicit binary mode,cf_cv_fopen_bin_r,[
2356         AC_TRY_RUN([
2357 #include <stdio.h>
2358 int main(void) {
2359         FILE *fp = fopen("conftest.tmp", "wb");
2360         int rc = 0;
2361         if (fp != 0) {
2362                 int p, q;
2363                 for (p = 0; p < 256; ++p) {
2364                         fputc(p, fp);
2365                 }
2366                 fclose(fp);
2367                 fp = fopen("conftest.tmp", "rb");
2368                 if (fp != 0) {
2369                         for (p = 0; p < 256; ++p) {
2370                                 q = fgetc(fp);
2371                                 if (q != p) {
2372                                         rc = 1;
2373                                         break;
2374                                 }
2375                         }
2376                 } else {
2377                         rc = 1;
2378                 }
2379         } else {
2380                 rc = 1;
2381         }
2382         ${cf_cv_main_return:-return} (rc);
2383 }
2384 ],
2385                 [cf_cv_fopen_bin_r=yes],
2386                 [cf_cv_fopen_bin_r=no],
2387                 [cf_cv_fopen_bin_r=unknown])
2388 ])
2389 test "x$cf_cv_fopen_bin_r" != xno && AC_DEFINE(USE_FOPEN_BIN_R,1,[Define to 1 if fopen accepts explicit binary mode])
2390 ])dnl
2391 dnl ---------------------------------------------------------------------------
2392 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
2393 dnl --------------
2394 dnl Forget that we saw the given tool.
2395 AC_DEFUN([CF_FORGET_TOOL],[
2396 unset ac_cv_prog_ac_ct_$1
2397 unset ac_ct_$1
2398 unset $1
2399 ])dnl
2400 dnl ---------------------------------------------------------------------------
2401 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
2402 dnl -------------
2403 dnl Test for dlsym() and related functions, as well as libdl.
2404 dnl
2405 dnl Sets
2406 dnl     $cf_have_dlsym
2407 dnl     $cf_have_libdl
2408 AC_DEFUN([CF_FUNC_DLSYM],[
2409 cf_have_dlsym=no
2410 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
2411
2412 cf_have_libdl=no
2413 AC_CHECK_LIB(dl,dlsym,[
2414         cf_have_dlsym=yes
2415         cf_have_libdl=yes])])
2416
2417 if test "$cf_have_dlsym" = yes ; then
2418         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
2419
2420         AC_MSG_CHECKING(whether able to link to dl*() functions)
2421         AC_TRY_LINK([#include <dlfcn.h>],[
2422                 void *obj;
2423                 if ((obj = dlopen("filename", 0)) != 0) {
2424                         if (dlsym(obj, "symbolname") == 0) {
2425                         dlclose(obj);
2426                         }
2427                 }],[
2428                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
2429                 AC_MSG_ERROR(Cannot link test program for libdl)])
2430         AC_MSG_RESULT(ok)
2431 else
2432         AC_MSG_ERROR(Cannot find dlsym function)
2433 fi
2434 ])
2435 dnl ---------------------------------------------------------------------------
2436 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
2437 dnl ---------------
2438 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
2439 dnl is found, add our own version of memmove to the list of objects.
2440 AC_DEFUN([CF_FUNC_MEMMOVE],
2441 [
2442 AC_CHECK_FUNC(memmove,,[
2443 AC_CHECK_FUNC(bcopy,[
2444         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
2445                 AC_TRY_RUN([
2446 int main(void) {
2447         static char data[] = "abcdefghijklmnopqrstuwwxyz";
2448         char temp[40];
2449         bcopy(data, temp, sizeof(data));
2450         bcopy(temp+10, temp, 15);
2451         bcopy(temp+5, temp+15, 10);
2452         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
2453 }
2454                 ],
2455                 [cf_cv_good_bcopy=yes],
2456                 [cf_cv_good_bcopy=no],
2457                 [cf_cv_good_bcopy=unknown])
2458                 ])
2459         ],[cf_cv_good_bcopy=no])
2460         if test "$cf_cv_good_bcopy" = yes ; then
2461                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
2462         else
2463                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
2464         fi
2465 ])])dnl
2466 dnl ---------------------------------------------------------------------------
2467 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
2468 dnl -----------------
2469 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
2470 dnl AIX 4.x, provide a non-working version.
2471 AC_DEFUN([CF_FUNC_NANOSLEEP],[
2472 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
2473 AC_TRY_RUN([
2474 #include <stdio.h>
2475 #include <errno.h>
2476 #include <time.h>
2477
2478 #ifdef HAVE_SYS_TIME_H
2479 #include <sys/time.h>
2480 #endif
2481
2482 int main(void) {
2483         struct timespec ts1, ts2;
2484         int code;
2485         ts1.tv_sec  = 0;
2486         ts1.tv_nsec = 750000000;
2487         ts2.tv_sec  = 0;
2488         ts2.tv_nsec = 0;
2489         errno = 0;
2490         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2491         ${cf_cv_main_return:-return}(code != 0);
2492 }
2493 ],
2494         [cf_cv_func_nanosleep=yes],
2495         [cf_cv_func_nanosleep=no],
2496         [cf_cv_func_nanosleep=unknown])])
2497
2498 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2499 ])
2500 dnl ---------------------------------------------------------------------------
2501 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
2502 dnl ---------------
2503 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2504 dnl "util" library as well.
2505 AC_DEFUN([CF_FUNC_OPENPTY],
2506 [
2507 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2508 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2509         cf_save_LIBS="$LIBS"
2510         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
2511         for cf_header in pty.h libutil.h util.h
2512         do
2513         AC_TRY_LINK([
2514 #include <$cf_header>
2515 ],[
2516         int x = openpty((int *)0, (int *)0, (char *)0,
2517                                    (struct termios *)0, (struct winsize *)0);
2518 ],[
2519                 cf_cv_func_openpty=$cf_header
2520                 break
2521 ],[
2522                 cf_cv_func_openpty=no
2523 ])
2524         done
2525         LIBS="$cf_save_LIBS"
2526 ])
2527 ])dnl
2528 dnl ---------------------------------------------------------------------------
2529 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
2530 dnl ------------
2531 dnl See if the poll function really works.  Some platforms have poll(), but
2532 dnl it does not work for terminals or files.
2533 AC_DEFUN([CF_FUNC_POLL],[
2534 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
2535 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2536 AC_TRY_RUN([
2537 #include <stdlib.h>
2538 #include <stdio.h>
2539 #include <unistd.h>
2540 #include <fcntl.h>
2541 #ifdef HAVE_POLL_H
2542 #include <poll.h>
2543 #else
2544 #include <sys/poll.h>
2545 #endif
2546 int main(void) {
2547         struct pollfd myfds;
2548         int ret;
2549
2550         /* check for Darwin bug with respect to "devices" */
2551         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2552         if (myfds.fd < 0)
2553                 myfds.fd = 0;
2554         myfds.events = POLLIN;
2555         myfds.revents = 0;
2556
2557         ret = poll(&myfds, 1, 100);
2558
2559         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2560                 ret = -1;
2561         } else {
2562                 int fd = 0;
2563                 if (!isatty(fd)) {
2564                         fd = open("/dev/tty", 2);       /* O_RDWR */
2565                 }
2566 #ifdef HAVE_POSIX_OPENPT
2567                 if (fd < 0) {
2568                         fd = posix_openpt(O_RDWR);
2569                 }
2570 #endif
2571
2572                 if (fd >= 0) {
2573                         /* also check with standard input */
2574                         myfds.fd = fd;
2575                         myfds.events = POLLIN;
2576                         myfds.revents = 0;
2577                         ret = poll(&myfds, 1, 100);
2578                 } else {
2579                         ret = -1;
2580                 }
2581         }
2582         ${cf_cv_main_return:-return}(ret < 0);
2583 }],
2584         [cf_cv_working_poll=yes],
2585         [cf_cv_working_poll=no],
2586         [cf_cv_working_poll=unknown])])
2587 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2588 ])dnl
2589 dnl ---------------------------------------------------------------------------
2590 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2591 dnl ---------------
2592 dnl Some old/broken variations define tcgetattr() only as a macro in
2593 dnl termio(s).h
2594 AC_DEFUN([CF_FUNC_TERMIOS],[
2595 AC_REQUIRE([CF_STRUCT_TERMIOS])
2596 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2597 AC_TRY_LINK([
2598 #include <sys/types.h>
2599 #ifdef HAVE_UNISTD_H
2600 #include <unistd.h>
2601 #endif
2602 #ifdef HAVE_TERMIOS_H
2603 #include <termios.h>
2604 #define TTY struct termios
2605 #else
2606 #ifdef HAVE_TERMIO_H
2607 #include <termio.h>
2608 #define TTY struct termio
2609 #endif
2610 #endif
2611 ],[
2612 TTY foo;
2613 tcgetattr(1, &foo);],
2614 [cf_cv_have_tcgetattr=yes],
2615 [cf_cv_have_tcgetattr=no])])
2616 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2617 ])dnl
2618 dnl ---------------------------------------------------------------------------
2619 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2620 dnl ---------------
2621 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2622 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2623 dnl other functions.
2624 AC_DEFUN([CF_FUNC_VSSCANF],
2625 [
2626 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2627 AC_TRY_LINK([
2628 #include <stdarg.h>
2629 #include <stdio.h>],[
2630         va_list ap;
2631         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2632 AC_TRY_LINK([
2633 #include <stdarg.h>
2634 #include <stdio.h>],[
2635         FILE strbuf;
2636         char *str = "from";
2637
2638         strbuf._flag = _IOREAD;
2639         strbuf._ptr = strbuf._base = (unsigned char *) str;
2640         strbuf._cnt = strlen(str);
2641         strbuf._file = _NFILE;
2642         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2643 AC_TRY_LINK([
2644 #include <stdarg.h>
2645 #include <stdio.h>],[
2646         FILE strbuf;
2647         char *str = "from";
2648
2649         strbuf._flag = _IOREAD;
2650         strbuf._ptr = strbuf._base = (unsigned char *) str;
2651         strbuf._cnt = strlen(str);
2652         strbuf._file = _NFILE;
2653         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2654 cf_cv_func_vsscanf=no])])])])
2655
2656 case $cf_cv_func_vsscanf in
2657 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2658 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2659 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2660 esac
2661
2662 ])dnl
2663 dnl ---------------------------------------------------------------------------
2664 dnl CF_GCC_ATTRIBUTES version: 19 updated: 2020/08/29 09:05:21
2665 dnl -----------------
2666 dnl Test for availability of useful gcc __attribute__ directives to quiet
2667 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2668 dnl to documentation, unrecognized directives cause older compilers to barf.
2669 AC_DEFUN([CF_GCC_ATTRIBUTES],
2670 [
2671 if ( test "$GCC" = yes || test "$GXX" = yes )
2672 then
2673 cat > conftest.i <<EOF
2674 #ifndef GCC_PRINTF
2675 #define GCC_PRINTF 0
2676 #endif
2677 #ifndef GCC_SCANF
2678 #define GCC_SCANF 0
2679 #endif
2680 #ifndef GCC_NORETURN
2681 #define GCC_NORETURN /* nothing */
2682 #endif
2683 #ifndef GCC_UNUSED
2684 #define GCC_UNUSED /* nothing */
2685 #endif
2686 EOF
2687 if test "$GCC" = yes
2688 then
2689         AC_CHECKING([for $CC __attribute__ directives])
2690 cat > conftest.$ac_ext <<EOF
2691 #line __oline__ "${as_me:-configure}"
2692 #include "confdefs.h"
2693 #include "conftest.h"
2694 #include "conftest.i"
2695 #if     GCC_PRINTF
2696 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2697 #else
2698 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2699 #endif
2700 #if     GCC_SCANF
2701 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2702 #else
2703 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2704 #endif
2705 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2706 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2707 extern void foo(void) GCC_NORETURN;
2708 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
2709 EOF
2710         cf_printf_attribute=no
2711         cf_scanf_attribute=no
2712         for cf_attribute in scanf printf unused noreturn
2713         do
2714                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2715                 cf_directive="__attribute__(($cf_attribute))"
2716                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2717
2718                 case $cf_attribute in
2719                 (printf)
2720                         cf_printf_attribute=yes
2721                         cat >conftest.h <<EOF
2722 #define GCC_$cf_ATTRIBUTE 1
2723 EOF
2724                         ;;
2725                 (scanf)
2726                         cf_scanf_attribute=yes
2727                         cat >conftest.h <<EOF
2728 #define GCC_$cf_ATTRIBUTE 1
2729 EOF
2730                         ;;
2731                 (*)
2732                         cat >conftest.h <<EOF
2733 #define GCC_$cf_ATTRIBUTE $cf_directive
2734 EOF
2735                         ;;
2736                 esac
2737
2738                 if AC_TRY_EVAL(ac_compile); then
2739                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2740                         cat conftest.h >>confdefs.h
2741                         case $cf_attribute in
2742                         (noreturn)
2743                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2744                                 ;;
2745                         (printf)
2746                                 cf_value='/* nothing */'
2747                                 if test "$cf_printf_attribute" != no ; then
2748                                         cf_value='__attribute__((format(printf,fmt,var)))'
2749                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2750                                 fi
2751                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2752                                 ;;
2753                         (scanf)
2754                                 cf_value='/* nothing */'
2755                                 if test "$cf_scanf_attribute" != no ; then
2756                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2757                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2758                                 fi
2759                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2760                                 ;;
2761                         (unused)
2762                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2763                                 ;;
2764                         esac
2765                 fi
2766         done
2767 else
2768         fgrep define conftest.i >>confdefs.h
2769 fi
2770 rm -rf conftest*
2771 fi
2772 ])dnl
2773 dnl ---------------------------------------------------------------------------
2774 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
2775 dnl --------------
2776 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
2777 dnl compatible), attempt to determine if icc/clang is actually used.
2778 AC_DEFUN([CF_GCC_VERSION],[
2779 AC_REQUIRE([AC_PROG_CC])
2780 GCC_VERSION=none
2781 if test "$GCC" = yes ; then
2782         AC_MSG_CHECKING(version of $CC)
2783         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2784         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2785         AC_MSG_RESULT($GCC_VERSION)
2786 fi
2787 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2788 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2789 ])dnl
2790 dnl ---------------------------------------------------------------------------
2791 dnl CF_GCC_WARNINGS version: 38 updated: 2020/08/28 15:08:28
2792 dnl ---------------
2793 dnl Check if the compiler supports useful warning options.  There's a few that
2794 dnl we don't use, simply because they're too noisy:
2795 dnl
2796 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2797 dnl     -Winline (usually not worthwhile)
2798 dnl     -Wredundant-decls (system headers make this too noisy)
2799 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2800 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2801 dnl             is enabled for ncurses using "--enable-const".
2802 dnl     -pedantic
2803 dnl
2804 dnl Parameter:
2805 dnl     $1 is an optional list of gcc warning flags that a particular
2806 dnl             application might want to use, e.g., "no-unused" for
2807 dnl             -Wno-unused
2808 dnl Special:
2809 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2810 dnl
2811 AC_DEFUN([CF_GCC_WARNINGS],
2812 [
2813 AC_REQUIRE([CF_GCC_VERSION])
2814 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
2815 cat > conftest.$ac_ext <<EOF
2816 #line __oline__ "${as_me:-configure}"
2817 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2818 EOF
2819 if test "$INTEL_COMPILER" = yes
2820 then
2821 # The "-wdXXX" options suppress warnings:
2822 # remark #1419: external declaration in primary source file
2823 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2824 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2825 # remark #193: zero used for undefined preprocessing identifier
2826 # remark #593: variable "curs_sb_left_arrow" was set but never used
2827 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2828 # remark #869: parameter "tw" was never referenced
2829 # remark #981: operands are evaluated in unspecified order
2830 # warning #279: controlling expression is constant
2831
2832         AC_CHECKING([for $CC warning options])
2833         cf_save_CFLAGS="$CFLAGS"
2834         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
2835         for cf_opt in \
2836                 wd1419 \
2837                 wd1683 \
2838                 wd1684 \
2839                 wd193 \
2840                 wd593 \
2841                 wd279 \
2842                 wd810 \
2843                 wd869 \
2844                 wd981
2845         do
2846                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2847                 if AC_TRY_EVAL(ac_compile); then
2848                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2849                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2850                 fi
2851         done
2852         CFLAGS="$cf_save_CFLAGS"
2853 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
2854 then
2855         AC_CHECKING([for $CC warning options])
2856         cf_save_CFLAGS="$CFLAGS"
2857         cf_warn_CONST=""
2858         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2859         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2860         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2861         for cf_opt in W Wall \
2862                 Wbad-function-cast \
2863                 Wcast-align \
2864                 Wcast-qual \
2865                 Wdeclaration-after-statement \
2866                 Wextra \
2867                 Winline \
2868                 Wmissing-declarations \
2869                 Wmissing-prototypes \
2870                 Wnested-externs \
2871                 Wpointer-arith \
2872                 Wshadow \
2873                 Wstrict-prototypes \
2874                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
2875         do
2876                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2877                 if AC_TRY_EVAL(ac_compile); then
2878                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2879                         case $cf_opt in
2880                         (Winline)
2881                                 case $GCC_VERSION in
2882                                 ([[34]].*)
2883                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2884                                         continue;;
2885                                 esac
2886                                 ;;
2887                         (Wpointer-arith)
2888                                 case $GCC_VERSION in
2889                                 ([[12]].*)
2890                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2891                                         continue;;
2892                                 esac
2893                                 ;;
2894                         esac
2895                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2896                 fi
2897         done
2898         CFLAGS="$cf_save_CFLAGS"
2899 fi
2900 rm -rf conftest*
2901
2902 AC_SUBST(EXTRA_CFLAGS)
2903 ])dnl
2904 dnl ---------------------------------------------------------------------------
2905 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2906 dnl ----------------
2907 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2908 dnl unistd.h or (nonstandard) in getopt.h
2909 AC_DEFUN([CF_GETOPT_HEADER],
2910 [
2911 AC_HAVE_HEADERS(unistd.h getopt.h)
2912 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2913 cf_cv_getopt_header=none
2914 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2915 do
2916 AC_TRY_COMPILE([
2917 #include <$cf_header>],
2918 [int x = optind; char *y = optarg],
2919 [cf_cv_getopt_header=$cf_header
2920  break])
2921 done
2922 ])
2923 if test $cf_cv_getopt_header != none ; then
2924         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2925 fi
2926 if test $cf_cv_getopt_header = getopt.h ; then
2927         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2928 fi
2929 ])dnl
2930 dnl ---------------------------------------------------------------------------
2931 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2932 dnl -----------------
2933 AC_DEFUN([CF_GNATPREP_OPT_T],[
2934 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2935 cf_cv_gnatprep_opt_t=no
2936 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2937 ])
2938 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2939 AC_SUBST(GNATPREP_OPTS)
2940 ])dnl
2941 dnl ---------------------------------------------------------------------------
2942 dnl CF_GNAT_GENERICS version: 6 updated: 2020/07/04 19:30:27
2943 dnl ----------------
2944 AC_DEFUN([CF_GNAT_GENERICS],
2945 [
2946 AC_REQUIRE([CF_GNAT_VERSION])
2947
2948 AC_MSG_CHECKING(if GNAT supports generics)
2949 case $cf_cv_gnat_version in
2950 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
2951         cf_gnat_generics=yes
2952         ;;
2953 (*)
2954         cf_gnat_generics=no
2955         ;;
2956 esac
2957 AC_MSG_RESULT($cf_gnat_generics)
2958
2959 if test "$cf_gnat_generics" = yes
2960 then
2961         cf_compile_generics=generics
2962         cf_generic_objects="\${GENOBJS}"
2963 else
2964         cf_compile_generics=
2965         cf_generic_objects=
2966 fi
2967
2968 AC_SUBST(cf_compile_generics)
2969 AC_SUBST(cf_generic_objects)
2970 ])dnl
2971 dnl ---------------------------------------------------------------------------
2972 dnl CF_GNAT_PROJECTS version: 10 updated: 2019/12/31 08:53:54
2973 dnl ----------------
2974 dnl GNAT projects are configured with ".gpr" project files.
2975 dnl GNAT libraries are a further development, using the project feature.
2976 AC_DEFUN([CF_GNAT_PROJECTS],
2977 [
2978 AC_REQUIRE([CF_GNAT_VERSION])
2979 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2980
2981 cf_gnat_libraries=no
2982 cf_gnat_projects=no
2983
2984 if test "$enable_gnat_projects" != no ; then
2985 AC_MSG_CHECKING(if GNAT supports project files)
2986 case $cf_cv_gnat_version in
2987 (3.[[0-9]]*)
2988         ;;
2989 (*)
2990         case $cf_cv_system_name in
2991         (cygwin*|msys*)
2992                 ;;
2993         (*)
2994                 rm -rf conftest* *~conftest*
2995                 if mkdir conftest.src conftest.bin conftest.lib
2996                 then
2997                         cd conftest.src
2998                         rm -rf conftest* *~conftest*
2999                         cat >>library.gpr <<CF_EOF
3000 project Library is
3001   Kind := External ("LIB_KIND");
3002   for Library_Name use "ConfTest";
3003   for Object_Dir use ".";
3004   for Library_ALI_Dir use External("LIBRARY_DIR");
3005   for Library_Version use External ("SONAME");
3006   for Library_Kind use Kind;
3007   for Library_Dir use External("BUILD_DIR");
3008   Source_Dir := External ("SOURCE_DIR");
3009   for Source_Dirs use (Source_Dir);
3010 end Library;
3011 CF_EOF
3012                         cat >>confpackage.ads <<CF_EOF
3013 package ConfPackage is
3014    procedure conftest;
3015 end ConfPackage;
3016 CF_EOF
3017                         cat >>confpackage.adb <<CF_EOF
3018 with Text_IO;
3019 package body ConfPackage is
3020    procedure conftest is
3021    begin
3022       Text_IO.Put ("Hello World");
3023       Text_IO.New_Line;
3024    end conftest;
3025 end ConfPackage;
3026 CF_EOF
3027                         if ( $cf_ada_make $ADAFLAGS \
3028                                         -Plibrary.gpr \
3029                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
3030                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
3031                                         -XSOURCE_DIR=`pwd` \
3032                                         -XSONAME=libConfTest.so.1 \
3033                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
3034                                 cf_gnat_projects=yes
3035                         fi
3036                         cd ..
3037                 fi
3038                 if test -f conftest.lib/confpackage.ali
3039                 then
3040                         cf_gnat_libraries=yes
3041                 fi
3042                 rm -rf conftest* *~conftest*
3043                 ;;
3044         esac
3045         ;;
3046 esac
3047 AC_MSG_RESULT($cf_gnat_projects)
3048 fi # enable_gnat_projects
3049
3050 if test $cf_gnat_projects = yes
3051 then
3052         AC_MSG_CHECKING(if GNAT supports libraries)
3053         AC_MSG_RESULT($cf_gnat_libraries)
3054 fi
3055
3056 if test "$cf_gnat_projects" = yes
3057 then
3058         USE_OLD_MAKERULES="#"
3059         USE_GNAT_PROJECTS=""
3060 else
3061         USE_OLD_MAKERULES=""
3062         USE_GNAT_PROJECTS="#"
3063 fi
3064
3065 if test "$cf_gnat_libraries" = yes
3066 then
3067         USE_GNAT_LIBRARIES=""
3068 else
3069         USE_GNAT_LIBRARIES="#"
3070 fi
3071
3072 AC_SUBST(USE_OLD_MAKERULES)
3073 AC_SUBST(USE_GNAT_PROJECTS)
3074 AC_SUBST(USE_GNAT_LIBRARIES)
3075 ])dnl
3076 dnl ---------------------------------------------------------------------------
3077 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
3078 dnl --------------
3079 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
3080 dnl is noted that gnat may compile a tasking unit even for configurations which
3081 dnl fail at runtime.
3082 AC_DEFUN([CF_GNAT_SIGINT],[
3083 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
3084 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
3085
3086 package ConfTest is
3087
3088    pragma Warnings (Off);  --  the next pragma exists since 3.11p
3089    pragma Unreserve_All_Interrupts;
3090    pragma Warnings (On);
3091
3092    protected Process is
3093       procedure Stop;
3094       function Continue return Boolean;
3095       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
3096    private
3097       Done : Boolean := False;
3098    end Process;
3099
3100 end ConfTest;],
3101 [package body ConfTest is
3102    protected body Process is
3103       procedure Stop is
3104       begin
3105          Done := True;
3106       end Stop;
3107       function Continue return Boolean is
3108       begin
3109          return not Done;
3110       end Continue;
3111    end Process;
3112 end ConfTest;],
3113         [cf_cv_gnat_sigint=yes],
3114         [cf_cv_gnat_sigint=no])])
3115
3116 if test $cf_cv_gnat_sigint = yes ; then
3117         USE_GNAT_SIGINT=""
3118 else
3119         USE_GNAT_SIGINT="#"
3120 fi
3121 AC_SUBST(USE_GNAT_SIGINT)
3122 ])dnl
3123 dnl ---------------------------------------------------------------------------
3124 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
3125 dnl ----------------
3126 dnl Verify that a test program compiles/links with GNAT.
3127 dnl $cf_ada_make is set to the program that compiles/links
3128 dnl $ADAFLAGS may be set to the GNAT flags.
3129 dnl
3130 dnl $1 is the text of the spec
3131 dnl $2 is the text of the body
3132 dnl $3 is the shell command to execute if successful
3133 dnl $4 is the shell command to execute if not successful
3134 AC_DEFUN([CF_GNAT_TRY_LINK],
3135 [
3136 rm -rf conftest* *~conftest*
3137 cat >>conftest.ads <<CF_EOF
3138 $1
3139 CF_EOF
3140 cat >>conftest.adb <<CF_EOF
3141 $2
3142 CF_EOF
3143 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3144 ifelse($3,,      :,[      $3])
3145 ifelse($4,,,[else
3146    $4])
3147 fi
3148 rm -rf conftest* *~conftest*
3149 ])dnl
3150 dnl ---------------------------------------------------------------------------
3151 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
3152 dnl ---------------
3153 dnl Verify that a test program compiles and runs with GNAT
3154 dnl $cf_ada_make is set to the program that compiles/links
3155 dnl $ADAFLAGS may be set to the GNAT flags.
3156 dnl
3157 dnl $1 is the text of the spec
3158 dnl $2 is the text of the body
3159 dnl $3 is the shell command to execute if successful
3160 dnl $4 is the shell command to execute if not successful
3161 AC_DEFUN([CF_GNAT_TRY_RUN],
3162 [
3163 rm -rf conftest* *~conftest*
3164 cat >>conftest.ads <<CF_EOF
3165 $1
3166 CF_EOF
3167 cat >>conftest.adb <<CF_EOF
3168 $2
3169 CF_EOF
3170 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3171    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
3172 ifelse($3,,      :,[      $3])
3173 ifelse($4,,,[   else
3174       $4])
3175    fi
3176 ifelse($4,,,[else
3177    $4])
3178 fi
3179 rm -rf conftest* *~conftest*
3180 ])dnl
3181 dnl ---------------------------------------------------------------------------
3182 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
3183 dnl ---------------
3184 dnl $1 = cache variable to update
3185 dnl $2 = program name
3186 dnl Verify version of GNAT or related tool
3187 AC_DEFUN([CF_GNAT_VERSION],
3188 [
3189 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
3190 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
3191         grep '[[0-9]].[[0-9]][[0-9]]*' |\
3192         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
3193 ])
3194 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
3195 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
3196 ])dnl
3197 dnl ---------------------------------------------------------------------------
3198 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
3199 dnl -------------
3200 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
3201 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
3202 dnl (or misfeature) of glibc2, which breaks portability of many applications,
3203 dnl since it is interwoven with GNU extensions.
3204 dnl
3205 dnl Well, yes we could work around it...
3206 dnl
3207 dnl Parameters:
3208 dnl     $1 is the nominal value for _XOPEN_SOURCE
3209 AC_DEFUN([CF_GNU_SOURCE],
3210 [
3211 cf_gnu_xopen_source=ifelse($1,,500,$1)
3212
3213 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
3214 AC_TRY_COMPILE([#include <sys/types.h>],[
3215         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
3216                 return 0;
3217         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
3218                 return 0;
3219         #else
3220         #       error not GNU C library
3221         #endif],
3222         [cf_cv_gnu_library=yes],
3223         [cf_cv_gnu_library=no])
3224 ])
3225
3226 if test x$cf_cv_gnu_library = xyes; then
3227
3228         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
3229         # was changed to help a little.  newlib incorporated the change about 4
3230         # years later.
3231         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
3232                 cf_save="$CPPFLAGS"
3233                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3234                 AC_TRY_COMPILE([#include <sys/types.h>],[
3235                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
3236                                 return 0;
3237                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
3238                                 return 0;
3239                         #else
3240                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
3241                         #endif],
3242                         [cf_cv_gnu_library_219=yes],
3243                         [cf_cv_gnu_library_219=no])
3244                 CPPFLAGS="$cf_save"
3245         ])
3246
3247         if test "x$cf_cv_gnu_library_219" = xyes; then
3248                 cf_save="$CPPFLAGS"
3249                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
3250                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
3251                         AC_TRY_COMPILE([
3252                                 #include <limits.h>
3253                                 #include <sys/types.h>
3254                                 ],[
3255                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
3256                                         return 0;
3257                                 #else
3258                                 #       error GNU C library is too old
3259                                 #endif],
3260                                 [cf_cv_gnu_dftsrc_219=yes],
3261                                 [cf_cv_gnu_dftsrc_219=no])
3262                         ])
3263                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
3264         else
3265                 cf_cv_gnu_dftsrc_219=maybe
3266         fi
3267
3268         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
3269
3270                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
3271                 AC_TRY_COMPILE([#include <sys/types.h>],[
3272                         #ifndef _XOPEN_SOURCE
3273                         #error  expected _XOPEN_SOURCE to be defined
3274                         #endif],
3275                         [cf_cv_gnu_source=no],
3276                         [cf_save="$CPPFLAGS"
3277                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
3278                          AC_TRY_COMPILE([#include <sys/types.h>],[
3279                                 #ifdef _XOPEN_SOURCE
3280                                 #error  expected _XOPEN_SOURCE to be undefined
3281                                 #endif],
3282                                 [cf_cv_gnu_source=no],
3283                                 [cf_cv_gnu_source=yes])
3284                         CPPFLAGS="$cf_save"
3285                         ])
3286                 ])
3287
3288                 if test "$cf_cv_gnu_source" = yes
3289                 then
3290                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
3291                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
3292                         AC_TRY_COMPILE([#include <sys/types.h>],[
3293                                 #ifdef _DEFAULT_SOURCE
3294                                 #error  expected _DEFAULT_SOURCE to be undefined
3295                                 #endif],
3296                                 [cf_cv_default_source=no],
3297                                 [cf_cv_default_source=yes])
3298                         ])
3299                         if test "$cf_cv_default_source" = yes
3300                         then
3301                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3302                         fi
3303                 fi
3304         fi
3305
3306 fi
3307 ])dnl
3308 dnl ---------------------------------------------------------------------------
3309 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
3310 dnl --------------
3311 dnl If we're trying to use g++, test if libg++ is installed (a rather common
3312 dnl problem :-).  If we have the compiler but no library, we'll be able to
3313 dnl configure, but won't be able to build the c++ demo program.
3314 AC_DEFUN([CF_GPP_LIBRARY],
3315 [
3316 cf_cxx_library=unknown
3317 case $cf_cv_system_name in
3318 (os2*)
3319         cf_gpp_libname=gpp
3320         ;;
3321 (*)
3322         cf_gpp_libname=g++
3323         ;;
3324 esac
3325 if test "$GXX" = yes; then
3326         AC_MSG_CHECKING([for lib$cf_gpp_libname])
3327         cf_save="$LIBS"
3328         CF_ADD_LIB($cf_gpp_libname)
3329         AC_TRY_LINK([
3330 #include <$cf_gpp_libname/builtin.h>
3331         ],
3332         [two_arg_error_handler_t foo2 = lib_error_handler],
3333         [cf_cxx_library=yes
3334          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3335          if test "$cf_gpp_libname" = cpp ; then
3336             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
3337          else
3338             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
3339          fi],
3340         [AC_TRY_LINK([
3341 #include <builtin.h>
3342         ],
3343         [two_arg_error_handler_t foo2 = lib_error_handler],
3344         [cf_cxx_library=yes
3345          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3346          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
3347         [cf_cxx_library=no])])
3348         LIBS="$cf_save"
3349         AC_MSG_RESULT($cf_cxx_library)
3350 fi
3351 ])dnl
3352 dnl ---------------------------------------------------------------------------
3353 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
3354 dnl --------------
3355 dnl Check for version of g++
3356 AC_DEFUN([CF_GXX_VERSION],[
3357 AC_REQUIRE([AC_PROG_CPP])
3358 GXX_VERSION=none
3359 if test "$GXX" = yes; then
3360         AC_MSG_CHECKING(version of ${CXX:-g++})
3361         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3362         if test -z "$GXX_VERSION"
3363         then
3364                 GXX_VERSION=unknown
3365                 GXX=no
3366         fi
3367         AC_MSG_RESULT($GXX_VERSION)
3368 fi
3369 ])dnl
3370 dnl ---------------------------------------------------------------------------
3371 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
3372 dnl ---------------
3373 dnl Check if the compiler supports useful warning options.
3374 dnl
3375 dnl Most of gcc's options apply to g++, except:
3376 dnl     -Wbad-function-cast
3377 dnl     -Wmissing-declarations
3378 dnl     -Wnested-externs
3379 dnl
3380 dnl Omit a few (for now):
3381 dnl     -Winline
3382 dnl
3383 dnl Parameter:
3384 dnl     $1 is an optional list of g++ warning flags that a particular
3385 dnl             application might want to use, e.g., "no-unused" for
3386 dnl             -Wno-unused
3387 dnl Special:
3388 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3389 dnl
3390 AC_DEFUN([CF_GXX_WARNINGS],
3391 [
3392
3393 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
3394 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
3395
3396 AC_REQUIRE([CF_GXX_VERSION])
3397
3398 AC_LANG_SAVE
3399 AC_LANG_CPLUSPLUS
3400
3401 cat > conftest.$ac_ext <<EOF
3402 #line __oline__ "configure"
3403 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3404 EOF
3405
3406 if test "$INTEL_CPLUSPLUS" = yes
3407 then
3408 # The "-wdXXX" options suppress warnings:
3409 # remark #1419: external declaration in primary source file
3410 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3411 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3412 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3413 # remark #193: zero used for undefined preprocessing identifier
3414 # remark #593: variable "curs_sb_left_arrow" was set but never used
3415 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3416 # remark #869: parameter "tw" was never referenced
3417 # remark #981: operands are evaluated in unspecified order
3418 # warning #269: invalid format string conversion
3419
3420         AC_CHECKING([for $CC warning options])
3421         cf_save_CXXFLAGS="$CXXFLAGS"
3422         EXTRA_CXXFLAGS="-Wall"
3423         for cf_opt in \
3424                 wd1419 \
3425                 wd1682 \
3426                 wd1683 \
3427                 wd1684 \
3428                 wd193 \
3429                 wd279 \
3430                 wd593 \
3431                 wd810 \
3432                 wd869 \
3433                 wd981
3434         do
3435                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
3436                 if AC_TRY_EVAL(ac_compile); then
3437                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3438                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3439                 fi
3440         done
3441         CXXFLAGS="$cf_save_CXXFLAGS"
3442
3443 elif test "$GXX" = yes
3444 then
3445         AC_CHECKING([for $CXX warning options])
3446         cf_save_CXXFLAGS="$CXXFLAGS"
3447         EXTRA_CXXFLAGS="-W -Wall"
3448         cf_gxx_extra_warnings=""
3449         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
3450         case "$GCC_VERSION" in
3451         ([[1-2]].*)
3452                 ;;
3453         (*)
3454                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
3455                 ;;
3456         esac
3457         for cf_opt in \
3458                 Wabi \
3459                 fabi-version=0 \
3460                 Wextra \
3461                 Wignored-qualifiers \
3462                 Wlogical-op \
3463                 Woverloaded-virtual \
3464                 Wsign-promo \
3465                 Wsynth \
3466                 Wold-style-cast \
3467                 Wcast-align \
3468                 Wcast-qual \
3469                 Wpointer-arith \
3470                 Wshadow \
3471                 Wundef $cf_gxx_extra_warnings $1
3472         do
3473                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
3474                 if AC_TRY_EVAL(ac_compile); then
3475                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3476                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3477                 else
3478                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
3479                 fi
3480         done
3481         CXXFLAGS="$cf_save_CXXFLAGS"
3482 fi
3483
3484 rm -rf conftest*
3485 AC_LANG_RESTORE
3486 AC_SUBST(EXTRA_CXXFLAGS)
3487 ])dnl
3488 dnl ---------------------------------------------------------------------------
3489 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3490 dnl ------------
3491 dnl Look for an instance of the Berkeley hashed database.
3492 dnl
3493 dnl $1 = optional parameter, to specify install-prefix for the database.
3494 AC_DEFUN([CF_HASHED_DB],
3495 [
3496 ifelse([$1],,,[
3497 case $1 in
3498 (yes|*able*)
3499         ;;
3500 (*)
3501         if test -d "$1" ; then
3502                 CF_ADD_INCDIR($1/include)
3503                 CF_ADD_LIBDIR($1/lib)
3504         else
3505                 case "$1" in
3506                 (./*|../*|/*)
3507                         AC_MSG_WARN(no such directory $1)
3508                         ;;
3509                 (*)
3510                         CF_FIND_SUB_INCDIR($1)
3511                         CF_FIND_SUB_LIBDIR($1)
3512                         ;;
3513                 esac
3514         fi
3515 esac
3516 ])
3517 AC_CHECK_HEADER(db.h,[
3518 CF_HASHED_DB_VERSION
3519 if test "$cf_cv_hashed_db_version" = unknown ; then
3520         AC_MSG_ERROR(Cannot determine version of db)
3521 else
3522         CF_HASHED_DB_LIBS
3523         if test "$cf_cv_hashed_db_libs" = unknown ; then
3524                 AC_MSG_ERROR(Cannot determine library for db)
3525         elif test "$cf_cv_hashed_db_libs" != default ; then
3526                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3527         fi
3528 fi
3529 ],[
3530         AC_MSG_ERROR(Cannot find db.h)
3531 ])
3532 ])dnl
3533 dnl ---------------------------------------------------------------------------
3534 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
3535 dnl -----------------
3536 dnl Given that we have the header and version for hashed database, find the
3537 dnl library information.
3538 AC_DEFUN([CF_HASHED_DB_LIBS],
3539 [
3540 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3541 cf_cv_hashed_db_libs=unknown
3542 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3543 do
3544         cf_save_libs="$LIBS"
3545         if test -n "$cf_db_libs"; then
3546                 CF_ADD_LIB($cf_db_libs)
3547         fi
3548         CF_MSG_LOG(checking for library "$cf_db_libs")
3549         AC_TRY_LINK([
3550 $ac_includes_default
3551 #include <db.h>
3552 ],[
3553         char *path = "/tmp/foo";
3554 #ifdef DB_VERSION_MAJOR
3555 #if DB_VERSION_MAJOR >= 4
3556         DB *result = 0;
3557         db_create(&result, NULL, 0);
3558         result->open(result,
3559                 NULL,
3560                 path,
3561                 path,
3562                 DB_HASH,
3563                 DB_CREATE,
3564                 0644);
3565 #elif DB_VERSION_MAJOR >= 3
3566         DB *result = 0;
3567         db_create(&result, NULL, 0);
3568         result->open(result,
3569                 path,
3570                 path,
3571                 DB_HASH,
3572                 DB_CREATE,
3573                 0644);
3574 #elif DB_VERSION_MAJOR >= 2
3575         DB *result = 0;
3576         db_open(path,
3577                 DB_HASH,
3578                 DB_CREATE,
3579                 0644,
3580                 (DB_ENV *) 0,
3581                 (DB_INFO *) 0,
3582                 &result);
3583 #endif /* DB_VERSION_MAJOR */
3584 #else
3585         DB *result = dbopen(path,
3586                      2,
3587                      0644,
3588                      DB_HASH,
3589                      0);
3590 #endif
3591         ${cf_cv_main_return:-return}(result != 0)
3592 ],[
3593         if test -n "$cf_db_libs" ; then
3594                 cf_cv_hashed_db_libs=$cf_db_libs
3595         else
3596                 cf_cv_hashed_db_libs=default
3597         fi
3598         LIBS="$cf_save_libs"
3599         break
3600 ])
3601         LIBS="$cf_save_libs"
3602 done
3603 ])
3604 ])dnl
3605 dnl ---------------------------------------------------------------------------
3606 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3607 dnl --------------------
3608 dnl Given that we have the header file for hashed database, find the version
3609 dnl information.
3610 AC_DEFUN([CF_HASHED_DB_VERSION],
3611 [
3612 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3613 cf_cv_hashed_db_version=unknown
3614
3615 for cf_db_version in 1 2 3 4 5 6
3616 do
3617         CF_MSG_LOG(checking for db version $cf_db_version)
3618         AC_TRY_COMPILE([
3619 $ac_includes_default
3620 #include <db.h>
3621
3622 #ifdef DB_VERSION_MAJOR
3623         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3624 #if $cf_db_version == DB_VERSION_MAJOR
3625         /* ok */
3626 #else
3627         make an error
3628 #endif
3629 #else
3630 #if $cf_db_version == 1
3631         /* ok: assuming this is DB 1.8.5 */
3632 #else
3633         make an error
3634 #endif
3635 #endif
3636 ],[DBT *foo = 0],[
3637         cf_cv_hashed_db_version=$cf_db_version
3638         break
3639         ])
3640 done
3641 ])
3642 ])dnl
3643 dnl ---------------------------------------------------------------------------
3644 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3645 dnl --------------
3646 dnl Construct a search-list of directories for a nonstandard header-file
3647 dnl
3648 dnl Parameters
3649 dnl     $1 = the variable to return as result
3650 dnl     $2 = the package name
3651 AC_DEFUN([CF_HEADER_PATH],
3652 [
3653 $1=
3654
3655 # collect the current set of include-directories from compiler flags
3656 cf_header_path_list=""
3657 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3658         for cf_header_path in $CPPFLAGS $CFLAGS
3659         do
3660                 case $cf_header_path in
3661                 (-I*)
3662                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3663                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3664                         cf_header_path_list="$cf_header_path_list [$]$1"
3665                         ;;
3666                 esac
3667         done
3668 fi
3669
3670 # add the variations for the package we are looking for
3671 CF_SUBDIR_PATH($1,$2,include)
3672
3673 test "$includedir" != NONE && \
3674 test "$includedir" != "/usr/include" && \
3675 test -d "$includedir" && {
3676         test -d $includedir &&    $1="[$]$1 $includedir"
3677         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3678 }
3679
3680 test "$oldincludedir" != NONE && \
3681 test "$oldincludedir" != "/usr/include" && \
3682 test -d "$oldincludedir" && {
3683         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3684         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3685 }
3686
3687 $1="[$]$1 $cf_header_path_list"
3688 ])dnl
3689 dnl ---------------------------------------------------------------------------
3690 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
3691 dnl ---------------
3692 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3693 AC_DEFUN([CF_HELP_MESSAGE],
3694 [CF_ACVERSION_CHECK(2.53,[],[
3695 AC_DIVERT_HELP($1)])dnl
3696 ])dnl
3697 dnl ---------------------------------------------------------------------------
3698 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3699 dnl ---------------
3700 dnl Construct the list of include-options according to whether we're building
3701 dnl in the source directory or using '--srcdir=DIR' option.
3702 AC_DEFUN([CF_INCLUDE_DIRS],
3703 [
3704 if test "$srcdir" != "."; then
3705         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3706 fi
3707 CPPFLAGS="-I../include $CPPFLAGS"
3708 if test "$srcdir" != "."; then
3709         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3710 fi
3711 CPPFLAGS="-I. $CPPFLAGS"
3712 AC_SUBST(CPPFLAGS)
3713 ])dnl
3714 dnl ---------------------------------------------------------------------------
3715 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
3716 dnl ---------------
3717 dnl prompt for/fill-in useful install-program options
3718 AC_DEFUN([CF_INSTALL_OPTS],
3719 [
3720 CF_INSTALL_OPT_S
3721 CF_INSTALL_OPT_P
3722 CF_INSTALL_OPT_O
3723 ])dnl
3724 dnl ---------------------------------------------------------------------------
3725 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
3726 dnl ----------------
3727 dnl Almost all "install" programs default to the current user's ownership.
3728 dnl Almost - MINIX is an exception.
3729 AC_DEFUN([CF_INSTALL_OPT_O],
3730 [
3731 AC_MSG_CHECKING(if install needs to be told about ownership)
3732 case `$ac_config_guess` in
3733 (*minix)
3734         with_install_o=yes
3735         ;;
3736 (*)
3737         with_install_o=no
3738         ;;
3739 esac
3740
3741 AC_MSG_RESULT($with_install_o)
3742 if test "x$with_install_o" = xyes
3743 then
3744         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
3745 else
3746         INSTALL_OPT_O=
3747 fi
3748
3749 AC_SUBST(INSTALL_OPT_O)
3750 ])dnl
3751 dnl ---------------------------------------------------------------------------
3752 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
3753 dnl ----------------
3754 dnl Some install-programs accept a "-p" option to preserve file modification
3755 dnl timestamps.  That can be useful as an install option, as well as a way to
3756 dnl avoid the need for ranlib after copying a static archive.
3757 AC_DEFUN([CF_INSTALL_OPT_P],
3758 [
3759 : ${INSTALL:=install}
3760 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
3761         rm -rf conftest*
3762         date >conftest.in
3763         mkdir conftest.out
3764         sleep 3
3765         if $INSTALL -p conftest.in conftest.out 2>/dev/null
3766         then
3767                 if test -f conftest.out/conftest.in
3768                 then
3769                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
3770                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
3771                         if test -s conftest.err
3772                         then
3773                                 cf_cv_install_p=no
3774                         else
3775                                 cf_cv_install_p=yes
3776                         fi
3777                 else
3778                         cf_cv_install_p=no
3779                 fi
3780         else
3781                 cf_cv_install_p=no
3782         fi
3783         rm -rf conftest*
3784 ])
3785 ])dnl
3786 dnl ---------------------------------------------------------------------------
3787 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
3788 dnl ----------------
3789 dnl By default, we should strip executables which are installed, but leave the
3790 dnl ability to suppress that for unit-testing.
3791 AC_DEFUN([CF_INSTALL_OPT_S],
3792 [
3793 AC_MSG_CHECKING(if you want to install stripped executables)
3794 CF_ARG_DISABLE(stripping,
3795         [  --disable-stripping     do not strip (debug info) installed executables],
3796         [with_stripping=no],
3797         [with_stripping=yes])
3798 AC_MSG_RESULT($with_stripping)
3799
3800 if test "$with_stripping" = yes
3801 then
3802         INSTALL_OPT_S="-s"
3803 else
3804         INSTALL_OPT_S=
3805 fi
3806 AC_SUBST(INSTALL_OPT_S)
3807 ])dnl
3808 dnl ---------------------------------------------------------------------------
3809 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3810 dnl -----------------
3811 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3812 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3813 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3814 dnl
3815 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3816 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3817 dnl the wrappers for gcc and g++ warnings.
3818 dnl
3819 dnl $1 = GCC (default) or GXX
3820 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3821 dnl $3 = CFLAGS (default) or CXXFLAGS
3822 AC_DEFUN([CF_INTEL_COMPILER],[
3823 AC_REQUIRE([AC_CANONICAL_HOST])
3824 ifelse([$2],,INTEL_COMPILER,[$2])=no
3825
3826 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3827         case $host_os in
3828         (linux*|gnu*)
3829                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3830                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3831                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3832                 AC_TRY_COMPILE([],[
3833 #ifdef __INTEL_COMPILER
3834 #else
3835 make an error
3836 #endif
3837 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3838 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3839 ],[])
3840                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3841                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3842                 ;;
3843         esac
3844 fi
3845 ])dnl
3846 dnl ---------------------------------------------------------------------------
3847 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3848 dnl ----------
3849 dnl Check if we have either a function or macro for 'isascii()'.
3850 AC_DEFUN([CF_ISASCII],
3851 [
3852 AC_MSG_CHECKING(for isascii)
3853 AC_CACHE_VAL(cf_cv_have_isascii,[
3854         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3855         [cf_cv_have_isascii=yes],
3856         [cf_cv_have_isascii=no])
3857 ])dnl
3858 AC_MSG_RESULT($cf_cv_have_isascii)
3859 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3860 ])dnl
3861 dnl ---------------------------------------------------------------------------
3862 dnl CF_LARGEFILE version: 12 updated: 2020/03/19 20:23:48
3863 dnl ------------
3864 dnl Add checks for large file support.
3865 AC_DEFUN([CF_LARGEFILE],[
3866 ifdef([AC_FUNC_FSEEKO],[
3867         AC_SYS_LARGEFILE
3868         if test "$enable_largefile" != no ; then
3869         AC_FUNC_FSEEKO
3870
3871         # Normally we would collect these definitions in the config.h,
3872         # but (like _XOPEN_SOURCE), some environments rely on having these
3873         # defined before any of the system headers are included.  Another
3874         # case comes up with C++, e.g., on AIX the compiler compiles the
3875         # header files by themselves before looking at the body files it is
3876         # told to compile.  For ncurses, those header files do not include
3877         # the config.h
3878         if test "$ac_cv_sys_large_files" != no
3879         then
3880                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
3881         fi
3882         if test "$ac_cv_sys_largefile_source" != no
3883         then
3884                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
3885         fi
3886         if test "$ac_cv_sys_file_offset_bits" != no
3887         then
3888                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
3889         fi
3890
3891         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3892                 AC_TRY_COMPILE([
3893 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
3894 #include <sys/types.h>
3895 #include <dirent.h>
3896                 ],[
3897                 /* if transitional largefile support is setup, this is true */
3898                 extern struct dirent64 * readdir(DIR *);
3899                 struct dirent64 *x = readdir((DIR *)0);
3900                 struct dirent *y = readdir((DIR *)0);
3901                 int z = x - y;
3902                 (void)z;
3903                 ],
3904                 [cf_cv_struct_dirent64=yes],
3905                 [cf_cv_struct_dirent64=no])
3906         ])
3907         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3908         fi
3909 ])
3910 ])
3911 dnl ---------------------------------------------------------------------------
3912 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3913 dnl -----------------
3914 dnl Check for compiler/linker flags used to temporarily force usage of static
3915 dnl libraries.  This depends on the compiler and platform.  Use this to help
3916 dnl ensure that the linker picks up a given library based on its position in
3917 dnl the list of linker options and libraries.
3918 AC_DEFUN([CF_LDFLAGS_STATIC],[
3919
3920 if test "$GCC" = yes ; then
3921         case $cf_cv_system_name in
3922         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3923                 LDFLAGS_STATIC=
3924                 LDFLAGS_SHARED=
3925                 ;;
3926         (*)     # normally, except when broken
3927                 LDFLAGS_STATIC=-static
3928                 LDFLAGS_SHARED=-dynamic
3929                 ;;
3930         esac
3931 else
3932         case $cf_cv_system_name in
3933         (aix[[4-7]]*)   # from ld manpage
3934                 LDFLAGS_STATIC=-bstatic
3935                 LDFLAGS_SHARED=-bdynamic
3936                 ;;
3937         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3938                 # We could also use just "archive" and "shared".
3939                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3940                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3941                 ;;
3942         (irix*)         # from ld manpage IRIX64
3943                 LDFLAGS_STATIC=-Bstatic
3944                 LDFLAGS_SHARED=-Bdynamic
3945                 ;;
3946         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3947                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3948                 LDFLAGS_STATIC=-noso
3949                 LDFLAGS_SHARED=-so_archive
3950                 ;;
3951         (solaris2*)
3952                 LDFLAGS_STATIC=-Bstatic
3953                 LDFLAGS_SHARED=-Bdynamic
3954                 ;;
3955         esac
3956 fi
3957
3958 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3959 then
3960         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3961
3962         rm -f libconftest.a
3963         cat >conftest.$ac_ext <<EOF
3964 #line __oline__ "configure"
3965 #include <stdio.h>
3966 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3967 EOF
3968         if AC_TRY_EVAL(ac_compile) ; then
3969                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3970                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3971         fi
3972         rm -f conftest.*
3973
3974         cf_save_LIBS="$LIBS"
3975
3976         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3977         AC_TRY_LINK([
3978 #line __oline__ "configure"
3979 #include <stdio.h>
3980 int cf_ldflags_static(FILE *fp);
3981 ],[
3982         return cf_ldflags_static(stdin);
3983 ],[
3984         # some linkers simply ignore the -dynamic
3985         case x`file conftest$ac_exeext 2>/dev/null` in
3986         (*static*)
3987                 cf_ldflags_static=no
3988                 ;;
3989         (*)
3990                 cf_ldflags_static=yes
3991                 ;;
3992         esac
3993 ],[cf_ldflags_static=no])
3994
3995         rm -f libconftest.*
3996         LIBS="$cf_save_LIBS"
3997
3998         AC_MSG_RESULT($cf_ldflags_static)
3999
4000         if test $cf_ldflags_static != yes
4001         then
4002                 LDFLAGS_STATIC=
4003                 LDFLAGS_SHARED=
4004         fi
4005 else
4006         LDFLAGS_STATIC=
4007         LDFLAGS_SHARED=
4008 fi
4009
4010 AC_SUBST(LDFLAGS_STATIC)
4011 AC_SUBST(LDFLAGS_SHARED)
4012 ])
4013 dnl ---------------------------------------------------------------------------
4014 dnl CF_LD_RPATH_OPT version: 8 updated: 2018/08/18 16:36:35
4015 dnl ---------------
4016 dnl For the given system and compiler, find the compiler flags to pass to the
4017 dnl loader to use the "rpath" feature.
4018 AC_DEFUN([CF_LD_RPATH_OPT],
4019 [
4020 AC_REQUIRE([CF_CHECK_CACHE])
4021
4022 LD_RPATH_OPT=
4023 if test "x$cf_cv_enable_rpath" != xno
4024 then
4025         AC_MSG_CHECKING(for an rpath option)
4026         case $cf_cv_system_name in
4027         (irix*)
4028                 if test "$GCC" = yes; then
4029                         LD_RPATH_OPT="-Wl,-rpath,"
4030                 else
4031                         LD_RPATH_OPT="-rpath "
4032                 fi
4033                 ;;
4034         (linux*|gnu*|k*bsd*-gnu|freebsd*)
4035                 LD_RPATH_OPT="-Wl,-rpath,"
4036                 ;;
4037         (openbsd[[2-9]].*|mirbsd*)
4038                 LD_RPATH_OPT="-Wl,-rpath,"
4039                 ;;
4040         (dragonfly*)
4041                 LD_RPATH_OPT="-rpath "
4042                 ;;
4043         (netbsd*)
4044                 LD_RPATH_OPT="-Wl,-rpath,"
4045                 ;;
4046         (osf*|mls+*)
4047                 LD_RPATH_OPT="-rpath "
4048                 ;;
4049         (solaris2*)
4050                 LD_RPATH_OPT="-R"
4051                 ;;
4052         (*)
4053                 ;;
4054         esac
4055         AC_MSG_RESULT($LD_RPATH_OPT)
4056
4057         case "x$LD_RPATH_OPT" in
4058         (x-R*)
4059                 AC_MSG_CHECKING(if we need a space after rpath option)
4060                 cf_save_LIBS="$LIBS"
4061                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
4062                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
4063                 LIBS="$cf_save_LIBS"
4064                 AC_MSG_RESULT($cf_rpath_space)
4065                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
4066                 ;;
4067         esac
4068 fi
4069 ])dnl
4070 dnl ---------------------------------------------------------------------------
4071 dnl CF_LD_SEARCHPATH version: 2 updated: 2019/09/26 20:34:14
4072 dnl ----------------
4073 dnl Try to obtain the linker's search-path, for use in scripts.
4074 dnl
4075 dnl Ignore LD_LIBRARY_PATH, etc.
4076 AC_DEFUN([CF_LD_SEARCHPATH],[
4077 AC_CACHE_CHECK(for linker search path,cf_cv_ld_searchpath,[
4078
4079 if test "$cross_compiling" != yes ; then
4080
4081 # GNU binutils' ld does not involve permissions which may stop ldconfig.
4082 cf_pathlist=`ld --verbose 2>/dev/null | grep SEARCH_DIR | sed -e 's,SEARCH_DIR[[("=]][[("=]]*,,g' -e 's/"[[)]];//gp' | sort -u`
4083
4084 # The -NX options tell newer versions of Linux ldconfig to not attempt to
4085 # update the cache, which makes it run faster.
4086 test -z "$cf_pathlist" && \
4087         cf_pathlist=`ldconfig -NX -v 2>/dev/null | sed -e '/^[[         ]]/d' -e 's/:$//' | sort -u`
4088
4089 test -z "$cf_pathlist" &&
4090         cf_pathlist=`ldconfig -v 2>/dev/null | sed -n -e '/^[[  ]]/d' -e 's/:$//p' | sort -u`
4091
4092 # This works with OpenBSD 6.5, which lists only filenames
4093 test -z "$cf_pathlist" &&
4094         cf_pathlist=`ldconfig -v 2>/dev/null | sed -n -e 's,^Adding \(.*\)/.*[$],\1,p' | sort -u`
4095
4096 if test -z "$cf_pathlist"
4097 then
4098         # dyld default path with MacOS
4099         if test -f /usr/bin/otool && test "x`uname -s`" = xDarwin
4100         then
4101                 # do this to bypass check
4102                 cf_cv_ld_searchpath='$HOME/lib'
4103                 cf_pathlist="/usr/local/lib /lib /usr/lib"
4104         fi
4105 fi
4106
4107 if test -z "$cf_pathlist"
4108 then
4109         # Solaris is hardcoded
4110         if test -d /opt/SUNWspro/lib
4111         then
4112                 cf_pathlist="/opt/SUNWspro/lib /usr/ccs/lib /usr/lib"
4113         elif test -d /usr/ccs/lib
4114         then
4115                 cf_pathlist="/usr/ccs/lib /usr/lib"
4116         fi
4117 fi
4118
4119 fi
4120
4121 # If nothing else, assume it is conventional
4122 test -z "$cf_pathlist" && cf_pathlist="/usr/lib /lib"
4123
4124 # Finally, check that this is only directories
4125 for cf_path in [$]0 $cf_pathlist
4126 do
4127         if test -d "$cf_path"; then
4128                 test -n "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath="${cf_cv_ld_searchpath} "
4129                 cf_cv_ld_searchpath="${cf_cv_ld_searchpath}${cf_path}"
4130         fi
4131 done
4132
4133 # Ensure that it is nonempty
4134 test -z "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath=/usr/lib
4135 ])
4136
4137 LD_SEARCHPATH=`echo "$cf_cv_ld_searchpath"|sed -e 's/ /|/g'`
4138 AC_SUBST(LD_SEARCHPATH)
4139 ])dnl
4140 dnl ---------------------------------------------------------------------------
4141 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
4142 dnl ---------------
4143 dnl Construct a search-list of directories for a nonstandard library-file
4144 dnl
4145 dnl Parameters
4146 dnl     $1 = the variable to return as result
4147 dnl     $2 = the package name
4148 AC_DEFUN([CF_LIBRARY_PATH],
4149 [
4150 $1=
4151 cf_library_path_list=""
4152 if test -n "${LDFLAGS}${LIBS}" ; then
4153         for cf_library_path in $LDFLAGS $LIBS
4154         do
4155                 case $cf_library_path in
4156                 (-L*)
4157                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
4158                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
4159                         cf_library_path_list="$cf_library_path_list [$]$1"
4160                         ;;
4161                 esac
4162         done
4163 fi
4164
4165 CF_SUBDIR_PATH($1,$2,lib)
4166
4167 $1="$cf_library_path_list [$]$1"
4168 ])dnl
4169 dnl ---------------------------------------------------------------------------
4170 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
4171 dnl ------------------
4172 AC_DEFUN([CF_LIBTOOL_VERSION],[
4173 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
4174 then
4175         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
4176 else
4177         cf_cv_libtool_version=
4178 fi
4179 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
4180 ])dnl
4181 dnl ---------------------------------------------------------------------------
4182 dnl CF_LIB_PREFIX version: 13 updated: 2020/04/04 10:11:47
4183 dnl -------------
4184 dnl Compute the library-prefix for the given host system
4185 dnl $1 = variable to set
4186 define([CF_LIB_PREFIX],
4187 [
4188         case $cf_cv_system_name in
4189         (OS/2*|os2*)
4190                 if test "$DFT_LWR_MODEL" = libtool; then
4191                         LIB_PREFIX='lib'
4192                 else
4193                         LIB_PREFIX=''
4194                 fi
4195                 ;;
4196         (*-msvc*)
4197                 LIB_PREFIX=''
4198                 ;;
4199         (*)     LIB_PREFIX='lib'
4200                 ;;
4201         esac
4202 ifelse($1,,,[$1=$LIB_PREFIX])
4203         AC_SUBST(LIB_PREFIX)
4204 ])dnl
4205 dnl ---------------------------------------------------------------------------
4206 dnl CF_LIB_RULES version: 90 updated: 2020/04/04 10:11:47
4207 dnl ------------
4208 dnl Append definitions and rules for the given models to the subdirectory
4209 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
4210 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
4211 dnl the corresponding makefile to list the models that we'll generate.
4212 dnl
4213 dnl For shared libraries, make a list of symbolic links to construct when
4214 dnl generating each library.  The convention used for Linux is the simplest
4215 dnl one:
4216 dnl     lib<name>.so    ->
4217 dnl     lib<name>.so.<major>    ->
4218 dnl     lib<name>.so.<maj>.<minor>
4219 dnl
4220 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
4221 AC_DEFUN([CF_LIB_RULES],
4222 [
4223 cf_prefix=$LIB_PREFIX
4224 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
4225
4226 case $cf_cv_shlib_version in
4227 (cygdll|msysdll|mingw|msvcdll)
4228         TINFO_NAME=$TINFO_ARG_SUFFIX
4229         TINFO_SUFFIX=.dll
4230         ;;
4231 esac
4232
4233 if test -n "$TINFO_SUFFIX" ; then
4234         case $TINFO_SUFFIX in
4235         (tw*)
4236                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
4237                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
4238                 ;;
4239         (t*)
4240                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
4241                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
4242                 ;;
4243         (w*)
4244                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
4245                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
4246                 ;;
4247         esac
4248 fi
4249
4250 for cf_dir in $SRC_SUBDIRS
4251 do
4252         if test ! -d $srcdir/$cf_dir ; then
4253                 continue
4254         elif test -f $srcdir/$cf_dir/modules; then
4255
4256                 SHARED_LIB=
4257                 Libs_To_Make=
4258                 cf_awk_program=
4259                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
4260                 then
4261                         cf_awk_program="$cf_awk_program\
4262 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
4263 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
4264 "
4265                 fi
4266
4267                 if test "x$WILDCARD_SYMS" = xno
4268                 then
4269                         cf_awk_program="$cf_awk_program\
4270 /[[     ]]_\\*;/ { skip=1; next; }\
4271 "
4272                 fi
4273
4274                 if test "x$cf_awk_program" != "x"
4275                 then
4276                         cat >>$cf_dir/Makefile <<CF_EOF
4277
4278 # Generated by CF_LIB_RULES
4279 resulting.map: $UNALTERED_SYMS
4280         $AWK 'BEGIN { skip = 1; last=""; } \
4281 $cf_awk_program \
4282 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
4283  skip = 0; last = \[$]\[$]0; } \
4284 END { print last; }' < $UNALTERED_SYMS >\[$]@
4285
4286 distclean::
4287         rm -f resulting.map
4288 CF_EOF
4289                 fi
4290
4291                 for cf_item in $cf_LIST_MODELS
4292                 do
4293                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4294                         if test "$cf_dir" = "c++"
4295                         then
4296                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4297                         else
4298                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4299                         fi
4300                         test -z "$cf_libname" && cf_libname="$cf_dir"
4301                         if test $cf_item = shared ; then
4302                                 if test -n "${LIB_SUFFIX}"
4303                                 then
4304                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4305                                 else
4306                                         cf_shared_suffix="$cf_suffix"
4307                                 fi
4308                                 if test "$cf_cv_do_symlinks" = yes ; then
4309                                         cf_version_name=
4310
4311                                         case "$cf_cv_shlib_version" in
4312                                         (rel)
4313                                                 cf_version_name=REL_VERSION
4314                                                 ;;
4315                                         (abi)
4316                                                 cf_version_name=ABI_VERSION
4317                                                 ;;
4318                                         esac
4319
4320                                         if test -n "$cf_version_name"
4321                                         then
4322                                                 case "$cf_cv_system_name" in
4323                                                 (darwin*)
4324                                                         # "w", etc?
4325                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
4326                                                         ;;
4327                                                 (*)
4328                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
4329                                                         ;;
4330                                                 esac
4331                                         fi
4332                                         if test -n "${USE_LIB_SUFFIX}"
4333                                         then
4334                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4335                                         else
4336                                                 cf_shared_suffix="$cf_suffix"
4337                                         fi
4338                                 fi
4339                                 # cygwin needs import library, and has unique naming convention
4340                                 # use autodetected ${cf_prefix} for import lib and static lib, but
4341                                 # use 'cyg' prefix for shared lib.
4342                                 case $cf_cv_shlib_version in
4343                                 (cygdll)
4344                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4345                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
4346                                         ;;
4347                                 (msysdll)
4348                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4349                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
4350                                         ;;
4351                                 (mingw)
4352                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4353                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
4354                                         ;;
4355                                 (msvcdll)
4356                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4357                                         cf_add_lib="../lib/${cf_libname}${cf_cygsuf}"
4358                                         ;;
4359                                 (*)
4360                                         cf_add_lib=
4361                                         ;;
4362                                 esac
4363                                 if test -n "$cf_add_lib"
4364                                 then
4365                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4366                                         continue
4367                                 fi
4368                         fi
4369                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
4370                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4371                 done
4372
4373                 if test $cf_dir = ncurses ; then
4374                         cf_subsets="$LIB_SUBSETS"
4375                         cf_r_parts="$cf_subsets"
4376                         cf_liblist="$Libs_To_Make"
4377
4378                         while test -n "$cf_r_parts"
4379                         do
4380                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
4381                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
4382                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
4383                                         cf_add_lib=
4384                                         case $cf_l_parts in
4385                                         (*termlib*)
4386                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
4387                                                 ;;
4388                                         (*ticlib*)
4389                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
4390                                                 ;;
4391                                         (*)
4392                                                 break
4393                                                 ;;
4394                                         esac
4395                                         if test -n "$cf_add_lib"; then
4396                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
4397                                         fi
4398                                 else
4399                                         break
4400                                 fi
4401                         done
4402                 else
4403                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
4404                 fi
4405
4406                 if test $cf_dir = c++; then
4407                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
4408                                 cf_list=
4409                                 for cf_item in $Libs_To_Make
4410                                 do
4411                                         case $cf_item in
4412                                         (*.a)
4413                                                 ;;
4414                                         (*)
4415                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
4416                                                 ;;
4417                                         esac
4418                                         for cf_test in $cf_list
4419                                         do
4420                                                 if test "$cf_test" = "$cf_item"
4421                                                 then
4422                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
4423                                                         cf_item=
4424                                                         break
4425                                                 fi
4426                                         done
4427                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
4428                                 done
4429                                 Libs_To_Make="$cf_list"
4430                         fi
4431                 fi
4432
4433                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
4434                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
4435                         $cf_dir/Makefile >$cf_dir/Makefile.out
4436                 mv $cf_dir/Makefile.out $cf_dir/Makefile
4437
4438                 $AWK -f $srcdir/mk-0th.awk \
4439                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
4440                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4441
4442                 for cf_subset in $cf_subsets
4443                 do
4444                         cf_subdirs=
4445                         for cf_item in $cf_LIST_MODELS
4446                         do
4447
4448                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
4449                         CF_UPPER(cf_ITEM,$cf_item)
4450
4451                         CXX_MODEL=$cf_ITEM
4452                         if test "$CXX_MODEL" = SHARED; then
4453                                 case $cf_cv_shlib_version in
4454                                 (cygdll|msysdll|mingw|msvcdll)
4455                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
4456                                         with_shared_cxx=yes
4457                                         ;;
4458                                 (*)
4459                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
4460                                         ;;
4461                                 esac
4462                         fi
4463
4464                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4465                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
4466
4467                         # Test for case where we build libtinfo with a different name.
4468                         cf_libname=$cf_dir
4469                         if test $cf_dir = ncurses ; then
4470                                 case $cf_subset in
4471                                 (*base*)
4472                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
4473                                         ;;
4474                                 (*termlib*)
4475                                         cf_libname=$TINFO_LIB_SUFFIX
4476                                         ;;
4477                                 (ticlib*)
4478                                         cf_libname=$TICS_LIB_SUFFIX
4479                                         ;;
4480                                 esac
4481                         elif test $cf_dir = c++ ; then
4482                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4483                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4484                         else
4485                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4486                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4487                         fi
4488                         if test -n "${USE_ARG_SUFFIX}" ; then
4489                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
4490                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
4491                         fi
4492
4493                         # These dependencies really are for development, not
4494                         # builds, but they are useful in porting, too.
4495                         cf_depend="../include/ncurses_cfg.h"
4496                         if test "$srcdir" = "."; then
4497                                 cf_reldir="."
4498                         else
4499                                 cf_reldir="\${srcdir}"
4500                         fi
4501
4502                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
4503                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
4504                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
4505                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
4506                         fi
4507
4508                         cf_dir_suffix=
4509                         old_cf_suffix="$cf_suffix"
4510                         if test "$cf_cv_shlib_version_infix" = yes ; then
4511                         if test -n "$USE_LIB_SUFFIX" ; then
4512                                 case $USE_LIB_SUFFIX in
4513                                 (tw*)
4514                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
4515                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
4516                                         cf_dir_suffix=tw$EXTRA_SUFFIX
4517                                         ;;
4518                                 (t*)
4519                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
4520                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
4521                                         cf_dir_suffix=t$EXTRA_SUFFIX
4522                                         ;;
4523                                 (w*)
4524                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
4525                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
4526                                         cf_dir_suffix=w$EXTRA_SUFFIX
4527                                         ;;
4528                                 (*)
4529                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
4530                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
4531                                         cf_dir_suffix=$EXTRA_SUFFIX
4532                                         ;;
4533                                 esac
4534                         fi
4535                         fi
4536
4537                         $AWK -f $srcdir/mk-1st.awk \
4538                                 name=${cf_libname}${cf_dir_suffix} \
4539                                 traces=$LIB_TRACING \
4540                                 MODEL=$cf_ITEM \
4541                                 CXX_MODEL=$CXX_MODEL \
4542                                 model=$cf_subdir \
4543                                 prefix=$cf_prefix \
4544                                 suffix=$cf_suffix \
4545                                 subset=$cf_subset \
4546                                 driver=$cf_cv_term_driver \
4547                                 SymLink="$LN_S" \
4548                                 TermlibRoot=$TINFO_NAME \
4549                                 TermlibSuffix=$TINFO_SUFFIX \
4550                                 ShlibVer=$cf_cv_shlib_version \
4551                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
4552                                 ReLink=${cf_cv_do_relink:-no} \
4553                                 ReRanlib=${cf_cv_do_reranlib:-yes} \
4554                                 DoLinks=$cf_cv_do_symlinks \
4555                                 rmSoLocs=$cf_cv_rm_so_locs \
4556                                 ldconfig="$LDCONFIG" \
4557                                 overwrite=$WITH_OVERWRITE \
4558                                 depend="$cf_depend" \
4559                                 host="$host" \
4560                                 libtool_version="$LIBTOOL_VERSION" \
4561                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4562
4563                         cf_suffix="$old_cf_suffix"
4564
4565                         for cf_subdir2 in $cf_subdirs lib
4566                         do
4567                                 test $cf_subdir = $cf_subdir2 && break
4568                         done
4569                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
4570                         $AWK -f $srcdir/mk-2nd.awk \
4571                                 name=$cf_dir \
4572                                 traces=$LIB_TRACING \
4573                                 MODEL=$cf_ITEM \
4574                                 model=$cf_subdir \
4575                                 subset=$cf_subset \
4576                                 srcdir=$srcdir \
4577                                 echo=$WITH_ECHO \
4578                                 crenames=$cf_cv_prog_CC_c_o \
4579                                 cxxrenames=$cf_cv_prog_CXX_c_o \
4580                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4581                         cf_subdirs="$cf_subdirs $cf_subdir"
4582                         done
4583                 done
4584         fi
4585
4586         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
4587 done
4588
4589 for cf_dir in $SRC_SUBDIRS
4590 do
4591         if test ! -d $srcdir/$cf_dir ; then
4592                 continue
4593         fi
4594
4595         if test -f $cf_dir/Makefile ; then
4596                 case "$cf_dir" in
4597                 (Ada95)
4598                         echo 'libs \' >> Makefile
4599                         echo 'install.libs \' >> Makefile
4600                         echo 'uninstall.libs ::' >> Makefile
4601                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
4602                         ;;
4603                 esac
4604         fi
4605
4606         if test -f $srcdir/$cf_dir/modules; then
4607                 echo >> Makefile
4608                 if test -f $srcdir/$cf_dir/headers; then
4609 cat >> Makefile <<CF_EOF
4610 install.includes \\
4611 uninstall.includes \\
4612 CF_EOF
4613                 fi
4614 if test "$cf_dir" != "c++" ; then
4615 echo 'lint \' >> Makefile
4616 fi
4617 cat >> Makefile <<CF_EOF
4618 libs \\
4619 lintlib \\
4620 install.libs \\
4621 uninstall.libs \\
4622 install.$cf_dir \\
4623 uninstall.$cf_dir ::
4624         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4625 CF_EOF
4626         elif test -f $srcdir/$cf_dir/headers; then
4627 cat >> Makefile <<CF_EOF
4628
4629 libs \\
4630 install.libs \\
4631 uninstall.libs \\
4632 install.includes \\
4633 uninstall.includes ::
4634         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4635 CF_EOF
4636 fi
4637 done
4638
4639 if test "x$cf_with_db_install" = xyes; then
4640 cat >> Makefile <<CF_EOF
4641
4642 install.libs uninstall.libs \\
4643 install.data uninstall.data ::
4644 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4645 CF_EOF
4646 else
4647 cat >> Makefile <<CF_EOF
4648
4649 install.libs uninstall.libs ::
4650         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4651 CF_EOF
4652 fi
4653
4654 if test "x$cf_with_manpages" = xyes; then
4655 cat >> Makefile <<CF_EOF
4656
4657 install.man \\
4658 uninstall.man ::
4659         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
4660 CF_EOF
4661 fi
4662
4663 cat >> Makefile <<CF_EOF
4664
4665 distclean ::
4666         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
4667         rm -f headers.sh headers.sed mk_shared_lib.sh
4668         rm -f edit_man.* man_alias.*
4669         rm -rf \${DIRS_TO_MAKE}
4670 CF_EOF
4671
4672 # Special case: tack's manpage lives in its own directory.
4673 if test "x$cf_with_manpages" = xyes; then
4674 if test "x$cf_with_tack" = "xyes"; then
4675 cat >> Makefile <<CF_EOF
4676
4677 install.man \\
4678 uninstall.man ::
4679         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
4680 CF_EOF
4681 fi
4682 fi
4683
4684 dnl If we're installing into a subdirectory of /usr/include, etc., we should
4685 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
4686 dnl anything, and will make it more standardized.  It's awkward to decide this
4687 dnl at configuration because of quoting, so we'll simply make all headers
4688 dnl installed via a script that can do the right thing.
4689
4690 rm -f headers.sed headers.sh
4691
4692 dnl ( generating this script makes the makefiles a little tidier :-)
4693 echo creating headers.sh
4694 cat >headers.sh <<CF_EOF
4695 #! $SHELL
4696 # This shell script is generated by the 'configure' script.  It is invoked in a
4697 # subdirectory of the build tree.  It generates a sed-script in the parent
4698 # directory that is used to adjust includes for header files that reside in a
4699 # subdirectory of /usr/include, etc.
4700 PRG=""
4701 while test \[$]# != 3
4702 do
4703 PRG="\$PRG \[$]1"; shift
4704 done
4705 DST=\[$]1
4706 REF=\[$]2
4707 SRC=\[$]3
4708 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
4709 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
4710 echo installing \$SRC in \$DST
4711 CF_EOF
4712
4713 if test $WITH_CURSES_H = yes; then
4714         cat >>headers.sh <<CF_EOF
4715 case \$DST in
4716 (/*/include/*)
4717         END=\`basename \$DST\`
4718         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4719         do
4720                 NAME=\`basename \$i\`
4721                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4722         done
4723         ;;
4724 (*)
4725         echo "" >> \$TMPSED
4726         ;;
4727 esac
4728 CF_EOF
4729
4730 else
4731         cat >>headers.sh <<CF_EOF
4732 case \$DST in
4733 (/*/include/*)
4734         END=\`basename \$DST\`
4735         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4736         do
4737                 NAME=\`basename \$i\`
4738                 if test "\$NAME" = "curses.h"
4739                 then
4740                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4741                         NAME=ncurses.h
4742                 fi
4743                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4744         done
4745         ;;
4746 (*)
4747         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4748         ;;
4749 esac
4750 CF_EOF
4751 fi
4752 cat >>headers.sh <<CF_EOF
4753 rm -f \$TMPSRC
4754 sed -f \$TMPSED \$SRC > \$TMPSRC
4755 NAME=\`basename \$SRC\`
4756 CF_EOF
4757 if test $WITH_CURSES_H != yes; then
4758         cat >>headers.sh <<CF_EOF
4759 test "\$NAME" = "curses.h" && NAME=ncurses.h
4760 CF_EOF
4761 fi
4762 cat >>headers.sh <<CF_EOF
4763 # Just in case someone gzip'd manpages, remove the conflicting copy.
4764 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
4765
4766 eval \$PRG \$TMPSRC \$DST/\$NAME
4767 rm -f \$TMPSRC \$TMPSED
4768 CF_EOF
4769
4770 chmod 0755 headers.sh
4771
4772 for cf_dir in $SRC_SUBDIRS
4773 do
4774         if test ! -d $srcdir/$cf_dir ; then
4775                 continue
4776         fi
4777
4778         if test -f $srcdir/$cf_dir/headers; then
4779                 $AWK -f $srcdir/mk-hdr.awk \
4780                         subset="$LIB_SUBSETS" \
4781                         compat="$WITH_CURSES_H" \
4782                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
4783         fi
4784
4785         if test -f $srcdir/$cf_dir/modules; then
4786                 if test "$cf_dir" != "c++" ; then
4787                         cat >>$cf_dir/Makefile <<"CF_EOF"
4788 depend : ${AUTO_SRC}
4789         makedepend -- ${CPPFLAGS} -- ${C_SRC}
4790
4791 # DO NOT DELETE THIS LINE -- make depend depends on it.
4792 CF_EOF
4793                 fi
4794         fi
4795 done
4796 AC_SUBST(Libs_To_Make)
4797 ])dnl
4798 dnl ---------------------------------------------------------------------------
4799 dnl CF_LIB_SONAME version: 6 updated: 2017/01/21 11:06:25
4800 dnl -------------
4801 dnl Find the and soname for the given shared library.  Set the cache variable
4802 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
4803 dnl variable to "unknown".
4804 dnl
4805 dnl $1 = headers
4806 dnl $2 = code
4807 dnl $3 = library name
4808 AC_DEFUN([CF_LIB_SONAME],
4809 [
4810 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
4811
4812 cf_cv_$3_soname=unknown
4813 if test "$cross_compiling" != yes ; then
4814 cat >conftest.$ac_ext <<CF_EOF
4815 $1
4816 int main(void)
4817 {
4818 $2
4819         ${cf_cv_main_return:-return}(0);
4820 }
4821 CF_EOF
4822 cf_save_LIBS="$LIBS"
4823         CF_ADD_LIB($3)
4824         if AC_TRY_EVAL(ac_compile) ; then
4825                 if AC_TRY_EVAL(ac_link) ; then
4826                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
4827                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4828                 fi
4829         fi
4830 rm -rf conftest*
4831 LIBS="$cf_save_LIBS"
4832 fi
4833 ])
4834 ])
4835 dnl ---------------------------------------------------------------------------
4836 dnl CF_LIB_SUFFIX version: 26 updated: 2020/04/04 10:11:47
4837 dnl -------------
4838 dnl Compute the library file-suffix from the given model name
4839 dnl $1 = model name
4840 dnl $2 = variable to set (the nominal library suffix)
4841 dnl $3 = dependency variable to set (actual filename)
4842 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4843 AC_DEFUN([CF_LIB_SUFFIX],
4844 [
4845         case X$1 in
4846         (Xlibtool)
4847                 $2='.la'
4848                 $3=[$]$2
4849                 ;;
4850         (Xdebug)
4851                 case $cf_cv_system_name in
4852                 (*-msvc*)
4853                         $2='_g.lib'
4854                         ;;
4855                 (*)
4856                         $2='_g.a'
4857                         ;;
4858                 esac
4859                 $3=[$]$2
4860                 ;;
4861         (Xprofile)
4862                 case $cf_cv_system_name in
4863                 (*-msvc*)
4864                         $2='_p.lib'
4865                         ;;
4866                 (*)
4867                         $2='_p.a'
4868                         ;;
4869                 esac
4870                 $3=[$]$2
4871                 ;;
4872         (Xshared)
4873                 case $cf_cv_system_name in
4874                 (aix[[5-7]]*)
4875                         $2='.so'
4876                         $3=[$]$2
4877                         ;;
4878                 (*-msvc*)
4879                         $2='.dll'
4880                         $3='.dll.lib'
4881                         ;;
4882                 (cygwin*|msys*|mingw*)
4883                         $2='.dll'
4884                         $3='.dll.a'
4885                         ;;
4886                 (darwin*)
4887                         $2='.dylib'
4888                         $3=[$]$2
4889                         ;;
4890                 (hpux*)
4891                         case $target in
4892                         (ia64*)
4893                                 $2='.so'
4894                                 $3=[$]$2
4895                                 ;;
4896                         (*)
4897                                 $2='.sl'
4898                                 $3=[$]$2
4899                                 ;;
4900                         esac
4901                         ;;
4902                 (*)
4903                         $2='.so'
4904                         $3=[$]$2
4905                         ;;
4906                 esac
4907                 ;;
4908         (*)
4909                 case $target in
4910                 (*-msvc*)
4911                         $2='.lib'
4912                         ;;
4913                 (*)
4914                         $2='.a'
4915                         ;;
4916                 esac
4917                 $3=[$]$2
4918                 ;;
4919         esac
4920         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
4921         then
4922                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
4923                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
4924         fi
4925 ])dnl
4926 dnl ---------------------------------------------------------------------------
4927 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
4928 dnl -----------
4929 dnl Compute the string to append to -library from the given model name
4930 dnl $1 = model name
4931 dnl $2 = variable to set
4932 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4933 AC_DEFUN([CF_LIB_TYPE],
4934 [
4935         case $1 in
4936         (libtool) $2=''   ;;
4937         (normal)  $2=''   ;;
4938         (debug)   $2='_g' ;;
4939         (profile) $2='_p' ;;
4940         (shared)  $2=''   ;;
4941         esac
4942         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
4943 ])dnl
4944 dnl ---------------------------------------------------------------------------
4945 dnl CF_LINK_DATAONLY version: 13 updated: 2020/02/08 15:59:30
4946 dnl ----------------
4947 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
4948 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
4949 dnl have to provide wrappers for global tables to ensure they're linked
4950 dnl properly.
4951 AC_DEFUN([CF_LINK_DATAONLY],
4952 [
4953 AC_MSG_CHECKING([if data-only library module links])
4954 AC_CACHE_VAL(cf_cv_link_dataonly,[
4955         rm -f conftest.a
4956         cat >conftest.$ac_ext <<EOF
4957 #line __oline__ "configure"
4958 int     testdata[[3]] = { 123, 456, 789 };
4959 EOF
4960         if AC_TRY_EVAL(ac_compile) ; then
4961                 mv conftest.o data.o && \
4962                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
4963         fi
4964         rm -f conftest.$ac_ext data.o
4965         cat >conftest.$ac_ext <<EOF
4966 #line __oline__ "configure"
4967 int     testfunc(void)
4968 {
4969 #if defined(NeXT)
4970         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
4971 #else
4972         extern int testdata[[3]];
4973         return testdata[[0]] == 123
4974            &&  testdata[[1]] == 456
4975            &&  testdata[[2]] == 789;
4976 #endif
4977 }
4978 EOF
4979         if AC_TRY_EVAL(ac_compile); then
4980                 mv conftest.o func.o && \
4981                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
4982         fi
4983         rm -f conftest.$ac_ext func.o
4984         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
4985         cf_saveLIBS="$LIBS"
4986         LIBS="conftest.a $LIBS"
4987         AC_TRY_RUN([
4988         int main(void)
4989         {
4990                 extern int testfunc();
4991                 ${cf_cv_main_return:-return} (!testfunc());
4992         }
4993         ],
4994         [cf_cv_link_dataonly=yes],
4995         [cf_cv_link_dataonly=no],
4996         [cf_cv_link_dataonly=unknown])
4997         LIBS="$cf_saveLIBS"
4998         ])
4999 AC_MSG_RESULT($cf_cv_link_dataonly)
5000
5001 if test "$cf_cv_link_dataonly" = no ; then
5002         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
5003         BROKEN_LINKER=1
5004 fi
5005 AC_SUBST(BROKEN_LINKER)
5006
5007 ])dnl
5008 dnl ---------------------------------------------------------------------------
5009 dnl CF_LINK_FUNCS version: 9 updated: 2017/01/21 11:11:02
5010 dnl -------------
5011 dnl Most Unix systems have both link and symlink, a few don't have symlink.
5012 dnl A few non-Unix systems implement symlink, but not link.
5013 dnl A few non-systems implement neither (or have nonfunctional versions).
5014 AC_DEFUN([CF_LINK_FUNCS],
5015 [
5016 AC_CHECK_HEADERS( \
5017 unistd.h \
5018 )
5019 AC_CHECK_FUNCS( \
5020         remove \
5021         unlink )
5022
5023 if test "$cross_compiling" = yes ; then
5024         AC_CHECK_FUNCS( \
5025                 link \
5026                 symlink )
5027 else
5028         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
5029                 cf_cv_link_funcs=
5030                 for cf_func in link symlink ; do
5031                         AC_TRY_RUN([
5032 #include <sys/types.h>
5033 #include <sys/stat.h>
5034 #ifdef HAVE_UNISTD_H
5035 #include <unistd.h>
5036 #endif
5037 int main(void)
5038 {
5039         int fail = 0;
5040         char *src = "config.log";
5041         char *dst = "conftest.chk";
5042         struct stat src_sb;
5043         struct stat dst_sb;
5044
5045         stat(src, &src_sb);
5046         fail = ($cf_func("config.log", "conftest.chk") < 0)
5047             || (stat(dst, &dst_sb) < 0)
5048             || (dst_sb.st_mtime != src_sb.st_mtime);
5049 #ifdef HAVE_UNLINK
5050         unlink(dst);
5051 #else
5052         remove(dst);
5053 #endif
5054         ${cf_cv_main_return:-return} (fail);
5055 }
5056                         ],[
5057                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
5058                         eval 'ac_cv_func_'$cf_func'=yes'],[
5059                         eval 'ac_cv_func_'$cf_func'=no'],[
5060                         eval 'ac_cv_func_'$cf_func'=error'])
5061                 done
5062                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
5063         ])
5064         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
5065         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
5066 fi
5067 ])dnl
5068 dnl ---------------------------------------------------------------------------
5069 dnl CF_MAKEFLAGS version: 18 updated: 2018/02/21 21:26:03
5070 dnl ------------
5071 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
5072 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
5073 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
5074 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
5075 AC_DEFUN([CF_MAKEFLAGS],
5076 [
5077 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
5078         cf_cv_makeflags=''
5079         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
5080         do
5081                 cat >cf_makeflags.tmp <<CF_EOF
5082 SHELL = $SHELL
5083 all :
5084         @ echo '.$cf_option'
5085 CF_EOF
5086                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
5087                 case "$cf_result" in
5088                 (.*k|.*kw)
5089                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
5090                         case "$cf_result" in
5091                         (.*CC=*)        cf_cv_makeflags=
5092                                 ;;
5093                         (*)     cf_cv_makeflags=$cf_option
5094                                 ;;
5095                         esac
5096                         break
5097                         ;;
5098                 (.-)
5099                         ;;
5100                 (*)
5101                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
5102                         ;;
5103                 esac
5104         done
5105         rm -f cf_makeflags.tmp
5106 ])
5107
5108 AC_SUBST(cf_cv_makeflags)
5109 ])dnl
5110 dnl ---------------------------------------------------------------------------
5111 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
5112 dnl ------------
5113 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
5114 dnl a monocase filesystem.
5115 AC_DEFUN([CF_MAKE_TAGS],[
5116 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
5117
5118 AC_CHECK_PROGS(CTAGS, exctags ctags)
5119 AC_CHECK_PROGS(ETAGS, exetags etags)
5120
5121 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
5122
5123 if test "$cf_cv_mixedcase" = yes ; then
5124         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
5125 else
5126         MAKE_UPPER_TAGS=no
5127 fi
5128
5129 if test "$MAKE_UPPER_TAGS" = yes ; then
5130         MAKE_UPPER_TAGS=
5131 else
5132         MAKE_UPPER_TAGS="#"
5133 fi
5134
5135 if test "$MAKE_LOWER_TAGS" = yes ; then
5136         MAKE_LOWER_TAGS=
5137 else
5138         MAKE_LOWER_TAGS="#"
5139 fi
5140
5141 AC_SUBST(CTAGS)
5142 AC_SUBST(ETAGS)
5143
5144 AC_SUBST(MAKE_UPPER_TAGS)
5145 AC_SUBST(MAKE_LOWER_TAGS)
5146 ])dnl
5147 dnl ---------------------------------------------------------------------------
5148 dnl CF_MANPAGE_FORMAT version: 11 updated: 2015/04/18 08:56:57
5149 dnl -----------------
5150 dnl Option to allow user to override automatic configuration of manpage format.
5151 dnl There are several special cases:
5152 dnl
5153 dnl     gzip - man checks for, can display gzip'd files
5154 dnl     compress - man checks for, can display compressed files
5155 dnl     BSDI - files in the cat-directories are suffixed ".0"
5156 dnl     formatted - installer should format (put files in cat-directory)
5157 dnl     catonly - installer should only format, e.g., for a turnkey system.
5158 dnl
5159 dnl There are other configurations which this macro does not test, e.g., HPUX's
5160 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
5161 dnl convention would not match our use).
5162 AC_DEFUN([CF_MANPAGE_FORMAT],
5163 [
5164 AC_REQUIRE([CF_PATHSEP])
5165 AC_MSG_CHECKING(format of man-pages)
5166
5167 AC_ARG_WITH(manpage-format,
5168         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
5169                           optionally formatted/catonly, e.g., gzip,formatted],
5170         [MANPAGE_FORMAT=$withval],
5171         [MANPAGE_FORMAT=unknown])
5172
5173 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
5174 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
5175
5176 cf_unknown=
5177
5178 case $MANPAGE_FORMAT in
5179 (unknown)
5180         if test -z "$MANPATH" ; then
5181                 MANPATH="/usr/man:/usr/share/man"
5182         fi
5183
5184         # look for the 'date' man-page (it's most likely to be installed!)
5185         MANPAGE_FORMAT=
5186         cf_preform=no
5187         cf_catonly=yes
5188         cf_example=date
5189
5190         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
5191         for cf_dir in $MANPATH; do
5192                 test -z "$cf_dir" && cf_dir=/usr/man
5193                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
5194                 do
5195                         cf_test=`echo $cf_name | sed -e 's/*//'`
5196                         if test "x$cf_test" = "x$cf_name" ; then
5197
5198                                 case "$cf_name" in
5199                                 (*.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
5200                                 (*.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
5201                                 (*.0)  MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
5202                                 (*)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
5203                                 esac
5204
5205                                 case "$cf_name" in
5206                                 ($cf_dir/man*)
5207                                         cf_catonly=no
5208                                         ;;
5209                                 ($cf_dir/cat*)
5210                                         cf_preform=yes
5211                                         ;;
5212                                 esac
5213                                 break
5214                         fi
5215
5216                         # if we found a match in either man* or cat*, stop looking
5217                         if test -n "$MANPAGE_FORMAT" ; then
5218                                 cf_found=no
5219                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
5220                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
5221                                 case "$cf_name" in
5222                                 ($cf_dir/cat*)
5223                                         cf_found=yes
5224                                         ;;
5225                                 esac
5226                                 test $cf_found=yes && break
5227                         fi
5228                 done
5229                 # only check the first directory in $MANPATH where we find manpages
5230                 if test -n "$MANPAGE_FORMAT" ; then
5231                         break
5232                 fi
5233         done
5234         # if we did not find the example, just assume it is normal
5235         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
5236         IFS="$ac_save_ifs"
5237         ;;
5238 (*)
5239         for cf_option in $MANPAGE_FORMAT; do
5240         case $cf_option in
5241         (gzip|compress|BSDI|normal|formatted|catonly)
5242                 ;;
5243         (*)
5244                 cf_unknown="$cf_unknown $cf_option"
5245                 ;;
5246         esac
5247         done
5248         ;;
5249 esac
5250
5251 AC_MSG_RESULT($MANPAGE_FORMAT)
5252 if test -n "$cf_unknown" ; then
5253         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
5254 fi
5255 ])dnl
5256 dnl ---------------------------------------------------------------------------
5257 dnl CF_MANPAGE_RENAMES version: 10 updated: 2015/08/05 20:44:28
5258 dnl ------------------
5259 dnl The Debian people have their own naming convention for manpages.  This
5260 dnl option lets us override the name of the file containing renaming, or
5261 dnl disable it altogether.
5262 AC_DEFUN([CF_MANPAGE_RENAMES],
5263 [
5264 AC_MSG_CHECKING(for manpage renaming)
5265
5266 AC_ARG_WITH(manpage-renames,
5267         [  --with-manpage-renames  specify manpage-renaming],
5268         [MANPAGE_RENAMES=$withval],
5269         [MANPAGE_RENAMES=yes])
5270
5271 case ".$MANPAGE_RENAMES" in
5272 (.no)
5273         ;;
5274 (.|.yes)
5275         # Debian 'man' program?
5276         if test -f /etc/debian_version ; then
5277                 MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
5278         else
5279                 MANPAGE_RENAMES=no
5280         fi
5281         ;;
5282 esac
5283
5284 if test "$MANPAGE_RENAMES" != no ; then
5285         if test -f $srcdir/man/$MANPAGE_RENAMES ; then
5286                 MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
5287         elif test ! -f $MANPAGE_RENAMES ; then
5288                 AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
5289         fi
5290
5291         test ! -d man && mkdir man
5292
5293         # Construct a sed-script to perform renaming within man-pages
5294         if test -n "$MANPAGE_RENAMES" ; then
5295                 test ! -d man && mkdir man
5296                 $SHELL $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
5297         fi
5298 fi
5299
5300 AC_MSG_RESULT($MANPAGE_RENAMES)
5301 AC_SUBST(MANPAGE_RENAMES)
5302 ])dnl
5303 dnl ---------------------------------------------------------------------------
5304 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
5305 dnl -------------------
5306 dnl Some people expect each tool to make all aliases for manpages in the
5307 dnl man-directory.  This accommodates the older, less-capable implementations
5308 dnl of 'man', and is optional.
5309 AC_DEFUN([CF_MANPAGE_SYMLINKS],
5310 [
5311 AC_MSG_CHECKING(if manpage aliases will be installed)
5312
5313 AC_ARG_WITH(manpage-aliases,
5314         [  --with-manpage-aliases  specify manpage-aliases using .so],
5315         [MANPAGE_ALIASES=$withval],
5316         [MANPAGE_ALIASES=yes])
5317
5318 AC_MSG_RESULT($MANPAGE_ALIASES)
5319
5320 case "x$LN_S" in
5321 (xln*)
5322         cf_use_symlinks=yes
5323         ;;
5324 (*)
5325         cf_use_symlinks=no
5326         ;;
5327 esac
5328
5329 MANPAGE_SYMLINKS=no
5330 if test "$MANPAGE_ALIASES" = yes ; then
5331 AC_MSG_CHECKING(if manpage symlinks should be used)
5332
5333 AC_ARG_WITH(manpage-symlinks,
5334         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
5335         [MANPAGE_SYMLINKS=$withval],
5336         [MANPAGE_SYMLINKS=$cf_use_symlinks])
5337
5338 if test "$$cf_use_symlinks" = no; then
5339 if test "$MANPAGE_SYMLINKS" = yes ; then
5340         AC_MSG_WARN(cannot make symlinks, will use .so files)
5341         MANPAGE_SYMLINKS=no
5342 fi
5343 fi
5344
5345 AC_MSG_RESULT($MANPAGE_SYMLINKS)
5346 fi
5347
5348 ])dnl
5349 dnl ---------------------------------------------------------------------------
5350 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
5351 dnl --------------
5352 dnl This option causes manpages to be run through tbl(1) to generate tables
5353 dnl correctly.
5354 AC_DEFUN([CF_MANPAGE_TBL],
5355 [
5356 AC_MSG_CHECKING(for manpage tbl)
5357
5358 AC_ARG_WITH(manpage-tbl,
5359         [  --with-manpage-tbl      specify manpage processing with tbl],
5360         [MANPAGE_TBL=$withval],
5361         [MANPAGE_TBL=no])
5362
5363 AC_MSG_RESULT($MANPAGE_TBL)
5364 ])dnl
5365 dnl ---------------------------------------------------------------------------
5366 dnl CF_MAN_PAGES version: 47 updated: 2017/08/12 07:58:51
5367 dnl ------------
5368 dnl Try to determine if the man-pages on the system are compressed, and if
5369 dnl so, what format is used.  Use this information to construct a script that
5370 dnl will install man-pages.
5371 AC_DEFUN([CF_MAN_PAGES],
5372 [
5373 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
5374 CF_MANPAGE_FORMAT
5375 CF_MANPAGE_RENAMES
5376 CF_MANPAGE_SYMLINKS
5377 CF_MANPAGE_TBL
5378
5379 if test "$prefix" = "NONE" ; then
5380         cf_prefix="$ac_default_prefix"
5381 else
5382         cf_prefix="$prefix"
5383 fi
5384
5385 case "$MANPAGE_FORMAT" in
5386 (*catonly*)
5387         cf_format=yes
5388         cf_inboth=no
5389         ;;
5390 (*formatted*)
5391         cf_format=yes
5392         cf_inboth=yes
5393         ;;
5394 (*)
5395         cf_format=no
5396         cf_inboth=no
5397         ;;
5398 esac
5399
5400 test ! -d man && mkdir man
5401
5402 cf_so_strip=
5403 cf_compress=
5404 case "$MANPAGE_FORMAT" in
5405 (*compress*)
5406         cf_so_strip="Z"
5407         cf_compress=compress
5408         ;;
5409 (*gzip*)
5410         cf_so_strip="gz"
5411         cf_compress=gzip
5412         ;;
5413 esac
5414
5415 cf_edit_man=./edit_man.sh
5416 cf_man_alias=`pwd`/man_alias.sed
5417
5418 cat >$cf_edit_man <<CF_EOF
5419 #! $SHELL
5420 # this script is generated by the configure-script CF_MAN_PAGES macro.
5421
5422 prefix="$cf_prefix"
5423 datarootdir="$datarootdir"
5424 datadir="$datadir"
5425
5426 NCURSES_MAJOR="$NCURSES_MAJOR"
5427 NCURSES_MINOR="$NCURSES_MINOR"
5428 NCURSES_PATCH="$NCURSES_PATCH"
5429
5430 NCURSES_OSPEED="$NCURSES_OSPEED"
5431 TERMINFO="$TERMINFO"
5432
5433 INSTALL="$INSTALL"
5434 INSTALL_DATA="$INSTALL_DATA"
5435
5436 transform="$program_transform_name"
5437
5438 TMP=\${TMPDIR:=/tmp}/man\$\$
5439 trap "rm -f \$TMP" 0 1 2 3 15
5440
5441 form=\[$]1
5442 shift || exit 1
5443
5444 verb=\[$]1
5445 shift || exit 1
5446
5447 mandir=\[$]1
5448 shift || exit 1
5449
5450 srcdir=\[$]1
5451 top_srcdir=\[$]srcdir/..
5452 shift || exit 1
5453
5454 if test "\$form" = normal ; then
5455         if test "$cf_format" = yes ; then
5456         if test "$cf_inboth" = no ; then
5457                 $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
5458                 exit $?
5459         fi
5460         fi
5461         cf_subdir=\$mandir/man
5462         cf_tables=$MANPAGE_TBL
5463 else
5464         cf_subdir=\$mandir/cat
5465         cf_tables=yes
5466 fi
5467
5468 # process the list of source-files
5469 for i in \[$]* ; do
5470 case \$i in
5471 (*.orig|*.rej) ;;
5472 (*.[[0-9]]*)
5473         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
5474         if test \$verb = installing ; then
5475         if test ! -d \$cf_subdir\${section} ; then
5476                 mkdir -p \$cf_subdir\$section
5477         fi
5478         fi
5479
5480         # replace variables in man page
5481         if test ! -f $cf_man_alias ; then
5482 cat >>$cf_man_alias <<-CF_EOF2
5483                 s,@DATADIR@,\$datadir,g
5484                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
5485                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
5486                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
5487                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
5488                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
5489                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
5490 CF_EOF
5491         ifelse($1,,,[
5492         for cf_name in $1
5493         do
5494                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
5495                 cf_name=`echo $cf_name|sed "$program_transform_name"`
5496 cat >>$cf_edit_man <<-CF_EOF
5497                 s,@$cf_NAME@,$cf_name,g
5498 CF_EOF
5499         done
5500         ])
5501 cat >>$cf_edit_man <<CF_EOF
5502 CF_EOF2
5503                 echo "...made $cf_man_alias"
5504         fi
5505
5506         aliases=
5507         cf_source=\`basename \$i\`
5508         inalias=\$cf_source
5509         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
5510         if test ! -f \$inalias ; then
5511                 echo .. skipped \$cf_source
5512                 continue
5513         fi
5514 CF_EOF
5515
5516 if test "$MANPAGE_ALIASES" != no ; then
5517 cat >>$cf_edit_man <<CF_EOF
5518         nCurses=ignore.3x
5519         test $with_curses_h = yes && nCurses=ncurses.3x
5520         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
5521 CF_EOF
5522 fi
5523
5524 if test "$MANPAGE_RENAMES" = no ; then
5525 cat >>$cf_edit_man <<CF_EOF
5526         # perform program transformations for section 1 man pages
5527         if test \$section = 1 ; then
5528                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
5529         else
5530                 cf_target=\$cf_subdir\${section}/\$cf_source
5531         fi
5532 CF_EOF
5533 else
5534 cat >>$cf_edit_man <<CF_EOF
5535         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
5536         if test -z "\$cf_target" ; then
5537                 echo '? missing rename for '\$cf_source
5538                 cf_target="\$cf_source"
5539         fi
5540         cf_target="\$cf_subdir\${section}/\${cf_target}"
5541
5542 CF_EOF
5543 fi
5544
5545 cat >>$cf_edit_man <<CF_EOF
5546         sed     -f $cf_man_alias \\
5547 CF_EOF
5548
5549 if test -f $MANPAGE_RENAMES ; then
5550 cat >>$cf_edit_man <<CF_EOF
5551                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
5552 CF_EOF
5553 else
5554 cat >>$cf_edit_man <<CF_EOF
5555                 < \$i >\$TMP
5556 CF_EOF
5557 fi
5558
5559 cat >>$cf_edit_man <<CF_EOF
5560 if test \$cf_tables = yes ; then
5561         tbl \$TMP >\$TMP.out
5562         mv \$TMP.out \$TMP
5563 fi
5564 CF_EOF
5565
5566 if test $with_overwrite != yes ; then
5567 cat >>$cf_edit_man <<CF_EOF
5568         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
5569         mv \$TMP.out \$TMP
5570 CF_EOF
5571 fi
5572
5573 if test $with_curses_h != yes ; then
5574 cat >>$cf_edit_man <<CF_EOF
5575         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
5576         mv \$TMP.out \$TMP
5577 CF_EOF
5578 fi
5579
5580 cat >>$cf_edit_man <<CF_EOF
5581         if test \$form = format ; then
5582                 nroff -man \$TMP >\$TMP.out
5583                 mv \$TMP.out \$TMP
5584         fi
5585 CF_EOF
5586
5587 if test -n "$cf_compress" ; then
5588 cat >>$cf_edit_man <<CF_EOF
5589         if test \$verb = installing ; then
5590         if ( $cf_compress -f \$TMP )
5591         then
5592                 mv \$TMP.$cf_so_strip \$TMP
5593         fi
5594         fi
5595         cf_target="\$cf_target.$cf_so_strip"
5596 CF_EOF
5597 fi
5598
5599 case "$MANPAGE_FORMAT" in
5600 (*BSDI*)
5601 cat >>$cf_edit_man <<CF_EOF
5602         if test \$form = format ; then
5603                 # BSDI installs only .0 suffixes in the cat directories
5604                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
5605         fi
5606 CF_EOF
5607   ;;
5608 esac
5609
5610 cat >>$cf_edit_man <<CF_EOF
5611         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
5612         if test \$verb = installing ; then
5613                 echo \$verb \$cf_target
5614                 \$INSTALL_DATA \$TMP \$cf_target
5615                 test -d \$cf_subdir\${section} &&
5616                 test -n "\$aliases" && (
5617                         cd \$cf_subdir\${section} && (
5618                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
5619                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
5620                                 cf_target=\`basename \$cf_target\`
5621                                 for cf_alias in \$aliases
5622                                 do
5623                                         if test \$section = 1 ; then
5624                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
5625                                         fi
5626
5627                                         if test "$MANPAGE_SYMLINKS" = yes ; then
5628                                                 if test -f \$cf_alias\${suffix} ; then
5629                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
5630                                                         then
5631                                                                 continue
5632                                                         fi
5633                                                 fi
5634                                                 echo .. \$verb alias \$cf_alias\${suffix}
5635 CF_EOF
5636 case "x$LN_S" in
5637 (*-f)
5638 cat >>$cf_edit_man <<CF_EOF
5639                                                 $LN_S \$cf_target \$cf_alias\${suffix}
5640 CF_EOF
5641         ;;
5642 (*)
5643 cat >>$cf_edit_man <<CF_EOF
5644                                                 rm -f \$cf_alias\${suffix}
5645                                                 $LN_S \$cf_target \$cf_alias\${suffix}
5646 CF_EOF
5647         ;;
5648 esac
5649 cat >>$cf_edit_man <<CF_EOF
5650                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
5651                                                 echo ".so \$cf_source" >\$TMP
5652 CF_EOF
5653 if test -n "$cf_compress" ; then
5654 cat >>$cf_edit_man <<CF_EOF
5655                                                 if test -n "$cf_so_strip" ; then
5656                                                         $cf_compress -f \$TMP
5657                                                         mv \$TMP.$cf_so_strip \$TMP
5658                                                 fi
5659 CF_EOF
5660 fi
5661 cat >>$cf_edit_man <<CF_EOF
5662                                                 echo .. \$verb alias \$cf_alias\${suffix}
5663                                                 rm -f \$cf_alias\${suffix}
5664                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
5665                                         fi
5666                                 done
5667                         )
5668                 )
5669         elif test \$verb = removing ; then
5670                 test -f \$cf_target && (
5671                         echo \$verb \$cf_target
5672                         rm -f \$cf_target
5673                 )
5674                 test -d \$cf_subdir\${section} &&
5675                 test -n "\$aliases" && (
5676                         cd \$cf_subdir\${section} && (
5677                                 for cf_alias in \$aliases
5678                                 do
5679                                         if test \$section = 1 ; then
5680                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
5681                                         fi
5682
5683                                         echo .. \$verb alias \$cf_alias\${suffix}
5684                                         rm -f \$cf_alias\${suffix}
5685                                 done
5686                         )
5687                 )
5688         else
5689 #               echo ".hy 0"
5690                 cat \$TMP
5691         fi
5692         ;;
5693 esac
5694 done
5695
5696 if test $cf_inboth = yes ; then
5697 if test \$form != format ; then
5698         $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
5699 fi
5700 fi
5701
5702 exit 0
5703 CF_EOF
5704 chmod 755 $cf_edit_man
5705
5706 ])dnl
5707 dnl ---------------------------------------------------------------------------
5708 dnl CF_MAP_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
5709 dnl -------------------
5710 dnl Convert a default-libname to the actual one used via CF_WITH_LIB_BASENAME.
5711 dnl
5712 dnl $1 = variable to set
5713 dnl $2 = default-libname
5714 AC_DEFUN([CF_MAP_LIB_BASENAME],[
5715 CF_UPPER(cf_map_lib_basename,$2)
5716 eval $1=\$${cf_map_lib_basename}_NAME
5717 ])dnl
5718 dnl ---------------------------------------------------------------------------
5719 dnl CF_MATH_LIB version: 9 updated: 2017/01/21 11:06:25
5720 dnl -----------
5721 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
5722 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
5723 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
5724 AC_DEFUN([CF_MATH_LIB],
5725 [
5726 AC_CACHE_CHECK(if -lm needed for math functions,
5727         cf_cv_need_libm,[
5728         AC_TRY_LINK([
5729         #include <stdio.h>
5730         #include <stdlib.h>
5731         #include <math.h>
5732         ],
5733         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
5734         [cf_cv_need_libm=no],
5735         [cf_cv_need_libm=yes])])
5736 if test "$cf_cv_need_libm" = yes
5737 then
5738 ifelse($1,,[
5739         CF_ADD_LIB(m)
5740 ],[$1=-lm])
5741 fi
5742 ])
5743 dnl ---------------------------------------------------------------------------
5744 dnl CF_MIXEDCASE_FILENAMES version: 8 updated: 2020/11/14 10:12:15
5745 dnl ----------------------
5746 dnl Check if the file-system supports mixed-case filenames.  If we're able to
5747 dnl create a lowercase name and see it as uppercase, it doesn't support that.
5748 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
5749 [
5750 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
5751 if test "$cross_compiling" = yes ; then
5752         case $target_alias in
5753         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*|darwin*)
5754                 cf_cv_mixedcase=no
5755                 ;;
5756         (*)
5757                 cf_cv_mixedcase=yes
5758                 ;;
5759         esac
5760 else
5761         rm -f conftest CONFTEST
5762         echo test >conftest
5763         if test -f CONFTEST ; then
5764                 cf_cv_mixedcase=no
5765         else
5766                 cf_cv_mixedcase=yes
5767         fi
5768         rm -f conftest CONFTEST
5769 fi
5770 ])
5771 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
5772 ])dnl
5773 dnl ---------------------------------------------------------------------------
5774 dnl CF_MKSTEMP version: 10 updated: 2017/01/21 11:12:16
5775 dnl ----------
5776 dnl Check for a working mkstemp.  This creates two files, checks that they are
5777 dnl successfully created and distinct (AmigaOS apparently fails on the last).
5778 AC_DEFUN([CF_MKSTEMP],[
5779 AC_CHECK_HEADERS( \
5780 unistd.h \
5781 )
5782 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
5783 rm -rf conftest*
5784 AC_TRY_RUN([
5785 #include <sys/types.h>
5786 #ifdef HAVE_UNISTD_H
5787 #include <unistd.h>
5788 #endif
5789 #include <stdlib.h>
5790 #include <stdio.h>
5791 #include <string.h>
5792 #include <sys/stat.h>
5793 int main(void)
5794 {
5795         char *tmpl = "conftestXXXXXX";
5796         char name[2][80];
5797         int n;
5798         int result = 0;
5799         int fd;
5800         struct stat sb;
5801
5802         umask(077);
5803         for (n = 0; n < 2; ++n) {
5804                 strcpy(name[n], tmpl);
5805                 if ((fd = mkstemp(name[n])) >= 0) {
5806                         if (!strcmp(name[n], tmpl)
5807                          || stat(name[n], &sb) != 0
5808                          || (sb.st_mode & S_IFMT) != S_IFREG
5809                          || (sb.st_mode & 077) != 0) {
5810                                 result = 1;
5811                         }
5812                         close(fd);
5813                 }
5814         }
5815         if (result == 0
5816          && !strcmp(name[0], name[1]))
5817                 result = 1;
5818         ${cf_cv_main_return:-return}(result);
5819 }
5820 ],[cf_cv_func_mkstemp=yes
5821 ],[cf_cv_func_mkstemp=no
5822 ],[cf_cv_func_mkstemp=maybe])
5823 ])
5824 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
5825         AC_CHECK_FUNC(mkstemp)
5826 fi
5827 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
5828         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
5829 fi
5830 ])dnl
5831 dnl ---------------------------------------------------------------------------
5832 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
5833 dnl ----------
5834 dnl Write a debug message to config.log, along with the line number in the
5835 dnl configure script.
5836 AC_DEFUN([CF_MSG_LOG],[
5837 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
5838 ])dnl
5839 dnl ---------------------------------------------------------------------------
5840 dnl CF_NCURSES_ABI_6 version: 3 updated: 2015/06/06 16:10:11
5841 dnl ----------------
5842 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
5843 dnl warn about this.
5844 AC_DEFUN([CF_NCURSES_ABI_6],[
5845 if test "${with_abi_version+set}" != set; then
5846         case $cf_cv_rel_version in
5847         (5.*)
5848                 cf_cv_rel_version=6.0
5849                 cf_cv_abi_version=6
5850                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_version)
5851                 ;;
5852         esac
5853 fi
5854 ])dnl
5855 dnl ---------------------------------------------------------------------------
5856 dnl CF_NCURSES_WITH_ABI_VERSION version: 2 updated: 2015/12/19 17:51:52
5857 dnl ---------------------------
5858 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
5859 dnl packager has incremented the ABI past that used in the original package,
5860 dnl and wishes to keep doing this.
5861 dnl
5862 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
5863 dnl symbol.
5864 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
5865 CF_WITH_ABI_VERSION($1)
5866 if test "x$cf_cv_abi_version" != "x$with_abi_version"
5867 then
5868         case $cf_cv_rel_version in
5869         (5.*)
5870                 cf_cv_rel_version=$with_abi_version.0
5871                 ;;
5872         esac
5873 fi
5874 ])dnl
5875 dnl ---------------------------------------------------------------------------
5876 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
5877 dnl ------------------
5878 dnl see CF_WITH_NO_LEAKS
5879 AC_DEFUN([CF_NO_LEAKS_OPTION],[
5880 AC_MSG_CHECKING(if you want to use $1 for testing)
5881 AC_ARG_WITH($1,
5882         [$2],
5883         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
5884          $4
5885 ])
5886         : ${with_cflags:=-g}
5887         : ${with_no_leaks:=yes}
5888          with_$1=yes],
5889         [with_$1=])
5890 AC_MSG_RESULT(${with_$1:-no})
5891
5892 case .$with_cflags in
5893 (.*-g*)
5894         case .$CFLAGS in
5895         (.*-g*)
5896                 ;;
5897         (*)
5898                 CF_ADD_CFLAGS([-g])
5899                 ;;
5900         esac
5901         ;;
5902 esac
5903 ])dnl
5904 dnl ---------------------------------------------------------------------------
5905 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
5906 dnl ----------------
5907 dnl Check if the given variable is a number.  If not, report an error.
5908 dnl $1 is the variable
5909 dnl $2 is the message
5910 AC_DEFUN([CF_NUMBER_SYNTAX],[
5911 if test -n "$1" ; then
5912   case $1 in
5913   ([[0-9]]*)
5914         ;;
5915   (*)
5916         AC_MSG_ERROR($2 is not a number: $1)
5917         ;;
5918   esac
5919 else
5920   AC_MSG_ERROR($2 value is empty)
5921 fi
5922 ])dnl
5923 dnl ---------------------------------------------------------------------------
5924 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
5925 dnl -------------
5926 dnl Compute the object-directory name from the given model name
5927 AC_DEFUN([CF_OBJ_SUBDIR],
5928 [
5929         case $1 in
5930         (libtool) $2='obj_lo'  ;;
5931         (normal)  $2='objects' ;;
5932         (debug)   $2='obj_g' ;;
5933         (profile) $2='obj_p' ;;
5934         (shared)
5935                 case $cf_cv_system_name in
5936                 (cygwin|msys)
5937                         $2='objects' ;;
5938                 (*)
5939                         $2='obj_s' ;;
5940                 esac
5941         esac
5942 ])dnl
5943 dnl ---------------------------------------------------------------------------
5944 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
5945 dnl ----------
5946 dnl Provide a value for the $PATH and similar separator (or amend the value
5947 dnl as provided in autoconf 2.5x).
5948 AC_DEFUN([CF_PATHSEP],
5949 [
5950         AC_MSG_CHECKING(for PATH separator)
5951         case $cf_cv_system_name in
5952         (os2*)  PATH_SEPARATOR=';'  ;;
5953         (*)     ${PATH_SEPARATOR:=':'}  ;;
5954         esac
5955 ifelse([$1],,,[$1=$PATH_SEPARATOR])
5956         AC_SUBST(PATH_SEPARATOR)
5957         AC_MSG_RESULT($PATH_SEPARATOR)
5958 ])dnl
5959 dnl ---------------------------------------------------------------------------
5960 dnl CF_PATH_PROG version: 10 updated: 2019/06/30 19:44:43
5961 dnl ------------
5962 dnl Check for a given program, defining corresponding symbol.
5963 dnl     $1 = environment variable, which is suffixed by "_PATH" in the #define.
5964 dnl     $2 = program name to find.
5965 dnl     $3 = optional list of additional program names to test.
5966 dnl $4 = $PATH
5967 dnl
5968 dnl If there is more than one token in the result, #define the remaining tokens
5969 dnl to $1_ARGS.  We need this for 'install' in particular.
5970 dnl
5971 dnl FIXME: we should allow this to be overridden by environment variables
5972 dnl
5973 AC_DEFUN([CF_PATH_PROG],[
5974 AC_REQUIRE([CF_PATHSEP])
5975 test -z "[$]$1" && $1=$2
5976 AC_PATH_PROGS($1,[$]$1 $2 ifelse($3,,,$3),[$]$1, ifelse($4,,,$4))
5977
5978 cf_path_prog=""
5979 cf_path_args=""
5980 IFS="${IFS:-    }"; cf_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR"
5981 for cf_temp in $ac_cv_path_$1
5982 do
5983         if test -z "$cf_path_prog" ; then
5984                 if test "$with_full_paths" = yes ; then
5985                         CF_PATH_SYNTAX(cf_temp,break)
5986                         cf_path_prog="$cf_temp"
5987                 else
5988                         cf_path_prog="`basename $cf_temp`"
5989                 fi
5990         elif test -z "$cf_path_args" ; then
5991                 cf_path_args="$cf_temp"
5992         else
5993                 cf_path_args="$cf_path_args $cf_temp"
5994         fi
5995 done
5996 IFS="$cf_save_ifs"
5997
5998 if test -n "$cf_path_prog" ; then
5999         CF_MSG_LOG(defining path for ${cf_path_prog})
6000         AC_DEFINE_UNQUOTED($1_PATH,"$cf_path_prog",Define to pathname $1)
6001         test -n "$cf_path_args" && AC_DEFINE_UNQUOTED($1_ARGS,"$cf_path_args",Define to provide args for $1)
6002 fi
6003 ])dnl
6004 dnl ---------------------------------------------------------------------------
6005 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
6006 dnl --------------
6007 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
6008 dnl begins with one of the prefix/exec_prefix variables, and then again if the
6009 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
6010 dnl delayed evaluation of those symbols.
6011 AC_DEFUN([CF_PATH_SYNTAX],[
6012 if test "x$prefix" != xNONE; then
6013         cf_path_syntax="$prefix"
6014 else
6015         cf_path_syntax="$ac_default_prefix"
6016 fi
6017
6018 case ".[$]$1" in
6019 (.\[$]\(*\)*|.\'*\'*)
6020         ;;
6021 (..|./*|.\\*)
6022         ;;
6023 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
6024         ;;
6025 (.\[$]{*prefix}*|.\[$]{*dir}*)
6026         eval $1="[$]$1"
6027         case ".[$]$1" in
6028         (.NONE/*)
6029                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
6030                 ;;
6031         esac
6032         ;;
6033 (.no|.NONE/*)
6034         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
6035         ;;
6036 (*)
6037         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
6038         ;;
6039 esac
6040 ])dnl
6041 dnl ---------------------------------------------------------------------------
6042 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
6043 dnl -------------
6044 dnl Check for the package-config program, unless disabled by command-line.
6045 AC_DEFUN([CF_PKG_CONFIG],
6046 [
6047 AC_MSG_CHECKING(if you want to use pkg-config)
6048 AC_ARG_WITH(pkg-config,
6049         [  --with-pkg-config{=path} enable/disable use of pkg-config],
6050         [cf_pkg_config=$withval],
6051         [cf_pkg_config=yes])
6052 AC_MSG_RESULT($cf_pkg_config)
6053
6054 case $cf_pkg_config in
6055 (no)
6056         PKG_CONFIG=none
6057         ;;
6058 (yes)
6059         CF_ACVERSION_CHECK(2.52,
6060                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
6061                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
6062         ;;
6063 (*)
6064         PKG_CONFIG=$withval
6065         ;;
6066 esac
6067
6068 test -z "$PKG_CONFIG" && PKG_CONFIG=none
6069 if test "$PKG_CONFIG" != none ; then
6070         CF_PATH_SYNTAX(PKG_CONFIG)
6071 elif test "x$cf_pkg_config" != xno ; then
6072         AC_MSG_WARN(pkg-config is not installed)
6073 fi
6074
6075 AC_SUBST(PKG_CONFIG)
6076 ])dnl
6077 dnl ---------------------------------------------------------------------------
6078 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
6079 dnl -----------------
6080 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
6081 dnl
6082 dnl     POSIX.1-1990                            _POSIX_SOURCE
6083 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
6084 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
6085 dnl             Bindings Option
6086 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
6087 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
6088 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
6089 dnl
6090 dnl Parameters:
6091 dnl     $1 is the nominal value for _POSIX_C_SOURCE
6092 AC_DEFUN([CF_POSIX_C_SOURCE],
6093 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
6094
6095 if test "$cf_cv_posix_visible" = no; then
6096
6097 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
6098
6099 cf_save_CFLAGS="$CFLAGS"
6100 cf_save_CPPFLAGS="$CPPFLAGS"
6101
6102 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
6103 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
6104
6105 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
6106         CF_MSG_LOG(if the symbol is already defined go no further)
6107         AC_TRY_COMPILE([#include <sys/types.h>],[
6108 #ifndef _POSIX_C_SOURCE
6109 make an error
6110 #endif],
6111         [cf_cv_posix_c_source=no],
6112         [cf_want_posix_source=no
6113          case .$cf_POSIX_C_SOURCE in
6114          (.[[12]]??*)
6115                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6116                 ;;
6117          (.2)
6118                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6119                 cf_want_posix_source=yes
6120                 ;;
6121          (.*)
6122                 cf_want_posix_source=yes
6123                 ;;
6124          esac
6125          if test "$cf_want_posix_source" = yes ; then
6126                 AC_TRY_COMPILE([#include <sys/types.h>],[
6127 #ifdef _POSIX_SOURCE
6128 make an error
6129 #endif],[],
6130                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
6131          fi
6132          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
6133          CFLAGS="$cf_trim_CFLAGS"
6134          CPPFLAGS="$cf_trim_CPPFLAGS"
6135          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
6136          CF_MSG_LOG(if the second compile does not leave our definition intact error)
6137          AC_TRY_COMPILE([#include <sys/types.h>],[
6138 #ifndef _POSIX_C_SOURCE
6139 make an error
6140 #endif],,
6141          [cf_cv_posix_c_source=no])
6142          CFLAGS="$cf_save_CFLAGS"
6143          CPPFLAGS="$cf_save_CPPFLAGS"
6144         ])
6145 ])
6146
6147 if test "$cf_cv_posix_c_source" != no ; then
6148         CFLAGS="$cf_trim_CFLAGS"
6149         CPPFLAGS="$cf_trim_CPPFLAGS"
6150         CF_ADD_CFLAGS($cf_cv_posix_c_source)
6151 fi
6152
6153 fi # cf_cv_posix_visible
6154
6155 ])dnl
6156 dnl ---------------------------------------------------------------------------
6157 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
6158 dnl ----------------
6159 dnl POSIX documents test-macros which an application may set before any system
6160 dnl headers are included to make features available.
6161 dnl
6162 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
6163 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
6164 dnl recent features visible in the system header files unless the application
6165 dnl overrides the corresponding test-macros.  Doing that introduces portability
6166 dnl problems.
6167 dnl
6168 dnl This macro makes a special check for the symbols used for this, to avoid a
6169 dnl conflicting definition.
6170 AC_DEFUN([CF_POSIX_VISIBLE],
6171 [
6172 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
6173 AC_TRY_COMPILE([#include <stdio.h>],[
6174 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
6175         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
6176         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
6177         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
6178 #error conflicting symbols found
6179 #endif
6180 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
6181 ])
6182 ])dnl
6183 dnl ---------------------------------------------------------------------------
6184 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
6185 dnl ------------
6186 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
6187 dnl
6188 dnl $1 = symbol to test
6189 dnl $2 = value (if any) to use for a predefinition
6190 AC_DEFUN([CF_PREDEFINE],
6191 [
6192 AC_MSG_CHECKING(if we must define $1)
6193 AC_TRY_COMPILE([#include <sys/types.h>
6194 ],[
6195 #ifndef $1
6196 make an error
6197 #endif],[cf_result=no],[cf_result=yes])
6198 AC_MSG_RESULT($cf_result)
6199
6200 if test "$cf_result" = yes ; then
6201         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
6202 elif test "x$2" != "x" ; then
6203         AC_MSG_CHECKING(checking for compatible value versus $2)
6204         AC_TRY_COMPILE([#include <sys/types.h>
6205 ],[
6206 #if $1-$2 < 0
6207 make an error
6208 #endif],[cf_result=yes],[cf_result=no])
6209         AC_MSG_RESULT($cf_result)
6210         if test "$cf_result" = no ; then
6211                 # perhaps we can override it - try...
6212                 CPPFLAGS="$CPPFLAGS -D$1=$2"
6213         fi
6214 fi
6215 ])dnl
6216 dnl ---------------------------------------------------------------------------
6217 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
6218 dnl ------------
6219 dnl Append definitions and rules for the given programs to the subdirectory
6220 dnl Makefiles, and the recursion rule for the top-level Makefile.
6221 dnl
6222 dnl parameters
6223 dnl     $1 = script to run
6224 dnl     $2 = list of subdirectories
6225 dnl
6226 dnl variables
6227 dnl     $AWK
6228 AC_DEFUN([CF_PRG_RULES],
6229 [
6230 for cf_dir in $2
6231 do
6232         if test ! -d $srcdir/$cf_dir; then
6233                 continue
6234         elif test -f $srcdir/$cf_dir/programs; then
6235                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
6236         fi
6237 done
6238
6239 ])dnl
6240 dnl ---------------------------------------------------------------------------
6241 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
6242 dnl ----------
6243 dnl Check for archiver "ar".
6244 AC_DEFUN([CF_PROG_AR],[
6245 AC_CHECK_TOOL(AR, ar, ar)
6246 ])
6247 dnl ---------------------------------------------------------------------------
6248 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
6249 dnl -----------
6250 dnl Check for awk, ensure that the check found something.
6251 AC_DEFUN([CF_PROG_AWK],
6252 [
6253 AC_PROG_AWK
6254 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
6255 ])dnl
6256 dnl ---------------------------------------------------------------------------
6257 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
6258 dnl ----------
6259 dnl standard check for CC, plus followup sanity checks
6260 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
6261 AC_DEFUN([CF_PROG_CC],[
6262 CF_ACVERSION_CHECK(2.53,
6263         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
6264          AC_REQUIRE([AC_PROG_CC])],
6265         [])
6266 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
6267 CF_GCC_VERSION
6268 CF_ACVERSION_CHECK(2.52,
6269         [AC_PROG_CC_STDC],
6270         [CF_ANSI_CC_REQD])
6271 CF_CC_ENV_FLAGS
6272 ])dnl
6273 dnl ---------------------------------------------------------------------------
6274 dnl CF_PROG_CC_C_O version: 5 updated: 2017/01/21 11:06:25
6275 dnl --------------
6276 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
6277 dnl the output file can be renamed, and allows for a shell variable that can
6278 dnl be used later.  The parameter is either CC or CXX.  The result is the
6279 dnl cache variable:
6280 dnl     $cf_cv_prog_CC_c_o
6281 dnl     $cf_cv_prog_CXX_c_o
6282 dnl
6283 dnl $1 = compiler
6284 dnl $2 = compiler options, if any
6285 AC_DEFUN([CF_PROG_CC_C_O],
6286 [AC_REQUIRE([AC_PROG_CC])dnl
6287 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
6288 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
6289 [
6290 cat > conftest.$ac_ext <<CF_EOF
6291 int main(void)
6292 {
6293         ${cf_cv_main_return:-return}(0);
6294 }
6295 CF_EOF
6296 # We do the test twice because some compilers refuse to overwrite an
6297 # existing .o file with -o, though they will create one.
6298 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
6299 if AC_TRY_EVAL(ac_try) &&
6300   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
6301 then
6302   eval cf_cv_prog_$1_c_o=yes
6303 else
6304   eval cf_cv_prog_$1_c_o=no
6305 fi
6306 rm -rf conftest*
6307 ])dnl
6308 if test $cf_cv_prog_$1_c_o = yes; then
6309   AC_MSG_RESULT([yes])
6310 else
6311   AC_MSG_RESULT([no])
6312 fi
6313 ])dnl
6314 dnl ---------------------------------------------------------------------------
6315 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
6316 dnl -------------
6317 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
6318 dnl This macro adds a check to ensure the script found something.
6319 AC_DEFUN([CF_PROG_EGREP],
6320 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
6321         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
6322                 then ac_cv_prog_egrep='grep -E'
6323                 else ac_cv_prog_egrep='egrep'
6324         fi])
6325         EGREP=$ac_cv_prog_egrep
6326         AC_SUBST([EGREP])
6327         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
6328 ])dnl
6329 dnl ---------------------------------------------------------------------------
6330 dnl CF_PROG_GNAT version: 10 updated: 2019/12/31 08:53:54
6331 dnl ------------
6332 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
6333 AC_DEFUN([CF_PROG_GNAT],[
6334 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
6335 do
6336         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
6337
6338         unset ac_cv_path_cf_TEMP_gnat
6339         unset cf_TEMP_gnat
6340         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
6341         eval cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat
6342
6343         if test "x$cf_TEMP_gnat" != xno; then
6344                 unset cf_cv_gnat_version
6345                 unset cf_TEMP_gnat
6346                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
6347         fi
6348         eval cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat
6349
6350         unset cf_TEMP_gnat
6351         unset cf_cv_gnat_version
6352         unset ac_cv_path_cf_TEMP_gnat
6353 done
6354
6355 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
6356         cf_ada_make=
6357         cf_cv_prog_gnat_correct=no
6358 else
6359         cf_ada_make=gnatmake
6360         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
6361                 # gprconfig is newer than gnatmake; we can continue...
6362                 cf_ada_config="##"
6363         else
6364                 rm -rf conftest* *~conftest*
6365                 if mkdir conftest.src
6366                 then
6367                         cf_ada_config=""
6368                         cd conftest.src
6369                         for cf_gprconfig in Ada C
6370                         do
6371                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
6372                                 if test $cf_gprconfig = C
6373                                 then
6374                                         for cf_gprconfig_param in \
6375                                                 $cf_gprconfig,,,,GNATGCC \
6376                                                 $cf_gprconfig,,,,GCC \
6377                                                 $cf_gprconfig
6378                                         do
6379                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6380                                                 test -n "$cf_gprconfig_value" && break
6381                                         done
6382                                 else
6383                                         cf_gprconfig_param=$cf_gprconfig
6384                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6385                                 fi
6386                                 if test -n "$cf_gprconfig_value"
6387                                 then
6388                                         eval cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value
6389                                         AC_MSG_RESULT($cf_gprconfig_value)
6390                                 else
6391                                         AC_MSG_RESULT(missing)
6392                                         cf_ada_config="#"
6393                                         break
6394                                 fi
6395                         done
6396                         cd ..
6397                         rm -rf conftest* *~conftest*
6398                 fi
6399         fi
6400         if test "x$cf_ada_config" != "x#"
6401         then
6402                 CF_GNAT_VERSION
6403                 CF_CHECK_GNAT_VERSION
6404                 AC_CHECK_PROG(M4_exists, m4, yes, no)
6405                 if test "$ac_cv_prog_M4_exists" = no; then
6406                         cf_cv_prog_gnat_correct=no
6407                         AC_MSG_WARN(Ada95 binding required program m4 not found. Ada95 binding disabled)
6408                 fi
6409                 if test "$cf_cv_prog_gnat_correct" = yes; then
6410                         AC_MSG_CHECKING(if GNAT works)
6411                         CF_GNAT_TRY_RUN([procedure conftest;],
6412 [with Text_IO;
6413 with GNAT.OS_Lib;
6414 procedure conftest is
6415 begin
6416    Text_IO.Put ("Hello World");
6417    Text_IO.New_Line;
6418    GNAT.OS_Lib.OS_Exit (0);
6419 end conftest;],
6420 [cf_cv_prog_gnat_correct=yes],
6421 [cf_cv_prog_gnat_correct=no])
6422                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
6423                 fi
6424         else
6425                 cf_cv_prog_gnat_correct=no
6426         fi
6427 fi
6428
6429 AC_SUBST(cf_ada_make)
6430 AC_SUBST(cf_ada_config)
6431 AC_SUBST(cf_ada_config_Ada)
6432 AC_SUBST(cf_ada_config_C)
6433 ])dnl
6434 dnl ---------------------------------------------------------------------------
6435 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
6436 dnl ---------------
6437 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
6438 dnl misc/tabset install won't work properly.  Usually this happens only when
6439 dnl using the fallback mkinstalldirs script
6440 AC_DEFUN([CF_PROG_INSTALL],
6441 [AC_PROG_INSTALL
6442 case $INSTALL in
6443 (/*)
6444         ;;
6445 (*)
6446         CF_DIRNAME(cf_dir,$INSTALL)
6447         test -z "$cf_dir" && cf_dir=.
6448         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
6449         ;;
6450 esac
6451 ])dnl
6452 dnl ---------------------------------------------------------------------------
6453 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
6454 dnl ----------------
6455 dnl Check for ldconfig, needed to fixup shared libraries that would be built
6456 dnl and then used in the install.
6457 AC_DEFUN([CF_PROG_LDCONFIG],[
6458 if test "$cross_compiling" = yes ; then
6459         LDCONFIG=:
6460 else
6461         case "$cf_cv_system_name" in
6462         (dragonfly*|mirbsd*|freebsd*)
6463                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
6464                 ;;
6465         (*) LDPATH=$PATH:/sbin:/usr/sbin
6466                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
6467                 ;;
6468         esac
6469 fi
6470 AC_SUBST(LDCONFIG)
6471 ])dnl
6472 dnl ---------------------------------------------------------------------------
6473 dnl CF_PROG_LINT version: 4 updated: 2019/11/20 18:55:37
6474 dnl ------------
6475 AC_DEFUN([CF_PROG_LINT],
6476 [
6477 AC_CHECK_PROGS(LINT, lint cppcheck splint)
6478 case "x$LINT" in
6479 (xcppcheck|x*/cppcheck)
6480         test -z "$LINT_OPTS" && LINT_OPTS="--enable=all"
6481         ;;
6482 esac
6483 AC_SUBST(LINT_OPTS)
6484 ])dnl
6485 dnl ---------------------------------------------------------------------------
6486 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
6487 dnl ------------
6488 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
6489 dnl option if it is supported.
6490 AC_DEFUN([CF_PROG_LN_S],[
6491 AC_PROG_LN_S
6492 AC_MSG_CHECKING(if $LN_S -f options work)
6493
6494 rm -f conf$$.src conf$$dst
6495 echo >conf$$.dst
6496 echo first >conf$$.src
6497 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
6498         cf_prog_ln_sf=yes
6499 else
6500         cf_prog_ln_sf=no
6501 fi
6502 rm -f conf$$.dst conf$$src
6503 AC_MSG_RESULT($cf_prog_ln_sf)
6504
6505 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
6506 ])dnl
6507 dnl ---------------------------------------------------------------------------
6508 dnl CF_REGEX version: 16 updated: 2020/09/26 19:56:36
6509 dnl --------
6510 dnl Attempt to determine if we've got one of the flavors of regular-expression
6511 dnl code that we can support.
6512 AC_DEFUN([CF_REGEX],
6513 [
6514
6515 cf_regex_func=no
6516 cf_regex_libs=
6517 case $host_os in
6518 (mingw*)
6519         # -lsystre -ltre -lintl -liconv
6520         AC_CHECK_LIB(systre,regcomp,[
6521                 AC_CHECK_LIB(iconv,libiconv_open,[CF_ADD_LIB(iconv)])
6522                 AC_CHECK_LIB(intl,libintl_gettext,[CF_ADD_LIB(intl)])
6523                 AC_CHECK_LIB(tre,tre_regcomp,[CF_ADD_LIB(tre)])
6524                 CF_ADD_LIB(systre)
6525                 cf_regex_func=regcomp
6526         ],[
6527                 AC_CHECK_LIB(gnurx,regcomp,[
6528                         CF_ADD_LIB(gnurx)
6529                         cf_regex_func=regcomp])
6530         ])
6531         ;;
6532 (*)
6533         cf_regex_libs="regex re"
6534         AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
6535                 for cf_regex_lib in $cf_regex_libs
6536                 do
6537                         AC_CHECK_LIB($cf_regex_lib,regcomp,[
6538                                         CF_ADD_LIB($cf_regex_lib)
6539                                         cf_regex_func=regcomp
6540                                         break])
6541                 done
6542         ])
6543         ;;
6544 esac
6545
6546 if test "$cf_regex_func" = no ; then
6547         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
6548                 AC_CHECK_LIB(gen,compile,[
6549                                 CF_ADD_LIB(gen)
6550                                 cf_regex_func=compile])])
6551 fi
6552
6553 if test "$cf_regex_func" = no ; then
6554         AC_MSG_WARN(cannot find regular expression library)
6555 fi
6556
6557 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
6558
6559 cf_cv_regex_hdrs=no
6560 case $cf_regex_func in
6561 (compile)
6562         for cf_regex_hdr in regexp.h regexpr.h
6563         do
6564                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
6565                         char *p = compile("", "", "", 0);
6566                         int x = step("", "");
6567                         (void)p;
6568                         (void)x;
6569                 ],[
6570                         cf_cv_regex_hdrs=$cf_regex_hdr
6571                         break
6572                 ])
6573         done
6574         ;;
6575 (*)
6576         for cf_regex_hdr in regex.h
6577         do
6578                 AC_TRY_LINK([#include <sys/types.h>
6579 #include <$cf_regex_hdr>],[
6580                         regex_t *p = 0;
6581                         int x = regcomp(p, "", 0);
6582                         int y = regexec(p, "", 0, 0, 0);
6583                         (void)x;
6584                         (void)y;
6585                         regfree(p);
6586                 ],[
6587                         cf_cv_regex_hdrs=$cf_regex_hdr
6588                         break
6589                 ])
6590         done
6591         ;;
6592 esac
6593
6594 ])
6595
6596 case $cf_cv_regex_hdrs in
6597         (no)            AC_MSG_WARN(no regular expression header found) ;;
6598         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
6599         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
6600         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
6601 esac
6602 ])dnl
6603 dnl ---------------------------------------------------------------------------
6604 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
6605 dnl ----------------
6606 dnl Remove all -U and -D options that refer to the given symbol from a list
6607 dnl of C compiler options.  This works around the problem that not all
6608 dnl compilers process -U and -D options from left-to-right, so a -U option
6609 dnl cannot be used to cancel the effect of a preceding -D option.
6610 dnl
6611 dnl $1 = target (which could be the same as the source variable)
6612 dnl $2 = source (including '$')
6613 dnl $3 = symbol to remove
6614 define([CF_REMOVE_DEFINE],
6615 [
6616 $1=`echo "$2" | \
6617         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
6618                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
6619 ])dnl
6620 dnl ---------------------------------------------------------------------------
6621 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
6622 dnl -------------
6623 dnl Remove the given library from the symbol
6624 dnl
6625 dnl $1 = target (which could be the same as the source variable)
6626 dnl $2 = source (including '$')
6627 dnl $3 = library to remove
6628 define([CF_REMOVE_LIB],
6629 [
6630 # remove $3 library from $2
6631 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
6632 ])dnl
6633 dnl ---------------------------------------------------------------------------
6634 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
6635 dnl ---------------------
6636 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
6637 dnl $1 = name of current macro
6638 define([CF_RESTORE_XTRA_FLAGS],
6639 [
6640 LIBS="$cf_save_LIBS_$1"
6641 CFLAGS="$cf_save_CFLAGS_$1"
6642 CPPFLAGS="$cf_save_CPPFLAGS_$1"
6643 ])dnl
6644 dnl ---------------------------------------------------------------------------
6645 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
6646 dnl -------------
6647 AC_DEFUN([CF_RPATH_HACK],
6648 [
6649 AC_REQUIRE([CF_LD_RPATH_OPT])
6650 AC_MSG_CHECKING(for updated LDFLAGS)
6651 if test -n "$LD_RPATH_OPT" ; then
6652         AC_MSG_RESULT(maybe)
6653
6654         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
6655         cf_rpath_list="/usr/lib /lib"
6656         if test "$cf_ldd_prog" != no
6657         then
6658                 cf_rpath_oops=
6659
6660 AC_TRY_LINK([#include <stdio.h>],
6661                 [printf("Hello");],
6662                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
6663                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
6664
6665                 # If we passed the link-test, but get a "not found" on a given library,
6666                 # this could be due to inept reconfiguration of gcc to make it only
6667                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
6668                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
6669                 # /usr/local libraries.
6670                 if test -n "$cf_rpath_oops"
6671                 then
6672                         for cf_rpath_src in $cf_rpath_oops
6673                         do
6674                                 for cf_rpath_dir in \
6675                                         /usr/local \
6676                                         /usr/pkg \
6677                                         /opt/sfw
6678                                 do
6679                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
6680                                         then
6681                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
6682                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
6683                                                 break
6684                                         fi
6685                                 done
6686                         done
6687                 fi
6688         fi
6689
6690         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
6691
6692         CF_RPATH_HACK_2(LDFLAGS)
6693         CF_RPATH_HACK_2(LIBS)
6694
6695         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
6696 else
6697         AC_MSG_RESULT(no)
6698 fi
6699 AC_SUBST(EXTRA_LDFLAGS)
6700 ])dnl
6701 dnl ---------------------------------------------------------------------------
6702 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
6703 dnl ---------------
6704 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
6705 dnl EXTRA_LDFLAGS for each -L option found.
6706 dnl
6707 dnl $cf_rpath_list contains a list of directories to ignore.
6708 dnl
6709 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
6710 dnl      but LIBS often has misplaced -L options.
6711 AC_DEFUN([CF_RPATH_HACK_2],
6712 [
6713 CF_VERBOSE(...checking $1 [$]$1)
6714
6715 cf_rpath_dst=
6716 for cf_rpath_src in [$]$1
6717 do
6718         case $cf_rpath_src in
6719         (-L*)
6720
6721                 # check if this refers to a directory which we will ignore
6722                 cf_rpath_skip=no
6723                 if test -n "$cf_rpath_list"
6724                 then
6725                         for cf_rpath_item in $cf_rpath_list
6726                         do
6727                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
6728                                 then
6729                                         cf_rpath_skip=yes
6730                                         break
6731                                 fi
6732                         done
6733                 fi
6734
6735                 if test "$cf_rpath_skip" = no
6736                 then
6737                         # transform the option
6738                         if test "$LD_RPATH_OPT" = "-R " ; then
6739                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
6740                         else
6741                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
6742                         fi
6743
6744                         # if we have not already added this, add it now
6745                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
6746                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
6747                         then
6748                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
6749                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
6750                         fi
6751                 fi
6752                 ;;
6753         esac
6754         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
6755 done
6756 $1=$cf_rpath_dst
6757
6758 CF_VERBOSE(...checked $1 [$]$1)
6759 AC_SUBST(EXTRA_LDFLAGS)
6760 ])dnl
6761 dnl ---------------------------------------------------------------------------
6762 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
6763 dnl ------------------
6764 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
6765 dnl and libraries which do not update those variables.
6766 dnl
6767 dnl $1 = name of current macro
6768 define([CF_SAVE_XTRA_FLAGS],
6769 [
6770 cf_save_LIBS_$1="$LIBS"
6771 cf_save_CFLAGS_$1="$CFLAGS"
6772 cf_save_CPPFLAGS_$1="$CPPFLAGS"
6773 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
6774 for cf_X_CFLAGS in $X_CFLAGS
6775 do
6776         case "x$cf_X_CFLAGS" in
6777         x-[[IUD]]*)
6778                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
6779                 ;;
6780         *)
6781                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
6782                 ;;
6783         esac
6784 done
6785 ])dnl
6786 dnl ---------------------------------------------------------------------------
6787 dnl CF_SHARED_OPTS version: 102 updated: 2020/08/22 18:17:19
6788 dnl --------------
6789 dnl --------------
6790 dnl Attempt to determine the appropriate CC/LD options for creating a shared
6791 dnl library.
6792 dnl
6793 dnl Notes:
6794 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
6795 dnl the build-tree, i.e., by making use of the libraries that are compiled in
6796 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
6797 dnl shared library since that can lead to unexpected results at runtime.
6798 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
6799 dnl libraries are compiled in ../../lib
6800 dnl
6801 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
6802 dnl to install symbolic links to the rel/abi versions of shared libraries.
6803 dnl
6804 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
6805 dnl version when making symbolic links.
6806 dnl
6807 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
6808 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
6809 dnl (ex: libncurses.so.<ver>).
6810 dnl
6811 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
6812 AC_DEFUN([CF_SHARED_OPTS],
6813 [
6814         AC_REQUIRE([CF_LD_RPATH_OPT])
6815
6816         RM_SHARED_OPTS=
6817         LOCAL_LDFLAGS=
6818         LOCAL_LDFLAGS2=
6819         LD_SHARED_OPTS=
6820         INSTALL_LIB="-m 644"
6821         : ${rel_builddir:=.}
6822
6823         shlibdir=$libdir
6824         AC_SUBST(shlibdir)
6825
6826         MAKE_DLLS="#"
6827         AC_SUBST(MAKE_DLLS)
6828
6829         cf_cv_do_symlinks=no
6830         cf_ld_rpath_opt=
6831         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
6832
6833         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
6834         AC_ARG_WITH(shlib-version,
6835         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
6836         [test -z "$withval" && withval=auto
6837         case $withval in
6838         (yes)
6839                 cf_cv_shlib_version=auto
6840                 ;;
6841         (rel|abi|auto)
6842                 cf_cv_shlib_version=$withval
6843                 ;;
6844         (*)
6845                 AC_MSG_RESULT($withval)
6846                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
6847                 ;;
6848         esac
6849         ],[cf_cv_shlib_version=auto])
6850         AC_MSG_RESULT($cf_cv_shlib_version)
6851
6852         cf_cv_rm_so_locs=no
6853         cf_try_cflags=
6854
6855         # Some less-capable ports of gcc support only -fpic
6856         CC_SHARED_OPTS=
6857
6858         cf_try_fPIC=no
6859         if test "$GCC" = yes
6860         then
6861                 cf_try_fPIC=yes
6862         else
6863                 case $cf_cv_system_name in
6864                 (*linux*)       # e.g., PGI compiler
6865                         cf_try_fPIC=yes
6866                         ;;
6867                 esac
6868         fi
6869
6870         if test "$cf_try_fPIC" = yes
6871         then
6872                 AC_MSG_CHECKING(which $CC option to use)
6873                 cf_save_CFLAGS="$CFLAGS"
6874                 for CC_SHARED_OPTS in -fPIC -fpic ''
6875                 do
6876                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
6877                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
6878                 done
6879                 AC_MSG_RESULT($CC_SHARED_OPTS)
6880                 CFLAGS="$cf_save_CFLAGS"
6881         fi
6882
6883         cf_cv_shlib_version_infix=no
6884
6885         case $cf_cv_system_name in
6886         (aix4.[3-9]*|aix[[5-7]]*)
6887                 if test "$GCC" = yes; then
6888                         CC_SHARED_OPTS='-Wl,-brtl'
6889                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6890                 else
6891                         CC_SHARED_OPTS='-brtl'
6892                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
6893                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6894                 fi
6895                 ;;
6896         (beos*)
6897                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
6898                 ;;
6899         (cygwin*)
6900                 CC_SHARED_OPTS=
6901                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6902                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6903                 cf_cv_shlib_version=cygdll
6904                 cf_cv_shlib_version_infix=cygdll
6905                 shlibdir=$bindir
6906                 MAKE_DLLS=
6907                 cat >mk_shared_lib.sh <<-CF_EOF
6908                 #!$SHELL
6909                 SHARED_LIB=\[$]1
6910                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6911                 shift
6912                 cat <<-EOF
6913                 Linking shared library
6914                 ** SHARED_LIB \[$]SHARED_LIB
6915                 ** IMPORT_LIB \[$]IMPORT_LIB
6916 EOF
6917                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6918 CF_EOF
6919                 chmod +x mk_shared_lib.sh
6920                 ;;
6921         (msys*)
6922                 CC_SHARED_OPTS=
6923                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6924                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6925                 cf_cv_shlib_version=msysdll
6926                 cf_cv_shlib_version_infix=msysdll
6927                 shlibdir=$bindir
6928                 MAKE_DLLS=
6929                 cat >mk_shared_lib.sh <<-CF_EOF
6930                 #!$SHELL
6931                 SHARED_LIB=\[$]1
6932                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6933                 shift
6934                 cat <<-EOF
6935                 Linking shared library
6936                 ** SHARED_LIB \[$]SHARED_LIB
6937                 ** IMPORT_LIB \[$]IMPORT_LIB
6938 EOF
6939                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6940 CF_EOF
6941                 chmod +x mk_shared_lib.sh
6942                 ;;
6943         (darwin*)
6944                 cf_try_cflags="no-cpp-precomp"
6945                 CC_SHARED_OPTS="-dynamic"
6946                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
6947                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
6948                 cf_cv_shlib_version_infix=yes
6949                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
6950                         cf_save_LDFLAGS=$LDFLAGS
6951                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
6952                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
6953                                 LDFLAGS=$cf_save_LDFLAGS])
6954                 if test $cf_cv_ldflags_search_paths_first = yes; then
6955                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
6956                 fi
6957                 ;;
6958         (hpux[[7-8]]*)
6959                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
6960                 if test "$GCC" != yes; then
6961                         CC_SHARED_OPTS='+Z'
6962                 fi
6963                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
6964                 INSTALL_LIB="-m 555"
6965                 ;;
6966         (hpux*)
6967                 # (tested with gcc 2.7.2 -- I don't have c89)
6968                 if test "$GCC" = yes; then
6969                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
6970                 else
6971                         CC_SHARED_OPTS='+Z'
6972                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
6973                 fi
6974                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
6975                 # HP-UX shared libraries must be executable, and should be
6976                 # readonly to exploit a quirk in the memory manager.
6977                 INSTALL_LIB="-m 555"
6978                 ;;
6979         (interix*)
6980                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6981                 if test "$cf_cv_shlib_version" = rel; then
6982                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
6983                 else
6984                         cf_shared_soname='`basename $[@]`'
6985                 fi
6986                 CC_SHARED_OPTS=
6987                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
6988                 ;;
6989         (irix*)
6990                 if test "$cf_cv_enable_rpath" = yes ; then
6991                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6992                 fi
6993                 # tested with IRIX 5.2 and 'cc'.
6994                 if test "$GCC" != yes; then
6995                         CC_SHARED_OPTS='-KPIC'
6996                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
6997                 else
6998                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
6999                 fi
7000                 cf_cv_rm_so_locs=yes
7001                 ;;
7002         (linux*|gnu*|k*bsd*-gnu)
7003                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7004                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7005                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7006                 fi
7007                 if test "$cf_cv_enable_rpath" = yes ; then
7008                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7009                 fi
7010                 CF_SHARED_SONAME
7011                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7012                 ;;
7013         (mingw*msvc*)
7014                 cf_cv_shlib_version=msvcdll
7015                 cf_cv_shlib_version_infix=msvcdll
7016                 shlibdir=$bindir
7017                 MAKE_DLLS=
7018                 if test "$DFT_LWR_MODEL" = "shared" ; then
7019                         LOCAL_LDFLAGS="-link -dll"
7020                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7021                         EXTRA_LDFLAGS="-link -dll $EXTRA_LDFLAGS"
7022                 fi
7023                 CC_SHARED_OPTS=
7024                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ ${LD} [$]{CFLAGS}'
7025                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.lib"
7026                 cat >mk_shared_lib.sh <<-CF_EOF
7027                 #!$SHELL
7028                 SHARED_LIB=\[$]1
7029                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.lib/'\`
7030                 shift
7031                 my_ld=\[$]1
7032                 shift
7033                 cat <<-EOF
7034                 Linking shared library
7035                 ** SHARED LIB \$SHARED_LIB
7036                 ** IMPORT_LIB \$IMPORT_LIB
7037 EOF
7038                 args=\$(echo \[$]* | sed -E "s#-l(\w*)#\1.dll.lib#g" | sed -E "s#-L(\w*)#-LIBPATH:\1#g")
7039                 exec \$my_ld -DLL -IMPLIB:"\${IMPORT_LIB}" -OUT:"\${SHARED_LIB}" ${LDFLAGS} \$args
7040                 mv "\${IMPORT_LIB}" "\${IMPORT_LIB}"
7041 CF_EOF
7042                 chmod +x mk_shared_lib.sh
7043                 cat >mk_prog.sh <<-CF_EOF
7044                 #!$SHELL
7045                 shift
7046                 # Ignore first argument (compiler) and use LD (link.exe) unconditionally
7047                 LD="[$]LD"
7048                 clopts=()
7049                 ldopts=("/subsystem:console")
7050                 libs=()
7051                 isdll=0
7052                 while test \[$]# -gt 0; do
7053                         case "\[$]1" in
7054                                 -link)
7055                                         # ignore -link argument
7056                                         ;;
7057                                 -M[[TD]] | -M[[TD]]d)
7058                                         # ignore runtime-library option
7059                                         ;;
7060                                 -dll)
7061                                         isdll=1
7062                                         ;;
7063                                 -W* | -w*)
7064                                         # ignore warnings
7065                                         ;;
7066                                 -D*)
7067                                         clopts+=("\[$]1")
7068                                         ;;
7069                                 -I*)
7070                                         clopts+=("\[$]1")
7071                                         ;;
7072                                 -l*)
7073                                         libs+=("\`echo \"\[$]1\" | sed \"s/^-l//\"\`")
7074                                         ;;
7075                                 -L*)
7076                                         ldopts+=("\`echo \"\[$]1\" | sed \"s/^-L/-LIBPATH:/\"\`")
7077                                         ;;
7078                                 *.obj | *.o)
7079                                         ldopts+=("\[$]1")
7080                                         ;;
7081                                 -Wl,*)
7082                                         for linkarg in \`echo '\[$]1' | sed -e 's/-Wl,//' -e 's/,/ /'\`; do
7083                                                 ldopts+=("\[$]{linkarg}")
7084                                         done
7085                                         ;;
7086                                 *.lib)
7087                                         ldopts+=("\[$]1")
7088                                         ;;
7089                                 -o)
7090                                         shift
7091                                         ldopts+=("-out:\[$]1")
7092                                         ;;
7093                                 *)
7094                                         clopts+=("\[$]1")
7095                                         ldopts+=("\[$]1")
7096                                         ;;
7097                         esac
7098                         shift
7099                 done
7100                 if [[ "\$isdll" -ne 0 ]]; then
7101                         for lib in \[$]{libs[[*]]}; do
7102                                 ldopts+=("\[$]lib.dll.lib")
7103                         done
7104                 else
7105                         for lib in \[$]{libs[[*]]}; do
7106                                 ldopts+=("\[$]lib.lib")
7107                         done
7108                 fi
7109                 cat <<-EOF
7110                 Creating program
7111                 ** ld options:   "\[$]{ldopts[[@]]}"
7112 EOF
7113                 exec \[$]LD \[$]{ldopts[[@]]}
7114 CF_EOF
7115                 chmod +x mk_prog.sh
7116                 LINK_PROGS="$SHELL ${rel_builddir}/mk_prog.sh"
7117                 LINK_TESTS="$SHELL ${rel_builddir}/mk_prog.sh"
7118                 ;;
7119         (mingw*)
7120                 cf_cv_shlib_version=mingw
7121                 cf_cv_shlib_version_infix=mingw
7122                 shlibdir=$bindir
7123                 MAKE_DLLS=
7124                 if test "$DFT_LWR_MODEL" = "shared" ; then
7125                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
7126                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7127                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
7128                 fi
7129                 CC_SHARED_OPTS=
7130                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7131                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7132                 cat >mk_shared_lib.sh <<-CF_EOF
7133                 #!$SHELL
7134                 SHARED_LIB=\[$]1
7135                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7136                 shift
7137                 cat <<-EOF
7138                 Linking shared library
7139                 ** SHARED_LIB \[$]SHARED_LIB
7140                 ** IMPORT_LIB \[$]IMPORT_LIB
7141 EOF
7142                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7143 CF_EOF
7144                 chmod +x mk_shared_lib.sh
7145                 ;;
7146         (openbsd[[2-9]].*|mirbsd*)
7147                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7148                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7149                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7150                 fi
7151                 if test "$cf_cv_enable_rpath" = yes ; then
7152                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7153                 fi
7154                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7155                 CF_SHARED_SONAME
7156                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7157                 ;;
7158         (nskJ*)
7159                 CC_SHARED_OPTS=
7160                 MK_SHARED_LIB='${LD} -Wshared -Weld=-export_all -o $[@]'
7161                 ;;
7162         (nskL*)
7163                 CC_SHARED_OPTS=
7164                 MK_SHARED_LIB='${LD} -Wshared -Wxld=-export_all -o $[@]'
7165                 ;;
7166         (nto-qnx*|openbsd*|freebsd[[12]].*)
7167                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7168                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
7169                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7170                 ;;
7171         (dragonfly*|freebsd*)
7172                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7173                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7174                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7175                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
7176                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7177                 fi
7178                 CF_SHARED_SONAME
7179                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7180                 ;;
7181         (netbsd*)
7182                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7183                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7184                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7185                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7186                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7187                         if test "$cf_cv_shlib_version" = auto; then
7188                         if test -f /usr/libexec/ld.elf_so; then
7189                                 cf_cv_shlib_version=abi
7190                         else
7191                                 cf_cv_shlib_version=rel
7192                         fi
7193                         fi
7194                         CF_SHARED_SONAME
7195                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
7196                 else
7197                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -o $[@]'
7198                 fi
7199                 ;;
7200         (osf*|mls+*)
7201                 # tested with OSF/1 V3.2 and 'cc'
7202                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
7203                 # link with shared libs).
7204                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
7205                 case $host_os in
7206                 (osf4*)
7207                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
7208                         ;;
7209                 esac
7210                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
7211                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7212                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7213                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7214                 fi
7215                 cf_cv_rm_so_locs=yes
7216                 ;;
7217         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
7218                 # tested with osr5.0.5
7219                 if test "$GCC" != yes; then
7220                         CC_SHARED_OPTS='-belf -KPIC'
7221                 fi
7222                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
7223                 if test "$cf_cv_enable_rpath" = yes ; then
7224                         # only way is to set LD_RUN_PATH but no switch for it
7225                         RUN_PATH=$libdir
7226                 fi
7227                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7228                 LINK_PROGS='LD_RUN_PATH=${libdir}'
7229                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
7230                 ;;
7231         (sunos4*)
7232                 # tested with SunOS 4.1.1 and gcc 2.7.0
7233                 if test "$GCC" != yes; then
7234                         CC_SHARED_OPTS='-KPIC'
7235                 fi
7236                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
7237                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7238                 ;;
7239         (solaris2*)
7240                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
7241                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
7242                 if test "$DFT_LWR_MODEL" = "shared" ; then
7243                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
7244                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7245                 fi
7246                 if test "$cf_cv_enable_rpath" = yes ; then
7247                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
7248                 fi
7249                 CF_SHARED_SONAME
7250                 if test "$GCC" != yes; then
7251                         cf_save_CFLAGS="$CFLAGS"
7252                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
7253                         do
7254                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
7255                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
7256                         done
7257                         CFLAGS="$cf_save_CFLAGS"
7258                         CC_SHARED_OPTS=$cf_shared_opts
7259                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7260                 else
7261                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7262                 fi
7263                 ;;
7264         (sysv5uw7*|unix_sv*)
7265                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
7266                 if test "$GCC" != yes; then
7267                         CC_SHARED_OPTS='-KPIC'
7268                 fi
7269                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
7270                 ;;
7271         (*)
7272                 CC_SHARED_OPTS='unknown'
7273                 MK_SHARED_LIB='echo unknown'
7274                 ;;
7275         esac
7276
7277         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
7278         case "$cf_cv_shlib_version" in
7279         (rel|abi)
7280                 case "$MK_SHARED_LIB" in
7281                 (*'-o $[@]')
7282                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
7283                         ;;
7284                 (*)
7285                         AC_MSG_WARN(ignored --with-shlib-version)
7286                         ;;
7287                 esac
7288                 ;;
7289         esac
7290
7291         if test -n "$cf_try_cflags"
7292         then
7293 cat > conftest.$ac_ext <<EOF
7294 #line __oline__ "${as_me:-configure}"
7295 #include <stdio.h>
7296 int main(int argc, char *argv[[]])
7297 {
7298         printf("hello\n");
7299         return (argv[[argc-1]] == 0) ;
7300 }
7301 EOF
7302                 cf_save_CFLAGS="$CFLAGS"
7303                 for cf_opt in $cf_try_cflags
7304                 do
7305                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
7306                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
7307                         if AC_TRY_EVAL(ac_compile); then
7308                                 AC_MSG_RESULT(yes)
7309                                 cf_save_CFLAGS="$CFLAGS"
7310                         else
7311                                 AC_MSG_RESULT(no)
7312                         fi
7313                 done
7314                 CFLAGS="$cf_save_CFLAGS"
7315         fi
7316
7317
7318         # RPATH_LIST is a colon-separated list of directories
7319         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
7320         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
7321
7322         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
7323
7324         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
7325         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7326
7327         AC_SUBST(CC_SHARED_OPTS)
7328         AC_SUBST(LD_RPATH_OPT)
7329         AC_SUBST(LD_SHARED_OPTS)
7330         AC_SUBST(MK_SHARED_LIB)
7331         AC_SUBST(RM_SHARED_OPTS)
7332
7333         AC_SUBST(LINK_PROGS)
7334         AC_SUBST(LINK_TESTS)
7335
7336         AC_SUBST(EXTRA_LDFLAGS)
7337         AC_SUBST(LOCAL_LDFLAGS)
7338         AC_SUBST(LOCAL_LDFLAGS2)
7339
7340         AC_SUBST(INSTALL_LIB)
7341         AC_SUBST(RPATH_LIST)
7342 ])dnl
7343 dnl ---------------------------------------------------------------------------
7344 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
7345 dnl ----------------
7346 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
7347 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
7348 dnl option.
7349 dnl
7350 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
7351 dnl If missing, use "rel".
7352 define([CF_SHARED_SONAME],
7353 [
7354         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
7355         if test "$cf_cv_shlib_version" = rel; then
7356                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
7357         else
7358                 cf_cv_shared_soname='`basename $[@]`'
7359         fi
7360 ])
7361 dnl ---------------------------------------------------------------------------
7362 dnl CF_SIGWINCH version: 3 updated: 2020/03/10 18:53:47
7363 dnl -----------
7364 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
7365 dnl programs need this test).
7366 dnl
7367 dnl This is really a Mac OS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
7368 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
7369 dnl winsize declaration is left alone - we may revisit this if Apple choose to
7370 dnl break that part of the interface as well.
7371 AC_DEFUN([CF_SIGWINCH],
7372 [
7373 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
7374         AC_TRY_COMPILE([
7375 #include <sys/types.h>
7376 #include <sys/signal.h>
7377 ],[int x = SIGWINCH; (void)x],
7378         [cf_cv_define_sigwinch=yes],
7379         [AC_TRY_COMPILE([
7380 #undef _XOPEN_SOURCE
7381 #undef _POSIX_SOURCE
7382 #undef _POSIX_C_SOURCE
7383 #include <sys/types.h>
7384 #include <sys/signal.h>
7385 ],[int x = SIGWINCH; (void)x],
7386         [cf_cv_define_sigwinch=maybe],
7387         [cf_cv_define_sigwinch=no])
7388 ])
7389 ])
7390
7391 if test "$cf_cv_define_sigwinch" = maybe ; then
7392 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
7393 cf_cv_fixup_sigwinch=unknown
7394 cf_sigwinch=32
7395 while test $cf_sigwinch != 1
7396 do
7397         AC_TRY_COMPILE([
7398 #undef _XOPEN_SOURCE
7399 #undef _POSIX_SOURCE
7400 #undef _POSIX_C_SOURCE
7401 #include <sys/types.h>
7402 #include <sys/signal.h>
7403 ],[
7404 #if SIGWINCH != $cf_sigwinch
7405 make an error
7406 #endif
7407 int x = SIGWINCH; (void)x],
7408         [cf_cv_fixup_sigwinch=$cf_sigwinch
7409          break])
7410
7411 cf_sigwinch=`expr $cf_sigwinch - 1`
7412 done
7413 ])
7414
7415         if test "$cf_cv_fixup_sigwinch" != unknown ; then
7416                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
7417         fi
7418 fi
7419 ])dnl
7420 dnl ---------------------------------------------------------------------------
7421 dnl CF_SIG_ATOMIC_T version: 5 updated: 2020/03/10 18:53:47
7422 dnl ---------------
7423 dnl signal handler, but there are some gcc dependencies in that recommendation.
7424 dnl Try anyway.
7425 AC_DEFUN([CF_SIG_ATOMIC_T],
7426 [
7427 AC_MSG_CHECKING(for signal global datatype)
7428 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
7429         for cf_type in \
7430                 "volatile sig_atomic_t" \
7431                 "sig_atomic_t" \
7432                 "int"
7433         do
7434         AC_TRY_COMPILE([
7435 #include <sys/types.h>
7436 #include <signal.h>
7437 #include <stdio.h>
7438
7439 extern $cf_type x;
7440 $cf_type x;
7441 static void handler(int sig)
7442 {
7443         (void)sig;
7444         x = 5;
7445 }],
7446                 [signal(SIGINT, handler);
7447                  x = 1],
7448                 [cf_cv_sig_atomic_t=$cf_type],
7449                 [cf_cv_sig_atomic_t=no])
7450                 test "$cf_cv_sig_atomic_t" != no && break
7451         done
7452         ])
7453 AC_MSG_RESULT($cf_cv_sig_atomic_t)
7454 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
7455 ])dnl
7456 dnl ---------------------------------------------------------------------------
7457 dnl CF_SIZECHANGE version: 16 updated: 2020/03/19 20:46:13
7458 dnl -------------
7459 dnl Check for definitions & structures needed for window size-changing
7460 dnl
7461 dnl https://stackoverflow.com/questions/18878141/difference-between-structures-ttysize-and-winsize/50769952#50769952
7462 AC_DEFUN([CF_SIZECHANGE],
7463 [
7464 AC_REQUIRE([CF_STRUCT_TERMIOS])
7465 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
7466         cf_cv_sizechange=unknown
7467         cf_save_CPPFLAGS="$CPPFLAGS"
7468
7469 for cf_opts in "" "NEED_PTEM_H"
7470 do
7471
7472         CPPFLAGS="$cf_save_CPPFLAGS"
7473         if test -n "$cf_opts"
7474         then
7475                 CF_APPEND_TEXT(CPPFLAGS,-D$cf_opts)
7476         fi
7477         AC_TRY_COMPILE([#include <sys/types.h>
7478 #ifdef HAVE_TERMIOS_H
7479 #include <termios.h>
7480 #else
7481 #ifdef HAVE_TERMIO_H
7482 #include <termio.h>
7483 #endif
7484 #endif
7485
7486 #ifdef NEED_PTEM_H
7487 /* This is a workaround for SCO:  they neglected to define struct winsize in
7488  * termios.h -- it's only in termio.h and ptem.h
7489  */
7490 #include <sys/stream.h>
7491 #include <sys/ptem.h>
7492 #endif
7493
7494 #ifdef HAVE_SYS_IOCTL_H
7495 #include <sys/ioctl.h>
7496 #endif
7497 ],[
7498 #ifdef TIOCGSIZE
7499         struct ttysize win;     /* SunOS 3.0... */
7500         int y = win.ts_lines = 2;
7501         int x = win.ts_cols = 1;
7502         (void)y;
7503         (void)x;
7504 #else
7505 #ifdef TIOCGWINSZ
7506         struct winsize win;     /* everything else */
7507         int y = win.ws_row = 2;
7508         int x = win.ws_col = 1;
7509         (void)y;
7510         (void)x;
7511 #else
7512         no TIOCGSIZE or TIOCGWINSZ
7513 #endif /* TIOCGWINSZ */
7514 #endif /* TIOCGSIZE */
7515         ],
7516         [cf_cv_sizechange=yes],
7517         [cf_cv_sizechange=no])
7518
7519         CPPFLAGS="$cf_save_CPPFLAGS"
7520         if test "$cf_cv_sizechange" = yes ; then
7521                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
7522                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
7523                 break
7524         fi
7525 done
7526 ])
7527 if test "$cf_cv_sizechange" != no ; then
7528         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechange declarations are provided])
7529         case $cf_cv_sizechange in
7530         (NEED*)
7531                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
7532                 ;;
7533         esac
7534 fi
7535 ])dnl
7536 dnl ---------------------------------------------------------------------------
7537 dnl CF_SRC_MODULES version: 32 updated: 2020/03/07 20:05:14
7538 dnl --------------
7539 dnl For each parameter, test if the source-directory exists, and if it contains
7540 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
7541 dnl use in CF_LIB_RULES.
7542 dnl
7543 dnl This uses the configured value to make the lists SRC_SUBDIRS and
7544 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
7545 AC_DEFUN([CF_SRC_MODULES],
7546 [
7547 AC_REQUIRE([CF_CHECK_GNAT_VERSION])
7548 AC_MSG_CHECKING(for src modules)
7549
7550 # dependencies and linker-arguments for test-programs
7551 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
7552 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
7553 if test "$DFT_LWR_MODEL" = "libtool"; then
7554         TEST_ARGS="${TEST_DEPS}"
7555         TEST_ARG2="${TEST_DEP2}"
7556 else
7557         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
7558         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
7559 fi
7560
7561 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
7562 cf_cv_src_modules=
7563 for cf_dir in $1
7564 do
7565         if test -f $srcdir/$cf_dir/modules; then
7566
7567                 # We may/may not have tack in the distribution, though the
7568                 # makefile is.
7569                 if test $cf_dir = tack ; then
7570                         if test "x$cf_with_tack" != "xyes"; then
7571                                 continue
7572                         fi
7573                 fi
7574
7575                 if test -z "$cf_cv_src_modules"; then
7576                         cf_cv_src_modules=$cf_dir
7577                 else
7578                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
7579                 fi
7580
7581                 # Make the ncurses_cfg.h file record the library interface files as
7582                 # well.  These are header files that are the same name as their
7583                 # directory.  Ncurses is the only library that does not follow
7584                 # that pattern.
7585                 if test $cf_dir = tack ; then
7586                         continue
7587                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
7588                         CF_UPPER(cf_have_include,$cf_dir)
7589                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
7590                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
7591                         CF_MAP_LIB_BASENAME(TEST_ROOT,$cf_dir)
7592                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEPS"
7593                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEP2"
7594                         if test "$DFT_LWR_MODEL" = "libtool"; then
7595                                 TEST_ARGS="${TEST_DEPS}"
7596                                 TEST_ARG2="${TEST_DEP2}"
7597                         else
7598                                 TEST_ARGS="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARGS"
7599                                 TEST_ARG2="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARG2"
7600                         fi
7601                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
7602                 fi
7603         fi
7604 done
7605 AC_MSG_RESULT($cf_cv_src_modules)
7606
7607 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
7608 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
7609
7610 AC_SUBST(TEST_ARGS)
7611 AC_SUBST(TEST_DEPS)
7612
7613 AC_SUBST(TEST_ARG2)
7614 AC_SUBST(TEST_DEP2)
7615
7616 SRC_SUBDIRS=
7617 if test "x$cf_with_manpages" != xno ; then
7618         SRC_SUBDIRS="$SRC_SUBDIRS man"
7619 fi
7620 SRC_SUBDIRS="$SRC_SUBDIRS include"
7621 for cf_dir in $cf_cv_src_modules
7622 do
7623         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
7624 done
7625 if test "x$cf_with_tests" != "xno" ; then
7626         SRC_SUBDIRS="$SRC_SUBDIRS test"
7627 fi
7628 # always make this, to install the ncurses-config script
7629 SRC_SUBDIRS="$SRC_SUBDIRS misc"
7630 if test "$cf_with_cxx_binding" != no; then
7631         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
7632         SRC_SUBDIRS="$SRC_SUBDIRS c++"
7633 fi
7634
7635 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
7636 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
7637
7638 AC_SUBST(PC_MODULES_TO_MAKE)
7639
7640 ADA_SUBDIRS=
7641 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
7642         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
7643         ADA_SUBDIRS="gen src"
7644         if test "x$cf_with_tests" != "xno" ; then
7645                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
7646         fi
7647 fi
7648
7649 SUB_MAKEFILES=
7650 for cf_dir in $SRC_SUBDIRS
7651 do
7652         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
7653 done
7654
7655 if test -n "$ADA_SUBDIRS"; then
7656         for cf_dir in $ADA_SUBDIRS
7657         do
7658                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
7659         done
7660         AC_SUBST(ADA_SUBDIRS)
7661 fi
7662 ])dnl
7663 dnl ---------------------------------------------------------------------------
7664 dnl CF_STDCPP_LIBRARY version: 11 updated: 2015/10/17 19:03:33
7665 dnl -----------------
7666 dnl Check for -lstdc++, which is GNU's standard C++ library.
7667 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
7668 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
7669 dnl add it to $CXXLIBS.
7670 AC_DEFUN([CF_STDCPP_LIBRARY],
7671 [
7672 if test -n "$GXX" ; then
7673
7674         cf_save="$LIBS"
7675         LIBS="$LIBS $CXXLIBS"
7676         AC_MSG_CHECKING(if we already have C++ library)
7677         AC_TRY_LINK([
7678                         #include <iostream>],[
7679                         std::cout << "Hello World!" << std::endl;],
7680                 [cf_have_libstdcpp=yes],
7681                 [cf_have_libstdcpp=no])
7682         AC_MSG_RESULT($cf_have_libstdcpp)
7683         LIBS="$cf_save"
7684
7685         if test $cf_have_libstdcpp != yes
7686         then
7687                 case $cf_cv_system_name in
7688                 (os2*)
7689                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
7690                                 cf_stdcpp_libname=stdcpp
7691                         else
7692                                 cf_stdcpp_libname=stdc++
7693                         fi
7694                         ;;
7695                 (*)
7696                         cf_stdcpp_libname=stdc++
7697                         ;;
7698                 esac
7699
7700                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
7701                         cf_save="$LIBS"
7702                         LIBS="$LIBS $CXXLIBS"
7703                         CF_ADD_LIB($cf_stdcpp_libname)
7704                 AC_TRY_LINK([
7705                                 #include <iostream>],[
7706                                 std::cout << "Hello World!" << std::endl;],
7707                         [cf_cv_libstdcpp=yes],
7708                         [cf_cv_libstdcpp=no])
7709                         LIBS="$cf_save"
7710                 ])
7711                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
7712         fi
7713 fi
7714 ])dnl
7715 dnl ---------------------------------------------------------------------------
7716 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
7717 dnl --------------
7718 dnl     Remove "-g" option from the compiler options
7719 AC_DEFUN([CF_STRIP_G_OPT],
7720 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
7721 dnl ---------------------------------------------------------------------------
7722 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
7723 dnl -------------------
7724 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
7725 dnl do this if we've found the sigaction function.
7726 AC_DEFUN([CF_STRUCT_SIGACTION],[
7727 AC_REQUIRE([CF_XOPEN_SOURCE])
7728
7729 if test "$ac_cv_func_sigaction" = yes; then
7730 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
7731 AC_TRY_COMPILE([
7732 #include <sys/types.h>
7733 #include <signal.h>],
7734         [struct sigaction act],
7735         [sigact_bad=no],
7736         [
7737 AC_TRY_COMPILE([
7738 #define _POSIX_SOURCE
7739 #include <sys/types.h>
7740 #include <signal.h>],
7741         [struct sigaction act],
7742         [sigact_bad=yes
7743          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
7744          [sigact_bad=unknown])])
7745 AC_MSG_RESULT($sigact_bad)
7746 fi
7747 ])dnl
7748 dnl ---------------------------------------------------------------------------
7749 dnl CF_STRUCT_TERMIOS version: 11 updated: 2020/03/19 20:46:13
7750 dnl -----------------
7751 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
7752 AC_DEFUN([CF_STRUCT_TERMIOS],[
7753 AC_REQUIRE([CF_XOPEN_SOURCE])
7754
7755 AC_CHECK_HEADERS( \
7756 termio.h \
7757 termios.h \
7758 unistd.h \
7759 sys/ioctl.h \
7760 sys/termio.h \
7761 )
7762
7763 if test "$ac_cv_header_termios_h" = yes ; then
7764         case "$CFLAGS $CPPFLAGS" in
7765         (*-D_POSIX_SOURCE*)
7766                 termios_bad=dunno ;;
7767         (*)     termios_bad=maybe ;;
7768         esac
7769         if test "$termios_bad" = maybe ; then
7770         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
7771         AC_TRY_COMPILE([#include <termios.h>],
7772                 [struct termios foo; int x = foo.c_iflag = 1; (void)x],
7773                 termios_bad=no, [
7774                 AC_TRY_COMPILE([
7775 #define _POSIX_SOURCE
7776 #include <termios.h>],
7777                         [struct termios foo; int x = foo.c_iflag = 2; (void)x],
7778                         termios_bad=unknown,
7779                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
7780                         ])
7781         AC_MSG_RESULT($termios_bad)
7782         fi
7783 fi
7784 ])dnl
7785 dnl ---------------------------------------------------------------------------
7786 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
7787 dnl --------------
7788 dnl Construct a search-list for a nonstandard header/lib-file
7789 dnl     $1 = the variable to return as result
7790 dnl     $2 = the package name
7791 dnl     $3 = the subdirectory, e.g., bin, include or lib
7792 AC_DEFUN([CF_SUBDIR_PATH],
7793 [
7794 $1=
7795
7796 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
7797
7798 for cf_subdir_prefix in \
7799         /usr \
7800         /usr/local \
7801         /usr/pkg \
7802         /opt \
7803         /opt/local \
7804         [$]HOME
7805 do
7806         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
7807 done
7808 ])dnl
7809 dnl ---------------------------------------------------------------------------
7810 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
7811 dnl -----------
7812 dnl     Shorthand macro for substituting things that the user may override
7813 dnl     with an environment variable.
7814 dnl
7815 dnl     $1 = condition to pass to "test"
7816 dnl     $2 = environment variable
7817 dnl     $3 = value if the test succeeds
7818 dnl     $4 = value if the test fails
7819 AC_DEFUN([CF_SUBST_IF],
7820 [
7821 if test $1 ; then
7822         $2=$3
7823 ifelse($4,,,[else
7824         $2=$4])
7825 fi
7826 AC_SUBST($2)
7827 ])dnl
7828 dnl ---------------------------------------------------------------------------
7829 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
7830 dnl ------------------------
7831 dnl Get the version-number for use in shared-library naming, etc.
7832 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
7833 [
7834 AC_REQUIRE([CF_PROG_EGREP])
7835 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7836 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7837 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7838 cf_cv_abi_version=${NCURSES_MAJOR}
7839 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
7840 dnl Show the computed version, for logging
7841 cf_cv_timestamp=`date`
7842 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
7843 dnl We need these values in the generated headers
7844 AC_SUBST(NCURSES_MAJOR)
7845 AC_SUBST(NCURSES_MINOR)
7846 AC_SUBST(NCURSES_PATCH)
7847 dnl We need these values in the generated makefiles
7848 AC_SUBST(cf_cv_rel_version)
7849 AC_SUBST(cf_cv_abi_version)
7850 AC_SUBST(cf_cv_builtin_bool)
7851 AC_SUBST(cf_cv_header_stdbool_h)
7852 AC_SUBST(cf_cv_type_of_bool)dnl
7853 ])dnl
7854 dnl ---------------------------------------------------------------------------
7855 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
7856 dnl ------------------
7857 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
7858 dnl older SCO configurations.
7859 AC_DEFUN([CF_SYS_TIME_SELECT],
7860 [
7861 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
7862 AC_CACHE_VAL(cf_cv_sys_time_select,[
7863 AC_TRY_COMPILE([
7864 #include <sys/types.h>
7865 #ifdef HAVE_SYS_TIME_H
7866 #include <sys/time.h>
7867 #endif
7868 #ifdef HAVE_SYS_SELECT_H
7869 #include <sys/select.h>
7870 #endif
7871 ],[],[cf_cv_sys_time_select=yes],
7872          [cf_cv_sys_time_select=no])
7873          ])
7874 AC_MSG_RESULT($cf_cv_sys_time_select)
7875 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
7876 ])dnl
7877 dnl ---------------------------------------------------------------------------
7878 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
7879 dnl ---------------
7880 dnl Define a top_builddir symbol, for applications that need an absolute path.
7881 AC_DEFUN([CF_TOP_BUILDDIR],
7882 [
7883 top_builddir=ifelse($1,,`pwd`,$1)
7884 AC_SUBST(top_builddir)
7885 ])dnl
7886 dnl ---------------------------------------------------------------------------
7887 dnl CF_TRY_PKG_CONFIG version: 5 updated: 2013/07/06 21:27:06
7888 dnl -----------------
7889 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
7890 dnl available in that form.
7891 dnl
7892 dnl $1 = package name
7893 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
7894 dnl $3 = logic to use if pkg-config does not have the package
7895 AC_DEFUN([CF_TRY_PKG_CONFIG],[
7896 AC_REQUIRE([CF_PKG_CONFIG])
7897
7898 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists $1; then
7899         CF_VERBOSE(found package $1)
7900         cf_pkgconfig_incs="`$PKG_CONFIG --cflags $1 2>/dev/null`"
7901         cf_pkgconfig_libs="`$PKG_CONFIG --libs   $1 2>/dev/null`"
7902         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
7903         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
7904         CF_ADD_CFLAGS($cf_pkgconfig_incs)
7905         CF_ADD_LIBS($cf_pkgconfig_libs)
7906         ifelse([$2],,:,[$2])
7907 else
7908         cf_pkgconfig_incs=
7909         cf_pkgconfig_libs=
7910         ifelse([$3],,:,[$3])
7911 fi
7912 ])
7913 dnl ---------------------------------------------------------------------------
7914 dnl CF_TRY_XOPEN_SOURCE version: 2 updated: 2018/06/20 20:23:13
7915 dnl -------------------
7916 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
7917 dnl can define it successfully.
7918 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
7919 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
7920         AC_TRY_COMPILE([
7921 #include <stdlib.h>
7922 #include <string.h>
7923 #include <sys/types.h>
7924 ],[
7925 #ifndef _XOPEN_SOURCE
7926 make an error
7927 #endif],
7928         [cf_cv_xopen_source=no],
7929         [cf_save="$CPPFLAGS"
7930          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
7931          AC_TRY_COMPILE([
7932 #include <stdlib.h>
7933 #include <string.h>
7934 #include <sys/types.h>
7935 ],[
7936 #ifdef _XOPEN_SOURCE
7937 make an error
7938 #endif],
7939         [cf_cv_xopen_source=no],
7940         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
7941         CPPFLAGS="$cf_save"
7942         ])
7943 ])
7944
7945 if test "$cf_cv_xopen_source" != no ; then
7946         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
7947         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
7948         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
7949         CF_ADD_CFLAGS($cf_temp_xopen_source)
7950 fi
7951 ])
7952 dnl ---------------------------------------------------------------------------
7953 dnl CF_TYPEOF_CHTYPE version: 10 updated: 2017/01/21 11:06:25
7954 dnl ----------------
7955 dnl Determine the type we should use for chtype (and attr_t, which is treated
7956 dnl as the same thing).  We want around 32 bits, so on most machines want a
7957 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
7958 dnl wide characters, we have to have a type compatible with that, as well.
7959 AC_DEFUN([CF_TYPEOF_CHTYPE],
7960 [
7961 AC_MSG_CHECKING([for type of chtype])
7962 AC_CACHE_VAL(cf_cv_typeof_chtype,[
7963                 AC_TRY_RUN([
7964 #define WANT_BITS 31
7965 #include <stdio.h>
7966 int main(void)
7967 {
7968         FILE *fp = fopen("cf_test.out", "w");
7969         if (fp != 0) {
7970                 char *result = "long";
7971                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
7972                         int n;
7973                         unsigned int x, y;
7974                         for (n = 0; n < WANT_BITS; n++) {
7975                                 x = (1 << n);
7976                                 y = (x >> n);
7977                                 if (y != 1 || x == 0) {
7978                                         x = 0;
7979                                         break;
7980                                 }
7981                         }
7982                         /*
7983                          * If x is nonzero, an int is big enough for the bits
7984                          * that we want.
7985                          */
7986                         result = (x != 0) ? "int" : "long";
7987                 }
7988                 fputs(result, fp);
7989                 fclose(fp);
7990         }
7991         ${cf_cv_main_return:-return}(0);
7992 }
7993                 ],
7994                 [cf_cv_typeof_chtype=`cat cf_test.out`],
7995                 [cf_cv_typeof_chtype=long],
7996                 [cf_cv_typeof_chtype=long])
7997                 rm -f cf_test.out
7998         ])
7999 AC_MSG_RESULT($cf_cv_typeof_chtype)
8000
8001 AC_SUBST(cf_cv_typeof_chtype)
8002 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
8003 ])dnl
8004 dnl ---------------------------------------------------------------------------
8005 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
8006 dnl -----------------
8007 dnl
8008 AC_DEFUN([CF_TYPE_SIGACTION],
8009 [
8010 AC_MSG_CHECKING([for type sigaction_t])
8011 AC_CACHE_VAL(cf_cv_type_sigaction,[
8012         AC_TRY_COMPILE([
8013 #include <signal.h>],
8014                 [sigaction_t x],
8015                 [cf_cv_type_sigaction=yes],
8016                 [cf_cv_type_sigaction=no])])
8017 AC_MSG_RESULT($cf_cv_type_sigaction)
8018 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
8019 ])dnl
8020 dnl ---------------------------------------------------------------------------
8021 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
8022 dnl --------------------
8023 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
8024 dnl won't, but they're still there.
8025 AC_DEFUN([CF_UNSIGNED_LITERALS],
8026 [
8027 AC_MSG_CHECKING([if unsigned literals are legal])
8028 AC_CACHE_VAL(cf_cv_unsigned_literals,[
8029         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
8030                 [cf_cv_unsigned_literals=yes],
8031                 [cf_cv_unsigned_literals=no])
8032         ])
8033 AC_MSG_RESULT($cf_cv_unsigned_literals)
8034 ])dnl
8035 dnl ---------------------------------------------------------------------------
8036 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
8037 dnl --------
8038 dnl Make an uppercase version of a variable
8039 dnl $1=uppercase($2)
8040 AC_DEFUN([CF_UPPER],
8041 [
8042 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
8043 ])dnl
8044 dnl ---------------------------------------------------------------------------
8045 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
8046 dnl -----------
8047 dnl Check for multibyte support, and if not found, utf8 compatibility library
8048 AC_DEFUN([CF_UTF8_LIB],
8049 [
8050 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
8051         cf_save_LIBS="$LIBS"
8052         AC_TRY_LINK([
8053 #include <stdlib.h>],[putwc(0,0);],
8054         [cf_cv_utf8_lib=yes],
8055         [CF_FIND_LINKAGE([
8056 #include <libutf8.h>],[putwc(0,0);],utf8,
8057                 [cf_cv_utf8_lib=add-on],
8058                 [cf_cv_utf8_lib=no])
8059 ])])
8060
8061 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
8062 # ncurses/ncursesw:
8063 if test "$cf_cv_utf8_lib" = "add-on" ; then
8064         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
8065         CF_ADD_INCDIR($cf_cv_header_path_utf8)
8066         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
8067         CF_ADD_LIBS($cf_cv_library_file_utf8)
8068 fi
8069 ])dnl
8070 dnl ---------------------------------------------------------------------------
8071 dnl CF_VA_COPY version: 6 updated: 2018/12/04 18:14:25
8072 dnl ----------
8073 dnl check for va_copy, part of stdarg.h starting with ISO C 1999.
8074 dnl Also, workaround for glibc's __va_copy, by checking for both.
8075 dnl Finally, try to accommodate pre-ISO C 1999 headers.
8076 AC_DEFUN([CF_VA_COPY],[
8077 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
8078 AC_TRY_LINK([
8079 #include <stdarg.h>
8080 ],[
8081         static va_list dst;
8082         static va_list src;
8083         va_copy(dst, src)],
8084         cf_cv_have_va_copy=yes,
8085         cf_cv_have_va_copy=no)])
8086
8087 if test "$cf_cv_have_va_copy" = yes;
8088 then
8089         AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
8090 else # !cf_cv_have_va_copy
8091
8092 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
8093 AC_TRY_LINK([
8094 #include <stdarg.h>
8095 ],[
8096         static va_list dst;
8097         static va_list src;
8098         __va_copy(dst, src)],
8099         cf_cv_have___va_copy=yes,
8100         cf_cv_have___va_copy=no)])
8101
8102 if test "$cf_cv_have___va_copy" = yes
8103 then
8104         AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
8105 else # !cf_cv_have___va_copy
8106
8107 AC_CACHE_CHECK(for __builtin_va_copy, cf_cv_have___builtin_va_copy,[
8108 AC_TRY_LINK([
8109 #include <stdarg.h>
8110 ],[
8111         static va_list dst;
8112         static va_list src;
8113         __builtin_va_copy(dst, src)],
8114         cf_cv_have___builtin_va_copy=yes,
8115         cf_cv_have___builtin_va_copy=no)])
8116
8117 test "$cf_cv_have___builtin_va_copy" = yes &&
8118         AC_DEFINE(HAVE___BUILTIN_VA_COPY,1,[Define to 1 if we have __builtin_va_copy])
8119
8120 fi # cf_cv_have___va_copy
8121
8122 fi # cf_cv_have_va_copy
8123
8124 case "${cf_cv_have_va_copy}${cf_cv_have___va_copy}${cf_cv_have___builtin_va_copy}" in
8125 (*yes*)
8126         ;;
8127
8128 (*)
8129         AC_CACHE_CHECK(if we can simply copy va_list, cf_cv_pointer_va_list,[
8130 AC_TRY_LINK([
8131 #include <stdarg.h>
8132 ],[
8133         va_list dst;
8134         va_list src;
8135         dst = src],
8136         cf_cv_pointer_va_list=yes,
8137         cf_cv_pointer_va_list=no)])
8138
8139         if test "$cf_cv_pointer_va_list" = no
8140         then
8141                 AC_CACHE_CHECK(if we can copy va_list indirectly, cf_cv_array_va_list,[
8142 AC_TRY_LINK([
8143 #include <stdarg.h>
8144 ],[
8145         va_list dst;
8146         va_list src;
8147         *dst = *src],
8148                         cf_cv_array_va_list=yes,
8149                         cf_cv_array_va_list=no)])
8150                 test "$cf_cv_array_va_list" = yes && AC_DEFINE(ARRAY_VA_LIST,1,[Define to 1 if we can copy va_list indirectly])
8151         fi
8152         ;;
8153 esac
8154 ])
8155 dnl ---------------------------------------------------------------------------
8156 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
8157 dnl ----------
8158 dnl Use AC_VERBOSE w/o the warnings
8159 AC_DEFUN([CF_VERBOSE],
8160 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
8161 CF_MSG_LOG([$1])
8162 ])dnl
8163 dnl ---------------------------------------------------------------------------
8164 dnl CF_VERSION_INFO version: 7 updated: 2015/04/17 21:13:04
8165 dnl ---------------
8166 dnl Define several useful symbols derived from the VERSION file.  A separate
8167 dnl file is preferred to embedding the version numbers in various scripts.
8168 dnl (automake is a textbook-example of why the latter is a bad idea, but there
8169 dnl are others).
8170 dnl
8171 dnl The file contents are:
8172 dnl     libtool-version release-version patch-version
8173 dnl or
8174 dnl     release-version
8175 dnl where
8176 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
8177 dnl     release-version consists of a major version and minor version
8178 dnl             separated by '.', optionally followed by a patch-version
8179 dnl             separated by '-'.  The minor version need not be an
8180 dnl             integer (but it is preferred).
8181 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
8182 dnl             scripts can easily compare versions.
8183 dnl
8184 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
8185 dnl simply extracts the first field using 'cut -f1'.
8186 dnl
8187 dnl Optional parameters:
8188 dnl $1 = internal name for package
8189 dnl $2 = external name for package
8190 AC_DEFUN([CF_VERSION_INFO],
8191 [
8192 if test -f $srcdir/VERSION ; then
8193         AC_MSG_CHECKING(for package version)
8194
8195         # if there are not enough fields, cut returns the last one...
8196         cf_field1=`sed -e '2,$d' $srcdir/VERSION|cut -f1`
8197         cf_field2=`sed -e '2,$d' $srcdir/VERSION|cut -f2`
8198         cf_field3=`sed -e '2,$d' $srcdir/VERSION|cut -f3`
8199
8200         # this is how CF_BUNDLED_INTL uses $VERSION:
8201         VERSION="$cf_field1"
8202
8203         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
8204         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
8205
8206         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
8207         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
8208
8209         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
8210
8211         AC_MSG_CHECKING(for package patch date)
8212         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
8213         case .$VERSION_PATCH in
8214         (.)
8215                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
8216                 ;;
8217         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
8218                 ;;
8219         (*)
8220                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
8221                 ;;
8222         esac
8223         AC_MSG_RESULT($VERSION_PATCH)
8224 else
8225         AC_MSG_ERROR(did not find $srcdir/VERSION)
8226 fi
8227
8228 # show the actual data that we have for versions:
8229 CF_VERBOSE(ABI VERSION $VERSION)
8230 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
8231 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
8232 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
8233
8234 AC_SUBST(VERSION)
8235 AC_SUBST(VERSION_MAJOR)
8236 AC_SUBST(VERSION_MINOR)
8237 AC_SUBST(VERSION_PATCH)
8238
8239 dnl if a package name is given, define its corresponding version info.  We
8240 dnl need the package name to ensure that the defined symbols are unique.
8241 ifelse($1,,,[
8242         cf_PACKAGE=$1
8243         PACKAGE=ifelse($2,,$1,$2)
8244         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
8245         AC_SUBST(PACKAGE)
8246         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
8247         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
8248         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
8249 ])
8250 ])dnl
8251 dnl ---------------------------------------------------------------------------
8252 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
8253 dnl -------------
8254 dnl Check if type wide-character type $1 is declared, and if so, which header
8255 dnl file is needed.  The second parameter is used to set a shell variable when
8256 dnl the type is not found.  The first parameter sets a shell variable for the
8257 dnl opposite sense.
8258 AC_DEFUN([CF_WCHAR_TYPE],
8259 [
8260 # This is needed on Tru64 5.0 to declare $1
8261 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
8262 AC_TRY_COMPILE([
8263 #include <stdlib.h>
8264 #include <stdarg.h>
8265 #include <stdio.h>
8266 #ifdef HAVE_LIBUTF8_H
8267 #include <libutf8.h>
8268 #endif],
8269         [$1 state],
8270         [cf_cv_$1=no],
8271         [AC_TRY_COMPILE([
8272 #include <stdlib.h>
8273 #include <stdarg.h>
8274 #include <stdio.h>
8275 #include <wchar.h>
8276 #ifdef HAVE_LIBUTF8_H
8277 #include <libutf8.h>
8278 #endif],
8279         [$1 value],
8280         [cf_cv_$1=yes],
8281         [cf_cv_$1=unknown])])])
8282
8283 if test "$cf_cv_$1" = yes ; then
8284         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
8285         NEED_WCHAR_H=1
8286 fi
8287
8288 ifelse([$2],,,[
8289 # if we do not find $1 in either place, use substitution to provide a fallback.
8290 if test "$cf_cv_$1" = unknown ; then
8291         $2=1
8292 fi
8293 ])
8294 ifelse($3,,,[
8295 # if we find $1 in either place, use substitution to provide a fallback.
8296 if test "$cf_cv_$1" != unknown ; then
8297         $3=1
8298 fi
8299 ])
8300 ])dnl
8301 dnl ---------------------------------------------------------------------------
8302 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
8303 dnl ---------------
8304 dnl Check for compiler-support for weak symbols.
8305 dnl This works with "recent" gcc.
8306 AC_DEFUN([CF_WEAK_SYMBOLS],[
8307 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
8308
8309 AC_TRY_COMPILE([
8310 #include <stdio.h>],
8311 [
8312 #if defined(__GNUC__)
8313 #  if defined __USE_ISOC99
8314 #    define _cat_pragma(exp)    _Pragma(#exp)
8315 #    define _weak_pragma(exp)   _cat_pragma(weak name)
8316 #  else
8317 #    define _weak_pragma(exp)
8318 #  endif
8319 #  define _declare(name)        __extension__ extern __typeof__(name) name
8320 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
8321 #endif
8322
8323 weak_symbol(fopen);
8324 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
8325 ])
8326 ])dnl
8327 dnl ---------------------------------------------------------------------------
8328 dnl CF_WITH_ABI_VERSION version: 3 updated: 2015/06/06 16:10:11
8329 dnl -------------------
8330 dnl Allow library's ABI to be overridden.  Generally this happens when a
8331 dnl packager has incremented the ABI past that used in the original package,
8332 dnl and wishes to keep doing this.
8333 dnl
8334 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
8335 dnl symbol.
8336 AC_DEFUN([CF_WITH_ABI_VERSION],[
8337 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
8338 AC_ARG_WITH(abi-version,
8339 [  --with-abi-version=XXX  override derived ABI version],[
8340         if test "x$cf_cv_abi_version" != "x$withval"
8341         then
8342                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
8343                 case $cf_cv_rel_version in
8344                 (5.*)
8345                         cf_cv_rel_version=$withval.0
8346                         ;;
8347                 (6.*)
8348                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
8349                         ;;
8350                 esac
8351         fi
8352         cf_cv_abi_version=$withval])
8353         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
8354 ifelse($1,,,[
8355 $1_ABI=$cf_cv_abi_version
8356 ])
8357 ])dnl
8358 dnl ---------------------------------------------------------------------------
8359 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
8360 dnl --------------------
8361 dnl Command-line option to specify the Ada95 compiler.
8362 AC_DEFUN([CF_WITH_ADA_COMPILER],[
8363 AC_MSG_CHECKING(for ada-compiler)
8364 AC_ARG_WITH(ada-compiler,
8365         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
8366         [cf_ada_compiler=$withval],
8367         [cf_ada_compiler=gnatmake])
8368 AC_SUBST(cf_ada_compiler)
8369 AC_MSG_RESULT($cf_ada_compiler)
8370 ])dnl
8371 dnl ---------------------------------------------------------------------------
8372 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
8373 dnl -------------------
8374 dnl Command-line option to specify where Ada includes will install.
8375 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
8376 AC_MSG_CHECKING(for ada-include)
8377 CF_WITH_PATH(ada-include,
8378    [  --with-ada-include=DIR  Ada includes are in DIR],
8379    ADA_INCLUDE,
8380    PREFIX/share/ada/adainclude,
8381    [$]prefix/share/ada/adainclude)
8382 AC_SUBST(ADA_INCLUDE)
8383 AC_MSG_RESULT($ADA_INCLUDE)
8384 ])dnl
8385 dnl ---------------------------------------------------------------------------
8386 dnl CF_WITH_ADA_LIBNAME version: 1 updated: 2019/09/07 18:59:41
8387 dnl -------------------
8388 dnl CF_WITH_ADA_LIBNAME
8389 dnl -------------------
8390 dnl Command-line option to specify how to name the resulting Ada library.
8391 dnl $1 = default value
8392 AC_DEFUN([CF_WITH_ADA_LIBNAME],[
8393 AC_MSG_CHECKING(for ada-libname)
8394 AC_ARG_WITH(ada-libname,
8395    [  --with-ada-libname=XXX  override default Ada library-name],
8396    ADA_LIBNAME=[$]withval,
8397    ADA_LIBNAME=$1)
8398 case "x$ADA_LIBNAME" in
8399 (x|xyes|xno)
8400         ADA_LIBNAME=$1
8401         ;;
8402 esac
8403 AC_SUBST(ADA_LIBNAME)
8404 AC_MSG_RESULT($ADA_LIBNAME)
8405 ])dnl
8406 dnl ---------------------------------------------------------------------------
8407 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
8408 dnl -------------------
8409 dnl Command-line option to specify where Ada objects will install.
8410 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
8411 AC_MSG_CHECKING(for ada-objects)
8412 CF_WITH_PATH(ada-objects,
8413    [  --with-ada-objects=DIR  Ada objects are in DIR],
8414    ADA_OBJECTS,
8415    PREFIX/lib/ada/adalib,
8416    [$]prefix/lib/ada/adalib)
8417 AC_SUBST(ADA_OBJECTS)
8418 AC_MSG_RESULT($ADA_OBJECTS)
8419 ])dnl
8420 dnl ---------------------------------------------------------------------------
8421 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
8422 dnl ---------------------
8423 dnl Command-line option to specify if an Ada95 shared-library should be built,
8424 dnl and optionally what its soname should be.
8425 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
8426 AC_REQUIRE([CF_GNAT_PROJECTS])
8427 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
8428 AC_ARG_WITH(ada-sharedlib,
8429         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
8430         [with_ada_sharedlib=$withval],
8431         [with_ada_sharedlib=no])
8432 AC_MSG_RESULT($with_ada_sharedlib)
8433
8434 if test "x$with_ada_sharedlib" != xno
8435 then
8436         if test "x$cf_gnat_projects" != xyes
8437         then
8438                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
8439                 with_ada_sharedlib=no
8440         fi
8441 fi
8442
8443 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
8444 MAKE_ADA_SHAREDLIB="#"
8445
8446 if test "x$with_ada_sharedlib" != xno
8447 then
8448         MAKE_ADA_SHAREDLIB=
8449         if test "x$with_ada_sharedlib" != xyes
8450         then
8451                 ADA_SHAREDLIB="$with_ada_sharedlib"
8452         fi
8453 fi
8454
8455 AC_SUBST(ADA_SHAREDLIB)
8456 AC_SUBST(MAKE_ADA_SHAREDLIB)
8457 ])dnl
8458 dnl ---------------------------------------------------------------------------
8459 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
8460 dnl ----------------
8461 dnl Configure-option for dbmalloc.  The optional parameter is used to override
8462 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
8463 AC_DEFUN([CF_WITH_DBMALLOC],[
8464 CF_NO_LEAKS_OPTION(dbmalloc,
8465         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
8466         [USE_DBMALLOC])
8467
8468 if test "$with_dbmalloc" = yes ; then
8469         AC_CHECK_HEADER(dbmalloc.h,
8470                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
8471 fi
8472 ])dnl
8473 dnl ---------------------------------------------------------------------------
8474 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
8475 dnl ---------------
8476 dnl Configure-option for dmalloc.  The optional parameter is used to override
8477 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
8478 AC_DEFUN([CF_WITH_DMALLOC],[
8479 CF_NO_LEAKS_OPTION(dmalloc,
8480         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
8481         [USE_DMALLOC])
8482
8483 if test "$with_dmalloc" = yes ; then
8484         AC_CHECK_HEADER(dmalloc.h,
8485                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
8486 fi
8487 ])dnl
8488 dnl ---------------------------------------------------------------------------
8489 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
8490 dnl -------------------
8491 dnl Use this with libtool to specify the list of symbols that may be exported.
8492 dnl The input file contains one symbol per line; comments work with "#".
8493 dnl
8494 dnl $1 = basename of the ".sym" file (default $PACKAGE)
8495 AC_DEFUN([CF_WITH_EXPORT_SYMS],
8496 [
8497 AC_MSG_CHECKING(if exported-symbols file should be used)
8498 AC_ARG_WITH(export-syms,
8499         [  --with-export-syms=XXX  limit exported symbols using libtool],
8500         [with_export_syms=$withval],
8501         [with_export_syms=no])
8502 if test "x$with_export_syms" = xyes
8503 then
8504         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
8505         AC_SUBST(PACKAGE)
8506 fi
8507 AC_MSG_RESULT($with_export_syms)
8508 if test "x$with_export_syms" != xno
8509 then
8510         EXPORT_SYMS="-export-symbols $with_export_syms"
8511         AC_SUBST(EXPORT_SYMS)
8512 fi
8513 ])dnl
8514 dnl ---------------------------------------------------------------------------
8515 dnl CF_WITH_GPM version: 10 updated: 2017/04/29 18:32:18
8516 dnl -----------
8517 dnl
8518 dnl The option parameter (if neither yes/no) is assumed to be the name of
8519 dnl the gpm library, e.g., for dynamic loading.
8520 AC_DEFUN([CF_WITH_GPM],
8521 [
8522 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
8523 AC_ARG_WITH(gpm,
8524         [  --with-gpm              use Alessandro Rubini's GPM library],
8525         [with_gpm=$withval],
8526         [with_gpm=maybe])
8527 AC_MSG_RESULT($with_gpm)
8528
8529 if test "$with_gpm" != no ; then
8530         AC_CHECK_HEADER(gpm.h,[
8531                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
8532                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
8533                         CF_VERBOSE(assuming we really have GPM library)
8534                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
8535                         with_gpm=yes
8536                 else
8537                         AC_CHECK_LIB(gpm,Gpm_Open,[with_gpm=yes],[
8538                                 if test "$with_gpm" = maybe; then
8539                                         AC_MSG_WARN(Cannot link with GPM library)
8540                                         with_gpm=no
8541                                 else
8542                                         AC_MSG_ERROR(Cannot link with GPM library)
8543                                 fi
8544                         ])
8545                 fi
8546         ],[
8547                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
8548                 with_gpm=no
8549         ])
8550 fi
8551 ])
8552 dnl ---------------------------------------------------------------------------
8553 dnl CF_WITH_LIBTOOL version: 35 updated: 2017/08/12 07:58:51
8554 dnl ---------------
8555 dnl Provide a configure option to incorporate libtool.  Define several useful
8556 dnl symbols for the makefile rules.
8557 dnl
8558 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
8559 dnl macros from libtool.m4 which is in the aclocal directory of automake.
8560 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
8561 dnl But that still does not work properly since the macro is expanded outside
8562 dnl the CF_WITH_LIBTOOL macro:
8563 dnl
8564 dnl     #!/bin/sh
8565 dnl     ACLOCAL=`aclocal --print-ac-dir`
8566 dnl     if test -z "$ACLOCAL" ; then
8567 dnl             echo cannot find aclocal directory
8568 dnl             exit 1
8569 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
8570 dnl             echo cannot find libtool.m4 file
8571 dnl             exit 1
8572 dnl     fi
8573 dnl
8574 dnl     LOCAL=aclocal.m4
8575 dnl     ORIG=aclocal.m4.orig
8576 dnl
8577 dnl     trap "mv $ORIG $LOCAL" 0 1 2 3 15
8578 dnl     rm -f $ORIG
8579 dnl     mv $LOCAL $ORIG
8580 dnl
8581 dnl     # sed the LIBTOOL= assignment to omit the current directory?
8582 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
8583 dnl     cat $ORIG >>$LOCAL
8584 dnl
8585 dnl     autoconf-257 $*
8586 dnl
8587 AC_DEFUN([CF_WITH_LIBTOOL],
8588 [
8589 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
8590 ifdef([AC_PROG_LIBTOOL],,[
8591 LIBTOOL=
8592 ])
8593 # common library maintenance symbols that are convenient for libtool scripts:
8594 LIB_CREATE='${AR} -cr'
8595 LIB_OBJECT='${OBJECTS}'
8596 LIB_SUFFIX=.a
8597 LIB_PREP="$RANLIB"
8598
8599 # symbols used to prop libtool up to enable it to determine what it should be
8600 # doing:
8601 LIB_CLEAN=
8602 LIB_COMPILE=
8603 LIB_LINK='${CC}'
8604 LIB_INSTALL=
8605 LIB_UNINSTALL=
8606
8607 AC_MSG_CHECKING(if you want to build libraries with libtool)
8608 AC_ARG_WITH(libtool,
8609         [  --with-libtool          generate libraries with libtool],
8610         [with_libtool=$withval],
8611         [with_libtool=no])
8612 AC_MSG_RESULT($with_libtool)
8613 if test "$with_libtool" != "no"; then
8614 ifdef([AC_PROG_LIBTOOL],[
8615         # missing_content_AC_PROG_LIBTOOL{{
8616         AC_PROG_LIBTOOL
8617         # missing_content_AC_PROG_LIBTOOL}}
8618 ],[
8619         if test "$with_libtool" != "yes" ; then
8620                 CF_PATH_SYNTAX(with_libtool)
8621                 LIBTOOL=$with_libtool
8622         else
8623                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
8624                 CF_LIBTOOL_VERSION
8625                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
8626                 then
8627                         CF_FORGET_TOOL(LIBTOOL)
8628                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
8629                         CF_LIBTOOL_VERSION
8630                 fi
8631         fi
8632         if test -z "$LIBTOOL" ; then
8633                 AC_MSG_ERROR(Cannot find libtool)
8634         fi
8635 ])dnl
8636         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
8637         LIB_OBJECT='${OBJECTS:.o=.lo}'
8638         LIB_SUFFIX=.la
8639         LIB_CLEAN='${LIBTOOL} --mode=clean'
8640         LIB_COMPILE='${LIBTOOL} --mode=compile'
8641         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
8642         LIB_INSTALL='${LIBTOOL} --mode=install'
8643         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
8644         LIB_PREP=:
8645
8646         CF_CHECK_LIBTOOL_VERSION
8647
8648         # special hack to add -no-undefined (which libtool should do for itself)
8649         LT_UNDEF=
8650         case "$cf_cv_system_name" in
8651         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
8652                 LT_UNDEF=-no-undefined
8653                 ;;
8654         esac
8655         AC_SUBST([LT_UNDEF])
8656
8657         # special hack to add --tag option for C++ compiler
8658         case $cf_cv_libtool_version in
8659         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
8660                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
8661                 LIBTOOL="$LIBTOOL --tag=CC"
8662                 ;;
8663         (*)
8664                 LIBTOOL_CXX="$LIBTOOL"
8665                 ;;
8666         esac
8667 else
8668         LIBTOOL=""
8669         LIBTOOL_CXX=""
8670 fi
8671
8672 test -z "$LIBTOOL" && ECHO_LT=
8673
8674 AC_SUBST(LIBTOOL)
8675 AC_SUBST(LIBTOOL_CXX)
8676 AC_SUBST(LIBTOOL_OPTS)
8677
8678 AC_SUBST(LIB_CREATE)
8679 AC_SUBST(LIB_OBJECT)
8680 AC_SUBST(LIB_SUFFIX)
8681 AC_SUBST(LIB_PREP)
8682
8683 AC_SUBST(LIB_CLEAN)
8684 AC_SUBST(LIB_COMPILE)
8685 AC_SUBST(LIB_LINK)
8686 AC_SUBST(LIB_INSTALL)
8687 AC_SUBST(LIB_UNINSTALL)
8688
8689 ])dnl
8690 dnl ---------------------------------------------------------------------------
8691 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
8692 dnl --------------------
8693 dnl Allow user to pass additional libtool options into the library creation
8694 dnl and link steps.  The main use for this is to do something like
8695 dnl     ./configure --with-libtool-opts=-static
8696 dnl to get the same behavior as automake-flavored
8697 dnl     ./configure --enable-static
8698 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
8699 AC_MSG_CHECKING(for additional libtool options)
8700 AC_ARG_WITH(libtool-opts,
8701         [  --with-libtool-opts=XXX specify additional libtool options],
8702         [with_libtool_opts=$withval],
8703         [with_libtool_opts=no])
8704 AC_MSG_RESULT($with_libtool_opts)
8705
8706 case .$with_libtool_opts in
8707 (.yes|.no|.)
8708         ;;
8709 (*)
8710         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
8711         ;;
8712 esac
8713
8714 AC_SUBST(LIBTOOL_OPTS)
8715 ])dnl
8716 dnl ---------------------------------------------------------------------------
8717 dnl CF_WITH_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
8718 dnl --------------------
8719 dnl Allow for overriding the basename of a library, i.e., the part to which
8720 dnl prefixes/suffixes are attached.
8721 dnl
8722 dnl $1 = variable to set
8723 dnl $2 = option name
8724 dnl $3 = default basename for library, if omitted use $2
8725 AC_DEFUN([CF_WITH_LIB_BASENAME],
8726 [
8727 AC_MSG_CHECKING(for desired basename for $2 library)
8728 AC_ARG_WITH($2-libname,
8729         [  --with-$2-libname=XXX override ifelse($3,,$2,$3) basename of library],
8730         [with_lib_basename=$withval],
8731         [with_lib_basename=ifelse($3,,$2,$3)])
8732 $1="$with_lib_basename"
8733
8734 case "x[$]$1" in
8735 (x|xno|xnone|xyes)
8736         $1=ifelse($3,,$2,$3)
8737         ;;
8738 (*)
8739         ;;
8740 esac
8741
8742 AC_MSG_RESULT([$]$1)
8743 AC_SUBST($1)
8744 ])dnl
8745 dnl ---------------------------------------------------------------------------
8746 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
8747 dnl ------------------
8748 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
8749 dnl "lib" prefix, e.g., because it used the dll naming convention.
8750 dnl
8751 dnl $1 = variable to set
8752 AC_DEFUN([CF_WITH_LIB_PREFIX],
8753 [
8754 AC_MSG_CHECKING(if you want to have a library-prefix)
8755 AC_ARG_WITH(lib-prefix,
8756         [  --with-lib-prefix       override library-prefix],
8757         [with_lib_prefix=$withval],
8758         [with_lib_prefix=auto])
8759 AC_MSG_RESULT($with_lib_prefix)
8760
8761 if test $with_lib_prefix = auto
8762 then
8763         CF_LIB_PREFIX($1)
8764 elif test $with_lib_prefix = no
8765 then
8766         LIB_PREFIX=
8767 else
8768         LIB_PREFIX=$with_lib_prefix
8769 fi
8770 ])dnl
8771 dnl ---------------------------------------------------------------------------
8772 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
8773 dnl ------------
8774 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
8775 dnl defaulting to yes/no.
8776 dnl
8777 dnl $1 = option name
8778 dnl $2 = help-text
8779 dnl $3 = environment variable to set
8780 dnl $4 = default value, shown in the help-message, must be a constant
8781 dnl $5 = default value, if it's an expression & cannot be in the help-message
8782 dnl
8783 AC_DEFUN([CF_WITH_PATH],
8784 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
8785 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
8786 if ifelse([$5],,true,[test -n "$5"]) ; then
8787 CF_PATH_SYNTAX(withval)
8788 fi
8789 eval $3="$withval"
8790 AC_SUBST($3)dnl
8791 ])dnl
8792 dnl ---------------------------------------------------------------------------
8793 dnl CF_WITH_PATHLIST version: 10 updated: 2015/04/17 21:13:04
8794 dnl ----------------
8795 dnl Process an option specifying a list of colon-separated paths.
8796 dnl
8797 dnl $1 = option name
8798 dnl $2 = help-text
8799 dnl $3 = environment variable to set
8800 dnl $4 = default value, shown in the help-message, must be a constant
8801 dnl $5 = default value, if it's an expression & cannot be in the help-message
8802 dnl $6 = flag to tell if we want to define or substitute
8803 dnl
8804 AC_DEFUN([CF_WITH_PATHLIST],[
8805 AC_REQUIRE([CF_PATHSEP])
8806 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
8807 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
8808
8809 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
8810 cf_dst_path=
8811 for cf_src_path in $withval
8812 do
8813   CF_PATH_SYNTAX(cf_src_path)
8814   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
8815   cf_dst_path="${cf_dst_path}${cf_src_path}"
8816 done
8817 IFS="$ac_save_ifs"
8818
8819 ifelse($6,define,[
8820 # Strip single quotes from the value, e.g., when it was supplied as a literal
8821 # for $4 or $5.
8822 case $cf_dst_path in
8823 (\'*)
8824   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
8825   ;;
8826 esac
8827 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
8828 ])
8829
8830 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
8831 # so we have to check/work around.  We do prefer the result of "eval"...
8832 eval cf_dst_eval="$cf_dst_path"
8833 case "x$cf_dst_eval" in
8834 (xNONE*)
8835         $3=$cf_dst_path
8836         ;;
8837 (*)
8838         $3="$cf_dst_eval"
8839         ;;
8840 esac
8841 AC_SUBST($3)dnl
8842
8843 ])dnl
8844 dnl ---------------------------------------------------------------------------
8845 dnl CF_WITH_PATH_PROG version: 1 updated: 2019/06/30 19:44:43
8846 dnl -----------------
8847 dnl Check for a given program, like CF_PATH_PROG, but allow override using a
8848 dnl "--with-xxx" option.
8849 dnl
8850 dnl Parameters:
8851 dnl             $1 = environment variable to set/update
8852 dnl             $2 = program name
8853 dnl             $3 = help-text
8854 dnl             $4 = $PATH
8855 AC_DEFUN([CF_WITH_PATH_PROG],[
8856 AC_ARG_WITH($2-path,
8857         [  --with-$2-path=XXX     specify path of $2 ifelse($3,,,$3)],
8858         [AC_MSG_CHECKING(for $2 program ifelse($3,,,$3))
8859                 $1=$withval
8860                 AC_MSG_RESULT([$]$1)
8861                 CF_PATH_SYNTAX($1)
8862         ],
8863         [CF_PATH_PROG($1,$2,,ifelse($4,,,$4))
8864                 if test -z "[$]$1"
8865                 then
8866                         AC_MSG_WARN(no $2 program found ifelse($3,,,$3))
8867                 fi
8868         ])
8869 ])
8870 dnl ---------------------------------------------------------------------------
8871 dnl CF_WITH_PCRE2 version: 3 updated: 2020/02/29 16:09:19
8872 dnl -------------
8873 dnl Add PCRE2 (Perl-compatible regular expressions v2) to the build if it is
8874 dnl available and the user requests it.  Assume the application will otherwise
8875 dnl use the POSIX interface.
8876 dnl
8877 dnl TODO allow $withval to specify package location
8878 AC_DEFUN([CF_WITH_PCRE2],
8879 [
8880 AC_REQUIRE([CF_PKG_CONFIG])
8881
8882 AC_MSG_CHECKING(if you want to use PCRE2 for regular-expressions)
8883 AC_ARG_WITH(pcre2,
8884         [  --with-pcre2            use PCRE2 for regular-expressions])
8885 test -z "$with_pcre2" && with_pcre2=no
8886 AC_MSG_RESULT($with_pcre2)
8887
8888 if test "x$with_pcre2" != xno ; then
8889         CF_TRY_PKG_CONFIG(libpcre2,,[
8890         CF_TRY_PKG_CONFIG(libpcre,,[
8891                         AC_MSG_ERROR(Cannot find PCRE2 library)])])
8892
8893         AC_DEFINE(HAVE_LIB_PCRE2,1,[Define to 1 if we can/should compile with the PCRE2 library])
8894
8895         # if pkgconfig gave no results, look for the libraries directly
8896         case $LIBS in
8897         (*pcre2-posix*|*pcreposix*)
8898                 ;;
8899         (*)
8900                 AC_CHECK_LIB(pcre2-posix,regcomp,[
8901                         CF_ADD_LIB(pcre2-posix)],
8902                         [AC_CHECK_LIB(pcreposix,regcomp,[
8903                          CF_ADD_LIB(pcreposix)
8904                         ],[AC_MSG_ERROR(Cannot find PCRE2 POSIX library)])])
8905                 ;;
8906         esac
8907
8908         # either way, check for the library header files
8909         AC_CHECK_HEADERS(pcre2posix.h pcreposix.h)
8910 fi
8911 ])dnl
8912 dnl ---------------------------------------------------------------------------
8913 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
8914 dnl -------------------------
8915 dnl Allow the choice of the pkg-config library directory to be overridden.
8916 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
8917
8918 case $PKG_CONFIG in
8919 (no|none|yes)
8920         AC_MSG_CHECKING(for pkg-config library directory)
8921         ;;
8922 (*)
8923         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
8924         ;;
8925 esac
8926
8927 PKG_CONFIG_LIBDIR=no
8928 AC_ARG_WITH(pkg-config-libdir,
8929         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
8930         [PKG_CONFIG_LIBDIR=$withval],
8931         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
8932
8933 case x$PKG_CONFIG_LIBDIR in
8934 (x/*)
8935         ;;
8936 (xyes)
8937         # Look for the library directory using the same prefix as the executable
8938         if test "x$PKG_CONFIG" = xnone
8939         then
8940                 cf_path=$prefix
8941         else
8942                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
8943         fi
8944
8945         # If you don't like using the default architecture, you have to specify the
8946         # intended library directory and corresponding compiler/linker options.
8947         #
8948         # This case allows for Debian's 2014-flavor of multiarch, along with the
8949         # most common variations before that point.  Some other variants spell the
8950         # directory differently, e.g., "pkg-config", and put it in unusual places.
8951         # pkg-config has always been poorly standardized, which is ironic...
8952         case x`(arch) 2>/dev/null` in
8953         (*64)
8954                 cf_search_path="\
8955                         $cf_path/lib/*64-linux-gnu \
8956                         $cf_path/share \
8957                         $cf_path/lib64 \
8958                         $cf_path/lib32 \
8959                         $cf_path/lib"
8960                 ;;
8961         (*)
8962                 cf_search_path="\
8963                         $cf_path/lib/*-linux-gnu \
8964                         $cf_path/share \
8965                         $cf_path/lib32 \
8966                         $cf_path/lib \
8967                         $cf_path/libdata"
8968                 ;;
8969         esac
8970
8971         CF_VERBOSE(list...)
8972         for cf_config in $cf_search_path
8973         do
8974                 CF_VERBOSE(checking $cf_config/pkgconfig)
8975                 if test -d $cf_config/pkgconfig
8976                 then
8977                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
8978                         AC_MSG_CHECKING(done)
8979                         break
8980                 fi
8981         done
8982         ;;
8983 (*)
8984         ;;
8985 esac
8986
8987 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
8988         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
8989 fi
8990
8991 AC_SUBST(PKG_CONFIG_LIBDIR)
8992 ])dnl
8993 dnl ---------------------------------------------------------------------------
8994 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
8995 dnl ---------------
8996 dnl Check for POSIX thread library.
8997 AC_DEFUN([CF_WITH_PTHREAD],
8998 [
8999 AC_MSG_CHECKING(if you want to link with the pthread library)
9000 AC_ARG_WITH(pthread,
9001         [  --with-pthread          use POSIX thread library],
9002         [with_pthread=$withval],
9003         [with_pthread=no])
9004 AC_MSG_RESULT($with_pthread)
9005
9006 if test "$with_pthread" != no ; then
9007         AC_CHECK_HEADER(pthread.h,[
9008         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
9009
9010         for cf_lib_pthread in pthread c_r
9011         do
9012             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
9013             cf_save_LIBS="$LIBS"
9014             CF_ADD_LIB($cf_lib_pthread)
9015             AC_TRY_LINK([
9016 #include <pthread.h>
9017 ],[
9018                 int rc = pthread_create(0,0,0,0);
9019                 int r2 = pthread_mutexattr_settype(0, 0);
9020 ],[with_pthread=yes],[with_pthread=no])
9021             LIBS="$cf_save_LIBS"
9022             AC_MSG_RESULT($with_pthread)
9023             test "$with_pthread" = yes && break
9024         done
9025
9026         if test "$with_pthread" = yes ; then
9027             CF_ADD_LIB($cf_lib_pthread)
9028             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
9029         else
9030             AC_MSG_ERROR(Cannot link with pthread library)
9031         fi
9032         ])
9033 fi
9034 ])
9035 dnl ---------------------------------------------------------------------------
9036 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
9037 dnl -------------------
9038 dnl Allow library's release-version to be overridden.  Generally this happens when a
9039 dnl packager has incremented the release-version past that used in the original package,
9040 dnl and wishes to keep doing this.
9041 dnl
9042 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
9043 dnl and {package}_MINOR symbols
9044 dnl symbol.
9045 AC_DEFUN([CF_WITH_REL_VERSION],[
9046 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
9047 AC_ARG_WITH(rel-version,
9048 [  --with-rel-version=XXX  override derived release version],
9049 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
9050  cf_cv_rel_version=$withval])
9051 ifelse($1,,[
9052  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
9053 ],[
9054  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
9055  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
9056  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
9057  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
9058 ])
9059 ])dnl
9060 dnl ---------------------------------------------------------------------------
9061 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
9062 dnl ----------------
9063 dnl If we can compile with sysmouse, make it available unless it is not wanted.
9064 AC_DEFUN([CF_WITH_SYSMOUSE],[
9065 # not everyone has "test -c"
9066 if test -c /dev/sysmouse 2>/dev/null ; then
9067 AC_MSG_CHECKING(if you want to use sysmouse)
9068 AC_ARG_WITH(sysmouse,
9069         [  --with-sysmouse         use sysmouse (FreeBSD console)],
9070         [cf_with_sysmouse=$withval],
9071         [cf_with_sysmouse=maybe])
9072         if test "$cf_with_sysmouse" != no ; then
9073         AC_TRY_COMPILE([
9074 #include <osreldate.h>
9075 #if (__FreeBSD_version >= 400017)
9076 #include <sys/consio.h>
9077 #include <sys/fbio.h>
9078 #else
9079 #include <machine/console.h>
9080 #endif
9081 ],[
9082         struct mouse_info the_mouse;
9083         ioctl(0, CONS_MOUSECTL, &the_mouse);
9084 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
9085         fi
9086 AC_MSG_RESULT($cf_with_sysmouse)
9087 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
9088 fi
9089 ])dnl
9090 dnl ---------------------------------------------------------------------------
9091 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
9092 dnl ---------------
9093 dnl For testing, override the derived host system-type which is used to decide
9094 dnl things such as the linker commands used to build shared libraries.  This is
9095 dnl normally chosen automatically based on the type of system which you are
9096 dnl building on.  We use it for testing the configure script.
9097 dnl
9098 dnl This is different from the --host option: it is used only for testing parts
9099 dnl of the configure script which would not be reachable with --host since that
9100 dnl relies on the build environment being real, rather than mocked up.
9101 AC_DEFUN([CF_WITH_SYSTYPE],[
9102 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
9103 AC_ARG_WITH(system-type,
9104         [  --with-system-type=XXX  test: override derived host system-type],
9105 [AC_MSG_WARN(overriding system type to $withval)
9106         cf_cv_system_name=$withval
9107         host_os=$withval
9108 ])
9109 ])dnl
9110 dnl ---------------------------------------------------------------------------
9111 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
9112 dnl ----------------
9113 AC_DEFUN([CF_WITH_VALGRIND],[
9114 CF_NO_LEAKS_OPTION(valgrind,
9115         [  --with-valgrind         test: use valgrind],
9116         [USE_VALGRIND])
9117 ])dnl
9118 dnl ---------------------------------------------------------------------------
9119 dnl CF_WITH_VERSIONED_SYMS version: 8 updated: 2018/10/20 20:24:34
9120 dnl ----------------------
9121 dnl Use this when building shared library with ELF, to markup symbols with the
9122 dnl version identifier from the given input file.  Generally that identifier is
9123 dnl the same as the SONAME at which the symbol was first introduced.
9124 dnl
9125 dnl $1 = basename of the ".map" file (default $PACKAGE)
9126 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
9127 [
9128 AC_MSG_CHECKING(if versioned-symbols file should be used)
9129 AC_ARG_WITH(versioned-syms,
9130         [  --with-versioned-syms=X markup versioned symbols using ld],
9131         [with_versioned_syms=$withval],
9132         [with_versioned_syms=no])
9133 case "x$with_versioned_syms" in
9134 (xyes)
9135         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
9136         AC_SUBST(PACKAGE)
9137         ;;
9138 (xno)
9139         ;;
9140 (x/*)
9141         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9142         ;;
9143 (*)
9144         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9145         with_versioned_syms=`pwd`/"$with_versioned_syms"
9146         ;;
9147 esac
9148 AC_MSG_RESULT($with_versioned_syms)
9149
9150 RESULTING_SYMS=
9151 VERSIONED_SYMS=
9152 WILDCARD_SYMS=
9153
9154 if test "x$with_versioned_syms" != xno
9155 then
9156         RESULTING_SYMS=$with_versioned_syms
9157         case "x$MK_SHARED_LIB" in
9158         (*-Wl,*)
9159                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
9160                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
9161                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9162                 ;;
9163         (*-dy\ *)
9164                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
9165                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
9166                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9167                 ;;
9168         (*)
9169                 AC_MSG_WARN(this system does not support versioned-symbols)
9170                 ;;
9171         esac
9172
9173         # Linux ld can selectively override scope, e.g., of symbols beginning with
9174         # "_" by first declaring some as global, and then using a wildcard to
9175         # declare the others as local.  Some other loaders cannot do this.  Check
9176         # by constructing a (very) simple shared library and inspecting its
9177         # symbols.
9178         if test "x$VERSIONED_SYMS" != "x"
9179         then
9180                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
9181                 WILDCARD_SYMS=no
9182
9183                 # make sources
9184                 rm -f conftest.*
9185
9186                 cat >conftest.ver <<EOF
9187 module_1.0 {
9188 global:
9189         globalf1;
9190 local:
9191         localf1;
9192 };
9193 module_2.0 {
9194 global:
9195         globalf2;
9196 local:
9197         localf2;
9198         _*;
9199 } module_1.0;
9200 submodule_1.0 {
9201 global:
9202         subglobalf1;
9203         _ismissing;
9204 local:
9205         sublocalf1;
9206 };
9207 submodule_2.0 {
9208 global:
9209         subglobalf2;
9210 local:
9211         sublocalf2;
9212         _*;
9213 } submodule_1.0;
9214 EOF
9215                 cat >conftest.$ac_ext <<EOF
9216 #line __oline__ "configure"
9217 int     _ismissing(void) { return 1; }
9218 int     _localf1(void) { return 1; }
9219 int     _localf2(void) { return 2; }
9220 int     globalf1(void) { return 1; }
9221 int     globalf2(void) { return 2; }
9222 int     _sublocalf1(void) { return 1; }
9223 int     _sublocalf2(void) { return 2; }
9224 int     subglobalf1(void) { return 1; }
9225 int     subglobalf2(void) { return 2; }
9226 EOF
9227                 cat >conftest.mk <<EOF
9228 CC=${CC}
9229 CFLAGS=${CFLAGS}
9230 CPPFLAGS=${CPPFLAGS}
9231 LDFLAGS=${LDFLAGS}
9232 LIBS=${LIBS}
9233 VERSIONED_SYMS=${VERSIONED_SYMS}
9234 RESULTING_SYMS=conftest.ver
9235 MK_SHARED_LIB=${MK_SHARED_LIB}
9236 conftest.so: conftest.$ac_cv_objext
9237                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
9238 EOF
9239
9240                 # compile source, make library
9241                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
9242                 then
9243                         # test for missing symbol in either Data or Text section
9244                         cf_missing=`nm -P conftest.so 2>&AC_FD_CC |fgrep _ismissing | egrep '[[         ]][[DT]][[      ]]'`
9245                         test -n "$cf_missing" && WILDCARD_SYMS=yes
9246                 fi
9247                 AC_MSG_RESULT($WILDCARD_SYMS)
9248                 rm -f conftest.*
9249         fi
9250 fi
9251 AC_SUBST(RESULTING_SYMS)
9252 AC_SUBST(VERSIONED_SYMS)
9253 AC_SUBST(WILDCARD_SYMS)
9254 ])dnl
9255 dnl ---------------------------------------------------------------------------
9256 dnl CF_WITH_X11_RGB version: 2 updated: 2019/12/31 08:53:54
9257 dnl ---------------
9258 dnl Handle configure option "--with-x11-rgb", setting these shell
9259 dnl variables:
9260 dnl
9261 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
9262 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
9263 dnl
9264 dnl Most Linux's use this:
9265 dnl     /usr/share/X11/rgb.txt
9266 dnl Debian uses this:
9267 dnl     /etc/X11/rgb.txt
9268 dnl DragonFlyBSD ports uses this:
9269 dnl     /usr/pkg/lib/X11/rgb.txt
9270 dnl FreeBSD ports use these:
9271 dnl     /usr/local/lib/X11/rgb.txt
9272 dnl     /usr/local/share/X11/rgb.txt
9273 dnl Mandriva has these:
9274 dnl     /usr/lib/X11/rgb.txt
9275 dnl     /usr/lib64/X11/rgb.txt
9276 dnl NetBSD has these
9277 dnl     /usr/X11R7/lib/X11/rgb.txt
9278 dnl OpenSolaris uses
9279 dnl     32-bit:
9280 dnl     /usr/X11/etc/X11/rgb.txt
9281 dnl     /usr/X11/share/X11/rgb.txt
9282 dnl     /usr/X11/lib/X11/rgb.txt
9283 dnl OSX uses
9284 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
9285 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
9286 dnl     64-bit:
9287 dnl     /usr/X11/etc/X11/rgb.txt
9288 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
9289 dnl     /usr/X11/lib/amd64/X11/rgb.txt
9290 dnl Solaris10 uses (in this order):
9291 dnl     /usr/openwin/lib/X11/rgb.txt
9292 dnl     /usr/X11/lib/X11/rgb.txt
9293 AC_DEFUN([CF_WITH_X11_RGB],[
9294 AC_MSG_CHECKING(for X11 rgb file)
9295 AC_ARG_WITH(x11-rgb,
9296         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
9297         [RGB_PATH=$withval],
9298         [RGB_PATH=auto])
9299
9300 if test "x[$]RGB_PATH" = xauto
9301 then
9302         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
9303         for cf_path in \
9304                 /opt/local/share/X11/rgb.txt \
9305                 /opt/X11/share/X11/rgb.txt \
9306                 /usr/share/X11/rgb.txt \
9307                 /usr/X11/share/X11/rgb.txt \
9308                 /usr/X11/lib/X11/rgb.txt \
9309                 /usr/lib/X11/rgb.txt \
9310                 /etc/X11/rgb.txt \
9311                 /usr/pkg/lib/X11/rgb.txt \
9312                 /usr/X11R7/lib/X11/rgb.txt \
9313                 /usr/X11R6/lib/X11/rgb.txt \
9314                 /usr/X11R5/lib/X11/rgb.txt \
9315                 /usr/X11R4/lib/X11/rgb.txt \
9316                 /usr/local/lib/X11/rgb.txt \
9317                 /usr/local/share/X11/rgb.txt \
9318                 /usr/lib64/X11/rgb.txt
9319         do
9320                 if test -f "$cf_path" ; then
9321                         RGB_PATH="$cf_path"
9322                         break
9323                 fi
9324         done
9325 else
9326         cf_path=$RGB_PATH
9327         CF_PATH_SYNTAX(cf_path)
9328 fi
9329
9330 AC_MSG_RESULT($RGB_PATH)
9331 AC_SUBST(RGB_PATH)
9332 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path",[Define to the full pathname of rgb.txt])
9333
9334 no_x11_rgb=
9335 if test "$RGB_PATH" = no
9336 then
9337         no_x11_rgb="#"
9338 fi
9339 AC_SUBST(no_x11_rgb)
9340 ])dnl
9341 dnl ---------------------------------------------------------------------------
9342 dnl CF_XOPEN_SOURCE version: 55 updated: 2018/12/31 20:46:17
9343 dnl ---------------
9344 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
9345 dnl or adapt to the vendor's definitions to get equivalent functionality,
9346 dnl without losing the common non-POSIX features.
9347 dnl
9348 dnl Parameters:
9349 dnl     $1 is the nominal value for _XOPEN_SOURCE
9350 dnl     $2 is the nominal value for _POSIX_C_SOURCE
9351 AC_DEFUN([CF_XOPEN_SOURCE],[
9352 AC_REQUIRE([AC_CANONICAL_HOST])
9353 AC_REQUIRE([CF_POSIX_VISIBLE])
9354
9355 if test "$cf_cv_posix_visible" = no; then
9356
9357 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
9358 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
9359 cf_xopen_source=
9360
9361 case $host_os in
9362 (aix[[4-7]]*)
9363         cf_xopen_source="-D_ALL_SOURCE"
9364         ;;
9365 (msys)
9366         cf_XOPEN_SOURCE=600
9367         ;;
9368 (darwin[[0-8]].*)
9369         cf_xopen_source="-D_APPLE_C_SOURCE"
9370         ;;
9371 (darwin*)
9372         cf_xopen_source="-D_DARWIN_C_SOURCE"
9373         cf_XOPEN_SOURCE=
9374         ;;
9375 (freebsd*|dragonfly*|midnightbsd*)
9376         # 5.x headers associate
9377         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
9378         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
9379         cf_POSIX_C_SOURCE=200112L
9380         cf_XOPEN_SOURCE=600
9381         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
9382         ;;
9383 (hpux11*)
9384         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
9385         ;;
9386 (hpux*)
9387         cf_xopen_source="-D_HPUX_SOURCE"
9388         ;;
9389 (irix[[56]].*)
9390         cf_xopen_source="-D_SGI_SOURCE"
9391         cf_XOPEN_SOURCE=
9392         ;;
9393 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
9394         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
9395         ;;
9396 (minix*)
9397         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
9398         ;;
9399 (mirbsd*)
9400         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
9401         cf_XOPEN_SOURCE=
9402         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
9403         ;;
9404 (netbsd*)
9405         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
9406         ;;
9407 (openbsd[[4-9]]*)
9408         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
9409         cf_xopen_source="-D_BSD_SOURCE"
9410         cf_XOPEN_SOURCE=600
9411         ;;
9412 (openbsd*)
9413         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
9414         ;;
9415 (osf[[45]]*)
9416         cf_xopen_source="-D_OSF_SOURCE"
9417         ;;
9418 (nto-qnx*)
9419         cf_xopen_source="-D_QNX_SOURCE"
9420         ;;
9421 (sco*)
9422         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
9423         ;;
9424 (solaris2.*)
9425         cf_xopen_source="-D__EXTENSIONS__"
9426         cf_cv_xopen_source=broken
9427         ;;
9428 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
9429         cf_XOPEN_SOURCE=
9430         cf_POSIX_C_SOURCE=
9431         ;;
9432 (*)
9433         CF_TRY_XOPEN_SOURCE
9434         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
9435         ;;
9436 esac
9437
9438 if test -n "$cf_xopen_source" ; then
9439         CF_ADD_CFLAGS($cf_xopen_source,true)
9440 fi
9441
9442 dnl In anything but the default case, we may have system-specific setting
9443 dnl which is still not guaranteed to provide all of the entrypoints that
9444 dnl _XOPEN_SOURCE would yield.
9445 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
9446         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
9447         AC_TRY_COMPILE([#include <stdlib.h>],[
9448 #ifndef _XOPEN_SOURCE
9449 make an error
9450 #endif],
9451         [cf_XOPEN_SOURCE_set=yes],
9452         [cf_XOPEN_SOURCE_set=no])
9453         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
9454         if test $cf_XOPEN_SOURCE_set = yes
9455         then
9456                 AC_TRY_COMPILE([#include <stdlib.h>],[
9457 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
9458 make an error
9459 #endif],
9460                 [cf_XOPEN_SOURCE_set_ok=yes],
9461                 [cf_XOPEN_SOURCE_set_ok=no])
9462                 if test $cf_XOPEN_SOURCE_set_ok = no
9463                 then
9464                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
9465                 fi
9466         else
9467                 CF_TRY_XOPEN_SOURCE
9468         fi
9469 fi
9470 fi # cf_cv_posix_visible
9471 ])