ncurses 6.1 - patch 20180324
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2017,2018 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.656 2018/02/10 18:19:38 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See https://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.52.20170501)
38 AC_REVISION($Revision: 1.656 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44 CF_VERSION_INFO(NCURSES,ncurses)
45
46 CF_WITH_REL_VERSION(NCURSES)
47 CF_NCURSES_WITH_ABI_VERSION
48
49 CF_WITH_SYSTYPE
50
51 ###     Save the given $CFLAGS to allow user-override.
52 cf_user_CFLAGS="$CFLAGS"
53
54 ###     Default install-location
55 CF_CFG_DEFAULTS
56 ### Defaults for ncurses ABI
57 CF_ABI_DEFAULTS
58
59 ###     Checks for programs.
60 AC_ARG_WITH(ada,
61         [  --without-ada           suppress check for Ada95, don't build demo],
62         [cf_with_ada=$withval],
63         [cf_with_ada=yes])
64 if test "x$cf_with_ada" = xyes
65 then
66         cf_PROG_CC="gnatgcc gcc cc"
67 else
68         cf_PROG_CC="gcc cc"
69 fi
70
71 CF_PROG_CC($cf_PROG_CC)
72
73 AC_PROG_CPP
74 AC_PROG_GCC_TRADITIONAL
75 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
76 CF_PROG_LDCONFIG
77
78 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
79 dnl                             configure script by not letting us test if C++
80 dnl                             is present, making this option necessary.
81 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
82 AC_ARG_WITH(cxx,
83         [  --without-cxx           do not adjust ncurses bool to match C++],
84         [cf_with_cxx=$withval],
85         [cf_with_cxx=yes])
86 AC_MSG_RESULT($cf_with_cxx)
87 if test "X$cf_with_cxx" = Xno ; then
88         CXX=""
89         GXX=""
90 else
91         # with autoconf 2.13, we can change the error to a warning:
92         pushdef([AC_MSG_ERROR],
93                 [AC_MSG_RESULT(no)
94                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
95                 cf_with_cxx=no; CXX=""; GXX="";])dnl
96         AC_PROG_CXX
97         popdef([AC_MSG_ERROR])dnl
98
99         AC_LANG_PUSH(C++)
100         if test "x$cf_with_cxx" != xno
101         then
102                 # Several of the C++ configurations do not work, particularly when
103                 # cross-compiling (20140913 -TD)
104                 AC_MSG_CHECKING(if $CXX works)
105
106                 save_CPPFLAGS="$CPPFLAGS"
107                 eval cf_includedir=${includedir}
108                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
109                 AC_TRY_COMPILE([
110 #include <stdlib.h>
111 #include <stdio.h>
112 ],
113                 [
114                 printf("Hello world!\n")
115                 ],
116                 [cf_cxx_works=yes],
117                 [cf_cxx_works=no])
118                 CPPFLAGS="$save_CPPFLAGS"
119
120                 AC_MSG_RESULT($cf_cxx_works)
121                 if test "x$cf_cxx_works" = xno
122                 then
123                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
124                         cf_with_cxx=no; CXX=""; GXX="";
125                 fi
126         fi
127         AC_LANG_POP
128
129         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
130         if test "$CXX" = "g++" ; then
131                 AC_PATH_PROG(CXX,g++)
132         fi
133         case "x$CXX" in
134         (x|xg++)
135                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
136                 cf_with_cxx=no; CXX=""; GXX="";
137                 ;;
138         esac
139 fi
140
141 CF_GXX_VERSION
142 case $GXX_VERSION in
143 (1*|2.[[0-6]]*)
144         # GXX=""; CXX=""; ac_cv_prog_gxx=no
145         # cf_cxx_library=no
146         AC_MSG_WARN(templates do not work)
147         ;;
148 esac
149
150 AC_MSG_CHECKING(if you want to build C++ binding and demo)
151 AC_ARG_WITH(cxx-binding,
152         [  --without-cxx-binding   do not build C++ binding and demo],
153         [cf_with_cxx_binding=$withval],
154         [cf_with_cxx_binding=$cf_with_cxx])
155 AC_MSG_RESULT($cf_with_cxx_binding)
156
157 AC_MSG_CHECKING(if you want to build with Ada95)
158 AC_MSG_RESULT($cf_with_ada)
159
160 AC_MSG_CHECKING(if you want to install terminal database)
161 AC_ARG_ENABLE(db-install,
162         [  --disable-db-install    suppress install of terminal database],
163         [cf_with_db_install=$enableval],
164         [cf_with_db_install=yes])
165 AC_MSG_RESULT($cf_with_db_install)
166
167 AC_MSG_CHECKING(if you want to install manpages)
168 AC_ARG_WITH(manpages,
169         [  --without-manpages      suppress install of manpages],
170         [cf_with_manpages=$withval],
171         [cf_with_manpages=yes])
172 AC_MSG_RESULT($cf_with_manpages)
173
174 AC_MSG_CHECKING(if you want to build programs such as tic)
175 AC_ARG_WITH(progs,
176         [  --without-progs         suppress build/install with programs (e.g., tic)],
177         [cf_with_progs=$withval],
178         [cf_with_progs=yes])
179 AC_MSG_RESULT($cf_with_progs)
180
181 if test -f $srcdir/tack/tack.h; then
182         if test "x$cross_compiling" = xyes ; then
183                 CF_VERBOSE(ignoring tack because we are cross-compiling)
184                 cf_with_tack=no
185         else
186                 AC_MSG_CHECKING(if you want to build the tack program)
187                 AC_ARG_WITH(tack,
188                         [  --without-tack          suppress build/install with tack program],
189                         [cf_with_tack=$withval],
190                         [cf_with_tack=$cf_with_progs])
191                 AC_MSG_RESULT($cf_with_tack)
192         fi
193 else
194         cf_with_tack=no
195 fi
196
197 AC_MSG_CHECKING(if you want to build test-programs)
198 AC_ARG_WITH(tests,
199         [  --without-tests         suppress build/install with test-programs],
200         [cf_with_tests=$withval],
201         [cf_with_tests=yes])
202 AC_MSG_RESULT($cf_with_tests)
203
204 AC_MSG_CHECKING(if you wish to install curses.h)
205 AC_ARG_WITH(curses-h,
206         [  --without-curses-h      install curses.h as ncurses.h only],
207         [with_curses_h=$withval],
208         [with_curses_h=yes])
209 AC_MSG_RESULT($with_curses_h)
210
211 modules_to_build="ncurses"
212 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
213 test "X$cf_with_tack"  != Xno && modules_to_build="$modules_to_build tack"
214 modules_to_build="$modules_to_build panel menu form"
215
216 AC_ARG_PROGRAM
217
218 CF_PROG_AWK
219 CF_PROG_EGREP
220 CF_PROG_INSTALL
221 CF_PROG_LINT
222 CF_PROG_LN_S
223
224 AC_SYS_LONG_FILE_NAMES
225
226 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
227 # of package conflict.
228 cf_config_suffix=
229 AC_ARG_WITH(config-suffix,
230         [  --with-config-suffix=X  suffixes ncursesXX-config file],
231         [case "x$withval" in
232         (xyes|xno)
233                 AC_MSG_WARN(expected a value for config-suffix option)
234                 ;;
235         (*)     cf_config_suffix="$withval"
236                 ;;
237         esac])
238 AC_SUBST(cf_config_suffix)
239
240 # If we find pkg-config, check if we should install the ".pc" files.
241 CF_PKG_CONFIG
242 CF_WITH_PKG_CONFIG_LIBDIR
243 CF_ENABLE_PC_FILES
244 if test -z "$MAKE_PC_FILES"
245 then
246         AC_MSG_CHECKING(for suffix to add to pc-files)
247 AC_ARG_WITH(pc-suffix,
248         [  --with-pc-suffix        suffixes pc-files],
249         [case "x$withval" in
250         (xyes|xno)
251                 PC_MODULE_SUFFIX=
252                 ;;
253         (*)     PC_MODULE_SUFFIX="$withval"
254                 ;;
255         esac])
256         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
257         AC_MSG_RESULT($PC_MODULE_SUFFIX)
258         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
259         AC_SUBST(PC_MODULE_SUFFIX)
260 fi
261
262 AC_MSG_CHECKING(if we should assume mixed-case filenames)
263 AC_ARG_ENABLE(mixed-case,
264         [  --enable-mixed-case     tic should assume mixed-case filenames],
265         [enable_mixedcase=$enableval],
266         [enable_mixedcase=auto])
267 AC_MSG_RESULT($enable_mixedcase)
268 if test "$enable_mixedcase" = "auto" ; then
269         CF_MIXEDCASE_FILENAMES
270 else
271         cf_cv_mixedcase=$enable_mixedcase
272         if test "x$enable_mixedcase" = "xyes" ; then
273                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
274         fi
275 fi
276
277 # do this after mixed-case option (tags/TAGS is not as important as tic).
278 AC_PROG_MAKE_SET
279 CF_MAKE_TAGS
280 CF_MAKEFLAGS
281
282 dnl These are standard among *NIX systems, but not when cross-compiling
283 AC_CHECK_TOOL(RANLIB, ranlib, ':')
284 AC_CHECK_TOOL(LD, ld, ld)
285 AC_CHECK_TOOL(AR, ar, ar)
286 AC_CHECK_TOOL(NM, nm, nm)
287 CF_AR_FLAGS
288
289 dnl Special option for use by system-builders: the install-prefix is used to
290 dnl adjust the location into which the actual install is done, so that an
291 dnl archive can be built without modifying the host system's configuration.
292 AC_MSG_CHECKING(if you have specified an install-prefix)
293 AC_ARG_WITH(install-prefix,
294         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
295         [case "x$withval" in
296         (xyes|xno)
297                 ;;
298         (*)     DESTDIR="$withval"
299                 ;;
300         esac])
301 AC_MSG_RESULT($DESTDIR)
302 AC_SUBST(DESTDIR)
303
304 ###############################################################################
305 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
306 # If we're cross-compiling, allow the user to override the tools and their
307 # options.  The configure script is oriented toward identifying the host
308 # compiler, etc., but we need a build compiler to generate parts of the source.
309 CF_BUILD_CC
310
311 ###############################################################################
312 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
313
314 ### Options to allow the user to specify the set of libraries which are used.
315 ### Use "--without-normal --with-shared" to allow the default model to be
316 ### shared, for example.
317 cf_list_models=""
318 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
319
320 CF_WITH_LIBTOOL
321 if test "$with_libtool" != "no" ; then
322
323 cf_list_models="$cf_list_models libtool"
324
325 else
326
327 AC_MSG_CHECKING(if you want to build shared libraries)
328 AC_ARG_WITH(shared,
329         [  --with-shared           generate shared-libraries],
330         [with_shared=$withval],
331         [with_shared=no])
332 AC_MSG_RESULT($with_shared)
333 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
334
335 AC_MSG_CHECKING(if you want to build static libraries)
336 AC_ARG_WITH(normal,
337         [  --with-normal           generate normal-libraries (default)],
338         [with_normal=$withval],
339         [with_normal=yes])
340 AC_MSG_RESULT($with_normal)
341 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
342
343 AC_MSG_CHECKING(if you want to build debug libraries)
344 AC_ARG_WITH(debug,
345         [  --with-debug            generate debug-libraries (default)],
346         [with_debug=$withval],
347         [with_debug=yes])
348 AC_MSG_RESULT($with_debug)
349 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
350
351 AC_MSG_CHECKING(if you want to build profiling libraries)
352 AC_ARG_WITH(profile,
353         [  --with-profile          generate profile-libraries],
354         [with_profile=$withval],
355         [with_profile=no])
356 AC_MSG_RESULT($with_profile)
357 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
358
359 fi
360
361 if test "X$cf_with_cxx_binding" != Xno; then
362 if test "x$with_shared" = "xyes"; then
363 AC_MSG_CHECKING(if you want to build C++ shared libraries)
364 AC_ARG_WITH(cxx-shared,
365         [  --with-cxx-shared       generate C++ shared-libraries],
366         [with_shared_cxx=$withval],
367         [with_shared_cxx=no])
368 AC_MSG_RESULT($with_shared_cxx)
369 fi
370 fi
371
372 ###############################################################################
373
374 AC_MSG_CHECKING(for specified models)
375 test -z "$cf_list_models" && cf_list_models=normal
376 dnl If we use libtool to generate libraries, then it must be the only
377 dnl specified model.
378 test "$with_libtool" != "no" && cf_list_models=libtool
379 AC_MSG_RESULT($cf_list_models)
380
381 ### Use the first model as the default, and save its suffix for use in building
382 ### up test-applications.
383 AC_MSG_CHECKING(for default model)
384 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
385 AC_MSG_RESULT($DFT_LWR_MODEL)
386
387 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
388
389 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
390 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
391
392 TICS_NAME=tic
393 AC_SUBST(TICS_NAME)
394
395 TINFO_NAME=tinfo
396 AC_SUBST(TINFO_NAME)
397
398 LIB_NAME=ncurses
399 AC_SUBST(LIB_NAME)
400
401 LIB_DIR=../lib
402 LIB_2ND=../../lib
403
404 CF_WITH_LIB_PREFIX(cf_prefix)
405
406 LIB_SUFFIX=
407 AC_SUBST(LIB_SUFFIX)
408 CF_PATHSEP
409
410 ###############################################################################
411
412 AC_MSG_CHECKING(if you want to build a separate terminfo library)
413 AC_ARG_WITH(termlib,
414         [  --with-termlib          generate separate terminfo library],
415         [with_termlib=$withval],
416         [with_termlib=no])
417 AC_MSG_RESULT($with_termlib)
418
419 AC_MSG_CHECKING(if you want to build a separate tic library)
420 AC_ARG_WITH(ticlib,
421         [  --with-ticlib           generate separate tic library],
422         [with_ticlib=$withval],
423         [with_ticlib=no])
424 AC_MSG_RESULT($with_ticlib)
425
426 ### Checks for special libraries, must be done up-front.
427 SHLIB_LIST=""
428 CF_WITH_GPM
429 if test "$with_gpm" != no ; then
430         AC_MSG_CHECKING(if you want to load GPM dynamically)
431         AC_ARG_WITH(dlsym,
432                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
433                 [with_dlsym=$withval],
434                 [with_dlsym=yes])
435         AC_MSG_RESULT($with_dlsym)
436         if test "x$with_dlsym" = xyes ; then
437                 CF_FUNC_DLSYM
438                 if test "x$with_gpm" != xyes ; then
439                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
440                         cf_cv_gpm_soname="$with_gpm"
441                 else
442                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
443                 fi
444                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
445                 SHLIB_LIST="-ldl $SHLIB_LIST"
446         else
447                 SHLIB_LIST="-lgpm $SHLIB_LIST"
448                 CF_ADD_LIB(gpm,TEST_LIBS)
449         fi
450         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
451         CF_CHECK_GPM_WGETCH
452 fi
453
454 CF_WITH_SYSMOUSE
455
456 dnl Not all ports of gcc support the -g option
457
458 if test X"$CC_G_OPT" = X"" ; then
459         CC_G_OPT='-g'
460         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
461 fi
462 AC_SUBST(CC_G_OPT)
463
464 if test X"$CXX_G_OPT" = X"" ; then
465         CXX_G_OPT='-g'
466         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
467 fi
468 AC_SUBST(CXX_G_OPT)
469
470 AC_MSG_CHECKING(for default loader flags)
471 case $DFT_LWR_MODEL in
472 (libtool) LD_MODEL=''   ;;
473 (normal)  LD_MODEL=''   ;;
474 (debug)   LD_MODEL=$CC_G_OPT ;;
475 (profile) LD_MODEL='-pg';;
476 (shared)  LD_MODEL=''   ;;
477 esac
478 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
479 AC_MSG_RESULT($LD_MODEL)
480
481 case $DFT_LWR_MODEL in
482 (shared)
483 CF_ENABLE_RPATH
484 AC_MSG_CHECKING(if shared libraries should be relinked during install)
485 AC_ARG_ENABLE(relink,
486 [  --disable-relink        relink shared libraries during install],
487 [cf_cv_do_relink=$enableval],
488 [cf_cv_do_relink=yes])
489 AC_MSG_RESULT($cf_cv_do_relink)
490         ;;
491 esac
492
493 # we will build libraries one-level down.
494 rel_builddir=..
495 CF_SHARED_OPTS
496 for model in $cf_list_models; do
497         case $model in
498         (libtool)
499                 CF_WITH_LIBTOOL_OPTS
500                 CF_WITH_EXPORT_SYMS
501                 ;;
502         (shared)
503                 if test "$CC_SHARED_OPTS" = "unknown"; then
504                         AC_ERROR(Shared libraries are not supported in this version)
505                 fi
506                 # workaround for inept transition to PIE vs PIC...
507                 AC_MSG_CHECKING(if current CFLAGS link properly)
508                 AC_TRY_LINK(
509                         [#include <stdio.h>],
510                         [printf("Hello work\n");],
511                         [cf_cflags_work=yes],
512                         [cf_cflags_work=no])
513                 AC_MSG_RESULT($cf_cflags_work)
514                 if test "$cf_cflags_work" = no
515                 then
516                         CF_VERBOSE(try to work around by appending shared-options)
517                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
518                 fi
519                 CF_WITH_VERSIONED_SYMS
520                 ;;
521         esac
522 done
523
524 # pretend that ncurses==ncursesw==ncursest
525 AC_MSG_CHECKING(if you want to disable library suffixes)
526 CF_ARG_DISABLE(lib-suffixes,
527         [  --disable-lib-suffixes  disable library suffixes],
528         [disable_lib_suffixes=yes],
529         [disable_lib_suffixes=no],
530         no)
531 AC_MSG_RESULT($disable_lib_suffixes)
532
533 ### If we're building with rpath, try to link non-standard libs that way too.
534 if test "$DFT_LWR_MODEL" = "shared"; then
535         CF_DISABLE_RPATH_HACK
536 fi
537
538 ###############################################################################
539 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
540
541 ###     use option --with-extra-suffix to append suffix to headers and libraries
542 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
543 EXTRA_SUFFIX=
544 AC_ARG_WITH(extra-suffix,
545         [  --with-extra-suffix=X   append extra suffix to header/library paths],
546         [case x$withval in
547         (no)
548                 ;;
549         (xyes|x)
550                 EXTRA_SUFFIX=$cf_cv_abi_version
551                 ;;
552         (*)
553                 EXTRA_SUFFIX=$withval
554                 ;;
555         esac
556         ])
557 AC_MSG_RESULT($EXTRA_SUFFIX)
558 AC_SUBST(EXTRA_SUFFIX)
559
560 ###     use option --disable-overwrite to leave out the link to -lcurses
561 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
562 AC_ARG_ENABLE(overwrite,
563         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
564         [with_overwrite=$enableval],
565         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
566 AC_MSG_RESULT($with_overwrite)
567
568 AC_MSG_CHECKING(if external terminfo-database is used)
569 AC_ARG_ENABLE(database,
570         [  --disable-database      do not use terminfo, only fallbacks/termcap],
571         [use_database=$enableval],
572         [use_database=yes])
573 AC_MSG_RESULT($use_database)
574
575 case $host_os in
576 (os2*)
577         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
578         ;;
579 (*)
580         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
581         ;;
582 esac
583 AC_SUBST(TERMINFO_SRC)
584
585 NCURSES_USE_DATABASE=0
586 if test "$use_database" != no ; then
587         NCURSES_USE_DATABASE=1
588
589         AC_MSG_CHECKING(which terminfo source-file will be installed)
590         AC_ARG_WITH(database,
591                 [  --with-database=XXX     specify terminfo source to install],
592                 [TERMINFO_SRC=$withval])
593         AC_MSG_RESULT($TERMINFO_SRC)
594
595         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
596         AC_ARG_WITH(hashed-db,
597                 [  --with-hashed-db        specify hashed-database library],,
598                 [with_hashed_db=no])
599         AC_MSG_RESULT($with_hashed_db)
600 else
601         with_hashed_db=no
602 fi
603 AC_SUBST(NCURSES_USE_DATABASE)
604
605 AC_MSG_CHECKING(for list of fallback descriptions)
606 AC_ARG_WITH(fallbacks,
607         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
608         [with_fallback=$withval],
609         [with_fallback=])
610 AC_MSG_RESULT($with_fallback)
611 FALLBACK_LIST=`test "$with_fallback" != no && echo "$with_fallback" | sed -e 's/,/ /g'`
612 AC_SUBST(FALLBACK_LIST)
613
614 AC_MSG_CHECKING(if you want modern xterm or antique)
615 AC_ARG_WITH(xterm-new,
616         [  --without-xterm-new     specify if xterm terminfo should be old version],
617         [with_xterm_new=$withval],
618         [with_xterm_new=yes])
619 case $with_xterm_new in
620 (no) with_xterm_new=xterm-old;;
621 (*)      with_xterm_new=xterm-new;;
622 esac
623 AC_MSG_RESULT($with_xterm_new)
624 WHICH_XTERM=$with_xterm_new
625 AC_SUBST(WHICH_XTERM)
626
627 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
628 AC_ARG_WITH(xterm-kbs,
629         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
630         [with_xterm_kbs=$withval],
631         [with_xterm_kbs=BS])
632 case x$with_xterm_kbs in
633 (xyes|xno|xBS|xbs|x8)
634         with_xterm_kbs=BS
635         ;;
636 (xDEL|xdel|x127)
637         with_xterm_kbs=DEL
638         ;;
639 (*)
640         with_xterm_kbs=$withval
641         ;;
642 esac
643 AC_MSG_RESULT($with_xterm_kbs)
644 XTERM_KBS=$with_xterm_kbs
645 AC_SUBST(XTERM_KBS)
646
647 MAKE_TERMINFO=
648 if test "$use_database" = no ; then
649         TERMINFO="${datadir}/terminfo"
650         MAKE_TERMINFO="#"
651 else
652
653 AC_MSG_CHECKING(for list of terminfo directories)
654 CF_WITH_PATHLIST(terminfo-dirs,
655         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
656         TERMINFO_DIRS,
657         DATADIR/terminfo,
658         ${datadir}/terminfo)
659 AC_MSG_RESULT($TERMINFO_DIRS)
660 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
661
662 AC_MSG_CHECKING(for default terminfo directory)
663 CF_WITH_PATH(default-terminfo-dir,
664         [  --with-default-terminfo-dir=DIR default terminfo directory],
665         TERMINFO,
666         DATADIR/terminfo,
667         ${datadir}/terminfo)
668 AC_MSG_RESULT($TERMINFO)
669 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
670
671 fi
672
673 AC_SUBST(TERMINFO)
674 AC_SUBST(MAKE_TERMINFO)
675
676 ###     use option --disable-big-core to make tic run on small machines
677 ###     We need 4Mb, check if we can allocate 50% more than that.
678 AC_MSG_CHECKING(if big-core option selected)
679 AC_ARG_ENABLE(big-core,
680         [  --disable-big-core      assume machine has little memory],
681         [with_big_core=$enableval],
682         [AC_TRY_RUN([
683 #include <stdlib.h>
684 #include <string.h>
685 int main() {
686         unsigned long n = 6000000L;
687         char *s = malloc(n);
688         if (s != 0)
689                 s[0] = s[n-1] = 0;
690         ${cf_cv_main_return:-return}(s == 0);
691 }],
692         [with_big_core=yes],
693         [with_big_core=no],
694         [with_big_core=no])])
695 AC_MSG_RESULT($with_big_core)
696 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
697
698 ### ISO C only guarantees 512-char strings, we have tables which load faster
699 ### when constructed using "big" strings.  More than the C compiler, the awk
700 ### program is a limit on most vendor UNIX systems.  Check that we can build.
701 AC_MSG_CHECKING(if big-strings option selected)
702 AC_ARG_ENABLE(big-strings,
703         [  --disable-big-strings   assume compiler has only standard-size strings],
704         [with_big_strings=$enableval],
705         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
706 AC_MSG_RESULT($with_big_strings)
707
708 USE_BIG_STRINGS=0
709 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
710 AC_SUBST(USE_BIG_STRINGS)
711
712 ###     use option --enable-termcap to compile in the termcap fallback support
713 AC_MSG_CHECKING(if you want termcap-fallback support)
714 AC_ARG_ENABLE(termcap,
715         [  --enable-termcap        compile in termcap fallback support],
716         [with_termcap=$enableval],
717         [with_termcap=no])
718 AC_MSG_RESULT($with_termcap)
719
720 NCURSES_USE_TERMCAP=0
721 if test "x$with_termcap" != "xyes" ; then
722         if test "$use_database" = no ; then
723                 if test -z "$with_fallback" ; then
724                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
725                 fi
726         fi
727         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
728 else
729
730         if test "$with_ticlib" != no ; then
731                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
732         fi
733
734         NCURSES_USE_TERMCAP=1
735         AC_MSG_CHECKING(for list of termcap files)
736         CF_WITH_PATHLIST(termpath,
737                 [  --with-termpath=XXX     specify list of termcap files],
738                 TERMPATH,
739                 /etc/termcap:/usr/share/misc/termcap)
740         AC_MSG_RESULT($TERMPATH)
741         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
742
743         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
744         AC_MSG_CHECKING(if fast termcap-loader is needed)
745         AC_ARG_ENABLE(getcap,
746                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
747                 [with_getcap=$enableval],
748                 [with_getcap=no])
749         AC_MSG_RESULT($with_getcap)
750         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
751
752         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
753         AC_ARG_ENABLE(getcap-cache,
754                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
755                 [with_getcap_cache=$enableval],
756                 [with_getcap_cache=no])
757         AC_MSG_RESULT($with_getcap_cache)
758         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
759
760 fi
761 AC_SUBST(NCURSES_USE_TERMCAP)
762
763 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
764 AC_MSG_CHECKING(if ~/.terminfo is wanted)
765 AC_ARG_ENABLE(home-terminfo,
766         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
767         [with_home_terminfo=$enableval],
768         [with_home_terminfo=yes])
769 AC_MSG_RESULT($with_home_terminfo)
770 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
771
772 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
773 AC_ARG_ENABLE(root-environ,
774         [  --disable-root-environ  restrict environment when running as root],
775         [with_root_environ=$enableval],
776         [with_root_environ=yes])
777 AC_MSG_RESULT($with_root_environ)
778 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
779
780 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
781 ###   to reduce storage requirements for the terminfo database.
782 CF_LINK_FUNCS
783
784 with_links=no
785 with_symlinks=no
786
787 # soft links (symbolic links) are useful for some systems where hard links do
788 # not work, or to make it simpler to copy terminfo trees around.
789 if test "x$ac_cv_func_symlink" = xyes ; then
790         AC_MSG_CHECKING(if tic should use symbolic links)
791         AC_ARG_ENABLE(symlinks,
792         [  --enable-symlinks       make tic use symbolic links not hard links],
793         [with_symlinks=$enableval],
794         [with_symlinks=no])
795         AC_MSG_RESULT($with_symlinks)
796 fi
797
798 # If we have hard links and did not choose to use soft links instead, there is
799 # no reason to make this choice optional - use the hard links.
800 if test "$with_symlinks" = no ; then
801         AC_MSG_CHECKING(if tic should use hard links)
802         if test "x$ac_cv_func_link" = xyes ; then
803                 with_links=yes
804         else
805                 with_links=no
806         fi
807         AC_MSG_RESULT($with_links)
808 fi
809
810 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
811 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
812
813 ###   use option --enable-broken-linker to force on use of broken-linker support
814 AC_MSG_CHECKING(if you want broken-linker support code)
815 AC_ARG_ENABLE(broken_linker,
816         [  --enable-broken_linker  compile with broken-linker support code],
817         [with_broken_linker=$enableval],
818         [with_broken_linker=${BROKEN_LINKER:-no}])
819 AC_MSG_RESULT($with_broken_linker)
820
821 BROKEN_LINKER=0
822 if test "x$with_broken_linker" = xyes ; then
823         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
824         BROKEN_LINKER=1
825 elif test "$DFT_LWR_MODEL" = shared ; then
826         case $cf_cv_system_name in
827         (cygwin*)
828                 AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
829                 BROKEN_LINKER=1
830                 CF_VERBOSE(cygwin linker is broken anyway)
831                 ;;
832         esac
833 fi
834 AC_SUBST(BROKEN_LINKER)
835
836 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
837 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
838 AC_ARG_ENABLE(bsdpad,
839         [  --enable-bsdpad         recognize BSD-style prefix padding],
840         [with_bsdpad=$enableval],
841         [with_bsdpad=no])
842 AC_MSG_RESULT($with_bsdpad)
843 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
844
845 ###   use option --enable-widec to turn on use of wide-character support
846 NCURSES_CH_T=chtype
847 NCURSES_LIBUTF8=0
848
849 NEED_WCHAR_H=0
850 NCURSES_MBSTATE_T=0
851 NCURSES_WCHAR_T=0
852 NCURSES_WINT_T=0
853
854 # Check to define _XOPEN_SOURCE "automatically"
855 CPPFLAGS_before_XOPEN="$CPPFLAGS"
856 CF_XOPEN_SOURCE(500)
857 CPPFLAGS_after_XOPEN="$CPPFLAGS"
858
859 # Work around breakage on OS X
860 CF_SIGWINCH
861
862 # Checks for CODESET support.
863 AM_LANGINFO_CODESET
864
865 # use these variables to work around a defect in gcc's fixincludes.
866 NCURSES_OK_WCHAR_T=
867 NCURSES_OK_WINT_T=
868
869 AC_MSG_CHECKING(if you want wide-character code)
870 AC_ARG_ENABLE(widec,
871         [  --enable-widec          compile with wide-char/UTF-8 code],
872         [with_widec=$enableval],
873         [with_widec=no])
874 AC_MSG_RESULT($with_widec)
875
876 NCURSES_WCWIDTH_GRAPHICS=1
877 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
878
879 if test "x$with_widec" = xyes ; then
880         if test "x$disable_lib_suffixes" = xno ; then
881                 LIB_SUFFIX="w${LIB_SUFFIX}"
882         fi
883         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
884         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
885
886         CF_CHECK_WCHAR_H
887         CF_CHECK_WCWIDTH_GRAPHICS
888         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
889
890         # with_overwrite=no
891         NCURSES_CH_T=cchar_t
892         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
893         if test "x$ac_cv_func_putwc" != xyes ; then
894                 CF_UTF8_LIB
895                 if test "$cf_cv_utf8_lib" != no ; then
896                         NCURSES_LIBUTF8=1
897                 fi
898         fi
899         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
900         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
901         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
902
903         if test "$NCURSES_MBSTATE_T" != 0; then
904                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
905         fi
906 fi
907 AC_SUBST(NCURSES_CH_T)
908 AC_SUBST(NCURSES_LIBUTF8)
909
910 AC_SUBST(NEED_WCHAR_H)
911 AC_SUBST(NCURSES_MBSTATE_T)
912 AC_SUBST(NCURSES_WCHAR_T)
913 AC_SUBST(NCURSES_WINT_T)
914
915 AC_SUBST(NCURSES_OK_WCHAR_T)
916 AC_SUBST(NCURSES_OK_WINT_T)
917
918 ###   use option --disable-lp64 to allow long chtype
919 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
920 AC_ARG_ENABLE(lp64,
921         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
922         [with_lp64=$enableval],
923         [with_lp64=$cf_dft_with_lp64])
924 AC_MSG_RESULT($with_lp64)
925
926 if test "x$with_lp64" = xyes ; then
927         cf_cv_enable_lp64=1
928 else
929         cf_cv_enable_lp64=0
930 fi
931 AC_SUBST(cf_cv_enable_lp64)
932
933 CF_LARGEFILE
934
935 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
936 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
937 AC_ARG_ENABLE(tparm-varargs,
938         [  --disable-tparm-varargs compile tparm() without varargs interface],
939         [with_tparm_varargs=$enableval],
940         [with_tparm_varargs=yes])
941 AC_MSG_RESULT($with_tparm_varargs)
942 NCURSES_TPARM_VARARGS=0
943 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
944 AC_SUBST(NCURSES_TPARM_VARARGS)
945
946 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
947 if test "$with_ticlib" != no ; then
948 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
949 AC_ARG_ENABLE(tic-depends,
950         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
951         [with_tic_depends=$enableval],
952         [with_tic_depends=yes])
953 AC_MSG_RESULT($with_tic_depends)
954 else
955         with_tic_depends=no
956 fi
957
958 ###   use option --disable-wattr-macros to suppress wattr* macros from curses.h
959 AC_MSG_CHECKING(if you want to suppress wattr* macros to help with ncurses5/ncurses6 transition)
960 AC_ARG_ENABLE(wattr-macros,
961         [  --disable-wattr-macros  suppress wattr* macros to help with ncurses5/ncurses6 transition],
962         [with_wattr_macros=$enableval],
963         [with_wattr_macros=yes])
964 if [[ "x$with_wattr_macros" != xyes ]]; then
965         NCURSES_WATTR_MACROS=0
966         AC_MSG_RESULT(yes)
967 else
968         NCURSES_WATTR_MACROS=1
969         AC_MSG_RESULT(no)
970 fi
971 AC_SUBST(NCURSES_WATTR_MACROS)
972
973 CF_WITH_X11_RGB
974
975 ###   use option --with-bool to override bool's type
976 AC_MSG_CHECKING(for type of bool)
977 AC_ARG_WITH(bool,
978         [  --with-bool=TYPE        override fallback type of bool variable],
979         [NCURSES_BOOL="$withval"],
980         [NCURSES_BOOL=auto])
981 AC_MSG_RESULT($NCURSES_BOOL)
982 AC_SUBST(NCURSES_BOOL)
983
984 AC_MSG_CHECKING(for alternate terminal capabilities file)
985 AC_ARG_WITH(caps,
986         [  --with-caps=alt         compile with alternate Caps file],
987         [TERMINFO_CAPS=Caps.$withval],
988         [TERMINFO_CAPS=Caps])
989 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
990 AC_MSG_RESULT($TERMINFO_CAPS)
991 AC_SUBST(TERMINFO_CAPS)
992
993 ###   use option --with-chtype to override chtype's type
994 AC_MSG_CHECKING(for type of chtype)
995 AC_ARG_WITH(chtype,
996         [  --with-chtype=TYPE      override type of chtype],
997         [NCURSES_CHTYPE="$withval"],
998         [NCURSES_CHTYPE=$cf_dft_chtype])
999 AC_MSG_RESULT($NCURSES_CHTYPE)
1000
1001 ###   use option --with-ospeed to override ospeed's type
1002 AC_MSG_CHECKING(for type of ospeed)
1003 AC_ARG_WITH(ospeed,
1004         [  --with-ospeed=TYPE      override type of ospeed variable],
1005         [NCURSES_OSPEED="$withval"],
1006         [NCURSES_OSPEED=short])
1007 AC_MSG_RESULT($NCURSES_OSPEED)
1008 AC_SUBST(NCURSES_OSPEED)
1009
1010 ###   use option --with-mmask-t to override mmask_t's type
1011 AC_MSG_CHECKING(for type of mmask_t)
1012 AC_ARG_WITH(mmask-t,
1013         [  --with-mmask-t=TYPE     override type of mmask_t],
1014         [NCURSES_MMASK_T="$withval"],
1015         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1016 AC_MSG_RESULT($NCURSES_MMASK_T)
1017
1018 ###   use option --with-ccharw-max to override CCHARW_MAX size
1019 AC_MSG_CHECKING(for size CCHARW_MAX)
1020 AC_ARG_WITH(ccharw-max,
1021         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1022         [NCURSES_CCHARW_MAX="$withval"],
1023         [NCURSES_CCHARW_MAX=5])
1024 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1025 AC_SUBST(NCURSES_CCHARW_MAX)
1026
1027 AC_CHECK_SIZEOF([signed char], 0)
1028 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1029         NCURSES_SBOOL="signed char"
1030 else
1031         NCURSES_SBOOL="char"
1032 fi
1033 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1034 AC_ARG_ENABLE(signed-char,
1035         [  --enable-signed-char    compile using signed Boolean's in term.h],
1036         [with_signed_char=$enableval],
1037         [with_signed_char=no])
1038 AC_MSG_RESULT($with_signed_char)
1039 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1040 AC_SUBST(NCURSES_SBOOL)
1041
1042 ###   use option --with-tparm-arg to override tparm's argument type
1043 AC_MSG_CHECKING(for type of tparm args)
1044 AC_ARG_WITH(tparm-arg,
1045         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1046         [NCURSES_TPARM_ARG="$withval"],
1047         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1048 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1049 AC_SUBST(NCURSES_TPARM_ARG)
1050
1051 ### Enable compiling-in rcs id's
1052 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1053 AC_ARG_WITH(rcs-ids,
1054         [  --with-rcs-ids          compile-in RCS identifiers],
1055         [with_rcs_ids=$withval],
1056         [with_rcs_ids=no])
1057 AC_MSG_RESULT($with_rcs_ids)
1058 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1059
1060 ###############################################################################
1061 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1062
1063 ###############################################################################
1064 CF_HELP_MESSAGE(Extensions:)
1065
1066 ### Note that some functions (such as const) are normally disabled anyway.
1067 AC_MSG_CHECKING(if you want to build with function extensions)
1068 AC_ARG_ENABLE(ext-funcs,
1069         [  --disable-ext-funcs     disable function-extensions],
1070         [with_ext_funcs=$enableval],
1071         [with_ext_funcs=yes])
1072 AC_MSG_RESULT($with_ext_funcs)
1073 if test "x$with_ext_funcs" = xyes ; then
1074         NCURSES_EXT_FUNCS=1
1075         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1076         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1077         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1078         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1079         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1080         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1081         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1082         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1083         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1084         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1085         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1086         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1087         GENERATED_EXT_FUNCS=generated
1088         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1089 else
1090         NCURSES_EXT_FUNCS=0
1091         GENERATED_EXT_FUNCS=
1092 fi
1093 AC_SUBST(NCURSES_EXT_FUNCS)
1094 AC_SUBST(GENERATED_EXT_FUNCS)
1095
1096 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1097 AC_ARG_ENABLE(sp-funcs,
1098         [  --enable-sp-funcs       enable SCREEN-extensions],
1099         [with_sp_funcs=$enableval],
1100         [with_sp_funcs=$cf_dft_ext_spfuncs])
1101 AC_MSG_RESULT($with_sp_funcs)
1102 if test "x$with_sp_funcs" = xyes ; then
1103         NCURSES_SP_FUNCS=1
1104         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1105         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1106         GENERATED_SP_FUNCS=generated
1107 else
1108         NCURSES_SP_FUNCS=0
1109         GENERATED_SP_FUNCS=
1110 fi
1111 AC_SUBST(NCURSES_SP_FUNCS)
1112 AC_SUBST(GENERATED_SP_FUNCS)
1113
1114 AC_MSG_CHECKING(if you want to build with terminal-driver)
1115 AC_ARG_ENABLE(term-driver,
1116         [  --enable-term-driver    enable terminal-driver],
1117         [with_term_driver=$enableval],
1118         [with_term_driver=no])
1119 AC_MSG_RESULT($with_term_driver)
1120 if test "x$with_term_driver" = xyes ; then
1121         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1122         if test "x$with_termlib" != xno ; then
1123                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1124         fi
1125         if test "x$with_sp_funcs" != xyes ; then
1126                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1127         fi
1128 fi
1129
1130 ###   use option --enable-const to turn on use of const beyond that in XSI.
1131 AC_MSG_CHECKING(for extended use of const keyword)
1132 AC_ARG_ENABLE(const,
1133         [  --enable-const          compile with extra/non-standard const],
1134         [with_ext_const=$enableval],
1135         [with_ext_const=$cf_dft_ext_const])
1136 AC_MSG_RESULT($with_ext_const)
1137 NCURSES_CONST='/*nothing*/'
1138 if test "x$with_ext_const" = xyes ; then
1139         NCURSES_CONST=const
1140 fi
1141 AC_SUBST(NCURSES_CONST)
1142
1143 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1144 AC_MSG_CHECKING(if you want to use extended colors)
1145 AC_ARG_ENABLE(ext-colors,
1146         [  --enable-ext-colors     compile for 256-color support],
1147         [with_ext_colors=$enableval],
1148         [with_ext_colors=$cf_dft_ext_colors])
1149 AC_MSG_RESULT($with_ext_colors)
1150 NCURSES_EXT_COLORS=0
1151 if test "x$with_ext_colors" = xyes ; then
1152         if test "x$with_widec" != xyes ; then
1153                 AC_MSG_WARN(This option applies only to wide-character library)
1154         else
1155                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1156                 CF_NCURSES_ABI_6
1157                 NCURSES_EXT_COLORS=1
1158                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1159                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1160                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1161                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1162         fi
1163 fi
1164 AC_SUBST(NCURSES_EXT_COLORS)
1165
1166 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1167 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1168 AC_ARG_ENABLE(ext-mouse,
1169         [  --enable-ext-mouse      compile for extended mouse-encoding],
1170         [with_ext_mouse=$enableval],
1171         [with_ext_mouse=$cf_dft_ext_mouse])
1172 AC_MSG_RESULT($with_ext_mouse)
1173 NCURSES_MOUSE_VERSION=1
1174 if test "x$with_ext_mouse" = xyes ; then
1175         NCURSES_MOUSE_VERSION=2
1176         CF_NCURSES_ABI_6
1177 fi
1178 AC_SUBST(NCURSES_MOUSE_VERSION)
1179
1180 ###   use option --enable-ext-putwin to turn on extended screendumps
1181 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1182 AC_ARG_ENABLE(ext-putwin,
1183         [  --enable-ext-putwin     compile with extended putwin/screendump],
1184         [with_ext_putwin=$enableval],
1185         [with_ext_putwin=$cf_dft_ext_putwin])
1186 AC_MSG_RESULT($with_ext_putwin)
1187 if test "x$with_ext_putwin" = xyes ; then
1188         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1189 fi
1190
1191 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1192 AC_ARG_ENABLE(no-padding,
1193         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1194         [with_no_padding=$enableval],
1195         [with_no_padding=$with_ext_funcs])
1196 AC_MSG_RESULT($with_no_padding)
1197 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1198
1199 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1200 AC_MSG_CHECKING(if you want SIGWINCH handler)
1201 AC_ARG_ENABLE(sigwinch,
1202         [  --enable-sigwinch       compile with SIGWINCH handler],
1203         [with_sigwinch=$enableval],
1204         [with_sigwinch=$with_ext_funcs])
1205 AC_MSG_RESULT($with_sigwinch)
1206 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1207
1208 ###   use option --enable-tcap-names to allow user to define new capabilities
1209 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1210 AC_ARG_ENABLE(tcap-names,
1211         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1212         [with_tcap_names=$enableval],
1213         [with_tcap_names=$with_ext_funcs])
1214 AC_MSG_RESULT($with_tcap_names)
1215 NCURSES_XNAMES=0
1216 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1217 AC_SUBST(NCURSES_XNAMES)
1218
1219 ##############################################################################
1220 CF_HELP_MESSAGE(Reentrant Code:)
1221 CF_WITH_PTHREAD
1222
1223 if test "x$with_pthread" != xno; then
1224         AC_CHECK_FUNC(pthread_kill,[
1225                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1226                 AC_ARG_ENABLE(pthreads-eintr,
1227                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1228                         [use_pthreads_eintr=$enableval],
1229                         [use_pthreads_eintr=no])
1230                 AC_MSG_RESULT($use_pthreads_eintr)
1231                 if test "x$use_pthreads_eintr" = xyes ; then
1232                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1233                 fi])
1234
1235         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1236         AC_ARG_ENABLE(weak-symbols,
1237                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1238                 [use_weak_symbols=$enableval],
1239                 [use_weak_symbols=no])
1240         AC_MSG_RESULT($use_weak_symbols)
1241         if test "x$use_weak_symbols" = xyes ; then
1242                 CF_WEAK_SYMBOLS
1243         else
1244                 cf_cv_weak_symbols=no
1245         fi
1246
1247         if test "x$cf_cv_weak_symbols" = xyes ; then
1248                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1249         fi
1250 fi
1251
1252 PTHREAD=
1253 if test "x$with_pthread" = "xyes" ; then
1254         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1255         enable_reentrant=yes
1256         if test "x$cf_cv_weak_symbols" = xyes ; then
1257                 PTHREAD=-lpthread
1258         fi
1259 fi
1260 AC_SUBST(PTHREAD)
1261
1262 # Reentrant code has to be opaque; there's little advantage to making ncurses
1263 # opaque outside of that, so there is no --enable-opaque option.  We can use
1264 # this option without --with-pthreads, but this will be always set for
1265 # pthreads.
1266 AC_MSG_CHECKING(if you want reentrant code)
1267 AC_ARG_ENABLE(reentrant,
1268         [  --enable-reentrant      compile with reentrant code],
1269         [with_reentrant=$enableval],
1270         [with_reentrant=no])
1271 AC_MSG_RESULT($with_reentrant)
1272 if test "x$with_reentrant" = xyes ; then
1273         cf_cv_enable_reentrant=1
1274         cf_cv_enable_opaque="NCURSES_INTERNALS"
1275         NCURSES_SIZE_T=int
1276         if test "x$cf_cv_weak_symbols" = xyes ; then
1277                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1278                 CF_ADD_LIB(pthread,TEST_LIBS)
1279                 CF_ADD_LIB(pthread,TEST_LIBS2)
1280         else
1281                 # when not using weak symbols but with_reentrant,
1282                 # add 't' to the library suffix on all platforms
1283                 # except cygwin, where we only do that if ALSO
1284                 # compiling with full thread support.
1285                 case "$host" in
1286                 (*cygwin* | *msys*)
1287                         if test "$with_pthread" = "yes" ; then
1288                                 if test "x$disable_lib_suffixes" = "xno" ; then
1289                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1290                                 fi
1291                         fi ;;
1292                 (*)
1293                         if test "x$disable_lib_suffixes" = "xno" ; then
1294                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1295                         fi
1296                         ;;
1297                 esac
1298         fi
1299         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1300         CF_NCURSES_ABI_6
1301 else
1302         cf_cv_enable_reentrant=0
1303         cf_cv_enable_opaque="NCURSES_OPAQUE"
1304         NCURSES_SIZE_T=short
1305 fi
1306 AC_SUBST(cf_cv_enable_reentrant)
1307 AC_SUBST(cf_cv_enable_opaque)
1308
1309 AC_SUBST(NCURSES_SIZE_T)
1310
1311 AC_MSG_CHECKING(if you want opaque curses-library structures)
1312 CF_ARG_ENABLE(opaque-curses,
1313         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1314         [enable_opaque_curses=yes],[
1315          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1316          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=no
1317         ])
1318 AC_MSG_RESULT($enable_opaque_curses)
1319
1320 test "$cf_cv_enable_reentrant" = 1 && \
1321 test "$enable_opaque_curses" = no && \
1322 AC_MSG_ERROR(reentrant configuration requires opaque library)
1323
1324 AC_MSG_CHECKING(if you want opaque form-library structures)
1325 AC_ARG_ENABLE(opaque-form,
1326         [  --enable-opaque-form    make form-library structures "opaque"],
1327         [enable_opaque_form=yes],[enable_opaque_form=no])
1328 AC_MSG_RESULT($enable_opaque_form)
1329
1330 AC_MSG_CHECKING(if you want opaque menu-library structures)
1331 AC_ARG_ENABLE(opaque-menu,
1332         [  --enable-opaque-menu    make menu-library structures "opaque"],
1333         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1334 AC_MSG_RESULT($enable_opaque_menu)
1335
1336 AC_MSG_CHECKING(if you want opaque panel-library structures)
1337 AC_ARG_ENABLE(opaque-panel,
1338         [  --enable-opaque-panel   make panel-library structures "opaque"],
1339         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1340 AC_MSG_RESULT($enable_opaque_panel)
1341
1342 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1343 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1344 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1345 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1346
1347 AC_SUBST(NCURSES_OPAQUE)
1348 AC_SUBST(NCURSES_OPAQUE_FORM)
1349 AC_SUBST(NCURSES_OPAQUE_MENU)
1350 AC_SUBST(NCURSES_OPAQUE_PANEL)
1351
1352 ### Allow using a different wrap-prefix
1353 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1354         AC_MSG_CHECKING(for prefix used to wrap public variables)
1355         AC_ARG_WITH(wrap-prefix,
1356                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1357                 [NCURSES_WRAP_PREFIX=$withval],
1358                 [NCURSES_WRAP_PREFIX=_nc_])
1359         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1360 else
1361         NCURSES_WRAP_PREFIX=_nc_
1362 fi
1363 AC_SUBST(NCURSES_WRAP_PREFIX)
1364 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1365
1366 ###############################################################################
1367 # These options are relatively safe to experiment with.
1368 CF_HELP_MESSAGE(Development Code:)
1369 AC_MSG_CHECKING(if you want all development code)
1370 AC_ARG_WITH(develop,
1371         [  --without-develop       disable development options],
1372         [with_develop=$withval],
1373         [with_develop=no])
1374 AC_MSG_RESULT($with_develop)
1375
1376 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1377 AC_MSG_CHECKING(if you want hard-tabs code)
1378 AC_ARG_ENABLE(hard-tabs,
1379         [  --enable-hard-tabs      compile with hard-tabs code],,
1380         [enable_hard_tabs=$with_develop])
1381 AC_MSG_RESULT($enable_hard_tabs)
1382 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1383
1384 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1385 AC_MSG_CHECKING(if you want limited support for xmc)
1386 AC_ARG_ENABLE(xmc-glitch,
1387         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1388         [enable_xmc_glitch=$with_develop])
1389 AC_MSG_RESULT($enable_xmc_glitch)
1390 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1391
1392 ###############################################################################
1393 # These are just experimental, probably should not be in a package:
1394 CF_HELP_MESSAGE(Experimental Code:)
1395
1396 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1397 AC_ARG_ENABLE(assumed-color,
1398         [  --disable-assumed-color do not assume anything about default-colors],
1399         [with_assumed_color=$enableval],
1400         [with_assumed_color=yes])
1401 AC_MSG_RESULT($with_assumed_color)
1402 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1403
1404 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1405 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1406 AC_ARG_ENABLE(hashmap,
1407         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1408         [with_hashmap=$enableval],
1409         [with_hashmap=yes])
1410 AC_MSG_RESULT($with_hashmap)
1411 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1412
1413 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1414 AC_MSG_CHECKING(if you want colorfgbg code)
1415 AC_ARG_ENABLE(colorfgbg,
1416         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1417         [with_colorfgbg=$enableval],
1418         [with_colorfgbg=no])
1419 AC_MSG_RESULT($with_colorfgbg)
1420 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1421
1422 ###   use option --enable-interop to turn on use of bindings used for interop
1423 AC_MSG_CHECKING(if you want interop bindings)
1424 AC_ARG_ENABLE(interop,
1425         [  --enable-interop        compile-in interop bindings],
1426         [with_exp_interop=$enableval],
1427         [with_exp_interop=$cf_dft_interop])
1428 AC_MSG_RESULT($with_exp_interop)
1429
1430 NCURSES_INTEROP_FUNCS=0
1431 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1432 AC_SUBST(NCURSES_INTEROP_FUNCS)
1433
1434
1435 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1436 AC_ARG_ENABLE(safe-sprintf,
1437         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1438         [with_safe_sprintf=$enableval],
1439         [with_safe_sprintf=no])
1440 AC_MSG_RESULT($with_safe_sprintf)
1441
1442 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1443 # when hashmap is used scroll hints are useless
1444 if test "$with_hashmap" = no ; then
1445 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1446 AC_ARG_ENABLE(scroll-hints,
1447         [  --disable-scroll-hints  compile without scroll-hints code],
1448         [with_scroll_hints=$enableval],
1449         [with_scroll_hints=yes])
1450 AC_MSG_RESULT($with_scroll_hints)
1451 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1452 fi
1453
1454 AC_MSG_CHECKING(if you want wgetch-events code)
1455 AC_ARG_ENABLE(wgetch-events,
1456         [  --enable-wgetch-events  compile with wgetch-events code],
1457         [with_wgetch_events=$enableval],
1458         [with_wgetch_events=no])
1459 AC_MSG_RESULT($with_wgetch_events)
1460 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1461
1462 ###############################################################################
1463 CF_HELP_MESSAGE(Testing/development Options:)
1464
1465 ###     use option --disable-echo to suppress full display compiling commands
1466 CF_DISABLE_ECHO
1467 if test "x$enable_echo" = xyes; then
1468         ECHO_LINK=
1469 else
1470         ECHO_LINK='@ echo linking $@ ... ;'
1471         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1472         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1473 fi
1474 AC_SUBST(ECHO_LINK)
1475
1476 # --disable-stripping is used for debugging
1477 CF_INSTALL_OPTS
1478
1479 ###     use option --enable-warnings to turn on all gcc warnings
1480 AC_MSG_CHECKING(if you want to see compiler warnings)
1481 AC_ARG_ENABLE(warnings,
1482         [  --enable-warnings       build: turn on GCC compiler warnings],
1483         [with_warnings=$enableval])
1484 AC_MSG_RESULT($with_warnings)
1485
1486 if test "x$with_warnings" = "xyes"; then
1487         CF_ADD_ADAFLAGS(-gnatg)
1488         CF_GCC_WARNINGS(Wno-unknown-pragmas Wswitch-enum)
1489         if test "x$cf_with_cxx" = xyes ; then
1490                 CF_GXX_WARNINGS(Wno-unused)
1491         fi
1492 fi
1493 CF_GCC_ATTRIBUTES
1494 CF_ENABLE_STRING_HACKS
1495
1496 ###     use option --enable-assertions to turn on generation of assertion code
1497 AC_MSG_CHECKING(if you want to enable runtime assertions)
1498 AC_ARG_ENABLE(assertions,
1499         [  --enable-assertions     test: turn on generation of assertion code],
1500         [with_assertions=$enableval],
1501         [with_assertions=no])
1502 AC_MSG_RESULT($with_assertions)
1503 if test -n "$GCC"
1504 then
1505         if test "$with_assertions" = no
1506         then
1507                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1508         else
1509                 CF_ADD_ADAFLAGS(-gnata)
1510         fi
1511 fi
1512
1513 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1514 CF_DISABLE_LEAKS
1515 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1516
1517 ###     use option --enable-expanded to generate certain macros as functions
1518 AC_ARG_ENABLE(expanded,
1519         [  --enable-expanded       test: generate functions for certain macros],
1520         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1521
1522 ###     use option --disable-macros to suppress macros in favor of functions
1523 AC_ARG_ENABLE(macros,
1524         [  --disable-macros        test: use functions rather than macros],
1525         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1526
1527 # Normally we only add trace() to the debug-library.  Allow this to be
1528 # extended to all models of the ncurses library:
1529 cf_all_traces=no
1530 case "$CFLAGS $CPPFLAGS" in
1531 (*-DTRACE*)
1532         cf_all_traces=yes
1533         ;;
1534 esac
1535
1536 AC_MSG_CHECKING(whether to add trace feature to all models)
1537 AC_ARG_WITH(trace,
1538 [  --with-trace            test: add trace() function to all models of ncurses],
1539 [cf_with_trace=$withval],
1540 [cf_with_trace=$cf_all_traces])
1541 AC_MSG_RESULT($cf_with_trace)
1542
1543 if test "x$cf_with_trace" = xyes ; then
1544         LIB_TRACING=all
1545         ADA_TRACE=TRUE
1546         CF_ADD_CFLAGS(-DTRACE)
1547         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1548 else
1549         LIB_TRACING=DEBUG
1550         ADA_TRACE=FALSE
1551 fi
1552
1553 AC_SUBST(ADA_TRACE)
1554
1555 CF_DISABLE_GNAT_PROJECTS
1556
1557 ###     Checks for libraries.
1558 case $cf_cv_system_name in
1559 (*mingw32*|*mingw64*)
1560         CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1561         LIBS=" -lpsapi $LIBS"
1562         ;;
1563 (*)
1564 AC_CHECK_FUNC(gettimeofday,
1565         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1566
1567 AC_CHECK_LIB(bsd, gettimeofday,
1568         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1569         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1570         ;;
1571 esac
1572
1573 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1574 AC_SUBST(MATH_LIB)
1575
1576 ###     Checks for header files.
1577 AC_STDC_HEADERS
1578 AC_HEADER_DIRENT
1579 AC_HEADER_TIME
1580 CF_REGEX
1581
1582 dnl These are some other potentially nonportable headers.
1583 AC_CHECK_HEADERS( \
1584 fcntl.h \
1585 getopt.h \
1586 limits.h \
1587 locale.h \
1588 math.h \
1589 poll.h \
1590 sys/bsdtypes.h \
1591 sys/ioctl.h \
1592 sys/param.h \
1593 sys/poll.h \
1594 sys/select.h \
1595 sys/time.h \
1596 sys/times.h \
1597 ttyent.h \
1598 unistd.h \
1599 wctype.h \
1600 )
1601
1602 CF_GETOPT_HEADER
1603
1604 # check for ISC (this may also define _POSIX_SOURCE)
1605 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1606 if test "x$ISC" = xyes ; then
1607         AC_CHECK_LIB(cposix,main)
1608         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1609 fi
1610
1611 CF_SYS_TIME_SELECT
1612
1613 ###     checks for compiler characteristics
1614 AC_LANG_C
1615 AC_C_CONST
1616 CF_C_INLINE(NCURSES_INLINE,1200)
1617 CF_SIG_ATOMIC_T
1618
1619 if test $NCURSES_CHTYPE = auto ; then
1620         CF_TYPEOF_CHTYPE
1621 else
1622         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1623 fi
1624 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1625 AC_SUBST(cf_cv_typeof_chtype)
1626
1627 CF_UNSIGNED_LITERALS
1628 cf_cv_1UL="1"
1629 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1630 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1631 AC_SUBST(cf_cv_1UL)
1632
1633 if test $NCURSES_MMASK_T = auto ; then
1634         cf_cv_typeof_mmask_t=long
1635 else
1636         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1637 fi
1638 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1639 AC_SUBST(cf_cv_typeof_mmask_t)
1640
1641 ###     Checks for external-data
1642 CF_ERRNO
1643 CF_LINK_DATAONLY
1644
1645 ###     Checks for library functions.
1646 AC_CHECK_FUNCS( \
1647 getcwd \
1648 getegid \
1649 geteuid \
1650 getopt \
1651 getttynam \
1652 issetugid \
1653 poll \
1654 putenv \
1655 remove \
1656 select \
1657 setbuf \
1658 setbuffer \
1659 setenv \
1660 setvbuf \
1661 sigaction \
1662 sigvec \
1663 strdup \
1664 strstr \
1665 tcgetpgrp \
1666 tdestroy \
1667 times \
1668 tsearch \
1669 vsnprintf \
1670 )
1671
1672 if test "x$ac_cv_func_getopt" = xno && \
1673    test "x$cf_with_progs$cf_with_tests" != xnono; then
1674         AC_MSG_ERROR(getopt is required for building programs)
1675 fi
1676
1677 if test "x$with_safe_sprintf" = xyes
1678 then
1679         if test "x$ac_cv_func_vsnprintf" = xyes
1680         then
1681                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1682         else
1683                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1684         fi
1685 fi
1686
1687 if test "x$with_getcap" = "xyes" ; then
1688         CF_CGETENT
1689 fi
1690
1691 CF_ISASCII
1692 CF_STRUCT_SIGACTION
1693 CF_FUNC_NANOSLEEP
1694 CF_FUNC_TERMIOS
1695 CF_FUNC_VSSCANF
1696 CF_MKSTEMP
1697
1698 # setup for prototype of fallback for vsscanf()
1699 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1700
1701 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1702 if test "x$cross_compiling" = xyes ; then
1703         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1704 else
1705         AC_FUNC_SETVBUF_REVERSED
1706 fi
1707 AC_CHECK_TYPE(intptr_t, long)
1708 AC_CHECK_TYPE(ssize_t, int)
1709 CF_TYPE_SIGACTION
1710 CF_SIZECHANGE
1711 CF_FUNC_MEMMOVE
1712 CF_FUNC_POLL
1713 CF_VA_COPY
1714 AC_FUNC_VFORK
1715
1716 # special check for test/ditto.c
1717 CF_FUNC_OPENPTY
1718 if test "$cf_cv_func_openpty" != no ; then
1719         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1720         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1721         if test "x$cf_cv_lib_util" = xyes ; then
1722                 CF_ADD_LIB(util,TEST_LIBS)
1723         fi
1724 fi
1725 AC_SUBST(TEST_LIBS)
1726 AC_SUBST(TEST_LIBS2)
1727
1728 if test "$with_hashed_db" != no ; then
1729         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1730         CF_HASHED_DB($with_hashed_db)
1731 fi
1732
1733 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1734 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1735         CF_STRIP_G_OPT(CFLAGS)
1736         CF_STRIP_G_OPT(CXXFLAGS)
1737 fi
1738
1739 # Just in case, check if the C compiler has a bool type.
1740 CF_BOOL_DECL(cf_cv_cc_bool_type)
1741
1742 # Check for C++ compiler characteristics (and ensure that it's there!)
1743 if test -n "$CXX" ; then
1744         AC_LANG_CPLUSPLUS
1745         CF_STDCPP_LIBRARY
1746         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1747
1748         case $GXX_VERSION in
1749         (1*|2.[0-6]*)
1750                 cf_cxx_library=yes
1751                 ;;
1752         (*-2.7*|2.7*)
1753                 CF_GPP_LIBRARY
1754                 ;;
1755         (*)
1756                 cf_cxx_library=no
1757                 ;;
1758         esac
1759
1760         AC_CHECK_HEADERS(typeinfo)
1761         CF_CXX_IOSTREAM_NAMESPACE
1762         CF_BOOL_DECL
1763         CF_BOOL_SIZE
1764         CF_ETIP_DEFINES
1765         CF_CPP_PARAM_INIT
1766         CF_CPP_STATIC_CAST
1767         CF_CXX_AR_FLAGS
1768 else
1769         cf_cxx_library=no
1770         cf_cv_builtin_bool=1
1771
1772         # Just because we are not configuring against C++ right now does not
1773         # mean that a user will not want to use C++.  Some distributors disable
1774         # the C++ portion of this configuration as a shortcut (or just to avoid
1775         # compiling the demo in the c++ directory).  So we need a reasonable
1776         # default for the 'bool' type.
1777         #
1778         # Caveat: since the storage of the bool type is not standardized, it
1779         # may change.
1780
1781         if test "$NCURSES_BOOL" != auto ; then
1782                 cf_cv_type_of_bool=$NCURSES_BOOL
1783                 cf_cv_header_stdbool_h=0
1784         else
1785                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1786                         CF_BOOL_SIZE
1787                 else
1788                         AC_MSG_CHECKING(for fallback type of bool)
1789                         case "$host_cpu" in
1790                         (i?86)  cf_cv_type_of_bool=char ;;
1791                         (*)     cf_cv_type_of_bool=int  ;;
1792                         esac
1793                         AC_MSG_RESULT($cf_cv_type_of_bool)
1794                 fi
1795         fi
1796 fi
1797 AC_SUBST(CXXLIBS)
1798
1799 # If the C compiler did not declare bool, and we did not determine that the C++
1800 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1801 # ncurses library use the same type as C++ bool.  Note that this allows one to
1802 # specify the type of bool in a configure-script option and postpone
1803 # integration with the C++ compiler provided that the types are compatible.
1804 USE_CXX_BOOL=1
1805 if test $cf_cv_cc_bool_type = 1
1806 then
1807         # oops: C has a bool.  Unlikely, but C++ could differ.
1808         USE_CXX_BOOL=0
1809 elif test $cf_cv_builtin_bool = 0
1810 then
1811         # C++ has no bool
1812         USE_CXX_BOOL=0
1813 else
1814         # this is the normal case
1815         USE_CXX_BOOL='defined(__cplusplus)'
1816 fi
1817 AC_SUBST(USE_CXX_BOOL)
1818
1819 CF_HELP_MESSAGE(Ada95 Binding Options:)
1820
1821 dnl If the Ada95 source-tree is present, add that to the build unless it will
1822 dnl not work, or was not requested.
1823 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1824
1825 dnl libtool does not know anything about GNAT, though a change made in 1998
1826 dnl provided for it "someday".  Disable the ada subtree if we are using
1827 dnl libtool -TD 20070714
1828         if test "$cf_with_ada" != "no" ; then
1829                 if test "$with_libtool" != "no"; then
1830                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1831                         cf_with_ada=no
1832                 fi
1833         fi
1834
1835 dnl Check for availability of GNU Ada Translator (GNAT).
1836 dnl At the moment we support no other Ada95 compiler.
1837         if test "$cf_with_ada" != "no" ; then
1838                 CF_PROG_GNAT
1839                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1840                         CF_ADD_ADAFLAGS(-gnatpn)
1841                         CF_FIXUP_ADAFLAGS
1842
1843                         CF_GNATPREP_OPT_T
1844
1845                         CF_GNAT_GENERICS
1846                         CF_GNAT_SIGINT
1847                         CF_GNAT_PROJECTS
1848
1849                         CF_WITH_ADA_COMPILER
1850
1851                         cf_ada_package=terminal_interface
1852                         AC_SUBST(cf_ada_package)
1853
1854                         CF_WITH_ADA_INCLUDE
1855                         CF_WITH_ADA_OBJECTS
1856                         CF_WITH_ADA_SHAREDLIB
1857                 fi
1858         fi
1859 else
1860         cf_with_ada=no
1861 fi
1862
1863 # do this "late" to avoid conflict with header-checks
1864 if test "x$with_widec" = xyes ; then
1865         AC_CHECK_SIZEOF(wchar_t)
1866 fi
1867
1868 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1869 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1870 ###
1871 ### ticlib modules may be a separate library, otherwise contained in termlib.
1872 ### termlib modules may be a separate library, otherwise contained in ncurses.
1873 ###
1874 ### The of "+" or " " between the tokens controls the way the script
1875 ### chooses to split module lists into libraries.
1876 ###
1877 ### (see CF_LIB_RULES).
1878 AC_MSG_CHECKING(for library subsets)
1879 LIB_SUBSETS=
1880
1881 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1882         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1883         if test "$with_ticlib" != no ; then
1884                 LIB_SUBSETS="${LIB_SUBSETS} "
1885         else
1886                 LIB_SUBSETS="${LIB_SUBSETS}+"
1887         fi
1888 fi
1889
1890 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1891 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1892
1893 if test "$with_termlib" != no ; then
1894         LIB_SUBSETS="${LIB_SUBSETS} "
1895 else
1896         LIB_SUBSETS="${LIB_SUBSETS}+"
1897 fi
1898
1899 LIB_SUBSETS="${LIB_SUBSETS}base"
1900
1901 # Most term-driver calls are to tinfo, but some like init_pair are to the
1902 # base library (so it resides in base).
1903 if test "$with_term_driver" != no ; then
1904         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1905         case $cf_cv_system_name in
1906         (*mingw32*|*mingw64*)
1907                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1908                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
1909                 ;;
1910         (*)
1911                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1912                 ;;
1913         esac
1914 fi
1915
1916 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1917 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1918
1919 AC_MSG_RESULT($LIB_SUBSETS)
1920
1921 ### Construct the list of include-directories to be generated
1922 CF_INCLUDE_DIRS
1923 CF_ADA_INCLUDE_DIRS
1924
1925 ### Build up pieces for makefile rules
1926 AC_MSG_CHECKING(default library suffix)
1927 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1928 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1929 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1930
1931 AC_MSG_CHECKING(default library-dependency suffix)
1932 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1933 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1934 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1935
1936 AC_MSG_CHECKING(default object directory)
1937 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1938 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1939 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1940
1941 if test "x$cf_with_cxx" = xyes ; then
1942 AC_MSG_CHECKING(c++ library-dependency suffix)
1943 if test "$with_libtool" != "no"; then
1944         # libtool thinks it can make c++ shared libraries (perhaps only g++)
1945         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1946 elif test "$with_shared_cxx" != "no"; then
1947         # also for g++ users...
1948         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1949 else
1950         # we normally make a static library because C/C++ library rules differ
1951         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
1952 fi
1953 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1954 AC_SUBST(CXX_LIB_SUFFIX)
1955 fi
1956
1957 # do not want -ldl in build except as needed for -lncurses dependency
1958 if test "x$with_dlsym" = xyes ; then
1959 if test $DFT_LWR_MODEL = shared || \
1960    test $DFT_LWR_MODEL = libtool ; then
1961         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1962 fi
1963 fi
1964 ### Set up low-level terminfo dependencies for makefiles.
1965
1966 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1967 # do not need libdl
1968 TICS_LIST=
1969 if test "x$with_dlsym" = xyes ; then
1970         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1971 fi
1972
1973 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
1974 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
1975 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
1976 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
1977 then
1978         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
1979 fi
1980 AC_SUBST(USE_ARG_SUFFIX)
1981 AC_SUBST(USE_CFG_SUFFIX)
1982 AC_SUBST(USE_LIB_SUFFIX)
1983
1984 if test "$with_ticlib" != no ; then
1985
1986         if test "x$with_ticlib" != xyes ; then
1987                 TICS_NAME=$with_ticlib
1988                 TICS_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
1989                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1990                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1991                 TICS_LIB_SUFFIX="${with_ticlib}"
1992         else
1993                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
1994                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
1995                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1996                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
1997         fi
1998         TICS_LDFLAGS="-L${LIB_DIR}"
1999         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2000 else
2001         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2002         TICS_LDFLAGS="-L${LIB_DIR}"
2003         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2004 fi
2005 AC_SUBST(TICS_ARG_SUFFIX)
2006 AC_SUBST(TICS_DEP_SUFFIX)
2007 AC_SUBST(TICS_LIB_SUFFIX)
2008 AC_SUBST(TICS_LDFLAGS)
2009 AC_SUBST(TICS_LIBS)
2010
2011 if test "$with_termlib" != no ; then
2012
2013         if test "x$with_termlib" != xyes ; then
2014                 TINFO_NAME=$with_termlib
2015                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2016                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2017                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2018                 TINFO_LIB_SUFFIX="${with_termlib}"
2019         else
2020                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2021                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2022                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2023                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2024         fi
2025
2026         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2027         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2028         if test "$DFT_LWR_MODEL" = "libtool"; then
2029                 TEST_ARGS="${TEST_DEPS}"
2030                 TEST_ARG2="${TEST_DEP2}"
2031                 TINFO_LDFLAGS="-L${LIB_DIR}"
2032                 TINFO_LIBS="$TEST_ARGS"
2033                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2034                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2035         else
2036                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2037                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2038                 if test "x$with_term_driver" != xno ; then
2039                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2040                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2041                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2042                 else
2043                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2044                         TINFO_LIBS="$TEST_ARGS"
2045                 fi
2046                 TINFO_LDFLAGS="-L${LIB_DIR}"
2047                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2048         fi
2049 else
2050         # the next lines are needed for linking libtic over libncurses
2051         TINFO_NAME=${LIB_NAME}
2052         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2053         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2054         if test "x$with_tic_depends" = xyes ; then
2055                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2056         else
2057                 TICS_LIST="$SHLIB_LIST"
2058         fi
2059
2060         TINFO_LDFLAGS="-L${LIB_DIR}"
2061         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2062 fi
2063
2064 if test "$DFT_LWR_MODEL" = shared ; then
2065         case $cf_cv_system_name in
2066         (cygwin*|msys*)
2067                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2068                 TINFO_SUFFIX=.dll
2069                 ;;
2070         esac
2071 fi
2072
2073 AC_SUBST(TINFO_ARG_SUFFIX)
2074 AC_SUBST(TINFO_DEP_SUFFIX)
2075 AC_SUBST(TINFO_LIB_SUFFIX)
2076 AC_SUBST(TINFO_LDFLAGS)
2077 AC_SUBST(TINFO_LIBS)
2078
2079 if test "x$with_dlsym" = xyes ; then
2080         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2081 fi
2082
2083 if test "$DFT_LWR_MODEL" = "libtool"; then
2084         OBJEXT=lo
2085 fi
2086
2087 # needed for Ada95
2088 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2089 AC_SUBST(TINFO_LDFLAGS2)
2090
2091 case $DFT_LWR_MODEL in
2092 (normal|debug|profile)
2093         CF_LDFLAGS_STATIC
2094         ;;
2095 esac
2096
2097 AC_MSG_CHECKING(where we will install curses.h)
2098 AC_SUBST(includesubdir)
2099 includesubdir=
2100 if test "$with_overwrite" = no && \
2101  ( test "x$includedir" = 'x${prefix}/include' || \
2102    test "x$includedir" = "x${prefix}/include" )
2103 then
2104         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2105 fi
2106 AC_MSG_RESULT(${includedir}${includesubdir})
2107
2108 ### Resolve a conflict between normal and wide-curses by forcing applications
2109 ### that will need libutf8 to add it to their configure script.
2110 if test "$with_overwrite" != no ; then
2111 if test "$NCURSES_LIBUTF8" = 1 ; then
2112         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2113         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2114 fi
2115 fi
2116 WITH_OVERWRITE=$with_overwrite
2117
2118 AC_SUBST(WITH_OVERWRITE)
2119 AC_SUBST(TICS_LIST)
2120 AC_SUBST(TINFO_LIST)
2121 AC_SUBST(SHLIB_LIST)
2122
2123 # used to separate tack out of the tree
2124 NCURSES_TREE=
2125 AC_SUBST(NCURSES_TREE)
2126
2127 ### predefined stuff for the test programs
2128 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2129
2130 ### Construct the list of subdirectories for which we'll customize makefiles
2131 ### with the appropriate compile-rules.
2132
2133 CF_SRC_MODULES($modules_to_build)
2134
2135 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2136    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2137    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2138 fi
2139
2140 CF_DIRS_TO_MAKE
2141
2142 # symbols that differ when compiling Ada95 by itself.
2143 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2144 AC_SUBST(NCURSES_SHLIB2)
2145
2146 # values to use as strings
2147 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2148
2149 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2150
2151 ### Now that we're done running tests, add the compiler-warnings, if any
2152 CF_ADD_CFLAGS($EXTRA_CFLAGS)
2153
2154 ### Define substitutions for header files to avoid name-pollution
2155 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2156 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2157 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2158 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2159
2160 ################################################################################
2161 test "x$use_database" = xyes && \
2162 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2163
2164 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2165 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2166
2167 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2168 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2169 fi
2170 AC_SUBST(cross_compiling)
2171
2172 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
2173 if test -n "$FALLBACK_LIST"
2174 then
2175         if test "$TIC_PATH" = unknown
2176         then
2177                 AC_MSG_WARN(no tic program found for fallbacks)
2178         fi
2179 fi
2180 AC_SUBST(TIC_PATH)
2181
2182 if test "x$cf_with_tests" != xno ; then
2183         MAKE_TESTS=
2184 else
2185         MAKE_TESTS="#"
2186 fi
2187 AC_SUBST(MAKE_TESTS)
2188
2189 ADAHTML_DIR=../../doc/html/ada
2190 AC_SUBST(ADAHTML_DIR)
2191
2192 # these could be configurable, but are not currently
2193 PANEL_NAME=panel
2194 MENU_NAME=menu
2195 FORM_NAME=form
2196 CXX_NAME=ncurses++
2197
2198 AC_SUBST(PANEL_NAME)
2199 AC_SUBST(MENU_NAME)
2200 AC_SUBST(FORM_NAME)
2201 AC_SUBST(CXX_NAME)
2202
2203 # workaround for OS/2 (20151017)
2204 case $cf_cv_system_name in
2205 (os2*)
2206         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2207         ;;
2208 (*)
2209         LIBTOOL_OPTS_CXX=
2210         ;;
2211 esac
2212 AC_SUBST(LIBTOOL_OPTS_CXX)
2213
2214 # workaround for g++ versus Solaris (20131116)
2215 case $cf_cv_system_name in
2216 (solaris2*)
2217         case "x$CPPFLAGS" in
2218         (*-D_XOPEN_SOURCE_EXTENDED*)
2219                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2220                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2221                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2222                 ;;
2223         esac
2224         ;;
2225 esac
2226
2227 # Help to automatically enable the extended curses features when using either
2228 # the *-config or the ".pc" files by adding defines.
2229 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2230 PKG_CFLAGS=
2231 for cf_loop1 in $CPPFLAGS_after_XOPEN
2232 do
2233         cf_found=no
2234         for cf_loop2 in $CPPFLAGS_before_XOPEN
2235         do
2236                 if test "x$cf_loop1" = "x$cf_loop2"
2237                 then
2238                         cf_found=yes
2239                         break
2240                 fi
2241         done
2242         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2243 done
2244 AC_MSG_RESULT($PKG_CFLAGS)
2245 AC_SUBST(PKG_CFLAGS)
2246
2247 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2248 case "x$NCURSES_OSPEED" in
2249 (*short*)
2250         cf_compatible=1
2251         ;;
2252 (*)
2253         cf_compatible=0
2254         ;;
2255 esac
2256 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2257
2258 case "x$cf_cv_typeof_chtype" in
2259 (xshort|xint|xlong)
2260         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2261         ;;
2262 esac
2263
2264 case "x$cf_cv_typeof_mmask_t" in
2265 (xshort|xint|xlong)
2266         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2267         ;;
2268 esac
2269
2270 # substitute into misc/Makefile to suppress
2271 # (un)install.data from the
2272 # (un)install rules.
2273 if test "x$cf_with_db_install" = "xno"; then
2274         MISC_INSTALL_DATA=
2275         MISC_UNINSTALL_DATA=
2276 else
2277         MISC_INSTALL_DATA=install.data
2278         MISC_UNINSTALL_DATA=uninstall.data
2279 fi
2280 AC_SUBST(MISC_INSTALL_DATA)
2281 AC_SUBST(MISC_UNINSTALL_DATA)
2282
2283 SUB_SCRIPTS=
2284
2285 dnl Override the package used for exported symbols
2286 if test -n "$PACKAGE"
2287 then
2288         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2289         export PACKAGE
2290         echo "package: $PACKAGE"
2291 fi
2292
2293 UNALTERED_SYMS=
2294 cf_filter_syms=no
2295
2296 if test -n "$RESULTING_SYMS"
2297 then
2298         cf_filter_syms=$cf_dft_filter_syms
2299         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2300 fi
2301
2302 if test "x$WILDCARD_SYMS" = xno
2303 then
2304         cf_filter_syms=yes
2305 fi
2306
2307 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2308
2309 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2310 if test $cf_filter_syms = yes
2311 then
2312         RESULTING_SYMS=resulting.map
2313 fi
2314 AC_SUBST(UNALTERED_SYMS)
2315
2316 if test "x$cross_compiling" = xyes ; then
2317         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2318         CHECK_BUILD="#"
2319 else
2320         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2321         CHECK_BUILD=
2322 fi
2323 AC_SUBST(ADAGEN_LDFLAGS)
2324 AC_SUBST(CHECK_BUILD)
2325
2326 AC_DEFINE(HAVE_CURSES_DATA_BOOLNAMES,1,[definition needed for in-tree build of tack])
2327
2328 AC_OUTPUT( \
2329         include/MKterm.h.awk \
2330         include/curses.head:include/curses.h.in \
2331         include/ncurses_dll.h \
2332         include/termcap.h \
2333         include/unctrl.h \
2334         $SUB_SCRIPTS \
2335         $SUB_MAKEFILES \
2336         Makefile,[
2337 if test "x$cf_with_tests" != xno ; then
2338         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2339 fi
2340 CF_LIB_RULES($SRC_SUBDIRS)
2341
2342 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2343 if test -z "$USE_OLD_MAKERULES" ; then
2344         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
2345 fi
2346 fi
2347 ],[
2348 ### Special initialization commands, used to pass information from the
2349 ### configuration-run into config.status
2350
2351 AWK="$AWK"
2352 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2353 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2354 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2355 ECHO_LD="$ECHO_LD"
2356 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2357 LDCONFIG="$LDCONFIG"
2358 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2359 LIB_NAME="$LIB_NAME"
2360 LIB_PREFIX="$LIB_PREFIX"
2361 LIB_SUBSETS="$LIB_SUBSETS"
2362 LIB_SUFFIX="$LIB_SUFFIX"
2363 LIB_TRACING="$LIB_TRACING"
2364 LN_S="$LN_S"
2365 MAKE_TERMINFO="$MAKE_TERMINFO"
2366 NCURSES_MAJOR="$NCURSES_MAJOR"
2367 NCURSES_MINOR="$NCURSES_MINOR"
2368 NCURSES_OSPEED="$NCURSES_OSPEED"
2369 NCURSES_PATCH="$NCURSES_PATCH"
2370 SRC_SUBDIRS="$SRC_SUBDIRS"
2371 TERMINFO="$TERMINFO"
2372 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2373 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2374 TICS_NAME="$TICS_NAME"
2375 TICS_SUFFIX="$TICS_SUFFIX"
2376 TIC_PATH="$TIC_PATH"
2377 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2378 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2379 TINFO_NAME="$TINFO_NAME"
2380 TINFO_SUFFIX="$TINFO_SUFFIX"
2381 UNALTERED_SYMS="$UNALTERED_SYMS"
2382 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2383 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2384 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2385 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2386 WILDCARD_SYMS="$WILDCARD_SYMS"
2387 WITH_CURSES_H="$with_curses_h"
2388 WITH_ECHO="${enable_echo:=yes}"
2389 WITH_OVERWRITE="$with_overwrite"
2390 cf_LIST_MODELS="$cf_list_models"
2391 cf_cv_abi_version="$cf_cv_abi_version"
2392 cf_cv_do_relink="$cf_cv_do_relink"
2393 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2394 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2395 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2396 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2397 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2398 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2399 cf_cv_rel_version="$cf_cv_rel_version"
2400 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2401 cf_cv_shared_soname='$cf_cv_shared_soname'
2402 cf_cv_shlib_version="$cf_cv_shlib_version"
2403 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2404 cf_cv_system_name="$cf_cv_system_name"
2405 cf_cv_term_driver="$with_term_driver"
2406 cf_with_ada="$cf_with_ada"
2407 cf_with_cxx_binding="$cf_with_cxx_binding"
2408 cf_with_db_install="$cf_with_db_install"
2409 cf_with_manpages="$cf_with_manpages"
2410 cf_with_tests="$cf_with_tests"
2411 host="$host"
2412 target="$target"
2413 with_shared_cxx="$with_shared_cxx"
2414
2415 ],cat)dnl
2416 ${MAKE:-make} preinstall