ncurses 5.6 - patch 20080816
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2007,2008 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.439 2008/08/17 01:26:58 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See http://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.13.20020210)
38 AC_REVISION($Revision: 1.439 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44
45 CF_WITH_REL_VERSION(NCURSES)
46 CF_WITH_ABI_VERSION
47
48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
49 AC_ARG_WITH(system-type,
50 [  --with-system-type=XXX  test: override derived host system-type],
51 [AC_MSG_WARN(overriding system type to $withval)
52  cf_cv_system_name=$withval])
53
54 ###     Save the given $CFLAGS to allow user-override.
55 cf_user_CFLAGS="$CFLAGS"
56
57 ###     Default install-location
58 CF_CFG_DEFAULTS
59
60 ###     Checks for programs.
61 AC_PROG_CC
62 CF_GCC_VERSION
63
64 AC_PROG_CPP
65 AC_PROG_GCC_TRADITIONAL
66 CF_PROG_CC_C_O(CC)
67 AC_ISC_POSIX
68 CF_ANSI_CC_REQD
69 CF_PROG_EXT
70 CF_PROG_LDCONFIG
71
72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
73 dnl                             configure script by not letting us test if C++
74 dnl                             is present, making this option necessary.
75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
76 AC_ARG_WITH(cxx,
77         [  --without-cxx           do not adjust ncurses bool to match C++],
78         [cf_with_cxx=$withval],
79         [cf_with_cxx=yes])
80 AC_MSG_RESULT($cf_with_cxx)
81 if test "X$cf_with_cxx" = Xno ; then
82         CXX=""
83         GXX=""
84 else
85         # with autoconf 2.13, we can change the error to a warning:
86         pushdef([AC_MSG_ERROR],
87                 [AC_MSG_RESULT(no)
88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
90         AC_PROG_CXX
91         popdef([AC_MSG_ERROR])dnl
92         # autoconf 2.5x removed the error - by hardcoding it to g++.
93         if test "$CXX" = "g++" ; then
94                 AC_PATH_PROG(CXX,g++)
95         fi
96         if test "$CXX" = "g++" ; then
97                 AC_MSG_WARN(ignoring hardcoded g++)
98                 cf_with_cxx=no; CXX=""; GXX="";
99         fi
100 fi
101
102 CF_GXX_VERSION
103 case $GXX_VERSION in
104 1*|2.[[0-6]]*)
105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
106         # cf_cxx_library=no
107         AC_MSG_WARN(templates do not work)
108         ;;
109 esac
110
111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
112 AC_ARG_WITH(cxx-binding,
113         [  --without-cxx-binding   do not build C++ binding and demo],
114         [cf_with_cxx_binding=$withval],
115         [cf_with_cxx_binding=$cf_with_cxx])
116 AC_MSG_RESULT($cf_with_cxx_binding)
117
118 AC_MSG_CHECKING(if you want to build with Ada95)
119 AC_ARG_WITH(ada,
120         [  --without-ada           suppress check for Ada95, don't build demo],
121         [cf_with_ada=$withval],
122         [cf_with_ada=yes])
123 AC_MSG_RESULT($cf_with_ada)
124
125 AC_MSG_CHECKING(if you want to build programs such as tic)
126 AC_ARG_WITH(progs,
127         [  --without-progs         suppress build with programs (e.g., tic)],
128         [cf_with_progs=$withval],
129         [cf_with_progs=yes])
130 AC_MSG_RESULT($cf_with_progs)
131
132 AC_MSG_CHECKING(if you wish to install curses.h)
133 AC_ARG_WITH(curses-h,
134         [  --without-curses-h      install curses.h as ncurses.h only],
135         [with_curses_h=$withval],
136         [with_curses_h=yes])
137 AC_MSG_RESULT($with_curses_h)
138
139 modules_to_build="ncurses"
140 if test "X$cf_with_progs" != Xno ; then
141 modules_to_build="$modules_to_build progs tack"
142 fi
143 modules_to_build="$modules_to_build panel menu form"
144
145 AC_ARG_PROGRAM
146
147 CF_PROG_AWK
148 CF_PROG_EGREP
149 CF_PROG_INSTALL
150 CF_PROG_LINT
151 AC_PROG_LN_S
152
153 AC_SYS_LONG_FILE_NAMES
154
155 AC_MSG_CHECKING(if we should assume mixed-case filenames)
156 AC_ARG_ENABLE(mixed-case,
157         [  --enable-mixed-case     tic should assume mixed-case filenames],
158         [enable_mixedcase=$enableval],
159         [enable_mixedcase=auto])
160 AC_MSG_RESULT($enable_mixedcase)
161 if test "$enable_mixedcase" = "auto" ; then
162     CF_MIXEDCASE_FILENAMES
163 else
164     cf_cv_mixedcase=$enable_mixedcase
165     if test "$enable_mixedcase" = "yes" ; then
166         AC_DEFINE(MIXEDCASE_FILENAMES)
167     fi
168 fi
169
170 # do this after mixed-case option (tags/TAGS is not as important as tic).
171 AC_PROG_MAKE_SET
172 CF_MAKE_TAGS
173 CF_MAKEFLAGS
174
175 dnl These are standard among *NIX systems, but not when cross-compiling
176 AC_CHECK_TOOL(RANLIB, ranlib, ':')
177 AC_CHECK_TOOL(LD, ld, ld)
178 AC_CHECK_TOOL(AR, ar, ar)
179 CF_SUBST(archiver options,AR_OPTS,rv)
180
181 dnl Special option for use by system-builders: the install-prefix is used to
182 dnl adjust the location into which the actual install is done, so that an
183 dnl archive can be built without modifying the host system's configuration.
184 AC_MSG_CHECKING(if you have specified an install-prefix)
185 AC_ARG_WITH(install-prefix,
186         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
187         [case "$withval" in #(vi
188         yes|no) #(vi
189                 ;;
190         *)      DESTDIR="$withval"
191                 ;;
192         esac])
193 AC_MSG_RESULT($DESTDIR)
194 AC_SUBST(DESTDIR)
195
196 ###############################################################################
197 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
198 # If we're cross-compiling, allow the user to override the tools and their
199 # options.  The configure script is oriented toward identifying the host
200 # compiler, etc., but we need a build compiler to generate parts of the source.
201 CF_BUILD_CC
202
203 ###############################################################################
204 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
205
206 ### Options to allow the user to specify the set of libraries which are used.
207 ### Use "--without-normal --with-shared" to allow the default model to be
208 ### shared, for example.
209 cf_list_models=""
210 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
211
212 CF_WITH_LIBTOOL
213 if test "$with_libtool" != "no" ; then
214
215 cf_list_models="$cf_list_models libtool"
216
217 else
218
219 AC_MSG_CHECKING(if you want to build shared libraries)
220 AC_ARG_WITH(shared,
221         [  --with-shared           generate shared-libraries],
222         [with_shared=$withval],
223         [with_shared=no])
224 AC_MSG_RESULT($with_shared)
225 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
226
227 AC_MSG_CHECKING(if you want to build static libraries)
228 AC_ARG_WITH(normal,
229         [  --with-normal           generate normal-libraries (default)],
230         [with_normal=$withval],
231         [with_normal=yes])
232 AC_MSG_RESULT($with_normal)
233 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
234
235 AC_MSG_CHECKING(if you want to build debug libraries)
236 AC_ARG_WITH(debug,
237         [  --with-debug            generate debug-libraries (default)],
238         [with_debug=$withval],
239         [with_debug=yes])
240 AC_MSG_RESULT($with_debug)
241 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
242
243 AC_MSG_CHECKING(if you want to build profiling libraries)
244 AC_ARG_WITH(profile,
245         [  --with-profile          generate profile-libraries],
246         [with_profile=$withval],
247         [with_profile=no])
248 AC_MSG_RESULT($with_profile)
249 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
250
251 fi
252
253 ###############################################################################
254
255 AC_MSG_CHECKING(for specified models)
256 test -z "$cf_list_models" && cf_list_models=normal
257 dnl If we use libtool to generate libraries, then it must be the only
258 dnl specified model.
259 test "$with_libtool" != "no" && cf_list_models=libtool
260 AC_MSG_RESULT($cf_list_models)
261
262 ### Use the first model as the default, and save its suffix for use in building
263 ### up test-applications.
264 AC_MSG_CHECKING(for default model)
265 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
266 AC_MSG_RESULT($DFT_LWR_MODEL)
267
268 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
269
270 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
271 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
272
273 TICS_NAME=tic
274 AC_SUBST(TICS_NAME)
275
276 TINFO_NAME=tinfo
277 AC_SUBST(TINFO_NAME)
278
279 LIB_NAME=ncurses
280 AC_SUBST(LIB_NAME)
281
282 LIB_DIR=../lib
283 LIB_2ND=../../lib
284
285 CF_LIB_PREFIX(cf_prefix)
286 LIB_PREFIX=$cf_prefix
287 AC_SUBST(LIB_PREFIX)
288
289 LIB_SUFFIX=
290 AC_SUBST(LIB_SUFFIX)
291
292 ###############################################################################
293
294 AC_MSG_CHECKING(if you want to build a separate terminfo library)
295 AC_ARG_WITH(termlib,
296         [  --with-termlib          generate separate terminfo library],
297         [with_termlib=$withval],
298         [with_termlib=no])
299 AC_MSG_RESULT($with_termlib)
300
301 AC_MSG_CHECKING(if you want to build a separate tic library)
302 AC_ARG_WITH(ticlib,
303         [  --with-ticlib           generate separate tic library],
304         [with_ticlib=$withval],
305         [with_ticlib=no])
306 AC_MSG_RESULT($with_ticlib)
307
308 ### Checks for special libraries, must be done up-front.
309 SHLIB_LIST=""
310 CF_WITH_GPM
311 if test "$with_gpm" != no ; then
312         AC_MSG_CHECKING(if you want to load GPM dynamically)
313         AC_ARG_WITH(dlsym,
314                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
315                 [with_dlsym=$withval],
316                 [with_dlsym=yes])
317         AC_MSG_RESULT($with_dlsym)
318         if test "$with_dlsym" = yes ; then
319                 CF_FUNC_DLSYM
320                 if test "$with_gpm" != yes ; then
321                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
322                         cf_cv_gpm_soname="$with_gpm"
323                 else
324                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
325                 fi
326                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
327                 SHLIB_LIST="-ldl $SHLIB_LIST"
328         else
329                 SHLIB_LIST="-lgpm $SHLIB_LIST"
330         fi
331         AC_DEFINE(HAVE_LIBGPM)
332         CF_CHECK_GPM_WGETCH
333 fi
334
335 CF_WITH_SYSMOUSE
336
337 dnl Not all ports of gcc support the -g option
338
339 if test X"$CC_G_OPT" = X"" ; then
340         CC_G_OPT='-g'
341         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
342 fi
343 AC_SUBST(CC_G_OPT)
344
345 if test X"$CXX_G_OPT" = X"" ; then
346         CXX_G_OPT='-g'
347         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
348 fi
349 AC_SUBST(CXX_G_OPT)
350
351 AC_MSG_CHECKING(for default loader flags)
352 case $DFT_LWR_MODEL in
353 libtool) LD_MODEL=''   ;;
354 normal)  LD_MODEL=''   ;;
355 debug)   LD_MODEL=$CC_G_OPT ;;
356 profile) LD_MODEL='-pg';;
357 shared)  LD_MODEL=''   ;;
358 esac
359 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
360 AC_MSG_RESULT($LD_MODEL)
361
362 case $DFT_LWR_MODEL in
363 shared)
364 AC_MSG_CHECKING(if rpath option should be used)
365 AC_ARG_ENABLE(rpath,
366 [  --enable-rpath          use rpath option when generating shared libraries],
367 [cf_cv_ld_rpath=$enableval],
368 [cf_cv_ld_rpath=no])
369 AC_MSG_RESULT($cf_cv_ld_rpath)
370 AC_MSG_CHECKING(if shared libraries should be relinked during install)
371 AC_ARG_ENABLE(relink,
372 [  --disable-relink        relink shared libraries during install],
373 [cf_cv_do_relink=$enableval],
374 [cf_cv_do_relink=yes])
375 AC_MSG_RESULT($cf_cv_do_relink)
376         ;;
377 esac
378
379 CF_SHARED_OPTS
380 if test "$CC_SHARED_OPTS" = "unknown"; then
381         for model in $cf_list_models; do
382                 if test "$model" = "shared"; then
383                         AC_ERROR(Shared libraries are not supported in this version)
384                 fi
385         done
386 fi
387
388 ###############################################################################
389 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
390
391 ###     use option --disable-overwrite to leave out the link to -lcurses
392 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
393 AC_ARG_ENABLE(overwrite,
394         [  --disable-overwrite     leave out the link to -lcurses],
395         [with_overwrite=$enableval],
396         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
397 AC_MSG_RESULT($with_overwrite)
398
399 AC_MSG_CHECKING(if external terminfo-database is used)
400 AC_ARG_ENABLE(database,
401         [  --disable-database      do not use terminfo, only fallbacks/termcap],
402         [use_database=$enableval],
403         [use_database=yes])
404 AC_MSG_RESULT($use_database)
405
406 case $host_os in #(vi
407 os2*) #(vi
408         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
409         ;;
410 *) #(vi
411         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
412         ;;
413 esac
414 AC_SUBST(TERMINFO_SRC)
415
416 CF_PATHSEP
417 if test "$use_database" != no ; then
418         AC_DEFINE(USE_DATABASE)
419
420         AC_MSG_CHECKING(which terminfo source-file will be installed)
421         AC_ARG_ENABLE(database,
422                 [  --with-database=XXX     specify terminfo source to install],
423                 [TERMINFO_SRC=$withval])
424         AC_MSG_RESULT($TERMINFO_SRC)
425
426         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
427         AC_ARG_WITH(hashed-db,
428                 [  --with-hashed-db        specify hashed-database library],,
429                 [with_hashed_db=no])
430         AC_MSG_RESULT($with_hashed_db)
431 fi
432
433 AC_MSG_CHECKING(for list of fallback descriptions)
434 AC_ARG_WITH(fallbacks,
435         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
436         [with_fallback=$withval],
437         [with_fallback=])
438 AC_MSG_RESULT($with_fallback)
439 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
440 AC_SUBST(FALLBACK_LIST)
441
442 AC_MSG_CHECKING(if you want modern xterm or antique)
443 AC_ARG_WITH(xterm-new,
444         [  --without-xterm-new     specify if xterm terminfo should be old version],
445         [with_xterm_new=$withval],
446         [with_xterm_new=yes])
447 case $with_xterm_new in
448 no)     with_xterm_new=xterm-old;;
449 *)      with_xterm_new=xterm-new;;
450 esac
451 AC_MSG_RESULT($with_xterm_new)
452 WHICH_XTERM=$with_xterm_new
453 AC_SUBST(WHICH_XTERM)
454
455 MAKE_TERMINFO=
456 if test "$use_database" = no ; then
457         TERMINFO="${datadir}/terminfo"
458         MAKE_TERMINFO="#"
459 else
460
461 AC_MSG_CHECKING(for list of terminfo directories)
462 CF_WITH_PATHLIST(terminfo-dirs,
463         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
464         TERMINFO_DIRS,
465         DATADIR/terminfo,
466         ${datadir}/terminfo)
467 AC_MSG_RESULT($TERMINFO_DIRS)
468 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
469
470 AC_MSG_CHECKING(for default terminfo directory)
471 CF_WITH_PATH(default-terminfo-dir,
472         [  --with-default-terminfo-dir=DIR default terminfo directory],
473         TERMINFO,
474         DATADIR/terminfo,
475         ${datadir}/terminfo)
476 AC_MSG_RESULT($TERMINFO)
477 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
478
479 fi
480
481 AC_SUBST(TERMINFO)
482 AC_SUBST(MAKE_TERMINFO)
483
484 ###     use option --disable-big-core to make tic run on small machines
485 ###     We need 4Mb, check if we can allocate 50% more than that.
486 AC_MSG_CHECKING(if big-core option selected)
487 AC_ARG_ENABLE(big-core,
488         [  --disable-big-core      assume machine has little memory],
489         [with_big_core=$enableval],
490         [AC_TRY_RUN([
491 #include <stdlib.h>
492 #include <string.h>
493 int main() {
494         unsigned long n = 6000000L;
495         char *s = malloc(n);
496         if (s != 0)
497                 s[0] = s[n-1] = 0;
498         ${cf_cv_main_return:-return}(s == 0);
499 }],
500         [with_big_core=yes],
501         [with_big_core=no],
502         [with_big_core=no])])
503 AC_MSG_RESULT($with_big_core)
504 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
505
506 ### ISO C only guarantees 512-char strings, we have tables which load faster
507 ### when constructed using "big" strings.
508 AC_MSG_CHECKING(if big-strings option selected)
509 AC_ARG_ENABLE(big-strings,
510         [  --disable-big-strings   assume compiler has only standard-size strings],
511         [with_big_strings=no],
512         [with_big_strings=yes])
513 AC_MSG_RESULT($with_big_strings)
514
515 USE_BIG_STRINGS=0
516 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
517 AC_SUBST(USE_BIG_STRINGS)
518
519 ###     use option --enable-termcap to compile in the termcap fallback support
520 AC_MSG_CHECKING(if you want termcap-fallback support)
521 AC_ARG_ENABLE(termcap,
522         [  --enable-termcap        compile in termcap fallback support],
523         [with_termcap=$enableval],
524         [with_termcap=no])
525 AC_MSG_RESULT($with_termcap)
526
527 if test "$with_termcap" != "yes" ; then
528         if test "$use_database" = no ; then
529                 if test -z "$with_fallback" ; then
530                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
531                 fi
532         fi
533         AC_DEFINE(PURE_TERMINFO)
534 else
535
536 if test "$with_ticlib" != no ; then
537         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
538 fi
539
540 AC_DEFINE(USE_TERMCAP)
541 AC_MSG_CHECKING(for list of termcap files)
542 CF_WITH_PATHLIST(termpath,
543         [  --with-termpath=XXX     specify list of termcap files],
544         TERMPATH,
545         /etc/termcap:/usr/share/misc/termcap)
546 AC_MSG_RESULT($TERMPATH)
547 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
548
549 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
550 AC_MSG_CHECKING(if fast termcap-loader is needed)
551 AC_ARG_ENABLE(getcap,
552         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
553         [with_getcap=$enableval],
554         [with_getcap=no])
555 AC_MSG_RESULT($with_getcap)
556 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
557
558 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
559 AC_ARG_ENABLE(getcap-cache,
560         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
561         [with_getcap_cache=$enableval],
562         [with_getcap_cache=no])
563 AC_MSG_RESULT($with_getcap_cache)
564 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
565
566 fi
567
568 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
569 AC_MSG_CHECKING(if ~/.terminfo is wanted)
570 AC_ARG_ENABLE(home-terminfo,
571         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
572         [with_home_terminfo=$enableval],
573         [with_home_terminfo=yes])
574 AC_MSG_RESULT($with_home_terminfo)
575 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
576
577 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
578 AC_ARG_ENABLE(root-environ,
579         [  --disable-root-environ  restrict environment when running as root],
580         [with_root_environ=$enableval],
581         [with_root_environ=yes])
582 AC_MSG_RESULT($with_root_environ)
583 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
584
585 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
586 ###   to reduce storage requirements for the terminfo database.
587 CF_LINK_FUNCS
588
589 with_links=no
590 with_symlinks=no
591
592 # soft links (symbolic links) are useful for some systems where hard links do
593 # not work, or to make it simpler to copy terminfo trees around.
594 if test "$ac_cv_func_symlink" = yes ; then
595     AC_MSG_CHECKING(if tic should use symbolic links)
596     AC_ARG_ENABLE(symlinks,
597         [  --enable-symlinks       make tic use symbolic links not hard links],
598         [with_symlinks=$enableval],
599         [with_symlinks=no])
600     AC_MSG_RESULT($with_symlinks)
601 fi
602
603 # If we have hard links and did not choose to use soft links instead, there is
604 # no reason to make this choice optional - use the hard links.
605 if test "$with_symlinks" = no ; then
606     AC_MSG_CHECKING(if tic should use hard links)
607     if test "$ac_cv_func_link" = yes ; then
608         with_links=yes
609     else
610         with_links=no
611     fi
612     AC_MSG_RESULT($with_links)
613 fi
614
615 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
616 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
617
618 ###   use option --enable-broken-linker to force on use of broken-linker support
619 AC_MSG_CHECKING(if you want broken-linker support code)
620 AC_ARG_ENABLE(broken_linker,
621         [  --enable-broken_linker  compile with broken-linker support code],
622         [with_broken_linker=$enableval],
623         [with_broken_linker=${BROKEN_LINKER-no}])
624 AC_MSG_RESULT($with_broken_linker)
625
626 BROKEN_LINKER=0
627 if test "$with_broken_linker" = yes ; then
628         AC_DEFINE(BROKEN_LINKER)
629         BROKEN_LINKER=1
630 elif test "$DFT_LWR_MODEL" = shared ; then
631         case $cf_cv_system_name in #(vi
632         cygwin*)
633                 AC_DEFINE(BROKEN_LINKER)
634                 BROKEN_LINKER=1
635                 CF_VERBOSE(cygwin linker is broken anyway)
636                 ;;
637         esac
638 fi
639 AC_SUBST(BROKEN_LINKER)
640
641 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
642 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
643 AC_ARG_ENABLE(bsdpad,
644         [  --enable-bsdpad         recognize BSD-style prefix padding],
645         [with_bsdpad=$enableval],
646         [with_bsdpad=no])
647 AC_MSG_RESULT($with_bsdpad)
648 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
649
650 ###   use option --enable-widec to turn on use of wide-character support
651 NCURSES_CH_T=chtype
652 NCURSES_LIBUTF8=0
653
654 NEED_WCHAR_H=0
655 NCURSES_MBSTATE_T=0
656 NCURSES_WCHAR_T=0
657 NCURSES_WINT_T=0
658
659 # Check to define _XOPEN_SOURCE "automatically"
660 CF_XOPEN_SOURCE
661
662 # Work around breakage on OS X
663 CF_SIGWINCH
664
665 # Checks for CODESET support.
666 AM_LANGINFO_CODESET
667
668 # use these variables to work around a defect in gcc's fixincludes.
669 NCURSES_OK_WCHAR_T=
670 NCURSES_OK_WINT_T=
671
672 AC_MSG_CHECKING(if you want wide-character code)
673 AC_ARG_ENABLE(widec,
674         [  --enable-widec          compile with wide-char/UTF-8 code],
675         [with_widec=$enableval],
676         [with_widec=no])
677 AC_MSG_RESULT($with_widec)
678 if test "$with_widec" = yes ; then
679         LIB_SUFFIX="w${LIB_SUFFIX}"
680         AC_DEFINE(USE_WIDEC_SUPPORT)
681         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
682         # with_overwrite=no
683         NCURSES_CH_T=cchar_t
684         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc)
685         if test "$ac_cv_func_putwc" != yes ; then
686                 CF_LIBUTF8
687                 if test "$cf_cv_libutf8" = yes ; then
688                         NCURSES_LIBUTF8=1
689                 fi
690         fi
691         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
692         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
693         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
694
695         if test "$NCURSES_MBSTATE_T" != 0; then
696                 AC_DEFINE(NEED_MBSTATE_T_DEF)
697         fi
698 fi
699 AC_SUBST(NCURSES_CH_T)
700 AC_SUBST(NCURSES_LIBUTF8)
701
702 AC_SUBST(NEED_WCHAR_H)
703 AC_SUBST(NCURSES_MBSTATE_T)
704 AC_SUBST(NCURSES_WCHAR_T)
705 AC_SUBST(NCURSES_WINT_T)
706
707 AC_SUBST(NCURSES_OK_WCHAR_T)
708 AC_SUBST(NCURSES_OK_WINT_T)
709
710 ###   use option --disable-lp64 to allow long chtype
711 case $cf_cv_abi_version in
712 [[345]]*)
713         default_with_lp64=no
714         ;;
715 *)
716         default_with_lp64=yes
717         ;;
718 esac
719
720 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
721 AC_ARG_ENABLE(lp64,
722         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
723         [with_lp64=$enableval],
724         [with_lp64=$default_with_lp64])
725 AC_MSG_RESULT($with_lp64)
726
727 if test "$with_lp64" = yes ; then
728         cf_cv_enable_lp64=1
729 else
730         cf_cv_enable_lp64=0
731 fi
732 AC_SUBST(cf_cv_enable_lp64)
733
734 CF_LARGEFILE
735
736 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
737 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
738 AC_ARG_ENABLE(tparm-varargs,
739         [  --disable-tparm-varargs compile tparm() without varargs interface],
740         [with_tparm_varargs=$enableval],
741         [with_tparm_varargs=yes])
742 AC_MSG_RESULT($with_tparm_varargs)
743 NCURSES_TPARM_VARARGS=0
744 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
745 AC_SUBST(NCURSES_TPARM_VARARGS)
746
747 ###   use option --with-bool to override bool's type
748 AC_MSG_CHECKING(for type of bool)
749 AC_ARG_WITH(bool,
750         [  --with-bool=TYPE        override fallback type of bool variable],
751         [NCURSES_BOOL="$withval"],
752         [NCURSES_BOOL=auto])
753 AC_MSG_RESULT($NCURSES_BOOL)
754 AC_SUBST(NCURSES_BOOL)
755
756 AC_MSG_CHECKING(for alternate terminal capabilities file)
757 AC_ARG_WITH(caps,
758         [  --with-caps=alt         compile with alternate Caps file],
759         [TERMINFO_CAPS=Caps.$withval],
760         [TERMINFO_CAPS=Caps])
761 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
762 AC_MSG_RESULT($TERMINFO_CAPS)
763 AC_SUBST(TERMINFO_CAPS)
764
765 ###   use option --with-chtype to override chtype's type
766 AC_MSG_CHECKING(for type of chtype)
767 AC_ARG_WITH(chtype,
768         [  --with-chtype=TYPE      override type of chtype],
769         [NCURSES_CHTYPE="$withval"],
770         [NCURSES_CHTYPE=auto])
771 AC_MSG_RESULT($NCURSES_CHTYPE)
772
773 ###   use option --with-ospeed to override ospeed's type
774 AC_MSG_CHECKING(for type of ospeed)
775 AC_ARG_WITH(ospeed,
776         [  --with-ospeed=TYPE      override type of ospeed variable],
777         [NCURSES_OSPEED="$withval"],
778         [NCURSES_OSPEED=short])
779 AC_MSG_RESULT($NCURSES_OSPEED)
780 AC_SUBST(NCURSES_OSPEED)
781
782 ###   use option --with-mmask-t to override mmask_t's type
783 AC_MSG_CHECKING(for type of mmask_t)
784 AC_ARG_WITH(mmask-t,
785         [  --with-mmask-t=TYPE     override type of mmask_t],
786         [NCURSES_MMASK_T="$withval"],
787         [NCURSES_MMASK_T=auto])
788 AC_MSG_RESULT($NCURSES_MMASK_T)
789
790 ### Enable compiling-in rcs id's
791 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
792 AC_ARG_WITH(rcs-ids,
793         [  --with-rcs-ids          compile-in RCS identifiers],
794         [with_rcs_ids=$withval],
795         [with_rcs_ids=no])
796 AC_MSG_RESULT($with_rcs_ids)
797 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
798
799 ###############################################################################
800 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tic toe tput ])
801
802 ###############################################################################
803 CF_HELP_MESSAGE(Extensions:)
804
805 ### Note that some functions (such as const) are normally disabled anyway.
806 AC_MSG_CHECKING(if you want to build with function extensions)
807 AC_ARG_ENABLE(ext-funcs,
808         [  --disable-ext-funcs     disable function-extensions],
809         [with_ext_funcs=$enableval],
810         [with_ext_funcs=yes])
811 AC_MSG_RESULT($with_ext_funcs)
812 if test "$with_ext_funcs" = yes ; then
813         NCURSES_EXT_FUNCS=1
814         AC_DEFINE(HAVE_CURSES_VERSION)
815         AC_DEFINE(HAVE_HAS_KEY)
816         AC_DEFINE(HAVE_RESIZETERM)
817         AC_DEFINE(HAVE_RESIZE_TERM)
818         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
819         AC_DEFINE(HAVE_WRESIZE)
820         AC_DEFINE(NCURSES_EXT_FUNCS)
821 else
822         NCURSES_EXT_FUNCS=0
823 fi
824 AC_SUBST(NCURSES_EXT_FUNCS)
825
826 ###   use option --enable-const to turn on use of const beyond that in XSI.
827 AC_MSG_CHECKING(for extended use of const keyword)
828 AC_ARG_ENABLE(const,
829         [  --enable-const          compile with extra/non-standard const],
830         [with_ext_const=$enableval],
831         [with_ext_const=no])
832 AC_MSG_RESULT($with_ext_const)
833 NCURSES_CONST='/*nothing*/'
834 if test "$with_ext_const" = yes ; then
835         NCURSES_CONST=const
836 fi
837 AC_SUBST(NCURSES_CONST)
838
839 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
840 AC_MSG_CHECKING(if you want to use extended colors)
841 AC_ARG_ENABLE(ext-colors,
842         [  --enable-ext-colors     compile for 256-color support],
843         [with_ext_colors=$enableval],
844         [with_ext_colors=no])
845 AC_MSG_RESULT($with_ext_colors)
846 NCURSES_EXT_COLORS=0
847 if test "$with_ext_colors" = yes ; then
848         if test "$with_widec" != yes ; then
849                 AC_MSG_ERROR(This option applies only to wide-character library)
850         else
851                 # cannot be ABI 5 since it changes sizeof(cchar_t)
852                 CF_NCURSES_ABI_6
853         fi
854         NCURSES_EXT_COLORS=1
855         AC_DEFINE(NCURSES_EXT_COLORS)
856 fi
857 AC_SUBST(NCURSES_EXT_COLORS)
858
859 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
860 AC_MSG_CHECKING(if you want to use extended mouse encoding)
861 AC_ARG_ENABLE(ext-mouse,
862         [  --enable-ext-mouse      compile for extended mouse-encoding],
863         [with_ext_mouse=$enableval],
864         [with_ext_mouse=no])
865 AC_MSG_RESULT($with_ext_mouse)
866 NCURSES_MOUSE_VERSION=1
867 if test "$with_ext_mouse" = yes ; then
868         NCURSES_MOUSE_VERSION=2
869         CF_NCURSES_ABI_6
870 fi
871 AC_SUBST(NCURSES_MOUSE_VERSION)
872
873 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
874 AC_ARG_ENABLE(no-padding,
875         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
876         [with_no_padding=$enableval],
877         [with_no_padding=$with_ext_funcs])
878 AC_MSG_RESULT($with_no_padding)
879 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
880
881 AC_CHECK_SIZEOF([signed char], 0)
882 if test "$ac_cv_sizeof_signed_char" = 1 ; then
883         NCURSES_SBOOL="signed char"
884 else
885         NCURSES_SBOOL="char"
886 fi
887 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
888 AC_ARG_ENABLE(signed-char,
889         [  --enable-signed-char    compile using signed Boolean's in term.h],
890         [with_signed_char=$enableval],
891         [with_signed_char=no])
892 AC_MSG_RESULT($with_signed_char)
893 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
894 AC_SUBST(NCURSES_SBOOL)
895
896 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
897 AC_MSG_CHECKING(if you want SIGWINCH handler)
898 AC_ARG_ENABLE(sigwinch,
899         [  --enable-sigwinch       compile with SIGWINCH handler],
900         [with_sigwinch=$enableval],
901         [with_sigwinch=$with_ext_funcs])
902 AC_MSG_RESULT($with_sigwinch)
903 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
904
905 ###   use option --enable-tcap-names to allow user to define new capabilities
906 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
907 AC_ARG_ENABLE(tcap-names,
908         [  --enable-tcap-names     compile with user-definable terminal capabilities],
909         [with_tcap_names=$enableval],
910         [with_tcap_names=$with_ext_funcs])
911 AC_MSG_RESULT($with_tcap_names)
912 NCURSES_XNAMES=0
913 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
914 AC_SUBST(NCURSES_XNAMES)
915
916 ###############################################################################
917 # These options are relatively safe to experiment with.
918 CF_HELP_MESSAGE(Development Code:)
919 AC_MSG_CHECKING(if you want all development code)
920 AC_ARG_WITH(develop,
921         [  --without-develop       disable development options],
922         [with_develop=$withval],
923         [with_develop=no])
924 AC_MSG_RESULT($with_develop)
925
926 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
927 AC_MSG_CHECKING(if you want hard-tabs code)
928 AC_ARG_ENABLE(hard-tabs,
929         [  --enable-hard-tabs      compile with hard-tabs code],,
930         [enable_hard_tabs=$with_develop])
931 AC_MSG_RESULT($enable_hard_tabs)
932 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
933
934 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
935 AC_MSG_CHECKING(if you want limited support for xmc)
936 AC_ARG_ENABLE(xmc-glitch,
937         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
938         [enable_xmc_glitch=$with_develop])
939 AC_MSG_RESULT($enable_xmc_glitch)
940 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
941
942 ###############################################################################
943 # These are just experimental, probably should not be in a package:
944 CF_HELP_MESSAGE(Experimental Code:)
945
946 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
947 AC_ARG_ENABLE(assumed-color,
948         [  --disable-assumed-color do not assume anything about default-colors],
949         [with_assumed_color=$enableval],
950         [with_assumed_color=yes])
951 AC_MSG_RESULT($with_assumed_color)
952 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
953
954 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
955 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
956 AC_ARG_ENABLE(hashmap,
957         [  --disable-hashmap       compile without hashmap scrolling-optimization],
958         [with_hashmap=$enableval],
959         [with_hashmap=yes])
960 AC_MSG_RESULT($with_hashmap)
961 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
962
963 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
964 AC_MSG_CHECKING(if you want colorfgbg code)
965 AC_ARG_ENABLE(colorfgbg,
966         [  --enable-colorfgbg      compile with $COLORFGBG code],
967         [with_colorfgbg=$enableval],
968         [with_colorfgbg=no])
969 AC_MSG_RESULT($with_colorfgbg)
970 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
971
972 # This is still experimental (20080329), but should ultimately be moved to
973 # the script-block --with-normal, etc.
974 CF_WITH_PTHREAD
975
976 AC_ARG_ENABLE(weak-symbols,
977     [  --enable-weak-symbols       enable weak-symbols for pthreads],
978     [use_weak_symbols=$withval],
979     [use_weak_symbols=no])
980 AC_MSG_RESULT($use_weak_symbols)
981 if test "$use_weak_symbols" = yes ; then
982     CF_WEAK_SYMBOLS
983 else
984     cf_cv_weak_symbols=no
985 fi
986
987 if test $cf_cv_weak_symbols = yes ; then
988     AC_DEFINE(USE_WEAK_SYMBOLS)
989 fi
990
991 PTHREAD=
992 if test "$with_pthread" = "yes" ; then
993     AC_DEFINE(USE_PTHREADS)
994     enable_reentrant=yes
995     if test $cf_cv_weak_symbols = yes ; then
996         PTHREAD=-lpthread
997     fi
998 fi
999 AC_SUBST(PTHREAD)
1000
1001 # Reentrant code has to be opaque; there's little advantage to making ncurses
1002 # opaque outside of that, so there is no --enable-opaque option.  We can use
1003 # this option without --with-pthreads, but this will be always set for
1004 # pthreads.
1005 AC_MSG_CHECKING(if you want experimental reentrant code)
1006 AC_ARG_ENABLE(reentrant,
1007         [  --enable-reentrant      compile with experimental reentrant code],
1008         [with_reentrant=$enableval],
1009         [with_reentrant=no])
1010 AC_MSG_RESULT($with_reentrant)
1011 if test "$with_reentrant" = yes ; then
1012         cf_cv_enable_reentrant=1
1013         cf_cv_enable_opaque="NCURSES_INTERNALS"
1014         NCURSES_OPAQUE=1
1015         NCURSES_SIZE_T=int
1016     if test $cf_cv_weak_symbols = yes ; then
1017         CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1018     else
1019         LIB_SUFFIX="t${LIB_SUFFIX}"
1020     fi
1021         AC_DEFINE(USE_REENTRANT)
1022         CF_NCURSES_ABI_6
1023 else
1024         cf_cv_enable_reentrant=0
1025         cf_cv_enable_opaque="NCURSES_OPAQUE"
1026         NCURSES_OPAQUE=0
1027         NCURSES_SIZE_T=short
1028 fi
1029 AC_SUBST(cf_cv_enable_reentrant)
1030 AC_SUBST(cf_cv_enable_opaque)
1031 AC_SUBST(NCURSES_OPAQUE)
1032 AC_SUBST(NCURSES_SIZE_T)
1033
1034 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1035 AC_ARG_ENABLE(safe-sprintf,
1036         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1037         [with_safe_sprintf=$enableval],
1038         [with_safe_sprintf=no])
1039 AC_MSG_RESULT($with_safe_sprintf)
1040 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1041
1042 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1043 # when hashmap is used scroll hints are useless
1044 if test "$with_hashmap" = no ; then
1045 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1046 AC_ARG_ENABLE(scroll-hints,
1047         [  --disable-scroll-hints  compile without scroll-hints code],
1048         [with_scroll_hints=$enableval],
1049         [with_scroll_hints=yes])
1050 AC_MSG_RESULT($with_scroll_hints)
1051 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1052 fi
1053
1054 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1055 AC_ARG_ENABLE(wgetch-events,
1056         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1057         [with_wgetch_events=$enableval],
1058         [with_wgetch_events=no])
1059 AC_MSG_RESULT($with_wgetch_events)
1060 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1061
1062 ###############################################################################
1063 CF_HELP_MESSAGE(Testing/development Options:)
1064
1065 ###     use option --disable-echo to suppress full display compiling commands
1066 AC_MSG_CHECKING(if you want to display full commands during build)
1067 AC_ARG_ENABLE(echo,
1068         [  --enable-echo           build: display "compiling" commands (default)],
1069         [with_echo=$enableval],
1070         [with_echo=yes])
1071 if test "$with_echo" = yes; then
1072         ECHO_LINK=
1073 else
1074         ECHO_LINK='@ echo linking $@ ... ;'
1075         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1076         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1077 fi
1078 AC_MSG_RESULT($with_echo)
1079 AC_SUBST(ECHO_LINK)
1080
1081 ###     use option --enable-warnings to turn on all gcc warnings
1082 AC_MSG_CHECKING(if you want to see compiler warnings)
1083 AC_ARG_ENABLE(warnings,
1084         [  --enable-warnings       build: turn on GCC compiler warnings],
1085         [with_warnings=$enableval])
1086 AC_MSG_RESULT($with_warnings)
1087
1088 if test "x$with_warnings" = "xyes"; then
1089         ADAFLAGS="$ADAFLAGS -gnatg"
1090         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1091         if test "$cf_with_cxx" = yes ; then
1092                 CF_GXX_WARNINGS(Wno-unused)
1093         fi
1094 fi
1095 CF_GCC_ATTRIBUTES
1096
1097 ###     use option --enable-assertions to turn on generation of assertion code
1098 AC_MSG_CHECKING(if you want to enable runtime assertions)
1099 AC_ARG_ENABLE(assertions,
1100         [  --enable-assertions     test: turn on generation of assertion code],
1101         [with_assertions=$enableval],
1102         [with_assertions=no])
1103 AC_MSG_RESULT($with_assertions)
1104 if test -n "$GCC"
1105 then
1106         if test "$with_assertions" = no
1107         then
1108                 AC_DEFINE(NDEBUG)
1109                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1110         else
1111                 ADAFLAGS="$ADAFLAGS -gnata"
1112         fi
1113 fi
1114
1115 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1116 CF_DISABLE_LEAKS
1117 AC_DEFINE(HAVE_NC_ALLOC_H)
1118
1119 ###     use option --enable-expanded to generate certain macros as functions
1120 AC_ARG_ENABLE(expanded,
1121         [  --enable-expanded       test: generate functions for certain macros],
1122         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1123
1124 ###     use option --disable-macros to suppress macros in favor of functions
1125 AC_ARG_ENABLE(macros,
1126         [  --disable-macros        test: use functions rather than macros],
1127         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1128
1129 # Normally we only add trace() to the debug-library.  Allow this to be
1130 # extended to all models of the ncurses library:
1131 cf_all_traces=no
1132 case "$CFLAGS $CPPFLAGS" in
1133 *-DTRACE*)
1134         cf_all_traces=yes
1135         ;;
1136 esac
1137
1138 AC_MSG_CHECKING(whether to add trace feature to all models)
1139 AC_ARG_WITH(trace,
1140 [  --with-trace            test: add trace() function to all models of ncurses],
1141 [cf_with_trace=$withval],
1142 [cf_with_trace=$cf_all_traces])
1143 AC_MSG_RESULT($cf_with_trace)
1144
1145 if test "$cf_with_trace" = yes ; then
1146         LIB_TRACING=all
1147         ADA_TRACE=TRUE
1148         CF_ADD_CFLAGS(-DTRACE)
1149 else
1150         LIB_TRACING=DEBUG
1151         ADA_TRACE=FALSE
1152 fi
1153
1154 AC_SUBST(ADA_TRACE)
1155
1156 ###     Checks for libraries.
1157 AC_CHECK_FUNC(gettimeofday,
1158         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1159
1160 AC_CHECK_LIB(bsd, gettimeofday,
1161         AC_DEFINE(HAVE_GETTIMEOFDAY)
1162         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
1163
1164 CF_MATH_LIB(MATH_LIB,sin(x))
1165 AC_SUBST(MATH_LIB)
1166
1167 ###     Checks for header files.
1168 AC_STDC_HEADERS
1169 AC_HEADER_DIRENT
1170 AC_HEADER_TIME
1171 CF_REGEX
1172
1173 dnl These are some other potentially nonportable headers.
1174 AC_CHECK_HEADERS( \
1175 fcntl.h \
1176 getopt.h \
1177 limits.h \
1178 locale.h \
1179 poll.h \
1180 sys/bsdtypes.h \
1181 sys/ioctl.h \
1182 sys/param.h \
1183 sys/poll.h \
1184 sys/select.h \
1185 sys/time.h \
1186 sys/times.h \
1187 ttyent.h \
1188 unistd.h \
1189 wctype.h \
1190 )
1191
1192 # check for ISC (this may also define _POSIX_SOURCE)
1193 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1194 if test "$ISC" = yes ; then
1195         AC_CHECK_LIB(cposix,main)
1196         AC_CHECK_LIB(inet,bzero,LIBS="$LIBS -linet")dnl also 'select()'
1197 fi
1198
1199 CF_SYS_TIME_SELECT
1200
1201 ###     checks for compiler characteristics
1202 AC_LANG_C
1203 AC_C_CONST
1204 CF_C_INLINE(NCURSES_INLINE,1200)
1205 CF_SIG_ATOMIC_T
1206
1207 if test $NCURSES_CHTYPE = auto ; then
1208         CF_TYPEOF_CHTYPE
1209 else
1210         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1211 fi
1212 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1213 AC_SUBST(cf_cv_typeof_chtype)
1214
1215 CF_UNSIGNED_LITERALS
1216 cf_cv_1UL="1"
1217 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1218 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1219 AC_SUBST(cf_cv_1UL)
1220
1221 if test $NCURSES_MMASK_T = auto ; then
1222         cf_cv_typeof_mmask_t=long
1223 else
1224         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1225 fi
1226 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1227 AC_SUBST(cf_cv_typeof_mmask_t)
1228
1229 ###     Checks for external-data
1230 CF_ERRNO
1231 CF_LINK_DATAONLY
1232
1233 ###     Checks for library functions.
1234 AC_CHECK_FUNCS( \
1235 getcwd \
1236 getegid \
1237 geteuid \
1238 getttynam \
1239 issetugid \
1240 poll \
1241 remove \
1242 select \
1243 setbuf \
1244 setbuffer \
1245 setvbuf \
1246 sigaction \
1247 sigvec \
1248 strdup \
1249 strstr \
1250 tcgetpgrp \
1251 times \
1252 vsnprintf \
1253 )
1254 if test "$with_getcap" = "yes" ; then
1255         CF_CGETENT
1256 fi
1257
1258 CF_ISASCII
1259 CF_STRUCT_SIGACTION
1260 CF_FUNC_NANOSLEEP
1261 CF_FUNC_TERMIOS
1262 CF_FUNC_VSSCANF
1263 CF_MKSTEMP
1264
1265 # setup for prototype of fallback for vsscanf()
1266 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1267
1268 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1269 if test "$cross_compiling" = yes ; then
1270         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1271 else
1272         AC_FUNC_SETVBUF_REVERSED
1273 fi
1274 AC_TYPE_SIGNAL
1275 CF_TYPE_SIGACTION
1276 CF_SIZECHANGE
1277 CF_FUNC_MEMMOVE
1278 CF_FUNC_POLL
1279
1280 # special check for test/ditto.c
1281 CF_FUNC_OPENPTY
1282 if test "$cf_cv_func_openpty" != no ; then
1283     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1284     AC_DEFINE(USE_XTERM_PTY)
1285     if test "$cf_cv_lib_util" = yes ; then
1286         TEST_LIBS="-lutil $TEST_LIBS"
1287     fi
1288 fi
1289 AC_SUBST(TEST_LIBS)
1290
1291 if test "$with_hashed_db" != no ; then
1292         AC_DEFINE(USE_HASHED_DB)
1293         CF_HASHED_DB($with_hashed_db)
1294 fi
1295
1296 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1297 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1298         CF_STRIP_G_OPT(CFLAGS)
1299         CF_STRIP_G_OPT(CXXFLAGS)
1300 fi
1301
1302 # Just in case, check if the C compiler has a bool type.
1303 CF_BOOL_DECL(cf_cv_cc_bool_type)
1304
1305 # Check for C++ compiler characteristics (and ensure that it's there!)
1306 if test -n "$CXX" ; then
1307         AC_LANG_CPLUSPLUS
1308         CF_STDCPP_LIBRARY
1309         CF_PROG_CC_C_O(CXX)
1310
1311         case $GXX_VERSION in
1312         1*|2.[0-6]*)
1313                 cf_cxx_library=yes
1314                 ;;
1315         *-2.7*|2.7*)
1316                 CF_GPP_LIBRARY
1317                 ;;
1318         *)
1319                 cf_cxx_library=no
1320                 ;;
1321         esac
1322
1323         AC_CHECK_HEADERS(iostream typeinfo)
1324
1325         CF_BOOL_DECL
1326         CF_BOOL_SIZE
1327         CF_ETIP_DEFINES
1328         CF_CPP_PARAM_INIT
1329         CF_CPP_STATIC_CAST
1330
1331         CXX_AR='$(AR)'
1332         CXX_AR_OPTS='$(AR_OPTS)'
1333         case $cf_cv_system_name in #(vi
1334         irix*) #(vi
1335             if test "$GXX" != yes ; then
1336                 CXX_AR='$(CXX)'
1337                 CXX_AR_OPTS='-ar -o'
1338             fi
1339             ;;
1340         sco3.2v5*) #(vi
1341             CXXLDFLAGS="-u main"
1342             ;;
1343         solaris2*)
1344             if test "$GXX" != yes ; then
1345                 CXX_AR='$(CXX)'
1346                 CXX_AR_OPTS='-xar -o'
1347             fi
1348             ;;
1349         esac
1350         AC_SUBST(CXXLDFLAGS)
1351         AC_SUBST(CXX_AR)
1352         AC_SUBST(CXX_AR_OPTS)
1353 else
1354         cf_cxx_library=no
1355         cf_cv_builtin_bool=1
1356
1357         # Just because we are not configuring against C++ right now does not
1358         # mean that a user will not want to use C++.  Some distributors disable
1359         # the C++ portion of this configuration as a shortcut (or just to avoid
1360         # compiling the demo in the c++ directory).  So we need a reasonable
1361         # default for the 'bool' type.
1362         #
1363         # Caveat: since the storage of the bool type is not standardized, it
1364         # may change.
1365
1366         if test "$NCURSES_BOOL" != auto ; then
1367                 cf_cv_type_of_bool=$NCURSES_BOOL
1368                 cf_cv_header_stdbool_h=0
1369         else
1370                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1371                         CF_BOOL_SIZE
1372                 else
1373                         AC_MSG_CHECKING(for fallback type of bool)
1374                         case "$host_cpu" in #(vi
1375                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1376                         *)      cf_cv_type_of_bool=int  ;;
1377                         esac
1378                         AC_MSG_RESULT($cf_cv_type_of_bool)
1379                 fi
1380         fi
1381 fi
1382 AC_SUBST(CXXLIBS)
1383
1384 # If the C compiler did not declare bool, and we did not determine that the C++
1385 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1386 # ncurses library use the same type as C++ bool.  Note that this allows one to
1387 # specify the type of bool in a configure-script option and postpone
1388 # integration with the C++ compiler provided that the types are compatible.
1389 USE_CXX_BOOL=1
1390 if test $cf_cv_cc_bool_type = 1
1391 then
1392         # oops: C has a bool.  Unlikely, but C++ could differ.
1393         USE_CXX_BOOL=0
1394 elif test $cf_cv_builtin_bool = 0
1395 then
1396         # C++ has no bool
1397         USE_CXX_BOOL=0
1398 else
1399         # this is the normal case
1400         USE_CXX_BOOL='defined(__cplusplus)'
1401 fi
1402 AC_SUBST(USE_CXX_BOOL)
1403
1404 CF_HELP_MESSAGE(Ada95 Binding Options:)
1405
1406 dnl If the Ada95 source-tree is present, add that to the build unless it will
1407 dnl not work, or was not requested.
1408 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1409
1410 dnl libtool does not know anything about GNAT, though a change made in 1998
1411 dnl provided for it "someday".  Disable the ada subtree if we are using
1412 dnl libtool -TD 20070714
1413 if test "$cf_with_ada" != "no" ; then
1414     if test "$with_libtool" != "no"; then
1415         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1416         cf_with_ada=no
1417     fi
1418 fi
1419
1420 dnl Check for availability of GNU Ada Translator (GNAT).
1421 dnl At the moment we support no other Ada95 compiler.
1422 if test "$cf_with_ada" != "no" ; then
1423 cf_ada_make=gnatmake
1424 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
1425 if test "$ac_cv_prog_gnat_exists" = no; then
1426    cf_ada_make=
1427 else
1428    CF_GNAT_VERSION
1429    AC_CHECK_PROG(M4_exists, m4, yes, no)
1430    if test "$ac_cv_prog_M4_exists" = no; then
1431       cf_cv_prog_gnat_correct=no
1432       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
1433    fi
1434    if test "$cf_cv_prog_gnat_correct" = yes; then
1435       AC_MSG_CHECKING(if GNAT works)
1436       CF_GNAT_TRY_RUN([procedure conftest;],
1437 [with Text_IO;
1438 with GNAT.OS_Lib;
1439 procedure conftest is
1440 begin
1441    Text_IO.Put ("Hello World");
1442    Text_IO.New_Line;
1443    GNAT.OS_Lib.OS_Exit (0);
1444 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
1445       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
1446    fi
1447 fi
1448 if test "$cf_cv_prog_gnat_correct" = yes; then
1449    ADAFLAGS="-O3 -gnatpn $ADAFLAGS"
1450
1451    AC_MSG_CHECKING(if GNAT pragma Unreferenced works)
1452    CF_GNAT_TRY_LINK([procedure conftest;],
1453 [with Text_IO;
1454 with GNAT.OS_Lib;
1455 procedure conftest is
1456    test : Integer;
1457    pragma Unreferenced (test);
1458 begin
1459    test := 1;
1460    Text_IO.Put ("Hello World");
1461    Text_IO.New_Line;
1462    GNAT.OS_Lib.OS_Exit (0);
1463 end conftest;],[cf_cv_pragma_unreferenced=yes],[cf_cv_pragma_unreferenced=no])
1464    AC_MSG_RESULT($cf_cv_pragma_unreferenced)
1465
1466    # if the pragma is supported, use it (needed in the Trace code).
1467    if test $cf_cv_pragma_unreferenced = yes ; then
1468       PRAGMA_UNREF=TRUE
1469    else
1470       PRAGMA_UNREF=FALSE
1471    fi
1472
1473    AC_ARG_WITH(ada-compiler,
1474         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
1475         [cf_ada_compiler=$withval],
1476         [cf_ada_compiler=gnatmake])
1477
1478    cf_ada_package=terminal_interface
1479
1480    AC_SUBST(cf_ada_make)
1481    AC_SUBST(cf_ada_compiler)
1482    AC_SUBST(cf_ada_package)
1483    AC_SUBST(ADAFLAGS)
1484    AC_SUBST(cf_compile_generics)
1485    AC_SUBST(cf_generic_objects)
1486    AC_SUBST(PRAGMA_UNREF)
1487
1488    CF_WITH_PATH(ada-include,
1489        [  --with-ada-include=DIR  Ada includes are in DIR],
1490        ADA_INCLUDE,
1491        PREFIX/lib/ada/adainclude,
1492        [$]prefix/lib/ada/adainclude)
1493    AC_SUBST(ADA_INCLUDE)
1494
1495    CF_WITH_PATH(ada-objects,
1496        [  --with-ada-objects=DIR  Ada objects are in DIR],
1497        ADA_OBJECTS,
1498        PREFIX/lib/ada/adalib,
1499        [$]prefix/lib/ada/adalib)
1500    AC_SUBST(ADA_OBJECTS)
1501
1502 fi
1503 fi
1504 else
1505    cf_with_ada=no
1506 fi
1507
1508 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1509 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1510 ###
1511 ### ticlib modules may be a separate library, otherwise contained in termlib.
1512 ### termlib modules may be a separate library, otherwise contained in ncurses.
1513 ###
1514 ### The of "+" or " " between the tokens controls the way the script
1515 ### chooses to split module lists into libraries.
1516 ###
1517 ### (see CF_LIB_RULES).
1518 AC_MSG_CHECKING(for library subsets)
1519 LIB_SUBSETS=
1520
1521 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1522         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1523         if test "$with_ticlib" != no ; then
1524                 LIB_SUBSETS="${LIB_SUBSETS} "
1525         else
1526                 LIB_SUBSETS="${LIB_SUBSETS}+"
1527         fi
1528 fi
1529
1530 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1531 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1532 if test "$with_termlib" != no ; then
1533         LIB_SUBSETS="${LIB_SUBSETS} "
1534 else
1535         LIB_SUBSETS="${LIB_SUBSETS}+"
1536 fi
1537
1538 LIB_SUBSETS="${LIB_SUBSETS}base"
1539 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1540 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1541
1542 AC_MSG_RESULT($LIB_SUBSETS)
1543
1544 ### Construct the list of include-directories to be generated
1545 CF_INCLUDE_DIRS
1546 CF_ADA_INCLUDE_DIRS
1547
1548 ### Build up pieces for makefile rules
1549 AC_MSG_CHECKING(default library suffix)
1550 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1551 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1552 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1553
1554 AC_MSG_CHECKING(default library-dependency suffix)
1555 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_DEP_SUFFIX)dnl
1556 DFT_LIB_SUFFIX=$DFT_DEP_SUFFIX
1557 if test $DFT_LWR_MODEL = shared ; then
1558         case $cf_cv_system_name in #(vi
1559         cygwin*)
1560                 DFT_DEP_SUFFIX=".dll.a"
1561                 DFT_LIB_SUFFIX=".dll"
1562                 ;;
1563         esac
1564 fi
1565 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1566 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1567
1568 AC_MSG_CHECKING(default object directory)
1569 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1570 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1571 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1572
1573 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1574 if test "$cf_with_cxx" = yes ; then
1575 AC_MSG_CHECKING(c++ library-dependency suffix)
1576 if test "$with_libtool" != "no"; then
1577         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1578 else
1579         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX)dnl we normally make a static library
1580 fi
1581 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1582 AC_SUBST(CXX_LIB_SUFFIX)
1583 fi
1584
1585 # do not want -ldl in build except as needed for -lncurses dependency
1586 if test "$with_dlsym" = yes ; then
1587 if test $DFT_LWR_MODEL = shared || \
1588    test $DFT_LWR_MODEL = libtool ; then
1589         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1590 fi
1591 fi
1592 ### Set up low-level terminfo dependencies for makefiles.
1593
1594 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1595 # do not need libdl
1596 TICS_LIST=
1597 if test "$with_dlsym" = yes ; then
1598         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1599 fi
1600
1601 if test "$with_ticlib" != no ; then
1602
1603         if test "$with_ticlib" != yes ; then
1604                 TICS_NAME=$with_ticlib
1605                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1606                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1607                 TICS_LIB_SUFFIX="${with_ticlib}"
1608         else
1609                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1610                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1611                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1612         fi
1613         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1614 else
1615         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1616 fi
1617 AC_SUBST(TICS_ARG_SUFFIX)
1618 AC_SUBST(TICS_DEP_SUFFIX)
1619 AC_SUBST(TICS_LIB_SUFFIX)
1620 AC_SUBST(TICS_ARGS)
1621
1622 if test "$with_termlib" != no ; then
1623
1624         if test "$with_termlib" != yes ; then
1625                 TINFO_NAME=$with_termlib
1626                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1627                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1628                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1629                 TINFO_LIB_SUFFIX="${with_termlib}"
1630         else
1631                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1632                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1633                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1634                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1635         fi
1636
1637         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1638         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1639         if test "$DFT_LWR_MODEL" = "libtool"; then
1640                 TEST_ARGS="${TEST_DEPS}"
1641                 TEST_ARG2="${TEST_DEP2}"
1642                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1643         else
1644                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1645                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1646                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1647                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1648                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1649         fi
1650 else
1651         # the next lines are needed for linking libtic over libncurses
1652         TINFO_NAME=${LIB_NAME}
1653         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1654         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1655         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1656
1657         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1658 fi
1659
1660 if test "$DFT_LWR_MODEL" = shared ; then
1661         case $cf_cv_system_name in #(vi
1662         cygwin*)
1663                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1664                 TINFO_SUFFIX=.dll
1665                 ;;
1666         esac
1667 fi
1668
1669 AC_SUBST(TINFO_ARG_SUFFIX)
1670 AC_SUBST(TINFO_DEP_SUFFIX)
1671 AC_SUBST(TINFO_LIB_SUFFIX)
1672 AC_SUBST(TINFO_ARGS)
1673
1674 if test "$with_dlsym" = yes ; then
1675         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1676 fi
1677
1678 if test "$DFT_LWR_MODEL" = "libtool"; then
1679     OBJEXT=lo
1680 fi
1681
1682 # needed for Ada95
1683 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1684 AC_SUBST(TINFO_ARGS2)
1685
1686 case $DFT_LWR_MODEL in
1687 normal|debug|profile)
1688         CF_LDFLAGS_STATIC
1689         ;;
1690 esac
1691
1692 AC_MSG_CHECKING(where we will install curses.h)
1693 test "$with_overwrite" = no && \
1694 test "x$includedir" = 'x${prefix}/include' && \
1695         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1696 AC_MSG_RESULT($includedir)
1697
1698 ### Resolve a conflict between normal and wide-curses by forcing applications
1699 ### that will need libutf8 to add it to their configure script.
1700 if test "$with_overwrite" != no ; then
1701 if test "$NCURSES_LIBUTF8" = 1 ; then
1702         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1703         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1704 fi
1705 fi
1706
1707 AC_SUBST(WITH_OVERWRITE)
1708 AC_SUBST(TICS_LIST)
1709 AC_SUBST(TINFO_LIST)
1710 AC_SUBST(SHLIB_LIST)
1711
1712 # used to separate tack out of the tree
1713 NCURSES_TREE=
1714 AC_SUBST(NCURSES_TREE)
1715
1716 ### predefined stuff for the test programs
1717 AC_DEFINE(HAVE_SLK_COLOR)
1718
1719 ### Construct the list of subdirectories for which we'll customize makefiles
1720 ### with the appropriate compile-rules.
1721
1722 CF_SRC_MODULES($modules_to_build)
1723
1724 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1725    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses-config"
1726 fi
1727
1728 CF_DIRS_TO_MAKE
1729
1730 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATHSEP')
1731
1732 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1733
1734 ### Now that we're done running tests, add the compiler-warnings, if any
1735 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1736
1737 ### If we're building with rpath, try to link non-standard libs that way too.
1738 if test "$DFT_LWR_MODEL" = "shared"; then
1739   CF_RPATH_HACK
1740 fi
1741
1742 ### Define substitutions for header files to avoid name-pollution
1743 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1744 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1745 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1746
1747 ################################################################################
1748 test "$use_database" = yes && SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1749 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1750 AC_OUTPUT( \
1751         include/MKterm.h.awk \
1752         include/curses.head:include/curses.h.in \
1753         include/termcap.h \
1754         include/unctrl.h \
1755         $SUB_MAKEFILES \
1756         Makefile,[
1757 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1758 CF_LIB_RULES($SRC_SUBDIRS)
1759 ],[
1760 ### Special initialization commands, used to pass information from the
1761 ### configuration-run into config.status
1762
1763 AWK="$AWK"
1764 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1765 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1766 ECHO_LINK="$ECHO_LINK"
1767 LDCONFIG="$LDCONFIG"
1768 LIB_NAME="$LIB_NAME"
1769 LIB_SUBSETS="$LIB_SUBSETS"
1770 LIB_SUFFIX="$LIB_SUFFIX"
1771 LIB_TRACING="$LIB_TRACING"
1772 MAKE_TERMINFO="$MAKE_TERMINFO"
1773 NCURSES_MAJOR="$NCURSES_MAJOR"
1774 NCURSES_MINOR="$NCURSES_MINOR"
1775 NCURSES_OSPEED="$NCURSES_OSPEED"
1776 NCURSES_PATCH="$NCURSES_PATCH"
1777 SRC_SUBDIRS="$SRC_SUBDIRS"
1778 TERMINFO="$TERMINFO"
1779 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1780 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1781 TINFO_NAME="$TINFO_NAME"
1782 TINFO_SUFFIX="$TINFO_SUFFIX"
1783 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1784 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1785 TICS_NAME="$TICS_NAME"
1786 WITH_CURSES_H="$with_curses_h"
1787 WITH_ECHO="$with_echo"
1788 WITH_OVERWRITE="$with_overwrite"
1789 cf_LIST_MODELS="$cf_list_models"
1790 cf_cv_abi_version="$cf_cv_abi_version"
1791 cf_cv_do_relink="$cf_cv_do_relink"
1792 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1793 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1794 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1795 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1796 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1797 cf_cv_rel_version="$cf_cv_rel_version"
1798 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1799 cf_cv_shlib_version="$cf_cv_shlib_version"
1800 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1801 cf_cv_system_name="$cf_cv_system_name"
1802 cf_with_cxx_binding="$cf_with_cxx_binding"
1803 host="$host"
1804 target="$target"
1805
1806 ],cat)dnl
1807 ${MAKE-make} preinstall