ncurses 5.7 - patch 20090704
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2008,2009 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.471 2009/06/13 21:40:19 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See http://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.13.20020210)
38 AC_REVISION($Revision: 1.471 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44
45 CF_WITH_REL_VERSION(NCURSES)
46 CF_WITH_ABI_VERSION
47
48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
49 AC_ARG_WITH(system-type,
50 [  --with-system-type=XXX  test: override derived host system-type],
51 [AC_MSG_WARN(overriding system type to $withval)
52  cf_cv_system_name=$withval])
53
54 ###     Save the given $CFLAGS to allow user-override.
55 cf_user_CFLAGS="$CFLAGS"
56
57 ###     Default install-location
58 CF_CFG_DEFAULTS
59
60 ###     Checks for programs.
61 AC_PROG_CC
62 CF_GCC_VERSION
63
64 AC_PROG_CPP
65 AC_PROG_GCC_TRADITIONAL
66 CF_PROG_CC_C_O(CC)
67 AC_ISC_POSIX
68 CF_ANSI_CC_REQD
69 CF_PROG_EXT
70 CF_PROG_LDCONFIG
71
72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
73 dnl                             configure script by not letting us test if C++
74 dnl                             is present, making this option necessary.
75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
76 AC_ARG_WITH(cxx,
77         [  --without-cxx           do not adjust ncurses bool to match C++],
78         [cf_with_cxx=$withval],
79         [cf_with_cxx=yes])
80 AC_MSG_RESULT($cf_with_cxx)
81 if test "X$cf_with_cxx" = Xno ; then
82         CXX=""
83         GXX=""
84 else
85         # with autoconf 2.13, we can change the error to a warning:
86         pushdef([AC_MSG_ERROR],
87                 [AC_MSG_RESULT(no)
88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
90         AC_PROG_CXX
91         popdef([AC_MSG_ERROR])dnl
92         # autoconf 2.5x removed the error - by hardcoding it to g++.
93         if test "$CXX" = "g++" ; then
94                 AC_PATH_PROG(CXX,g++)
95         fi
96         if test "$CXX" = "g++" ; then
97                 AC_MSG_WARN(ignoring hardcoded g++)
98                 cf_with_cxx=no; CXX=""; GXX="";
99         fi
100 fi
101
102 CF_GXX_VERSION
103 case $GXX_VERSION in
104 1*|2.[[0-6]]*)
105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
106         # cf_cxx_library=no
107         AC_MSG_WARN(templates do not work)
108         ;;
109 esac
110
111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
112 AC_ARG_WITH(cxx-binding,
113         [  --without-cxx-binding   do not build C++ binding and demo],
114         [cf_with_cxx_binding=$withval],
115         [cf_with_cxx_binding=$cf_with_cxx])
116 AC_MSG_RESULT($cf_with_cxx_binding)
117
118 AC_MSG_CHECKING(if you want to build with Ada95)
119 AC_ARG_WITH(ada,
120         [  --without-ada           suppress check for Ada95, don't build demo],
121         [cf_with_ada=$withval],
122         [cf_with_ada=yes])
123 AC_MSG_RESULT($cf_with_ada)
124
125 AC_MSG_CHECKING(if you want to install manpages)
126 AC_ARG_WITH(manpages,
127         [  --without-manpages      suppress install of manpages],
128         [cf_with_manpages=$withval],
129         [cf_with_manpages=yes])
130 AC_MSG_RESULT($cf_with_manpages)
131
132 AC_MSG_CHECKING(if you want to build programs such as tic)
133 AC_ARG_WITH(progs,
134         [  --without-progs         suppress build with programs (e.g., tic)],
135         [cf_with_progs=$withval],
136         [cf_with_progs=yes])
137 AC_MSG_RESULT($cf_with_progs)
138
139 AC_MSG_CHECKING(if you wish to install curses.h)
140 AC_ARG_WITH(curses-h,
141         [  --without-curses-h      install curses.h as ncurses.h only],
142         [with_curses_h=$withval],
143         [with_curses_h=yes])
144 AC_MSG_RESULT($with_curses_h)
145
146 modules_to_build="ncurses"
147 if test "X$cf_with_progs" != Xno ; then
148 modules_to_build="$modules_to_build progs tack"
149 fi
150 modules_to_build="$modules_to_build panel menu form"
151
152 AC_ARG_PROGRAM
153
154 CF_PROG_AWK
155 CF_PROG_EGREP
156 CF_PROG_INSTALL
157 CF_PROG_LINT
158 AC_PROG_LN_S
159
160 AC_SYS_LONG_FILE_NAMES
161
162 # if we find pkg-config, check if we should install the ".pc" files.
163 CF_PKG_CONFIG
164
165 if test "$PKG_CONFIG" != no ; then
166         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
167
168         # Leave this as something that can be overridden in the environment.
169         if test -z "$PKG_CONFIG_LIBDIR" ; then
170                 PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`/lib/pkgconfig
171         fi
172
173         if test -d "$PKG_CONFIG_LIBDIR" ; then
174                 AC_ARG_ENABLE(pc-files,
175                         [  --enable-pc-files       generate and install .pc files for pkg-config],
176                         [enable_pc_files=$enableval],
177                         [enable_pc_files=no])
178                 AC_MSG_RESULT($enable_pc_files)
179         else
180                 AC_MSG_RESULT(no)
181                 AC_MSG_WARN(did not find library $PKG_CONFIG_LIBDIR)
182                 enable_pc_files=no
183         fi
184 fi
185 AC_SUBST(PKG_CONFIG_LIBDIR)
186
187 AC_MSG_CHECKING(if we should assume mixed-case filenames)
188 AC_ARG_ENABLE(mixed-case,
189         [  --enable-mixed-case     tic should assume mixed-case filenames],
190         [enable_mixedcase=$enableval],
191         [enable_mixedcase=auto])
192 AC_MSG_RESULT($enable_mixedcase)
193 if test "$enable_mixedcase" = "auto" ; then
194     CF_MIXEDCASE_FILENAMES
195 else
196     cf_cv_mixedcase=$enable_mixedcase
197     if test "$enable_mixedcase" = "yes" ; then
198         AC_DEFINE(MIXEDCASE_FILENAMES)
199     fi
200 fi
201
202 # do this after mixed-case option (tags/TAGS is not as important as tic).
203 AC_PROG_MAKE_SET
204 CF_MAKE_TAGS
205 CF_MAKEFLAGS
206
207 dnl These are standard among *NIX systems, but not when cross-compiling
208 AC_CHECK_TOOL(RANLIB, ranlib, ':')
209 AC_CHECK_TOOL(LD, ld, ld)
210 AC_CHECK_TOOL(AR, ar, ar)
211 CF_AR_FLAGS
212
213 dnl Special option for use by system-builders: the install-prefix is used to
214 dnl adjust the location into which the actual install is done, so that an
215 dnl archive can be built without modifying the host system's configuration.
216 AC_MSG_CHECKING(if you have specified an install-prefix)
217 AC_ARG_WITH(install-prefix,
218         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
219         [case "$withval" in #(vi
220         yes|no) #(vi
221                 ;;
222         *)      DESTDIR="$withval"
223                 ;;
224         esac])
225 AC_MSG_RESULT($DESTDIR)
226 AC_SUBST(DESTDIR)
227
228 ###############################################################################
229 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
230 # If we're cross-compiling, allow the user to override the tools and their
231 # options.  The configure script is oriented toward identifying the host
232 # compiler, etc., but we need a build compiler to generate parts of the source.
233 CF_BUILD_CC
234
235 ###############################################################################
236 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
237
238 ### Options to allow the user to specify the set of libraries which are used.
239 ### Use "--without-normal --with-shared" to allow the default model to be
240 ### shared, for example.
241 cf_list_models=""
242 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
243
244 CF_WITH_LIBTOOL
245 if test "$with_libtool" != "no" ; then
246
247 cf_list_models="$cf_list_models libtool"
248
249 else
250
251 AC_MSG_CHECKING(if you want to build shared libraries)
252 AC_ARG_WITH(shared,
253         [  --with-shared           generate shared-libraries],
254         [with_shared=$withval],
255         [with_shared=no])
256 AC_MSG_RESULT($with_shared)
257 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
258
259 AC_MSG_CHECKING(if you want to build static libraries)
260 AC_ARG_WITH(normal,
261         [  --with-normal           generate normal-libraries (default)],
262         [with_normal=$withval],
263         [with_normal=yes])
264 AC_MSG_RESULT($with_normal)
265 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
266
267 AC_MSG_CHECKING(if you want to build debug libraries)
268 AC_ARG_WITH(debug,
269         [  --with-debug            generate debug-libraries (default)],
270         [with_debug=$withval],
271         [with_debug=yes])
272 AC_MSG_RESULT($with_debug)
273 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
274
275 AC_MSG_CHECKING(if you want to build profiling libraries)
276 AC_ARG_WITH(profile,
277         [  --with-profile          generate profile-libraries],
278         [with_profile=$withval],
279         [with_profile=no])
280 AC_MSG_RESULT($with_profile)
281 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
282
283 fi
284
285 ###############################################################################
286
287 AC_MSG_CHECKING(for specified models)
288 test -z "$cf_list_models" && cf_list_models=normal
289 dnl If we use libtool to generate libraries, then it must be the only
290 dnl specified model.
291 test "$with_libtool" != "no" && cf_list_models=libtool
292 AC_MSG_RESULT($cf_list_models)
293
294 ### Use the first model as the default, and save its suffix for use in building
295 ### up test-applications.
296 AC_MSG_CHECKING(for default model)
297 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
298 AC_MSG_RESULT($DFT_LWR_MODEL)
299
300 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
301
302 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
303 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
304
305 TICS_NAME=tic
306 AC_SUBST(TICS_NAME)
307
308 TINFO_NAME=tinfo
309 AC_SUBST(TINFO_NAME)
310
311 LIB_NAME=ncurses
312 AC_SUBST(LIB_NAME)
313
314 LIB_DIR=../lib
315 LIB_2ND=../../lib
316
317 CF_LIB_PREFIX(cf_prefix)
318 LIB_PREFIX=$cf_prefix
319 AC_SUBST(LIB_PREFIX)
320
321 LIB_SUFFIX=
322 AC_SUBST(LIB_SUFFIX)
323
324 ###############################################################################
325
326 AC_MSG_CHECKING(if you want to build a separate terminfo library)
327 AC_ARG_WITH(termlib,
328         [  --with-termlib          generate separate terminfo library],
329         [with_termlib=$withval],
330         [with_termlib=no])
331 AC_MSG_RESULT($with_termlib)
332
333 AC_MSG_CHECKING(if you want to build a separate tic library)
334 AC_ARG_WITH(ticlib,
335         [  --with-ticlib           generate separate tic library],
336         [with_ticlib=$withval],
337         [with_ticlib=no])
338 AC_MSG_RESULT($with_ticlib)
339
340 ### Checks for special libraries, must be done up-front.
341 SHLIB_LIST=""
342 CF_WITH_GPM
343 if test "$with_gpm" != no ; then
344         AC_MSG_CHECKING(if you want to load GPM dynamically)
345         AC_ARG_WITH(dlsym,
346                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
347                 [with_dlsym=$withval],
348                 [with_dlsym=yes])
349         AC_MSG_RESULT($with_dlsym)
350         if test "$with_dlsym" = yes ; then
351                 CF_FUNC_DLSYM
352                 if test "$with_gpm" != yes ; then
353                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
354                         cf_cv_gpm_soname="$with_gpm"
355                 else
356                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
357                 fi
358                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
359                 SHLIB_LIST="-ldl $SHLIB_LIST"
360         else
361                 SHLIB_LIST="-lgpm $SHLIB_LIST"
362         fi
363         AC_DEFINE(HAVE_LIBGPM)
364         CF_CHECK_GPM_WGETCH
365 fi
366
367 CF_WITH_SYSMOUSE
368
369 dnl Not all ports of gcc support the -g option
370
371 if test X"$CC_G_OPT" = X"" ; then
372         CC_G_OPT='-g'
373         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
374 fi
375 AC_SUBST(CC_G_OPT)
376
377 if test X"$CXX_G_OPT" = X"" ; then
378         CXX_G_OPT='-g'
379         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
380 fi
381 AC_SUBST(CXX_G_OPT)
382
383 AC_MSG_CHECKING(for default loader flags)
384 case $DFT_LWR_MODEL in
385 libtool) LD_MODEL=''   ;;
386 normal)  LD_MODEL=''   ;;
387 debug)   LD_MODEL=$CC_G_OPT ;;
388 profile) LD_MODEL='-pg';;
389 shared)  LD_MODEL=''   ;;
390 esac
391 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
392 AC_MSG_RESULT($LD_MODEL)
393
394 case $DFT_LWR_MODEL in
395 shared)
396 CF_ENABLE_RPATH
397 AC_MSG_CHECKING(if shared libraries should be relinked during install)
398 AC_ARG_ENABLE(relink,
399 [  --disable-relink        relink shared libraries during install],
400 [cf_cv_do_relink=$enableval],
401 [cf_cv_do_relink=yes])
402 AC_MSG_RESULT($cf_cv_do_relink)
403         ;;
404 esac
405
406 CF_SHARED_OPTS
407 if test "$CC_SHARED_OPTS" = "unknown"; then
408         for model in $cf_list_models; do
409                 if test "$model" = "shared"; then
410                         AC_ERROR(Shared libraries are not supported in this version)
411                 fi
412         done
413 fi
414
415 ###############################################################################
416 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
417
418 ###     use option --disable-overwrite to leave out the link to -lcurses
419 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
420 AC_ARG_ENABLE(overwrite,
421         [  --disable-overwrite     leave out the link to -lcurses],
422         [with_overwrite=$enableval],
423         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
424 AC_MSG_RESULT($with_overwrite)
425
426 AC_MSG_CHECKING(if external terminfo-database is used)
427 AC_ARG_ENABLE(database,
428         [  --disable-database      do not use terminfo, only fallbacks/termcap],
429         [use_database=$enableval],
430         [use_database=yes])
431 AC_MSG_RESULT($use_database)
432
433 case $host_os in #(vi
434 os2*) #(vi
435         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
436         ;;
437 *) #(vi
438         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
439         ;;
440 esac
441 AC_SUBST(TERMINFO_SRC)
442
443 CF_PATHSEP
444 if test "$use_database" != no ; then
445         AC_DEFINE(USE_DATABASE)
446
447         AC_MSG_CHECKING(which terminfo source-file will be installed)
448         AC_ARG_ENABLE(database,
449                 [  --with-database=XXX     specify terminfo source to install],
450                 [TERMINFO_SRC=$withval])
451         AC_MSG_RESULT($TERMINFO_SRC)
452
453         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
454         AC_ARG_WITH(hashed-db,
455                 [  --with-hashed-db        specify hashed-database library],,
456                 [with_hashed_db=no])
457         AC_MSG_RESULT($with_hashed_db)
458 else
459         with_hashed_db=no
460 fi
461
462 AC_MSG_CHECKING(for list of fallback descriptions)
463 AC_ARG_WITH(fallbacks,
464         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
465         [with_fallback=$withval],
466         [with_fallback=])
467 AC_MSG_RESULT($with_fallback)
468 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
469 AC_SUBST(FALLBACK_LIST)
470
471 AC_MSG_CHECKING(if you want modern xterm or antique)
472 AC_ARG_WITH(xterm-new,
473         [  --without-xterm-new     specify if xterm terminfo should be old version],
474         [with_xterm_new=$withval],
475         [with_xterm_new=yes])
476 case $with_xterm_new in
477 no)     with_xterm_new=xterm-old;;
478 *)      with_xterm_new=xterm-new;;
479 esac
480 AC_MSG_RESULT($with_xterm_new)
481 WHICH_XTERM=$with_xterm_new
482 AC_SUBST(WHICH_XTERM)
483
484 MAKE_TERMINFO=
485 if test "$use_database" = no ; then
486         TERMINFO="${datadir}/terminfo"
487         MAKE_TERMINFO="#"
488 else
489
490 AC_MSG_CHECKING(for list of terminfo directories)
491 CF_WITH_PATHLIST(terminfo-dirs,
492         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
493         TERMINFO_DIRS,
494         DATADIR/terminfo,
495         ${datadir}/terminfo)
496 AC_MSG_RESULT($TERMINFO_DIRS)
497 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
498
499 AC_MSG_CHECKING(for default terminfo directory)
500 CF_WITH_PATH(default-terminfo-dir,
501         [  --with-default-terminfo-dir=DIR default terminfo directory],
502         TERMINFO,
503         DATADIR/terminfo,
504         ${datadir}/terminfo)
505 AC_MSG_RESULT($TERMINFO)
506 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
507
508 fi
509
510 AC_SUBST(TERMINFO)
511 AC_SUBST(MAKE_TERMINFO)
512
513 ###     use option --disable-big-core to make tic run on small machines
514 ###     We need 4Mb, check if we can allocate 50% more than that.
515 AC_MSG_CHECKING(if big-core option selected)
516 AC_ARG_ENABLE(big-core,
517         [  --disable-big-core      assume machine has little memory],
518         [with_big_core=$enableval],
519         [AC_TRY_RUN([
520 #include <stdlib.h>
521 #include <string.h>
522 int main() {
523         unsigned long n = 6000000L;
524         char *s = malloc(n);
525         if (s != 0)
526                 s[0] = s[n-1] = 0;
527         ${cf_cv_main_return:-return}(s == 0);
528 }],
529         [with_big_core=yes],
530         [with_big_core=no],
531         [with_big_core=no])])
532 AC_MSG_RESULT($with_big_core)
533 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
534
535 ### ISO C only guarantees 512-char strings, we have tables which load faster
536 ### when constructed using "big" strings.  More than the C compiler, the awk
537 ### program is a limit on most vendor UNIX systems.  Check that we can build.
538 AC_MSG_CHECKING(if big-strings option selected)
539 AC_ARG_ENABLE(big-strings,
540         [  --disable-big-strings   assume compiler has only standard-size strings],
541         [with_big_strings=$enableval],
542         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
543 AC_MSG_RESULT($with_big_strings)
544
545 USE_BIG_STRINGS=0
546 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
547 AC_SUBST(USE_BIG_STRINGS)
548
549 ###     use option --enable-termcap to compile in the termcap fallback support
550 AC_MSG_CHECKING(if you want termcap-fallback support)
551 AC_ARG_ENABLE(termcap,
552         [  --enable-termcap        compile in termcap fallback support],
553         [with_termcap=$enableval],
554         [with_termcap=no])
555 AC_MSG_RESULT($with_termcap)
556
557 if test "$with_termcap" != "yes" ; then
558         if test "$use_database" = no ; then
559                 if test -z "$with_fallback" ; then
560                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
561                 fi
562         fi
563         AC_DEFINE(PURE_TERMINFO)
564 else
565
566 if test "$with_ticlib" != no ; then
567         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
568 fi
569
570 AC_DEFINE(USE_TERMCAP)
571 AC_MSG_CHECKING(for list of termcap files)
572 CF_WITH_PATHLIST(termpath,
573         [  --with-termpath=XXX     specify list of termcap files],
574         TERMPATH,
575         /etc/termcap:/usr/share/misc/termcap)
576 AC_MSG_RESULT($TERMPATH)
577 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
578
579 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
580 AC_MSG_CHECKING(if fast termcap-loader is needed)
581 AC_ARG_ENABLE(getcap,
582         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
583         [with_getcap=$enableval],
584         [with_getcap=no])
585 AC_MSG_RESULT($with_getcap)
586 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
587
588 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
589 AC_ARG_ENABLE(getcap-cache,
590         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
591         [with_getcap_cache=$enableval],
592         [with_getcap_cache=no])
593 AC_MSG_RESULT($with_getcap_cache)
594 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
595
596 fi
597
598 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
599 AC_MSG_CHECKING(if ~/.terminfo is wanted)
600 AC_ARG_ENABLE(home-terminfo,
601         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
602         [with_home_terminfo=$enableval],
603         [with_home_terminfo=yes])
604 AC_MSG_RESULT($with_home_terminfo)
605 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
606
607 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
608 AC_ARG_ENABLE(root-environ,
609         [  --disable-root-environ  restrict environment when running as root],
610         [with_root_environ=$enableval],
611         [with_root_environ=yes])
612 AC_MSG_RESULT($with_root_environ)
613 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
614
615 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
616 ###   to reduce storage requirements for the terminfo database.
617 CF_LINK_FUNCS
618
619 with_links=no
620 with_symlinks=no
621
622 # soft links (symbolic links) are useful for some systems where hard links do
623 # not work, or to make it simpler to copy terminfo trees around.
624 if test "$ac_cv_func_symlink" = yes ; then
625     AC_MSG_CHECKING(if tic should use symbolic links)
626     AC_ARG_ENABLE(symlinks,
627         [  --enable-symlinks       make tic use symbolic links not hard links],
628         [with_symlinks=$enableval],
629         [with_symlinks=no])
630     AC_MSG_RESULT($with_symlinks)
631 fi
632
633 # If we have hard links and did not choose to use soft links instead, there is
634 # no reason to make this choice optional - use the hard links.
635 if test "$with_symlinks" = no ; then
636     AC_MSG_CHECKING(if tic should use hard links)
637     if test "$ac_cv_func_link" = yes ; then
638         with_links=yes
639     else
640         with_links=no
641     fi
642     AC_MSG_RESULT($with_links)
643 fi
644
645 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
646 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
647
648 ###   use option --enable-broken-linker to force on use of broken-linker support
649 AC_MSG_CHECKING(if you want broken-linker support code)
650 AC_ARG_ENABLE(broken_linker,
651         [  --enable-broken_linker  compile with broken-linker support code],
652         [with_broken_linker=$enableval],
653         [with_broken_linker=${BROKEN_LINKER-no}])
654 AC_MSG_RESULT($with_broken_linker)
655
656 BROKEN_LINKER=0
657 if test "$with_broken_linker" = yes ; then
658         AC_DEFINE(BROKEN_LINKER)
659         BROKEN_LINKER=1
660 elif test "$DFT_LWR_MODEL" = shared ; then
661         case $cf_cv_system_name in #(vi
662         cygwin*)
663                 AC_DEFINE(BROKEN_LINKER)
664                 BROKEN_LINKER=1
665                 CF_VERBOSE(cygwin linker is broken anyway)
666                 ;;
667         esac
668 fi
669 AC_SUBST(BROKEN_LINKER)
670
671 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
672 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
673 AC_ARG_ENABLE(bsdpad,
674         [  --enable-bsdpad         recognize BSD-style prefix padding],
675         [with_bsdpad=$enableval],
676         [with_bsdpad=no])
677 AC_MSG_RESULT($with_bsdpad)
678 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
679
680 ###   use option --enable-widec to turn on use of wide-character support
681 NCURSES_CH_T=chtype
682 NCURSES_LIBUTF8=0
683
684 NEED_WCHAR_H=0
685 NCURSES_MBSTATE_T=0
686 NCURSES_WCHAR_T=0
687 NCURSES_WINT_T=0
688
689 # Check to define _XOPEN_SOURCE "automatically"
690 CF_XOPEN_SOURCE
691
692 # Work around breakage on OS X
693 CF_SIGWINCH
694
695 # Checks for CODESET support.
696 AM_LANGINFO_CODESET
697
698 # use these variables to work around a defect in gcc's fixincludes.
699 NCURSES_OK_WCHAR_T=
700 NCURSES_OK_WINT_T=
701
702 AC_MSG_CHECKING(if you want wide-character code)
703 AC_ARG_ENABLE(widec,
704         [  --enable-widec          compile with wide-char/UTF-8 code],
705         [with_widec=$enableval],
706         [with_widec=no])
707 AC_MSG_RESULT($with_widec)
708 if test "$with_widec" = yes ; then
709         LIB_SUFFIX="w${LIB_SUFFIX}"
710         AC_DEFINE(USE_WIDEC_SUPPORT)
711         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
712         # with_overwrite=no
713         NCURSES_CH_T=cchar_t
714         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
715         if test "$ac_cv_func_putwc" != yes ; then
716                 CF_UTF8_LIB
717                 if test "$cf_cv_utf8_lib" != no ; then
718                         NCURSES_LIBUTF8=1
719                 fi
720         fi
721         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
722         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
723         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
724
725         if test "$NCURSES_MBSTATE_T" != 0; then
726                 AC_DEFINE(NEED_MBSTATE_T_DEF)
727         fi
728 fi
729 AC_SUBST(NCURSES_CH_T)
730 AC_SUBST(NCURSES_LIBUTF8)
731
732 AC_SUBST(NEED_WCHAR_H)
733 AC_SUBST(NCURSES_MBSTATE_T)
734 AC_SUBST(NCURSES_WCHAR_T)
735 AC_SUBST(NCURSES_WINT_T)
736
737 AC_SUBST(NCURSES_OK_WCHAR_T)
738 AC_SUBST(NCURSES_OK_WINT_T)
739
740 ###   use option --disable-lp64 to allow long chtype
741 case $cf_cv_abi_version in
742 [[345]]*)
743         default_with_lp64=no
744         ;;
745 *)
746         default_with_lp64=yes
747         ;;
748 esac
749
750 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
751 AC_ARG_ENABLE(lp64,
752         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
753         [with_lp64=$enableval],
754         [with_lp64=$default_with_lp64])
755 AC_MSG_RESULT($with_lp64)
756
757 if test "$with_lp64" = yes ; then
758         cf_cv_enable_lp64=1
759 else
760         cf_cv_enable_lp64=0
761 fi
762 AC_SUBST(cf_cv_enable_lp64)
763
764 CF_LARGEFILE
765
766 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
767 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
768 AC_ARG_ENABLE(tparm-varargs,
769         [  --disable-tparm-varargs compile tparm() without varargs interface],
770         [with_tparm_varargs=$enableval],
771         [with_tparm_varargs=yes])
772 AC_MSG_RESULT($with_tparm_varargs)
773 NCURSES_TPARM_VARARGS=0
774 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
775 AC_SUBST(NCURSES_TPARM_VARARGS)
776
777 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
778 if test "$with_ticlib" != no ; then
779 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
780 AC_ARG_ENABLE(tic-depends,
781         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
782         [with_tic_depends=$enableval],
783         [with_tic_depends=yes])
784 AC_MSG_RESULT($with_tic_depends)
785 else
786         with_tic_depends=no
787 fi
788
789 ###   use option --with-bool to override bool's type
790 AC_MSG_CHECKING(for type of bool)
791 AC_ARG_WITH(bool,
792         [  --with-bool=TYPE        override fallback type of bool variable],
793         [NCURSES_BOOL="$withval"],
794         [NCURSES_BOOL=auto])
795 AC_MSG_RESULT($NCURSES_BOOL)
796 AC_SUBST(NCURSES_BOOL)
797
798 AC_MSG_CHECKING(for alternate terminal capabilities file)
799 AC_ARG_WITH(caps,
800         [  --with-caps=alt         compile with alternate Caps file],
801         [TERMINFO_CAPS=Caps.$withval],
802         [TERMINFO_CAPS=Caps])
803 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
804 AC_MSG_RESULT($TERMINFO_CAPS)
805 AC_SUBST(TERMINFO_CAPS)
806
807 ###   use option --with-chtype to override chtype's type
808 AC_MSG_CHECKING(for type of chtype)
809 AC_ARG_WITH(chtype,
810         [  --with-chtype=TYPE      override type of chtype],
811         [NCURSES_CHTYPE="$withval"],
812         [NCURSES_CHTYPE=auto])
813 AC_MSG_RESULT($NCURSES_CHTYPE)
814
815 ###   use option --with-ospeed to override ospeed's type
816 AC_MSG_CHECKING(for type of ospeed)
817 AC_ARG_WITH(ospeed,
818         [  --with-ospeed=TYPE      override type of ospeed variable],
819         [NCURSES_OSPEED="$withval"],
820         [NCURSES_OSPEED=short])
821 AC_MSG_RESULT($NCURSES_OSPEED)
822 AC_SUBST(NCURSES_OSPEED)
823
824 ###   use option --with-mmask-t to override mmask_t's type
825 AC_MSG_CHECKING(for type of mmask_t)
826 AC_ARG_WITH(mmask-t,
827         [  --with-mmask-t=TYPE     override type of mmask_t],
828         [NCURSES_MMASK_T="$withval"],
829         [NCURSES_MMASK_T=auto])
830 AC_MSG_RESULT($NCURSES_MMASK_T)
831
832 ### Enable compiling-in rcs id's
833 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
834 AC_ARG_WITH(rcs-ids,
835         [  --with-rcs-ids          compile-in RCS identifiers],
836         [with_rcs_ids=$withval],
837         [with_rcs_ids=no])
838 AC_MSG_RESULT($with_rcs_ids)
839 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
840
841 ###############################################################################
842 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
843
844 ###############################################################################
845 CF_HELP_MESSAGE(Extensions:)
846
847 ### Note that some functions (such as const) are normally disabled anyway.
848 AC_MSG_CHECKING(if you want to build with function extensions)
849 AC_ARG_ENABLE(ext-funcs,
850         [  --disable-ext-funcs     disable function-extensions],
851         [with_ext_funcs=$enableval],
852         [with_ext_funcs=yes])
853 AC_MSG_RESULT($with_ext_funcs)
854 if test "$with_ext_funcs" = yes ; then
855         NCURSES_EXT_FUNCS=1
856         AC_DEFINE(HAVE_CURSES_VERSION)
857         AC_DEFINE(HAVE_HAS_KEY)
858         AC_DEFINE(HAVE_RESIZETERM)
859         AC_DEFINE(HAVE_RESIZE_TERM)
860         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
861         AC_DEFINE(HAVE_WRESIZE)
862         AC_DEFINE(NCURSES_EXT_FUNCS)
863         GENERATED_EXT_FUNCS=generated
864 else
865         NCURSES_EXT_FUNCS=0
866         GENERATED_EXT_FUNCS=
867 fi
868 AC_SUBST(NCURSES_EXT_FUNCS)
869 AC_SUBST(GENERATED_EXT_FUNCS)
870
871 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
872 AC_ARG_ENABLE(sp-funcs,
873         [  --enable-sp-funcs       disable experimental SCREEN-extensions],
874         [with_sp_funcs=$enableval],
875         [with_sp_funcs=no])
876 AC_MSG_RESULT($with_sp_funcs)
877 if test "$with_sp_funcs" = yes ; then
878         NCURSES_SP_FUNCS=1
879         AC_DEFINE(NCURSES_SP_FUNCS)
880         GENERATED_SP_FUNCS=generated
881 else
882         NCURSES_SP_FUNCS=0
883         GENERATED_SP_FUNCS=
884 fi
885 AC_SUBST(NCURSES_SP_FUNCS)
886 AC_SUBST(GENERATED_SP_FUNCS)
887
888 ###   use option --enable-const to turn on use of const beyond that in XSI.
889 AC_MSG_CHECKING(for extended use of const keyword)
890 AC_ARG_ENABLE(const,
891         [  --enable-const          compile with extra/non-standard const],
892         [with_ext_const=$enableval],
893         [with_ext_const=no])
894 AC_MSG_RESULT($with_ext_const)
895 NCURSES_CONST='/*nothing*/'
896 if test "$with_ext_const" = yes ; then
897         NCURSES_CONST=const
898 fi
899 AC_SUBST(NCURSES_CONST)
900
901 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
902 AC_MSG_CHECKING(if you want to use extended colors)
903 AC_ARG_ENABLE(ext-colors,
904         [  --enable-ext-colors     compile for 256-color support],
905         [with_ext_colors=$enableval],
906         [with_ext_colors=no])
907 AC_MSG_RESULT($with_ext_colors)
908 NCURSES_EXT_COLORS=0
909 if test "$with_ext_colors" = yes ; then
910         if test "$with_widec" != yes ; then
911                 AC_MSG_ERROR(This option applies only to wide-character library)
912         else
913                 # cannot be ABI 5 since it changes sizeof(cchar_t)
914                 CF_NCURSES_ABI_6
915         fi
916         NCURSES_EXT_COLORS=1
917         AC_DEFINE(NCURSES_EXT_COLORS)
918 fi
919 AC_SUBST(NCURSES_EXT_COLORS)
920
921 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
922 AC_MSG_CHECKING(if you want to use extended mouse encoding)
923 AC_ARG_ENABLE(ext-mouse,
924         [  --enable-ext-mouse      compile for extended mouse-encoding],
925         [with_ext_mouse=$enableval],
926         [with_ext_mouse=no])
927 AC_MSG_RESULT($with_ext_mouse)
928 NCURSES_MOUSE_VERSION=1
929 if test "$with_ext_mouse" = yes ; then
930         NCURSES_MOUSE_VERSION=2
931         CF_NCURSES_ABI_6
932 fi
933 AC_SUBST(NCURSES_MOUSE_VERSION)
934
935 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
936 AC_ARG_ENABLE(no-padding,
937         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
938         [with_no_padding=$enableval],
939         [with_no_padding=$with_ext_funcs])
940 AC_MSG_RESULT($with_no_padding)
941 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
942
943 AC_CHECK_SIZEOF([signed char], 0)
944 if test "$ac_cv_sizeof_signed_char" = 1 ; then
945         NCURSES_SBOOL="signed char"
946 else
947         NCURSES_SBOOL="char"
948 fi
949 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
950 AC_ARG_ENABLE(signed-char,
951         [  --enable-signed-char    compile using signed Boolean's in term.h],
952         [with_signed_char=$enableval],
953         [with_signed_char=no])
954 AC_MSG_RESULT($with_signed_char)
955 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
956 AC_SUBST(NCURSES_SBOOL)
957
958 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
959 AC_MSG_CHECKING(if you want SIGWINCH handler)
960 AC_ARG_ENABLE(sigwinch,
961         [  --enable-sigwinch       compile with SIGWINCH handler],
962         [with_sigwinch=$enableval],
963         [with_sigwinch=$with_ext_funcs])
964 AC_MSG_RESULT($with_sigwinch)
965 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
966
967 ###   use option --enable-tcap-names to allow user to define new capabilities
968 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
969 AC_ARG_ENABLE(tcap-names,
970         [  --enable-tcap-names     compile with user-definable terminal capabilities],
971         [with_tcap_names=$enableval],
972         [with_tcap_names=$with_ext_funcs])
973 AC_MSG_RESULT($with_tcap_names)
974 NCURSES_XNAMES=0
975 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
976 AC_SUBST(NCURSES_XNAMES)
977
978 ###############################################################################
979 # These options are relatively safe to experiment with.
980 CF_HELP_MESSAGE(Development Code:)
981 AC_MSG_CHECKING(if you want all development code)
982 AC_ARG_WITH(develop,
983         [  --without-develop       disable development options],
984         [with_develop=$withval],
985         [with_develop=no])
986 AC_MSG_RESULT($with_develop)
987
988 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
989 AC_MSG_CHECKING(if you want hard-tabs code)
990 AC_ARG_ENABLE(hard-tabs,
991         [  --enable-hard-tabs      compile with hard-tabs code],,
992         [enable_hard_tabs=$with_develop])
993 AC_MSG_RESULT($enable_hard_tabs)
994 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
995
996 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
997 AC_MSG_CHECKING(if you want limited support for xmc)
998 AC_ARG_ENABLE(xmc-glitch,
999         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1000         [enable_xmc_glitch=$with_develop])
1001 AC_MSG_RESULT($enable_xmc_glitch)
1002 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
1003
1004 ###############################################################################
1005 # These are just experimental, probably should not be in a package:
1006 CF_HELP_MESSAGE(Experimental Code:)
1007
1008 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1009 AC_ARG_ENABLE(assumed-color,
1010         [  --disable-assumed-color do not assume anything about default-colors],
1011         [with_assumed_color=$enableval],
1012         [with_assumed_color=yes])
1013 AC_MSG_RESULT($with_assumed_color)
1014 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
1015
1016 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1017 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1018 AC_ARG_ENABLE(hashmap,
1019         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1020         [with_hashmap=$enableval],
1021         [with_hashmap=yes])
1022 AC_MSG_RESULT($with_hashmap)
1023 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1024
1025 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1026 AC_MSG_CHECKING(if you want colorfgbg code)
1027 AC_ARG_ENABLE(colorfgbg,
1028         [  --enable-colorfgbg      compile with $COLORFGBG code],
1029         [with_colorfgbg=$enableval],
1030         [with_colorfgbg=no])
1031 AC_MSG_RESULT($with_colorfgbg)
1032 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1033
1034 # This is still experimental (20080329), but should ultimately be moved to
1035 # the script-block --with-normal, etc.
1036 CF_WITH_PTHREAD
1037
1038 AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1039 AC_ARG_ENABLE(weak-symbols,
1040     [  --enable-weak-symbols   enable weak-symbols for pthreads],
1041     [use_weak_symbols=$withval],
1042     [use_weak_symbols=no])
1043 AC_MSG_RESULT($use_weak_symbols)
1044 if test "$use_weak_symbols" = yes ; then
1045     CF_WEAK_SYMBOLS
1046 else
1047     cf_cv_weak_symbols=no
1048 fi
1049
1050 if test $cf_cv_weak_symbols = yes ; then
1051     AC_DEFINE(USE_WEAK_SYMBOLS)
1052 fi
1053
1054 PTHREAD=
1055 if test "$with_pthread" = "yes" ; then
1056     AC_DEFINE(USE_PTHREADS)
1057     enable_reentrant=yes
1058     if test $cf_cv_weak_symbols = yes ; then
1059         PTHREAD=-lpthread
1060     fi
1061 fi
1062 AC_SUBST(PTHREAD)
1063
1064 # Reentrant code has to be opaque; there's little advantage to making ncurses
1065 # opaque outside of that, so there is no --enable-opaque option.  We can use
1066 # this option without --with-pthreads, but this will be always set for
1067 # pthreads.
1068 AC_MSG_CHECKING(if you want experimental reentrant code)
1069 AC_ARG_ENABLE(reentrant,
1070         [  --enable-reentrant      compile with experimental reentrant code],
1071         [with_reentrant=$enableval],
1072         [with_reentrant=no])
1073 AC_MSG_RESULT($with_reentrant)
1074 if test "$with_reentrant" = yes ; then
1075         cf_cv_enable_reentrant=1
1076         cf_cv_enable_opaque="NCURSES_INTERNALS"
1077         NCURSES_OPAQUE=1
1078         NCURSES_SIZE_T=int
1079         if test $cf_cv_weak_symbols = yes ; then
1080                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1081         else
1082                 LIB_SUFFIX="t${LIB_SUFFIX}"
1083         fi
1084         AC_DEFINE(USE_REENTRANT)
1085         CF_NCURSES_ABI_6
1086 else
1087         cf_cv_enable_reentrant=0
1088         cf_cv_enable_opaque="NCURSES_OPAQUE"
1089         NCURSES_OPAQUE=0
1090         NCURSES_SIZE_T=short
1091 fi
1092 AC_SUBST(cf_cv_enable_reentrant)
1093 AC_SUBST(cf_cv_enable_opaque)
1094 AC_SUBST(NCURSES_OPAQUE)
1095 AC_SUBST(NCURSES_SIZE_T)
1096
1097 ### Allow using a different wrap-prefix
1098 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1099         AC_MSG_CHECKING(for prefix used to wrap public variables)
1100         AC_ARG_WITH(wrap-prefix,
1101                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1102                 [NCURSES_WRAP_PREFIX=$withval],
1103                 [NCURSES_WRAP_PREFIX=_nc_])
1104         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1105 else
1106         NCURSES_WRAP_PREFIX=_nc_
1107 fi
1108 AC_SUBST(NCURSES_WRAP_PREFIX)
1109 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX")
1110
1111 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1112 AC_ARG_ENABLE(safe-sprintf,
1113         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1114         [with_safe_sprintf=$enableval],
1115         [with_safe_sprintf=no])
1116 AC_MSG_RESULT($with_safe_sprintf)
1117 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1118
1119 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1120 # when hashmap is used scroll hints are useless
1121 if test "$with_hashmap" = no ; then
1122 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1123 AC_ARG_ENABLE(scroll-hints,
1124         [  --disable-scroll-hints  compile without scroll-hints code],
1125         [with_scroll_hints=$enableval],
1126         [with_scroll_hints=yes])
1127 AC_MSG_RESULT($with_scroll_hints)
1128 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1129 fi
1130
1131 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1132 AC_ARG_ENABLE(wgetch-events,
1133         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1134         [with_wgetch_events=$enableval],
1135         [with_wgetch_events=no])
1136 AC_MSG_RESULT($with_wgetch_events)
1137 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1138
1139 ###############################################################################
1140 CF_HELP_MESSAGE(Testing/development Options:)
1141
1142 ###     use option --disable-echo to suppress full display compiling commands
1143 AC_MSG_CHECKING(if you want to display full commands during build)
1144 AC_ARG_ENABLE(echo,
1145         [  --enable-echo           build: display "compiling" commands (default)],
1146         [with_echo=$enableval],
1147         [with_echo=yes])
1148 if test "$with_echo" = yes; then
1149         ECHO_LINK=
1150 else
1151         ECHO_LINK='@ echo linking $@ ... ;'
1152         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1153         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1154 fi
1155 AC_MSG_RESULT($with_echo)
1156 AC_SUBST(ECHO_LINK)
1157
1158 ###     use option --enable-warnings to turn on all gcc warnings
1159 AC_MSG_CHECKING(if you want to see compiler warnings)
1160 AC_ARG_ENABLE(warnings,
1161         [  --enable-warnings       build: turn on GCC compiler warnings],
1162         [with_warnings=$enableval])
1163 AC_MSG_RESULT($with_warnings)
1164
1165 if test "x$with_warnings" = "xyes"; then
1166         ADAFLAGS="$ADAFLAGS -gnatg"
1167         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1168         if test "$cf_with_cxx" = yes ; then
1169                 CF_GXX_WARNINGS(Wno-unused)
1170         fi
1171 fi
1172 CF_GCC_ATTRIBUTES
1173
1174 ###     use option --enable-assertions to turn on generation of assertion code
1175 AC_MSG_CHECKING(if you want to enable runtime assertions)
1176 AC_ARG_ENABLE(assertions,
1177         [  --enable-assertions     test: turn on generation of assertion code],
1178         [with_assertions=$enableval],
1179         [with_assertions=no])
1180 AC_MSG_RESULT($with_assertions)
1181 if test -n "$GCC"
1182 then
1183         if test "$with_assertions" = no
1184         then
1185                 AC_DEFINE(NDEBUG)
1186                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1187         else
1188                 ADAFLAGS="$ADAFLAGS -gnata"
1189         fi
1190 fi
1191
1192 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1193 CF_DISABLE_LEAKS
1194 AC_DEFINE(HAVE_NC_ALLOC_H)
1195
1196 ###     use option --enable-expanded to generate certain macros as functions
1197 AC_ARG_ENABLE(expanded,
1198         [  --enable-expanded       test: generate functions for certain macros],
1199         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1200
1201 ###     use option --disable-macros to suppress macros in favor of functions
1202 AC_ARG_ENABLE(macros,
1203         [  --disable-macros        test: use functions rather than macros],
1204         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1205
1206 # Normally we only add trace() to the debug-library.  Allow this to be
1207 # extended to all models of the ncurses library:
1208 cf_all_traces=no
1209 case "$CFLAGS $CPPFLAGS" in
1210 *-DTRACE*)
1211         cf_all_traces=yes
1212         ;;
1213 esac
1214
1215 AC_MSG_CHECKING(whether to add trace feature to all models)
1216 AC_ARG_WITH(trace,
1217 [  --with-trace            test: add trace() function to all models of ncurses],
1218 [cf_with_trace=$withval],
1219 [cf_with_trace=$cf_all_traces])
1220 AC_MSG_RESULT($cf_with_trace)
1221
1222 if test "$cf_with_trace" = yes ; then
1223         LIB_TRACING=all
1224         ADA_TRACE=TRUE
1225         CF_ADD_CFLAGS(-DTRACE)
1226 else
1227         LIB_TRACING=DEBUG
1228         ADA_TRACE=FALSE
1229 fi
1230
1231 AC_SUBST(ADA_TRACE)
1232
1233 ###     Checks for libraries.
1234 case $cf_cv_system_name in #(vi
1235 *mingw32*) #(vi
1236         ;;
1237 *)
1238 AC_CHECK_FUNC(gettimeofday,
1239         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1240
1241 AC_CHECK_LIB(bsd, gettimeofday,
1242         AC_DEFINE(HAVE_GETTIMEOFDAY)
1243         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
1244         ;;
1245 esac
1246
1247 CF_MATH_LIB(MATH_LIB,sin(x))
1248 AC_SUBST(MATH_LIB)
1249
1250 ###     Checks for header files.
1251 AC_STDC_HEADERS
1252 AC_HEADER_DIRENT
1253 AC_HEADER_TIME
1254 CF_REGEX
1255
1256 dnl These are some other potentially nonportable headers.
1257 AC_CHECK_HEADERS( \
1258 fcntl.h \
1259 getopt.h \
1260 limits.h \
1261 locale.h \
1262 poll.h \
1263 sys/bsdtypes.h \
1264 sys/ioctl.h \
1265 sys/param.h \
1266 sys/poll.h \
1267 sys/select.h \
1268 sys/time.h \
1269 sys/times.h \
1270 ttyent.h \
1271 unistd.h \
1272 wctype.h \
1273 )
1274
1275 # check for ISC (this may also define _POSIX_SOURCE)
1276 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1277 if test "$ISC" = yes ; then
1278         AC_CHECK_LIB(cposix,main)
1279         AC_CHECK_LIB(inet,bzero,LIBS="$LIBS -linet")dnl also 'select()'
1280 fi
1281
1282 CF_SYS_TIME_SELECT
1283
1284 ###     checks for compiler characteristics
1285 AC_LANG_C
1286 AC_C_CONST
1287 CF_C_INLINE(NCURSES_INLINE,1200)
1288 CF_SIG_ATOMIC_T
1289
1290 if test $NCURSES_CHTYPE = auto ; then
1291         CF_TYPEOF_CHTYPE
1292 else
1293         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1294 fi
1295 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1296 AC_SUBST(cf_cv_typeof_chtype)
1297
1298 CF_UNSIGNED_LITERALS
1299 cf_cv_1UL="1"
1300 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1301 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1302 AC_SUBST(cf_cv_1UL)
1303
1304 if test $NCURSES_MMASK_T = auto ; then
1305         cf_cv_typeof_mmask_t=long
1306 else
1307         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1308 fi
1309 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1310 AC_SUBST(cf_cv_typeof_mmask_t)
1311
1312 ###     Checks for external-data
1313 CF_ERRNO
1314 CF_LINK_DATAONLY
1315
1316 ###     Checks for library functions.
1317 AC_CHECK_FUNCS( \
1318 getcwd \
1319 getegid \
1320 geteuid \
1321 getttynam \
1322 issetugid \
1323 poll \
1324 remove \
1325 select \
1326 setbuf \
1327 setbuffer \
1328 setvbuf \
1329 sigaction \
1330 sigvec \
1331 strdup \
1332 strstr \
1333 tcgetpgrp \
1334 times \
1335 vsnprintf \
1336 )
1337 if test "$with_getcap" = "yes" ; then
1338         CF_CGETENT
1339 fi
1340
1341 CF_ISASCII
1342 CF_STRUCT_SIGACTION
1343 CF_FUNC_NANOSLEEP
1344 CF_FUNC_TERMIOS
1345 CF_FUNC_VSSCANF
1346 CF_MKSTEMP
1347
1348 # setup for prototype of fallback for vsscanf()
1349 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1350
1351 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1352 if test "$cross_compiling" = yes ; then
1353         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1354 else
1355         AC_FUNC_SETVBUF_REVERSED
1356 fi
1357 AC_TYPE_SIGNAL
1358 CF_TYPE_SIGACTION
1359 CF_SIZECHANGE
1360 CF_FUNC_MEMMOVE
1361 CF_FUNC_POLL
1362
1363 # special check for test/ditto.c
1364 CF_FUNC_OPENPTY
1365 if test "$cf_cv_func_openpty" != no ; then
1366     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1367     AC_DEFINE(USE_XTERM_PTY)
1368     if test "$cf_cv_lib_util" = yes ; then
1369         TEST_LIBS="-lutil $TEST_LIBS"
1370     fi
1371 fi
1372 AC_SUBST(TEST_LIBS)
1373
1374 if test "$with_hashed_db" != no ; then
1375         AC_DEFINE(USE_HASHED_DB)
1376         CF_HASHED_DB($with_hashed_db)
1377 fi
1378
1379 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1380 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1381         CF_STRIP_G_OPT(CFLAGS)
1382         CF_STRIP_G_OPT(CXXFLAGS)
1383 fi
1384
1385 # Just in case, check if the C compiler has a bool type.
1386 CF_BOOL_DECL(cf_cv_cc_bool_type)
1387
1388 # Check for C++ compiler characteristics (and ensure that it's there!)
1389 if test -n "$CXX" ; then
1390         AC_LANG_CPLUSPLUS
1391         CF_STDCPP_LIBRARY
1392         CF_PROG_CC_C_O(CXX)
1393
1394         case $GXX_VERSION in
1395         1*|2.[0-6]*)
1396                 cf_cxx_library=yes
1397                 ;;
1398         *-2.7*|2.7*)
1399                 CF_GPP_LIBRARY
1400                 ;;
1401         *)
1402                 cf_cxx_library=no
1403                 ;;
1404         esac
1405
1406         AC_CHECK_HEADERS(iostream typeinfo)
1407
1408     if test x"$ac_cv_header_iostream" = xyes ; then
1409         AC_MSG_CHECKING(if iostream uses std-namespace)
1410         AC_TRY_COMPILE([
1411 #include <iostream>
1412 using std::endl;
1413 using std::cerr;],[
1414 cerr << "testing" << endl;
1415 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1416         AC_MSG_RESULT($cf_iostream_namespace)
1417         if test "$cf_iostream_namespace" = yes ; then
1418             AC_DEFINE(IOSTREAM_NAMESPACE)
1419         fi
1420     fi
1421
1422         CF_BOOL_DECL
1423         CF_BOOL_SIZE
1424         CF_ETIP_DEFINES
1425         CF_CPP_PARAM_INIT
1426         CF_CPP_STATIC_CAST
1427
1428         CXX_AR='$(AR)'
1429         CXX_ARFLAGS='$(ARFLAGS)'
1430         case $cf_cv_system_name in #(vi
1431         irix*) #(vi
1432             if test "$GXX" != yes ; then
1433                 CXX_AR='$(CXX)'
1434                 CXX_ARFLAGS='-ar -o'
1435             fi
1436             ;;
1437         sco3.2v5*) #(vi
1438             CXXLDFLAGS="-u main"
1439             ;;
1440         solaris2*)
1441             if test "$GXX" != yes ; then
1442                 CXX_AR='$(CXX)'
1443                 CXX_ARFLAGS='-xar -o'
1444             fi
1445             ;;
1446         esac
1447         AC_SUBST(CXXLDFLAGS)
1448         AC_SUBST(CXX_AR)
1449         AC_SUBST(CXX_ARFLAGS)
1450 else
1451         cf_cxx_library=no
1452         cf_cv_builtin_bool=1
1453
1454         # Just because we are not configuring against C++ right now does not
1455         # mean that a user will not want to use C++.  Some distributors disable
1456         # the C++ portion of this configuration as a shortcut (or just to avoid
1457         # compiling the demo in the c++ directory).  So we need a reasonable
1458         # default for the 'bool' type.
1459         #
1460         # Caveat: since the storage of the bool type is not standardized, it
1461         # may change.
1462
1463         if test "$NCURSES_BOOL" != auto ; then
1464                 cf_cv_type_of_bool=$NCURSES_BOOL
1465                 cf_cv_header_stdbool_h=0
1466         else
1467                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1468                         CF_BOOL_SIZE
1469                 else
1470                         AC_MSG_CHECKING(for fallback type of bool)
1471                         case "$host_cpu" in #(vi
1472                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1473                         *)      cf_cv_type_of_bool=int  ;;
1474                         esac
1475                         AC_MSG_RESULT($cf_cv_type_of_bool)
1476                 fi
1477         fi
1478 fi
1479 AC_SUBST(CXXLIBS)
1480
1481 # If the C compiler did not declare bool, and we did not determine that the C++
1482 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1483 # ncurses library use the same type as C++ bool.  Note that this allows one to
1484 # specify the type of bool in a configure-script option and postpone
1485 # integration with the C++ compiler provided that the types are compatible.
1486 USE_CXX_BOOL=1
1487 if test $cf_cv_cc_bool_type = 1
1488 then
1489         # oops: C has a bool.  Unlikely, but C++ could differ.
1490         USE_CXX_BOOL=0
1491 elif test $cf_cv_builtin_bool = 0
1492 then
1493         # C++ has no bool
1494         USE_CXX_BOOL=0
1495 else
1496         # this is the normal case
1497         USE_CXX_BOOL='defined(__cplusplus)'
1498 fi
1499 AC_SUBST(USE_CXX_BOOL)
1500
1501 CF_HELP_MESSAGE(Ada95 Binding Options:)
1502
1503 dnl If the Ada95 source-tree is present, add that to the build unless it will
1504 dnl not work, or was not requested.
1505 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1506
1507 dnl libtool does not know anything about GNAT, though a change made in 1998
1508 dnl provided for it "someday".  Disable the ada subtree if we are using
1509 dnl libtool -TD 20070714
1510 if test "$cf_with_ada" != "no" ; then
1511     if test "$with_libtool" != "no"; then
1512         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1513         cf_with_ada=no
1514     fi
1515 fi
1516
1517 dnl Check for availability of GNU Ada Translator (GNAT).
1518 dnl At the moment we support no other Ada95 compiler.
1519 if test "$cf_with_ada" != "no" ; then
1520 cf_ada_make=gnatmake
1521 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
1522 if test "$ac_cv_prog_gnat_exists" = no; then
1523    cf_ada_make=
1524 else
1525    CF_GNAT_VERSION
1526    AC_CHECK_PROG(M4_exists, m4, yes, no)
1527    if test "$ac_cv_prog_M4_exists" = no; then
1528       cf_cv_prog_gnat_correct=no
1529       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
1530    fi
1531    if test "$cf_cv_prog_gnat_correct" = yes; then
1532       AC_MSG_CHECKING(if GNAT works)
1533       CF_GNAT_TRY_RUN([procedure conftest;],
1534 [with Text_IO;
1535 with GNAT.OS_Lib;
1536 procedure conftest is
1537 begin
1538    Text_IO.Put ("Hello World");
1539    Text_IO.New_Line;
1540    GNAT.OS_Lib.OS_Exit (0);
1541 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
1542       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
1543    fi
1544 fi
1545 if test "$cf_cv_prog_gnat_correct" = yes; then
1546    ADAFLAGS="-O3 -gnatpn $ADAFLAGS"
1547
1548    AC_MSG_CHECKING(if GNAT pragma Unreferenced works)
1549    CF_GNAT_TRY_LINK([procedure conftest;],
1550 [with Text_IO;
1551 with GNAT.OS_Lib;
1552 procedure conftest is
1553    test : Integer;
1554    pragma Unreferenced (test);
1555 begin
1556    test := 1;
1557    Text_IO.Put ("Hello World");
1558    Text_IO.New_Line;
1559    GNAT.OS_Lib.OS_Exit (0);
1560 end conftest;],[cf_cv_pragma_unreferenced=yes],[cf_cv_pragma_unreferenced=no])
1561    AC_MSG_RESULT($cf_cv_pragma_unreferenced)
1562
1563    # if the pragma is supported, use it (needed in the Trace code).
1564    if test $cf_cv_pragma_unreferenced = yes ; then
1565       PRAGMA_UNREF=TRUE
1566    else
1567       PRAGMA_UNREF=FALSE
1568    fi
1569
1570    AC_ARG_WITH(ada-compiler,
1571         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
1572         [cf_ada_compiler=$withval],
1573         [cf_ada_compiler=gnatmake])
1574
1575    cf_ada_package=terminal_interface
1576
1577    AC_SUBST(cf_ada_make)
1578    AC_SUBST(cf_ada_compiler)
1579    AC_SUBST(cf_ada_package)
1580    AC_SUBST(ADAFLAGS)
1581    AC_SUBST(cf_compile_generics)
1582    AC_SUBST(cf_generic_objects)
1583    AC_SUBST(PRAGMA_UNREF)
1584
1585    CF_WITH_PATH(ada-include,
1586        [  --with-ada-include=DIR  Ada includes are in DIR],
1587        ADA_INCLUDE,
1588        PREFIX/lib/ada/adainclude,
1589        [$]prefix/lib/ada/adainclude)
1590    AC_SUBST(ADA_INCLUDE)
1591
1592    CF_WITH_PATH(ada-objects,
1593        [  --with-ada-objects=DIR  Ada objects are in DIR],
1594        ADA_OBJECTS,
1595        PREFIX/lib/ada/adalib,
1596        [$]prefix/lib/ada/adalib)
1597    AC_SUBST(ADA_OBJECTS)
1598
1599 fi
1600 fi
1601 else
1602    cf_with_ada=no
1603 fi
1604
1605 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1606 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1607 ###
1608 ### ticlib modules may be a separate library, otherwise contained in termlib.
1609 ### termlib modules may be a separate library, otherwise contained in ncurses.
1610 ###
1611 ### The of "+" or " " between the tokens controls the way the script
1612 ### chooses to split module lists into libraries.
1613 ###
1614 ### (see CF_LIB_RULES).
1615 AC_MSG_CHECKING(for library subsets)
1616 LIB_SUBSETS=
1617
1618 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1619         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1620         if test "$with_ticlib" != no ; then
1621                 LIB_SUBSETS="${LIB_SUBSETS} "
1622         else
1623                 LIB_SUBSETS="${LIB_SUBSETS}+"
1624         fi
1625 fi
1626
1627 LIB_SUBSETS="${LIB_SUBSETS}termlib+port_drivers"
1628
1629 case $cf_cv_system_name in #(vi
1630 *mingw32*) #(vi
1631         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1632         ;;
1633 *) #(vi
1634         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1635         ;;
1636 esac
1637
1638 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1639 if test "$with_termlib" != no ; then
1640         LIB_SUBSETS="${LIB_SUBSETS} "
1641 else
1642         LIB_SUBSETS="${LIB_SUBSETS}+"
1643 fi
1644
1645 LIB_SUBSETS="${LIB_SUBSETS}base"
1646
1647 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1648 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1649
1650 AC_MSG_RESULT($LIB_SUBSETS)
1651
1652 ### Construct the list of include-directories to be generated
1653 CF_INCLUDE_DIRS
1654 CF_ADA_INCLUDE_DIRS
1655
1656 ### Build up pieces for makefile rules
1657 AC_MSG_CHECKING(default library suffix)
1658 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1659 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1660 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1661
1662 AC_MSG_CHECKING(default library-dependency suffix)
1663 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1664 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1665 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1666
1667 AC_MSG_CHECKING(default object directory)
1668 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1669 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1670 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1671
1672 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1673 if test "$cf_with_cxx" = yes ; then
1674 AC_MSG_CHECKING(c++ library-dependency suffix)
1675 if test "$with_libtool" != "no"; then
1676         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1677 else
1678         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1679 fi
1680 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1681 AC_SUBST(CXX_LIB_SUFFIX)
1682 fi
1683
1684 # do not want -ldl in build except as needed for -lncurses dependency
1685 if test "$with_dlsym" = yes ; then
1686 if test $DFT_LWR_MODEL = shared || \
1687    test $DFT_LWR_MODEL = libtool ; then
1688         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1689 fi
1690 fi
1691 ### Set up low-level terminfo dependencies for makefiles.
1692
1693 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1694 # do not need libdl
1695 TICS_LIST=
1696 if test "$with_dlsym" = yes ; then
1697         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1698 fi
1699
1700 if test "$with_ticlib" != no ; then
1701
1702         if test "$with_ticlib" != yes ; then
1703                 TICS_NAME=$with_ticlib
1704                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1705                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1706                 TICS_LIB_SUFFIX="${with_ticlib}"
1707         else
1708                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1709                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1710                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1711         fi
1712         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1713 else
1714         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1715 fi
1716 AC_SUBST(TICS_ARG_SUFFIX)
1717 AC_SUBST(TICS_DEP_SUFFIX)
1718 AC_SUBST(TICS_LIB_SUFFIX)
1719 AC_SUBST(TICS_ARGS)
1720
1721 if test "$with_termlib" != no ; then
1722
1723         if test "$with_termlib" != yes ; then
1724                 TINFO_NAME=$with_termlib
1725                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1726                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1727                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1728                 TINFO_LIB_SUFFIX="${with_termlib}"
1729         else
1730                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1731                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1732                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1733                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1734         fi
1735
1736         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1737         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1738         if test "$DFT_LWR_MODEL" = "libtool"; then
1739                 TEST_ARGS="${TEST_DEPS}"
1740                 TEST_ARG2="${TEST_DEP2}"
1741                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1742                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1743                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1744         else
1745                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1746                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1747                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1748                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1749                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1750         fi
1751 else
1752         # the next lines are needed for linking libtic over libncurses
1753         TINFO_NAME=${LIB_NAME}
1754         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1755         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1756         if test "$with_tic_depends" = yes ; then
1757                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1758         else
1759                 TICS_LIST="$SHLIB_LIST"
1760         fi
1761
1762         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1763 fi
1764
1765 if test "$DFT_LWR_MODEL" = shared ; then
1766         case $cf_cv_system_name in #(vi
1767         cygwin*)
1768                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1769                 TINFO_SUFFIX=.dll
1770                 ;;
1771         esac
1772 fi
1773
1774 AC_SUBST(TINFO_ARG_SUFFIX)
1775 AC_SUBST(TINFO_DEP_SUFFIX)
1776 AC_SUBST(TINFO_LIB_SUFFIX)
1777 AC_SUBST(TINFO_ARGS)
1778
1779 if test "$with_dlsym" = yes ; then
1780         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1781 fi
1782
1783 if test "$DFT_LWR_MODEL" = "libtool"; then
1784     OBJEXT=lo
1785 fi
1786
1787 # needed for Ada95
1788 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1789 AC_SUBST(TINFO_ARGS2)
1790
1791 case $DFT_LWR_MODEL in
1792 normal|debug|profile)
1793         CF_LDFLAGS_STATIC
1794         ;;
1795 esac
1796
1797 AC_MSG_CHECKING(where we will install curses.h)
1798 test "$with_overwrite" = no && \
1799 test "x$includedir" = 'x${prefix}/include' && \
1800         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1801 AC_MSG_RESULT($includedir)
1802
1803 ### Resolve a conflict between normal and wide-curses by forcing applications
1804 ### that will need libutf8 to add it to their configure script.
1805 if test "$with_overwrite" != no ; then
1806 if test "$NCURSES_LIBUTF8" = 1 ; then
1807         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1808         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1809 fi
1810 fi
1811 WITH_OVERWRITE=$with_overwrite
1812
1813 AC_SUBST(WITH_OVERWRITE)
1814 AC_SUBST(TICS_LIST)
1815 AC_SUBST(TINFO_LIST)
1816 AC_SUBST(SHLIB_LIST)
1817
1818 # used to separate tack out of the tree
1819 NCURSES_TREE=
1820 AC_SUBST(NCURSES_TREE)
1821
1822 ### predefined stuff for the test programs
1823 AC_DEFINE(HAVE_SLK_COLOR)
1824
1825 ### Construct the list of subdirectories for which we'll customize makefiles
1826 ### with the appropriate compile-rules.
1827
1828 CF_SRC_MODULES($modules_to_build)
1829
1830 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1831    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1832 fi
1833
1834 CF_DIRS_TO_MAKE
1835
1836 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR')
1837
1838 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1839
1840 ### Now that we're done running tests, add the compiler-warnings, if any
1841 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1842
1843 ### If we're building with rpath, try to link non-standard libs that way too.
1844 if test "$DFT_LWR_MODEL" = "shared"; then
1845   CF_RPATH_HACK
1846 fi
1847
1848 ### Define substitutions for header files to avoid name-pollution
1849 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1850 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1851 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1852
1853 ################################################################################
1854 test "$use_database" = yes && \
1855 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1856
1857 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1858
1859 if test x"$enable_pc_files" = xyes ; then \
1860 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1861 MAKE_PC_FILES=
1862 else
1863 MAKE_PC_FILES="#"
1864 fi
1865 AC_SUBST(MAKE_PC_FILES)
1866
1867 AC_OUTPUT( \
1868         include/MKterm.h.awk \
1869         include/curses.head:include/curses.h.in \
1870         include/ncurses_dll.h \
1871         include/termcap.h \
1872         include/unctrl.h \
1873         $SUB_MAKEFILES \
1874         Makefile,[
1875 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1876 CF_LIB_RULES($SRC_SUBDIRS)
1877 ],[
1878 ### Special initialization commands, used to pass information from the
1879 ### configuration-run into config.status
1880
1881 AWK="$AWK"
1882 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1883 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1884 ECHO_LINK="$ECHO_LINK"
1885 LDCONFIG="$LDCONFIG"
1886 LIB_NAME="$LIB_NAME"
1887 LIB_SUBSETS="$LIB_SUBSETS"
1888 LIB_SUFFIX="$LIB_SUFFIX"
1889 LIB_TRACING="$LIB_TRACING"
1890 MAKE_TERMINFO="$MAKE_TERMINFO"
1891 NCURSES_MAJOR="$NCURSES_MAJOR"
1892 NCURSES_MINOR="$NCURSES_MINOR"
1893 NCURSES_OSPEED="$NCURSES_OSPEED"
1894 NCURSES_PATCH="$NCURSES_PATCH"
1895 SRC_SUBDIRS="$SRC_SUBDIRS"
1896 TERMINFO="$TERMINFO"
1897 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1898 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1899 TICS_NAME="$TICS_NAME"
1900 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1901 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1902 TINFO_NAME="$TINFO_NAME"
1903 TINFO_SUFFIX="$TINFO_SUFFIX"
1904 WITH_CURSES_H="$with_curses_h"
1905 WITH_ECHO="$with_echo"
1906 WITH_OVERWRITE="$with_overwrite"
1907 cf_LIST_MODELS="$cf_list_models"
1908 cf_cv_abi_version="$cf_cv_abi_version"
1909 cf_cv_do_relink="$cf_cv_do_relink"
1910 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1911 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1912 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1913 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1914 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1915 cf_cv_rel_version="$cf_cv_rel_version"
1916 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1917 cf_cv_shared_soname='$cf_cv_shared_soname'
1918 cf_cv_shlib_version="$cf_cv_shlib_version"
1919 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1920 cf_cv_system_name="$cf_cv_system_name"
1921 cf_with_cxx_binding="$cf_with_cxx_binding"
1922 cf_with_manpages="$cf_with_manpages"
1923 host="$host"
1924 target="$target"
1925
1926 ],cat)dnl
1927 ${MAKE-make} preinstall