ncurses 6.1 - patch 20190720
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2018,2019 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.688 2019/06/30 15:21:02 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See https://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.52.20170501)
38 AC_REVISION($Revision: 1.688 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44 CF_VERSION_INFO(NCURSES,ncurses)
45
46 CF_WITH_REL_VERSION(NCURSES)
47 CF_NCURSES_WITH_ABI_VERSION
48
49 CF_WITH_SYSTYPE
50
51 ###     Save the given $CFLAGS to allow user-override.
52 cf_user_CFLAGS="$CFLAGS"
53
54 ###     Default install-location
55 CF_CFG_DEFAULTS
56 ### Defaults for ncurses ABI
57 CF_ABI_DEFAULTS
58
59 ###     Checks for programs.
60 AC_ARG_WITH(ada,
61         [  --without-ada           suppress check for Ada95, don't build demo],
62         [cf_with_ada=$withval],
63         [cf_with_ada=yes])
64
65 if test "x$cf_with_ada" = xyes
66 then
67         cf_prog_cc="gnatgcc gcc cc"
68 else
69         cf_prog_cc="gcc cc"
70 fi
71 CF_PROG_CC($cf_prog_cc)
72
73 AC_PROG_CPP
74 AC_PROG_GCC_TRADITIONAL
75 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
76 CF_PROG_LDCONFIG
77
78 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
79 dnl                             configure script by not letting us test if C++
80 dnl                             is present, making this option necessary.
81 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
82 AC_ARG_WITH(cxx,
83         [  --without-cxx           do not adjust ncurses bool to match C++],
84         [cf_with_cxx=$withval],
85         [cf_with_cxx=yes])
86 AC_MSG_RESULT($cf_with_cxx)
87 if test "X$cf_with_cxx" = Xno ; then
88         CXX=""
89         GXX=""
90 else
91         # with autoconf 2.13, we can change the error to a warning:
92         pushdef([AC_MSG_ERROR],
93                 [AC_MSG_RESULT(no)
94                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
95                 cf_with_cxx=no; CXX=""; GXX="";])dnl
96         AC_PROG_CXX
97         popdef([AC_MSG_ERROR])dnl
98
99         AC_LANG_PUSH(C++)
100         if test "x$cf_with_cxx" != xno
101         then
102                 # Several of the C++ configurations do not work, particularly when
103                 # cross-compiling (20140913 -TD)
104                 AC_MSG_CHECKING(if $CXX works)
105
106                 save_CPPFLAGS="$CPPFLAGS"
107                 eval cf_includedir=${includedir}
108                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
109                 AC_TRY_COMPILE([
110 #include <stdlib.h>
111 #include <stdio.h>
112 ],
113                 [
114                 printf("Hello world!\n")
115                 ],
116                 [cf_cxx_works=yes],
117                 [cf_cxx_works=no])
118                 CPPFLAGS="$save_CPPFLAGS"
119
120                 AC_MSG_RESULT($cf_cxx_works)
121                 if test "x$cf_cxx_works" = xno
122                 then
123                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
124                         cf_with_cxx=no; CXX=""; GXX="";
125                 fi
126         fi
127         AC_LANG_POP
128
129         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
130         if test "$CXX" = "g++" ; then
131                 AC_PATH_PROG(CXX,g++)
132         fi
133         case "x$CXX" in
134         (x|xg++)
135                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
136                 cf_with_cxx=no; CXX=""; GXX="";
137                 ;;
138         esac
139 fi
140
141 CF_GXX_VERSION
142 case $GXX_VERSION in
143 (1*|2.[[0-6]]*)
144         # GXX=""; CXX=""; ac_cv_prog_gxx=no
145         # cf_cxx_library=no
146         AC_MSG_WARN(templates do not work)
147         ;;
148 esac
149
150 AC_MSG_CHECKING(if you want to build C++ binding and demo)
151 AC_ARG_WITH(cxx-binding,
152         [  --without-cxx-binding   do not build C++ binding and demo],
153         [cf_with_cxx_binding=$withval],
154         [cf_with_cxx_binding=$cf_with_cxx])
155 AC_MSG_RESULT($cf_with_cxx_binding)
156
157 AC_MSG_CHECKING(if you want to build with Ada95)
158 AC_MSG_RESULT($cf_with_ada)
159
160 AC_MSG_CHECKING(if you want to install terminal database)
161 AC_ARG_ENABLE(db-install,
162         [  --disable-db-install    suppress install of terminal database],
163         [cf_with_db_install=$enableval],
164         [cf_with_db_install=yes])
165 AC_MSG_RESULT($cf_with_db_install)
166
167 AC_MSG_CHECKING(if you want to install manpages)
168 AC_ARG_WITH(manpages,
169         [  --without-manpages      suppress install of manpages],
170         [cf_with_manpages=$withval],
171         [cf_with_manpages=yes])
172 AC_MSG_RESULT($cf_with_manpages)
173
174 AC_MSG_CHECKING(if you want to build programs such as tic)
175 AC_ARG_WITH(progs,
176         [  --without-progs         suppress build/install with programs (e.g., tic)],
177         [cf_with_progs=$withval],
178         [cf_with_progs=yes])
179 AC_MSG_RESULT($cf_with_progs)
180
181 if test -f $srcdir/tack/tack.h; then
182         if test "x$cross_compiling" = xyes ; then
183                 CF_VERBOSE(ignoring tack because we are cross-compiling)
184                 cf_with_tack=no
185         else
186                 AC_MSG_CHECKING(if you want to build the tack program)
187                 AC_ARG_WITH(tack,
188                         [  --without-tack          suppress build/install with tack program],
189                         [cf_with_tack=$withval],
190                         [cf_with_tack=$cf_with_progs])
191                 AC_MSG_RESULT($cf_with_tack)
192         fi
193 else
194         cf_with_tack=no
195 fi
196
197 AC_MSG_CHECKING(if you want to build test-programs)
198 AC_ARG_WITH(tests,
199         [  --without-tests         suppress build/install with test-programs],
200         [cf_with_tests=$withval],
201         [cf_with_tests=yes])
202 AC_MSG_RESULT($cf_with_tests)
203
204 AC_MSG_CHECKING(if you wish to install curses.h)
205 AC_ARG_WITH(curses-h,
206         [  --without-curses-h      install curses.h as ncurses.h only],
207         [with_curses_h=$withval],
208         [with_curses_h=yes])
209 AC_MSG_RESULT($with_curses_h)
210
211 modules_to_build="ncurses"
212 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
213 test "X$cf_with_tack"  != Xno && modules_to_build="$modules_to_build tack"
214 modules_to_build="$modules_to_build panel menu form"
215
216 AC_ARG_PROGRAM
217
218 CF_PROG_AWK
219 CF_PROG_EGREP
220 CF_PROG_INSTALL
221 CF_PROG_LINT
222 CF_PROG_LN_S
223
224 AC_SYS_LONG_FILE_NAMES
225
226 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
227 # of package conflict.
228 cf_config_suffix=
229 AC_ARG_WITH(config-suffix,
230         [  --with-config-suffix=X  suffixes ncursesXX-config file],
231         [case "x$withval" in
232         (xyes|xno)
233                 AC_MSG_WARN(expected a value for config-suffix option)
234                 ;;
235         (*)     cf_config_suffix="$withval"
236                 ;;
237         esac])
238 AC_SUBST(cf_config_suffix)
239
240 # If we find pkg-config, check if we should install the ".pc" files.
241 CF_PKG_CONFIG
242 CF_WITH_PKG_CONFIG_LIBDIR
243 CF_ENABLE_PC_FILES
244 if test -z "$MAKE_PC_FILES"
245 then
246         AC_MSG_CHECKING(for suffix to add to pc-files)
247 AC_ARG_WITH(pc-suffix,
248         [  --with-pc-suffix        suffixes pc-files],
249         [case "x$withval" in
250         (xyes|xno)
251                 PC_MODULE_SUFFIX=
252                 ;;
253         (*)     PC_MODULE_SUFFIX="$withval"
254                 ;;
255         esac])
256         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
257         AC_MSG_RESULT($PC_MODULE_SUFFIX)
258         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
259         AC_SUBST(PC_MODULE_SUFFIX)
260 fi
261
262 AC_MSG_CHECKING(if we should assume mixed-case filenames)
263 AC_ARG_ENABLE(mixed-case,
264         [  --enable-mixed-case     tic should assume mixed-case filenames],
265         [enable_mixedcase=$enableval],
266         [enable_mixedcase=auto])
267 AC_MSG_RESULT($enable_mixedcase)
268 if test "$enable_mixedcase" = "auto" ; then
269         CF_MIXEDCASE_FILENAMES
270 else
271         cf_cv_mixedcase=$enable_mixedcase
272         if test "x$enable_mixedcase" = "xyes" ; then
273                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
274         fi
275 fi
276
277 # do this after mixed-case option (tags/TAGS is not as important as tic).
278 AC_PROG_MAKE_SET
279 CF_MAKE_TAGS
280 CF_MAKEFLAGS
281
282 dnl These are standard among *NIX systems, but not when cross-compiling
283 AC_CHECK_TOOL(RANLIB, ranlib, ':')
284 AC_CHECK_TOOL(LD, ld, ld)
285 AC_CHECK_TOOL(AR, ar, ar)
286 AC_CHECK_TOOL(NM, nm, nm)
287 CF_AR_FLAGS
288
289 dnl Special option for use by system-builders: the install-prefix is used to
290 dnl adjust the location into which the actual install is done, so that an
291 dnl archive can be built without modifying the host system's configuration.
292 AC_MSG_CHECKING(if you have specified an install-prefix)
293 AC_ARG_WITH(install-prefix,
294         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
295         [case "x$withval" in
296         (xyes|xno)
297                 ;;
298         (*)     DESTDIR="$withval"
299                 ;;
300         esac])
301 AC_MSG_RESULT($DESTDIR)
302 AC_SUBST(DESTDIR)
303
304 ###############################################################################
305 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
306 # If we're cross-compiling, allow the user to override the tools and their
307 # options.  The configure script is oriented toward identifying the host
308 # compiler, etc., but we need a build compiler to generate parts of the source.
309 CF_BUILD_CC
310
311 ###############################################################################
312 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
313
314 ### Options to allow the user to specify the set of libraries which are used.
315 ### Use "--without-normal --with-shared" to allow the default model to be
316 ### shared, for example.
317 cf_list_models=""
318 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
319
320 CF_WITH_LIBTOOL
321 if test "$with_libtool" != "no" ; then
322
323 cf_list_models="$cf_list_models libtool"
324
325 else
326
327 AC_MSG_CHECKING(if you want to build shared libraries)
328 AC_ARG_WITH(shared,
329         [  --with-shared           generate shared-libraries],
330         [with_shared=$withval],
331         [with_shared=no])
332 AC_MSG_RESULT($with_shared)
333 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
334
335 AC_MSG_CHECKING(if you want to build static libraries)
336 AC_ARG_WITH(normal,
337         [  --with-normal           generate normal-libraries (default)],
338         [with_normal=$withval],
339         [with_normal=yes])
340 AC_MSG_RESULT($with_normal)
341 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
342
343 AC_MSG_CHECKING(if you want to build debug libraries)
344 AC_ARG_WITH(debug,
345         [  --with-debug            generate debug-libraries (default)],
346         [with_debug=$withval],
347         [with_debug=yes])
348 AC_MSG_RESULT($with_debug)
349 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
350
351 AC_MSG_CHECKING(if you want to build profiling libraries)
352 AC_ARG_WITH(profile,
353         [  --with-profile          generate profile-libraries],
354         [with_profile=$withval],
355         [with_profile=no])
356 AC_MSG_RESULT($with_profile)
357 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
358
359 fi
360
361 if test "X$cf_with_cxx_binding" != Xno; then
362 if test "x$with_shared" = "xyes"; then
363 AC_MSG_CHECKING(if you want to build C++ shared libraries)
364 AC_ARG_WITH(cxx-shared,
365         [  --with-cxx-shared       generate C++ shared-libraries],
366         [with_shared_cxx=$withval],
367         [with_shared_cxx=no])
368 AC_MSG_RESULT($with_shared_cxx)
369 fi
370 fi
371
372 ###############################################################################
373
374 AC_MSG_CHECKING(for specified models)
375 test -z "$cf_list_models" && cf_list_models=normal
376 dnl If we use libtool to generate libraries, then it must be the only
377 dnl specified model.
378 test "$with_libtool" != "no" && cf_list_models=libtool
379 AC_MSG_RESULT($cf_list_models)
380
381 ### Use the first model as the default, and save its suffix for use in building
382 ### up test-applications.
383 AC_MSG_CHECKING(for default model)
384 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
385 AC_MSG_RESULT($DFT_LWR_MODEL)
386
387 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
388
389 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
390 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
391
392 TICS_NAME=tic
393 AC_SUBST(TICS_NAME)
394
395 TINFO_NAME=tinfo
396 AC_SUBST(TINFO_NAME)
397
398 LIB_NAME=ncurses
399 AC_SUBST(LIB_NAME)
400
401 LIB_DIR=../lib
402 LIB_2ND=../../lib
403
404 CF_WITH_LIB_PREFIX(cf_prefix)
405
406 LIB_SUFFIX=
407 AC_SUBST(LIB_SUFFIX)
408 CF_PATHSEP
409
410 ###############################################################################
411
412 AC_MSG_CHECKING(if you want to build a separate terminfo library)
413 AC_ARG_WITH(termlib,
414         [  --with-termlib          generate separate terminfo library],
415         [with_termlib=$withval],
416         [with_termlib=no])
417 AC_MSG_RESULT($with_termlib)
418
419 AC_MSG_CHECKING(if you want to build a separate tic library)
420 AC_ARG_WITH(ticlib,
421         [  --with-ticlib           generate separate tic library],
422         [with_ticlib=$withval],
423         [with_ticlib=no])
424 AC_MSG_RESULT($with_ticlib)
425
426 dnl Not all ports of gcc support the -g option
427
428 if test X"$CC_G_OPT" = X"" ; then
429         CC_G_OPT='-g'
430         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
431 fi
432 AC_SUBST(CC_G_OPT)
433
434 if test X"$CXX_G_OPT" = X"" ; then
435         CXX_G_OPT='-g'
436         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
437 fi
438 AC_SUBST(CXX_G_OPT)
439
440 AC_MSG_CHECKING(for default loader flags)
441 case $DFT_LWR_MODEL in
442 (libtool) LD_MODEL=''   ;;
443 (normal)  LD_MODEL=''   ;;
444 (debug)   LD_MODEL=$CC_G_OPT ;;
445 (profile) LD_MODEL='-pg';;
446 (shared)  LD_MODEL=''   ;;
447 esac
448 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
449 AC_MSG_RESULT($LD_MODEL)
450
451 case $DFT_LWR_MODEL in
452 (shared)
453 CF_ENABLE_RPATH
454 AC_MSG_CHECKING(if shared libraries should be relinked during install)
455 AC_ARG_ENABLE(relink,
456 [  --disable-relink        relink shared libraries during install],
457 [cf_cv_do_relink=$enableval],
458 [cf_cv_do_relink=yes])
459 AC_MSG_RESULT($cf_cv_do_relink)
460         ;;
461 esac
462
463 # we will build libraries one-level down.
464 rel_builddir=..
465 CF_SHARED_OPTS
466 for model in $cf_list_models; do
467         case $model in
468         (libtool)
469                 CF_WITH_LIBTOOL_OPTS
470                 CF_WITH_EXPORT_SYMS
471                 ;;
472         (shared)
473                 if test "$CC_SHARED_OPTS" = "unknown"; then
474                         AC_ERROR(Shared libraries are not supported in this version)
475                 fi
476                 # workaround for inept transition to PIE vs PIC...
477                 AC_MSG_CHECKING(if current CFLAGS link properly)
478                 AC_TRY_LINK(
479                         [#include <stdio.h>],
480                         [printf("Hello work\n");],
481                         [cf_cflags_work=yes],
482                         [cf_cflags_work=no])
483                 AC_MSG_RESULT($cf_cflags_work)
484                 if test "$cf_cflags_work" = no
485                 then
486                         CF_VERBOSE(try to work around by appending shared-options)
487                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
488                 fi
489                 CF_WITH_VERSIONED_SYMS
490                 ;;
491         esac
492 done
493
494 ### Checks for special libraries, must be done up-front.
495 SHLIB_LIST=""
496 CF_WITH_GPM
497 if test "$with_gpm" != no ; then
498         AC_MSG_CHECKING(if you want to load GPM dynamically)
499         AC_ARG_WITH(dlsym,
500                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
501                 [with_dlsym=$withval],
502                 [with_dlsym=yes])
503         AC_MSG_RESULT($with_dlsym)
504         if test "x$with_dlsym" = xyes ; then
505                 CF_FUNC_DLSYM
506                 if test "x$with_gpm" != xyes ; then
507                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
508                         cf_cv_gpm_soname="$with_gpm"
509                 else
510                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
511                 fi
512                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
513                 SHLIB_LIST="-ldl $SHLIB_LIST"
514                 CF_ADD_LIB(dl,PRIVATE_LIBS)
515         else
516                 SHLIB_LIST="-lgpm $SHLIB_LIST"
517                 CF_ADD_LIB(gpm,TEST_LIBS)
518                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
519         fi
520         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
521         CF_CHECK_GPM_WGETCH
522 fi
523
524 CF_WITH_PCRE2
525 CF_WITH_SYSMOUSE
526
527 # pretend that ncurses==ncursesw==ncursest
528 AC_MSG_CHECKING(if you want to disable library suffixes)
529 CF_ARG_DISABLE(lib-suffixes,
530         [  --disable-lib-suffixes  disable library suffixes],
531         [disable_lib_suffixes=yes],
532         [disable_lib_suffixes=no],
533         no)
534 AC_MSG_RESULT($disable_lib_suffixes)
535
536 ### If we're building with rpath, try to link non-standard libs that way too.
537 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
538         CF_DISABLE_RPATH_HACK
539 fi
540
541 ###############################################################################
542 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
543
544 ###     use option --with-extra-suffix to append suffix to headers and libraries
545 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
546 EXTRA_SUFFIX=
547 AC_ARG_WITH(extra-suffix,
548         [  --with-extra-suffix=X   append extra suffix to header/library paths],
549         [case x$withval in
550         (no)
551                 ;;
552         (xyes|x)
553                 EXTRA_SUFFIX=$cf_cv_abi_version
554                 ;;
555         (*)
556                 EXTRA_SUFFIX=$withval
557                 ;;
558         esac
559         ])
560 AC_MSG_RESULT($EXTRA_SUFFIX)
561 AC_SUBST(EXTRA_SUFFIX)
562
563 ###     use option --disable-overwrite to leave out the link to -lcurses
564 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
565 AC_ARG_ENABLE(overwrite,
566         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
567         [with_overwrite=$enableval],
568         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
569 AC_MSG_RESULT($with_overwrite)
570
571 AC_MSG_CHECKING(if external terminfo-database is used)
572 AC_ARG_ENABLE(database,
573         [  --disable-database      do not use terminfo, only fallbacks/termcap],
574         [use_database=$enableval],
575         [use_database=yes])
576 AC_MSG_RESULT($use_database)
577
578 case $host_os in
579 (os2*)
580         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
581         ;;
582 (*)
583         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
584         ;;
585 esac
586 AC_SUBST(TERMINFO_SRC)
587
588 NCURSES_USE_DATABASE=0
589 if test "$use_database" != no ; then
590         NCURSES_USE_DATABASE=1
591
592         AC_MSG_CHECKING(which terminfo source-file will be installed)
593         AC_ARG_WITH(database,
594                 [  --with-database=XXX     specify terminfo source to install],
595                 [TERMINFO_SRC=$withval])
596         AC_MSG_RESULT($TERMINFO_SRC)
597
598         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
599         AC_ARG_WITH(hashed-db,
600                 [  --with-hashed-db        specify hashed-database library],,
601                 [with_hashed_db=no])
602         AC_MSG_RESULT($with_hashed_db)
603 else
604         with_hashed_db=no
605 fi
606 AC_SUBST(NCURSES_USE_DATABASE)
607
608 AC_MSG_CHECKING(for list of fallback descriptions)
609 AC_ARG_WITH(fallbacks,
610         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
611         [with_fallback=$withval],
612         [with_fallback=])
613 AC_MSG_RESULT($with_fallback)
614
615 case ".$with_fallback" in
616 (.|.no)
617         FALLBACK_LIST=
618         ;;
619 (.yes)
620         AC_MSG_WARN(expected a list of terminal descriptions)
621         ;;
622 (*)
623         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
624         ;;
625 esac
626
627 USE_FALLBACKS=
628 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
629 AC_SUBST(FALLBACK_LIST)
630 AC_SUBST(USE_FALLBACKS)
631
632 # The fallback feature in ncurses relies upon tic/infocmp outside the build
633 # tree for generating the terminal descriptions that will be compiled into the
634 # library.  If your toolchain is old, it may not handle current terminal
635 # databases.  Use configure-options to point to the tools which will be used,
636 # rather than the first ones found on the $PATH.
637 if test -n "$FALLBACK_LIST"
638 then
639         CF_WITH_PATH_PROG(TIC,     tic,     [for fallbacks], $PATH:/usr/local/ncurses/bin)
640         CF_WITH_PATH_PROG(INFOCMP, infocmp, [for fallbacks], $PATH:/usr/local/ncurses/bin)
641 else
642         : ${TIC:=tic}
643         : ${INFOCMP:=infocmp}
644 fi
645 AC_SUBST(TIC)
646 AC_SUBST(INFOCMP)
647
648 AC_MSG_CHECKING(if you want modern xterm or antique)
649 AC_ARG_WITH(xterm-new,
650         [  --without-xterm-new     specify if xterm terminfo should be old version],
651         [with_xterm_new=$withval],
652         [with_xterm_new=yes])
653 case $with_xterm_new in
654 (no) with_xterm_new=xterm-old;;
655 (*)      with_xterm_new=xterm-new;;
656 esac
657 AC_MSG_RESULT($with_xterm_new)
658 WHICH_XTERM=$with_xterm_new
659 AC_SUBST(WHICH_XTERM)
660
661 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
662 AC_ARG_WITH(xterm-kbs,
663         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
664         [with_xterm_kbs=$withval],
665         [with_xterm_kbs=BS])
666 case x$with_xterm_kbs in
667 (xyes|xno|xBS|xbs|x8)
668         with_xterm_kbs=BS
669         ;;
670 (xDEL|xdel|x127)
671         with_xterm_kbs=DEL
672         ;;
673 (*)
674         with_xterm_kbs=$withval
675         ;;
676 esac
677 AC_MSG_RESULT($with_xterm_kbs)
678 XTERM_KBS=$with_xterm_kbs
679 AC_SUBST(XTERM_KBS)
680
681 MAKE_TERMINFO=
682 if test "$use_database" = no ; then
683         TERMINFO="${datadir}/terminfo"
684         MAKE_TERMINFO="#"
685 else
686
687 AC_MSG_CHECKING(for list of terminfo directories)
688 CF_WITH_PATHLIST(terminfo-dirs,
689         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
690         TERMINFO_DIRS,
691         DATADIR/terminfo,
692         ${datadir}/terminfo)
693 AC_MSG_RESULT($TERMINFO_DIRS)
694 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
695
696 case "x$TERMINFO" in
697 x???:*)
698         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
699         unset TERMINFO
700         ;;
701 esac
702
703 AC_MSG_CHECKING(for default terminfo directory)
704 CF_WITH_PATH(default-terminfo-dir,
705         [  --with-default-terminfo-dir=DIR default terminfo directory],
706         TERMINFO,
707         DATADIR/terminfo,
708         ${datadir}/terminfo)
709 AC_MSG_RESULT($TERMINFO)
710 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
711
712 fi
713
714 AC_SUBST(TERMINFO)
715 AC_SUBST(MAKE_TERMINFO)
716
717 ###     use option --disable-big-core to make tic run on small machines
718 ###     We need 4Mb, check if we can allocate 50% more than that.
719 AC_MSG_CHECKING(if big-core option selected)
720 AC_ARG_ENABLE(big-core,
721         [  --disable-big-core      assume machine has little memory],
722         [with_big_core=$enableval],
723         [AC_TRY_RUN([
724 #include <stdlib.h>
725 #include <string.h>
726 int main() {
727         unsigned long n = 6000000L;
728         char *s = malloc(n);
729         if (s != 0)
730                 s[0] = s[n-1] = 0;
731         ${cf_cv_main_return:-return}(s == 0);
732 }],
733         [with_big_core=yes],
734         [with_big_core=no],
735         [with_big_core=no])])
736 AC_MSG_RESULT($with_big_core)
737 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
738
739 ### ISO C only guarantees 512-char strings, we have tables which load faster
740 ### when constructed using "big" strings.  More than the C compiler, the awk
741 ### program is a limit on most vendor UNIX systems.  Check that we can build.
742 AC_MSG_CHECKING(if big-strings option selected)
743 AC_ARG_ENABLE(big-strings,
744         [  --disable-big-strings   assume compiler has only standard-size strings],
745         [with_big_strings=$enableval],
746         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
747 AC_MSG_RESULT($with_big_strings)
748
749 USE_BIG_STRINGS=0
750 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
751 AC_SUBST(USE_BIG_STRINGS)
752
753 ###     use option --enable-termcap to compile in the termcap fallback support
754 AC_MSG_CHECKING(if you want termcap-fallback support)
755 AC_ARG_ENABLE(termcap,
756         [  --enable-termcap        compile in termcap fallback support],
757         [with_termcap=$enableval],
758         [with_termcap=no])
759 AC_MSG_RESULT($with_termcap)
760
761 NCURSES_USE_TERMCAP=0
762 if test "x$with_termcap" != "xyes" ; then
763         if test "$use_database" = no ; then
764                 if test -z "$with_fallback" ; then
765                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
766                 fi
767         fi
768         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
769 else
770
771         if test "$with_ticlib" != no ; then
772                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
773         fi
774
775         NCURSES_USE_TERMCAP=1
776         AC_MSG_CHECKING(for list of termcap files)
777         CF_WITH_PATHLIST(termpath,
778                 [  --with-termpath=XXX     specify list of termcap files],
779                 TERMPATH,
780                 /etc/termcap:/usr/share/misc/termcap)
781         AC_MSG_RESULT($TERMPATH)
782         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
783
784         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
785         AC_MSG_CHECKING(if fast termcap-loader is needed)
786         AC_ARG_ENABLE(getcap,
787                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
788                 [with_getcap=$enableval],
789                 [with_getcap=no])
790         AC_MSG_RESULT($with_getcap)
791         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
792
793         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
794         AC_ARG_ENABLE(getcap-cache,
795                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
796                 [with_getcap_cache=$enableval],
797                 [with_getcap_cache=no])
798         AC_MSG_RESULT($with_getcap_cache)
799         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
800
801 fi
802 AC_SUBST(NCURSES_USE_TERMCAP)
803
804 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
805 AC_MSG_CHECKING(if ~/.terminfo is wanted)
806 AC_ARG_ENABLE(home-terminfo,
807         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
808         [with_home_terminfo=$enableval],
809         [with_home_terminfo=yes])
810 AC_MSG_RESULT($with_home_terminfo)
811 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
812
813 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
814 AC_ARG_ENABLE(root-environ,
815         [  --disable-root-environ  restrict environment when running as root],
816         [with_root_environ=$enableval],
817         [with_root_environ=yes])
818 AC_MSG_RESULT($with_root_environ)
819 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
820
821 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
822 ###   to reduce storage requirements for the terminfo database.
823 CF_LINK_FUNCS
824
825 with_links=no
826 with_symlinks=no
827
828 # soft links (symbolic links) are useful for some systems where hard links do
829 # not work, or to make it simpler to copy terminfo trees around.
830 if test "x$ac_cv_func_symlink" = xyes ; then
831         AC_MSG_CHECKING(if tic should use symbolic links)
832         AC_ARG_ENABLE(symlinks,
833         [  --enable-symlinks       make tic use symbolic links not hard links],
834         [with_symlinks=$enableval],
835         [with_symlinks=no])
836         AC_MSG_RESULT($with_symlinks)
837 fi
838
839 # If we have hard links and did not choose to use soft links instead, there is
840 # no reason to make this choice optional - use the hard links.
841 if test "$with_symlinks" = no ; then
842         AC_MSG_CHECKING(if tic should use hard links)
843         if test "x$ac_cv_func_link" = xyes ; then
844                 with_links=yes
845         else
846                 with_links=no
847         fi
848         AC_MSG_RESULT($with_links)
849 fi
850
851 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
852 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
853
854 ###   use option --enable-broken-linker to force on use of broken-linker support
855 AC_MSG_CHECKING(if you want broken-linker support code)
856 AC_ARG_ENABLE(broken_linker,
857         [  --enable-broken_linker  compile with broken-linker support code],
858         [with_broken_linker=$enableval],
859         [with_broken_linker=${BROKEN_LINKER:-no}])
860 AC_MSG_RESULT($with_broken_linker)
861
862 BROKEN_LINKER=0
863 if test "x$with_broken_linker" = xyes ; then
864         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
865         BROKEN_LINKER=1
866 elif test "$DFT_LWR_MODEL" = shared ; then
867         case $cf_cv_system_name in
868         (cygwin*)
869                 AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
870                 BROKEN_LINKER=1
871                 CF_VERBOSE(cygwin linker is broken anyway)
872                 ;;
873         esac
874 fi
875 AC_SUBST(BROKEN_LINKER)
876
877 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
878 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
879 AC_ARG_ENABLE(bsdpad,
880         [  --enable-bsdpad         recognize BSD-style prefix padding],
881         [with_bsdpad=$enableval],
882         [with_bsdpad=no])
883 AC_MSG_RESULT($with_bsdpad)
884 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
885
886 ###   use option --enable-widec to turn on use of wide-character support
887 NCURSES_CH_T=chtype
888 NCURSES_LIBUTF8=0
889
890 NEED_WCHAR_H=0
891 NCURSES_MBSTATE_T=0
892 NCURSES_WCHAR_T=0
893 NCURSES_WINT_T=0
894
895 # Check to define _XOPEN_SOURCE "automatically"
896 CPPFLAGS_before_XOPEN="$CPPFLAGS"
897 CF_XOPEN_SOURCE(600)
898 CPPFLAGS_after_XOPEN="$CPPFLAGS"
899
900 # Work around breakage on OS X
901 CF_SIGWINCH
902
903 # Checks for CODESET support.
904 AM_LANGINFO_CODESET
905
906 # use these variables to work around a defect in gcc's fixincludes.
907 NCURSES_OK_WCHAR_T=
908 NCURSES_OK_WINT_T=
909
910 AC_MSG_CHECKING(if you want wide-character code)
911 AC_ARG_ENABLE(widec,
912         [  --enable-widec          compile with wide-char/UTF-8 code],
913         [with_widec=$enableval],
914         [with_widec=no])
915 AC_MSG_RESULT($with_widec)
916
917 NCURSES_WCWIDTH_GRAPHICS=1
918 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
919
920 if test "x$with_widec" = xyes ; then
921         if test "x$disable_lib_suffixes" = xno ; then
922                 LIB_SUFFIX="w${LIB_SUFFIX}"
923         fi
924         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
925         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
926
927         CF_CHECK_WCHAR_H
928         CF_CHECK_WCWIDTH_GRAPHICS
929         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
930
931         # with_overwrite=no
932         NCURSES_CH_T=cchar_t
933         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
934         if test "x$ac_cv_func_putwc" != xyes ; then
935                 CF_UTF8_LIB
936                 if test "$cf_cv_utf8_lib" != no ; then
937                         NCURSES_LIBUTF8=1
938                 fi
939         fi
940         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
941         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
942         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
943
944         if test "$NCURSES_MBSTATE_T" != 0; then
945                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
946         fi
947 fi
948 AC_SUBST(NCURSES_CH_T)
949 AC_SUBST(NCURSES_LIBUTF8)
950
951 AC_SUBST(NEED_WCHAR_H)
952 AC_SUBST(NCURSES_MBSTATE_T)
953 AC_SUBST(NCURSES_WCHAR_T)
954 AC_SUBST(NCURSES_WINT_T)
955
956 AC_SUBST(NCURSES_OK_WCHAR_T)
957 AC_SUBST(NCURSES_OK_WINT_T)
958
959 ###   use option --disable-lp64 to allow long chtype
960 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
961 AC_ARG_ENABLE(lp64,
962         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
963         [with_lp64=$enableval],
964         [with_lp64=$cf_dft_with_lp64])
965 AC_MSG_RESULT($with_lp64)
966
967 if test "x$with_lp64" = xyes ; then
968         cf_cv_enable_lp64=1
969 else
970         cf_cv_enable_lp64=0
971 fi
972 AC_SUBST(cf_cv_enable_lp64)
973
974 CF_LARGEFILE
975
976 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
977 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
978 AC_ARG_ENABLE(tparm-varargs,
979         [  --disable-tparm-varargs compile tparm() without varargs interface],
980         [with_tparm_varargs=$enableval],
981         [with_tparm_varargs=yes])
982 AC_MSG_RESULT($with_tparm_varargs)
983 NCURSES_TPARM_VARARGS=0
984 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
985 AC_SUBST(NCURSES_TPARM_VARARGS)
986
987 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
988 if test "$with_ticlib" != no ; then
989 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
990 AC_ARG_ENABLE(tic-depends,
991         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
992         [with_tic_depends=$enableval],
993         [with_tic_depends=yes])
994 AC_MSG_RESULT($with_tic_depends)
995 else
996         with_tic_depends=no
997 fi
998
999 ###   use option --disable-wattr-macros to suppress wattr* macros from curses.h
1000 AC_MSG_CHECKING(if you want to suppress wattr* macros to help with ncurses5/ncurses6 transition)
1001 AC_ARG_ENABLE(wattr-macros,
1002         [  --disable-wattr-macros  suppress wattr* macros to help with ncurses5/ncurses6 transition],
1003         [with_wattr_macros=$enableval],
1004         [with_wattr_macros=yes])
1005 if [[ "x$with_wattr_macros" != xyes ]]; then
1006         NCURSES_WATTR_MACROS=0
1007         AC_MSG_RESULT(yes)
1008 else
1009         NCURSES_WATTR_MACROS=1
1010         AC_MSG_RESULT(no)
1011 fi
1012 AC_SUBST(NCURSES_WATTR_MACROS)
1013
1014 CF_WITH_X11_RGB
1015
1016 ###   use option --with-bool to override bool's type
1017 AC_MSG_CHECKING(for type of bool)
1018 AC_ARG_WITH(bool,
1019         [  --with-bool=TYPE        override fallback type of bool variable],
1020         [NCURSES_BOOL="$withval"],
1021         [NCURSES_BOOL=auto])
1022 AC_MSG_RESULT($NCURSES_BOOL)
1023 AC_SUBST(NCURSES_BOOL)
1024
1025 AC_MSG_CHECKING(for alternate terminal capabilities file)
1026 AC_ARG_WITH(caps,
1027         [  --with-caps=alt         compile with alternate Caps file],
1028         [TERMINFO_CAPS=Caps.$withval],
1029         [TERMINFO_CAPS=Caps])
1030 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
1031 AC_MSG_RESULT($TERMINFO_CAPS)
1032 AC_SUBST(TERMINFO_CAPS)
1033
1034 ###   use option --with-chtype to override chtype's type
1035 AC_MSG_CHECKING(for type of chtype)
1036 AC_ARG_WITH(chtype,
1037         [  --with-chtype=TYPE      override type of chtype],
1038         [NCURSES_CHTYPE="$withval"],
1039         [NCURSES_CHTYPE=$cf_dft_chtype])
1040 AC_MSG_RESULT($NCURSES_CHTYPE)
1041
1042 ###   use option --with-ospeed to override ospeed's type
1043 AC_MSG_CHECKING(for type of ospeed)
1044 AC_ARG_WITH(ospeed,
1045         [  --with-ospeed=TYPE      override type of ospeed variable],
1046         [NCURSES_OSPEED="$withval"],
1047         [NCURSES_OSPEED=short])
1048 AC_MSG_RESULT($NCURSES_OSPEED)
1049 AC_SUBST(NCURSES_OSPEED)
1050
1051 ###   use option --with-mmask-t to override mmask_t's type
1052 AC_MSG_CHECKING(for type of mmask_t)
1053 AC_ARG_WITH(mmask-t,
1054         [  --with-mmask-t=TYPE     override type of mmask_t],
1055         [NCURSES_MMASK_T="$withval"],
1056         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1057 AC_MSG_RESULT($NCURSES_MMASK_T)
1058
1059 ###   use option --with-ccharw-max to override CCHARW_MAX size
1060 AC_MSG_CHECKING(for size CCHARW_MAX)
1061 AC_ARG_WITH(ccharw-max,
1062         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1063         [NCURSES_CCHARW_MAX="$withval"],
1064         [NCURSES_CCHARW_MAX=5])
1065 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1066 AC_SUBST(NCURSES_CCHARW_MAX)
1067
1068 AC_CHECK_SIZEOF([signed char], 0)
1069 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1070         NCURSES_SBOOL="signed char"
1071 else
1072         NCURSES_SBOOL="char"
1073 fi
1074 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1075 AC_ARG_ENABLE(signed-char,
1076         [  --enable-signed-char    compile using signed Boolean's in term.h],
1077         [with_signed_char=$enableval],
1078         [with_signed_char=no])
1079 AC_MSG_RESULT($with_signed_char)
1080 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1081 AC_SUBST(NCURSES_SBOOL)
1082
1083 ###   use option --with-tparm-arg to override tparm's argument type
1084 AC_MSG_CHECKING(for type of tparm args)
1085 AC_ARG_WITH(tparm-arg,
1086         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1087         [NCURSES_TPARM_ARG="$withval"],
1088         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1089 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1090 AC_SUBST(NCURSES_TPARM_ARG)
1091
1092 ### Enable compiling-in rcs id's
1093 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1094 AC_ARG_WITH(rcs-ids,
1095         [  --with-rcs-ids          compile-in RCS identifiers],
1096         [with_rcs_ids=$withval],
1097         [with_rcs_ids=no])
1098 AC_MSG_RESULT($with_rcs_ids)
1099 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1100
1101 ###############################################################################
1102 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1103
1104 ###############################################################################
1105 CF_HELP_MESSAGE(Extensions:)
1106
1107 ### Note that some functions (such as const) are normally disabled anyway.
1108 AC_MSG_CHECKING(if you want to build with function extensions)
1109 AC_ARG_ENABLE(ext-funcs,
1110         [  --disable-ext-funcs     disable function-extensions],
1111         [with_ext_funcs=$enableval],
1112         [with_ext_funcs=yes])
1113 AC_MSG_RESULT($with_ext_funcs)
1114 if test "x$with_ext_funcs" = xyes ; then
1115         NCURSES_EXT_FUNCS=1
1116         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1117         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1118         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1119         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1120         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1121         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1122         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1123         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1124         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1125         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1126         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1127         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1128         GENERATED_EXT_FUNCS=generated
1129         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1130 else
1131         NCURSES_EXT_FUNCS=0
1132         GENERATED_EXT_FUNCS=
1133 fi
1134 AC_SUBST(NCURSES_EXT_FUNCS)
1135 AC_SUBST(GENERATED_EXT_FUNCS)
1136
1137 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1138 AC_ARG_ENABLE(sp-funcs,
1139         [  --enable-sp-funcs       enable SCREEN-extensions],
1140         [with_sp_funcs=$enableval],
1141         [with_sp_funcs=$cf_dft_ext_spfuncs])
1142 AC_MSG_RESULT($with_sp_funcs)
1143 if test "x$with_sp_funcs" = xyes ; then
1144         NCURSES_SP_FUNCS=1
1145         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1146         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1147         GENERATED_SP_FUNCS=generated
1148 else
1149         NCURSES_SP_FUNCS=0
1150         GENERATED_SP_FUNCS=
1151 fi
1152 AC_SUBST(NCURSES_SP_FUNCS)
1153 AC_SUBST(GENERATED_SP_FUNCS)
1154
1155 AC_MSG_CHECKING(if you want to build with terminal-driver)
1156 AC_ARG_ENABLE(term-driver,
1157         [  --enable-term-driver    enable terminal-driver],
1158         [with_term_driver=$enableval],
1159         [with_term_driver=no])
1160 AC_MSG_RESULT($with_term_driver)
1161 if test "x$with_term_driver" = xyes ; then
1162         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1163         if test "x$with_termlib" != xno ; then
1164                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1165         fi
1166         if test "x$with_sp_funcs" != xyes ; then
1167                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1168         fi
1169 fi
1170
1171 ###   use option --enable-const to turn on use of const beyond that in XSI.
1172 AC_MSG_CHECKING(for extended use of const keyword)
1173 AC_ARG_ENABLE(const,
1174         [  --enable-const          compile with extra/non-standard const],
1175         [with_ext_const=$enableval],
1176         [with_ext_const=$cf_dft_ext_const])
1177 AC_MSG_RESULT($with_ext_const)
1178 NCURSES_CONST='/*nothing*/'
1179 if test "x$with_ext_const" = xyes ; then
1180         NCURSES_CONST=const
1181 fi
1182 AC_SUBST(NCURSES_CONST)
1183
1184 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1185 AC_MSG_CHECKING(if you want to use extended colors)
1186 AC_ARG_ENABLE(ext-colors,
1187         [  --enable-ext-colors     compile for 256-color support],
1188         [with_ext_colors=$enableval],
1189         [with_ext_colors=$cf_dft_ext_colors])
1190 AC_MSG_RESULT($with_ext_colors)
1191 NCURSES_EXT_COLORS=0
1192 if test "x$with_ext_colors" = xyes ; then
1193         if test "x$with_widec" != xyes ; then
1194                 AC_MSG_WARN(This option applies only to wide-character library)
1195         else
1196                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1197                 CF_NCURSES_ABI_6
1198                 NCURSES_EXT_COLORS=1
1199                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1200                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1201                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1202                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1203         fi
1204 fi
1205 AC_SUBST(NCURSES_EXT_COLORS)
1206
1207 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1208 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1209 AC_ARG_ENABLE(ext-mouse,
1210         [  --enable-ext-mouse      compile for extended mouse-encoding],
1211         [with_ext_mouse=$enableval],
1212         [with_ext_mouse=$cf_dft_ext_mouse])
1213 AC_MSG_RESULT($with_ext_mouse)
1214 NCURSES_MOUSE_VERSION=1
1215 if test "x$with_ext_mouse" = xyes ; then
1216         NCURSES_MOUSE_VERSION=2
1217         CF_NCURSES_ABI_6
1218 fi
1219 AC_SUBST(NCURSES_MOUSE_VERSION)
1220
1221 ###   use option --enable-ext-putwin to turn on extended screendumps
1222 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1223 AC_ARG_ENABLE(ext-putwin,
1224         [  --enable-ext-putwin     compile with extended putwin/screendump],
1225         [with_ext_putwin=$enableval],
1226         [with_ext_putwin=$cf_dft_ext_putwin])
1227 AC_MSG_RESULT($with_ext_putwin)
1228 if test "x$with_ext_putwin" = xyes ; then
1229         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1230 fi
1231
1232 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1233 AC_ARG_ENABLE(no-padding,
1234         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1235         [with_no_padding=$enableval],
1236         [with_no_padding=$with_ext_funcs])
1237 AC_MSG_RESULT($with_no_padding)
1238 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1239
1240 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1241 AC_MSG_CHECKING(if you want SIGWINCH handler)
1242 AC_ARG_ENABLE(sigwinch,
1243         [  --enable-sigwinch       compile with SIGWINCH handler],
1244         [with_sigwinch=$enableval],
1245         [with_sigwinch=$with_ext_funcs])
1246 AC_MSG_RESULT($with_sigwinch)
1247 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1248
1249 ###   use option --enable-tcap-names to allow user to define new capabilities
1250 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1251 AC_ARG_ENABLE(tcap-names,
1252         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1253         [with_tcap_names=$enableval],
1254         [with_tcap_names=$with_ext_funcs])
1255 AC_MSG_RESULT($with_tcap_names)
1256 NCURSES_XNAMES=0
1257 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1258 AC_SUBST(NCURSES_XNAMES)
1259
1260 ##############################################################################
1261 CF_HELP_MESSAGE(Reentrant Code:)
1262 CF_WITH_PTHREAD
1263
1264 if test "x$with_pthread" != xno; then
1265         AC_CHECK_FUNC(pthread_kill,[
1266                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1267                 AC_ARG_ENABLE(pthreads-eintr,
1268                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1269                         [use_pthreads_eintr=$enableval],
1270                         [use_pthreads_eintr=no])
1271                 AC_MSG_RESULT($use_pthreads_eintr)
1272                 if test "x$use_pthreads_eintr" = xyes ; then
1273                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1274                 fi])
1275
1276         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1277         AC_ARG_ENABLE(weak-symbols,
1278                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1279                 [use_weak_symbols=$enableval],
1280                 [use_weak_symbols=no])
1281         AC_MSG_RESULT($use_weak_symbols)
1282         if test "x$use_weak_symbols" = xyes ; then
1283                 CF_WEAK_SYMBOLS
1284         else
1285                 cf_cv_weak_symbols=no
1286         fi
1287
1288         if test "x$cf_cv_weak_symbols" = xyes ; then
1289                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1290         fi
1291 fi
1292
1293 PTHREAD=
1294 if test "x$with_pthread" = "xyes" ; then
1295         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1296         enable_reentrant=yes
1297         if test "x$cf_cv_weak_symbols" = xyes ; then
1298                 PTHREAD=-lpthread
1299                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1300         fi
1301 fi
1302 AC_SUBST(PTHREAD)
1303
1304 # Reentrant code has to be opaque; there's little advantage to making ncurses
1305 # opaque outside of that, so there is no --enable-opaque option.  We can use
1306 # this option without --with-pthreads, but this will be always set for
1307 # pthreads.
1308 AC_MSG_CHECKING(if you want reentrant code)
1309 AC_ARG_ENABLE(reentrant,
1310         [  --enable-reentrant      compile with reentrant code],
1311         [with_reentrant=$enableval],
1312         [with_reentrant=no])
1313 AC_MSG_RESULT($with_reentrant)
1314 if test "x$with_reentrant" = xyes ; then
1315         cf_cv_enable_reentrant=1
1316         cf_cv_enable_opaque="NCURSES_INTERNALS"
1317         NCURSES_SIZE_T=int
1318         if test "x$cf_cv_weak_symbols" = xyes ; then
1319                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1320                 CF_ADD_LIB(pthread,TEST_LIBS)
1321                 CF_ADD_LIB(pthread,TEST_LIBS2)
1322                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1323         else
1324                 # when not using weak symbols but with_reentrant,
1325                 # add 't' to the library suffix on all platforms
1326                 # except cygwin, where we only do that if ALSO
1327                 # compiling with full thread support.
1328                 case "$host" in
1329                 (*cygwin* | *msys*)
1330                         if test "$with_pthread" = "yes" ; then
1331                                 if test "x$disable_lib_suffixes" = "xno" ; then
1332                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1333                                 fi
1334                         fi ;;
1335                 (*)
1336                         if test "x$disable_lib_suffixes" = "xno" ; then
1337                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1338                         fi
1339                         ;;
1340                 esac
1341         fi
1342         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1343         CF_NCURSES_ABI_6
1344 else
1345         cf_cv_enable_reentrant=0
1346         cf_cv_enable_opaque="NCURSES_OPAQUE"
1347         NCURSES_SIZE_T=short
1348 fi
1349 AC_SUBST(cf_cv_enable_reentrant)
1350 AC_SUBST(cf_cv_enable_opaque)
1351
1352 AC_SUBST(NCURSES_SIZE_T)
1353
1354 AC_MSG_CHECKING(if you want opaque curses-library structures)
1355 CF_ARG_ENABLE(opaque-curses,
1356         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1357         [enable_opaque_curses=yes],[
1358          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1359          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=no
1360         ])
1361 AC_MSG_RESULT($enable_opaque_curses)
1362
1363 test "$cf_cv_enable_reentrant" = 1 && \
1364 test "$enable_opaque_curses" = no && \
1365 AC_MSG_ERROR(reentrant configuration requires opaque library)
1366
1367 AC_MSG_CHECKING(if you want opaque form-library structures)
1368 AC_ARG_ENABLE(opaque-form,
1369         [  --enable-opaque-form    make form-library structures "opaque"],
1370         [enable_opaque_form=yes],[enable_opaque_form=no])
1371 AC_MSG_RESULT($enable_opaque_form)
1372
1373 AC_MSG_CHECKING(if you want opaque menu-library structures)
1374 AC_ARG_ENABLE(opaque-menu,
1375         [  --enable-opaque-menu    make menu-library structures "opaque"],
1376         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1377 AC_MSG_RESULT($enable_opaque_menu)
1378
1379 AC_MSG_CHECKING(if you want opaque panel-library structures)
1380 AC_ARG_ENABLE(opaque-panel,
1381         [  --enable-opaque-panel   make panel-library structures "opaque"],
1382         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1383 AC_MSG_RESULT($enable_opaque_panel)
1384
1385 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1386 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1387 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1388 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1389
1390 AC_SUBST(NCURSES_OPAQUE)
1391 AC_SUBST(NCURSES_OPAQUE_FORM)
1392 AC_SUBST(NCURSES_OPAQUE_MENU)
1393 AC_SUBST(NCURSES_OPAQUE_PANEL)
1394
1395 ### Allow using a different wrap-prefix
1396 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1397         AC_MSG_CHECKING(for prefix used to wrap public variables)
1398         AC_ARG_WITH(wrap-prefix,
1399                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1400                 [NCURSES_WRAP_PREFIX=$withval],
1401                 [NCURSES_WRAP_PREFIX=_nc_])
1402         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1403 else
1404         NCURSES_WRAP_PREFIX=_nc_
1405 fi
1406 AC_SUBST(NCURSES_WRAP_PREFIX)
1407 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1408
1409 ###############################################################################
1410 # These options are relatively safe to experiment with.
1411 CF_HELP_MESSAGE(Development Code:)
1412 AC_MSG_CHECKING(if you want all development code)
1413 AC_ARG_WITH(develop,
1414         [  --without-develop       disable development options],
1415         [with_develop=$withval],
1416         [with_develop=no])
1417 AC_MSG_RESULT($with_develop)
1418
1419 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1420 AC_MSG_CHECKING(if you want hard-tabs code)
1421 AC_ARG_ENABLE(hard-tabs,
1422         [  --enable-hard-tabs      compile with hard-tabs code],,
1423         [enable_hard_tabs=$with_develop])
1424 AC_MSG_RESULT($enable_hard_tabs)
1425 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1426
1427 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1428 AC_MSG_CHECKING(if you want limited support for xmc)
1429 AC_ARG_ENABLE(xmc-glitch,
1430         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1431         [enable_xmc_glitch=$with_develop])
1432 AC_MSG_RESULT($enable_xmc_glitch)
1433 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1434
1435 ###############################################################################
1436 # These are just experimental, probably should not be in a package:
1437 CF_HELP_MESSAGE(Experimental Code:)
1438
1439 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1440 AC_ARG_ENABLE(assumed-color,
1441         [  --disable-assumed-color do not assume anything about default-colors],
1442         [with_assumed_color=$enableval],
1443         [with_assumed_color=yes])
1444 AC_MSG_RESULT($with_assumed_color)
1445 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1446
1447 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1448 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1449 AC_ARG_ENABLE(hashmap,
1450         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1451         [with_hashmap=$enableval],
1452         [with_hashmap=yes])
1453 AC_MSG_RESULT($with_hashmap)
1454 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1455
1456 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1457 AC_MSG_CHECKING(if you want colorfgbg code)
1458 AC_ARG_ENABLE(colorfgbg,
1459         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1460         [with_colorfgbg=$enableval],
1461         [with_colorfgbg=no])
1462 AC_MSG_RESULT($with_colorfgbg)
1463 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1464
1465 ###   use option --enable-interop to turn on use of bindings used for interop
1466 AC_MSG_CHECKING(if you want interop bindings)
1467 AC_ARG_ENABLE(interop,
1468         [  --enable-interop        compile-in interop bindings],
1469         [with_exp_interop=$enableval],
1470         [with_exp_interop=$cf_dft_interop])
1471 AC_MSG_RESULT($with_exp_interop)
1472
1473 NCURSES_INTEROP_FUNCS=0
1474 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1475 AC_SUBST(NCURSES_INTEROP_FUNCS)
1476
1477
1478 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1479 AC_ARG_ENABLE(safe-sprintf,
1480         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1481         [with_safe_sprintf=$enableval],
1482         [with_safe_sprintf=no])
1483 AC_MSG_RESULT($with_safe_sprintf)
1484
1485 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1486 # when hashmap is used scroll hints are useless
1487 if test "$with_hashmap" = no ; then
1488 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1489 AC_ARG_ENABLE(scroll-hints,
1490         [  --disable-scroll-hints  compile without scroll-hints code],
1491         [with_scroll_hints=$enableval],
1492         [with_scroll_hints=yes])
1493 AC_MSG_RESULT($with_scroll_hints)
1494 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1495 fi
1496
1497 AC_MSG_CHECKING(if you want wgetch-events code)
1498 AC_ARG_ENABLE(wgetch-events,
1499         [  --enable-wgetch-events  compile with wgetch-events code],
1500         [with_wgetch_events=$enableval],
1501         [with_wgetch_events=no])
1502 AC_MSG_RESULT($with_wgetch_events)
1503 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1504
1505 ###############################################################################
1506 CF_HELP_MESSAGE(Testing/development Options:)
1507
1508 ###     use option --disable-echo to suppress full display compiling commands
1509 CF_DISABLE_ECHO
1510 if test "x$enable_echo" = xyes; then
1511         ECHO_LINK=
1512 else
1513         ECHO_LINK='@ echo linking $@ ... ;'
1514         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1515         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1516 fi
1517 AC_SUBST(ECHO_LINK)
1518
1519 # --disable-stripping is used for debugging
1520 CF_INSTALL_OPTS
1521
1522 # If we're avoiding relinking of shared libraries during install, that is to
1523 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1524 # the install program has "-p" (for preserving timestamps).
1525 cf_cv_do_reranlib=yes
1526 if test "x$cf_cv_install_p" = xyes
1527 then
1528         if test "x$cf_cv_do_relink" != xyes
1529         then
1530                 cf_cv_do_reranlib=no
1531                 INSTALL_OPT_P="-p"
1532                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1533         fi
1534 fi
1535 AC_SUBST(INSTALL_OPT_P)
1536
1537 ###     use option --enable-warnings to turn on all gcc warnings
1538 AC_MSG_CHECKING(if you want to see compiler warnings)
1539 AC_ARG_ENABLE(warnings,
1540         [  --enable-warnings       build: turn on GCC compiler warnings],
1541         [with_warnings=$enableval])
1542 AC_MSG_RESULT($with_warnings)
1543
1544 if test "x$with_warnings" = "xyes"; then
1545         CF_ADD_ADAFLAGS(-gnatg)
1546         CF_GCC_WARNINGS(Wno-unknown-pragmas Wswitch-enum)
1547         if test "x$cf_with_cxx" = xyes ; then
1548                 CF_GXX_WARNINGS(Wno-unused)
1549         fi
1550 fi
1551 CF_GCC_ATTRIBUTES
1552 CF_ENABLE_STRING_HACKS
1553
1554 ###     use option --enable-assertions to turn on generation of assertion code
1555 AC_MSG_CHECKING(if you want to enable runtime assertions)
1556 AC_ARG_ENABLE(assertions,
1557         [  --enable-assertions     test: turn on generation of assertion code],
1558         [with_assertions=$enableval],
1559         [with_assertions=no])
1560 AC_MSG_RESULT($with_assertions)
1561 if test -n "$GCC"
1562 then
1563         if test "$with_assertions" = no
1564         then
1565                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1566         else
1567                 CF_ADD_ADAFLAGS(-gnata)
1568         fi
1569 fi
1570
1571 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1572 CF_DISABLE_LEAKS
1573 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1574
1575 ###     use option --enable-expanded to generate certain macros as functions
1576 AC_ARG_ENABLE(expanded,
1577         [  --enable-expanded       test: generate functions for certain macros],
1578         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1579
1580 ###     use option --disable-macros to suppress macros in favor of functions
1581 AC_ARG_ENABLE(macros,
1582         [  --disable-macros        test: use functions rather than macros],
1583         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1584
1585 # Normally we only add trace() to the debug-library.  Allow this to be
1586 # extended to all models of the ncurses library:
1587 cf_all_traces=no
1588 case "$CFLAGS $CPPFLAGS" in
1589 (*-DTRACE*)
1590         cf_all_traces=yes
1591         ;;
1592 esac
1593
1594 AC_MSG_CHECKING(whether to add trace feature to all models)
1595 AC_ARG_WITH(trace,
1596 [  --with-trace            test: add trace() function to all models of ncurses],
1597 [cf_with_trace=$withval],
1598 [cf_with_trace=$cf_all_traces])
1599 AC_MSG_RESULT($cf_with_trace)
1600
1601 if test "x$cf_with_trace" = xyes ; then
1602         LIB_TRACING=all
1603         ADA_TRACE=TRUE
1604         CF_ADD_CFLAGS(-DTRACE)
1605         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1606 else
1607         LIB_TRACING=DEBUG
1608         ADA_TRACE=FALSE
1609 fi
1610
1611 AC_SUBST(ADA_TRACE)
1612
1613 CF_DISABLE_GNAT_PROJECTS
1614
1615 ###     Checks for libraries.
1616 case $cf_cv_system_name in
1617 (*mingw32*|*mingw64*)
1618         CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1619         LIBS=" -lpsapi $LIBS"
1620         ;;
1621 (*)
1622 AC_CHECK_FUNC(gettimeofday,
1623         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1624
1625 AC_CHECK_LIB(bsd, gettimeofday,
1626         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1627         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1628         ;;
1629 esac
1630
1631 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1632 AC_SUBST(MATH_LIB)
1633
1634 ###     Checks for header files.
1635 AC_STDC_HEADERS
1636 AC_HEADER_DIRENT
1637 AC_HEADER_TIME
1638 CF_REGEX
1639
1640 dnl These are some other potentially nonportable headers.
1641 AC_CHECK_HEADERS( \
1642 fcntl.h \
1643 getopt.h \
1644 limits.h \
1645 locale.h \
1646 math.h \
1647 poll.h \
1648 sys/bsdtypes.h \
1649 sys/ioctl.h \
1650 sys/param.h \
1651 sys/poll.h \
1652 sys/select.h \
1653 sys/time.h \
1654 sys/times.h \
1655 ttyent.h \
1656 unistd.h \
1657 wctype.h \
1658 )
1659
1660 CF_GETOPT_HEADER
1661
1662 CF_CHECK_ENVIRON(environ)
1663 CF_CHECK_GETENV
1664 if test "x$cf_cv_consistent_getenv" = xno && \
1665         test "x$cf_with_trace" = xyes
1666 then
1667         AC_MSG_WARN(The NCURSES_TRACE environment variable is not supported with this configuration)
1668 fi
1669
1670 # check for ISC (this may also define _POSIX_SOURCE)
1671 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1672 if test "x$ISC" = xyes ; then
1673         AC_CHECK_LIB(cposix,main)
1674         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1675 fi
1676
1677 CF_SYS_TIME_SELECT
1678
1679 ###     checks for compiler characteristics
1680 AC_LANG_C
1681 AC_C_CONST
1682 CF_C_INLINE(NCURSES_INLINE,1200)
1683 CF_SIG_ATOMIC_T
1684
1685 if test $NCURSES_CHTYPE = auto ; then
1686         CF_TYPEOF_CHTYPE
1687 else
1688         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1689 fi
1690 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1691 AC_SUBST(cf_cv_typeof_chtype)
1692
1693 CF_UNSIGNED_LITERALS
1694 cf_cv_1UL="1"
1695 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1696 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1697 AC_SUBST(cf_cv_1UL)
1698
1699 if test $NCURSES_MMASK_T = auto ; then
1700         cf_cv_typeof_mmask_t=long
1701 else
1702         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1703 fi
1704 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1705 AC_SUBST(cf_cv_typeof_mmask_t)
1706
1707 ###     Checks for external-data
1708 CF_ERRNO
1709 CF_LINK_DATAONLY
1710
1711 ###     Checks for library functions.
1712 AC_CHECK_FUNCS( \
1713 getcwd \
1714 getegid \
1715 geteuid \
1716 getopt \
1717 getttynam \
1718 issetugid \
1719 localeconv \
1720 poll \
1721 putenv \
1722 remove \
1723 select \
1724 setbuf \
1725 setbuffer \
1726 setenv \
1727 setvbuf \
1728 sigaction \
1729 sigvec \
1730 strdup \
1731 strstr \
1732 sysconf \
1733 tcgetpgrp \
1734 times \
1735 tsearch \
1736 vsnprintf \
1737 )
1738
1739 if test "x$ac_cv_func_getopt" = xno && \
1740    test "x$cf_with_progs$cf_with_tests" != xnono; then
1741         AC_MSG_ERROR(getopt is required for building programs)
1742 fi
1743
1744 if test "x$with_safe_sprintf" = xyes
1745 then
1746         if test "x$ac_cv_func_vsnprintf" = xyes
1747         then
1748                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1749         else
1750                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1751         fi
1752 fi
1753
1754 if test "x$with_getcap" = "xyes" ; then
1755         CF_CGETENT
1756 fi
1757
1758 CF_ISASCII
1759 CF_STRUCT_SIGACTION
1760 CF_FUNC_NANOSLEEP
1761 CF_FUNC_TERMIOS
1762 CF_FUNC_VSSCANF
1763 CF_MKSTEMP
1764
1765 # setup for prototype of fallback for vsscanf()
1766 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1767
1768 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1769 if test "x$cross_compiling" = xyes ; then
1770         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1771 else
1772         AC_FUNC_SETVBUF_REVERSED
1773 fi
1774 AC_CHECK_TYPE(intptr_t, long)
1775 AC_CHECK_TYPE(ssize_t, int)
1776 CF_TYPE_SIGACTION
1777 CF_SIZECHANGE
1778 CF_FUNC_MEMMOVE
1779 CF_FUNC_POLL
1780 CF_VA_COPY
1781 AC_FUNC_VFORK
1782 CF_FOPEN_BIN_R
1783
1784 # special check for test/ditto.c
1785 CF_FUNC_OPENPTY
1786 if test "$cf_cv_func_openpty" != no ; then
1787         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1788         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1789         if test "x$cf_cv_lib_util" = xyes ; then
1790                 CF_ADD_LIB(util,TEST_LIBS)
1791         fi
1792 fi
1793 AC_SUBST(TEST_LIBS)
1794 AC_SUBST(TEST_LIBS2)
1795
1796 if test "$with_hashed_db" != no ; then
1797         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1798         CF_HASHED_DB($with_hashed_db)
1799 fi
1800
1801 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1802 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1803         CF_STRIP_G_OPT(CFLAGS)
1804         CF_STRIP_G_OPT(CXXFLAGS)
1805 fi
1806
1807 # Just in case, check if the C compiler has a bool type.
1808 CF_BOOL_DECL(cf_cv_cc_bool_type)
1809
1810 # Check for C++ compiler characteristics (and ensure that it's there!)
1811 if test -n "$CXX" ; then
1812         AC_LANG_CPLUSPLUS
1813         CF_STDCPP_LIBRARY
1814         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1815
1816         case $GXX_VERSION in
1817         (1*|2.[0-6]*)
1818                 cf_cxx_library=yes
1819                 ;;
1820         (*-2.7*|2.7*)
1821                 CF_GPP_LIBRARY
1822                 ;;
1823         (*)
1824                 cf_cxx_library=no
1825                 ;;
1826         esac
1827
1828         AC_CHECK_HEADERS(typeinfo)
1829         CF_CXX_IOSTREAM_NAMESPACE
1830         CF_BOOL_DECL
1831         CF_BOOL_SIZE
1832         CF_ETIP_DEFINES
1833         CF_CPP_PARAM_INIT
1834         CF_CPP_STATIC_CAST
1835         CF_CXX_AR_FLAGS
1836 else
1837         cf_cxx_library=no
1838         cf_cv_builtin_bool=1
1839
1840         # Just because we are not configuring against C++ right now does not
1841         # mean that a user will not want to use C++.  Some distributors disable
1842         # the C++ portion of this configuration as a shortcut (or just to avoid
1843         # compiling the demo in the c++ directory).  So we need a reasonable
1844         # default for the 'bool' type.
1845         #
1846         # Caveat: since the storage of the bool type is not standardized, it
1847         # may change.
1848
1849         if test "$NCURSES_BOOL" != auto ; then
1850                 cf_cv_type_of_bool=$NCURSES_BOOL
1851                 cf_cv_header_stdbool_h=0
1852         else
1853                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1854                         CF_BOOL_SIZE
1855                 else
1856                         AC_MSG_CHECKING(for fallback type of bool)
1857                         case "$host_cpu" in
1858                         (i?86)  cf_cv_type_of_bool=char ;;
1859                         (*)     cf_cv_type_of_bool=int  ;;
1860                         esac
1861                         AC_MSG_RESULT($cf_cv_type_of_bool)
1862                 fi
1863         fi
1864 fi
1865 AC_SUBST(CXXLIBS)
1866
1867 # If the C compiler did not declare bool, and we did not determine that the C++
1868 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1869 # ncurses library use the same type as C++ bool.  Note that this allows one to
1870 # specify the type of bool in a configure-script option and postpone
1871 # integration with the C++ compiler provided that the types are compatible.
1872 USE_CXX_BOOL=1
1873 if test $cf_cv_cc_bool_type = 1
1874 then
1875         # oops: C has a bool.  Unlikely, but C++ could differ.
1876         USE_CXX_BOOL=0
1877 elif test $cf_cv_builtin_bool = 0
1878 then
1879         # C++ has no bool
1880         USE_CXX_BOOL=0
1881 else
1882         # this is the normal case
1883         USE_CXX_BOOL='defined(__cplusplus)'
1884 fi
1885 AC_SUBST(USE_CXX_BOOL)
1886
1887 CF_HELP_MESSAGE(Ada95 Binding Options:)
1888
1889 dnl If the Ada95 source-tree is present, add that to the build unless it will
1890 dnl not work, or was not requested.
1891 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1892
1893 dnl libtool does not know anything about GNAT, though a change made in 1998
1894 dnl provided for it "someday".  Disable the ada subtree if we are using
1895 dnl libtool -TD 20070714
1896         if test "$cf_with_ada" != "no" ; then
1897                 if test "$with_libtool" != "no"; then
1898                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1899                         cf_with_ada=no
1900                 fi
1901         fi
1902
1903 dnl Check for availability of GNU Ada Translator (GNAT).
1904 dnl At the moment we support no other Ada95 compiler.
1905         if test "$cf_with_ada" != "no" ; then
1906                 CF_PROG_GNAT
1907                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1908                         CF_ADD_ADAFLAGS(-gnatpn)
1909                         CF_FIXUP_ADAFLAGS
1910
1911                         CF_GNATPREP_OPT_T
1912
1913                         CF_GNAT_GENERICS
1914                         CF_GNAT_SIGINT
1915                         CF_GNAT_PROJECTS
1916
1917                         CF_WITH_ADA_COMPILER
1918
1919                         cf_ada_package=terminal_interface
1920                         AC_SUBST(cf_ada_package)
1921
1922                         CF_WITH_ADA_INCLUDE
1923                         CF_WITH_ADA_OBJECTS
1924                         CF_WITH_ADA_SHAREDLIB
1925                 fi
1926         fi
1927 else
1928         cf_with_ada=no
1929 fi
1930
1931 # do this "late" to avoid conflict with header-checks
1932 if test "x$with_widec" = xyes ; then
1933         AC_CHECK_SIZEOF(wchar_t)
1934 fi
1935
1936 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1937 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1938 ###
1939 ### ticlib modules may be a separate library, otherwise contained in termlib.
1940 ### termlib modules may be a separate library, otherwise contained in ncurses.
1941 ###
1942 ### The of "+" or " " between the tokens controls the way the script
1943 ### chooses to split module lists into libraries.
1944 ###
1945 ### (see CF_LIB_RULES).
1946 AC_MSG_CHECKING(for library subsets)
1947 LIB_SUBSETS=
1948
1949 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1950         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1951         if test "$with_ticlib" != no ; then
1952                 LIB_SUBSETS="${LIB_SUBSETS} "
1953         else
1954                 LIB_SUBSETS="${LIB_SUBSETS}+"
1955         fi
1956 fi
1957
1958 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1959 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1960
1961 if test "$with_termlib" != no ; then
1962         LIB_SUBSETS="${LIB_SUBSETS} "
1963 else
1964         LIB_SUBSETS="${LIB_SUBSETS}+"
1965 fi
1966
1967 LIB_SUBSETS="${LIB_SUBSETS}base"
1968
1969 # Most term-driver calls are to tinfo, but some like init_pair are to the
1970 # base library (so it resides in base).
1971 if test "$with_term_driver" != no ; then
1972         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1973         case $cf_cv_system_name in
1974         (*mingw32*|*mingw64*)
1975                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1976                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
1977                 ;;
1978         (*)
1979                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1980                 ;;
1981         esac
1982 fi
1983
1984 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1985 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1986
1987 AC_MSG_RESULT($LIB_SUBSETS)
1988
1989 ### Construct the list of include-directories to be generated
1990 CF_INCLUDE_DIRS
1991 CF_ADA_INCLUDE_DIRS
1992
1993 ### Build up pieces for makefile rules
1994 AC_MSG_CHECKING(default library suffix)
1995 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1996 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1997 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1998
1999 AC_MSG_CHECKING(default library-dependency suffix)
2000 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
2001 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
2002 AC_MSG_RESULT($DFT_DEP_SUFFIX)
2003
2004 AC_MSG_CHECKING(default object directory)
2005 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
2006 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
2007 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
2008
2009 if test "x$cf_with_cxx" = xyes ; then
2010 AC_MSG_CHECKING(c++ library-dependency suffix)
2011 if test "$with_libtool" != "no"; then
2012         # libtool thinks it can make c++ shared libraries (perhaps only g++)
2013         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2014 elif test "$with_shared_cxx" != "no"; then
2015         # also for g++ users...
2016         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2017 else
2018         # we normally make a static library because C/C++ library rules differ
2019         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
2020 fi
2021 AC_MSG_RESULT($CXX_LIB_SUFFIX)
2022 AC_SUBST(CXX_LIB_SUFFIX)
2023 fi
2024
2025 # do not want -ldl in build except as needed for -lncurses dependency
2026 if test "x$with_dlsym" = xyes ; then
2027 if test $DFT_LWR_MODEL = shared || \
2028    test $DFT_LWR_MODEL = libtool ; then
2029         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2030 fi
2031 fi
2032 ### Set up low-level terminfo dependencies for makefiles.
2033
2034 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2035 # do not need libdl
2036 TICS_LIST=
2037 if test "x$with_dlsym" = xyes ; then
2038         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2039 fi
2040
2041 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2042 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2043 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2044 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2045 then
2046         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2047 fi
2048 AC_SUBST(USE_ARG_SUFFIX)
2049 AC_SUBST(USE_CFG_SUFFIX)
2050 AC_SUBST(USE_LIB_SUFFIX)
2051
2052 if test "$with_ticlib" != no ; then
2053
2054         if test "x$with_ticlib" != xyes ; then
2055                 TICS_NAME=$with_ticlib
2056                 TICS_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2057                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2058                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2059                 TICS_LIB_SUFFIX="${with_ticlib}"
2060         else
2061                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2062                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2063                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2064                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2065         fi
2066         TICS_LDFLAGS="-L${LIB_DIR}"
2067         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2068 else
2069         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2070         TICS_LDFLAGS="-L${LIB_DIR}"
2071         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2072 fi
2073 AC_SUBST(TICS_ARG_SUFFIX)
2074 AC_SUBST(TICS_DEP_SUFFIX)
2075 AC_SUBST(TICS_LIB_SUFFIX)
2076 AC_SUBST(TICS_LDFLAGS)
2077 AC_SUBST(TICS_LIBS)
2078
2079 if test "$with_termlib" != no ; then
2080
2081         if test "x$with_termlib" != xyes ; then
2082                 TINFO_NAME=$with_termlib
2083                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2084                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2085                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2086                 TINFO_LIB_SUFFIX="${with_termlib}"
2087         else
2088                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2089                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2090                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2091                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2092         fi
2093
2094         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2095         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2096         if test "$DFT_LWR_MODEL" = "libtool"; then
2097                 TEST_ARGS="${TEST_DEPS}"
2098                 TEST_ARG2="${TEST_DEP2}"
2099                 TINFO_LDFLAGS="-L${LIB_DIR}"
2100                 TINFO_LIBS="$TEST_ARGS"
2101                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2102                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2103         else
2104                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2105                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2106                 if test "x$with_term_driver" != xno ; then
2107                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2108                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2109                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2110                 else
2111                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2112                         TINFO_LIBS="$TEST_ARGS"
2113                 fi
2114                 TINFO_LDFLAGS="-L${LIB_DIR}"
2115                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2116         fi
2117 else
2118         # the next lines are needed for linking libtic over libncurses
2119         TINFO_NAME=${LIB_NAME}
2120         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2121         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2122         if test "x$with_tic_depends" = xyes ; then
2123                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2124         else
2125                 TICS_LIST="$SHLIB_LIST"
2126         fi
2127
2128         TINFO_LDFLAGS="-L${LIB_DIR}"
2129         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2130 fi
2131
2132 if test "$DFT_LWR_MODEL" = shared ; then
2133         case $cf_cv_system_name in
2134         (cygwin*|msys*)
2135                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2136                 TINFO_SUFFIX=.dll
2137                 ;;
2138         esac
2139 fi
2140
2141 AC_SUBST(TINFO_ARG_SUFFIX)
2142 AC_SUBST(TINFO_DEP_SUFFIX)
2143 AC_SUBST(TINFO_LIB_SUFFIX)
2144 AC_SUBST(TINFO_LDFLAGS)
2145 AC_SUBST(TINFO_LIBS)
2146
2147 if test "x$with_dlsym" = xyes ; then
2148         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2149 fi
2150
2151 if test "$DFT_LWR_MODEL" = "libtool"; then
2152         OBJEXT=lo
2153 fi
2154
2155 # needed for Ada95
2156 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2157 AC_SUBST(TINFO_LDFLAGS2)
2158
2159 case $DFT_LWR_MODEL in
2160 (normal|debug|profile)
2161         CF_LDFLAGS_STATIC
2162         ;;
2163 esac
2164
2165 AC_MSG_CHECKING(where we will install curses.h)
2166 AC_SUBST(includesubdir)
2167 includesubdir=
2168 if test "$with_overwrite" = no && \
2169  ( test "x$includedir" = 'x${prefix}/include' || \
2170    test "x$includedir" = "x${prefix}/include" )
2171 then
2172         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2173 fi
2174 AC_MSG_RESULT(${includedir}${includesubdir})
2175
2176 ### Resolve a conflict between normal and wide-curses by forcing applications
2177 ### that will need libutf8 to add it to their configure script.
2178 if test "$with_overwrite" != no ; then
2179 if test "$NCURSES_LIBUTF8" = 1 ; then
2180         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2181         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2182 fi
2183 fi
2184 WITH_OVERWRITE=$with_overwrite
2185
2186 AC_SUBST(WITH_OVERWRITE)
2187 AC_SUBST(TICS_LIST)
2188 AC_SUBST(TINFO_LIST)
2189 AC_SUBST(SHLIB_LIST)
2190
2191 # used to separate tack out of the tree
2192 NCURSES_TREE=
2193 AC_SUBST(NCURSES_TREE)
2194
2195 ### predefined stuff for the test programs
2196 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2197
2198 ### Construct the list of subdirectories for which we'll customize makefiles
2199 ### with the appropriate compile-rules.
2200
2201 CF_SRC_MODULES($modules_to_build)
2202
2203 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2204    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2205    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2206 fi
2207
2208 CF_DIRS_TO_MAKE
2209
2210 # symbols that differ when compiling Ada95 by itself.
2211 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2212 AC_SUBST(NCURSES_SHLIB2)
2213
2214 # values to use as strings
2215 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2216
2217 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2218
2219 ### Now that we're done running tests, add the compiler-warnings, if any
2220 CF_ADD_CFLAGS($EXTRA_CFLAGS)
2221
2222 ### Define substitutions for header files to avoid name-pollution
2223 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2224 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2225 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2226 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2227
2228 ################################################################################
2229 test "x$use_database" = xyes && \
2230 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2231
2232 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2233 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2234
2235 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2236 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2237 fi
2238 AC_SUBST(cross_compiling)
2239
2240 if test "x$cf_with_tests" != xno ; then
2241         MAKE_TESTS=
2242 else
2243         MAKE_TESTS="#"
2244 fi
2245 AC_SUBST(MAKE_TESTS)
2246
2247 ADAHTML_DIR=../../doc/html/ada
2248 AC_SUBST(ADAHTML_DIR)
2249
2250 # these could be configurable, but are not currently
2251 PANEL_NAME=panel
2252 MENU_NAME=menu
2253 FORM_NAME=form
2254 CXX_NAME=ncurses++
2255
2256 AC_SUBST(PANEL_NAME)
2257 AC_SUBST(MENU_NAME)
2258 AC_SUBST(FORM_NAME)
2259 AC_SUBST(CXX_NAME)
2260
2261 # workaround for OS/2 (20151017)
2262 case $cf_cv_system_name in
2263 (os2*)
2264         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2265         ;;
2266 (*)
2267         LIBTOOL_OPTS_CXX=
2268         ;;
2269 esac
2270 AC_SUBST(LIBTOOL_OPTS_CXX)
2271
2272 # workaround for g++ versus Solaris (20131116)
2273 case $cf_cv_system_name in
2274 (solaris2*)
2275         case "x$CPPFLAGS" in
2276         (*-D_XOPEN_SOURCE_EXTENDED*)
2277                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2278                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2279                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2280                 ;;
2281         esac
2282         ;;
2283 esac
2284
2285 # Help to automatically enable the extended curses features when using either
2286 # the *-config or the ".pc" files by adding defines.
2287 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2288 PKG_CFLAGS=
2289 for cf_loop1 in $CPPFLAGS_after_XOPEN
2290 do
2291         cf_found=no
2292         for cf_loop2 in $CPPFLAGS_before_XOPEN
2293         do
2294                 if test "x$cf_loop1" = "x$cf_loop2"
2295                 then
2296                         cf_found=yes
2297                         break
2298                 fi
2299         done
2300         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2301 done
2302 AC_MSG_RESULT($PKG_CFLAGS)
2303 AC_SUBST(PKG_CFLAGS)
2304
2305 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2306 case "x$NCURSES_OSPEED" in
2307 (*short*)
2308         cf_compatible=1
2309         ;;
2310 (*)
2311         cf_compatible=0
2312         ;;
2313 esac
2314 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2315
2316 case "x$cf_cv_typeof_chtype" in
2317 (xshort|xint|xlong)
2318         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2319         ;;
2320 esac
2321
2322 case "x$cf_cv_typeof_mmask_t" in
2323 (xshort|xint|xlong)
2324         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2325         ;;
2326 esac
2327
2328 # substitute into misc/Makefile to suppress
2329 # (un)install.data from the
2330 # (un)install rules.
2331 if test "x$cf_with_db_install" = "xno"; then
2332         MISC_INSTALL_DATA=
2333         MISC_UNINSTALL_DATA=
2334 else
2335         MISC_INSTALL_DATA=install.data
2336         MISC_UNINSTALL_DATA=uninstall.data
2337 fi
2338 AC_SUBST(MISC_INSTALL_DATA)
2339 AC_SUBST(MISC_UNINSTALL_DATA)
2340
2341 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2342         MAKE_DATABASE="#"
2343 else
2344         MAKE_DATABASE="$MAKE_TERMINFO"
2345 fi
2346 AC_SUBST(MAKE_DATABASE)
2347
2348 SUB_SCRIPTS=
2349
2350 dnl Override the package used for exported symbols
2351 if test -n "$PACKAGE"
2352 then
2353         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2354         export PACKAGE
2355         echo "package: $PACKAGE"
2356 fi
2357
2358 UNALTERED_SYMS=
2359 cf_filter_syms=no
2360
2361 if test -n "$RESULTING_SYMS"
2362 then
2363         cf_filter_syms=$cf_dft_filter_syms
2364         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2365 fi
2366
2367 if test "x$WILDCARD_SYMS" = xno
2368 then
2369         cf_filter_syms=yes
2370 fi
2371
2372 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2373
2374 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2375 if test $cf_filter_syms = yes
2376 then
2377         RESULTING_SYMS=resulting.map
2378 fi
2379 AC_SUBST(UNALTERED_SYMS)
2380
2381 if test "x$cross_compiling" = xyes ; then
2382         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2383         CHECK_BUILD="#"
2384 else
2385         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2386         CHECK_BUILD=
2387 fi
2388 AC_SUBST(ADAGEN_LDFLAGS)
2389 AC_SUBST(CHECK_BUILD)
2390 AC_SUBST(PRIVATE_LIBS)
2391
2392 AC_DEFINE(HAVE_CURSES_DATA_BOOLNAMES,1,[definition needed for in-tree build of tack])
2393
2394 AC_OUTPUT( \
2395         include/MKterm.h.awk \
2396         include/curses.head:include/curses.h.in \
2397         include/ncurses_dll.h \
2398         include/termcap.h \
2399         include/unctrl.h \
2400         $SUB_SCRIPTS \
2401         $SUB_MAKEFILES \
2402         Makefile,[
2403 if test "x$cf_with_tests" != xno ; then
2404         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2405 fi
2406 CF_LIB_RULES($SRC_SUBDIRS)
2407
2408 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2409 if test -z "$USE_OLD_MAKERULES" ; then
2410         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
2411 fi
2412 fi
2413 ],[
2414 ### Special initialization commands, used to pass information from the
2415 ### configuration-run into config.status
2416
2417 AWK="$AWK"
2418 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2419 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2420 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2421 ECHO_LD="$ECHO_LD"
2422 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2423 LDCONFIG="$LDCONFIG"
2424 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2425 LIB_NAME="$LIB_NAME"
2426 LIB_PREFIX="$LIB_PREFIX"
2427 LIB_SUBSETS="$LIB_SUBSETS"
2428 LIB_SUFFIX="$LIB_SUFFIX"
2429 LIB_TRACING="$LIB_TRACING"
2430 LN_S="$LN_S"
2431 MAKE_TERMINFO="$MAKE_TERMINFO"
2432 NCURSES_MAJOR="$NCURSES_MAJOR"
2433 NCURSES_MINOR="$NCURSES_MINOR"
2434 NCURSES_OSPEED="$NCURSES_OSPEED"
2435 NCURSES_PATCH="$NCURSES_PATCH"
2436 SRC_SUBDIRS="$SRC_SUBDIRS"
2437 TERMINFO="$TERMINFO"
2438 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2439 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2440 TICS_NAME="$TICS_NAME"
2441 TICS_SUFFIX="$TICS_SUFFIX"
2442 TIC_PATH="$TIC_PATH"
2443 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2444 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2445 TINFO_NAME="$TINFO_NAME"
2446 TINFO_SUFFIX="$TINFO_SUFFIX"
2447 UNALTERED_SYMS="$UNALTERED_SYMS"
2448 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2449 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2450 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2451 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2452 WILDCARD_SYMS="$WILDCARD_SYMS"
2453 WITH_CURSES_H="$with_curses_h"
2454 WITH_ECHO="${enable_echo:=yes}"
2455 WITH_OVERWRITE="$with_overwrite"
2456 cf_LIST_MODELS="$cf_list_models"
2457 cf_cv_abi_version="$cf_cv_abi_version"
2458 cf_cv_do_relink="$cf_cv_do_relink"
2459 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2460 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2461 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2462 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2463 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2464 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2465 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2466 cf_cv_rel_version="$cf_cv_rel_version"
2467 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2468 cf_cv_shared_soname='$cf_cv_shared_soname'
2469 cf_cv_shlib_version="$cf_cv_shlib_version"
2470 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2471 cf_cv_system_name="$cf_cv_system_name"
2472 cf_cv_term_driver="$with_term_driver"
2473 cf_with_ada="$cf_with_ada"
2474 cf_with_cxx_binding="$cf_with_cxx_binding"
2475 cf_with_db_install="$cf_with_db_install"
2476 cf_with_manpages="$cf_with_manpages"
2477 cf_with_tests="$cf_with_tests"
2478 host="$host"
2479 target="$target"
2480 with_shared_cxx="$with_shared_cxx"
2481
2482 ],cat)dnl
2483 ${MAKE:-make} preinstall