configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2008,2009 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.472 2009/07/18 16:18:30 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.472 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to install manpages)
 126 AC_ARG_WITH(manpages,
 127         [  --without-manpages      suppress install of manpages],
 128         [cf_with_manpages=$withval],
 129         [cf_with_manpages=yes])
 130 AC_MSG_RESULT($cf_with_manpages)
 131
 132 AC_MSG_CHECKING(if you want to build programs such as tic)
 133 AC_ARG_WITH(progs,
 134         [  --without-progs         suppress build with programs (e.g., tic)],
 135         [cf_with_progs=$withval],
 136         [cf_with_progs=yes])
 137 AC_MSG_RESULT($cf_with_progs)
 138
 139 AC_MSG_CHECKING(if you wish to install curses.h)
 140 AC_ARG_WITH(curses-h,
 141         [  --without-curses-h      install curses.h as ncurses.h only],
 142         [with_curses_h=$withval],
 143         [with_curses_h=yes])
 144 AC_MSG_RESULT($with_curses_h)
 145
 146 modules_to_build="ncurses"
 147 if test "X$cf_with_progs" != Xno ; then
 148 modules_to_build="$modules_to_build progs tack"
 149 fi
 150 modules_to_build="$modules_to_build panel menu form"
 151
 152 AC_ARG_PROGRAM
 153
 154 CF_PROG_AWK
 155 CF_PROG_EGREP
 156 CF_PROG_INSTALL
 157 CF_PROG_LINT
 158 AC_PROG_LN_S
 159
 160 AC_SYS_LONG_FILE_NAMES
 161
 162 # if we find pkg-config, check if we should install the ".pc" files.
 163 CF_PKG_CONFIG
 164
 165 if test "$PKG_CONFIG" != no ; then
 166         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
 167
 168         # Leave this as something that can be overridden in the environment.
 169         if test -z "$PKG_CONFIG_LIBDIR" ; then
 170                 PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`/lib/pkgconfig
 171         fi
 172
 173         if test -d "$PKG_CONFIG_LIBDIR" ; then
 174                 AC_ARG_ENABLE(pc-files,
 175                         [  --enable-pc-files       generate and install .pc files for pkg-config],
 176                         [enable_pc_files=$enableval],
 177                         [enable_pc_files=no])
 178                 AC_MSG_RESULT($enable_pc_files)
 179         else
 180                 AC_MSG_RESULT(no)
 181                 AC_MSG_WARN(did not find library $PKG_CONFIG_LIBDIR)
 182                 enable_pc_files=no
 183         fi
 184 fi
 185 AC_SUBST(PKG_CONFIG_LIBDIR)
 186
 187 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 188 AC_ARG_ENABLE(mixed-case,
 189         [  --enable-mixed-case     tic should assume mixed-case filenames],
 190         [enable_mixedcase=$enableval],
 191         [enable_mixedcase=auto])
 192 AC_MSG_RESULT($enable_mixedcase)
 193 if test "$enable_mixedcase" = "auto" ; then
 194     CF_MIXEDCASE_FILENAMES
 195 else
 196     cf_cv_mixedcase=$enable_mixedcase
 197     if test "$enable_mixedcase" = "yes" ; then
 198         AC_DEFINE(MIXEDCASE_FILENAMES)
 199     fi
 200 fi
 201
 202 # do this after mixed-case option (tags/TAGS is not as important as tic).
 203 AC_PROG_MAKE_SET
 204 CF_MAKE_TAGS
 205 CF_MAKEFLAGS
 206
 207 dnl These are standard among *NIX systems, but not when cross-compiling
 208 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 209 AC_CHECK_TOOL(LD, ld, ld)
 210 AC_CHECK_TOOL(AR, ar, ar)
 211 CF_AR_FLAGS
 212
 213 dnl Special option for use by system-builders: the install-prefix is used to
 214 dnl adjust the location into which the actual install is done, so that an
 215 dnl archive can be built without modifying the host system's configuration.
 216 AC_MSG_CHECKING(if you have specified an install-prefix)
 217 AC_ARG_WITH(install-prefix,
 218         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 219         [case "$withval" in #(vi
 220         yes|no) #(vi
 221                 ;;
 222         *)      DESTDIR="$withval"
 223                 ;;
 224         esac])
 225 AC_MSG_RESULT($DESTDIR)
 226 AC_SUBST(DESTDIR)
 227
 228 ###############################################################################
 229 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 230 # If we're cross-compiling, allow the user to override the tools and their
 231 # options.  The configure script is oriented toward identifying the host
 232 # compiler, etc., but we need a build compiler to generate parts of the source.
 233 CF_BUILD_CC
 234
 235 ###############################################################################
 236 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 237
 238 ### Options to allow the user to specify the set of libraries which are used.
 239 ### Use "--without-normal --with-shared" to allow the default model to be
 240 ### shared, for example.
 241 cf_list_models=""
 242 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 243
 244 CF_WITH_LIBTOOL
 245 if test "$with_libtool" != "no" ; then
 246
 247 cf_list_models="$cf_list_models libtool"
 248
 249 else
 250
 251 AC_MSG_CHECKING(if you want to build shared libraries)
 252 AC_ARG_WITH(shared,
 253         [  --with-shared           generate shared-libraries],
 254         [with_shared=$withval],
 255         [with_shared=no])
 256 AC_MSG_RESULT($with_shared)
 257 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 258
 259 AC_MSG_CHECKING(if you want to build static libraries)
 260 AC_ARG_WITH(normal,
 261         [  --with-normal           generate normal-libraries (default)],
 262         [with_normal=$withval],
 263         [with_normal=yes])
 264 AC_MSG_RESULT($with_normal)
 265 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 266
 267 AC_MSG_CHECKING(if you want to build debug libraries)
 268 AC_ARG_WITH(debug,
 269         [  --with-debug            generate debug-libraries (default)],
 270         [with_debug=$withval],
 271         [with_debug=yes])
 272 AC_MSG_RESULT($with_debug)
 273 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 274
 275 AC_MSG_CHECKING(if you want to build profiling libraries)
 276 AC_ARG_WITH(profile,
 277         [  --with-profile          generate profile-libraries],
 278         [with_profile=$withval],
 279         [with_profile=no])
 280 AC_MSG_RESULT($with_profile)
 281 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 282
 283 fi
 284
 285 ###############################################################################
 286
 287 AC_MSG_CHECKING(for specified models)
 288 test -z "$cf_list_models" && cf_list_models=normal
 289 dnl If we use libtool to generate libraries, then it must be the only
 290 dnl specified model.
 291 test "$with_libtool" != "no" && cf_list_models=libtool
 292 AC_MSG_RESULT($cf_list_models)
 293
 294 ### Use the first model as the default, and save its suffix for use in building
 295 ### up test-applications.
 296 AC_MSG_CHECKING(for default model)
 297 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 298 AC_MSG_RESULT($DFT_LWR_MODEL)
 299
 300 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 301
 302 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 303 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 304
 305 TICS_NAME=tic
 306 AC_SUBST(TICS_NAME)
 307
 308 TINFO_NAME=tinfo
 309 AC_SUBST(TINFO_NAME)
 310
 311 LIB_NAME=ncurses
 312 AC_SUBST(LIB_NAME)
 313
 314 LIB_DIR=../lib
 315 LIB_2ND=../../lib
 316
 317 CF_LIB_PREFIX(cf_prefix)
 318 LIB_PREFIX=$cf_prefix
 319 AC_SUBST(LIB_PREFIX)
 320
 321 LIB_SUFFIX=
 322 AC_SUBST(LIB_SUFFIX)
 323
 324 ###############################################################################
 325
 326 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 327 AC_ARG_WITH(termlib,
 328         [  --with-termlib          generate separate terminfo library],
 329         [with_termlib=$withval],
 330         [with_termlib=no])
 331 AC_MSG_RESULT($with_termlib)
 332
 333 AC_MSG_CHECKING(if you want to build a separate tic library)
 334 AC_ARG_WITH(ticlib,
 335         [  --with-ticlib           generate separate tic library],
 336         [with_ticlib=$withval],
 337         [with_ticlib=no])
 338 AC_MSG_RESULT($with_ticlib)
 339
 340 ### Checks for special libraries, must be done up-front.
 341 SHLIB_LIST=""
 342 CF_WITH_GPM
 343 if test "$with_gpm" != no ; then
 344         AC_MSG_CHECKING(if you want to load GPM dynamically)
 345         AC_ARG_WITH(dlsym,
 346                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 347                 [with_dlsym=$withval],
 348                 [with_dlsym=yes])
 349         AC_MSG_RESULT($with_dlsym)
 350         if test "$with_dlsym" = yes ; then
 351                 CF_FUNC_DLSYM
 352                 if test "$with_gpm" != yes ; then
 353                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 354                         cf_cv_gpm_soname="$with_gpm"
 355                 else
 356                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 357                 fi
 358                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 359                 SHLIB_LIST="-ldl $SHLIB_LIST"
 360         else
 361                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 362         fi
 363         AC_DEFINE(HAVE_LIBGPM)
 364         CF_CHECK_GPM_WGETCH
 365 fi
 366
 367 CF_WITH_SYSMOUSE
 368
 369 dnl Not all ports of gcc support the -g option
 370
 371 if test X"$CC_G_OPT" = X"" ; then
 372         CC_G_OPT='-g'
 373         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 374 fi
 375 AC_SUBST(CC_G_OPT)
 376
 377 if test X"$CXX_G_OPT" = X"" ; then
 378         CXX_G_OPT='-g'
 379         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 380 fi
 381 AC_SUBST(CXX_G_OPT)
 382
 383 AC_MSG_CHECKING(for default loader flags)
 384 case $DFT_LWR_MODEL in
 385 libtool) LD_MODEL=''   ;;
 386 normal)  LD_MODEL=''   ;;
 387 debug)   LD_MODEL=$CC_G_OPT ;;
 388 profile) LD_MODEL='-pg';;
 389 shared)  LD_MODEL=''   ;;
 390 esac
 391 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 392 AC_MSG_RESULT($LD_MODEL)
 393
 394 case $DFT_LWR_MODEL in
 395 shared)
 396 CF_ENABLE_RPATH
 397 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 398 AC_ARG_ENABLE(relink,
 399 [  --disable-relink        relink shared libraries during install],
 400 [cf_cv_do_relink=$enableval],
 401 [cf_cv_do_relink=yes])
 402 AC_MSG_RESULT($cf_cv_do_relink)
 403         ;;
 404 esac
 405
 406 CF_SHARED_OPTS
 407 if test "$CC_SHARED_OPTS" = "unknown"; then
 408         for model in $cf_list_models; do
 409                 if test "$model" = "shared"; then
 410                         AC_ERROR(Shared libraries are not supported in this version)
 411                 fi
 412         done
 413 fi
 414
 415 ###############################################################################
 416 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 417
 418 ###     use option --disable-overwrite to leave out the link to -lcurses
 419 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 420 AC_ARG_ENABLE(overwrite,
 421         [  --disable-overwrite     leave out the link to -lcurses],
 422         [with_overwrite=$enableval],
 423         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 424 AC_MSG_RESULT($with_overwrite)
 425
 426 AC_MSG_CHECKING(if external terminfo-database is used)
 427 AC_ARG_ENABLE(database,
 428         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 429         [use_database=$enableval],
 430         [use_database=yes])
 431 AC_MSG_RESULT($use_database)
 432
 433 case $host_os in #(vi
 434 os2*) #(vi
 435         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 436         ;;
 437 *) #(vi
 438         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 439         ;;
 440 esac
 441 AC_SUBST(TERMINFO_SRC)
 442
 443 CF_PATHSEP
 444 if test "$use_database" != no ; then
 445         AC_DEFINE(USE_DATABASE)
 446
 447         AC_MSG_CHECKING(which terminfo source-file will be installed)
 448         AC_ARG_ENABLE(database,
 449                 [  --with-database=XXX     specify terminfo source to install],
 450                 [TERMINFO_SRC=$withval])
 451         AC_MSG_RESULT($TERMINFO_SRC)
 452
 453         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 454         AC_ARG_WITH(hashed-db,
 455                 [  --with-hashed-db        specify hashed-database library],,
 456                 [with_hashed_db=no])
 457         AC_MSG_RESULT($with_hashed_db)
 458 else
 459         with_hashed_db=no
 460 fi
 461
 462 AC_MSG_CHECKING(for list of fallback descriptions)
 463 AC_ARG_WITH(fallbacks,
 464         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 465         [with_fallback=$withval],
 466         [with_fallback=])
 467 AC_MSG_RESULT($with_fallback)
 468 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 469 AC_SUBST(FALLBACK_LIST)
 470
 471 AC_MSG_CHECKING(if you want modern xterm or antique)
 472 AC_ARG_WITH(xterm-new,
 473         [  --without-xterm-new     specify if xterm terminfo should be old version],
 474         [with_xterm_new=$withval],
 475         [with_xterm_new=yes])
 476 case $with_xterm_new in
 477 no)     with_xterm_new=xterm-old;;
 478 *)      with_xterm_new=xterm-new;;
 479 esac
 480 AC_MSG_RESULT($with_xterm_new)
 481 WHICH_XTERM=$with_xterm_new
 482 AC_SUBST(WHICH_XTERM)
 483
 484 MAKE_TERMINFO=
 485 if test "$use_database" = no ; then
 486         TERMINFO="${datadir}/terminfo"
 487         MAKE_TERMINFO="#"
 488 else
 489
 490 AC_MSG_CHECKING(for list of terminfo directories)
 491 CF_WITH_PATHLIST(terminfo-dirs,
 492         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 493         TERMINFO_DIRS,
 494         DATADIR/terminfo,
 495         ${datadir}/terminfo)
 496 AC_MSG_RESULT($TERMINFO_DIRS)
 497 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 498
 499 AC_MSG_CHECKING(for default terminfo directory)
 500 CF_WITH_PATH(default-terminfo-dir,
 501         [  --with-default-terminfo-dir=DIR default terminfo directory],
 502         TERMINFO,
 503         DATADIR/terminfo,
 504         ${datadir}/terminfo)
 505 AC_MSG_RESULT($TERMINFO)
 506 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 507
 508 fi
 509
 510 AC_SUBST(TERMINFO)
 511 AC_SUBST(MAKE_TERMINFO)
 512
 513 ###     use option --disable-big-core to make tic run on small machines
 514 ###     We need 4Mb, check if we can allocate 50% more than that.
 515 AC_MSG_CHECKING(if big-core option selected)
 516 AC_ARG_ENABLE(big-core,
 517         [  --disable-big-core      assume machine has little memory],
 518         [with_big_core=$enableval],
 519         [AC_TRY_RUN([
 520 #include <stdlib.h>
 521 #include <string.h>
 522 int main() {
 523         unsigned long n = 6000000L;
 524         char *s = malloc(n);
 525         if (s != 0)
 526                 s[0] = s[n-1] = 0;
 527         ${cf_cv_main_return:-return}(s == 0);
 528 }],
 529         [with_big_core=yes],
 530         [with_big_core=no],
 531         [with_big_core=no])])
 532 AC_MSG_RESULT($with_big_core)
 533 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 534
 535 ### ISO C only guarantees 512-char strings, we have tables which load faster
 536 ### when constructed using "big" strings.  More than the C compiler, the awk
 537 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 538 AC_MSG_CHECKING(if big-strings option selected)
 539 AC_ARG_ENABLE(big-strings,
 540         [  --disable-big-strings   assume compiler has only standard-size strings],
 541         [with_big_strings=$enableval],
 542         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 543 AC_MSG_RESULT($with_big_strings)
 544
 545 USE_BIG_STRINGS=0
 546 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
 547 AC_SUBST(USE_BIG_STRINGS)
 548
 549 ###     use option --enable-termcap to compile in the termcap fallback support
 550 AC_MSG_CHECKING(if you want termcap-fallback support)
 551 AC_ARG_ENABLE(termcap,
 552         [  --enable-termcap        compile in termcap fallback support],
 553         [with_termcap=$enableval],
 554         [with_termcap=no])
 555 AC_MSG_RESULT($with_termcap)
 556
 557 if test "$with_termcap" != "yes" ; then
 558         if test "$use_database" = no ; then
 559                 if test -z "$with_fallback" ; then
 560                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 561                 fi
 562         fi
 563         AC_DEFINE(PURE_TERMINFO)
 564 else
 565
 566 if test "$with_ticlib" != no ; then
 567         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 568 fi
 569
 570 AC_DEFINE(USE_TERMCAP)
 571 AC_MSG_CHECKING(for list of termcap files)
 572 CF_WITH_PATHLIST(termpath,
 573         [  --with-termpath=XXX     specify list of termcap files],
 574         TERMPATH,
 575         /etc/termcap:/usr/share/misc/termcap)
 576 AC_MSG_RESULT($TERMPATH)
 577 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 578
 579 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 580 AC_MSG_CHECKING(if fast termcap-loader is needed)
 581 AC_ARG_ENABLE(getcap,
 582         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 583         [with_getcap=$enableval],
 584         [with_getcap=no])
 585 AC_MSG_RESULT($with_getcap)
 586 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 587
 588 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 589 AC_ARG_ENABLE(getcap-cache,
 590         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 591         [with_getcap_cache=$enableval],
 592         [with_getcap_cache=no])
 593 AC_MSG_RESULT($with_getcap_cache)
 594 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 595
 596 fi
 597
 598 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 599 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 600 AC_ARG_ENABLE(home-terminfo,
 601         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 602         [with_home_terminfo=$enableval],
 603         [with_home_terminfo=yes])
 604 AC_MSG_RESULT($with_home_terminfo)
 605 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 606
 607 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 608 AC_ARG_ENABLE(root-environ,
 609         [  --disable-root-environ  restrict environment when running as root],
 610         [with_root_environ=$enableval],
 611         [with_root_environ=yes])
 612 AC_MSG_RESULT($with_root_environ)
 613 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 614
 615 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 616 ###   to reduce storage requirements for the terminfo database.
 617 CF_LINK_FUNCS
 618
 619 with_links=no
 620 with_symlinks=no
 621
 622 # soft links (symbolic links) are useful for some systems where hard links do
 623 # not work, or to make it simpler to copy terminfo trees around.
 624 if test "$ac_cv_func_symlink" = yes ; then
 625     AC_MSG_CHECKING(if tic should use symbolic links)
 626     AC_ARG_ENABLE(symlinks,
 627         [  --enable-symlinks       make tic use symbolic links not hard links],
 628         [with_symlinks=$enableval],
 629         [with_symlinks=no])
 630     AC_MSG_RESULT($with_symlinks)
 631 fi
 632
 633 # If we have hard links and did not choose to use soft links instead, there is
 634 # no reason to make this choice optional - use the hard links.
 635 if test "$with_symlinks" = no ; then
 636     AC_MSG_CHECKING(if tic should use hard links)
 637     if test "$ac_cv_func_link" = yes ; then
 638         with_links=yes
 639     else
 640         with_links=no
 641     fi
 642     AC_MSG_RESULT($with_links)
 643 fi
 644
 645 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 646 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 647
 648 ###   use option --enable-broken-linker to force on use of broken-linker support
 649 AC_MSG_CHECKING(if you want broken-linker support code)
 650 AC_ARG_ENABLE(broken_linker,
 651         [  --enable-broken_linker  compile with broken-linker support code],
 652         [with_broken_linker=$enableval],
 653         [with_broken_linker=${BROKEN_LINKER-no}])
 654 AC_MSG_RESULT($with_broken_linker)
 655
 656 BROKEN_LINKER=0
 657 if test "$with_broken_linker" = yes ; then
 658         AC_DEFINE(BROKEN_LINKER)
 659         BROKEN_LINKER=1
 660 elif test "$DFT_LWR_MODEL" = shared ; then
 661         case $cf_cv_system_name in #(vi
 662         cygwin*)
 663                 AC_DEFINE(BROKEN_LINKER)
 664                 BROKEN_LINKER=1
 665                 CF_VERBOSE(cygwin linker is broken anyway)
 666                 ;;
 667         esac
 668 fi
 669 AC_SUBST(BROKEN_LINKER)
 670
 671 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 672 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 673 AC_ARG_ENABLE(bsdpad,
 674         [  --enable-bsdpad         recognize BSD-style prefix padding],
 675         [with_bsdpad=$enableval],
 676         [with_bsdpad=no])
 677 AC_MSG_RESULT($with_bsdpad)
 678 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 679
 680 ###   use option --enable-widec to turn on use of wide-character support
 681 NCURSES_CH_T=chtype
 682 NCURSES_LIBUTF8=0
 683
 684 NEED_WCHAR_H=0
 685 NCURSES_MBSTATE_T=0
 686 NCURSES_WCHAR_T=0
 687 NCURSES_WINT_T=0
 688
 689 # Check to define _XOPEN_SOURCE "automatically"
 690 CF_XOPEN_SOURCE
 691
 692 # Work around breakage on OS X
 693 CF_SIGWINCH
 694
 695 # Checks for CODESET support.
 696 AM_LANGINFO_CODESET
 697
 698 # use these variables to work around a defect in gcc's fixincludes.
 699 NCURSES_OK_WCHAR_T=
 700 NCURSES_OK_WINT_T=
 701
 702 AC_MSG_CHECKING(if you want wide-character code)
 703 AC_ARG_ENABLE(widec,
 704         [  --enable-widec          compile with wide-char/UTF-8 code],
 705         [with_widec=$enableval],
 706         [with_widec=no])
 707 AC_MSG_RESULT($with_widec)
 708 if test "$with_widec" = yes ; then
 709         LIB_SUFFIX="w${LIB_SUFFIX}"
 710         AC_DEFINE(USE_WIDEC_SUPPORT)
 711         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 712         # with_overwrite=no
 713         NCURSES_CH_T=cchar_t
 714         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 715         if test "$ac_cv_func_putwc" != yes ; then
 716                 CF_UTF8_LIB
 717                 if test "$cf_cv_utf8_lib" != no ; then
 718                         NCURSES_LIBUTF8=1
 719                 fi
 720         fi
 721         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 722         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 723         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 724
 725         if test "$NCURSES_MBSTATE_T" != 0; then
 726                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 727         fi
 728 fi
 729 AC_SUBST(NCURSES_CH_T)
 730 AC_SUBST(NCURSES_LIBUTF8)
 731
 732 AC_SUBST(NEED_WCHAR_H)
 733 AC_SUBST(NCURSES_MBSTATE_T)
 734 AC_SUBST(NCURSES_WCHAR_T)
 735 AC_SUBST(NCURSES_WINT_T)
 736
 737 AC_SUBST(NCURSES_OK_WCHAR_T)
 738 AC_SUBST(NCURSES_OK_WINT_T)
 739
 740 ###   use option --disable-lp64 to allow long chtype
 741 case $cf_cv_abi_version in
 742 [[345]]*)
 743         default_with_lp64=no
 744         ;;
 745 *)
 746         default_with_lp64=yes
 747         ;;
 748 esac
 749
 750 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 751 AC_ARG_ENABLE(lp64,
 752         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 753         [with_lp64=$enableval],
 754         [with_lp64=$default_with_lp64])
 755 AC_MSG_RESULT($with_lp64)
 756
 757 if test "$with_lp64" = yes ; then
 758         cf_cv_enable_lp64=1
 759 else
 760         cf_cv_enable_lp64=0
 761 fi
 762 AC_SUBST(cf_cv_enable_lp64)
 763
 764 CF_LARGEFILE
 765
 766 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 767 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 768 AC_ARG_ENABLE(tparm-varargs,
 769         [  --disable-tparm-varargs compile tparm() without varargs interface],
 770         [with_tparm_varargs=$enableval],
 771         [with_tparm_varargs=yes])
 772 AC_MSG_RESULT($with_tparm_varargs)
 773 NCURSES_TPARM_VARARGS=0
 774 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 775 AC_SUBST(NCURSES_TPARM_VARARGS)
 776
 777 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 778 if test "$with_ticlib" != no ; then
 779 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 780 AC_ARG_ENABLE(tic-depends,
 781         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 782         [with_tic_depends=$enableval],
 783         [with_tic_depends=yes])
 784 AC_MSG_RESULT($with_tic_depends)
 785 else
 786         with_tic_depends=no
 787 fi
 788
 789 ###   use option --with-bool to override bool's type
 790 AC_MSG_CHECKING(for type of bool)
 791 AC_ARG_WITH(bool,
 792         [  --with-bool=TYPE        override fallback type of bool variable],
 793         [NCURSES_BOOL="$withval"],
 794         [NCURSES_BOOL=auto])
 795 AC_MSG_RESULT($NCURSES_BOOL)
 796 AC_SUBST(NCURSES_BOOL)
 797
 798 AC_MSG_CHECKING(for alternate terminal capabilities file)
 799 AC_ARG_WITH(caps,
 800         [  --with-caps=alt         compile with alternate Caps file],
 801         [TERMINFO_CAPS=Caps.$withval],
 802         [TERMINFO_CAPS=Caps])
 803 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 804 AC_MSG_RESULT($TERMINFO_CAPS)
 805 AC_SUBST(TERMINFO_CAPS)
 806
 807 ###   use option --with-chtype to override chtype's type
 808 AC_MSG_CHECKING(for type of chtype)
 809 AC_ARG_WITH(chtype,
 810         [  --with-chtype=TYPE      override type of chtype],
 811         [NCURSES_CHTYPE="$withval"],
 812         [NCURSES_CHTYPE=auto])
 813 AC_MSG_RESULT($NCURSES_CHTYPE)
 814
 815 ###   use option --with-ospeed to override ospeed's type
 816 AC_MSG_CHECKING(for type of ospeed)
 817 AC_ARG_WITH(ospeed,
 818         [  --with-ospeed=TYPE      override type of ospeed variable],
 819         [NCURSES_OSPEED="$withval"],
 820         [NCURSES_OSPEED=short])
 821 AC_MSG_RESULT($NCURSES_OSPEED)
 822 AC_SUBST(NCURSES_OSPEED)
 823
 824 ###   use option --with-mmask-t to override mmask_t's type
 825 AC_MSG_CHECKING(for type of mmask_t)
 826 AC_ARG_WITH(mmask-t,
 827         [  --with-mmask-t=TYPE     override type of mmask_t],
 828         [NCURSES_MMASK_T="$withval"],
 829         [NCURSES_MMASK_T=auto])
 830 AC_MSG_RESULT($NCURSES_MMASK_T)
 831
 832 ###   use option --with-ccharw-max to override CCHARW_MAX size
 833 AC_MSG_CHECKING(for size CCHARW_MAX)
 834 AC_ARG_WITH(ccharw-max,
 835         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
 836         [NCURSES_CCHARW_MAX="$withval"],
 837         [NCURSES_CCHARW_MAX=5])
 838 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
 839 AC_SUBST(NCURSES_CCHARW_MAX)
 840
 841 ### Enable compiling-in rcs id's
 842 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 843 AC_ARG_WITH(rcs-ids,
 844         [  --with-rcs-ids          compile-in RCS identifiers],
 845         [with_rcs_ids=$withval],
 846         [with_rcs_ids=no])
 847 AC_MSG_RESULT($with_rcs_ids)
 848 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 849
 850 ###############################################################################
 851 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
 852
 853 ###############################################################################
 854 CF_HELP_MESSAGE(Extensions:)
 855
 856 ### Note that some functions (such as const) are normally disabled anyway.
 857 AC_MSG_CHECKING(if you want to build with function extensions)
 858 AC_ARG_ENABLE(ext-funcs,
 859         [  --disable-ext-funcs     disable function-extensions],
 860         [with_ext_funcs=$enableval],
 861         [with_ext_funcs=yes])
 862 AC_MSG_RESULT($with_ext_funcs)
 863 if test "$with_ext_funcs" = yes ; then
 864         NCURSES_EXT_FUNCS=1
 865         AC_DEFINE(HAVE_CURSES_VERSION)
 866         AC_DEFINE(HAVE_HAS_KEY)
 867         AC_DEFINE(HAVE_RESIZETERM)
 868         AC_DEFINE(HAVE_RESIZE_TERM)
 869         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 870         AC_DEFINE(HAVE_WRESIZE)
 871         AC_DEFINE(NCURSES_EXT_FUNCS)
 872         GENERATED_EXT_FUNCS=generated
 873 else
 874         NCURSES_EXT_FUNCS=0
 875         GENERATED_EXT_FUNCS=
 876 fi
 877 AC_SUBST(NCURSES_EXT_FUNCS)
 878 AC_SUBST(GENERATED_EXT_FUNCS)
 879
 880 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
 881 AC_ARG_ENABLE(sp-funcs,
 882         [  --enable-sp-funcs       disable experimental SCREEN-extensions],
 883         [with_sp_funcs=$enableval],
 884         [with_sp_funcs=no])
 885 AC_MSG_RESULT($with_sp_funcs)
 886 if test "$with_sp_funcs" = yes ; then
 887         NCURSES_SP_FUNCS=1
 888         AC_DEFINE(NCURSES_SP_FUNCS)
 889         GENERATED_SP_FUNCS=generated
 890 else
 891         NCURSES_SP_FUNCS=0
 892         GENERATED_SP_FUNCS=
 893 fi
 894 AC_SUBST(NCURSES_SP_FUNCS)
 895 AC_SUBST(GENERATED_SP_FUNCS)
 896
 897 ###   use option --enable-const to turn on use of const beyond that in XSI.
 898 AC_MSG_CHECKING(for extended use of const keyword)
 899 AC_ARG_ENABLE(const,
 900         [  --enable-const          compile with extra/non-standard const],
 901         [with_ext_const=$enableval],
 902         [with_ext_const=no])
 903 AC_MSG_RESULT($with_ext_const)
 904 NCURSES_CONST='/*nothing*/'
 905 if test "$with_ext_const" = yes ; then
 906         NCURSES_CONST=const
 907 fi
 908 AC_SUBST(NCURSES_CONST)
 909
 910 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 911 AC_MSG_CHECKING(if you want to use extended colors)
 912 AC_ARG_ENABLE(ext-colors,
 913         [  --enable-ext-colors     compile for 256-color support],
 914         [with_ext_colors=$enableval],
 915         [with_ext_colors=no])
 916 AC_MSG_RESULT($with_ext_colors)
 917 NCURSES_EXT_COLORS=0
 918 if test "$with_ext_colors" = yes ; then
 919         if test "$with_widec" != yes ; then
 920                 AC_MSG_ERROR(This option applies only to wide-character library)
 921         else
 922                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 923                 CF_NCURSES_ABI_6
 924         fi
 925         NCURSES_EXT_COLORS=1
 926         AC_DEFINE(NCURSES_EXT_COLORS)
 927 fi
 928 AC_SUBST(NCURSES_EXT_COLORS)
 929
 930 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 931 AC_MSG_CHECKING(if you want to use extended mouse encoding)
 932 AC_ARG_ENABLE(ext-mouse,
 933         [  --enable-ext-mouse      compile for extended mouse-encoding],
 934         [with_ext_mouse=$enableval],
 935         [with_ext_mouse=no])
 936 AC_MSG_RESULT($with_ext_mouse)
 937 NCURSES_MOUSE_VERSION=1
 938 if test "$with_ext_mouse" = yes ; then
 939         NCURSES_MOUSE_VERSION=2
 940         CF_NCURSES_ABI_6
 941 fi
 942 AC_SUBST(NCURSES_MOUSE_VERSION)
 943
 944 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 945 AC_ARG_ENABLE(no-padding,
 946         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 947         [with_no_padding=$enableval],
 948         [with_no_padding=$with_ext_funcs])
 949 AC_MSG_RESULT($with_no_padding)
 950 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 951
 952 AC_CHECK_SIZEOF([signed char], 0)
 953 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 954         NCURSES_SBOOL="signed char"
 955 else
 956         NCURSES_SBOOL="char"
 957 fi
 958 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 959 AC_ARG_ENABLE(signed-char,
 960         [  --enable-signed-char    compile using signed Boolean's in term.h],
 961         [with_signed_char=$enableval],
 962         [with_signed_char=no])
 963 AC_MSG_RESULT($with_signed_char)
 964 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
 965 AC_SUBST(NCURSES_SBOOL)
 966
 967 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
 968 AC_MSG_CHECKING(if you want SIGWINCH handler)
 969 AC_ARG_ENABLE(sigwinch,
 970         [  --enable-sigwinch       compile with SIGWINCH handler],
 971         [with_sigwinch=$enableval],
 972         [with_sigwinch=$with_ext_funcs])
 973 AC_MSG_RESULT($with_sigwinch)
 974 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
 975
 976 ###   use option --enable-tcap-names to allow user to define new capabilities
 977 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
 978 AC_ARG_ENABLE(tcap-names,
 979         [  --enable-tcap-names     compile with user-definable terminal capabilities],
 980         [with_tcap_names=$enableval],
 981         [with_tcap_names=$with_ext_funcs])
 982 AC_MSG_RESULT($with_tcap_names)
 983 NCURSES_XNAMES=0
 984 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
 985 AC_SUBST(NCURSES_XNAMES)
 986
 987 ###############################################################################
 988 # These options are relatively safe to experiment with.
 989 CF_HELP_MESSAGE(Development Code:)
 990 AC_MSG_CHECKING(if you want all development code)
 991 AC_ARG_WITH(develop,
 992         [  --without-develop       disable development options],
 993         [with_develop=$withval],
 994         [with_develop=no])
 995 AC_MSG_RESULT($with_develop)
 996
 997 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
 998 AC_MSG_CHECKING(if you want hard-tabs code)
 999 AC_ARG_ENABLE(hard-tabs,
1000         [  --enable-hard-tabs      compile with hard-tabs code],,
1001         [enable_hard_tabs=$with_develop])
1002 AC_MSG_RESULT($enable_hard_tabs)
1003 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
1004
1005 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1006 AC_MSG_CHECKING(if you want limited support for xmc)
1007 AC_ARG_ENABLE(xmc-glitch,
1008         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1009         [enable_xmc_glitch=$with_develop])
1010 AC_MSG_RESULT($enable_xmc_glitch)
1011 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
1012
1013 ###############################################################################
1014 # These are just experimental, probably should not be in a package:
1015 CF_HELP_MESSAGE(Experimental Code:)
1016
1017 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1018 AC_ARG_ENABLE(assumed-color,
1019         [  --disable-assumed-color do not assume anything about default-colors],
1020         [with_assumed_color=$enableval],
1021         [with_assumed_color=yes])
1022 AC_MSG_RESULT($with_assumed_color)
1023 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
1024
1025 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1026 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1027 AC_ARG_ENABLE(hashmap,
1028         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1029         [with_hashmap=$enableval],
1030         [with_hashmap=yes])
1031 AC_MSG_RESULT($with_hashmap)
1032 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1033
1034 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1035 AC_MSG_CHECKING(if you want colorfgbg code)
1036 AC_ARG_ENABLE(colorfgbg,
1037         [  --enable-colorfgbg      compile with $COLORFGBG code],
1038         [with_colorfgbg=$enableval],
1039         [with_colorfgbg=no])
1040 AC_MSG_RESULT($with_colorfgbg)
1041 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1042
1043 # This is still experimental (20080329), but should ultimately be moved to
1044 # the script-block --with-normal, etc.
1045 CF_WITH_PTHREAD
1046
1047 AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1048 AC_ARG_ENABLE(weak-symbols,
1049     [  --enable-weak-symbols   enable weak-symbols for pthreads],
1050     [use_weak_symbols=$withval],
1051     [use_weak_symbols=no])
1052 AC_MSG_RESULT($use_weak_symbols)
1053 if test "$use_weak_symbols" = yes ; then
1054     CF_WEAK_SYMBOLS
1055 else
1056     cf_cv_weak_symbols=no
1057 fi
1058
1059 if test $cf_cv_weak_symbols = yes ; then
1060     AC_DEFINE(USE_WEAK_SYMBOLS)
1061 fi
1062
1063 PTHREAD=
1064 if test "$with_pthread" = "yes" ; then
1065     AC_DEFINE(USE_PTHREADS)
1066     enable_reentrant=yes
1067     if test $cf_cv_weak_symbols = yes ; then
1068         PTHREAD=-lpthread
1069     fi
1070 fi
1071 AC_SUBST(PTHREAD)
1072
1073 # Reentrant code has to be opaque; there's little advantage to making ncurses
1074 # opaque outside of that, so there is no --enable-opaque option.  We can use
1075 # this option without --with-pthreads, but this will be always set for
1076 # pthreads.
1077 AC_MSG_CHECKING(if you want experimental reentrant code)
1078 AC_ARG_ENABLE(reentrant,
1079         [  --enable-reentrant      compile with experimental reentrant code],
1080         [with_reentrant=$enableval],
1081         [with_reentrant=no])
1082 AC_MSG_RESULT($with_reentrant)
1083 if test "$with_reentrant" = yes ; then
1084         cf_cv_enable_reentrant=1
1085         cf_cv_enable_opaque="NCURSES_INTERNALS"
1086         NCURSES_OPAQUE=1
1087         NCURSES_SIZE_T=int
1088         if test $cf_cv_weak_symbols = yes ; then
1089                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1090         else
1091                 LIB_SUFFIX="t${LIB_SUFFIX}"
1092         fi
1093         AC_DEFINE(USE_REENTRANT)
1094         CF_NCURSES_ABI_6
1095 else
1096         cf_cv_enable_reentrant=0
1097         cf_cv_enable_opaque="NCURSES_OPAQUE"
1098         NCURSES_OPAQUE=0
1099         NCURSES_SIZE_T=short
1100 fi
1101 AC_SUBST(cf_cv_enable_reentrant)
1102 AC_SUBST(cf_cv_enable_opaque)
1103 AC_SUBST(NCURSES_OPAQUE)
1104 AC_SUBST(NCURSES_SIZE_T)
1105
1106 ### Allow using a different wrap-prefix
1107 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1108         AC_MSG_CHECKING(for prefix used to wrap public variables)
1109         AC_ARG_WITH(wrap-prefix,
1110                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1111                 [NCURSES_WRAP_PREFIX=$withval],
1112                 [NCURSES_WRAP_PREFIX=_nc_])
1113         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1114 else
1115         NCURSES_WRAP_PREFIX=_nc_
1116 fi
1117 AC_SUBST(NCURSES_WRAP_PREFIX)
1118 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX")
1119
1120 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1121 AC_ARG_ENABLE(safe-sprintf,
1122         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1123         [with_safe_sprintf=$enableval],
1124         [with_safe_sprintf=no])
1125 AC_MSG_RESULT($with_safe_sprintf)
1126 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1127
1128 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1129 # when hashmap is used scroll hints are useless
1130 if test "$with_hashmap" = no ; then
1131 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1132 AC_ARG_ENABLE(scroll-hints,
1133         [  --disable-scroll-hints  compile without scroll-hints code],
1134         [with_scroll_hints=$enableval],
1135         [with_scroll_hints=yes])
1136 AC_MSG_RESULT($with_scroll_hints)
1137 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1138 fi
1139
1140 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1141 AC_ARG_ENABLE(wgetch-events,
1142         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1143         [with_wgetch_events=$enableval],
1144         [with_wgetch_events=no])
1145 AC_MSG_RESULT($with_wgetch_events)
1146 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1147
1148 ###############################################################################
1149 CF_HELP_MESSAGE(Testing/development Options:)
1150
1151 ###     use option --disable-echo to suppress full display compiling commands
1152 AC_MSG_CHECKING(if you want to display full commands during build)
1153 AC_ARG_ENABLE(echo,
1154         [  --enable-echo           build: display "compiling" commands (default)],
1155         [with_echo=$enableval],
1156         [with_echo=yes])
1157 if test "$with_echo" = yes; then
1158         ECHO_LINK=
1159 else
1160         ECHO_LINK='@ echo linking $@ ... ;'
1161         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1162         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1163 fi
1164 AC_MSG_RESULT($with_echo)
1165 AC_SUBST(ECHO_LINK)
1166
1167 ###     use option --enable-warnings to turn on all gcc warnings
1168 AC_MSG_CHECKING(if you want to see compiler warnings)
1169 AC_ARG_ENABLE(warnings,
1170         [  --enable-warnings       build: turn on GCC compiler warnings],
1171         [with_warnings=$enableval])
1172 AC_MSG_RESULT($with_warnings)
1173
1174 if test "x$with_warnings" = "xyes"; then
1175         ADAFLAGS="$ADAFLAGS -gnatg"
1176         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1177         if test "$cf_with_cxx" = yes ; then
1178                 CF_GXX_WARNINGS(Wno-unused)
1179         fi
1180 fi
1181 CF_GCC_ATTRIBUTES
1182
1183 ###     use option --enable-assertions to turn on generation of assertion code
1184 AC_MSG_CHECKING(if you want to enable runtime assertions)
1185 AC_ARG_ENABLE(assertions,
1186         [  --enable-assertions     test: turn on generation of assertion code],
1187         [with_assertions=$enableval],
1188         [with_assertions=no])
1189 AC_MSG_RESULT($with_assertions)
1190 if test -n "$GCC"
1191 then
1192         if test "$with_assertions" = no
1193         then
1194                 AC_DEFINE(NDEBUG)
1195                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1196         else
1197                 ADAFLAGS="$ADAFLAGS -gnata"
1198         fi
1199 fi
1200
1201 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1202 CF_DISABLE_LEAKS
1203 AC_DEFINE(HAVE_NC_ALLOC_H)
1204
1205 ###     use option --enable-expanded to generate certain macros as functions
1206 AC_ARG_ENABLE(expanded,
1207         [  --enable-expanded       test: generate functions for certain macros],
1208         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1209
1210 ###     use option --disable-macros to suppress macros in favor of functions
1211 AC_ARG_ENABLE(macros,
1212         [  --disable-macros        test: use functions rather than macros],
1213         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1214
1215 # Normally we only add trace() to the debug-library.  Allow this to be
1216 # extended to all models of the ncurses library:
1217 cf_all_traces=no
1218 case "$CFLAGS $CPPFLAGS" in
1219 *-DTRACE*)
1220         cf_all_traces=yes
1221         ;;
1222 esac
1223
1224 AC_MSG_CHECKING(whether to add trace feature to all models)
1225 AC_ARG_WITH(trace,
1226 [  --with-trace            test: add trace() function to all models of ncurses],
1227 [cf_with_trace=$withval],
1228 [cf_with_trace=$cf_all_traces])
1229 AC_MSG_RESULT($cf_with_trace)
1230
1231 if test "$cf_with_trace" = yes ; then
1232         LIB_TRACING=all
1233         ADA_TRACE=TRUE
1234         CF_ADD_CFLAGS(-DTRACE)
1235 else
1236         LIB_TRACING=DEBUG
1237         ADA_TRACE=FALSE
1238 fi
1239
1240 AC_SUBST(ADA_TRACE)
1241
1242 ###     Checks for libraries.
1243 case $cf_cv_system_name in #(vi
1244 *mingw32*) #(vi
1245         ;;
1246 *)
1247 AC_CHECK_FUNC(gettimeofday,
1248         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1249
1250 AC_CHECK_LIB(bsd, gettimeofday,
1251         AC_DEFINE(HAVE_GETTIMEOFDAY)
1252         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
1253         ;;
1254 esac
1255
1256 CF_MATH_LIB(MATH_LIB,sin(x))
1257 AC_SUBST(MATH_LIB)
1258
1259 ###     Checks for header files.
1260 AC_STDC_HEADERS
1261 AC_HEADER_DIRENT
1262 AC_HEADER_TIME
1263 CF_REGEX
1264
1265 dnl These are some other potentially nonportable headers.
1266 AC_CHECK_HEADERS( \
1267 fcntl.h \
1268 getopt.h \
1269 limits.h \
1270 locale.h \
1271 poll.h \
1272 sys/bsdtypes.h \
1273 sys/ioctl.h \
1274 sys/param.h \
1275 sys/poll.h \
1276 sys/select.h \
1277 sys/time.h \
1278 sys/times.h \
1279 ttyent.h \
1280 unistd.h \
1281 wctype.h \
1282 )
1283
1284 # check for ISC (this may also define _POSIX_SOURCE)
1285 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1286 if test "$ISC" = yes ; then
1287         AC_CHECK_LIB(cposix,main)
1288         AC_CHECK_LIB(inet,bzero,LIBS="$LIBS -linet")dnl also 'select()'
1289 fi
1290
1291 CF_SYS_TIME_SELECT
1292
1293 ###     checks for compiler characteristics
1294 AC_LANG_C
1295 AC_C_CONST
1296 CF_C_INLINE(NCURSES_INLINE,1200)
1297 CF_SIG_ATOMIC_T
1298
1299 if test $NCURSES_CHTYPE = auto ; then
1300         CF_TYPEOF_CHTYPE
1301 else
1302         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1303 fi
1304 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1305 AC_SUBST(cf_cv_typeof_chtype)
1306
1307 CF_UNSIGNED_LITERALS
1308 cf_cv_1UL="1"
1309 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1310 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1311 AC_SUBST(cf_cv_1UL)
1312
1313 if test $NCURSES_MMASK_T = auto ; then
1314         cf_cv_typeof_mmask_t=long
1315 else
1316         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1317 fi
1318 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1319 AC_SUBST(cf_cv_typeof_mmask_t)
1320
1321 ###     Checks for external-data
1322 CF_ERRNO
1323 CF_LINK_DATAONLY
1324
1325 ###     Checks for library functions.
1326 AC_CHECK_FUNCS( \
1327 getcwd \
1328 getegid \
1329 geteuid \
1330 getttynam \
1331 issetugid \
1332 poll \
1333 remove \
1334 select \
1335 setbuf \
1336 setbuffer \
1337 setvbuf \
1338 sigaction \
1339 sigvec \
1340 strdup \
1341 strstr \
1342 tcgetpgrp \
1343 times \
1344 vsnprintf \
1345 )
1346 if test "$with_getcap" = "yes" ; then
1347         CF_CGETENT
1348 fi
1349
1350 CF_ISASCII
1351 CF_STRUCT_SIGACTION
1352 CF_FUNC_NANOSLEEP
1353 CF_FUNC_TERMIOS
1354 CF_FUNC_VSSCANF
1355 CF_MKSTEMP
1356
1357 # setup for prototype of fallback for vsscanf()
1358 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1359
1360 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1361 if test "$cross_compiling" = yes ; then
1362         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1363 else
1364         AC_FUNC_SETVBUF_REVERSED
1365 fi
1366 AC_TYPE_SIGNAL
1367 CF_TYPE_SIGACTION
1368 CF_SIZECHANGE
1369 CF_FUNC_MEMMOVE
1370 CF_FUNC_POLL
1371
1372 # special check for test/ditto.c
1373 CF_FUNC_OPENPTY
1374 if test "$cf_cv_func_openpty" != no ; then
1375     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1376     AC_DEFINE(USE_XTERM_PTY)
1377     if test "$cf_cv_lib_util" = yes ; then
1378         TEST_LIBS="-lutil $TEST_LIBS"
1379     fi
1380 fi
1381 AC_SUBST(TEST_LIBS)
1382
1383 if test "$with_hashed_db" != no ; then
1384         AC_DEFINE(USE_HASHED_DB)
1385         CF_HASHED_DB($with_hashed_db)
1386 fi
1387
1388 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1389 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1390         CF_STRIP_G_OPT(CFLAGS)
1391         CF_STRIP_G_OPT(CXXFLAGS)
1392 fi
1393
1394 # Just in case, check if the C compiler has a bool type.
1395 CF_BOOL_DECL(cf_cv_cc_bool_type)
1396
1397 # Check for C++ compiler characteristics (and ensure that it's there!)
1398 if test -n "$CXX" ; then
1399         AC_LANG_CPLUSPLUS
1400         CF_STDCPP_LIBRARY
1401         CF_PROG_CC_C_O(CXX)
1402
1403         case $GXX_VERSION in
1404         1*|2.[0-6]*)
1405                 cf_cxx_library=yes
1406                 ;;
1407         *-2.7*|2.7*)
1408                 CF_GPP_LIBRARY
1409                 ;;
1410         *)
1411                 cf_cxx_library=no
1412                 ;;
1413         esac
1414
1415         AC_CHECK_HEADERS(iostream typeinfo)
1416
1417     if test x"$ac_cv_header_iostream" = xyes ; then
1418         AC_MSG_CHECKING(if iostream uses std-namespace)
1419         AC_TRY_COMPILE([
1420 #include <iostream>
1421 using std::endl;
1422 using std::cerr;],[
1423 cerr << "testing" << endl;
1424 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1425         AC_MSG_RESULT($cf_iostream_namespace)
1426         if test "$cf_iostream_namespace" = yes ; then
1427             AC_DEFINE(IOSTREAM_NAMESPACE)
1428         fi
1429     fi
1430
1431         CF_BOOL_DECL
1432         CF_BOOL_SIZE
1433         CF_ETIP_DEFINES
1434         CF_CPP_PARAM_INIT
1435         CF_CPP_STATIC_CAST
1436
1437         CXX_AR='$(AR)'
1438         CXX_ARFLAGS='$(ARFLAGS)'
1439         case $cf_cv_system_name in #(vi
1440         irix*) #(vi
1441             if test "$GXX" != yes ; then
1442                 CXX_AR='$(CXX)'
1443                 CXX_ARFLAGS='-ar -o'
1444             fi
1445             ;;
1446         sco3.2v5*) #(vi
1447             CXXLDFLAGS="-u main"
1448             ;;
1449         solaris2*)
1450             if test "$GXX" != yes ; then
1451                 CXX_AR='$(CXX)'
1452                 CXX_ARFLAGS='-xar -o'
1453             fi
1454             ;;
1455         esac
1456         AC_SUBST(CXXLDFLAGS)
1457         AC_SUBST(CXX_AR)
1458         AC_SUBST(CXX_ARFLAGS)
1459 else
1460         cf_cxx_library=no
1461         cf_cv_builtin_bool=1
1462
1463         # Just because we are not configuring against C++ right now does not
1464         # mean that a user will not want to use C++.  Some distributors disable
1465         # the C++ portion of this configuration as a shortcut (or just to avoid
1466         # compiling the demo in the c++ directory).  So we need a reasonable
1467         # default for the 'bool' type.
1468         #
1469         # Caveat: since the storage of the bool type is not standardized, it
1470         # may change.
1471
1472         if test "$NCURSES_BOOL" != auto ; then
1473                 cf_cv_type_of_bool=$NCURSES_BOOL
1474                 cf_cv_header_stdbool_h=0
1475         else
1476                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1477                         CF_BOOL_SIZE
1478                 else
1479                         AC_MSG_CHECKING(for fallback type of bool)
1480                         case "$host_cpu" in #(vi
1481                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1482                         *)      cf_cv_type_of_bool=int  ;;
1483                         esac
1484                         AC_MSG_RESULT($cf_cv_type_of_bool)
1485                 fi
1486         fi
1487 fi
1488 AC_SUBST(CXXLIBS)
1489
1490 # If the C compiler did not declare bool, and we did not determine that the C++
1491 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1492 # ncurses library use the same type as C++ bool.  Note that this allows one to
1493 # specify the type of bool in a configure-script option and postpone
1494 # integration with the C++ compiler provided that the types are compatible.
1495 USE_CXX_BOOL=1
1496 if test $cf_cv_cc_bool_type = 1
1497 then
1498         # oops: C has a bool.  Unlikely, but C++ could differ.
1499         USE_CXX_BOOL=0
1500 elif test $cf_cv_builtin_bool = 0
1501 then
1502         # C++ has no bool
1503         USE_CXX_BOOL=0
1504 else
1505         # this is the normal case
1506         USE_CXX_BOOL='defined(__cplusplus)'
1507 fi
1508 AC_SUBST(USE_CXX_BOOL)
1509
1510 CF_HELP_MESSAGE(Ada95 Binding Options:)
1511
1512 dnl If the Ada95 source-tree is present, add that to the build unless it will
1513 dnl not work, or was not requested.
1514 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1515
1516 dnl libtool does not know anything about GNAT, though a change made in 1998
1517 dnl provided for it "someday".  Disable the ada subtree if we are using
1518 dnl libtool -TD 20070714
1519 if test "$cf_with_ada" != "no" ; then
1520     if test "$with_libtool" != "no"; then
1521         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1522         cf_with_ada=no
1523     fi
1524 fi
1525
1526 dnl Check for availability of GNU Ada Translator (GNAT).
1527 dnl At the moment we support no other Ada95 compiler.
1528 if test "$cf_with_ada" != "no" ; then
1529 cf_ada_make=gnatmake
1530 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
1531 if test "$ac_cv_prog_gnat_exists" = no; then
1532    cf_ada_make=
1533 else
1534    CF_GNAT_VERSION
1535    AC_CHECK_PROG(M4_exists, m4, yes, no)
1536    if test "$ac_cv_prog_M4_exists" = no; then
1537       cf_cv_prog_gnat_correct=no
1538       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
1539    fi
1540    if test "$cf_cv_prog_gnat_correct" = yes; then
1541       AC_MSG_CHECKING(if GNAT works)
1542       CF_GNAT_TRY_RUN([procedure conftest;],
1543 [with Text_IO;
1544 with GNAT.OS_Lib;
1545 procedure conftest is
1546 begin
1547    Text_IO.Put ("Hello World");
1548    Text_IO.New_Line;
1549    GNAT.OS_Lib.OS_Exit (0);
1550 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
1551       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
1552    fi
1553 fi
1554 if test "$cf_cv_prog_gnat_correct" = yes; then
1555    ADAFLAGS="-O3 -gnatpn $ADAFLAGS"
1556
1557    AC_MSG_CHECKING(if GNAT pragma Unreferenced works)
1558    CF_GNAT_TRY_LINK([procedure conftest;],
1559 [with Text_IO;
1560 with GNAT.OS_Lib;
1561 procedure conftest is
1562    test : Integer;
1563    pragma Unreferenced (test);
1564 begin
1565    test := 1;
1566    Text_IO.Put ("Hello World");
1567    Text_IO.New_Line;
1568    GNAT.OS_Lib.OS_Exit (0);
1569 end conftest;],[cf_cv_pragma_unreferenced=yes],[cf_cv_pragma_unreferenced=no])
1570    AC_MSG_RESULT($cf_cv_pragma_unreferenced)
1571
1572    # if the pragma is supported, use it (needed in the Trace code).
1573    if test $cf_cv_pragma_unreferenced = yes ; then
1574       PRAGMA_UNREF=TRUE
1575    else
1576       PRAGMA_UNREF=FALSE
1577    fi
1578
1579    AC_ARG_WITH(ada-compiler,
1580         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
1581         [cf_ada_compiler=$withval],
1582         [cf_ada_compiler=gnatmake])
1583
1584    cf_ada_package=terminal_interface
1585
1586    AC_SUBST(cf_ada_make)
1587    AC_SUBST(cf_ada_compiler)
1588    AC_SUBST(cf_ada_package)
1589    AC_SUBST(ADAFLAGS)
1590    AC_SUBST(cf_compile_generics)
1591    AC_SUBST(cf_generic_objects)
1592    AC_SUBST(PRAGMA_UNREF)
1593
1594    CF_WITH_PATH(ada-include,
1595        [  --with-ada-include=DIR  Ada includes are in DIR],
1596        ADA_INCLUDE,
1597        PREFIX/lib/ada/adainclude,
1598        [$]prefix/lib/ada/adainclude)
1599    AC_SUBST(ADA_INCLUDE)
1600
1601    CF_WITH_PATH(ada-objects,
1602        [  --with-ada-objects=DIR  Ada objects are in DIR],
1603        ADA_OBJECTS,
1604        PREFIX/lib/ada/adalib,
1605        [$]prefix/lib/ada/adalib)
1606    AC_SUBST(ADA_OBJECTS)
1607
1608 fi
1609 fi
1610 else
1611    cf_with_ada=no
1612 fi
1613
1614 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1615 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1616 ###
1617 ### ticlib modules may be a separate library, otherwise contained in termlib.
1618 ### termlib modules may be a separate library, otherwise contained in ncurses.
1619 ###
1620 ### The of "+" or " " between the tokens controls the way the script
1621 ### chooses to split module lists into libraries.
1622 ###
1623 ### (see CF_LIB_RULES).
1624 AC_MSG_CHECKING(for library subsets)
1625 LIB_SUBSETS=
1626
1627 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1628         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1629         if test "$with_ticlib" != no ; then
1630                 LIB_SUBSETS="${LIB_SUBSETS} "
1631         else
1632                 LIB_SUBSETS="${LIB_SUBSETS}+"
1633         fi
1634 fi
1635
1636 LIB_SUBSETS="${LIB_SUBSETS}termlib+port_drivers"
1637
1638 case $cf_cv_system_name in #(vi
1639 *mingw32*) #(vi
1640         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1641         ;;
1642 *) #(vi
1643         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1644         ;;
1645 esac
1646
1647 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1648 if test "$with_termlib" != no ; then
1649         LIB_SUBSETS="${LIB_SUBSETS} "
1650 else
1651         LIB_SUBSETS="${LIB_SUBSETS}+"
1652 fi
1653
1654 LIB_SUBSETS="${LIB_SUBSETS}base"
1655
1656 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1657 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1658
1659 AC_MSG_RESULT($LIB_SUBSETS)
1660
1661 ### Construct the list of include-directories to be generated
1662 CF_INCLUDE_DIRS
1663 CF_ADA_INCLUDE_DIRS
1664
1665 ### Build up pieces for makefile rules
1666 AC_MSG_CHECKING(default library suffix)
1667 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1668 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1669 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1670
1671 AC_MSG_CHECKING(default library-dependency suffix)
1672 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1673 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1674 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1675
1676 AC_MSG_CHECKING(default object directory)
1677 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1678 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1679 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1680
1681 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1682 if test "$cf_with_cxx" = yes ; then
1683 AC_MSG_CHECKING(c++ library-dependency suffix)
1684 if test "$with_libtool" != "no"; then
1685         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1686 else
1687         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1688 fi
1689 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1690 AC_SUBST(CXX_LIB_SUFFIX)
1691 fi
1692
1693 # do not want -ldl in build except as needed for -lncurses dependency
1694 if test "$with_dlsym" = yes ; then
1695 if test $DFT_LWR_MODEL = shared || \
1696    test $DFT_LWR_MODEL = libtool ; then
1697         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1698 fi
1699 fi
1700 ### Set up low-level terminfo dependencies for makefiles.
1701
1702 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1703 # do not need libdl
1704 TICS_LIST=
1705 if test "$with_dlsym" = yes ; then
1706         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1707 fi
1708
1709 if test "$with_ticlib" != no ; then
1710
1711         if test "$with_ticlib" != yes ; then
1712                 TICS_NAME=$with_ticlib
1713                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1714                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1715                 TICS_LIB_SUFFIX="${with_ticlib}"
1716         else
1717                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1718                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1719                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1720         fi
1721         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1722 else
1723         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1724 fi
1725 AC_SUBST(TICS_ARG_SUFFIX)
1726 AC_SUBST(TICS_DEP_SUFFIX)
1727 AC_SUBST(TICS_LIB_SUFFIX)
1728 AC_SUBST(TICS_ARGS)
1729
1730 if test "$with_termlib" != no ; then
1731
1732         if test "$with_termlib" != yes ; then
1733                 TINFO_NAME=$with_termlib
1734                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1735                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1736                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1737                 TINFO_LIB_SUFFIX="${with_termlib}"
1738         else
1739                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1740                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1741                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1742                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1743         fi
1744
1745         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1746         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1747         if test "$DFT_LWR_MODEL" = "libtool"; then
1748                 TEST_ARGS="${TEST_DEPS}"
1749                 TEST_ARG2="${TEST_DEP2}"
1750                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1751                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1752                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1753         else
1754                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1755                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1756                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1757                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1758                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1759         fi
1760 else
1761         # the next lines are needed for linking libtic over libncurses
1762         TINFO_NAME=${LIB_NAME}
1763         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1764         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1765         if test "$with_tic_depends" = yes ; then
1766                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1767         else
1768                 TICS_LIST="$SHLIB_LIST"
1769         fi
1770
1771         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1772 fi
1773
1774 if test "$DFT_LWR_MODEL" = shared ; then
1775         case $cf_cv_system_name in #(vi
1776         cygwin*)
1777                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1778                 TINFO_SUFFIX=.dll
1779                 ;;
1780         esac
1781 fi
1782
1783 AC_SUBST(TINFO_ARG_SUFFIX)
1784 AC_SUBST(TINFO_DEP_SUFFIX)
1785 AC_SUBST(TINFO_LIB_SUFFIX)
1786 AC_SUBST(TINFO_ARGS)
1787
1788 if test "$with_dlsym" = yes ; then
1789         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1790 fi
1791
1792 if test "$DFT_LWR_MODEL" = "libtool"; then
1793     OBJEXT=lo
1794 fi
1795
1796 # needed for Ada95
1797 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1798 AC_SUBST(TINFO_ARGS2)
1799
1800 case $DFT_LWR_MODEL in
1801 normal|debug|profile)
1802         CF_LDFLAGS_STATIC
1803         ;;
1804 esac
1805
1806 AC_MSG_CHECKING(where we will install curses.h)
1807 test "$with_overwrite" = no && \
1808 test "x$includedir" = 'x${prefix}/include' && \
1809         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1810 AC_MSG_RESULT($includedir)
1811
1812 ### Resolve a conflict between normal and wide-curses by forcing applications
1813 ### that will need libutf8 to add it to their configure script.
1814 if test "$with_overwrite" != no ; then
1815 if test "$NCURSES_LIBUTF8" = 1 ; then
1816         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1817         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1818 fi
1819 fi
1820 WITH_OVERWRITE=$with_overwrite
1821
1822 AC_SUBST(WITH_OVERWRITE)
1823 AC_SUBST(TICS_LIST)
1824 AC_SUBST(TINFO_LIST)
1825 AC_SUBST(SHLIB_LIST)
1826
1827 # used to separate tack out of the tree
1828 NCURSES_TREE=
1829 AC_SUBST(NCURSES_TREE)
1830
1831 ### predefined stuff for the test programs
1832 AC_DEFINE(HAVE_SLK_COLOR)
1833
1834 ### Construct the list of subdirectories for which we'll customize makefiles
1835 ### with the appropriate compile-rules.
1836
1837 CF_SRC_MODULES($modules_to_build)
1838
1839 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1840    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1841 fi
1842
1843 CF_DIRS_TO_MAKE
1844
1845 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR')
1846
1847 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1848
1849 ### Now that we're done running tests, add the compiler-warnings, if any
1850 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1851
1852 ### If we're building with rpath, try to link non-standard libs that way too.
1853 if test "$DFT_LWR_MODEL" = "shared"; then
1854   CF_RPATH_HACK
1855 fi
1856
1857 ### Define substitutions for header files to avoid name-pollution
1858 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1859 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1860 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1861
1862 ################################################################################
1863 test "$use_database" = yes && \
1864 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1865
1866 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1867
1868 if test x"$enable_pc_files" = xyes ; then \
1869 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1870 MAKE_PC_FILES=
1871 else
1872 MAKE_PC_FILES="#"
1873 fi
1874 AC_SUBST(MAKE_PC_FILES)
1875
1876 AC_OUTPUT( \
1877         include/MKterm.h.awk \
1878         include/curses.head:include/curses.h.in \
1879         include/ncurses_dll.h \
1880         include/termcap.h \
1881         include/unctrl.h \
1882         $SUB_MAKEFILES \
1883         Makefile,[
1884 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1885 CF_LIB_RULES($SRC_SUBDIRS)
1886 ],[
1887 ### Special initialization commands, used to pass information from the
1888 ### configuration-run into config.status
1889
1890 AWK="$AWK"
1891 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1892 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1893 ECHO_LINK="$ECHO_LINK"
1894 LDCONFIG="$LDCONFIG"
1895 LIB_NAME="$LIB_NAME"
1896 LIB_SUBSETS="$LIB_SUBSETS"
1897 LIB_SUFFIX="$LIB_SUFFIX"
1898 LIB_TRACING="$LIB_TRACING"
1899 MAKE_TERMINFO="$MAKE_TERMINFO"
1900 NCURSES_MAJOR="$NCURSES_MAJOR"
1901 NCURSES_MINOR="$NCURSES_MINOR"
1902 NCURSES_OSPEED="$NCURSES_OSPEED"
1903 NCURSES_PATCH="$NCURSES_PATCH"
1904 SRC_SUBDIRS="$SRC_SUBDIRS"
1905 TERMINFO="$TERMINFO"
1906 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1907 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1908 TICS_NAME="$TICS_NAME"
1909 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1910 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1911 TINFO_NAME="$TINFO_NAME"
1912 TINFO_SUFFIX="$TINFO_SUFFIX"
1913 WITH_CURSES_H="$with_curses_h"
1914 WITH_ECHO="$with_echo"
1915 WITH_OVERWRITE="$with_overwrite"
1916 cf_LIST_MODELS="$cf_list_models"
1917 cf_cv_abi_version="$cf_cv_abi_version"
1918 cf_cv_do_relink="$cf_cv_do_relink"
1919 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1920 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1921 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1922 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1923 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1924 cf_cv_rel_version="$cf_cv_rel_version"
1925 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1926 cf_cv_shared_soname='$cf_cv_shared_soname'
1927 cf_cv_shlib_version="$cf_cv_shlib_version"
1928 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1929 cf_cv_system_name="$cf_cv_system_name"
1930 cf_with_cxx_binding="$cf_with_cxx_binding"
1931 cf_with_manpages="$cf_with_manpages"
1932 host="$host"
1933 target="$target"
1934
1935 ],cat)dnl
1936 ${MAKE-make} preinstall