aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2017,2018 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.861 2019/01/01 01:49:46 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See https://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54         [AC_TRY_LINK([#include <langinfo.h>],
  55         [char* cs = nl_langinfo(CODESET);],
  56         am_cv_langinfo_codeset=yes,
  57         am_cv_langinfo_codeset=no)
  58         ])
  59         if test $am_cv_langinfo_codeset = yes; then
  60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62         fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  66 dnl ---------------
  67 dnl Provide configure-script defaults for different ncurses ABIs.
  68 AC_DEFUN([CF_ABI_DEFAULTS],[
  69 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  70 case x$cf_cv_abi_version in
  71 (x[[6789]])
  72         cf_dft_ext_colors=yes
  73         cf_dft_ext_const=yes
  74         cf_dft_ext_mouse=yes
  75         cf_dft_ext_putwin=yes
  76         cf_dft_ext_spfuncs=yes
  77         cf_dft_filter_syms=yes
  78         cf_dft_chtype=uint32_t
  79         cf_dft_mmask_t=uint32_t
  80         cf_dft_interop=yes
  81         cf_dft_tparm_arg=intptr_t
  82         cf_dft_with_lp64=yes
  83         ;;
  84 (*)
  85         cf_dft_ext_colors=no
  86         cf_dft_ext_const=no
  87         cf_dft_ext_mouse=no
  88         cf_dft_ext_putwin=no
  89         cf_dft_ext_spfuncs=no
  90         cf_dft_filter_syms=no
  91         cf_dft_chtype=auto
  92         cf_dft_mmask_t=auto
  93         cf_dft_interop=no
  94         cf_dft_tparm_arg=long
  95         cf_dft_with_lp64=no
  96         ;;
  97 esac
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 101 dnl ------------------
 102 dnl Conditionally generate script according to whether we're using a given autoconf.
 103 dnl
 104 dnl $1 = version to compare against
 105 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 106 dnl $3 = code to use if AC_ACVERSION is older than $1.
 107 define([CF_ACVERSION_CHECK],
 108 [
 109 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 110 ifdef([m4_version_compare],
 111 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 112 [CF_ACVERSION_COMPARE(
 113 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 114 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 115 dnl ---------------------------------------------------------------------------
 116 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 117 dnl --------------------
 118 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 119 dnl                      MAJOR2, MINOR2, TERNARY2,
 120 dnl                      PRINTABLE2, not FOUND, FOUND)
 121 define([CF_ACVERSION_COMPARE],
 122 [ifelse(builtin([eval], [$2 < $5]), 1,
 123 [ifelse([$8], , ,[$8])],
 124 [ifelse([$9], , ,[$9])])])dnl
 125 dnl ---------------------------------------------------------------------------
 126 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 127 dnl -------------------
 128 dnl Construct the list of include-options for the C programs in the Ada95
 129 dnl binding.
 130 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 131 [
 132 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 133 if test "$srcdir" != "."; then
 134         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 135 fi
 136 if test "$GCC" != yes; then
 137         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 138 elif test "$includedir" != "/usr/include"; then
 139         if test "$includedir" = '${prefix}/include' ; then
 140                 if test x$prefix != x/usr ; then
 141                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 142                 fi
 143         else
 144                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145         fi
 146 fi
 147 AC_SUBST(ACPPFLAGS)
 148 ])dnl
 149 dnl ---------------------------------------------------------------------------
 150 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 151 dnl ---------------
 152 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 153 AC_DEFUN([CF_ADD_ADAFLAGS],[
 154         ADAFLAGS="$ADAFLAGS $1"
 155         AC_SUBST(ADAFLAGS)
 156 ])dnl
 157 dnl ---------------------------------------------------------------------------
 158 dnl CF_ADD_CFLAGS version: 13 updated: 2017/02/25 18:57:40
 159 dnl -------------
 160 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 161 dnl The second parameter if given makes this macro verbose.
 162 dnl
 163 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 164 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 165 dnl confused by the quotes (which require backslashes to keep them usable).
 166 AC_DEFUN([CF_ADD_CFLAGS],
 167 [
 168 cf_fix_cppflags=no
 169 cf_new_cflags=
 170 cf_new_cppflags=
 171 cf_new_extra_cppflags=
 172
 173 for cf_add_cflags in $1
 174 do
 175 case $cf_fix_cppflags in
 176 (no)
 177         case $cf_add_cflags in
 178         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 179                 case $cf_add_cflags in
 180                 (-D*)
 181                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 182
 183                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 184                                 && test -z "${cf_tst_cflags}" \
 185                                 && cf_fix_cppflags=yes
 186
 187                         if test $cf_fix_cppflags = yes ; then
 188                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 189                                 continue
 190                         elif test "${cf_tst_cflags}" = "\"'" ; then
 191                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 192                                 continue
 193                         fi
 194                         ;;
 195                 esac
 196                 case "$CPPFLAGS" in
 197                 (*$cf_add_cflags)
 198                         ;;
 199                 (*)
 200                         case $cf_add_cflags in
 201                         (-D*)
 202                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 203                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 204                                 ;;
 205                         esac
 206                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 207                         ;;
 208                 esac
 209                 ;;
 210         (*)
 211                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 212                 ;;
 213         esac
 214         ;;
 215 (yes)
 216         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 217
 218         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 219
 220         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 221                 && test -z "${cf_tst_cflags}" \
 222                 && cf_fix_cppflags=no
 223         ;;
 224 esac
 225 done
 226
 227 if test -n "$cf_new_cflags" ; then
 228         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 229         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 230 fi
 231
 232 if test -n "$cf_new_cppflags" ; then
 233         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 234         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 235 fi
 236
 237 if test -n "$cf_new_extra_cppflags" ; then
 238         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 239         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 240 fi
 241
 242 AC_SUBST(EXTRA_CPPFLAGS)
 243
 244 ])dnl
 245 dnl ---------------------------------------------------------------------------
 246 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
 247 dnl -------------
 248 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 249 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 250 dnl but old versions (and some misinstalled ones) need that.  To make things
 251 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 252 dnl the include-path).
 253 AC_DEFUN([CF_ADD_INCDIR],
 254 [
 255 if test -n "$1" ; then
 256   for cf_add_incdir in $1
 257   do
 258         while test $cf_add_incdir != /usr/include
 259         do
 260           if test -d $cf_add_incdir
 261           then
 262                 cf_have_incdir=no
 263                 if test -n "$CFLAGS$CPPFLAGS" ; then
 264                   # a loop is needed to ensure we can add subdirs of existing dirs
 265                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 266                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 267                           cf_have_incdir=yes; break
 268                         fi
 269                   done
 270                 fi
 271
 272                 if test "$cf_have_incdir" = no ; then
 273                   if test "$cf_add_incdir" = /usr/local/include ; then
 274                         if test "$GCC" = yes
 275                         then
 276                           cf_save_CPPFLAGS=$CPPFLAGS
 277                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 278                           AC_TRY_COMPILE([#include <stdio.h>],
 279                                   [printf("Hello")],
 280                                   [],
 281                                   [cf_have_incdir=yes])
 282                           CPPFLAGS=$cf_save_CPPFLAGS
 283                         fi
 284                   fi
 285                 fi
 286
 287                 if test "$cf_have_incdir" = no ; then
 288                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 289                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 290
 291                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 292                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 293                   cf_add_incdir="$cf_top_incdir"
 294                 else
 295                   break
 296                 fi
 297           else
 298                 break
 299           fi
 300         done
 301   done
 302 fi
 303 ])dnl
 304 dnl ---------------------------------------------------------------------------
 305 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 306 dnl ----------
 307 dnl Add a library, used to enforce consistency.
 308 dnl
 309 dnl $1 = library to add, without the "-l"
 310 dnl $2 = variable to update (default $LIBS)
 311 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 312 dnl ---------------------------------------------------------------------------
 313 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 314 dnl -------------
 315 dnl     Adds to the library-path
 316 dnl
 317 dnl     Some machines have trouble with multiple -L options.
 318 dnl
 319 dnl $1 is the (list of) directory(s) to add
 320 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 321 dnl
 322 AC_DEFUN([CF_ADD_LIBDIR],
 323 [
 324 if test -n "$1" ; then
 325         for cf_add_libdir in $1
 326         do
 327                 if test $cf_add_libdir = /usr/lib ; then
 328                         :
 329                 elif test -d $cf_add_libdir
 330                 then
 331                         cf_have_libdir=no
 332                         if test -n "$LDFLAGS$LIBS" ; then
 333                                 # a loop is needed to ensure we can add subdirs of existing dirs
 334                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 335                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 336                                                 cf_have_libdir=yes; break
 337                                         fi
 338                                 done
 339                         fi
 340                         if test "$cf_have_libdir" = no ; then
 341                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 342                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 343                         fi
 344                 fi
 345         done
 346 fi
 347 ])dnl
 348 dnl ---------------------------------------------------------------------------
 349 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 350 dnl -----------
 351 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 352 dnl prepended to an existing list, since their dependencies are assumed to
 353 dnl already exist in the list.
 354 dnl
 355 dnl $1 = libraries to add, with the "-l", etc.
 356 dnl $2 = variable to update (default $LIBS)
 357 AC_DEFUN([CF_ADD_LIBS],[
 358 cf_add_libs="$1"
 359 # Filter out duplicates - this happens with badly-designed ".pc" files...
 360 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 361 do
 362         for cf_add_2lib in $cf_add_libs
 363         do
 364                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 365                 then
 366                         cf_add_1lib=
 367                         break
 368                 fi
 369         done
 370         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 371 done
 372 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 373 ])dnl
 374 dnl ---------------------------------------------------------------------------
 375 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 376 dnl ------------------
 377 dnl Append to a search-list for a nonstandard header/lib-file
 378 dnl     $1 = the variable to return as result
 379 dnl     $2 = the package name
 380 dnl     $3 = the subdirectory, e.g., bin, include or lib
 381 dnl $4 = the directory under which we will test for subdirectories
 382 dnl $5 = a directory that we do not want $4 to match
 383 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 384 [
 385 test "x$4" != "x$5" && \
 386 test -d "$4" && \
 387 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 388         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 389         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 390         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 391         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 392         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 393         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 394 }
 395 ])dnl
 396 dnl ---------------------------------------------------------------------------
 397 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 398 dnl --------------
 399 dnl use this macro for appending text without introducing an extra blank at
 400 dnl the beginning
 401 define([CF_APPEND_TEXT],
 402 [
 403         test -n "[$]$1" && $1="[$]$1 "
 404         $1="[$]{$1}$2"
 405 ])dnl
 406 dnl ---------------------------------------------------------------------------
 407 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 408 dnl --------------
 409 dnl Allow user to disable a normally-on option.
 410 AC_DEFUN([CF_ARG_DISABLE],
 411 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 412 dnl ---------------------------------------------------------------------------
 413 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 414 dnl -------------
 415 dnl Allow user to enable a normally-off option.
 416 AC_DEFUN([CF_ARG_ENABLE],
 417 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 418 dnl ---------------------------------------------------------------------------
 419 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 420 dnl -------------
 421 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 422 dnl values.
 423 dnl
 424 dnl Parameters:
 425 dnl $1 = option name
 426 dnl $2 = help-string
 427 dnl $3 = action to perform if option is not default
 428 dnl $4 = action if perform if option is default
 429 dnl $5 = default option value (either 'yes' or 'no')
 430 AC_DEFUN([CF_ARG_OPTION],
 431 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 432         if test "$enableval" != "$5" ; then
 433 ifelse([$3],,[    :]dnl
 434 ,[    $3]) ifelse([$4],,,[
 435         else
 436                 $4])
 437         fi],[enableval=$5 ifelse([$4],,,[
 438         $4
 439 ])dnl
 440 ])])dnl
 441 dnl ---------------------------------------------------------------------------
 442 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 443 dnl -----------
 444 dnl Check for suitable "ar" (archiver) options for updating an archive.
 445 dnl
 446 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 447 dnl as well as a workaround for breakage of make's archive rules by the GNU
 448 dnl binutils "ar" program.
 449 AC_DEFUN([CF_AR_FLAGS],[
 450 AC_REQUIRE([CF_PROG_AR])
 451
 452 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 453         cf_cv_ar_flags=unknown
 454         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 455         do
 456
 457                 # check if $ARFLAGS already contains this choice
 458                 if test "x$ARFLAGS" != "x" ; then
 459                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 460                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 461                                 cf_cv_ar_flags=
 462                                 break
 463                         fi
 464                 fi
 465
 466                 rm -f conftest.$ac_cv_objext
 467                 rm -f conftest.a
 468
 469                 cat >conftest.$ac_ext <<EOF
 470 #line __oline__ "configure"
 471 int     testdata[[3]] = { 123, 456, 789 };
 472 EOF
 473                 if AC_TRY_EVAL(ac_compile) ; then
 474                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 475                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 476                         if test -f conftest.a ; then
 477                                 cf_cv_ar_flags=$cf_ar_flags
 478                                 break
 479                         fi
 480                 else
 481                         CF_VERBOSE(cannot compile test-program)
 482                         break
 483                 fi
 484         done
 485         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 486 ])
 487
 488 if test -n "$ARFLAGS" ; then
 489         if test -n "$cf_cv_ar_flags" ; then
 490                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 491         fi
 492 else
 493         ARFLAGS=$cf_cv_ar_flags
 494 fi
 495
 496 AC_SUBST(ARFLAGS)
 497 ])
 498 dnl ---------------------------------------------------------------------------
 499 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 500 dnl -----------------
 501 dnl Check if awk can handle big strings using printf.  Some older versions of
 502 dnl awk choke on large strings passed via "%s".
 503 dnl
 504 dnl $1 = desired string size
 505 dnl $2 = variable to set with result
 506 AC_DEFUN([CF_AWK_BIG_PRINTF],
 507 [
 508         case x$AWK in
 509         (x)
 510                 eval $2=no
 511                 ;;
 512         (*)
 513                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 514                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 515                         eval $2=yes
 516                 else
 517                         eval $2=no
 518                 fi
 519                 ;;
 520         esac
 521 ])dnl
 522 dnl ---------------------------------------------------------------------------
 523 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 524 dnl ------------
 525 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 526 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 527 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 528 dnl
 529 dnl Treat the configuration-variable specially here, since we're directly
 530 dnl substituting its value (i.e., 1/0).
 531 dnl
 532 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 533 AC_DEFUN([CF_BOOL_DECL],
 534 [
 535 AC_MSG_CHECKING(if we should include stdbool.h)
 536
 537 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 538         AC_TRY_COMPILE([],[bool foo = false],
 539                 [cf_cv_header_stdbool_h=0],
 540                 [AC_TRY_COMPILE([
 541 #ifndef __BEOS__
 542 #include <stdbool.h>
 543 #endif
 544 ],[bool foo = false],
 545                         [cf_cv_header_stdbool_h=1],
 546                         [cf_cv_header_stdbool_h=0])])])
 547
 548 if test "$cf_cv_header_stdbool_h" = 1
 549 then    AC_MSG_RESULT(yes)
 550 else    AC_MSG_RESULT(no)
 551 fi
 552
 553 AC_MSG_CHECKING([for builtin bool type])
 554
 555 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 556         AC_TRY_COMPILE([
 557 #include <stdio.h>
 558 #include <sys/types.h>
 559 ],[bool x = false],
 560                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 561                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 562         ])
 563
 564 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 565 then    AC_MSG_RESULT(yes)
 566 else    AC_MSG_RESULT(no)
 567 fi
 568 ])dnl
 569 dnl ---------------------------------------------------------------------------
 570 dnl CF_BOOL_SIZE version: 15 updated: 2017/01/21 11:06:25
 571 dnl ------------
 572 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 573 dnl Don't bother looking for bool.h, since it's been deprecated.
 574 dnl
 575 dnl If the current compiler is C rather than C++, we get the bool definition
 576 dnl from <stdbool.h>.
 577 AC_DEFUN([CF_BOOL_SIZE],
 578 [
 579 AC_MSG_CHECKING([for size of bool])
 580 AC_CACHE_VAL(cf_cv_type_of_bool,[
 581         rm -f cf_test.out
 582         AC_TRY_RUN([
 583 #include <stdlib.h>
 584 #include <stdio.h>
 585
 586 #if defined(__cplusplus)
 587
 588 #ifdef HAVE_GXX_BUILTIN_H
 589 #include <g++/builtin.h>
 590 #elif HAVE_GPP_BUILTIN_H
 591 #include <gpp/builtin.h>
 592 #elif HAVE_BUILTIN_H
 593 #include <builtin.h>
 594 #endif
 595
 596 #else
 597
 598 #if $cf_cv_header_stdbool_h
 599 #include <stdbool.h>
 600 #endif
 601
 602 #endif
 603
 604 int main(void)
 605 {
 606         FILE *fp = fopen("cf_test.out", "w");
 607         if (fp != 0) {
 608                 bool x = true;
 609                 if ((bool)(-x) >= 0)
 610                         fputs("unsigned ", fp);
 611                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 612                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 613                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 614                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 615                 fclose(fp);
 616         }
 617         ${cf_cv_main_return:-return}(0);
 618 }
 619                 ],
 620                 [cf_cv_type_of_bool=`cat cf_test.out`
 621                  if test -z "$cf_cv_type_of_bool"; then
 622                    cf_cv_type_of_bool=unknown
 623                  fi],
 624                 [cf_cv_type_of_bool=unknown],
 625                 [cf_cv_type_of_bool=unknown])
 626         ])
 627         rm -f cf_test.out
 628 AC_MSG_RESULT($cf_cv_type_of_bool)
 629 if test "$cf_cv_type_of_bool" = unknown ; then
 630         case .$NCURSES_BOOL in
 631         (.auto|.) NCURSES_BOOL=unsigned;;
 632         esac
 633         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 634         cf_cv_type_of_bool=$NCURSES_BOOL
 635 fi
 636 ])dnl
 637 dnl ---------------------------------------------------------------------------
 638 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
 639 dnl -----------
 640 dnl If we're cross-compiling, allow the user to override the tools and their
 641 dnl options.  The configure script is oriented toward identifying the host
 642 dnl compiler, etc., but we need a build compiler to generate parts of the
 643 dnl source.
 644 dnl
 645 dnl $1 = default for $CPPFLAGS
 646 dnl $2 = default for $LIBS
 647 AC_DEFUN([CF_BUILD_CC],[
 648 CF_ACVERSION_CHECK(2.52,,
 649         [AC_REQUIRE([CF_PROG_EXT])])
 650 if test "$cross_compiling" = yes ; then
 651
 652         # defaults that we might want to override
 653         : ${BUILD_CFLAGS:=''}
 654         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 655         : ${BUILD_LDFLAGS:=''}
 656         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 657         : ${BUILD_EXEEXT:='$x'}
 658         : ${BUILD_OBJEXT:='o'}
 659
 660         AC_ARG_WITH(build-cc,
 661                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 662                 [BUILD_CC="$withval"],
 663                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 664         AC_MSG_CHECKING(for native build C compiler)
 665         AC_MSG_RESULT($BUILD_CC)
 666
 667         AC_MSG_CHECKING(for native build C preprocessor)
 668         AC_ARG_WITH(build-cpp,
 669                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 670                 [BUILD_CPP="$withval"],
 671                 [BUILD_CPP='${BUILD_CC} -E'])
 672         AC_MSG_RESULT($BUILD_CPP)
 673
 674         AC_MSG_CHECKING(for native build C flags)
 675         AC_ARG_WITH(build-cflags,
 676                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 677                 [BUILD_CFLAGS="$withval"])
 678         AC_MSG_RESULT($BUILD_CFLAGS)
 679
 680         AC_MSG_CHECKING(for native build C preprocessor-flags)
 681         AC_ARG_WITH(build-cppflags,
 682                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 683                 [BUILD_CPPFLAGS="$withval"])
 684         AC_MSG_RESULT($BUILD_CPPFLAGS)
 685
 686         AC_MSG_CHECKING(for native build linker-flags)
 687         AC_ARG_WITH(build-ldflags,
 688                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 689                 [BUILD_LDFLAGS="$withval"])
 690         AC_MSG_RESULT($BUILD_LDFLAGS)
 691
 692         AC_MSG_CHECKING(for native build linker-libraries)
 693         AC_ARG_WITH(build-libs,
 694                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 695                 [BUILD_LIBS="$withval"])
 696         AC_MSG_RESULT($BUILD_LIBS)
 697
 698         # this assumes we're on Unix.
 699         BUILD_EXEEXT=
 700         BUILD_OBJEXT=o
 701
 702         : ${BUILD_CC:='${CC}'}
 703
 704         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 705                 AC_MSG_ERROR([Cross-build requires two compilers.
 706 Use --with-build-cc to specify the native compiler.])
 707         fi
 708
 709 else
 710         : ${BUILD_CC:='${CC}'}
 711         : ${BUILD_CPP:='${CPP}'}
 712         : ${BUILD_CFLAGS:='${CFLAGS}'}
 713         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 714         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 715         : ${BUILD_LIBS:='${LIBS}'}
 716         : ${BUILD_EXEEXT:='$x'}
 717         : ${BUILD_OBJEXT:='o'}
 718 fi
 719
 720 AC_SUBST(BUILD_CC)
 721 AC_SUBST(BUILD_CPP)
 722 AC_SUBST(BUILD_CFLAGS)
 723 AC_SUBST(BUILD_CPPFLAGS)
 724 AC_SUBST(BUILD_LDFLAGS)
 725 AC_SUBST(BUILD_LIBS)
 726 AC_SUBST(BUILD_EXEEXT)
 727 AC_SUBST(BUILD_OBJEXT)
 728 ])dnl
 729 dnl ---------------------------------------------------------------------------
 730 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
 731 dnl ---------------
 732 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 733 dnl into CC.  This will not help with broken scripts that wrap the compiler
 734 dnl with options, but eliminates a more common category of user confusion.
 735 dnl
 736 dnl In particular, it addresses the problem of being able to run the C
 737 dnl preprocessor in a consistent manner.
 738 dnl
 739 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 740 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 741 dnl outweighs that limitation.
 742 AC_DEFUN([CF_CC_ENV_FLAGS],
 743 [
 744 # This should have been defined by AC_PROG_CC
 745 : ${CC:=cc}
 746
 747 AC_MSG_CHECKING(\$CFLAGS variable)
 748 case "x$CFLAGS" in
 749 (*-[[IUD]]*)
 750         AC_MSG_RESULT(broken)
 751         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 752         cf_flags="$CFLAGS"
 753         CFLAGS=
 754         for cf_arg in $cf_flags
 755         do
 756                 CF_ADD_CFLAGS($cf_arg)
 757         done
 758         ;;
 759 (*)
 760         AC_MSG_RESULT(ok)
 761         ;;
 762 esac
 763
 764 AC_MSG_CHECKING(\$CC variable)
 765 case "$CC" in
 766 (*[[\ \ ]]-*)
 767         AC_MSG_RESULT(broken)
 768         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 769         # humor him...
 770         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 771         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 772         CC="$cf_prog"
 773         for cf_arg in $cf_flags
 774         do
 775                 case "x$cf_arg" in
 776                 (x-[[IUDfgOW]]*)
 777                         CF_ADD_CFLAGS($cf_arg)
 778                         ;;
 779                 (*)
 780                         CC="$CC $cf_arg"
 781                         ;;
 782                 esac
 783         done
 784         CF_VERBOSE(resulting CC: '$CC')
 785         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 786         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 787         ;;
 788 (*)
 789         AC_MSG_RESULT(ok)
 790         ;;
 791 esac
 792 ])dnl
 793 dnl ---------------------------------------------------------------------------
 794 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 795 dnl ---------------
 796 dnl Determine the default configuration into which we'll install ncurses.  This
 797 dnl can be overridden by the user's command-line options.  There's two items to
 798 dnl look for:
 799 dnl     1. the prefix (e.g., /usr)
 800 dnl     2. the header files (e.g., /usr/include/ncurses)
 801 dnl We'll look for a previous installation of ncurses and use the same defaults.
 802 dnl
 803 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 804 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 805 dnl programs from a vendor's.
 806 AC_DEFUN([CF_CFG_DEFAULTS],
 807 [
 808 AC_MSG_CHECKING(for prefix)
 809 if test "x$prefix" = "xNONE" ; then
 810         case "$cf_cv_system_name" in
 811                 # non-vendor systems don't have a conflict
 812         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 813                 prefix=/usr
 814                 ;;
 815         (*)     prefix=$ac_default_prefix
 816                 ;;
 817         esac
 818 fi
 819 AC_MSG_RESULT($prefix)
 820
 821 if test "x$prefix" = "xNONE" ; then
 822 AC_MSG_CHECKING(for default include-directory)
 823 test -n "$verbose" && echo 1>&AC_FD_MSG
 824 for cf_symbol in \
 825         $includedir \
 826         $includedir/ncurses \
 827         $prefix/include \
 828         $prefix/include/ncurses \
 829         /usr/local/include \
 830         /usr/local/include/ncurses \
 831         /usr/include \
 832         /usr/include/ncurses
 833 do
 834         cf_dir=`eval echo $cf_symbol`
 835         if test -f $cf_dir/curses.h ; then
 836         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 837                 includedir="$cf_symbol"
 838                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 839                 break
 840         fi
 841         fi
 842         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 843 done
 844 AC_MSG_RESULT($includedir)
 845 fi
 846 ])dnl
 847 dnl ---------------------------------------------------------------------------
 848 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
 849 dnl ----------
 850 dnl Check if the terminal-capability database functions are available.  If not,
 851 dnl ncurses has a much-reduced version.
 852 AC_DEFUN([CF_CGETENT],[
 853 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 854 AC_TRY_LINK([
 855 #include <stdlib.h>],[
 856         char temp[128];
 857         char *buf = temp;
 858         char *db_array = temp;
 859         cgetent(&buf, &db_array, "vt100");
 860         cgetcap(buf, "tc", '=');
 861         cgetmatch(buf, "tc");
 862         ],
 863         [cf_cv_cgetent=yes],
 864         [cf_cv_cgetent=no])
 865 ])
 866
 867 if test "$cf_cv_cgetent" = yes
 868 then
 869         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 870 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 871 AC_TRY_LINK([
 872 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
 873 #include <stdlib.h>],[
 874         char temp[128];
 875         char *buf = temp;
 876 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 877         const char *db_array = temp;
 878         cgetent(&buf, &db_array, "vt100");
 879 #endif
 880         cgetcap(buf, "tc", '=');
 881         cgetmatch(buf, "tc");
 882         ],
 883         [cf_cv_cgetent_const=yes],
 884         [cf_cv_cgetent_const=no])
 885 ])
 886         if test "$cf_cv_cgetent_const" = yes
 887         then
 888                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 889         fi
 890 fi
 891 ])dnl
 892 dnl ---------------------------------------------------------------------------
 893 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 894 dnl --------------
 895 dnl Check if we're accidentally using a cache from a different machine.
 896 dnl Derive the system name, as a check for reusing the autoconf cache.
 897 dnl
 898 dnl If we've packaged config.guess and config.sub, run that (since it does a
 899 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 900 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 901 dnl which is useful in cross-compiles.
 902 dnl
 903 dnl Note: we would use $ac_config_sub, but that is one of the places where
 904 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 905 AC_DEFUN([CF_CHECK_CACHE],
 906 [
 907 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 908         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 909         system_name="$host_os"
 910 else
 911         system_name="`(uname -s -r) 2>/dev/null`"
 912         if test -z "$system_name" ; then
 913                 system_name="`(hostname) 2>/dev/null`"
 914         fi
 915 fi
 916 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 917 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 918
 919 test -z "$system_name" && system_name="$cf_cv_system_name"
 920 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 921
 922 if test ".$system_name" != ".$cf_cv_system_name" ; then
 923         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 924         AC_MSG_ERROR("Please remove config.cache and try again.")
 925 fi
 926 ])dnl
 927 dnl ---------------------------------------------------------------------------
 928 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
 929 dnl --------------
 930 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 931 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 932 dnl ourselves.
 933 dnl
 934 dnl $1 = the name to check
 935 dnl $2 = the assumed type
 936 AC_DEFUN([CF_CHECK_ERRNO],
 937 [
 938 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 939         AC_TRY_COMPILE([
 940 #ifdef HAVE_STDLIB_H
 941 #include <stdlib.h>
 942 #endif
 943 #include <stdio.h>
 944 #include <sys/types.h>
 945 #include <errno.h> ],
 946         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 947         [cf_cv_dcl_$1=yes],
 948         [cf_cv_dcl_$1=no])
 949 ])
 950
 951 if test "$cf_cv_dcl_$1" = no ; then
 952         CF_UPPER(cf_result,decl_$1)
 953         AC_DEFINE_UNQUOTED($cf_result)
 954 fi
 955
 956 # It's possible (for near-UNIX clones) that the data doesn't exist
 957 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 958 ])dnl
 959 dnl ---------------------------------------------------------------------------
 960 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
 961 dnl --------------------
 962 dnl Check for existence of external data in the current set of libraries.  If
 963 dnl we can modify it, it's real enough.
 964 dnl $1 = the name to check
 965 dnl $2 = its type
 966 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 967 [
 968 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 969         AC_TRY_LINK([
 970 #undef $1
 971 extern $2 $1;
 972 ],
 973         [$1 = 2],
 974         [cf_cv_have_$1=yes],
 975         [cf_cv_have_$1=no])
 976 ])
 977
 978 if test "$cf_cv_have_$1" = yes ; then
 979         CF_UPPER(cf_result,have_$1)
 980         AC_DEFINE_UNQUOTED($cf_result)
 981 fi
 982
 983 ])dnl
 984 dnl ---------------------------------------------------------------------------
 985 dnl CF_CHECK_GPM_WGETCH version: 3 updated: 2017/01/21 11:06:25
 986 dnl -------------------
 987 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 988 dnl is not "weak" - warn about this because it can create problems linking
 989 dnl applications with ncurses.
 990 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 991 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 992
 993 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 994 cf_cv_check_gpm_wgetch=unknown
 995 if test "$cross_compiling" != yes ; then
 996
 997 cat >conftest.$ac_ext <<CF_EOF
 998 #include <gpm.h>
 999 int main(void)
