configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2006,2007 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.395 2007/02/10 22:47:04 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.395 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to build programs such as tic)
 126 AC_ARG_WITH(progs,
 127         [  --without-progs         suppress build with programs (e.g., tic)],
 128         [cf_with_progs=$withval],
 129         [cf_with_progs=yes])
 130 AC_MSG_RESULT($cf_with_progs)
 131
 132 AC_MSG_CHECKING(if you wish to install curses.h)
 133 AC_ARG_WITH(curses-h,
 134         [  --without-curses-h      install curses.h as ncurses.h only],
 135         [with_curses_h=$withval],
 136         [with_curses_h=yes])
 137 AC_MSG_RESULT($with_curses_h)
 138
 139 modules_to_build="ncurses"
 140 if test "X$cf_with_progs" != Xno ; then
 141 modules_to_build="$modules_to_build progs tack"
 142 fi
 143 modules_to_build="$modules_to_build panel menu form"
 144
 145 AC_ARG_PROGRAM
 146
 147 CF_PROG_AWK
 148 CF_PROG_EGREP
 149 CF_PROG_INSTALL
 150 CF_PROG_LINT
 151 AC_PROG_LN_S
 152
 153 AC_PROG_MAKE_SET
 154 CF_MAKE_TAGS
 155 CF_MAKEFLAGS
 156
 157 AC_SYS_LONG_FILE_NAMES
 158 CF_MIXEDCASE_FILENAMES
 159
 160 dnl These are standard among *NIX systems, but not when cross-compiling
 161 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 162 AC_CHECK_TOOL(LD, ld, ld)
 163 AC_CHECK_TOOL(AR, ar, ar)
 164 CF_SUBST(archiver options,AR_OPTS,rv)
 165
 166 dnl Special option for use by system-builders: the install-prefix is used to
 167 dnl adjust the location into which the actual install is done, so that an
 168 dnl archive can be built without modifying the host system's configuration.
 169 AC_MSG_CHECKING(if you have specified an install-prefix)
 170 AC_ARG_WITH(install-prefix,
 171         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 172         [case "$withval" in #(vi
 173         yes|no) #(vi
 174                 ;;
 175         *)      DESTDIR="$withval"
 176                 ;;
 177         esac])
 178 AC_MSG_RESULT($DESTDIR)
 179 AC_SUBST(DESTDIR)
 180
 181 ###############################################################################
 182 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 183 # If we're cross-compiling, allow the user to override the tools and their
 184 # options.  The configure script is oriented toward identifying the host
 185 # compiler, etc., but we need a build compiler to generate parts of the source.
 186 CF_BUILD_CC
 187
 188 ###############################################################################
 189 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 190
 191 ### Options to allow the user to specify the set of libraries which are used.
 192 ### Use "--without-normal --with-shared" to allow the default model to be
 193 ### shared, for example.
 194 cf_list_models=""
 195 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 196
 197 CF_WITH_LIBTOOL
 198 if test "$with_libtool" != "no" ; then
 199
 200 cf_list_models="$cf_list_models libtool"
 201
 202 else
 203
 204 AC_MSG_CHECKING(if you want to build shared libraries)
 205 AC_ARG_WITH(shared,
 206         [  --with-shared           generate shared-libraries],
 207         [with_shared=$withval],
 208         [with_shared=no])
 209 AC_MSG_RESULT($with_shared)
 210 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 211
 212 AC_MSG_CHECKING(if you want to build static libraries)
 213 AC_ARG_WITH(normal,
 214         [  --with-normal           generate normal-libraries (default)],
 215         [with_normal=$withval],
 216         [with_normal=yes])
 217 AC_MSG_RESULT($with_normal)
 218 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 219
 220 AC_MSG_CHECKING(if you want to build debug libraries)
 221 AC_ARG_WITH(debug,
 222         [  --with-debug            generate debug-libraries (default)],
 223         [with_debug=$withval],
 224         [with_debug=yes])
 225 AC_MSG_RESULT($with_debug)
 226 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 227
 228 AC_MSG_CHECKING(if you want to build profiling libraries)
 229 AC_ARG_WITH(profile,
 230         [  --with-profile          generate profile-libraries],
 231         [with_profile=$withval],
 232         [with_profile=no])
 233 AC_MSG_RESULT($with_profile)
 234 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 235
 236 fi
 237
 238 ###############################################################################
 239
 240 AC_MSG_CHECKING(for specified models)
 241 test -z "$cf_list_models" && cf_list_models=normal
 242 dnl If we use libtool to generate libraries, then it must be the only
 243 dnl specified model.
 244 test "$with_libtool" != "no" && cf_list_models=libtool
 245 AC_MSG_RESULT($cf_list_models)
 246
 247 ### Use the first model as the default, and save its suffix for use in building
 248 ### up test-applications.
 249 AC_MSG_CHECKING(for default model)
 250 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 251 AC_MSG_RESULT($DFT_LWR_MODEL)
 252
 253 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 254
 255 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 256 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 257
 258 TICS_NAME=tic
 259 AC_SUBST(TICS_NAME)
 260
 261 TINFO_NAME=tinfo
 262 AC_SUBST(TINFO_NAME)
 263
 264 LIB_NAME=ncurses
 265 AC_SUBST(LIB_NAME)
 266
 267 LIB_DIR=../lib
 268 LIB_2ND=../../lib
 269
 270 CF_LIB_PREFIX(cf_prefix)
 271 LIB_PREFIX=$cf_prefix
 272 AC_SUBST(LIB_PREFIX)
 273
 274 LIB_SUFFIX=
 275 AC_SUBST(LIB_SUFFIX)
 276
 277 ###############################################################################
 278
 279 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 280 AC_ARG_WITH(termlib,
 281         [  --with-termlib          generate separate terminfo library],
 282         [with_termlib=$withval],
 283         [with_termlib=no])
 284 AC_MSG_RESULT($with_termlib)
 285
 286 AC_MSG_CHECKING(if you want to build a separate tic library)
 287 AC_ARG_WITH(ticlib,
 288         [  --with-ticlib           generate separate tic library],
 289         [with_ticlib=$withval],
 290         [with_ticlib=no])
 291 AC_MSG_RESULT($with_ticlib)
 292
 293 ### Checks for special libraries, must be done up-front.
 294 SHLIB_LIST=""
 295 CF_WITH_GPM
 296 if test "$with_gpm" != no ; then
 297         AC_MSG_CHECKING(if you want to load GPM dynamically)
 298         AC_ARG_WITH(dlsym,
 299                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 300                 [with_dlsym=$withval],
 301                 [with_dlsym=yes])
 302         AC_MSG_RESULT($with_dlsym)
 303         if test "$with_dlsym" = yes ; then
 304                 CF_FUNC_DLSYM
 305                 if test "$with_gpm" != yes ; then
 306                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 307                         cf_cv_gpm_soname="$with_gpm"
 308                 else
 309                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 310                 fi
 311                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 312                 SHLIB_LIST="-ldl $SHLIB_LIST"
 313         else
 314                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 315         fi
 316         AC_DEFINE(HAVE_LIBGPM)
 317         AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 318                 AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 319         ])
 320 fi
 321
 322 CF_WITH_SYSMOUSE
 323
 324 dnl Not all ports of gcc support the -g option
 325
 326 if test X"$CC_G_OPT" = X"" ; then
 327         CC_G_OPT='-g'
 328         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 329 fi
 330 AC_SUBST(CC_G_OPT)
 331
 332 if test X"$CXX_G_OPT" = X"" ; then
 333         CXX_G_OPT='-g'
 334         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 335 fi
 336 AC_SUBST(CXX_G_OPT)
 337
 338 AC_MSG_CHECKING(for default loader flags)
 339 case $DFT_LWR_MODEL in
 340 libtool) LD_MODEL=''   ;;
 341 normal)  LD_MODEL=''   ;;
 342 debug)   LD_MODEL=$CC_G_OPT ;;
 343 profile) LD_MODEL='-pg';;
 344 shared)  LD_MODEL=''   ;;
 345 esac
 346 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 347 AC_MSG_RESULT($LD_MODEL)
 348
 349 case $DFT_LWR_MODEL in
 350 shared)
 351 AC_MSG_CHECKING(if rpath option should be used)
 352 AC_ARG_ENABLE(rpath,
 353 [  --enable-rpath          use rpath option when generating shared libraries],
 354 [cf_cv_ld_rpath=$enableval],
 355 [cf_cv_ld_rpath=no])
 356 AC_MSG_RESULT($cf_cv_ld_rpath)
 357         ;;
 358 esac
 359
 360 CF_SHARED_OPTS
 361 if test "$CC_SHARED_OPTS" = "unknown"; then
 362         for model in $cf_list_models; do
 363                 if test "$model" = "shared"; then
 364                         AC_ERROR(Shared libraries are not supported in this version)
 365                 fi
 366         done
 367 fi
 368
 369 ###############################################################################
 370 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 371
 372 ###     use option --disable-overwrite to leave out the link to -lcurses
 373 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 374 AC_ARG_ENABLE(overwrite,
 375         [  --disable-overwrite     leave out the link to -lcurses],
 376         [with_overwrite=$enableval],
 377         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 378 AC_MSG_RESULT($with_overwrite)
 379
 380 AC_MSG_CHECKING(if external terminfo-database is used)
 381 AC_ARG_ENABLE(database,
 382         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 383         [use_database=$enableval],
 384         [use_database=yes])
 385 AC_MSG_RESULT($use_database)
 386
 387 case $host_os in #(vi
 388 os2*) #(vi
 389         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 390         ;;
 391 *) #(vi
 392         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 393         ;;
 394 esac
 395 AC_SUBST(TERMINFO_SRC)
 396
 397 CF_PATHSEP
 398 if test "$use_database" != no ; then
 399         AC_DEFINE(USE_DATABASE)
 400
 401         AC_MSG_CHECKING(which terminfo source-file will be installed)
 402         AC_ARG_ENABLE(database,
 403                 [  --with-database=XXX     specify terminfo source to install],
 404                 [TERMINFO_SRC=$withval])
 405         AC_MSG_RESULT($TERMINFO_SRC)
 406
 407         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 408         AC_ARG_WITH(hashed-db,
 409                 [  --with-hashed-db        specify hashed-database library],,
 410                 [with_hashed_db=no])
 411         AC_MSG_RESULT($with_hashed_db)
 412 fi
 413
 414 AC_MSG_CHECKING(for list of fallback descriptions)
 415 AC_ARG_WITH(fallbacks,
 416         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 417         [with_fallback=$withval],
 418         [with_fallback=])
 419 AC_MSG_RESULT($with_fallback)
 420 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 421 AC_SUBST(FALLBACK_LIST)
 422
 423 AC_MSG_CHECKING(if you want modern xterm or antique)
 424 AC_ARG_WITH(xterm-new,
 425         [  --without-xterm-new     specify if xterm terminfo should be old version],
 426         [with_xterm_new=$withval],
 427         [with_xterm_new=yes])
 428 case $with_xterm_new in
 429 no)     with_xterm_new=xterm-old;;
 430 *)      with_xterm_new=xterm-new;;
 431 esac
 432 AC_MSG_RESULT($with_xterm_new)
 433 WHICH_XTERM=$with_xterm_new
 434 AC_SUBST(WHICH_XTERM)
 435
 436 MAKE_TERMINFO=
 437 if test "$use_database" = no ; then
 438         TERMINFO="${datadir}/terminfo"
 439         MAKE_TERMINFO="#"
 440 else
 441
 442 AC_MSG_CHECKING(for list of terminfo directories)
 443 CF_WITH_PATHLIST(terminfo-dirs,
 444         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 445         TERMINFO_DIRS,
 446         DATADIR/terminfo,
 447         ${datadir}/terminfo)
 448 AC_MSG_RESULT($TERMINFO_DIRS)
 449 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 450
 451 AC_MSG_CHECKING(for default terminfo directory)
 452 CF_WITH_PATH(default-terminfo-dir,
 453         [  --with-default-terminfo-dir=DIR default terminfo directory],
 454         TERMINFO,
 455         DATADIR/terminfo,
 456         ${datadir}/terminfo)
 457 AC_MSG_RESULT($TERMINFO)
 458 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 459
 460 fi
 461
 462 AC_SUBST(TERMINFO)
 463 AC_SUBST(MAKE_TERMINFO)
 464
 465 ###     use option --disable-big-core to make tic run on small machines
 466 ###     We need 4Mb, check if we can allocate 50% more than that.
 467 AC_MSG_CHECKING(if big-core option selected)
 468 AC_ARG_ENABLE(big-core,
 469         [  --disable-big-core      assume machine has little memory],
 470         [with_big_core=$enableval],
 471         [AC_TRY_RUN([
 472 #include <stdlib.h>
 473 #include <string.h>
 474 int main() {
 475         unsigned long n = 6000000L;
 476         char *s = malloc(n);
 477         if (s != 0)
 478                 s[0] = s[n-1] = 0;
 479         ${cf_cv_main_return:-return}(s == 0);
 480 }],
 481         [with_big_core=yes],
 482         [with_big_core=no],
 483         [with_big_core=no])])
 484 AC_MSG_RESULT($with_big_core)
 485 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 486
 487 ###     use option --enable-termcap to compile in the termcap fallback support
 488 AC_MSG_CHECKING(if you want termcap-fallback support)
 489 AC_ARG_ENABLE(termcap,
 490         [  --enable-termcap        compile in termcap fallback support],
 491         [with_termcap=$enableval],
 492         [with_termcap=no])
 493 AC_MSG_RESULT($with_termcap)
 494
 495 if test "$with_termcap" != "yes" ; then
 496         if test "$use_database" = no ; then
 497                 if test -z "$with_fallback" ; then
 498                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 499                 fi
 500         fi
 501         AC_DEFINE(PURE_TERMINFO)
 502 else
 503
 504 if test "$with_ticlib" != no ; then
 505         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 506 fi
 507
 508 AC_DEFINE(USE_TERMCAP)
 509 AC_MSG_CHECKING(for list of termcap files)
 510 CF_WITH_PATHLIST(termpath,
 511         [  --with-termpath=XXX     specify list of termcap files],
 512         TERMPATH,
 513         /etc/termcap:/usr/share/misc/termcap)
 514 AC_MSG_RESULT($TERMPATH)
 515 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 516
 517 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 518 AC_MSG_CHECKING(if fast termcap-loader is needed)
 519 AC_ARG_ENABLE(getcap,
 520         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 521         [with_getcap=$enableval],
 522         [with_getcap=no])
 523 AC_MSG_RESULT($with_getcap)
 524 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 525
 526 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 527 AC_ARG_ENABLE(getcap-cache,
 528         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 529         [with_getcap_cache=$enableval],
 530         [with_getcap_cache=no])
 531 AC_MSG_RESULT($with_getcap_cache)
 532 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 533
 534 fi
 535
 536 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 537 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 538 AC_ARG_ENABLE(home-terminfo,
 539         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 540         [with_home_terminfo=$enableval],
 541         [with_home_terminfo=yes])
 542 AC_MSG_RESULT($with_home_terminfo)
 543 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 544
 545 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 546 AC_ARG_ENABLE(root-environ,
 547         [  --disable-root-environ  restrict environment when running as root],
 548         [with_root_environ=$enableval],
 549         [with_root_environ=yes])
 550 AC_MSG_RESULT($with_root_environ)
 551 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 552
 553 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 554 ###   to reduce storage requirements for the terminfo database.
 555 CF_LINK_FUNCS
 556
 557 with_links=no
 558 with_symlinks=no
 559
 560 # soft links (symbolic links) are useful for some systems where hard links do
 561 # not work, or to make it simpler to copy terminfo trees around.
 562 if test "$ac_cv_func_symlink" = yes ; then
 563     AC_MSG_CHECKING(if tic should use symbolic links)
 564     AC_ARG_ENABLE(symlinks,
 565         [  --enable-symlinks       make tic use symbolic links not hard links],
 566         [with_symlinks=$enableval],
 567         [with_symlinks=no])
 568     AC_MSG_RESULT($with_symlinks)
 569 fi
 570
 571 # If we have hard links and did not choose to use soft links instead, there is
 572 # no reason to make this choice optional - use the hard links.
 573 if test "$with_symlinks" = no ; then
 574     AC_MSG_CHECKING(if tic should use hard links)
 575     if test "$ac_cv_func_link" = yes ; then
 576         with_links=yes
 577     else
 578         with_links=no
 579     fi
 580     AC_MSG_RESULT($with_links)
 581 fi
 582
 583 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 584 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 585
 586 ###   use option --enable-broken-linker to force on use of broken-linker support
 587 AC_MSG_CHECKING(if you want broken-linker support code)
 588 AC_ARG_ENABLE(broken_linker,
 589         [  --enable-broken_linker  compile with broken-linker support code],
 590         [with_broken_linker=$enableval],
 591         [with_broken_linker=${BROKEN_LINKER-no}])
 592 AC_MSG_RESULT($with_broken_linker)
 593
 594 BROKEN_LINKER=0
 595 if test "$with_broken_linker" = yes ; then
 596         AC_DEFINE(BROKEN_LINKER)
 597         BROKEN_LINKER=1
 598 elif test "$DFT_LWR_MODEL" = shared ; then
 599         case $cf_cv_system_name in #(vi
 600         cygwin*)
 601                 AC_DEFINE(BROKEN_LINKER)
 602                 BROKEN_LINKER=1
 603                 CF_VERBOSE(cygwin linker is broken anyway)
 604                 ;;
 605         esac
 606 fi
 607 AC_SUBST(BROKEN_LINKER)
 608
 609 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 610 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 611 AC_ARG_ENABLE(bsdpad,
 612         [  --enable-bsdpad         recognize BSD-style prefix padding],
 613         [with_bsdpad=$enableval],
 614         [with_bsdpad=no])
 615 AC_MSG_RESULT($with_bsdpad)
 616 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 617
 618 ###   use option --enable-widec to turn on use of wide-character support
 619 NCURSES_CH_T=chtype
 620 NCURSES_LIBUTF8=0
 621
 622 NEED_WCHAR_H=0
 623 NCURSES_MBSTATE_T=0
 624 NCURSES_WCHAR_T=0
 625 NCURSES_WINT_T=0
 626
 627 # Check to define _XOPEN_SOURCE "automatically"
 628 CF_XOPEN_SOURCE
 629
 630 # Work around breakage on OS X
 631 CF_SIGWINCH
 632
 633 # Checks for CODESET support.
 634 AM_LANGINFO_CODESET
 635
 636 # use these variables to work around a defect in gcc's fixincludes.
 637 NCURSES_OK_WCHAR_T=
 638 NCURSES_OK_WINT_T=
 639
 640 AC_MSG_CHECKING(if you want wide-character code)
 641 AC_ARG_ENABLE(widec,
 642         [  --enable-widec          compile with wide-char/UTF-8 code],
 643         [with_widec=$enableval],
 644         [with_widec=no])
 645 AC_MSG_RESULT($with_widec)
 646 if test "$with_widec" = yes ; then
 647         LIB_SUFFIX="w${LIB_SUFFIX}"
 648         AC_DEFINE(USE_WIDEC_SUPPORT)
 649         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 650         # with_overwrite=no
 651         NCURSES_CH_T=cchar_t
 652         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc)
 653         if test "$ac_cv_func_putwc" != yes ; then
 654                 CF_LIBUTF8
 655                 if test "$cf_cv_libutf8" = yes ; then
 656                         NCURSES_LIBUTF8=1
 657                 fi
 658         fi
 659         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 660         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 661         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 662
 663         if test "$NCURSES_MBSTATE_T" != 0; then
 664                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 665         fi
 666 fi
 667 AC_SUBST(NCURSES_CH_T)
 668 AC_SUBST(NCURSES_LIBUTF8)
 669
 670 AC_SUBST(NEED_WCHAR_H)
 671 AC_SUBST(NCURSES_MBSTATE_T)
 672 AC_SUBST(NCURSES_WCHAR_T)
 673 AC_SUBST(NCURSES_WINT_T)
 674
 675 AC_SUBST(NCURSES_OK_WCHAR_T)
 676 AC_SUBST(NCURSES_OK_WINT_T)
 677
 678 ###   use option --disable-lp64 to allow long chtype
 679 case $cf_cv_abi_version in
 680 [[345]]*)
 681         default_with_lp64=no
 682         ;;
 683 *)
 684         default_with_lp64=yes
 685         ;;
 686 esac
 687
 688 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 689 AC_ARG_ENABLE(lp64,
 690         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 691         [with_lp64=$enableval],
 692         [with_lp64=$default_with_lp64])
 693 AC_MSG_RESULT($with_lp64)
 694
 695 if test "$with_lp64" = yes ; then
 696         cf_cv_enable_lp64=1
 697 else
 698         cf_cv_enable_lp64=0
 699 fi
 700 AC_SUBST(cf_cv_enable_lp64)
 701
 702 CF_LARGEFILE
 703
 704 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 705 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 706 AC_ARG_ENABLE(tparm-varargs,
 707         [  --disable-tparm-varargs compile tparm() without varargs interface],
 708         [with_tparm_varargs=$enableval],
 709         [with_tparm_varargs=yes])
 710 AC_MSG_RESULT($with_tparm_varargs)
 711 NCURSES_TPARM_VARARGS=0
 712 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 713 AC_SUBST(NCURSES_TPARM_VARARGS)
 714
 715 ###   use option --with-bool to override bool's type
 716 AC_MSG_CHECKING(for type of bool)
 717 AC_ARG_WITH(bool,
 718         [  --with-bool=TYPE        override fallback type of bool variable],
 719         [NCURSES_BOOL="$withval"],
 720         [NCURSES_BOOL=auto])
 721 AC_MSG_RESULT($NCURSES_BOOL)
 722 AC_SUBST(NCURSES_BOOL)
 723
 724 AC_MSG_CHECKING(for alternate terminal capabilities file)
 725 AC_ARG_WITH(caps,
 726         [  --with-caps=alt         compile with alternate Caps file],
 727         [TERMINFO_CAPS=Caps.$withval],
 728         [TERMINFO_CAPS=Caps])
 729 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 730 AC_MSG_RESULT($TERMINFO_CAPS)
 731 AC_SUBST(TERMINFO_CAPS)
 732
 733 ###   use option --with-chtype to override chtype's type
 734 AC_MSG_CHECKING(for type of chtype)
 735 AC_ARG_WITH(chtype,
 736         [  --with-chtype=TYPE      override type of chtype],
 737         [NCURSES_CHTYPE="$withval"],
 738         [NCURSES_CHTYPE=auto])
 739 AC_MSG_RESULT($NCURSES_CHTYPE)
 740
 741 ###   use option --with-ospeed to override ospeed's type
 742 AC_MSG_CHECKING(for type of ospeed)
 743 AC_ARG_WITH(ospeed,
 744         [  --with-ospeed=TYPE      override type of ospeed variable],
 745         [NCURSES_OSPEED="$withval"],
 746         [NCURSES_OSPEED=short])
 747 AC_MSG_RESULT($NCURSES_OSPEED)
 748 AC_SUBST(NCURSES_OSPEED)
 749
 750 ###   use option --with-mmask-t to override mmask_t's type
 751 AC_MSG_CHECKING(for type of mmask_t)
 752 AC_ARG_WITH(mmask-t,
 753         [  --with-mmask-t=TYPE     override type of mmask_t],
 754         [NCURSES_MMASK_T="$withval"],
 755         [NCURSES_MMASK_T=auto])
 756 AC_MSG_RESULT($NCURSES_MMASK_T)
 757
 758 ### Enable compiling-in rcs id's
 759 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 760 AC_ARG_WITH(rcs-ids,
 761         [  --with-rcs-ids          compile-in RCS identifiers],
 762         [with_rcs_ids=$withval],
 763         [with_rcs_ids=no])
 764 AC_MSG_RESULT($with_rcs_ids)
 765 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 766
 767 ###############################################################################
 768 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tic toe tput ])
 769
 770 ###############################################################################
 771 CF_HELP_MESSAGE(Extensions:)
 772
 773 ### Note that some functions (such as const) are normally disabled anyway.
 774 AC_MSG_CHECKING(if you want to build with function extensions)
 775 AC_ARG_ENABLE(ext-funcs,
 776         [  --disable-ext-funcs     disable function-extensions],
 777         [with_ext_funcs=$enableval],
 778         [with_ext_funcs=yes])
 779 AC_MSG_RESULT($with_ext_funcs)
 780 if test "$with_ext_funcs" = yes ; then
 781         NCURSES_EXT_FUNCS=1
 782         AC_DEFINE(HAVE_CURSES_VERSION)
 783         AC_DEFINE(HAVE_HAS_KEY)
 784         AC_DEFINE(HAVE_RESIZETERM)
 785         AC_DEFINE(HAVE_RESIZE_TERM)
 786         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 787         AC_DEFINE(HAVE_WRESIZE)
 788         AC_DEFINE(NCURSES_EXT_FUNCS)
 789 else
 790         NCURSES_EXT_FUNCS=0
 791 fi
 792 AC_SUBST(NCURSES_EXT_FUNCS)
 793
 794 ###   use option --enable-const to turn on use of const beyond that in XSI.
 795 AC_MSG_CHECKING(for extended use of const keyword)
 796 AC_ARG_ENABLE(const,
 797         [  --enable-const          compile with extra/non-standard const],
 798         [with_ext_const=$enableval],
 799         [with_ext_const=no])
 800 AC_MSG_RESULT($with_ext_const)
 801 NCURSES_CONST='/*nothing*/'
 802 if test "$with_ext_const" = yes ; then
 803         NCURSES_CONST=const
 804 fi
 805 AC_SUBST(NCURSES_CONST)
 806
 807 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 808 AC_ARG_ENABLE(no-padding,
 809         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 810         [with_no_padding=$enableval],
 811         [with_no_padding=$with_ext_funcs])
 812 AC_MSG_RESULT($with_no_padding)
 813 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 814
 815 AC_CHECK_SIZEOF([signed char], 0)
 816 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 817         NCURSES_SBOOL="signed char"
 818 else
 819         NCURSES_SBOOL="char"
 820 fi
 821 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 822 AC_ARG_ENABLE(signed-char,
 823         [  --enable-signed-char    compile with SIGWINCH handler],
 824         [with_signed_char=$enableval],
 825         [with_signed_char=no])
 826 AC_MSG_RESULT($with_signed_char)
 827 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
 828 AC_SUBST(NCURSES_SBOOL)
 829
 830 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
 831 AC_MSG_CHECKING(if you want SIGWINCH handler)
 832 AC_ARG_ENABLE(sigwinch,
 833         [  --enable-sigwinch       compile with SIGWINCH handler],
 834         [with_sigwinch=$enableval],
 835         [with_sigwinch=$with_ext_funcs])
 836 AC_MSG_RESULT($with_sigwinch)
 837 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
 838
 839 ###   use option --enable-tcap-names to allow user to define new capabilities
 840 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
 841 AC_ARG_ENABLE(tcap-names,
 842         [  --enable-tcap-names     compile with user-definable terminal capabilities],
 843         [with_tcap_names=$enableval],
 844         [with_tcap_names=$with_ext_funcs])
 845 AC_MSG_RESULT($with_tcap_names)
 846 NCURSES_XNAMES=0
 847 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
 848 AC_SUBST(NCURSES_XNAMES)
 849
 850 ###############################################################################
 851 # These options are relatively safe to experiment with.
 852 CF_HELP_MESSAGE(Development Code:)
 853 AC_MSG_CHECKING(if you want all development code)
 854 AC_ARG_WITH(develop,
 855         [  --without-develop       disable development options],
 856         [with_develop=$withval],
 857         [with_develop=no])
 858 AC_MSG_RESULT($with_develop)
 859
 860 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
 861 AC_MSG_CHECKING(if you want hard-tabs code)
 862 AC_ARG_ENABLE(hard-tabs,
 863         [  --enable-hard-tabs      compile with hard-tabs code],,
 864         [enable_hard_tabs=$with_develop])
 865 AC_MSG_RESULT($enable_hard_tabs)
 866 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
 867
 868 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
 869 AC_MSG_CHECKING(if you want limited support for xmc)
 870 AC_ARG_ENABLE(xmc-glitch,
 871         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
 872         [enable_xmc_glitch=$with_develop])
 873 AC_MSG_RESULT($enable_xmc_glitch)
 874 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
 875
 876 ###############################################################################
 877 # These are just experimental, probably should not be in a package:
 878 CF_HELP_MESSAGE(Experimental Code:)
 879
 880 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
 881 AC_ARG_ENABLE(assumed-color,
 882         [  --disable-assumed-color do not assume anything about default-colors],
 883         [with_assumed_color=$enableval],
 884         [with_assumed_color=yes])
 885 AC_MSG_RESULT($with_assumed_color)
 886 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
 887
 888 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
 889 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
 890 AC_ARG_ENABLE(hashmap,
 891         [  --disable-hashmap       compile without hashmap scrolling-optimization],
 892         [with_hashmap=$enableval],
 893         [with_hashmap=yes])
 894 AC_MSG_RESULT($with_hashmap)
 895 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
 896
 897 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
 898 AC_MSG_CHECKING(if you want colorfgbg code)
 899 AC_ARG_ENABLE(colorfgbg,
 900         [  --enable-colorfgbg      compile with $COLORFGBG code],
 901         [with_colorfgbg=$enableval],
 902         [with_colorfgbg=no])
 903 AC_MSG_RESULT($with_colorfgbg)
 904 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
 905
 906 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 907 AC_MSG_CHECKING(if you want to use experimental extended colors)
 908 AC_ARG_ENABLE(ext-colors,
 909         [  --enable-ext-colors     compile for experimental 256-color support],
 910         [with_ext_colors=$enableval],
 911         [with_ext_colors=no])
 912 AC_MSG_RESULT($with_ext_colors)
 913 NCURSES_EXT_COLORS=0
 914 if test "$with_ext_colors" = yes ; then
 915         if test "$with_widec" != yes ; then
 916                 AC_MSG_WARN(This option applies only to wide-character library)
 917         else
 918                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 919                 CF_NCURSES_ABI_6
 920         fi
 921         NCURSES_EXT_COLORS=1
 922         AC_DEFINE(NCURSES_EXT_COLORS)
 923 fi
 924 AC_SUBST(NCURSES_EXT_COLORS)
 925
 926 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 927 AC_MSG_CHECKING(if you want to use experimental extended mouse encoding)
 928 AC_ARG_ENABLE(ext-mouse,
 929         [  --enable-ext-mouse      compile for experimental mouse-encoding],
 930         [with_ext_mouse=$enableval],
 931         [with_ext_mouse=no])
 932 AC_MSG_RESULT($with_ext_mouse)
 933 NCURSES_MOUSE_VERSION=1
 934 if test "$with_ext_mouse" = yes ; then
 935         NCURSES_MOUSE_VERSION=2
 936         CF_NCURSES_ABI_6
 937 fi
 938 AC_SUBST(NCURSES_MOUSE_VERSION)
 939
 940 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
 941 AC_ARG_ENABLE(safe-sprintf,
 942         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
 943         [with_safe_sprintf=$enableval],
 944         [with_safe_sprintf=no])
 945 AC_MSG_RESULT($with_safe_sprintf)
 946 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
 947
 948 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
 949 # when hashmap is used scroll hints are useless
 950 if test "$with_hashmap" = no ; then
 951 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
 952 AC_ARG_ENABLE(scroll-hints,
 953         [  --disable-scroll-hints  compile without scroll-hints code],
 954         [with_scroll_hints=$enableval],
 955         [with_scroll_hints=yes])
 956 AC_MSG_RESULT($with_scroll_hints)
 957 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
 958 fi
 959
 960 AC_MSG_CHECKING(if you want experimental wgetch-events code)
 961 AC_ARG_ENABLE(wgetch-events,
 962         [  --enable-wgetch-events  compile with experimental wgetch-events code],
 963         [with_wgetch_events=$enableval],
 964         [with_wgetch_events=no])
 965 AC_MSG_RESULT($with_wgetch_events)
 966 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
 967
 968 ###############################################################################
 969 CF_HELP_MESSAGE(Testing/development Options:)
 970
 971 ###     use option --disable-echo to suppress full display compiling commands
 972 AC_MSG_CHECKING(if you want to display full commands during build)
 973 AC_ARG_ENABLE(echo,
 974         [  --enable-echo           build: display "compiling" commands (default)],
 975         [with_echo=$enableval],
 976         [with_echo=yes])
 977 if test "$with_echo" = yes; then
 978         ECHO_LINK=
 979 else
 980         ECHO_LINK='@ echo linking $@ ... ;'
 981         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
 982 fi
 983 AC_MSG_RESULT($with_echo)
 984 AC_SUBST(ECHO_LINK)
 985
 986 ###     use option --enable-warnings to turn on all gcc warnings
 987 AC_MSG_CHECKING(if you want to see compiler warnings)
 988 AC_ARG_ENABLE(warnings,
 989         [  --enable-warnings       build: turn on GCC compiler warnings],
 990         [with_warnings=$enableval])
 991 AC_MSG_RESULT($with_warnings)
 992
 993 if test -n "$with_warnings"; then
 994         ADAFLAGS="$ADAFLAGS -gnatg"
 995         CF_GCC_WARNINGS
 996         if test "$cf_with_cxx" = yes ; then
 997                 CF_GXX_WARNINGS(Wno-unused)
 998         fi
 999 fi
