ncurses 6.2 - patch 20200523
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright 2018-2019,2020 Thomas E. Dickey                                *
3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
4 dnl                                                                          *
5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
6 dnl copy of this software and associated documentation files (the            *
7 dnl "Software"), to deal in the Software without restriction, including      *
8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
10 dnl copies of the Software, and to permit persons to whom the Software is    *
11 dnl furnished to do so, subject to the following conditions:                 *
12 dnl                                                                          *
13 dnl The above copyright notice and this permission notice shall be included  *
14 dnl in all copies or substantial portions of the Software.                   *
15 dnl                                                                          *
16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
23 dnl                                                                          *
24 dnl Except as contained in this notice, the name(s) of the above copyright   *
25 dnl holders shall not be used in advertising or otherwise to promote the     *
26 dnl sale, use or other dealings in this Software without prior written       *
27 dnl authorization.                                                           *
28 dnl***************************************************************************
29 dnl
30 dnl Author: Thomas E. Dickey 1995-on
31 dnl
32 dnl $Id: configure.in,v 1.707 2020/05/23 18:16:07 tom Exp $
33 dnl Process this file with autoconf to produce a configure script.
34 dnl
35 dnl For additional information, see
36 dnl     https://invisible-island.net/autoconf/
37 dnl     https://invisible-island.net/autoconf/my-autoconf.html
38 dnl
39 dnl ---------------------------------------------------------------------------
40 AC_PREREQ(2.52.20200111)
41 AC_REVISION($Revision: 1.707 $)
42 AC_INIT(ncurses/base/lib_initscr.c)
43 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
44
45 AC_DEFUN([AC_PATH_XTRA],[])dnl ignore dependencies on this
46
47 CF_TOP_BUILDDIR
48 CF_SUBST_NCURSES_VERSION
49 CF_VERSION_INFO(NCURSES,ncurses)
50
51 CF_WITH_REL_VERSION(NCURSES)
52 CF_NCURSES_WITH_ABI_VERSION
53
54 CF_WITH_SYSTYPE
55
56 ###     Save the given $CFLAGS to allow user-override.
57 cf_user_CFLAGS="$CFLAGS"
58
59 ###     Default install-location
60 CF_CFG_DEFAULTS
61 ### Defaults for ncurses ABI
62 CF_ABI_DEFAULTS
63
64 ###     Checks for programs.
65 AC_ARG_WITH(ada,
66         [  --without-ada           suppress check for Ada compiler, don't build demo],
67         [cf_with_ada=$withval],
68         [cf_with_ada=yes])
69
70 if test "x$cf_with_ada" = xyes
71 then
72         cf_prog_cc="gnatgcc gcc cc"
73 else
74         cf_prog_cc="gcc cc"
75 fi
76 CF_PROG_CC($cf_prog_cc)
77
78 AC_PROG_CPP
79 AC_PROG_GCC_TRADITIONAL
80 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
81 CF_PROG_LDCONFIG
82
83 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
84 dnl                             configure script by not letting us test if C++
85 dnl                             is present, making this option necessary.
86 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
87 AC_ARG_WITH(cxx,
88         [  --without-cxx           do not adjust ncurses bool to match C++],
89         [cf_with_cxx=$withval],
90         [cf_with_cxx=yes])
91 AC_MSG_RESULT($cf_with_cxx)
92 if test "X$cf_with_cxx" = Xno ; then
93         CXX=""
94         GXX=""
95 else
96         # with autoconf 2.13, we can change the error to a warning:
97         pushdef([AC_MSG_ERROR],
98                 [AC_MSG_RESULT(no)
99                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
100                 cf_with_cxx=no; CXX=""; GXX="";])dnl
101         AC_PROG_CXX
102         popdef([AC_MSG_ERROR])dnl
103
104         AC_LANG_PUSH(C++)
105         if test "x$cf_with_cxx" != xno
106         then
107                 # Several of the C++ configurations do not work, particularly when
108                 # cross-compiling (20140913 -TD)
109                 AC_MSG_CHECKING(if $CXX works)
110
111                 save_CPPFLAGS="$CPPFLAGS"
112                 eval cf_includedir=${includedir}
113                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
114                 AC_TRY_COMPILE([
115 #include <stdlib.h>
116 #include <stdio.h>
117 ],
118                 [
119                 printf("Hello world!\n")
120                 ],
121                 [cf_cxx_works=yes],
122                 [cf_cxx_works=no])
123                 CPPFLAGS="$save_CPPFLAGS"
124
125                 AC_MSG_RESULT($cf_cxx_works)
126                 if test "x$cf_cxx_works" = xno
127                 then
128                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
129                         cf_with_cxx=no; CXX=""; GXX="";
130                 fi
131         fi
132         AC_LANG_POP
133
134         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
135         if test "$CXX" = "g++" ; then
136                 AC_PATH_PROG(CXX,g++)
137         fi
138         case "x$CXX" in
139         (x|xg++)
140                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
141                 cf_with_cxx=no; CXX=""; GXX="";
142                 ;;
143         esac
144 fi
145
146 CF_GXX_VERSION
147 case $GXX_VERSION in
148 (1*|2.[[0-6]]*)
149         # GXX=""; CXX=""; ac_cv_prog_gxx=no
150         # cf_cxx_library=no
151         AC_MSG_WARN(templates do not work)
152         ;;
153 esac
154
155 AC_MSG_CHECKING(if you want to build C++ binding and demo)
156 AC_ARG_WITH(cxx-binding,
157         [  --without-cxx-binding   do not build C++ binding and demo],
158         [cf_with_cxx_binding=$withval],
159         [cf_with_cxx_binding=$cf_with_cxx])
160 AC_MSG_RESULT($cf_with_cxx_binding)
161
162 AC_MSG_CHECKING(if you want to build with Ada)
163 AC_MSG_RESULT($cf_with_ada)
164
165 AC_MSG_CHECKING(if you want to install terminal database)
166 AC_ARG_ENABLE(db-install,
167         [  --disable-db-install    suppress install of terminal database],
168         [cf_with_db_install=$enableval],
169         [cf_with_db_install=yes])
170 AC_MSG_RESULT($cf_with_db_install)
171
172 AC_MSG_CHECKING(if you want to install manpages)
173 AC_ARG_WITH(manpages,
174         [  --without-manpages      suppress install of manpages],
175         [cf_with_manpages=$withval],
176         [cf_with_manpages=yes])
177 AC_MSG_RESULT($cf_with_manpages)
178
179 AC_MSG_CHECKING(if you want to build programs such as tic)
180 AC_ARG_WITH(progs,
181         [  --without-progs         suppress build/install with programs (e.g., tic)],
182         [cf_with_progs=$withval],
183         [cf_with_progs=yes])
184 AC_MSG_RESULT($cf_with_progs)
185
186 if test -f $srcdir/tack/tack.h; then
187         if test "x$cross_compiling" = xyes ; then
188                 CF_VERBOSE(ignoring tack because we are cross-compiling)
189                 cf_with_tack=no
190         else
191                 AC_MSG_CHECKING(if you want to build the tack program)
192                 AC_ARG_WITH(tack,
193                         [  --without-tack          suppress build/install with tack program],
194                         [cf_with_tack=$withval],
195                         [cf_with_tack=$cf_with_progs])
196                 AC_MSG_RESULT($cf_with_tack)
197         fi
198 else
199         cf_with_tack=no
200 fi
201
202 AC_MSG_CHECKING(if you want to build test-programs)
203 AC_ARG_WITH(tests,
204         [  --without-tests         suppress build/install with test-programs],
205         [cf_with_tests=$withval],
206         [cf_with_tests=yes])
207 AC_MSG_RESULT($cf_with_tests)
208
209 AC_MSG_CHECKING(if you wish to install curses.h)
210 AC_ARG_WITH(curses-h,
211         [  --without-curses-h      install curses.h as ncurses.h only],
212         [with_curses_h=$withval],
213         [with_curses_h=yes])
214 AC_MSG_RESULT($with_curses_h)
215
216 modules_to_build="ncurses"
217 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
218 test "X$cf_with_tack"  != Xno && modules_to_build="$modules_to_build tack"
219 modules_to_build="$modules_to_build panel menu form"
220
221 AC_ARG_PROGRAM
222
223 CF_PROG_AWK
224 CF_PROG_EGREP
225 CF_PROG_INSTALL
226 CF_PROG_LINT
227 CF_PROG_LN_S
228
229 AC_SYS_LONG_FILE_NAMES
230
231 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
232 # of package conflict.
233 cf_config_suffix=
234 AC_ARG_WITH(config-suffix,
235         [  --with-config-suffix=X  suffixes ncursesXX-config file],
236         [case "x$withval" in
237         (xyes|xno)
238                 AC_MSG_WARN(expected a value for config-suffix option)
239                 ;;
240         (*)     cf_config_suffix="$withval"
241                 ;;
242         esac])
243 AC_SUBST(cf_config_suffix)
244
245 # If we find pkg-config, check if we should install the ".pc" files.
246 CF_PKG_CONFIG
247 CF_WITH_PKG_CONFIG_LIBDIR
248 CF_ENABLE_PC_FILES
249 if test -z "$MAKE_PC_FILES"
250 then
251         AC_MSG_CHECKING(for suffix to add to pc-files)
252 AC_ARG_WITH(pc-suffix,
253         [  --with-pc-suffix        suffixes pc-files],
254         [case "x$withval" in
255         (xyes|xno)
256                 PC_MODULE_SUFFIX=
257                 ;;
258         (*)     PC_MODULE_SUFFIX="$withval"
259                 ;;
260         esac])
261         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
262         AC_MSG_RESULT($PC_MODULE_SUFFIX)
263         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
264         AC_SUBST(PC_MODULE_SUFFIX)
265 fi
266
267 AC_MSG_CHECKING(if we should assume mixed-case filenames)
268 AC_ARG_ENABLE(mixed-case,
269         [  --enable-mixed-case     tic should assume mixed-case filenames],
270         [enable_mixedcase=$enableval],
271         [enable_mixedcase=auto])
272 AC_MSG_RESULT($enable_mixedcase)
273 if test "$enable_mixedcase" = "auto" ; then
274         CF_MIXEDCASE_FILENAMES
275 else
276         cf_cv_mixedcase=$enable_mixedcase
277         if test "x$enable_mixedcase" = "xyes" ; then
278                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
279         fi
280 fi
281
282 # do this after mixed-case option (tags/TAGS is not as important as tic).
283 AC_PROG_MAKE_SET
284 CF_MAKE_TAGS
285 CF_MAKEFLAGS
286
287 dnl These are standard among *NIX systems, but not when cross-compiling
288 AC_CHECK_TOOL(RANLIB, ranlib, ':')
289 AC_CHECK_TOOL(LD, ld, ld)
290 AC_CHECK_TOOL(AR, ar, ar)
291 AC_CHECK_TOOL(NM, nm, nm)
292 CF_AR_FLAGS
293
294 dnl Special option for use by system-builders: the install-prefix is used to
295 dnl adjust the location into which the actual install is done, so that an
296 dnl archive can be built without modifying the host system's configuration.
297 AC_MSG_CHECKING(if you have specified an install-prefix)
298 AC_ARG_WITH(install-prefix,
299         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
300         [case "x$withval" in
301         (xyes|xno)
302                 ;;
303         (*)     DESTDIR="$withval"
304                 ;;
305         esac])
306 AC_MSG_RESULT($DESTDIR)
307 AC_SUBST(DESTDIR)
308
309 ###############################################################################
310 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
311 # If we're cross-compiling, allow the user to override the tools and their
312 # options.  The configure script is oriented toward identifying the host
313 # compiler, etc., but we need a build compiler to generate parts of the source.
314 CF_BUILD_CC
315
316 ###############################################################################
317 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
318
319 ### Options to allow the user to specify the set of libraries which are used.
320 ### Use "--without-normal --with-shared" to allow the default model to be
321 ### shared, for example.
322 cf_list_models=""
323 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
324
325 CF_WITH_LIBTOOL
326 if test "$with_libtool" != "no" ; then
327
328 cf_list_models="$cf_list_models libtool"
329
330 else
331
332 AC_MSG_CHECKING(if you want to build shared libraries)
333 AC_ARG_WITH(shared,
334         [  --with-shared           generate shared-libraries],
335         [with_shared=$withval],
336         [with_shared=no])
337 AC_MSG_RESULT($with_shared)
338 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
339
340 AC_MSG_CHECKING(if you want to build static libraries)
341 AC_ARG_WITH(normal,
342         [  --with-normal           generate normal-libraries (default)],
343         [with_normal=$withval],
344         [with_normal=yes])
345 AC_MSG_RESULT($with_normal)
346 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
347
348 AC_MSG_CHECKING(if you want to build debug libraries)
349 AC_ARG_WITH(debug,
350         [  --with-debug            generate debug-libraries (default)],
351         [with_debug=$withval],
352         [with_debug=yes])
353 AC_MSG_RESULT($with_debug)
354 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
355
356 AC_MSG_CHECKING(if you want to build profiling libraries)
357 AC_ARG_WITH(profile,
358         [  --with-profile          generate profile-libraries],
359         [with_profile=$withval],
360         [with_profile=no])
361 AC_MSG_RESULT($with_profile)
362 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
363
364 fi
365
366 if test "X$cf_with_cxx_binding" != Xno; then
367 if test "x$with_shared" = "xyes"; then
368 AC_MSG_CHECKING(if you want to build C++ shared libraries)
369 AC_ARG_WITH(cxx-shared,
370         [  --with-cxx-shared       generate C++ shared-libraries],
371         [with_shared_cxx=$withval],
372         [with_shared_cxx=no])
373 AC_MSG_RESULT($with_shared_cxx)
374 fi
375 fi
376
377 ###############################################################################
378
379 AC_MSG_CHECKING(for specified models)
380 test -z "$cf_list_models" && cf_list_models=normal
381 dnl If we use libtool to generate libraries, then it must be the only
382 dnl specified model.
383 test "$with_libtool" != "no" && cf_list_models=libtool
384 AC_MSG_RESULT($cf_list_models)
385
386 ### Use the first model as the default, and save its suffix for use in building
387 ### up test-applications.
388 AC_MSG_CHECKING(for default model)
389 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
390 AC_MSG_RESULT($DFT_LWR_MODEL)
391
392 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
393
394 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
395 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
396
397 TICS_NAME=tic
398 AC_SUBST(TICS_NAME)
399
400 TINFO_NAME=tinfo
401 AC_SUBST(TINFO_NAME)
402
403 LIB_NAME=ncurses
404 AC_SUBST(LIB_NAME)
405
406 LIB_DIR=../lib
407 LIB_2ND=../../lib
408
409 CF_WITH_LIB_PREFIX(cf_prefix)
410
411 LIB_SUFFIX=
412 AC_SUBST(LIB_SUFFIX)
413 CF_PATHSEP
414
415 ###############################################################################
416
417 AC_MSG_CHECKING(if you want to build a separate terminfo library)
418 AC_ARG_WITH(termlib,
419         [  --with-termlib          generate separate terminfo library],
420         [with_termlib=$withval],
421         [with_termlib=no])
422 AC_MSG_RESULT($with_termlib)
423
424 AC_MSG_CHECKING(if you want to build a separate tic library)
425 AC_ARG_WITH(ticlib,
426         [  --with-ticlib           generate separate tic library],
427         [with_ticlib=$withval],
428         [with_ticlib=no])
429 AC_MSG_RESULT($with_ticlib)
430
431 dnl Not all ports of gcc support the -g option
432
433 if test X"$CC_G_OPT" = X"" ; then
434         CC_G_OPT='-g'
435         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
436 fi
437 AC_SUBST(CC_G_OPT)
438
439 if test X"$CXX_G_OPT" = X"" ; then
440         CXX_G_OPT='-g'
441         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
442 fi
443 AC_SUBST(CXX_G_OPT)
444
445 AC_MSG_CHECKING(for default loader flags)
446 case $DFT_LWR_MODEL in
447 (libtool) LD_MODEL=''   ;;
448 (normal)  LD_MODEL=''   ;;
449 (debug)   LD_MODEL=$CC_G_OPT ;;
450 (profile) LD_MODEL='-pg';;
451 (shared)  LD_MODEL=''   ;;
452 esac
453 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
454 AC_MSG_RESULT($LD_MODEL)
455
456 case $DFT_LWR_MODEL in
457 (shared)
458 CF_ENABLE_RPATH
459 AC_MSG_CHECKING(if shared libraries should be relinked during install)
460 AC_ARG_ENABLE(relink,
461 [  --disable-relink        relink shared libraries during install],
462 [cf_cv_do_relink=$enableval],
463 [cf_cv_do_relink=yes])
464 AC_MSG_RESULT($cf_cv_do_relink)
465         ;;
466 esac
467
468 # we will build libraries one-level down.
469 rel_builddir=..
470 CF_SHARED_OPTS
471 for model in $cf_list_models; do
472         case $model in
473         (libtool)
474                 CF_WITH_LIBTOOL_OPTS
475                 CF_WITH_EXPORT_SYMS
476                 ;;
477         (shared)
478                 if test "$CC_SHARED_OPTS" = "unknown"; then
479                         AC_ERROR(Shared libraries are not supported in this version)
480                 fi
481                 # workaround for inept transition to PIE vs PIC...
482                 AC_MSG_CHECKING(if current CFLAGS link properly)
483                 AC_TRY_LINK(
484                         [#include <stdio.h>],
485                         [printf("Hello work\n");],
486                         [cf_cflags_work=yes],
487                         [cf_cflags_work=no])
488                 AC_MSG_RESULT($cf_cflags_work)
489                 if test "$cf_cflags_work" = no
490                 then
491                         CF_VERBOSE(try to work around by appending shared-options)
492                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
493                 fi
494                 CF_WITH_VERSIONED_SYMS
495                 ;;
496         esac
497 done
498
499 ### Checks for special libraries, must be done up-front.
500 SHLIB_LIST=""
501 CF_WITH_GPM
502 if test "$with_gpm" != no ; then
503         AC_MSG_CHECKING(if you want to load GPM dynamically)
504         AC_ARG_WITH(dlsym,
505                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
506                 [with_dlsym=$withval],
507                 [with_dlsym=yes])
508         AC_MSG_RESULT($with_dlsym)
509         if test "x$with_dlsym" = xyes ; then
510                 CF_FUNC_DLSYM
511                 if test "x$with_gpm" != xyes ; then
512                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
513                         cf_cv_gpm_soname="$with_gpm"
514                 else
515                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
516                 fi
517                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
518                 SHLIB_LIST="-ldl $SHLIB_LIST"
519                 CF_ADD_LIB(dl,PRIVATE_LIBS)
520         else
521                 SHLIB_LIST="-lgpm $SHLIB_LIST"
522                 CF_ADD_LIB(gpm,TEST_LIBS)
523                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
524         fi
525         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
526         CF_CHECK_GPM_WGETCH
527 fi
528
529 CF_WITH_PCRE2
530 CF_WITH_SYSMOUSE
531
532 # pretend that ncurses==ncursesw==ncursest
533 AC_MSG_CHECKING(if you want to disable library suffixes)
534 CF_ARG_DISABLE(lib-suffixes,
535         [  --disable-lib-suffixes  disable library suffixes],
536         [disable_lib_suffixes=yes],
537         [disable_lib_suffixes=no],
538         no)
539 AC_MSG_RESULT($disable_lib_suffixes)
540
541 ### If we're building with rpath, try to link non-standard libs that way too.
542 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
543         CF_DISABLE_RPATH_HACK
544 fi
545
546 ### Depending on the system, someone may use rpath to build ncurses but not
547 # want users of the package to rely upon that feature.  Give those people an
548 # option to suppress that detail from EXTRA_LDFLAGS.
549 EXTRA_PKG_LDFLAGS="$EXTRA_LDFLAGS"
550 if test -n "$EXTRA_PKG_LDFLAGS"
551 then
552         AC_MSG_CHECKING(if you want to disable extra LDFLAGS for package-scripts)
553         CF_ARG_DISABLE(pkg-ldflags,
554                 [  --disable-pkg-ldflags   disable extra LDFLAGS for package-scripts],
555                 [disable_pkg_ldflags=yes],
556                 [disable_pkg_ldflags=no],
557                 no)
558         AC_MSG_RESULT($disable_pkg_ldflags)
559         test "$disable_pkg_ldflags" = yes && EXTRA_PKG_LDFLAGS=
560 fi
561 AC_SUBST(EXTRA_PKG_LDFLAGS)
562
563 ###############################################################################
564 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
565
566 ###     use option --with-extra-suffix to append suffix to headers and libraries
567 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
568 EXTRA_SUFFIX=
569 AC_ARG_WITH(extra-suffix,
570         [  --with-extra-suffix=X   append extra suffix to header/library paths],
571         [case x$withval in
572         (no)
573                 ;;
574         (xyes|x)
575                 EXTRA_SUFFIX=$cf_cv_abi_version
576                 ;;
577         (*)
578                 EXTRA_SUFFIX=$withval
579                 ;;
580         esac
581         ])
582 AC_MSG_RESULT($EXTRA_SUFFIX)
583 AC_SUBST(EXTRA_SUFFIX)
584
585 ###     use option --disable-overwrite to leave out the link to -lcurses
586 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
587 AC_ARG_ENABLE(overwrite,
588         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
589         [with_overwrite=$enableval],
590         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
591 AC_MSG_RESULT($with_overwrite)
592
593 AC_MSG_CHECKING(if external terminfo-database is used)
594 AC_ARG_ENABLE(database,
595         [  --disable-database      do not use terminfo, only fallbacks/termcap],
596         [use_database=$enableval],
597         [use_database=yes])
598 AC_MSG_RESULT($use_database)
599
600 case $host_os in
601 (os2*)
602         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
603         ;;
604 (*)
605         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
606         ;;
607 esac
608 AC_SUBST(TERMINFO_SRC)
609
610 NCURSES_USE_DATABASE=0
611 if test "$use_database" != no ; then
612         NCURSES_USE_DATABASE=1
613
614         AC_MSG_CHECKING(which terminfo source-file will be installed)
615         AC_ARG_WITH(database,
616                 [  --with-database=XXX     specify terminfo source to install],
617                 [TERMINFO_SRC=$withval])
618         AC_MSG_RESULT($TERMINFO_SRC)
619
620         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
621         AC_ARG_WITH(hashed-db,
622                 [  --with-hashed-db        specify hashed-database library],,
623                 [with_hashed_db=no])
624         AC_MSG_RESULT($with_hashed_db)
625 else
626         with_hashed_db=no
627 fi
628 AC_SUBST(NCURSES_USE_DATABASE)
629
630 AC_MSG_CHECKING(for list of fallback descriptions)
631 AC_ARG_WITH(fallbacks,
632         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
633         [with_fallback=$withval],
634         [with_fallback=])
635 AC_MSG_RESULT($with_fallback)
636
637 case ".$with_fallback" in
638 (.|.no)
639         FALLBACK_LIST=
640         ;;
641 (.yes)
642         AC_MSG_WARN(expected a list of terminal descriptions)
643         ;;
644 (*)
645         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
646         ;;
647 esac
648
649 USE_FALLBACKS=
650 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
651 AC_SUBST(FALLBACK_LIST)
652 AC_SUBST(USE_FALLBACKS)
653
654 # The fallback feature in ncurses relies upon tic/infocmp outside the build
655 # tree for generating the terminal descriptions that will be compiled into the
656 # library.  If your toolchain is old, it may not handle current terminal
657 # databases.  Use configure-options to point to the tools which will be used,
658 # rather than the first ones found on the $PATH.
659 if test -n "$FALLBACK_LIST"
660 then
661         CF_WITH_PATH_PROG(TIC,     tic,     [for fallbacks], $PATH:/usr/local/ncurses/bin)
662         CF_WITH_PATH_PROG(INFOCMP, infocmp, [for fallbacks], $PATH:/usr/local/ncurses/bin)
663 else
664         : ${TIC:=tic}
665         : ${INFOCMP:=infocmp}
666 fi
667 AC_SUBST(TIC)
668 AC_SUBST(INFOCMP)
669
670 AC_MSG_CHECKING(if you want modern xterm or antique)
671 AC_ARG_WITH(xterm-new,
672         [  --without-xterm-new     specify if xterm terminfo should be old version],
673         [with_xterm_new=$withval],
674         [with_xterm_new=yes])
675 case $with_xterm_new in
676 (no) with_xterm_new=xterm-old;;
677 (*)      with_xterm_new=xterm-new;;
678 esac
679 AC_MSG_RESULT($with_xterm_new)
680 WHICH_XTERM=$with_xterm_new
681 AC_SUBST(WHICH_XTERM)
682
683 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
684 AC_ARG_WITH(xterm-kbs,
685         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
686         [with_xterm_kbs=$withval],
687         [with_xterm_kbs=BS])
688 case x$with_xterm_kbs in
689 (xyes|xno|xBS|xbs|x8)
690         with_xterm_kbs=BS
691         ;;
692 (xDEL|xdel|x127)
693         with_xterm_kbs=DEL
694         ;;
695 (*)
696         with_xterm_kbs=$withval
697         ;;
698 esac
699 AC_MSG_RESULT($with_xterm_kbs)
700 XTERM_KBS=$with_xterm_kbs
701 AC_SUBST(XTERM_KBS)
702
703 MAKE_TERMINFO=
704 if test "$use_database" = no ; then
705         TERMINFO="${datadir}/terminfo"
706         MAKE_TERMINFO="#"
707 else
708
709 AC_MSG_CHECKING(for list of terminfo directories)
710 CF_WITH_PATHLIST(terminfo-dirs,
711         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
712         TERMINFO_DIRS,
713         DATADIR/terminfo,
714         ${datadir}/terminfo)
715 AC_MSG_RESULT($TERMINFO_DIRS)
716 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
717
718 case "x$TERMINFO" in
719 x???:*)
720         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
721         unset TERMINFO
722         ;;
723 esac
724
725 AC_MSG_CHECKING(for default terminfo directory)
726 CF_WITH_PATH(default-terminfo-dir,
727         [  --with-default-terminfo-dir=DIR default terminfo directory],
728         TERMINFO,
729         DATADIR/terminfo,
730         ${datadir}/terminfo)
731 AC_MSG_RESULT($TERMINFO)
732 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
733
734 fi
735
736 AC_SUBST(TERMINFO)
737 AC_SUBST(MAKE_TERMINFO)
738
739 ###     use option --disable-big-core to make tic run on small machines
740 ###     We need 4Mb, check if we can allocate 50% more than that.
741 AC_MSG_CHECKING(if big-core option selected)
742 AC_ARG_ENABLE(big-core,
743         [  --disable-big-core      assume machine has little memory],
744         [with_big_core=$enableval],
745         [AC_TRY_RUN([
746 #include <stdlib.h>
747 #include <string.h>
748 int main() {
749         unsigned long n = 6000000L;
750         char *s = malloc(n);
751         if (s != 0)
752                 s[0] = s[n-1] = 0;
753         ${cf_cv_main_return:-return}(s == 0);
754 }],
755         [with_big_core=yes],
756         [with_big_core=no],
757         [with_big_core=no])])
758 AC_MSG_RESULT($with_big_core)
759 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
760
761 ### ISO C only guarantees 512-char strings, we have tables which load faster
762 ### when constructed using "big" strings.  More than the C compiler, the awk
763 ### program is a limit on most vendor UNIX systems.  Check that we can build.
764 AC_MSG_CHECKING(if big-strings option selected)
765 AC_ARG_ENABLE(big-strings,
766         [  --disable-big-strings   assume compiler has only standard-size strings],
767         [with_big_strings=$enableval],
768         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
769 AC_MSG_RESULT($with_big_strings)
770
771 USE_BIG_STRINGS=0
772 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
773 AC_SUBST(USE_BIG_STRINGS)
774
775 ###     use option --enable-termcap to compile in the termcap fallback support
776 AC_MSG_CHECKING(if you want termcap-fallback support)
777 AC_ARG_ENABLE(termcap,
778         [  --enable-termcap        compile in termcap fallback support],
779         [with_termcap=$enableval],
780         [with_termcap=no])
781 AC_MSG_RESULT($with_termcap)
782
783 NCURSES_USE_TERMCAP=0
784 if test "x$with_termcap" != "xyes" ; then
785         if test "$use_database" = no ; then
786                 if test -z "$with_fallback" ; then
787                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
788                 fi
789         fi
790         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
791 else
792
793         if test "$with_ticlib" != no ; then
794                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
795         fi
796
797         NCURSES_USE_TERMCAP=1
798         AC_MSG_CHECKING(for list of termcap files)
799         CF_WITH_PATHLIST(termpath,
800                 [  --with-termpath=XXX     specify list of termcap files],
801                 TERMPATH,
802                 /etc/termcap:/usr/share/misc/termcap)
803         AC_MSG_RESULT($TERMPATH)
804         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
805
806         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
807         AC_MSG_CHECKING(if fast termcap-loader is needed)
808         AC_ARG_ENABLE(getcap,
809                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
810                 [with_getcap=$enableval],
811                 [with_getcap=no])
812         AC_MSG_RESULT($with_getcap)
813         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
814
815         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
816         AC_ARG_ENABLE(getcap-cache,
817                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
818                 [with_getcap_cache=$enableval],
819                 [with_getcap_cache=no])
820         AC_MSG_RESULT($with_getcap_cache)
821         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
822
823 fi
824 AC_SUBST(NCURSES_USE_TERMCAP)
825
826 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
827 AC_MSG_CHECKING(if ~/.terminfo is wanted)
828 AC_ARG_ENABLE(home-terminfo,
829         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
830         [with_home_terminfo=$enableval],
831         [with_home_terminfo=yes])
832 AC_MSG_RESULT($with_home_terminfo)
833 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
834
835 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
836 AC_ARG_ENABLE(root-environ,
837         [  --disable-root-environ  restrict environment when running as root],
838         [with_root_environ=$enableval],
839         [with_root_environ=yes])
840 AC_MSG_RESULT($with_root_environ)
841 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
842
843 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
844 ###   to reduce storage requirements for the terminfo database.
845 CF_LINK_FUNCS
846
847 with_links=no
848 with_symlinks=no
849
850 # soft links (symbolic links) are useful for some systems where hard links do
851 # not work, or to make it simpler to copy terminfo trees around.
852 if test "x$ac_cv_func_symlink" = xyes ; then
853         AC_MSG_CHECKING(if tic should use symbolic links)
854         AC_ARG_ENABLE(symlinks,
855         [  --enable-symlinks       make tic use symbolic links not hard links],
856         [with_symlinks=$enableval],
857         [with_symlinks=no])
858         AC_MSG_RESULT($with_symlinks)
859 fi
860
861 # If we have hard links and did not choose to use soft links instead, there is
862 # no reason to make this choice optional - use the hard links.
863 if test "$with_symlinks" = no ; then
864         AC_MSG_CHECKING(if tic should use hard links)
865         if test "x$ac_cv_func_link" = xyes ; then
866                 with_links=yes
867         else
868                 with_links=no
869         fi
870         AC_MSG_RESULT($with_links)
871 fi
872
873 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
874 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
875
876 ###   use option --enable-broken-linker to force on use of broken-linker support
877 CF_ENABLE_BROKEN_LINKER
878
879 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
880 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
881 AC_ARG_ENABLE(bsdpad,
882         [  --enable-bsdpad         recognize BSD-style prefix padding],
883         [with_bsdpad=$enableval],
884         [with_bsdpad=no])
885 AC_MSG_RESULT($with_bsdpad)
886 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
887
888 ###   use option --enable-widec to turn on use of wide-character support
889 NCURSES_CH_T=chtype
890 NCURSES_LIBUTF8=0
891
892 NEED_WCHAR_H=0
893 NCURSES_MBSTATE_T=0
894 NCURSES_WCHAR_T=0
895 NCURSES_WINT_T=0
896
897 # Check to define _XOPEN_SOURCE "automatically"
898 CPPFLAGS_before_XOPEN="$CPPFLAGS"
899 CF_XOPEN_SOURCE(600)
900 CPPFLAGS_after_XOPEN="$CPPFLAGS"
901
902 # Work around breakage on OS X
903 CF_SIGWINCH
904
905 # Checks for CODESET support.
906 AM_LANGINFO_CODESET
907
908 # use these variables to work around a defect in gcc's fixincludes.
909 NCURSES_OK_WCHAR_T=
910 NCURSES_OK_WINT_T=
911
912 AC_MSG_CHECKING(if you want wide-character code)
913 AC_ARG_ENABLE(widec,
914         [  --enable-widec          compile with wide-char/UTF-8 code],
915         [with_widec=$enableval],
916         [with_widec=no])
917 AC_MSG_RESULT($with_widec)
918
919 NCURSES_WCWIDTH_GRAPHICS=1
920 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
921
922 if test "x$with_widec" = xyes ; then
923         if test "x$disable_lib_suffixes" = xno ; then
924                 LIB_SUFFIX="w${LIB_SUFFIX}"
925         fi
926         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
927         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
928
929         CF_CHECK_WCHAR_H
930         CF_CHECK_WCWIDTH_GRAPHICS
931         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
932
933         # with_overwrite=no
934         NCURSES_CH_T=cchar_t
935         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
936         if test "x$ac_cv_func_putwc" != xyes ; then
937                 CF_UTF8_LIB
938                 if test "$cf_cv_utf8_lib" != no ; then
939                         NCURSES_LIBUTF8=1
940                 fi
941         fi
942         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
943         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
944         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
945
946         if test "$NCURSES_MBSTATE_T" != 0; then
947                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
948         fi
949 fi
950 AC_SUBST(NCURSES_CH_T)
951 AC_SUBST(NCURSES_LIBUTF8)
952
953 AC_SUBST(NEED_WCHAR_H)
954 AC_SUBST(NCURSES_MBSTATE_T)
955 AC_SUBST(NCURSES_WCHAR_T)
956 AC_SUBST(NCURSES_WINT_T)
957
958 AC_SUBST(NCURSES_OK_WCHAR_T)
959 AC_SUBST(NCURSES_OK_WINT_T)
960
961 ###   use option --disable-lp64 to allow long chtype
962 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
963 AC_ARG_ENABLE(lp64,
964         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
965         [with_lp64=$enableval],
966         [with_lp64=$cf_dft_with_lp64])
967 AC_MSG_RESULT($with_lp64)
968
969 if test "x$with_lp64" = xyes ; then
970         cf_cv_enable_lp64=1
971 else
972         cf_cv_enable_lp64=0
973 fi
974 AC_SUBST(cf_cv_enable_lp64)
975
976 CF_LARGEFILE
977
978 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
979 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
980 AC_ARG_ENABLE(tparm-varargs,
981         [  --disable-tparm-varargs compile tparm() without varargs interface],
982         [with_tparm_varargs=$enableval],
983         [with_tparm_varargs=yes])
984 AC_MSG_RESULT($with_tparm_varargs)
985 NCURSES_TPARM_VARARGS=0
986 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
987 AC_SUBST(NCURSES_TPARM_VARARGS)
988
989 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
990 if test "$with_ticlib" != no ; then
991 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
992 AC_ARG_ENABLE(tic-depends,
993         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
994         [with_tic_depends=$enableval],
995         [with_tic_depends=yes])
996 AC_MSG_RESULT($with_tic_depends)
997 else
998         with_tic_depends=no
999 fi
1000
1001 ###   use option --disable-wattr-macros to suppress wattr* macros from curses.h
1002 AC_MSG_CHECKING(if you want to suppress wattr* macros to help with ncurses5/ncurses6 transition)
1003 AC_ARG_ENABLE(wattr-macros,
1004         [  --disable-wattr-macros  suppress wattr* macros to help with ncurses5/ncurses6 transition],
1005         [with_wattr_macros=$enableval],
1006         [with_wattr_macros=yes])
1007 if [[ "x$with_wattr_macros" != xyes ]]; then
1008         NCURSES_WATTR_MACROS=0
1009         AC_MSG_RESULT(yes)
1010 else
1011         NCURSES_WATTR_MACROS=1
1012         AC_MSG_RESULT(no)
1013 fi
1014 AC_SUBST(NCURSES_WATTR_MACROS)
1015
1016 CF_WITH_X11_RGB
1017
1018 ###   use option --with-bool to override bool's type
1019 AC_MSG_CHECKING(for type of bool)
1020 AC_ARG_WITH(bool,
1021         [  --with-bool=TYPE        override fallback type of bool variable],
1022         [NCURSES_BOOL="$withval"],
1023         [NCURSES_BOOL=auto])
1024 AC_MSG_RESULT($NCURSES_BOOL)
1025 AC_SUBST(NCURSES_BOOL)
1026
1027 AC_MSG_CHECKING(for alternate terminal capabilities file)
1028 AC_ARG_WITH(caps,
1029         [  --with-caps=alt         compile with alternate Caps file],
1030         [TERMINFO_CAPS=Caps.$withval],
1031         [TERMINFO_CAPS=Caps])
1032 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
1033 AC_MSG_RESULT($TERMINFO_CAPS)
1034 AC_SUBST(TERMINFO_CAPS)
1035
1036 ###   use option --with-chtype to override chtype's type
1037 AC_MSG_CHECKING(for type of chtype)
1038 AC_ARG_WITH(chtype,
1039         [  --with-chtype=TYPE      override type of chtype],
1040         [NCURSES_CHTYPE="$withval"],
1041         [NCURSES_CHTYPE=$cf_dft_chtype])
1042 AC_MSG_RESULT($NCURSES_CHTYPE)
1043
1044 ###   use option --with-ospeed to override ospeed's type
1045 AC_MSG_CHECKING(for type of ospeed)
1046 AC_ARG_WITH(ospeed,
1047         [  --with-ospeed=TYPE      override type of ospeed variable],
1048         [NCURSES_OSPEED="$withval"],
1049         [NCURSES_OSPEED=short])
1050 AC_MSG_RESULT($NCURSES_OSPEED)
1051 AC_SUBST(NCURSES_OSPEED)
1052
1053 ###   use option --with-mmask-t to override mmask_t's type
1054 AC_MSG_CHECKING(for type of mmask_t)
1055 AC_ARG_WITH(mmask-t,
1056         [  --with-mmask-t=TYPE     override type of mmask_t],
1057         [NCURSES_MMASK_T="$withval"],
1058         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1059 AC_MSG_RESULT($NCURSES_MMASK_T)
1060
1061 ###   use option --with-ccharw-max to override CCHARW_MAX size
1062 AC_MSG_CHECKING(for size CCHARW_MAX)
1063 AC_ARG_WITH(ccharw-max,
1064         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1065         [NCURSES_CCHARW_MAX="$withval"],
1066         [NCURSES_CCHARW_MAX=5])
1067 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1068 AC_SUBST(NCURSES_CCHARW_MAX)
1069
1070 AC_CHECK_SIZEOF([signed char])
1071 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1072         NCURSES_SBOOL="signed char"
1073 else
1074         NCURSES_SBOOL="char"
1075 fi
1076 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1077 AC_ARG_ENABLE(signed-char,
1078         [  --enable-signed-char    compile using signed Boolean's in term.h],
1079         [with_signed_char=$enableval],
1080         [with_signed_char=no])
1081 AC_MSG_RESULT($with_signed_char)
1082 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1083 AC_SUBST(NCURSES_SBOOL)
1084
1085 ###   use option --with-tparm-arg to override tparm's argument type
1086 AC_MSG_CHECKING(for type of tparm args)
1087 AC_ARG_WITH(tparm-arg,
1088         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1089         [NCURSES_TPARM_ARG="$withval"],
1090         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1091 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1092 AC_SUBST(NCURSES_TPARM_ARG)
1093
1094 ### Enable compiling-in rcs id's
1095 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1096 AC_ARG_WITH(rcs-ids,
1097         [  --with-rcs-ids          compile-in RCS identifiers],
1098         [with_rcs_ids=$withval],
1099         [with_rcs_ids=no])
1100 AC_MSG_RESULT($with_rcs_ids)
1101 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1102
1103 ###############################################################################
1104 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1105
1106 ###############################################################################
1107 CF_HELP_MESSAGE(Extensions:)
1108
1109 ### Note that some functions (such as const) are normally disabled anyway.
1110 AC_MSG_CHECKING(if you want to build with function extensions)
1111 AC_ARG_ENABLE(ext-funcs,
1112         [  --disable-ext-funcs     disable function-extensions],
1113         [with_ext_funcs=$enableval],
1114         [with_ext_funcs=yes])
1115 AC_MSG_RESULT($with_ext_funcs)
1116 if test "x$with_ext_funcs" = xyes ; then
1117         NCURSES_EXT_FUNCS=1
1118         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1119         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1120         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1121         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1122         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1123         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1124         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1125         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1126         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1127         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1128         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1129         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1130         GENERATED_EXT_FUNCS=generated
1131         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1132 else
1133         NCURSES_EXT_FUNCS=0
1134         GENERATED_EXT_FUNCS=
1135 fi
1136 AC_SUBST(NCURSES_EXT_FUNCS)
1137 AC_SUBST(GENERATED_EXT_FUNCS)
1138
1139 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1140 AC_ARG_ENABLE(sp-funcs,
1141         [  --enable-sp-funcs       enable SCREEN-extensions],
1142         [with_sp_funcs=$enableval],
1143         [with_sp_funcs=$cf_dft_ext_spfuncs])
1144 AC_MSG_RESULT($with_sp_funcs)
1145 if test "x$with_sp_funcs" = xyes ; then
1146         NCURSES_SP_FUNCS=1
1147         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1148         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1149         GENERATED_SP_FUNCS=generated
1150 else
1151         NCURSES_SP_FUNCS=0
1152         GENERATED_SP_FUNCS=
1153 fi
1154 AC_SUBST(NCURSES_SP_FUNCS)
1155 AC_SUBST(GENERATED_SP_FUNCS)
1156
1157 AC_MSG_CHECKING(if you want to build with terminal-driver)
1158 AC_ARG_ENABLE(term-driver,
1159         [  --enable-term-driver    enable terminal-driver],
1160         [with_term_driver=$enableval],
1161         [with_term_driver=no])
1162 AC_MSG_RESULT($with_term_driver)
1163 if test "x$with_term_driver" = xyes ; then
1164         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1165         if test "x$with_termlib" != xno ; then
1166                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1167         fi
1168         if test "x$with_sp_funcs" != xyes ; then
1169                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1170         fi
1171 fi
1172
1173 ###   use option --enable-const to turn on use of const beyond that in XSI.
1174 AC_MSG_CHECKING(for extended use of const keyword)
1175 AC_ARG_ENABLE(const,
1176         [  --enable-const          compile with extra/non-standard const],
1177         [with_ext_const=$enableval],
1178         [with_ext_const=$cf_dft_ext_const])
1179 AC_MSG_RESULT($with_ext_const)
1180 NCURSES_CONST='/*nothing*/'
1181 if test "x$with_ext_const" = xyes ; then
1182         NCURSES_CONST=const
1183 fi
1184 AC_SUBST(NCURSES_CONST)
1185
1186 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1187 AC_MSG_CHECKING(if you want to use extended colors)
1188 AC_ARG_ENABLE(ext-colors,
1189         [  --enable-ext-colors     compile for 256-color support],
1190         [with_ext_colors=$enableval],
1191         [with_ext_colors=$cf_dft_ext_colors])
1192 AC_MSG_RESULT($with_ext_colors)
1193 NCURSES_EXT_COLORS=0
1194 if test "x$with_ext_colors" = xyes ; then
1195         if test "x$with_widec" != xyes ; then
1196                 AC_MSG_WARN(This option applies only to wide-character library)
1197         else
1198                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1199                 CF_NCURSES_ABI_6
1200                 NCURSES_EXT_COLORS=1
1201                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1202                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1203                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1204                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1205         fi
1206 fi
1207 AC_SUBST(NCURSES_EXT_COLORS)
1208
1209 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1210 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1211 AC_ARG_ENABLE(ext-mouse,
1212         [  --enable-ext-mouse      compile for extended mouse-encoding],
1213         [with_ext_mouse=$enableval],
1214         [with_ext_mouse=$cf_dft_ext_mouse])
1215 AC_MSG_RESULT($with_ext_mouse)
1216 NCURSES_MOUSE_VERSION=1
1217 if test "x$with_ext_mouse" = xyes ; then
1218         NCURSES_MOUSE_VERSION=2
1219         CF_NCURSES_ABI_6
1220 fi
1221 AC_SUBST(NCURSES_MOUSE_VERSION)
1222
1223 ###   use option --enable-ext-putwin to turn on extended screendumps
1224 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1225 AC_ARG_ENABLE(ext-putwin,
1226         [  --enable-ext-putwin     compile with extended putwin/screendump],
1227         [with_ext_putwin=$enableval],
1228         [with_ext_putwin=$cf_dft_ext_putwin])
1229 AC_MSG_RESULT($with_ext_putwin)
1230 if test "x$with_ext_putwin" = xyes ; then
1231         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1232 fi
1233
1234 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1235 AC_ARG_ENABLE(no-padding,
1236         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1237         [with_no_padding=$enableval],
1238         [with_no_padding=$with_ext_funcs])
1239 AC_MSG_RESULT($with_no_padding)
1240 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1241
1242 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1243 AC_MSG_CHECKING(if you want SIGWINCH handler)
1244 AC_ARG_ENABLE(sigwinch,
1245         [  --enable-sigwinch       compile with SIGWINCH handler],
1246         [with_sigwinch=$enableval],
1247         [with_sigwinch=$with_ext_funcs])
1248 AC_MSG_RESULT($with_sigwinch)
1249 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1250
1251 ###   use option --enable-tcap-names to allow user to define new capabilities
1252 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1253 AC_ARG_ENABLE(tcap-names,
1254         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1255         [with_tcap_names=$enableval],
1256         [with_tcap_names=$with_ext_funcs])
1257 AC_MSG_RESULT($with_tcap_names)
1258 NCURSES_XNAMES=0
1259 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1260 AC_SUBST(NCURSES_XNAMES)
1261
1262 ##############################################################################
1263 CF_HELP_MESSAGE(Reentrant Code:)
1264 CF_WITH_PTHREAD
1265
1266 if test "x$with_pthread" != xno; then
1267         AC_CHECK_FUNC(pthread_kill,[
1268                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1269                 AC_ARG_ENABLE(pthreads-eintr,
1270                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1271                         [use_pthreads_eintr=$enableval],
1272                         [use_pthreads_eintr=no])
1273                 AC_MSG_RESULT($use_pthreads_eintr)
1274                 if test "x$use_pthreads_eintr" = xyes ; then
1275                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1276                 fi])
1277
1278         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1279         AC_ARG_ENABLE(weak-symbols,
1280                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1281                 [use_weak_symbols=$enableval],
1282                 [use_weak_symbols=no])
1283         AC_MSG_RESULT($use_weak_symbols)
1284         if test "x$use_weak_symbols" = xyes ; then
1285                 CF_WEAK_SYMBOLS
1286         else
1287                 cf_cv_weak_symbols=no
1288         fi
1289
1290         if test "x$cf_cv_weak_symbols" = xyes ; then
1291                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1292         fi
1293 fi
1294
1295 PTHREAD=
1296 if test "x$with_pthread" = "xyes" ; then
1297         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1298         enable_reentrant=yes
1299         if test "x$cf_cv_weak_symbols" = xyes ; then
1300                 PTHREAD=-lpthread
1301                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1302         fi
1303 fi
1304 AC_SUBST(PTHREAD)
1305
1306 # Reentrant code has to be opaque; there's little advantage to making ncurses
1307 # opaque outside of that, so there is no --enable-opaque option.  We can use
1308 # this option without --with-pthreads, but this will be always set for
1309 # pthreads.
1310 AC_MSG_CHECKING(if you want reentrant code)
1311 AC_ARG_ENABLE(reentrant,
1312         [  --enable-reentrant      compile with reentrant code],
1313         [with_reentrant=$enableval],
1314         [with_reentrant=no])
1315 AC_MSG_RESULT($with_reentrant)
1316 if test "x$with_reentrant" = xyes ; then
1317         cf_cv_enable_reentrant=1
1318         cf_cv_enable_opaque="NCURSES_INTERNALS"
1319         NCURSES_SIZE_T=int
1320         if test "x$cf_cv_weak_symbols" = xyes ; then
1321                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1322                 CF_ADD_LIB(pthread,TEST_LIBS)
1323                 CF_ADD_LIB(pthread,TEST_LIBS2)
1324                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1325         else
1326                 # when not using weak symbols but with_reentrant,
1327                 # add 't' to the library suffix on all platforms
1328                 # except cygwin, where we only do that if ALSO
1329                 # compiling with full thread support.
1330                 case "$host" in
1331                 (*cygwin* | *msys*)
1332                         if test "$with_pthread" = "yes" ; then
1333                                 if test "x$disable_lib_suffixes" = "xno" ; then
1334                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1335                                 fi
1336                         fi ;;
1337                 (*)
1338                         if test "x$disable_lib_suffixes" = "xno" ; then
1339                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1340                         fi
1341                         ;;
1342                 esac
1343         fi
1344         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1345         CF_NCURSES_ABI_6
1346 else
1347         cf_cv_enable_reentrant=0
1348         cf_cv_enable_opaque="NCURSES_OPAQUE"
1349         NCURSES_SIZE_T=short
1350 fi
1351 AC_SUBST(cf_cv_enable_reentrant)
1352 AC_SUBST(cf_cv_enable_opaque)
1353
1354 AC_SUBST(NCURSES_SIZE_T)
1355
1356 AC_MSG_CHECKING(if you want opaque curses-library structures)
1357 CF_ARG_ENABLE(opaque-curses,
1358         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1359         [enable_opaque_curses=yes],[
1360          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1361          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=no
1362         ])
1363 AC_MSG_RESULT($enable_opaque_curses)
1364
1365 test "$cf_cv_enable_reentrant" = 1 && \
1366 test "$enable_opaque_curses" = no && \
1367 AC_MSG_ERROR(reentrant configuration requires opaque library)
1368
1369 AC_MSG_CHECKING(if you want opaque form-library structures)
1370 AC_ARG_ENABLE(opaque-form,
1371         [  --enable-opaque-form    make form-library structures "opaque"],
1372         [enable_opaque_form=yes],[enable_opaque_form=no])
1373 AC_MSG_RESULT($enable_opaque_form)
1374
1375 AC_MSG_CHECKING(if you want opaque menu-library structures)
1376 AC_ARG_ENABLE(opaque-menu,
1377         [  --enable-opaque-menu    make menu-library structures "opaque"],
1378         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1379 AC_MSG_RESULT($enable_opaque_menu)
1380
1381 AC_MSG_CHECKING(if you want opaque panel-library structures)
1382 AC_ARG_ENABLE(opaque-panel,
1383         [  --enable-opaque-panel   make panel-library structures "opaque"],
1384         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1385 AC_MSG_RESULT($enable_opaque_panel)
1386
1387 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1388 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1389 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1390 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1391
1392 AC_SUBST(NCURSES_OPAQUE)
1393 AC_SUBST(NCURSES_OPAQUE_FORM)
1394 AC_SUBST(NCURSES_OPAQUE_MENU)
1395 AC_SUBST(NCURSES_OPAQUE_PANEL)
1396
1397 ### Allow using a different wrap-prefix
1398 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1399         AC_MSG_CHECKING(for prefix used to wrap public variables)
1400         AC_ARG_WITH(wrap-prefix,
1401                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1402                 [NCURSES_WRAP_PREFIX=$withval],
1403                 [NCURSES_WRAP_PREFIX=_nc_])
1404         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1405 else
1406         NCURSES_WRAP_PREFIX=_nc_
1407 fi
1408 AC_SUBST(NCURSES_WRAP_PREFIX)
1409 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1410
1411 ###############################################################################
1412 # These options are relatively safe to experiment with.
1413 CF_HELP_MESSAGE(Development Code:)
1414 AC_MSG_CHECKING(if you want all development code)
1415 AC_ARG_WITH(develop,
1416         [  --without-develop       disable development options],
1417         [with_develop=$withval],
1418         [with_develop=no])
1419 AC_MSG_RESULT($with_develop)
1420
1421 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1422 AC_MSG_CHECKING(if you want hard-tabs code)
1423 AC_ARG_ENABLE(hard-tabs,
1424         [  --enable-hard-tabs      compile with hard-tabs code],,
1425         [enable_hard_tabs=$with_develop])
1426 AC_MSG_RESULT($enable_hard_tabs)
1427 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1428
1429 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1430 AC_MSG_CHECKING(if you want limited support for xmc)
1431 AC_ARG_ENABLE(xmc-glitch,
1432         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1433         [enable_xmc_glitch=$with_develop])
1434 AC_MSG_RESULT($enable_xmc_glitch)
1435 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1436
1437 ###############################################################################
1438 # These are just experimental, probably should not be in a package:
1439 CF_HELP_MESSAGE(Experimental Code:)
1440
1441 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1442 AC_ARG_ENABLE(assumed-color,
1443         [  --disable-assumed-color do not assume anything about default-colors],
1444         [with_assumed_color=$enableval],
1445         [with_assumed_color=yes])
1446 AC_MSG_RESULT($with_assumed_color)
1447 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1448
1449 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1450 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1451 AC_ARG_ENABLE(hashmap,
1452         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1453         [with_hashmap=$enableval],
1454         [with_hashmap=yes])
1455 AC_MSG_RESULT($with_hashmap)
1456 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1457
1458 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1459 AC_MSG_CHECKING(if you want colorfgbg code)
1460 AC_ARG_ENABLE(colorfgbg,
1461         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1462         [with_colorfgbg=$enableval],
1463         [with_colorfgbg=no])
1464 AC_MSG_RESULT($with_colorfgbg)
1465 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1466
1467 ###   use option --enable-fvisibility to turn on use of gcc-specific feature
1468 AC_MSG_CHECKING(if you want to use gcc -fvisibility option)
1469 AC_ARG_ENABLE(fvisibility,
1470         [  --enable-fvisibility    compile with -fvisibility=hidden],
1471         [cf_with_fvisibility=$enableval],
1472         [cf_with_fvisibility=no])
1473 AC_MSG_RESULT($cf_with_fvisibility)
1474
1475 NCURSES_IMPEXP=
1476 NCURSES_CXX_IMPEXP=
1477 if test "x$cf_with_fvisibility" = xyes; then
1478         CF_CHECK_FVISIBILITY($CC,CFLAGS,cf_cv_fvisibility_hidden)
1479         if test "x$cf_cv_fvisibility_hidden" = xyes
1480         then
1481                 CF_ADD_CFLAGS([-fvisibility=hidden])
1482                 NCURSES_IMPEXP="__attribute__ ((visibility(\"default\")))"
1483         fi
1484         if test -n "$CXX"
1485         then
1486                 AC_LANG_PUSH(C++)
1487                 CF_CHECK_FVISIBILITY($CXX,CXXFLAGS,cf_cv_fvisibility_hidden2)
1488                 if test "x$cf_cv_fvisibility_hidden2" = xyes
1489                 then
1490                         CF_ADD_CXXFLAGS([-fvisibility=hidden])
1491                         NCURSES_CXX_IMPEXP="__attribute__ ((visibility(\"default\")))"
1492                 fi
1493                 AC_LANG_POP
1494         fi
1495 fi
1496 AC_SUBST(NCURSES_IMPEXP)
1497 AC_SUBST(NCURSES_CXX_IMPEXP)
1498
1499 ###   use option --enable-interop to turn on use of bindings used for interop
1500 AC_MSG_CHECKING(if you want interop bindings)
1501 AC_ARG_ENABLE(interop,
1502         [  --enable-interop        compile-in interop bindings],
1503         [with_exp_interop=$enableval],
1504         [with_exp_interop=$cf_dft_interop])
1505 AC_MSG_RESULT($with_exp_interop)
1506
1507 NCURSES_INTEROP_FUNCS=0
1508 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1509 AC_SUBST(NCURSES_INTEROP_FUNCS)
1510
1511
1512 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1513 AC_ARG_ENABLE(safe-sprintf,
1514         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1515         [with_safe_sprintf=$enableval],
1516         [with_safe_sprintf=no])
1517 AC_MSG_RESULT($with_safe_sprintf)
1518
1519 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1520 # when hashmap is used scroll hints are useless
1521 if test "$with_hashmap" = no ; then
1522 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1523 AC_ARG_ENABLE(scroll-hints,
1524         [  --disable-scroll-hints  compile without scroll-hints code],
1525         [with_scroll_hints=$enableval],
1526         [with_scroll_hints=yes])
1527 AC_MSG_RESULT($with_scroll_hints)
1528 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1529 fi
1530
1531 AC_MSG_CHECKING(if you want wgetch-events code)
1532 AC_ARG_ENABLE(wgetch-events,
1533         [  --enable-wgetch-events  compile with wgetch-events code],
1534         [with_wgetch_events=$enableval],
1535         [with_wgetch_events=no])
1536 AC_MSG_RESULT($with_wgetch_events)
1537 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1538
1539 ###############################################################################
1540 CF_HELP_MESSAGE(Testing/development Options:)
1541
1542 ###     use option --disable-echo to suppress full display compiling commands
1543 CF_DISABLE_ECHO
1544 if test "x$enable_echo" = xyes; then
1545         ECHO_LINK=
1546 else
1547         ECHO_LINK='@ echo linking $@ ... ;'
1548         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1549         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1550 fi
1551 AC_SUBST(ECHO_LINK)
1552
1553 # --disable-stripping is used for debugging
1554 CF_INSTALL_OPTS
1555
1556 # If we're avoiding relinking of shared libraries during install, that is to
1557 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1558 # the install program has "-p" (for preserving timestamps).
1559 cf_cv_do_reranlib=yes
1560 if test "x$cf_cv_install_p" = xyes
1561 then
1562         if test "x$cf_cv_do_relink" != xyes
1563         then
1564                 cf_cv_do_reranlib=no
1565                 INSTALL_OPT_P="-p"
1566                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1567         fi
1568 fi
1569 AC_SUBST(INSTALL_OPT_P)
1570
1571 ###     use option --enable-warnings to turn on all gcc warnings
1572 AC_MSG_CHECKING(if you want to see compiler warnings)
1573 AC_ARG_ENABLE(warnings,
1574         [  --enable-warnings       build: turn on GCC compiler warnings],
1575         [with_warnings=$enableval])
1576 AC_MSG_RESULT($with_warnings)
1577
1578 if test "x$with_warnings" = "xyes"; then
1579         CF_ADD_ADAFLAGS(-gnatg)
1580         CF_GCC_WARNINGS(Wno-unknown-pragmas Wswitch-enum)
1581         if test "x$cf_with_cxx" = xyes ; then
1582                 CF_GXX_WARNINGS(Wno-unused)
1583         fi
1584 fi
1585 CF_GCC_ATTRIBUTES
1586 CF_ENABLE_STRING_HACKS
1587
1588 ###     use option --enable-assertions to turn on generation of assertion code
1589 AC_MSG_CHECKING(if you want to enable runtime assertions)
1590 AC_ARG_ENABLE(assertions,
1591         [  --enable-assertions     test: turn on generation of assertion code],
1592         [with_assertions=$enableval],
1593         [with_assertions=no])
1594 AC_MSG_RESULT($with_assertions)
1595 if test -n "$GCC"
1596 then
1597         if test "$with_assertions" = no
1598         then
1599                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1600         else
1601                 CF_ADD_ADAFLAGS(-gnata)
1602         fi
1603 fi
1604
1605 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1606 CF_DISABLE_LEAKS
1607 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1608
1609 ###     use option --enable-expanded to generate certain macros as functions
1610 AC_ARG_ENABLE(expanded,
1611         [  --enable-expanded       test: generate functions for certain macros],
1612         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1613
1614 ###     use option --disable-macros to suppress macros in favor of functions
1615 AC_ARG_ENABLE(macros,
1616         [  --disable-macros        test: use functions rather than macros],
1617         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1618
1619 # Normally we only add trace() to the debug-library.  Allow this to be
1620 # extended to all models of the ncurses library:
1621 cf_all_traces=no
1622 case "$CFLAGS $CPPFLAGS" in
1623 (*-DTRACE*)
1624         cf_all_traces=yes
1625         ;;
1626 esac
1627
1628 AC_MSG_CHECKING(whether to add trace feature to all models)
1629 AC_ARG_WITH(trace,
1630 [  --with-trace            test: add trace() function to all models of ncurses],
1631 [cf_with_trace=$withval],
1632 [cf_with_trace=$cf_all_traces])
1633 AC_MSG_RESULT($cf_with_trace)
1634
1635 if test "x$cf_with_trace" = xyes ; then
1636         LIB_TRACING=all
1637         ADA_TRACE=TRUE
1638         CF_ADD_CFLAGS(-DTRACE)
1639         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1640 else
1641         LIB_TRACING=DEBUG
1642         ADA_TRACE=FALSE
1643 fi
1644
1645 AC_SUBST(ADA_TRACE)
1646
1647 CF_DISABLE_GNAT_PROJECTS
1648
1649 ###     Checks for libraries.
1650 case $cf_cv_system_name in
1651 (*mingw32*|*mingw64*)
1652         CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1653         # Note: WINVER may be a problem with Windows 10
1654         ;;
1655 (*)
1656 AC_CHECK_FUNC(gettimeofday,
1657         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1658
1659 AC_CHECK_LIB(bsd, gettimeofday,
1660         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1661         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1662         ;;
1663 esac
1664
1665 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1666 AC_SUBST(MATH_LIB)
1667
1668 ###     Checks for header files.
1669 AC_STDC_HEADERS
1670 AC_HEADER_DIRENT
1671 AC_HEADER_TIME
1672 CF_REGEX
1673
1674 dnl These are some other potentially nonportable headers.
1675 AC_CHECK_HEADERS( \
1676 fcntl.h \
1677 getopt.h \
1678 limits.h \
1679 locale.h \
1680 math.h \
1681 poll.h \
1682 sys/bsdtypes.h \
1683 sys/ioctl.h \
1684 sys/param.h \
1685 sys/poll.h \
1686 sys/select.h \
1687 sys/time.h \
1688 sys/times.h \
1689 ttyent.h \
1690 unistd.h \
1691 wctype.h \
1692 )
1693
1694 CF_GETOPT_HEADER
1695
1696 CF_CHECK_ENVIRON(environ)
1697 CF_CHECK_GETENV
1698 if test "x$cf_cv_consistent_getenv" = xno && \
1699         test "x$cf_with_trace" = xyes
1700 then
1701         AC_MSG_WARN(The NCURSES_TRACE environment variable is not supported with this configuration)
1702 fi
1703
1704 # check for ISC (this may also define _POSIX_SOURCE)
1705 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1706 if test "x$ISC" = xyes ; then
1707         AC_CHECK_LIB(cposix,main)
1708         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1709 fi
1710
1711 CF_SYS_TIME_SELECT
1712
1713 ###     checks for compiler characteristics
1714 AC_LANG_C
1715 AC_C_CONST
1716 CF_C_INLINE(NCURSES_INLINE,1200)
1717 CF_SIG_ATOMIC_T
1718
1719 if test $NCURSES_CHTYPE = auto ; then
1720         CF_TYPEOF_CHTYPE
1721 else
1722         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1723 fi
1724 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1725 AC_SUBST(cf_cv_typeof_chtype)
1726
1727 CF_UNSIGNED_LITERALS
1728 cf_cv_1UL="1"
1729 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1730 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1731 AC_SUBST(cf_cv_1UL)
1732
1733 if test $NCURSES_MMASK_T = auto ; then
1734         cf_cv_typeof_mmask_t=long
1735 else
1736         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1737 fi
1738 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1739 AC_SUBST(cf_cv_typeof_mmask_t)
1740
1741 ###     Checks for external-data
1742 CF_ERRNO
1743 CF_LINK_DATAONLY
1744
1745 ###     Checks for library functions.
1746 AC_CHECK_FUNCS( \
1747 getcwd \
1748 getegid \
1749 geteuid \
1750 getopt \
1751 getttynam \
1752 issetugid \
1753 localeconv \
1754 poll \
1755 putenv \
1756 remove \
1757 select \
1758 setbuf \
1759 setbuffer \
1760 setenv \
1761 setvbuf \
1762 sigaction \
1763 sigvec \
1764 strdup \
1765 strstr \
1766 sysconf \
1767 tcgetpgrp \
1768 times \
1769 tsearch \
1770 vsnprintf \
1771 )
1772
1773 if test "x$ac_cv_func_getopt" = xno && \
1774    test "x$cf_with_progs$cf_with_tests" != xnono; then
1775         AC_MSG_ERROR(getopt is required for building programs)
1776 fi
1777
1778 if test "x$with_safe_sprintf" = xyes
1779 then
1780         if test "x$ac_cv_func_vsnprintf" = xyes
1781         then
1782                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1783         else
1784                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1785         fi
1786 fi
1787
1788 if test "x$with_getcap" = "xyes" ; then
1789         CF_CGETENT
1790 fi
1791
1792 CF_ISASCII
1793 CF_STRUCT_SIGACTION
1794 CF_FUNC_NANOSLEEP
1795 CF_FUNC_TERMIOS
1796 CF_FUNC_VSSCANF
1797 CF_MKSTEMP
1798
1799 # setup for prototype of fallback for vsscanf()
1800 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1801
1802 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1803 if test "x$cross_compiling" = xyes ; then
1804         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1805 else
1806         AC_FUNC_SETVBUF_REVERSED
1807 fi
1808 AC_CHECK_TYPE(intptr_t, long)
1809 AC_CHECK_TYPE(ssize_t, int)
1810 CF_TYPE_SIGACTION
1811 CF_SIZECHANGE
1812 CF_FUNC_MEMMOVE
1813 CF_FUNC_POLL
1814 CF_VA_COPY
1815 AC_FUNC_VFORK
1816 CF_FOPEN_BIN_R
1817
1818 # special check for test/ditto.c
1819 CF_FUNC_OPENPTY
1820 if test "$cf_cv_func_openpty" != no ; then
1821         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1822         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1823         if test "x$cf_cv_lib_util" = xyes ; then
1824                 CF_ADD_LIB(util,TEST_LIBS)
1825         fi
1826 fi
1827 AC_SUBST(TEST_LIBS)
1828 AC_SUBST(TEST_LIBS2)
1829
1830 if test "$with_hashed_db" != no ; then
1831         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1832         CF_HASHED_DB($with_hashed_db)
1833 fi
1834
1835 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1836 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1837         CF_STRIP_G_OPT(CFLAGS)
1838         CF_STRIP_G_OPT(CXXFLAGS)
1839 fi
1840
1841 # Just in case, check if the C compiler has a bool type.
1842 CF_BOOL_DECL(cf_cv_cc_bool_type)
1843
1844 # Check for C++ compiler characteristics (and ensure that it's there!)
1845 if test -n "$CXX" ; then
1846         AC_LANG_CPLUSPLUS
1847         CF_STDCPP_LIBRARY
1848         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1849
1850         case $GXX_VERSION in
1851         (1*|2.[0-6]*)
1852                 cf_cxx_library=yes
1853                 ;;
1854         (*-2.7*|2.7*)
1855                 CF_GPP_LIBRARY
1856                 ;;
1857         (*)
1858                 cf_cxx_library=no
1859                 ;;
1860         esac
1861
1862         AC_CHECK_HEADERS(typeinfo)
1863         CF_CXX_IOSTREAM_NAMESPACE
1864         CF_BOOL_DECL
1865         CF_BOOL_SIZE
1866         CF_ETIP_DEFINES
1867         CF_CPP_PARAM_INIT
1868         CF_CPP_STATIC_CAST
1869         CF_CXX_AR_FLAGS
1870 else
1871         cf_cxx_library=no
1872         cf_cv_builtin_bool=1
1873
1874         # Just because we are not configuring against C++ right now does not
1875         # mean that a user will not want to use C++.  Some distributors disable
1876         # the C++ portion of this configuration as a shortcut (or just to avoid
1877         # compiling the demo in the c++ directory).  So we need a reasonable
1878         # default for the 'bool' type.
1879         #
1880         # Caveat: since the storage of the bool type is not standardized, it
1881         # may change.
1882
1883         if test "$NCURSES_BOOL" != auto ; then
1884                 cf_cv_type_of_bool=$NCURSES_BOOL
1885                 cf_cv_header_stdbool_h=0
1886         else
1887                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1888                         CF_BOOL_SIZE
1889                 else
1890                         AC_MSG_CHECKING(for fallback type of bool)
1891                         case "$host_cpu" in
1892                         (i?86)  cf_cv_type_of_bool=char ;;
1893                         (*)     cf_cv_type_of_bool=int  ;;
1894                         esac
1895                         AC_MSG_RESULT($cf_cv_type_of_bool)
1896                 fi
1897         fi
1898 fi
1899 AC_SUBST(CXXLIBS)
1900
1901 # If the C compiler did not declare bool, and we did not determine that the C++
1902 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1903 # ncurses library use the same type as C++ bool.  Note that this allows one to
1904 # specify the type of bool in a configure-script option and postpone
1905 # integration with the C++ compiler provided that the types are compatible.
1906 USE_CXX_BOOL=1
1907 if test $cf_cv_cc_bool_type = 1
1908 then
1909         # oops: C has a bool.  Unlikely, but C++ could differ.
1910         USE_CXX_BOOL=0
1911 elif test $cf_cv_builtin_bool = 0
1912 then
1913         # C++ has no bool
1914         USE_CXX_BOOL=0
1915 else
1916         # this is the normal case
1917         USE_CXX_BOOL='defined(__cplusplus)'
1918 fi
1919 AC_SUBST(USE_CXX_BOOL)
1920
1921 CF_HELP_MESSAGE(Ada Binding Options:)
1922
1923 dnl If the Ada95 source-tree is present, add that to the build unless it will
1924 dnl not work, or was not requested.
1925 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1926
1927 dnl libtool does not know anything about GNAT, though a change made in 1998
1928 dnl provided for it "someday".  Disable the ada subtree if we are using
1929 dnl libtool -TD 20070714
1930         if test "$cf_with_ada" != "no" ; then
1931                 if test "$with_libtool" != "no"; then
1932                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1933                         cf_with_ada=no
1934                 fi
1935         fi
1936
1937 dnl Check for availability of GNU Ada Translator (GNAT).
1938 dnl At the moment we support no other Ada compiler.
1939         if test "$cf_with_ada" != "no" ; then
1940                 CF_PROG_GNAT
1941                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1942                         CF_ADD_ADAFLAGS(-gnatpn)
1943                         CF_FIXUP_ADAFLAGS
1944
1945                         CF_GNATPREP_OPT_T
1946
1947                         CF_GNAT_GENERICS
1948                         CF_GNAT_SIGINT
1949                         CF_GNAT_PROJECTS
1950
1951                         CF_WITH_ADA_COMPILER
1952
1953                         cf_ada_package=terminal_interface
1954                         AC_SUBST(cf_ada_package)
1955
1956                         CF_WITH_ADA_INCLUDE
1957                         CF_WITH_ADA_OBJECTS
1958                         CF_WITH_ADA_SHAREDLIB
1959
1960                         # allow the Ada binding to be renamed
1961                         CF_WITH_ADA_LIBNAME(AdaCurses)
1962                 fi
1963         fi
1964 else
1965         cf_with_ada=no
1966 fi
1967
1968 # do this "late" to avoid conflict with header-checks
1969 if test "x$with_widec" = xyes ; then
1970         AC_CHECK_SIZEOF(wchar_t)
1971         # cross-compiling to mingw can run into the problem that attempting to
1972         # link with the regex library fails, causing the test to not set this to
1973         # a number.  "recent" autoconf does not address this problem either -TD
1974         if test -z "$ac_cv_sizeof_wchar_t"
1975         then
1976                 CF_VERBOSE(test failed (assume 2))
1977                 sed /SIZEOF_WCHAR_T/d confdefs.h >confdefs.tmp
1978                 mv confdefs.tmp confdefs.h
1979                 echo "#define SIZEOF_WCHAR_T 2" >>confdefs.h
1980         fi
1981 fi
1982
1983 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1984 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1985 ###
1986 ### ticlib modules may be a separate library, otherwise contained in termlib.
1987 ### termlib modules may be a separate library, otherwise contained in ncurses.
1988 ###
1989 ### The of "+" or " " between the tokens controls the way the script
1990 ### chooses to split module lists into libraries.
1991 ###
1992 ### (see CF_LIB_RULES).
1993 AC_MSG_CHECKING(for library subsets)
1994 LIB_SUBSETS=
1995
1996 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1997         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1998         if test "$with_ticlib" != no ; then
1999                 LIB_SUBSETS="${LIB_SUBSETS} "
2000         else
2001                 LIB_SUBSETS="${LIB_SUBSETS}+"
2002         fi
2003 fi
2004
2005 LIB_SUBSETS="${LIB_SUBSETS}termlib"
2006 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
2007
2008 if test "$with_termlib" != no ; then
2009         LIB_SUBSETS="${LIB_SUBSETS} "
2010 else
2011         LIB_SUBSETS="${LIB_SUBSETS}+"
2012 fi
2013
2014 LIB_SUBSETS="${LIB_SUBSETS}base"
2015
2016 # Most term-driver calls are to tinfo, but some like init_pair are to the
2017 # base library (so it resides in base).
2018 if test "$with_term_driver" != no ; then
2019         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
2020         case $cf_cv_system_name in
2021         (*mingw32*|*mingw64*)
2022                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
2023                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
2024                 ;;
2025         (*)
2026                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
2027                 ;;
2028         esac
2029 fi
2030
2031 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
2032 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
2033
2034 AC_MSG_RESULT($LIB_SUBSETS)
2035
2036 ### Construct the list of include-directories to be generated
2037 CF_INCLUDE_DIRS
2038 CF_ADA_INCLUDE_DIRS
2039
2040 ### Build up pieces for makefile rules
2041 AC_MSG_CHECKING(default library suffix)
2042 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
2043 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
2044 AC_MSG_RESULT($DFT_ARG_SUFFIX)
2045
2046 AC_MSG_CHECKING(default library-dependency suffix)
2047 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
2048 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
2049 AC_MSG_RESULT($DFT_DEP_SUFFIX)
2050
2051 AC_MSG_CHECKING(default object directory)
2052 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
2053 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
2054 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
2055
2056 if test "x$cf_with_cxx" = xyes ; then
2057 AC_MSG_CHECKING(c++ library-dependency suffix)
2058 if test "$with_libtool" != "no"; then
2059         # libtool thinks it can make c++ shared libraries (perhaps only g++)
2060         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2061 elif test "$with_shared_cxx" != "no"; then
2062         # also for g++ users...
2063         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2064 else
2065         # we normally make a static library because C/C++ library rules differ
2066         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
2067 fi
2068 AC_MSG_RESULT($CXX_LIB_SUFFIX)
2069 AC_SUBST(CXX_LIB_SUFFIX)
2070 fi
2071
2072 # do not want -ldl in build except as needed for -lncurses dependency
2073 if test "x$with_dlsym" = xyes ; then
2074 if test $DFT_LWR_MODEL = shared || \
2075    test $DFT_LWR_MODEL = libtool ; then
2076         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2077 fi
2078 fi
2079 ### Set up low-level terminfo dependencies for makefiles.
2080
2081 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2082 # do not need libdl
2083 TICS_LIST=
2084 if test "x$with_dlsym" = xyes ; then
2085         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2086 fi
2087
2088 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2089 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2090 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2091 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2092 then
2093         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2094 fi
2095 AC_SUBST(USE_ARG_SUFFIX)
2096 AC_SUBST(USE_CFG_SUFFIX)
2097 AC_SUBST(USE_LIB_SUFFIX)
2098
2099 if test "$with_ticlib" != no ; then
2100
2101         if test "x$with_ticlib" != xyes ; then
2102                 TICS_NAME=$with_ticlib
2103                 TICS_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2104                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2105                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2106                 TICS_LIB_SUFFIX="${with_ticlib}"
2107         else
2108                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2109                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2110                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2111                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2112         fi
2113         TICS_LDFLAGS="-L${LIB_DIR}"
2114         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2115 else
2116         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2117         TICS_LDFLAGS="-L${LIB_DIR}"
2118         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2119 fi
2120 AC_SUBST(TICS_ARG_SUFFIX)
2121 AC_SUBST(TICS_DEP_SUFFIX)
2122 AC_SUBST(TICS_LIB_SUFFIX)
2123 AC_SUBST(TICS_LDFLAGS)
2124 AC_SUBST(TICS_LIBS)
2125
2126 if test "$with_termlib" != no ; then
2127
2128         if test "x$with_termlib" != xyes ; then
2129                 TINFO_NAME=$with_termlib
2130                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2131                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2132                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2133                 TINFO_LIB_SUFFIX="${with_termlib}"
2134         else
2135                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2136                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2137                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2138                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2139         fi
2140
2141         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2142         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2143         if test "$DFT_LWR_MODEL" = "libtool"; then
2144                 TEST_ARGS="${TEST_DEPS}"
2145                 TEST_ARG2="${TEST_DEP2}"
2146                 TINFO_LDFLAGS="-L${LIB_DIR}"
2147                 TINFO_LIBS="$TEST_ARGS"
2148                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2149                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2150         else
2151                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2152                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2153                 if test "x$with_term_driver" != xno ; then
2154                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2155                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2156                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2157                 else
2158                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2159                         TINFO_LIBS="$TEST_ARGS"
2160                 fi
2161                 TINFO_LDFLAGS="-L${LIB_DIR}"
2162                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2163         fi
2164 else
2165         # the next lines are needed for linking libtic over libncurses
2166         TINFO_NAME=${LIB_NAME}
2167         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2168         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2169         if test "x$with_tic_depends" = xyes ; then
2170                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2171         else
2172                 TICS_LIST="$SHLIB_LIST"
2173         fi
2174
2175         TINFO_LDFLAGS="-L${LIB_DIR}"
2176         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2177 fi
2178
2179 if test "$DFT_LWR_MODEL" = shared ; then
2180         case $cf_cv_system_name in
2181         (cygwin*|msys*)
2182                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2183                 TINFO_SUFFIX=.dll
2184                 ;;
2185         esac
2186 fi
2187
2188 AC_SUBST(TINFO_ARG_SUFFIX)
2189 AC_SUBST(TINFO_DEP_SUFFIX)
2190 AC_SUBST(TINFO_LIB_SUFFIX)
2191 AC_SUBST(TINFO_LDFLAGS)
2192 AC_SUBST(TINFO_LIBS)
2193
2194 if test "x$with_dlsym" = xyes ; then
2195         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2196 fi
2197
2198 if test "$DFT_LWR_MODEL" = "libtool"; then
2199         OBJEXT=lo
2200 fi
2201
2202 # needed for Ada95
2203 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2204 AC_SUBST(TINFO_LDFLAGS2)
2205
2206 case $DFT_LWR_MODEL in
2207 (normal|debug|profile)
2208         CF_LDFLAGS_STATIC
2209         ;;
2210 esac
2211
2212 AC_MSG_CHECKING(where we will install curses.h)
2213 AC_SUBST(includesubdir)
2214 includesubdir=
2215 if test "$with_overwrite" = no && \
2216  ( test "x$includedir" = 'x${prefix}/include' || \
2217    test "x$includedir" = "x${prefix}/include" )
2218 then
2219         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2220 fi
2221 AC_MSG_RESULT(${includedir}${includesubdir})
2222
2223 ### Resolve a conflict between normal and wide-curses by forcing applications
2224 ### that will need libutf8 to add it to their configure script.
2225 if test "$with_overwrite" != no ; then
2226 if test "$NCURSES_LIBUTF8" = 1 ; then
2227         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2228         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2229 fi
2230 fi
2231 WITH_OVERWRITE=$with_overwrite
2232
2233 AC_SUBST(WITH_OVERWRITE)
2234 AC_SUBST(TICS_LIST)
2235 AC_SUBST(TINFO_LIST)
2236 AC_SUBST(SHLIB_LIST)
2237
2238 # used to separate tack out of the tree
2239 NCURSES_TREE=
2240 AC_SUBST(NCURSES_TREE)
2241
2242 ### predefined stuff for the test programs
2243 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2244
2245 # pkgsrc uses these
2246 CF_WITH_LIB_BASENAME(FORM_NAME,form)
2247 CF_WITH_LIB_BASENAME(MENU_NAME,menu)
2248 CF_WITH_LIB_BASENAME(PANEL_NAME,panel)
2249 CF_WITH_LIB_BASENAME(CXX_NAME,cxx,ncurses++)
2250
2251 ### Construct the list of subdirectories for which we'll customize makefiles
2252 ### with the appropriate compile-rules.
2253
2254 CF_SRC_MODULES($modules_to_build)
2255
2256 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2257    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/src/library.gpr:Ada95/src/library.gpr.in"
2258    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2259    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2260 fi
2261
2262 CF_DIRS_TO_MAKE
2263
2264 # symbols that differ when compiling Ada95 by itself.
2265 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2266 AC_SUBST(NCURSES_SHLIB2)
2267
2268 # values to use as strings
2269 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2270
2271 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2272
2273 ### Now that we're done running tests, add the compiler-warnings, if any
2274 CF_ADD_CFLAGS($EXTRA_CFLAGS)
2275
2276 ### Define substitutions for header files to avoid name-pollution
2277 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2278 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2279 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2280 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2281
2282 ################################################################################
2283 test "x$use_database" = xyes && \
2284 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2285
2286 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2287 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2288
2289 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2290 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2291 fi
2292 AC_SUBST(cross_compiling)
2293
2294 if test "x$cf_with_tests" != xno ; then
2295         MAKE_TESTS=
2296 else
2297         MAKE_TESTS="#"
2298 fi
2299 AC_SUBST(MAKE_TESTS)
2300
2301 ADAHTML_DIR=../../doc/html/ada
2302 AC_SUBST(ADAHTML_DIR)
2303
2304 # workaround for OS/2 (20151017)
2305 case $cf_cv_system_name in
2306 (os2*)
2307         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2308         ;;
2309 (*)
2310         LIBTOOL_OPTS_CXX=
2311         ;;
2312 esac
2313 AC_SUBST(LIBTOOL_OPTS_CXX)
2314
2315 # workaround for g++ versus Solaris (20131116)
2316 case $cf_cv_system_name in
2317 (solaris2*)
2318         case "x$CPPFLAGS" in
2319         (*-D_XOPEN_SOURCE_EXTENDED*)
2320                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2321                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2322                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2323                 ;;
2324         esac
2325         ;;
2326 esac
2327
2328 # Help to automatically enable the extended curses features when using either
2329 # the *-config or the ".pc" files by adding defines.
2330 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2331 PKG_CFLAGS=
2332 for cf_loop1 in $CPPFLAGS_after_XOPEN
2333 do
2334         cf_found=no
2335         for cf_loop2 in $CPPFLAGS_before_XOPEN
2336         do
2337                 if test "x$cf_loop1" = "x$cf_loop2"
2338                 then
2339                         cf_found=yes
2340                         break
2341                 fi
2342         done
2343         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2344 done
2345 AC_MSG_RESULT($PKG_CFLAGS)
2346 AC_SUBST(PKG_CFLAGS)
2347
2348 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2349 case "x$NCURSES_OSPEED" in
2350 (*short*)
2351         cf_compatible=1
2352         ;;
2353 (*)
2354         cf_compatible=0
2355         ;;
2356 esac
2357 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2358
2359 case "x$cf_cv_typeof_chtype" in
2360 (xshort|xint|xlong)
2361         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2362         ;;
2363 esac
2364
2365 case "x$cf_cv_typeof_mmask_t" in
2366 (xshort|xint|xlong)
2367         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2368         ;;
2369 esac
2370
2371 # substitute into misc/Makefile to suppress
2372 # (un)install.data from the
2373 # (un)install rules.
2374 if test "x$cf_with_db_install" = "xno"; then
2375         MISC_INSTALL_DATA=
2376         MISC_UNINSTALL_DATA=
2377 else
2378         MISC_INSTALL_DATA=install.data
2379         MISC_UNINSTALL_DATA=uninstall.data
2380 fi
2381 AC_SUBST(MISC_INSTALL_DATA)
2382 AC_SUBST(MISC_UNINSTALL_DATA)
2383
2384 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2385         MAKE_DATABASE="#"
2386 else
2387         MAKE_DATABASE="$MAKE_TERMINFO"
2388 fi
2389 AC_SUBST(MAKE_DATABASE)
2390
2391 dnl Override the package used for exported symbols
2392 if test -n "$PACKAGE"
2393 then
2394         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2395         export PACKAGE
2396         echo "package: $PACKAGE"
2397 fi
2398
2399 UNALTERED_SYMS=
2400 cf_filter_syms=no
2401
2402 if test -n "$RESULTING_SYMS"
2403 then
2404         cf_filter_syms=$cf_dft_filter_syms
2405         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2406 fi
2407
2408 if test "x$WILDCARD_SYMS" = xno
2409 then
2410         cf_filter_syms=yes
2411 fi
2412
2413 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2414
2415 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2416 if test $cf_filter_syms = yes
2417 then
2418         RESULTING_SYMS=resulting.map
2419 fi
2420 AC_SUBST(UNALTERED_SYMS)
2421
2422 if test "x$cross_compiling" = xyes ; then
2423         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2424         CHECK_BUILD="#"
2425 else
2426         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2427         CHECK_BUILD=
2428 fi
2429 AC_SUBST(ADAGEN_LDFLAGS)
2430 AC_SUBST(CHECK_BUILD)
2431 AC_SUBST(PRIVATE_LIBS)
2432
2433 # This is used for the *-config script and *.pc data files.
2434 CF_LD_SEARCHPATH
2435
2436 AC_DEFINE(HAVE_CURSES_DATA_BOOLNAMES,1,[definition needed for in-tree build of tack])
2437
2438 AC_OUTPUT( \
2439         include/MKterm.h.awk \
2440         include/curses.head:include/curses.h.in \
2441         include/ncurses_dll.h \
2442         include/termcap.h \
2443         include/unctrl.h \
2444         $SUB_MAKEFILES \
2445         Makefile,[
2446 if test "x$cf_with_tests" != xno ; then
2447         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2448 fi
2449 CF_LIB_RULES($SRC_SUBDIRS)
2450
2451 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2452 if test -z "$USE_OLD_MAKERULES" ; then
2453         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
2454 fi
2455 fi
2456 ],[
2457 ### Special initialization commands, used to pass information from the
2458 ### configuration-run into config.status
2459
2460 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2461 AWK="$AWK"
2462 CXX_NAME="$CXX_NAME"
2463 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2464 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2465 ECHO_LD="$ECHO_LD"
2466 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2467 FORM_NAME="$FORM_NAME"
2468 LDCONFIG="$LDCONFIG"
2469 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2470 LIB_NAME="$LIB_NAME"
2471 LIB_PREFIX="$LIB_PREFIX"
2472 LIB_SUBSETS="$LIB_SUBSETS"
2473 LIB_SUFFIX="$LIB_SUFFIX"
2474 LIB_TRACING="$LIB_TRACING"
2475 LN_S="$LN_S"
2476 MAKE_TERMINFO="$MAKE_TERMINFO"
2477 MENU_NAME="$MENU_NAME"
2478 NCURSES_MAJOR="$NCURSES_MAJOR"
2479 NCURSES_MINOR="$NCURSES_MINOR"
2480 NCURSES_OSPEED="$NCURSES_OSPEED"
2481 NCURSES_PATCH="$NCURSES_PATCH"
2482 PANEL_NAME="$PANEL_NAME"
2483 SRC_SUBDIRS="$SRC_SUBDIRS"
2484 TERMINFO="$TERMINFO"
2485 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2486 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2487 TICS_NAME="$TICS_NAME"
2488 TICS_SUFFIX="$TICS_SUFFIX"
2489 TIC_PATH="$TIC_PATH"
2490 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2491 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2492 TINFO_NAME="$TINFO_NAME"
2493 TINFO_SUFFIX="$TINFO_SUFFIX"
2494 UNALTERED_SYMS="$UNALTERED_SYMS"
2495 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2496 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2497 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2498 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2499 WILDCARD_SYMS="$WILDCARD_SYMS"
2500 WITH_CURSES_H="$with_curses_h"
2501 WITH_ECHO="${enable_echo:=yes}"
2502 WITH_OVERWRITE="$with_overwrite"
2503 cf_LIST_MODELS="$cf_list_models"
2504 cf_cv_abi_version="$cf_cv_abi_version"
2505 cf_cv_do_relink="$cf_cv_do_relink"
2506 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2507 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2508 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2509 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2510 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2511 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2512 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2513 cf_cv_rel_version="$cf_cv_rel_version"
2514 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2515 cf_cv_shared_soname='$cf_cv_shared_soname'
2516 cf_cv_shlib_version="$cf_cv_shlib_version"
2517 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2518 cf_cv_system_name="$cf_cv_system_name"
2519 cf_cv_term_driver="$with_term_driver"
2520 cf_with_ada="$cf_with_ada"
2521 cf_with_cxx_binding="$cf_with_cxx_binding"
2522 cf_with_db_install="$cf_with_db_install"
2523 cf_with_manpages="$cf_with_manpages"
2524 cf_with_tests="$cf_with_tests"
2525 host="$host"
2526 target="$target"
2527 with_shared_cxx="$with_shared_cxx"
2528
2529 ],cat)dnl
2530 ${MAKE:-make} preinstall