1000 {
1001         Gpm_Wgetch();
1002         ${cf_cv_main_return:-return}(0);
1003 }
1004 CF_EOF
1005
1006         cf_save_LIBS="$LIBS"
1007         # This only works if we can look at the symbol table.  If a shared
1008         # library is stripped for install, we cannot use that.  So we're forced
1009         # to rely on the static library, noting that some packagers may not
1010         # include it.
1011         LIBS="-static -lgpm -dynamic $LIBS"
1012         if AC_TRY_EVAL(ac_compile) ; then
1013                 if AC_TRY_EVAL(ac_link) ; then
1014                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
1015                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1016                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1017                 fi
1018         fi
1019         rm -rf conftest*
1020         LIBS="$cf_save_LIBS"
1021 fi
1022 ])
1023
1024 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1025         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1026 fi
1027 ])])dnl
1028 dnl ---------------------------------------------------------------------------
1029 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
1030 dnl ------------------------
1031 dnl Show the version of libtool
1032 dnl
1033 dnl Save the version in a cache variable - this is not entirely a good thing,
1034 dnl but the version string from libtool is very ugly, and for bug reports it
1035 dnl might be useful to have the original string.
1036 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1037 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1038 then
1039         AC_MSG_CHECKING(version of $LIBTOOL)
1040         CF_LIBTOOL_VERSION
1041         AC_MSG_RESULT($cf_cv_libtool_version)
1042         if test -z "$cf_cv_libtool_version" ; then
1043                 AC_MSG_ERROR(This is not GNU libtool)
1044         fi
1045 else
1046         AC_MSG_ERROR(GNU libtool has not been found)
1047 fi
1048 ])dnl
1049 dnl ---------------------------------------------------------------------------
1050 dnl CF_CHECK_WCHAR_H version: 2 updated: 2017/01/21 11:06:25
1051 dnl ----------------
1052 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1053 AC_DEFUN([CF_CHECK_WCHAR_H],[
1054 AC_CHECK_HEADERS( \
1055 wchar.h \
1056 wctype.h \
1057 )
1058 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1059 AC_TRY_COMPILE(
1060 [
1061 #include <stdlib.h>
1062 #ifdef HAVE_WCHAR_H
1063 #include <wchar.h>
1064 #endif
1065 #ifdef HAVE_WCTYPE_H
1066 #include <wctype.h>
1067 #endif
1068 ],[
1069         wint_t foo = 0;
1070         int bar = iswpunct(foo)],
1071         [cf_cv_wchar_h_okay=yes],
1072         [cf_cv_wchar_h_okay=no])])
1073
1074 if test $cf_cv_wchar_h_okay = no
1075 then
1076         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1077 fi
1078 ])dnl
1079 dnl ---------------------------------------------------------------------------
1080 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1081 dnl -------------------------
1082 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1083 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1084 dnl
1085 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1086 dnl all of those were combined into a page of useful graphics characters.
1087 dnl
1088 dnl So far, so good.
1089 dnl
1090 dnl However, while they are useful, there are other considerations.  CJK
1091 dnl is (because of poor device resolution) often rendered as double-width
1092 dnl characters.  So... for these generally-useful characters, what should
1093 dnl be the width (to make them consistent with adjacent characters)?
1094 dnl
1095 dnl The obvious choice would have been to make this locale-dependent, and use
1096 dnl wcwidth() to tell applications what the actual width is.  That was too
1097 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1098 dnl See for example
1099 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1100 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1101 dnl
1102 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1103 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1104 dnl instance, it lists half (44/96) of the Latin-1 characters as
1105 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1106 dnl
1107 dnl What this means for the implementor is that on some systems wcwidth() can
1108 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1109 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1110 dnl characters).  These do not necessarily match the behavior of the terminal
1111 dnl emulator.  xterm, for instance, does an optional startup check to find if
1112 dnl this problem (or similar) exists with the system's locale tables, rejecting
1113 dnl them if they are too unreliable.
1114 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1115 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1116 cat >conftest.in <<CF_EOF
1117 -       VT100 symbols
1118 0x250c  upper left corner
1119 0x2514  lower left corner
1120 0x2510  upper right corner
1121 0x2518  lower right corner
1122 0x251c  tee pointing left
1123 0x2524  tee pointing right
1124 0x2534  tee pointing up
1125 0x252c  tee pointing down
1126 0x2500  horizontal line
1127 0x2502  vertical line
1128 0x253c  large plus or crossover
1129 0x23ba  scan line 1
1130 0x23bd  scan line 9
1131 0x25c6  diamond
1132 0x2592  checker board (stipple)
1133 0x00b0  degree symbol
1134 0x00b1  plus/minus
1135 0x00b7  bullet
1136 -       Teletype 5410v1 symbols
1137 0x2190  arrow pointing left
1138 0x2192  arrow pointing right
1139 0x2193  arrow pointing down
1140 0x2191  arrow pointing up
1141 0x2592  board of squares
1142 0x2603  lantern symbol
1143 0x25ae  solid square block
1144 -       these defaults were invented for ncurses
1145 0x23bb  scan line 3
1146 0x23bc  scan line 7
1147 0x2264  less-than-or-equal-to
1148 0x2265  greater-than-or-equal-to
1149 0x03c0  greek pi
1150 0x2260  not-equal
1151 0x00a3  pound-sterling symbol
1152 -       thick-line-drawing
1153 0x250f  upper left corner
1154 0x2517  lower left corner
1155 0x2513  upper right corner
1156 0x251b  lower right corner
1157 0x2523  tee pointing left
1158 0x252b  tee pointing right
1159 0x253b  tee pointing up
1160 0x2533  tee pointing down
1161 0x2501  horizontal line
1162 0x2503  vertical line
1163 0x254b  large plus or crossover
1164 -       double-line-drawing
1165 0x2554  upper left corner
1166 0x255a  lower left corner
1167 0x2557  upper right corner
1168 0x255d  lower right corner
1169 0x2563  tee pointing left
1170 0x2560  tee pointing right
1171 0x2569  tee pointing up
1172 0x2566  tee pointing down
1173 0x2550  horizontal line
1174 0x2551  vertical line
1175 0x256c  large plus or crossover
1176 CF_EOF
1177 AC_TRY_RUN([
1178 #include <locale.h>
1179 #include <stdio.h>
1180 #include <wchar.h>
1181
1182 #define MY_LEN 80
1183
1184 int
1185 main(void)
1186 {
1187         FILE *fp;
1188         int value;
1189         char buffer[MY_LEN + 1];
1190         char notes[MY_LEN + 1];
1191         int totals = 0;
1192         int passed = 0;
1193
1194         if (setlocale(LC_ALL, "en_US.UTF8") ||
1195                 setlocale(LC_ALL, "en_US.UTF-8") ||
1196                 setlocale(LC_ALL, "en_US.utf8") ||
1197                 setlocale(LC_ALL, "en_US.utf-8")) {
1198                 if ((fp = fopen("conftest.in", "r")) != 0) {
1199                         while (fgets(buffer, MY_LEN, fp) != 0) {
1200                                 if (*buffer == '-') {
1201                                         fprintf(stderr, "\t%s", buffer);
1202                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1203                                         ++totals;
1204                                         if (wcwidth(value) == 1)
1205                                                 ++passed;
1206                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1207                                 } else {
1208                                         fprintf(stderr, "?\t%s", buffer);
1209                                 }
1210                         }
1211                 }
1212         }
1213         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1214         return (totals == passed) ? 0 : 1;
1215 }
1216 ],
1217 [cf_cv_wcwidth_graphics=yes],
1218 [cf_cv_wcwidth_graphics=no],
1219 [cf_cv_wcwidth_graphics=unknown])
1220 ])
1221 ])dnl
1222 dnl ---------------------------------------------------------------------------
1223 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1224 dnl -----------------
1225 dnl Check if the given compiler is really clang.  clang's C driver defines
1226 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1227 dnl not ignore some gcc options.
1228 dnl
1229 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1230 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1231 dnl the wrappers for gcc and g++ warnings.
1232 dnl
1233 dnl $1 = GCC (default) or GXX
1234 dnl $2 = CLANG_COMPILER (default)
1235 dnl $3 = CFLAGS (default) or CXXFLAGS
1236 AC_DEFUN([CF_CLANG_COMPILER],[
1237 ifelse([$2],,CLANG_COMPILER,[$2])=no
1238
1239 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1240         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1241         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1242         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1243         AC_TRY_COMPILE([],[
1244 #ifdef __clang__
1245 #else
1246 make an error
1247 #endif
1248 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1249 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1250 ],[])
1251         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1252         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1253 fi
1254 ])
1255 dnl ---------------------------------------------------------------------------
1256 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1257 dnl -----------------
1258 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1259 dnl is a late feature for the standard and is not in some recent compilers
1260 dnl (1999/9/11).
1261 AC_DEFUN([CF_CPP_PARAM_INIT],
1262 [
1263 if test -n "$CXX"; then
1264 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1265         AC_LANG_SAVE
1266         AC_LANG_CPLUSPLUS
1267         AC_TRY_RUN([
1268 class TEST {
1269 private:
1270         int value;
1271 public:
1272         TEST(int x = 1);
1273         ~TEST();
1274 };
1275
1276 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1277 {
1278         value = x;
1279 }
1280 int main(void) { }
1281 ],
1282         [cf_cv_cpp_param_init=yes],
1283         [cf_cv_cpp_param_init=no],
1284         [cf_cv_cpp_param_init=unknown])
1285         AC_LANG_RESTORE
1286 ])
1287 fi
1288 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1289 ])dnl
1290 dnl ---------------------------------------------------------------------------
1291 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1292 dnl ------------------
1293 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1294 dnl not be supported in g++ before 3.0
1295 AC_DEFUN([CF_CPP_STATIC_CAST],
1296 [
1297 if test -n "$CXX"; then
1298
1299 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1300         AC_LANG_SAVE
1301         AC_LANG_CPLUSPLUS
1302
1303         AC_TRY_COMPILE([
1304 class NCursesPanel
1305 {
1306 public:
1307   NCursesPanel(int nlines,
1308                int ncols,
1309                int begin_y = 0,
1310                int begin_x = 0)
1311   {
1312   }
1313   NCursesPanel();
1314   ~NCursesPanel();
1315 };
1316
1317 template<class T> class NCursesUserPanel : public NCursesPanel
1318 {
1319 public:
1320   NCursesUserPanel (int nlines,
1321                     int ncols,
1322                     int begin_y = 0,
1323                     int begin_x = 0,
1324                     const T* p_UserData = static_cast<T*>(0))
1325     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1326   {
1327   };
1328   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1329   {
1330   };
1331
1332   virtual ~NCursesUserPanel() {};
1333 };
1334 ],[
1335         const char* p_UserData = static_cast<char*>(0)],
1336         [cf_cv_cpp_static_cast=yes],
1337         [cf_cv_cpp_static_cast=no])
1338
1339         AC_LANG_RESTORE
1340 ])
1341
1342 fi
1343
1344 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1345 ])dnl
1346 dnl ---------------------------------------------------------------------------
1347 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1348 dnl ---------------
1349 dnl Setup special archiver flags for given compilers.
1350 AC_DEFUN([CF_CXX_AR_FLAGS],[
1351         CXX_AR='$(AR)'
1352         CXX_ARFLAGS='$(ARFLAGS)'
1353         case $cf_cv_system_name in
1354         (irix*)
1355             if test "$GXX" != yes ; then
1356                 CXX_AR='$(CXX)'
1357                 CXX_ARFLAGS='-ar -o'
1358             fi
1359             ;;
1360         (sco3.2v5*)
1361             CXXLDFLAGS="-u main"
1362             ;;
1363         (solaris2*)
1364             if test "$GXX" != yes ; then
1365                 CXX_AR='$(CXX)'
1366                 CXX_ARFLAGS='-xar -o'
1367             fi
1368             ;;
1369         esac
1370         AC_SUBST(CXXLDFLAGS)
1371         AC_SUBST(CXX_AR)
1372         AC_SUBST(CXX_ARFLAGS)
1373 ])dnl
1374 dnl ---------------------------------------------------------------------------
1375 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1376 dnl -------------------------
1377 dnl For c++, check if iostream uses "std::" namespace.
1378 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1379 AC_CHECK_HEADERS(iostream)
1380 if test x"$ac_cv_header_iostream" = xyes ; then
1381         AC_MSG_CHECKING(if iostream uses std-namespace)
1382         AC_TRY_COMPILE([
1383 #include <iostream>
1384 using std::endl;
1385 using std::cerr;],[
1386 cerr << "testing" << endl;
1387 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1388         AC_MSG_RESULT($cf_iostream_namespace)
1389         if test "$cf_iostream_namespace" = yes ; then
1390                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1391         fi
1392 fi
1393 ])dnl
1394 dnl ---------------------------------------------------------------------------
1395 dnl CF_C_INLINE version: 5 updated: 2015/04/18 08:56:57
1396 dnl -----------
1397 dnl Check if the C compiler supports "inline".
1398 dnl $1 is the name of a shell variable to set if inline is supported
1399 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1400 AC_DEFUN([CF_C_INLINE],[
1401 AC_C_INLINE
1402 $1=
1403 if test "$ac_cv_c_inline" != no ; then
1404         $1=inline
1405         if test "$INTEL_COMPILER" = yes
1406         then
1407                 :
1408         elif test "$CLANG_COMPILER" = yes
1409         then
1410                 :
1411         elif test "$GCC" = yes
1412         then
1413                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1414                 cf_save_CFLAGS=$CFLAGS
1415                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1416                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1417                 [${cf_cv_main_return:-return} foo()],
1418                 [cf_cv_gcc_inline=yes],
1419                 [cf_cv_gcc_inline=no])
1420                 CFLAGS=$cf_save_CFLAGS
1421                 ])
1422                 if test "$cf_cv_gcc_inline" = yes ; then
1423                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1424                 fi
1425         fi
1426 fi
1427 AC_SUBST($1)
1428 ])dnl
1429 dnl ---------------------------------------------------------------------------
1430 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1431 dnl ----------
1432 dnl "dirname" is not portable, so we fake it with a shell script.
1433 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1434 dnl ---------------------------------------------------------------------------
1435 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1436 dnl ---------------
1437 AC_DEFUN([CF_DIRS_TO_MAKE],
1438 [
1439 DIRS_TO_MAKE="lib"
1440 for cf_item in $cf_list_models
1441 do
1442         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1443         for cf_item2 in $DIRS_TO_MAKE
1444         do
1445                 test $cf_item2 = $cf_subdir && break
1446         done
1447         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1448 done
1449 for cf_dir in $DIRS_TO_MAKE
1450 do
1451         test ! -d $cf_dir && mkdir $cf_dir
1452 done
1453 AC_SUBST(DIRS_TO_MAKE)
1454 ])dnl
1455 dnl ---------------------------------------------------------------------------
1456 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1457 dnl ---------------
1458 dnl You can always use "make -n" to see the actual options, but it's hard to
1459 dnl pick out/analyze warning messages when the compile-line is long.
1460 dnl
1461 dnl Sets:
1462 dnl     ECHO_LT - symbol to control if libtool is verbose
1463 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1464 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1465 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1466 dnl     ECHO_CC - symbol to put before any "cc" line
1467 dnl
1468 AC_DEFUN([CF_DISABLE_ECHO],[
1469 AC_MSG_CHECKING(if you want to see long compiling messages)
1470 CF_ARG_DISABLE(echo,
1471         [  --disable-echo          do not display "compiling" commands],
1472         [
1473         ECHO_LT='--silent'
1474         ECHO_LD='@echo linking [$]@;'
1475         RULE_CC='@echo compiling [$]<'
1476         SHOW_CC='@echo compiling [$]@'
1477         ECHO_CC='@'
1478 ],[
1479         ECHO_LT=''
1480         ECHO_LD=''
1481         RULE_CC=''
1482         SHOW_CC=''
1483         ECHO_CC=''
1484 ])
1485 AC_MSG_RESULT($enableval)
1486 AC_SUBST(ECHO_LT)
1487 AC_SUBST(ECHO_LD)
1488 AC_SUBST(RULE_CC)
1489 AC_SUBST(SHOW_CC)
1490 AC_SUBST(ECHO_CC)
1491 ])dnl
1492 dnl ---------------------------------------------------------------------------
1493 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1494 dnl ------------------------
1495 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1496 AC_MSG_CHECKING(if we want to use GNAT projects)
1497 CF_ARG_DISABLE(gnat-projects,
1498         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1499         [enable_gnat_projects=no],
1500         [enable_gnat_projects=yes])
1501 AC_MSG_RESULT($enable_gnat_projects)
1502 ])dnl
1503 dnl ---------------------------------------------------------------------------
1504 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1505 dnl ----------------
1506 dnl Combine no-leak checks with the libraries or tools that are used for the
1507 dnl checks.
1508 AC_DEFUN([CF_DISABLE_LEAKS],[
1509
1510 AC_REQUIRE([CF_WITH_DMALLOC])
1511 AC_REQUIRE([CF_WITH_DBMALLOC])
1512 AC_REQUIRE([CF_WITH_VALGRIND])
1513
1514 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1515 AC_ARG_ENABLE(leaks,
1516         [  --disable-leaks         test: free permanent memory, analyze leaks],
1517         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1518         : ${with_no_leaks:=no})
1519 AC_MSG_RESULT($with_no_leaks)
1520
1521 if test "$with_no_leaks" = yes ; then
1522         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1523         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1524 fi
1525 ])dnl
1526 dnl ---------------------------------------------------------------------------
1527 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1528 dnl --------------------------
1529 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1530 dnl the older "-version-info" feature.  The newer feature allows us to use
1531 dnl version numbering on shared libraries which make them compatible with
1532 dnl various systems.
1533 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1534 [
1535 AC_MSG_CHECKING(if libtool -version-number should be used)
1536 CF_ARG_DISABLE(libtool-version,
1537         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1538         [cf_libtool_version=no],
1539         [cf_libtool_version=yes])
1540 AC_MSG_RESULT($cf_libtool_version)
1541
1542 if test "$cf_libtool_version" = yes ; then
1543         LIBTOOL_VERSION="-version-number"
1544 else
1545         LIBTOOL_VERSION="-version-info"
1546         case "x$VERSION" in
1547         (x)
1548                 AC_MSG_WARN(VERSION was not set)
1549                 ;;
1550         (x*.*.*)
1551                 ABI_VERSION="$VERSION"
1552                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1553                 ;;
1554         (x*:*:*)
1555                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1556                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1557                 ;;
1558         (*)
1559                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1560                 ;;
1561         esac
1562 fi
1563
1564 AC_SUBST(ABI_VERSION)
1565 AC_SUBST(LIBTOOL_VERSION)
1566 ])dnl
1567 dnl ---------------------------------------------------------------------------
1568 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1569 dnl ---------------------
1570 dnl The rpath-hack makes it simpler to build programs, particularly with the
1571 dnl *BSD ports which may have essential libraries in unusual places.  But it
1572 dnl can interfere with building an executable for the base system.  Use this
1573 dnl option in that case.
1574 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1575 [
1576 AC_MSG_CHECKING(if rpath-hack should be disabled)
1577 CF_ARG_DISABLE(rpath-hack,
1578         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1579         [cf_disable_rpath_hack=yes],
1580         [cf_disable_rpath_hack=no])
1581 AC_MSG_RESULT($cf_disable_rpath_hack)
1582 if test "$cf_disable_rpath_hack" = no ; then
1583         CF_RPATH_HACK
1584 fi
1585 ])
1586 dnl ---------------------------------------------------------------------------
1587 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1588 dnl ------------------
1589 dnl This is the "--enable-pc-files" option, which is available if there is a
1590 dnl pkg-config configuration on the local machine.
1591 AC_DEFUN([CF_ENABLE_PC_FILES],[
1592 AC_REQUIRE([CF_PKG_CONFIG])
1593 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1594
1595 if test "x$PKG_CONFIG" != xnone
1596 then
1597         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1598 else
1599         AC_MSG_CHECKING(if we should install .pc files)
1600 fi
1601
1602 AC_ARG_ENABLE(pc-files,
1603         [  --enable-pc-files       generate and install .pc files for pkg-config],
1604         [enable_pc_files=$enableval],
1605         [enable_pc_files=no])
1606 AC_MSG_RESULT($enable_pc_files)
1607
1608 if test "x$enable_pc_files" != xno
1609 then
1610         MAKE_PC_FILES=
1611         case "x$PKG_CONFIG_LIBDIR" in
1612         (xno|xyes)
1613                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1614                 ;;
1615         (*)
1616                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1617                 ;;
1618         esac
1619 else
1620         MAKE_PC_FILES="#"
1621 fi
1622 AC_SUBST(MAKE_PC_FILES)
1623 ])dnl
1624 dnl ---------------------------------------------------------------------------
1625 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1626 dnl ---------------
1627 dnl Check if the rpath option should be used, setting cache variable
1628 dnl cf_cv_enable_rpath if so.
1629 AC_DEFUN([CF_ENABLE_RPATH],
1630 [
1631 AC_MSG_CHECKING(if rpath option should be used)
1632 AC_ARG_ENABLE(rpath,
1633 [  --enable-rpath          use rpath option when generating shared libraries],
1634 [cf_cv_enable_rpath=$enableval],
1635 [cf_cv_enable_rpath=no])
1636 AC_MSG_RESULT($cf_cv_enable_rpath)
1637 ])dnl
1638 dnl ---------------------------------------------------------------------------
1639 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
1640 dnl ----------------------
1641 dnl On a few platforms, the compiler and/or loader nags with untruthful
1642 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1643 dnl and implying that most uses of the recommended alternatives are correct.
1644 dnl
1645 dnl Factually speaking, no one has actually counted the number of uses of these
1646 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1647 dnl instances are meaningless compared to the hundreds of millions of lines of
1648 dnl existing C code.
1649 dnl
1650 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1651 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1652 dnl standard - but evolved through phases, and older implementations are likely
1653 dnl to yield surprising results, as documented in manpages on various systems.
1654 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1655 [
1656 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1657 AC_ARG_ENABLE(string-hacks,
1658         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1659         [with_string_hacks=$enableval],
1660         [with_string_hacks=no])
1661 AC_MSG_RESULT($with_string_hacks)
1662
1663 if test "x$with_string_hacks" = "xyes"; then
1664         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1665         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1666         AC_CHECK_FUNC(strlcat,[
1667                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1668                 ],[
1669                 AC_CHECK_LIB(bsd,strlcat,[
1670                         CF_ADD_LIB(bsd)
1671                         AC_CHECK_HEADERS(bsd/string.h)
1672                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1673                         ])
1674                 ])
1675         AC_CHECK_FUNCS( strlcpy snprintf )
1676 fi
1677 ])dnl
1678 dnl ---------------------------------------------------------------------------
1679 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1680 dnl --------
1681 dnl Check if 'errno' is declared in <errno.h>
1682 AC_DEFUN([CF_ERRNO],
1683 [
1684 CF_CHECK_ERRNO(errno)
1685 ])dnl
1686 dnl ---------------------------------------------------------------------------
1687 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1688 dnl ---------------
1689 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1690 dnl math.h and builtin.h, only for ncurses
1691 AC_DEFUN([CF_ETIP_DEFINES],
1692 [
1693 AC_MSG_CHECKING(for special defines needed for etip.h)
1694 cf_save_CXXFLAGS="$CXXFLAGS"
1695 cf_result="none"
1696
1697 # etip.h includes ncurses.h which includes ncurses_dll.h
1698 # But ncurses_dll.h is generated - fix here.
1699 test -d include || mkdir include
1700 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1701
1702 for cf_math in "" MATH_H
1703 do
1704 for cf_excp in "" MATH_EXCEPTION
1705 do
1706         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1707         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1708         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1709 AC_TRY_COMPILE([
1710 #include <etip.h.in>
1711 ],[],[
1712         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1713         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1714         cf_result="$cf_math $cf_excp"
1715         break 2
1716 ],[])
1717 done
1718 done
1719 AC_MSG_RESULT($cf_result)
1720 CXXFLAGS="$cf_save_CXXFLAGS"
1721 ])
1722 dnl ---------------------------------------------------------------------------
1723 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
1724 dnl ---------------
1725 dnl Find a library (specifically the linkage used in the code fragment),
1726 dnl searching for it if it is not already in the library path.
1727 dnl See also CF_ADD_SEARCHPATH.
1728 dnl
1729 dnl Parameters (4-on are optional):
1730 dnl     $1 = headers for library entrypoint
1731 dnl     $2 = code fragment for library entrypoint
1732 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1733 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1734 dnl     $5 = action to perform if not successful
1735 dnl     $6 = module name, if not the same as the library name
1736 dnl     $7 = extra libraries
1737 dnl
1738 dnl Sets these variables:
1739 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1740 dnl     $cf_cv_header_path_$3 - include-directory if needed
1741 dnl     $cf_cv_library_path_$3 - library-directory if needed
1742 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1743 AC_DEFUN([CF_FIND_LINKAGE],[
1744
1745 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1746 # will be set on completion of the AC_TRY_LINK below.
1747 cf_cv_header_path_$3=
1748 cf_cv_library_path_$3=
1749
1750 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1751
1752 cf_save_LIBS="$LIBS"
1753
1754 AC_TRY_LINK([$1],[$2],[
1755         cf_cv_find_linkage_$3=yes
1756         cf_cv_header_path_$3=/usr/include
1757         cf_cv_library_path_$3=/usr/lib
1758 ],[
1759
1760 LIBS="-l$3 $7 $cf_save_LIBS"
1761
1762 AC_TRY_LINK([$1],[$2],[
1763         cf_cv_find_linkage_$3=yes
1764         cf_cv_header_path_$3=/usr/include
1765         cf_cv_library_path_$3=/usr/lib
1766         cf_cv_library_file_$3="-l$3"
1767 ],[
1768         cf_cv_find_linkage_$3=no
1769         LIBS="$cf_save_LIBS"
1770
1771         CF_VERBOSE(find linkage for $3 library)
1772         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1773
1774         cf_save_CPPFLAGS="$CPPFLAGS"
1775         cf_test_CPPFLAGS="$CPPFLAGS"
1776
1777         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1778         for cf_cv_header_path_$3 in $cf_search
1779         do
1780                 if test -d $cf_cv_header_path_$3 ; then
1781                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1782                         CPPFLAGS="$cf_save_CPPFLAGS"
1783                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1784                         AC_TRY_COMPILE([$1],[$2],[
1785                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1786                                 cf_cv_find_linkage_$3=maybe
1787                                 cf_test_CPPFLAGS="$CPPFLAGS"
1788                                 break],[
1789                                 CPPFLAGS="$cf_save_CPPFLAGS"
1790                                 ])
1791                 fi
1792         done
1793
1794         if test "$cf_cv_find_linkage_$3" = maybe ; then
1795
1796                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1797
1798                 cf_save_LIBS="$LIBS"
1799                 cf_save_LDFLAGS="$LDFLAGS"
1800
1801                 ifelse([$6],,,[
1802                 CPPFLAGS="$cf_test_CPPFLAGS"
1803                 LIBS="-l$3 $7 $cf_save_LIBS"
1804                 AC_TRY_LINK([$1],[$2],[
1805                         CF_VERBOSE(... found $3 library in system)
1806                         cf_cv_find_linkage_$3=yes])
1807                         CPPFLAGS="$cf_save_CPPFLAGS"
1808                         LIBS="$cf_save_LIBS"
1809                         ])
1810
1811                 if test "$cf_cv_find_linkage_$3" != yes ; then
1812                         CF_LIBRARY_PATH(cf_search,$3)
1813                         for cf_cv_library_path_$3 in $cf_search
1814                         do
1815                                 if test -d $cf_cv_library_path_$3 ; then
1816                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1817                                         CPPFLAGS="$cf_test_CPPFLAGS"
1818                                         LIBS="-l$3 $7 $cf_save_LIBS"
1819                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1820                                         AC_TRY_LINK([$1],[$2],[
1821                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1822                                         cf_cv_find_linkage_$3=yes
1823                                         cf_cv_library_file_$3="-l$3"
1824                                         break],[
1825                                         CPPFLAGS="$cf_save_CPPFLAGS"
1826                                         LIBS="$cf_save_LIBS"
1827                                         LDFLAGS="$cf_save_LDFLAGS"
1828                                         ])
1829                                 fi
1830                         done
1831                         CPPFLAGS="$cf_save_CPPFLAGS"
1832                         LDFLAGS="$cf_save_LDFLAGS"
1833                 fi
1834
1835         else
1836                 cf_cv_find_linkage_$3=no
1837         fi
1838         ],$7)
1839 ])
1840
1841 LIBS="$cf_save_LIBS"
1842
1843 if test "$cf_cv_find_linkage_$3" = yes ; then
1844 ifelse([$4],,[
1845         CF_ADD_INCDIR($cf_cv_header_path_$3)
1846         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1847         CF_ADD_LIB($3)
1848 ],[$4])
1849 else
1850 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1851 fi
1852 ])dnl
1853 dnl ---------------------------------------------------------------------------
1854 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
1855 dnl ------------------
1856 dnl Find an include-directory with the given leaf-name.  This is useful for
1857 dnl example with FreeBSD ports, which use this convention to distinguish
1858 dnl different versions of the same port.
1859 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1860         CF_SUBDIR_PATH(cf_search,$1,include)
1861         for cf_item in $cf_search
1862         do
1863                 case $cf_item in
1864                 (*/$1)
1865                         CF_ADD_INCDIR($cf_item)
1866                         ;;
1867                 esac
1868         done
1869 ])dnl
1870 dnl ---------------------------------------------------------------------------
1871 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
1872 dnl ------------------
1873 dnl Find a library-directory with the given leaf-name.  This is useful for
1874 dnl example with FreeBSD ports, which use this convention to distinguish
1875 dnl different versions of the same port.
1876 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1877         CF_SUBDIR_PATH(cf_search,$1,lib)
1878         for cf_item in $cf_search
1879         do
1880                 case $cf_item in
1881                 (*/$1)
1882                         CF_ADD_LIBDIR($cf_item)
1883                         ;;
1884                 esac
1885         done
1886 ])dnl
1887 dnl ---------------------------------------------------------------------------
1888 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1889 dnl -----------------
1890 dnl make ADAFLAGS consistent with CFLAGS
1891 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1892         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1893         case "$CFLAGS" in
1894         (*-g*)
1895                 CF_ADD_ADAFLAGS(-g)
1896                 ;;
1897         esac
1898         case "$CFLAGS" in
1899         (*-O*)
1900                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1901                 CF_ADD_ADAFLAGS($cf_O_flag)
1902                 ;;
1903         esac
1904         AC_MSG_RESULT($ADAFLAGS)
1905 ])dnl
1906 dnl ---------------------------------------------------------------------------
1907 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1908 dnl --------------
1909 dnl Forget that we saw the given tool.
1910 AC_DEFUN([CF_FORGET_TOOL],[
1911 unset ac_cv_prog_ac_ct_$1
1912 unset ac_ct_$1
1913 unset $1
1914 ])dnl
1915 dnl ---------------------------------------------------------------------------
1916 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
1917 dnl -------------
1918 dnl Test for dlsym() and related functions, as well as libdl.
1919 dnl
1920 dnl Sets
1921 dnl     $cf_have_dlsym
1922 dnl     $cf_have_libdl
1923 AC_DEFUN([CF_FUNC_DLSYM],[
1924 cf_have_dlsym=no
1925 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1926
1927 cf_have_libdl=no
1928 AC_CHECK_LIB(dl,dlsym,[
1929         cf_have_dlsym=yes
1930         cf_have_libdl=yes])])
1931
1932 if test "$cf_have_dlsym" = yes ; then
1933         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
1934
1935         AC_MSG_CHECKING(whether able to link to dl*() functions)
1936         AC_TRY_LINK([#include <dlfcn.h>],[
1937                 void *obj;
1938                 if ((obj = dlopen("filename", 0)) != 0) {
1939                         if (dlsym(obj, "symbolname") == 0) {
1940                         dlclose(obj);
1941                         }
1942                 }],[
1943                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1944                 AC_MSG_ERROR(Cannot link test program for libdl)])
1945         AC_MSG_RESULT(ok)
1946 else
1947         AC_MSG_ERROR(Cannot find dlsym function)
1948 fi
1949 ])
1950 dnl ---------------------------------------------------------------------------
1951 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
1952 dnl ---------------
1953 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1954 dnl is found, add our own version of memmove to the list of objects.
1955 AC_DEFUN([CF_FUNC_MEMMOVE],
1956 [
1957 AC_CHECK_FUNC(memmove,,[
1958 AC_CHECK_FUNC(bcopy,[
1959         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1960                 AC_TRY_RUN([
1961 int main(void) {
1962         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1963         char temp[40];
1964         bcopy(data, temp, sizeof(data));
1965         bcopy(temp+10, temp, 15);
1966         bcopy(temp+5, temp+15, 10);
1967         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1968 }
1969                 ],
1970                 [cf_cv_good_bcopy=yes],
1971                 [cf_cv_good_bcopy=no],
1972                 [cf_cv_good_bcopy=unknown])
1973                 ])
1974         ],[cf_cv_good_bcopy=no])
1975         if test "$cf_cv_good_bcopy" = yes ; then
1976                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1977         else
1978                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1979         fi
1980 ])])dnl
1981 dnl ---------------------------------------------------------------------------
1982 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
1983 dnl -----------------
1984 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1985 dnl AIX 4.x, provide a non-working version.
1986 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1987 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1988 AC_TRY_RUN([
1989 #include <stdio.h>
1990 #include <errno.h>
1991 #include <time.h>
1992
1993 #ifdef HAVE_SYS_TIME_H
1994 #include <sys/time.h>
1995 #endif
1996
1997 int main(void) {
1998         struct timespec ts1, ts2;
1999         int code;
2000         ts1.tv_sec  = 0;
2001         ts1.tv_nsec = 750000000;
2002         ts2.tv_sec  = 0;
2003         ts2.tv_nsec = 0;
2004         errno = 0;
2005         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2006         ${cf_cv_main_return:-return}(code != 0);
2007 }
2008 ],
2009         [cf_cv_func_nanosleep=yes],
2010         [cf_cv_func_nanosleep=no],
2011         [cf_cv_func_nanosleep=unknown])])
2012
2013 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2014 ])
2015 dnl ---------------------------------------------------------------------------
2016 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
2017 dnl ---------------
2018 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2019 dnl "util" library as well.
2020 AC_DEFUN([CF_FUNC_OPENPTY],
2021 [
2022 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2023 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2024         cf_save_LIBS="$LIBS"
2025         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
2026         for cf_header in pty.h libutil.h util.h
2027         do
2028         AC_TRY_LINK([
2029 #include <$cf_header>
2030 ],[
2031         int x = openpty((int *)0, (int *)0, (char *)0,
2032                                    (struct termios *)0, (struct winsize *)0);
2033 ],[
2034                 cf_cv_func_openpty=$cf_header
2035                 break
2036 ],[
2037                 cf_cv_func_openpty=no
2038 ])
2039         done
2040         LIBS="$cf_save_LIBS"
2041 ])
2042 ])dnl
2043 dnl ---------------------------------------------------------------------------
2044 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
2045 dnl ------------
2046 dnl See if the poll function really works.  Some platforms have poll(), but
2047 dnl it does not work for terminals or files.
2048 AC_DEFUN([CF_FUNC_POLL],[
2049 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
2050 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2051 AC_TRY_RUN([
2052 #include <stdlib.h>
2053 #include <stdio.h>
2054 #include <unistd.h>
2055 #include <fcntl.h>
2056 #ifdef HAVE_POLL_H
2057 #include <poll.h>
2058 #else
2059 #include <sys/poll.h>
2060 #endif
2061 int main(void) {
2062         struct pollfd myfds;
2063         int ret;
2064
2065         /* check for Darwin bug with respect to "devices" */
2066         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2067         if (myfds.fd < 0)
2068                 myfds.fd = 0;
2069         myfds.events = POLLIN;
2070         myfds.revents = 0;
2071
2072         ret = poll(&myfds, 1, 100);
2073
2074         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2075                 ret = -1;
2076         } else {
2077                 int fd = 0;
2078                 if (!isatty(fd)) {
2079                         fd = open("/dev/tty", 2);       /* O_RDWR */
2080                 }
2081 #ifdef HAVE_POSIX_OPENPT
2082                 if (fd < 0) {
2083                         fd = posix_openpt(O_RDWR);
2084                 }
2085 #endif
2086
2087                 if (fd >= 0) {
2088                         /* also check with standard input */
2089                         myfds.fd = fd;
2090                         myfds.events = POLLIN;
2091                         myfds.revents = 0;
2092                         ret = poll(&myfds, 1, 100);
2093                 } else {
2094                         ret = -1;
2095                 }
2096         }
2097         ${cf_cv_main_return:-return}(ret < 0);
2098 }],
2099         [cf_cv_working_poll=yes],
2100         [cf_cv_working_poll=no],
2101         [cf_cv_working_poll=unknown])])
2102 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2103 ])dnl
2104 dnl ---------------------------------------------------------------------------
2105 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2106 dnl ---------------
2107 dnl Some old/broken variations define tcgetattr() only as a macro in
2108 dnl termio(s).h
2109 AC_DEFUN([CF_FUNC_TERMIOS],[
2110 AC_REQUIRE([CF_STRUCT_TERMIOS])
2111 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2112 AC_TRY_LINK([
2113 #include <sys/types.h>
2114 #ifdef HAVE_UNISTD_H
2115 #include <unistd.h>
2116 #endif
2117 #ifdef HAVE_TERMIOS_H
2118 #include <termios.h>
2119 #define TTY struct termios
2120 #else
2121 #ifdef HAVE_TERMIO_H
2122 #include <termio.h>
2123 #define TTY struct termio
2124 #endif
2125 #endif
2126 ],[
2127 TTY foo;
2128 tcgetattr(1, &foo);],
2129 [cf_cv_have_tcgetattr=yes],
2130 [cf_cv_have_tcgetattr=no])])
2131 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2132 ])dnl
2133 dnl ---------------------------------------------------------------------------
2134 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2135 dnl ---------------
2136 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2137 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2138 dnl other functions.
2139 AC_DEFUN([CF_FUNC_VSSCANF],
2140 [
2141 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2142 AC_TRY_LINK([
2143 #include <stdarg.h>
2144 #include <stdio.h>],[
2145         va_list ap;
2146         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2147 AC_TRY_LINK([
2148 #include <stdarg.h>
2149 #include <stdio.h>],[
2150         FILE strbuf;
2151         char *str = "from";
2152
2153         strbuf._flag = _IOREAD;
2154         strbuf._ptr = strbuf._base = (unsigned char *) str;
2155         strbuf._cnt = strlen(str);
2156         strbuf._file = _NFILE;
2157         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2158 AC_TRY_LINK([
2159 #include <stdarg.h>
2160 #include <stdio.h>],[
2161         FILE strbuf;
2162         char *str = "from";
2163
2164         strbuf._flag = _IOREAD;
2165         strbuf._ptr = strbuf._base = (unsigned char *) str;
2166         strbuf._cnt = strlen(str);
2167         strbuf._file = _NFILE;
2168         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2169 cf_cv_func_vsscanf=no])])])])
2170
2171 case $cf_cv_func_vsscanf in
2172 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2173 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2174 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2175 esac
2176
2177 ])dnl
2178 dnl ---------------------------------------------------------------------------
2179 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
2180 dnl -----------------
2181 dnl Test for availability of useful gcc __attribute__ directives to quiet
2182 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2183 dnl to documentation, unrecognized directives cause older compilers to barf.
2184 AC_DEFUN([CF_GCC_ATTRIBUTES],
2185 [
2186 if test "$GCC" = yes
2187 then
2188 cat > conftest.i <<EOF
2189 #ifndef GCC_PRINTF
2190 #define GCC_PRINTF 0
2191 #endif
2192 #ifndef GCC_SCANF
2193 #define GCC_SCANF 0
2194 #endif
2195 #ifndef GCC_NORETURN
2196 #define GCC_NORETURN /* nothing */
2197 #endif
2198 #ifndef GCC_UNUSED
2199 #define GCC_UNUSED /* nothing */
2200 #endif
2201 EOF
2202 if test "$GCC" = yes
2203 then
2204         AC_CHECKING([for $CC __attribute__ directives])
2205 cat > conftest.$ac_ext <<EOF
2206 #line __oline__ "${as_me:-configure}"
2207 #include "confdefs.h"
2208 #include "conftest.h"
2209 #include "conftest.i"
2210 #if     GCC_PRINTF
2211 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2212 #else
2213 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2214 #endif
2215 #if     GCC_SCANF
2216 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2217 #else
2218 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2219 #endif
2220 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2221 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2222 extern void foo(void) GCC_NORETURN;
2223 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
2224 EOF
2225         cf_printf_attribute=no
2226         cf_scanf_attribute=no
2227         for cf_attribute in scanf printf unused noreturn
2228         do
2229                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2230                 cf_directive="__attribute__(($cf_attribute))"
2231                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2232
2233                 case $cf_attribute in
2234                 (printf)
2235                         cf_printf_attribute=yes
2236                         cat >conftest.h <<EOF
2237 #define GCC_$cf_ATTRIBUTE 1
2238 EOF
2239                         ;;
2240                 (scanf)
2241                         cf_scanf_attribute=yes
2242                         cat >conftest.h <<EOF
2243 #define GCC_$cf_ATTRIBUTE 1
2244 EOF
2245                         ;;
2246                 (*)
2247                         cat >conftest.h <<EOF
2248 #define GCC_$cf_ATTRIBUTE $cf_directive
2249 EOF
2250                         ;;
2251                 esac
2252
2253                 if AC_TRY_EVAL(ac_compile); then
2254                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2255                         cat conftest.h >>confdefs.h
2256                         case $cf_attribute in
2257                         (noreturn)
2258                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2259                                 ;;
2260                         (printf)
2261                                 cf_value='/* nothing */'
2262                                 if test "$cf_printf_attribute" != no ; then
2263                                         cf_value='__attribute__((format(printf,fmt,var)))'
2264                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2265                                 fi
2266                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2267                                 ;;
2268                         (scanf)
2269                                 cf_value='/* nothing */'
2270                                 if test "$cf_scanf_attribute" != no ; then
2271                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2272                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2273                                 fi
2274                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2275                                 ;;
2276                         (unused)
2277                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2278                                 ;;
2279                         esac
2280                 fi
2281         done
2282 else
2283         fgrep define conftest.i >>confdefs.h
2284 fi
2285 rm -rf conftest*
2286 fi
2287 ])dnl
2288 dnl ---------------------------------------------------------------------------
2289 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2290 dnl --------------
2291 dnl Find version of gcc
2292 AC_DEFUN([CF_GCC_VERSION],[
2293 AC_REQUIRE([AC_PROG_CC])
2294 GCC_VERSION=none
2295 if test "$GCC" = yes ; then
2296         AC_MSG_CHECKING(version of $CC)
2297         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2298         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2299         AC_MSG_RESULT($GCC_VERSION)
2300 fi
2301 ])dnl
2302 dnl ---------------------------------------------------------------------------
2303 dnl CF_GCC_WARNINGS version: 33 updated: 2018/06/20 20:23:13
2304 dnl ---------------
2305 dnl Check if the compiler supports useful warning options.  There's a few that
2306 dnl we don't use, simply because they're too noisy:
2307 dnl
2308 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2309 dnl     -Wredundant-decls (system headers make this too noisy)
2310 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2311 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2312 dnl             is enabled for ncurses using "--enable-const".
2313 dnl     -pedantic
2314 dnl
2315 dnl Parameter:
2316 dnl     $1 is an optional list of gcc warning flags that a particular
2317 dnl             application might want to use, e.g., "no-unused" for
2318 dnl             -Wno-unused
2319 dnl Special:
2320 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2321 dnl
2322 AC_DEFUN([CF_GCC_WARNINGS],
2323 [
2324 AC_REQUIRE([CF_GCC_VERSION])
2325 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2326 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2327
2328 cat > conftest.$ac_ext <<EOF
2329 #line __oline__ "${as_me:-configure}"
2330 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2331 EOF
2332
2333 if test "$INTEL_COMPILER" = yes
2334 then
2335 # The "-wdXXX" options suppress warnings:
2336 # remark #1419: external declaration in primary source file
2337 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2338 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2339 # remark #193: zero used for undefined preprocessing identifier
2340 # remark #593: variable "curs_sb_left_arrow" was set but never used
2341 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2342 # remark #869: parameter "tw" was never referenced
2343 # remark #981: operands are evaluated in unspecified order
2344 # warning #279: controlling expression is constant
2345
2346         AC_CHECKING([for $CC warning options])
2347         cf_save_CFLAGS="$CFLAGS"
2348         EXTRA_CFLAGS="-Wall"
2349         for cf_opt in \
2350                 wd1419 \
2351                 wd1683 \
2352                 wd1684 \
2353                 wd193 \
2354                 wd593 \
2355                 wd279 \
2356                 wd810 \
2357                 wd869 \
2358                 wd981
2359         do
2360                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2361                 if AC_TRY_EVAL(ac_compile); then
2362                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2363                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2364                 fi
2365         done
2366         CFLAGS="$cf_save_CFLAGS"
2367
2368 elif test "$GCC" = yes
2369 then
2370         AC_CHECKING([for $CC warning options])
2371         cf_save_CFLAGS="$CFLAGS"
2372         EXTRA_CFLAGS=
2373         cf_warn_CONST=""
2374         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2375         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2376         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2377         for cf_opt in W Wall \
2378                 Wbad-function-cast \
2379                 Wcast-align \
2380                 Wcast-qual \
2381                 Wdeclaration-after-statement \
2382                 Wextra \
2383                 Winline \
2384                 Wmissing-declarations \
2385                 Wmissing-prototypes \
2386                 Wnested-externs \
2387                 Wpointer-arith \
2388                 Wshadow \
2389                 Wstrict-prototypes \
2390                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2391         do
2392                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2393                 if AC_TRY_EVAL(ac_compile); then
2394                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2395                         case $cf_opt in
2396                         (Wcast-qual)
2397                                 CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
2398                                 ;;
2399                         (Winline)
2400                                 case $GCC_VERSION in
2401                                 ([[34]].*)
2402                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2403                                         continue;;
2404                                 esac
2405                                 ;;
2406                         (Wpointer-arith)
2407                                 case $GCC_VERSION in
2408                                 ([[12]].*)
2409                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2410                                         continue;;
2411                                 esac
2412                                 ;;
2413                         esac
2414                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2415                 fi
2416         done
2417         CFLAGS="$cf_save_CFLAGS"
2418 fi
2419 rm -rf conftest*
2420
2421 AC_SUBST(EXTRA_CFLAGS)
2422 ])dnl
2423 dnl ---------------------------------------------------------------------------
2424 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2425 dnl ----------------
2426 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2427 dnl unistd.h or (nonstandard) in getopt.h
2428 AC_DEFUN([CF_GETOPT_HEADER],
2429 [
2430 AC_HAVE_HEADERS(unistd.h getopt.h)
2431 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2432 cf_cv_getopt_header=none
2433 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2434 do
2435 AC_TRY_COMPILE([
2436 #include <$cf_header>],
2437 [int x = optind; char *y = optarg],
2438 [cf_cv_getopt_header=$cf_header
2439  break])
2440 done
2441 ])
2442 if test $cf_cv_getopt_header != none ; then
2443         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2444 fi
2445 if test $cf_cv_getopt_header = getopt.h ; then
2446         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2447 fi
2448 ])dnl
2449 dnl ---------------------------------------------------------------------------
2450 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2451 dnl -----------------
2452 AC_DEFUN([CF_GNATPREP_OPT_T],[
2453 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2454 cf_cv_gnatprep_opt_t=no
2455 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2456 ])
2457 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2458 AC_SUBST(GNATPREP_OPTS)
2459 ])dnl
2460 dnl ---------------------------------------------------------------------------
2461 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2462 dnl ----------------
2463 AC_DEFUN([CF_GNAT_GENERICS],
2464 [
2465 AC_REQUIRE([CF_GNAT_VERSION])
2466
2467 AC_MSG_CHECKING(if GNAT supports generics)
2468 case $cf_gnat_version in
2469 (3.[[1-9]]*|[[4-9]].*)
2470         cf_gnat_generics=yes
2471         ;;
2472 (*)
2473         cf_gnat_generics=no
2474         ;;
2475 esac
2476 AC_MSG_RESULT($cf_gnat_generics)
2477
2478 if test "$cf_gnat_generics" = yes
2479 then
2480         cf_compile_generics=generics
2481         cf_generic_objects="\${GENOBJS}"
2482 else
2483         cf_compile_generics=
2484         cf_generic_objects=
2485 fi
2486
2487 AC_SUBST(cf_compile_generics)
2488 AC_SUBST(cf_generic_objects)
2489 ])dnl
2490 dnl ---------------------------------------------------------------------------
2491 dnl CF_GNAT_PROJECTS version: 9 updated: 2018/01/14 15:46:09
2492 dnl ----------------
2493 dnl GNAT projects are configured with ".gpr" project files.
2494 dnl GNAT libraries are a further development, using the project feature.
2495 AC_DEFUN([CF_GNAT_PROJECTS],
2496 [
2497 AC_REQUIRE([CF_GNAT_VERSION])
2498 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2499
2500 cf_gnat_libraries=no
2501 cf_gnat_projects=no
2502
2503 if test "$enable_gnat_projects" != no ; then
2504 AC_MSG_CHECKING(if GNAT supports project files)
2505 case $cf_gnat_version in
2506 (3.[[0-9]]*)
2507         ;;
2508 (*)
2509         case $cf_cv_system_name in
2510         (cygwin*|msys*)
2511                 ;;
2512         (*)
2513                 rm -rf conftest* *~conftest*
2514                 if mkdir conftest.src conftest.bin conftest.lib
2515                 then
2516                         cd conftest.src
2517                         rm -rf conftest* *~conftest*
2518                         cat >>library.gpr <<CF_EOF
2519 project Library is
2520   Kind := External ("LIB_KIND");
2521   for Library_Name use "ConfTest";
2522   for Object_Dir use ".";
2523   for Library_ALI_Dir use External("LIBRARY_DIR");
2524   for Library_Version use External ("SONAME");
2525   for Library_Kind use Kind;
2526   for Library_Dir use External("BUILD_DIR");
2527   Source_Dir := External ("SOURCE_DIR");
2528   for Source_Dirs use (Source_Dir);
2529 end Library;
2530 CF_EOF
2531                         cat >>confpackage.ads <<CF_EOF
2532 package ConfPackage is
2533    procedure conftest;
2534 end ConfPackage;
2535 CF_EOF
2536                         cat >>confpackage.adb <<CF_EOF
2537 with Text_IO;
2538 package body ConfPackage is
2539    procedure conftest is
2540    begin
2541       Text_IO.Put ("Hello World");
2542       Text_IO.New_Line;
2543    end conftest;
2544 end ConfPackage;
2545 CF_EOF
2546                         if ( $cf_ada_make $ADAFLAGS \
2547                                         -Plibrary.gpr \
2548                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2549                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2550                                         -XSOURCE_DIR=`pwd` \
2551                                         -XSONAME=libConfTest.so.1 \
2552                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2553                                 cf_gnat_projects=yes
2554                         fi
2555                         cd ..
2556                 fi
2557                 if test -f conftest.lib/confpackage.ali
2558                 then
2559                         cf_gnat_libraries=yes
2560                 fi
2561                 rm -rf conftest* *~conftest*
2562                 ;;
2563         esac
2564         ;;
2565 esac
2566 AC_MSG_RESULT($cf_gnat_projects)
2567 fi # enable_gnat_projects
2568
2569 if test $cf_gnat_projects = yes
2570 then
2571         AC_MSG_CHECKING(if GNAT supports libraries)
2572         AC_MSG_RESULT($cf_gnat_libraries)
2573 fi
2574
2575 if test "$cf_gnat_projects" = yes
2576 then
2577         USE_OLD_MAKERULES="#"
2578         USE_GNAT_PROJECTS=""
2579 else
2580         USE_OLD_MAKERULES=""
2581         USE_GNAT_PROJECTS="#"
2582 fi
2583
2584 if test "$cf_gnat_libraries" = yes
2585 then
2586         USE_GNAT_LIBRARIES=""
2587 else
2588         USE_GNAT_LIBRARIES="#"
2589 fi
2590
2591 AC_SUBST(USE_OLD_MAKERULES)
2592 AC_SUBST(USE_GNAT_PROJECTS)
2593 AC_SUBST(USE_GNAT_LIBRARIES)
2594 ])dnl
2595 dnl ---------------------------------------------------------------------------
2596 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2597 dnl --------------
2598 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2599 dnl is noted that gnat may compile a tasking unit even for configurations which
2600 dnl fail at runtime.
2601 AC_DEFUN([CF_GNAT_SIGINT],[
2602 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2603 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2604
2605 package ConfTest is
2606
2607    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2608    pragma Unreserve_All_Interrupts;
2609    pragma Warnings (On);
2610
2611    protected Process is
2612       procedure Stop;
2613       function Continue return Boolean;
2614       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2615    private
2616       Done : Boolean := False;
2617    end Process;
2618
2619 end ConfTest;],
2620 [package body ConfTest is
2621    protected body Process is
2622       procedure Stop is
2623       begin
2624          Done := True;
2625       end Stop;
2626       function Continue return Boolean is
2627       begin
2628          return not Done;
2629       end Continue;
2630    end Process;
2631 end ConfTest;],
2632         [cf_cv_gnat_sigint=yes],
2633         [cf_cv_gnat_sigint=no])])
2634
2635 if test $cf_cv_gnat_sigint = yes ; then
2636         USE_GNAT_SIGINT=""
2637 else
2638         USE_GNAT_SIGINT="#"
2639 fi
2640 AC_SUBST(USE_GNAT_SIGINT)
2641 ])dnl
2642 dnl ---------------------------------------------------------------------------
2643 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2644 dnl ----------------
2645 dnl Verify that a test program compiles/links with GNAT.
2646 dnl $cf_ada_make is set to the program that compiles/links
2647 dnl $ADAFLAGS may be set to the GNAT flags.
2648 dnl
2649 dnl $1 is the text of the spec
2650 dnl $2 is the text of the body
2651 dnl $3 is the shell command to execute if successful
2652 dnl $4 is the shell command to execute if not successful
2653 AC_DEFUN([CF_GNAT_TRY_LINK],
2654 [
2655 rm -rf conftest* *~conftest*
2656 cat >>conftest.ads <<CF_EOF
2657 $1
2658 CF_EOF
2659 cat >>conftest.adb <<CF_EOF
2660 $2
2661 CF_EOF
2662 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2663 ifelse($3,,      :,[      $3])
2664 ifelse($4,,,[else
2665    $4])
2666 fi
2667 rm -rf conftest* *~conftest*
2668 ])dnl
2669 dnl ---------------------------------------------------------------------------
2670 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2671 dnl ---------------
2672 dnl Verify that a test program compiles and runs with GNAT
2673 dnl $cf_ada_make is set to the program that compiles/links
2674 dnl $ADAFLAGS may be set to the GNAT flags.
2675 dnl
2676 dnl $1 is the text of the spec
2677 dnl $2 is the text of the body
2678 dnl $3 is the shell command to execute if successful
2679 dnl $4 is the shell command to execute if not successful
2680 AC_DEFUN([CF_GNAT_TRY_RUN],
2681 [
2682 rm -rf conftest* *~conftest*
2683 cat >>conftest.ads <<CF_EOF
2684 $1
2685 CF_EOF
2686 cat >>conftest.adb <<CF_EOF
2687 $2
2688 CF_EOF
2689 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2690    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2691 ifelse($3,,      :,[      $3])
2692 ifelse($4,,,[   else
2693       $4])
2694    fi
2695 ifelse($4,,,[else
2696    $4])
2697 fi
2698 rm -rf conftest* *~conftest*
2699 ])dnl
2700 dnl ---------------------------------------------------------------------------
2701 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
2702 dnl ---------------
2703 dnl Verify version of GNAT.
2704 AC_DEFUN([CF_GNAT_VERSION],
2705 [
2706 AC_MSG_CHECKING(for gnat version)
2707 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2708         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2709         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2710 AC_MSG_RESULT($cf_gnat_version)
2711
2712 case $cf_gnat_version in
2713 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
2714         cf_cv_prog_gnat_correct=yes
2715         ;;
2716 (*)
2717         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2718         cf_cv_prog_gnat_correct=no
2719         ;;
2720 esac
2721 ])
2722 dnl ---------------------------------------------------------------------------
2723 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
2724 dnl -------------
2725 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2726 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2727 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2728 dnl since it is interwoven with GNU extensions.
2729 dnl
2730 dnl Well, yes we could work around it...
2731 dnl
2732 dnl Parameters:
2733 dnl     $1 is the nominal value for _XOPEN_SOURCE
2734 AC_DEFUN([CF_GNU_SOURCE],
2735 [
2736 cf_gnu_xopen_source=ifelse($1,,500,$1)
2737
2738 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
2739 AC_TRY_COMPILE([#include <sys/types.h>],[
2740         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
2741                 return 0;
2742         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
2743                 return 0;
2744         #else
2745         #       error not GNU C library
2746         #endif],
2747         [cf_cv_gnu_library=yes],
2748         [cf_cv_gnu_library=no])
2749 ])
2750
2751 if test x$cf_cv_gnu_library = xyes; then
2752
2753         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
2754         # was changed to help a little.  newlib incorporated the change about 4
2755         # years later.
2756         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
2757                 cf_save="$CPPFLAGS"
2758                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2759                 AC_TRY_COMPILE([#include <sys/types.h>],[
2760                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
2761                                 return 0;
2762                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
2763                                 return 0;
2764                         #else
2765                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
2766                         #endif],
2767                         [cf_cv_gnu_library_219=yes],
2768                         [cf_cv_gnu_library_219=no])
2769                 CPPFLAGS="$cf_save"
2770         ])
2771
2772         if test "x$cf_cv_gnu_library_219" = xyes; then
2773                 cf_save="$CPPFLAGS"
2774                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
2775                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
2776                         AC_TRY_COMPILE([
2777                                 #include <limits.h>
2778                                 #include <sys/types.h>
2779                                 ],[
2780                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
2781                                         return 0;
2782                                 #else
2783                                 #       error GNU C library is too old
2784                                 #endif],
2785                                 [cf_cv_gnu_dftsrc_219=yes],
2786                                 [cf_cv_gnu_dftsrc_219=no])
2787                         ])
2788                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
2789         else
2790                 cf_cv_gnu_dftsrc_219=maybe
2791         fi
2792
2793         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
2794
2795                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2796                 AC_TRY_COMPILE([#include <sys/types.h>],[
2797                         #ifndef _XOPEN_SOURCE
2798                         #error  expected _XOPEN_SOURCE to be defined
2799                         #endif],
2800                         [cf_cv_gnu_source=no],
2801                         [cf_save="$CPPFLAGS"
2802                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
2803                          AC_TRY_COMPILE([#include <sys/types.h>],[
2804                                 #ifdef _XOPEN_SOURCE
2805                                 #error  expected _XOPEN_SOURCE to be undefined
2806                                 #endif],
2807                                 [cf_cv_gnu_source=no],
2808                                 [cf_cv_gnu_source=yes])
2809                         CPPFLAGS="$cf_save"
2810                         ])
2811                 ])
2812
2813                 if test "$cf_cv_gnu_source" = yes
2814                 then
2815                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
2816                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
2817                         AC_TRY_COMPILE([#include <sys/types.h>],[
2818                                 #ifdef _DEFAULT_SOURCE
2819                                 #error  expected _DEFAULT_SOURCE to be undefined
2820                                 #endif],
2821                                 [cf_cv_default_source=no],
2822                                 [cf_cv_default_source=yes])
2823                         ])
2824                         if test "$cf_cv_default_source" = yes
2825                         then
2826                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2827                         fi
2828                 fi
2829         fi
2830
2831 fi
2832 ])dnl
2833 dnl ---------------------------------------------------------------------------
2834 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
2835 dnl --------------
2836 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2837 dnl problem :-).  If we have the compiler but no library, we'll be able to
2838 dnl configure, but won't be able to build the c++ demo program.
2839 AC_DEFUN([CF_GPP_LIBRARY],
2840 [
2841 cf_cxx_library=unknown
2842 case $cf_cv_system_name in
2843 (os2*)
2844         cf_gpp_libname=gpp
2845         ;;
2846 (*)
2847         cf_gpp_libname=g++
2848         ;;
2849 esac
2850 if test "$GXX" = yes; then
2851         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2852         cf_save="$LIBS"
2853         CF_ADD_LIB($cf_gpp_libname)
2854         AC_TRY_LINK([
2855 #include <$cf_gpp_libname/builtin.h>
2856         ],
2857         [two_arg_error_handler_t foo2 = lib_error_handler],
2858         [cf_cxx_library=yes
2859          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2860          if test "$cf_gpp_libname" = cpp ; then
2861             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2862          else
2863             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2864          fi],
2865         [AC_TRY_LINK([
2866 #include <builtin.h>
2867         ],
2868         [two_arg_error_handler_t foo2 = lib_error_handler],
2869         [cf_cxx_library=yes
2870          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2871          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2872         [cf_cxx_library=no])])
2873         LIBS="$cf_save"
2874         AC_MSG_RESULT($cf_cxx_library)
2875 fi
2876 ])dnl
2877 dnl ---------------------------------------------------------------------------
2878 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
2879 dnl --------------
2880 dnl Check for version of g++
2881 AC_DEFUN([CF_GXX_VERSION],[
2882 AC_REQUIRE([AC_PROG_CPP])
2883 GXX_VERSION=none
2884 if test "$GXX" = yes; then
2885         AC_MSG_CHECKING(version of ${CXX:-g++})
2886         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2887         if test -z "$GXX_VERSION"
2888         then
2889                 GXX_VERSION=unknown
2890                 GXX=no
2891         fi
2892         AC_MSG_RESULT($GXX_VERSION)
2893 fi
2894 ])dnl
2895 dnl ---------------------------------------------------------------------------
2896 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
2897 dnl ---------------
2898 dnl Check if the compiler supports useful warning options.
2899 dnl
2900 dnl Most of gcc's options apply to g++, except:
2901 dnl     -Wbad-function-cast
2902 dnl     -Wmissing-declarations
2903 dnl     -Wnested-externs
2904 dnl
2905 dnl Omit a few (for now):
2906 dnl     -Winline
2907 dnl
2908 dnl Parameter:
2909 dnl     $1 is an optional list of g++ warning flags that a particular
2910 dnl             application might want to use, e.g., "no-unused" for
2911 dnl             -Wno-unused
2912 dnl Special:
2913 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2914 dnl
2915 AC_DEFUN([CF_GXX_WARNINGS],
2916 [
2917
2918 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2919 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2920
2921 AC_REQUIRE([CF_GXX_VERSION])
2922
2923 AC_LANG_SAVE
2924 AC_LANG_CPLUSPLUS
2925
2926 cat > conftest.$ac_ext <<EOF
2927 #line __oline__ "configure"
2928 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2929 EOF
2930
2931 if test "$INTEL_CPLUSPLUS" = yes
2932 then
2933 # The "-wdXXX" options suppress warnings:
2934 # remark #1419: external declaration in primary source file
2935 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2936 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2937 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2938 # remark #193: zero used for undefined preprocessing identifier
2939 # remark #593: variable "curs_sb_left_arrow" was set but never used
2940 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2941 # remark #869: parameter "tw" was never referenced
2942 # remark #981: operands are evaluated in unspecified order
2943 # warning #269: invalid format string conversion
2944
2945         AC_CHECKING([for $CC warning options])
2946         cf_save_CXXFLAGS="$CXXFLAGS"
2947         EXTRA_CXXFLAGS="-Wall"
2948         for cf_opt in \
2949                 wd1419 \
2950                 wd1682 \
2951                 wd1683 \
2952                 wd1684 \
2953                 wd193 \
2954                 wd279 \
2955                 wd593 \
2956                 wd810 \
2957                 wd869 \
2958                 wd981
2959         do
2960                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2961                 if AC_TRY_EVAL(ac_compile); then
2962                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2963                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2964                 fi
2965         done
2966         CXXFLAGS="$cf_save_CXXFLAGS"
2967
2968 elif test "$GXX" = yes
2969 then
2970         AC_CHECKING([for $CXX warning options])
2971         cf_save_CXXFLAGS="$CXXFLAGS"
2972         EXTRA_CXXFLAGS="-W -Wall"
2973         cf_gxx_extra_warnings=""
2974         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2975         case "$GCC_VERSION" in
2976         ([[1-2]].*)
2977                 ;;
2978         (*)
2979                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2980                 ;;
2981         esac
2982         for cf_opt in \
2983                 Wabi \
2984                 fabi-version=0 \
2985                 Wextra \
2986                 Wignored-qualifiers \
2987                 Wlogical-op \
2988                 Woverloaded-virtual \
2989                 Wsign-promo \
2990                 Wsynth \
2991                 Wold-style-cast \
2992                 Wcast-align \
2993                 Wcast-qual \
2994                 Wpointer-arith \
2995                 Wshadow \
2996                 Wundef $cf_gxx_extra_warnings $1
2997         do
2998                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2999                 if AC_TRY_EVAL(ac_compile); then
3000                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3001                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3002                 else
3003                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
3004                 fi
3005         done
3006         CXXFLAGS="$cf_save_CXXFLAGS"
3007 fi
3008
3009 rm -rf conftest*
3010 AC_LANG_RESTORE
3011 AC_SUBST(EXTRA_CXXFLAGS)
3012 ])dnl
3013 dnl ---------------------------------------------------------------------------
3014 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3015 dnl ------------
3016 dnl Look for an instance of the Berkeley hashed database.
3017 dnl
3018 dnl $1 = optional parameter, to specify install-prefix for the database.
3019 AC_DEFUN([CF_HASHED_DB],
3020 [
3021 ifelse([$1],,,[
3022 case $1 in
3023 (yes|*able*)
3024         ;;
3025 (*)
3026         if test -d "$1" ; then
3027                 CF_ADD_INCDIR($1/include)
3028                 CF_ADD_LIBDIR($1/lib)
3029         else
3030                 case "$1" in
3031                 (./*|../*|/*)
3032                         AC_MSG_WARN(no such directory $1)
3033                         ;;
3034                 (*)
3035                         CF_FIND_SUB_INCDIR($1)
3036                         CF_FIND_SUB_LIBDIR($1)
3037                         ;;
3038                 esac
3039         fi
3040 esac
3041 ])
3042 AC_CHECK_HEADER(db.h,[
3043 CF_HASHED_DB_VERSION
3044 if test "$cf_cv_hashed_db_version" = unknown ; then
3045         AC_MSG_ERROR(Cannot determine version of db)
3046 else
3047         CF_HASHED_DB_LIBS
3048         if test "$cf_cv_hashed_db_libs" = unknown ; then
3049                 AC_MSG_ERROR(Cannot determine library for db)
3050         elif test "$cf_cv_hashed_db_libs" != default ; then
3051                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3052         fi
3053 fi
3054 ],[
3055         AC_MSG_ERROR(Cannot find db.h)
3056 ])
3057 ])dnl
3058 dnl ---------------------------------------------------------------------------
3059 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
3060 dnl -----------------
3061 dnl Given that we have the header and version for hashed database, find the
3062 dnl library information.
3063 AC_DEFUN([CF_HASHED_DB_LIBS],
3064 [
3065 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3066 cf_cv_hashed_db_libs=unknown
3067 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3068 do
3069         cf_save_libs="$LIBS"
3070         if test -n "$cf_db_libs"; then
3071                 CF_ADD_LIB($cf_db_libs)
3072         fi
3073         CF_MSG_LOG(checking for library "$cf_db_libs")
3074         AC_TRY_LINK([
3075 $ac_includes_default
3076 #include <db.h>
3077 ],[
3078         char *path = "/tmp/foo";
3079 #ifdef DB_VERSION_MAJOR
3080 #if DB_VERSION_MAJOR >= 4
3081         DB *result = 0;
3082         db_create(&result, NULL, 0);
3083         result->open(result,
3084                 NULL,
3085                 path,
3086                 path,
3087                 DB_HASH,
3088                 DB_CREATE,
3089                 0644);
3090 #elif DB_VERSION_MAJOR >= 3
3091         DB *result = 0;
3092         db_create(&result, NULL, 0);
3093         result->open(result,
3094                 path,
3095                 path,
3096                 DB_HASH,
3097                 DB_CREATE,
3098                 0644);
3099 #elif DB_VERSION_MAJOR >= 2
3100         DB *result = 0;
3101         db_open(path,
3102                 DB_HASH,
3103                 DB_CREATE,
3104                 0644,
3105                 (DB_ENV *) 0,
3106                 (DB_INFO *) 0,
3107                 &result);
3108 #endif /* DB_VERSION_MAJOR */
3109 #else
3110         DB *result = dbopen(path,
3111                      2,
3112                      0644,
3113                      DB_HASH,
3114                      0);
3115 #endif
3116         ${cf_cv_main_return:-return}(result != 0)
3117 ],[
3118         if test -n "$cf_db_libs" ; then
3119                 cf_cv_hashed_db_libs=$cf_db_libs
3120         else
3121                 cf_cv_hashed_db_libs=default
3122         fi
3123         LIBS="$cf_save_libs"
3124         break
3125 ])
3126         LIBS="$cf_save_libs"
3127 done
3128 ])
3129 ])dnl
3130 dnl ---------------------------------------------------------------------------
3131 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3132 dnl --------------------
3133 dnl Given that we have the header file for hashed database, find the version
3134 dnl information.
3135 AC_DEFUN([CF_HASHED_DB_VERSION],
3136 [
3137 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3138 cf_cv_hashed_db_version=unknown
3139
3140 for cf_db_version in 1 2 3 4 5 6
3141 do
3142         CF_MSG_LOG(checking for db version $cf_db_version)
3143         AC_TRY_COMPILE([
3144 $ac_includes_default
3145 #include <db.h>
3146
3147 #ifdef DB_VERSION_MAJOR
3148         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3149 #if $cf_db_version == DB_VERSION_MAJOR
3150         /* ok */
3151 #else
3152         make an error
3153 #endif
3154 #else
3155 #if $cf_db_version == 1
3156         /* ok: assuming this is DB 1.8.5 */
3157 #else
3158         make an error
3159 #endif
3160 #endif
3161 ],[DBT *foo = 0],[
3162         cf_cv_hashed_db_version=$cf_db_version
3163         break
3164         ])
3165 done
3166 ])
3167 ])dnl
3168 dnl ---------------------------------------------------------------------------
3169 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3170 dnl --------------
3171 dnl Construct a search-list of directories for a nonstandard header-file
3172 dnl
3173 dnl Parameters
3174 dnl     $1 = the variable to return as result
3175 dnl     $2 = the package name
3176 AC_DEFUN([CF_HEADER_PATH],
3177 [
3178 $1=
3179
3180 # collect the current set of include-directories from compiler flags
3181 cf_header_path_list=""
3182 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3183         for cf_header_path in $CPPFLAGS $CFLAGS
3184         do
3185                 case $cf_header_path in
3186                 (-I*)
3187                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3188                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3189                         cf_header_path_list="$cf_header_path_list [$]$1"
3190                         ;;
3191                 esac
3192         done
3193 fi
3194
3195 # add the variations for the package we are looking for
3196 CF_SUBDIR_PATH($1,$2,include)
3197
3198 test "$includedir" != NONE && \
3199 test "$includedir" != "/usr/include" && \
3200 test -d "$includedir" && {
3201         test -d $includedir &&    $1="[$]$1 $includedir"
3202         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3203 }
3204
3205 test "$oldincludedir" != NONE && \
3206 test "$oldincludedir" != "/usr/include" && \
3207 test -d "$oldincludedir" && {
3208         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3209         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3210 }
3211
3212 $1="[$]$1 $cf_header_path_list"
3213 ])dnl
3214 dnl ---------------------------------------------------------------------------
3215 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
3216 dnl ---------------
3217 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3218 AC_DEFUN([CF_HELP_MESSAGE],
3219 [AC_DIVERT_HELP([$1])dnl
3220 ])dnl
3221 dnl ---------------------------------------------------------------------------
3222 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3223 dnl ---------------
3224 dnl Construct the list of include-options according to whether we're building
3225 dnl in the source directory or using '--srcdir=DIR' option.
3226 AC_DEFUN([CF_INCLUDE_DIRS],
3227 [
3228 if test "$srcdir" != "."; then
3229         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3230 fi
3231 CPPFLAGS="-I../include $CPPFLAGS"
3232 if test "$srcdir" != "."; then
3233         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3234 fi
3235 CPPFLAGS="-I. $CPPFLAGS"
3236 AC_SUBST(CPPFLAGS)
3237 ])dnl
3238 dnl ---------------------------------------------------------------------------
3239 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
3240 dnl ---------------
3241 dnl prompt for/fill-in useful install-program options
3242 AC_DEFUN([CF_INSTALL_OPTS],
3243 [
3244 CF_INSTALL_OPT_S
3245 CF_INSTALL_OPT_P
3246 CF_INSTALL_OPT_O
3247 ])dnl
3248 dnl ---------------------------------------------------------------------------
3249 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
3250 dnl ----------------
3251 dnl Almost all "install" programs default to the current user's ownership.
3252 dnl Almost - MINIX is an exception.
3253 AC_DEFUN([CF_INSTALL_OPT_O],
3254 [
3255 AC_MSG_CHECKING(if install needs to be told about ownership)
3256 case `$ac_config_guess` in
3257 (*minix)
3258         with_install_o=yes
3259         ;;
3260 (*)
3261         with_install_o=no
3262         ;;
3263 esac
3264
3265 AC_MSG_RESULT($with_install_o)
3266 if test "x$with_install_o" = xyes
3267 then
3268         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
3269 else
3270         INSTALL_OPT_O=
3271 fi
3272
3273 AC_SUBST(INSTALL_OPT_O)
3274 ])dnl
3275 dnl ---------------------------------------------------------------------------
3276 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
3277 dnl ----------------
3278 dnl Some install-programs accept a "-p" option to preserve file modification
3279 dnl timestamps.  That can be useful as an install option, as well as a way to
3280 dnl avoid the need for ranlib after copying a static archive.
3281 AC_DEFUN([CF_INSTALL_OPT_P],
3282 [
3283 : ${INSTALL:=install}
3284 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
3285         rm -rf conftest*
3286         date >conftest.in
3287         mkdir conftest.out
3288         sleep 3
3289         if $INSTALL -p conftest.in conftest.out 2>/dev/null
3290         then
3291                 if test -f conftest.out/conftest.in
3292                 then
3293                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
3294                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
3295                         if test -s conftest.err
3296                         then
3297                                 cf_cv_install_p=no
3298                         else
3299                                 cf_cv_install_p=yes
3300                         fi
3301                 else
3302                         cf_cv_install_p=no
3303                 fi
3304         else
3305                 cf_cv_install_p=no
3306         fi
3307         rm -rf conftest*
3308 ])
3309 ])dnl
3310 dnl ---------------------------------------------------------------------------
3311 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
3312 dnl ----------------
3313 dnl By default, we should strip executables which are installed, but leave the
3314 dnl ability to suppress that for unit-testing.
3315 AC_DEFUN([CF_INSTALL_OPT_S],
3316 [
3317 AC_MSG_CHECKING(if you want to install stripped executables)
3318 CF_ARG_DISABLE(stripping,
3319         [  --disable-stripping     do not strip (debug info) installed executables],
3320         [with_stripping=no],
3321         [with_stripping=yes])
3322 AC_MSG_RESULT($with_stripping)
3323
3324 if test "$with_stripping" = yes
3325 then
3326         INSTALL_OPT_S="-s"
3327 else
3328         INSTALL_OPT_S=
3329 fi
3330 AC_SUBST(INSTALL_OPT_S)
3331 ])dnl
3332 dnl ---------------------------------------------------------------------------
3333 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3334 dnl -----------------
3335 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3336 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3337 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3338 dnl
3339 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3340 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3341 dnl the wrappers for gcc and g++ warnings.
3342 dnl
3343 dnl $1 = GCC (default) or GXX
3344 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3345 dnl $3 = CFLAGS (default) or CXXFLAGS
3346 AC_DEFUN([CF_INTEL_COMPILER],[
3347 AC_REQUIRE([AC_CANONICAL_HOST])
3348 ifelse([$2],,INTEL_COMPILER,[$2])=no
3349
3350 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3351         case $host_os in
3352         (linux*|gnu*)
3353                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3354                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3355                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3356                 AC_TRY_COMPILE([],[
3357 #ifdef __INTEL_COMPILER
3358 #else
3359 make an error
3360 #endif
3361 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3362 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3363 ],[])
3364                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3365                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3366                 ;;
3367         esac
3368 fi
3369 ])dnl
3370 dnl ---------------------------------------------------------------------------
3371 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3372 dnl ----------
3373 dnl Check if we have either a function or macro for 'isascii()'.
3374 AC_DEFUN([CF_ISASCII],
3375 [
3376 AC_MSG_CHECKING(for isascii)
3377 AC_CACHE_VAL(cf_cv_have_isascii,[
3378         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3379         [cf_cv_have_isascii=yes],
3380         [cf_cv_have_isascii=no])
3381 ])dnl
3382 AC_MSG_RESULT($cf_cv_have_isascii)
3383 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3384 ])dnl
3385 dnl ---------------------------------------------------------------------------
3386 dnl CF_LARGEFILE version: 11 updated: 2018/06/20 20:23:13
3387 dnl ------------
3388 dnl Add checks for large file support.
3389 AC_DEFUN([CF_LARGEFILE],[
3390 ifdef([AC_FUNC_FSEEKO],[
3391         AC_SYS_LARGEFILE
3392         if test "$enable_largefile" != no ; then
3393         AC_FUNC_FSEEKO
3394
3395         # Normally we would collect these definitions in the config.h,
3396         # but (like _XOPEN_SOURCE), some environments rely on having these
3397         # defined before any of the system headers are included.  Another
3398         # case comes up with C++, e.g., on AIX the compiler compiles the
3399         # header files by themselves before looking at the body files it is
3400         # told to compile.  For ncurses, those header files do not include
3401         # the config.h
3402         if test "$ac_cv_sys_large_files" != no
3403         then
3404                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
3405         fi
3406         if test "$ac_cv_sys_largefile_source" != no
3407         then
3408                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
3409         fi
3410         if test "$ac_cv_sys_file_offset_bits" != no
3411         then
3412                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
3413         fi
3414
3415         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3416                 AC_TRY_COMPILE([
3417 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
3418 #include <sys/types.h>
3419 #include <dirent.h>
3420                 ],[
3421                 /* if transitional largefile support is setup, this is true */
3422                 extern struct dirent64 * readdir(DIR *);
3423                 struct dirent64 *x = readdir((DIR *)0);
3424                 struct dirent *y = readdir((DIR *)0);
3425                 int z = x - y;
3426                 ],
3427                 [cf_cv_struct_dirent64=yes],
3428                 [cf_cv_struct_dirent64=no])
3429         ])
3430         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3431         fi
3432 ])
3433 ])
3434 dnl ---------------------------------------------------------------------------
3435 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3436 dnl -----------------
3437 dnl Check for compiler/linker flags used to temporarily force usage of static
3438 dnl libraries.  This depends on the compiler and platform.  Use this to help
3439 dnl ensure that the linker picks up a given library based on its position in
3440 dnl the list of linker options and libraries.
3441 AC_DEFUN([CF_LDFLAGS_STATIC],[
3442
3443 if test "$GCC" = yes ; then
3444         case $cf_cv_system_name in
3445         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3446                 LDFLAGS_STATIC=
3447                 LDFLAGS_SHARED=
3448                 ;;
3449         (*)     # normally, except when broken
3450                 LDFLAGS_STATIC=-static
3451                 LDFLAGS_SHARED=-dynamic
3452                 ;;
3453         esac
3454 else
3455         case $cf_cv_system_name in
3456         (aix[[4-7]]*)   # from ld manpage
3457                 LDFLAGS_STATIC=-bstatic
3458                 LDFLAGS_SHARED=-bdynamic
3459                 ;;
3460         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3461                 # We could also use just "archive" and "shared".
3462                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3463                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3464                 ;;
3465         (irix*)         # from ld manpage IRIX64
3466                 LDFLAGS_STATIC=-Bstatic
3467                 LDFLAGS_SHARED=-Bdynamic
3468                 ;;
3469         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3470                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3471                 LDFLAGS_STATIC=-noso
3472                 LDFLAGS_SHARED=-so_archive
3473                 ;;
3474         (solaris2*)
3475                 LDFLAGS_STATIC=-Bstatic
3476                 LDFLAGS_SHARED=-Bdynamic
3477                 ;;
3478         esac
3479 fi
3480
3481 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3482 then
3483         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3484
3485         rm -f libconftest.a
3486         cat >conftest.$ac_ext <<EOF
3487 #line __oline__ "configure"
3488 #include <stdio.h>
3489 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3490 EOF
3491         if AC_TRY_EVAL(ac_compile) ; then
3492                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3493                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3494         fi
3495         rm -f conftest.*
3496
3497         cf_save_LIBS="$LIBS"
3498
3499         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3500         AC_TRY_LINK([
3501 #line __oline__ "configure"
3502 #include <stdio.h>
3503 int cf_ldflags_static(FILE *fp);
3504 ],[
3505         return cf_ldflags_static(stdin);
3506 ],[
3507         # some linkers simply ignore the -dynamic
3508         case x`file conftest$ac_exeext 2>/dev/null` in
3509         (*static*)
3510                 cf_ldflags_static=no
3511                 ;;
3512         (*)
3513                 cf_ldflags_static=yes
3514                 ;;
3515         esac
3516 ],[cf_ldflags_static=no])
3517
3518         rm -f libconftest.*
3519         LIBS="$cf_save_LIBS"
3520
3521         AC_MSG_RESULT($cf_ldflags_static)
3522
3523         if test $cf_ldflags_static != yes
3524         then
3525                 LDFLAGS_STATIC=
3526                 LDFLAGS_SHARED=
3527         fi
3528 else
3529         LDFLAGS_STATIC=
3530         LDFLAGS_SHARED=
3531 fi
3532
3533 AC_SUBST(LDFLAGS_STATIC)
3534 AC_SUBST(LDFLAGS_SHARED)
3535 ])
3536 dnl ---------------------------------------------------------------------------
3537 dnl CF_LD_RPATH_OPT version: 8 updated: 2018/08/18 16:36:35
3538 dnl ---------------
3539 dnl For the given system and compiler, find the compiler flags to pass to the
3540 dnl loader to use the "rpath" feature.
3541 AC_DEFUN([CF_LD_RPATH_OPT],
3542 [
3543 AC_REQUIRE([CF_CHECK_CACHE])
3544
3545 LD_RPATH_OPT=
3546 if test "x$cf_cv_enable_rpath" != xno
3547 then
3548         AC_MSG_CHECKING(for an rpath option)
3549         case $cf_cv_system_name in
3550         (irix*)
3551                 if test "$GCC" = yes; then
3552                         LD_RPATH_OPT="-Wl,-rpath,"
3553                 else
3554                         LD_RPATH_OPT="-rpath "
3555                 fi
3556                 ;;
3557         (linux*|gnu*|k*bsd*-gnu|freebsd*)
3558                 LD_RPATH_OPT="-Wl,-rpath,"
3559                 ;;
3560         (openbsd[[2-9]].*|mirbsd*)
3561                 LD_RPATH_OPT="-Wl,-rpath,"
3562                 ;;
3563         (dragonfly*)
3564                 LD_RPATH_OPT="-rpath "
3565                 ;;
3566         (netbsd*)
3567                 LD_RPATH_OPT="-Wl,-rpath,"
3568                 ;;
3569         (osf*|mls+*)
3570                 LD_RPATH_OPT="-rpath "
3571                 ;;
3572         (solaris2*)
3573                 LD_RPATH_OPT="-R"
3574                 ;;
3575         (*)
3576                 ;;
3577         esac
3578         AC_MSG_RESULT($LD_RPATH_OPT)
3579
3580         case "x$LD_RPATH_OPT" in
3581         (x-R*)
3582                 AC_MSG_CHECKING(if we need a space after rpath option)
3583                 cf_save_LIBS="$LIBS"
3584                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3585                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3586                 LIBS="$cf_save_LIBS"
3587                 AC_MSG_RESULT($cf_rpath_space)
3588                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3589                 ;;
3590         esac
3591 fi
3592 ])dnl
3593 dnl ---------------------------------------------------------------------------
3594 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3595 dnl ---------------
3596 dnl Construct a search-list of directories for a nonstandard library-file
3597 dnl
3598 dnl Parameters
3599 dnl     $1 = the variable to return as result
3600 dnl     $2 = the package name
3601 AC_DEFUN([CF_LIBRARY_PATH],
3602 [
3603 $1=
3604 cf_library_path_list=""
3605 if test -n "${LDFLAGS}${LIBS}" ; then
3606         for cf_library_path in $LDFLAGS $LIBS
3607         do
3608                 case $cf_library_path in
3609                 (-L*)
3610                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3611                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3612                         cf_library_path_list="$cf_library_path_list [$]$1"
3613                         ;;
3614                 esac
3615         done
3616 fi
3617
3618 CF_SUBDIR_PATH($1,$2,lib)
3619
3620 $1="$cf_library_path_list [$]$1"
3621 ])dnl
3622 dnl ---------------------------------------------------------------------------
3623 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3624 dnl ------------------
3625 AC_DEFUN([CF_LIBTOOL_VERSION],[
3626 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3627 then
3628         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3629 else
3630         cf_cv_libtool_version=
3631 fi
3632 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3633 ])dnl
3634 dnl ---------------------------------------------------------------------------
3635 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
3636 dnl -------------
3637 dnl Compute the library-prefix for the given host system
3638 dnl $1 = variable to set
3639 define([CF_LIB_PREFIX],
3640 [
3641         case $cf_cv_system_name in
3642         (OS/2*|os2*)
3643                 if test "$DFT_LWR_MODEL" = libtool; then
3644                         LIB_PREFIX='lib'
3645                 else
3646                         LIB_PREFIX=''
3647                 fi
3648                 ;;
3649         (*)     LIB_PREFIX='lib'
3650                 ;;
3651         esac
3652 ifelse($1,,,[$1=$LIB_PREFIX])
3653         AC_SUBST(LIB_PREFIX)
3654 ])dnl
3655 dnl ---------------------------------------------------------------------------
3656 dnl CF_LIB_RULES version: 88 updated: 2018/08/18 12:19:21
3657 dnl ------------
3658 dnl Append definitions and rules for the given models to the subdirectory
3659 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3660 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3661 dnl the corresponding makefile to list the models that we'll generate.
3662 dnl
3663 dnl For shared libraries, make a list of symbolic links to construct when
3664 dnl generating each library.  The convention used for Linux is the simplest
3665 dnl one:
3666 dnl     lib<name>.so    ->
3667 dnl     lib<name>.so.<major>    ->
3668 dnl     lib<name>.so.<maj>.<minor>
3669 dnl
3670 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3671 AC_DEFUN([CF_LIB_RULES],
3672 [
3673 cf_prefix=$LIB_PREFIX
3674 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3675
3676 case $cf_cv_shlib_version in
3677 (cygdll|msysdll|mingw)
3678         TINFO_NAME=$TINFO_ARG_SUFFIX
3679         TINFO_SUFFIX=.dll
3680         ;;
3681 esac
3682
3683 if test -n "$TINFO_SUFFIX" ; then
3684         case $TINFO_SUFFIX in
3685         (tw*)
3686                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
3687                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
3688                 ;;
3689         (t*)
3690                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
3691                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
3692                 ;;
3693         (w*)
3694                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
3695                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
3696                 ;;
3697         esac
3698 fi
3699
3700 for cf_dir in $SRC_SUBDIRS
3701 do
3702         if test ! -d $srcdir/$cf_dir ; then
3703                 continue
3704         elif test -f $srcdir/$cf_dir/modules; then
3705
3706                 SHARED_LIB=
3707                 Libs_To_Make=
3708                 cf_awk_program=
3709                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3710                 then
3711                         cf_awk_program="$cf_awk_program\
3712 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
3713 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
3714 "
3715                 fi
3716
3717                 if test "x$WILDCARD_SYMS" = xno
3718                 then
3719                         cf_awk_program="$cf_awk_program\
3720 /[[     ]]_\\*;/ { skip=1; next; }\
3721 "
3722                 fi
3723
3724                 if test "x$cf_awk_program" != "x"
3725                 then
3726                         cat >>$cf_dir/Makefile <<CF_EOF
3727
3728 # Generated by CF_LIB_RULES
3729 resulting.map: $UNALTERED_SYMS
3730         $AWK 'BEGIN { skip = 1; last=""; } \
3731 $cf_awk_program \
3732 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
3733  skip = 0; last = \[$]\[$]0; } \
3734 END { print last; }' < $UNALTERED_SYMS >\[$]@
3735
3736 distclean::
3737         rm -f resulting.map
3738 CF_EOF
3739                 fi
3740
3741                 for cf_item in $cf_LIST_MODELS
3742                 do
3743                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3744                         cf_libname=$cf_dir
3745                         test "$cf_dir" = c++ && cf_libname=ncurses++
3746                         if test $cf_item = shared ; then
3747                                 if test -n "${LIB_SUFFIX}"
3748                                 then
3749                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3750                                 else
3751                                         cf_shared_suffix="$cf_suffix"
3752                                 fi
3753                                 if test "$cf_cv_do_symlinks" = yes ; then
3754                                         cf_version_name=
3755
3756                                         case "$cf_cv_shlib_version" in
3757                                         (rel)
3758                                                 cf_version_name=REL_VERSION
3759                                                 ;;
3760                                         (abi)
3761                                                 cf_version_name=ABI_VERSION
3762                                                 ;;
3763                                         esac
3764
3765                                         if test -n "$cf_version_name"
3766                                         then
3767                                                 case "$cf_cv_system_name" in
3768                                                 (darwin*)
3769                                                         # "w", etc?
3770                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3771                                                         ;;
3772                                                 (*)
3773                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3774                                                         ;;
3775                                                 esac
3776                                         fi
3777                                         if test -n "${USE_LIB_SUFFIX}"
3778                                         then
3779                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3780                                         else
3781                                                 cf_shared_suffix="$cf_suffix"
3782                                         fi
3783                                 fi
3784                                 # cygwin needs import library, and has unique naming convention
3785                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3786                                 # use 'cyg' prefix for shared lib.
3787                                 case $cf_cv_shlib_version in
3788                                 (cygdll)
3789                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3790                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
3791                                         ;;
3792                                 (msysdll)
3793                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3794                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
3795                                         ;;
3796                                 (mingw)
3797                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3798                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
3799                                         ;;
3800                                 (*)
3801                                         cf_add_lib=
3802                                         ;;
3803                                 esac
3804                                 if test -n "$cf_add_lib"
3805                                 then
3806                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3807                                         continue
3808                                 fi
3809                         fi
3810                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3811                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3812                 done
3813
3814                 if test $cf_dir = ncurses ; then
3815                         cf_subsets="$LIB_SUBSETS"
3816                         cf_r_parts="$cf_subsets"
3817                         cf_liblist="$Libs_To_Make"
3818
3819                         while test -n "$cf_r_parts"
3820                         do
3821                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3822                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3823                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3824                                         cf_add_lib=
3825                                         case $cf_l_parts in
3826                                         (*termlib*)
3827                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3828                                                 ;;
3829                                         (*ticlib*)
3830                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3831                                                 ;;
3832                                         (*)
3833                                                 break
3834                                                 ;;
3835                                         esac
3836                                         if test -n "$cf_add_lib"; then
3837                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
3838                                         fi
3839                                 else
3840                                         break
3841                                 fi
3842                         done
3843                 else
3844                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3845                 fi
3846
3847                 if test $cf_dir = c++; then
3848                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3849                                 cf_list=
3850                                 for cf_item in $Libs_To_Make
3851                                 do
3852                                         case $cf_item in
3853                                         (*.a)
3854                                                 ;;
3855                                         (*)
3856                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3857                                                 ;;
3858                                         esac
3859                                         for cf_test in $cf_list
3860                                         do
3861                                                 if test "$cf_test" = "$cf_item"
3862                                                 then
3863                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3864                                                         cf_item=
3865                                                         break
3866                                                 fi
3867                                         done
3868                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3869                                 done
3870                                 Libs_To_Make="$cf_list"
3871                         fi
3872                 fi
3873
3874                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3875                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3876                         $cf_dir/Makefile >$cf_dir/Makefile.out
3877                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3878
3879                 $AWK -f $srcdir/mk-0th.awk \
3880                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3881                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3882
3883                 for cf_subset in $cf_subsets
3884                 do
3885                         cf_subdirs=
3886                         for cf_item in $cf_LIST_MODELS
3887                         do
3888
3889                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3890                         CF_UPPER(cf_ITEM,$cf_item)
3891
3892                         CXX_MODEL=$cf_ITEM
3893                         if test "$CXX_MODEL" = SHARED; then
3894                                 case $cf_cv_shlib_version in
3895                                 (cygdll|msysdll|mingw)
3896                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3897                                         with_shared_cxx=yes
3898                                         ;;
3899                                 (*)
3900                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3901                                         ;;
3902                                 esac
3903                         fi
3904
3905                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3906                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3907
3908                         # Test for case where we build libtinfo with a different name.
3909                         cf_libname=$cf_dir
3910                         if test $cf_dir = ncurses ; then
3911                                 case $cf_subset in
3912                                 (*base*)
3913                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
3914                                         ;;
3915                                 (*termlib*)
3916                                         cf_libname=$TINFO_LIB_SUFFIX
3917                                         ;;
3918                                 (ticlib*)
3919                                         cf_libname=$TICS_LIB_SUFFIX
3920                                         ;;
3921                                 esac
3922                         elif test $cf_dir = c++ ; then
3923                                 cf_libname=ncurses++$USE_LIB_SUFFIX
3924                         else
3925                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
3926                         fi
3927                         if test -n "${USE_ARG_SUFFIX}" ; then
3928                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
3929                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
3930                         fi
3931
3932                         # These dependencies really are for development, not
3933                         # builds, but they are useful in porting, too.
3934                         cf_depend="../include/ncurses_cfg.h"
3935                         if test "$srcdir" = "."; then
3936                                 cf_reldir="."
3937                         else
3938                                 cf_reldir="\${srcdir}"
3939                         fi
3940
3941                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3942                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3943                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3944                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3945                         fi
3946
3947                         cf_dir_suffix=
3948                         old_cf_suffix="$cf_suffix"
3949                         if test "$cf_cv_shlib_version_infix" = yes ; then
3950                         if test -n "$USE_LIB_SUFFIX" ; then
3951                                 case $USE_LIB_SUFFIX in
3952                                 (tw*)
3953                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
3954                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
3955                                         cf_dir_suffix=tw$EXTRA_SUFFIX
3956                                         ;;
3957                                 (t*)
3958                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
3959                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
3960                                         cf_dir_suffix=t$EXTRA_SUFFIX
3961                                         ;;
3962                                 (w*)
3963                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
3964                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
3965                                         cf_dir_suffix=w$EXTRA_SUFFIX
3966                                         ;;
3967                                 (*)
3968                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
3969                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
3970                                         cf_dir_suffix=$EXTRA_SUFFIX
3971                                         ;;
3972                                 esac
3973                         fi
3974                         fi
3975
3976                         $AWK -f $srcdir/mk-1st.awk \
3977                                 name=${cf_libname}${cf_dir_suffix} \
3978                                 traces=$LIB_TRACING \
3979                                 MODEL=$cf_ITEM \
3980                                 CXX_MODEL=$CXX_MODEL \
3981                                 model=$cf_subdir \
3982                                 prefix=$cf_prefix \
3983                                 suffix=$cf_suffix \
3984                                 subset=$cf_subset \
3985                                 driver=$cf_cv_term_driver \
3986                                 SymLink="$LN_S" \
3987                                 TermlibRoot=$TINFO_NAME \
3988                                 TermlibSuffix=$TINFO_SUFFIX \
3989                                 ShlibVer=$cf_cv_shlib_version \
3990                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3991                                 ReLink=${cf_cv_do_relink:-no} \
3992                                 ReRanlib=${cf_cv_do_reranlib:-yes} \
3993                                 DoLinks=$cf_cv_do_symlinks \
3994                                 rmSoLocs=$cf_cv_rm_so_locs \
3995                                 ldconfig="$LDCONFIG" \
3996                                 overwrite=$WITH_OVERWRITE \
3997                                 depend="$cf_depend" \
3998                                 host="$host" \
3999                                 libtool_version="$LIBTOOL_VERSION" \
4000                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4001
4002                         cf_suffix="$old_cf_suffix"
4003
4004                         for cf_subdir2 in $cf_subdirs lib
4005                         do
4006                                 test $cf_subdir = $cf_subdir2 && break
4007                         done
4008                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
4009                         $AWK -f $srcdir/mk-2nd.awk \
4010                                 name=$cf_dir \
4011                                 traces=$LIB_TRACING \
4012                                 MODEL=$cf_ITEM \
4013                                 model=$cf_subdir \
4014                                 subset=$cf_subset \
4015                                 srcdir=$srcdir \
4016                                 echo=$WITH_ECHO \
4017                                 crenames=$cf_cv_prog_CC_c_o \
4018                                 cxxrenames=$cf_cv_prog_CXX_c_o \
4019                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4020                         cf_subdirs="$cf_subdirs $cf_subdir"
4021                         done
4022                 done
4023         fi
4024
4025         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
4026 done
4027
4028 for cf_dir in $SRC_SUBDIRS
4029 do
4030         if test ! -d $srcdir/$cf_dir ; then
4031                 continue
4032         fi
4033
4034         if test -f $cf_dir/Makefile ; then
4035                 case "$cf_dir" in
4036                 (Ada95)
4037                         echo 'libs \' >> Makefile
4038                         echo 'install.libs \' >> Makefile
4039                         echo 'uninstall.libs ::' >> Makefile
4040                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
4041                         ;;
4042                 esac
4043         fi
4044
4045         if test -f $srcdir/$cf_dir/modules; then
4046                 echo >> Makefile
4047                 if test -f $srcdir/$cf_dir/headers; then
4048 cat >> Makefile <<CF_EOF
4049 install.includes \\
4050 uninstall.includes \\
4051 CF_EOF
4052                 fi
4053 if test "$cf_dir" != "c++" ; then
4054 echo 'lint \' >> Makefile
4055 fi
4056 cat >> Makefile <<CF_EOF
4057 libs \\
4058 lintlib \\
4059 install.libs \\
4060 uninstall.libs \\
4061 install.$cf_dir \\
4062 uninstall.$cf_dir ::
4063         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4064 CF_EOF
4065         elif test -f $srcdir/$cf_dir/headers; then
4066 cat >> Makefile <<CF_EOF
4067
4068 libs \\
4069 install.libs \\
4070 uninstall.libs \\
4071 install.includes \\
4072 uninstall.includes ::
4073         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4074 CF_EOF
4075 fi
4076 done
4077
4078 if test "x$cf_with_db_install" = xyes; then
4079 cat >> Makefile <<CF_EOF
4080
4081 install.libs uninstall.libs \\
4082 install.data uninstall.data ::
4083 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4084 CF_EOF
4085 else
4086 cat >> Makefile <<CF_EOF
4087
4088 install.libs uninstall.libs ::
4089         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4090 CF_EOF
4091 fi
4092
4093 if test "x$cf_with_manpages" = xyes; then
4094 cat >> Makefile <<CF_EOF
4095
4096 install.man \\
4097 uninstall.man ::
4098         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
4099 CF_EOF
4100 fi
4101
4102 cat >> Makefile <<CF_EOF
4103
4104 distclean ::
4105         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
4106         rm -f headers.sh headers.sed mk_shared_lib.sh
4107         rm -f edit_man.* man_alias.*
4108         rm -rf \${DIRS_TO_MAKE}
4109 CF_EOF
4110
4111 # Special case: tack's manpage lives in its own directory.
4112 if test "x$cf_with_manpages" = xyes; then
4113 if test "x$cf_with_tack" = "xyes"; then
4114 cat >> Makefile <<CF_EOF
4115
4116 install.man \\
4117 uninstall.man ::
4118         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
4119 CF_EOF
4120 fi
4121 fi
4122
4123 dnl If we're installing into a subdirectory of /usr/include, etc., we should
4124 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
4125 dnl anything, and will make it more standardized.  It's awkward to decide this
4126 dnl at configuration because of quoting, so we'll simply make all headers
4127 dnl installed via a script that can do the right thing.
4128
4129 rm -f headers.sed headers.sh
4130
4131 dnl ( generating this script makes the makefiles a little tidier :-)
4132 echo creating headers.sh
4133 cat >headers.sh <<CF_EOF
4134 #! $SHELL
4135 # This shell script is generated by the 'configure' script.  It is invoked in a
4136 # subdirectory of the build tree.  It generates a sed-script in the parent
4137 # directory that is used to adjust includes for header files that reside in a
4138 # subdirectory of /usr/include, etc.
4139 PRG=""
4140 while test \[$]# != 3
4141 do
4142 PRG="\$PRG \[$]1"; shift
4143 done
4144 DST=\[$]1
4145 REF=\[$]2
4146 SRC=\[$]3
4147 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
4148 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
4149 echo installing \$SRC in \$DST
4150 CF_EOF
4151
4152 if test $WITH_CURSES_H = yes; then
4153         cat >>headers.sh <<CF_EOF
4154 case \$DST in
4155 (/*/include/*)
4156         END=\`basename \$DST\`
4157         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4158         do
4159                 NAME=\`basename \$i\`
4160                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4161         done
4162         ;;
4163 (*)
4164         echo "" >> \$TMPSED
4165         ;;
4166 esac
4167 CF_EOF
4168
4169 else
4170         cat >>headers.sh <<CF_EOF
4171 case \$DST in
4172 (/*/include/*)
4173         END=\`basename \$DST\`
4174         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4175         do
4176                 NAME=\`basename \$i\`
4177                 if test "\$NAME" = "curses.h"
4178                 then
4179                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4180                         NAME=ncurses.h
4181                 fi
4182                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4183         done
4184         ;;
4185 (*)
4186         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4187         ;;
4188 esac
4189 CF_EOF
4190 fi
4191 cat >>headers.sh <<CF_EOF
4192 rm -f \$TMPSRC
4193 sed -f \$TMPSED \$SRC > \$TMPSRC
4194 NAME=\`basename \$SRC\`
4195 CF_EOF
4196 if test $WITH_CURSES_H != yes; then
4197         cat >>headers.sh <<CF_EOF
4198 test "\$NAME" = "curses.h" && NAME=ncurses.h
4199 CF_EOF
4200 fi
4201 cat >>headers.sh <<CF_EOF
4202 # Just in case someone gzip'd manpages, remove the conflicting copy.
4203 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
4204
4205 eval \$PRG \$TMPSRC \$DST/\$NAME
4206 rm -f \$TMPSRC \$TMPSED
4207 CF_EOF
4208
4209 chmod 0755 headers.sh
4210
4211 for cf_dir in $SRC_SUBDIRS
4212 do
4213         if test ! -d $srcdir/$cf_dir ; then
4214                 continue
4215         fi
4216
4217         if test -f $srcdir/$cf_dir/headers; then
4218                 $AWK -f $srcdir/mk-hdr.awk \
4219                         subset="$LIB_SUBSETS" \
4220                         compat="$WITH_CURSES_H" \
4221                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
4222         fi
4223
4224         if test -f $srcdir/$cf_dir/modules; then
4225                 if test "$cf_dir" != "c++" ; then
4226                         cat >>$cf_dir/Makefile <<"CF_EOF"
4227 depend : ${AUTO_SRC}
4228         makedepend -- ${CPPFLAGS} -- ${C_SRC}
4229
4230 # DO NOT DELETE THIS LINE -- make depend depends on it.
4231 CF_EOF
4232                 fi
4233         fi
4234 done
4235 AC_SUBST(Libs_To_Make)
4236 ])dnl
4237 dnl ---------------------------------------------------------------------------
4238 dnl CF_LIB_SONAME version: 6 updated: 2017/01/21 11:06:25
4239 dnl -------------
4240 dnl Find the and soname for the given shared library.  Set the cache variable
4241 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
4242 dnl variable to "unknown".
4243 dnl
4244 dnl $1 = headers
4245 dnl $2 = code
4246 dnl $3 = library name
4247 AC_DEFUN([CF_LIB_SONAME],
4248 [
4249 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
4250
4251 cf_cv_$3_soname=unknown
4252 if test "$cross_compiling" != yes ; then
4253 cat >conftest.$ac_ext <<CF_EOF
4254 $1
4255 int main(void)
4256 {
4257 $2
4258         ${cf_cv_main_return:-return}(0);
4259 }
4260 CF_EOF
4261 cf_save_LIBS="$LIBS"
4262         CF_ADD_LIB($3)
4263         if AC_TRY_EVAL(ac_compile) ; then
4264                 if AC_TRY_EVAL(ac_link) ; then
4265                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
4266                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4267                 fi
4268         fi
4269 rm -rf conftest*
4270 LIBS="$cf_save_LIBS"
4271 fi
4272 ])
4273 ])
4274 dnl ---------------------------------------------------------------------------
4275 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
4276 dnl -------------
4277 dnl Compute the library file-suffix from the given model name
4278 dnl $1 = model name
4279 dnl $2 = variable to set (the nominal library suffix)
4280 dnl $3 = dependency variable to set (actual filename)
4281 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4282 AC_DEFUN([CF_LIB_SUFFIX],
4283 [
4284         case X$1 in
4285         (Xlibtool)
4286                 $2='.la'
4287                 $3=[$]$2
4288                 ;;
4289         (Xdebug)
4290                 $2='_g.a'
4291                 $3=[$]$2
4292                 ;;
4293         (Xprofile)
4294                 $2='_p.a'
4295                 $3=[$]$2
4296                 ;;
4297         (Xshared)
4298                 case $cf_cv_system_name in
4299                 (aix[[5-7]]*)
4300                         $2='.so'
4301                         $3=[$]$2
4302                         ;;
4303                 (cygwin*|msys*|mingw*)
4304                         $2='.dll'
4305                         $3='.dll.a'
4306                         ;;
4307                 (darwin*)
4308                         $2='.dylib'
4309                         $3=[$]$2
4310                         ;;
4311                 (hpux*)
4312                         case $target in
4313                         (ia64*)
4314                                 $2='.so'
4315                                 $3