ncurses 6.1 - patch 20190623
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2018,2019 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.682 2019/06/23 21:26:48 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See https://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.52.20170501)
38 AC_REVISION($Revision: 1.682 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44 CF_VERSION_INFO(NCURSES,ncurses)
45
46 CF_WITH_REL_VERSION(NCURSES)
47 CF_NCURSES_WITH_ABI_VERSION
48
49 CF_WITH_SYSTYPE
50
51 ###     Save the given $CFLAGS to allow user-override.
52 cf_user_CFLAGS="$CFLAGS"
53
54 ###     Default install-location
55 CF_CFG_DEFAULTS
56 ### Defaults for ncurses ABI
57 CF_ABI_DEFAULTS
58
59 ###     Checks for programs.
60 AC_ARG_WITH(ada,
61         [  --without-ada           suppress check for Ada95, don't build demo],
62         [cf_with_ada=$withval],
63         [cf_with_ada=yes])
64
65 if test "x$cf_with_ada" = xyes
66 then
67         cf_prog_cc="gnatgcc gcc cc"
68 else
69         cf_prog_cc="gcc cc"
70 fi
71 CF_PROG_CC($cf_prog_cc)
72
73 AC_PROG_CPP
74 AC_PROG_GCC_TRADITIONAL
75 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
76 CF_PROG_LDCONFIG
77
78 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
79 dnl                             configure script by not letting us test if C++
80 dnl                             is present, making this option necessary.
81 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
82 AC_ARG_WITH(cxx,
83         [  --without-cxx           do not adjust ncurses bool to match C++],
84         [cf_with_cxx=$withval],
85         [cf_with_cxx=yes])
86 AC_MSG_RESULT($cf_with_cxx)
87 if test "X$cf_with_cxx" = Xno ; then
88         CXX=""
89         GXX=""
90 else
91         # with autoconf 2.13, we can change the error to a warning:
92         pushdef([AC_MSG_ERROR],
93                 [AC_MSG_RESULT(no)
94                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
95                 cf_with_cxx=no; CXX=""; GXX="";])dnl
96         AC_PROG_CXX
97         popdef([AC_MSG_ERROR])dnl
98
99         AC_LANG_PUSH(C++)
100         if test "x$cf_with_cxx" != xno
101         then
102                 # Several of the C++ configurations do not work, particularly when
103                 # cross-compiling (20140913 -TD)
104                 AC_MSG_CHECKING(if $CXX works)
105
106                 save_CPPFLAGS="$CPPFLAGS"
107                 eval cf_includedir=${includedir}
108                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
109                 AC_TRY_COMPILE([
110 #include <stdlib.h>
111 #include <stdio.h>
112 ],
113                 [
114                 printf("Hello world!\n")
115                 ],
116                 [cf_cxx_works=yes],
117                 [cf_cxx_works=no])
118                 CPPFLAGS="$save_CPPFLAGS"
119
120                 AC_MSG_RESULT($cf_cxx_works)
121                 if test "x$cf_cxx_works" = xno
122                 then
123                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
124                         cf_with_cxx=no; CXX=""; GXX="";
125                 fi
126         fi
127         AC_LANG_POP
128
129         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
130         if test "$CXX" = "g++" ; then
131                 AC_PATH_PROG(CXX,g++)
132         fi
133         case "x$CXX" in
134         (x|xg++)
135                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
136                 cf_with_cxx=no; CXX=""; GXX="";
137                 ;;
138         esac
139 fi
140
141 CF_GXX_VERSION
142 case $GXX_VERSION in
143 (1*|2.[[0-6]]*)
144         # GXX=""; CXX=""; ac_cv_prog_gxx=no
145         # cf_cxx_library=no
146         AC_MSG_WARN(templates do not work)
147         ;;
148 esac
149
150 AC_MSG_CHECKING(if you want to build C++ binding and demo)
151 AC_ARG_WITH(cxx-binding,
152         [  --without-cxx-binding   do not build C++ binding and demo],
153         [cf_with_cxx_binding=$withval],
154         [cf_with_cxx_binding=$cf_with_cxx])
155 AC_MSG_RESULT($cf_with_cxx_binding)
156
157 AC_MSG_CHECKING(if you want to build with Ada95)
158 AC_MSG_RESULT($cf_with_ada)
159
160 AC_MSG_CHECKING(if you want to install terminal database)
161 AC_ARG_ENABLE(db-install,
162         [  --disable-db-install    suppress install of terminal database],
163         [cf_with_db_install=$enableval],
164         [cf_with_db_install=yes])
165 AC_MSG_RESULT($cf_with_db_install)
166
167 AC_MSG_CHECKING(if you want to install manpages)
168 AC_ARG_WITH(manpages,
169         [  --without-manpages      suppress install of manpages],
170         [cf_with_manpages=$withval],
171         [cf_with_manpages=yes])
172 AC_MSG_RESULT($cf_with_manpages)
173
174 AC_MSG_CHECKING(if you want to build programs such as tic)
175 AC_ARG_WITH(progs,
176         [  --without-progs         suppress build/install with programs (e.g., tic)],
177         [cf_with_progs=$withval],
178         [cf_with_progs=yes])
179 AC_MSG_RESULT($cf_with_progs)
180
181 if test -f $srcdir/tack/tack.h; then
182         if test "x$cross_compiling" = xyes ; then
183                 CF_VERBOSE(ignoring tack because we are cross-compiling)
184                 cf_with_tack=no
185         else
186                 AC_MSG_CHECKING(if you want to build the tack program)
187                 AC_ARG_WITH(tack,
188                         [  --without-tack          suppress build/install with tack program],
189                         [cf_with_tack=$withval],
190                         [cf_with_tack=$cf_with_progs])
191                 AC_MSG_RESULT($cf_with_tack)
192         fi
193 else
194         cf_with_tack=no
195 fi
196
197 AC_MSG_CHECKING(if you want to build test-programs)
198 AC_ARG_WITH(tests,
199         [  --without-tests         suppress build/install with test-programs],
200         [cf_with_tests=$withval],
201         [cf_with_tests=yes])
202 AC_MSG_RESULT($cf_with_tests)
203
204 AC_MSG_CHECKING(if you wish to install curses.h)
205 AC_ARG_WITH(curses-h,
206         [  --without-curses-h      install curses.h as ncurses.h only],
207         [with_curses_h=$withval],
208         [with_curses_h=yes])
209 AC_MSG_RESULT($with_curses_h)
210
211 modules_to_build="ncurses"
212 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
213 test "X$cf_with_tack"  != Xno && modules_to_build="$modules_to_build tack"
214 modules_to_build="$modules_to_build panel menu form"
215
216 AC_ARG_PROGRAM
217
218 CF_PROG_AWK
219 CF_PROG_EGREP
220 CF_PROG_INSTALL
221 CF_PROG_LINT
222 CF_PROG_LN_S
223
224 AC_SYS_LONG_FILE_NAMES
225
226 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
227 # of package conflict.
228 cf_config_suffix=
229 AC_ARG_WITH(config-suffix,
230         [  --with-config-suffix=X  suffixes ncursesXX-config file],
231         [case "x$withval" in
232         (xyes|xno)
233                 AC_MSG_WARN(expected a value for config-suffix option)
234                 ;;
235         (*)     cf_config_suffix="$withval"
236                 ;;
237         esac])
238 AC_SUBST(cf_config_suffix)
239
240 # If we find pkg-config, check if we should install the ".pc" files.
241 CF_PKG_CONFIG
242 CF_WITH_PKG_CONFIG_LIBDIR
243 CF_ENABLE_PC_FILES
244 if test -z "$MAKE_PC_FILES"
245 then
246         AC_MSG_CHECKING(for suffix to add to pc-files)
247 AC_ARG_WITH(pc-suffix,
248         [  --with-pc-suffix        suffixes pc-files],
249         [case "x$withval" in
250         (xyes|xno)
251                 PC_MODULE_SUFFIX=
252                 ;;
253         (*)     PC_MODULE_SUFFIX="$withval"
254                 ;;
255         esac])
256         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
257         AC_MSG_RESULT($PC_MODULE_SUFFIX)
258         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
259         AC_SUBST(PC_MODULE_SUFFIX)
260 fi
261
262 AC_MSG_CHECKING(if we should assume mixed-case filenames)
263 AC_ARG_ENABLE(mixed-case,
264         [  --enable-mixed-case     tic should assume mixed-case filenames],
265         [enable_mixedcase=$enableval],
266         [enable_mixedcase=auto])
267 AC_MSG_RESULT($enable_mixedcase)
268 if test "$enable_mixedcase" = "auto" ; then
269         CF_MIXEDCASE_FILENAMES
270 else
271         cf_cv_mixedcase=$enable_mixedcase
272         if test "x$enable_mixedcase" = "xyes" ; then
273                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
274         fi
275 fi
276
277 # do this after mixed-case option (tags/TAGS is not as important as tic).
278 AC_PROG_MAKE_SET
279 CF_MAKE_TAGS
280 CF_MAKEFLAGS
281
282 dnl These are standard among *NIX systems, but not when cross-compiling
283 AC_CHECK_TOOL(RANLIB, ranlib, ':')
284 AC_CHECK_TOOL(LD, ld, ld)
285 AC_CHECK_TOOL(AR, ar, ar)
286 AC_CHECK_TOOL(NM, nm, nm)
287 CF_AR_FLAGS
288
289 dnl Special option for use by system-builders: the install-prefix is used to
290 dnl adjust the location into which the actual install is done, so that an
291 dnl archive can be built without modifying the host system's configuration.
292 AC_MSG_CHECKING(if you have specified an install-prefix)
293 AC_ARG_WITH(install-prefix,
294         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
295         [case "x$withval" in
296         (xyes|xno)
297                 ;;
298         (*)     DESTDIR="$withval"
299                 ;;
300         esac])
301 AC_MSG_RESULT($DESTDIR)
302 AC_SUBST(DESTDIR)
303
304 ###############################################################################
305 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
306 # If we're cross-compiling, allow the user to override the tools and their
307 # options.  The configure script is oriented toward identifying the host
308 # compiler, etc., but we need a build compiler to generate parts of the source.
309 CF_BUILD_CC
310
311 ###############################################################################
312 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
313
314 ### Options to allow the user to specify the set of libraries which are used.
315 ### Use "--without-normal --with-shared" to allow the default model to be
316 ### shared, for example.
317 cf_list_models=""
318 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
319
320 CF_WITH_LIBTOOL
321 if test "$with_libtool" != "no" ; then
322
323 cf_list_models="$cf_list_models libtool"
324
325 else
326
327 AC_MSG_CHECKING(if you want to build shared libraries)
328 AC_ARG_WITH(shared,
329         [  --with-shared           generate shared-libraries],
330         [with_shared=$withval],
331         [with_shared=no])
332 AC_MSG_RESULT($with_shared)
333 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
334
335 AC_MSG_CHECKING(if you want to build static libraries)
336 AC_ARG_WITH(normal,
337         [  --with-normal           generate normal-libraries (default)],
338         [with_normal=$withval],
339         [with_normal=yes])
340 AC_MSG_RESULT($with_normal)
341 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
342
343 AC_MSG_CHECKING(if you want to build debug libraries)
344 AC_ARG_WITH(debug,
345         [  --with-debug            generate debug-libraries (default)],
346         [with_debug=$withval],
347         [with_debug=yes])
348 AC_MSG_RESULT($with_debug)
349 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
350
351 AC_MSG_CHECKING(if you want to build profiling libraries)
352 AC_ARG_WITH(profile,
353         [  --with-profile          generate profile-libraries],
354         [with_profile=$withval],
355         [with_profile=no])
356 AC_MSG_RESULT($with_profile)
357 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
358
359 fi
360
361 if test "X$cf_with_cxx_binding" != Xno; then
362 if test "x$with_shared" = "xyes"; then
363 AC_MSG_CHECKING(if you want to build C++ shared libraries)
364 AC_ARG_WITH(cxx-shared,
365         [  --with-cxx-shared       generate C++ shared-libraries],
366         [with_shared_cxx=$withval],
367         [with_shared_cxx=no])
368 AC_MSG_RESULT($with_shared_cxx)
369 fi
370 fi
371
372 ###############################################################################
373
374 AC_MSG_CHECKING(for specified models)
375 test -z "$cf_list_models" && cf_list_models=normal
376 dnl If we use libtool to generate libraries, then it must be the only
377 dnl specified model.
378 test "$with_libtool" != "no" && cf_list_models=libtool
379 AC_MSG_RESULT($cf_list_models)
380
381 ### Use the first model as the default, and save its suffix for use in building
382 ### up test-applications.
383 AC_MSG_CHECKING(for default model)
384 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
385 AC_MSG_RESULT($DFT_LWR_MODEL)
386
387 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
388
389 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
390 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
391
392 TICS_NAME=tic
393 AC_SUBST(TICS_NAME)
394
395 TINFO_NAME=tinfo
396 AC_SUBST(TINFO_NAME)
397
398 LIB_NAME=ncurses
399 AC_SUBST(LIB_NAME)
400
401 LIB_DIR=../lib
402 LIB_2ND=../../lib
403
404 CF_WITH_LIB_PREFIX(cf_prefix)
405
406 LIB_SUFFIX=
407 AC_SUBST(LIB_SUFFIX)
408 CF_PATHSEP
409
410 ###############################################################################
411
412 AC_MSG_CHECKING(if you want to build a separate terminfo library)
413 AC_ARG_WITH(termlib,
414         [  --with-termlib          generate separate terminfo library],
415         [with_termlib=$withval],
416         [with_termlib=no])
417 AC_MSG_RESULT($with_termlib)
418
419 AC_MSG_CHECKING(if you want to build a separate tic library)
420 AC_ARG_WITH(ticlib,
421         [  --with-ticlib           generate separate tic library],
422         [with_ticlib=$withval],
423         [with_ticlib=no])
424 AC_MSG_RESULT($with_ticlib)
425
426 dnl Not all ports of gcc support the -g option
427
428 if test X"$CC_G_OPT" = X"" ; then
429         CC_G_OPT='-g'
430         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
431 fi
432 AC_SUBST(CC_G_OPT)
433
434 if test X"$CXX_G_OPT" = X"" ; then
435         CXX_G_OPT='-g'
436         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
437 fi
438 AC_SUBST(CXX_G_OPT)
439
440 AC_MSG_CHECKING(for default loader flags)
441 case $DFT_LWR_MODEL in
442 (libtool) LD_MODEL=''   ;;
443 (normal)  LD_MODEL=''   ;;
444 (debug)   LD_MODEL=$CC_G_OPT ;;
445 (profile) LD_MODEL='-pg';;
446 (shared)  LD_MODEL=''   ;;
447 esac
448 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
449 AC_MSG_RESULT($LD_MODEL)
450
451 case $DFT_LWR_MODEL in
452 (shared)
453 CF_ENABLE_RPATH
454 AC_MSG_CHECKING(if shared libraries should be relinked during install)
455 AC_ARG_ENABLE(relink,
456 [  --disable-relink        relink shared libraries during install],
457 [cf_cv_do_relink=$enableval],
458 [cf_cv_do_relink=yes])
459 AC_MSG_RESULT($cf_cv_do_relink)
460         ;;
461 esac
462
463 # we will build libraries one-level down.
464 rel_builddir=..
465 CF_SHARED_OPTS
466 for model in $cf_list_models; do
467         case $model in
468         (libtool)
469                 CF_WITH_LIBTOOL_OPTS
470                 CF_WITH_EXPORT_SYMS
471                 ;;
472         (shared)
473                 if test "$CC_SHARED_OPTS" = "unknown"; then
474                         AC_ERROR(Shared libraries are not supported in this version)
475                 fi
476                 # workaround for inept transition to PIE vs PIC...
477                 AC_MSG_CHECKING(if current CFLAGS link properly)
478                 AC_TRY_LINK(
479                         [#include <stdio.h>],
480                         [printf("Hello work\n");],
481                         [cf_cflags_work=yes],
482                         [cf_cflags_work=no])
483                 AC_MSG_RESULT($cf_cflags_work)
484                 if test "$cf_cflags_work" = no
485                 then
486                         CF_VERBOSE(try to work around by appending shared-options)
487                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
488                 fi
489                 CF_WITH_VERSIONED_SYMS
490                 ;;
491         esac
492 done
493
494 ### Checks for special libraries, must be done up-front.
495 SHLIB_LIST=""
496 CF_WITH_GPM
497 if test "$with_gpm" != no ; then
498         AC_MSG_CHECKING(if you want to load GPM dynamically)
499         AC_ARG_WITH(dlsym,
500                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
501                 [with_dlsym=$withval],
502                 [with_dlsym=yes])
503         AC_MSG_RESULT($with_dlsym)
504         if test "x$with_dlsym" = xyes ; then
505                 CF_FUNC_DLSYM
506                 if test "x$with_gpm" != xyes ; then
507                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
508                         cf_cv_gpm_soname="$with_gpm"
509                 else
510                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
511                 fi
512                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
513                 SHLIB_LIST="-ldl $SHLIB_LIST"
514                 CF_ADD_LIB(dl,PRIVATE_LIBS)
515         else
516                 SHLIB_LIST="-lgpm $SHLIB_LIST"
517                 CF_ADD_LIB(gpm,TEST_LIBS)
518                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
519         fi
520         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
521         CF_CHECK_GPM_WGETCH
522 fi
523
524 CF_WITH_PCRE2
525 CF_WITH_SYSMOUSE
526
527 # pretend that ncurses==ncursesw==ncursest
528 AC_MSG_CHECKING(if you want to disable library suffixes)
529 CF_ARG_DISABLE(lib-suffixes,
530         [  --disable-lib-suffixes  disable library suffixes],
531         [disable_lib_suffixes=yes],
532         [disable_lib_suffixes=no],
533         no)
534 AC_MSG_RESULT($disable_lib_suffixes)
535
536 ### If we're building with rpath, try to link non-standard libs that way too.
537 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
538         CF_DISABLE_RPATH_HACK
539 fi
540
541 ###############################################################################
542 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
543
544 ###     use option --with-extra-suffix to append suffix to headers and libraries
545 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
546 EXTRA_SUFFIX=
547 AC_ARG_WITH(extra-suffix,
548         [  --with-extra-suffix=X   append extra suffix to header/library paths],
549         [case x$withval in
550         (no)
551                 ;;
552         (xyes|x)
553                 EXTRA_SUFFIX=$cf_cv_abi_version
554                 ;;
555         (*)
556                 EXTRA_SUFFIX=$withval
557                 ;;
558         esac
559         ])
560 AC_MSG_RESULT($EXTRA_SUFFIX)
561 AC_SUBST(EXTRA_SUFFIX)
562
563 ###     use option --disable-overwrite to leave out the link to -lcurses
564 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
565 AC_ARG_ENABLE(overwrite,
566         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
567         [with_overwrite=$enableval],
568         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
569 AC_MSG_RESULT($with_overwrite)
570
571 AC_MSG_CHECKING(if external terminfo-database is used)
572 AC_ARG_ENABLE(database,
573         [  --disable-database      do not use terminfo, only fallbacks/termcap],
574         [use_database=$enableval],
575         [use_database=yes])
576 AC_MSG_RESULT($use_database)
577
578 case $host_os in
579 (os2*)
580         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
581         ;;
582 (*)
583         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
584         ;;
585 esac
586 AC_SUBST(TERMINFO_SRC)
587
588 NCURSES_USE_DATABASE=0
589 if test "$use_database" != no ; then
590         NCURSES_USE_DATABASE=1
591
592         AC_MSG_CHECKING(which terminfo source-file will be installed)
593         AC_ARG_WITH(database,
594                 [  --with-database=XXX     specify terminfo source to install],
595                 [TERMINFO_SRC=$withval])
596         AC_MSG_RESULT($TERMINFO_SRC)
597
598         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
599         AC_ARG_WITH(hashed-db,
600                 [  --with-hashed-db        specify hashed-database library],,
601                 [with_hashed_db=no])
602         AC_MSG_RESULT($with_hashed_db)
603 else
604         with_hashed_db=no
605 fi
606 AC_SUBST(NCURSES_USE_DATABASE)
607
608 AC_MSG_CHECKING(for list of fallback descriptions)
609 AC_ARG_WITH(fallbacks,
610         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
611         [with_fallback=$withval],
612         [with_fallback=])
613 AC_MSG_RESULT($with_fallback)
614
615 case ".$with_fallback" in
616 (.|.no)
617         FALLBACK_LIST=
618         ;;
619 (.yes)
620         AC_MSG_WARN(expected a list of terminal descriptions)
621         ;;
622 (*)
623         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
624         ;;
625 esac
626
627 USE_FALLBACKS=
628 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
629 AC_SUBST(FALLBACK_LIST)
630 AC_SUBST(USE_FALLBACKS)
631
632 AC_MSG_CHECKING(if you want modern xterm or antique)
633 AC_ARG_WITH(xterm-new,
634         [  --without-xterm-new     specify if xterm terminfo should be old version],
635         [with_xterm_new=$withval],
636         [with_xterm_new=yes])
637 case $with_xterm_new in
638 (no) with_xterm_new=xterm-old;;
639 (*)      with_xterm_new=xterm-new;;
640 esac
641 AC_MSG_RESULT($with_xterm_new)
642 WHICH_XTERM=$with_xterm_new
643 AC_SUBST(WHICH_XTERM)
644
645 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
646 AC_ARG_WITH(xterm-kbs,
647         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
648         [with_xterm_kbs=$withval],
649         [with_xterm_kbs=BS])
650 case x$with_xterm_kbs in
651 (xyes|xno|xBS|xbs|x8)
652         with_xterm_kbs=BS
653         ;;
654 (xDEL|xdel|x127)
655         with_xterm_kbs=DEL
656         ;;
657 (*)
658         with_xterm_kbs=$withval
659         ;;
660 esac
661 AC_MSG_RESULT($with_xterm_kbs)
662 XTERM_KBS=$with_xterm_kbs
663 AC_SUBST(XTERM_KBS)
664
665 MAKE_TERMINFO=
666 if test "$use_database" = no ; then
667         TERMINFO="${datadir}/terminfo"
668         MAKE_TERMINFO="#"
669 else
670
671 AC_MSG_CHECKING(for list of terminfo directories)
672 CF_WITH_PATHLIST(terminfo-dirs,
673         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
674         TERMINFO_DIRS,
675         DATADIR/terminfo,
676         ${datadir}/terminfo)
677 AC_MSG_RESULT($TERMINFO_DIRS)
678 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
679
680 case "x$TERMINFO" in
681 x???:*)
682         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
683         unset TERMINFO
684         ;;
685 esac
686
687 AC_MSG_CHECKING(for default terminfo directory)
688 CF_WITH_PATH(default-terminfo-dir,
689         [  --with-default-terminfo-dir=DIR default terminfo directory],
690         TERMINFO,
691         DATADIR/terminfo,
692         ${datadir}/terminfo)
693 AC_MSG_RESULT($TERMINFO)
694 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
695
696 fi
697
698 AC_SUBST(TERMINFO)
699 AC_SUBST(MAKE_TERMINFO)
700
701 ###     use option --disable-big-core to make tic run on small machines
702 ###     We need 4Mb, check if we can allocate 50% more than that.
703 AC_MSG_CHECKING(if big-core option selected)
704 AC_ARG_ENABLE(big-core,
705         [  --disable-big-core      assume machine has little memory],
706         [with_big_core=$enableval],
707         [AC_TRY_RUN([
708 #include <stdlib.h>
709 #include <string.h>
710 int main() {
711         unsigned long n = 6000000L;
712         char *s = malloc(n);
713         if (s != 0)
714                 s[0] = s[n-1] = 0;
715         ${cf_cv_main_return:-return}(s == 0);
716 }],
717         [with_big_core=yes],
718         [with_big_core=no],
719         [with_big_core=no])])
720 AC_MSG_RESULT($with_big_core)
721 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
722
723 ### ISO C only guarantees 512-char strings, we have tables which load faster
724 ### when constructed using "big" strings.  More than the C compiler, the awk
725 ### program is a limit on most vendor UNIX systems.  Check that we can build.
726 AC_MSG_CHECKING(if big-strings option selected)
727 AC_ARG_ENABLE(big-strings,
728         [  --disable-big-strings   assume compiler has only standard-size strings],
729         [with_big_strings=$enableval],
730         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
731 AC_MSG_RESULT($with_big_strings)
732
733 USE_BIG_STRINGS=0
734 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
735 AC_SUBST(USE_BIG_STRINGS)
736
737 ###     use option --enable-termcap to compile in the termcap fallback support
738 AC_MSG_CHECKING(if you want termcap-fallback support)
739 AC_ARG_ENABLE(termcap,
740         [  --enable-termcap        compile in termcap fallback support],
741         [with_termcap=$enableval],
742         [with_termcap=no])
743 AC_MSG_RESULT($with_termcap)
744
745 NCURSES_USE_TERMCAP=0
746 if test "x$with_termcap" != "xyes" ; then
747         if test "$use_database" = no ; then
748                 if test -z "$with_fallback" ; then
749                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
750                 fi
751         fi
752         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
753 else
754
755         if test "$with_ticlib" != no ; then
756                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
757         fi
758
759         NCURSES_USE_TERMCAP=1
760         AC_MSG_CHECKING(for list of termcap files)
761         CF_WITH_PATHLIST(termpath,
762                 [  --with-termpath=XXX     specify list of termcap files],
763                 TERMPATH,
764                 /etc/termcap:/usr/share/misc/termcap)
765         AC_MSG_RESULT($TERMPATH)
766         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
767
768         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
769         AC_MSG_CHECKING(if fast termcap-loader is needed)
770         AC_ARG_ENABLE(getcap,
771                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
772                 [with_getcap=$enableval],
773                 [with_getcap=no])
774         AC_MSG_RESULT($with_getcap)
775         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
776
777         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
778         AC_ARG_ENABLE(getcap-cache,
779                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
780                 [with_getcap_cache=$enableval],
781                 [with_getcap_cache=no])
782         AC_MSG_RESULT($with_getcap_cache)
783         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
784
785 fi
786 AC_SUBST(NCURSES_USE_TERMCAP)
787
788 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
789 AC_MSG_CHECKING(if ~/.terminfo is wanted)
790 AC_ARG_ENABLE(home-terminfo,
791         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
792         [with_home_terminfo=$enableval],
793         [with_home_terminfo=yes])
794 AC_MSG_RESULT($with_home_terminfo)
795 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
796
797 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
798 AC_ARG_ENABLE(root-environ,
799         [  --disable-root-environ  restrict environment when running as root],
800         [with_root_environ=$enableval],
801         [with_root_environ=yes])
802 AC_MSG_RESULT($with_root_environ)
803 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
804
805 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
806 ###   to reduce storage requirements for the terminfo database.
807 CF_LINK_FUNCS
808
809 with_links=no
810 with_symlinks=no
811
812 # soft links (symbolic links) are useful for some systems where hard links do
813 # not work, or to make it simpler to copy terminfo trees around.
814 if test "x$ac_cv_func_symlink" = xyes ; then
815         AC_MSG_CHECKING(if tic should use symbolic links)
816         AC_ARG_ENABLE(symlinks,
817         [  --enable-symlinks       make tic use symbolic links not hard links],
818         [with_symlinks=$enableval],
819         [with_symlinks=no])
820         AC_MSG_RESULT($with_symlinks)
821 fi
822
823 # If we have hard links and did not choose to use soft links instead, there is
824 # no reason to make this choice optional - use the hard links.
825 if test "$with_symlinks" = no ; then
826         AC_MSG_CHECKING(if tic should use hard links)
827         if test "x$ac_cv_func_link" = xyes ; then
828                 with_links=yes
829         else
830                 with_links=no
831         fi
832         AC_MSG_RESULT($with_links)
833 fi
834
835 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
836 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
837
838 ###   use option --enable-broken-linker to force on use of broken-linker support
839 AC_MSG_CHECKING(if you want broken-linker support code)
840 AC_ARG_ENABLE(broken_linker,
841         [  --enable-broken_linker  compile with broken-linker support code],
842         [with_broken_linker=$enableval],
843         [with_broken_linker=${BROKEN_LINKER:-no}])
844 AC_MSG_RESULT($with_broken_linker)
845
846 BROKEN_LINKER=0
847 if test "x$with_broken_linker" = xyes ; then
848         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
849         BROKEN_LINKER=1
850 elif test "$DFT_LWR_MODEL" = shared ; then
851         case $cf_cv_system_name in
852         (cygwin*)
853                 AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
854                 BROKEN_LINKER=1
855                 CF_VERBOSE(cygwin linker is broken anyway)
856                 ;;
857         esac
858 fi
859 AC_SUBST(BROKEN_LINKER)
860
861 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
862 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
863 AC_ARG_ENABLE(bsdpad,
864         [  --enable-bsdpad         recognize BSD-style prefix padding],
865         [with_bsdpad=$enableval],
866         [with_bsdpad=no])
867 AC_MSG_RESULT($with_bsdpad)
868 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
869
870 ###   use option --enable-widec to turn on use of wide-character support
871 NCURSES_CH_T=chtype
872 NCURSES_LIBUTF8=0
873
874 NEED_WCHAR_H=0
875 NCURSES_MBSTATE_T=0
876 NCURSES_WCHAR_T=0
877 NCURSES_WINT_T=0
878
879 # Check to define _XOPEN_SOURCE "automatically"
880 CPPFLAGS_before_XOPEN="$CPPFLAGS"
881 CF_XOPEN_SOURCE(600)
882 CPPFLAGS_after_XOPEN="$CPPFLAGS"
883
884 # Work around breakage on OS X
885 CF_SIGWINCH
886
887 # Checks for CODESET support.
888 AM_LANGINFO_CODESET
889
890 # use these variables to work around a defect in gcc's fixincludes.
891 NCURSES_OK_WCHAR_T=
892 NCURSES_OK_WINT_T=
893
894 AC_MSG_CHECKING(if you want wide-character code)
895 AC_ARG_ENABLE(widec,
896         [  --enable-widec          compile with wide-char/UTF-8 code],
897         [with_widec=$enableval],
898         [with_widec=no])
899 AC_MSG_RESULT($with_widec)
900
901 NCURSES_WCWIDTH_GRAPHICS=1
902 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
903
904 if test "x$with_widec" = xyes ; then
905         if test "x$disable_lib_suffixes" = xno ; then
906                 LIB_SUFFIX="w${LIB_SUFFIX}"
907         fi
908         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
909         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
910
911         CF_CHECK_WCHAR_H
912         CF_CHECK_WCWIDTH_GRAPHICS
913         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
914
915         # with_overwrite=no
916         NCURSES_CH_T=cchar_t
917         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
918         if test "x$ac_cv_func_putwc" != xyes ; then
919                 CF_UTF8_LIB
920                 if test "$cf_cv_utf8_lib" != no ; then
921                         NCURSES_LIBUTF8=1
922                 fi
923         fi
924         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
925         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
926         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
927
928         if test "$NCURSES_MBSTATE_T" != 0; then
929                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
930         fi
931 fi
932 AC_SUBST(NCURSES_CH_T)
933 AC_SUBST(NCURSES_LIBUTF8)
934
935 AC_SUBST(NEED_WCHAR_H)
936 AC_SUBST(NCURSES_MBSTATE_T)
937 AC_SUBST(NCURSES_WCHAR_T)
938 AC_SUBST(NCURSES_WINT_T)
939
940 AC_SUBST(NCURSES_OK_WCHAR_T)
941 AC_SUBST(NCURSES_OK_WINT_T)
942
943 ###   use option --disable-lp64 to allow long chtype
944 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
945 AC_ARG_ENABLE(lp64,
946         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
947         [with_lp64=$enableval],
948         [with_lp64=$cf_dft_with_lp64])
949 AC_MSG_RESULT($with_lp64)
950
951 if test "x$with_lp64" = xyes ; then
952         cf_cv_enable_lp64=1
953 else
954         cf_cv_enable_lp64=0
955 fi
956 AC_SUBST(cf_cv_enable_lp64)
957
958 CF_LARGEFILE
959
960 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
961 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
962 AC_ARG_ENABLE(tparm-varargs,
963         [  --disable-tparm-varargs compile tparm() without varargs interface],
964         [with_tparm_varargs=$enableval],
965         [with_tparm_varargs=yes])
966 AC_MSG_RESULT($with_tparm_varargs)
967 NCURSES_TPARM_VARARGS=0
968 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
969 AC_SUBST(NCURSES_TPARM_VARARGS)
970
971 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
972 if test "$with_ticlib" != no ; then
973 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
974 AC_ARG_ENABLE(tic-depends,
975         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
976         [with_tic_depends=$enableval],
977         [with_tic_depends=yes])
978 AC_MSG_RESULT($with_tic_depends)
979 else
980         with_tic_depends=no
981 fi
982
983 ###   use option --disable-wattr-macros to suppress wattr* macros from curses.h
984 AC_MSG_CHECKING(if you want to suppress wattr* macros to help with ncurses5/ncurses6 transition)
985 AC_ARG_ENABLE(wattr-macros,
986         [  --disable-wattr-macros  suppress wattr* macros to help with ncurses5/ncurses6 transition],
987         [with_wattr_macros=$enableval],
988         [with_wattr_macros=yes])
989 if [[ "x$with_wattr_macros" != xyes ]]; then
990         NCURSES_WATTR_MACROS=0
991         AC_MSG_RESULT(yes)
992 else
993         NCURSES_WATTR_MACROS=1
994         AC_MSG_RESULT(no)
995 fi
996 AC_SUBST(NCURSES_WATTR_MACROS)
997
998 CF_WITH_X11_RGB
999
1000 ###   use option --with-bool to override bool's type
1001 AC_MSG_CHECKING(for type of bool)
1002 AC_ARG_WITH(bool,
1003         [  --with-bool=TYPE        override fallback type of bool variable],
1004         [NCURSES_BOOL="$withval"],
1005         [NCURSES_BOOL=auto])
1006 AC_MSG_RESULT($NCURSES_BOOL)
1007 AC_SUBST(NCURSES_BOOL)
1008
1009 AC_MSG_CHECKING(for alternate terminal capabilities file)
1010 AC_ARG_WITH(caps,
1011         [  --with-caps=alt         compile with alternate Caps file],
1012         [TERMINFO_CAPS=Caps.$withval],
1013         [TERMINFO_CAPS=Caps])
1014 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
1015 AC_MSG_RESULT($TERMINFO_CAPS)
1016 AC_SUBST(TERMINFO_CAPS)
1017
1018 ###   use option --with-chtype to override chtype's type
1019 AC_MSG_CHECKING(for type of chtype)
1020 AC_ARG_WITH(chtype,
1021         [  --with-chtype=TYPE      override type of chtype],
1022         [NCURSES_CHTYPE="$withval"],
1023         [NCURSES_CHTYPE=$cf_dft_chtype])
1024 AC_MSG_RESULT($NCURSES_CHTYPE)
1025
1026 ###   use option --with-ospeed to override ospeed's type
1027 AC_MSG_CHECKING(for type of ospeed)
1028 AC_ARG_WITH(ospeed,
1029         [  --with-ospeed=TYPE      override type of ospeed variable],
1030         [NCURSES_OSPEED="$withval"],
1031         [NCURSES_OSPEED=short])
1032 AC_MSG_RESULT($NCURSES_OSPEED)
1033 AC_SUBST(NCURSES_OSPEED)
1034
1035 ###   use option --with-mmask-t to override mmask_t's type
1036 AC_MSG_CHECKING(for type of mmask_t)
1037 AC_ARG_WITH(mmask-t,
1038         [  --with-mmask-t=TYPE     override type of mmask_t],
1039         [NCURSES_MMASK_T="$withval"],
1040         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1041 AC_MSG_RESULT($NCURSES_MMASK_T)
1042
1043 ###   use option --with-ccharw-max to override CCHARW_MAX size
1044 AC_MSG_CHECKING(for size CCHARW_MAX)
1045 AC_ARG_WITH(ccharw-max,
1046         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1047         [NCURSES_CCHARW_MAX="$withval"],
1048         [NCURSES_CCHARW_MAX=5])
1049 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1050 AC_SUBST(NCURSES_CCHARW_MAX)
1051
1052 AC_CHECK_SIZEOF([signed char], 0)
1053 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1054         NCURSES_SBOOL="signed char"
1055 else
1056         NCURSES_SBOOL="char"
1057 fi
1058 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1059 AC_ARG_ENABLE(signed-char,
1060         [  --enable-signed-char    compile using signed Boolean's in term.h],
1061         [with_signed_char=$enableval],
1062         [with_signed_char=no])
1063 AC_MSG_RESULT($with_signed_char)
1064 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1065 AC_SUBST(NCURSES_SBOOL)
1066
1067 ###   use option --with-tparm-arg to override tparm's argument type
1068 AC_MSG_CHECKING(for type of tparm args)
1069 AC_ARG_WITH(tparm-arg,
1070         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1071         [NCURSES_TPARM_ARG="$withval"],
1072         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1073 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1074 AC_SUBST(NCURSES_TPARM_ARG)
1075
1076 ### Enable compiling-in rcs id's
1077 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1078 AC_ARG_WITH(rcs-ids,
1079         [  --with-rcs-ids          compile-in RCS identifiers],
1080         [with_rcs_ids=$withval],
1081         [with_rcs_ids=no])
1082 AC_MSG_RESULT($with_rcs_ids)
1083 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1084
1085 ###############################################################################
1086 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1087
1088 ###############################################################################
1089 CF_HELP_MESSAGE(Extensions:)
1090
1091 ### Note that some functions (such as const) are normally disabled anyway.
1092 AC_MSG_CHECKING(if you want to build with function extensions)
1093 AC_ARG_ENABLE(ext-funcs,
1094         [  --disable-ext-funcs     disable function-extensions],
1095         [with_ext_funcs=$enableval],
1096         [with_ext_funcs=yes])
1097 AC_MSG_RESULT($with_ext_funcs)
1098 if test "x$with_ext_funcs" = xyes ; then
1099         NCURSES_EXT_FUNCS=1
1100         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1101         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1102         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1103         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1104         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1105         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1106         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1107         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1108         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1109         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1110         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1111         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1112         GENERATED_EXT_FUNCS=generated
1113         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1114 else
1115         NCURSES_EXT_FUNCS=0
1116         GENERATED_EXT_FUNCS=
1117 fi
1118 AC_SUBST(NCURSES_EXT_FUNCS)
1119 AC_SUBST(GENERATED_EXT_FUNCS)
1120
1121 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1122 AC_ARG_ENABLE(sp-funcs,
1123         [  --enable-sp-funcs       enable SCREEN-extensions],
1124         [with_sp_funcs=$enableval],
1125         [with_sp_funcs=$cf_dft_ext_spfuncs])
1126 AC_MSG_RESULT($with_sp_funcs)
1127 if test "x$with_sp_funcs" = xyes ; then
1128         NCURSES_SP_FUNCS=1
1129         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1130         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1131         GENERATED_SP_FUNCS=generated
1132 else
1133         NCURSES_SP_FUNCS=0
1134         GENERATED_SP_FUNCS=
1135 fi
1136 AC_SUBST(NCURSES_SP_FUNCS)
1137 AC_SUBST(GENERATED_SP_FUNCS)
1138
1139 AC_MSG_CHECKING(if you want to build with terminal-driver)
1140 AC_ARG_ENABLE(term-driver,
1141         [  --enable-term-driver    enable terminal-driver],
1142         [with_term_driver=$enableval],
1143         [with_term_driver=no])
1144 AC_MSG_RESULT($with_term_driver)
1145 if test "x$with_term_driver" = xyes ; then
1146         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1147         if test "x$with_termlib" != xno ; then
1148                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1149         fi
1150         if test "x$with_sp_funcs" != xyes ; then
1151                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1152         fi
1153 fi
1154
1155 ###   use option --enable-const to turn on use of const beyond that in XSI.
1156 AC_MSG_CHECKING(for extended use of const keyword)
1157 AC_ARG_ENABLE(const,
1158         [  --enable-const          compile with extra/non-standard const],
1159         [with_ext_const=$enableval],
1160         [with_ext_const=$cf_dft_ext_const])
1161 AC_MSG_RESULT($with_ext_const)
1162 NCURSES_CONST='/*nothing*/'
1163 if test "x$with_ext_const" = xyes ; then
1164         NCURSES_CONST=const
1165 fi
1166 AC_SUBST(NCURSES_CONST)
1167
1168 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1169 AC_MSG_CHECKING(if you want to use extended colors)
1170 AC_ARG_ENABLE(ext-colors,
1171         [  --enable-ext-colors     compile for 256-color support],
1172         [with_ext_colors=$enableval],
1173         [with_ext_colors=$cf_dft_ext_colors])
1174 AC_MSG_RESULT($with_ext_colors)
1175 NCURSES_EXT_COLORS=0
1176 if test "x$with_ext_colors" = xyes ; then
1177         if test "x$with_widec" != xyes ; then
1178                 AC_MSG_WARN(This option applies only to wide-character library)
1179         else
1180                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1181                 CF_NCURSES_ABI_6
1182                 NCURSES_EXT_COLORS=1
1183                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1184                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1185                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1186                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1187         fi
1188 fi
1189 AC_SUBST(NCURSES_EXT_COLORS)
1190
1191 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1192 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1193 AC_ARG_ENABLE(ext-mouse,
1194         [  --enable-ext-mouse      compile for extended mouse-encoding],
1195         [with_ext_mouse=$enableval],
1196         [with_ext_mouse=$cf_dft_ext_mouse])
1197 AC_MSG_RESULT($with_ext_mouse)
1198 NCURSES_MOUSE_VERSION=1
1199 if test "x$with_ext_mouse" = xyes ; then
1200         NCURSES_MOUSE_VERSION=2
1201         CF_NCURSES_ABI_6
1202 fi
1203 AC_SUBST(NCURSES_MOUSE_VERSION)
1204
1205 ###   use option --enable-ext-putwin to turn on extended screendumps
1206 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1207 AC_ARG_ENABLE(ext-putwin,
1208         [  --enable-ext-putwin     compile with extended putwin/screendump],
1209         [with_ext_putwin=$enableval],
1210         [with_ext_putwin=$cf_dft_ext_putwin])
1211 AC_MSG_RESULT($with_ext_putwin)
1212 if test "x$with_ext_putwin" = xyes ; then
1213         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1214 fi
1215
1216 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1217 AC_ARG_ENABLE(no-padding,
1218         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1219         [with_no_padding=$enableval],
1220         [with_no_padding=$with_ext_funcs])
1221 AC_MSG_RESULT($with_no_padding)
1222 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1223
1224 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1225 AC_MSG_CHECKING(if you want SIGWINCH handler)
1226 AC_ARG_ENABLE(sigwinch,
1227         [  --enable-sigwinch       compile with SIGWINCH handler],
1228         [with_sigwinch=$enableval],
1229         [with_sigwinch=$with_ext_funcs])
1230 AC_MSG_RESULT($with_sigwinch)
1231 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1232
1233 ###   use option --enable-tcap-names to allow user to define new capabilities
1234 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1235 AC_ARG_ENABLE(tcap-names,
1236         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1237         [with_tcap_names=$enableval],
1238         [with_tcap_names=$with_ext_funcs])
1239 AC_MSG_RESULT($with_tcap_names)
1240 NCURSES_XNAMES=0
1241 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1242 AC_SUBST(NCURSES_XNAMES)
1243
1244 ##############################################################################
1245 CF_HELP_MESSAGE(Reentrant Code:)
1246 CF_WITH_PTHREAD
1247
1248 if test "x$with_pthread" != xno; then
1249         AC_CHECK_FUNC(pthread_kill,[
1250                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1251                 AC_ARG_ENABLE(pthreads-eintr,
1252                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1253                         [use_pthreads_eintr=$enableval],
1254                         [use_pthreads_eintr=no])
1255                 AC_MSG_RESULT($use_pthreads_eintr)
1256                 if test "x$use_pthreads_eintr" = xyes ; then
1257                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1258                 fi])
1259
1260         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1261         AC_ARG_ENABLE(weak-symbols,
1262                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1263                 [use_weak_symbols=$enableval],
1264                 [use_weak_symbols=no])
1265         AC_MSG_RESULT($use_weak_symbols)
1266         if test "x$use_weak_symbols" = xyes ; then
1267                 CF_WEAK_SYMBOLS
1268         else
1269                 cf_cv_weak_symbols=no
1270         fi
1271
1272         if test "x$cf_cv_weak_symbols" = xyes ; then
1273                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1274         fi
1275 fi
1276
1277 PTHREAD=
1278 if test "x$with_pthread" = "xyes" ; then
1279         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1280         enable_reentrant=yes
1281         if test "x$cf_cv_weak_symbols" = xyes ; then
1282                 PTHREAD=-lpthread
1283                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1284         fi
1285 fi
1286 AC_SUBST(PTHREAD)
1287
1288 # Reentrant code has to be opaque; there's little advantage to making ncurses
1289 # opaque outside of that, so there is no --enable-opaque option.  We can use
1290 # this option without --with-pthreads, but this will be always set for
1291 # pthreads.
1292 AC_MSG_CHECKING(if you want reentrant code)
1293 AC_ARG_ENABLE(reentrant,
1294         [  --enable-reentrant      compile with reentrant code],
1295         [with_reentrant=$enableval],
1296         [with_reentrant=no])
1297 AC_MSG_RESULT($with_reentrant)
1298 if test "x$with_reentrant" = xyes ; then
1299         cf_cv_enable_reentrant=1
1300         cf_cv_enable_opaque="NCURSES_INTERNALS"
1301         NCURSES_SIZE_T=int
1302         if test "x$cf_cv_weak_symbols" = xyes ; then
1303                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1304                 CF_ADD_LIB(pthread,TEST_LIBS)
1305                 CF_ADD_LIB(pthread,TEST_LIBS2)
1306                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1307         else
1308                 # when not using weak symbols but with_reentrant,
1309                 # add 't' to the library suffix on all platforms
1310                 # except cygwin, where we only do that if ALSO
1311                 # compiling with full thread support.
1312                 case "$host" in
1313                 (*cygwin* | *msys*)
1314                         if test "$with_pthread" = "yes" ; then
1315                                 if test "x$disable_lib_suffixes" = "xno" ; then
1316                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1317                                 fi
1318                         fi ;;
1319                 (*)
1320                         if test "x$disable_lib_suffixes" = "xno" ; then
1321                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1322                         fi
1323                         ;;
1324                 esac
1325         fi
1326         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1327         CF_NCURSES_ABI_6
1328 else
1329         cf_cv_enable_reentrant=0
1330         cf_cv_enable_opaque="NCURSES_OPAQUE"
1331         NCURSES_SIZE_T=short
1332 fi
1333 AC_SUBST(cf_cv_enable_reentrant)
1334 AC_SUBST(cf_cv_enable_opaque)
1335
1336 AC_SUBST(NCURSES_SIZE_T)
1337
1338 AC_MSG_CHECKING(if you want opaque curses-library structures)
1339 CF_ARG_ENABLE(opaque-curses,
1340         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1341         [enable_opaque_curses=yes],[
1342          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1343          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=no
1344         ])
1345 AC_MSG_RESULT($enable_opaque_curses)
1346
1347 test "$cf_cv_enable_reentrant" = 1 && \
1348 test "$enable_opaque_curses" = no && \
1349 AC_MSG_ERROR(reentrant configuration requires opaque library)
1350
1351 AC_MSG_CHECKING(if you want opaque form-library structures)
1352 AC_ARG_ENABLE(opaque-form,
1353         [  --enable-opaque-form    make form-library structures "opaque"],
1354         [enable_opaque_form=yes],[enable_opaque_form=no])
1355 AC_MSG_RESULT($enable_opaque_form)
1356
1357 AC_MSG_CHECKING(if you want opaque menu-library structures)
1358 AC_ARG_ENABLE(opaque-menu,
1359         [  --enable-opaque-menu    make menu-library structures "opaque"],
1360         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1361 AC_MSG_RESULT($enable_opaque_menu)
1362
1363 AC_MSG_CHECKING(if you want opaque panel-library structures)
1364 AC_ARG_ENABLE(opaque-panel,
1365         [  --enable-opaque-panel   make panel-library structures "opaque"],
1366         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1367 AC_MSG_RESULT($enable_opaque_panel)
1368
1369 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1370 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1371 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1372 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1373
1374 AC_SUBST(NCURSES_OPAQUE)
1375 AC_SUBST(NCURSES_OPAQUE_FORM)
1376 AC_SUBST(NCURSES_OPAQUE_MENU)
1377 AC_SUBST(NCURSES_OPAQUE_PANEL)
1378
1379 ### Allow using a different wrap-prefix
1380 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1381         AC_MSG_CHECKING(for prefix used to wrap public variables)
1382         AC_ARG_WITH(wrap-prefix,
1383                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1384                 [NCURSES_WRAP_PREFIX=$withval],
1385                 [NCURSES_WRAP_PREFIX=_nc_])
1386         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1387 else
1388         NCURSES_WRAP_PREFIX=_nc_
1389 fi
1390 AC_SUBST(NCURSES_WRAP_PREFIX)
1391 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1392
1393 ###############################################################################
1394 # These options are relatively safe to experiment with.
1395 CF_HELP_MESSAGE(Development Code:)
1396 AC_MSG_CHECKING(if you want all development code)
1397 AC_ARG_WITH(develop,
1398         [  --without-develop       disable development options],
1399         [with_develop=$withval],
1400         [with_develop=no])
1401 AC_MSG_RESULT($with_develop)
1402
1403 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1404 AC_MSG_CHECKING(if you want hard-tabs code)
1405 AC_ARG_ENABLE(hard-tabs,
1406         [  --enable-hard-tabs      compile with hard-tabs code],,
1407         [enable_hard_tabs=$with_develop])
1408 AC_MSG_RESULT($enable_hard_tabs)
1409 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1410
1411 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1412 AC_MSG_CHECKING(if you want limited support for xmc)
1413 AC_ARG_ENABLE(xmc-glitch,
1414         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1415         [enable_xmc_glitch=$with_develop])
1416 AC_MSG_RESULT($enable_xmc_glitch)
1417 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1418
1419 ###############################################################################
1420 # These are just experimental, probably should not be in a package:
1421 CF_HELP_MESSAGE(Experimental Code:)
1422
1423 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1424 AC_ARG_ENABLE(assumed-color,
1425         [  --disable-assumed-color do not assume anything about default-colors],
1426         [with_assumed_color=$enableval],
1427         [with_assumed_color=yes])
1428 AC_MSG_RESULT($with_assumed_color)
1429 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1430
1431 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1432 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1433 AC_ARG_ENABLE(hashmap,
1434         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1435         [with_hashmap=$enableval],
1436         [with_hashmap=yes])
1437 AC_MSG_RESULT($with_hashmap)
1438 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1439
1440 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1441 AC_MSG_CHECKING(if you want colorfgbg code)
1442 AC_ARG_ENABLE(colorfgbg,
1443         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1444         [with_colorfgbg=$enableval],
1445         [with_colorfgbg=no])
1446 AC_MSG_RESULT($with_colorfgbg)
1447 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1448
1449 ###   use option --enable-interop to turn on use of bindings used for interop
1450 AC_MSG_CHECKING(if you want interop bindings)
1451 AC_ARG_ENABLE(interop,
1452         [  --enable-interop        compile-in interop bindings],
1453         [with_exp_interop=$enableval],
1454         [with_exp_interop=$cf_dft_interop])
1455 AC_MSG_RESULT($with_exp_interop)
1456
1457 NCURSES_INTEROP_FUNCS=0
1458 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1459 AC_SUBST(NCURSES_INTEROP_FUNCS)
1460
1461
1462 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1463 AC_ARG_ENABLE(safe-sprintf,
1464         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1465         [with_safe_sprintf=$enableval],
1466         [with_safe_sprintf=no])
1467 AC_MSG_RESULT($with_safe_sprintf)
1468
1469 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1470 # when hashmap is used scroll hints are useless
1471 if test "$with_hashmap" = no ; then
1472 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1473 AC_ARG_ENABLE(scroll-hints,
1474         [  --disable-scroll-hints  compile without scroll-hints code],
1475         [with_scroll_hints=$enableval],
1476         [with_scroll_hints=yes])
1477 AC_MSG_RESULT($with_scroll_hints)
1478 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1479 fi
1480
1481 AC_MSG_CHECKING(if you want wgetch-events code)
1482 AC_ARG_ENABLE(wgetch-events,
1483         [  --enable-wgetch-events  compile with wgetch-events code],
1484         [with_wgetch_events=$enableval],
1485         [with_wgetch_events=no])
1486 AC_MSG_RESULT($with_wgetch_events)
1487 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1488
1489 ###############################################################################
1490 CF_HELP_MESSAGE(Testing/development Options:)
1491
1492 ###     use option --disable-echo to suppress full display compiling commands
1493 CF_DISABLE_ECHO
1494 if test "x$enable_echo" = xyes; then
1495         ECHO_LINK=
1496 else
1497         ECHO_LINK='@ echo linking $@ ... ;'
1498         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1499         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1500 fi
1501 AC_SUBST(ECHO_LINK)
1502
1503 # --disable-stripping is used for debugging
1504 CF_INSTALL_OPTS
1505
1506 # If we're avoiding relinking of shared libraries during install, that is to
1507 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1508 # the install program has "-p" (for preserving timestamps).
1509 cf_cv_do_reranlib=yes
1510 if test "x$cf_cv_install_p" = xyes
1511 then
1512         if test "x$cf_cv_do_relink" != xyes
1513         then
1514                 cf_cv_do_reranlib=no
1515                 INSTALL_OPT_P="-p"
1516                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1517         fi
1518 fi
1519 AC_SUBST(INSTALL_OPT_P)
1520
1521 ###     use option --enable-warnings to turn on all gcc warnings
1522 AC_MSG_CHECKING(if you want to see compiler warnings)
1523 AC_ARG_ENABLE(warnings,
1524         [  --enable-warnings       build: turn on GCC compiler warnings],
1525         [with_warnings=$enableval])
1526 AC_MSG_RESULT($with_warnings)
1527
1528 if test "x$with_warnings" = "xyes"; then
1529         CF_ADD_ADAFLAGS(-gnatg)
1530         CF_GCC_WARNINGS(Wno-unknown-pragmas Wswitch-enum)
1531         if test "x$cf_with_cxx" = xyes ; then
1532                 CF_GXX_WARNINGS(Wno-unused)
1533         fi
1534 fi
1535 CF_GCC_ATTRIBUTES
1536 CF_ENABLE_STRING_HACKS
1537
1538 ###     use option --enable-assertions to turn on generation of assertion code
1539 AC_MSG_CHECKING(if you want to enable runtime assertions)
1540 AC_ARG_ENABLE(assertions,
1541         [  --enable-assertions     test: turn on generation of assertion code],
1542         [with_assertions=$enableval],
1543         [with_assertions=no])
1544 AC_MSG_RESULT($with_assertions)
1545 if test -n "$GCC"
1546 then
1547         if test "$with_assertions" = no
1548         then
1549                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1550         else
1551                 CF_ADD_ADAFLAGS(-gnata)
1552         fi
1553 fi
1554
1555 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1556 CF_DISABLE_LEAKS
1557 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1558
1559 ###     use option --enable-expanded to generate certain macros as functions
1560 AC_ARG_ENABLE(expanded,
1561         [  --enable-expanded       test: generate functions for certain macros],
1562         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1563
1564 ###     use option --disable-macros to suppress macros in favor of functions
1565 AC_ARG_ENABLE(macros,
1566         [  --disable-macros        test: use functions rather than macros],
1567         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1568
1569 # Normally we only add trace() to the debug-library.  Allow this to be
1570 # extended to all models of the ncurses library:
1571 cf_all_traces=no
1572 case "$CFLAGS $CPPFLAGS" in
1573 (*-DTRACE*)
1574         cf_all_traces=yes
1575         ;;
1576 esac
1577
1578 AC_MSG_CHECKING(whether to add trace feature to all models)
1579 AC_ARG_WITH(trace,
1580 [  --with-trace            test: add trace() function to all models of ncurses],
1581 [cf_with_trace=$withval],
1582 [cf_with_trace=$cf_all_traces])
1583 AC_MSG_RESULT($cf_with_trace)
1584
1585 if test "x$cf_with_trace" = xyes ; then
1586         LIB_TRACING=all
1587         ADA_TRACE=TRUE
1588         CF_ADD_CFLAGS(-DTRACE)
1589         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1590 else
1591         LIB_TRACING=DEBUG
1592         ADA_TRACE=FALSE
1593 fi
1594
1595 AC_SUBST(ADA_TRACE)
1596
1597 CF_DISABLE_GNAT_PROJECTS
1598
1599 ###     Checks for libraries.
1600 case $cf_cv_system_name in
1601 (*mingw32*|*mingw64*)
1602         CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1603         LIBS=" -lpsapi $LIBS"
1604         ;;
1605 (*)
1606 AC_CHECK_FUNC(gettimeofday,
1607         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1608
1609 AC_CHECK_LIB(bsd, gettimeofday,
1610         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1611         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1612         ;;
1613 esac
1614
1615 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1616 AC_SUBST(MATH_LIB)
1617
1618 ###     Checks for header files.
1619 AC_STDC_HEADERS
1620 AC_HEADER_DIRENT
1621 AC_HEADER_TIME
1622 CF_REGEX
1623
1624 dnl These are some other potentially nonportable headers.
1625 AC_CHECK_HEADERS( \
1626 fcntl.h \
1627 getopt.h \
1628 limits.h \
1629 locale.h \
1630 math.h \
1631 poll.h \
1632 sys/bsdtypes.h \
1633 sys/ioctl.h \
1634 sys/param.h \
1635 sys/poll.h \
1636 sys/select.h \
1637 sys/time.h \
1638 sys/times.h \
1639 ttyent.h \
1640 unistd.h \
1641 wctype.h \
1642 )
1643
1644 CF_GETOPT_HEADER
1645
1646 CF_CHECK_ENVIRON(environ)
1647 CF_CHECK_GETENV
1648 if test "x$cf_cv_consistent_getenv" = xno && \
1649         test "x$cf_with_trace" = xyes
1650 then
1651         AC_MSG_WARN(The NCURSES_TRACE environment variable is not supported with this configuration)
1652 fi
1653
1654 # check for ISC (this may also define _POSIX_SOURCE)
1655 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1656 if test "x$ISC" = xyes ; then
1657         AC_CHECK_LIB(cposix,main)
1658         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1659 fi
1660
1661 CF_SYS_TIME_SELECT
1662
1663 ###     checks for compiler characteristics
1664 AC_LANG_C
1665 AC_C_CONST
1666 CF_C_INLINE(NCURSES_INLINE,1200)
1667 CF_SIG_ATOMIC_T
1668
1669 if test $NCURSES_CHTYPE = auto ; then
1670         CF_TYPEOF_CHTYPE
1671 else
1672         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1673 fi
1674 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1675 AC_SUBST(cf_cv_typeof_chtype)
1676
1677 CF_UNSIGNED_LITERALS
1678 cf_cv_1UL="1"
1679 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1680 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1681 AC_SUBST(cf_cv_1UL)
1682
1683 if test $NCURSES_MMASK_T = auto ; then
1684         cf_cv_typeof_mmask_t=long
1685 else
1686         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1687 fi
1688 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1689 AC_SUBST(cf_cv_typeof_mmask_t)
1690
1691 ###     Checks for external-data
1692 CF_ERRNO
1693 CF_LINK_DATAONLY
1694
1695 ###     Checks for library functions.
1696 AC_CHECK_FUNCS( \
1697 getcwd \
1698 getegid \
1699 geteuid \
1700 getopt \
1701 getttynam \
1702 issetugid \
1703 localeconv \
1704 poll \
1705 putenv \
1706 remove \
1707 select \
1708 setbuf \
1709 setbuffer \
1710 setenv \
1711 setvbuf \
1712 sigaction \
1713 sigvec \
1714 strdup \
1715 strstr \
1716 sysconf \
1717 tcgetpgrp \
1718 times \
1719 tsearch \
1720 vsnprintf \
1721 )
1722
1723 if test "x$ac_cv_func_getopt" = xno && \
1724    test "x$cf_with_progs$cf_with_tests" != xnono; then
1725         AC_MSG_ERROR(getopt is required for building programs)
1726 fi
1727
1728 if test "x$with_safe_sprintf" = xyes
1729 then
1730         if test "x$ac_cv_func_vsnprintf" = xyes
1731         then
1732                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1733         else
1734                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1735         fi
1736 fi
1737
1738 if test "x$with_getcap" = "xyes" ; then
1739         CF_CGETENT
1740 fi
1741
1742 CF_ISASCII
1743 CF_STRUCT_SIGACTION
1744 CF_FUNC_NANOSLEEP
1745 CF_FUNC_TERMIOS
1746 CF_FUNC_VSSCANF
1747 CF_MKSTEMP
1748
1749 # setup for prototype of fallback for vsscanf()
1750 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1751
1752 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1753 if test "x$cross_compiling" = xyes ; then
1754         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1755 else
1756         AC_FUNC_SETVBUF_REVERSED
1757 fi
1758 AC_CHECK_TYPE(intptr_t, long)
1759 AC_CHECK_TYPE(ssize_t, int)
1760 CF_TYPE_SIGACTION
1761 CF_SIZECHANGE
1762 CF_FUNC_MEMMOVE
1763 CF_FUNC_POLL
1764 CF_VA_COPY
1765 AC_FUNC_VFORK
1766 CF_FOPEN_BIN_R
1767
1768 # special check for test/ditto.c
1769 CF_FUNC_OPENPTY
1770 if test "$cf_cv_func_openpty" != no ; then
1771         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1772         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1773         if test "x$cf_cv_lib_util" = xyes ; then
1774                 CF_ADD_LIB(util,TEST_LIBS)
1775         fi
1776 fi
1777 AC_SUBST(TEST_LIBS)
1778 AC_SUBST(TEST_LIBS2)
1779
1780 if test "$with_hashed_db" != no ; then
1781         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1782         CF_HASHED_DB($with_hashed_db)
1783 fi
1784
1785 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1786 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1787         CF_STRIP_G_OPT(CFLAGS)
1788         CF_STRIP_G_OPT(CXXFLAGS)
1789 fi
1790
1791 # Just in case, check if the C compiler has a bool type.
1792 CF_BOOL_DECL(cf_cv_cc_bool_type)
1793
1794 # Check for C++ compiler characteristics (and ensure that it's there!)
1795 if test -n "$CXX" ; then
1796         AC_LANG_CPLUSPLUS
1797         CF_STDCPP_LIBRARY
1798         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1799
1800         case $GXX_VERSION in
1801         (1*|2.[0-6]*)
1802                 cf_cxx_library=yes
1803                 ;;
1804         (*-2.7*|2.7*)
1805                 CF_GPP_LIBRARY
1806                 ;;
1807         (*)
1808                 cf_cxx_library=no
1809                 ;;
1810         esac
1811
1812         AC_CHECK_HEADERS(typeinfo)
1813         CF_CXX_IOSTREAM_NAMESPACE
1814         CF_BOOL_DECL
1815         CF_BOOL_SIZE
1816         CF_ETIP_DEFINES
1817         CF_CPP_PARAM_INIT
1818         CF_CPP_STATIC_CAST
1819         CF_CXX_AR_FLAGS
1820 else
1821         cf_cxx_library=no
1822         cf_cv_builtin_bool=1
1823
1824         # Just because we are not configuring against C++ right now does not
1825         # mean that a user will not want to use C++.  Some distributors disable
1826         # the C++ portion of this configuration as a shortcut (or just to avoid
1827         # compiling the demo in the c++ directory).  So we need a reasonable
1828         # default for the 'bool' type.
1829         #
1830         # Caveat: since the storage of the bool type is not standardized, it
1831         # may change.
1832
1833         if test "$NCURSES_BOOL" != auto ; then
1834                 cf_cv_type_of_bool=$NCURSES_BOOL
1835                 cf_cv_header_stdbool_h=0
1836         else
1837                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1838                         CF_BOOL_SIZE
1839                 else
1840                         AC_MSG_CHECKING(for fallback type of bool)
1841                         case "$host_cpu" in
1842                         (i?86)  cf_cv_type_of_bool=char ;;
1843                         (*)     cf_cv_type_of_bool=int  ;;
1844                         esac
1845                         AC_MSG_RESULT($cf_cv_type_of_bool)
1846                 fi
1847         fi
1848 fi
1849 AC_SUBST(CXXLIBS)
1850
1851 # If the C compiler did not declare bool, and we did not determine that the C++
1852 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1853 # ncurses library use the same type as C++ bool.  Note that this allows one to
1854 # specify the type of bool in a configure-script option and postpone
1855 # integration with the C++ compiler provided that the types are compatible.
1856 USE_CXX_BOOL=1
1857 if test $cf_cv_cc_bool_type = 1
1858 then
1859         # oops: C has a bool.  Unlikely, but C++ could differ.
1860         USE_CXX_BOOL=0
1861 elif test $cf_cv_builtin_bool = 0
1862 then
1863         # C++ has no bool
1864         USE_CXX_BOOL=0
1865 else
1866         # this is the normal case
1867         USE_CXX_BOOL='defined(__cplusplus)'
1868 fi
1869 AC_SUBST(USE_CXX_BOOL)
1870
1871 CF_HELP_MESSAGE(Ada95 Binding Options:)
1872
1873 dnl If the Ada95 source-tree is present, add that to the build unless it will
1874 dnl not work, or was not requested.
1875 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1876
1877 dnl libtool does not know anything about GNAT, though a change made in 1998
1878 dnl provided for it "someday".  Disable the ada subtree if we are using
1879 dnl libtool -TD 20070714
1880         if test "$cf_with_ada" != "no" ; then
1881                 if test "$with_libtool" != "no"; then
1882                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1883                         cf_with_ada=no
1884                 fi
1885         fi
1886
1887 dnl Check for availability of GNU Ada Translator (GNAT).
1888 dnl At the moment we support no other Ada95 compiler.
1889         if test "$cf_with_ada" != "no" ; then
1890                 CF_PROG_GNAT
1891                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1892                         CF_ADD_ADAFLAGS(-gnatpn)
1893                         CF_FIXUP_ADAFLAGS
1894
1895                         CF_GNATPREP_OPT_T
1896
1897                         CF_GNAT_GENERICS
1898                         CF_GNAT_SIGINT
1899                         CF_GNAT_PROJECTS
1900
1901                         CF_WITH_ADA_COMPILER
1902
1903                         cf_ada_package=terminal_interface
1904                         AC_SUBST(cf_ada_package)
1905
1906                         CF_WITH_ADA_INCLUDE
1907                         CF_WITH_ADA_OBJECTS
1908                         CF_WITH_ADA_SHAREDLIB
1909                 fi
1910         fi
1911 else
1912         cf_with_ada=no
1913 fi
1914
1915 # do this "late" to avoid conflict with header-checks
1916 if test "x$with_widec" = xyes ; then
1917         AC_CHECK_SIZEOF(wchar_t)
1918 fi
1919
1920 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1921 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1922 ###
1923 ### ticlib modules may be a separate library, otherwise contained in termlib.
1924 ### termlib modules may be a separate library, otherwise contained in ncurses.
1925 ###
1926 ### The of "+" or " " between the tokens controls the way the script
1927 ### chooses to split module lists into libraries.
1928 ###
1929 ### (see CF_LIB_RULES).
1930 AC_MSG_CHECKING(for library subsets)
1931 LIB_SUBSETS=
1932
1933 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1934         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1935         if test "$with_ticlib" != no ; then
1936                 LIB_SUBSETS="${LIB_SUBSETS} "
1937         else
1938                 LIB_SUBSETS="${LIB_SUBSETS}+"
1939         fi
1940 fi
1941
1942 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1943 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1944
1945 if test "$with_termlib" != no ; then
1946         LIB_SUBSETS="${LIB_SUBSETS} "
1947 else
1948         LIB_SUBSETS="${LIB_SUBSETS}+"
1949 fi
1950
1951 LIB_SUBSETS="${LIB_SUBSETS}base"
1952
1953 # Most term-driver calls are to tinfo, but some like init_pair are to the
1954 # base library (so it resides in base).
1955 if test "$with_term_driver" != no ; then
1956         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1957         case $cf_cv_system_name in
1958         (*mingw32*|*mingw64*)
1959                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1960                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
1961                 ;;
1962         (*)
1963                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1964                 ;;
1965         esac
1966 fi
1967
1968 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1969 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1970
1971 AC_MSG_RESULT($LIB_SUBSETS)
1972
1973 ### Construct the list of include-directories to be generated
1974 CF_INCLUDE_DIRS
1975 CF_ADA_INCLUDE_DIRS
1976
1977 ### Build up pieces for makefile rules
1978 AC_MSG_CHECKING(default library suffix)
1979 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1980 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1981 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1982
1983 AC_MSG_CHECKING(default library-dependency suffix)
1984 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1985 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1986 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1987
1988 AC_MSG_CHECKING(default object directory)
1989 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1990 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1991 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1992
1993 if test "x$cf_with_cxx" = xyes ; then
1994 AC_MSG_CHECKING(c++ library-dependency suffix)
1995 if test "$with_libtool" != "no"; then
1996         # libtool thinks it can make c++ shared libraries (perhaps only g++)
1997         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1998 elif test "$with_shared_cxx" != "no"; then
1999         # also for g++ users...
2000         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2001 else
2002         # we normally make a static library because C/C++ library rules differ
2003         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
2004 fi
2005 AC_MSG_RESULT($CXX_LIB_SUFFIX)
2006 AC_SUBST(CXX_LIB_SUFFIX)
2007 fi
2008
2009 # do not want -ldl in build except as needed for -lncurses dependency
2010 if test "x$with_dlsym" = xyes ; then
2011 if test $DFT_LWR_MODEL = shared || \
2012    test $DFT_LWR_MODEL = libtool ; then
2013         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2014 fi
2015 fi
2016 ### Set up low-level terminfo dependencies for makefiles.
2017
2018 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2019 # do not need libdl
2020 TICS_LIST=
2021 if test "x$with_dlsym" = xyes ; then
2022         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2023 fi
2024
2025 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2026 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2027 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2028 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2029 then
2030         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2031 fi
2032 AC_SUBST(USE_ARG_SUFFIX)
2033 AC_SUBST(USE_CFG_SUFFIX)
2034 AC_SUBST(USE_LIB_SUFFIX)
2035
2036 if test "$with_ticlib" != no ; then
2037
2038         if test "x$with_ticlib" != xyes ; then
2039                 TICS_NAME=$with_ticlib
2040                 TICS_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2041                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2042                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2043                 TICS_LIB_SUFFIX="${with_ticlib}"
2044         else
2045                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2046                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2047                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2048                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2049         fi
2050         TICS_LDFLAGS="-L${LIB_DIR}"
2051         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2052 else
2053         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2054         TICS_LDFLAGS="-L${LIB_DIR}"
2055         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2056 fi
2057 AC_SUBST(TICS_ARG_SUFFIX)
2058 AC_SUBST(TICS_DEP_SUFFIX)
2059 AC_SUBST(TICS_LIB_SUFFIX)
2060 AC_SUBST(TICS_LDFLAGS)
2061 AC_SUBST(TICS_LIBS)
2062
2063 if test "$with_termlib" != no ; then
2064
2065         if test "x$with_termlib" != xyes ; then
2066                 TINFO_NAME=$with_termlib
2067                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2068                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2069                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2070                 TINFO_LIB_SUFFIX="${with_termlib}"
2071         else
2072                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2073                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2074                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2075                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2076         fi
2077
2078         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2079         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2080         if test "$DFT_LWR_MODEL" = "libtool"; then
2081                 TEST_ARGS="${TEST_DEPS}"
2082                 TEST_ARG2="${TEST_DEP2}"
2083                 TINFO_LDFLAGS="-L${LIB_DIR}"
2084                 TINFO_LIBS="$TEST_ARGS"
2085                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2086                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2087         else
2088                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2089                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2090                 if test "x$with_term_driver" != xno ; then
2091                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2092                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2093                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2094                 else
2095                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2096                         TINFO_LIBS="$TEST_ARGS"
2097                 fi
2098                 TINFO_LDFLAGS="-L${LIB_DIR}"
2099                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2100         fi
2101 else
2102         # the next lines are needed for linking libtic over libncurses
2103         TINFO_NAME=${LIB_NAME}
2104         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2105         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2106         if test "x$with_tic_depends" = xyes ; then
2107                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2108         else
2109                 TICS_LIST="$SHLIB_LIST"
2110         fi
2111
2112         TINFO_LDFLAGS="-L${LIB_DIR}"
2113         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2114 fi
2115
2116 if test "$DFT_LWR_MODEL" = shared ; then
2117         case $cf_cv_system_name in
2118         (cygwin*|msys*)
2119                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2120                 TINFO_SUFFIX=.dll
2121                 ;;
2122         esac
2123 fi
2124
2125 AC_SUBST(TINFO_ARG_SUFFIX)
2126 AC_SUBST(TINFO_DEP_SUFFIX)
2127 AC_SUBST(TINFO_LIB_SUFFIX)
2128 AC_SUBST(TINFO_LDFLAGS)
2129 AC_SUBST(TINFO_LIBS)
2130
2131 if test "x$with_dlsym" = xyes ; then
2132         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2133 fi
2134
2135 if test "$DFT_LWR_MODEL" = "libtool"; then
2136         OBJEXT=lo
2137 fi
2138
2139 # needed for Ada95
2140 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2141 AC_SUBST(TINFO_LDFLAGS2)
2142
2143 case $DFT_LWR_MODEL in
2144 (normal|debug|profile)
2145         CF_LDFLAGS_STATIC
2146         ;;
2147 esac
2148
2149 AC_MSG_CHECKING(where we will install curses.h)
2150 AC_SUBST(includesubdir)
2151 includesubdir=
2152 if test "$with_overwrite" = no && \
2153  ( test "x$includedir" = 'x${prefix}/include' || \
2154    test "x$includedir" = "x${prefix}/include" )
2155 then
2156         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2157 fi
2158 AC_MSG_RESULT(${includedir}${includesubdir})
2159
2160 ### Resolve a conflict between normal and wide-curses by forcing applications
2161 ### that will need libutf8 to add it to their configure script.
2162 if test "$with_overwrite" != no ; then
2163 if test "$NCURSES_LIBUTF8" = 1 ; then
2164         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2165         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2166 fi
2167 fi
2168 WITH_OVERWRITE=$with_overwrite
2169
2170 AC_SUBST(WITH_OVERWRITE)
2171 AC_SUBST(TICS_LIST)
2172 AC_SUBST(TINFO_LIST)
2173 AC_SUBST(SHLIB_LIST)
2174
2175 # used to separate tack out of the tree
2176 NCURSES_TREE=
2177 AC_SUBST(NCURSES_TREE)
2178
2179 ### predefined stuff for the test programs
2180 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2181
2182 ### Construct the list of subdirectories for which we'll customize makefiles
2183 ### with the appropriate compile-rules.
2184
2185 CF_SRC_MODULES($modules_to_build)
2186
2187 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2188    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2189    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2190 fi
2191
2192 CF_DIRS_TO_MAKE
2193
2194 # symbols that differ when compiling Ada95 by itself.
2195 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2196 AC_SUBST(NCURSES_SHLIB2)
2197
2198 # values to use as strings
2199 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2200
2201 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2202
2203 ### Now that we're done running tests, add the compiler-warnings, if any
2204 CF_ADD_CFLAGS($EXTRA_CFLAGS)
2205
2206 ### Define substitutions for header files to avoid name-pollution
2207 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2208 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2209 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2210 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2211
2212 ################################################################################
2213 test "x$use_database" = xyes && \
2214 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2215
2216 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2217 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2218
2219 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2220 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2221 fi
2222 AC_SUBST(cross_compiling)
2223
2224 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
2225 if test -n "$FALLBACK_LIST"
2226 then
2227         if test "$TIC_PATH" = unknown
2228         then
2229                 AC_MSG_WARN(no tic program found for fallbacks)
2230         fi
2231 fi
2232 AC_SUBST(TIC_PATH)
2233
2234 if test "x$cf_with_tests" != xno ; then
2235         MAKE_TESTS=
2236 else
2237         MAKE_TESTS="#"
2238 fi
2239 AC_SUBST(MAKE_TESTS)
2240
2241 ADAHTML_DIR=../../doc/html/ada
2242 AC_SUBST(ADAHTML_DIR)
2243
2244 # these could be configurable, but are not currently
2245 PANEL_NAME=panel
2246 MENU_NAME=menu
2247 FORM_NAME=form
2248 CXX_NAME=ncurses++
2249
2250 AC_SUBST(PANEL_NAME)
2251 AC_SUBST(MENU_NAME)
2252 AC_SUBST(FORM_NAME)
2253 AC_SUBST(CXX_NAME)
2254
2255 # workaround for OS/2 (20151017)
2256 case $cf_cv_system_name in
2257 (os2*)
2258         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2259         ;;
2260 (*)
2261         LIBTOOL_OPTS_CXX=
2262         ;;
2263 esac
2264 AC_SUBST(LIBTOOL_OPTS_CXX)
2265
2266 # workaround for g++ versus Solaris (20131116)
2267 case $cf_cv_system_name in
2268 (solaris2*)
2269         case "x$CPPFLAGS" in
2270         (*-D_XOPEN_SOURCE_EXTENDED*)
2271                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2272                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2273                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2274                 ;;
2275         esac
2276         ;;
2277 esac
2278
2279 # Help to automatically enable the extended curses features when using either
2280 # the *-config or the ".pc" files by adding defines.
2281 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2282 PKG_CFLAGS=
2283 for cf_loop1 in $CPPFLAGS_after_XOPEN
2284 do
2285         cf_found=no
2286         for cf_loop2 in $CPPFLAGS_before_XOPEN
2287         do
2288                 if test "x$cf_loop1" = "x$cf_loop2"
2289                 then
2290                         cf_found=yes
2291                         break
2292                 fi
2293         done
2294         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2295 done
2296 AC_MSG_RESULT($PKG_CFLAGS)
2297 AC_SUBST(PKG_CFLAGS)
2298
2299 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2300 case "x$NCURSES_OSPEED" in
2301 (*short*)
2302         cf_compatible=1
2303         ;;
2304 (*)
2305         cf_compatible=0
2306         ;;
2307 esac
2308 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2309
2310 case "x$cf_cv_typeof_chtype" in
2311 (xshort|xint|xlong)
2312         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2313         ;;
2314 esac
2315
2316 case "x$cf_cv_typeof_mmask_t" in
2317 (xshort|xint|xlong)
2318         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2319         ;;
2320 esac
2321
2322 # substitute into misc/Makefile to suppress
2323 # (un)install.data from the
2324 # (un)install rules.
2325 if test "x$cf_with_db_install" = "xno"; then
2326         MISC_INSTALL_DATA=
2327         MISC_UNINSTALL_DATA=
2328 else
2329         MISC_INSTALL_DATA=install.data
2330         MISC_UNINSTALL_DATA=uninstall.data
2331 fi
2332 AC_SUBST(MISC_INSTALL_DATA)
2333 AC_SUBST(MISC_UNINSTALL_DATA)
2334
2335 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2336         MAKE_DATABASE="#"
2337 else
2338         MAKE_DATABASE="$MAKE_TERMINFO"
2339 fi
2340 AC_SUBST(MAKE_DATABASE)
2341
2342 SUB_SCRIPTS=
2343
2344 dnl Override the package used for exported symbols
2345 if test -n "$PACKAGE"
2346 then
2347         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2348         export PACKAGE
2349         echo "package: $PACKAGE"
2350 fi
2351
2352 UNALTERED_SYMS=
2353 cf_filter_syms=no
2354
2355 if test -n "$RESULTING_SYMS"
2356 then
2357         cf_filter_syms=$cf_dft_filter_syms
2358         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2359 fi
2360
2361 if test "x$WILDCARD_SYMS" = xno
2362 then
2363         cf_filter_syms=yes
2364 fi
2365
2366 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2367
2368 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2369 if test $cf_filter_syms = yes
2370 then
2371         RESULTING_SYMS=resulting.map
2372 fi
2373 AC_SUBST(UNALTERED_SYMS)
2374
2375 if test "x$cross_compiling" = xyes ; then
2376         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2377         CHECK_BUILD="#"
2378 else
2379         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2380         CHECK_BUILD=
2381 fi
2382 AC_SUBST(ADAGEN_LDFLAGS)
2383 AC_SUBST(CHECK_BUILD)
2384 AC_SUBST(PRIVATE_LIBS)
2385
2386 AC_DEFINE(HAVE_CURSES_DATA_BOOLNAMES,1,[definition needed for in-tree build of tack])
2387
2388 AC_OUTPUT( \
2389         include/MKterm.h.awk \
2390         include/curses.head:include/curses.h.in \
2391         include/ncurses_dll.h \
2392         include/termcap.h \
2393         include/unctrl.h \
2394         $SUB_SCRIPTS \
2395         $SUB_MAKEFILES \
2396         Makefile,[
2397 if test "x$cf_with_tests" != xno ; then
2398         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2399 fi
2400 CF_LIB_RULES($SRC_SUBDIRS)
2401
2402 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2403 if test -z "$USE_OLD_MAKERULES" ; then
2404         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
2405 fi
2406 fi
2407 ],[
2408 ### Special initialization commands, used to pass information from the
2409 ### configuration-run into config.status
2410
2411 AWK="$AWK"
2412 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2413 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2414 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2415 ECHO_LD="$ECHO_LD"
2416 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2417 LDCONFIG="$LDCONFIG"
2418 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2419 LIB_NAME="$LIB_NAME"
2420 LIB_PREFIX="$LIB_PREFIX"
2421 LIB_SUBSETS="$LIB_SUBSETS"
2422 LIB_SUFFIX="$LIB_SUFFIX"
2423 LIB_TRACING="$LIB_TRACING"
2424 LN_S="$LN_S"
2425 MAKE_TERMINFO="$MAKE_TERMINFO"
2426 NCURSES_MAJOR="$NCURSES_MAJOR"
2427 NCURSES_MINOR="$NCURSES_MINOR"
2428 NCURSES_OSPEED="$NCURSES_OSPEED"
2429 NCURSES_PATCH="$NCURSES_PATCH"
2430 SRC_SUBDIRS="$SRC_SUBDIRS"
2431 TERMINFO="$TERMINFO"
2432 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2433 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2434 TICS_NAME="$TICS_NAME"
2435 TICS_SUFFIX="$TICS_SUFFIX"
2436 TIC_PATH="$TIC_PATH"
2437 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2438 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2439 TINFO_NAME="$TINFO_NAME"
2440 TINFO_SUFFIX="$TINFO_SUFFIX"
2441 UNALTERED_SYMS="$UNALTERED_SYMS"
2442 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2443 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2444 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2445 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2446 WILDCARD_SYMS="$WILDCARD_SYMS"
2447 WITH_CURSES_H="$with_curses_h"
2448 WITH_ECHO="${enable_echo:=yes}"
2449 WITH_OVERWRITE="$with_overwrite"
2450 cf_LIST_MODELS="$cf_list_models"
2451 cf_cv_abi_version="$cf_cv_abi_version"
2452 cf_cv_do_relink="$cf_cv_do_relink"
2453 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2454 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2455 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2456 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2457 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2458 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2459 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2460 cf_cv_rel_version="$cf_cv_rel_version"
2461 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2462 cf_cv_shared_soname='$cf_cv_shared_soname'
2463 cf_cv_shlib_version="$cf_cv_shlib_version"
2464 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2465 cf_cv_system_name="$cf_cv_system_name"
2466 cf_cv_term_driver="$with_term_driver"
2467 cf_with_ada="$cf_with_ada"
2468 cf_with_cxx_binding="$cf_with_cxx_binding"
2469 cf_with_db_install="$cf_with_db_install"
2470 cf_with_manpages="$cf_with_manpages"
2471 cf_with_tests="$cf_with_tests"
2472 host="$host"
2473 target="$target"
2474 with_shared_cxx="$with_shared_cxx"
2475
2476 ],cat)dnl
2477 ${MAKE:-make} preinstall