configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2016,2017 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.646 2017/08/07 23:27:56 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.52.20170501)
  38 AC_REVISION($Revision: 1.646 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44 CF_VERSION_INFO(NCURSES,ncurses)
  45
  46 CF_WITH_REL_VERSION(NCURSES)
  47 CF_NCURSES_WITH_ABI_VERSION
  48
  49 CF_WITH_SYSTYPE
  50
  51 ###     Save the given $CFLAGS to allow user-override.
  52 cf_user_CFLAGS="$CFLAGS"
  53
  54 ###     Default install-location
  55 CF_CFG_DEFAULTS
  56 ### Defaults for ncurses ABI
  57 CF_ABI_DEFAULTS
  58
  59 ###     Checks for programs.
  60 AC_ARG_WITH(ada,
  61         [  --without-ada           suppress check for Ada95, don't build demo],
  62         [cf_with_ada=$withval],
  63         [cf_with_ada=yes])
  64 if test "x$cf_with_ada" = xyes
  65 then
  66         cf_PROG_CC="gnatgcc gcc cc"
  67 else
  68         cf_PROG_CC="gcc cc"
  69 fi
  70
  71 CF_PROG_CC($cf_PROG_CC)
  72
  73 AC_PROG_CPP
  74 AC_PROG_GCC_TRADITIONAL
  75 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
  76 CF_PROG_LDCONFIG
  77
  78 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  79 dnl                             configure script by not letting us test if C++
  80 dnl                             is present, making this option necessary.
  81 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  82 AC_ARG_WITH(cxx,
  83         [  --without-cxx           do not adjust ncurses bool to match C++],
  84         [cf_with_cxx=$withval],
  85         [cf_with_cxx=yes])
  86 AC_MSG_RESULT($cf_with_cxx)
  87 if test "X$cf_with_cxx" = Xno ; then
  88         CXX=""
  89         GXX=""
  90 else
  91         # with autoconf 2.13, we can change the error to a warning:
  92         pushdef([AC_MSG_ERROR],
  93                 [AC_MSG_RESULT(no)
  94                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  95                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  96         AC_PROG_CXX
  97         popdef([AC_MSG_ERROR])dnl
  98
  99         AC_LANG_PUSH(C++)
 100         if test "x$cf_with_cxx" != xno
 101         then
 102                 # Several of the C++ configurations do not work, particularly when
 103                 # cross-compiling (20140913 -TD)
 104                 AC_MSG_CHECKING(if $CXX works)
 105
 106                 save_CPPFLAGS="$CPPFLAGS"
 107                 eval cf_includedir=${includedir}
 108                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 109                 AC_TRY_COMPILE([
 110 #include <stdlib.h>
 111 #include <stdio.h>
 112 ],
 113                 [
 114                 printf("Hello world!\n")
 115                 ],
 116                 [cf_cxx_works=yes],
 117                 [cf_cxx_works=no])
 118                 CPPFLAGS="$save_CPPFLAGS"
 119
 120                 AC_MSG_RESULT($cf_cxx_works)
 121                 if test "x$cf_cxx_works" = xno
 122                 then
 123                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 124                         cf_with_cxx=no; CXX=""; GXX="";
 125                 fi
 126         fi
 127         AC_LANG_POP
 128
 129         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 130         if test "$CXX" = "g++" ; then
 131                 AC_PATH_PROG(CXX,g++)
 132         fi
 133         case "x$CXX" in
 134         (x|xg++)
 135                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 136                 cf_with_cxx=no; CXX=""; GXX="";
 137                 ;;
 138         esac
 139 fi
 140
 141 CF_GXX_VERSION
 142 case $GXX_VERSION in
 143 (1*|2.[[0-6]]*)
 144         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 145         # cf_cxx_library=no
 146         AC_MSG_WARN(templates do not work)
 147         ;;
 148 esac
 149
 150 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 151 AC_ARG_WITH(cxx-binding,
 152         [  --without-cxx-binding   do not build C++ binding and demo],
 153         [cf_with_cxx_binding=$withval],
 154         [cf_with_cxx_binding=$cf_with_cxx])
 155 AC_MSG_RESULT($cf_with_cxx_binding)
 156
 157 AC_MSG_CHECKING(if you want to build with Ada95)
 158 AC_MSG_RESULT($cf_with_ada)
 159
 160 AC_MSG_CHECKING(if you want to install terminal database)
 161 AC_ARG_ENABLE(db-install,
 162         [  --disable-db-install    suppress install of terminal database],
 163         [cf_with_db_install=$enableval],
 164         [cf_with_db_install=yes])
 165 AC_MSG_RESULT($cf_with_db_install)
 166
 167 AC_MSG_CHECKING(if you want to install manpages)
 168 AC_ARG_WITH(manpages,
 169         [  --without-manpages      suppress install of manpages],
 170         [cf_with_manpages=$withval],
 171         [cf_with_manpages=yes])
 172 AC_MSG_RESULT($cf_with_manpages)
 173
 174 AC_MSG_CHECKING(if you want to build programs such as tic)
 175 AC_ARG_WITH(progs,
 176         [  --without-progs         suppress build/install with programs (e.g., tic)],
 177         [cf_with_progs=$withval],
 178         [cf_with_progs=yes])
 179 AC_MSG_RESULT($cf_with_progs)
 180
 181 if test -f $srcdir/tack/tack.h; then
 182         if test "x$cross_compiling" = xyes ; then
 183                 CF_VERBOSE(ignoring tack because we are cross-compiling)
 184                 cf_with_tack=no
 185         else
 186                 AC_MSG_CHECKING(if you want to build the tack program)
 187                 AC_ARG_WITH(tack,
 188                         [  --without-tack          suppress build/install with tack program],
 189                         [cf_with_tack=$withval],
 190                         [cf_with_tack=$cf_with_progs])
 191                 AC_MSG_RESULT($cf_with_tack)
 192         fi
 193 else
 194         cf_with_tack=no
 195 fi
 196
 197 AC_MSG_CHECKING(if you want to build test-programs)
 198 AC_ARG_WITH(tests,
 199         [  --without-tests         suppress build/install with test-programs],
 200         [cf_with_tests=$withval],
 201         [cf_with_tests=yes])
 202 AC_MSG_RESULT($cf_with_tests)
 203
 204 AC_MSG_CHECKING(if you wish to install curses.h)
 205 AC_ARG_WITH(curses-h,
 206         [  --without-curses-h      install curses.h as ncurses.h only],
 207         [with_curses_h=$withval],
 208         [with_curses_h=yes])
 209 AC_MSG_RESULT($with_curses_h)
 210
 211 modules_to_build="ncurses"
 212 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
 213 test "X$cf_with_tack"  != Xno && modules_to_build="$modules_to_build tack"
 214 modules_to_build="$modules_to_build panel menu form"
 215
 216 AC_ARG_PROGRAM
 217
 218 CF_PROG_AWK
 219 CF_PROG_EGREP
 220 CF_PROG_INSTALL
 221 CF_PROG_LINT
 222 CF_PROG_LN_S
 223
 224 AC_SYS_LONG_FILE_NAMES
 225
 226 # if we find pkg-config, check if we should install the ".pc" files.
 227 CF_PKG_CONFIG
 228 CF_WITH_PKG_CONFIG_LIBDIR
 229 CF_ENABLE_PC_FILES
 230 if test -z "$MAKE_PC_FILES"
 231 then
 232         AC_MSG_CHECKING(for suffix to add to pc-files)
 233 AC_ARG_WITH(pc-suffix,
 234         [  --with-pc-suffix        suffixes pc-files],
 235         [case "x$withval" in
 236         (xyes|xno)
 237                 PC_MODULE_SUFFIX=
 238                 ;;
 239         (*)     PC_MODULE_SUFFIX="$withval"
 240                 ;;
 241         esac])
 242         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
 243         AC_MSG_RESULT($PC_MODULE_SUFFIX)
 244         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
 245         AC_SUBST(PC_MODULE_SUFFIX)
 246 fi
 247
 248 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 249 AC_ARG_ENABLE(mixed-case,
 250         [  --enable-mixed-case     tic should assume mixed-case filenames],
 251         [enable_mixedcase=$enableval],
 252         [enable_mixedcase=auto])
 253 AC_MSG_RESULT($enable_mixedcase)
 254 if test "$enable_mixedcase" = "auto" ; then
 255         CF_MIXEDCASE_FILENAMES
 256 else
 257         cf_cv_mixedcase=$enable_mixedcase
 258         if test "x$enable_mixedcase" = "xyes" ; then
 259                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 260         fi
 261 fi
 262
 263 # do this after mixed-case option (tags/TAGS is not as important as tic).
 264 AC_PROG_MAKE_SET
 265 CF_MAKE_TAGS
 266 CF_MAKEFLAGS
 267
 268 dnl These are standard among *NIX systems, but not when cross-compiling
 269 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 270 AC_CHECK_TOOL(LD, ld, ld)
 271 AC_CHECK_TOOL(AR, ar, ar)
 272 AC_CHECK_TOOL(NM, nm, nm)
 273 CF_AR_FLAGS
 274
 275 dnl Special option for use by system-builders: the install-prefix is used to
 276 dnl adjust the location into which the actual install is done, so that an
 277 dnl archive can be built without modifying the host system's configuration.
 278 AC_MSG_CHECKING(if you have specified an install-prefix)
 279 AC_ARG_WITH(install-prefix,
 280         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 281         [case "x$withval" in
 282         (xyes|xno)
 283                 ;;
 284         (*)     DESTDIR="$withval"
 285                 ;;
 286         esac])
 287 AC_MSG_RESULT($DESTDIR)
 288 AC_SUBST(DESTDIR)
 289
 290 ###############################################################################
 291 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 292 # If we're cross-compiling, allow the user to override the tools and their
 293 # options.  The configure script is oriented toward identifying the host
 294 # compiler, etc., but we need a build compiler to generate parts of the source.
 295 CF_BUILD_CC
 296
 297 ###############################################################################
 298 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 299
 300 ### Options to allow the user to specify the set of libraries which are used.
 301 ### Use "--without-normal --with-shared" to allow the default model to be
 302 ### shared, for example.
 303 cf_list_models=""
 304 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 305
 306 CF_WITH_LIBTOOL
 307 if test "$with_libtool" != "no" ; then
 308
 309 cf_list_models="$cf_list_models libtool"
 310
 311 else
 312
 313 AC_MSG_CHECKING(if you want to build shared libraries)
 314 AC_ARG_WITH(shared,
 315         [  --with-shared           generate shared-libraries],
 316         [with_shared=$withval],
 317         [with_shared=no])
 318 AC_MSG_RESULT($with_shared)
 319 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 320
 321 AC_MSG_CHECKING(if you want to build static libraries)
 322 AC_ARG_WITH(normal,
 323         [  --with-normal           generate normal-libraries (default)],
 324         [with_normal=$withval],
 325         [with_normal=yes])
 326 AC_MSG_RESULT($with_normal)
 327 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 328
 329 AC_MSG_CHECKING(if you want to build debug libraries)
 330 AC_ARG_WITH(debug,
 331         [  --with-debug            generate debug-libraries (default)],
 332         [with_debug=$withval],
 333         [with_debug=yes])
 334 AC_MSG_RESULT($with_debug)
 335 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 336
 337 AC_MSG_CHECKING(if you want to build profiling libraries)
 338 AC_ARG_WITH(profile,
 339         [  --with-profile          generate profile-libraries],
 340         [with_profile=$withval],
 341         [with_profile=no])
 342 AC_MSG_RESULT($with_profile)
 343 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 344
 345 fi
 346
 347 if test "X$cf_with_cxx_binding" != Xno; then
 348 if test "x$with_shared" = "xyes"; then
 349 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 350 AC_ARG_WITH(cxx-shared,
 351         [  --with-cxx-shared       generate C++ shared-libraries],
 352         [with_shared_cxx=$withval],
 353         [with_shared_cxx=no])
 354 AC_MSG_RESULT($with_shared_cxx)
 355 fi
 356 fi
 357
 358 ###############################################################################
 359
 360 AC_MSG_CHECKING(for specified models)
 361 test -z "$cf_list_models" && cf_list_models=normal
 362 dnl If we use libtool to generate libraries, then it must be the only
 363 dnl specified model.
 364 test "$with_libtool" != "no" && cf_list_models=libtool
 365 AC_MSG_RESULT($cf_list_models)
 366
 367 ### Use the first model as the default, and save its suffix for use in building
 368 ### up test-applications.
 369 AC_MSG_CHECKING(for default model)
 370 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 371 AC_MSG_RESULT($DFT_LWR_MODEL)
 372
 373 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 374
 375 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 376 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 377
 378 TICS_NAME=tic
 379 AC_SUBST(TICS_NAME)
 380
 381 TINFO_NAME=tinfo
 382 AC_SUBST(TINFO_NAME)
 383
 384 LIB_NAME=ncurses
 385 AC_SUBST(LIB_NAME)
 386
 387 LIB_DIR=../lib
 388 LIB_2ND=../../lib
 389
 390 CF_WITH_LIB_PREFIX(cf_prefix)
 391
 392 LIB_SUFFIX=
 393 AC_SUBST(LIB_SUFFIX)
 394 CF_PATHSEP
 395
 396 ###############################################################################
 397
 398 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 399 AC_ARG_WITH(termlib,
 400         [  --with-termlib          generate separate terminfo library],
 401         [with_termlib=$withval],
 402         [with_termlib=no])
 403 AC_MSG_RESULT($with_termlib)
 404
 405 AC_MSG_CHECKING(if you want to build a separate tic library)
 406 AC_ARG_WITH(ticlib,
 407         [  --with-ticlib           generate separate tic library],
 408         [with_ticlib=$withval],
 409         [with_ticlib=no])
 410 AC_MSG_RESULT($with_ticlib)
 411
 412 ### Checks for special libraries, must be done up-front.
 413 SHLIB_LIST=""
 414 CF_WITH_GPM
 415 if test "$with_gpm" != no ; then
 416         AC_MSG_CHECKING(if you want to load GPM dynamically)
 417         AC_ARG_WITH(dlsym,
 418                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 419                 [with_dlsym=$withval],
 420                 [with_dlsym=yes])
 421         AC_MSG_RESULT($with_dlsym)
 422         if test "x$with_dlsym" = xyes ; then
 423                 CF_FUNC_DLSYM
 424                 if test "x$with_gpm" != xyes ; then
 425                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 426                         cf_cv_gpm_soname="$with_gpm"
 427                 else
 428                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 429                 fi
 430                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 431                 SHLIB_LIST="-ldl $SHLIB_LIST"
 432         else
 433                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 434                 CF_ADD_LIB(gpm,TEST_LIBS)
 435         fi
 436         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 437         CF_CHECK_GPM_WGETCH
 438 fi
 439
 440 CF_WITH_SYSMOUSE
 441
 442 dnl Not all ports of gcc support the -g option
 443
 444 if test X"$CC_G_OPT" = X"" ; then
 445         CC_G_OPT='-g'
 446         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 447 fi
 448 AC_SUBST(CC_G_OPT)
 449
 450 if test X"$CXX_G_OPT" = X"" ; then
 451         CXX_G_OPT='-g'
 452         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 453 fi
 454 AC_SUBST(CXX_G_OPT)
 455
 456 AC_MSG_CHECKING(for default loader flags)
 457 case $DFT_LWR_MODEL in
 458 (libtool) LD_MODEL=''   ;;
 459 (normal)  LD_MODEL=''   ;;
 460 (debug)   LD_MODEL=$CC_G_OPT ;;
 461 (profile) LD_MODEL='-pg';;
 462 (shared)  LD_MODEL=''   ;;
 463 esac
 464 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 465 AC_MSG_RESULT($LD_MODEL)
 466
 467 case $DFT_LWR_MODEL in
 468 (shared)
 469 CF_ENABLE_RPATH
 470 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 471 AC_ARG_ENABLE(relink,
 472 [  --disable-relink        relink shared libraries during install],
 473 [cf_cv_do_relink=$enableval],
 474 [cf_cv_do_relink=yes])
 475 AC_MSG_RESULT($cf_cv_do_relink)
 476         ;;
 477 esac
 478
 479 # we will build libraries one-level down.
 480 rel_builddir=..
 481 CF_SHARED_OPTS
 482 for model in $cf_list_models; do
 483         case $model in
 484         (libtool)
 485                 CF_WITH_LIBTOOL_OPTS
 486                 CF_WITH_EXPORT_SYMS
 487                 ;;
 488         (shared)
 489                 if test "$CC_SHARED_OPTS" = "unknown"; then
 490                         AC_ERROR(Shared libraries are not supported in this version)
 491                 fi
 492                 # workaround for inept transition to PIE vs PIC...
 493                 AC_MSG_CHECKING(if current CFLAGS link properly)
 494                 AC_TRY_LINK(
 495                         [#include <stdio.h>],
 496                         [printf("Hello work\n");],
 497                         [cf_cflags_work=yes],
 498                         [cf_cflags_work=no])
 499                 AC_MSG_RESULT($cf_cflags_work)
 500                 if test "$cf_cflags_work" = no
 501                 then
 502                         CF_VERBOSE(try to work around by appending shared-options)
 503                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
 504                 fi
 505                 CF_WITH_VERSIONED_SYMS
 506                 ;;
 507         esac
 508 done
 509
 510 # pretend that ncurses==ncursesw==ncursest
 511 AC_MSG_CHECKING(if you want to disable library suffixes)
 512 CF_ARG_DISABLE(lib-suffixes,
 513         [  --disable-lib-suffixes  disable library suffixes],
 514         [disable_lib_suffixes=yes],
 515         [disable_lib_suffixes=no],
 516         no)
 517 AC_MSG_RESULT($disable_lib_suffixes)
 518
 519 ### If we're building with rpath, try to link non-standard libs that way too.
 520 if test "$DFT_LWR_MODEL" = "shared"; then
 521         CF_DISABLE_RPATH_HACK
 522 fi
 523
 524 ###############################################################################
 525 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 526
 527 ###     use option --with-extra-suffix to append suffix to headers and libraries
 528 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
 529 EXTRA_SUFFIX=
 530 AC_ARG_WITH(extra-suffix,
 531         [  --with-extra-suffix=X   append extra suffix to header/library paths],
 532         [case x$withval in
 533         (no)
 534                 ;;
 535         (xyes|x)
 536                 EXTRA_SUFFIX=$cf_cv_abi_version
 537                 ;;
 538         (*)
 539                 EXTRA_SUFFIX=$withval
 540                 ;;
 541         esac
 542         ])
 543 AC_MSG_RESULT($EXTRA_SUFFIX)
 544 AC_SUBST(EXTRA_SUFFIX)
 545
 546 ###     use option --disable-overwrite to leave out the link to -lcurses
 547 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 548 AC_ARG_ENABLE(overwrite,
 549         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
 550         [with_overwrite=$enableval],
 551         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 552 AC_MSG_RESULT($with_overwrite)
 553
 554 AC_MSG_CHECKING(if external terminfo-database is used)
 555 AC_ARG_ENABLE(database,
 556         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 557         [use_database=$enableval],
 558         [use_database=yes])
 559 AC_MSG_RESULT($use_database)
 560
 561 case $host_os in
 562 (os2*)
 563         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 564         ;;
 565 (*)
 566         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 567         ;;
 568 esac
 569 AC_SUBST(TERMINFO_SRC)
 570
 571 NCURSES_USE_DATABASE=0
 572 if test "$use_database" != no ; then
 573         NCURSES_USE_DATABASE=1
 574
 575         AC_MSG_CHECKING(which terminfo source-file will be installed)
 576         AC_ARG_WITH(database,
 577                 [  --with-database=XXX     specify terminfo source to install],
 578                 [TERMINFO_SRC=$withval])
 579         AC_MSG_RESULT($TERMINFO_SRC)
 580
 581         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 582         AC_ARG_WITH(hashed-db,
 583                 [  --with-hashed-db        specify hashed-database library],,
 584                 [with_hashed_db=no])
 585         AC_MSG_RESULT($with_hashed_db)
 586 else
 587         with_hashed_db=no
 588 fi
 589 AC_SUBST(NCURSES_USE_DATABASE)
 590
 591 AC_MSG_CHECKING(for list of fallback descriptions)
 592 AC_ARG_WITH(fallbacks,
 593         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 594         [with_fallback=$withval],
 595         [with_fallback=])
 596 AC_MSG_RESULT($with_fallback)
 597 FALLBACK_LIST=`test "$with_fallback" != no && echo "$with_fallback" | sed -e 's/,/ /g'`
 598 AC_SUBST(FALLBACK_LIST)
 599
 600 AC_MSG_CHECKING(if you want modern xterm or antique)
 601 AC_ARG_WITH(xterm-new,
 602         [  --without-xterm-new     specify if xterm terminfo should be old version],
 603         [with_xterm_new=$withval],
 604         [with_xterm_new=yes])
 605 case $with_xterm_new in
 606 (no) with_xterm_new=xterm-old;;
 607 (*)      with_xterm_new=xterm-new;;
 608 esac
 609 AC_MSG_RESULT($with_xterm_new)
 610 WHICH_XTERM=$with_xterm_new
 611 AC_SUBST(WHICH_XTERM)
 612
 613 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 614 AC_ARG_WITH(xterm-kbs,
 615         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
 616         [with_xterm_kbs=$withval],
 617         [with_xterm_kbs=BS])
 618 case x$with_xterm_kbs in
 619 (xyes|xno|xBS|xbs|x8)
 620         with_xterm_kbs=BS
 621         ;;
 622 (xDEL|xdel|x127)
 623         with_xterm_kbs=DEL
 624         ;;
 625 (*)
 626         with_xterm_kbs=$withval
 627         ;;
 628 esac
 629 AC_MSG_RESULT($with_xterm_kbs)
 630 XTERM_KBS=$with_xterm_kbs
 631 AC_SUBST(XTERM_KBS)
 632
 633 MAKE_TERMINFO=
 634 if test "$use_database" = no ; then
 635         TERMINFO="${datadir}/terminfo"
 636         MAKE_TERMINFO="#"
 637 else
 638
 639 AC_MSG_CHECKING(for list of terminfo directories)
 640 CF_WITH_PATHLIST(terminfo-dirs,
 641         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 642         TERMINFO_DIRS,
 643         DATADIR/terminfo,
 644         ${datadir}/terminfo)
 645 AC_MSG_RESULT($TERMINFO_DIRS)
 646 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 647
 648 AC_MSG_CHECKING(for default terminfo directory)
 649 CF_WITH_PATH(default-terminfo-dir,
 650         [  --with-default-terminfo-dir=DIR default terminfo directory],
 651         TERMINFO,
 652         DATADIR/terminfo,
 653         ${datadir}/terminfo)
 654 AC_MSG_RESULT($TERMINFO)
 655 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 656
 657 fi
 658
 659 AC_SUBST(TERMINFO)
 660 AC_SUBST(MAKE_TERMINFO)
 661
 662 ###     use option --disable-big-core to make tic run on small machines
 663 ###     We need 4Mb, check if we can allocate 50% more than that.
 664 AC_MSG_CHECKING(if big-core option selected)
 665 AC_ARG_ENABLE(big-core,
 666         [  --disable-big-core      assume machine has little memory],
 667         [with_big_core=$enableval],
 668         [AC_TRY_RUN([
 669 #include <stdlib.h>
 670 #include <string.h>
 671 int main() {
 672         unsigned long n = 6000000L;
 673         char *s = malloc(n);
 674         if (s != 0)
 675                 s[0] = s[n-1] = 0;
 676         ${cf_cv_main_return:-return}(s == 0);
 677 }],
 678         [with_big_core=yes],
 679         [with_big_core=no],
 680         [with_big_core=no])])
 681 AC_MSG_RESULT($with_big_core)
 682 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 683
 684 ### ISO C only guarantees 512-char strings, we have tables which load faster
 685 ### when constructed using "big" strings.  More than the C compiler, the awk
 686 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 687 AC_MSG_CHECKING(if big-strings option selected)
 688 AC_ARG_ENABLE(big-strings,
 689         [  --disable-big-strings   assume compiler has only standard-size strings],
 690         [with_big_strings=$enableval],
 691         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 692 AC_MSG_RESULT($with_big_strings)
 693
 694 USE_BIG_STRINGS=0
 695 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 696 AC_SUBST(USE_BIG_STRINGS)
 697
 698 ###     use option --enable-termcap to compile in the termcap fallback support
 699 AC_MSG_CHECKING(if you want termcap-fallback support)
 700 AC_ARG_ENABLE(termcap,
 701         [  --enable-termcap        compile in termcap fallback support],
 702         [with_termcap=$enableval],
 703         [with_termcap=no])
 704 AC_MSG_RESULT($with_termcap)
 705
 706 NCURSES_USE_TERMCAP=0
 707 if test "x$with_termcap" != "xyes" ; then
 708         if test "$use_database" = no ; then
 709                 if test -z "$with_fallback" ; then
 710                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 711                 fi
 712         fi
 713         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 714 else
 715
 716         if test "$with_ticlib" != no ; then
 717                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 718         fi
 719
 720         NCURSES_USE_TERMCAP=1
 721         AC_MSG_CHECKING(for list of termcap files)
 722         CF_WITH_PATHLIST(termpath,
 723                 [  --with-termpath=XXX     specify list of termcap files],
 724                 TERMPATH,
 725                 /etc/termcap:/usr/share/misc/termcap)
 726         AC_MSG_RESULT($TERMPATH)
 727         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 728
 729         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 730         AC_MSG_CHECKING(if fast termcap-loader is needed)
 731         AC_ARG_ENABLE(getcap,
 732                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 733                 [with_getcap=$enableval],
 734                 [with_getcap=no])
 735         AC_MSG_RESULT($with_getcap)
 736         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 737
 738         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 739         AC_ARG_ENABLE(getcap-cache,
 740                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 741                 [with_getcap_cache=$enableval],
 742                 [with_getcap_cache=no])
 743         AC_MSG_RESULT($with_getcap_cache)
 744         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 745
 746 fi
 747 AC_SUBST(NCURSES_USE_TERMCAP)
 748
 749 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 750 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 751 AC_ARG_ENABLE(home-terminfo,
 752         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 753         [with_home_terminfo=$enableval],
 754         [with_home_terminfo=yes])
 755 AC_MSG_RESULT($with_home_terminfo)
 756 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 757
 758 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 759 AC_ARG_ENABLE(root-environ,
 760         [  --disable-root-environ  restrict environment when running as root],
 761         [with_root_environ=$enableval],
 762         [with_root_environ=yes])
 763 AC_MSG_RESULT($with_root_environ)
 764 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
 765
 766 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 767 ###   to reduce storage requirements for the terminfo database.
 768 CF_LINK_FUNCS
 769
 770 with_links=no
 771 with_symlinks=no
 772
 773 # soft links (symbolic links) are useful for some systems where hard links do
 774 # not work, or to make it simpler to copy terminfo trees around.
 775 if test "x$ac_cv_func_symlink" = xyes ; then
 776         AC_MSG_CHECKING(if tic should use symbolic links)
 777         AC_ARG_ENABLE(symlinks,
 778         [  --enable-symlinks       make tic use symbolic links not hard links],
 779         [with_symlinks=$enableval],
 780         [with_symlinks=no])
 781         AC_MSG_RESULT($with_symlinks)
 782 fi
 783
 784 # If we have hard links and did not choose to use soft links instead, there is
 785 # no reason to make this choice optional - use the hard links.
 786 if test "$with_symlinks" = no ; then
 787         AC_MSG_CHECKING(if tic should use hard links)
 788         if test "x$ac_cv_func_link" = xyes ; then
 789                 with_links=yes
 790         else
 791                 with_links=no
 792         fi
 793         AC_MSG_RESULT($with_links)
 794 fi
 795
 796 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 797 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 798
 799 ###   use option --enable-broken-linker to force on use of broken-linker support
 800 AC_MSG_CHECKING(if you want broken-linker support code)
 801 AC_ARG_ENABLE(broken_linker,
 802         [  --enable-broken_linker  compile with broken-linker support code],
 803         [with_broken_linker=$enableval],
 804         [with_broken_linker=${BROKEN_LINKER:-no}])
 805 AC_MSG_RESULT($with_broken_linker)
 806
 807 BROKEN_LINKER=0
 808 if test "x$with_broken_linker" = xyes ; then
 809         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
 810         BROKEN_LINKER=1
 811 elif test "$DFT_LWR_MODEL" = shared ; then
 812         case $cf_cv_system_name in
 813         (cygwin*)
 814                 AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
 815                 BROKEN_LINKER=1
 816                 CF_VERBOSE(cygwin linker is broken anyway)
 817                 ;;
 818         esac
 819 fi
 820 AC_SUBST(BROKEN_LINKER)
 821
 822 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 823 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 824 AC_ARG_ENABLE(bsdpad,
 825         [  --enable-bsdpad         recognize BSD-style prefix padding],
 826         [with_bsdpad=$enableval],
 827         [with_bsdpad=no])
 828 AC_MSG_RESULT($with_bsdpad)
 829 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 830
 831 ###   use option --enable-widec to turn on use of wide-character support
 832 NCURSES_CH_T=chtype
 833 NCURSES_LIBUTF8=0
 834
 835 NEED_WCHAR_H=0
 836 NCURSES_MBSTATE_T=0
 837 NCURSES_WCHAR_T=0
 838 NCURSES_WINT_T=0
 839
 840 # Check to define _XOPEN_SOURCE "automatically"
 841 CPPFLAGS_before_XOPEN="$CPPFLAGS"
 842 CF_XOPEN_SOURCE(500)
 843 CPPFLAGS_after_XOPEN="$CPPFLAGS"
 844
 845 # Work around breakage on OS X
 846 CF_SIGWINCH
 847
 848 # Checks for CODESET support.
 849 AM_LANGINFO_CODESET
 850
 851 # use these variables to work around a defect in gcc's fixincludes.
 852 NCURSES_OK_WCHAR_T=
 853 NCURSES_OK_WINT_T=
 854
 855 AC_MSG_CHECKING(if you want wide-character code)
 856 AC_ARG_ENABLE(widec,
 857         [  --enable-widec          compile with wide-char/UTF-8 code],
 858         [with_widec=$enableval],
 859         [with_widec=no])
 860 AC_MSG_RESULT($with_widec)
 861
 862 NCURSES_WCWIDTH_GRAPHICS=1
 863 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
 864
 865 if test "x$with_widec" = xyes ; then
 866         if test "x$disable_lib_suffixes" = xno ; then
 867                 LIB_SUFFIX="w${LIB_SUFFIX}"
 868         fi
 869         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
 870         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
 871
 872         CF_CHECK_WCHAR_H
 873         CF_CHECK_WCWIDTH_GRAPHICS
 874         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
 875
 876         # with_overwrite=no
 877         NCURSES_CH_T=cchar_t
 878         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 879         if test "x$ac_cv_func_putwc" != xyes ; then
 880                 CF_UTF8_LIB
 881                 if test "$cf_cv_utf8_lib" != no ; then
 882                         NCURSES_LIBUTF8=1
 883                 fi
 884         fi
 885         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 886         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 887         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 888
 889         if test "$NCURSES_MBSTATE_T" != 0; then
 890                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 891         fi
 892 fi
 893 AC_SUBST(NCURSES_CH_T)
 894 AC_SUBST(NCURSES_LIBUTF8)
 895
 896 AC_SUBST(NEED_WCHAR_H)
 897 AC_SUBST(NCURSES_MBSTATE_T)
 898 AC_SUBST(NCURSES_WCHAR_T)
 899 AC_SUBST(NCURSES_WINT_T)
 900
 901 AC_SUBST(NCURSES_OK_WCHAR_T)
 902 AC_SUBST(NCURSES_OK_WINT_T)
 903
 904 ###   use option --disable-lp64 to allow long chtype
 905 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 906 AC_ARG_ENABLE(lp64,
 907         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 908         [with_lp64=$enableval],
 909         [with_lp64=$cf_dft_with_lp64])
 910 AC_MSG_RESULT($with_lp64)
 911
 912 if test "x$with_lp64" = xyes ; then
 913         cf_cv_enable_lp64=1
 914 else
 915         cf_cv_enable_lp64=0
 916 fi
 917 AC_SUBST(cf_cv_enable_lp64)
 918
 919 CF_LARGEFILE
 920
 921 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 922 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 923 AC_ARG_ENABLE(tparm-varargs,
 924         [  --disable-tparm-varargs compile tparm() without varargs interface],
 925         [with_tparm_varargs=$enableval],
 926         [with_tparm_varargs=yes])
 927 AC_MSG_RESULT($with_tparm_varargs)
 928 NCURSES_TPARM_VARARGS=0
 929 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
 930 AC_SUBST(NCURSES_TPARM_VARARGS)
 931
 932 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 933 if test "$with_ticlib" != no ; then
 934 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 935 AC_ARG_ENABLE(tic-depends,
 936         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 937         [with_tic_depends=$enableval],
 938         [with_tic_depends=yes])
 939 AC_MSG_RESULT($with_tic_depends)
 940 else
 941         with_tic_depends=no
 942 fi
 943
 944 ###   use option --disable-wattr-macros to suppress wattr* macros from curses.h
 945 AC_MSG_CHECKING(if you want to suppress wattr* macros to help with ncurses5/ncurses6 transition)
 946 AC_ARG_ENABLE(wattr-macros,
 947         [  --disable-wattr-macros  suppress wattr* macros to help with ncurses5/ncurses6 transition],
 948         [with_wattr_macros=$enableval],
 949         [with_wattr_macros=yes])
 950 if [[ "x$with_wattr_macros" != xyes ]]; then
 951         NCURSES_WATTR_MACROS=0
 952         AC_MSG_RESULT(yes)
 953 else
 954         NCURSES_WATTR_MACROS=1
 955         AC_MSG_RESULT(no)
 956 fi
 957 AC_SUBST(NCURSES_WATTR_MACROS)
 958
 959 ###   use option --with-bool to override bool's type
 960 AC_MSG_CHECKING(for type of bool)
 961 AC_ARG_WITH(bool,
 962         [  --with-bool=TYPE        override fallback type of bool variable],
 963         [NCURSES_BOOL="$withval"],
 964         [NCURSES_BOOL=auto])
 965 AC_MSG_RESULT($NCURSES_BOOL)
 966 AC_SUBST(NCURSES_BOOL)
 967
 968 AC_MSG_CHECKING(for alternate terminal capabilities file)
 969 AC_ARG_WITH(caps,
 970         [  --with-caps=alt         compile with alternate Caps file],
 971         [TERMINFO_CAPS=Caps.$withval],
 972         [TERMINFO_CAPS=Caps])
 973 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 974 AC_MSG_RESULT($TERMINFO_CAPS)
 975 AC_SUBST(TERMINFO_CAPS)
 976
 977 ###   use option --with-chtype to override chtype's type
 978 AC_MSG_CHECKING(for type of chtype)
 979 AC_ARG_WITH(chtype,
 980         [  --with-chtype=TYPE      override type of chtype],
 981         [NCURSES_CHTYPE="$withval"],
 982         [NCURSES_CHTYPE=$cf_dft_chtype])
 983 AC_MSG_RESULT($NCURSES_CHTYPE)
 984
 985 ###   use option --with-ospeed to override ospeed's type
 986 AC_MSG_CHECKING(for type of ospeed)
 987 AC_ARG_WITH(ospeed,
 988         [  --with-ospeed=TYPE      override type of ospeed variable],
 989         [NCURSES_OSPEED="$withval"],
 990         [NCURSES_OSPEED=short])
 991 AC_MSG_RESULT($NCURSES_OSPEED)
 992 AC_SUBST(NCURSES_OSPEED)
 993
 994 ###   use option --with-mmask-t to override mmask_t's type
 995 AC_MSG_CHECKING(for type of mmask_t)
 996 AC_ARG_WITH(mmask-t,
 997         [  --with-mmask-t=TYPE     override type of mmask_t],
 998         [NCURSES_MMASK_T="$withval"],
 999         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1000 AC_MSG_RESULT($NCURSES_MMASK_T)
1001
1002 ###   use option --with-ccharw-max to override CCHARW_MAX size
1003 AC_MSG_CHECKING(for size CCHARW_MAX)
1004 AC_ARG_WITH(ccharw-max,
1005         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1006         [NCURSES_CCHARW_MAX="$withval"],
1007         [NCURSES_CCHARW_MAX=5])
1008 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1009 AC_SUBST(NCURSES_CCHARW_MAX)
1010
1011 ###   use option --with-tparm-arg to override tparm's argument type
1012 AC_MSG_CHECKING(for type of tparm args)
1013 AC_ARG_WITH(tparm-arg,
1014         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1015         [NCURSES_TPARM_ARG="$withval"],
1016         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1017 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1018 AC_SUBST(NCURSES_TPARM_ARG)
1019
1020 ### Enable compiling-in rcs id's
1021 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1022 AC_ARG_WITH(rcs-ids,
1023         [  --with-rcs-ids          compile-in RCS identifiers],
1024         [with_rcs_ids=$withval],
1025         [with_rcs_ids=no])
1026 AC_MSG_RESULT($with_rcs_ids)
1027 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1028
1029 ###############################################################################
1030 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1031
1032 ###############################################################################
1033 CF_HELP_MESSAGE(Extensions:)
1034
1035 ### Note that some functions (such as const) are normally disabled anyway.
1036 AC_MSG_CHECKING(if you want to build with function extensions)
1037 AC_ARG_ENABLE(ext-funcs,
1038         [  --disable-ext-funcs     disable function-extensions],
1039         [with_ext_funcs=$enableval],
1040         [with_ext_funcs=yes])
1041 AC_MSG_RESULT($with_ext_funcs)
1042 if test "x$with_ext_funcs" = xyes ; then
1043         NCURSES_EXT_FUNCS=1
1044         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1045         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1046         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1047         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1048         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1049         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1050         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1051         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1052         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1053         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1054         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1055         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1056         GENERATED_EXT_FUNCS=generated
1057         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1058 else
1059         NCURSES_EXT_FUNCS=0
1060         GENERATED_EXT_FUNCS=
1061 fi
1062 AC_SUBST(NCURSES_EXT_FUNCS)
1063 AC_SUBST(GENERATED_EXT_FUNCS)
1064
1065 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1066 AC_ARG_ENABLE(sp-funcs,
1067         [  --enable-sp-funcs       enable SCREEN-extensions],
1068         [with_sp_funcs=$enableval],
1069         [with_sp_funcs=$cf_dft_ext_spfuncs])
1070 AC_MSG_RESULT($with_sp_funcs)
1071 if test "x$with_sp_funcs" = xyes ; then
1072         NCURSES_SP_FUNCS=1
1073         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1074         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1075         GENERATED_SP_FUNCS=generated
1076 else
1077         NCURSES_SP_FUNCS=0
1078         GENERATED_SP_FUNCS=
1079 fi
1080 AC_SUBST(NCURSES_SP_FUNCS)
1081 AC_SUBST(GENERATED_SP_FUNCS)
1082
1083 AC_MSG_CHECKING(if you want to build with terminal-driver)
1084 AC_ARG_ENABLE(term-driver,
1085         [  --enable-term-driver    enable terminal-driver],
1086         [with_term_driver=$enableval],
1087         [with_term_driver=no])
1088 AC_MSG_RESULT($with_term_driver)
1089 if test "x$with_term_driver" = xyes ; then
1090         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1091         if test "x$with_termlib" != xno ; then
1092                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1093         fi
1094         if test "x$with_sp_funcs" != xyes ; then
1095                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1096         fi
1097 fi
1098
1099 ###   use option --enable-const to turn on use of const beyond that in XSI.
1100 AC_MSG_CHECKING(for extended use of const keyword)
1101 AC_ARG_ENABLE(const,
1102         [  --enable-const          compile with extra/non-standard const],
1103         [with_ext_const=$enableval],
1104         [with_ext_const=$cf_dft_ext_const])
1105 AC_MSG_RESULT($with_ext_const)
1106 NCURSES_CONST='/*nothing*/'
1107 if test "x$with_ext_const" = xyes ; then
1108         NCURSES_CONST=const
1109 fi
1110 AC_SUBST(NCURSES_CONST)
1111
1112 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1113 AC_MSG_CHECKING(if you want to use extended colors)
1114 AC_ARG_ENABLE(ext-colors,
1115         [  --enable-ext-colors     compile for 256-color support],
1116         [with_ext_colors=$enableval],
1117         [with_ext_colors=$cf_dft_ext_colors])
1118 AC_MSG_RESULT($with_ext_colors)
1119 NCURSES_EXT_COLORS=0
1120 if test "x$with_ext_colors" = xyes ; then
1121         if test "x$with_widec" != xyes ; then
1122                 AC_MSG_WARN(This option applies only to wide-character library)
1123         else
1124                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1125                 CF_NCURSES_ABI_6
1126                 NCURSES_EXT_COLORS=1
1127                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1128                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1129                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1130         fi
1131 fi
1132 AC_SUBST(NCURSES_EXT_COLORS)
1133
1134 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1135 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1136 AC_ARG_ENABLE(ext-mouse,
1137         [  --enable-ext-mouse      compile for extended mouse-encoding],
1138         [with_ext_mouse=$enableval],
1139         [with_ext_mouse=$cf_dft_ext_mouse])
1140 AC_MSG_RESULT($with_ext_mouse)
1141 NCURSES_MOUSE_VERSION=1
1142 if test "x$with_ext_mouse" = xyes ; then
1143         NCURSES_MOUSE_VERSION=2
1144         CF_NCURSES_ABI_6
1145 fi
1146 AC_SUBST(NCURSES_MOUSE_VERSION)
1147
1148 ###   use option --enable-ext-putwin to turn on extended screendumps
1149 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1150 AC_ARG_ENABLE(ext-putwin,
1151         [  --enable-ext-putwin     compile with extended putwin/screendump],
1152         [with_ext_putwin=$enableval],
1153         [with_ext_putwin=$cf_dft_ext_putwin])
1154 AC_MSG_RESULT($with_ext_putwin)
1155 if test "x$with_ext_putwin" = xyes ; then
1156         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1157 fi
1158
1159 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1160 AC_ARG_ENABLE(no-padding,
1161         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1162         [with_no_padding=$enableval],
1163         [with_no_padding=$with_ext_funcs])
1164 AC_MSG_RESULT($with_no_padding)
1165 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1166
1167 AC_CHECK_SIZEOF([signed char], 0)
1168 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1169         NCURSES_SBOOL="signed char"
1170 else
1171         NCURSES_SBOOL="char"
1172 fi
1173 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1174 AC_ARG_ENABLE(signed-char,
1175         [  --enable-signed-char    compile using signed Boolean's in term.h],
1176         [with_signed_char=$enableval],
1177         [with_signed_char=no])
1178 AC_MSG_RESULT($with_signed_char)
1179 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1180 AC_SUBST(NCURSES_SBOOL)
1181
1182 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1183 AC_MSG_CHECKING(if you want SIGWINCH handler)
1184 AC_ARG_ENABLE(sigwinch,
1185         [  --enable-sigwinch       compile with SIGWINCH handler],
1186         [with_sigwinch=$enableval],
1187         [with_sigwinch=$with_ext_funcs])
1188 AC_MSG_RESULT($with_sigwinch)
1189 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1190
1191 ###   use option --enable-tcap-names to allow user to define new capabilities
1192 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1193 AC_ARG_ENABLE(tcap-names,
1194         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1195         [with_tcap_names=$enableval],
1196         [with_tcap_names=$with_ext_funcs])
1197 AC_MSG_RESULT($with_tcap_names)
1198 NCURSES_XNAMES=0
1199 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1200 AC_SUBST(NCURSES_XNAMES)
1201
1202 ##############################################################################
1203 CF_WITH_PTHREAD
1204
1205 if test "x$with_pthread" != xno; then
1206         AC_CHECK_FUNC(pthread_kill,[
1207                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1208                 AC_ARG_ENABLE(pthreads-eintr,
1209                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1210                         [use_pthreads_eintr=$enableval],
1211                         [use_pthreads_eintr=no])
1212                 AC_MSG_RESULT($use_pthreads_eintr)
1213                 if test "x$use_pthreads_eintr" = xyes ; then
1214                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1215                 fi])
1216
1217         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1218         AC_ARG_ENABLE(weak-symbols,
1219                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1220                 [use_weak_symbols=$enableval],
1221                 [use_weak_symbols=no])
1222         AC_MSG_RESULT($use_weak_symbols)
1223         if test "x$use_weak_symbols" = xyes ; then
1224                 CF_WEAK_SYMBOLS
1225         else
1226                 cf_cv_weak_symbols=no
1227         fi
1228
1229         if test "x$cf_cv_weak_symbols" = xyes ; then
1230                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1231         fi
1232 fi
1233
1234 PTHREAD=
1235 if test "x$with_pthread" = "xyes" ; then
1236         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1237         enable_reentrant=yes
1238         if test "x$cf_cv_weak_symbols" = xyes ; then
1239                 PTHREAD=-lpthread
1240         fi
1241 fi
1242 AC_SUBST(PTHREAD)
1243
1244 # Reentrant code has to be opaque; there's little advantage to making ncurses
1245 # opaque outside of that, so there is no --enable-opaque option.  We can use
1246 # this option without --with-pthreads, but this will be always set for
1247 # pthreads.
1248 AC_MSG_CHECKING(if you want reentrant code)
1249 AC_ARG_ENABLE(reentrant,
1250         [  --enable-reentrant      compile with reentrant code],
1251         [with_reentrant=$enableval],
1252         [with_reentrant=no])
1253 AC_MSG_RESULT($with_reentrant)
1254 if test "x$with_reentrant" = xyes ; then
1255         cf_cv_enable_reentrant=1
1256         cf_cv_enable_opaque="NCURSES_INTERNALS"
1257         NCURSES_SIZE_T=int
1258         if test "x$cf_cv_weak_symbols" = xyes ; then
1259                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1260                 CF_ADD_LIB(pthread,TEST_LIBS)
1261                 CF_ADD_LIB(pthread,TEST_LIBS2)
1262         else
1263                 # when not using weak symbols but with_reentrant,
1264                 # add 't' to the library suffix on all platforms
1265                 # except cygwin, where we only do that if ALSO
1266                 # compiling with full thread support.
1267                 case "$host" in
1268                 (*cygwin* | *msys*)
1269                         if test "$with_pthread" = "yes" ; then
1270                                 if test "x$disable_lib_suffixes" = "xno" ; then
1271                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1272                                 fi
1273                         fi ;;
1274                 (*)
1275                         if test "x$disable_lib_suffixes" = "xno" ; then
1276                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1277                         fi
1278                         ;;
1279                 esac
1280         fi
1281         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1282         CF_NCURSES_ABI_6
1283 else
1284         cf_cv_enable_reentrant=0
1285         cf_cv_enable_opaque="NCURSES_OPAQUE"
1286         NCURSES_SIZE_T=short
1287 fi
1288 AC_SUBST(cf_cv_enable_reentrant)
1289 AC_SUBST(cf_cv_enable_opaque)
1290
1291 AC_SUBST(NCURSES_SIZE_T)
1292
1293 AC_MSG_CHECKING(if you want opaque curses-library structures)
1294 CF_ARG_ENABLE(opaque-curses,
1295         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1296         [enable_opaque_curses=yes],[
1297          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1298          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=no
1299         ])
1300 AC_MSG_RESULT($enable_opaque_curses)
1301
1302 test "$cf_cv_enable_reentrant" = 1 && \
1303 test "$enable_opaque_curses" = no && \
1304 AC_MSG_ERROR(reentrant configuration requires opaque library)
1305
1306 AC_MSG_CHECKING(if you want opaque form-library structures)
1307 AC_ARG_ENABLE(opaque-form,
1308         [  --enable-opaque-form    make form-library structures "opaque"],
1309         [enable_opaque_form=yes],[enable_opaque_form=no])
1310 AC_MSG_RESULT($enable_opaque_form)
1311
1312 AC_MSG_CHECKING(if you want opaque menu-library structures)
1313 AC_ARG_ENABLE(opaque-menu,
1314         [  --enable-opaque-menu    make menu-library structures "opaque"],
1315         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1316 AC_MSG_RESULT($enable_opaque_menu)
1317
1318 AC_MSG_CHECKING(if you want opaque panel-library structures)
1319 AC_ARG_ENABLE(opaque-panel,
1320         [  --enable-opaque-panel   make panel-library structures "opaque"],
1321         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1322 AC_MSG_RESULT($enable_opaque_panel)
1323
1324 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1325 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1326 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1327 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1328
1329 AC_SUBST(NCURSES_OPAQUE)
1330 AC_SUBST(NCURSES_OPAQUE_FORM)
1331 AC_SUBST(NCURSES_OPAQUE_MENU)
1332 AC_SUBST(NCURSES_OPAQUE_PANEL)
1333
1334 ### Allow using a different wrap-prefix
1335 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1336         AC_MSG_CHECKING(for prefix used to wrap public variables)
1337         AC_ARG_WITH(wrap-prefix,
1338                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1339                 [NCURSES_WRAP_PREFIX=$withval],
1340                 [NCURSES_WRAP_PREFIX=_nc_])
1341         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1342 else
1343         NCURSES_WRAP_PREFIX=_nc_
1344 fi
1345 AC_SUBST(NCURSES_WRAP_PREFIX)
1346 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1347
1348 ###############################################################################
1349 # These options are relatively safe to experiment with.
1350 CF_HELP_MESSAGE(Development Code:)
1351 AC_MSG_CHECKING(if you want all development code)
1352 AC_ARG_WITH(develop,
1353         [  --without-develop       disable development options],
1354         [with_develop=$withval],
1355         [with_develop=no])
1356 AC_MSG_RESULT($with_develop)
1357
1358 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1359 AC_MSG_CHECKING(if you want hard-tabs code)
1360 AC_ARG_ENABLE(hard-tabs,
1361         [  --enable-hard-tabs      compile with hard-tabs code],,
1362         [enable_hard_tabs=$with_develop])
1363 AC_MSG_RESULT($enable_hard_tabs)
1364 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1365
1366 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1367 AC_MSG_CHECKING(if you want limited support for xmc)
1368 AC_ARG_ENABLE(xmc-glitch,
1369         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1370         [enable_xmc_glitch=$with_develop])
1371 AC_MSG_RESULT($enable_xmc_glitch)
1372 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1373
1374 ###############################################################################
1375 # These are just experimental, probably should not be in a package:
1376 CF_HELP_MESSAGE(Experimental Code:)
1377
1378 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1379 AC_ARG_ENABLE(assumed-color,
1380         [  --disable-assumed-color do not assume anything about default-colors],
1381         [with_assumed_color=$enableval],
1382         [with_assumed_color=yes])
1383 AC_MSG_RESULT($with_assumed_color)
1384 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1385
1386 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1387 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1388 AC_ARG_ENABLE(hashmap,
1389         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1390         [with_hashmap=$enableval],
1391         [with_hashmap=yes])
1392 AC_MSG_RESULT($with_hashmap)
1393 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1394
1395 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1396 AC_MSG_CHECKING(if you want colorfgbg code)
1397 AC_ARG_ENABLE(colorfgbg,
1398         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1399         [with_colorfgbg=$enableval],
1400         [with_colorfgbg=no])
1401 AC_MSG_RESULT($with_colorfgbg)
1402 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1403
1404 ###   use option --enable-interop to turn on use of bindings used for interop
1405 AC_MSG_CHECKING(if you want interop bindings)
1406 AC_ARG_ENABLE(interop,
1407         [  --enable-interop        compile-in interop bindings],
1408         [with_exp_interop=$enableval],
1409         [with_exp_interop=$cf_dft_interop])
1410 AC_MSG_RESULT($with_exp_interop)
1411
1412 NCURSES_INTEROP_FUNCS=0
1413 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1414 AC_SUBST(NCURSES_INTEROP_FUNCS)
1415
1416
1417 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1418 AC_ARG_ENABLE(safe-sprintf,
1419         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1420         [with_safe_sprintf=$enableval],
1421         [with_safe_sprintf=no])
1422 AC_MSG_RESULT($with_safe_sprintf)
1423 test "x$with_safe_sprintf" = xyes && AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1424
1425 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1426 # when hashmap is used scroll hints are useless
1427 if test "$with_hashmap" = no ; then
1428 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1429 AC_ARG_ENABLE(scroll-hints,
1430         [  --disable-scroll-hints  compile without scroll-hints code],
1431         [with_scroll_hints=$enableval],
1432         [with_scroll_hints=yes])
1433 AC_MSG_RESULT($with_scroll_hints)
1434 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1435 fi
1436
1437 AC_MSG_CHECKING(if you want wgetch-events code)
1438 AC_ARG_ENABLE(wgetch-events,
1439         [  --enable-wgetch-events  compile with wgetch-events code],
1440         [with_wgetch_events=$enableval],
1441         [with_wgetch_events=no])
1442 AC_MSG_RESULT($with_wgetch_events)
1443 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1444
1445 ###############################################################################
1446 CF_HELP_MESSAGE(Testing/development Options:)
1447
1448 ###     use option --disable-echo to suppress full display compiling commands
1449 CF_DISABLE_ECHO
1450 if test "x$enable_echo" = xyes; then
1451         ECHO_LINK=
1452 else
1453         ECHO_LINK='@ echo linking $@ ... ;'
1454         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1455         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1456 fi
1457 AC_SUBST(ECHO_LINK)
1458
1459 ###     use option --enable-warnings to turn on all gcc warnings
1460 AC_MSG_CHECKING(if you want to see compiler warnings)
1461 AC_ARG_ENABLE(warnings,
1462         [  --enable-warnings       build: turn on GCC compiler warnings],
1463         [with_warnings=$enableval])
1464 AC_MSG_RESULT($with_warnings)
1465
1466 if test "x$with_warnings" = "xyes"; then
1467         CF_ADD_ADAFLAGS(-gnatg)
1468         CF_GCC_WARNINGS(Wno-unknown-pragmas Wswitch-enum)
1469         if test "x$cf_with_cxx" = xyes ; then
1470                 CF_GXX_WARNINGS(Wno-unused)
1471         fi
1472 fi
1473 CF_GCC_ATTRIBUTES
1474 CF_ENABLE_STRING_HACKS
1475
1476 ###     use option --enable-assertions to turn on generation of assertion code
1477 AC_MSG_CHECKING(if you want to enable runtime assertions)
1478 AC_ARG_ENABLE(assertions,
1479         [  --enable-assertions     test: turn on generation of assertion code],
1480         [with_assertions=$enableval],
1481         [with_assertions=no])
1482 AC_MSG_RESULT($with_assertions)
1483 if test -n "$GCC"
1484 then
1485         if test "$with_assertions" = no
1486         then
1487                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1488         else
1489                 CF_ADD_ADAFLAGS(-gnata)
1490         fi
1491 fi
1492
1493 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1494 CF_DISABLE_LEAKS
1495 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1496
1497 ###     use option --enable-expanded to generate certain macros as functions
1498 AC_ARG_ENABLE(expanded,
1499         [  --enable-expanded       test: generate functions for certain macros],
1500         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1501
1502 ###     use option --disable-macros to suppress macros in favor of functions
1503 AC_ARG_ENABLE(macros,
1504         [  --disable-macros        test: use functions rather than macros],
1505         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1506
1507 # Normally we only add trace() to the debug-library.  Allow this to be
1508 # extended to all models of the ncurses library:
1509 cf_all_traces=no
1510 case "$CFLAGS $CPPFLAGS" in
1511 (*-DTRACE*)
1512         cf_all_traces=yes
1513         ;;
1514 esac
1515
1516 AC_MSG_CHECKING(whether to add trace feature to all models)
1517 AC_ARG_WITH(trace,
1518 [  --with-trace            test: add trace() function to all models of ncurses],
1519 [cf_with_trace=$withval],
1520 [cf_with_trace=$cf_all_traces])
1521 AC_MSG_RESULT($cf_with_trace)
1522
1523 if test "x$cf_with_trace" = xyes ; then
1524         LIB_TRACING=all
1525         ADA_TRACE=TRUE
1526         CF_ADD_CFLAGS(-DTRACE)
1527         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1528 else
1529         LIB_TRACING=DEBUG
1530         ADA_TRACE=FALSE
1531 fi
1532
1533 AC_SUBST(ADA_TRACE)
1534
1535 CF_DISABLE_GNAT_PROJECTS
1536
1537 ###     Checks for libraries.
1538 case $cf_cv_system_name in
1539 (*mingw32*|*mingw64*)
1540         CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1541         LIBS=" -lpsapi $LIBS"
1542         ;;
1543 (*)
1544 AC_CHECK_FUNC(gettimeofday,
1545         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1546
1547 AC_CHECK_LIB(bsd, gettimeofday,
1548         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1549         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1550         ;;
1551 esac
1552
1553 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1554 AC_SUBST(MATH_LIB)
1555
1556 ###     Checks for header files.
1557 AC_STDC_HEADERS
1558 AC_HEADER_DIRENT
1559 AC_HEADER_TIME
1560 CF_REGEX
1561
1562 dnl These are some other potentially nonportable headers.
1563 AC_CHECK_HEADERS( \
1564 fcntl.h \
1565 getopt.h \
1566 limits.h \
1567 locale.h \
1568 math.h \
1569 poll.h \
1570 sys/bsdtypes.h \
1571 sys/ioctl.h \
1572 sys/param.h \
1573 sys/poll.h \
1574 sys/select.h \
1575 sys/time.h \
1576 sys/times.h \
1577 ttyent.h \
1578 unistd.h \
1579 wctype.h \
1580 )
1581
1582 CF_GETOPT_HEADER
1583
1584 # check for ISC (this may also define _POSIX_SOURCE)
1585 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1586 if test "x$ISC" = xyes ; then
1587         AC_CHECK_LIB(cposix,main)
1588         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1589 fi
1590
1591 CF_SYS_TIME_SELECT
1592
1593 ###     checks for compiler characteristics
1594 AC_LANG_C
1595 AC_C_CONST
1596 CF_C_INLINE(NCURSES_INLINE,1200)
1597 CF_SIG_ATOMIC_T
1598
1599 if test $NCURSES_CHTYPE = auto ; then
1600         CF_TYPEOF_CHTYPE
1601 else
1602         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1603 fi
1604 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1605 AC_SUBST(cf_cv_typeof_chtype)
1606
1607 CF_UNSIGNED_LITERALS
1608 cf_cv_1UL="1"
1609 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1610 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1611 AC_SUBST(cf_cv_1UL)
1612
1613 if test $NCURSES_MMASK_T = auto ; then
1614         cf_cv_typeof_mmask_t=long
1615 else
1616         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1617 fi
1618 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1619 AC_SUBST(cf_cv_typeof_mmask_t)
1620
1621 ###     Checks for external-data
1622 CF_ERRNO
1623 CF_LINK_DATAONLY
1624
1625 ###     Checks for library functions.
1626 AC_CHECK_FUNCS( \
1627 getcwd \
1628 getegid \
1629 geteuid \
1630 getopt \
1631 getttynam \
1632 issetugid \
1633 poll \
1634 putenv \
1635 remove \
1636 select \
1637 setbuf \
1638 setbuffer \
1639 setenv \
1640 setvbuf \
1641 sigaction \
1642 sigvec \
1643 strdup \
1644 strstr \
1645 tcgetpgrp \
1646 tdestroy \
1647 times \
1648 tsearch \
1649 vsnprintf \
1650 )
1651
1652 if test "x$ac_cv_func_getopt" = xno && \
1653    test "x$cf_with_progs$cf_with_tests" != xnono; then
1654         AC_MSG_ERROR(getopt is required for building programs)
1655 fi
1656
1657 if test "x$with_getcap" = "xyes" ; then
1658         CF_CGETENT
1659 fi
1660
1661 CF_ISASCII
1662 CF_STRUCT_SIGACTION
1663 CF_FUNC_NANOSLEEP
1664 CF_FUNC_TERMIOS
1665 CF_FUNC_VSSCANF
1666 CF_MKSTEMP
1667
1668 # setup for prototype of fallback for vsscanf()
1669 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1670
1671 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1672 if test "x$cross_compiling" = xyes ; then
1673         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1674 else
1675         AC_FUNC_SETVBUF_REVERSED
1676 fi
1677 AC_CHECK_TYPE(intptr_t, long)
1678 AC_CHECK_TYPE(ssize_t, int)
1679 CF_TYPE_SIGACTION
1680 CF_SIZECHANGE
1681 CF_FUNC_MEMMOVE
1682 CF_FUNC_POLL
1683 CF_VA_COPY
1684 AC_FUNC_VFORK
1685
1686 # special check for test/ditto.c
1687 CF_FUNC_OPENPTY
1688 if test "$cf_cv_func_openpty" != no ; then
1689         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1690         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1691         if test "x$cf_cv_lib_util" = xyes ; then
1692                 CF_ADD_LIB(util,TEST_LIBS)
1693         fi
1694 fi
1695 AC_SUBST(TEST_LIBS)
1696 AC_SUBST(TEST_LIBS2)
1697
1698 if test "$with_hashed_db" != no ; then
1699         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1700         CF_HASHED_DB($with_hashed_db)
1701 fi
1702
1703 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1704 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1705         CF_STRIP_G_OPT(CFLAGS)
1706         CF_STRIP_G_OPT(CXXFLAGS)
1707 fi
1708
1709 # Just in case, check if the C compiler has a bool type.
1710 CF_BOOL_DECL(cf_cv_cc_bool_type)
1711
1712 # Check for C++ compiler characteristics (and ensure that it's there!)
1713 if test -n "$CXX" ; then
1714         AC_LANG_CPLUSPLUS
1715         CF_STDCPP_LIBRARY
1716         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1717
1718         case $GXX_VERSION in
1719         (1*|2.[0-6]*)
1720                 cf_cxx_library=yes
1721                 ;;
1722         (*-2.7*|2.7*)
1723                 CF_GPP_LIBRARY
1724                 ;;
1725         (*)
1726                 cf_cxx_library=no
1727                 ;;
1728         esac
1729
1730         AC_CHECK_HEADERS(typeinfo)
1731         CF_CXX_IOSTREAM_NAMESPACE
1732         CF_BOOL_DECL
1733         CF_BOOL_SIZE
1734         CF_ETIP_DEFINES
1735         CF_CPP_PARAM_INIT
1736         CF_CPP_STATIC_CAST
1737         CF_CXX_AR_FLAGS
1738 else
1739         cf_cxx_library=no
1740         cf_cv_builtin_bool=1
1741
1742         # Just because we are not configuring against C++ right now does not
1743         # mean that a user will not want to use C++.  Some distributors disable
1744         # the C++ portion of this configuration as a shortcut (or just to avoid
1745         # compiling the demo in the c++ directory).  So we need a reasonable
1746         # default for the 'bool' type.
1747         #
1748         # Caveat: since the storage of the bool type is not standardized, it
1749         # may change.
1750
1751         if test "$NCURSES_BOOL" != auto ; then
1752                 cf_cv_type_of_bool=$NCURSES_BOOL
1753                 cf_cv_header_stdbool_h=0
1754         else
1755                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1756                         CF_BOOL_SIZE
1757                 else
1758                         AC_MSG_CHECKING(for fallback type of bool)
1759                         case "$host_cpu" in
1760                         (i?86)  cf_cv_type_of_bool=char ;;
1761                         (*)     cf_cv_type_of_bool=int  ;;
1762                         esac
1763                         AC_MSG_RESULT($cf_cv_type_of_bool)
1764                 fi
1765         fi
1766 fi
1767 AC_SUBST(CXXLIBS)
1768
1769 # If the C compiler did not declare bool, and we did not determine that the C++
1770 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1771 # ncurses library use the same type as C++ bool.  Note that this allows one to
1772 # specify the type of bool in a configure-script option and postpone
1773 # integration with the C++ compiler provided that the types are compatible.
1774 USE_CXX_BOOL=1
1775 if test $cf_cv_cc_bool_type = 1
1776 then
1777         # oops: C has a bool.  Unlikely, but C++ could differ.
1778         USE_CXX_BOOL=0
1779 elif test $cf_cv_builtin_bool = 0
1780 then
1781         # C++ has no bool
1782         USE_CXX_BOOL=0
1783 else
1784         # this is the normal case
1785         USE_CXX_BOOL='defined(__cplusplus)'
1786 fi
1787 AC_SUBST(USE_CXX_BOOL)
1788
1789 CF_HELP_MESSAGE(Ada95 Binding Options:)
1790
1791 dnl If the Ada95 source-tree is present, add that to the build unless it will
1792 dnl not work, or was not requested.
1793 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1794
1795 dnl libtool does not know anything about GNAT, though a change made in 1998
1796 dnl provided for it "someday".  Disable the ada subtree if we are using
1797 dnl libtool -TD 20070714
1798         if test "$cf_with_ada" != "no" ; then
1799                 if test "$with_libtool" != "no"; then
1800                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1801                         cf_with_ada=no
1802                 fi
1803         fi
1804
1805 dnl Check for availability of GNU Ada Translator (GNAT).
1806 dnl At the moment we support no other Ada95 compiler.
1807         if test "$cf_with_ada" != "no" ; then
1808                 CF_PROG_GNAT
1809                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1810                         CF_ADD_ADAFLAGS(-gnatpn)
1811                         CF_FIXUP_ADAFLAGS
1812
1813                         CF_GNATPREP_OPT_T
1814
1815                         CF_GNAT_GENERICS
1816                         CF_GNAT_SIGINT
1817                         CF_GNAT_PROJECTS
1818
1819                         CF_WITH_ADA_COMPILER
1820
1821                         cf_ada_package=terminal_interface
1822                         AC_SUBST(cf_ada_package)
1823
1824                         CF_WITH_ADA_INCLUDE
1825                         CF_WITH_ADA_OBJECTS
1826                         CF_WITH_ADA_SHAREDLIB
1827                 fi
1828         fi
1829 else
1830         cf_with_ada=no
1831 fi
1832
1833 # do this "late" to avoid conflict with header-checks
1834 if test "x$with_widec" = xyes ; then
1835         AC_CHECK_SIZEOF(wchar_t)
1836 fi
1837
1838 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1839 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1840 ###
1841 ### ticlib modules may be a separate library, otherwise contained in termlib.
1842 ### termlib modules may be a separate library, otherwise contained in ncurses.
1843 ###
1844 ### The of "+" or " " between the tokens controls the way the script
1845 ### chooses to split module lists into libraries.
1846 ###
1847 ### (see CF_LIB_RULES).
1848 AC_MSG_CHECKING(for library subsets)
1849 LIB_SUBSETS=
1850
1851 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1852         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1853         if test "$with_ticlib" != no ; then
1854                 LIB_SUBSETS="${LIB_SUBSETS} "
1855         else
1856                 LIB_SUBSETS="${LIB_SUBSETS}+"
1857         fi
1858 fi
1859
1860 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1861 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1862
1863 if test "$with_termlib" != no ; then
1864         LIB_SUBSETS="${LIB_SUBSETS} "
1865 else
1866         LIB_SUBSETS="${LIB_SUBSETS}+"
1867 fi
1868
1869 LIB_SUBSETS="${LIB_SUBSETS}base"
1870
1871 # Most term-driver calls are to tinfo, but some like init_pair are to the
1872 # base library (so it resides in base).
1873 if test "$with_term_driver" != no ; then
1874         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1875         case $cf_cv_system_name in
1876         (*mingw32*|*mingw64*)
1877                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1878                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
1879                 ;;
1880         (*)
1881                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1882                 ;;
1883         esac
1884 fi
1885
1886 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1887 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1888
1889 AC_MSG_RESULT($LIB_SUBSETS)
1890
1891 ### Construct the list of include-directories to be generated
1892 CF_INCLUDE_DIRS
1893 CF_ADA_INCLUDE_DIRS
1894
1895 ### Build up pieces for makefile rules
1896 AC_MSG_CHECKING(default library suffix)
1897 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1898 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1899 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1900
1901 AC_MSG_CHECKING(default library-dependency suffix)
1902 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1903 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1904 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1905
1906 AC_MSG_CHECKING(default object directory)
1907 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1908 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1909 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1910
1911 if test "x$cf_with_cxx" = xyes ; then
1912 AC_MSG_CHECKING(c++ library-dependency suffix)
1913 if test "$with_libtool" != "no"; then
1914         # libtool thinks it can make c++ shared libraries (perhaps only g++)
1915         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1916 elif test "$with_shared_cxx" != "no"; then
1917         # also for g++ users...
1918         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1919 else
1920         # we normally make a static library because C/C++ library rules differ
1921         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
1922 fi
1923 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1924 AC_SUBST(CXX_LIB_SUFFIX)
1925 fi
1926
1927 # do not want -ldl in build except as needed for -lncurses dependency
1928 if test "x$with_dlsym" = xyes ; then
1929 if test $DFT_LWR_MODEL = shared || \
1930    test $DFT_LWR_MODEL = libtool ; then
1931         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1932 fi
1933 fi
1934 ### Set up low-level terminfo dependencies for makefiles.
1935
1936 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1937 # do not need libdl
1938 TICS_LIST=
1939 if test "x$with_dlsym" = xyes ; then
1940         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1941 fi
1942
1943 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
1944 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
1945 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
1946 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
1947 then
1948         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
1949 fi
1950 AC_SUBST(USE_ARG_SUFFIX)
1951 AC_SUBST(USE_CFG_SUFFIX)
1952 AC_SUBST(USE_LIB_SUFFIX)
1953
1954 if test "$with_ticlib" != no ; then
1955
1956         if test "x$with_ticlib" != xyes ; then
1957                 TICS_NAME=$with_ticlib
1958                 TICS_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
1959                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1960                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1961                 TICS_LIB_SUFFIX="${with_ticlib}"
1962         else
1963                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
1964                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
1965                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1966                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
1967         fi
1968         TICS_LDFLAGS="-L${LIB_DIR}"
1969         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
1970 else
1971         TICS_SUFFIX=${DFT_LIB_SUFFIX}
1972         TICS_LDFLAGS="-L${LIB_DIR}"
1973         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
1974 fi
1975 AC_SUBST(TICS_ARG_SUFFIX)
1976 AC_SUBST(TICS_DEP_SUFFIX)
1977 AC_SUBST(TICS_LIB_SUFFIX)
1978 AC_SUBST(TICS_LDFLAGS)
1979 AC_SUBST(TICS_LIBS)
1980
1981 if test "$with_termlib" != no ; then
1982
1983         if test "x$with_termlib" != xyes ; then
1984                 TINFO_NAME=$with_termlib
1985                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
1986                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1987                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1988                 TINFO_LIB_SUFFIX="${with_termlib}"
1989         else
1990                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1991                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
1992                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1993                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
1994         fi
1995
1996         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1997         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1998         if test "$DFT_LWR_MODEL" = "libtool"; then
1999                 TEST_ARGS="${TEST_DEPS}"
2000                 TEST_ARG2="${TEST_DEP2}"
2001                 TINFO_LDFLAGS="-L${LIB_DIR}"
2002                 TINFO_LIBS="$TEST_ARGS"
2003                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2004                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2005         else
2006                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2007                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2008                 if test "x$with_term_driver" != xno ; then
2009                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2010                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2011                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2012                 else
2013                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2014                         TINFO_LIBS="$TEST_ARGS"
2015                 fi
2016                 TINFO_LDFLAGS="-L${LIB_DIR}"
2017                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2018         fi
2019 else
2020         # the next lines are needed for linking libtic over libncurses
2021         TINFO_NAME=${LIB_NAME}
2022         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2023         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2024         if test "x$with_tic_depends" = xyes ; then
2025                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2026         else
2027                 TICS_LIST="$SHLIB_LIST"
2028         fi
2029
2030         TINFO_LDFLAGS="-L${LIB_DIR}"
2031         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2032 fi
2033
2034 if test "$DFT_LWR_MODEL" = shared ; then
2035         case $cf_cv_system_name in
2036         (cygwin*|msys*)
2037                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2038                 TINFO_SUFFIX=.dll
2039                 ;;
2040         esac
2041 fi
2042
2043 AC_SUBST(TINFO_ARG_SUFFIX)
2044 AC_SUBST(TINFO_DEP_SUFFIX)
2045 AC_SUBST(TINFO_LIB_SUFFIX)
2046 AC_SUBST(TINFO_LDFLAGS)
2047 AC_SUBST(TINFO_LIBS)
2048
2049 if test "x$with_dlsym" = xyes ; then
2050         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2051 fi
2052
2053 if test "$DFT_LWR_MODEL" = "libtool"; then
2054         OBJEXT=lo
2055 fi
2056
2057 # needed for Ada95
2058 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2059 AC_SUBST(TINFO_LDFLAGS2)
2060
2061 case $DFT_LWR_MODEL in
2062 (normal|debug|profile)
2063         CF_LDFLAGS_STATIC
2064         ;;
2065 esac
2066
2067 AC_MSG_CHECKING(where we will install curses.h)
2068 AC_SUBST(includesubdir)
2069 includesubdir=
2070 if test "$with_overwrite" = no && \
2071  ( test "x$includedir" = 'x${prefix}/include' || \
2072    test "x$includedir" = "x${prefix}/include" )
2073 then
2074         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2075 fi
2076 AC_MSG_RESULT(${includedir}${includesubdir})
2077
2078 ### Resolve a conflict between normal and wide-curses by forcing applications
2079 ### that will need libutf8 to add it to their configure script.
2080 if test "$with_overwrite" != no ; then
2081 if test "$NCURSES_LIBUTF8" = 1 ; then
2082         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2083         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2084 fi
2085 fi
2086 WITH_OVERWRITE=$with_overwrite
2087
2088 AC_SUBST(WITH_OVERWRITE)
2089 AC_SUBST(TICS_LIST)
2090 AC_SUBST(TINFO_LIST)
2091 AC_SUBST(SHLIB_LIST)
2092
2093 # used to separate tack out of the tree
2094 NCURSES_TREE=
2095 AC_SUBST(NCURSES_TREE)
2096
2097 ### predefined stuff for the test programs
2098 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2099
2100 ### Construct the list of subdirectories for which we'll customize makefiles
2101 ### with the appropriate compile-rules.
2102
2103 CF_SRC_MODULES($modules_to_build)
2104
2105 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2106    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2107    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2108 fi
2109
2110 CF_DIRS_TO_MAKE
2111
2112 # symbols that differ when compiling Ada95 by itself.
2113 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2114 AC_SUBST(NCURSES_SHLIB2)
2115
2116 # values to use as strings
2117 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2118
2119 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2120
2121 ### Now that we're done running tests, add the compiler-warnings, if any
2122 CF_ADD_CFLAGS($EXTRA_CFLAGS)
2123
2124 ### Define substitutions for header files to avoid name-pollution
2125 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2126 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2127 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2128 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2129
2130 ################################################################################
2131 test "x$use_database" = xyes && \
2132 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2133
2134 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2135 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2136
2137 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2138 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2139 fi
2140 AC_SUBST(cross_compiling)
2141
2142 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
2143 if test -n "$FALLBACK_LIST"
2144 then
2145         if test "$TIC_PATH" = unknown
2146         then
2147                 AC_MSG_WARN(no tic program found for fallbacks)
2148         fi
2149 fi
2150 AC_SUBST(TIC_PATH)
2151
2152 if test "x$cf_with_tests" != xno ; then
2153         MAKE_TESTS=
2154 else
2155         MAKE_TESTS="#"
2156 fi
2157 AC_SUBST(MAKE_TESTS)
2158
2159 ADAHTML_DIR=../../doc/html/ada
2160 AC_SUBST(ADAHTML_DIR)
2161
2162 # these could be configurable, but are not currently
2163 PANEL_NAME=panel
2164 MENU_NAME=menu
2165 FORM_NAME=form
2166 CXX_NAME=ncurses++
2167
2168 AC_SUBST(PANEL_NAME)
2169 AC_SUBST(MENU_NAME)
2170 AC_SUBST(FORM_NAME)
2171 AC_SUBST(CXX_NAME)
2172
2173 # workaround for OS/2 (20151017)
2174 case $cf_cv_system_name in
2175 (os2*)
2176         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2177         ;;
2178 (*)
2179         LIBTOOL_OPTS_CXX=
2180         ;;
2181 esac
2182 AC_SUBST(LIBTOOL_OPTS_CXX)
2183
2184 # workaround for g++ versus Solaris (20131116)
2185 case $cf_cv_system_name in
2186 (solaris2*)
2187         case "x$CPPFLAGS" in
2188         (*-D_XOPEN_SOURCE_EXTENDED*)
2189                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2190                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2191                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2192                 ;;
2193         esac
2194         ;;
2195 esac
2196
2197 # Help to automatically enable the extended curses features when using either
2198 # the *-config or the ".pc" files by adding defines.
2199 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2200 PKG_CFLAGS=
2201 for cf_loop1 in $CPPFLAGS_after_XOPEN
2202 do
2203         cf_found=no
2204         for cf_loop2 in $CPPFLAGS_before_XOPEN
2205         do
2206                 if test "x$cf_loop1" = "x$cf_loop2"
2207                 then
2208                         cf_found=yes
2209                         break
2210                 fi
2211         done
2212         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2213 done
2214 AC_MSG_RESULT($PKG_CFLAGS)
2215 AC_SUBST(PKG_CFLAGS)
2216
2217 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2218 case "x$NCURSES_OSPEED" in
2219 (*short*)
2220         cf_compatible=1
2221         ;;
2222 (*)
2223         cf_compatible=0
2224         ;;
2225 esac
2226 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2227
2228 case "x$cf_cv_typeof_chtype" in
2229 (xshort|xint|xlong)
2230         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2231         ;;
2232 esac
2233
2234 case "x$cf_cv_typeof_mmask_t" in
2235 (xshort|xint|xlong)
2236         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2237         ;;
2238 esac
2239
2240 # substitute into misc/Makefile to suppress
2241 # (un)install.data from the
2242 # (un)install rules.
2243 if test "x$cf_with_db_install" = "xno"; then
2244         MISC_INSTALL_DATA=
2245         MISC_UNINSTALL_DATA=
2246 else
2247         MISC_INSTALL_DATA=install.data
2248         MISC_UNINSTALL_DATA=uninstall.data
2249 fi
2250 AC_SUBST(MISC_INSTALL_DATA)
2251 AC_SUBST(MISC_UNINSTALL_DATA)
2252
2253 SUB_SCRIPTS=
2254
2255 dnl Override the package used for exported symbols
2256 if test -n "$PACKAGE"
2257 then
2258         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2259         export PACKAGE
2260         echo "package: $PACKAGE"
2261 fi
2262
2263 UNALTERED_SYMS=
2264 cf_filter_syms=no
2265
2266 if test -n "$RESULTING_SYMS"
2267 then
2268         cf_filter_syms=$cf_dft_filter_syms
2269         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2270 fi
2271
2272 if test "x$WILDCARD_SYMS" = xno
2273 then
2274         cf_filter_syms=yes
2275 fi
2276
2277 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2278
2279 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2280 if test $cf_filter_syms = yes
2281 then
2282         RESULTING_SYMS=resulting.map
2283 fi
2284 AC_SUBST(UNALTERED_SYMS)
2285
2286 if test "x$cross_compiling" = xyes ; then
2287         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2288         CHECK_BUILD="#"
2289 else
2290         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2291         CHECK_BUILD=
2292 fi
2293 AC_SUBST(ADAGEN_LDFLAGS)
2294 AC_SUBST(CHECK_BUILD)
2295
2296 AC_DEFINE(HAVE_CURSES_DATA_BOOLNAMES,1,[definition needed for in-tree build of tack])
2297
2298 AC_OUTPUT( \
2299         include/MKterm.h.awk \
2300         include/curses.head:include/curses.h.in \
2301         include/ncurses_dll.h \
2302         include/termcap.h \
2303         include/unctrl.h \
2304         $SUB_SCRIPTS \
2305         $SUB_MAKEFILES \
2306         Makefile,[
2307 if test "x$cf_with_tests" != xno ; then
2308         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2309 fi
2310 CF_LIB_RULES($SRC_SUBDIRS)
2311
2312 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2313 if test -z "$USE_OLD_MAKERULES" ; then
2314         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
2315 fi
2316 fi
2317 ],[
2318 ### Special initialization commands, used to pass information from the
2319 ### configuration-run into config.status
2320
2321 AWK="$AWK"
2322 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2323 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2324 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2325 ECHO_LD="$ECHO_LD"
2326 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2327 LDCONFIG="$LDCONFIG"
2328 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2329 LIB_NAME="$LIB_NAME"
2330 LIB_PREFIX="$LIB_PREFIX"
2331 LIB_SUBSETS="$LIB_SUBSETS"
2332 LIB_SUFFIX="$LIB_SUFFIX"
2333 LIB_TRACING="$LIB_TRACING"
2334 LN_S="$LN_S"
2335 MAKE_TERMINFO="$MAKE_TERMINFO"
2336 NCURSES_MAJOR="$NCURSES_MAJOR"
2337 NCURSES_MINOR="$NCURSES_MINOR"
2338 NCURSES_OSPEED="$NCURSES_OSPEED"
2339 NCURSES_PATCH="$NCURSES_PATCH"
2340 SRC_SUBDIRS="$SRC_SUBDIRS"
2341 TERMINFO="$TERMINFO"
2342 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2343 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2344 TICS_NAME="$TICS_NAME"
2345 TICS_SUFFIX="$TICS_SUFFIX"
2346 TIC_PATH="$TIC_PATH"
2347 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2348 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2349 TINFO_NAME="$TINFO_NAME"
2350 TINFO_SUFFIX="$TINFO_SUFFIX"
2351 UNALTERED_SYMS="$UNALTERED_SYMS"
2352 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2353 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2354 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2355 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2356 WILDCARD_SYMS="$WILDCARD_SYMS"
2357 WITH_CURSES_H="$with_curses_h"
2358 WITH_ECHO="${enable_echo:=yes}"
2359 WITH_OVERWRITE="$with_overwrite"
2360 cf_LIST_MODELS="$cf_list_models"
2361 cf_cv_abi_version="$cf_cv_abi_version"
2362 cf_cv_do_relink="$cf_cv_do_relink"
2363 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2364 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2365 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2366 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2367 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2368 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2369 cf_cv_rel_version="$cf_cv_rel_version"
2370 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2371 cf_cv_shared_soname='$cf_cv_shared_soname'
2372 cf_cv_shlib_version="$cf_cv_shlib_version"
2373 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2374 cf_cv_system_name="$cf_cv_system_name"
2375 cf_cv_term_driver="$with_term_driver"
2376 cf_with_ada="$cf_with_ada"
2377 cf_with_cxx_binding="$cf_with_cxx_binding"
2378 cf_with_db_install="$cf_with_db_install"
2379 cf_with_manpages="$cf_with_manpages"
2380 cf_with_tests="$cf_with_tests"
2381 host="$host"
2382 target="$target"
2383 with_shared_cxx="$with_shared_cxx"
2384
2385 ],cat)dnl
2386 ${MAKE:-make} preinstall