ncurses 5.9 - patch 20140426
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2013,2014 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.579 2014/04/26 20:02:13 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See http://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.52.20030208)
38 AC_REVISION($Revision: 1.579 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44
45 CF_WITH_REL_VERSION(NCURSES)
46 CF_WITH_ABI_VERSION
47
48 CF_WITH_SYSTYPE
49
50 ###     Save the given $CFLAGS to allow user-override.
51 cf_user_CFLAGS="$CFLAGS"
52
53 ###     Default install-location
54 CF_CFG_DEFAULTS
55
56 ###     Checks for programs.
57 AC_ARG_WITH(ada,
58         [  --without-ada           suppress check for Ada95, don't build demo],
59         [cf_with_ada=$withval],
60         [cf_with_ada=yes])
61 if test "x$cf_with_ada" = xyes
62 then
63         cf_PROG_CC="gnatgcc gcc cc"
64 else
65         cf_PROG_CC="gcc cc"
66 fi
67
68 CF_PROG_CC($cf_PROG_CC)
69
70 AC_PROG_CPP
71 AC_PROG_GCC_TRADITIONAL
72 CF_PROG_CC_C_O(CC)
73 CF_PROG_LDCONFIG
74
75 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
76 dnl                             configure script by not letting us test if C++
77 dnl                             is present, making this option necessary.
78 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
79 AC_ARG_WITH(cxx,
80         [  --without-cxx           do not adjust ncurses bool to match C++],
81         [cf_with_cxx=$withval],
82         [cf_with_cxx=yes])
83 AC_MSG_RESULT($cf_with_cxx)
84 if test "X$cf_with_cxx" = Xno ; then
85         CXX=""
86         GXX=""
87 else
88         # with autoconf 2.13, we can change the error to a warning:
89         pushdef([AC_MSG_ERROR],
90                 [AC_MSG_RESULT(no)
91                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
92                 cf_with_cxx=no; CXX=""; GXX="";])dnl
93         AC_PROG_CXX
94         popdef([AC_MSG_ERROR])dnl
95         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
96         if test "$CXX" = "g++" ; then
97                 AC_PATH_PROG(CXX,g++)
98         fi
99         case "x$CXX" in #(vi
100         x|xg++)
101                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
102                 cf_with_cxx=no; CXX=""; GXX="";
103                 ;;
104         esac
105 fi
106
107 CF_GXX_VERSION
108 case $GXX_VERSION in
109 1*|2.[[0-6]]*)
110         # GXX=""; CXX=""; ac_cv_prog_gxx=no
111         # cf_cxx_library=no
112         AC_MSG_WARN(templates do not work)
113         ;;
114 esac
115
116 AC_MSG_CHECKING(if you want to build C++ binding and demo)
117 AC_ARG_WITH(cxx-binding,
118         [  --without-cxx-binding   do not build C++ binding and demo],
119         [cf_with_cxx_binding=$withval],
120         [cf_with_cxx_binding=$cf_with_cxx])
121 AC_MSG_RESULT($cf_with_cxx_binding)
122
123 AC_MSG_CHECKING(if you want to build with Ada95)
124 AC_MSG_RESULT($cf_with_ada)
125
126 AC_MSG_CHECKING(if you want to install terminal database)
127 AC_ARG_ENABLE(db-install,
128         [  --disable-db-install    suppress install of terminal database],
129         [cf_with_db_install=$enableval],
130         [cf_with_db_install=yes])
131 AC_MSG_RESULT($cf_with_db_install)
132
133 AC_MSG_CHECKING(if you want to install manpages)
134 AC_ARG_WITH(manpages,
135         [  --without-manpages      suppress install of manpages],
136         [cf_with_manpages=$withval],
137         [cf_with_manpages=yes])
138 AC_MSG_RESULT($cf_with_manpages)
139
140 AC_MSG_CHECKING(if you want to build programs such as tic)
141 AC_ARG_WITH(progs,
142         [  --without-progs         suppress build/install with programs (e.g., tic)],
143         [cf_with_progs=$withval],
144         [cf_with_progs=yes])
145 AC_MSG_RESULT($cf_with_progs)
146
147 AC_MSG_CHECKING(if you want to build test-programs)
148 AC_ARG_WITH(tests,
149         [  --without-tests         suppress build/install with test-programs],
150         [cf_with_tests=$withval],
151         [cf_with_tests=yes])
152 AC_MSG_RESULT($cf_with_tests)
153
154 AC_MSG_CHECKING(if you wish to install curses.h)
155 AC_ARG_WITH(curses-h,
156         [  --without-curses-h      install curses.h as ncurses.h only],
157         [with_curses_h=$withval],
158         [with_curses_h=yes])
159 AC_MSG_RESULT($with_curses_h)
160
161 modules_to_build="ncurses"
162 if test "X$cf_with_progs" != Xno ; then
163 modules_to_build="$modules_to_build progs tack"
164 fi
165 modules_to_build="$modules_to_build panel menu form"
166
167 AC_ARG_PROGRAM
168
169 CF_PROG_AWK
170 CF_PROG_EGREP
171 CF_PROG_INSTALL
172 CF_PROG_LINT
173 CF_PROG_LN_S
174
175 AC_SYS_LONG_FILE_NAMES
176
177 # if we find pkg-config, check if we should install the ".pc" files.
178 CF_PKG_CONFIG
179 CF_WITH_PKG_CONFIG_LIBDIR
180 CF_ENABLE_PC_FILES
181
182 AC_MSG_CHECKING(if we should assume mixed-case filenames)
183 AC_ARG_ENABLE(mixed-case,
184         [  --enable-mixed-case     tic should assume mixed-case filenames],
185         [enable_mixedcase=$enableval],
186         [enable_mixedcase=auto])
187 AC_MSG_RESULT($enable_mixedcase)
188 if test "$enable_mixedcase" = "auto" ; then
189     CF_MIXEDCASE_FILENAMES
190 else
191     cf_cv_mixedcase=$enable_mixedcase
192     if test "x$enable_mixedcase" = "xyes" ; then
193         AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
194     fi
195 fi
196
197 # do this after mixed-case option (tags/TAGS is not as important as tic).
198 AC_PROG_MAKE_SET
199 CF_MAKE_TAGS
200 CF_MAKEFLAGS
201
202 dnl These are standard among *NIX systems, but not when cross-compiling
203 AC_CHECK_TOOL(RANLIB, ranlib, ':')
204 AC_CHECK_TOOL(LD, ld, ld)
205 AC_CHECK_TOOL(AR, ar, ar)
206 AC_CHECK_TOOL(NM, nm, nm)
207 CF_AR_FLAGS
208
209 dnl Special option for use by system-builders: the install-prefix is used to
210 dnl adjust the location into which the actual install is done, so that an
211 dnl archive can be built without modifying the host system's configuration.
212 AC_MSG_CHECKING(if you have specified an install-prefix)
213 AC_ARG_WITH(install-prefix,
214         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
215         [case "x$withval" in #(vi
216         xyes|xno) #(vi
217                 ;;
218         *)      DESTDIR="$withval"
219                 ;;
220         esac])
221 AC_MSG_RESULT($DESTDIR)
222 AC_SUBST(DESTDIR)
223
224 ###############################################################################
225 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
226 # If we're cross-compiling, allow the user to override the tools and their
227 # options.  The configure script is oriented toward identifying the host
228 # compiler, etc., but we need a build compiler to generate parts of the source.
229 CF_BUILD_CC
230
231 ###############################################################################
232 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
233
234 ### Options to allow the user to specify the set of libraries which are used.
235 ### Use "--without-normal --with-shared" to allow the default model to be
236 ### shared, for example.
237 cf_list_models=""
238 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
239
240 CF_WITH_LIBTOOL
241 if test "$with_libtool" != "no" ; then
242
243 cf_list_models="$cf_list_models libtool"
244
245 else
246
247 AC_MSG_CHECKING(if you want to build shared libraries)
248 AC_ARG_WITH(shared,
249         [  --with-shared           generate shared-libraries],
250         [with_shared=$withval],
251         [with_shared=no])
252 AC_MSG_RESULT($with_shared)
253 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
254
255 AC_MSG_CHECKING(if you want to build static libraries)
256 AC_ARG_WITH(normal,
257         [  --with-normal           generate normal-libraries (default)],
258         [with_normal=$withval],
259         [with_normal=yes])
260 AC_MSG_RESULT($with_normal)
261 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
262
263 AC_MSG_CHECKING(if you want to build debug libraries)
264 AC_ARG_WITH(debug,
265         [  --with-debug            generate debug-libraries (default)],
266         [with_debug=$withval],
267         [with_debug=yes])
268 AC_MSG_RESULT($with_debug)
269 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
270
271 AC_MSG_CHECKING(if you want to build profiling libraries)
272 AC_ARG_WITH(profile,
273         [  --with-profile          generate profile-libraries],
274         [with_profile=$withval],
275         [with_profile=no])
276 AC_MSG_RESULT($with_profile)
277 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
278
279 fi
280
281 if test "X$cf_with_cxx_binding" != Xno; then
282 if test "x$with_shared" = "xyes"; then
283 AC_MSG_CHECKING(if you want to build C++ shared libraries)
284 AC_ARG_WITH(cxx-shared,
285         [  --with-cxx-shared       generate C++ shared-libraries],
286         [with_shared_cxx=$withval],
287         [with_shared_cxx=no])
288 AC_MSG_RESULT($with_shared_cxx)
289 fi
290 fi
291
292 ###############################################################################
293
294 AC_MSG_CHECKING(for specified models)
295 test -z "$cf_list_models" && cf_list_models=normal
296 dnl If we use libtool to generate libraries, then it must be the only
297 dnl specified model.
298 test "$with_libtool" != "no" && cf_list_models=libtool
299 AC_MSG_RESULT($cf_list_models)
300
301 ### Use the first model as the default, and save its suffix for use in building
302 ### up test-applications.
303 AC_MSG_CHECKING(for default model)
304 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
305 AC_MSG_RESULT($DFT_LWR_MODEL)
306
307 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
308
309 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
310 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
311
312 TICS_NAME=tic
313 AC_SUBST(TICS_NAME)
314
315 TINFO_NAME=tinfo
316 AC_SUBST(TINFO_NAME)
317
318 LIB_NAME=ncurses
319 AC_SUBST(LIB_NAME)
320
321 LIB_DIR=../lib
322 LIB_2ND=../../lib
323
324 CF_WITH_LIB_PREFIX(cf_prefix)
325
326 LIB_SUFFIX=
327 AC_SUBST(LIB_SUFFIX)
328 CF_PATHSEP
329
330 ###############################################################################
331
332 AC_MSG_CHECKING(if you want to build a separate terminfo library)
333 AC_ARG_WITH(termlib,
334         [  --with-termlib          generate separate terminfo library],
335         [with_termlib=$withval],
336         [with_termlib=no])
337 AC_MSG_RESULT($with_termlib)
338
339 AC_MSG_CHECKING(if you want to build a separate tic library)
340 AC_ARG_WITH(ticlib,
341         [  --with-ticlib           generate separate tic library],
342         [with_ticlib=$withval],
343         [with_ticlib=no])
344 AC_MSG_RESULT($with_ticlib)
345
346 ### Checks for special libraries, must be done up-front.
347 SHLIB_LIST=""
348 CF_WITH_GPM
349 if test "$with_gpm" != no ; then
350         AC_MSG_CHECKING(if you want to load GPM dynamically)
351         AC_ARG_WITH(dlsym,
352                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
353                 [with_dlsym=$withval],
354                 [with_dlsym=yes])
355         AC_MSG_RESULT($with_dlsym)
356         if test "x$with_dlsym" = xyes ; then
357                 CF_FUNC_DLSYM
358                 if test "x$with_gpm" != xyes ; then
359                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
360                         cf_cv_gpm_soname="$with_gpm"
361                 else
362                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
363                 fi
364                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
365                 SHLIB_LIST="-ldl $SHLIB_LIST"
366         else
367                 SHLIB_LIST="-lgpm $SHLIB_LIST"
368                 CF_ADD_LIB(gpm,TEST_LIBS)
369         fi
370         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
371         CF_CHECK_GPM_WGETCH
372 fi
373
374 CF_WITH_SYSMOUSE
375
376 dnl Not all ports of gcc support the -g option
377
378 if test X"$CC_G_OPT" = X"" ; then
379         CC_G_OPT='-g'
380         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
381 fi
382 AC_SUBST(CC_G_OPT)
383
384 if test X"$CXX_G_OPT" = X"" ; then
385         CXX_G_OPT='-g'
386         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
387 fi
388 AC_SUBST(CXX_G_OPT)
389
390 AC_MSG_CHECKING(for default loader flags)
391 case $DFT_LWR_MODEL in
392 libtool) LD_MODEL=''   ;;
393 normal)  LD_MODEL=''   ;;
394 debug)   LD_MODEL=$CC_G_OPT ;;
395 profile) LD_MODEL='-pg';;
396 shared)  LD_MODEL=''   ;;
397 esac
398 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
399 AC_MSG_RESULT($LD_MODEL)
400
401 case $DFT_LWR_MODEL in
402 shared)
403 CF_ENABLE_RPATH
404 AC_MSG_CHECKING(if shared libraries should be relinked during install)
405 AC_ARG_ENABLE(relink,
406 [  --disable-relink        relink shared libraries during install],
407 [cf_cv_do_relink=$enableval],
408 [cf_cv_do_relink=yes])
409 AC_MSG_RESULT($cf_cv_do_relink)
410         ;;
411 esac
412
413 # we will build libraries one-level down.
414 rel_builddir=..
415 CF_SHARED_OPTS
416 if test "$CC_SHARED_OPTS" = "unknown"; then
417         for model in $cf_list_models; do
418                 if test "$model" = "shared"; then
419                         AC_ERROR(Shared libraries are not supported in this version)
420                 fi
421         done
422 fi
423
424 # pretend that ncurses==ncursesw==ncursest
425 AC_MSG_CHECKING(if you want to disable library suffixes)
426 AC_ARG_ENABLE(lib-suffixes,
427         [  --disable-lib-suffixes  disable library suffixes],
428         [disable_lib_suffixes=$enableval],
429         [disable_lib_suffixes=no])
430 AC_MSG_RESULT($disable_lib_suffixes)
431
432 ### If we're building with rpath, try to link non-standard libs that way too.
433 if test "$DFT_LWR_MODEL" = "shared"; then
434         CF_DISABLE_RPATH_HACK
435 fi
436
437 ###############################################################################
438 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
439
440 ###     use option --disable-overwrite to leave out the link to -lcurses
441 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
442 AC_ARG_ENABLE(overwrite,
443         [  --disable-overwrite     leave out the link to -lcurses],
444         [with_overwrite=$enableval],
445         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
446 AC_MSG_RESULT($with_overwrite)
447
448 AC_MSG_CHECKING(if external terminfo-database is used)
449 AC_ARG_ENABLE(database,
450         [  --disable-database      do not use terminfo, only fallbacks/termcap],
451         [use_database=$enableval],
452         [use_database=yes])
453 AC_MSG_RESULT($use_database)
454
455 case $host_os in #(vi
456 os2*) #(vi
457         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
458         ;;
459 *) #(vi
460         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
461         ;;
462 esac
463 AC_SUBST(TERMINFO_SRC)
464
465 NCURSES_USE_DATABASE=0
466 if test "$use_database" != no ; then
467         NCURSES_USE_DATABASE=1
468
469         AC_MSG_CHECKING(which terminfo source-file will be installed)
470         AC_ARG_WITH(database,
471                 [  --with-database=XXX     specify terminfo source to install],
472                 [TERMINFO_SRC=$withval])
473         AC_MSG_RESULT($TERMINFO_SRC)
474
475         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
476         AC_ARG_WITH(hashed-db,
477                 [  --with-hashed-db        specify hashed-database library],,
478                 [with_hashed_db=no])
479         AC_MSG_RESULT($with_hashed_db)
480 else
481         with_hashed_db=no
482 fi
483 AC_SUBST(NCURSES_USE_DATABASE)
484
485 AC_MSG_CHECKING(for list of fallback descriptions)
486 AC_ARG_WITH(fallbacks,
487         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
488         [with_fallback=$withval],
489         [with_fallback=])
490 AC_MSG_RESULT($with_fallback)
491 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
492 AC_SUBST(FALLBACK_LIST)
493
494 AC_MSG_CHECKING(if you want modern xterm or antique)
495 AC_ARG_WITH(xterm-new,
496         [  --without-xterm-new     specify if xterm terminfo should be old version],
497         [with_xterm_new=$withval],
498         [with_xterm_new=yes])
499 case $with_xterm_new in
500 no)     with_xterm_new=xterm-old;;
501 *)      with_xterm_new=xterm-new;;
502 esac
503 AC_MSG_RESULT($with_xterm_new)
504 WHICH_XTERM=$with_xterm_new
505 AC_SUBST(WHICH_XTERM)
506
507 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
508 AC_ARG_WITH(xterm-kbs,
509         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
510         [with_xterm_kbs=$withval],
511         [with_xterm_kbs=BS])
512 case x$with_xterm_kbs in
513 xyes|xno|xBS|xbs|x8)
514         with_xterm_kbs=BS
515         ;;
516 xDEL|xdel|x127)
517         with_xterm_kbs=DEL
518         ;;
519 *)
520         with_xterm_kbs=$withval
521         ;;
522 esac
523 AC_MSG_RESULT($with_xterm_kbs)
524 XTERM_KBS=$with_xterm_kbs
525 AC_SUBST(XTERM_KBS)
526
527 MAKE_TERMINFO=
528 if test "$use_database" = no ; then
529         TERMINFO="${datadir}/terminfo"
530         MAKE_TERMINFO="#"
531 else
532
533 AC_MSG_CHECKING(for list of terminfo directories)
534 CF_WITH_PATHLIST(terminfo-dirs,
535         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
536         TERMINFO_DIRS,
537         DATADIR/terminfo,
538         ${datadir}/terminfo)
539 AC_MSG_RESULT($TERMINFO_DIRS)
540 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
541
542 AC_MSG_CHECKING(for default terminfo directory)
543 CF_WITH_PATH(default-terminfo-dir,
544         [  --with-default-terminfo-dir=DIR default terminfo directory],
545         TERMINFO,
546         DATADIR/terminfo,
547         ${datadir}/terminfo)
548 AC_MSG_RESULT($TERMINFO)
549 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
550
551 fi
552
553 AC_SUBST(TERMINFO)
554 AC_SUBST(MAKE_TERMINFO)
555
556 ###     use option --disable-big-core to make tic run on small machines
557 ###     We need 4Mb, check if we can allocate 50% more than that.
558 AC_MSG_CHECKING(if big-core option selected)
559 AC_ARG_ENABLE(big-core,
560         [  --disable-big-core      assume machine has little memory],
561         [with_big_core=$enableval],
562         [AC_TRY_RUN([
563 #include <stdlib.h>
564 #include <string.h>
565 int main() {
566         unsigned long n = 6000000L;
567         char *s = malloc(n);
568         if (s != 0)
569                 s[0] = s[n-1] = 0;
570         ${cf_cv_main_return:-return}(s == 0);
571 }],
572         [with_big_core=yes],
573         [with_big_core=no],
574         [with_big_core=no])])
575 AC_MSG_RESULT($with_big_core)
576 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
577
578 ### ISO C only guarantees 512-char strings, we have tables which load faster
579 ### when constructed using "big" strings.  More than the C compiler, the awk
580 ### program is a limit on most vendor UNIX systems.  Check that we can build.
581 AC_MSG_CHECKING(if big-strings option selected)
582 AC_ARG_ENABLE(big-strings,
583         [  --disable-big-strings   assume compiler has only standard-size strings],
584         [with_big_strings=$enableval],
585         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
586 AC_MSG_RESULT($with_big_strings)
587
588 USE_BIG_STRINGS=0
589 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
590 AC_SUBST(USE_BIG_STRINGS)
591
592 ###     use option --enable-termcap to compile in the termcap fallback support
593 AC_MSG_CHECKING(if you want termcap-fallback support)
594 AC_ARG_ENABLE(termcap,
595         [  --enable-termcap        compile in termcap fallback support],
596         [with_termcap=$enableval],
597         [with_termcap=no])
598 AC_MSG_RESULT($with_termcap)
599
600 NCURSES_USE_TERMCAP=0
601 if test "x$with_termcap" != "xyes" ; then
602         if test "$use_database" = no ; then
603                 if test -z "$with_fallback" ; then
604                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
605                 fi
606         fi
607         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
608 else
609
610         if test "$with_ticlib" != no ; then
611                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
612         fi
613
614         NCURSES_USE_TERMCAP=1
615         AC_MSG_CHECKING(for list of termcap files)
616         CF_WITH_PATHLIST(termpath,
617                 [  --with-termpath=XXX     specify list of termcap files],
618                 TERMPATH,
619                 /etc/termcap:/usr/share/misc/termcap)
620         AC_MSG_RESULT($TERMPATH)
621         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
622
623         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
624         AC_MSG_CHECKING(if fast termcap-loader is needed)
625         AC_ARG_ENABLE(getcap,
626                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
627                 [with_getcap=$enableval],
628                 [with_getcap=no])
629         AC_MSG_RESULT($with_getcap)
630         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
631
632         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
633         AC_ARG_ENABLE(getcap-cache,
634                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
635                 [with_getcap_cache=$enableval],
636                 [with_getcap_cache=no])
637         AC_MSG_RESULT($with_getcap_cache)
638         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
639
640 fi
641 AC_SUBST(NCURSES_USE_TERMCAP)
642
643 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
644 AC_MSG_CHECKING(if ~/.terminfo is wanted)
645 AC_ARG_ENABLE(home-terminfo,
646         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
647         [with_home_terminfo=$enableval],
648         [with_home_terminfo=yes])
649 AC_MSG_RESULT($with_home_terminfo)
650 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
651
652 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
653 AC_ARG_ENABLE(root-environ,
654         [  --disable-root-environ  restrict environment when running as root],
655         [with_root_environ=$enableval],
656         [with_root_environ=yes])
657 AC_MSG_RESULT($with_root_environ)
658 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
659
660 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
661 ###   to reduce storage requirements for the terminfo database.
662 CF_LINK_FUNCS
663
664 with_links=no
665 with_symlinks=no
666
667 # soft links (symbolic links) are useful for some systems where hard links do
668 # not work, or to make it simpler to copy terminfo trees around.
669 if test "x$ac_cv_func_symlink" = xyes ; then
670     AC_MSG_CHECKING(if tic should use symbolic links)
671     AC_ARG_ENABLE(symlinks,
672         [  --enable-symlinks       make tic use symbolic links not hard links],
673         [with_symlinks=$enableval],
674         [with_symlinks=no])
675     AC_MSG_RESULT($with_symlinks)
676 fi
677
678 # If we have hard links and did not choose to use soft links instead, there is
679 # no reason to make this choice optional - use the hard links.
680 if test "$with_symlinks" = no ; then
681     AC_MSG_CHECKING(if tic should use hard links)
682     if test "x$ac_cv_func_link" = xyes ; then
683         with_links=yes
684     else
685         with_links=no
686     fi
687     AC_MSG_RESULT($with_links)
688 fi
689
690 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
691 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
692
693 ###   use option --enable-broken-linker to force on use of broken-linker support
694 AC_MSG_CHECKING(if you want broken-linker support code)
695 AC_ARG_ENABLE(broken_linker,
696         [  --enable-broken_linker  compile with broken-linker support code],
697         [with_broken_linker=$enableval],
698         [with_broken_linker=${BROKEN_LINKER:-no}])
699 AC_MSG_RESULT($with_broken_linker)
700
701 BROKEN_LINKER=0
702 if test "x$with_broken_linker" = xyes ; then
703         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
704         BROKEN_LINKER=1
705 elif test "$DFT_LWR_MODEL" = shared ; then
706         case $cf_cv_system_name in #(vi
707         cygwin*)
708                 AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
709                 BROKEN_LINKER=1
710                 CF_VERBOSE(cygwin linker is broken anyway)
711                 ;;
712         esac
713 fi
714 AC_SUBST(BROKEN_LINKER)
715
716 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
717 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
718 AC_ARG_ENABLE(bsdpad,
719         [  --enable-bsdpad         recognize BSD-style prefix padding],
720         [with_bsdpad=$enableval],
721         [with_bsdpad=no])
722 AC_MSG_RESULT($with_bsdpad)
723 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
724
725 ###   use option --enable-widec to turn on use of wide-character support
726 NCURSES_CH_T=chtype
727 NCURSES_LIBUTF8=0
728
729 NEED_WCHAR_H=0
730 NCURSES_MBSTATE_T=0
731 NCURSES_WCHAR_T=0
732 NCURSES_WINT_T=0
733
734 # Check to define _XOPEN_SOURCE "automatically"
735 CF_XOPEN_SOURCE(500)
736
737 # Work around breakage on OS X
738 CF_SIGWINCH
739
740 # Checks for CODESET support.
741 AM_LANGINFO_CODESET
742
743 # use these variables to work around a defect in gcc's fixincludes.
744 NCURSES_OK_WCHAR_T=
745 NCURSES_OK_WINT_T=
746
747 AC_MSG_CHECKING(if you want wide-character code)
748 AC_ARG_ENABLE(widec,
749         [  --enable-widec          compile with wide-char/UTF-8 code],
750         [with_widec=$enableval],
751         [with_widec=no])
752 AC_MSG_RESULT($with_widec)
753 if test "x$with_widec" = xyes ; then
754         if test "x$disable_lib_suffixes" = xno ; then
755                 LIB_SUFFIX="w${LIB_SUFFIX}"
756         fi
757         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
758         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
759
760         CF_CHECK_WCHAR_H
761
762         # with_overwrite=no
763         NCURSES_CH_T=cchar_t
764         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
765         if test "x$ac_cv_func_putwc" != xyes ; then
766                 CF_UTF8_LIB
767                 if test "$cf_cv_utf8_lib" != no ; then
768                         NCURSES_LIBUTF8=1
769                 fi
770         fi
771         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
772         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
773         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
774
775         if test "$NCURSES_MBSTATE_T" != 0; then
776                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
777         fi
778 fi
779 AC_SUBST(NCURSES_CH_T)
780 AC_SUBST(NCURSES_LIBUTF8)
781
782 AC_SUBST(NEED_WCHAR_H)
783 AC_SUBST(NCURSES_MBSTATE_T)
784 AC_SUBST(NCURSES_WCHAR_T)
785 AC_SUBST(NCURSES_WINT_T)
786
787 AC_SUBST(NCURSES_OK_WCHAR_T)
788 AC_SUBST(NCURSES_OK_WINT_T)
789
790 ###   use option --disable-lp64 to allow long chtype
791 case $cf_cv_abi_version in
792 [[345]]*)
793         default_with_lp64=no
794         ;;
795 *)
796         default_with_lp64=yes
797         ;;
798 esac
799
800 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
801 AC_ARG_ENABLE(lp64,
802         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
803         [with_lp64=$enableval],
804         [with_lp64=$default_with_lp64])
805 AC_MSG_RESULT($with_lp64)
806
807 if test "x$with_lp64" = xyes ; then
808         cf_cv_enable_lp64=1
809 else
810         cf_cv_enable_lp64=0
811 fi
812 AC_SUBST(cf_cv_enable_lp64)
813
814 CF_LARGEFILE
815
816 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
817 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
818 AC_ARG_ENABLE(tparm-varargs,
819         [  --disable-tparm-varargs compile tparm() without varargs interface],
820         [with_tparm_varargs=$enableval],
821         [with_tparm_varargs=yes])
822 AC_MSG_RESULT($with_tparm_varargs)
823 NCURSES_TPARM_VARARGS=0
824 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
825 AC_SUBST(NCURSES_TPARM_VARARGS)
826
827 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
828 if test "$with_ticlib" != no ; then
829 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
830 AC_ARG_ENABLE(tic-depends,
831         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
832         [with_tic_depends=$enableval],
833         [with_tic_depends=yes])
834 AC_MSG_RESULT($with_tic_depends)
835 else
836         with_tic_depends=no
837 fi
838
839 ###   use option --with-bool to override bool's type
840 AC_MSG_CHECKING(for type of bool)
841 AC_ARG_WITH(bool,
842         [  --with-bool=TYPE        override fallback type of bool variable],
843         [NCURSES_BOOL="$withval"],
844         [NCURSES_BOOL=auto])
845 AC_MSG_RESULT($NCURSES_BOOL)
846 AC_SUBST(NCURSES_BOOL)
847
848 AC_MSG_CHECKING(for alternate terminal capabilities file)
849 AC_ARG_WITH(caps,
850         [  --with-caps=alt         compile with alternate Caps file],
851         [TERMINFO_CAPS=Caps.$withval],
852         [TERMINFO_CAPS=Caps])
853 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
854 AC_MSG_RESULT($TERMINFO_CAPS)
855 AC_SUBST(TERMINFO_CAPS)
856
857 ###   use option --with-chtype to override chtype's type
858 AC_MSG_CHECKING(for type of chtype)
859 AC_ARG_WITH(chtype,
860         [  --with-chtype=TYPE      override type of chtype],
861         [NCURSES_CHTYPE="$withval"],
862         [NCURSES_CHTYPE=auto])
863 AC_MSG_RESULT($NCURSES_CHTYPE)
864
865 ###   use option --with-ospeed to override ospeed's type
866 AC_MSG_CHECKING(for type of ospeed)
867 AC_ARG_WITH(ospeed,
868         [  --with-ospeed=TYPE      override type of ospeed variable],
869         [NCURSES_OSPEED="$withval"],
870         [NCURSES_OSPEED=short])
871 AC_MSG_RESULT($NCURSES_OSPEED)
872 AC_SUBST(NCURSES_OSPEED)
873
874 ###   use option --with-mmask-t to override mmask_t's type
875 AC_MSG_CHECKING(for type of mmask_t)
876 AC_ARG_WITH(mmask-t,
877         [  --with-mmask-t=TYPE     override type of mmask_t],
878         [NCURSES_MMASK_T="$withval"],
879         [NCURSES_MMASK_T=auto])
880 AC_MSG_RESULT($NCURSES_MMASK_T)
881
882 ###   use option --with-ccharw-max to override CCHARW_MAX size
883 AC_MSG_CHECKING(for size CCHARW_MAX)
884 AC_ARG_WITH(ccharw-max,
885         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
886         [NCURSES_CCHARW_MAX="$withval"],
887         [NCURSES_CCHARW_MAX=5])
888 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
889 AC_SUBST(NCURSES_CCHARW_MAX)
890
891 ###   use option --with-tparm-arg to override tparm's argument type
892 AC_MSG_CHECKING(for type of tparm args)
893 AC_ARG_WITH(tparm-arg,
894         [  --with-tparm-arg=TYPE   override parameter type of tparm],
895         [NCURSES_TPARM_ARG="$withval"],
896         [NCURSES_TPARM_ARG=long])
897 AC_MSG_RESULT($NCURSES_TPARM_ARG)
898 AC_SUBST(NCURSES_TPARM_ARG)
899
900 ### Enable compiling-in rcs id's
901 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
902 AC_ARG_WITH(rcs-ids,
903         [  --with-rcs-ids          compile-in RCS identifiers],
904         [with_rcs_ids=$withval],
905         [with_rcs_ids=no])
906 AC_MSG_RESULT($with_rcs_ids)
907 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
908
909 ###############################################################################
910 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
911
912 ###############################################################################
913 CF_HELP_MESSAGE(Extensions:)
914
915 ### Note that some functions (such as const) are normally disabled anyway.
916 AC_MSG_CHECKING(if you want to build with function extensions)
917 AC_ARG_ENABLE(ext-funcs,
918         [  --disable-ext-funcs     disable function-extensions],
919         [with_ext_funcs=$enableval],
920         [with_ext_funcs=yes])
921 AC_MSG_RESULT($with_ext_funcs)
922 if test "x$with_ext_funcs" = xyes ; then
923         NCURSES_EXT_FUNCS=1
924         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function])
925         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function])
926         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function])
927         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function])
928         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function])
929         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function])
930         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function])
931         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function])
932         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function])
933         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function])
934         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
935         GENERATED_EXT_FUNCS=generated
936 else
937         NCURSES_EXT_FUNCS=0
938         GENERATED_EXT_FUNCS=
939 fi
940 AC_SUBST(NCURSES_EXT_FUNCS)
941 AC_SUBST(GENERATED_EXT_FUNCS)
942
943 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
944 AC_ARG_ENABLE(sp-funcs,
945         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
946         [with_sp_funcs=$enableval],
947         [with_sp_funcs=no])
948 AC_MSG_RESULT($with_sp_funcs)
949 if test "x$with_sp_funcs" = xyes ; then
950         NCURSES_SP_FUNCS=1
951         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable experimental SCREEN-extensions])
952         GENERATED_SP_FUNCS=generated
953 else
954         NCURSES_SP_FUNCS=0
955         GENERATED_SP_FUNCS=
956 fi
957 AC_SUBST(NCURSES_SP_FUNCS)
958 AC_SUBST(GENERATED_SP_FUNCS)
959
960 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
961 AC_ARG_ENABLE(term-driver,
962         [  --enable-term-driver    enable experimental terminal-driver],
963         [with_term_driver=$enableval],
964         [with_term_driver=no])
965 AC_MSG_RESULT($with_term_driver)
966 if test "x$with_term_driver" = xyes ; then
967         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable experimental terminal-driver])
968         if test "x$with_sp_funcs" != xyes ; then
969                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
970         fi
971 fi
972
973 ###   use option --enable-const to turn on use of const beyond that in XSI.
974 AC_MSG_CHECKING(for extended use of const keyword)
975 AC_ARG_ENABLE(const,
976         [  --enable-const          compile with extra/non-standard const],
977         [with_ext_const=$enableval],
978         [with_ext_const=no])
979 AC_MSG_RESULT($with_ext_const)
980 NCURSES_CONST='/*nothing*/'
981 if test "x$with_ext_const" = xyes ; then
982         NCURSES_CONST=const
983 fi
984 AC_SUBST(NCURSES_CONST)
985
986 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
987 AC_MSG_CHECKING(if you want to use extended colors)
988 AC_ARG_ENABLE(ext-colors,
989         [  --enable-ext-colors     compile for 256-color support],
990         [with_ext_colors=$enableval],
991         [with_ext_colors=no])
992 AC_MSG_RESULT($with_ext_colors)
993 NCURSES_EXT_COLORS=0
994 if test "x$with_ext_colors" = xyes ; then
995         if test "x$with_widec" != xyes ; then
996                 AC_MSG_ERROR(This option applies only to wide-character library)
997         else
998                 # cannot be ABI 5 since it changes sizeof(cchar_t)
999                 CF_NCURSES_ABI_6
1000         fi
1001         NCURSES_EXT_COLORS=1
1002         AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1003 fi
1004 AC_SUBST(NCURSES_EXT_COLORS)
1005
1006 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1007 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1008 AC_ARG_ENABLE(ext-mouse,
1009         [  --enable-ext-mouse      compile for extended mouse-encoding],
1010         [with_ext_mouse=$enableval],
1011         [with_ext_mouse=no])
1012 AC_MSG_RESULT($with_ext_mouse)
1013 NCURSES_MOUSE_VERSION=1
1014 if test "x$with_ext_mouse" = xyes ; then
1015         NCURSES_MOUSE_VERSION=2
1016         CF_NCURSES_ABI_6
1017 fi
1018 AC_SUBST(NCURSES_MOUSE_VERSION)
1019
1020 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1021 AC_ARG_ENABLE(no-padding,
1022         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1023         [with_no_padding=$enableval],
1024         [with_no_padding=$with_ext_funcs])
1025 AC_MSG_RESULT($with_no_padding)
1026 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1027
1028 AC_CHECK_SIZEOF([signed char], 0)
1029 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1030         NCURSES_SBOOL="signed char"
1031 else
1032         NCURSES_SBOOL="char"
1033 fi
1034 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1035 AC_ARG_ENABLE(signed-char,
1036         [  --enable-signed-char    compile using signed Boolean's in term.h],
1037         [with_signed_char=$enableval],
1038         [with_signed_char=no])
1039 AC_MSG_RESULT($with_signed_char)
1040 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1041 AC_SUBST(NCURSES_SBOOL)
1042
1043 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1044 AC_MSG_CHECKING(if you want SIGWINCH handler)
1045 AC_ARG_ENABLE(sigwinch,
1046         [  --enable-sigwinch       compile with SIGWINCH handler],
1047         [with_sigwinch=$enableval],
1048         [with_sigwinch=$with_ext_funcs])
1049 AC_MSG_RESULT($with_sigwinch)
1050 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1051
1052 ###   use option --enable-tcap-names to allow user to define new capabilities
1053 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1054 AC_ARG_ENABLE(tcap-names,
1055         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1056         [with_tcap_names=$enableval],
1057         [with_tcap_names=$with_ext_funcs])
1058 AC_MSG_RESULT($with_tcap_names)
1059 NCURSES_XNAMES=0
1060 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1061 AC_SUBST(NCURSES_XNAMES)
1062
1063 ###############################################################################
1064 # These options are relatively safe to experiment with.
1065 CF_HELP_MESSAGE(Development Code:)
1066 AC_MSG_CHECKING(if you want all development code)
1067 AC_ARG_WITH(develop,
1068         [  --without-develop       disable development options],
1069         [with_develop=$withval],
1070         [with_develop=no])
1071 AC_MSG_RESULT($with_develop)
1072
1073 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1074 AC_MSG_CHECKING(if you want hard-tabs code)
1075 AC_ARG_ENABLE(hard-tabs,
1076         [  --enable-hard-tabs      compile with hard-tabs code],,
1077         [enable_hard_tabs=$with_develop])
1078 AC_MSG_RESULT($enable_hard_tabs)
1079 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1080
1081 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1082 AC_MSG_CHECKING(if you want limited support for xmc)
1083 AC_ARG_ENABLE(xmc-glitch,
1084         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1085         [enable_xmc_glitch=$with_develop])
1086 AC_MSG_RESULT($enable_xmc_glitch)
1087 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1088
1089 ###############################################################################
1090 # These are just experimental, probably should not be in a package:
1091 CF_HELP_MESSAGE(Experimental Code:)
1092
1093 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1094 AC_ARG_ENABLE(assumed-color,
1095         [  --disable-assumed-color do not assume anything about default-colors],
1096         [with_assumed_color=$enableval],
1097         [with_assumed_color=yes])
1098 AC_MSG_RESULT($with_assumed_color)
1099 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1100
1101 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1102 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1103 AC_ARG_ENABLE(hashmap,
1104         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1105         [with_hashmap=$enableval],
1106         [with_hashmap=yes])
1107 AC_MSG_RESULT($with_hashmap)
1108 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1109
1110 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1111 AC_MSG_CHECKING(if you want colorfgbg code)
1112 AC_ARG_ENABLE(colorfgbg,
1113         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1114         [with_colorfgbg=$enableval],
1115         [with_colorfgbg=no])
1116 AC_MSG_RESULT($with_colorfgbg)
1117 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1118
1119 ###   use option --enable-interop to turn on use of bindings used for interop
1120 AC_MSG_CHECKING(if you want interop bindings)
1121 AC_ARG_ENABLE(interop,
1122         [  --enable-interop        compile-in experimental interop bindings],
1123         [with_exp_interop=$enableval],
1124         [with_exp_interop=no])
1125 AC_MSG_RESULT($with_exp_interop)
1126
1127 NCURSES_INTEROP_FUNCS=0
1128 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1129 AC_SUBST(NCURSES_INTEROP_FUNCS)
1130
1131 # This is still experimental (20080329), but should ultimately be moved to
1132 # the script-block --with-normal, etc.
1133 CF_WITH_PTHREAD
1134
1135 if test "x$with_pthread" != xno; then
1136         AC_CHECK_FUNC(pthread_kill,[
1137                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1138                 AC_ARG_ENABLE(pthreads-eintr,
1139                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1140                         [use_pthreads_eintr=$enableval],
1141                         [use_pthreads_eintr=no])
1142                 AC_MSG_RESULT($use_pthreads_eintr)
1143                 if test "x$use_pthreads_eintr" = xyes ; then
1144                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1145                 fi])
1146
1147         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1148         AC_ARG_ENABLE(weak-symbols,
1149                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1150                 [use_weak_symbols=$enableval],
1151                 [use_weak_symbols=no])
1152         AC_MSG_RESULT($use_weak_symbols)
1153         if test "x$use_weak_symbols" = xyes ; then
1154                 CF_WEAK_SYMBOLS
1155         else
1156                 cf_cv_weak_symbols=no
1157         fi
1158
1159         if test "x$cf_cv_weak_symbols" = xyes ; then
1160                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1161         fi
1162 fi
1163
1164 PTHREAD=
1165 if test "x$with_pthread" = "xyes" ; then
1166     AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1167     enable_reentrant=yes
1168     if test "x$cf_cv_weak_symbols" = xyes ; then
1169         PTHREAD=-lpthread
1170     fi
1171 fi
1172 AC_SUBST(PTHREAD)
1173
1174 # Reentrant code has to be opaque; there's little advantage to making ncurses
1175 # opaque outside of that, so there is no --enable-opaque option.  We can use
1176 # this option without --with-pthreads, but this will be always set for
1177 # pthreads.
1178 AC_MSG_CHECKING(if you want experimental reentrant code)
1179 AC_ARG_ENABLE(reentrant,
1180         [  --enable-reentrant      compile with experimental reentrant code],
1181         [with_reentrant=$enableval],
1182         [with_reentrant=no])
1183 AC_MSG_RESULT($with_reentrant)
1184 if test "x$with_reentrant" = xyes ; then
1185         cf_cv_enable_reentrant=1
1186         cf_cv_enable_opaque="NCURSES_INTERNALS"
1187         NCURSES_OPAQUE=1
1188         NCURSES_SIZE_T=int
1189         if test "x$cf_cv_weak_symbols" = xyes ; then
1190                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1191                 CF_ADD_LIB(pthread,TEST_LIBS)
1192                 CF_ADD_LIB(pthread,TEST_LIBS2)
1193         else
1194                 # when not using weak symbols but with_reentrant,
1195                 # add 't' to the library suffix on all platforms
1196                 # except cygwin, where we only do that if ALSO
1197                 # compiling with full thread support.
1198                 case "$host" in
1199                 *cygwin* | *msys*) #(vi
1200                         if test "$with_pthread" = "yes" ; then
1201                                 if test "x$disable_lib_suffixes" = "xno" ; then
1202                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1203                                 fi
1204                         fi ;;
1205                 *)
1206                         if test "x$disable_lib_suffixes" = "xno" ; then
1207                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1208                         fi
1209                         ;;
1210                 esac
1211         fi
1212         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use experimental reentrant feature])
1213         CF_NCURSES_ABI_6
1214 else
1215         cf_cv_enable_reentrant=0
1216         cf_cv_enable_opaque="NCURSES_OPAQUE"
1217         NCURSES_OPAQUE=0
1218         NCURSES_SIZE_T=short
1219 fi
1220 AC_SUBST(cf_cv_enable_reentrant)
1221 AC_SUBST(cf_cv_enable_opaque)
1222 AC_SUBST(NCURSES_OPAQUE)
1223 AC_SUBST(NCURSES_SIZE_T)
1224
1225 ### Allow using a different wrap-prefix
1226 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1227         AC_MSG_CHECKING(for prefix used to wrap public variables)
1228         AC_ARG_WITH(wrap-prefix,
1229                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1230                 [NCURSES_WRAP_PREFIX=$withval],
1231                 [NCURSES_WRAP_PREFIX=_nc_])
1232         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1233 else
1234         NCURSES_WRAP_PREFIX=_nc_
1235 fi
1236 AC_SUBST(NCURSES_WRAP_PREFIX)
1237 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1238
1239 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1240 AC_ARG_ENABLE(safe-sprintf,
1241         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1242         [with_safe_sprintf=$enableval],
1243         [with_safe_sprintf=no])
1244 AC_MSG_RESULT($with_safe_sprintf)
1245 test "x$with_safe_sprintf" = xyes && AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1246
1247 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1248 # when hashmap is used scroll hints are useless
1249 if test "$with_hashmap" = no ; then
1250 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1251 AC_ARG_ENABLE(scroll-hints,
1252         [  --disable-scroll-hints  compile without scroll-hints code],
1253         [with_scroll_hints=$enableval],
1254         [with_scroll_hints=yes])
1255 AC_MSG_RESULT($with_scroll_hints)
1256 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1257 fi
1258
1259 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1260 AC_ARG_ENABLE(wgetch-events,
1261         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1262         [with_wgetch_events=$enableval],
1263         [with_wgetch_events=no])
1264 AC_MSG_RESULT($with_wgetch_events)
1265 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with experimental wgetch-events code])
1266
1267 ###############################################################################
1268 CF_HELP_MESSAGE(Testing/development Options:)
1269
1270 ###     use option --disable-echo to suppress full display compiling commands
1271 CF_DISABLE_ECHO
1272 if test "x$enable_echo" = xyes; then
1273         ECHO_LINK=
1274 else
1275         ECHO_LINK='@ echo linking $@ ... ;'
1276         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1277         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1278 fi
1279 AC_SUBST(ECHO_LINK)
1280
1281 ###     use option --enable-warnings to turn on all gcc warnings
1282 AC_MSG_CHECKING(if you want to see compiler warnings)
1283 AC_ARG_ENABLE(warnings,
1284         [  --enable-warnings       build: turn on GCC compiler warnings],
1285         [with_warnings=$enableval])
1286 AC_MSG_RESULT($with_warnings)
1287
1288 if test "x$with_warnings" = "xyes"; then
1289         CF_ADD_ADAFLAGS(-gnatg)
1290         CF_GCC_WARNINGS(Wno-unknown-pragmas Wswitch-enum)
1291         if test "x$cf_with_cxx" = xyes ; then
1292                 CF_GXX_WARNINGS(Wno-unused)
1293         fi
1294 fi
1295 CF_GCC_ATTRIBUTES
1296 CF_ENABLE_STRING_HACKS
1297
1298 ###     use option --enable-assertions to turn on generation of assertion code
1299 AC_MSG_CHECKING(if you want to enable runtime assertions)
1300 AC_ARG_ENABLE(assertions,
1301         [  --enable-assertions     test: turn on generation of assertion code],
1302         [with_assertions=$enableval],
1303         [with_assertions=no])
1304 AC_MSG_RESULT($with_assertions)
1305 if test -n "$GCC"
1306 then
1307         if test "$with_assertions" = no
1308         then
1309                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1310         else
1311                 CF_ADD_ADAFLAGS(-gnata)
1312         fi
1313 fi
1314
1315 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1316 CF_DISABLE_LEAKS
1317 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1318
1319 ###     use option --enable-expanded to generate certain macros as functions
1320 AC_ARG_ENABLE(expanded,
1321         [  --enable-expanded       test: generate functions for certain macros],
1322         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1323
1324 ###     use option --disable-macros to suppress macros in favor of functions
1325 AC_ARG_ENABLE(macros,
1326         [  --disable-macros        test: use functions rather than macros],
1327         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1328
1329 # Normally we only add trace() to the debug-library.  Allow this to be
1330 # extended to all models of the ncurses library:
1331 cf_all_traces=no
1332 case "$CFLAGS $CPPFLAGS" in
1333 *-DTRACE*)
1334         cf_all_traces=yes
1335         ;;
1336 esac
1337
1338 AC_MSG_CHECKING(whether to add trace feature to all models)
1339 AC_ARG_WITH(trace,
1340 [  --with-trace            test: add trace() function to all models of ncurses],
1341 [cf_with_trace=$withval],
1342 [cf_with_trace=$cf_all_traces])
1343 AC_MSG_RESULT($cf_with_trace)
1344
1345 if test "x$cf_with_trace" = xyes ; then
1346         LIB_TRACING=all
1347         ADA_TRACE=TRUE
1348         CF_ADD_CFLAGS(-DTRACE)
1349 else
1350         LIB_TRACING=DEBUG
1351         ADA_TRACE=FALSE
1352 fi
1353
1354 AC_SUBST(ADA_TRACE)
1355
1356 ###     Checks for libraries.
1357 case $cf_cv_system_name in #(vi
1358 *mingw32*) #(vi
1359         LIBS=" -lpsapi $LIBS"
1360         ;;
1361 *)
1362 AC_CHECK_FUNC(gettimeofday,
1363         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1364
1365 AC_CHECK_LIB(bsd, gettimeofday,
1366         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1367         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1368         ;;
1369 esac
1370
1371 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1372 AC_SUBST(MATH_LIB)
1373
1374 ###     Checks for header files.
1375 AC_STDC_HEADERS
1376 AC_HEADER_DIRENT
1377 AC_HEADER_TIME
1378 CF_REGEX
1379
1380 dnl These are some other potentially nonportable headers.
1381 AC_CHECK_HEADERS( \
1382 fcntl.h \
1383 getopt.h \
1384 limits.h \
1385 locale.h \
1386 math.h \
1387 poll.h \
1388 sys/bsdtypes.h \
1389 sys/ioctl.h \
1390 sys/param.h \
1391 sys/poll.h \
1392 sys/select.h \
1393 sys/time.h \
1394 sys/times.h \
1395 ttyent.h \
1396 unistd.h \
1397 wctype.h \
1398 )
1399
1400 CF_GETOPT_HEADER
1401
1402 # check for ISC (this may also define _POSIX_SOURCE)
1403 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1404 if test "x$ISC" = xyes ; then
1405         AC_CHECK_LIB(cposix,main)
1406         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1407 fi
1408
1409 CF_SYS_TIME_SELECT
1410
1411 ###     checks for compiler characteristics
1412 AC_LANG_C
1413 AC_C_CONST
1414 CF_C_INLINE(NCURSES_INLINE,1200)
1415 CF_SIG_ATOMIC_T
1416
1417 if test $NCURSES_CHTYPE = auto ; then
1418         CF_TYPEOF_CHTYPE
1419 else
1420         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1421 fi
1422 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1423 AC_SUBST(cf_cv_typeof_chtype)
1424
1425 CF_UNSIGNED_LITERALS
1426 cf_cv_1UL="1"
1427 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1428 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1429 AC_SUBST(cf_cv_1UL)
1430
1431 if test $NCURSES_MMASK_T = auto ; then
1432         cf_cv_typeof_mmask_t=long
1433 else
1434         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1435 fi
1436 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1437 AC_SUBST(cf_cv_typeof_mmask_t)
1438
1439 ###     Checks for external-data
1440 CF_ERRNO
1441 CF_LINK_DATAONLY
1442
1443 ###     Checks for library functions.
1444 AC_CHECK_FUNCS( \
1445 getcwd \
1446 getegid \
1447 geteuid \
1448 getttynam \
1449 issetugid \
1450 poll \
1451 putenv \
1452 remove \
1453 select \
1454 setbuf \
1455 setbuffer \
1456 setenv \
1457 setvbuf \
1458 sigaction \
1459 sigvec \
1460 strdup \
1461 strstr \
1462 tcgetpgrp \
1463 times \
1464 vsnprintf \
1465 )
1466 if test "x$with_getcap" = "xyes" ; then
1467         CF_CGETENT
1468 fi
1469
1470 CF_ISASCII
1471 CF_STRUCT_SIGACTION
1472 CF_FUNC_NANOSLEEP
1473 CF_FUNC_TERMIOS
1474 CF_FUNC_VSSCANF
1475 CF_MKSTEMP
1476
1477 # setup for prototype of fallback for vsscanf()
1478 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1479
1480 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1481 if test "x$cross_compiling" = xyes ; then
1482         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1483 else
1484         AC_FUNC_SETVBUF_REVERSED
1485 fi
1486 AC_CHECK_TYPE(intptr_t, long)
1487 CF_TYPE_SIGACTION
1488 CF_SIZECHANGE
1489 CF_FUNC_MEMMOVE
1490 CF_FUNC_POLL
1491 CF_VA_COPY
1492 AC_FUNC_VFORK
1493
1494 # special check for test/ditto.c
1495 CF_FUNC_OPENPTY
1496 if test "$cf_cv_func_openpty" != no ; then
1497     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1498     AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1499     if test "x$cf_cv_lib_util" = xyes ; then
1500         CF_ADD_LIB(util,TEST_LIBS)
1501     fi
1502 fi
1503 AC_SUBST(TEST_LIBS)
1504 AC_SUBST(TEST_LIBS2)
1505
1506 if test "$with_hashed_db" != no ; then
1507         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1508         CF_HASHED_DB($with_hashed_db)
1509 fi
1510
1511 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1512 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1513         CF_STRIP_G_OPT(CFLAGS)
1514         CF_STRIP_G_OPT(CXXFLAGS)
1515 fi
1516
1517 # Just in case, check if the C compiler has a bool type.
1518 CF_BOOL_DECL(cf_cv_cc_bool_type)
1519
1520 # Check for C++ compiler characteristics (and ensure that it's there!)
1521 if test -n "$CXX" ; then
1522         AC_LANG_CPLUSPLUS
1523         CF_STDCPP_LIBRARY
1524         CF_PROG_CC_C_O(CXX)
1525
1526         case $GXX_VERSION in
1527         1*|2.[0-6]*)
1528                 cf_cxx_library=yes
1529                 ;;
1530         *-2.7*|2.7*)
1531                 CF_GPP_LIBRARY
1532                 ;;
1533         *)
1534                 cf_cxx_library=no
1535                 ;;
1536         esac
1537
1538         AC_CHECK_HEADERS(typeinfo)
1539         CF_CXX_IOSTREAM_NAMESPACE
1540         CF_BOOL_DECL
1541         CF_BOOL_SIZE
1542         CF_ETIP_DEFINES
1543         CF_CPP_PARAM_INIT
1544         CF_CPP_STATIC_CAST
1545         CF_CXX_AR_FLAGS
1546 else
1547         cf_cxx_library=no
1548         cf_cv_builtin_bool=1
1549
1550         # Just because we are not configuring against C++ right now does not
1551         # mean that a user will not want to use C++.  Some distributors disable
1552         # the C++ portion of this configuration as a shortcut (or just to avoid
1553         # compiling the demo in the c++ directory).  So we need a reasonable
1554         # default for the 'bool' type.
1555         #
1556         # Caveat: since the storage of the bool type is not standardized, it
1557         # may change.
1558
1559         if test "$NCURSES_BOOL" != auto ; then
1560                 cf_cv_type_of_bool=$NCURSES_BOOL
1561                 cf_cv_header_stdbool_h=0
1562         else
1563                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1564                         CF_BOOL_SIZE
1565                 else
1566                         AC_MSG_CHECKING(for fallback type of bool)
1567                         case "$host_cpu" in #(vi
1568                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1569                         *)      cf_cv_type_of_bool=int  ;;
1570                         esac
1571                         AC_MSG_RESULT($cf_cv_type_of_bool)
1572                 fi
1573         fi
1574 fi
1575 AC_SUBST(CXXLIBS)
1576
1577 # If the C compiler did not declare bool, and we did not determine that the C++
1578 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1579 # ncurses library use the same type as C++ bool.  Note that this allows one to
1580 # specify the type of bool in a configure-script option and postpone
1581 # integration with the C++ compiler provided that the types are compatible.
1582 USE_CXX_BOOL=1
1583 if test $cf_cv_cc_bool_type = 1
1584 then
1585         # oops: C has a bool.  Unlikely, but C++ could differ.
1586         USE_CXX_BOOL=0
1587 elif test $cf_cv_builtin_bool = 0
1588 then
1589         # C++ has no bool
1590         USE_CXX_BOOL=0
1591 else
1592         # this is the normal case
1593         USE_CXX_BOOL='defined(__cplusplus)'
1594 fi
1595 AC_SUBST(USE_CXX_BOOL)
1596
1597 CF_HELP_MESSAGE(Ada95 Binding Options:)
1598
1599 dnl If the Ada95 source-tree is present, add that to the build unless it will
1600 dnl not work, or was not requested.
1601 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1602
1603 dnl libtool does not know anything about GNAT, though a change made in 1998
1604 dnl provided for it "someday".  Disable the ada subtree if we are using
1605 dnl libtool -TD 20070714
1606         if test "$cf_with_ada" != "no" ; then
1607                 if test "$with_libtool" != "no"; then
1608                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1609                         cf_with_ada=no
1610                 fi
1611         fi
1612
1613 dnl Check for availability of GNU Ada Translator (GNAT).
1614 dnl At the moment we support no other Ada95 compiler.
1615         if test "$cf_with_ada" != "no" ; then
1616                 CF_PROG_GNAT
1617                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1618                         CF_ADD_ADAFLAGS(-gnatpn)
1619                         CF_FIXUP_ADAFLAGS
1620
1621                         CF_GNAT_GENERICS
1622                         CF_GNAT_SIGINT
1623                         CF_GNAT_PRAGMA_UNREF
1624                         CF_GNAT_PROJECTS
1625
1626                         CF_WITH_ADA_COMPILER
1627
1628                         cf_ada_package=terminal_interface
1629                         AC_SUBST(cf_ada_package)
1630
1631                         CF_WITH_ADA_INCLUDE
1632                         CF_WITH_ADA_OBJECTS
1633                         CF_WITH_ADA_SHAREDLIB
1634                 fi
1635         fi
1636 else
1637         cf_with_ada=no
1638 fi
1639
1640 # do this "late" to avoid conflict with header-checks
1641 if test "x$with_widec" = xyes ; then
1642         AC_CHECK_SIZEOF(wchar_t)
1643 fi
1644
1645 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1646 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1647 ###
1648 ### ticlib modules may be a separate library, otherwise contained in termlib.
1649 ### termlib modules may be a separate library, otherwise contained in ncurses.
1650 ###
1651 ### The of "+" or " " between the tokens controls the way the script
1652 ### chooses to split module lists into libraries.
1653 ###
1654 ### (see CF_LIB_RULES).
1655 AC_MSG_CHECKING(for library subsets)
1656 LIB_SUBSETS=
1657
1658 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1659         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1660         if test "$with_ticlib" != no ; then
1661                 LIB_SUBSETS="${LIB_SUBSETS} "
1662         else
1663                 LIB_SUBSETS="${LIB_SUBSETS}+"
1664         fi
1665 fi
1666
1667 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1668 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1669
1670 if test "$with_termlib" != no ; then
1671         LIB_SUBSETS="${LIB_SUBSETS} "
1672 else
1673         LIB_SUBSETS="${LIB_SUBSETS}+"
1674 fi
1675
1676 LIB_SUBSETS="${LIB_SUBSETS}base"
1677
1678 # Most term-driver calls are to tinfo, but some like init_pair are to the
1679 # base library (so it resides in base).
1680 if test "$with_term_driver" != no ; then
1681         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1682         case $cf_cv_system_name in #(vi
1683         *mingw32*) #(vi
1684                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1685                 ;;
1686         *) #(vi
1687                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1688                 ;;
1689         esac
1690 fi
1691
1692 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1693 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1694
1695 AC_MSG_RESULT($LIB_SUBSETS)
1696
1697 ### Construct the list of include-directories to be generated
1698 CF_INCLUDE_DIRS
1699 CF_ADA_INCLUDE_DIRS
1700
1701 ### Build up pieces for makefile rules
1702 AC_MSG_CHECKING(default library suffix)
1703 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1704 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1705 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1706
1707 AC_MSG_CHECKING(default library-dependency suffix)
1708 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1709 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1710 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1711
1712 AC_MSG_CHECKING(default object directory)
1713 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1714 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1715 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1716
1717 if test "x$cf_with_cxx" = xyes ; then
1718 AC_MSG_CHECKING(c++ library-dependency suffix)
1719 if test "$with_libtool" != "no"; then
1720         # libtool thinks it can make c++ shared libraries (perhaps only g++)
1721         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1722 elif test "$with_shared_cxx" != "no"; then
1723         # also for g++ users...
1724         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1725 else
1726         # we normally make a static library because C/C++ library rules differ
1727         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
1728 fi
1729 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1730 AC_SUBST(CXX_LIB_SUFFIX)
1731 fi
1732
1733 # do not want -ldl in build except as needed for -lncurses dependency
1734 if test "x$with_dlsym" = xyes ; then
1735 if test $DFT_LWR_MODEL = shared || \
1736    test $DFT_LWR_MODEL = libtool ; then
1737         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1738 fi
1739 fi
1740 ### Set up low-level terminfo dependencies for makefiles.
1741
1742 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1743 # do not need libdl
1744 TICS_LIST=
1745 if test "x$with_dlsym" = xyes ; then
1746         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1747 fi
1748
1749 if test "$with_ticlib" != no ; then
1750
1751         if test "x$with_ticlib" != xyes ; then
1752                 TICS_NAME=$with_ticlib
1753                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1754                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1755                 TICS_LIB_SUFFIX="${with_ticlib}"
1756         else
1757                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1758                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1759                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1760         fi
1761         TICS_LDFLAGS="-L${LIB_DIR}"
1762         TICS_LIBS="-l${TICS_LIB_SUFFIX}"
1763 else
1764         TICS_LDFLAGS="-L${LIB_DIR}"
1765         TICS_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1766 fi
1767 AC_SUBST(TICS_ARG_SUFFIX)
1768 AC_SUBST(TICS_DEP_SUFFIX)
1769 AC_SUBST(TICS_LIB_SUFFIX)
1770 AC_SUBST(TICS_LDFLAGS)
1771 AC_SUBST(TICS_LIBS)
1772
1773 if test "$with_termlib" != no ; then
1774
1775         if test "x$with_termlib" != xyes ; then
1776                 TINFO_NAME=$with_termlib
1777                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1778                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1779                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1780                 TINFO_LIB_SUFFIX="${with_termlib}"
1781         else
1782                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1783                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1784                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1785                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1786         fi
1787
1788         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1789         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1790         if test "$DFT_LWR_MODEL" = "libtool"; then
1791                 TEST_ARGS="${TEST_DEPS}"
1792                 TEST_ARG2="${TEST_DEP2}"
1793                 TINFO_LDFLAGS="-L${LIB_DIR}"
1794                 TINFO_LIBS="$TEST_ARGS"
1795                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1796                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1797         else
1798                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1799                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1800                 if test "x$with_term_driver" != xno ; then
1801                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1802                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1803                         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
1804                 else
1805                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1806                         TINFO_LIBS="$TEST_ARGS"
1807                 fi
1808                 TINFO_LDFLAGS="-L${LIB_DIR}"
1809                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1810         fi
1811 else
1812         # the next lines are needed for linking libtic over libncurses
1813         TINFO_NAME=${LIB_NAME}
1814         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1815         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1816         if test "x$with_tic_depends" = xyes ; then
1817                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1818         else
1819                 TICS_LIST="$SHLIB_LIST"
1820         fi
1821
1822         TINFO_LDFLAGS="-L${LIB_DIR}"
1823         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1824 fi
1825
1826 if test "$DFT_LWR_MODEL" = shared ; then
1827         case $cf_cv_system_name in #(vi
1828         cygwin*|msys*)
1829                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
1830                 TINFO_SUFFIX=.dll
1831                 ;;
1832         esac
1833 fi
1834
1835 AC_SUBST(TINFO_ARG_SUFFIX)
1836 AC_SUBST(TINFO_DEP_SUFFIX)
1837 AC_SUBST(TINFO_LIB_SUFFIX)
1838 AC_SUBST(TINFO_LDFLAGS)
1839 AC_SUBST(TINFO_LIBS)
1840
1841 if test "x$with_dlsym" = xyes ; then
1842         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1843 fi
1844
1845 if test "$DFT_LWR_MODEL" = "libtool"; then
1846     OBJEXT=lo
1847 fi
1848
1849 # needed for Ada95
1850 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
1851 AC_SUBST(TINFO_LDFLAGS2)
1852
1853 case $DFT_LWR_MODEL in
1854 normal|debug|profile)
1855         CF_LDFLAGS_STATIC
1856         ;;
1857 esac
1858
1859 AC_MSG_CHECKING(where we will install curses.h)
1860 AC_SUBST(includesubdir)
1861 includesubdir=
1862 if test "$with_overwrite" = no && \
1863  ( test "x$includedir" = 'x${prefix}/include' || \
1864    test "x$includedir" = "x${prefix}/include" )
1865 then
1866         includesubdir="/ncurses${LIB_SUFFIX}"
1867 fi
1868 AC_MSG_RESULT(${includedir}${includesubdir})
1869
1870 ### Resolve a conflict between normal and wide-curses by forcing applications
1871 ### that will need libutf8 to add it to their configure script.
1872 if test "$with_overwrite" != no ; then
1873 if test "$NCURSES_LIBUTF8" = 1 ; then
1874         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1875         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1876 fi
1877 fi
1878 WITH_OVERWRITE=$with_overwrite
1879
1880 AC_SUBST(WITH_OVERWRITE)
1881 AC_SUBST(TICS_LIST)
1882 AC_SUBST(TINFO_LIST)
1883 AC_SUBST(SHLIB_LIST)
1884
1885 # used to separate tack out of the tree
1886 NCURSES_TREE=
1887 AC_SUBST(NCURSES_TREE)
1888
1889 ### predefined stuff for the test programs
1890 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
1891
1892 ### Construct the list of subdirectories for which we'll customize makefiles
1893 ### with the appropriate compile-rules.
1894
1895 CF_SRC_MODULES($modules_to_build)
1896
1897 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
1898    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1899    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1900 fi
1901
1902 CF_DIRS_TO_MAKE
1903
1904 # symbols that differ when compiling Ada95 by itself.
1905 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1906 AC_SUBST(NCURSES_SHLIB2)
1907
1908 # values to use as strings
1909 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
1910
1911 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
1912
1913 ### Now that we're done running tests, add the compiler-warnings, if any
1914 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1915
1916 ### Define substitutions for header files to avoid name-pollution
1917 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
1918 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
1919 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
1920 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
1921
1922 ################################################################################
1923 test "x$use_database" = xyes && \
1924 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1925
1926 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1927 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1928
1929 if test "x$enable_pc_files" = xyes ; then \
1930 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1931 MAKE_PC_FILES=
1932 else
1933 MAKE_PC_FILES="#"
1934 fi
1935 AC_SUBST(MAKE_PC_FILES)
1936 AC_SUBST(cross_compiling)
1937
1938 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
1939 if test -n "$FALLBACK_LIST"
1940 then
1941         if test "$TIC_PATH" = unknown
1942         then
1943                 AC_MSG_WARN(no tic program found for fallbacks)
1944         fi
1945 fi
1946 AC_SUBST(TIC_PATH)
1947
1948 if test "x$cf_with_tests" != xno ; then
1949         MAKE_TESTS=
1950 else
1951         MAKE_TESTS="#"
1952 fi
1953 AC_SUBST(MAKE_TESTS)
1954
1955 ADAHTML_DIR=../../doc/html/ada
1956 AC_SUBST(ADAHTML_DIR)
1957
1958 # these could be configurable, but are not currently
1959 PANEL_NAME=panel
1960 MENU_NAME=menu
1961 FORM_NAME=form
1962 CXX_NAME=ncurses++
1963
1964 AC_SUBST(PANEL_NAME)
1965 AC_SUBST(MENU_NAME)
1966 AC_SUBST(FORM_NAME)
1967 AC_SUBST(CXX_NAME)
1968
1969 # workaround for g++ versus Solaris (20131116)
1970 case $cf_cv_system_name in #(vi
1971 solaris2*) #(vi
1972         case "x$CPPFLAGS" in #(vi
1973         *-D_XOPEN_SOURCE_EXTENDED*)
1974                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
1975                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
1976                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
1977                 ;;
1978         esac
1979         ;;
1980 esac
1981
1982 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
1983 case "x$NCURSES_OSPEED" in #(vi
1984 *short*) #(vi
1985         cf_compatible=1
1986         ;;
1987 *)
1988         cf_compatible=0
1989         ;;
1990 esac
1991 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
1992
1993 case "x$cf_cv_typeof_chtype" in
1994 xshort|xint|xlong)
1995         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
1996         ;;
1997 esac
1998
1999 case "x$cf_cv_typeof_mmask_t" in
2000 xshort|xint|xlong)
2001         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2002         ;;
2003 esac
2004
2005 SUB_SCRIPTS=
2006
2007 AC_OUTPUT( \
2008         include/MKterm.h.awk \
2009         include/curses.head:include/curses.h.in \
2010         include/ncurses_dll.h \
2011         include/termcap.h \
2012         include/unctrl.h \
2013         $SUB_SCRIPTS \
2014         $SUB_MAKEFILES \
2015         Makefile,[
2016 if test "x$cf_with_tests" != xno ; then
2017         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2018 fi
2019 CF_LIB_RULES($SRC_SUBDIRS)
2020
2021 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2022 if test -z "$USE_OLD_MAKERULES" ; then
2023         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
2024 fi
2025 fi
2026 ],[
2027 ### Special initialization commands, used to pass information from the
2028 ### configuration-run into config.status
2029
2030 AWK="$AWK"
2031 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2032 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2033 ECHO_LD="$ECHO_LD"
2034 LDCONFIG="$LDCONFIG"
2035 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2036 LIB_NAME="$LIB_NAME"
2037 LIB_PREFIX="$LIB_PREFIX"
2038 LIB_SUBSETS="$LIB_SUBSETS"
2039 LIB_SUFFIX="$LIB_SUFFIX"
2040 LIB_TRACING="$LIB_TRACING"
2041 LN_S="$LN_S"
2042 MAKE_TERMINFO="$MAKE_TERMINFO"
2043 NCURSES_MAJOR="$NCURSES_MAJOR"
2044 NCURSES_MINOR="$NCURSES_MINOR"
2045 NCURSES_OSPEED="$NCURSES_OSPEED"
2046 NCURSES_PATCH="$NCURSES_PATCH"
2047 SRC_SUBDIRS="$SRC_SUBDIRS"
2048 TERMINFO="$TERMINFO"
2049 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2050 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2051 TICS_NAME="$TICS_NAME"
2052 TIC_PATH="$TIC_PATH"
2053 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2054 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2055 TINFO_NAME="$TINFO_NAME"
2056 TINFO_SUFFIX="$TINFO_SUFFIX"
2057 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2058 WITH_CURSES_H="$with_curses_h"
2059 WITH_ECHO="${enable_echo:=yes}"
2060 WITH_OVERWRITE="$with_overwrite"
2061 cf_LIST_MODELS="$cf_list_models"
2062 cf_cv_abi_version="$cf_cv_abi_version"
2063 cf_cv_do_relink="$cf_cv_do_relink"
2064 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2065 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2066 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2067 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2068 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2069 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2070 cf_cv_rel_version="$cf_cv_rel_version"
2071 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2072 cf_cv_shared_soname='$cf_cv_shared_soname'
2073 cf_cv_shlib_version="$cf_cv_shlib_version"
2074 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2075 cf_cv_system_name="$cf_cv_system_name"
2076 cf_cv_term_driver="$with_term_driver"
2077 cf_with_ada="$cf_with_ada"
2078 cf_with_cxx_binding="$cf_with_cxx_binding"
2079 cf_with_db_install="$cf_with_db_install"
2080 cf_with_manpages="$cf_with_manpages"
2081 cf_with_tests="$cf_with_tests"
2082 with_shared_cxx="$with_shared_cxx"
2083 host="$host"
2084 target="$target"
2085
2086 ],cat)dnl
2087 ${MAKE:-make} preinstall