configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2010,2011 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.523 2011/07/16 21:54:34 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.523 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to install manpages)
 126 AC_ARG_WITH(manpages,
 127         [  --without-manpages      suppress install of manpages],
 128         [cf_with_manpages=$withval],
 129         [cf_with_manpages=yes])
 130 AC_MSG_RESULT($cf_with_manpages)
 131
 132 AC_MSG_CHECKING(if you want to build programs such as tic)
 133 AC_ARG_WITH(progs,
 134         [  --without-progs         suppress build with programs (e.g., tic)],
 135         [cf_with_progs=$withval],
 136         [cf_with_progs=yes])
 137 AC_MSG_RESULT($cf_with_progs)
 138
 139 AC_MSG_CHECKING(if you want to build test-programs)
 140 AC_ARG_WITH(tests,
 141         [  --without-tests         suppress build with test-programs],
 142         [cf_with_tests=$withval],
 143         [cf_with_tests=yes])
 144 AC_MSG_RESULT($cf_with_tests)
 145
 146 AC_MSG_CHECKING(if you wish to install curses.h)
 147 AC_ARG_WITH(curses-h,
 148         [  --without-curses-h      install curses.h as ncurses.h only],
 149         [with_curses_h=$withval],
 150         [with_curses_h=yes])
 151 AC_MSG_RESULT($with_curses_h)
 152
 153 modules_to_build="ncurses"
 154 if test "X$cf_with_progs" != Xno ; then
 155 modules_to_build="$modules_to_build progs tack"
 156 fi
 157 modules_to_build="$modules_to_build panel menu form"
 158
 159 AC_ARG_PROGRAM
 160
 161 CF_PROG_AWK
 162 CF_PROG_EGREP
 163 CF_PROG_INSTALL
 164 CF_PROG_LINT
 165 CF_PROG_LN_S
 166
 167 AC_SYS_LONG_FILE_NAMES
 168
 169 # if we find pkg-config, check if we should install the ".pc" files.
 170 CF_PKG_CONFIG
 171 CF_ENABLE_PC_FILES
 172
 173 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 174 AC_ARG_ENABLE(mixed-case,
 175         [  --enable-mixed-case     tic should assume mixed-case filenames],
 176         [enable_mixedcase=$enableval],
 177         [enable_mixedcase=auto])
 178 AC_MSG_RESULT($enable_mixedcase)
 179 if test "$enable_mixedcase" = "auto" ; then
 180     CF_MIXEDCASE_FILENAMES
 181 else
 182     cf_cv_mixedcase=$enable_mixedcase
 183     if test "$enable_mixedcase" = "yes" ; then
 184         AC_DEFINE(MIXEDCASE_FILENAMES)
 185     fi
 186 fi
 187
 188 # do this after mixed-case option (tags/TAGS is not as important as tic).
 189 AC_PROG_MAKE_SET
 190 CF_MAKE_TAGS
 191 CF_MAKEFLAGS
 192
 193 dnl These are standard among *NIX systems, but not when cross-compiling
 194 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 195 AC_CHECK_TOOL(LD, ld, ld)
 196 AC_CHECK_TOOL(AR, ar, ar)
 197 CF_AR_FLAGS
 198
 199 dnl Special option for use by system-builders: the install-prefix is used to
 200 dnl adjust the location into which the actual install is done, so that an
 201 dnl archive can be built without modifying the host system's configuration.
 202 AC_MSG_CHECKING(if you have specified an install-prefix)
 203 AC_ARG_WITH(install-prefix,
 204         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 205         [case "$withval" in #(vi
 206         yes|no) #(vi
 207                 ;;
 208         *)      DESTDIR="$withval"
 209                 ;;
 210         esac])
 211 AC_MSG_RESULT($DESTDIR)
 212 AC_SUBST(DESTDIR)
 213
 214 ###############################################################################
 215 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 216 # If we're cross-compiling, allow the user to override the tools and their
 217 # options.  The configure script is oriented toward identifying the host
 218 # compiler, etc., but we need a build compiler to generate parts of the source.
 219 CF_BUILD_CC
 220
 221 ###############################################################################
 222 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 223
 224 ### Options to allow the user to specify the set of libraries which are used.
 225 ### Use "--without-normal --with-shared" to allow the default model to be
 226 ### shared, for example.
 227 cf_list_models=""
 228 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 229
 230 CF_WITH_LIBTOOL
 231 if test "$with_libtool" != "no" ; then
 232
 233 cf_list_models="$cf_list_models libtool"
 234
 235 else
 236
 237 AC_MSG_CHECKING(if you want to build shared libraries)
 238 AC_ARG_WITH(shared,
 239         [  --with-shared           generate shared-libraries],
 240         [with_shared=$withval],
 241         [with_shared=no])
 242 AC_MSG_RESULT($with_shared)
 243 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 244
 245 AC_MSG_CHECKING(if you want to build static libraries)
 246 AC_ARG_WITH(normal,
 247         [  --with-normal           generate normal-libraries (default)],
 248         [with_normal=$withval],
 249         [with_normal=yes])
 250 AC_MSG_RESULT($with_normal)
 251 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 252
 253 AC_MSG_CHECKING(if you want to build debug libraries)
 254 AC_ARG_WITH(debug,
 255         [  --with-debug            generate debug-libraries (default)],
 256         [with_debug=$withval],
 257         [with_debug=yes])
 258 AC_MSG_RESULT($with_debug)
 259 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 260
 261 AC_MSG_CHECKING(if you want to build profiling libraries)
 262 AC_ARG_WITH(profile,
 263         [  --with-profile          generate profile-libraries],
 264         [with_profile=$withval],
 265         [with_profile=no])
 266 AC_MSG_RESULT($with_profile)
 267 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 268
 269 fi
 270
 271 ###############################################################################
 272
 273 AC_MSG_CHECKING(for specified models)
 274 test -z "$cf_list_models" && cf_list_models=normal
 275 dnl If we use libtool to generate libraries, then it must be the only
 276 dnl specified model.
 277 test "$with_libtool" != "no" && cf_list_models=libtool
 278 AC_MSG_RESULT($cf_list_models)
 279
 280 ### Use the first model as the default, and save its suffix for use in building
 281 ### up test-applications.
 282 AC_MSG_CHECKING(for default model)
 283 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 284 AC_MSG_RESULT($DFT_LWR_MODEL)
 285
 286 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 287
 288 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 289 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 290
 291 TICS_NAME=tic
 292 AC_SUBST(TICS_NAME)
 293
 294 TINFO_NAME=tinfo
 295 AC_SUBST(TINFO_NAME)
 296
 297 LIB_NAME=ncurses
 298 AC_SUBST(LIB_NAME)
 299
 300 LIB_DIR=../lib
 301 LIB_2ND=../../lib
 302
 303 CF_LIB_PREFIX(cf_prefix)
 304 LIB_PREFIX=$cf_prefix
 305 AC_SUBST(LIB_PREFIX)
 306
 307 LIB_SUFFIX=
 308 AC_SUBST(LIB_SUFFIX)
 309
 310 ###############################################################################
 311
 312 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 313 AC_ARG_WITH(termlib,
 314         [  --with-termlib          generate separate terminfo library],
 315         [with_termlib=$withval],
 316         [with_termlib=no])
 317 AC_MSG_RESULT($with_termlib)
 318
 319 AC_MSG_CHECKING(if you want to build a separate tic library)
 320 AC_ARG_WITH(ticlib,
 321         [  --with-ticlib           generate separate tic library],
 322         [with_ticlib=$withval],
 323         [with_ticlib=no])
 324 AC_MSG_RESULT($with_ticlib)
 325
 326 ### Checks for special libraries, must be done up-front.
 327 SHLIB_LIST=""
 328 CF_WITH_GPM
 329 if test "$with_gpm" != no ; then
 330         AC_MSG_CHECKING(if you want to load GPM dynamically)
 331         AC_ARG_WITH(dlsym,
 332                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 333                 [with_dlsym=$withval],
 334                 [with_dlsym=yes])
 335         AC_MSG_RESULT($with_dlsym)
 336         if test "$with_dlsym" = yes ; then
 337                 CF_FUNC_DLSYM
 338                 if test "$with_gpm" != yes ; then
 339                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 340                         cf_cv_gpm_soname="$with_gpm"
 341                 else
 342                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 343                 fi
 344                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 345                 SHLIB_LIST="-ldl $SHLIB_LIST"
 346         else
 347                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 348                 CF_ADD_LIB(gpm,TEST_LIBS)
 349         fi
 350         AC_DEFINE(HAVE_LIBGPM)
 351         CF_CHECK_GPM_WGETCH
 352 fi
 353
 354 CF_WITH_SYSMOUSE
 355
 356 dnl Not all ports of gcc support the -g option
 357
 358 if test X"$CC_G_OPT" = X"" ; then
 359         CC_G_OPT='-g'
 360         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 361 fi
 362 AC_SUBST(CC_G_OPT)
 363
 364 if test X"$CXX_G_OPT" = X"" ; then
 365         CXX_G_OPT='-g'
 366         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 367 fi
 368 AC_SUBST(CXX_G_OPT)
 369
 370 AC_MSG_CHECKING(for default loader flags)
 371 case $DFT_LWR_MODEL in
 372 libtool) LD_MODEL=''   ;;
 373 normal)  LD_MODEL=''   ;;
 374 debug)   LD_MODEL=$CC_G_OPT ;;
 375 profile) LD_MODEL='-pg';;
 376 shared)  LD_MODEL=''   ;;
 377 esac
 378 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 379 AC_MSG_RESULT($LD_MODEL)
 380
 381 case $DFT_LWR_MODEL in
 382 shared)
 383 CF_ENABLE_RPATH
 384 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 385 AC_ARG_ENABLE(relink,
 386 [  --disable-relink        relink shared libraries during install],
 387 [cf_cv_do_relink=$enableval],
 388 [cf_cv_do_relink=yes])
 389 AC_MSG_RESULT($cf_cv_do_relink)
 390         ;;
 391 esac
 392
 393 CF_SHARED_OPTS
 394 if test "$CC_SHARED_OPTS" = "unknown"; then
 395         for model in $cf_list_models; do
 396                 if test "$model" = "shared"; then
 397                         AC_ERROR(Shared libraries are not supported in this version)
 398                 fi
 399         done
 400 fi
 401
 402 ### If we're building with rpath, try to link non-standard libs that way too.
 403 if test "$DFT_LWR_MODEL" = "shared"; then
 404         CF_DISABLE_RPATH_HACK
 405 fi
 406
 407 ###############################################################################
 408 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 409
 410 ###     use option --disable-overwrite to leave out the link to -lcurses
 411 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 412 AC_ARG_ENABLE(overwrite,
 413         [  --disable-overwrite     leave out the link to -lcurses],
 414         [with_overwrite=$enableval],
 415         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 416 AC_MSG_RESULT($with_overwrite)
 417
 418 AC_MSG_CHECKING(if external terminfo-database is used)
 419 AC_ARG_ENABLE(database,
 420         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 421         [use_database=$enableval],
 422         [use_database=yes])
 423 AC_MSG_RESULT($use_database)
 424
 425 case $host_os in #(vi
 426 os2*) #(vi
 427         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 428         ;;
 429 *) #(vi
 430         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 431         ;;
 432 esac
 433 AC_SUBST(TERMINFO_SRC)
 434
 435 if test "$use_database" != no ; then
 436         AC_DEFINE(USE_DATABASE)
 437
 438         AC_MSG_CHECKING(which terminfo source-file will be installed)
 439         AC_ARG_WITH(database,
 440                 [  --with-database=XXX     specify terminfo source to install],
 441                 [TERMINFO_SRC=$withval])
 442         AC_MSG_RESULT($TERMINFO_SRC)
 443
 444         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 445         AC_ARG_WITH(hashed-db,
 446                 [  --with-hashed-db        specify hashed-database library],,
 447                 [with_hashed_db=no])
 448         AC_MSG_RESULT($with_hashed_db)
 449 else
 450         with_hashed_db=no
 451 fi
 452
 453 AC_MSG_CHECKING(for list of fallback descriptions)
 454 AC_ARG_WITH(fallbacks,
 455         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 456         [with_fallback=$withval],
 457         [with_fallback=])
 458 AC_MSG_RESULT($with_fallback)
 459 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 460 AC_SUBST(FALLBACK_LIST)
 461
 462 AC_MSG_CHECKING(if you want modern xterm or antique)
 463 AC_ARG_WITH(xterm-new,
 464         [  --without-xterm-new     specify if xterm terminfo should be old version],
 465         [with_xterm_new=$withval],
 466         [with_xterm_new=yes])
 467 case $with_xterm_new in
 468 no)     with_xterm_new=xterm-old;;
 469 *)      with_xterm_new=xterm-new;;
 470 esac
 471 AC_MSG_RESULT($with_xterm_new)
 472 WHICH_XTERM=$with_xterm_new
 473 AC_SUBST(WHICH_XTERM)
 474
 475 MAKE_TERMINFO=
 476 if test "$use_database" = no ; then
 477         TERMINFO="${datadir}/terminfo"
 478         MAKE_TERMINFO="#"
 479 else
 480
 481 AC_MSG_CHECKING(for list of terminfo directories)
 482 CF_WITH_PATHLIST(terminfo-dirs,
 483         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 484         TERMINFO_DIRS,
 485         DATADIR/terminfo,
 486         ${datadir}/terminfo)
 487 AC_MSG_RESULT($TERMINFO_DIRS)
 488 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 489
 490 AC_MSG_CHECKING(for default terminfo directory)
 491 CF_WITH_PATH(default-terminfo-dir,
 492         [  --with-default-terminfo-dir=DIR default terminfo directory],
 493         TERMINFO,
 494         DATADIR/terminfo,
 495         ${datadir}/terminfo)
 496 AC_MSG_RESULT($TERMINFO)
 497 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 498
 499 fi
 500
 501 AC_SUBST(TERMINFO)
 502 AC_SUBST(MAKE_TERMINFO)
 503
 504 ###     use option --disable-big-core to make tic run on small machines
 505 ###     We need 4Mb, check if we can allocate 50% more than that.
 506 AC_MSG_CHECKING(if big-core option selected)
 507 AC_ARG_ENABLE(big-core,
 508         [  --disable-big-core      assume machine has little memory],
 509         [with_big_core=$enableval],
 510         [AC_TRY_RUN([
 511 #include <stdlib.h>
 512 #include <string.h>
 513 int main() {
 514         unsigned long n = 6000000L;
 515         char *s = malloc(n);
 516         if (s != 0)
 517                 s[0] = s[n-1] = 0;
 518         ${cf_cv_main_return:-return}(s == 0);
 519 }],
 520         [with_big_core=yes],
 521         [with_big_core=no],
 522         [with_big_core=no])])
 523 AC_MSG_RESULT($with_big_core)
 524 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 525
 526 ### ISO C only guarantees 512-char strings, we have tables which load faster
 527 ### when constructed using "big" strings.  More than the C compiler, the awk
 528 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 529 AC_MSG_CHECKING(if big-strings option selected)
 530 AC_ARG_ENABLE(big-strings,
 531         [  --disable-big-strings   assume compiler has only standard-size strings],
 532         [with_big_strings=$enableval],
 533         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 534 AC_MSG_RESULT($with_big_strings)
 535
 536 USE_BIG_STRINGS=0
 537 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
 538 AC_SUBST(USE_BIG_STRINGS)
 539
 540 ###     use option --enable-termcap to compile in the termcap fallback support
 541 AC_MSG_CHECKING(if you want termcap-fallback support)
 542 AC_ARG_ENABLE(termcap,
 543         [  --enable-termcap        compile in termcap fallback support],
 544         [with_termcap=$enableval],
 545         [with_termcap=no])
 546 AC_MSG_RESULT($with_termcap)
 547
 548 if test "$with_termcap" != "yes" ; then
 549         if test "$use_database" = no ; then
 550                 if test -z "$with_fallback" ; then
 551                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 552                 fi
 553         fi
 554         AC_DEFINE(PURE_TERMINFO)
 555 else
 556
 557 if test "$with_ticlib" != no ; then
 558         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 559 fi
 560
 561 AC_DEFINE(USE_TERMCAP)
 562 AC_MSG_CHECKING(for list of termcap files)
 563 CF_WITH_PATHLIST(termpath,
 564         [  --with-termpath=XXX     specify list of termcap files],
 565         TERMPATH,
 566         /etc/termcap:/usr/share/misc/termcap)
 567 AC_MSG_RESULT($TERMPATH)
 568 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 569
 570 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 571 AC_MSG_CHECKING(if fast termcap-loader is needed)
 572 AC_ARG_ENABLE(getcap,
 573         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 574         [with_getcap=$enableval],
 575         [with_getcap=no])
 576 AC_MSG_RESULT($with_getcap)
 577 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 578
 579 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 580 AC_ARG_ENABLE(getcap-cache,
 581         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 582         [with_getcap_cache=$enableval],
 583         [with_getcap_cache=no])
 584 AC_MSG_RESULT($with_getcap_cache)
 585 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 586
 587 fi
 588
 589 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 590 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 591 AC_ARG_ENABLE(home-terminfo,
 592         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 593         [with_home_terminfo=$enableval],
 594         [with_home_terminfo=yes])
 595 AC_MSG_RESULT($with_home_terminfo)
 596 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 597
 598 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 599 AC_ARG_ENABLE(root-environ,
 600         [  --disable-root-environ  restrict environment when running as root],
 601         [with_root_environ=$enableval],
 602         [with_root_environ=yes])
 603 AC_MSG_RESULT($with_root_environ)
 604 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 605
 606 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 607 ###   to reduce storage requirements for the terminfo database.
 608 CF_LINK_FUNCS
 609
 610 with_links=no
 611 with_symlinks=no
 612
 613 # soft links (symbolic links) are useful for some systems where hard links do
 614 # not work, or to make it simpler to copy terminfo trees around.
 615 if test "$ac_cv_func_symlink" = yes ; then
 616     AC_MSG_CHECKING(if tic should use symbolic links)
 617     AC_ARG_ENABLE(symlinks,
 618         [  --enable-symlinks       make tic use symbolic links not hard links],
 619         [with_symlinks=$enableval],
 620         [with_symlinks=no])
 621     AC_MSG_RESULT($with_symlinks)
 622 fi
 623
 624 # If we have hard links and did not choose to use soft links instead, there is
 625 # no reason to make this choice optional - use the hard links.
 626 if test "$with_symlinks" = no ; then
 627     AC_MSG_CHECKING(if tic should use hard links)
 628     if test "$ac_cv_func_link" = yes ; then
 629         with_links=yes
 630     else
 631         with_links=no
 632     fi
 633     AC_MSG_RESULT($with_links)
 634 fi
 635
 636 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 637 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 638
 639 ###   use option --enable-broken-linker to force on use of broken-linker support
 640 AC_MSG_CHECKING(if you want broken-linker support code)
 641 AC_ARG_ENABLE(broken_linker,
 642         [  --enable-broken_linker  compile with broken-linker support code],
 643         [with_broken_linker=$enableval],
 644         [with_broken_linker=${BROKEN_LINKER:-no}])
 645 AC_MSG_RESULT($with_broken_linker)
 646
 647 BROKEN_LINKER=0
 648 if test "$with_broken_linker" = yes ; then
 649         AC_DEFINE(BROKEN_LINKER)
 650         BROKEN_LINKER=1
 651 elif test "$DFT_LWR_MODEL" = shared ; then
 652         case $cf_cv_system_name in #(vi
 653         cygwin*)
 654                 AC_DEFINE(BROKEN_LINKER)
 655                 BROKEN_LINKER=1
 656                 CF_VERBOSE(cygwin linker is broken anyway)
 657                 ;;
 658         esac
 659 fi
 660 AC_SUBST(BROKEN_LINKER)
 661
 662 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 663 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 664 AC_ARG_ENABLE(bsdpad,
 665         [  --enable-bsdpad         recognize BSD-style prefix padding],
 666         [with_bsdpad=$enableval],
 667         [with_bsdpad=no])
 668 AC_MSG_RESULT($with_bsdpad)
 669 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 670
 671 ###   use option --enable-widec to turn on use of wide-character support
 672 NCURSES_CH_T=chtype
 673 NCURSES_LIBUTF8=0
 674
 675 NEED_WCHAR_H=0
 676 NCURSES_MBSTATE_T=0
 677 NCURSES_WCHAR_T=0
 678 NCURSES_WINT_T=0
 679
 680 # Check to define _XOPEN_SOURCE "automatically"
 681 CF_XOPEN_SOURCE(500)
 682
 683 # Work around breakage on OS X
 684 CF_SIGWINCH
 685
 686 # Checks for CODESET support.
 687 AM_LANGINFO_CODESET
 688
 689 # use these variables to work around a defect in gcc's fixincludes.
 690 NCURSES_OK_WCHAR_T=
 691 NCURSES_OK_WINT_T=
 692
 693 AC_MSG_CHECKING(if you want wide-character code)
 694 AC_ARG_ENABLE(widec,
 695         [  --enable-widec          compile with wide-char/UTF-8 code],
 696         [with_widec=$enableval],
 697         [with_widec=no])
 698 AC_MSG_RESULT($with_widec)
 699 if test "$with_widec" = yes ; then
 700         LIB_SUFFIX="w${LIB_SUFFIX}"
 701         AC_DEFINE(USE_WIDEC_SUPPORT)
 702
 703         case "$CFLAGS $CPPFLAGS" in #(vi
 704         *-D_XOPEN_SOURCE=500) #(vi
 705                 ;;
 706         *)
 707                 CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 708                 ;;
 709         esac
 710
 711         # with_overwrite=no
 712         NCURSES_CH_T=cchar_t
 713         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 714         if test "$ac_cv_func_putwc" != yes ; then
 715                 CF_UTF8_LIB
 716                 if test "$cf_cv_utf8_lib" != no ; then
 717                         NCURSES_LIBUTF8=1
 718                 fi
 719         fi
 720         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 721         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 722         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 723
 724         if test "$NCURSES_MBSTATE_T" != 0; then
 725                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 726         fi
 727 fi
 728 AC_SUBST(NCURSES_CH_T)
 729 AC_SUBST(NCURSES_LIBUTF8)
 730
 731 AC_SUBST(NEED_WCHAR_H)
 732 AC_SUBST(NCURSES_MBSTATE_T)
 733 AC_SUBST(NCURSES_WCHAR_T)
 734 AC_SUBST(NCURSES_WINT_T)
 735
 736 AC_SUBST(NCURSES_OK_WCHAR_T)
 737 AC_SUBST(NCURSES_OK_WINT_T)
 738
 739 ###   use option --disable-lp64 to allow long chtype
 740 case $cf_cv_abi_version in
 741 [[345]]*)
 742         default_with_lp64=no
 743         ;;
 744 *)
 745         default_with_lp64=yes
 746         ;;
 747 esac
 748
 749 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 750 AC_ARG_ENABLE(lp64,
 751         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 752         [with_lp64=$enableval],
 753         [with_lp64=$default_with_lp64])
 754 AC_MSG_RESULT($with_lp64)
 755
 756 if test "$with_lp64" = yes ; then
 757         cf_cv_enable_lp64=1
 758 else
 759         cf_cv_enable_lp64=0
 760 fi
 761 AC_SUBST(cf_cv_enable_lp64)
 762
 763 CF_LARGEFILE
 764
 765 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 766 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 767 AC_ARG_ENABLE(tparm-varargs,
 768         [  --disable-tparm-varargs compile tparm() without varargs interface],
 769         [with_tparm_varargs=$enableval],
 770         [with_tparm_varargs=yes])
 771 AC_MSG_RESULT($with_tparm_varargs)
 772 NCURSES_TPARM_VARARGS=0
 773 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 774 AC_SUBST(NCURSES_TPARM_VARARGS)
 775
 776 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 777 if test "$with_ticlib" != no ; then
 778 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 779 AC_ARG_ENABLE(tic-depends,
 780         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 781         [with_tic_depends=$enableval],
 782         [with_tic_depends=yes])
 783 AC_MSG_RESULT($with_tic_depends)
 784 else
 785         with_tic_depends=no
 786 fi
 787
 788 ###   use option --with-bool to override bool's type
 789 AC_MSG_CHECKING(for type of bool)
 790 AC_ARG_WITH(bool,
 791         [  --with-bool=TYPE        override fallback type of bool variable],
 792         [NCURSES_BOOL="$withval"],
 793         [NCURSES_BOOL=auto])
 794 AC_MSG_RESULT($NCURSES_BOOL)
 795 AC_SUBST(NCURSES_BOOL)
 796
 797 AC_MSG_CHECKING(for alternate terminal capabilities file)
 798 AC_ARG_WITH(caps,
 799         [  --with-caps=alt         compile with alternate Caps file],
 800         [TERMINFO_CAPS=Caps.$withval],
 801         [TERMINFO_CAPS=Caps])
 802 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 803 AC_MSG_RESULT($TERMINFO_CAPS)
 804 AC_SUBST(TERMINFO_CAPS)
 805
 806 ###   use option --with-chtype to override chtype's type
 807 AC_MSG_CHECKING(for type of chtype)
 808 AC_ARG_WITH(chtype,
 809         [  --with-chtype=TYPE      override type of chtype],
 810         [NCURSES_CHTYPE="$withval"],
 811         [NCURSES_CHTYPE=auto])
 812 AC_MSG_RESULT($NCURSES_CHTYPE)
 813
 814 ###   use option --with-ospeed to override ospeed's type
 815 AC_MSG_CHECKING(for type of ospeed)
 816 AC_ARG_WITH(ospeed,
 817         [  --with-ospeed=TYPE      override type of ospeed variable],
 818         [NCURSES_OSPEED="$withval"],
 819         [NCURSES_OSPEED=short])
 820 AC_MSG_RESULT($NCURSES_OSPEED)
 821 AC_SUBST(NCURSES_OSPEED)
 822
 823 ###   use option --with-mmask-t to override mmask_t's type
 824 AC_MSG_CHECKING(for type of mmask_t)
 825 AC_ARG_WITH(mmask-t,
 826         [  --with-mmask-t=TYPE     override type of mmask_t],
 827         [NCURSES_MMASK_T="$withval"],
 828         [NCURSES_MMASK_T=auto])
 829 AC_MSG_RESULT($NCURSES_MMASK_T)
 830
 831 ###   use option --with-ccharw-max to override CCHARW_MAX size
 832 AC_MSG_CHECKING(for size CCHARW_MAX)
 833 AC_ARG_WITH(ccharw-max,
 834         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
 835         [NCURSES_CCHARW_MAX="$withval"],
 836         [NCURSES_CCHARW_MAX=5])
 837 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
 838 AC_SUBST(NCURSES_CCHARW_MAX)
 839
 840 ### Enable compiling-in rcs id's
 841 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 842 AC_ARG_WITH(rcs-ids,
 843         [  --with-rcs-ids          compile-in RCS identifiers],
 844         [with_rcs_ids=$withval],
 845         [with_rcs_ids=no])
 846 AC_MSG_RESULT($with_rcs_ids)
 847 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 848
 849 ###############################################################################
 850 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
 851
 852 ###############################################################################
 853 CF_HELP_MESSAGE(Extensions:)
 854
 855 ### Note that some functions (such as const) are normally disabled anyway.
 856 AC_MSG_CHECKING(if you want to build with function extensions)
 857 AC_ARG_ENABLE(ext-funcs,
 858         [  --disable-ext-funcs     disable function-extensions],
 859         [with_ext_funcs=$enableval],
 860         [with_ext_funcs=yes])
 861 AC_MSG_RESULT($with_ext_funcs)
 862 if test "$with_ext_funcs" = yes ; then
 863         NCURSES_EXT_FUNCS=1
 864         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS)
 865         AC_DEFINE(HAVE_CURSES_VERSION)
 866         AC_DEFINE(HAVE_HAS_KEY)
 867         AC_DEFINE(HAVE_RESIZETERM)
 868         AC_DEFINE(HAVE_RESIZE_TERM)
 869         AC_DEFINE(HAVE_TERM_ENTRY_H)
 870         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 871         AC_DEFINE(HAVE_USE_SCREEN)
 872         AC_DEFINE(HAVE_USE_WINDOW)
 873         AC_DEFINE(HAVE_WRESIZE)
 874         AC_DEFINE(NCURSES_EXT_FUNCS)
 875         GENERATED_EXT_FUNCS=generated
 876 else
 877         NCURSES_EXT_FUNCS=0
 878         GENERATED_EXT_FUNCS=
 879 fi
 880 AC_SUBST(NCURSES_EXT_FUNCS)
 881 AC_SUBST(GENERATED_EXT_FUNCS)
 882
 883 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
 884 AC_ARG_ENABLE(sp-funcs,
 885         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
 886         [with_sp_funcs=$enableval],
 887         [with_sp_funcs=no])
 888 AC_MSG_RESULT($with_sp_funcs)
 889 if test "$with_sp_funcs" = yes ; then
 890         NCURSES_SP_FUNCS=1
 891         AC_DEFINE(NCURSES_SP_FUNCS)
 892         GENERATED_SP_FUNCS=generated
 893 else
 894         NCURSES_SP_FUNCS=0
 895         GENERATED_SP_FUNCS=
 896 fi
 897 AC_SUBST(NCURSES_SP_FUNCS)
 898 AC_SUBST(GENERATED_SP_FUNCS)
 899
 900 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
 901 AC_ARG_ENABLE(term-driver,
 902         [  --enable-term-driver    enable experimental terminal-driver],
 903         [with_term_driver=$enableval],
 904         [with_term_driver=no])
 905 AC_MSG_RESULT($with_term_driver)
 906 if test "$with_term_driver" = yes ; then
 907         AC_DEFINE(USE_TERM_DRIVER)
 908         if test "$with_sp_funcs" != yes ; then
 909                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
 910         fi
 911 fi
 912
 913 ###   use option --enable-const to turn on use of const beyond that in XSI.
 914 AC_MSG_CHECKING(for extended use of const keyword)
 915 AC_ARG_ENABLE(const,
 916         [  --enable-const          compile with extra/non-standard const],
 917         [with_ext_const=$enableval],
 918         [with_ext_const=no])
 919 AC_MSG_RESULT($with_ext_const)
 920 NCURSES_CONST='/*nothing*/'
 921 if test "$with_ext_const" = yes ; then
 922         NCURSES_CONST=const
 923 fi
 924 AC_SUBST(NCURSES_CONST)
 925
 926 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 927 AC_MSG_CHECKING(if you want to use extended colors)
 928 AC_ARG_ENABLE(ext-colors,
 929         [  --enable-ext-colors     compile for 256-color support],
 930         [with_ext_colors=$enableval],
 931         [with_ext_colors=no])
 932 AC_MSG_RESULT($with_ext_colors)
 933 NCURSES_EXT_COLORS=0
 934 if test "$with_ext_colors" = yes ; then
 935         if test "$with_widec" != yes ; then
 936                 AC_MSG_ERROR(This option applies only to wide-character library)
 937         else
 938                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 939                 CF_NCURSES_ABI_6
 940         fi
 941         NCURSES_EXT_COLORS=1
 942         AC_DEFINE(NCURSES_EXT_COLORS)
 943 fi
 944 AC_SUBST(NCURSES_EXT_COLORS)
 945
 946 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 947 AC_MSG_CHECKING(if you want to use extended mouse encoding)
 948 AC_ARG_ENABLE(ext-mouse,
 949         [  --enable-ext-mouse      compile for extended mouse-encoding],
 950         [with_ext_mouse=$enableval],
 951         [with_ext_mouse=no])
 952 AC_MSG_RESULT($with_ext_mouse)
 953 NCURSES_MOUSE_VERSION=1
 954 if test "$with_ext_mouse" = yes ; then
 955         NCURSES_MOUSE_VERSION=2
 956         CF_NCURSES_ABI_6
 957 fi
 958 AC_SUBST(NCURSES_MOUSE_VERSION)
 959
 960 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 961 AC_ARG_ENABLE(no-padding,
 962         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 963         [with_no_padding=$enableval],
 964         [with_no_padding=$with_ext_funcs])
 965 AC_MSG_RESULT($with_no_padding)
 966 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 967
 968 AC_CHECK_SIZEOF([signed char], 0)
 969 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 970         NCURSES_SBOOL="signed char"
 971 else
 972         NCURSES_SBOOL="char"
 973 fi
 974 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 975 AC_ARG_ENABLE(signed-char,
 976         [  --enable-signed-char    compile using signed Boolean's in term.h],
 977         [with_signed_char=$enableval],
 978         [with_signed_char=no])
 979 AC_MSG_RESULT($with_signed_char)
 980 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
 981 AC_SUBST(NCURSES_SBOOL)
 982
 983 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
 984 AC_MSG_CHECKING(if you want SIGWINCH handler)
 985 AC_ARG_ENABLE(sigwinch,
 986         [  --enable-sigwinch       compile with SIGWINCH handler],
 987         [with_sigwinch=$enableval],
 988         [with_sigwinch=$with_ext_funcs])
 989 AC_MSG_RESULT($with_sigwinch)
 990 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
 991
 992 ###   use option --enable-tcap-names to allow user to define new capabilities
 993 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
 994 AC_ARG_ENABLE(tcap-names,
 995         [  --enable-tcap-names     compile with user-definable terminal capabilities],
 996         [with_tcap_names=$enableval],
 997         [with_tcap_names=$with_ext_funcs])
 998 AC_MSG_RESULT($with_tcap_names)
 999 NCURSES_XNAMES=0
1000 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
1001 AC_SUBST(NCURSES_XNAMES)
1002
1003 ###############################################################################
1004 # These options are relatively safe to experiment with.
1005 CF_HELP_MESSAGE(Development Code:)
1006 AC_MSG_CHECKING(if you want all development code)
1007 AC_ARG_WITH(develop,
1008         [  --without-develop       disable development options],
1009         [with_develop=$withval],
1010         [with_develop=no])
1011 AC_MSG_RESULT($with_develop)
1012
1013 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1014 AC_MSG_CHECKING(if you want hard-tabs code)
1015 AC_ARG_ENABLE(hard-tabs,
1016         [  --enable-hard-tabs      compile with hard-tabs code],,
1017         [enable_hard_tabs=$with_develop])
1018 AC_MSG_RESULT($enable_hard_tabs)
1019 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
1020
1021 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1022 AC_MSG_CHECKING(if you want limited support for xmc)
1023 AC_ARG_ENABLE(xmc-glitch,
1024         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1025         [enable_xmc_glitch=$with_develop])
1026 AC_MSG_RESULT($enable_xmc_glitch)
1027 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
1028
1029 ###############################################################################
1030 # These are just experimental, probably should not be in a package:
1031 CF_HELP_MESSAGE(Experimental Code:)
1032
1033 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1034 AC_ARG_ENABLE(assumed-color,
1035         [  --disable-assumed-color do not assume anything about default-colors],
1036         [with_assumed_color=$enableval],
1037         [with_assumed_color=yes])
1038 AC_MSG_RESULT($with_assumed_color)
1039 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
1040
1041 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1042 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1043 AC_ARG_ENABLE(hashmap,
1044         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1045         [with_hashmap=$enableval],
1046         [with_hashmap=yes])
1047 AC_MSG_RESULT($with_hashmap)
1048 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1049
1050 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1051 AC_MSG_CHECKING(if you want colorfgbg code)
1052 AC_ARG_ENABLE(colorfgbg,
1053         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1054         [with_colorfgbg=$enableval],
1055         [with_colorfgbg=no])
1056 AC_MSG_RESULT($with_colorfgbg)
1057 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1058
1059 ###   use option --enable-interop to turn on use of bindings used for interop
1060 AC_MSG_CHECKING(if you want interop bindings)
1061 AC_ARG_ENABLE(interop,
1062         [  --enable-interop        compile-in experimental interop bindings],
1063         [with_exp_interop=$enableval],
1064         [with_exp_interop=no])
1065 AC_MSG_RESULT($with_exp_interop)
1066
1067 NCURSES_INTEROP_FUNCS=0
1068 test "$with_exp_interop" = yes && NCURSES_INTEROP_FUNCS=1
1069 AC_SUBST(NCURSES_INTEROP_FUNCS)
1070
1071 # This is still experimental (20080329), but should ultimately be moved to
1072 # the script-block --with-normal, etc.
1073 CF_WITH_PTHREAD
1074
1075 if test "x$with_pthread" != xno; then
1076         AC_CHECK_FUNC(pthread_kill,[
1077                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1078                 AC_ARG_ENABLE(pthreads-eintr,
1079                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1080                         [use_pthreads_eintr=$enableval],
1081                         [use_pthreads_eintr=no])
1082                 AC_MSG_RESULT($use_pthreads_eintr)
1083                 if test $use_pthreads_eintr = yes ; then
1084                         AC_DEFINE(USE_PTHREADS_EINTR)
1085                 fi])
1086
1087         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1088         AC_ARG_ENABLE(weak-symbols,
1089                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1090                 [use_weak_symbols=$enableval],
1091                 [use_weak_symbols=no])
1092         AC_MSG_RESULT($use_weak_symbols)
1093         if test "$use_weak_symbols" = yes ; then
1094                 CF_WEAK_SYMBOLS
1095         else
1096                 cf_cv_weak_symbols=no
1097         fi
1098
1099         if test $cf_cv_weak_symbols = yes ; then
1100                 AC_DEFINE(USE_WEAK_SYMBOLS)
1101         fi
1102 fi
1103
1104 PTHREAD=
1105 if test "$with_pthread" = "yes" ; then
1106     AC_DEFINE(USE_PTHREADS)
1107     enable_reentrant=yes
1108     if test $cf_cv_weak_symbols = yes ; then
1109         PTHREAD=-lpthread
1110     fi
1111 fi
1112 AC_SUBST(PTHREAD)
1113
1114 # Reentrant code has to be opaque; there's little advantage to making ncurses
1115 # opaque outside of that, so there is no --enable-opaque option.  We can use
1116 # this option without --with-pthreads, but this will be always set for
1117 # pthreads.
1118 AC_MSG_CHECKING(if you want experimental reentrant code)
1119 AC_ARG_ENABLE(reentrant,
1120         [  --enable-reentrant      compile with experimental reentrant code],
1121         [with_reentrant=$enableval],
1122         [with_reentrant=no])
1123 AC_MSG_RESULT($with_reentrant)
1124 if test "$with_reentrant" = yes ; then
1125         cf_cv_enable_reentrant=1
1126         cf_cv_enable_opaque="NCURSES_INTERNALS"
1127         NCURSES_OPAQUE=1
1128         NCURSES_SIZE_T=int
1129         if test $cf_cv_weak_symbols = yes ; then
1130                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1131                 CF_ADD_LIB(pthread,TEST_LIBS)
1132                 CF_ADD_LIB(pthread,TEST_LIBS2)
1133         else
1134                 LIB_SUFFIX="t${LIB_SUFFIX}"
1135         fi
1136         AC_DEFINE(USE_REENTRANT)
1137         CF_NCURSES_ABI_6
1138 else
1139         cf_cv_enable_reentrant=0
1140         cf_cv_enable_opaque="NCURSES_OPAQUE"
1141         NCURSES_OPAQUE=0
1142         NCURSES_SIZE_T=short
1143 fi
1144 AC_SUBST(cf_cv_enable_reentrant)
1145 AC_SUBST(cf_cv_enable_opaque)
1146 AC_SUBST(NCURSES_OPAQUE)
1147 AC_SUBST(NCURSES_SIZE_T)
1148
1149 ### Allow using a different wrap-prefix
1150 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1151         AC_MSG_CHECKING(for prefix used to wrap public variables)
1152         AC_ARG_WITH(wrap-prefix,
1153                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1154                 [NCURSES_WRAP_PREFIX=$withval],
1155                 [NCURSES_WRAP_PREFIX=_nc_])
1156         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1157 else
1158         NCURSES_WRAP_PREFIX=_nc_
1159 fi
1160 AC_SUBST(NCURSES_WRAP_PREFIX)
1161 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX")
1162
1163 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1164 AC_ARG_ENABLE(safe-sprintf,
1165         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1166         [with_safe_sprintf=$enableval],
1167         [with_safe_sprintf=no])
1168 AC_MSG_RESULT($with_safe_sprintf)
1169 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1170
1171 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1172 # when hashmap is used scroll hints are useless
1173 if test "$with_hashmap" = no ; then
1174 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1175 AC_ARG_ENABLE(scroll-hints,
1176         [  --disable-scroll-hints  compile without scroll-hints code],
1177         [with_scroll_hints=$enableval],
1178         [with_scroll_hints=yes])
1179 AC_MSG_RESULT($with_scroll_hints)
1180 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1181 fi
1182
1183 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1184 AC_ARG_ENABLE(wgetch-events,
1185         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1186         [with_wgetch_events=$enableval],
1187         [with_wgetch_events=no])
1188 AC_MSG_RESULT($with_wgetch_events)
1189 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1190
1191 ###############################################################################
1192 CF_HELP_MESSAGE(Testing/development Options:)
1193
1194 ###     use option --disable-echo to suppress full display compiling commands
1195 AC_MSG_CHECKING(if you want to display full commands during build)
1196 AC_ARG_ENABLE(echo,
1197         [  --enable-echo           build: display "compiling" commands (default)],
1198         [with_echo=$enableval],
1199         [with_echo=yes])
1200 if test "$with_echo" = yes; then
1201         ECHO_LINK=
1202 else
1203         ECHO_LINK='@ echo linking $@ ... ;'
1204         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1205         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1206 fi
1207 AC_MSG_RESULT($with_echo)
1208 AC_SUBST(ECHO_LINK)
1209
1210 ###     use option --enable-warnings to turn on all gcc warnings
1211 AC_MSG_CHECKING(if you want to see compiler warnings)
1212 AC_ARG_ENABLE(warnings,
1213         [  --enable-warnings       build: turn on GCC compiler warnings],
1214         [with_warnings=$enableval])
1215 AC_MSG_RESULT($with_warnings)
1216
1217 if test "x$with_warnings" = "xyes"; then
1218         CF_ADD_ADAFLAGS(-gnatg)
1219         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1220         if test "$cf_with_cxx" = yes ; then
1221                 CF_GXX_WARNINGS(Wno-unused)
1222         fi
1223 fi
1224 CF_GCC_ATTRIBUTES
1225
1226 ###     use option --enable-assertions to turn on generation of assertion code
1227 AC_MSG_CHECKING(if you want to enable runtime assertions)
1228 AC_ARG_ENABLE(assertions,
1229         [  --enable-assertions     test: turn on generation of assertion code],
1230         [with_assertions=$enableval],
1231         [with_assertions=no])
1232 AC_MSG_RESULT($with_assertions)
1233 if test -n "$GCC"
1234 then
1235         if test "$with_assertions" = no
1236         then
1237                 AC_DEFINE(NDEBUG)
1238                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1239         else
1240                 CF_ADD_ADAFLAGS(-gnata)
1241         fi
1242 fi
1243
1244 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1245 CF_DISABLE_LEAKS
1246 AC_DEFINE(HAVE_NC_ALLOC_H)
1247
1248 ###     use option --enable-expanded to generate certain macros as functions
1249 AC_ARG_ENABLE(expanded,
1250         [  --enable-expanded       test: generate functions for certain macros],
1251         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1252
1253 ###     use option --disable-macros to suppress macros in favor of functions
1254 AC_ARG_ENABLE(macros,
1255         [  --disable-macros        test: use functions rather than macros],
1256         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1257
1258 # Normally we only add trace() to the debug-library.  Allow this to be
1259 # extended to all models of the ncurses library:
1260 cf_all_traces=no
1261 case "$CFLAGS $CPPFLAGS" in
1262 *-DTRACE*)
1263         cf_all_traces=yes
1264         ;;
1265 esac
1266
1267 AC_MSG_CHECKING(whether to add trace feature to all models)
1268 AC_ARG_WITH(trace,
1269 [  --with-trace            test: add trace() function to all models of ncurses],
1270 [cf_with_trace=$withval],
1271 [cf_with_trace=$cf_all_traces])
1272 AC_MSG_RESULT($cf_with_trace)
1273
1274 if test "$cf_with_trace" = yes ; then
1275         LIB_TRACING=all
1276         ADA_TRACE=TRUE
1277         CF_ADD_CFLAGS(-DTRACE)
1278 else
1279         LIB_TRACING=DEBUG
1280         ADA_TRACE=FALSE
1281 fi
1282
1283 AC_SUBST(ADA_TRACE)
1284
1285 ###     Checks for libraries.
1286 case $cf_cv_system_name in #(vi
1287 *mingw32*) #(vi
1288         ;;
1289 *)
1290 AC_CHECK_FUNC(gettimeofday,
1291         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1292
1293 AC_CHECK_LIB(bsd, gettimeofday,
1294         AC_DEFINE(HAVE_GETTIMEOFDAY)
1295         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1296         ;;
1297 esac
1298
1299 CF_MATH_LIB(MATH_LIB,sin(x))
1300 AC_SUBST(MATH_LIB)
1301
1302 ###     Checks for header files.
1303 AC_STDC_HEADERS
1304 AC_HEADER_DIRENT
1305 AC_HEADER_TIME
1306 CF_REGEX
1307
1308 dnl These are some other potentially nonportable headers.
1309 AC_CHECK_HEADERS( \
1310 fcntl.h \
1311 getopt.h \
1312 limits.h \
1313 locale.h \
1314 math.h \
1315 poll.h \
1316 sys/bsdtypes.h \
1317 sys/ioctl.h \
1318 sys/param.h \
1319 sys/poll.h \
1320 sys/select.h \
1321 sys/time.h \
1322 sys/times.h \
1323 ttyent.h \
1324 unistd.h \
1325 wctype.h \
1326 )
1327
1328 CF_GETOPT_HEADER
1329
1330 # check for ISC (this may also define _POSIX_SOURCE)
1331 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1332 if test "$ISC" = yes ; then
1333         AC_CHECK_LIB(cposix,main)
1334         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1335 fi
1336
1337 CF_SYS_TIME_SELECT
1338
1339 ###     checks for compiler characteristics
1340 AC_LANG_C
1341 AC_C_CONST
1342 CF_C_INLINE(NCURSES_INLINE,1200)
1343 CF_SIG_ATOMIC_T
1344
1345 if test $NCURSES_CHTYPE = auto ; then
1346         CF_TYPEOF_CHTYPE
1347 else
1348         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1349 fi
1350 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1351 AC_SUBST(cf_cv_typeof_chtype)
1352
1353 CF_UNSIGNED_LITERALS
1354 cf_cv_1UL="1"
1355 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1356 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1357 AC_SUBST(cf_cv_1UL)
1358
1359 if test $NCURSES_MMASK_T = auto ; then
1360         cf_cv_typeof_mmask_t=long
1361 else
1362         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1363 fi
1364 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1365 AC_SUBST(cf_cv_typeof_mmask_t)
1366
1367 ###     Checks for external-data
1368 CF_ERRNO
1369 CF_LINK_DATAONLY
1370
1371 ###     Checks for library functions.
1372 AC_CHECK_FUNCS( \
1373 getcwd \
1374 getegid \
1375 geteuid \
1376 getttynam \
1377 issetugid \
1378 poll \
1379 remove \
1380 select \
1381 setbuf \
1382 setbuffer \
1383 setvbuf \
1384 sigaction \
1385 sigvec \
1386 strdup \
1387 strstr \
1388 tcgetpgrp \
1389 times \
1390 vsnprintf \
1391 )
1392 if test "$with_getcap" = "yes" ; then
1393         CF_CGETENT
1394 fi
1395
1396 CF_ISASCII
1397 CF_STRUCT_SIGACTION
1398 CF_FUNC_NANOSLEEP
1399 CF_FUNC_TERMIOS
1400 CF_FUNC_VSSCANF
1401 CF_MKSTEMP
1402
1403 # setup for prototype of fallback for vsscanf()
1404 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1405
1406 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1407 if test "$cross_compiling" = yes ; then
1408         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1409 else
1410         AC_FUNC_SETVBUF_REVERSED
1411 fi
1412 AC_TYPE_SIGNAL
1413 CF_TYPE_SIGACTION
1414 CF_SIZECHANGE
1415 CF_FUNC_MEMMOVE
1416 CF_FUNC_POLL
1417 CF_VA_COPY
1418 AC_FUNC_VFORK
1419
1420 # special check for test/ditto.c
1421 CF_FUNC_OPENPTY
1422 if test "$cf_cv_func_openpty" != no ; then
1423     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1424     AC_DEFINE(USE_XTERM_PTY)
1425     if test "$cf_cv_lib_util" = yes ; then
1426         CF_ADD_LIB(util,TEST_LIBS)
1427     fi
1428 fi
1429 AC_SUBST(TEST_LIBS)
1430 AC_SUBST(TEST_LIBS2)
1431
1432 if test "$with_hashed_db" != no ; then
1433         AC_DEFINE(USE_HASHED_DB)
1434         CF_HASHED_DB($with_hashed_db)
1435 fi
1436
1437 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1438 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1439         CF_STRIP_G_OPT(CFLAGS)
1440         CF_STRIP_G_OPT(CXXFLAGS)
1441 fi
1442
1443 # Just in case, check if the C compiler has a bool type.
1444 CF_BOOL_DECL(cf_cv_cc_bool_type)
1445
1446 # Check for C++ compiler characteristics (and ensure that it's there!)
1447 if test -n "$CXX" ; then
1448         AC_LANG_CPLUSPLUS
1449         CF_STDCPP_LIBRARY
1450         CF_PROG_CC_C_O(CXX)
1451
1452         case $GXX_VERSION in
1453         1*|2.[0-6]*)
1454                 cf_cxx_library=yes
1455                 ;;
1456         *-2.7*|2.7*)
1457                 CF_GPP_LIBRARY
1458                 ;;
1459         *)
1460                 cf_cxx_library=no
1461                 ;;
1462         esac
1463
1464         AC_CHECK_HEADERS(iostream typeinfo)
1465
1466     if test x"$ac_cv_header_iostream" = xyes ; then
1467         AC_MSG_CHECKING(if iostream uses std-namespace)
1468         AC_TRY_COMPILE([
1469 #include <iostream>
1470 using std::endl;
1471 using std::cerr;],[
1472 cerr << "testing" << endl;
1473 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1474         AC_MSG_RESULT($cf_iostream_namespace)
1475         if test "$cf_iostream_namespace" = yes ; then
1476             AC_DEFINE(IOSTREAM_NAMESPACE)
1477         fi
1478     fi
1479
1480         CF_BOOL_DECL
1481         CF_BOOL_SIZE
1482         CF_ETIP_DEFINES
1483         CF_CPP_PARAM_INIT
1484         CF_CPP_STATIC_CAST
1485
1486         CXX_AR='$(AR)'
1487         CXX_ARFLAGS='$(ARFLAGS)'
1488         case $cf_cv_system_name in #(vi
1489         irix*) #(vi
1490             if test "$GXX" != yes ; then
1491                 CXX_AR='$(CXX)'
1492                 CXX_ARFLAGS='-ar -o'
1493             fi
1494             ;;
1495         sco3.2v5*) #(vi
1496             CXXLDFLAGS="-u main"
1497             ;;
1498         solaris2*)
1499             if test "$GXX" != yes ; then
1500                 CXX_AR='$(CXX)'
1501                 CXX_ARFLAGS='-xar -o'
1502             fi
1503             ;;
1504         esac
1505         AC_SUBST(CXXLDFLAGS)
1506         AC_SUBST(CXX_AR)
1507         AC_SUBST(CXX_ARFLAGS)
1508 else
1509         cf_cxx_library=no
1510         cf_cv_builtin_bool=1
1511
1512         # Just because we are not configuring against C++ right now does not
1513         # mean that a user will not want to use C++.  Some distributors disable
1514         # the C++ portion of this configuration as a shortcut (or just to avoid
1515         # compiling the demo in the c++ directory).  So we need a reasonable
1516         # default for the 'bool' type.
1517         #
1518         # Caveat: since the storage of the bool type is not standardized, it
1519         # may change.
1520
1521         if test "$NCURSES_BOOL" != auto ; then
1522                 cf_cv_type_of_bool=$NCURSES_BOOL
1523                 cf_cv_header_stdbool_h=0
1524         else
1525                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1526                         CF_BOOL_SIZE
1527                 else
1528                         AC_MSG_CHECKING(for fallback type of bool)
1529                         case "$host_cpu" in #(vi
1530                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1531                         *)      cf_cv_type_of_bool=int  ;;
1532                         esac
1533                         AC_MSG_RESULT($cf_cv_type_of_bool)
1534                 fi
1535         fi
1536 fi
1537 AC_SUBST(CXXLIBS)
1538
1539 # If the C compiler did not declare bool, and we did not determine that the C++
1540 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1541 # ncurses library use the same type as C++ bool.  Note that this allows one to
1542 # specify the type of bool in a configure-script option and postpone
1543 # integration with the C++ compiler provided that the types are compatible.
1544 USE_CXX_BOOL=1
1545 if test $cf_cv_cc_bool_type = 1
1546 then
1547         # oops: C has a bool.  Unlikely, but C++ could differ.
1548         USE_CXX_BOOL=0
1549 elif test $cf_cv_builtin_bool = 0
1550 then
1551         # C++ has no bool
1552         USE_CXX_BOOL=0
1553 else
1554         # this is the normal case
1555         USE_CXX_BOOL='defined(__cplusplus)'
1556 fi
1557 AC_SUBST(USE_CXX_BOOL)
1558
1559 CF_HELP_MESSAGE(Ada95 Binding Options:)
1560
1561 dnl If the Ada95 source-tree is present, add that to the build unless it will
1562 dnl not work, or was not requested.
1563 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1564
1565 dnl libtool does not know anything about GNAT, though a change made in 1998
1566 dnl provided for it "someday".  Disable the ada subtree if we are using
1567 dnl libtool -TD 20070714
1568         if test "$cf_with_ada" != "no" ; then
1569                 if test "$with_libtool" != "no"; then
1570                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1571                         cf_with_ada=no
1572                 fi
1573         fi
1574
1575 dnl Check for availability of GNU Ada Translator (GNAT).
1576 dnl At the moment we support no other Ada95 compiler.
1577         if test "$cf_with_ada" != "no" ; then
1578                 CF_PROG_GNAT
1579                 if test "$cf_cv_prog_gnat_correct" = yes; then
1580                         CF_ADD_ADAFLAGS(-gnatpn)
1581
1582                         # make ADAFLAGS consistent with CFLAGS
1583                         case "$CFLAGS" in
1584                         *-g*)
1585                                 CF_ADD_ADAFLAGS(-g)
1586                                 ;;
1587                         esac
1588                         case "$CFLAGS" in
1589                         *-O*)
1590                                 CF_ADD_ADAFLAGS(-O3)
1591                                 ;;
1592                         esac
1593
1594                         CF_GNAT_GENERICS
1595                         CF_GNAT_SIGINT
1596                         CF_GNAT_PRAGMA_UNREF
1597                         CF_GNAT_PROJECTS
1598
1599                         CF_WITH_ADA_COMPILER
1600
1601                         cf_ada_package=terminal_interface
1602                         AC_SUBST(cf_ada_package)
1603
1604                         CF_WITH_ADA_INCLUDE
1605                         CF_WITH_ADA_OBJECTS
1606                         CF_WITH_ADA_SHAREDLIB
1607                 fi
1608         fi
1609 else
1610         cf_with_ada=no
1611 fi
1612
1613 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1614 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1615 ###
1616 ### ticlib modules may be a separate library, otherwise contained in termlib.
1617 ### termlib modules may be a separate library, otherwise contained in ncurses.
1618 ###
1619 ### The of "+" or " " between the tokens controls the way the script
1620 ### chooses to split module lists into libraries.
1621 ###
1622 ### (see CF_LIB_RULES).
1623 AC_MSG_CHECKING(for library subsets)
1624 LIB_SUBSETS=
1625
1626 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1627         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1628         if test "$with_ticlib" != no ; then
1629                 LIB_SUBSETS="${LIB_SUBSETS} "
1630         else
1631                 LIB_SUBSETS="${LIB_SUBSETS}+"
1632         fi
1633 fi
1634
1635 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1636 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1637
1638 if test "$with_termlib" != no ; then
1639         LIB_SUBSETS="${LIB_SUBSETS} "
1640 else
1641         LIB_SUBSETS="${LIB_SUBSETS}+"
1642 fi
1643
1644 LIB_SUBSETS="${LIB_SUBSETS}base"
1645
1646 # Most term-driver calls are to tinfo, but some like init_pair are to the
1647 # base library (so it resides in base).
1648 if test "$with_term_driver" != no ; then
1649         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1650         case $cf_cv_system_name in #(vi
1651         *mingw32*) #(vi
1652                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1653                 ;;
1654         *) #(vi
1655                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1656                 ;;
1657         esac
1658 fi
1659
1660 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1661 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1662
1663 AC_MSG_RESULT($LIB_SUBSETS)
1664
1665 ### Construct the list of include-directories to be generated
1666 CF_INCLUDE_DIRS
1667 CF_ADA_INCLUDE_DIRS
1668
1669 ### Build up pieces for makefile rules
1670 AC_MSG_CHECKING(default library suffix)
1671 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1672 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1673 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1674
1675 AC_MSG_CHECKING(default library-dependency suffix)
1676 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1677 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1678 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1679
1680 AC_MSG_CHECKING(default object directory)
1681 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1682 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1683 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1684
1685 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1686 if test "$cf_with_cxx" = yes ; then
1687 AC_MSG_CHECKING(c++ library-dependency suffix)
1688 if test "$with_libtool" != "no"; then
1689         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1690 else
1691         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1692 fi
1693 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1694 AC_SUBST(CXX_LIB_SUFFIX)
1695 fi
1696
1697 # do not want -ldl in build except as needed for -lncurses dependency
1698 if test "$with_dlsym" = yes ; then
1699 if test $DFT_LWR_MODEL = shared || \
1700    test $DFT_LWR_MODEL = libtool ; then
1701         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1702 fi
1703 fi
1704 ### Set up low-level terminfo dependencies for makefiles.
1705
1706 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1707 # do not need libdl
1708 TICS_LIST=
1709 if test "$with_dlsym" = yes ; then
1710         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1711 fi
1712
1713 if test "$with_ticlib" != no ; then
1714
1715         if test "$with_ticlib" != yes ; then
1716                 TICS_NAME=$with_ticlib
1717                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1718                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1719                 TICS_LIB_SUFFIX="${with_ticlib}"
1720         else
1721                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1722                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1723                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1724         fi
1725         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1726 else
1727         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1728 fi
1729 AC_SUBST(TICS_ARG_SUFFIX)
1730 AC_SUBST(TICS_DEP_SUFFIX)
1731 AC_SUBST(TICS_LIB_SUFFIX)
1732 AC_SUBST(TICS_ARGS)
1733
1734 if test "$with_termlib" != no ; then
1735
1736         if test "$with_termlib" != yes ; then
1737                 TINFO_NAME=$with_termlib
1738                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1739                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1740                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1741                 TINFO_LIB_SUFFIX="${with_termlib}"
1742         else
1743                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1744                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1745                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1746                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1747         fi
1748
1749         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1750         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1751         if test "$DFT_LWR_MODEL" = "libtool"; then
1752                 TEST_ARGS="${TEST_DEPS}"
1753                 TEST_ARG2="${TEST_DEP2}"
1754                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1755                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1756                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1757         else
1758                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1759                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1760                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1761                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1762                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1763         fi
1764 else
1765         # the next lines are needed for linking libtic over libncurses
1766         TINFO_NAME=${LIB_NAME}
1767         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1768         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1769         if test "$with_tic_depends" = yes ; then
1770                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1771         else
1772                 TICS_LIST="$SHLIB_LIST"
1773         fi
1774
1775         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1776 fi
1777
1778 if test "$DFT_LWR_MODEL" = shared ; then
1779         case $cf_cv_system_name in #(vi
1780         cygwin*)
1781                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1782                 TINFO_SUFFIX=.dll
1783                 ;;
1784         esac
1785 fi
1786
1787 AC_SUBST(TINFO_ARG_SUFFIX)
1788 AC_SUBST(TINFO_DEP_SUFFIX)
1789 AC_SUBST(TINFO_LIB_SUFFIX)
1790 AC_SUBST(TINFO_ARGS)
1791
1792 if test "$with_dlsym" = yes ; then
1793         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1794 fi
1795
1796 if test "$DFT_LWR_MODEL" = "libtool"; then
1797     OBJEXT=lo
1798 fi
1799
1800 # needed for Ada95
1801 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1802 AC_SUBST(TINFO_ARGS2)
1803
1804 case $DFT_LWR_MODEL in
1805 normal|debug|profile)
1806         CF_LDFLAGS_STATIC
1807         ;;
1808 esac
1809
1810 AC_MSG_CHECKING(where we will install curses.h)
1811 test "$with_overwrite" = no && \
1812 test "x$includedir" = 'x${prefix}/include' && \
1813         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1814 AC_MSG_RESULT($includedir)
1815
1816 ### Resolve a conflict between normal and wide-curses by forcing applications
1817 ### that will need libutf8 to add it to their configure script.
1818 if test "$with_overwrite" != no ; then
1819 if test "$NCURSES_LIBUTF8" = 1 ; then
1820         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1821         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1822 fi
1823 fi
1824 WITH_OVERWRITE=$with_overwrite
1825
1826 AC_SUBST(WITH_OVERWRITE)
1827 AC_SUBST(TICS_LIST)
1828 AC_SUBST(TINFO_LIST)
1829 AC_SUBST(SHLIB_LIST)
1830
1831 # used to separate tack out of the tree
1832 NCURSES_TREE=
1833 AC_SUBST(NCURSES_TREE)
1834
1835 ### predefined stuff for the test programs
1836 AC_DEFINE(HAVE_SLK_COLOR)
1837
1838 ### Construct the list of subdirectories for which we'll customize makefiles
1839 ### with the appropriate compile-rules.
1840
1841 CF_SRC_MODULES($modules_to_build)
1842
1843 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1844    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1845    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1846 fi
1847
1848 CF_DIRS_TO_MAKE
1849
1850 # symbols that differ when compiling Ada95 by itself.
1851 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1852 AC_SUBST(NCURSES_SHLIB2)
1853
1854 # values to use as strings
1855 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR')
1856
1857 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1858
1859 ### Now that we're done running tests, add the compiler-warnings, if any
1860 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1861
1862 ### Define substitutions for header files to avoid name-pollution
1863 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1864 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1865 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1866
1867 ################################################################################
1868 test "$use_database" = yes && \
1869 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1870
1871 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1872 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1873
1874 if test x"$enable_pc_files" = xyes ; then \
1875 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1876 MAKE_PC_FILES=
1877 else
1878 MAKE_PC_FILES="#"
1879 fi
1880 AC_SUBST(MAKE_PC_FILES)
1881 AC_SUBST(cross_compiling)
1882
1883 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
1884 if test -n "$FALLBACK_LIST"
1885 then
1886         if test "$TIC_PATH" = unknown
1887         then
1888                 AC_MSG_WARN(no tic program found for fallbacks)
1889         fi
1890 fi
1891 AC_SUBST(TIC_PATH)
1892
1893 if test "x$cf_with_tests" != xno ; then
1894         MAKE_TESTS=
1895 else
1896         MAKE_TESTS="#"
1897 fi
1898 AC_SUBST(MAKE_TESTS)
1899
1900 ADAHTML_DIR=../../doc/html/ada
1901 AC_SUBST(ADAHTML_DIR)
1902
1903 SUB_SCRIPTS=
1904 case $cf_cv_system_name in #(vi
1905 *mingw32*) #(vi
1906         SUB_SCRIPTS="mk-dlls.sh"
1907         ;;
1908 esac
1909
1910 AC_OUTPUT( \
1911         include/MKterm.h.awk \
1912         include/curses.head:include/curses.h.in \
1913         include/ncurses_dll.h \
1914         include/termcap.h \
1915         include/unctrl.h \
1916         $SUB_SCRIPTS \
1917         $SUB_MAKEFILES \
1918         Makefile,[
1919 if test "x$cf_with_tests" != xno ; then
1920         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LINK"], test)
1921 fi
1922 CF_LIB_RULES($SRC_SUBDIRS)
1923
1924 if test "x$cf_with_ada" != xno ; then
1925 if test -z "$USE_OLD_MAKERULES" ; then
1926         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
1927 fi
1928 fi
1929 ],[
1930 ### Special initialization commands, used to pass information from the
1931 ### configuration-run into config.status
1932
1933 AWK="$AWK"
1934 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1935 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1936 ECHO_LINK="$ECHO_LINK"
1937 LDCONFIG="$LDCONFIG"
1938 LIBTOOL_VERSION="$LIBTOOL_VERSION"
1939 LIB_NAME="$LIB_NAME"
1940 LIB_SUBSETS="$LIB_SUBSETS"
1941 LIB_SUFFIX="$LIB_SUFFIX"
1942 LIB_TRACING="$LIB_TRACING"
1943 LN_S="$LN_S"
1944 MAKE_TERMINFO="$MAKE_TERMINFO"
1945 NCURSES_MAJOR="$NCURSES_MAJOR"
1946 NCURSES_MINOR="$NCURSES_MINOR"
1947 NCURSES_OSPEED="$NCURSES_OSPEED"
1948 NCURSES_PATCH="$NCURSES_PATCH"
1949 SRC_SUBDIRS="$SRC_SUBDIRS"
1950 TERMINFO="$TERMINFO"
1951 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1952 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1953 TICS_NAME="$TICS_NAME"
1954 TIC_PATH="$TIC_PATH"
1955 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1956 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1957 TINFO_NAME="$TINFO_NAME"
1958 TINFO_SUFFIX="$TINFO_SUFFIX"
1959 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
1960 WITH_CURSES_H="$with_curses_h"
1961 WITH_ECHO="$with_echo"
1962 WITH_OVERWRITE="$with_overwrite"
1963 cf_LIST_MODELS="$cf_list_models"
1964 cf_cv_abi_version="$cf_cv_abi_version"
1965 cf_cv_do_relink="$cf_cv_do_relink"
1966 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1967 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1968 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1969 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1970 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1971 cf_cv_rel_version="$cf_cv_rel_version"
1972 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1973 cf_cv_shared_soname='$cf_cv_shared_soname'
1974 cf_cv_shlib_version="$cf_cv_shlib_version"
1975 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1976 cf_cv_system_name="$cf_cv_system_name"
1977 cf_with_ada="$cf_with_ada"
1978 cf_with_cxx_binding="$cf_with_cxx_binding"
1979 cf_with_manpages="$cf_with_manpages"
1980 cf_with_tests="$cf_with_tests"
1981 host="$host"
1982 target="$target"
1983
1984 ],cat)dnl
1985 ${MAKE:-make} preinstall