configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2015,2016 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.633 2016/12/11 02:17:55 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.52.20030208)
  38 AC_REVISION($Revision: 1.633 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44 CF_VERSION_INFO(NCURSES,ncurses)
  45
  46 CF_WITH_REL_VERSION(NCURSES)
  47 CF_NCURSES_WITH_ABI_VERSION
  48
  49 CF_WITH_SYSTYPE
  50
  51 ###     Save the given $CFLAGS to allow user-override.
  52 cf_user_CFLAGS="$CFLAGS"
  53
  54 ###     Default install-location
  55 CF_CFG_DEFAULTS
  56 ### Defaults for ncurses ABI
  57 CF_ABI_DEFAULTS
  58
  59 ###     Checks for programs.
  60 AC_ARG_WITH(ada,
  61         [  --without-ada           suppress check for Ada95, don't build demo],
  62         [cf_with_ada=$withval],
  63         [cf_with_ada=yes])
  64 if test "x$cf_with_ada" = xyes
  65 then
  66         cf_PROG_CC="gnatgcc gcc cc"
  67 else
  68         cf_PROG_CC="gcc cc"
  69 fi
  70
  71 CF_PROG_CC($cf_PROG_CC)
  72
  73 AC_PROG_CPP
  74 AC_PROG_GCC_TRADITIONAL
  75 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
  76 CF_PROG_LDCONFIG
  77
  78 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  79 dnl                             configure script by not letting us test if C++
  80 dnl                             is present, making this option necessary.
  81 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  82 AC_ARG_WITH(cxx,
  83         [  --without-cxx           do not adjust ncurses bool to match C++],
  84         [cf_with_cxx=$withval],
  85         [cf_with_cxx=yes])
  86 AC_MSG_RESULT($cf_with_cxx)
  87 if test "X$cf_with_cxx" = Xno ; then
  88         CXX=""
  89         GXX=""
  90 else
  91         # with autoconf 2.13, we can change the error to a warning:
  92         pushdef([AC_MSG_ERROR],
  93                 [AC_MSG_RESULT(no)
  94                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  95                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  96         AC_PROG_CXX
  97         popdef([AC_MSG_ERROR])dnl
  98
  99         AC_LANG_PUSH(C++)
 100         if test "x$cf_with_cxx" != xno
 101         then
 102                 # Several of the C++ configurations do not work, particularly when
 103                 # cross-compiling (20140913 -TD)
 104                 AC_MSG_CHECKING(if $CXX works)
 105
 106                 save_CPPFLAGS="$CPPFLAGS"
 107                 eval cf_includedir=${includedir}
 108                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 109                 AC_TRY_COMPILE([
 110 #include <stdlib.h>
 111 #include <stdio.h>
 112 ],
 113                 [
 114                 printf("Hello world!\n")
 115                 ],
 116                 [cf_cxx_works=yes],
 117                 [cf_cxx_works=no])
 118                 CPPFLAGS="$save_CPPFLAGS"
 119
 120                 AC_MSG_RESULT($cf_cxx_works)
 121                 if test "x$cf_cxx_works" = xno
 122                 then
 123                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 124                         cf_with_cxx=no; CXX=""; GXX="";
 125                 fi
 126         fi
 127         AC_LANG_POP
 128
 129         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 130         if test "$CXX" = "g++" ; then
 131                 AC_PATH_PROG(CXX,g++)
 132         fi
 133         case "x$CXX" in
 134         (x|xg++)
 135                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 136                 cf_with_cxx=no; CXX=""; GXX="";
 137                 ;;
 138         esac
 139 fi
 140
 141 CF_GXX_VERSION
 142 case $GXX_VERSION in
 143 (1*|2.[[0-6]]*)
 144         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 145         # cf_cxx_library=no
 146         AC_MSG_WARN(templates do not work)
 147         ;;
 148 esac
 149
 150 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 151 AC_ARG_WITH(cxx-binding,
 152         [  --without-cxx-binding   do not build C++ binding and demo],
 153         [cf_with_cxx_binding=$withval],
 154         [cf_with_cxx_binding=$cf_with_cxx])
 155 AC_MSG_RESULT($cf_with_cxx_binding)
 156
 157 AC_MSG_CHECKING(if you want to build with Ada95)
 158 AC_MSG_RESULT($cf_with_ada)
 159
 160 AC_MSG_CHECKING(if you want to install terminal database)
 161 AC_ARG_ENABLE(db-install,
 162         [  --disable-db-install    suppress install of terminal database],
 163         [cf_with_db_install=$enableval],
 164         [cf_with_db_install=yes])
 165 AC_MSG_RESULT($cf_with_db_install)
 166
 167 AC_MSG_CHECKING(if you want to install manpages)
 168 AC_ARG_WITH(manpages,
 169         [  --without-manpages      suppress install of manpages],
 170         [cf_with_manpages=$withval],
 171         [cf_with_manpages=yes])
 172 AC_MSG_RESULT($cf_with_manpages)
 173
 174 AC_MSG_CHECKING(if you want to build programs such as tic)
 175 AC_ARG_WITH(progs,
 176         [  --without-progs         suppress build/install with programs (e.g., tic)],
 177         [cf_with_progs=$withval],
 178         [cf_with_progs=yes])
 179 AC_MSG_RESULT($cf_with_progs)
 180
 181 AC_MSG_CHECKING(if you want to build test-programs)
 182 AC_ARG_WITH(tests,
 183         [  --without-tests         suppress build/install with test-programs],
 184         [cf_with_tests=$withval],
 185         [cf_with_tests=yes])
 186 AC_MSG_RESULT($cf_with_tests)
 187
 188 AC_MSG_CHECKING(if you wish to install curses.h)
 189 AC_ARG_WITH(curses-h,
 190         [  --without-curses-h      install curses.h as ncurses.h only],
 191         [with_curses_h=$withval],
 192         [with_curses_h=yes])
 193 AC_MSG_RESULT($with_curses_h)
 194
 195 modules_to_build="ncurses"
 196 if test "X$cf_with_progs" != Xno ; then
 197 modules_to_build="$modules_to_build progs tack"
 198 fi
 199 modules_to_build="$modules_to_build panel menu form"
 200
 201 AC_ARG_PROGRAM
 202
 203 CF_PROG_AWK
 204 CF_PROG_EGREP
 205 CF_PROG_INSTALL
 206 CF_PROG_LINT
 207 CF_PROG_LN_S
 208
 209 AC_SYS_LONG_FILE_NAMES
 210
 211 # if we find pkg-config, check if we should install the ".pc" files.
 212 CF_PKG_CONFIG
 213 CF_WITH_PKG_CONFIG_LIBDIR
 214 CF_ENABLE_PC_FILES
 215 if test -z "$MAKE_PC_FILES"
 216 then
 217         AC_MSG_CHECKING(for suffix to add to pc-files)
 218 AC_ARG_WITH(pc-suffix,
 219         [  --with-pc-suffix        suffixes pc-files],
 220         [case "x$withval" in
 221         (xyes|xno)
 222                 PC_MODULE_SUFFIX=
 223                 ;;
 224         (*)     PC_MODULE_SUFFIX="$withval"
 225                 ;;
 226         esac])
 227         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
 228         AC_MSG_RESULT($PC_MODULE_SUFFIX)
 229         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
 230         AC_SUBST(PC_MODULE_SUFFIX)
 231 fi
 232
 233 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 234 AC_ARG_ENABLE(mixed-case,
 235         [  --enable-mixed-case     tic should assume mixed-case filenames],
 236         [enable_mixedcase=$enableval],
 237         [enable_mixedcase=auto])
 238 AC_MSG_RESULT($enable_mixedcase)
 239 if test "$enable_mixedcase" = "auto" ; then
 240         CF_MIXEDCASE_FILENAMES
 241 else
 242         cf_cv_mixedcase=$enable_mixedcase
 243         if test "x$enable_mixedcase" = "xyes" ; then
 244                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 245         fi
 246 fi
 247
 248 # do this after mixed-case option (tags/TAGS is not as important as tic).
 249 AC_PROG_MAKE_SET
 250 CF_MAKE_TAGS
 251 CF_MAKEFLAGS
 252
 253 dnl These are standard among *NIX systems, but not when cross-compiling
 254 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 255 AC_CHECK_TOOL(LD, ld, ld)
 256 AC_CHECK_TOOL(AR, ar, ar)
 257 AC_CHECK_TOOL(NM, nm, nm)
 258 CF_AR_FLAGS
 259
 260 dnl Special option for use by system-builders: the install-prefix is used to
 261 dnl adjust the location into which the actual install is done, so that an
 262 dnl archive can be built without modifying the host system's configuration.
 263 AC_MSG_CHECKING(if you have specified an install-prefix)
 264 AC_ARG_WITH(install-prefix,
 265         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 266         [case "x$withval" in
 267         (xyes|xno)
 268                 ;;
 269         (*)     DESTDIR="$withval"
 270                 ;;
 271         esac])
 272 AC_MSG_RESULT($DESTDIR)
 273 AC_SUBST(DESTDIR)
 274
 275 ###############################################################################
 276 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 277 # If we're cross-compiling, allow the user to override the tools and their
 278 # options.  The configure script is oriented toward identifying the host
 279 # compiler, etc., but we need a build compiler to generate parts of the source.
 280 CF_BUILD_CC
 281
 282 ###############################################################################
 283 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 284
 285 ### Options to allow the user to specify the set of libraries which are used.
 286 ### Use "--without-normal --with-shared" to allow the default model to be
 287 ### shared, for example.
 288 cf_list_models=""
 289 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 290
 291 CF_WITH_LIBTOOL
 292 if test "$with_libtool" != "no" ; then
 293
 294 cf_list_models="$cf_list_models libtool"
 295
 296 else
 297
 298 AC_MSG_CHECKING(if you want to build shared libraries)
 299 AC_ARG_WITH(shared,
 300         [  --with-shared           generate shared-libraries],
 301         [with_shared=$withval],
 302         [with_shared=no])
 303 AC_MSG_RESULT($with_shared)
 304 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 305
 306 AC_MSG_CHECKING(if you want to build static libraries)
 307 AC_ARG_WITH(normal,
 308         [  --with-normal           generate normal-libraries (default)],
 309         [with_normal=$withval],
 310         [with_normal=yes])
 311 AC_MSG_RESULT($with_normal)
 312 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 313
 314 AC_MSG_CHECKING(if you want to build debug libraries)
 315 AC_ARG_WITH(debug,
 316         [  --with-debug            generate debug-libraries (default)],
 317         [with_debug=$withval],
 318         [with_debug=yes])
 319 AC_MSG_RESULT($with_debug)
 320 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 321
 322 AC_MSG_CHECKING(if you want to build profiling libraries)
 323 AC_ARG_WITH(profile,
 324         [  --with-profile          generate profile-libraries],
 325         [with_profile=$withval],
 326         [with_profile=no])
 327 AC_MSG_RESULT($with_profile)
 328 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 329
 330 fi
 331
 332 if test "X$cf_with_cxx_binding" != Xno; then
 333 if test "x$with_shared" = "xyes"; then
 334 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 335 AC_ARG_WITH(cxx-shared,
 336         [  --with-cxx-shared       generate C++ shared-libraries],
 337         [with_shared_cxx=$withval],
 338         [with_shared_cxx=no])
 339 AC_MSG_RESULT($with_shared_cxx)
 340 fi
 341 fi
 342
 343 ###############################################################################
 344
 345 AC_MSG_CHECKING(for specified models)
 346 test -z "$cf_list_models" && cf_list_models=normal
 347 dnl If we use libtool to generate libraries, then it must be the only
 348 dnl specified model.
 349 test "$with_libtool" != "no" && cf_list_models=libtool
 350 AC_MSG_RESULT($cf_list_models)
 351
 352 ### Use the first model as the default, and save its suffix for use in building
 353 ### up test-applications.
 354 AC_MSG_CHECKING(for default model)
 355 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 356 AC_MSG_RESULT($DFT_LWR_MODEL)
 357
 358 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 359
 360 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 361 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 362
 363 TICS_NAME=tic
 364 AC_SUBST(TICS_NAME)
 365
 366 TINFO_NAME=tinfo
 367 AC_SUBST(TINFO_NAME)
 368
 369 LIB_NAME=ncurses
 370 AC_SUBST(LIB_NAME)
 371
 372 LIB_DIR=../lib
 373 LIB_2ND=../../lib
 374
 375 CF_WITH_LIB_PREFIX(cf_prefix)
 376
 377 LIB_SUFFIX=
 378 AC_SUBST(LIB_SUFFIX)
 379 CF_PATHSEP
 380
 381 ###############################################################################
 382
 383 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 384 AC_ARG_WITH(termlib,
 385         [  --with-termlib          generate separate terminfo library],
 386         [with_termlib=$withval],
 387         [with_termlib=no])
 388 AC_MSG_RESULT($with_termlib)
 389
 390 AC_MSG_CHECKING(if you want to build a separate tic library)
 391 AC_ARG_WITH(ticlib,
 392         [  --with-ticlib           generate separate tic library],
 393         [with_ticlib=$withval],
 394         [with_ticlib=no])
 395 AC_MSG_RESULT($with_ticlib)
 396
 397 ### Checks for special libraries, must be done up-front.
 398 SHLIB_LIST=""
 399 CF_WITH_GPM
 400 if test "$with_gpm" != no ; then
 401         AC_MSG_CHECKING(if you want to load GPM dynamically)
 402         AC_ARG_WITH(dlsym,
 403                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 404                 [with_dlsym=$withval],
 405                 [with_dlsym=yes])
 406         AC_MSG_RESULT($with_dlsym)
 407         if test "x$with_dlsym" = xyes ; then
 408                 CF_FUNC_DLSYM
 409                 if test "x$with_gpm" != xyes ; then
 410                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 411                         cf_cv_gpm_soname="$with_gpm"
 412                 else
 413                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 414                 fi
 415                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 416                 SHLIB_LIST="-ldl $SHLIB_LIST"
 417         else
 418                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 419                 CF_ADD_LIB(gpm,TEST_LIBS)
 420         fi
 421         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 422         CF_CHECK_GPM_WGETCH
 423 fi
 424
 425 CF_WITH_SYSMOUSE
 426
 427 dnl Not all ports of gcc support the -g option
 428
 429 if test X"$CC_G_OPT" = X"" ; then
 430         CC_G_OPT='-g'
 431         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 432 fi
 433 AC_SUBST(CC_G_OPT)
 434
 435 if test X"$CXX_G_OPT" = X"" ; then
 436         CXX_G_OPT='-g'
 437         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 438 fi
 439 AC_SUBST(CXX_G_OPT)
 440
 441 AC_MSG_CHECKING(for default loader flags)
 442 case $DFT_LWR_MODEL in
 443 (libtool) LD_MODEL=''   ;;
 444 (normal)  LD_MODEL=''   ;;
 445 (debug)   LD_MODEL=$CC_G_OPT ;;
 446 (profile) LD_MODEL='-pg';;
 447 (shared)  LD_MODEL=''   ;;
 448 esac
 449 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 450 AC_MSG_RESULT($LD_MODEL)
 451
 452 case $DFT_LWR_MODEL in
 453 (shared)
 454 CF_ENABLE_RPATH
 455 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 456 AC_ARG_ENABLE(relink,
 457 [  --disable-relink        relink shared libraries during install],
 458 [cf_cv_do_relink=$enableval],
 459 [cf_cv_do_relink=yes])
 460 AC_MSG_RESULT($cf_cv_do_relink)
 461         ;;
 462 esac
 463
 464 # we will build libraries one-level down.
 465 rel_builddir=..
 466 CF_SHARED_OPTS
 467 for model in $cf_list_models; do
 468         case $model in
 469         (libtool)
 470                 CF_WITH_LIBTOOL_OPTS
 471                 CF_WITH_EXPORT_SYMS
 472                 ;;
 473         (shared)
 474                 if test "$CC_SHARED_OPTS" = "unknown"; then
 475                         AC_ERROR(Shared libraries are not supported in this version)
 476                 fi
 477                 # workaround for inept transition to PIE vs PIC...
 478                 AC_MSG_CHECKING(if current CFLAGS link properly)
 479                 AC_TRY_LINK(
 480                         [#include <stdio.h>],
 481                         [printf("Hello work\n");],
 482                         [cf_cflags_work=yes],
 483                         [cf_cflags_work=no])
 484                 AC_MSG_RESULT($cf_cflags_work)
 485                 if test "$cf_cflags_work" = no
 486                 then
 487                         CF_VERBOSE(try to work around by appending shared-options)
 488                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
 489                 fi
 490                 CF_WITH_VERSIONED_SYMS
 491                 ;;
 492         esac
 493 done
 494
 495 # pretend that ncurses==ncursesw==ncursest
 496 AC_MSG_CHECKING(if you want to disable library suffixes)
 497 CF_ARG_DISABLE(lib-suffixes,
 498         [  --disable-lib-suffixes  disable library suffixes],
 499         [disable_lib_suffixes=yes],
 500         [disable_lib_suffixes=no],
 501         no)
 502 AC_MSG_RESULT($disable_lib_suffixes)
 503
 504 ### If we're building with rpath, try to link non-standard libs that way too.
 505 if test "$DFT_LWR_MODEL" = "shared"; then
 506         CF_DISABLE_RPATH_HACK
 507 fi
 508
 509 ###############################################################################
 510 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 511
 512 ###     use option --with-extra-suffix to append suffix to headers and libraries
 513 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
 514 EXTRA_SUFFIX=
 515 AC_ARG_WITH(extra-suffix,
 516         [  --with-extra-suffix=X   append extra suffix to header/library paths],
 517         [case x$withval in
 518         (no)
 519                 ;;
 520         (xyes|x)
 521                 EXTRA_SUFFIX=$cf_cv_abi_version
 522                 ;;
 523         (*)
 524                 EXTRA_SUFFIX=$withval
 525                 ;;
 526         esac
 527         ])
 528 AC_MSG_RESULT($EXTRA_SUFFIX)
 529 AC_SUBST(EXTRA_SUFFIX)
 530
 531 ###     use option --disable-overwrite to leave out the link to -lcurses
 532 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 533 AC_ARG_ENABLE(overwrite,
 534         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
 535         [with_overwrite=$enableval],
 536         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 537 AC_MSG_RESULT($with_overwrite)
 538
 539 AC_MSG_CHECKING(if external terminfo-database is used)
 540 AC_ARG_ENABLE(database,
 541         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 542         [use_database=$enableval],
 543         [use_database=yes])
 544 AC_MSG_RESULT($use_database)
 545
 546 case $host_os in
 547 (os2*)
 548         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 549         ;;
 550 (*)
 551         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 552         ;;
 553 esac
 554 AC_SUBST(TERMINFO_SRC)
 555
 556 NCURSES_USE_DATABASE=0
 557 if test "$use_database" != no ; then
 558         NCURSES_USE_DATABASE=1
 559
 560         AC_MSG_CHECKING(which terminfo source-file will be installed)
 561         AC_ARG_WITH(database,
 562                 [  --with-database=XXX     specify terminfo source to install],
 563                 [TERMINFO_SRC=$withval])
 564         AC_MSG_RESULT($TERMINFO_SRC)
 565
 566         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 567         AC_ARG_WITH(hashed-db,
 568                 [  --with-hashed-db        specify hashed-database library],,
 569                 [with_hashed_db=no])
 570         AC_MSG_RESULT($with_hashed_db)
 571 else
 572         with_hashed_db=no
 573 fi
 574 AC_SUBST(NCURSES_USE_DATABASE)
 575
 576 AC_MSG_CHECKING(for list of fallback descriptions)
 577 AC_ARG_WITH(fallbacks,
 578         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 579         [with_fallback=$withval],
 580         [with_fallback=])
 581 AC_MSG_RESULT($with_fallback)
 582 FALLBACK_LIST=`test "$with_fallback" != no && echo "$with_fallback" | sed -e 's/,/ /g'`
 583 AC_SUBST(FALLBACK_LIST)
 584
 585 AC_MSG_CHECKING(if you want modern xterm or antique)
 586 AC_ARG_WITH(xterm-new,
 587         [  --without-xterm-new     specify if xterm terminfo should be old version],
 588         [with_xterm_new=$withval],
 589         [with_xterm_new=yes])
 590 case $with_xterm_new in
 591 (no) with_xterm_new=xterm-old;;
 592 (*)      with_xterm_new=xterm-new;;
 593 esac
 594 AC_MSG_RESULT($with_xterm_new)
 595 WHICH_XTERM=$with_xterm_new
 596 AC_SUBST(WHICH_XTERM)
 597
 598 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 599 AC_ARG_WITH(xterm-kbs,
 600         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
 601         [with_xterm_kbs=$withval],
 602         [with_xterm_kbs=BS])
 603 case x$with_xterm_kbs in
 604 (xyes|xno|xBS|xbs|x8)
 605         with_xterm_kbs=BS
 606         ;;
 607 (xDEL|xdel|x127)
 608         with_xterm_kbs=DEL
 609         ;;
 610 (*)
 611         with_xterm_kbs=$withval
 612         ;;
 613 esac
 614 AC_MSG_RESULT($with_xterm_kbs)
 615 XTERM_KBS=$with_xterm_kbs
 616 AC_SUBST(XTERM_KBS)
 617
 618 MAKE_TERMINFO=
 619 if test "$use_database" = no ; then
 620         TERMINFO="${datadir}/terminfo"
 621         MAKE_TERMINFO="#"
 622 else
 623
 624 AC_MSG_CHECKING(for list of terminfo directories)
 625 CF_WITH_PATHLIST(terminfo-dirs,
 626         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 627         TERMINFO_DIRS,
 628         DATADIR/terminfo,
 629         ${datadir}/terminfo)
 630 AC_MSG_RESULT($TERMINFO_DIRS)
 631 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 632
 633 AC_MSG_CHECKING(for default terminfo directory)
 634 CF_WITH_PATH(default-terminfo-dir,
 635         [  --with-default-terminfo-dir=DIR default terminfo directory],
 636         TERMINFO,
 637         DATADIR/terminfo,
 638         ${datadir}/terminfo)
 639 AC_MSG_RESULT($TERMINFO)
 640 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 641
 642 fi
 643
 644 AC_SUBST(TERMINFO)
 645 AC_SUBST(MAKE_TERMINFO)
 646
 647 ###     use option --disable-big-core to make tic run on small machines
 648 ###     We need 4Mb, check if we can allocate 50% more than that.
 649 AC_MSG_CHECKING(if big-core option selected)
 650 AC_ARG_ENABLE(big-core,
 651         [  --disable-big-core      assume machine has little memory],
 652         [with_big_core=$enableval],
 653         [AC_TRY_RUN([
 654 #include <stdlib.h>
 655 #include <string.h>
 656 int main() {
 657         unsigned long n = 6000000L;
 658         char *s = malloc(n);
 659         if (s != 0)
 660                 s[0] = s[n-1] = 0;
 661         ${cf_cv_main_return:-return}(s == 0);
 662 }],
 663         [with_big_core=yes],
 664         [with_big_core=no],
 665         [with_big_core=no])])
 666 AC_MSG_RESULT($with_big_core)
 667 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 668
 669 ### ISO C only guarantees 512-char strings, we have tables which load faster
 670 ### when constructed using "big" strings.  More than the C compiler, the awk
 671 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 672 AC_MSG_CHECKING(if big-strings option selected)
 673 AC_ARG_ENABLE(big-strings,
 674         [  --disable-big-strings   assume compiler has only standard-size strings],
 675         [with_big_strings=$enableval],
 676         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 677 AC_MSG_RESULT($with_big_strings)
 678
 679 USE_BIG_STRINGS=0
 680 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 681 AC_SUBST(USE_BIG_STRINGS)
 682
 683 ###     use option --enable-termcap to compile in the termcap fallback support
 684 AC_MSG_CHECKING(if you want termcap-fallback support)
 685 AC_ARG_ENABLE(termcap,
 686         [  --enable-termcap        compile in termcap fallback support],
 687         [with_termcap=$enableval],
 688         [with_termcap=no])
 689 AC_MSG_RESULT($with_termcap)
 690
 691 NCURSES_USE_TERMCAP=0
 692 if test "x$with_termcap" != "xyes" ; then
 693         if test "$use_database" = no ; then
 694                 if test -z "$with_fallback" ; then
 695                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 696                 fi
 697         fi
 698         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 699 else
 700
 701         if test "$with_ticlib" != no ; then
 702                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 703         fi
 704
 705         NCURSES_USE_TERMCAP=1
 706         AC_MSG_CHECKING(for list of termcap files)
 707         CF_WITH_PATHLIST(termpath,
 708                 [  --with-termpath=XXX     specify list of termcap files],
 709                 TERMPATH,
 710                 /etc/termcap:/usr/share/misc/termcap)
 711         AC_MSG_RESULT($TERMPATH)
 712         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 713
 714         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 715         AC_MSG_CHECKING(if fast termcap-loader is needed)
 716         AC_ARG_ENABLE(getcap,
 717                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 718                 [with_getcap=$enableval],
 719                 [with_getcap=no])
 720         AC_MSG_RESULT($with_getcap)
 721         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 722
 723         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 724         AC_ARG_ENABLE(getcap-cache,
 725                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 726                 [with_getcap_cache=$enableval],
 727                 [with_getcap_cache=no])
 728         AC_MSG_RESULT($with_getcap_cache)
 729         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 730
 731 fi
 732 AC_SUBST(NCURSES_USE_TERMCAP)
 733
 734 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 735 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 736 AC_ARG_ENABLE(home-terminfo,
 737         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 738         [with_home_terminfo=$enableval],
 739         [with_home_terminfo=yes])
 740 AC_MSG_RESULT($with_home_terminfo)
 741 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 742
 743 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 744 AC_ARG_ENABLE(root-environ,
 745         [  --disable-root-environ  restrict environment when running as root],
 746         [with_root_environ=$enableval],
 747         [with_root_environ=yes])
 748 AC_MSG_RESULT($with_root_environ)
 749 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
 750
 751 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 752 ###   to reduce storage requirements for the terminfo database.
 753 CF_LINK_FUNCS
 754
 755 with_links=no
 756 with_symlinks=no
 757
 758 # soft links (symbolic links) are useful for some systems where hard links do
 759 # not work, or to make it simpler to copy terminfo trees around.
 760 if test "x$ac_cv_func_symlink" = xyes ; then
 761         AC_MSG_CHECKING(if tic should use symbolic links)
 762         AC_ARG_ENABLE(symlinks,
 763         [  --enable-symlinks       make tic use symbolic links not hard links],
 764         [with_symlinks=$enableval],
 765         [with_symlinks=no])
 766         AC_MSG_RESULT($with_symlinks)
 767 fi
 768
 769 # If we have hard links and did not choose to use soft links instead, there is
 770 # no reason to make this choice optional - use the hard links.
 771 if test "$with_symlinks" = no ; then
 772         AC_MSG_CHECKING(if tic should use hard links)
 773         if test "x$ac_cv_func_link" = xyes ; then
 774                 with_links=yes
 775         else
 776                 with_links=no
 777         fi
 778         AC_MSG_RESULT($with_links)
 779 fi
 780
 781 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 782 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 783
 784 ###   use option --enable-broken-linker to force on use of broken-linker support
 785 AC_MSG_CHECKING(if you want broken-linker support code)
 786 AC_ARG_ENABLE(broken_linker,
 787         [  --enable-broken_linker  compile with broken-linker support code],
 788         [with_broken_linker=$enableval],
 789         [with_broken_linker=${BROKEN_LINKER:-no}])
 790 AC_MSG_RESULT($with_broken_linker)
 791
 792 BROKEN_LINKER=0
 793 if test "x$with_broken_linker" = xyes ; then
 794         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
 795         BROKEN_LINKER=1
 796 elif test "$DFT_LWR_MODEL" = shared ; then
 797         case $cf_cv_system_name in
 798         (cygwin*)
 799                 AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
 800                 BROKEN_LINKER=1
 801                 CF_VERBOSE(cygwin linker is broken anyway)
 802                 ;;
 803         esac
 804 fi
 805 AC_SUBST(BROKEN_LINKER)
 806
 807 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 808 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 809 AC_ARG_ENABLE(bsdpad,
 810         [  --enable-bsdpad         recognize BSD-style prefix padding],
 811         [with_bsdpad=$enableval],
 812         [with_bsdpad=no])
 813 AC_MSG_RESULT($with_bsdpad)
 814 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 815
 816 ###   use option --enable-widec to turn on use of wide-character support
 817 NCURSES_CH_T=chtype
 818 NCURSES_LIBUTF8=0
 819
 820 NEED_WCHAR_H=0
 821 NCURSES_MBSTATE_T=0
 822 NCURSES_WCHAR_T=0
 823 NCURSES_WINT_T=0
 824
 825 # Check to define _XOPEN_SOURCE "automatically"
 826 CPPFLAGS_before_XOPEN="$CPPFLAGS"
 827 CF_XOPEN_SOURCE(500)
 828 CPPFLAGS_after_XOPEN="$CPPFLAGS"
 829
 830 # Work around breakage on OS X
 831 CF_SIGWINCH
 832
 833 # Checks for CODESET support.
 834 AM_LANGINFO_CODESET
 835
 836 # use these variables to work around a defect in gcc's fixincludes.
 837 NCURSES_OK_WCHAR_T=
 838 NCURSES_OK_WINT_T=
 839
 840 AC_MSG_CHECKING(if you want wide-character code)
 841 AC_ARG_ENABLE(widec,
 842         [  --enable-widec          compile with wide-char/UTF-8 code],
 843         [with_widec=$enableval],
 844         [with_widec=no])
 845 AC_MSG_RESULT($with_widec)
 846
 847 NCURSES_WCWIDTH_GRAPHICS=1
 848 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
 849
 850 if test "x$with_widec" = xyes ; then
 851         if test "x$disable_lib_suffixes" = xno ; then
 852                 LIB_SUFFIX="w${LIB_SUFFIX}"
 853         fi
 854         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
 855         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
 856
 857         CF_CHECK_WCHAR_H
 858         CF_CHECK_WCWIDTH_GRAPHICS
 859         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
 860
 861         # with_overwrite=no
 862         NCURSES_CH_T=cchar_t
 863         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 864         if test "x$ac_cv_func_putwc" != xyes ; then
 865                 CF_UTF8_LIB
 866                 if test "$cf_cv_utf8_lib" != no ; then
 867                         NCURSES_LIBUTF8=1
 868                 fi
 869         fi
 870         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 871         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 872         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 873
 874         if test "$NCURSES_MBSTATE_T" != 0; then
 875                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 876         fi
 877 fi
 878 AC_SUBST(NCURSES_CH_T)
 879 AC_SUBST(NCURSES_LIBUTF8)
 880
 881 AC_SUBST(NEED_WCHAR_H)
 882 AC_SUBST(NCURSES_MBSTATE_T)
 883 AC_SUBST(NCURSES_WCHAR_T)
 884 AC_SUBST(NCURSES_WINT_T)
 885
 886 AC_SUBST(NCURSES_OK_WCHAR_T)
 887 AC_SUBST(NCURSES_OK_WINT_T)
 888
 889 ###   use option --disable-lp64 to allow long chtype
 890 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 891 AC_ARG_ENABLE(lp64,
 892         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 893         [with_lp64=$enableval],
 894         [with_lp64=$cf_dft_with_lp64])
 895 AC_MSG_RESULT($with_lp64)
 896
 897 if test "x$with_lp64" = xyes ; then
 898         cf_cv_enable_lp64=1
 899 else
 900         cf_cv_enable_lp64=0
 901 fi
 902 AC_SUBST(cf_cv_enable_lp64)
 903
 904 CF_LARGEFILE
 905
 906 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 907 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 908 AC_ARG_ENABLE(tparm-varargs,
 909         [  --disable-tparm-varargs compile tparm() without varargs interface],
 910         [with_tparm_varargs=$enableval],
 911         [with_tparm_varargs=yes])
 912 AC_MSG_RESULT($with_tparm_varargs)
 913 NCURSES_TPARM_VARARGS=0
 914 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
 915 AC_SUBST(NCURSES_TPARM_VARARGS)
 916
 917 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 918 if test "$with_ticlib" != no ; then
 919 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 920 AC_ARG_ENABLE(tic-depends,
 921         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 922         [with_tic_depends=$enableval],
 923         [with_tic_depends=yes])
 924 AC_MSG_RESULT($with_tic_depends)
 925 else
 926         with_tic_depends=no
 927 fi
 928
 929 ###   use option --disable-wattr-macros to suppress wattr* macros from curses.h
 930 AC_MSG_CHECKING(if you want to suppress wattr* macros to help with ncurses5/ncurses6 transition)
 931 AC_ARG_ENABLE(wattr-macros,
 932         [  --disable-wattr-macros  suppress wattr* macros to help with ncurses5/ncurses6 transition],
 933         [with_wattr_macros=$enableval],
 934         [with_wattr_macros=yes])
 935 if [[ "x$with_wattr_macros" != xyes ]]; then
 936         NCURSES_WATTR_MACROS=0
 937         AC_MSG_RESULT(yes)
 938 else
 939         NCURSES_WATTR_MACROS=1
 940         AC_MSG_RESULT(no)
 941 fi
 942 AC_SUBST(NCURSES_WATTR_MACROS)
 943
 944 ###   use option --with-bool to override bool's type
 945 AC_MSG_CHECKING(for type of bool)
 946 AC_ARG_WITH(bool,
 947         [  --with-bool=TYPE        override fallback type of bool variable],
 948         [NCURSES_BOOL="$withval"],
 949         [NCURSES_BOOL=auto])
 950 AC_MSG_RESULT($NCURSES_BOOL)
 951 AC_SUBST(NCURSES_BOOL)
 952
 953 AC_MSG_CHECKING(for alternate terminal capabilities file)
 954 AC_ARG_WITH(caps,
 955         [  --with-caps=alt         compile with alternate Caps file],
 956         [TERMINFO_CAPS=Caps.$withval],
 957         [TERMINFO_CAPS=Caps])
 958 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 959 AC_MSG_RESULT($TERMINFO_CAPS)
 960 AC_SUBST(TERMINFO_CAPS)
 961
 962 ###   use option --with-chtype to override chtype's type
 963 AC_MSG_CHECKING(for type of chtype)
 964 AC_ARG_WITH(chtype,
 965         [  --with-chtype=TYPE      override type of chtype],
 966         [NCURSES_CHTYPE="$withval"],
 967         [NCURSES_CHTYPE=$cf_dft_chtype])
 968 AC_MSG_RESULT($NCURSES_CHTYPE)
 969
 970 ###   use option --with-ospeed to override ospeed's type
 971 AC_MSG_CHECKING(for type of ospeed)
 972 AC_ARG_WITH(ospeed,
 973         [  --with-ospeed=TYPE      override type of ospeed variable],
 974         [NCURSES_OSPEED="$withval"],
 975         [NCURSES_OSPEED=short])
 976 AC_MSG_RESULT($NCURSES_OSPEED)
 977 AC_SUBST(NCURSES_OSPEED)
 978
 979 ###   use option --with-mmask-t to override mmask_t's type
 980 AC_MSG_CHECKING(for type of mmask_t)
 981 AC_ARG_WITH(mmask-t,
 982         [  --with-mmask-t=TYPE     override type of mmask_t],
 983         [NCURSES_MMASK_T="$withval"],
 984         [NCURSES_MMASK_T=$cf_dft_mmask_t])
 985 AC_MSG_RESULT($NCURSES_MMASK_T)
 986
 987 ###   use option --with-ccharw-max to override CCHARW_MAX size
 988 AC_MSG_CHECKING(for size CCHARW_MAX)
 989 AC_ARG_WITH(ccharw-max,
 990         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
 991         [NCURSES_CCHARW_MAX="$withval"],
 992         [NCURSES_CCHARW_MAX=5])
 993 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
 994 AC_SUBST(NCURSES_CCHARW_MAX)
 995
 996 ###   use option --with-tparm-arg to override tparm's argument type
 997 AC_MSG_CHECKING(for type of tparm args)
 998 AC_ARG_WITH(tparm-arg,
 999         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1000         [NCURSES_TPARM_ARG="$withval"],
1001         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1002 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1003 AC_SUBST(NCURSES_TPARM_ARG)
1004
1005 ### Enable compiling-in rcs id's
1006 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1007 AC_ARG_WITH(rcs-ids,
1008         [  --with-rcs-ids          compile-in RCS identifiers],
1009         [with_rcs_ids=$withval],
1010         [with_rcs_ids=no])
1011 AC_MSG_RESULT($with_rcs_ids)
1012 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1013
1014 ###############################################################################
1015 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1016
1017 ###############################################################################
1018 CF_HELP_MESSAGE(Extensions:)
1019
1020 ### Note that some functions (such as const) are normally disabled anyway.
1021 AC_MSG_CHECKING(if you want to build with function extensions)
1022 AC_ARG_ENABLE(ext-funcs,
1023         [  --disable-ext-funcs     disable function-extensions],
1024         [with_ext_funcs=$enableval],
1025         [with_ext_funcs=yes])
1026 AC_MSG_RESULT($with_ext_funcs)
1027 if test "x$with_ext_funcs" = xyes ; then
1028         NCURSES_EXT_FUNCS=1
1029         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function])
1030         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function])
1031         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function])
1032         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function])
1033         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function])
1034         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function])
1035         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function])
1036         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function])
1037         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function])
1038         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function])
1039         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function])
1040         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1041         GENERATED_EXT_FUNCS=generated
1042 else
1043         NCURSES_EXT_FUNCS=0
1044         GENERATED_EXT_FUNCS=
1045 fi
1046 AC_SUBST(NCURSES_EXT_FUNCS)
1047 AC_SUBST(GENERATED_EXT_FUNCS)
1048
1049 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1050 AC_ARG_ENABLE(sp-funcs,
1051         [  --enable-sp-funcs       enable SCREEN-extensions],
1052         [with_sp_funcs=$enableval],
1053         [with_sp_funcs=$cf_dft_ext_spfuncs])
1054 AC_MSG_RESULT($with_sp_funcs)
1055 if test "x$with_sp_funcs" = xyes ; then
1056         NCURSES_SP_FUNCS=1
1057         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1058         GENERATED_SP_FUNCS=generated
1059 else
1060         NCURSES_SP_FUNCS=0
1061         GENERATED_SP_FUNCS=
1062 fi
1063 AC_SUBST(NCURSES_SP_FUNCS)
1064 AC_SUBST(GENERATED_SP_FUNCS)
1065
1066 AC_MSG_CHECKING(if you want to build with terminal-driver)
1067 AC_ARG_ENABLE(term-driver,
1068         [  --enable-term-driver    enable terminal-driver],
1069         [with_term_driver=$enableval],
1070         [with_term_driver=no])
1071 AC_MSG_RESULT($with_term_driver)
1072 if test "x$with_term_driver" = xyes ; then
1073         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1074         if test "x$with_termlib" != xno ; then
1075                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1076         fi
1077         if test "x$with_sp_funcs" != xyes ; then
1078                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1079         fi
1080 fi
1081
1082 ###   use option --enable-const to turn on use of const beyond that in XSI.
1083 AC_MSG_CHECKING(for extended use of const keyword)
1084 AC_ARG_ENABLE(const,
1085         [  --enable-const          compile with extra/non-standard const],
1086         [with_ext_const=$enableval],
1087         [with_ext_const=$cf_dft_ext_const])
1088 AC_MSG_RESULT($with_ext_const)
1089 NCURSES_CONST='/*nothing*/'
1090 if test "x$with_ext_const" = xyes ; then
1091         NCURSES_CONST=const
1092 fi
1093 AC_SUBST(NCURSES_CONST)
1094
1095 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1096 AC_MSG_CHECKING(if you want to use extended colors)
1097 AC_ARG_ENABLE(ext-colors,
1098         [  --enable-ext-colors     compile for 256-color support],
1099         [with_ext_colors=$enableval],
1100         [with_ext_colors=$cf_dft_ext_colors])
1101 AC_MSG_RESULT($with_ext_colors)
1102 NCURSES_EXT_COLORS=0
1103 if test "x$with_ext_colors" = xyes ; then
1104         if test "x$with_widec" != xyes ; then
1105                 AC_MSG_WARN(This option applies only to wide-character library)
1106         else
1107                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1108                 CF_NCURSES_ABI_6
1109                 NCURSES_EXT_COLORS=1
1110                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1111         fi
1112 fi
1113 AC_SUBST(NCURSES_EXT_COLORS)
1114
1115 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1116 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1117 AC_ARG_ENABLE(ext-mouse,
1118         [  --enable-ext-mouse      compile for extended mouse-encoding],
1119         [with_ext_mouse=$enableval],
1120         [with_ext_mouse=$cf_dft_ext_mouse])
1121 AC_MSG_RESULT($with_ext_mouse)
1122 NCURSES_MOUSE_VERSION=1
1123 if test "x$with_ext_mouse" = xyes ; then
1124         NCURSES_MOUSE_VERSION=2
1125         CF_NCURSES_ABI_6
1126 fi
1127 AC_SUBST(NCURSES_MOUSE_VERSION)
1128
1129 ###   use option --enable-ext-putwin to turn on extended screendumps
1130 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1131 AC_ARG_ENABLE(ext-putwin,
1132         [  --enable-ext-putwin     compile with extended putwin/screendump],
1133         [with_ext_putwin=$enableval],
1134         [with_ext_putwin=$cf_dft_ext_putwin])
1135 AC_MSG_RESULT($with_ext_putwin)
1136 if test "x$with_ext_putwin" = xyes ; then
1137         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1138 fi
1139
1140 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1141 AC_ARG_ENABLE(no-padding,
1142         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1143         [with_no_padding=$enableval],
1144         [with_no_padding=$with_ext_funcs])
1145 AC_MSG_RESULT($with_no_padding)
1146 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1147
1148 AC_CHECK_SIZEOF([signed char], 0)
1149 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1150         NCURSES_SBOOL="signed char"
1151 else
1152         NCURSES_SBOOL="char"
1153 fi
1154 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1155 AC_ARG_ENABLE(signed-char,
1156         [  --enable-signed-char    compile using signed Boolean's in term.h],
1157         [with_signed_char=$enableval],
1158         [with_signed_char=no])
1159 AC_MSG_RESULT($with_signed_char)
1160 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1161 AC_SUBST(NCURSES_SBOOL)
1162
1163 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1164 AC_MSG_CHECKING(if you want SIGWINCH handler)
1165 AC_ARG_ENABLE(sigwinch,
1166         [  --enable-sigwinch       compile with SIGWINCH handler],
1167         [with_sigwinch=$enableval],
1168         [with_sigwinch=$with_ext_funcs])
1169 AC_MSG_RESULT($with_sigwinch)
1170 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1171
1172 ###   use option --enable-tcap-names to allow user to define new capabilities
1173 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1174 AC_ARG_ENABLE(tcap-names,
1175         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1176         [with_tcap_names=$enableval],
1177         [with_tcap_names=$with_ext_funcs])
1178 AC_MSG_RESULT($with_tcap_names)
1179 NCURSES_XNAMES=0
1180 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1181 AC_SUBST(NCURSES_XNAMES)
1182
1183 ###############################################################################
1184 # These options are relatively safe to experiment with.
1185 CF_HELP_MESSAGE(Development Code:)
1186 AC_MSG_CHECKING(if you want all development code)
1187 AC_ARG_WITH(develop,
1188         [  --without-develop       disable development options],
1189         [with_develop=$withval],
1190         [with_develop=no])
1191 AC_MSG_RESULT($with_develop)
1192
1193 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1194 AC_MSG_CHECKING(if you want hard-tabs code)
1195 AC_ARG_ENABLE(hard-tabs,
1196         [  --enable-hard-tabs      compile with hard-tabs code],,
1197         [enable_hard_tabs=$with_develop])
1198 AC_MSG_RESULT($enable_hard_tabs)
1199 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1200
1201 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1202 AC_MSG_CHECKING(if you want limited support for xmc)
1203 AC_ARG_ENABLE(xmc-glitch,
1204         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1205         [enable_xmc_glitch=$with_develop])
1206 AC_MSG_RESULT($enable_xmc_glitch)
1207 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1208
1209 ###############################################################################
1210 # These are just experimental, probably should not be in a package:
1211 CF_HELP_MESSAGE(Experimental Code:)
1212
1213 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1214 AC_ARG_ENABLE(assumed-color,
1215         [  --disable-assumed-color do not assume anything about default-colors],
1216         [with_assumed_color=$enableval],
1217         [with_assumed_color=yes])
1218 AC_MSG_RESULT($with_assumed_color)
1219 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1220
1221 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1222 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1223 AC_ARG_ENABLE(hashmap,
1224         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1225         [with_hashmap=$enableval],
1226         [with_hashmap=yes])
1227 AC_MSG_RESULT($with_hashmap)
1228 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1229
1230 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1231 AC_MSG_CHECKING(if you want colorfgbg code)
1232 AC_ARG_ENABLE(colorfgbg,
1233         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1234         [with_colorfgbg=$enableval],
1235         [with_colorfgbg=no])
1236 AC_MSG_RESULT($with_colorfgbg)
1237 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1238
1239 ###   use option --enable-interop to turn on use of bindings used for interop
1240 AC_MSG_CHECKING(if you want interop bindings)
1241 AC_ARG_ENABLE(interop,
1242         [  --enable-interop        compile-in interop bindings],
1243         [with_exp_interop=$enableval],
1244         [with_exp_interop=$cf_dft_interop])
1245 AC_MSG_RESULT($with_exp_interop)
1246
1247 NCURSES_INTEROP_FUNCS=0
1248 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1249 AC_SUBST(NCURSES_INTEROP_FUNCS)
1250
1251 # This is still experimental (20080329), but should ultimately be moved to
1252 # the script-block --with-normal, etc.
1253 CF_WITH_PTHREAD
1254
1255 if test "x$with_pthread" != xno; then
1256         AC_CHECK_FUNC(pthread_kill,[
1257                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1258                 AC_ARG_ENABLE(pthreads-eintr,
1259                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1260                         [use_pthreads_eintr=$enableval],
1261                         [use_pthreads_eintr=no])
1262                 AC_MSG_RESULT($use_pthreads_eintr)
1263                 if test "x$use_pthreads_eintr" = xyes ; then
1264                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1265                 fi])
1266
1267         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1268         AC_ARG_ENABLE(weak-symbols,
1269                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1270                 [use_weak_symbols=$enableval],
1271                 [use_weak_symbols=no])
1272         AC_MSG_RESULT($use_weak_symbols)
1273         if test "x$use_weak_symbols" = xyes ; then
1274                 CF_WEAK_SYMBOLS
1275         else
1276                 cf_cv_weak_symbols=no
1277         fi
1278
1279         if test "x$cf_cv_weak_symbols" = xyes ; then
1280                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1281         fi
1282 fi
1283
1284 PTHREAD=
1285 if test "x$with_pthread" = "xyes" ; then
1286         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1287         enable_reentrant=yes
1288         if test "x$cf_cv_weak_symbols" = xyes ; then
1289                 PTHREAD=-lpthread
1290         fi
1291 fi
1292 AC_SUBST(PTHREAD)
1293
1294 # Reentrant code has to be opaque; there's little advantage to making ncurses
1295 # opaque outside of that, so there is no --enable-opaque option.  We can use
1296 # this option without --with-pthreads, but this will be always set for
1297 # pthreads.
1298 AC_MSG_CHECKING(if you want reentrant code)
1299 AC_ARG_ENABLE(reentrant,
1300         [  --enable-reentrant      compile with reentrant code],
1301         [with_reentrant=$enableval],
1302         [with_reentrant=no])
1303 AC_MSG_RESULT($with_reentrant)
1304 if test "x$with_reentrant" = xyes ; then
1305         cf_cv_enable_reentrant=1
1306         cf_cv_enable_opaque="NCURSES_INTERNALS"
1307         NCURSES_OPAQUE=1
1308         NCURSES_SIZE_T=int
1309         if test "x$cf_cv_weak_symbols" = xyes ; then
1310                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1311                 CF_ADD_LIB(pthread,TEST_LIBS)
1312                 CF_ADD_LIB(pthread,TEST_LIBS2)
1313         else
1314                 # when not using weak symbols but with_reentrant,
1315                 # add 't' to the library suffix on all platforms
1316                 # except cygwin, where we only do that if ALSO
1317                 # compiling with full thread support.
1318                 case "$host" in
1319                 (*cygwin* | *msys*)
1320                         if test "$with_pthread" = "yes" ; then
1321                                 if test "x$disable_lib_suffixes" = "xno" ; then
1322                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1323                                 fi
1324                         fi ;;
1325                 (*)
1326                         if test "x$disable_lib_suffixes" = "xno" ; then
1327                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1328                         fi
1329                         ;;
1330                 esac
1331         fi
1332         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1333         CF_NCURSES_ABI_6
1334 else
1335         cf_cv_enable_reentrant=0
1336         cf_cv_enable_opaque="NCURSES_OPAQUE"
1337         NCURSES_OPAQUE=0
1338         NCURSES_SIZE_T=short
1339 fi
1340 AC_SUBST(cf_cv_enable_reentrant)
1341 AC_SUBST(cf_cv_enable_opaque)
1342 AC_SUBST(NCURSES_OPAQUE)
1343 AC_SUBST(NCURSES_SIZE_T)
1344
1345 ### Allow using a different wrap-prefix
1346 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1347         AC_MSG_CHECKING(for prefix used to wrap public variables)
1348         AC_ARG_WITH(wrap-prefix,
1349                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1350                 [NCURSES_WRAP_PREFIX=$withval],
1351                 [NCURSES_WRAP_PREFIX=_nc_])
1352         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1353 else
1354         NCURSES_WRAP_PREFIX=_nc_
1355 fi
1356 AC_SUBST(NCURSES_WRAP_PREFIX)
1357 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1358
1359 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1360 AC_ARG_ENABLE(safe-sprintf,
1361         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1362         [with_safe_sprintf=$enableval],
1363         [with_safe_sprintf=no])
1364 AC_MSG_RESULT($with_safe_sprintf)
1365 test "x$with_safe_sprintf" = xyes && AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1366
1367 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1368 # when hashmap is used scroll hints are useless
1369 if test "$with_hashmap" = no ; then
1370 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1371 AC_ARG_ENABLE(scroll-hints,
1372         [  --disable-scroll-hints  compile without scroll-hints code],
1373         [with_scroll_hints=$enableval],
1374         [with_scroll_hints=yes])
1375 AC_MSG_RESULT($with_scroll_hints)
1376 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1377 fi
1378
1379 AC_MSG_CHECKING(if you want wgetch-events code)
1380 AC_ARG_ENABLE(wgetch-events,
1381         [  --enable-wgetch-events  compile with wgetch-events code],
1382         [with_wgetch_events=$enableval],
1383         [with_wgetch_events=no])
1384 AC_MSG_RESULT($with_wgetch_events)
1385 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1386
1387 ###############################################################################
1388 CF_HELP_MESSAGE(Testing/development Options:)
1389
1390 ###     use option --disable-echo to suppress full display compiling commands
1391 CF_DISABLE_ECHO
1392 if test "x$enable_echo" = xyes; then
1393         ECHO_LINK=
1394 else
1395         ECHO_LINK='@ echo linking $@ ... ;'
1396         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1397         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1398 fi
1399 AC_SUBST(ECHO_LINK)
1400
1401 ###     use option --enable-warnings to turn on all gcc warnings
1402 AC_MSG_CHECKING(if you want to see compiler warnings)
1403 AC_ARG_ENABLE(warnings,
1404         [  --enable-warnings       build: turn on GCC compiler warnings],
1405         [with_warnings=$enableval])
1406 AC_MSG_RESULT($with_warnings)
1407
1408 if test "x$with_warnings" = "xyes"; then
1409         CF_ADD_ADAFLAGS(-gnatg)
1410         CF_GCC_WARNINGS(Wno-unknown-pragmas Wswitch-enum)
1411         if test "x$cf_with_cxx" = xyes ; then
1412                 CF_GXX_WARNINGS(Wno-unused)
1413         fi
1414 fi
1415 CF_GCC_ATTRIBUTES
1416 CF_ENABLE_STRING_HACKS
1417
1418 ###     use option --enable-assertions to turn on generation of assertion code
1419 AC_MSG_CHECKING(if you want to enable runtime assertions)
1420 AC_ARG_ENABLE(assertions,
1421         [  --enable-assertions     test: turn on generation of assertion code],
1422         [with_assertions=$enableval],
1423         [with_assertions=no])
1424 AC_MSG_RESULT($with_assertions)
1425 if test -n "$GCC"
1426 then
1427         if test "$with_assertions" = no
1428         then
1429                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1430         else
1431                 CF_ADD_ADAFLAGS(-gnata)
1432         fi
1433 fi
1434
1435 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1436 CF_DISABLE_LEAKS
1437 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1438
1439 ###     use option --enable-expanded to generate certain macros as functions
1440 AC_ARG_ENABLE(expanded,
1441         [  --enable-expanded       test: generate functions for certain macros],
1442         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1443
1444 ###     use option --disable-macros to suppress macros in favor of functions
1445 AC_ARG_ENABLE(macros,
1446         [  --disable-macros        test: use functions rather than macros],
1447         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1448
1449 # Normally we only add trace() to the debug-library.  Allow this to be
1450 # extended to all models of the ncurses library:
1451 cf_all_traces=no
1452 case "$CFLAGS $CPPFLAGS" in
1453 (*-DTRACE*)
1454         cf_all_traces=yes
1455         ;;
1456 esac
1457
1458 AC_MSG_CHECKING(whether to add trace feature to all models)
1459 AC_ARG_WITH(trace,
1460 [  --with-trace            test: add trace() function to all models of ncurses],
1461 [cf_with_trace=$withval],
1462 [cf_with_trace=$cf_all_traces])
1463 AC_MSG_RESULT($cf_with_trace)
1464
1465 if test "x$cf_with_trace" = xyes ; then
1466         LIB_TRACING=all
1467         ADA_TRACE=TRUE
1468         CF_ADD_CFLAGS(-DTRACE)
1469 else
1470         LIB_TRACING=DEBUG
1471         ADA_TRACE=FALSE
1472 fi
1473
1474 AC_SUBST(ADA_TRACE)
1475
1476 CF_DISABLE_GNAT_PROJECTS
1477
1478 ###     Checks for libraries.
1479 case $cf_cv_system_name in
1480 (*mingw32*|*mingw64*)
1481         CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1482         LIBS=" -lpsapi $LIBS"
1483         ;;
1484 (*)
1485 AC_CHECK_FUNC(gettimeofday,
1486         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1487
1488 AC_CHECK_LIB(bsd, gettimeofday,
1489         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1490         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1491         ;;
1492 esac
1493
1494 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1495 AC_SUBST(MATH_LIB)
1496
1497 ###     Checks for header files.
1498 AC_STDC_HEADERS
1499 AC_HEADER_DIRENT
1500 AC_HEADER_TIME
1501 CF_REGEX
1502
1503 dnl These are some other potentially nonportable headers.
1504 AC_CHECK_HEADERS( \
1505 fcntl.h \
1506 getopt.h \
1507 limits.h \
1508 locale.h \
1509 math.h \
1510 poll.h \
1511 sys/bsdtypes.h \
1512 sys/ioctl.h \
1513 sys/param.h \
1514 sys/poll.h \
1515 sys/select.h \
1516 sys/time.h \
1517 sys/times.h \
1518 ttyent.h \
1519 unistd.h \
1520 wctype.h \
1521 )
1522
1523 CF_GETOPT_HEADER
1524
1525 # check for ISC (this may also define _POSIX_SOURCE)
1526 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1527 if test "x$ISC" = xyes ; then
1528         AC_CHECK_LIB(cposix,main)
1529         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1530 fi
1531
1532 CF_SYS_TIME_SELECT
1533
1534 ###     checks for compiler characteristics
1535 AC_LANG_C
1536 AC_C_CONST
1537 CF_C_INLINE(NCURSES_INLINE,1200)
1538 CF_SIG_ATOMIC_T
1539
1540 if test $NCURSES_CHTYPE = auto ; then
1541         CF_TYPEOF_CHTYPE
1542 else
1543         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1544 fi
1545 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1546 AC_SUBST(cf_cv_typeof_chtype)
1547
1548 CF_UNSIGNED_LITERALS
1549 cf_cv_1UL="1"
1550 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1551 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1552 AC_SUBST(cf_cv_1UL)
1553
1554 if test $NCURSES_MMASK_T = auto ; then
1555         cf_cv_typeof_mmask_t=long
1556 else
1557         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1558 fi
1559 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1560 AC_SUBST(cf_cv_typeof_mmask_t)
1561
1562 ###     Checks for external-data
1563 CF_ERRNO
1564 CF_LINK_DATAONLY
1565
1566 ###     Checks for library functions.
1567 AC_CHECK_FUNCS( \
1568 getcwd \
1569 getegid \
1570 geteuid \
1571 getopt \
1572 getttynam \
1573 issetugid \
1574 poll \
1575 putenv \
1576 remove \
1577 select \
1578 setbuf \
1579 setbuffer \
1580 setenv \
1581 setvbuf \
1582 sigaction \
1583 sigvec \
1584 strdup \
1585 strstr \
1586 tcgetpgrp \
1587 times \
1588 vsnprintf \
1589 )
1590
1591 if test "x$ac_cv_func_getopt" = xno &&
1592    test "x$cf_with_progs$cf_with_tests" != xnono; then
1593         AC_MSG_ERROR(getopt is required for building programs)
1594 fi
1595
1596 if test "x$with_getcap" = "xyes" ; then
1597         CF_CGETENT
1598 fi
1599
1600 CF_ISASCII
1601 CF_STRUCT_SIGACTION
1602 CF_FUNC_NANOSLEEP
1603 CF_FUNC_TERMIOS
1604 CF_FUNC_VSSCANF
1605 CF_MKSTEMP
1606
1607 # setup for prototype of fallback for vsscanf()
1608 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1609
1610 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1611 if test "x$cross_compiling" = xyes ; then
1612         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1613 else
1614         AC_FUNC_SETVBUF_REVERSED
1615 fi
1616 AC_CHECK_TYPE(intptr_t, long)
1617 AC_CHECK_TYPE(ssize_t, int)
1618 CF_TYPE_SIGACTION
1619 CF_SIZECHANGE
1620 CF_FUNC_MEMMOVE
1621 CF_FUNC_POLL
1622 CF_VA_COPY
1623 AC_FUNC_VFORK
1624
1625 # special check for test/ditto.c
1626 CF_FUNC_OPENPTY
1627 if test "$cf_cv_func_openpty" != no ; then
1628         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1629         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1630         if test "x$cf_cv_lib_util" = xyes ; then
1631                 CF_ADD_LIB(util,TEST_LIBS)
1632         fi
1633 fi
1634 AC_SUBST(TEST_LIBS)
1635 AC_SUBST(TEST_LIBS2)
1636
1637 if test "$with_hashed_db" != no ; then
1638         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1639         CF_HASHED_DB($with_hashed_db)
1640 fi
1641
1642 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1643 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1644         CF_STRIP_G_OPT(CFLAGS)
1645         CF_STRIP_G_OPT(CXXFLAGS)
1646 fi
1647
1648 # Just in case, check if the C compiler has a bool type.
1649 CF_BOOL_DECL(cf_cv_cc_bool_type)
1650
1651 # Check for C++ compiler characteristics (and ensure that it's there!)
1652 if test -n "$CXX" ; then
1653         AC_LANG_CPLUSPLUS
1654         CF_STDCPP_LIBRARY
1655         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1656
1657         case $GXX_VERSION in
1658         (1*|2.[0-6]*)
1659                 cf_cxx_library=yes
1660                 ;;
1661         (*-2.7*|2.7*)
1662                 CF_GPP_LIBRARY
1663                 ;;
1664         (*)
1665                 cf_cxx_library=no
1666                 ;;
1667         esac
1668
1669         AC_CHECK_HEADERS(typeinfo)
1670         CF_CXX_IOSTREAM_NAMESPACE
1671         CF_BOOL_DECL
1672         CF_BOOL_SIZE
1673         CF_ETIP_DEFINES
1674         CF_CPP_PARAM_INIT
1675         CF_CPP_STATIC_CAST
1676         CF_CXX_AR_FLAGS
1677 else
1678         cf_cxx_library=no
1679         cf_cv_builtin_bool=1
1680
1681         # Just because we are not configuring against C++ right now does not
1682         # mean that a user will not want to use C++.  Some distributors disable
1683         # the C++ portion of this configuration as a shortcut (or just to avoid
1684         # compiling the demo in the c++ directory).  So we need a reasonable
1685         # default for the 'bool' type.
1686         #
1687         # Caveat: since the storage of the bool type is not standardized, it
1688         # may change.
1689
1690         if test "$NCURSES_BOOL" != auto ; then
1691                 cf_cv_type_of_bool=$NCURSES_BOOL
1692                 cf_cv_header_stdbool_h=0
1693         else
1694                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1695                         CF_BOOL_SIZE
1696                 else
1697                         AC_MSG_CHECKING(for fallback type of bool)
1698                         case "$host_cpu" in
1699                         (i?86)  cf_cv_type_of_bool=char ;;
1700                         (*)     cf_cv_type_of_bool=int  ;;
1701                         esac
1702                         AC_MSG_RESULT($cf_cv_type_of_bool)
1703                 fi
1704         fi
1705 fi
1706 AC_SUBST(CXXLIBS)
1707
1708 # If the C compiler did not declare bool, and we did not determine that the C++
1709 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1710 # ncurses library use the same type as C++ bool.  Note that this allows one to
1711 # specify the type of bool in a configure-script option and postpone
1712 # integration with the C++ compiler provided that the types are compatible.
1713 USE_CXX_BOOL=1
1714 if test $cf_cv_cc_bool_type = 1
1715 then
1716         # oops: C has a bool.  Unlikely, but C++ could differ.
1717         USE_CXX_BOOL=0
1718 elif test $cf_cv_builtin_bool = 0
1719 then
1720         # C++ has no bool
1721         USE_CXX_BOOL=0
1722 else
1723         # this is the normal case
1724         USE_CXX_BOOL='defined(__cplusplus)'
1725 fi
1726 AC_SUBST(USE_CXX_BOOL)
1727
1728 CF_HELP_MESSAGE(Ada95 Binding Options:)
1729
1730 dnl If the Ada95 source-tree is present, add that to the build unless it will
1731 dnl not work, or was not requested.
1732 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1733
1734 dnl libtool does not know anything about GNAT, though a change made in 1998
1735 dnl provided for it "someday".  Disable the ada subtree if we are using
1736 dnl libtool -TD 20070714
1737         if test "$cf_with_ada" != "no" ; then
1738                 if test "$with_libtool" != "no"; then
1739                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1740                         cf_with_ada=no
1741                 fi
1742         fi
1743
1744 dnl Check for availability of GNU Ada Translator (GNAT).
1745 dnl At the moment we support no other Ada95 compiler.
1746         if test "$cf_with_ada" != "no" ; then
1747                 CF_PROG_GNAT
1748                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1749                         CF_ADD_ADAFLAGS(-gnatpn)
1750                         CF_FIXUP_ADAFLAGS
1751
1752                         CF_GNATPREP_OPT_T
1753
1754                         CF_GNAT_GENERICS
1755                         CF_GNAT_SIGINT
1756                         CF_GNAT_PROJECTS
1757
1758                         CF_WITH_ADA_COMPILER
1759
1760                         cf_ada_package=terminal_interface
1761                         AC_SUBST(cf_ada_package)
1762
1763                         CF_WITH_ADA_INCLUDE
1764                         CF_WITH_ADA_OBJECTS
1765                         CF_WITH_ADA_SHAREDLIB
1766                 fi
1767         fi
1768 else
1769         cf_with_ada=no
1770 fi
1771
1772 # do this "late" to avoid conflict with header-checks
1773 if test "x$with_widec" = xyes ; then
1774         AC_CHECK_SIZEOF(wchar_t)
1775 fi
1776
1777 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1778 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1779 ###
1780 ### ticlib modules may be a separate library, otherwise contained in termlib.
1781 ### termlib modules may be a separate library, otherwise contained in ncurses.
1782 ###
1783 ### The of "+" or " " between the tokens controls the way the script
1784 ### chooses to split module lists into libraries.
1785 ###
1786 ### (see CF_LIB_RULES).
1787 AC_MSG_CHECKING(for library subsets)
1788 LIB_SUBSETS=
1789
1790 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1791         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1792         if test "$with_ticlib" != no ; then
1793                 LIB_SUBSETS="${LIB_SUBSETS} "
1794         else
1795                 LIB_SUBSETS="${LIB_SUBSETS}+"
1796         fi
1797 fi
1798
1799 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1800 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1801
1802 if test "$with_termlib" != no ; then
1803         LIB_SUBSETS="${LIB_SUBSETS} "
1804 else
1805         LIB_SUBSETS="${LIB_SUBSETS}+"
1806 fi
1807
1808 LIB_SUBSETS="${LIB_SUBSETS}base"
1809
1810 # Most term-driver calls are to tinfo, but some like init_pair are to the
1811 # base library (so it resides in base).
1812 if test "$with_term_driver" != no ; then
1813         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1814         case $cf_cv_system_name in
1815         (*mingw32*|*mingw64*)
1816                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1817                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
1818                 ;;
1819         (*)
1820                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1821                 ;;
1822         esac
1823 fi
1824
1825 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1826 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1827
1828 AC_MSG_RESULT($LIB_SUBSETS)
1829
1830 ### Construct the list of include-directories to be generated
1831 CF_INCLUDE_DIRS
1832 CF_ADA_INCLUDE_DIRS
1833
1834 ### Build up pieces for makefile rules
1835 AC_MSG_CHECKING(default library suffix)
1836 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1837 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1838 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1839
1840 AC_MSG_CHECKING(default library-dependency suffix)
1841 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1842 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1843 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1844
1845 AC_MSG_CHECKING(default object directory)
1846 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1847 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1848 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1849
1850 if test "x$cf_with_cxx" = xyes ; then
1851 AC_MSG_CHECKING(c++ library-dependency suffix)
1852 if test "$with_libtool" != "no"; then
1853         # libtool thinks it can make c++ shared libraries (perhaps only g++)
1854         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1855 elif test "$with_shared_cxx" != "no"; then
1856         # also for g++ users...
1857         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1858 else
1859         # we normally make a static library because C/C++ library rules differ
1860         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
1861 fi
1862 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1863 AC_SUBST(CXX_LIB_SUFFIX)
1864 fi
1865
1866 # do not want -ldl in build except as needed for -lncurses dependency
1867 if test "x$with_dlsym" = xyes ; then
1868 if test $DFT_LWR_MODEL = shared || \
1869    test $DFT_LWR_MODEL = libtool ; then
1870         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1871 fi
1872 fi
1873 ### Set up low-level terminfo dependencies for makefiles.
1874
1875 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1876 # do not need libdl
1877 TICS_LIST=
1878 if test "x$with_dlsym" = xyes ; then
1879         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1880 fi
1881
1882 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
1883 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
1884 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
1885 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
1886 then
1887         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
1888 fi
1889 AC_SUBST(USE_ARG_SUFFIX)
1890 AC_SUBST(USE_CFG_SUFFIX)
1891 AC_SUBST(USE_LIB_SUFFIX)
1892
1893 if test "$with_ticlib" != no ; then
1894
1895         if test "x$with_ticlib" != xyes ; then
1896                 TICS_NAME=$with_ticlib
1897                 TICS_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
1898                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1899                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1900                 TICS_LIB_SUFFIX="${with_ticlib}"
1901         else
1902                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
1903                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
1904                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1905                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
1906         fi
1907         TICS_LDFLAGS="-L${LIB_DIR}"
1908         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
1909 else
1910         TICS_SUFFIX=${DFT_LIB_SUFFIX}
1911         TICS_LDFLAGS="-L${LIB_DIR}"
1912         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
1913 fi
1914 AC_SUBST(TICS_ARG_SUFFIX)
1915 AC_SUBST(TICS_DEP_SUFFIX)
1916 AC_SUBST(TICS_LIB_SUFFIX)
1917 AC_SUBST(TICS_LDFLAGS)
1918 AC_SUBST(TICS_LIBS)
1919
1920 if test "$with_termlib" != no ; then
1921
1922         if test "x$with_termlib" != xyes ; then
1923                 TINFO_NAME=$with_termlib
1924                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
1925                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1926                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1927                 TINFO_LIB_SUFFIX="${with_termlib}"
1928         else
1929                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1930                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
1931                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1932                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
1933         fi
1934
1935         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1936         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1937         if test "$DFT_LWR_MODEL" = "libtool"; then
1938                 TEST_ARGS="${TEST_DEPS}"
1939                 TEST_ARG2="${TEST_DEP2}"
1940                 TINFO_LDFLAGS="-L${LIB_DIR}"
1941                 TINFO_LIBS="$TEST_ARGS"
1942                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1943                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1944         else
1945                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1946                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1947                 if test "x$with_term_driver" != xno ; then
1948                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
1949                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
1950                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
1951                 else
1952                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1953                         TINFO_LIBS="$TEST_ARGS"
1954                 fi
1955                 TINFO_LDFLAGS="-L${LIB_DIR}"
1956                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1957         fi
1958 else
1959         # the next lines are needed for linking libtic over libncurses
1960         TINFO_NAME=${LIB_NAME}
1961         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1962         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
1963         if test "x$with_tic_depends" = xyes ; then
1964                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
1965         else
1966                 TICS_LIST="$SHLIB_LIST"
1967         fi
1968
1969         TINFO_LDFLAGS="-L${LIB_DIR}"
1970         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
1971 fi
1972
1973 if test "$DFT_LWR_MODEL" = shared ; then
1974         case $cf_cv_system_name in
1975         (cygwin*|msys*)
1976                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
1977                 TINFO_SUFFIX=.dll
1978                 ;;
1979         esac
1980 fi
1981
1982 AC_SUBST(TINFO_ARG_SUFFIX)
1983 AC_SUBST(TINFO_DEP_SUFFIX)
1984 AC_SUBST(TINFO_LIB_SUFFIX)
1985 AC_SUBST(TINFO_LDFLAGS)
1986 AC_SUBST(TINFO_LIBS)
1987
1988 if test "x$with_dlsym" = xyes ; then
1989         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1990 fi
1991
1992 if test "$DFT_LWR_MODEL" = "libtool"; then
1993         OBJEXT=lo
1994 fi
1995
1996 # needed for Ada95
1997 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
1998 AC_SUBST(TINFO_LDFLAGS2)
1999
2000 case $DFT_LWR_MODEL in
2001 (normal|debug|profile)
2002         CF_LDFLAGS_STATIC
2003         ;;
2004 esac
2005
2006 AC_MSG_CHECKING(where we will install curses.h)
2007 AC_SUBST(includesubdir)
2008 includesubdir=
2009 if test "$with_overwrite" = no && \
2010  ( test "x$includedir" = 'x${prefix}/include' || \
2011    test "x$includedir" = "x${prefix}/include" )
2012 then
2013         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2014 fi
2015 AC_MSG_RESULT(${includedir}${includesubdir})
2016
2017 ### Resolve a conflict between normal and wide-curses by forcing applications
2018 ### that will need libutf8 to add it to their configure script.
2019 if test "$with_overwrite" != no ; then
2020 if test "$NCURSES_LIBUTF8" = 1 ; then
2021         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2022         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2023 fi
2024 fi
2025 WITH_OVERWRITE=$with_overwrite
2026
2027 AC_SUBST(WITH_OVERWRITE)
2028 AC_SUBST(TICS_LIST)
2029 AC_SUBST(TINFO_LIST)
2030 AC_SUBST(SHLIB_LIST)
2031
2032 # used to separate tack out of the tree
2033 NCURSES_TREE=
2034 AC_SUBST(NCURSES_TREE)
2035
2036 ### predefined stuff for the test programs
2037 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2038
2039 ### Construct the list of subdirectories for which we'll customize makefiles
2040 ### with the appropriate compile-rules.
2041
2042 CF_SRC_MODULES($modules_to_build)
2043
2044 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2045    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2046    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2047 fi
2048
2049 CF_DIRS_TO_MAKE
2050
2051 # symbols that differ when compiling Ada95 by itself.
2052 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2053 AC_SUBST(NCURSES_SHLIB2)
2054
2055 # values to use as strings
2056 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2057
2058 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2059
2060 ### Now that we're done running tests, add the compiler-warnings, if any
2061 CF_ADD_CFLAGS($EXTRA_CFLAGS)
2062
2063 ### Define substitutions for header files to avoid name-pollution
2064 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2065 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2066 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2067 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2068
2069 ################################################################################
2070 test "x$use_database" = xyes && \
2071 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2072
2073 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2074 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2075
2076 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2077 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2078 fi
2079 AC_SUBST(cross_compiling)
2080
2081 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
2082 if test -n "$FALLBACK_LIST"
2083 then
2084         if test "$TIC_PATH" = unknown
2085         then
2086                 AC_MSG_WARN(no tic program found for fallbacks)
2087         fi
2088 fi
2089 AC_SUBST(TIC_PATH)
2090
2091 if test "x$cf_with_tests" != xno ; then
2092         MAKE_TESTS=
2093 else
2094         MAKE_TESTS="#"
2095 fi
2096 AC_SUBST(MAKE_TESTS)
2097
2098 ADAHTML_DIR=../../doc/html/ada
2099 AC_SUBST(ADAHTML_DIR)
2100
2101 # these could be configurable, but are not currently
2102 PANEL_NAME=panel
2103 MENU_NAME=menu
2104 FORM_NAME=form
2105 CXX_NAME=ncurses++
2106
2107 AC_SUBST(PANEL_NAME)
2108 AC_SUBST(MENU_NAME)
2109 AC_SUBST(FORM_NAME)
2110 AC_SUBST(CXX_NAME)
2111
2112 # workaround for OS/2 (20151017)
2113 case $cf_cv_system_name in
2114 (os2*)
2115         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2116         ;;
2117 (*)
2118         LIBTOOL_OPTS_CXX=
2119         ;;
2120 esac
2121 AC_SUBST(LIBTOOL_OPTS_CXX)
2122
2123 # workaround for g++ versus Solaris (20131116)
2124 case $cf_cv_system_name in
2125 (solaris2*)
2126         case "x$CPPFLAGS" in
2127         (*-D_XOPEN_SOURCE_EXTENDED*)
2128                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2129                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2130                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2131                 ;;
2132         esac
2133         ;;
2134 esac
2135
2136 # Help to automatically enable the extended curses features when using either
2137 # the *-config or the ".pc" files by adding defines.
2138 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2139 PKG_CFLAGS=
2140 for cf_loop1 in $CPPFLAGS_after_XOPEN
2141 do
2142         cf_found=no
2143         for cf_loop2 in $CPPFLAGS_before_XOPEN
2144         do
2145                 if test "x$cf_loop1" = "x$cf_loop2"
2146                 then
2147                         cf_found=yes
2148                         break
2149                 fi
2150         done
2151         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2152 done
2153 AC_MSG_RESULT($PKG_CFLAGS)
2154 AC_SUBST(PKG_CFLAGS)
2155
2156 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2157 case "x$NCURSES_OSPEED" in
2158 (*short*)
2159         cf_compatible=1
2160         ;;
2161 (*)
2162         cf_compatible=0
2163         ;;
2164 esac
2165 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2166
2167 case "x$cf_cv_typeof_chtype" in
2168 (xshort|xint|xlong)
2169         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2170         ;;
2171 esac
2172
2173 case "x$cf_cv_typeof_mmask_t" in
2174 (xshort|xint|xlong)
2175         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2176         ;;
2177 esac
2178
2179 # substitute into misc/Makefile to suppress
2180 # (un)install.data from the
2181 # (un)install rules.
2182 if test "x$cf_with_db_install" = "xno"; then
2183         MISC_INSTALL_DATA=
2184         MISC_UNINSTALL_DATA=
2185 else
2186         MISC_INSTALL_DATA=install.data
2187         MISC_UNINSTALL_DATA=uninstall.data
2188 fi
2189 AC_SUBST(MISC_INSTALL_DATA)
2190 AC_SUBST(MISC_UNINSTALL_DATA)
2191
2192 SUB_SCRIPTS=
2193
2194 dnl Override the package used for exported symbols
2195 if test -n "$PACKAGE"
2196 then
2197         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2198         export PACKAGE
2199         echo "package: $PACKAGE"
2200 fi
2201
2202 UNALTERED_SYMS=
2203 cf_filter_syms=no
2204
2205 if test -n "$RESULTING_SYMS"
2206 then
2207         cf_filter_syms=$cf_dft_filter_syms
2208         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2209 fi
2210
2211 if test "x$WILDCARD_SYMS" = xno
2212 then
2213         cf_filter_syms=yes
2214 fi
2215
2216 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2217
2218 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2219 if test $cf_filter_syms = yes
2220 then
2221         RESULTING_SYMS=resulting.map
2222 fi
2223 AC_SUBST(UNALTERED_SYMS)
2224
2225 if test "x$cross_compiling" = xyes ; then
2226         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2227 else
2228         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2229 fi
2230 AC_SUBST(ADAGEN_LDFLAGS)
2231
2232 AC_OUTPUT( \
2233         include/MKterm.h.awk \
2234         include/curses.head:include/curses.h.in \
2235         include/ncurses_dll.h \
2236         include/termcap.h \
2237         include/unctrl.h \
2238         $SUB_SCRIPTS \
2239         $SUB_MAKEFILES \
2240         Makefile,[
2241 if test "x$cf_with_tests" != xno ; then
2242         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2243 fi
2244 CF_LIB_RULES($SRC_SUBDIRS)
2245
2246 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2247 if test -z "$USE_OLD_MAKERULES" ; then
2248         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
2249 fi
2250 fi
2251 ],[
2252 ### Special initialization commands, used to pass information from the
2253 ### configuration-run into config.status
2254
2255 AWK="$AWK"
2256 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2257 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2258 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2259 ECHO_LD="$ECHO_LD"
2260 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2261 LDCONFIG="$LDCONFIG"
2262 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2263 LIB_NAME="$LIB_NAME"
2264 LIB_PREFIX="$LIB_PREFIX"
2265 LIB_SUBSETS="$LIB_SUBSETS"
2266 LIB_SUFFIX="$LIB_SUFFIX"
2267 LIB_TRACING="$LIB_TRACING"
2268 LN_S="$LN_S"
2269 MAKE_TERMINFO="$MAKE_TERMINFO"
2270 NCURSES_MAJOR="$NCURSES_MAJOR"
2271 NCURSES_MINOR="$NCURSES_MINOR"
2272 NCURSES_OSPEED="$NCURSES_OSPEED"
2273 NCURSES_PATCH="$NCURSES_PATCH"
2274 SRC_SUBDIRS="$SRC_SUBDIRS"
2275 TERMINFO="$TERMINFO"
2276 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2277 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2278 TICS_NAME="$TICS_NAME"
2279 TICS_SUFFIX="$TICS_SUFFIX"
2280 TIC_PATH="$TIC_PATH"
2281 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2282 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2283 TINFO_NAME="$TINFO_NAME"
2284 TINFO_SUFFIX="$TINFO_SUFFIX"
2285 UNALTERED_SYMS="$UNALTERED_SYMS"
2286 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2287 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2288 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2289 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2290 WILDCARD_SYMS="$WILDCARD_SYMS"
2291 WITH_CURSES_H="$with_curses_h"
2292 WITH_ECHO="${enable_echo:=yes}"
2293 WITH_OVERWRITE="$with_overwrite"
2294 cf_LIST_MODELS="$cf_list_models"
2295 cf_cv_abi_version="$cf_cv_abi_version"
2296 cf_cv_do_relink="$cf_cv_do_relink"
2297 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2298 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2299 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2300 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2301 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2302 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2303 cf_cv_rel_version="$cf_cv_rel_version"
2304 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2305 cf_cv_shared_soname='$cf_cv_shared_soname'
2306 cf_cv_shlib_version="$cf_cv_shlib_version"
2307 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2308 cf_cv_system_name="$cf_cv_system_name"
2309 cf_cv_term_driver="$with_term_driver"
2310 cf_with_ada="$cf_with_ada"
2311 cf_with_cxx_binding="$cf_with_cxx_binding"
2312 cf_with_db_install="$cf_with_db_install"
2313 cf_with_manpages="$cf_with_manpages"
2314 cf_with_tests="$cf_with_tests"
2315 host="$host"
2316 target="$target"
2317 with_shared_cxx="$with_shared_cxx"
2318
2319 ],cat)dnl
2320 ${MAKE:-make} preinstall