configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2010,2011 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.525 2011/09/10 19:53:50 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.525 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to install manpages)
 126 AC_ARG_WITH(manpages,
 127         [  --without-manpages      suppress install of manpages],
 128         [cf_with_manpages=$withval],
 129         [cf_with_manpages=yes])
 130 AC_MSG_RESULT($cf_with_manpages)
 131
 132 AC_MSG_CHECKING(if you want to build programs such as tic)
 133 AC_ARG_WITH(progs,
 134         [  --without-progs         suppress build with programs (e.g., tic)],
 135         [cf_with_progs=$withval],
 136         [cf_with_progs=yes])
 137 AC_MSG_RESULT($cf_with_progs)
 138
 139 AC_MSG_CHECKING(if you want to build test-programs)
 140 AC_ARG_WITH(tests,
 141         [  --without-tests         suppress build with test-programs],
 142         [cf_with_tests=$withval],
 143         [cf_with_tests=yes])
 144 AC_MSG_RESULT($cf_with_tests)
 145
 146 AC_MSG_CHECKING(if you wish to install curses.h)
 147 AC_ARG_WITH(curses-h,
 148         [  --without-curses-h      install curses.h as ncurses.h only],
 149         [with_curses_h=$withval],
 150         [with_curses_h=yes])
 151 AC_MSG_RESULT($with_curses_h)
 152
 153 modules_to_build="ncurses"
 154 if test "X$cf_with_progs" != Xno ; then
 155 modules_to_build="$modules_to_build progs tack"
 156 fi
 157 modules_to_build="$modules_to_build panel menu form"
 158
 159 AC_ARG_PROGRAM
 160
 161 CF_PROG_AWK
 162 CF_PROG_EGREP
 163 CF_PROG_INSTALL
 164 CF_PROG_LINT
 165 CF_PROG_LN_S
 166
 167 AC_SYS_LONG_FILE_NAMES
 168
 169 # if we find pkg-config, check if we should install the ".pc" files.
 170 CF_PKG_CONFIG
 171 CF_WITH_PKG_CONFIG_LIBDIR
 172 CF_ENABLE_PC_FILES
 173
 174 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 175 AC_ARG_ENABLE(mixed-case,
 176         [  --enable-mixed-case     tic should assume mixed-case filenames],
 177         [enable_mixedcase=$enableval],
 178         [enable_mixedcase=auto])
 179 AC_MSG_RESULT($enable_mixedcase)
 180 if test "$enable_mixedcase" = "auto" ; then
 181     CF_MIXEDCASE_FILENAMES
 182 else
 183     cf_cv_mixedcase=$enable_mixedcase
 184     if test "$enable_mixedcase" = "yes" ; then
 185         AC_DEFINE(MIXEDCASE_FILENAMES)
 186     fi
 187 fi
 188
 189 # do this after mixed-case option (tags/TAGS is not as important as tic).
 190 AC_PROG_MAKE_SET
 191 CF_MAKE_TAGS
 192 CF_MAKEFLAGS
 193
 194 dnl These are standard among *NIX systems, but not when cross-compiling
 195 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 196 AC_CHECK_TOOL(LD, ld, ld)
 197 AC_CHECK_TOOL(AR, ar, ar)
 198 CF_AR_FLAGS
 199
 200 dnl Special option for use by system-builders: the install-prefix is used to
 201 dnl adjust the location into which the actual install is done, so that an
 202 dnl archive can be built without modifying the host system's configuration.
 203 AC_MSG_CHECKING(if you have specified an install-prefix)
 204 AC_ARG_WITH(install-prefix,
 205         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 206         [case "$withval" in #(vi
 207         yes|no) #(vi
 208                 ;;
 209         *)      DESTDIR="$withval"
 210                 ;;
 211         esac])
 212 AC_MSG_RESULT($DESTDIR)
 213 AC_SUBST(DESTDIR)
 214
 215 ###############################################################################
 216 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 217 # If we're cross-compiling, allow the user to override the tools and their
 218 # options.  The configure script is oriented toward identifying the host
 219 # compiler, etc., but we need a build compiler to generate parts of the source.
 220 CF_BUILD_CC
 221
 222 ###############################################################################
 223 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 224
 225 ### Options to allow the user to specify the set of libraries which are used.
 226 ### Use "--without-normal --with-shared" to allow the default model to be
 227 ### shared, for example.
 228 cf_list_models=""
 229 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 230
 231 CF_WITH_LIBTOOL
 232 if test "$with_libtool" != "no" ; then
 233
 234 cf_list_models="$cf_list_models libtool"
 235
 236 else
 237
 238 AC_MSG_CHECKING(if you want to build shared libraries)
 239 AC_ARG_WITH(shared,
 240         [  --with-shared           generate shared-libraries],
 241         [with_shared=$withval],
 242         [with_shared=no])
 243 AC_MSG_RESULT($with_shared)
 244 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 245
 246 AC_MSG_CHECKING(if you want to build static libraries)
 247 AC_ARG_WITH(normal,
 248         [  --with-normal           generate normal-libraries (default)],
 249         [with_normal=$withval],
 250         [with_normal=yes])
 251 AC_MSG_RESULT($with_normal)
 252 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 253
 254 AC_MSG_CHECKING(if you want to build debug libraries)
 255 AC_ARG_WITH(debug,
 256         [  --with-debug            generate debug-libraries (default)],
 257         [with_debug=$withval],
 258         [with_debug=yes])
 259 AC_MSG_RESULT($with_debug)
 260 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 261
 262 AC_MSG_CHECKING(if you want to build profiling libraries)
 263 AC_ARG_WITH(profile,
 264         [  --with-profile          generate profile-libraries],
 265         [with_profile=$withval],
 266         [with_profile=no])
 267 AC_MSG_RESULT($with_profile)
 268 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 269
 270 fi
 271
 272 ###############################################################################
 273
 274 AC_MSG_CHECKING(for specified models)
 275 test -z "$cf_list_models" && cf_list_models=normal
 276 dnl If we use libtool to generate libraries, then it must be the only
 277 dnl specified model.
 278 test "$with_libtool" != "no" && cf_list_models=libtool
 279 AC_MSG_RESULT($cf_list_models)
 280
 281 ### Use the first model as the default, and save its suffix for use in building
 282 ### up test-applications.
 283 AC_MSG_CHECKING(for default model)
 284 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 285 AC_MSG_RESULT($DFT_LWR_MODEL)
 286
 287 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 288
 289 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 290 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 291
 292 TICS_NAME=tic
 293 AC_SUBST(TICS_NAME)
 294
 295 TINFO_NAME=tinfo
 296 AC_SUBST(TINFO_NAME)
 297
 298 LIB_NAME=ncurses
 299 AC_SUBST(LIB_NAME)
 300
 301 LIB_DIR=../lib
 302 LIB_2ND=../../lib
 303
 304 CF_LIB_PREFIX(cf_prefix)
 305 LIB_PREFIX=$cf_prefix
 306 AC_SUBST(LIB_PREFIX)
 307
 308 LIB_SUFFIX=
 309 AC_SUBST(LIB_SUFFIX)
 310
 311 ###############################################################################
 312
 313 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 314 AC_ARG_WITH(termlib,
 315         [  --with-termlib          generate separate terminfo library],
 316         [with_termlib=$withval],
 317         [with_termlib=no])
 318 AC_MSG_RESULT($with_termlib)
 319
 320 AC_MSG_CHECKING(if you want to build a separate tic library)
 321 AC_ARG_WITH(ticlib,
 322         [  --with-ticlib           generate separate tic library],
 323         [with_ticlib=$withval],
 324         [with_ticlib=no])
 325 AC_MSG_RESULT($with_ticlib)
 326
 327 ### Checks for special libraries, must be done up-front.
 328 SHLIB_LIST=""
 329 CF_WITH_GPM
 330 if test "$with_gpm" != no ; then
 331         AC_MSG_CHECKING(if you want to load GPM dynamically)
 332         AC_ARG_WITH(dlsym,
 333                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 334                 [with_dlsym=$withval],
 335                 [with_dlsym=yes])
 336         AC_MSG_RESULT($with_dlsym)
 337         if test "$with_dlsym" = yes ; then
 338                 CF_FUNC_DLSYM
 339                 if test "$with_gpm" != yes ; then
 340                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 341                         cf_cv_gpm_soname="$with_gpm"
 342                 else
 343                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 344                 fi
 345                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 346                 SHLIB_LIST="-ldl $SHLIB_LIST"
 347         else
 348                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 349                 CF_ADD_LIB(gpm,TEST_LIBS)
 350         fi
 351         AC_DEFINE(HAVE_LIBGPM)
 352         CF_CHECK_GPM_WGETCH
 353 fi
 354
 355 CF_WITH_SYSMOUSE
 356
 357 dnl Not all ports of gcc support the -g option
 358
 359 if test X"$CC_G_OPT" = X"" ; then
 360         CC_G_OPT='-g'
 361         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 362 fi
 363 AC_SUBST(CC_G_OPT)
 364
 365 if test X"$CXX_G_OPT" = X"" ; then
 366         CXX_G_OPT='-g'
 367         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 368 fi
 369 AC_SUBST(CXX_G_OPT)
 370
 371 AC_MSG_CHECKING(for default loader flags)
 372 case $DFT_LWR_MODEL in
 373 libtool) LD_MODEL=''   ;;
 374 normal)  LD_MODEL=''   ;;
 375 debug)   LD_MODEL=$CC_G_OPT ;;
 376 profile) LD_MODEL='-pg';;
 377 shared)  LD_MODEL=''   ;;
 378 esac
 379 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 380 AC_MSG_RESULT($LD_MODEL)
 381
 382 case $DFT_LWR_MODEL in
 383 shared)
 384 CF_ENABLE_RPATH
 385 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 386 AC_ARG_ENABLE(relink,
 387 [  --disable-relink        relink shared libraries during install],
 388 [cf_cv_do_relink=$enableval],
 389 [cf_cv_do_relink=yes])
 390 AC_MSG_RESULT($cf_cv_do_relink)
 391         ;;
 392 esac
 393
 394 CF_SHARED_OPTS
 395 if test "$CC_SHARED_OPTS" = "unknown"; then
 396         for model in $cf_list_models; do
 397                 if test "$model" = "shared"; then
 398                         AC_ERROR(Shared libraries are not supported in this version)
 399                 fi
 400         done
 401 fi
 402
 403 ### If we're building with rpath, try to link non-standard libs that way too.
 404 if test "$DFT_LWR_MODEL" = "shared"; then
 405         CF_DISABLE_RPATH_HACK
 406 fi
 407
 408 ###############################################################################
 409 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 410
 411 ###     use option --disable-overwrite to leave out the link to -lcurses
 412 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 413 AC_ARG_ENABLE(overwrite,
 414         [  --disable-overwrite     leave out the link to -lcurses],
 415         [with_overwrite=$enableval],
 416         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 417 AC_MSG_RESULT($with_overwrite)
 418
 419 AC_MSG_CHECKING(if external terminfo-database is used)
 420 AC_ARG_ENABLE(database,
 421         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 422         [use_database=$enableval],
 423         [use_database=yes])
 424 AC_MSG_RESULT($use_database)
 425
 426 case $host_os in #(vi
 427 os2*) #(vi
 428         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 429         ;;
 430 *) #(vi
 431         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 432         ;;
 433 esac
 434 AC_SUBST(TERMINFO_SRC)
 435
 436 if test "$use_database" != no ; then
 437         AC_DEFINE(USE_DATABASE)
 438
 439         AC_MSG_CHECKING(which terminfo source-file will be installed)
 440         AC_ARG_WITH(database,
 441                 [  --with-database=XXX     specify terminfo source to install],
 442                 [TERMINFO_SRC=$withval])
 443         AC_MSG_RESULT($TERMINFO_SRC)
 444
 445         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 446         AC_ARG_WITH(hashed-db,
 447                 [  --with-hashed-db        specify hashed-database library],,
 448                 [with_hashed_db=no])
 449         AC_MSG_RESULT($with_hashed_db)
 450 else
 451         with_hashed_db=no
 452 fi
 453
 454 AC_MSG_CHECKING(for list of fallback descriptions)
 455 AC_ARG_WITH(fallbacks,
 456         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 457         [with_fallback=$withval],
 458         [with_fallback=])
 459 AC_MSG_RESULT($with_fallback)
 460 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 461 AC_SUBST(FALLBACK_LIST)
 462
 463 AC_MSG_CHECKING(if you want modern xterm or antique)
 464 AC_ARG_WITH(xterm-new,
 465         [  --without-xterm-new     specify if xterm terminfo should be old version],
 466         [with_xterm_new=$withval],
 467         [with_xterm_new=yes])
 468 case $with_xterm_new in
 469 no)     with_xterm_new=xterm-old;;
 470 *)      with_xterm_new=xterm-new;;
 471 esac
 472 AC_MSG_RESULT($with_xterm_new)
 473 WHICH_XTERM=$with_xterm_new
 474 AC_SUBST(WHICH_XTERM)
 475
 476 MAKE_TERMINFO=
 477 if test "$use_database" = no ; then
 478         TERMINFO="${datadir}/terminfo"
 479         MAKE_TERMINFO="#"
 480 else
 481
 482 AC_MSG_CHECKING(for list of terminfo directories)
 483 CF_WITH_PATHLIST(terminfo-dirs,
 484         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 485         TERMINFO_DIRS,
 486         DATADIR/terminfo,
 487         ${datadir}/terminfo)
 488 AC_MSG_RESULT($TERMINFO_DIRS)
 489 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 490
 491 AC_MSG_CHECKING(for default terminfo directory)
 492 CF_WITH_PATH(default-terminfo-dir,
 493         [  --with-default-terminfo-dir=DIR default terminfo directory],
 494         TERMINFO,
 495         DATADIR/terminfo,
 496         ${datadir}/terminfo)
 497 AC_MSG_RESULT($TERMINFO)
 498 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 499
 500 fi
 501
 502 AC_SUBST(TERMINFO)
 503 AC_SUBST(MAKE_TERMINFO)
 504
 505 ###     use option --disable-big-core to make tic run on small machines
 506 ###     We need 4Mb, check if we can allocate 50% more than that.
 507 AC_MSG_CHECKING(if big-core option selected)
 508 AC_ARG_ENABLE(big-core,
 509         [  --disable-big-core      assume machine has little memory],
 510         [with_big_core=$enableval],
 511         [AC_TRY_RUN([
 512 #include <stdlib.h>
 513 #include <string.h>
 514 int main() {
 515         unsigned long n = 6000000L;
 516         char *s = malloc(n);
 517         if (s != 0)
 518                 s[0] = s[n-1] = 0;
 519         ${cf_cv_main_return:-return}(s == 0);
 520 }],
 521         [with_big_core=yes],
 522         [with_big_core=no],
 523         [with_big_core=no])])
 524 AC_MSG_RESULT($with_big_core)
 525 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 526
 527 ### ISO C only guarantees 512-char strings, we have tables which load faster
 528 ### when constructed using "big" strings.  More than the C compiler, the awk
 529 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 530 AC_MSG_CHECKING(if big-strings option selected)
 531 AC_ARG_ENABLE(big-strings,
 532         [  --disable-big-strings   assume compiler has only standard-size strings],
 533         [with_big_strings=$enableval],
 534         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 535 AC_MSG_RESULT($with_big_strings)
 536
 537 USE_BIG_STRINGS=0
 538 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
 539 AC_SUBST(USE_BIG_STRINGS)
 540
 541 ###     use option --enable-termcap to compile in the termcap fallback support
 542 AC_MSG_CHECKING(if you want termcap-fallback support)
 543 AC_ARG_ENABLE(termcap,
 544         [  --enable-termcap        compile in termcap fallback support],
 545         [with_termcap=$enableval],
 546         [with_termcap=no])
 547 AC_MSG_RESULT($with_termcap)
 548
 549 if test "$with_termcap" != "yes" ; then
 550         if test "$use_database" = no ; then
 551                 if test -z "$with_fallback" ; then
 552                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 553                 fi
 554         fi
 555         AC_DEFINE(PURE_TERMINFO)
 556 else
 557
 558 if test "$with_ticlib" != no ; then
 559         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 560 fi
 561
 562 AC_DEFINE(USE_TERMCAP)
 563 AC_MSG_CHECKING(for list of termcap files)
 564 CF_WITH_PATHLIST(termpath,
 565         [  --with-termpath=XXX     specify list of termcap files],
 566         TERMPATH,
 567         /etc/termcap:/usr/share/misc/termcap)
 568 AC_MSG_RESULT($TERMPATH)
 569 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 570
 571 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 572 AC_MSG_CHECKING(if fast termcap-loader is needed)
 573 AC_ARG_ENABLE(getcap,
 574         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 575         [with_getcap=$enableval],
 576         [with_getcap=no])
 577 AC_MSG_RESULT($with_getcap)
 578 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 579
 580 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 581 AC_ARG_ENABLE(getcap-cache,
 582         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 583         [with_getcap_cache=$enableval],
 584         [with_getcap_cache=no])
 585 AC_MSG_RESULT($with_getcap_cache)
 586 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 587
 588 fi
 589
 590 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 591 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 592 AC_ARG_ENABLE(home-terminfo,
 593         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 594         [with_home_terminfo=$enableval],
 595         [with_home_terminfo=yes])
 596 AC_MSG_RESULT($with_home_terminfo)
 597 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 598
 599 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 600 AC_ARG_ENABLE(root-environ,
 601         [  --disable-root-environ  restrict environment when running as root],
 602         [with_root_environ=$enableval],
 603         [with_root_environ=yes])
 604 AC_MSG_RESULT($with_root_environ)
 605 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 606
 607 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 608 ###   to reduce storage requirements for the terminfo database.
 609 CF_LINK_FUNCS
 610
 611 with_links=no
 612 with_symlinks=no
 613
 614 # soft links (symbolic links) are useful for some systems where hard links do
 615 # not work, or to make it simpler to copy terminfo trees around.
 616 if test "$ac_cv_func_symlink" = yes ; then
 617     AC_MSG_CHECKING(if tic should use symbolic links)
 618     AC_ARG_ENABLE(symlinks,
 619         [  --enable-symlinks       make tic use symbolic links not hard links],
 620         [with_symlinks=$enableval],
 621         [with_symlinks=no])
 622     AC_MSG_RESULT($with_symlinks)
 623 fi
 624
 625 # If we have hard links and did not choose to use soft links instead, there is
 626 # no reason to make this choice optional - use the hard links.
 627 if test "$with_symlinks" = no ; then
 628     AC_MSG_CHECKING(if tic should use hard links)
 629     if test "$ac_cv_func_link" = yes ; then
 630         with_links=yes
 631     else
 632         with_links=no
 633     fi
 634     AC_MSG_RESULT($with_links)
 635 fi
 636
 637 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 638 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 639
 640 ###   use option --enable-broken-linker to force on use of broken-linker support
 641 AC_MSG_CHECKING(if you want broken-linker support code)
 642 AC_ARG_ENABLE(broken_linker,
 643         [  --enable-broken_linker  compile with broken-linker support code],
 644         [with_broken_linker=$enableval],
 645         [with_broken_linker=${BROKEN_LINKER:-no}])
 646 AC_MSG_RESULT($with_broken_linker)
 647
 648 BROKEN_LINKER=0
 649 if test "$with_broken_linker" = yes ; then
 650         AC_DEFINE(BROKEN_LINKER)
 651         BROKEN_LINKER=1
 652 elif test "$DFT_LWR_MODEL" = shared ; then
 653         case $cf_cv_system_name in #(vi
 654         cygwin*)
 655                 AC_DEFINE(BROKEN_LINKER)
 656                 BROKEN_LINKER=1
 657                 CF_VERBOSE(cygwin linker is broken anyway)
 658                 ;;
 659         esac
 660 fi
 661 AC_SUBST(BROKEN_LINKER)
 662
 663 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 664 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 665 AC_ARG_ENABLE(bsdpad,
 666         [  --enable-bsdpad         recognize BSD-style prefix padding],
 667         [with_bsdpad=$enableval],
 668         [with_bsdpad=no])
 669 AC_MSG_RESULT($with_bsdpad)
 670 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 671
 672 ###   use option --enable-widec to turn on use of wide-character support
 673 NCURSES_CH_T=chtype
 674 NCURSES_LIBUTF8=0
 675
 676 NEED_WCHAR_H=0
 677 NCURSES_MBSTATE_T=0
 678 NCURSES_WCHAR_T=0
 679 NCURSES_WINT_T=0
 680
 681 # Check to define _XOPEN_SOURCE "automatically"
 682 CF_XOPEN_SOURCE(500)
 683
 684 # Work around breakage on OS X
 685 CF_SIGWINCH
 686
 687 # Checks for CODESET support.
 688 AM_LANGINFO_CODESET
 689
 690 # use these variables to work around a defect in gcc's fixincludes.
 691 NCURSES_OK_WCHAR_T=
 692 NCURSES_OK_WINT_T=
 693
 694 AC_MSG_CHECKING(if you want wide-character code)
 695 AC_ARG_ENABLE(widec,
 696         [  --enable-widec          compile with wide-char/UTF-8 code],
 697         [with_widec=$enableval],
 698         [with_widec=no])
 699 AC_MSG_RESULT($with_widec)
 700 if test "$with_widec" = yes ; then
 701         LIB_SUFFIX="w${LIB_SUFFIX}"
 702         AC_DEFINE(USE_WIDEC_SUPPORT)
 703
 704         case "$CFLAGS $CPPFLAGS" in #(vi
 705         *-D_XOPEN_SOURCE=500) #(vi
 706                 ;;
 707         *)
 708                 CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 709                 ;;
 710         esac
 711
 712         # with_overwrite=no
 713         NCURSES_CH_T=cchar_t
 714         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 715         if test "$ac_cv_func_putwc" != yes ; then
 716                 CF_UTF8_LIB
 717                 if test "$cf_cv_utf8_lib" != no ; then
 718                         NCURSES_LIBUTF8=1
 719                 fi
 720         fi
 721         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 722         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 723         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 724
 725         if test "$NCURSES_MBSTATE_T" != 0; then
 726                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 727         fi
 728 fi
 729 AC_SUBST(NCURSES_CH_T)
 730 AC_SUBST(NCURSES_LIBUTF8)
 731
 732 AC_SUBST(NEED_WCHAR_H)
 733 AC_SUBST(NCURSES_MBSTATE_T)
 734 AC_SUBST(NCURSES_WCHAR_T)
 735 AC_SUBST(NCURSES_WINT_T)
 736
 737 AC_SUBST(NCURSES_OK_WCHAR_T)
 738 AC_SUBST(NCURSES_OK_WINT_T)
 739
 740 ###   use option --disable-lp64 to allow long chtype
 741 case $cf_cv_abi_version in
 742 [[345]]*)
 743         default_with_lp64=no
 744         ;;
 745 *)
 746         default_with_lp64=yes
 747         ;;
 748 esac
 749
 750 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 751 AC_ARG_ENABLE(lp64,
 752         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 753         [with_lp64=$enableval],
 754         [with_lp64=$default_with_lp64])
 755 AC_MSG_RESULT($with_lp64)
 756
 757 if test "$with_lp64" = yes ; then
 758         cf_cv_enable_lp64=1
 759 else
 760         cf_cv_enable_lp64=0
 761 fi
 762 AC_SUBST(cf_cv_enable_lp64)
 763
 764 CF_LARGEFILE
 765
 766 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 767 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 768 AC_ARG_ENABLE(tparm-varargs,
 769         [  --disable-tparm-varargs compile tparm() without varargs interface],
 770         [with_tparm_varargs=$enableval],
 771         [with_tparm_varargs=yes])
 772 AC_MSG_RESULT($with_tparm_varargs)
 773 NCURSES_TPARM_VARARGS=0
 774 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 775 AC_SUBST(NCURSES_TPARM_VARARGS)
 776
 777 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 778 if test "$with_ticlib" != no ; then
 779 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 780 AC_ARG_ENABLE(tic-depends,
 781         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 782         [with_tic_depends=$enableval],
 783         [with_tic_depends=yes])
 784 AC_MSG_RESULT($with_tic_depends)
 785 else
 786         with_tic_depends=no
 787 fi
 788
 789 ###   use option --with-bool to override bool's type
 790 AC_MSG_CHECKING(for type of bool)
 791 AC_ARG_WITH(bool,
 792         [  --with-bool=TYPE        override fallback type of bool variable],
 793         [NCURSES_BOOL="$withval"],
 794         [NCURSES_BOOL=auto])
 795 AC_MSG_RESULT($NCURSES_BOOL)
 796 AC_SUBST(NCURSES_BOOL)
 797
 798 AC_MSG_CHECKING(for alternate terminal capabilities file)
 799 AC_ARG_WITH(caps,
 800         [  --with-caps=alt         compile with alternate Caps file],
 801         [TERMINFO_CAPS=Caps.$withval],
 802         [TERMINFO_CAPS=Caps])
 803 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 804 AC_MSG_RESULT($TERMINFO_CAPS)
 805 AC_SUBST(TERMINFO_CAPS)
 806
 807 ###   use option --with-chtype to override chtype's type
 808 AC_MSG_CHECKING(for type of chtype)
 809 AC_ARG_WITH(chtype,
 810         [  --with-chtype=TYPE      override type of chtype],
 811         [NCURSES_CHTYPE="$withval"],
 812         [NCURSES_CHTYPE=auto])
 813 AC_MSG_RESULT($NCURSES_CHTYPE)
 814
 815 ###   use option --with-ospeed to override ospeed's type
 816 AC_MSG_CHECKING(for type of ospeed)
 817 AC_ARG_WITH(ospeed,
 818         [  --with-ospeed=TYPE      override type of ospeed variable],
 819         [NCURSES_OSPEED="$withval"],
 820         [NCURSES_OSPEED=short])
 821 AC_MSG_RESULT($NCURSES_OSPEED)
 822 AC_SUBST(NCURSES_OSPEED)
 823
 824 ###   use option --with-mmask-t to override mmask_t's type
 825 AC_MSG_CHECKING(for type of mmask_t)
 826 AC_ARG_WITH(mmask-t,
 827         [  --with-mmask-t=TYPE     override type of mmask_t],
 828         [NCURSES_MMASK_T="$withval"],
 829         [NCURSES_MMASK_T=auto])
 830 AC_MSG_RESULT($NCURSES_MMASK_T)
 831
 832 ###   use option --with-ccharw-max to override CCHARW_MAX size
 833 AC_MSG_CHECKING(for size CCHARW_MAX)
 834 AC_ARG_WITH(ccharw-max,
 835         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
 836         [NCURSES_CCHARW_MAX="$withval"],
 837         [NCURSES_CCHARW_MAX=5])
 838 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
 839 AC_SUBST(NCURSES_CCHARW_MAX)
 840
 841 ### Enable compiling-in rcs id's
 842 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 843 AC_ARG_WITH(rcs-ids,
 844         [  --with-rcs-ids          compile-in RCS identifiers],
 845         [with_rcs_ids=$withval],
 846         [with_rcs_ids=no])
 847 AC_MSG_RESULT($with_rcs_ids)
 848 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 849
 850 ###############################################################################
 851 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
 852
 853 ###############################################################################
 854 CF_HELP_MESSAGE(Extensions:)
 855
 856 ### Note that some functions (such as const) are normally disabled anyway.
 857 AC_MSG_CHECKING(if you want to build with function extensions)
 858 AC_ARG_ENABLE(ext-funcs,
 859         [  --disable-ext-funcs     disable function-extensions],
 860         [with_ext_funcs=$enableval],
 861         [with_ext_funcs=yes])
 862 AC_MSG_RESULT($with_ext_funcs)
 863 if test "$with_ext_funcs" = yes ; then
 864         NCURSES_EXT_FUNCS=1
 865         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS)
 866         AC_DEFINE(HAVE_CURSES_VERSION)
 867         AC_DEFINE(HAVE_HAS_KEY)
 868         AC_DEFINE(HAVE_RESIZETERM)
 869         AC_DEFINE(HAVE_RESIZE_TERM)
 870         AC_DEFINE(HAVE_TERM_ENTRY_H)
 871         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 872         AC_DEFINE(HAVE_USE_SCREEN)
 873         AC_DEFINE(HAVE_USE_WINDOW)
 874         AC_DEFINE(HAVE_WRESIZE)
 875         AC_DEFINE(NCURSES_EXT_FUNCS)
 876         GENERATED_EXT_FUNCS=generated
 877 else
 878         NCURSES_EXT_FUNCS=0
 879         GENERATED_EXT_FUNCS=
 880 fi
 881 AC_SUBST(NCURSES_EXT_FUNCS)
 882 AC_SUBST(GENERATED_EXT_FUNCS)
 883
 884 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
 885 AC_ARG_ENABLE(sp-funcs,
 886         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
 887         [with_sp_funcs=$enableval],
 888         [with_sp_funcs=no])
 889 AC_MSG_RESULT($with_sp_funcs)
 890 if test "$with_sp_funcs" = yes ; then
 891         NCURSES_SP_FUNCS=1
 892         AC_DEFINE(NCURSES_SP_FUNCS)
 893         GENERATED_SP_FUNCS=generated
 894 else
 895         NCURSES_SP_FUNCS=0
 896         GENERATED_SP_FUNCS=
 897 fi
 898 AC_SUBST(NCURSES_SP_FUNCS)
 899 AC_SUBST(GENERATED_SP_FUNCS)
 900
 901 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
 902 AC_ARG_ENABLE(term-driver,
 903         [  --enable-term-driver    enable experimental terminal-driver],
 904         [with_term_driver=$enableval],
 905         [with_term_driver=no])
 906 AC_MSG_RESULT($with_term_driver)
 907 if test "$with_term_driver" = yes ; then
 908         AC_DEFINE(USE_TERM_DRIVER)
 909         if test "$with_sp_funcs" != yes ; then
 910                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
 911         fi
 912 fi
 913
 914 ###   use option --enable-const to turn on use of const beyond that in XSI.
 915 AC_MSG_CHECKING(for extended use of const keyword)
 916 AC_ARG_ENABLE(const,
 917         [  --enable-const          compile with extra/non-standard const],
 918         [with_ext_const=$enableval],
 919         [with_ext_const=no])
 920 AC_MSG_RESULT($with_ext_const)
 921 NCURSES_CONST='/*nothing*/'
 922 if test "$with_ext_const" = yes ; then
 923         NCURSES_CONST=const
 924 fi
 925 AC_SUBST(NCURSES_CONST)
 926
 927 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 928 AC_MSG_CHECKING(if you want to use extended colors)
 929 AC_ARG_ENABLE(ext-colors,
 930         [  --enable-ext-colors     compile for 256-color support],
 931         [with_ext_colors=$enableval],
 932         [with_ext_colors=no])
 933 AC_MSG_RESULT($with_ext_colors)
 934 NCURSES_EXT_COLORS=0
 935 if test "$with_ext_colors" = yes ; then
 936         if test "$with_widec" != yes ; then
 937                 AC_MSG_ERROR(This option applies only to wide-character library)
 938         else
 939                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 940                 CF_NCURSES_ABI_6
 941         fi
 942         NCURSES_EXT_COLORS=1
 943         AC_DEFINE(NCURSES_EXT_COLORS)
 944 fi
 945 AC_SUBST(NCURSES_EXT_COLORS)
 946
 947 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 948 AC_MSG_CHECKING(if you want to use extended mouse encoding)
 949 AC_ARG_ENABLE(ext-mouse,
 950         [  --enable-ext-mouse      compile for extended mouse-encoding],
 951         [with_ext_mouse=$enableval],
 952         [with_ext_mouse=no])
 953 AC_MSG_RESULT($with_ext_mouse)
 954 NCURSES_MOUSE_VERSION=1
 955 if test "$with_ext_mouse" = yes ; then
 956         NCURSES_MOUSE_VERSION=2
 957         CF_NCURSES_ABI_6
 958 fi
 959 AC_SUBST(NCURSES_MOUSE_VERSION)
 960
 961 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 962 AC_ARG_ENABLE(no-padding,
 963         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 964         [with_no_padding=$enableval],
 965         [with_no_padding=$with_ext_funcs])
 966 AC_MSG_RESULT($with_no_padding)
 967 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 968
 969 AC_CHECK_SIZEOF([signed char], 0)
 970 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 971         NCURSES_SBOOL="signed char"
 972 else
 973         NCURSES_SBOOL="char"
 974 fi
 975 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 976 AC_ARG_ENABLE(signed-char,
 977         [  --enable-signed-char    compile using signed Boolean's in term.h],
 978         [with_signed_char=$enableval],
 979         [with_signed_char=no])
 980 AC_MSG_RESULT($with_signed_char)
 981 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
 982 AC_SUBST(NCURSES_SBOOL)
 983
 984 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
 985 AC_MSG_CHECKING(if you want SIGWINCH handler)
 986 AC_ARG_ENABLE(sigwinch,
 987         [  --enable-sigwinch       compile with SIGWINCH handler],
 988         [with_sigwinch=$enableval],
 989         [with_sigwinch=$with_ext_funcs])
 990 AC_MSG_RESULT($with_sigwinch)
 991 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
 992
 993 ###   use option --enable-tcap-names to allow user to define new capabilities
 994 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
 995 AC_ARG_ENABLE(tcap-names,
 996         [  --enable-tcap-names     compile with user-definable terminal capabilities],
 997         [with_tcap_names=$enableval],
 998         [with_tcap_names=$with_ext_funcs])
 999 AC_MSG_RESULT($with_tcap_names)
1000 NCURSES_XNAMES=0
1001 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
1002 AC_SUBST(NCURSES_XNAMES)
1003
1004 ###############################################################################
1005 # These options are relatively safe to experiment with.
1006 CF_HELP_MESSAGE(Development Code:)
1007 AC_MSG_CHECKING(if you want all development code)
1008 AC_ARG_WITH(develop,
1009         [  --without-develop       disable development options],
1010         [with_develop=$withval],
1011         [with_develop=no])
1012 AC_MSG_RESULT($with_develop)
1013
1014 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1015 AC_MSG_CHECKING(if you want hard-tabs code)
1016 AC_ARG_ENABLE(hard-tabs,
1017         [  --enable-hard-tabs      compile with hard-tabs code],,
1018         [enable_hard_tabs=$with_develop])
1019 AC_MSG_RESULT($enable_hard_tabs)
1020 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
1021
1022 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1023 AC_MSG_CHECKING(if you want limited support for xmc)
1024 AC_ARG_ENABLE(xmc-glitch,
1025         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1026         [enable_xmc_glitch=$with_develop])
1027 AC_MSG_RESULT($enable_xmc_glitch)
1028 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
1029
1030 ###############################################################################
1031 # These are just experimental, probably should not be in a package:
1032 CF_HELP_MESSAGE(Experimental Code:)
1033
1034 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1035 AC_ARG_ENABLE(assumed-color,
1036         [  --disable-assumed-color do not assume anything about default-colors],
1037         [with_assumed_color=$enableval],
1038         [with_assumed_color=yes])
1039 AC_MSG_RESULT($with_assumed_color)
1040 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
1041
1042 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1043 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1044 AC_ARG_ENABLE(hashmap,
1045         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1046         [with_hashmap=$enableval],
1047         [with_hashmap=yes])
1048 AC_MSG_RESULT($with_hashmap)
1049 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1050
1051 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1052 AC_MSG_CHECKING(if you want colorfgbg code)
1053 AC_ARG_ENABLE(colorfgbg,
1054         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1055         [with_colorfgbg=$enableval],
1056         [with_colorfgbg=no])
1057 AC_MSG_RESULT($with_colorfgbg)
1058 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1059
1060 ###   use option --enable-interop to turn on use of bindings used for interop
1061 AC_MSG_CHECKING(if you want interop bindings)
1062 AC_ARG_ENABLE(interop,
1063         [  --enable-interop        compile-in experimental interop bindings],
1064         [with_exp_interop=$enableval],
1065         [with_exp_interop=no])
1066 AC_MSG_RESULT($with_exp_interop)
1067
1068 NCURSES_INTEROP_FUNCS=0
1069 test "$with_exp_interop" = yes && NCURSES_INTEROP_FUNCS=1
1070 AC_SUBST(NCURSES_INTEROP_FUNCS)
1071
1072 # This is still experimental (20080329), but should ultimately be moved to
1073 # the script-block --with-normal, etc.
1074 CF_WITH_PTHREAD
1075
1076 if test "x$with_pthread" != xno; then
1077         AC_CHECK_FUNC(pthread_kill,[
1078                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1079                 AC_ARG_ENABLE(pthreads-eintr,
1080                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1081                         [use_pthreads_eintr=$enableval],
1082                         [use_pthreads_eintr=no])
1083                 AC_MSG_RESULT($use_pthreads_eintr)
1084                 if test $use_pthreads_eintr = yes ; then
1085                         AC_DEFINE(USE_PTHREADS_EINTR)
1086                 fi])
1087
1088         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1089         AC_ARG_ENABLE(weak-symbols,
1090                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1091                 [use_weak_symbols=$enableval],
1092                 [use_weak_symbols=no])
1093         AC_MSG_RESULT($use_weak_symbols)
1094         if test "$use_weak_symbols" = yes ; then
1095                 CF_WEAK_SYMBOLS
1096         else
1097                 cf_cv_weak_symbols=no
1098         fi
1099
1100         if test $cf_cv_weak_symbols = yes ; then
1101                 AC_DEFINE(USE_WEAK_SYMBOLS)
1102         fi
1103 fi
1104
1105 PTHREAD=
1106 if test "$with_pthread" = "yes" ; then
1107     AC_DEFINE(USE_PTHREADS)
1108     enable_reentrant=yes
1109     if test $cf_cv_weak_symbols = yes ; then
1110         PTHREAD=-lpthread
1111     fi
1112 fi
1113 AC_SUBST(PTHREAD)
1114
1115 # Reentrant code has to be opaque; there's little advantage to making ncurses
1116 # opaque outside of that, so there is no --enable-opaque option.  We can use
1117 # this option without --with-pthreads, but this will be always set for
1118 # pthreads.
1119 AC_MSG_CHECKING(if you want experimental reentrant code)
1120 AC_ARG_ENABLE(reentrant,
1121         [  --enable-reentrant      compile with experimental reentrant code],
1122         [with_reentrant=$enableval],
1123         [with_reentrant=no])
1124 AC_MSG_RESULT($with_reentrant)
1125 if test "$with_reentrant" = yes ; then
1126         cf_cv_enable_reentrant=1
1127         cf_cv_enable_opaque="NCURSES_INTERNALS"
1128         NCURSES_OPAQUE=1
1129         NCURSES_SIZE_T=int
1130         if test $cf_cv_weak_symbols = yes ; then
1131                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1132                 CF_ADD_LIB(pthread,TEST_LIBS)
1133                 CF_ADD_LIB(pthread,TEST_LIBS2)
1134         else
1135                 LIB_SUFFIX="t${LIB_SUFFIX}"
1136         fi
1137         AC_DEFINE(USE_REENTRANT)
1138         CF_NCURSES_ABI_6
1139 else
1140         cf_cv_enable_reentrant=0
1141         cf_cv_enable_opaque="NCURSES_OPAQUE"
1142         NCURSES_OPAQUE=0
1143         NCURSES_SIZE_T=short
1144 fi
1145 AC_SUBST(cf_cv_enable_reentrant)
1146 AC_SUBST(cf_cv_enable_opaque)
1147 AC_SUBST(NCURSES_OPAQUE)
1148 AC_SUBST(NCURSES_SIZE_T)
1149
1150 ### Allow using a different wrap-prefix
1151 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1152         AC_MSG_CHECKING(for prefix used to wrap public variables)
1153         AC_ARG_WITH(wrap-prefix,
1154                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1155                 [NCURSES_WRAP_PREFIX=$withval],
1156                 [NCURSES_WRAP_PREFIX=_nc_])
1157         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1158 else
1159         NCURSES_WRAP_PREFIX=_nc_
1160 fi
1161 AC_SUBST(NCURSES_WRAP_PREFIX)
1162 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX")
1163
1164 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1165 AC_ARG_ENABLE(safe-sprintf,
1166         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1167         [with_safe_sprintf=$enableval],
1168         [with_safe_sprintf=no])
1169 AC_MSG_RESULT($with_safe_sprintf)
1170 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1171
1172 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1173 # when hashmap is used scroll hints are useless
1174 if test "$with_hashmap" = no ; then
1175 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1176 AC_ARG_ENABLE(scroll-hints,
1177         [  --disable-scroll-hints  compile without scroll-hints code],
1178         [with_scroll_hints=$enableval],
1179         [with_scroll_hints=yes])
1180 AC_MSG_RESULT($with_scroll_hints)
1181 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1182 fi
1183
1184 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1185 AC_ARG_ENABLE(wgetch-events,
1186         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1187         [with_wgetch_events=$enableval],
1188         [with_wgetch_events=no])
1189 AC_MSG_RESULT($with_wgetch_events)
1190 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1191
1192 ###############################################################################
1193 CF_HELP_MESSAGE(Testing/development Options:)
1194
1195 ###     use option --disable-echo to suppress full display compiling commands
1196 AC_MSG_CHECKING(if you want to display full commands during build)
1197 AC_ARG_ENABLE(echo,
1198         [  --enable-echo           build: display "compiling" commands (default)],
1199         [with_echo=$enableval],
1200         [with_echo=yes])
1201 if test "$with_echo" = yes; then
1202         ECHO_LINK=
1203 else
1204         ECHO_LINK='@ echo linking $@ ... ;'
1205         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1206         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1207 fi
1208 AC_MSG_RESULT($with_echo)
1209 AC_SUBST(ECHO_LINK)
1210
1211 ###     use option --enable-warnings to turn on all gcc warnings
1212 AC_MSG_CHECKING(if you want to see compiler warnings)
1213 AC_ARG_ENABLE(warnings,
1214         [  --enable-warnings       build: turn on GCC compiler warnings],
1215         [with_warnings=$enableval])
1216 AC_MSG_RESULT($with_warnings)
1217
1218 if test "x$with_warnings" = "xyes"; then
1219         CF_ADD_ADAFLAGS(-gnatg)
1220         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1221         if test "$cf_with_cxx" = yes ; then
1222                 CF_GXX_WARNINGS(Wno-unused)
1223         fi
1224 fi
1225 CF_GCC_ATTRIBUTES
1226
1227 ###     use option --enable-assertions to turn on generation of assertion code
1228 AC_MSG_CHECKING(if you want to enable runtime assertions)
1229 AC_ARG_ENABLE(assertions,
1230         [  --enable-assertions     test: turn on generation of assertion code],
1231         [with_assertions=$enableval],
1232         [with_assertions=no])
1233 AC_MSG_RESULT($with_assertions)
1234 if test -n "$GCC"
1235 then
1236         if test "$with_assertions" = no
1237         then
1238                 AC_DEFINE(NDEBUG)
1239                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1240         else
1241                 CF_ADD_ADAFLAGS(-gnata)
1242         fi
1243 fi
1244
1245 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1246 CF_DISABLE_LEAKS
1247 AC_DEFINE(HAVE_NC_ALLOC_H)
1248
1249 ###     use option --enable-expanded to generate certain macros as functions
1250 AC_ARG_ENABLE(expanded,
1251         [  --enable-expanded       test: generate functions for certain macros],
1252         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1253
1254 ###     use option --disable-macros to suppress macros in favor of functions
1255 AC_ARG_ENABLE(macros,
1256         [  --disable-macros        test: use functions rather than macros],
1257         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1258
1259 # Normally we only add trace() to the debug-library.  Allow this to be
1260 # extended to all models of the ncurses library:
1261 cf_all_traces=no
1262 case "$CFLAGS $CPPFLAGS" in
1263 *-DTRACE*)
1264         cf_all_traces=yes
1265         ;;
1266 esac
1267
1268 AC_MSG_CHECKING(whether to add trace feature to all models)
1269 AC_ARG_WITH(trace,
1270 [  --with-trace            test: add trace() function to all models of ncurses],
1271 [cf_with_trace=$withval],
1272 [cf_with_trace=$cf_all_traces])
1273 AC_MSG_RESULT($cf_with_trace)
1274
1275 if test "$cf_with_trace" = yes ; then
1276         LIB_TRACING=all
1277         ADA_TRACE=TRUE
1278         CF_ADD_CFLAGS(-DTRACE)
1279 else
1280         LIB_TRACING=DEBUG
1281         ADA_TRACE=FALSE
1282 fi
1283
1284 AC_SUBST(ADA_TRACE)
1285
1286 ###     Checks for libraries.
1287 case $cf_cv_system_name in #(vi
1288 *mingw32*) #(vi
1289         ;;
1290 *)
1291 AC_CHECK_FUNC(gettimeofday,
1292         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1293
1294 AC_CHECK_LIB(bsd, gettimeofday,
1295         AC_DEFINE(HAVE_GETTIMEOFDAY)
1296         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1297         ;;
1298 esac
1299
1300 CF_MATH_LIB(MATH_LIB,sin(x))
1301 AC_SUBST(MATH_LIB)
1302
1303 ###     Checks for header files.
1304 AC_STDC_HEADERS
1305 AC_HEADER_DIRENT
1306 AC_HEADER_TIME
1307 CF_REGEX
1308
1309 dnl These are some other potentially nonportable headers.
1310 AC_CHECK_HEADERS( \
1311 fcntl.h \
1312 getopt.h \
1313 limits.h \
1314 locale.h \
1315 math.h \
1316 poll.h \
1317 sys/bsdtypes.h \
1318 sys/ioctl.h \
1319 sys/param.h \
1320 sys/poll.h \
1321 sys/select.h \
1322 sys/time.h \
1323 sys/times.h \
1324 ttyent.h \
1325 unistd.h \
1326 wctype.h \
1327 )
1328
1329 CF_GETOPT_HEADER
1330
1331 # check for ISC (this may also define _POSIX_SOURCE)
1332 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1333 if test "$ISC" = yes ; then
1334         AC_CHECK_LIB(cposix,main)
1335         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1336 fi
1337
1338 CF_SYS_TIME_SELECT
1339
1340 ###     checks for compiler characteristics
1341 AC_LANG_C
1342 AC_C_CONST
1343 CF_C_INLINE(NCURSES_INLINE,1200)
1344 CF_SIG_ATOMIC_T
1345
1346 if test $NCURSES_CHTYPE = auto ; then
1347         CF_TYPEOF_CHTYPE
1348 else
1349         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1350 fi
1351 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1352 AC_SUBST(cf_cv_typeof_chtype)
1353
1354 CF_UNSIGNED_LITERALS
1355 cf_cv_1UL="1"
1356 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1357 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1358 AC_SUBST(cf_cv_1UL)
1359
1360 if test $NCURSES_MMASK_T = auto ; then
1361         cf_cv_typeof_mmask_t=long
1362 else
1363         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1364 fi
1365 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1366 AC_SUBST(cf_cv_typeof_mmask_t)
1367
1368 ###     Checks for external-data
1369 CF_ERRNO
1370 CF_LINK_DATAONLY
1371
1372 ###     Checks for library functions.
1373 AC_CHECK_FUNCS( \
1374 getcwd \
1375 getegid \
1376 geteuid \
1377 getttynam \
1378 issetugid \
1379 poll \
1380 remove \
1381 select \
1382 setbuf \
1383 setbuffer \
1384 setvbuf \
1385 sigaction \
1386 sigvec \
1387 strdup \
1388 strstr \
1389 tcgetpgrp \
1390 times \
1391 vsnprintf \
1392 )
1393 if test "$with_getcap" = "yes" ; then
1394         CF_CGETENT
1395 fi
1396
1397 CF_ISASCII
1398 CF_STRUCT_SIGACTION
1399 CF_FUNC_NANOSLEEP
1400 CF_FUNC_TERMIOS
1401 CF_FUNC_VSSCANF
1402 CF_MKSTEMP
1403
1404 # setup for prototype of fallback for vsscanf()
1405 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1406
1407 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1408 if test "$cross_compiling" = yes ; then
1409         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1410 else
1411         AC_FUNC_SETVBUF_REVERSED
1412 fi
1413 AC_TYPE_SIGNAL
1414 CF_TYPE_SIGACTION
1415 CF_SIZECHANGE
1416 CF_FUNC_MEMMOVE
1417 CF_FUNC_POLL
1418 CF_VA_COPY
1419 AC_FUNC_VFORK
1420
1421 # special check for test/ditto.c
1422 CF_FUNC_OPENPTY
1423 if test "$cf_cv_func_openpty" != no ; then
1424     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1425     AC_DEFINE(USE_XTERM_PTY)
1426     if test "$cf_cv_lib_util" = yes ; then
1427         CF_ADD_LIB(util,TEST_LIBS)
1428     fi
1429 fi
1430 AC_SUBST(TEST_LIBS)
1431 AC_SUBST(TEST_LIBS2)
1432
1433 if test "$with_hashed_db" != no ; then
1434         AC_DEFINE(USE_HASHED_DB)
1435         CF_HASHED_DB($with_hashed_db)
1436 fi
1437
1438 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1439 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1440         CF_STRIP_G_OPT(CFLAGS)
1441         CF_STRIP_G_OPT(CXXFLAGS)
1442 fi
1443
1444 # Just in case, check if the C compiler has a bool type.
1445 CF_BOOL_DECL(cf_cv_cc_bool_type)
1446
1447 # Check for C++ compiler characteristics (and ensure that it's there!)
1448 if test -n "$CXX" ; then
1449         AC_LANG_CPLUSPLUS
1450         CF_STDCPP_LIBRARY
1451         CF_PROG_CC_C_O(CXX)
1452
1453         case $GXX_VERSION in
1454         1*|2.[0-6]*)
1455                 cf_cxx_library=yes
1456                 ;;
1457         *-2.7*|2.7*)
1458                 CF_GPP_LIBRARY
1459                 ;;
1460         *)
1461                 cf_cxx_library=no
1462                 ;;
1463         esac
1464
1465         AC_CHECK_HEADERS(iostream typeinfo)
1466
1467     if test x"$ac_cv_header_iostream" = xyes ; then
1468         AC_MSG_CHECKING(if iostream uses std-namespace)
1469         AC_TRY_COMPILE([
1470 #include <iostream>
1471 using std::endl;
1472 using std::cerr;],[
1473 cerr << "testing" << endl;
1474 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1475         AC_MSG_RESULT($cf_iostream_namespace)
1476         if test "$cf_iostream_namespace" = yes ; then
1477             AC_DEFINE(IOSTREAM_NAMESPACE)
1478         fi
1479     fi
1480
1481         CF_BOOL_DECL
1482         CF_BOOL_SIZE
1483         CF_ETIP_DEFINES
1484         CF_CPP_PARAM_INIT
1485         CF_CPP_STATIC_CAST
1486
1487         CXX_AR='$(AR)'
1488         CXX_ARFLAGS='$(ARFLAGS)'
1489         case $cf_cv_system_name in #(vi
1490         irix*) #(vi
1491             if test "$GXX" != yes ; then
1492                 CXX_AR='$(CXX)'
1493                 CXX_ARFLAGS='-ar -o'
1494             fi
1495             ;;
1496         sco3.2v5*) #(vi
1497             CXXLDFLAGS="-u main"
1498             ;;
1499         solaris2*)
1500             if test "$GXX" != yes ; then
1501                 CXX_AR='$(CXX)'
1502                 CXX_ARFLAGS='-xar -o'
1503             fi
1504             ;;
1505         esac
1506         AC_SUBST(CXXLDFLAGS)
1507         AC_SUBST(CXX_AR)
1508         AC_SUBST(CXX_ARFLAGS)
1509 else
1510         cf_cxx_library=no
1511         cf_cv_builtin_bool=1
1512
1513         # Just because we are not configuring against C++ right now does not
1514         # mean that a user will not want to use C++.  Some distributors disable
1515         # the C++ portion of this configuration as a shortcut (or just to avoid
1516         # compiling the demo in the c++ directory).  So we need a reasonable
1517         # default for the 'bool' type.
1518         #
1519         # Caveat: since the storage of the bool type is not standardized, it
1520         # may change.
1521
1522         if test "$NCURSES_BOOL" != auto ; then
1523                 cf_cv_type_of_bool=$NCURSES_BOOL
1524                 cf_cv_header_stdbool_h=0
1525         else
1526                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1527                         CF_BOOL_SIZE
1528                 else
1529                         AC_MSG_CHECKING(for fallback type of bool)
1530                         case "$host_cpu" in #(vi
1531                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1532                         *)      cf_cv_type_of_bool=int  ;;
1533                         esac
1534                         AC_MSG_RESULT($cf_cv_type_of_bool)
1535                 fi
1536         fi
1537 fi
1538 AC_SUBST(CXXLIBS)
1539
1540 # If the C compiler did not declare bool, and we did not determine that the C++
1541 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1542 # ncurses library use the same type as C++ bool.  Note that this allows one to
1543 # specify the type of bool in a configure-script option and postpone
1544 # integration with the C++ compiler provided that the types are compatible.
1545 USE_CXX_BOOL=1
1546 if test $cf_cv_cc_bool_type = 1
1547 then
1548         # oops: C has a bool.  Unlikely, but C++ could differ.
1549         USE_CXX_BOOL=0
1550 elif test $cf_cv_builtin_bool = 0
1551 then
1552         # C++ has no bool
1553         USE_CXX_BOOL=0
1554 else
1555         # this is the normal case
1556         USE_CXX_BOOL='defined(__cplusplus)'
1557 fi
1558 AC_SUBST(USE_CXX_BOOL)
1559
1560 CF_HELP_MESSAGE(Ada95 Binding Options:)
1561
1562 dnl If the Ada95 source-tree is present, add that to the build unless it will
1563 dnl not work, or was not requested.
1564 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1565
1566 dnl libtool does not know anything about GNAT, though a change made in 1998
1567 dnl provided for it "someday".  Disable the ada subtree if we are using
1568 dnl libtool -TD 20070714
1569         if test "$cf_with_ada" != "no" ; then
1570                 if test "$with_libtool" != "no"; then
1571                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1572                         cf_with_ada=no
1573                 fi
1574         fi
1575
1576 dnl Check for availability of GNU Ada Translator (GNAT).
1577 dnl At the moment we support no other Ada95 compiler.
1578         if test "$cf_with_ada" != "no" ; then
1579                 CF_PROG_GNAT
1580                 if test "$cf_cv_prog_gnat_correct" = yes; then
1581                         CF_ADD_ADAFLAGS(-gnatpn)
1582
1583                         # make ADAFLAGS consistent with CFLAGS
1584                         case "$CFLAGS" in
1585                         *-g*)
1586                                 CF_ADD_ADAFLAGS(-g)
1587                                 ;;
1588                         esac
1589                         case "$CFLAGS" in
1590                         *-O*)
1591                                 CF_ADD_ADAFLAGS(-O3)
1592                                 ;;
1593                         esac
1594
1595                         CF_GNAT_GENERICS
1596                         CF_GNAT_SIGINT
1597                         CF_GNAT_PRAGMA_UNREF
1598                         CF_GNAT_PROJECTS
1599
1600                         CF_WITH_ADA_COMPILER
1601
1602                         cf_ada_package=terminal_interface
1603                         AC_SUBST(cf_ada_package)
1604
1605                         CF_WITH_ADA_INCLUDE
1606                         CF_WITH_ADA_OBJECTS
1607                         CF_WITH_ADA_SHAREDLIB
1608                 fi
1609         fi
1610 else
1611         cf_with_ada=no
1612 fi
1613
1614 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1615 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1616 ###
1617 ### ticlib modules may be a separate library, otherwise contained in termlib.
1618 ### termlib modules may be a separate library, otherwise contained in ncurses.
1619 ###
1620 ### The of "+" or " " between the tokens controls the way the script
1621 ### chooses to split module lists into libraries.
1622 ###
1623 ### (see CF_LIB_RULES).
1624 AC_MSG_CHECKING(for library subsets)
1625 LIB_SUBSETS=
1626
1627 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1628         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1629         if test "$with_ticlib" != no ; then
1630                 LIB_SUBSETS="${LIB_SUBSETS} "
1631         else
1632                 LIB_SUBSETS="${LIB_SUBSETS}+"
1633         fi
1634 fi
1635
1636 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1637 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1638
1639 if test "$with_termlib" != no ; then
1640         LIB_SUBSETS="${LIB_SUBSETS} "
1641 else
1642         LIB_SUBSETS="${LIB_SUBSETS}+"
1643 fi
1644
1645 LIB_SUBSETS="${LIB_SUBSETS}base"
1646
1647 # Most term-driver calls are to tinfo, but some like init_pair are to the
1648 # base library (so it resides in base).
1649 if test "$with_term_driver" != no ; then
1650         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1651         case $cf_cv_system_name in #(vi
1652         *mingw32*) #(vi
1653                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1654                 ;;
1655         *) #(vi
1656                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1657                 ;;
1658         esac
1659 fi
1660
1661 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1662 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1663
1664 AC_MSG_RESULT($LIB_SUBSETS)
1665
1666 ### Construct the list of include-directories to be generated
1667 CF_INCLUDE_DIRS
1668 CF_ADA_INCLUDE_DIRS
1669
1670 ### Build up pieces for makefile rules
1671 AC_MSG_CHECKING(default library suffix)
1672 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1673 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1674 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1675
1676 AC_MSG_CHECKING(default library-dependency suffix)
1677 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1678 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1679 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1680
1681 AC_MSG_CHECKING(default object directory)
1682 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1683 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1684 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1685
1686 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1687 if test "$cf_with_cxx" = yes ; then
1688 AC_MSG_CHECKING(c++ library-dependency suffix)
1689 if test "$with_libtool" != "no"; then
1690         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1691 else
1692         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1693 fi
1694 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1695 AC_SUBST(CXX_LIB_SUFFIX)
1696 fi
1697
1698 # do not want -ldl in build except as needed for -lncurses dependency
1699 if test "$with_dlsym" = yes ; then
1700 if test $DFT_LWR_MODEL = shared || \
1701    test $DFT_LWR_MODEL = libtool ; then
1702         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1703 fi
1704 fi
1705 ### Set up low-level terminfo dependencies for makefiles.
1706
1707 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1708 # do not need libdl
1709 TICS_LIST=
1710 if test "$with_dlsym" = yes ; then
1711         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1712 fi
1713
1714 if test "$with_ticlib" != no ; then
1715
1716         if test "$with_ticlib" != yes ; then
1717                 TICS_NAME=$with_ticlib
1718                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1719                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1720                 TICS_LIB_SUFFIX="${with_ticlib}"
1721         else
1722                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1723                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1724                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1725         fi
1726         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1727 else
1728         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1729 fi
1730 AC_SUBST(TICS_ARG_SUFFIX)
1731 AC_SUBST(TICS_DEP_SUFFIX)
1732 AC_SUBST(TICS_LIB_SUFFIX)
1733 AC_SUBST(TICS_ARGS)
1734
1735 if test "$with_termlib" != no ; then
1736
1737         if test "$with_termlib" != yes ; then
1738                 TINFO_NAME=$with_termlib
1739                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1740                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1741                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1742                 TINFO_LIB_SUFFIX="${with_termlib}"
1743         else
1744                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1745                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1746                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1747                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1748         fi
1749
1750         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1751         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1752         if test "$DFT_LWR_MODEL" = "libtool"; then
1753                 TEST_ARGS="${TEST_DEPS}"
1754                 TEST_ARG2="${TEST_DEP2}"
1755                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1756                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1757                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1758         else
1759                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1760                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1761                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1762                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1763                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1764         fi
1765 else
1766         # the next lines are needed for linking libtic over libncurses
1767         TINFO_NAME=${LIB_NAME}
1768         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1769         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1770         if test "$with_tic_depends" = yes ; then
1771                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1772         else
1773                 TICS_LIST="$SHLIB_LIST"
1774         fi
1775
1776         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1777 fi
1778
1779 if test "$DFT_LWR_MODEL" = shared ; then
1780         case $cf_cv_system_name in #(vi
1781         cygwin*)
1782                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1783                 TINFO_SUFFIX=.dll
1784                 ;;
1785         esac
1786 fi
1787
1788 AC_SUBST(TINFO_ARG_SUFFIX)
1789 AC_SUBST(TINFO_DEP_SUFFIX)
1790 AC_SUBST(TINFO_LIB_SUFFIX)
1791 AC_SUBST(TINFO_ARGS)
1792
1793 if test "$with_dlsym" = yes ; then
1794         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1795 fi
1796
1797 if test "$DFT_LWR_MODEL" = "libtool"; then
1798     OBJEXT=lo
1799 fi
1800
1801 # needed for Ada95
1802 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1803 AC_SUBST(TINFO_ARGS2)
1804
1805 case $DFT_LWR_MODEL in
1806 normal|debug|profile)
1807         CF_LDFLAGS_STATIC
1808         ;;
1809 esac
1810
1811 AC_MSG_CHECKING(where we will install curses.h)
1812 test "$with_overwrite" = no && \
1813 test "x$includedir" = 'x${prefix}/include' && \
1814         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1815 AC_MSG_RESULT($includedir)
1816
1817 ### Resolve a conflict between normal and wide-curses by forcing applications
1818 ### that will need libutf8 to add it to their configure script.
1819 if test "$with_overwrite" != no ; then
1820 if test "$NCURSES_LIBUTF8" = 1 ; then
1821         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1822         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1823 fi
1824 fi
1825 WITH_OVERWRITE=$with_overwrite
1826
1827 AC_SUBST(WITH_OVERWRITE)
1828 AC_SUBST(TICS_LIST)
1829 AC_SUBST(TINFO_LIST)
1830 AC_SUBST(SHLIB_LIST)
1831
1832 # used to separate tack out of the tree
1833 NCURSES_TREE=
1834 AC_SUBST(NCURSES_TREE)
1835
1836 ### predefined stuff for the test programs
1837 AC_DEFINE(HAVE_SLK_COLOR)
1838
1839 ### Construct the list of subdirectories for which we'll customize makefiles
1840 ### with the appropriate compile-rules.
1841
1842 CF_SRC_MODULES($modules_to_build)
1843
1844 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1845    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1846    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1847 fi
1848
1849 CF_DIRS_TO_MAKE
1850
1851 # symbols that differ when compiling Ada95 by itself.
1852 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1853 AC_SUBST(NCURSES_SHLIB2)
1854
1855 # values to use as strings
1856 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR')
1857
1858 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1859
1860 ### Now that we're done running tests, add the compiler-warnings, if any
1861 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1862
1863 ### Define substitutions for header files to avoid name-pollution
1864 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1865 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1866 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1867
1868 ################################################################################
1869 test "$use_database" = yes && \
1870 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1871
1872 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1873 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1874
1875 if test x"$enable_pc_files" = xyes ; then \
1876 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1877 MAKE_PC_FILES=
1878 else
1879 MAKE_PC_FILES="#"
1880 fi
1881 AC_SUBST(MAKE_PC_FILES)
1882 AC_SUBST(cross_compiling)
1883
1884 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
1885 if test -n "$FALLBACK_LIST"
1886 then
1887         if test "$TIC_PATH" = unknown
1888         then
1889                 AC_MSG_WARN(no tic program found for fallbacks)
1890         fi
1891 fi
1892 AC_SUBST(TIC_PATH)
1893
1894 if test "x$cf_with_tests" != xno ; then
1895         MAKE_TESTS=
1896 else
1897         MAKE_TESTS="#"
1898 fi
1899 AC_SUBST(MAKE_TESTS)
1900
1901 ADAHTML_DIR=../../doc/html/ada
1902 AC_SUBST(ADAHTML_DIR)
1903
1904 SUB_SCRIPTS=
1905 case $cf_cv_system_name in #(vi
1906 *mingw32*) #(vi
1907         SUB_SCRIPTS="mk-dlls.sh"
1908         ;;
1909 esac
1910
1911 AC_OUTPUT( \
1912         include/MKterm.h.awk \
1913         include/curses.head:include/curses.h.in \
1914         include/ncurses_dll.h \
1915         include/termcap.h \
1916         include/unctrl.h \
1917         $SUB_SCRIPTS \
1918         $SUB_MAKEFILES \
1919         Makefile,[
1920 if test "x$cf_with_tests" != xno ; then
1921         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LINK"], test)
1922 fi
1923 CF_LIB_RULES($SRC_SUBDIRS)
1924
1925 if test "x$cf_with_ada" != xno ; then
1926 if test -z "$USE_OLD_MAKERULES" ; then
1927         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
1928 fi
1929 fi
1930 ],[
1931 ### Special initialization commands, used to pass information from the
1932 ### configuration-run into config.status
1933
1934 AWK="$AWK"
1935 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1936 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1937 ECHO_LINK="$ECHO_LINK"
1938 LDCONFIG="$LDCONFIG"
1939 LIBTOOL_VERSION="$LIBTOOL_VERSION"
1940 LIB_NAME="$LIB_NAME"
1941 LIB_SUBSETS="$LIB_SUBSETS"
1942 LIB_SUFFIX="$LIB_SUFFIX"
1943 LIB_TRACING="$LIB_TRACING"
1944 LN_S="$LN_S"
1945 MAKE_TERMINFO="$MAKE_TERMINFO"
1946 NCURSES_MAJOR="$NCURSES_MAJOR"
1947 NCURSES_MINOR="$NCURSES_MINOR"
1948 NCURSES_OSPEED="$NCURSES_OSPEED"
1949 NCURSES_PATCH="$NCURSES_PATCH"
1950 SRC_SUBDIRS="$SRC_SUBDIRS"
1951 TERMINFO="$TERMINFO"
1952 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1953 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1954 TICS_NAME="$TICS_NAME"
1955 TIC_PATH="$TIC_PATH"
1956 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1957 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1958 TINFO_NAME="$TINFO_NAME"
1959 TINFO_SUFFIX="$TINFO_SUFFIX"
1960 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
1961 WITH_CURSES_H="$with_curses_h"
1962 WITH_ECHO="$with_echo"
1963 WITH_OVERWRITE="$with_overwrite"
1964 cf_LIST_MODELS="$cf_list_models"
1965 cf_cv_abi_version="$cf_cv_abi_version"
1966 cf_cv_do_relink="$cf_cv_do_relink"
1967 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1968 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1969 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1970 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1971 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1972 cf_cv_rel_version="$cf_cv_rel_version"
1973 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1974 cf_cv_shared_soname='$cf_cv_shared_soname'
1975 cf_cv_shlib_version="$cf_cv_shlib_version"
1976 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1977 cf_cv_system_name="$cf_cv_system_name"
1978 cf_with_ada="$cf_with_ada"
1979 cf_with_cxx_binding="$cf_with_cxx_binding"
1980 cf_with_manpages="$cf_with_manpages"
1981 cf_with_tests="$cf_with_tests"
1982 host="$host"
1983 target="$target"
1984
1985 ],cat)dnl
1986 ${MAKE:-make} preinstall