ncurses 6.1 - patch 20190518
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2018,2019 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.679 2019/03/30 21:44:53 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See https://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.52.20170501)
38 AC_REVISION($Revision: 1.679 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44 CF_VERSION_INFO(NCURSES,ncurses)
45
46 CF_WITH_REL_VERSION(NCURSES)
47 CF_NCURSES_WITH_ABI_VERSION
48
49 CF_WITH_SYSTYPE
50
51 ###     Save the given $CFLAGS to allow user-override.
52 cf_user_CFLAGS="$CFLAGS"
53
54 ###     Default install-location
55 CF_CFG_DEFAULTS
56 ### Defaults for ncurses ABI
57 CF_ABI_DEFAULTS
58
59 ###     Checks for programs.
60 AC_ARG_WITH(ada,
61         [  --without-ada           suppress check for Ada95, don't build demo],
62         [cf_with_ada=$withval],
63         [cf_with_ada=yes])
64
65 if test "x$cf_with_ada" = xyes
66 then
67         cf_prog_cc="gnatgcc gcc cc"
68 else
69         cf_prog_cc="gcc cc"
70 fi
71 CF_PROG_CC($cf_prog_cc)
72
73 AC_PROG_CPP
74 AC_PROG_GCC_TRADITIONAL
75 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
76 CF_PROG_LDCONFIG
77
78 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
79 dnl                             configure script by not letting us test if C++
80 dnl                             is present, making this option necessary.
81 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
82 AC_ARG_WITH(cxx,
83         [  --without-cxx           do not adjust ncurses bool to match C++],
84         [cf_with_cxx=$withval],
85         [cf_with_cxx=yes])
86 AC_MSG_RESULT($cf_with_cxx)
87 if test "X$cf_with_cxx" = Xno ; then
88         CXX=""
89         GXX=""
90 else
91         # with autoconf 2.13, we can change the error to a warning:
92         pushdef([AC_MSG_ERROR],
93                 [AC_MSG_RESULT(no)
94                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
95                 cf_with_cxx=no; CXX=""; GXX="";])dnl
96         AC_PROG_CXX
97         popdef([AC_MSG_ERROR])dnl
98
99         AC_LANG_PUSH(C++)
100         if test "x$cf_with_cxx" != xno
101         then
102                 # Several of the C++ configurations do not work, particularly when
103                 # cross-compiling (20140913 -TD)
104                 AC_MSG_CHECKING(if $CXX works)
105
106                 save_CPPFLAGS="$CPPFLAGS"
107                 eval cf_includedir=${includedir}
108                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
109                 AC_TRY_COMPILE([
110 #include <stdlib.h>
111 #include <stdio.h>
112 ],
113                 [
114                 printf("Hello world!\n")
115                 ],
116                 [cf_cxx_works=yes],
117                 [cf_cxx_works=no])
118                 CPPFLAGS="$save_CPPFLAGS"
119
120                 AC_MSG_RESULT($cf_cxx_works)
121                 if test "x$cf_cxx_works" = xno
122                 then
123                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
124                         cf_with_cxx=no; CXX=""; GXX="";
125                 fi
126         fi
127         AC_LANG_POP
128
129         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
130         if test "$CXX" = "g++" ; then
131                 AC_PATH_PROG(CXX,g++)
132         fi
133         case "x$CXX" in
134         (x|xg++)
135                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
136                 cf_with_cxx=no; CXX=""; GXX="";
137                 ;;
138         esac
139 fi
140
141 CF_GXX_VERSION
142 case $GXX_VERSION in
143 (1*|2.[[0-6]]*)
144         # GXX=""; CXX=""; ac_cv_prog_gxx=no
145         # cf_cxx_library=no
146         AC_MSG_WARN(templates do not work)
147         ;;
148 esac
149
150 AC_MSG_CHECKING(if you want to build C++ binding and demo)
151 AC_ARG_WITH(cxx-binding,
152         [  --without-cxx-binding   do not build C++ binding and demo],
153         [cf_with_cxx_binding=$withval],
154         [cf_with_cxx_binding=$cf_with_cxx])
155 AC_MSG_RESULT($cf_with_cxx_binding)
156
157 AC_MSG_CHECKING(if you want to build with Ada95)
158 AC_MSG_RESULT($cf_with_ada)
159
160 AC_MSG_CHECKING(if you want to install terminal database)
161 AC_ARG_ENABLE(db-install,
162         [  --disable-db-install    suppress install of terminal database],
163         [cf_with_db_install=$enableval],
164         [cf_with_db_install=yes])
165 AC_MSG_RESULT($cf_with_db_install)
166
167 AC_MSG_CHECKING(if you want to install manpages)
168 AC_ARG_WITH(manpages,
169         [  --without-manpages      suppress install of manpages],
170         [cf_with_manpages=$withval],
171         [cf_with_manpages=yes])
172 AC_MSG_RESULT($cf_with_manpages)
173
174 AC_MSG_CHECKING(if you want to build programs such as tic)
175 AC_ARG_WITH(progs,
176         [  --without-progs         suppress build/install with programs (e.g., tic)],
177         [cf_with_progs=$withval],
178         [cf_with_progs=yes])
179 AC_MSG_RESULT($cf_with_progs)
180
181 if test -f $srcdir/tack/tack.h; then
182         if test "x$cross_compiling" = xyes ; then
183                 CF_VERBOSE(ignoring tack because we are cross-compiling)
184                 cf_with_tack=no
185         else
186                 AC_MSG_CHECKING(if you want to build the tack program)
187                 AC_ARG_WITH(tack,
188                         [  --without-tack          suppress build/install with tack program],
189                         [cf_with_tack=$withval],
190                         [cf_with_tack=$cf_with_progs])
191                 AC_MSG_RESULT($cf_with_tack)
192         fi
193 else
194         cf_with_tack=no
195 fi
196
197 AC_MSG_CHECKING(if you want to build test-programs)
198 AC_ARG_WITH(tests,
199         [  --without-tests         suppress build/install with test-programs],
200         [cf_with_tests=$withval],
201         [cf_with_tests=yes])
202 AC_MSG_RESULT($cf_with_tests)
203
204 AC_MSG_CHECKING(if you wish to install curses.h)
205 AC_ARG_WITH(curses-h,
206         [  --without-curses-h      install curses.h as ncurses.h only],
207         [with_curses_h=$withval],
208         [with_curses_h=yes])
209 AC_MSG_RESULT($with_curses_h)
210
211 modules_to_build="ncurses"
212 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
213 test "X$cf_with_tack"  != Xno && modules_to_build="$modules_to_build tack"
214 modules_to_build="$modules_to_build panel menu form"
215
216 AC_ARG_PROGRAM
217
218 CF_PROG_AWK
219 CF_PROG_EGREP
220 CF_PROG_INSTALL
221 CF_PROG_LINT
222 CF_PROG_LN_S
223
224 AC_SYS_LONG_FILE_NAMES
225
226 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
227 # of package conflict.
228 cf_config_suffix=
229 AC_ARG_WITH(config-suffix,
230         [  --with-config-suffix=X  suffixes ncursesXX-config file],
231         [case "x$withval" in
232         (xyes|xno)
233                 AC_MSG_WARN(expected a value for config-suffix option)
234                 ;;
235         (*)     cf_config_suffix="$withval"
236                 ;;
237         esac])
238 AC_SUBST(cf_config_suffix)
239
240 # If we find pkg-config, check if we should install the ".pc" files.
241 CF_PKG_CONFIG
242 CF_WITH_PKG_CONFIG_LIBDIR
243 CF_ENABLE_PC_FILES
244 if test -z "$MAKE_PC_FILES"
245 then
246         AC_MSG_CHECKING(for suffix to add to pc-files)
247 AC_ARG_WITH(pc-suffix,
248         [  --with-pc-suffix        suffixes pc-files],
249         [case "x$withval" in
250         (xyes|xno)
251                 PC_MODULE_SUFFIX=
252                 ;;
253         (*)     PC_MODULE_SUFFIX="$withval"
254                 ;;
255         esac])
256         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
257         AC_MSG_RESULT($PC_MODULE_SUFFIX)
258         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
259         AC_SUBST(PC_MODULE_SUFFIX)
260 fi
261
262 AC_MSG_CHECKING(if we should assume mixed-case filenames)
263 AC_ARG_ENABLE(mixed-case,
264         [  --enable-mixed-case     tic should assume mixed-case filenames],
265         [enable_mixedcase=$enableval],
266         [enable_mixedcase=auto])
267 AC_MSG_RESULT($enable_mixedcase)
268 if test "$enable_mixedcase" = "auto" ; then
269         CF_MIXEDCASE_FILENAMES
270 else
271         cf_cv_mixedcase=$enable_mixedcase
272         if test "x$enable_mixedcase" = "xyes" ; then
273                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
274         fi
275 fi
276
277 # do this after mixed-case option (tags/TAGS is not as important as tic).
278 AC_PROG_MAKE_SET
279 CF_MAKE_TAGS
280 CF_MAKEFLAGS
281
282 dnl These are standard among *NIX systems, but not when cross-compiling
283 AC_CHECK_TOOL(RANLIB, ranlib, ':')
284 AC_CHECK_TOOL(LD, ld, ld)
285 AC_CHECK_TOOL(AR, ar, ar)
286 AC_CHECK_TOOL(NM, nm, nm)
287 CF_AR_FLAGS
288
289 dnl Special option for use by system-builders: the install-prefix is used to
290 dnl adjust the location into which the actual install is done, so that an
291 dnl archive can be built without modifying the host system's configuration.
292 AC_MSG_CHECKING(if you have specified an install-prefix)
293 AC_ARG_WITH(install-prefix,
294         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
295         [case "x$withval" in
296         (xyes|xno)
297                 ;;
298         (*)     DESTDIR="$withval"
299                 ;;
300         esac])
301 AC_MSG_RESULT($DESTDIR)
302 AC_SUBST(DESTDIR)
303
304 ###############################################################################
305 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
306 # If we're cross-compiling, allow the user to override the tools and their
307 # options.  The configure script is oriented toward identifying the host
308 # compiler, etc., but we need a build compiler to generate parts of the source.
309 CF_BUILD_CC
310
311 ###############################################################################
312 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
313
314 ### Options to allow the user to specify the set of libraries which are used.
315 ### Use "--without-normal --with-shared" to allow the default model to be
316 ### shared, for example.
317 cf_list_models=""
318 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
319
320 CF_WITH_LIBTOOL
321 if test "$with_libtool" != "no" ; then
322
323 cf_list_models="$cf_list_models libtool"
324
325 else
326
327 AC_MSG_CHECKING(if you want to build shared libraries)
328 AC_ARG_WITH(shared,
329         [  --with-shared           generate shared-libraries],
330         [with_shared=$withval],
331         [with_shared=no])
332 AC_MSG_RESULT($with_shared)
333 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
334
335 AC_MSG_CHECKING(if you want to build static libraries)
336 AC_ARG_WITH(normal,
337         [  --with-normal           generate normal-libraries (default)],
338         [with_normal=$withval],
339         [with_normal=yes])
340 AC_MSG_RESULT($with_normal)
341 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
342
343 AC_MSG_CHECKING(if you want to build debug libraries)
344 AC_ARG_WITH(debug,
345         [  --with-debug            generate debug-libraries (default)],
346         [with_debug=$withval],
347         [with_debug=yes])
348 AC_MSG_RESULT($with_debug)
349 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
350
351 AC_MSG_CHECKING(if you want to build profiling libraries)
352 AC_ARG_WITH(profile,
353         [  --with-profile          generate profile-libraries],
354         [with_profile=$withval],
355         [with_profile=no])
356 AC_MSG_RESULT($with_profile)
357 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
358
359 fi
360
361 if test "X$cf_with_cxx_binding" != Xno; then
362 if test "x$with_shared" = "xyes"; then
363 AC_MSG_CHECKING(if you want to build C++ shared libraries)
364 AC_ARG_WITH(cxx-shared,
365         [  --with-cxx-shared       generate C++ shared-libraries],
366         [with_shared_cxx=$withval],
367         [with_shared_cxx=no])
368 AC_MSG_RESULT($with_shared_cxx)
369 fi
370 fi
371
372 ###############################################################################
373
374 AC_MSG_CHECKING(for specified models)
375 test -z "$cf_list_models" && cf_list_models=normal
376 dnl If we use libtool to generate libraries, then it must be the only
377 dnl specified model.
378 test "$with_libtool" != "no" && cf_list_models=libtool
379 AC_MSG_RESULT($cf_list_models)
380
381 ### Use the first model as the default, and save its suffix for use in building
382 ### up test-applications.
383 AC_MSG_CHECKING(for default model)
384 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
385 AC_MSG_RESULT($DFT_LWR_MODEL)
386
387 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
388
389 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
390 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
391
392 TICS_NAME=tic
393 AC_SUBST(TICS_NAME)
394
395 TINFO_NAME=tinfo
396 AC_SUBST(TINFO_NAME)
397
398 LIB_NAME=ncurses
399 AC_SUBST(LIB_NAME)
400
401 LIB_DIR=../lib
402 LIB_2ND=../../lib
403
404 CF_WITH_LIB_PREFIX(cf_prefix)
405
406 LIB_SUFFIX=
407 AC_SUBST(LIB_SUFFIX)
408 CF_PATHSEP
409
410 ###############################################################################
411
412 AC_MSG_CHECKING(if you want to build a separate terminfo library)
413 AC_ARG_WITH(termlib,
414         [  --with-termlib          generate separate terminfo library],
415         [with_termlib=$withval],
416         [with_termlib=no])
417 AC_MSG_RESULT($with_termlib)
418
419 AC_MSG_CHECKING(if you want to build a separate tic library)
420 AC_ARG_WITH(ticlib,
421         [  --with-ticlib           generate separate tic library],
422         [with_ticlib=$withval],
423         [with_ticlib=no])
424 AC_MSG_RESULT($with_ticlib)
425
426 dnl Not all ports of gcc support the -g option
427
428 if test X"$CC_G_OPT" = X"" ; then
429         CC_G_OPT='-g'
430         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
431 fi
432 AC_SUBST(CC_G_OPT)
433
434 if test X"$CXX_G_OPT" = X"" ; then
435         CXX_G_OPT='-g'
436         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
437 fi
438 AC_SUBST(CXX_G_OPT)
439
440 AC_MSG_CHECKING(for default loader flags)
441 case $DFT_LWR_MODEL in
442 (libtool) LD_MODEL=''   ;;
443 (normal)  LD_MODEL=''   ;;
444 (debug)   LD_MODEL=$CC_G_OPT ;;
445 (profile) LD_MODEL='-pg';;
446 (shared)  LD_MODEL=''   ;;
447 esac
448 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
449 AC_MSG_RESULT($LD_MODEL)
450
451 case $DFT_LWR_MODEL in
452 (shared)
453 CF_ENABLE_RPATH
454 AC_MSG_CHECKING(if shared libraries should be relinked during install)
455 AC_ARG_ENABLE(relink,
456 [  --disable-relink        relink shared libraries during install],
457 [cf_cv_do_relink=$enableval],
458 [cf_cv_do_relink=yes])
459 AC_MSG_RESULT($cf_cv_do_relink)
460         ;;
461 esac
462
463 # we will build libraries one-level down.
464 rel_builddir=..
465 CF_SHARED_OPTS
466 for model in $cf_list_models; do
467         case $model in
468         (libtool)
469                 CF_WITH_LIBTOOL_OPTS
470                 CF_WITH_EXPORT_SYMS
471                 ;;
472         (shared)
473                 if test "$CC_SHARED_OPTS" = "unknown"; then
474                         AC_ERROR(Shared libraries are not supported in this version)
475                 fi
476                 # workaround for inept transition to PIE vs PIC...
477                 AC_MSG_CHECKING(if current CFLAGS link properly)
478                 AC_TRY_LINK(
479                         [#include <stdio.h>],
480                         [printf("Hello work\n");],
481                         [cf_cflags_work=yes],
482                         [cf_cflags_work=no])
483                 AC_MSG_RESULT($cf_cflags_work)
484                 if test "$cf_cflags_work" = no
485                 then
486                         CF_VERBOSE(try to work around by appending shared-options)
487                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
488                 fi
489                 CF_WITH_VERSIONED_SYMS
490                 ;;
491         esac
492 done
493
494 ### Checks for special libraries, must be done up-front.
495 SHLIB_LIST=""
496 CF_WITH_GPM
497 if test "$with_gpm" != no ; then
498         AC_MSG_CHECKING(if you want to load GPM dynamically)
499         AC_ARG_WITH(dlsym,
500                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
501                 [with_dlsym=$withval],
502                 [with_dlsym=yes])
503         AC_MSG_RESULT($with_dlsym)
504         if test "x$with_dlsym" = xyes ; then
505                 CF_FUNC_DLSYM
506                 if test "x$with_gpm" != xyes ; then
507                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
508                         cf_cv_gpm_soname="$with_gpm"
509                 else
510                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
511                 fi
512                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
513                 SHLIB_LIST="-ldl $SHLIB_LIST"
514                 CF_ADD_LIB(dl,PRIVATE_LIBS)
515         else
516                 SHLIB_LIST="-lgpm $SHLIB_LIST"
517                 CF_ADD_LIB(gpm,TEST_LIBS)
518                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
519         fi
520         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
521         CF_CHECK_GPM_WGETCH
522 fi
523
524 CF_WITH_PCRE2
525 CF_WITH_SYSMOUSE
526
527 # pretend that ncurses==ncursesw==ncursest
528 AC_MSG_CHECKING(if you want to disable library suffixes)
529 CF_ARG_DISABLE(lib-suffixes,
530         [  --disable-lib-suffixes  disable library suffixes],
531         [disable_lib_suffixes=yes],
532         [disable_lib_suffixes=no],
533         no)
534 AC_MSG_RESULT($disable_lib_suffixes)
535
536 ### If we're building with rpath, try to link non-standard libs that way too.
537 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
538         CF_DISABLE_RPATH_HACK
539 fi
540
541 ###############################################################################
542 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
543
544 ###     use option --with-extra-suffix to append suffix to headers and libraries
545 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
546 EXTRA_SUFFIX=
547 AC_ARG_WITH(extra-suffix,
548         [  --with-extra-suffix=X   append extra suffix to header/library paths],
549         [case x$withval in
550         (no)
551                 ;;
552         (xyes|x)
553                 EXTRA_SUFFIX=$cf_cv_abi_version
554                 ;;
555         (*)
556                 EXTRA_SUFFIX=$withval
557                 ;;
558         esac
559         ])
560 AC_MSG_RESULT($EXTRA_SUFFIX)
561 AC_SUBST(EXTRA_SUFFIX)
562
563 ###     use option --disable-overwrite to leave out the link to -lcurses
564 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
565 AC_ARG_ENABLE(overwrite,
566         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
567         [with_overwrite=$enableval],
568         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
569 AC_MSG_RESULT($with_overwrite)
570
571 AC_MSG_CHECKING(if external terminfo-database is used)
572 AC_ARG_ENABLE(database,
573         [  --disable-database      do not use terminfo, only fallbacks/termcap],
574         [use_database=$enableval],
575         [use_database=yes])
576 AC_MSG_RESULT($use_database)
577
578 case $host_os in
579 (os2*)
580         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
581         ;;
582 (*)
583         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
584         ;;
585 esac
586 AC_SUBST(TERMINFO_SRC)
587
588 NCURSES_USE_DATABASE=0
589 if test "$use_database" != no ; then
590         NCURSES_USE_DATABASE=1
591
592         AC_MSG_CHECKING(which terminfo source-file will be installed)
593         AC_ARG_WITH(database,
594                 [  --with-database=XXX     specify terminfo source to install],
595                 [TERMINFO_SRC=$withval])
596         AC_MSG_RESULT($TERMINFO_SRC)
597
598         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
599         AC_ARG_WITH(hashed-db,
600                 [  --with-hashed-db        specify hashed-database library],,
601                 [with_hashed_db=no])
602         AC_MSG_RESULT($with_hashed_db)
603 else
604         with_hashed_db=no
605 fi
606 AC_SUBST(NCURSES_USE_DATABASE)
607
608 AC_MSG_CHECKING(for list of fallback descriptions)
609 AC_ARG_WITH(fallbacks,
610         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
611         [with_fallback=$withval],
612         [with_fallback=])
613 AC_MSG_RESULT($with_fallback)
614
615 case ".$with_fallback" in
616 (.|.no)
617         FALLBACK_LIST=
618         ;;
619 (.yes)
620         AC_MSG_WARN(expected a list of terminal descriptions)
621         ;;
622 (*)
623         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
624         ;;
625 esac
626
627 USE_FALLBACKS=
628 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
629 AC_SUBST(FALLBACK_LIST)
630 AC_SUBST(USE_FALLBACKS)
631
632 AC_MSG_CHECKING(if you want modern xterm or antique)
633 AC_ARG_WITH(xterm-new,
634         [  --without-xterm-new     specify if xterm terminfo should be old version],
635         [with_xterm_new=$withval],
636         [with_xterm_new=yes])
637 case $with_xterm_new in
638 (no) with_xterm_new=xterm-old;;
639 (*)      with_xterm_new=xterm-new;;
640 esac
641 AC_MSG_RESULT($with_xterm_new)
642 WHICH_XTERM=$with_xterm_new
643 AC_SUBST(WHICH_XTERM)
644
645 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
646 AC_ARG_WITH(xterm-kbs,
647         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
648         [with_xterm_kbs=$withval],
649         [with_xterm_kbs=BS])
650 case x$with_xterm_kbs in
651 (xyes|xno|xBS|xbs|x8)
652         with_xterm_kbs=BS
653         ;;
654 (xDEL|xdel|x127)
655         with_xterm_kbs=DEL
656         ;;
657 (*)
658         with_xterm_kbs=$withval
659         ;;
660 esac
661 AC_MSG_RESULT($with_xterm_kbs)
662 XTERM_KBS=$with_xterm_kbs
663 AC_SUBST(XTERM_KBS)
664
665 MAKE_TERMINFO=
666 if test "$use_database" = no ; then
667         TERMINFO="${datadir}/terminfo"
668         MAKE_TERMINFO="#"
669 else
670
671 AC_MSG_CHECKING(for list of terminfo directories)
672 CF_WITH_PATHLIST(terminfo-dirs,
673         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
674         TERMINFO_DIRS,
675         DATADIR/terminfo,
676         ${datadir}/terminfo)
677 AC_MSG_RESULT($TERMINFO_DIRS)
678 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
679
680 case "x$TERMINFO" in
681 x???:*)
682         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
683         unset TERMINFO
684         ;;
685 esac
686
687 AC_MSG_CHECKING(for default terminfo directory)
688 CF_WITH_PATH(default-terminfo-dir,
689         [  --with-default-terminfo-dir=DIR default terminfo directory],
690         TERMINFO,
691         DATADIR/terminfo,
692         ${datadir}/terminfo)
693 AC_MSG_RESULT($TERMINFO)
694 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
695
696 fi
697
698 AC_SUBST(TERMINFO)
699 AC_SUBST(MAKE_TERMINFO)
700
701 ###     use option --disable-big-core to make tic run on small machines
702 ###     We need 4Mb, check if we can allocate 50% more than that.
703 AC_MSG_CHECKING(if big-core option selected)
704 AC_ARG_ENABLE(big-core,
705         [  --disable-big-core      assume machine has little memory],
706         [with_big_core=$enableval],
707         [AC_TRY_RUN([
708 #include <stdlib.h>
709 #include <string.h>
710 int main() {
711         unsigned long n = 6000000L;
712         char *s = malloc(n);
713         if (s != 0)
714                 s[0] = s[n-1] = 0;
715         ${cf_cv_main_return:-return}(s == 0);
716 }],
717         [with_big_core=yes],
718         [with_big_core=no],
719         [with_big_core=no])])
720 AC_MSG_RESULT($with_big_core)
721 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
722
723 ### ISO C only guarantees 512-char strings, we have tables which load faster
724 ### when constructed using "big" strings.  More than the C compiler, the awk
725 ### program is a limit on most vendor UNIX systems.  Check that we can build.
726 AC_MSG_CHECKING(if big-strings option selected)
727 AC_ARG_ENABLE(big-strings,
728         [  --disable-big-strings   assume compiler has only standard-size strings],
729         [with_big_strings=$enableval],
730         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
731 AC_MSG_RESULT($with_big_strings)
732
733 USE_BIG_STRINGS=0
734 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
735 AC_SUBST(USE_BIG_STRINGS)
736
737 ###     use option --enable-termcap to compile in the termcap fallback support
738 AC_MSG_CHECKING(if you want termcap-fallback support)
739 AC_ARG_ENABLE(termcap,
740         [  --enable-termcap        compile in termcap fallback support],
741         [with_termcap=$enableval],
742         [with_termcap=no])
743 AC_MSG_RESULT($with_termcap)
744
745 NCURSES_USE_TERMCAP=0
746 if test "x$with_termcap" != "xyes" ; then
747         if test "$use_database" = no ; then
748                 if test -z "$with_fallback" ; then
749                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
750                 fi
751         fi
752         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
753 else
754
755         if test "$with_ticlib" != no ; then
756                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
757         fi
758
759         NCURSES_USE_TERMCAP=1
760         AC_MSG_CHECKING(for list of termcap files)
761         CF_WITH_PATHLIST(termpath,
762                 [  --with-termpath=XXX     specify list of termcap files],
763                 TERMPATH,
764                 /etc/termcap:/usr/share/misc/termcap)
765         AC_MSG_RESULT($TERMPATH)
766         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
767
768         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
769         AC_MSG_CHECKING(if fast termcap-loader is needed)
770         AC_ARG_ENABLE(getcap,
771                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
772                 [with_getcap=$enableval],
773                 [with_getcap=no])
774         AC_MSG_RESULT($with_getcap)
775         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
776
777         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
778         AC_ARG_ENABLE(getcap-cache,
779                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
780                 [with_getcap_cache=$enableval],
781                 [with_getcap_cache=no])
782         AC_MSG_RESULT($with_getcap_cache)
783         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
784
785 fi
786 AC_SUBST(NCURSES_USE_TERMCAP)
787
788 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
789 AC_MSG_CHECKING(if ~/.terminfo is wanted)
790 AC_ARG_ENABLE(home-terminfo,
791         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
792         [with_home_terminfo=$enableval],
793         [with_home_terminfo=yes])
794 AC_MSG_RESULT($with_home_terminfo)
795 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
796
797 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
798 AC_ARG_ENABLE(root-environ,
799         [  --disable-root-environ  restrict environment when running as root],
800         [with_root_environ=$enableval],
801         [with_root_environ=yes])
802 AC_MSG_RESULT($with_root_environ)
803 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
804
805 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
806 ###   to reduce storage requirements for the terminfo database.
807 CF_LINK_FUNCS
808
809 with_links=no
810 with_symlinks=no
811
812 # soft links (symbolic links) are useful for some systems where hard links do
813 # not work, or to make it simpler to copy terminfo trees around.
814 if test "x$ac_cv_func_symlink" = xyes ; then
815         AC_MSG_CHECKING(if tic should use symbolic links)
816         AC_ARG_ENABLE(symlinks,
817         [  --enable-symlinks       make tic use symbolic links not hard links],
818         [with_symlinks=$enableval],
819         [with_symlinks=no])
820         AC_MSG_RESULT($with_symlinks)
821 fi
822
823 # If we have hard links and did not choose to use soft links instead, there is
824 # no reason to make this choice optional - use the hard links.
825 if test "$with_symlinks" = no ; then
826         AC_MSG_CHECKING(if tic should use hard links)
827         if test "x$ac_cv_func_link" = xyes ; then
828                 with_links=yes
829         else
830                 with_links=no
831         fi
832         AC_MSG_RESULT($with_links)
833 fi
834
835 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
836 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
837
838 ###   use option --enable-broken-linker to force on use of broken-linker support
839 AC_MSG_CHECKING(if you want broken-linker support code)
840 AC_ARG_ENABLE(broken_linker,
841         [  --enable-broken_linker  compile with broken-linker support code],
842         [with_broken_linker=$enableval],
843         [with_broken_linker=${BROKEN_LINKER:-no}])
844 AC_MSG_RESULT($with_broken_linker)
845
846 BROKEN_LINKER=0
847 if test "x$with_broken_linker" = xyes ; then
848         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
849         BROKEN_LINKER=1
850 elif test "$DFT_LWR_MODEL" = shared ; then
851         case $cf_cv_system_name in
852         (cygwin*)
853                 AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
854                 BROKEN_LINKER=1
855                 CF_VERBOSE(cygwin linker is broken anyway)
856                 ;;
857         esac
858 fi
859 AC_SUBST(BROKEN_LINKER)
860
861 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
862 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
863 AC_ARG_ENABLE(bsdpad,
864         [  --enable-bsdpad         recognize BSD-style prefix padding],
865         [with_bsdpad=$enableval],
866         [with_bsdpad=no])
867 AC_MSG_RESULT($with_bsdpad)
868 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
869
870 ###   use option --enable-widec to turn on use of wide-character support
871 NCURSES_CH_T=chtype
872 NCURSES_LIBUTF8=0
873
874 NEED_WCHAR_H=0
875 NCURSES_MBSTATE_T=0
876 NCURSES_WCHAR_T=0
877 NCURSES_WINT_T=0
878
879 # Check to define _XOPEN_SOURCE "automatically"
880 CPPFLAGS_before_XOPEN="$CPPFLAGS"
881 CF_XOPEN_SOURCE(600)
882 CPPFLAGS_after_XOPEN="$CPPFLAGS"
883
884 # Work around breakage on OS X
885 CF_SIGWINCH
886
887 # Checks for CODESET support.
888 AM_LANGINFO_CODESET
889
890 # use these variables to work around a defect in gcc's fixincludes.
891 NCURSES_OK_WCHAR_T=
892 NCURSES_OK_WINT_T=
893
894 AC_MSG_CHECKING(if you want wide-character code)
895 AC_ARG_ENABLE(widec,
896         [  --enable-widec          compile with wide-char/UTF-8 code],
897         [with_widec=$enableval],
898         [with_widec=no])
899 AC_MSG_RESULT($with_widec)
900
901 NCURSES_WCWIDTH_GRAPHICS=1
902 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
903
904 if test "x$with_widec" = xyes ; then
905         if test "x$disable_lib_suffixes" = xno ; then
906                 LIB_SUFFIX="w${LIB_SUFFIX}"
907         fi
908         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
909         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
910
911         CF_CHECK_WCHAR_H
912         CF_CHECK_WCWIDTH_GRAPHICS
913         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
914
915         # with_overwrite=no
916         NCURSES_CH_T=cchar_t
917         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
918         if test "x$ac_cv_func_putwc" != xyes ; then
919                 CF_UTF8_LIB
920                 if test "$cf_cv_utf8_lib" != no ; then
921                         NCURSES_LIBUTF8=1
922                 fi
923         fi
924         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
925         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
926         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
927
928         if test "$NCURSES_MBSTATE_T" != 0; then
929                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
930         fi
931 fi
932 AC_SUBST(NCURSES_CH_T)
933 AC_SUBST(NCURSES_LIBUTF8)
934
935 AC_SUBST(NEED_WCHAR_H)
936 AC_SUBST(NCURSES_MBSTATE_T)
937 AC_SUBST(NCURSES_WCHAR_T)
938 AC_SUBST(NCURSES_WINT_T)
939
940 AC_SUBST(NCURSES_OK_WCHAR_T)
941 AC_SUBST(NCURSES_OK_WINT_T)
942
943 ###   use option --disable-lp64 to allow long chtype
944 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
945 AC_ARG_ENABLE(lp64,
946         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
947         [with_lp64=$enableval],
948         [with_lp64=$cf_dft_with_lp64])
949 AC_MSG_RESULT($with_lp64)
950
951 if test "x$with_lp64" = xyes ; then
952         cf_cv_enable_lp64=1
953 else
954         cf_cv_enable_lp64=0
955 fi
956 AC_SUBST(cf_cv_enable_lp64)
957
958 CF_LARGEFILE
959
960 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
961 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
962 AC_ARG_ENABLE(tparm-varargs,
963         [  --disable-tparm-varargs compile tparm() without varargs interface],
964         [with_tparm_varargs=$enableval],
965         [with_tparm_varargs=yes])
966 AC_MSG_RESULT($with_tparm_varargs)
967 NCURSES_TPARM_VARARGS=0
968 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
969 AC_SUBST(NCURSES_TPARM_VARARGS)
970
971 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
972 if test "$with_ticlib" != no ; then
973 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
974 AC_ARG_ENABLE(tic-depends,
975         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
976         [with_tic_depends=$enableval],
977         [with_tic_depends=yes])
978 AC_MSG_RESULT($with_tic_depends)
979 else
980         with_tic_depends=no
981 fi
982
983 ###   use option --disable-wattr-macros to suppress wattr* macros from curses.h
984 AC_MSG_CHECKING(if you want to suppress wattr* macros to help with ncurses5/ncurses6 transition)
985 AC_ARG_ENABLE(wattr-macros,
986         [  --disable-wattr-macros  suppress wattr* macros to help with ncurses5/ncurses6 transition],
987         [with_wattr_macros=$enableval],
988         [with_wattr_macros=yes])
989 if [[ "x$with_wattr_macros" != xyes ]]; then
990         NCURSES_WATTR_MACROS=0
991         AC_MSG_RESULT(yes)
992 else
993         NCURSES_WATTR_MACROS=1
994         AC_MSG_RESULT(no)
995 fi
996 AC_SUBST(NCURSES_WATTR_MACROS)
997
998 CF_WITH_X11_RGB
999
1000 ###   use option --with-bool to override bool's type
1001 AC_MSG_CHECKING(for type of bool)
1002 AC_ARG_WITH(bool,
1003         [  --with-bool=TYPE        override fallback type of bool variable],
1004         [NCURSES_BOOL="$withval"],
1005         [NCURSES_BOOL=auto])
1006 AC_MSG_RESULT($NCURSES_BOOL)
1007 AC_SUBST(NCURSES_BOOL)
1008
1009 AC_MSG_CHECKING(for alternate terminal capabilities file)
1010 AC_ARG_WITH(caps,
1011         [  --with-caps=alt         compile with alternate Caps file],
1012         [TERMINFO_CAPS=Caps.$withval],
1013         [TERMINFO_CAPS=Caps])
1014 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
1015 AC_MSG_RESULT($TERMINFO_CAPS)
1016 AC_SUBST(TERMINFO_CAPS)
1017
1018 ###   use option --with-chtype to override chtype's type
1019 AC_MSG_CHECKING(for type of chtype)
1020 AC_ARG_WITH(chtype,
1021         [  --with-chtype=TYPE      override type of chtype],
1022         [NCURSES_CHTYPE="$withval"],
1023         [NCURSES_CHTYPE=$cf_dft_chtype])
1024 AC_MSG_RESULT($NCURSES_CHTYPE)
1025
1026 ###   use option --with-ospeed to override ospeed's type
1027 AC_MSG_CHECKING(for type of ospeed)
1028 AC_ARG_WITH(ospeed,
1029         [  --with-ospeed=TYPE      override type of ospeed variable],
1030         [NCURSES_OSPEED="$withval"],
1031         [NCURSES_OSPEED=short])
1032 AC_MSG_RESULT($NCURSES_OSPEED)
1033 AC_SUBST(NCURSES_OSPEED)
1034
1035 ###   use option --with-mmask-t to override mmask_t's type
1036 AC_MSG_CHECKING(for type of mmask_t)
1037 AC_ARG_WITH(mmask-t,
1038         [  --with-mmask-t=TYPE     override type of mmask_t],
1039         [NCURSES_MMASK_T="$withval"],
1040         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1041 AC_MSG_RESULT($NCURSES_MMASK_T)
1042
1043 ###   use option --with-ccharw-max to override CCHARW_MAX size
1044 AC_MSG_CHECKING(for size CCHARW_MAX)
1045 AC_ARG_WITH(ccharw-max,
1046         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1047         [NCURSES_CCHARW_MAX="$withval"],
1048         [NCURSES_CCHARW_MAX=5])
1049 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1050 AC_SUBST(NCURSES_CCHARW_MAX)
1051
1052 AC_CHECK_SIZEOF([signed char], 0)
1053 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1054         NCURSES_SBOOL="signed char"
1055 else
1056         NCURSES_SBOOL="char"
1057 fi
1058 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1059 AC_ARG_ENABLE(signed-char,
1060         [  --enable-signed-char    compile using signed Boolean's in term.h],
1061         [with_signed_char=$enableval],
1062         [with_signed_char=no])
1063 AC_MSG_RESULT($with_signed_char)
1064 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1065 AC_SUBST(NCURSES_SBOOL)
1066
1067 ###   use option --with-tparm-arg to override tparm's argument type
1068 AC_MSG_CHECKING(for type of tparm args)
1069 AC_ARG_WITH(tparm-arg,
1070         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1071         [NCURSES_TPARM_ARG="$withval"],
1072         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1073 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1074 AC_SUBST(NCURSES_TPARM_ARG)
1075
1076 ### Enable compiling-in rcs id's
1077 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1078 AC_ARG_WITH(rcs-ids,
1079         [  --with-rcs-ids          compile-in RCS identifiers],
1080         [with_rcs_ids=$withval],
1081         [with_rcs_ids=no])
1082 AC_MSG_RESULT($with_rcs_ids)
1083 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1084
1085 ###############################################################################
1086 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1087
1088 ###############################################################################
1089 CF_HELP_MESSAGE(Extensions:)
1090
1091 ### Note that some functions (such as const) are normally disabled anyway.
1092 AC_MSG_CHECKING(if you want to build with function extensions)
1093 AC_ARG_ENABLE(ext-funcs,
1094         [  --disable-ext-funcs     disable function-extensions],
1095         [with_ext_funcs=$enableval],
1096         [with_ext_funcs=yes])
1097 AC_MSG_RESULT($with_ext_funcs)
1098 if test "x$with_ext_funcs" = xyes ; then
1099         NCURSES_EXT_FUNCS=1
1100         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1101         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1102         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1103         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1104         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1105         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1106         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1107         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1108         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1109         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1110         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1111         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1112         GENERATED_EXT_FUNCS=generated
1113         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1114 else
1115         NCURSES_EXT_FUNCS=0
1116         GENERATED_EXT_FUNCS=
1117 fi
1118 AC_SUBST(NCURSES_EXT_FUNCS)
1119 AC_SUBST(GENERATED_EXT_FUNCS)
1120
1121 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1122 AC_ARG_ENABLE(sp-funcs,
1123         [  --enable-sp-funcs       enable SCREEN-extensions],
1124         [with_sp_funcs=$enableval],
1125         [with_sp_funcs=$cf_dft_ext_spfuncs])
1126 AC_MSG_RESULT($with_sp_funcs)
1127 if test "x$with_sp_funcs" = xyes ; then
1128         NCURSES_SP_FUNCS=1
1129         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1130         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1131         GENERATED_SP_FUNCS=generated
1132 else
1133         NCURSES_SP_FUNCS=0
1134         GENERATED_SP_FUNCS=
1135 fi
1136 AC_SUBST(NCURSES_SP_FUNCS)
1137 AC_SUBST(GENERATED_SP_FUNCS)
1138
1139 AC_MSG_CHECKING(if you want to build with terminal-driver)
1140 AC_ARG_ENABLE(term-driver,
1141         [  --enable-term-driver    enable terminal-driver],
1142         [with_term_driver=$enableval],
1143         [with_term_driver=no])
1144 AC_MSG_RESULT($with_term_driver)
1145 if test "x$with_term_driver" = xyes ; then
1146         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1147         if test "x$with_termlib" != xno ; then
1148                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1149         fi
1150         if test "x$with_sp_funcs" != xyes ; then
1151                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1152         fi
1153 fi
1154
1155 ###   use option --enable-const to turn on use of const beyond that in XSI.
1156 AC_MSG_CHECKING(for extended use of const keyword)
1157 AC_ARG_ENABLE(const,
1158         [  --enable-const          compile with extra/non-standard const],
1159         [with_ext_const=$enableval],
1160         [with_ext_const=$cf_dft_ext_const])
1161 AC_MSG_RESULT($with_ext_const)
1162 NCURSES_CONST='/*nothing*/'
1163 if test "x$with_ext_const" = xyes ; then
1164         NCURSES_CONST=const
1165 fi
1166 AC_SUBST(NCURSES_CONST)
1167
1168 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1169 AC_MSG_CHECKING(if you want to use extended colors)
1170 AC_ARG_ENABLE(ext-colors,
1171         [  --enable-ext-colors     compile for 256-color support],
1172         [with_ext_colors=$enableval],
1173         [with_ext_colors=$cf_dft_ext_colors])
1174 AC_MSG_RESULT($with_ext_colors)
1175 NCURSES_EXT_COLORS=0
1176 if test "x$with_ext_colors" = xyes ; then
1177         if test "x$with_widec" != xyes ; then
1178                 AC_MSG_WARN(This option applies only to wide-character library)
1179         else
1180                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1181                 CF_NCURSES_ABI_6
1182                 NCURSES_EXT_COLORS=1
1183                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1184                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1185                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1186                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1187         fi
1188 fi
1189 AC_SUBST(NCURSES_EXT_COLORS)
1190
1191 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1192 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1193 AC_ARG_ENABLE(ext-mouse,
1194         [  --enable-ext-mouse      compile for extended mouse-encoding],
1195         [with_ext_mouse=$enableval],
1196         [with_ext_mouse=$cf_dft_ext_mouse])
1197 AC_MSG_RESULT($with_ext_mouse)
1198 NCURSES_MOUSE_VERSION=1
1199 if test "x$with_ext_mouse" = xyes ; then
1200         NCURSES_MOUSE_VERSION=2
1201         CF_NCURSES_ABI_6
1202 fi
1203 AC_SUBST(NCURSES_MOUSE_VERSION)
1204
1205 ###   use option --enable-ext-putwin to turn on extended screendumps
1206 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1207 AC_ARG_ENABLE(ext-putwin,
1208         [  --enable-ext-putwin     compile with extended putwin/screendump],
1209         [with_ext_putwin=$enableval],
1210         [with_ext_putwin=$cf_dft_ext_putwin])
1211 AC_MSG_RESULT($with_ext_putwin)
1212 if test "x$with_ext_putwin" = xyes ; then
1213         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1214 fi
1215
1216 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1217 AC_ARG_ENABLE(no-padding,
1218         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1219         [with_no_padding=$enableval],
1220         [with_no_padding=$with_ext_funcs])
1221 AC_MSG_RESULT($with_no_padding)
1222 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1223
1224 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1225 AC_MSG_CHECKING(if you want SIGWINCH handler)
1226 AC_ARG_ENABLE(sigwinch,
1227         [  --enable-sigwinch       compile with SIGWINCH handler],
1228         [with_sigwinch=$enableval],
1229         [with_sigwinch=$with_ext_funcs])
1230 AC_MSG_RESULT($with_sigwinch)
1231 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1232
1233 ###   use option --enable-tcap-names to allow user to define new capabilities
1234 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1235 AC_ARG_ENABLE(tcap-names,
1236         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1237         [with_tcap_names=$enableval],
1238         [with_tcap_names=$with_ext_funcs])
1239 AC_MSG_RESULT($with_tcap_names)
1240 NCURSES_XNAMES=0
1241 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1242 AC_SUBST(NCURSES_XNAMES)
1243
1244 ##############################################################################
1245 CF_HELP_MESSAGE(Reentrant Code:)
1246 CF_WITH_PTHREAD
1247
1248 if test "x$with_pthread" != xno; then
1249         AC_CHECK_FUNC(pthread_kill,[
1250                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1251                 AC_ARG_ENABLE(pthreads-eintr,
1252                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1253                         [use_pthreads_eintr=$enableval],
1254                         [use_pthreads_eintr=no])
1255                 AC_MSG_RESULT($use_pthreads_eintr)
1256                 if test "x$use_pthreads_eintr" = xyes ; then
1257                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1258                 fi])
1259
1260         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1261         AC_ARG_ENABLE(weak-symbols,
1262                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1263                 [use_weak_symbols=$enableval],
1264                 [use_weak_symbols=no])
1265         AC_MSG_RESULT($use_weak_symbols)
1266         if test "x$use_weak_symbols" = xyes ; then
1267                 CF_WEAK_SYMBOLS
1268         else
1269                 cf_cv_weak_symbols=no
1270         fi
1271
1272         if test "x$cf_cv_weak_symbols" = xyes ; then
1273                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1274         fi
1275 fi
1276
1277 PTHREAD=
1278 if test "x$with_pthread" = "xyes" ; then
1279         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1280         enable_reentrant=yes
1281         if test "x$cf_cv_weak_symbols" = xyes ; then
1282                 PTHREAD=-lpthread
1283                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1284         fi
1285 fi
1286 AC_SUBST(PTHREAD)
1287
1288 # Reentrant code has to be opaque; there's little advantage to making ncurses
1289 # opaque outside of that, so there is no --enable-opaque option.  We can use
1290 # this option without --with-pthreads, but this will be always set for
1291 # pthreads.
1292 AC_MSG_CHECKING(if you want reentrant code)
1293 AC_ARG_ENABLE(reentrant,
1294         [  --enable-reentrant      compile with reentrant code],
1295         [with_reentrant=$enableval],
1296         [with_reentrant=no])
1297 AC_MSG_RESULT($with_reentrant)
1298 if test "x$with_reentrant" = xyes ; then
1299         cf_cv_enable_reentrant=1
1300         cf_cv_enable_opaque="NCURSES_INTERNALS"
1301         NCURSES_SIZE_T=int
1302         if test "x$cf_cv_weak_symbols" = xyes ; then
1303                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1304                 CF_ADD_LIB(pthread,TEST_LIBS)
1305                 CF_ADD_LIB(pthread,TEST_LIBS2)
1306                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1307         else
1308                 # when not using weak symbols but with_reentrant,
1309                 # add 't' to the library suffix on all platforms
1310                 # except cygwin, where we only do that if ALSO
1311                 # compiling with full thread support.
1312                 case "$host" in
1313                 (*cygwin* | *msys*)
1314                         if test "$with_pthread" = "yes" ; then
1315                                 if test "x$disable_lib_suffixes" = "xno" ; then
1316                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1317                                 fi
1318                         fi ;;
1319                 (*)
1320                         if test "x$disable_lib_suffixes" = "xno" ; then
1321                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1322                         fi
1323                         ;;
1324                 esac
1325         fi
1326         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1327         CF_NCURSES_ABI_6
1328 else
1329         cf_cv_enable_reentrant=0
1330         cf_cv_enable_opaque="NCURSES_OPAQUE"
1331         NCURSES_SIZE_T=short
1332 fi
1333 AC_SUBST(cf_cv_enable_reentrant)
1334 AC_SUBST(cf_cv_enable_opaque)
1335
1336 AC_SUBST(NCURSES_SIZE_T)
1337
1338 AC_MSG_CHECKING(if you want opaque curses-library structures)
1339 CF_ARG_ENABLE(opaque-curses,
1340         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1341         [enable_opaque_curses=yes],[
1342          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1343          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=no
1344         ])
1345 AC_MSG_RESULT($enable_opaque_curses)
1346
1347 test "$cf_cv_enable_reentrant" = 1 && \
1348 test "$enable_opaque_curses" = no && \
1349 AC_MSG_ERROR(reentrant configuration requires opaque library)
1350
1351 AC_MSG_CHECKING(if you want opaque form-library structures)
1352 AC_ARG_ENABLE(opaque-form,
1353         [  --enable-opaque-form    make form-library structures "opaque"],
1354         [enable_opaque_form=yes],[enable_opaque_form=no])
1355 AC_MSG_RESULT($enable_opaque_form)
1356
1357 AC_MSG_CHECKING(if you want opaque menu-library structures)
1358 AC_ARG_ENABLE(opaque-menu,
1359         [  --enable-opaque-menu    make menu-library structures "opaque"],
1360         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1361 AC_MSG_RESULT($enable_opaque_menu)
1362
1363 AC_MSG_CHECKING(if you want opaque panel-library structures)
1364 AC_ARG_ENABLE(opaque-panel,
1365         [  --enable-opaque-panel   make panel-library structures "opaque"],
1366         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1367 AC_MSG_RESULT($enable_opaque_panel)
1368
1369 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1370 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1371 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1372 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1373
1374 AC_SUBST(NCURSES_OPAQUE)
1375 AC_SUBST(NCURSES_OPAQUE_FORM)
1376 AC_SUBST(NCURSES_OPAQUE_MENU)
1377 AC_SUBST(NCURSES_OPAQUE_PANEL)
1378
1379 ### Allow using a different wrap-prefix
1380 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1381         AC_MSG_CHECKING(for prefix used to wrap public variables)
1382         AC_ARG_WITH(wrap-prefix,
1383                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1384                 [NCURSES_WRAP_PREFIX=$withval],
1385                 [NCURSES_WRAP_PREFIX=_nc_])
1386         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1387 else
1388         NCURSES_WRAP_PREFIX=_nc_
1389 fi
1390 AC_SUBST(NCURSES_WRAP_PREFIX)
1391 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1392
1393 ###############################################################################
1394 # These options are relatively safe to experiment with.
1395 CF_HELP_MESSAGE(Development Code:)
1396 AC_MSG_CHECKING(if you want all development code)
1397 AC_ARG_WITH(develop,
1398         [  --without-develop       disable development options],
1399         [with_develop=$withval],
1400         [with_develop=no])
1401 AC_MSG_RESULT($with_develop)
1402
1403 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1404 AC_MSG_CHECKING(if you want hard-tabs code)
1405 AC_ARG_ENABLE(hard-tabs,
1406         [  --enable-hard-tabs      compile with hard-tabs code],,
1407         [enable_hard_tabs=$with_develop])
1408 AC_MSG_RESULT($enable_hard_tabs)
1409 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1410
1411 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1412 AC_MSG_CHECKING(if you want limited support for xmc)
1413 AC_ARG_ENABLE(xmc-glitch,
1414         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1415         [enable_xmc_glitch=$with_develop])
1416 AC_MSG_RESULT($enable_xmc_glitch)
1417 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1418
1419 ###############################################################################
1420 # These are just experimental, probably should not be in a package:
1421 CF_HELP_MESSAGE(Experimental Code:)
1422
1423 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1424 AC_ARG_ENABLE(assumed-color,
1425         [  --disable-assumed-color do not assume anything about default-colors],
1426         [with_assumed_color=$enableval],
1427         [with_assumed_color=yes])
1428 AC_MSG_RESULT($with_assumed_color)
1429 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1430
1431 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1432 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1433 AC_ARG_ENABLE(hashmap,
1434         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1435         [with_hashmap=$enableval],
1436         [with_hashmap=yes])
1437 AC_MSG_RESULT($with_hashmap)
1438 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1439
1440 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1441 AC_MSG_CHECKING(if you want colorfgbg code)
1442 AC_ARG_ENABLE(colorfgbg,
1443         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1444         [with_colorfgbg=$enableval],
1445         [with_colorfgbg=no])
1446 AC_MSG_RESULT($with_colorfgbg)
1447 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1448
1449 ###   use option --enable-interop to turn on use of bindings used for interop
1450 AC_MSG_CHECKING(if you want interop bindings)
1451 AC_ARG_ENABLE(interop,
1452         [  --enable-interop        compile-in interop bindings],
1453         [with_exp_interop=$enableval],
1454         [with_exp_interop=$cf_dft_interop])
1455 AC_MSG_RESULT($with_exp_interop)
1456
1457 NCURSES_INTEROP_FUNCS=0
1458 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1459 AC_SUBST(NCURSES_INTEROP_FUNCS)
1460
1461
1462 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1463 AC_ARG_ENABLE(safe-sprintf,
1464         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1465         [with_safe_sprintf=$enableval],
1466         [with_safe_sprintf=no])
1467 AC_MSG_RESULT($with_safe_sprintf)
1468
1469 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1470 # when hashmap is used scroll hints are useless
1471 if test "$with_hashmap" = no ; then
1472 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1473 AC_ARG_ENABLE(scroll-hints,
1474         [  --disable-scroll-hints  compile without scroll-hints code],
1475         [with_scroll_hints=$enableval],
1476         [with_scroll_hints=yes])
1477 AC_MSG_RESULT($with_scroll_hints)
1478 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1479 fi
1480
1481 AC_MSG_CHECKING(if you want wgetch-events code)
1482 AC_ARG_ENABLE(wgetch-events,
1483         [  --enable-wgetch-events  compile with wgetch-events code],
1484         [with_wgetch_events=$enableval],
1485         [with_wgetch_events=no])
1486 AC_MSG_RESULT($with_wgetch_events)
1487 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1488
1489 ###############################################################################
1490 CF_HELP_MESSAGE(Testing/development Options:)
1491
1492 ###     use option --disable-echo to suppress full display compiling commands
1493 CF_DISABLE_ECHO
1494 if test "x$enable_echo" = xyes; then
1495         ECHO_LINK=
1496 else
1497         ECHO_LINK='@ echo linking $@ ... ;'
1498         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1499         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1500 fi
1501 AC_SUBST(ECHO_LINK)
1502
1503 # --disable-stripping is used for debugging
1504 CF_INSTALL_OPTS
1505
1506 # If we're avoiding relinking of shared libraries during install, that is to
1507 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1508 # the install program has "-p" (for preserving timestamps).
1509 cf_cv_do_reranlib=yes
1510 if test "x$cf_cv_install_p" = xyes
1511 then
1512         if test "x$cf_cv_do_relink" != xyes
1513         then
1514                 cf_cv_do_reranlib=no
1515                 INSTALL_OPT_P="-p"
1516                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1517         fi
1518 fi
1519 AC_SUBST(INSTALL_OPT_P)
1520
1521 ###     use option --enable-warnings to turn on all gcc warnings
1522 AC_MSG_CHECKING(if you want to see compiler warnings)
1523 AC_ARG_ENABLE(warnings,
1524         [  --enable-warnings       build: turn on GCC compiler warnings],
1525         [with_warnings=$enableval])
1526 AC_MSG_RESULT($with_warnings)
1527
1528 if test "x$with_warnings" = "xyes"; then
1529         CF_ADD_ADAFLAGS(-gnatg)
1530         CF_GCC_WARNINGS(Wno-unknown-pragmas Wswitch-enum)
1531         if test "x$cf_with_cxx" = xyes ; then
1532                 CF_GXX_WARNINGS(Wno-unused)
1533         fi
1534 fi
1535 CF_GCC_ATTRIBUTES
1536 CF_ENABLE_STRING_HACKS
1537
1538 ###     use option --enable-assertions to turn on generation of assertion code
1539 AC_MSG_CHECKING(if you want to enable runtime assertions)
1540 AC_ARG_ENABLE(assertions,
1541         [  --enable-assertions     test: turn on generation of assertion code],
1542         [with_assertions=$enableval],
1543         [with_assertions=no])
1544 AC_MSG_RESULT($with_assertions)
1545 if test -n "$GCC"
1546 then
1547         if test "$with_assertions" = no
1548         then
1549                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1550         else
1551                 CF_ADD_ADAFLAGS(-gnata)
1552         fi
1553 fi
1554
1555 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1556 CF_DISABLE_LEAKS
1557 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1558
1559 ###     use option --enable-expanded to generate certain macros as functions
1560 AC_ARG_ENABLE(expanded,
1561         [  --enable-expanded       test: generate functions for certain macros],
1562         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1563
1564 ###     use option --disable-macros to suppress macros in favor of functions
1565 AC_ARG_ENABLE(macros,
1566         [  --disable-macros        test: use functions rather than macros],
1567         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1568
1569 # Normally we only add trace() to the debug-library.  Allow this to be
1570 # extended to all models of the ncurses library:
1571 cf_all_traces=no
1572 case "$CFLAGS $CPPFLAGS" in
1573 (*-DTRACE*)
1574         cf_all_traces=yes
1575         ;;
1576 esac
1577
1578 AC_MSG_CHECKING(whether to add trace feature to all models)
1579 AC_ARG_WITH(trace,
1580 [  --with-trace            test: add trace() function to all models of ncurses],
1581 [cf_with_trace=$withval],
1582 [cf_with_trace=$cf_all_traces])
1583 AC_MSG_RESULT($cf_with_trace)
1584
1585 if test "x$cf_with_trace" = xyes ; then
1586         LIB_TRACING=all
1587         ADA_TRACE=TRUE
1588         CF_ADD_CFLAGS(-DTRACE)
1589         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1590 else
1591         LIB_TRACING=DEBUG
1592         ADA_TRACE=FALSE
1593 fi
1594
1595 AC_SUBST(ADA_TRACE)
1596
1597 CF_DISABLE_GNAT_PROJECTS
1598
1599 ###     Checks for libraries.
1600 case $cf_cv_system_name in
1601 (*mingw32*|*mingw64*)
1602         CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1603         LIBS=" -lpsapi $LIBS"
1604         ;;
1605 (*)
1606 AC_CHECK_FUNC(gettimeofday,
1607         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1608
1609 AC_CHECK_LIB(bsd, gettimeofday,
1610         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1611         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1612         ;;
1613 esac
1614
1615 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1616 AC_SUBST(MATH_LIB)
1617
1618 ###     Checks for header files.
1619 AC_STDC_HEADERS
1620 AC_HEADER_DIRENT
1621 AC_HEADER_TIME
1622 CF_REGEX
1623
1624 dnl These are some other potentially nonportable headers.
1625 AC_CHECK_HEADERS( \
1626 fcntl.h \
1627 getopt.h \
1628 limits.h \
1629 locale.h \
1630 math.h \
1631 poll.h \
1632 sys/bsdtypes.h \
1633 sys/ioctl.h \
1634 sys/param.h \
1635 sys/poll.h \
1636 sys/select.h \
1637 sys/time.h \
1638 sys/times.h \
1639 ttyent.h \
1640 unistd.h \
1641 wctype.h \
1642 )
1643
1644 CF_GETOPT_HEADER
1645
1646 # check for ISC (this may also define _POSIX_SOURCE)
1647 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1648 if test "x$ISC" = xyes ; then
1649         AC_CHECK_LIB(cposix,main)
1650         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1651 fi
1652
1653 CF_SYS_TIME_SELECT
1654
1655 ###     checks for compiler characteristics
1656 AC_LANG_C
1657 AC_C_CONST
1658 CF_C_INLINE(NCURSES_INLINE,1200)
1659 CF_SIG_ATOMIC_T
1660
1661 if test $NCURSES_CHTYPE = auto ; then
1662         CF_TYPEOF_CHTYPE
1663 else
1664         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1665 fi
1666 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1667 AC_SUBST(cf_cv_typeof_chtype)
1668
1669 CF_UNSIGNED_LITERALS
1670 cf_cv_1UL="1"
1671 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1672 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1673 AC_SUBST(cf_cv_1UL)
1674
1675 if test $NCURSES_MMASK_T = auto ; then
1676         cf_cv_typeof_mmask_t=long
1677 else
1678         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1679 fi
1680 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1681 AC_SUBST(cf_cv_typeof_mmask_t)
1682
1683 ###     Checks for external-data
1684 CF_ERRNO
1685 CF_LINK_DATAONLY
1686
1687 ###     Checks for library functions.
1688 AC_CHECK_FUNCS( \
1689 getcwd \
1690 getegid \
1691 geteuid \
1692 getopt \
1693 getttynam \
1694 issetugid \
1695 localeconv \
1696 poll \
1697 putenv \
1698 remove \
1699 select \
1700 setbuf \
1701 setbuffer \
1702 setenv \
1703 setvbuf \
1704 sigaction \
1705 sigvec \
1706 strdup \
1707 strstr \
1708 sysconf \
1709 tcgetpgrp \
1710 times \
1711 tsearch \
1712 vsnprintf \
1713 )
1714
1715 if test "x$ac_cv_func_getopt" = xno && \
1716    test "x$cf_with_progs$cf_with_tests" != xnono; then
1717         AC_MSG_ERROR(getopt is required for building programs)
1718 fi
1719
1720 if test "x$with_safe_sprintf" = xyes
1721 then
1722         if test "x$ac_cv_func_vsnprintf" = xyes
1723         then
1724                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1725         else
1726                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1727         fi
1728 fi
1729
1730 if test "x$with_getcap" = "xyes" ; then
1731         CF_CGETENT
1732 fi
1733
1734 CF_ISASCII
1735 CF_STRUCT_SIGACTION
1736 CF_FUNC_NANOSLEEP
1737 CF_FUNC_TERMIOS
1738 CF_FUNC_VSSCANF
1739 CF_MKSTEMP
1740
1741 # setup for prototype of fallback for vsscanf()
1742 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1743
1744 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1745 if test "x$cross_compiling" = xyes ; then
1746         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1747 else
1748         AC_FUNC_SETVBUF_REVERSED
1749 fi
1750 AC_CHECK_TYPE(intptr_t, long)
1751 AC_CHECK_TYPE(ssize_t, int)
1752 CF_TYPE_SIGACTION
1753 CF_SIZECHANGE
1754 CF_FUNC_MEMMOVE
1755 CF_FUNC_POLL
1756 CF_VA_COPY
1757 AC_FUNC_VFORK
1758 CF_FOPEN_BIN_R
1759
1760 # special check for test/ditto.c
1761 CF_FUNC_OPENPTY
1762 if test "$cf_cv_func_openpty" != no ; then
1763         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1764         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1765         if test "x$cf_cv_lib_util" = xyes ; then
1766                 CF_ADD_LIB(util,TEST_LIBS)
1767         fi
1768 fi
1769 AC_SUBST(TEST_LIBS)
1770 AC_SUBST(TEST_LIBS2)
1771
1772 if test "$with_hashed_db" != no ; then
1773         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1774         CF_HASHED_DB($with_hashed_db)
1775 fi
1776
1777 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1778 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1779         CF_STRIP_G_OPT(CFLAGS)
1780         CF_STRIP_G_OPT(CXXFLAGS)
1781 fi
1782
1783 # Just in case, check if the C compiler has a bool type.
1784 CF_BOOL_DECL(cf_cv_cc_bool_type)
1785
1786 # Check for C++ compiler characteristics (and ensure that it's there!)
1787 if test -n "$CXX" ; then
1788         AC_LANG_CPLUSPLUS
1789         CF_STDCPP_LIBRARY
1790         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1791
1792         case $GXX_VERSION in
1793         (1*|2.[0-6]*)
1794                 cf_cxx_library=yes
1795                 ;;
1796         (*-2.7*|2.7*)
1797                 CF_GPP_LIBRARY
1798                 ;;
1799         (*)
1800                 cf_cxx_library=no
1801                 ;;
1802         esac
1803
1804         AC_CHECK_HEADERS(typeinfo)
1805         CF_CXX_IOSTREAM_NAMESPACE
1806         CF_BOOL_DECL
1807         CF_BOOL_SIZE
1808         CF_ETIP_DEFINES
1809         CF_CPP_PARAM_INIT
1810         CF_CPP_STATIC_CAST
1811         CF_CXX_AR_FLAGS
1812 else
1813         cf_cxx_library=no
1814         cf_cv_builtin_bool=1
1815
1816         # Just because we are not configuring against C++ right now does not
1817         # mean that a user will not want to use C++.  Some distributors disable
1818         # the C++ portion of this configuration as a shortcut (or just to avoid
1819         # compiling the demo in the c++ directory).  So we need a reasonable
1820         # default for the 'bool' type.
1821         #
1822         # Caveat: since the storage of the bool type is not standardized, it
1823         # may change.
1824
1825         if test "$NCURSES_BOOL" != auto ; then
1826                 cf_cv_type_of_bool=$NCURSES_BOOL
1827                 cf_cv_header_stdbool_h=0
1828         else
1829                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1830                         CF_BOOL_SIZE
1831                 else
1832                         AC_MSG_CHECKING(for fallback type of bool)
1833                         case "$host_cpu" in
1834                         (i?86)  cf_cv_type_of_bool=char ;;
1835                         (*)     cf_cv_type_of_bool=int  ;;
1836                         esac
1837                         AC_MSG_RESULT($cf_cv_type_of_bool)
1838                 fi
1839         fi
1840 fi
1841 AC_SUBST(CXXLIBS)
1842
1843 # If the C compiler did not declare bool, and we did not determine that the C++
1844 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1845 # ncurses library use the same type as C++ bool.  Note that this allows one to
1846 # specify the type of bool in a configure-script option and postpone
1847 # integration with the C++ compiler provided that the types are compatible.
1848 USE_CXX_BOOL=1
1849 if test $cf_cv_cc_bool_type = 1
1850 then
1851         # oops: C has a bool.  Unlikely, but C++ could differ.
1852         USE_CXX_BOOL=0
1853 elif test $cf_cv_builtin_bool = 0
1854 then
1855         # C++ has no bool
1856         USE_CXX_BOOL=0
1857 else
1858         # this is the normal case
1859         USE_CXX_BOOL='defined(__cplusplus)'
1860 fi
1861 AC_SUBST(USE_CXX_BOOL)
1862
1863 CF_HELP_MESSAGE(Ada95 Binding Options:)
1864
1865 dnl If the Ada95 source-tree is present, add that to the build unless it will
1866 dnl not work, or was not requested.
1867 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1868
1869 dnl libtool does not know anything about GNAT, though a change made in 1998
1870 dnl provided for it "someday".  Disable the ada subtree if we are using
1871 dnl libtool -TD 20070714
1872         if test "$cf_with_ada" != "no" ; then
1873                 if test "$with_libtool" != "no"; then
1874                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1875                         cf_with_ada=no
1876                 fi
1877         fi
1878
1879 dnl Check for availability of GNU Ada Translator (GNAT).
1880 dnl At the moment we support no other Ada95 compiler.
1881         if test "$cf_with_ada" != "no" ; then
1882                 CF_PROG_GNAT
1883                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1884                         CF_ADD_ADAFLAGS(-gnatpn)
1885                         CF_FIXUP_ADAFLAGS
1886
1887                         CF_GNATPREP_OPT_T
1888
1889                         CF_GNAT_GENERICS
1890                         CF_GNAT_SIGINT
1891                         CF_GNAT_PROJECTS
1892
1893                         CF_WITH_ADA_COMPILER
1894
1895                         cf_ada_package=terminal_interface
1896                         AC_SUBST(cf_ada_package)
1897
1898                         CF_WITH_ADA_INCLUDE
1899                         CF_WITH_ADA_OBJECTS
1900                         CF_WITH_ADA_SHAREDLIB
1901                 fi
1902         fi
1903 else
1904         cf_with_ada=no
1905 fi
1906
1907 # do this "late" to avoid conflict with header-checks
1908 if test "x$with_widec" = xyes ; then
1909         AC_CHECK_SIZEOF(wchar_t)
1910 fi
1911
1912 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1913 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1914 ###
1915 ### ticlib modules may be a separate library, otherwise contained in termlib.
1916 ### termlib modules may be a separate library, otherwise contained in ncurses.
1917 ###
1918 ### The of "+" or " " between the tokens controls the way the script
1919 ### chooses to split module lists into libraries.
1920 ###
1921 ### (see CF_LIB_RULES).
1922 AC_MSG_CHECKING(for library subsets)
1923 LIB_SUBSETS=
1924
1925 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1926         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1927         if test "$with_ticlib" != no ; then
1928                 LIB_SUBSETS="${LIB_SUBSETS} "
1929         else
1930                 LIB_SUBSETS="${LIB_SUBSETS}+"
1931         fi
1932 fi
1933
1934 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1935 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1936
1937 if test "$with_termlib" != no ; then
1938         LIB_SUBSETS="${LIB_SUBSETS} "
1939 else
1940         LIB_SUBSETS="${LIB_SUBSETS}+"
1941 fi
1942
1943 LIB_SUBSETS="${LIB_SUBSETS}base"
1944
1945 # Most term-driver calls are to tinfo, but some like init_pair are to the
1946 # base library (so it resides in base).
1947 if test "$with_term_driver" != no ; then
1948         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1949         case $cf_cv_system_name in
1950         (*mingw32*|*mingw64*)
1951                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1952                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
1953                 ;;
1954         (*)
1955                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1956                 ;;
1957         esac
1958 fi
1959
1960 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1961 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1962
1963 AC_MSG_RESULT($LIB_SUBSETS)
1964
1965 ### Construct the list of include-directories to be generated
1966 CF_INCLUDE_DIRS
1967 CF_ADA_INCLUDE_DIRS
1968
1969 ### Build up pieces for makefile rules
1970 AC_MSG_CHECKING(default library suffix)
1971 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1972 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1973 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1974
1975 AC_MSG_CHECKING(default library-dependency suffix)
1976 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1977 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1978 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1979
1980 AC_MSG_CHECKING(default object directory)
1981 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1982 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1983 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1984
1985 if test "x$cf_with_cxx" = xyes ; then
1986 AC_MSG_CHECKING(c++ library-dependency suffix)
1987 if test "$with_libtool" != "no"; then
1988         # libtool thinks it can make c++ shared libraries (perhaps only g++)
1989         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1990 elif test "$with_shared_cxx" != "no"; then
1991         # also for g++ users...
1992         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1993 else
1994         # we normally make a static library because C/C++ library rules differ
1995         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
1996 fi
1997 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1998 AC_SUBST(CXX_LIB_SUFFIX)
1999 fi
2000
2001 # do not want -ldl in build except as needed for -lncurses dependency
2002 if test "x$with_dlsym" = xyes ; then
2003 if test $DFT_LWR_MODEL = shared || \
2004    test $DFT_LWR_MODEL = libtool ; then
2005         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2006 fi
2007 fi
2008 ### Set up low-level terminfo dependencies for makefiles.
2009
2010 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2011 # do not need libdl
2012 TICS_LIST=
2013 if test "x$with_dlsym" = xyes ; then
2014         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2015 fi
2016
2017 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2018 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2019 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2020 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2021 then
2022         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2023 fi
2024 AC_SUBST(USE_ARG_SUFFIX)
2025 AC_SUBST(USE_CFG_SUFFIX)
2026 AC_SUBST(USE_LIB_SUFFIX)
2027
2028 if test "$with_ticlib" != no ; then
2029
2030         if test "x$with_ticlib" != xyes ; then
2031                 TICS_NAME=$with_ticlib
2032                 TICS_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2033                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2034                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2035                 TICS_LIB_SUFFIX="${with_ticlib}"
2036         else
2037                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2038                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2039                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2040                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2041         fi
2042         TICS_LDFLAGS="-L${LIB_DIR}"
2043         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2044 else
2045         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2046         TICS_LDFLAGS="-L${LIB_DIR}"
2047         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2048 fi
2049 AC_SUBST(TICS_ARG_SUFFIX)
2050 AC_SUBST(TICS_DEP_SUFFIX)
2051 AC_SUBST(TICS_LIB_SUFFIX)
2052 AC_SUBST(TICS_LDFLAGS)
2053 AC_SUBST(TICS_LIBS)
2054
2055 if test "$with_termlib" != no ; then
2056
2057         if test "x$with_termlib" != xyes ; then
2058                 TINFO_NAME=$with_termlib
2059                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2060                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2061                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2062                 TINFO_LIB_SUFFIX="${with_termlib}"
2063         else
2064                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2065                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2066                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2067                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2068         fi
2069
2070         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2071         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2072         if test "$DFT_LWR_MODEL" = "libtool"; then
2073                 TEST_ARGS="${TEST_DEPS}"
2074                 TEST_ARG2="${TEST_DEP2}"
2075                 TINFO_LDFLAGS="-L${LIB_DIR}"
2076                 TINFO_LIBS="$TEST_ARGS"
2077                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2078                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2079         else
2080                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2081                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2082                 if test "x$with_term_driver" != xno ; then
2083                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2084                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2085                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2086                 else
2087                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2088                         TINFO_LIBS="$TEST_ARGS"
2089                 fi
2090                 TINFO_LDFLAGS="-L${LIB_DIR}"
2091                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2092         fi
2093 else
2094         # the next lines are needed for linking libtic over libncurses
2095         TINFO_NAME=${LIB_NAME}
2096         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2097         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2098         if test "x$with_tic_depends" = xyes ; then
2099                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2100         else
2101                 TICS_LIST="$SHLIB_LIST"
2102         fi
2103
2104         TINFO_LDFLAGS="-L${LIB_DIR}"
2105         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2106 fi
2107
2108 if test "$DFT_LWR_MODEL" = shared ; then
2109         case $cf_cv_system_name in
2110         (cygwin*|msys*)
2111                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2112                 TINFO_SUFFIX=.dll
2113                 ;;
2114         esac
2115 fi
2116
2117 AC_SUBST(TINFO_ARG_SUFFIX)
2118 AC_SUBST(TINFO_DEP_SUFFIX)
2119 AC_SUBST(TINFO_LIB_SUFFIX)
2120 AC_SUBST(TINFO_LDFLAGS)
2121 AC_SUBST(TINFO_LIBS)
2122
2123 if test "x$with_dlsym" = xyes ; then
2124         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2125 fi
2126
2127 if test "$DFT_LWR_MODEL" = "libtool"; then
2128         OBJEXT=lo
2129 fi
2130
2131 # needed for Ada95
2132 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2133 AC_SUBST(TINFO_LDFLAGS2)
2134
2135 case $DFT_LWR_MODEL in
2136 (normal|debug|profile)
2137         CF_LDFLAGS_STATIC
2138         ;;
2139 esac
2140
2141 AC_MSG_CHECKING(where we will install curses.h)
2142 AC_SUBST(includesubdir)
2143 includesubdir=
2144 if test "$with_overwrite" = no && \
2145  ( test "x$includedir" = 'x${prefix}/include' || \
2146    test "x$includedir" = "x${prefix}/include" )
2147 then
2148         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2149 fi
2150 AC_MSG_RESULT(${includedir}${includesubdir})
2151
2152 ### Resolve a conflict between normal and wide-curses by forcing applications
2153 ### that will need libutf8 to add it to their configure script.
2154 if test "$with_overwrite" != no ; then
2155 if test "$NCURSES_LIBUTF8" = 1 ; then
2156         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2157         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2158 fi
2159 fi
2160 WITH_OVERWRITE=$with_overwrite
2161
2162 AC_SUBST(WITH_OVERWRITE)
2163 AC_SUBST(TICS_LIST)
2164 AC_SUBST(TINFO_LIST)
2165 AC_SUBST(SHLIB_LIST)
2166
2167 # used to separate tack out of the tree
2168 NCURSES_TREE=
2169 AC_SUBST(NCURSES_TREE)
2170
2171 ### predefined stuff for the test programs
2172 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2173
2174 ### Construct the list of subdirectories for which we'll customize makefiles
2175 ### with the appropriate compile-rules.
2176
2177 CF_SRC_MODULES($modules_to_build)
2178
2179 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2180    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2181    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2182 fi
2183
2184 CF_DIRS_TO_MAKE
2185
2186 # symbols that differ when compiling Ada95 by itself.
2187 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2188 AC_SUBST(NCURSES_SHLIB2)
2189
2190 # values to use as strings
2191 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2192
2193 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2194
2195 ### Now that we're done running tests, add the compiler-warnings, if any
2196 CF_ADD_CFLAGS($EXTRA_CFLAGS)
2197
2198 ### Define substitutions for header files to avoid name-pollution
2199 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2200 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2201 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2202 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2203
2204 ################################################################################
2205 test "x$use_database" = xyes && \
2206 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2207
2208 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2209 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2210
2211 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2212 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2213 fi
2214 AC_SUBST(cross_compiling)
2215
2216 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
2217 if test -n "$FALLBACK_LIST"
2218 then
2219         if test "$TIC_PATH" = unknown
2220         then
2221                 AC_MSG_WARN(no tic program found for fallbacks)
2222         fi
2223 fi
2224 AC_SUBST(TIC_PATH)
2225
2226 if test "x$cf_with_tests" != xno ; then
2227         MAKE_TESTS=
2228 else
2229         MAKE_TESTS="#"
2230 fi
2231 AC_SUBST(MAKE_TESTS)
2232
2233 ADAHTML_DIR=../../doc/html/ada
2234 AC_SUBST(ADAHTML_DIR)
2235
2236 # these could be configurable, but are not currently
2237 PANEL_NAME=panel
2238 MENU_NAME=menu
2239 FORM_NAME=form
2240 CXX_NAME=ncurses++
2241
2242 AC_SUBST(PANEL_NAME)
2243 AC_SUBST(MENU_NAME)
2244 AC_SUBST(FORM_NAME)
2245 AC_SUBST(CXX_NAME)
2246
2247 # workaround for OS/2 (20151017)
2248 case $cf_cv_system_name in
2249 (os2*)
2250         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2251         ;;
2252 (*)
2253         LIBTOOL_OPTS_CXX=
2254         ;;
2255 esac
2256 AC_SUBST(LIBTOOL_OPTS_CXX)
2257
2258 # workaround for g++ versus Solaris (20131116)
2259 case $cf_cv_system_name in
2260 (solaris2*)
2261         case "x$CPPFLAGS" in
2262         (*-D_XOPEN_SOURCE_EXTENDED*)
2263                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2264                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2265                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2266                 ;;
2267         esac
2268         ;;
2269 esac
2270
2271 # Help to automatically enable the extended curses features when using either
2272 # the *-config or the ".pc" files by adding defines.
2273 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2274 PKG_CFLAGS=
2275 for cf_loop1 in $CPPFLAGS_after_XOPEN
2276 do
2277         cf_found=no
2278         for cf_loop2 in $CPPFLAGS_before_XOPEN
2279         do
2280                 if test "x$cf_loop1" = "x$cf_loop2"
2281                 then
2282                         cf_found=yes
2283                         break
2284                 fi
2285         done
2286         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2287 done
2288 AC_MSG_RESULT($PKG_CFLAGS)
2289 AC_SUBST(PKG_CFLAGS)
2290
2291 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2292 case "x$NCURSES_OSPEED" in
2293 (*short*)
2294         cf_compatible=1
2295         ;;
2296 (*)
2297         cf_compatible=0
2298         ;;
2299 esac
2300 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2301
2302 case "x$cf_cv_typeof_chtype" in
2303 (xshort|xint|xlong)
2304         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2305         ;;
2306 esac
2307
2308 case "x$cf_cv_typeof_mmask_t" in
2309 (xshort|xint|xlong)
2310         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2311         ;;
2312 esac
2313
2314 # substitute into misc/Makefile to suppress
2315 # (un)install.data from the
2316 # (un)install rules.
2317 if test "x$cf_with_db_install" = "xno"; then
2318         MISC_INSTALL_DATA=
2319         MISC_UNINSTALL_DATA=
2320 else
2321         MISC_INSTALL_DATA=install.data
2322         MISC_UNINSTALL_DATA=uninstall.data
2323 fi
2324 AC_SUBST(MISC_INSTALL_DATA)
2325 AC_SUBST(MISC_UNINSTALL_DATA)
2326
2327 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2328         MAKE_DATABASE="#"
2329 else
2330         MAKE_DATABASE="$MAKE_TERMINFO"
2331 fi
2332 AC_SUBST(MAKE_DATABASE)
2333
2334 SUB_SCRIPTS=
2335
2336 dnl Override the package used for exported symbols
2337 if test -n "$PACKAGE"
2338 then
2339         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2340         export PACKAGE
2341         echo "package: $PACKAGE"
2342 fi
2343
2344 UNALTERED_SYMS=
2345 cf_filter_syms=no
2346
2347 if test -n "$RESULTING_SYMS"
2348 then
2349         cf_filter_syms=$cf_dft_filter_syms
2350         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2351 fi
2352
2353 if test "x$WILDCARD_SYMS" = xno
2354 then
2355         cf_filter_syms=yes
2356 fi
2357
2358 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2359
2360 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2361 if test $cf_filter_syms = yes
2362 then
2363         RESULTING_SYMS=resulting.map
2364 fi
2365 AC_SUBST(UNALTERED_SYMS)
2366
2367 if test "x$cross_compiling" = xyes ; then
2368         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2369         CHECK_BUILD="#"
2370 else
2371         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2372         CHECK_BUILD=
2373 fi
2374 AC_SUBST(ADAGEN_LDFLAGS)
2375 AC_SUBST(CHECK_BUILD)
2376 AC_SUBST(PRIVATE_LIBS)
2377
2378 AC_DEFINE(HAVE_CURSES_DATA_BOOLNAMES,1,[definition needed for in-tree build of tack])
2379
2380 AC_OUTPUT( \
2381         include/MKterm.h.awk \
2382         include/curses.head:include/curses.h.in \
2383         include/ncurses_dll.h \
2384         include/termcap.h \
2385         include/unctrl.h \
2386         $SUB_SCRIPTS \
2387         $SUB_MAKEFILES \
2388         Makefile,[
2389 if test "x$cf_with_tests" != xno ; then
2390         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2391 fi
2392 CF_LIB_RULES($SRC_SUBDIRS)
2393
2394 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2395 if test -z "$USE_OLD_MAKERULES" ; then
2396         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
2397 fi
2398 fi
2399 ],[
2400 ### Special initialization commands, used to pass information from the
2401 ### configuration-run into config.status
2402
2403 AWK="$AWK"
2404 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2405 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2406 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2407 ECHO_LD="$ECHO_LD"
2408 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2409 LDCONFIG="$LDCONFIG"
2410 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2411 LIB_NAME="$LIB_NAME"
2412 LIB_PREFIX="$LIB_PREFIX"
2413 LIB_SUBSETS="$LIB_SUBSETS"
2414 LIB_SUFFIX="$LIB_SUFFIX"
2415 LIB_TRACING="$LIB_TRACING"
2416 LN_S="$LN_S"
2417 MAKE_TERMINFO="$MAKE_TERMINFO"
2418 NCURSES_MAJOR="$NCURSES_MAJOR"
2419 NCURSES_MINOR="$NCURSES_MINOR"
2420 NCURSES_OSPEED="$NCURSES_OSPEED"
2421 NCURSES_PATCH="$NCURSES_PATCH"
2422 SRC_SUBDIRS="$SRC_SUBDIRS"
2423 TERMINFO="$TERMINFO"
2424 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2425 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2426 TICS_NAME="$TICS_NAME"
2427 TICS_SUFFIX="$TICS_SUFFIX"
2428 TIC_PATH="$TIC_PATH"
2429 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2430 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2431 TINFO_NAME="$TINFO_NAME"
2432 TINFO_SUFFIX="$TINFO_SUFFIX"
2433 UNALTERED_SYMS="$UNALTERED_SYMS"
2434 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2435 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2436 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2437 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2438 WILDCARD_SYMS="$WILDCARD_SYMS"
2439 WITH_CURSES_H="$with_curses_h"
2440 WITH_ECHO="${enable_echo:=yes}"
2441 WITH_OVERWRITE="$with_overwrite"
2442 cf_LIST_MODELS="$cf_list_models"
2443 cf_cv_abi_version="$cf_cv_abi_version"
2444 cf_cv_do_relink="$cf_cv_do_relink"
2445 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2446 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2447 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2448 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2449 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2450 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2451 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2452 cf_cv_rel_version="$cf_cv_rel_version"
2453 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2454 cf_cv_shared_soname='$cf_cv_shared_soname'
2455 cf_cv_shlib_version="$cf_cv_shlib_version"
2456 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2457 cf_cv_system_name="$cf_cv_system_name"
2458 cf_cv_term_driver="$with_term_driver"
2459 cf_with_ada="$cf_with_ada"
2460 cf_with_cxx_binding="$cf_with_cxx_binding"
2461 cf_with_db_install="$cf_with_db_install"
2462 cf_with_manpages="$cf_with_manpages"
2463 cf_with_tests="$cf_with_tests"
2464 host="$host"
2465 target="$target"
2466 with_shared_cxx="$with_shared_cxx"
2467
2468 ],cat)dnl
2469 ${MAKE:-make} preinstall