configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2008,2009 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.479 2009/11/28 21:44:28 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.479 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to install manpages)
 126 AC_ARG_WITH(manpages,
 127         [  --without-manpages      suppress install of manpages],
 128         [cf_with_manpages=$withval],
 129         [cf_with_manpages=yes])
 130 AC_MSG_RESULT($cf_with_manpages)
 131
 132 AC_MSG_CHECKING(if you want to build programs such as tic)
 133 AC_ARG_WITH(progs,
 134         [  --without-progs         suppress build with programs (e.g., tic)],
 135         [cf_with_progs=$withval],
 136         [cf_with_progs=yes])
 137 AC_MSG_RESULT($cf_with_progs)
 138
 139 AC_MSG_CHECKING(if you wish to install curses.h)
 140 AC_ARG_WITH(curses-h,
 141         [  --without-curses-h      install curses.h as ncurses.h only],
 142         [with_curses_h=$withval],
 143         [with_curses_h=yes])
 144 AC_MSG_RESULT($with_curses_h)
 145
 146 modules_to_build="ncurses"
 147 if test "X$cf_with_progs" != Xno ; then
 148 modules_to_build="$modules_to_build progs tack"
 149 fi
 150 modules_to_build="$modules_to_build panel menu form"
 151
 152 AC_ARG_PROGRAM
 153
 154 CF_PROG_AWK
 155 CF_PROG_EGREP
 156 CF_PROG_INSTALL
 157 CF_PROG_LINT
 158 AC_PROG_LN_S
 159
 160 AC_SYS_LONG_FILE_NAMES
 161
 162 # if we find pkg-config, check if we should install the ".pc" files.
 163 CF_PKG_CONFIG
 164
 165 if test "$PKG_CONFIG" != no ; then
 166         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
 167
 168         # Leave this as something that can be overridden in the environment.
 169         if test -z "$PKG_CONFIG_LIBDIR" ; then
 170                 PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`/lib/pkgconfig
 171         fi
 172         PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG_LIBDIR" | sed -e 's/^://' -e 's/:.*//'`
 173         if test -n "$PKG_CONFIG_LIBDIR" && test -d "$PKG_CONFIG_LIBDIR" ; then
 174                 AC_ARG_ENABLE(pc-files,
 175                         [  --enable-pc-files       generate and install .pc files for pkg-config],
 176                         [enable_pc_files=$enableval],
 177                         [enable_pc_files=no])
 178                 AC_MSG_RESULT($enable_pc_files)
 179         else
 180                 AC_MSG_RESULT(no)
 181                 AC_MSG_WARN(did not find library $PKG_CONFIG_LIBDIR)
 182                 enable_pc_files=no
 183         fi
 184 fi
 185 AC_SUBST(PKG_CONFIG_LIBDIR)
 186
 187 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 188 AC_ARG_ENABLE(mixed-case,
 189         [  --enable-mixed-case     tic should assume mixed-case filenames],
 190         [enable_mixedcase=$enableval],
 191         [enable_mixedcase=auto])
 192 AC_MSG_RESULT($enable_mixedcase)
 193 if test "$enable_mixedcase" = "auto" ; then
 194     CF_MIXEDCASE_FILENAMES
 195 else
 196     cf_cv_mixedcase=$enable_mixedcase
 197     if test "$enable_mixedcase" = "yes" ; then
 198         AC_DEFINE(MIXEDCASE_FILENAMES)
 199     fi
 200 fi
 201
 202 # do this after mixed-case option (tags/TAGS is not as important as tic).
 203 AC_PROG_MAKE_SET
 204 CF_MAKE_TAGS
 205 CF_MAKEFLAGS
 206
 207 dnl These are standard among *NIX systems, but not when cross-compiling
 208 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 209 AC_CHECK_TOOL(LD, ld, ld)
 210 AC_CHECK_TOOL(AR, ar, ar)
 211 CF_AR_FLAGS
 212
 213 dnl Special option for use by system-builders: the install-prefix is used to
 214 dnl adjust the location into which the actual install is done, so that an
 215 dnl archive can be built without modifying the host system's configuration.
 216 AC_MSG_CHECKING(if you have specified an install-prefix)
 217 AC_ARG_WITH(install-prefix,
 218         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 219         [case "$withval" in #(vi
 220         yes|no) #(vi
 221                 ;;
 222         *)      DESTDIR="$withval"
 223                 ;;
 224         esac])
 225 AC_MSG_RESULT($DESTDIR)
 226 AC_SUBST(DESTDIR)
 227
 228 ###############################################################################
 229 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 230 # If we're cross-compiling, allow the user to override the tools and their
 231 # options.  The configure script is oriented toward identifying the host
 232 # compiler, etc., but we need a build compiler to generate parts of the source.
 233 CF_BUILD_CC
 234
 235 ###############################################################################
 236 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 237
 238 ### Options to allow the user to specify the set of libraries which are used.
 239 ### Use "--without-normal --with-shared" to allow the default model to be
 240 ### shared, for example.
 241 cf_list_models=""
 242 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 243
 244 CF_WITH_LIBTOOL
 245 if test "$with_libtool" != "no" ; then
 246
 247 cf_list_models="$cf_list_models libtool"
 248
 249 else
 250
 251 AC_MSG_CHECKING(if you want to build shared libraries)
 252 AC_ARG_WITH(shared,
 253         [  --with-shared           generate shared-libraries],
 254         [with_shared=$withval],
 255         [with_shared=no])
 256 AC_MSG_RESULT($with_shared)
 257 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 258
 259 AC_MSG_CHECKING(if you want to build static libraries)
 260 AC_ARG_WITH(normal,
 261         [  --with-normal           generate normal-libraries (default)],
 262         [with_normal=$withval],
 263         [with_normal=yes])
 264 AC_MSG_RESULT($with_normal)
 265 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 266
 267 AC_MSG_CHECKING(if you want to build debug libraries)
 268 AC_ARG_WITH(debug,
 269         [  --with-debug            generate debug-libraries (default)],
 270         [with_debug=$withval],
 271         [with_debug=yes])
 272 AC_MSG_RESULT($with_debug)
 273 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 274
 275 AC_MSG_CHECKING(if you want to build profiling libraries)
 276 AC_ARG_WITH(profile,
 277         [  --with-profile          generate profile-libraries],
 278         [with_profile=$withval],
 279         [with_profile=no])
 280 AC_MSG_RESULT($with_profile)
 281 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 282
 283 fi
 284
 285 ###############################################################################
 286
 287 AC_MSG_CHECKING(for specified models)
 288 test -z "$cf_list_models" && cf_list_models=normal
 289 dnl If we use libtool to generate libraries, then it must be the only
 290 dnl specified model.
 291 test "$with_libtool" != "no" && cf_list_models=libtool
 292 AC_MSG_RESULT($cf_list_models)
 293
 294 ### Use the first model as the default, and save its suffix for use in building
 295 ### up test-applications.
 296 AC_MSG_CHECKING(for default model)
 297 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 298 AC_MSG_RESULT($DFT_LWR_MODEL)
 299
 300 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 301
 302 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 303 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 304
 305 TICS_NAME=tic
 306 AC_SUBST(TICS_NAME)
 307
 308 TINFO_NAME=tinfo
 309 AC_SUBST(TINFO_NAME)
 310
 311 LIB_NAME=ncurses
 312 AC_SUBST(LIB_NAME)
 313
 314 LIB_DIR=../lib
 315 LIB_2ND=../../lib
 316
 317 CF_LIB_PREFIX(cf_prefix)
 318 LIB_PREFIX=$cf_prefix
 319 AC_SUBST(LIB_PREFIX)
 320
 321 LIB_SUFFIX=
 322 AC_SUBST(LIB_SUFFIX)
 323
 324 ###############################################################################
 325
 326 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 327 AC_ARG_WITH(termlib,
 328         [  --with-termlib          generate separate terminfo library],
 329         [with_termlib=$withval],
 330         [with_termlib=no])
 331 AC_MSG_RESULT($with_termlib)
 332
 333 AC_MSG_CHECKING(if you want to build a separate tic library)
 334 AC_ARG_WITH(ticlib,
 335         [  --with-ticlib           generate separate tic library],
 336         [with_ticlib=$withval],
 337         [with_ticlib=no])
 338 AC_MSG_RESULT($with_ticlib)
 339
 340 ### Checks for special libraries, must be done up-front.
 341 SHLIB_LIST=""
 342 CF_WITH_GPM
 343 if test "$with_gpm" != no ; then
 344         AC_MSG_CHECKING(if you want to load GPM dynamically)
 345         AC_ARG_WITH(dlsym,
 346                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 347                 [with_dlsym=$withval],
 348                 [with_dlsym=yes])
 349         AC_MSG_RESULT($with_dlsym)
 350         if test "$with_dlsym" = yes ; then
 351                 CF_FUNC_DLSYM
 352                 if test "$with_gpm" != yes ; then
 353                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 354                         cf_cv_gpm_soname="$with_gpm"
 355                 else
 356                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 357                 fi
 358                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 359                 SHLIB_LIST="-ldl $SHLIB_LIST"
 360         else
 361                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 362         fi
 363         AC_DEFINE(HAVE_LIBGPM)
 364         CF_CHECK_GPM_WGETCH
 365 fi
 366
 367 CF_WITH_SYSMOUSE
 368
 369 dnl Not all ports of gcc support the -g option
 370
 371 if test X"$CC_G_OPT" = X"" ; then
 372         CC_G_OPT='-g'
 373         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 374 fi
 375 AC_SUBST(CC_G_OPT)
 376
 377 if test X"$CXX_G_OPT" = X"" ; then
 378         CXX_G_OPT='-g'
 379         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 380 fi
 381 AC_SUBST(CXX_G_OPT)
 382
 383 AC_MSG_CHECKING(for default loader flags)
 384 case $DFT_LWR_MODEL in
 385 libtool) LD_MODEL=''   ;;
 386 normal)  LD_MODEL=''   ;;
 387 debug)   LD_MODEL=$CC_G_OPT ;;
 388 profile) LD_MODEL='-pg';;
 389 shared)  LD_MODEL=''   ;;
 390 esac
 391 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 392 AC_MSG_RESULT($LD_MODEL)
 393
 394 case $DFT_LWR_MODEL in
 395 shared)
 396 CF_ENABLE_RPATH
 397 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 398 AC_ARG_ENABLE(relink,
 399 [  --disable-relink        relink shared libraries during install],
 400 [cf_cv_do_relink=$enableval],
 401 [cf_cv_do_relink=yes])
 402 AC_MSG_RESULT($cf_cv_do_relink)
 403         ;;
 404 esac
 405
 406 CF_SHARED_OPTS
 407 if test "$CC_SHARED_OPTS" = "unknown"; then
 408         for model in $cf_list_models; do
 409                 if test "$model" = "shared"; then
 410                         AC_ERROR(Shared libraries are not supported in this version)
 411                 fi
 412         done
 413 fi
 414
 415 ###############################################################################
 416 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 417
 418 ###     use option --disable-overwrite to leave out the link to -lcurses
 419 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 420 AC_ARG_ENABLE(overwrite,
 421         [  --disable-overwrite     leave out the link to -lcurses],
 422         [with_overwrite=$enableval],
 423         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 424 AC_MSG_RESULT($with_overwrite)
 425
 426 AC_MSG_CHECKING(if external terminfo-database is used)
 427 AC_ARG_ENABLE(database,
 428         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 429         [use_database=$enableval],
 430         [use_database=yes])
 431 AC_MSG_RESULT($use_database)
 432
 433 case $host_os in #(vi
 434 os2*) #(vi
 435         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 436         ;;
 437 *) #(vi
 438         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 439         ;;
 440 esac
 441 AC_SUBST(TERMINFO_SRC)
 442
 443 CF_PATHSEP
 444 if test "$use_database" != no ; then
 445         AC_DEFINE(USE_DATABASE)
 446
 447         AC_MSG_CHECKING(which terminfo source-file will be installed)
 448         AC_ARG_WITH(database,
 449                 [  --with-database=XXX     specify terminfo source to install],
 450                 [TERMINFO_SRC=$withval])
 451         AC_MSG_RESULT($TERMINFO_SRC)
 452
 453         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 454         AC_ARG_WITH(hashed-db,
 455                 [  --with-hashed-db        specify hashed-database library],,
 456                 [with_hashed_db=no])
 457         AC_MSG_RESULT($with_hashed_db)
 458 else
 459         with_hashed_db=no
 460 fi
 461
 462 AC_MSG_CHECKING(for list of fallback descriptions)
 463 AC_ARG_WITH(fallbacks,
 464         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 465         [with_fallback=$withval],
 466         [with_fallback=])
 467 AC_MSG_RESULT($with_fallback)
 468 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 469 AC_SUBST(FALLBACK_LIST)
 470
 471 AC_MSG_CHECKING(if you want modern xterm or antique)
 472 AC_ARG_WITH(xterm-new,
 473         [  --without-xterm-new     specify if xterm terminfo should be old version],
 474         [with_xterm_new=$withval],
 475         [with_xterm_new=yes])
 476 case $with_xterm_new in
 477 no)     with_xterm_new=xterm-old;;
 478 *)      with_xterm_new=xterm-new;;
 479 esac
 480 AC_MSG_RESULT($with_xterm_new)
 481 WHICH_XTERM=$with_xterm_new
 482 AC_SUBST(WHICH_XTERM)
 483
 484 MAKE_TERMINFO=
 485 if test "$use_database" = no ; then
 486         TERMINFO="${datadir}/terminfo"
 487         MAKE_TERMINFO="#"
 488 else
 489
 490 AC_MSG_CHECKING(for list of terminfo directories)
 491 CF_WITH_PATHLIST(terminfo-dirs,
 492         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 493         TERMINFO_DIRS,
 494         DATADIR/terminfo,
 495         ${datadir}/terminfo)
 496 AC_MSG_RESULT($TERMINFO_DIRS)
 497 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 498
 499 AC_MSG_CHECKING(for default terminfo directory)
 500 CF_WITH_PATH(default-terminfo-dir,
 501         [  --with-default-terminfo-dir=DIR default terminfo directory],
 502         TERMINFO,
 503         DATADIR/terminfo,
 504         ${datadir}/terminfo)
 505 AC_MSG_RESULT($TERMINFO)
 506 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 507
 508 fi
 509
 510 AC_SUBST(TERMINFO)
 511 AC_SUBST(MAKE_TERMINFO)
 512
 513 ###     use option --disable-big-core to make tic run on small machines
 514 ###     We need 4Mb, check if we can allocate 50% more than that.
 515 AC_MSG_CHECKING(if big-core option selected)
 516 AC_ARG_ENABLE(big-core,
 517         [  --disable-big-core      assume machine has little memory],
 518         [with_big_core=$enableval],
 519         [AC_TRY_RUN([
 520 #include <stdlib.h>
 521 #include <string.h>
 522 int main() {
 523         unsigned long n = 6000000L;
 524         char *s = malloc(n);
 525         if (s != 0)
 526                 s[0] = s[n-1] = 0;
 527         ${cf_cv_main_return:-return}(s == 0);
 528 }],
 529         [with_big_core=yes],
 530         [with_big_core=no],
 531         [with_big_core=no])])
 532 AC_MSG_RESULT($with_big_core)
 533 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 534
 535 ### ISO C only guarantees 512-char strings, we have tables which load faster
 536 ### when constructed using "big" strings.  More than the C compiler, the awk
 537 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 538 AC_MSG_CHECKING(if big-strings option selected)
 539 AC_ARG_ENABLE(big-strings,
 540         [  --disable-big-strings   assume compiler has only standard-size strings],
 541         [with_big_strings=$enableval],
 542         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 543 AC_MSG_RESULT($with_big_strings)
 544
 545 USE_BIG_STRINGS=0
 546 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
 547 AC_SUBST(USE_BIG_STRINGS)
 548
 549 ###     use option --enable-termcap to compile in the termcap fallback support
 550 AC_MSG_CHECKING(if you want termcap-fallback support)
 551 AC_ARG_ENABLE(termcap,
 552         [  --enable-termcap        compile in termcap fallback support],
 553         [with_termcap=$enableval],
 554         [with_termcap=no])
 555 AC_MSG_RESULT($with_termcap)
 556
 557 if test "$with_termcap" != "yes" ; then
 558         if test "$use_database" = no ; then
 559                 if test -z "$with_fallback" ; then
 560                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 561                 fi
 562         fi
 563         AC_DEFINE(PURE_TERMINFO)
 564 else
 565
 566 if test "$with_ticlib" != no ; then
 567         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 568 fi
 569
 570 AC_DEFINE(USE_TERMCAP)
 571 AC_MSG_CHECKING(for list of termcap files)
 572 CF_WITH_PATHLIST(termpath,
 573         [  --with-termpath=XXX     specify list of termcap files],
 574         TERMPATH,
 575         /etc/termcap:/usr/share/misc/termcap)
 576 AC_MSG_RESULT($TERMPATH)
 577 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 578
 579 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 580 AC_MSG_CHECKING(if fast termcap-loader is needed)
 581 AC_ARG_ENABLE(getcap,
 582         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 583         [with_getcap=$enableval],
 584         [with_getcap=no])
 585 AC_MSG_RESULT($with_getcap)
 586 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 587
 588 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 589 AC_ARG_ENABLE(getcap-cache,
 590         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 591         [with_getcap_cache=$enableval],
 592         [with_getcap_cache=no])
 593 AC_MSG_RESULT($with_getcap_cache)
 594 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 595
 596 fi
 597
 598 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 599 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 600 AC_ARG_ENABLE(home-terminfo,
 601         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 602         [with_home_terminfo=$enableval],
 603         [with_home_terminfo=yes])
 604 AC_MSG_RESULT($with_home_terminfo)
 605 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 606
 607 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 608 AC_ARG_ENABLE(root-environ,
 609         [  --disable-root-environ  restrict environment when running as root],
 610         [with_root_environ=$enableval],
 611         [with_root_environ=yes])
 612 AC_MSG_RESULT($with_root_environ)
 613 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 614
 615 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 616 ###   to reduce storage requirements for the terminfo database.
 617 CF_LINK_FUNCS
 618
 619 with_links=no
 620 with_symlinks=no
 621
 622 # soft links (symbolic links) are useful for some systems where hard links do
 623 # not work, or to make it simpler to copy terminfo trees around.
 624 if test "$ac_cv_func_symlink" = yes ; then
 625     AC_MSG_CHECKING(if tic should use symbolic links)
 626     AC_ARG_ENABLE(symlinks,
 627         [  --enable-symlinks       make tic use symbolic links not hard links],
 628         [with_symlinks=$enableval],
 629         [with_symlinks=no])
 630     AC_MSG_RESULT($with_symlinks)
 631 fi
 632
 633 # If we have hard links and did not choose to use soft links instead, there is
 634 # no reason to make this choice optional - use the hard links.
 635 if test "$with_symlinks" = no ; then
 636     AC_MSG_CHECKING(if tic should use hard links)
 637     if test "$ac_cv_func_link" = yes ; then
 638         with_links=yes
 639     else
 640         with_links=no
 641     fi
 642     AC_MSG_RESULT($with_links)
 643 fi
 644
 645 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 646 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 647
 648 ###   use option --enable-broken-linker to force on use of broken-linker support
 649 AC_MSG_CHECKING(if you want broken-linker support code)
 650 AC_ARG_ENABLE(broken_linker,
 651         [  --enable-broken_linker  compile with broken-linker support code],
 652         [with_broken_linker=$enableval],
 653         [with_broken_linker=${BROKEN_LINKER-no}])
 654 AC_MSG_RESULT($with_broken_linker)
 655
 656 BROKEN_LINKER=0
 657 if test "$with_broken_linker" = yes ; then
 658         AC_DEFINE(BROKEN_LINKER)
 659         BROKEN_LINKER=1
 660 elif test "$DFT_LWR_MODEL" = shared ; then
 661         case $cf_cv_system_name in #(vi
 662         cygwin*)
 663                 AC_DEFINE(BROKEN_LINKER)
 664                 BROKEN_LINKER=1
 665                 CF_VERBOSE(cygwin linker is broken anyway)
 666                 ;;
 667         esac
 668 fi
 669 AC_SUBST(BROKEN_LINKER)
 670
 671 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 672 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 673 AC_ARG_ENABLE(bsdpad,
 674         [  --enable-bsdpad         recognize BSD-style prefix padding],
 675         [with_bsdpad=$enableval],
 676         [with_bsdpad=no])
 677 AC_MSG_RESULT($with_bsdpad)
 678 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 679
 680 ###   use option --enable-widec to turn on use of wide-character support
 681 NCURSES_CH_T=chtype
 682 NCURSES_LIBUTF8=0
 683
 684 NEED_WCHAR_H=0
 685 NCURSES_MBSTATE_T=0
 686 NCURSES_WCHAR_T=0
 687 NCURSES_WINT_T=0
 688
 689 # Check to define _XOPEN_SOURCE "automatically"
 690 CF_XOPEN_SOURCE
 691
 692 # Work around breakage on OS X
 693 CF_SIGWINCH
 694
 695 # Checks for CODESET support.
 696 AM_LANGINFO_CODESET
 697
 698 # use these variables to work around a defect in gcc's fixincludes.
 699 NCURSES_OK_WCHAR_T=
 700 NCURSES_OK_WINT_T=
 701
 702 AC_MSG_CHECKING(if you want wide-character code)
 703 AC_ARG_ENABLE(widec,
 704         [  --enable-widec          compile with wide-char/UTF-8 code],
 705         [with_widec=$enableval],
 706         [with_widec=no])
 707 AC_MSG_RESULT($with_widec)
 708 if test "$with_widec" = yes ; then
 709         LIB_SUFFIX="w${LIB_SUFFIX}"
 710         AC_DEFINE(USE_WIDEC_SUPPORT)
 711         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 712         # with_overwrite=no
 713         NCURSES_CH_T=cchar_t
 714         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 715         if test "$ac_cv_func_putwc" != yes ; then
 716                 CF_UTF8_LIB
 717                 if test "$cf_cv_utf8_lib" != no ; then
 718                         NCURSES_LIBUTF8=1
 719                 fi
 720         fi
 721         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 722         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 723         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 724
 725         if test "$NCURSES_MBSTATE_T" != 0; then
 726                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 727         fi
 728 fi
 729 AC_SUBST(NCURSES_CH_T)
 730 AC_SUBST(NCURSES_LIBUTF8)
 731
 732 AC_SUBST(NEED_WCHAR_H)
 733 AC_SUBST(NCURSES_MBSTATE_T)
 734 AC_SUBST(NCURSES_WCHAR_T)
 735 AC_SUBST(NCURSES_WINT_T)
 736
 737 AC_SUBST(NCURSES_OK_WCHAR_T)
 738 AC_SUBST(NCURSES_OK_WINT_T)
 739
 740 ###   use option --disable-lp64 to allow long chtype
 741 case $cf_cv_abi_version in
 742 [[345]]*)
 743         default_with_lp64=no
 744         ;;
 745 *)
 746         default_with_lp64=yes
 747         ;;
 748 esac
 749
 750 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 751 AC_ARG_ENABLE(lp64,
 752         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 753         [with_lp64=$enableval],
 754         [with_lp64=$default_with_lp64])
 755 AC_MSG_RESULT($with_lp64)
 756
 757 if test "$with_lp64" = yes ; then
 758         cf_cv_enable_lp64=1
 759 else
 760         cf_cv_enable_lp64=0
 761 fi
 762 AC_SUBST(cf_cv_enable_lp64)
 763
 764 CF_LARGEFILE
 765
 766 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 767 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 768 AC_ARG_ENABLE(tparm-varargs,
 769         [  --disable-tparm-varargs compile tparm() without varargs interface],
 770         [with_tparm_varargs=$enableval],
 771         [with_tparm_varargs=yes])
 772 AC_MSG_RESULT($with_tparm_varargs)
 773 NCURSES_TPARM_VARARGS=0
 774 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 775 AC_SUBST(NCURSES_TPARM_VARARGS)
 776
 777 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 778 if test "$with_ticlib" != no ; then
 779 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 780 AC_ARG_ENABLE(tic-depends,
 781         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 782         [with_tic_depends=$enableval],
 783         [with_tic_depends=yes])
 784 AC_MSG_RESULT($with_tic_depends)
 785 else
 786         with_tic_depends=no
 787 fi
 788
 789 ###   use option --with-bool to override bool's type
 790 AC_MSG_CHECKING(for type of bool)
 791 AC_ARG_WITH(bool,
 792         [  --with-bool=TYPE        override fallback type of bool variable],
 793         [NCURSES_BOOL="$withval"],
 794         [NCURSES_BOOL=auto])
 795 AC_MSG_RESULT($NCURSES_BOOL)
 796 AC_SUBST(NCURSES_BOOL)
 797
 798 AC_MSG_CHECKING(for alternate terminal capabilities file)
 799 AC_ARG_WITH(caps,
 800         [  --with-caps=alt         compile with alternate Caps file],
 801         [TERMINFO_CAPS=Caps.$withval],
 802         [TERMINFO_CAPS=Caps])
 803 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 804 AC_MSG_RESULT($TERMINFO_CAPS)
 805 AC_SUBST(TERMINFO_CAPS)
 806
 807 ###   use option --with-chtype to override chtype's type
 808 AC_MSG_CHECKING(for type of chtype)
 809 AC_ARG_WITH(chtype,
 810         [  --with-chtype=TYPE      override type of chtype],
 811         [NCURSES_CHTYPE="$withval"],
 812         [NCURSES_CHTYPE=auto])
 813 AC_MSG_RESULT($NCURSES_CHTYPE)
 814
 815 ###   use option --with-ospeed to override ospeed's type
 816 AC_MSG_CHECKING(for type of ospeed)
 817 AC_ARG_WITH(ospeed,
 818         [  --with-ospeed=TYPE      override type of ospeed variable],
 819         [NCURSES_OSPEED="$withval"],
 820         [NCURSES_OSPEED=short])
 821 AC_MSG_RESULT($NCURSES_OSPEED)
 822 AC_SUBST(NCURSES_OSPEED)
 823
 824 ###   use option --with-mmask-t to override mmask_t's type
 825 AC_MSG_CHECKING(for type of mmask_t)
 826 AC_ARG_WITH(mmask-t,
 827         [  --with-mmask-t=TYPE     override type of mmask_t],
 828         [NCURSES_MMASK_T="$withval"],
 829         [NCURSES_MMASK_T=auto])
 830 AC_MSG_RESULT($NCURSES_MMASK_T)
 831
 832 ###   use option --with-ccharw-max to override CCHARW_MAX size
 833 AC_MSG_CHECKING(for size CCHARW_MAX)
 834 AC_ARG_WITH(ccharw-max,
 835         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
 836         [NCURSES_CCHARW_MAX="$withval"],
 837         [NCURSES_CCHARW_MAX=5])
 838 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
 839 AC_SUBST(NCURSES_CCHARW_MAX)
 840
 841 ### Enable compiling-in rcs id's
 842 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 843 AC_ARG_WITH(rcs-ids,
 844         [  --with-rcs-ids          compile-in RCS identifiers],
 845         [with_rcs_ids=$withval],
 846         [with_rcs_ids=no])
 847 AC_MSG_RESULT($with_rcs_ids)
 848 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 849
 850 ###############################################################################
 851 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
 852
 853 ###############################################################################
 854 CF_HELP_MESSAGE(Extensions:)
 855
 856 ### Note that some functions (such as const) are normally disabled anyway.
 857 AC_MSG_CHECKING(if you want to build with function extensions)
 858 AC_ARG_ENABLE(ext-funcs,
 859         [  --disable-ext-funcs     disable function-extensions],
 860         [with_ext_funcs=$enableval],
 861         [with_ext_funcs=yes])
 862 AC_MSG_RESULT($with_ext_funcs)
 863 if test "$with_ext_funcs" = yes ; then
 864         NCURSES_EXT_FUNCS=1
 865         AC_DEFINE(HAVE_CURSES_VERSION)
 866         AC_DEFINE(HAVE_HAS_KEY)
 867         AC_DEFINE(HAVE_RESIZETERM)
 868         AC_DEFINE(HAVE_RESIZE_TERM)
 869         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 870         AC_DEFINE(HAVE_WRESIZE)
 871         AC_DEFINE(NCURSES_EXT_FUNCS)
 872         GENERATED_EXT_FUNCS=generated
 873 else
 874         NCURSES_EXT_FUNCS=0
 875         GENERATED_EXT_FUNCS=
 876 fi
 877 AC_SUBST(NCURSES_EXT_FUNCS)
 878 AC_SUBST(GENERATED_EXT_FUNCS)
 879
 880 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
 881 AC_ARG_ENABLE(sp-funcs,
 882         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
 883         [with_sp_funcs=$enableval],
 884         [with_sp_funcs=no])
 885 AC_MSG_RESULT($with_sp_funcs)
 886 if test "$with_sp_funcs" = yes ; then
 887         NCURSES_SP_FUNCS=1
 888         AC_DEFINE(NCURSES_SP_FUNCS)
 889         GENERATED_SP_FUNCS=generated
 890 else
 891         NCURSES_SP_FUNCS=0
 892         GENERATED_SP_FUNCS=
 893 fi
 894 AC_SUBST(NCURSES_SP_FUNCS)
 895 AC_SUBST(GENERATED_SP_FUNCS)
 896
 897 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
 898 AC_ARG_ENABLE(term-driver,
 899         [  --enable-term-driver    enable experimental terminal-driver],
 900         [with_term_driver=$enableval],
 901         [with_term_driver=no])
 902 AC_MSG_RESULT($with_term_driver)
 903 if test "$with_term_driver" = yes ; then
 904         AC_DEFINE(USE_TERM_DRIVER)
 905         if test "$with_sp_funcs" != yes ; then
 906                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
 907         fi
 908 fi
 909
 910 ###   use option --enable-const to turn on use of const beyond that in XSI.
 911 AC_MSG_CHECKING(for extended use of const keyword)
 912 AC_ARG_ENABLE(const,
 913         [  --enable-const          compile with extra/non-standard const],
 914         [with_ext_const=$enableval],
 915         [with_ext_const=no])
 916 AC_MSG_RESULT($with_ext_const)
 917 NCURSES_CONST='/*nothing*/'
 918 if test "$with_ext_const" = yes ; then
 919         NCURSES_CONST=const
 920 fi
 921 AC_SUBST(NCURSES_CONST)
 922
 923 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 924 AC_MSG_CHECKING(if you want to use extended colors)
 925 AC_ARG_ENABLE(ext-colors,
 926         [  --enable-ext-colors     compile for 256-color support],
 927         [with_ext_colors=$enableval],
 928         [with_ext_colors=no])
 929 AC_MSG_RESULT($with_ext_colors)
 930 NCURSES_EXT_COLORS=0
 931 if test "$with_ext_colors" = yes ; then
 932         if test "$with_widec" != yes ; then
 933                 AC_MSG_ERROR(This option applies only to wide-character library)
 934         else
 935                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 936                 CF_NCURSES_ABI_6
 937         fi
 938         NCURSES_EXT_COLORS=1
 939         AC_DEFINE(NCURSES_EXT_COLORS)
 940 fi
 941 AC_SUBST(NCURSES_EXT_COLORS)
 942
 943 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 944 AC_MSG_CHECKING(if you want to use extended mouse encoding)
 945 AC_ARG_ENABLE(ext-mouse,
 946         [  --enable-ext-mouse      compile for extended mouse-encoding],
 947         [with_ext_mouse=$enableval],
 948         [with_ext_mouse=no])
 949 AC_MSG_RESULT($with_ext_mouse)
 950 NCURSES_MOUSE_VERSION=1
 951 if test "$with_ext_mouse" = yes ; then
 952         NCURSES_MOUSE_VERSION=2
 953         CF_NCURSES_ABI_6
 954 fi
 955 AC_SUBST(NCURSES_MOUSE_VERSION)
 956
 957 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 958 AC_ARG_ENABLE(no-padding,
 959         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 960         [with_no_padding=$enableval],
 961         [with_no_padding=$with_ext_funcs])
 962 AC_MSG_RESULT($with_no_padding)
 963 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 964
 965 AC_CHECK_SIZEOF([signed char], 0)
 966 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 967         NCURSES_SBOOL="signed char"
 968 else
 969         NCURSES_SBOOL="char"
 970 fi
 971 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 972 AC_ARG_ENABLE(signed-char,
 973         [  --enable-signed-char    compile using signed Boolean's in term.h],
 974         [with_signed_char=$enableval],
 975         [with_signed_char=no])
 976 AC_MSG_RESULT($with_signed_char)
 977 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
 978 AC_SUBST(NCURSES_SBOOL)
 979
 980 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
 981 AC_MSG_CHECKING(if you want SIGWINCH handler)
 982 AC_ARG_ENABLE(sigwinch,
 983         [  --enable-sigwinch       compile with SIGWINCH handler],
 984         [with_sigwinch=$enableval],
 985         [with_sigwinch=$with_ext_funcs])
 986 AC_MSG_RESULT($with_sigwinch)
 987 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
 988
 989 ###   use option --enable-tcap-names to allow user to define new capabilities
 990 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
 991 AC_ARG_ENABLE(tcap-names,
 992         [  --enable-tcap-names     compile with user-definable terminal capabilities],
 993         [with_tcap_names=$enableval],
 994         [with_tcap_names=$with_ext_funcs])
 995 AC_MSG_RESULT($with_tcap_names)
 996 NCURSES_XNAMES=0
 997 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
 998 AC_SUBST(NCURSES_XNAMES)
 999
1000 ###############################################################################
1001 # These options are relatively safe to experiment with.
1002 CF_HELP_MESSAGE(Development Code:)
1003 AC_MSG_CHECKING(if you want all development code)
1004 AC_ARG_WITH(develop,
1005         [  --without-develop       disable development options],
1006         [with_develop=$withval],
1007         [with_develop=no])
1008 AC_MSG_RESULT($with_develop)
1009
1010 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1011 AC_MSG_CHECKING(if you want hard-tabs code)
1012 AC_ARG_ENABLE(hard-tabs,
1013         [  --enable-hard-tabs      compile with hard-tabs code],,
1014         [enable_hard_tabs=$with_develop])
1015 AC_MSG_RESULT($enable_hard_tabs)
1016 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
1017
1018 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1019 AC_MSG_CHECKING(if you want limited support for xmc)
1020 AC_ARG_ENABLE(xmc-glitch,
1021         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1022         [enable_xmc_glitch=$with_develop])
1023 AC_MSG_RESULT($enable_xmc_glitch)
1024 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
1025
1026 ###############################################################################
1027 # These are just experimental, probably should not be in a package:
1028 CF_HELP_MESSAGE(Experimental Code:)
1029
1030 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1031 AC_ARG_ENABLE(assumed-color,
1032         [  --disable-assumed-color do not assume anything about default-colors],
1033         [with_assumed_color=$enableval],
1034         [with_assumed_color=yes])
1035 AC_MSG_RESULT($with_assumed_color)
1036 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
1037
1038 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1039 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1040 AC_ARG_ENABLE(hashmap,
1041         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1042         [with_hashmap=$enableval],
1043         [with_hashmap=yes])
1044 AC_MSG_RESULT($with_hashmap)
1045 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1046
1047 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1048 AC_MSG_CHECKING(if you want colorfgbg code)
1049 AC_ARG_ENABLE(colorfgbg,
1050         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1051         [with_colorfgbg=$enableval],
1052         [with_colorfgbg=no])
1053 AC_MSG_RESULT($with_colorfgbg)
1054 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1055
1056 ###   use option --enable-interop to turn on use of bindings used for interop
1057 AC_MSG_CHECKING(if you want interop bindings)
1058 AC_ARG_ENABLE(interop,
1059         [  --enable-interop        compile-in experimental interop bindings],
1060         [with_exp_interop=$enableval],
1061         [with_exp_interop=no])
1062 AC_MSG_RESULT($with_exp_interop)
1063
1064 NCURSES_INTEROP_FUNCS=0
1065 test "$with_exp_interop" = yes && NCURSES_INTEROP_FUNCS=1
1066 AC_SUBST(NCURSES_INTEROP_FUNCS)
1067
1068 # This is still experimental (20080329), but should ultimately be moved to
1069 # the script-block --with-normal, etc.
1070 CF_WITH_PTHREAD
1071
1072 AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1073 AC_ARG_ENABLE(weak-symbols,
1074     [  --enable-weak-symbols   enable weak-symbols for pthreads],
1075     [use_weak_symbols=$withval],
1076     [use_weak_symbols=no])
1077 AC_MSG_RESULT($use_weak_symbols)
1078 if test "$use_weak_symbols" = yes ; then
1079     CF_WEAK_SYMBOLS
1080 else
1081     cf_cv_weak_symbols=no
1082 fi
1083
1084 if test $cf_cv_weak_symbols = yes ; then
1085     AC_DEFINE(USE_WEAK_SYMBOLS)
1086 fi
1087
1088 PTHREAD=
1089 if test "$with_pthread" = "yes" ; then
1090     AC_DEFINE(USE_PTHREADS)
1091     enable_reentrant=yes
1092     if test $cf_cv_weak_symbols = yes ; then
1093         PTHREAD=-lpthread
1094     fi
1095 fi
1096 AC_SUBST(PTHREAD)
1097
1098 # Reentrant code has to be opaque; there's little advantage to making ncurses
1099 # opaque outside of that, so there is no --enable-opaque option.  We can use
1100 # this option without --with-pthreads, but this will be always set for
1101 # pthreads.
1102 AC_MSG_CHECKING(if you want experimental reentrant code)
1103 AC_ARG_ENABLE(reentrant,
1104         [  --enable-reentrant      compile with experimental reentrant code],
1105         [with_reentrant=$enableval],
1106         [with_reentrant=no])
1107 AC_MSG_RESULT($with_reentrant)
1108 if test "$with_reentrant" = yes ; then
1109         cf_cv_enable_reentrant=1
1110         cf_cv_enable_opaque="NCURSES_INTERNALS"
1111         NCURSES_OPAQUE=1
1112         NCURSES_SIZE_T=int
1113         if test $cf_cv_weak_symbols = yes ; then
1114                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1115         else
1116                 LIB_SUFFIX="t${LIB_SUFFIX}"
1117         fi
1118         AC_DEFINE(USE_REENTRANT)
1119         CF_NCURSES_ABI_6
1120 else
1121         cf_cv_enable_reentrant=0
1122         cf_cv_enable_opaque="NCURSES_OPAQUE"
1123         NCURSES_OPAQUE=0
1124         NCURSES_SIZE_T=short
1125 fi
1126 AC_SUBST(cf_cv_enable_reentrant)
1127 AC_SUBST(cf_cv_enable_opaque)
1128 AC_SUBST(NCURSES_OPAQUE)
1129 AC_SUBST(NCURSES_SIZE_T)
1130
1131 ### Allow using a different wrap-prefix
1132 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1133         AC_MSG_CHECKING(for prefix used to wrap public variables)
1134         AC_ARG_WITH(wrap-prefix,
1135                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1136                 [NCURSES_WRAP_PREFIX=$withval],
1137                 [NCURSES_WRAP_PREFIX=_nc_])
1138         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1139 else
1140         NCURSES_WRAP_PREFIX=_nc_
1141 fi
1142 AC_SUBST(NCURSES_WRAP_PREFIX)
1143 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX")
1144
1145 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1146 AC_ARG_ENABLE(safe-sprintf,
1147         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1148         [with_safe_sprintf=$enableval],
1149         [with_safe_sprintf=no])
1150 AC_MSG_RESULT($with_safe_sprintf)
1151 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1152
1153 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1154 # when hashmap is used scroll hints are useless
1155 if test "$with_hashmap" = no ; then
1156 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1157 AC_ARG_ENABLE(scroll-hints,
1158         [  --disable-scroll-hints  compile without scroll-hints code],
1159         [with_scroll_hints=$enableval],
1160         [with_scroll_hints=yes])
1161 AC_MSG_RESULT($with_scroll_hints)
1162 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1163 fi
1164
1165 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1166 AC_ARG_ENABLE(wgetch-events,
1167         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1168         [with_wgetch_events=$enableval],
1169         [with_wgetch_events=no])
1170 AC_MSG_RESULT($with_wgetch_events)
1171 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1172
1173 ###############################################################################
1174 CF_HELP_MESSAGE(Testing/development Options:)
1175
1176 ###     use option --disable-echo to suppress full display compiling commands
1177 AC_MSG_CHECKING(if you want to display full commands during build)
1178 AC_ARG_ENABLE(echo,
1179         [  --enable-echo           build: display "compiling" commands (default)],
1180         [with_echo=$enableval],
1181         [with_echo=yes])
1182 if test "$with_echo" = yes; then
1183         ECHO_LINK=
1184 else
1185         ECHO_LINK='@ echo linking $@ ... ;'
1186         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1187         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1188 fi
1189 AC_MSG_RESULT($with_echo)
1190 AC_SUBST(ECHO_LINK)
1191
1192 ###     use option --enable-warnings to turn on all gcc warnings
1193 AC_MSG_CHECKING(if you want to see compiler warnings)
1194 AC_ARG_ENABLE(warnings,
1195         [  --enable-warnings       build: turn on GCC compiler warnings],
1196         [with_warnings=$enableval])
1197 AC_MSG_RESULT($with_warnings)
1198
1199 if test "x$with_warnings" = "xyes"; then
1200         ADAFLAGS="$ADAFLAGS -gnatg"
1201         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1202         if test "$cf_with_cxx" = yes ; then
1203                 CF_GXX_WARNINGS(Wno-unused)
1204         fi
1205 fi
1206 CF_GCC_ATTRIBUTES
1207
1208 ###     use option --enable-assertions to turn on generation of assertion code
1209 AC_MSG_CHECKING(if you want to enable runtime assertions)
1210 AC_ARG_ENABLE(assertions,
1211         [  --enable-assertions     test: turn on generation of assertion code],
1212         [with_assertions=$enableval],
1213         [with_assertions=no])
1214 AC_MSG_RESULT($with_assertions)
1215 if test -n "$GCC"
1216 then
1217         if test "$with_assertions" = no
1218         then
1219                 AC_DEFINE(NDEBUG)
1220                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1221         else
1222                 ADAFLAGS="$ADAFLAGS -gnata"
1223         fi
1224 fi
1225
1226 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1227 CF_DISABLE_LEAKS
1228 AC_DEFINE(HAVE_NC_ALLOC_H)
1229
1230 ###     use option --enable-expanded to generate certain macros as functions
1231 AC_ARG_ENABLE(expanded,
1232         [  --enable-expanded       test: generate functions for certain macros],
1233         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1234
1235 ###     use option --disable-macros to suppress macros in favor of functions
1236 AC_ARG_ENABLE(macros,
1237         [  --disable-macros        test: use functions rather than macros],
1238         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1239
1240 # Normally we only add trace() to the debug-library.  Allow this to be
1241 # extended to all models of the ncurses library:
1242 cf_all_traces=no
1243 case "$CFLAGS $CPPFLAGS" in
1244 *-DTRACE*)
1245         cf_all_traces=yes
1246         ;;
1247 esac
1248
1249 AC_MSG_CHECKING(whether to add trace feature to all models)
1250 AC_ARG_WITH(trace,
1251 [  --with-trace            test: add trace() function to all models of ncurses],
1252 [cf_with_trace=$withval],
1253 [cf_with_trace=$cf_all_traces])
1254 AC_MSG_RESULT($cf_with_trace)
1255
1256 if test "$cf_with_trace" = yes ; then
1257         LIB_TRACING=all
1258         ADA_TRACE=TRUE
1259         CF_ADD_CFLAGS(-DTRACE)
1260 else
1261         LIB_TRACING=DEBUG
1262         ADA_TRACE=FALSE
1263 fi
1264
1265 AC_SUBST(ADA_TRACE)
1266
1267 ###     Checks for libraries.
1268 case $cf_cv_system_name in #(vi
1269 *mingw32*) #(vi
1270         ;;
1271 *)
1272 AC_CHECK_FUNC(gettimeofday,
1273         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1274
1275 AC_CHECK_LIB(bsd, gettimeofday,
1276         AC_DEFINE(HAVE_GETTIMEOFDAY)
1277         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
1278         ;;
1279 esac
1280
1281 CF_MATH_LIB(MATH_LIB,sin(x))
1282 AC_SUBST(MATH_LIB)
1283
1284 ###     Checks for header files.
1285 AC_STDC_HEADERS
1286 AC_HEADER_DIRENT
1287 AC_HEADER_TIME
1288 CF_REGEX
1289
1290 dnl These are some other potentially nonportable headers.
1291 AC_CHECK_HEADERS( \
1292 fcntl.h \
1293 getopt.h \
1294 limits.h \
1295 locale.h \
1296 poll.h \
1297 sys/bsdtypes.h \
1298 sys/ioctl.h \
1299 sys/param.h \
1300 sys/poll.h \
1301 sys/select.h \
1302 sys/time.h \
1303 sys/times.h \
1304 ttyent.h \
1305 unistd.h \
1306 wctype.h \
1307 )
1308
1309 # check for ISC (this may also define _POSIX_SOURCE)
1310 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1311 if test "$ISC" = yes ; then
1312         AC_CHECK_LIB(cposix,main)
1313         AC_CHECK_LIB(inet,bzero,LIBS="$LIBS -linet")dnl also 'select()'
1314 fi
1315
1316 CF_SYS_TIME_SELECT
1317
1318 ###     checks for compiler characteristics
1319 AC_LANG_C
1320 AC_C_CONST
1321 CF_C_INLINE(NCURSES_INLINE,1200)
1322 CF_SIG_ATOMIC_T
1323
1324 if test $NCURSES_CHTYPE = auto ; then
1325         CF_TYPEOF_CHTYPE
1326 else
1327         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1328 fi
1329 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1330 AC_SUBST(cf_cv_typeof_chtype)
1331
1332 CF_UNSIGNED_LITERALS
1333 cf_cv_1UL="1"
1334 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1335 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1336 AC_SUBST(cf_cv_1UL)
1337
1338 if test $NCURSES_MMASK_T = auto ; then
1339         cf_cv_typeof_mmask_t=long
1340 else
1341         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1342 fi
1343 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1344 AC_SUBST(cf_cv_typeof_mmask_t)
1345
1346 ###     Checks for external-data
1347 CF_ERRNO
1348 CF_LINK_DATAONLY
1349
1350 ###     Checks for library functions.
1351 AC_CHECK_FUNCS( \
1352 getcwd \
1353 getegid \
1354 geteuid \
1355 getttynam \
1356 issetugid \
1357 poll \
1358 remove \
1359 select \
1360 setbuf \
1361 setbuffer \
1362 setvbuf \
1363 sigaction \
1364 sigvec \
1365 strdup \
1366 strstr \
1367 tcgetpgrp \
1368 times \
1369 vsnprintf \
1370 )
1371 if test "$with_getcap" = "yes" ; then
1372         CF_CGETENT
1373 fi
1374
1375 CF_ISASCII
1376 CF_STRUCT_SIGACTION
1377 CF_FUNC_NANOSLEEP
1378 CF_FUNC_TERMIOS
1379 CF_FUNC_VSSCANF
1380 CF_MKSTEMP
1381
1382 # setup for prototype of fallback for vsscanf()
1383 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1384
1385 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1386 if test "$cross_compiling" = yes ; then
1387         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1388 else
1389         AC_FUNC_SETVBUF_REVERSED
1390 fi
1391 AC_TYPE_SIGNAL
1392 CF_TYPE_SIGACTION
1393 CF_SIZECHANGE
1394 CF_FUNC_MEMMOVE
1395 CF_FUNC_POLL
1396
1397 # special check for test/ditto.c
1398 CF_FUNC_OPENPTY
1399 if test "$cf_cv_func_openpty" != no ; then
1400     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1401     AC_DEFINE(USE_XTERM_PTY)
1402     if test "$cf_cv_lib_util" = yes ; then
1403         TEST_LIBS="-lutil $TEST_LIBS"
1404     fi
1405 fi
1406 AC_SUBST(TEST_LIBS)
1407
1408 if test "$with_hashed_db" != no ; then
1409         AC_DEFINE(USE_HASHED_DB)
1410         CF_HASHED_DB($with_hashed_db)
1411 fi
1412
1413 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1414 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1415         CF_STRIP_G_OPT(CFLAGS)
1416         CF_STRIP_G_OPT(CXXFLAGS)
1417 fi
1418
1419 # Just in case, check if the C compiler has a bool type.
1420 CF_BOOL_DECL(cf_cv_cc_bool_type)
1421
1422 # Check for C++ compiler characteristics (and ensure that it's there!)
1423 if test -n "$CXX" ; then
1424         AC_LANG_CPLUSPLUS
1425         CF_STDCPP_LIBRARY
1426         CF_PROG_CC_C_O(CXX)
1427
1428         case $GXX_VERSION in
1429         1*|2.[0-6]*)
1430                 cf_cxx_library=yes
1431                 ;;
1432         *-2.7*|2.7*)
1433                 CF_GPP_LIBRARY
1434                 ;;
1435         *)
1436                 cf_cxx_library=no
1437                 ;;
1438         esac
1439
1440         AC_CHECK_HEADERS(iostream typeinfo)
1441
1442     if test x"$ac_cv_header_iostream" = xyes ; then
1443         AC_MSG_CHECKING(if iostream uses std-namespace)
1444         AC_TRY_COMPILE([
1445 #include <iostream>
1446 using std::endl;
1447 using std::cerr;],[
1448 cerr << "testing" << endl;
1449 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1450         AC_MSG_RESULT($cf_iostream_namespace)
1451         if test "$cf_iostream_namespace" = yes ; then
1452             AC_DEFINE(IOSTREAM_NAMESPACE)
1453         fi
1454     fi
1455
1456         CF_BOOL_DECL
1457         CF_BOOL_SIZE
1458         CF_ETIP_DEFINES
1459         CF_CPP_PARAM_INIT
1460         CF_CPP_STATIC_CAST
1461
1462         CXX_AR='$(AR)'
1463         CXX_ARFLAGS='$(ARFLAGS)'
1464         case $cf_cv_system_name in #(vi
1465         irix*) #(vi
1466             if test "$GXX" != yes ; then
1467                 CXX_AR='$(CXX)'
1468                 CXX_ARFLAGS='-ar -o'
1469             fi
1470             ;;
1471         sco3.2v5*) #(vi
1472             CXXLDFLAGS="-u main"
1473             ;;
1474         solaris2*)
1475             if test "$GXX" != yes ; then
1476                 CXX_AR='$(CXX)'
1477                 CXX_ARFLAGS='-xar -o'
1478             fi
1479             ;;
1480         esac
1481         AC_SUBST(CXXLDFLAGS)
1482         AC_SUBST(CXX_AR)
1483         AC_SUBST(CXX_ARFLAGS)
1484 else
1485         cf_cxx_library=no
1486         cf_cv_builtin_bool=1
1487
1488         # Just because we are not configuring against C++ right now does not
1489         # mean that a user will not want to use C++.  Some distributors disable
1490         # the C++ portion of this configuration as a shortcut (or just to avoid
1491         # compiling the demo in the c++ directory).  So we need a reasonable
1492         # default for the 'bool' type.
1493         #
1494         # Caveat: since the storage of the bool type is not standardized, it
1495         # may change.
1496
1497         if test "$NCURSES_BOOL" != auto ; then
1498                 cf_cv_type_of_bool=$NCURSES_BOOL
1499                 cf_cv_header_stdbool_h=0
1500         else
1501                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1502                         CF_BOOL_SIZE
1503                 else
1504                         AC_MSG_CHECKING(for fallback type of bool)
1505                         case "$host_cpu" in #(vi
1506                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1507                         *)      cf_cv_type_of_bool=int  ;;
1508                         esac
1509                         AC_MSG_RESULT($cf_cv_type_of_bool)
1510                 fi
1511         fi
1512 fi
1513 AC_SUBST(CXXLIBS)
1514
1515 # If the C compiler did not declare bool, and we did not determine that the C++
1516 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1517 # ncurses library use the same type as C++ bool.  Note that this allows one to
1518 # specify the type of bool in a configure-script option and postpone
1519 # integration with the C++ compiler provided that the types are compatible.
1520 USE_CXX_BOOL=1
1521 if test $cf_cv_cc_bool_type = 1
1522 then
1523         # oops: C has a bool.  Unlikely, but C++ could differ.
1524         USE_CXX_BOOL=0
1525 elif test $cf_cv_builtin_bool = 0
1526 then
1527         # C++ has no bool
1528         USE_CXX_BOOL=0
1529 else
1530         # this is the normal case
1531         USE_CXX_BOOL='defined(__cplusplus)'
1532 fi
1533 AC_SUBST(USE_CXX_BOOL)
1534
1535 CF_HELP_MESSAGE(Ada95 Binding Options:)
1536
1537 dnl If the Ada95 source-tree is present, add that to the build unless it will
1538 dnl not work, or was not requested.
1539 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1540
1541 dnl libtool does not know anything about GNAT, though a change made in 1998
1542 dnl provided for it "someday".  Disable the ada subtree if we are using
1543 dnl libtool -TD 20070714
1544 if test "$cf_with_ada" != "no" ; then
1545     if test "$with_libtool" != "no"; then
1546         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1547         cf_with_ada=no
1548     fi
1549 fi
1550
1551 dnl Check for availability of GNU Ada Translator (GNAT).
1552 dnl At the moment we support no other Ada95 compiler.
1553 if test "$cf_with_ada" != "no" ; then
1554 cf_ada_make=gnatmake
1555 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
1556 if test "$ac_cv_prog_gnat_exists" = no; then
1557    cf_ada_make=
1558 else
1559    CF_GNAT_VERSION
1560    AC_CHECK_PROG(M4_exists, m4, yes, no)
1561    if test "$ac_cv_prog_M4_exists" = no; then
1562       cf_cv_prog_gnat_correct=no
1563       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
1564    fi
1565    if test "$cf_cv_prog_gnat_correct" = yes; then
1566       AC_MSG_CHECKING(if GNAT works)
1567       CF_GNAT_TRY_RUN([procedure conftest;],
1568 [with Text_IO;
1569 with GNAT.OS_Lib;
1570 procedure conftest is
1571 begin
1572    Text_IO.Put ("Hello World");
1573    Text_IO.New_Line;
1574    GNAT.OS_Lib.OS_Exit (0);
1575 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
1576       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
1577    fi
1578 fi
1579 if test "$cf_cv_prog_gnat_correct" = yes; then
1580    ADAFLAGS="-O3 -gnatpn $ADAFLAGS"
1581
1582    AC_MSG_CHECKING(if GNAT pragma Unreferenced works)
1583    CF_GNAT_TRY_LINK([procedure conftest;],
1584 [with Text_IO;
1585 with GNAT.OS_Lib;
1586 procedure conftest is
1587    test : Integer;
1588    pragma Unreferenced (test);
1589 begin
1590    test := 1;
1591    Text_IO.Put ("Hello World");
1592    Text_IO.New_Line;
1593    GNAT.OS_Lib.OS_Exit (0);
1594 end conftest;],[cf_cv_pragma_unreferenced=yes],[cf_cv_pragma_unreferenced=no])
1595    AC_MSG_RESULT($cf_cv_pragma_unreferenced)
1596
1597    # if the pragma is supported, use it (needed in the Trace code).
1598    if test $cf_cv_pragma_unreferenced = yes ; then
1599       PRAGMA_UNREF=TRUE
1600    else
1601       PRAGMA_UNREF=FALSE
1602    fi
1603
1604    AC_ARG_WITH(ada-compiler,
1605         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
1606         [cf_ada_compiler=$withval],
1607         [cf_ada_compiler=gnatmake])
1608
1609    cf_ada_package=terminal_interface
1610
1611    AC_SUBST(cf_ada_make)
1612    AC_SUBST(cf_ada_compiler)
1613    AC_SUBST(cf_ada_package)
1614    AC_SUBST(ADAFLAGS)
1615    AC_SUBST(cf_compile_generics)
1616    AC_SUBST(cf_generic_objects)
1617    AC_SUBST(PRAGMA_UNREF)
1618
1619    CF_WITH_PATH(ada-include,
1620        [  --with-ada-include=DIR  Ada includes are in DIR],
1621        ADA_INCLUDE,
1622        PREFIX/lib/ada/adainclude,
1623        [$]prefix/lib/ada/adainclude)
1624    AC_SUBST(ADA_INCLUDE)
1625
1626    CF_WITH_PATH(ada-objects,
1627        [  --with-ada-objects=DIR  Ada objects are in DIR],
1628        ADA_OBJECTS,
1629        PREFIX/lib/ada/adalib,
1630        [$]prefix/lib/ada/adalib)
1631    AC_SUBST(ADA_OBJECTS)
1632
1633 fi
1634 fi
1635 else
1636    cf_with_ada=no
1637 fi
1638
1639 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1640 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1641 ###
1642 ### ticlib modules may be a separate library, otherwise contained in termlib.
1643 ### termlib modules may be a separate library, otherwise contained in ncurses.
1644 ###
1645 ### The of "+" or " " between the tokens controls the way the script
1646 ### chooses to split module lists into libraries.
1647 ###
1648 ### (see CF_LIB_RULES).
1649 AC_MSG_CHECKING(for library subsets)
1650 LIB_SUBSETS=
1651
1652 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1653         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1654         if test "$with_ticlib" != no ; then
1655                 LIB_SUBSETS="${LIB_SUBSETS} "
1656         else
1657                 LIB_SUBSETS="${LIB_SUBSETS}+"
1658         fi
1659 fi
1660
1661 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1662 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1663
1664 if test "$with_termlib" != no ; then
1665         LIB_SUBSETS="${LIB_SUBSETS} "
1666 else
1667         LIB_SUBSETS="${LIB_SUBSETS}+"
1668 fi
1669
1670 LIB_SUBSETS="${LIB_SUBSETS}base"
1671
1672 # Most term-driver calls are to tinfo, but some like init_pair are to the
1673 # base library (so it resides in base).
1674 if test "$with_term_driver" != no ; then
1675         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1676         case $cf_cv_system_name in #(vi
1677         *mingw32*) #(vi
1678                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1679                 ;;
1680         *) #(vi
1681                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1682                 ;;
1683         esac
1684 fi
1685
1686 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1687 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1688
1689 AC_MSG_RESULT($LIB_SUBSETS)
1690
1691 ### Construct the list of include-directories to be generated
1692 CF_INCLUDE_DIRS
1693 CF_ADA_INCLUDE_DIRS
1694
1695 ### Build up pieces for makefile rules
1696 AC_MSG_CHECKING(default library suffix)
1697 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1698 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1699 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1700
1701 AC_MSG_CHECKING(default library-dependency suffix)
1702 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1703 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1704 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1705
1706 AC_MSG_CHECKING(default object directory)
1707 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1708 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1709 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1710
1711 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1712 if test "$cf_with_cxx" = yes ; then
1713 AC_MSG_CHECKING(c++ library-dependency suffix)
1714 if test "$with_libtool" != "no"; then
1715         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1716 else
1717         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1718 fi
1719 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1720 AC_SUBST(CXX_LIB_SUFFIX)
1721 fi
1722
1723 # do not want -ldl in build except as needed for -lncurses dependency
1724 if test "$with_dlsym" = yes ; then
1725 if test $DFT_LWR_MODEL = shared || \
1726    test $DFT_LWR_MODEL = libtool ; then
1727         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1728 fi
1729 fi
1730 ### Set up low-level terminfo dependencies for makefiles.
1731
1732 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1733 # do not need libdl
1734 TICS_LIST=
1735 if test "$with_dlsym" = yes ; then
1736         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1737 fi
1738
1739 if test "$with_ticlib" != no ; then
1740
1741         if test "$with_ticlib" != yes ; then
1742                 TICS_NAME=$with_ticlib
1743                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1744                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1745                 TICS_LIB_SUFFIX="${with_ticlib}"
1746         else
1747                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1748                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1749                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1750         fi
1751         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1752 else
1753         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1754 fi
1755 AC_SUBST(TICS_ARG_SUFFIX)
1756 AC_SUBST(TICS_DEP_SUFFIX)
1757 AC_SUBST(TICS_LIB_SUFFIX)
1758 AC_SUBST(TICS_ARGS)
1759
1760 if test "$with_termlib" != no ; then
1761
1762         if test "$with_termlib" != yes ; then
1763                 TINFO_NAME=$with_termlib
1764                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1765                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1766                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1767                 TINFO_LIB_SUFFIX="${with_termlib}"
1768         else
1769                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1770                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1771                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1772                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1773         fi
1774
1775         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1776         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1777         if test "$DFT_LWR_MODEL" = "libtool"; then
1778                 TEST_ARGS="${TEST_DEPS}"
1779                 TEST_ARG2="${TEST_DEP2}"
1780                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1781                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1782                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1783         else
1784                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1785                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1786                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1787                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1788                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1789         fi
1790 else
1791         # the next lines are needed for linking libtic over libncurses
1792         TINFO_NAME=${LIB_NAME}
1793         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1794         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1795         if test "$with_tic_depends" = yes ; then
1796                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1797         else
1798                 TICS_LIST="$SHLIB_LIST"
1799         fi
1800
1801         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1802 fi
1803
1804 if test "$DFT_LWR_MODEL" = shared ; then
1805         case $cf_cv_system_name in #(vi
1806         cygwin*)
1807                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1808                 TINFO_SUFFIX=.dll
1809                 ;;
1810         esac
1811 fi
1812
1813 AC_SUBST(TINFO_ARG_SUFFIX)
1814 AC_SUBST(TINFO_DEP_SUFFIX)
1815 AC_SUBST(TINFO_LIB_SUFFIX)
1816 AC_SUBST(TINFO_ARGS)
1817
1818 if test "$with_dlsym" = yes ; then
1819         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1820 fi
1821
1822 if test "$DFT_LWR_MODEL" = "libtool"; then
1823     OBJEXT=lo
1824 fi
1825
1826 # needed for Ada95
1827 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1828 AC_SUBST(TINFO_ARGS2)
1829
1830 case $DFT_LWR_MODEL in
1831 normal|debug|profile)
1832         CF_LDFLAGS_STATIC
1833         ;;
1834 esac
1835
1836 AC_MSG_CHECKING(where we will install curses.h)
1837 test "$with_overwrite" = no && \
1838 test "x$includedir" = 'x${prefix}/include' && \
1839         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1840 AC_MSG_RESULT($includedir)
1841
1842 ### Resolve a conflict between normal and wide-curses by forcing applications
1843 ### that will need libutf8 to add it to their configure script.
1844 if test "$with_overwrite" != no ; then
1845 if test "$NCURSES_LIBUTF8" = 1 ; then
1846         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1847         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1848 fi
1849 fi
1850 WITH_OVERWRITE=$with_overwrite
1851
1852 AC_SUBST(WITH_OVERWRITE)
1853 AC_SUBST(TICS_LIST)
1854 AC_SUBST(TINFO_LIST)
1855 AC_SUBST(SHLIB_LIST)
1856
1857 # used to separate tack out of the tree
1858 NCURSES_TREE=
1859 AC_SUBST(NCURSES_TREE)
1860
1861 ### predefined stuff for the test programs
1862 AC_DEFINE(HAVE_SLK_COLOR)
1863
1864 ### Construct the list of subdirectories for which we'll customize makefiles
1865 ### with the appropriate compile-rules.
1866
1867 CF_SRC_MODULES($modules_to_build)
1868
1869 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1870    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1871 fi
1872
1873 CF_DIRS_TO_MAKE
1874
1875 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR')
1876
1877 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1878
1879 ### Now that we're done running tests, add the compiler-warnings, if any
1880 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1881
1882 ### If we're building with rpath, try to link non-standard libs that way too.
1883 if test "$DFT_LWR_MODEL" = "shared"; then
1884   CF_RPATH_HACK
1885 fi
1886
1887 ### Define substitutions for header files to avoid name-pollution
1888 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1889 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1890 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1891
1892 ################################################################################
1893 test "$use_database" = yes && \
1894 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1895
1896 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1897
1898 if test x"$enable_pc_files" = xyes ; then \
1899 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1900 MAKE_PC_FILES=
1901 else
1902 MAKE_PC_FILES="#"
1903 fi
1904 AC_SUBST(MAKE_PC_FILES)
1905 AC_SUBST(cross_compiling)
1906
1907 AC_OUTPUT( \
1908         include/MKterm.h.awk \
1909         include/curses.head:include/curses.h.in \
1910         include/ncurses_dll.h \
1911         include/termcap.h \
1912         include/unctrl.h \
1913         $SUB_MAKEFILES \
1914         Makefile,[
1915 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1916 CF_LIB_RULES($SRC_SUBDIRS)
1917 ],[
1918 ### Special initialization commands, used to pass information from the
1919 ### configuration-run into config.status
1920
1921 AWK="$AWK"
1922 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1923 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1924 ECHO_LINK="$ECHO_LINK"
1925 LDCONFIG="$LDCONFIG"
1926 LIB_NAME="$LIB_NAME"
1927 LIB_SUBSETS="$LIB_SUBSETS"
1928 LIB_SUFFIX="$LIB_SUFFIX"
1929 LIB_TRACING="$LIB_TRACING"
1930 MAKE_TERMINFO="$MAKE_TERMINFO"
1931 NCURSES_MAJOR="$NCURSES_MAJOR"
1932 NCURSES_MINOR="$NCURSES_MINOR"
1933 NCURSES_OSPEED="$NCURSES_OSPEED"
1934 NCURSES_PATCH="$NCURSES_PATCH"
1935 SRC_SUBDIRS="$SRC_SUBDIRS"
1936 TERMINFO="$TERMINFO"
1937 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1938 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1939 TICS_NAME="$TICS_NAME"
1940 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1941 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1942 TINFO_NAME="$TINFO_NAME"
1943 TINFO_SUFFIX="$TINFO_SUFFIX"
1944 WITH_CURSES_H="$with_curses_h"
1945 WITH_ECHO="$with_echo"
1946 WITH_OVERWRITE="$with_overwrite"
1947 cf_LIST_MODELS="$cf_list_models"
1948 cf_cv_abi_version="$cf_cv_abi_version"
1949 cf_cv_do_relink="$cf_cv_do_relink"
1950 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1951 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1952 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1953 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1954 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1955 cf_cv_rel_version="$cf_cv_rel_version"
1956 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1957 cf_cv_shared_soname='$cf_cv_shared_soname'
1958 cf_cv_shlib_version="$cf_cv_shlib_version"
1959 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1960 cf_cv_system_name="$cf_cv_system_name"
1961 cf_with_cxx_binding="$cf_with_cxx_binding"
1962 cf_with_manpages="$cf_with_manpages"
1963 host="$host"
1964 target="$target"
1965
1966 ],cat)dnl
1967 ${MAKE-make} preinstall