aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2015,2016 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.795 2016/08/30 00:57:00 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54         [AC_TRY_LINK([#include <langinfo.h>],
  55         [char* cs = nl_langinfo(CODESET);],
  56         am_cv_langinfo_codeset=yes,
  57         am_cv_langinfo_codeset=no)
  58         ])
  59         if test $am_cv_langinfo_codeset = yes; then
  60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62         fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  66 dnl ---------------
  67 dnl Provide configure-script defaults for different ncurses ABIs.
  68 AC_DEFUN([CF_ABI_DEFAULTS],[
  69 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  70 case x$cf_cv_abi_version in
  71 (x[[6789]])
  72         cf_dft_ext_colors=yes
  73         cf_dft_ext_const=yes
  74         cf_dft_ext_mouse=yes
  75         cf_dft_ext_putwin=yes
  76         cf_dft_ext_spfuncs=yes
  77         cf_dft_filter_syms=yes
  78         cf_dft_chtype=uint32_t
  79         cf_dft_mmask_t=uint32_t
  80         cf_dft_interop=yes
  81         cf_dft_tparm_arg=intptr_t
  82         cf_dft_with_lp64=yes
  83         ;;
  84 (*)
  85         cf_dft_ext_colors=no
  86         cf_dft_ext_const=no
  87         cf_dft_ext_mouse=no
  88         cf_dft_ext_putwin=no
  89         cf_dft_ext_spfuncs=no
  90         cf_dft_filter_syms=no
  91         cf_dft_chtype=auto
  92         cf_dft_mmask_t=auto
  93         cf_dft_interop=no
  94         cf_dft_tparm_arg=long
  95         cf_dft_with_lp64=no
  96         ;;
  97 esac
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 101 dnl ------------------
 102 dnl Conditionally generate script according to whether we're using a given autoconf.
 103 dnl
 104 dnl $1 = version to compare against
 105 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 106 dnl $3 = code to use if AC_ACVERSION is older than $1.
 107 define([CF_ACVERSION_CHECK],
 108 [
 109 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 110 ifdef([m4_version_compare],
 111 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 112 [CF_ACVERSION_COMPARE(
 113 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 114 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 115 dnl ---------------------------------------------------------------------------
 116 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 117 dnl --------------------
 118 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 119 dnl                      MAJOR2, MINOR2, TERNARY2,
 120 dnl                      PRINTABLE2, not FOUND, FOUND)
 121 define([CF_ACVERSION_COMPARE],
 122 [ifelse(builtin([eval], [$2 < $5]), 1,
 123 [ifelse([$8], , ,[$8])],
 124 [ifelse([$9], , ,[$9])])])dnl
 125 dnl ---------------------------------------------------------------------------
 126 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 127 dnl -------------------
 128 dnl Construct the list of include-options for the C programs in the Ada95
 129 dnl binding.
 130 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 131 [
 132 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 133 if test "$srcdir" != "."; then
 134         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 135 fi
 136 if test "$GCC" != yes; then
 137         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 138 elif test "$includedir" != "/usr/include"; then
 139         if test "$includedir" = '${prefix}/include' ; then
 140                 if test x$prefix != x/usr ; then
 141                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 142                 fi
 143         else
 144                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145         fi
 146 fi
 147 AC_SUBST(ACPPFLAGS)
 148 ])dnl
 149 dnl ---------------------------------------------------------------------------
 150 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 151 dnl ---------------
 152 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 153 AC_DEFUN([CF_ADD_ADAFLAGS],[
 154         ADAFLAGS="$ADAFLAGS $1"
 155         AC_SUBST(ADAFLAGS)
 156 ])dnl
 157 dnl ---------------------------------------------------------------------------
 158 dnl CF_ADD_CFLAGS version: 12 updated: 2015/04/12 15:39:00
 159 dnl -------------
 160 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 161 dnl The second parameter if given makes this macro verbose.
 162 dnl
 163 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 164 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 165 dnl confused by the quotes (which require backslashes to keep them usable).
 166 AC_DEFUN([CF_ADD_CFLAGS],
 167 [
 168 cf_fix_cppflags=no
 169 cf_new_cflags=
 170 cf_new_cppflags=
 171 cf_new_extra_cppflags=
 172
 173 for cf_add_cflags in $1
 174 do
 175 case $cf_fix_cppflags in
 176 (no)
 177         case $cf_add_cflags in
 178         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 179                 case $cf_add_cflags in
 180                 (-D*)
 181                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 182
 183                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 184                                 && test -z "${cf_tst_cflags}" \
 185                                 && cf_fix_cppflags=yes
 186
 187                         if test $cf_fix_cppflags = yes ; then
 188                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 189                                 continue
 190                         elif test "${cf_tst_cflags}" = "\"'" ; then
 191                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 192                                 continue
 193                         fi
 194                         ;;
 195                 esac
 196                 case "$CPPFLAGS" in
 197                 (*$cf_add_cflags)
 198                         ;;
 199                 (*)
 200                         case $cf_add_cflags in
 201                         (-D*)
 202                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 203                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 204                                 ;;
 205                         esac
 206                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 207                         ;;
 208                 esac
 209                 ;;
 210         (*)
 211                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 212                 ;;
 213         esac
 214         ;;
 215 (yes)
 216         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 217
 218         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 219
 220         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 221                 && test -z "${cf_tst_cflags}" \
 222                 && cf_fix_cppflags=no
 223         ;;
 224 esac
 225 done
 226
 227 if test -n "$cf_new_cflags" ; then
 228         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 229         CFLAGS="$CFLAGS $cf_new_cflags"
 230 fi
 231
 232 if test -n "$cf_new_cppflags" ; then
 233         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 234         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 235 fi
 236
 237 if test -n "$cf_new_extra_cppflags" ; then
 238         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 239         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 240 fi
 241
 242 AC_SUBST(EXTRA_CPPFLAGS)
 243
 244 ])dnl
 245 dnl ---------------------------------------------------------------------------
 246 dnl CF_ADD_INCDIR version: 14 updated: 2015/05/25 20:53:04
 247 dnl -------------
 248 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 249 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 250 dnl but old versions (and some misinstalled ones) need that.  To make things
 251 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 252 dnl the include-path).
 253 AC_DEFUN([CF_ADD_INCDIR],
 254 [
 255 if test -n "$1" ; then
 256   for cf_add_incdir in $1
 257   do
 258         while test $cf_add_incdir != /usr/include
 259         do
 260           if test -d $cf_add_incdir
 261           then
 262                 cf_have_incdir=no
 263                 if test -n "$CFLAGS$CPPFLAGS" ; then
 264                   # a loop is needed to ensure we can add subdirs of existing dirs
 265                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 266                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 267                           cf_have_incdir=yes; break
 268                         fi
 269                   done
 270                 fi
 271
 272                 if test "$cf_have_incdir" = no ; then
 273                   if test "$cf_add_incdir" = /usr/local/include ; then
 274                         if test "$GCC" = yes
 275                         then
 276                           cf_save_CPPFLAGS=$CPPFLAGS
 277                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 278                           AC_TRY_COMPILE([#include <stdio.h>],
 279                                   [printf("Hello")],
 280                                   [],
 281                                   [cf_have_incdir=yes])
 282                           CPPFLAGS=$cf_save_CPPFLAGS
 283                         fi
 284                   fi
 285                 fi
 286
 287                 if test "$cf_have_incdir" = no ; then
 288                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 289                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 290
 291                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 292                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 293                   cf_add_incdir="$cf_top_incdir"
 294                 else
 295                   break
 296                 fi
 297           else
 298                 break
 299           fi
 300         done
 301   done
 302 fi
 303 ])dnl
 304 dnl ---------------------------------------------------------------------------
 305 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 306 dnl ----------
 307 dnl Add a library, used to enforce consistency.
 308 dnl
 309 dnl $1 = library to add, without the "-l"
 310 dnl $2 = variable to update (default $LIBS)
 311 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 312 dnl ---------------------------------------------------------------------------
 313 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 314 dnl -------------
 315 dnl     Adds to the library-path
 316 dnl
 317 dnl     Some machines have trouble with multiple -L options.
 318 dnl
 319 dnl $1 is the (list of) directory(s) to add
 320 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 321 dnl
 322 AC_DEFUN([CF_ADD_LIBDIR],
 323 [
 324 if test -n "$1" ; then
 325         for cf_add_libdir in $1
 326         do
 327                 if test $cf_add_libdir = /usr/lib ; then
 328                         :
 329                 elif test -d $cf_add_libdir
 330                 then
 331                         cf_have_libdir=no
 332                         if test -n "$LDFLAGS$LIBS" ; then
 333                                 # a loop is needed to ensure we can add subdirs of existing dirs
 334                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 335                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 336                                                 cf_have_libdir=yes; break
 337                                         fi
 338                                 done
 339                         fi
 340                         if test "$cf_have_libdir" = no ; then
 341                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 342                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 343                         fi
 344                 fi
 345         done
 346 fi
 347 ])dnl
 348 dnl ---------------------------------------------------------------------------
 349 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 350 dnl -----------
 351 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 352 dnl prepended to an existing list, since their dependencies are assumed to
 353 dnl already exist in the list.
 354 dnl
 355 dnl $1 = libraries to add, with the "-l", etc.
 356 dnl $2 = variable to update (default $LIBS)
 357 AC_DEFUN([CF_ADD_LIBS],[
 358 cf_add_libs="$1"
 359 # Filter out duplicates - this happens with badly-designed ".pc" files...
 360 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 361 do
 362         for cf_add_2lib in $cf_add_libs
 363         do
 364                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 365                 then
 366                         cf_add_1lib=
 367                         break
 368                 fi
 369         done
 370         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 371 done
 372 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 373 ])dnl
 374 dnl ---------------------------------------------------------------------------
 375 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 376 dnl ------------------
 377 dnl Append to a search-list for a nonstandard header/lib-file
 378 dnl     $1 = the variable to return as result
 379 dnl     $2 = the package name
 380 dnl     $3 = the subdirectory, e.g., bin, include or lib
 381 dnl $4 = the directory under which we will test for subdirectories
 382 dnl $5 = a directory that we do not want $4 to match
 383 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 384 [
 385 test "x$4" != "x$5" && \
 386 test -d "$4" && \
 387 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 388         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 389         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 390         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 391         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 392         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 393         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 394 }
 395 ])dnl
 396 dnl ---------------------------------------------------------------------------
 397 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 398 dnl --------------
 399 dnl Allow user to disable a normally-on option.
 400 AC_DEFUN([CF_ARG_DISABLE],
 401 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 402 dnl ---------------------------------------------------------------------------
 403 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 404 dnl -------------
 405 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 406 dnl values.
 407 dnl
 408 dnl Parameters:
 409 dnl $1 = option name
 410 dnl $2 = help-string
 411 dnl $3 = action to perform if option is not default
 412 dnl $4 = action if perform if option is default
 413 dnl $5 = default option value (either 'yes' or 'no')
 414 AC_DEFUN([CF_ARG_OPTION],
 415 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 416         if test "$enableval" != "$5" ; then
 417 ifelse([$3],,[    :]dnl
 418 ,[    $3]) ifelse([$4],,,[
 419         else
 420                 $4])
 421         fi],[enableval=$5 ifelse([$4],,,[
 422         $4
 423 ])dnl
 424 ])])dnl
 425 dnl ---------------------------------------------------------------------------
 426 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 427 dnl -----------
 428 dnl Check for suitable "ar" (archiver) options for updating an archive.
 429 dnl
 430 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 431 dnl as well as a workaround for breakage of make's archive rules by the GNU
 432 dnl binutils "ar" program.
 433 AC_DEFUN([CF_AR_FLAGS],[
 434 AC_REQUIRE([CF_PROG_AR])
 435
 436 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 437         cf_cv_ar_flags=unknown
 438         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 439         do
 440
 441                 # check if $ARFLAGS already contains this choice
 442                 if test "x$ARFLAGS" != "x" ; then
 443                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 444                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 445                                 cf_cv_ar_flags=
 446                                 break
 447                         fi
 448                 fi
 449
 450                 rm -f conftest.$ac_cv_objext
 451                 rm -f conftest.a
 452
 453                 cat >conftest.$ac_ext <<EOF
 454 #line __oline__ "configure"
 455 int     testdata[[3]] = { 123, 456, 789 };
 456 EOF
 457                 if AC_TRY_EVAL(ac_compile) ; then
 458                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 459                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 460                         if test -f conftest.a ; then
 461                                 cf_cv_ar_flags=$cf_ar_flags
 462                                 break
 463                         fi
 464                 else
 465                         CF_VERBOSE(cannot compile test-program)
 466                         break
 467                 fi
 468         done
 469         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 470 ])
 471
 472 if test -n "$ARFLAGS" ; then
 473         if test -n "$cf_cv_ar_flags" ; then
 474                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 475         fi
 476 else
 477         ARFLAGS=$cf_cv_ar_flags
 478 fi
 479
 480 AC_SUBST(ARFLAGS)
 481 ])
 482 dnl ---------------------------------------------------------------------------
 483 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 484 dnl -----------------
 485 dnl Check if awk can handle big strings using printf.  Some older versions of
 486 dnl awk choke on large strings passed via "%s".
 487 dnl
 488 dnl $1 = desired string size
 489 dnl $2 = variable to set with result
 490 AC_DEFUN([CF_AWK_BIG_PRINTF],
 491 [
 492         case x$AWK in
 493         (x)
 494                 eval $2=no
 495                 ;;
 496         (*)
 497                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 498                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 499                         eval $2=yes
 500                 else
 501                         eval $2=no
 502                 fi
 503                 ;;
 504         esac
 505 ])dnl
 506 dnl ---------------------------------------------------------------------------
 507 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 508 dnl ------------
 509 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 510 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 511 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 512 dnl
 513 dnl Treat the configuration-variable specially here, since we're directly
 514 dnl substituting its value (i.e., 1/0).
 515 dnl
 516 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 517 AC_DEFUN([CF_BOOL_DECL],
 518 [
 519 AC_MSG_CHECKING(if we should include stdbool.h)
 520
 521 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 522         AC_TRY_COMPILE([],[bool foo = false],
 523                 [cf_cv_header_stdbool_h=0],
 524                 [AC_TRY_COMPILE([
 525 #ifndef __BEOS__
 526 #include <stdbool.h>
 527 #endif
 528 ],[bool foo = false],
 529                         [cf_cv_header_stdbool_h=1],
 530                         [cf_cv_header_stdbool_h=0])])])
 531
 532 if test "$cf_cv_header_stdbool_h" = 1
 533 then    AC_MSG_RESULT(yes)
 534 else    AC_MSG_RESULT(no)
 535 fi
 536
 537 AC_MSG_CHECKING([for builtin bool type])
 538
 539 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 540         AC_TRY_COMPILE([
 541 #include <stdio.h>
 542 #include <sys/types.h>
 543 ],[bool x = false],
 544                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 545                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 546         ])
 547
 548 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 549 then    AC_MSG_RESULT(yes)
 550 else    AC_MSG_RESULT(no)
 551 fi
 552 ])dnl
 553 dnl ---------------------------------------------------------------------------
 554 dnl CF_BOOL_SIZE version: 14 updated: 2015/04/17 21:13:04
 555 dnl ------------
 556 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 557 dnl Don't bother looking for bool.h, since it's been deprecated.
 558 dnl
 559 dnl If the current compiler is C rather than C++, we get the bool definition
 560 dnl from <stdbool.h>.
 561 AC_DEFUN([CF_BOOL_SIZE],
 562 [
 563 AC_MSG_CHECKING([for size of bool])
 564 AC_CACHE_VAL(cf_cv_type_of_bool,[
 565         rm -f cf_test.out
 566         AC_TRY_RUN([
 567 #include <stdlib.h>
 568 #include <stdio.h>
 569
 570 #if defined(__cplusplus)
 571
 572 #ifdef HAVE_GXX_BUILTIN_H
 573 #include <g++/builtin.h>
 574 #elif HAVE_GPP_BUILTIN_H
 575 #include <gpp/builtin.h>
 576 #elif HAVE_BUILTIN_H
 577 #include <builtin.h>
 578 #endif
 579
 580 #else
 581
 582 #if $cf_cv_header_stdbool_h
 583 #include <stdbool.h>
 584 #endif
 585
 586 #endif
 587
 588 int main()
 589 {
 590         FILE *fp = fopen("cf_test.out", "w");
 591         if (fp != 0) {
 592                 bool x = true;
 593                 if ((bool)(-x) >= 0)
 594                         fputs("unsigned ", fp);
 595                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 596                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 597                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 598                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 599                 fclose(fp);
 600         }
 601         ${cf_cv_main_return:-return}(0);
 602 }
 603                 ],
 604                 [cf_cv_type_of_bool=`cat cf_test.out`
 605                  if test -z "$cf_cv_type_of_bool"; then
 606                    cf_cv_type_of_bool=unknown
 607                  fi],
 608                 [cf_cv_type_of_bool=unknown],
 609                 [cf_cv_type_of_bool=unknown])
 610         ])
 611         rm -f cf_test.out
 612 AC_MSG_RESULT($cf_cv_type_of_bool)
 613 if test "$cf_cv_type_of_bool" = unknown ; then
 614         case .$NCURSES_BOOL in
 615         (.auto|.) NCURSES_BOOL=unsigned;;
 616         esac
 617         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 618         cf_cv_type_of_bool=$NCURSES_BOOL
 619 fi
 620 ])dnl
 621 dnl ---------------------------------------------------------------------------
 622 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 623 dnl -----------
 624 dnl If we're cross-compiling, allow the user to override the tools and their
 625 dnl options.  The configure script is oriented toward identifying the host
 626 dnl compiler, etc., but we need a build compiler to generate parts of the
 627 dnl source.
 628 dnl
 629 dnl $1 = default for $CPPFLAGS
 630 dnl $2 = default for $LIBS
 631 AC_DEFUN([CF_BUILD_CC],[
 632 CF_ACVERSION_CHECK(2.52,,
 633         [AC_REQUIRE([CF_PROG_EXT])])
 634 if test "$cross_compiling" = yes ; then
 635
 636         # defaults that we might want to override
 637         : ${BUILD_CFLAGS:=''}
 638         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 639         : ${BUILD_LDFLAGS:=''}
 640         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 641         : ${BUILD_EXEEXT:='$x'}
 642         : ${BUILD_OBJEXT:='o'}
 643
 644         AC_ARG_WITH(build-cc,
 645                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 646                 [BUILD_CC="$withval"],
 647                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 648         AC_MSG_CHECKING(for native build C compiler)
 649         AC_MSG_RESULT($BUILD_CC)
 650
 651         AC_MSG_CHECKING(for native build C preprocessor)
 652         AC_ARG_WITH(build-cpp,
 653                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 654                 [BUILD_CPP="$withval"],
 655                 [BUILD_CPP='${BUILD_CC} -E'])
 656         AC_MSG_RESULT($BUILD_CPP)
 657
 658         AC_MSG_CHECKING(for native build C flags)
 659         AC_ARG_WITH(build-cflags,
 660                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 661                 [BUILD_CFLAGS="$withval"])
 662         AC_MSG_RESULT($BUILD_CFLAGS)
 663
 664         AC_MSG_CHECKING(for native build C preprocessor-flags)
 665         AC_ARG_WITH(build-cppflags,
 666                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 667                 [BUILD_CPPFLAGS="$withval"])
 668         AC_MSG_RESULT($BUILD_CPPFLAGS)
 669
 670         AC_MSG_CHECKING(for native build linker-flags)
 671         AC_ARG_WITH(build-ldflags,
 672                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 673                 [BUILD_LDFLAGS="$withval"])
 674         AC_MSG_RESULT($BUILD_LDFLAGS)
 675
 676         AC_MSG_CHECKING(for native build linker-libraries)
 677         AC_ARG_WITH(build-libs,
 678                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 679                 [BUILD_LIBS="$withval"])
 680         AC_MSG_RESULT($BUILD_LIBS)
 681
 682         # this assumes we're on Unix.
 683         BUILD_EXEEXT=
 684         BUILD_OBJEXT=o
 685
 686         : ${BUILD_CC:='${CC}'}
 687
 688         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 689                 AC_MSG_ERROR([Cross-build requires two compilers.
 690 Use --with-build-cc to specify the native compiler.])
 691         fi
 692
 693 else
 694         : ${BUILD_CC:='${CC}'}
 695         : ${BUILD_CPP:='${CPP}'}
 696         : ${BUILD_CFLAGS:='${CFLAGS}'}
 697         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 698         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 699         : ${BUILD_LIBS:='${LIBS}'}
 700         : ${BUILD_EXEEXT:='$x'}
 701         : ${BUILD_OBJEXT:='o'}
 702 fi
 703
 704 AC_SUBST(BUILD_CC)
 705 AC_SUBST(BUILD_CPP)
 706 AC_SUBST(BUILD_CFLAGS)
 707 AC_SUBST(BUILD_CPPFLAGS)
 708 AC_SUBST(BUILD_LDFLAGS)
 709 AC_SUBST(BUILD_LIBS)
 710 AC_SUBST(BUILD_EXEEXT)
 711 AC_SUBST(BUILD_OBJEXT)
 712 ])dnl
 713 dnl ---------------------------------------------------------------------------
 714 dnl CF_CC_ENV_FLAGS version: 6 updated: 2016/08/29 20:57:00
 715 dnl ---------------
 716 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 717 dnl into CC.  This will not help with broken scripts that wrap the compiler
 718 dnl with options, but eliminates a more common category of user confusion.
 719 dnl
 720 dnl In particular, it addresses the problem of being able to run the C
 721 dnl preprocessor in a consistent manner.
 722 dnl
 723 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 724 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 725 dnl outweighs that limitation.
 726 AC_DEFUN([CF_CC_ENV_FLAGS],
 727 [
 728 # This should have been defined by AC_PROG_CC
 729 : ${CC:=cc}
 730
 731 AC_MSG_CHECKING(\$CC variable)
 732 case "$CC" in
 733 (*[[\ \ ]]-*)
 734         AC_MSG_RESULT(broken)
 735         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 736         # humor him...
 737         cf_flags=`echo "$CC" | sed -e 's/^.*[[  ]]\(-[[^        ]]\)/\1/'`
 738         CC=`echo "$CC " | sed -e 's/[[  ]]-[[^  ]].*$//' -e 's/[[       ]]*$//'`
 739         for cf_arg in $cf_flags
 740         do
 741                 case "x$cf_arg" in
 742                 (x-[[IUDfgOW]]*)
 743                         CF_ADD_CFLAGS($cf_flags)
 744                         ;;
 745                 (*)
 746                         CC="$CC $cf_arg"
 747                         ;;
 748                 esac
 749         done
 750         CF_VERBOSE(resulting CC: '$CC')
 751         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 752         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 753         ;;
 754 (*)
 755         AC_MSG_RESULT(ok)
 756         ;;
 757 esac
 758 ])dnl
 759 dnl ---------------------------------------------------------------------------
 760 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 761 dnl ---------------
 762 dnl Determine the default configuration into which we'll install ncurses.  This
 763 dnl can be overridden by the user's command-line options.  There's two items to
 764 dnl look for:
 765 dnl     1. the prefix (e.g., /usr)
 766 dnl     2. the header files (e.g., /usr/include/ncurses)
 767 dnl We'll look for a previous installation of ncurses and use the same defaults.
 768 dnl
 769 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 770 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 771 dnl programs from a vendor's.
 772 AC_DEFUN([CF_CFG_DEFAULTS],
 773 [
 774 AC_MSG_CHECKING(for prefix)
 775 if test "x$prefix" = "xNONE" ; then
 776         case "$cf_cv_system_name" in
 777                 # non-vendor systems don't have a conflict
 778         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 779                 prefix=/usr
 780                 ;;
 781         (*)     prefix=$ac_default_prefix
 782                 ;;
 783         esac
 784 fi
 785 AC_MSG_RESULT($prefix)
 786
 787 if test "x$prefix" = "xNONE" ; then
 788 AC_MSG_CHECKING(for default include-directory)
 789 test -n "$verbose" && echo 1>&AC_FD_MSG
 790 for cf_symbol in \
 791         $includedir \
 792         $includedir/ncurses \
 793         $prefix/include \
 794         $prefix/include/ncurses \
 795         /usr/local/include \
 796         /usr/local/include/ncurses \
 797         /usr/include \
 798         /usr/include/ncurses
 799 do
 800         cf_dir=`eval echo $cf_symbol`
 801         if test -f $cf_dir/curses.h ; then
 802         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 803                 includedir="$cf_symbol"
 804                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 805                 break
 806         fi
 807         fi
 808         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 809 done
 810 AC_MSG_RESULT($includedir)
 811 fi
 812 ])dnl
 813 dnl ---------------------------------------------------------------------------
 814 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
 815 dnl ----------
 816 dnl Check if the terminal-capability database functions are available.  If not,
 817 dnl ncurses has a much-reduced version.
 818 AC_DEFUN([CF_CGETENT],[
 819 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 820 AC_TRY_LINK([
 821 #include <stdlib.h>],[
 822         char temp[128];
 823         char *buf = temp;
 824         char *db_array = temp;
 825         cgetent(&buf, &db_array, "vt100");
 826         cgetcap(buf, "tc", '=');
 827         cgetmatch(buf, "tc");
 828         ],
 829         [cf_cv_cgetent=yes],
 830         [cf_cv_cgetent=no])
 831 ])
 832
 833 if test "$cf_cv_cgetent" = yes
 834 then
 835         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 836 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 837 AC_TRY_LINK([
 838 #include <stdlib.h>],[
 839         char temp[128];
 840         char *buf = temp;
 841 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 842         const char *db_array = temp;
 843         cgetent(&buf, &db_array, "vt100");
 844 #endif
 845         cgetcap(buf, "tc", '=');
 846         cgetmatch(buf, "tc");
 847         ],
 848         [cf_cv_cgetent_const=yes],
 849         [cf_cv_cgetent_const=no])
 850 ])
 851         if test "$cf_cv_cgetent_const" = yes
 852         then
 853                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 854         fi
 855 fi
 856 ])dnl
 857 dnl ---------------------------------------------------------------------------
 858 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 859 dnl --------------
 860 dnl Check if we're accidentally using a cache from a different machine.
 861 dnl Derive the system name, as a check for reusing the autoconf cache.
 862 dnl
 863 dnl If we've packaged config.guess and config.sub, run that (since it does a
 864 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 865 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 866 dnl which is useful in cross-compiles.
 867 dnl
 868 dnl Note: we would use $ac_config_sub, but that is one of the places where
 869 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 870 AC_DEFUN([CF_CHECK_CACHE],
 871 [
 872 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 873         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 874         system_name="$host_os"
 875 else
 876         system_name="`(uname -s -r) 2>/dev/null`"
 877         if test -z "$system_name" ; then
 878                 system_name="`(hostname) 2>/dev/null`"
 879         fi
 880 fi
 881 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 882 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 883
 884 test -z "$system_name" && system_name="$cf_cv_system_name"
 885 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 886
 887 if test ".$system_name" != ".$cf_cv_system_name" ; then
 888         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 889         AC_MSG_ERROR("Please remove config.cache and try again.")
 890 fi
 891 ])dnl
 892 dnl ---------------------------------------------------------------------------
 893 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
 894 dnl --------------
 895 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 896 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 897 dnl ourselves.
 898 dnl
 899 dnl $1 = the name to check
 900 dnl $2 = the assumed type
 901 AC_DEFUN([CF_CHECK_ERRNO],
 902 [
 903 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 904         AC_TRY_COMPILE([
 905 #ifdef HAVE_STDLIB_H
 906 #include <stdlib.h>
 907 #endif
 908 #include <stdio.h>
 909 #include <sys/types.h>
 910 #include <errno.h> ],
 911         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 912         [cf_cv_dcl_$1=yes],
 913         [cf_cv_dcl_$1=no])
 914 ])
 915
 916 if test "$cf_cv_dcl_$1" = no ; then
 917         CF_UPPER(cf_result,decl_$1)
 918         AC_DEFINE_UNQUOTED($cf_result)
 919 fi
 920
 921 # It's possible (for near-UNIX clones) that the data doesn't exist
 922 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 923 ])dnl
 924 dnl ---------------------------------------------------------------------------
 925 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
 926 dnl --------------------
 927 dnl Check for existence of external data in the current set of libraries.  If
 928 dnl we can modify it, it's real enough.
 929 dnl $1 = the name to check
 930 dnl $2 = its type
 931 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 932 [
 933 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 934         AC_TRY_LINK([
 935 #undef $1
 936 extern $2 $1;
 937 ],
 938         [$1 = 2],
 939         [cf_cv_have_$1=yes],
 940         [cf_cv_have_$1=no])
 941 ])
 942
 943 if test "$cf_cv_have_$1" = yes ; then
 944         CF_UPPER(cf_result,have_$1)
 945         AC_DEFINE_UNQUOTED($cf_result)
 946 fi
 947
 948 ])dnl
 949 dnl ---------------------------------------------------------------------------
 950 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 951 dnl -------------------
 952 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 953 dnl is not "weak" - warn about this because it can create problems linking
 954 dnl applications with ncurses.
 955 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 956 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 957
 958 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 959 cf_cv_check_gpm_wgetch=unknown
 960 if test "$cross_compiling" != yes ; then
 961
 962 cat >conftest.$ac_ext <<CF_EOF
 963 #include <gpm.h>
 964 int main()
 965 {
 966         Gpm_Wgetch();
 967         ${cf_cv_main_return:-return}(0);
 968 }
 969 CF_EOF
 970
 971         cf_save_LIBS="$LIBS"
 972         # This only works if we can look at the symbol table.  If a shared
 973         # library is stripped for install, we cannot use that.  So we're forced
 974         # to rely on the static library, noting that some packagers may not
 975         # include it.
 976         LIBS="-static -lgpm -dynamic $LIBS"
 977         if AC_TRY_EVAL(ac_compile) ; then
 978                 if AC_TRY_EVAL(ac_link) ; then
 979                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 980                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 981                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 982                 fi
 983         fi
 984         rm -rf conftest*
 985         LIBS="$cf_save_LIBS"
 986 fi
 987 ])
 988
 989 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 990         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 991 fi
 992 ])])dnl
 993 dnl ---------------------------------------------------------------------------
 994 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
 995 dnl ------------------------
 996 dnl Show the version of libtool
 997 dnl
 998 dnl Save the version in a cache variable - this is not entirely a good thing,
 999 dnl but the version string from libtool is very ugly, and for bug reports it