1000 CF_GCC_ATTRIBUTES
1001
1002 ###     use option --enable-assertions to turn on generation of assertion code
1003 AC_MSG_CHECKING(if you want to enable runtime assertions)
1004 AC_ARG_ENABLE(assertions,
1005         [  --enable-assertions     test: turn on generation of assertion code],
1006         [with_assertions=$enableval],
1007         [with_assertions=no])
1008 AC_MSG_RESULT($with_assertions)
1009 if test -n "$GCC"
1010 then
1011         if test "$with_assertions" = no
1012         then
1013                 AC_DEFINE(NDEBUG)
1014                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1015         else
1016                 ADAFLAGS="$ADAFLAGS -gnata"
1017         fi
1018 fi
1019
1020 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1021 CF_DISABLE_LEAKS
1022 AC_DEFINE(HAVE_NC_ALLOC_H)
1023
1024 ###     use option --enable-expanded to generate certain macros as functions
1025 AC_ARG_ENABLE(expanded,
1026         [  --enable-expanded       test: generate functions for certain macros],
1027         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1028
1029 ###     use option --disable-macros to suppress macros in favor of functions
1030 AC_ARG_ENABLE(macros,
1031         [  --disable-macros        test: use functions rather than macros],
1032         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1033
1034 # Normally we only add trace() to the debug-library.  Allow this to be
1035 # extended to all models of the ncurses library:
1036 cf_all_traces=no
1037 case "$CFLAGS $CPPFLAGS" in
1038 *-DTRACE*)
1039         cf_all_traces=yes
1040         ;;
1041 esac
1042
1043 AC_MSG_CHECKING(whether to add trace feature to all models)
1044 AC_ARG_WITH(trace,
1045 [  --with-trace            test: add trace() function to all models of ncurses],
1046 [cf_with_trace=$withval],
1047 [cf_with_trace=$cf_all_traces])
1048 AC_MSG_RESULT($cf_with_trace)
1049
1050 if test "$cf_with_trace" = yes ; then
1051         LIB_TRACING=all
1052         ADA_TRACE=TRUE
1053         CF_ADD_CFLAGS(-DTRACE)
1054 else
1055         LIB_TRACING=DEBUG
1056         ADA_TRACE=FALSE
1057 fi
1058
1059 AC_SUBST(ADA_TRACE)
1060
1061 ###     Checks for libraries.
1062 AC_CHECK_FUNC(gettimeofday,
1063         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1064
1065 AC_CHECK_LIB(bsd, gettimeofday,
1066         AC_DEFINE(HAVE_GETTIMEOFDAY)
1067         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
1068
1069 CF_MATH_LIB(MATH_LIB,sin(x))
1070 AC_SUBST(MATH_LIB)
1071
1072 ###     Checks for header files.
1073 AC_STDC_HEADERS
1074 AC_HEADER_DIRENT
1075 AC_HEADER_TIME
1076 CF_REGEX
1077
1078 dnl These are some other potentially nonportable headers.
1079 AC_CHECK_HEADERS( \
1080 fcntl.h \
1081 getopt.h \
1082 limits.h \
1083 locale.h \
1084 poll.h \
1085 sys/bsdtypes.h \
1086 sys/ioctl.h \
1087 sys/param.h \
1088 sys/poll.h \
1089 sys/select.h \
1090 sys/time.h \
1091 sys/times.h \
1092 ttyent.h \
1093 unistd.h \
1094 wctype.h \
1095 )
1096
1097 # check for ISC (this may also define _POSIX_SOURCE)
1098 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1099 if test "$ISC" = yes ; then
1100         AC_CHECK_LIB(cposix,main)
1101         AC_CHECK_LIB(inet,bzero,LIBS="$LIBS -linet")dnl also 'select()'
1102 fi
1103
1104 CF_SYS_TIME_SELECT
1105
1106 ###     checks for compiler characteristics
1107 AC_LANG_C
1108 AC_C_CONST
1109 AC_C_INLINE
1110
1111 NCURSES_INLINE=
1112 if test "$ac_cv_c_inline" != no ; then
1113         AC_DEFINE(CC_HAS_INLINE_FUNCS)
1114         NCURSES_INLINE=inline
1115 fi
1116 AC_SUBST(NCURSES_INLINE)
1117
1118 if test $NCURSES_CHTYPE = auto ; then
1119         CF_TYPEOF_CHTYPE
1120 else
1121         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1122 fi
1123 AC_SUBST(cf_cv_typeof_chtype)
1124
1125 CF_UNSIGNED_LITERALS
1126 cf_cv_1UL="1"
1127 test "$cf_cv_unsigned_literals" = yes && cf_cv_1UL="${cf_cv_1UL}U"
1128 test "$cf_cv_typeof_chtype"    = long && cf_cv_1UL="${cf_cv_1UL}L"
1129 AC_SUBST(cf_cv_1UL)
1130
1131 if test $NCURSES_MMASK_T = auto ; then
1132         cf_cv_typeof_mmask_t=long
1133 else
1134         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1135 fi
1136 AC_SUBST(cf_cv_typeof_mmask_t)
1137
1138 ###     Checks for external-data
1139 CF_ERRNO
1140 CF_LINK_DATAONLY
1141
1142 ###     Checks for library functions.
1143 AC_CHECK_FUNCS( \
1144 getcwd \
1145 getegid \
1146 geteuid \
1147 getttynam \
1148 issetugid \
1149 poll \
1150 remove \
1151 select \
1152 setbuf \
1153 setbuffer \
1154 setvbuf \
1155 sigaction \
1156 sigvec \
1157 strdup \
1158 strstr \
1159 tcgetpgrp \
1160 times \
1161 vsnprintf \
1162 )
1163 if test "$with_getcap" = "yes" ; then
1164         CF_CGETENT
1165 fi
1166
1167 CF_ISASCII
1168 CF_STRUCT_SIGACTION
1169 CF_FUNC_NANOSLEEP
1170 CF_FUNC_TERMIOS
1171 CF_FUNC_VSSCANF
1172 CF_MKSTEMP
1173
1174 # setup for prototype of fallback for vsscanf()
1175 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1176
1177 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1178 if test "$cross_compiling" = yes ; then
1179         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1180 else
1181         AC_FUNC_SETVBUF_REVERSED
1182 fi
1183 AC_TYPE_SIGNAL
1184 CF_TYPE_SIGACTION
1185 CF_SIZECHANGE
1186 CF_FUNC_MEMMOVE
1187 CF_FUNC_POLL
1188
1189 if test "$with_hashed_db" != no ; then
1190         AC_DEFINE(USE_HASHED_DB)
1191         CF_HASHED_DB
1192 fi
1193
1194 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1195 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1196         CF_STRIP_G_OPT(CFLAGS)
1197         CF_STRIP_G_OPT(CXXFLAGS)
1198 fi
1199
1200 # Just in case, check if the C compiler has a bool type.
1201 CF_BOOL_DECL(cf_cv_cc_bool_type)
1202
1203 # Check for C++ compiler characteristics (and ensure that it's there!)
1204 if test -n "$CXX" ; then
1205         AC_LANG_CPLUSPLUS
1206         CF_STDCPP_LIBRARY
1207         CF_PROG_CC_C_O(CXX)
1208
1209         case $GXX_VERSION in
1210         1*|2.[0-6]*)
1211                 cf_cxx_library=yes
1212                 ;;
1213         *-2.7*|2.7*)
1214                 CF_GPP_LIBRARY
1215                 ;;
1216         *)
1217                 cf_cxx_library=no
1218                 ;;
1219         esac
1220
1221         AC_CHECK_HEADERS(typeinfo)
1222
1223         CF_BOOL_DECL
1224         CF_BOOL_SIZE
1225         CF_ETIP_DEFINES
1226         CF_CPP_PARAM_INIT
1227         CF_CPP_STATIC_CAST
1228
1229         CXX_AR='$(AR)'
1230         CXX_AR_OPTS='$(AR_OPTS)'
1231         case $cf_cv_system_name in #(vi
1232         irix*) #(vi
1233             if test "$GXX" != yes ; then
1234                 CXX_AR='$(CXX)'
1235                 CXX_AR_OPTS='-ar -o'
1236             fi
1237             ;;
1238         sco3.2v5*) #(vi
1239             CXXLDFLAGS="-u main"
1240             ;;
1241         solaris2*)
1242             if test "$GXX" != yes ; then
1243                 CXX_AR='$(CXX)'
1244                 CXX_AR_OPTS='-xar -o'
1245             fi
1246             ;;
1247         esac
1248         AC_SUBST(CXXLDFLAGS)
1249         AC_SUBST(CXX_AR)
1250         AC_SUBST(CXX_AR_OPTS)
1251 else
1252         cf_cxx_library=no
1253         cf_cv_builtin_bool=1
1254
1255         # Just because we are not configuring against C++ right now does not
1256         # mean that a user will not want to use C++.  Some distributors disable
1257         # the C++ portion of this configuration as a shortcut (or just to avoid
1258         # compiling the demo in the c++ directory).  So we need a reasonable
1259         # default for the 'bool' type.
1260         #
1261         # Caveat: since the storage of the bool type is not standardized, it
1262         # may change.
1263
1264         if test "$NCURSES_BOOL" != auto ; then
1265                 cf_cv_type_of_bool=$NCURSES_BOOL
1266                 cf_cv_header_stdbool_h=0
1267         else
1268                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1269                         CF_BOOL_SIZE
1270                 else
1271                         AC_MSG_CHECKING(for fallback type of bool)
1272                         case "$host_cpu" in #(vi
1273                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1274                         *)      cf_cv_type_of_bool=int  ;;
1275                         esac
1276                         AC_MSG_RESULT($cf_cv_type_of_bool)
1277                 fi
1278         fi
1279 fi
1280 AC_SUBST(CXXLIBS)
1281
1282 # If the C compiler did not declare bool, and we did not determine that the C++
1283 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1284 # ncurses library use the same type as C++ bool.  Note that this allows one to
1285 # specify the type of bool in a configure-script option and postpone
1286 # integration with the C++ compiler provided that the types are compatible.
1287 USE_CXX_BOOL=1
1288 if test $cf_cv_cc_bool_type = 1
1289 then
1290         # oops: C has a bool.  Unlikely, but C++ could differ.
1291         USE_CXX_BOOL=0
1292 elif test $cf_cv_builtin_bool = 0
1293 then
1294         # C++ has no bool
1295         USE_CXX_BOOL=0
1296 else
1297         # this is the normal case
1298         USE_CXX_BOOL='defined(__cplusplus)'
1299 fi
1300 AC_SUBST(USE_CXX_BOOL)
1301
1302 CF_HELP_MESSAGE(Ada95 Binding Options:)
1303
1304 dnl Check for availability of GNU Ada Translator (GNAT).
1305 dnl At the moment we support no other Ada95 compiler.
1306 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1307 if test "$cf_with_ada" != "no" ; then
1308 cf_ada_make=gnatmake
1309 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
1310 if test "$ac_cv_prog_gnat_exists" = no; then
1311    cf_ada_make=
1312 else
1313    CF_GNAT_VERSION
1314    AC_CHECK_PROG(M4_exists, m4, yes, no)
1315    if test "$ac_cv_prog_M4_exists" = no; then
1316       cf_cv_prog_gnat_correct=no
1317       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
1318    fi
1319    if test "$cf_cv_prog_gnat_correct" = yes; then
1320       AC_MSG_CHECKING(if GNAT works)
1321       CF_GNAT_TRY_RUN([procedure conftest;],
1322 [with Text_IO;
1323 with GNAT.OS_Lib;
1324 procedure conftest is
1325 begin
1326    Text_IO.Put ("Hello World");
1327    Text_IO.New_Line;
1328    GNAT.OS_Lib.OS_Exit (0);
1329 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
1330       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
1331    fi
1332 fi
1333 if test "$cf_cv_prog_gnat_correct" = yes; then
1334    ADAFLAGS="-O3 -gnatpn $ADAFLAGS"
1335
1336    AC_MSG_CHECKING(if GNAT pragma Unreferenced works)
1337    CF_GNAT_TRY_LINK([procedure conftest;],
1338 [with Text_IO;
1339 with GNAT.OS_Lib;
1340 procedure conftest is
1341    test : Integer;
1342    pragma Unreferenced (test);
1343 begin
1344    test := 1;
1345    Text_IO.Put ("Hello World");
1346    Text_IO.New_Line;
1347    GNAT.OS_Lib.OS_Exit (0);
1348 end conftest;],[cf_cv_pragma_unreferenced=yes],[cf_cv_pragma_unreferenced=no])
1349    AC_MSG_RESULT($cf_cv_pragma_unreferenced)
1350
1351    # if the pragma is supported, use it (needed in the Trace code).
1352    if test $cf_cv_pragma_unreferenced = yes ; then
1353       PRAGMA_UNREF=TRUE
1354    else
1355       PRAGMA_UNREF=FALSE
1356    fi
1357
1358    AC_ARG_WITH(ada-compiler,
1359         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
1360         [cf_ada_compiler=$withval],
1361         [cf_ada_compiler=gnatmake])
1362
1363    cf_ada_package=terminal_interface
1364
1365    AC_SUBST(cf_ada_make)
1366    AC_SUBST(cf_ada_compiler)
1367    AC_SUBST(cf_ada_package)
1368    AC_SUBST(ADAFLAGS)
1369    AC_SUBST(cf_compile_generics)
1370    AC_SUBST(cf_generic_objects)
1371    AC_SUBST(PRAGMA_UNREF)
1372
1373    CF_WITH_PATH(ada-include,
1374        [  --with-ada-include=DIR  Ada includes are in DIR],
1375        ADA_INCLUDE,
1376        PREFIX/lib/ada/adainclude,
1377        [$]prefix/lib/ada/adainclude)
1378    AC_SUBST(ADA_INCLUDE)
1379
1380    CF_WITH_PATH(ada-objects,
1381        [  --with-ada-objects=DIR  Ada objects are in DIR],
1382        ADA_OBJECTS,
1383        PREFIX/lib/ada/adalib,
1384        [$]prefix/lib/ada/adalib)
1385    AC_SUBST(ADA_OBJECTS)
1386
1387 fi
1388 fi
1389 fi
1390
1391 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1392 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1393 ###
1394 ### ticlib modules may be a separate library, otherwise contained in termlib.
1395 ### termlib modules may be a separate library, otherwise contained in ncurses.
1396 ###
1397 ### The of "+" or " " between the tokens controls the way the script
1398 ### chooses to split module lists into libraries.
1399 ###
1400 ### (see CF_LIB_RULES).
1401 AC_MSG_CHECKING(for library subsets)
1402 LIB_SUBSETS=
1403
1404 if test "$cf_with_progs" = yes || test "$with_ticlib" != no; then
1405         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1406         if test "$with_ticlib" != no ; then
1407                 LIB_SUBSETS="${LIB_SUBSETS} "
1408         else
1409                 LIB_SUBSETS="${LIB_SUBSETS}+"
1410         fi
1411 fi
1412
1413 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1414 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1415 if test "$with_termlib" != no ; then
1416         LIB_SUBSETS="${LIB_SUBSETS} "
1417 else
1418         LIB_SUBSETS="${LIB_SUBSETS}+"
1419 fi
1420
1421 LIB_SUBSETS="${LIB_SUBSETS}base"
1422 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1423 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1424
1425 AC_MSG_RESULT($LIB_SUBSETS)
1426
1427 ### Construct the list of include-directories to be generated
1428 CF_INCLUDE_DIRS
1429 CF_ADA_INCLUDE_DIRS
1430
1431 ### Build up pieces for makefile rules
1432 AC_MSG_CHECKING(default library suffix)
1433 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1434 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1435 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1436
1437 AC_MSG_CHECKING(default library-dependency suffix)
1438 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_DEP_SUFFIX)dnl
1439 if test $DFT_LWR_MODEL = shared ; then
1440         case $cf_cv_system_name in #(vi
1441         cygwin*)
1442                 DFT_DEP_SUFFIX=".dll.a"
1443                 ;;
1444         esac
1445 fi
1446 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1447 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1448
1449 AC_MSG_CHECKING(default object directory)
1450 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1451 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1452 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1453
1454 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1455 if test "$cf_with_cxx" = yes ; then
1456 AC_MSG_CHECKING(c++ library-dependency suffix)
1457 if test "$with_libtool" != "no"; then
1458         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1459 else
1460         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX)dnl we normally make a static library
1461 fi
1462 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1463 AC_SUBST(CXX_LIB_SUFFIX)
1464 fi
1465
1466 ### Set up low-level terminfo dependencies for makefiles.
1467
1468 # TICS_LIST and TINFO_LIST are needed to build the libtic.so and libterm.so
1469 TICS_LIST="$SHLIB_LIST"
1470 TINFO_LIST=`echo "$SHLIB_LIST" | sed -e 's/-ldl//'`
1471
1472 if test "$with_ticlib" != no ; then
1473
1474         if test "$with_ticlib" != yes ; then
1475                 TICS_NAME=$with_ticlib
1476                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1477                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1478                 TICS_LIB_SUFFIX="${with_ticlib}"
1479         else
1480                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1481                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1482                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1483         fi
1484         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1485 else
1486         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1487 fi
1488 AC_SUBST(TICS_ARG_SUFFIX)
1489 AC_SUBST(TICS_DEP_SUFFIX)
1490 AC_SUBST(TICS_LIB_SUFFIX)
1491 AC_SUBST(TICS_ARGS)
1492
1493 if test "$with_termlib" != no ; then
1494
1495         if test "$with_termlib" != yes ; then
1496                 TINFO_NAME=$with_termlib
1497                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1498                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1499                 TINFO_LIB_SUFFIX="${with_termlib}"
1500         else
1501                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1502                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1503                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1504         fi
1505
1506         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1507         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1508         if test "$DFT_LWR_MODEL" = "libtool"; then
1509                 TEST_ARGS="${TEST_DEPS}"
1510                 TEST_ARG2="${TEST_DEP2}"
1511                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1512         else
1513                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1514                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1515                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1516                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1517         fi
1518 else
1519         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1520 fi
1521 AC_SUBST(TINFO_ARG_SUFFIX)
1522 AC_SUBST(TINFO_DEP_SUFFIX)
1523 AC_SUBST(TINFO_LIB_SUFFIX)
1524 AC_SUBST(TINFO_ARGS)
1525
1526 # needed for Ada95
1527 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1528 AC_SUBST(TINFO_ARGS2)
1529
1530 AC_MSG_CHECKING(where we will install curses.h)
1531 test "$with_overwrite" = no && \
1532 test "x$includedir" = 'x${prefix}/include' && \
1533         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1534 AC_MSG_RESULT($includedir)
1535
1536 ### Resolve a conflict between normal and wide-curses by forcing applications
1537 ### that will need libutf8 to add it to their configure script.
1538 if test "$with_overwrite" != no ; then
1539 if test "$NCURSES_LIBUTF8" = 1 ; then
1540         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1541         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1542 fi
1543 fi
1544
1545 AC_SUBST(WITH_OVERWRITE)
1546 AC_SUBST(TINFO_LIST)
1547 AC_SUBST(SHLIB_LIST)
1548
1549 # used to separate tack out of the tree
1550 NCURSES_TREE=
1551 AC_SUBST(NCURSES_TREE)
1552
1553 ### predefined stuff for the test programs
1554 AC_DEFINE(HAVE_SLK_COLOR)
1555
1556 ### Construct the list of subdirectories for which we'll customize makefiles
1557 ### with the appropriate compile-rules.
1558
1559 CF_SRC_MODULES($modules_to_build)
1560 CF_DIRS_TO_MAKE
1561
1562 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATHSEP')
1563
1564 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1565
1566 ### Now that we're done running tests, add the compiler-warnings, if any
1567 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1568
1569 ### Define substitutions for header files to avoid name-pollution
1570 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1571 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1572 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1573
1574 ################################################################################
1575 test "$use_database" = yes && SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1576 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1577 AC_OUTPUT( \
1578         include/MKterm.h.awk \
1579         include/curses.head:include/curses.h.in \
1580         include/termcap.h \
1581         include/unctrl.h \
1582         $SUB_MAKEFILES \
1583         Makefile,[
1584 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1585 CF_LIB_RULES($SRC_SUBDIRS)
1586 ],[
1587 ### Special initialization commands, used to pass information from the
1588 ### configuration-run into config.status
1589
1590 AWK="$AWK"
1591 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1592 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1593 ECHO_LINK="$ECHO_LINK"
1594 LDCONFIG="$LDCONFIG"
1595 LIB_NAME="$LIB_NAME"
1596 LIB_SUBSETS="$LIB_SUBSETS"
1597 LIB_SUFFIX="$LIB_SUFFIX"
1598 LIB_TRACING="$LIB_TRACING"
1599 MAKE_TERMINFO="$MAKE_TERMINFO"
1600 NCURSES_MAJOR="$NCURSES_MAJOR"
1601 NCURSES_MINOR="$NCURSES_MINOR"
1602 NCURSES_OSPEED="$NCURSES_OSPEED"
1603 NCURSES_PATCH="$NCURSES_PATCH"
1604 SRC_SUBDIRS="$SRC_SUBDIRS"
1605 TERMINFO="$TERMINFO"
1606 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1607 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1608 TINFO_NAME="$TINFO_NAME"
1609 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1610 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1611 TICS_NAME="$TICS_NAME"
1612 WITH_CURSES_H="$with_curses_h"
1613 WITH_ECHO="$with_echo"
1614 WITH_OVERWRITE="$with_overwrite"
1615 cf_LIST_MODELS="$cf_list_models"
1616 cf_cv_abi_version="$cf_cv_abi_version"
1617 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1618 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1619 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1620 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1621 cf_cv_rel_version="$cf_cv_rel_version"
1622 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1623 cf_cv_shlib_version="$cf_cv_shlib_version"
1624 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1625 cf_cv_system_name="$cf_cv_system_name"
1626 cf_with_cxx_binding="$cf_with_cxx_binding"
1627 host="$host"
1628 target="$target"
1629
1630 ],cat)dnl
1631 ${MAKE-make} preinstall