configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2016,2017 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.638 2017/03/10 02:01:39 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.52.20030208)
  38 AC_REVISION($Revision: 1.638 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44 CF_VERSION_INFO(NCURSES,ncurses)
  45
  46 CF_WITH_REL_VERSION(NCURSES)
  47 CF_NCURSES_WITH_ABI_VERSION
  48
  49 CF_WITH_SYSTYPE
  50
  51 ###     Save the given $CFLAGS to allow user-override.
  52 cf_user_CFLAGS="$CFLAGS"
  53
  54 ###     Default install-location
  55 CF_CFG_DEFAULTS
  56 ### Defaults for ncurses ABI
  57 CF_ABI_DEFAULTS
  58
  59 ###     Checks for programs.
  60 AC_ARG_WITH(ada,
  61         [  --without-ada           suppress check for Ada95, don't build demo],
  62         [cf_with_ada=$withval],
  63         [cf_with_ada=yes])
  64 if test "x$cf_with_ada" = xyes
  65 then
  66         cf_PROG_CC="gnatgcc gcc cc"
  67 else
  68         cf_PROG_CC="gcc cc"
  69 fi
  70
  71 CF_PROG_CC($cf_PROG_CC)
  72
  73 AC_PROG_CPP
  74 AC_PROG_GCC_TRADITIONAL
  75 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
  76 CF_PROG_LDCONFIG
  77
  78 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  79 dnl                             configure script by not letting us test if C++
  80 dnl                             is present, making this option necessary.
  81 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  82 AC_ARG_WITH(cxx,
  83         [  --without-cxx           do not adjust ncurses bool to match C++],
  84         [cf_with_cxx=$withval],
  85         [cf_with_cxx=yes])
  86 AC_MSG_RESULT($cf_with_cxx)
  87 if test "X$cf_with_cxx" = Xno ; then
  88         CXX=""
  89         GXX=""
  90 else
  91         # with autoconf 2.13, we can change the error to a warning:
  92         pushdef([AC_MSG_ERROR],
  93                 [AC_MSG_RESULT(no)
  94                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  95                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  96         AC_PROG_CXX
  97         popdef([AC_MSG_ERROR])dnl
  98
  99         AC_LANG_PUSH(C++)
 100         if test "x$cf_with_cxx" != xno
 101         then
 102                 # Several of the C++ configurations do not work, particularly when
 103                 # cross-compiling (20140913 -TD)
 104                 AC_MSG_CHECKING(if $CXX works)
 105
 106                 save_CPPFLAGS="$CPPFLAGS"
 107                 eval cf_includedir=${includedir}
 108                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 109                 AC_TRY_COMPILE([
 110 #include <stdlib.h>
 111 #include <stdio.h>
 112 ],
 113                 [
 114                 printf("Hello world!\n")
 115                 ],
 116                 [cf_cxx_works=yes],
 117                 [cf_cxx_works=no])
 118                 CPPFLAGS="$save_CPPFLAGS"
 119
 120                 AC_MSG_RESULT($cf_cxx_works)
 121                 if test "x$cf_cxx_works" = xno
 122                 then
 123                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 124                         cf_with_cxx=no; CXX=""; GXX="";
 125                 fi
 126         fi
 127         AC_LANG_POP
 128
 129         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 130         if test "$CXX" = "g++" ; then
 131                 AC_PATH_PROG(CXX,g++)
 132         fi
 133         case "x$CXX" in
 134         (x|xg++)
 135                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 136                 cf_with_cxx=no; CXX=""; GXX="";
 137                 ;;
 138         esac
 139 fi
 140
 141 CF_GXX_VERSION
 142 case $GXX_VERSION in
 143 (1*|2.[[0-6]]*)
 144         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 145         # cf_cxx_library=no
 146         AC_MSG_WARN(templates do not work)
 147         ;;
 148 esac
 149
 150 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 151 AC_ARG_WITH(cxx-binding,
 152         [  --without-cxx-binding   do not build C++ binding and demo],
 153         [cf_with_cxx_binding=$withval],
 154         [cf_with_cxx_binding=$cf_with_cxx])
 155 AC_MSG_RESULT($cf_with_cxx_binding)
 156
 157 AC_MSG_CHECKING(if you want to build with Ada95)
 158 AC_MSG_RESULT($cf_with_ada)
 159
 160 AC_MSG_CHECKING(if you want to install terminal database)
 161 AC_ARG_ENABLE(db-install,
 162         [  --disable-db-install    suppress install of terminal database],
 163         [cf_with_db_install=$enableval],
 164         [cf_with_db_install=yes])
 165 AC_MSG_RESULT($cf_with_db_install)
 166
 167 AC_MSG_CHECKING(if you want to install manpages)
 168 AC_ARG_WITH(manpages,
 169         [  --without-manpages      suppress install of manpages],
 170         [cf_with_manpages=$withval],
 171         [cf_with_manpages=yes])
 172 AC_MSG_RESULT($cf_with_manpages)
 173
 174 AC_MSG_CHECKING(if you want to build programs such as tic)
 175 AC_ARG_WITH(progs,
 176         [  --without-progs         suppress build/install with programs (e.g., tic)],
 177         [cf_with_progs=$withval],
 178         [cf_with_progs=yes])
 179 AC_MSG_RESULT($cf_with_progs)
 180
 181 AC_MSG_CHECKING(if you want to build test-programs)
 182 AC_ARG_WITH(tests,
 183         [  --without-tests         suppress build/install with test-programs],
 184         [cf_with_tests=$withval],
 185         [cf_with_tests=yes])
 186 AC_MSG_RESULT($cf_with_tests)
 187
 188 AC_MSG_CHECKING(if you wish to install curses.h)
 189 AC_ARG_WITH(curses-h,
 190         [  --without-curses-h      install curses.h as ncurses.h only],
 191         [with_curses_h=$withval],
 192         [with_curses_h=yes])
 193 AC_MSG_RESULT($with_curses_h)
 194
 195 modules_to_build="ncurses"
 196 if test "X$cf_with_progs" != Xno ; then
 197 modules_to_build="$modules_to_build progs tack"
 198 fi
 199 modules_to_build="$modules_to_build panel menu form"
 200
 201 AC_ARG_PROGRAM
 202
 203 CF_PROG_AWK
 204 CF_PROG_EGREP
 205 CF_PROG_INSTALL
 206 CF_PROG_LINT
 207 CF_PROG_LN_S
 208
 209 AC_SYS_LONG_FILE_NAMES
 210
 211 # if we find pkg-config, check if we should install the ".pc" files.
 212 CF_PKG_CONFIG
 213 CF_WITH_PKG_CONFIG_LIBDIR
 214 CF_ENABLE_PC_FILES
 215 if test -z "$MAKE_PC_FILES"
 216 then
 217         AC_MSG_CHECKING(for suffix to add to pc-files)
 218 AC_ARG_WITH(pc-suffix,
 219         [  --with-pc-suffix        suffixes pc-files],
 220         [case "x$withval" in
 221         (xyes|xno)
 222                 PC_MODULE_SUFFIX=
 223                 ;;
 224         (*)     PC_MODULE_SUFFIX="$withval"
 225                 ;;
 226         esac])
 227         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
 228         AC_MSG_RESULT($PC_MODULE_SUFFIX)
 229         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
 230         AC_SUBST(PC_MODULE_SUFFIX)
 231 fi
 232
 233 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 234 AC_ARG_ENABLE(mixed-case,
 235         [  --enable-mixed-case     tic should assume mixed-case filenames],
 236         [enable_mixedcase=$enableval],
 237         [enable_mixedcase=auto])
 238 AC_MSG_RESULT($enable_mixedcase)
 239 if test "$enable_mixedcase" = "auto" ; then
 240         CF_MIXEDCASE_FILENAMES
 241 else
 242         cf_cv_mixedcase=$enable_mixedcase
 243         if test "x$enable_mixedcase" = "xyes" ; then
 244                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 245         fi
 246 fi
 247
 248 # do this after mixed-case option (tags/TAGS is not as important as tic).
 249 AC_PROG_MAKE_SET
 250 CF_MAKE_TAGS
 251 CF_MAKEFLAGS
 252
 253 dnl These are standard among *NIX systems, but not when cross-compiling
 254 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 255 AC_CHECK_TOOL(LD, ld, ld)
 256 AC_CHECK_TOOL(AR, ar, ar)
 257 AC_CHECK_TOOL(NM, nm, nm)
 258 CF_AR_FLAGS
 259
 260 dnl Special option for use by system-builders: the install-prefix is used to
 261 dnl adjust the location into which the actual install is done, so that an
 262 dnl archive can be built without modifying the host system's configuration.
 263 AC_MSG_CHECKING(if you have specified an install-prefix)
 264 AC_ARG_WITH(install-prefix,
 265         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 266         [case "x$withval" in
 267         (xyes|xno)
 268                 ;;
 269         (*)     DESTDIR="$withval"
 270                 ;;
 271         esac])
 272 AC_MSG_RESULT($DESTDIR)
 273 AC_SUBST(DESTDIR)
 274
 275 ###############################################################################
 276 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 277 # If we're cross-compiling, allow the user to override the tools and their
 278 # options.  The configure script is oriented toward identifying the host
 279 # compiler, etc., but we need a build compiler to generate parts of the source.
 280 CF_BUILD_CC
 281
 282 ###############################################################################
 283 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 284
 285 ### Options to allow the user to specify the set of libraries which are used.
 286 ### Use "--without-normal --with-shared" to allow the default model to be
 287 ### shared, for example.
 288 cf_list_models=""
 289 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 290
 291 CF_WITH_LIBTOOL
 292 if test "$with_libtool" != "no" ; then
 293
 294 cf_list_models="$cf_list_models libtool"
 295
 296 else
 297
 298 AC_MSG_CHECKING(if you want to build shared libraries)
 299 AC_ARG_WITH(shared,
 300         [  --with-shared           generate shared-libraries],
 301         [with_shared=$withval],
 302         [with_shared=no])
 303 AC_MSG_RESULT($with_shared)
 304 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 305
 306 AC_MSG_CHECKING(if you want to build static libraries)
 307 AC_ARG_WITH(normal,
 308         [  --with-normal           generate normal-libraries (default)],
 309         [with_normal=$withval],
 310         [with_normal=yes])
 311 AC_MSG_RESULT($with_normal)
 312 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 313
 314 AC_MSG_CHECKING(if you want to build debug libraries)
 315 AC_ARG_WITH(debug,
 316         [  --with-debug            generate debug-libraries (default)],
 317         [with_debug=$withval],
 318         [with_debug=yes])
 319 AC_MSG_RESULT($with_debug)
 320 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 321
 322 AC_MSG_CHECKING(if you want to build profiling libraries)
 323 AC_ARG_WITH(profile,
 324         [  --with-profile          generate profile-libraries],
 325         [with_profile=$withval],
 326         [with_profile=no])
 327 AC_MSG_RESULT($with_profile)
 328 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 329
 330 fi
 331
 332 if test "X$cf_with_cxx_binding" != Xno; then
 333 if test "x$with_shared" = "xyes"; then
 334 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 335 AC_ARG_WITH(cxx-shared,
 336         [  --with-cxx-shared       generate C++ shared-libraries],
 337         [with_shared_cxx=$withval],
 338         [with_shared_cxx=no])
 339 AC_MSG_RESULT($with_shared_cxx)
 340 fi
 341 fi
 342
 343 ###############################################################################
 344
 345 AC_MSG_CHECKING(for specified models)
 346 test -z "$cf_list_models" && cf_list_models=normal
 347 dnl If we use libtool to generate libraries, then it must be the only
 348 dnl specified model.
 349 test "$with_libtool" != "no" && cf_list_models=libtool
 350 AC_MSG_RESULT($cf_list_models)
 351
 352 ### Use the first model as the default, and save its suffix for use in building
 353 ### up test-applications.
 354 AC_MSG_CHECKING(for default model)
 355 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 356 AC_MSG_RESULT($DFT_LWR_MODEL)
 357
 358 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 359
 360 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 361 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 362
 363 TICS_NAME=tic
 364 AC_SUBST(TICS_NAME)
 365
 366 TINFO_NAME=tinfo
 367 AC_SUBST(TINFO_NAME)
 368
 369 LIB_NAME=ncurses
 370 AC_SUBST(LIB_NAME)
 371
 372 LIB_DIR=../lib
 373 LIB_2ND=../../lib
 374
 375 CF_WITH_LIB_PREFIX(cf_prefix)
 376
 377 LIB_SUFFIX=
 378 AC_SUBST(LIB_SUFFIX)
 379 CF_PATHSEP
 380
 381 ###############################################################################
 382
 383 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 384 AC_ARG_WITH(termlib,
 385         [  --with-termlib          generate separate terminfo library],
 386         [with_termlib=$withval],
 387         [with_termlib=no])
 388 AC_MSG_RESULT($with_termlib)
 389
 390 AC_MSG_CHECKING(if you want to build a separate tic library)
 391 AC_ARG_WITH(ticlib,
 392         [  --with-ticlib           generate separate tic library],
 393         [with_ticlib=$withval],
 394         [with_ticlib=no])
 395 AC_MSG_RESULT($with_ticlib)
 396
 397 ### Checks for special libraries, must be done up-front.
 398 SHLIB_LIST=""
 399 CF_WITH_GPM
 400 if test "$with_gpm" != no ; then
 401         AC_MSG_CHECKING(if you want to load GPM dynamically)
 402         AC_ARG_WITH(dlsym,
 403                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 404                 [with_dlsym=$withval],
 405                 [with_dlsym=yes])
 406         AC_MSG_RESULT($with_dlsym)
 407         if test "x$with_dlsym" = xyes ; then
 408                 CF_FUNC_DLSYM
 409                 if test "x$with_gpm" != xyes ; then
 410                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 411                         cf_cv_gpm_soname="$with_gpm"
 412                 else
 413                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 414                 fi
 415                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 416                 SHLIB_LIST="-ldl $SHLIB_LIST"
 417         else
 418                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 419                 CF_ADD_LIB(gpm,TEST_LIBS)
 420         fi
 421         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 422         CF_CHECK_GPM_WGETCH
 423 fi
 424
 425 CF_WITH_SYSMOUSE
 426
 427 dnl Not all ports of gcc support the -g option
 428
 429 if test X"$CC_G_OPT" = X"" ; then
 430         CC_G_OPT='-g'
 431         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 432 fi
 433 AC_SUBST(CC_G_OPT)
 434
 435 if test X"$CXX_G_OPT" = X"" ; then
 436         CXX_G_OPT='-g'
 437         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 438 fi
 439 AC_SUBST(CXX_G_OPT)
 440
 441 AC_MSG_CHECKING(for default loader flags)
 442 case $DFT_LWR_MODEL in
 443 (libtool) LD_MODEL=''   ;;
 444 (normal)  LD_MODEL=''   ;;
 445 (debug)   LD_MODEL=$CC_G_OPT ;;
 446 (profile) LD_MODEL='-pg';;
 447 (shared)  LD_MODEL=''   ;;
 448 esac
 449 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 450 AC_MSG_RESULT($LD_MODEL)
 451
 452 case $DFT_LWR_MODEL in
 453 (shared)
 454 CF_ENABLE_RPATH
 455 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 456 AC_ARG_ENABLE(relink,
 457 [  --disable-relink        relink shared libraries during install],
 458 [cf_cv_do_relink=$enableval],
 459 [cf_cv_do_relink=yes])
 460 AC_MSG_RESULT($cf_cv_do_relink)
 461         ;;
 462 esac
 463
 464 # we will build libraries one-level down.
 465 rel_builddir=..
 466 CF_SHARED_OPTS
 467 for model in $cf_list_models; do
 468         case $model in
 469         (libtool)
 470                 CF_WITH_LIBTOOL_OPTS
 471                 CF_WITH_EXPORT_SYMS
 472                 ;;
 473         (shared)
 474                 if test "$CC_SHARED_OPTS" = "unknown"; then
 475                         AC_ERROR(Shared libraries are not supported in this version)
 476                 fi
 477                 # workaround for inept transition to PIE vs PIC...
 478                 AC_MSG_CHECKING(if current CFLAGS link properly)
 479                 AC_TRY_LINK(
 480                         [#include <stdio.h>],
 481                         [printf("Hello work\n");],
 482                         [cf_cflags_work=yes],
 483                         [cf_cflags_work=no])
 484                 AC_MSG_RESULT($cf_cflags_work)
 485                 if test "$cf_cflags_work" = no
 486                 then
 487                         CF_VERBOSE(try to work around by appending shared-options)
 488                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
 489                 fi
 490                 CF_WITH_VERSIONED_SYMS
 491                 ;;
 492         esac
 493 done
 494
 495 # pretend that ncurses==ncursesw==ncursest
 496 AC_MSG_CHECKING(if you want to disable library suffixes)
 497 CF_ARG_DISABLE(lib-suffixes,
 498         [  --disable-lib-suffixes  disable library suffixes],
 499         [disable_lib_suffixes=yes],
 500         [disable_lib_suffixes=no],
 501         no)
 502 AC_MSG_RESULT($disable_lib_suffixes)
 503
 504 ### If we're building with rpath, try to link non-standard libs that way too.
 505 if test "$DFT_LWR_MODEL" = "shared"; then
 506         CF_DISABLE_RPATH_HACK
 507 fi
 508
 509 ###############################################################################
 510 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 511
 512 ###     use option --with-extra-suffix to append suffix to headers and libraries
 513 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
 514 EXTRA_SUFFIX=
 515 AC_ARG_WITH(extra-suffix,
 516         [  --with-extra-suffix=X   append extra suffix to header/library paths],
 517         [case x$withval in
 518         (no)
 519                 ;;
 520         (xyes|x)
 521                 EXTRA_SUFFIX=$cf_cv_abi_version
 522                 ;;
 523         (*)
 524                 EXTRA_SUFFIX=$withval
 525                 ;;
 526         esac
 527         ])
 528 AC_MSG_RESULT($EXTRA_SUFFIX)
 529 AC_SUBST(EXTRA_SUFFIX)
 530
 531 ###     use option --disable-overwrite to leave out the link to -lcurses
 532 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 533 AC_ARG_ENABLE(overwrite,
 534         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
 535         [with_overwrite=$enableval],
 536         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 537 AC_MSG_RESULT($with_overwrite)
 538
 539 AC_MSG_CHECKING(if external terminfo-database is used)
 540 AC_ARG_ENABLE(database,
 541         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 542         [use_database=$enableval],
 543         [use_database=yes])
 544 AC_MSG_RESULT($use_database)
 545
 546 case $host_os in
 547 (os2*)
 548         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 549         ;;
 550 (*)
 551         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 552         ;;
 553 esac
 554 AC_SUBST(TERMINFO_SRC)
 555
 556 NCURSES_USE_DATABASE=0
 557 if test "$use_database" != no ; then
 558         NCURSES_USE_DATABASE=1
 559
 560         AC_MSG_CHECKING(which terminfo source-file will be installed)
 561         AC_ARG_WITH(database,
 562                 [  --with-database=XXX     specify terminfo source to install],
 563                 [TERMINFO_SRC=$withval])
 564         AC_MSG_RESULT($TERMINFO_SRC)
 565
 566         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 567         AC_ARG_WITH(hashed-db,
 568                 [  --with-hashed-db        specify hashed-database library],,
 569                 [with_hashed_db=no])
 570         AC_MSG_RESULT($with_hashed_db)
 571 else
 572         with_hashed_db=no
 573 fi
 574 AC_SUBST(NCURSES_USE_DATABASE)
 575
 576 AC_MSG_CHECKING(for list of fallback descriptions)
 577 AC_ARG_WITH(fallbacks,
 578         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 579         [with_fallback=$withval],
 580         [with_fallback=])
 581 AC_MSG_RESULT($with_fallback)
 582 FALLBACK_LIST=`test "$with_fallback" != no && echo "$with_fallback" | sed -e 's/,/ /g'`
 583 AC_SUBST(FALLBACK_LIST)
 584
 585 AC_MSG_CHECKING(if you want modern xterm or antique)
 586 AC_ARG_WITH(xterm-new,
 587         [  --without-xterm-new     specify if xterm terminfo should be old version],
 588         [with_xterm_new=$withval],
 589         [with_xterm_new=yes])
 590 case $with_xterm_new in
 591 (no) with_xterm_new=xterm-old;;
 592 (*)      with_xterm_new=xterm-new;;
 593 esac
 594 AC_MSG_RESULT($with_xterm_new)
 595 WHICH_XTERM=$with_xterm_new
 596 AC_SUBST(WHICH_XTERM)
 597
 598 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 599 AC_ARG_WITH(xterm-kbs,
 600         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
 601         [with_xterm_kbs=$withval],
 602         [with_xterm_kbs=BS])
 603 case x$with_xterm_kbs in
 604 (xyes|xno|xBS|xbs|x8)
 605         with_xterm_kbs=BS
 606         ;;
 607 (xDEL|xdel|x127)
 608         with_xterm_kbs=DEL
 609         ;;
 610 (*)
 611         with_xterm_kbs=$withval
 612         ;;
 613 esac
 614 AC_MSG_RESULT($with_xterm_kbs)
 615 XTERM_KBS=$with_xterm_kbs
 616 AC_SUBST(XTERM_KBS)
 617
 618 MAKE_TERMINFO=
 619 if test "$use_database" = no ; then
 620         TERMINFO="${datadir}/terminfo"
 621         MAKE_TERMINFO="#"
 622 else
 623
 624 AC_MSG_CHECKING(for list of terminfo directories)
 625 CF_WITH_PATHLIST(terminfo-dirs,
 626         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 627         TERMINFO_DIRS,
 628         DATADIR/terminfo,
 629         ${datadir}/terminfo)
 630 AC_MSG_RESULT($TERMINFO_DIRS)
 631 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 632
 633 AC_MSG_CHECKING(for default terminfo directory)
 634 CF_WITH_PATH(default-terminfo-dir,
 635         [  --with-default-terminfo-dir=DIR default terminfo directory],
 636         TERMINFO,
 637         DATADIR/terminfo,
 638         ${datadir}/terminfo)
 639 AC_MSG_RESULT($TERMINFO)
 640 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 641
 642 fi
 643
 644 AC_SUBST(TERMINFO)
 645 AC_SUBST(MAKE_TERMINFO)
 646
 647 ###     use option --disable-big-core to make tic run on small machines
 648 ###     We need 4Mb, check if we can allocate 50% more than that.
 649 AC_MSG_CHECKING(if big-core option selected)
 650 AC_ARG_ENABLE(big-core,
 651         [  --disable-big-core      assume machine has little memory],
 652         [with_big_core=$enableval],
 653         [AC_TRY_RUN([
 654 #include <stdlib.h>
 655 #include <string.h>
 656 int main() {
 657         unsigned long n = 6000000L;
 658         char *s = malloc(n);
 659         if (s != 0)
 660                 s[0] = s[n-1] = 0;
 661         ${cf_cv_main_return:-return}(s == 0);
 662 }],
 663         [with_big_core=yes],
 664         [with_big_core=no],
 665         [with_big_core=no])])
 666 AC_MSG_RESULT($with_big_core)
 667 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 668
 669 ### ISO C only guarantees 512-char strings, we have tables which load faster
 670 ### when constructed using "big" strings.  More than the C compiler, the awk
 671 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 672 AC_MSG_CHECKING(if big-strings option selected)
 673 AC_ARG_ENABLE(big-strings,
 674         [  --disable-big-strings   assume compiler has only standard-size strings],
 675         [with_big_strings=$enableval],
 676         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 677 AC_MSG_RESULT($with_big_strings)
 678
 679 USE_BIG_STRINGS=0
 680 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 681 AC_SUBST(USE_BIG_STRINGS)
 682
 683 ###     use option --enable-termcap to compile in the termcap fallback support
 684 AC_MSG_CHECKING(if you want termcap-fallback support)
 685 AC_ARG_ENABLE(termcap,
 686         [  --enable-termcap        compile in termcap fallback support],
 687         [with_termcap=$enableval],
 688         [with_termcap=no])
 689 AC_MSG_RESULT($with_termcap)
 690
 691 NCURSES_USE_TERMCAP=0
 692 if test "x$with_termcap" != "xyes" ; then
 693         if test "$use_database" = no ; then
 694                 if test -z "$with_fallback" ; then
 695                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 696                 fi
 697         fi
 698         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 699 else
 700
 701         if test "$with_ticlib" != no ; then
 702                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 703         fi
 704
 705         NCURSES_USE_TERMCAP=1
 706         AC_MSG_CHECKING(for list of termcap files)
 707         CF_WITH_PATHLIST(termpath,
 708                 [  --with-termpath=XXX     specify list of termcap files],
 709                 TERMPATH,
 710                 /etc/termcap:/usr/share/misc/termcap)
 711         AC_MSG_RESULT($TERMPATH)
 712         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 713
 714         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 715         AC_MSG_CHECKING(if fast termcap-loader is needed)
 716         AC_ARG_ENABLE(getcap,
 717                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 718                 [with_getcap=$enableval],
 719                 [with_getcap=no])
 720         AC_MSG_RESULT($with_getcap)
 721         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 722
 723         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 724         AC_ARG_ENABLE(getcap-cache,
 725                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 726                 [with_getcap_cache=$enableval],
 727                 [with_getcap_cache=no])
 728         AC_MSG_RESULT($with_getcap_cache)
 729         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 730
 731 fi
 732 AC_SUBST(NCURSES_USE_TERMCAP)
 733
 734 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 735 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 736 AC_ARG_ENABLE(home-terminfo,
 737         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 738         [with_home_terminfo=$enableval],
 739         [with_home_terminfo=yes])
 740 AC_MSG_RESULT($with_home_terminfo)
 741 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 742
 743 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 744 AC_ARG_ENABLE(root-environ,
 745         [  --disable-root-environ  restrict environment when running as root],
 746         [with_root_environ=$enableval],
 747         [with_root_environ=yes])
 748 AC_MSG_RESULT($with_root_environ)
 749 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
 750
 751 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 752 ###   to reduce storage requirements for the terminfo database.
 753 CF_LINK_FUNCS
 754
 755 with_links=no
 756 with_symlinks=no
 757
 758 # soft links (symbolic links) are useful for some systems where hard links do
 759 # not work, or to make it simpler to copy terminfo trees around.
 760 if test "x$ac_cv_func_symlink" = xyes ; then
 761         AC_MSG_CHECKING(if tic should use symbolic links)
 762         AC_ARG_ENABLE(symlinks,
 763         [  --enable-symlinks       make tic use symbolic links not hard links],
 764         [with_symlinks=$enableval],
 765         [with_symlinks=no])
 766         AC_MSG_RESULT($with_symlinks)
 767 fi
 768
 769 # If we have hard links and did not choose to use soft links instead, there is
 770 # no reason to make this choice optional - use the hard links.
 771 if test "$with_symlinks" = no ; then
 772         AC_MSG_CHECKING(if tic should use hard links)
 773         if test "x$ac_cv_func_link" = xyes ; then
 774                 with_links=yes
 775         else
 776                 with_links=no
 777         fi
 778         AC_MSG_RESULT($with_links)
 779 fi
 780
 781 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 782 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 783
 784 ###   use option --enable-broken-linker to force on use of broken-linker support
 785 AC_MSG_CHECKING(if you want broken-linker support code)
 786 AC_ARG_ENABLE(broken_linker,
 787         [  --enable-broken_linker  compile with broken-linker support code],
 788         [with_broken_linker=$enableval],
 789         [with_broken_linker=${BROKEN_LINKER:-no}])
 790 AC_MSG_RESULT($with_broken_linker)
 791
 792 BROKEN_LINKER=0
 793 if test "x$with_broken_linker" = xyes ; then
 794         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
 795         BROKEN_LINKER=1
 796 elif test "$DFT_LWR_MODEL" = shared ; then
 797         case $cf_cv_system_name in
 798         (cygwin*)
 799                 AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
 800                 BROKEN_LINKER=1
 801                 CF_VERBOSE(cygwin linker is broken anyway)
 802                 ;;
 803         esac
 804 fi
 805 AC_SUBST(BROKEN_LINKER)
 806
 807 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 808 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 809 AC_ARG_ENABLE(bsdpad,
 810         [  --enable-bsdpad         recognize BSD-style prefix padding],
 811         [with_bsdpad=$enableval],
 812         [with_bsdpad=no])
 813 AC_MSG_RESULT($with_bsdpad)
 814 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 815
 816 ###   use option --enable-widec to turn on use of wide-character support
 817 NCURSES_CH_T=chtype
 818 NCURSES_LIBUTF8=0
 819
 820 NEED_WCHAR_H=0
 821 NCURSES_MBSTATE_T=0
 822 NCURSES_WCHAR_T=0
 823 NCURSES_WINT_T=0
 824
 825 # Check to define _XOPEN_SOURCE "automatically"
 826 CPPFLAGS_before_XOPEN="$CPPFLAGS"
 827 CF_XOPEN_SOURCE(500)
 828 CPPFLAGS_after_XOPEN="$CPPFLAGS"
 829
 830 # Work around breakage on OS X
 831 CF_SIGWINCH
 832
 833 # Checks for CODESET support.
 834 AM_LANGINFO_CODESET
 835
 836 # use these variables to work around a defect in gcc's fixincludes.
 837 NCURSES_OK_WCHAR_T=
 838 NCURSES_OK_WINT_T=
 839
 840 AC_MSG_CHECKING(if you want wide-character code)
 841 AC_ARG_ENABLE(widec,
 842         [  --enable-widec          compile with wide-char/UTF-8 code],
 843         [with_widec=$enableval],
 844         [with_widec=no])
 845 AC_MSG_RESULT($with_widec)
 846
 847 NCURSES_WCWIDTH_GRAPHICS=1
 848 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
 849
 850 if test "x$with_widec" = xyes ; then
 851         if test "x$disable_lib_suffixes" = xno ; then
 852                 LIB_SUFFIX="w${LIB_SUFFIX}"
 853         fi
 854         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
 855         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
 856
 857         CF_CHECK_WCHAR_H
 858         CF_CHECK_WCWIDTH_GRAPHICS
 859         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
 860
 861         # with_overwrite=no
 862         NCURSES_CH_T=cchar_t
 863         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 864         if test "x$ac_cv_func_putwc" != xyes ; then
 865                 CF_UTF8_LIB
 866                 if test "$cf_cv_utf8_lib" != no ; then
 867                         NCURSES_LIBUTF8=1
 868                 fi
 869         fi
 870         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 871         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 872         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 873
 874         if test "$NCURSES_MBSTATE_T" != 0; then
 875                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 876         fi
 877 fi
 878 AC_SUBST(NCURSES_CH_T)
 879 AC_SUBST(NCURSES_LIBUTF8)
 880
 881 AC_SUBST(NEED_WCHAR_H)
 882 AC_SUBST(NCURSES_MBSTATE_T)
 883 AC_SUBST(NCURSES_WCHAR_T)
 884 AC_SUBST(NCURSES_WINT_T)
 885
 886 AC_SUBST(NCURSES_OK_WCHAR_T)
 887 AC_SUBST(NCURSES_OK_WINT_T)
 888
 889 ###   use option --disable-lp64 to allow long chtype
 890 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 891 AC_ARG_ENABLE(lp64,
 892         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 893         [with_lp64=$enableval],
 894         [with_lp64=$cf_dft_with_lp64])
 895 AC_MSG_RESULT($with_lp64)
 896
 897 if test "x$with_lp64" = xyes ; then
 898         cf_cv_enable_lp64=1
 899 else
 900         cf_cv_enable_lp64=0
 901 fi
 902 AC_SUBST(cf_cv_enable_lp64)
 903
 904 CF_LARGEFILE
 905
 906 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 907 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 908 AC_ARG_ENABLE(tparm-varargs,
 909         [  --disable-tparm-varargs compile tparm() without varargs interface],
 910         [with_tparm_varargs=$enableval],
 911         [with_tparm_varargs=yes])
 912 AC_MSG_RESULT($with_tparm_varargs)
 913 NCURSES_TPARM_VARARGS=0
 914 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
 915 AC_SUBST(NCURSES_TPARM_VARARGS)
 916
 917 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 918 if test "$with_ticlib" != no ; then
 919 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 920 AC_ARG_ENABLE(tic-depends,
 921         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 922         [with_tic_depends=$enableval],
 923         [with_tic_depends=yes])
 924 AC_MSG_RESULT($with_tic_depends)
 925 else
 926         with_tic_depends=no
 927 fi
 928
 929 ###   use option --disable-wattr-macros to suppress wattr* macros from curses.h
 930 AC_MSG_CHECKING(if you want to suppress wattr* macros to help with ncurses5/ncurses6 transition)
 931 AC_ARG_ENABLE(wattr-macros,
 932         [  --disable-wattr-macros  suppress wattr* macros to help with ncurses5/ncurses6 transition],
 933         [with_wattr_macros=$enableval],
 934         [with_wattr_macros=yes])
 935 if [[ "x$with_wattr_macros" != xyes ]]; then
 936         NCURSES_WATTR_MACROS=0
 937         AC_MSG_RESULT(yes)
 938 else
 939         NCURSES_WATTR_MACROS=1
 940         AC_MSG_RESULT(no)
 941 fi
 942 AC_SUBST(NCURSES_WATTR_MACROS)
 943
 944 ###   use option --with-bool to override bool's type
 945 AC_MSG_CHECKING(for type of bool)
 946 AC_ARG_WITH(bool,
 947         [  --with-bool=TYPE        override fallback type of bool variable],
 948         [NCURSES_BOOL="$withval"],
 949         [NCURSES_BOOL=auto])
 950 AC_MSG_RESULT($NCURSES_BOOL)
 951 AC_SUBST(NCURSES_BOOL)
 952
 953 AC_MSG_CHECKING(for alternate terminal capabilities file)
 954 AC_ARG_WITH(caps,
 955         [  --with-caps=alt         compile with alternate Caps file],
 956         [TERMINFO_CAPS=Caps.$withval],
 957         [TERMINFO_CAPS=Caps])
 958 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 959 AC_MSG_RESULT($TERMINFO_CAPS)
 960 AC_SUBST(TERMINFO_CAPS)
 961
 962 ###   use option --with-chtype to override chtype's type
 963 AC_MSG_CHECKING(for type of chtype)
 964 AC_ARG_WITH(chtype,
 965         [  --with-chtype=TYPE      override type of chtype],
 966         [NCURSES_CHTYPE="$withval"],
 967         [NCURSES_CHTYPE=$cf_dft_chtype])
 968 AC_MSG_RESULT($NCURSES_CHTYPE)
 969
 970 ###   use option --with-ospeed to override ospeed's type
 971 AC_MSG_CHECKING(for type of ospeed)
 972 AC_ARG_WITH(ospeed,
 973         [  --with-ospeed=TYPE      override type of ospeed variable],
 974         [NCURSES_OSPEED="$withval"],
 975         [NCURSES_OSPEED=short])
 976 AC_MSG_RESULT($NCURSES_OSPEED)
 977 AC_SUBST(NCURSES_OSPEED)
 978
 979 ###   use option --with-mmask-t to override mmask_t's type
 980 AC_MSG_CHECKING(for type of mmask_t)
 981 AC_ARG_WITH(mmask-t,
 982         [  --with-mmask-t=TYPE     override type of mmask_t],
 983         [NCURSES_MMASK_T="$withval"],
 984         [NCURSES_MMASK_T=$cf_dft_mmask_t])
 985 AC_MSG_RESULT($NCURSES_MMASK_T)
 986
 987 ###   use option --with-ccharw-max to override CCHARW_MAX size
 988 AC_MSG_CHECKING(for size CCHARW_MAX)
 989 AC_ARG_WITH(ccharw-max,
 990         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
 991         [NCURSES_CCHARW_MAX="$withval"],
 992         [NCURSES_CCHARW_MAX=5])
 993 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
 994 AC_SUBST(NCURSES_CCHARW_MAX)
 995
 996 ###   use option --with-tparm-arg to override tparm's argument type
 997 AC_MSG_CHECKING(for type of tparm args)
 998 AC_ARG_WITH(tparm-arg,
 999         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1000         [NCURSES_TPARM_ARG="$withval"],
1001         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1002 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1003 AC_SUBST(NCURSES_TPARM_ARG)
1004
1005 ### Enable compiling-in rcs id's
1006 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1007 AC_ARG_WITH(rcs-ids,
1008         [  --with-rcs-ids          compile-in RCS identifiers],
1009         [with_rcs_ids=$withval],
1010         [with_rcs_ids=no])
1011 AC_MSG_RESULT($with_rcs_ids)
1012 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1013
1014 ###############################################################################
1015 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1016
1017 ###############################################################################
1018 CF_HELP_MESSAGE(Extensions:)
1019
1020 ### Note that some functions (such as const) are normally disabled anyway.
1021 AC_MSG_CHECKING(if you want to build with function extensions)
1022 AC_ARG_ENABLE(ext-funcs,
1023         [  --disable-ext-funcs     disable function-extensions],
1024         [with_ext_funcs=$enableval],
1025         [with_ext_funcs=yes])
1026 AC_MSG_RESULT($with_ext_funcs)
1027 if test "x$with_ext_funcs" = xyes ; then
1028         NCURSES_EXT_FUNCS=1
1029         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function])
1030         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function])
1031         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function])
1032         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function])
1033         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function])
1034         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function])
1035         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function])
1036         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function])
1037         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function])
1038         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function])
1039         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function])
1040         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1041         GENERATED_EXT_FUNCS=generated
1042         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1043 else
1044         NCURSES_EXT_FUNCS=0
1045         GENERATED_EXT_FUNCS=
1046 fi
1047 AC_SUBST(NCURSES_EXT_FUNCS)
1048 AC_SUBST(GENERATED_EXT_FUNCS)
1049
1050 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1051 AC_ARG_ENABLE(sp-funcs,
1052         [  --enable-sp-funcs       enable SCREEN-extensions],
1053         [with_sp_funcs=$enableval],
1054         [with_sp_funcs=$cf_dft_ext_spfuncs])
1055 AC_MSG_RESULT($with_sp_funcs)
1056 if test "x$with_sp_funcs" = xyes ; then
1057         NCURSES_SP_FUNCS=1
1058         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1059         GENERATED_SP_FUNCS=generated
1060 else
1061         NCURSES_SP_FUNCS=0
1062         GENERATED_SP_FUNCS=
1063 fi
1064 AC_SUBST(NCURSES_SP_FUNCS)
1065 AC_SUBST(GENERATED_SP_FUNCS)
1066
1067 AC_MSG_CHECKING(if you want to build with terminal-driver)
1068 AC_ARG_ENABLE(term-driver,
1069         [  --enable-term-driver    enable terminal-driver],
1070         [with_term_driver=$enableval],
1071         [with_term_driver=no])
1072 AC_MSG_RESULT($with_term_driver)
1073 if test "x$with_term_driver" = xyes ; then
1074         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1075         if test "x$with_termlib" != xno ; then
1076                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1077         fi
1078         if test "x$with_sp_funcs" != xyes ; then
1079                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1080         fi
1081 fi
1082
1083 ###   use option --enable-const to turn on use of const beyond that in XSI.
1084 AC_MSG_CHECKING(for extended use of const keyword)
1085 AC_ARG_ENABLE(const,
1086         [  --enable-const          compile with extra/non-standard const],
1087         [with_ext_const=$enableval],
1088         [with_ext_const=$cf_dft_ext_const])
1089 AC_MSG_RESULT($with_ext_const)
1090 NCURSES_CONST='/*nothing*/'
1091 if test "x$with_ext_const" = xyes ; then
1092         NCURSES_CONST=const
1093 fi
1094 AC_SUBST(NCURSES_CONST)
1095
1096 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1097 AC_MSG_CHECKING(if you want to use extended colors)
1098 AC_ARG_ENABLE(ext-colors,
1099         [  --enable-ext-colors     compile for 256-color support],
1100         [with_ext_colors=$enableval],
1101         [with_ext_colors=$cf_dft_ext_colors])
1102 AC_MSG_RESULT($with_ext_colors)
1103 NCURSES_EXT_COLORS=0
1104 if test "x$with_ext_colors" = xyes ; then
1105         if test "x$with_widec" != xyes ; then
1106                 AC_MSG_WARN(This option applies only to wide-character library)
1107         else
1108                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1109                 CF_NCURSES_ABI_6
1110                 NCURSES_EXT_COLORS=1
1111                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1112                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1113         fi
1114 fi
1115 AC_SUBST(NCURSES_EXT_COLORS)
1116
1117 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1118 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1119 AC_ARG_ENABLE(ext-mouse,
1120         [  --enable-ext-mouse      compile for extended mouse-encoding],
1121         [with_ext_mouse=$enableval],
1122         [with_ext_mouse=$cf_dft_ext_mouse])
1123 AC_MSG_RESULT($with_ext_mouse)
1124 NCURSES_MOUSE_VERSION=1
1125 if test "x$with_ext_mouse" = xyes ; then
1126         NCURSES_MOUSE_VERSION=2
1127         CF_NCURSES_ABI_6
1128 fi
1129 AC_SUBST(NCURSES_MOUSE_VERSION)
1130
1131 ###   use option --enable-ext-putwin to turn on extended screendumps
1132 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1133 AC_ARG_ENABLE(ext-putwin,
1134         [  --enable-ext-putwin     compile with extended putwin/screendump],
1135         [with_ext_putwin=$enableval],
1136         [with_ext_putwin=$cf_dft_ext_putwin])
1137 AC_MSG_RESULT($with_ext_putwin)
1138 if test "x$with_ext_putwin" = xyes ; then
1139         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1140 fi
1141
1142 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1143 AC_ARG_ENABLE(no-padding,
1144         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1145         [with_no_padding=$enableval],
1146         [with_no_padding=$with_ext_funcs])
1147 AC_MSG_RESULT($with_no_padding)
1148 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1149
1150 AC_CHECK_SIZEOF([signed char], 0)
1151 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1152         NCURSES_SBOOL="signed char"
1153 else
1154         NCURSES_SBOOL="char"
1155 fi
1156 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1157 AC_ARG_ENABLE(signed-char,
1158         [  --enable-signed-char    compile using signed Boolean's in term.h],
1159         [with_signed_char=$enableval],
1160         [with_signed_char=no])
1161 AC_MSG_RESULT($with_signed_char)
1162 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1163 AC_SUBST(NCURSES_SBOOL)
1164
1165 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1166 AC_MSG_CHECKING(if you want SIGWINCH handler)
1167 AC_ARG_ENABLE(sigwinch,
1168         [  --enable-sigwinch       compile with SIGWINCH handler],
1169         [with_sigwinch=$enableval],
1170         [with_sigwinch=$with_ext_funcs])
1171 AC_MSG_RESULT($with_sigwinch)
1172 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1173
1174 ###   use option --enable-tcap-names to allow user to define new capabilities
1175 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1176 AC_ARG_ENABLE(tcap-names,
1177         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1178         [with_tcap_names=$enableval],
1179         [with_tcap_names=$with_ext_funcs])
1180 AC_MSG_RESULT($with_tcap_names)
1181 NCURSES_XNAMES=0
1182 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1183 AC_SUBST(NCURSES_XNAMES)
1184
1185 ##############################################################################
1186 CF_WITH_PTHREAD
1187
1188 if test "x$with_pthread" != xno; then
1189         AC_CHECK_FUNC(pthread_kill,[
1190                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1191                 AC_ARG_ENABLE(pthreads-eintr,
1192                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1193                         [use_pthreads_eintr=$enableval],
1194                         [use_pthreads_eintr=no])
1195                 AC_MSG_RESULT($use_pthreads_eintr)
1196                 if test "x$use_pthreads_eintr" = xyes ; then
1197                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1198                 fi])
1199
1200         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1201         AC_ARG_ENABLE(weak-symbols,
1202                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1203                 [use_weak_symbols=$enableval],
1204                 [use_weak_symbols=no])
1205         AC_MSG_RESULT($use_weak_symbols)
1206         if test "x$use_weak_symbols" = xyes ; then
1207                 CF_WEAK_SYMBOLS
1208         else
1209                 cf_cv_weak_symbols=no
1210         fi
1211
1212         if test "x$cf_cv_weak_symbols" = xyes ; then
1213                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1214         fi
1215 fi
1216
1217 PTHREAD=
1218 if test "x$with_pthread" = "xyes" ; then
1219         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1220         enable_reentrant=yes
1221         if test "x$cf_cv_weak_symbols" = xyes ; then
1222                 PTHREAD=-lpthread
1223         fi
1224 fi
1225 AC_SUBST(PTHREAD)
1226
1227 # Reentrant code has to be opaque; there's little advantage to making ncurses
1228 # opaque outside of that, so there is no --enable-opaque option.  We can use
1229 # this option without --with-pthreads, but this will be always set for
1230 # pthreads.
1231 AC_MSG_CHECKING(if you want reentrant code)
1232 AC_ARG_ENABLE(reentrant,
1233         [  --enable-reentrant      compile with reentrant code],
1234         [with_reentrant=$enableval],
1235         [with_reentrant=no])
1236 AC_MSG_RESULT($with_reentrant)
1237 if test "x$with_reentrant" = xyes ; then
1238         cf_cv_enable_reentrant=1
1239         cf_cv_enable_opaque="NCURSES_INTERNALS"
1240         NCURSES_SIZE_T=int
1241         if test "x$cf_cv_weak_symbols" = xyes ; then
1242                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1243                 CF_ADD_LIB(pthread,TEST_LIBS)
1244                 CF_ADD_LIB(pthread,TEST_LIBS2)
1245         else
1246                 # when not using weak symbols but with_reentrant,
1247                 # add 't' to the library suffix on all platforms
1248                 # except cygwin, where we only do that if ALSO
1249                 # compiling with full thread support.
1250                 case "$host" in
1251                 (*cygwin* | *msys*)
1252                         if test "$with_pthread" = "yes" ; then
1253                                 if test "x$disable_lib_suffixes" = "xno" ; then
1254                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1255                                 fi
1256                         fi ;;
1257                 (*)
1258                         if test "x$disable_lib_suffixes" = "xno" ; then
1259                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1260                         fi
1261                         ;;
1262                 esac
1263         fi
1264         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1265         CF_NCURSES_ABI_6
1266 else
1267         cf_cv_enable_reentrant=0
1268         cf_cv_enable_opaque="NCURSES_OPAQUE"
1269         NCURSES_SIZE_T=short
1270 fi
1271 AC_SUBST(cf_cv_enable_reentrant)
1272 AC_SUBST(cf_cv_enable_opaque)
1273
1274 AC_SUBST(NCURSES_SIZE_T)
1275
1276 AC_MSG_CHECKING(if you want opaque curses-library structures)
1277 CF_ARG_ENABLE(opaque-curses,
1278         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1279         [enable_opaque_curses=yes],[
1280          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1281          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=no
1282         ])
1283 AC_MSG_RESULT($enable_opaque_curses)
1284
1285 test "$cf_cv_enable_reentrant" = 1 && \
1286 test "$enable_opaque_curses" = no && \
1287 AC_MSG_ERROR(reentrant configuration requires opaque library)
1288
1289 AC_MSG_CHECKING(if you want opaque form-library structures)
1290 AC_ARG_ENABLE(opaque-form,
1291         [  --enable-opaque-form    make form-library structures "opaque"],
1292         [enable_opaque_form=yes],[enable_opaque_form=no])
1293 AC_MSG_RESULT($enable_opaque_form)
1294
1295 AC_MSG_CHECKING(if you want opaque menu-library structures)
1296 AC_ARG_ENABLE(opaque-menu,
1297         [  --enable-opaque-menu    make menu-library structures "opaque"],
1298         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1299 AC_MSG_RESULT($enable_opaque_menu)
1300
1301 AC_MSG_CHECKING(if you want opaque panel-library structures)
1302 AC_ARG_ENABLE(opaque-panel,
1303         [  --enable-opaque-panel   make panel-library structures "opaque"],
1304         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1305 AC_MSG_RESULT($enable_opaque_panel)
1306
1307 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1308 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1309 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1310 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1311
1312 AC_SUBST(NCURSES_OPAQUE)
1313 AC_SUBST(NCURSES_OPAQUE_FORM)
1314 AC_SUBST(NCURSES_OPAQUE_MENU)
1315 AC_SUBST(NCURSES_OPAQUE_PANEL)
1316
1317 ### Allow using a different wrap-prefix
1318 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1319         AC_MSG_CHECKING(for prefix used to wrap public variables)
1320         AC_ARG_WITH(wrap-prefix,
1321                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1322                 [NCURSES_WRAP_PREFIX=$withval],
1323                 [NCURSES_WRAP_PREFIX=_nc_])
1324         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1325 else
1326         NCURSES_WRAP_PREFIX=_nc_
1327 fi
1328 AC_SUBST(NCURSES_WRAP_PREFIX)
1329 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1330
1331 ###############################################################################
1332 # These options are relatively safe to experiment with.
1333 CF_HELP_MESSAGE(Development Code:)
1334 AC_MSG_CHECKING(if you want all development code)
1335 AC_ARG_WITH(develop,
1336         [  --without-develop       disable development options],
1337         [with_develop=$withval],
1338         [with_develop=no])
1339 AC_MSG_RESULT($with_develop)
1340
1341 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1342 AC_MSG_CHECKING(if you want hard-tabs code)
1343 AC_ARG_ENABLE(hard-tabs,
1344         [  --enable-hard-tabs      compile with hard-tabs code],,
1345         [enable_hard_tabs=$with_develop])
1346 AC_MSG_RESULT($enable_hard_tabs)
1347 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1348
1349 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1350 AC_MSG_CHECKING(if you want limited support for xmc)
1351 AC_ARG_ENABLE(xmc-glitch,
1352         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1353         [enable_xmc_glitch=$with_develop])
1354 AC_MSG_RESULT($enable_xmc_glitch)
1355 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1356
1357 ###############################################################################
1358 # These are just experimental, probably should not be in a package:
1359 CF_HELP_MESSAGE(Experimental Code:)
1360
1361 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1362 AC_ARG_ENABLE(assumed-color,
1363         [  --disable-assumed-color do not assume anything about default-colors],
1364         [with_assumed_color=$enableval],
1365         [with_assumed_color=yes])
1366 AC_MSG_RESULT($with_assumed_color)
1367 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1368
1369 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1370 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1371 AC_ARG_ENABLE(hashmap,
1372         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1373         [with_hashmap=$enableval],
1374         [with_hashmap=yes])
1375 AC_MSG_RESULT($with_hashmap)
1376 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1377
1378 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1379 AC_MSG_CHECKING(if you want colorfgbg code)
1380 AC_ARG_ENABLE(colorfgbg,
1381         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1382         [with_colorfgbg=$enableval],
1383         [with_colorfgbg=no])
1384 AC_MSG_RESULT($with_colorfgbg)
1385 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1386
1387 ###   use option --enable-interop to turn on use of bindings used for interop
1388 AC_MSG_CHECKING(if you want interop bindings)
1389 AC_ARG_ENABLE(interop,
1390         [  --enable-interop        compile-in interop bindings],
1391         [with_exp_interop=$enableval],
1392         [with_exp_interop=$cf_dft_interop])
1393 AC_MSG_RESULT($with_exp_interop)
1394
1395 NCURSES_INTEROP_FUNCS=0
1396 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1397 AC_SUBST(NCURSES_INTEROP_FUNCS)
1398
1399
1400 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1401 AC_ARG_ENABLE(safe-sprintf,
1402         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1403         [with_safe_sprintf=$enableval],
1404         [with_safe_sprintf=no])
1405 AC_MSG_RESULT($with_safe_sprintf)
1406 test "x$with_safe_sprintf" = xyes && AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1407
1408 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1409 # when hashmap is used scroll hints are useless
1410 if test "$with_hashmap" = no ; then
1411 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1412 AC_ARG_ENABLE(scroll-hints,
1413         [  --disable-scroll-hints  compile without scroll-hints code],
1414         [with_scroll_hints=$enableval],
1415         [with_scroll_hints=yes])
1416 AC_MSG_RESULT($with_scroll_hints)
1417 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1418 fi
1419
1420 AC_MSG_CHECKING(if you want wgetch-events code)
1421 AC_ARG_ENABLE(wgetch-events,
1422         [  --enable-wgetch-events  compile with wgetch-events code],
1423         [with_wgetch_events=$enableval],
1424         [with_wgetch_events=no])
1425 AC_MSG_RESULT($with_wgetch_events)
1426 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1427
1428 ###############################################################################
1429 CF_HELP_MESSAGE(Testing/development Options:)
1430
1431 ###     use option --disable-echo to suppress full display compiling commands
1432 CF_DISABLE_ECHO
1433 if test "x$enable_echo" = xyes; then
1434         ECHO_LINK=
1435 else
1436         ECHO_LINK='@ echo linking $@ ... ;'
1437         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1438         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1439 fi
1440 AC_SUBST(ECHO_LINK)
1441
1442 ###     use option --enable-warnings to turn on all gcc warnings
1443 AC_MSG_CHECKING(if you want to see compiler warnings)
1444 AC_ARG_ENABLE(warnings,
1445         [  --enable-warnings       build: turn on GCC compiler warnings],
1446         [with_warnings=$enableval])
1447 AC_MSG_RESULT($with_warnings)
1448
1449 if test "x$with_warnings" = "xyes"; then
1450         CF_ADD_ADAFLAGS(-gnatg)
1451         CF_GCC_WARNINGS(Wno-unknown-pragmas Wswitch-enum)
1452         if test "x$cf_with_cxx" = xyes ; then
1453                 CF_GXX_WARNINGS(Wno-unused)
1454         fi
1455 fi
1456 CF_GCC_ATTRIBUTES
1457 CF_ENABLE_STRING_HACKS
1458
1459 ###     use option --enable-assertions to turn on generation of assertion code
1460 AC_MSG_CHECKING(if you want to enable runtime assertions)
1461 AC_ARG_ENABLE(assertions,
1462         [  --enable-assertions     test: turn on generation of assertion code],
1463         [with_assertions=$enableval],
1464         [with_assertions=no])
1465 AC_MSG_RESULT($with_assertions)
1466 if test -n "$GCC"
1467 then
1468         if test "$with_assertions" = no
1469         then
1470                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1471         else
1472                 CF_ADD_ADAFLAGS(-gnata)
1473         fi
1474 fi
1475
1476 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1477 CF_DISABLE_LEAKS
1478 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1479
1480 ###     use option --enable-expanded to generate certain macros as functions
1481 AC_ARG_ENABLE(expanded,
1482         [  --enable-expanded       test: generate functions for certain macros],
1483         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1484
1485 ###     use option --disable-macros to suppress macros in favor of functions
1486 AC_ARG_ENABLE(macros,
1487         [  --disable-macros        test: use functions rather than macros],
1488         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1489
1490 # Normally we only add trace() to the debug-library.  Allow this to be
1491 # extended to all models of the ncurses library:
1492 cf_all_traces=no
1493 case "$CFLAGS $CPPFLAGS" in
1494 (*-DTRACE*)
1495         cf_all_traces=yes
1496         ;;
1497 esac
1498
1499 AC_MSG_CHECKING(whether to add trace feature to all models)
1500 AC_ARG_WITH(trace,
1501 [  --with-trace            test: add trace() function to all models of ncurses],
1502 [cf_with_trace=$withval],
1503 [cf_with_trace=$cf_all_traces])
1504 AC_MSG_RESULT($cf_with_trace)
1505
1506 if test "x$cf_with_trace" = xyes ; then
1507         LIB_TRACING=all
1508         ADA_TRACE=TRUE
1509         CF_ADD_CFLAGS(-DTRACE)
1510 else
1511         LIB_TRACING=DEBUG
1512         ADA_TRACE=FALSE
1513 fi
1514
1515 AC_SUBST(ADA_TRACE)
1516
1517 CF_DISABLE_GNAT_PROJECTS
1518
1519 ###     Checks for libraries.
1520 case $cf_cv_system_name in
1521 (*mingw32*|*mingw64*)
1522         CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1523         LIBS=" -lpsapi $LIBS"
1524         ;;
1525 (*)
1526 AC_CHECK_FUNC(gettimeofday,
1527         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1528
1529 AC_CHECK_LIB(bsd, gettimeofday,
1530         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1531         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1532         ;;
1533 esac
1534
1535 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1536 AC_SUBST(MATH_LIB)
1537
1538 ###     Checks for header files.
1539 AC_STDC_HEADERS
1540 AC_HEADER_DIRENT
1541 AC_HEADER_TIME
1542 CF_REGEX
1543
1544 dnl These are some other potentially nonportable headers.
1545 AC_CHECK_HEADERS( \
1546 fcntl.h \
1547 getopt.h \
1548 limits.h \
1549 locale.h \
1550 math.h \
1551 poll.h \
1552 sys/bsdtypes.h \
1553 sys/ioctl.h \
1554 sys/param.h \
1555 sys/poll.h \
1556 sys/select.h \
1557 sys/time.h \
1558 sys/times.h \
1559 ttyent.h \
1560 unistd.h \
1561 wctype.h \
1562 )
1563
1564 CF_GETOPT_HEADER
1565
1566 # check for ISC (this may also define _POSIX_SOURCE)
1567 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1568 if test "x$ISC" = xyes ; then
1569         AC_CHECK_LIB(cposix,main)
1570         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1571 fi
1572
1573 CF_SYS_TIME_SELECT
1574
1575 ###     checks for compiler characteristics
1576 AC_LANG_C
1577 AC_C_CONST
1578 CF_C_INLINE(NCURSES_INLINE,1200)
1579 CF_SIG_ATOMIC_T
1580
1581 if test $NCURSES_CHTYPE = auto ; then
1582         CF_TYPEOF_CHTYPE
1583 else
1584         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1585 fi
1586 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1587 AC_SUBST(cf_cv_typeof_chtype)
1588
1589 CF_UNSIGNED_LITERALS
1590 cf_cv_1UL="1"
1591 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1592 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1593 AC_SUBST(cf_cv_1UL)
1594
1595 if test $NCURSES_MMASK_T = auto ; then
1596         cf_cv_typeof_mmask_t=long
1597 else
1598         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1599 fi
1600 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1601 AC_SUBST(cf_cv_typeof_mmask_t)
1602
1603 ###     Checks for external-data
1604 CF_ERRNO
1605 CF_LINK_DATAONLY
1606
1607 ###     Checks for library functions.
1608 AC_CHECK_FUNCS( \
1609 getcwd \
1610 getegid \
1611 geteuid \
1612 getopt \
1613 getttynam \
1614 issetugid \
1615 poll \
1616 putenv \
1617 remove \
1618 select \
1619 setbuf \
1620 setbuffer \
1621 setenv \
1622 setvbuf \
1623 sigaction \
1624 sigvec \
1625 strdup \
1626 strstr \
1627 tcgetpgrp \
1628 times \
1629 vsnprintf \
1630 )
1631
1632 if test "x$ac_cv_func_getopt" = xno &&
1633    test "x$cf_with_progs$cf_with_tests" != xnono; then
1634         AC_MSG_ERROR(getopt is required for building programs)
1635 fi
1636
1637 if test "x$with_getcap" = "xyes" ; then
1638         CF_CGETENT
1639 fi
1640
1641 CF_ISASCII
1642 CF_STRUCT_SIGACTION
1643 CF_FUNC_NANOSLEEP
1644 CF_FUNC_TERMIOS
1645 CF_FUNC_VSSCANF
1646 CF_MKSTEMP
1647
1648 # setup for prototype of fallback for vsscanf()
1649 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1650
1651 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1652 if test "x$cross_compiling" = xyes ; then
1653         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1654 else
1655         AC_FUNC_SETVBUF_REVERSED
1656 fi
1657 AC_CHECK_TYPE(intptr_t, long)
1658 AC_CHECK_TYPE(ssize_t, int)
1659 CF_TYPE_SIGACTION
1660 CF_SIZECHANGE
1661 CF_FUNC_MEMMOVE
1662 CF_FUNC_POLL
1663 CF_VA_COPY
1664 AC_FUNC_VFORK
1665
1666 # special check for test/ditto.c
1667 CF_FUNC_OPENPTY
1668 if test "$cf_cv_func_openpty" != no ; then
1669         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1670         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1671         if test "x$cf_cv_lib_util" = xyes ; then
1672                 CF_ADD_LIB(util,TEST_LIBS)
1673         fi
1674 fi
1675 AC_SUBST(TEST_LIBS)
1676 AC_SUBST(TEST_LIBS2)
1677
1678 if test "$with_hashed_db" != no ; then
1679         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1680         CF_HASHED_DB($with_hashed_db)
1681 fi
1682
1683 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1684 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1685         CF_STRIP_G_OPT(CFLAGS)
1686         CF_STRIP_G_OPT(CXXFLAGS)
1687 fi
1688
1689 # Just in case, check if the C compiler has a bool type.
1690 CF_BOOL_DECL(cf_cv_cc_bool_type)
1691
1692 # Check for C++ compiler characteristics (and ensure that it's there!)
1693 if test -n "$CXX" ; then
1694         AC_LANG_CPLUSPLUS
1695         CF_STDCPP_LIBRARY
1696         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1697
1698         case $GXX_VERSION in
1699         (1*|2.[0-6]*)
1700                 cf_cxx_library=yes
1701                 ;;
1702         (*-2.7*|2.7*)
1703                 CF_GPP_LIBRARY
1704                 ;;
1705         (*)
1706                 cf_cxx_library=no
1707                 ;;
1708         esac
1709
1710         AC_CHECK_HEADERS(typeinfo)
1711         CF_CXX_IOSTREAM_NAMESPACE
1712         CF_BOOL_DECL
1713         CF_BOOL_SIZE
1714         CF_ETIP_DEFINES
1715         CF_CPP_PARAM_INIT
1716         CF_CPP_STATIC_CAST
1717         CF_CXX_AR_FLAGS
1718 else
1719         cf_cxx_library=no
1720         cf_cv_builtin_bool=1
1721
1722         # Just because we are not configuring against C++ right now does not
1723         # mean that a user will not want to use C++.  Some distributors disable
1724         # the C++ portion of this configuration as a shortcut (or just to avoid
1725         # compiling the demo in the c++ directory).  So we need a reasonable
1726         # default for the 'bool' type.
1727         #
1728         # Caveat: since the storage of the bool type is not standardized, it
1729         # may change.
1730
1731         if test "$NCURSES_BOOL" != auto ; then
1732                 cf_cv_type_of_bool=$NCURSES_BOOL
1733                 cf_cv_header_stdbool_h=0
1734         else
1735                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1736                         CF_BOOL_SIZE
1737                 else
1738                         AC_MSG_CHECKING(for fallback type of bool)
1739                         case "$host_cpu" in
1740                         (i?86)  cf_cv_type_of_bool=char ;;
1741                         (*)     cf_cv_type_of_bool=int  ;;
1742                         esac
1743                         AC_MSG_RESULT($cf_cv_type_of_bool)
1744                 fi
1745         fi
1746 fi
1747 AC_SUBST(CXXLIBS)
1748
1749 # If the C compiler did not declare bool, and we did not determine that the C++
1750 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1751 # ncurses library use the same type as C++ bool.  Note that this allows one to
1752 # specify the type of bool in a configure-script option and postpone
1753 # integration with the C++ compiler provided that the types are compatible.
1754 USE_CXX_BOOL=1
1755 if test $cf_cv_cc_bool_type = 1
1756 then
1757         # oops: C has a bool.  Unlikely, but C++ could differ.
1758         USE_CXX_BOOL=0
1759 elif test $cf_cv_builtin_bool = 0
1760 then
1761         # C++ has no bool
1762         USE_CXX_BOOL=0
1763 else
1764         # this is the normal case
1765         USE_CXX_BOOL='defined(__cplusplus)'
1766 fi
1767 AC_SUBST(USE_CXX_BOOL)
1768
1769 CF_HELP_MESSAGE(Ada95 Binding Options:)
1770
1771 dnl If the Ada95 source-tree is present, add that to the build unless it will
1772 dnl not work, or was not requested.
1773 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1774
1775 dnl libtool does not know anything about GNAT, though a change made in 1998
1776 dnl provided for it "someday".  Disable the ada subtree if we are using
1777 dnl libtool -TD 20070714
1778         if test "$cf_with_ada" != "no" ; then
1779                 if test "$with_libtool" != "no"; then
1780                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1781                         cf_with_ada=no
1782                 fi
1783         fi
1784
1785 dnl Check for availability of GNU Ada Translator (GNAT).
1786 dnl At the moment we support no other Ada95 compiler.
1787         if test "$cf_with_ada" != "no" ; then
1788                 CF_PROG_GNAT
1789                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1790                         CF_ADD_ADAFLAGS(-gnatpn)
1791                         CF_FIXUP_ADAFLAGS
1792
1793                         CF_GNATPREP_OPT_T
1794
1795                         CF_GNAT_GENERICS
1796                         CF_GNAT_SIGINT
1797                         CF_GNAT_PROJECTS
1798
1799                         CF_WITH_ADA_COMPILER
1800
1801                         cf_ada_package=terminal_interface
1802                         AC_SUBST(cf_ada_package)
1803
1804                         CF_WITH_ADA_INCLUDE
1805                         CF_WITH_ADA_OBJECTS
1806                         CF_WITH_ADA_SHAREDLIB
1807                 fi
1808         fi
1809 else
1810         cf_with_ada=no
1811 fi
1812
1813 # do this "late" to avoid conflict with header-checks
1814 if test "x$with_widec" = xyes ; then
1815         AC_CHECK_SIZEOF(wchar_t)
1816 fi
1817
1818 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1819 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1820 ###
1821 ### ticlib modules may be a separate library, otherwise contained in termlib.
1822 ### termlib modules may be a separate library, otherwise contained in ncurses.
1823 ###
1824 ### The of "+" or " " between the tokens controls the way the script
1825 ### chooses to split module lists into libraries.
1826 ###
1827 ### (see CF_LIB_RULES).
1828 AC_MSG_CHECKING(for library subsets)
1829 LIB_SUBSETS=
1830
1831 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1832         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1833         if test "$with_ticlib" != no ; then
1834                 LIB_SUBSETS="${LIB_SUBSETS} "
1835         else
1836                 LIB_SUBSETS="${LIB_SUBSETS}+"
1837         fi
1838 fi
1839
1840 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1841 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1842
1843 if test "$with_termlib" != no ; then
1844         LIB_SUBSETS="${LIB_SUBSETS} "
1845 else
1846         LIB_SUBSETS="${LIB_SUBSETS}+"
1847 fi
1848
1849 LIB_SUBSETS="${LIB_SUBSETS}base"
1850
1851 # Most term-driver calls are to tinfo, but some like init_pair are to the
1852 # base library (so it resides in base).
1853 if test "$with_term_driver" != no ; then
1854         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1855         case $cf_cv_system_name in
1856         (*mingw32*|*mingw64*)
1857                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1858                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
1859                 ;;
1860         (*)
1861                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1862                 ;;
1863         esac
1864 fi
1865
1866 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1867 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1868
1869 AC_MSG_RESULT($LIB_SUBSETS)
1870
1871 ### Construct the list of include-directories to be generated
1872 CF_INCLUDE_DIRS
1873 CF_ADA_INCLUDE_DIRS
1874
1875 ### Build up pieces for makefile rules
1876 AC_MSG_CHECKING(default library suffix)
1877 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1878 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1879 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1880
1881 AC_MSG_CHECKING(default library-dependency suffix)
1882 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1883 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1884 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1885
1886 AC_MSG_CHECKING(default object directory)
1887 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1888 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1889 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1890
1891 if test "x$cf_with_cxx" = xyes ; then
1892 AC_MSG_CHECKING(c++ library-dependency suffix)
1893 if test "$with_libtool" != "no"; then
1894         # libtool thinks it can make c++ shared libraries (perhaps only g++)
1895         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1896 elif test "$with_shared_cxx" != "no"; then
1897         # also for g++ users...
1898         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1899 else
1900         # we normally make a static library because C/C++ library rules differ
1901         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
1902 fi
1903 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1904 AC_SUBST(CXX_LIB_SUFFIX)
1905 fi
1906
1907 # do not want -ldl in build except as needed for -lncurses dependency
1908 if test "x$with_dlsym" = xyes ; then
1909 if test $DFT_LWR_MODEL = shared || \
1910    test $DFT_LWR_MODEL = libtool ; then
1911         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1912 fi
1913 fi
1914 ### Set up low-level terminfo dependencies for makefiles.
1915
1916 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1917 # do not need libdl
1918 TICS_LIST=
1919 if test "x$with_dlsym" = xyes ; then
1920         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1921 fi
1922
1923 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
1924 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
1925 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
1926 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
1927 then
1928         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
1929 fi
1930 AC_SUBST(USE_ARG_SUFFIX)
1931 AC_SUBST(USE_CFG_SUFFIX)
1932 AC_SUBST(USE_LIB_SUFFIX)
1933
1934 if test "$with_ticlib" != no ; then
1935
1936         if test "x$with_ticlib" != xyes ; then
1937                 TICS_NAME=$with_ticlib
1938                 TICS_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
1939                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1940                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1941                 TICS_LIB_SUFFIX="${with_ticlib}"
1942         else
1943                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
1944                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
1945                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1946                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
1947         fi
1948         TICS_LDFLAGS="-L${LIB_DIR}"
1949         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
1950 else
1951         TICS_SUFFIX=${DFT_LIB_SUFFIX}
1952         TICS_LDFLAGS="-L${LIB_DIR}"
1953         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
1954 fi
1955 AC_SUBST(TICS_ARG_SUFFIX)
1956 AC_SUBST(TICS_DEP_SUFFIX)
1957 AC_SUBST(TICS_LIB_SUFFIX)
1958 AC_SUBST(TICS_LDFLAGS)
1959 AC_SUBST(TICS_LIBS)
1960
1961 if test "$with_termlib" != no ; then
1962
1963         if test "x$with_termlib" != xyes ; then
1964                 TINFO_NAME=$with_termlib
1965                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
1966                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1967                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1968                 TINFO_LIB_SUFFIX="${with_termlib}"
1969         else
1970                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1971                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
1972                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1973                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
1974         fi
1975
1976         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1977         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1978         if test "$DFT_LWR_MODEL" = "libtool"; then
1979                 TEST_ARGS="${TEST_DEPS}"
1980                 TEST_ARG2="${TEST_DEP2}"
1981                 TINFO_LDFLAGS="-L${LIB_DIR}"
1982                 TINFO_LIBS="$TEST_ARGS"
1983                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1984                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1985         else
1986                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1987                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1988                 if test "x$with_term_driver" != xno ; then
1989                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
1990                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
1991                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
1992                 else
1993                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1994                         TINFO_LIBS="$TEST_ARGS"
1995                 fi
1996                 TINFO_LDFLAGS="-L${LIB_DIR}"
1997                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1998         fi
1999 else
2000         # the next lines are needed for linking libtic over libncurses
2001         TINFO_NAME=${LIB_NAME}
2002         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2003         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2004         if test "x$with_tic_depends" = xyes ; then
2005                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2006         else
2007                 TICS_LIST="$SHLIB_LIST"
2008         fi
2009
2010         TINFO_LDFLAGS="-L${LIB_DIR}"
2011         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2012 fi
2013
2014 if test "$DFT_LWR_MODEL" = shared ; then
2015         case $cf_cv_system_name in
2016         (cygwin*|msys*)
2017                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2018                 TINFO_SUFFIX=.dll
2019                 ;;
2020         esac
2021 fi
2022
2023 AC_SUBST(TINFO_ARG_SUFFIX)
2024 AC_SUBST(TINFO_DEP_SUFFIX)
2025 AC_SUBST(TINFO_LIB_SUFFIX)
2026 AC_SUBST(TINFO_LDFLAGS)
2027 AC_SUBST(TINFO_LIBS)
2028
2029 if test "x$with_dlsym" = xyes ; then
2030         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2031 fi
2032
2033 if test "$DFT_LWR_MODEL" = "libtool"; then
2034         OBJEXT=lo
2035 fi
2036
2037 # needed for Ada95
2038 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2039 AC_SUBST(TINFO_LDFLAGS2)
2040
2041 case $DFT_LWR_MODEL in
2042 (normal|debug|profile)
2043         CF_LDFLAGS_STATIC
2044         ;;
2045 esac
2046
2047 AC_MSG_CHECKING(where we will install curses.h)
2048 AC_SUBST(includesubdir)
2049 includesubdir=
2050 if test "$with_overwrite" = no && \
2051  ( test "x$includedir" = 'x${prefix}/include' || \
2052    test "x$includedir" = "x${prefix}/include" )
2053 then
2054         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2055 fi
2056 AC_MSG_RESULT(${includedir}${includesubdir})
2057
2058 ### Resolve a conflict between normal and wide-curses by forcing applications
2059 ### that will need libutf8 to add it to their configure script.
2060 if test "$with_overwrite" != no ; then
2061 if test "$NCURSES_LIBUTF8" = 1 ; then
2062         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2063         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2064 fi
2065 fi
2066 WITH_OVERWRITE=$with_overwrite
2067
2068 AC_SUBST(WITH_OVERWRITE)
2069 AC_SUBST(TICS_LIST)
2070 AC_SUBST(TINFO_LIST)
2071 AC_SUBST(SHLIB_LIST)
2072
2073 # used to separate tack out of the tree
2074 NCURSES_TREE=
2075 AC_SUBST(NCURSES_TREE)
2076
2077 ### predefined stuff for the test programs
2078 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2079
2080 ### Construct the list of subdirectories for which we'll customize makefiles
2081 ### with the appropriate compile-rules.
2082
2083 CF_SRC_MODULES($modules_to_build)
2084
2085 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2086    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2087    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2088 fi
2089
2090 CF_DIRS_TO_MAKE
2091
2092 # symbols that differ when compiling Ada95 by itself.
2093 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2094 AC_SUBST(NCURSES_SHLIB2)
2095
2096 # values to use as strings
2097 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2098
2099 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2100
2101 ### Now that we're done running tests, add the compiler-warnings, if any
2102 CF_ADD_CFLAGS($EXTRA_CFLAGS)
2103
2104 ### Define substitutions for header files to avoid name-pollution
2105 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2106 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2107 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2108 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2109
2110 ################################################################################
2111 test "x$use_database" = xyes && \
2112 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2113
2114 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2115 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2116
2117 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2118 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2119 fi
2120 AC_SUBST(cross_compiling)
2121
2122 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
2123 if test -n "$FALLBACK_LIST"
2124 then
2125         if test "$TIC_PATH" = unknown
2126         then
2127                 AC_MSG_WARN(no tic program found for fallbacks)
2128         fi
2129 fi
2130 AC_SUBST(TIC_PATH)
2131
2132 if test "x$cf_with_tests" != xno ; then
2133         MAKE_TESTS=
2134 else
2135         MAKE_TESTS="#"
2136 fi
2137 AC_SUBST(MAKE_TESTS)
2138
2139 ADAHTML_DIR=../../doc/html/ada
2140 AC_SUBST(ADAHTML_DIR)
2141
2142 # these could be configurable, but are not currently
2143 PANEL_NAME=panel
2144 MENU_NAME=menu
2145 FORM_NAME=form
2146 CXX_NAME=ncurses++
2147
2148 AC_SUBST(PANEL_NAME)
2149 AC_SUBST(MENU_NAME)
2150 AC_SUBST(FORM_NAME)
2151 AC_SUBST(CXX_NAME)
2152
2153 # workaround for OS/2 (20151017)
2154 case $cf_cv_system_name in
2155 (os2*)
2156         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2157         ;;
2158 (*)
2159         LIBTOOL_OPTS_CXX=
2160         ;;
2161 esac
2162 AC_SUBST(LIBTOOL_OPTS_CXX)
2163
2164 # workaround for g++ versus Solaris (20131116)
2165 case $cf_cv_system_name in
2166 (solaris2*)
2167         case "x$CPPFLAGS" in
2168         (*-D_XOPEN_SOURCE_EXTENDED*)
2169                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2170                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2171                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2172                 ;;
2173         esac
2174         ;;
2175 esac
2176
2177 # Help to automatically enable the extended curses features when using either
2178 # the *-config or the ".pc" files by adding defines.
2179 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2180 PKG_CFLAGS=
2181 for cf_loop1 in $CPPFLAGS_after_XOPEN
2182 do
2183         cf_found=no
2184         for cf_loop2 in $CPPFLAGS_before_XOPEN
2185         do
2186                 if test "x$cf_loop1" = "x$cf_loop2"
2187                 then
2188                         cf_found=yes
2189                         break
2190                 fi
2191         done
2192         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2193 done
2194 AC_MSG_RESULT($PKG_CFLAGS)
2195 AC_SUBST(PKG_CFLAGS)
2196
2197 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2198 case "x$NCURSES_OSPEED" in
2199 (*short*)
2200         cf_compatible=1
2201         ;;
2202 (*)
2203         cf_compatible=0
2204         ;;
2205 esac
2206 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2207
2208 case "x$cf_cv_typeof_chtype" in
2209 (xshort|xint|xlong)
2210         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2211         ;;
2212 esac
2213
2214 case "x$cf_cv_typeof_mmask_t" in
2215 (xshort|xint|xlong)
2216         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2217         ;;
2218 esac
2219
2220 # substitute into misc/Makefile to suppress
2221 # (un)install.data from the
2222 # (un)install rules.
2223 if test "x$cf_with_db_install" = "xno"; then
2224         MISC_INSTALL_DATA=
2225         MISC_UNINSTALL_DATA=
2226 else
2227         MISC_INSTALL_DATA=install.data
2228         MISC_UNINSTALL_DATA=uninstall.data
2229 fi
2230 AC_SUBST(MISC_INSTALL_DATA)
2231 AC_SUBST(MISC_UNINSTALL_DATA)
2232
2233 SUB_SCRIPTS=
2234
2235 dnl Override the package used for exported symbols
2236 if test -n "$PACKAGE"
2237 then
2238         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2239         export PACKAGE
2240         echo "package: $PACKAGE"
2241 fi
2242
2243 UNALTERED_SYMS=
2244 cf_filter_syms=no
2245
2246 if test -n "$RESULTING_SYMS"
2247 then
2248         cf_filter_syms=$cf_dft_filter_syms
2249         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2250 fi
2251
2252 if test "x$WILDCARD_SYMS" = xno
2253 then
2254         cf_filter_syms=yes
2255 fi
2256
2257 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2258
2259 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2260 if test $cf_filter_syms = yes
2261 then
2262         RESULTING_SYMS=resulting.map
2263 fi
2264 AC_SUBST(UNALTERED_SYMS)
2265
2266 if test "x$cross_compiling" = xyes ; then
2267         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2268 else
2269         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2270 fi
2271 AC_SUBST(ADAGEN_LDFLAGS)
2272
2273 AC_OUTPUT( \
2274         include/MKterm.h.awk \
2275         include/curses.head:include/curses.h.in \
2276         include/ncurses_dll.h \
2277         include/termcap.h \
2278         include/unctrl.h \
2279         $SUB_SCRIPTS \
2280         $SUB_MAKEFILES \
2281         Makefile,[
2282 if test "x$cf_with_tests" != xno ; then
2283         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2284 fi
2285 CF_LIB_RULES($SRC_SUBDIRS)
2286
2287 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2288 if test -z "$USE_OLD_MAKERULES" ; then
2289         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
2290 fi
2291 fi
2292 ],[
2293 ### Special initialization commands, used to pass information from the
2294 ### configuration-run into config.status
2295
2296 AWK="$AWK"
2297 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2298 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2299 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2300 ECHO_LD="$ECHO_LD"
2301 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2302 LDCONFIG="$LDCONFIG"
2303 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2304 LIB_NAME="$LIB_NAME"
2305 LIB_PREFIX="$LIB_PREFIX"
2306 LIB_SUBSETS="$LIB_SUBSETS"
2307 LIB_SUFFIX="$LIB_SUFFIX"
2308 LIB_TRACING="$LIB_TRACING"
2309 LN_S="$LN_S"
2310 MAKE_TERMINFO="$MAKE_TERMINFO"
2311 NCURSES_MAJOR="$NCURSES_MAJOR"
2312 NCURSES_MINOR="$NCURSES_MINOR"
2313 NCURSES_OSPEED="$NCURSES_OSPEED"
2314 NCURSES_PATCH="$NCURSES_PATCH"
2315 SRC_SUBDIRS="$SRC_SUBDIRS"
2316 TERMINFO="$TERMINFO"
2317 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2318 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2319 TICS_NAME="$TICS_NAME"
2320 TICS_SUFFIX="$TICS_SUFFIX"
2321 TIC_PATH="$TIC_PATH"
2322 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2323 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2324 TINFO_NAME="$TINFO_NAME"
2325 TINFO_SUFFIX="$TINFO_SUFFIX"
2326 UNALTERED_SYMS="$UNALTERED_SYMS"
2327 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2328 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2329 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2330 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2331 WILDCARD_SYMS="$WILDCARD_SYMS"
2332 WITH_CURSES_H="$with_curses_h"
2333 WITH_ECHO="${enable_echo:=yes}"
2334 WITH_OVERWRITE="$with_overwrite"
2335 cf_LIST_MODELS="$cf_list_models"
2336 cf_cv_abi_version="$cf_cv_abi_version"
2337 cf_cv_do_relink="$cf_cv_do_relink"
2338 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2339 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2340 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2341 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2342 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2343 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2344 cf_cv_rel_version="$cf_cv_rel_version"
2345 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2346 cf_cv_shared_soname='$cf_cv_shared_soname'
2347 cf_cv_shlib_version="$cf_cv_shlib_version"
2348 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2349 cf_cv_system_name="$cf_cv_system_name"
2350 cf_cv_term_driver="$with_term_driver"
2351 cf_with_ada="$cf_with_ada"
2352 cf_with_cxx_binding="$cf_with_cxx_binding"
2353 cf_with_db_install="$cf_with_db_install"
2354 cf_with_manpages="$cf_with_manpages"
2355 cf_with_tests="$cf_with_tests"
2356 host="$host"
2357 target="$target"
2358 with_shared_cxx="$with_shared_cxx"
2359
2360 ],cat)dnl
2361 ${MAKE:-make} preinstall