configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2011,2012 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.543 2012/02/18 21:31:19 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.543 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to install manpages)
 126 AC_ARG_WITH(manpages,
 127         [  --without-manpages      suppress install of manpages],
 128         [cf_with_manpages=$withval],
 129         [cf_with_manpages=yes])
 130 AC_MSG_RESULT($cf_with_manpages)
 131
 132 AC_MSG_CHECKING(if you want to build programs such as tic)
 133 AC_ARG_WITH(progs,
 134         [  --without-progs         suppress build with programs (e.g., tic)],
 135         [cf_with_progs=$withval],
 136         [cf_with_progs=yes])
 137 AC_MSG_RESULT($cf_with_progs)
 138
 139 AC_MSG_CHECKING(if you want to build test-programs)
 140 AC_ARG_WITH(tests,
 141         [  --without-tests         suppress build with test-programs],
 142         [cf_with_tests=$withval],
 143         [cf_with_tests=yes])
 144 AC_MSG_RESULT($cf_with_tests)
 145
 146 AC_MSG_CHECKING(if you wish to install curses.h)
 147 AC_ARG_WITH(curses-h,
 148         [  --without-curses-h      install curses.h as ncurses.h only],
 149         [with_curses_h=$withval],
 150         [with_curses_h=yes])
 151 AC_MSG_RESULT($with_curses_h)
 152
 153 modules_to_build="ncurses"
 154 if test "X$cf_with_progs" != Xno ; then
 155 modules_to_build="$modules_to_build progs tack"
 156 fi
 157 modules_to_build="$modules_to_build panel menu form"
 158
 159 AC_ARG_PROGRAM
 160
 161 CF_PROG_AWK
 162 CF_PROG_EGREP
 163 CF_PROG_INSTALL
 164 CF_PROG_LINT
 165 CF_PROG_LN_S
 166
 167 AC_SYS_LONG_FILE_NAMES
 168
 169 # if we find pkg-config, check if we should install the ".pc" files.
 170 CF_PKG_CONFIG
 171 CF_WITH_PKG_CONFIG_LIBDIR
 172 CF_ENABLE_PC_FILES
 173
 174 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 175 AC_ARG_ENABLE(mixed-case,
 176         [  --enable-mixed-case     tic should assume mixed-case filenames],
 177         [enable_mixedcase=$enableval],
 178         [enable_mixedcase=auto])
 179 AC_MSG_RESULT($enable_mixedcase)
 180 if test "$enable_mixedcase" = "auto" ; then
 181     CF_MIXEDCASE_FILENAMES
 182 else
 183     cf_cv_mixedcase=$enable_mixedcase
 184     if test "$enable_mixedcase" = "yes" ; then
 185         AC_DEFINE(MIXEDCASE_FILENAMES)
 186     fi
 187 fi
 188
 189 # do this after mixed-case option (tags/TAGS is not as important as tic).
 190 AC_PROG_MAKE_SET
 191 CF_MAKE_TAGS
 192 CF_MAKEFLAGS
 193
 194 dnl These are standard among *NIX systems, but not when cross-compiling
 195 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 196 AC_CHECK_TOOL(LD, ld, ld)
 197 AC_CHECK_TOOL(AR, ar, ar)
 198 CF_AR_FLAGS
 199
 200 dnl Special option for use by system-builders: the install-prefix is used to
 201 dnl adjust the location into which the actual install is done, so that an
 202 dnl archive can be built without modifying the host system's configuration.
 203 AC_MSG_CHECKING(if you have specified an install-prefix)
 204 AC_ARG_WITH(install-prefix,
 205         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 206         [case "$withval" in #(vi
 207         yes|no) #(vi
 208                 ;;
 209         *)      DESTDIR="$withval"
 210                 ;;
 211         esac])
 212 AC_MSG_RESULT($DESTDIR)
 213 AC_SUBST(DESTDIR)
 214
 215 ###############################################################################
 216 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 217 # If we're cross-compiling, allow the user to override the tools and their
 218 # options.  The configure script is oriented toward identifying the host
 219 # compiler, etc., but we need a build compiler to generate parts of the source.
 220 CF_BUILD_CC
 221
 222 ###############################################################################
 223 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 224
 225 ### Options to allow the user to specify the set of libraries which are used.
 226 ### Use "--without-normal --with-shared" to allow the default model to be
 227 ### shared, for example.
 228 cf_list_models=""
 229 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 230
 231 CF_WITH_LIBTOOL
 232 if test "$with_libtool" != "no" ; then
 233
 234 cf_list_models="$cf_list_models libtool"
 235
 236 else
 237
 238 AC_MSG_CHECKING(if you want to build shared libraries)
 239 AC_ARG_WITH(shared,
 240         [  --with-shared           generate shared-libraries],
 241         [with_shared=$withval],
 242         [with_shared=no])
 243 AC_MSG_RESULT($with_shared)
 244 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 245
 246 AC_MSG_CHECKING(if you want to build static libraries)
 247 AC_ARG_WITH(normal,
 248         [  --with-normal           generate normal-libraries (default)],
 249         [with_normal=$withval],
 250         [with_normal=yes])
 251 AC_MSG_RESULT($with_normal)
 252 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 253
 254 AC_MSG_CHECKING(if you want to build debug libraries)
 255 AC_ARG_WITH(debug,
 256         [  --with-debug            generate debug-libraries (default)],
 257         [with_debug=$withval],
 258         [with_debug=yes])
 259 AC_MSG_RESULT($with_debug)
 260 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 261
 262 AC_MSG_CHECKING(if you want to build profiling libraries)
 263 AC_ARG_WITH(profile,
 264         [  --with-profile          generate profile-libraries],
 265         [with_profile=$withval],
 266         [with_profile=no])
 267 AC_MSG_RESULT($with_profile)
 268 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 269
 270 fi
 271
 272 ###############################################################################
 273
 274 AC_MSG_CHECKING(for specified models)
 275 test -z "$cf_list_models" && cf_list_models=normal
 276 dnl If we use libtool to generate libraries, then it must be the only
 277 dnl specified model.
 278 test "$with_libtool" != "no" && cf_list_models=libtool
 279 AC_MSG_RESULT($cf_list_models)
 280
 281 ### Use the first model as the default, and save its suffix for use in building
 282 ### up test-applications.
 283 AC_MSG_CHECKING(for default model)
 284 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 285 AC_MSG_RESULT($DFT_LWR_MODEL)
 286
 287 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 288
 289 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 290 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 291
 292 TICS_NAME=tic
 293 AC_SUBST(TICS_NAME)
 294
 295 TINFO_NAME=tinfo
 296 AC_SUBST(TINFO_NAME)
 297
 298 LIB_NAME=ncurses
 299 AC_SUBST(LIB_NAME)
 300
 301 LIB_DIR=../lib
 302 LIB_2ND=../../lib
 303
 304 CF_WITH_LIB_PREFIX(cf_prefix)
 305
 306 LIB_SUFFIX=
 307 AC_SUBST(LIB_SUFFIX)
 308
 309 ###############################################################################
 310
 311 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 312 AC_ARG_WITH(termlib,
 313         [  --with-termlib          generate separate terminfo library],
 314         [with_termlib=$withval],
 315         [with_termlib=no])
 316 AC_MSG_RESULT($with_termlib)
 317
 318 AC_MSG_CHECKING(if you want to build a separate tic library)
 319 AC_ARG_WITH(ticlib,
 320         [  --with-ticlib           generate separate tic library],
 321         [with_ticlib=$withval],
 322         [with_ticlib=no])
 323 AC_MSG_RESULT($with_ticlib)
 324
 325 ### Checks for special libraries, must be done up-front.
 326 SHLIB_LIST=""
 327 CF_WITH_GPM
 328 if test "$with_gpm" != no ; then
 329         AC_MSG_CHECKING(if you want to load GPM dynamically)
 330         AC_ARG_WITH(dlsym,
 331                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 332                 [with_dlsym=$withval],
 333                 [with_dlsym=yes])
 334         AC_MSG_RESULT($with_dlsym)
 335         if test "$with_dlsym" = yes ; then
 336                 CF_FUNC_DLSYM
 337                 if test "$with_gpm" != yes ; then
 338                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 339                         cf_cv_gpm_soname="$with_gpm"
 340                 else
 341                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 342                 fi
 343                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 344                 SHLIB_LIST="-ldl $SHLIB_LIST"
 345         else
 346                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 347                 CF_ADD_LIB(gpm,TEST_LIBS)
 348         fi
 349         AC_DEFINE(HAVE_LIBGPM)
 350         CF_CHECK_GPM_WGETCH
 351 fi
 352
 353 CF_WITH_SYSMOUSE
 354
 355 dnl Not all ports of gcc support the -g option
 356
 357 if test X"$CC_G_OPT" = X"" ; then
 358         CC_G_OPT='-g'
 359         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 360 fi
 361 AC_SUBST(CC_G_OPT)
 362
 363 if test X"$CXX_G_OPT" = X"" ; then
 364         CXX_G_OPT='-g'
 365         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 366 fi
 367 AC_SUBST(CXX_G_OPT)
 368
 369 AC_MSG_CHECKING(for default loader flags)
 370 case $DFT_LWR_MODEL in
 371 libtool) LD_MODEL=''   ;;
 372 normal)  LD_MODEL=''   ;;
 373 debug)   LD_MODEL=$CC_G_OPT ;;
 374 profile) LD_MODEL='-pg';;
 375 shared)  LD_MODEL=''   ;;
 376 esac
 377 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 378 AC_MSG_RESULT($LD_MODEL)
 379
 380 case $DFT_LWR_MODEL in
 381 shared)
 382 CF_ENABLE_RPATH
 383 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 384 AC_ARG_ENABLE(relink,
 385 [  --disable-relink        relink shared libraries during install],
 386 [cf_cv_do_relink=$enableval],
 387 [cf_cv_do_relink=yes])
 388 AC_MSG_RESULT($cf_cv_do_relink)
 389         ;;
 390 esac
 391
 392 CF_SHARED_OPTS
 393 if test "$CC_SHARED_OPTS" = "unknown"; then
 394         for model in $cf_list_models; do
 395                 if test "$model" = "shared"; then
 396                         AC_ERROR(Shared libraries are not supported in this version)
 397                 fi
 398         done
 399 fi
 400
 401 ### If we're building with rpath, try to link non-standard libs that way too.
 402 if test "$DFT_LWR_MODEL" = "shared"; then
 403         CF_DISABLE_RPATH_HACK
 404 fi
 405
 406 ###############################################################################
 407 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 408
 409 ###     use option --disable-overwrite to leave out the link to -lcurses
 410 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 411 AC_ARG_ENABLE(overwrite,
 412         [  --disable-overwrite     leave out the link to -lcurses],
 413         [with_overwrite=$enableval],
 414         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 415 AC_MSG_RESULT($with_overwrite)
 416
 417 AC_MSG_CHECKING(if external terminfo-database is used)
 418 AC_ARG_ENABLE(database,
 419         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 420         [use_database=$enableval],
 421         [use_database=yes])
 422 AC_MSG_RESULT($use_database)
 423
 424 case $host_os in #(vi
 425 os2*) #(vi
 426         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 427         ;;
 428 *) #(vi
 429         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 430         ;;
 431 esac
 432 AC_SUBST(TERMINFO_SRC)
 433
 434 if test "$use_database" != no ; then
 435         AC_DEFINE(USE_DATABASE)
 436
 437         AC_MSG_CHECKING(which terminfo source-file will be installed)
 438         AC_ARG_WITH(database,
 439                 [  --with-database=XXX     specify terminfo source to install],
 440                 [TERMINFO_SRC=$withval])
 441         AC_MSG_RESULT($TERMINFO_SRC)
 442
 443         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 444         AC_ARG_WITH(hashed-db,
 445                 [  --with-hashed-db        specify hashed-database library],,
 446                 [with_hashed_db=no])
 447         AC_MSG_RESULT($with_hashed_db)
 448 else
 449         with_hashed_db=no
 450 fi
 451
 452 AC_MSG_CHECKING(for list of fallback descriptions)
 453 AC_ARG_WITH(fallbacks,
 454         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 455         [with_fallback=$withval],
 456         [with_fallback=])
 457 AC_MSG_RESULT($with_fallback)
 458 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 459 AC_SUBST(FALLBACK_LIST)
 460
 461 AC_MSG_CHECKING(if you want modern xterm or antique)
 462 AC_ARG_WITH(xterm-new,
 463         [  --without-xterm-new     specify if xterm terminfo should be old version],
 464         [with_xterm_new=$withval],
 465         [with_xterm_new=yes])
 466 case $with_xterm_new in
 467 no)     with_xterm_new=xterm-old;;
 468 *)      with_xterm_new=xterm-new;;
 469 esac
 470 AC_MSG_RESULT($with_xterm_new)
 471 WHICH_XTERM=$with_xterm_new
 472 AC_SUBST(WHICH_XTERM)
 473
 474 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 475 AC_ARG_WITH(xterm-kbs,
 476         [  --with-xterm-kbs=XXX     specify if xterm backspace sends BS or DEL],
 477         [with_xterm_kbs=$withval],
 478         [with_xterm_kbs=BS])
 479 case x$with_xterm_kbs in
 480 xyes|xno|xBS|xbs|x8)
 481         with_xterm_kbs=BS
 482         ;;
 483 xDEL|xdel|x127)
 484         with_xterm_kbs=DEL
 485         ;;
 486 *)
 487         with_xterm_kbs=$withval
 488         ;;
 489 esac
 490 AC_MSG_RESULT($with_xterm_kbs)
 491 XTERM_KBS=$with_xterm_kbs
 492 AC_SUBST(XTERM_KBS)
 493
 494 MAKE_TERMINFO=
 495 if test "$use_database" = no ; then
 496         TERMINFO="${datadir}/terminfo"
 497         MAKE_TERMINFO="#"
 498 else
 499
 500 AC_MSG_CHECKING(for list of terminfo directories)
 501 CF_WITH_PATHLIST(terminfo-dirs,
 502         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 503         TERMINFO_DIRS,
 504         DATADIR/terminfo,
 505         ${datadir}/terminfo)
 506 AC_MSG_RESULT($TERMINFO_DIRS)
 507 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 508
 509 AC_MSG_CHECKING(for default terminfo directory)
 510 CF_WITH_PATH(default-terminfo-dir,
 511         [  --with-default-terminfo-dir=DIR default terminfo directory],
 512         TERMINFO,
 513         DATADIR/terminfo,
 514         ${datadir}/terminfo)
 515 AC_MSG_RESULT($TERMINFO)
 516 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 517
 518 fi
 519
 520 AC_SUBST(TERMINFO)
 521 AC_SUBST(MAKE_TERMINFO)
 522
 523 ###     use option --disable-big-core to make tic run on small machines
 524 ###     We need 4Mb, check if we can allocate 50% more than that.
 525 AC_MSG_CHECKING(if big-core option selected)
 526 AC_ARG_ENABLE(big-core,
 527         [  --disable-big-core      assume machine has little memory],
 528         [with_big_core=$enableval],
 529         [AC_TRY_RUN([
 530 #include <stdlib.h>
 531 #include <string.h>
 532 int main() {
 533         unsigned long n = 6000000L;
 534         char *s = malloc(n);
 535         if (s != 0)
 536                 s[0] = s[n-1] = 0;
 537         ${cf_cv_main_return:-return}(s == 0);
 538 }],
 539         [with_big_core=yes],
 540         [with_big_core=no],
 541         [with_big_core=no])])
 542 AC_MSG_RESULT($with_big_core)
 543 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 544
 545 ### ISO C only guarantees 512-char strings, we have tables which load faster
 546 ### when constructed using "big" strings.  More than the C compiler, the awk
 547 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 548 AC_MSG_CHECKING(if big-strings option selected)
 549 AC_ARG_ENABLE(big-strings,
 550         [  --disable-big-strings   assume compiler has only standard-size strings],
 551         [with_big_strings=$enableval],
 552         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 553 AC_MSG_RESULT($with_big_strings)
 554
 555 USE_BIG_STRINGS=0
 556 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
 557 AC_SUBST(USE_BIG_STRINGS)
 558
 559 ###     use option --enable-termcap to compile in the termcap fallback support
 560 AC_MSG_CHECKING(if you want termcap-fallback support)
 561 AC_ARG_ENABLE(termcap,
 562         [  --enable-termcap        compile in termcap fallback support],
 563         [with_termcap=$enableval],
 564         [with_termcap=no])
 565 AC_MSG_RESULT($with_termcap)
 566
 567 if test "$with_termcap" != "yes" ; then
 568         if test "$use_database" = no ; then
 569                 if test -z "$with_fallback" ; then
 570                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 571                 fi
 572         fi
 573         AC_DEFINE(PURE_TERMINFO)
 574 else
 575
 576 if test "$with_ticlib" != no ; then
 577         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 578 fi
 579
 580 AC_DEFINE(USE_TERMCAP)
 581 AC_MSG_CHECKING(for list of termcap files)
 582 CF_WITH_PATHLIST(termpath,
 583         [  --with-termpath=XXX     specify list of termcap files],
 584         TERMPATH,
 585         /etc/termcap:/usr/share/misc/termcap)
 586 AC_MSG_RESULT($TERMPATH)
 587 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 588
 589 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 590 AC_MSG_CHECKING(if fast termcap-loader is needed)
 591 AC_ARG_ENABLE(getcap,
 592         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 593         [with_getcap=$enableval],
 594         [with_getcap=no])
 595 AC_MSG_RESULT($with_getcap)
 596 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 597
 598 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 599 AC_ARG_ENABLE(getcap-cache,
 600         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 601         [with_getcap_cache=$enableval],
 602         [with_getcap_cache=no])
 603 AC_MSG_RESULT($with_getcap_cache)
 604 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 605
 606 fi
 607
 608 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 609 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 610 AC_ARG_ENABLE(home-terminfo,
 611         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 612         [with_home_terminfo=$enableval],
 613         [with_home_terminfo=yes])
 614 AC_MSG_RESULT($with_home_terminfo)
 615 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 616
 617 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 618 AC_ARG_ENABLE(root-environ,
 619         [  --disable-root-environ  restrict environment when running as root],
 620         [with_root_environ=$enableval],
 621         [with_root_environ=yes])
 622 AC_MSG_RESULT($with_root_environ)
 623 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 624
 625 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 626 ###   to reduce storage requirements for the terminfo database.
 627 CF_LINK_FUNCS
 628
 629 with_links=no
 630 with_symlinks=no
 631
 632 # soft links (symbolic links) are useful for some systems where hard links do
 633 # not work, or to make it simpler to copy terminfo trees around.
 634 if test "$ac_cv_func_symlink" = yes ; then
 635     AC_MSG_CHECKING(if tic should use symbolic links)
 636     AC_ARG_ENABLE(symlinks,
 637         [  --enable-symlinks       make tic use symbolic links not hard links],
 638         [with_symlinks=$enableval],
 639         [with_symlinks=no])
 640     AC_MSG_RESULT($with_symlinks)
 641 fi
 642
 643 # If we have hard links and did not choose to use soft links instead, there is
 644 # no reason to make this choice optional - use the hard links.
 645 if test "$with_symlinks" = no ; then
 646     AC_MSG_CHECKING(if tic should use hard links)
 647     if test "$ac_cv_func_link" = yes ; then
 648         with_links=yes
 649     else
 650         with_links=no
 651     fi
 652     AC_MSG_RESULT($with_links)
 653 fi
 654
 655 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 656 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 657
 658 ###   use option --enable-broken-linker to force on use of broken-linker support
 659 AC_MSG_CHECKING(if you want broken-linker support code)
 660 AC_ARG_ENABLE(broken_linker,
 661         [  --enable-broken_linker  compile with broken-linker support code],
 662         [with_broken_linker=$enableval],
 663         [with_broken_linker=${BROKEN_LINKER:-no}])
 664 AC_MSG_RESULT($with_broken_linker)
 665
 666 BROKEN_LINKER=0
 667 if test "$with_broken_linker" = yes ; then
 668         AC_DEFINE(BROKEN_LINKER)
 669         BROKEN_LINKER=1
 670 elif test "$DFT_LWR_MODEL" = shared ; then
 671         case $cf_cv_system_name in #(vi
 672         cygwin*)
 673                 AC_DEFINE(BROKEN_LINKER)
 674                 BROKEN_LINKER=1
 675                 CF_VERBOSE(cygwin linker is broken anyway)
 676                 ;;
 677         esac
 678 fi
 679 AC_SUBST(BROKEN_LINKER)
 680
 681 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 682 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 683 AC_ARG_ENABLE(bsdpad,
 684         [  --enable-bsdpad         recognize BSD-style prefix padding],
 685         [with_bsdpad=$enableval],
 686         [with_bsdpad=no])
 687 AC_MSG_RESULT($with_bsdpad)
 688 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 689
 690 ###   use option --enable-widec to turn on use of wide-character support
 691 NCURSES_CH_T=chtype
 692 NCURSES_LIBUTF8=0
 693
 694 NEED_WCHAR_H=0
 695 NCURSES_MBSTATE_T=0
 696 NCURSES_WCHAR_T=0
 697 NCURSES_WINT_T=0
 698
 699 # Check to define _XOPEN_SOURCE "automatically"
 700 CF_XOPEN_SOURCE(500)
 701
 702 # Work around breakage on OS X
 703 CF_SIGWINCH
 704
 705 # Checks for CODESET support.
 706 AM_LANGINFO_CODESET
 707
 708 # use these variables to work around a defect in gcc's fixincludes.
 709 NCURSES_OK_WCHAR_T=
 710 NCURSES_OK_WINT_T=
 711
 712 AC_MSG_CHECKING(if you want wide-character code)
 713 AC_ARG_ENABLE(widec,
 714         [  --enable-widec          compile with wide-char/UTF-8 code],
 715         [with_widec=$enableval],
 716         [with_widec=no])
 717 AC_MSG_RESULT($with_widec)
 718 if test "$with_widec" = yes ; then
 719         LIB_SUFFIX="w${LIB_SUFFIX}"
 720         AC_DEFINE(USE_WIDEC_SUPPORT)
 721         AC_DEFINE(NCURSES_WIDECHAR)
 722
 723         CF_CHECK_WCHAR_H
 724
 725         # with_overwrite=no
 726         NCURSES_CH_T=cchar_t
 727         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 728         if test "$ac_cv_func_putwc" != yes ; then
 729                 CF_UTF8_LIB
 730                 if test "$cf_cv_utf8_lib" != no ; then
 731                         NCURSES_LIBUTF8=1
 732                 fi
 733         fi
 734         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 735         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 736         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 737
 738         if test "$NCURSES_MBSTATE_T" != 0; then
 739                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 740         fi
 741 fi
 742 AC_SUBST(NCURSES_CH_T)
 743 AC_SUBST(NCURSES_LIBUTF8)
 744
 745 AC_SUBST(NEED_WCHAR_H)
 746 AC_SUBST(NCURSES_MBSTATE_T)
 747 AC_SUBST(NCURSES_WCHAR_T)
 748 AC_SUBST(NCURSES_WINT_T)
 749
 750 AC_SUBST(NCURSES_OK_WCHAR_T)
 751 AC_SUBST(NCURSES_OK_WINT_T)
 752
 753 ###   use option --disable-lp64 to allow long chtype
 754 case $cf_cv_abi_version in
 755 [[345]]*)
 756         default_with_lp64=no
 757         ;;
 758 *)
 759         default_with_lp64=yes
 760         ;;
 761 esac
 762
 763 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 764 AC_ARG_ENABLE(lp64,
 765         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 766         [with_lp64=$enableval],
 767         [with_lp64=$default_with_lp64])
 768 AC_MSG_RESULT($with_lp64)
 769
 770 if test "$with_lp64" = yes ; then
 771         cf_cv_enable_lp64=1
 772 else
 773         cf_cv_enable_lp64=0
 774 fi
 775 AC_SUBST(cf_cv_enable_lp64)
 776
 777 CF_LARGEFILE
 778
 779 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 780 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 781 AC_ARG_ENABLE(tparm-varargs,
 782         [  --disable-tparm-varargs compile tparm() without varargs interface],
 783         [with_tparm_varargs=$enableval],
 784         [with_tparm_varargs=yes])
 785 AC_MSG_RESULT($with_tparm_varargs)
 786 NCURSES_TPARM_VARARGS=0
 787 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 788 AC_SUBST(NCURSES_TPARM_VARARGS)
 789
 790 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 791 if test "$with_ticlib" != no ; then
 792 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 793 AC_ARG_ENABLE(tic-depends,
 794         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 795         [with_tic_depends=$enableval],
 796         [with_tic_depends=yes])
 797 AC_MSG_RESULT($with_tic_depends)
 798 else
 799         with_tic_depends=no
 800 fi
 801
 802 ###   use option --with-bool to override bool's type
 803 AC_MSG_CHECKING(for type of bool)
 804 AC_ARG_WITH(bool,
 805         [  --with-bool=TYPE        override fallback type of bool variable],
 806         [NCURSES_BOOL="$withval"],
 807         [NCURSES_BOOL=auto])
 808 AC_MSG_RESULT($NCURSES_BOOL)
 809 AC_SUBST(NCURSES_BOOL)
 810
 811 AC_MSG_CHECKING(for alternate terminal capabilities file)
 812 AC_ARG_WITH(caps,
 813         [  --with-caps=alt         compile with alternate Caps file],
 814         [TERMINFO_CAPS=Caps.$withval],
 815         [TERMINFO_CAPS=Caps])
 816 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 817 AC_MSG_RESULT($TERMINFO_CAPS)
 818 AC_SUBST(TERMINFO_CAPS)
 819
 820 ###   use option --with-chtype to override chtype's type
 821 AC_MSG_CHECKING(for type of chtype)
 822 AC_ARG_WITH(chtype,
 823         [  --with-chtype=TYPE      override type of chtype],
 824         [NCURSES_CHTYPE="$withval"],
 825         [NCURSES_CHTYPE=auto])
 826 AC_MSG_RESULT($NCURSES_CHTYPE)
 827
 828 ###   use option --with-ospeed to override ospeed's type
 829 AC_MSG_CHECKING(for type of ospeed)
 830 AC_ARG_WITH(ospeed,
 831         [  --with-ospeed=TYPE      override type of ospeed variable],
 832         [NCURSES_OSPEED="$withval"],
 833         [NCURSES_OSPEED=short])
 834 AC_MSG_RESULT($NCURSES_OSPEED)
 835 AC_SUBST(NCURSES_OSPEED)
 836
 837 ###   use option --with-mmask-t to override mmask_t's type
 838 AC_MSG_CHECKING(for type of mmask_t)
 839 AC_ARG_WITH(mmask-t,
 840         [  --with-mmask-t=TYPE     override type of mmask_t],
 841         [NCURSES_MMASK_T="$withval"],
 842         [NCURSES_MMASK_T=auto])
 843 AC_MSG_RESULT($NCURSES_MMASK_T)
 844
 845 ###   use option --with-ccharw-max to override CCHARW_MAX size
 846 AC_MSG_CHECKING(for size CCHARW_MAX)
 847 AC_ARG_WITH(ccharw-max,
 848         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
 849         [NCURSES_CCHARW_MAX="$withval"],
 850         [NCURSES_CCHARW_MAX=5])
 851 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
 852 AC_SUBST(NCURSES_CCHARW_MAX)
 853
 854 ###   use option --with-tparm-arg to override tparm's argument type
 855 AC_MSG_CHECKING(for type of tparm args)
 856 AC_ARG_WITH(tparm-arg,
 857         [  --with-tparm-arg=TYPE   override parameter type of tparm],
 858         [NCURSES_TPARM_ARG="$withval"],
 859         [NCURSES_TPARM_ARG=long])
 860 AC_MSG_RESULT($NCURSES_TPARM_ARG)
 861 AC_SUBST(NCURSES_TPARM_ARG)
 862
 863 ### Enable compiling-in rcs id's
 864 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 865 AC_ARG_WITH(rcs-ids,
 866         [  --with-rcs-ids          compile-in RCS identifiers],
 867         [with_rcs_ids=$withval],
 868         [with_rcs_ids=no])
 869 AC_MSG_RESULT($with_rcs_ids)
 870 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 871
 872 ###############################################################################
 873 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
 874
 875 ###############################################################################
 876 CF_HELP_MESSAGE(Extensions:)
 877
 878 ### Note that some functions (such as const) are normally disabled anyway.
 879 AC_MSG_CHECKING(if you want to build with function extensions)
 880 AC_ARG_ENABLE(ext-funcs,
 881         [  --disable-ext-funcs     disable function-extensions],
 882         [with_ext_funcs=$enableval],
 883         [with_ext_funcs=yes])
 884 AC_MSG_RESULT($with_ext_funcs)
 885 if test "$with_ext_funcs" = yes ; then
 886         NCURSES_EXT_FUNCS=1
 887         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS)
 888         AC_DEFINE(HAVE_CURSES_VERSION)
 889         AC_DEFINE(HAVE_HAS_KEY)
 890         AC_DEFINE(HAVE_RESIZETERM)
 891         AC_DEFINE(HAVE_RESIZE_TERM)
 892         AC_DEFINE(HAVE_TERM_ENTRY_H)
 893         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 894         AC_DEFINE(HAVE_USE_SCREEN)
 895         AC_DEFINE(HAVE_USE_WINDOW)
 896         AC_DEFINE(HAVE_WRESIZE)
 897         AC_DEFINE(NCURSES_EXT_FUNCS)
 898         GENERATED_EXT_FUNCS=generated
 899 else
 900         NCURSES_EXT_FUNCS=0
 901         GENERATED_EXT_FUNCS=
 902 fi
 903 AC_SUBST(NCURSES_EXT_FUNCS)
 904 AC_SUBST(GENERATED_EXT_FUNCS)
 905
 906 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
 907 AC_ARG_ENABLE(sp-funcs,
 908         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
 909         [with_sp_funcs=$enableval],
 910         [with_sp_funcs=no])
 911 AC_MSG_RESULT($with_sp_funcs)
 912 if test "$with_sp_funcs" = yes ; then
 913         NCURSES_SP_FUNCS=1
 914         AC_DEFINE(NCURSES_SP_FUNCS)
 915         GENERATED_SP_FUNCS=generated
 916 else
 917         NCURSES_SP_FUNCS=0
 918         GENERATED_SP_FUNCS=
 919 fi
 920 AC_SUBST(NCURSES_SP_FUNCS)
 921 AC_SUBST(GENERATED_SP_FUNCS)
 922
 923 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
 924 AC_ARG_ENABLE(term-driver,
 925         [  --enable-term-driver    enable experimental terminal-driver],
 926         [with_term_driver=$enableval],
 927         [with_term_driver=no])
 928 AC_MSG_RESULT($with_term_driver)
 929 if test "$with_term_driver" = yes ; then
 930         AC_DEFINE(USE_TERM_DRIVER)
 931         if test "$with_sp_funcs" != yes ; then
 932                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
 933         fi
 934 fi
 935
 936 ###   use option --enable-const to turn on use of const beyond that in XSI.
 937 AC_MSG_CHECKING(for extended use of const keyword)
 938 AC_ARG_ENABLE(const,
 939         [  --enable-const          compile with extra/non-standard const],
 940         [with_ext_const=$enableval],
 941         [with_ext_const=no])
 942 AC_MSG_RESULT($with_ext_const)
 943 NCURSES_CONST='/*nothing*/'
 944 if test "$with_ext_const" = yes ; then
 945         NCURSES_CONST=const
 946 fi
 947 AC_SUBST(NCURSES_CONST)
 948
 949 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 950 AC_MSG_CHECKING(if you want to use extended colors)
 951 AC_ARG_ENABLE(ext-colors,
 952         [  --enable-ext-colors     compile for 256-color support],
 953         [with_ext_colors=$enableval],
 954         [with_ext_colors=no])
 955 AC_MSG_RESULT($with_ext_colors)
 956 NCURSES_EXT_COLORS=0
 957 if test "$with_ext_colors" = yes ; then
 958         if test "$with_widec" != yes ; then
 959                 AC_MSG_ERROR(This option applies only to wide-character library)
 960         else
 961                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 962                 CF_NCURSES_ABI_6
 963         fi
 964         NCURSES_EXT_COLORS=1
 965         AC_DEFINE(NCURSES_EXT_COLORS)
 966 fi
 967 AC_SUBST(NCURSES_EXT_COLORS)
 968
 969 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 970 AC_MSG_CHECKING(if you want to use extended mouse encoding)
 971 AC_ARG_ENABLE(ext-mouse,
 972         [  --enable-ext-mouse      compile for extended mouse-encoding],
 973         [with_ext_mouse=$enableval],
 974         [with_ext_mouse=no])
 975 AC_MSG_RESULT($with_ext_mouse)
 976 NCURSES_MOUSE_VERSION=1
 977 if test "$with_ext_mouse" = yes ; then
 978         NCURSES_MOUSE_VERSION=2
 979         CF_NCURSES_ABI_6
 980 fi
 981 AC_SUBST(NCURSES_MOUSE_VERSION)
 982
 983 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 984 AC_ARG_ENABLE(no-padding,
 985         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 986         [with_no_padding=$enableval],
 987         [with_no_padding=$with_ext_funcs])
 988 AC_MSG_RESULT($with_no_padding)
 989 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 990
 991 AC_CHECK_SIZEOF([signed char], 0)
 992 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 993         NCURSES_SBOOL="signed char"
 994 else
 995         NCURSES_SBOOL="char"
 996 fi
 997 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 998 AC_ARG_ENABLE(signed-char,
 999         [  --enable-signed-char    compile using signed Boolean's in term.h],
1000         [with_signed_char=$enableval],
1001         [with_signed_char=no])
1002 AC_MSG_RESULT($with_signed_char)
1003 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
1004 AC_SUBST(NCURSES_SBOOL)
1005
1006 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1007 AC_MSG_CHECKING(if you want SIGWINCH handler)
1008 AC_ARG_ENABLE(sigwinch,
1009         [  --enable-sigwinch       compile with SIGWINCH handler],
1010         [with_sigwinch=$enableval],
1011         [with_sigwinch=$with_ext_funcs])
1012 AC_MSG_RESULT($with_sigwinch)
1013 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
1014
1015 ###   use option --enable-tcap-names to allow user to define new capabilities
1016 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1017 AC_ARG_ENABLE(tcap-names,
1018         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1019         [with_tcap_names=$enableval],
1020         [with_tcap_names=$with_ext_funcs])
1021 AC_MSG_RESULT($with_tcap_names)
1022 NCURSES_XNAMES=0
1023 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
1024 AC_SUBST(NCURSES_XNAMES)
1025
1026 ###############################################################################
1027 # These options are relatively safe to experiment with.
1028 CF_HELP_MESSAGE(Development Code:)
1029 AC_MSG_CHECKING(if you want all development code)
1030 AC_ARG_WITH(develop,
1031         [  --without-develop       disable development options],
1032         [with_develop=$withval],
1033         [with_develop=no])
1034 AC_MSG_RESULT($with_develop)
1035
1036 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1037 AC_MSG_CHECKING(if you want hard-tabs code)
1038 AC_ARG_ENABLE(hard-tabs,
1039         [  --enable-hard-tabs      compile with hard-tabs code],,
1040         [enable_hard_tabs=$with_develop])
1041 AC_MSG_RESULT($enable_hard_tabs)
1042 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
1043
1044 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1045 AC_MSG_CHECKING(if you want limited support for xmc)
1046 AC_ARG_ENABLE(xmc-glitch,
1047         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1048         [enable_xmc_glitch=$with_develop])
1049 AC_MSG_RESULT($enable_xmc_glitch)
1050 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
1051
1052 ###############################################################################
1053 # These are just experimental, probably should not be in a package:
1054 CF_HELP_MESSAGE(Experimental Code:)
1055
1056 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1057 AC_ARG_ENABLE(assumed-color,
1058         [  --disable-assumed-color do not assume anything about default-colors],
1059         [with_assumed_color=$enableval],
1060         [with_assumed_color=yes])
1061 AC_MSG_RESULT($with_assumed_color)
1062 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
1063
1064 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1065 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1066 AC_ARG_ENABLE(hashmap,
1067         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1068         [with_hashmap=$enableval],
1069         [with_hashmap=yes])
1070 AC_MSG_RESULT($with_hashmap)
1071 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1072
1073 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1074 AC_MSG_CHECKING(if you want colorfgbg code)
1075 AC_ARG_ENABLE(colorfgbg,
1076         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1077         [with_colorfgbg=$enableval],
1078         [with_colorfgbg=no])
1079 AC_MSG_RESULT($with_colorfgbg)
1080 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1081
1082 ###   use option --enable-interop to turn on use of bindings used for interop
1083 AC_MSG_CHECKING(if you want interop bindings)
1084 AC_ARG_ENABLE(interop,
1085         [  --enable-interop        compile-in experimental interop bindings],
1086         [with_exp_interop=$enableval],
1087         [with_exp_interop=no])
1088 AC_MSG_RESULT($with_exp_interop)
1089
1090 NCURSES_INTEROP_FUNCS=0
1091 test "$with_exp_interop" = yes && NCURSES_INTEROP_FUNCS=1
1092 AC_SUBST(NCURSES_INTEROP_FUNCS)
1093
1094 # This is still experimental (20080329), but should ultimately be moved to
1095 # the script-block --with-normal, etc.
1096 CF_WITH_PTHREAD
1097
1098 if test "x$with_pthread" != xno; then
1099         AC_CHECK_FUNC(pthread_kill,[
1100                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1101                 AC_ARG_ENABLE(pthreads-eintr,
1102                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1103                         [use_pthreads_eintr=$enableval],
1104                         [use_pthreads_eintr=no])
1105                 AC_MSG_RESULT($use_pthreads_eintr)
1106                 if test $use_pthreads_eintr = yes ; then
1107                         AC_DEFINE(USE_PTHREADS_EINTR)
1108                 fi])
1109
1110         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1111         AC_ARG_ENABLE(weak-symbols,
1112                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1113                 [use_weak_symbols=$enableval],
1114                 [use_weak_symbols=no])
1115         AC_MSG_RESULT($use_weak_symbols)
1116         if test "$use_weak_symbols" = yes ; then
1117                 CF_WEAK_SYMBOLS
1118         else
1119                 cf_cv_weak_symbols=no
1120         fi
1121
1122         if test $cf_cv_weak_symbols = yes ; then
1123                 AC_DEFINE(USE_WEAK_SYMBOLS)
1124         fi
1125 fi
1126
1127 PTHREAD=
1128 if test "$with_pthread" = "yes" ; then
1129     AC_DEFINE(USE_PTHREADS)
1130     enable_reentrant=yes
1131     if test $cf_cv_weak_symbols = yes ; then
1132         PTHREAD=-lpthread
1133     fi
1134 fi
1135 AC_SUBST(PTHREAD)
1136
1137 # Reentrant code has to be opaque; there's little advantage to making ncurses
1138 # opaque outside of that, so there is no --enable-opaque option.  We can use
1139 # this option without --with-pthreads, but this will be always set for
1140 # pthreads.
1141 AC_MSG_CHECKING(if you want experimental reentrant code)
1142 AC_ARG_ENABLE(reentrant,
1143         [  --enable-reentrant      compile with experimental reentrant code],
1144         [with_reentrant=$enableval],
1145         [with_reentrant=no])
1146 AC_MSG_RESULT($with_reentrant)
1147 if test "$with_reentrant" = yes ; then
1148         cf_cv_enable_reentrant=1
1149         cf_cv_enable_opaque="NCURSES_INTERNALS"
1150         NCURSES_OPAQUE=1
1151         NCURSES_SIZE_T=int
1152         if test $cf_cv_weak_symbols = yes ; then
1153                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1154                 CF_ADD_LIB(pthread,TEST_LIBS)
1155                 CF_ADD_LIB(pthread,TEST_LIBS2)
1156         else
1157                 LIB_SUFFIX="t${LIB_SUFFIX}"
1158         fi
1159         AC_DEFINE(USE_REENTRANT)
1160         CF_NCURSES_ABI_6
1161 else
1162         cf_cv_enable_reentrant=0
1163         cf_cv_enable_opaque="NCURSES_OPAQUE"
1164         NCURSES_OPAQUE=0
1165         NCURSES_SIZE_T=short
1166 fi
1167 AC_SUBST(cf_cv_enable_reentrant)
1168 AC_SUBST(cf_cv_enable_opaque)
1169 AC_SUBST(NCURSES_OPAQUE)
1170 AC_SUBST(NCURSES_SIZE_T)
1171
1172 ### Allow using a different wrap-prefix
1173 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1174         AC_MSG_CHECKING(for prefix used to wrap public variables)
1175         AC_ARG_WITH(wrap-prefix,
1176                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1177                 [NCURSES_WRAP_PREFIX=$withval],
1178                 [NCURSES_WRAP_PREFIX=_nc_])
1179         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1180 else
1181         NCURSES_WRAP_PREFIX=_nc_
1182 fi
1183 AC_SUBST(NCURSES_WRAP_PREFIX)
1184 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX")
1185
1186 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1187 AC_ARG_ENABLE(safe-sprintf,
1188         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1189         [with_safe_sprintf=$enableval],
1190         [with_safe_sprintf=no])
1191 AC_MSG_RESULT($with_safe_sprintf)
1192 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1193
1194 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1195 # when hashmap is used scroll hints are useless
1196 if test "$with_hashmap" = no ; then
1197 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1198 AC_ARG_ENABLE(scroll-hints,
1199         [  --disable-scroll-hints  compile without scroll-hints code],
1200         [with_scroll_hints=$enableval],
1201         [with_scroll_hints=yes])
1202 AC_MSG_RESULT($with_scroll_hints)
1203 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1204 fi
1205
1206 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1207 AC_ARG_ENABLE(wgetch-events,
1208         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1209         [with_wgetch_events=$enableval],
1210         [with_wgetch_events=no])
1211 AC_MSG_RESULT($with_wgetch_events)
1212 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1213
1214 ###############################################################################
1215 CF_HELP_MESSAGE(Testing/development Options:)
1216
1217 ###     use option --disable-echo to suppress full display compiling commands
1218 AC_MSG_CHECKING(if you want to display full commands during build)
1219 AC_ARG_ENABLE(echo,
1220         [  --enable-echo           build: display "compiling" commands (default)],
1221         [with_echo=$enableval],
1222         [with_echo=yes])
1223 if test "$with_echo" = yes; then
1224         ECHO_LINK=
1225 else
1226         ECHO_LINK='@ echo linking $@ ... ;'
1227         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1228         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1229 fi
1230 AC_MSG_RESULT($with_echo)
1231 AC_SUBST(ECHO_LINK)
1232
1233 ###     use option --enable-warnings to turn on all gcc warnings
1234 AC_MSG_CHECKING(if you want to see compiler warnings)
1235 AC_ARG_ENABLE(warnings,
1236         [  --enable-warnings       build: turn on GCC compiler warnings],
1237         [with_warnings=$enableval])
1238 AC_MSG_RESULT($with_warnings)
1239
1240 if test "x$with_warnings" = "xyes"; then
1241         CF_ADD_ADAFLAGS(-gnatg)
1242         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1243         if test "$cf_with_cxx" = yes ; then
1244                 CF_GXX_WARNINGS(Wno-unused)
1245         fi
1246 fi
1247 CF_GCC_ATTRIBUTES
1248
1249 ###     use option --enable-assertions to turn on generation of assertion code
1250 AC_MSG_CHECKING(if you want to enable runtime assertions)
1251 AC_ARG_ENABLE(assertions,
1252         [  --enable-assertions     test: turn on generation of assertion code],
1253         [with_assertions=$enableval],
1254         [with_assertions=no])
1255 AC_MSG_RESULT($with_assertions)
1256 if test -n "$GCC"
1257 then
1258         if test "$with_assertions" = no
1259         then
1260                 AC_DEFINE(NDEBUG)
1261                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1262         else
1263                 CF_ADD_ADAFLAGS(-gnata)
1264         fi
1265 fi
1266
1267 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1268 CF_DISABLE_LEAKS
1269 AC_DEFINE(HAVE_NC_ALLOC_H)
1270
1271 ###     use option --enable-expanded to generate certain macros as functions
1272 AC_ARG_ENABLE(expanded,
1273         [  --enable-expanded       test: generate functions for certain macros],
1274         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1275
1276 ###     use option --disable-macros to suppress macros in favor of functions
1277 AC_ARG_ENABLE(macros,
1278         [  --disable-macros        test: use functions rather than macros],
1279         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1280
1281 # Normally we only add trace() to the debug-library.  Allow this to be
1282 # extended to all models of the ncurses library:
1283 cf_all_traces=no
1284 case "$CFLAGS $CPPFLAGS" in
1285 *-DTRACE*)
1286         cf_all_traces=yes
1287         ;;
1288 esac
1289
1290 AC_MSG_CHECKING(whether to add trace feature to all models)
1291 AC_ARG_WITH(trace,
1292 [  --with-trace            test: add trace() function to all models of ncurses],
1293 [cf_with_trace=$withval],
1294 [cf_with_trace=$cf_all_traces])
1295 AC_MSG_RESULT($cf_with_trace)
1296
1297 if test "$cf_with_trace" = yes ; then
1298         LIB_TRACING=all
1299         ADA_TRACE=TRUE
1300         CF_ADD_CFLAGS(-DTRACE)
1301 else
1302         LIB_TRACING=DEBUG
1303         ADA_TRACE=FALSE
1304 fi
1305
1306 AC_SUBST(ADA_TRACE)
1307
1308 ###     Checks for libraries.
1309 case $cf_cv_system_name in #(vi
1310 *mingw32*) #(vi
1311         ;;
1312 *)
1313 AC_CHECK_FUNC(gettimeofday,
1314         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1315
1316 AC_CHECK_LIB(bsd, gettimeofday,
1317         AC_DEFINE(HAVE_GETTIMEOFDAY)
1318         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1319         ;;
1320 esac
1321
1322 CF_MATH_LIB(MATH_LIB,sin(x))
1323 AC_SUBST(MATH_LIB)
1324
1325 ###     Checks for header files.
1326 AC_STDC_HEADERS
1327 AC_HEADER_DIRENT
1328 AC_HEADER_TIME
1329 CF_REGEX
1330
1331 dnl These are some other potentially nonportable headers.
1332 AC_CHECK_HEADERS( \
1333 fcntl.h \
1334 getopt.h \
1335 limits.h \
1336 locale.h \
1337 math.h \
1338 poll.h \
1339 sys/bsdtypes.h \
1340 sys/ioctl.h \
1341 sys/param.h \
1342 sys/poll.h \
1343 sys/select.h \
1344 sys/time.h \
1345 sys/times.h \
1346 ttyent.h \
1347 unistd.h \
1348 wctype.h \
1349 )
1350
1351 CF_GETOPT_HEADER
1352
1353 # check for ISC (this may also define _POSIX_SOURCE)
1354 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1355 if test "$ISC" = yes ; then
1356         AC_CHECK_LIB(cposix,main)
1357         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1358 fi
1359
1360 CF_SYS_TIME_SELECT
1361
1362 ###     checks for compiler characteristics
1363 AC_LANG_C
1364 AC_C_CONST
1365 CF_C_INLINE(NCURSES_INLINE,1200)
1366 CF_SIG_ATOMIC_T
1367
1368 if test $NCURSES_CHTYPE = auto ; then
1369         CF_TYPEOF_CHTYPE
1370 else
1371         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1372 fi
1373 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1374 AC_SUBST(cf_cv_typeof_chtype)
1375
1376 CF_UNSIGNED_LITERALS
1377 cf_cv_1UL="1"
1378 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1379 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1380 AC_SUBST(cf_cv_1UL)
1381
1382 if test $NCURSES_MMASK_T = auto ; then
1383         cf_cv_typeof_mmask_t=long
1384 else
1385         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1386 fi
1387 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1388 AC_SUBST(cf_cv_typeof_mmask_t)
1389
1390 ###     Checks for external-data
1391 CF_ERRNO
1392 CF_LINK_DATAONLY
1393
1394 ###     Checks for library functions.
1395 AC_CHECK_FUNCS( \
1396 getcwd \
1397 getegid \
1398 geteuid \
1399 getttynam \
1400 issetugid \
1401 poll \
1402 remove \
1403 select \
1404 setbuf \
1405 setbuffer \
1406 setvbuf \
1407 sigaction \
1408 sigvec \
1409 strdup \
1410 strstr \
1411 tcgetpgrp \
1412 times \
1413 vsnprintf \
1414 )
1415 if test "$with_getcap" = "yes" ; then
1416         CF_CGETENT
1417 fi
1418
1419 CF_ISASCII
1420 CF_STRUCT_SIGACTION
1421 CF_FUNC_NANOSLEEP
1422 CF_FUNC_TERMIOS
1423 CF_FUNC_VSSCANF
1424 CF_MKSTEMP
1425
1426 # setup for prototype of fallback for vsscanf()
1427 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1428
1429 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1430 if test "$cross_compiling" = yes ; then
1431         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1432 else
1433         AC_FUNC_SETVBUF_REVERSED
1434 fi
1435 AC_TYPE_SIGNAL
1436 AC_CHECK_TYPE(intptr_t, long)
1437 CF_TYPE_SIGACTION
1438 CF_SIZECHANGE
1439 CF_FUNC_MEMMOVE
1440 CF_FUNC_POLL
1441 CF_VA_COPY
1442 AC_FUNC_VFORK
1443
1444 # special check for test/ditto.c
1445 CF_FUNC_OPENPTY
1446 if test "$cf_cv_func_openpty" != no ; then
1447     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1448     AC_DEFINE(USE_XTERM_PTY)
1449     if test "$cf_cv_lib_util" = yes ; then
1450         CF_ADD_LIB(util,TEST_LIBS)
1451     fi
1452 fi
1453 AC_SUBST(TEST_LIBS)
1454 AC_SUBST(TEST_LIBS2)
1455
1456 if test "$with_hashed_db" != no ; then
1457         AC_DEFINE(USE_HASHED_DB)
1458         CF_HASHED_DB($with_hashed_db)
1459 fi
1460
1461 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1462 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1463         CF_STRIP_G_OPT(CFLAGS)
1464         CF_STRIP_G_OPT(CXXFLAGS)
1465 fi
1466
1467 # Just in case, check if the C compiler has a bool type.
1468 CF_BOOL_DECL(cf_cv_cc_bool_type)
1469
1470 # Check for C++ compiler characteristics (and ensure that it's there!)
1471 if test -n "$CXX" ; then
1472         AC_LANG_CPLUSPLUS
1473         CF_STDCPP_LIBRARY
1474         CF_PROG_CC_C_O(CXX)
1475
1476         case $GXX_VERSION in
1477         1*|2.[0-6]*)
1478                 cf_cxx_library=yes
1479                 ;;
1480         *-2.7*|2.7*)
1481                 CF_GPP_LIBRARY
1482                 ;;
1483         *)
1484                 cf_cxx_library=no
1485                 ;;
1486         esac
1487
1488         AC_CHECK_HEADERS(typeinfo)
1489         CF_CXX_IOSTREAM_NAMESPACE
1490         CF_BOOL_DECL
1491         CF_BOOL_SIZE
1492         CF_ETIP_DEFINES
1493         CF_CPP_PARAM_INIT
1494         CF_CPP_STATIC_CAST
1495         CF_CXX_AR_FLAGS
1496 else
1497         cf_cxx_library=no
1498         cf_cv_builtin_bool=1
1499
1500         # Just because we are not configuring against C++ right now does not
1501         # mean that a user will not want to use C++.  Some distributors disable
1502         # the C++ portion of this configuration as a shortcut (or just to avoid
1503         # compiling the demo in the c++ directory).  So we need a reasonable
1504         # default for the 'bool' type.
1505         #
1506         # Caveat: since the storage of the bool type is not standardized, it
1507         # may change.
1508
1509         if test "$NCURSES_BOOL" != auto ; then
1510                 cf_cv_type_of_bool=$NCURSES_BOOL
1511                 cf_cv_header_stdbool_h=0
1512         else
1513                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1514                         CF_BOOL_SIZE
1515                 else
1516                         AC_MSG_CHECKING(for fallback type of bool)
1517                         case "$host_cpu" in #(vi
1518                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1519                         *)      cf_cv_type_of_bool=int  ;;
1520                         esac
1521                         AC_MSG_RESULT($cf_cv_type_of_bool)
1522                 fi
1523         fi
1524 fi
1525 AC_SUBST(CXXLIBS)
1526
1527 # If the C compiler did not declare bool, and we did not determine that the C++
1528 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1529 # ncurses library use the same type as C++ bool.  Note that this allows one to
1530 # specify the type of bool in a configure-script option and postpone
1531 # integration with the C++ compiler provided that the types are compatible.
1532 USE_CXX_BOOL=1
1533 if test $cf_cv_cc_bool_type = 1
1534 then
1535         # oops: C has a bool.  Unlikely, but C++ could differ.
1536         USE_CXX_BOOL=0
1537 elif test $cf_cv_builtin_bool = 0
1538 then
1539         # C++ has no bool
1540         USE_CXX_BOOL=0
1541 else
1542         # this is the normal case
1543         USE_CXX_BOOL='defined(__cplusplus)'
1544 fi
1545 AC_SUBST(USE_CXX_BOOL)
1546
1547 CF_HELP_MESSAGE(Ada95 Binding Options:)
1548
1549 dnl If the Ada95 source-tree is present, add that to the build unless it will
1550 dnl not work, or was not requested.
1551 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1552
1553 dnl libtool does not know anything about GNAT, though a change made in 1998
1554 dnl provided for it "someday".  Disable the ada subtree if we are using
1555 dnl libtool -TD 20070714
1556         if test "$cf_with_ada" != "no" ; then
1557                 if test "$with_libtool" != "no"; then
1558                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1559                         cf_with_ada=no
1560                 fi
1561         fi
1562
1563 dnl Check for availability of GNU Ada Translator (GNAT).
1564 dnl At the moment we support no other Ada95 compiler.
1565         if test "$cf_with_ada" != "no" ; then
1566                 CF_PROG_GNAT
1567                 if test "$cf_cv_prog_gnat_correct" = yes; then
1568                         CF_ADD_ADAFLAGS(-gnatpn)
1569
1570                         # make ADAFLAGS consistent with CFLAGS
1571                         case "$CFLAGS" in
1572                         *-g*)
1573                                 CF_ADD_ADAFLAGS(-g)
1574                                 ;;
1575                         esac
1576                         case "$CFLAGS" in
1577                         *-O*)
1578                                 CF_ADD_ADAFLAGS(-O3)
1579                                 ;;
1580                         esac
1581
1582                         CF_GNAT_GENERICS
1583                         CF_GNAT_SIGINT
1584                         CF_GNAT_PRAGMA_UNREF
1585                         CF_GNAT_PROJECTS
1586
1587                         CF_WITH_ADA_COMPILER
1588
1589                         cf_ada_package=terminal_interface
1590                         AC_SUBST(cf_ada_package)
1591
1592                         CF_WITH_ADA_INCLUDE
1593                         CF_WITH_ADA_OBJECTS
1594                         CF_WITH_ADA_SHAREDLIB
1595                 fi
1596         fi
1597 else
1598         cf_with_ada=no
1599 fi
1600
1601 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1602 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1603 ###
1604 ### ticlib modules may be a separate library, otherwise contained in termlib.
1605 ### termlib modules may be a separate library, otherwise contained in ncurses.
1606 ###
1607 ### The of "+" or " " between the tokens controls the way the script
1608 ### chooses to split module lists into libraries.
1609 ###
1610 ### (see CF_LIB_RULES).
1611 AC_MSG_CHECKING(for library subsets)
1612 LIB_SUBSETS=
1613
1614 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1615         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1616         if test "$with_ticlib" != no ; then
1617                 LIB_SUBSETS="${LIB_SUBSETS} "
1618         else
1619                 LIB_SUBSETS="${LIB_SUBSETS}+"
1620         fi
1621 fi
1622
1623 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1624 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1625
1626 if test "$with_termlib" != no ; then
1627         LIB_SUBSETS="${LIB_SUBSETS} "
1628 else
1629         LIB_SUBSETS="${LIB_SUBSETS}+"
1630 fi
1631
1632 LIB_SUBSETS="${LIB_SUBSETS}base"
1633
1634 # Most term-driver calls are to tinfo, but some like init_pair are to the
1635 # base library (so it resides in base).
1636 if test "$with_term_driver" != no ; then
1637         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1638         case $cf_cv_system_name in #(vi
1639         *mingw32*) #(vi
1640                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1641                 ;;
1642         *) #(vi
1643                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1644                 ;;
1645         esac
1646 fi
1647
1648 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1649 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1650
1651 AC_MSG_RESULT($LIB_SUBSETS)
1652
1653 ### Construct the list of include-directories to be generated
1654 CF_INCLUDE_DIRS
1655 CF_ADA_INCLUDE_DIRS
1656
1657 ### Build up pieces for makefile rules
1658 AC_MSG_CHECKING(default library suffix)
1659 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1660 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1661 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1662
1663 AC_MSG_CHECKING(default library-dependency suffix)
1664 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1665 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1666 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1667
1668 AC_MSG_CHECKING(default object directory)
1669 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1670 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1671 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1672
1673 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1674 if test "$cf_with_cxx" = yes ; then
1675 AC_MSG_CHECKING(c++ library-dependency suffix)
1676 if test "$with_libtool" != "no"; then
1677         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1678 else
1679         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1680 fi
1681 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1682 AC_SUBST(CXX_LIB_SUFFIX)
1683 fi
1684
1685 # do not want -ldl in build except as needed for -lncurses dependency
1686 if test "$with_dlsym" = yes ; then
1687 if test $DFT_LWR_MODEL = shared || \
1688    test $DFT_LWR_MODEL = libtool ; then
1689         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1690 fi
1691 fi
1692 ### Set up low-level terminfo dependencies for makefiles.
1693
1694 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1695 # do not need libdl
1696 TICS_LIST=
1697 if test "$with_dlsym" = yes ; then
1698         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1699 fi
1700
1701 if test "$with_ticlib" != no ; then
1702
1703         if test "$with_ticlib" != yes ; then
1704                 TICS_NAME=$with_ticlib
1705                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1706                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1707                 TICS_LIB_SUFFIX="${with_ticlib}"
1708         else
1709                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1710                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1711                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1712         fi
1713         TICS_LDFLAGS="-L${LIB_DIR}"
1714         TICS_LIBS="-l${TICS_LIB_SUFFIX}"
1715 else
1716         TICS_LDFLAGS="-L${LIB_DIR}"
1717         TICS_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1718 fi
1719 AC_SUBST(TICS_ARG_SUFFIX)
1720 AC_SUBST(TICS_DEP_SUFFIX)
1721 AC_SUBST(TICS_LIB_SUFFIX)
1722 AC_SUBST(TICS_LDFLAGS)
1723 AC_SUBST(TICS_LIBS)
1724
1725 if test "$with_termlib" != no ; then
1726
1727         if test "$with_termlib" != yes ; then
1728                 TINFO_NAME=$with_termlib
1729                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1730                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1731                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1732                 TINFO_LIB_SUFFIX="${with_termlib}"
1733         else
1734                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1735                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1736                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1737                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1738         fi
1739
1740         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1741         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1742         if test "$DFT_LWR_MODEL" = "libtool"; then
1743                 TEST_ARGS="${TEST_DEPS}"
1744                 TEST_ARG2="${TEST_DEP2}"
1745                 TINFO_LDFLAGS="-L${LIB_DIR}"
1746                 TINFO_LIBS="$TEST_ARGS"
1747                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1748                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1749         else
1750                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1751                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1752                 if test "x$with_term_driver" != xno ; then
1753                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1754                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1755                         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
1756                 else
1757                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1758                         TINFO_LIBS="$TEST_ARGS"
1759                 fi
1760                 TINFO_LDFLAGS="-L${LIB_DIR}"
1761                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1762         fi
1763 else
1764         # the next lines are needed for linking libtic over libncurses
1765         TINFO_NAME=${LIB_NAME}
1766         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1767         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1768         if test "$with_tic_depends" = yes ; then
1769                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1770         else
1771                 TICS_LIST="$SHLIB_LIST"
1772         fi
1773
1774         TINFO_LDFLAGS="-L${LIB_DIR}"
1775         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1776 fi
1777
1778 if test "$DFT_LWR_MODEL" = shared ; then
1779         case $cf_cv_system_name in #(vi
1780         cygwin*)
1781                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1782                 TINFO_SUFFIX=.dll
1783                 ;;
1784         esac
1785 fi
1786
1787 AC_SUBST(TINFO_ARG_SUFFIX)
1788 AC_SUBST(TINFO_DEP_SUFFIX)
1789 AC_SUBST(TINFO_LIB_SUFFIX)
1790 AC_SUBST(TINFO_LDFLAGS)
1791 AC_SUBST(TINFO_LIBS)
1792
1793 if test "$with_dlsym" = yes ; then
1794         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1795 fi
1796
1797 if test "$DFT_LWR_MODEL" = "libtool"; then
1798     OBJEXT=lo
1799 fi
1800
1801 # needed for Ada95
1802 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
1803 AC_SUBST(TINFO_LDFLAGS2)
1804
1805 case $DFT_LWR_MODEL in
1806 normal|debug|profile)
1807         CF_LDFLAGS_STATIC
1808         ;;
1809 esac
1810
1811 AC_MSG_CHECKING(where we will install curses.h)
1812 test "$with_overwrite" = no && \
1813 test "x$includedir" = 'x${prefix}/include' && \
1814         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1815 AC_MSG_RESULT($includedir)
1816
1817 ### Resolve a conflict between normal and wide-curses by forcing applications
1818 ### that will need libutf8 to add it to their configure script.
1819 if test "$with_overwrite" != no ; then
1820 if test "$NCURSES_LIBUTF8" = 1 ; then
1821         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1822         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1823 fi
1824 fi
1825 WITH_OVERWRITE=$with_overwrite
1826
1827 AC_SUBST(WITH_OVERWRITE)
1828 AC_SUBST(TICS_LIST)
1829 AC_SUBST(TINFO_LIST)
1830 AC_SUBST(SHLIB_LIST)
1831
1832 # used to separate tack out of the tree
1833 NCURSES_TREE=
1834 AC_SUBST(NCURSES_TREE)
1835
1836 ### predefined stuff for the test programs
1837 AC_DEFINE(HAVE_SLK_COLOR)
1838
1839 ### Construct the list of subdirectories for which we'll customize makefiles
1840 ### with the appropriate compile-rules.
1841
1842 CF_SRC_MODULES($modules_to_build)
1843
1844 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
1845    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1846    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1847 fi
1848
1849 CF_DIRS_TO_MAKE
1850
1851 # symbols that differ when compiling Ada95 by itself.
1852 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1853 AC_SUBST(NCURSES_SHLIB2)
1854
1855 # values to use as strings
1856 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR')
1857
1858 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1859
1860 ### Now that we're done running tests, add the compiler-warnings, if any
1861 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1862
1863 ### Define substitutions for header files to avoid name-pollution
1864 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1865 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1866 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1867
1868 ################################################################################
1869 test "$use_database" = yes && \
1870 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1871
1872 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1873 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1874
1875 if test x"$enable_pc_files" = xyes ; then \
1876 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1877 MAKE_PC_FILES=
1878 else
1879 MAKE_PC_FILES="#"
1880 fi
1881 AC_SUBST(MAKE_PC_FILES)
1882 AC_SUBST(cross_compiling)
1883
1884 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
1885 if test -n "$FALLBACK_LIST"
1886 then
1887         if test "$TIC_PATH" = unknown
1888         then
1889                 AC_MSG_WARN(no tic program found for fallbacks)
1890         fi
1891 fi
1892 AC_SUBST(TIC_PATH)
1893
1894 if test "x$cf_with_tests" != xno ; then
1895         MAKE_TESTS=
1896 else
1897         MAKE_TESTS="#"
1898 fi
1899 AC_SUBST(MAKE_TESTS)
1900
1901 ADAHTML_DIR=../../doc/html/ada
1902 AC_SUBST(ADAHTML_DIR)
1903
1904 SUB_SCRIPTS=
1905
1906 AC_OUTPUT( \
1907         include/MKterm.h.awk \
1908         include/curses.head:include/curses.h.in \
1909         include/ncurses_dll.h \
1910         include/termcap.h \
1911         include/unctrl.h \
1912         $SUB_SCRIPTS \
1913         $SUB_MAKEFILES \
1914         Makefile,[
1915 if test "x$cf_with_tests" != xno ; then
1916         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LINK"], test)
1917 fi
1918 CF_LIB_RULES($SRC_SUBDIRS)
1919
1920 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
1921 if test -z "$USE_OLD_MAKERULES" ; then
1922         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
1923 fi
1924 fi
1925 ],[
1926 ### Special initialization commands, used to pass information from the
1927 ### configuration-run into config.status
1928
1929 AWK="$AWK"
1930 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1931 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1932 ECHO_LINK="$ECHO_LINK"
1933 LDCONFIG="$LDCONFIG"
1934 LIBTOOL_VERSION="$LIBTOOL_VERSION"
1935 LIB_NAME="$LIB_NAME"
1936 LIB_PREFIX="$LIB_PREFIX"
1937 LIB_SUBSETS="$LIB_SUBSETS"
1938 LIB_SUFFIX="$LIB_SUFFIX"
1939 LIB_TRACING="$LIB_TRACING"
1940 LN_S="$LN_S"
1941 MAKE_TERMINFO="$MAKE_TERMINFO"
1942 NCURSES_MAJOR="$NCURSES_MAJOR"
1943 NCURSES_MINOR="$NCURSES_MINOR"
1944 NCURSES_OSPEED="$NCURSES_OSPEED"
1945 NCURSES_PATCH="$NCURSES_PATCH"
1946 SRC_SUBDIRS="$SRC_SUBDIRS"
1947 TERMINFO="$TERMINFO"
1948 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1949 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1950 TICS_NAME="$TICS_NAME"
1951 TIC_PATH="$TIC_PATH"
1952 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1953 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1954 TINFO_NAME="$TINFO_NAME"
1955 TINFO_SUFFIX="$TINFO_SUFFIX"
1956 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
1957 WITH_CURSES_H="$with_curses_h"
1958 WITH_ECHO="$with_echo"
1959 WITH_OVERWRITE="$with_overwrite"
1960 cf_LIST_MODELS="$cf_list_models"
1961 cf_cv_abi_version="$cf_cv_abi_version"
1962 cf_cv_do_relink="$cf_cv_do_relink"
1963 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1964 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1965 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1966 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1967 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1968 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
1969 cf_cv_rel_version="$cf_cv_rel_version"
1970 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1971 cf_cv_shared_soname='$cf_cv_shared_soname'
1972 cf_cv_shlib_version="$cf_cv_shlib_version"
1973 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1974 cf_cv_system_name="$cf_cv_system_name"
1975 cf_cv_term_driver="$with_term_driver"
1976 cf_with_ada="$cf_with_ada"
1977 cf_with_cxx_binding="$cf_with_cxx_binding"
1978 cf_with_manpages="$cf_with_manpages"
1979 cf_with_tests="$cf_with_tests"
1980 host="$host"
1981 target="$target"
1982
1983 ],cat)dnl
1984 ${MAKE:-make} preinstall