configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2009,2010 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.509 2010/09/25 22:32:53 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.509 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to install manpages)
 126 AC_ARG_WITH(manpages,
 127         [  --without-manpages      suppress install of manpages],
 128         [cf_with_manpages=$withval],
 129         [cf_with_manpages=yes])
 130 AC_MSG_RESULT($cf_with_manpages)
 131
 132 AC_MSG_CHECKING(if you want to build programs such as tic)
 133 AC_ARG_WITH(progs,
 134         [  --without-progs         suppress build with programs (e.g., tic)],
 135         [cf_with_progs=$withval],
 136         [cf_with_progs=yes])
 137 AC_MSG_RESULT($cf_with_progs)
 138
 139 AC_MSG_CHECKING(if you want to build test-programs)
 140 AC_ARG_WITH(tests,
 141         [  --without-tests         suppress build with test-programs],
 142         [cf_with_tests=$withval],
 143         [cf_with_tests=yes])
 144 AC_MSG_RESULT($cf_with_tests)
 145
 146 AC_MSG_CHECKING(if you wish to install curses.h)
 147 AC_ARG_WITH(curses-h,
 148         [  --without-curses-h      install curses.h as ncurses.h only],
 149         [with_curses_h=$withval],
 150         [with_curses_h=yes])
 151 AC_MSG_RESULT($with_curses_h)
 152
 153 modules_to_build="ncurses"
 154 if test "X$cf_with_progs" != Xno ; then
 155 modules_to_build="$modules_to_build progs tack"
 156 fi
 157 modules_to_build="$modules_to_build panel menu form"
 158
 159 AC_ARG_PROGRAM
 160
 161 CF_PROG_AWK
 162 CF_PROG_EGREP
 163 CF_PROG_INSTALL
 164 CF_PROG_LINT
 165 CF_PROG_LN_S
 166
 167 AC_SYS_LONG_FILE_NAMES
 168
 169 # if we find pkg-config, check if we should install the ".pc" files.
 170 CF_PKG_CONFIG
 171
 172 if test "$PKG_CONFIG" != no ; then
 173         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
 174
 175         # Leave this as something that can be overridden in the environment.
 176         if test -z "$PKG_CONFIG_LIBDIR" ; then
 177                 PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`/lib/pkgconfig
 178         fi
 179         PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG_LIBDIR" | sed -e 's/^://' -e 's/:.*//'`
 180         if test -n "$PKG_CONFIG_LIBDIR" && test -d "$PKG_CONFIG_LIBDIR" ; then
 181                 AC_ARG_ENABLE(pc-files,
 182                         [  --enable-pc-files       generate and install .pc files for pkg-config],
 183                         [enable_pc_files=$enableval],
 184                         [enable_pc_files=no])
 185                 AC_MSG_RESULT($enable_pc_files)
 186         else
 187                 AC_MSG_RESULT(no)
 188                 AC_MSG_WARN(did not find library $PKG_CONFIG_LIBDIR)
 189                 enable_pc_files=no
 190         fi
 191 fi
 192 AC_SUBST(PKG_CONFIG_LIBDIR)
 193
 194 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 195 AC_ARG_ENABLE(mixed-case,
 196         [  --enable-mixed-case     tic should assume mixed-case filenames],
 197         [enable_mixedcase=$enableval],
 198         [enable_mixedcase=auto])
 199 AC_MSG_RESULT($enable_mixedcase)
 200 if test "$enable_mixedcase" = "auto" ; then
 201     CF_MIXEDCASE_FILENAMES
 202 else
 203     cf_cv_mixedcase=$enable_mixedcase
 204     if test "$enable_mixedcase" = "yes" ; then
 205         AC_DEFINE(MIXEDCASE_FILENAMES)
 206     fi
 207 fi
 208
 209 # do this after mixed-case option (tags/TAGS is not as important as tic).
 210 AC_PROG_MAKE_SET
 211 CF_MAKE_TAGS
 212 CF_MAKEFLAGS
 213
 214 dnl These are standard among *NIX systems, but not when cross-compiling
 215 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 216 AC_CHECK_TOOL(LD, ld, ld)
 217 AC_CHECK_TOOL(AR, ar, ar)
 218 CF_AR_FLAGS
 219
 220 dnl Special option for use by system-builders: the install-prefix is used to
 221 dnl adjust the location into which the actual install is done, so that an
 222 dnl archive can be built without modifying the host system's configuration.
 223 AC_MSG_CHECKING(if you have specified an install-prefix)
 224 AC_ARG_WITH(install-prefix,
 225         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 226         [case "$withval" in #(vi
 227         yes|no) #(vi
 228                 ;;
 229         *)      DESTDIR="$withval"
 230                 ;;
 231         esac])
 232 AC_MSG_RESULT($DESTDIR)
 233 AC_SUBST(DESTDIR)
 234
 235 ###############################################################################
 236 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 237 # If we're cross-compiling, allow the user to override the tools and their
 238 # options.  The configure script is oriented toward identifying the host
 239 # compiler, etc., but we need a build compiler to generate parts of the source.
 240 CF_BUILD_CC
 241
 242 ###############################################################################
 243 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 244
 245 ### Options to allow the user to specify the set of libraries which are used.
 246 ### Use "--without-normal --with-shared" to allow the default model to be
 247 ### shared, for example.
 248 cf_list_models=""
 249 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 250
 251 CF_WITH_LIBTOOL
 252 if test "$with_libtool" != "no" ; then
 253
 254 cf_list_models="$cf_list_models libtool"
 255
 256 else
 257
 258 AC_MSG_CHECKING(if you want to build shared libraries)
 259 AC_ARG_WITH(shared,
 260         [  --with-shared           generate shared-libraries],
 261         [with_shared=$withval],
 262         [with_shared=no])
 263 AC_MSG_RESULT($with_shared)
 264 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 265
 266 AC_MSG_CHECKING(if you want to build static libraries)
 267 AC_ARG_WITH(normal,
 268         [  --with-normal           generate normal-libraries (default)],
 269         [with_normal=$withval],
 270         [with_normal=yes])
 271 AC_MSG_RESULT($with_normal)
 272 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 273
 274 AC_MSG_CHECKING(if you want to build debug libraries)
 275 AC_ARG_WITH(debug,
 276         [  --with-debug            generate debug-libraries (default)],
 277         [with_debug=$withval],
 278         [with_debug=yes])
 279 AC_MSG_RESULT($with_debug)
 280 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 281
 282 AC_MSG_CHECKING(if you want to build profiling libraries)
 283 AC_ARG_WITH(profile,
 284         [  --with-profile          generate profile-libraries],
 285         [with_profile=$withval],
 286         [with_profile=no])
 287 AC_MSG_RESULT($with_profile)
 288 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 289
 290 fi
 291
 292 ###############################################################################
 293
 294 AC_MSG_CHECKING(for specified models)
 295 test -z "$cf_list_models" && cf_list_models=normal
 296 dnl If we use libtool to generate libraries, then it must be the only
 297 dnl specified model.
 298 test "$with_libtool" != "no" && cf_list_models=libtool
 299 AC_MSG_RESULT($cf_list_models)
 300
 301 ### Use the first model as the default, and save its suffix for use in building
 302 ### up test-applications.
 303 AC_MSG_CHECKING(for default model)
 304 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 305 AC_MSG_RESULT($DFT_LWR_MODEL)
 306
 307 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 308
 309 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 310 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 311
 312 TICS_NAME=tic
 313 AC_SUBST(TICS_NAME)
 314
 315 TINFO_NAME=tinfo
 316 AC_SUBST(TINFO_NAME)
 317
 318 LIB_NAME=ncurses
 319 AC_SUBST(LIB_NAME)
 320
 321 LIB_DIR=../lib
 322 LIB_2ND=../../lib
 323
 324 CF_LIB_PREFIX(cf_prefix)
 325 LIB_PREFIX=$cf_prefix
 326 AC_SUBST(LIB_PREFIX)
 327
 328 LIB_SUFFIX=
 329 AC_SUBST(LIB_SUFFIX)
 330
 331 ###############################################################################
 332
 333 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 334 AC_ARG_WITH(termlib,
 335         [  --with-termlib          generate separate terminfo library],
 336         [with_termlib=$withval],
 337         [with_termlib=no])
 338 AC_MSG_RESULT($with_termlib)
 339
 340 AC_MSG_CHECKING(if you want to build a separate tic library)
 341 AC_ARG_WITH(ticlib,
 342         [  --with-ticlib           generate separate tic library],
 343         [with_ticlib=$withval],
 344         [with_ticlib=no])
 345 AC_MSG_RESULT($with_ticlib)
 346
 347 ### Checks for special libraries, must be done up-front.
 348 SHLIB_LIST=""
 349 CF_WITH_GPM
 350 if test "$with_gpm" != no ; then
 351         AC_MSG_CHECKING(if you want to load GPM dynamically)
 352         AC_ARG_WITH(dlsym,
 353                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 354                 [with_dlsym=$withval],
 355                 [with_dlsym=yes])
 356         AC_MSG_RESULT($with_dlsym)
 357         if test "$with_dlsym" = yes ; then
 358                 CF_FUNC_DLSYM
 359                 if test "$with_gpm" != yes ; then
 360                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 361                         cf_cv_gpm_soname="$with_gpm"
 362                 else
 363                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 364                 fi
 365                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 366                 SHLIB_LIST="-ldl $SHLIB_LIST"
 367         else
 368                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 369                 CF_ADD_LIB(gpm,TEST_LIBS)
 370         fi
 371         AC_DEFINE(HAVE_LIBGPM)
 372         CF_CHECK_GPM_WGETCH
 373 fi
 374
 375 CF_WITH_SYSMOUSE
 376
 377 dnl Not all ports of gcc support the -g option
 378
 379 if test X"$CC_G_OPT" = X"" ; then
 380         CC_G_OPT='-g'
 381         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 382 fi
 383 AC_SUBST(CC_G_OPT)
 384
 385 if test X"$CXX_G_OPT" = X"" ; then
 386         CXX_G_OPT='-g'
 387         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 388 fi
 389 AC_SUBST(CXX_G_OPT)
 390
 391 AC_MSG_CHECKING(for default loader flags)
 392 case $DFT_LWR_MODEL in
 393 libtool) LD_MODEL=''   ;;
 394 normal)  LD_MODEL=''   ;;
 395 debug)   LD_MODEL=$CC_G_OPT ;;
 396 profile) LD_MODEL='-pg';;
 397 shared)  LD_MODEL=''   ;;
 398 esac
 399 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 400 AC_MSG_RESULT($LD_MODEL)
 401
 402 case $DFT_LWR_MODEL in
 403 shared)
 404 CF_ENABLE_RPATH
 405 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 406 AC_ARG_ENABLE(relink,
 407 [  --disable-relink        relink shared libraries during install],
 408 [cf_cv_do_relink=$enableval],
 409 [cf_cv_do_relink=yes])
 410 AC_MSG_RESULT($cf_cv_do_relink)
 411         ;;
 412 esac
 413
 414 CF_SHARED_OPTS
 415 if test "$CC_SHARED_OPTS" = "unknown"; then
 416         for model in $cf_list_models; do
 417                 if test "$model" = "shared"; then
 418                         AC_ERROR(Shared libraries are not supported in this version)
 419                 fi
 420         done
 421 fi
 422
 423 ### If we're building with rpath, try to link non-standard libs that way too.
 424 if test "$DFT_LWR_MODEL" = "shared"; then
 425         CF_DISABLE_RPATH_HACK
 426 fi
 427
 428 ###############################################################################
 429 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 430
 431 ###     use option --disable-overwrite to leave out the link to -lcurses
 432 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 433 AC_ARG_ENABLE(overwrite,
 434         [  --disable-overwrite     leave out the link to -lcurses],
 435         [with_overwrite=$enableval],
 436         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 437 AC_MSG_RESULT($with_overwrite)
 438
 439 AC_MSG_CHECKING(if external terminfo-database is used)
 440 AC_ARG_ENABLE(database,
 441         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 442         [use_database=$enableval],
 443         [use_database=yes])
 444 AC_MSG_RESULT($use_database)
 445
 446 case $host_os in #(vi
 447 os2*) #(vi
 448         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 449         ;;
 450 *) #(vi
 451         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 452         ;;
 453 esac
 454 AC_SUBST(TERMINFO_SRC)
 455
 456 CF_PATHSEP
 457 if test "$use_database" != no ; then
 458         AC_DEFINE(USE_DATABASE)
 459
 460         AC_MSG_CHECKING(which terminfo source-file will be installed)
 461         AC_ARG_WITH(database,
 462                 [  --with-database=XXX     specify terminfo source to install],
 463                 [TERMINFO_SRC=$withval])
 464         AC_MSG_RESULT($TERMINFO_SRC)
 465
 466         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 467         AC_ARG_WITH(hashed-db,
 468                 [  --with-hashed-db        specify hashed-database library],,
 469                 [with_hashed_db=no])
 470         AC_MSG_RESULT($with_hashed_db)
 471 else
 472         with_hashed_db=no
 473 fi
 474
 475 AC_MSG_CHECKING(for list of fallback descriptions)
 476 AC_ARG_WITH(fallbacks,
 477         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 478         [with_fallback=$withval],
 479         [with_fallback=])
 480 AC_MSG_RESULT($with_fallback)
 481 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 482 AC_SUBST(FALLBACK_LIST)
 483
 484 AC_MSG_CHECKING(if you want modern xterm or antique)
 485 AC_ARG_WITH(xterm-new,
 486         [  --without-xterm-new     specify if xterm terminfo should be old version],
 487         [with_xterm_new=$withval],
 488         [with_xterm_new=yes])
 489 case $with_xterm_new in
 490 no)     with_xterm_new=xterm-old;;
 491 *)      with_xterm_new=xterm-new;;
 492 esac
 493 AC_MSG_RESULT($with_xterm_new)
 494 WHICH_XTERM=$with_xterm_new
 495 AC_SUBST(WHICH_XTERM)
 496
 497 MAKE_TERMINFO=
 498 if test "$use_database" = no ; then
 499         TERMINFO="${datadir}/terminfo"
 500         MAKE_TERMINFO="#"
 501 else
 502
 503 AC_MSG_CHECKING(for list of terminfo directories)
 504 CF_WITH_PATHLIST(terminfo-dirs,
 505         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 506         TERMINFO_DIRS,
 507         DATADIR/terminfo,
 508         ${datadir}/terminfo)
 509 AC_MSG_RESULT($TERMINFO_DIRS)
 510 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 511
 512 AC_MSG_CHECKING(for default terminfo directory)
 513 CF_WITH_PATH(default-terminfo-dir,
 514         [  --with-default-terminfo-dir=DIR default terminfo directory],
 515         TERMINFO,
 516         DATADIR/terminfo,
 517         ${datadir}/terminfo)
 518 AC_MSG_RESULT($TERMINFO)
 519 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 520
 521 fi
 522
 523 AC_SUBST(TERMINFO)
 524 AC_SUBST(MAKE_TERMINFO)
 525
 526 ###     use option --disable-big-core to make tic run on small machines
 527 ###     We need 4Mb, check if we can allocate 50% more than that.
 528 AC_MSG_CHECKING(if big-core option selected)
 529 AC_ARG_ENABLE(big-core,
 530         [  --disable-big-core      assume machine has little memory],
 531         [with_big_core=$enableval],
 532         [AC_TRY_RUN([
 533 #include <stdlib.h>
 534 #include <string.h>
 535 int main() {
 536         unsigned long n = 6000000L;
 537         char *s = malloc(n);
 538         if (s != 0)
 539                 s[0] = s[n-1] = 0;
 540         ${cf_cv_main_return:-return}(s == 0);
 541 }],
 542         [with_big_core=yes],
 543         [with_big_core=no],
 544         [with_big_core=no])])
 545 AC_MSG_RESULT($with_big_core)
 546 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 547
 548 ### ISO C only guarantees 512-char strings, we have tables which load faster
 549 ### when constructed using "big" strings.  More than the C compiler, the awk
 550 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 551 AC_MSG_CHECKING(if big-strings option selected)
 552 AC_ARG_ENABLE(big-strings,
 553         [  --disable-big-strings   assume compiler has only standard-size strings],
 554         [with_big_strings=$enableval],
 555         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 556 AC_MSG_RESULT($with_big_strings)
 557
 558 USE_BIG_STRINGS=0
 559 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
 560 AC_SUBST(USE_BIG_STRINGS)
 561
 562 ###     use option --enable-termcap to compile in the termcap fallback support
 563 AC_MSG_CHECKING(if you want termcap-fallback support)
 564 AC_ARG_ENABLE(termcap,
 565         [  --enable-termcap        compile in termcap fallback support],
 566         [with_termcap=$enableval],
 567         [with_termcap=no])
 568 AC_MSG_RESULT($with_termcap)
 569
 570 if test "$with_termcap" != "yes" ; then
 571         if test "$use_database" = no ; then
 572                 if test -z "$with_fallback" ; then
 573                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 574                 fi
 575         fi
 576         AC_DEFINE(PURE_TERMINFO)
 577 else
 578
 579 if test "$with_ticlib" != no ; then
 580         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 581 fi
 582
 583 AC_DEFINE(USE_TERMCAP)
 584 AC_MSG_CHECKING(for list of termcap files)
 585 CF_WITH_PATHLIST(termpath,
 586         [  --with-termpath=XXX     specify list of termcap files],
 587         TERMPATH,
 588         /etc/termcap:/usr/share/misc/termcap)
 589 AC_MSG_RESULT($TERMPATH)
 590 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 591
 592 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 593 AC_MSG_CHECKING(if fast termcap-loader is needed)
 594 AC_ARG_ENABLE(getcap,
 595         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 596         [with_getcap=$enableval],
 597         [with_getcap=no])
 598 AC_MSG_RESULT($with_getcap)
 599 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 600
 601 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 602 AC_ARG_ENABLE(getcap-cache,
 603         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 604         [with_getcap_cache=$enableval],
 605         [with_getcap_cache=no])
 606 AC_MSG_RESULT($with_getcap_cache)
 607 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 608
 609 fi
 610
 611 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 612 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 613 AC_ARG_ENABLE(home-terminfo,
 614         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 615         [with_home_terminfo=$enableval],
 616         [with_home_terminfo=yes])
 617 AC_MSG_RESULT($with_home_terminfo)
 618 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 619
 620 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 621 AC_ARG_ENABLE(root-environ,
 622         [  --disable-root-environ  restrict environment when running as root],
 623         [with_root_environ=$enableval],
 624         [with_root_environ=yes])
 625 AC_MSG_RESULT($with_root_environ)
 626 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 627
 628 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 629 ###   to reduce storage requirements for the terminfo database.
 630 CF_LINK_FUNCS
 631
 632 with_links=no
 633 with_symlinks=no
 634
 635 # soft links (symbolic links) are useful for some systems where hard links do
 636 # not work, or to make it simpler to copy terminfo trees around.
 637 if test "$ac_cv_func_symlink" = yes ; then
 638     AC_MSG_CHECKING(if tic should use symbolic links)
 639     AC_ARG_ENABLE(symlinks,
 640         [  --enable-symlinks       make tic use symbolic links not hard links],
 641         [with_symlinks=$enableval],
 642         [with_symlinks=no])
 643     AC_MSG_RESULT($with_symlinks)
 644 fi
 645
 646 # If we have hard links and did not choose to use soft links instead, there is
 647 # no reason to make this choice optional - use the hard links.
 648 if test "$with_symlinks" = no ; then
 649     AC_MSG_CHECKING(if tic should use hard links)
 650     if test "$ac_cv_func_link" = yes ; then
 651         with_links=yes
 652     else
 653         with_links=no
 654     fi
 655     AC_MSG_RESULT($with_links)
 656 fi
 657
 658 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 659 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 660
 661 ###   use option --enable-broken-linker to force on use of broken-linker support
 662 AC_MSG_CHECKING(if you want broken-linker support code)
 663 AC_ARG_ENABLE(broken_linker,
 664         [  --enable-broken_linker  compile with broken-linker support code],
 665         [with_broken_linker=$enableval],
 666         [with_broken_linker=${BROKEN_LINKER-no}])
 667 AC_MSG_RESULT($with_broken_linker)
 668
 669 BROKEN_LINKER=0
 670 if test "$with_broken_linker" = yes ; then
 671         AC_DEFINE(BROKEN_LINKER)
 672         BROKEN_LINKER=1
 673 elif test "$DFT_LWR_MODEL" = shared ; then
 674         case $cf_cv_system_name in #(vi
 675         cygwin*)
 676                 AC_DEFINE(BROKEN_LINKER)
 677                 BROKEN_LINKER=1
 678                 CF_VERBOSE(cygwin linker is broken anyway)
 679                 ;;
 680         esac
 681 fi
 682 AC_SUBST(BROKEN_LINKER)
 683
 684 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 685 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 686 AC_ARG_ENABLE(bsdpad,
 687         [  --enable-bsdpad         recognize BSD-style prefix padding],
 688         [with_bsdpad=$enableval],
 689         [with_bsdpad=no])
 690 AC_MSG_RESULT($with_bsdpad)
 691 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 692
 693 ###   use option --enable-widec to turn on use of wide-character support
 694 NCURSES_CH_T=chtype
 695 NCURSES_LIBUTF8=0
 696
 697 NEED_WCHAR_H=0
 698 NCURSES_MBSTATE_T=0
 699 NCURSES_WCHAR_T=0
 700 NCURSES_WINT_T=0
 701
 702 # Check to define _XOPEN_SOURCE "automatically"
 703 CF_XOPEN_SOURCE(500)
 704
 705 # Work around breakage on OS X
 706 CF_SIGWINCH
 707
 708 # Checks for CODESET support.
 709 AM_LANGINFO_CODESET
 710
 711 # use these variables to work around a defect in gcc's fixincludes.
 712 NCURSES_OK_WCHAR_T=
 713 NCURSES_OK_WINT_T=
 714
 715 AC_MSG_CHECKING(if you want wide-character code)
 716 AC_ARG_ENABLE(widec,
 717         [  --enable-widec          compile with wide-char/UTF-8 code],
 718         [with_widec=$enableval],
 719         [with_widec=no])
 720 AC_MSG_RESULT($with_widec)
 721 if test "$with_widec" = yes ; then
 722         LIB_SUFFIX="w${LIB_SUFFIX}"
 723         AC_DEFINE(USE_WIDEC_SUPPORT)
 724
 725         case "$CFLAGS $CPPFLAGS" in #(vi
 726         *-D_XOPEN_SOURCE=500) #(vi
 727                 ;;
 728         *)
 729                 CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 730                 ;;
 731         esac
 732
 733         # with_overwrite=no
 734         NCURSES_CH_T=cchar_t
 735         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 736         if test "$ac_cv_func_putwc" != yes ; then
 737                 CF_UTF8_LIB
 738                 if test "$cf_cv_utf8_lib" != no ; then
 739                         NCURSES_LIBUTF8=1
 740                 fi
 741         fi
 742         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 743         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 744         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 745
 746         if test "$NCURSES_MBSTATE_T" != 0; then
 747                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 748         fi
 749 fi
 750 AC_SUBST(NCURSES_CH_T)
 751 AC_SUBST(NCURSES_LIBUTF8)
 752
 753 AC_SUBST(NEED_WCHAR_H)
 754 AC_SUBST(NCURSES_MBSTATE_T)
 755 AC_SUBST(NCURSES_WCHAR_T)
 756 AC_SUBST(NCURSES_WINT_T)
 757
 758 AC_SUBST(NCURSES_OK_WCHAR_T)
 759 AC_SUBST(NCURSES_OK_WINT_T)
 760
 761 ###   use option --disable-lp64 to allow long chtype
 762 case $cf_cv_abi_version in
 763 [[345]]*)
 764         default_with_lp64=no
 765         ;;
 766 *)
 767         default_with_lp64=yes
 768         ;;
 769 esac
 770
 771 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 772 AC_ARG_ENABLE(lp64,
 773         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 774         [with_lp64=$enableval],
 775         [with_lp64=$default_with_lp64])
 776 AC_MSG_RESULT($with_lp64)
 777
 778 if test "$with_lp64" = yes ; then
 779         cf_cv_enable_lp64=1
 780 else
 781         cf_cv_enable_lp64=0
 782 fi
 783 AC_SUBST(cf_cv_enable_lp64)
 784
 785 CF_LARGEFILE
 786
 787 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 788 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 789 AC_ARG_ENABLE(tparm-varargs,
 790         [  --disable-tparm-varargs compile tparm() without varargs interface],
 791         [with_tparm_varargs=$enableval],
 792         [with_tparm_varargs=yes])
 793 AC_MSG_RESULT($with_tparm_varargs)
 794 NCURSES_TPARM_VARARGS=0
 795 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 796 AC_SUBST(NCURSES_TPARM_VARARGS)
 797
 798 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 799 if test "$with_ticlib" != no ; then
 800 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 801 AC_ARG_ENABLE(tic-depends,
 802         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 803         [with_tic_depends=$enableval],
 804         [with_tic_depends=yes])
 805 AC_MSG_RESULT($with_tic_depends)
 806 else
 807         with_tic_depends=no
 808 fi
 809
 810 ###   use option --with-bool to override bool's type
 811 AC_MSG_CHECKING(for type of bool)
 812 AC_ARG_WITH(bool,
 813         [  --with-bool=TYPE        override fallback type of bool variable],
 814         [NCURSES_BOOL="$withval"],
 815         [NCURSES_BOOL=auto])
 816 AC_MSG_RESULT($NCURSES_BOOL)
 817 AC_SUBST(NCURSES_BOOL)
 818
 819 AC_MSG_CHECKING(for alternate terminal capabilities file)
 820 AC_ARG_WITH(caps,
 821         [  --with-caps=alt         compile with alternate Caps file],
 822         [TERMINFO_CAPS=Caps.$withval],
 823         [TERMINFO_CAPS=Caps])
 824 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 825 AC_MSG_RESULT($TERMINFO_CAPS)
 826 AC_SUBST(TERMINFO_CAPS)
 827
 828 ###   use option --with-chtype to override chtype's type
 829 AC_MSG_CHECKING(for type of chtype)
 830 AC_ARG_WITH(chtype,
 831         [  --with-chtype=TYPE      override type of chtype],
 832         [NCURSES_CHTYPE="$withval"],
 833         [NCURSES_CHTYPE=auto])
 834 AC_MSG_RESULT($NCURSES_CHTYPE)
 835
 836 ###   use option --with-ospeed to override ospeed's type
 837 AC_MSG_CHECKING(for type of ospeed)
 838 AC_ARG_WITH(ospeed,
 839         [  --with-ospeed=TYPE      override type of ospeed variable],
 840         [NCURSES_OSPEED="$withval"],
 841         [NCURSES_OSPEED=short])
 842 AC_MSG_RESULT($NCURSES_OSPEED)
 843 AC_SUBST(NCURSES_OSPEED)
 844
 845 ###   use option --with-mmask-t to override mmask_t's type
 846 AC_MSG_CHECKING(for type of mmask_t)
 847 AC_ARG_WITH(mmask-t,
 848         [  --with-mmask-t=TYPE     override type of mmask_t],
 849         [NCURSES_MMASK_T="$withval"],
 850         [NCURSES_MMASK_T=auto])
 851 AC_MSG_RESULT($NCURSES_MMASK_T)
 852
 853 ###   use option --with-ccharw-max to override CCHARW_MAX size
 854 AC_MSG_CHECKING(for size CCHARW_MAX)
 855 AC_ARG_WITH(ccharw-max,
 856         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
 857         [NCURSES_CCHARW_MAX="$withval"],
 858         [NCURSES_CCHARW_MAX=5])
 859 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
 860 AC_SUBST(NCURSES_CCHARW_MAX)
 861
 862 ### Enable compiling-in rcs id's
 863 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 864 AC_ARG_WITH(rcs-ids,
 865         [  --with-rcs-ids          compile-in RCS identifiers],
 866         [with_rcs_ids=$withval],
 867         [with_rcs_ids=no])
 868 AC_MSG_RESULT($with_rcs_ids)
 869 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 870
 871 ###############################################################################
 872 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
 873
 874 ###############################################################################
 875 CF_HELP_MESSAGE(Extensions:)
 876
 877 ### Note that some functions (such as const) are normally disabled anyway.
 878 AC_MSG_CHECKING(if you want to build with function extensions)
 879 AC_ARG_ENABLE(ext-funcs,
 880         [  --disable-ext-funcs     disable function-extensions],
 881         [with_ext_funcs=$enableval],
 882         [with_ext_funcs=yes])
 883 AC_MSG_RESULT($with_ext_funcs)
 884 if test "$with_ext_funcs" = yes ; then
 885         NCURSES_EXT_FUNCS=1
 886         AC_DEFINE(HAVE_CURSES_VERSION)
 887         AC_DEFINE(HAVE_HAS_KEY)
 888         AC_DEFINE(HAVE_RESIZETERM)
 889         AC_DEFINE(HAVE_RESIZE_TERM)
 890         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 891         AC_DEFINE(HAVE_WRESIZE)
 892         AC_DEFINE(NCURSES_EXT_FUNCS)
 893         GENERATED_EXT_FUNCS=generated
 894 else
 895         NCURSES_EXT_FUNCS=0
 896         GENERATED_EXT_FUNCS=
 897 fi
 898 AC_SUBST(NCURSES_EXT_FUNCS)
 899 AC_SUBST(GENERATED_EXT_FUNCS)
 900
 901 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
 902 AC_ARG_ENABLE(sp-funcs,
 903         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
 904         [with_sp_funcs=$enableval],
 905         [with_sp_funcs=no])
 906 AC_MSG_RESULT($with_sp_funcs)
 907 if test "$with_sp_funcs" = yes ; then
 908         NCURSES_SP_FUNCS=1
 909         AC_DEFINE(NCURSES_SP_FUNCS)
 910         GENERATED_SP_FUNCS=generated
 911 else
 912         NCURSES_SP_FUNCS=0
 913         GENERATED_SP_FUNCS=
 914 fi
 915 AC_SUBST(NCURSES_SP_FUNCS)
 916 AC_SUBST(GENERATED_SP_FUNCS)
 917
 918 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
 919 AC_ARG_ENABLE(term-driver,
 920         [  --enable-term-driver    enable experimental terminal-driver],
 921         [with_term_driver=$enableval],
 922         [with_term_driver=no])
 923 AC_MSG_RESULT($with_term_driver)
 924 if test "$with_term_driver" = yes ; then
 925         AC_DEFINE(USE_TERM_DRIVER)
 926         if test "$with_sp_funcs" != yes ; then
 927                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
 928         fi
 929 fi
 930
 931 ###   use option --enable-const to turn on use of const beyond that in XSI.
 932 AC_MSG_CHECKING(for extended use of const keyword)
 933 AC_ARG_ENABLE(const,
 934         [  --enable-const          compile with extra/non-standard const],
 935         [with_ext_const=$enableval],
 936         [with_ext_const=no])
 937 AC_MSG_RESULT($with_ext_const)
 938 NCURSES_CONST='/*nothing*/'
 939 if test "$with_ext_const" = yes ; then
 940         NCURSES_CONST=const
 941 fi
 942 AC_SUBST(NCURSES_CONST)
 943
 944 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 945 AC_MSG_CHECKING(if you want to use extended colors)
 946 AC_ARG_ENABLE(ext-colors,
 947         [  --enable-ext-colors     compile for 256-color support],
 948         [with_ext_colors=$enableval],
 949         [with_ext_colors=no])
 950 AC_MSG_RESULT($with_ext_colors)
 951 NCURSES_EXT_COLORS=0
 952 if test "$with_ext_colors" = yes ; then
 953         if test "$with_widec" != yes ; then
 954                 AC_MSG_ERROR(This option applies only to wide-character library)
 955         else
 956                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 957                 CF_NCURSES_ABI_6
 958         fi
 959         NCURSES_EXT_COLORS=1
 960         AC_DEFINE(NCURSES_EXT_COLORS)
 961 fi
 962 AC_SUBST(NCURSES_EXT_COLORS)
 963
 964 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 965 AC_MSG_CHECKING(if you want to use extended mouse encoding)
 966 AC_ARG_ENABLE(ext-mouse,
 967         [  --enable-ext-mouse      compile for extended mouse-encoding],
 968         [with_ext_mouse=$enableval],
 969         [with_ext_mouse=no])
 970 AC_MSG_RESULT($with_ext_mouse)
 971 NCURSES_MOUSE_VERSION=1
 972 if test "$with_ext_mouse" = yes ; then
 973         NCURSES_MOUSE_VERSION=2
 974         CF_NCURSES_ABI_6
 975 fi
 976 AC_SUBST(NCURSES_MOUSE_VERSION)
 977
 978 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 979 AC_ARG_ENABLE(no-padding,
 980         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 981         [with_no_padding=$enableval],
 982         [with_no_padding=$with_ext_funcs])
 983 AC_MSG_RESULT($with_no_padding)
 984 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 985
 986 AC_CHECK_SIZEOF([signed char], 0)
 987 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 988         NCURSES_SBOOL="signed char"
 989 else
 990         NCURSES_SBOOL="char"
 991 fi
 992 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 993 AC_ARG_ENABLE(signed-char,
 994         [  --enable-signed-char    compile using signed Boolean's in term.h],
 995         [with_signed_char=$enableval],
 996         [with_signed_char=no])
 997 AC_MSG_RESULT($with_signed_char)
 998 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
 999 AC_SUBST(NCURSES_SBOOL)
1000
1001 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1002 AC_MSG_CHECKING(if you want SIGWINCH handler)
1003 AC_ARG_ENABLE(sigwinch,
1004         [  --enable-sigwinch       compile with SIGWINCH handler],
1005         [with_sigwinch=$enableval],
1006         [with_sigwinch=$with_ext_funcs])
1007 AC_MSG_RESULT($with_sigwinch)
1008 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
1009
1010 ###   use option --enable-tcap-names to allow user to define new capabilities
1011 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1012 AC_ARG_ENABLE(tcap-names,
1013         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1014         [with_tcap_names=$enableval],
1015         [with_tcap_names=$with_ext_funcs])
1016 AC_MSG_RESULT($with_tcap_names)
1017 NCURSES_XNAMES=0
1018 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
1019 AC_SUBST(NCURSES_XNAMES)
1020
1021 ###############################################################################
1022 # These options are relatively safe to experiment with.
1023 CF_HELP_MESSAGE(Development Code:)
1024 AC_MSG_CHECKING(if you want all development code)
1025 AC_ARG_WITH(develop,
1026         [  --without-develop       disable development options],
1027         [with_develop=$withval],
1028         [with_develop=no])
1029 AC_MSG_RESULT($with_develop)
1030
1031 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1032 AC_MSG_CHECKING(if you want hard-tabs code)
1033 AC_ARG_ENABLE(hard-tabs,
1034         [  --enable-hard-tabs      compile with hard-tabs code],,
1035         [enable_hard_tabs=$with_develop])
1036 AC_MSG_RESULT($enable_hard_tabs)
1037 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
1038
1039 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1040 AC_MSG_CHECKING(if you want limited support for xmc)
1041 AC_ARG_ENABLE(xmc-glitch,
1042         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1043         [enable_xmc_glitch=$with_develop])
1044 AC_MSG_RESULT($enable_xmc_glitch)
1045 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
1046
1047 ###############################################################################
1048 # These are just experimental, probably should not be in a package:
1049 CF_HELP_MESSAGE(Experimental Code:)
1050
1051 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1052 AC_ARG_ENABLE(assumed-color,
1053         [  --disable-assumed-color do not assume anything about default-colors],
1054         [with_assumed_color=$enableval],
1055         [with_assumed_color=yes])
1056 AC_MSG_RESULT($with_assumed_color)
1057 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
1058
1059 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1060 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1061 AC_ARG_ENABLE(hashmap,
1062         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1063         [with_hashmap=$enableval],
1064         [with_hashmap=yes])
1065 AC_MSG_RESULT($with_hashmap)
1066 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1067
1068 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1069 AC_MSG_CHECKING(if you want colorfgbg code)
1070 AC_ARG_ENABLE(colorfgbg,
1071         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1072         [with_colorfgbg=$enableval],
1073         [with_colorfgbg=no])
1074 AC_MSG_RESULT($with_colorfgbg)
1075 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1076
1077 ###   use option --enable-interop to turn on use of bindings used for interop
1078 AC_MSG_CHECKING(if you want interop bindings)
1079 AC_ARG_ENABLE(interop,
1080         [  --enable-interop        compile-in experimental interop bindings],
1081         [with_exp_interop=$enableval],
1082         [with_exp_interop=no])
1083 AC_MSG_RESULT($with_exp_interop)
1084
1085 NCURSES_INTEROP_FUNCS=0
1086 test "$with_exp_interop" = yes && NCURSES_INTEROP_FUNCS=1
1087 AC_SUBST(NCURSES_INTEROP_FUNCS)
1088
1089 # This is still experimental (20080329), but should ultimately be moved to
1090 # the script-block --with-normal, etc.
1091 CF_WITH_PTHREAD
1092
1093 if test "x$with_pthread" != xno; then
1094         AC_CHECK_FUNC(pthread_kill,[
1095                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1096                 AC_ARG_ENABLE(pthreads-eintr,
1097                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1098                         [use_pthreads_eintr=$enableval],
1099                         [use_pthreads_eintr=no])
1100                 AC_MSG_RESULT($use_pthreads_eintr)
1101                 if test $use_pthreads_eintr = yes ; then
1102                         AC_DEFINE(USE_PTHREADS_EINTR)
1103                 fi])
1104
1105         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1106         AC_ARG_ENABLE(weak-symbols,
1107                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1108                 [use_weak_symbols=$enableval],
1109                 [use_weak_symbols=no])
1110         AC_MSG_RESULT($use_weak_symbols)
1111         if test "$use_weak_symbols" = yes ; then
1112                 CF_WEAK_SYMBOLS
1113         else
1114                 cf_cv_weak_symbols=no
1115         fi
1116
1117         if test $cf_cv_weak_symbols = yes ; then
1118                 AC_DEFINE(USE_WEAK_SYMBOLS)
1119         fi
1120 fi
1121
1122 PTHREAD=
1123 if test "$with_pthread" = "yes" ; then
1124     AC_DEFINE(USE_PTHREADS)
1125     enable_reentrant=yes
1126     if test $cf_cv_weak_symbols = yes ; then
1127         PTHREAD=-lpthread
1128     fi
1129 fi
1130 AC_SUBST(PTHREAD)
1131
1132 # Reentrant code has to be opaque; there's little advantage to making ncurses
1133 # opaque outside of that, so there is no --enable-opaque option.  We can use
1134 # this option without --with-pthreads, but this will be always set for
1135 # pthreads.
1136 AC_MSG_CHECKING(if you want experimental reentrant code)
1137 AC_ARG_ENABLE(reentrant,
1138         [  --enable-reentrant      compile with experimental reentrant code],
1139         [with_reentrant=$enableval],
1140         [with_reentrant=no])
1141 AC_MSG_RESULT($with_reentrant)
1142 if test "$with_reentrant" = yes ; then
1143         cf_cv_enable_reentrant=1
1144         cf_cv_enable_opaque="NCURSES_INTERNALS"
1145         NCURSES_OPAQUE=1
1146         NCURSES_SIZE_T=int
1147         if test $cf_cv_weak_symbols = yes ; then
1148                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1149                 CF_ADD_LIB(pthread,TEST_LIBS)
1150                 CF_ADD_LIB(pthread,TEST_LIBS2)
1151         fi
1152         LIB_SUFFIX="t${LIB_SUFFIX}"
1153         AC_DEFINE(USE_REENTRANT)
1154         CF_NCURSES_ABI_6
1155 else
1156         cf_cv_enable_reentrant=0
1157         cf_cv_enable_opaque="NCURSES_OPAQUE"
1158         NCURSES_OPAQUE=0
1159         NCURSES_SIZE_T=short
1160 fi
1161 AC_SUBST(cf_cv_enable_reentrant)
1162 AC_SUBST(cf_cv_enable_opaque)
1163 AC_SUBST(NCURSES_OPAQUE)
1164 AC_SUBST(NCURSES_SIZE_T)
1165
1166 ### Allow using a different wrap-prefix
1167 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1168         AC_MSG_CHECKING(for prefix used to wrap public variables)
1169         AC_ARG_WITH(wrap-prefix,
1170                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1171                 [NCURSES_WRAP_PREFIX=$withval],
1172                 [NCURSES_WRAP_PREFIX=_nc_])
1173         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1174 else
1175         NCURSES_WRAP_PREFIX=_nc_
1176 fi
1177 AC_SUBST(NCURSES_WRAP_PREFIX)
1178 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX")
1179
1180 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1181 AC_ARG_ENABLE(safe-sprintf,
1182         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1183         [with_safe_sprintf=$enableval],
1184         [with_safe_sprintf=no])
1185 AC_MSG_RESULT($with_safe_sprintf)
1186 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1187
1188 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1189 # when hashmap is used scroll hints are useless
1190 if test "$with_hashmap" = no ; then
1191 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1192 AC_ARG_ENABLE(scroll-hints,
1193         [  --disable-scroll-hints  compile without scroll-hints code],
1194         [with_scroll_hints=$enableval],
1195         [with_scroll_hints=yes])
1196 AC_MSG_RESULT($with_scroll_hints)
1197 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1198 fi
1199
1200 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1201 AC_ARG_ENABLE(wgetch-events,
1202         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1203         [with_wgetch_events=$enableval],
1204         [with_wgetch_events=no])
1205 AC_MSG_RESULT($with_wgetch_events)
1206 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1207
1208 ###############################################################################
1209 CF_HELP_MESSAGE(Testing/development Options:)
1210
1211 ###     use option --disable-echo to suppress full display compiling commands
1212 AC_MSG_CHECKING(if you want to display full commands during build)
1213 AC_ARG_ENABLE(echo,
1214         [  --enable-echo           build: display "compiling" commands (default)],
1215         [with_echo=$enableval],
1216         [with_echo=yes])
1217 if test "$with_echo" = yes; then
1218         ECHO_LINK=
1219 else
1220         ECHO_LINK='@ echo linking $@ ... ;'
1221         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1222         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1223 fi
1224 AC_MSG_RESULT($with_echo)
1225 AC_SUBST(ECHO_LINK)
1226
1227 ###     use option --enable-warnings to turn on all gcc warnings
1228 AC_MSG_CHECKING(if you want to see compiler warnings)
1229 AC_ARG_ENABLE(warnings,
1230         [  --enable-warnings       build: turn on GCC compiler warnings],
1231         [with_warnings=$enableval])
1232 AC_MSG_RESULT($with_warnings)
1233
1234 if test "x$with_warnings" = "xyes"; then
1235         CF_ADD_ADAFLAGS(-gnatg)
1236         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1237         if test "$cf_with_cxx" = yes ; then
1238                 CF_GXX_WARNINGS(Wno-unused)
1239         fi
1240 fi
1241 CF_GCC_ATTRIBUTES
1242
1243 ###     use option --enable-assertions to turn on generation of assertion code
1244 AC_MSG_CHECKING(if you want to enable runtime assertions)
1245 AC_ARG_ENABLE(assertions,
1246         [  --enable-assertions     test: turn on generation of assertion code],
1247         [with_assertions=$enableval],
1248         [with_assertions=no])
1249 AC_MSG_RESULT($with_assertions)
1250 if test -n "$GCC"
1251 then
1252         if test "$with_assertions" = no
1253         then
1254                 AC_DEFINE(NDEBUG)
1255                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1256         else
1257                 CF_ADD_ADAFLAGS(-gnata)
1258         fi
1259 fi
1260
1261 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1262 CF_DISABLE_LEAKS
1263 AC_DEFINE(HAVE_NC_ALLOC_H)
1264
1265 ###     use option --enable-expanded to generate certain macros as functions
1266 AC_ARG_ENABLE(expanded,
1267         [  --enable-expanded       test: generate functions for certain macros],
1268         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1269
1270 ###     use option --disable-macros to suppress macros in favor of functions
1271 AC_ARG_ENABLE(macros,
1272         [  --disable-macros        test: use functions rather than macros],
1273         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1274
1275 # Normally we only add trace() to the debug-library.  Allow this to be
1276 # extended to all models of the ncurses library:
1277 cf_all_traces=no
1278 case "$CFLAGS $CPPFLAGS" in
1279 *-DTRACE*)
1280         cf_all_traces=yes
1281         ;;
1282 esac
1283
1284 AC_MSG_CHECKING(whether to add trace feature to all models)
1285 AC_ARG_WITH(trace,
1286 [  --with-trace            test: add trace() function to all models of ncurses],
1287 [cf_with_trace=$withval],
1288 [cf_with_trace=$cf_all_traces])
1289 AC_MSG_RESULT($cf_with_trace)
1290
1291 if test "$cf_with_trace" = yes ; then
1292         LIB_TRACING=all
1293         ADA_TRACE=TRUE
1294         CF_ADD_CFLAGS(-DTRACE)
1295 else
1296         LIB_TRACING=DEBUG
1297         ADA_TRACE=FALSE
1298 fi
1299
1300 AC_SUBST(ADA_TRACE)
1301
1302 ###     Checks for libraries.
1303 case $cf_cv_system_name in #(vi
1304 *mingw32*) #(vi
1305         ;;
1306 *)
1307 AC_CHECK_FUNC(gettimeofday,
1308         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1309
1310 AC_CHECK_LIB(bsd, gettimeofday,
1311         AC_DEFINE(HAVE_GETTIMEOFDAY)
1312         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1313         ;;
1314 esac
1315
1316 CF_MATH_LIB(MATH_LIB,sin(x))
1317 AC_SUBST(MATH_LIB)
1318
1319 ###     Checks for header files.
1320 AC_STDC_HEADERS
1321 AC_HEADER_DIRENT
1322 AC_HEADER_TIME
1323 CF_REGEX
1324
1325 dnl These are some other potentially nonportable headers.
1326 AC_CHECK_HEADERS( \
1327 fcntl.h \
1328 getopt.h \
1329 limits.h \
1330 locale.h \
1331 poll.h \
1332 sys/bsdtypes.h \
1333 sys/ioctl.h \
1334 sys/param.h \
1335 sys/poll.h \
1336 sys/select.h \
1337 sys/time.h \
1338 sys/times.h \
1339 ttyent.h \
1340 unistd.h \
1341 wctype.h \
1342 )
1343
1344 # check for ISC (this may also define _POSIX_SOURCE)
1345 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1346 if test "$ISC" = yes ; then
1347         AC_CHECK_LIB(cposix,main)
1348         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1349 fi
1350
1351 CF_SYS_TIME_SELECT
1352
1353 ###     checks for compiler characteristics
1354 AC_LANG_C
1355 AC_C_CONST
1356 CF_C_INLINE(NCURSES_INLINE,1200)
1357 CF_SIG_ATOMIC_T
1358
1359 if test $NCURSES_CHTYPE = auto ; then
1360         CF_TYPEOF_CHTYPE
1361 else
1362         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1363 fi
1364 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1365 AC_SUBST(cf_cv_typeof_chtype)
1366
1367 CF_UNSIGNED_LITERALS
1368 cf_cv_1UL="1"
1369 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1370 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1371 AC_SUBST(cf_cv_1UL)
1372
1373 if test $NCURSES_MMASK_T = auto ; then
1374         cf_cv_typeof_mmask_t=long
1375 else
1376         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1377 fi
1378 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1379 AC_SUBST(cf_cv_typeof_mmask_t)
1380
1381 ###     Checks for external-data
1382 CF_ERRNO
1383 CF_LINK_DATAONLY
1384
1385 ###     Checks for library functions.
1386 AC_CHECK_FUNCS( \
1387 getcwd \
1388 getegid \
1389 geteuid \
1390 getttynam \
1391 issetugid \
1392 poll \
1393 remove \
1394 select \
1395 setbuf \
1396 setbuffer \
1397 setvbuf \
1398 sigaction \
1399 sigvec \
1400 strdup \
1401 strstr \
1402 tcgetpgrp \
1403 times \
1404 vsnprintf \
1405 )
1406 if test "$with_getcap" = "yes" ; then
1407         CF_CGETENT
1408 fi
1409
1410 CF_ISASCII
1411 CF_STRUCT_SIGACTION
1412 CF_FUNC_NANOSLEEP
1413 CF_FUNC_TERMIOS
1414 CF_FUNC_VSSCANF
1415 CF_MKSTEMP
1416
1417 # setup for prototype of fallback for vsscanf()
1418 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1419
1420 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1421 if test "$cross_compiling" = yes ; then
1422         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1423 else
1424         AC_FUNC_SETVBUF_REVERSED
1425 fi
1426 AC_TYPE_SIGNAL
1427 CF_TYPE_SIGACTION
1428 CF_SIZECHANGE
1429 CF_FUNC_MEMMOVE
1430 CF_FUNC_POLL
1431 CF_VA_COPY
1432 AC_FUNC_VFORK
1433
1434 # special check for test/ditto.c
1435 CF_FUNC_OPENPTY
1436 if test "$cf_cv_func_openpty" != no ; then
1437     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1438     AC_DEFINE(USE_XTERM_PTY)
1439     if test "$cf_cv_lib_util" = yes ; then
1440         CF_ADD_LIB(util,TEST_LIBS)
1441     fi
1442 fi
1443 AC_SUBST(TEST_LIBS)
1444 AC_SUBST(TEST_LIBS2)
1445
1446 if test "$with_hashed_db" != no ; then
1447         AC_DEFINE(USE_HASHED_DB)
1448         CF_HASHED_DB($with_hashed_db)
1449 fi
1450
1451 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1452 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1453         CF_STRIP_G_OPT(CFLAGS)
1454         CF_STRIP_G_OPT(CXXFLAGS)
1455 fi
1456
1457 # Just in case, check if the C compiler has a bool type.
1458 CF_BOOL_DECL(cf_cv_cc_bool_type)
1459
1460 # Check for C++ compiler characteristics (and ensure that it's there!)
1461 if test -n "$CXX" ; then
1462         AC_LANG_CPLUSPLUS
1463         CF_STDCPP_LIBRARY
1464         CF_PROG_CC_C_O(CXX)
1465
1466         case $GXX_VERSION in
1467         1*|2.[0-6]*)
1468                 cf_cxx_library=yes
1469                 ;;
1470         *-2.7*|2.7*)
1471                 CF_GPP_LIBRARY
1472                 ;;
1473         *)
1474                 cf_cxx_library=no
1475                 ;;
1476         esac
1477
1478         AC_CHECK_HEADERS(iostream typeinfo)
1479
1480     if test x"$ac_cv_header_iostream" = xyes ; then
1481         AC_MSG_CHECKING(if iostream uses std-namespace)
1482         AC_TRY_COMPILE([
1483 #include <iostream>
1484 using std::endl;
1485 using std::cerr;],[
1486 cerr << "testing" << endl;
1487 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1488         AC_MSG_RESULT($cf_iostream_namespace)
1489         if test "$cf_iostream_namespace" = yes ; then
1490             AC_DEFINE(IOSTREAM_NAMESPACE)
1491         fi
1492     fi
1493
1494         CF_BOOL_DECL
1495         CF_BOOL_SIZE
1496         CF_ETIP_DEFINES
1497         CF_CPP_PARAM_INIT
1498         CF_CPP_STATIC_CAST
1499
1500         CXX_AR='$(AR)'
1501         CXX_ARFLAGS='$(ARFLAGS)'
1502         case $cf_cv_system_name in #(vi
1503         irix*) #(vi
1504             if test "$GXX" != yes ; then
1505                 CXX_AR='$(CXX)'
1506                 CXX_ARFLAGS='-ar -o'
1507             fi
1508             ;;
1509         sco3.2v5*) #(vi
1510             CXXLDFLAGS="-u main"
1511             ;;
1512         solaris2*)
1513             if test "$GXX" != yes ; then
1514                 CXX_AR='$(CXX)'
1515                 CXX_ARFLAGS='-xar -o'
1516             fi
1517             ;;
1518         esac
1519         AC_SUBST(CXXLDFLAGS)
1520         AC_SUBST(CXX_AR)
1521         AC_SUBST(CXX_ARFLAGS)
1522 else
1523         cf_cxx_library=no
1524         cf_cv_builtin_bool=1
1525
1526         # Just because we are not configuring against C++ right now does not
1527         # mean that a user will not want to use C++.  Some distributors disable
1528         # the C++ portion of this configuration as a shortcut (or just to avoid
1529         # compiling the demo in the c++ directory).  So we need a reasonable
1530         # default for the 'bool' type.
1531         #
1532         # Caveat: since the storage of the bool type is not standardized, it
1533         # may change.
1534
1535         if test "$NCURSES_BOOL" != auto ; then
1536                 cf_cv_type_of_bool=$NCURSES_BOOL
1537                 cf_cv_header_stdbool_h=0
1538         else
1539                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1540                         CF_BOOL_SIZE
1541                 else
1542                         AC_MSG_CHECKING(for fallback type of bool)
1543                         case "$host_cpu" in #(vi
1544                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1545                         *)      cf_cv_type_of_bool=int  ;;
1546                         esac
1547                         AC_MSG_RESULT($cf_cv_type_of_bool)
1548                 fi
1549         fi
1550 fi
1551 AC_SUBST(CXXLIBS)
1552
1553 # If the C compiler did not declare bool, and we did not determine that the C++
1554 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1555 # ncurses library use the same type as C++ bool.  Note that this allows one to
1556 # specify the type of bool in a configure-script option and postpone
1557 # integration with the C++ compiler provided that the types are compatible.
1558 USE_CXX_BOOL=1
1559 if test $cf_cv_cc_bool_type = 1
1560 then
1561         # oops: C has a bool.  Unlikely, but C++ could differ.
1562         USE_CXX_BOOL=0
1563 elif test $cf_cv_builtin_bool = 0
1564 then
1565         # C++ has no bool
1566         USE_CXX_BOOL=0
1567 else
1568         # this is the normal case
1569         USE_CXX_BOOL='defined(__cplusplus)'
1570 fi
1571 AC_SUBST(USE_CXX_BOOL)
1572
1573 CF_HELP_MESSAGE(Ada95 Binding Options:)
1574
1575 dnl If the Ada95 source-tree is present, add that to the build unless it will
1576 dnl not work, or was not requested.
1577 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1578
1579 dnl libtool does not know anything about GNAT, though a change made in 1998
1580 dnl provided for it "someday".  Disable the ada subtree if we are using
1581 dnl libtool -TD 20070714
1582         if test "$cf_with_ada" != "no" ; then
1583                 if test "$with_libtool" != "no"; then
1584                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1585                         cf_with_ada=no
1586                 fi
1587         fi
1588
1589 dnl Check for availability of GNU Ada Translator (GNAT).
1590 dnl At the moment we support no other Ada95 compiler.
1591         if test "$cf_with_ada" != "no" ; then
1592                 CF_PROG_GNAT
1593                 if test "$cf_cv_prog_gnat_correct" = yes; then
1594                         CF_ADD_ADAFLAGS(-O3 -gnatpn)
1595
1596                         CF_GNAT_PRAGMA_UNREF
1597
1598                         CF_WITH_ADA_COMPILER
1599
1600                         cf_ada_package=terminal_interface
1601                         AC_SUBST(cf_ada_package)
1602
1603                         CF_WITH_ADA_INCLUDE
1604                         CF_WITH_ADA_OBJECTS
1605                         CF_WITH_ADA_SHAREDLIB
1606                 fi
1607         fi
1608 else
1609         cf_with_ada=no
1610 fi
1611
1612 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1613 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1614 ###
1615 ### ticlib modules may be a separate library, otherwise contained in termlib.
1616 ### termlib modules may be a separate library, otherwise contained in ncurses.
1617 ###
1618 ### The of "+" or " " between the tokens controls the way the script
1619 ### chooses to split module lists into libraries.
1620 ###
1621 ### (see CF_LIB_RULES).
1622 AC_MSG_CHECKING(for library subsets)
1623 LIB_SUBSETS=
1624
1625 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1626         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1627         if test "$with_ticlib" != no ; then
1628                 LIB_SUBSETS="${LIB_SUBSETS} "
1629         else
1630                 LIB_SUBSETS="${LIB_SUBSETS}+"
1631         fi
1632 fi
1633
1634 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1635 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1636
1637 if test "$with_termlib" != no ; then
1638         LIB_SUBSETS="${LIB_SUBSETS} "
1639 else
1640         LIB_SUBSETS="${LIB_SUBSETS}+"
1641 fi
1642
1643 LIB_SUBSETS="${LIB_SUBSETS}base"
1644
1645 # Most term-driver calls are to tinfo, but some like init_pair are to the
1646 # base library (so it resides in base).
1647 if test "$with_term_driver" != no ; then
1648         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1649         case $cf_cv_system_name in #(vi
1650         *mingw32*) #(vi
1651                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1652                 ;;
1653         *) #(vi
1654                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1655                 ;;
1656         esac
1657 fi
1658
1659 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1660 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1661
1662 AC_MSG_RESULT($LIB_SUBSETS)
1663
1664 ### Construct the list of include-directories to be generated
1665 CF_INCLUDE_DIRS
1666 CF_ADA_INCLUDE_DIRS
1667
1668 ### Build up pieces for makefile rules
1669 AC_MSG_CHECKING(default library suffix)
1670 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1671 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1672 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1673
1674 AC_MSG_CHECKING(default library-dependency suffix)
1675 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1676 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1677 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1678
1679 AC_MSG_CHECKING(default object directory)
1680 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1681 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1682 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1683
1684 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1685 if test "$cf_with_cxx" = yes ; then
1686 AC_MSG_CHECKING(c++ library-dependency suffix)
1687 if test "$with_libtool" != "no"; then
1688         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1689 else
1690         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1691 fi
1692 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1693 AC_SUBST(CXX_LIB_SUFFIX)
1694 fi
1695
1696 # do not want -ldl in build except as needed for -lncurses dependency
1697 if test "$with_dlsym" = yes ; then
1698 if test $DFT_LWR_MODEL = shared || \
1699    test $DFT_LWR_MODEL = libtool ; then
1700         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1701 fi
1702 fi
1703 ### Set up low-level terminfo dependencies for makefiles.
1704
1705 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1706 # do not need libdl
1707 TICS_LIST=
1708 if test "$with_dlsym" = yes ; then
1709         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1710 fi
1711
1712 if test "$with_ticlib" != no ; then
1713
1714         if test "$with_ticlib" != yes ; then
1715                 TICS_NAME=$with_ticlib
1716                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1717                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1718                 TICS_LIB_SUFFIX="${with_ticlib}"
1719         else
1720                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1721                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1722                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1723         fi
1724         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1725 else
1726         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1727 fi
1728 AC_SUBST(TICS_ARG_SUFFIX)
1729 AC_SUBST(TICS_DEP_SUFFIX)
1730 AC_SUBST(TICS_LIB_SUFFIX)
1731 AC_SUBST(TICS_ARGS)
1732
1733 if test "$with_termlib" != no ; then
1734
1735         if test "$with_termlib" != yes ; then
1736                 TINFO_NAME=$with_termlib
1737                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1738                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1739                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1740                 TINFO_LIB_SUFFIX="${with_termlib}"
1741         else
1742                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1743                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1744                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1745                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1746         fi
1747
1748         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1749         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1750         if test "$DFT_LWR_MODEL" = "libtool"; then
1751                 TEST_ARGS="${TEST_DEPS}"
1752                 TEST_ARG2="${TEST_DEP2}"
1753                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1754                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1755                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1756         else
1757                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1758                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1759                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1760                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1761                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1762         fi
1763 else
1764         # the next lines are needed for linking libtic over libncurses
1765         TINFO_NAME=${LIB_NAME}
1766         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1767         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1768         if test "$with_tic_depends" = yes ; then
1769                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1770         else
1771                 TICS_LIST="$SHLIB_LIST"
1772         fi
1773
1774         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1775 fi
1776
1777 if test "$DFT_LWR_MODEL" = shared ; then
1778         case $cf_cv_system_name in #(vi
1779         cygwin*)
1780                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1781                 TINFO_SUFFIX=.dll
1782                 ;;
1783         esac
1784 fi
1785
1786 AC_SUBST(TINFO_ARG_SUFFIX)
1787 AC_SUBST(TINFO_DEP_SUFFIX)
1788 AC_SUBST(TINFO_LIB_SUFFIX)
1789 AC_SUBST(TINFO_ARGS)
1790
1791 if test "$with_dlsym" = yes ; then
1792         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1793 fi
1794
1795 if test "$DFT_LWR_MODEL" = "libtool"; then
1796     OBJEXT=lo
1797 fi
1798
1799 # needed for Ada95
1800 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1801 AC_SUBST(TINFO_ARGS2)
1802
1803 case $DFT_LWR_MODEL in
1804 normal|debug|profile)
1805         CF_LDFLAGS_STATIC
1806         ;;
1807 esac
1808
1809 AC_MSG_CHECKING(where we will install curses.h)
1810 test "$with_overwrite" = no && \
1811 test "x$includedir" = 'x${prefix}/include' && \
1812         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1813 AC_MSG_RESULT($includedir)
1814
1815 ### Resolve a conflict between normal and wide-curses by forcing applications
1816 ### that will need libutf8 to add it to their configure script.
1817 if test "$with_overwrite" != no ; then
1818 if test "$NCURSES_LIBUTF8" = 1 ; then
1819         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1820         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1821 fi
1822 fi
1823 WITH_OVERWRITE=$with_overwrite
1824
1825 AC_SUBST(WITH_OVERWRITE)
1826 AC_SUBST(TICS_LIST)
1827 AC_SUBST(TINFO_LIST)
1828 AC_SUBST(SHLIB_LIST)
1829
1830 # used to separate tack out of the tree
1831 NCURSES_TREE=
1832 AC_SUBST(NCURSES_TREE)
1833
1834 ### predefined stuff for the test programs
1835 AC_DEFINE(HAVE_SLK_COLOR)
1836
1837 ### Construct the list of subdirectories for which we'll customize makefiles
1838 ### with the appropriate compile-rules.
1839
1840 CF_SRC_MODULES($modules_to_build)
1841
1842 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1843    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1844    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1845 fi
1846
1847 CF_DIRS_TO_MAKE
1848
1849 # symbols that differ when compiling Ada95 by itself.
1850 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1851 AC_SUBST(NCURSES_SHLIB2)
1852
1853 # values to use as strings
1854 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR')
1855
1856 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1857
1858 ### Now that we're done running tests, add the compiler-warnings, if any
1859 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1860
1861 ### Define substitutions for header files to avoid name-pollution
1862 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1863 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1864 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1865
1866 ################################################################################
1867 test "$use_database" = yes && \
1868 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1869
1870 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1871 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1872
1873 if test x"$enable_pc_files" = xyes ; then \
1874 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1875 MAKE_PC_FILES=
1876 else
1877 MAKE_PC_FILES="#"
1878 fi
1879 AC_SUBST(MAKE_PC_FILES)
1880 AC_SUBST(cross_compiling)
1881
1882 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
1883 if test -n "$FALLBACK_LIST"
1884 then
1885         if test "$TIC_PATH" = unknown
1886         then
1887                 AC_MSG_ERROR(no tic program found for fallbacks)
1888         fi
1889 fi
1890 AC_SUBST(TIC_PATH)
1891
1892 if test "x$cf_with_tests" != xno ; then
1893         MAKE_TESTS=
1894 else
1895         MAKE_TESTS="#"
1896 fi
1897 AC_SUBST(MAKE_TESTS)
1898
1899 SUB_SCRIPTS=
1900 case $cf_cv_system_name in #(vi
1901 *mingw32*) #(vi
1902         SUB_SCRIPTS="mk-dlls.sh"
1903         ;;
1904 esac
1905
1906 AC_OUTPUT( \
1907         include/MKterm.h.awk \
1908         include/curses.head:include/curses.h.in \
1909         include/ncurses_dll.h \
1910         include/termcap.h \
1911         include/unctrl.h \
1912         $SUB_SCRIPTS \
1913         $SUB_MAKEFILES \
1914         Makefile,[
1915 if test "x$cf_with_tests" != xno ; then
1916         CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1917 fi
1918 CF_LIB_RULES($SRC_SUBDIRS)
1919
1920 if test "x$cf_with_ada" != xno ; then
1921 if test -z "$USE_OLD_MAKERULES" ; then
1922         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
1923 fi
1924 fi
1925 ],[
1926 ### Special initialization commands, used to pass information from the
1927 ### configuration-run into config.status
1928
1929 AWK="$AWK"
1930 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1931 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1932 ECHO_LINK="$ECHO_LINK"
1933 LDCONFIG="$LDCONFIG"
1934 LIBTOOL_VERSION="$LIBTOOL_VERSION"
1935 LIB_NAME="$LIB_NAME"
1936 LIB_SUBSETS="$LIB_SUBSETS"
1937 LIB_SUFFIX="$LIB_SUFFIX"
1938 LIB_TRACING="$LIB_TRACING"
1939 LN_S="$LN_S"
1940 MAKE_TERMINFO="$MAKE_TERMINFO"
1941 NCURSES_MAJOR="$NCURSES_MAJOR"
1942 NCURSES_MINOR="$NCURSES_MINOR"
1943 NCURSES_OSPEED="$NCURSES_OSPEED"
1944 NCURSES_PATCH="$NCURSES_PATCH"
1945 SRC_SUBDIRS="$SRC_SUBDIRS"
1946 TERMINFO="$TERMINFO"
1947 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1948 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1949 TICS_NAME="$TICS_NAME"
1950 TIC_PATH="$TIC_PATH"
1951 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1952 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1953 TINFO_NAME="$TINFO_NAME"
1954 TINFO_SUFFIX="$TINFO_SUFFIX"
1955 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
1956 WITH_CURSES_H="$with_curses_h"
1957 WITH_ECHO="$with_echo"
1958 WITH_OVERWRITE="$with_overwrite"
1959 cf_LIST_MODELS="$cf_list_models"
1960 cf_cv_abi_version="$cf_cv_abi_version"
1961 cf_cv_do_relink="$cf_cv_do_relink"
1962 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1963 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1964 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1965 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1966 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1967 cf_cv_rel_version="$cf_cv_rel_version"
1968 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1969 cf_cv_shared_soname='$cf_cv_shared_soname'
1970 cf_cv_shlib_version="$cf_cv_shlib_version"
1971 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1972 cf_cv_system_name="$cf_cv_system_name"
1973 cf_with_ada="$cf_with_ada"
1974 cf_with_cxx_binding="$cf_with_cxx_binding"
1975 cf_with_manpages="$cf_with_manpages"
1976 cf_with_tests="$cf_with_tests"
1977 host="$host"
1978 target="$target"
1979
1980 ],cat)dnl
1981 ${MAKE-make} preinstall