1000 dnl might be useful to have the original string.
1001 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1002 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1003 then
1004         AC_MSG_CHECKING(version of $LIBTOOL)
1005         CF_LIBTOOL_VERSION
1006         AC_MSG_RESULT($cf_cv_libtool_version)
1007         if test -z "$cf_cv_libtool_version" ; then
1008                 AC_MSG_ERROR(This is not GNU libtool)
1009         fi
1010 else
1011         AC_MSG_ERROR(GNU libtool has not been found)
1012 fi
1013 ])dnl
1014 dnl ---------------------------------------------------------------------------
1015 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
1016 dnl ----------------
1017 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1018 AC_DEFUN([CF_CHECK_WCHAR_H],[
1019 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1020 AC_TRY_COMPILE(
1021 [
1022 #include <stdlib.h>
1023 #include <wchar.h>
1024 ],[
1025         wint_t foo = 0;
1026         int bar = iswpunct(foo)],
1027         [cf_cv_wchar_h_okay=yes],
1028         [cf_cv_wchar_h_okay=no])])
1029
1030 if test $cf_cv_wchar_h_okay = no
1031 then
1032         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1033 fi
1034 ])dnl
1035 dnl ---------------------------------------------------------------------------
1036 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1037 dnl -------------------------
1038 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1039 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1040 dnl
1041 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1042 dnl all of those were combined into a page of useful graphics characters.
1043 dnl
1044 dnl So far, so good.
1045 dnl
1046 dnl However, while they are useful, there are other considerations.  CJK
1047 dnl is (because of poor device resolution) often rendered as double-width
1048 dnl characters.  So... for these generally-useful characters, what should
1049 dnl be the width (to make them consistent with adjacent characters)?
1050 dnl
1051 dnl The obvious choice would have been to make this locale-dependent, and use
1052 dnl wcwidth() to tell applications what the actual width is.  That was too
1053 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1054 dnl See for example
1055 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1056 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1057 dnl
1058 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1059 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1060 dnl instance, it lists half (44/96) of the Latin-1 characters as
1061 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1062 dnl
1063 dnl What this means for the implementor is that on some systems wcwidth() can
1064 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1065 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1066 dnl characters).  These do not necessarily match the behavior of the terminal
1067 dnl emulator.  xterm, for instance, does an optional startup check to find if
1068 dnl this problem (or similar) exists with the system's locale tables, rejecting
1069 dnl them if they are too unreliable.
1070 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1071 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1072 cat >conftest.in <<CF_EOF
1073 -       VT100 symbols
1074 0x250c  upper left corner
1075 0x2514  lower left corner
1076 0x2510  upper right corner
1077 0x2518  lower right corner
1078 0x251c  tee pointing left
1079 0x2524  tee pointing right
1080 0x2534  tee pointing up
1081 0x252c  tee pointing down
1082 0x2500  horizontal line
1083 0x2502  vertical line
1084 0x253c  large plus or crossover
1085 0x23ba  scan line 1
1086 0x23bd  scan line 9
1087 0x25c6  diamond
1088 0x2592  checker board (stipple)
1089 0x00b0  degree symbol
1090 0x00b1  plus/minus
1091 0x00b7  bullet
1092 -       Teletype 5410v1 symbols
1093 0x2190  arrow pointing left
1094 0x2192  arrow pointing right
1095 0x2193  arrow pointing down
1096 0x2191  arrow pointing up
1097 0x2592  board of squares
1098 0x2603  lantern symbol
1099 0x25ae  solid square block
1100 -       these defaults were invented for ncurses
1101 0x23bb  scan line 3
1102 0x23bc  scan line 7
1103 0x2264  less-than-or-equal-to
1104 0x2265  greater-than-or-equal-to
1105 0x03c0  greek pi
1106 0x2260  not-equal
1107 0x00a3  pound-sterling symbol
1108 -       thick-line-drawing
1109 0x250f  upper left corner
1110 0x2517  lower left corner
1111 0x2513  upper right corner
1112 0x251b  lower right corner
1113 0x2523  tee pointing left
1114 0x252b  tee pointing right
1115 0x253b  tee pointing up
1116 0x2533  tee pointing down
1117 0x2501  horizontal line
1118 0x2503  vertical line
1119 0x254b  large plus or crossover
1120 -       double-line-drawing
1121 0x2554  upper left corner
1122 0x255a  lower left corner
1123 0x2557  upper right corner
1124 0x255d  lower right corner
1125 0x2563  tee pointing left
1126 0x2560  tee pointing right
1127 0x2569  tee pointing up
1128 0x2566  tee pointing down
1129 0x2550  horizontal line
1130 0x2551  vertical line
1131 0x256c  large plus or crossover
1132 CF_EOF
1133 AC_TRY_RUN([
1134 #include <locale.h>
1135 #include <stdio.h>
1136 #include <wchar.h>
1137
1138 #define MY_LEN 80
1139
1140 int
1141 main(void)
1142 {
1143         FILE *fp;
1144         int value;
1145         char buffer[MY_LEN + 1];
1146         char notes[MY_LEN + 1];
1147         int totals = 0;
1148         int passed = 0;
1149
1150         if (setlocale(LC_ALL, "en_US.UTF8") ||
1151                 setlocale(LC_ALL, "en_US.UTF-8") ||
1152                 setlocale(LC_ALL, "en_US.utf8") ||
1153                 setlocale(LC_ALL, "en_US.utf-8")) {
1154                 if ((fp = fopen("conftest.in", "r")) != 0) {
1155                         while (fgets(buffer, MY_LEN, fp) != 0) {
1156                                 if (*buffer == '-') {
1157                                         fprintf(stderr, "\t%s", buffer);
1158                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1159                                         ++totals;
1160                                         if (wcwidth(value) == 1)
1161                                                 ++passed;
1162                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1163                                 } else {
1164                                         fprintf(stderr, "?\t%s", buffer);
1165                                 }
1166                         }
1167                 }
1168         }
1169         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1170         return (totals == passed) ? 0 : 1;
1171 }
1172 ],
1173 [cf_cv_wcwidth_graphics=yes],
1174 [cf_cv_wcwidth_graphics=no],
1175 [cf_cv_wcwidth_graphics=unknown])
1176 ])
1177 ])dnl
1178 dnl ---------------------------------------------------------------------------
1179 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1180 dnl -----------------
1181 dnl Check if the given compiler is really clang.  clang's C driver defines
1182 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1183 dnl not ignore some gcc options.
1184 dnl
1185 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1186 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1187 dnl the wrappers for gcc and g++ warnings.
1188 dnl
1189 dnl $1 = GCC (default) or GXX
1190 dnl $2 = CLANG_COMPILER (default)
1191 dnl $3 = CFLAGS (default) or CXXFLAGS
1192 AC_DEFUN([CF_CLANG_COMPILER],[
1193 ifelse([$2],,CLANG_COMPILER,[$2])=no
1194
1195 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1196         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1197         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1198         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1199         AC_TRY_COMPILE([],[
1200 #ifdef __clang__
1201 #else
1202 make an error
1203 #endif
1204 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1205 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1206 ],[])
1207         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1208         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1209 fi
1210 ])
1211 dnl ---------------------------------------------------------------------------
1212 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
1213 dnl -----------------
1214 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1215 dnl is a late feature for the standard and is not in some recent compilers
1216 dnl (1999/9/11).
1217 AC_DEFUN([CF_CPP_PARAM_INIT],
1218 [
1219 if test -n "$CXX"; then
1220 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1221         AC_LANG_SAVE
1222         AC_LANG_CPLUSPLUS
1223         AC_TRY_RUN([
1224 class TEST {
1225 private:
1226         int value;
1227 public:
1228         TEST(int x = 1);
1229         ~TEST();
1230 };
1231
1232 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1233 {
1234         value = x;
1235 }
1236 int main() { }
1237 ],
1238         [cf_cv_cpp_param_init=yes],
1239         [cf_cv_cpp_param_init=no],
1240         [cf_cv_cpp_param_init=unknown])
1241         AC_LANG_RESTORE
1242 ])
1243 fi
1244 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1245 ])dnl
1246 dnl ---------------------------------------------------------------------------
1247 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1248 dnl ------------------
1249 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1250 dnl not be supported in g++ before 3.0
1251 AC_DEFUN([CF_CPP_STATIC_CAST],
1252 [
1253 if test -n "$CXX"; then
1254
1255 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1256         AC_LANG_SAVE
1257         AC_LANG_CPLUSPLUS
1258
1259         AC_TRY_COMPILE([
1260 class NCursesPanel
1261 {
1262 public:
1263   NCursesPanel(int nlines,
1264                int ncols,
1265                int begin_y = 0,
1266                int begin_x = 0)
1267   {
1268   }
1269   NCursesPanel();
1270   ~NCursesPanel();
1271 };
1272
1273 template<class T> class NCursesUserPanel : public NCursesPanel
1274 {
1275 public:
1276   NCursesUserPanel (int nlines,
1277                     int ncols,
1278                     int begin_y = 0,
1279                     int begin_x = 0,
1280                     const T* p_UserData = static_cast<T*>(0))
1281     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1282   {
1283   };
1284   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1285   {
1286   };
1287
1288   virtual ~NCursesUserPanel() {};
1289 };
1290 ],[
1291         const char* p_UserData = static_cast<char*>(0)],
1292         [cf_cv_cpp_static_cast=yes],
1293         [cf_cv_cpp_static_cast=no])
1294
1295         AC_LANG_RESTORE
1296 ])
1297
1298 fi
1299
1300 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1301 ])dnl
1302 dnl ---------------------------------------------------------------------------
1303 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1304 dnl ---------------
1305 dnl Setup special archiver flags for given compilers.
1306 AC_DEFUN([CF_CXX_AR_FLAGS],[
1307         CXX_AR='$(AR)'
1308         CXX_ARFLAGS='$(ARFLAGS)'
1309         case $cf_cv_system_name in
1310         (irix*)
1311             if test "$GXX" != yes ; then
1312                 CXX_AR='$(CXX)'
1313                 CXX_ARFLAGS='-ar -o'
1314             fi
1315             ;;
1316         (sco3.2v5*)
1317             CXXLDFLAGS="-u main"
1318             ;;
1319         (solaris2*)
1320             if test "$GXX" != yes ; then
1321                 CXX_AR='$(CXX)'
1322                 CXX_ARFLAGS='-xar -o'
1323             fi
1324             ;;
1325         esac
1326         AC_SUBST(CXXLDFLAGS)
1327         AC_SUBST(CXX_AR)
1328         AC_SUBST(CXX_ARFLAGS)
1329 ])dnl
1330 dnl ---------------------------------------------------------------------------
1331 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1332 dnl -------------------------
1333 dnl For c++, check if iostream uses "std::" namespace.
1334 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1335 AC_CHECK_HEADERS(iostream)
1336 if test x"$ac_cv_header_iostream" = xyes ; then
1337         AC_MSG_CHECKING(if iostream uses std-namespace)
1338         AC_TRY_COMPILE([
1339 #include <iostream>
1340 using std::endl;
1341 using std::cerr;],[
1342 cerr << "testing" << endl;
1343 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1344         AC_MSG_RESULT($cf_iostream_namespace)
1345         if test "$cf_iostream_namespace" = yes ; then
1346                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1347         fi
1348 fi
1349 ])dnl
1350 dnl ---------------------------------------------------------------------------
1351 dnl CF_C_INLINE version: 5 updated: 2015/04/18 08:56:57
1352 dnl -----------
1353 dnl Check if the C compiler supports "inline".
1354 dnl $1 is the name of a shell variable to set if inline is supported
1355 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1356 AC_DEFUN([CF_C_INLINE],[
1357 AC_C_INLINE
1358 $1=
1359 if test "$ac_cv_c_inline" != no ; then
1360         $1=inline
1361         if test "$INTEL_COMPILER" = yes
1362         then
1363                 :
1364         elif test "$CLANG_COMPILER" = yes
1365         then
1366                 :
1367         elif test "$GCC" = yes
1368         then
1369                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1370                 cf_save_CFLAGS=$CFLAGS
1371                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1372                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1373                 [${cf_cv_main_return:-return} foo()],
1374                 [cf_cv_gcc_inline=yes],
1375                 [cf_cv_gcc_inline=no])
1376                 CFLAGS=$cf_save_CFLAGS
1377                 ])
1378                 if test "$cf_cv_gcc_inline" = yes ; then
1379                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1380                 fi
1381         fi
1382 fi
1383 AC_SUBST($1)
1384 ])dnl
1385 dnl ---------------------------------------------------------------------------
1386 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1387 dnl ----------
1388 dnl "dirname" is not portable, so we fake it with a shell script.
1389 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1390 dnl ---------------------------------------------------------------------------
1391 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1392 dnl ---------------
1393 AC_DEFUN([CF_DIRS_TO_MAKE],
1394 [
1395 DIRS_TO_MAKE="lib"
1396 for cf_item in $cf_list_models
1397 do
1398         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1399         for cf_item2 in $DIRS_TO_MAKE
1400         do
1401                 test $cf_item2 = $cf_subdir && break
1402         done
1403         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1404 done
1405 for cf_dir in $DIRS_TO_MAKE
1406 do
1407         test ! -d $cf_dir && mkdir $cf_dir
1408 done
1409 AC_SUBST(DIRS_TO_MAKE)
1410 ])dnl
1411 dnl ---------------------------------------------------------------------------
1412 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1413 dnl ---------------
1414 dnl You can always use "make -n" to see the actual options, but it's hard to
1415 dnl pick out/analyze warning messages when the compile-line is long.
1416 dnl
1417 dnl Sets:
1418 dnl     ECHO_LT - symbol to control if libtool is verbose
1419 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1420 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1421 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1422 dnl     ECHO_CC - symbol to put before any "cc" line
1423 dnl
1424 AC_DEFUN([CF_DISABLE_ECHO],[
1425 AC_MSG_CHECKING(if you want to see long compiling messages)
1426 CF_ARG_DISABLE(echo,
1427         [  --disable-echo          do not display "compiling" commands],
1428         [
1429         ECHO_LT='--silent'
1430         ECHO_LD='@echo linking [$]@;'
1431         RULE_CC='@echo compiling [$]<'
1432         SHOW_CC='@echo compiling [$]@'
1433         ECHO_CC='@'
1434 ],[
1435         ECHO_LT=''
1436         ECHO_LD=''
1437         RULE_CC=''
1438         SHOW_CC=''
1439         ECHO_CC=''
1440 ])
1441 AC_MSG_RESULT($enableval)
1442 AC_SUBST(ECHO_LT)
1443 AC_SUBST(ECHO_LD)
1444 AC_SUBST(RULE_CC)
1445 AC_SUBST(SHOW_CC)
1446 AC_SUBST(ECHO_CC)
1447 ])dnl
1448 dnl ---------------------------------------------------------------------------
1449 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1450 dnl ------------------------
1451 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1452 AC_MSG_CHECKING(if we want to use GNAT projects)
1453 CF_ARG_DISABLE(gnat-projects,
1454         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1455         [enable_gnat_projects=no],
1456         [enable_gnat_projects=yes])
1457 AC_MSG_RESULT($enable_gnat_projects)
1458 ])dnl
1459 dnl ---------------------------------------------------------------------------
1460 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1461 dnl ----------------
1462 dnl Combine no-leak checks with the libraries or tools that are used for the
1463 dnl checks.
1464 AC_DEFUN([CF_DISABLE_LEAKS],[
1465
1466 AC_REQUIRE([CF_WITH_DMALLOC])
1467 AC_REQUIRE([CF_WITH_DBMALLOC])
1468 AC_REQUIRE([CF_WITH_VALGRIND])
1469
1470 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1471 AC_ARG_ENABLE(leaks,
1472         [  --disable-leaks         test: free permanent memory, analyze leaks],
1473         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1474         : ${with_no_leaks:=no})
1475 AC_MSG_RESULT($with_no_leaks)
1476
1477 if test "$with_no_leaks" = yes ; then
1478         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1479         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1480 fi
1481 ])dnl
1482 dnl ---------------------------------------------------------------------------
1483 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1484 dnl --------------------------
1485 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1486 dnl the older "-version-info" feature.  The newer feature allows us to use
1487 dnl version numbering on shared libraries which make them compatible with
1488 dnl various systems.
1489 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1490 [
1491 AC_MSG_CHECKING(if libtool -version-number should be used)
1492 CF_ARG_DISABLE(libtool-version,
1493         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1494         [cf_libtool_version=no],
1495         [cf_libtool_version=yes])
1496 AC_MSG_RESULT($cf_libtool_version)
1497
1498 if test "$cf_libtool_version" = yes ; then
1499         LIBTOOL_VERSION="-version-number"
1500 else
1501         LIBTOOL_VERSION="-version-info"
1502         case "x$VERSION" in
1503         (x)
1504                 AC_MSG_WARN(VERSION was not set)
1505                 ;;
1506         (x*.*.*)
1507                 ABI_VERSION="$VERSION"
1508                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1509                 ;;
1510         (x*:*:*)
1511                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1512                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1513                 ;;
1514         (*)
1515                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1516                 ;;
1517         esac
1518 fi
1519
1520 AC_SUBST(ABI_VERSION)
1521 AC_SUBST(LIBTOOL_VERSION)
1522 ])dnl
1523 dnl ---------------------------------------------------------------------------
1524 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1525 dnl ---------------------
1526 dnl The rpath-hack makes it simpler to build programs, particularly with the
1527 dnl *BSD ports which may have essential libraries in unusual places.  But it
1528 dnl can interfere with building an executable for the base system.  Use this
1529 dnl option in that case.
1530 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1531 [
1532 AC_MSG_CHECKING(if rpath-hack should be disabled)
1533 CF_ARG_DISABLE(rpath-hack,
1534         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1535         [cf_disable_rpath_hack=yes],
1536         [cf_disable_rpath_hack=no])
1537 AC_MSG_RESULT($cf_disable_rpath_hack)
1538 if test "$cf_disable_rpath_hack" = no ; then
1539         CF_RPATH_HACK
1540 fi
1541 ])
1542 dnl ---------------------------------------------------------------------------
1543 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1544 dnl ------------------
1545 dnl This is the "--enable-pc-files" option, which is available if there is a
1546 dnl pkg-config configuration on the local machine.
1547 AC_DEFUN([CF_ENABLE_PC_FILES],[
1548 AC_REQUIRE([CF_PKG_CONFIG])
1549 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1550
1551 if test "x$PKG_CONFIG" != xnone
1552 then
1553         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1554 else
1555         AC_MSG_CHECKING(if we should install .pc files)
1556 fi
1557
1558 AC_ARG_ENABLE(pc-files,
1559         [  --enable-pc-files       generate and install .pc files for pkg-config],
1560         [enable_pc_files=$enableval],
1561         [enable_pc_files=no])
1562 AC_MSG_RESULT($enable_pc_files)
1563
1564 if test "x$enable_pc_files" != xno
1565 then
1566         MAKE_PC_FILES=
1567         case "x$PKG_CONFIG_LIBDIR" in
1568         (xno|xyes)
1569                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1570                 ;;
1571         (*)
1572                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1573                 ;;
1574         esac
1575 else
1576         MAKE_PC_FILES="#"
1577 fi
1578 AC_SUBST(MAKE_PC_FILES)
1579 ])dnl
1580 dnl ---------------------------------------------------------------------------
1581 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1582 dnl ---------------
1583 dnl Check if the rpath option should be used, setting cache variable
1584 dnl cf_cv_enable_rpath if so.
1585 AC_DEFUN([CF_ENABLE_RPATH],
1586 [
1587 AC_MSG_CHECKING(if rpath option should be used)
1588 AC_ARG_ENABLE(rpath,
1589 [  --enable-rpath          use rpath option when generating shared libraries],
1590 [cf_cv_enable_rpath=$enableval],
1591 [cf_cv_enable_rpath=no])
1592 AC_MSG_RESULT($cf_cv_enable_rpath)
1593 ])dnl
1594 dnl ---------------------------------------------------------------------------
1595 dnl CF_ENABLE_STRING_HACKS version: 3 updated: 2013/01/26 16:26:12
1596 dnl ----------------------
1597 dnl On a few platforms, the compiler and/or loader nags with untruthful
1598 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1599 dnl and implying that most uses of the recommended alternatives are correct.
1600 dnl
1601 dnl Factually speaking, no one has actually counted the number of uses of these
1602 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1603 dnl instances are meaningless compared to the hundreds of millions of lines of
1604 dnl existing C code.
1605 dnl
1606 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1607 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1608 dnl standard - but evolved through phases, and older implementations are likely
1609 dnl to yield surprising results, as documented in manpages on various systems.
1610 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1611 [
1612 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1613 AC_ARG_ENABLE(string-hacks,
1614         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1615         [with_string_hacks=$enableval],
1616         [with_string_hacks=no])
1617 AC_MSG_RESULT($with_string_hacks)
1618
1619 if test "x$with_string_hacks" = "xyes"; then
1620         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1621         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1622         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1623 fi
1624 ])dnl
1625 dnl ---------------------------------------------------------------------------
1626 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1627 dnl --------
1628 dnl Check if 'errno' is declared in <errno.h>
1629 AC_DEFUN([CF_ERRNO],
1630 [
1631 CF_CHECK_ERRNO(errno)
1632 ])dnl
1633 dnl ---------------------------------------------------------------------------
1634 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1635 dnl ---------------
1636 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1637 dnl math.h and builtin.h, only for ncurses
1638 AC_DEFUN([CF_ETIP_DEFINES],
1639 [
1640 AC_MSG_CHECKING(for special defines needed for etip.h)
1641 cf_save_CXXFLAGS="$CXXFLAGS"
1642 cf_result="none"
1643
1644 # etip.h includes ncurses.h which includes ncurses_dll.h
1645 # But ncurses_dll.h is generated - fix here.
1646 test -d include || mkdir include
1647 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1648
1649 for cf_math in "" MATH_H
1650 do
1651 for cf_excp in "" MATH_EXCEPTION
1652 do
1653         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1654         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1655         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1656 AC_TRY_COMPILE([
1657 #include <etip.h.in>
1658 ],[],[
1659         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1660         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1661         cf_result="$cf_math $cf_excp"
1662         break 2
1663 ],[])
1664 done
1665 done
1666 AC_MSG_RESULT($cf_result)
1667 CXXFLAGS="$cf_save_CXXFLAGS"
1668 ])
1669 dnl ---------------------------------------------------------------------------
1670 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
1671 dnl ---------------
1672 dnl Find a library (specifically the linkage used in the code fragment),
1673 dnl searching for it if it is not already in the library path.
1674 dnl See also CF_ADD_SEARCHPATH.
1675 dnl
1676 dnl Parameters (4-on are optional):
1677 dnl     $1 = headers for library entrypoint
1678 dnl     $2 = code fragment for library entrypoint
1679 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1680 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1681 dnl     $5 = action to perform if not successful
1682 dnl     $6 = module name, if not the same as the library name
1683 dnl     $7 = extra libraries
1684 dnl
1685 dnl Sets these variables:
1686 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1687 dnl     $cf_cv_header_path_$3 - include-directory if needed
1688 dnl     $cf_cv_library_path_$3 - library-directory if needed
1689 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1690 AC_DEFUN([CF_FIND_LINKAGE],[
1691
1692 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1693 # will be set on completion of the AC_TRY_LINK below.
1694 cf_cv_header_path_$3=
1695 cf_cv_library_path_$3=
1696
1697 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1698
1699 cf_save_LIBS="$LIBS"
1700
1701 AC_TRY_LINK([$1],[$2],[
1702         cf_cv_find_linkage_$3=yes
1703         cf_cv_header_path_$3=/usr/include
1704         cf_cv_library_path_$3=/usr/lib
1705 ],[
1706
1707 LIBS="-l$3 $7 $cf_save_LIBS"
1708
1709 AC_TRY_LINK([$1],[$2],[
1710         cf_cv_find_linkage_$3=yes
1711         cf_cv_header_path_$3=/usr/include
1712         cf_cv_library_path_$3=/usr/lib
1713         cf_cv_library_file_$3="-l$3"
1714 ],[
1715         cf_cv_find_linkage_$3=no
1716         LIBS="$cf_save_LIBS"
1717
1718         CF_VERBOSE(find linkage for $3 library)
1719         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1720
1721         cf_save_CPPFLAGS="$CPPFLAGS"
1722         cf_test_CPPFLAGS="$CPPFLAGS"
1723
1724         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1725         for cf_cv_header_path_$3 in $cf_search
1726         do
1727                 if test -d $cf_cv_header_path_$3 ; then
1728                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1729                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1730                         AC_TRY_COMPILE([$1],[$2],[
1731                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1732                                 cf_cv_find_linkage_$3=maybe
1733                                 cf_test_CPPFLAGS="$CPPFLAGS"
1734                                 break],[
1735                                 CPPFLAGS="$cf_save_CPPFLAGS"
1736                                 ])
1737                 fi
1738         done
1739
1740         if test "$cf_cv_find_linkage_$3" = maybe ; then
1741
1742                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1743
1744                 cf_save_LIBS="$LIBS"
1745                 cf_save_LDFLAGS="$LDFLAGS"
1746
1747                 ifelse([$6],,,[
1748                 CPPFLAGS="$cf_test_CPPFLAGS"
1749                 LIBS="-l$3 $7 $cf_save_LIBS"
1750                 AC_TRY_LINK([$1],[$2],[
1751                         CF_VERBOSE(... found $3 library in system)
1752                         cf_cv_find_linkage_$3=yes])
1753                         CPPFLAGS="$cf_save_CPPFLAGS"
1754                         LIBS="$cf_save_LIBS"
1755                         ])
1756
1757                 if test "$cf_cv_find_linkage_$3" != yes ; then
1758                         CF_LIBRARY_PATH(cf_search,$3)
1759                         for cf_cv_library_path_$3 in $cf_search
1760                         do
1761                                 if test -d $cf_cv_library_path_$3 ; then
1762                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1763                                         CPPFLAGS="$cf_test_CPPFLAGS"
1764                                         LIBS="-l$3 $7 $cf_save_LIBS"
1765                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1766                                         AC_TRY_LINK([$1],[$2],[
1767                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1768                                         cf_cv_find_linkage_$3=yes
1769                                         cf_cv_library_file_$3="-l$3"
1770                                         break],[
1771                                         CPPFLAGS="$cf_save_CPPFLAGS"
1772                                         LIBS="$cf_save_LIBS"
1773                                         LDFLAGS="$cf_save_LDFLAGS"
1774                                         ])
1775                                 fi
1776                         done
1777                         CPPFLAGS="$cf_save_CPPFLAGS"
1778                         LDFLAGS="$cf_save_LDFLAGS"
1779                 fi
1780
1781         else
1782                 cf_cv_find_linkage_$3=no
1783         fi
1784         ],$7)
1785 ])
1786
1787 LIBS="$cf_save_LIBS"
1788
1789 if test "$cf_cv_find_linkage_$3" = yes ; then
1790 ifelse([$4],,[
1791         CF_ADD_INCDIR($cf_cv_header_path_$3)
1792         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1793         CF_ADD_LIB($3)
1794 ],[$4])
1795 else
1796 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1797 fi
1798 ])dnl
1799 dnl ---------------------------------------------------------------------------
1800 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
1801 dnl ------------------
1802 dnl Find an include-directory with the given leaf-name.  This is useful for
1803 dnl example with FreeBSD ports, which use this convention to distinguish
1804 dnl different versions of the same port.
1805 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1806         CF_SUBDIR_PATH(cf_search,$1,include)
1807         for cf_item in $cf_search
1808         do
1809                 case $cf_item in
1810                 (*/$1)
1811                         CF_ADD_INCDIR($cf_item)
1812                         ;;
1813                 esac
1814         done
1815 ])dnl
1816 dnl ---------------------------------------------------------------------------
1817 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
1818 dnl ------------------
1819 dnl Find a library-directory with the given leaf-name.  This is useful for
1820 dnl example with FreeBSD ports, which use this convention to distinguish
1821 dnl different versions of the same port.
1822 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1823         CF_SUBDIR_PATH(cf_search,$1,lib)
1824         for cf_item in $cf_search
1825         do
1826                 case $cf_item in
1827                 (*/$1)
1828                         CF_ADD_LIBDIR($cf_item)
1829                         ;;
1830                 esac
1831         done
1832 ])dnl
1833 dnl ---------------------------------------------------------------------------
1834 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1835 dnl -----------------
1836 dnl make ADAFLAGS consistent with CFLAGS
1837 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1838         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1839         case "$CFLAGS" in
1840         (*-g*)
1841                 CF_ADD_ADAFLAGS(-g)
1842                 ;;
1843         esac
1844         case "$CFLAGS" in
1845         (*-O*)
1846                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1847                 CF_ADD_ADAFLAGS($cf_O_flag)
1848                 ;;
1849         esac
1850         AC_MSG_RESULT($ADAFLAGS)
1851 ])dnl
1852 dnl ---------------------------------------------------------------------------
1853 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1854 dnl --------------
1855 dnl Forget that we saw the given tool.
1856 AC_DEFUN([CF_FORGET_TOOL],[
1857 unset ac_cv_prog_ac_ct_$1
1858 unset ac_ct_$1
1859 unset $1
1860 ])dnl
1861 dnl ---------------------------------------------------------------------------
1862 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
1863 dnl -------------
1864 dnl Test for dlsym() and related functions, as well as libdl.
1865 dnl
1866 dnl Sets
1867 dnl     $cf_have_dlsym
1868 dnl     $cf_have_libdl
1869 AC_DEFUN([CF_FUNC_DLSYM],[
1870 cf_have_dlsym=no
1871 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1872
1873 cf_have_libdl=no
1874 AC_CHECK_LIB(dl,dlsym,[
1875         cf_have_dlsym=yes
1876         cf_have_libdl=yes])])
1877
1878 if test "$cf_have_dlsym" = yes ; then
1879         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
1880
1881         AC_MSG_CHECKING(whether able to link to dl*() functions)
1882         AC_TRY_LINK([#include <dlfcn.h>],[
1883                 void *obj;
1884                 if ((obj = dlopen("filename", 0)) != 0) {
1885                         if (dlsym(obj, "symbolname") == 0) {
1886                         dlclose(obj);
1887                         }
1888                 }],[
1889                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1890                 AC_MSG_ERROR(Cannot link test program for libdl)])
1891         AC_MSG_RESULT(ok)
1892 else
1893         AC_MSG_ERROR(Cannot find dlsym function)
1894 fi
1895 ])
1896 dnl ---------------------------------------------------------------------------
1897 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1898 dnl ---------------
1899 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1900 dnl is found, add our own version of memmove to the list of objects.
1901 AC_DEFUN([CF_FUNC_MEMMOVE],
1902 [
1903 AC_CHECK_FUNC(memmove,,[
1904 AC_CHECK_FUNC(bcopy,[
1905         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1906                 AC_TRY_RUN([
1907 int main() {
1908         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1909         char temp[40];
1910         bcopy(data, temp, sizeof(data));
1911         bcopy(temp+10, temp, 15);
1912         bcopy(temp+5, temp+15, 10);
1913         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1914 }
1915                 ],
1916                 [cf_cv_good_bcopy=yes],
1917                 [cf_cv_good_bcopy=no],
1918                 [cf_cv_good_bcopy=unknown])
1919                 ])
1920         ],[cf_cv_good_bcopy=no])
1921         if test "$cf_cv_good_bcopy" = yes ; then
1922                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1923         else
1924                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1925         fi
1926 ])])dnl
1927 dnl ---------------------------------------------------------------------------
1928 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1929 dnl -----------------
1930 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1931 dnl AIX 4.x, provide a non-working version.
1932 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1933 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1934 AC_TRY_RUN([
1935 #include <stdio.h>
1936 #include <errno.h>
1937 #include <time.h>
1938
1939 #ifdef HAVE_SYS_TIME_H
1940 #include <sys/time.h>
1941 #endif
1942
1943 int main() {
1944         struct timespec ts1, ts2;
1945         int code;
1946         ts1.tv_sec  = 0;
1947         ts1.tv_nsec = 750000000;
1948         ts2.tv_sec  = 0;
1949         ts2.tv_nsec = 0;
1950         errno = 0;
1951         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1952         ${cf_cv_main_return:-return}(code != 0);
1953 }
1954 ],
1955         [cf_cv_func_nanosleep=yes],
1956         [cf_cv_func_nanosleep=no],
1957         [cf_cv_func_nanosleep=unknown])])
1958
1959 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1960 ])
1961 dnl ---------------------------------------------------------------------------
1962 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
1963 dnl ---------------
1964 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1965 dnl "util" library as well.
1966 AC_DEFUN([CF_FUNC_OPENPTY],
1967 [
1968 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1969 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1970         cf_save_LIBS="$LIBS"
1971         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
1972         for cf_header in pty.h libutil.h util.h
1973         do
1974         AC_TRY_LINK([
1975 #include <$cf_header>
1976 ],[
1977         int x = openpty((int *)0, (int *)0, (char *)0,
1978                                    (struct termios *)0, (struct winsize *)0);
1979 ],[
1980                 cf_cv_func_openpty=$cf_header
1981                 break
1982 ],[
1983                 cf_cv_func_openpty=no
1984 ])
1985         done
1986         LIBS="$cf_save_LIBS"
1987 ])
1988 ])dnl
1989 dnl ---------------------------------------------------------------------------
1990 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
1991 dnl ------------
1992 dnl See if the poll function really works.  Some platforms have poll(), but
1993 dnl it does not work for terminals or files.
1994 AC_DEFUN([CF_FUNC_POLL],[
1995 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
1996 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1997 AC_TRY_RUN([
1998 #include <stdlib.h>
1999 #include <stdio.h>
2000 #include <unistd.h>
2001 #include <fcntl.h>
2002 #ifdef HAVE_POLL_H
2003 #include <poll.h>
2004 #else
2005 #include <sys/poll.h>
2006 #endif
2007 int main(void) {
2008         struct pollfd myfds;
2009         int ret;
2010
2011         /* check for Darwin bug with respect to "devices" */
2012         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2013         if (myfds.fd < 0)
2014                 myfds.fd = 0;
2015         myfds.events = POLLIN;
2016         myfds.revents = 0;
2017
2018         ret = poll(&myfds, 1, 100);
2019
2020         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2021                 ret = -1;
2022         } else {
2023                 int fd = 0;
2024                 if (!isatty(fd)) {
2025                         fd = open("/dev/tty", 2);       /* O_RDWR */
2026                 }
2027 #ifdef HAVE_POSIX_OPENPT
2028                 if (fd < 0) {
2029                         fd = posix_openpt(O_RDWR);
2030                 }
2031 #endif
2032
2033                 if (fd >= 0) {
2034                         /* also check with standard input */
2035                         myfds.fd = fd;
2036                         myfds.events = POLLIN;
2037                         myfds.revents = 0;
2038                         ret = poll(&myfds, 1, 100);
2039                 } else {
2040                         ret = -1;
2041                 }
2042         }
2043         ${cf_cv_main_return:-return}(ret < 0);
2044 }],
2045         [cf_cv_working_poll=yes],
2046         [cf_cv_working_poll=no],
2047         [cf_cv_working_poll=unknown])])
2048 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2049 ])dnl
2050 dnl ---------------------------------------------------------------------------
2051 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2052 dnl ---------------
2053 dnl Some old/broken variations define tcgetattr() only as a macro in
2054 dnl termio(s).h
2055 AC_DEFUN([CF_FUNC_TERMIOS],[
2056 AC_REQUIRE([CF_STRUCT_TERMIOS])
2057 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2058 AC_TRY_LINK([
2059 #include <sys/types.h>
2060 #ifdef HAVE_UNISTD_H
2061 #include <unistd.h>
2062 #endif
2063 #ifdef HAVE_TERMIOS_H
2064 #include <termios.h>
2065 #define TTY struct termios
2066 #else
2067 #ifdef HAVE_TERMIO_H
2068 #include <termio.h>
2069 #define TTY struct termio
2070 #endif
2071 #endif
2072 ],[
2073 TTY foo;
2074 tcgetattr(1, &foo);],
2075 [cf_cv_have_tcgetattr=yes],
2076 [cf_cv_have_tcgetattr=no])])
2077 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2078 ])dnl
2079 dnl ---------------------------------------------------------------------------
2080 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2081 dnl ---------------
2082 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2083 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2084 dnl other functions.
2085 AC_DEFUN([CF_FUNC_VSSCANF],
2086 [
2087 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2088 AC_TRY_LINK([
2089 #include <stdarg.h>
2090 #include <stdio.h>],[
2091         va_list ap;
2092         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2093 AC_TRY_LINK([
2094 #include <stdarg.h>
2095 #include <stdio.h>],[
2096         FILE strbuf;
2097         char *str = "from";
2098
2099         strbuf._flag = _IOREAD;
2100         strbuf._ptr = strbuf._base = (unsigned char *) str;
2101         strbuf._cnt = strlen(str);
2102         strbuf._file = _NFILE;
2103         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2104 AC_TRY_LINK([
2105 #include <stdarg.h>
2106 #include <stdio.h>],[
2107         FILE strbuf;
2108         char *str = "from";
2109
2110         strbuf._flag = _IOREAD;
2111         strbuf._ptr = strbuf._base = (unsigned char *) str;
2112         strbuf._cnt = strlen(str);
2113         strbuf._file = _NFILE;
2114         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2115 cf_cv_func_vsscanf=no])])])])
2116
2117 case $cf_cv_func_vsscanf in
2118 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2119 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2120 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2121 esac
2122
2123 ])dnl
2124 dnl ---------------------------------------------------------------------------
2125 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
2126 dnl -----------------
2127 dnl Test for availability of useful gcc __attribute__ directives to quiet
2128 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2129 dnl to documentation, unrecognized directives cause older compilers to barf.
2130 AC_DEFUN([CF_GCC_ATTRIBUTES],
2131 [
2132 if test "$GCC" = yes
2133 then
2134 cat > conftest.i <<EOF
2135 #ifndef GCC_PRINTF
2136 #define GCC_PRINTF 0
2137 #endif
2138 #ifndef GCC_SCANF
2139 #define GCC_SCANF 0
2140 #endif
2141 #ifndef GCC_NORETURN
2142 #define GCC_NORETURN /* nothing */
2143 #endif
2144 #ifndef GCC_UNUSED
2145 #define GCC_UNUSED /* nothing */
2146 #endif
2147 EOF
2148 if test "$GCC" = yes
2149 then
2150         AC_CHECKING([for $CC __attribute__ directives])
2151 cat > conftest.$ac_ext <<EOF
2152 #line __oline__ "${as_me:-configure}"
2153 #include "confdefs.h"
2154 #include "conftest.h"
2155 #include "conftest.i"
2156 #if     GCC_PRINTF
2157 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2158 #else
2159 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2160 #endif
2161 #if     GCC_SCANF
2162 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2163 #else
2164 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2165 #endif
2166 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2167 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2168 extern void foo(void) GCC_NORETURN;
2169 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
2170 EOF
2171         cf_printf_attribute=no
2172         cf_scanf_attribute=no
2173         for cf_attribute in scanf printf unused noreturn
2174         do
2175                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2176                 cf_directive="__attribute__(($cf_attribute))"
2177                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2178
2179                 case $cf_attribute in
2180                 (printf)
2181                         cf_printf_attribute=yes
2182                         cat >conftest.h <<EOF
2183 #define GCC_$cf_ATTRIBUTE 1
2184 EOF
2185                         ;;
2186                 (scanf)
2187                         cf_scanf_attribute=yes
2188                         cat >conftest.h <<EOF
2189 #define GCC_$cf_ATTRIBUTE 1
2190 EOF
2191                         ;;
2192                 (*)
2193                         cat >conftest.h <<EOF
2194 #define GCC_$cf_ATTRIBUTE $cf_directive
2195 EOF
2196                         ;;
2197                 esac
2198
2199                 if AC_TRY_EVAL(ac_compile); then
2200                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2201                         cat conftest.h >>confdefs.h
2202                         case $cf_attribute in
2203                         (noreturn)
2204                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2205                                 ;;
2206                         (printf)
2207                                 cf_value='/* nothing */'
2208                                 if test "$cf_printf_attribute" != no ; then
2209                                         cf_value='__attribute__((format(printf,fmt,var)))'
2210                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2211                                 fi
2212                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2213                                 ;;
2214                         (scanf)
2215                                 cf_value='/* nothing */'
2216                                 if test "$cf_scanf_attribute" != no ; then
2217                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2218                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2219                                 fi
2220                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2221                                 ;;
2222                         (unused)
2223                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2224                                 ;;
2225                         esac
2226                 fi
2227         done
2228 else
2229         fgrep define conftest.i >>confdefs.h
2230 fi
2231 rm -rf conftest*
2232 fi
2233 ])dnl
2234 dnl ---------------------------------------------------------------------------
2235 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2236 dnl --------------
2237 dnl Find version of gcc
2238 AC_DEFUN([CF_GCC_VERSION],[
2239 AC_REQUIRE([AC_PROG_CC])
2240 GCC_VERSION=none
2241 if test "$GCC" = yes ; then
2242         AC_MSG_CHECKING(version of $CC)
2243         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2244         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2245         AC_MSG_RESULT($GCC_VERSION)
2246 fi
2247 ])dnl
2248 dnl ---------------------------------------------------------------------------
2249 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
2250 dnl ---------------
2251 dnl Check if the compiler supports useful warning options.  There's a few that
2252 dnl we don't use, simply because they're too noisy:
2253 dnl
2254 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2255 dnl     -Wredundant-decls (system headers make this too noisy)
2256 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2257 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2258 dnl             is enabled for ncurses using "--enable-const".
2259 dnl     -pedantic
2260 dnl
2261 dnl Parameter:
2262 dnl     $1 is an optional list of gcc warning flags that a particular
2263 dnl             application might want to use, e.g., "no-unused" for
2264 dnl             -Wno-unused
2265 dnl Special:
2266 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2267 dnl
2268 AC_DEFUN([CF_GCC_WARNINGS],
2269 [
2270 AC_REQUIRE([CF_GCC_VERSION])
2271 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2272 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2273
2274 cat > conftest.$ac_ext <<EOF
2275 #line __oline__ "${as_me:-configure}"
2276 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2277 EOF
2278
2279 if test "$INTEL_COMPILER" = yes
2280 then
2281 # The "-wdXXX" options suppress warnings:
2282 # remark #1419: external declaration in primary source file
2283 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2284 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2285 # remark #193: zero used for undefined preprocessing identifier
2286 # remark #593: variable "curs_sb_left_arrow" was set but never used
2287 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2288 # remark #869: parameter "tw" was never referenced
2289 # remark #981: operands are evaluated in unspecified order
2290 # warning #279: controlling expression is constant
2291
2292         AC_CHECKING([for $CC warning options])
2293         cf_save_CFLAGS="$CFLAGS"
2294         EXTRA_CFLAGS="-Wall"
2295         for cf_opt in \
2296                 wd1419 \
2297                 wd1683 \
2298                 wd1684 \
2299                 wd193 \
2300                 wd593 \
2301                 wd279 \
2302                 wd810 \
2303                 wd869 \
2304                 wd981
2305         do
2306                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2307                 if AC_TRY_EVAL(ac_compile); then
2308                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2309                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2310                 fi
2311         done
2312         CFLAGS="$cf_save_CFLAGS"
2313
2314 elif test "$GCC" = yes
2315 then
2316         AC_CHECKING([for $CC warning options])
2317         cf_save_CFLAGS="$CFLAGS"
2318         EXTRA_CFLAGS=
2319         cf_warn_CONST=""
2320         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2321         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2322         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2323         for cf_opt in W Wall \
2324                 Wbad-function-cast \
2325                 Wcast-align \
2326                 Wcast-qual \
2327                 Wdeclaration-after-statement \
2328                 Wextra \
2329                 Winline \
2330                 Wmissing-declarations \
2331                 Wmissing-prototypes \
2332                 Wnested-externs \
2333                 Wpointer-arith \
2334                 Wshadow \
2335                 Wstrict-prototypes \
2336                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2337         do
2338                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2339                 if AC_TRY_EVAL(ac_compile); then
2340                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2341                         case $cf_opt in
2342                         (Wcast-qual)
2343                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2344                                 ;;
2345                         (Winline)
2346                                 case $GCC_VERSION in
2347                                 ([[34]].*)
2348                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2349                                         continue;;
2350                                 esac
2351                                 ;;
2352                         (Wpointer-arith)
2353                                 case $GCC_VERSION in
2354                                 ([[12]].*)
2355                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2356                                         continue;;
2357                                 esac
2358                                 ;;
2359                         esac
2360                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2361                 fi
2362         done
2363         CFLAGS="$cf_save_CFLAGS"
2364 fi
2365 rm -rf conftest*
2366
2367 AC_SUBST(EXTRA_CFLAGS)
2368 ])dnl
2369 dnl ---------------------------------------------------------------------------
2370 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2371 dnl ----------------
2372 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2373 dnl unistd.h or (nonstandard) in getopt.h
2374 AC_DEFUN([CF_GETOPT_HEADER],
2375 [
2376 AC_HAVE_HEADERS(unistd.h getopt.h)
2377 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2378 cf_cv_getopt_header=none
2379 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2380 do
2381 AC_TRY_COMPILE([
2382 #include <$cf_header>],
2383 [int x = optind; char *y = optarg],
2384 [cf_cv_getopt_header=$cf_header
2385  break])
2386 done
2387 ])
2388 if test $cf_cv_getopt_header != none ; then
2389         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2390 fi
2391 if test $cf_cv_getopt_header = getopt.h ; then
2392         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2393 fi
2394 ])dnl
2395 dnl ---------------------------------------------------------------------------
2396 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2397 dnl -----------------
2398 AC_DEFUN([CF_GNATPREP_OPT_T],[
2399 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2400 cf_cv_gnatprep_opt_t=no
2401 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2402 ])
2403 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2404 AC_SUBST(GNATPREP_OPTS)
2405 ])dnl
2406 dnl ---------------------------------------------------------------------------
2407 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2408 dnl ----------------
2409 AC_DEFUN([CF_GNAT_GENERICS],
2410 [
2411 AC_REQUIRE([CF_GNAT_VERSION])
2412
2413 AC_MSG_CHECKING(if GNAT supports generics)
2414 case $cf_gnat_version in
2415 (3.[[1-9]]*|[[4-9]].*)
2416         cf_gnat_generics=yes
2417         ;;
2418 (*)
2419         cf_gnat_generics=no
2420         ;;
2421 esac
2422 AC_MSG_RESULT($cf_gnat_generics)
2423
2424 if test "$cf_gnat_generics" = yes
2425 then
2426         cf_compile_generics=generics
2427         cf_generic_objects="\${GENOBJS}"
2428 else
2429         cf_compile_generics=
2430         cf_generic_objects=
2431 fi
2432
2433 AC_SUBST(cf_compile_generics)
2434 AC_SUBST(cf_generic_objects)
2435 ])dnl
2436 dnl ---------------------------------------------------------------------------
2437 dnl CF_GNAT_PROJECTS version: 8 updated: 2015/04/17 21:13:04
2438 dnl ----------------
2439 dnl GNAT projects are configured with ".gpr" project files.
2440 dnl GNAT libraries are a further development, using the project feature.
2441 AC_DEFUN([CF_GNAT_PROJECTS],
2442 [
2443 AC_REQUIRE([CF_GNAT_VERSION])
2444 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2445
2446 cf_gnat_libraries=no
2447 cf_gnat_projects=no
2448
2449 if test "$enable_gnat_projects" != no ; then
2450 AC_MSG_CHECKING(if GNAT supports project files)
2451 case $cf_gnat_version in
2452 (3.[[0-9]]*)
2453         ;;
2454 (*)
2455         case $cf_cv_system_name in
2456         (cygwin*|msys*)
2457                 ;;
2458         (*)
2459                 mkdir conftest.src conftest.bin conftest.lib
2460                 cd conftest.src
2461                 rm -rf conftest* *~conftest*
2462                 cat >>library.gpr <<CF_EOF
2463 project Library is
2464   Kind := External ("LIB_KIND");
2465   for Library_Name use "ConfTest";
2466   for Object_Dir use ".";
2467   for Library_ALI_Dir use External("LIBRARY_DIR");
2468   for Library_Version use External ("SONAME");
2469   for Library_Kind use Kind;
2470   for Library_Dir use External("BUILD_DIR");
2471   Source_Dir := External ("SOURCE_DIR");
2472   for Source_Dirs use (Source_Dir);
2473 end Library;
2474 CF_EOF
2475                 cat >>confpackage.ads <<CF_EOF
2476 package ConfPackage is
2477    procedure conftest;
2478 end ConfPackage;
2479 CF_EOF
2480                 cat >>confpackage.adb <<CF_EOF
2481 with Text_IO;
2482 package body ConfPackage is
2483    procedure conftest is
2484    begin
2485       Text_IO.Put ("Hello World");
2486       Text_IO.New_Line;
2487    end conftest;
2488 end ConfPackage;
2489 CF_EOF
2490                 if ( $cf_ada_make $ADAFLAGS \
2491                                 -Plibrary.gpr \
2492                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2493                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2494                                 -XSOURCE_DIR=`pwd` \
2495                                 -XSONAME=libConfTest.so.1 \
2496                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2497                         cf_gnat_projects=yes
2498                 fi
2499                 cd ..
2500                 if test -f conftest.lib/confpackage.ali
2501                 then
2502                         cf_gnat_libraries=yes
2503                 fi
2504                 rm -rf conftest* *~conftest*
2505                 ;;
2506         esac
2507         ;;
2508 esac
2509 AC_MSG_RESULT($cf_gnat_projects)
2510 fi # enable_gnat_projects
2511
2512 if test $cf_gnat_projects = yes
2513 then
2514         AC_MSG_CHECKING(if GNAT supports libraries)
2515         AC_MSG_RESULT($cf_gnat_libraries)
2516 fi
2517
2518 if test "$cf_gnat_projects" = yes
2519 then
2520         USE_OLD_MAKERULES="#"
2521         USE_GNAT_PROJECTS=""
2522 else
2523         USE_OLD_MAKERULES=""
2524         USE_GNAT_PROJECTS="#"
2525 fi
2526
2527 if test "$cf_gnat_libraries" = yes
2528 then
2529         USE_GNAT_LIBRARIES=""
2530 else
2531         USE_GNAT_LIBRARIES="#"
2532 fi
2533
2534 AC_SUBST(USE_OLD_MAKERULES)
2535 AC_SUBST(USE_GNAT_PROJECTS)
2536 AC_SUBST(USE_GNAT_LIBRARIES)
2537 ])dnl
2538 dnl ---------------------------------------------------------------------------
2539 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2540 dnl --------------
2541 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2542 dnl is noted that gnat may compile a tasking unit even for configurations which
2543 dnl fail at runtime.
2544 AC_DEFUN([CF_GNAT_SIGINT],[
2545 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2546 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2547
2548 package ConfTest is
2549
2550    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2551    pragma Unreserve_All_Interrupts;
2552    pragma Warnings (On);
2553
2554    protected Process is
2555       procedure Stop;
2556       function Continue return Boolean;
2557       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2558    private
2559       Done : Boolean := False;
2560    end Process;
2561
2562 end ConfTest;],
2563 [package body ConfTest is
2564    protected body Process is
2565       procedure Stop is
2566       begin
2567          Done := True;
2568       end Stop;
2569       function Continue return Boolean is
2570       begin
2571          return not Done;
2572       end Continue;
2573    end Process;
2574 end ConfTest;],
2575         [cf_cv_gnat_sigint=yes],
2576         [cf_cv_gnat_sigint=no])])
2577
2578 if test $cf_cv_gnat_sigint = yes ; then
2579         USE_GNAT_SIGINT=""
2580 else
2581         USE_GNAT_SIGINT="#"
2582 fi
2583 AC_SUBST(USE_GNAT_SIGINT)
2584 ])dnl
2585 dnl ---------------------------------------------------------------------------
2586 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2587 dnl ----------------
2588 dnl Verify that a test program compiles/links with GNAT.
2589 dnl $cf_ada_make is set to the program that compiles/links
2590 dnl $ADAFLAGS may be set to the GNAT flags.
2591 dnl
2592 dnl $1 is the text of the spec
2593 dnl $2 is the text of the body
2594 dnl $3 is the shell command to execute if successful
2595 dnl $4 is the shell command to execute if not successful
2596 AC_DEFUN([CF_GNAT_TRY_LINK],
2597 [
2598 rm -rf conftest* *~conftest*
2599 cat >>conftest.ads <<CF_EOF
2600 $1
2601 CF_EOF
2602 cat >>conftest.adb <<CF_EOF
2603 $2
2604 CF_EOF
2605 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2606 ifelse($3,,      :,[      $3])
2607 ifelse($4,,,[else
2608    $4])
2609 fi
2610 rm -rf conftest* *~conftest*
2611 ])dnl
2612 dnl ---------------------------------------------------------------------------
2613 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2614 dnl ---------------
2615 dnl Verify that a test program compiles and runs with GNAT
2616 dnl $cf_ada_make is set to the program that compiles/links
2617 dnl $ADAFLAGS may be set to the GNAT flags.
2618 dnl
2619 dnl $1 is the text of the spec
2620 dnl $2 is the text of the body
2621 dnl $3 is the shell command to execute if successful
2622 dnl $4 is the shell command to execute if not successful
2623 AC_DEFUN([CF_GNAT_TRY_RUN],
2624 [
2625 rm -rf conftest* *~conftest*
2626 cat >>conftest.ads <<CF_EOF
2627 $1
2628 CF_EOF
2629 cat >>conftest.adb <<CF_EOF
2630 $2
2631 CF_EOF
2632 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2633    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2634 ifelse($3,,      :,[      $3])
2635 ifelse($4,,,[   else
2636       $4])
2637    fi
2638 ifelse($4,,,[else
2639    $4])
2640 fi
2641 rm -rf conftest* *~conftest*
2642 ])dnl
2643 dnl ---------------------------------------------------------------------------
2644 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
2645 dnl ---------------
2646 dnl Verify version of GNAT.
2647 AC_DEFUN([CF_GNAT_VERSION],
2648 [
2649 AC_MSG_CHECKING(for gnat version)
2650 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2651         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2652         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2653 AC_MSG_RESULT($cf_gnat_version)
2654
2655 case $cf_gnat_version in
2656 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
2657         cf_cv_prog_gnat_correct=yes
2658         ;;
2659 (*)
2660         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2661         cf_cv_prog_gnat_correct=no
2662         ;;
2663 esac
2664 ])
2665 dnl ---------------------------------------------------------------------------
2666 dnl CF_GNU_SOURCE version: 7 updated: 2016/08/05 05:15:37
2667 dnl -------------
2668 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2669 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2670 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2671 dnl since it is interwoven with GNU extensions.
2672 dnl
2673 dnl Well, yes we could work around it...
2674 AC_DEFUN([CF_GNU_SOURCE],
2675 [
2676 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2677 AC_TRY_COMPILE([#include <sys/types.h>],[
2678 #ifndef _XOPEN_SOURCE
2679 make an error
2680 #endif],
2681         [cf_cv_gnu_source=no],
2682         [cf_save="$CPPFLAGS"
2683          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2684          AC_TRY_COMPILE([#include <sys/types.h>],[
2685 #ifdef _XOPEN_SOURCE
2686 make an error
2687 #endif],
2688         [cf_cv_gnu_source=no],
2689         [cf_cv_gnu_source=yes])
2690         CPPFLAGS="$cf_save"
2691         ])
2692 ])
2693
2694 if test "$cf_cv_gnu_source" = yes
2695 then
2696 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
2697 CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2698         AC_TRY_COMPILE([#include <sys/types.h>],[
2699 #ifdef _DEFAULT_SOURCE
2700 make an error
2701 #endif],
2702                 [cf_cv_default_source=no],
2703                 [cf_cv_default_source=yes])
2704         ])
2705 test "$cf_cv_default_source" = yes && CPPFLAGS="$CPPFLAGS -D_DEFAULT_SOURCE"
2706 fi
2707 ])dnl
2708 dnl ---------------------------------------------------------------------------
2709 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
2710 dnl --------------
2711 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2712 dnl problem :-).  If we have the compiler but no library, we'll be able to
2713 dnl configure, but won't be able to build the c++ demo program.
2714 AC_DEFUN([CF_GPP_LIBRARY],
2715 [
2716 cf_cxx_library=unknown
2717 case $cf_cv_system_name in
2718 (os2*)
2719         cf_gpp_libname=gpp
2720         ;;
2721 (*)
2722         cf_gpp_libname=g++
2723         ;;
2724 esac
2725 if test "$GXX" = yes; then
2726         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2727         cf_save="$LIBS"
2728         CF_ADD_LIB($cf_gpp_libname)
2729         AC_TRY_LINK([
2730 #include <$cf_gpp_libname/builtin.h>
2731         ],
2732         [two_arg_error_handler_t foo2 = lib_error_handler],
2733         [cf_cxx_library=yes
2734          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2735          if test "$cf_gpp_libname" = cpp ; then
2736             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2737          else
2738             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2739          fi],
2740         [AC_TRY_LINK([
2741 #include <builtin.h>
2742         ],
2743         [two_arg_error_handler_t foo2 = lib_error_handler],
2744         [cf_cxx_library=yes
2745          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2746          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2747         [cf_cxx_library=no])])
2748         LIBS="$cf_save"
2749         AC_MSG_RESULT($cf_cxx_library)
2750 fi
2751 ])dnl
2752 dnl ---------------------------------------------------------------------------
2753 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2754 dnl --------------
2755 dnl Check for version of g++
2756 AC_DEFUN([CF_GXX_VERSION],[
2757 AC_REQUIRE([AC_PROG_CPP])
2758 GXX_VERSION=none
2759 if test "$GXX" = yes; then
2760         AC_MSG_CHECKING(version of ${CXX:-g++})
2761         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2762         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2763         AC_MSG_RESULT($GXX_VERSION)
2764 fi
2765 ])dnl
2766 dnl ---------------------------------------------------------------------------
2767 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
2768 dnl ---------------
2769 dnl Check if the compiler supports useful warning options.
2770 dnl
2771 dnl Most of gcc's options apply to g++, except:
2772 dnl     -Wbad-function-cast
2773 dnl     -Wmissing-declarations
2774 dnl     -Wnested-externs
2775 dnl
2776 dnl Omit a few (for now):
2777 dnl     -Winline
2778 dnl
2779 dnl Parameter:
2780 dnl     $1 is an optional list of g++ warning flags that a particular
2781 dnl             application might want to use, e.g., "no-unused" for
2782 dnl             -Wno-unused
2783 dnl Special:
2784 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2785 dnl
2786 AC_DEFUN([CF_GXX_WARNINGS],
2787 [
2788
2789 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2790 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2791
2792 AC_REQUIRE([CF_GXX_VERSION])
2793
2794 AC_LANG_SAVE
2795 AC_LANG_CPLUSPLUS
2796
2797 cat > conftest.$ac_ext <<EOF
2798 #line __oline__ "configure"
2799 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2800 EOF
2801
2802 if test "$INTEL_CPLUSPLUS" = yes
2803 then
2804 # The "-wdXXX" options suppress warnings:
2805 # remark #1419: external declaration in primary source file
2806 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2807 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2808 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2809 # remark #193: zero used for undefined preprocessing identifier
2810 # remark #593: variable "curs_sb_left_arrow" was set but never used
2811 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2812 # remark #869: parameter "tw" was never referenced
2813 # remark #981: operands are evaluated in unspecified order
2814 # warning #269: invalid format string conversion
2815
2816         AC_CHECKING([for $CC warning options])
2817         cf_save_CXXFLAGS="$CXXFLAGS"
2818         EXTRA_CXXFLAGS="-Wall"
2819         for cf_opt in \
2820                 wd1419 \
2821                 wd1682 \
2822                 wd1683 \
2823                 wd1684 \
2824                 wd193 \
2825                 wd279 \
2826                 wd593 \
2827                 wd810 \
2828                 wd869 \
2829                 wd981
2830         do
2831                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2832                 if AC_TRY_EVAL(ac_compile); then
2833                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2834                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2835                 fi
2836         done
2837         CXXFLAGS="$cf_save_CXXFLAGS"
2838
2839 elif test "$GXX" = yes
2840 then
2841         AC_CHECKING([for $CXX warning options])
2842         cf_save_CXXFLAGS="$CXXFLAGS"
2843         EXTRA_CXXFLAGS="-W -Wall"
2844         cf_gxx_extra_warnings=""
2845         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2846         case "$GCC_VERSION" in
2847         ([[1-2]].*)
2848                 ;;
2849         (*)
2850                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2851                 ;;
2852         esac
2853         for cf_opt in \
2854                 Wabi \
2855                 fabi-version=0 \
2856                 Wextra \
2857                 Wignored-qualifiers \
2858                 Wlogical-op \
2859                 Woverloaded-virtual \
2860                 Wsign-promo \
2861                 Wsynth \
2862                 Wold-style-cast \
2863                 Wcast-align \
2864                 Wcast-qual \
2865                 Wpointer-arith \
2866                 Wshadow \
2867                 Wundef $cf_gxx_extra_warnings $1
2868         do
2869                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2870                 if AC_TRY_EVAL(ac_compile); then
2871                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2872                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2873                 else
2874                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2875                 fi
2876         done
2877         CXXFLAGS="$cf_save_CXXFLAGS"
2878 fi
2879
2880 rm -rf conftest*
2881 AC_LANG_RESTORE
2882 AC_SUBST(EXTRA_CXXFLAGS)
2883 ])dnl
2884 dnl ---------------------------------------------------------------------------
2885 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
2886 dnl ------------
2887 dnl Look for an instance of the Berkeley hashed database.
2888 dnl
2889 dnl $1 = optional parameter, to specify install-prefix for the database.
2890 AC_DEFUN([CF_HASHED_DB],
2891 [
2892 ifelse([$1],,,[
2893 case $1 in
2894 (yes|*able*)
2895         ;;
2896 (*)
2897         if test -d "$1" ; then
2898                 CF_ADD_INCDIR($1/include)
2899                 CF_ADD_LIBDIR($1/lib)
2900         else
2901                 case "$1" in
2902                 (./*|../*|/*)
2903                         AC_MSG_WARN(no such directory $1)
2904                         ;;
2905                 (*)
2906                         CF_FIND_SUB_INCDIR($1)
2907                         CF_FIND_SUB_LIBDIR($1)
2908                         ;;
2909                 esac
2910         fi
2911 esac
2912 ])
2913 AC_CHECK_HEADER(db.h,[
2914 CF_HASHED_DB_VERSION
2915 if test "$cf_cv_hashed_db_version" = unknown ; then
2916         AC_MSG_ERROR(Cannot determine version of db)
2917 else
2918         CF_HASHED_DB_LIBS
2919         if test "$cf_cv_hashed_db_libs" = unknown ; then
2920                 AC_MSG_ERROR(Cannot determine library for db)
2921         elif test "$cf_cv_hashed_db_libs" != default ; then
2922                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2923         fi
2924 fi
2925 ],[
2926         AC_MSG_ERROR(Cannot find db.h)
2927 ])
2928 ])dnl
2929 dnl ---------------------------------------------------------------------------
2930 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2931 dnl -----------------
2932 dnl Given that we have the header and version for hashed database, find the
2933 dnl library information.
2934 AC_DEFUN([CF_HASHED_DB_LIBS],
2935 [
2936 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2937 cf_cv_hashed_db_libs=unknown
2938 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2939 do
2940         cf_save_libs="$LIBS"
2941         if test -n "$cf_db_libs"; then
2942                 CF_ADD_LIB($cf_db_libs)
2943         fi
2944         CF_MSG_LOG(checking for library "$cf_db_libs")
2945         AC_TRY_LINK([
2946 $ac_includes_default
2947 #include <db.h>
2948 ],[
2949         char *path = "/tmp/foo";
2950 #ifdef DB_VERSION_MAJOR
2951 #if DB_VERSION_MAJOR >= 4
2952         DB *result = 0;
2953         db_create(&result, NULL, 0);
2954         result->open(result,
2955                 NULL,
2956                 path,
2957                 path,
2958                 DB_HASH,
2959                 DB_CREATE,
2960                 0644);
2961 #elif DB_VERSION_MAJOR >= 3
2962         DB *result = 0;
2963         db_create(&result, NULL, 0);
2964         result->open(result,
2965                 path,
2966                 path,
2967                 DB_HASH,
2968                 DB_CREATE,
2969                 0644);
2970 #elif DB_VERSION_MAJOR >= 2
2971         DB *result = 0;
2972         db_open(path,
2973                 DB_HASH,
2974                 DB_CREATE,
2975                 0644,
2976                 (DB_ENV *) 0,
2977                 (DB_INFO *) 0,
2978                 &result);
2979 #endif /* DB_VERSION_MAJOR */
2980 #else
2981         DB *result = dbopen(path,
2982                      2,
2983                      0644,
2984                      DB_HASH,
2985                      0);
2986 #endif
2987         ${cf_cv_main_return:-return}(result != 0)
2988 ],[
2989         if test -n "$cf_db_libs" ; then
2990                 cf_cv_hashed_db_libs=$cf_db_libs
2991         else
2992                 cf_cv_hashed_db_libs=default
2993         fi
2994         LIBS="$cf_save_libs"
2995         break
2996 ])
2997         LIBS="$cf_save_libs"
2998 done
2999 ])
3000 ])dnl
3001 dnl ---------------------------------------------------------------------------
3002 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3003 dnl --------------------
3004 dnl Given that we have the header file for hashed database, find the version
3005 dnl information.
3006 AC_DEFUN([CF_HASHED_DB_VERSION],
3007 [
3008 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3009 cf_cv_hashed_db_version=unknown
3010
3011 for cf_db_version in 1 2 3 4 5 6
3012 do
3013         CF_MSG_LOG(checking for db version $cf_db_version)
3014         AC_TRY_COMPILE([
3015 $ac_includes_default
3016 #include <db.h>
3017
3018 #ifdef DB_VERSION_MAJOR
3019         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3020 #if $cf_db_version == DB_VERSION_MAJOR
3021         /* ok */
3022 #else
3023         make an error
3024 #endif
3025 #else
3026 #if $cf_db_version == 1
3027         /* ok: assuming this is DB 1.8.5 */
3028 #else
3029         make an error
3030 #endif
3031 #endif
3032 ],[DBT *foo = 0],[
3033         cf_cv_hashed_db_version=$cf_db_version
3034         break
3035         ])
3036 done
3037 ])
3038 ])dnl
3039 dnl ---------------------------------------------------------------------------
3040 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3041 dnl --------------
3042 dnl Construct a search-list of directories for a nonstandard header-file
3043 dnl
3044 dnl Parameters
3045 dnl     $1 = the variable to return as result
3046 dnl     $2 = the package name
3047 AC_DEFUN([CF_HEADER_PATH],
3048 [
3049 $1=
3050
3051 # collect the current set of include-directories from compiler flags
3052 cf_header_path_list=""
3053 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3054         for cf_header_path in $CPPFLAGS $CFLAGS
3055         do
3056                 case $cf_header_path in
3057                 (-I*)
3058                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3059                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3060                         cf_header_path_list="$cf_header_path_list [$]$1"
3061                         ;;
3062                 esac
3063         done
3064 fi
3065
3066 # add the variations for the package we are looking for
3067 CF_SUBDIR_PATH($1,$2,include)
3068
3069 test "$includedir" != NONE && \
3070 test "$includedir" != "/usr/include" && \
3071 test -d "$includedir" && {
3072         test -d $includedir &&    $1="[$]$1 $includedir"
3073         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3074 }
3075
3076 test "$oldincludedir" != NONE && \
3077 test "$oldincludedir" != "/usr/include" && \
3078 test -d "$oldincludedir" && {
3079         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3080         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3081 }
3082
3083 $1="[$]$1 $cf_header_path_list"
3084 ])dnl
3085 dnl ---------------------------------------------------------------------------
3086 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
3087 dnl ---------------
3088 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3089 AC_DEFUN([CF_HELP_MESSAGE],
3090 [AC_DIVERT_HELP([$1])dnl
3091 ])dnl
3092 dnl ---------------------------------------------------------------------------
3093 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3094 dnl ---------------
3095 dnl Construct the list of include-options according to whether we're building
3096 dnl in the source directory or using '--srcdir=DIR' option.
3097 AC_DEFUN([CF_INCLUDE_DIRS],
3098 [
3099 if test "$srcdir" != "."; then
3100         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3101 fi
3102 CPPFLAGS="-I../include $CPPFLAGS"
3103 if test "$srcdir" != "."; then
3104         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3105 fi
3106 CPPFLAGS="-I. $CPPFLAGS"
3107 AC_SUBST(CPPFLAGS)
3108 ])dnl
3109 dnl ---------------------------------------------------------------------------
3110 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3111 dnl -----------------
3112 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3113 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3114 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3115 dnl
3116 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3117 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3118 dnl the wrappers for gcc and g++ warnings.
3119 dnl
3120 dnl $1 = GCC (default) or GXX
3121 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3122 dnl $3 = CFLAGS (default) or CXXFLAGS
3123 AC_DEFUN([CF_INTEL_COMPILER],[
3124 AC_REQUIRE([AC_CANONICAL_HOST])
3125 ifelse([$2],,INTEL_COMPILER,[$2])=no
3126
3127 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3128         case $host_os in
3129         (linux*|gnu*)
3130                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3131                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3132                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3133                 AC_TRY_COMPILE([],[
3134 #ifdef __INTEL_COMPILER
3135 #else
3136 make an error
3137 #endif
3138 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3139 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3140 ],[])
3141                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3142                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3143                 ;;
3144         esac
3145 fi
3146 ])dnl
3147 dnl ---------------------------------------------------------------------------
3148 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3149 dnl ----------
3150 dnl Check if we have either a function or macro for 'isascii()'.
3151 AC_DEFUN([CF_ISASCII],
3152 [
3153 AC_MSG_CHECKING(for isascii)
3154 AC_CACHE_VAL(cf_cv_have_isascii,[
3155         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3156         [cf_cv_have_isascii=yes],
3157         [cf_cv_have_isascii=no])
3158 ])dnl
3159 AC_MSG_RESULT($cf_cv_have_isascii)
3160 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3161 ])dnl
3162 dnl ---------------------------------------------------------------------------
3163 dnl CF_LARGEFILE version: 9 updated: 2015/04/18 08:56:57
3164 dnl ------------
3165 dnl Add checks for large file support.
3166 AC_DEFUN([CF_LARGEFILE],[
3167 ifdef([AC_FUNC_FSEEKO],[
3168         AC_SYS_LARGEFILE
3169         if test "$enable_largefile" != no ; then
3170         AC_FUNC_FSEEKO
3171
3172         # Normally we would collect these definitions in the config.h,
3173         # but (like _XOPEN_SOURCE), some environments rely on having these
3174         # defined before any of the system headers are included.  Another
3175         # case comes up with C++, e.g., on AIX the compiler compiles the
3176         # header files by themselves before looking at the body files it is
3177         # told to compile.  For ncurses, those header files do not include
3178         # the config.h
3179         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
3180         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
3181         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
3182
3183         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3184                 AC_TRY_COMPILE([
3185 #include <sys/types.h>
3186 #include <dirent.h>
3187                 ],[
3188                 /* if transitional largefile support is setup, this is true */
3189                 extern struct dirent64 * readdir(DIR *);
3190                 struct dirent64 *x = readdir((DIR *)0);
3191                 struct dirent *y = readdir((DIR *)0);
3192                 int z = x - y;
3193                 ],
3194                 [cf_cv_struct_dirent64=yes],
3195                 [cf_cv_struct_dirent64=no])
3196         ])
3197         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3198         fi
3199 ])
3200 ])
3201 dnl ---------------------------------------------------------------------------
3202 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3203 dnl -----------------
3204 dnl Check for compiler/linker flags used to temporarily force usage of static
3205 dnl libraries.  This depends on the compiler and platform.  Use this to help
3206 dnl ensure that the linker picks up a given library based on its position in
3207 dnl the list of linker options and libraries.
3208 AC_DEFUN([CF_LDFLAGS_STATIC],[
3209
3210 if test "$GCC" = yes ; then
3211         case $cf_cv_system_name in
3212         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3213                 LDFLAGS_STATIC=
3214                 LDFLAGS_SHARED=
3215                 ;;
3216         (*)     # normally, except when broken
3217                 LDFLAGS_STATIC=-static
3218                 LDFLAGS_SHARED=-dynamic
3219                 ;;
3220         esac
3221 else
3222         case $cf_cv_system_name in
3223         (aix[[4-7]]*)   # from ld manpage
3224                 LDFLAGS_STATIC=-bstatic
3225                 LDFLAGS_SHARED=-bdynamic
3226                 ;;
3227         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3228                 # We could also use just "archive" and "shared".
3229                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3230                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3231                 ;;
3232         (irix*)         # from ld manpage IRIX64
3233                 LDFLAGS_STATIC=-Bstatic
3234                 LDFLAGS_SHARED=-Bdynamic
3235                 ;;
3236         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3237                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3238                 LDFLAGS_STATIC=-noso
3239                 LDFLAGS_SHARED=-so_archive
3240                 ;;
3241         (solaris2*)
3242                 LDFLAGS_STATIC=-Bstatic
3243                 LDFLAGS_SHARED=-Bdynamic
3244                 ;;
3245         esac
3246 fi
3247
3248 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3249 then
3250         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3251
3252         rm -f libconftest.a
3253         cat >conftest.$ac_ext <<EOF
3254 #line __oline__ "configure"
3255 #include <stdio.h>
3256 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3257 EOF
3258         if AC_TRY_EVAL(ac_compile) ; then
3259                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3260                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3261         fi
3262         rm -f conftest.*
3263
3264         cf_save_LIBS="$LIBS"
3265
3266         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3267         AC_TRY_LINK([
3268 #line __oline__ "configure"
3269 #include <stdio.h>
3270 int cf_ldflags_static(FILE *fp);
3271 ],[
3272         return cf_ldflags_static(stdin);
3273 ],[
3274         # some linkers simply ignore the -dynamic
3275         case x`file conftest$ac_exeext 2>/dev/null` in
3276         (*static*)
3277                 cf_ldflags_static=no
3278                 ;;
3279         (*)
3280                 cf_ldflags_static=yes
3281                 ;;
3282         esac
3283 ],[cf_ldflags_static=no])
3284
3285         rm -f libconftest.*
3286         LIBS="$cf_save_LIBS"
3287
3288         AC_MSG_RESULT($cf_ldflags_static)
3289
3290         if test $cf_ldflags_static != yes
3291         then
3292                 LDFLAGS_STATIC=
3293                 LDFLAGS_SHARED=
3294         fi
3295 else
3296         LDFLAGS_STATIC=
3297         LDFLAGS_SHARED=
3298 fi
3299
3300 AC_SUBST(LDFLAGS_STATIC)
3301 AC_SUBST(LDFLAGS_SHARED)
3302 ])
3303 dnl ---------------------------------------------------------------------------
3304 dnl CF_LD_RPATH_OPT version: 7 updated: 2016/02/20 18:01:19
3305 dnl ---------------
3306 dnl For the given system and compiler, find the compiler flags to pass to the
3307 dnl loader to use the "rpath" feature.
3308 AC_DEFUN([CF_LD_RPATH_OPT],
3309 [
3310 AC_REQUIRE([CF_CHECK_CACHE])
3311
3312 LD_RPATH_OPT=
3313 AC_MSG_CHECKING(for an rpath option)
3314 case $cf_cv_system_name in
3315 (irix*)
3316         if test "$GCC" = yes; then
3317                 LD_RPATH_OPT="-Wl,-rpath,"
3318         else
3319                 LD_RPATH_OPT="-rpath "
3320         fi
3321         ;;
3322 (linux*|gnu*|k*bsd*-gnu|freebsd*)
3323         LD_RPATH_OPT="-Wl,-rpath,"
3324         ;;
3325 (openbsd[[2-9]].*|mirbsd*)
3326         LD_RPATH_OPT="-Wl,-rpath,"
3327         ;;
3328 (dragonfly*)
3329         LD_RPATH_OPT="-rpath "
3330         ;;
3331 (netbsd*)
3332         LD_RPATH_OPT="-Wl,-rpath,"
3333         ;;
3334 (osf*|mls+*)
3335         LD_RPATH_OPT="-rpath "
3336         ;;
3337 (solaris2*)
3338         LD_RPATH_OPT="-R"
3339         ;;
3340 (*)
3341         ;;
3342 esac
3343 AC_MSG_RESULT($LD_RPATH_OPT)
3344
3345 case "x$LD_RPATH_OPT" in
3346 (x-R*)
3347         AC_MSG_CHECKING(if we need a space after rpath option)
3348         cf_save_LIBS="$LIBS"
3349         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3350         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3351         LIBS="$cf_save_LIBS"
3352         AC_MSG_RESULT($cf_rpath_space)
3353         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3354         ;;
3355 esac
3356 ])dnl
3357 dnl ---------------------------------------------------------------------------
3358 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3359 dnl ---------------
3360 dnl Construct a search-list of directories for a nonstandard library-file
3361 dnl
3362 dnl Parameters
3363 dnl     $1 = the variable to return as result
3364 dnl     $2 = the package name
3365 AC_DEFUN([CF_LIBRARY_PATH],
3366 [
3367 $1=
3368 cf_library_path_list=""
3369 if test -n "${LDFLAGS}${LIBS}" ; then
3370         for cf_library_path in $LDFLAGS $LIBS
3371         do
3372                 case $cf_library_path in
3373                 (-L*)
3374                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3375                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3376                         cf_library_path_list="$cf_library_path_list [$]$1"
3377                         ;;
3378                 esac
3379         done
3380 fi
3381
3382 CF_SUBDIR_PATH($1,$2,lib)
3383
3384 $1="$cf_library_path_list [$]$1"
3385 ])dnl
3386 dnl ---------------------------------------------------------------------------
3387 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3388 dnl ------------------
3389 AC_DEFUN([CF_LIBTOOL_VERSION],[
3390 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3391 then
3392         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3393 else
3394         cf_cv_libtool_version=
3395 fi
3396 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3397 ])dnl
3398 dnl ---------------------------------------------------------------------------
3399 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
3400 dnl -------------
3401 dnl Compute the library-prefix for the given host system
3402 dnl $1 = variable to set
3403 define([CF_LIB_PREFIX],
3404 [
3405         case $cf_cv_system_name in
3406         (OS/2*|os2*)
3407                 if test "$DFT_LWR_MODEL" = libtool; then
3408                         LIB_PREFIX='lib'
3409                 else
3410                         LIB_PREFIX=''
3411                 fi
3412                 ;;
3413         (*)     LIB_PREFIX='lib'
3414                 ;;
3415         esac
3416 ifelse($1,,,[$1=$LIB_PREFIX])
3417         AC_SUBST(LIB_PREFIX)
3418 ])dnl
3419 dnl ---------------------------------------------------------------------------
3420 dnl CF_LIB_RULES version: 86 updated: 2015/11/07 20:01:34
3421 dnl ------------
3422 dnl Append definitions and rules for the given models to the subdirectory
3423 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3424 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3425 dnl the corresponding makefile to list the models that we'll generate.
3426 dnl
3427 dnl For shared libraries, make a list of symbolic links to construct when
3428 dnl generating each library.  The convention used for Linux is the simplest
3429 dnl one:
3430 dnl     lib<name>.so    ->
3431 dnl     lib<name>.so.<major>    ->
3432 dnl     lib<name>.so.<maj>.<minor>
3433 dnl
3434 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3435 AC_DEFUN([CF_LIB_RULES],
3436 [
3437 cf_prefix=$LIB_PREFIX
3438 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3439
3440 case $cf_cv_shlib_version in
3441 (cygdll|msysdll|mingw)
3442         TINFO_NAME=$TINFO_ARG_SUFFIX
3443         TINFO_SUFFIX=.dll
3444         ;;
3445 esac
3446
3447 if test -n "$TINFO_SUFFIX" ; then
3448         case $TINFO_SUFFIX in
3449         (tw*)
3450                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
3451                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
3452                 ;;
3453         (t*)
3454                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
3455                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
3456                 ;;
3457         (w*)
3458                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
3459                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
3460                 ;;
3461         esac
3462 fi
3463
3464 for cf_dir in $SRC_SUBDIRS
3465 do
3466         if test ! -d $srcdir/$cf_dir ; then
3467                 continue
3468         elif test -f $srcdir/$cf_dir/modules; then
3469
3470                 SHARED_LIB=
3471                 Libs_To_Make=
3472                 cf_awk_program=
3473                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3474                 then
3475                         cf_awk_program="$cf_awk_program\
3476 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
3477 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
3478 "
3479                 fi
3480
3481                 if test "x$WILDCARD_SYMS" = xno
3482                 then
3483                         cf_awk_program="$cf_awk_program\
3484 /[[     ]]_\\*;/ { skip=1; next; }\
3485 "
3486                 fi
3487
3488                 if test "x$cf_awk_program" != "x"
3489                 then
3490                         cat >>$cf_dir/Makefile <<CF_EOF
3491
3492 # Generated by CF_LIB_RULES
3493 resulting.map: $UNALTERED_SYMS
3494         $AWK 'BEGIN { skip = 1; last=""; } \
3495 $cf_awk_program \
3496 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
3497  skip = 0; last = \[$]\[$]0; } \
3498 END { print last; }' < $UNALTERED_SYMS >\[$]@
3499
3500 distclean::
3501         rm -f resulting.map
3502 CF_EOF
3503                 fi
3504
3505                 for cf_item in $cf_LIST_MODELS
3506                 do
3507                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3508                         cf_libname=$cf_dir
3509                         test "$cf_dir" = c++ && cf_libname=ncurses++
3510                         if test $cf_item = shared ; then
3511                                 if test -n "${LIB_SUFFIX}"
3512                                 then
3513                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3514                                 else
3515                                         cf_shared_suffix="$cf_suffix"
3516                                 fi
3517                                 if test "$cf_cv_do_symlinks" = yes ; then
3518                                         cf_version_name=
3519
3520                                         case "$cf_cv_shlib_version" in
3521                                         (rel)
3522                                                 cf_version_name=REL_VERSION
3523                                                 ;;
3524                                         (abi)
3525                                                 cf_version_name=ABI_VERSION
3526                                                 ;;
3527                                         esac
3528
3529                                         if test -n "$cf_version_name"
3530                                         then
3531                                                 case "$cf_cv_system_name" in
3532                                                 (darwin*)
3533                                                         # "w", etc?
3534                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3535                                                         ;;
3536                                                 (*)
3537                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3538                                                         ;;
3539                                                 esac
3540                                         fi
3541                                         if test -n "${USE_LIB_SUFFIX}"
3542                                         then
3543                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3544                                         else
3545                                                 cf_shared_suffix="$cf_suffix"
3546                                         fi
3547                                 fi
3548                                 # cygwin needs import library, and has unique naming convention
3549                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3550                                 # use 'cyg' prefix for shared lib.
3551                                 case $cf_cv_shlib_version in
3552                                 (cygdll)
3553                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3554                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
3555                                         ;;
3556                                 (msysdll)
3557                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3558                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
3559                                         ;;
3560                                 (mingw)
3561                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3562                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
3563                                         ;;
3564                                 (*)
3565                                         cf_add_lib=
3566                                         ;;
3567                                 esac
3568                                 if test -n "$cf_add_lib"
3569                                 then
3570                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3571                                         continue
3572                                 fi
3573                         fi
3574                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3575                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3576                 done
3577
3578                 if test $cf_dir = ncurses ; then
3579                         cf_subsets="$LIB_SUBSETS"
3580                         cf_r_parts="$cf_subsets"
3581                         cf_liblist="$Libs_To_Make"
3582
3583                         while test -n "$cf_r_parts"
3584                         do
3585                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3586                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3587                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3588                                         cf_add_lib=
3589                                         case $cf_l_parts in
3590                                         (*termlib*)
3591                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3592                                                 ;;
3593                                         (*ticlib*)
3594                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3595                                                 ;;
3596                                         (*)
3597                                                 break
3598                                                 ;;
3599                                         esac
3600                                         if test -n "$cf_add_lib"; then
3601                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
3602                                         fi
3603                                 else
3604                                         break
3605                                 fi
3606                         done
3607                 else
3608                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3609                 fi
3610
3611                 if test $cf_dir = c++; then
3612                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3613                                 cf_list=
3614                                 for cf_item in $Libs_To_Make
3615                                 do
3616                                         case $cf_item in
3617                                         (*.a)
3618                                                 ;;
3619                                         (*)
3620                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3621                                                 ;;
3622                                         esac
3623                                         for cf_test in $cf_list
3624                                         do
3625                                                 if test "$cf_test" = "$cf_item"
3626                                                 then
3627                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3628                                                         cf_item=
3629                                                         break
3630                                                 fi
3631                                         done
3632                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3633                                 done
3634                                 Libs_To_Make="$cf_list"
3635                         fi
3636                 fi
3637
3638                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3639                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3640                         $cf_dir/Makefile >$cf_dir/Makefile.out
3641                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3642
3643                 $AWK -f $srcdir/mk-0th.awk \
3644                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3645                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3646
3647                 for cf_subset in $cf_subsets
3648                 do
3649                         cf_subdirs=
3650                         for cf_item in $cf_LIST_MODELS
3651                         do
3652
3653                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3654                         CF_UPPER(cf_ITEM,$cf_item)
3655
3656                         CXX_MODEL=$cf_ITEM
3657                         if test "$CXX_MODEL" = SHARED; then
3658                                 case $cf_cv_shlib_version in
3659                                 (cygdll|msysdll|mingw)
3660                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3661                                         with_shared_cxx=yes
3662                                         ;;
3663                                 (*)
3664                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3665                                         ;;
3666                                 esac
3667                         fi
3668
3669                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3670                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3671
3672                         # Test for case where we build libtinfo with a different name.
3673                         cf_libname=$cf_dir
3674                         if test $cf_dir = ncurses ; then
3675                                 case $cf_subset in
3676                                 (*base*)
3677                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
3678                                         ;;
3679                                 (*termlib*)
3680                                         cf_libname=$TINFO_LIB_SUFFIX
3681                                         ;;
3682                                 (ticlib*)
3683                                         cf_libname=$TICS_LIB_SUFFIX
3684                                         ;;
3685                                 esac
3686                         elif test $cf_dir = c++ ; then
3687                                 cf_libname=ncurses++$USE_LIB_SUFFIX
3688                         else
3689                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
3690                         fi
3691                         if test -n "${USE_ARG_SUFFIX}" ; then
3692                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
3693                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
3694                         fi
3695
3696                         # These dependencies really are for development, not
3697                         # builds, but they are useful in porting, too.
3698                         cf_depend="../include/ncurses_cfg.h"
3699                         if test "$srcdir" = "."; then
3700                                 cf_reldir="."
3701                         else
3702                                 cf_reldir="\${srcdir}"
3703                         fi
3704
3705                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3706                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3707                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3708                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3709                         fi
3710
3711                         cf_dir_suffix=
3712                         old_cf_suffix="$cf_suffix"
3713                         if test "$cf_cv_shlib_version_infix" = yes ; then
3714                         if test -n "$USE_LIB_SUFFIX" ; then
3715                                 case $USE_LIB_SUFFIX in
3716                                 (tw*)
3717                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
3718                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
3719                                         cf_dir_suffix=tw$EXTRA_SUFFIX
3720                                         ;;
3721                                 (t*)
3722                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
3723                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
3724                                         cf_dir_suffix=t$EXTRA_SUFFIX
3725                                         ;;
3726                                 (w*)
3727                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
3728                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
3729                                         cf_dir_suffix=w$EXTRA_SUFFIX
3730                                         ;;
3731                                 (*)
3732                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
3733                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
3734                                         cf_dir_suffix=$EXTRA_SUFFIX
3735                                         ;;
3736                                 esac
3737                         fi
3738                         fi
3739
3740                         $AWK -f $srcdir/mk-1st.awk \
3741                                 name=${cf_libname}${cf_dir_suffix} \
3742                                 traces=$LIB_TRACING \
3743                                 MODEL=$cf_ITEM \
3744                                 CXX_MODEL=$CXX_MODEL \
3745                                 model=$cf_subdir \
3746                                 prefix=$cf_prefix \
3747                                 suffix=$cf_suffix \
3748                                 subset=$cf_subset \
3749                                 driver=$cf_cv_term_driver \
3750                                 SymLink="$LN_S" \
3751                                 TermlibRoot=$TINFO_NAME \
3752                                 TermlibSuffix=$TINFO_SUFFIX \
3753                                 ShlibVer=$cf_cv_shlib_version \
3754                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3755                                 ReLink=${cf_cv_do_relink:-no} \
3756                                 DoLinks=$cf_cv_do_symlinks \
3757                                 rmSoLocs=$cf_cv_rm_so_locs \
3758                                 ldconfig="$LDCONFIG" \
3759                                 overwrite=$WITH_OVERWRITE \
3760                                 depend="$cf_depend" \
3761                                 host="$host" \
3762                                 libtool_version="$LIBTOOL_VERSION" \
3763                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3764
3765                         cf_suffix="$old_cf_suffix"
3766
3767                         for cf_subdir2 in $cf_subdirs lib
3768                         do
3769                                 test $cf_subdir = $cf_subdir2 && break
3770                         done
3771                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3772                         $AWK -f $srcdir/mk-2nd.awk \
3773                                 name=$cf_dir \
3774                                 traces=$LIB_TRACING \
3775                                 MODEL=$cf_ITEM \
3776                                 model=$cf_subdir \
3777                                 subset=$cf_subset \
3778                                 srcdir=$srcdir \
3779                                 echo=$WITH_ECHO \
3780                                 crenames=$cf_cv_prog_CC_c_o \
3781                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3782                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3783                         cf_subdirs="$cf_subdirs $cf_subdir"
3784                         done
3785                 done
3786         fi
3787
3788         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3789 done
3790
3791 for cf_dir in $SRC_SUBDIRS
3792 do
3793         if test ! -d $srcdir/$cf_dir ; then
3794                 continue
3795         fi
3796
3797         if test -f $cf_dir/Makefile ; then
3798                 case "$cf_dir" in
3799                 (Ada95)
3800                         echo 'libs \' >> Makefile
3801                         echo 'install.libs \' >> Makefile
3802                         echo 'uninstall.libs ::' >> Makefile
3803                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3804                         ;;
3805                 esac
3806         fi
3807
3808         if test -f $srcdir/$cf_dir/modules; then
3809                 echo >> Makefile
3810                 if test -f $srcdir/$cf_dir/headers; then
3811 cat >> Makefile <<CF_EOF
3812 install.includes \\
3813 uninstall.includes \\
3814 CF_EOF
3815                 fi
3816 if test "$cf_dir" != "c++" ; then
3817 echo 'lint \' >> Makefile
3818 fi
3819 cat >> Makefile <<CF_EOF
3820 libs \\
3821 lintlib \\
3822 install.libs \\
3823 uninstall.libs \\
3824 install.$cf_dir \\
3825 uninstall.$cf_dir ::
3826         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3827 CF_EOF
3828         elif test -f $srcdir/$cf_dir/headers; then
3829 cat >> Makefile <<CF_EOF
3830
3831 libs \\
3832 install.libs \\
3833 uninstall.libs \\
3834 install.includes \\
3835 uninstall.includes ::
3836         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3837 CF_EOF
3838 fi
3839 done
3840
3841 if test "x$cf_with_db_install" = xyes; then
3842 cat >> Makefile <<CF_EOF
3843
3844 install.libs uninstall.libs \\
3845 install.data uninstall.data ::
3846 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3847 CF_EOF
3848 else
3849 cat >> Makefile <<CF_EOF
3850
3851 install.libs uninstall.libs ::
3852         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3853 CF_EOF
3854 fi
3855
3856 if test "x$cf_with_manpages" = xyes; then
3857 cat >> Makefile <<CF_EOF
3858
3859 install.man \\
3860 uninstall.man ::
3861         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3862 CF_EOF
3863 fi
3864
3865 cat >> Makefile <<CF_EOF
3866
3867 distclean ::
3868         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3869         rm -f headers.sh headers.sed mk_shared_lib.sh
3870         rm -f edit_man.* man_alias.*
3871         rm -rf \${DIRS_TO_MAKE}
3872 CF_EOF
3873
3874 # Special case: tack's manpage lives in its own directory.
3875 if test "x$cf_with_manpages" = xyes; then
3876 if test -d tack ; then
3877 if test -f $srcdir/$tack.h; then
3878 cat >> Makefile <<CF_EOF
3879
3880 install.man \\
3881 uninstall.man ::
3882         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3883 CF_EOF
3884 fi
3885 fi
3886 fi
3887
3888 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3889 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3890 dnl anything, and will make it more standardized.  It's awkward to decide this
3891 dnl at configuration because of quoting, so we'll simply make all headers
3892 dnl installed via a script that can do the right thing.
3893
3894 rm -f headers.sed headers.sh
3895
3896 dnl ( generating this script makes the makefiles a little tidier :-)
3897 echo creating headers.sh
3898 cat >headers.sh <<CF_EOF
3899 #! $SHELL
3900 # This shell script is generated by the 'configure' script.  It is invoked in a
3901 # subdirectory of the build tree.  It generates a sed-script in the parent
3902 # directory that is used to adjust includes for header files that reside in a
3903 # subdirectory of /usr/include, etc.
3904 PRG=""
3905 while test \[$]# != 3
3906 do
3907 PRG="\$PRG \[$]1"; shift
3908 done
3909 DST=\[$]1
3910 REF=\[$]2
3911 SRC=\[$]3
3912 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3913 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3914 echo installing \$SRC in \$DST
3915 CF_EOF
3916
3917 if test $WITH_CURSES_H = yes; then
3918         cat >>headers.sh <<CF_EOF
3919 case \$DST in
3920 (/*/include/*)
3921         END=\`basename \$DST\`
3922         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3923         do
3924                 NAME=\`basename \$i\`
3925                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3926         done
3927         ;;
3928 (*)
3929         echo "" >> \$TMPSED
3930         ;;
3931 esac
3932 CF_EOF
3933
3934 else
3935         cat >>headers.sh <<CF_EOF
3936 case \$DST in
3937 (/*/include/*)
3938         END=\`basename \$DST\`
3939         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3940         do
3941                 NAME=\`basename \$i\`
3942                 if test "\$NAME" = "curses.h"
3943                 then
3944                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3945                         NAME=ncurses.h
3946                 fi
3947                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3948         done
3949         ;;
3950 (*)
3951         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3952         ;;
3953 esac
3954 CF_EOF
3955 fi
3956 cat >>headers.sh <<CF_EOF
3957 rm -f \$TMPSRC
3958 sed -f \$TMPSED \$SRC > \$TMPSRC
3959 NAME=\`basename \$SRC\`
3960 CF_EOF
3961 if test $WITH_CURSES_H != yes; then
3962         cat >>headers.sh <<CF_EOF
3963 test "\$NAME" = "curses.h" && NAME=ncurses.h
3964 CF_EOF
3965 fi
3966 cat >>headers.sh <<CF_EOF
3967 # Just in case someone gzip'd manpages, remove the conflicting copy.
3968 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3969
3970 eval \$PRG \$TMPSRC \$DST/\$NAME
3971 rm -f \$TMPSRC \$TMPSED
3972 CF_EOF
3973
3974 chmod 0755 headers.sh
3975
3976 for cf_dir in $SRC_SUBDIRS
3977 do
3978         if test ! -d $srcdir/$cf_dir ; then
3979                 continue
3980         fi
3981
3982         if test -f $srcdir/$cf_dir/headers; then
3983                 $AWK -f $srcdir/mk-hdr.awk \
3984                         subset="$LIB_SUBSETS" \
3985                         compat="$WITH_CURSES_H" \
3986                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3987         fi
3988
3989         if test -f $srcdir/$cf_dir/modules; then
3990                 if test "$cf_dir" != "c++" ; then
3991                         cat >>$cf_dir/Makefile <<"CF_EOF"
3992 depend : ${AUTO_SRC}
3993         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3994
3995 # DO NOT DELETE THIS LINE -- make depend depends on it.
3996 CF_EOF
3997                 fi
3998         fi
3999 done
4000 AC_SUBST(Libs_To_Make)
4001 ])dnl
4002 dnl ---------------------------------------------------------------------------
4003 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
4004 dnl -------------
4005 dnl Find the and soname for the given shared library.  Set the cache variable
4006 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
4007 dnl variable to "unknown".
4008 dnl
4009 dnl $1 = headers
4010 dnl $2 = code
4011 dnl $3 = library name
4012 AC_DEFUN([CF_LIB_SONAME],
4013 [
4014 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
4015
4016 cf_cv_$3_soname=unknown
4017 if test "$cross_compiling" != yes ; then
4018 cat >conftest.$ac_ext <<CF_EOF
4019 $1
4020 int main()
4021 {
4022 $2
4023         ${cf_cv_main_return:-return}(0);
4024 }
4025 CF_EOF
4026 cf_save_LIBS="$LIBS"
4027         CF_ADD_LIB($3)
4028         if AC_TRY_EVAL(ac_compile) ; then
4029                 if AC_TRY_EVAL(ac_link) ; then
4030                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
4031                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4032                 fi
4033         fi
4034 rm -rf conftest*
4035 LIBS="$cf_save_LIBS"
4036 fi
4037 ])
4038 ])
4039 dnl ---------------------------------------------------------------------------
4040 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
4041 dnl -------------
4042 dnl Compute the library file-suffix from the given model name
4043 dnl $1 = model name
4044 dnl $2 = variable to set (the nominal library suffix)
4045 dnl $3 = dependency variable to set (actual filename)
4046 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4047 AC_DEFUN([CF_LIB_SUFFIX],
4048 [
4049         case X$1 in
4050         (Xlibtool)
4051                 $2='.la'
4052                 $3=[$]$2
4053                 ;;
4054         (Xdebug)
4055                 $2='_g.a'
4056                 $3=[$]$2
4057                 ;;
4058         (Xprofile)
4059                 $2='_p.a'
4060                 $3=[$]$2
4061                 ;;
4062         (Xshared)
4063                 case $cf_cv_system_name in
4064                 (aix[[5-7]]*)
4065                         $2='.so'
4066                         $3=[$]$2
4067                         ;;
4068                 (cygwin*|msys*|mingw*)
4069                         $2='.dll'
4070                         $3='.dll.a'
4071                         ;;
4072                 (darwin*)
4073                         $2='.dylib'
4074                         $3=[$]$2
4075                         ;;
4076                 (hpux*)
4077                         case $target in
4078                         (ia64*)
4079                                 $2='.so'
4080                                 $3=[$]$2
4081                                 ;;
4082                         (*)
4083                                 $2='.sl'
4084                                 $3=[$]$2
4085                                 ;;
4086                         esac
4087                         ;;
4088                 (*)
4089                         $2='.so'
4090                         $3=[$]$2
4091                         ;;
4092                 esac
4093                 ;;
4094         (*)
4095                 $2='.a'
4096                 $3=[$]$2
4097                 ;;
4098         esac
4099         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
4100         then
4101                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
4102                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
4103         fi
4104 ])dnl
4105 dnl ---------------------------------------------------------------------------
4106 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
4107 dnl -----------
4108 dnl Compute the string to append to -library from the given model name
4109 dnl $1 = model name
4110 dnl $2 = variable to set
4111 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4112 AC_DEFUN([CF_LIB_TYPE],
4113 [
4114         case $1 in
4115         (libtool) $2=''   ;;
4116         (normal)  $2=''   ;;
4117         (debug)   $2='_g' ;;
4118         (profile) $2='_p' ;;
4119         (shared)  $2=''   ;;
4120         esac
4121         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
4122 ])dnl
4123 dnl ---------------------------------------------------------------------------
4124 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
4125 dnl ----------------
4126 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
4127 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
4128 dnl have to provide wrappers for global tables to ensure they're linked
4129 dnl properly.
4130 AC_DEFUN([CF_LINK_DATAONLY],
4131 [
4132 AC_MSG_CHECKING([if data-only library module links])
4133 AC_CACHE_VAL(cf_cv_link_dataonly,[
4134         rm -f conftest.a
4135         cat >conftest.$ac_ext <<EOF
4136 #line __oline__ "configure"
4137 int     testdata[[3]] = { 123, 456, 789 };
4138 EOF
4139         if AC_TRY_EVAL(ac_compile) ; then
4140                 mv conftest.o data.o && \
4141                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
4142         fi
4143         rm -f conftest.$ac_ext data.o
4144         cat >conftest.$ac_ext <<EOF
4145 #line __oline__ "configure"
4146 int     testfunc()
4147 {
4148 #if defined(NeXT)
4149         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
4150 #else
4151         extern int testdata[[3]];
4152         return testdata[[0]] == 123
4153            &&  testdata[[1]] == 456
4154            &&  testdata[[2]] == 789;
4155 #endif
4156 }
4157 EOF
4158         if AC_TRY_EVAL(ac_compile); then
4159                 mv conftest.o func.o && \
4160                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
4161         fi
4162         rm -f conftest.$ac_ext func.o
4163         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
4164         cf_saveLIBS="$LIBS"
4165         LIBS="conftest.a $LIBS"
4166         AC_TRY_RUN([
4167         int main()
4168         {
4169                 extern int testfunc();
4170                 ${cf_cv_main_return:-return} (!testfunc());
4171         }
4172         ],
4173         [cf_cv_link_dataonly=yes],
4174         [cf_cv_link_dataonly=no],
4175         [cf_cv_link_dataonly=unknown])
4176         LIBS="$cf_saveLIBS"
4177         ])
4178 AC_MSG_RESULT($cf_cv_link_dataonly)
4179
4180 if test "$cf_cv_link_dataonly" = no ; then
4181         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
4182         BROKEN_LINKER=1
4183 fi
4184
4185 ])dnl
4186 dnl ---------------------------------------------------------------------------
4187 dnl CF_LINK_FUNCS version: 8 updated: 2012/10/06 17:56:13
4188 dnl -------------
4189 dnl Most Unix systems have both link and symlink, a few don't have symlink.
4190 dnl A few non-Unix systems implement symlink, but not link.
4191 dnl A few non-systems implement neither (or have nonfunctional versions).
4192 AC_DEFUN([CF_LINK_FUNCS],
4193 [
4194 AC_CHECK_FUNCS( \
4195         remove \
4196         unlink )
4197
4198 if test "$cross_compiling" = yes ; then
4199         AC_CHECK_FUNCS( \
4200                 link \
4201                 symlink )
4202 else
4203         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
4204                 cf_cv_link_funcs=
4205                 for cf_func in link symlink ; do
4206                         AC_TRY_RUN([
4207 #include <sys/types.h>
4208 #include <sys/stat.h>
4209 #ifdef HAVE_UNISTD_H
4210 #include <unistd.h>
4211 #endif
4212 int main()
4213 {
4214         int fail = 0;
4215         char *src = "config.log";
4216         char *dst = "conftest.chk";
4217         struct stat src_sb;
4218         struct stat dst_sb;
4219
4220         stat(src, &src_sb);
4221         fail = ($cf_func("config.log", "conftest.chk") < 0)
4222             || (stat(dst, &dst_sb) < 0)
4223             || (dst_sb.st_mtime != src_sb.st_mtime);
4224 #ifdef HAVE_UNLINK
4225         unlink(dst);
4226 #else
4227         remove(dst);
4228 #endif
4229         ${cf_cv_main_return:-return} (fail);
4230 }
4231                         ],[
4232                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
4233                         eval 'ac_cv_func_'$cf_func'=yes'],[
4234                         eval 'ac_cv_func_'$cf_func'=no'],[
4235                         eval 'ac_cv_func_'$cf_func'=error'])
4236                 done
4237                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
4238         ])
4239         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
4240         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
4241 fi
4242 ])dnl
4243 dnl ---------------------------------------------------------------------------
4244 dnl CF_MAKEFLAGS version: 17 updated: 2015/08/05 20:44:28
4245 dnl ------------
4246 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
4247 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
4248 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
4249 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
4250 AC_DEFUN([CF_MAKEFLAGS],
4251 [
4252 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
4253         cf_cv_makeflags=''
4254         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
4255         do
4256                 cat >cf_makeflags.tmp <<CF_EOF
4257 SHELL = $SHELL
4258 all :
4259         @ echo '.$cf_option'
4260 CF_EOF
4261                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
4262                 case "$cf_result" in
4263                 (.*k|.*kw)
4264                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
4265                         case "$cf_result" in
4266                         (.*CC=*)        cf_cv_makeflags=
4267                                 ;;
4268                         (*)     cf_cv_makeflags=$cf_option
4269                                 ;;
4270                         esac
4271                         break
4272                         ;;
4273                 (.-)    ;;
4274                 (*)     echo "given option \"$cf_option\", no match \"$cf_result\""
4275                         ;;
4276                 esac
4277         done
4278         rm -f cf_makeflags.tmp
4279 ])
4280
4281 AC_SUBST(cf_cv_makeflags)
4282 ])dnl
4283 dnl ---------------------------------------------------------------------------
4284 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
4285 dnl ------------
4286 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
4287 dnl a monocase filesystem.
4288 AC_DEFUN([CF_MAKE_TAGS],[
4289 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
4290
4291 AC_CHECK_PROGS(CTAGS, exctags ctags)
4292 AC_CHECK_PROGS(ETAGS, exetags etags)
4293
4294 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
4295
4296 if test "$cf_cv_mixedcase" = yes ; then
4297         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
4298 else
4299         MAKE_UPPER_TAGS=no
4300 fi
4301
4302 if test "$MAKE_UPPER_TAGS" = yes ; then
4303         MAKE_UPPER_TAGS=
4304 else
4305         MAKE_UPPER_TAGS="#"
4306 fi
4307
4308 if test "$MAKE_LOWER_TAGS" = yes ; then
4309         MAKE_LOWER_TAGS=
4310 else
4311         MAKE_LOWER_TAGS="#"
4312 fi
4313
4314 AC_SUBST(CTAGS)
4315 AC_SUBST(ETAGS)
4316
4317 AC_SUBST(MAKE_UPPER_TAGS)
4318 AC_SUBST(MAKE_LOWER_TAGS)
4319 ])dnl
4320 dnl ---------------------------------------------------------------------------
4321 dnl CF_MANPAGE_FORMAT version: 11 updated: 2015/04/18 08:56:57
4322 dnl -----------------
4323 dnl Option to allow user to override automatic configuration of manpage format.
4324 dnl There are several special cases:
4325 dnl
4326 dnl     gzip - man checks for, can display gzip'd files
4327 dnl     compress - man checks for, can display compressed files
4328 dnl     BSDI - files in the cat-directories are suffixed ".0"
4329 dnl     formatted - installer should format (put files in cat-directory)
4330 dnl     catonly - installer should only format, e.g., for a turnkey system.
4331 dnl
4332 dnl There are other configurations which this macro does not test, e.g., HPUX's
4333 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
4334 dnl convention would not match our use).
4335 AC_DEFUN([CF_MANPAGE_FORMAT],
4336 [
4337 AC_REQUIRE([CF_PATHSEP])
4338 AC_MSG_CHECKING(format of man-pages)
4339
4340 AC_ARG_WITH(manpage-format,
4341         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
4342                           optionally formatted/catonly, e.g., gzip,formatted],
4343         [MANPAGE_FORMAT=$withval],
4344         [MANPAGE_FORMAT=unknown])
4345
4346 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
4347 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
4348
4349 cf_unknown=
4350