ncurses 6.3 - patch 20220514
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright 2018-2021,2022 Thomas E. Dickey                                *
3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
4 dnl                                                                          *
5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
6 dnl copy of this software and associated documentation files (the            *
7 dnl "Software"), to deal in the Software without restriction, including      *
8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
10 dnl copies of the Software, and to permit persons to whom the Software is    *
11 dnl furnished to do so, subject to the following conditions:                 *
12 dnl                                                                          *
13 dnl The above copyright notice and this permission notice shall be included  *
14 dnl in all copies or substantial portions of the Software.                   *
15 dnl                                                                          *
16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
23 dnl                                                                          *
24 dnl Except as contained in this notice, the name(s) of the above copyright   *
25 dnl holders shall not be used in advertising or otherwise to promote the     *
26 dnl sale, use or other dealings in this Software without prior written       *
27 dnl authorization.                                                           *
28 dnl***************************************************************************
29 dnl
30 dnl Author: Thomas E. Dickey 1995-on
31 dnl
32 dnl $Id: configure.in,v 1.741 2022/01/23 00:11:08 tom Exp $
33 dnl Process this file with autoconf to produce a configure script.
34 dnl
35 dnl For additional information, see
36 dnl     https://invisible-island.net/autoconf/
37 dnl     https://invisible-island.net/autoconf/my-autoconf.html
38 dnl
39 dnl ---------------------------------------------------------------------------
40 AC_PREREQ(2.52.20210101)
41 AC_REVISION($Revision: 1.741 $)
42 AC_INIT(ncurses/base/lib_initscr.c)
43 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
44
45 AC_DEFUN([AC_PATH_XTRA],[])dnl ignore dependencies on this
46
47 CF_TOP_BUILDDIR
48 CF_SUBST_NCURSES_VERSION
49 CF_VERSION_INFO(NCURSES,ncurses)
50
51 CF_WITH_REL_VERSION(NCURSES)
52 CF_NCURSES_WITH_ABI_VERSION
53
54 CF_WITH_SYSTYPE
55
56 ###     Save the given $CFLAGS to allow user-override.
57 cf_user_CFLAGS="$CFLAGS"
58
59 ###     Default install-location
60 CF_CFG_DEFAULTS
61 ### Defaults for ncurses ABI
62 CF_ABI_DEFAULTS
63
64 ###     Checks for programs.
65 AC_ARG_WITH(ada,
66         [  --without-ada           suppress check for Ada compiler, don't build demo],
67         [cf_with_ada=$withval],
68         [cf_with_ada=yes])
69
70 if test "x$cf_with_ada" = xyes
71 then
72         cf_prog_cc="gnatgcc gcc cc"
73 else
74         cf_prog_cc="gcc cc"
75 fi
76 CF_PROG_CC($cf_prog_cc)
77
78 AC_PROG_CPP
79 AC_PROG_GCC_TRADITIONAL
80 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
81 CF_PROG_LDCONFIG
82
83 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
84 dnl                             configure script by not letting us test if C++
85 dnl                             is present, making this option necessary.
86 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
87 AC_ARG_WITH(cxx,
88         [  --without-cxx           do not adjust ncurses bool to match C++],
89         [cf_with_cxx=$withval],
90         [cf_with_cxx=yes])
91 AC_MSG_RESULT($cf_with_cxx)
92 if test "X$cf_with_cxx" = Xno ; then
93         CXX=""
94         GXX=""
95 else
96         # with autoconf 2.13, we can change the error to a warning:
97         pushdef([AC_MSG_ERROR],
98                 [AC_MSG_RESULT(no)
99                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
100                 cf_with_cxx=no; CXX=""; GXX="";])dnl
101         AC_PROG_CXX
102         popdef([AC_MSG_ERROR])dnl
103
104         AC_LANG_PUSH(C++)
105         if test "x$cf_with_cxx" != xno
106         then
107                 # Several of the C++ configurations do not work, particularly when
108                 # cross-compiling (20140913 -TD)
109                 AC_MSG_CHECKING(if $CXX works)
110
111                 save_CPPFLAGS="$CPPFLAGS"
112                 eval cf_includedir=${includedir}
113                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
114                 AC_TRY_COMPILE([
115 #include <stdlib.h>
116 #include <stdio.h>
117 ],
118                 [
119                 printf("Hello world!\n")
120                 ],
121                 [cf_cxx_works=yes],
122                 [cf_cxx_works=no])
123                 CPPFLAGS="$save_CPPFLAGS"
124
125                 AC_MSG_RESULT($cf_cxx_works)
126                 if test "x$cf_cxx_works" = xno
127                 then
128                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
129                         cf_with_cxx=no; CXX=""; GXX="";
130                 fi
131         fi
132         AC_LANG_POP
133
134         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
135         if test "$CXX" = "g++" ; then
136                 AC_PATH_PROG(CXX,g++)
137         fi
138         case "x$CXX" in
139         (x|xg++)
140                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
141                 cf_with_cxx=no; CXX=""; GXX="";
142                 ;;
143         esac
144 fi
145
146 CF_GXX_VERSION
147 case "$GXX_VERSION" in
148 ([[1-9]][[0-9]].*)
149         ;;
150 (1.*|2.[[0-6]]*)
151         AC_MSG_WARN(templates do not work)
152         ;;
153 esac
154
155 AC_MSG_CHECKING(if you want to build C++ binding and demo)
156 AC_ARG_WITH(cxx-binding,
157         [  --without-cxx-binding   do not build C++ binding and demo],
158         [cf_with_cxx_binding=$withval],
159         [cf_with_cxx_binding=$cf_with_cxx])
160 AC_MSG_RESULT($cf_with_cxx_binding)
161
162 AC_MSG_CHECKING(if you want to build with Ada)
163 AC_MSG_RESULT($cf_with_ada)
164
165 AC_MSG_CHECKING(if you want to install terminal database)
166 AC_ARG_ENABLE(db-install,
167         [  --disable-db-install    suppress install of terminal database],
168         [cf_with_db_install=$enableval],
169         [cf_with_db_install=yes])
170 AC_MSG_RESULT($cf_with_db_install)
171
172 AC_MSG_CHECKING(if you want to install manpages)
173 AC_ARG_WITH(manpages,
174         [  --without-manpages      suppress install of manpages],
175         [cf_with_manpages=$withval],
176         [cf_with_manpages=yes])
177 AC_MSG_RESULT($cf_with_manpages)
178
179 AC_MSG_CHECKING(if you want to build programs such as tic)
180 AC_ARG_WITH(progs,
181         [  --without-progs         suppress build/install with programs (e.g., tic)],
182         [cf_with_progs=$withval],
183         [cf_with_progs=yes])
184 AC_MSG_RESULT($cf_with_progs)
185
186 if test -f "$srcdir/tack/tack.h" ; then
187         if test "x$cross_compiling" = xyes ; then
188                 CF_VERBOSE(ignoring tack because we are cross-compiling)
189                 cf_with_tack=no
190         else
191                 AC_MSG_CHECKING(if you want to build the tack program)
192                 AC_ARG_WITH(tack,
193                         [  --without-tack          suppress build/install with tack program],
194                         [cf_with_tack=$withval],
195                         [cf_with_tack=$cf_with_progs])
196                 AC_MSG_RESULT($cf_with_tack)
197         fi
198 else
199         cf_with_tack=no
200 fi
201
202 AC_MSG_CHECKING(if you want to build test-programs)
203 AC_ARG_WITH(tests,
204         [  --without-tests         suppress build/install with test-programs],
205         [cf_with_tests=$withval],
206         [cf_with_tests=yes])
207 AC_MSG_RESULT($cf_with_tests)
208
209 AC_MSG_CHECKING(if you wish to install curses.h)
210 AC_ARG_WITH(curses-h,
211         [  --without-curses-h      install curses.h as ncurses.h only],
212         [with_curses_h=$withval],
213         [with_curses_h=yes])
214 AC_MSG_RESULT($with_curses_h)
215
216 modules_to_build="ncurses"
217 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
218 test "X$cf_with_tack"  != Xno && modules_to_build="$modules_to_build tack"
219 modules_to_build="$modules_to_build panel menu form"
220
221 AC_ARG_PROGRAM
222
223 CF_PROG_AWK
224 CF_PROG_INSTALL
225 CF_PROG_LINT
226 CF_PROG_LN_S
227
228 AC_SYS_LONG_FILE_NAMES
229
230 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
231 # of package conflict.
232 cf_config_suffix=
233 AC_ARG_WITH(config-suffix,
234         [  --with-config-suffix=X  suffixes ncursesXX-config file],
235         [case "x$withval" in
236         (xyes|xno)
237                 AC_MSG_WARN(expected a value for config-suffix option)
238                 ;;
239         (*)     cf_config_suffix="$withval"
240                 ;;
241         esac])
242 AC_SUBST(cf_config_suffix)
243
244 # If we find pkg-config, check if we should install the ".pc" files.
245 CF_PKG_CONFIG
246 CF_WITH_PKG_CONFIG_LIBDIR
247 CF_ENABLE_PC_FILES
248 if test -z "$MAKE_PC_FILES"
249 then
250         AC_MSG_CHECKING(for suffix to add to pc-files)
251 AC_ARG_WITH(pc-suffix,
252         [  --with-pc-suffix        suffixes pc-files],
253         [case "x$withval" in
254         (xyes|xno)
255                 PC_MODULE_SUFFIX=
256                 ;;
257         (*)     PC_MODULE_SUFFIX="$withval"
258                 ;;
259         esac])
260         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
261         AC_MSG_RESULT($PC_MODULE_SUFFIX)
262         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
263         AC_SUBST(PC_MODULE_SUFFIX)
264 fi
265
266 AC_MSG_CHECKING(if we should assume mixed-case filenames)
267 AC_ARG_ENABLE(mixed-case,
268         [  --enable-mixed-case     tic should assume mixed-case filenames],
269         [enable_mixedcase=$enableval],
270         [enable_mixedcase=auto])
271 AC_MSG_RESULT($enable_mixedcase)
272 if test "$enable_mixedcase" = "auto" ; then
273         CF_MIXEDCASE_FILENAMES
274 else
275         cf_cv_mixedcase=$enable_mixedcase
276         if test "x$enable_mixedcase" = "xyes" ; then
277                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
278         fi
279 fi
280
281 # do this after mixed-case option (tags/TAGS is not as important as tic).
282 AC_PROG_MAKE_SET
283 CF_MAKE_PHONY
284 CF_MAKE_TAGS
285 CF_MAKEFLAGS
286
287 dnl These are standard among *NIX systems, but not when cross-compiling
288 AC_CHECK_TOOL(RANLIB, ranlib, ':')
289 AC_CHECK_TOOL(LD, ld, ld)
290 AC_CHECK_TOOL(AR, ar, ar)
291 AC_CHECK_TOOL(NM, nm, nm)
292 CF_AR_FLAGS
293
294 dnl Special option for use by system-builders: the install-prefix is used to
295 dnl adjust the location into which the actual install is done, so that an
296 dnl archive can be built without modifying the host system's configuration.
297 AC_MSG_CHECKING(if you have specified an install-prefix)
298 AC_ARG_WITH(install-prefix,
299         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
300         [case "x$withval" in
301         (xyes|xno)
302                 ;;
303         (*)     DESTDIR="$withval"
304                 ;;
305         esac])
306 AC_MSG_RESULT($DESTDIR)
307 AC_SUBST(DESTDIR)
308
309 ###############################################################################
310 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
311 # If we're cross-compiling, allow the user to override the tools and their
312 # options.  The configure script is oriented toward identifying the host
313 # compiler, etc., but we need a build compiler to generate parts of the source.
314
315 case "$cf_cv_system_name" in
316 (*-msvc*)
317         LDFLAGS="$LDFLAGS user32.lib"
318         export LDFLAGS
319         ;;
320 esac
321
322 CF_BUILD_CC
323
324 ###############################################################################
325 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
326
327 ### Options to allow the user to specify the set of libraries which are used.
328 ### Use "--without-normal --with-shared" to allow the default model to be
329 ### shared, for example.
330 cf_list_models=""
331 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
332
333 CF_WITH_LIBTOOL
334 if test "$with_libtool" != "no" ; then
335
336 cf_list_models="$cf_list_models libtool"
337
338 else
339
340 AC_MSG_CHECKING(if you want to build shared libraries)
341 AC_ARG_WITH(shared,
342         [  --with-shared           generate shared-libraries],
343         [with_shared=$withval],
344         [with_shared=no])
345 AC_MSG_RESULT($with_shared)
346 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
347
348 AC_MSG_CHECKING(if you want to build static libraries)
349 AC_ARG_WITH(normal,
350         [  --with-normal           generate normal-libraries (default)],
351         [with_normal=$withval],
352         [with_normal=yes])
353 AC_MSG_RESULT($with_normal)
354 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
355
356 AC_MSG_CHECKING(if you want to build debug libraries)
357 AC_ARG_WITH(debug,
358         [  --with-debug            generate debug-libraries (default)],
359         [with_debug=$withval],
360         [with_debug=yes])
361 AC_MSG_RESULT($with_debug)
362 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
363
364 AC_MSG_CHECKING(if you want to build profiling libraries)
365 AC_ARG_WITH(profile,
366         [  --with-profile          generate profile-libraries],
367         [with_profile=$withval],
368         [with_profile=no])
369 AC_MSG_RESULT($with_profile)
370 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
371
372 fi
373
374 if test "X$cf_with_cxx_binding" != Xno; then
375 if test "x$with_shared" = "xyes"; then
376 AC_MSG_CHECKING(if you want to build C++ shared libraries)
377 AC_ARG_WITH(cxx-shared,
378         [  --with-cxx-shared       generate C++ shared-libraries],
379         [with_shared_cxx=$withval],
380         [with_shared_cxx=no])
381 AC_MSG_RESULT($with_shared_cxx)
382 fi
383 fi
384
385 ###############################################################################
386
387 AC_MSG_CHECKING(for specified models)
388 test -z "$cf_list_models" && cf_list_models=normal
389 dnl If we use libtool to generate libraries, then it must be the only
390 dnl specified model.
391 test "$with_libtool" != "no" && cf_list_models=libtool
392 AC_MSG_RESULT($cf_list_models)
393
394 ### Use the first model as the default, and save its suffix for use in building
395 ### up test-applications.
396 AC_MSG_CHECKING(for default model)
397 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
398 AC_MSG_RESULT($DFT_LWR_MODEL)
399
400 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
401
402 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
403 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
404
405 TICS_NAME=tic
406 AC_SUBST(TICS_NAME)
407
408 TINFO_NAME=tinfo
409 AC_SUBST(TINFO_NAME)
410
411 LIB_NAME=ncurses
412 AC_SUBST(LIB_NAME)
413
414 LIB_DIR=../lib
415 LIB_2ND=../../lib
416
417 CF_WITH_LIB_PREFIX(cf_prefix)
418
419 LIB_SUFFIX=
420 AC_SUBST(LIB_SUFFIX)
421 CF_PATHSEP
422
423 ###############################################################################
424
425 AC_MSG_CHECKING(if you want to build a separate terminfo library)
426 AC_ARG_WITH(termlib,
427         [  --with-termlib          generate separate terminfo library],
428         [with_termlib=$withval],
429         [with_termlib=no])
430 AC_MSG_RESULT($with_termlib)
431
432 AC_MSG_CHECKING(if you want to build a separate tic library)
433 AC_ARG_WITH(ticlib,
434         [  --with-ticlib           generate separate tic library],
435         [with_ticlib=$withval],
436         [with_ticlib=no])
437 AC_MSG_RESULT($with_ticlib)
438
439 dnl Not all ports of gcc support the -g option
440
441 if test X"$CC_G_OPT" = X"" ; then
442         CC_G_OPT='-g'
443         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
444 fi
445 AC_SUBST(CC_G_OPT)
446
447 if test X"$CXX_G_OPT" = X"" ; then
448         CXX_G_OPT='-g'
449         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
450 fi
451 AC_SUBST(CXX_G_OPT)
452
453 AC_MSG_CHECKING(for default loader flags)
454 case "$DFT_LWR_MODEL" in
455 (libtool) LD_MODEL=''   ;;
456 (normal)  LD_MODEL=''   ;;
457 (debug)   LD_MODEL=$CC_G_OPT ;;
458 (profile) LD_MODEL='-pg';;
459 (shared)  LD_MODEL=''   ;;
460 esac
461 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
462 AC_MSG_RESULT($LD_MODEL)
463
464 case "$DFT_LWR_MODEL" in
465 (shared)
466 CF_ENABLE_RPATH
467 AC_MSG_CHECKING(if shared libraries should be relinked during install)
468 AC_ARG_ENABLE(relink,
469 [  --disable-relink        relink shared libraries during install],
470 [cf_cv_do_relink=$enableval],
471 [cf_cv_do_relink=yes])
472 AC_MSG_RESULT($cf_cv_do_relink)
473         ;;
474 esac
475
476 # we will build libraries one-level down.
477 rel_builddir=..
478 CF_SHARED_OPTS
479 for model in $cf_list_models ; do
480         case "$model" in
481         (libtool)
482                 CF_WITH_LIBTOOL_OPTS
483                 CF_WITH_EXPORT_SYMS
484                 ;;
485         (shared)
486                 if test "$CC_SHARED_OPTS" = "unknown"; then
487                         AC_ERROR(Shared libraries are not supported in this version)
488                 fi
489                 # workaround for inept transition to PIE vs PIC...
490                 AC_MSG_CHECKING(if current CFLAGS link properly)
491                 AC_TRY_LINK(
492                         [#include <stdio.h>],
493                         [printf("Hello work\\n");],
494                         [cf_cflags_work=yes],
495                         [cf_cflags_work=no])
496                 AC_MSG_RESULT($cf_cflags_work)
497                 if test "$cf_cflags_work" = no
498                 then
499                         CF_VERBOSE(try to work around by appending shared-options)
500                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
501                 fi
502                 CF_WITH_VERSIONED_SYMS
503                 ;;
504         esac
505 done
506
507 ### Checks for special libraries, must be done up-front.
508 SHLIB_LIST=""
509 CF_WITH_GPM
510 if test "$with_gpm" != no ; then
511         AC_MSG_CHECKING(if you want to load GPM dynamically)
512         AC_ARG_WITH(dlsym,
513                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
514                 [with_dlsym=$withval],
515                 [with_dlsym=yes])
516         AC_MSG_RESULT($with_dlsym)
517         if test "x$with_dlsym" = xyes ; then
518                 CF_FUNC_DLSYM
519                 if test "x$with_gpm" != xyes ; then
520                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
521                         cf_cv_gpm_soname="$with_gpm"
522                 else
523                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
524                 fi
525                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
526                 SHLIB_LIST="-ldl $SHLIB_LIST"
527                 CF_ADD_LIB(dl,PRIVATE_LIBS)
528         else
529                 SHLIB_LIST="-lgpm $SHLIB_LIST"
530                 CF_ADD_LIB(gpm,TEST_LIBS)
531                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
532         fi
533         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
534         CF_CHECK_GPM_WGETCH
535 fi
536
537 CF_WITH_PCRE2
538 CF_WITH_SYSMOUSE
539
540 # pretend that ncurses==ncursesw==ncursest
541 AC_MSG_CHECKING(if you want to disable library suffixes)
542 CF_ARG_DISABLE(lib-suffixes,
543         [  --disable-lib-suffixes  disable library suffixes],
544         [disable_lib_suffixes=yes],
545         [disable_lib_suffixes=no],
546         no)
547 AC_MSG_RESULT($disable_lib_suffixes)
548
549 ### If we're building with rpath, try to link non-standard libs that way too.
550 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
551         CF_DISABLE_RPATH_HACK
552 fi
553
554 ### Depending on the system, someone may use rpath to build ncurses but not
555 # want users of the package to rely upon that feature.  Give those people an
556 # option to suppress that detail from EXTRA_LDFLAGS.
557 EXTRA_PKG_LDFLAGS="$LDFLAGS $EXTRA_LDFLAGS"
558 if test -n "$EXTRA_PKG_LDFLAGS"
559 then
560         AC_MSG_CHECKING(if you want to disable extra LDFLAGS for package-scripts)
561         CF_ARG_DISABLE(pkg-ldflags,
562                 [  --disable-pkg-ldflags   disable extra LDFLAGS for package-scripts],
563                 [disable_pkg_ldflags=yes],
564                 [disable_pkg_ldflags=no],
565                 no)
566         AC_MSG_RESULT($disable_pkg_ldflags)
567         test "$disable_pkg_ldflags" = yes && EXTRA_PKG_LDFLAGS=
568 fi
569 AC_SUBST(EXTRA_PKG_LDFLAGS)
570
571 ###############################################################################
572 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
573
574 ###     use option --with-extra-suffix to append suffix to headers and libraries
575 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
576 EXTRA_SUFFIX=
577 AC_ARG_WITH(extra-suffix,
578         [  --with-extra-suffix=X   append extra suffix to header/library paths],
579         [case x$withval in
580         (xno)
581                 ;;
582         (xyes|x)
583                 EXTRA_SUFFIX=$cf_cv_abi_version
584                 ;;
585         (*)
586                 EXTRA_SUFFIX=$withval
587                 ;;
588         esac
589         ])
590 AC_MSG_RESULT($EXTRA_SUFFIX)
591 AC_SUBST(EXTRA_SUFFIX)
592
593 ###     use option --disable-overwrite to leave out the link to -lcurses
594 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
595 AC_ARG_ENABLE(overwrite,
596         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
597         [with_overwrite=$enableval],
598         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
599 AC_MSG_RESULT($with_overwrite)
600
601 AC_MSG_CHECKING(if external terminfo-database is used)
602 AC_ARG_ENABLE(database,
603         [  --disable-database      do not use terminfo, only fallbacks/termcap],
604         [use_database=$enableval],
605         [use_database=yes])
606 AC_MSG_RESULT($use_database)
607
608 case "$host_os" in
609 (os2*)
610         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
611         ;;
612 (*)
613         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
614         ;;
615 esac
616 AC_SUBST(TERMINFO_SRC)
617
618 NCURSES_USE_DATABASE=0
619 if test "$use_database" != no ; then
620         NCURSES_USE_DATABASE=1
621
622         AC_MSG_CHECKING(which terminfo source-file will be installed)
623         AC_ARG_WITH(database,
624                 [  --with-database=XXX     specify terminfo source to install],
625                 [TERMINFO_SRC=$withval])
626         AC_MSG_RESULT($TERMINFO_SRC)
627
628         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
629         AC_ARG_WITH(hashed-db,
630                 [  --with-hashed-db        specify hashed-database library],,
631                 [with_hashed_db=no])
632         AC_MSG_RESULT($with_hashed_db)
633 else
634         with_hashed_db=no
635 fi
636 AC_SUBST(NCURSES_USE_DATABASE)
637
638 AC_MSG_CHECKING(for list of fallback descriptions)
639 AC_ARG_WITH(fallbacks,
640         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
641         [with_fallback=$withval],
642         [with_fallback=])
643 AC_MSG_RESULT($with_fallback)
644
645 case ".$with_fallback" in
646 (.|.no)
647         FALLBACK_LIST=
648         ;;
649 (.yes)
650         AC_MSG_WARN(expected a list of terminal descriptions)
651         ;;
652 (*)
653         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
654         ;;
655 esac
656
657 # The fallback feature in ncurses relies upon tic/infocmp outside the build
658 # tree for generating the terminal descriptions that will be compiled into the
659 # library.  If your toolchain is old, it may not handle current terminal
660 # databases.  Use configure-options to point to the tools which will be used,
661 # rather than the first ones found on the $PATH.
662 AC_CHECK_TOOL(TIC, tic)
663 AC_CHECK_TOOL(INFOCMP, infocmp)
664 if test -n "$FALLBACK_LIST"
665 then
666         CF_WITH_PATH_PROG(TIC,     tic,     [for fallbacks], $PATH:/usr/local/ncurses/bin)
667         CF_WITH_PATH_PROG(INFOCMP, infocmp, [for fallbacks], $PATH:/usr/local/ncurses/bin)
668         test -z "$TIC" && FALLBACK_LIST=
669         test -z "$INFOCMP" && FALLBACK_LIST=
670         if test -z "$FALLBACK_LIST"
671         then
672                 AC_MSG_WARN(ignoring fallback option because tic/infocmp are not available)
673         fi
674 fi
675 AC_SUBST(TIC)
676 AC_SUBST(INFOCMP)
677
678 USE_FALLBACKS=
679 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
680 AC_SUBST(FALLBACK_LIST)
681 AC_SUBST(USE_FALLBACKS)
682
683 AC_MSG_CHECKING(if you want modern xterm or antique)
684 AC_ARG_WITH(xterm-new,
685         [  --without-xterm-new     specify if xterm terminfo should be old version],
686         [with_xterm_new=$withval],
687         [with_xterm_new=yes])
688 case "$with_xterm_new" in
689 (no) with_xterm_new=xterm-old;;
690 (*)      with_xterm_new=xterm-new;;
691 esac
692 AC_MSG_RESULT($with_xterm_new)
693 WHICH_XTERM=$with_xterm_new
694 AC_SUBST(WHICH_XTERM)
695
696 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
697 AC_ARG_WITH(xterm-kbs,
698         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
699         [with_xterm_kbs=$withval],
700         [with_xterm_kbs=BS])
701 case x$with_xterm_kbs in
702 (xyes|xno|xBS|xbs|x8)
703         with_xterm_kbs=BS
704         ;;
705 (xDEL|xdel|x127)
706         with_xterm_kbs=DEL
707         ;;
708 (*)
709         with_xterm_kbs=$withval
710         ;;
711 esac
712 AC_MSG_RESULT($with_xterm_kbs)
713 XTERM_KBS=$with_xterm_kbs
714 AC_SUBST(XTERM_KBS)
715
716 MAKE_TERMINFO=
717 if test "$use_database" = no ; then
718         TERMINFO="${datadir}/terminfo"
719         MAKE_TERMINFO="#"
720 else
721
722 AC_MSG_CHECKING(for list of terminfo directories)
723 CF_WITH_PATHLIST(terminfo-dirs,
724         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
725         TERMINFO_DIRS,
726         DATADIR/terminfo,
727         ${datadir}/terminfo)
728 AC_MSG_RESULT($TERMINFO_DIRS)
729 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
730
731 case "x$TERMINFO" in
732 x???:*)
733         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
734         unset TERMINFO
735         ;;
736 esac
737
738 AC_MSG_CHECKING(for default terminfo directory)
739 CF_WITH_PATH(default-terminfo-dir,
740         [  --with-default-terminfo-dir=DIR default terminfo directory],
741         TERMINFO,
742         DATADIR/terminfo,
743         ${datadir}/terminfo)
744 AC_MSG_RESULT($TERMINFO)
745 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
746
747 fi
748
749 AC_SUBST(TERMINFO)
750 AC_SUBST(MAKE_TERMINFO)
751
752 ###     use option --disable-big-core to make tic run on small machines
753 ###     We need 4Mb, check if we can allocate 50% more than that.
754 AC_MSG_CHECKING(if big-core option selected)
755 AC_ARG_ENABLE(big-core,
756         [  --disable-big-core      assume machine has little memory],
757         [with_big_core=$enableval],
758         [AC_TRY_RUN([
759 #include <stdlib.h>
760 #include <string.h>
761 int main() {
762         unsigned long n = 6000000L;
763         char *s = malloc(n);
764         if (s != 0)
765                 s[0] = s[n-1] = 0;
766         ${cf_cv_main_return:-return}(s == 0);
767 }],
768         [with_big_core=yes],
769         [with_big_core=no],
770         [with_big_core=no])])
771 AC_MSG_RESULT($with_big_core)
772 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
773
774 ### ISO C only guarantees 512-char strings, we have tables which load faster
775 ### when constructed using "big" strings.  More than the C compiler, the awk
776 ### program is a limit on most vendor UNIX systems.  Check that we can build.
777 AC_MSG_CHECKING(if big-strings option selected)
778 AC_ARG_ENABLE(big-strings,
779         [  --disable-big-strings   assume compiler has only standard-size strings],
780         [with_big_strings=$enableval],
781         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
782 AC_MSG_RESULT($with_big_strings)
783
784 USE_BIG_STRINGS=0
785 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
786 AC_SUBST(USE_BIG_STRINGS)
787
788 ###     use option --enable-termcap to compile in the termcap fallback support
789 AC_MSG_CHECKING(if you want termcap-fallback support)
790 AC_ARG_ENABLE(termcap,
791         [  --enable-termcap        compile in termcap fallback support],
792         [with_termcap=$enableval],
793         [with_termcap=no])
794 AC_MSG_RESULT($with_termcap)
795
796 NCURSES_USE_TERMCAP=0
797 if test "x$with_termcap" != "xyes" ; then
798         if test "$use_database" = no ; then
799                 if test -z "$with_fallback" ; then
800                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
801                 fi
802         fi
803         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
804 else
805
806         if test "$with_ticlib" != no ; then
807                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
808         fi
809
810         NCURSES_USE_TERMCAP=1
811         AC_MSG_CHECKING(for list of termcap files)
812         CF_WITH_PATHLIST(termpath,
813                 [  --with-termpath=XXX     specify list of termcap files],
814                 TERMPATH,
815                 /etc/termcap:/usr/share/misc/termcap)
816         AC_MSG_RESULT($TERMPATH)
817         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
818
819         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
820         AC_MSG_CHECKING(if fast termcap-loader is needed)
821         AC_ARG_ENABLE(getcap,
822                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
823                 [with_getcap=$enableval],
824                 [with_getcap=no])
825         AC_MSG_RESULT($with_getcap)
826         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
827
828         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
829         AC_ARG_ENABLE(getcap-cache,
830                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
831                 [with_getcap_cache=$enableval],
832                 [with_getcap_cache=no])
833         AC_MSG_RESULT($with_getcap_cache)
834         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
835
836 fi
837 AC_SUBST(NCURSES_USE_TERMCAP)
838
839 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
840 AC_MSG_CHECKING(if ~/.terminfo is wanted)
841 AC_ARG_ENABLE(home-terminfo,
842         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
843         [with_home_terminfo=$enableval],
844         [with_home_terminfo=yes])
845 AC_MSG_RESULT($with_home_terminfo)
846 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
847
848 AC_MSG_CHECKING(if you want to permit root to use ncurses environment variables)
849 AC_ARG_ENABLE(root-environ,
850         [  --disable-root-environ  restrict root use of ncurses environment variables],
851         [with_root_environ=$enableval],
852         [with_root_environ=yes])
853 AC_MSG_RESULT($with_root_environ)
854 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if root is allowed to use ncurses environment])
855
856 AC_MSG_CHECKING(if you want to permit setuid programs to access all files)
857 AC_ARG_ENABLE(root-environ,
858         [  --disable-root-access   restrict file-access when running setuid],
859         [with_root_access=$enableval],
860         [with_root_access=yes])
861 AC_MSG_RESULT($with_root_access)
862 test "x$with_root_access" = xyes && AC_DEFINE(USE_ROOT_ACCESS,1,[Define to 1 if setuid is allowed all file-access])
863
864 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
865 ###   to reduce storage requirements for the terminfo database.
866 CF_LINK_FUNCS
867
868 with_links=no
869 with_symlinks=no
870
871 # soft links (symbolic links) are useful for some systems where hard links do
872 # not work, or to make it simpler to copy terminfo trees around.
873 if test "x$ac_cv_func_symlink" = xyes ; then
874         AC_MSG_CHECKING(if tic should use symbolic links)
875         AC_ARG_ENABLE(symlinks,
876         [  --enable-symlinks       make tic use symbolic links not hard links],
877         [with_symlinks=$enableval],
878         [with_symlinks=no])
879         AC_MSG_RESULT($with_symlinks)
880 fi
881
882 # If we have hard links and did not choose to use soft links instead, there is
883 # no reason to make this choice optional - use the hard links.
884 if test "$with_symlinks" = no ; then
885         AC_MSG_CHECKING(if tic should use hard links)
886         if test "x$ac_cv_func_link" = xyes ; then
887                 with_links=yes
888         else
889                 with_links=no
890         fi
891         AC_MSG_RESULT($with_links)
892 fi
893
894 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
895 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
896
897 ###   use option --enable-broken-linker to force on use of broken-linker support
898 CF_ENABLE_BROKEN_LINKER
899
900 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
901 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
902 AC_ARG_ENABLE(bsdpad,
903         [  --enable-bsdpad         recognize BSD-style prefix padding],
904         [with_bsdpad=$enableval],
905         [with_bsdpad=no])
906 AC_MSG_RESULT($with_bsdpad)
907 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
908
909 ###   use option --enable-widec to turn on use of wide-character support
910 NCURSES_CH_T=chtype
911 NCURSES_LIBUTF8=0
912
913 NEED_WCHAR_H=0
914 NCURSES_MBSTATE_T=0
915 NCURSES_WCHAR_T=0
916 NCURSES_WINT_T=0
917
918 # Check to define _XOPEN_SOURCE "automatically"
919 CPPFLAGS_before_XOPEN="$CPPFLAGS"
920 CF_XOPEN_SOURCE(600)
921 CPPFLAGS_after_XOPEN="$CPPFLAGS"
922
923 # Work around breakage on OS X
924 CF_SIGWINCH
925
926 # Checks for CODESET support.
927 AM_LANGINFO_CODESET
928
929 # use these variables to work around a defect in gcc's fixincludes.
930 NCURSES_OK_WCHAR_T=
931 NCURSES_OK_WINT_T=
932
933 AC_MSG_CHECKING(if you want wide-character code)
934 AC_ARG_ENABLE(widec,
935         [  --enable-widec          compile with wide-char/UTF-8 code],
936         [with_widec=$enableval],
937         [with_widec=no])
938 AC_MSG_RESULT($with_widec)
939
940 NCURSES_WCWIDTH_GRAPHICS=1
941 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
942
943 if test "x$with_widec" = xyes ; then
944         if test "x$disable_lib_suffixes" = xno ; then
945                 LIB_SUFFIX="w${LIB_SUFFIX}"
946         fi
947         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
948         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
949
950         CF_CHECK_WCHAR_H
951         CF_CHECK_WCWIDTH_GRAPHICS
952         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
953
954         # with_overwrite=no
955         NCURSES_CH_T=cchar_t
956         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
957         if test "x$ac_cv_func_putwc" != xyes ; then
958                 CF_UTF8_LIB
959                 if test "$cf_cv_utf8_lib" != no ; then
960                         NCURSES_LIBUTF8=1
961                 fi
962         fi
963         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
964         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
965         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
966
967         if test "$NCURSES_MBSTATE_T" != 0; then
968                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
969         fi
970 fi
971 AC_SUBST(NCURSES_CH_T)
972 AC_SUBST(NCURSES_LIBUTF8)
973
974 AC_SUBST(NEED_WCHAR_H)
975 AC_SUBST(NCURSES_MBSTATE_T)
976 AC_SUBST(NCURSES_WCHAR_T)
977 AC_SUBST(NCURSES_WINT_T)
978
979 AC_SUBST(NCURSES_OK_WCHAR_T)
980 AC_SUBST(NCURSES_OK_WINT_T)
981
982 ###   use option --disable-lp64 to allow long chtype
983 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
984 AC_ARG_ENABLE(lp64,
985         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
986         [with_lp64=$enableval],
987         [with_lp64=$cf_dft_with_lp64])
988 AC_MSG_RESULT($with_lp64)
989
990 if test "x$with_lp64" = xyes ; then
991         cf_cv_enable_lp64=1
992 else
993         cf_cv_enable_lp64=0
994 fi
995 AC_SUBST(cf_cv_enable_lp64)
996
997 CF_LARGEFILE
998
999 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
1000 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
1001 AC_ARG_ENABLE(tparm-varargs,
1002         [  --disable-tparm-varargs compile tparm() without varargs interface],
1003         [with_tparm_varargs=$enableval],
1004         [with_tparm_varargs=yes])
1005 AC_MSG_RESULT($with_tparm_varargs)
1006 NCURSES_TPARM_VARARGS=0
1007 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
1008 AC_SUBST(NCURSES_TPARM_VARARGS)
1009
1010 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
1011 if test "$with_ticlib" != no ; then
1012 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
1013 AC_ARG_ENABLE(tic-depends,
1014         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
1015         [with_tic_depends=$enableval],
1016         [with_tic_depends=yes])
1017 AC_MSG_RESULT($with_tic_depends)
1018 else
1019         with_tic_depends=no
1020 fi
1021
1022 ###   use option --enable-wattr-macros to enable wattr* macros in curses.h
1023 AC_MSG_CHECKING(if you want to enable wattr* macros)
1024 AC_ARG_ENABLE(wattr-macros,
1025         [  --enable-wattr-macros   enable wattr* macros],
1026         [with_wattr_macros=$enableval],
1027         [with_wattr_macros=no])
1028 if [[ "x$with_wattr_macros" != xyes ]]; then
1029         NCURSES_WATTR_MACROS=0
1030         AC_MSG_RESULT(no)
1031 else
1032         NCURSES_WATTR_MACROS=1
1033         AC_MSG_RESULT(yes)
1034 fi
1035 AC_SUBST(NCURSES_WATTR_MACROS)
1036
1037 CF_WITH_X11_RGB
1038
1039 ###   use option --with-bool to override bool's type
1040 AC_MSG_CHECKING(for type of bool)
1041 AC_ARG_WITH(bool,
1042         [  --with-bool=TYPE        override fallback type of bool variable],
1043         [NCURSES_BOOL="$withval"],
1044         [NCURSES_BOOL=auto])
1045 AC_MSG_RESULT($NCURSES_BOOL)
1046 AC_SUBST(NCURSES_BOOL)
1047
1048 AC_MSG_CHECKING(for alternate terminal capabilities file)
1049 AC_ARG_WITH(caps,
1050         [  --with-caps=alt         compile with alternate Caps file],
1051         [TERMINFO_CAPS=Caps.$withval],
1052         [TERMINFO_CAPS=Caps])
1053 if test ! -f "${srcdir}/include/${TERMINFO_CAPS}"
1054 then
1055         AC_MSG_WARN(file not found: "${srcdir}/include/${TERMINFO_CAPS}")
1056         TERMINFO_CAPS=Caps
1057 fi
1058 AC_MSG_RESULT($TERMINFO_CAPS)
1059 AC_SUBST(TERMINFO_CAPS)
1060
1061 ###   use option --with-chtype to override chtype's type
1062 AC_MSG_CHECKING(for type of chtype)
1063 AC_ARG_WITH(chtype,
1064         [  --with-chtype=TYPE      override type of chtype],
1065         [NCURSES_CHTYPE="$withval"],
1066         [NCURSES_CHTYPE=$cf_dft_chtype])
1067 AC_MSG_RESULT($NCURSES_CHTYPE)
1068
1069 ###   use option --with-ospeed to override ospeed's type
1070 AC_MSG_CHECKING(for type of ospeed)
1071 AC_ARG_WITH(ospeed,
1072         [  --with-ospeed=TYPE      override type of ospeed variable],
1073         [NCURSES_OSPEED="$withval"],
1074         [NCURSES_OSPEED=short])
1075 AC_MSG_RESULT($NCURSES_OSPEED)
1076 AC_SUBST(NCURSES_OSPEED)
1077
1078 ###   use option --with-mmask-t to override mmask_t's type
1079 AC_MSG_CHECKING(for type of mmask_t)
1080 AC_ARG_WITH(mmask-t,
1081         [  --with-mmask-t=TYPE     override type of mmask_t],
1082         [NCURSES_MMASK_T="$withval"],
1083         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1084 AC_MSG_RESULT($NCURSES_MMASK_T)
1085
1086 ###   use option --with-ccharw-max to override CCHARW_MAX size
1087 AC_MSG_CHECKING(for size CCHARW_MAX)
1088 AC_ARG_WITH(ccharw-max,
1089         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1090         [NCURSES_CCHARW_MAX="$withval"],
1091         [NCURSES_CCHARW_MAX=$cf_dft_ccharw_max])
1092 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1093 AC_SUBST(NCURSES_CCHARW_MAX)
1094
1095 AC_CHECK_SIZEOF([signed char])
1096 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1097         NCURSES_SBOOL="signed char"
1098 else
1099         NCURSES_SBOOL="char"
1100 fi
1101 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1102 AC_ARG_ENABLE(signed-char,
1103         [  --enable-signed-char    compile using signed Boolean's in term.h],
1104         [with_signed_char=$enableval],
1105         [with_signed_char=$cf_dft_signed_char])
1106 AC_MSG_RESULT($with_signed_char)
1107 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1108 AC_SUBST(NCURSES_SBOOL)
1109
1110 ###   use option --with-tparm-arg to override tparm's argument type
1111 AC_MSG_CHECKING(for type of tparm args)
1112 AC_ARG_WITH(tparm-arg,
1113         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1114         [NCURSES_TPARM_ARG="$withval"],
1115         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1116 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1117 AC_SUBST(NCURSES_TPARM_ARG)
1118
1119 ### Enable compiling-in rcs id's
1120 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1121 AC_ARG_WITH(rcs-ids,
1122         [  --with-rcs-ids          compile-in RCS identifiers],
1123         [with_rcs_ids=$withval],
1124         [with_rcs_ids=no])
1125 AC_MSG_RESULT($with_rcs_ids)
1126 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1127
1128 ###############################################################################
1129 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1130
1131 ###############################################################################
1132 CF_HELP_MESSAGE(Extensions:)
1133
1134 ### Note that some functions (such as const) are normally disabled anyway.
1135 AC_MSG_CHECKING(if you want to build with function extensions)
1136 AC_ARG_ENABLE(ext-funcs,
1137         [  --disable-ext-funcs     disable function-extensions],
1138         [with_ext_funcs=$enableval],
1139         [with_ext_funcs=yes])
1140 AC_MSG_RESULT($with_ext_funcs)
1141 if test "x$with_ext_funcs" = xyes ; then
1142         NCURSES_EXT_FUNCS=1
1143         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1144         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1145         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1146         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1147         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1148         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1149         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1150         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1151         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1152         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1153         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1154         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1155         GENERATED_EXT_FUNCS=generated
1156         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1157 else
1158         NCURSES_EXT_FUNCS=0
1159         GENERATED_EXT_FUNCS=
1160 fi
1161 AC_SUBST(NCURSES_EXT_FUNCS)
1162 AC_SUBST(GENERATED_EXT_FUNCS)
1163
1164 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1165 AC_ARG_ENABLE(sp-funcs,
1166         [  --enable-sp-funcs       enable SCREEN-extensions],
1167         [with_sp_funcs=$enableval],
1168         [with_sp_funcs=$cf_dft_ext_spfuncs])
1169 AC_MSG_RESULT($with_sp_funcs)
1170 if test "x$with_sp_funcs" = xyes ; then
1171         NCURSES_SP_FUNCS=1
1172         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1173         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1174         GENERATED_SP_FUNCS=generated
1175 else
1176         NCURSES_SP_FUNCS=0
1177         GENERATED_SP_FUNCS=
1178 fi
1179 AC_SUBST(NCURSES_SP_FUNCS)
1180 AC_SUBST(GENERATED_SP_FUNCS)
1181
1182 AC_MSG_CHECKING(if you want to build with terminal-driver)
1183 AC_ARG_ENABLE(term-driver,
1184         [  --enable-term-driver    enable terminal-driver],
1185         [with_term_driver=$enableval],
1186         [with_term_driver=no])
1187 AC_MSG_RESULT($with_term_driver)
1188 if test "x$with_term_driver" = xyes ; then
1189         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1190         if test "x$with_termlib" != xno ; then
1191                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1192         fi
1193         if test "x$with_sp_funcs" != xyes ; then
1194                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1195         fi
1196 fi
1197
1198 ###   use option --enable-const to turn on use of const beyond that in XSI.
1199 AC_MSG_CHECKING(for extended use of const keyword)
1200 AC_ARG_ENABLE(const,
1201         [  --enable-const          compile with extra/non-standard const],
1202         [with_ext_const=$enableval],
1203         [with_ext_const=$cf_dft_ext_const])
1204 AC_MSG_RESULT($with_ext_const)
1205 NCURSES_CONST='/*nothing*/'
1206 if test "x$with_ext_const" = xyes ; then
1207         NCURSES_CONST=const
1208 fi
1209 AC_SUBST(NCURSES_CONST)
1210
1211 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1212 AC_MSG_CHECKING(if you want to use extended colors)
1213 AC_ARG_ENABLE(ext-colors,
1214         [  --enable-ext-colors     compile for 256-color support],
1215         [with_ext_colors=$enableval],
1216         [with_ext_colors=$cf_dft_ext_colors])
1217 AC_MSG_RESULT($with_ext_colors)
1218 NCURSES_EXT_COLORS=0
1219 if test "x$with_ext_colors" = xyes ; then
1220         if test "x$with_widec" != xyes ; then
1221                 AC_MSG_WARN(This option applies only to wide-character library)
1222         else
1223                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1224                 CF_NCURSES_ABI_6
1225                 NCURSES_EXT_COLORS=1
1226                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1227                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1228                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1229                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1230         fi
1231 fi
1232 AC_SUBST(NCURSES_EXT_COLORS)
1233
1234 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1235 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1236 AC_ARG_ENABLE(ext-mouse,
1237         [  --enable-ext-mouse      compile for extended mouse-encoding],
1238         [with_ext_mouse=$enableval],
1239         [with_ext_mouse=$cf_dft_ext_mouse])
1240 AC_MSG_RESULT($with_ext_mouse)
1241 if test "x$with_ext_mouse" = xyes ; then
1242         CF_NCURSES_ABI_6
1243 fi
1244
1245 case $cf_cv_abi_version in
1246 (5)
1247         NCURSES_MOUSE_VERSION=1
1248         ;;
1249 (6)
1250         NCURSES_MOUSE_VERSION=2
1251         ;;
1252 ([789])
1253         NCURSES_MOUSE_VERSION=3
1254         ;;
1255 esac
1256
1257 AC_SUBST(NCURSES_MOUSE_VERSION)
1258
1259 ###   use option --enable-ext-putwin to turn on extended screendumps
1260 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1261 AC_ARG_ENABLE(ext-putwin,
1262         [  --enable-ext-putwin     compile with extended putwin/screendump],
1263         [with_ext_putwin=$enableval],
1264         [with_ext_putwin=$cf_dft_ext_putwin])
1265 AC_MSG_RESULT($with_ext_putwin)
1266 if test "x$with_ext_putwin" = xyes ; then
1267         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1268 fi
1269
1270 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1271 AC_ARG_ENABLE(no-padding,
1272         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1273         [with_no_padding=$enableval],
1274         [with_no_padding=$with_ext_funcs])
1275 AC_MSG_RESULT($with_no_padding)
1276 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1277
1278 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1279 AC_MSG_CHECKING(if you want SIGWINCH handler)
1280 AC_ARG_ENABLE(sigwinch,
1281         [  --enable-sigwinch       compile with SIGWINCH handler],
1282         [with_sigwinch=$enableval],
1283         [with_sigwinch=$with_ext_funcs])
1284 AC_MSG_RESULT($with_sigwinch)
1285 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1286
1287 ###   use option --enable-tcap-names to allow user to define new capabilities
1288 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1289 AC_ARG_ENABLE(tcap-names,
1290         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1291         [with_tcap_names=$enableval],
1292         [with_tcap_names=$with_ext_funcs])
1293 AC_MSG_RESULT($with_tcap_names)
1294 NCURSES_XNAMES=0
1295 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1296 AC_SUBST(NCURSES_XNAMES)
1297
1298 ##############################################################################
1299 CF_HELP_MESSAGE(Reentrant Code:)
1300 CF_WITH_PTHREAD
1301
1302 if test "x$with_pthread" != xno; then
1303         AC_CHECK_FUNC(pthread_kill,[
1304                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1305                 AC_ARG_ENABLE(pthreads-eintr,
1306                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1307                         [use_pthreads_eintr=$enableval],
1308                         [use_pthreads_eintr=no])
1309                 AC_MSG_RESULT($use_pthreads_eintr)
1310                 if test "x$use_pthreads_eintr" = xyes ; then
1311                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1312                 fi])
1313
1314         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1315         AC_ARG_ENABLE(weak-symbols,
1316                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1317                 [use_weak_symbols=$enableval],
1318                 [use_weak_symbols=no])
1319         AC_MSG_RESULT($use_weak_symbols)
1320         if test "x$use_weak_symbols" = xyes ; then
1321                 CF_WEAK_SYMBOLS
1322         else
1323                 cf_cv_weak_symbols=no
1324         fi
1325
1326         if test "x$cf_cv_weak_symbols" = xyes ; then
1327                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1328         fi
1329 fi
1330
1331 PTHREAD=
1332 if test "x$with_pthread" = "xyes" ; then
1333         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1334         enable_reentrant=yes
1335         if test "x$cf_cv_weak_symbols" = xyes ; then
1336                 PTHREAD=-lpthread
1337                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1338         fi
1339 fi
1340 AC_SUBST(PTHREAD)
1341
1342 # Reentrant code has to be opaque; there's little advantage to making ncurses
1343 # opaque outside of that, so there is no --enable-opaque option.  We can use
1344 # this option without --with-pthreads, but this will be always set for
1345 # pthreads.
1346 AC_MSG_CHECKING(if you want reentrant code)
1347 AC_ARG_ENABLE(reentrant,
1348         [  --enable-reentrant      compile with reentrant code],
1349         [with_reentrant=$enableval],
1350         [with_reentrant=no])
1351 AC_MSG_RESULT($with_reentrant)
1352 if test "x$with_reentrant" = xyes ; then
1353         cf_cv_enable_reentrant=1
1354         cf_cv_enable_opaque="NCURSES_INTERNALS"
1355         NCURSES_SIZE_T=int
1356         if test "x$cf_cv_weak_symbols" = xyes ; then
1357                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1358                 CF_ADD_LIB(pthread,TEST_LIBS)
1359                 CF_ADD_LIB(pthread,TEST_LIBS2)
1360                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1361         else
1362                 # when not using weak symbols but with_reentrant,
1363                 # add 't' to the library suffix on all platforms
1364                 # except cygwin, where we only do that if ALSO
1365                 # compiling with full thread support.
1366                 case "$host" in
1367                 (*cygwin* | *msys*)
1368                         if test "$with_pthread" = "yes" ; then
1369                                 if test "x$disable_lib_suffixes" = "xno" ; then
1370                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1371                                 fi
1372                         fi ;;
1373                 (*)
1374                         if test "x$disable_lib_suffixes" = "xno" ; then
1375                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1376                         fi
1377                         ;;
1378                 esac
1379         fi
1380         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1381         CF_NCURSES_ABI_6
1382 else
1383         cf_cv_enable_reentrant=0
1384         cf_cv_enable_opaque="NCURSES_OPAQUE"
1385         NCURSES_SIZE_T=$cf_dft_ordinate_type
1386 fi
1387 AC_SUBST(cf_cv_enable_reentrant)
1388 AC_SUBST(cf_cv_enable_opaque)
1389
1390 AC_SUBST(NCURSES_SIZE_T)
1391
1392 AC_MSG_CHECKING(if you want opaque curses-library structures)
1393 CF_ARG_ENABLE(opaque-curses,
1394         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1395         [enable_opaque_curses=yes],[
1396          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1397          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=$cf_dft_opaque_curses
1398         ])
1399 AC_MSG_RESULT($enable_opaque_curses)
1400
1401 test "$cf_cv_enable_reentrant" = 1 && \
1402 test "$enable_opaque_curses" = no && \
1403 AC_MSG_ERROR(reentrant configuration requires opaque library)
1404
1405 AC_MSG_CHECKING(if you want opaque form-library structures)
1406 AC_ARG_ENABLE(opaque-form,
1407         [  --enable-opaque-form    make form-library structures "opaque"],
1408         [enable_opaque_form=yes],[enable_opaque_form=no])
1409 AC_MSG_RESULT($enable_opaque_form)
1410
1411 AC_MSG_CHECKING(if you want opaque menu-library structures)
1412 AC_ARG_ENABLE(opaque-menu,
1413         [  --enable-opaque-menu    make menu-library structures "opaque"],
1414         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1415 AC_MSG_RESULT($enable_opaque_menu)
1416
1417 AC_MSG_CHECKING(if you want opaque panel-library structures)
1418 AC_ARG_ENABLE(opaque-panel,
1419         [  --enable-opaque-panel   make panel-library structures "opaque"],
1420         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1421 AC_MSG_RESULT($enable_opaque_panel)
1422
1423 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1424 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1425 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1426 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1427
1428 AC_SUBST(NCURSES_OPAQUE)
1429 AC_SUBST(NCURSES_OPAQUE_FORM)
1430 AC_SUBST(NCURSES_OPAQUE_MENU)
1431 AC_SUBST(NCURSES_OPAQUE_PANEL)
1432
1433 ### Allow using a different wrap-prefix
1434 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1435         AC_MSG_CHECKING(for prefix used to wrap public variables)
1436         AC_ARG_WITH(wrap-prefix,
1437                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1438                 [NCURSES_WRAP_PREFIX=$withval],
1439                 [NCURSES_WRAP_PREFIX=_nc_])
1440         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1441 else
1442         NCURSES_WRAP_PREFIX=_nc_
1443 fi
1444 AC_SUBST(NCURSES_WRAP_PREFIX)
1445 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1446
1447 ###############################################################################
1448 # These options are relatively safe to experiment with.
1449 CF_HELP_MESSAGE(Development Code:)
1450 AC_MSG_CHECKING(if you want all development code)
1451 AC_ARG_WITH(develop,
1452         [  --without-develop       disable development options],
1453         [with_develop=$withval],
1454         [with_develop=no])
1455 AC_MSG_RESULT($with_develop)
1456
1457 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1458 AC_MSG_CHECKING(if you want hard-tabs code)
1459 AC_ARG_ENABLE(hard-tabs,
1460         [  --enable-hard-tabs      compile with hard-tabs code],,
1461         [enable_hard_tabs=$with_develop])
1462 AC_MSG_RESULT($enable_hard_tabs)
1463 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1464
1465 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1466 AC_MSG_CHECKING(if you want limited support for xmc)
1467 AC_ARG_ENABLE(xmc-glitch,
1468         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1469         [enable_xmc_glitch=$with_develop])
1470 AC_MSG_RESULT($enable_xmc_glitch)
1471 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1472
1473 ###############################################################################
1474 # These are just experimental, probably should not be in a package:
1475 CF_HELP_MESSAGE(Experimental Code:)
1476
1477 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1478 AC_ARG_ENABLE(assumed-color,
1479         [  --disable-assumed-color do not assume anything about default-colors],
1480         [with_assumed_color=$enableval],
1481         [with_assumed_color=yes])
1482 AC_MSG_RESULT($with_assumed_color)
1483 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1484
1485 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1486 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1487 AC_ARG_ENABLE(hashmap,
1488         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1489         [with_hashmap=$enableval],
1490         [with_hashmap=yes])
1491 AC_MSG_RESULT($with_hashmap)
1492 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1493
1494 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1495 AC_MSG_CHECKING(if you want colorfgbg code)
1496 AC_ARG_ENABLE(colorfgbg,
1497         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1498         [with_colorfgbg=$enableval],
1499         [with_colorfgbg=no])
1500 AC_MSG_RESULT($with_colorfgbg)
1501 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1502
1503 ###   use option --enable-fvisibility to turn on use of gcc-specific feature
1504 AC_MSG_CHECKING(if you want to use gcc -fvisibility option)
1505 AC_ARG_ENABLE(fvisibility,
1506         [  --enable-fvisibility    compile with -fvisibility=hidden],
1507         [cf_with_fvisibility=$enableval],
1508         [cf_with_fvisibility=no])
1509 AC_MSG_RESULT($cf_with_fvisibility)
1510
1511 NCURSES_IMPEXP=
1512 NCURSES_CXX_IMPEXP=
1513 if test "x$cf_with_fvisibility" = xyes; then
1514         CF_CHECK_FVISIBILITY($CC,CFLAGS,cf_cv_fvisibility_hidden)
1515         if test "x$cf_cv_fvisibility_hidden" = xyes
1516         then
1517                 CF_ADD_CFLAGS([-fvisibility=hidden])
1518                 NCURSES_IMPEXP="__attribute__ ((visibility(\"default\")))"
1519         fi
1520         if test -n "$CXX"
1521         then
1522                 AC_LANG_PUSH(C++)
1523                 CF_CHECK_FVISIBILITY($CXX,CXXFLAGS,cf_cv_fvisibility_hidden2)
1524                 if test "x$cf_cv_fvisibility_hidden2" = xyes
1525                 then
1526                         CF_ADD_CXXFLAGS([-fvisibility=hidden])
1527                         NCURSES_CXX_IMPEXP="__attribute__ ((visibility(\"default\")))"
1528                 fi
1529                 AC_LANG_POP
1530         fi
1531 fi
1532 AC_SUBST(NCURSES_IMPEXP)
1533 AC_SUBST(NCURSES_CXX_IMPEXP)
1534
1535 ###   use option --enable-interop to turn on use of bindings used for interop
1536 AC_MSG_CHECKING(if you want interop bindings)
1537 AC_ARG_ENABLE(interop,
1538         [  --enable-interop        compile-in interop bindings],
1539         [with_exp_interop=$enableval],
1540         [with_exp_interop=$cf_dft_interop])
1541 AC_MSG_RESULT($with_exp_interop)
1542
1543 NCURSES_INTEROP_FUNCS=0
1544 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1545 AC_SUBST(NCURSES_INTEROP_FUNCS)
1546
1547
1548 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1549 AC_ARG_ENABLE(safe-sprintf,
1550         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1551         [with_safe_sprintf=$enableval],
1552         [with_safe_sprintf=no])
1553 AC_MSG_RESULT($with_safe_sprintf)
1554
1555 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1556 # when hashmap is used scroll hints are useless
1557 if test "$with_hashmap" = no ; then
1558 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1559 AC_ARG_ENABLE(scroll-hints,
1560         [  --disable-scroll-hints  compile without scroll-hints code],
1561         [with_scroll_hints=$enableval],
1562         [with_scroll_hints=yes])
1563 AC_MSG_RESULT($with_scroll_hints)
1564 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1565 fi
1566
1567 AC_MSG_CHECKING(if you want wgetch-events code)
1568 AC_ARG_ENABLE(wgetch-events,
1569         [  --enable-wgetch-events  compile with wgetch-events code],
1570         [with_wgetch_events=$enableval],
1571         [with_wgetch_events=no])
1572 AC_MSG_RESULT($with_wgetch_events)
1573 if test "x$with_wgetch_events" = xyes ; then
1574         AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1575         NCURSES_WGETCH_EVENTS=1
1576 else
1577         NCURSES_WGETCH_EVENTS=0
1578 fi
1579 AC_SUBST(NCURSES_WGETCH_EVENTS)
1580
1581 case "$cf_cv_system_name" in
1582 (*mingw32*|*mingw64*|*-msvc*)
1583         AC_MSG_CHECKING(if you want experimental-Windows driver)
1584         AC_ARG_ENABLE(exp-win32,
1585                 [  --enable-exp-win32      compile with experimental-Windows driver],
1586                 [with_exp_win32=$enableval],
1587                 [with_exp_win32=no])
1588         AC_MSG_RESULT($with_exp_win32)
1589         if test "x$with_exp_win32" = xyes
1590         then
1591                 AC_DEFINE(EXP_WIN32_DRIVER,1,[Define to 1 to compile with experimental win32 driver])
1592                 EXP_WIN32_DRIVER=1
1593                 INTERNALS_HDR='[$](INCDIR)/nc_win32.h'
1594         else
1595                 INTERNALS_HDR='[$](INCDIR)/nc_mingw.h'
1596                 EXP_WIN32_DRIVER=0
1597         fi
1598         ;;
1599 (*)
1600         EXP_WIN32_DRIVER=0
1601         INTERNALS_HDR=
1602         ;;
1603 esac
1604 AC_SUBST(EXP_WIN32_DRIVER)
1605 AC_SUBST(INTERNALS_HDR)
1606
1607 ###############################################################################
1608 CF_HELP_MESSAGE(Testing/development Options:)
1609
1610 ###     use option --disable-echo to suppress full display compiling commands
1611 CF_DISABLE_ECHO
1612 if test "x$enable_echo" = xyes; then
1613         ECHO_LINK=
1614 else
1615         ECHO_LINK='@ echo linking $@ ... ;'
1616         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1617         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1618 fi
1619 AC_SUBST(ECHO_LINK)
1620
1621 # --disable-stripping is used for debugging
1622 CF_INSTALL_OPTS
1623
1624 # If we're avoiding relinking of shared libraries during install, that is to
1625 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1626 # the install program has "-p" (for preserving timestamps).
1627 cf_cv_do_reranlib=yes
1628 if test "x$cf_cv_install_p" = xyes
1629 then
1630         if test "x$cf_cv_do_relink" != xyes
1631         then
1632                 cf_cv_do_reranlib=no
1633                 INSTALL_OPT_P="-p"
1634                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1635         fi
1636 fi
1637 AC_SUBST(INSTALL_OPT_P)
1638
1639 ###     use option --enable-warnings to turn on all gcc warnings
1640 CF_ENABLE_WARNINGS(Wno-unknown-pragmas Wswitch-enum,yes)
1641
1642 if test "x$enable_warnings" = "xyes"; then
1643         CF_ADD_ADAFLAGS(-gnatg)
1644         if test "x$cf_with_cxx" = xyes ; then
1645                 CF_GXX_WARNINGS(Wno-unused)
1646         fi
1647 fi
1648 CF_ENABLE_STRING_HACKS
1649
1650 ###     use option --enable-assertions to turn on generation of assertion code
1651 AC_MSG_CHECKING(if you want to enable runtime assertions)
1652 AC_ARG_ENABLE(assertions,
1653         [  --enable-assertions     test: turn on generation of assertion code],
1654         [with_assertions=$enableval],
1655         [with_assertions=no])
1656 AC_MSG_RESULT($with_assertions)
1657 if test -n "$GCC"
1658 then
1659         if test "$with_assertions" = no
1660         then
1661                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1662         else
1663                 CF_ADD_ADAFLAGS(-gnata)
1664         fi
1665 fi
1666
1667 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1668 CF_DISABLE_LEAKS
1669 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1670
1671 ###     use option --enable-expanded to generate certain macros as functions
1672 AC_ARG_ENABLE(expanded,
1673         [  --enable-expanded       test: generate functions for certain macros],
1674         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1675
1676 ###     use option --disable-macros to suppress macros in favor of functions
1677 AC_ARG_ENABLE(macros,
1678         [  --disable-macros        test: use functions rather than macros],
1679         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1680
1681 # Normally we only add trace() to the debug-library.  Allow this to be
1682 # extended to all models of the ncurses library:
1683 cf_all_traces=no
1684 case "$CFLAGS $CPPFLAGS" in
1685 (*-DTRACE*)
1686         cf_all_traces=yes
1687         ;;
1688 esac
1689
1690 AC_MSG_CHECKING(whether to add trace feature to all models)
1691 AC_ARG_WITH(trace,
1692 [  --with-trace            test: add trace() function to all models of ncurses],
1693 [cf_with_trace=$withval],
1694 [cf_with_trace=$cf_all_traces])
1695 AC_MSG_RESULT($cf_with_trace)
1696
1697 if test "x$cf_with_trace" = xyes ; then
1698         LIB_TRACING=all
1699         ADA_TRACE=TRUE
1700         CF_ADD_CFLAGS(-DTRACE)
1701         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1702 else
1703         LIB_TRACING=DEBUG
1704         ADA_TRACE=FALSE
1705 fi
1706
1707 AC_SUBST(ADA_TRACE)
1708
1709 CF_DISABLE_GNAT_PROJECTS
1710
1711 ###     Checks for libraries.
1712 case "$cf_cv_system_name" in
1713 (*mingw32*|*mingw64*)
1714         # Note: WINVER may be a problem with Windows 10
1715         if test "x$with_exp_win32" = xyes ; then
1716                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0600 -DWIN32_LEAN_AND_MEAN"
1717         else
1718                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1719         fi
1720         CF_CHECK_LIBSSP
1721         ;;
1722 (*)
1723 AC_CHECK_FUNC(gettimeofday,
1724         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1725
1726 AC_CHECK_LIB(bsd, gettimeofday,
1727         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1728         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1729         ;;
1730 esac
1731
1732 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1733 AC_SUBST(MATH_LIB)
1734
1735 ###     Checks for header files.
1736 AC_STDC_HEADERS
1737 AC_HEADER_DIRENT
1738 AC_HEADER_TIME
1739 CF_REGEX
1740
1741 dnl These are some other potentially nonportable headers.
1742 AC_CHECK_HEADERS( \
1743 fcntl.h \
1744 getopt.h \
1745 limits.h \
1746 locale.h \
1747 math.h \
1748 poll.h \
1749 sys/ioctl.h \
1750 sys/param.h \
1751 sys/poll.h \
1752 sys/select.h \
1753 sys/time.h \
1754 sys/times.h \
1755 unistd.h \
1756 wctype.h \
1757 )
1758
1759 CF_GETOPT_HEADER
1760
1761 CF_CHECK_ENVIRON(environ)
1762 CF_CHECK_GETENV
1763 if test "x$cf_cv_consistent_getenv" = xno && \
1764         test "x$cf_with_trace" = xyes
1765 then
1766         AC_MSG_WARN(The NCURSES_TRACE environment variable is not supported with this configuration)
1767 fi
1768
1769 CF_SYS_TIME_SELECT
1770
1771 ###     checks for compiler characteristics
1772 AC_LANG_C
1773 AC_C_CONST
1774 CF_C_INLINE(NCURSES_INLINE,1200)
1775 CF_SIG_ATOMIC_T
1776
1777 if test "$NCURSES_CHTYPE" = auto ; then
1778         CF_TYPEOF_CHTYPE
1779 else
1780         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1781 fi
1782 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1783 AC_SUBST(cf_cv_typeof_chtype)
1784
1785 CF_UNSIGNED_LITERALS
1786 cf_cv_1UL="1"
1787 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1788 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1789 AC_SUBST(cf_cv_1UL)
1790
1791 if test "$NCURSES_MMASK_T" = auto ; then
1792         cf_cv_typeof_mmask_t=long
1793 else
1794         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1795 fi
1796 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1797 AC_SUBST(cf_cv_typeof_mmask_t)
1798
1799 ###     Checks for external-data
1800 CF_ERRNO
1801 CF_LINK_DATAONLY
1802
1803 ###     Checks for library functions.
1804 AC_CHECK_FUNCS( \
1805 getcwd \
1806 getegid \
1807 geteuid \
1808 getopt \
1809 issetugid \
1810 localeconv \
1811 poll \
1812 putenv \
1813 remove \
1814 select \
1815 setbuf \
1816 setbuffer \
1817 setenv \
1818 setfsuid \
1819 setvbuf \
1820 sigaction \
1821 sigvec \
1822 snprintf \
1823 strdup \
1824 strstr \
1825 sysconf \
1826 tcgetpgrp \
1827 times \
1828 tsearch \
1829 vsnprintf \
1830 )
1831
1832 CF_FUNC_GETTTYNAM
1833
1834 if test "x$ac_cv_func_getopt" = xno && \
1835    test "x$cf_with_progs$cf_with_tests" != xnono; then
1836         AC_MSG_ERROR(getopt is required for building programs)
1837 fi
1838
1839 if test "x$with_safe_sprintf" = xyes
1840 then
1841         if test "x$ac_cv_func_vsnprintf" = xyes
1842         then
1843                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1844         else
1845                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1846         fi
1847 fi
1848
1849 if test "x$with_getcap" = "xyes" ; then
1850         CF_CGETENT
1851 fi
1852
1853 CF_ISASCII
1854 CF_STRUCT_SIGACTION
1855 CF_FUNC_NANOSLEEP
1856 CF_FUNC_TERMIOS
1857 CF_FUNC_VSSCANF
1858 CF_MKSTEMP
1859
1860 # setup for prototype of fallback for vsscanf()
1861 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1862
1863 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1864 if test "x$cross_compiling" = xyes ; then
1865         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1866 else
1867         AC_FUNC_SETVBUF_REVERSED
1868 fi
1869 AC_CHECK_TYPE(intptr_t, long)
1870 AC_CHECK_TYPE(ssize_t, int)
1871 CF_TYPE_SIGACTION
1872 CF_SIZECHANGE
1873 CF_FUNC_MEMMOVE
1874 CF_FUNC_POLL
1875 CF_VA_COPY
1876 AC_FUNC_VFORK
1877 CF_FOPEN_BIN_R
1878
1879 # special check for test/ditto.c
1880 CF_FUNC_OPENPTY
1881 if test "$cf_cv_func_openpty" != no ; then
1882         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1883         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1884         if test "x$cf_cv_lib_util" = xyes ; then
1885                 CF_ADD_LIB(util,TEST_LIBS)
1886         fi
1887 fi
1888 AC_SUBST(TEST_LIBS)
1889 AC_SUBST(TEST_LIBS2)
1890
1891 if test "$with_hashed_db" != no ; then
1892         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1893         CF_HASHED_DB($with_hashed_db)
1894 fi
1895
1896 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1897 if test -z "$cf_user_CFLAGS" && test "$enable_leaks" = yes ; then
1898         CF_STRIP_G_OPT(CFLAGS)
1899         CF_STRIP_G_OPT(CXXFLAGS)
1900 fi
1901
1902 # Just in case, check if the C compiler has a bool type.
1903 CF_BOOL_DECL(cf_cv_cc_bool_type)
1904
1905 # Check for C++ compiler characteristics (and ensure that it's there!)
1906 if test -n "$CXX" ; then
1907         AC_LANG_CPLUSPLUS
1908         CF_STDCPP_LIBRARY
1909         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1910
1911         case "$GXX_VERSION" in
1912         (1.*|2.[[0-6]]*|[[1-9]][[0-9]].*)
1913                 cf_cxx_library=yes
1914                 ;;
1915         (*-2.7*|2.7*)
1916                 CF_GPP_LIBRARY
1917                 ;;
1918         (*)
1919                 cf_cxx_library=no
1920                 ;;
1921         esac
1922
1923         AC_CHECK_HEADERS(typeinfo)
1924         CF_CXX_IOSTREAM_NAMESPACE
1925         CF_BOOL_DECL
1926         CF_BOOL_SIZE
1927         CF_ETIP_DEFINES
1928         CF_CPP_PARAM_INIT
1929         CF_CPP_STATIC_CAST
1930         CF_CXX_AR_FLAGS
1931 else
1932         cf_cxx_library=no
1933         cf_cv_builtin_bool=1
1934
1935         # Just because we are not configuring against C++ right now does not
1936         # mean that a user will not want to use C++.  Some distributors disable
1937         # the C++ portion of this configuration as a shortcut (or just to avoid
1938         # compiling the demo in the c++ directory).  So we need a reasonable
1939         # default for the 'bool' type.
1940         #
1941         # Caveat: since the storage of the bool type is not standardized, it
1942         # may change.
1943
1944         if test "$NCURSES_BOOL" != auto ; then
1945                 cf_cv_type_of_bool=$NCURSES_BOOL
1946                 cf_cv_header_stdbool_h=0
1947         else
1948                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1949                         CF_BOOL_SIZE
1950                 else
1951                         AC_MSG_CHECKING(for fallback type of bool)
1952                         case "$host_cpu" in
1953                         (i?86)  cf_cv_type_of_bool=char ;;
1954                         (*)     cf_cv_type_of_bool=int  ;;
1955                         esac
1956                         AC_MSG_RESULT($cf_cv_type_of_bool)
1957                 fi
1958         fi
1959 fi
1960 AC_SUBST(CXXLIBS)
1961
1962 # If the C compiler did not declare bool, and we did not determine that the C++
1963 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1964 # ncurses library use the same type as C++ bool.  Note that this allows one to
1965 # specify the type of bool in a configure-script option and postpone
1966 # integration with the C++ compiler provided that the types are compatible.
1967 USE_CXX_BOOL=1
1968 if test "$cf_cv_cc_bool_type" = 1
1969 then
1970         # oops: C has a bool.  Unlikely, but C++ could differ.
1971         USE_CXX_BOOL=0
1972 elif test "$cf_cv_builtin_bool" = 0
1973 then
1974         # C++ has no bool
1975         USE_CXX_BOOL=0
1976 else
1977         # this is the normal case
1978         USE_CXX_BOOL='defined(__cplusplus)'
1979 fi
1980 AC_SUBST(USE_CXX_BOOL)
1981
1982 CF_HELP_MESSAGE(Ada Binding Options:)
1983
1984 dnl If the Ada95 source-tree is present, add that to the build unless it will
1985 dnl not work, or was not requested.
1986 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1987
1988 dnl libtool does not know anything about GNAT, though a change made in 1998
1989 dnl provided for it "someday".  Disable the ada subtree if we are using
1990 dnl libtool -TD 20070714
1991         if test "$cf_with_ada" != "no" ; then
1992                 if test "$with_libtool" != "no"; then
1993                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1994                         cf_with_ada=no
1995                 fi
1996         fi
1997
1998 dnl Check for availability of GNU Ada Translator (GNAT).
1999 dnl At the moment we support no other Ada compiler.
2000         if test "$cf_with_ada" != "no" ; then
2001                 CF_PROG_GNAT
2002                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
2003                         CF_ADD_ADAFLAGS(-gnatpn)
2004                         CF_FIXUP_ADAFLAGS
2005
2006                         CF_GNATPREP_OPT_T
2007
2008                         CF_GNAT_GENERICS
2009                         CF_GNAT_SIGINT
2010                         CF_GNAT_PROJECTS
2011
2012                         CF_WITH_ADA_COMPILER
2013
2014                         cf_ada_package=terminal_interface
2015                         AC_SUBST(cf_ada_package)
2016
2017                         CF_WITH_ADA_INCLUDE
2018                         CF_WITH_ADA_OBJECTS
2019                         CF_WITH_ADA_SHAREDLIB
2020
2021                         # allow the Ada binding to be renamed
2022                         CF_WITH_ADA_LIBNAME(AdaCurses)
2023                 fi
2024         fi
2025 else
2026         cf_with_ada=no
2027 fi
2028
2029 # do this "late" to avoid conflict with header-checks
2030 if test "x$with_widec" = xyes ; then
2031         AC_CHECK_SIZEOF(wchar_t)
2032         # cross-compiling to mingw can run into the problem that attempting to
2033         # link with the regex library fails, causing the test to not set this to
2034         # a number.  "recent" autoconf does not address this problem either -TD
2035         if test -z "$ac_cv_sizeof_wchar_t"
2036         then
2037                 CF_VERBOSE(test failed (assume 2))
2038                 sed /SIZEOF_WCHAR_T/d confdefs.h >confdefs.tmp
2039                 mv confdefs.tmp confdefs.h
2040                 echo "#define SIZEOF_WCHAR_T 2" >>confdefs.h
2041         fi
2042 fi
2043
2044 ### Construct the ncurses library-subsets, if any, from this set of keywords:
2045 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
2046 ###
2047 ### ticlib modules may be a separate library, otherwise contained in termlib.
2048 ### termlib modules may be a separate library, otherwise contained in ncurses.
2049 ###
2050 ### The of "+" or " " between the tokens controls the way the script
2051 ### chooses to split module lists into libraries.
2052 ###
2053 ### (see CF_LIB_RULES).
2054 AC_MSG_CHECKING(for library subsets)
2055 LIB_SUBSETS=
2056
2057 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
2058         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
2059         if test "$with_ticlib" != no ; then
2060                 LIB_SUBSETS="${LIB_SUBSETS} "
2061         else
2062                 LIB_SUBSETS="${LIB_SUBSETS}+"
2063         fi
2064 fi
2065
2066 LIB_SUBSETS="${LIB_SUBSETS}termlib"
2067 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
2068
2069 if test "$with_termlib" != no ; then
2070         LIB_SUBSETS="${LIB_SUBSETS} "
2071 else
2072         LIB_SUBSETS="${LIB_SUBSETS}+"
2073 fi
2074
2075 LIB_SUBSETS="${LIB_SUBSETS}base"
2076
2077 # Most term-driver calls are to tinfo, but some like init_pair are to the
2078 # base library (so it resides in base).
2079 if test "$with_term_driver" != no ; then
2080         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
2081         case "$cf_cv_system_name" in
2082         (*mingw32*|*mingw64*)
2083                 if test "x$with_exp_win32" = xyes ; then
2084                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32"
2085                 else
2086                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
2087                 fi
2088                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
2089                 ;;
2090         (*)
2091                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
2092                 ;;
2093         esac
2094 elif test "x$with_exp_win32" = xyes ; then
2095         case "$cf_cv_system_name" in
2096         (*mingw32*|*mingw64*)
2097                 LIB_SUBSETS="${LIB_SUBSETS}+port_win32"
2098                 ;;
2099         (*)
2100                 ;;
2101         esac
2102 fi
2103
2104 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
2105 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
2106
2107 AC_MSG_RESULT($LIB_SUBSETS)
2108
2109 ### Construct the list of include-directories to be generated
2110 CF_INCLUDE_DIRS
2111 CF_ADA_INCLUDE_DIRS
2112
2113 ### Build up pieces for makefile rules
2114 AC_MSG_CHECKING(default library suffix)
2115 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
2116 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
2117 AC_MSG_RESULT($DFT_ARG_SUFFIX)
2118
2119 AC_MSG_CHECKING(default library-dependency suffix)
2120 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
2121 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
2122 AC_MSG_RESULT($DFT_DEP_SUFFIX)
2123
2124 AC_MSG_CHECKING(default object directory)
2125 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
2126 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
2127 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
2128
2129 if test "x$cf_with_cxx" = xyes ; then
2130 AC_MSG_CHECKING(c++ library-dependency suffix)
2131 if test "$with_libtool" != "no"; then
2132         # libtool thinks it can make c++ shared libraries (perhaps only g++)
2133         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2134 elif test "$with_shared_cxx" != "no"; then
2135         # also for g++ users...
2136         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2137 else
2138         # we normally make a static library because C/C++ library rules differ
2139         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
2140 fi
2141 AC_MSG_RESULT($CXX_LIB_SUFFIX)
2142 AC_SUBST(CXX_LIB_SUFFIX)
2143 fi
2144
2145 # do not want -ldl in build except as needed for -lncurses dependency
2146 if test "x$with_dlsym" = xyes ; then
2147 if test "$DFT_LWR_MODEL" = shared || \
2148    test "$DFT_LWR_MODEL" = libtool ; then
2149         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2150 fi
2151 fi
2152 ### Set up low-level terminfo dependencies for makefiles.
2153
2154 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2155 # do not need libdl
2156 TICS_LIST=
2157 if test "x$with_dlsym" = xyes ; then
2158         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2159 fi
2160
2161 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2162 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2163 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2164 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2165 then
2166         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2167 fi
2168 AC_SUBST(USE_ARG_SUFFIX)
2169 AC_SUBST(USE_CFG_SUFFIX)
2170 AC_SUBST(USE_LIB_SUFFIX)
2171
2172 if test "$with_ticlib" != no ; then
2173
2174         if test "x$with_ticlib" != xyes ; then
2175                 TICS_NAME=$with_ticlib
2176                 TICS_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2177                 TICS_ARG_SUFFIX="${with_ticlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2178                 TICS_DEP_SUFFIX="${with_ticlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2179                 TICS_LIB_SUFFIX="${with_ticlib}"
2180         else
2181                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2182                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2183                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2184                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2185         fi
2186         TICS_LDFLAGS="-L${LIB_DIR}"
2187         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2188 else
2189         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2190         TICS_LDFLAGS="-L${LIB_DIR}"
2191         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2192 fi
2193 AC_SUBST(TICS_ARG_SUFFIX)
2194 AC_SUBST(TICS_DEP_SUFFIX)
2195 AC_SUBST(TICS_LIB_SUFFIX)
2196 AC_SUBST(TICS_LDFLAGS)
2197 AC_SUBST(TICS_LIBS)
2198
2199 if test "$with_termlib" != no ; then
2200
2201         if test "x$with_termlib" != xyes ; then
2202                 TINFO_NAME=$with_termlib
2203                 TINFO_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2204                 TINFO_ARG_SUFFIX="${with_termlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2205                 TINFO_DEP_SUFFIX="${with_termlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2206                 TINFO_LIB_SUFFIX="${with_termlib}"
2207         else
2208                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2209                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2210                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2211                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2212         fi
2213
2214         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2215         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2216         if test "$DFT_LWR_MODEL" = "libtool"; then
2217                 TEST_ARGS="${TEST_DEPS}"
2218                 TEST_ARG2="${TEST_DEP2}"
2219                 TINFO_LDFLAGS="-L${LIB_DIR}"
2220                 TINFO_LIBS="$TEST_ARGS"
2221                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2222                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2223         else
2224                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2225                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2226                 if test "x$with_term_driver" != xno ; then
2227                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2228                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2229                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2230                 else
2231                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2232                         TINFO_LIBS="$TEST_ARGS"
2233                 fi
2234                 TINFO_LDFLAGS="-L${LIB_DIR}"
2235                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2236         fi
2237 else
2238         # the next lines are needed for linking libtic over libncurses
2239         TINFO_NAME=${LIB_NAME}
2240         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2241         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2242         if test "x$with_tic_depends" = xyes ; then
2243                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2244         else
2245                 TICS_LIST="$SHLIB_LIST"
2246         fi
2247
2248         TINFO_LDFLAGS="-L${LIB_DIR}"
2249         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2250 fi
2251
2252 if test "$DFT_LWR_MODEL" = shared ; then
2253         case "$cf_cv_system_name" in
2254         (cygwin*|msys*)
2255                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2256                 TINFO_SUFFIX=.dll
2257                 ;;
2258         esac
2259 fi
2260
2261 AC_SUBST(TINFO_ARG_SUFFIX)
2262 AC_SUBST(TINFO_DEP_SUFFIX)
2263 AC_SUBST(TINFO_LIB_SUFFIX)
2264 AC_SUBST(TINFO_LDFLAGS)
2265 AC_SUBST(TINFO_LIBS)
2266
2267 if test "x$with_dlsym" = xyes ; then
2268         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2269 fi
2270
2271 if test "$DFT_LWR_MODEL" = "libtool"; then
2272         OBJEXT=lo
2273 fi
2274
2275 # needed for Ada95
2276 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2277 AC_SUBST(TINFO_LDFLAGS2)
2278
2279 case "$DFT_LWR_MODEL" in
2280 (normal|debug|profile)
2281         CF_LDFLAGS_STATIC
2282         ;;
2283 esac
2284
2285 AC_MSG_CHECKING(where we will install curses.h)
2286 AC_SUBST(includesubdir)
2287 includesubdir=
2288 if test "$with_overwrite" = no && \
2289  { test "x$includedir" = 'x${prefix}/include' || \
2290    test "x$includedir" = "x${prefix}/include"; }
2291 then
2292         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2293 fi
2294 AC_MSG_RESULT(${includedir}${includesubdir})
2295
2296 ### Resolve a conflict between normal and wide-curses by forcing applications
2297 ### that will need libutf8 to add it to their configure script.
2298 if test "$with_overwrite" != no ; then
2299 if test "$NCURSES_LIBUTF8" = 1 ; then
2300         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2301         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2302 fi
2303 fi
2304 WITH_OVERWRITE=$with_overwrite
2305
2306 ### At least on MinGW a shared library build without libtool
2307 ### requires adding the additional libs to the link list.
2308 case "$cf_cv_system_name" in
2309 (*mingw32*|*mingw64*)
2310         if test "$DFT_LWR_MODEL" != "libtool"; then
2311            SHLIB_LIST="$SHLIB_LIST ${LIBS}"
2312         fi
2313         ;;
2314 *)      ;;
2315 esac
2316
2317 AC_SUBST(WITH_OVERWRITE)
2318 AC_SUBST(TICS_LIST)
2319 AC_SUBST(TINFO_LIST)
2320 AC_SUBST(SHLIB_LIST)
2321
2322 # used to separate tack out of the tree
2323 NCURSES_TREE=
2324 AC_SUBST(NCURSES_TREE)
2325
2326 ### predefined stuff for the test programs
2327 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2328
2329 # pkgsrc uses these
2330 CF_WITH_LIB_BASENAME(FORM_NAME,form)
2331 CF_WITH_LIB_BASENAME(MENU_NAME,menu)
2332 CF_WITH_LIB_BASENAME(PANEL_NAME,panel)
2333 CF_WITH_LIB_BASENAME(CXX_NAME,cxx,ncurses++)
2334
2335 ### Construct the list of subdirectories for which we'll customize makefiles
2336 ### with the appropriate compile-rules.
2337
2338 CF_SRC_MODULES($modules_to_build)
2339
2340 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2341    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/src/library.gpr:Ada95/src/library.gpr.in"
2342    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2343    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2344 fi
2345
2346 CF_DIRS_TO_MAKE
2347
2348 # symbols that differ when compiling Ada95 by itself.
2349 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2350 AC_SUBST(NCURSES_SHLIB2)
2351
2352 # values to use as strings
2353 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2354
2355 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2356
2357 ### Define substitutions for header files to avoid name-pollution
2358 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2359 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2360 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2361 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2362
2363 ################################################################################
2364 test "x$use_database" = xyes && \
2365 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2366
2367 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2368 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2369
2370 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2371 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2372 fi
2373 AC_SUBST(cross_compiling)
2374
2375 if test "x$cf_with_tests" != xno ; then
2376         MAKE_TESTS=
2377 else
2378         MAKE_TESTS="#"
2379 fi
2380 AC_SUBST(MAKE_TESTS)
2381
2382 ADAHTML_DIR=../../doc/html/ada
2383 AC_SUBST(ADAHTML_DIR)
2384
2385 # workaround for OS/2 (20151017)
2386 case "$cf_cv_system_name" in
2387 (os2*)
2388         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2389         ;;
2390 (*)
2391         LIBTOOL_OPTS_CXX=
2392         ;;
2393 esac
2394 AC_SUBST(LIBTOOL_OPTS_CXX)
2395
2396 # workaround for g++ versus Solaris (20131116)
2397 case "$cf_cv_system_name" in
2398 (solaris2*)
2399         case "x$CPPFLAGS" in
2400         (*-D_XOPEN_SOURCE_EXTENDED*)
2401                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2402                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2403                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2404                 ;;
2405         esac
2406         ;;
2407 esac
2408
2409 # Help to automatically enable the extended curses features when using either
2410 # the *-config or the ".pc" files by adding defines.
2411 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2412 PKG_CFLAGS=
2413 for cf_loop1 in $CPPFLAGS_after_XOPEN
2414 do
2415         cf_found=no
2416         for cf_loop2 in $CPPFLAGS_before_XOPEN
2417         do
2418                 if test "x$cf_loop1" = "x$cf_loop2"
2419                 then
2420                         cf_found=yes
2421                         break
2422                 fi
2423         done
2424         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2425 done
2426 AC_MSG_RESULT($PKG_CFLAGS)
2427 AC_SUBST(PKG_CFLAGS)
2428
2429 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2430 case "x$NCURSES_OSPEED" in
2431 (*short*)
2432         cf_compatible=1
2433         ;;
2434 (*)
2435         cf_compatible=0
2436         ;;
2437 esac
2438 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2439
2440 case "x$cf_cv_typeof_chtype" in
2441 (xshort|xint|xlong)
2442         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2443         ;;
2444 esac
2445
2446 case "x$cf_cv_typeof_mmask_t" in
2447 (xshort|xint|xlong)
2448         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2449         ;;
2450 esac
2451
2452 # substitute into misc/Makefile to suppress
2453 # (un)install.data from the
2454 # (un)install rules.
2455 if test "x$cf_with_db_install" = "xno"; then
2456         MISC_INSTALL_DATA=
2457         MISC_UNINSTALL_DATA=
2458 else
2459         MISC_INSTALL_DATA=install.data
2460         MISC_UNINSTALL_DATA=uninstall.data
2461 fi
2462 AC_SUBST(MISC_INSTALL_DATA)
2463 AC_SUBST(MISC_UNINSTALL_DATA)
2464
2465 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2466         MAKE_DATABASE="#"
2467 else
2468         MAKE_DATABASE="$MAKE_TERMINFO"
2469 fi
2470 AC_SUBST(MAKE_DATABASE)
2471
2472 dnl Override the package used for exported symbols
2473 if test -n "$PACKAGE"
2474 then
2475         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2476         export PACKAGE
2477         echo "package: $PACKAGE"
2478 fi
2479
2480 UNALTERED_SYMS=
2481 cf_filter_syms=no
2482
2483 if test -n "$RESULTING_SYMS"
2484 then
2485         cf_filter_syms=$cf_dft_filter_syms
2486         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2487 fi
2488
2489 if test "x$WILDCARD_SYMS" = xno
2490 then
2491         cf_filter_syms=yes
2492 fi
2493
2494 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2495
2496 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2497 if test "$cf_filter_syms" = yes
2498 then
2499         RESULTING_SYMS=resulting.map
2500 fi
2501 AC_SUBST(UNALTERED_SYMS)
2502
2503 if test "x$cross_compiling" = xyes ; then
2504         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2505         CHECK_BUILD="#"
2506 else
2507         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2508         CHECK_BUILD=
2509 fi
2510 AC_SUBST(ADAGEN_LDFLAGS)
2511 AC_SUBST(CHECK_BUILD)
2512 AC_SUBST(PRIVATE_LIBS)
2513
2514 # This is used for the *-config script and *.pc data files.
2515 CF_LD_SEARCHPATH
2516
2517 AC_DEFINE(HAVE_CURSES_DATA_BOOLNAMES,1,[definition needed for in-tree build of tack])
2518
2519 AC_OUTPUT( \
2520         include/MKterm.h.awk \
2521         include/curses.head:include/curses.h.in \
2522         include/ncurses_dll.h \
2523         include/termcap.h \
2524         include/unctrl.h \
2525         $SUB_MAKEFILES \
2526         Makefile,[
2527 if test "x$cf_with_tests" != xno ; then
2528         CF_PRG_RULES(["$srcdir/test/mk-test.awk" INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2529 fi
2530 CF_LIB_RULES($SRC_SUBDIRS)
2531
2532 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2533 if test -z "$USE_OLD_MAKERULES" ; then
2534         $AWK -f "$srcdir/Ada95/mk-1st.awk" <"$srcdir/Ada95/src/modules" >>Ada95/src/Makefile
2535 fi
2536 fi
2537 ],[
2538 ### Special initialization commands, used to pass information from the
2539 ### configuration-run into config.status
2540
2541 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2542 AWK="$AWK"
2543 CXX_NAME="$CXX_NAME"
2544 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2545 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2546 ECHO_LD="$ECHO_LD"
2547 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2548 FORM_NAME="$FORM_NAME"
2549 LDCONFIG="$LDCONFIG"
2550 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2551 LIB_NAME="$LIB_NAME"
2552 LIB_PREFIX="$LIB_PREFIX"
2553 LIB_SUBSETS="$LIB_SUBSETS"
2554 LIB_SUFFIX="$LIB_SUFFIX"
2555 LIB_TRACING="$LIB_TRACING"
2556 LN_S="$LN_S"
2557 MAKE_TERMINFO="$MAKE_TERMINFO"
2558 MENU_NAME="$MENU_NAME"
2559 NCURSES_MAJOR="$NCURSES_MAJOR"
2560 NCURSES_MINOR="$NCURSES_MINOR"
2561 NCURSES_OSPEED="$NCURSES_OSPEED"
2562 NCURSES_PATCH="$NCURSES_PATCH"
2563 PANEL_NAME="$PANEL_NAME"
2564 SRC_SUBDIRS="$SRC_SUBDIRS"
2565 TERMINFO="$TERMINFO"
2566 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2567 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2568 TICS_NAME="$TICS_NAME"
2569 TICS_SUFFIX="$TICS_SUFFIX"
2570 TIC_PATH="$TIC_PATH"
2571 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2572 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2573 TINFO_NAME="$TINFO_NAME"
2574 TINFO_SUFFIX="$TINFO_SUFFIX"
2575 UNALTERED_SYMS="$UNALTERED_SYMS"
2576 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2577 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2578 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2579 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2580 WILDCARD_SYMS="$WILDCARD_SYMS"
2581 WITH_CURSES_H="$with_curses_h"
2582 WITH_ECHO="${enable_echo:=yes}"
2583 WITH_OVERWRITE="$with_overwrite"
2584 cf_LIST_MODELS="$cf_list_models"
2585 cf_cv_VERSION_GNATMAKE=$cf_cv_VERSION_GNATMAKE
2586 cf_cv_VERSION_GPRBUILD=$cf_cv_VERSION_GPRBUILD
2587 cf_cv_abi_version="$cf_cv_abi_version"
2588 cf_cv_do_relink="$cf_cv_do_relink"
2589 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2590 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2591 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2592 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2593 cf_cv_make_PHONY="$cf_cv_make_PHONY"
2594 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2595 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2596 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2597 cf_cv_rel_version="$cf_cv_rel_version"
2598 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2599 cf_cv_shared_soname='$cf_cv_shared_soname'
2600 cf_cv_shlib_version="$cf_cv_shlib_version"
2601 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2602 cf_cv_system_name="$cf_cv_system_name"
2603 cf_cv_term_driver="$with_term_driver"
2604 cf_with_ada="$cf_with_ada"
2605 cf_with_cxx_binding="$cf_with_cxx_binding"
2606 cf_with_db_install="$cf_with_db_install"
2607 cf_with_manpages="$cf_with_manpages"
2608 cf_with_tests="$cf_with_tests"
2609 host="$host"
2610 target="$target"
2611 with_shared_cxx="$with_shared_cxx"
2612
2613 ],cat)dnl
2614 ${MAKE:-make} preinstall